This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Remove commented-out code from regen/opcode.pl
[perl5.git] / regen / opcode.pl
1 #!/usr/bin/perl -w
2
3 # Regenerate (overwriting only if changed):
4 #
5 #    opcode.h
6 #    opnames.h
7 #    pp_proto.h
8 #
9 # from information stored in regen/opcodes, plus the
10 # values hardcoded into this script in @raw_alias.
11 #
12 # Accepts the standard regen_lib -q and -v args.
13 #
14 # This script is normally invoked from regen.pl.
15
16 use strict;
17
18 BEGIN {
19     # Get function prototypes
20     require 'regen/regen_lib.pl';
21 }
22
23 my $opcode_new = 'opcode.h-new';
24 my $opname_new = 'opnames.h-new';
25 my $oc = safer_open($opcode_new);
26 my $on = safer_open($opname_new);
27 select $oc;
28
29 # Read data.
30
31 my %seen;
32 my (@ops, %desc, %check, %ckname, %flags, %args, %opnum);
33
34 open OPS, 'regen/opcodes' or die $!;
35
36 while (<OPS>) {
37     chop;
38     next unless $_;
39     next if /^#/;
40     my ($key, $desc, $check, $flags, $args) = split(/\t+/, $_, 5);
41     $args = '' unless defined $args;
42
43     warn qq[Description "$desc" duplicates $seen{$desc}\n]
44      if $seen{$desc} and $key ne "transr";
45     die qq[Opcode "$key" duplicates $seen{$key}\n] if $seen{$key};
46     $seen{$desc} = qq[description of opcode "$key"];
47     $seen{$key} = qq[opcode "$key"];
48
49     push(@ops, $key);
50     $opnum{$key} = $#ops;
51     $desc{$key} = $desc;
52     $check{$key} = $check;
53     $ckname{$check}++;
54     $flags{$key} = $flags;
55     $args{$key} = $args;
56 }
57
58 # Set up aliases
59
60 my %alias;
61
62 # Format is "this function" => "does these op names"
63 my @raw_alias = (
64                  Perl_do_kv => [qw( keys values )],
65                  Perl_unimplemented_op => [qw(padany mapstart custom)],
66                  # All the ops with a body of { return NORMAL; }
67                  Perl_pp_null => [qw(scalar regcmaybe lineseq scope)],
68
69                  Perl_pp_goto => ['dump'],
70                  Perl_pp_require => ['dofile'],
71                  Perl_pp_untie => ['dbmclose'],
72                  Perl_pp_sysread => [qw(read recv)],
73                  Perl_pp_sysseek => ['seek'],
74                  Perl_pp_ioctl => ['fcntl'],
75                  Perl_pp_ssockopt => ['gsockopt'],
76                  Perl_pp_getpeername => ['getsockname'],
77                  Perl_pp_stat => ['lstat'],
78                  Perl_pp_ftrowned => [qw(fteowned ftzero ftsock ftchr ftblk
79                                          ftfile ftdir ftpipe ftsuid ftsgid
80                                          ftsvtx)],
81                  Perl_pp_fttext => ['ftbinary'],
82                  Perl_pp_gmtime => ['localtime'],
83                  Perl_pp_semget => [qw(shmget msgget)],
84                  Perl_pp_semctl => [qw(shmctl msgctl)],
85                  Perl_pp_ghostent => [qw(ghbyname ghbyaddr)],
86                  Perl_pp_gnetent => [qw(gnbyname gnbyaddr)],
87                  Perl_pp_gprotoent => [qw(gpbyname gpbynumber)],
88                  Perl_pp_gservent => [qw(gsbyname gsbyport)],
89                  Perl_pp_gpwent => [qw(gpwnam gpwuid)],
90                  Perl_pp_ggrent => [qw(ggrnam ggrgid)],
91                  Perl_pp_ftis => [qw(ftsize ftmtime ftatime ftctime)],
92                  Perl_pp_chown => [qw(unlink chmod utime kill)],
93                  Perl_pp_link => ['symlink'],
94                  Perl_pp_ftrread => [qw(ftrwrite ftrexec fteread ftewrite
95                                         fteexec)],
96                  Perl_pp_shmwrite => [qw(shmread msgsnd msgrcv semop)],
97                  Perl_pp_send => ['syswrite'],
98                  Perl_pp_defined => [qw(dor dorassign)],
99                  Perl_pp_and => ['andassign'],
100                  Perl_pp_or => ['orassign'],
101                  Perl_pp_ucfirst => ['lcfirst'],
102                  Perl_pp_sle => [qw(slt sgt sge)],
103                  Perl_pp_print => ['say'],
104                  Perl_pp_index => ['rindex'],
105                  Perl_pp_oct => ['hex'],
106                  Perl_pp_shift => ['pop'],
107                  Perl_pp_sin => [qw(cos exp log sqrt)],
108                  Perl_pp_bit_or => ['bit_xor'],
109                  Perl_pp_rv2av => ['rv2hv'],
110                  Perl_pp_akeys => ['avalues'],
111                  Perl_pp_rkeys => [qw(rvalues reach)],
112                  Perl_pp_trans => ['transr'],
113                  Perl_pp_chop => ['chomp'],
114                  Perl_pp_schop => ['schomp'],
115                  Perl_pp_bind => ['connect'],
116                  Perl_pp_preinc => ['i_preinc'],
117                  Perl_pp_predec => ['i_predec'],
118                  Perl_pp_postinc => ['i_postinc'],
119                  Perl_pp_postdec => ['i_postdec'],
120                 );
121
122 while (my ($func, $names) = splice @raw_alias, 0, 2) {
123     foreach (@$names) {
124         $alias{$_} = $func;
125     }
126 }
127
128 # Emit defines.
129
130 print <<"END";
131 /* -*- buffer-read-only: t -*-
132  *
133  *    opcode.h
134  *
135  *    Copyright (C) 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
136  *    2001, 2002, 2003, 2004, 2005, 2006, 2007 by Larry Wall and others
137  *
138  *    You may distribute under the terms of either the GNU General Public
139  *    License or the Artistic License, as specified in the README file.
140  *
141  * !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
142  *  This file is built by regen/opcode.pl from its data.  Any changes made
143  *  here will be lost!
144  */
145
146 #ifndef PERL_GLOBAL_STRUCT_INIT
147
148 END
149
150 for (@ops) {
151     print "#define Perl_pp_$_ $alias{$_}\n" if $alias{$_};
152 }
153
154 print $on <<"END";
155 /* -*- buffer-read-only: t -*-
156  *
157  *    opnames.h
158  *
159  *    Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
160  *    2007, 2008 by Larry Wall and others
161  *
162  *    You may distribute under the terms of either the GNU General Public
163  *    License or the Artistic License, as specified in the README file.
164  *
165  *
166  * !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
167  *  This file is built by regen/opcode.pl from its data.  Any changes made
168  *  here will be lost!
169  */
170
171 typedef enum opcode {
172 END
173
174 my $i = 0;
175 for (@ops) {
176       print $on "\t", &tab(3,"OP_\U$_"), " = ", $i++, ",\n";
177 }
178 print $on "\t", &tab(3,"OP_max"), "\n";
179 print $on "} opcode;\n";
180 print $on "\n#define MAXO ", scalar @ops, "\n";
181
182 # Emit op names and descriptions.
183
184 print <<END;
185 START_EXTERN_C
186
187 #ifndef DOINIT
188 EXTCONST char* const PL_op_name[];
189 #else
190 EXTCONST char* const PL_op_name[] = {
191 END
192
193 for (@ops) {
194     print qq(\t"$_",\n);
195 }
196
197 print <<END;
198 };
199 #endif
200
201 END
202
203 print <<END;
204 #ifndef DOINIT
205 EXTCONST char* const PL_op_desc[];
206 #else
207 EXTCONST char* const PL_op_desc[] = {
208 END
209
210 for (@ops) {
211     my($safe_desc) = $desc{$_};
212
213     # Have to escape double quotes and escape characters.
214     $safe_desc =~ s/([\\"])/\\$1/g;
215
216     print qq(\t"$safe_desc",\n);
217 }
218
219 print <<END;
220 };
221 #endif
222
223 END_EXTERN_C
224
225 #endif /* !PERL_GLOBAL_STRUCT_INIT */
226 END
227
228 # Emit ppcode switch array.
229
230 print <<END;
231
232 START_EXTERN_C
233
234 #ifdef PERL_GLOBAL_STRUCT_INIT
235 #  define PERL_PPADDR_INITED
236 static const Perl_ppaddr_t Gppaddr[]
237 #else
238 #  ifndef PERL_GLOBAL_STRUCT
239 #    define PERL_PPADDR_INITED
240 EXT Perl_ppaddr_t PL_ppaddr[] /* or perlvars.h */
241 #  endif
242 #endif /* PERL_GLOBAL_STRUCT */
243 #if (defined(DOINIT) && !defined(PERL_GLOBAL_STRUCT)) || defined(PERL_GLOBAL_STRUCT_INIT)
244 #  define PERL_PPADDR_INITED
245 = {
246 END
247
248 for (@ops) {
249     if (my $name = $alias{$_}) {
250         print "\t$name,\t/* Perl_pp_$_ */\n";
251     }
252     else {
253         print "\tPerl_pp_$_,\n";
254     }
255 }
256
257 print <<END;
258 }
259 #endif
260 #ifdef PERL_PPADDR_INITED
261 ;
262 #endif
263
264 END
265
266 # Emit check routines.
267
268 print <<END;
269 #ifdef PERL_GLOBAL_STRUCT_INIT
270 #  define PERL_CHECK_INITED
271 static const Perl_check_t Gcheck[]
272 #else
273 #  ifndef PERL_GLOBAL_STRUCT
274 #    define PERL_CHECK_INITED
275 EXT Perl_check_t PL_check[] /* or perlvars.h */
276 #  endif
277 #endif
278 #if (defined(DOINIT) && !defined(PERL_GLOBAL_STRUCT)) || defined(PERL_GLOBAL_STRUCT_INIT)
279 #  define PERL_CHECK_INITED
280 = {
281 END
282
283 for (@ops) {
284     print "\t", &tab(3, "Perl_$check{$_},"), "\t/* $_ */\n";
285 }
286
287 print <<END;
288 }
289 #endif
290 #ifdef PERL_CHECK_INITED
291 ;
292 #endif /* #ifdef PERL_CHECK_INITED */
293
294 END
295
296 # Emit allowed argument types.
297
298 my $ARGBITS = 32;
299
300 print <<END;
301 #ifndef PERL_GLOBAL_STRUCT_INIT
302
303 #ifndef DOINIT
304 EXTCONST U32 PL_opargs[];
305 #else
306 EXTCONST U32 PL_opargs[] = {
307 END
308
309 my %argnum = (
310     'S',  1,            # scalar
311     'L',  2,            # list
312     'A',  3,            # array value
313     'H',  4,            # hash value
314     'C',  5,            # code value
315     'F',  6,            # file value
316     'R',  7,            # scalar reference
317 );
318
319 my %opclass = (
320     '0',  0,            # baseop
321     '1',  1,            # unop
322     '2',  2,            # binop
323     '|',  3,            # logop
324     '@',  4,            # listop
325     '/',  5,            # pmop
326     '$',  6,            # svop_or_padop
327     '#',  7,            # padop
328     '"',  8,            # pvop_or_svop
329     '{',  9,            # loop
330     ';',  10,           # cop
331     '%',  11,           # baseop_or_unop
332     '-',  12,           # filestatop
333     '}',  13,           # loopexop
334 );
335
336 my %opflags = (
337     'm' =>   1,         # needs stack mark
338     'f' =>   2,         # fold constants
339     's' =>   4,         # always produces scalar
340     't' =>   8,         # needs target scalar
341     'T' =>   8 | 16,    # ... which may be lexical
342     'i' =>   0,         # always produces integer (unused since e7311069)
343     'I' =>  32,         # has corresponding int op
344     'd' =>  64,         # danger, unknown side effects
345     'u' => 128,         # defaults to $_
346 );
347
348 my %OP_IS_SOCKET;
349 my %OP_IS_FILETEST;
350 my %OP_IS_FT_ACCESS;
351 my $OCSHIFT = 8;
352 my $OASHIFT = 12;
353
354 for my $op (@ops) {
355     my $argsum = 0;
356     my $flags = $flags{$op};
357     for my $flag (keys %opflags) {
358         if ($flags =~ s/$flag//) {
359             die "Flag collision for '$op' ($flags{$op}, $flag)\n"
360                 if $argsum & $opflags{$flag};
361             $argsum |= $opflags{$flag};
362         }
363     }
364     die qq[Opcode '$op' has no class indicator ($flags{$op} => $flags)\n]
365         unless exists $opclass{$flags};
366     $argsum |= $opclass{$flags} << $OCSHIFT;
367     my $argshift = $OASHIFT;
368     for my $arg (split(' ',$args{$op})) {
369         if ($arg =~ /^F/) {
370             # record opnums of these opnames
371             $OP_IS_SOCKET{$op}   = $opnum{$op} if $arg =~ s/s//;
372             $OP_IS_FILETEST{$op} = $opnum{$op} if $arg =~ s/-//;
373             $OP_IS_FT_ACCESS{$op} = $opnum{$op} if $arg =~ s/\+//;
374         }
375         my $argnum = ($arg =~ s/\?//) ? 8 : 0;
376         die "op = $op, arg = $arg\n"
377             unless exists $argnum{$arg};
378         $argnum += $argnum{$arg};
379         die "Argument overflow for '$op'\n"
380             if $argshift >= $ARGBITS ||
381                $argnum > ((1 << ($ARGBITS - $argshift)) - 1);
382         $argsum += $argnum << $argshift;
383         $argshift += 4;
384     }
385     $argsum = sprintf("0x%08x", $argsum);
386     print "\t", &tab(3, "$argsum,"), "/* $op */\n";
387 }
388
389 print <<END;
390 };
391 #endif
392
393 #endif /* !PERL_GLOBAL_STRUCT_INIT */
394
395 END_EXTERN_C
396
397 END
398
399 # Emit OP_IS_* macros
400
401 print $on <<EO_OP_IS_COMMENT;
402
403 /* the OP_IS_(SOCKET|FILETEST) macros are optimized to a simple range
404     check because all the member OPs are contiguous in opcode.pl
405     <OPS> table.  opcode.pl verifies the range contiguity.  */
406
407 EO_OP_IS_COMMENT
408
409 gen_op_is_macro( \%OP_IS_SOCKET, 'OP_IS_SOCKET');
410 gen_op_is_macro( \%OP_IS_FILETEST, 'OP_IS_FILETEST');
411 gen_op_is_macro( \%OP_IS_FT_ACCESS, 'OP_IS_FILETEST_ACCESS');
412
413 sub gen_op_is_macro {
414     my ($op_is, $macname) = @_;
415     if (keys %$op_is) {
416         
417         # get opnames whose numbers are lowest and highest
418         my ($first, @rest) = sort {
419             $op_is->{$a} <=> $op_is->{$b}
420         } keys %$op_is;
421         
422         my $last = pop @rest;   # @rest slurped, get its last
423         die "Invalid range of ops: $first .. $last\n" unless $last;
424
425         print $on "#define $macname(op) \\\n\t(";
426
427         # verify that op-ct matches 1st..last range (and fencepost)
428         # (we know there are no dups)
429         if ( $op_is->{$last} - $op_is->{$first} == scalar @rest + 1) {
430             
431             # contiguous ops -> optimized version
432             print $on "(op) >= OP_" . uc($first) . " && (op) <= OP_" . uc($last);
433             print $on ")\n\n";
434         }
435         else {
436             print $on join(" || \\\n\t ",
437                           map { "(op) == OP_" . uc() } sort keys %$op_is);
438             print $on ")\n\n";
439         }
440     }
441 }
442
443 print $oc "/* ex: set ro: */\n";
444 print $on "/* ex: set ro: */\n";
445
446 safer_close($oc);
447 safer_close($on);
448
449 rename_if_different $opcode_new, 'opcode.h';
450 rename_if_different $opname_new, 'opnames.h';
451
452 my $pp_proto_new = 'pp_proto.h-new';
453
454 my $pp = safer_open($pp_proto_new);
455
456 print $pp <<"END";
457 /* -*- buffer-read-only: t -*-
458    !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
459    This file is built by opcode.pl from its data.  Any changes made here
460    will be lost!
461 */
462
463 END
464
465 {
466     my %funcs;
467     for (@ops) {
468         my $name = $alias{$_} || "Perl_pp_$_";
469         ++$funcs{$name};
470     }
471     print $pp "PERL_CALLCONV OP *$_(pTHX);\n" foreach sort keys %funcs;
472 }
473 print $pp "\n/* ex: set ro: */\n";
474
475 safer_close($pp);
476
477 rename_if_different $pp_proto_new, 'pp_proto.h';
478
479 END {
480   foreach ('opcode.h', 'opnames.h', 'pp_proto.h') {
481     1 while unlink "$_-old";
482   }
483 }
484
485 ###########################################################################
486 sub tab {
487     my ($l, $t) = @_;
488     $t .= "\t" x ($l - (length($t) + 1) / 8);
489     $t;
490 }
491 ###########################################################################
492
493 # Some comments about 'T' opcode classifier:
494
495 # Safe to set if the ppcode uses:
496 #       tryAMAGICbin, tryAMAGICun, SETn, SETi, SETu, PUSHn, PUSHTARG, SETTARG,
497 #       SETs(TARG), XPUSHn, XPUSHu,
498
499 # Unsafe to set if the ppcode uses dTARG or [X]RETPUSH[YES|NO|UNDEF]
500
501 # lt and friends do SETs (including ncmp, but not scmp)
502
503 # Additional mode of failure: the opcode can modify TARG before it "used"
504 # all the arguments (or may call an external function which does the same).
505 # If the target coincides with one of the arguments ==> kaboom.
506
507 # pp.c  pos substr each not OK (RETPUSHUNDEF)
508 #       substr vec also not OK due to LV to target (are they???)
509 #       ref not OK (RETPUSHNO)
510 #       trans not OK (dTARG; TARG = sv_newmortal();)
511 #       ucfirst etc not OK: TMP arg processed inplace
512 #       quotemeta not OK (unsafe when TARG == arg)
513 #       each repeat not OK too due to list context
514 #       pack split - unknown whether they are safe
515 #       sprintf: is calling do_sprintf(TARG,...) which can act on TARG
516 #         before other args are processed.
517
518 #       Suspicious wrt "additional mode of failure" (and only it):
519 #       schop, chop, postinc/dec, bit_and etc, negate, complement.
520
521 #       Also suspicious: 4-arg substr, sprintf, uc/lc (POK_only), reverse, pack.
522
523 #       substr/vec: doing TAINT_off()???
524
525 # pp_hot.c
526 #       readline - unknown whether it is safe
527 #       match subst not OK (dTARG)
528 #       grepwhile not OK (not always setting)
529 #       join not OK (unsafe when TARG == arg)
530
531 #       Suspicious wrt "additional mode of failure": concat (dealt with
532 #       in ck_sassign()), join (same).
533
534 # pp_ctl.c
535 #       mapwhile flip caller not OK (not always setting)
536
537 # pp_sys.c
538 #       backtick glob warn die not OK (not always setting)
539 #       warn not OK (RETPUSHYES)
540 #       open fileno getc sysread syswrite ioctl accept shutdown
541 #        ftsize(etc) readlink telldir fork alarm getlogin not OK (RETPUSHUNDEF)
542 #       umask select not OK (XPUSHs(&PL_sv_undef);)
543 #       fileno getc sysread syswrite tell not OK (meth("FILENO" "GETC"))
544 #       sselect shm* sem* msg* syscall - unknown whether they are safe
545 #       gmtime not OK (list context)
546
547 #       Suspicious wrt "additional mode of failure": warn, die, select.