This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
PATCH: [perl #132851] Empty /(?)/
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a tutorial introduction
11 is available in L<perlretut>.  If you know just a little about them,
12 a quick-start introduction is available in L<perlrequick>.
13
14 Except for L</The Basics> section, this page assumes you are familiar
15 with regular expression basics, like what is a "pattern", what does it
16 look like, and how it is basically used.  For a reference on how they
17 are used, plus various examples of the same, see discussions of C<m//>,
18 C<s///>, C<qr//> and C<"??"> in L<perlop/"Regexp Quote-Like Operators">.
19
20 New in v5.22, L<C<use re 'strict'>|re/'strict' mode> applies stricter
21 rules than otherwise when compiling regular expression patterns.  It can
22 find things that, while legal, may not be what you intended.
23
24 =head2 The Basics
25 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
26
27 Regular expressions are strings with the very particular syntax and
28 meaning described in this document and auxiliary documents referred to
29 by this one.  The strings are called "patterns".  Patterns are used to
30 determine if some other string, called the "target", has (or doesn't
31 have) the characteristics specified by the pattern.  We call this
32 "matching" the target string against the pattern.  Usually the match is
33 done by having the target be the first operand, and the pattern be the
34 second operand, of one of the two binary operators C<=~> and C<!~>,
35 listed in L<perlop/Binding Operators>; and the pattern will have been
36 converted from an ordinary string by one of the operators in
37 L<perlop/"Regexp Quote-Like Operators">, like so:
38
39  $foo =~ m/abc/
40
41 This evaluates to true if and only if the string in the variable C<$foo>
42 contains somewhere in it, the sequence of characters "a", "b", then "c".
43 (The C<=~ m>, or match operator, is described in
44 L<perlop/m/PATTERN/msixpodualngc>.)
45
46 Patterns that aren't already stored in some variable must be delimitted,
47 at both ends, by delimitter characters.  These are often, as in the
48 example above, forward slashes, and the typical way a pattern is written
49 in documentation is with those slashes.  In most cases, the delimitter
50 is the same character, fore and aft, but there are a few cases where a
51 character looks like it has a mirror-image mate, where the opening
52 version is the beginning delimiter, and the closing one is the ending
53 delimiter, like
54
55  $foo =~ m<abc>
56
57 Most times, the pattern is evaluated in double-quotish context, but it
58 is possible to choose delimiters to force single-quotish, like
59
60  $foo =~ m'abc'
61
62 If the pattern contains its delimiter within it, that delimiter must be
63 escaped.  Prefixing it with a backslash (I<e.g.>, C<"/foo\/bar/">)
64 serves this purpose.
65
66 Any single character in a pattern matches that same character in the
67 target string, unless the character is a I<metacharacter> with a special
68 meaning described in this document.  A sequence of non-metacharacters
69 matches the same sequence in the target string, as we saw above with
70 C<m/abc/>.
71
72 Only a few characters (all of them being ASCII punctuation characters)
73 are metacharacters.  The most commonly used one is a dot C<".">, which
74 normally matches almost any character (including a dot itself).
75
76 You can cause characters that normally function as metacharacters to be
77 interpreted literally by prefixing them with a C<"\">, just like the
78 pattern's delimiter must be escaped if it also occurs within the
79 pattern.  Thus, C<"\."> matches just a literal dot, C<"."> instead of
80 its normal meaning.  This means that the backslash is also a
81 metacharacter, so C<"\\"> matches a single C<"\">.  And a sequence that
82 contains an escaped metacharacter matches the same sequence (but without
83 the escape) in the target string.  So, the pattern C</blur\\fl/> would
84 match any target string that contains the sequence C<"blur\fl">.
85
86 The metacharacter C<"|"> is used to match one thing or another.  Thus
87
88  $foo =~ m/this|that/
89
90 is TRUE if and only if C<$foo> contains either the sequence C<"this"> or
91 the sequence C<"that">.  Like all metacharacters, prefixing the C<"|">
92 with a backslash makes it match the plain punctuation character; in its
93 case, the VERTICAL LINE.
94
95  $foo =~ m/this\|that/
96
97 is TRUE if and only if C<$foo> contains the sequence C<"this|that">.
98
99 You aren't limited to just a single C<"|">.
100
101  $foo =~ m/fee|fie|foe|fum/
102
103 is TRUE if and only if C<$foo> contains any of those 4 sequences from
104 the children's story "Jack and the Beanstalk".
105
106 As you can see, the C<"|"> binds less tightly than a sequence of
107 ordinary characters.  We can override this by using the grouping
108 metacharacters, the parentheses C<"("> and C<")">.
109
110  $foo =~ m/th(is|at) thing/
111
112 is TRUE if and only if C<$foo> contains either the sequence S<C<"this
113 thing">> or the sequence S<C<"that thing">>.  The portions of the string
114 that match the portions of the pattern enclosed in parentheses are
115 normally made available separately for use later in the pattern,
116 substitution, or program.  This is called "capturing", and it can get
117 complicated.  See L</Capture groups>.
118
119 The first alternative includes everything from the last pattern
120 delimiter (C<"(">, C<"(?:"> (described later), I<etc>. or the beginning
121 of the pattern) up to the first C<"|">, and the last alternative
122 contains everything from the last C<"|"> to the next closing pattern
123 delimiter.  That's why it's common practice to include alternatives in
124 parentheses: to minimize confusion about where they start and end.
125
126 Alternatives are tried from left to right, so the first
127 alternative found for which the entire expression matches, is the one that
128 is chosen. This means that alternatives are not necessarily greedy. For
129 example: when matching C<foo|foot> against C<"barefoot">, only the C<"foo">
130 part will match, as that is the first alternative tried, and it successfully
131 matches the target string. (This might not seem important, but it is
132 important when you are capturing matched text using parentheses.)
133
134 Besides taking away the special meaning of a metacharacter, a prefixed
135 backslash changes some letter and digit characters away from matching
136 just themselves to instead have special meaning.  These are called
137 "escape sequences", and all such are described in L<perlrebackslash>.  A
138 backslash sequence (of a letter or digit) that doesn't currently have
139 special meaning to Perl will raise a warning if warnings are enabled,
140 as those are reserved for potential future use.
141
142 One such sequence is C<\b>, which matches a boundary of some sort.
143 C<\b{wb}> and a few others give specialized types of boundaries.
144 (They are all described in detail starting at
145 L<perlrebackslash/\b{}, \b, \B{}, \B>.)  Note that these don't match
146 characters, but the zero-width spaces between characters.  They are an
147 example of a L<zero-width assertion|/Assertions>.  Consider again,
148
149  $foo =~ m/fee|fie|foe|fum/
150
151 It evaluates to TRUE if, besides those 4 words, any of the sequences
152 "feed", "field", "Defoe", "fume", and many others are in C<$foo>.  By
153 judicious use of C<\b> (or better (because it is designed to handle
154 natural language) C<\b{wb}>), we can make sure that only the Giant's
155 words are matched:
156
157  $foo =~ m/\b(fee|fie|foe|fum)\b/
158  $foo =~ m/\b{wb}(fee|fie|foe|fum)\b{wb}/
159
160 The final example shows that the characters C<"{"> and C<"}"> are
161 metacharacters.
162
163 Another use for escape sequences is to specify characters that cannot
164 (or which you prefer not to) be written literally.  These are described
165 in detail in L<perlrebackslash/Character Escapes>, but the next three
166 paragraphs briefly describe some of them.
167
168 Various control characters can be written in C language style: C<"\n">
169 matches a newline, C<"\t"> a tab, C<"\r"> a carriage return, C<"\f"> a
170 form feed, I<etc>.
171
172 More generally, C<\I<nnn>>, where I<nnn> is a string of three octal
173 digits, matches the character whose native code point is I<nnn>.  You
174 can easily run into trouble if you don't have exactly three digits.  So
175 always use three, or since Perl 5.14, you can use C<\o{...}> to specify
176 any number of octal digits.
177
178 Similarly, C<\xI<nn>>, where I<nn> are hexadecimal digits, matches the
179 character whose native ordinal is I<nn>.  Again, not using exactly two
180 digits is a recipe for disaster, but you can use C<\x{...}> to specify
181 any number of hex digits.
182
183 Besides being a metacharacter, the C<"."> is an example of a "character
184 class", something that can match any single character of a given set of
185 them.  In its case, the set is just about all possible characters.  Perl
186 predefines several character classes besides the C<".">; there is a
187 separate reference page about just these, L<perlrecharclass>.
188
189 You can define your own custom character classes, by putting into your
190 pattern in the appropriate place(s), a list of all the characters you
191 want in the set.  You do this by enclosing the list within C<[]> bracket
192 characters.  These are called "bracketed character classes" when we are
193 being precise, but often the word "bracketed" is dropped.  (Dropping it
194 usually doesn't cause confusion.)  This means that the C<"["> character
195 is another metacharacter.  It doesn't match anything just by itself; it
196 is used only to tell Perl that what follows it is a bracketed character
197 class.  If you want to match a literal left square bracket, you must
198 escape it, like C<"\[">.  The matching C<"]"> is also a metacharacter;
199 again it doesn't match anything by itself, but just marks the end of
200 your custom class to Perl.  It is an example of a "sometimes
201 metacharacter".  It isn't a metacharacter if there is no corresponding
202 C<"[">, and matches its literal self:
203
204  print "]" =~ /]/;  # prints 1
205
206 The list of characters within the character class gives the set of
207 characters matched by the class.  C<"[abc]"> matches a single "a" or "b"
208 or "c".  But if the first character after the C<"["> is C<"^">, the
209 class instead matches any character not in the list.  Within a list, the
210 C<"-"> character specifies a range of characters, so that C<a-z>
211 represents all characters between "a" and "z", inclusive.  If you want
212 either C<"-"> or C<"]"> itself to be a member of a class, put it at the
213 start of the list (possibly after a C<"^">), or escape it with a
214 backslash.  C<"-"> is also taken literally when it is at the end of the
215 list, just before the closing C<"]">.  (The following all specify the
216 same class of three characters: C<[-az]>, C<[az-]>, and C<[a\-z]>.  All
217 are different from C<[a-z]>, which specifies a class containing
218 twenty-six characters, even on EBCDIC-based character sets.)
219
220 There is lots more to bracketed character classes; full details are in
221 L<perlrecharclass/Bracketed Character Classes>.
222
223 =head3 Metacharacters
224 X<metacharacter>
225 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
226
227 L</The Basics> introduced some of the metacharacters.  This section
228 gives them all.  Most of them have the same meaning as in the I<egrep>
229 command.
230
231 Only the C<"\"> is always a metacharacter.  The others are metacharacters
232 just sometimes.  The following tables lists all of them, summarizes
233 their use, and gives the contexts where they are metacharacters.
234 Outside those contexts or if prefixed by a C<"\">, they match their
235 corresponding punctuation character.  In some cases, their meaning
236 varies depending on various pattern modifiers that alter the default
237 behaviors.  See L</Modifiers>.
238
239
240             PURPOSE                                  WHERE
241  \   Escape the next character                    Always, except when
242                                                   escaped by another \
243  ^   Match the beginning of the string            Not in []
244        (or line, if /m is used)
245  ^   Complement the [] class                      At the beginning of []
246  .   Match any single character except newline    Not in []
247        (under /s, includes newline)
248  $   Match the end of the string                  Not in [], but can
249        (or before newline at the end of the       mean interpolate a
250        string; or before any newline if /m is     scalar
251        used)
252  |   Alternation                                  Not in []
253  ()  Grouping                                     Not in []
254  [   Start Bracketed Character class              Not in []
255  ]   End Bracketed Character class                Only in [], and
256                                                     not first
257  *   Matches the preceding element 0 or more      Not in []
258        times
259  +   Matches the preceding element 1 or more      Not in []
260        times
261  ?   Matches the preceding element 0 or 1         Not in []
262        times
263  {   Starts a sequence that gives number(s)       Not in []
264        of times the preceding element can be
265        matched
266  {   when following certain escape sequences
267        starts a modifier to the meaning of the
268        sequence
269  }   End sequence started by {
270  -   Indicates a range                            Only in [] interior
271  #   Beginning of comment, extends to line end    Only with /x modifier
272
273 Notice that most of the metacharacters lose their special meaning when
274 they occur in a bracketed character class, except C<"^"> has a different
275 meaning when it is at the beginning of such a class.  And C<"-"> and C<"]">
276 are metacharacters only at restricted positions within bracketed
277 character classes; while C<"}"> is a metacharacter only when closing a
278 special construct started by C<"{">.
279
280 In double-quotish context, as is usually the case,  you need to be
281 careful about C<"$"> and the non-metacharacter C<"@">.  Those could
282 interpolate variables, which may or may not be what you intended.
283
284 These rules were designed for compactness of expression, rather than
285 legibility and maintainability.  The L</E<sol>x and E<sol>xx> pattern
286 modifiers allow you to insert white space to improve readability.  And
287 use of S<C<L<re 'strict'|re/'strict' mode>>> adds extra checking to
288 catch some typos that might silently compile into something unintended.
289
290 By default, the C<"^"> character is guaranteed to match only the
291 beginning of the string, the C<"$"> character only the end (or before the
292 newline at the end), and Perl does certain optimizations with the
293 assumption that the string contains only one line.  Embedded newlines
294 will not be matched by C<"^"> or C<"$">.  You may, however, wish to treat a
295 string as a multi-line buffer, such that the C<"^"> will match after any
296 newline within the string (except if the newline is the last character in
297 the string), and C<"$"> will match before any newline.  At the
298 cost of a little more overhead, you can do this by using the
299 L</C<E<sol>m>> modifier on the pattern match operator.  (Older programs
300 did this by setting C<$*>, but this option was removed in perl 5.10.)
301 X<^> X<$> X</m>
302
303 To simplify multi-line substitutions, the C<"."> character never matches a
304 newline unless you use the L<C<E<sol>s>|/s> modifier, which in effect tells
305 Perl to pretend the string is a single line--even if it isn't.
306 X<.> X</s>
307
308 =head2 Modifiers
309
310 =head3 Overview
311
312 The default behavior for matching can be changed, using various
313 modifiers.  Modifiers that relate to the interpretation of the pattern
314 are listed just below.  Modifiers that alter the way a pattern is used
315 by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
316 L<perlop/"Gory details of parsing quoted constructs">.
317
318 =over 4
319
320 =item B<C<m>>
321 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
322
323 Treat the string being matched against as multiple lines.  That is, change C<"^"> and C<"$"> from matching
324 the start of the string's first line and the end of its last line to
325 matching the start and end of each line within the string.
326
327 =item B<C<s>>
328 X</s> X<regex, single-line> X<regexp, single-line>
329 X<regular expression, single-line>
330
331 Treat the string as single line.  That is, change C<"."> to match any character
332 whatsoever, even a newline, which normally it would not match.
333
334 Used together, as C</ms>, they let the C<"."> match any character whatsoever,
335 while still allowing C<"^"> and C<"$"> to match, respectively, just after
336 and just before newlines within the string.
337
338 =item B<C<i>>
339 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
340 X<regular expression, case-insensitive>
341
342 Do case-insensitive pattern matching.  For example, "A" will match "a"
343 under C</i>.
344
345 If locale matching rules are in effect, the case map is taken from the
346 current
347 locale for code points less than 255, and from Unicode rules for larger
348 code points.  However, matches that would cross the Unicode
349 rules/non-Unicode rules boundary (ords 255/256) will not succeed, unless
350 the locale is a UTF-8 one.  See L<perllocale>.
351
352 There are a number of Unicode characters that match a sequence of
353 multiple characters under C</i>.  For example,
354 C<LATIN SMALL LIGATURE FI> should match the sequence C<fi>.  Perl is not
355 currently able to do this when the multiple characters are in the pattern and
356 are split between groupings, or when one or more are quantified.  Thus
357
358  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
359  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
360  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
361
362  # The below doesn't match, and it isn't clear what $1 and $2 would
363  # be even if it did!!
364  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
365
366 Perl doesn't match multiple characters in a bracketed
367 character class unless the character that maps to them is explicitly
368 mentioned, and it doesn't match them at all if the character class is
369 inverted, which otherwise could be highly confusing.  See
370 L<perlrecharclass/Bracketed Character Classes>, and
371 L<perlrecharclass/Negation>.
372
373 =item B<C<x>> and B<C<xx>>
374 X</x>
375
376 Extend your pattern's legibility by permitting whitespace and comments.
377 Details in L</E<sol>x and  E<sol>xx>
378
379 =item B<C<p>>
380 X</p> X<regex, preserve> X<regexp, preserve>
381
382 Preserve the string matched such that C<${^PREMATCH}>, C<${^MATCH}>, and
383 C<${^POSTMATCH}> are available for use after matching.
384
385 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
386 mechanism, C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> will be available
387 after the match regardless of the modifier.
388
389 =item B<C<a>>, B<C<d>>, B<C<l>>, and B<C<u>>
390 X</a> X</d> X</l> X</u>
391
392 These modifiers, all new in 5.14, affect which character-set rules
393 (Unicode, I<etc>.) are used, as described below in
394 L</Character set modifiers>.
395
396 =item B<C<n>>
397 X</n> X<regex, non-capture> X<regexp, non-capture>
398 X<regular expression, non-capture>
399
400 Prevent the grouping metacharacters C<()> from capturing. This modifier,
401 new in 5.22, will stop C<$1>, C<$2>, I<etc>... from being filled in.
402
403   "hello" =~ /(hi|hello)/;   # $1 is "hello"
404   "hello" =~ /(hi|hello)/n;  # $1 is undef
405
406 This is equivalent to putting C<?:> at the beginning of every capturing group:
407
408   "hello" =~ /(?:hi|hello)/; # $1 is undef
409
410 C</n> can be negated on a per-group basis. Alternatively, named captures
411 may still be used.
412
413   "hello" =~ /(?-n:(hi|hello))/n;   # $1 is "hello"
414   "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
415                                     # "hello"
416
417 =item Other Modifiers
418
419 There are a number of flags that can be found at the end of regular
420 expression constructs that are I<not> generic regular expression flags, but
421 apply to the operation being performed, like matching or substitution (C<m//>
422 or C<s///> respectively).
423
424 Flags described further in
425 L<perlretut/"Using regular expressions in Perl"> are:
426
427   c  - keep the current position during repeated matching
428   g  - globally match the pattern repeatedly in the string
429
430 Substitution-specific modifiers described in
431 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualngcer"> are:
432
433   e  - evaluate the right-hand side as an expression
434   ee - evaluate the right side as a string then eval the result
435   o  - pretend to optimize your code, but actually introduce bugs
436   r  - perform non-destructive substitution and return the new value
437
438 =back
439
440 Regular expression modifiers are usually written in documentation
441 as I<e.g.>, "the C</x> modifier", even though the delimiter
442 in question might not really be a slash.  The modifiers C</imnsxadlup>
443 may also be embedded within the regular expression itself using
444 the C<(?...)> construct, see L</Extended Patterns> below.
445
446 =head3 Details on some modifiers
447
448 Some of the modifiers require more explanation than given in the
449 L</Overview> above.
450
451 =head4 C</x> and  C</xx>
452
453 A single C</x> tells
454 the regular expression parser to ignore most whitespace that is neither
455 backslashed nor within a bracketed character class.  You can use this to
456 break up your regular expression into more readable parts.
457 Also, the C<"#"> character is treated as a metacharacter introducing a
458 comment that runs up to the pattern's closing delimiter, or to the end
459 of the current line if the pattern extends onto the next line.  Hence,
460 this is very much like an ordinary Perl code comment.  (You can include
461 the closing delimiter within the comment only if you precede it with a
462 backslash, so be careful!)
463
464 Use of C</x> means that if you want real
465 whitespace or C<"#"> characters in the pattern (outside a bracketed character
466 class, which is unaffected by C</x>), then you'll either have to
467 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
468 hex, or C<\N{}> escapes.
469 It is ineffective to try to continue a comment onto the next line by
470 escaping the C<\n> with a backslash or C<\Q>.
471
472 You can use L</(?#text)> to create a comment that ends earlier than the
473 end of the current line, but C<text> also can't contain the closing
474 delimiter unless escaped with a backslash.
475
476 A common pitfall is to forget that C<"#"> characters begin a comment under
477 C</x> and are not matched literally.  Just keep that in mind when trying
478 to puzzle out why a particular C</x> pattern isn't working as expected.
479
480 Starting in Perl v5.26, if the modifier has a second C<"x"> within it,
481 it does everything that a single C</x> does, but additionally
482 non-backslashed SPACE and TAB characters within bracketed character
483 classes are also generally ignored, and hence can be added to make the
484 classes more readable.
485
486     / [d-e g-i 3-7]/xx
487     /[ ! @ " # $ % ^ & * () = ? <> ' ]/xx
488
489 may be easier to grasp than the squashed equivalents
490
491     /[d-eg-i3-7]/
492     /[!@"#$%^&*()=?<>']/
493
494 Taken together, these features go a long way towards
495 making Perl's regular expressions more readable.  Here's an example:
496
497     # Delete (most) C comments.
498     $program =~ s {
499         /\*     # Match the opening delimiter.
500         .*?     # Match a minimal number of characters.
501         \*/     # Match the closing delimiter.
502     } []gsx;
503
504 Note that anything inside
505 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
506 space interpretation within a single multi-character construct.  For
507 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
508 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
509 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<"(">,
510 C<"?">, and C<":">.  Within any delimiters for such a
511 construct, allowed spaces are not affected by C</x>, and depend on the
512 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
513 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
514 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
515 L<perluniprops/Properties accessible through \p{} and \P{}>.
516 X</x>
517
518 The set of characters that are deemed whitespace are those that Unicode
519 calls "Pattern White Space", namely:
520
521  U+0009 CHARACTER TABULATION
522  U+000A LINE FEED
523  U+000B LINE TABULATION
524  U+000C FORM FEED
525  U+000D CARRIAGE RETURN
526  U+0020 SPACE
527  U+0085 NEXT LINE
528  U+200E LEFT-TO-RIGHT MARK
529  U+200F RIGHT-TO-LEFT MARK
530  U+2028 LINE SEPARATOR
531  U+2029 PARAGRAPH SEPARATOR
532
533 =head4 Character set modifiers
534
535 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
536 the character set modifiers; they affect the character set rules
537 used for the regular expression.
538
539 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
540 to you, and so you need not worry about them very much.  They exist for
541 Perl's internal use, so that complex regular expression data structures
542 can be automatically serialized and later exactly reconstituted,
543 including all their nuances.  But, since Perl can't keep a secret, and
544 there may be rare instances where they are useful, they are documented
545 here.
546
547 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
548 allow code that is to work mostly on ASCII data to not have to concern
549 itself with Unicode.
550
551 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
552 effect at the time of the execution of the pattern match.
553
554 C</u> sets the character set to B<U>nicode.
555
556 C</a> also sets the character set to Unicode, BUT adds several
557 restrictions for B<A>SCII-safe matching.
558
559 C</d> is the old, problematic, pre-5.14 B<D>efault character set
560 behavior.  Its only use is to force that old behavior.
561
562 At any given time, exactly one of these modifiers is in effect.  Their
563 existence allows Perl to keep the originally compiled behavior of a
564 regular expression, regardless of what rules are in effect when it is
565 actually executed.  And if it is interpolated into a larger regex, the
566 original's rules continue to apply to it, and don't affect the other
567 parts.
568
569 The C</l> and C</u> modifiers are automatically selected for
570 regular expressions compiled within the scope of various pragmas,
571 and we recommend that in general, you use those pragmas instead of
572 specifying these modifiers explicitly.  For one thing, the modifiers
573 affect only pattern matching, and do not extend to even any replacement
574 done, whereas using the pragmas gives consistent results for all
575 appropriate operations within their scopes.  For example,
576
577  s/foo/\Ubar/il
578
579 will match "foo" using the locale's rules for case-insensitive matching,
580 but the C</l> does not affect how the C<\U> operates.  Most likely you
581 want both of them to use locale rules.  To do this, instead compile the
582 regular expression within the scope of C<use locale>.  This both
583 implicitly adds the C</l>, and applies locale rules to the C<\U>.   The
584 lesson is to C<use locale>, and not C</l> explicitly.
585
586 Similarly, it would be better to use C<use feature 'unicode_strings'>
587 instead of,
588
589  s/foo/\Lbar/iu
590
591 to get Unicode rules, as the C<\L> in the former (but not necessarily
592 the latter) would also use Unicode rules.
593
594 More detail on each of the modifiers follows.  Most likely you don't
595 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
596 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
597
598 =head4 /l
599
600 means to use the current locale's rules (see L<perllocale>) when pattern
601 matching.  For example, C<\w> will match the "word" characters of that
602 locale, and C<"/i"> case-insensitive matching will match according to
603 the locale's case folding rules.  The locale used will be the one in
604 effect at the time of execution of the pattern match.  This may not be
605 the same as the compilation-time locale, and can differ from one match
606 to another if there is an intervening call of the
607 L<setlocale() function|perllocale/The setlocale function>.
608
609 Prior to v5.20, Perl did not support multi-byte locales.  Starting then,
610 UTF-8 locales are supported.  No other multi byte locales are ever
611 likely to be supported.  However, in all locales, one can have code
612 points above 255 and these will always be treated as Unicode no matter
613 what locale is in effect.
614
615 Under Unicode rules, there are a few case-insensitive matches that cross
616 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
617 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
618 platforms) does not caselessly match the character at 0x178, C<LATIN
619 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
620 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
621 knowing if that character even exists in the locale, much less what code
622 point it is.
623
624 In a UTF-8 locale in v5.20 and later, the only visible difference
625 between locale and non-locale in regular expressions should be tainting
626 (see L<perlsec>).
627
628 This modifier may be specified to be the default by C<use locale>, but
629 see L</Which character set modifier is in effect?>.
630 X</l>
631
632 =head4 /u
633
634 means to use Unicode rules when pattern matching.  On ASCII platforms,
635 this means that the code points between 128 and 255 take on their
636 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
637 (Otherwise Perl considers their meanings to be undefined.)  Thus,
638 under this modifier, the ASCII platform effectively becomes a Unicode
639 platform; and hence, for example, C<\w> will match any of the more than
640 100_000 word characters in Unicode.
641
642 Unlike most locales, which are specific to a language and country pair,
643 Unicode classifies all the characters that are letters I<somewhere> in
644 the world as
645 C<\w>.  For example, your locale might not think that C<LATIN SMALL
646 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
647 Unicode does.  Similarly, all the characters that are decimal digits
648 somewhere in the world will match C<\d>; this is hundreds, not 10,
649 possible matches.  And some of those digits look like some of the 10
650 ASCII digits, but mean a different number, so a human could easily think
651 a number is a different quantity than it really is.  For example,
652 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
653 C<ASCII DIGIT EIGHT> (U+0038), and C<LEPCHA DIGIT SIX> (U+1C46) looks
654 very much like an C<ASCII DIGIT FIVE> (U+0035).  And, C<\d+>, may match
655 strings of digits that are a mixture from different writing systems,
656 creating a security issue.  A fraudulent website, for example, could
657 display the price of something using U+1C46, and it would appear to the
658 user that something cost 500 units, but it really costs 600.  A browser
659 that enforced script runs (L</Script Runs>) would prevent that
660 fraudulent display.  L<Unicode::UCD/num()> can also be used to sort this
661 out.  Or the C</a> modifier can be used to force C<\d> to match just the
662 ASCII 0 through 9.
663
664 Also, under this modifier, case-insensitive matching works on the full
665 set of Unicode
666 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
667 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
668 if you're not prepared, might make it look like a hexadecimal constant,
669 presenting another potential security issue.  See
670 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
671 security issues.
672
673 This modifier may be specified to be the default by C<use feature
674 'unicode_strings>, C<use locale ':not_characters'>, or
675 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
676 but see L</Which character set modifier is in effect?>.
677 X</u>
678
679 =head4 /d
680
681 This modifier means to use the "Default" native rules of the platform
682 except when there is cause to use Unicode rules instead, as follows:
683
684 =over 4
685
686 =item 1
687
688 the target string is encoded in UTF-8; or
689
690 =item 2
691
692 the pattern is encoded in UTF-8; or
693
694 =item 3
695
696 the pattern explicitly mentions a code point that is above 255 (say by
697 C<\x{100}>); or
698
699 =item 4
700
701 the pattern uses a Unicode name (C<\N{...}>);  or
702
703 =item 5
704
705 the pattern uses a Unicode property (C<\p{...}> or C<\P{...}>); or
706
707 =item 6
708
709 the pattern uses a Unicode break (C<\b{...}> or C<\B{...}>); or
710
711 =item 7
712
713 the pattern uses L</C<(?[ ])>>
714
715 =item 8
716
717 the pattern uses L<C<(*script_run: ...)>|/Script Runs>
718
719 =back
720
721 Another mnemonic for this modifier is "Depends", as the rules actually
722 used depend on various things, and as a result you can get unexpected
723 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
724 become rather infamous, leading to yet another (without swearing) name
725 for this modifier, "Dodgy".
726
727 Unless the pattern or string are encoded in UTF-8, only ASCII characters
728 can match positively.
729
730 Here are some examples of how that works on an ASCII platform:
731
732  $str =  "\xDF";      # $str is not in UTF-8 format.
733  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
734  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
735  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
736  chop $str;
737  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
738
739 This modifier is automatically selected by default when none of the
740 others are, so yet another name for it is "Default".
741
742 Because of the unexpected behaviors associated with this modifier, you
743 probably should only explicitly use it to maintain weird backward
744 compatibilities.
745
746 =head4 /a (and /aa)
747
748 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier
749 may be doubled-up to increase its effect.
750
751 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
752 the Posix character classes to match only in the ASCII range.  They thus
753 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
754 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
755 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, the vertical tab;
756 C<\w> means the 63 characters
757 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
758 C<[[:print:]]> match only the appropriate ASCII-range characters.
759
760 This modifier is useful for people who only incidentally use Unicode,
761 and who do not wish to be burdened with its complexities and security
762 concerns.
763
764 With C</a>, one can write C<\d> with confidence that it will only match
765 ASCII characters, and should the need arise to match beyond ASCII, you
766 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
767 similar C<\p{...}> constructs that can match beyond ASCII both white
768 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
769 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
770 doesn't mean you can't use Unicode, it means that to get Unicode
771 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
772 signals Unicode.
773
774 As you would expect, this modifier causes, for example, C<\D> to mean
775 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
776 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
777 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
778 for C<\B>).
779
780 Otherwise, C</a> behaves like the C</u> modifier, in that
781 case-insensitive matching uses Unicode rules; for example, "k" will
782 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
783 points in the Latin1 range, above ASCII will have Unicode rules when it
784 comes to case-insensitive matching.
785
786 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
787 specify the C<"a"> twice, for example C</aai> or C</aia>.  (The first
788 occurrence of C<"a"> restricts the C<\d>, I<etc>., and the second occurrence
789 adds the C</i> restrictions.)  But, note that code points outside the
790 ASCII range will use Unicode rules for C</i> matching, so the modifier
791 doesn't really restrict things to just ASCII; it just forbids the
792 intermixing of ASCII and non-ASCII.
793
794 To summarize, this modifier provides protection for applications that
795 don't wish to be exposed to all of Unicode.  Specifying it twice
796 gives added protection.
797
798 This modifier may be specified to be the default by C<use re '/a'>
799 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
800 the C</u> modifier explicitly if there are a few regular expressions
801 where you do want full Unicode rules (but even here, it's best if
802 everything were under feature C<"unicode_strings">, along with the
803 C<use re '/aa'>).  Also see L</Which character set modifier is in
804 effect?>.
805 X</a>
806 X</aa>
807
808 =head4 Which character set modifier is in effect?
809
810 Which of these modifiers is in effect at any given point in a regular
811 expression depends on a fairly complex set of interactions.  These have
812 been designed so that in general you don't have to worry about it, but
813 this section gives the gory details.  As
814 explained below in L</Extended Patterns> it is possible to explicitly
815 specify modifiers that apply only to portions of a regular expression.
816 The innermost always has priority over any outer ones, and one applying
817 to the whole expression has priority over any of the default settings that are
818 described in the remainder of this section.
819
820 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
821 default modifiers (including these) for regular expressions compiled
822 within its scope.  This pragma has precedence over the other pragmas
823 listed below that also change the defaults.
824
825 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
826 and C<L<use feature 'unicode_strings|feature>>, or
827 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
828 C</u> when not in the same scope as either C<L<use locale|perllocale>>
829 or C<L<use bytes|bytes>>.
830 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
831 sets the default to C</u>, overriding any plain C<use locale>.)
832 Unlike the mechanisms mentioned above, these
833 affect operations besides regular expressions pattern matching, and so
834 give more consistent results with other operators, including using
835 C<\U>, C<\l>, I<etc>. in substitution replacements.
836
837 If none of the above apply, for backwards compatibility reasons, the
838 C</d> modifier is the one in effect by default.  As this can lead to
839 unexpected results, it is best to specify which other rule set should be
840 used.
841
842 =head4 Character set modifier behavior prior to Perl 5.14
843
844 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
845 for regexes compiled within the scope of C<use locale>, and C</d> was
846 implied otherwise.  However, interpolating a regex into a larger regex
847 would ignore the original compilation in favor of whatever was in effect
848 at the time of the second compilation.  There were a number of
849 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
850 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
851 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
852
853 =head2 Regular Expressions
854
855 =head3 Quantifiers
856
857 Quantifiers are used when a particular portion of a pattern needs to
858 match a certain number (or numbers) of times.  If there isn't a
859 quantifier the number of times to match is exactly one.  The following
860 standard quantifiers are recognized:
861 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
862
863     *           Match 0 or more times
864     +           Match 1 or more times
865     ?           Match 1 or 0 times
866     {n}         Match exactly n times
867     {n,}        Match at least n times
868     {n,m}       Match at least n but not more than m times
869
870 (If a non-escaped curly bracket occurs in a context other than one of
871 the quantifiers listed above, where it does not form part of a
872 backslashed sequence like C<\x{...}>, it is either a fatal syntax error,
873 or treated as a regular character, generally with a deprecation warning
874 raised.  To escape it, you can precede it with a backslash (C<"\{">) or
875 enclose it within square brackets  (C<"[{]">).
876 This change will allow for future syntax extensions (like making the
877 lower bound of a quantifier optional), and better error checking of
878 quantifiers).
879
880 The C<"*"> quantifier is equivalent to C<{0,}>, the C<"+">
881 quantifier to C<{1,}>, and the C<"?"> quantifier to C<{0,1}>.  I<n> and I<m> are limited
882 to non-negative integral values less than a preset limit defined when perl is built.
883 This is usually 32766 on the most common platforms.  The actual limit can
884 be seen in the error message generated by code such as this:
885
886     $_ **= $_ , / {$_} / for 2 .. 42;
887
888 By default, a quantified subpattern is "greedy", that is, it will match as
889 many times as possible (given a particular starting location) while still
890 allowing the rest of the pattern to match.  If you want it to match the
891 minimum number of times possible, follow the quantifier with a C<"?">.  Note
892 that the meanings don't change, just the "greediness":
893 X<metacharacter> X<greedy> X<greediness>
894 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
895
896     *?        Match 0 or more times, not greedily
897     +?        Match 1 or more times, not greedily
898     ??        Match 0 or 1 time, not greedily
899     {n}?      Match exactly n times, not greedily (redundant)
900     {n,}?     Match at least n times, not greedily
901     {n,m}?    Match at least n but not more than m times, not greedily
902
903 Normally when a quantified subpattern does not allow the rest of the
904 overall pattern to match, Perl will backtrack. However, this behaviour is
905 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
906 as well.
907
908  *+     Match 0 or more times and give nothing back
909  ++     Match 1 or more times and give nothing back
910  ?+     Match 0 or 1 time and give nothing back
911  {n}+   Match exactly n times and give nothing back (redundant)
912  {n,}+  Match at least n times and give nothing back
913  {n,m}+ Match at least n but not more than m times and give nothing back
914
915 For instance,
916
917    'aaaa' =~ /a++a/
918
919 will never match, as the C<a++> will gobble up all the C<"a">'s in the
920 string and won't leave any for the remaining part of the pattern. This
921 feature can be extremely useful to give perl hints about where it
922 shouldn't backtrack. For instance, the typical "match a double-quoted
923 string" problem can be most efficiently performed when written as:
924
925    /"(?:[^"\\]++|\\.)*+"/
926
927 as we know that if the final quote does not match, backtracking will not
928 help. See the independent subexpression
929 L</C<< (?>I<pattern>) >>> for more details;
930 possessive quantifiers are just syntactic sugar for that construct. For
931 instance the above example could also be written as follows:
932
933    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
934
935 Note that the possessive quantifier modifier can not be combined
936 with the non-greedy modifier. This is because it would make no sense.
937 Consider the follow equivalency table:
938
939     Illegal         Legal
940     ------------    ------
941     X??+            X{0}
942     X+?+            X{1}
943     X{min,max}?+    X{min}
944
945 =head3 Escape sequences
946
947 Because patterns are processed as double-quoted strings, the following
948 also work:
949
950  \t          tab                   (HT, TAB)
951  \n          newline               (LF, NL)
952  \r          return                (CR)
953  \f          form feed             (FF)
954  \a          alarm (bell)          (BEL)
955  \e          escape (think troff)  (ESC)
956  \cK         control char          (example: VT)
957  \x{}, \x00  character whose ordinal is the given hexadecimal number
958  \N{name}    named Unicode character or character sequence
959  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
960  \o{}, \000  character whose ordinal is the given octal number
961  \l          lowercase next char (think vi)
962  \u          uppercase next char (think vi)
963  \L          lowercase until \E (think vi)
964  \U          uppercase until \E (think vi)
965  \Q          quote (disable) pattern metacharacters until \E
966  \E          end either case modification or quoted section, think vi
967
968 Details are in L<perlop/Quote and Quote-like Operators>.
969
970 =head3 Character Classes and other Special Escapes
971
972 In addition, Perl defines the following:
973 X<\g> X<\k> X<\K> X<backreference>
974
975  Sequence   Note    Description
976   [...]     [1]  Match a character according to the rules of the
977                    bracketed character class defined by the "...".
978                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
979   [[:...:]] [2]  Match a character according to the rules of the POSIX
980                    character class "..." within the outer bracketed
981                    character class.  Example: [[:upper:]] matches any
982                    uppercase character.
983   (?[...])  [8]  Extended bracketed character class
984   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
985                    other connector punctuation chars plus Unicode
986                    marks)
987   \W        [3]  Match a non-"word" character
988   \s        [3]  Match a whitespace character
989   \S        [3]  Match a non-whitespace character
990   \d        [3]  Match a decimal digit character
991   \D        [3]  Match a non-digit character
992   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
993   \PP       [3]  Match non-P
994   \X        [4]  Match Unicode "eXtended grapheme cluster"
995   \1        [5]  Backreference to a specific capture group or buffer.
996                    '1' may actually be any positive integer.
997   \g1       [5]  Backreference to a specific or previous group,
998   \g{-1}    [5]  The number may be negative indicating a relative
999                    previous group and may optionally be wrapped in
1000                    curly brackets for safer parsing.
1001   \g{name}  [5]  Named backreference
1002   \k<name>  [5]  Named backreference
1003   \K        [6]  Keep the stuff left of the \K, don't include it in $&
1004   \N        [7]  Any character but \n.  Not affected by /s modifier
1005   \v        [3]  Vertical whitespace
1006   \V        [3]  Not vertical whitespace
1007   \h        [3]  Horizontal whitespace
1008   \H        [3]  Not horizontal whitespace
1009   \R        [4]  Linebreak
1010
1011 =over 4
1012
1013 =item [1]
1014
1015 See L<perlrecharclass/Bracketed Character Classes> for details.
1016
1017 =item [2]
1018
1019 See L<perlrecharclass/POSIX Character Classes> for details.
1020
1021 =item [3]
1022
1023 See L<perlunicode/Unicode Character Properties> for details
1024
1025 =item [4]
1026
1027 See L<perlrebackslash/Misc> for details.
1028
1029 =item [5]
1030
1031 See L</Capture groups> below for details.
1032
1033 =item [6]
1034
1035 See L</Extended Patterns> below for details.
1036
1037 =item [7]
1038
1039 Note that C<\N> has two meanings.  When of the form C<\N{I<NAME>}>, it
1040 matches the character or character sequence whose name is I<NAME>; and
1041 similarly
1042 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
1043 code point is I<hex>.  Otherwise it matches any character but C<\n>.
1044
1045 =item [8]
1046
1047 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
1048
1049 =back
1050
1051 =head3 Assertions
1052
1053 Besides L<C<"^"> and C<"$">|/Metacharacters>, Perl defines the following
1054 zero-width assertions:
1055 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
1056 X<regexp, zero-width assertion>
1057 X<regular expression, zero-width assertion>
1058 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
1059
1060  \b{}   Match at Unicode boundary of specified type
1061  \B{}   Match where corresponding \b{} doesn't match
1062  \b     Match a \w\W or \W\w boundary
1063  \B     Match except at a \w\W or \W\w boundary
1064  \A     Match only at beginning of string
1065  \Z     Match only at end of string, or before newline at the end
1066  \z     Match only at end of string
1067  \G     Match only at pos() (e.g. at the end-of-match position
1068         of prior m//g)
1069
1070 A Unicode boundary (C<\b{}>), available starting in v5.22, is a spot
1071 between two characters, or before the first character in the string, or
1072 after the final character in the string where certain criteria defined
1073 by Unicode are met.  See L<perlrebackslash/\b{}, \b, \B{}, \B> for
1074 details.
1075
1076 A word boundary (C<\b>) is a spot between two characters
1077 that has a C<\w> on one side of it and a C<\W> on the other side
1078 of it (in either order), counting the imaginary characters off the
1079 beginning and end of the string as matching a C<\W>.  (Within
1080 character classes C<\b> represents backspace rather than a word
1081 boundary, just as it normally does in any double-quoted string.)
1082 The C<\A> and C<\Z> are just like C<"^"> and C<"$">, except that they
1083 won't match multiple times when the C</m> modifier is used, while
1084 C<"^"> and C<"$"> will match at every internal line boundary.  To match
1085 the actual end of the string and not ignore an optional trailing
1086 newline, use C<\z>.
1087 X<\b> X<\A> X<\Z> X<\z> X</m>
1088
1089 The C<\G> assertion can be used to chain global matches (using
1090 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
1091 It is also useful when writing C<lex>-like scanners, when you have
1092 several patterns that you want to match against consequent substrings
1093 of your string; see the previous reference.  The actual location
1094 where C<\G> will match can also be influenced by using C<pos()> as
1095 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
1096 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
1097 is modified somewhat, in that contents to the left of C<\G> are
1098 not counted when determining the length of the match. Thus the following
1099 will not match forever:
1100 X<\G>
1101
1102      my $string = 'ABC';
1103      pos($string) = 1;
1104      while ($string =~ /(.\G)/g) {
1105          print $1;
1106      }
1107
1108 It will print 'A' and then terminate, as it considers the match to
1109 be zero-width, and thus will not match at the same position twice in a
1110 row.
1111
1112 It is worth noting that C<\G> improperly used can result in an infinite
1113 loop. Take care when using patterns that include C<\G> in an alternation.
1114
1115 Note also that C<s///> will refuse to overwrite part of a substitution
1116 that has already been replaced; so for example this will stop after the
1117 first iteration, rather than iterating its way backwards through the
1118 string:
1119
1120     $_ = "123456789";
1121     pos = 6;
1122     s/.(?=.\G)/X/g;
1123     print;      # prints 1234X6789, not XXXXX6789
1124
1125
1126 =head3 Capture groups
1127
1128 The grouping construct C<( ... )> creates capture groups (also referred to as
1129 capture buffers). To refer to the current contents of a group later on, within
1130 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
1131 for the second, and so on.
1132 This is called a I<backreference>.
1133 X<regex, capture buffer> X<regexp, capture buffer>
1134 X<regex, capture group> X<regexp, capture group>
1135 X<regular expression, capture buffer> X<backreference>
1136 X<regular expression, capture group> X<backreference>
1137 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
1138 X<named capture buffer> X<regular expression, named capture buffer>
1139 X<named capture group> X<regular expression, named capture group>
1140 X<%+> X<$+{name}> X<< \k<name> >>
1141 There is no limit to the number of captured substrings that you may use.
1142 Groups are numbered with the leftmost open parenthesis being number 1, I<etc>.  If
1143 a group did not match, the associated backreference won't match either. (This
1144 can happen if the group is optional, or in a different branch of an
1145 alternation.)
1146 You can omit the C<"g">, and write C<"\1">, I<etc>, but there are some issues with
1147 this form, described below.
1148
1149 You can also refer to capture groups relatively, by using a negative number, so
1150 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
1151 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
1152 example:
1153
1154         /
1155          (Y)            # group 1
1156          (              # group 2
1157             (X)         # group 3
1158             \g{-1}      # backref to group 3
1159             \g{-3}      # backref to group 1
1160          )
1161         /x
1162
1163 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
1164 interpolate regexes into larger regexes and not have to worry about the
1165 capture groups being renumbered.
1166
1167 You can dispense with numbers altogether and create named capture groups.
1168 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
1169 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
1170 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
1171 I<name> must not begin with a number, nor contain hyphens.
1172 When different groups within the same pattern have the same name, any reference
1173 to that name assumes the leftmost defined group.  Named groups count in
1174 absolute and relative numbering, and so can also be referred to by those
1175 numbers.
1176 (It's possible to do things with named capture groups that would otherwise
1177 require C<(??{})>.)
1178
1179 Capture group contents are dynamically scoped and available to you outside the
1180 pattern until the end of the enclosing block or until the next successful
1181 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
1182 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
1183 I<etc>); or by name via the C<%+> hash, using C<"$+{I<name>}">.
1184
1185 Braces are required in referring to named capture groups, but are optional for
1186 absolute or relative numbered ones.  Braces are safer when creating a regex by
1187 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
1188 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
1189 is probably not what you intended.
1190
1191 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
1192 there were no named nor relative numbered capture groups.  Absolute numbered
1193 groups were referred to using C<\1>,
1194 C<\2>, I<etc>., and this notation is still
1195 accepted (and likely always will be).  But it leads to some ambiguities if
1196 there are more than 9 capture groups, as C<\10> could mean either the tenth
1197 capture group, or the character whose ordinal in octal is 010 (a backspace in
1198 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
1199 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
1200 a backreference only if at least 11 left parentheses have opened before it.
1201 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
1202 There are several examples below that illustrate these perils.  You can avoid
1203 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
1204 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
1205 digits padded with leading zeros, since a leading zero implies an octal
1206 constant.
1207
1208 The C<\I<digit>> notation also works in certain circumstances outside
1209 the pattern.  See L</Warning on \1 Instead of $1> below for details.
1210
1211 Examples:
1212
1213     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
1214
1215     /(.)\g1/                        # find first doubled char
1216          and print "'$1' is the first doubled character\n";
1217
1218     /(?<char>.)\k<char>/            # ... a different way
1219          and print "'$+{char}' is the first doubled character\n";
1220
1221     /(?'char'.)\g1/                 # ... mix and match
1222          and print "'$1' is the first doubled character\n";
1223
1224     if (/Time: (..):(..):(..)/) {   # parse out values
1225         $hours = $1;
1226         $minutes = $2;
1227         $seconds = $3;
1228     }
1229
1230     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
1231     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
1232     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
1233     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
1234
1235     $a = '(.)\1';        # Creates problems when concatenated.
1236     $b = '(.)\g{1}';     # Avoids the problems.
1237     "aa" =~ /${a}/;      # True
1238     "aa" =~ /${b}/;      # True
1239     "aa0" =~ /${a}0/;    # False!
1240     "aa0" =~ /${b}0/;    # True
1241     "aa\x08" =~ /${a}0/;  # True!
1242     "aa\x08" =~ /${b}0/;  # False
1243
1244 Several special variables also refer back to portions of the previous
1245 match.  C<$+> returns whatever the last bracket match matched.
1246 C<$&> returns the entire matched string.  (At one point C<$0> did
1247 also, but now it returns the name of the program.)  C<$`> returns
1248 everything before the matched string.  C<$'> returns everything
1249 after the matched string. And C<$^N> contains whatever was matched by
1250 the most-recently closed group (submatch). C<$^N> can be used in
1251 extended patterns (see below), for example to assign a submatch to a
1252 variable.
1253 X<$+> X<$^N> X<$&> X<$`> X<$'>
1254
1255 These special variables, like the C<%+> hash and the numbered match variables
1256 (C<$1>, C<$2>, C<$3>, I<etc>.) are dynamically scoped
1257 until the end of the enclosing block or until the next successful
1258 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
1259 X<$+> X<$^N> X<$&> X<$`> X<$'>
1260 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
1261
1262 B<NOTE>: Failed matches in Perl do not reset the match variables,
1263 which makes it easier to write code that tests for a series of more
1264 specific cases and remembers the best match.
1265
1266 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
1267 beware that once Perl sees that you need one of C<$&>, C<$`>, or
1268 C<$'> anywhere in the program, it has to provide them for every
1269 pattern match.  This may substantially slow your program.
1270
1271 Perl uses the same mechanism to produce C<$1>, C<$2>, I<etc>, so you also
1272 pay a price for each pattern that contains capturing parentheses.
1273 (To avoid this cost while retaining the grouping behaviour, use the
1274 extended regular expression C<(?: ... )> instead.)  But if you never
1275 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
1276 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
1277 if you can, but if you can't (and some algorithms really appreciate
1278 them), once you've used them once, use them at will, because you've
1279 already paid the price.
1280 X<$&> X<$`> X<$'>
1281
1282 Perl 5.16 introduced a slightly more efficient mechanism that notes
1283 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
1284 thus may only need to copy part of the string.  Perl 5.20 introduced a
1285 much more efficient copy-on-write mechanism which eliminates any slowdown.
1286
1287 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
1288 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
1289 and C<$'>, B<except> that they are only guaranteed to be defined after a
1290 successful match that was executed with the C</p> (preserve) modifier.
1291 The use of these variables incurs no global performance penalty, unlike
1292 their punctuation character equivalents, however at the trade-off that you
1293 have to tell perl when you want to use them.  As of Perl 5.20, these three
1294 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
1295 X</p> X<p modifier>
1296
1297 =head2 Quoting metacharacters
1298
1299 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
1300 C<\w>, C<\n>.  Unlike some other regular expression languages, there
1301 are no backslashed symbols that aren't alphanumeric.  So anything
1302 that looks like C<\\>, C<\(>, C<\)>, C<\[>, C<\]>, C<\{>, or C<\}> is
1303 always
1304 interpreted as a literal character, not a metacharacter.  This was
1305 once used in a common idiom to disable or quote the special meanings
1306 of regular expression metacharacters in a string that you want to
1307 use for a pattern. Simply quote all non-"word" characters:
1308
1309     $pattern =~ s/(\W)/\\$1/g;
1310
1311 (If C<use locale> is set, then this depends on the current locale.)
1312 Today it is more common to use the C<L<quotemeta()|perlfunc/quotemeta>>
1313 function or the C<\Q> metaquoting escape sequence to disable all
1314 metacharacters' special meanings like this:
1315
1316     /$unquoted\Q$quoted\E$unquoted/
1317
1318 Beware that if you put literal backslashes (those not inside
1319 interpolated variables) between C<\Q> and C<\E>, double-quotish
1320 backslash interpolation may lead to confusing results.  If you
1321 I<need> to use literal backslashes within C<\Q...\E>,
1322 consult L<perlop/"Gory details of parsing quoted constructs">.
1323
1324 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
1325
1326 =head2 Extended Patterns
1327
1328 Perl also defines a consistent extension syntax for features not
1329 found in standard tools like B<awk> and
1330 B<lex>.  The syntax for most of these is a
1331 pair of parentheses with a question mark as the first thing within
1332 the parentheses.  The character after the question mark indicates
1333 the extension.
1334
1335 A question mark was chosen for this and for the minimal-matching
1336 construct because 1) question marks are rare in older regular
1337 expressions, and 2) whenever you see one, you should stop and
1338 "question" exactly what is going on.  That's psychology....
1339
1340 =over 4
1341
1342 =item C<(?#I<text>)>
1343 X<(?#)>
1344
1345 A comment.  The I<text> is ignored.
1346 Note that Perl closes
1347 the comment as soon as it sees a C<")">, so there is no way to put a literal
1348 C<")"> in the comment.  The pattern's closing delimiter must be escaped by
1349 a backslash if it appears in the comment.
1350
1351 See L</E<sol>x> for another way to have comments in patterns.
1352
1353 Note that a comment can go just about anywhere, except in the middle of
1354 an escape sequence.   Examples:
1355
1356  qr/foo(?#comment)bar/'  # Matches 'foobar'
1357
1358  # The pattern below matches 'abcd', 'abccd', or 'abcccd'
1359  qr/abc(?#comment between literal and its quantifier){1,3}d/
1360
1361  # The pattern below generates a syntax error, because the '\p' must
1362  # be followed immediately by a '{'.
1363  qr/\p(?#comment between \p and its property name){Any}/
1364
1365  # The pattern below generates a syntax error, because the initial
1366  # '\(' is a literal opening parenthesis, and so there is nothing
1367  # for the  closing ')' to match
1368  qr/\(?#the backslash means this isn't a comment)p{Any}/
1369
1370  # Comments can be used to fold long patterns into multiple lines
1371  qr/First part of a long regex(?#
1372    )remaining part/
1373
1374 =item C<(?adlupimnsx-imnsx)>
1375
1376 =item C<(?^alupimnsx)>
1377 X<(?)> X<(?^)>
1378
1379 Zero or more embedded pattern-match modifiers, to be turned on (or
1380 turned off if preceded by C<"-">) for the remainder of the pattern or
1381 the remainder of the enclosing pattern group (if any).
1382
1383 This is particularly useful for dynamically-generated patterns,
1384 such as those read in from a
1385 configuration file, taken from an argument, or specified in a table
1386 somewhere.  Consider the case where some patterns want to be
1387 case-sensitive and some do not:  The case-insensitive ones merely need to
1388 include C<(?i)> at the front of the pattern.  For example:
1389
1390     $pattern = "foobar";
1391     if ( /$pattern/i ) { }
1392
1393     # more flexible:
1394
1395     $pattern = "(?i)foobar";
1396     if ( /$pattern/ ) { }
1397
1398 These modifiers are restored at the end of the enclosing group. For example,
1399
1400     ( (?i) blah ) \s+ \g1
1401
1402 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1403 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1404 modifier outside this group.
1405
1406 These modifiers do not carry over into named subpatterns called in the
1407 enclosing group. In other words, a pattern such as C<((?i)(?&I<NAME>))> does not
1408 change the case-sensitivity of the I<NAME> pattern.
1409
1410 A modifier is overridden by later occurrences of this construct in the
1411 same scope containing the same modifier, so that
1412
1413     /((?im)foo(?-m)bar)/
1414
1415 matches all of C<foobar> case insensitively, but uses C</m> rules for
1416 only the C<foo> portion.  The C<"a"> flag overrides C<aa> as well;
1417 likewise C<aa> overrides C<"a">.  The same goes for C<"x"> and C<xx>.
1418 Hence, in
1419
1420     /(?-x)foo/xx
1421
1422 both C</x> and C</xx> are turned off during matching C<foo>.  And in
1423
1424     /(?x)foo/x
1425
1426 C</x> but NOT C</xx> is turned on for matching C<foo>.  (One might
1427 mistakenly think that since the inner C<(?x)> is already in the scope of
1428 C</x>, that the result would effectively be the sum of them, yielding
1429 C</xx>.  It doesn't work that way.)  Similarly, doing something like
1430 C<(?xx-x)foo> turns off all C<"x"> behavior for matching C<foo>, it is not
1431 that you subtract 1 C<"x"> from 2 to get 1 C<"x"> remaining.
1432
1433 Any of these modifiers can be set to apply globally to all regular
1434 expressions compiled within the scope of a C<use re>.  See
1435 L<re/"'/flags' mode">.
1436
1437 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1438 after the C<"?"> is a shorthand equivalent to C<d-imnsx>.  Flags (except
1439 C<"d">) may follow the caret to override it.
1440 But a minus sign is not legal with it.
1441
1442 Note that the C<"a">, C<"d">, C<"l">, C<"p">, and C<"u"> modifiers are special in
1443 that they can only be enabled, not disabled, and the C<"a">, C<"d">, C<"l">, and
1444 C<"u"> modifiers are mutually exclusive: specifying one de-specifies the
1445 others, and a maximum of one (or two C<"a">'s) may appear in the
1446 construct.  Thus, for
1447 example, C<(?-p)> will warn when compiled under C<use warnings>;
1448 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1449
1450 Note also that the C<"p"> modifier is special in that its presence
1451 anywhere in a pattern has a global effect.
1452
1453 Having zero modifiers makes this a no-op (so why did you specify it,
1454 unless it's generated code), and starting in v5.30, warns under L<C<use
1455 re 'strict'>|re/'strict' mode>.
1456
1457 =item C<(?:I<pattern>)>
1458 X<(?:)>
1459
1460 =item C<(?adluimnsx-imnsx:I<pattern>)>
1461
1462 =item C<(?^aluimnsx:I<pattern>)>
1463 X<(?^:)>
1464
1465 This is for clustering, not capturing; it groups subexpressions like
1466 C<"()">, but doesn't make backreferences as C<"()"> does.  So
1467
1468     @fields = split(/\b(?:a|b|c)\b/)
1469
1470 matches the same field delimiters as
1471
1472     @fields = split(/\b(a|b|c)\b/)
1473
1474 but doesn't spit out the delimiters themselves as extra fields (even though
1475 that's the behaviour of L<perlfunc/split> when its pattern contains capturing
1476 groups).  It's also cheaper not to capture
1477 characters if you don't need to.
1478
1479 Any letters between C<"?"> and C<":"> act as flags modifiers as with
1480 C<(?adluimnsx-imnsx)>.  For example,
1481
1482     /(?s-i:more.*than).*million/i
1483
1484 is equivalent to the more verbose
1485
1486     /(?:(?s-i)more.*than).*million/i
1487
1488 Note that any C<()> constructs enclosed within this one will still
1489 capture unless the C</n> modifier is in effect.
1490
1491 Like the L</(?adlupimnsx-imnsx)> construct, C<aa> and C<"a"> override each
1492 other, as do C<xx> and C<"x">.  They are not additive.  So, doing
1493 something like C<(?xx-x:foo)> turns off all C<"x"> behavior for matching
1494 C<foo>.
1495
1496 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1497 after the C<"?"> is a shorthand equivalent to C<d-imnsx>.  Any positive
1498 flags (except C<"d">) may follow the caret, so
1499
1500     (?^x:foo)
1501
1502 is equivalent to
1503
1504     (?x-imns:foo)
1505
1506 The caret tells Perl that this cluster doesn't inherit the flags of any
1507 surrounding pattern, but uses the system defaults (C<d-imnsx>),
1508 modified by any flags specified.
1509
1510 The caret allows for simpler stringification of compiled regular
1511 expressions.  These look like
1512
1513     (?^:pattern)
1514
1515 with any non-default flags appearing between the caret and the colon.
1516 A test that looks at such stringification thus doesn't need to have the
1517 system default flags hard-coded in it, just the caret.  If new flags are
1518 added to Perl, the meaning of the caret's expansion will change to include
1519 the default for those flags, so the test will still work, unchanged.
1520
1521 Specifying a negative flag after the caret is an error, as the flag is
1522 redundant.
1523
1524 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1525 to match at the beginning.
1526
1527 =item C<(?|I<pattern>)>
1528 X<(?|)> X<Branch reset>
1529
1530 This is the "branch reset" pattern, which has the special property
1531 that the capture groups are numbered from the same starting point
1532 in each alternation branch. It is available starting from perl 5.10.0.
1533
1534 Capture groups are numbered from left to right, but inside this
1535 construct the numbering is restarted for each branch.
1536
1537 The numbering within each branch will be as normal, and any groups
1538 following this construct will be numbered as though the construct
1539 contained only one branch, that being the one with the most capture
1540 groups in it.
1541
1542 This construct is useful when you want to capture one of a
1543 number of alternative matches.
1544
1545 Consider the following pattern.  The numbers underneath show in
1546 which group the captured content will be stored.
1547
1548
1549     # before  ---------------branch-reset----------- after
1550     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1551     # 1            2         2  3        2     3     4
1552
1553 Be careful when using the branch reset pattern in combination with
1554 named captures. Named captures are implemented as being aliases to
1555 numbered groups holding the captures, and that interferes with the
1556 implementation of the branch reset pattern. If you are using named
1557 captures in a branch reset pattern, it's best to use the same names,
1558 in the same order, in each of the alternations:
1559
1560    /(?|  (?<a> x ) (?<b> y )
1561       |  (?<a> z ) (?<b> w )) /x
1562
1563 Not doing so may lead to surprises:
1564
1565   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1566   say $+{a};    # Prints '12'
1567   say $+{b};    # *Also* prints '12'.
1568
1569 The problem here is that both the group named C<< a >> and the group
1570 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1571
1572 =item Lookaround Assertions
1573 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1574
1575 Lookaround assertions are zero-width patterns which match a specific
1576 pattern without including it in C<$&>. Positive assertions match when
1577 their subpattern matches, negative assertions match when their subpattern
1578 fails. Lookbehind matches text up to the current match position,
1579 lookahead matches text following the current match position.
1580
1581 =over 4
1582
1583 =item C<(?=I<pattern>)>
1584
1585 =item C<(*pla:I<pattern>)>
1586
1587 =item C<(*positive_lookahead:I<pattern>)>
1588 X<(?=)>
1589 X<(*pla>
1590 X<(*positive_lookahead>
1591 X<look-ahead, positive> X<lookahead, positive>
1592
1593 A zero-width positive lookahead assertion.  For example, C</\w+(?=\t)/>
1594 matches a word followed by a tab, without including the tab in C<$&>.
1595
1596 The alphabetic forms are experimental; using them yields a warning in the
1597 C<experimental::alpha_assertions> category.
1598
1599 =item C<(?!I<pattern>)>
1600
1601 =item C<(*nla:I<pattern>)>
1602
1603 =item C<(*negative_lookahead:I<pattern>)>
1604 X<(?!)>
1605 X<(*nla>
1606 X<(*negative_lookahead>
1607 X<look-ahead, negative> X<lookahead, negative>
1608
1609 A zero-width negative lookahead assertion.  For example C</foo(?!bar)/>
1610 matches any occurrence of "foo" that isn't followed by "bar".  Note
1611 however that lookahead and lookbehind are NOT the same thing.  You cannot
1612 use this for lookbehind.
1613
1614 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1615 will not do what you want.  That's because the C<(?!foo)> is just saying that
1616 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1617 match.  Use lookbehind instead (see below).
1618
1619 The alphabetic forms are experimental; using them yields a warning in the
1620 C<experimental::alpha_assertions> category.
1621
1622 =item C<(?<=I<pattern>)>
1623
1624 =item C<\K>
1625
1626 =item C<(*plb:I<pattern>)>
1627
1628 =item C<(*positive_lookbehind:I<pattern>)>
1629 X<(?<=)>
1630 X<(*plb>
1631 X<(*positive_lookbehind>
1632 X<look-behind, positive> X<lookbehind, positive> X<\K>
1633
1634 A zero-width positive lookbehind assertion.  For example, C</(?<=\t)\w+/>
1635 matches a word that follows a tab, without including the tab in C<$&>.
1636
1637 Prior to Perl 5.30, it worked only for fixed-width lookbehind, but
1638 starting in that release, it can handle variable lengths from 1 to 255
1639 characters as an experimental feature.  The feature is enabled
1640 automatically if you use a variable length lookbehind assertion, but
1641 will raise a warning at pattern compilation time, unless turned off, in
1642 the C<experimental::vlb> category.  This is to warn you that the exact
1643 behavior is subject to change should feedback from actual use in the
1644 field indicate to do so; or even complete removal if the problems found
1645 are not practically surmountable.  You can achieve close to pre-5.30
1646 behavior by fatalizing warnings in this category.
1647
1648 There is a special form of this construct, called C<\K>
1649 (available since Perl 5.10.0), which causes the
1650 regex engine to "keep" everything it had matched prior to the C<\K> and
1651 not include it in C<$&>. This effectively provides non-experimental
1652 variable-length lookbehind of any length.
1653
1654 And, there is a technique that can be used to handle variable length
1655 lookbehinds on earlier releases, and longer than 255 characters.  It is
1656 described in
1657 L<http://www.drregex.com/2019/02/variable-length-lookbehinds-actually.html>.
1658
1659 Note that under C</i>, a few single characters match two or three other
1660 characters.  This makes them variable length, and the 255 length applies
1661 to the maximum number of characters in the match.  For
1662 example C<qr/\N{LATIN SMALL LETTER SHARP S}/i> matches the sequence
1663 C<"ss">.  Your lookbehind assertion could contain 127 Sharp S
1664 characters under C</i>, but adding a 128th would generate a compilation
1665 error, as that could match 256 C<"s"> characters in a row.
1666
1667 The use of C<\K> inside of another lookaround assertion
1668 is allowed, but the behaviour is currently not well defined.
1669
1670 For various reasons C<\K> may be significantly more efficient than the
1671 equivalent C<< (?<=...) >> construct, and it is especially useful in
1672 situations where you want to efficiently remove something following
1673 something else in a string. For instance
1674
1675   s/(foo)bar/$1/g;
1676
1677 can be rewritten as the much more efficient
1678
1679   s/foo\Kbar//g;
1680
1681 Use of the non-greedy modifier C<"?"> may not give you the expected
1682 results if it is within a capturing group within the construct.
1683
1684 The alphabetic forms (not including C<\K> are experimental; using them
1685 yields a warning in the C<experimental::alpha_assertions> category.
1686
1687 =item C<(?<!I<pattern>)>
1688
1689 =item C<(*nlb:I<pattern>)>
1690
1691 =item C<(*negative_lookbehind:I<pattern>)>
1692 X<(?<!)>
1693 X<(*nlb>
1694 X<(*negative_lookbehind>
1695 X<look-behind, negative> X<lookbehind, negative>
1696
1697 A zero-width negative lookbehind assertion.  For example C</(?<!bar)foo/>
1698 matches any occurrence of "foo" that does not follow "bar".
1699
1700 Prior to Perl 5.30, it worked only for fixed-width lookbehind, but
1701 starting in that release, it can handle variable lengths from 1 to 255
1702 characters as an experimental feature.  The feature is enabled
1703 automatically if you use a variable length lookbehind assertion, but
1704 will raise a warning at pattern compilation time, unless turned off, in
1705 the C<experimental::vlb> category.  This is to warn you that the exact
1706 behavior is subject to change should feedback from actual use in the
1707 field indicate to do so; or even complete removal if the problems found
1708 are not practically surmountable.  You can achieve close to pre-5.30
1709 behavior by fatalizing warnings in this category.
1710
1711 There is a technique that can be used to handle variable length
1712 lookbehinds on earlier releases, and longer than 255 characters.  It is
1713 described in
1714 L<http://www.drregex.com/2019/02/variable-length-lookbehinds-actually.html>.
1715
1716 Note that under C</i>, a few single characters match two or three other
1717 characters.  This makes them variable length, and the 255 length applies
1718 to the maximum number of characters in the match.  For
1719 example C<qr/\N{LATIN SMALL LETTER SHARP S}/i> matches the sequence
1720 C<"ss">.  Your lookbehind assertion could contain 127 Sharp S
1721 characters under C</i>, but adding a 128th would generate a compilation
1722 error, as that could match 256 C<"s"> characters in a row.
1723
1724 Use of the non-greedy modifier C<"?"> may not give you the expected
1725 results if it is within a capturing group within the construct.
1726
1727 The alphabetic forms are experimental; using them yields a warning in the
1728 C<experimental::alpha_assertions> category.
1729
1730 =back
1731
1732 =item C<< (?<I<NAME>>I<pattern>) >>
1733
1734 =item C<(?'I<NAME>'I<pattern>)>
1735 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1736
1737 A named capture group. Identical in every respect to normal capturing
1738 parentheses C<()> but for the additional fact that the group
1739 can be referred to by name in various regular expression
1740 constructs (like C<\g{I<NAME>}>) and can be accessed by name
1741 after a successful match via C<%+> or C<%->. See L<perlvar>
1742 for more details on the C<%+> and C<%-> hashes.
1743
1744 If multiple distinct capture groups have the same name, then
1745 C<$+{I<NAME>}> will refer to the leftmost defined group in the match.
1746
1747 The forms C<(?'I<NAME>'I<pattern>)> and C<< (?<I<NAME>>I<pattern>) >>
1748 are equivalent.
1749
1750 B<NOTE:> While the notation of this construct is the same as the similar
1751 function in .NET regexes, the behavior is not. In Perl the groups are
1752 numbered sequentially regardless of being named or not. Thus in the
1753 pattern
1754
1755   /(x)(?<foo>y)(z)/
1756
1757 C<$+{foo}> will be the same as C<$2>, and C<$3> will contain 'z' instead of
1758 the opposite which is what a .NET regex hacker might expect.
1759
1760 Currently I<NAME> is restricted to simple identifiers only.
1761 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1762 its Unicode extension (see L<utf8>),
1763 though it isn't extended by the locale (see L<perllocale>).
1764
1765 B<NOTE:> In order to make things easier for programmers with experience
1766 with the Python or PCRE regex engines, the pattern C<<
1767 (?PE<lt>I<NAME>E<gt>I<pattern>) >>
1768 may be used instead of C<< (?<I<NAME>>I<pattern>) >>; however this form does not
1769 support the use of single quotes as a delimiter for the name.
1770
1771 =item C<< \k<I<NAME>> >>
1772
1773 =item C<< \k'I<NAME>' >>
1774
1775 Named backreference. Similar to numeric backreferences, except that
1776 the group is designated by name and not number. If multiple groups
1777 have the same name then it refers to the leftmost defined group in
1778 the current match.
1779
1780 It is an error to refer to a name not defined by a C<< (?<I<NAME>>) >>
1781 earlier in the pattern.
1782
1783 Both forms are equivalent.
1784
1785 B<NOTE:> In order to make things easier for programmers with experience
1786 with the Python or PCRE regex engines, the pattern C<< (?P=I<NAME>) >>
1787 may be used instead of C<< \k<I<NAME>> >>.
1788
1789 =item C<(?{ I<code> })>
1790 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1791
1792 B<WARNING>: Using this feature safely requires that you understand its
1793 limitations.  Code executed that has side effects may not perform identically
1794 from version to version due to the effect of future optimisations in the regex
1795 engine.  For more information on this, see L</Embedded Code Execution
1796 Frequency>.
1797
1798 This zero-width assertion executes any embedded Perl code.  It always
1799 succeeds, and its return value is set as C<$^R>.
1800
1801 In literal patterns, the code is parsed at the same time as the
1802 surrounding code. While within the pattern, control is passed temporarily
1803 back to the perl parser, until the logically-balancing closing brace is
1804 encountered. This is similar to the way that an array index expression in
1805 a literal string is handled, for example
1806
1807     "abc$array[ 1 + f('[') + g()]def"
1808
1809 In particular, braces do not need to be balanced:
1810
1811     s/abc(?{ f('{'); })/def/
1812
1813 Even in a pattern that is interpolated and compiled at run-time, literal
1814 code blocks will be compiled once, at perl compile time; the following
1815 prints "ABCD":
1816
1817     print "D";
1818     my $qr = qr/(?{ BEGIN { print "A" } })/;
1819     my $foo = "foo";
1820     /$foo$qr(?{ BEGIN { print "B" } })/;
1821     BEGIN { print "C" }
1822
1823 In patterns where the text of the code is derived from run-time
1824 information rather than appearing literally in a source code /pattern/,
1825 the code is compiled at the same time that the pattern is compiled, and
1826 for reasons of security, C<use re 'eval'> must be in scope. This is to
1827 stop user-supplied patterns containing code snippets from being
1828 executable.
1829
1830 In situations where you need to enable this with C<use re 'eval'>, you should
1831 also have taint checking enabled.  Better yet, use the carefully
1832 constrained evaluation within a Safe compartment.  See L<perlsec> for
1833 details about both these mechanisms.
1834
1835 From the viewpoint of parsing, lexical variable scope and closures,
1836
1837     /AAA(?{ BBB })CCC/
1838
1839 behaves approximately like
1840
1841     /AAA/ && do { BBB } && /CCC/
1842
1843 Similarly,
1844
1845     qr/AAA(?{ BBB })CCC/
1846
1847 behaves approximately like
1848
1849     sub { /AAA/ && do { BBB } && /CCC/ }
1850
1851 In particular:
1852
1853     { my $i = 1; $r = qr/(?{ print $i })/ }
1854     my $i = 2;
1855     /$r/; # prints "1"
1856
1857 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1858 expression is matching against. You can also use C<pos()> to know what is
1859 the current position of matching within this string.
1860
1861 The code block introduces a new scope from the perspective of lexical
1862 variable declarations, but B<not> from the perspective of C<local> and
1863 similar localizing behaviours. So later code blocks within the same
1864 pattern will still see the values which were localized in earlier blocks.
1865 These accumulated localizations are undone either at the end of a
1866 successful match, or if the assertion is backtracked (compare
1867 L</"Backtracking">). For example,
1868
1869   $_ = 'a' x 8;
1870   m<
1871      (?{ $cnt = 0 })               # Initialize $cnt.
1872      (
1873        a
1874        (?{
1875            local $cnt = $cnt + 1;  # Update $cnt,
1876                                    # backtracking-safe.
1877        })
1878      )*
1879      aaaa
1880      (?{ $res = $cnt })            # On success copy to
1881                                    # non-localized location.
1882    >x;
1883
1884 will initially increment C<$cnt> up to 8; then during backtracking, its
1885 value will be unwound back to 4, which is the value assigned to C<$res>.
1886 At the end of the regex execution, C<$cnt> will be wound back to its initial
1887 value of 0.
1888
1889 This assertion may be used as the condition in a
1890
1891     (?(condition)yes-pattern|no-pattern)
1892
1893 switch.  If I<not> used in this way, the result of evaluation of I<code>
1894 is put into the special variable C<$^R>.  This happens immediately, so
1895 C<$^R> can be used from other C<(?{ I<code> })> assertions inside the same
1896 regular expression.
1897
1898 The assignment to C<$^R> above is properly localized, so the old
1899 value of C<$^R> is restored if the assertion is backtracked; compare
1900 L</"Backtracking">.
1901
1902 Note that the special variable C<$^N>  is particularly useful with code
1903 blocks to capture the results of submatches in variables without having to
1904 keep track of the number of nested parentheses. For example:
1905
1906   $_ = "The brown fox jumps over the lazy dog";
1907   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1908   print "color = $color, animal = $animal\n";
1909
1910
1911 =item C<(??{ I<code> })>
1912 X<(??{})>
1913 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1914
1915 B<WARNING>: Using this feature safely requires that you understand its
1916 limitations.  Code executed that has side effects may not perform
1917 identically from version to version due to the effect of future
1918 optimisations in the regex engine.  For more information on this, see
1919 L</Embedded Code Execution Frequency>.
1920
1921 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1922 same way as a C<(?{ I<code> })> code block as described above, except that
1923 its return value, rather than being assigned to C<$^R>, is treated as a
1924 pattern, compiled if it's a string (or used as-is if its a qr// object),
1925 then matched as if it were inserted instead of this construct.
1926
1927 During the matching of this sub-pattern, it has its own set of
1928 captures which are valid during the sub-match, but are discarded once
1929 control returns to the main pattern. For example, the following matches,
1930 with the inner pattern capturing "B" and matching "BB", while the outer
1931 pattern captures "A";
1932
1933     my $inner = '(.)\1';
1934     "ABBA" =~ /^(.)(??{ $inner })\1/;
1935     print $1; # prints "A";
1936
1937 Note that this means that  there is no way for the inner pattern to refer
1938 to a capture group defined outside.  (The code block itself can use C<$1>,
1939 I<etc>., to refer to the enclosing pattern's capture groups.)  Thus, although
1940
1941     ('a' x 100)=~/(??{'(.)' x 100})/
1942
1943 I<will> match, it will I<not> set C<$1> on exit.
1944
1945 The following pattern matches a parenthesized group:
1946
1947  $re = qr{
1948             \(
1949             (?:
1950                (?> [^()]+ )  # Non-parens without backtracking
1951              |
1952                (??{ $re })   # Group with matching parens
1953             )*
1954             \)
1955          }x;
1956
1957 See also
1958 L<C<(?I<PARNO>)>|/(?I<PARNO>) (?-I<PARNO>) (?+I<PARNO>) (?R) (?0)>
1959 for a different, more efficient way to accomplish
1960 the same task.
1961
1962 Executing a postponed regular expression too many times without
1963 consuming any input string will also result in a fatal error.  The depth
1964 at which that happens is compiled into perl, so it can be changed with a
1965 custom build.
1966
1967 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1968 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1969 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1970 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1971
1972 Recursive subpattern. Treat the contents of a given capture buffer in the
1973 current pattern as an independent subpattern and attempt to match it at
1974 the current position in the string. Information about capture state from
1975 the caller for things like backreferences is available to the subpattern,
1976 but capture buffers set by the subpattern are not visible to the caller.
1977
1978 Similar to C<(??{ I<code> })> except that it does not involve executing any
1979 code or potentially compiling a returned pattern string; instead it treats
1980 the part of the current pattern contained within a specified capture group
1981 as an independent pattern that must match at the current position. Also
1982 different is the treatment of capture buffers, unlike C<(??{ I<code> })>
1983 recursive patterns have access to their caller's match state, so one can
1984 use backreferences safely.
1985
1986 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1987 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1988 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1989 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1990 to be relative, with negative numbers indicating preceding capture groups
1991 and positive ones following. Thus C<(?-1)> refers to the most recently
1992 declared group, and C<(?+1)> indicates the next group to be declared.
1993 Note that the counting for relative recursion differs from that of
1994 relative backreferences, in that with recursion unclosed groups B<are>
1995 included.
1996
1997 The following pattern matches a function C<foo()> which may contain
1998 balanced parentheses as the argument.
1999
2000   $re = qr{ (                   # paren group 1 (full function)
2001               foo
2002               (                 # paren group 2 (parens)
2003                 \(
2004                   (             # paren group 3 (contents of parens)
2005                   (?:
2006                    (?> [^()]+ ) # Non-parens without backtracking
2007                   |
2008                    (?2)         # Recurse to start of paren group 2
2009                   )*
2010                   )
2011                 \)
2012               )
2013             )
2014           }x;
2015
2016 If the pattern was used as follows
2017
2018     'foo(bar(baz)+baz(bop))'=~/$re/
2019         and print "\$1 = $1\n",
2020                   "\$2 = $2\n",
2021                   "\$3 = $3\n";
2022
2023 the output produced should be the following:
2024
2025     $1 = foo(bar(baz)+baz(bop))
2026     $2 = (bar(baz)+baz(bop))
2027     $3 = bar(baz)+baz(bop)
2028
2029 If there is no corresponding capture group defined, then it is a
2030 fatal error.  Recursing deeply without consuming any input string will
2031 also result in a fatal error.  The depth at which that happens is
2032 compiled into perl, so it can be changed with a custom build.
2033
2034 The following shows how using negative indexing can make it
2035 easier to embed recursive patterns inside of a C<qr//> construct
2036 for later use:
2037
2038     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
2039     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
2040        # do something here...
2041     }
2042
2043 B<Note> that this pattern does not behave the same way as the equivalent
2044 PCRE or Python construct of the same form. In Perl you can backtrack into
2045 a recursed group, in PCRE and Python the recursed into group is treated
2046 as atomic. Also, modifiers are resolved at compile time, so constructs
2047 like C<(?i:(?1))> or C<(?:(?i)(?1))> do not affect how the sub-pattern will
2048 be processed.
2049
2050 =item C<(?&I<NAME>)>
2051 X<(?&NAME)>
2052
2053 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
2054 parenthesis to recurse to is determined by name. If multiple parentheses have
2055 the same name, then it recurses to the leftmost.
2056
2057 It is an error to refer to a name that is not declared somewhere in the
2058 pattern.
2059
2060 B<NOTE:> In order to make things easier for programmers with experience
2061 with the Python or PCRE regex engines the pattern C<< (?P>I<NAME>) >>
2062 may be used instead of C<< (?&I<NAME>) >>.
2063
2064 =item C<(?(I<condition>)I<yes-pattern>|I<no-pattern>)>
2065 X<(?()>
2066
2067 =item C<(?(I<condition>)I<yes-pattern>)>
2068
2069 Conditional expression. Matches I<yes-pattern> if I<condition> yields
2070 a true value, matches I<no-pattern> otherwise. A missing pattern always
2071 matches.
2072
2073 C<(I<condition>)> should be one of:
2074
2075 =over 4
2076
2077 =item an integer in parentheses
2078
2079 (which is valid if the corresponding pair of parentheses
2080 matched);
2081
2082 =item a lookahead/lookbehind/evaluate zero-width assertion;
2083
2084 =item a name in angle brackets or single quotes
2085
2086 (which is valid if a group with the given name matched);
2087
2088 =item the special symbol C<(R)>
2089
2090 (true when evaluated inside of recursion or eval).  Additionally the
2091 C<"R"> may be
2092 followed by a number, (which will be true when evaluated when recursing
2093 inside of the appropriate group), or by C<&I<NAME>>, in which case it will
2094 be true only when evaluated during recursion in the named group.
2095
2096 =back
2097
2098 Here's a summary of the possible predicates:
2099
2100 =over 4
2101
2102 =item C<(1)> C<(2)> ...
2103
2104 Checks if the numbered capturing group has matched something.
2105 Full syntax: C<< (?(1)then|else) >>
2106
2107 =item C<(E<lt>I<NAME>E<gt>)> C<('I<NAME>')>
2108
2109 Checks if a group with the given name has matched something.
2110 Full syntax: C<< (?(<name>)then|else) >>
2111
2112 =item C<(?=...)> C<(?!...)> C<(?<=...)> C<(?<!...)>
2113
2114 Checks whether the pattern matches (or does not match, for the C<"!">
2115 variants).
2116 Full syntax: C<< (?(?=I<lookahead>)I<then>|I<else>) >>
2117
2118 =item C<(?{ I<CODE> })>
2119
2120 Treats the return value of the code block as the condition.
2121 Full syntax: C<< (?(?{ I<code> })I<then>|I<else>) >>
2122
2123 =item C<(R)>
2124
2125 Checks if the expression has been evaluated inside of recursion.
2126 Full syntax: C<< (?(R)I<then>|I<else>) >>
2127
2128 =item C<(R1)> C<(R2)> ...
2129
2130 Checks if the expression has been evaluated while executing directly
2131 inside of the n-th capture group. This check is the regex equivalent of
2132
2133   if ((caller(0))[3] eq 'subname') { ... }
2134
2135 In other words, it does not check the full recursion stack.
2136
2137 Full syntax: C<< (?(R1)I<then>|I<else>) >>
2138
2139 =item C<(R&I<NAME>)>
2140
2141 Similar to C<(R1)>, this predicate checks to see if we're executing
2142 directly inside of the leftmost group with a given name (this is the same
2143 logic used by C<(?&I<NAME>)> to disambiguate). It does not check the full
2144 stack, but only the name of the innermost active recursion.
2145 Full syntax: C<< (?(R&I<name>)I<then>|I<else>) >>
2146
2147 =item C<(DEFINE)>
2148
2149 In this case, the yes-pattern is never directly executed, and no
2150 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
2151 See below for details.
2152 Full syntax: C<< (?(DEFINE)I<definitions>...) >>
2153
2154 =back
2155
2156 For example:
2157
2158     m{ ( \( )?
2159        [^()]+
2160        (?(1) \) )
2161      }x
2162
2163 matches a chunk of non-parentheses, possibly included in parentheses
2164 themselves.
2165
2166 A special form is the C<(DEFINE)> predicate, which never executes its
2167 yes-pattern directly, and does not allow a no-pattern. This allows one to
2168 define subpatterns which will be executed only by the recursion mechanism.
2169 This way, you can define a set of regular expression rules that can be
2170 bundled into any pattern you choose.
2171
2172 It is recommended that for this usage you put the DEFINE block at the
2173 end of the pattern, and that you name any subpatterns defined within it.
2174
2175 Also, it's worth noting that patterns defined this way probably will
2176 not be as efficient, as the optimizer is not very clever about
2177 handling them.
2178
2179 An example of how this might be used is as follows:
2180
2181   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
2182    (?(DEFINE)
2183      (?<NAME_PAT>....)
2184      (?<ADDRESS_PAT>....)
2185    )/x
2186
2187 Note that capture groups matched inside of recursion are not accessible
2188 after the recursion returns, so the extra layer of capturing groups is
2189 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
2190 C<$+{NAME}> would be.
2191
2192 Finally, keep in mind that subpatterns created inside a DEFINE block
2193 count towards the absolute and relative number of captures, so this:
2194
2195     my @captures = "a" =~ /(.)                  # First capture
2196                            (?(DEFINE)
2197                                (?<EXAMPLE> 1 )  # Second capture
2198                            )/x;
2199     say scalar @captures;
2200
2201 Will output 2, not 1. This is particularly important if you intend to
2202 compile the definitions with the C<qr//> operator, and later
2203 interpolate them in another pattern.
2204
2205 =item C<< (?>I<pattern>) >>
2206
2207 =item C<< (*atomic:I<pattern>) >>
2208 X<(?E<gt>pattern)>
2209 X<(*atomic>
2210 X<backtrack> X<backtracking> X<atomic> X<possessive>
2211
2212 An "independent" subexpression, one which matches the substring
2213 that a standalone I<pattern> would match if anchored at the given
2214 position, and it matches I<nothing other than this substring>.  This
2215 construct is useful for optimizations of what would otherwise be
2216 "eternal" matches, because it will not backtrack (see L</"Backtracking">).
2217 It may also be useful in places where the "grab all you can, and do not
2218 give anything back" semantic is desirable.
2219
2220 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
2221 (anchored at the beginning of string, as above) will match I<all>
2222 characters C<"a"> at the beginning of string, leaving no C<"a"> for
2223 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
2224 since the match of the subgroup C<a*> is influenced by the following
2225 group C<ab> (see L</"Backtracking">).  In particular, C<a*> inside
2226 C<a*ab> will match fewer characters than a standalone C<a*>, since
2227 this makes the tail match.
2228
2229 C<< (?>I<pattern>) >> does not disable backtracking altogether once it has
2230 matched. It is still possible to backtrack past the construct, but not
2231 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
2232
2233 An effect similar to C<< (?>I<pattern>) >> may be achieved by writing
2234 C<(?=(I<pattern>))\g{-1}>.  This matches the same substring as a standalone
2235 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
2236 makes a zero-length assertion into an analogue of C<< (?>...) >>.
2237 (The difference between these two constructs is that the second one
2238 uses a capturing group, thus shifting ordinals of backreferences
2239 in the rest of a regular expression.)
2240
2241 Consider this pattern:
2242
2243     m{ \(
2244           (
2245             [^()]+           # x+
2246           |
2247             \( [^()]* \)
2248           )+
2249        \)
2250      }x
2251
2252 That will efficiently match a nonempty group with matching parentheses
2253 two levels deep or less.  However, if there is no such group, it
2254 will take virtually forever on a long string.  That's because there
2255 are so many different ways to split a long string into several
2256 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
2257 to a subpattern of the above pattern.  Consider how the pattern
2258 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
2259 seconds, but that each extra letter doubles this time.  This
2260 exponential performance will make it appear that your program has
2261 hung.  However, a tiny change to this pattern
2262
2263     m{ \(
2264           (
2265             (?> [^()]+ )        # change x+ above to (?> x+ )
2266           |
2267             \( [^()]* \)
2268           )+
2269        \)
2270      }x
2271
2272 which uses C<< (?>...) >> matches exactly when the one above does (verifying
2273 this yourself would be a productive exercise), but finishes in a fourth
2274 the time when used on a similar string with 1000000 C<"a">s.  Be aware,
2275 however, that, when this construct is followed by a
2276 quantifier, it currently triggers a warning message under
2277 the C<use warnings> pragma or B<-w> switch saying it
2278 C<"matches null string many times in regex">.
2279
2280 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
2281 effect may be achieved by negative lookahead, as in C<[^()]+ (?! [^()] )>.
2282 This was only 4 times slower on a string with 1000000 C<"a">s.
2283
2284 The "grab all you can, and do not give anything back" semantic is desirable
2285 in many situations where on the first sight a simple C<()*> looks like
2286 the correct solution.  Suppose we parse text with comments being delimited
2287 by C<"#"> followed by some optional (horizontal) whitespace.  Contrary to
2288 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
2289 the comment delimiter, because it may "give up" some whitespace if
2290 the remainder of the pattern can be made to match that way.  The correct
2291 answer is either one of these:
2292
2293     (?>#[ \t]*)
2294     #[ \t]*(?![ \t])
2295
2296 For example, to grab non-empty comments into C<$1>, one should use either
2297 one of these:
2298
2299     / (?> \# [ \t]* ) (        .+ ) /x;
2300     /     \# [ \t]*   ( [^ \t] .* ) /x;
2301
2302 Which one you pick depends on which of these expressions better reflects
2303 the above specification of comments.
2304
2305 In some literature this construct is called "atomic matching" or
2306 "possessive matching".
2307
2308 Possessive quantifiers are equivalent to putting the item they are applied
2309 to inside of one of these constructs. The following equivalences apply:
2310
2311     Quantifier Form     Bracketing Form
2312     ---------------     ---------------
2313     PAT*+               (?>PAT*)
2314     PAT++               (?>PAT+)
2315     PAT?+               (?>PAT?)
2316     PAT{min,max}+       (?>PAT{min,max})
2317
2318 Nested C<(?E<gt>...)> constructs are not no-ops, even if at first glance
2319 they might seem to be.  This is because the nested C<(?E<gt>...)> can
2320 restrict internal backtracking that otherwise might occur.  For example,
2321
2322  "abc" =~ /(?>a[bc]*c)/
2323
2324 matches, but
2325
2326  "abc" =~ /(?>a(?>[bc]*)c)/
2327
2328 does not.
2329
2330 The alphabetic form (C<(*atomic:...)>) is experimental; using it
2331 yields a warning in the C<experimental::alpha_assertions> category.
2332
2333 =item C<(?[ ])>
2334
2335 See L<perlrecharclass/Extended Bracketed Character Classes>.
2336
2337 Note that this feature is currently L<experimental|perlpolicy/experimental>;
2338 using it yields a warning in the C<experimental::regex_sets> category.
2339
2340 =back
2341
2342 =head2 Backtracking
2343 X<backtrack> X<backtracking>
2344
2345 NOTE: This section presents an abstract approximation of regular
2346 expression behavior.  For a more rigorous (and complicated) view of
2347 the rules involved in selecting a match among possible alternatives,
2348 see L</Combining RE Pieces>.
2349
2350 A fundamental feature of regular expression matching involves the
2351 notion called I<backtracking>, which is currently used (when needed)
2352 by all regular non-possessive expression quantifiers, namely C<"*">, C<*?>, C<"+">,
2353 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2354 internally, but the general principle outlined here is valid.
2355
2356 For a regular expression to match, the I<entire> regular expression must
2357 match, not just part of it.  So if the beginning of a pattern containing a
2358 quantifier succeeds in a way that causes later parts in the pattern to
2359 fail, the matching engine backs up and recalculates the beginning
2360 part--that's why it's called backtracking.
2361
2362 Here is an example of backtracking:  Let's say you want to find the
2363 word following "foo" in the string "Food is on the foo table.":
2364
2365     $_ = "Food is on the foo table.";
2366     if ( /\b(foo)\s+(\w+)/i ) {
2367         print "$2 follows $1.\n";
2368     }
2369
2370 When the match runs, the first part of the regular expression (C<\b(foo)>)
2371 finds a possible match right at the beginning of the string, and loads up
2372 C<$1> with "Foo".  However, as soon as the matching engine sees that there's
2373 no whitespace following the "Foo" that it had saved in C<$1>, it realizes its
2374 mistake and starts over again one character after where it had the
2375 tentative match.  This time it goes all the way until the next occurrence
2376 of "foo". The complete regular expression matches this time, and you get
2377 the expected output of "table follows foo."
2378
2379 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2380 everything between "foo" and "bar".  Initially, you write something
2381 like this:
2382
2383     $_ =  "The food is under the bar in the barn.";
2384     if ( /foo(.*)bar/ ) {
2385         print "got <$1>\n";
2386     }
2387
2388 Which perhaps unexpectedly yields:
2389
2390   got <d is under the bar in the >
2391
2392 That's because C<.*> was greedy, so you get everything between the
2393 I<first> "foo" and the I<last> "bar".  Here it's more effective
2394 to use minimal matching to make sure you get the text between a "foo"
2395 and the first "bar" thereafter.
2396
2397     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2398   got <d is under the >
2399
2400 Here's another example. Let's say you'd like to match a number at the end
2401 of a string, and you also want to keep the preceding part of the match.
2402 So you write this:
2403
2404     $_ = "I have 2 numbers: 53147";
2405     if ( /(.*)(\d*)/ ) {                                # Wrong!
2406         print "Beginning is <$1>, number is <$2>.\n";
2407     }
2408
2409 That won't work at all, because C<.*> was greedy and gobbled up the
2410 whole string. As C<\d*> can match on an empty string the complete
2411 regular expression matched successfully.
2412
2413     Beginning is <I have 2 numbers: 53147>, number is <>.
2414
2415 Here are some variants, most of which don't work:
2416
2417     $_ = "I have 2 numbers: 53147";
2418     @pats = qw{
2419         (.*)(\d*)
2420         (.*)(\d+)
2421         (.*?)(\d*)
2422         (.*?)(\d+)
2423         (.*)(\d+)$
2424         (.*?)(\d+)$
2425         (.*)\b(\d+)$
2426         (.*\D)(\d+)$
2427     };
2428
2429     for $pat (@pats) {
2430         printf "%-12s ", $pat;
2431         if ( /$pat/ ) {
2432             print "<$1> <$2>\n";
2433         } else {
2434             print "FAIL\n";
2435         }
2436     }
2437
2438 That will print out:
2439
2440     (.*)(\d*)    <I have 2 numbers: 53147> <>
2441     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2442     (.*?)(\d*)   <> <>
2443     (.*?)(\d+)   <I have > <2>
2444     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2445     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2446     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2447     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2448
2449 As you see, this can be a bit tricky.  It's important to realize that a
2450 regular expression is merely a set of assertions that gives a definition
2451 of success.  There may be 0, 1, or several different ways that the
2452 definition might succeed against a particular string.  And if there are
2453 multiple ways it might succeed, you need to understand backtracking to
2454 know which variety of success you will achieve.
2455
2456 When using lookahead assertions and negations, this can all get even
2457 trickier.  Imagine you'd like to find a sequence of non-digits not
2458 followed by "123".  You might try to write that as
2459
2460     $_ = "ABC123";
2461     if ( /^\D*(?!123)/ ) {                # Wrong!
2462         print "Yup, no 123 in $_\n";
2463     }
2464
2465 But that isn't going to match; at least, not the way you're hoping.  It
2466 claims that there is no 123 in the string.  Here's a clearer picture of
2467 why that pattern matches, contrary to popular expectations:
2468
2469     $x = 'ABC123';
2470     $y = 'ABC445';
2471
2472     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2473     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2474
2475     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2476     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2477
2478 This prints
2479
2480     2: got ABC
2481     3: got AB
2482     4: got ABC
2483
2484 You might have expected test 3 to fail because it seems to a more
2485 general purpose version of test 1.  The important difference between
2486 them is that test 3 contains a quantifier (C<\D*>) and so can use
2487 backtracking, whereas test 1 will not.  What's happening is
2488 that you've asked "Is it true that at the start of C<$x>, following 0 or more
2489 non-digits, you have something that's not 123?"  If the pattern matcher had
2490 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2491 fail.
2492
2493 The search engine will initially match C<\D*> with "ABC".  Then it will
2494 try to match C<(?!123)> with "123", which fails.  But because
2495 a quantifier (C<\D*>) has been used in the regular expression, the
2496 search engine can backtrack and retry the match differently
2497 in the hope of matching the complete regular expression.
2498
2499 The pattern really, I<really> wants to succeed, so it uses the
2500 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2501 time.  Now there's indeed something following "AB" that is not
2502 "123".  It's "C123", which suffices.
2503
2504 We can deal with this by using both an assertion and a negation.
2505 We'll say that the first part in C<$1> must be followed both by a digit
2506 and by something that's not "123".  Remember that the lookaheads
2507 are zero-width expressions--they only look, but don't consume any
2508 of the string in their match.  So rewriting this way produces what
2509 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2510
2511     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2512     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2513
2514     6: got ABC
2515
2516 In other words, the two zero-width assertions next to each other work as though
2517 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2518 matches only if you're at the beginning of the line AND the end of the
2519 line simultaneously.  The deeper underlying truth is that juxtaposition in
2520 regular expressions always means AND, except when you write an explicit OR
2521 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2522 although the attempted matches are made at different positions because "a"
2523 is not a zero-width assertion, but a one-width assertion.
2524
2525 B<WARNING>: Particularly complicated regular expressions can take
2526 exponential time to solve because of the immense number of possible
2527 ways they can use backtracking to try for a match.  For example, without
2528 internal optimizations done by the regular expression engine, this will
2529 take a painfully long time to run:
2530
2531     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2532
2533 And if you used C<"*">'s in the internal groups instead of limiting them
2534 to 0 through 5 matches, then it would take forever--or until you ran
2535 out of stack space.  Moreover, these internal optimizations are not
2536 always applicable.  For example, if you put C<{0,5}> instead of C<"*">
2537 on the external group, no current optimization is applicable, and the
2538 match takes a long time to finish.
2539
2540 A powerful tool for optimizing such beasts is what is known as an
2541 "independent group",
2542 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2543 zero-length lookahead/lookbehind assertions will not backtrack to make
2544 the tail match, since they are in "logical" context: only
2545 whether they match is considered relevant.  For an example
2546 where side-effects of lookahead I<might> have influenced the
2547 following match, see L</C<< (?>pattern) >>>.
2548
2549 =head2 Script Runs
2550 X<(*script_run:...)> X<(sr:...)>
2551 X<(*atomic_script_run:...)> X<(asr:...)>
2552
2553 A script run is basically a sequence of characters, all from the same
2554 Unicode script (see L<perlunicode/Scripts>), such as Latin or Greek.  In
2555 most places a single word would never be written in multiple scripts,
2556 unless it is a spoofing attack.  An infamous example, is
2557
2558  paypal.com
2559
2560 Those letters could all be Latin (as in the example just above), or they
2561 could be all Cyrillic (except for the dot), or they could be a mixture
2562 of the two.  In the case of an internet address the C<.com> would be in
2563 Latin, And any Cyrillic ones would cause it to be a mixture, not a
2564 script run.  Someone clicking on such a link would not be directed to
2565 the real Paypal website, but an attacker would craft a look-alike one to
2566 attempt to gather sensitive information from the person.
2567
2568 Starting in Perl 5.28, it is now easy to detect strings that aren't
2569 script runs.  Simply enclose just about any pattern like either of
2570 these:
2571
2572  (*script_run:pattern)
2573  (*sr:pattern)
2574
2575 What happens is that after I<pattern> succeeds in matching, it is
2576 subjected to the additional criterion that every character in it must be
2577 from the same script (see exceptions below).  If this isn't true,
2578 backtracking occurs until something all in the same script is found that
2579 matches, or all possibilities are exhausted.  This can cause a lot of
2580 backtracking, but generally, only malicious input will result in this,
2581 though the slow down could cause a denial of service attack.  If your
2582 needs permit, it is best to make the pattern atomic to cut down on the
2583 amount of backtracking.  This is so likely to be what you want, that
2584 instead of writing this:
2585
2586  (*script_run:(?>pattern))
2587
2588 you can write either of these:
2589
2590  (*atomic_script_run:pattern)
2591  (*asr:pattern)
2592
2593 (See L</C<(?E<gt>I<pattern>)>>.)
2594
2595 In Taiwan, Japan, and Korea, it is common for text to have a mixture of
2596 characters from their native scripts and base Chinese.  Perl follows
2597 Unicode's UTS 39 (L<http://unicode.org/reports/tr39/>) Unicode Security
2598 Mechanisms in allowing such mixtures.  For example, the Japanese scripts
2599 Katakana and Hiragana are commonly mixed together in practice, along
2600 with some Chinese characters, and hence are treated as being in a single
2601 script run by Perl.
2602
2603 The rules used for matching decimal digits are slightly stricter.  Many
2604 scripts have their own sets of digits equivalent to the Western C<0>
2605 through C<9> ones.  A few, such as Arabic, have more than one set.  For
2606 a string to be considered a script run, all digits in it must come from
2607 the same set of ten, as determined by the first digit encountered.
2608 As an example,
2609
2610  qr/(*script_run: \d+ \b )/x
2611
2612 guarantees that the digits matched will all be from the same set of 10.
2613 You won't get a look-alike digit from a different script that has a
2614 different value than what it appears to be.
2615
2616 Unicode has three pseudo scripts that are handled specially.
2617
2618 "Unknown" is applied to code points whose meaning has yet to be
2619 determined.  Perl currently will match as a script run, any single
2620 character string consisting of one of these code points.  But any string
2621 longer than one code point containing one of these will not be
2622 considered a script run.
2623
2624 "Inherited" is applied to characters that modify another, such as an
2625 accent of some type.  These are considered to be in the script of the
2626 master character, and so never cause a script run to not match.
2627
2628 The other one is "Common".  This consists of mostly punctuation, emoji,
2629 and characters used in mathematics and music, the ASCII digits C<0>
2630 through C<9>, and full-width forms of these digits.  These characters
2631 can appear intermixed in text in many of the world's scripts.  These
2632 also don't cause a script run to not match.  But like other scripts, all
2633 digits in a run must come from the same set of 10.
2634
2635 This construct is non-capturing.  You can add parentheses to I<pattern>
2636 to capture, if desired.  You will have to do this if you plan to use
2637 L</(*ACCEPT) (*ACCEPT:arg)> and not have it bypass the script run
2638 checking.
2639
2640 This feature is experimental, and the exact syntax and details of
2641 operation are subject to change; using it yields a warning in the
2642 C<experimental::script_run> category.
2643
2644 The C<Script_Extensions> property as modified by UTS 39
2645 (L<http://unicode.org/reports/tr39/>) is used as the basis for this
2646 feature.
2647
2648 To summarize,
2649
2650 =over 4
2651
2652 =item *
2653
2654 All length 0 or length 1 sequences are script runs.
2655
2656 =item *
2657
2658 A longer sequence is a script run if and only if B<all> of the following
2659 conditions are met:
2660
2661 Z<>
2662
2663 =over
2664
2665 =item 1
2666
2667 No code point in the sequence has the C<Script_Extension> property of
2668 C<Unknown>.
2669
2670 This currently means that all code points in the sequence have been
2671 assigned by Unicode to be characters that aren't private use nor
2672 surrogate code points.
2673
2674 =item 2
2675
2676 All characters in the sequence come from the Common script and/or the
2677 Inherited script and/or a single other script.
2678
2679 The script of a character is determined by the C<Script_Extensions>
2680 property as modified by UTS 39 (L<http://unicode.org/reports/tr39/>), as
2681 described above.
2682
2683 =item 3
2684
2685 All decimal digits in the sequence come from the same block of 10
2686 consecutive digits.
2687
2688 =back
2689
2690 =back
2691
2692 =head2 Special Backtracking Control Verbs
2693
2694 These special patterns are generally of the form C<(*I<VERB>:I<arg>)>. Unless
2695 otherwise stated the I<arg> argument is optional; in some cases, it is
2696 mandatory.
2697
2698 Any pattern containing a special backtracking verb that allows an argument
2699 has the special behaviour that when executed it sets the current package's
2700 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
2701 rules apply:
2702
2703 On failure, the C<$REGERROR> variable will be set to the I<arg> value of the
2704 verb pattern, if the verb was involved in the failure of the match. If the
2705 I<arg> part of the pattern was omitted, then C<$REGERROR> will be set to the
2706 name of the last C<(*MARK:I<NAME>)> pattern executed, or to TRUE if there was
2707 none. Also, the C<$REGMARK> variable will be set to FALSE.
2708
2709 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
2710 the C<$REGMARK> variable will be set to the name of the last
2711 C<(*MARK:I<NAME>)> pattern executed.  See the explanation for the
2712 C<(*MARK:I<NAME>)> verb below for more details.
2713
2714 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
2715 and most other regex-related variables. They are not local to a scope, nor
2716 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
2717 They are set in the package containing the code that I<executed> the regex
2718 (rather than the one that compiled it, where those differ).  If necessary, you
2719 can use C<local> to localize changes to these variables to a specific scope
2720 before executing a regex.
2721
2722 If a pattern does not contain a special backtracking verb that allows an
2723 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
2724
2725 =over 3
2726
2727 =item Verbs
2728
2729 =over 4
2730
2731 =item C<(*PRUNE)> C<(*PRUNE:I<NAME>)>
2732 X<(*PRUNE)> X<(*PRUNE:NAME)>
2733
2734 This zero-width pattern prunes the backtracking tree at the current point
2735 when backtracked into on failure. Consider the pattern C</I<A> (*PRUNE) I<B>/>,
2736 where I<A> and I<B> are complex patterns. Until the C<(*PRUNE)> verb is reached,
2737 I<A> may backtrack as necessary to match. Once it is reached, matching
2738 continues in I<B>, which may also backtrack as necessary; however, should B
2739 not match, then no further backtracking will take place, and the pattern
2740 will fail outright at the current starting position.
2741
2742 The following example counts all the possible matching strings in a
2743 pattern (without actually matching any of them).
2744
2745     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
2746     print "Count=$count\n";
2747
2748 which produces:
2749
2750     aaab
2751     aaa
2752     aa
2753     a
2754     aab
2755     aa
2756     a
2757     ab
2758     a
2759     Count=9
2760
2761 If we add a C<(*PRUNE)> before the count like the following
2762
2763     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
2764     print "Count=$count\n";
2765
2766 we prevent backtracking and find the count of the longest matching string
2767 at each matching starting point like so:
2768
2769     aaab
2770     aab
2771     ab
2772     Count=3
2773
2774 Any number of C<(*PRUNE)> assertions may be used in a pattern.
2775
2776 See also C<<< L<< /(?>I<pattern>) >> >>> and possessive quantifiers for
2777 other ways to
2778 control backtracking. In some cases, the use of C<(*PRUNE)> can be
2779 replaced with a C<< (?>pattern) >> with no functional difference; however,
2780 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
2781 C<< (?>pattern) >> alone.
2782
2783 =item C<(*SKIP)> C<(*SKIP:I<NAME>)>
2784 X<(*SKIP)>
2785
2786 This zero-width pattern is similar to C<(*PRUNE)>, except that on
2787 failure it also signifies that whatever text that was matched leading up
2788 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
2789 of this pattern. This effectively means that the regex engine "skips" forward
2790 to this position on failure and tries to match again, (assuming that
2791 there is sufficient room to match).
2792
2793 The name of the C<(*SKIP:I<NAME>)> pattern has special significance. If a
2794 C<(*MARK:I<NAME>)> was encountered while matching, then it is that position
2795 which is used as the "skip point". If no C<(*MARK)> of that name was
2796 encountered, then the C<(*SKIP)> operator has no effect. When used
2797 without a name the "skip point" is where the match point was when
2798 executing the C<(*SKIP)> pattern.
2799
2800 Compare the following to the examples in C<(*PRUNE)>; note the string
2801 is twice as long:
2802
2803  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
2804  print "Count=$count\n";
2805
2806 outputs
2807
2808     aaab
2809     aaab
2810     Count=2
2811
2812 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
2813 executed, the next starting point will be where the cursor was when the
2814 C<(*SKIP)> was executed.
2815
2816 =item C<(*MARK:I<NAME>)> C<(*:I<NAME>)>
2817 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
2818
2819 This zero-width pattern can be used to mark the point reached in a string
2820 when a certain part of the pattern has been successfully matched. This
2821 mark may be given a name. A later C<(*SKIP)> pattern will then skip
2822 forward to that point if backtracked into on failure. Any number of
2823 C<(*MARK)> patterns are allowed, and the I<NAME> portion may be duplicated.
2824
2825 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:I<NAME>)>
2826 can be used to "label" a pattern branch, so that after matching, the
2827 program can determine which branches of the pattern were involved in the
2828 match.
2829
2830 When a match is successful, the C<$REGMARK> variable will be set to the
2831 name of the most recently executed C<(*MARK:I<NAME>)> that was involved
2832 in the match.
2833
2834 This can be used to determine which branch of a pattern was matched
2835 without using a separate capture group for each branch, which in turn
2836 can result in a performance improvement, as perl cannot optimize
2837 C</(?:(x)|(y)|(z))/> as efficiently as something like
2838 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
2839
2840 When a match has failed, and unless another verb has been involved in
2841 failing the match and has provided its own name to use, the C<$REGERROR>
2842 variable will be set to the name of the most recently executed
2843 C<(*MARK:I<NAME>)>.
2844
2845 See L</(*SKIP)> for more details.
2846
2847 As a shortcut C<(*MARK:I<NAME>)> can be written C<(*:I<NAME>)>.
2848
2849 =item C<(*THEN)> C<(*THEN:I<NAME>)>
2850
2851 This is similar to the "cut group" operator C<::> from Perl 6.  Like
2852 C<(*PRUNE)>, this verb always matches, and when backtracked into on
2853 failure, it causes the regex engine to try the next alternation in the
2854 innermost enclosing group (capturing or otherwise) that has alternations.
2855 The two branches of a C<(?(I<condition>)I<yes-pattern>|I<no-pattern>)> do not
2856 count as an alternation, as far as C<(*THEN)> is concerned.
2857
2858 Its name comes from the observation that this operation combined with the
2859 alternation operator (C<"|">) can be used to create what is essentially a
2860 pattern-based if/then/else block:
2861
2862   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2863
2864 Note that if this operator is used and NOT inside of an alternation then
2865 it acts exactly like the C<(*PRUNE)> operator.
2866
2867   / A (*PRUNE) B /
2868
2869 is the same as
2870
2871   / A (*THEN) B /
2872
2873 but
2874
2875   / ( A (*THEN) B | C ) /
2876
2877 is not the same as
2878
2879   / ( A (*PRUNE) B | C ) /
2880
2881 as after matching the I<A> but failing on the I<B> the C<(*THEN)> verb will
2882 backtrack and try I<C>; but the C<(*PRUNE)> verb will simply fail.
2883
2884 =item C<(*COMMIT)> C<(*COMMIT:I<arg>)>
2885 X<(*COMMIT)>
2886
2887 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2888 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2889 into on failure it causes the match to fail outright. No further attempts
2890 to find a valid match by advancing the start pointer will occur again.
2891 For example,
2892
2893  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2894  print "Count=$count\n";
2895
2896 outputs
2897
2898     aaab
2899     Count=1
2900
2901 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2902 does not match, the regex engine will not try any further matching on the
2903 rest of the string.
2904
2905 =item C<(*FAIL)> C<(*F)> C<(*FAIL:I<arg>)>
2906 X<(*FAIL)> X<(*F)>
2907
2908 This pattern matches nothing and always fails. It can be used to force the
2909 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2910 fact, C<(?!)> gets optimised into C<(*FAIL)> internally. You can provide
2911 an argument so that if the match fails because of this C<FAIL> directive
2912 the argument can be obtained from C<$REGERROR>.
2913
2914 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2915
2916 =item C<(*ACCEPT)> C<(*ACCEPT:I<arg>)>
2917 X<(*ACCEPT)>
2918
2919 This pattern matches nothing and causes the end of successful matching at
2920 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2921 whether there is actually more to match in the string. When inside of a
2922 nested pattern, such as recursion, or in a subpattern dynamically generated
2923 via C<(??{})>, only the innermost pattern is ended immediately.
2924
2925 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2926 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2927 For instance:
2928
2929   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2930
2931 will match, and C<$1> will be C<AB> and C<$2> will be C<"B">, C<$3> will not
2932 be set. If another branch in the inner parentheses was matched, such as in the
2933 string 'ACDE', then the C<"D"> and C<"E"> would have to be matched as well.
2934
2935 You can provide an argument, which will be available in the var
2936 C<$REGMARK> after the match completes.
2937
2938 =back
2939
2940 =back
2941
2942 =head2 Warning on C<\1> Instead of C<$1>
2943
2944 Some people get too used to writing things like:
2945
2946     $pattern =~ s/(\W)/\\\1/g;
2947
2948 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2949 shocking the
2950 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2951 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2952 the usual double-quoted string means a control-A.  The customary Unix
2953 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2954 of doing that, you get yourself into trouble if you then add an C</e>
2955 modifier.
2956
2957     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2958
2959 Or if you try to do
2960
2961     s/(\d+)/\1000/;
2962
2963 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2964 C<${1}000>.  The operation of interpolation should not be confused
2965 with the operation of matching a backreference.  Certainly they mean two
2966 different things on the I<left> side of the C<s///>.
2967
2968 =head2 Repeated Patterns Matching a Zero-length Substring
2969
2970 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2971
2972 Regular expressions provide a terse and powerful programming language.  As
2973 with most other power tools, power comes together with the ability
2974 to wreak havoc.
2975
2976 A common abuse of this power stems from the ability to make infinite
2977 loops using regular expressions, with something as innocuous as:
2978
2979     'foo' =~ m{ ( o? )* }x;
2980
2981 The C<o?> matches at the beginning of "C<foo>", and since the position
2982 in the string is not moved by the match, C<o?> would match again and again
2983 because of the C<"*"> quantifier.  Another common way to create a similar cycle
2984 is with the looping modifier C</g>:
2985
2986     @matches = ( 'foo' =~ m{ o? }xg );
2987
2988 or
2989
2990     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2991
2992 or the loop implied by C<split()>.
2993
2994 However, long experience has shown that many programming tasks may
2995 be significantly simplified by using repeated subexpressions that
2996 may match zero-length substrings.  Here's a simple example being:
2997
2998     @chars = split //, $string;           # // is not magic in split
2999     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
3000
3001 Thus Perl allows such constructs, by I<forcefully breaking
3002 the infinite loop>.  The rules for this are different for lower-level
3003 loops given by the greedy quantifiers C<*+{}>, and for higher-level
3004 ones like the C</g> modifier or C<split()> operator.
3005
3006 The lower-level loops are I<interrupted> (that is, the loop is
3007 broken) when Perl detects that a repeated expression matched a
3008 zero-length substring.   Thus
3009
3010    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
3011
3012 is made equivalent to
3013
3014    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
3015
3016 For example, this program
3017
3018    #!perl -l
3019    "aaaaab" =~ /
3020      (?:
3021         a                 # non-zero
3022         |                 # or
3023        (?{print "hello"}) # print hello whenever this
3024                           #    branch is tried
3025        (?=(b))            # zero-width assertion
3026      )*  # any number of times
3027     /x;
3028    print $&;
3029    print $1;
3030
3031 prints
3032
3033    hello
3034    aaaaa
3035    b
3036
3037 Notice that "hello" is only printed once, as when Perl sees that the sixth
3038 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
3039 the C<"*">.
3040
3041 The higher-level loops preserve an additional state between iterations:
3042 whether the last match was zero-length.  To break the loop, the following
3043 match after a zero-length match is prohibited to have a length of zero.
3044 This prohibition interacts with backtracking (see L</"Backtracking">),
3045 and so the I<second best> match is chosen if the I<best> match is of
3046 zero length.
3047
3048 For example:
3049
3050     $_ = 'bar';
3051     s/\w??/<$&>/g;
3052
3053 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
3054 match given by non-greedy C<??> is the zero-length match, and the I<second
3055 best> match is what is matched by C<\w>.  Thus zero-length matches
3056 alternate with one-character-long matches.
3057
3058 Similarly, for repeated C<m/()/g> the second-best match is the match at the
3059 position one notch further in the string.
3060
3061 The additional state of being I<matched with zero-length> is associated with
3062 the matched string, and is reset by each assignment to C<pos()>.
3063 Zero-length matches at the end of the previous match are ignored
3064 during C<split>.
3065
3066 =head2 Combining RE Pieces
3067
3068 Each of the elementary pieces of regular expressions which were described
3069 before (such as C<ab> or C<\Z>) could match at most one substring
3070 at the given position of the input string.  However, in a typical regular
3071 expression these elementary pieces are combined into more complicated
3072 patterns using combining operators C<ST>, C<S|T>, C<S*> I<etc>.
3073 (in these examples C<"S"> and C<"T"> are regular subexpressions).
3074
3075 Such combinations can include alternatives, leading to a problem of choice:
3076 if we match a regular expression C<a|ab> against C<"abc">, will it match
3077 substring C<"a"> or C<"ab">?  One way to describe which substring is
3078 actually matched is the concept of backtracking (see L</"Backtracking">).
3079 However, this description is too low-level and makes you think
3080 in terms of a particular implementation.
3081
3082 Another description starts with notions of "better"/"worse".  All the
3083 substrings which may be matched by the given regular expression can be
3084 sorted from the "best" match to the "worst" match, and it is the "best"
3085 match which is chosen.  This substitutes the question of "what is chosen?"
3086 by the question of "which matches are better, and which are worse?".
3087
3088 Again, for elementary pieces there is no such question, since at most
3089 one match at a given position is possible.  This section describes the
3090 notion of better/worse for combining operators.  In the description
3091 below C<"S"> and C<"T"> are regular subexpressions.
3092
3093 =over 4
3094
3095 =item C<ST>
3096
3097 Consider two possible matches, C<AB> and C<A'B'>, C<"A"> and C<A'> are
3098 substrings which can be matched by C<"S">, C<"B"> and C<B'> are substrings
3099 which can be matched by C<"T">.
3100
3101 If C<"A"> is a better match for C<"S"> than C<A'>, C<AB> is a better
3102 match than C<A'B'>.
3103
3104 If C<"A"> and C<A'> coincide: C<AB> is a better match than C<AB'> if
3105 C<"B"> is a better match for C<"T"> than C<B'>.
3106
3107 =item C<S|T>
3108
3109 When C<"S"> can match, it is a better match than when only C<"T"> can match.
3110
3111 Ordering of two matches for C<"S"> is the same as for C<"S">.  Similar for
3112 two matches for C<"T">.
3113
3114 =item C<S{REPEAT_COUNT}>
3115
3116 Matches as C<SSS...S> (repeated as many times as necessary).
3117
3118 =item C<S{min,max}>
3119
3120 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
3121
3122 =item C<S{min,max}?>
3123
3124 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
3125
3126 =item C<S?>, C<S*>, C<S+>
3127
3128 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
3129
3130 =item C<S??>, C<S*?>, C<S+?>
3131
3132 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
3133
3134 =item C<< (?>S) >>
3135
3136 Matches the best match for C<"S"> and only that.
3137
3138 =item C<(?=S)>, C<(?<=S)>
3139
3140 Only the best match for C<"S"> is considered.  (This is important only if
3141 C<"S"> has capturing parentheses, and backreferences are used somewhere
3142 else in the whole regular expression.)
3143
3144 =item C<(?!S)>, C<(?<!S)>
3145
3146 For this grouping operator there is no need to describe the ordering, since
3147 only whether or not C<"S"> can match is important.
3148
3149 =item C<(??{ I<EXPR> })>, C<(?I<PARNO>)>
3150
3151 The ordering is the same as for the regular expression which is
3152 the result of I<EXPR>, or the pattern contained by capture group I<PARNO>.
3153
3154 =item C<(?(I<condition>)I<yes-pattern>|I<no-pattern>)>
3155
3156 Recall that which of I<yes-pattern> or I<no-pattern> actually matches is
3157 already determined.  The ordering of the matches is the same as for the
3158 chosen subexpression.
3159
3160 =back
3161
3162 The above recipes describe the ordering of matches I<at a given position>.
3163 One more rule is needed to understand how a match is determined for the
3164 whole regular expression: a match at an earlier position is always better
3165 than a match at a later position.
3166
3167 =head2 Creating Custom RE Engines
3168
3169 As of Perl 5.10.0, one can create custom regular expression engines.  This
3170 is not for the faint of heart, as they have to plug in at the C level.  See
3171 L<perlreapi> for more details.
3172
3173 As an alternative, overloaded constants (see L<overload>) provide a simple
3174 way to extend the functionality of the RE engine, by substituting one
3175 pattern for another.
3176
3177 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
3178 matches at a boundary between whitespace characters and non-whitespace
3179 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
3180 at these positions, so we want to have each C<\Y|> in the place of the
3181 more complicated version.  We can create a module C<customre> to do
3182 this:
3183
3184     package customre;
3185     use overload;
3186
3187     sub import {
3188       shift;
3189       die "No argument to customre::import allowed" if @_;
3190       overload::constant 'qr' => \&convert;
3191     }
3192
3193     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
3194
3195     # We must also take care of not escaping the legitimate \\Y|
3196     # sequence, hence the presence of '\\' in the conversion rules.
3197     my %rules = ( '\\' => '\\\\',
3198                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
3199     sub convert {
3200       my $re = shift;
3201       $re =~ s{
3202                 \\ ( \\ | Y . )
3203               }
3204               { $rules{$1} or invalid($re,$1) }sgex;
3205       return $re;
3206     }
3207
3208 Now C<use customre> enables the new escape in constant regular
3209 expressions, I<i.e.>, those without any runtime variable interpolations.
3210 As documented in L<overload>, this conversion will work only over
3211 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
3212 part of this regular expression needs to be converted explicitly
3213 (but only if the special meaning of C<\Y|> should be enabled inside C<$re>):
3214
3215     use customre;
3216     $re = <>;
3217     chomp $re;
3218     $re = customre::convert $re;
3219     /\Y|$re\Y|/;
3220
3221 =head2 Embedded Code Execution Frequency
3222
3223 The exact rules for how often C<(??{})> and C<(?{})> are executed in a pattern
3224 are unspecified.  In the case of a successful match you can assume that
3225 they DWIM and will be executed in left to right order the appropriate
3226 number of times in the accepting path of the pattern as would any other
3227 meta-pattern.  How non-accepting pathways and match failures affect the
3228 number of times a pattern is executed is specifically unspecified and
3229 may vary depending on what optimizations can be applied to the pattern
3230 and is likely to change from version to version.
3231
3232 For instance in
3233
3234   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
3235
3236 the exact number of times "a" or "b" are printed out is unspecified for
3237 failure, but you may assume they will be printed at least once during
3238 a successful match, additionally you may assume that if "b" is printed,
3239 it will be preceded by at least one "a".
3240
3241 In the case of branching constructs like the following:
3242
3243   /a(b|(?{ print "a" }))c(?{ print "c" })/;
3244
3245 you can assume that the input "ac" will output "ac", and that "abc"
3246 will output only "c".
3247
3248 When embedded code is quantified, successful matches will call the
3249 code once for each matched iteration of the quantifier.  For
3250 example:
3251
3252   "good" =~ /g(?:o(?{print "o"}))*d/;
3253
3254 will output "o" twice.
3255
3256 =head2 PCRE/Python Support
3257
3258 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
3259 to the regex syntax. While Perl programmers are encouraged to use the
3260 Perl-specific syntax, the following are also accepted:
3261
3262 =over 4
3263
3264 =item C<< (?PE<lt>I<NAME>E<gt>I<pattern>) >>
3265
3266 Define a named capture group. Equivalent to C<< (?<I<NAME>>I<pattern>) >>.
3267
3268 =item C<< (?P=I<NAME>) >>
3269
3270 Backreference to a named capture group. Equivalent to C<< \g{I<NAME>} >>.
3271
3272 =item C<< (?P>I<NAME>) >>
3273
3274 Subroutine call to a named capture group. Equivalent to C<< (?&I<NAME>) >>.
3275
3276 =back
3277
3278 =head1 BUGS
3279
3280 There are a number of issues with regard to case-insensitive matching
3281 in Unicode rules.  See C<"i"> under L</Modifiers> above.
3282
3283 This document varies from difficult to understand to completely
3284 and utterly opaque.  The wandering prose riddled with jargon is
3285 hard to fathom in several places.
3286
3287 This document needs a rewrite that separates the tutorial content
3288 from the reference content.
3289
3290 =head1 SEE ALSO
3291
3292 The syntax of patterns used in Perl pattern matching evolved from those
3293 supplied in the Bell Labs Research Unix 8th Edition (Version 8) regex
3294 routines.  (The code is actually derived (distantly) from Henry
3295 Spencer's freely redistributable reimplementation of those V8 routines.)
3296
3297 L<perlrequick>.
3298
3299 L<perlretut>.
3300
3301 L<perlop/"Regexp Quote-Like Operators">.
3302
3303 L<perlop/"Gory details of parsing quoted constructs">.
3304
3305 L<perlfaq6>.
3306
3307 L<perlfunc/pos>.
3308
3309 L<perllocale>.
3310
3311 L<perlebcdic>.
3312
3313 I<Mastering Regular Expressions> by Jeffrey Friedl, published
3314 by O'Reilly and Associates.