This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Fix links to POD sections
[perl5.git] / pod / perlretut.pod
1 =head1 NAME
2
3 perlretut - Perl regular expressions tutorial
4
5 =head1 DESCRIPTION
6
7 This page provides a basic tutorial on understanding, creating and
8 using regular expressions in Perl.  It serves as a complement to the
9 reference page on regular expressions L<perlre>.  Regular expressions
10 are an integral part of the C<m//>, C<s///>, C<qr//> and C<split>
11 operators and so this tutorial also overlaps with
12 L<perlop/"Regexp Quote-Like Operators"> and L<perlfunc/split>.
13
14 Perl is widely renowned for excellence in text processing, and regular
15 expressions are one of the big factors behind this fame.  Perl regular
16 expressions display an efficiency and flexibility unknown in most
17 other computer languages.  Mastering even the basics of regular
18 expressions will allow you to manipulate text with surprising ease.
19
20 What is a regular expression?  A regular expression is simply a string
21 that describes a pattern.  Patterns are in common use these days;
22 examples are the patterns typed into a search engine to find web pages
23 and the patterns used to list files in a directory, e.g., C<ls *.txt>
24 or C<dir *.*>.  In Perl, the patterns described by regular expressions
25 are used to search strings, extract desired parts of strings, and to
26 do search and replace operations.
27
28 Regular expressions have the undeserved reputation of being abstract
29 and difficult to understand.  Regular expressions are constructed using
30 simple concepts like conditionals and loops and are no more difficult
31 to understand than the corresponding C<if> conditionals and C<while>
32 loops in the Perl language itself.  In fact, the main challenge in
33 learning regular expressions is just getting used to the terse
34 notation used to express these concepts.
35
36 This tutorial flattens the learning curve by discussing regular
37 expression concepts, along with their notation, one at a time and with
38 many examples.  The first part of the tutorial will progress from the
39 simplest word searches to the basic regular expression concepts.  If
40 you master the first part, you will have all the tools needed to solve
41 about 98% of your needs.  The second part of the tutorial is for those
42 comfortable with the basics and hungry for more power tools.  It
43 discusses the more advanced regular expression operators and
44 introduces the latest cutting edge innovations in 5.6.0.
45
46 A note: to save time, 'regular expression' is often abbreviated as
47 regexp or regex.  Regexp is a more natural abbreviation than regex, but
48 is harder to pronounce.  The Perl pod documentation is evenly split on
49 regexp vs regex; in Perl, there is more than one way to abbreviate it.
50 We'll use regexp in this tutorial.
51
52 =head1 Part 1: The basics
53
54 =head2 Simple word matching
55
56 The simplest regexp is simply a word, or more generally, a string of
57 characters.  A regexp consisting of a word matches any string that
58 contains that word:
59
60     "Hello World" =~ /World/;  # matches
61
62 What is this Perl statement all about? C<"Hello World"> is a simple
63 double quoted string.  C<World> is the regular expression and the
64 C<//> enclosing C</World/> tells Perl to search a string for a match.
65 The operator C<=~> associates the string with the regexp match and
66 produces a true value if the regexp matched, or false if the regexp
67 did not match.  In our case, C<World> matches the second word in
68 C<"Hello World">, so the expression is true.  Expressions like this
69 are useful in conditionals:
70
71     if ("Hello World" =~ /World/) {
72         print "It matches\n";
73     }
74     else {
75         print "It doesn't match\n";
76     }
77
78 There are useful variations on this theme.  The sense of the match can
79 be reversed by using the C<!~> operator:
80
81     if ("Hello World" !~ /World/) {
82         print "It doesn't match\n";
83     }
84     else {
85         print "It matches\n";
86     }
87
88 The literal string in the regexp can be replaced by a variable:
89
90     $greeting = "World";
91     if ("Hello World" =~ /$greeting/) {
92         print "It matches\n";
93     }
94     else {
95         print "It doesn't match\n";
96     }
97
98 If you're matching against the special default variable C<$_>, the
99 C<$_ =~> part can be omitted:
100
101     $_ = "Hello World";
102     if (/World/) {
103         print "It matches\n";
104     }
105     else {
106         print "It doesn't match\n";
107     }
108
109 And finally, the C<//> default delimiters for a match can be changed
110 to arbitrary delimiters by putting an C<'m'> out front:
111
112     "Hello World" =~ m!World!;   # matches, delimited by '!'
113     "Hello World" =~ m{World};   # matches, note the matching '{}'
114     "/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
115                                  # '/' becomes an ordinary char
116
117 C</World/>, C<m!World!>, and C<m{World}> all represent the
118 same thing.  When, e.g., the quote (C<">) is used as a delimiter, the forward
119 slash C<'/'> becomes an ordinary character and can be used in this regexp
120 without trouble.
121
122 Let's consider how different regexps would match C<"Hello World">:
123
124     "Hello World" =~ /world/;  # doesn't match
125     "Hello World" =~ /o W/;    # matches
126     "Hello World" =~ /oW/;     # doesn't match
127     "Hello World" =~ /World /; # doesn't match
128
129 The first regexp C<world> doesn't match because regexps are
130 case-sensitive.  The second regexp matches because the substring
131 S<C<'o W'>> occurs in the string S<C<"Hello World">>.  The space
132 character ' ' is treated like any other character in a regexp and is
133 needed to match in this case.  The lack of a space character is the
134 reason the third regexp C<'oW'> doesn't match.  The fourth regexp
135 C<'World '> doesn't match because there is a space at the end of the
136 regexp, but not at the end of the string.  The lesson here is that
137 regexps must match a part of the string I<exactly> in order for the
138 statement to be true.
139
140 If a regexp matches in more than one place in the string, Perl will
141 always match at the earliest possible point in the string:
142
143     "Hello World" =~ /o/;       # matches 'o' in 'Hello'
144     "That hat is red" =~ /hat/; # matches 'hat' in 'That'
145
146 With respect to character matching, there are a few more points you
147 need to know about.   First of all, not all characters can be used 'as
148 is' in a match.  Some characters, called I<metacharacters>, are reserved
149 for use in regexp notation.  The metacharacters are
150
151     {}[]()^$.|*+?\
152
153 The significance of each of these will be explained
154 in the rest of the tutorial, but for now, it is important only to know
155 that a metacharacter can be matched by putting a backslash before it:
156
157     "2+2=4" =~ /2+2/;    # doesn't match, + is a metacharacter
158     "2+2=4" =~ /2\+2/;   # matches, \+ is treated like an ordinary +
159     "The interval is [0,1)." =~ /[0,1)./     # is a syntax error!
160     "The interval is [0,1)." =~ /\[0,1\)\./  # matches
161     "#!/usr/bin/perl" =~ /#!\/usr\/bin\/perl/;  # matches
162
163 In the last regexp, the forward slash C<'/'> is also backslashed,
164 because it is used to delimit the regexp.  This can lead to LTS
165 (leaning toothpick syndrome), however, and it is often more readable
166 to change delimiters.
167
168     "#!/usr/bin/perl" =~ m!#\!/usr/bin/perl!;  # easier to read
169
170 The backslash character C<'\'> is a metacharacter itself and needs to
171 be backslashed:
172
173     'C:\WIN32' =~ /C:\\WIN/;   # matches
174
175 In addition to the metacharacters, there are some ASCII characters
176 which don't have printable character equivalents and are instead
177 represented by I<escape sequences>.  Common examples are C<\t> for a
178 tab, C<\n> for a newline, C<\r> for a carriage return and C<\a> for a
179 bell.  If your string is better thought of as a sequence of arbitrary
180 bytes, the octal escape sequence, e.g., C<\033>, or hexadecimal escape
181 sequence, e.g., C<\x1B> may be a more natural representation for your
182 bytes.  Here are some examples of escapes:
183
184     "1000\t2000" =~ m(0\t2)   # matches
185     "1000\n2000" =~ /0\n20/   # matches
186     "1000\t2000" =~ /\000\t2/ # doesn't match, "0" ne "\000"
187     "cat"   =~ /\o{143}\x61\x74/ # matches in ASCII, but a weird way
188                                  # to spell cat
189
190 If you've been around Perl a while, all this talk of escape sequences
191 may seem familiar.  Similar escape sequences are used in double-quoted
192 strings and in fact the regexps in Perl are mostly treated as
193 double-quoted strings.  This means that variables can be used in
194 regexps as well.  Just like double-quoted strings, the values of the
195 variables in the regexp will be substituted in before the regexp is
196 evaluated for matching purposes.  So we have:
197
198     $foo = 'house';
199     'housecat' =~ /$foo/;      # matches
200     'cathouse' =~ /cat$foo/;   # matches
201     'housecat' =~ /${foo}cat/; # matches
202
203 So far, so good.  With the knowledge above you can already perform
204 searches with just about any literal string regexp you can dream up.
205 Here is a I<very simple> emulation of the Unix grep program:
206
207     % cat > simple_grep
208     #!/usr/bin/perl
209     $regexp = shift;
210     while (<>) {
211         print if /$regexp/;
212     }
213     ^D
214
215     % chmod +x simple_grep
216
217     % simple_grep abba /usr/dict/words
218     Babbage
219     cabbage
220     cabbages
221     sabbath
222     Sabbathize
223     Sabbathizes
224     sabbatical
225     scabbard
226     scabbards
227
228 This program is easy to understand.  C<#!/usr/bin/perl> is the standard
229 way to invoke a perl program from the shell.
230 S<C<$regexp = shift;>> saves the first command line argument as the
231 regexp to be used, leaving the rest of the command line arguments to
232 be treated as files.  S<C<< while (<>) >>> loops over all the lines in
233 all the files.  For each line, S<C<print if /$regexp/;>> prints the
234 line if the regexp matches the line.  In this line, both C<print> and
235 C</$regexp/> use the default variable C<$_> implicitly.
236
237 With all of the regexps above, if the regexp matched anywhere in the
238 string, it was considered a match.  Sometimes, however, we'd like to
239 specify I<where> in the string the regexp should try to match.  To do
240 this, we would use the I<anchor> metacharacters C<^> and C<$>.  The
241 anchor C<^> means match at the beginning of the string and the anchor
242 C<$> means match at the end of the string, or before a newline at the
243 end of the string.  Here is how they are used:
244
245     "housekeeper" =~ /keeper/;    # matches
246     "housekeeper" =~ /^keeper/;   # doesn't match
247     "housekeeper" =~ /keeper$/;   # matches
248     "housekeeper\n" =~ /keeper$/; # matches
249
250 The second regexp doesn't match because C<^> constrains C<keeper> to
251 match only at the beginning of the string, but C<"housekeeper"> has
252 keeper starting in the middle.  The third regexp does match, since the
253 C<$> constrains C<keeper> to match only at the end of the string.
254
255 When both C<^> and C<$> are used at the same time, the regexp has to
256 match both the beginning and the end of the string, i.e., the regexp
257 matches the whole string.  Consider
258
259     "keeper" =~ /^keep$/;      # doesn't match
260     "keeper" =~ /^keeper$/;    # matches
261     ""       =~ /^$/;          # ^$ matches an empty string
262
263 The first regexp doesn't match because the string has more to it than
264 C<keep>.  Since the second regexp is exactly the string, it
265 matches.  Using both C<^> and C<$> in a regexp forces the complete
266 string to match, so it gives you complete control over which strings
267 match and which don't.  Suppose you are looking for a fellow named
268 bert, off in a string by himself:
269
270     "dogbert" =~ /bert/;   # matches, but not what you want
271
272     "dilbert" =~ /^bert/;  # doesn't match, but ..
273     "bertram" =~ /^bert/;  # matches, so still not good enough
274
275     "bertram" =~ /^bert$/; # doesn't match, good
276     "dilbert" =~ /^bert$/; # doesn't match, good
277     "bert"    =~ /^bert$/; # matches, perfect
278
279 Of course, in the case of a literal string, one could just as easily
280 use the string comparison S<C<$string eq 'bert'>> and it would be
281 more efficient.   The  C<^...$> regexp really becomes useful when we
282 add in the more powerful regexp tools below.
283
284 =head2 Using character classes
285
286 Although one can already do quite a lot with the literal string
287 regexps above, we've only scratched the surface of regular expression
288 technology.  In this and subsequent sections we will introduce regexp
289 concepts (and associated metacharacter notations) that will allow a
290 regexp to not just represent a single character sequence, but a I<whole
291 class> of them.
292
293 One such concept is that of a I<character class>.  A character class
294 allows a set of possible characters, rather than just a single
295 character, to match at a particular point in a regexp.  Character
296 classes are denoted by brackets C<[...]>, with the set of characters
297 to be possibly matched inside.  Here are some examples:
298
299     /cat/;       # matches 'cat'
300     /[bcr]at/;   # matches 'bat, 'cat', or 'rat'
301     /item[0123456789]/;  # matches 'item0' or ... or 'item9'
302     "abc" =~ /[cab]/;    # matches 'a'
303
304 In the last statement, even though C<'c'> is the first character in
305 the class, C<'a'> matches because the first character position in the
306 string is the earliest point at which the regexp can match.
307
308     /[yY][eE][sS]/;      # match 'yes' in a case-insensitive way
309                          # 'yes', 'Yes', 'YES', etc.
310
311 This regexp displays a common task: perform a case-insensitive
312 match.  Perl provides a way of avoiding all those brackets by simply
313 appending an C<'i'> to the end of the match.  Then C</[yY][eE][sS]/;>
314 can be rewritten as C</yes/i;>.  The C<'i'> stands for
315 case-insensitive and is an example of a I<modifier> of the matching
316 operation.  We will meet other modifiers later in the tutorial.
317
318 We saw in the section above that there were ordinary characters, which
319 represented themselves, and special characters, which needed a
320 backslash C<\> to represent themselves.  The same is true in a
321 character class, but the sets of ordinary and special characters
322 inside a character class are different than those outside a character
323 class.  The special characters for a character class are C<-]\^$> (and
324 the pattern delimiter, whatever it is).
325 C<]> is special because it denotes the end of a character class.  C<$> is
326 special because it denotes a scalar variable.  C<\> is special because
327 it is used in escape sequences, just like above.  Here is how the
328 special characters C<]$\> are handled:
329
330    /[\]c]def/; # matches ']def' or 'cdef'
331    $x = 'bcr';
332    /[$x]at/;   # matches 'bat', 'cat', or 'rat'
333    /[\$x]at/;  # matches '$at' or 'xat'
334    /[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'
335
336 The last two are a little tricky.  In C<[\$x]>, the backslash protects
337 the dollar sign, so the character class has two members C<$> and C<x>.
338 In C<[\\$x]>, the backslash is protected, so C<$x> is treated as a
339 variable and substituted in double quote fashion.
340
341 The special character C<'-'> acts as a range operator within character
342 classes, so that a contiguous set of characters can be written as a
343 range.  With ranges, the unwieldy C<[0123456789]> and C<[abc...xyz]>
344 become the svelte C<[0-9]> and C<[a-z]>.  Some examples are
345
346     /item[0-9]/;  # matches 'item0' or ... or 'item9'
347     /[0-9bx-z]aa/;  # matches '0aa', ..., '9aa',
348                     # 'baa', 'xaa', 'yaa', or 'zaa'
349     /[0-9a-fA-F]/;  # matches a hexadecimal digit
350     /[0-9a-zA-Z_]/; # matches a "word" character,
351                     # like those in a Perl variable name
352
353 If C<'-'> is the first or last character in a character class, it is
354 treated as an ordinary character; C<[-ab]>, C<[ab-]> and C<[a\-b]> are
355 all equivalent.
356
357 The special character C<^> in the first position of a character class
358 denotes a I<negated character class>, which matches any character but
359 those in the brackets.  Both C<[...]> and C<[^...]> must match a
360 character, or the match fails.  Then
361
362     /[^a]at/;  # doesn't match 'aat' or 'at', but matches
363                # all other 'bat', 'cat, '0at', '%at', etc.
364     /[^0-9]/;  # matches a non-numeric character
365     /[a^]at/;  # matches 'aat' or '^at'; here '^' is ordinary
366
367 Now, even C<[0-9]> can be a bother to write multiple times, so in the
368 interest of saving keystrokes and making regexps more readable, Perl
369 has several abbreviations for common character classes, as shown below.
370 Since the introduction of Unicode, these character classes match more
371 than just a few characters in the ISO 8859-1 range.
372
373 =over 4
374
375 =item *
376
377 \d matches a digit, not just [0-9] but also digits from non-roman scripts
378
379 =item *
380
381 \s matches a whitespace character, the set [\ \t\r\n\f] and others
382
383 =item *
384
385 \w matches a word character (alphanumeric or _), not just [0-9a-zA-Z_]
386 but also digits and characters from non-roman scripts
387
388 =item *
389
390 \D is a negated \d; it represents any other character than a digit, or [^\d]
391
392 =item *
393
394 \S is a negated \s; it represents any non-whitespace character [^\s]
395
396 =item *
397
398 \W is a negated \w; it represents any non-word character [^\w]
399
400 =item *
401
402 The period '.' matches any character but "\n" (unless the modifier C<//s> is
403 in effect, as explained below).
404
405 =back
406
407 The C<\d\s\w\D\S\W> abbreviations can be used both inside and outside
408 of character classes.  Here are some in use:
409
410     /\d\d:\d\d:\d\d/; # matches a hh:mm:ss time format
411     /[\d\s]/;         # matches any digit or whitespace character
412     /\w\W\w/;         # matches a word char, followed by a
413                       # non-word char, followed by a word char
414     /..rt/;           # matches any two chars, followed by 'rt'
415     /end\./;          # matches 'end.'
416     /end[.]/;         # same thing, matches 'end.'
417
418 Because a period is a metacharacter, it needs to be escaped to match
419 as an ordinary period. Because, for example, C<\d> and C<\w> are sets
420 of characters, it is incorrect to think of C<[^\d\w]> as C<[\D\W]>; in
421 fact C<[^\d\w]> is the same as C<[^\w]>, which is the same as
422 C<[\W]>. Think DeMorgan's laws.
423
424 An anchor useful in basic regexps is the I<word anchor>
425 C<\b>.  This matches a boundary between a word character and a non-word
426 character C<\w\W> or C<\W\w>:
427
428     $x = "Housecat catenates house and cat";
429     $x =~ /cat/;    # matches cat in 'housecat'
430     $x =~ /\bcat/;  # matches cat in 'catenates'
431     $x =~ /cat\b/;  # matches cat in 'housecat'
432     $x =~ /\bcat\b/;  # matches 'cat' at end of string
433
434 Note in the last example, the end of the string is considered a word
435 boundary.
436
437 You might wonder why C<'.'> matches everything but C<"\n"> - why not
438 every character? The reason is that often one is matching against
439 lines and would like to ignore the newline characters.  For instance,
440 while the string C<"\n"> represents one line, we would like to think
441 of it as empty.  Then
442
443     ""   =~ /^$/;    # matches
444     "\n" =~ /^$/;    # matches, $ anchors before "\n"
445
446     ""   =~ /./;      # doesn't match; it needs a char
447     ""   =~ /^.$/;    # doesn't match; it needs a char
448     "\n" =~ /^.$/;    # doesn't match; it needs a char other than "\n"
449     "a"  =~ /^.$/;    # matches
450     "a\n"  =~ /^.$/;  # matches, $ anchors before "\n"
451
452 This behavior is convenient, because we usually want to ignore
453 newlines when we count and match characters in a line.  Sometimes,
454 however, we want to keep track of newlines.  We might even want C<^>
455 and C<$> to anchor at the beginning and end of lines within the
456 string, rather than just the beginning and end of the string.  Perl
457 allows us to choose between ignoring and paying attention to newlines
458 by using the C<//s> and C<//m> modifiers.  C<//s> and C<//m> stand for
459 single line and multi-line and they determine whether a string is to
460 be treated as one continuous string, or as a set of lines.  The two
461 modifiers affect two aspects of how the regexp is interpreted: 1) how
462 the C<'.'> character class is defined, and 2) where the anchors C<^>
463 and C<$> are able to match.  Here are the four possible combinations:
464
465 =over 4
466
467 =item *
468
469 no modifiers (//): Default behavior.  C<'.'> matches any character
470 except C<"\n">.  C<^> matches only at the beginning of the string and
471 C<$> matches only at the end or before a newline at the end.
472
473 =item *
474
475 s modifier (//s): Treat string as a single long line.  C<'.'> matches
476 any character, even C<"\n">.  C<^> matches only at the beginning of
477 the string and C<$> matches only at the end or before a newline at the
478 end.
479
480 =item *
481
482 m modifier (//m): Treat string as a set of multiple lines.  C<'.'>
483 matches any character except C<"\n">.  C<^> and C<$> are able to match
484 at the start or end of I<any> line within the string.
485
486 =item *
487
488 both s and m modifiers (//sm): Treat string as a single long line, but
489 detect multiple lines.  C<'.'> matches any character, even
490 C<"\n">.  C<^> and C<$>, however, are able to match at the start or end
491 of I<any> line within the string.
492
493 =back
494
495 Here are examples of C<//s> and C<//m> in action:
496
497     $x = "There once was a girl\nWho programmed in Perl\n";
498
499     $x =~ /^Who/;   # doesn't match, "Who" not at start of string
500     $x =~ /^Who/s;  # doesn't match, "Who" not at start of string
501     $x =~ /^Who/m;  # matches, "Who" at start of second line
502     $x =~ /^Who/sm; # matches, "Who" at start of second line
503
504     $x =~ /girl.Who/;   # doesn't match, "." doesn't match "\n"
505     $x =~ /girl.Who/s;  # matches, "." matches "\n"
506     $x =~ /girl.Who/m;  # doesn't match, "." doesn't match "\n"
507     $x =~ /girl.Who/sm; # matches, "." matches "\n"
508
509 Most of the time, the default behavior is what is wanted, but C<//s> and
510 C<//m> are occasionally very useful.  If C<//m> is being used, the start
511 of the string can still be matched with C<\A> and the end of the string
512 can still be matched with the anchors C<\Z> (matches both the end and
513 the newline before, like C<$>), and C<\z> (matches only the end):
514
515     $x =~ /^Who/m;   # matches, "Who" at start of second line
516     $x =~ /\AWho/m;  # doesn't match, "Who" is not at start of string
517
518     $x =~ /girl$/m;  # matches, "girl" at end of first line
519     $x =~ /girl\Z/m; # doesn't match, "girl" is not at end of string
520
521     $x =~ /Perl\Z/m; # matches, "Perl" is at newline before end
522     $x =~ /Perl\z/m; # doesn't match, "Perl" is not at end of string
523
524 We now know how to create choices among classes of characters in a
525 regexp.  What about choices among words or character strings? Such
526 choices are described in the next section.
527
528 =head2 Matching this or that
529
530 Sometimes we would like our regexp to be able to match different
531 possible words or character strings.  This is accomplished by using
532 the I<alternation> metacharacter C<|>.  To match C<dog> or C<cat>, we
533 form the regexp C<dog|cat>.  As before, Perl will try to match the
534 regexp at the earliest possible point in the string.  At each
535 character position, Perl will first try to match the first
536 alternative, C<dog>.  If C<dog> doesn't match, Perl will then try the
537 next alternative, C<cat>.  If C<cat> doesn't match either, then the
538 match fails and Perl moves to the next position in the string.  Some
539 examples:
540
541     "cats and dogs" =~ /cat|dog|bird/;  # matches "cat"
542     "cats and dogs" =~ /dog|cat|bird/;  # matches "cat"
543
544 Even though C<dog> is the first alternative in the second regexp,
545 C<cat> is able to match earlier in the string.
546
547     "cats"          =~ /c|ca|cat|cats/; # matches "c"
548     "cats"          =~ /cats|cat|ca|c/; # matches "cats"
549
550 Here, all the alternatives match at the first string position, so the
551 first alternative is the one that matches.  If some of the
552 alternatives are truncations of the others, put the longest ones first
553 to give them a chance to match.
554
555     "cab" =~ /a|b|c/ # matches "c"
556                      # /a|b|c/ == /[abc]/
557
558 The last example points out that character classes are like
559 alternations of characters.  At a given character position, the first
560 alternative that allows the regexp match to succeed will be the one
561 that matches.
562
563 =head2 Grouping things and hierarchical matching
564
565 Alternation allows a regexp to choose among alternatives, but by
566 itself it is unsatisfying.  The reason is that each alternative is a whole
567 regexp, but sometime we want alternatives for just part of a
568 regexp.  For instance, suppose we want to search for housecats or
569 housekeepers.  The regexp C<housecat|housekeeper> fits the bill, but is
570 inefficient because we had to type C<house> twice.  It would be nice to
571 have parts of the regexp be constant, like C<house>, and some
572 parts have alternatives, like C<cat|keeper>.
573
574 The I<grouping> metacharacters C<()> solve this problem.  Grouping
575 allows parts of a regexp to be treated as a single unit.  Parts of a
576 regexp are grouped by enclosing them in parentheses.  Thus we could solve
577 the C<housecat|housekeeper> by forming the regexp as
578 C<house(cat|keeper)>.  The regexp C<house(cat|keeper)> means match
579 C<house> followed by either C<cat> or C<keeper>.  Some more examples
580 are
581
582     /(a|b)b/;    # matches 'ab' or 'bb'
583     /(ac|b)b/;   # matches 'acb' or 'bb'
584     /(^a|b)c/;   # matches 'ac' at start of string or 'bc' anywhere
585     /(a|[bc])d/; # matches 'ad', 'bd', or 'cd'
586
587     /house(cat|)/;  # matches either 'housecat' or 'house'
588     /house(cat(s|)|)/;  # matches either 'housecats' or 'housecat' or
589                         # 'house'.  Note groups can be nested.
590
591     /(19|20|)\d\d/;  # match years 19xx, 20xx, or the Y2K problem, xx
592     "20" =~ /(19|20|)\d\d/;  # matches the null alternative '()\d\d',
593                              # because '20\d\d' can't match
594
595 Alternations behave the same way in groups as out of them: at a given
596 string position, the leftmost alternative that allows the regexp to
597 match is taken.  So in the last example at the first string position,
598 C<"20"> matches the second alternative, but there is nothing left over
599 to match the next two digits C<\d\d>.  So Perl moves on to the next
600 alternative, which is the null alternative and that works, since
601 C<"20"> is two digits.
602
603 The process of trying one alternative, seeing if it matches, and
604 moving on to the next alternative, while going back in the string
605 from where the previous alternative was tried, if it doesn't, is called
606 I<backtracking>.  The term 'backtracking' comes from the idea that
607 matching a regexp is like a walk in the woods.  Successfully matching
608 a regexp is like arriving at a destination.  There are many possible
609 trailheads, one for each string position, and each one is tried in
610 order, left to right.  From each trailhead there may be many paths,
611 some of which get you there, and some which are dead ends.  When you
612 walk along a trail and hit a dead end, you have to backtrack along the
613 trail to an earlier point to try another trail.  If you hit your
614 destination, you stop immediately and forget about trying all the
615 other trails.  You are persistent, and only if you have tried all the
616 trails from all the trailheads and not arrived at your destination, do
617 you declare failure.  To be concrete, here is a step-by-step analysis
618 of what Perl does when it tries to match the regexp
619
620     "abcde" =~ /(abd|abc)(df|d|de)/;
621
622 =over 4
623
624 =item 0
625
626 Start with the first letter in the string 'a'.
627
628 =item 1
629
630 Try the first alternative in the first group 'abd'.
631
632 =item 2
633
634 Match 'a' followed by 'b'. So far so good.
635
636 =item 3
637
638 'd' in the regexp doesn't match 'c' in the string - a dead
639 end.  So backtrack two characters and pick the second alternative in
640 the first group 'abc'.
641
642 =item 4
643
644 Match 'a' followed by 'b' followed by 'c'.  We are on a roll
645 and have satisfied the first group. Set $1 to 'abc'.
646
647 =item 5
648
649 Move on to the second group and pick the first alternative
650 'df'.
651
652 =item 6
653
654 Match the 'd'.
655
656 =item 7
657
658 'f' in the regexp doesn't match 'e' in the string, so a dead
659 end.  Backtrack one character and pick the second alternative in the
660 second group 'd'.
661
662 =item 8
663
664 'd' matches. The second grouping is satisfied, so set $2 to
665 'd'.
666
667 =item 9
668
669 We are at the end of the regexp, so we are done! We have
670 matched 'abcd' out of the string "abcde".
671
672 =back
673
674 There are a couple of things to note about this analysis.  First, the
675 third alternative in the second group 'de' also allows a match, but we
676 stopped before we got to it - at a given character position, leftmost
677 wins.  Second, we were able to get a match at the first character
678 position of the string 'a'.  If there were no matches at the first
679 position, Perl would move to the second character position 'b' and
680 attempt the match all over again.  Only when all possible paths at all
681 possible character positions have been exhausted does Perl give
682 up and declare S<C<$string =~ /(abd|abc)(df|d|de)/;>> to be false.
683
684 Even with all this work, regexp matching happens remarkably fast.  To
685 speed things up, Perl compiles the regexp into a compact sequence of
686 opcodes that can often fit inside a processor cache.  When the code is
687 executed, these opcodes can then run at full throttle and search very
688 quickly.
689
690 =head2 Extracting matches
691
692 The grouping metacharacters C<()> also serve another completely
693 different function: they allow the extraction of the parts of a string
694 that matched.  This is very useful to find out what matched and for
695 text processing in general.  For each grouping, the part that matched
696 inside goes into the special variables C<$1>, C<$2>, etc.  They can be
697 used just as ordinary variables:
698
699     # extract hours, minutes, seconds
700     if ($time =~ /(\d\d):(\d\d):(\d\d)/) {    # match hh:mm:ss format
701         $hours = $1;
702         $minutes = $2;
703         $seconds = $3;
704     }
705
706 Now, we know that in scalar context,
707 S<C<$time =~ /(\d\d):(\d\d):(\d\d)/>> returns a true or false
708 value.  In list context, however, it returns the list of matched values
709 C<($1,$2,$3)>.  So we could write the code more compactly as
710
711     # extract hours, minutes, seconds
712     ($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);
713
714 If the groupings in a regexp are nested, C<$1> gets the group with the
715 leftmost opening parenthesis, C<$2> the next opening parenthesis,
716 etc.  Here is a regexp with nested groups:
717
718     /(ab(cd|ef)((gi)|j))/;
719      1  2      34
720
721 If this regexp matches, C<$1> contains a string starting with
722 C<'ab'>, C<$2> is either set to C<'cd'> or C<'ef'>, C<$3> equals either
723 C<'gi'> or C<'j'>, and C<$4> is either set to C<'gi'>, just like C<$3>,
724 or it remains undefined.
725
726 For convenience, Perl sets C<$+> to the string held by the highest numbered
727 C<$1>, C<$2>,... that got assigned (and, somewhat related, C<$^N> to the
728 value of the C<$1>, C<$2>,... most-recently assigned; i.e. the C<$1>,
729 C<$2>,... associated with the rightmost closing parenthesis used in the
730 match).
731
732
733 =head2 Backreferences
734
735 Closely associated with the matching variables C<$1>, C<$2>, ... are
736 the I<backreferences> C<\g1>, C<\g2>,...  Backreferences are simply
737 matching variables that can be used I<inside> a regexp.  This is a
738 really nice feature; what matches later in a regexp is made to depend on
739 what matched earlier in the regexp.  Suppose we wanted to look
740 for doubled words in a text, like 'the the'.  The following regexp finds
741 all 3-letter doubles with a space in between:
742
743     /\b(\w\w\w)\s\g1\b/;
744
745 The grouping assigns a value to \g1, so that the same 3 letter sequence
746 is used for both parts.
747
748 A similar task is to find words consisting of two identical parts:
749
750     % simple_grep '^(\w\w\w\w|\w\w\w|\w\w|\w)\g1$' /usr/dict/words
751     beriberi
752     booboo
753     coco
754     mama
755     murmur
756     papa
757
758 The regexp has a single grouping which considers 4-letter
759 combinations, then 3-letter combinations, etc., and uses C<\g1> to look for
760 a repeat.  Although C<$1> and C<\g1> represent the same thing, care should be
761 taken to use matched variables C<$1>, C<$2>,... only I<outside> a regexp
762 and backreferences C<\g1>, C<\g2>,... only I<inside> a regexp; not doing
763 so may lead to surprising and unsatisfactory results.
764
765
766 =head2 Relative backreferences
767
768 Counting the opening parentheses to get the correct number for a
769 backreference is errorprone as soon as there is more than one
770 capturing group.  A more convenient technique became available
771 with Perl 5.10: relative backreferences. To refer to the immediately
772 preceding capture group one now may write C<\g{-1}>, the next but
773 last is available via C<\g{-2}>, and so on.
774
775 Another good reason in addition to readability and maintainability
776 for using relative backreferences  is illustrated by the following example,
777 where a simple pattern for matching peculiar strings is used:
778
779     $a99a = '([a-z])(\d)\g2\g1';   # matches a11a, g22g, x33x, etc.
780
781 Now that we have this pattern stored as a handy string, we might feel
782 tempted to use it as a part of some other pattern:
783
784     $line = "code=e99e";
785     if ($line =~ /^(\w+)=$a99a$/){   # unexpected behavior!
786         print "$1 is valid\n";
787     } else {
788         print "bad line: '$line'\n";
789     }
790
791 But this doesn't match, at least not the way one might expect. Only
792 after inserting the interpolated C<$a99a> and looking at the resulting
793 full text of the regexp is it obvious that the backreferences have
794 backfired. The subexpression C<(\w+)> has snatched number 1 and
795 demoted the groups in C<$a99a> by one rank. This can be avoided by
796 using relative backreferences:
797
798     $a99a = '([a-z])(\d)\g{-1}\g{-2}';  # safe for being interpolated
799
800
801 =head2 Named backreferences
802
803 Perl 5.10 also introduced named capture groups and named backreferences.
804 To attach a name to a capturing group, you write either
805 C<< (?<name>...) >> or C<< (?'name'...) >>.  The backreference may
806 then be written as C<\g{name}>.  It is permissible to attach the
807 same name to more than one group, but then only the leftmost one of the
808 eponymous set can be referenced.  Outside of the pattern a named
809 capture group is accessible through the C<%+> hash.
810
811 Assuming that we have to match calendar dates which may be given in one
812 of the three formats yyyy-mm-dd, mm/dd/yyyy or dd.mm.yyyy, we can write
813 three suitable patterns where we use 'd', 'm' and 'y' respectively as the
814 names of the groups capturing the pertaining components of a date. The
815 matching operation combines the three patterns as alternatives:
816
817     $fmt1 = '(?<y>\d\d\d\d)-(?<m>\d\d)-(?<d>\d\d)';
818     $fmt2 = '(?<m>\d\d)/(?<d>\d\d)/(?<y>\d\d\d\d)';
819     $fmt3 = '(?<d>\d\d)\.(?<m>\d\d)\.(?<y>\d\d\d\d)';
820     for my $d qw( 2006-10-21 15.01.2007 10/31/2005 ){
821         if ( $d =~ m{$fmt1|$fmt2|$fmt3} ){
822             print "day=$+{d} month=$+{m} year=$+{y}\n";
823         }
824     }
825
826 If any of the alternatives matches, the hash C<%+> is bound to contain the
827 three key-value pairs.
828
829
830 =head2 Alternative capture group numbering
831
832 Yet another capturing group numbering technique (also as from Perl 5.10)
833 deals with the problem of referring to groups within a set of alternatives.
834 Consider a pattern for matching a time of the day, civil or military style:
835
836     if ( $time =~ /(\d\d|\d):(\d\d)|(\d\d)(\d\d)/ ){
837         # process hour and minute
838     }
839
840 Processing the results requires an additional if statement to determine
841 whether C<$1> and C<$2> or C<$3> and C<$4> contain the goodies. It would
842 be easier if we could use group numbers 1 and 2 in second alternative as
843 well, and this is exactly what the parenthesized construct C<(?|...)>,
844 set around an alternative achieves. Here is an extended version of the
845 previous pattern:
846
847     if ( $time =~ /(?|(\d\d|\d):(\d\d)|(\d\d)(\d\d))\s+([A-Z][A-Z][A-Z])/ ){
848         print "hour=$1 minute=$2 zone=$3\n";
849     }
850
851 Within the alternative numbering group, group numbers start at the same
852 position for each alternative. After the group, numbering continues
853 with one higher than the maximum reached across all the alternatives.
854
855 =head2 Position information
856
857 In addition to what was matched, Perl (since 5.6.0) also provides the
858 positions of what was matched as contents of the C<@-> and C<@+>
859 arrays. C<$-[0]> is the position of the start of the entire match and
860 C<$+[0]> is the position of the end. Similarly, C<$-[n]> is the
861 position of the start of the C<$n> match and C<$+[n]> is the position
862 of the end. If C<$n> is undefined, so are C<$-[n]> and C<$+[n]>. Then
863 this code
864
865     $x = "Mmm...donut, thought Homer";
866     $x =~ /^(Mmm|Yech)\.\.\.(donut|peas)/; # matches
867     foreach $expr (1..$#-) {
868         print "Match $expr: '${$expr}' at position ($-[$expr],$+[$expr])\n";
869     }
870
871 prints
872
873     Match 1: 'Mmm' at position (0,3)
874     Match 2: 'donut' at position (6,11)
875
876 Even if there are no groupings in a regexp, it is still possible to
877 find out what exactly matched in a string.  If you use them, Perl
878 will set C<$`> to the part of the string before the match, will set C<$&>
879 to the part of the string that matched, and will set C<$'> to the part
880 of the string after the match.  An example:
881
882     $x = "the cat caught the mouse";
883     $x =~ /cat/;  # $` = 'the ', $& = 'cat', $' = ' caught the mouse'
884     $x =~ /the/;  # $` = '', $& = 'the', $' = ' cat caught the mouse'
885
886 In the second match, C<$`> equals C<''> because the regexp matched at the
887 first character position in the string and stopped; it never saw the
888 second 'the'.  It is important to note that using C<$`> and C<$'>
889 slows down regexp matching quite a bit, while C<$&> slows it down to a
890 lesser extent, because if they are used in one regexp in a program,
891 they are generated for I<all> regexps in the program.  So if raw
892 performance is a goal of your application, they should be avoided.
893 If you need to extract the corresponding substrings, use C<@-> and
894 C<@+> instead:
895
896     $` is the same as substr( $x, 0, $-[0] )
897     $& is the same as substr( $x, $-[0], $+[0]-$-[0] )
898     $' is the same as substr( $x, $+[0] )
899
900
901 =head2 Non-capturing groupings
902
903 A group that is required to bundle a set of alternatives may or may not be
904 useful as a capturing group.  If it isn't, it just creates a superfluous
905 addition to the set of available capture group values, inside as well as
906 outside the regexp.  Non-capturing groupings, denoted by C<(?:regexp)>,
907 still allow the regexp to be treated as a single unit, but don't establish
908 a capturing group at the same time.  Both capturing and non-capturing
909 groupings are allowed to co-exist in the same regexp.  Because there is
910 no extraction, non-capturing groupings are faster than capturing
911 groupings.  Non-capturing groupings are also handy for choosing exactly
912 which parts of a regexp are to be extracted to matching variables:
913
914     # match a number, $1-$4 are set, but we only want $1
915     /([+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?)/;
916
917     # match a number faster , only $1 is set
918     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE][+-]?\d+)?)/;
919
920     # match a number, get $1 = whole number, $2 = exponent
921     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE]([+-]?\d+))?)/;
922
923 Non-capturing groupings are also useful for removing nuisance
924 elements gathered from a split operation where parentheses are
925 required for some reason:
926
927     $x = '12aba34ba5';
928     @num = split /(a|b)+/, $x;    # @num = ('12','a','34','a','5')
929     @num = split /(?:a|b)+/, $x;  # @num = ('12','34','5')
930
931
932 =head2 Matching repetitions
933
934 The examples in the previous section display an annoying weakness.  We
935 were only matching 3-letter words, or chunks of words of 4 letters or
936 less.  We'd like to be able to match words or, more generally, strings
937 of any length, without writing out tedious alternatives like
938 C<\w\w\w\w|\w\w\w|\w\w|\w>.
939
940 This is exactly the problem the I<quantifier> metacharacters C<?>,
941 C<*>, C<+>, and C<{}> were created for.  They allow us to delimit the
942 number of repeats for a portion of a regexp we consider to be a
943 match.  Quantifiers are put immediately after the character, character
944 class, or grouping that we want to specify.  They have the following
945 meanings:
946
947 =over 4
948
949 =item *
950
951 C<a?> means: match 'a' 1 or 0 times
952
953 =item *
954
955 C<a*> means: match 'a' 0 or more times, i.e., any number of times
956
957 =item *
958
959 C<a+> means: match 'a' 1 or more times, i.e., at least once
960
961 =item *
962
963 C<a{n,m}> means: match at least C<n> times, but not more than C<m>
964 times.
965
966 =item *
967
968 C<a{n,}> means: match at least C<n> or more times
969
970 =item *
971
972 C<a{n}> means: match exactly C<n> times
973
974 =back
975
976 Here are some examples:
977
978     /[a-z]+\s+\d*/;  # match a lowercase word, at least one space, and
979                      # any number of digits
980     /(\w+)\s+\g1/;    # match doubled words of arbitrary length
981     /y(es)?/i;       # matches 'y', 'Y', or a case-insensitive 'yes'
982     $year =~ /^\d{2,4}$/;  # make sure year is at least 2 but not more
983                            # than 4 digits
984     $year =~ /^\d{4}$|^\d{2}$/;    # better match; throw out 3 digit dates
985     $year =~ /^\d{2}(\d{2})?$/;  # same thing written differently. However,
986                                  # this captures the last two digits in $1
987                                  # and the other does not.
988
989     % simple_grep '^(\w+)\g1$' /usr/dict/words   # isn't this easier?
990     beriberi
991     booboo
992     coco
993     mama
994     murmur
995     papa
996
997 For all of these quantifiers, Perl will try to match as much of the
998 string as possible, while still allowing the regexp to succeed.  Thus
999 with C</a?.../>, Perl will first try to match the regexp with the C<a>
1000 present; if that fails, Perl will try to match the regexp without the
1001 C<a> present.  For the quantifier C<*>, we get the following:
1002
1003     $x = "the cat in the hat";
1004     $x =~ /^(.*)(cat)(.*)$/; # matches,
1005                              # $1 = 'the '
1006                              # $2 = 'cat'
1007                              # $3 = ' in the hat'
1008
1009 Which is what we might expect, the match finds the only C<cat> in the
1010 string and locks onto it.  Consider, however, this regexp:
1011
1012     $x =~ /^(.*)(at)(.*)$/; # matches,
1013                             # $1 = 'the cat in the h'
1014                             # $2 = 'at'
1015                             # $3 = ''   (0 characters match)
1016
1017 One might initially guess that Perl would find the C<at> in C<cat> and
1018 stop there, but that wouldn't give the longest possible string to the
1019 first quantifier C<.*>.  Instead, the first quantifier C<.*> grabs as
1020 much of the string as possible while still having the regexp match.  In
1021 this example, that means having the C<at> sequence with the final C<at>
1022 in the string.  The other important principle illustrated here is that
1023 when there are two or more elements in a regexp, the I<leftmost>
1024 quantifier, if there is one, gets to grab as much the string as
1025 possible, leaving the rest of the regexp to fight over scraps.  Thus in
1026 our example, the first quantifier C<.*> grabs most of the string, while
1027 the second quantifier C<.*> gets the empty string.   Quantifiers that
1028 grab as much of the string as possible are called I<maximal match> or
1029 I<greedy> quantifiers.
1030
1031 When a regexp can match a string in several different ways, we can use
1032 the principles above to predict which way the regexp will match:
1033
1034 =over 4
1035
1036 =item *
1037
1038 Principle 0: Taken as a whole, any regexp will be matched at the
1039 earliest possible position in the string.
1040
1041 =item *
1042
1043 Principle 1: In an alternation C<a|b|c...>, the leftmost alternative
1044 that allows a match for the whole regexp will be the one used.
1045
1046 =item *
1047
1048 Principle 2: The maximal matching quantifiers C<?>, C<*>, C<+> and
1049 C<{n,m}> will in general match as much of the string as possible while
1050 still allowing the whole regexp to match.
1051
1052 =item *
1053
1054 Principle 3: If there are two or more elements in a regexp, the
1055 leftmost greedy quantifier, if any, will match as much of the string
1056 as possible while still allowing the whole regexp to match.  The next
1057 leftmost greedy quantifier, if any, will try to match as much of the
1058 string remaining available to it as possible, while still allowing the
1059 whole regexp to match.  And so on, until all the regexp elements are
1060 satisfied.
1061
1062 =back
1063
1064 As we have seen above, Principle 0 overrides the others. The regexp
1065 will be matched as early as possible, with the other principles
1066 determining how the regexp matches at that earliest character
1067 position.
1068
1069 Here is an example of these principles in action:
1070
1071     $x = "The programming republic of Perl";
1072     $x =~ /^(.+)(e|r)(.*)$/;  # matches,
1073                               # $1 = 'The programming republic of Pe'
1074                               # $2 = 'r'
1075                               # $3 = 'l'
1076
1077 This regexp matches at the earliest string position, C<'T'>.  One
1078 might think that C<e>, being leftmost in the alternation, would be
1079 matched, but C<r> produces the longest string in the first quantifier.
1080
1081     $x =~ /(m{1,2})(.*)$/;  # matches,
1082                             # $1 = 'mm'
1083                             # $2 = 'ing republic of Perl'
1084
1085 Here, The earliest possible match is at the first C<'m'> in
1086 C<programming>. C<m{1,2}> is the first quantifier, so it gets to match
1087 a maximal C<mm>.
1088
1089     $x =~ /.*(m{1,2})(.*)$/;  # matches,
1090                               # $1 = 'm'
1091                               # $2 = 'ing republic of Perl'
1092
1093 Here, the regexp matches at the start of the string. The first
1094 quantifier C<.*> grabs as much as possible, leaving just a single
1095 C<'m'> for the second quantifier C<m{1,2}>.
1096
1097     $x =~ /(.?)(m{1,2})(.*)$/;  # matches,
1098                                 # $1 = 'a'
1099                                 # $2 = 'mm'
1100                                 # $3 = 'ing republic of Perl'
1101
1102 Here, C<.?> eats its maximal one character at the earliest possible
1103 position in the string, C<'a'> in C<programming>, leaving C<m{1,2}>
1104 the opportunity to match both C<m>'s. Finally,
1105
1106     "aXXXb" =~ /(X*)/; # matches with $1 = ''
1107
1108 because it can match zero copies of C<'X'> at the beginning of the
1109 string.  If you definitely want to match at least one C<'X'>, use
1110 C<X+>, not C<X*>.
1111
1112 Sometimes greed is not good.  At times, we would like quantifiers to
1113 match a I<minimal> piece of string, rather than a maximal piece.  For
1114 this purpose, Larry Wall created the I<minimal match> or
1115 I<non-greedy> quantifiers C<??>, C<*?>, C<+?>, and C<{}?>.  These are
1116 the usual quantifiers with a C<?> appended to them.  They have the
1117 following meanings:
1118
1119 =over 4
1120
1121 =item *
1122
1123 C<a??> means: match 'a' 0 or 1 times. Try 0 first, then 1.
1124
1125 =item *
1126
1127 C<a*?> means: match 'a' 0 or more times, i.e., any number of times,
1128 but as few times as possible
1129
1130 =item *
1131
1132 C<a+?> means: match 'a' 1 or more times, i.e., at least once, but
1133 as few times as possible
1134
1135 =item *
1136
1137 C<a{n,m}?> means: match at least C<n> times, not more than C<m>
1138 times, as few times as possible
1139
1140 =item *
1141
1142 C<a{n,}?> means: match at least C<n> times, but as few times as
1143 possible
1144
1145 =item *
1146
1147 C<a{n}?> means: match exactly C<n> times.  Because we match exactly
1148 C<n> times, C<a{n}?> is equivalent to C<a{n}> and is just there for
1149 notational consistency.
1150
1151 =back
1152
1153 Let's look at the example above, but with minimal quantifiers:
1154
1155     $x = "The programming republic of Perl";
1156     $x =~ /^(.+?)(e|r)(.*)$/; # matches,
1157                               # $1 = 'Th'
1158                               # $2 = 'e'
1159                               # $3 = ' programming republic of Perl'
1160
1161 The minimal string that will allow both the start of the string C<^>
1162 and the alternation to match is C<Th>, with the alternation C<e|r>
1163 matching C<e>.  The second quantifier C<.*> is free to gobble up the
1164 rest of the string.
1165
1166     $x =~ /(m{1,2}?)(.*?)$/;  # matches,
1167                               # $1 = 'm'
1168                               # $2 = 'ming republic of Perl'
1169
1170 The first string position that this regexp can match is at the first
1171 C<'m'> in C<programming>. At this position, the minimal C<m{1,2}?>
1172 matches just one C<'m'>.  Although the second quantifier C<.*?> would
1173 prefer to match no characters, it is constrained by the end-of-string
1174 anchor C<$> to match the rest of the string.
1175
1176     $x =~ /(.*?)(m{1,2}?)(.*)$/;  # matches,
1177                                   # $1 = 'The progra'
1178                                   # $2 = 'm'
1179                                   # $3 = 'ming republic of Perl'
1180
1181 In this regexp, you might expect the first minimal quantifier C<.*?>
1182 to match the empty string, because it is not constrained by a C<^>
1183 anchor to match the beginning of the word.  Principle 0 applies here,
1184 however.  Because it is possible for the whole regexp to match at the
1185 start of the string, it I<will> match at the start of the string.  Thus
1186 the first quantifier has to match everything up to the first C<m>.  The
1187 second minimal quantifier matches just one C<m> and the third
1188 quantifier matches the rest of the string.
1189
1190     $x =~ /(.??)(m{1,2})(.*)$/;  # matches,
1191                                  # $1 = 'a'
1192                                  # $2 = 'mm'
1193                                  # $3 = 'ing republic of Perl'
1194
1195 Just as in the previous regexp, the first quantifier C<.??> can match
1196 earliest at position C<'a'>, so it does.  The second quantifier is
1197 greedy, so it matches C<mm>, and the third matches the rest of the
1198 string.
1199
1200 We can modify principle 3 above to take into account non-greedy
1201 quantifiers:
1202
1203 =over 4
1204
1205 =item *
1206
1207 Principle 3: If there are two or more elements in a regexp, the
1208 leftmost greedy (non-greedy) quantifier, if any, will match as much
1209 (little) of the string as possible while still allowing the whole
1210 regexp to match.  The next leftmost greedy (non-greedy) quantifier, if
1211 any, will try to match as much (little) of the string remaining
1212 available to it as possible, while still allowing the whole regexp to
1213 match.  And so on, until all the regexp elements are satisfied.
1214
1215 =back
1216
1217 Just like alternation, quantifiers are also susceptible to
1218 backtracking.  Here is a step-by-step analysis of the example
1219
1220     $x = "the cat in the hat";
1221     $x =~ /^(.*)(at)(.*)$/; # matches,
1222                             # $1 = 'the cat in the h'
1223                             # $2 = 'at'
1224                             # $3 = ''   (0 matches)
1225
1226 =over 4
1227
1228 =item 0
1229
1230 Start with the first letter in the string 't'.
1231
1232 =item 1
1233
1234 The first quantifier '.*' starts out by matching the whole
1235 string 'the cat in the hat'.
1236
1237 =item 2
1238
1239 'a' in the regexp element 'at' doesn't match the end of the
1240 string.  Backtrack one character.
1241
1242 =item 3
1243
1244 'a' in the regexp element 'at' still doesn't match the last
1245 letter of the string 't', so backtrack one more character.
1246
1247 =item 4
1248
1249 Now we can match the 'a' and the 't'.
1250
1251 =item 5
1252
1253 Move on to the third element '.*'.  Since we are at the end of
1254 the string and '.*' can match 0 times, assign it the empty string.
1255
1256 =item 6
1257
1258 We are done!
1259
1260 =back
1261
1262 Most of the time, all this moving forward and backtracking happens
1263 quickly and searching is fast. There are some pathological regexps,
1264 however, whose execution time exponentially grows with the size of the
1265 string.  A typical structure that blows up in your face is of the form
1266
1267     /(a|b+)*/;
1268
1269 The problem is the nested indeterminate quantifiers.  There are many
1270 different ways of partitioning a string of length n between the C<+>
1271 and C<*>: one repetition with C<b+> of length n, two repetitions with
1272 the first C<b+> length k and the second with length n-k, m repetitions
1273 whose bits add up to length n, etc.  In fact there are an exponential
1274 number of ways to partition a string as a function of its length.  A
1275 regexp may get lucky and match early in the process, but if there is
1276 no match, Perl will try I<every> possibility before giving up.  So be
1277 careful with nested C<*>'s, C<{n,m}>'s, and C<+>'s.  The book
1278 I<Mastering Regular Expressions> by Jeffrey Friedl gives a wonderful
1279 discussion of this and other efficiency issues.
1280
1281
1282 =head2 Possessive quantifiers
1283
1284 Backtracking during the relentless search for a match may be a waste
1285 of time, particularly when the match is bound to fail.  Consider
1286 the simple pattern
1287
1288     /^\w+\s+\w+$/; # a word, spaces, a word
1289
1290 Whenever this is applied to a string which doesn't quite meet the
1291 pattern's expectations such as S<C<"abc  ">> or S<C<"abc  def ">>,
1292 the regex engine will backtrack, approximately once for each character
1293 in the string.  But we know that there is no way around taking I<all>
1294 of the initial word characters to match the first repetition, that I<all>
1295 spaces must be eaten by the middle part, and the same goes for the second
1296 word.
1297
1298 With the introduction of the I<possessive quantifiers> in Perl 5.10, we
1299 have a way of instructing the regex engine not to backtrack, with the
1300 usual quantifiers with a C<+> appended to them.  This makes them greedy as
1301 well as stingy; once they succeed they won't give anything back to permit
1302 another solution. They have the following meanings:
1303
1304 =over 4
1305
1306 =item *
1307
1308 C<a{n,m}+> means: match at least C<n> times, not more than C<m> times,
1309 as many times as possible, and don't give anything up. C<a?+> is short
1310 for C<a{0,1}+>
1311
1312 =item *
1313
1314 C<a{n,}+> means: match at least C<n> times, but as many times as possible,
1315 and don't give anything up. C<a*+> is short for C<a{0,}+> and C<a++> is
1316 short for C<a{1,}+>.
1317
1318 =item *
1319
1320 C<a{n}+> means: match exactly C<n> times.  It is just there for
1321 notational consistency.
1322
1323 =back
1324
1325 These possessive quantifiers represent a special case of a more general
1326 concept, the I<independent subexpression>, see below.
1327
1328 As an example where a possessive quantifier is suitable we consider
1329 matching a quoted string, as it appears in several programming languages.
1330 The backslash is used as an escape character that indicates that the
1331 next character is to be taken literally, as another character for the
1332 string.  Therefore, after the opening quote, we expect a (possibly
1333 empty) sequence of alternatives: either some character except an
1334 unescaped quote or backslash or an escaped character.
1335
1336     /"(?:[^"\\]++|\\.)*+"/;
1337
1338
1339 =head2 Building a regexp
1340
1341 At this point, we have all the basic regexp concepts covered, so let's
1342 give a more involved example of a regular expression.  We will build a
1343 regexp that matches numbers.
1344
1345 The first task in building a regexp is to decide what we want to match
1346 and what we want to exclude.  In our case, we want to match both
1347 integers and floating point numbers and we want to reject any string
1348 that isn't a number.
1349
1350 The next task is to break the problem down into smaller problems that
1351 are easily converted into a regexp.
1352
1353 The simplest case is integers.  These consist of a sequence of digits,
1354 with an optional sign in front.  The digits we can represent with
1355 C<\d+> and the sign can be matched with C<[+-]>.  Thus the integer
1356 regexp is
1357
1358     /[+-]?\d+/;  # matches integers
1359
1360 A floating point number potentially has a sign, an integral part, a
1361 decimal point, a fractional part, and an exponent.  One or more of these
1362 parts is optional, so we need to check out the different
1363 possibilities.  Floating point numbers which are in proper form include
1364 123., 0.345, .34, -1e6, and 25.4E-72.  As with integers, the sign out
1365 front is completely optional and can be matched by C<[+-]?>.  We can
1366 see that if there is no exponent, floating point numbers must have a
1367 decimal point, otherwise they are integers.  We might be tempted to
1368 model these with C<\d*\.\d*>, but this would also match just a single
1369 decimal point, which is not a number.  So the three cases of floating
1370 point number without exponent are
1371
1372    /[+-]?\d+\./;  # 1., 321., etc.
1373    /[+-]?\.\d+/;  # .1, .234, etc.
1374    /[+-]?\d+\.\d+/;  # 1.0, 30.56, etc.
1375
1376 These can be combined into a single regexp with a three-way alternation:
1377
1378    /[+-]?(\d+\.\d+|\d+\.|\.\d+)/;  # floating point, no exponent
1379
1380 In this alternation, it is important to put C<'\d+\.\d+'> before
1381 C<'\d+\.'>.  If C<'\d+\.'> were first, the regexp would happily match that
1382 and ignore the fractional part of the number.
1383
1384 Now consider floating point numbers with exponents.  The key
1385 observation here is that I<both> integers and numbers with decimal
1386 points are allowed in front of an exponent.  Then exponents, like the
1387 overall sign, are independent of whether we are matching numbers with
1388 or without decimal points, and can be 'decoupled' from the
1389 mantissa.  The overall form of the regexp now becomes clear:
1390
1391     /^(optional sign)(integer | f.p. mantissa)(optional exponent)$/;
1392
1393 The exponent is an C<e> or C<E>, followed by an integer.  So the
1394 exponent regexp is
1395
1396    /[eE][+-]?\d+/;  # exponent
1397
1398 Putting all the parts together, we get a regexp that matches numbers:
1399
1400    /^[+-]?(\d+\.\d+|\d+\.|\.\d+|\d+)([eE][+-]?\d+)?$/;  # Ta da!
1401
1402 Long regexps like this may impress your friends, but can be hard to
1403 decipher.  In complex situations like this, the C<//x> modifier for a
1404 match is invaluable.  It allows one to put nearly arbitrary whitespace
1405 and comments into a regexp without affecting their meaning.  Using it,
1406 we can rewrite our 'extended' regexp in the more pleasing form
1407
1408    /^
1409       [+-]?         # first, match an optional sign
1410       (             # then match integers or f.p. mantissas:
1411           \d+\.\d+  # mantissa of the form a.b
1412          |\d+\.     # mantissa of the form a.
1413          |\.\d+     # mantissa of the form .b
1414          |\d+       # integer of the form a
1415       )
1416       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1417    $/x;
1418
1419 If whitespace is mostly irrelevant, how does one include space
1420 characters in an extended regexp? The answer is to backslash it
1421 S<C<'\ '>> or put it in a character class S<C<[ ]>>.  The same thing
1422 goes for pound signs, use C<\#> or C<[#]>.  For instance, Perl allows
1423 a space between the sign and the mantissa or integer, and we could add
1424 this to our regexp as follows:
1425
1426    /^
1427       [+-]?\ *      # first, match an optional sign *and space*
1428       (             # then match integers or f.p. mantissas:
1429           \d+\.\d+  # mantissa of the form a.b
1430          |\d+\.     # mantissa of the form a.
1431          |\.\d+     # mantissa of the form .b
1432          |\d+       # integer of the form a
1433       )
1434       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1435    $/x;
1436
1437 In this form, it is easier to see a way to simplify the
1438 alternation.  Alternatives 1, 2, and 4 all start with C<\d+>, so it
1439 could be factored out:
1440
1441    /^
1442       [+-]?\ *      # first, match an optional sign
1443       (             # then match integers or f.p. mantissas:
1444           \d+       # start out with a ...
1445           (
1446               \.\d* # mantissa of the form a.b or a.
1447           )?        # ? takes care of integers of the form a
1448          |\.\d+     # mantissa of the form .b
1449       )
1450       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1451    $/x;
1452
1453 or written in the compact form,
1454
1455     /^[+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?$/;
1456
1457 This is our final regexp.  To recap, we built a regexp by
1458
1459 =over 4
1460
1461 =item *
1462
1463 specifying the task in detail,
1464
1465 =item *
1466
1467 breaking down the problem into smaller parts,
1468
1469 =item *
1470
1471 translating the small parts into regexps,
1472
1473 =item *
1474
1475 combining the regexps,
1476
1477 =item *
1478
1479 and optimizing the final combined regexp.
1480
1481 =back
1482
1483 These are also the typical steps involved in writing a computer
1484 program.  This makes perfect sense, because regular expressions are
1485 essentially programs written in a little computer language that specifies
1486 patterns.
1487
1488 =head2 Using regular expressions in Perl
1489
1490 The last topic of Part 1 briefly covers how regexps are used in Perl
1491 programs.  Where do they fit into Perl syntax?
1492
1493 We have already introduced the matching operator in its default
1494 C</regexp/> and arbitrary delimiter C<m!regexp!> forms.  We have used
1495 the binding operator C<=~> and its negation C<!~> to test for string
1496 matches.  Associated with the matching operator, we have discussed the
1497 single line C<//s>, multi-line C<//m>, case-insensitive C<//i> and
1498 extended C<//x> modifiers.  There are a few more things you might
1499 want to know about matching operators.
1500
1501 =head3 Optimizing pattern evaluation
1502
1503 We pointed out earlier that variables in regexps are substituted
1504 before the regexp is evaluated:
1505
1506     $pattern = 'Seuss';
1507     while (<>) {
1508         print if /$pattern/;
1509     }
1510
1511 This will print any lines containing the word C<Seuss>.  It is not as
1512 efficient as it could be, however, because Perl has to re-evaluate
1513 (or compile) C<$pattern> each time through the loop.  If C<$pattern> won't be
1514 changing over the lifetime of the script, we can add the C<//o>
1515 modifier, which directs Perl to only perform variable substitutions
1516 once:
1517
1518     #!/usr/bin/perl
1519     #    Improved simple_grep
1520     $regexp = shift;
1521     while (<>) {
1522         print if /$regexp/o;  # a good deal faster
1523     }
1524
1525
1526 =head3 Prohibiting substitution
1527
1528 If you change C<$pattern> after the first substitution happens, Perl
1529 will ignore it.  If you don't want any substitutions at all, use the
1530 special delimiter C<m''>:
1531
1532     @pattern = ('Seuss');
1533     while (<>) {
1534         print if m'@pattern';  # matches literal '@pattern', not 'Seuss'
1535     }
1536
1537 Similar to strings, C<m''> acts like apostrophes on a regexp; all other
1538 C<m> delimiters act like quotes.  If the regexp evaluates to the empty string,
1539 the regexp in the I<last successful match> is used instead.  So we have
1540
1541     "dog" =~ /d/;  # 'd' matches
1542     "dogbert =~ //;  # this matches the 'd' regexp used before
1543
1544
1545 =head3 Global matching
1546
1547 The final two modifiers C<//g> and C<//c> concern multiple matches.
1548 The modifier C<//g> stands for global matching and allows the
1549 matching operator to match within a string as many times as possible.
1550 In scalar context, successive invocations against a string will have
1551 `C<//g> jump from match to match, keeping track of position in the
1552 string as it goes along.  You can get or set the position with the
1553 C<pos()> function.
1554
1555 The use of C<//g> is shown in the following example.  Suppose we have
1556 a string that consists of words separated by spaces.  If we know how
1557 many words there are in advance, we could extract the words using
1558 groupings:
1559
1560     $x = "cat dog house"; # 3 words
1561     $x =~ /^\s*(\w+)\s+(\w+)\s+(\w+)\s*$/; # matches,
1562                                            # $1 = 'cat'
1563                                            # $2 = 'dog'
1564                                            # $3 = 'house'
1565
1566 But what if we had an indeterminate number of words? This is the sort
1567 of task C<//g> was made for.  To extract all words, form the simple
1568 regexp C<(\w+)> and loop over all matches with C</(\w+)/g>:
1569
1570     while ($x =~ /(\w+)/g) {
1571         print "Word is $1, ends at position ", pos $x, "\n";
1572     }
1573
1574 prints
1575
1576     Word is cat, ends at position 3
1577     Word is dog, ends at position 7
1578     Word is house, ends at position 13
1579
1580 A failed match or changing the target string resets the position.  If
1581 you don't want the position reset after failure to match, add the
1582 C<//c>, as in C</regexp/gc>.  The current position in the string is
1583 associated with the string, not the regexp.  This means that different
1584 strings have different positions and their respective positions can be
1585 set or read independently.
1586
1587 In list context, C<//g> returns a list of matched groupings, or if
1588 there are no groupings, a list of matches to the whole regexp.  So if
1589 we wanted just the words, we could use
1590
1591     @words = ($x =~ /(\w+)/g);  # matches,
1592                                 # $word[0] = 'cat'
1593                                 # $word[1] = 'dog'
1594                                 # $word[2] = 'house'
1595
1596 Closely associated with the C<//g> modifier is the C<\G> anchor.  The
1597 C<\G> anchor matches at the point where the previous C<//g> match left
1598 off.  C<\G> allows us to easily do context-sensitive matching:
1599
1600     $metric = 1;  # use metric units
1601     ...
1602     $x = <FILE>;  # read in measurement
1603     $x =~ /^([+-]?\d+)\s*/g;  # get magnitude
1604     $weight = $1;
1605     if ($metric) { # error checking
1606         print "Units error!" unless $x =~ /\Gkg\./g;
1607     }
1608     else {
1609         print "Units error!" unless $x =~ /\Glbs\./g;
1610     }
1611     $x =~ /\G\s+(widget|sprocket)/g;  # continue processing
1612
1613 The combination of C<//g> and C<\G> allows us to process the string a
1614 bit at a time and use arbitrary Perl logic to decide what to do next.
1615 Currently, the C<\G> anchor is only fully supported when used to anchor
1616 to the start of the pattern.
1617
1618 C<\G> is also invaluable in processing fixed length records with
1619 regexps.  Suppose we have a snippet of coding region DNA, encoded as
1620 base pair letters C<ATCGTTGAAT...> and we want to find all the stop
1621 codons C<TGA>.  In a coding region, codons are 3-letter sequences, so
1622 we can think of the DNA snippet as a sequence of 3-letter records.  The
1623 naive regexp
1624
1625     # expanded, this is "ATC GTT GAA TGC AAA TGA CAT GAC"
1626     $dna = "ATCGTTGAATGCAAATGACATGAC";
1627     $dna =~ /TGA/;
1628
1629 doesn't work; it may match a C<TGA>, but there is no guarantee that
1630 the match is aligned with codon boundaries, e.g., the substring
1631 S<C<GTT GAA>> gives a match.  A better solution is
1632
1633     while ($dna =~ /(\w\w\w)*?TGA/g) {  # note the minimal *?
1634         print "Got a TGA stop codon at position ", pos $dna, "\n";
1635     }
1636
1637 which prints
1638
1639     Got a TGA stop codon at position 18
1640     Got a TGA stop codon at position 23
1641
1642 Position 18 is good, but position 23 is bogus.  What happened?
1643
1644 The answer is that our regexp works well until we get past the last
1645 real match.  Then the regexp will fail to match a synchronized C<TGA>
1646 and start stepping ahead one character position at a time, not what we
1647 want.  The solution is to use C<\G> to anchor the match to the codon
1648 alignment:
1649
1650     while ($dna =~ /\G(\w\w\w)*?TGA/g) {
1651         print "Got a TGA stop codon at position ", pos $dna, "\n";
1652     }
1653
1654 This prints
1655
1656     Got a TGA stop codon at position 18
1657
1658 which is the correct answer.  This example illustrates that it is
1659 important not only to match what is desired, but to reject what is not
1660 desired.
1661
1662 =head3 Search and replace
1663
1664 Regular expressions also play a big role in I<search and replace>
1665 operations in Perl.  Search and replace is accomplished with the
1666 C<s///> operator.  The general form is
1667 C<s/regexp/replacement/modifiers>, with everything we know about
1668 regexps and modifiers applying in this case as well.  The
1669 C<replacement> is a Perl double quoted string that replaces in the
1670 string whatever is matched with the C<regexp>.  The operator C<=~> is
1671 also used here to associate a string with C<s///>.  If matching
1672 against C<$_>, the S<C<$_ =~>> can be dropped.  If there is a match,
1673 C<s///> returns the number of substitutions made, otherwise it returns
1674 false.  Here are a few examples:
1675
1676     $x = "Time to feed the cat!";
1677     $x =~ s/cat/hacker/;   # $x contains "Time to feed the hacker!"
1678     if ($x =~ s/^(Time.*hacker)!$/$1 now!/) {
1679         $more_insistent = 1;
1680     }
1681     $y = "'quoted words'";
1682     $y =~ s/^'(.*)'$/$1/;  # strip single quotes,
1683                            # $y contains "quoted words"
1684
1685 In the last example, the whole string was matched, but only the part
1686 inside the single quotes was grouped.  With the C<s///> operator, the
1687 matched variables C<$1>, C<$2>, etc.  are immediately available for use
1688 in the replacement expression, so we use C<$1> to replace the quoted
1689 string with just what was quoted.  With the global modifier, C<s///g>
1690 will search and replace all occurrences of the regexp in the string:
1691
1692     $x = "I batted 4 for 4";
1693     $x =~ s/4/four/;   # doesn't do it all:
1694                        # $x contains "I batted four for 4"
1695     $x = "I batted 4 for 4";
1696     $x =~ s/4/four/g;  # does it all:
1697                        # $x contains "I batted four for four"
1698
1699 If you prefer 'regex' over 'regexp' in this tutorial, you could use
1700 the following program to replace it:
1701
1702     % cat > simple_replace
1703     #!/usr/bin/perl
1704     $regexp = shift;
1705     $replacement = shift;
1706     while (<>) {
1707         s/$regexp/$replacement/go;
1708         print;
1709     }
1710     ^D
1711
1712     % simple_replace regexp regex perlretut.pod
1713
1714 In C<simple_replace> we used the C<s///g> modifier to replace all
1715 occurrences of the regexp on each line and the C<s///o> modifier to
1716 compile the regexp only once.  As with C<simple_grep>, both the
1717 C<print> and the C<s/$regexp/$replacement/go> use C<$_> implicitly.
1718
1719 If you don't want C<s///> to change your original variable you can use
1720 the non-destructive substitute modifier, C<s///r>.  This changes the
1721 behavior so that C<s///r> returns the final substituted string:
1722
1723     $x = "I like dogs.";
1724     $y = $x =~ s/dogs/cats/r;
1725     print "$x $y\n";
1726
1727 That example will print "I like dogs. I like cats". Notice the original
1728 C<$x> variable has not been affected by the substitute. The overall
1729 result of the substitution is instead stored in C<$y>. If the
1730 substitution doesn't affect anything then the original string is
1731 returned:
1732
1733     $x = "I like dogs.";
1734     $y = $x =~ s/elephants/cougars/r;
1735     print "$x $y\n"; # prints "I like dogs. I like dogs."
1736
1737 One other interesting thing that the C<s///r> flag allows is chaining
1738 substitutions:
1739
1740     $x = "Cats are great.";
1741     print $x =~ s/Cats/Dogs/r =~ s/Dogs/Frogs/r =~ s/Frogs/Hedgehogs/r, "\n";
1742     # prints "Hedgehogs are great."
1743
1744 A modifier available specifically to search and replace is the
1745 C<s///e> evaluation modifier.  C<s///e> wraps an C<eval{...}> around
1746 the replacement string and the evaluated result is substituted for the
1747 matched substring.  C<s///e> is useful if you need to do a bit of
1748 computation in the process of replacing text.  This example counts
1749 character frequencies in a line:
1750
1751     $x = "Bill the cat";
1752     $x =~ s/(.)/$chars{$1}++;$1/eg;  # final $1 replaces char with itself
1753     print "frequency of '$_' is $chars{$_}\n"
1754         foreach (sort {$chars{$b} <=> $chars{$a}} keys %chars);
1755
1756 This prints
1757
1758     frequency of ' ' is 2
1759     frequency of 't' is 2
1760     frequency of 'l' is 2
1761     frequency of 'B' is 1
1762     frequency of 'c' is 1
1763     frequency of 'e' is 1
1764     frequency of 'h' is 1
1765     frequency of 'i' is 1
1766     frequency of 'a' is 1
1767
1768 As with the match C<m//> operator, C<s///> can use other delimiters,
1769 such as C<s!!!> and C<s{}{}>, and even C<s{}//>.  If single quotes are
1770 used C<s'''>, then the regexp and replacement are treated as single
1771 quoted strings and there are no substitutions.  C<s///> in list context
1772 returns the same thing as in scalar context, i.e., the number of
1773 matches.
1774
1775 =head3 The split function
1776
1777 The C<split()> function is another place where a regexp is used.
1778 C<split /regexp/, string, limit> separates the C<string> operand into
1779 a list of substrings and returns that list.  The regexp must be designed
1780 to match whatever constitutes the separators for the desired substrings.
1781 The C<limit>, if present, constrains splitting into no more than C<limit>
1782 number of strings.  For example, to split a string into words, use
1783
1784     $x = "Calvin and Hobbes";
1785     @words = split /\s+/, $x;  # $word[0] = 'Calvin'
1786                                # $word[1] = 'and'
1787                                # $word[2] = 'Hobbes'
1788
1789 If the empty regexp C<//> is used, the regexp always matches and
1790 the string is split into individual characters.  If the regexp has
1791 groupings, then the resulting list contains the matched substrings from the
1792 groupings as well.  For instance,
1793
1794     $x = "/usr/bin/perl";
1795     @dirs = split m!/!, $x;  # $dirs[0] = ''
1796                              # $dirs[1] = 'usr'
1797                              # $dirs[2] = 'bin'
1798                              # $dirs[3] = 'perl'
1799     @parts = split m!(/)!, $x;  # $parts[0] = ''
1800                                 # $parts[1] = '/'
1801                                 # $parts[2] = 'usr'
1802                                 # $parts[3] = '/'
1803                                 # $parts[4] = 'bin'
1804                                 # $parts[5] = '/'
1805                                 # $parts[6] = 'perl'
1806
1807 Since the first character of $x matched the regexp, C<split> prepended
1808 an empty initial element to the list.
1809
1810 If you have read this far, congratulations! You now have all the basic
1811 tools needed to use regular expressions to solve a wide range of text
1812 processing problems.  If this is your first time through the tutorial,
1813 why not stop here and play around with regexps a while...  S<Part 2>
1814 concerns the more esoteric aspects of regular expressions and those
1815 concepts certainly aren't needed right at the start.
1816
1817 =head1 Part 2: Power tools
1818
1819 OK, you know the basics of regexps and you want to know more.  If
1820 matching regular expressions is analogous to a walk in the woods, then
1821 the tools discussed in Part 1 are analogous to topo maps and a
1822 compass, basic tools we use all the time.  Most of the tools in part 2
1823 are analogous to flare guns and satellite phones.  They aren't used
1824 too often on a hike, but when we are stuck, they can be invaluable.
1825
1826 What follows are the more advanced, less used, or sometimes esoteric
1827 capabilities of Perl regexps.  In Part 2, we will assume you are
1828 comfortable with the basics and concentrate on the new features.
1829
1830 =head2 More on characters, strings, and character classes
1831
1832 There are a number of escape sequences and character classes that we
1833 haven't covered yet.
1834
1835 There are several escape sequences that convert characters or strings
1836 between upper and lower case, and they are also available within
1837 patterns.  C<\l> and C<\u> convert the next character to lower or
1838 upper case, respectively:
1839
1840     $x = "perl";
1841     $string =~ /\u$x/;  # matches 'Perl' in $string
1842     $x = "M(rs?|s)\\."; # note the double backslash
1843     $string =~ /\l$x/;  # matches 'mr.', 'mrs.', and 'ms.',
1844
1845 A C<\L> or C<\U> indicates a lasting conversion of case, until
1846 terminated by C<\E> or thrown over by another C<\U> or C<\L>:
1847
1848     $x = "This word is in lower case:\L SHOUT\E";
1849     $x =~ /shout/;       # matches
1850     $x = "I STILL KEYPUNCH CARDS FOR MY 360"
1851     $x =~ /\Ukeypunch/;  # matches punch card string
1852
1853 If there is no C<\E>, case is converted until the end of the
1854 string. The regexps C<\L\u$word> or C<\u\L$word> convert the first
1855 character of C<$word> to uppercase and the rest of the characters to
1856 lowercase.
1857
1858 Control characters can be escaped with C<\c>, so that a control-Z
1859 character would be matched with C<\cZ>.  The escape sequence
1860 C<\Q>...C<\E> quotes, or protects most non-alphabetic characters.   For
1861 instance,
1862
1863     $x = "\QThat !^*&%~& cat!";
1864     $x =~ /\Q!^*&%~&\E/;  # check for rough language
1865
1866 It does not protect C<$> or C<@>, so that variables can still be
1867 substituted.
1868
1869 With the advent of 5.6.0, Perl regexps can handle more than just the
1870 standard ASCII character set.  Perl now supports I<Unicode>, a standard
1871 for representing the alphabets from virtually all of the world's written
1872 languages, and a host of symbols.  Perl's text strings are Unicode strings, so
1873 they can contain characters with a value (codepoint or character number) higher
1874 than 255
1875
1876 What does this mean for regexps? Well, regexp users don't need to know
1877 much about Perl's internal representation of strings.  But they do need
1878 to know 1) how to represent Unicode characters in a regexp and 2) that
1879 a matching operation will treat the string to be searched as a sequence
1880 of characters, not bytes.  The answer to 1) is that Unicode characters
1881 greater than C<chr(255)> are represented using the C<\x{hex}> notation, because
1882 \x hex (without curly braces) doesn't go further than 255.  (Starting in Perl
1883 5.14) if you're an octal fan, you can also use C<\o{oct}>.
1884
1885     /\x{263a}/;  # match a Unicode smiley face :)
1886
1887 B<NOTE>: In Perl 5.6.0 it used to be that one needed to say C<use
1888 utf8> to use any Unicode features.  This is no more the case: for
1889 almost all Unicode processing, the explicit C<utf8> pragma is not
1890 needed.  (The only case where it matters is if your Perl script is in
1891 Unicode and encoded in UTF-8, then an explicit C<use utf8> is needed.)
1892
1893 Figuring out the hexadecimal sequence of a Unicode character you want
1894 or deciphering someone else's hexadecimal Unicode regexp is about as
1895 much fun as programming in machine code.  So another way to specify
1896 Unicode characters is to use the I<named character> escape
1897 sequence C<\N{I<name>}>.  I<name> is a name for the Unicode character, as
1898 specified in the Unicode standard.  For instance, if we wanted to
1899 represent or match the astrological sign for the planet Mercury, we
1900 could use
1901
1902     use charnames ":full"; # use named chars with Unicode full names
1903     $x = "abc\N{MERCURY}def";
1904     $x =~ /\N{MERCURY}/;   # matches
1905
1906 One can also use short names or restrict names to a certain alphabet:
1907
1908     use charnames ':full';
1909     print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
1910
1911     use charnames ":short";
1912     print "\N{greek:Sigma} is an upper-case sigma.\n";
1913
1914     use charnames qw(greek);
1915     print "\N{sigma} is Greek sigma\n";
1916
1917 A list of full names is found in the file NamesList.txt in the
1918 lib/perl5/X.X.X/unicore directory (where X.X.X is the perl
1919 version number as it is installed on your system).
1920
1921 The answer to requirement 2), as of 5.6.0, is that a regexp uses Unicode
1922 characters. Internally, this is encoded to bytes using either UTF-8 or a
1923 native 8 bit encoding, depending on the history of the string, but
1924 conceptually it is a sequence of characters, not bytes. See
1925 L<perlunitut> for a tutorial about that.
1926
1927 Let us now discuss Unicode character classes.  Just as with Unicode
1928 characters, there are named Unicode character classes represented by the
1929 C<\p{name}> escape sequence.  Closely associated is the C<\P{name}>
1930 character class, which is the negation of the C<\p{name}> class.  For
1931 example, to match lower and uppercase characters,
1932
1933     use charnames ":full"; # use named chars with Unicode full names
1934     $x = "BOB";
1935     $x =~ /^\p{IsUpper}/;   # matches, uppercase char class
1936     $x =~ /^\P{IsUpper}/;   # doesn't match, char class sans uppercase
1937     $x =~ /^\p{IsLower}/;   # doesn't match, lowercase char class
1938     $x =~ /^\P{IsLower}/;   # matches, char class sans lowercase
1939
1940 Here is the association between some Perl named classes and the
1941 traditional Unicode classes:
1942
1943     Perl class name  Unicode class name or regular expression
1944
1945     IsAlpha          /^[LM]/
1946     IsAlnum          /^[LMN]/
1947     IsASCII          $code <= 127
1948     IsCntrl          /^C/
1949     IsBlank          $code =~ /^(0020|0009)$/ || /^Z[^lp]/
1950     IsDigit          Nd
1951     IsGraph          /^([LMNPS]|Co)/
1952     IsLower          Ll
1953     IsPrint          /^([LMNPS]|Co|Zs)/
1954     IsPunct          /^P/
1955     IsSpace          /^Z/ || ($code =~ /^(0009|000A|000B|000C|000D)$/
1956     IsSpacePerl      /^Z/ || ($code =~ /^(0009|000A|000C|000D|0085|2028|2029)$/
1957     IsUpper          /^L[ut]/
1958     IsWord           /^[LMN]/ || $code eq "005F"
1959     IsXDigit         $code =~ /^00(3[0-9]|[46][1-6])$/
1960
1961 You can also use the official Unicode class names with the C<\p> and
1962 C<\P>, like C<\p{L}> for Unicode 'letters', or C<\p{Lu}> for uppercase
1963 letters, or C<\P{Nd}> for non-digits.  If a C<name> is just one
1964 letter, the braces can be dropped.  For instance, C<\pM> is the
1965 character class of Unicode 'marks', for example accent marks.
1966 For the full list see L<perlunicode>.
1967
1968 The Unicode has also been separated into various sets of characters
1969 which you can test with C<\p{...}> (in) and C<\P{...}> (not in).
1970 To test whether a character is (or is not) an element of a script
1971 you would use the script name, for example C<\p{Latin}>, C<\p{Greek}>,
1972 or C<\P{Katakana}>. Other sets are the Unicode blocks, the names
1973 of which begin with "In". One such block is dedicated to mathematical
1974 operators, and its pattern formula is <C\p{InMathematicalOperators>}>.
1975 For the full list see L<perluniprops>.
1976
1977 What we have described so far is the single form of the C<\p{...}> character
1978 classes.  There is also a compound form which you may run into.  These
1979 look like C<\p{name=value}> or C<\p{name:value}> (the equals sign and colon
1980 can be used interchangeably).  These are more general than the single form,
1981 and in fact most of the single forms are just Perl-defined shortcuts for common
1982 compound forms.  For example, the script examples in the previous paragraph
1983 could be written equivalently as C<\p{Script=Latin}>, C<\p{Script:Greek}>, and
1984 C<\P{script=katakana}> (case is irrelevant between the C<{}> braces).  You may
1985 never have to use the compound forms, but sometimes it is necessary, and their
1986 use can make your code easier to understand.
1987
1988 C<\X> is an abbreviation for a character class that comprises
1989 a Unicode I<extended grapheme cluster>.  This represents a "logical character",
1990 what appears to be a single character, but may be represented internally by more
1991 than one.  As an example, using the Unicode full names, e.g., S<C<A + COMBINING
1992 RING>> is a grapheme cluster with base character C<A> and combining character
1993 S<C<COMBINING RING>>, which translates in Danish to A with the circle atop it,
1994 as in the word Angstrom.
1995
1996 For the full and latest information about Unicode see the latest
1997 Unicode standard, or the Unicode Consortium's website L<http://www.unicode.org>
1998
1999 As if all those classes weren't enough, Perl also defines POSIX style
2000 character classes.  These have the form C<[:name:]>, with C<name> the
2001 name of the POSIX class.  The POSIX classes are C<alpha>, C<alnum>,
2002 C<ascii>, C<cntrl>, C<digit>, C<graph>, C<lower>, C<print>, C<punct>,
2003 C<space>, C<upper>, and C<xdigit>, and two extensions, C<word> (a Perl
2004 extension to match C<\w>), and C<blank> (a GNU extension).  If C<utf8>
2005 is being used, then these classes are defined the same as their
2006 corresponding Perl Unicode classes: C<[:upper:]> is the same as
2007 C<\p{IsUpper}>, etc.  The POSIX character classes, however, don't
2008 require using C<utf8>.  The C<[:digit:]>, C<[:word:]>, and
2009 C<[:space:]> correspond to the familiar C<\d>, C<\w>, and C<\s>
2010 character classes.  To negate a POSIX class, put a C<^> in front of
2011 the name, so that, e.g., C<[:^digit:]> corresponds to C<\D> and under
2012 C<utf8>, C<\P{IsDigit}>.  The Unicode and POSIX character classes can
2013 be used just like C<\d>, with the exception that POSIX character
2014 classes can only be used inside of a character class:
2015
2016     /\s+[abc[:digit:]xyz]\s*/;  # match a,b,c,x,y,z, or a digit
2017     /^=item\s[[:digit:]]/;      # match '=item',
2018                                 # followed by a space and a digit
2019     use charnames ":full";
2020     /\s+[abc\p{IsDigit}xyz]\s+/;  # match a,b,c,x,y,z, or a digit
2021     /^=item\s\p{IsDigit}/;        # match '=item',
2022                                   # followed by a space and a digit
2023
2024 Whew! That is all the rest of the characters and character classes.
2025
2026 =head2 Compiling and saving regular expressions
2027
2028 In Part 1 we discussed the C<//o> modifier, which compiles a regexp
2029 just once.  This suggests that a compiled regexp is some data structure
2030 that can be stored once and used again and again.  The regexp quote
2031 C<qr//> does exactly that: C<qr/string/> compiles the C<string> as a
2032 regexp and transforms the result into a form that can be assigned to a
2033 variable:
2034
2035     $reg = qr/foo+bar?/;  # reg contains a compiled regexp
2036
2037 Then C<$reg> can be used as a regexp:
2038
2039     $x = "fooooba";
2040     $x =~ $reg;     # matches, just like /foo+bar?/
2041     $x =~ /$reg/;   # same thing, alternate form
2042
2043 C<$reg> can also be interpolated into a larger regexp:
2044
2045     $x =~ /(abc)?$reg/;  # still matches
2046
2047 As with the matching operator, the regexp quote can use different
2048 delimiters, e.g., C<qr!!>, C<qr{}> or C<qr~~>.  Apostrophes
2049 as delimiters (C<qr''>) inhibit any interpolation.
2050
2051 Pre-compiled regexps are useful for creating dynamic matches that
2052 don't need to be recompiled each time they are encountered.  Using
2053 pre-compiled regexps, we write a C<grep_step> program which greps
2054 for a sequence of patterns, advancing to the next pattern as soon
2055 as one has been satisfied.
2056
2057     % cat > grep_step
2058     #!/usr/bin/perl
2059     # grep_step - match <number> regexps, one after the other
2060     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2061
2062     $number = shift;
2063     $regexp[$_] = shift foreach (0..$number-1);
2064     @compiled = map qr/$_/, @regexp;
2065     while ($line = <>) {
2066         if ($line =~ /$compiled[0]/) {
2067             print $line;
2068             shift @compiled;
2069             last unless @compiled;
2070         }
2071     }
2072     ^D
2073
2074     % grep_step 3 shift print last grep_step
2075     $number = shift;
2076             print $line;
2077             last unless @compiled;
2078
2079 Storing pre-compiled regexps in an array C<@compiled> allows us to
2080 simply loop through the regexps without any recompilation, thus gaining
2081 flexibility without sacrificing speed.
2082
2083
2084 =head2 Composing regular expressions at runtime
2085
2086 Backtracking is more efficient than repeated tries with different regular
2087 expressions.  If there are several regular expressions and a match with
2088 any of them is acceptable, then it is possible to combine them into a set
2089 of alternatives.  If the individual expressions are input data, this
2090 can be done by programming a join operation.  We'll exploit this idea in
2091 an improved version of the C<simple_grep> program: a program that matches
2092 multiple patterns:
2093
2094     % cat > multi_grep
2095     #!/usr/bin/perl
2096     # multi_grep - match any of <number> regexps
2097     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2098
2099     $number = shift;
2100     $regexp[$_] = shift foreach (0..$number-1);
2101     $pattern = join '|', @regexp;
2102
2103     while ($line = <>) {
2104         print $line if $line =~ /$pattern/o;
2105     }
2106     ^D
2107
2108     % multi_grep 2 shift for multi_grep
2109     $number = shift;
2110     $regexp[$_] = shift foreach (0..$number-1);
2111
2112 Sometimes it is advantageous to construct a pattern from the I<input>
2113 that is to be analyzed and use the permissible values on the left
2114 hand side of the matching operations.  As an example for this somewhat
2115 paradoxical situation, let's assume that our input contains a command
2116 verb which should match one out of a set of available command verbs,
2117 with the additional twist that commands may be abbreviated as long as
2118 the given string is unique. The program below demonstrates the basic
2119 algorithm.
2120
2121     % cat > keymatch
2122     #!/usr/bin/perl
2123     $kwds = 'copy compare list print';
2124     while( $command = <> ){
2125         $command =~ s/^\s+|\s+$//g;  # trim leading and trailing spaces
2126         if( ( @matches = $kwds =~ /\b$command\w*/g ) == 1 ){
2127             print "command: '@matches'\n";
2128         } elsif( @matches == 0 ){
2129             print "no such command: '$command'\n";
2130         } else {
2131             print "not unique: '$command' (could be one of: @matches)\n";
2132         }
2133     }
2134     ^D
2135
2136     % keymatch
2137     li
2138     command: 'list'
2139     co
2140     not unique: 'co' (could be one of: copy compare)
2141     printer
2142     no such command: 'printer'
2143
2144 Rather than trying to match the input against the keywords, we match the
2145 combined set of keywords against the input.  The pattern matching
2146 operation S<C<$kwds =~ /\b($command\w*)/g>> does several things at the
2147 same time. It makes sure that the given command begins where a keyword
2148 begins (C<\b>). It tolerates abbreviations due to the added C<\w*>. It
2149 tells us the number of matches (C<scalar @matches>) and all the keywords
2150 that were actually matched.  You could hardly ask for more.
2151
2152 =head2 Embedding comments and modifiers in a regular expression
2153
2154 Starting with this section, we will be discussing Perl's set of
2155 I<extended patterns>.  These are extensions to the traditional regular
2156 expression syntax that provide powerful new tools for pattern
2157 matching.  We have already seen extensions in the form of the minimal
2158 matching constructs C<??>, C<*?>, C<+?>, C<{n,m}?>, and C<{n,}?>.  The
2159 rest of the extensions below have the form C<(?char...)>, where the
2160 C<char> is a character that determines the type of extension.
2161
2162 The first extension is an embedded comment C<(?#text)>.  This embeds a
2163 comment into the regular expression without affecting its meaning.  The
2164 comment should not have any closing parentheses in the text.  An
2165 example is
2166
2167     /(?# Match an integer:)[+-]?\d+/;
2168
2169 This style of commenting has been largely superseded by the raw,
2170 freeform commenting that is allowed with the C<//x> modifier.
2171
2172 The modifiers C<//i>, C<//m>, C<//s> and C<//x> (or any
2173 combination thereof) can also be embedded in
2174 a regexp using C<(?i)>, C<(?m)>, C<(?s)>, and C<(?x)>.  For instance,
2175
2176     /(?i)yes/;  # match 'yes' case insensitively
2177     /yes/i;     # same thing
2178     /(?x)(          # freeform version of an integer regexp
2179              [+-]?  # match an optional sign
2180              \d+    # match a sequence of digits
2181          )
2182     /x;
2183
2184 Embedded modifiers can have two important advantages over the usual
2185 modifiers.  Embedded modifiers allow a custom set of modifiers to
2186 I<each> regexp pattern.  This is great for matching an array of regexps
2187 that must have different modifiers:
2188
2189     $pattern[0] = '(?i)doctor';
2190     $pattern[1] = 'Johnson';
2191     ...
2192     while (<>) {
2193         foreach $patt (@pattern) {
2194             print if /$patt/;
2195         }
2196     }
2197
2198 The second advantage is that embedded modifiers (except C<//p>, which
2199 modifies the entire regexp) only affect the regexp
2200 inside the group the embedded modifier is contained in.  So grouping
2201 can be used to localize the modifier's effects:
2202
2203     /Answer: ((?i)yes)/;  # matches 'Answer: yes', 'Answer: YES', etc.
2204
2205 Embedded modifiers can also turn off any modifiers already present
2206 by using, e.g., C<(?-i)>.  Modifiers can also be combined into
2207 a single expression, e.g., C<(?s-i)> turns on single line mode and
2208 turns off case insensitivity.
2209
2210 Embedded modifiers may also be added to a non-capturing grouping.
2211 C<(?i-m:regexp)> is a non-capturing grouping that matches C<regexp>
2212 case insensitively and turns off multi-line mode.
2213
2214
2215 =head2 Looking ahead and looking behind
2216
2217 This section concerns the lookahead and lookbehind assertions.  First,
2218 a little background.
2219
2220 In Perl regular expressions, most regexp elements 'eat up' a certain
2221 amount of string when they match.  For instance, the regexp element
2222 C<[abc}]> eats up one character of the string when it matches, in the
2223 sense that Perl moves to the next character position in the string
2224 after the match.  There are some elements, however, that don't eat up
2225 characters (advance the character position) if they match.  The examples
2226 we have seen so far are the anchors.  The anchor C<^> matches the
2227 beginning of the line, but doesn't eat any characters.  Similarly, the
2228 word boundary anchor C<\b> matches wherever a character matching C<\w>
2229 is next to a character that doesn't, but it doesn't eat up any
2230 characters itself.  Anchors are examples of I<zero-width assertions>.
2231 Zero-width, because they consume
2232 no characters, and assertions, because they test some property of the
2233 string.  In the context of our walk in the woods analogy to regexp
2234 matching, most regexp elements move us along a trail, but anchors have
2235 us stop a moment and check our surroundings.  If the local environment
2236 checks out, we can proceed forward.  But if the local environment
2237 doesn't satisfy us, we must backtrack.
2238
2239 Checking the environment entails either looking ahead on the trail,
2240 looking behind, or both.  C<^> looks behind, to see that there are no
2241 characters before.  C<$> looks ahead, to see that there are no
2242 characters after.  C<\b> looks both ahead and behind, to see if the
2243 characters on either side differ in their "word-ness".
2244
2245 The lookahead and lookbehind assertions are generalizations of the
2246 anchor concept.  Lookahead and lookbehind are zero-width assertions
2247 that let us specify which characters we want to test for.  The
2248 lookahead assertion is denoted by C<(?=regexp)> and the lookbehind
2249 assertion is denoted by C<< (?<=fixed-regexp) >>.  Some examples are
2250
2251     $x = "I catch the housecat 'Tom-cat' with catnip";
2252     $x =~ /cat(?=\s)/;   # matches 'cat' in 'housecat'
2253     @catwords = ($x =~ /(?<=\s)cat\w+/g);  # matches,
2254                                            # $catwords[0] = 'catch'
2255                                            # $catwords[1] = 'catnip'
2256     $x =~ /\bcat\b/;  # matches 'cat' in 'Tom-cat'
2257     $x =~ /(?<=\s)cat(?=\s)/; # doesn't match; no isolated 'cat' in
2258                               # middle of $x
2259
2260 Note that the parentheses in C<(?=regexp)> and C<< (?<=regexp) >> are
2261 non-capturing, since these are zero-width assertions.  Thus in the
2262 second regexp, the substrings captured are those of the whole regexp
2263 itself.  Lookahead C<(?=regexp)> can match arbitrary regexps, but
2264 lookbehind C<< (?<=fixed-regexp) >> only works for regexps of fixed
2265 width, i.e., a fixed number of characters long.  Thus
2266 C<< (?<=(ab|bc)) >> is fine, but C<< (?<=(ab)*) >> is not.  The
2267 negated versions of the lookahead and lookbehind assertions are
2268 denoted by C<(?!regexp)> and C<< (?<!fixed-regexp) >> respectively.
2269 They evaluate true if the regexps do I<not> match:
2270
2271     $x = "foobar";
2272     $x =~ /foo(?!bar)/;  # doesn't match, 'bar' follows 'foo'
2273     $x =~ /foo(?!baz)/;  # matches, 'baz' doesn't follow 'foo'
2274     $x =~ /(?<!\s)foo/;  # matches, there is no \s before 'foo'
2275
2276 The C<\C> is unsupported in lookbehind, because the already
2277 treacherous definition of C<\C> would become even more so
2278 when going backwards.
2279
2280 Here is an example where a string containing blank-separated words,
2281 numbers and single dashes is to be split into its components.
2282 Using C</\s+/> alone won't work, because spaces are not required between
2283 dashes, or a word or a dash. Additional places for a split are established
2284 by looking ahead and behind:
2285
2286     $str = "one two - --6-8";
2287     @toks = split / \s+              # a run of spaces
2288                   | (?<=\S) (?=-)    # any non-space followed by '-'
2289                   | (?<=-)  (?=\S)   # a '-' followed by any non-space
2290                   /x, $str;          # @toks = qw(one two - - - 6 - 8)
2291
2292
2293 =head2 Using independent subexpressions to prevent backtracking
2294
2295 I<Independent subexpressions> are regular expressions, in the
2296 context of a larger regular expression, that function independently of
2297 the larger regular expression.  That is, they consume as much or as
2298 little of the string as they wish without regard for the ability of
2299 the larger regexp to match.  Independent subexpressions are represented
2300 by C<< (?>regexp) >>.  We can illustrate their behavior by first
2301 considering an ordinary regexp:
2302
2303     $x = "ab";
2304     $x =~ /a*ab/;  # matches
2305
2306 This obviously matches, but in the process of matching, the
2307 subexpression C<a*> first grabbed the C<a>.  Doing so, however,
2308 wouldn't allow the whole regexp to match, so after backtracking, C<a*>
2309 eventually gave back the C<a> and matched the empty string.  Here, what
2310 C<a*> matched was I<dependent> on what the rest of the regexp matched.
2311
2312 Contrast that with an independent subexpression:
2313
2314     $x =~ /(?>a*)ab/;  # doesn't match!
2315
2316 The independent subexpression C<< (?>a*) >> doesn't care about the rest
2317 of the regexp, so it sees an C<a> and grabs it.  Then the rest of the
2318 regexp C<ab> cannot match.  Because C<< (?>a*) >> is independent, there
2319 is no backtracking and the independent subexpression does not give
2320 up its C<a>.  Thus the match of the regexp as a whole fails.  A similar
2321 behavior occurs with completely independent regexps:
2322
2323     $x = "ab";
2324     $x =~ /a*/g;   # matches, eats an 'a'
2325     $x =~ /\Gab/g; # doesn't match, no 'a' available
2326
2327 Here C<//g> and C<\G> create a 'tag team' handoff of the string from
2328 one regexp to the other.  Regexps with an independent subexpression are
2329 much like this, with a handoff of the string to the independent
2330 subexpression, and a handoff of the string back to the enclosing
2331 regexp.
2332
2333 The ability of an independent subexpression to prevent backtracking
2334 can be quite useful.  Suppose we want to match a non-empty string
2335 enclosed in parentheses up to two levels deep.  Then the following
2336 regexp matches:
2337
2338     $x = "abc(de(fg)h";  # unbalanced parentheses
2339     $x =~ /\( ( [^()]+ | \([^()]*\) )+ \)/x;
2340
2341 The regexp matches an open parenthesis, one or more copies of an
2342 alternation, and a close parenthesis.  The alternation is two-way, with
2343 the first alternative C<[^()]+> matching a substring with no
2344 parentheses and the second alternative C<\([^()]*\)>  matching a
2345 substring delimited by parentheses.  The problem with this regexp is
2346 that it is pathological: it has nested indeterminate quantifiers
2347 of the form C<(a+|b)+>.  We discussed in Part 1 how nested quantifiers
2348 like this could take an exponentially long time to execute if there
2349 was no match possible.  To prevent the exponential blowup, we need to
2350 prevent useless backtracking at some point.  This can be done by
2351 enclosing the inner quantifier as an independent subexpression:
2352
2353     $x =~ /\( ( (?>[^()]+) | \([^()]*\) )+ \)/x;
2354
2355 Here, C<< (?>[^()]+) >> breaks the degeneracy of string partitioning
2356 by gobbling up as much of the string as possible and keeping it.   Then
2357 match failures fail much more quickly.
2358
2359
2360 =head2 Conditional expressions
2361
2362 A I<conditional expression> is a form of if-then-else statement
2363 that allows one to choose which patterns are to be matched, based on
2364 some condition.  There are two types of conditional expression:
2365 C<(?(condition)yes-regexp)> and
2366 C<(?(condition)yes-regexp|no-regexp)>.  C<(?(condition)yes-regexp)> is
2367 like an S<C<'if () {}'>> statement in Perl.  If the C<condition> is true,
2368 the C<yes-regexp> will be matched.  If the C<condition> is false, the
2369 C<yes-regexp> will be skipped and Perl will move onto the next regexp
2370 element.  The second form is like an S<C<'if () {} else {}'>> statement
2371 in Perl.  If the C<condition> is true, the C<yes-regexp> will be
2372 matched, otherwise the C<no-regexp> will be matched.
2373
2374 The C<condition> can have several forms.  The first form is simply an
2375 integer in parentheses C<(integer)>.  It is true if the corresponding
2376 backreference C<\integer> matched earlier in the regexp.  The same
2377 thing can be done with a name associated with a capture group, written
2378 as C<< (<name>) >> or C<< ('name') >>.  The second form is a bare
2379 zero width assertion C<(?...)>, either a lookahead, a lookbehind, or a
2380 code assertion (discussed in the next section).  The third set of forms
2381 provides tests that return true if the expression is executed within
2382 a recursion (C<(R)>) or is being called from some capturing group,
2383 referenced either by number (C<(R1)>, C<(R2)>,...) or by name
2384 (C<(R&name)>).
2385
2386 The integer or name form of the C<condition> allows us to choose,
2387 with more flexibility, what to match based on what matched earlier in the
2388 regexp. This searches for words of the form C<"$x$x"> or C<"$x$y$y$x">:
2389
2390     % simple_grep '^(\w+)(\w+)?(?(2)\g2\g1|\g1)$' /usr/dict/words
2391     beriberi
2392     coco
2393     couscous
2394     deed
2395     ...
2396     toot
2397     toto
2398     tutu
2399
2400 The lookbehind C<condition> allows, along with backreferences,
2401 an earlier part of the match to influence a later part of the
2402 match.  For instance,
2403
2404     /[ATGC]+(?(?<=AA)G|C)$/;
2405
2406 matches a DNA sequence such that it either ends in C<AAG>, or some
2407 other base pair combination and C<C>.  Note that the form is
2408 C<< (?(?<=AA)G|C) >> and not C<< (?((?<=AA))G|C) >>; for the
2409 lookahead, lookbehind or code assertions, the parentheses around the
2410 conditional are not needed.
2411
2412
2413 =head2 Defining named patterns
2414
2415 Some regular expressions use identical subpatterns in several places.
2416 Starting with Perl 5.10, it is possible to define named subpatterns in
2417 a section of the pattern so that they can be called up by name
2418 anywhere in the pattern.  This syntactic pattern for this definition
2419 group is C<< (?(DEFINE)(?<name>pattern)...) >>.  An insertion
2420 of a named pattern is written as C<(?&name)>.
2421
2422 The example below illustrates this feature using the pattern for
2423 floating point numbers that was presented earlier on.  The three
2424 subpatterns that are used more than once are the optional sign, the
2425 digit sequence for an integer and the decimal fraction.  The DEFINE
2426 group at the end of the pattern contains their definition.  Notice
2427 that the decimal fraction pattern is the first place where we can
2428 reuse the integer pattern.
2429
2430    /^ (?&osg)\ * ( (?&int)(?&dec)? | (?&dec) )
2431       (?: [eE](?&osg)(?&int) )?
2432     $
2433     (?(DEFINE)
2434       (?<osg>[-+]?)         # optional sign
2435       (?<int>\d++)          # integer
2436       (?<dec>\.(?&int))     # decimal fraction
2437     )/x
2438
2439
2440 =head2 Recursive patterns
2441
2442 This feature (introduced in Perl 5.10) significantly extends the
2443 power of Perl's pattern matching.  By referring to some other
2444 capture group anywhere in the pattern with the construct
2445 C<(?group-ref)>, the I<pattern> within the referenced group is used
2446 as an independent subpattern in place of the group reference itself.
2447 Because the group reference may be contained I<within> the group it
2448 refers to, it is now possible to apply pattern matching to tasks that
2449 hitherto required a recursive parser.
2450
2451 To illustrate this feature, we'll design a pattern that matches if
2452 a string contains a palindrome. (This is a word or a sentence that,
2453 while ignoring spaces, interpunctuation and case, reads the same backwards
2454 as forwards. We begin by observing that the empty string or a string
2455 containing just one word character is a palindrome. Otherwise it must
2456 have a word character up front and the same at its end, with another
2457 palindrome in between.
2458
2459     /(?: (\w) (?...Here be a palindrome...) \g{-1} | \w? )/x
2460
2461 Adding C<\W*> at either end to eliminate what is to be ignored, we already
2462 have the full pattern:
2463
2464     my $pp = qr/^(\W* (?: (\w) (?1) \g{-1} | \w? ) \W*)$/ix;
2465     for $s ( "saippuakauppias", "A man, a plan, a canal: Panama!" ){
2466         print "'$s' is a palindrome\n" if $s =~ /$pp/;
2467     }
2468
2469 In C<(?...)> both absolute and relative backreferences may be used.
2470 The entire pattern can be reinserted with C<(?R)> or C<(?0)>.
2471 If you prefer to name your groups, you can use C<(?&name)> to
2472 recurse into that group.
2473
2474
2475 =head2 A bit of magic: executing Perl code in a regular expression
2476
2477 Normally, regexps are a part of Perl expressions.
2478 I<Code evaluation> expressions turn that around by allowing
2479 arbitrary Perl code to be a part of a regexp.  A code evaluation
2480 expression is denoted C<(?{code})>, with I<code> a string of Perl
2481 statements.
2482
2483 Be warned that this feature is considered experimental, and may be
2484 changed without notice.
2485
2486 Code expressions are zero-width assertions, and the value they return
2487 depends on their environment.  There are two possibilities: either the
2488 code expression is used as a conditional in a conditional expression
2489 C<(?(condition)...)>, or it is not.  If the code expression is a
2490 conditional, the code is evaluated and the result (i.e., the result of
2491 the last statement) is used to determine truth or falsehood.  If the
2492 code expression is not used as a conditional, the assertion always
2493 evaluates true and the result is put into the special variable
2494 C<$^R>.  The variable C<$^R> can then be used in code expressions later
2495 in the regexp.  Here are some silly examples:
2496
2497     $x = "abcdef";
2498     $x =~ /abc(?{print "Hi Mom!";})def/; # matches,
2499                                          # prints 'Hi Mom!'
2500     $x =~ /aaa(?{print "Hi Mom!";})def/; # doesn't match,
2501                                          # no 'Hi Mom!'
2502
2503 Pay careful attention to the next example:
2504
2505     $x =~ /abc(?{print "Hi Mom!";})ddd/; # doesn't match,
2506                                          # no 'Hi Mom!'
2507                                          # but why not?
2508
2509 At first glance, you'd think that it shouldn't print, because obviously
2510 the C<ddd> isn't going to match the target string. But look at this
2511 example:
2512
2513     $x =~ /abc(?{print "Hi Mom!";})[dD]dd/; # doesn't match,
2514                                             # but _does_ print
2515
2516 Hmm. What happened here? If you've been following along, you know that
2517 the above pattern should be effectively (almost) the same as the last one;
2518 enclosing the C<d> in a character class isn't going to change what it
2519 matches. So why does the first not print while the second one does?
2520
2521 The answer lies in the optimizations the regex engine makes. In the first
2522 case, all the engine sees are plain old characters (aside from the
2523 C<?{}> construct). It's smart enough to realize that the string 'ddd'
2524 doesn't occur in our target string before actually running the pattern
2525 through. But in the second case, we've tricked it into thinking that our
2526 pattern is more complicated. It takes a look, sees our
2527 character class, and decides that it will have to actually run the
2528 pattern to determine whether or not it matches, and in the process of
2529 running it hits the print statement before it discovers that we don't
2530 have a match.
2531
2532 To take a closer look at how the engine does optimizations, see the
2533 section L<"Pragmas and debugging"> below.
2534
2535 More fun with C<?{}>:
2536
2537     $x =~ /(?{print "Hi Mom!";})/;       # matches,
2538                                          # prints 'Hi Mom!'
2539     $x =~ /(?{$c = 1;})(?{print "$c";})/;  # matches,
2540                                            # prints '1'
2541     $x =~ /(?{$c = 1;})(?{print "$^R";})/; # matches,
2542                                            # prints '1'
2543
2544 The bit of magic mentioned in the section title occurs when the regexp
2545 backtracks in the process of searching for a match.  If the regexp
2546 backtracks over a code expression and if the variables used within are
2547 localized using C<local>, the changes in the variables produced by the
2548 code expression are undone! Thus, if we wanted to count how many times
2549 a character got matched inside a group, we could use, e.g.,
2550
2551     $x = "aaaa";
2552     $count = 0;  # initialize 'a' count
2553     $c = "bob";  # test if $c gets clobbered
2554     $x =~ /(?{local $c = 0;})         # initialize count
2555            ( a                        # match 'a'
2556              (?{local $c = $c + 1;})  # increment count
2557            )*                         # do this any number of times,
2558            aa                         # but match 'aa' at the end
2559            (?{$count = $c;})          # copy local $c var into $count
2560           /x;
2561     print "'a' count is $count, \$c variable is '$c'\n";
2562
2563 This prints
2564
2565     'a' count is 2, $c variable is 'bob'
2566
2567 If we replace the S<C< (?{local $c = $c + 1;})>> with
2568 S<C< (?{$c = $c + 1;})>>, the variable changes are I<not> undone
2569 during backtracking, and we get
2570
2571     'a' count is 4, $c variable is 'bob'
2572
2573 Note that only localized variable changes are undone.  Other side
2574 effects of code expression execution are permanent.  Thus
2575
2576     $x = "aaaa";
2577     $x =~ /(a(?{print "Yow\n";}))*aa/;
2578
2579 produces
2580
2581    Yow
2582    Yow
2583    Yow
2584    Yow
2585
2586 The result C<$^R> is automatically localized, so that it will behave
2587 properly in the presence of backtracking.
2588
2589 This example uses a code expression in a conditional to match a
2590 definite article, either 'the' in English or 'der|die|das' in German:
2591
2592     $lang = 'DE';  # use German
2593     ...
2594     $text = "das";
2595     print "matched\n"
2596         if $text =~ /(?(?{
2597                           $lang eq 'EN'; # is the language English?
2598                          })
2599                        the |             # if so, then match 'the'
2600                        (der|die|das)     # else, match 'der|die|das'
2601                      )
2602                     /xi;
2603
2604 Note that the syntax here is C<(?(?{...})yes-regexp|no-regexp)>, not
2605 C<(?((?{...}))yes-regexp|no-regexp)>.  In other words, in the case of a
2606 code expression, we don't need the extra parentheses around the
2607 conditional.
2608
2609 If you try to use code expressions with interpolating variables, Perl
2610 may surprise you:
2611
2612     $bar = 5;
2613     $pat = '(?{ 1 })';
2614     /foo(?{ $bar })bar/; # compiles ok, $bar not interpolated
2615     /foo(?{ 1 })$bar/;   # compile error!
2616     /foo${pat}bar/;      # compile error!
2617
2618     $pat = qr/(?{ $foo = 1 })/;  # precompile code regexp
2619     /foo${pat}bar/;      # compiles ok
2620
2621 If a regexp has (1) code expressions and interpolating variables, or
2622 (2) a variable that interpolates a code expression, Perl treats the
2623 regexp as an error. If the code expression is precompiled into a
2624 variable, however, interpolating is ok. The question is, why is this
2625 an error?
2626
2627 The reason is that variable interpolation and code expressions
2628 together pose a security risk.  The combination is dangerous because
2629 many programmers who write search engines often take user input and
2630 plug it directly into a regexp:
2631
2632     $regexp = <>;       # read user-supplied regexp
2633     $chomp $regexp;     # get rid of possible newline
2634     $text =~ /$regexp/; # search $text for the $regexp
2635
2636 If the C<$regexp> variable contains a code expression, the user could
2637 then execute arbitrary Perl code.  For instance, some joker could
2638 search for S<C<system('rm -rf *');>> to erase your files.  In this
2639 sense, the combination of interpolation and code expressions I<taints>
2640 your regexp.  So by default, using both interpolation and code
2641 expressions in the same regexp is not allowed.  If you're not
2642 concerned about malicious users, it is possible to bypass this
2643 security check by invoking S<C<use re 'eval'>>:
2644
2645     use re 'eval';       # throw caution out the door
2646     $bar = 5;
2647     $pat = '(?{ 1 })';
2648     /foo(?{ 1 })$bar/;   # compiles ok
2649     /foo${pat}bar/;      # compiles ok
2650
2651 Another form of code expression is the I<pattern code expression>.
2652 The pattern code expression is like a regular code expression, except
2653 that the result of the code evaluation is treated as a regular
2654 expression and matched immediately.  A simple example is
2655
2656     $length = 5;
2657     $char = 'a';
2658     $x = 'aaaaabb';
2659     $x =~ /(??{$char x $length})/x; # matches, there are 5 of 'a'
2660
2661
2662 This final example contains both ordinary and pattern code
2663 expressions.  It detects whether a binary string C<1101010010001...> has a
2664 Fibonacci spacing 0,1,1,2,3,5,...  of the C<1>'s:
2665
2666     $x = "1101010010001000001";
2667     $z0 = ''; $z1 = '0';   # initial conditions
2668     print "It is a Fibonacci sequence\n"
2669         if $x =~ /^1         # match an initial '1'
2670                     (?:
2671                        ((??{ $z0 })) # match some '0'
2672                        1             # and then a '1'
2673                        (?{ $z0 = $z1; $z1 .= $^N; })
2674                     )+   # repeat as needed
2675                   $      # that is all there is
2676                  /x;
2677     printf "Largest sequence matched was %d\n", length($z1)-length($z0);
2678
2679 Remember that C<$^N> is set to whatever was matched by the last
2680 completed capture group. This prints
2681
2682     It is a Fibonacci sequence
2683     Largest sequence matched was 5
2684
2685 Ha! Try that with your garden variety regexp package...
2686
2687 Note that the variables C<$z0> and C<$z1> are not substituted when the
2688 regexp is compiled, as happens for ordinary variables outside a code
2689 expression.  Rather, the code expressions are evaluated when Perl
2690 encounters them during the search for a match.
2691
2692 The regexp without the C<//x> modifier is
2693
2694     /^1(?:((??{ $z0 }))1(?{ $z0 = $z1; $z1 .= $^N; }))+$/
2695
2696 which shows that spaces are still possible in the code parts. Nevertheless,
2697 when working with code and conditional expressions, the extended form of
2698 regexps is almost necessary in creating and debugging regexps.
2699
2700
2701 =head2 Backtracking control verbs
2702
2703 Perl 5.10 introduced a number of control verbs intended to provide
2704 detailed control over the backtracking process, by directly influencing
2705 the regexp engine and by providing monitoring techniques.  As all
2706 the features in this group are experimental and subject to change or
2707 removal in a future version of Perl, the interested reader is
2708 referred to L<perlre/"Special Backtracking Control Verbs"> for a
2709 detailed description.
2710
2711 Below is just one example, illustrating the control verb C<(*FAIL)>,
2712 which may be abbreviated as C<(*F)>. If this is inserted in a regexp
2713 it will cause to fail, just like at some mismatch between the pattern
2714 and the string. Processing of the regexp continues like after any "normal"
2715 failure, so that, for instance, the next position in the string or another
2716 alternative will be tried. As failing to match doesn't preserve capture
2717 groups or produce results, it may be necessary to use this in
2718 combination with embedded code.
2719
2720    %count = ();
2721    "supercalifragilisticexpialidoceous" =~
2722        /([aeiou])(?{ $count{$1}++; })(*FAIL)/oi;
2723    printf "%3d '%s'\n", $count{$_}, $_ for (sort keys %count);
2724
2725 The pattern begins with a class matching a subset of letters.  Whenever
2726 this matches, a statement like C<$count{'a'}++;> is executed, incrementing
2727 the letter's counter. Then C<(*FAIL)> does what it says, and
2728 the regexp  engine proceeds according to the book: as long as the end of
2729 the string  hasn't been reached, the position is advanced before looking
2730 for another vowel. Thus, match or no match makes no difference, and the
2731 regexp engine proceeds until the entire string has been inspected.
2732 (It's remarkable that an alternative solution using something like
2733
2734    $count{lc($_)}++ for split('', "supercalifragilisticexpialidoceous");
2735    printf "%3d '%s'\n", $count2{$_}, $_ for ( qw{ a e i o u } );
2736
2737 is considerably slower.)
2738
2739
2740 =head2 Pragmas and debugging
2741
2742 Speaking of debugging, there are several pragmas available to control
2743 and debug regexps in Perl.  We have already encountered one pragma in
2744 the previous section, S<C<use re 'eval';>>, that allows variable
2745 interpolation and code expressions to coexist in a regexp.  The other
2746 pragmas are
2747
2748     use re 'taint';
2749     $tainted = <>;
2750     @parts = ($tainted =~ /(\w+)\s+(\w+)/; # @parts is now tainted
2751
2752 The C<taint> pragma causes any substrings from a match with a tainted
2753 variable to be tainted as well.  This is not normally the case, as
2754 regexps are often used to extract the safe bits from a tainted
2755 variable.  Use C<taint> when you are not extracting safe bits, but are
2756 performing some other processing.  Both C<taint> and C<eval> pragmas
2757 are lexically scoped, which means they are in effect only until
2758 the end of the block enclosing the pragmas.
2759
2760     use re 'debug';
2761     /^(.*)$/s;       # output debugging info
2762
2763     use re 'debugcolor';
2764     /^(.*)$/s;       # output debugging info in living color
2765
2766 The global C<debug> and C<debugcolor> pragmas allow one to get
2767 detailed debugging info about regexp compilation and
2768 execution.  C<debugcolor> is the same as debug, except the debugging
2769 information is displayed in color on terminals that can display
2770 termcap color sequences.  Here is example output:
2771
2772     % perl -e 'use re "debug"; "abc" =~ /a*b+c/;'
2773     Compiling REx `a*b+c'
2774     size 9 first at 1
2775        1: STAR(4)
2776        2:   EXACT <a>(0)
2777        4: PLUS(7)
2778        5:   EXACT <b>(0)
2779        7: EXACT <c>(9)
2780        9: END(0)
2781     floating `bc' at 0..2147483647 (checking floating) minlen 2
2782     Guessing start of match, REx `a*b+c' against `abc'...
2783     Found floating substr `bc' at offset 1...
2784     Guessed: match at offset 0
2785     Matching REx `a*b+c' against `abc'
2786       Setting an EVAL scope, savestack=3
2787        0 <> <abc>             |  1:  STAR
2788                                EXACT <a> can match 1 times out of 32767...
2789       Setting an EVAL scope, savestack=3
2790        1 <a> <bc>             |  4:    PLUS
2791                                EXACT <b> can match 1 times out of 32767...
2792       Setting an EVAL scope, savestack=3
2793        2 <ab> <c>             |  7:      EXACT <c>
2794        3 <abc> <>             |  9:      END
2795     Match successful!
2796     Freeing REx: `a*b+c'
2797
2798 If you have gotten this far into the tutorial, you can probably guess
2799 what the different parts of the debugging output tell you.  The first
2800 part
2801
2802     Compiling REx `a*b+c'
2803     size 9 first at 1
2804        1: STAR(4)
2805        2:   EXACT <a>(0)
2806        4: PLUS(7)
2807        5:   EXACT <b>(0)
2808        7: EXACT <c>(9)
2809        9: END(0)
2810
2811 describes the compilation stage.  C<STAR(4)> means that there is a
2812 starred object, in this case C<'a'>, and if it matches, goto line 4,
2813 i.e., C<PLUS(7)>.  The middle lines describe some heuristics and
2814 optimizations performed before a match:
2815
2816     floating `bc' at 0..2147483647 (checking floating) minlen 2
2817     Guessing start of match, REx `a*b+c' against `abc'...
2818     Found floating substr `bc' at offset 1...
2819     Guessed: match at offset 0
2820
2821 Then the match is executed and the remaining lines describe the
2822 process:
2823
2824     Matching REx `a*b+c' against `abc'
2825       Setting an EVAL scope, savestack=3
2826        0 <> <abc>             |  1:  STAR
2827                                EXACT <a> can match 1 times out of 32767...
2828       Setting an EVAL scope, savestack=3
2829        1 <a> <bc>             |  4:    PLUS
2830                                EXACT <b> can match 1 times out of 32767...
2831       Setting an EVAL scope, savestack=3
2832        2 <ab> <c>             |  7:      EXACT <c>
2833        3 <abc> <>             |  9:      END
2834     Match successful!
2835     Freeing REx: `a*b+c'
2836
2837 Each step is of the form S<C<< n <x> <y> >>>, with C<< <x> >> the
2838 part of the string matched and C<< <y> >> the part not yet
2839 matched.  The S<C<< |  1:  STAR >>> says that Perl is at line number 1
2840 n the compilation list above.  See
2841 L<perldebguts/"Debugging Regular Expressions"> for much more detail.
2842
2843 An alternative method of debugging regexps is to embed C<print>
2844 statements within the regexp.  This provides a blow-by-blow account of
2845 the backtracking in an alternation:
2846
2847     "that this" =~ m@(?{print "Start at position ", pos, "\n";})
2848                      t(?{print "t1\n";})
2849                      h(?{print "h1\n";})
2850                      i(?{print "i1\n";})
2851                      s(?{print "s1\n";})
2852                          |
2853                      t(?{print "t2\n";})
2854                      h(?{print "h2\n";})
2855                      a(?{print "a2\n";})
2856                      t(?{print "t2\n";})
2857                      (?{print "Done at position ", pos, "\n";})
2858                     @x;
2859
2860 prints
2861
2862     Start at position 0
2863     t1
2864     h1
2865     t2
2866     h2
2867     a2
2868     t2
2869     Done at position 4
2870
2871 =head1 BUGS
2872
2873 Code expressions, conditional expressions, and independent expressions
2874 are I<experimental>.  Don't use them in production code.  Yet.
2875
2876 =head1 SEE ALSO
2877
2878 This is just a tutorial.  For the full story on Perl regular
2879 expressions, see the L<perlre> regular expressions reference page.
2880
2881 For more information on the matching C<m//> and substitution C<s///>
2882 operators, see L<perlop/"Regexp Quote-Like Operators">.  For
2883 information on the C<split> operation, see L<perlfunc/split>.
2884
2885 For an excellent all-around resource on the care and feeding of
2886 regular expressions, see the book I<Mastering Regular Expressions> by
2887 Jeffrey Friedl (published by O'Reilly, ISBN 1556592-257-3).
2888
2889 =head1 AUTHOR AND COPYRIGHT
2890
2891 Copyright (c) 2000 Mark Kvale
2892 All rights reserved.
2893
2894 This document may be distributed under the same terms as Perl itself.
2895
2896 =head2 Acknowledgments
2897
2898 The inspiration for the stop codon DNA example came from the ZIP
2899 code example in chapter 7 of I<Mastering Regular Expressions>.
2900
2901 The author would like to thank Jeff Pinyan, Andrew Johnson, Peter
2902 Haworth, Ronald J Kimball, and Joe Smith for all their helpful
2903 comments.
2904
2905 =cut
2906