This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
da1502a0e9f6ba29e827dc17f3b90e9229af18a0
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
111 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed-length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>,
165 C<dump>, C<eval>, C<evalbytes> C<exit>,
166 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
167 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
168
169 C<__SUB__> is only available with a C<use v5.16> (or higher) declaration or
170 with the C<"current_sub"> feature (see L<feature>).
171
172 =item Keywords related to the switch feature
173
174 C<break>, C<continue>, C<default>, C<given>, C<when>
175
176 Except for C<continue>, these are available only if you enable the
177 C<"switch"> feature or use the C<CORE::> prefix.
178 See L<feature> and L<perlsyn/"Switch Statements">.  
179 Alternately, include a C<use v5.10> or later to the current scope.  In Perl
180 5.14 and earlier, C<continue> required the C<"switch"> feature, like the
181 other keywords.
182
183 =item Keywords related to scoping
184
185 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
186
187 C<state> is available only if the C<"state"> feature
188 is enabled or if it is prefixed with C<CORE::>.  See
189 L<feature>.  Alternately, include a C<use v5.10> or later to the current scope.
190
191 =item Miscellaneous functions
192
193 C<defined>, C<dump>, C<eval>, C<evalbytes>,
194 C<formline>, C<local>, C<my>, C<our>,
195 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
196
197 =item Functions for processes and process groups
198 X<process> X<pid> X<process id>
199
200 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
201 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
202 C<setpriority>, C<sleep>, C<system>,
203 C<times>, C<wait>, C<waitpid>
204
205 =item Keywords related to Perl modules
206 X<module>
207
208 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
209
210 =item Keywords related to classes and object-orientation
211 X<object> X<class> X<package>
212
213 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
214 C<untie>, C<use>
215
216 =item Low-level socket functions
217 X<socket> X<sock>
218
219 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
220 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
221 C<socket>, C<socketpair>
222
223 =item System V interprocess communication functions
224 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
225
226 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
227 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
228
229 =item Fetching user and group info
230 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
231
232 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
233 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
234 C<getpwuid>, C<setgrent>, C<setpwent>
235
236 =item Fetching network info
237 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
238
239 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
240 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
241 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
242 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
243 C<setnetent>, C<setprotoent>, C<setservent>
244
245 =item Time-related functions
246 X<time> X<date>
247
248 C<gmtime>, C<localtime>, C<time>, C<times>
249
250 =item Non-function keywords
251
252 C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<CORE>, C<DESTROY>, C<END>, C<INIT>,
253 C<UNITCHECK>, C<__DATA__>, C<__END__>, C<and>, C<cmp>, C<else>, C<elseif>,
254 C<elsif>, C<eq>, C<for>, C<foreach>, C<ge>, C<gt>, C<if>, C<le>, C<lt>, C<ne>,
255 C<not>, C<or>, C<unless>, C<until>, C<while>, C<x>, C<xor>
256
257 =back
258
259 =head2 Portability
260 X<portability> X<Unix> X<portable>
261
262 Perl was born in Unix and can therefore access all common Unix
263 system calls.  In non-Unix environments, the functionality of some
264 Unix system calls may not be available or details of the available
265 functionality may differ slightly.  The Perl functions affected
266 by this are:
267
268 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
269 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
270 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
271 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
272 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
273 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
274 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
275 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
276 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
277 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
278 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
279 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
280 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
281 C<shmwrite>, C<socket>, C<socketpair>,
282 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
283 C<times>, C<truncate>, C<umask>, C<unlink>,
284 C<utime>, C<wait>, C<waitpid>
285
286 For more information about the portability of these functions, see
287 L<perlport> and other available platform-specific documentation.
288
289 =head2 Alphabetical Listing of Perl Functions
290
291 =over 
292
293 =item -X FILEHANDLE
294 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
295 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
296
297 =item -X EXPR
298
299 =item -X DIRHANDLE
300
301 =item -X
302
303 A file test, where X is one of the letters listed below.  This unary
304 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
305 and tests the associated file to see if something is true about it.  If the
306 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
307 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
308 the undefined value if the file doesn't exist.  Despite the funny
309 names, precedence is the same as any other named unary operator.  The
310 operator may be any of:
311
312     -r  File is readable by effective uid/gid.
313     -w  File is writable by effective uid/gid.
314     -x  File is executable by effective uid/gid.
315     -o  File is owned by effective uid.
316
317     -R  File is readable by real uid/gid.
318     -W  File is writable by real uid/gid.
319     -X  File is executable by real uid/gid.
320     -O  File is owned by real uid.
321
322     -e  File exists.
323     -z  File has zero size (is empty).
324     -s  File has nonzero size (returns size in bytes).
325
326     -f  File is a plain file.
327     -d  File is a directory.
328     -l  File is a symbolic link.
329     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
330     -S  File is a socket.
331     -b  File is a block special file.
332     -c  File is a character special file.
333     -t  Filehandle is opened to a tty.
334
335     -u  File has setuid bit set.
336     -g  File has setgid bit set.
337     -k  File has sticky bit set.
338
339     -T  File is an ASCII text file (heuristic guess).
340     -B  File is a "binary" file (opposite of -T).
341
342     -M  Script start time minus file modification time, in days.
343     -A  Same for access time.
344     -C  Same for inode change time (Unix, may differ for other platforms)
345
346 Example:
347
348     while (<>) {
349         chomp;
350         next unless -f $_;  # ignore specials
351         #...
352     }
353
354 Note that C<-s/a/b/> does not do a negated substitution.  Saying
355 C<-exp($foo)> still works as expected, however: only single letters
356 following a minus are interpreted as file tests.
357
358 These operators are exempt from the "looks like a function rule" described
359 above.  That is, an opening parenthesis after the operator does not affect
360 how much of the following code constitutes the argument.  Put the opening
361 parentheses before the operator to separate it from code that follows (this
362 applies only to operators with higher precedence than unary operators, of
363 course):
364
365     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
366     (-s $file) + 1024  # correct
367
368 The interpretation of the file permission operators C<-r>, C<-R>,
369 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
370 of the file and the uids and gids of the user.  There may be other
371 reasons you can't actually read, write, or execute the file: for
372 example network filesystem access controls, ACLs (access control lists),
373 read-only filesystems, and unrecognized executable formats.  Note
374 that the use of these six specific operators to verify if some operation
375 is possible is usually a mistake, because it may be open to race
376 conditions.
377
378 Also note that, for the superuser on the local filesystems, the C<-r>,
379 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
380 if any execute bit is set in the mode.  Scripts run by the superuser
381 may thus need to do a stat() to determine the actual mode of the file,
382 or temporarily set their effective uid to something else.
383
384 If you are using ACLs, there is a pragma called C<filetest> that may
385 produce more accurate results than the bare stat() mode bits.
386 When under C<use filetest 'access'> the above-mentioned filetests
387 test whether the permission can(not) be granted using the
388 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
389 under this pragma return true even if there are no execute permission
390 bits set (nor any extra execute permission ACLs).  This strangeness is
391 due to the underlying system calls' definitions.  Note also that, due to
392 the implementation of C<use filetest 'access'>, the C<_> special
393 filehandle won't cache the results of the file tests when this pragma is
394 in effect.  Read the documentation for the C<filetest> pragma for more
395 information.
396
397 The C<-T> and C<-B> switches work as follows.  The first block or so of the
398 file is examined for odd characters such as strange control codes or
399 characters with the high bit set.  If too many strange characters (>30%)
400 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
401 containing a zero byte in the first block is considered a binary file.  If C<-T>
402 or C<-B> is used on a filehandle, the current IO buffer is examined
403 rather than the first block.  Both C<-T> and C<-B> return true on an empty
404 file, or a file at EOF when testing a filehandle.  Because you have to
405 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
406 against the file first, as in C<next unless -f $file && -T $file>.
407
408 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
409 the special filehandle consisting of a solitary underline, then the stat
410 structure of the previous file test (or stat operator) is used, saving
411 a system call.  (This doesn't work with C<-t>, and you need to remember
412 that lstat() and C<-l> leave values in the stat structure for the
413 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
414 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
415 Example:
416
417     print "Can do.\n" if -r $a || -w _ || -x _;
418
419     stat($filename);
420     print "Readable\n" if -r _;
421     print "Writable\n" if -w _;
422     print "Executable\n" if -x _;
423     print "Setuid\n" if -u _;
424     print "Setgid\n" if -g _;
425     print "Sticky\n" if -k _;
426     print "Text\n" if -T _;
427     print "Binary\n" if -B _;
428
429 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
430 test operators, in a way that C<-f -w -x $file> is equivalent to
431 C<-x $file && -w _ && -f _>.  (This is only fancy fancy: if you use
432 the return value of C<-f $file> as an argument to another filetest
433 operator, no special magic will happen.)
434
435 Portability issues: L<perlport/-X>.
436
437 To avoid confusing would-be users of your code with mysterious
438 syntax errors, put something like this at the top of your script:
439
440     use 5.010;  # so filetest ops can stack
441
442 =item abs VALUE
443 X<abs> X<absolute>
444
445 =item abs
446
447 Returns the absolute value of its argument.
448 If VALUE is omitted, uses C<$_>.
449
450 =item accept NEWSOCKET,GENERICSOCKET
451 X<accept>
452
453 Accepts an incoming socket connect, just as accept(2) 
454 does.  Returns the packed address if it succeeded, false otherwise.
455 See the example in L<perlipc/"Sockets: Client/Server Communication">.
456
457 On systems that support a close-on-exec flag on files, the flag will
458 be set for the newly opened file descriptor, as determined by the
459 value of $^F.  See L<perlvar/$^F>.
460
461 =item alarm SECONDS
462 X<alarm>
463 X<SIGALRM>
464 X<timer>
465
466 =item alarm
467
468 Arranges to have a SIGALRM delivered to this process after the
469 specified number of wallclock seconds has elapsed.  If SECONDS is not
470 specified, the value stored in C<$_> is used.  (On some machines,
471 unfortunately, the elapsed time may be up to one second less or more
472 than you specified because of how seconds are counted, and process
473 scheduling may delay the delivery of the signal even further.)
474
475 Only one timer may be counting at once.  Each call disables the
476 previous timer, and an argument of C<0> may be supplied to cancel the
477 previous timer without starting a new one.  The returned value is the
478 amount of time remaining on the previous timer.
479
480 For delays of finer granularity than one second, the Time::HiRes module
481 (from CPAN, and starting from Perl 5.8 part of the standard
482 distribution) provides ualarm().  You may also use Perl's four-argument
483 version of select() leaving the first three arguments undefined, or you
484 might be able to use the C<syscall> interface to access setitimer(2) if
485 your system supports it.  See L<perlfaq8> for details.
486
487 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
488 C<sleep> may be internally implemented on your system with C<alarm>.
489
490 If you want to use C<alarm> to time out a system call you need to use an
491 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
492 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
493 restart system calls on some systems.  Using C<eval>/C<die> always works,
494 modulo the caveats given in L<perlipc/"Signals">.
495
496     eval {
497         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
498         alarm $timeout;
499         $nread = sysread SOCKET, $buffer, $size;
500         alarm 0;
501     };
502     if ($@) {
503         die unless $@ eq "alarm\n";   # propagate unexpected errors
504         # timed out
505     }
506     else {
507         # didn't
508     }
509
510 For more information see L<perlipc>.
511
512 Portability issues: L<perlport/alarm>.
513
514 =item atan2 Y,X
515 X<atan2> X<arctangent> X<tan> X<tangent>
516
517 Returns the arctangent of Y/X in the range -PI to PI.
518
519 For the tangent operation, you may use the C<Math::Trig::tan>
520 function, or use the familiar relation:
521
522     sub tan { sin($_[0]) / cos($_[0])  }
523
524 The return value for C<atan2(0,0)> is implementation-defined; consult
525 your atan2(3) manpage for more information.
526
527 Portability issues: L<perlport/atan2>.
528
529 =item bind SOCKET,NAME
530 X<bind>
531
532 Binds a network address to a socket, just as bind(2)
533 does.  Returns true if it succeeded, false otherwise.  NAME should be a
534 packed address of the appropriate type for the socket.  See the examples in
535 L<perlipc/"Sockets: Client/Server Communication">.
536
537 =item binmode FILEHANDLE, LAYER
538 X<binmode> X<binary> X<text> X<DOS> X<Windows>
539
540 =item binmode FILEHANDLE
541
542 Arranges for FILEHANDLE to be read or written in "binary" or "text"
543 mode on systems where the run-time libraries distinguish between
544 binary and text files.  If FILEHANDLE is an expression, the value is
545 taken as the name of the filehandle.  Returns true on success,
546 otherwise it returns C<undef> and sets C<$!> (errno).
547
548 On some systems (in general, DOS- and Windows-based systems) binmode()
549 is necessary when you're not working with a text file.  For the sake
550 of portability it is a good idea always to use it when appropriate,
551 and never to use it when it isn't appropriate.  Also, people can
552 set their I/O to be by default UTF8-encoded Unicode, not bytes.
553
554 In other words: regardless of platform, use binmode() on binary data,
555 like images, for example.
556
557 If LAYER is present it is a single string, but may contain multiple
558 directives.  The directives alter the behaviour of the filehandle.
559 When LAYER is present, using binmode on a text file makes sense.
560
561 If LAYER is omitted or specified as C<:raw> the filehandle is made
562 suitable for passing binary data.  This includes turning off possible CRLF
563 translation and marking it as bytes (as opposed to Unicode characters).
564 Note that, despite what may be implied in I<"Programming Perl"> (the
565 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
566 Other layers that would affect the binary nature of the stream are
567 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
568 PERLIO environment variable.
569
570 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
571 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
572 establish default I/O layers.  See L<open>.
573
574 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
575 in "Programming Perl, 3rd Edition".  However, since the publishing of this
576 book, by many known as "Camel III", the consensus of the naming of this
577 functionality has moved from "discipline" to "layer".  All documentation
578 of this version of Perl therefore refers to "layers" rather than to
579 "disciplines".  Now back to the regularly scheduled documentation...>
580
581 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
582 C<:utf8> just marks the data as UTF-8 without further checking,
583 while C<:encoding(UTF-8)> checks the data for actually being valid
584 UTF-8.  More details can be found in L<PerlIO::encoding>.
585
586 In general, binmode() should be called after open() but before any I/O
587 is done on the filehandle.  Calling binmode() normally flushes any
588 pending buffered output data (and perhaps pending input data) on the
589 handle.  An exception to this is the C<:encoding> layer that
590 changes the default character encoding of the handle; see L</open>.
591 The C<:encoding> layer sometimes needs to be called in
592 mid-stream, and it doesn't flush the stream.  The C<:encoding>
593 also implicitly pushes on top of itself the C<:utf8> layer because
594 internally Perl operates on UTF8-encoded Unicode characters.
595
596 The operating system, device drivers, C libraries, and Perl run-time
597 system all conspire to let the programmer treat a single
598 character (C<\n>) as the line terminator, irrespective of external
599 representation.  On many operating systems, the native text file
600 representation matches the internal representation, but on some
601 platforms the external representation of C<\n> is made up of more than
602 one character.
603
604 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
605 a single character to end each line in the external representation of text
606 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
607 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
608 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
609 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
610 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
611 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
612 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
613 output.  This is what you want for text files, but it can be disastrous for
614 binary files.
615
616 Another consequence of using binmode() (on some systems) is that
617 special end-of-file markers will be seen as part of the data stream.
618 For systems from the Microsoft family this means that, if your binary
619 data contain C<\cZ>, the I/O subsystem will regard it as the end of
620 the file, unless you use binmode().
621
622 binmode() is important not only for readline() and print() operations,
623 but also when using read(), seek(), sysread(), syswrite() and tell()
624 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
625 in L<perlvar> for how to manually set your input and output
626 line-termination sequences.
627
628 Portability issues: L<perlport/binmode>.
629
630 =item bless REF,CLASSNAME
631 X<bless>
632
633 =item bless REF
634
635 This function tells the thingy referenced by REF that it is now an object
636 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
637 is used.  Because a C<bless> is often the last thing in a constructor,
638 it returns the reference for convenience.  Always use the two-argument
639 version if a derived class might inherit the function doing the blessing.
640 SeeL<perlobj> for more about the blessing (and blessings) of objects.
641
642 Consider always blessing objects in CLASSNAMEs that are mixed case.
643 Namespaces with all lowercase names are considered reserved for
644 Perl pragmata.  Builtin types have all uppercase names.  To prevent
645 confusion, you may wish to avoid such package names as well.  Make sure
646 that CLASSNAME is a true value.
647
648 See L<perlmod/"Perl Modules">.
649
650 =item break
651
652 Break out of a C<given()> block.
653
654 This keyword is enabled by the C<"switch"> feature: see
655 L<feature> for more information.  You can also access it by
656 prefixing it with C<CORE::>.  Alternately, include a C<use
657 v5.10> or later to the current scope.
658
659 =item caller EXPR
660 X<caller> X<call stack> X<stack> X<stack trace>
661
662 =item caller
663
664 Returns the context of the current subroutine call.  In scalar context,
665 returns the caller's package name if there I<is> a caller (that is, if
666 we're in a subroutine or C<eval> or C<require>) and the undefined value
667 otherwise.  In list context, returns
668
669     # 0         1          2
670     ($package, $filename, $line) = caller;
671
672 With EXPR, it returns some extra information that the debugger uses to
673 print a stack trace.  The value of EXPR indicates how many call frames
674 to go back before the current one.
675
676     #  0         1          2      3            4
677     ($package, $filename, $line, $subroutine, $hasargs,
678
679     #  5          6          7            8       9         10
680     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
681      = caller($i);
682
683 Here $subroutine may be C<(eval)> if the frame is not a subroutine
684 call, but an C<eval>.  In such a case additional elements $evaltext and
685 C<$is_require> are set: C<$is_require> is true if the frame is created by a
686 C<require> or C<use> statement, $evaltext contains the text of the
687 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
688 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
689 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
690 frame.)  $subroutine may also be C<(unknown)> if this particular
691 subroutine happens to have been deleted from the symbol table.
692 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
693 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
694 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
695 between versions of Perl, and are not meant for external use.
696
697 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
698 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
699 of this hash, as they are the actual values stored in the optree.
700
701 Furthermore, when called from within the DB package in
702 list context, and with an argument, caller returns more
703 detailed information: it sets the list variable C<@DB::args> to be the
704 arguments with which the subroutine was invoked.
705
706 Be aware that the optimizer might have optimized call frames away before
707 C<caller> had a chance to get the information.  That means that C<caller(N)>
708 might not return information about the call frame you expect it to, for
709 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
710 previous time C<caller> was called.
711
712 Be aware that setting C<@DB::args> is I<best effort>, intended for
713 debugging or generating backtraces, and should not be relied upon.  In
714 particular, as C<@_> contains aliases to the caller's arguments, Perl does
715 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
716 subroutine makes to C<@_> or its contents, not the original values at call
717 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
718 elements, so under certain cases its elements may have become freed and
719 reallocated for other variables or temporary values.  Finally, a side effect
720 of the current implementation is that the effects of C<shift @_> can
721 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
722 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
723 elements), so C<@DB::args> is actually a hybrid of the current state and
724 initial state of C<@_>.  Buyer beware.
725
726 =item chdir EXPR
727 X<chdir>
728 X<cd>
729 X<directory, change>
730
731 =item chdir FILEHANDLE
732
733 =item chdir DIRHANDLE
734
735 =item chdir
736
737 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
738 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
739 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
740 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
741 neither is set, C<chdir> does nothing.  It returns true on success,
742 false otherwise.  See the example under C<die>.
743
744 On systems that support fchdir(2), you may pass a filehandle or
745 directory handle as the argument.  On systems that don't support fchdir(2),
746 passing handles raises an exception.
747
748 =item chmod LIST
749 X<chmod> X<permission> X<mode>
750
751 Changes the permissions of a list of files.  The first element of the
752 list must be the numeric mode, which should probably be an octal
753 number, and which definitely should I<not> be a string of octal digits:
754 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
755 successfully changed.  See also L</oct> if all you have is a string.
756
757     $cnt = chmod 0755, "foo", "bar";
758     chmod 0755, @executables;
759     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
760                                              # --w----r-T
761     $mode = "0644"; chmod oct($mode), "foo"; # this is better
762     $mode = 0644;   chmod $mode, "foo";      # this is best
763
764 On systems that support fchmod(2), you may pass filehandles among the
765 files.  On systems that don't support fchmod(2), passing filehandles raises
766 an exception.  Filehandles must be passed as globs or glob references to be
767 recognized; barewords are considered filenames.
768
769     open(my $fh, "<", "foo");
770     my $perm = (stat $fh)[2] & 07777;
771     chmod($perm | 0600, $fh);
772
773 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
774 module:
775
776     use Fcntl qw( :mode );
777     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
778     # Identical to the chmod 0755 of the example above.
779
780 Portability issues: L<perlport/chmod>.
781
782 =item chomp VARIABLE
783 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
784
785 =item chomp( LIST )
786
787 =item chomp
788
789 This safer version of L</chop> removes any trailing string
790 that corresponds to the current value of C<$/> (also known as
791 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
792 number of characters removed from all its arguments.  It's often used to
793 remove the newline from the end of an input record when you're worried
794 that the final record may be missing its newline.  When in paragraph
795 mode (C<$/ = "">), it removes all trailing newlines from the string.
796 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
797 a reference to an integer or the like; see L<perlvar>) chomp() won't
798 remove anything.
799 If VARIABLE is omitted, it chomps C<$_>.  Example:
800
801     while (<>) {
802         chomp;  # avoid \n on last field
803         @array = split(/:/);
804         # ...
805     }
806
807 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
808
809 You can actually chomp anything that's an lvalue, including an assignment:
810
811     chomp($cwd = `pwd`);
812     chomp($answer = <STDIN>);
813
814 If you chomp a list, each element is chomped, and the total number of
815 characters removed is returned.
816
817 Note that parentheses are necessary when you're chomping anything
818 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
819 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
820 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
821 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
822 as C<chomp($a, $b)>.
823
824 =item chop VARIABLE
825 X<chop>
826
827 =item chop( LIST )
828
829 =item chop
830
831 Chops off the last character of a string and returns the character
832 chopped.  It is much more efficient than C<s/.$//s> because it neither
833 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
834 If VARIABLE is a hash, it chops the hash's values, but not its keys.
835
836 You can actually chop anything that's an lvalue, including an assignment.
837
838 If you chop a list, each element is chopped.  Only the value of the
839 last C<chop> is returned.
840
841 Note that C<chop> returns the last character.  To return all but the last
842 character, use C<substr($string, 0, -1)>.
843
844 See also L</chomp>.
845
846 =item chown LIST
847 X<chown> X<owner> X<user> X<group>
848
849 Changes the owner (and group) of a list of files.  The first two
850 elements of the list must be the I<numeric> uid and gid, in that
851 order.  A value of -1 in either position is interpreted by most
852 systems to leave that value unchanged.  Returns the number of files
853 successfully changed.
854
855     $cnt = chown $uid, $gid, 'foo', 'bar';
856     chown $uid, $gid, @filenames;
857
858 On systems that support fchown(2), you may pass filehandles among the
859 files.  On systems that don't support fchown(2), passing filehandles raises
860 an exception.  Filehandles must be passed as globs or glob references to be
861 recognized; barewords are considered filenames.
862
863 Here's an example that looks up nonnumeric uids in the passwd file:
864
865     print "User: ";
866     chomp($user = <STDIN>);
867     print "Files: ";
868     chomp($pattern = <STDIN>);
869
870     ($login,$pass,$uid,$gid) = getpwnam($user)
871         or die "$user not in passwd file";
872
873     @ary = glob($pattern);  # expand filenames
874     chown $uid, $gid, @ary;
875
876 On most systems, you are not allowed to change the ownership of the
877 file unless you're the superuser, although you should be able to change
878 the group to any of your secondary groups.  On insecure systems, these
879 restrictions may be relaxed, but this is not a portable assumption.
880 On POSIX systems, you can detect this condition this way:
881
882     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
883     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
884
885 Portability issues: L<perlport/chmod>.
886
887 =item chr NUMBER
888 X<chr> X<character> X<ASCII> X<Unicode>
889
890 =item chr
891
892 Returns the character represented by that NUMBER in the character set.
893 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
894 chr(0x263a) is a Unicode smiley face.  
895
896 Negative values give the Unicode replacement character (chr(0xfffd)),
897 except under the L<bytes> pragma, where the low eight bits of the value
898 (truncated to an integer) are used.
899
900 If NUMBER is omitted, uses C<$_>.
901
902 For the reverse, use L</ord>.
903
904 Note that characters from 128 to 255 (inclusive) are by default
905 internally not encoded as UTF-8 for backward compatibility reasons.
906
907 See L<perlunicode> for more about Unicode.
908
909 =item chroot FILENAME
910 X<chroot> X<root>
911
912 =item chroot
913
914 This function works like the system call by the same name: it makes the
915 named directory the new root directory for all further pathnames that
916 begin with a C</> by your process and all its children.  (It doesn't
917 change your current working directory, which is unaffected.)  For security
918 reasons, this call is restricted to the superuser.  If FILENAME is
919 omitted, does a C<chroot> to C<$_>.
920
921 Portability issues: L<perlport/chroot>.
922
923 =item close FILEHANDLE
924 X<close>
925
926 =item close
927
928 Closes the file or pipe associated with the filehandle, flushes the IO
929 buffers, and closes the system file descriptor.  Returns true if those
930 operations succeed and if no error was reported by any PerlIO
931 layer.  Closes the currently selected filehandle if the argument is
932 omitted.
933
934 You don't have to close FILEHANDLE if you are immediately going to do
935 another C<open> on it, because C<open> closes it for you.  (See
936 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
937 counter (C<$.>), while the implicit close done by C<open> does not.
938
939 If the filehandle came from a piped open, C<close> returns false if one of
940 the other syscalls involved fails or if its program exits with non-zero
941 status.  If the only problem was that the program exited non-zero, C<$!>
942 will be set to C<0>.  Closing a pipe also waits for the process executing
943 on the pipe to exit--in case you wish to look at the output of the pipe
944 afterwards--and implicitly puts the exit status value of that command into
945 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
946
947 If there are multiple threads running, C<close> on a filehandle from a
948 piped open returns true without waiting for the child process to terminate,
949 if the filehandle is still open in another thread.
950
951 Closing the read end of a pipe before the process writing to it at the
952 other end is done writing results in the writer receiving a SIGPIPE.  If
953 the other end can't handle that, be sure to read all the data before
954 closing the pipe.
955
956 Example:
957
958     open(OUTPUT, '|sort >foo')  # pipe to sort
959         or die "Can't start sort: $!";
960     #...                        # print stuff to output
961     close OUTPUT                # wait for sort to finish
962         or warn $! ? "Error closing sort pipe: $!"
963                    : "Exit status $? from sort";
964     open(INPUT, 'foo')          # get sort's results
965         or die "Can't open 'foo' for input: $!";
966
967 FILEHANDLE may be an expression whose value can be used as an indirect
968 filehandle, usually the real filehandle name or an autovivified handle.
969
970 =item closedir DIRHANDLE
971 X<closedir>
972
973 Closes a directory opened by C<opendir> and returns the success of that
974 system call.
975
976 =item connect SOCKET,NAME
977 X<connect>
978
979 Attempts to connect to a remote socket, just like connect(2).
980 Returns true if it succeeded, false otherwise.  NAME should be a
981 packed address of the appropriate type for the socket.  See the examples in
982 L<perlipc/"Sockets: Client/Server Communication">.
983
984 =item continue BLOCK
985 X<continue>
986
987 =item continue
988
989 When followed by a BLOCK, C<continue> is actually a
990 flow control statement rather than a function.  If
991 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
992 C<foreach>), it is always executed just before the conditional is about to
993 be evaluated again, just like the third part of a C<for> loop in C.  Thus
994 it can be used to increment a loop variable, even when the loop has been
995 continued via the C<next> statement (which is similar to the C C<continue>
996 statement).
997
998 C<last>, C<next>, or C<redo> may appear within a C<continue>
999 block; C<last> and C<redo> behave as if they had been executed within
1000 the main block.  So will C<next>, but since it will execute a C<continue>
1001 block, it may be more entertaining.
1002
1003     while (EXPR) {
1004         ### redo always comes here
1005         do_something;
1006     } continue {
1007         ### next always comes here
1008         do_something_else;
1009         # then back the top to re-check EXPR
1010     }
1011     ### last always comes here
1012
1013 Omitting the C<continue> section is equivalent to using an
1014 empty one, logically enough, so C<next> goes directly back
1015 to check the condition at the top of the loop.
1016
1017 When there is no BLOCK, C<continue> is a function that
1018 falls through the current C<when> or C<default> block instead of iterating
1019 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1020 In Perl 5.14 and earlier, this form of C<continue> was
1021 only available when the C<"switch"> feature was enabled.
1022 See L<feature> and L<perlsyn/"Switch Statements"> for more
1023 information.
1024
1025 =item cos EXPR
1026 X<cos> X<cosine> X<acos> X<arccosine>
1027
1028 =item cos
1029
1030 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1031 takes the cosine of C<$_>.
1032
1033 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1034 function, or use this relation:
1035
1036     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1037
1038 =item crypt PLAINTEXT,SALT
1039 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1040 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1041
1042 Creates a digest string exactly like the crypt(3) function in the C
1043 library (assuming that you actually have a version there that has not
1044 been extirpated as a potential munition).
1045
1046 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1047 into a short string, called a digest, which is returned.  The same
1048 PLAINTEXT and SALT will always return the same string, but there is no
1049 (known) way to get the original PLAINTEXT from the hash.  Small
1050 changes in the PLAINTEXT or SALT will result in large changes in the
1051 digest.
1052
1053 There is no decrypt function.  This function isn't all that useful for
1054 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1055 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1056 primarily used to check if two pieces of text are the same without
1057 having to transmit or store the text itself.  An example is checking
1058 if a correct password is given.  The digest of the password is stored,
1059 not the password itself.  The user types in a password that is
1060 crypt()'d with the same salt as the stored digest.  If the two digests
1061 match, the password is correct.
1062
1063 When verifying an existing digest string you should use the digest as
1064 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1065 to create the digest is visible as part of the digest.  This ensures
1066 crypt() will hash the new string with the same salt as the digest.
1067 This allows your code to work with the standard L<crypt|/crypt> and
1068 with more exotic implementations.  In other words, assume
1069 nothing about the returned string itself nor about how many bytes 
1070 of SALT may matter.
1071
1072 Traditionally the result is a string of 13 bytes: two first bytes of
1073 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1074 the first eight bytes of PLAINTEXT mattered.  But alternative
1075 hashing schemes (like MD5), higher level security schemes (like C2),
1076 and implementations on non-Unix platforms may produce different
1077 strings.
1078
1079 When choosing a new salt create a random two character string whose
1080 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1081 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1082 characters is just a recommendation; the characters allowed in
1083 the salt depend solely on your system's crypt library, and Perl can't
1084 restrict what salts C<crypt()> accepts.
1085
1086 Here's an example that makes sure that whoever runs this program knows
1087 their password:
1088
1089     $pwd = (getpwuid($<))[1];
1090
1091     system "stty -echo";
1092     print "Password: ";
1093     chomp($word = <STDIN>);
1094     print "\n";
1095     system "stty echo";
1096
1097     if (crypt($word, $pwd) ne $pwd) {
1098         die "Sorry...\n";
1099     } else {
1100         print "ok\n";
1101     }
1102
1103 Of course, typing in your own password to whoever asks you
1104 for it is unwise.
1105
1106 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1107 of data, not least of all because you can't get the information
1108 back.  Look at the L<Digest> module for more robust algorithms.
1109
1110 If using crypt() on a Unicode string (which I<potentially> has
1111 characters with codepoints above 255), Perl tries to make sense
1112 of the situation by trying to downgrade (a copy of)
1113 the string back to an eight-bit byte string before calling crypt()
1114 (on that copy).  If that works, good.  If not, crypt() dies with
1115 C<Wide character in crypt>.
1116
1117 Portability issues: L<perlport/crypt>.
1118
1119 =item dbmclose HASH
1120 X<dbmclose>
1121
1122 [This function has been largely superseded by the C<untie> function.]
1123
1124 Breaks the binding between a DBM file and a hash.
1125
1126 Portability issues: L<perlport/dbmclose>.
1127
1128 =item dbmopen HASH,DBNAME,MASK
1129 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1130
1131 [This function has been largely superseded by the
1132 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1133
1134 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1135 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1136 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1137 is the name of the database (without the F<.dir> or F<.pag> extension if
1138 any).  If the database does not exist, it is created with protection
1139 specified by MASK (as modified by the C<umask>).  To prevent creation of
1140 the database if it doesn't exist, you may specify a MODE
1141 of 0, and the function will return a false value if it
1142 can't find an existing database.  If your system supports
1143 only the older DBM functions, you may make only one C<dbmopen> call in your
1144 program.  In older versions of Perl, if your system had neither DBM nor
1145 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1146 sdbm(3).
1147
1148 If you don't have write access to the DBM file, you can only read hash
1149 variables, not set them.  If you want to test whether you can write,
1150 either use file tests or try setting a dummy hash entry inside an C<eval> 
1151 to trap the error.
1152
1153 Note that functions such as C<keys> and C<values> may return huge lists
1154 when used on large DBM files.  You may prefer to use the C<each>
1155 function to iterate over large DBM files.  Example:
1156
1157     # print out history file offsets
1158     dbmopen(%HIST,'/usr/lib/news/history',0666);
1159     while (($key,$val) = each %HIST) {
1160         print $key, ' = ', unpack('L',$val), "\n";
1161     }
1162     dbmclose(%HIST);
1163
1164 See also L<AnyDBM_File> for a more general description of the pros and
1165 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1166 rich implementation.
1167
1168 You can control which DBM library you use by loading that library
1169 before you call dbmopen():
1170
1171     use DB_File;
1172     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1173         or die "Can't open netscape history file: $!";
1174
1175 Portability issues: L<perlport/dbmopen>.
1176
1177 =item default BLOCK
1178
1179 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1180 that's always true.  Only available after Perl 5.10, and only if the
1181 C<switch> feature has been requested or if the keyword is prefixed with
1182 C<CORE::>.  See L</when>.
1183
1184 =item defined EXPR
1185 X<defined> X<undef> X<undefined>
1186
1187 =item defined
1188
1189 Returns a Boolean value telling whether EXPR has a value other than
1190 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1191 checked.
1192
1193 Many operations return C<undef> to indicate failure, end of file,
1194 system error, uninitialized variable, and other exceptional
1195 conditions.  This function allows you to distinguish C<undef> from
1196 other values.  (A simple Boolean test will not distinguish among
1197 C<undef>, zero, the empty string, and C<"0">, which are all equally
1198 false.)  Note that since C<undef> is a valid scalar, its presence
1199 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1200 returns C<undef> when its argument is an empty array, I<or> when the
1201 element to return happens to be C<undef>.
1202
1203 You may also use C<defined(&func)> to check whether subroutine C<&func>
1204 has ever been defined.  The return value is unaffected by any forward
1205 declarations of C<&func>.  A subroutine that is not defined
1206 may still be callable: its package may have an C<AUTOLOAD> method that
1207 makes it spring into existence the first time that it is called; see
1208 L<perlsub>.
1209
1210 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1211 used to report whether memory for that aggregate had ever been
1212 allocated.  This behavior may disappear in future versions of Perl.
1213 You should instead use a simple test for size:
1214
1215     if (@an_array) { print "has array elements\n" }
1216     if (%a_hash)   { print "has hash members\n"   }
1217
1218 When used on a hash element, it tells you whether the value is defined,
1219 not whether the key exists in the hash.  Use L</exists> for the latter
1220 purpose.
1221
1222 Examples:
1223
1224     print if defined $switch{D};
1225     print "$val\n" while defined($val = pop(@ary));
1226     die "Can't readlink $sym: $!"
1227         unless defined($value = readlink $sym);
1228     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1229     $debugging = 0 unless defined $debugging;
1230
1231 Note:  Many folks tend to overuse C<defined> and are then surprised to
1232 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1233 defined values.  For example, if you say
1234
1235     "ab" =~ /a(.*)b/;
1236
1237 The pattern match succeeds and C<$1> is defined, although it
1238 matched "nothing".  It didn't really fail to match anything.  Rather, it
1239 matched something that happened to be zero characters long.  This is all
1240 very above-board and honest.  When a function returns an undefined value,
1241 it's an admission that it couldn't give you an honest answer.  So you
1242 should use C<defined> only when questioning the integrity of what
1243 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1244 what you want.
1245
1246 See also L</undef>, L</exists>, L</ref>.
1247
1248 =item delete EXPR
1249 X<delete>
1250
1251 Given an expression that specifies an element or slice of a hash, C<delete>
1252 deletes the specified elements from that hash so that exists() on that element
1253 no longer returns true.  Setting a hash element to the undefined value does
1254 not remove its key, but deleting it does; see L</exists>.
1255
1256 In list context, returns the value or values deleted, or the last such
1257 element in scalar context.  The return list's length always matches that of
1258 the argument list: deleting non-existent elements returns the undefined value
1259 in their corresponding positions.
1260
1261 delete() may also be used on arrays and array slices, but its behavior is less
1262 straightforward.  Although exists() will return false for deleted entries,
1263 deleting array elements never changes indices of existing values; use shift()
1264 or splice() for that.  However, if all deleted elements fall at the end of an
1265 array, the array's size shrinks to the position of the highest element that
1266 still tests true for exists(), or to 0 if none do.
1267
1268 B<WARNING:> Calling delete on array values is deprecated and likely to
1269 be removed in a future version of Perl.
1270
1271 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1272 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1273 or array may not necessarily return anything; it depends on the implementation
1274 of the C<tied> package's DELETE method, which may do whatever it pleases.
1275
1276 The C<delete local EXPR> construct localizes the deletion to the current
1277 block at run time.  Until the block exits, elements locally deleted
1278 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1279 of composite types">.
1280
1281     %hash = (foo => 11, bar => 22, baz => 33);
1282     $scalar = delete $hash{foo};             # $scalar is 11
1283     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1284     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1285
1286 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1287
1288     foreach $key (keys %HASH) {
1289         delete $HASH{$key};
1290     }
1291
1292     foreach $index (0 .. $#ARRAY) {
1293         delete $ARRAY[$index];
1294     }
1295
1296 And so do these:
1297
1298     delete @HASH{keys %HASH};
1299
1300     delete @ARRAY[0 .. $#ARRAY];
1301
1302 But both are slower than assigning the empty list
1303 or undefining %HASH or @ARRAY, which is the customary 
1304 way to empty out an aggregate:
1305
1306     %HASH = ();     # completely empty %HASH
1307     undef %HASH;    # forget %HASH ever existed
1308
1309     @ARRAY = ();    # completely empty @ARRAY
1310     undef @ARRAY;   # forget @ARRAY ever existed
1311
1312 The EXPR can be arbitrarily complicated provided its
1313 final operation is an element or slice of an aggregate:
1314
1315     delete $ref->[$x][$y]{$key};
1316     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1317
1318     delete $ref->[$x][$y][$index];
1319     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1320
1321 =item die LIST
1322 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1323
1324 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1325 into C<$@> and the C<eval> is terminated with the undefined value.
1326 If the exception is outside of all enclosing C<eval>s, then the uncaught
1327 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1328 need to exit the process with a specific exit code, see L</exit>.
1329
1330 Equivalent examples:
1331
1332     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1333     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1334
1335 If the last element of LIST does not end in a newline, the current
1336 script line number and input line number (if any) are also printed,
1337 and a newline is supplied.  Note that the "input line number" (also
1338 known as "chunk") is subject to whatever notion of "line" happens to
1339 be currently in effect, and is also available as the special variable
1340 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1341
1342 Hint: sometimes appending C<", stopped"> to your message will cause it
1343 to make better sense when the string C<"at foo line 123"> is appended.
1344 Suppose you are running script "canasta".
1345
1346     die "/etc/games is no good";
1347     die "/etc/games is no good, stopped";
1348
1349 produce, respectively
1350
1351     /etc/games is no good at canasta line 123.
1352     /etc/games is no good, stopped at canasta line 123.
1353
1354 If the output is empty and C<$@> already contains a value (typically from a
1355 previous eval) that value is reused after appending C<"\t...propagated">.
1356 This is useful for propagating exceptions:
1357
1358     eval { ... };
1359     die unless $@ =~ /Expected exception/;
1360
1361 If the output is empty and C<$@> contains an object reference that has a
1362 C<PROPAGATE> method, that method will be called with additional file
1363 and line number parameters.  The return value replaces the value in
1364 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1365 were called.
1366
1367 If C<$@> is empty then the string C<"Died"> is used.
1368
1369 If an uncaught exception results in interpreter exit, the exit code is
1370 determined from the values of C<$!> and C<$?> with this pseudocode:
1371
1372     exit $! if $!;              # errno
1373     exit $? >> 8 if $? >> 8;    # child exit status
1374     exit 255;                   # last resort
1375
1376 The intent is to squeeze as much possible information about the likely cause
1377 into the limited space of the system exit
1378 code.  However, as C<$!> is the value
1379 of C's C<errno>, which can be set by any system call, this means that the value
1380 of the exit code used by C<die> can be non-predictable, so should not be relied
1381 upon, other than to be non-zero.
1382
1383 You can also call C<die> with a reference argument, and if this is trapped
1384 within an C<eval>, C<$@> contains that reference.  This permits more
1385 elaborate exception handling using objects that maintain arbitrary state
1386 about the exception.  Such a scheme is sometimes preferable to matching
1387 particular string values of C<$@> with regular expressions.  Because C<$@> 
1388 is a global variable and C<eval> may be used within object implementations,
1389 be careful that analyzing the error object doesn't replace the reference in
1390 the global variable.  It's easiest to make a local copy of the reference
1391 before any manipulations.  Here's an example:
1392
1393     use Scalar::Util "blessed";
1394
1395     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1396     if (my $ev_err = $@) {
1397         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1398             # handle Some::Module::Exception
1399         }
1400         else {
1401             # handle all other possible exceptions
1402         }
1403     }
1404
1405 Because Perl stringifies uncaught exception messages before display,
1406 you'll probably want to overload stringification operations on
1407 exception objects.  See L<overload> for details about that.
1408
1409 You can arrange for a callback to be run just before the C<die>
1410 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1411 handler is called with the error text and can change the error
1412 message, if it sees fit, by calling C<die> again.  See
1413 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1414 L<"eval BLOCK"> for some examples.  Although this feature was 
1415 to be run only right before your program was to exit, this is not
1416 currently so: the C<$SIG{__DIE__}> hook is currently called
1417 even inside eval()ed blocks/strings!  If one wants the hook to do
1418 nothing in such situations, put
1419
1420     die @_ if $^S;
1421
1422 as the first line of the handler (see L<perlvar/$^S>).  Because
1423 this promotes strange action at a distance, this counterintuitive
1424 behavior may be fixed in a future release.
1425
1426 See also exit(), warn(), and the Carp module.
1427
1428 =item do BLOCK
1429 X<do> X<block>
1430
1431 Not really a function.  Returns the value of the last command in the
1432 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1433 C<until> loop modifier, executes the BLOCK once before testing the loop
1434 condition.  (On other statements the loop modifiers test the conditional
1435 first.)
1436
1437 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1438 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1439 See L<perlsyn> for alternative strategies.
1440
1441 =item do SUBROUTINE(LIST)
1442 X<do>
1443
1444 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1445 a scalar variable or a subroutine beginning with C<&>.
1446
1447 =item do EXPR
1448 X<do>
1449
1450 Uses the value of EXPR as a filename and executes the contents of the
1451 file as a Perl script.
1452
1453     do 'stat.pl';
1454
1455 is just like
1456
1457     eval `cat stat.pl`;
1458
1459 except that it's more efficient and concise, keeps track of the current
1460 filename for error messages, searches the C<@INC> directories, and updates
1461 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1462 these variables.  It also differs in that code evaluated with C<do FILENAME>
1463 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1464 same, however, in that it does reparse the file every time you call it,
1465 so you probably don't want to do this inside a loop.
1466
1467 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1468 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1469 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1470 could fail in a way that also sets C<$!>.  If the file is successfully
1471 compiled, C<do> returns the value of the last expression evaluated.
1472
1473 Inclusion of library modules is better done with the
1474 C<use> and C<require> operators, which also do automatic error checking
1475 and raise an exception if there's a problem.
1476
1477 You might like to use C<do> to read in a program configuration
1478 file.  Manual error checking can be done this way:
1479
1480     # read in config files: system first, then user
1481     for $file ("/share/prog/defaults.rc",
1482                "$ENV{HOME}/.someprogrc")
1483     {
1484         unless ($return = do $file) {
1485             warn "couldn't parse $file: $@" if $@;
1486             warn "couldn't do $file: $!"    unless defined $return;
1487             warn "couldn't run $file"       unless $return;
1488         }
1489     }
1490
1491 =item dump LABEL
1492 X<dump> X<core> X<undump>
1493
1494 =item dump
1495
1496 This function causes an immediate core dump.  See also the B<-u>
1497 command-line switch in L<perlrun>, which does the same thing.
1498 Primarily this is so that you can use the B<undump> program (not
1499 supplied) to turn your core dump into an executable binary after
1500 having initialized all your variables at the beginning of the
1501 program.  When the new binary is executed it will begin by executing
1502 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1503 Think of it as a goto with an intervening core dump and reincarnation.
1504 If C<LABEL> is omitted, restarts the program from the top.
1505
1506 B<WARNING>: Any files opened at the time of the dump will I<not>
1507 be open any more when the program is reincarnated, with possible
1508 resulting confusion by Perl.
1509
1510 This function is now largely obsolete, mostly because it's very hard to
1511 convert a core file into an executable.  That's why you should now invoke
1512 it as C<CORE::dump()>, if you don't want to be warned against a possible
1513 typo.
1514
1515 Portability issues: L<perlport/dump>.
1516
1517 =item each HASH
1518 X<each> X<hash, iterator>
1519
1520 =item each ARRAY
1521 X<array, iterator>
1522
1523 =item each EXPR
1524
1525 When called on a hash in list context, returns a 2-element list
1526 consisting of the key and value for the next element of a hash.  In Perl
1527 5.12 and later only, it will also return the index and value for the next
1528 element of an array so that you can iterate over it; older Perls consider
1529 this a syntax error.  When called in scalar context, returns only the key
1530 (not the value) in a hash, or the index in an array.
1531
1532 Hash entries are returned in an apparently random order.  The actual random
1533 order is subject to change in future versions of Perl, but it is
1534 guaranteed to be in the same order as either the C<keys> or C<values>
1535 function would produce on the same (unmodified) hash.  Since Perl
1536 5.8.2 the ordering can be different even between different runs of Perl
1537 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1538
1539 After C<each> has returned all entries from the hash or array, the next
1540 call to C<each> returns the empty list in list context and C<undef> in
1541 scalar context; the next call following I<that> one restarts iteration.
1542 Each hash or array has its own internal iterator, accessed by C<each>,
1543 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1544 reached the end as just described; it can be explicitly reset by calling
1545 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1546 elements while iterating over it, entries may be skipped or duplicated--so
1547 don't do that.  Exception: In the current implementation, it is always safe
1548 to delete the item most recently returned by C<each()>, so the following
1549 code works properly:
1550
1551         while (($key, $value) = each %hash) {
1552           print $key, "\n";
1553           delete $hash{$key};   # This is safe
1554         }
1555
1556 This prints out your environment like the printenv(1) program,
1557 but in a different order:
1558
1559     while (($key,$value) = each %ENV) {
1560         print "$key=$value\n";
1561     }
1562
1563 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1564 reference to an unblessed hash or array.  The argument will be dereferenced
1565 automatically.  This aspect of C<each> is considered highly experimental.
1566 The exact behaviour may change in a future version of Perl.
1567
1568     while (($key,$value) = each $hashref) { ... }
1569
1570 To avoid confusing would-be users of your code who are running earlier
1571 versions of Perl with mysterious syntax errors, put this sort of thing at
1572 the top of your file to signal that your code will work I<only> on Perls of
1573 a recent vintage:
1574
1575     use 5.012;  # so keys/values/each work on arrays
1576     use 5.014;  # so keys/values/each work on scalars (experimental)
1577
1578 See also C<keys>, C<values>, and C<sort>.
1579
1580 =item eof FILEHANDLE
1581 X<eof>
1582 X<end of file>
1583 X<end-of-file>
1584
1585 =item eof ()
1586
1587 =item eof
1588
1589 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1590 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1591 gives the real filehandle.  (Note that this function actually
1592 reads a character and then C<ungetc>s it, so isn't useful in an
1593 interactive context.)  Do not read from a terminal file (or call
1594 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1595 as terminals may lose the end-of-file condition if you do.
1596
1597 An C<eof> without an argument uses the last file read.  Using C<eof()>
1598 with empty parentheses is different.  It refers to the pseudo file
1599 formed from the files listed on the command line and accessed via the
1600 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1601 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1602 used will cause C<@ARGV> to be examined to determine if input is
1603 available.   Similarly, an C<eof()> after C<< <> >> has returned
1604 end-of-file will assume you are processing another C<@ARGV> list,
1605 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1606 see L<perlop/"I/O Operators">.
1607
1608 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1609 detect the end of each file, whereas C<eof()> will detect the end 
1610 of the very last file only.  Examples:
1611
1612     # reset line numbering on each input file
1613     while (<>) {
1614         next if /^\s*#/;  # skip comments
1615         print "$.\t$_";
1616     } continue {
1617         close ARGV if eof;  # Not eof()!
1618     }
1619
1620     # insert dashes just before last line of last file
1621     while (<>) {
1622         if (eof()) {  # check for end of last file
1623             print "--------------\n";
1624         }
1625         print;
1626         last if eof();      # needed if we're reading from a terminal
1627     }
1628
1629 Practical hint: you almost never need to use C<eof> in Perl, because the
1630 input operators typically return C<undef> when they run out of data or 
1631 encounter an error.
1632
1633 =item eval EXPR
1634 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1635 X<error, handling> X<exception, handling>
1636
1637 =item eval BLOCK
1638
1639 =item eval
1640
1641 In the first form, the return value of EXPR is parsed and executed as if it
1642 were a little Perl program.  The value of the expression (which is itself
1643 determined within scalar context) is first parsed, and if there were no
1644 errors, executed as a block within the lexical context of the current Perl
1645 program.  This means, that in particular, any outer lexical variables are
1646 visible to it, and any package variable settings or subroutine and format
1647 definitions remain afterwards.
1648
1649 Note that the value is parsed every time the C<eval> executes.
1650 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1651 delay parsing and subsequent execution of the text of EXPR until run time.
1652
1653 If the C<unicode_eval> feature is enabled (which is the default under a
1654 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1655 characters, so C<use utf8> declarations have no effect, and source filters
1656 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1657 will sometimes be treated as characters and sometimes as bytes, depending
1658 on the internal encoding, and source filters activated within the C<eval>
1659 exhibit the erratic, but historical, behaviour of affecting some outer file
1660 scope that is still compiling.  See also the L</evalbytes> keyword, which
1661 always treats its input as a byte stream and works properly with source
1662 filters, and the L<feature> pragma.
1663
1664 In the second form, the code within the BLOCK is parsed only once--at the
1665 same time the code surrounding the C<eval> itself was parsed--and executed
1666 within the context of the current Perl program.  This form is typically
1667 used to trap exceptions more efficiently than the first (see below), while
1668 also providing the benefit of checking the code within BLOCK at compile
1669 time.
1670
1671 The final semicolon, if any, may be omitted from the value of EXPR or within
1672 the BLOCK.
1673
1674 In both forms, the value returned is the value of the last expression
1675 evaluated inside the mini-program; a return statement may be also used, just
1676 as with subroutines.  The expression providing the return value is evaluated
1677 in void, scalar, or list context, depending on the context of the C<eval> 
1678 itself.  See L</wantarray> for more on how the evaluation context can be 
1679 determined.
1680
1681 If there is a syntax error or runtime error, or a C<die> statement is
1682 executed, C<eval> returns C<undef> in scalar context
1683 or an empty list in list context, and C<$@> is set to the error
1684 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1685 in list context for syntax errors, but not for runtime errors.)
1686 If there was no error, C<$@> is set to the empty string.  A
1687 control flow operator like C<last> or C<goto> can bypass the setting of
1688 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1689 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1690 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1691 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1692 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1693
1694 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1695 determining whether a particular feature (such as C<socket> or C<symlink>)
1696 is implemented.  It is also Perl's exception-trapping mechanism, where
1697 the die operator is used to raise exceptions.
1698
1699 If you want to trap errors when loading an XS module, some problems with
1700 the binary interface (such as Perl version skew) may be fatal even with
1701 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1702
1703 If the code to be executed doesn't vary, you may use the eval-BLOCK
1704 form to trap run-time errors without incurring the penalty of
1705 recompiling each time.  The error, if any, is still returned in C<$@>.
1706 Examples:
1707
1708     # make divide-by-zero nonfatal
1709     eval { $answer = $a / $b; }; warn $@ if $@;
1710
1711     # same thing, but less efficient
1712     eval '$answer = $a / $b'; warn $@ if $@;
1713
1714     # a compile-time error
1715     eval { $answer = }; # WRONG
1716
1717     # a run-time error
1718     eval '$answer =';   # sets $@
1719
1720 Using the C<eval{}> form as an exception trap in libraries does have some
1721 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1722 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1723 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1724 as this example shows:
1725
1726     # a private exception trap for divide-by-zero
1727     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1728     warn $@ if $@;
1729
1730 This is especially significant, given that C<__DIE__> hooks can call
1731 C<die> again, which has the effect of changing their error messages:
1732
1733     # __DIE__ hooks may modify error messages
1734     {
1735        local $SIG{'__DIE__'} =
1736               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1737        eval { die "foo lives here" };
1738        print $@ if $@;                # prints "bar lives here"
1739     }
1740
1741 Because this promotes action at a distance, this counterintuitive behavior
1742 may be fixed in a future release.
1743
1744 With an C<eval>, you should be especially careful to remember what's
1745 being looked at when:
1746
1747     eval $x;        # CASE 1
1748     eval "$x";      # CASE 2
1749
1750     eval '$x';      # CASE 3
1751     eval { $x };    # CASE 4
1752
1753     eval "\$$x++";  # CASE 5
1754     $$x++;          # CASE 6
1755
1756 Cases 1 and 2 above behave identically: they run the code contained in
1757 the variable $x.  (Although case 2 has misleading double quotes making
1758 the reader wonder what else might be happening (nothing is).)  Cases 3
1759 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1760 does nothing but return the value of $x.  (Case 4 is preferred for
1761 purely visual reasons, but it also has the advantage of compiling at
1762 compile-time instead of at run-time.)  Case 5 is a place where
1763 normally you I<would> like to use double quotes, except that in this
1764 particular situation, you can just use symbolic references instead, as
1765 in case 6.
1766
1767 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1768 of localized variables, which means that for your code to run on older
1769 versions, a temporary is required if you want to mask some but not all
1770 errors:
1771
1772     # alter $@ on nefarious repugnancy only
1773     {
1774        my $e;
1775        {
1776           local $@; # protect existing $@
1777           eval { test_repugnancy() };
1778           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1779           $@ =~ /nefarious/ and $e = $@;
1780        }
1781        die $e if defined $e
1782     }
1783
1784 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1785 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1786
1787 An C<eval ''> executed within the C<DB> package doesn't see the usual
1788 surrounding lexical scope, but rather the scope of the first non-DB piece
1789 of code that called it.  You don't normally need to worry about this unless
1790 you are writing a Perl debugger.
1791
1792 =item evalbytes EXPR
1793 X<evalbytes>
1794
1795 =item evalbytes
1796
1797 This function is like L</eval> with a string argument, except it always
1798 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1799 string containing characters whose ordinal value exceeds 255 results in an
1800 error.  Source filters activated within the evaluated code apply to the
1801 code itself.
1802
1803 This function is only available under the C<evalbytes> feature, a
1804 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1805 L<feature> for more information.
1806
1807 =item exec LIST
1808 X<exec> X<execute>
1809
1810 =item exec PROGRAM LIST
1811
1812 The C<exec> function executes a system command I<and never returns>;
1813 use C<system> instead of C<exec> if you want it to return.  It fails and
1814 returns false only if the command does not exist I<and> it is executed
1815 directly instead of via your system's command shell (see below).
1816
1817 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1818 warns you if there is a following statement that isn't C<die>, C<warn>,
1819 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1820 I<really> want to follow an C<exec> with some other statement, you
1821 can use one of these styles to avoid the warning:
1822
1823     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1824     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1825
1826 If there is more than one argument in LIST, or if LIST is an array
1827 with more than one value, calls execvp(3) with the arguments in LIST.
1828 If there is only one scalar argument or an array with one element in it,
1829 the argument is checked for shell metacharacters, and if there are any,
1830 the entire argument is passed to the system's command shell for parsing
1831 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1832 If there are no shell metacharacters in the argument, it is split into
1833 words and passed directly to C<execvp>, which is more efficient.
1834 Examples:
1835
1836     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1837     exec "sort $outfile | uniq";
1838
1839 If you don't really want to execute the first argument, but want to lie
1840 to the program you are executing about its own name, you can specify
1841 the program you actually want to run as an "indirect object" (without a
1842 comma) in front of the LIST.  (This always forces interpretation of the
1843 LIST as a multivalued list, even if there is only a single scalar in
1844 the list.)  Example:
1845
1846     $shell = '/bin/csh';
1847     exec $shell '-sh';    # pretend it's a login shell
1848
1849 or, more directly,
1850
1851     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1852
1853 When the arguments get executed via the system shell, results are
1854 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1855 for details.
1856
1857 Using an indirect object with C<exec> or C<system> is also more
1858 secure.  This usage (which also works fine with system()) forces
1859 interpretation of the arguments as a multivalued list, even if the
1860 list had just one argument.  That way you're safe from the shell
1861 expanding wildcards or splitting up words with whitespace in them.
1862
1863     @args = ( "echo surprise" );
1864
1865     exec @args;               # subject to shell escapes
1866                                 # if @args == 1
1867     exec { $args[0] } @args;  # safe even with one-arg list
1868
1869 The first version, the one without the indirect object, ran the I<echo>
1870 program, passing it C<"surprise"> an argument.  The second version didn't;
1871 it tried to run a program named I<"echo surprise">, didn't find it, and set
1872 C<$?> to a non-zero value indicating failure.
1873
1874 Beginning with v5.6.0, Perl attempts to flush all files opened for
1875 output before the exec, but this may not be supported on some platforms
1876 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1877 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1878 open handles to avoid lost output.
1879
1880 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1881 C<DESTROY> methods on your objects.
1882
1883 Portability issues: L<perlport/exec>.
1884
1885 =item exists EXPR
1886 X<exists> X<autovivification>
1887
1888 Given an expression that specifies an element of a hash, returns true if the
1889 specified element in the hash has ever been initialized, even if the
1890 corresponding value is undefined.
1891
1892     print "Exists\n"    if exists $hash{$key};
1893     print "Defined\n"   if defined $hash{$key};
1894     print "True\n"      if $hash{$key};
1895
1896 exists may also be called on array elements, but its behavior is much less
1897 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1898 that calling exists on array values is deprecated and likely to be removed in
1899 a future version of Perl.
1900
1901     print "Exists\n"    if exists $array[$index];
1902     print "Defined\n"   if defined $array[$index];
1903     print "True\n"      if $array[$index];
1904
1905 A hash or array element can be true only if it's defined and defined only if
1906 it exists, but the reverse doesn't necessarily hold true.
1907
1908 Given an expression that specifies the name of a subroutine,
1909 returns true if the specified subroutine has ever been declared, even
1910 if it is undefined.  Mentioning a subroutine name for exists or defined
1911 does not count as declaring it.  Note that a subroutine that does not
1912 exist may still be callable: its package may have an C<AUTOLOAD>
1913 method that makes it spring into existence the first time that it is
1914 called; see L<perlsub>.
1915
1916     print "Exists\n"  if exists &subroutine;
1917     print "Defined\n" if defined &subroutine;
1918
1919 Note that the EXPR can be arbitrarily complicated as long as the final
1920 operation is a hash or array key lookup or subroutine name:
1921
1922     if (exists $ref->{A}->{B}->{$key})  { }
1923     if (exists $hash{A}{B}{$key})       { }
1924
1925     if (exists $ref->{A}->{B}->[$ix])   { }
1926     if (exists $hash{A}{B}[$ix])        { }
1927
1928     if (exists &{$ref->{A}{B}{$key}})   { }
1929
1930 Although the mostly deeply nested array or hash will not spring into
1931 existence just because its existence was tested, any intervening ones will.
1932 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1933 into existence due to the existence test for the $key element above.
1934 This happens anywhere the arrow operator is used, including even here:
1935
1936     undef $ref;
1937     if (exists $ref->{"Some key"})    { }
1938     print $ref;  # prints HASH(0x80d3d5c)
1939
1940 This surprising autovivification in what does not at first--or even
1941 second--glance appear to be an lvalue context may be fixed in a future
1942 release.
1943
1944 Use of a subroutine call, rather than a subroutine name, as an argument
1945 to exists() is an error.
1946
1947     exists &sub;    # OK
1948     exists &sub();  # Error
1949
1950 =item exit EXPR
1951 X<exit> X<terminate> X<abort>
1952
1953 =item exit
1954
1955 Evaluates EXPR and exits immediately with that value.    Example:
1956
1957     $ans = <STDIN>;
1958     exit 0 if $ans =~ /^[Xx]/;
1959
1960 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1961 universally recognized values for EXPR are C<0> for success and C<1>
1962 for error; other values are subject to interpretation depending on the
1963 environment in which the Perl program is running.  For example, exiting
1964 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1965 the mailer to return the item undelivered, but that's not true everywhere.
1966
1967 Don't use C<exit> to abort a subroutine if there's any chance that
1968 someone might want to trap whatever error happened.  Use C<die> instead,
1969 which can be trapped by an C<eval>.
1970
1971 The exit() function does not always exit immediately.  It calls any
1972 defined C<END> routines first, but these C<END> routines may not
1973 themselves abort the exit.  Likewise any object destructors that need to
1974 be called are called before the real exit.  C<END> routines and destructors
1975 can change the exit status by modifying C<$?>.  If this is a problem, you
1976 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1977 See L<perlmod> for details.
1978
1979 Portability issues: L<perlport/exit>.
1980
1981 =item exp EXPR
1982 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1983
1984 =item exp
1985
1986 Returns I<e> (the natural logarithm base) to the power of EXPR.
1987 If EXPR is omitted, gives C<exp($_)>.
1988
1989 =item fc EXPR
1990 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
1991
1992 =item fc
1993
1994 Returns the casefolded version of EXPR.  This is the internal function
1995 implementing the C<\F> escape in double-quoted strings.
1996
1997 Casefolding is the process of mapping strings to a form where case
1998 differences are erased; comparing two strings in their casefolded
1999 form is effectively a way of asking if two strings are equal,
2000 regardless of case.
2001
2002 Roughly, if you ever found yourself writing this
2003
2004     lc($this) eq lc($that)  # Wrong!
2005         # or
2006     uc($this) eq uc($that)  # Also wrong!
2007         # or
2008     $this =~ /\Q$that/i     # Right!
2009
2010 Now you can write
2011
2012     fc($this) eq fc($that)
2013
2014 And get the correct results.
2015
2016 Perl only implements the full form of casefolding.
2017 For further information on casefolding, refer to
2018 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2019 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2020 available at L<http://www.unicode.org/versions/latest/>, as well as the
2021 Case Charts available at L<http://www.unicode.org/charts/case/>.
2022
2023 If EXPR is omitted, uses C<$_>.
2024
2025 This function behaves the same way under various pragma, such as in a locale,
2026 as L</lc> does.
2027
2028 While the Unicode Standard defines two additional forms of casefolding,
2029 one for Turkic languages and one that never maps one character into multiple
2030 characters, these are not provided by the Perl core; However, the CPAN module
2031 C<Unicode::Casing> may be used to provide an implementation.
2032
2033 This keyword is available only when the C<"fc"> feature is enabled,
2034 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2035 include a C<use v5.16> or later to the current scope.
2036
2037 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2038 X<fcntl>
2039
2040 Implements the fcntl(2) function.  You'll probably have to say
2041
2042     use Fcntl;
2043
2044 first to get the correct constant definitions.  Argument processing and
2045 value returned work just like C<ioctl> below.
2046 For example:
2047
2048     use Fcntl;
2049     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2050         or die "can't fcntl F_GETFL: $!";
2051
2052 You don't have to check for C<defined> on the return from C<fcntl>.
2053 Like C<ioctl>, it maps a C<0> return from the system call into
2054 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2055 in numeric context.  It is also exempt from the normal B<-w> warnings
2056 on improper numeric conversions.
2057
2058 Note that C<fcntl> raises an exception if used on a machine that
2059 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2060 manpage to learn what functions are available on your system.
2061
2062 Here's an example of setting a filehandle named C<REMOTE> to be
2063 non-blocking at the system level.  You'll have to negotiate C<$|>
2064 on your own, though.
2065
2066     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2067
2068     $flags = fcntl(REMOTE, F_GETFL, 0)
2069                 or die "Can't get flags for the socket: $!\n";
2070
2071     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2072                 or die "Can't set flags for the socket: $!\n";
2073
2074 Portability issues: L<perlport/fcntl>.
2075
2076 =item __FILE__
2077 X<__FILE__>
2078
2079 A special token that returns the name of the file in which it occurs.
2080
2081 =item fileno FILEHANDLE
2082 X<fileno>
2083
2084 Returns the file descriptor for a filehandle, or undefined if the
2085 filehandle is not open.  If there is no real file descriptor at the OS
2086 level, as can happen with filehandles connected to memory objects via
2087 C<open> with a reference for the third argument, -1 is returned.
2088
2089 This is mainly useful for constructing
2090 bitmaps for C<select> and low-level POSIX tty-handling operations.
2091 If FILEHANDLE is an expression, the value is taken as an indirect
2092 filehandle, generally its name.
2093
2094 You can use this to find out whether two handles refer to the
2095 same underlying descriptor:
2096
2097     if (fileno(THIS) == fileno(THAT)) {
2098         print "THIS and THAT are dups\n";
2099     }
2100
2101 =item flock FILEHANDLE,OPERATION
2102 X<flock> X<lock> X<locking>
2103
2104 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2105 for success, false on failure.  Produces a fatal error if used on a
2106 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2107 C<flock> is Perl's portable file-locking interface, although it locks
2108 entire files only, not records.
2109
2110 Two potentially non-obvious but traditional C<flock> semantics are
2111 that it waits indefinitely until the lock is granted, and that its locks
2112 are B<merely advisory>.  Such discretionary locks are more flexible, but
2113 offer fewer guarantees.  This means that programs that do not also use
2114 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2115 your port's specific documentation, and your system-specific local manpages
2116 for details.  It's best to assume traditional behavior if you're writing
2117 portable programs.  (But if you're not, you should as always feel perfectly
2118 free to write for your own system's idiosyncrasies (sometimes called
2119 "features").  Slavish adherence to portability concerns shouldn't get
2120 in the way of your getting your job done.)
2121
2122 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2123 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2124 you can use the symbolic names if you import them from the L<Fcntl> module,
2125 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2126 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2127 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2128 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2129 waiting for the lock; check the return status to see if you got it.
2130
2131 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2132 before locking or unlocking it.
2133
2134 Note that the emulation built with lockf(3) doesn't provide shared
2135 locks, and it requires that FILEHANDLE be open with write intent.  These
2136 are the semantics that lockf(3) implements.  Most if not all systems
2137 implement lockf(3) in terms of fcntl(2) locking, though, so the
2138 differing semantics shouldn't bite too many people.
2139
2140 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2141 be open with read intent to use LOCK_SH and requires that it be open
2142 with write intent to use LOCK_EX.
2143
2144 Note also that some versions of C<flock> cannot lock things over the
2145 network; you would need to use the more system-specific C<fcntl> for
2146 that.  If you like you can force Perl to ignore your system's flock(2)
2147 function, and so provide its own fcntl(2)-based emulation, by passing
2148 the switch C<-Ud_flock> to the F<Configure> program when you configure
2149 and build a new Perl.
2150
2151 Here's a mailbox appender for BSD systems.
2152
2153     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2154
2155     sub lock {
2156         my ($fh) = @_;
2157         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2158
2159         # and, in case someone appended while we were waiting...
2160         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2161     }
2162
2163     sub unlock {
2164         my ($fh) = @_;
2165         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2166     }
2167
2168     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2169         or die "Can't open mailbox: $!";
2170
2171     lock($mbox);
2172     print $mbox $msg,"\n\n";
2173     unlock($mbox);
2174
2175 On systems that support a real flock(2), locks are inherited across fork()
2176 calls, whereas those that must resort to the more capricious fcntl(2)
2177 function lose their locks, making it seriously harder to write servers.
2178
2179 See also L<DB_File> for other flock() examples.
2180
2181 Portability issues: L<perlport/flock>.
2182
2183 =item fork
2184 X<fork> X<child> X<parent>
2185
2186 Does a fork(2) system call to create a new process running the
2187 same program at the same point.  It returns the child pid to the
2188 parent process, C<0> to the child process, or C<undef> if the fork is
2189 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2190 are shared, while everything else is copied.  On most systems supporting
2191 fork(), great care has gone into making it extremely efficient (for
2192 example, using copy-on-write technology on data pages), making it the
2193 dominant paradigm for multitasking over the last few decades.
2194
2195 Beginning with v5.6.0, Perl attempts to flush all files opened for
2196 output before forking the child process, but this may not be supported
2197 on some platforms (see L<perlport>).  To be safe, you may need to set
2198 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2199 C<IO::Handle> on any open handles to avoid duplicate output.
2200
2201 If you C<fork> without ever waiting on your children, you will
2202 accumulate zombies.  On some systems, you can avoid this by setting
2203 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2204 forking and reaping moribund children.
2205
2206 Note that if your forked child inherits system file descriptors like
2207 STDIN and STDOUT that are actually connected by a pipe or socket, even
2208 if you exit, then the remote server (such as, say, a CGI script or a
2209 backgrounded job launched from a remote shell) won't think you're done.
2210 You should reopen those to F</dev/null> if it's any issue.
2211
2212 On some platforms such as Windows, where the fork() system call is not available,
2213 Perl can be built to emulate fork() in the Perl interpreter.
2214 The emulation is designed, at the level of the Perl program,
2215 to be as compatible as possible with the "Unix" fork().
2216 However it has limitations that have to be considered in code intended to be portable.
2217 See L<perlfork> for more details.
2218
2219 Portability issues: L<perlport/fork>.
2220
2221 =item format
2222 X<format>
2223
2224 Declare a picture format for use by the C<write> function.  For
2225 example:
2226
2227     format Something =
2228         Test: @<<<<<<<< @||||| @>>>>>
2229               $str,     $%,    '$' . int($num)
2230     .
2231
2232     $str = "widget";
2233     $num = $cost/$quantity;
2234     $~ = 'Something';
2235     write;
2236
2237 See L<perlform> for many details and examples.
2238
2239 =item formline PICTURE,LIST
2240 X<formline>
2241
2242 This is an internal function used by C<format>s, though you may call it,
2243 too.  It formats (see L<perlform>) a list of values according to the
2244 contents of PICTURE, placing the output into the format output
2245 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2246 Eventually, when a C<write> is done, the contents of
2247 C<$^A> are written to some filehandle.  You could also read C<$^A>
2248 and then set C<$^A> back to C<"">.  Note that a format typically
2249 does one C<formline> per line of form, but the C<formline> function itself
2250 doesn't care how many newlines are embedded in the PICTURE.  This means
2251 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2252 You may therefore need to use multiple formlines to implement a single
2253 record format, just like the C<format> compiler.
2254
2255 Be careful if you put double quotes around the picture, because an C<@>
2256 character may be taken to mean the beginning of an array name.
2257 C<formline> always returns true.  See L<perlform> for other examples.
2258
2259 If you are trying to use this instead of C<write> to capture the output,
2260 you may find it easier to open a filehandle to a scalar
2261 (C<< open $fh, ">", \$output >>) and write to that instead.
2262
2263 =item getc FILEHANDLE
2264 X<getc> X<getchar> X<character> X<file, read>
2265
2266 =item getc
2267
2268 Returns the next character from the input file attached to FILEHANDLE,
2269 or the undefined value at end of file or if there was an error (in
2270 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2271 STDIN.  This is not particularly efficient.  However, it cannot be
2272 used by itself to fetch single characters without waiting for the user
2273 to hit enter.  For that, try something more like:
2274
2275     if ($BSD_STYLE) {
2276         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2277     }
2278     else {
2279         system "stty", '-icanon', 'eol', "\001";
2280     }
2281
2282     $key = getc(STDIN);
2283
2284     if ($BSD_STYLE) {
2285         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2286     }
2287     else {
2288         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2289     }
2290     print "\n";
2291
2292 Determination of whether $BSD_STYLE should be set
2293 is left as an exercise to the reader.
2294
2295 The C<POSIX::getattr> function can do this more portably on
2296 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2297 module from your nearest CPAN site; details on CPAN can be found under
2298 L<perlmodlib/CPAN>.
2299
2300 =item getlogin
2301 X<getlogin> X<login>
2302
2303 This implements the C library function of the same name, which on most
2304 systems returns the current login from F</etc/utmp>, if any.  If it
2305 returns the empty string, use C<getpwuid>.
2306
2307     $login = getlogin || getpwuid($<) || "Kilroy";
2308
2309 Do not consider C<getlogin> for authentication: it is not as
2310 secure as C<getpwuid>.
2311
2312 Portability issues: L<perlport/getlogin>.
2313
2314 =item getpeername SOCKET
2315 X<getpeername> X<peer>
2316
2317 Returns the packed sockaddr address of the other end of the SOCKET
2318 connection.
2319
2320     use Socket;
2321     $hersockaddr    = getpeername(SOCK);
2322     ($port, $iaddr) = sockaddr_in($hersockaddr);
2323     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2324     $herstraddr     = inet_ntoa($iaddr);
2325
2326 =item getpgrp PID
2327 X<getpgrp> X<group>
2328
2329 Returns the current process group for the specified PID.  Use
2330 a PID of C<0> to get the current process group for the
2331 current process.  Will raise an exception if used on a machine that
2332 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2333 group of the current process.  Note that the POSIX version of C<getpgrp>
2334 does not accept a PID argument, so only C<PID==0> is truly portable.
2335
2336 Portability issues: L<perlport/getpgrp>.
2337
2338 =item getppid
2339 X<getppid> X<parent> X<pid>
2340
2341 Returns the process id of the parent process.
2342
2343 Note for Linux users: on Linux, the C functions C<getpid()> and
2344 C<getppid()> return different values from different threads.  In order to
2345 be portable, this behavior is not reflected by the Perl-level function
2346 C<getppid()>, that returns a consistent value across threads.  If you want
2347 to call the underlying C<getppid()>, you may use the CPAN module
2348 C<Linux::Pid>.
2349
2350 Portability issues: L<perlport/getppid>.
2351
2352 =item getpriority WHICH,WHO
2353 X<getpriority> X<priority> X<nice>
2354
2355 Returns the current priority for a process, a process group, or a user.
2356 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2357 machine that doesn't implement getpriority(2).
2358
2359 Portability issues: L<perlport/getpriority>.
2360
2361 =item getpwnam NAME
2362 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2363 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2364 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2365 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2366 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2367 X<endnetent> X<endprotoent> X<endservent> 
2368
2369 =item getgrnam NAME
2370
2371 =item gethostbyname NAME
2372
2373 =item getnetbyname NAME
2374
2375 =item getprotobyname NAME
2376
2377 =item getpwuid UID
2378
2379 =item getgrgid GID
2380
2381 =item getservbyname NAME,PROTO
2382
2383 =item gethostbyaddr ADDR,ADDRTYPE
2384
2385 =item getnetbyaddr ADDR,ADDRTYPE
2386
2387 =item getprotobynumber NUMBER
2388
2389 =item getservbyport PORT,PROTO
2390
2391 =item getpwent
2392
2393 =item getgrent
2394
2395 =item gethostent
2396
2397 =item getnetent
2398
2399 =item getprotoent
2400
2401 =item getservent
2402
2403 =item setpwent
2404
2405 =item setgrent
2406
2407 =item sethostent STAYOPEN
2408
2409 =item setnetent STAYOPEN
2410
2411 =item setprotoent STAYOPEN
2412
2413 =item setservent STAYOPEN
2414
2415 =item endpwent
2416
2417 =item endgrent
2418
2419 =item endhostent
2420
2421 =item endnetent
2422
2423 =item endprotoent
2424
2425 =item endservent
2426
2427 These routines are the same as their counterparts in the
2428 system C library.  In list context, the return values from the
2429 various get routines are as follows:
2430
2431     ($name,$passwd,$uid,$gid,
2432        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2433     ($name,$passwd,$gid,$members) = getgr*
2434     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2435     ($name,$aliases,$addrtype,$net) = getnet*
2436     ($name,$aliases,$proto) = getproto*
2437     ($name,$aliases,$port,$proto) = getserv*
2438
2439 (If the entry doesn't exist you get an empty list.)
2440
2441 The exact meaning of the $gcos field varies but it usually contains
2442 the real name of the user (as opposed to the login name) and other
2443 information pertaining to the user.  Beware, however, that in many
2444 system users are able to change this information and therefore it
2445 cannot be trusted and therefore the $gcos is tainted (see
2446 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2447 login shell, are also tainted, for the same reason.
2448
2449 In scalar context, you get the name, unless the function was a
2450 lookup by name, in which case you get the other thing, whatever it is.
2451 (If the entry doesn't exist you get the undefined value.)  For example:
2452
2453     $uid   = getpwnam($name);
2454     $name  = getpwuid($num);
2455     $name  = getpwent();
2456     $gid   = getgrnam($name);
2457     $name  = getgrgid($num);
2458     $name  = getgrent();
2459     #etc.
2460
2461 In I<getpw*()> the fields $quota, $comment, and $expire are special
2462 in that they are unsupported on many systems.  If the
2463 $quota is unsupported, it is an empty scalar.  If it is supported, it
2464 usually encodes the disk quota.  If the $comment field is unsupported,
2465 it is an empty scalar.  If it is supported it usually encodes some
2466 administrative comment about the user.  In some systems the $quota
2467 field may be $change or $age, fields that have to do with password
2468 aging.  In some systems the $comment field may be $class.  The $expire
2469 field, if present, encodes the expiration period of the account or the
2470 password.  For the availability and the exact meaning of these fields
2471 in your system, please consult getpwnam(3) and your system's 
2472 F<pwd.h> file.  You can also find out from within Perl what your
2473 $quota and $comment fields mean and whether you have the $expire field
2474 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2475 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2476 files are supported only if your vendor has implemented them in the
2477 intuitive fashion that calling the regular C library routines gets the
2478 shadow versions if you're running under privilege or if there exists
2479 the shadow(3) functions as found in System V (this includes Solaris
2480 and Linux).  Those systems that implement a proprietary shadow password
2481 facility are unlikely to be supported.
2482
2483 The $members value returned by I<getgr*()> is a space-separated list of
2484 the login names of the members of the group.
2485
2486 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2487 C, it will be returned to you via C<$?> if the function call fails.  The
2488 C<@addrs> value returned by a successful call is a list of raw
2489 addresses returned by the corresponding library call.  In the
2490 Internet domain, each address is four bytes long; you can unpack it
2491 by saying something like:
2492
2493     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2494
2495 The Socket library makes this slightly easier:
2496
2497     use Socket;
2498     $iaddr = inet_aton("127.1"); # or whatever address
2499     $name  = gethostbyaddr($iaddr, AF_INET);
2500
2501     # or going the other way
2502     $straddr = inet_ntoa($iaddr);
2503
2504 In the opposite way, to resolve a hostname to the IP address
2505 you can write this:
2506
2507     use Socket;
2508     $packed_ip = gethostbyname("www.perl.org");
2509     if (defined $packed_ip) {
2510         $ip_address = inet_ntoa($packed_ip);
2511     }
2512
2513 Make sure C<gethostbyname()> is called in SCALAR context and that
2514 its return value is checked for definedness.
2515
2516 The C<getprotobynumber> function, even though it only takes one argument,
2517 has the precedence of a list operator, so beware:
2518
2519     getprotobynumber $number eq 'icmp'   # WRONG
2520     getprotobynumber($number eq 'icmp')  # actually means this
2521     getprotobynumber($number) eq 'icmp'  # better this way
2522
2523 If you get tired of remembering which element of the return list
2524 contains which return value, by-name interfaces are provided
2525 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2526 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2527 and C<User::grent>.  These override the normal built-ins, supplying
2528 versions that return objects with the appropriate names
2529 for each field.  For example:
2530
2531    use File::stat;
2532    use User::pwent;
2533    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2534
2535 Even though it looks as though they're the same method calls (uid),
2536 they aren't, because a C<File::stat> object is different from
2537 a C<User::pwent> object.
2538
2539 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2540
2541 =item getsockname SOCKET
2542 X<getsockname>
2543
2544 Returns the packed sockaddr address of this end of the SOCKET connection,
2545 in case you don't know the address because you have several different
2546 IPs that the connection might have come in on.
2547
2548     use Socket;
2549     $mysockaddr = getsockname(SOCK);
2550     ($port, $myaddr) = sockaddr_in($mysockaddr);
2551     printf "Connect to %s [%s]\n",
2552        scalar gethostbyaddr($myaddr, AF_INET),
2553        inet_ntoa($myaddr);
2554
2555 =item getsockopt SOCKET,LEVEL,OPTNAME
2556 X<getsockopt>
2557
2558 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2559 Options may exist at multiple protocol levels depending on the socket
2560 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2561 C<Socket> module) will exist.  To query options at another level the
2562 protocol number of the appropriate protocol controlling the option
2563 should be supplied.  For example, to indicate that an option is to be
2564 interpreted by the TCP protocol, LEVEL should be set to the protocol
2565 number of TCP, which you can get using C<getprotobyname>.
2566
2567 The function returns a packed string representing the requested socket
2568 option, or C<undef> on error, with the reason for the error placed in
2569 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2570 consult getsockopt(2) for details.  A common case is that the option is an
2571 integer, in which case the result is a packed integer, which you can decode
2572 using C<unpack> with the C<i> (or C<I>) format.
2573
2574 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2575
2576     use Socket qw(:all);
2577
2578     defined(my $tcp = getprotobyname("tcp"))
2579         or die "Could not determine the protocol number for tcp";
2580     # my $tcp = IPPROTO_TCP; # Alternative
2581     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2582         or die "getsockopt TCP_NODELAY: $!";
2583     my $nodelay = unpack("I", $packed);
2584     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2585
2586 Portability issues: L<perlport/getsockopt>.
2587
2588 =item given EXPR BLOCK
2589 X<given>
2590
2591 =item given BLOCK
2592
2593 C<given> is analogous to the C<switch>
2594 keyword in other languages.  C<given>
2595 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2596 Only available after Perl 5.10.  For example:
2597
2598     use v5.10;
2599     given ($fruit) {
2600         when (/apples?/) {
2601             print "I like apples."
2602         }
2603         when (/oranges?/) {
2604             print "I don't like oranges."
2605         }
2606         default {
2607             print "I don't like anything"
2608         }
2609     }
2610
2611 See L<perlsyn/"Switch Statements"> for detailed information.
2612
2613 =item glob EXPR
2614 X<glob> X<wildcard> X<filename, expansion> X<expand>
2615
2616 =item glob
2617
2618 In list context, returns a (possibly empty) list of filename expansions on
2619 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2620 scalar context, glob iterates through such filename expansions, returning
2621 undef when the list is exhausted.  This is the internal function
2622 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2623 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2624 more detail in L<perlop/"I/O Operators">.
2625
2626 Note that C<glob> splits its arguments on whitespace and treats
2627 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2628 matches all files with a F<.c> or F<.h> extension.  The expression
2629 C<glob(".* *")> matches all files in the current working directory.
2630 If you want to glob filenames that might contain whitespace, you'll
2631 have to use extra quotes around the spacey filename to protect it.
2632 For example, to glob filenames that have an C<e> followed by a space
2633 followed by an C<f>, use either of:
2634
2635     @spacies = <"*e f*">;
2636     @spacies = glob '"*e f*"';
2637     @spacies = glob q("*e f*");
2638
2639 If you had to get a variable through, you could do this:
2640
2641     @spacies = glob "'*${var}e f*'";
2642     @spacies = glob qq("*${var}e f*");
2643
2644 If non-empty braces are the only wildcard characters used in the
2645 C<glob>, no filenames are matched, but potentially many strings
2646 are returned.  For example, this produces nine strings, one for
2647 each pairing of fruits and colors:
2648
2649     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2650
2651 Beginning with v5.6.0, this operator is implemented using the standard
2652 C<File::Glob> extension.  See L<File::Glob> for details, including
2653 C<bsd_glob> which does not treat whitespace as a pattern separator.
2654
2655 Portability issues: L<perlport/glob>.
2656
2657 =item gmtime EXPR
2658 X<gmtime> X<UTC> X<Greenwich>
2659
2660 =item gmtime
2661
2662 Works just like L</localtime> but the returned values are
2663 localized for the standard Greenwich time zone.
2664
2665 Note: When called in list context, $isdst, the last value
2666 returned by gmtime, is always C<0>.  There is no
2667 Daylight Saving Time in GMT.
2668
2669 Portability issues: L<perlport/gmtime>.
2670
2671 =item goto LABEL
2672 X<goto> X<jump> X<jmp>
2673
2674 =item goto EXPR
2675
2676 =item goto &NAME
2677
2678 The C<goto-LABEL> form finds the statement labeled with LABEL and
2679 resumes execution there.  It can't be used to get out of a block or
2680 subroutine given to C<sort>.  It can be used to go almost anywhere
2681 else within the dynamic scope, including out of subroutines, but it's
2682 usually better to use some other construct such as C<last> or C<die>.
2683 The author of Perl has never felt the need to use this form of C<goto>
2684 (in Perl, that is; C is another matter).  (The difference is that C
2685 does not offer named loops combined with loop control.  Perl does, and
2686 this replaces most structured uses of C<goto> in other languages.)
2687
2688 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2689 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2690 necessarily recommended if you're optimizing for maintainability:
2691
2692     goto ("FOO", "BAR", "GLARCH")[$i];
2693
2694 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2695 function" rule.  A pair of parentheses following it does not (necessarily)
2696 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2697
2698 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2699 deprecated and will issue a warning.  Even then, it may not be used to
2700 go into any construct that requires initialization, such as a
2701 subroutine or a C<foreach> loop.  It also can't be used to go into a
2702 construct that is optimized away.
2703
2704 The C<goto-&NAME> form is quite different from the other forms of
2705 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2706 doesn't have the stigma associated with other gotos.  Instead, it
2707 exits the current subroutine (losing any changes set by local()) and
2708 immediately calls in its place the named subroutine using the current
2709 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2710 load another subroutine and then pretend that the other subroutine had
2711 been called in the first place (except that any modifications to C<@_>
2712 in the current subroutine are propagated to the other subroutine.)
2713 After the C<goto>, not even C<caller> will be able to tell that this
2714 routine was called first.
2715
2716 NAME needn't be the name of a subroutine; it can be a scalar variable
2717 containing a code reference or a block that evaluates to a code
2718 reference.
2719
2720 =item grep BLOCK LIST
2721 X<grep>
2722
2723 =item grep EXPR,LIST
2724
2725 This is similar in spirit to, but not the same as, grep(1) and its
2726 relatives.  In particular, it is not limited to using regular expressions.
2727
2728 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2729 C<$_> to each element) and returns the list value consisting of those
2730 elements for which the expression evaluated to true.  In scalar
2731 context, returns the number of times the expression was true.
2732
2733     @foo = grep(!/^#/, @bar);    # weed out comments
2734
2735 or equivalently,
2736
2737     @foo = grep {!/^#/} @bar;    # weed out comments
2738
2739 Note that C<$_> is an alias to the list value, so it can be used to
2740 modify the elements of the LIST.  While this is useful and supported,
2741 it can cause bizarre results if the elements of LIST are not variables.
2742 Similarly, grep returns aliases into the original list, much as a for
2743 loop's index variable aliases the list elements.  That is, modifying an
2744 element of a list returned by grep (for example, in a C<foreach>, C<map>
2745 or another C<grep>) actually modifies the element in the original list.
2746 This is usually something to be avoided when writing clear code.
2747
2748 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2749 been declared with C<my $_>) then, in addition to being locally aliased to
2750 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2751 can't be seen from the outside, avoiding any potential side-effects.
2752
2753 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2754
2755 =item hex EXPR
2756 X<hex> X<hexadecimal>
2757
2758 =item hex
2759
2760 Interprets EXPR as a hex string and returns the corresponding value.
2761 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2762 L</oct>.)  If EXPR is omitted, uses C<$_>.
2763
2764     print hex '0xAf'; # prints '175'
2765     print hex 'aF';   # same
2766
2767 Hex strings may only represent integers.  Strings that would cause
2768 integer overflow trigger a warning.  Leading whitespace is not stripped,
2769 unlike oct().  To present something as hex, look into L</printf>,
2770 L</sprintf>, and L</unpack>.
2771
2772 =item import LIST
2773 X<import>
2774
2775 There is no builtin C<import> function.  It is just an ordinary
2776 method (subroutine) defined (or inherited) by modules that wish to export
2777 names to another module.  The C<use> function calls the C<import> method
2778 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2779
2780 =item index STR,SUBSTR,POSITION
2781 X<index> X<indexOf> X<InStr>
2782
2783 =item index STR,SUBSTR
2784
2785 The index function searches for one string within another, but without
2786 the wildcard-like behavior of a full regular-expression pattern match.
2787 It returns the position of the first occurrence of SUBSTR in STR at
2788 or after POSITION.  If POSITION is omitted, starts searching from the
2789 beginning of the string.  POSITION before the beginning of the string
2790 or after its end is treated as if it were the beginning or the end,
2791 respectively.  POSITION and the return value are based at zero.
2792 If the substring is not found, C<index> returns -1.
2793
2794 =item int EXPR
2795 X<int> X<integer> X<truncate> X<trunc> X<floor>
2796
2797 =item int
2798
2799 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2800 You should not use this function for rounding: one because it truncates
2801 towards C<0>, and two because machine representations of floating-point
2802 numbers can sometimes produce counterintuitive results.  For example,
2803 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2804 because it's really more like -268.99999999999994315658 instead.  Usually,
2805 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2806 functions will serve you better than will int().
2807
2808 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2809 X<ioctl>
2810
2811 Implements the ioctl(2) function.  You'll probably first have to say
2812
2813     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2814
2815 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2816 exist or doesn't have the correct definitions you'll have to roll your
2817 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2818 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2819 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2820 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2821 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2822 has no string value but does have a numeric value, that value will be
2823 passed rather than a pointer to the string value.  To guarantee this to be
2824 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2825 functions may be needed to manipulate the values of structures used by
2826 C<ioctl>.
2827
2828 The return value of C<ioctl> (and C<fcntl>) is as follows:
2829
2830     if OS returns:      then Perl returns:
2831         -1               undefined value
2832          0              string "0 but true"
2833     anything else           that number
2834
2835 Thus Perl returns true on success and false on failure, yet you can
2836 still easily determine the actual value returned by the operating
2837 system:
2838
2839     $retval = ioctl(...) || -1;
2840     printf "System returned %d\n", $retval;
2841
2842 The special string C<"0 but true"> is exempt from B<-w> complaints
2843 about improper numeric conversions.
2844
2845 Portability issues: L<perlport/ioctl>.
2846
2847 =item join EXPR,LIST
2848 X<join>
2849
2850 Joins the separate strings of LIST into a single string with fields
2851 separated by the value of EXPR, and returns that new string.  Example:
2852
2853     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2854
2855 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2856 first argument.  Compare L</split>.
2857
2858 =item keys HASH
2859 X<keys> X<key>
2860
2861 =item keys ARRAY
2862
2863 =item keys EXPR
2864
2865 Called in list context, returns a list consisting of all the keys of the
2866 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
2867 releases prior to 5.12 will produce a syntax error if you try to use an
2868 array argument.  In scalar context, returns the number of keys or indices.
2869
2870 The keys of a hash are returned in an apparently random order.  The actual
2871 random order is subject to change in future versions of Perl, but it
2872 is guaranteed to be the same order as either the C<values> or C<each>
2873 function produces (given that the hash has not been modified).  Since
2874 Perl 5.8.1 the ordering can be different even between different runs of
2875 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2876 Attacks">).
2877
2878 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
2879 (see L</each>).  In particular, calling keys() in void context resets
2880 the iterator with no other overhead.
2881
2882 Here is yet another way to print your environment:
2883
2884     @keys = keys %ENV;
2885     @values = values %ENV;
2886     while (@keys) {
2887         print pop(@keys), '=', pop(@values), "\n";
2888     }
2889
2890 or how about sorted by key:
2891
2892     foreach $key (sort(keys %ENV)) {
2893         print $key, '=', $ENV{$key}, "\n";
2894     }
2895
2896 The returned values are copies of the original keys in the hash, so
2897 modifying them will not affect the original hash.  Compare L</values>.
2898
2899 To sort a hash by value, you'll need to use a C<sort> function.
2900 Here's a descending numeric sort of a hash by its values:
2901
2902     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2903         printf "%4d %s\n", $hash{$key}, $key;
2904     }
2905
2906 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2907 allocated for the given hash.  This can gain you a measure of efficiency if
2908 you know the hash is going to get big.  (This is similar to pre-extending
2909 an array by assigning a larger number to $#array.)  If you say
2910
2911     keys %hash = 200;
2912
2913 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2914 in fact, since it rounds up to the next power of two.  These
2915 buckets will be retained even if you do C<%hash = ()>, use C<undef
2916 %hash> if you want to free the storage while C<%hash> is still in scope.
2917 You can't shrink the number of buckets allocated for the hash using
2918 C<keys> in this way (but you needn't worry about doing this by accident,
2919 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
2920 error.
2921
2922 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
2923 a reference to an unblessed hash or array.  The argument will be
2924 dereferenced automatically.  This aspect of C<keys> is considered highly
2925 experimental.  The exact behaviour may change in a future version of Perl.
2926
2927     for (keys $hashref) { ... }
2928     for (keys $obj->get_arrayref) { ... }
2929
2930 To avoid confusing would-be users of your code who are running earlier
2931 versions of Perl with mysterious syntax errors, put this sort of thing at
2932 the top of your file to signal that your code will work I<only> on Perls of
2933 a recent vintage:
2934
2935     use 5.012;  # so keys/values/each work on arrays
2936     use 5.014;  # so keys/values/each work on scalars (experimental)
2937
2938 See also C<each>, C<values>, and C<sort>.
2939
2940 =item kill SIGNAL, LIST
2941
2942 =item kill SIGNAL
2943 X<kill> X<signal>
2944
2945 Sends a signal to a list of processes.  Returns the number of
2946 processes successfully signaled (which is not necessarily the
2947 same as the number actually killed).
2948
2949     $cnt = kill 1, $child1, $child2;
2950     kill 9, @goners;
2951
2952 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2953 checks whether it's I<possible> to send a signal to it (that
2954 means, to be brief, that the process is owned by the same user, or we are
2955 the super-user).  This is useful to check that a child process is still
2956 alive (even if only as a zombie) and hasn't changed its UID.  See
2957 L<perlport> for notes on the portability of this construct.
2958
2959 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2960 of processes.  That means you usually
2961 want to use positive not negative signals.
2962 You may also use a signal name in quotes.
2963
2964 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2965 the operating system.  For example, on POSIX-conforming systems, zero will
2966 signal the current process group and -1 will signal all processes.
2967
2968 See L<perlipc/"Signals"> for more details.
2969
2970 On some platforms such as Windows where the fork() system call is not available.
2971 Perl can be built to emulate fork() at the interpreter level.
2972 This emulation has limitations related to kill that have to be considered,
2973 for code running on Windows and in code intended to be portable.
2974
2975 See L<perlfork> for more details.
2976
2977 If there is no I<LIST> of processes, no signal is sent, and the return
2978 value is 0.  This form is sometimes used, however, because it causes
2979 tainting checks to be run.  But see
2980 L<perlsec/Laundering and Detecting Tainted Data>.
2981
2982 Portability issues: L<perlport/kill>.
2983
2984 =item last LABEL
2985 X<last> X<break>
2986
2987 =item last
2988
2989 The C<last> command is like the C<break> statement in C (as used in
2990 loops); it immediately exits the loop in question.  If the LABEL is
2991 omitted, the command refers to the innermost enclosing loop.  The
2992 C<continue> block, if any, is not executed:
2993
2994     LINE: while (<STDIN>) {
2995         last LINE if /^$/;  # exit when done with header
2996         #...
2997     }
2998
2999 C<last> cannot be used to exit a block that returns a value such as
3000 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3001 a grep() or map() operation.
3002
3003 Note that a block by itself is semantically identical to a loop
3004 that executes once.  Thus C<last> can be used to effect an early
3005 exit out of such a block.
3006
3007 See also L</continue> for an illustration of how C<last>, C<next>, and
3008 C<redo> work.
3009
3010 =item lc EXPR
3011 X<lc> X<lowercase>
3012
3013 =item lc
3014
3015 Returns a lowercased version of EXPR.  This is the internal function
3016 implementing the C<\L> escape in double-quoted strings.
3017
3018 If EXPR is omitted, uses C<$_>.
3019
3020 What gets returned depends on several factors:
3021
3022 =over
3023
3024 =item If C<use bytes> is in effect:
3025
3026 =over
3027
3028 =item On EBCDIC platforms
3029
3030 The results are what the C language system call C<tolower()> returns.
3031
3032 =item On ASCII platforms
3033
3034 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3035 respectively.
3036
3037 =back
3038
3039 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3040
3041 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3042 semantics for the remaining code points (this last can only happen if
3043 the UTF8 flag is also set).  See L<perllocale>.
3044
3045 A deficiency in this is that case changes that cross the 255/256
3046 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3047 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3048 platforms).   But under C<use locale>, the lower case of U+1E9E is
3049 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3050 current locale, and Perl has no way of knowing if that character even
3051 exists in the locale, much less what code point it is.  Perl returns
3052 the input character unchanged, for all instances (and there aren't
3053 many) where the 255/256 boundary would otherwise be crossed.
3054
3055 =item Otherwise, If EXPR has the UTF8 flag set:
3056
3057 Unicode semantics are used for the case change.
3058
3059 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'>) is in effect:
3060
3061 Unicode semantics are used for the case change.
3062
3063 =item Otherwise:
3064
3065 =over
3066
3067 =item On EBCDIC platforms
3068
3069 The results are what the C language system call C<tolower()> returns.
3070
3071 =item On ASCII platforms
3072
3073 ASCII semantics are used for the case change.  The lowercase of any character
3074 outside the ASCII range is the character itself.
3075
3076 =back
3077
3078 =back
3079
3080 =item lcfirst EXPR
3081 X<lcfirst> X<lowercase>
3082
3083 =item lcfirst
3084
3085 Returns the value of EXPR with the first character lowercased.  This
3086 is the internal function implementing the C<\l> escape in
3087 double-quoted strings.
3088
3089 If EXPR is omitted, uses C<$_>.
3090
3091 This function behaves the same way under various pragmata, such as in a locale,
3092 as L</lc> does.
3093
3094 =item length EXPR
3095 X<length> X<size>
3096
3097 =item length
3098
3099 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3100 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3101 C<undef>.
3102
3103 This function cannot be used on an entire array or hash to find out how
3104 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3105 %hash>, respectively.
3106
3107 Like all Perl character operations, length() normally deals in logical
3108 characters, not physical bytes.  For how many bytes a string encoded as
3109 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3110 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3111
3112 =item __LINE__
3113 X<__LINE__>
3114
3115 A special token that compiles to the current line number.
3116
3117 =item link OLDFILE,NEWFILE
3118 X<link>
3119
3120 Creates a new filename linked to the old filename.  Returns true for
3121 success, false otherwise.
3122
3123 Portability issues: L<perlport/link>.
3124
3125 =item listen SOCKET,QUEUESIZE
3126 X<listen>
3127
3128 Does the same thing that the listen(2) system call does.  Returns true if
3129 it succeeded, false otherwise.  See the example in
3130 L<perlipc/"Sockets: Client/Server Communication">.
3131
3132 =item local EXPR
3133 X<local>
3134
3135 You really probably want to be using C<my> instead, because C<local> isn't
3136 what most people think of as "local".  See
3137 L<perlsub/"Private Variables via my()"> for details.
3138
3139 A local modifies the listed variables to be local to the enclosing
3140 block, file, or eval.  If more than one value is listed, the list must
3141 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3142 for details, including issues with tied arrays and hashes.
3143
3144 The C<delete local EXPR> construct can also be used to localize the deletion
3145 of array/hash elements to the current block.
3146 See L<perlsub/"Localized deletion of elements of composite types">.
3147
3148 =item localtime EXPR
3149 X<localtime> X<ctime>
3150
3151 =item localtime
3152
3153 Converts a time as returned by the time function to a 9-element list
3154 with the time analyzed for the local time zone.  Typically used as
3155 follows:
3156
3157     #  0    1    2     3     4    5     6     7     8
3158     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3159                                                 localtime(time);
3160
3161 All list elements are numeric and come straight out of the C `struct
3162 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3163 of the specified time.
3164
3165 C<$mday> is the day of the month and C<$mon> the month in
3166 the range C<0..11>, with 0 indicating January and 11 indicating December.
3167 This makes it easy to get a month name from a list:
3168
3169     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
3170     print "$abbr[$mon] $mday";
3171     # $mon=9, $mday=18 gives "Oct 18"
3172
3173 C<$year> contains the number of years since 1900.  To get a 4-digit
3174 year write:
3175
3176     $year += 1900;
3177
3178 To get the last two digits of the year (e.g., "01" in 2001) do:
3179
3180     $year = sprintf("%02d", $year % 100);
3181
3182 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3183 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3184 (or C<0..365> in leap years.)
3185
3186 C<$isdst> is true if the specified time occurs during Daylight Saving
3187 Time, false otherwise.
3188
3189 If EXPR is omitted, C<localtime()> uses the current time (as returned
3190 by time(3)).
3191
3192 In scalar context, C<localtime()> returns the ctime(3) value:
3193
3194     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3195
3196 The format of this scalar value is B<not> locale-dependent
3197 but built into Perl.  For GMT instead of local
3198 time use the L</gmtime> builtin.  See also the
3199 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3200 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3201 and mktime(3) functions.
3202
3203 To get somewhat similar but locale-dependent date strings, set up your
3204 locale environment variables appropriately (please see L<perllocale>) and
3205 try for example:
3206
3207     use POSIX qw(strftime);
3208     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3209     # or for GMT formatted appropriately for your locale:
3210     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3211
3212 Note that the C<%a> and C<%b>, the short forms of the day of the week
3213 and the month of the year, may not necessarily be three characters wide.
3214
3215 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3216 by-name access mechanism to the gmtime() and localtime() functions,
3217 respectively.
3218
3219 For a comprehensive date and time representation look at the
3220 L<DateTime> module on CPAN.
3221
3222 Portability issues: L<perlport/localtime>.
3223
3224 =item lock THING
3225 X<lock>
3226
3227 This function places an advisory lock on a shared variable or referenced
3228 object contained in I<THING> until the lock goes out of scope.
3229
3230 The value returned is the scalar itself, if the argument is a scalar, or a
3231 reference, if the argument is a hash, array or subroutine.
3232
3233 lock() is a "weak keyword" : this means that if you've defined a function
3234 by this name (before any calls to it), that function will be called
3235 instead.  If you are not under C<use threads::shared> this does nothing.
3236 See L<threads::shared>.
3237
3238 =item log EXPR
3239 X<log> X<logarithm> X<e> X<ln> X<base>
3240
3241 =item log
3242
3243 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3244 returns the log of C<$_>.  To get the
3245 log of another base, use basic algebra:
3246 The base-N log of a number is equal to the natural log of that number
3247 divided by the natural log of N.  For example:
3248
3249     sub log10 {
3250         my $n = shift;
3251         return log($n)/log(10);
3252     }
3253
3254 See also L</exp> for the inverse operation.
3255
3256 =item lstat FILEHANDLE
3257 X<lstat>
3258
3259 =item lstat EXPR
3260
3261 =item lstat DIRHANDLE
3262
3263 =item lstat
3264
3265 Does the same thing as the C<stat> function (including setting the
3266 special C<_> filehandle) but stats a symbolic link instead of the file
3267 the symbolic link points to.  If symbolic links are unimplemented on
3268 your system, a normal C<stat> is done.  For much more detailed
3269 information, please see the documentation for C<stat>.
3270
3271 If EXPR is omitted, stats C<$_>.
3272
3273 Portability issues: L<perlport/lstat>.
3274
3275 =item m//
3276
3277 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3278
3279 =item map BLOCK LIST
3280 X<map>
3281
3282 =item map EXPR,LIST
3283
3284 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3285 C<$_> to each element) and returns the list value composed of the
3286 results of each such evaluation.  In scalar context, returns the
3287 total number of elements so generated.  Evaluates BLOCK or EXPR in
3288 list context, so each element of LIST may produce zero, one, or
3289 more elements in the returned value.
3290
3291     @chars = map(chr, @numbers);
3292
3293 translates a list of numbers to the corresponding characters.
3294
3295     my @squares = map { $_ * $_ } @numbers;
3296
3297 translates a list of numbers to their squared values.
3298
3299     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3300
3301 shows that number of returned elements can differ from the number of
3302 input elements.  To omit an element, return an empty list ().
3303 This could also be achieved by writing
3304
3305     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3306
3307 which makes the intention more clear.
3308
3309 Map always returns a list, which can be
3310 assigned to a hash such that the elements
3311 become key/value pairs.  See L<perldata> for more details.
3312
3313     %hash = map { get_a_key_for($_) => $_ } @array;
3314
3315 is just a funny way to write
3316
3317     %hash = ();
3318     foreach (@array) {
3319         $hash{get_a_key_for($_)} = $_;
3320     }
3321
3322 Note that C<$_> is an alias to the list value, so it can be used to
3323 modify the elements of the LIST.  While this is useful and supported,
3324 it can cause bizarre results if the elements of LIST are not variables.
3325 Using a regular C<foreach> loop for this purpose would be clearer in
3326 most cases.  See also L</grep> for an array composed of those items of
3327 the original list for which the BLOCK or EXPR evaluates to true.
3328
3329 If C<$_> is lexical in the scope where the C<map> appears (because it has
3330 been declared with C<my $_>), then, in addition to being locally aliased to
3331 the list elements, C<$_> keeps being lexical inside the block; that is, it
3332 can't be seen from the outside, avoiding any potential side-effects.
3333
3334 C<{> starts both hash references and blocks, so C<map { ...> could be either
3335 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3336 ahead for the closing C<}> it has to take a guess at which it's dealing with
3337 based on what it finds just after the
3338 C<{>.  Usually it gets it right, but if it
3339 doesn't it won't realize something is wrong until it gets to the C<}> and
3340 encounters the missing (or unexpected) comma.  The syntax error will be
3341 reported close to the C<}>, but you'll need to change something near the C<{>
3342 such as using a unary C<+> to give Perl some help:
3343
3344     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3345     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3346     %hash = map { ("\L$_" => 1) } @array  # this also works
3347     %hash = map {  lc($_) => 1  } @array  # as does this.
3348     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3349
3350     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3351
3352 or to force an anon hash constructor use C<+{>:
3353
3354    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3355
3356 to get a list of anonymous hashes each with only one entry apiece.
3357
3358 =item mkdir FILENAME,MASK
3359 X<mkdir> X<md> X<directory, create>
3360
3361 =item mkdir FILENAME
3362
3363 =item mkdir
3364
3365 Creates the directory specified by FILENAME, with permissions
3366 specified by MASK (as modified by C<umask>).  If it succeeds it
3367 returns true; otherwise it returns false and sets C<$!> (errno).
3368 MASK defaults to 0777 if omitted, and FILENAME defaults
3369 to C<$_> if omitted.
3370
3371 In general, it is better to create directories with a permissive MASK
3372 and let the user modify that with their C<umask> than it is to supply
3373 a restrictive MASK and give the user no way to be more permissive.
3374 The exceptions to this rule are when the file or directory should be
3375 kept private (mail files, for instance).  The perlfunc(1) entry on
3376 C<umask> discusses the choice of MASK in more detail.
3377
3378 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3379 number of trailing slashes.  Some operating and filesystems do not get
3380 this right, so Perl automatically removes all trailing slashes to keep
3381 everyone happy.
3382
3383 To recursively create a directory structure, look at
3384 the C<mkpath> function of the L<File::Path> module.
3385
3386 =item msgctl ID,CMD,ARG
3387 X<msgctl>
3388
3389 Calls the System V IPC function msgctl(2).  You'll probably have to say
3390
3391     use IPC::SysV;
3392
3393 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3394 then ARG must be a variable that will hold the returned C<msqid_ds>
3395 structure.  Returns like C<ioctl>: the undefined value for error,
3396 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3397 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3398 C<IPC::Semaphore>.
3399
3400 Portability issues: L<perlport/msgctl>.
3401
3402 =item msgget KEY,FLAGS
3403 X<msgget>
3404
3405 Calls the System V IPC function msgget(2).  Returns the message queue
3406 id, or C<undef> on error.  See also
3407 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3408 C<IPC::Msg>.
3409
3410 Portability issues: L<perlport/msgget>.
3411
3412 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3413 X<msgrcv>
3414
3415 Calls the System V IPC function msgrcv to receive a message from
3416 message queue ID into variable VAR with a maximum message size of
3417 SIZE.  Note that when a message is received, the message type as a
3418 native long integer will be the first thing in VAR, followed by the
3419 actual message.  This packing may be opened with C<unpack("l! a*")>.
3420 Taints the variable.  Returns true if successful, false 
3421 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3422 C<IPC::SysV> and C<IPC::SysV::Msg>.
3423
3424 Portability issues: L<perlport/msgrcv>.
3425
3426 =item msgsnd ID,MSG,FLAGS
3427 X<msgsnd>
3428
3429 Calls the System V IPC function msgsnd to send the message MSG to the
3430 message queue ID.  MSG must begin with the native long integer message
3431 type, be followed by the length of the actual message, and then finally
3432 the message itself.  This kind of packing can be achieved with
3433 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3434 false on error.  See also the C<IPC::SysV>
3435 and C<IPC::SysV::Msg> documentation.
3436
3437 Portability issues: L<perlport/msgsnd>.
3438
3439 =item my EXPR
3440 X<my>
3441
3442 =item my TYPE EXPR
3443
3444 =item my EXPR : ATTRS
3445
3446 =item my TYPE EXPR : ATTRS
3447
3448 A C<my> declares the listed variables to be local (lexically) to the
3449 enclosing block, file, or C<eval>.  If more than one value is listed,
3450 the list must be placed in parentheses.
3451
3452 The exact semantics and interface of TYPE and ATTRS are still
3453 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3454 and attributes are handled using the C<attributes> pragma, or starting
3455 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3456 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3457 L<attributes>, and L<Attribute::Handlers>.
3458
3459 =item next LABEL
3460 X<next> X<continue>
3461
3462 =item next
3463
3464 The C<next> command is like the C<continue> statement in C; it starts
3465 the next iteration of the loop:
3466
3467     LINE: while (<STDIN>) {
3468         next LINE if /^#/;  # discard comments
3469         #...
3470     }
3471
3472 Note that if there were a C<continue> block on the above, it would get
3473 executed even on discarded lines.  If LABEL is omitted, the command
3474 refers to the innermost enclosing loop.
3475
3476 C<next> cannot be used to exit a block which returns a value such as
3477 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3478 a grep() or map() operation.
3479
3480 Note that a block by itself is semantically identical to a loop
3481 that executes once.  Thus C<next> will exit such a block early.
3482
3483 See also L</continue> for an illustration of how C<last>, C<next>, and
3484 C<redo> work.
3485
3486 =item no MODULE VERSION LIST
3487 X<no declarations>
3488 X<unimporting>
3489
3490 =item no MODULE VERSION
3491
3492 =item no MODULE LIST
3493
3494 =item no MODULE
3495
3496 =item no VERSION
3497
3498 See the C<use> function, of which C<no> is the opposite.
3499
3500 =item oct EXPR
3501 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3502
3503 =item oct
3504
3505 Interprets EXPR as an octal string and returns the corresponding
3506 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3507 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3508 binary string.  Leading whitespace is ignored in all three cases.)
3509 The following will handle decimal, binary, octal, and hex in standard
3510 Perl notation:
3511
3512     $val = oct($val) if $val =~ /^0/;
3513
3514 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3515 in octal), use sprintf() or printf():
3516
3517     $dec_perms = (stat("filename"))[2] & 07777;
3518     $oct_perm_str = sprintf "%o", $perms;
3519
3520 The oct() function is commonly used when a string such as C<644> needs
3521 to be converted into a file mode, for example.  Although Perl 
3522 automatically converts strings into numbers as needed, this automatic
3523 conversion assumes base 10.
3524
3525 Leading white space is ignored without warning, as too are any trailing 
3526 non-digits, such as a decimal point (C<oct> only handles non-negative
3527 integers, not negative integers or floating point).
3528
3529 =item open FILEHANDLE,EXPR
3530 X<open> X<pipe> X<file, open> X<fopen>
3531
3532 =item open FILEHANDLE,MODE,EXPR
3533
3534 =item open FILEHANDLE,MODE,EXPR,LIST
3535
3536 =item open FILEHANDLE,MODE,REFERENCE
3537
3538 =item open FILEHANDLE
3539
3540 Opens the file whose filename is given by EXPR, and associates it with
3541 FILEHANDLE.
3542
3543 Simple examples to open a file for reading:
3544
3545     open(my $fh, "<", "input.txt") 
3546         or die "cannot open < input.txt: $!";
3547
3548 and for writing:
3549
3550     open(my $fh, ">", "output.txt") 
3551         or die "cannot open > output.txt: $!";
3552
3553 (The following is a comprehensive reference to open(): for a gentler
3554 introduction you may consider L<perlopentut>.)
3555
3556 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3557 new filehandle is autovivified, meaning that the variable is assigned a
3558 reference to a newly allocated anonymous filehandle.  Otherwise if
3559 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3560 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3561 in effect.)
3562
3563 If EXPR is omitted, the global (package) scalar variable of the same
3564 name as the FILEHANDLE contains the filename.  (Note that lexical 
3565 variables--those declared with C<my> or C<state>--will not work for this
3566 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3567 call to open.)
3568
3569 If three (or more) arguments are specified, the open mode (including
3570 optional encoding) in the second argument are distinct from the filename in
3571 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3572 If MODE is C<< > >>, the file is opened for output, with existing files
3573 first being truncated ("clobbered") and nonexisting files newly created.
3574 If MODE is C<<< >> >>>, the file is opened for appending, again being
3575 created if necessary.
3576
3577 You can put a C<+> in front of the C<< > >> or C<< < >> to
3578 indicate that you want both read and write access to the file; thus
3579 C<< +< >> is almost always preferred for read/write updates--the 
3580 C<< +> >> mode would clobber the file first.  You can't usually use
3581 either read-write mode for updating textfiles, since they have
3582 variable-length records.  See the B<-i> switch in L<perlrun> for a
3583 better approach.  The file is created with permissions of C<0666>
3584 modified by the process's C<umask> value.
3585
3586 These various prefixes correspond to the fopen(3) modes of C<r>,
3587 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3588
3589 In the one- and two-argument forms of the call, the mode and filename
3590 should be concatenated (in that order), preferably separated by white
3591 space.  You can--but shouldn't--omit the mode in these forms when that mode
3592 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3593 the filename argument is a known literal.
3594
3595 For three or more arguments if MODE is C<|->, the filename is
3596 interpreted as a command to which output is to be piped, and if MODE
3597 is C<-|>, the filename is interpreted as a command that pipes
3598 output to us.  In the two-argument (and one-argument) form, one should
3599 replace dash (C<->) with the command.
3600 See L<perlipc/"Using open() for IPC"> for more examples of this.
3601 (You are not allowed to C<open> to a command that pipes both in I<and>
3602 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3603 L<perlipc/"Bidirectional Communication with Another Process"> for
3604 alternatives.)
3605
3606 In the form of pipe opens taking three or more arguments, if LIST is specified
3607 (extra arguments after the command name) then LIST becomes arguments
3608 to the command invoked if the platform supports it.  The meaning of
3609 C<open> with more than three arguments for non-pipe modes is not yet
3610 defined, but experimental "layers" may give extra LIST arguments
3611 meaning.
3612
3613 In the two-argument (and one-argument) form, opening C<< <- >> 
3614 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3615
3616 You may (and usually should) use the three-argument form of open to specify
3617 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3618 that affect how the input and output are processed (see L<open> and
3619 L<PerlIO> for more details).  For example:
3620
3621   open(my $fh, "<:encoding(UTF-8)", "filename")
3622     || die "can't open UTF-8 encoded filename: $!";
3623
3624 opens the UTF8-encoded file containing Unicode characters;
3625 see L<perluniintro>.  Note that if layers are specified in the
3626 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3627 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3628 Those layers will also be ignored if you specifying a colon with no name
3629 following it.  In that case the default layer for the operating system
3630 (:raw on Unix, :crlf on Windows) is used.
3631
3632 Open returns nonzero on success, the undefined value otherwise.  If
3633 the C<open> involved a pipe, the return value happens to be the pid of
3634 the subprocess.
3635
3636 If you're running Perl on a system that distinguishes between text
3637 files and binary files, then you should check out L</binmode> for tips
3638 for dealing with this.  The key distinction between systems that need
3639 C<binmode> and those that don't is their text file formats.  Systems
3640 like Unix, Mac OS, and Plan 9, that end lines with a single
3641 character and encode that character in C as C<"\n"> do not
3642 need C<binmode>.  The rest need it.
3643
3644 When opening a file, it's seldom a good idea to continue 
3645 if the request failed, so C<open> is frequently used with
3646 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3647 where you want to format a suitable error message (but there are
3648 modules that can help with that problem)) always check
3649 the return value from opening a file.  
3650
3651 As a special case the three-argument form with a read/write mode and the third
3652 argument being C<undef>:
3653
3654     open(my $tmp, "+>", undef) or die ...
3655
3656 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3657 works for symmetry, but you really should consider writing something
3658 to the temporary file first.  You will need to seek() to do the
3659 reading.
3660
3661 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3662 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3663 open filehandles directly to Perl scalars via:
3664
3665     open($fh, ">", \$variable) || ..
3666
3667 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3668
3669     close STDOUT;
3670     open(STDOUT, ">", \$variable)
3671         or die "Can't open STDOUT: $!";
3672
3673 General examples:
3674
3675     $ARTICLE = 100;
3676     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3677     while (<ARTICLE>) {...
3678
3679     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3680     # if the open fails, output is discarded
3681
3682     open(my $dbase, "+<", "dbase.mine")      # open for update
3683         or die "Can't open 'dbase.mine' for update: $!";
3684
3685     open(my $dbase, "+<dbase.mine")          # ditto
3686         or die "Can't open 'dbase.mine' for update: $!";
3687
3688     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3689         or die "Can't start caesar: $!";
3690
3691     open(ARTICLE, "caesar <$article |")      # ditto
3692         or die "Can't start caesar: $!";
3693
3694     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3695         or die "Can't start sort: $!";
3696
3697     # in-memory files
3698     open(MEMORY, ">", \$var)
3699         or die "Can't open memory file: $!";
3700     print MEMORY "foo!\n";                   # output will appear in $var
3701
3702     # process argument list of files along with any includes
3703
3704     foreach $file (@ARGV) {
3705         process($file, "fh00");
3706     }
3707
3708     sub process {
3709         my($filename, $input) = @_;
3710         $input++;    # this is a string increment
3711         unless (open($input, "<", $filename)) {
3712             print STDERR "Can't open $filename: $!\n";
3713             return;
3714         }
3715
3716         local $_;
3717         while (<$input>) {    # note use of indirection
3718             if (/^#include "(.*)"/) {
3719                 process($1, $input);
3720                 next;
3721             }
3722             #...          # whatever
3723         }
3724     }
3725
3726 See L<perliol> for detailed info on PerlIO.
3727
3728 You may also, in the Bourne shell tradition, specify an EXPR beginning
3729 with C<< >& >>, in which case the rest of the string is interpreted
3730 as the name of a filehandle (or file descriptor, if numeric) to be
3731 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3732 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3733 The mode you specify should match the mode of the original filehandle.
3734 (Duping a filehandle does not take into account any existing contents
3735 of IO buffers.)  If you use the three-argument
3736 form, then you can pass either a
3737 number, the name of a filehandle, or the normal "reference to a glob".
3738
3739 Here is a script that saves, redirects, and restores C<STDOUT> and
3740 C<STDERR> using various methods:
3741
3742     #!/usr/bin/perl
3743     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3744     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
3745
3746     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
3747     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3748
3749     select STDERR; $| = 1;  # make unbuffered
3750     select STDOUT; $| = 1;  # make unbuffered
3751
3752     print STDOUT "stdout 1\n";  # this works for
3753     print STDERR "stderr 1\n";  # subprocesses too
3754
3755     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
3756     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
3757
3758     print STDOUT "stdout 2\n";
3759     print STDERR "stderr 2\n";
3760
3761 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3762 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3763 that file descriptor (and not call C<dup(2)>); this is more
3764 parsimonious of file descriptors.  For example:
3765
3766     # open for input, reusing the fileno of $fd
3767     open(FILEHANDLE, "<&=$fd")
3768
3769 or
3770
3771     open(FILEHANDLE, "<&=", $fd)
3772
3773 or
3774
3775     # open for append, using the fileno of OLDFH
3776     open(FH, ">>&=", OLDFH)
3777
3778 or
3779
3780     open(FH, ">>&=OLDFH")
3781
3782 Being parsimonious on filehandles is also useful (besides being
3783 parsimonious) for example when something is dependent on file
3784 descriptors, like for example locking using flock().  If you do just
3785 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
3786 descriptor as B, and therefore flock(A) will not flock(B) nor vice
3787 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
3788 the same underlying system file descriptor.
3789
3790 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
3791 fdopen() to implement the C<=> functionality.  On many Unix systems,
3792 fdopen() fails when file descriptors exceed a certain value, typically 255.
3793 For Perls 5.8.0 and later, PerlIO is (most often) the default.
3794
3795 You can see whether your Perl was built with PerlIO by running C<perl -V>
3796 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
3797 have PerlIO; otherwise you don't.
3798
3799 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
3800 with the one- or two-argument forms of C<open>), 
3801 an implicit C<fork> is done, so C<open> returns twice: in the parent
3802 process it returns the pid
3803 of the child process, and in the child process it returns (a defined) C<0>.
3804 Use C<defined($pid)> or C<//> to determine whether the open was successful.
3805
3806 For example, use either
3807
3808     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
3809
3810 or
3811     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
3812
3813 followed by 
3814
3815     if ($child_pid) {
3816         # am the parent:
3817         # either write TO_KID or else read FROM_KID
3818         ...
3819         wait $child_pid;
3820     } else {
3821         # am the child; use STDIN/STDOUT normally
3822         ...
3823         exit;
3824     } 
3825
3826 The filehandle behaves normally for the parent, but I/O to that
3827 filehandle is piped from/to the STDOUT/STDIN of the child process.
3828 In the child process, the filehandle isn't opened--I/O happens from/to
3829 the new STDOUT/STDIN.  Typically this is used like the normal
3830 piped open when you want to exercise more control over just how the
3831 pipe command gets executed, such as when running setuid and
3832 you don't want to have to scan shell commands for metacharacters.
3833
3834 The following blocks are more or less equivalent:
3835
3836     open(FOO, "|tr '[a-z]' '[A-Z]'");
3837     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
3838     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
3839     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
3840
3841     open(FOO, "cat -n '$file'|");
3842     open(FOO, "-|", "cat -n '$file'");
3843     open(FOO, "-|") || exec "cat", "-n", $file;
3844     open(FOO, "-|", "cat", "-n", $file);
3845
3846 The last two examples in each block show the pipe as "list form", which is
3847 not yet supported on all platforms.  A good rule of thumb is that if
3848 your platform has a real C<fork()> (in other words, if your platform is
3849 Unix, including Linux and MacOS X), you can use the list form.  You would 
3850 want to use the list form of the pipe so you can pass literal arguments
3851 to the command without risk of the shell interpreting any shell metacharacters
3852 in them.  However, this also bars you from opening pipes to commands
3853 that intentionally contain shell metacharacters, such as:
3854
3855     open(FOO, "|cat -n | expand -4 | lpr")
3856         // die "Can't open pipeline to lpr: $!";
3857
3858 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3859
3860 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3861 output before any operation that may do a fork, but this may not be
3862 supported on some platforms (see L<perlport>).  To be safe, you may need
3863 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3864 of C<IO::Handle> on any open handles.
3865
3866 On systems that support a close-on-exec flag on files, the flag will
3867 be set for the newly opened file descriptor as determined by the value
3868 of C<$^F>.  See L<perlvar/$^F>.
3869
3870 Closing any piped filehandle causes the parent process to wait for the
3871 child to finish, then returns the status value in C<$?> and
3872 C<${^CHILD_ERROR_NATIVE}>.
3873
3874 The filename passed to the one- and two-argument forms of open() will
3875 have leading and trailing whitespace deleted and normal
3876 redirection characters honored.  This property, known as "magic open",
3877 can often be used to good effect.  A user could specify a filename of
3878 F<"rsh cat file |">, or you could change certain filenames as needed:
3879
3880     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3881     open(FH, $filename) or die "Can't open $filename: $!";
3882
3883 Use the three-argument form to open a file with arbitrary weird characters in it,
3884
3885     open(FOO, "<", $file)
3886         || die "can't open < $file: $!";
3887
3888 otherwise it's necessary to protect any leading and trailing whitespace:
3889
3890     $file =~ s#^(\s)#./$1#;
3891     open(FOO, "< $file\0")
3892         || die "open failed: $!";
3893
3894 (this may not work on some bizarre filesystems).  One should
3895 conscientiously choose between the I<magic> and I<three-argument> form
3896 of open():
3897
3898     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
3899
3900 will allow the user to specify an argument of the form C<"rsh cat file |">,
3901 but will not work on a filename that happens to have a trailing space, while
3902
3903     open(IN, "<", $ARGV[0])
3904         || die "can't open < $ARGV[0]: $!";
3905
3906 will have exactly the opposite restrictions.
3907
3908 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3909 should use the C<sysopen> function, which involves no such magic (but may
3910 use subtly different filemodes than Perl open(), which is mapped to C
3911 fopen()).  This is another way to protect your filenames from
3912 interpretation.  For example:
3913
3914     use IO::Handle;
3915     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3916         or die "sysopen $path: $!";
3917     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3918     print HANDLE "stuff $$\n";
3919     seek(HANDLE, 0, 0);
3920     print "File contains: ", <HANDLE>;
3921
3922 Using the constructor from the C<IO::Handle> package (or one of its
3923 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3924 filehandles that have the scope of the variables used to hold them, then
3925 automatically (but silently) close once their reference counts become
3926 zero, typically at scope exit:
3927
3928     use IO::File;
3929     #...
3930     sub read_myfile_munged {
3931         my $ALL = shift;
3932         # or just leave it undef to autoviv
3933         my $handle = IO::File->new;
3934         open($handle, "<", "myfile") or die "myfile: $!";
3935         $first = <$handle>
3936             or return ();     # Automatically closed here.
3937         mung($first) or die "mung failed";  # Or here.
3938         return (first, <$handle>) if $ALL;  # Or here.
3939         return $first;                      # Or here.
3940     }
3941
3942 B<WARNING:> The previous example has a bug because the automatic
3943 close that happens when the refcount on C<handle> does not
3944 properly detect and report failures.  I<Always> close the handle
3945 yourself and inspect the return value.
3946
3947     close($handle) 
3948         || warn "close failed: $!";
3949
3950 See L</seek> for some details about mixing reading and writing.
3951
3952 Portability issues: L<perlport/open>.
3953
3954 =item opendir DIRHANDLE,EXPR
3955 X<opendir>
3956
3957 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3958 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3959 DIRHANDLE may be an expression whose value can be used as an indirect
3960 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3961 scalar variable (or array or hash element), the variable is assigned a
3962 reference to a new anonymous dirhandle; that is, it's autovivified.
3963 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3964
3965 See the example at C<readdir>.
3966
3967 =item ord EXPR
3968 X<ord> X<encoding>
3969
3970 =item ord
3971
3972 Returns the numeric value of the first character of EXPR.
3973 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
3974 (Note I<character>, not byte.)
3975
3976 For the reverse, see L</chr>.
3977 See L<perlunicode> for more about Unicode.
3978
3979 =item our EXPR
3980 X<our> X<global>
3981
3982 =item our TYPE EXPR
3983
3984 =item our EXPR : ATTRS
3985
3986 =item our TYPE EXPR : ATTRS
3987
3988 C<our> associates a simple name with a package variable in the current
3989 package for use within the current scope.  When C<use strict 'vars'> is in
3990 effect, C<our> lets you use declared global variables without qualifying
3991 them with package names, within the lexical scope of the C<our> declaration.
3992 In this way C<our> differs from C<use vars>, which is package-scoped.
3993
3994 Unlike C<my> or C<state>, which allocates storage for a variable and
3995 associates a simple name with that storage for use within the current
3996 scope, C<our> associates a simple name with a package (read: global)
3997 variable in the current package, for use within the current lexical scope.
3998 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
3999 does not necessarily create a variable.
4000
4001 If more than one value is listed, the list must be placed
4002 in parentheses.
4003
4004     our $foo;
4005     our($bar, $baz);
4006
4007 An C<our> declaration declares a global variable that will be visible
4008 across its entire lexical scope, even across package boundaries.  The
4009 package in which the variable is entered is determined at the point
4010 of the declaration, not at the point of use.  This means the following
4011 behavior holds:
4012
4013     package Foo;
4014     our $bar;      # declares $Foo::bar for rest of lexical scope
4015     $bar = 20;
4016
4017     package Bar;
4018     print $bar;    # prints 20, as it refers to $Foo::bar
4019
4020 Multiple C<our> declarations with the same name in the same lexical
4021 scope are allowed if they are in different packages.  If they happen
4022 to be in the same package, Perl will emit warnings if you have asked
4023 for them, just like multiple C<my> declarations.  Unlike a second
4024 C<my> declaration, which will bind the name to a fresh variable, a
4025 second C<our> declaration in the same package, in the same scope, is
4026 merely redundant.
4027
4028     use warnings;
4029     package Foo;
4030     our $bar;      # declares $Foo::bar for rest of lexical scope
4031     $bar = 20;
4032
4033     package Bar;
4034     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4035     print $bar;    # prints 30
4036
4037     our $bar;      # emits warning but has no other effect
4038     print $bar;    # still prints 30
4039
4040 An C<our> declaration may also have a list of attributes associated
4041 with it.
4042
4043 The exact semantics and interface of TYPE and ATTRS are still
4044 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4045 and attributes are handled using the C<attributes> pragma, or, starting
4046 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4047 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4048 L<attributes>, and L<Attribute::Handlers>.
4049
4050 =item pack TEMPLATE,LIST
4051 X<pack>
4052
4053 Takes a LIST of values and converts it into a string using the rules
4054 given by the TEMPLATE.  The resulting string is the concatenation of
4055 the converted values.  Typically, each converted value looks
4056 like its machine-level representation.  For example, on 32-bit machines
4057 an integer may be represented by a sequence of 4 bytes, which  will in
4058 Perl be presented as a string that's 4 characters long. 
4059
4060 See L<perlpacktut> for an introduction to this function.
4061
4062 The TEMPLATE is a sequence of characters that give the order and type
4063 of values, as follows:
4064
4065     a  A string with arbitrary binary data, will be null padded.
4066     A  A text (ASCII) string, will be space padded.
4067     Z  A null-terminated (ASCIZ) string, will be null padded.
4068
4069     b  A bit string (ascending bit order inside each byte,
4070        like vec()).
4071     B  A bit string (descending bit order inside each byte).
4072     h  A hex string (low nybble first).
4073     H  A hex string (high nybble first).
4074
4075     c  A signed char (8-bit) value.
4076     C  An unsigned char (octet) value.
4077     W  An unsigned char value (can be greater than 255).
4078
4079     s  A signed short (16-bit) value.
4080     S  An unsigned short value.
4081
4082     l  A signed long (32-bit) value.
4083     L  An unsigned long value.
4084
4085     q  A signed quad (64-bit) value.
4086     Q  An unsigned quad value.
4087          (Quads are available only if your system supports 64-bit
4088           integer values _and_ if Perl has been compiled to support
4089           those.  Raises an exception otherwise.)
4090
4091     i  A signed integer value.
4092     I  A unsigned integer value.
4093          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4094           size depends on what a local C compiler calls 'int'.)
4095
4096     n  An unsigned short (16-bit) in "network" (big-endian) order.
4097     N  An unsigned long (32-bit) in "network" (big-endian) order.
4098     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4099     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4100
4101     j  A Perl internal signed integer value (IV).
4102     J  A Perl internal unsigned integer value (UV).
4103
4104     f  A single-precision float in native format.
4105     d  A double-precision float in native format.
4106
4107     F  A Perl internal floating-point value (NV) in native format
4108     D  A float of long-double precision in native format.
4109          (Long doubles are available only if your system supports
4110           long double values _and_ if Perl has been compiled to
4111           support those.  Raises an exception otherwise.)
4112
4113     p  A pointer to a null-terminated string.
4114     P  A pointer to a structure (fixed-length string).
4115
4116     u  A uuencoded string.
4117     U  A Unicode character number.  Encodes to a character in char-
4118        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4119        byte mode.
4120
4121     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4122        for details).  Its bytes represent an unsigned integer in
4123        base 128, most significant digit first, with as few digits
4124        as possible.  Bit eight (the high bit) is set on each byte
4125        except the last.
4126
4127     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4128     X  Back up a byte.
4129     @  Null-fill or truncate to absolute position, counted from the
4130        start of the innermost ()-group.
4131     .  Null-fill or truncate to absolute position specified by
4132        the value.
4133     (  Start of a ()-group.
4134
4135 One or more modifiers below may optionally follow certain letters in the
4136 TEMPLATE (the second column lists letters for which the modifier is valid):
4137
4138     !   sSlLiI     Forces native (short, long, int) sizes instead
4139                    of fixed (16-/32-bit) sizes.
4140
4141         xX         Make x and X act as alignment commands.
4142
4143         nNvV       Treat integers as signed instead of unsigned.
4144
4145         @.         Specify position as byte offset in the internal
4146                    representation of the packed string.  Efficient
4147                    but dangerous.
4148
4149     >   sSiIlLqQ   Force big-endian byte-order on the type.
4150         jJfFdDpP   (The "big end" touches the construct.)
4151
4152     <   sSiIlLqQ   Force little-endian byte-order on the type.
4153         jJfFdDpP   (The "little end" touches the construct.)
4154
4155 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4156 to force a particular byte-order on all components in that group, 
4157 including all its subgroups.
4158
4159 The following rules apply:
4160
4161 =over 
4162
4163 =item *
4164
4165 Each letter may optionally be followed by a number indicating the repeat
4166 count.  A numeric repeat count may optionally be enclosed in brackets, as
4167 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4168 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4169 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4170 something else, described below.  Supplying a C<*> for the repeat count
4171 instead of a number means to use however many items are left, except for:
4172
4173 =over 
4174
4175 =item * 
4176
4177 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4178
4179 =item * 
4180
4181 <.>, where it means relative to the start of the string.
4182
4183 =item * 
4184
4185 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4186
4187 =back 
4188
4189 One can replace a numeric repeat count with a template letter enclosed in
4190 brackets to use the packed byte length of the bracketed template for the
4191 repeat count.
4192
4193 For example, the template C<x[L]> skips as many bytes as in a packed long,
4194 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4195 variable-expanded) unpacks.  If the template in brackets contains alignment
4196 commands (such as C<x![d]>), its packed length is calculated as if the
4197 start of the template had the maximal possible alignment.
4198
4199 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4200 trailing null byte, so the resulting string is always one byte longer than
4201 the byte length of the item itself.
4202
4203 When used with C<@>, the repeat count represents an offset from the start
4204 of the innermost C<()> group.
4205
4206 When used with C<.>, the repeat count determines the starting position to
4207 calculate the value offset as follows:
4208
4209 =over 
4210
4211 =item *
4212
4213 If the repeat count is C<0>, it's relative to the current position.
4214
4215 =item *
4216
4217 If the repeat count is C<*>, the offset is relative to the start of the
4218 packed string.
4219
4220 =item *
4221
4222 And if it's an integer I<n>, the offset is relative to the start of the
4223 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4224 bigger then the group level.
4225
4226 =back
4227
4228 The repeat count for C<u> is interpreted as the maximal number of bytes
4229 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4230 count should not be more than 65.
4231
4232 =item *
4233
4234 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4235 string of length count, padding with nulls or spaces as needed.  When
4236 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4237 after the first null, and C<a> returns data with no stripping at all.
4238
4239 If the value to pack is too long, the result is truncated.  If it's too
4240 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4241 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4242 when the count is 0.
4243
4244 =item *
4245
4246 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4247 Each such format generates 1 bit of the result.  These are typically followed
4248 by a repeat count like C<B8> or C<B64>.
4249
4250 Each result bit is based on the least-significant bit of the corresponding
4251 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4252 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4253
4254 Starting from the beginning of the input string, each 8-tuple
4255 of characters is converted to 1 character of output.  With format C<b>,
4256 the first character of the 8-tuple determines the least-significant bit of a
4257 character; with format C<B>, it determines the most-significant bit of
4258 a character.
4259
4260 If the length of the input string is not evenly divisible by 8, the
4261 remainder is packed as if the input string were padded by null characters
4262 at the end.  Similarly during unpacking, "extra" bits are ignored.
4263
4264 If the input string is longer than needed, remaining characters are ignored.
4265
4266 A C<*> for the repeat count uses all characters of the input field.  
4267 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4268
4269 =item *
4270
4271 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4272 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4273
4274 For each such format, pack() generates 4 bits of result.
4275 With non-alphabetical characters, the result is based on the 4 least-significant
4276 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4277 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4278 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4279 is compatible with the usual hexadecimal digits, so that C<"a"> and
4280 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4281 characters with this format.
4282
4283 Starting from the beginning of the template to pack(), each pair
4284 of characters is converted to 1 character of output.  With format C<h>, the
4285 first character of the pair determines the least-significant nybble of the
4286 output character; with format C<H>, it determines the most-significant
4287 nybble.
4288
4289 If the length of the input string is not even, it behaves as if padded by
4290 a null character at the end.  Similarly, "extra" nybbles are ignored during
4291 unpacking.
4292
4293 If the input string is longer than needed, extra characters are ignored.
4294
4295 A C<*> for the repeat count uses all characters of the input field.  For
4296 unpack(), nybbles are converted to a string of hexadecimal digits.
4297
4298 =item *
4299
4300 The C<p> format packs a pointer to a null-terminated string.  You are
4301 responsible for ensuring that the string is not a temporary value, as that
4302 could potentially get deallocated before you got around to using the packed
4303 result.  The C<P> format packs a pointer to a structure of the size indicated
4304 by the length.  A null pointer is created if the corresponding value for
4305 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4306 unpacks into C<undef>.
4307
4308 If your system has a strange pointer size--meaning a pointer is neither as
4309 big as an int nor as big as a long--it may not be possible to pack or
4310 unpack pointers in big- or little-endian byte order.  Attempting to do
4311 so raises an exception.
4312
4313 =item *
4314
4315 The C</> template character allows packing and unpacking of a sequence of
4316 items where the packed structure contains a packed item count followed by
4317 the packed items themselves.  This is useful when the structure you're
4318 unpacking has encoded the sizes or repeat counts for some of its fields
4319 within the structure itself as separate fields.
4320
4321 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4322 I<length-item> describes how the length value is packed.  Formats likely
4323 to be of most use are integer-packing ones like C<n> for Java strings,
4324 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4325
4326 For C<pack>, I<sequence-item> may have a repeat count, in which case
4327 the minimum of that and the number of available items is used as the argument
4328 for I<length-item>.  If it has no repeat count or uses a '*', the number
4329 of available items is used.
4330
4331 For C<unpack>, an internal stack of integer arguments unpacked so far is
4332 used.  You write C</>I<sequence-item> and the repeat count is obtained by
4333 popping off the last element from the stack.  The I<sequence-item> must not
4334 have a repeat count.
4335
4336 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4337 the I<length-item> is the string length, not the number of strings.  With
4338 an explicit repeat count for pack, the packed string is adjusted to that
4339 length.  For example:
4340
4341  This code:                              gives this result:
4342  
4343   unpack("W/a", "\004Gurusamy")          ("Guru")
4344   unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4345   unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4346
4347   pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4348   pack("a/W2", ord("a") .. ord("z"))    "2ab"
4349
4350 The I<length-item> is not returned explicitly from C<unpack>.
4351
4352 Supplying a count to the I<length-item> format letter is only useful with
4353 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4354 introduce C<"\000"> characters, which Perl does not regard as legal in
4355 numeric strings.
4356
4357 =item *
4358
4359 The integer types C<s>, C<S>, C<l>, and C<L> may be
4360 followed by a C<!> modifier to specify native shorts or
4361 longs.  As shown in the example above, a bare C<l> means
4362 exactly 32 bits, although the native C<long> as seen by the local C compiler
4363 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4364 see whether using C<!> makes any difference this way:
4365
4366     printf "format s is %d, s! is %d\n", 
4367         length pack("s"), length pack("s!");
4368
4369     printf "format l is %d, l! is %d\n", 
4370         length pack("l"), length pack("l!");
4371
4372
4373 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4374 they are identical to C<i> and C<I>.
4375
4376 The actual sizes (in bytes) of native shorts, ints, longs, and long
4377 longs on the platform where Perl was built are also available from
4378 the command line:
4379
4380     $ perl -V:{short,int,long{,long}}size
4381     shortsize='2';
4382     intsize='4';
4383     longsize='4';
4384     longlongsize='8';
4385
4386 or programmatically via the C<Config> module:
4387
4388        use Config;
4389        print $Config{shortsize},    "\n";
4390        print $Config{intsize},      "\n";
4391        print $Config{longsize},     "\n";
4392        print $Config{longlongsize}, "\n";
4393
4394 C<$Config{longlongsize}> is undefined on systems without 
4395 long long support.
4396
4397 =item *
4398
4399 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4400 inherently non-portable between processors and operating systems because
4401 they obey native byteorder and endianness.  For example, a 4-byte integer
4402 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4403 handled by the CPU registers) into bytes as
4404
4405     0x12 0x34 0x56 0x78  # big-endian
4406     0x78 0x56 0x34 0x12  # little-endian
4407
4408 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4409 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4410 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4411 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4412
4413 The names I<big-endian> and I<little-endian> are comic references to the
4414 egg-eating habits of the little-endian Lilliputians and the big-endian
4415 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4416 This entered computer lingo via the paper "On Holy Wars and a Plea for
4417 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4418
4419 Some systems may have even weirder byte orders such as
4420
4421    0x56 0x78 0x12 0x34
4422    0x34 0x12 0x78 0x56
4423
4424 You can determine your system endianness with this incantation:
4425
4426    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4427
4428 The byteorder on the platform where Perl was built is also available
4429 via L<Config>:
4430
4431     use Config;
4432     print "$Config{byteorder}\n";
4433
4434 or from the command line:
4435
4436     $ perl -V:byteorder
4437
4438 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4439 and C<"87654321"> are big-endian.
4440
4441 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4442 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4443 immediately below.  See also L<perlport>.
4444
4445 =item *
4446
4447 Starting with Perl 5.9.2, integer and floating-point formats, along with
4448 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4449 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4450 or little-endian byte-order.  These modifiers are especially useful 
4451 given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, 
4452 64-bit integers, or floating-point values.
4453
4454 Here are some concerns to keep in mind when using an endianness modifier:
4455
4456 =over
4457
4458 =item * 
4459
4460 Exchanging signed integers between different platforms works only 
4461 when all platforms store them in the same format.  Most platforms store
4462 signed integers in two's-complement notation, so usually this is not an issue.
4463
4464 =item * 
4465
4466 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4467 formats on big- or little-endian machines.  Otherwise, attempting to
4468 use them raises an exception.
4469
4470 =item * 
4471
4472 Forcing big- or little-endian byte-order on floating-point values for
4473 data exchange can work only if all platforms use the same
4474 binary representation such as IEEE floating-point.  Even if all
4475 platforms are using IEEE, there may still be subtle differences.  Being able
4476 to use C<< > >> or C<< < >> on floating-point values can be useful,
4477 but also dangerous if you don't know exactly what you're doing.
4478 It is not a general way to portably store floating-point values.
4479
4480 =item * 
4481
4482 When using C<< > >> or C<< < >> on a C<()> group, this affects
4483 all types inside the group that accept byte-order modifiers,
4484 including all subgroups.  It is silently ignored for all other
4485 types.  You are not allowed to override the byte-order within a group
4486 that already has a byte-order modifier suffix.
4487
4488 =back
4489
4490 =item *
4491
4492 Real numbers (floats and doubles) are in native machine format only.
4493 Due to the multiplicity of floating-point formats and the lack of a
4494 standard "network" representation for them, no facility for interchange has been
4495 made.  This means that packed floating-point data written on one machine
4496 may not be readable on another, even if both use IEEE floating-point
4497 arithmetic (because the endianness of the memory representation is not part
4498 of the IEEE spec).  See also L<perlport>.
4499
4500 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4501 modifiers to force big- or little-endian byte-order on floating-point values.
4502
4503 Because Perl uses doubles (or long doubles, if configured) internally for
4504 all numeric calculation, converting from double into float and thence 
4505 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4506 will not in general equal $foo.
4507
4508 =item *
4509
4510 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4511 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4512 where the packed string is processed in its UTF-8-encoded Unicode form on
4513 a byte-by-byte basis.  Character mode is the default
4514 unless the format string starts with C<U>.  You
4515 can always switch mode mid-format with an explicit 
4516 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4517 mode change, or until the end of the C<()> group it (directly) applies to.
4518
4519 Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode 
4520 bytes is not necessarily obvious.   Probably only the first of these
4521 is what you want:
4522
4523     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4524       perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)'
4525     03B1.03C9
4526     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4527       perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4528     CE.B1.CF.89
4529     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4530       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)'
4531     CE.B1.CF.89
4532     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4533       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4534     C3.8E.C2.B1.C3.8F.C2.89
4535
4536 Those examples also illustrate that you should not try to use
4537 C<pack>/C<unpack> as a substitute for the L<Encode> module.
4538
4539 =item *
4540
4541 You must yourself do any alignment or padding by inserting, for example,
4542 enough C<"x">es while packing.  There is no way for pack() and unpack()
4543 to know where characters are going to or coming from, so they 
4544 handle their output and input as flat sequences of characters.
4545
4546 =item *
4547
4548 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4549 take a repeat count either as postfix, or for unpack(), also via the C</>
4550 template character.  Within each repetition of a group, positioning with
4551 C<@> starts over at 0.  Therefore, the result of
4552
4553     pack("@1A((@2A)@3A)", qw[X Y Z])
4554
4555 is the string C<"\0X\0\0YZ">.
4556
4557 =item *
4558
4559 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4560 jump forward or back to the closest position aligned at a multiple of C<count>
4561 characters.  For example, to pack() or unpack() a C structure like
4562
4563     struct {
4564         char   c;    /* one signed, 8-bit character */
4565         double d; 
4566         char   cc[2];
4567     }
4568
4569 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4570 doubles must be aligned to the size of double.
4571
4572 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4573 both are no-ops.
4574
4575 =item *
4576
4577 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4578 represent signed 16-/32-bit integers in big-/little-endian order.
4579 This is portable only when all platforms sharing packed data use the
4580 same binary representation for signed integers; for example, when all
4581 platforms use two's-complement representation.
4582
4583 =item *
4584
4585 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4586 White space can separate pack codes from each other, but modifiers and
4587 repeat counts must follow immediately.  Breaking complex templates into
4588 individual line-by-line components, suitably annotated, can do as much to
4589 improve legibility and maintainability of pack/unpack formats as C</x> can
4590 for complicated pattern matches.
4591
4592 =item *
4593
4594 If TEMPLATE requires more arguments than pack() is given, pack()
4595 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4596 than given, extra arguments are ignored.
4597
4598 =back
4599
4600 Examples:
4601
4602     $foo = pack("WWWW",65,66,67,68);
4603     # foo eq "ABCD"
4604     $foo = pack("W4",65,66,67,68);
4605     # same thing
4606     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4607     # same thing with Unicode circled letters.
4608     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4609     # same thing with Unicode circled letters.  You don't get the
4610     # UTF-8 bytes because the U at the start of the format caused
4611     # a switch to U0-mode, so the UTF-8 bytes get joined into
4612     # characters
4613     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4614     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4615     # This is the UTF-8 encoding of the string in the
4616     # previous example
4617
4618     $foo = pack("ccxxcc",65,66,67,68);
4619     # foo eq "AB\0\0CD"
4620
4621     # NOTE: The examples above featuring "W" and "c" are true
4622     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4623     # and UTF-8.  On EBCDIC systems, the first example would be
4624     #      $foo = pack("WWWW",193,194,195,196);
4625
4626     $foo = pack("s2",1,2);
4627     # "\001\000\002\000" on little-endian
4628     # "\000\001\000\002" on big-endian
4629
4630     $foo = pack("a4","abcd","x","y","z");
4631     # "abcd"
4632
4633     $foo = pack("aaaa","abcd","x","y","z");
4634     # "axyz"
4635
4636     $foo = pack("a14","abcdefg");
4637     # "abcdefg\0\0\0\0\0\0\0"
4638
4639     $foo = pack("i9pl", gmtime);
4640     # a real struct tm (on my system anyway)
4641
4642     $utmp_template = "Z8 Z8 Z16 L";
4643     $utmp = pack($utmp_template, @utmp1);
4644     # a struct utmp (BSDish)
4645
4646     @utmp2 = unpack($utmp_template, $utmp);
4647     # "@utmp1" eq "@utmp2"
4648
4649     sub bintodec {
4650         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4651     }
4652
4653     $foo = pack('sx2l', 12, 34);
4654     # short 12, two zero bytes padding, long 34
4655     $bar = pack('s@4l', 12, 34);
4656     # short 12, zero fill to position 4, long 34