This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlre.pod: corrections for /a
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore most whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
93 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
99 whether space interpretation within a single multi-character construct.  For
100 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
101 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
102 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
103 but can between the C<(> and C<?>.  Within any delimiters for such a
104 construct, allowed spaces are not affected by C</x>, and depend on the
105 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
106 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
107 in C<\p{...}>  there can be spaces that follow the Unicode rules, for which see
108 L<perluniprops/Properties accessible through \p{} and \P{}>.
109 X</x>
110
111 =head2 Regular Expressions
112
113 =head3 Metacharacters
114
115 The patterns used in Perl pattern matching evolved from those supplied in
116 the Version 8 regex routines.  (The routines are derived
117 (distantly) from Henry Spencer's freely redistributable reimplementation
118 of the V8 routines.)  See L<Version 8 Regular Expressions> for
119 details.
120
121 In particular the following metacharacters have their standard I<egrep>-ish
122 meanings:
123 X<metacharacter>
124 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
125
126
127     \        Quote the next metacharacter
128     ^        Match the beginning of the line
129     .        Match any character (except newline)
130     $        Match the end of the line (or before newline at the end)
131     |        Alternation
132     ()       Grouping
133     []       Bracketed Character class
134
135 By default, the "^" character is guaranteed to match only the
136 beginning of the string, the "$" character only the end (or before the
137 newline at the end), and Perl does certain optimizations with the
138 assumption that the string contains only one line.  Embedded newlines
139 will not be matched by "^" or "$".  You may, however, wish to treat a
140 string as a multi-line buffer, such that the "^" will match after any
141 newline within the string (except if the newline is the last character in
142 the string), and "$" will match before any newline.  At the
143 cost of a little more overhead, you can do this by using the /m modifier
144 on the pattern match operator.  (Older programs did this by setting C<$*>,
145 but this practice has been removed in perl 5.9.)
146 X<^> X<$> X</m>
147
148 To simplify multi-line substitutions, the "." character never matches a
149 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
150 the string is a single line--even if it isn't.
151 X<.> X</s>
152
153 =head3 Quantifiers
154
155 The following standard quantifiers are recognized:
156 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
157
158     *           Match 0 or more times
159     +           Match 1 or more times
160     ?           Match 1 or 0 times
161     {n}         Match exactly n times
162     {n,}        Match at least n times
163     {n,m}       Match at least n but not more than m times
164
165 (If a curly bracket occurs in any other context, it is treated
166 as a regular character.  In particular, the lower bound
167 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
168 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
169 to non-negative integral values less than a preset limit defined when perl is built.
170 This is usually 32766 on the most common platforms.  The actual limit can
171 be seen in the error message generated by code such as this:
172
173     $_ **= $_ , / {$_} / for 2 .. 42;
174
175 By default, a quantified subpattern is "greedy", that is, it will match as
176 many times as possible (given a particular starting location) while still
177 allowing the rest of the pattern to match.  If you want it to match the
178 minimum number of times possible, follow the quantifier with a "?".  Note
179 that the meanings don't change, just the "greediness":
180 X<metacharacter> X<greedy> X<greediness>
181 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
182
183     *?        Match 0 or more times, not greedily
184     +?        Match 1 or more times, not greedily
185     ??        Match 0 or 1 time, not greedily
186     {n}?      Match exactly n times, not greedily
187     {n,}?     Match at least n times, not greedily
188     {n,m}?    Match at least n but not more than m times, not greedily
189
190 By default, when a quantified subpattern does not allow the rest of the
191 overall pattern to match, Perl will backtrack. However, this behaviour is
192 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
193 as well.
194
195  *+     Match 0 or more times and give nothing back
196  ++     Match 1 or more times and give nothing back
197  ?+     Match 0 or 1 time and give nothing back
198  {n}+   Match exactly n times and give nothing back (redundant)
199  {n,}+  Match at least n times and give nothing back
200  {n,m}+ Match at least n but not more than m times and give nothing back
201
202 For instance,
203
204    'aaaa' =~ /a++a/
205
206 will never match, as the C<a++> will gobble up all the C<a>'s in the
207 string and won't leave any for the remaining part of the pattern. This
208 feature can be extremely useful to give perl hints about where it
209 shouldn't backtrack. For instance, the typical "match a double-quoted
210 string" problem can be most efficiently performed when written as:
211
212    /"(?:[^"\\]++|\\.)*+"/
213
214 as we know that if the final quote does not match, backtracking will not
215 help. See the independent subexpression C<< (?>...) >> for more details;
216 possessive quantifiers are just syntactic sugar for that construct. For
217 instance the above example could also be written as follows:
218
219    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
220
221 =head3 Escape sequences
222
223 Because patterns are processed as double quoted strings, the following
224 also work:
225
226  \t          tab                   (HT, TAB)
227  \n          newline               (LF, NL)
228  \r          return                (CR)
229  \f          form feed             (FF)
230  \a          alarm (bell)          (BEL)
231  \e          escape (think troff)  (ESC)
232  \cK         control char          (example: VT)
233  \x{}, \x00  character whose ordinal is the given hexadecimal number
234  \N{name}    named Unicode character or character sequence
235  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
236  \o{}, \000  character whose ordinal is the given octal number
237  \l          lowercase next char (think vi)
238  \u          uppercase next char (think vi)
239  \L          lowercase till \E (think vi)
240  \U          uppercase till \E (think vi)
241  \Q          quote (disable) pattern metacharacters till \E
242  \E          end either case modification or quoted section, think vi
243
244 Details are in L<perlop/Quote and Quote-like Operators>.
245
246 =head3 Character Classes and other Special Escapes
247
248 In addition, Perl defines the following:
249 X<\g> X<\k> X<\K> X<backreference>
250
251  Sequence   Note    Description
252   [...]     [1]  Match a character according to the rules of the
253                    bracketed character class defined by the "...".
254                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
255   [[:...:]] [2]  Match a character according to the rules of the POSIX
256                    character class "..." within the outer bracketed
257                    character class.  Example: [[:upper:]] matches any
258                    uppercase character.
259   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
260                    other connector punctuation chars plus Unicode
261                    marks
262   \W        [3]  Match a non-"word" character
263   \s        [3]  Match a whitespace character
264   \S        [3]  Match a non-whitespace character
265   \d        [3]  Match a decimal digit character
266   \D        [3]  Match a non-digit character
267   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
268   \PP       [3]  Match non-P
269   \X        [4]  Match Unicode "eXtended grapheme cluster"
270   \C             Match a single C-language char (octet) even if that is
271                    part of a larger UTF-8 character.  Thus it breaks up
272                    characters into their UTF-8 bytes, so you may end up
273                    with malformed pieces of UTF-8.  Unsupported in
274                    lookbehind.
275   \1        [5]  Backreference to a specific capture group or buffer.
276                    '1' may actually be any positive integer.
277   \g1       [5]  Backreference to a specific or previous group,
278   \g{-1}    [5]  The number may be negative indicating a relative
279                    previous group and may optionally be wrapped in
280                    curly brackets for safer parsing.
281   \g{name}  [5]  Named backreference
282   \k<name>  [5]  Named backreference
283   \K        [6]  Keep the stuff left of the \K, don't include it in $&
284   \N        [7]  Any character but \n (experimental).  Not affected by
285                    /s modifier
286   \v        [3]  Vertical whitespace
287   \V        [3]  Not vertical whitespace
288   \h        [3]  Horizontal whitespace
289   \H        [3]  Not horizontal whitespace
290   \R        [4]  Linebreak
291
292 =over 4
293
294 =item [1]
295
296 See L<perlrecharclass/Bracketed Character Classes> for details.
297
298 =item [2]
299
300 See L<perlrecharclass/POSIX Character Classes> for details.
301
302 =item [3]
303
304 See L<perlrecharclass/Backslash sequences> for details.
305
306 =item [4]
307
308 See L<perlrebackslash/Misc> for details.
309
310 =item [5]
311
312 See L</Capture groups> below for details.
313
314 =item [6]
315
316 See L</Extended Patterns> below for details.
317
318 =item [7]
319
320 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
321 character or character sequence whose name is C<NAME>; and similarly
322 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
323 code point is I<hex>.  Otherwise it matches any character but C<\n>.
324
325 =back
326
327 =head3 Assertions
328
329 Perl defines the following zero-width assertions:
330 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
331 X<regexp, zero-width assertion>
332 X<regular expression, zero-width assertion>
333 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
334
335     \b  Match a word boundary
336     \B  Match except at a word boundary
337     \A  Match only at beginning of string
338     \Z  Match only at end of string, or before newline at the end
339     \z  Match only at end of string
340     \G  Match only at pos() (e.g. at the end-of-match position
341         of prior m//g)
342
343 A word boundary (C<\b>) is a spot between two characters
344 that has a C<\w> on one side of it and a C<\W> on the other side
345 of it (in either order), counting the imaginary characters off the
346 beginning and end of the string as matching a C<\W>.  (Within
347 character classes C<\b> represents backspace rather than a word
348 boundary, just as it normally does in any double-quoted string.)
349 The C<\A> and C<\Z> are just like "^" and "$", except that they
350 won't match multiple times when the C</m> modifier is used, while
351 "^" and "$" will match at every internal line boundary.  To match
352 the actual end of the string and not ignore an optional trailing
353 newline, use C<\z>.
354 X<\b> X<\A> X<\Z> X<\z> X</m>
355
356 The C<\G> assertion can be used to chain global matches (using
357 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
358 It is also useful when writing C<lex>-like scanners, when you have
359 several patterns that you want to match against consequent substrings
360 of your string, see the previous reference.  The actual location
361 where C<\G> will match can also be influenced by using C<pos()> as
362 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
363 matches is modified somewhat, in that contents to the left of C<\G> is
364 not counted when determining the length of the match. Thus the following
365 will not match forever:
366 X<\G>
367
368      my $string = 'ABC';
369      pos($string) = 1;
370      while ($string =~ /(.\G)/g) {
371          print $1;
372      }
373
374 It will print 'A' and then terminate, as it considers the match to
375 be zero-width, and thus will not match at the same position twice in a
376 row.
377
378 It is worth noting that C<\G> improperly used can result in an infinite
379 loop. Take care when using patterns that include C<\G> in an alternation.
380
381 =head3 Capture groups
382
383 The bracketing construct C<( ... )> creates capture groups (also referred to as
384 capture buffers). To refer to the current contents of a group later on, within
385 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
386 for the second, and so on.
387 This is called a I<backreference>.
388 X<regex, capture buffer> X<regexp, capture buffer>
389 X<regex, capture group> X<regexp, capture group>
390 X<regular expression, capture buffer> X<backreference>
391 X<regular expression, capture group> X<backreference>
392 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
393 X<named capture buffer> X<regular expression, named capture buffer>
394 X<named capture group> X<regular expression, named capture group>
395 X<%+> X<$+{name}> X<< \k<name> >>
396 There is no limit to the number of captured substrings that you may use.
397 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
398 a group did not match, the associated backreference won't match either. (This
399 can happen if the group is optional, or in a different branch of an
400 alternation.)
401 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
402 this form, described below.
403
404 You can also refer to capture groups relatively, by using a negative number, so
405 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
406 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
407 example:
408
409         /
410          (Y)            # group 1
411          (              # group 2
412             (X)         # group 3
413             \g{-1}      # backref to group 3
414             \g{-3}      # backref to group 1
415          )
416         /x
417
418 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
419 interpolate regexes into larger regexes and not have to worry about the
420 capture groups being renumbered.
421
422 You can dispense with numbers altogether and create named capture groups.
423 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
424 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
425 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
426 I<name> must not begin with a number, nor contain hyphens.
427 When different groups within the same pattern have the same name, any reference
428 to that name assumes the leftmost defined group.  Named groups count in
429 absolute and relative numbering, and so can also be referred to by those
430 numbers.
431 (It's possible to do things with named capture groups that would otherwise
432 require C<(??{})>.)
433
434 Capture group contents are dynamically scoped and available to you outside the
435 pattern until the end of the enclosing block or until the next successful
436 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
437 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
438 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
439
440 Braces are required in referring to named capture groups, but are optional for
441 absolute or relative numbered ones.  Braces are safer when creating a regex by
442 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
443 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
444 is probably not what you intended.
445
446 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
447 there were no named nor relative numbered capture groups.  Absolute numbered
448 groups were referred to using C<\1>, C<\2>, etc, and this notation is still
449 accepted (and likely always will be).  But it leads to some ambiguities if
450 there are more than 9 capture groups, as C<\10> could mean either the tenth
451 capture group, or the character whose ordinal in octal is 010 (a backspace in
452 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
453 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
454 a backreference only if at least 11 left parentheses have opened before it.
455 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
456 There are several examples below that illustrate these perils.  You can avoid
457 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
458 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
459 digits padded with leading zeros, since a leading zero implies an octal
460 constant.
461
462 The C<\I<digit>> notation also works in certain circumstances outside
463 the pattern.  See L</Warning on \1 Instead of $1> below for details.)
464
465 Examples:
466
467     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
468
469     /(.)\g1/                        # find first doubled char
470          and print "'$1' is the first doubled character\n";
471
472     /(?<char>.)\k<char>/            # ... a different way
473          and print "'$+{char}' is the first doubled character\n";
474
475     /(?'char'.)\g1/                 # ... mix and match
476          and print "'$1' is the first doubled character\n";
477
478     if (/Time: (..):(..):(..)/) {   # parse out values
479         $hours = $1;
480         $minutes = $2;
481         $seconds = $3;
482     }
483
484     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
485     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
486     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
487     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
488
489     $a = '(.)\1';        # Creates problems when concatenated.
490     $b = '(.)\g{1}';     # Avoids the problems.
491     "aa" =~ /${a}/;      # True
492     "aa" =~ /${b}/;      # True
493     "aa0" =~ /${a}0/;    # False!
494     "aa0" =~ /${b}0/;    # True
495     "aa\x08" =~ /${a}0/;  # True!
496     "aa\x08" =~ /${b}0/;  # False
497
498 Several special variables also refer back to portions of the previous
499 match.  C<$+> returns whatever the last bracket match matched.
500 C<$&> returns the entire matched string.  (At one point C<$0> did
501 also, but now it returns the name of the program.)  C<$`> returns
502 everything before the matched string.  C<$'> returns everything
503 after the matched string. And C<$^N> contains whatever was matched by
504 the most-recently closed group (submatch). C<$^N> can be used in
505 extended patterns (see below), for example to assign a submatch to a
506 variable.
507 X<$+> X<$^N> X<$&> X<$`> X<$'>
508
509 These special variables, like the C<%+> hash and the numbered match variables
510 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
511 until the end of the enclosing block or until the next successful
512 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
513 X<$+> X<$^N> X<$&> X<$`> X<$'>
514 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
515
516 B<NOTE>: Failed matches in Perl do not reset the match variables,
517 which makes it easier to write code that tests for a series of more
518 specific cases and remembers the best match.
519
520 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
521 C<$'> anywhere in the program, it has to provide them for every
522 pattern match.  This may substantially slow your program.  Perl
523 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
524 price for each pattern that contains capturing parentheses.  (To
525 avoid this cost while retaining the grouping behaviour, use the
526 extended regular expression C<(?: ... )> instead.)  But if you never
527 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
528 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
529 if you can, but if you can't (and some algorithms really appreciate
530 them), once you've used them once, use them at will, because you've
531 already paid the price.  As of 5.005, C<$&> is not so costly as the
532 other two.
533 X<$&> X<$`> X<$'>
534
535 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
536 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
537 and C<$'>, B<except> that they are only guaranteed to be defined after a
538 successful match that was executed with the C</p> (preserve) modifier.
539 The use of these variables incurs no global performance penalty, unlike
540 their punctuation char equivalents, however at the trade-off that you
541 have to tell perl when you want to use them.
542 X</p> X<p modifier>
543
544 =head2 Quoting metacharacters
545
546 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
547 C<\w>, C<\n>.  Unlike some other regular expression languages, there
548 are no backslashed symbols that aren't alphanumeric.  So anything
549 that looks like \\, \(, \), \<, \>, \{, or \} is always
550 interpreted as a literal character, not a metacharacter.  This was
551 once used in a common idiom to disable or quote the special meanings
552 of regular expression metacharacters in a string that you want to
553 use for a pattern. Simply quote all non-"word" characters:
554
555     $pattern =~ s/(\W)/\\$1/g;
556
557 (If C<use locale> is set, then this depends on the current locale.)
558 Today it is more common to use the quotemeta() function or the C<\Q>
559 metaquoting escape sequence to disable all metacharacters' special
560 meanings like this:
561
562     /$unquoted\Q$quoted\E$unquoted/
563
564 Beware that if you put literal backslashes (those not inside
565 interpolated variables) between C<\Q> and C<\E>, double-quotish
566 backslash interpolation may lead to confusing results.  If you
567 I<need> to use literal backslashes within C<\Q...\E>,
568 consult L<perlop/"Gory details of parsing quoted constructs">.
569
570 =head2 Extended Patterns
571
572 Perl also defines a consistent extension syntax for features not
573 found in standard tools like B<awk> and B<lex>.  The syntax is a
574 pair of parentheses with a question mark as the first thing within
575 the parentheses.  The character after the question mark indicates
576 the extension.
577
578 The stability of these extensions varies widely.  Some have been
579 part of the core language for many years.  Others are experimental
580 and may change without warning or be completely removed.  Check
581 the documentation on an individual feature to verify its current
582 status.
583
584 A question mark was chosen for this and for the minimal-matching
585 construct because 1) question marks are rare in older regular
586 expressions, and 2) whenever you see one, you should stop and
587 "question" exactly what is going on.  That's psychology...
588
589 =over 10
590
591 =item C<(?#text)>
592 X<(?#)>
593
594 A comment.  The text is ignored.  If the C</x> modifier enables
595 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
596 the comment as soon as it sees a C<)>, so there is no way to put a literal
597 C<)> in the comment.
598
599 =item C<(?adlupimsx-imsx)>
600
601 =item C<(?^alupimsx)>
602 X<(?)> X<(?^)>
603
604 One or more embedded pattern-match modifiers, to be turned on (or
605 turned off, if preceded by C<->) for the remainder of the pattern or
606 the remainder of the enclosing pattern group (if any).
607
608 This is particularly useful for dynamic patterns, such as those read in from a
609 configuration file, taken from an argument, or specified in a table
610 somewhere.  Consider the case where some patterns want to be case
611 sensitive and some do not:  The case insensitive ones merely need to
612 include C<(?i)> at the front of the pattern.  For example:
613
614     $pattern = "foobar";
615     if ( /$pattern/i ) { }
616
617     # more flexible:
618
619     $pattern = "(?i)foobar";
620     if ( /$pattern/ ) { }
621
622 These modifiers are restored at the end of the enclosing group. For example,
623
624     ( (?i) blah ) \s+ \g1
625
626 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
627 repetition of the previous word, assuming the C</x> modifier, and no C</i>
628 modifier outside this group.
629
630 These modifiers do not carry over into named subpatterns called in the
631 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
632 change the case-sensitivity of the "NAME" pattern.
633
634 Any of these modifiers can be set to apply globally to all regular
635 expressions compiled within the scope of a C<use re>.  See
636 L<re/'/flags' mode>.
637
638 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
639 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
640 C<"d">) may follow the caret to override it.
641 But a minus sign is not legal with it.
642
643 Also, starting in Perl 5.14, are modifiers C<"a">, C<"d">, C<"l">, and
644 C<"u">, which for 5.14 may not be used as suffix modifiers.
645
646 C<"l"> means to use a locale (see L<perllocale>) when pattern matching.
647 The locale used will be the one in effect at the time of execution of
648 the pattern match.  This may not be the same as the compilation-time
649 locale, and can differ from one match to another if there is an
650 intervening call of the
651 L<setlocale() function|perllocale/The setlocale function>.
652 This modifier is automatically set if the regular expression is compiled
653 within the scope of a C<"use locale"> pragma.  Results are not
654 well-defined when using this and matching against a utf8-encoded string.
655
656 C<"u"> means to use Unicode semantics when pattern matching.  It is
657 automatically set if the regular expression is encoded in utf8, or is
658 compiled within the scope of a
659 L<C<"use feature 'unicode_strings">|feature> pragma (and isn't also in
660 the scope of L<C<"use locale">|locale> nor L<C<"use bytes">|bytes>
661 pragmas.  On ASCII platforms, the code points between 128 and 255 take on their
662 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's), whereas
663 in strict ASCII their meanings are undefined.  Thus the platform
664 effectively becomes a Unicode platform.  The ASCII characters remain as
665 ASCII characters (since ASCII is a subset of Latin-1 and Unicode).  For
666 example, when this option is not on, on a non-utf8 string, C<"\w">
667 matches precisely C<[A-Za-z0-9_]>.  When the option is on, it matches
668 not just those, but all the Latin-1 word characters (such as an "n" with
669 a tilde).  On EBCDIC platforms, which already are equivalent to Latin-1,
670 this modifier changes behavior only when the C<"/i"> modifier is also
671 specified, and affects only two characters, giving them full Unicode
672 semantics: the C<MICRO SIGN> will match the Greek capital and
673 small letters C<MU>; otherwise not; and the C<LATIN CAPITAL LETTER SHARP
674 S> will match any of C<SS>, C<Ss>, C<sS>, and C<ss>, otherwise not.
675 (This last case is buggy, however.)
676
677 C<"a"> is the same as C<"u">, except that C<\d>, C<\s>, C<\w>, and the
678 Posix character classes are restricted to matching in the ASCII range
679 only.  That is, with this modifier, C<\d> always means precisely the
680 digits C<"0"> to C<"9">; C<\s> means the five characters C<[ \f\n\r\t]>;
681 C<\w> means the 63 characters C<[A-Za-z0-9_]>; and likewise, all the
682 Posix classes such as C<[[:print:]]> match only the appropriate
683 ASCII-range characters.  As you would expect, this modifier causes, for
684 example, C<\D> to mean the same thing as C<[^0-9]>; in fact, all
685 non-ASCII characters match C<\D>, C<\S>, and C<\W>.  C<\b> still means
686 to match at the boundary between C<\w> and C<\W>, using the C<"a">
687 definitions of them (similarly for C<\B>).  Otherwise, C<"a"> behaves
688 like the C<"u"> modifier, in that case-insensitive matching uses Unicode
689 semantics; for example, "k" will match the Unicode C<\N{KELVIN SIGN}>
690 under C</i> matching, and code points in the Latin1 range, above ASCII
691 will have Unicode semantics when it comes to case-insensitive matching.
692
693 C<"d"> means to use the traditional Perl pattern matching behavior.
694 This is dualistic (hence the name C<"d">, which also could stand for
695 "depends").  When this is in effect, Perl matches utf8-encoded strings
696 using Unicode rules, and matches non-utf8-encoded strings using the
697 platform's native character set rules.  (If the regular expression
698 itself is encoded in utf8, Unicode rules are used regardless of the
699 target string's encoding.)
700 See L<perlunicode/The "Unicode Bug">.  It is automatically selected by
701 default if the regular expression is compiled neither within the scope
702 of a C<"use locale"> pragma nor a <C<"use feature 'unicode_strings">
703 pragma.
704
705 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
706 that they can only be enabled, not disabled, and the C<d>, C<l>, and
707 C<u> modifiers are mutually exclusive: specifying one de-specifies the
708 others, and a maximum of one may appear in the construct.  Thus, for
709 example, C<(?-p)>, C<(?-d:...)>, and C<(?dl:...)> will warn when
710 compiled under C<use warnings>.
711
712 Note also that the C<p> modifier is special in that its presence
713 anywhere in a pattern has a global effect.
714
715 =item C<(?:pattern)>
716 X<(?:)>
717
718 =item C<(?adluimsx-imsx:pattern)>
719
720 =item C<(?^aluimsx:pattern)>
721 X<(?^:)>
722
723 This is for clustering, not capturing; it groups subexpressions like
724 "()", but doesn't make backreferences as "()" does.  So
725
726     @fields = split(/\b(?:a|b|c)\b/)
727
728 is like
729
730     @fields = split(/\b(a|b|c)\b/)
731
732 but doesn't spit out extra fields.  It's also cheaper not to capture
733 characters if you don't need to.
734
735 Any letters between C<?> and C<:> act as flags modifiers as with
736 C<(?adluimsx-imsx)>.  For example,
737
738     /(?s-i:more.*than).*million/i
739
740 is equivalent to the more verbose
741
742     /(?:(?s-i)more.*than).*million/i
743
744 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
745 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
746 flags (except C<"d">) may follow the caret, so
747
748     (?^x:foo)
749
750 is equivalent to
751
752     (?x-ims:foo)
753
754 The caret tells Perl that this cluster doesn't inherit the flags of any
755 surrounding pattern, but to go back to the system defaults (C<d-imsx>),
756 modified by any flags specified.
757
758 The caret allows for simpler stringification of compiled regular
759 expressions.  These look like
760
761     (?^:pattern)
762
763 with any non-default flags appearing between the caret and the colon.
764 A test that looks at such stringification thus doesn't need to have the
765 system default flags hard-coded in it, just the caret.  If new flags are
766 added to Perl, the meaning of the caret's expansion will change to include
767 the default for those flags, so the test will still work, unchanged.
768
769 Specifying a negative flag after the caret is an error, as the flag is
770 redundant.
771
772 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
773 to match at the beginning.
774
775 =item C<(?|pattern)>
776 X<(?|)> X<Branch reset>
777
778 This is the "branch reset" pattern, which has the special property
779 that the capture groups are numbered from the same starting point
780 in each alternation branch. It is available starting from perl 5.10.0.
781
782 Capture groups are numbered from left to right, but inside this
783 construct the numbering is restarted for each branch.
784
785 The numbering within each branch will be as normal, and any groups
786 following this construct will be numbered as though the construct
787 contained only one branch, that being the one with the most capture
788 groups in it.
789
790 This construct will be useful when you want to capture one of a
791 number of alternative matches.
792
793 Consider the following pattern.  The numbers underneath show in
794 which group the captured content will be stored.
795
796
797     # before  ---------------branch-reset----------- after        
798     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
799     # 1            2         2  3        2     3     4  
800
801 Be careful when using the branch reset pattern in combination with 
802 named captures. Named captures are implemented as being aliases to 
803 numbered groups holding the captures, and that interferes with the
804 implementation of the branch reset pattern. If you are using named
805 captures in a branch reset pattern, it's best to use the same names,
806 in the same order, in each of the alternations:
807
808    /(?|  (?<a> x ) (?<b> y )
809       |  (?<a> z ) (?<b> w )) /x
810
811 Not doing so may lead to surprises:
812
813   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
814   say $+ {a};   # Prints '12'
815   say $+ {b};   # *Also* prints '12'.
816
817 The problem here is that both the group named C<< a >> and the group
818 named C<< b >> are aliases for the group belonging to C<< $1 >>.
819
820 =item Look-Around Assertions
821 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
822
823 Look-around assertions are zero width patterns which match a specific
824 pattern without including it in C<$&>. Positive assertions match when
825 their subpattern matches, negative assertions match when their subpattern
826 fails. Look-behind matches text up to the current match position,
827 look-ahead matches text following the current match position.
828
829 =over 4
830
831 =item C<(?=pattern)>
832 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
833
834 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
835 matches a word followed by a tab, without including the tab in C<$&>.
836
837 =item C<(?!pattern)>
838 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
839
840 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
841 matches any occurrence of "foo" that isn't followed by "bar".  Note
842 however that look-ahead and look-behind are NOT the same thing.  You cannot
843 use this for look-behind.
844
845 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
846 will not do what you want.  That's because the C<(?!foo)> is just saying that
847 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
848 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
849 say "like" because there's the case of your "bar" not having three characters
850 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
851 Sometimes it's still easier just to say:
852
853     if (/bar/ && $` !~ /foo$/)
854
855 For look-behind see below.
856
857 =item C<(?<=pattern)> C<\K>
858 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
859
860 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
861 matches a word that follows a tab, without including the tab in C<$&>.
862 Works only for fixed-width look-behind.
863
864 There is a special form of this construct, called C<\K>, which causes the
865 regex engine to "keep" everything it had matched prior to the C<\K> and
866 not include it in C<$&>. This effectively provides variable length
867 look-behind. The use of C<\K> inside of another look-around assertion
868 is allowed, but the behaviour is currently not well defined.
869
870 For various reasons C<\K> may be significantly more efficient than the
871 equivalent C<< (?<=...) >> construct, and it is especially useful in
872 situations where you want to efficiently remove something following
873 something else in a string. For instance
874
875   s/(foo)bar/$1/g;
876
877 can be rewritten as the much more efficient
878
879   s/foo\Kbar//g;
880
881 =item C<(?<!pattern)>
882 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
883
884 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
885 matches any occurrence of "foo" that does not follow "bar".  Works
886 only for fixed-width look-behind.
887
888 =back
889
890 =item C<(?'NAME'pattern)>
891
892 =item C<< (?<NAME>pattern) >>
893 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
894
895 A named capture group. Identical in every respect to normal capturing
896 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
897 used after a successful match to refer to a named group. See C<perlvar>
898 for more details on the C<%+> and C<%-> hashes.
899
900 If multiple distinct capture groups have the same name then the
901 $+{NAME} will refer to the leftmost defined group in the match.
902
903 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
904
905 B<NOTE:> While the notation of this construct is the same as the similar
906 function in .NET regexes, the behavior is not. In Perl the groups are
907 numbered sequentially regardless of being named or not. Thus in the
908 pattern
909
910   /(x)(?<foo>y)(z)/
911
912 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
913 the opposite which is what a .NET regex hacker might expect.
914
915 Currently NAME is restricted to simple identifiers only.
916 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
917 its Unicode extension (see L<utf8>),
918 though it isn't extended by the locale (see L<perllocale>).
919
920 B<NOTE:> In order to make things easier for programmers with experience
921 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
922 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
923 support the use of single quotes as a delimiter for the name.
924
925 =item C<< \k<NAME> >>
926
927 =item C<< \k'NAME' >>
928
929 Named backreference. Similar to numeric backreferences, except that
930 the group is designated by name and not number. If multiple groups
931 have the same name then it refers to the leftmost defined group in
932 the current match.
933
934 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
935 earlier in the pattern.
936
937 Both forms are equivalent.
938
939 B<NOTE:> In order to make things easier for programmers with experience
940 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
941 may be used instead of C<< \k<NAME> >>.
942
943 =item C<(?{ code })>
944 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
945
946 B<WARNING>: This extended regular expression feature is considered
947 experimental, and may be changed without notice. Code executed that
948 has side effects may not perform identically from version to version
949 due to the effect of future optimisations in the regex engine.
950
951 This zero-width assertion evaluates any embedded Perl code.  It
952 always succeeds, and its C<code> is not interpolated.  Currently,
953 the rules to determine where the C<code> ends are somewhat convoluted.
954
955 This feature can be used together with the special variable C<$^N> to
956 capture the results of submatches in variables without having to keep
957 track of the number of nested parentheses. For example:
958
959   $_ = "The brown fox jumps over the lazy dog";
960   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
961   print "color = $color, animal = $animal\n";
962
963 Inside the C<(?{...})> block, C<$_> refers to the string the regular
964 expression is matching against. You can also use C<pos()> to know what is
965 the current position of matching within this string.
966
967 The C<code> is properly scoped in the following sense: If the assertion
968 is backtracked (compare L<"Backtracking">), all changes introduced after
969 C<local>ization are undone, so that
970
971   $_ = 'a' x 8;
972   m<
973      (?{ $cnt = 0 })                   # Initialize $cnt.
974      (
975        a
976        (?{
977            local $cnt = $cnt + 1;      # Update $cnt, backtracking-safe.
978        })
979      )*
980      aaaa
981      (?{ $res = $cnt })                # On success copy to
982                                        # non-localized location.
983    >x;
984
985 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
986 introduced value, because the scopes that restrict C<local> operators
987 are unwound.
988
989 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
990 switch.  If I<not> used in this way, the result of evaluation of
991 C<code> is put into the special variable C<$^R>.  This happens
992 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
993 inside the same regular expression.
994
995 The assignment to C<$^R> above is properly localized, so the old
996 value of C<$^R> is restored if the assertion is backtracked; compare
997 L<"Backtracking">.
998
999 For reasons of security, this construct is forbidden if the regular
1000 expression involves run-time interpolation of variables, unless the
1001 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1002 variables contain results of C<qr//> operator (see
1003 L<perlop/"qr/STRINGE<sol>msixpo">).
1004
1005 This restriction is due to the wide-spread and remarkably convenient
1006 custom of using run-time determined strings as patterns.  For example:
1007
1008     $re = <>;
1009     chomp $re;
1010     $string =~ /$re/;
1011
1012 Before Perl knew how to execute interpolated code within a pattern,
1013 this operation was completely safe from a security point of view,
1014 although it could raise an exception from an illegal pattern.  If
1015 you turn on the C<use re 'eval'>, though, it is no longer secure,
1016 so you should only do so if you are also using taint checking.
1017 Better yet, use the carefully constrained evaluation within a Safe
1018 compartment.  See L<perlsec> for details about both these mechanisms.
1019
1020 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
1021 broken. The result is unpredictable and will make perl unstable. The
1022 workaround is to use global (C<our>) variables.
1023
1024 B<WARNING>: In perl 5.12.x and earlier, the regex engine
1025 was not re-entrant, so interpolated code could not
1026 safely invoke the regex engine either directly with
1027 C<m//> or C<s///>), or indirectly with functions such as
1028 C<split>. Invoking the regex engine in these blocks would make perl
1029 unstable.
1030
1031 =item C<(??{ code })>
1032 X<(??{})>
1033 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1034
1035 B<WARNING>: This extended regular expression feature is considered
1036 experimental, and may be changed without notice. Code executed that
1037 has side effects may not perform identically from version to version
1038 due to the effect of future optimisations in the regex engine.
1039
1040 This is a "postponed" regular subexpression.  The C<code> is evaluated
1041 at run time, at the moment this subexpression may match.  The result
1042 of evaluation is considered as a regular expression and matched as
1043 if it were inserted instead of this construct.  Note that this means
1044 that the contents of capture groups defined inside an eval'ed pattern
1045 are not available outside of the pattern, and vice versa, there is no
1046 way for the inner pattern to refer to a capture group defined outside.
1047 Thus,
1048
1049     ('a' x 100)=~/(??{'(.)' x 100})/
1050
1051 B<will> match, it will B<not> set $1.
1052
1053 The C<code> is not interpolated.  As before, the rules to determine
1054 where the C<code> ends are currently somewhat convoluted.
1055
1056 The following pattern matches a parenthesized group:
1057
1058   $re = qr{
1059              \(
1060              (?:
1061                 (?> [^()]+ )       # Non-parens without backtracking
1062               |
1063                 (??{ $re })        # Group with matching parens
1064              )*
1065              \)
1066           }x;
1067
1068 See also C<(?PARNO)> for a different, more efficient way to accomplish
1069 the same task.
1070
1071 For reasons of security, this construct is forbidden if the regular
1072 expression involves run-time interpolation of variables, unless the
1073 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1074 variables contain results of C<qr//> operator (see
1075 L<perlop/"qrE<sol>STRINGE<sol>msixpo">).
1076
1077 In perl 5.12.x and earlier, because the regex engine was not re-entrant,
1078 delayed code could not safely invoke the regex engine either directly with
1079 C<m//> or C<s///>), or indirectly with functions such as C<split>.
1080
1081 Recursing deeper than 50 times without consuming any input string will
1082 result in a fatal error.  The maximum depth is compiled into perl, so
1083 changing it requires a custom build.
1084
1085 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1086 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1087 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1088 X<regex, relative recursion>
1089
1090 Similar to C<(??{ code })> except it does not involve compiling any code,
1091 instead it treats the contents of a capture group as an independent
1092 pattern that must match at the current position.  Capture groups
1093 contained by the pattern will have the value as determined by the
1094 outermost recursion.
1095
1096 PARNO is a sequence of digits (not starting with 0) whose value reflects
1097 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1098 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1099 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1100 to be relative, with negative numbers indicating preceding capture groups
1101 and positive ones following. Thus C<(?-1)> refers to the most recently
1102 declared group, and C<(?+1)> indicates the next group to be declared.
1103 Note that the counting for relative recursion differs from that of
1104 relative backreferences, in that with recursion unclosed groups B<are>
1105 included.
1106
1107 The following pattern matches a function foo() which may contain
1108 balanced parentheses as the argument.
1109
1110   $re = qr{ (                    # paren group 1 (full function)
1111               foo
1112               (                  # paren group 2 (parens)
1113                 \(
1114                   (              # paren group 3 (contents of parens)
1115                   (?:
1116                    (?> [^()]+ )  # Non-parens without backtracking
1117                   |
1118                    (?2)          # Recurse to start of paren group 2
1119                   )*
1120                   )
1121                 \)
1122               )
1123             )
1124           }x;
1125
1126 If the pattern was used as follows
1127
1128     'foo(bar(baz)+baz(bop))'=~/$re/
1129         and print "\$1 = $1\n",
1130                   "\$2 = $2\n",
1131                   "\$3 = $3\n";
1132
1133 the output produced should be the following:
1134
1135     $1 = foo(bar(baz)+baz(bop))
1136     $2 = (bar(baz)+baz(bop))
1137     $3 = bar(baz)+baz(bop)
1138
1139 If there is no corresponding capture group defined, then it is a
1140 fatal error.  Recursing deeper than 50 times without consuming any input
1141 string will also result in a fatal error.  The maximum depth is compiled
1142 into perl, so changing it requires a custom build.
1143
1144 The following shows how using negative indexing can make it
1145 easier to embed recursive patterns inside of a C<qr//> construct
1146 for later use:
1147
1148     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1149     if (/foo $parens \s+ + \s+ bar $parens/x) {
1150        # do something here...
1151     }
1152
1153 B<Note> that this pattern does not behave the same way as the equivalent
1154 PCRE or Python construct of the same form. In Perl you can backtrack into
1155 a recursed group, in PCRE and Python the recursed into group is treated
1156 as atomic. Also, modifiers are resolved at compile time, so constructs
1157 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1158 be processed.
1159
1160 =item C<(?&NAME)>
1161 X<(?&NAME)>
1162
1163 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1164 parenthesis to recurse to is determined by name. If multiple parentheses have
1165 the same name, then it recurses to the leftmost.
1166
1167 It is an error to refer to a name that is not declared somewhere in the
1168 pattern.
1169
1170 B<NOTE:> In order to make things easier for programmers with experience
1171 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1172 may be used instead of C<< (?&NAME) >>.
1173
1174 =item C<(?(condition)yes-pattern|no-pattern)>
1175 X<(?()>
1176
1177 =item C<(?(condition)yes-pattern)>
1178
1179 Conditional expression.  C<(condition)> should be either an integer in
1180 parentheses (which is valid if the corresponding pair of parentheses
1181 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1182 name in angle brackets or single quotes (which is valid if a group
1183 with the given name matched), or the special symbol (R) (true when
1184 evaluated inside of recursion or eval). Additionally the R may be
1185 followed by a number, (which will be true when evaluated when recursing
1186 inside of the appropriate group), or by C<&NAME>, in which case it will
1187 be true only when evaluated during recursion in the named group.
1188
1189 Here's a summary of the possible predicates:
1190
1191 =over 4
1192
1193 =item (1) (2) ...
1194
1195 Checks if the numbered capturing group has matched something.
1196
1197 =item (<NAME>) ('NAME')
1198
1199 Checks if a group with the given name has matched something.
1200
1201 =item (?{ CODE })
1202
1203 Treats the code block as the condition.
1204
1205 =item (R)
1206
1207 Checks if the expression has been evaluated inside of recursion.
1208
1209 =item (R1) (R2) ...
1210
1211 Checks if the expression has been evaluated while executing directly
1212 inside of the n-th capture group. This check is the regex equivalent of
1213
1214   if ((caller(0))[3] eq 'subname') { ... }
1215
1216 In other words, it does not check the full recursion stack.
1217
1218 =item (R&NAME)
1219
1220 Similar to C<(R1)>, this predicate checks to see if we're executing
1221 directly inside of the leftmost group with a given name (this is the same
1222 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1223 stack, but only the name of the innermost active recursion.
1224
1225 =item (DEFINE)
1226
1227 In this case, the yes-pattern is never directly executed, and no
1228 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1229 See below for details.
1230
1231 =back
1232
1233 For example:
1234
1235     m{ ( \( )?
1236        [^()]+
1237        (?(1) \) )
1238      }x
1239
1240 matches a chunk of non-parentheses, possibly included in parentheses
1241 themselves.
1242
1243 A special form is the C<(DEFINE)> predicate, which never executes directly
1244 its yes-pattern, and does not allow a no-pattern. This allows to define
1245 subpatterns which will be executed only by using the recursion mechanism.
1246 This way, you can define a set of regular expression rules that can be
1247 bundled into any pattern you choose.
1248
1249 It is recommended that for this usage you put the DEFINE block at the
1250 end of the pattern, and that you name any subpatterns defined within it.
1251
1252 Also, it's worth noting that patterns defined this way probably will
1253 not be as efficient, as the optimiser is not very clever about
1254 handling them.
1255
1256 An example of how this might be used is as follows:
1257
1258   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1259    (?(DEFINE)
1260      (?<NAME_PAT>....)
1261      (?<ADRESS_PAT>....)
1262    )/x
1263
1264 Note that capture groups matched inside of recursion are not accessible
1265 after the recursion returns, so the extra layer of capturing groups is
1266 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1267 C<$+{NAME}> would be.
1268
1269 =item C<< (?>pattern) >>
1270 X<backtrack> X<backtracking> X<atomic> X<possessive>
1271
1272 An "independent" subexpression, one which matches the substring
1273 that a I<standalone> C<pattern> would match if anchored at the given
1274 position, and it matches I<nothing other than this substring>.  This
1275 construct is useful for optimizations of what would otherwise be
1276 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1277 It may also be useful in places where the "grab all you can, and do not
1278 give anything back" semantic is desirable.
1279
1280 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1281 (anchored at the beginning of string, as above) will match I<all>
1282 characters C<a> at the beginning of string, leaving no C<a> for
1283 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1284 since the match of the subgroup C<a*> is influenced by the following
1285 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1286 C<a*ab> will match fewer characters than a standalone C<a*>, since
1287 this makes the tail match.
1288
1289 An effect similar to C<< (?>pattern) >> may be achieved by writing
1290 C<(?=(pattern))\g1>.  This matches the same substring as a standalone
1291 C<a+>, and the following C<\g1> eats the matched string; it therefore
1292 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1293 (The difference between these two constructs is that the second one
1294 uses a capturing group, thus shifting ordinals of backreferences
1295 in the rest of a regular expression.)
1296
1297 Consider this pattern:
1298
1299     m{ \(
1300           (
1301             [^()]+           # x+
1302           |
1303             \( [^()]* \)
1304           )+
1305        \)
1306      }x
1307
1308 That will efficiently match a nonempty group with matching parentheses
1309 two levels deep or less.  However, if there is no such group, it
1310 will take virtually forever on a long string.  That's because there
1311 are so many different ways to split a long string into several
1312 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1313 to a subpattern of the above pattern.  Consider how the pattern
1314 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1315 seconds, but that each extra letter doubles this time.  This
1316 exponential performance will make it appear that your program has
1317 hung.  However, a tiny change to this pattern
1318
1319     m{ \(
1320           (
1321             (?> [^()]+ )        # change x+ above to (?> x+ )
1322           |
1323             \( [^()]* \)
1324           )+
1325        \)
1326      }x
1327
1328 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1329 this yourself would be a productive exercise), but finishes in a fourth
1330 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1331 however, that this pattern currently triggers a warning message under
1332 the C<use warnings> pragma or B<-w> switch saying it
1333 C<"matches null string many times in regex">.
1334
1335 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1336 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1337 This was only 4 times slower on a string with 1000000 C<a>s.
1338
1339 The "grab all you can, and do not give anything back" semantic is desirable
1340 in many situations where on the first sight a simple C<()*> looks like
1341 the correct solution.  Suppose we parse text with comments being delimited
1342 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1343 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1344 the comment delimiter, because it may "give up" some whitespace if
1345 the remainder of the pattern can be made to match that way.  The correct
1346 answer is either one of these:
1347
1348     (?>#[ \t]*)
1349     #[ \t]*(?![ \t])
1350
1351 For example, to grab non-empty comments into $1, one should use either
1352 one of these:
1353
1354     / (?> \# [ \t]* ) (        .+ ) /x;
1355     /     \# [ \t]*   ( [^ \t] .* ) /x;
1356
1357 Which one you pick depends on which of these expressions better reflects
1358 the above specification of comments.
1359
1360 In some literature this construct is called "atomic matching" or
1361 "possessive matching".
1362
1363 Possessive quantifiers are equivalent to putting the item they are applied
1364 to inside of one of these constructs. The following equivalences apply:
1365
1366     Quantifier Form     Bracketing Form
1367     ---------------     ---------------
1368     PAT*+               (?>PAT*)
1369     PAT++               (?>PAT+)
1370     PAT?+               (?>PAT?)
1371     PAT{min,max}+       (?>PAT{min,max})
1372
1373 =back
1374
1375 =head2 Special Backtracking Control Verbs
1376
1377 B<WARNING:> These patterns are experimental and subject to change or
1378 removal in a future version of Perl. Their usage in production code should
1379 be noted to avoid problems during upgrades.
1380
1381 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1382 otherwise stated the ARG argument is optional; in some cases, it is
1383 forbidden.
1384
1385 Any pattern containing a special backtracking verb that allows an argument
1386 has the special behaviour that when executed it sets the current package's
1387 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1388 rules apply:
1389
1390 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1391 verb pattern, if the verb was involved in the failure of the match. If the
1392 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1393 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1394 none. Also, the C<$REGMARK> variable will be set to FALSE.
1395
1396 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1397 the C<$REGMARK> variable will be set to the name of the last
1398 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1399 C<(*MARK:NAME)> verb below for more details.
1400
1401 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1402 and most other regex related variables. They are not local to a scope, nor
1403 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1404 Use C<local> to localize changes to them to a specific scope if necessary.
1405
1406 If a pattern does not contain a special backtracking verb that allows an
1407 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1408
1409 =over 4
1410
1411 =item Verbs that take an argument
1412
1413 =over 4
1414
1415 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1416 X<(*PRUNE)> X<(*PRUNE:NAME)>
1417
1418 This zero-width pattern prunes the backtracking tree at the current point
1419 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1420 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1421 A may backtrack as necessary to match. Once it is reached, matching
1422 continues in B, which may also backtrack as necessary; however, should B
1423 not match, then no further backtracking will take place, and the pattern
1424 will fail outright at the current starting position.
1425
1426 The following example counts all the possible matching strings in a
1427 pattern (without actually matching any of them).
1428
1429     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1430     print "Count=$count\n";
1431
1432 which produces:
1433
1434     aaab
1435     aaa
1436     aa
1437     a
1438     aab
1439     aa
1440     a
1441     ab
1442     a
1443     Count=9
1444
1445 If we add a C<(*PRUNE)> before the count like the following
1446
1447     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1448     print "Count=$count\n";
1449
1450 we prevent backtracking and find the count of the longest matching
1451 at each matching starting point like so:
1452
1453     aaab
1454     aab
1455     ab
1456     Count=3
1457
1458 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1459
1460 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1461 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1462 replaced with a C<< (?>pattern) >> with no functional difference; however,
1463 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1464 C<< (?>pattern) >> alone.
1465
1466
1467 =item C<(*SKIP)> C<(*SKIP:NAME)>
1468 X<(*SKIP)>
1469
1470 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1471 failure it also signifies that whatever text that was matched leading up
1472 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1473 of this pattern. This effectively means that the regex engine "skips" forward
1474 to this position on failure and tries to match again, (assuming that
1475 there is sufficient room to match).
1476
1477 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1478 C<(*MARK:NAME)> was encountered while matching, then it is that position
1479 which is used as the "skip point". If no C<(*MARK)> of that name was
1480 encountered, then the C<(*SKIP)> operator has no effect. When used
1481 without a name the "skip point" is where the match point was when
1482 executing the (*SKIP) pattern.
1483
1484 Compare the following to the examples in C<(*PRUNE)>, note the string
1485 is twice as long:
1486
1487     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1488     print "Count=$count\n";
1489
1490 outputs
1491
1492     aaab
1493     aaab
1494     Count=2
1495
1496 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1497 executed, the next starting point will be where the cursor was when the
1498 C<(*SKIP)> was executed.
1499
1500 =item C<(*MARK:NAME)> C<(*:NAME)>
1501 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1502
1503 This zero-width pattern can be used to mark the point reached in a string
1504 when a certain part of the pattern has been successfully matched. This
1505 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1506 forward to that point if backtracked into on failure. Any number of
1507 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1508
1509 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1510 can be used to "label" a pattern branch, so that after matching, the
1511 program can determine which branches of the pattern were involved in the
1512 match.
1513
1514 When a match is successful, the C<$REGMARK> variable will be set to the
1515 name of the most recently executed C<(*MARK:NAME)> that was involved
1516 in the match.
1517
1518 This can be used to determine which branch of a pattern was matched
1519 without using a separate capture group for each branch, which in turn
1520 can result in a performance improvement, as perl cannot optimize
1521 C</(?:(x)|(y)|(z))/> as efficiently as something like
1522 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1523
1524 When a match has failed, and unless another verb has been involved in
1525 failing the match and has provided its own name to use, the C<$REGERROR>
1526 variable will be set to the name of the most recently executed
1527 C<(*MARK:NAME)>.
1528
1529 See C<(*SKIP)> for more details.
1530
1531 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1532
1533 =item C<(*THEN)> C<(*THEN:NAME)>
1534
1535 This is similar to the "cut group" operator C<::> from Perl 6. Like
1536 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1537 failure, it causes the regex engine to try the next alternation in the
1538 innermost enclosing group (capturing or otherwise).
1539
1540 Its name comes from the observation that this operation combined with the
1541 alternation operator (C<|>) can be used to create what is essentially a
1542 pattern-based if/then/else block:
1543
1544   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1545
1546 Note that if this operator is used and NOT inside of an alternation then
1547 it acts exactly like the C<(*PRUNE)> operator.
1548
1549   / A (*PRUNE) B /
1550
1551 is the same as
1552
1553   / A (*THEN) B /
1554
1555 but
1556
1557   / ( A (*THEN) B | C (*THEN) D ) /
1558
1559 is not the same as
1560
1561   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1562
1563 as after matching the A but failing on the B the C<(*THEN)> verb will
1564 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1565
1566 =item C<(*COMMIT)>
1567 X<(*COMMIT)>
1568
1569 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1570 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1571 into on failure it causes the match to fail outright. No further attempts
1572 to find a valid match by advancing the start pointer will occur again.
1573 For example,
1574
1575     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1576     print "Count=$count\n";
1577
1578 outputs
1579
1580     aaab
1581     Count=1
1582
1583 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1584 does not match, the regex engine will not try any further matching on the
1585 rest of the string.
1586
1587 =back
1588
1589 =item Verbs without an argument
1590
1591 =over 4
1592
1593 =item C<(*FAIL)> C<(*F)>
1594 X<(*FAIL)> X<(*F)>
1595
1596 This pattern matches nothing and always fails. It can be used to force the
1597 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1598 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1599
1600 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1601
1602 =item C<(*ACCEPT)>
1603 X<(*ACCEPT)>
1604
1605 B<WARNING:> This feature is highly experimental. It is not recommended
1606 for production code.
1607
1608 This pattern matches nothing and causes the end of successful matching at
1609 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1610 whether there is actually more to match in the string. When inside of a
1611 nested pattern, such as recursion, or in a subpattern dynamically generated
1612 via C<(??{})>, only the innermost pattern is ended immediately.
1613
1614 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1615 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1616 For instance:
1617
1618   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1619
1620 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1621 be set. If another branch in the inner parentheses were matched, such as in the
1622 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1623
1624 =back
1625
1626 =back
1627
1628 =head2 Backtracking
1629 X<backtrack> X<backtracking>
1630
1631 NOTE: This section presents an abstract approximation of regular
1632 expression behavior.  For a more rigorous (and complicated) view of
1633 the rules involved in selecting a match among possible alternatives,
1634 see L<Combining RE Pieces>.
1635
1636 A fundamental feature of regular expression matching involves the
1637 notion called I<backtracking>, which is currently used (when needed)
1638 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1639 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1640 internally, but the general principle outlined here is valid.
1641
1642 For a regular expression to match, the I<entire> regular expression must
1643 match, not just part of it.  So if the beginning of a pattern containing a
1644 quantifier succeeds in a way that causes later parts in the pattern to
1645 fail, the matching engine backs up and recalculates the beginning
1646 part--that's why it's called backtracking.
1647
1648 Here is an example of backtracking:  Let's say you want to find the
1649 word following "foo" in the string "Food is on the foo table.":
1650
1651     $_ = "Food is on the foo table.";
1652     if ( /\b(foo)\s+(\w+)/i ) {
1653         print "$2 follows $1.\n";
1654     }
1655
1656 When the match runs, the first part of the regular expression (C<\b(foo)>)
1657 finds a possible match right at the beginning of the string, and loads up
1658 $1 with "Foo".  However, as soon as the matching engine sees that there's
1659 no whitespace following the "Foo" that it had saved in $1, it realizes its
1660 mistake and starts over again one character after where it had the
1661 tentative match.  This time it goes all the way until the next occurrence
1662 of "foo". The complete regular expression matches this time, and you get
1663 the expected output of "table follows foo."
1664
1665 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1666 everything between "foo" and "bar".  Initially, you write something
1667 like this:
1668
1669     $_ =  "The food is under the bar in the barn.";
1670     if ( /foo(.*)bar/ ) {
1671         print "got <$1>\n";
1672     }
1673
1674 Which perhaps unexpectedly yields:
1675
1676   got <d is under the bar in the >
1677
1678 That's because C<.*> was greedy, so you get everything between the
1679 I<first> "foo" and the I<last> "bar".  Here it's more effective
1680 to use minimal matching to make sure you get the text between a "foo"
1681 and the first "bar" thereafter.
1682
1683     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1684   got <d is under the >
1685
1686 Here's another example. Let's say you'd like to match a number at the end
1687 of a string, and you also want to keep the preceding part of the match.
1688 So you write this:
1689
1690     $_ = "I have 2 numbers: 53147";
1691     if ( /(.*)(\d*)/ ) {                                # Wrong!
1692         print "Beginning is <$1>, number is <$2>.\n";
1693     }
1694
1695 That won't work at all, because C<.*> was greedy and gobbled up the
1696 whole string. As C<\d*> can match on an empty string the complete
1697 regular expression matched successfully.
1698
1699     Beginning is <I have 2 numbers: 53147>, number is <>.
1700
1701 Here are some variants, most of which don't work:
1702
1703     $_ = "I have 2 numbers: 53147";
1704     @pats = qw{
1705         (.*)(\d*)
1706         (.*)(\d+)
1707         (.*?)(\d*)
1708         (.*?)(\d+)
1709         (.*)(\d+)$
1710         (.*?)(\d+)$
1711         (.*)\b(\d+)$
1712         (.*\D)(\d+)$
1713     };
1714
1715     for $pat (@pats) {
1716         printf "%-12s ", $pat;
1717         if ( /$pat/ ) {
1718             print "<$1> <$2>\n";
1719         } else {
1720             print "FAIL\n";
1721         }
1722     }
1723
1724 That will print out:
1725
1726     (.*)(\d*)    <I have 2 numbers: 53147> <>
1727     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1728     (.*?)(\d*)   <> <>
1729     (.*?)(\d+)   <I have > <2>
1730     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1731     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1732     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1733     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1734
1735 As you see, this can be a bit tricky.  It's important to realize that a
1736 regular expression is merely a set of assertions that gives a definition
1737 of success.  There may be 0, 1, or several different ways that the
1738 definition might succeed against a particular string.  And if there are
1739 multiple ways it might succeed, you need to understand backtracking to
1740 know which variety of success you will achieve.
1741
1742 When using look-ahead assertions and negations, this can all get even
1743 trickier.  Imagine you'd like to find a sequence of non-digits not
1744 followed by "123".  You might try to write that as
1745
1746     $_ = "ABC123";
1747     if ( /^\D*(?!123)/ ) {                # Wrong!
1748         print "Yup, no 123 in $_\n";
1749     }
1750
1751 But that isn't going to match; at least, not the way you're hoping.  It
1752 claims that there is no 123 in the string.  Here's a clearer picture of
1753 why that pattern matches, contrary to popular expectations:
1754
1755     $x = 'ABC123';
1756     $y = 'ABC445';
1757
1758     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1759     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1760
1761     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1762     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1763
1764 This prints
1765
1766     2: got ABC
1767     3: got AB
1768     4: got ABC
1769
1770 You might have expected test 3 to fail because it seems to a more
1771 general purpose version of test 1.  The important difference between
1772 them is that test 3 contains a quantifier (C<\D*>) and so can use
1773 backtracking, whereas test 1 will not.  What's happening is
1774 that you've asked "Is it true that at the start of $x, following 0 or more
1775 non-digits, you have something that's not 123?"  If the pattern matcher had
1776 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1777 fail.
1778
1779 The search engine will initially match C<\D*> with "ABC".  Then it will
1780 try to match C<(?!123> with "123", which fails.  But because
1781 a quantifier (C<\D*>) has been used in the regular expression, the
1782 search engine can backtrack and retry the match differently
1783 in the hope of matching the complete regular expression.
1784
1785 The pattern really, I<really> wants to succeed, so it uses the
1786 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1787 time.  Now there's indeed something following "AB" that is not
1788 "123".  It's "C123", which suffices.
1789
1790 We can deal with this by using both an assertion and a negation.
1791 We'll say that the first part in $1 must be followed both by a digit
1792 and by something that's not "123".  Remember that the look-aheads
1793 are zero-width expressions--they only look, but don't consume any
1794 of the string in their match.  So rewriting this way produces what
1795 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1796
1797     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1798     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1799
1800     6: got ABC
1801
1802 In other words, the two zero-width assertions next to each other work as though
1803 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1804 matches only if you're at the beginning of the line AND the end of the
1805 line simultaneously.  The deeper underlying truth is that juxtaposition in
1806 regular expressions always means AND, except when you write an explicit OR
1807 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1808 although the attempted matches are made at different positions because "a"
1809 is not a zero-width assertion, but a one-width assertion.
1810
1811 B<WARNING>: Particularly complicated regular expressions can take
1812 exponential time to solve because of the immense number of possible
1813 ways they can use backtracking to try for a match.  For example, without
1814 internal optimizations done by the regular expression engine, this will
1815 take a painfully long time to run:
1816
1817     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1818
1819 And if you used C<*>'s in the internal groups instead of limiting them
1820 to 0 through 5 matches, then it would take forever--or until you ran
1821 out of stack space.  Moreover, these internal optimizations are not
1822 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1823 on the external group, no current optimization is applicable, and the
1824 match takes a long time to finish.
1825
1826 A powerful tool for optimizing such beasts is what is known as an
1827 "independent group",
1828 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1829 zero-length look-ahead/look-behind assertions will not backtrack to make
1830 the tail match, since they are in "logical" context: only
1831 whether they match is considered relevant.  For an example
1832 where side-effects of look-ahead I<might> have influenced the
1833 following match, see L<C<< (?>pattern) >>>.
1834
1835 =head2 Version 8 Regular Expressions
1836 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1837
1838 In case you're not familiar with the "regular" Version 8 regex
1839 routines, here are the pattern-matching rules not described above.
1840
1841 Any single character matches itself, unless it is a I<metacharacter>
1842 with a special meaning described here or above.  You can cause
1843 characters that normally function as metacharacters to be interpreted
1844 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1845 character; "\\" matches a "\"). This escape mechanism is also required
1846 for the character used as the pattern delimiter.
1847
1848 A series of characters matches that series of characters in the target
1849 string, so the pattern  C<blurfl> would match "blurfl" in the target
1850 string.
1851
1852 You can specify a character class, by enclosing a list of characters
1853 in C<[]>, which will match any character from the list.  If the
1854 first character after the "[" is "^", the class matches any character not
1855 in the list.  Within a list, the "-" character specifies a
1856 range, so that C<a-z> represents all characters between "a" and "z",
1857 inclusive.  If you want either "-" or "]" itself to be a member of a
1858 class, put it at the start of the list (possibly after a "^"), or
1859 escape it with a backslash.  "-" is also taken literally when it is
1860 at the end of the list, just before the closing "]".  (The
1861 following all specify the same class of three characters: C<[-az]>,
1862 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1863 specifies a class containing twenty-six characters, even on EBCDIC-based
1864 character sets.)  Also, if you try to use the character
1865 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1866 a range, the "-" is understood literally.
1867
1868 Note also that the whole range idea is rather unportable between
1869 character sets--and even within character sets they may cause results
1870 you probably didn't expect.  A sound principle is to use only ranges
1871 that begin from and end at either alphabetics of equal case ([a-e],
1872 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1873 spell out the character sets in full.
1874
1875 Characters may be specified using a metacharacter syntax much like that
1876 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1877 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1878 of three octal digits, matches the character whose coded character set value
1879 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1880 matches the character whose ordinal is I<nn>. The expression \cI<x>
1881 matches the character control-I<x>.  Finally, the "." metacharacter
1882 matches any character except "\n" (unless you use C</s>).
1883
1884 You can specify a series of alternatives for a pattern using "|" to
1885 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1886 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1887 first alternative includes everything from the last pattern delimiter
1888 ("(", "[", or the beginning of the pattern) up to the first "|", and
1889 the last alternative contains everything from the last "|" to the next
1890 pattern delimiter.  That's why it's common practice to include
1891 alternatives in parentheses: to minimize confusion about where they
1892 start and end.
1893
1894 Alternatives are tried from left to right, so the first
1895 alternative found for which the entire expression matches, is the one that
1896 is chosen. This means that alternatives are not necessarily greedy. For
1897 example: when matching C<foo|foot> against "barefoot", only the "foo"
1898 part will match, as that is the first alternative tried, and it successfully
1899 matches the target string. (This might not seem important, but it is
1900 important when you are capturing matched text using parentheses.)
1901
1902 Also remember that "|" is interpreted as a literal within square brackets,
1903 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1904
1905 Within a pattern, you may designate subpatterns for later reference
1906 by enclosing them in parentheses, and you may refer back to the
1907 I<n>th subpattern later in the pattern using the metacharacter
1908 \I<n>.  Subpatterns are numbered based on the left to right order
1909 of their opening parenthesis.  A backreference matches whatever
1910 actually matched the subpattern in the string being examined, not
1911 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
1912 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1913 1 matched "0x", even though the rule C<0|0x> could potentially match
1914 the leading 0 in the second number.
1915
1916 =head2 Warning on \1 Instead of $1
1917
1918 Some people get too used to writing things like:
1919
1920     $pattern =~ s/(\W)/\\\1/g;
1921
1922 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
1923 shocking the
1924 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1925 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1926 the usual double-quoted string means a control-A.  The customary Unix
1927 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1928 of doing that, you get yourself into trouble if you then add an C</e>
1929 modifier.
1930
1931     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
1932
1933 Or if you try to do
1934
1935     s/(\d+)/\1000/;
1936
1937 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1938 C<${1}000>.  The operation of interpolation should not be confused
1939 with the operation of matching a backreference.  Certainly they mean two
1940 different things on the I<left> side of the C<s///>.
1941
1942 =head2 Repeated Patterns Matching a Zero-length Substring
1943
1944 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1945
1946 Regular expressions provide a terse and powerful programming language.  As
1947 with most other power tools, power comes together with the ability
1948 to wreak havoc.
1949
1950 A common abuse of this power stems from the ability to make infinite
1951 loops using regular expressions, with something as innocuous as:
1952
1953     'foo' =~ m{ ( o? )* }x;
1954
1955 The C<o?> matches at the beginning of C<'foo'>, and since the position
1956 in the string is not moved by the match, C<o?> would match again and again
1957 because of the C<*> quantifier.  Another common way to create a similar cycle
1958 is with the looping modifier C<//g>:
1959
1960     @matches = ( 'foo' =~ m{ o? }xg );
1961
1962 or
1963
1964     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1965
1966 or the loop implied by split().
1967
1968 However, long experience has shown that many programming tasks may
1969 be significantly simplified by using repeated subexpressions that
1970 may match zero-length substrings.  Here's a simple example being:
1971
1972     @chars = split //, $string;                  # // is not magic in split
1973     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1974
1975 Thus Perl allows such constructs, by I<forcefully breaking
1976 the infinite loop>.  The rules for this are different for lower-level
1977 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1978 ones like the C</g> modifier or split() operator.
1979
1980 The lower-level loops are I<interrupted> (that is, the loop is
1981 broken) when Perl detects that a repeated expression matched a
1982 zero-length substring.   Thus
1983
1984    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1985
1986 is made equivalent to
1987
1988    m{   (?: NON_ZERO_LENGTH )*
1989       |
1990         (?: ZERO_LENGTH )?
1991     }x;
1992
1993 The higher level-loops preserve an additional state between iterations:
1994 whether the last match was zero-length.  To break the loop, the following
1995 match after a zero-length match is prohibited to have a length of zero.
1996 This prohibition interacts with backtracking (see L<"Backtracking">),
1997 and so the I<second best> match is chosen if the I<best> match is of
1998 zero length.
1999
2000 For example:
2001
2002     $_ = 'bar';
2003     s/\w??/<$&>/g;
2004
2005 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2006 match given by non-greedy C<??> is the zero-length match, and the I<second
2007 best> match is what is matched by C<\w>.  Thus zero-length matches
2008 alternate with one-character-long matches.
2009
2010 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2011 position one notch further in the string.
2012
2013 The additional state of being I<matched with zero-length> is associated with
2014 the matched string, and is reset by each assignment to pos().
2015 Zero-length matches at the end of the previous match are ignored
2016 during C<split>.
2017
2018 =head2 Combining RE Pieces
2019
2020 Each of the elementary pieces of regular expressions which were described
2021 before (such as C<ab> or C<\Z>) could match at most one substring
2022 at the given position of the input string.  However, in a typical regular
2023 expression these elementary pieces are combined into more complicated
2024 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
2025 (in these examples C<S> and C<T> are regular subexpressions).
2026
2027 Such combinations can include alternatives, leading to a problem of choice:
2028 if we match a regular expression C<a|ab> against C<"abc">, will it match
2029 substring C<"a"> or C<"ab">?  One way to describe which substring is
2030 actually matched is the concept of backtracking (see L<"Backtracking">).
2031 However, this description is too low-level and makes you think
2032 in terms of a particular implementation.
2033
2034 Another description starts with notions of "better"/"worse".  All the
2035 substrings which may be matched by the given regular expression can be
2036 sorted from the "best" match to the "worst" match, and it is the "best"
2037 match which is chosen.  This substitutes the question of "what is chosen?"
2038 by the question of "which matches are better, and which are worse?".
2039
2040 Again, for elementary pieces there is no such question, since at most
2041 one match at a given position is possible.  This section describes the
2042 notion of better/worse for combining operators.  In the description
2043 below C<S> and C<T> are regular subexpressions.
2044
2045 =over 4
2046
2047 =item C<ST>
2048
2049 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2050 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2051 which can be matched by C<T>.
2052
2053 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2054 match than C<A'B'>.
2055
2056 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2057 C<B> is better match for C<T> than C<B'>.
2058
2059 =item C<S|T>
2060
2061 When C<S> can match, it is a better match than when only C<T> can match.
2062
2063 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2064 two matches for C<T>.
2065
2066 =item C<S{REPEAT_COUNT}>
2067
2068 Matches as C<SSS...S> (repeated as many times as necessary).
2069
2070 =item C<S{min,max}>
2071
2072 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2073
2074 =item C<S{min,max}?>
2075
2076 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2077
2078 =item C<S?>, C<S*>, C<S+>
2079
2080 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2081
2082 =item C<S??>, C<S*?>, C<S+?>
2083
2084 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2085
2086 =item C<< (?>S) >>
2087
2088 Matches the best match for C<S> and only that.
2089
2090 =item C<(?=S)>, C<(?<=S)>
2091
2092 Only the best match for C<S> is considered.  (This is important only if
2093 C<S> has capturing parentheses, and backreferences are used somewhere
2094 else in the whole regular expression.)
2095
2096 =item C<(?!S)>, C<(?<!S)>
2097
2098 For this grouping operator there is no need to describe the ordering, since
2099 only whether or not C<S> can match is important.
2100
2101 =item C<(??{ EXPR })>, C<(?PARNO)>
2102
2103 The ordering is the same as for the regular expression which is
2104 the result of EXPR, or the pattern contained by capture group PARNO.
2105
2106 =item C<(?(condition)yes-pattern|no-pattern)>
2107
2108 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2109 already determined.  The ordering of the matches is the same as for the
2110 chosen subexpression.
2111
2112 =back
2113
2114 The above recipes describe the ordering of matches I<at a given position>.
2115 One more rule is needed to understand how a match is determined for the
2116 whole regular expression: a match at an earlier position is always better
2117 than a match at a later position.
2118
2119 =head2 Creating Custom RE Engines
2120
2121 Overloaded constants (see L<overload>) provide a simple way to extend
2122 the functionality of the RE engine.
2123
2124 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2125 matches at a boundary between whitespace characters and non-whitespace
2126 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2127 at these positions, so we want to have each C<\Y|> in the place of the
2128 more complicated version.  We can create a module C<customre> to do
2129 this:
2130
2131     package customre;
2132     use overload;
2133
2134     sub import {
2135       shift;
2136       die "No argument to customre::import allowed" if @_;
2137       overload::constant 'qr' => \&convert;
2138     }
2139
2140     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2141
2142     # We must also take care of not escaping the legitimate \\Y|
2143     # sequence, hence the presence of '\\' in the conversion rules.
2144     my %rules = ( '\\' => '\\\\',
2145                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2146     sub convert {
2147       my $re = shift;
2148       $re =~ s{
2149                 \\ ( \\ | Y . )
2150               }
2151               { $rules{$1} or invalid($re,$1) }sgex;
2152       return $re;
2153     }
2154
2155 Now C<use customre> enables the new escape in constant regular
2156 expressions, i.e., those without any runtime variable interpolations.
2157 As documented in L<overload>, this conversion will work only over
2158 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2159 part of this regular expression needs to be converted explicitly
2160 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2161
2162     use customre;
2163     $re = <>;
2164     chomp $re;
2165     $re = customre::convert $re;
2166     /\Y|$re\Y|/;
2167
2168 =head1 PCRE/Python Support
2169
2170 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2171 to the regex syntax. While Perl programmers are encouraged to use the
2172 Perl specific syntax, the following are also accepted:
2173
2174 =over 4
2175
2176 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2177
2178 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2179
2180 =item C<< (?P=NAME) >>
2181
2182 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2183
2184 =item C<< (?P>NAME) >>
2185
2186 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2187
2188 =back
2189
2190 =head1 BUGS
2191
2192 There are numerous problems with case insensitive matching of characters
2193 outside the ASCII range, especially with those whose folds are multiple
2194 characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2195
2196 In a bracketed character class with case insensitive matching, ranges only work
2197 for ASCII characters.  For example,
2198 C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2199 doesn't match all the Russian upper and lower case letters.
2200
2201 Many regular expression constructs don't work on EBCDIC platforms.
2202
2203 This document varies from difficult to understand to completely
2204 and utterly opaque.  The wandering prose riddled with jargon is
2205 hard to fathom in several places.
2206
2207 This document needs a rewrite that separates the tutorial content
2208 from the reference content.
2209
2210 =head1 SEE ALSO
2211
2212 L<perlrequick>.
2213
2214 L<perlretut>.
2215
2216 L<perlop/"Regexp Quote-Like Operators">.
2217
2218 L<perlop/"Gory details of parsing quoted constructs">.
2219
2220 L<perlfaq6>.
2221
2222 L<perlfunc/pos>.
2223
2224 L<perllocale>.
2225
2226 L<perlebcdic>.
2227
2228 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2229 by O'Reilly and Associates.