This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Set PERL_DL_NONLAZY in t/TEST to check existence of all symbols
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still currrent
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # "not absolute" is the the default, as it saves some fakery within TestInit
27 # which can peturb tests, and takes CPU. Working with the upstream author of
28 # any of these, to figure out how to remove them from this list, considered
29 # "a good thing".
30 my %abs = (
31            '../cpan/Archive-Extract' => 1,
32            '../cpan/Archive-Tar' => 1,
33            '../cpan/AutoLoader' => 1,
34            '../cpan/CPAN' => 1,
35            '../cpan/Class-ISA' => 1,
36            '../cpan/Devel-PPPort' => 1,
37            '../cpan/Encode' => 1,
38            '../cpan/ExtUtils-Constant' => 1,
39            '../cpan/ExtUtils-MakeMaker' => 1,
40            '../cpan/File-Fetch' => 1,
41            '../cpan/IPC-Cmd' => 1,
42            '../cpan/IPC-SysV' => 1,
43            '../cpan/Locale-Codes' => 1,
44            '../cpan/Log-Message' => 1,
45            '../cpan/Module-Build' => 1,
46            '../cpan/Module-Load' => 1,
47            '../cpan/Module-Load-Conditional' => 1,
48            '../cpan/Object-Accessor' => 1,
49            '../cpan/Package-Constants' => 1,
50            '../cpan/Parse-CPAN-Meta' => 1,
51            '../cpan/Pod-Simple' => 1,
52            '../cpan/Term-UI' => 1,
53            '../cpan/Test-Simple' => 1,
54            '../cpan/Tie-File' => 1,
55            '../cpan/podlators' => 1,
56            '../dist/Cwd' => 1,
57            '../dist/ExtUtils-Command' => 1,
58            '../dist/ExtUtils-Install' => 1,
59            '../dist/ExtUtils-Manifest' => 1,
60            '../dist/ExtUtils-ParseXS' => 1,
61           );
62
63 my %temp_no_core =
64     ('../cpan/B-Debug' => 1,
65      '../cpan/Compress-Raw-Bzip2' => 1,
66      '../cpan/Compress-Raw-Zlib' => 1,
67      '../cpan/Devel-PPPort' => 1,
68      '../cpan/Getopt-Long' => 1,
69      '../cpan/IO-Compress' => 1,
70      '../cpan/MIME-Base64' => 1,
71      '../cpan/parent' => 1,
72      '../cpan/Parse-CPAN-Meta' => 1,
73      '../cpan/Pod-Simple' => 1,
74      '../cpan/podlators' => 1,
75      '../cpan/Test-Simple' => 1,
76      '../cpan/Tie-RefHash' => 1,
77      '../cpan/Unicode-Collate' => 1,
78      '../cpan/Unicode-Normalize' => 1,
79     );
80
81 # delete env vars that may influence the results
82 # but allow override via *_TEST env var if wanted
83 # (e.g. PERL5OPT_TEST=-d:NYTProf)
84 for my $envname (qw(PERL5LIB PERLLIB PERL5OPT)) {
85     my $override = $ENV{"${envname}_TEST"};
86     if (defined $override) {
87         warn "$0: $envname=$override\n";
88         $ENV{$envname} = $override;
89     }
90     else {
91         delete $ENV{$envname};
92     }
93 }
94
95 if ($::do_nothing) {
96     return 1;
97 }
98
99 # Location to put the Valgrind log.
100 our $Valgrind_Log;
101
102 $| = 1;
103
104 # for testing TEST only
105 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
106 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
107
108 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
109 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
110 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
111
112 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
113 # can't rely on require working.
114 {
115     my @argv = ();
116     foreach my $idx (0..$#ARGV) {
117         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
118         $::benchmark = 1 if $1 eq 'benchmark';
119         $::core    = 1 if $1 eq 'core';
120         $::verbose = 1 if $1 eq 'v';
121         $::torture = 1 if $1 eq 'torture';
122         $::with_utf8 = 1 if $1 eq 'utf8';
123         $::with_utf16 = 1 if $1 eq 'utf16';
124         $::taintwarn = 1 if $1 eq 'taintwarn';
125         if ($1 =~ /^deparse(,.+)?$/) {
126             $::deparse = 1;
127             $::deparse_opts = $1;
128         }
129     }
130     @ARGV = @argv;
131 }
132
133 chdir 't' if -f 't/TEST';
134 if (-f 'TEST' && -f 'harness' && -d '../lib') {
135     @INC = '../lib';
136 }
137
138 die "You need to run \"make test\" first to set things up.\n"
139   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
140
141 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
142     unless (-x 'perl.third') {
143         unless (-x '../perl.third') {
144             die "You need to run \"make perl.third first.\n";
145         }
146         else {
147             print "Symlinking ../perl.third as perl.third...\n";
148             die "Failed to symlink: $!\n"
149                 unless symlink("../perl.third", "perl.third");
150             die "Symlinked but no executable perl.third: $!\n"
151                 unless -x 'perl.third';
152         }
153     }
154 }
155
156 # check leakage for embedders
157 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
158 # check existence of all symbols
159 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
160
161 $ENV{EMXSHELL} = 'sh';        # For OS/2
162
163 if ($show_elapsed_time) { require Time::HiRes }
164 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
165
166 my %skip = (
167             '.' => 1,
168             '..' => 1,
169             'CVS' => 1,
170             'RCS' => 1,
171             'SCCS' => 1,
172             '.svn' => 1,
173            );
174
175 # Roll your own File::Find!
176 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
177 sub _find_files {
178     my($patt, @dirs) = @_;
179     for my $dir (@dirs) {
180         opendir DIR, $dir or die "Trouble opening $dir: $!";
181         foreach my $f (sort { $a cmp $b } readdir DIR) {
182             next if $skip{$f};
183
184             my $fullpath = "$dir/$f";
185             
186             if (-d $fullpath) {
187                 _find_files($patt, $fullpath);
188             } elsif ($f =~ /$patt/) {
189                 push @found, $fullpath;
190             }
191         }
192     }
193     @found;
194 }
195
196
197 # Scan the text of the test program to find switches and special options
198 # we might need to apply.
199 sub _scan_test {
200     my($test, $type) = @_;
201
202     open(my $script, "<", $test) or die "Can't read $test.\n";
203     my $first_line = <$script>;
204
205     $first_line =~ tr/\0//d if $::with_utf16;
206
207     my $switch = "";
208     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
209         $switch = "-$1";
210     } else {
211         if ($::taintwarn) {
212             # not all tests are expected to pass with this option
213             $switch = '-t';
214         } else {
215             $switch = '';
216         }
217     }
218
219     my $file_opts = "";
220     if ($type eq 'deparse') {
221         # Look for #line directives which change the filename
222         while (<$script>) {
223             $file_opts = $file_opts . ",-f$3$4"
224               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
225         }
226     }
227
228     close $script;
229
230     my $perl = './perl';
231     my $lib  = '../lib';
232     my $run_dir;
233     my $return_dir;
234
235     $test =~ /^(.+)\/[^\/]+/;
236     my $dir = $1;
237     my $testswitch = $dir_to_switch{$dir};
238     if (!defined $testswitch) {
239         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
240             $run_dir = $1;
241             $return_dir = '../../t';
242             $lib = '../../lib';
243             $perl = '../../t/perl';
244             $testswitch = "-I../.. -MTestInit=U2T";
245             if ($2 eq 'cpan' || $2 eq 'dist') {
246                 if($abs{$run_dir}) {
247                     $testswitch = $testswitch . ',A';
248                 }
249                 if ($temp_no_core{$run_dir}) {
250                     $testswitch = $testswitch . ',NC';
251                 }
252             }
253         } elsif ($test =~ m!^\.\./lib!) {
254             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
255         } else {
256             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
257         }
258     }
259
260     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
261
262     my %options = (
263         perl => $perl,
264         lib => $lib,
265         test => $test,
266         run_dir => $run_dir,
267         return_dir => $return_dir,
268         testswitch => $testswitch,
269         utf8 => $utf8,
270         file => $file_opts,
271         switch => $switch,
272     );
273
274     return \%options;
275 }
276
277 sub _cmd {
278     my($options, $type) = @_;
279
280     my $test = $options->{test};
281
282     my $cmd;
283     if ($type eq 'deparse') {
284         my $perl = "$options->{perl} $options->{testswitch}";
285         my $lib = $options->{lib};
286
287         $cmd = (
288           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
289           "-l$::deparse_opts$options->{file} ".
290           "$test > $test.dp ".
291           "&& $perl $options->{switch} -I$lib $test.dp"
292         );
293     }
294     elsif ($type eq 'perl') {
295         my $perl = $options->{perl};
296         my $redir = $^O eq 'VMS' ? '2>&1' : '';
297
298         if ($ENV{PERL_VALGRIND}) {
299             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
300             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
301             my $vg_opts = $ENV{VG_OPTS}
302               // '--log-fd=3 '
303                   . "--suppressions=$perl_supp --leak-check=yes "
304                   . "--leak-resolution=high --show-reachable=yes "
305                   . "--num-callers=50 --track-origins=yes";
306             $perl = "$valgrind_exe $vg_opts $perl";
307             $redir = "3>$Valgrind_Log";
308             if ($options->{run_dir}) {
309                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
310             }
311         }
312
313         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
314         $cmd = $perl . _quote_args($args) . " $test $redir";
315     }
316     return $cmd;
317 }
318
319 sub _before_fork {
320     my ($options) = @_;
321
322     if ($options->{run_dir}) {
323         my $run_dir = $options->{run_dir};
324         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
325     }
326
327     return;
328 }
329
330 sub _after_fork {
331     my ($options) = @_;
332
333     if ($options->{return_dir}) {
334         my $return_dir = $options->{return_dir};
335         chdir $return_dir
336            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
337     }
338
339     return;
340 }
341
342 sub _run_test {
343     my ($test, $type) = @_;
344
345     my $options = _scan_test($test, $type);
346     # $test might have changed if we're in ext/Foo, so don't use it anymore
347     # from now on. Use $options->{test} instead.
348
349     _before_fork($options);
350
351     my $cmd = _cmd($options, $type);
352
353     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
354
355     _after_fork($options);
356
357     # Our environment may force us to use UTF-8, but we can't be sure that
358     # anything we're reading from will be generating (well formed) UTF-8
359     # This may not be the best way - possibly we should unset ${^OPEN} up
360     # top?
361     binmode $results;
362
363     return $results;
364 }
365
366 sub _quote_args {
367     my ($args) = @_;
368     my $argstring = '';
369
370     foreach (split(/\s+/,$args)) {
371        # In VMS protect with doublequotes because otherwise
372        # DCL will lowercase -- unless already doublequoted.
373        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
374        $argstring = $argstring . ' ' . $_;
375     }
376     return $argstring;
377 }
378
379 sub _populate_hash {
380     return unless defined $_[0];
381     return map {$_, 1} split /\s+/, $_[0];
382 }
383
384 sub _tests_from_manifest {
385     my ($extensions, $known_extensions) = @_;
386     my %skip;
387     my %extensions = _populate_hash($extensions);
388     my %known_extensions = _populate_hash($known_extensions);
389
390     foreach (keys %known_extensions) {
391         $skip{$_} = 1 unless $extensions{$_};
392     }
393
394     my @results;
395     my $mani = '../MANIFEST';
396     if (open(MANI, $mani)) {
397         while (<MANI>) {
398             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
399                 my $t = $1;
400                 my $extension = $2;
401                 if (!$::core || $t =~ m!^lib/[a-z]!) {
402                     if (defined $extension) {
403                         $extension =~ s!/t(:?/\S+)*$!!;
404                         # XXX Do I want to warn that I'm skipping these?
405                         next if $skip{$extension};
406                         my $flat_extension = $extension;
407                         $flat_extension =~ s!-!/!g;
408                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
409                     }
410                     my $path = "../$t";
411                     push @results, $path;
412                     $::path_to_name{$path} = $t;
413                 }
414             }
415         }
416         close MANI;
417     } else {
418         warn "$0: cannot open $mani: $!\n";
419     }
420     return @results;
421 }
422
423 unless (@ARGV) {
424     # base first, as TEST bails out if that can't run
425     # then comp, to validate that require works
426     # then run, to validate that -M works
427     # then we know we can -MTestInit for everything else, making life simpler
428     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
429         _find_tests($dir);
430     }
431     _find_tests("lib") unless $::core;
432     # Config.pm may be broken for make minitest. And this is only a refinement
433     # for skipping tests on non-default builds, so it is allowed to fail.
434     # What we want to to is make a list of extensions which we did not build.
435     my $configsh = '../config.sh';
436     my ($extensions, $known_extensions);
437     if (-f $configsh) {
438         open FH, $configsh or die "Can't open $configsh: $!";
439         while (<FH>) {
440             if (/^extensions=['"](.*)['"]$/) {
441                 $extensions = $1;
442             }
443             elsif (/^known_extensions=['"](.*)['"]$/) {
444                 $known_extensions = $1;
445             }
446         }
447         if (!defined $known_extensions) {
448             warn "No known_extensions line found in $configsh";
449         }
450         if (!defined $extensions) {
451             warn "No extensions line found in $configsh";
452         }
453     }
454     # The "complex" constructions of list return from a subroutine, and push of
455     # a list, might fail if perl is really hosed, but they aren't needed for
456     # make minitest, and the building of extensions will likely also fail if
457     # something is that badly wrong.
458     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
459     unless ($::core) {
460         _find_tests('x2p');
461         _find_tests('porting');
462         _find_tests('japh') if $::torture;
463         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
464     }
465 }
466
467 if ($::deparse) {
468     _testprogs('deparse', '',   @ARGV);
469 }
470 elsif ($::with_utf16) {
471     for my $e (0, 1) {
472         for my $b (0, 1) {
473             print STDERR "# ENDIAN $e BOM $b\n";
474             my @UARGV;
475             for my $a (@ARGV) {
476                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
477                 my $f = $e ? "v" : "n";
478                 push @UARGV, $u;
479                 unlink($u);
480                 if (open(A, $a)) {
481                     if (open(U, ">$u")) {
482                         print U pack("$f", 0xFEFF) if $b;
483                         while (<A>) {
484                             print U pack("$f*", unpack("C*", $_));
485                         }
486                         close(U);
487                     }
488                     close(A);
489                 }
490             }
491             _testprogs('perl', '', @UARGV);
492             unlink(@UARGV);
493         }
494     }
495 }
496 else {
497     _testprogs('perl',    '',   @ARGV);
498 }
499
500 sub _testprogs {
501     my ($type, $args, @tests) = @_;
502
503     print <<'EOT' if ($type eq 'deparse');
504 ------------------------------------------------------------------------------
505 TESTING DEPARSER
506 ------------------------------------------------------------------------------
507 EOT
508
509     $::bad_files = 0;
510
511     foreach my $t (@tests) {
512       unless (exists $::path_to_name{$t}) {
513         my $tname = "t/$t";
514         $::path_to_name{$t} = $tname;
515       }
516     }
517     my $maxlen = 0;
518     foreach (@::path_to_name{@tests}) {
519         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
520         my $len = length ;
521         $maxlen = $len if $len > $maxlen;
522     }
523     # + 3 : we want three dots between the test name and the "ok"
524     my $dotdotdot = $maxlen + 3 ;
525     my $grind_ct = 0;           # count of non-empty valgrind reports
526     my $total_files = @tests;
527     my $good_files = 0;
528     my $tested_files  = 0;
529     my $totmax = 0;
530     my %failed_tests;
531     my $toolnm;         # valgrind, cachegrind, perf
532
533     while (my $test = shift @tests) {
534         my ($test_start_time, @starttimes) = 0;
535         if ($show_elapsed_time) {
536             $test_start_time = Time::HiRes::time();
537             # times() reports usage by TEST, but we want usage of each
538             # testprog it calls, so record accumulated times now,
539             # subtract them out afterwards.  Ideally, we'd take times
540             # in BEGIN/END blocks (giving better visibility of self vs
541             # children of each testprog), but that would require some
542             # IPC to send results back here, or a completely different
543             # collection scheme (Storable isnt tuned for incremental use)
544             @starttimes = times;
545         }
546         if ($test =~ /^$/) {
547             next;
548         }
549         if ($type eq 'deparse') {
550             if ($test eq "comp/redef.t") {
551                 # Redefinition happens at compile time
552                 next;
553             }
554             elsif ($test =~ m{lib/Switch/t/}) {
555                 # B::Deparse doesn't support source filtering
556                 next;
557             }
558         }
559         my $te = $::path_to_name{$test} . '.'
560                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
561
562         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
563             print $te;
564             $te = '';
565         }
566
567         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
568         my $results = _run_test($test, $type);
569
570         my $failure;
571         my $next = 0;
572         my $seen_leader = 0;
573         my $seen_ok = 0;
574         my $trailing_leader = 0;
575         my $max;
576         my %todo;
577         while (<$results>) {
578             next if /^\s*$/; # skip blank lines
579             if (/^1..$/ && ($^O eq 'VMS')) {
580                 # VMS pipe bug inserts blank lines.
581                 my $l2 = <RESULTS>;
582                 if ($l2 =~ /^\s*$/) {
583                     $l2 = <RESULTS>;
584                 }
585                 $_ = '1..' . $l2;
586             }
587             if ($::verbose) {
588                 print $_;
589             }
590             unless (/^\#/) {
591                 if ($trailing_leader) {
592                     # shouldn't be anything following a postfix 1..n
593                     $failure = 'FAILED--extra output after trailing 1..n';
594                     last;
595                 }
596                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
597                     if ($seen_leader) {
598                         $failure = 'FAILED--seen duplicate leader';
599                         last;
600                     }
601                     $max = $1;
602                     %todo = map { $_ => 1 } split / /, $3 if $3;
603                     $totmax = $totmax + $max;
604                     $tested_files = $tested_files + 1;
605                     if ($seen_ok) {
606                         # 1..n appears at end of file
607                         $trailing_leader = 1;
608                         if ($next != $max) {
609                             $failure = "FAILED--expected $max tests, saw $next";
610                             last;
611                         }
612                     }
613                     else {
614                         $next = 0;
615                     }
616                     $seen_leader = 1;
617                 }
618                 else {
619                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
620                         unless ($seen_leader) {
621                             unless ($seen_ok) {
622                                 $next = 0;
623                             }
624                         }
625                         $seen_ok = 1;
626                         $next = $next + 1;
627                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
628                         $num = $next unless $num;
629
630                         if ($num == $next) {
631
632                             # SKIP is essentially the same as TODO for t/TEST
633                             # this still conforms to TAP:
634                             # http://testanything.org/wiki/index.php/TAP_specification
635                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
636                             $istodo = 1 if $todo{$num};
637
638                             if( $not && !$istodo ) {
639                                 $failure = "FAILED at test $num";
640                                 last;
641                             }
642                         }
643                         else {
644                             $failure ="FAILED--expected test $next, saw test $num";
645                             last;
646                         }
647                     }
648                     elsif (/^Bail out!\s*(.*)/i) { # magic words
649                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
650                     }
651                     else {
652                         # module tests are allowed extra output,
653                         # because Test::Harness allows it
654                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
655                         $failure = "FAILED--unexpected output at test $next";
656                         last;
657                     }
658                 }
659             }
660         }
661         close $results;
662
663         if (not defined $failure) {
664             $failure = 'FAILED--no leader found' unless $seen_leader;
665         }
666
667         if ($ENV{PERL_VALGRIND}) {
668             $toolnm = $ENV{VALGRIND};
669             $toolnm =~ s|.*/||;  # keep basename
670             my @valgrind;       # gets content of file
671             if (-e $Valgrind_Log) {
672                 if (open(V, $Valgrind_Log)) {
673                     @valgrind = <V>;
674                     close V;
675                 } else {
676                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
677                 }
678             }
679             if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $toolnm =~ /(perf)/) {
680                 $toolnm = $1;
681                 if ($toolnm eq 'perf') {
682                     # append perfs subcommand, not just stat
683                     my ($sub) = split /\s/, $ENV{VG_OPTS};
684                     $toolnm .= "-$sub";
685                 }
686                 if (rename $Valgrind_Log, "$test.$toolnm") {
687                     $grind_ct++;
688                 } else {
689                     warn "$0: Failed to create '$test.$toolnm': $!\n";
690                 }
691             }
692             elsif (@valgrind) {
693                 my $leaks = 0;
694                 my $errors = 0;
695                 for my $i (0..$#valgrind) {
696                     local $_ = $valgrind[$i];
697                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
698                         $errors = $errors + $1;   # there may be multiple error summaries
699                     } elsif (/^==\d+== LEAK SUMMARY:/) {
700                         for my $off (1 .. 4) {
701                             if ($valgrind[$i+$off] =~
702                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
703                                 $leaks = $leaks + $1;
704                             }
705                         }
706                     }
707                 }
708                 if ($errors or $leaks) {
709                     if (rename $Valgrind_Log, "$test.valgrind") {
710                         $grind_ct = $grind_ct + 1;
711                     } else {
712                         warn "$0: Failed to create '$test.valgrind': $!\n";
713                     }
714                 }
715             } else {
716                 warn "No valgrind output?\n";
717             }
718             if (-e $Valgrind_Log) {
719                 unlink $Valgrind_Log
720                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
721             }
722         }
723         if ($type eq 'deparse') {
724             unlink "./$test.dp";
725         }
726         if ($ENV{PERL_3LOG}) {
727             my $tpp = $test;
728             $tpp =~ s:^\.\./::;
729             $tpp =~ s:/:_:g;
730             $tpp =~ s:\.t$:.3log:;
731             rename("perl.3log", $tpp) ||
732                 die "rename: perl3.log to $tpp: $!\n";
733         }
734         if (not defined $failure and $next != $max) {
735             $failure="FAILED--expected $max tests, saw $next";
736         }
737
738         if( !defined $failure  # don't mask a test failure
739             and $? )
740         {
741             $failure = "FAILED--non-zero wait status: $?";
742         }
743
744         if (defined $failure) {
745             print "${te}$failure\n";
746             $::bad_files = $::bad_files + 1;
747             if ($test =~ /^base/) {
748                 die "Failed a basic test ($test) -- cannot continue.\n";
749             }
750             $failed_tests{$test} = 1;
751         }
752         else {
753             if ($max) {
754                 my ($elapsed, $etms) = ("", 0);
755                 if ( $show_elapsed_time ) {
756                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
757                     $elapsed = sprintf(" %8.0f ms", $etms);
758
759                     my (@endtimes) = times;
760                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
761                     splice @endtimes, 0, 2;    # drop self/harness times
762                     $_ *= 1000 for @endtimes;  # and scale to ms
763                     $timings{$test} = [$etms,@endtimes];
764                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
765                 }
766                 print "${te}ok$elapsed\n";
767                 $good_files = $good_files + 1;
768             }
769             else {
770                 print "${te}skipped\n";
771                 $tested_files = $tested_files - 1;
772             }
773         }
774     } # while tests
775
776     if ($::bad_files == 0) {
777         if ($good_files) {
778             print "All tests successful.\n";
779             # XXX add mention of 'perlbug -ok' ?
780         }
781         else {
782             die "FAILED--no tests were run for some reason.\n";
783         }
784     }
785     else {
786         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
787         my $s = $::bad_files == 1 ? "" : "s";
788         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
789         for my $test ( sort keys %failed_tests ) {
790             print "\t$test\n";
791         }
792         warn <<'SHRDLU_1';
793 ### Since not all tests were successful, you may want to run some of
794 ### them individually and examine any diagnostic messages they produce.
795 ### See the INSTALL document's section on "make test".
796 SHRDLU_1
797         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
798 ### You have a good chance to get more information by running
799 ###   ./perl harness
800 ### in the 't' directory since most (>=80%) of the tests succeeded.
801 SHRDLU_2
802         if (eval {require Config; import Config; 1}) {
803             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
804                 warn <<SHRDLU_3;
805 ### You may have to set your dynamic library search path,
806 ### $p, to point to the build directory:
807 SHRDLU_3
808                 if (exists $ENV{$p} && $ENV{$p} ne '') {
809                     warn <<SHRDLU_4a;
810 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
811 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
812 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
813 SHRDLU_4a
814                 } else {
815                     warn <<SHRDLU_4b;
816 ###   setenv $p `pwd`; cd t; ./perl harness
817 ###   $p=`pwd`; export $p; cd t; ./perl harness
818 ###   export $p=`pwd`; cd t; ./perl harness
819 SHRDLU_4b
820                 }
821                 warn <<SHRDLU_5;
822 ### for csh-style shells, like tcsh; or for traditional/modern
823 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
824 SHRDLU_5
825             }
826         }
827     }
828     my ($user,$sys,$cuser,$csys) = times;
829     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
830                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
831     print "$tot\n";
832     if ($good_files) {
833         if (-d $show_elapsed_time) {
834             # HARNESS_TIMER = <a-directory>.  Save timings etc to
835             # storable file there.  NB: the test cds to ./t/, so
836             # relative path must account for that, ie ../../perf
837             # points to dir next to source tree.
838             require Storable;
839             my @dt = localtime;
840             $dt[5] += 1900; $dt[4] += 1; # fix year, month
841             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
842             Storable::store({ perf => \%timings,
843                               gather_conf_platform_info(),
844                               total => $tot,
845                             }, $fn);
846             print "wrote storable file: $fn\n";
847         }
848     }
849     if ($ENV{PERL_VALGRIND}) {
850         my $s = $grind_ct == 1 ? '' : 's';
851         print "$grind_ct valgrind report$s created.\n", ;
852         if ($toolnm eq 'cachegrind') {
853             # cachegrind leaves a lot of cachegrind.out.$pid litter
854             # around the tree, find and delete them
855             unlink _find_files('cachegrind.out.\d+$',
856                              qw ( ../t ../cpan ../ext ../dist/ ));
857         }
858     }
859 }
860 exit ($::bad_files != 0);
861
862 # Collect platform, config data that should allow comparing
863 # performance data between different machines.  With enough data,
864 # and/or clever statistical analysis, it should be possible to
865 # determine the effect of config choices, more memory, etc
866
867 sub gather_conf_platform_info {
868     # currently rather quick & dirty, and subject to change
869     # for both content and format.
870     require Config;
871     my (%conf, @platform) = ();
872     $conf{$_} = $Config::Config{$_} for
873         grep /cc|git|config_arg\d+/, keys %Config::Config;
874     if (-f '/proc/cpuinfo') {
875         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
876         @platform = grep /name|cpu/, <$fh>;
877         chomp $_ for @platform;
878     }
879     unshift @platform, $^O;
880
881     return (
882         conf => \%conf,
883         platform => {cpu => \@platform,
884                      mem => [ grep s/\s+/ /,
885                               grep chomp, `free` ],
886                      load => [ grep chomp, `uptime` ],
887         },
888         host => (grep chomp, `hostname -f`),
889         version => '0.03', # bump for conf, platform, or data collection changes
890         );
891 }
892
893 # ex: set ts=8 sts=4 sw=4 noet: