This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
valgrind update
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.
5
6 $| = 1;
7
8 # Let tests know they're running in the perl core.  Useful for modules
9 # which live dual lives on CPAN.
10 $ENV{PERL_CORE} = 1;
11
12 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
13 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
14
15 # Cheesy version of Getopt::Std.  Maybe we should replace it with that.
16 @argv = ();
17 if ($#ARGV >= 0) {
18     foreach my $idx (0..$#ARGV) {
19         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
20         $core    = 1 if $1 eq 'core';
21         $verbose = 1 if $1 eq 'v';
22         $torture = 1 if $1 eq 'torture';
23         $with_utf= 1 if $1 eq 'utf8';
24         $bytecompile = 1 if $1 eq 'bytecompile';
25         $compile = 1 if $1 eq 'compile';
26         if ($1 =~ /^deparse(,.+)?$/) {
27             $deparse = 1;
28             $deparse_opts = $1;
29         }
30     }
31 }
32 @ARGV = @argv;
33
34 chdir 't' if -f 't/TEST';
35
36 die "You need to run \"make test\" first to set things up.\n"
37   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
38
39 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
40     unless (-x 'perl.third') {
41         unless (-x '../perl.third') {
42             die "You need to run \"make perl.third first.\n";
43         }
44         else {
45             print "Symlinking ../perl.third as perl.third...\n";
46             die "Failed to symlink: $!\n"
47                 unless symlink("../perl.third", "perl.third");
48             die "Symlinked but no executable perl.third: $!\n"
49                 unless -x 'perl.third';
50         }
51     }
52 }
53
54 # check leakage for embedders
55 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
56
57 $ENV{EMXSHELL} = 'sh';        # For OS/2
58
59 # Roll your own File::Find!
60 use TestInit;
61 use File::Spec;
62 my $curdir = File::Spec->curdir;
63 my $updir  = File::Spec->updir;
64
65 sub _find_tests {
66     my($dir) = @_;
67     opendir DIR, $dir or die "Trouble opening $dir: $!";
68     foreach my $f (sort { $a cmp $b } readdir DIR) {
69         next if $f eq $curdir or $f eq $updir;
70
71         my $fullpath = File::Spec->catfile($dir, $f);
72
73         _find_tests($fullpath) if -d $fullpath;
74         $fullpath = VMS::Filespec::unixify($fullpath) if $^O eq 'VMS';
75         push @ARGV, $fullpath if $f =~ /\.t$/;
76     }
77 }
78
79 sub _quote_args {
80     my ($args) = @_;
81     my $argstring = '';
82
83     foreach (split(/\s+/,$args)) {
84        # In VMS protect with doublequotes because otherwise
85        # DCL will lowercase -- unless already doublequoted.
86        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
87        $argstring .= ' ' . $_;
88     }
89     return $argstring;
90 }
91
92 unless (@ARGV) {
93     foreach my $dir (qw(base comp cmd run io op uni)) {
94         _find_tests($dir);
95     }
96     _find_tests("lib") unless $core;
97     my $mani = File::Spec->catfile($updir, "MANIFEST");
98     if (open(MANI, $mani)) {
99         while (<MANI>) { # similar code in t/harness
100             if (m!^(ext/\S+/?(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
101                 $t = $1;
102                 if (!$core || $t =~ m!^lib/[a-z]!)
103                 {
104                     $path = File::Spec->catfile($updir, $t);
105                     push @ARGV, $path;
106                     $name{$path} = $t;
107                 }
108             }
109         }
110         close MANI;
111     } else {
112         warn "$0: cannot open $mani: $!\n";
113     }
114     unless ($core) {
115         _find_tests('pod');
116         _find_tests('x2p');
117         _find_tests('japh') if $torture;
118     }
119 }
120
121 # Tests known to cause infinite loops for the perlcc tests.
122 # %infinite = ( 'comp/require.t', 1, 'op/bop.t', 1, 'lib/hostname.t', 1 );
123 %infinite = ();
124
125 if ($deparse) {
126     _testprogs('deparse', '',   @ARGV);
127 }
128 elsif( $compile ) { 
129     _testprogs('compile', '',   @ARGV);
130 }
131 elsif( $bytecompile ) {
132     _testprogs('bytecompile', '', @ARGV);
133 }
134 else {
135     _testprogs('compile', '',   @ARGV) if -e "../testcompile";
136     _testprogs('perl',    '',   @ARGV);
137 }
138
139 sub _testprogs {
140     $type = shift @_;
141     $args = shift;
142     @tests = @_;
143
144     print <<'EOT' if ($type eq 'compile');
145 ------------------------------------------------------------------------------
146 TESTING COMPILER
147 ------------------------------------------------------------------------------
148 EOT
149
150     print <<'EOT' if ($type eq 'deparse');
151 ------------------------------------------------------------------------------
152 TESTING DEPARSER
153 ------------------------------------------------------------------------------
154 EOT
155
156     print <<EOT if ($type eq 'bytecompile');
157 ------------------------------------------------------------------------------
158 TESTING BYTECODE COMPILER
159 ------------------------------------------------------------------------------
160 EOT
161
162     $ENV{PERLCC_TIMEOUT} = 120
163           if ($type eq 'compile' && !$ENV{PERLCC_TIMEOUT});
164
165     $bad = 0;
166     $good = 0;
167     $total = @tests;
168     $files  = 0;
169     $totmax = 0;
170
171     foreach my $t (@tests) {
172       unless (exists $name{$t}) {
173         my $tname = File::Spec->catfile('t',$t);
174         $tname = VMS::Filespec::unixify($tname) if $^O eq 'VMS';
175         $name{$t} = $tname;
176       }
177     }
178     my $maxlen = 0;
179     foreach (@name{@tests}) {
180         s/\.\w+\z/./;
181         my $len = length ;
182         $maxlen = $len if $len > $maxlen;
183     }
184     # + 3 : we want three dots between the test name and the "ok"
185     $dotdotdot = $maxlen + 3 ;
186     my $valgrind = 0;
187     my $valgrind_log = 'current.valgrind';
188     while ($test = shift @tests) {
189
190         if ( $infinite{$test} && $type eq 'compile' ) {
191             print STDERR "$test creates infinite loop! Skipping.\n";
192             next;
193         }
194         if ($test =~ /^$/) {
195             next;
196         }
197         if ($type eq 'deparse') {
198             if ($test eq "comp/redef.t") {
199                 # Redefinition happens at compile time
200                 next;
201             }
202             elsif ($test =~ m{lib/Switch/t/}) {
203                 # B::Deparse doesn't support source filtering
204                 next;
205             }
206         }
207         $te = $name{$test} . '.' x ($dotdotdot - length($name{$test}));
208
209         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
210             print $te;
211             $te = '';
212         }
213
214         $test = $OVER{$test} if exists $OVER{$test};
215
216         open(SCRIPT,"<$test") or die "Can't run $test.\n";
217         $_ = <SCRIPT>;
218         close(SCRIPT) unless ($type eq 'deparse');
219         if (/#!.*\bperl.*\s-\w*([tT])/) {
220             $switch = qq{"-$1"};
221         }
222         else {
223             $switch = '';
224         }
225
226         my $test_executable; # for 'compile' tests
227         my $file_opts = "";
228         if ($type eq 'deparse') {
229             # Look for #line directives which change the filename
230             while (<SCRIPT>) {
231                 $file_opts .= ",-f$3$4"
232                         if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
233             }
234             close(SCRIPT);
235         }
236
237         my $utf = $with_utf ? '-I../lib -Mutf8' : '';
238         my $testswitch = '-I. -MTestInit'; # -T will strict . from @INC
239         if ($type eq 'deparse') {
240             my $deparse =
241                 "./perl $testswitch $switch -I../lib -MO=-qq,Deparse,-sv1.,".
242                 "-l$deparse_opts$file_opts ".
243                 "$test > $test.dp ".
244                 "&& ./perl $testswitch $switch -I../lib $test.dp |";
245             open(RESULTS, $deparse)
246                 or print "can't deparse '$deparse': $!.\n";
247         }
248         elsif ($type eq 'bytecompile') {
249             my $perl = $ENV{PERL} || './perl';
250             my $redir = ($^O eq 'VMS' ? '2>&1' : '');
251             my $bswitch = "-MO=Bytecode,-H,-TI,-s`pwd`/$test,";
252             $bswitch .= "-TF$test.plc,"
253                 if $test =~ m(chdir|pod/|CGI/t/carp|lib/DB);
254             $bswitch .= "-k,"
255                 if $test =~ m(deparse|terse|ext/Storable/t/code);
256             $bswitch .= "-b,"
257                 if $test =~ m(op/getpid);
258             my $bytecompile =
259                 "$perl $testswitch $switch -I../lib $bswitch". 
260                 "-o$test.plc $test 2>/dev/null &&".
261                 "$perl $testswitch $switch -I../lib $utf $test.plc $redir|";
262             open(RESULTS,$bytecompile)
263                 or print "can't byte-compile '$bytecompile': $!.\n";
264         }
265         elsif ($type eq 'perl') {
266             my $perl = $ENV{PERL} || './perl';
267             my $redir = $^O eq 'VMS' ? '2>&1' : '';
268             if ($ENV{PERL_VALGRIND}) {
269                 $perl = "valgrind --suppressions=perl.supp --leak-check=yes "
270                                . "--leak-resolution=high --show-reachable=yes "
271                                . "--num-callers=50 --logfile-fd=3 $perl";
272                 $redir = "3>$valgrind_log";
273             }
274             my $run = "$perl" . _quote_args("$testswitch $switch $utf") . " $test $redir|";
275             open(RESULTS,$run) or print "can't run '$run': $!.\n";
276         }
277         else {
278             my $compile;
279             my $pl2c = "$testswitch -I../lib ../utils/perlcc --testsuite " .
280               # -O9 for good measure, -fcog is broken ATM
281                        "$switch -Wb=-O9,-fno-cog -L .. " .
282                        "-I \".. ../lib/CORE\" $args $utf $test -o ";
283
284             if( $^O eq 'MSWin32' ) {
285                 $test_executable = "$test.exe";
286                 # hopefully unused name...
287                 open HACK, "> xweghyz.pl";
288                 print HACK <<EOT;
289 #!./perl
290
291 open HACK, '.\\perl $pl2c $test_executable |';
292 # cl.exe prints the name of the .c file on stdout (\%^\$^#)
293 while(<HACK>) {m/^\\w+\\.[cC]\$/ && next;print}
294 open HACK, '$test_executable |';
295 while(<HACK>) {print}
296 EOT
297                 close HACK;
298                 $compile = 'xweghyz.pl |';
299             }
300             else {
301                 $test_executable = "$test.plc";
302                 $compile = "./perl $pl2c $test_executable && $test_executable |";
303             }
304             unlink $test_executable if -f $test_executable;
305             open(RESULTS, $compile)
306                 or print "can't compile '$compile': $!.\n";
307         }
308
309         $ok = 0;
310         $next = 0;
311         my $seen_leader = 0;
312         my $seen_ok = 0;
313         while (<RESULTS>) {
314             next if /^\s*$/; # skip blank lines
315             if ($verbose) {
316                 print $_;
317             }
318             unless (/^\#/) {
319                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
320                     $max = $1;
321                     %todo = map { $_ => 1 } split / /, $3 if $3;
322                     $totmax += $max;
323                     $files += 1;
324                     unless ($seen_ok) {
325                       $next = 1;
326                       $ok = 1;
327                     }
328                     $seen_leader = 1;
329                 }
330                 else {
331                     if (/^(not )?ok (\d+)[^\#]*(\s*\#.*)?/) {
332                         unless ($seen_leader) {
333                             unless ($seen_ok) {
334                                 $next = 1;
335                                 $ok = 1;
336                             }
337                         }
338                         $seen_ok = 1;
339                         if ($2 == $next) {
340                             my($not, $num, $extra) = ($1, $2, $3);
341                             my($istodo) = $extra =~ /^\s*#\s*TODO/ if $extra;
342                             $istodo = 1 if $todo{$num};
343
344                             if( $not && !$istodo ) {
345                                 $ok = 0;
346                                 $next = $num;
347                                 last;
348                             }
349                             else {
350                                 $next = $next + 1;
351                             }
352                         }
353                     }
354                     elsif (/^Bail out!\s*(.*)/i) { # magic words
355                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
356                     }
357                     else {
358                         $ok = 0;
359                     }
360                 }
361             }
362         }
363         close RESULTS;
364         if ($ENV{PERL_VALGRIND}) {
365             my @valgrind;
366             if (-e $valgrind_log) {
367                 if (open(V, $valgrind_log)) {
368                     @valgrind = <V>;
369                     close V;
370                 } else {
371                     warn "$0: Failed to open '$valgrind_log': $!\n";
372                 }
373             }
374             if (@valgrind) {
375                 my $leaks = 0;
376                 my $errors = 0;
377                 for my $i (0..$#valgrind) {
378                     local $_ = $valgrind[$i];
379                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
380                         $errors += $1;   # there may be multiple error summaries
381                     } elsif (/^==\d+== LEAK SUMMARY:/) {
382                         for my $off (1 .. 4) {
383                             if ($valgrind[$i+$off] =~
384                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
385                                 $leaks += $1;
386                             }
387                         }
388                     }
389                 }
390                 if ($errors or $leaks) {
391                     if (rename $valgrind_log, "$test.valgrind") {
392                         $valgrind++;
393                     } else {
394                         warn "$0: Failed to create '$test.valgrind': $!\n";
395                     }
396                 }
397             } else {
398                 warn "No valgrind output?\n";
399             }
400             if (-e $valgrind_log) {
401                 unlink $valgrind_log
402                     or warn "$0: Failed to unlink '$valgrind_log': $!\n";
403             }
404         }
405         if ($type eq 'deparse') {
406             unlink "./$test.dp";
407         }
408         if ($ENV{PERL_3LOG}) {
409             my $tpp = $test;
410             $tpp =~ s:^\.\./::;
411             $tpp =~ s:/:_:g;
412             $tpp =~ s:\.t$:.3log:;
413             rename("perl.3log", $tpp) ||
414                 die "rename: perl3.log to $tpp: $!\n";
415         }
416         $next = $next - 1;
417         # test if the compiler compiled something
418         if( $type eq 'compile' && !-e "$test_executable" ) {
419             $ok = 0;
420             print "Test did not compile\n";
421         }
422         if ($ok && $next == $max ) {
423             if ($max) {
424                 print "${te}ok\n";
425                 $good = $good + 1;
426             }
427             else {
428                 print "${te}skipping test on this platform\n";
429                 $files -= 1;
430             }
431         }
432         else {
433             $next += 1;
434             print "${te}FAILED at test $next\n";
435             $bad = $bad + 1;
436             $_ = $test;
437             if (/^base/) {
438                 die "Failed a basic test--cannot continue.\n";
439             }
440         }
441     }
442
443     if ($bad == 0) {
444         if ($ok) {
445             print "All tests successful.\n";
446             # XXX add mention of 'perlbug -ok' ?
447         }
448         else {
449             die "FAILED--no tests were run for some reason.\n";
450         }
451     }
452     else {
453         $pct = $files ? sprintf("%.2f", ($files - $bad) / $files * 100) : "0.00";
454         if ($bad == 1) {
455             warn "Failed 1 test script out of $files, $pct% okay.\n";
456         }
457         else {
458             warn "Failed $bad test scripts out of $files, $pct% okay.\n";
459         }
460         warn <<'SHRDLU_1';
461 ### Since not all tests were successful, you may want to run some of
462 ### them individually and examine any diagnostic messages they produce.
463 ### See the INSTALL document's section on "make test".
464 SHRDLU_1
465         warn <<'SHRDLU_2' if $good / $total > 0.8;
466 ### You have a good chance to get more information by running
467 ###   ./perl harness
468 ### in the 't' directory since most (>=80%) of the tests succeeded.
469 SHRDLU_2
470         if (eval {require Config; import Config; 1}) {
471             if ($Config{usedl} && (my $p = $Config{ldlibpthname})) {
472                 warn <<SHRDLU_3;
473 ### You may have to set your dynamic library search path,
474 ### $p, to point to the build directory:
475 SHRDLU_3
476                 if (exists $ENV{$p} && $ENV{$p} ne '') {
477                     warn <<SHRDLU_4a;
478 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
479 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
480 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
481 SHRDLU_4a
482                 } else {
483                     warn <<SHRDLU_4b;
484 ###   setenv $p `pwd`; cd t; ./perl harness
485 ###   $p=`pwd`; export $p; cd t; ./perl harness
486 ###   export $p=`pwd`; cd t; ./perl harness
487 SHRDLU_4b
488                 }    
489                 warn <<SHRDLU_5;
490 ### for csh-style shells, like tcsh; or for traditional/modern
491 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
492 SHRDLU_5
493             }
494         }
495     }
496     ($user,$sys,$cuser,$csys) = times;
497     print sprintf("u=%g  s=%g  cu=%g  cs=%g  scripts=%d  tests=%d\n",
498         $user,$sys,$cuser,$csys,$files,$totmax);
499     if ($ENV{PERL_VALGRIND}) {
500         my $s = $valgrind == 1 ? '' : 's';
501         print "$valgrind valgrind report$s created.\n", ;
502     }
503 }
504 exit ($bad != 0);