This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
In TestInit, inline new_inc() and set_opt() into import(), their only caller.
[perl5.git] / TestInit.pm
1 # This is a replacement for the old BEGIN preamble which heads (or
2 # should head) up every core test program to prepare it for running.
3 # Now instead of:
4 #
5 # BEGIN {
6 #   chdir 't' if -d 't';
7 #   @INC = '../lib';
8 # }
9 #
10 # Its primary purpose is to clear @INC so core tests don't pick up
11 # modules from an installed Perl.
12 #
13 # t/TEST will use -MTestInit.  You may "use TestInit" in the test
14 # programs but it is not required.
15 #
16 # P.S. This documentation is not in POD format in order to avoid
17 # problems when there are fundamental bugs in perl.
18
19 package TestInit;
20
21 $VERSION = 1.04;
22
23 # Let tests know they're running in the perl core.  Useful for modules
24 # which live dual lives on CPAN.
25 # Don't interfere with the taintedness of %ENV, this could perturbate tests.
26 # This feels like a better solution than the original, from
27 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2003-07/msg00154.html
28 $ENV{PERL_CORE} = $^X;
29
30 sub import {
31     my $self = shift;
32     my @up_2_t = ('../../lib', '../../t');
33     my @new_inc;
34     my ($abs, $chdir, $setopt);
35     foreach (@_) {
36         if ($_ eq 'U2T') {
37             @new_inc = @up_2_t;
38             $setopt = 1;
39         } elsif ($_ eq 'U1') {
40             @new_inc = '../lib';
41             $setopt = 1;
42         } elsif ($_ eq 'NC') {
43             delete $ENV{PERL_CORE}
44         } elsif ($_ eq 'A') {
45             $abs = 1;
46         } elsif ($_ eq 'T') {
47             $chdir = '..'
48                 unless -f 't/TEST' && -f 'MANIFEST' && -d 'lib' && -d 'ext';
49             @new_inc = 'lib';
50             $setopt = 1;
51         } else {
52             die "Unknown option '$_'";
53         }
54     }
55
56     # Need to default. This behaviour is consistent with previous behaviour,
57     # as the equivalent of this code used to be run at the top level, hence
58     # would happen (unconditionally) before import() was called.
59     unless (@new_inc) {
60         if (-f 't/TEST' && -f 'MANIFEST' && -d 'lib' && -d 'ext') {
61             # We're being run from the top level. Try to change directory, and
62             # set things up correctly. This is a 90% solution, but for
63             # hand-running tests, that's good enough
64             if ($0 =~ s!^((?:ext|dist|cpan)[\\/][^\\/]+)[\//](.*\.t)$!$2!) {
65                 # Looks like a test in ext.
66                 $chdir = $1;
67                 @new_inc = @up_2_t;
68                 $setopt = 1;
69                 $^X =~ s!^\.([/\\])!..$1..$1!;
70             } else {
71                 $chdir = 't';
72                 @new_inc = '../lib';
73                 $setopt = $0 =~ m!^lib/!;
74             }
75         } else {
76             # (likely) we're being run by t/TEST or t/harness, and we're a test
77             # in t/
78             @new_inc = '../lib';
79         }
80     }
81
82     if (defined $chdir) {
83         chdir $chdir or die "Can't chdir '$chdir': $!";
84     }
85
86     if ($abs) {
87         @INC = @new_inc;
88         require File::Spec::Functions;
89         # Forcibly untaint this.
90         @new_inc = map { $_ = File::Spec::Functions::rel2abs($_); /(.*)/; $1 }
91             @new_inc;
92         $^X = File::Spec::Functions::rel2abs($^X);
93     }
94
95     @INC = @new_inc;
96     push @INC, '.' unless ${^TAINT};
97
98     if ($setopt) {
99         my $sep;
100         if ($^O eq 'VMS') {
101             $sep = '|';
102         } elsif ($^O eq 'MSWin32') {
103             $sep = ';';
104         } else {
105             $sep = ':';
106         }
107
108         my $lib = join $sep, @new_inc;
109         if (exists $ENV{PERL5LIB}) {
110             $ENV{PERL5LIB} = $lib . substr $ENV{PERL5LIB}, 0, 0;
111         } else {
112             $ENV{PERL5LIB} = $lib;
113         }
114     }
115 }
116
117 $0 =~ s/\.dp$//; # for the test.deparse make target
118 1;