This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
handle freed backref array in global cleanup
[perl5.git] / t / op / ref.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = qw(. ../lib);
6     require 'test.pl';
7 }
8
9 use strict qw(refs subs);
10
11 plan(217);
12
13 # Test glob operations.
14
15 $bar = "one";
16 $foo = "two";
17 {
18     local(*foo) = *bar;
19     is($foo, 'one');
20 }
21 is ($foo, 'two');
22
23 $baz = "three";
24 $foo = "four";
25 {
26     local(*foo) = 'baz';
27     is ($foo, 'three');
28 }
29 is ($foo, 'four');
30
31 $foo = "global";
32 {
33     local(*foo);
34     is ($foo, undef);
35     $foo = "local";
36     is ($foo, 'local');
37 }
38 is ($foo, 'global');
39
40 {
41     no strict 'refs';
42 # Test fake references.
43
44     $baz = "valid";
45     $bar = 'baz';
46     $foo = 'bar';
47     is ($$$foo, 'valid');
48 }
49
50 # Test real references.
51
52 $FOO = \$BAR;
53 $BAR = \$BAZ;
54 $BAZ = "hit";
55 is ($$$FOO, 'hit');
56
57 # Test references to real arrays.
58
59 my $test = curr_test();
60 @ary = ($test,$test+1,$test+2,$test+3);
61 $ref[0] = \@a;
62 $ref[1] = \@b;
63 $ref[2] = \@c;
64 $ref[3] = \@d;
65 for $i (3,1,2,0) {
66     push(@{$ref[$i]}, "ok $ary[$i]\n");
67 }
68 print @a;
69 print ${$ref[1]}[0];
70 print @{$ref[2]}[0];
71 {
72     no strict 'refs';
73     print @{'d'};
74 }
75 curr_test($test+4);
76
77 # Test references to references.
78
79 $refref = \\$x;
80 $x = "Good";
81 is ($$$refref, 'Good');
82
83 # Test nested anonymous lists.
84
85 $ref = [[],2,[3,4,5,]];
86 is (scalar @$ref, 3);
87 is ($$ref[1], 2);
88 is (${$$ref[2]}[2], 5);
89 is (scalar @{$$ref[0]}, 0);
90
91 is ($ref->[1], 2);
92 is ($ref->[2]->[0], 3);
93
94 # Test references to hashes of references.
95
96 $refref = \%whatever;
97 $refref->{"key"} = $ref;
98 is ($refref->{"key"}->[2]->[0], 3);
99
100 # Test to see if anonymous subarrays spring into existence.
101
102 $spring[5]->[0] = 123;
103 $spring[5]->[1] = 456;
104 push(@{$spring[5]}, 789);
105 is (join(':',@{$spring[5]}), "123:456:789");
106
107 # Test to see if anonymous subhashes spring into existence.
108
109 @{$spring2{"foo"}} = (1,2,3);
110 $spring2{"foo"}->[3] = 4;
111 is (join(':',@{$spring2{"foo"}}), "1:2:3:4");
112
113 # Test references to subroutines.
114
115 {
116     my $called;
117     sub mysub { $called++; }
118     $subref = \&mysub;
119     &$subref;
120     is ($called, 1);
121 }
122
123 # Test references to return values of operators (TARGs/PADTMPs)
124 {
125     my @refs;
126     for("a", "b") {
127         push @refs, \"$_"
128     }
129     is join(" ", map $$_, @refs), "a b", 'refgen+PADTMP';
130 }
131
132 $subrefref = \\&mysub2;
133 is ($$subrefref->("GOOD"), "good");
134 sub mysub2 { lc shift }
135
136 # Test REGEXP assignment
137
138 SKIP: {
139     skip_if_miniperl("no dynamic loading on miniperl, so can't load re", 5);
140     require re;
141     my $x = qr/x/;
142     my $str = "$x"; # regex stringification may change
143
144     my $y = $$x;
145     is ($y, $str, "bare REGEXP stringifies correctly");
146     ok (eval { "x" =~ $y }, "bare REGEXP matches correctly");
147     
148     my $z = \$y;
149     ok (re::is_regexp($z), "new ref to REXEXP passes is_regexp");
150     is ($z, $str, "new ref to REGEXP stringifies correctly");
151     ok (eval { "x" =~ $z }, "new ref to REGEXP matches correctly");
152 }
153 {
154     my ($x, $str);
155     {
156         my $y = qr/x/;
157         $str = "$y";
158         $x = $$y;
159     }
160     is ($x, $str, "REGEXP keeps a ref to its mother_re");
161     ok (eval { "x" =~ $x }, "REGEXP with mother_re still matches");
162 }
163
164 # Test the ref operator.
165
166 sub PVBM () { 'foo' }
167 { my $dummy = index 'foo', PVBM }
168
169 my $pviv = 1; "$pviv";
170 my $pvnv = 1.0; "$pvnv";
171 my $x;
172
173 # we don't test
174 #   tied lvalue => SCALAR, as we haven't tested tie yet
175 #   BIND, 'cos we can't create them yet
176 #   REGEXP, 'cos that requires overload or Scalar::Util
177 #   LVALUE ref, 'cos I can't work out how to create one :)
178
179 for (
180     [ 'undef',          SCALAR  => \undef               ],
181     [ 'constant IV',    SCALAR  => \1                   ],
182     [ 'constant NV',    SCALAR  => \1.0                 ],
183     [ 'constant PV',    SCALAR  => \'f'                 ],
184     [ 'scalar',         SCALAR  => \$x                  ],
185     [ 'PVIV',           SCALAR  => \$pviv               ],
186     [ 'PVNV',           SCALAR  => \$pvnv               ],
187     [ 'PVMG',           SCALAR  => \$0                  ],
188     [ 'PVBM',           SCALAR  => \PVBM                ],
189     [ 'vstring',        VSTRING => \v1                  ],
190     [ 'ref',            REF     => \\1                  ],
191     [ 'lvalue',         LVALUE  => \substr($x, 0, 0)    ],
192     [ 'named array',    ARRAY   => \@ary                ],
193     [ 'anon array',     ARRAY   => [ 1 ]                ],
194     [ 'named hash',     HASH    => \%whatever           ],
195     [ 'anon hash',      HASH    => { a => 1 }           ],
196     [ 'named sub',      CODE    => \&mysub,             ],
197     [ 'anon sub',       CODE    => sub { 1; }           ],
198     [ 'glob',           GLOB    => \*foo                ],
199     [ 'format',         FORMAT  => *STDERR{FORMAT}      ],
200 ) {
201     my ($desc, $type, $ref) = @$_;
202     is (ref $ref, $type, "ref() for ref to $desc");
203     like ("$ref", qr/^$type\(0x[0-9a-f]+\)$/, "stringify for ref to $desc");
204 }
205
206 is (ref *STDOUT{IO}, 'IO::File', 'IO refs are blessed into IO::File');
207 like (*STDOUT{IO}, qr/^IO::File=IO\(0x[0-9a-f]+\)$/,
208     'stringify for IO refs');
209
210 # Test anonymous hash syntax.
211
212 $anonhash = {};
213 is (ref $anonhash, 'HASH');
214 $anonhash2 = {FOO => 'BAR', ABC => 'XYZ',};
215 is (join('', sort values %$anonhash2), 'BARXYZ');
216
217 # Test bless operator.
218
219 package MYHASH;
220
221 $object = bless $main'anonhash2;
222 main::is (ref $object, 'MYHASH');
223 main::is ($object->{ABC}, 'XYZ');
224
225 $object2 = bless {};
226 main::is (ref $object2, 'MYHASH');
227
228 # Test ordinary call on object method.
229
230 &mymethod($object,"argument");
231
232 sub mymethod {
233     local($THIS, @ARGS) = @_;
234     die 'Got a "' . ref($THIS). '" instead of a MYHASH'
235         unless ref $THIS eq 'MYHASH';
236     main::is ($ARGS[0], "argument");
237     main::is ($THIS->{FOO}, 'BAR');
238 }
239
240 # Test automatic destructor call.
241
242 $string = "bad";
243 $object = "foo";
244 $string = "good";
245 $main'anonhash2 = "foo";
246 $string = "";
247
248 DESTROY {
249     return unless $string;
250     main::is ($string, 'good');
251
252     # Test that the object has not already been "cursed".
253     main::isnt (ref shift, 'HASH');
254 }
255
256 # Now test inheritance of methods.
257
258 package OBJ;
259
260 @ISA = ('BASEOBJ');
261
262 $main'object = bless {FOO => 'foo', BAR => 'bar'};
263
264 package main;
265
266 # Test arrow-style method invocation.
267
268 is ($object->doit("BAR"), 'bar');
269
270 # Test indirect-object-style method invocation.
271
272 $foo = doit $object "FOO";
273 main::is ($foo, 'foo');
274
275 sub BASEOBJ'doit {
276     local $ref = shift;
277     die "Not an OBJ" unless ref $ref eq 'OBJ';
278     $ref->{shift()};
279 }
280
281 package UNIVERSAL;
282 @ISA = 'LASTCHANCE';
283
284 package LASTCHANCE;
285 sub foo { main::is ($_[1], 'works') }
286
287 package WHATEVER;
288 foo WHATEVER "works";
289
290 #
291 # test the \(@foo) construct
292 #
293 package main;
294 @foo = \(1..3);
295 @bar = \(@foo);
296 @baz = \(1,@foo,@bar);
297 is (scalar (@bar), 3);
298 is (scalar grep(ref($_), @bar), 3);
299 is (scalar (@baz), 3);
300
301 my(@fuu) = \(1..2,3);
302 my(@baa) = \(@fuu);
303 my(@bzz) = \(1,@fuu,@baa);
304 is (scalar (@baa), 3);
305 is (scalar grep(ref($_), @baa), 3);
306 is (scalar (@bzz), 3);
307
308 # also, it can't be an lvalue
309 eval '\\($x, $y) = (1, 2);';
310 like ($@, qr/Can\'t modify.*ref.*in.*assignment/);
311
312 # test for proper destruction of lexical objects
313 $test = curr_test();
314 sub larry::DESTROY { print "# larry\nok $test\n"; }
315 sub curly::DESTROY { print "# curly\nok ", $test + 1, "\n"; }
316 sub moe::DESTROY   { print "# moe\nok ", $test + 2, "\n"; }
317
318 {
319     my ($joe, @curly, %larry);
320     my $moe = bless \$joe, 'moe';
321     my $curly = bless \@curly, 'curly';
322     my $larry = bless \%larry, 'larry';
323     print "# leaving block\n";
324 }
325
326 print "# left block\n";
327 curr_test($test + 3);
328
329 # another glob test
330
331
332 $foo = "garbage";
333 { local(*bar) = "foo" }
334 $bar = "glob 3";
335 local(*bar) = *bar;
336 is ($bar, "glob 3");
337
338 $var = "glob 4";
339 $_   = \$var;
340 is ($$_, 'glob 4');
341
342
343 # test if reblessing during destruction results in more destruction
344 $test = curr_test();
345 {
346     package A;
347     sub new { bless {}, shift }
348     DESTROY { print "# destroying 'A'\nok ", $test + 1, "\n" }
349     package _B;
350     sub new { bless {}, shift }
351     DESTROY { print "# destroying '_B'\nok $test\n"; bless shift, 'A' }
352     package main;
353     my $b = _B->new;
354 }
355 curr_test($test + 2);
356
357 # test if $_[0] is properly protected in DESTROY()
358
359 {
360     my $test = curr_test();
361     my $i = 0;
362     local $SIG{'__DIE__'} = sub {
363         my $m = shift;
364         if ($i++ > 4) {
365             print "# infinite recursion, bailing\nnot ok $test\n";
366             exit 1;
367         }
368         like ($m, qr/^Modification of a read-only/);
369     };
370     package C;
371     sub new { bless {}, shift }
372     DESTROY { $_[0] = 'foo' }
373     {
374         print "# should generate an error...\n";
375         my $c = C->new;
376     }
377     print "# good, didn't recurse\n";
378 }
379
380 # test that DESTROY is called on all objects during global destruction,
381 # even those without hard references [perl #36347]
382
383 $TODO = 'bug #36347';
384 is(
385   runperl(
386    stderr => 1, prog => 'sub DESTROY { print qq-aaa\n- } bless \$a[0]'
387   ),
388  "aaa\n", 'DESTROY called on array elem'
389 );
390 is(
391   runperl(
392    stderr => 1,
393    prog => '{ bless \my@x; *a=sub{@x}}sub DESTROY { print qq-aaa\n- }'
394   ),
395  "aaa\n",
396  'DESTROY called on closure variable'
397 );
398 $TODO = undef;
399
400 # test if refgen behaves with autoviv magic
401 {
402     my @a;
403     $a[1] = "good";
404     my $got;
405     for (@a) {
406         $got .= ${\$_};
407         $got .= ';';
408     }
409     is ($got, ";good;");
410 }
411
412 # This test is the reason for postponed destruction in sv_unref
413 $a = [1,2,3];
414 $a = $a->[1];
415 is ($a, 2);
416
417 # This test used to coredump. The BEGIN block is important as it causes the
418 # op that created the constant reference to be freed. Hence the only
419 # reference to the constant string "pass" is in $a. The hack that made
420 # sure $a = $a->[1] would work didn't work with references to constants.
421
422
423 foreach my $lexical ('', 'my $a; ') {
424   my $expect = "pass\n";
425   my $result = runperl (switches => ['-wl'], stderr => 1,
426     prog => $lexical . 'BEGIN {$a = \q{pass}}; $a = $$a; print $a');
427
428   is ($?, 0);
429   is ($result, $expect);
430 }
431
432 $test = curr_test();
433 sub x::DESTROY {print "ok ", $test + shift->[0], "\n"}
434 { my $a1 = bless [3],"x";
435   my $a2 = bless [2],"x";
436   { my $a3 = bless [1],"x";
437     my $a4 = bless [0],"x";
438     567;
439   }
440 }
441 curr_test($test+4);
442
443 is (runperl (switches=>['-l'],
444              prog=> 'print 1; print qq-*$\*-;print 1;'),
445     "1\n*\n*\n1\n");
446
447 # bug #21347
448
449 runperl(prog => 'sub UNIVERSAL::AUTOLOAD { qr// } a->p' );
450 is ($?, 0, 'UNIVERSAL::AUTOLOAD called when freeing qr//');
451
452 runperl(prog => 'sub UNIVERSAL::DESTROY { warn } bless \$a, A', stderr => 1);
453 is ($?, 0, 'warn called inside UNIVERSAL::DESTROY');
454
455
456 # bug #22719
457
458 runperl(prog => 'sub f { my $x = shift; *z = $x; } f({}); f();');
459 is ($?, 0, 'coredump on typeglob = (SvRV && !SvROK)');
460
461 # bug #27268: freeing self-referential typeglobs could trigger
462 # "Attempt to free unreferenced scalar" warnings
463
464 is (runperl(
465     prog => 'use Symbol;my $x=bless \gensym,q{t}; print;*$$x=$x',
466     stderr => 1
467 ), '', 'freeing self-referential typeglob');
468
469 # using a regex in the destructor for STDOUT segfaulted because the
470 # REGEX pad had already been freed (ithreads build only). The
471 # object is required to trigger the early freeing of GV refs to to STDOUT
472
473 TODO: {
474     local $TODO = "works but output through pipe is mangled" if $^O eq 'VMS';
475     like (runperl(
476         prog => '$x=bless[]; sub IO::Handle::DESTROY{$_=q{bad};s/bad/ok/;print}',
477         stderr => 1
478           ), qr/^(ok)+$/, 'STDOUT destructor');
479 }
480
481 TODO: {
482     no strict 'refs';
483     $name8 = chr 163;
484     $name_utf8 = $name8 . chr 256;
485     chop $name_utf8;
486
487     is ($$name8, undef, 'Nothing before we start');
488     is ($$name_utf8, undef, 'Nothing before we start');
489     $$name8 = "Pound";
490     is ($$name8, "Pound", 'Accessing via 8 bit symref works');
491     local $TODO = "UTF8 mangled in symrefs";
492     is ($$name_utf8, "Pound", 'Accessing via UTF8 symref works');
493 }
494
495 TODO: {
496     no strict 'refs';
497     $name_utf8 = $name = chr 9787;
498     utf8::encode $name_utf8;
499
500     is (length $name, 1, "Name is 1 char");
501     is (length $name_utf8, 3, "UTF8 representation is 3 chars");
502
503     is ($$name, undef, 'Nothing before we start');
504     is ($$name_utf8, undef, 'Nothing before we start');
505     $$name = "Face";
506     is ($$name, "Face", 'Accessing via Unicode symref works');
507     local $TODO = "UTF8 mangled in symrefs";
508     is ($$name_utf8, undef,
509         'Accessing via the UTF8 byte sequence gives nothing');
510 }
511
512 {
513     no strict 'refs';
514     $name1 = "\0Chalk";
515     $name2 = "\0Cheese";
516
517     isnt ($name1, $name2, "They differ");
518
519     is ($$name1, undef, 'Nothing before we start (scalars)');
520     is ($$name2, undef, 'Nothing before we start');
521     $$name1 = "Yummy";
522     is ($$name1, "Yummy", 'Accessing via the correct name works');
523     is ($$name2, undef,
524         'Accessing via a different NUL-containing name gives nothing');
525     # defined uses a different code path
526     ok (defined $$name1, 'defined via the correct name works');
527     ok (!defined $$name2,
528         'defined via a different NUL-containing name gives nothing');
529
530     is ($name1->[0], undef, 'Nothing before we start (arrays)');
531     is ($name2->[0], undef, 'Nothing before we start');
532     $name1->[0] = "Yummy";
533     is ($name1->[0], "Yummy", 'Accessing via the correct name works');
534     is ($name2->[0], undef,
535         'Accessing via a different NUL-containing name gives nothing');
536     ok (defined $name1->[0], 'defined via the correct name works');
537     ok (!defined$name2->[0],
538         'defined via a different NUL-containing name gives nothing');
539
540     my (undef, $one) = @{$name1}[2,3];
541     my (undef, $two) = @{$name2}[2,3];
542     is ($one, undef, 'Nothing before we start (array slices)');
543     is ($two, undef, 'Nothing before we start');
544     @{$name1}[2,3] = ("Very", "Yummy");
545     (undef, $one) = @{$name1}[2,3];
546     (undef, $two) = @{$name2}[2,3];
547     is ($one, "Yummy", 'Accessing via the correct name works');
548     is ($two, undef,
549         'Accessing via a different NUL-containing name gives nothing');
550     ok (defined $one, 'defined via the correct name works');
551     ok (!defined $two,
552         'defined via a different NUL-containing name gives nothing');
553
554     is ($name1->{PWOF}, undef, 'Nothing before we start (hashes)');
555     is ($name2->{PWOF}, undef, 'Nothing before we start');
556     $name1->{PWOF} = "Yummy";
557     is ($name1->{PWOF}, "Yummy", 'Accessing via the correct name works');
558     is ($name2->{PWOF}, undef,
559         'Accessing via a different NUL-containing name gives nothing');
560     ok (defined $name1->{PWOF}, 'defined via the correct name works');
561     ok (!defined $name2->{PWOF},
562         'defined via a different NUL-containing name gives nothing');
563
564     my (undef, $one) = @{$name1}{'SNIF', 'BEEYOOP'};
565     my (undef, $two) = @{$name2}{'SNIF', 'BEEYOOP'};
566     is ($one, undef, 'Nothing before we start (hash slices)');
567     is ($two, undef, 'Nothing before we start');
568     @{$name1}{'SNIF', 'BEEYOOP'} = ("Very", "Yummy");
569     (undef, $one) = @{$name1}{'SNIF', 'BEEYOOP'};
570     (undef, $two) = @{$name2}{'SNIF', 'BEEYOOP'};
571     is ($one, "Yummy", 'Accessing via the correct name works');
572     is ($two, undef,
573         'Accessing via a different NUL-containing name gives nothing');
574     ok (defined $one, 'defined via the correct name works');
575     ok (!defined $two,
576         'defined via a different NUL-containing name gives nothing');
577
578     $name1 = "Left"; $name2 = "Left\0Right";
579     my $glob2 = *{$name2};
580
581     is ($glob1, undef, "We get different typeglobs. In fact, undef");
582
583     *{$name1} = sub {"One"};
584     *{$name2} = sub {"Two"};
585
586     is (&{$name1}, "One");
587     is (&{$name2}, "Two");
588 }
589
590 # test derefs after list slice
591
592 is ( ({foo => "bar"})[0]{foo}, "bar", 'hash deref from list slice w/o ->' );
593 is ( ({foo => "bar"})[0]->{foo}, "bar", 'hash deref from list slice w/ ->' );
594 is ( ([qw/foo bar/])[0][1], "bar", 'array deref from list slice w/o ->' );
595 is ( ([qw/foo bar/])[0]->[1], "bar", 'array deref from list slice w/ ->' );
596 is ( (sub {"bar"})[0](), "bar", 'code deref from list slice w/o ->' );
597 is ( (sub {"bar"})[0]->(), "bar", 'code deref from list slice w/ ->' );
598
599 # deref on empty list shouldn't autovivify
600 {
601     local $@;
602     eval { ()[0]{foo} };
603     like ( "$@", "Can't use an undefined value as a HASH reference",
604            "deref of undef from list slice fails" );
605 }
606
607 # test dereferencing errors
608 {
609     format STDERR =
610 .
611     my $ref;
612     foreach $ref (*STDOUT{IO}, *STDERR{FORMAT}) {
613         eval q/ $$ref /;
614         like($@, qr/Not a SCALAR reference/, "Scalar dereference");
615         eval q/ @$ref /;
616         like($@, qr/Not an ARRAY reference/, "Array dereference");
617         eval q/ %$ref /;
618         like($@, qr/Not a HASH reference/, "Hash dereference");
619         eval q/ &$ref /;
620         like($@, qr/Not a CODE reference/, "Code dereference");
621     }
622
623     $ref = *STDERR{FORMAT};
624     eval q/ *$ref /;
625     like($@, qr/Not a GLOB reference/, "Glob dereference");
626
627     $ref = *STDOUT{IO};
628     eval q/ *$ref /;
629     is($@, '', "Glob dereference of PVIO is acceptable");
630
631     is($ref, *{$ref}{IO}, "IO slot of the temporary glob is set correctly");
632 }
633
634 # these will segfault if they fail
635
636 my $pvbm = PVBM;
637 my $rpvbm = \$pvbm;
638
639 ok (!eval { *$rpvbm }, 'PVBM ref is not a GLOB ref');
640 ok (!eval { *$pvbm }, 'PVBM is not a GLOB ref');
641 ok (!eval { $$pvbm }, 'PVBM is not a SCALAR ref');
642 ok (!eval { @$pvbm }, 'PVBM is not an ARRAY ref');
643 ok (!eval { %$pvbm }, 'PVBM is not a HASH ref');
644 ok (!eval { $pvbm->() }, 'PVBM is not a CODE ref');
645 ok (!eval { $rpvbm->foo }, 'PVBM is not an object');
646
647 # bug 24254
648 is( runperl(stderr => 1, prog => 'map eval qq(exit),1 for 1'), "");
649 is( runperl(stderr => 1, prog => 'eval { for (1) { map { die } 2 } };'), "");
650 is( runperl(stderr => 1, prog => 'for (125) { map { exit } (213)}'), "");
651 my $hushed = $^O eq 'VMS' ? 'use vmsish qw(hushed);' : '';
652 is( runperl(stderr => 1, prog => $hushed . 'map die,4 for 3'), "Died at -e line 1.\n");
653 is( runperl(stderr => 1, prog => $hushed . 'grep die,4 for 3'), "Died at -e line 1.\n");
654 is( runperl(stderr => 1, prog => $hushed . 'for $a (3) {@b=sort {die} 4,5}'), "Died at -e line 1.\n");
655
656 # bug 57564
657 is( runperl(stderr => 1, prog => 'my $i;for $i (1) { for $i (2) { } }'), "");
658
659 # The mechanism for freeing objects in globs used to leave dangling
660 # pointers to freed SVs. To test this, we construct this nested structure:
661 #    GV => blessed(AV) => RV => GV => blessed(SV)
662 # all with a refcnt of 1, and hope that the second GV gets processed first
663 # by do_clean_named_objs.  Then when the first GV is processed, it mustn't
664 # find anything nasty left by the previous GV processing.
665 # The eval is stop things in the main body of the code holding a reference
666 # to a GV, and the print at the end seems to bee necessary to ensure
667 # the correct freeing order of *x and *y (no, I don't know why - DAPM).
668
669 is (runperl(
670         prog => 'eval q[bless \@y; bless \$x; $y[0] = \*x; $z = \*y; ]; '
671                 . 'delete $::{x}; delete $::{y}; print qq{ok\n};',
672         stderr => 1),
673     "ok\n", 'freeing freed glob in global destruction');
674
675
676 # Test undefined hash references as arguments to %{} in boolean context
677 # [perl #81750]
678 {
679  no strict 'refs';
680  eval { my $foo; %$foo;             }; ok !$@, '%$undef';
681  eval { my $foo; scalar %$foo;      }; ok !$@, 'scalar %$undef';
682  eval { my $foo; !%$foo;            }; ok !$@, '!%$undef';
683  eval { my $foo; if ( %$foo) {}     }; ok !$@, 'if ( %$undef) {}';
684  eval { my $foo; if (!%$foo) {}     }; ok !$@, 'if (!%$undef) {}';
685  eval { my $foo; unless ( %$foo) {} }; ok !$@, 'unless ( %$undef) {}';
686  eval { my $foo; unless (!%$foo) {} }; ok !$@, 'unless (!%$undef) {}';
687  eval { my $foo; 1 if %$foo;        }; ok !$@, '1 if %$undef';
688  eval { my $foo; 1 if !%$foo;       }; ok !$@, '1 if !%$undef';
689  eval { my $foo; 1 unless %$foo;    }; ok !$@, '1 unless %$undef;';
690  eval { my $foo; 1 unless ! %$foo;  }; ok !$@, '1 unless ! %$undef';
691  eval { my $foo;  %$foo ? 1 : 0;    }; ok !$@, ' %$undef ? 1 : 0';
692  eval { my $foo; !%$foo ? 1 : 0;    }; ok !$@, '!%$undef ? 1 : 0';
693 }
694
695 # RT #88330
696 # Make sure that a leaked thinggy with multiple weak references to
697 # it doesn't trigger a panic with multiple rounds of global cleanup
698 # (Perl_sv_clean_all).
699
700 SKIP: {
701     skip_if_miniperl('no Scalar::Util under miniperl', 4);
702
703     local $ENV{PERL_DESTRUCT_LEVEL} = 2;
704
705     # we do all permutations of array/hash, 1ref/2ref, to account
706     # for the different way backref magic is stored
707
708     fresh_perl_is(<<'EOF', 'ok', { stderr => 1 }, 'array with 1 weak ref');
709 use Scalar::Util qw(weaken);
710 my $r = [];
711 Internals::SvREFCNT(@$r, 9);
712 my $r1 = $r;
713 weaken($r1);
714 print "ok";
715 EOF
716
717     fresh_perl_is(<<'EOF', 'ok', { stderr => 1 }, 'array with 2 weak refs');
718 use Scalar::Util qw(weaken);
719 my $r = [];
720 Internals::SvREFCNT(@$r, 9);
721 my $r1 = $r;
722 weaken($r1);
723 my $r2 = $r;
724 weaken($r2);
725 print "ok";
726 EOF
727
728     fresh_perl_is(<<'EOF', 'ok', { stderr => 1 }, 'hash with 1 weak ref');
729 use Scalar::Util qw(weaken);
730 my $r = {};
731 Internals::SvREFCNT(%$r, 9);
732 my $r1 = $r;
733 weaken($r1);
734 print "ok";
735 EOF
736
737     fresh_perl_is(<<'EOF', 'ok', { stderr => 1 }, 'hash with 2 weak refs');
738 use Scalar::Util qw(weaken);
739 my $r = {};
740 Internals::SvREFCNT(%$r, 9);
741 my $r1 = $r;
742 weaken($r1);
743 my $r2 = $r;
744 weaken($r2);
745 print "ok";
746 EOF
747
748 }
749
750 # Bit of a hack to make test.pl happy. There are 3 more tests after it leaves.
751 $test = curr_test();
752 curr_test($test + 3);
753 # test global destruction
754
755 my $test1 = $test + 1;
756 my $test2 = $test + 2;
757
758 package FINALE;
759
760 {
761     $ref3 = bless ["ok $test2\n"];      # package destruction
762     my $ref2 = bless ["ok $test1\n"];   # lexical destruction
763     local $ref1 = bless ["ok $test\n"]; # dynamic destruction
764     1;                                  # flush any temp values on stack
765 }
766
767 DESTROY {
768     print $_[0][0];
769 }
770