This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
regen/embed.pl: Don't: #define FOO FOO
[perl5.git] / regen / embed.pl
1 #!/usr/bin/perl -w
2
3 # Regenerate (overwriting only if changed):
4 #
5 #    embed.h
6 #    embedvar.h
7 #    perlapi.c
8 #    perlapi.h
9 #    proto.h
10 #
11 # from information stored in
12 #
13 #    embed.fnc
14 #    intrpvar.h
15 #    perlvars.h
16 #    regen/opcodes
17 #
18 # Accepts the standard regen_lib -q and -v args.
19 #
20 # This script is normally invoked from regen.pl.
21
22 require 5.004;  # keep this compatible, an old perl is all we may have before
23                 # we build the new one
24
25 use strict;
26
27 BEGIN {
28     # Get function prototypes
29     require 'regen/regen_lib.pl';
30     require 'regen/embed_lib.pl';
31 }
32
33 my $SPLINT = 0; # Turn true for experimental splint support http://www.splint.org
34 my $unflagged_pointers;
35
36 #
37 # See database of global and static function prototypes in embed.fnc
38 # This is used to generate prototype headers under various configurations,
39 # export symbols lists for different platforms, and macros to provide an
40 # implicit interpreter context argument.
41 #
42
43 sub full_name ($$) { # Returns the function name with potentially the
44                      # prefixes 'S_' or 'Perl_'
45     my ($func, $flags) = @_;
46
47     return "S_$func" if $flags =~ /[si]/;
48     return "Perl_$func" if $flags =~ /p/;
49     return $func;
50 }
51
52 sub open_print_header {
53     my ($file, $quote) = @_;
54
55     return open_new($file, '>',
56                     { file => $file, style => '*', by => 'regen/embed.pl',
57                       from => ['data in embed.fnc', 'regen/embed.pl',
58                                'regen/opcodes', 'intrpvar.h', 'perlvars.h'],
59                       final => "\nEdit those files and run 'make regen_headers' to effect changes.\n",
60                       copyright => [1993 .. 2009], quote => $quote });
61 }
62
63 my ($embed, $core, $ext, $api) = setup_embed();
64
65 # generate proto.h
66 {
67     my $pr = open_print_header("proto.h");
68     print $pr "START_EXTERN_C\n";
69     my $ret;
70
71     foreach (@$embed) {
72         if (@$_ == 1) {
73             print $pr "$_->[0]\n";
74             next;
75         }
76
77         my ($flags,$retval,$plain_func,@args) = @$_;
78         if ($flags =~ / ( [^AabDdEfiMmnOoPpRrsUXx] ) /x) {
79             warn "flag $1 is not legal (for function $plain_func)";
80         }
81         my @nonnull;
82         my $has_context = ( $flags !~ /n/ );
83         my $never_returns = ( $flags =~ /r/ );
84         my $commented_out = ( $flags =~ /m/ );
85         my $binarycompat = ( $flags =~ /b/ );
86         my $is_malloc = ( $flags =~ /a/ );
87         my $can_ignore = ( $flags !~ /R/ ) && !$is_malloc;
88         my @names_of_nn;
89         my $func;
90
91         if (! $can_ignore && $retval eq 'void') {
92             warn "It is nonsensical to require the return value of a void function ($plain_func) to be checked";
93         }
94
95         my $scope_type_flag_count = 0;
96         $scope_type_flag_count++ if $flags =~ /s/;
97         $scope_type_flag_count++ if $flags =~ /i/;
98         $scope_type_flag_count++ if $flags =~ /p/;
99         warn "$plain_func: i, p, and s flags are all mutually exclusive"
100                                                    if $scope_type_flag_count > 1;
101         my $splint_flags = "";
102         if ( $SPLINT && !$commented_out ) {
103             $splint_flags .= '/*@noreturn@*/ ' if $never_returns;
104             if ($can_ignore && ($retval ne 'void') && ($retval !~ /\*/)) {
105                 $retval .= " /*\@alt void\@*/";
106             }
107         }
108
109         if ($flags =~ /([si])/) {
110             my $type;
111             if ($never_returns) {
112                 $type = $1 eq 's' ? "PERL_STATIC_NO_RET" : "PERL_STATIC_INLINE_NO_RET";
113             }
114             else {
115                 $type = $1 eq 's' ? "STATIC" : "PERL_STATIC_INLINE";
116             }
117             $retval = "$type $splint_flags$retval";
118         }
119         else {
120             if ($never_returns) {
121                 $retval = "PERL_CALLCONV_NO_RET $splint_flags$retval";
122             }
123             else {
124                 $retval = "PERL_CALLCONV $splint_flags$retval";
125             }
126         }
127         $func = full_name($plain_func, $flags);
128         $ret = "$retval\t$func(";
129         if ( $has_context ) {
130             $ret .= @args ? "pTHX_ " : "pTHX";
131         }
132         if (@args) {
133             my $n;
134             for my $arg ( @args ) {
135                 ++$n;
136                 if ( $arg =~ /\*/ && $arg !~ /\b(NN|NULLOK)\b/ ) {
137                     warn "$func: $arg needs NN or NULLOK\n";
138                     ++$unflagged_pointers;
139                 }
140                 my $nn = ( $arg =~ s/\s*\bNN\b\s+// );
141                 push( @nonnull, $n ) if $nn;
142
143                 my $nullok = ( $arg =~ s/\s*\bNULLOK\b\s+// ); # strip NULLOK with no effect
144
145                 # Make sure each arg has at least a type and a var name.
146                 # An arg of "int" is valid C, but want it to be "int foo".
147                 my $temp_arg = $arg;
148                 $temp_arg =~ s/\*//g;
149                 $temp_arg =~ s/\s*\bstruct\b\s*/ /g;
150                 if ( ($temp_arg ne "...")
151                      && ($temp_arg !~ /\w+\s+(\w+)(?:\[\d+\])?\s*$/) ) {
152                     warn "$func: $arg ($n) doesn't have a name\n";
153                 }
154                 if ( $SPLINT && $nullok && !$commented_out ) {
155                     $arg = '/*@null@*/ ' . $arg;
156                 }
157                 if (defined $1 && $nn && !($commented_out && !$binarycompat)) {
158                     push @names_of_nn, $1;
159                 }
160             }
161             $ret .= join ", ", @args;
162         }
163         else {
164             $ret .= "void" if !$has_context;
165         }
166         $ret .= ")";
167         my @attrs;
168         if ( $flags =~ /r/ ) {
169             push @attrs, "__attribute__noreturn__";
170         }
171         if ( $flags =~ /D/ ) {
172             push @attrs, "__attribute__deprecated__";
173         }
174         if ( $is_malloc ) {
175             push @attrs, "__attribute__malloc__";
176         }
177         if ( !$can_ignore ) {
178             push @attrs, "__attribute__warn_unused_result__";
179         }
180         if ( $flags =~ /P/ ) {
181             push @attrs, "__attribute__pure__";
182         }
183         if( $flags =~ /f/ ) {
184             my $prefix  = $has_context ? 'pTHX_' : '';
185             my ($args, $pat);
186             if ($args[-1] eq '...') {
187                 $args   = scalar @args;
188                 $pat    = $args - 1;
189                 $args   = $prefix . $args;
190             }
191             else {
192                 # don't check args, and guess which arg is the pattern
193                 # (one of 'fmt', 'pat', 'f'),
194                 $args = 0;
195                 my @fmts = grep $args[$_] =~ /\b(f|pat|fmt)$/, 0..$#args;
196                 if (@fmts != 1) {
197                     die "embed.pl: '$plain_func': can't determine pattern arg\n";
198                 }
199                 $pat = $fmts[0] + 1;
200             }
201             my $macro   = grep($_ == $pat, @nonnull)
202                                 ? '__attribute__format__'
203                                 : '__attribute__format__null_ok__';
204             if ($plain_func =~ /strftime/) {
205                 push @attrs, sprintf "%s(__strftime__,%s1,0)", $macro, $prefix;
206             }
207             else {
208                 push @attrs, sprintf "%s(__printf__,%s%d,%s)", $macro,
209                                     $prefix, $pat, $args;
210             }
211         }
212         if ( @attrs ) {
213             $ret .= "\n";
214             $ret .= join( "\n", map { "\t\t\t$_" } @attrs );
215         }
216         $ret .= ";";
217         $ret = "/* $ret */" if $commented_out;
218         if (@names_of_nn) {
219             $ret .= "\n#define PERL_ARGS_ASSERT_\U$plain_func\E\t\\\n\t"
220                 . join '; ', map "assert($_)", @names_of_nn;
221         }
222         $ret .= @attrs ? "\n\n" : "\n";
223
224         print $pr $ret;
225     }
226
227     print $pr <<'EOF';
228 #ifdef PERL_CORE
229 #  include "pp_proto.h"
230 #endif
231 END_EXTERN_C
232 EOF
233
234     read_only_bottom_close_and_rename($pr);
235 }
236
237 warn "$unflagged_pointers pointer arguments to clean up\n" if $unflagged_pointers;
238
239 sub readvars {
240     my ($file, $pre) = @_;
241     local (*FILE, $_);
242     my %seen;
243     open(FILE, "< $file")
244         or die "embed.pl: Can't open $file: $!\n";
245     while (<FILE>) {
246         s/[ \t]*#.*//;          # Delete comments.
247         if (/PERLVARA?I?C?\($pre,\s*(\w+)/) {
248             warn "duplicate symbol $1 while processing $file line $.\n"
249                 if $seen{$1}++;
250         }
251     }
252     close(FILE);
253     return sort keys %seen;
254 }
255
256 my @intrp = readvars 'intrpvar.h','I';
257 my @globvar = readvars 'perlvars.h','G';
258
259 sub hide {
260     my ($from, $to, $indent) = @_;
261     $indent = '' unless defined $indent;
262     my $t = int(length("$indent$from") / 8);
263     "#${indent}define $from" . "\t" x ($t < 3 ? 3 - $t : 1) . "$to\n";
264 }
265
266 sub multon ($$$) {
267     my ($sym,$pre,$ptr) = @_;
268     hide("PL_$sym", "($ptr$pre$sym)");
269 }
270
271 my $em = open_print_header('embed.h');
272
273 print $em <<'END';
274 /* (Doing namespace management portably in C is really gross.) */
275
276 /* By defining PERL_NO_SHORT_NAMES (not done by default) the short forms
277  * (like warn instead of Perl_warn) for the API are not defined.
278  * Not defining the short forms is a good thing for cleaner embedding. */
279
280 #ifndef PERL_NO_SHORT_NAMES
281
282 /* Hide global symbols */
283
284 END
285
286 my @az = ('a'..'z');
287
288 sub embed_h {
289     my ($guard, $funcs) = @_;
290     print $em "$guard\n" if $guard;
291
292     my $lines;
293     foreach (@$funcs) {
294         if (@$_ == 1) {
295             my $cond = $_->[0];
296             # Indent the conditionals if we are wrapped in an #if/#endif pair.
297             $cond =~ s/#(.*)/#  $1/ if $guard;
298             $lines .= "$cond\n";
299             next;
300         }
301         my $ret = "";
302         my ($flags,$retval,$func,@args) = @$_;
303         unless ($flags =~ /[om]/) {
304             my $args = scalar @args;
305             if ($flags =~ /n/) {
306                 my $full_name = full_name($func, $flags);
307                 next if $full_name eq $func;    # Don't output a no-op.
308                 $ret = hide($func, $full_name);
309             }
310             elsif ($args and $args[$args-1] =~ /\.\.\./) {
311                 if ($flags =~ /p/) {
312                     # we're out of luck for varargs functions under CPP
313                     # So we can only do these macros for no implicit context:
314                     $ret = "#ifndef PERL_IMPLICIT_CONTEXT\n"
315                         . hide($func, full_name($func, $flags)) . "#endif\n";
316                 }
317             }
318             else {
319                 my $alist = join(",", @az[0..$args-1]);
320                 $ret = "#define $func($alist)";
321                 my $t = int(length($ret) / 8);
322                 $ret .=  "\t" x ($t < 4 ? 4 - $t : 1);
323                 $ret .= full_name($func, $flags) . "(aTHX";
324                 $ret .= "_ " if $alist;
325                 $ret .= $alist . ")\n";
326             }
327         }
328         $lines .= $ret;
329     }
330     # Prune empty #if/#endif pairs.
331     while ($lines =~ s/#\s*if[^\n]+\n#\s*endif\n//) {
332     }
333     # Merge adjacent blocks.
334     while ($lines =~ s/(#ifndef PERL_IMPLICIT_CONTEXT
335 [^\n]+
336 )#endif
337 #ifndef PERL_IMPLICIT_CONTEXT
338 /$1/) {
339     }
340
341     print $em $lines;
342     print $em "#endif\n" if $guard;
343 }
344
345 embed_h('', $api);
346 embed_h('#if defined(PERL_CORE) || defined(PERL_EXT)', $ext);
347 embed_h('#ifdef PERL_CORE', $core);
348
349 print $em <<'END';
350
351 #endif  /* #ifndef PERL_NO_SHORT_NAMES */
352
353 /* Compatibility stubs.  Compile extensions with -DPERL_NOCOMPAT to
354    disable them.
355  */
356
357 #if !defined(PERL_CORE)
358 #  define sv_setptrobj(rv,ptr,name)     sv_setref_iv(rv,name,PTR2IV(ptr))
359 #  define sv_setptrref(rv,ptr)          sv_setref_iv(rv,NULL,PTR2IV(ptr))
360 #endif
361
362 #if !defined(PERL_CORE) && !defined(PERL_NOCOMPAT)
363
364 /* Compatibility for various misnamed functions.  All functions
365    in the API that begin with "perl_" (not "Perl_") take an explicit
366    interpreter context pointer.
367    The following are not like that, but since they had a "perl_"
368    prefix in previous versions, we provide compatibility macros.
369  */
370 #  define perl_atexit(a,b)              call_atexit(a,b)
371 END
372
373 foreach (@$embed) {
374     my ($flags, $retval, $func, @args) = @$_;
375     next unless $func;
376     next unless $flags =~ /O/;
377
378     my $alist = join ",", @az[0..$#args];
379     my $ret = "#  define perl_$func($alist)";
380     my $t = (length $ret) >> 3;
381     $ret .=  "\t" x ($t < 5 ? 5 - $t : 1);
382     print $em "$ret$func($alist)\n";
383 }
384
385 my @nocontext;
386 {
387     my (%has_va, %has_nocontext);
388     foreach (@$embed) {
389         next unless @$_ > 1;
390         ++$has_va{$_->[2]} if $_->[-1] =~ /\.\.\./;
391         ++$has_nocontext{$1} if $_->[2] =~ /(.*)_nocontext/;
392     }
393
394     @nocontext = sort grep {
395         $has_nocontext{$_}
396             && !/printf/ # Not clear to me why these are skipped but they are.
397     } keys %has_va;
398 }
399
400 print $em <<'END';
401
402 /* varargs functions can't be handled with CPP macros. :-(
403    This provides a set of compatibility functions that don't take
404    an extra argument but grab the context pointer using the macro
405    dTHX.
406  */
407 #if defined(PERL_IMPLICIT_CONTEXT) && !defined(PERL_NO_SHORT_NAMES)
408 END
409
410 foreach (@nocontext) {
411     print $em hide($_, "Perl_${_}_nocontext", "  ");
412 }
413
414 print $em <<'END';
415 #endif
416
417 #endif /* !defined(PERL_CORE) && !defined(PERL_NOCOMPAT) */
418
419 #if !defined(PERL_IMPLICIT_CONTEXT)
420 /* undefined symbols, point them back at the usual ones */
421 END
422
423 foreach (@nocontext) {
424     print $em hide("Perl_${_}_nocontext", "Perl_$_", "  ");
425 }
426
427 print $em <<'END';
428 #endif
429 END
430
431 read_only_bottom_close_and_rename($em);
432
433 $em = open_print_header('embedvar.h');
434
435 print $em <<'END';
436 /* (Doing namespace management portably in C is really gross.) */
437
438 /*
439    The following combinations of MULTIPLICITY and PERL_IMPLICIT_CONTEXT
440    are supported:
441      1) none
442      2) MULTIPLICITY    # supported for compatibility
443      3) MULTIPLICITY && PERL_IMPLICIT_CONTEXT
444
445    All other combinations of these flags are errors.
446
447    only #3 is supported directly, while #2 is a special
448    case of #3 (supported by redefining vTHX appropriately).
449 */
450
451 #if defined(MULTIPLICITY)
452 /* cases 2 and 3 above */
453
454 #  if defined(PERL_IMPLICIT_CONTEXT)
455 #    define vTHX        aTHX
456 #  else
457 #    define vTHX        PERL_GET_INTERP
458 #  endif
459
460 END
461
462 my $sym;
463
464 for $sym (@intrp) {
465     if ($sym eq 'sawampersand') {
466         print $em "#ifndef PL_sawampersand\n";
467     }
468     print $em multon($sym,'I','vTHX->');
469     if ($sym eq 'sawampersand') {
470         print $em "#endif\n";
471     }
472 }
473
474 print $em <<'END';
475
476 #endif  /* MULTIPLICITY */
477
478 #if defined(PERL_GLOBAL_STRUCT)
479
480 END
481
482 for $sym (@globvar) {
483     print $em "#ifdef OS2\n" if $sym eq 'sh_path';
484     print $em multon($sym,   'G','my_vars->');
485     print $em multon("G$sym",'', 'my_vars->');
486     print $em "#endif\n" if $sym eq 'sh_path';
487 }
488
489 print $em <<'END';
490
491 #endif /* PERL_GLOBAL_STRUCT */
492 END
493
494 read_only_bottom_close_and_rename($em);
495
496 my $capih = open_print_header('perlapi.h');
497
498 print $capih <<'EOT';
499 /* declare accessor functions for Perl variables */
500 #ifndef __perlapi_h__
501 #define __perlapi_h__
502
503 #if defined (MULTIPLICITY) && defined (PERL_GLOBAL_STRUCT)
504
505 START_EXTERN_C
506
507 #undef PERLVAR
508 #undef PERLVARA
509 #undef PERLVARI
510 #undef PERLVARIC
511 #define PERLVAR(p,v,t)  EXTERN_C t* Perl_##p##v##_ptr(pTHX);
512 #define PERLVARA(p,v,n,t)       typedef t PL_##v##_t[n];                \
513                         EXTERN_C PL_##v##_t* Perl_##p##v##_ptr(pTHX);
514 #define PERLVARI(p,v,t,i)       PERLVAR(p,v,t)
515 #define PERLVARIC(p,v,t,i) PERLVAR(p,v, const t)
516
517 #include "perlvars.h"
518
519 #undef PERLVAR
520 #undef PERLVARA
521 #undef PERLVARI
522 #undef PERLVARIC
523
524 END_EXTERN_C
525
526 #if defined(PERL_CORE)
527
528 /* accessor functions for Perl "global" variables */
529
530 /* these need to be mentioned here, or most linkers won't put them in
531    the perl executable */
532
533 #ifndef PERL_NO_FORCE_LINK
534
535 START_EXTERN_C
536
537 #ifndef DOINIT
538 EXTCONST void * const PL_force_link_funcs[];
539 #else
540 EXTCONST void * const PL_force_link_funcs[] = {
541 #undef PERLVAR
542 #undef PERLVARA
543 #undef PERLVARI
544 #undef PERLVARIC
545 #define PERLVAR(p,v,t)          (void*)Perl_##p##v##_ptr,
546 #define PERLVARA(p,v,n,t)       PERLVAR(p,v,t)
547 #define PERLVARI(p,v,t,i)       PERLVAR(p,v,t)
548 #define PERLVARIC(p,v,t,i)      PERLVAR(p,v,t)
549
550 /* In Tru64 (__DEC && __osf__) the cc option -std1 causes that one
551  * cannot cast between void pointers and function pointers without
552  * info level warnings.  The PL_force_link_funcs[] would cause a few
553  * hundred of those warnings.  In code one can circumnavigate this by using
554  * unions that overlay the different pointers, but in declarations one
555  * cannot use this trick.  Therefore we just disable the warning here
556  * for the duration of the PL_force_link_funcs[] declaration. */
557
558 #if defined(__DECC) && defined(__osf__)
559 #pragma message save
560 #pragma message disable (nonstandcast)
561 #endif
562
563 #include "perlvars.h"
564
565 #if defined(__DECC) && defined(__osf__)
566 #pragma message restore
567 #endif
568
569 #undef PERLVAR
570 #undef PERLVARA
571 #undef PERLVARI
572 #undef PERLVARIC
573 };
574 #endif  /* DOINIT */
575
576 END_EXTERN_C
577
578 #endif  /* PERL_NO_FORCE_LINK */
579
580 #else   /* !PERL_CORE */
581
582 EOT
583
584 foreach $sym (@globvar) {
585     print $capih
586         "#undef  PL_$sym\n" . hide("PL_$sym", "(*Perl_G${sym}_ptr(NULL))");
587 }
588
589 print $capih <<'EOT';
590
591 #endif /* !PERL_CORE */
592 #endif /* MULTIPLICITY && PERL_GLOBAL_STRUCT */
593
594 #endif /* __perlapi_h__ */
595 EOT
596
597 read_only_bottom_close_and_rename($capih);
598
599 my $capi = open_print_header('perlapi.c', <<'EOQ');
600  *
601  *
602  * Up to the threshold of the door there mounted a flight of twenty-seven
603  * broad stairs, hewn by some unknown art of the same black stone.  This
604  * was the only entrance to the tower; ...
605  *
606  *     [p.577 of _The Lord of the Rings_, III/x: "The Voice of Saruman"]
607  *
608  */
609 EOQ
610
611 print $capi <<'EOT';
612 #include "EXTERN.h"
613 #include "perl.h"
614 #include "perlapi.h"
615
616 #if defined (MULTIPLICITY) && defined (PERL_GLOBAL_STRUCT)
617
618 /* accessor functions for Perl "global" variables */
619 START_EXTERN_C
620
621 #undef PERLVARI
622 #define PERLVARI(p,v,t,i) PERLVAR(p,v,t)
623
624 #undef PERLVAR
625 #undef PERLVARA
626 #define PERLVAR(p,v,t)          t* Perl_##p##v##_ptr(pTHX)              \
627                         { dVAR; PERL_UNUSED_CONTEXT; return &(PL_##v); }
628 #define PERLVARA(p,v,n,t)       PL_##v##_t* Perl_##p##v##_ptr(pTHX)     \
629                         { dVAR; PERL_UNUSED_CONTEXT; return &(PL_##v); }
630 #undef PERLVARIC
631 #define PERLVARIC(p,v,t,i)      \
632                         const t* Perl_##p##v##_ptr(pTHX)                \
633                         { PERL_UNUSED_CONTEXT; return (const t *)&(PL_##v); }
634 #include "perlvars.h"
635
636 #undef PERLVAR
637 #undef PERLVARA
638 #undef PERLVARI
639 #undef PERLVARIC
640
641 END_EXTERN_C
642
643 #endif /* MULTIPLICITY && PERL_GLOBAL_STRUCT */
644 EOT
645
646 read_only_bottom_close_and_rename($capi);
647
648 # ex: set ts=8 sts=4 sw=4 noet: