This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Integrate #16254 from macperl;
[perl5.git] / t / op / chdir.t
1 #!./perl -w
2
3 BEGIN {
4     # We're not going to chdir() into 't' because we don't know if
5     # chdir() works!  Instead, we'll hedge our bets and put both
6     # possibilities into @INC.
7     @INC = qw(t . lib ../lib);
8 }
9
10 use Config;
11 require "test.pl";
12 plan(tests => 31);
13
14 my $IsVMS   = $^O eq 'VMS';
15 my $IsMacOS = $^O eq 'MacOS';
16
17 # Might be a little early in the testing process to start using these,
18 # but I can't think of a way to write this test without them.
19 use File::Spec::Functions qw(:DEFAULT splitdir rel2abs splitpath);
20
21 # Can't use Cwd::abs_path() because it has different ideas about
22 # path separators than File::Spec.
23 sub abs_path {
24     $IsVMS ? uc(rel2abs(curdir)) : rel2abs(curdir);
25 }
26
27 my $Cwd = abs_path;
28
29 # Let's get to a known position
30 SKIP: {
31     my ($vol,$dir) = splitpath(abs_path,1);
32     my $test_dir = $IsVMS ? 'T' : 't';
33     skip("Already in t/", 2) if (splitdir($dir))[-1] eq $test_dir;
34
35     ok( chdir($test_dir),     'chdir($test_dir)');
36     is( abs_path, catdir($Cwd, $test_dir),    '  abs_path() agrees' );
37 }
38
39 $Cwd = abs_path;
40
41 # The environment variables chdir() pays attention to.
42 my @magic_envs = qw(HOME LOGDIR SYS$LOGIN);
43
44 sub check_env {
45     my($key) = @_;
46
47     # Make sure $ENV{'SYS$LOGIN'} is only honored on VMS.
48     if( $key eq 'SYS$LOGIN' && !$IsVMS && !$IsMacOS ) {
49         ok( !chdir(),         "chdir() on $^O ignores only \$ENV{$key} set" );
50         is( abs_path, $Cwd,   '  abs_path() did not change' );
51         pass( "  no need to test SYS\$LOGIN on $^O" ) for 1..7;
52     }
53     else {
54         ok( chdir(),              "chdir() w/ only \$ENV{$key} set" );
55         is( abs_path, $ENV{$key}, '  abs_path() agrees' );
56         chdir($Cwd);
57         is( abs_path, $Cwd,       '  and back again' );
58
59         my $warning = '';
60         local $SIG{__WARN__} = sub { $warning .= join '', @_ };
61
62
63         # Check the deprecated chdir(undef) feature.
64 #line 64
65         ok( chdir(undef),           "chdir(undef) w/ only \$ENV{$key} set" );
66         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
67         is( $warning,  <<WARNING,   '  got uninit & deprecation warning' );
68 Use of uninitialized value in chdir at $0 line 64.
69 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 64.
70 WARNING
71
72         chdir($Cwd);
73
74         # Ditto chdir('').
75         $warning = '';
76 #line 76
77         ok( chdir(''),              "chdir('') w/ only \$ENV{$key} set" );
78         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
79         is( $warning,  <<WARNING,   '  got deprecation warning' );
80 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 76.
81 WARNING
82
83         chdir($Cwd);
84     }
85 }
86
87 my %Saved_Env = ();
88 sub clean_env {
89     foreach my $env (@magic_envs) {
90         $Saved_Env{$env} = $ENV{$env};
91
92         # Can't actually delete SYS$ stuff on VMS.
93         next if $IsVMS && $env eq 'SYS$LOGIN';
94         next if $IsVMS && $env eq 'HOME' && !$Config{'d_setenv'};
95
96         unless ($IsMacOS) { # ENV on MacOS is "special" :-)
97             # On VMS, %ENV is many layered.
98             delete $ENV{$env} while exists $ENV{$env};
99         }
100     }
101
102     # The following means we won't really be testing for non-existence,
103     # but in Perl we can only delete from the process table, not the job 
104     # table.
105     $ENV{'SYS$LOGIN'} = '' if $IsVMS;
106 }
107
108 END {
109     no warnings 'uninitialized';
110
111     # Restore the environment for VMS (and doesn't hurt for anyone else)
112     @ENV{@magic_envs} = @Saved_Env{@magic_envs};
113 }
114
115
116 foreach my $key (@magic_envs) {
117     # We're going to be using undefs a lot here.
118     no warnings 'uninitialized';
119
120     clean_env;
121     $ENV{$key} = catdir $Cwd, ($IsVMS ? 'OP' : 'op');
122
123     check_env($key);
124 }
125
126 {
127     clean_env;
128     if (($IsVMS || $IsMacOS) && !$Config{'d_setenv'}) {
129         pass("Can't reset HOME, so chdir() test meaningless");
130     } else {
131         ok( !chdir(),                   'chdir() w/o any ENV set' );
132     }
133     is( abs_path, $Cwd,             '  abs_path() agrees' );
134 }