This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
dc79a138492a83fc14749a0c78e3c19a8cdd1b5f
[perl5.git] / pod / perlunicode.pod
1 =head1 NAME
2
3 perlunicode - Unicode support in Perl
4
5 =head1 DESCRIPTION
6
7 If you haven't already, before reading this document, you should become
8 familiar with both L<perlunitut> and L<perluniintro>.
9
10 Unicode aims to B<UNI>-fy the en-B<CODE>-ings of all the world's
11 character sets into a single Standard.   For quite a few of the various
12 coding standards that existed when Unicode was first created, converting
13 from each to Unicode essentially meant adding a constant to each code
14 point in the original standard, and converting back meant just
15 subtracting that same constant.  For ASCII and ISO-8859-1, the constant
16 is 0.  For ISO-8859-5, (Cyrillic) the constant is 864; for Hebrew
17 (ISO-8859-8), it's 1488; Thai (ISO-8859-11), 3424; and so forth.  This
18 made it easy to do the conversions, and facilitated the adoption of
19 Unicode.
20
21 And it worked; nowadays, those legacy standards are rarely used.  Most
22 everyone uses Unicode.
23
24 Unicode is a comprehensive standard.  It specifies many things outside
25 the scope of Perl, such as how to display sequences of characters.  For
26 a full discussion of all aspects of Unicode, see
27 L<http://www.unicode.org>.
28
29 =head2 Important Caveats
30
31 Even though some of this section may not be understandable to you on
32 first reading, we think it's important enough to highlight some of the
33 gotchas before delving further, so here goes:
34
35 Unicode support is an extensive requirement. While Perl does not
36 implement the Unicode standard or the accompanying technical reports
37 from cover to cover, Perl does support many Unicode features.
38
39 Also, the use of Unicode may present security issues that aren't obvious.
40 Read L<Unicode Security Considerations|http://www.unicode.org/reports/tr36>.
41
42 =over 4
43
44 =item Safest if you C<use feature 'unicode_strings'>
45
46 In order to preserve backward compatibility, Perl does not turn
47 on full internal Unicode support unless the pragma
48 L<S<C<use feature 'unicode_strings'>>|feature/The 'unicode_strings' feature>
49 is specified.  (This is automatically
50 selected if you S<C<use 5.012>> or higher.)  Failure to do this can
51 trigger unexpected surprises.  See L</The "Unicode Bug"> below.
52
53 This pragma doesn't affect I/O.  Nor does it change the internal
54 representation of strings, only their interpretation.  There are still
55 several places where Unicode isn't fully supported, such as in
56 filenames.
57
58 =item Input and Output Layers
59
60 Use the C<:encoding(...)> layer  to read from and write to
61 filehandles using the specified encoding.  (See L<open>.)
62
63 =item You should convert your non-ASCII, non-UTF-8 Perl scripts to be
64 UTF-8.
65
66 See L<encoding>.
67
68 =item C<use utf8> still needed to enable L<UTF-8|/Unicode Encodings> in scripts
69
70 If your Perl script is itself encoded in L<UTF-8|/Unicode Encodings>,
71 the S<C<use utf8>> pragma must be explicitly included to enable
72 recognition of that (in string or regular expression literals, or in
73 identifier names).  B<This is the only time when an explicit S<C<use
74 utf8>> is needed.>  (See L<utf8>).
75
76 If a Perl script begins with the bytes that form the UTF-8 encoding of
77 the Unicode BYTE ORDER MARK (C<BOM>, see L</Unicode Encodings>), those
78 bytes are completely ignored.
79
80 =item L<UTF-16|/Unicode Encodings> scripts autodetected
81
82 If a Perl script begins with the Unicode C<BOM> (UTF-16LE,
83 UTF16-BE), or if the script looks like non-C<BOM>-marked
84 UTF-16 of either endianness, Perl will correctly read in the script as
85 the appropriate Unicode encoding.
86
87 =back
88
89 =head2 Byte and Character Semantics
90
91 Before Unicode, most encodings used 8 bits (a single byte) to encode
92 each character.  Thus a character was a byte, and a byte was a
93 character, and there could be only 256 or fewer possible characters.
94 "Byte Semantics" in the title of this section refers to
95 this behavior.  There was no need to distinguish between "Byte" and
96 "Character".
97
98 Then along comes Unicode which has room for over a million characters
99 (and Perl allows for even more).  This means that a character may
100 require more than a single byte to represent it, and so the two terms
101 are no longer equivalent.  What matter are the characters as whole
102 entities, and not usually the bytes that comprise them.  That's what the
103 term "Character Semantics" in the title of this section refers to.
104
105 Perl had to change internally to decouple "bytes" from "characters".
106 It is important that you too change your ideas, if you haven't already,
107 so that "byte" and "character" no longer mean the same thing in your
108 mind.
109
110 The basic building block of Perl strings has always been a "character".
111 The changes basically come down to that the implementation no longer
112 thinks that a character is always just a single byte.
113
114 There are various things to note:
115
116 =over 4
117
118 =item *
119
120 String handling functions, for the most part, continue to operate in
121 terms of characters.  C<length()>, for example, returns the number of
122 characters in a string, just as before.  But that number no longer is
123 necessarily the same as the number of bytes in the string (there may be
124 more bytes than characters).  The other such functions include
125 C<chop()>, C<chomp()>, C<substr()>, C<pos()>, C<index()>, C<rindex()>,
126 C<sort()>, C<sprintf()>, and C<write()>.
127
128 The exceptions are:
129
130 =over 4
131
132 =item *
133
134 the bit-oriented C<vec>
135
136 E<nbsp>
137
138 =item *
139
140 the byte-oriented C<pack>/C<unpack> C<"C"> format
141
142 However, the C<W> specifier does operate on whole characters, as does the
143 C<U> specifier.
144
145 =item *
146
147 some operators that interact with the platform's operating system
148
149 Operators dealing with filenames are examples.
150
151 =item *
152
153 when the functions are called from within the scope of the
154 S<C<L<use bytes|bytes>>> pragma
155
156 Likely, you should use this only for debugging anyway.
157
158 =back
159
160 =item *
161
162 Strings--including hash keys--and regular expression patterns may
163 contain characters that have ordinal values larger than 255.
164
165 If you use a Unicode editor to edit your program, Unicode characters may
166 occur directly within the literal strings in UTF-8 encoding, or UTF-16.
167 (The former requires a C<use utf8>, the latter may require a C<BOM>.)
168
169 L<perluniintro/Creating Unicode> gives other ways to place non-ASCII
170 characters in your strings.
171
172 =item *
173
174 The C<chr()> and C<ord()> functions work on whole characters.
175
176 =item *
177
178 Regular expressions match whole characters.  For example, C<"."> matches
179 a whole character instead of only a single byte.
180
181 =item *
182
183 The C<tr///> operator translates whole characters.  (Note that the
184 C<tr///CU> functionality has been removed.  For similar functionality to
185 that, see C<pack('U0', ...)> and C<pack('C0', ...)>).
186
187 =item *
188
189 C<scalar reverse()> reverses by character rather than by byte.
190
191 =item *
192
193 The bit string operators, C<& | ^ ~> and (starting in v5.22)
194 C<&. |. ^.  ~.> can operate on characters that don't fit into a byte.
195 However, the current behavior is likely to change.  You should not use
196 these operators on strings that are encoded in UTF-8.  If you're not
197 sure about the encoding of a string, downgrade it before using any of
198 these operators; you can use
199 L<C<utf8::utf8_downgrade()>|utf8/Utility functions>.
200
201 =back
202
203 The bottom line is that Perl has always practiced "Character Semantics",
204 but with the advent of Unicode, that is now different than "Byte
205 Semantics".
206
207 =head2 ASCII Rules versus Unicode Rules
208
209 Before Unicode, when a character was a byte was a character,
210 Perl knew only about the 128 characters defined by ASCII, code points 0
211 through 127 (except for under S<C<use locale>>).  That left the code
212 points 128 to 255 as unassigned, and available for whatever use a
213 program might want.  The only semantics they have is their ordinal
214 numbers, and that they are members of none of the non-negative character
215 classes.  None are considered to match C<\w> for example, but all match
216 C<\W>.
217
218 Unicode, of course, assigns each of those code points a particular
219 meaning (along with ones above 255).  To preserve backward
220 compatibility, Perl only uses the Unicode meanings when there is some
221 indication that Unicode is what is intended; otherwise the non-ASCII
222 code points remain treated as if they are unassigned.
223
224 Here are the ways that Perl knows that a string should be treated as
225 Unicode:
226
227 =over
228
229 =item *
230
231 Within the scope of S<C<use utf8>>
232
233 If the whole program is Unicode (signified by using 8-bit B<U>nicode
234 B<T>ransformation B<F>ormat), then all strings within it must be
235 Unicode.
236
237 =item *
238
239 Within the scope of
240 L<S<C<use feature 'unicode_strings'>>|feature/The 'unicode_strings' feature>
241
242 This pragma was created so you can explicitly tell Perl that operations
243 executed within its scope are to use Unicode rules.  More operations are
244 affected with newer perls.  See L</The "Unicode Bug">.
245
246 =item *
247
248 Within the scope of S<C<use 5.012>> or higher
249
250 This implicitly turns on S<C<use feature 'unicode_strings'>>.
251
252 =item *
253
254 Within the scope of
255 L<S<C<use locale 'not_characters'>>|perllocale/Unicode and UTF-8>,
256 or L<S<C<use locale>>|perllocale> and the current
257 locale is a UTF-8 locale.
258
259 The former is defined to imply Unicode handling; and the latter
260 indicates a Unicode locale, hence a Unicode interpretation of all
261 strings within it.
262
263 =item *
264
265 When the string contains a Unicode-only code point
266
267 Perl has never accepted code points above 255 without them being
268 Unicode, so their use implies Unicode for the whole string.
269
270 =item *
271
272 When the string contains a Unicode named code point C<\N{...}>
273
274 The C<\N{...}> construct explicitly refers to a Unicode code point,
275 even if it is one that is also in ASCII.  Therefore the string
276 containing it must be Unicode.
277
278 =item *
279
280 When the string has come from an external source marked as
281 Unicode
282
283 The L<C<-C>|perlrun/-C [numberE<sol>list]> command line option can
284 specify that certain inputs to the program are Unicode, and the values
285 of this can be read by your Perl code, see L<perlvar/"${^UNICODE}">.
286
287 =item * When the string has been upgraded to UTF-8
288
289 The function L<C<utf8::utf8_upgrade()>|utf8/Utility functions>
290 can be explicitly used to permanently (unless a subsequent
291 C<utf8::utf8_downgrade()> is called) cause a string to be treated as
292 Unicode.
293
294 =item * There are additional methods for regular expression patterns
295
296 A pattern that is compiled with the C<< /u >> or C<< /a >> modifiers is
297 treated as Unicode (though there are some restrictions with C<< /a >>).
298 Under the C<< /d >> and C<< /l >> modifiers, there are several other
299 indications for Unicode; see L<perlre/Character set modifiers>.
300
301 =back
302
303 Note that all of the above are overridden within the scope of
304 C<L<use bytes|bytes>>; but you should be using this pragma only for
305 debugging.
306
307 Note also that some interactions with the platform's operating system
308 never use Unicode rules.
309
310 When Unicode rules are in effect:
311
312 =over 4
313
314 =item *
315
316 Case translation operators use the Unicode case translation tables.
317
318 Note that C<uc()>, or C<\U> in interpolated strings, translates to
319 uppercase, while C<ucfirst>, or C<\u> in interpolated strings,
320 translates to titlecase in languages that make the distinction (which is
321 equivalent to uppercase in languages without the distinction).
322
323 There is a CPAN module, C<L<Unicode::Casing>>, which allows you to
324 define your own mappings to be used in C<lc()>, C<lcfirst()>, C<uc()>,
325 C<ucfirst()>, and C<fc> (or their double-quoted string inlined versions
326 such as C<\U>).  (Prior to Perl 5.16, this functionality was partially
327 provided in the Perl core, but suffered from a number of insurmountable
328 drawbacks, so the CPAN module was written instead.)
329
330 =item *
331
332 Character classes in regular expressions match based on the character
333 properties specified in the Unicode properties database.
334
335 C<\w> can be used to match a Japanese ideograph, for instance; and
336 C<[[:digit:]]> a Bengali number.
337
338 =item *
339
340 Named Unicode properties, scripts, and block ranges may be used (like
341 bracketed character classes) by using the C<\p{}> "matches property"
342 construct and the C<\P{}> negation, "doesn't match property".
343
344 See L</"Unicode Character Properties"> for more details.
345
346 You can define your own character properties and use them
347 in the regular expression with the C<\p{}> or C<\P{}> construct.
348 See L</"User-Defined Character Properties"> for more details.
349
350 =back
351
352 =head2 Extended Grapheme Clusters (Logical characters)
353
354 Consider a character, say C<H>.  It could appear with various marks around it,
355 such as an acute accent, or a circumflex, or various hooks, circles, arrows,
356 I<etc.>, above, below, to one side or the other, I<etc>.  There are many
357 possibilities among the world's languages.  The number of combinations is
358 astronomical, and if there were a character for each combination, it would
359 soon exhaust Unicode's more than a million possible characters.  So Unicode
360 took a different approach: there is a character for the base C<H>, and a
361 character for each of the possible marks, and these can be variously combined
362 to get a final logical character.  So a logical character--what appears to be a
363 single character--can be a sequence of more than one individual characters.
364 The Unicode standard calls these "extended grapheme clusters" (which
365 is an improved version of the no-longer much used "grapheme cluster");
366 Perl furnishes the C<\X> regular expression construct to match such
367 sequences in their entirety.
368
369 But Unicode's intent is to unify the existing character set standards and
370 practices, and several pre-existing standards have single characters that
371 mean the same thing as some of these combinations, like ISO-8859-1,
372 which has quite a few of them. For example, C<"LATIN CAPITAL LETTER E
373 WITH ACUTE"> was already in this standard when Unicode came along.
374 Unicode therefore added it to its repertoire as that single character.
375 But this character is considered by Unicode to be equivalent to the
376 sequence consisting of the character C<"LATIN CAPITAL LETTER E">
377 followed by the character C<"COMBINING ACUTE ACCENT">.
378
379 C<"LATIN CAPITAL LETTER E WITH ACUTE"> is called a "pre-composed"
380 character, and its equivalence with the "E" and the "COMBINING ACCENT"
381 sequence is called canonical equivalence.  All pre-composed characters
382 are said to have a decomposition (into the equivalent sequence), and the
383 decomposition type is also called canonical.  A string may be comprised
384 as much as possible of precomposed characters, or it may be comprised of
385 entirely decomposed characters.  Unicode calls these respectively,
386 "Normalization Form Composed" (NFC) and "Normalization Form Decomposed".
387 The C<L<Unicode::Normalize>> module contains functions that convert
388 between the two.  A string may also have both composed characters and
389 decomposed characters; this module can be used to make it all one or the
390 other.
391
392 You may be presented with strings in any of these equivalent forms.
393 There is currently nothing in Perl 5 that ignores the differences.  So
394 you'll have to specially hanlde it.  The usual advice is to convert your
395 inputs to C<NFD> before processing further.
396
397 For more detailed information, see L<http://unicode.org/reports/tr15/>.
398
399 =head2 Unicode Character Properties
400
401 (The only time that Perl considers a sequence of individual code
402 points as a single logical character is in the C<\X> construct, already
403 mentioned above.   Therefore "character" in this discussion means a single
404 Unicode code point.)
405
406 Very nearly all Unicode character properties are accessible through
407 regular expressions by using the C<\p{}> "matches property" construct
408 and the C<\P{}> "doesn't match property" for its negation.
409
410 For instance, C<\p{Uppercase}> matches any single character with the Unicode
411 C<"Uppercase"> property, while C<\p{L}> matches any character with a
412 C<General_Category> of C<"L"> (letter) property (see
413 L</General_Category> below).  Brackets are not
414 required for single letter property names, so C<\p{L}> is equivalent to C<\pL>.
415
416 More formally, C<\p{Uppercase}> matches any single character whose Unicode
417 C<Uppercase> property value is C<True>, and C<\P{Uppercase}> matches any character
418 whose C<Uppercase> property value is C<False>, and they could have been written as
419 C<\p{Uppercase=True}> and C<\p{Uppercase=False}>, respectively.
420
421 This formality is needed when properties are not binary; that is, if they can
422 take on more values than just C<True> and C<False>.  For example, the
423 C<Bidi_Class> property (see L</"Bidirectional Character Types"> below),
424 can take on several different
425 values, such as C<Left>, C<Right>, C<Whitespace>, and others.  To match these, one needs
426 to specify both the property name (C<Bidi_Class>), AND the value being
427 matched against
428 (C<Left>, C<Right>, I<etc.>).  This is done, as in the examples above, by having the
429 two components separated by an equal sign (or interchangeably, a colon), like
430 C<\p{Bidi_Class: Left}>.
431
432 All Unicode-defined character properties may be written in these compound forms
433 of C<\p{I<property>=I<value>}> or C<\p{I<property>:I<value>}>, but Perl provides some
434 additional properties that are written only in the single form, as well as
435 single-form short-cuts for all binary properties and certain others described
436 below, in which you may omit the property name and the equals or colon
437 separator.
438
439 Most Unicode character properties have at least two synonyms (or aliases if you
440 prefer): a short one that is easier to type and a longer one that is more
441 descriptive and hence easier to understand.  Thus the C<"L"> and
442 C<"Letter"> properties above are equivalent and can be used
443 interchangeably.  Likewise, C<"Upper"> is a synonym for C<"Uppercase">,
444 and we could have written C<\p{Uppercase}> equivalently as C<\p{Upper}>.
445 Also, there are typically various synonyms for the values the property
446 can be.   For binary properties, C<"True"> has 3 synonyms: C<"T">,
447 C<"Yes">, and C<"Y">; and C<"False"> has correspondingly C<"F">,
448 C<"No">, and C<"N">.  But be careful.  A short form of a value for one
449 property may not mean the same thing as the same short form for another.
450 Thus, for the C<L</General_Category>> property, C<"L"> means
451 C<"Letter">, but for the L<C<Bidi_Class>|/Bidirectional Character Types>
452 property, C<"L"> means C<"Left">.  A complete list of properties and
453 synonyms is in L<perluniprops>.
454
455 Upper/lower case differences in property names and values are irrelevant;
456 thus C<\p{Upper}> means the same thing as C<\p{upper}> or even C<\p{UpPeR}>.
457 Similarly, you can add or subtract underscores anywhere in the middle of a
458 word, so that these are also equivalent to C<\p{U_p_p_e_r}>.  And white space
459 is irrelevant adjacent to non-word characters, such as the braces and the equals
460 or colon separators, so C<\p{   Upper  }> and C<\p{ Upper_case : Y }> are
461 equivalent to these as well.  In fact, white space and even
462 hyphens can usually be added or deleted anywhere.  So even C<\p{ Up-per case = Yes}> is
463 equivalent.  All this is called "loose-matching" by Unicode.  The few places
464 where stricter matching is used is in the middle of numbers, and in the Perl
465 extension properties that begin or end with an underscore.  Stricter matching
466 cares about white space (except adjacent to non-word characters),
467 hyphens, and non-interior underscores.
468
469 You can also use negation in both C<\p{}> and C<\P{}> by introducing a caret
470 (C<^>) between the first brace and the property name: C<\p{^Tamil}> is
471 equal to C<\P{Tamil}>.
472
473 Almost all properties are immune to case-insensitive matching.  That is,
474 adding a C</i> regular expression modifier does not change what they
475 match.  There are two sets that are affected.
476 The first set is
477 C<Uppercase_Letter>,
478 C<Lowercase_Letter>,
479 and C<Titlecase_Letter>,
480 all of which match C<Cased_Letter> under C</i> matching.
481 And the second set is
482 C<Uppercase>,
483 C<Lowercase>,
484 and C<Titlecase>,
485 all of which match C<Cased> under C</i> matching.
486 This set also includes its subsets C<PosixUpper> and C<PosixLower> both
487 of which under C</i> match C<PosixAlpha>.
488 (The difference between these sets is that some things, such as Roman
489 numerals, come in both upper and lower case so they are C<Cased>, but
490 aren't considered letters, so they aren't C<Cased_Letter>'s.)
491
492 See L</Beyond Unicode code points> for special considerations when
493 matching Unicode properties against non-Unicode code points.
494
495 =head3 B<General_Category>
496
497 Every Unicode character is assigned a general category, which is the "most
498 usual categorization of a character" (from
499 L<http://www.unicode.org/reports/tr44>).
500
501 The compound way of writing these is like C<\p{General_Category=Number}>
502 (short: C<\p{gc:n}>).  But Perl furnishes shortcuts in which everything up
503 through the equal or colon separator is omitted.  So you can instead just write
504 C<\pN>.
505
506 Here are the short and long forms of the values the C<General Category> property
507 can have:
508
509     Short       Long
510
511     L           Letter
512     LC, L&      Cased_Letter (that is: [\p{Ll}\p{Lu}\p{Lt}])
513     Lu          Uppercase_Letter
514     Ll          Lowercase_Letter
515     Lt          Titlecase_Letter
516     Lm          Modifier_Letter
517     Lo          Other_Letter
518
519     M           Mark
520     Mn          Nonspacing_Mark
521     Mc          Spacing_Mark
522     Me          Enclosing_Mark
523
524     N           Number
525     Nd          Decimal_Number (also Digit)
526     Nl          Letter_Number
527     No          Other_Number
528
529     P           Punctuation (also Punct)
530     Pc          Connector_Punctuation
531     Pd          Dash_Punctuation
532     Ps          Open_Punctuation
533     Pe          Close_Punctuation
534     Pi          Initial_Punctuation
535                 (may behave like Ps or Pe depending on usage)
536     Pf          Final_Punctuation
537                 (may behave like Ps or Pe depending on usage)
538     Po          Other_Punctuation
539
540     S           Symbol
541     Sm          Math_Symbol
542     Sc          Currency_Symbol
543     Sk          Modifier_Symbol
544     So          Other_Symbol
545
546     Z           Separator
547     Zs          Space_Separator
548     Zl          Line_Separator
549     Zp          Paragraph_Separator
550
551     C           Other
552     Cc          Control (also Cntrl)
553     Cf          Format
554     Cs          Surrogate
555     Co          Private_Use
556     Cn          Unassigned
557
558 Single-letter properties match all characters in any of the
559 two-letter sub-properties starting with the same letter.
560 C<LC> and C<L&> are special: both are aliases for the set consisting of everything matched by C<Ll>, C<Lu>, and C<Lt>.
561
562 =head3 B<Bidirectional Character Types>
563
564 Because scripts differ in their directionality (Hebrew and Arabic are
565 written right to left, for example) Unicode supplies a C<Bidi_Class> property.
566 Some of the values this property can have are:
567
568     Value       Meaning
569
570     L           Left-to-Right
571     LRE         Left-to-Right Embedding
572     LRO         Left-to-Right Override
573     R           Right-to-Left
574     AL          Arabic Letter
575     RLE         Right-to-Left Embedding
576     RLO         Right-to-Left Override
577     PDF         Pop Directional Format
578     EN          European Number
579     ES          European Separator
580     ET          European Terminator
581     AN          Arabic Number
582     CS          Common Separator
583     NSM         Non-Spacing Mark
584     BN          Boundary Neutral
585     B           Paragraph Separator
586     S           Segment Separator
587     WS          Whitespace
588     ON          Other Neutrals
589
590 This property is always written in the compound form.
591 For example, C<\p{Bidi_Class:R}> matches characters that are normally
592 written right to left.  Unlike the
593 C<L</General_Category>> property, this
594 property can have more values added in a future Unicode release.  Those
595 listed above comprised the complete set for many Unicode releases, but
596 others were added in Unicode 6.3; you can always find what the
597 current ones are in L<perluniprops>.  And
598 L<http://www.unicode.org/reports/tr9/> describes how to use them.
599
600 =head3 B<Scripts>
601
602 The world's languages are written in many different scripts.  This sentence
603 (unless you're reading it in translation) is written in Latin, while Russian is
604 written in Cyrillic, and Greek is written in, well, Greek; Japanese mainly in
605 Hiragana or Katakana.  There are many more.
606
607 The Unicode C<Script> and C<Script_Extensions> properties give what
608 script a given character is in.  The C<Script_Extensions> property is an
609 improved version of C<Script>, as demonstrated below.  Either property
610 can be specified with the compound form like
611 C<\p{Script=Hebrew}> (short: C<\p{sc=hebr}>), or
612 C<\p{Script_Extensions=Javanese}> (short: C<\p{scx=java}>).
613 In addition, Perl furnishes shortcuts for all
614 C<Script_Extensions> property names.  You can omit everything up through
615 the equals (or colon), and simply write C<\p{Latin}> or C<\P{Cyrillic}>.
616 (This is not true for C<Script>, which is required to be
617 written in the compound form.  Prior to Perl v5.26, the single form
618 returned the plain old C<Script> version, but was changed because
619 C<Script_Extensions> gives better results.)
620
621 The difference between these two properties involves characters that are
622 used in multiple scripts.  For example the digits '0' through '9' are
623 used in many parts of the world.  These are placed in a script named
624 C<Common>.  Other characters are used in just a few scripts.  For
625 example, the C<"KATAKANA-HIRAGANA DOUBLE HYPHEN"> is used in both Japanese
626 scripts, Katakana and Hiragana, but nowhere else.  The C<Script>
627 property places all characters that are used in multiple scripts in the
628 C<Common> script, while the C<Script_Extensions> property places those
629 that are used in only a few scripts into each of those scripts; while
630 still using C<Common> for those used in many scripts.  Thus both these
631 match:
632
633  "0" =~ /\p{sc=Common}/     # Matches
634  "0" =~ /\p{scx=Common}/    # Matches
635
636 and only the first of these match:
637
638  "\N{KATAKANA-HIRAGANA DOUBLE HYPHEN}" =~ /\p{sc=Common}  # Matches
639  "\N{KATAKANA-HIRAGANA DOUBLE HYPHEN}" =~ /\p{scx=Common} # No match
640
641 And only the last two of these match:
642
643  "\N{KATAKANA-HIRAGANA DOUBLE HYPHEN}" =~ /\p{sc=Hiragana}  # No match
644  "\N{KATAKANA-HIRAGANA DOUBLE HYPHEN}" =~ /\p{sc=Katakana}  # No match
645  "\N{KATAKANA-HIRAGANA DOUBLE HYPHEN}" =~ /\p{scx=Hiragana} # Matches
646  "\N{KATAKANA-HIRAGANA DOUBLE HYPHEN}" =~ /\p{scx=Katakana} # Matches
647
648 C<Script_Extensions> is thus an improved C<Script>, in which there are
649 fewer characters in the C<Common> script, and correspondingly more in
650 other scripts.  It is new in Unicode version 6.0, and its data are likely
651 to change significantly in later releases, as things get sorted out.
652 New code should probably be using C<Script_Extensions> and not plain
653 C<Script>.  If you compile perl with a Unicode release that doesn't have
654 C<Script_Extensions>, the single form Perl extensions will instead refer
655 to the plain C<Script> property.  If you compile with a version of
656 Unicode that doesn't have the C<Script> property, these extensions will
657 not be defined at all.
658
659 (Actually, besides C<Common>, the C<Inherited> script, contains
660 characters that are used in multiple scripts.  These are modifier
661 characters which inherit the script value
662 of the controlling character.  Some of these are used in many scripts,
663 and so go into C<Inherited> in both C<Script> and C<Script_Extensions>.
664 Others are used in just a few scripts, so are in C<Inherited> in
665 C<Script>, but not in C<Script_Extensions>.)
666
667 It is worth stressing that there are several different sets of digits in
668 Unicode that are equivalent to 0-9 and are matchable by C<\d> in a
669 regular expression.  If they are used in a single language only, they
670 are in that language's C<Script> and C<Script_Extensions>.  If they are
671 used in more than one script, they will be in C<sc=Common>, but only
672 if they are used in many scripts should they be in C<scx=Common>.
673
674 The explanation above has omitted some detail; refer to UAX#24 "Unicode
675 Script Property": L<http://www.unicode.org/reports/tr24>.
676
677 A complete list of scripts and their shortcuts is in L<perluniprops>.
678
679 =head3 B<Use of the C<"Is"> Prefix>
680
681 For backward compatibility (with Perl 5.6), all properties writable
682 without using the compound form mentioned
683 so far may have C<Is> or C<Is_> prepended to their name, so C<\P{Is_Lu}>, for
684 example, is equal to C<\P{Lu}>, and C<\p{IsScript:Arabic}> is equal to
685 C<\p{Arabic}>.
686
687 =head3 B<Blocks>
688
689 In addition to B<scripts>, Unicode also defines B<blocks> of
690 characters.  The difference between scripts and blocks is that the
691 concept of scripts is closer to natural languages, while the concept
692 of blocks is more of an artificial grouping based on groups of Unicode
693 characters with consecutive ordinal values. For example, the C<"Basic Latin">
694 block is all the characters whose ordinals are between 0 and 127, inclusive; in
695 other words, the ASCII characters.  The C<"Latin"> script contains some letters
696 from this as well as several other blocks, like C<"Latin-1 Supplement">,
697 C<"Latin Extended-A">, I<etc.>, but it does not contain all the characters from
698 those blocks. It does not, for example, contain the digits 0-9, because
699 those digits are shared across many scripts, and hence are in the
700 C<Common> script.
701
702 For more about scripts versus blocks, see UAX#24 "Unicode Script Property":
703 L<http://www.unicode.org/reports/tr24>
704
705 The C<Script_Extensions> or C<Script> properties are likely to be the
706 ones you want to use when processing
707 natural language; the C<Block> property may occasionally be useful in working
708 with the nuts and bolts of Unicode.
709
710 Block names are matched in the compound form, like C<\p{Block: Arrows}> or
711 C<\p{Blk=Hebrew}>.  Unlike most other properties, only a few block names have a
712 Unicode-defined short name.
713
714 Perl also defines single form synonyms for the block property in cases
715 where these do not conflict with something else.  But don't use any of
716 these, because they are unstable.  Since these are Perl extensions, they
717 are subordinate to official Unicode property names; Unicode doesn't know
718 nor care about Perl's extensions.  It may happen that a name that
719 currently means the Perl extension will later be changed without warning
720 to mean a different Unicode property in a future version of the perl
721 interpreter that uses a later Unicode release, and your code would no
722 longer work.  The extensions are mentioned here for completeness:  Take
723 the block name and prefix it with one of: C<In> (for example
724 C<\p{Blk=Arrows}> can currently be written as C<\p{In_Arrows}>); or
725 sometimes C<Is> (like C<\p{Is_Arrows}>); or sometimes no prefix at all
726 (C<\p{Arrows}>).  As of this writing (Unicode 9.0) there are no
727 conflicts with using the C<In_> prefix, but there are plenty with the
728 other two forms.  For example, C<\p{Is_Hebrew}> and C<\p{Hebrew}> mean
729 C<\p{Script_Extensions=Hebrew}> which is NOT the same thing as
730 C<\p{Blk=Hebrew}>.  Our
731 advice used to be to use the C<In_> prefix as a single form way of
732 specifying a block.  But Unicode 8.0 added properties whose names begin
733 with C<In>, and it's now clear that it's only luck that's so far
734 prevented a conflict.  Using C<In> is only marginally less typing than
735 C<Blk:>, and the latter's meaning is clearer anyway, and guaranteed to
736 never conflict.  So don't take chances.  Use C<\p{Blk=foo}> for new
737 code.  And be sure that block is what you really really want to do.  In
738 most cases scripts are what you want instead.
739
740 A complete list of blocks is in L<perluniprops>.
741
742 =head3 B<Other Properties>
743
744 There are many more properties than the very basic ones described here.
745 A complete list is in L<perluniprops>.
746
747 Unicode defines all its properties in the compound form, so all single-form
748 properties are Perl extensions.  Most of these are just synonyms for the
749 Unicode ones, but some are genuine extensions, including several that are in
750 the compound form.  And quite a few of these are actually recommended by Unicode
751 (in L<http://www.unicode.org/reports/tr18>).
752
753 This section gives some details on all extensions that aren't just
754 synonyms for compound-form Unicode properties
755 (for those properties, you'll have to refer to the
756 L<Unicode Standard|http://www.unicode.org/reports/tr44>.
757
758 =over
759
760 =item B<C<\p{All}>>
761
762 This matches every possible code point.  It is equivalent to C<qr/./s>.
763 Unlike all the other non-user-defined C<\p{}> property matches, no
764 warning is ever generated if this is property is matched against a
765 non-Unicode code point (see L</Beyond Unicode code points> below).
766
767 =item B<C<\p{Alnum}>>
768
769 This matches any C<\p{Alphabetic}> or C<\p{Decimal_Number}> character.
770
771 =item B<C<\p{Any}>>
772
773 This matches any of the 1_114_112 Unicode code points.  It is a synonym
774 for C<\p{Unicode}>.
775
776 =item B<C<\p{ASCII}>>
777
778 This matches any of the 128 characters in the US-ASCII character set,
779 which is a subset of Unicode.
780
781 =item B<C<\p{Assigned}>>
782
783 This matches any assigned code point; that is, any code point whose L<general
784 category|/General_Category> is not C<Unassigned> (or equivalently, not C<Cn>).
785
786 =item B<C<\p{Blank}>>
787
788 This is the same as C<\h> and C<\p{HorizSpace}>:  A character that changes the
789 spacing horizontally.
790
791 =item B<C<\p{Decomposition_Type: Non_Canonical}>>    (Short: C<\p{Dt=NonCanon}>)
792
793 Matches a character that has a non-canonical decomposition.
794
795 The L</Extended Grapheme Clusters (Logical characters)> section above
796 talked about canonical decompositions.  However, many more characters
797 have a different type of decomposition, a "compatible" or
798 "non-canonical" decomposition.  The sequences that form these
799 decompositions are not considered canonically equivalent to the
800 pre-composed character.  An example is the C<"SUPERSCRIPT ONE">.  It is
801 somewhat like a regular digit 1, but not exactly; its decomposition into
802 the digit 1 is called a "compatible" decomposition, specifically a
803 "super" decomposition.  There are several such compatibility
804 decompositions (see L<http://www.unicode.org/reports/tr44>), including
805 one called "compat", which means some miscellaneous type of
806 decomposition that doesn't fit into the other decomposition categories
807 that Unicode has chosen.
808
809 Note that most Unicode characters don't have a decomposition, so their
810 decomposition type is C<"None">.
811
812 For your convenience, Perl has added the C<Non_Canonical> decomposition
813 type to mean any of the several compatibility decompositions.
814
815 =item B<C<\p{Graph}>>
816
817 Matches any character that is graphic.  Theoretically, this means a character
818 that on a printer would cause ink to be used.
819
820 =item B<C<\p{HorizSpace}>>
821
822 This is the same as C<\h> and C<\p{Blank}>:  a character that changes the
823 spacing horizontally.
824
825 =item B<C<\p{In=*}>>
826
827 This is a synonym for C<\p{Present_In=*}>
828
829 =item B<C<\p{PerlSpace}>>
830
831 This is the same as C<\s>, restricted to ASCII, namely C<S<[ \f\n\r\t]>>
832 and starting in Perl v5.18, a vertical tab.
833
834 Mnemonic: Perl's (original) space
835
836 =item B<C<\p{PerlWord}>>
837
838 This is the same as C<\w>, restricted to ASCII, namely C<[A-Za-z0-9_]>
839
840 Mnemonic: Perl's (original) word.
841
842 =item B<C<\p{Posix...}>>
843
844 There are several of these, which are equivalents, using the C<\p{}>
845 notation, for Posix classes and are described in
846 L<perlrecharclass/POSIX Character Classes>.
847
848 =item B<C<\p{Present_In: *}>>    (Short: C<\p{In=*}>)
849
850 This property is used when you need to know in what Unicode version(s) a
851 character is.
852
853 The "*" above stands for some two digit Unicode version number, such as
854 C<1.1> or C<4.0>; or the "*" can also be C<Unassigned>.  This property will
855 match the code points whose final disposition has been settled as of the
856 Unicode release given by the version number; C<\p{Present_In: Unassigned}>
857 will match those code points whose meaning has yet to be assigned.
858
859 For example, C<U+0041> C<"LATIN CAPITAL LETTER A"> was present in the very first
860 Unicode release available, which is C<1.1>, so this property is true for all
861 valid "*" versions.  On the other hand, C<U+1EFF> was not assigned until version
862 5.1 when it became C<"LATIN SMALL LETTER Y WITH LOOP">, so the only "*" that
863 would match it are 5.1, 5.2, and later.
864
865 Unicode furnishes the C<Age> property from which this is derived.  The problem
866 with Age is that a strict interpretation of it (which Perl takes) has it
867 matching the precise release a code point's meaning is introduced in.  Thus
868 C<U+0041> would match only 1.1; and C<U+1EFF> only 5.1.  This is not usually what
869 you want.
870
871 Some non-Perl implementations of the Age property may change its meaning to be
872 the same as the Perl C<Present_In> property; just be aware of that.
873
874 Another confusion with both these properties is that the definition is not
875 that the code point has been I<assigned>, but that the meaning of the code point
876 has been I<determined>.  This is because 66 code points will always be
877 unassigned, and so the C<Age> for them is the Unicode version in which the decision
878 to make them so was made.  For example, C<U+FDD0> is to be permanently
879 unassigned to a character, and the decision to do that was made in version 3.1,
880 so C<\p{Age=3.1}> matches this character, as also does C<\p{Present_In: 3.1}> and up.
881
882 =item B<C<\p{Print}>>
883
884 This matches any character that is graphical or blank, except controls.
885
886 =item B<C<\p{SpacePerl}>>
887
888 This is the same as C<\s>, including beyond ASCII.
889
890 Mnemonic: Space, as modified by Perl.  (It doesn't include the vertical tab
891 until v5.18, which both the Posix standard and Unicode consider white space.)
892
893 =item B<C<\p{Title}>> and  B<C<\p{Titlecase}>>
894
895 Under case-sensitive matching, these both match the same code points as
896 C<\p{General Category=Titlecase_Letter}> (C<\p{gc=lt}>).  The difference
897 is that under C</i> caseless matching, these match the same as
898 C<\p{Cased}>, whereas C<\p{gc=lt}> matches C<\p{Cased_Letter>).
899
900 =item B<C<\p{Unicode}>>
901
902 This matches any of the 1_114_112 Unicode code points.
903 C<\p{Any}>.
904
905 =item B<C<\p{VertSpace}>>
906
907 This is the same as C<\v>:  A character that changes the spacing vertically.
908
909 =item B<C<\p{Word}>>
910
911 This is the same as C<\w>, including over 100_000 characters beyond ASCII.
912
913 =item B<C<\p{XPosix...}>>
914
915 There are several of these, which are the standard Posix classes
916 extended to the full Unicode range.  They are described in
917 L<perlrecharclass/POSIX Character Classes>.
918
919 =back
920
921
922 =head2 User-Defined Character Properties
923
924 You can define your own binary character properties by defining subroutines
925 whose names begin with C<"In"> or C<"Is">.  (The experimental feature
926 L<perlre/(?[ ])> provides an alternative which allows more complex
927 definitions.)  The subroutines can be defined in any
928 package.  The user-defined properties can be used in the regular expression
929 C<\p{}> and C<\P{}> constructs; if you are using a user-defined property from a
930 package other than the one you are in, you must specify its package in the
931 C<\p{}> or C<\P{}> construct.
932
933     # assuming property Is_Foreign defined in Lang::
934     package main;  # property package name required
935     if ($txt =~ /\p{Lang::IsForeign}+/) { ... }
936
937     package Lang;  # property package name not required
938     if ($txt =~ /\p{IsForeign}+/) { ... }
939
940
941 Note that the effect is compile-time and immutable once defined.
942 However, the subroutines are passed a single parameter, which is 0 if
943 case-sensitive matching is in effect and non-zero if caseless matching
944 is in effect.  The subroutine may return different values depending on
945 the value of the flag, and one set of values will immutably be in effect
946 for all case-sensitive matches, and the other set for all case-insensitive
947 matches.
948
949 Note that if the regular expression is tainted, then Perl will die rather
950 than calling the subroutine when the name of the subroutine is
951 determined by the tainted data.
952
953 The subroutines must return a specially-formatted string, with one
954 or more newline-separated lines.  Each line must be one of the following:
955
956 =over 4
957
958 =item *
959
960 A single hexadecimal number denoting a code point to include.
961
962 =item *
963
964 Two hexadecimal numbers separated by horizontal whitespace (space or
965 tabular characters) denoting a range of code points to include.
966
967 =item *
968
969 Something to include, prefixed by C<"+">: a built-in character
970 property (prefixed by C<"utf8::">) or a fully qualified (including package
971 name) user-defined character property,
972 to represent all the characters in that property; two hexadecimal code
973 points for a range; or a single hexadecimal code point.
974
975 =item *
976
977 Something to exclude, prefixed by C<"-">: an existing character
978 property (prefixed by C<"utf8::">) or a fully qualified (including package
979 name) user-defined character property,
980 to represent all the characters in that property; two hexadecimal code
981 points for a range; or a single hexadecimal code point.
982
983 =item *
984
985 Something to negate, prefixed C<"!">: an existing character
986 property (prefixed by C<"utf8::">) or a fully qualified (including package
987 name) user-defined character property,
988 to represent all the characters in that property; two hexadecimal code
989 points for a range; or a single hexadecimal code point.
990
991 =item *
992
993 Something to intersect with, prefixed by C<"&">: an existing character
994 property (prefixed by C<"utf8::">) or a fully qualified (including package
995 name) user-defined character property,
996 for all the characters except the characters in the property; two
997 hexadecimal code points for a range; or a single hexadecimal code point.
998
999 =back
1000
1001 For example, to define a property that covers both the Japanese
1002 syllabaries (hiragana and katakana), you can define
1003
1004     sub InKana {
1005         return <<END;
1006     3040\t309F
1007     30A0\t30FF
1008     END
1009     }
1010
1011 Imagine that the here-doc end marker is at the beginning of the line.
1012 Now you can use C<\p{InKana}> and C<\P{InKana}>.
1013
1014 You could also have used the existing block property names:
1015
1016     sub InKana {
1017         return <<'END';
1018     +utf8::InHiragana
1019     +utf8::InKatakana
1020     END
1021     }
1022
1023 Suppose you wanted to match only the allocated characters,
1024 not the raw block ranges: in other words, you want to remove
1025 the unassigned characters:
1026
1027     sub InKana {
1028         return <<'END';
1029     +utf8::InHiragana
1030     +utf8::InKatakana
1031     -utf8::IsCn
1032     END
1033     }
1034
1035 The negation is useful for defining (surprise!) negated classes.
1036
1037     sub InNotKana {
1038         return <<'END';
1039     !utf8::InHiragana
1040     -utf8::InKatakana
1041     +utf8::IsCn
1042     END
1043     }
1044
1045 This will match all non-Unicode code points, since every one of them is
1046 not in Kana.  You can use intersection to exclude these, if desired, as
1047 this modified example shows:
1048
1049     sub InNotKana {
1050         return <<'END';
1051     !utf8::InHiragana
1052     -utf8::InKatakana
1053     +utf8::IsCn
1054     &utf8::Any
1055     END
1056     }
1057
1058 C<&utf8::Any> must be the last line in the definition.
1059
1060 Intersection is used generally for getting the common characters matched
1061 by two (or more) classes.  It's important to remember not to use C<"&"> for
1062 the first set; that would be intersecting with nothing, resulting in an
1063 empty set.
1064
1065 Unlike non-user-defined C<\p{}> property matches, no warning is ever
1066 generated if these properties are matched against a non-Unicode code
1067 point (see L</Beyond Unicode code points> below).
1068
1069 =head2 User-Defined Case Mappings (for serious hackers only)
1070
1071 B<This feature has been removed as of Perl 5.16.>
1072 The CPAN module C<L<Unicode::Casing>> provides better functionality without
1073 the drawbacks that this feature had.  If you are using a Perl earlier
1074 than 5.16, this feature was most fully documented in the 5.14 version of
1075 this pod:
1076 L<http://perldoc.perl.org/5.14.0/perlunicode.html#User-Defined-Case-Mappings-%28for-serious-hackers-only%29>
1077
1078 =head2 Character Encodings for Input and Output
1079
1080 See L<Encode>.
1081
1082 =head2 Unicode Regular Expression Support Level
1083
1084 The following list of Unicode supported features for regular expressions describes
1085 all features currently directly supported by core Perl.  The references
1086 to "Level I<N>" and the section numbers refer to
1087 L<UTS#18 "Unicode Regular Expressions"|http://www.unicode.org/reports/tr18>,
1088 version 13, November 2013.
1089
1090 =head3 Level 1 - Basic Unicode Support
1091
1092  RL1.1   Hex Notation                     - Done          [1]
1093  RL1.2   Properties                       - Done          [2]
1094  RL1.2a  Compatibility Properties         - Done          [3]
1095  RL1.3   Subtraction and Intersection     - Experimental  [4]
1096  RL1.4   Simple Word Boundaries           - Done          [5]
1097  RL1.5   Simple Loose Matches             - Done          [6]
1098  RL1.6   Line Boundaries                  - Partial       [7]
1099  RL1.7   Supplementary Code Points        - Done          [8]
1100
1101 =over 4
1102
1103 =item [1] C<\N{U+...}> and C<\x{...}>
1104
1105 =item [2]
1106 C<\p{...}> C<\P{...}>.  This requirement is for a minimal list of
1107 properties.  Perl supports these and all other Unicode character
1108 properties, as R2.7 asks (see L</"Unicode Character Properties"> above).
1109
1110 =item [3]
1111 Perl has C<\d> C<\D> C<\s> C<\S> C<\w> C<\W> C<\X> C<[:I<prop>:]>
1112 C<[:^I<prop>:]>, plus all the properties specified by
1113 L<http://www.unicode.org/reports/tr18/#Compatibility_Properties>.  These
1114 are described above in L</Other Properties>
1115
1116 =item [4]
1117
1118 The experimental feature C<"(?[...])"> starting in v5.18 accomplishes
1119 this.
1120
1121 See L<perlre/(?[ ])>.  If you don't want to use an experimental
1122 feature, you can use one of the following:
1123
1124 =over 4
1125
1126 =item *
1127 Regular expression lookahead
1128
1129 You can mimic class subtraction using lookahead.
1130 For example, what UTS#18 might write as
1131
1132     [{Block=Greek}-[{UNASSIGNED}]]
1133
1134 in Perl can be written as:
1135
1136     (?!\p{Unassigned})\p{Block=Greek}
1137     (?=\p{Assigned})\p{Block=Greek}
1138
1139 But in this particular example, you probably really want
1140
1141     \p{Greek}
1142
1143 which will match assigned characters known to be part of the Greek script.
1144
1145 =item *
1146
1147 CPAN module C<L<Unicode::Regex::Set>>
1148
1149 It does implement the full UTS#18 grouping, intersection, union, and
1150 removal (subtraction) syntax.
1151
1152 =item *
1153
1154 L</"User-Defined Character Properties">
1155
1156 C<"+"> for union, C<"-"> for removal (set-difference), C<"&"> for intersection
1157
1158 =back
1159
1160 =item [5]
1161 C<\b> C<\B> meet most, but not all, the details of this requirement, but
1162 C<\b{wb}> and C<\B{wb}> do, as well as the stricter R2.3.
1163
1164 =item [6]
1165
1166 Note that Perl does Full case-folding in matching, not Simple:
1167
1168 For example C<U+1F88> is equivalent to C<U+1F00 U+03B9>, instead of just
1169 C<U+1F80>.  This difference matters mainly for certain Greek capital
1170 letters with certain modifiers: the Full case-folding decomposes the
1171 letter, while the Simple case-folding would map it to a single
1172 character.
1173
1174 =item [7]
1175
1176 The reason this is considered to be only partially implemented is that
1177 Perl has L<C<qrE<sol>\b{lb}E<sol>>|perlrebackslash/\b{lb}> and
1178 C<L<Unicode::LineBreak>> that are conformant with
1179 L<UAX#14 "Unicode Line Breaking Algorithm"|http://www.unicode.org/reports/tr14>.
1180 The regular expression construct provides default behavior, while the
1181 heavier-weight module provides customizable line breaking.
1182
1183 But Perl treats C<\n> as the start- and end-line
1184 delimiter, whereas Unicode specifies more characters that should be
1185 so-interpreted.
1186
1187 These are:
1188
1189  VT   U+000B  (\v in C)
1190  FF   U+000C  (\f)
1191  CR   U+000D  (\r)
1192  NEL  U+0085
1193  LS   U+2028
1194  PS   U+2029
1195
1196 C<^> and C<$> in regular expression patterns are supposed to match all
1197 these, but don't.
1198 These characters also don't, but should, affect C<< <> >> C<$.>, and
1199 script line numbers.
1200
1201 Also, lines should not be split within C<CRLF> (i.e. there is no
1202 empty line between C<\r> and C<\n>).  For C<CRLF>, try the C<:crlf>
1203 layer (see L<PerlIO>).
1204
1205 =item [8]
1206 UTF-8/UTF-EBDDIC used in Perl allows not only C<U+10000> to
1207 C<U+10FFFF> but also beyond C<U+10FFFF>
1208
1209 =back
1210
1211 =head3 Level 2 - Extended Unicode Support
1212
1213  RL2.1   Canonical Equivalents           - Retracted     [9]
1214                                            by Unicode
1215  RL2.2   Extended Grapheme Clusters      - Partial       [10]
1216  RL2.3   Default Word Boundaries         - Done          [11]
1217  RL2.4   Default Case Conversion         - Done
1218  RL2.5   Name Properties                 - Done
1219  RL2.6   Wildcard Properties             - Missing
1220  RL2.7   Full Properties                 - Done
1221
1222 =over 4
1223
1224 =item [9]
1225 Unicode has rewritten this portion of UTS#18 to say that getting
1226 canonical equivalence (see UAX#15
1227 L<"Unicode Normalization Forms"|http://www.unicode.org/reports/tr15>)
1228 is basically to be done at the programmer level.  Use NFD to write
1229 both your regular expressions and text to match them against (you
1230 can use L<Unicode::Normalize>).
1231
1232 =item [10]
1233 Perl has C<\X> and C<\b{gcb}> but we don't have a "Grapheme Cluster Mode".
1234
1235 =item [11] see
1236 L<UAX#29 "Unicode Text Segmentation"|http://www.unicode.org/reports/tr29>,
1237
1238 =back
1239
1240 =head3 Level 3 - Tailored Support
1241
1242  RL3.1   Tailored Punctuation            - Missing
1243  RL3.2   Tailored Grapheme Clusters      - Missing       [12]
1244  RL3.3   Tailored Word Boundaries        - Missing
1245  RL3.4   Tailored Loose Matches          - Retracted by Unicode
1246  RL3.5   Tailored Ranges                 - Retracted by Unicode
1247  RL3.6   Context Matching                - Missing       [13]
1248  RL3.7   Incremental Matches             - Missing
1249  RL3.8   Unicode Set Sharing             - Unicode is proposing
1250                                            to retract this
1251  RL3.9   Possible Match Sets             - Missing
1252  RL3.10  Folded Matching                 - Retracted by Unicode
1253  RL3.11  Submatchers                     - Missing
1254
1255 =over 4
1256
1257 =item [12]
1258 Perl has L<Unicode::Collate>, but it isn't integrated with regular
1259 expressions.  See
1260 L<UTS#10 "Unicode Collation Algorithms"|http://www.unicode.org/reports/tr10>.
1261
1262 =item [13]
1263 Perl has C<(?<=x)> and C<(?=x)>, but lookaheads or lookbehinds should
1264 see outside of the target substring
1265
1266 =back
1267
1268 =head2 Unicode Encodings
1269
1270 Unicode characters are assigned to I<code points>, which are abstract
1271 numbers.  To use these numbers, various encodings are needed.
1272
1273 =over 4
1274
1275 =item *
1276
1277 UTF-8
1278
1279 UTF-8 is a variable-length (1 to 4 bytes), byte-order independent
1280 encoding.  In most of Perl's documentation, including elsewhere in this
1281 document, the term "UTF-8" means also "UTF-EBCDIC".  But in this section,
1282 "UTF-8" refers only to the encoding used on ASCII platforms.  It is a
1283 superset of 7-bit US-ASCII, so anything encoded in ASCII has the
1284 identical representation when encoded in UTF-8.
1285
1286 The following table is from Unicode 3.2.
1287
1288  Code Points            1st Byte  2nd Byte  3rd Byte 4th Byte
1289
1290    U+0000..U+007F       00..7F
1291    U+0080..U+07FF     * C2..DF    80..BF
1292    U+0800..U+0FFF       E0      * A0..BF    80..BF
1293    U+1000..U+CFFF       E1..EC    80..BF    80..BF
1294    U+D000..U+D7FF       ED        80..9F    80..BF
1295    U+D800..U+DFFF       +++++ utf16 surrogates, not legal utf8 +++++
1296    U+E000..U+FFFF       EE..EF    80..BF    80..BF
1297   U+10000..U+3FFFF      F0      * 90..BF    80..BF    80..BF
1298   U+40000..U+FFFFF      F1..F3    80..BF    80..BF    80..BF
1299  U+100000..U+10FFFF     F4        80..8F    80..BF    80..BF
1300
1301 Note the gaps marked by "*" before several of the byte entries above.  These are
1302 caused by legal UTF-8 avoiding non-shortest encodings: it is technically
1303 possible to UTF-8-encode a single code point in different ways, but that is
1304 explicitly forbidden, and the shortest possible encoding should always be used
1305 (and that is what Perl does).
1306
1307 Another way to look at it is via bits:
1308
1309                 Code Points  1st Byte  2nd Byte  3rd Byte  4th Byte
1310
1311                    0aaaaaaa  0aaaaaaa
1312            00000bbbbbaaaaaa  110bbbbb  10aaaaaa
1313            ccccbbbbbbaaaaaa  1110cccc  10bbbbbb  10aaaaaa
1314  00000dddccccccbbbbbbaaaaaa  11110ddd  10cccccc  10bbbbbb  10aaaaaa
1315
1316 As you can see, the continuation bytes all begin with C<"10">, and the
1317 leading bits of the start byte tell how many bytes there are in the
1318 encoded character.
1319
1320 The original UTF-8 specification allowed up to 6 bytes, to allow
1321 encoding of numbers up to C<0x7FFF_FFFF>.  Perl continues to allow those,
1322 and has extended that up to 13 bytes to encode code points up to what
1323 can fit in a 64-bit word.  However, Perl will warn if you output any of
1324 these as being non-portable; and under strict UTF-8 input protocols,
1325 they are forbidden.  In addition, it is deprecated to use a code point
1326 larger than what a signed integer variable on your system can hold.  On
1327 32-bit ASCII systems, this means C<0x7FFF_FFFF> is the legal maximum
1328 going forward (much higher on 64-bit systems).
1329
1330 =item *
1331
1332 UTF-EBCDIC
1333
1334 Like UTF-8, but EBCDIC-safe, in the way that UTF-8 is ASCII-safe.
1335 This means that all the basic characters (which includes all
1336 those that have ASCII equivalents (like C<"A">, C<"0">, C<"%">, I<etc.>)
1337 are the same in both EBCDIC and UTF-EBCDIC.)
1338
1339 UTF-EBCDIC is used on EBCDIC platforms.  It generally requires more
1340 bytes to represent a given code point than UTF-8 does; the largest
1341 Unicode code points take 5 bytes to represent (instead of 4 in UTF-8),
1342 and, extended for 64-bit words, it uses 14 bytes instead of 13 bytes in
1343 UTF-8.
1344
1345 =item *
1346
1347 UTF-16, UTF-16BE, UTF-16LE, Surrogates, and C<BOM>'s (Byte Order Marks)
1348
1349 The followings items are mostly for reference and general Unicode
1350 knowledge, Perl doesn't use these constructs internally.
1351
1352 Like UTF-8, UTF-16 is a variable-width encoding, but where
1353 UTF-8 uses 8-bit code units, UTF-16 uses 16-bit code units.
1354 All code points occupy either 2 or 4 bytes in UTF-16: code points
1355 C<U+0000..U+FFFF> are stored in a single 16-bit unit, and code
1356 points C<U+10000..U+10FFFF> in two 16-bit units.  The latter case is
1357 using I<surrogates>, the first 16-bit unit being the I<high
1358 surrogate>, and the second being the I<low surrogate>.
1359
1360 Surrogates are code points set aside to encode the C<U+10000..U+10FFFF>
1361 range of Unicode code points in pairs of 16-bit units.  The I<high
1362 surrogates> are the range C<U+D800..U+DBFF> and the I<low surrogates>
1363 are the range C<U+DC00..U+DFFF>.  The surrogate encoding is
1364
1365     $hi = ($uni - 0x10000) / 0x400 + 0xD800;
1366     $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
1367
1368 and the decoding is
1369
1370     $uni = 0x10000 + ($hi - 0xD800) * 0x400 + ($lo - 0xDC00);
1371
1372 Because of the 16-bitness, UTF-16 is byte-order dependent.  UTF-16
1373 itself can be used for in-memory computations, but if storage or
1374 transfer is required either UTF-16BE (big-endian) or UTF-16LE
1375 (little-endian) encodings must be chosen.
1376
1377 This introduces another problem: what if you just know that your data
1378 is UTF-16, but you don't know which endianness?  Byte Order Marks, or
1379 C<BOM>'s, are a solution to this.  A special character has been reserved
1380 in Unicode to function as a byte order marker: the character with the
1381 code point C<U+FEFF> is the C<BOM>.
1382
1383 The trick is that if you read a C<BOM>, you will know the byte order,
1384 since if it was written on a big-endian platform, you will read the
1385 bytes C<0xFE 0xFF>, but if it was written on a little-endian platform,
1386 you will read the bytes C<0xFF 0xFE>.  (And if the originating platform
1387 was writing in ASCII platform UTF-8, you will read the bytes
1388 C<0xEF 0xBB 0xBF>.)
1389
1390 The way this trick works is that the character with the code point
1391 C<U+FFFE> is not supposed to be in input streams, so the
1392 sequence of bytes C<0xFF 0xFE> is unambiguously "C<BOM>, represented in
1393 little-endian format" and cannot be C<U+FFFE>, represented in big-endian
1394 format".
1395
1396 Surrogates have no meaning in Unicode outside their use in pairs to
1397 represent other code points.  However, Perl allows them to be
1398 represented individually internally, for example by saying
1399 C<chr(0xD801)>, so that all code points, not just those valid for open
1400 interchange, are
1401 representable.  Unicode does define semantics for them, such as their
1402 C<L</General_Category>> is C<"Cs">.  But because their use is somewhat dangerous,
1403 Perl will warn (using the warning category C<"surrogate">, which is a
1404 sub-category of C<"utf8">) if an attempt is made
1405 to do things like take the lower case of one, or match
1406 case-insensitively, or to output them.  (But don't try this on Perls
1407 before 5.14.)
1408
1409 =item *
1410
1411 UTF-32, UTF-32BE, UTF-32LE
1412
1413 The UTF-32 family is pretty much like the UTF-16 family, except that
1414 the units are 32-bit, and therefore the surrogate scheme is not
1415 needed.  UTF-32 is a fixed-width encoding.  The C<BOM> signatures are
1416 C<0x00 0x00 0xFE 0xFF> for BE and C<0xFF 0xFE 0x00 0x00> for LE.
1417
1418 =item *
1419
1420 UCS-2, UCS-4
1421
1422 Legacy, fixed-width encodings defined by the ISO 10646 standard.  UCS-2 is a 16-bit
1423 encoding.  Unlike UTF-16, UCS-2 is not extensible beyond C<U+FFFF>,
1424 because it does not use surrogates.  UCS-4 is a 32-bit encoding,
1425 functionally identical to UTF-32 (the difference being that
1426 UCS-4 forbids neither surrogates nor code points larger than C<0x10_FFFF>).
1427
1428 =item *
1429
1430 UTF-7
1431
1432 A seven-bit safe (non-eight-bit) encoding, which is useful if the
1433 transport or storage is not eight-bit safe.  Defined by RFC 2152.
1434
1435 =back
1436
1437 =head2 Noncharacter code points
1438
1439 66 code points are set aside in Unicode as "noncharacter code points".
1440 These all have the C<Unassigned> (C<Cn>) C<L</General_Category>>, and
1441 no character will ever be assigned to any of them.  They are the 32 code
1442 points between C<U+FDD0> and C<U+FDEF> inclusive, and the 34 code
1443 points:
1444
1445  U+FFFE   U+FFFF
1446  U+1FFFE  U+1FFFF
1447  U+2FFFE  U+2FFFF
1448  ...
1449  U+EFFFE  U+EFFFF
1450  U+FFFFE  U+FFFFF
1451  U+10FFFE U+10FFFF
1452
1453 Until Unicode 7.0, the noncharacters were "B<forbidden> for use in open
1454 interchange of Unicode text data", so that code that processed those
1455 streams could use these code points as sentinels that could be mixed in
1456 with character data, and would always be distinguishable from that data.
1457 (Emphasis above and in the next paragraph are added in this document.)
1458
1459 Unicode 7.0 changed the wording so that they are "B<not recommended> for
1460 use in open interchange of Unicode text data".  The 7.0 Standard goes on
1461 to say:
1462
1463 =over 4
1464
1465 "If a noncharacter is received in open interchange, an application is
1466 not required to interpret it in any way.  It is good practice, however,
1467 to recognize it as a noncharacter and to take appropriate action, such
1468 as replacing it with C<U+FFFD> replacement character, to indicate the
1469 problem in the text.  It is not recommended to simply delete
1470 noncharacter code points from such text, because of the potential
1471 security issues caused by deleting uninterpreted characters.  (See
1472 conformance clause C7 in Section 3.2, Conformance Requirements, and
1473 L<Unicode Technical Report #36, "Unicode Security
1474 Considerations"|http://www.unicode.org/reports/tr36/#Substituting_for_Ill_Formed_Subsequences>)."
1475
1476 =back
1477
1478 This change was made because it was found that various commercial tools
1479 like editors, or for things like source code control, had been written
1480 so that they would not handle program files that used these code points,
1481 effectively precluding their use almost entirely!  And that was never
1482 the intent.  They've always been meant to be usable within an
1483 application, or cooperating set of applications, at will.
1484
1485 If you're writing code, such as an editor, that is supposed to be able
1486 to handle any Unicode text data, then you shouldn't be using these code
1487 points yourself, and instead allow them in the input.  If you need
1488 sentinels, they should instead be something that isn't legal Unicode.
1489 For UTF-8 data, you can use the bytes 0xC1 and 0xC2 as sentinels, as
1490 they never appear in well-formed UTF-8.  (There are equivalents for
1491 UTF-EBCDIC).  You can also store your Unicode code points in integer
1492 variables and use negative values as sentinels.
1493
1494 If you're not writing such a tool, then whether you accept noncharacters
1495 as input is up to you (though the Standard recommends that you not).  If
1496 you do strict input stream checking with Perl, these code points
1497 continue to be forbidden.  This is to maintain backward compatibility
1498 (otherwise potential security holes could open up, as an unsuspecting
1499 application that was written assuming the noncharacters would be
1500 filtered out before getting to it, could now, without warning, start
1501 getting them).  To do strict checking, you can use the layer
1502 C<:encoding('UTF-8')>.
1503
1504 Perl continues to warn (using the warning category C<"nonchar">, which
1505 is a sub-category of C<"utf8">) if an attempt is made to output
1506 noncharacters.
1507
1508 =head2 Beyond Unicode code points
1509
1510 The maximum Unicode code point is C<U+10FFFF>, and Unicode only defines
1511 operations on code points up through that.  But Perl works on code
1512 points up to the maximum permissible unsigned number available on the
1513 platform.  However, Perl will not accept these from input streams unless
1514 lax rules are being used, and will warn (using the warning category
1515 C<"non_unicode">, which is a sub-category of C<"utf8">) if any are output.
1516
1517 Since Unicode rules are not defined on these code points, if a
1518 Unicode-defined operation is done on them, Perl uses what we believe are
1519 sensible rules, while generally warning, using the C<"non_unicode">
1520 category.  For example, C<uc("\x{11_0000}")> will generate such a
1521 warning, returning the input parameter as its result, since Perl defines
1522 the uppercase of every non-Unicode code point to be the code point
1523 itself.  (All the case changing operations, not just uppercasing, work
1524 this way.)
1525
1526 The situation with matching Unicode properties in regular expressions,
1527 the C<\p{}> and C<\P{}> constructs, against these code points is not as
1528 clear cut, and how these are handled has changed as we've gained
1529 experience.
1530
1531 One possibility is to treat any match against these code points as
1532 undefined.  But since Perl doesn't have the concept of a match being
1533 undefined, it converts this to failing or C<FALSE>.  This is almost, but
1534 not quite, what Perl did from v5.14 (when use of these code points
1535 became generally reliable) through v5.18.  The difference is that Perl
1536 treated all C<\p{}> matches as failing, but all C<\P{}> matches as
1537 succeeding.
1538
1539 One problem with this is that it leads to unexpected, and confusing
1540 results in some cases:
1541
1542  chr(0x110000) =~ \p{ASCII_Hex_Digit=True}      # Failed on <= v5.18
1543  chr(0x110000) =~ \p{ASCII_Hex_Digit=False}     # Failed! on <= v5.18
1544
1545 That is, it treated both matches as undefined, and converted that to
1546 false (raising a warning on each).  The first case is the expected
1547 result, but the second is likely counterintuitive: "How could both be
1548 false when they are complements?"  Another problem was that the
1549 implementation optimized many Unicode property matches down to already
1550 existing simpler, faster operations, which don't raise the warning.  We
1551 chose to not forgo those optimizations, which help the vast majority of
1552 matches, just to generate a warning for the unlikely event that an
1553 above-Unicode code point is being matched against.
1554
1555 As a result of these problems, starting in v5.20, what Perl does is
1556 to treat non-Unicode code points as just typical unassigned Unicode
1557 characters, and matches accordingly.  (Note: Unicode has atypical
1558 unassigned code points.  For example, it has noncharacter code points,
1559 and ones that, when they do get assigned, are destined to be written
1560 Right-to-left, as Arabic and Hebrew are.  Perl assumes that no
1561 non-Unicode code point has any atypical properties.)
1562
1563 Perl, in most cases, will raise a warning when matching an above-Unicode
1564 code point against a Unicode property when the result is C<TRUE> for
1565 C<\p{}>, and C<FALSE> for C<\P{}>.  For example:
1566
1567  chr(0x110000) =~ \p{ASCII_Hex_Digit=True}      # Fails, no warning
1568  chr(0x110000) =~ \p{ASCII_Hex_Digit=False}     # Succeeds, with warning
1569
1570 In both these examples, the character being matched is non-Unicode, so
1571 Unicode doesn't define how it should match.  It clearly isn't an ASCII
1572 hex digit, so the first example clearly should fail, and so it does,
1573 with no warning.  But it is arguable that the second example should have
1574 an undefined, hence C<FALSE>, result.  So a warning is raised for it.
1575
1576 Thus the warning is raised for many fewer cases than in earlier Perls,
1577 and only when what the result is could be arguable.  It turns out that
1578 none of the optimizations made by Perl (or are ever likely to be made)
1579 cause the warning to be skipped, so it solves both problems of Perl's
1580 earlier approach.  The most commonly used property that is affected by
1581 this change is C<\p{Unassigned}> which is a short form for
1582 C<\p{General_Category=Unassigned}>.  Starting in v5.20, all non-Unicode
1583 code points are considered C<Unassigned>.  In earlier releases the
1584 matches failed because the result was considered undefined.
1585
1586 The only place where the warning is not raised when it might ought to
1587 have been is if optimizations cause the whole pattern match to not even
1588 be attempted.  For example, Perl may figure out that for a string to
1589 match a certain regular expression pattern, the string has to contain
1590 the substring C<"foobar">.  Before attempting the match, Perl may look
1591 for that substring, and if not found, immediately fail the match without
1592 actually trying it; so no warning gets generated even if the string
1593 contains an above-Unicode code point.
1594
1595 This behavior is more "Do what I mean" than in earlier Perls for most
1596 applications.  But it catches fewer issues for code that needs to be
1597 strictly Unicode compliant.  Therefore there is an additional mode of
1598 operation available to accommodate such code.  This mode is enabled if a
1599 regular expression pattern is compiled within the lexical scope where
1600 the C<"non_unicode"> warning class has been made fatal, say by:
1601
1602  use warnings FATAL => "non_unicode"
1603
1604 (see L<warnings>).  In this mode of operation, Perl will raise the
1605 warning for all matches against a non-Unicode code point (not just the
1606 arguable ones), and it skips the optimizations that might cause the
1607 warning to not be output.  (It currently still won't warn if the match
1608 isn't even attempted, like in the C<"foobar"> example above.)
1609
1610 In summary, Perl now normally treats non-Unicode code points as typical
1611 Unicode unassigned code points for regular expression matches, raising a
1612 warning only when it is arguable what the result should be.  However, if
1613 this warning has been made fatal, it isn't skipped.
1614
1615 There is one exception to all this.  C<\p{All}> looks like a Unicode
1616 property, but it is a Perl extension that is defined to be true for all
1617 possible code points, Unicode or not, so no warning is ever generated
1618 when matching this against a non-Unicode code point.  (Prior to v5.20,
1619 it was an exact synonym for C<\p{Any}>, matching code points C<0>
1620 through C<0x10FFFF>.)
1621
1622 =head2 Security Implications of Unicode
1623
1624 First, read
1625 L<Unicode Security Considerations|http://www.unicode.org/reports/tr36>.
1626
1627 Also, note the following:
1628
1629 =over 4
1630
1631 =item *
1632
1633 Malformed UTF-8
1634
1635 Unfortunately, the original specification of UTF-8 leaves some room for
1636 interpretation of how many bytes of encoded output one should generate
1637 from one input Unicode character.  Strictly speaking, the shortest
1638 possible sequence of UTF-8 bytes should be generated,
1639 because otherwise there is potential for an input buffer overflow at
1640 the receiving end of a UTF-8 connection.  Perl always generates the
1641 shortest length UTF-8, and with warnings on, Perl will warn about
1642 non-shortest length UTF-8 along with other malformations, such as the
1643 surrogates, which are not Unicode code points valid for interchange.
1644
1645 =item *
1646
1647 Regular expression pattern matching may surprise you if you're not
1648 accustomed to Unicode.  Starting in Perl 5.14, several pattern
1649 modifiers are available to control this, called the character set
1650 modifiers.  Details are given in L<perlre/Character set modifiers>.
1651
1652 =back
1653
1654 As discussed elsewhere, Perl has one foot (two hooves?) planted in
1655 each of two worlds: the old world of ASCII and single-byte locales, and
1656 the new world of Unicode, upgrading when necessary.
1657 If your legacy code does not explicitly use Unicode, no automatic
1658 switch-over to Unicode should happen.
1659
1660 =head2 Unicode in Perl on EBCDIC
1661
1662 Unicode is supported on EBCDIC platforms.  See L<perlebcdic>.
1663
1664 Unless ASCII vs. EBCDIC issues are specifically being discussed,
1665 references to UTF-8 encoding in this document and elsewhere should be
1666 read as meaning UTF-EBCDIC on EBCDIC platforms.
1667 See L<perlebcdic/Unicode and UTF>.
1668
1669 Because UTF-EBCDIC is so similar to UTF-8, the differences are mostly
1670 hidden from you; S<C<use utf8>> (and NOT something like
1671 S<C<use utfebcdic>>) declares the the script is in the platform's
1672 "native" 8-bit encoding of Unicode.  (Similarly for the C<":utf8">
1673 layer.)
1674
1675 =head2 Locales
1676
1677 See L<perllocale/Unicode and UTF-8>
1678
1679 =head2 When Unicode Does Not Happen
1680
1681 There are still many places where Unicode (in some encoding or
1682 another) could be given as arguments or received as results, or both in
1683 Perl, but it is not, in spite of Perl having extensive ways to input and
1684 output in Unicode, and a few other "entry points" like the C<@ARGV>
1685 array (which can sometimes be interpreted as UTF-8).
1686
1687 The following are such interfaces.  Also, see L</The "Unicode Bug">.
1688 For all of these interfaces Perl
1689 currently (as of v5.16.0) simply assumes byte strings both as arguments
1690 and results, or UTF-8 strings if the (deprecated) C<encoding> pragma has been used.
1691
1692 One reason that Perl does not attempt to resolve the role of Unicode in
1693 these situations is that the answers are highly dependent on the operating
1694 system and the file system(s).  For example, whether filenames can be
1695 in Unicode and in exactly what kind of encoding, is not exactly a
1696 portable concept.  Similarly for C<qx> and C<system>: how well will the
1697 "command-line interface" (and which of them?) handle Unicode?
1698
1699 =over 4
1700
1701 =item *
1702
1703 C<chdir>, C<chmod>, C<chown>, C<chroot>, C<exec>, C<link>, C<lstat>, C<mkdir>,
1704 C<rename>, C<rmdir>, C<stat>, C<symlink>, C<truncate>, C<unlink>, C<utime>, C<-X>
1705
1706 =item *
1707
1708 C<%ENV>
1709
1710 =item *
1711
1712 C<glob> (aka the C<E<lt>*E<gt>>)
1713
1714 =item *
1715
1716 C<open>, C<opendir>, C<sysopen>
1717
1718 =item *
1719
1720 C<qx> (aka the backtick operator), C<system>
1721
1722 =item *
1723
1724 C<readdir>, C<readlink>
1725
1726 =back
1727
1728 =head2 The "Unicode Bug"
1729
1730 The term, "Unicode bug" has been applied to an inconsistency with the
1731 code points in the C<Latin-1 Supplement> block, that is, between
1732 128 and 255.  Without a locale specified, unlike all other characters or
1733 code points, these characters can have very different semantics
1734 depending on the rules in effect.  (Characters whose code points are
1735 above 255 force Unicode rules; whereas the rules for ASCII characters
1736 are the same under both ASCII and Unicode rules.)
1737
1738 Under Unicode rules, these upper-Latin1 characters are interpreted as
1739 Unicode code points, which means they have the same semantics as Latin-1
1740 (ISO-8859-1) and C1 controls.
1741
1742 As explained in L</ASCII Rules versus Unicode Rules>, under ASCII rules,
1743 they are considered to be unassigned characters.
1744
1745 This can lead to unexpected results.  For example, a string's
1746 semantics can suddenly change if a code point above 255 is appended to
1747 it, which changes the rules from ASCII to Unicode.  As an
1748 example, consider the following program and its output:
1749
1750  $ perl -le'
1751      no feature "unicode_strings";
1752      $s1 = "\xC2";
1753      $s2 = "\x{2660}";
1754      for ($s1, $s2, $s1.$s2) {
1755          print /\w/ || 0;
1756      }
1757  '
1758  0
1759  0
1760  1
1761
1762 If there's no C<\w> in C<s1> nor in C<s2>, why does their concatenation
1763 have one?
1764
1765 This anomaly stems from Perl's attempt to not disturb older programs that
1766 didn't use Unicode, along with Perl's desire to add Unicode support
1767 seamlessly.  But the result turned out to not be seamless.  (By the way,
1768 you can choose to be warned when things like this happen.  See
1769 C<L<encoding::warnings>>.)
1770
1771 L<S<C<use feature 'unicode_strings'>>|feature/The 'unicode_strings' feature>
1772 was added, starting in Perl v5.12, to address this problem.  It affects
1773 these things:
1774
1775 =over 4
1776
1777 =item *
1778
1779 Changing the case of a scalar, that is, using C<uc()>, C<ucfirst()>, C<lc()>,
1780 and C<lcfirst()>, or C<\L>, C<\U>, C<\u> and C<\l> in double-quotish
1781 contexts, such as regular expression substitutions.
1782
1783 Under C<unicode_strings> starting in Perl 5.12.0, Unicode rules are
1784 generally used.  See L<perlfunc/lc> for details on how this works
1785 in combination with various other pragmas.
1786
1787 =item *
1788
1789 Using caseless (C</i>) regular expression matching.
1790
1791 Starting in Perl 5.14.0, regular expressions compiled within
1792 the scope of C<unicode_strings> use Unicode rules
1793 even when executed or compiled into larger
1794 regular expressions outside the scope.
1795
1796 =item *
1797
1798 Matching any of several properties in regular expressions.
1799
1800 These properties are C<\b> (without braces), C<\B> (without braces),
1801 C<\s>, C<\S>, C<\w>, C<\W>, and all the Posix character classes
1802 I<except> C<[[:ascii:]]>.
1803
1804 Starting in Perl 5.14.0, regular expressions compiled within
1805 the scope of C<unicode_strings> use Unicode rules
1806 even when executed or compiled into larger
1807 regular expressions outside the scope.
1808
1809 =item *
1810
1811 In C<quotemeta> or its inline equivalent C<\Q>.
1812
1813 Starting in Perl 5.16.0, consistent quoting rules are used within the
1814 scope of C<unicode_strings>, as described in L<perlfunc/quotemeta>.
1815 Prior to that, or outside its scope, no code points above 127 are quoted
1816 in UTF-8 encoded strings, but in byte encoded strings, code points
1817 between 128-255 are always quoted.
1818
1819 =item *
1820
1821 In the C<..> or L<range|perlop/Range Operators> operator.
1822
1823 Starting in Perl 5.26.0, the range operator on strings treats their lengths
1824 consistently within the scope of C<unicode_strings>. Prior to that, or
1825 outside its scope, it could produce strings whose length in characters
1826 exceeded that of the right-hand side, where the right-hand side took up more
1827 bytes than the correct range endpoint.
1828
1829 =back
1830
1831 You can see from the above that the effect of C<unicode_strings>
1832 increased over several Perl releases.  (And Perl's support for Unicode
1833 continues to improve; it's best to use the latest available release in
1834 order to get the most complete and accurate results possible.)  Note that
1835 C<unicode_strings> is automatically chosen if you S<C<use 5.012>> or
1836 higher.
1837
1838 For Perls earlier than those described above, or when a string is passed
1839 to a function outside the scope of C<unicode_strings>, see the next section.
1840
1841 =head2 Forcing Unicode in Perl (Or Unforcing Unicode in Perl)
1842
1843 Sometimes (see L</"When Unicode Does Not Happen"> or L</The "Unicode Bug">)
1844 there are situations where you simply need to force a byte
1845 string into UTF-8, or vice versa.  The standard module L<Encode> can be
1846 used for this, or the low-level calls
1847 L<C<utf8::upgrade($bytestring)>|utf8/Utility functions> and
1848 L<C<utf8::downgrade($utf8string[, FAIL_OK])>|utf8/Utility functions>.
1849
1850 Note that C<utf8::downgrade()> can fail if the string contains characters
1851 that don't fit into a byte.
1852
1853 Calling either function on a string that already is in the desired state is a
1854 no-op.
1855
1856 L</ASCII Rules versus Unicode Rules> gives all the ways that a string is
1857 made to use Unicode rules.
1858
1859 =head2 Using Unicode in XS
1860
1861 See L<perlguts/"Unicode Support"> for an introduction to Unicode at
1862 the XS level, and L<perlapi/Unicode Support> for the API details.
1863
1864 =head2 Hacking Perl to work on earlier Unicode versions (for very serious hackers only)
1865
1866 Perl by default comes with the latest supported Unicode version built-in, but
1867 the goal is to allow you to change to use any earlier one.  In Perls
1868 v5.20 and v5.22, however, the earliest usable version is Unicode 5.1.
1869 Perl v5.18 and v5.24 are able to handle all earlier versions.
1870
1871 Download the files in the desired version of Unicode from the Unicode web
1872 site L<http://www.unicode.org>).  These should replace the existing files in
1873 F<lib/unicore> in the Perl source tree.  Follow the instructions in
1874 F<README.perl> in that directory to change some of their names, and then build
1875 perl (see L<INSTALL>).
1876
1877 =head2 Porting code from perl-5.6.X
1878
1879 Perls starting in 5.8 have a different Unicode model from 5.6. In 5.6 the
1880 programmer was required to use the C<utf8> pragma to declare that a
1881 given scope expected to deal with Unicode data and had to make sure that
1882 only Unicode data were reaching that scope. If you have code that is
1883 working with 5.6, you will need some of the following adjustments to
1884 your code. The examples are written such that the code will continue to
1885 work under 5.6, so you should be safe to try them out.
1886
1887 =over 3
1888
1889 =item *
1890
1891 A filehandle that should read or write UTF-8
1892
1893   if ($] > 5.008) {
1894     binmode $fh, ":encoding(UTF-8)";
1895   }
1896
1897 =item *
1898
1899 A scalar that is going to be passed to some extension
1900
1901 Be it C<Compress::Zlib>, C<Apache::Request> or any extension that has no
1902 mention of Unicode in the manpage, you need to make sure that the
1903 UTF8 flag is stripped off. Note that at the time of this writing
1904 (January 2012) the mentioned modules are not UTF-8-aware. Please
1905 check the documentation to verify if this is still true.
1906
1907   if ($] > 5.008) {
1908     require Encode;
1909     $val = Encode::encode("UTF-8", $val); # make octets
1910   }
1911
1912 =item *
1913
1914 A scalar we got back from an extension
1915
1916 If you believe the scalar comes back as UTF-8, you will most likely
1917 want the UTF8 flag restored:
1918
1919   if ($] > 5.008) {
1920     require Encode;
1921     $val = Encode::decode("UTF-8", $val);
1922   }
1923
1924 =item *
1925
1926 Same thing, if you are really sure it is UTF-8
1927
1928   if ($] > 5.008) {
1929     require Encode;
1930     Encode::_utf8_on($val);
1931   }
1932
1933 =item *
1934
1935 A wrapper for L<DBI> C<fetchrow_array> and C<fetchrow_hashref>
1936
1937 When the database contains only UTF-8, a wrapper function or method is
1938 a convenient way to replace all your C<fetchrow_array> and
1939 C<fetchrow_hashref> calls. A wrapper function will also make it easier to
1940 adapt to future enhancements in your database driver. Note that at the
1941 time of this writing (January 2012), the DBI has no standardized way
1942 to deal with UTF-8 data. Please check the L<DBI documentation|DBI> to verify if
1943 that is still true.
1944
1945   sub fetchrow {
1946     # $what is one of fetchrow_{array,hashref}
1947     my($self, $sth, $what) = @_;
1948     if ($] < 5.008) {
1949       return $sth->$what;
1950     } else {
1951       require Encode;
1952       if (wantarray) {
1953         my @arr = $sth->$what;
1954         for (@arr) {
1955           defined && /[^\000-\177]/ && Encode::_utf8_on($_);
1956         }
1957         return @arr;
1958       } else {
1959         my $ret = $sth->$what;
1960         if (ref $ret) {
1961           for my $k (keys %$ret) {
1962             defined
1963             && /[^\000-\177]/
1964             && Encode::_utf8_on($_) for $ret->{$k};
1965           }
1966           return $ret;
1967         } else {
1968           defined && /[^\000-\177]/ && Encode::_utf8_on($_) for $ret;
1969           return $ret;
1970         }
1971       }
1972     }
1973   }
1974
1975
1976 =item *
1977
1978 A large scalar that you know can only contain ASCII
1979
1980 Scalars that contain only ASCII and are marked as UTF-8 are sometimes
1981 a drag to your program. If you recognize such a situation, just remove
1982 the UTF8 flag:
1983
1984   utf8::downgrade($val) if $] > 5.008;
1985
1986 =back
1987
1988 =head1 BUGS
1989
1990 See also L</The "Unicode Bug"> above.
1991
1992 =head2 Interaction with Extensions
1993
1994 When Perl exchanges data with an extension, the extension should be
1995 able to understand the UTF8 flag and act accordingly. If the
1996 extension doesn't recognize that flag, it's likely that the extension
1997 will return incorrectly-flagged data.
1998
1999 So if you're working with Unicode data, consult the documentation of
2000 every module you're using if there are any issues with Unicode data
2001 exchange. If the documentation does not talk about Unicode at all,
2002 suspect the worst and probably look at the source to learn how the
2003 module is implemented. Modules written completely in Perl shouldn't
2004 cause problems. Modules that directly or indirectly access code written
2005 in other programming languages are at risk.
2006
2007 For affected functions, the simple strategy to avoid data corruption is
2008 to always make the encoding of the exchanged data explicit. Choose an
2009 encoding that you know the extension can handle. Convert arguments passed
2010 to the extensions to that encoding and convert results back from that
2011 encoding. Write wrapper functions that do the conversions for you, so
2012 you can later change the functions when the extension catches up.
2013
2014 To provide an example, let's say the popular C<Foo::Bar::escape_html>
2015 function doesn't deal with Unicode data yet. The wrapper function
2016 would convert the argument to raw UTF-8 and convert the result back to
2017 Perl's internal representation like so:
2018
2019     sub my_escape_html ($) {
2020         my($what) = shift;
2021         return unless defined $what;
2022         Encode::decode("UTF-8", Foo::Bar::escape_html(
2023                                      Encode::encode("UTF-8", $what)));
2024     }
2025
2026 Sometimes, when the extension does not convert data but just stores
2027 and retrieves it, you will be able to use the otherwise
2028 dangerous L<C<Encode::_utf8_on()>|Encode/_utf8_on> function. Let's say
2029 the popular C<Foo::Bar> extension, written in C, provides a C<param>
2030 method that lets you store and retrieve data according to these prototypes:
2031
2032     $self->param($name, $value);            # set a scalar
2033     $value = $self->param($name);           # retrieve a scalar
2034
2035 If it does not yet provide support for any encoding, one could write a
2036 derived class with such a C<param> method:
2037
2038     sub param {
2039       my($self,$name,$value) = @_;
2040       utf8::upgrade($name);     # make sure it is UTF-8 encoded
2041       if (defined $value) {
2042         utf8::upgrade($value);  # make sure it is UTF-8 encoded
2043         return $self->SUPER::param($name,$value);
2044       } else {
2045         my $ret = $self->SUPER::param($name);
2046         Encode::_utf8_on($ret); # we know, it is UTF-8 encoded
2047         return $ret;
2048       }
2049     }
2050
2051 Some extensions provide filters on data entry/exit points, such as
2052 C<DB_File::filter_store_key> and family. Look out for such filters in
2053 the documentation of your extensions; they can make the transition to
2054 Unicode data much easier.
2055
2056 =head2 Speed
2057
2058 Some functions are slower when working on UTF-8 encoded strings than
2059 on byte encoded strings.  All functions that need to hop over
2060 characters such as C<length()>, C<substr()> or C<index()>, or matching
2061 regular expressions can work B<much> faster when the underlying data are
2062 byte-encoded.
2063
2064 In Perl 5.8.0 the slowness was often quite spectacular; in Perl 5.8.1
2065 a caching scheme was introduced which improved the situation.  In general,
2066 operations with UTF-8 encoded strings are still slower. As an example,
2067 the Unicode properties (character classes) like C<\p{Nd}> are known to
2068 be quite a bit slower (5-20 times) than their simpler counterparts
2069 like C<[0-9]> (then again, there are hundreds of Unicode characters matching
2070 C<Nd> compared with the 10 ASCII characters matching C<[0-9]>).
2071
2072 =head1 SEE ALSO
2073
2074 L<perlunitut>, L<perluniintro>, L<perluniprops>, L<Encode>, L<open>, L<utf8>, L<bytes>,
2075 L<perlretut>, L<perlvar/"${^UNICODE}">,
2076 L<http://www.unicode.org/reports/tr44>).
2077
2078 =cut