This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
db31f443d4b676fec28fd1882acd2a0acb2956b9
[perl5.git] / t / porting / extrefs.t
1 #!./perl -w
2
3 # What does this test?
4 # Test that changes to perl header files don't cause external
5 # references by simplying #including them.  This breaks library probe
6 # code on CPAN, and can break cflags.SH.
7 #
8 # Why do we test this?
9 # See https://rt.perl.org/rt3/Ticket/Display.html?id=116989
10 #
11 # It's broken - how do I fix it?
12 # You added an initializer or static function to a header file that
13 # references some symbol you didn't define, you need to remove it.
14
15 BEGIN {
16   require "./test.pl";
17   unshift @INC, ".." if -f "../TestInit.pm";
18 }
19
20 use TestInit qw(T A); # T is chdir to the top level, A makes paths absolute
21 use strict;
22 use warnings;
23 use Config;
24 use File::Path 'rmtree';
25 use Cwd;
26
27 plan(tests => 1);
28
29 ok(try_compile_and_link(<<'CODE'));
30 #include "EXTERN.h"
31 #include "perl.h"
32 #include "XSUB.h"
33
34 int main(int argc, char **argv) {
35   return 0;
36 }
37 CODE
38
39
40 # from Time::HiRes's Makefile.PL with minor modifications
41 sub try_compile_and_link {
42     my ($c, %args) = @_;
43
44     my $ld_exeext = ($^O eq 'cygwin' || $^O eq 'MSWin32' ||
45                  $^O eq 'os2' && $Config{ldflags} =~ /-Zexe\b/) ? '.exe' :
46                 (($^O eq 'vos') ? $Config{exe_ext} : '');
47     my $VERBOSE = 0;
48
49     my ($ok) = 0;
50     my $tempdir = tempfile();
51     my $cwd = getcwd();
52     mkdir $tempdir;
53     chdir $tempdir;
54     my ($tmp) = "temp";
55
56     my $obj_ext = $Config{obj_ext} || ".o";
57
58     if (open(my $tmpc, ">$tmp.c")) {
59         print $tmpc $c;
60         unless (close($tmpc)) {
61             chdir($cwd);
62             rmtree($tempdir);
63             warn "Failing closing code file: $!\n" if $VERBOSE;
64             return 0;
65         }
66
67         my $COREincdir = File::Spec->catdir(File::Spec->updir);
68
69         my $ccflags = $Config{'ccflags'} . ' ' . "-I$COREincdir"
70          . ' -DPERL_NO_INLINE_FUNCTIONS';
71
72         if ($^O eq "MSWin32") {
73             $ccflags .= " -I../win32 -I../win32/include";
74         }
75
76         my $null = File::Spec->devnull;
77
78         my $errornull = $VERBOSE ? '' : ">$null 2>$null";
79
80         my $out_opt = "-o";
81         if ($^O eq "MSWin32" && $Config{cc} =~ /\bcl\b/i) {
82             $out_opt = "/Fe";
83         }
84
85         my $tmp_exe = "$tmp$ld_exeext";
86
87         my $cccmd = "$Config{'cc'} $out_opt$tmp_exe $ccflags $tmp.c $errornull";
88
89         if ($^O eq 'VMS') {
90             $cccmd = "$Config{'cc'} /include=($COREincdir) $tmp.c";
91         }
92
93        if ($^O eq 'VMS') {
94             open( my $cmdfile, ">$tmp.com" );
95             print $cmdfile "\$ SET MESSAGE/NOFACILITY/NOSEVERITY/NOIDENT/NOTEXT\n";
96             print $cmdfile "\$ $cccmd\n";
97             print $cmdfile "\$ IF \$SEVERITY .NE. 1 THEN EXIT 44\n"; # escalate
98             close $cmdfile;
99             system("\@ $tmp.com");
100             $ok = $?==0;
101             chdir($cwd);
102             rmtree($tempdir);
103         }
104         else
105         {
106             printf "cccmd = $cccmd\n" if $VERBOSE;
107             my $res = system($cccmd);
108             $ok = defined($res) && $res == 0 && -s $tmp_exe && -x _;
109
110             chdir($cwd);
111             rmtree($tempdir);
112         }
113     }
114
115     return $ok;
116 }