This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Change syntax of script runs
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a tutorial introduction
11 is available in L<perlretut>.  If you know just a little about them,
12 a quick-start introduction is available in L<perlrequick>.
13
14 Except for L</The Basics> section, this page assumes you are familiar
15 with regular expression basics, like what is a "pattern", what does it
16 look like, and how it is basically used.  For a reference on how they
17 are used, plus various examples of the same, see discussions of C<m//>,
18 C<s///>, C<qr//> and C<"??"> in L<perlop/"Regexp Quote-Like Operators">.
19
20 New in v5.22, L<C<use re 'strict'>|re/'strict' mode> applies stricter
21 rules than otherwise when compiling regular expression patterns.  It can
22 find things that, while legal, may not be what you intended.
23
24 =head2 The Basics
25 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
26
27 Regular expressions are strings with the very particular syntax and
28 meaning described in this document and auxiliary documents referred to
29 by this one.  The strings are called "patterns".  Patterns are used to
30 determine if some other string, called the "target", has (or doesn't
31 have) the characteristics specified by the pattern.  We call this
32 "matching" the target string against the pattern.  Usually the match is
33 done by having the target be the first operand, and the pattern be the
34 second operand, of one of the two binary operators C<=~> and C<!~>,
35 listed in L<perlop/Binding Operators>; and the pattern will have been
36 converted from an ordinary string by one of the operators in
37 L<perlop/"Regexp Quote-Like Operators">, like so:
38
39  $foo =~ m/abc/
40
41 This evaluates to true if and only if the string in the variable C<$foo>
42 contains somewhere in it, the sequence of characters "a", "b", then "c".
43 (The C<=~ m>, or match operator, is described in
44 L<perlop/m/PATTERN/msixpodualngc>.)
45
46 Patterns that aren't already stored in some variable must be delimitted,
47 at both ends, by delimitter characters.  These are often, as in the
48 example above, forward slashes, and the typical way a pattern is written
49 in documentation is with those slashes.  In most cases, the delimitter
50 is the same character, fore and aft, but there are a few cases where a
51 character looks like it has a mirror-image mate, where the opening
52 version is the beginning delimiter, and the closing one is the ending
53 delimiter, like
54
55  $foo =~ m<abc>
56
57 Most times, the pattern is evaluated in double-quotish context, but it
58 is possible to choose delimiters to force single-quotish, like
59
60  $foo =~ m'abc'
61
62 If the pattern contains its delimiter within it, that delimiter must be
63 escaped.  Prefixing it with a backslash (I<e.g.>, C<"/foo\/bar/">)
64 serves this purpose.
65
66 Any single character in a pattern matches that same character in the
67 target string, unless the character is a I<metacharacter> with a special
68 meaning described in this document.  A sequence of non-metacharacters
69 matches the same sequence in the target string, as we saw above with
70 C<m/abc/>.
71
72 Only a few characters (all of them being ASCII punctuation characters)
73 are metacharacters.  The most commonly used one is a dot C<".">, which
74 normally matches almost any character (including a dot itself).
75
76 You can cause characters that normally function as metacharacters to be
77 interpreted literally by prefixing them with a C<"\">, just like the
78 pattern's delimiter must be escaped if it also occurs within the
79 pattern.  Thus, C<"\."> matches just a literal dot, C<"."> instead of
80 its normal meaning.  This means that the backslash is also a
81 metacharacter, so C<"\\"> matches a single C<"\">.  And a sequence that
82 contains an escaped metacharacter matches the same sequence (but without
83 the escape) in the target string.  So, the pattern C</blur\\fl/> would
84 match any target string that contains the sequence C<"blur\fl">.
85
86 The metacharacter C<"|"> is used to match one thing or another.  Thus
87
88  $foo =~ m/this|that/
89
90 is TRUE if and only if C<$foo> contains either the sequence C<"this"> or
91 the sequence C<"that">.  Like all metacharacters, prefixing the C<"|">
92 with a backslash makes it match the plain punctuation character; in its
93 case, the VERTICAL LINE.
94
95  $foo =~ m/this\|that/
96
97 is TRUE if and only if C<$foo> contains the sequence C<"this|that">.
98
99 You aren't limited to just a single C<"|">.
100
101  $foo =~ m/fee|fie|foe|fum/
102
103 is TRUE if and only if C<$foo> contains any of those 4 sequences from
104 the children's story "Jack and the Beanstalk".
105
106 As you can see, the C<"|"> binds less tightly than a sequence of
107 ordinary characters.  We can override this by using the grouping
108 metacharacters, the parentheses C<"("> and C<")">.
109
110  $foo =~ m/th(is|at) thing/
111
112 is TRUE if and only if C<$foo> contains either the sequence S<C<"this
113 thing">> or the sequence S<C<"that thing">>.  The portions of the string
114 that match the portions of the pattern enclosed in parentheses are
115 normally made available separately for use later in the pattern,
116 substitution, or program.  This is called "capturing", and it can get
117 complicated.  See L</Capture groups>.
118
119 The first alternative includes everything from the last pattern
120 delimiter (C<"(">, C<"(?:"> (described later), I<etc>. or the beginning
121 of the pattern) up to the first C<"|">, and the last alternative
122 contains everything from the last C<"|"> to the next closing pattern
123 delimiter.  That's why it's common practice to include alternatives in
124 parentheses: to minimize confusion about where they start and end.
125
126 Alternatives are tried from left to right, so the first
127 alternative found for which the entire expression matches, is the one that
128 is chosen. This means that alternatives are not necessarily greedy. For
129 example: when matching C<foo|foot> against C<"barefoot">, only the C<"foo">
130 part will match, as that is the first alternative tried, and it successfully
131 matches the target string. (This might not seem important, but it is
132 important when you are capturing matched text using parentheses.)
133
134 Besides taking away the special meaning of a metacharacter, a prefixed
135 backslash changes some letter and digit characters away from matching
136 just themselves to instead have special meaning.  These are called
137 "escape sequences", and all such are described in L<perlrebackslash>.  A
138 backslash sequence (of a letter or digit) that doesn't currently have
139 special meaning to Perl will raise a warning if warnings are enabled,
140 as those are reserved for potential future use.
141
142 One such sequence is C<\b>, which matches a boundary of some sort.
143 C<\b{wb}> and a few others give specialized types of boundaries.
144 (They are all described in detail starting at
145 L<perlrebackslash/\b{}, \b, \B{}, \B>.)  Note that these don't match
146 characters, but the zero-width spaces between characters.  They are an
147 example of a L<zero-width assertion|/Assertions>.  Consider again,
148
149  $foo =~ m/fee|fie|foe|fum/
150
151 It evaluates to TRUE if, besides those 4 words, any of the sequences
152 "feed", "field", "Defoe", "fume", and many others are in C<$foo>.  By
153 judicious use of C<\b> (or better (because it is designed to handle
154 natural language) C<\b{wb}>), we can make sure that only the Giant's
155 words are matched:
156
157  $foo =~ m/\b(fee|fie|foe|fum)\b/
158  $foo =~ m/\b{wb}(fee|fie|foe|fum)\b{wb}/
159
160 The final example shows that the characters C<"{"> and C<"}"> are
161 metacharacters.
162
163 Another use for escape sequences is to specify characters that cannot
164 (or which you prefer not to) be written literally.  These are described
165 in detail in L<perlrebackslash/Character Escapes>, but the next three
166 paragraphs briefly describe some of them.
167
168 Various control characters can be written in C language style: C<"\n">
169 matches a newline, C<"\t"> a tab, C<"\r"> a carriage return, C<"\f"> a
170 form feed, I<etc>.
171
172 More generally, C<\I<nnn>>, where I<nnn> is a string of three octal
173 digits, matches the character whose native code point is I<nnn>.  You
174 can easily run into trouble if you don't have exactly three digits.  So
175 always use three, or since Perl 5.14, you can use C<\o{...}> to specify
176 any number of octal digits.
177
178 Similarly, C<\xI<nn>>, where I<nn> are hexadecimal digits, matches the
179 character whose native ordinal is I<nn>.  Again, not using exactly two
180 digits is a recipe for disaster, but you can use C<\x{...}> to specify
181 any number of hex digits.
182
183 Besides being a metacharacter, the C<"."> is an example of a "character
184 class", something that can match any single character of a given set of
185 them.  In its case, the set is just about all possible characters.  Perl
186 predefines several character classes besides the C<".">; there is a
187 separate reference page about just these, L<perlrecharclass>.
188
189 You can define your own custom character classes, by putting into your
190 pattern in the appropriate place(s), a list of all the characters you
191 want in the set.  You do this by enclosing the list within C<[]> bracket
192 characters.  These are called "bracketed character classes" when we are
193 being precise, but often the word "bracketed" is dropped.  (Dropping it
194 usually doesn't cause confusion.)  This means that the C<"["> character
195 is another metacharacter.  It doesn't match anything just by itelf; it
196 is used only to tell Perl that what follows it is a bracketed character
197 class.  If you want to match a literal left square bracket, you must
198 escape it, like C<"\[">.  The matching C<"]"> is also a metacharacter;
199 again it doesn't match anything by itself, but just marks the end of
200 your custom class to Perl.  It is an example of a "sometimes
201 metacharacter".  It isn't a metacharacter if there is no corresponding
202 C<"[">, and matches its literal self:
203
204  print "]" =~ /]/;  # prints 1
205
206 The list of characters within the character class gives the set of
207 characters matched by the class.  C<"[abc]"> matches a single "a" or "b"
208 or "c".  But if the first character after the C<"["> is C<"^">, the
209 class instead matches any character not in the list.  Within a list, the
210 C<"-"> character specifies a range of characters, so that C<a-z>
211 represents all characters between "a" and "z", inclusive.  If you want
212 either C<"-"> or C<"]"> itself to be a member of a class, put it at the
213 start of the list (possibly after a C<"^">), or escape it with a
214 backslash.  C<"-"> is also taken literally when it is at the end of the
215 list, just before the closing C<"]">.  (The following all specify the
216 same class of three characters: C<[-az]>, C<[az-]>, and C<[a\-z]>.  All
217 are different from C<[a-z]>, which specifies a class containing
218 twenty-six characters, even on EBCDIC-based character sets.)
219
220 There is lots more to bracketed character classes; full details are in
221 L<perlrecharclass/Bracketed Character Classes>.
222
223 =head3 Metacharacters
224 X<metacharacter>
225 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
226
227 L</The Basics> introduced some of the metacharacters.  This section
228 gives them all.  Most of them have the same meaning as in the I<egrep>
229 command.
230
231 Only the C<"\"> is always a metacharacter.  The others are metacharacters
232 just sometimes.  The following tables lists all of them, summarizes
233 their use, and gives the contexts where they are metacharacters.
234 Outside those contexts or if prefixed by a C<"\">, they match their
235 corresponding punctuation character.  In some cases, their meaning
236 varies depending on various pattern modifiers that alter the default
237 behaviors.  See L</Modifiers>.
238
239
240             PURPOSE                                  WHERE
241  \   Escape the next character                    Always, except when
242                                                   escaped by another \
243  ^   Match the beginning of the string            Not in []
244        (or line, if /m is used)
245  ^   Complement the [] class                      At the beginning of []
246  .   Match any single character except newline    Not in []
247        (under /s, includes newline)
248  $   Match the end of the string                  Not in [], but can
249        (or before newline at the end of the       mean interpolate a
250        string; or before any newline if /m is     scalar
251        used)
252  |   Alternation                                  Not in []
253  ()  Grouping                                     Not in []
254  [   Start Bracketed Character class              Not in []
255  ]   End Bracketed Character class                Only in [], and
256                                                     not first
257  *   Matches the preceding element 0 or more      Not in []
258        times
259  +   Matches the preceding element 1 or more      Not in []
260        times
261  ?   Matches the preceding element 0 or 1         Not in []
262        times
263  {   Starts a sequence that gives number(s)       Not in []
264        of times the preceding element can be
265        matched
266  {   when following certain escape sequences
267        starts a modifier to the meaning of the
268        sequence
269  }   End sequence started by {
270  -   Indicates a range                            Only in [] interior
271  #   Beginning of comment, extends to line end    Only with /x modifier
272
273 Notice that most of the metacharacters lose their special meaning when
274 they occur in a bracketed character class, except C<"^"> has a different
275 meaning when it is at the beginning of such a class.  And C<"-"> and C<"]">
276 are metacharacters only at restricted positions within bracketed
277 character classes; while C<"}"> is a metacharacter only when closing a
278 special construct started by C<"{">.
279
280 In double-quotish context, as is usually the case,  you need to be
281 careful about C<"$"> and the non-metacharacter C<"@">.  Those could
282 interpolate variables, which may or may not be what you intended.
283
284 These rules were designed for compactness of expression, rather than
285 legibility and maintainability.  The L</E<sol>x and E<sol>xx> pattern
286 modifiers allow you to insert white space to improve readability.  And
287 use of S<C<L<re 'strict'|re/'strict' mode>>> adds extra checking to
288 catch some typos that might silently compile into something unintended.
289
290 By default, the C<"^"> character is guaranteed to match only the
291 beginning of the string, the C<"$"> character only the end (or before the
292 newline at the end), and Perl does certain optimizations with the
293 assumption that the string contains only one line.  Embedded newlines
294 will not be matched by C<"^"> or C<"$">.  You may, however, wish to treat a
295 string as a multi-line buffer, such that the C<"^"> will match after any
296 newline within the string (except if the newline is the last character in
297 the string), and C<"$"> will match before any newline.  At the
298 cost of a little more overhead, you can do this by using the
299 L</C<E<sol>m>> modifier on the pattern match operator.  (Older programs
300 did this by setting C<$*>, but this option was removed in perl 5.10.)
301 X<^> X<$> X</m>
302
303 To simplify multi-line substitutions, the C<"."> character never matches a
304 newline unless you use the L<C<E<sol>s>|/s> modifier, which in effect tells
305 Perl to pretend the string is a single line--even if it isn't.
306 X<.> X</s>
307
308 =head2 Modifiers
309
310 =head3 Overview
311
312 The default behavior for matching can be changed, using various
313 modifiers.  Modifiers that relate to the interpretation of the pattern
314 are listed just below.  Modifiers that alter the way a pattern is used
315 by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
316 L<perlop/"Gory details of parsing quoted constructs">.
317
318 =over 4
319
320 =item B<C<m>>
321 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
322
323 Treat the string being matched against as multiple lines.  That is, change C<"^"> and C<"$"> from matching
324 the start of the string's first line and the end of its last line to
325 matching the start and end of each line within the string.
326
327 =item B<C<s>>
328 X</s> X<regex, single-line> X<regexp, single-line>
329 X<regular expression, single-line>
330
331 Treat the string as single line.  That is, change C<"."> to match any character
332 whatsoever, even a newline, which normally it would not match.
333
334 Used together, as C</ms>, they let the C<"."> match any character whatsoever,
335 while still allowing C<"^"> and C<"$"> to match, respectively, just after
336 and just before newlines within the string.
337
338 =item B<C<i>>
339 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
340 X<regular expression, case-insensitive>
341
342 Do case-insensitive pattern matching.  For example, "A" will match "a"
343 under C</i>.
344
345 If locale matching rules are in effect, the case map is taken from the
346 current
347 locale for code points less than 255, and from Unicode rules for larger
348 code points.  However, matches that would cross the Unicode
349 rules/non-Unicode rules boundary (ords 255/256) will not succeed, unless
350 the locale is a UTF-8 one.  See L<perllocale>.
351
352 There are a number of Unicode characters that match a sequence of
353 multiple characters under C</i>.  For example,
354 C<LATIN SMALL LIGATURE FI> should match the sequence C<fi>.  Perl is not
355 currently able to do this when the multiple characters are in the pattern and
356 are split between groupings, or when one or more are quantified.  Thus
357
358  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
359  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
360  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
361
362  # The below doesn't match, and it isn't clear what $1 and $2 would
363  # be even if it did!!
364  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
365
366 Perl doesn't match multiple characters in a bracketed
367 character class unless the character that maps to them is explicitly
368 mentioned, and it doesn't match them at all if the character class is
369 inverted, which otherwise could be highly confusing.  See
370 L<perlrecharclass/Bracketed Character Classes>, and
371 L<perlrecharclass/Negation>.
372
373 =item B<C<x>> and B<C<xx>>
374 X</x>
375
376 Extend your pattern's legibility by permitting whitespace and comments.
377 Details in L</E<sol>x and  E<sol>xx>
378
379 =item B<C<p>>
380 X</p> X<regex, preserve> X<regexp, preserve>
381
382 Preserve the string matched such that C<${^PREMATCH}>, C<${^MATCH}>, and
383 C<${^POSTMATCH}> are available for use after matching.
384
385 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
386 mechanism, C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> will be available
387 after the match regardless of the modifier.
388
389 =item B<C<a>>, B<C<d>>, B<C<l>>, and B<C<u>>
390 X</a> X</d> X</l> X</u>
391
392 These modifiers, all new in 5.14, affect which character-set rules
393 (Unicode, I<etc>.) are used, as described below in
394 L</Character set modifiers>.
395
396 =item B<C<n>>
397 X</n> X<regex, non-capture> X<regexp, non-capture>
398 X<regular expression, non-capture>
399
400 Prevent the grouping metacharacters C<()> from capturing. This modifier,
401 new in 5.22, will stop C<$1>, C<$2>, I<etc>... from being filled in.
402
403   "hello" =~ /(hi|hello)/;   # $1 is "hello"
404   "hello" =~ /(hi|hello)/n;  # $1 is undef
405
406 This is equivalent to putting C<?:> at the beginning of every capturing group:
407
408   "hello" =~ /(?:hi|hello)/; # $1 is undef
409
410 C</n> can be negated on a per-group basis. Alternatively, named captures
411 may still be used.
412
413   "hello" =~ /(?-n:(hi|hello))/n;   # $1 is "hello"
414   "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
415                                     # "hello"
416
417 =item Other Modifiers
418
419 There are a number of flags that can be found at the end of regular
420 expression constructs that are I<not> generic regular expression flags, but
421 apply to the operation being performed, like matching or substitution (C<m//>
422 or C<s///> respectively).
423
424 Flags described further in
425 L<perlretut/"Using regular expressions in Perl"> are:
426
427   c  - keep the current position during repeated matching
428   g  - globally match the pattern repeatedly in the string
429
430 Substitution-specific modifiers described in
431 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualngcer"> are:
432
433   e  - evaluate the right-hand side as an expression
434   ee - evaluate the right side as a string then eval the result
435   o  - pretend to optimize your code, but actually introduce bugs
436   r  - perform non-destructive substitution and return the new value
437
438 =back
439
440 Regular expression modifiers are usually written in documentation
441 as I<e.g.>, "the C</x> modifier", even though the delimiter
442 in question might not really be a slash.  The modifiers C</imnsxadlup>
443 may also be embedded within the regular expression itself using
444 the C<(?...)> construct, see L</Extended Patterns> below.
445
446 =head3 Details on some modifiers
447
448 Some of the modifiers require more explanation than given in the
449 L</Overview> above.
450
451 =head4 C</x> and  C</xx>
452
453 A single C</x> tells
454 the regular expression parser to ignore most whitespace that is neither
455 backslashed nor within a bracketed character class.  You can use this to
456 break up your regular expression into more readable parts.
457 Also, the C<"#"> character is treated as a metacharacter introducing a
458 comment that runs up to the pattern's closing delimiter, or to the end
459 of the current line if the pattern extends onto the next line.  Hence,
460 this is very much like an ordinary Perl code comment.  (You can include
461 the closing delimiter within the comment only if you precede it with a
462 backslash, so be careful!)
463
464 Use of C</x> means that if you want real
465 whitespace or C<"#"> characters in the pattern (outside a bracketed character
466 class, which is unaffected by C</x>), then you'll either have to
467 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
468 hex, or C<\N{}> escapes.
469 It is ineffective to try to continue a comment onto the next line by
470 escaping the C<\n> with a backslash or C<\Q>.
471
472 You can use L</(?#text)> to create a comment that ends earlier than the
473 end of the current line, but C<text> also can't contain the closing
474 delimiter unless escaped with a backslash.
475
476 A common pitfall is to forget that C<"#"> characters begin a comment under
477 C</x> and are not matched literally.  Just keep that in mind when trying
478 to puzzle out why a particular C</x> pattern isn't working as expected.
479
480 Starting in Perl v5.26, if the modifier has a second C<"x"> within it,
481 it does everything that a single C</x> does, but additionally
482 non-backslashed SPACE and TAB characters within bracketed character
483 classes are also generally ignored, and hence can be added to make the
484 classes more readable.
485
486     / [d-e g-i 3-7]/xx
487     /[ ! @ " # $ % ^ & * () = ? <> ' ]/xx
488
489 may be easier to grasp than the squashed equivalents
490
491     /[d-eg-i3-7]/
492     /[!@"#$%^&*()=?<>']/
493
494 Taken together, these features go a long way towards
495 making Perl's regular expressions more readable.  Here's an example:
496
497     # Delete (most) C comments.
498     $program =~ s {
499         /\*     # Match the opening delimiter.
500         .*?     # Match a minimal number of characters.
501         \*/     # Match the closing delimiter.
502     } []gsx;
503
504 Note that anything inside
505 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
506 space interpretation within a single multi-character construct.  For
507 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
508 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
509 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<"(">,
510 C<"?">, and C<":">.  Within any delimiters for such a
511 construct, allowed spaces are not affected by C</x>, and depend on the
512 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
513 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
514 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
515 L<perluniprops/Properties accessible through \p{} and \P{}>.
516 X</x>
517
518 The set of characters that are deemed whitespace are those that Unicode
519 calls "Pattern White Space", namely:
520
521  U+0009 CHARACTER TABULATION
522  U+000A LINE FEED
523  U+000B LINE TABULATION
524  U+000C FORM FEED
525  U+000D CARRIAGE RETURN
526  U+0020 SPACE
527  U+0085 NEXT LINE
528  U+200E LEFT-TO-RIGHT MARK
529  U+200F RIGHT-TO-LEFT MARK
530  U+2028 LINE SEPARATOR
531  U+2029 PARAGRAPH SEPARATOR
532
533 =head4 Character set modifiers
534
535 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
536 the character set modifiers; they affect the character set rules
537 used for the regular expression.
538
539 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
540 to you, and so you need not worry about them very much.  They exist for
541 Perl's internal use, so that complex regular expression data structures
542 can be automatically serialized and later exactly reconstituted,
543 including all their nuances.  But, since Perl can't keep a secret, and
544 there may be rare instances where they are useful, they are documented
545 here.
546
547 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
548 allow code that is to work mostly on ASCII data to not have to concern
549 itself with Unicode.
550
551 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
552 effect at the time of the execution of the pattern match.
553
554 C</u> sets the character set to B<U>nicode.
555
556 C</a> also sets the character set to Unicode, BUT adds several
557 restrictions for B<A>SCII-safe matching.
558
559 C</d> is the old, problematic, pre-5.14 B<D>efault character set
560 behavior.  Its only use is to force that old behavior.
561
562 At any given time, exactly one of these modifiers is in effect.  Their
563 existence allows Perl to keep the originally compiled behavior of a
564 regular expression, regardless of what rules are in effect when it is
565 actually executed.  And if it is interpolated into a larger regex, the
566 original's rules continue to apply to it, and only it.
567
568 The C</l> and C</u> modifiers are automatically selected for
569 regular expressions compiled within the scope of various pragmas,
570 and we recommend that in general, you use those pragmas instead of
571 specifying these modifiers explicitly.  For one thing, the modifiers
572 affect only pattern matching, and do not extend to even any replacement
573 done, whereas using the pragmas gives consistent results for all
574 appropriate operations within their scopes.  For example,
575
576  s/foo/\Ubar/il
577
578 will match "foo" using the locale's rules for case-insensitive matching,
579 but the C</l> does not affect how the C<\U> operates.  Most likely you
580 want both of them to use locale rules.  To do this, instead compile the
581 regular expression within the scope of C<use locale>.  This both
582 implicitly adds the C</l>, and applies locale rules to the C<\U>.   The
583 lesson is to C<use locale>, and not C</l> explicitly.
584
585 Similarly, it would be better to use C<use feature 'unicode_strings'>
586 instead of,
587
588  s/foo/\Lbar/iu
589
590 to get Unicode rules, as the C<\L> in the former (but not necessarily
591 the latter) would also use Unicode rules.
592
593 More detail on each of the modifiers follows.  Most likely you don't
594 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
595 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
596
597 =head4 /l
598
599 means to use the current locale's rules (see L<perllocale>) when pattern
600 matching.  For example, C<\w> will match the "word" characters of that
601 locale, and C<"/i"> case-insensitive matching will match according to
602 the locale's case folding rules.  The locale used will be the one in
603 effect at the time of execution of the pattern match.  This may not be
604 the same as the compilation-time locale, and can differ from one match
605 to another if there is an intervening call of the
606 L<setlocale() function|perllocale/The setlocale function>.
607
608 Prior to v5.20, Perl did not support multi-byte locales.  Starting then,
609 UTF-8 locales are supported.  No other multi byte locales are ever
610 likely to be supported.  However, in all locales, one can have code
611 points above 255 and these will always be treated as Unicode no matter
612 what locale is in effect.
613
614 Under Unicode rules, there are a few case-insensitive matches that cross
615 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
616 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
617 platforms) does not caselessly match the character at 0x178, C<LATIN
618 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
619 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
620 knowing if that character even exists in the locale, much less what code
621 point it is.
622
623 In a UTF-8 locale in v5.20 and later, the only visible difference
624 between locale and non-locale in regular expressions should be tainting
625 (see L<perlsec>).
626
627 This modifier may be specified to be the default by C<use locale>, but
628 see L</Which character set modifier is in effect?>.
629 X</l>
630
631 =head4 /u
632
633 means to use Unicode rules when pattern matching.  On ASCII platforms,
634 this means that the code points between 128 and 255 take on their
635 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
636 (Otherwise Perl considers their meanings to be undefined.)  Thus,
637 under this modifier, the ASCII platform effectively becomes a Unicode
638 platform; and hence, for example, C<\w> will match any of the more than
639 100_000 word characters in Unicode.
640
641 Unlike most locales, which are specific to a language and country pair,
642 Unicode classifies all the characters that are letters I<somewhere> in
643 the world as
644 C<\w>.  For example, your locale might not think that C<LATIN SMALL
645 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
646 Unicode does.  Similarly, all the characters that are decimal digits
647 somewhere in the world will match C<\d>; this is hundreds, not 10,
648 possible matches.  And some of those digits look like some of the 10
649 ASCII digits, but mean a different number, so a human could easily think
650 a number is a different quantity than it really is.  For example,
651 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
652 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
653 that are a mixture from different writing systems, creating a security
654 issue.  L<Unicode::UCD/num()> can be used to sort
655 this out.  Or the C</a> modifier can be used to force C<\d> to match
656 just the ASCII 0 through 9.
657
658 Also, under this modifier, case-insensitive matching works on the full
659 set of Unicode
660 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
661 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
662 if you're not prepared, might make it look like a hexadecimal constant,
663 presenting another potential security issue.  See
664 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
665 security issues.
666
667 This modifier may be specified to be the default by C<use feature
668 'unicode_strings>, C<use locale ':not_characters'>, or
669 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
670 but see L</Which character set modifier is in effect?>.
671 X</u>
672
673 =head4 /d
674
675 This modifier means to use the "Default" native rules of the platform
676 except when there is cause to use Unicode rules instead, as follows:
677
678 =over 4
679
680 =item 1
681
682 the target string is encoded in UTF-8; or
683
684 =item 2
685
686 the pattern is encoded in UTF-8; or
687
688 =item 3
689
690 the pattern explicitly mentions a code point that is above 255 (say by
691 C<\x{100}>); or
692
693 =item 4
694
695 the pattern uses a Unicode name (C<\N{...}>);  or
696
697 =item 5
698
699 the pattern uses a Unicode property (C<\p{...}> or C<\P{...}>); or
700
701 =item 6
702
703 the pattern uses a Unicode break (C<\b{...}> or C<\B{...}>); or
704
705 =item 7
706
707 the pattern uses L</C<(?[ ])>>
708
709 =item 8
710
711 the pattern uses L<C<(*script_run: ...)>|/Script Runs>
712
713 =back
714
715 Another mnemonic for this modifier is "Depends", as the rules actually
716 used depend on various things, and as a result you can get unexpected
717 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
718 become rather infamous, leading to yet another (printable) name for this
719 modifier, "Dodgy".
720
721 Unless the pattern or string are encoded in UTF-8, only ASCII characters
722 can match positively.
723
724 Here are some examples of how that works on an ASCII platform:
725
726  $str =  "\xDF";      # $str is not in UTF-8 format.
727  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
728  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
729  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
730  chop $str;
731  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
732
733 This modifier is automatically selected by default when none of the
734 others are, so yet another name for it is "Default".
735
736 Because of the unexpected behaviors associated with this modifier, you
737 probably should only explicitly use it to maintain weird backward
738 compatibilities.
739
740 =head4 /a (and /aa)
741
742 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier
743 may be doubled-up to increase its effect.
744
745 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
746 the Posix character classes to match only in the ASCII range.  They thus
747 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
748 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
749 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, the vertical tab;
750 C<\w> means the 63 characters
751 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
752 C<[[:print:]]> match only the appropriate ASCII-range characters.
753
754 This modifier is useful for people who only incidentally use Unicode,
755 and who do not wish to be burdened with its complexities and security
756 concerns.
757
758 With C</a>, one can write C<\d> with confidence that it will only match
759 ASCII characters, and should the need arise to match beyond ASCII, you
760 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
761 similar C<\p{...}> constructs that can match beyond ASCII both white
762 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
763 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
764 doesn't mean you can't use Unicode, it means that to get Unicode
765 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
766 signals Unicode.
767
768 As you would expect, this modifier causes, for example, C<\D> to mean
769 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
770 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
771 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
772 for C<\B>).
773
774 Otherwise, C</a> behaves like the C</u> modifier, in that
775 case-insensitive matching uses Unicode rules; for example, "k" will
776 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
777 points in the Latin1 range, above ASCII will have Unicode rules when it
778 comes to case-insensitive matching.
779
780 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
781 specify the C<"a"> twice, for example C</aai> or C</aia>.  (The first
782 occurrence of C<"a"> restricts the C<\d>, I<etc>., and the second occurrence
783 adds the C</i> restrictions.)  But, note that code points outside the
784 ASCII range will use Unicode rules for C</i> matching, so the modifier
785 doesn't really restrict things to just ASCII; it just forbids the
786 intermixing of ASCII and non-ASCII.
787
788 To summarize, this modifier provides protection for applications that
789 don't wish to be exposed to all of Unicode.  Specifying it twice
790 gives added protection.
791
792 This modifier may be specified to be the default by C<use re '/a'>
793 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
794 the C</u> modifier explicitly if there are a few regular expressions
795 where you do want full Unicode rules (but even here, it's best if
796 everything were under feature C<"unicode_strings">, along with the
797 C<use re '/aa'>).  Also see L</Which character set modifier is in
798 effect?>.
799 X</a>
800 X</aa>
801
802 =head4 Which character set modifier is in effect?
803
804 Which of these modifiers is in effect at any given point in a regular
805 expression depends on a fairly complex set of interactions.  These have
806 been designed so that in general you don't have to worry about it, but
807 this section gives the gory details.  As
808 explained below in L</Extended Patterns> it is possible to explicitly
809 specify modifiers that apply only to portions of a regular expression.
810 The innermost always has priority over any outer ones, and one applying
811 to the whole expression has priority over any of the default settings that are
812 described in the remainder of this section.
813
814 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
815 default modifiers (including these) for regular expressions compiled
816 within its scope.  This pragma has precedence over the other pragmas
817 listed below that also change the defaults.
818
819 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
820 and C<L<use feature 'unicode_strings|feature>>, or
821 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
822 C</u> when not in the same scope as either C<L<use locale|perllocale>>
823 or C<L<use bytes|bytes>>.
824 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
825 sets the default to C</u>, overriding any plain C<use locale>.)
826 Unlike the mechanisms mentioned above, these
827 affect operations besides regular expressions pattern matching, and so
828 give more consistent results with other operators, including using
829 C<\U>, C<\l>, I<etc>. in substitution replacements.
830
831 If none of the above apply, for backwards compatibility reasons, the
832 C</d> modifier is the one in effect by default.  As this can lead to
833 unexpected results, it is best to specify which other rule set should be
834 used.
835
836 =head4 Character set modifier behavior prior to Perl 5.14
837
838 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
839 for regexes compiled within the scope of C<use locale>, and C</d> was
840 implied otherwise.  However, interpolating a regex into a larger regex
841 would ignore the original compilation in favor of whatever was in effect
842 at the time of the second compilation.  There were a number of
843 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
844 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
845 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
846
847 =head2 Regular Expressions
848
849 =head3 Quantifiers
850
851 Quantifiers are used when a particular portion of a pattern needs to
852 match a certain number (or numbers) of times.  If there isn't a
853 quantifier the number of times to match is exactly one.  The following
854 standard quantifiers are recognized:
855 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
856
857     *           Match 0 or more times
858     +           Match 1 or more times
859     ?           Match 1 or 0 times
860     {n}         Match exactly n times
861     {n,}        Match at least n times
862     {n,m}       Match at least n but not more than m times
863
864 (If a non-escaped curly bracket occurs in a context other than one of
865 the quantifiers listed above, where it does not form part of a
866 backslashed sequence like C<\x{...}>, it is either a fatal syntax error,
867 or treated as a regular character, generally with a deprecation warning
868 raised.  To escape it, you can precede it with a backslash (C<"\{">) or
869 enclose it within square brackets  (C<"[{]">).
870 This change will allow for future syntax extensions (like making the
871 lower bound of a quantifier optional), and better error checking of
872 quantifiers).
873
874 The C<"*"> quantifier is equivalent to C<{0,}>, the C<"+">
875 quantifier to C<{1,}>, and the C<"?"> quantifier to C<{0,1}>.  I<n> and I<m> are limited
876 to non-negative integral values less than a preset limit defined when perl is built.
877 This is usually 32766 on the most common platforms.  The actual limit can
878 be seen in the error message generated by code such as this:
879
880     $_ **= $_ , / {$_} / for 2 .. 42;
881
882 By default, a quantified subpattern is "greedy", that is, it will match as
883 many times as possible (given a particular starting location) while still
884 allowing the rest of the pattern to match.  If you want it to match the
885 minimum number of times possible, follow the quantifier with a C<"?">.  Note
886 that the meanings don't change, just the "greediness":
887 X<metacharacter> X<greedy> X<greediness>
888 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
889
890     *?        Match 0 or more times, not greedily
891     +?        Match 1 or more times, not greedily
892     ??        Match 0 or 1 time, not greedily
893     {n}?      Match exactly n times, not greedily (redundant)
894     {n,}?     Match at least n times, not greedily
895     {n,m}?    Match at least n but not more than m times, not greedily
896
897 Normally when a quantified subpattern does not allow the rest of the
898 overall pattern to match, Perl will backtrack. However, this behaviour is
899 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
900 as well.
901
902  *+     Match 0 or more times and give nothing back
903  ++     Match 1 or more times and give nothing back
904  ?+     Match 0 or 1 time and give nothing back
905  {n}+   Match exactly n times and give nothing back (redundant)
906  {n,}+  Match at least n times and give nothing back
907  {n,m}+ Match at least n but not more than m times and give nothing back
908
909 For instance,
910
911    'aaaa' =~ /a++a/
912
913 will never match, as the C<a++> will gobble up all the C<"a">'s in the
914 string and won't leave any for the remaining part of the pattern. This
915 feature can be extremely useful to give perl hints about where it
916 shouldn't backtrack. For instance, the typical "match a double-quoted
917 string" problem can be most efficiently performed when written as:
918
919    /"(?:[^"\\]++|\\.)*+"/
920
921 as we know that if the final quote does not match, backtracking will not
922 help. See the independent subexpression
923 L</C<< (?>pattern) >>> for more details;
924 possessive quantifiers are just syntactic sugar for that construct. For
925 instance the above example could also be written as follows:
926
927    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
928
929 Note that the possessive quantifier modifier can not be be combined
930 with the non-greedy modifier. This is because it would make no sense.
931 Consider the follow equivalency table:
932
933     Illegal         Legal
934     ------------    ------
935     X??+            X{0}
936     X+?+            X{1}
937     X{min,max}?+    X{min}
938
939 =head3 Escape sequences
940
941 Because patterns are processed as double-quoted strings, the following
942 also work:
943
944  \t          tab                   (HT, TAB)
945  \n          newline               (LF, NL)
946  \r          return                (CR)
947  \f          form feed             (FF)
948  \a          alarm (bell)          (BEL)
949  \e          escape (think troff)  (ESC)
950  \cK         control char          (example: VT)
951  \x{}, \x00  character whose ordinal is the given hexadecimal number
952  \N{name}    named Unicode character or character sequence
953  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
954  \o{}, \000  character whose ordinal is the given octal number
955  \l          lowercase next char (think vi)
956  \u          uppercase next char (think vi)
957  \L          lowercase until \E (think vi)
958  \U          uppercase until \E (think vi)
959  \Q          quote (disable) pattern metacharacters until \E
960  \E          end either case modification or quoted section, think vi
961
962 Details are in L<perlop/Quote and Quote-like Operators>.
963
964 =head3 Character Classes and other Special Escapes
965
966 In addition, Perl defines the following:
967 X<\g> X<\k> X<\K> X<backreference>
968
969  Sequence   Note    Description
970   [...]     [1]  Match a character according to the rules of the
971                    bracketed character class defined by the "...".
972                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
973   [[:...:]] [2]  Match a character according to the rules of the POSIX
974                    character class "..." within the outer bracketed
975                    character class.  Example: [[:upper:]] matches any
976                    uppercase character.
977   (?[...])  [8]  Extended bracketed character class
978   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
979                    other connector punctuation chars plus Unicode
980                    marks)
981   \W        [3]  Match a non-"word" character
982   \s        [3]  Match a whitespace character
983   \S        [3]  Match a non-whitespace character
984   \d        [3]  Match a decimal digit character
985   \D        [3]  Match a non-digit character
986   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
987   \PP       [3]  Match non-P
988   \X        [4]  Match Unicode "eXtended grapheme cluster"
989   \1        [5]  Backreference to a specific capture group or buffer.
990                    '1' may actually be any positive integer.
991   \g1       [5]  Backreference to a specific or previous group,
992   \g{-1}    [5]  The number may be negative indicating a relative
993                    previous group and may optionally be wrapped in
994                    curly brackets for safer parsing.
995   \g{name}  [5]  Named backreference
996   \k<name>  [5]  Named backreference
997   \K        [6]  Keep the stuff left of the \K, don't include it in $&
998   \N        [7]  Any character but \n.  Not affected by /s modifier
999   \v        [3]  Vertical whitespace
1000   \V        [3]  Not vertical whitespace
1001   \h        [3]  Horizontal whitespace
1002   \H        [3]  Not horizontal whitespace
1003   \R        [4]  Linebreak
1004
1005 =over 4
1006
1007 =item [1]
1008
1009 See L<perlrecharclass/Bracketed Character Classes> for details.
1010
1011 =item [2]
1012
1013 See L<perlrecharclass/POSIX Character Classes> for details.
1014
1015 =item [3]
1016
1017 See L<perlrecharclass/Backslash sequences> for details.
1018
1019 =item [4]
1020
1021 See L<perlrebackslash/Misc> for details.
1022
1023 =item [5]
1024
1025 See L</Capture groups> below for details.
1026
1027 =item [6]
1028
1029 See L</Extended Patterns> below for details.
1030
1031 =item [7]
1032
1033 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
1034 character or character sequence whose name is C<NAME>; and similarly
1035 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
1036 code point is I<hex>.  Otherwise it matches any character but C<\n>.
1037
1038 =item [8]
1039
1040 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
1041
1042 =back
1043
1044 =head3 Assertions
1045
1046 Besides L<C<"^"> and C<"$">|/Metacharacters>, Perl defines the following
1047 zero-width assertions:
1048 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
1049 X<regexp, zero-width assertion>
1050 X<regular expression, zero-width assertion>
1051 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
1052
1053  \b{}   Match at Unicode boundary of specified type
1054  \B{}   Match where corresponding \b{} doesn't match
1055  \b     Match a \w\W or \W\w boundary
1056  \B     Match except at a \w\W or \W\w boundary
1057  \A     Match only at beginning of string
1058  \Z     Match only at end of string, or before newline at the end
1059  \z     Match only at end of string
1060  \G     Match only at pos() (e.g. at the end-of-match position
1061         of prior m//g)
1062
1063 A Unicode boundary (C<\b{}>), available starting in v5.22, is a spot
1064 between two characters, or before the first character in the string, or
1065 after the final character in the string where certain criteria defined
1066 by Unicode are met.  See L<perlrebackslash/\b{}, \b, \B{}, \B> for
1067 details.
1068
1069 A word boundary (C<\b>) is a spot between two characters
1070 that has a C<\w> on one side of it and a C<\W> on the other side
1071 of it (in either order), counting the imaginary characters off the
1072 beginning and end of the string as matching a C<\W>.  (Within
1073 character classes C<\b> represents backspace rather than a word
1074 boundary, just as it normally does in any double-quoted string.)
1075 The C<\A> and C<\Z> are just like C<"^"> and C<"$">, except that they
1076 won't match multiple times when the C</m> modifier is used, while
1077 C<"^"> and C<"$"> will match at every internal line boundary.  To match
1078 the actual end of the string and not ignore an optional trailing
1079 newline, use C<\z>.
1080 X<\b> X<\A> X<\Z> X<\z> X</m>
1081
1082 The C<\G> assertion can be used to chain global matches (using
1083 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
1084 It is also useful when writing C<lex>-like scanners, when you have
1085 several patterns that you want to match against consequent substrings
1086 of your string; see the previous reference.  The actual location
1087 where C<\G> will match can also be influenced by using C<pos()> as
1088 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
1089 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
1090 is modified somewhat, in that contents to the left of C<\G> are
1091 not counted when determining the length of the match. Thus the following
1092 will not match forever:
1093 X<\G>
1094
1095      my $string = 'ABC';
1096      pos($string) = 1;
1097      while ($string =~ /(.\G)/g) {
1098          print $1;
1099      }
1100
1101 It will print 'A' and then terminate, as it considers the match to
1102 be zero-width, and thus will not match at the same position twice in a
1103 row.
1104
1105 It is worth noting that C<\G> improperly used can result in an infinite
1106 loop. Take care when using patterns that include C<\G> in an alternation.
1107
1108 Note also that C<s///> will refuse to overwrite part of a substitution
1109 that has already been replaced; so for example this will stop after the
1110 first iteration, rather than iterating its way backwards through the
1111 string:
1112
1113     $_ = "123456789";
1114     pos = 6;
1115     s/.(?=.\G)/X/g;
1116     print;      # prints 1234X6789, not XXXXX6789
1117
1118
1119 =head3 Capture groups
1120
1121 The grouping construct C<( ... )> creates capture groups (also referred to as
1122 capture buffers). To refer to the current contents of a group later on, within
1123 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
1124 for the second, and so on.
1125 This is called a I<backreference>.
1126 X<regex, capture buffer> X<regexp, capture buffer>
1127 X<regex, capture group> X<regexp, capture group>
1128 X<regular expression, capture buffer> X<backreference>
1129 X<regular expression, capture group> X<backreference>
1130 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
1131 X<named capture buffer> X<regular expression, named capture buffer>
1132 X<named capture group> X<regular expression, named capture group>
1133 X<%+> X<$+{name}> X<< \k<name> >>
1134 There is no limit to the number of captured substrings that you may use.
1135 Groups are numbered with the leftmost open parenthesis being number 1, I<etc>.  If
1136 a group did not match, the associated backreference won't match either. (This
1137 can happen if the group is optional, or in a different branch of an
1138 alternation.)
1139 You can omit the C<"g">, and write C<"\1">, I<etc>, but there are some issues with
1140 this form, described below.
1141
1142 You can also refer to capture groups relatively, by using a negative number, so
1143 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
1144 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
1145 example:
1146
1147         /
1148          (Y)            # group 1
1149          (              # group 2
1150             (X)         # group 3
1151             \g{-1}      # backref to group 3
1152             \g{-3}      # backref to group 1
1153          )
1154         /x
1155
1156 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
1157 interpolate regexes into larger regexes and not have to worry about the
1158 capture groups being renumbered.
1159
1160 You can dispense with numbers altogether and create named capture groups.
1161 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
1162 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
1163 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
1164 I<name> must not begin with a number, nor contain hyphens.
1165 When different groups within the same pattern have the same name, any reference
1166 to that name assumes the leftmost defined group.  Named groups count in
1167 absolute and relative numbering, and so can also be referred to by those
1168 numbers.
1169 (It's possible to do things with named capture groups that would otherwise
1170 require C<(??{})>.)
1171
1172 Capture group contents are dynamically scoped and available to you outside the
1173 pattern until the end of the enclosing block or until the next successful
1174 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
1175 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
1176 I<etc>); or by name via the C<%+> hash, using C<"$+{I<name>}">.
1177
1178 Braces are required in referring to named capture groups, but are optional for
1179 absolute or relative numbered ones.  Braces are safer when creating a regex by
1180 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
1181 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
1182 is probably not what you intended.
1183
1184 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
1185 there were no named nor relative numbered capture groups.  Absolute numbered
1186 groups were referred to using C<\1>,
1187 C<\2>, I<etc>., and this notation is still
1188 accepted (and likely always will be).  But it leads to some ambiguities if
1189 there are more than 9 capture groups, as C<\10> could mean either the tenth
1190 capture group, or the character whose ordinal in octal is 010 (a backspace in
1191 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
1192 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
1193 a backreference only if at least 11 left parentheses have opened before it.
1194 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
1195 There are several examples below that illustrate these perils.  You can avoid
1196 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
1197 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
1198 digits padded with leading zeros, since a leading zero implies an octal
1199 constant.
1200
1201 The C<\I<digit>> notation also works in certain circumstances outside
1202 the pattern.  See L</Warning on \1 Instead of $1> below for details.
1203
1204 Examples:
1205
1206     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
1207
1208     /(.)\g1/                        # find first doubled char
1209          and print "'$1' is the first doubled character\n";
1210
1211     /(?<char>.)\k<char>/            # ... a different way
1212          and print "'$+{char}' is the first doubled character\n";
1213
1214     /(?'char'.)\g1/                 # ... mix and match
1215          and print "'$1' is the first doubled character\n";
1216
1217     if (/Time: (..):(..):(..)/) {   # parse out values
1218         $hours = $1;
1219         $minutes = $2;
1220         $seconds = $3;
1221     }
1222
1223     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
1224     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
1225     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
1226     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
1227
1228     $a = '(.)\1';        # Creates problems when concatenated.
1229     $b = '(.)\g{1}';     # Avoids the problems.
1230     "aa" =~ /${a}/;      # True
1231     "aa" =~ /${b}/;      # True
1232     "aa0" =~ /${a}0/;    # False!
1233     "aa0" =~ /${b}0/;    # True
1234     "aa\x08" =~ /${a}0/;  # True!
1235     "aa\x08" =~ /${b}0/;  # False
1236
1237 Several special variables also refer back to portions of the previous
1238 match.  C<$+> returns whatever the last bracket match matched.
1239 C<$&> returns the entire matched string.  (At one point C<$0> did
1240 also, but now it returns the name of the program.)  C<$`> returns
1241 everything before the matched string.  C<$'> returns everything
1242 after the matched string. And C<$^N> contains whatever was matched by
1243 the most-recently closed group (submatch). C<$^N> can be used in
1244 extended patterns (see below), for example to assign a submatch to a
1245 variable.
1246 X<$+> X<$^N> X<$&> X<$`> X<$'>
1247
1248 These special variables, like the C<%+> hash and the numbered match variables
1249 (C<$1>, C<$2>, C<$3>, I<etc>.) are dynamically scoped
1250 until the end of the enclosing block or until the next successful
1251 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
1252 X<$+> X<$^N> X<$&> X<$`> X<$'>
1253 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
1254
1255 B<NOTE>: Failed matches in Perl do not reset the match variables,
1256 which makes it easier to write code that tests for a series of more
1257 specific cases and remembers the best match.
1258
1259 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
1260 beware that once Perl sees that you need one of C<$&>, C<$`>, or
1261 C<$'> anywhere in the program, it has to provide them for every
1262 pattern match.  This may substantially slow your program.
1263
1264 Perl uses the same mechanism to produce C<$1>, C<$2>, I<etc>, so you also
1265 pay a price for each pattern that contains capturing parentheses.
1266 (To avoid this cost while retaining the grouping behaviour, use the
1267 extended regular expression C<(?: ... )> instead.)  But if you never
1268 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
1269 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
1270 if you can, but if you can't (and some algorithms really appreciate
1271 them), once you've used them once, use them at will, because you've
1272 already paid the price.
1273 X<$&> X<$`> X<$'>
1274
1275 Perl 5.16 introduced a slightly more efficient mechanism that notes
1276 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
1277 thus may only need to copy part of the string.  Perl 5.20 introduced a
1278 much more efficient copy-on-write mechanism which eliminates any slowdown.
1279
1280 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
1281 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
1282 and C<$'>, B<except> that they are only guaranteed to be defined after a
1283 successful match that was executed with the C</p> (preserve) modifier.
1284 The use of these variables incurs no global performance penalty, unlike
1285 their punctuation character equivalents, however at the trade-off that you
1286 have to tell perl when you want to use them.  As of Perl 5.20, these three
1287 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
1288 X</p> X<p modifier>
1289
1290 =head2 Quoting metacharacters
1291
1292 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
1293 C<\w>, C<\n>.  Unlike some other regular expression languages, there
1294 are no backslashed symbols that aren't alphanumeric.  So anything
1295 that looks like C<\\>, C<\(>, C<\)>, C<\[>, C<\]>, C<\{>, or C<\}> is
1296 always
1297 interpreted as a literal character, not a metacharacter.  This was
1298 once used in a common idiom to disable or quote the special meanings
1299 of regular expression metacharacters in a string that you want to
1300 use for a pattern. Simply quote all non-"word" characters:
1301
1302     $pattern =~ s/(\W)/\\$1/g;
1303
1304 (If C<use locale> is set, then this depends on the current locale.)
1305 Today it is more common to use the C<L<quotemeta()|perlfunc/quotemeta>>
1306 function or the C<\Q> metaquoting escape sequence to disable all
1307 metacharacters' special meanings like this:
1308
1309     /$unquoted\Q$quoted\E$unquoted/
1310
1311 Beware that if you put literal backslashes (those not inside
1312 interpolated variables) between C<\Q> and C<\E>, double-quotish
1313 backslash interpolation may lead to confusing results.  If you
1314 I<need> to use literal backslashes within C<\Q...\E>,
1315 consult L<perlop/"Gory details of parsing quoted constructs">.
1316
1317 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
1318
1319 =head2 Extended Patterns
1320
1321 Perl also defines a consistent extension syntax for features not
1322 found in standard tools like B<awk> and
1323 B<lex>.  The syntax for most of these is a
1324 pair of parentheses with a question mark as the first thing within
1325 the parentheses.  The character after the question mark indicates
1326 the extension.
1327
1328 A question mark was chosen for this and for the minimal-matching
1329 construct because 1) question marks are rare in older regular
1330 expressions, and 2) whenever you see one, you should stop and
1331 "question" exactly what is going on.  That's psychology....
1332
1333 =over 4
1334
1335 =item C<(?#text)>
1336 X<(?#)>
1337
1338 A comment.  The text is ignored.
1339 Note that Perl closes
1340 the comment as soon as it sees a C<")">, so there is no way to put a literal
1341 C<")"> in the comment.  The pattern's closing delimiter must be escaped by
1342 a backslash if it appears in the comment.
1343
1344 See L</E<sol>x> for another way to have comments in patterns.
1345
1346 Note that a comment can go just about anywhere, except in the middle of
1347 an escape sequence.   Examples:
1348
1349  qr/foo(?#comment)bar/'  # Matches 'foobar'
1350
1351  # The pattern below matches 'abcd', 'abccd', or 'abcccd'
1352  qr/abc(?#comment between literal and its quantifier){1,3}d/
1353
1354  # The pattern below generates a syntax error, because the '\p' must
1355  # be followed immediately by a '{'.
1356  qr/\p(?#comment between \p and its property name){Any}/
1357
1358  # The pattern below generates a syntax error, because the initial
1359  # '\(' is a literal opening parenthesis, and so there is nothing
1360  # for the  closing ')' to match
1361  qr/\(?#the backslash means this isn't a comment)p{Any}/
1362
1363  # Comments can be used to fold long patterns into multiple lines
1364  qr/First part of a long regex(?#
1365    )remaining part/
1366
1367 =item C<(?adlupimnsx-imnsx)>
1368
1369 =item C<(?^alupimnsx)>
1370 X<(?)> X<(?^)>
1371
1372 One or more embedded pattern-match modifiers, to be turned on (or
1373 turned off if preceded by C<"-">) for the remainder of the pattern or
1374 the remainder of the enclosing pattern group (if any).
1375
1376 This is particularly useful for dynamically-generated patterns,
1377 such as those read in from a
1378 configuration file, taken from an argument, or specified in a table
1379 somewhere.  Consider the case where some patterns want to be
1380 case-sensitive and some do not:  The case-insensitive ones merely need to
1381 include C<(?i)> at the front of the pattern.  For example:
1382
1383     $pattern = "foobar";
1384     if ( /$pattern/i ) { }
1385
1386     # more flexible:
1387
1388     $pattern = "(?i)foobar";
1389     if ( /$pattern/ ) { }
1390
1391 These modifiers are restored at the end of the enclosing group. For example,
1392
1393     ( (?i) blah ) \s+ \g1
1394
1395 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1396 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1397 modifier outside this group.
1398
1399 These modifiers do not carry over into named subpatterns called in the
1400 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1401 change the case-sensitivity of the C<"NAME"> pattern.
1402
1403 A modifier is overridden by later occurrences of this construct in the
1404 same scope containing the same modifier, so that
1405
1406     /((?im)foo(?-m)bar)/
1407
1408 matches all of C<foobar> case insensitively, but uses C</m> rules for
1409 only the C<foo> portion.  The C<"a"> flag overrides C<aa> as well;
1410 likewise C<aa> overrides C<"a">.  The same goes for C<"x"> and C<xx>.
1411 Hence, in
1412
1413     /(?-x)foo/xx
1414
1415 both C</x> and C</xx> are turned off during matching C<foo>.  And in
1416
1417     /(?x)foo/x
1418
1419 C</x> but NOT C</xx> is turned on for matching C<foo>.  (One might
1420 mistakenly think that since the inner C<(?x)> is already in the scope of
1421 C</x>, that the result would effectively be the sum of them, yielding
1422 C</xx>.  It doesn't work that way.)  Similarly, doing something like
1423 C<(?xx-x)foo> turns off all C<"x"> behavior for matching C<foo>, it is not
1424 that you subtract 1 C<"x"> from 2 to get 1 C<"x"> remaining.
1425
1426 Any of these modifiers can be set to apply globally to all regular
1427 expressions compiled within the scope of a C<use re>.  See
1428 L<re/"'/flags' mode">.
1429
1430 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1431 after the C<"?"> is a shorthand equivalent to C<d-imnsx>.  Flags (except
1432 C<"d">) may follow the caret to override it.
1433 But a minus sign is not legal with it.
1434
1435 Note that the C<"a">, C<"d">, C<"l">, C<"p">, and C<"u"> modifiers are special in
1436 that they can only be enabled, not disabled, and the C<"a">, C<"d">, C<"l">, and
1437 C<"u"> modifiers are mutually exclusive: specifying one de-specifies the
1438 others, and a maximum of one (or two C<"a">'s) may appear in the
1439 construct.  Thus, for
1440 example, C<(?-p)> will warn when compiled under C<use warnings>;
1441 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1442
1443 Note also that the C<"p"> modifier is special in that its presence
1444 anywhere in a pattern has a global effect.
1445
1446 =item C<(?:pattern)>
1447 X<(?:)>
1448
1449 =item C<(?adluimnsx-imnsx:pattern)>
1450
1451 =item C<(?^aluimnsx:pattern)>
1452 X<(?^:)>
1453
1454 This is for clustering, not capturing; it groups subexpressions like
1455 C<"()">, but doesn't make backreferences as C<"()"> does.  So
1456
1457     @fields = split(/\b(?:a|b|c)\b/)
1458
1459 matches the same field delimiters as
1460
1461     @fields = split(/\b(a|b|c)\b/)
1462
1463 but doesn't spit out the delimiters themselves as extra fields (even though
1464 that's the behaviour of L<perlfunc/split> when its pattern contains capturing
1465 groups).  It's also cheaper not to capture
1466 characters if you don't need to.
1467
1468 Any letters between C<"?"> and C<":"> act as flags modifiers as with
1469 C<(?adluimnsx-imnsx)>.  For example,
1470
1471     /(?s-i:more.*than).*million/i
1472
1473 is equivalent to the more verbose
1474
1475     /(?:(?s-i)more.*than).*million/i
1476
1477 Note that any C<()> constructs enclosed within this one will still
1478 capture unless the C</n> modifier is in effect.
1479
1480 Like the L</(?adlupimnsx-imnsx)> construct, C<aa> and C<"a"> override each
1481 other, as do C<xx> and C<"x">.  They are not additive.  So, doing
1482 something like C<(?xx-x:foo)> turns off all C<"x"> behavior for matching
1483 C<foo>.
1484
1485 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1486 after the C<"?"> is a shorthand equivalent to C<d-imnsx>.  Any positive
1487 flags (except C<"d">) may follow the caret, so
1488
1489     (?^x:foo)
1490
1491 is equivalent to
1492
1493     (?x-imns:foo)
1494
1495 The caret tells Perl that this cluster doesn't inherit the flags of any
1496 surrounding pattern, but uses the system defaults (C<d-imnsx>),
1497 modified by any flags specified.
1498
1499 The caret allows for simpler stringification of compiled regular
1500 expressions.  These look like
1501
1502     (?^:pattern)
1503
1504 with any non-default flags appearing between the caret and the colon.
1505 A test that looks at such stringification thus doesn't need to have the
1506 system default flags hard-coded in it, just the caret.  If new flags are
1507 added to Perl, the meaning of the caret's expansion will change to include
1508 the default for those flags, so the test will still work, unchanged.
1509
1510 Specifying a negative flag after the caret is an error, as the flag is
1511 redundant.
1512
1513 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1514 to match at the beginning.
1515
1516 =item C<(?|pattern)>
1517 X<(?|)> X<Branch reset>
1518
1519 This is the "branch reset" pattern, which has the special property
1520 that the capture groups are numbered from the same starting point
1521 in each alternation branch. It is available starting from perl 5.10.0.
1522
1523 Capture groups are numbered from left to right, but inside this
1524 construct the numbering is restarted for each branch.
1525
1526 The numbering within each branch will be as normal, and any groups
1527 following this construct will be numbered as though the construct
1528 contained only one branch, that being the one with the most capture
1529 groups in it.
1530
1531 This construct is useful when you want to capture one of a
1532 number of alternative matches.
1533
1534 Consider the following pattern.  The numbers underneath show in
1535 which group the captured content will be stored.
1536
1537
1538     # before  ---------------branch-reset----------- after
1539     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1540     # 1            2         2  3        2     3     4
1541
1542 Be careful when using the branch reset pattern in combination with
1543 named captures. Named captures are implemented as being aliases to
1544 numbered groups holding the captures, and that interferes with the
1545 implementation of the branch reset pattern. If you are using named
1546 captures in a branch reset pattern, it's best to use the same names,
1547 in the same order, in each of the alternations:
1548
1549    /(?|  (?<a> x ) (?<b> y )
1550       |  (?<a> z ) (?<b> w )) /x
1551
1552 Not doing so may lead to surprises:
1553
1554   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1555   say $+{a};    # Prints '12'
1556   say $+{b};    # *Also* prints '12'.
1557
1558 The problem here is that both the group named C<< a >> and the group
1559 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1560
1561 =item Lookaround Assertions
1562 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1563
1564 Lookaround assertions are zero-width patterns which match a specific
1565 pattern without including it in C<$&>. Positive assertions match when
1566 their subpattern matches, negative assertions match when their subpattern
1567 fails. Lookbehind matches text up to the current match position,
1568 lookahead matches text following the current match position.
1569
1570 =over 4
1571
1572 =item C<(?=pattern)>
1573 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1574
1575 A zero-width positive lookahead assertion.  For example, C</\w+(?=\t)/>
1576 matches a word followed by a tab, without including the tab in C<$&>.
1577
1578 =item C<(?!pattern)>
1579 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1580
1581 A zero-width negative lookahead assertion.  For example C</foo(?!bar)/>
1582 matches any occurrence of "foo" that isn't followed by "bar".  Note
1583 however that lookahead and lookbehind are NOT the same thing.  You cannot
1584 use this for lookbehind.
1585
1586 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1587 will not do what you want.  That's because the C<(?!foo)> is just saying that
1588 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1589 match.  Use lookbehind instead (see below).
1590
1591 =item C<(?<=pattern)>
1592
1593 =item C<\K>
1594 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1595
1596 A zero-width positive lookbehind assertion.  For example, C</(?<=\t)\w+/>
1597 matches a word that follows a tab, without including the tab in C<$&>.
1598 Works only for fixed-width lookbehind.
1599
1600 There is a special form of this construct, called C<\K> (available since
1601 Perl 5.10.0), which causes the
1602 regex engine to "keep" everything it had matched prior to the C<\K> and
1603 not include it in C<$&>. This effectively provides variable-length
1604 lookbehind. The use of C<\K> inside of another lookaround assertion
1605 is allowed, but the behaviour is currently not well defined.
1606
1607 For various reasons C<\K> may be significantly more efficient than the
1608 equivalent C<< (?<=...) >> construct, and it is especially useful in
1609 situations where you want to efficiently remove something following
1610 something else in a string. For instance
1611
1612   s/(foo)bar/$1/g;
1613
1614 can be rewritten as the much more efficient
1615
1616   s/foo\Kbar//g;
1617
1618 =item C<(?<!pattern)>
1619 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1620
1621 A zero-width negative lookbehind assertion.  For example C</(?<!bar)foo/>
1622 matches any occurrence of "foo" that does not follow "bar".  Works
1623 only for fixed-width lookbehind.
1624
1625 =back
1626
1627 =item C<< (?<NAME>pattern) >>
1628
1629 =item C<(?'NAME'pattern)>
1630 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1631
1632 A named capture group. Identical in every respect to normal capturing
1633 parentheses C<()> but for the additional fact that the group
1634 can be referred to by name in various regular expression
1635 constructs (like C<\g{NAME}>) and can be accessed by name
1636 after a successful match via C<%+> or C<%->. See L<perlvar>
1637 for more details on the C<%+> and C<%-> hashes.
1638
1639 If multiple distinct capture groups have the same name, then
1640 C<$+{NAME}> will refer to the leftmost defined group in the match.
1641
1642 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1643
1644 B<NOTE:> While the notation of this construct is the same as the similar
1645 function in .NET regexes, the behavior is not. In Perl the groups are
1646 numbered sequentially regardless of being named or not. Thus in the
1647 pattern
1648
1649   /(x)(?<foo>y)(z)/
1650
1651 C<$+{I<foo>}> will be the same as C<$2>, and C<$3> will contain 'z' instead of
1652 the opposite which is what a .NET regex hacker might expect.
1653
1654 Currently I<NAME> is restricted to simple identifiers only.
1655 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1656 its Unicode extension (see L<utf8>),
1657 though it isn't extended by the locale (see L<perllocale>).
1658
1659 B<NOTE:> In order to make things easier for programmers with experience
1660 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1661 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1662 support the use of single quotes as a delimiter for the name.
1663
1664 =item C<< \k<NAME> >>
1665
1666 =item C<< \k'NAME' >>
1667
1668 Named backreference. Similar to numeric backreferences, except that
1669 the group is designated by name and not number. If multiple groups
1670 have the same name then it refers to the leftmost defined group in
1671 the current match.
1672
1673 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1674 earlier in the pattern.
1675
1676 Both forms are equivalent.
1677
1678 B<NOTE:> In order to make things easier for programmers with experience
1679 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1680 may be used instead of C<< \k<NAME> >>.
1681
1682 =item C<(?{ code })>
1683 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1684
1685 B<WARNING>: Using this feature safely requires that you understand its
1686 limitations.  Code executed that has side effects may not perform identically
1687 from version to version due to the effect of future optimisations in the regex
1688 engine.  For more information on this, see L</Embedded Code Execution
1689 Frequency>.
1690
1691 This zero-width assertion executes any embedded Perl code.  It always
1692 succeeds, and its return value is set as C<$^R>.
1693
1694 In literal patterns, the code is parsed at the same time as the
1695 surrounding code. While within the pattern, control is passed temporarily
1696 back to the perl parser, until the logically-balancing closing brace is
1697 encountered. This is similar to the way that an array index expression in
1698 a literal string is handled, for example
1699
1700     "abc$array[ 1 + f('[') + g()]def"
1701
1702 In particular, braces do not need to be balanced:
1703
1704     s/abc(?{ f('{'); })/def/
1705
1706 Even in a pattern that is interpolated and compiled at run-time, literal
1707 code blocks will be compiled once, at perl compile time; the following
1708 prints "ABCD":
1709
1710     print "D";
1711     my $qr = qr/(?{ BEGIN { print "A" } })/;
1712     my $foo = "foo";
1713     /$foo$qr(?{ BEGIN { print "B" } })/;
1714     BEGIN { print "C" }
1715
1716 In patterns where the text of the code is derived from run-time
1717 information rather than appearing literally in a source code /pattern/,
1718 the code is compiled at the same time that the pattern is compiled, and
1719 for reasons of security, C<use re 'eval'> must be in scope. This is to
1720 stop user-supplied patterns containing code snippets from being
1721 executable.
1722
1723 In situations where you need to enable this with C<use re 'eval'>, you should
1724 also have taint checking enabled.  Better yet, use the carefully
1725 constrained evaluation within a Safe compartment.  See L<perlsec> for
1726 details about both these mechanisms.
1727
1728 From the viewpoint of parsing, lexical variable scope and closures,
1729
1730     /AAA(?{ BBB })CCC/
1731
1732 behaves approximately like
1733
1734     /AAA/ && do { BBB } && /CCC/
1735
1736 Similarly,
1737
1738     qr/AAA(?{ BBB })CCC/
1739
1740 behaves approximately like
1741
1742     sub { /AAA/ && do { BBB } && /CCC/ }
1743
1744 In particular:
1745
1746     { my $i = 1; $r = qr/(?{ print $i })/ }
1747     my $i = 2;
1748     /$r/; # prints "1"
1749
1750 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1751 expression is matching against. You can also use C<pos()> to know what is
1752 the current position of matching within this string.
1753
1754 The code block introduces a new scope from the perspective of lexical
1755 variable declarations, but B<not> from the perspective of C<local> and
1756 similar localizing behaviours. So later code blocks within the same
1757 pattern will still see the values which were localized in earlier blocks.
1758 These accumulated localizations are undone either at the end of a
1759 successful match, or if the assertion is backtracked (compare
1760 L</"Backtracking">). For example,
1761
1762   $_ = 'a' x 8;
1763   m<
1764      (?{ $cnt = 0 })               # Initialize $cnt.
1765      (
1766        a
1767        (?{
1768            local $cnt = $cnt + 1;  # Update $cnt,
1769                                    # backtracking-safe.
1770        })
1771      )*
1772      aaaa
1773      (?{ $res = $cnt })            # On success copy to
1774                                    # non-localized location.
1775    >x;
1776
1777 will initially increment C<$cnt> up to 8; then during backtracking, its
1778 value will be unwound back to 4, which is the value assigned to C<$res>.
1779 At the end of the regex execution, C<$cnt> will be wound back to its initial
1780 value of 0.
1781
1782 This assertion may be used as the condition in a
1783
1784     (?(condition)yes-pattern|no-pattern)
1785
1786 switch.  If I<not> used in this way, the result of evaluation of C<code>
1787 is put into the special variable C<$^R>.  This happens immediately, so
1788 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1789 regular expression.
1790
1791 The assignment to C<$^R> above is properly localized, so the old
1792 value of C<$^R> is restored if the assertion is backtracked; compare
1793 L</"Backtracking">.
1794
1795 Note that the special variable C<$^N>  is particularly useful with code
1796 blocks to capture the results of submatches in variables without having to
1797 keep track of the number of nested parentheses. For example:
1798
1799   $_ = "The brown fox jumps over the lazy dog";
1800   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1801   print "color = $color, animal = $animal\n";
1802
1803
1804 =item C<(??{ code })>
1805 X<(??{})>
1806 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1807
1808 B<WARNING>: Using this feature safely requires that you understand its
1809 limitations.  Code executed that has side effects may not perform
1810 identically from version to version due to the effect of future
1811 optimisations in the regex engine.  For more information on this, see
1812 L</Embedded Code Execution Frequency>.
1813
1814 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1815 same way as a C<(?{ code })> code block as described above, except that
1816 its return value, rather than being assigned to C<$^R>, is treated as a
1817 pattern, compiled if it's a string (or used as-is if its a qr// object),
1818 then matched as if it were inserted instead of this construct.
1819
1820 During the matching of this sub-pattern, it has its own set of
1821 captures which are valid during the sub-match, but are discarded once
1822 control returns to the main pattern. For example, the following matches,
1823 with the inner pattern capturing "B" and matching "BB", while the outer
1824 pattern captures "A";
1825
1826     my $inner = '(.)\1';
1827     "ABBA" =~ /^(.)(??{ $inner })\1/;
1828     print $1; # prints "A";
1829
1830 Note that this means that  there is no way for the inner pattern to refer
1831 to a capture group defined outside.  (The code block itself can use C<$1>,
1832 I<etc>., to refer to the enclosing pattern's capture groups.)  Thus, although
1833
1834     ('a' x 100)=~/(??{'(.)' x 100})/
1835
1836 I<will> match, it will I<not> set C<$1> on exit.
1837
1838 The following pattern matches a parenthesized group:
1839
1840  $re = qr{
1841             \(
1842             (?:
1843                (?> [^()]+ )  # Non-parens without backtracking
1844              |
1845                (??{ $re })   # Group with matching parens
1846             )*
1847             \)
1848          }x;
1849
1850 See also
1851 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1852 for a different, more efficient way to accomplish
1853 the same task.
1854
1855 Executing a postponed regular expression too many times without
1856 consuming any input string will also result in a fatal error.  The depth
1857 at which that happens is compiled into perl, so it can be changed with a
1858 custom build.
1859
1860 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1861 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1862 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1863 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1864
1865 Recursive subpattern. Treat the contents of a given capture buffer in the
1866 current pattern as an independent subpattern and attempt to match it at
1867 the current position in the string. Information about capture state from
1868 the caller for things like backreferences is available to the subpattern,
1869 but capture buffers set by the subpattern are not visible to the caller.
1870
1871 Similar to C<(??{ code })> except that it does not involve executing any
1872 code or potentially compiling a returned pattern string; instead it treats
1873 the part of the current pattern contained within a specified capture group
1874 as an independent pattern that must match at the current position. Also
1875 different is the treatment of capture buffers, unlike C<(??{ code })>
1876 recursive patterns have access to their caller's match state, so one can
1877 use backreferences safely.
1878
1879 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1880 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1881 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1882 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1883 to be relative, with negative numbers indicating preceding capture groups
1884 and positive ones following. Thus C<(?-1)> refers to the most recently
1885 declared group, and C<(?+1)> indicates the next group to be declared.
1886 Note that the counting for relative recursion differs from that of
1887 relative backreferences, in that with recursion unclosed groups B<are>
1888 included.
1889
1890 The following pattern matches a function C<foo()> which may contain
1891 balanced parentheses as the argument.
1892
1893   $re = qr{ (                   # paren group 1 (full function)
1894               foo
1895               (                 # paren group 2 (parens)
1896                 \(
1897                   (             # paren group 3 (contents of parens)
1898                   (?:
1899                    (?> [^()]+ ) # Non-parens without backtracking
1900                   |
1901                    (?2)         # Recurse to start of paren group 2
1902                   )*
1903                   )
1904                 \)
1905               )
1906             )
1907           }x;
1908
1909 If the pattern was used as follows
1910
1911     'foo(bar(baz)+baz(bop))'=~/$re/
1912         and print "\$1 = $1\n",
1913                   "\$2 = $2\n",
1914                   "\$3 = $3\n";
1915
1916 the output produced should be the following:
1917
1918     $1 = foo(bar(baz)+baz(bop))
1919     $2 = (bar(baz)+baz(bop))
1920     $3 = bar(baz)+baz(bop)
1921
1922 If there is no corresponding capture group defined, then it is a
1923 fatal error.  Recursing deeply without consuming any input string will
1924 also result in a fatal error.  The depth at which that happens is
1925 compiled into perl, so it can be changed with a custom build.
1926
1927 The following shows how using negative indexing can make it
1928 easier to embed recursive patterns inside of a C<qr//> construct
1929 for later use:
1930
1931     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1932     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1933        # do something here...
1934     }
1935
1936 B<Note> that this pattern does not behave the same way as the equivalent
1937 PCRE or Python construct of the same form. In Perl you can backtrack into
1938 a recursed group, in PCRE and Python the recursed into group is treated
1939 as atomic. Also, modifiers are resolved at compile time, so constructs
1940 like C<(?i:(?1))> or C<(?:(?i)(?1))> do not affect how the sub-pattern will
1941 be processed.
1942
1943 =item C<(?&NAME)>
1944 X<(?&NAME)>
1945
1946 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
1947 parenthesis to recurse to is determined by name. If multiple parentheses have
1948 the same name, then it recurses to the leftmost.
1949
1950 It is an error to refer to a name that is not declared somewhere in the
1951 pattern.
1952
1953 B<NOTE:> In order to make things easier for programmers with experience
1954 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1955 may be used instead of C<< (?&NAME) >>.
1956
1957 =item C<(?(condition)yes-pattern|no-pattern)>
1958 X<(?()>
1959
1960 =item C<(?(condition)yes-pattern)>
1961
1962 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1963 a true value, matches C<no-pattern> otherwise. A missing pattern always
1964 matches.
1965
1966 C<(condition)> should be one of:
1967
1968 =over 4
1969
1970 =item an integer in parentheses
1971
1972 (which is valid if the corresponding pair of parentheses
1973 matched);
1974
1975 =item a lookahead/lookbehind/evaluate zero-width assertion;
1976
1977 =item a name in angle brackets or single quotes
1978
1979 (which is valid if a group with the given name matched);
1980
1981 =item the special symbol C<(R)>
1982
1983 (true when evaluated inside of recursion or eval).  Additionally the
1984 C<"R"> may be
1985 followed by a number, (which will be true when evaluated when recursing
1986 inside of the appropriate group), or by C<&NAME>, in which case it will
1987 be true only when evaluated during recursion in the named group.
1988
1989 =back
1990
1991 Here's a summary of the possible predicates:
1992
1993 =over 4
1994
1995 =item C<(1)> C<(2)> ...
1996
1997 Checks if the numbered capturing group has matched something.
1998 Full syntax: C<< (?(1)then|else) >>
1999
2000 =item C<(E<lt>I<NAME>E<gt>)> C<('I<NAME>')>
2001
2002 Checks if a group with the given name has matched something.
2003 Full syntax: C<< (?(<name>)then|else) >>
2004
2005 =item C<(?=...)> C<(?!...)> C<(?<=...)> C<(?<!...)>
2006
2007 Checks whether the pattern matches (or does not match, for the C<"!">
2008 variants).
2009 Full syntax: C<< (?(?=lookahead)then|else) >>
2010
2011 =item C<(?{ I<CODE> })>
2012
2013 Treats the return value of the code block as the condition.
2014 Full syntax: C<< (?(?{ code })then|else) >>
2015
2016 =item C<(R)>
2017
2018 Checks if the expression has been evaluated inside of recursion.
2019 Full syntax: C<< (?(R)then|else) >>
2020
2021 =item C<(R1)> C<(R2)> ...
2022
2023 Checks if the expression has been evaluated while executing directly
2024 inside of the n-th capture group. This check is the regex equivalent of
2025
2026   if ((caller(0))[3] eq 'subname') { ... }
2027
2028 In other words, it does not check the full recursion stack.
2029
2030 Full syntax: C<< (?(R1)then|else) >>
2031
2032 =item C<(R&I<NAME>)>
2033
2034 Similar to C<(R1)>, this predicate checks to see if we're executing
2035 directly inside of the leftmost group with a given name (this is the same
2036 logic used by C<(?&I<NAME>)> to disambiguate). It does not check the full
2037 stack, but only the name of the innermost active recursion.
2038 Full syntax: C<< (?(R&name)then|else) >>
2039
2040 =item C<(DEFINE)>
2041
2042 In this case, the yes-pattern is never directly executed, and no
2043 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
2044 See below for details.
2045 Full syntax: C<< (?(DEFINE)definitions...) >>
2046
2047 =back
2048
2049 For example:
2050
2051     m{ ( \( )?
2052        [^()]+
2053        (?(1) \) )
2054      }x
2055
2056 matches a chunk of non-parentheses, possibly included in parentheses
2057 themselves.
2058
2059 A special form is the C<(DEFINE)> predicate, which never executes its
2060 yes-pattern directly, and does not allow a no-pattern. This allows one to
2061 define subpatterns which will be executed only by the recursion mechanism.
2062 This way, you can define a set of regular expression rules that can be
2063 bundled into any pattern you choose.
2064
2065 It is recommended that for this usage you put the DEFINE block at the
2066 end of the pattern, and that you name any subpatterns defined within it.
2067
2068 Also, it's worth noting that patterns defined this way probably will
2069 not be as efficient, as the optimizer is not very clever about
2070 handling them.
2071
2072 An example of how this might be used is as follows:
2073
2074   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
2075    (?(DEFINE)
2076      (?<NAME_PAT>....)
2077      (?<ADDRESS_PAT>....)
2078    )/x
2079
2080 Note that capture groups matched inside of recursion are not accessible
2081 after the recursion returns, so the extra layer of capturing groups is
2082 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
2083 C<$+{NAME}> would be.
2084
2085 Finally, keep in mind that subpatterns created inside a DEFINE block
2086 count towards the absolute and relative number of captures, so this:
2087
2088     my @captures = "a" =~ /(.)                  # First capture
2089                            (?(DEFINE)
2090                                (?<EXAMPLE> 1 )  # Second capture
2091                            )/x;
2092     say scalar @captures;
2093
2094 Will output 2, not 1. This is particularly important if you intend to
2095 compile the definitions with the C<qr//> operator, and later
2096 interpolate them in another pattern.
2097
2098 =item C<< (?>pattern) >>
2099 X<backtrack> X<backtracking> X<atomic> X<possessive>
2100
2101 An "independent" subexpression, one which matches the substring
2102 that a I<standalone> C<pattern> would match if anchored at the given
2103 position, and it matches I<nothing other than this substring>.  This
2104 construct is useful for optimizations of what would otherwise be
2105 "eternal" matches, because it will not backtrack (see L</"Backtracking">).
2106 It may also be useful in places where the "grab all you can, and do not
2107 give anything back" semantic is desirable.
2108
2109 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
2110 (anchored at the beginning of string, as above) will match I<all>
2111 characters C<"a"> at the beginning of string, leaving no C<"a"> for
2112 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
2113 since the match of the subgroup C<a*> is influenced by the following
2114 group C<ab> (see L</"Backtracking">).  In particular, C<a*> inside
2115 C<a*ab> will match fewer characters than a standalone C<a*>, since
2116 this makes the tail match.
2117
2118 C<< (?>pattern) >> does not disable backtracking altogether once it has
2119 matched. It is still possible to backtrack past the construct, but not
2120 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
2121
2122 An effect similar to C<< (?>pattern) >> may be achieved by writing
2123 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
2124 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
2125 makes a zero-length assertion into an analogue of C<< (?>...) >>.
2126 (The difference between these two constructs is that the second one
2127 uses a capturing group, thus shifting ordinals of backreferences
2128 in the rest of a regular expression.)
2129
2130 Consider this pattern:
2131
2132     m{ \(
2133           (
2134             [^()]+           # x+
2135           |
2136             \( [^()]* \)
2137           )+
2138        \)
2139      }x
2140
2141 That will efficiently match a nonempty group with matching parentheses
2142 two levels deep or less.  However, if there is no such group, it
2143 will take virtually forever on a long string.  That's because there
2144 are so many different ways to split a long string into several
2145 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
2146 to a subpattern of the above pattern.  Consider how the pattern
2147 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
2148 seconds, but that each extra letter doubles this time.  This
2149 exponential performance will make it appear that your program has
2150 hung.  However, a tiny change to this pattern
2151
2152     m{ \(
2153           (
2154             (?> [^()]+ )        # change x+ above to (?> x+ )
2155           |
2156             \( [^()]* \)
2157           )+
2158        \)
2159      }x
2160
2161 which uses C<< (?>...) >> matches exactly when the one above does (verifying
2162 this yourself would be a productive exercise), but finishes in a fourth
2163 the time when used on a similar string with 1000000 C<"a">s.  Be aware,
2164 however, that, when this construct is followed by a
2165 quantifier, it currently triggers a warning message under
2166 the C<use warnings> pragma or B<-w> switch saying it
2167 C<"matches null string many times in regex">.
2168
2169 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
2170 effect may be achieved by negative lookahead, as in C<[^()]+ (?! [^()] )>.
2171 This was only 4 times slower on a string with 1000000 C<"a">s.
2172
2173 The "grab all you can, and do not give anything back" semantic is desirable
2174 in many situations where on the first sight a simple C<()*> looks like
2175 the correct solution.  Suppose we parse text with comments being delimited
2176 by C<"#"> followed by some optional (horizontal) whitespace.  Contrary to
2177 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
2178 the comment delimiter, because it may "give up" some whitespace if
2179 the remainder of the pattern can be made to match that way.  The correct
2180 answer is either one of these:
2181
2182     (?>#[ \t]*)
2183     #[ \t]*(?![ \t])
2184
2185 For example, to grab non-empty comments into C<$1>, one should use either
2186 one of these:
2187
2188     / (?> \# [ \t]* ) (        .+ ) /x;
2189     /     \# [ \t]*   ( [^ \t] .* ) /x;
2190
2191 Which one you pick depends on which of these expressions better reflects
2192 the above specification of comments.
2193
2194 In some literature this construct is called "atomic matching" or
2195 "possessive matching".
2196
2197 Possessive quantifiers are equivalent to putting the item they are applied
2198 to inside of one of these constructs. The following equivalences apply:
2199
2200     Quantifier Form     Bracketing Form
2201     ---------------     ---------------
2202     PAT*+               (?>PAT*)
2203     PAT++               (?>PAT+)
2204     PAT?+               (?>PAT?)
2205     PAT{min,max}+       (?>PAT{min,max})
2206
2207 =item C<(?[ ])>
2208
2209 See L<perlrecharclass/Extended Bracketed Character Classes>.
2210
2211 Note that this feature is currently L<experimental|perlpolicy/experimental>;
2212 using it yields a warning in the C<experimental::regex_sets> category.
2213
2214 =back
2215
2216 =head2 Backtracking
2217 X<backtrack> X<backtracking>
2218
2219 NOTE: This section presents an abstract approximation of regular
2220 expression behavior.  For a more rigorous (and complicated) view of
2221 the rules involved in selecting a match among possible alternatives,
2222 see L</Combining RE Pieces>.
2223
2224 A fundamental feature of regular expression matching involves the
2225 notion called I<backtracking>, which is currently used (when needed)
2226 by all regular non-possessive expression quantifiers, namely C<"*">, C<*?>, C<"+">,
2227 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2228 internally, but the general principle outlined here is valid.
2229
2230 For a regular expression to match, the I<entire> regular expression must
2231 match, not just part of it.  So if the beginning of a pattern containing a
2232 quantifier succeeds in a way that causes later parts in the pattern to
2233 fail, the matching engine backs up and recalculates the beginning
2234 part--that's why it's called backtracking.
2235
2236 Here is an example of backtracking:  Let's say you want to find the
2237 word following "foo" in the string "Food is on the foo table.":
2238
2239     $_ = "Food is on the foo table.";
2240     if ( /\b(foo)\s+(\w+)/i ) {
2241         print "$2 follows $1.\n";
2242     }
2243
2244 When the match runs, the first part of the regular expression (C<\b(foo)>)
2245 finds a possible match right at the beginning of the string, and loads up
2246 C<$1> with "Foo".  However, as soon as the matching engine sees that there's
2247 no whitespace following the "Foo" that it had saved in C<$1>, it realizes its
2248 mistake and starts over again one character after where it had the
2249 tentative match.  This time it goes all the way until the next occurrence
2250 of "foo". The complete regular expression matches this time, and you get
2251 the expected output of "table follows foo."
2252
2253 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2254 everything between "foo" and "bar".  Initially, you write something
2255 like this:
2256
2257     $_ =  "The food is under the bar in the barn.";
2258     if ( /foo(.*)bar/ ) {
2259         print "got <$1>\n";
2260     }
2261
2262 Which perhaps unexpectedly yields:
2263
2264   got <d is under the bar in the >
2265
2266 That's because C<.*> was greedy, so you get everything between the
2267 I<first> "foo" and the I<last> "bar".  Here it's more effective
2268 to use minimal matching to make sure you get the text between a "foo"
2269 and the first "bar" thereafter.
2270
2271     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2272   got <d is under the >
2273
2274 Here's another example. Let's say you'd like to match a number at the end
2275 of a string, and you also want to keep the preceding part of the match.
2276 So you write this:
2277
2278     $_ = "I have 2 numbers: 53147";
2279     if ( /(.*)(\d*)/ ) {                                # Wrong!
2280         print "Beginning is <$1>, number is <$2>.\n";
2281     }
2282
2283 That won't work at all, because C<.*> was greedy and gobbled up the
2284 whole string. As C<\d*> can match on an empty string the complete
2285 regular expression matched successfully.
2286
2287     Beginning is <I have 2 numbers: 53147>, number is <>.
2288
2289 Here are some variants, most of which don't work:
2290
2291     $_ = "I have 2 numbers: 53147";
2292     @pats = qw{
2293         (.*)(\d*)
2294         (.*)(\d+)
2295         (.*?)(\d*)
2296         (.*?)(\d+)
2297         (.*)(\d+)$
2298         (.*?)(\d+)$
2299         (.*)\b(\d+)$
2300         (.*\D)(\d+)$
2301     };
2302
2303     for $pat (@pats) {
2304         printf "%-12s ", $pat;
2305         if ( /$pat/ ) {
2306             print "<$1> <$2>\n";
2307         } else {
2308             print "FAIL\n";
2309         }
2310     }
2311
2312 That will print out:
2313
2314     (.*)(\d*)    <I have 2 numbers: 53147> <>
2315     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2316     (.*?)(\d*)   <> <>
2317     (.*?)(\d+)   <I have > <2>
2318     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2319     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2320     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2321     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2322
2323 As you see, this can be a bit tricky.  It's important to realize that a
2324 regular expression is merely a set of assertions that gives a definition
2325 of success.  There may be 0, 1, or several different ways that the
2326 definition might succeed against a particular string.  And if there are
2327 multiple ways it might succeed, you need to understand backtracking to
2328 know which variety of success you will achieve.
2329
2330 When using lookahead assertions and negations, this can all get even
2331 trickier.  Imagine you'd like to find a sequence of non-digits not
2332 followed by "123".  You might try to write that as
2333
2334     $_ = "ABC123";
2335     if ( /^\D*(?!123)/ ) {                # Wrong!
2336         print "Yup, no 123 in $_\n";
2337     }
2338
2339 But that isn't going to match; at least, not the way you're hoping.  It
2340 claims that there is no 123 in the string.  Here's a clearer picture of
2341 why that pattern matches, contrary to popular expectations:
2342
2343     $x = 'ABC123';
2344     $y = 'ABC445';
2345
2346     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2347     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2348
2349     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2350     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2351
2352 This prints
2353
2354     2: got ABC
2355     3: got AB
2356     4: got ABC
2357
2358 You might have expected test 3 to fail because it seems to a more
2359 general purpose version of test 1.  The important difference between
2360 them is that test 3 contains a quantifier (C<\D*>) and so can use
2361 backtracking, whereas test 1 will not.  What's happening is
2362 that you've asked "Is it true that at the start of C<$x>, following 0 or more
2363 non-digits, you have something that's not 123?"  If the pattern matcher had
2364 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2365 fail.
2366
2367 The search engine will initially match C<\D*> with "ABC".  Then it will
2368 try to match C<(?!123)> with "123", which fails.  But because
2369 a quantifier (C<\D*>) has been used in the regular expression, the
2370 search engine can backtrack and retry the match differently
2371 in the hope of matching the complete regular expression.
2372
2373 The pattern really, I<really> wants to succeed, so it uses the
2374 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2375 time.  Now there's indeed something following "AB" that is not
2376 "123".  It's "C123", which suffices.
2377
2378 We can deal with this by using both an assertion and a negation.
2379 We'll say that the first part in C<$1> must be followed both by a digit
2380 and by something that's not "123".  Remember that the lookaheads
2381 are zero-width expressions--they only look, but don't consume any
2382 of the string in their match.  So rewriting this way produces what
2383 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2384
2385     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2386     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2387
2388     6: got ABC
2389
2390 In other words, the two zero-width assertions next to each other work as though
2391 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2392 matches only if you're at the beginning of the line AND the end of the
2393 line simultaneously.  The deeper underlying truth is that juxtaposition in
2394 regular expressions always means AND, except when you write an explicit OR
2395 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2396 although the attempted matches are made at different positions because "a"
2397 is not a zero-width assertion, but a one-width assertion.
2398
2399 B<WARNING>: Particularly complicated regular expressions can take
2400 exponential time to solve because of the immense number of possible
2401 ways they can use backtracking to try for a match.  For example, without
2402 internal optimizations done by the regular expression engine, this will
2403 take a painfully long time to run:
2404
2405     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2406
2407 And if you used C<"*">'s in the internal groups instead of limiting them
2408 to 0 through 5 matches, then it would take forever--or until you ran
2409 out of stack space.  Moreover, these internal optimizations are not
2410 always applicable.  For example, if you put C<{0,5}> instead of C<"*">
2411 on the external group, no current optimization is applicable, and the
2412 match takes a long time to finish.
2413
2414 A powerful tool for optimizing such beasts is what is known as an
2415 "independent group",
2416 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2417 zero-length lookahead/lookbehind assertions will not backtrack to make
2418 the tail match, since they are in "logical" context: only
2419 whether they match is considered relevant.  For an example
2420 where side-effects of lookahead I<might> have influenced the
2421 following match, see L</C<< (?>pattern) >>>.
2422
2423 =head2 Script Runs
2424 X<(*script_run:...)> X<(sr:...)>
2425
2426 A script run is basically a sequence of characters, all from the same
2427 Unicode script (see L<perlunicode/Scripts>), such as Latin or Greek.  In
2428 most places a single word would never be written in multiple scripts,
2429 unless it is a spoofing attack.  An infamous example, is
2430
2431  paypal.com
2432
2433 Those letters could all be Latin (as in the example just above), or they
2434 could be all Cyrillic (except for the dot), or they could be a mixture
2435 of the two.  In the case of an internet address the C<.com> would be in
2436 Latin, And any Cyrillic ones would cause it to be a mixture, not a
2437 script run.  Someone clicking on such a link would not be directed to
2438 the real Paypal website, but an attacker would craft a look-alike one to
2439 attempt to gather sensitive information from the person.
2440
2441 Starting in Perl 5.28, it is now easy to detect strings that aren't
2442 script runs.  Simply enclose just about any pattern like either of
2443 these:
2444
2445  (*script_run:pattern)
2446  (*sr:pattern)
2447
2448 What happens is that after I<pattern> succeeds in matching, it is
2449 subjected to the additional criterion that every character in it must be
2450 from the same script (see exceptions below).  If this isn't true,
2451 backtracking occurs until something all in the same script is found that
2452 matches, or all possibilities are exhausted.  This can cause a lot of
2453 backtracking, but generally, only malicious input will result in this,
2454 though the slow down could cause a denial of service attack.  If your
2455 needs permit, it is best to make the pattern atomic.
2456
2457  (*script_run:(?>pattern))
2458
2459 (See L</C<(?E<gt>pattern)>>.)
2460
2461 In Taiwan, Japan, and Korea, it is common for text to have a mixture of
2462 characters from their native scripts and base Chinese.  Perl follows
2463 Unicode's UTS 39 (L<http://unicode.org/reports/tr39/>) Unicode Security
2464 Mechanisms in allowing such mixtures.
2465
2466 The rules used for matching decimal digits are somewhat different.  Many
2467 scripts have their own sets of digits equivalent to the Western C<0>
2468 through C<9> ones.  A few, such as Arabic, have more than one set.  For
2469 a string to be considered a script run, all digits in it must come from
2470 the same set, as determined by the first digit encountered. The ASCII
2471 C<[0-9]> are accepted as being in any script, even those that have their
2472 own set.  This is because these are often used in commerce even in such
2473 scripts.  But any mixing of the ASCII and other digits will cause the
2474 sequence to not be a script run, failing the match.  As an example,
2475
2476  qr/(*script_run: \d+ \b )/x
2477
2478 guarantees that the digits matched will all be from the same set of 10.
2479 You won't get a look-alike digit from a different script that has a
2480 different value than what it appears to be.
2481
2482 Unicode has three pseudo scripts that are handled specially.
2483
2484 "Unknown" is applied to code points whose meaning has yet to be
2485 determined.  Perl currently will match as a script run, any single
2486 character string consisting of one of these code points.  But any string
2487 longer than one code point containing one of these will not be
2488 considered a script run.
2489
2490 "Inherited" is applied to characters that modify another, such as an
2491 accent of some type.  These are considered to be in the script of the
2492 master character, and so never cause a script run to not match.
2493
2494 The other one is "Common".  This consists of mostly punctuation, emoji,
2495 and characters used in mathematics and music, and the ASCII digits C<0>
2496 through C<9>.  These characters can appear intermixed in text in many of
2497 the world's scripts.  These also don't cause a script run to not match,
2498 except any ASCII digits encountered have to obey the decimal digit rules
2499 described above.
2500
2501 This construct is non-capturing.  You can add parentheses to I<pattern>
2502 to capture, if desired.  You will have to do this if you plan to use
2503 L</(*ACCEPT) (*ACCEPT:arg)> and not have it bypass the script run
2504 checking.
2505
2506 This feature is experimental, and the exact syntax and details of
2507 operation are subject to change; using it yields a warning in the
2508 C<experimental::script_run> category.
2509
2510 The C<Script_Extensions> property is used as the basis for this feature.
2511
2512 =head2 Special Backtracking Control Verbs
2513
2514 These special patterns are generally of the form C<(*I<VERB>:I<ARG>)>. Unless
2515 otherwise stated the I<ARG> argument is optional; in some cases, it is
2516 mandatory.
2517
2518 Any pattern containing a special backtracking verb that allows an argument
2519 has the special behaviour that when executed it sets the current package's
2520 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
2521 rules apply:
2522
2523 On failure, the C<$REGERROR> variable will be set to the I<ARG> value of the
2524 verb pattern, if the verb was involved in the failure of the match. If the
2525 I<ARG> part of the pattern was omitted, then C<$REGERROR> will be set to the
2526 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
2527 none. Also, the C<$REGMARK> variable will be set to FALSE.
2528
2529 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
2530 the C<$REGMARK> variable will be set to the name of the last
2531 C<(*MARK:NAME)> pattern executed.  See the explanation for the
2532 C<(*MARK:NAME)> verb below for more details.
2533
2534 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
2535 and most other regex-related variables. They are not local to a scope, nor
2536 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
2537 They are set in the package containing the code that I<executed> the regex
2538 (rather than the one that compiled it, where those differ).  If necessary, you
2539 can use C<local> to localize changes to these variables to a specific scope
2540 before executing a regex.
2541
2542 If a pattern does not contain a special backtracking verb that allows an
2543 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
2544
2545 =over 3
2546
2547 =item Verbs
2548
2549 =over 4
2550
2551 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
2552 X<(*PRUNE)> X<(*PRUNE:NAME)>
2553
2554 This zero-width pattern prunes the backtracking tree at the current point
2555 when backtracked into on failure. Consider the pattern C</I<A> (*PRUNE) I<B>/>,
2556 where I<A> and I<B> are complex patterns. Until the C<(*PRUNE)> verb is reached,
2557 I<A> may backtrack as necessary to match. Once it is reached, matching
2558 continues in I<B>, which may also backtrack as necessary; however, should B
2559 not match, then no further backtracking will take place, and the pattern
2560 will fail outright at the current starting position.
2561
2562 The following example counts all the possible matching strings in a
2563 pattern (without actually matching any of them).
2564
2565     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
2566     print "Count=$count\n";
2567
2568 which produces:
2569
2570     aaab
2571     aaa
2572     aa
2573     a
2574     aab
2575     aa
2576     a
2577     ab
2578     a
2579     Count=9
2580
2581 If we add a C<(*PRUNE)> before the count like the following
2582
2583     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
2584     print "Count=$count\n";
2585
2586 we prevent backtracking and find the count of the longest matching string
2587 at each matching starting point like so:
2588
2589     aaab
2590     aab
2591     ab
2592     Count=3
2593
2594 Any number of C<(*PRUNE)> assertions may be used in a pattern.
2595
2596 See also C<<< L<< /(?>pattern) >> >>> and possessive quantifiers for
2597 other ways to
2598 control backtracking. In some cases, the use of C<(*PRUNE)> can be
2599 replaced with a C<< (?>pattern) >> with no functional difference; however,
2600 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
2601 C<< (?>pattern) >> alone.
2602
2603 =item C<(*SKIP)> C<(*SKIP:NAME)>
2604 X<(*SKIP)>
2605
2606 This zero-width pattern is similar to C<(*PRUNE)>, except that on
2607 failure it also signifies that whatever text that was matched leading up
2608 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
2609 of this pattern. This effectively means that the regex engine "skips" forward
2610 to this position on failure and tries to match again, (assuming that
2611 there is sufficient room to match).
2612
2613 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
2614 C<(*MARK:NAME)> was encountered while matching, then it is that position
2615 which is used as the "skip point". If no C<(*MARK)> of that name was
2616 encountered, then the C<(*SKIP)> operator has no effect. When used
2617 without a name the "skip point" is where the match point was when
2618 executing the C<(*SKIP)> pattern.
2619
2620 Compare the following to the examples in C<(*PRUNE)>; note the string
2621 is twice as long:
2622
2623  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
2624  print "Count=$count\n";
2625
2626 outputs
2627
2628     aaab
2629     aaab
2630     Count=2
2631
2632 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
2633 executed, the next starting point will be where the cursor was when the
2634 C<(*SKIP)> was executed.
2635
2636 =item C<(*MARK:NAME)> C<(*:NAME)>
2637 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
2638
2639 This zero-width pattern can be used to mark the point reached in a string
2640 when a certain part of the pattern has been successfully matched. This
2641 mark may be given a name. A later C<(*SKIP)> pattern will then skip
2642 forward to that point if backtracked into on failure. Any number of
2643 C<(*MARK)> patterns are allowed, and the I<NAME> portion may be duplicated.
2644
2645 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
2646 can be used to "label" a pattern branch, so that after matching, the
2647 program can determine which branches of the pattern were involved in the
2648 match.
2649
2650 When a match is successful, the C<$REGMARK> variable will be set to the
2651 name of the most recently executed C<(*MARK:NAME)> that was involved
2652 in the match.
2653
2654 This can be used to determine which branch of a pattern was matched
2655 without using a separate capture group for each branch, which in turn
2656 can result in a performance improvement, as perl cannot optimize
2657 C</(?:(x)|(y)|(z))/> as efficiently as something like
2658 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
2659
2660 When a match has failed, and unless another verb has been involved in
2661 failing the match and has provided its own name to use, the C<$REGERROR>
2662 variable will be set to the name of the most recently executed
2663 C<(*MARK:NAME)>.
2664
2665 See L</(*SKIP)> for more details.
2666
2667 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
2668
2669 =item C<(*THEN)> C<(*THEN:NAME)>
2670
2671 This is similar to the "cut group" operator C<::> from Perl 6.  Like
2672 C<(*PRUNE)>, this verb always matches, and when backtracked into on
2673 failure, it causes the regex engine to try the next alternation in the
2674 innermost enclosing group (capturing or otherwise) that has alternations.
2675 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
2676 count as an alternation, as far as C<(*THEN)> is concerned.
2677
2678 Its name comes from the observation that this operation combined with the
2679 alternation operator (C<"|">) can be used to create what is essentially a
2680 pattern-based if/then/else block:
2681
2682   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2683
2684 Note that if this operator is used and NOT inside of an alternation then
2685 it acts exactly like the C<(*PRUNE)> operator.
2686
2687   / A (*PRUNE) B /
2688
2689 is the same as
2690
2691   / A (*THEN) B /
2692
2693 but
2694
2695   / ( A (*THEN) B | C ) /
2696
2697 is not the same as
2698
2699   / ( A (*PRUNE) B | C ) /
2700
2701 as after matching the I<A> but failing on the I<B> the C<(*THEN)> verb will
2702 backtrack and try I<C>; but the C<(*PRUNE)> verb will simply fail.
2703
2704 =item C<(*COMMIT)> C<(*COMMIT:args)>
2705 X<(*COMMIT)>
2706
2707 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2708 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2709 into on failure it causes the match to fail outright. No further attempts
2710 to find a valid match by advancing the start pointer will occur again.
2711 For example,
2712
2713  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2714  print "Count=$count\n";
2715
2716 outputs
2717
2718     aaab
2719     Count=1
2720
2721 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2722 does not match, the regex engine will not try any further matching on the
2723 rest of the string.
2724
2725 =item C<(*FAIL)> C<(*F)> C<(*FAIL:arg)>
2726 X<(*FAIL)> X<(*F)>
2727
2728 This pattern matches nothing and always fails. It can be used to force the
2729 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2730 fact, C<(?!)> gets optimised into C<(*FAIL)> internally. You can provide
2731 an argument so that if the match fails because of this C<FAIL> directive
2732 the argument can be obtained from C<$REGERROR>.
2733
2734 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2735
2736 =item C<(*ACCEPT)> C<(*ACCEPT:arg)>
2737 X<(*ACCEPT)>
2738
2739 This pattern matches nothing and causes the end of successful matching at
2740 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2741 whether there is actually more to match in the string. When inside of a
2742 nested pattern, such as recursion, or in a subpattern dynamically generated
2743 via C<(??{})>, only the innermost pattern is ended immediately.
2744
2745 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2746 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2747 For instance:
2748
2749   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2750
2751 will match, and C<$1> will be C<AB> and C<$2> will be C<"B">, C<$3> will not
2752 be set. If another branch in the inner parentheses was matched, such as in the
2753 string 'ACDE', then the C<"D"> and C<"E"> would have to be matched as well.
2754
2755 You can provide an argument, which will be available in the var
2756 C<$REGMARK> after the match completes.
2757
2758 =back
2759
2760 =back
2761
2762 =head2 Warning on C<\1> Instead of C<$1>
2763
2764 Some people get too used to writing things like:
2765
2766     $pattern =~ s/(\W)/\\\1/g;
2767
2768 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2769 shocking the
2770 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2771 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2772 the usual double-quoted string means a control-A.  The customary Unix
2773 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2774 of doing that, you get yourself into trouble if you then add an C</e>
2775 modifier.
2776
2777     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2778
2779 Or if you try to do
2780
2781     s/(\d+)/\1000/;
2782
2783 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2784 C<${1}000>.  The operation of interpolation should not be confused
2785 with the operation of matching a backreference.  Certainly they mean two
2786 different things on the I<left> side of the C<s///>.
2787
2788 =head2 Repeated Patterns Matching a Zero-length Substring
2789
2790 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2791
2792 Regular expressions provide a terse and powerful programming language.  As
2793 with most other power tools, power comes together with the ability
2794 to wreak havoc.
2795
2796 A common abuse of this power stems from the ability to make infinite
2797 loops using regular expressions, with something as innocuous as:
2798
2799     'foo' =~ m{ ( o? )* }x;
2800
2801 The C<o?> matches at the beginning of "C<foo>", and since the position
2802 in the string is not moved by the match, C<o?> would match again and again
2803 because of the C<"*"> quantifier.  Another common way to create a similar cycle
2804 is with the looping modifier C</g>:
2805
2806     @matches = ( 'foo' =~ m{ o? }xg );
2807
2808 or
2809
2810     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2811
2812 or the loop implied by C<split()>.
2813
2814 However, long experience has shown that many programming tasks may
2815 be significantly simplified by using repeated subexpressions that
2816 may match zero-length substrings.  Here's a simple example being:
2817
2818     @chars = split //, $string;           # // is not magic in split
2819     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2820
2821 Thus Perl allows such constructs, by I<forcefully breaking
2822 the infinite loop>.  The rules for this are different for lower-level
2823 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2824 ones like the C</g> modifier or C<split()> operator.
2825
2826 The lower-level loops are I<interrupted> (that is, the loop is
2827 broken) when Perl detects that a repeated expression matched a
2828 zero-length substring.   Thus
2829
2830    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2831
2832 is made equivalent to
2833
2834    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2835
2836 For example, this program
2837
2838    #!perl -l
2839    "aaaaab" =~ /
2840      (?:
2841         a                 # non-zero
2842         |                 # or
2843        (?{print "hello"}) # print hello whenever this
2844                           #    branch is tried
2845        (?=(b))            # zero-width assertion
2846      )*  # any number of times
2847     /x;
2848    print $&;
2849    print $1;
2850
2851 prints
2852
2853    hello
2854    aaaaa
2855    b
2856
2857 Notice that "hello" is only printed once, as when Perl sees that the sixth
2858 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2859 the C<"*">.
2860
2861 The higher-level loops preserve an additional state between iterations:
2862 whether the last match was zero-length.  To break the loop, the following
2863 match after a zero-length match is prohibited to have a length of zero.
2864 This prohibition interacts with backtracking (see L</"Backtracking">),
2865 and so the I<second best> match is chosen if the I<best> match is of
2866 zero length.
2867
2868 For example:
2869
2870     $_ = 'bar';
2871     s/\w??/<$&>/g;
2872
2873 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2874 match given by non-greedy C<??> is the zero-length match, and the I<second
2875 best> match is what is matched by C<\w>.  Thus zero-length matches
2876 alternate with one-character-long matches.
2877
2878 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2879 position one notch further in the string.
2880
2881 The additional state of being I<matched with zero-length> is associated with
2882 the matched string, and is reset by each assignment to C<pos()>.
2883 Zero-length matches at the end of the previous match are ignored
2884 during C<split>.
2885
2886 =head2 Combining RE Pieces
2887
2888 Each of the elementary pieces of regular expressions which were described
2889 before (such as C<ab> or C<\Z>) could match at most one substring
2890 at the given position of the input string.  However, in a typical regular
2891 expression these elementary pieces are combined into more complicated
2892 patterns using combining operators C<ST>, C<S|T>, C<S*> I<etc>.
2893 (in these examples C<"S"> and C<"T"> are regular subexpressions).
2894
2895 Such combinations can include alternatives, leading to a problem of choice:
2896 if we match a regular expression C<a|ab> against C<"abc">, will it match
2897 substring C<"a"> or C<"ab">?  One way to describe which substring is
2898 actually matched is the concept of backtracking (see L</"Backtracking">).
2899 However, this description is too low-level and makes you think
2900 in terms of a particular implementation.
2901
2902 Another description starts with notions of "better"/"worse".  All the
2903 substrings which may be matched by the given regular expression can be
2904 sorted from the "best" match to the "worst" match, and it is the "best"
2905 match which is chosen.  This substitutes the question of "what is chosen?"
2906 by the question of "which matches are better, and which are worse?".
2907
2908 Again, for elementary pieces there is no such question, since at most
2909 one match at a given position is possible.  This section describes the
2910 notion of better/worse for combining operators.  In the description
2911 below C<"S"> and C<"T"> are regular subexpressions.
2912
2913 =over 4
2914
2915 =item C<ST>
2916
2917 Consider two possible matches, C<AB> and C<A'B'>, C<"A"> and C<A'> are
2918 substrings which can be matched by C<"S">, C<"B"> and C<B'> are substrings
2919 which can be matched by C<"T">.
2920
2921 If C<"A"> is a better match for C<"S"> than C<A'>, C<AB> is a better
2922 match than C<A'B'>.
2923
2924 If C<"A"> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2925 C<"B"> is a better match for C<"T"> than C<B'>.
2926
2927 =item C<S|T>
2928
2929 When C<"S"> can match, it is a better match than when only C<"T"> can match.
2930
2931 Ordering of two matches for C<"S"> is the same as for C<"S">.  Similar for
2932 two matches for C<"T">.
2933
2934 =item C<S{REPEAT_COUNT}>
2935
2936 Matches as C<SSS...S> (repeated as many times as necessary).
2937
2938 =item C<S{min,max}>
2939
2940 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2941
2942 =item C<S{min,max}?>
2943
2944 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2945
2946 =item C<S?>, C<S*>, C<S+>
2947
2948 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2949
2950 =item C<S??>, C<S*?>, C<S+?>
2951
2952 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2953
2954 =item C<< (?>S) >>
2955
2956 Matches the best match for C<"S"> and only that.
2957
2958 =item C<(?=S)>, C<(?<=S)>
2959
2960 Only the best match for C<"S"> is considered.  (This is important only if
2961 C<"S"> has capturing parentheses, and backreferences are used somewhere
2962 else in the whole regular expression.)
2963
2964 =item C<(?!S)>, C<(?<!S)>
2965
2966 For this grouping operator there is no need to describe the ordering, since
2967 only whether or not C<"S"> can match is important.
2968
2969 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
2970
2971 The ordering is the same as for the regular expression which is
2972 the result of EXPR, or the pattern contained by capture group I<PARNO>.
2973
2974 =item C<(?(condition)yes-pattern|no-pattern)>
2975
2976 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2977 already determined.  The ordering of the matches is the same as for the
2978 chosen subexpression.
2979
2980 =back
2981
2982 The above recipes describe the ordering of matches I<at a given position>.
2983 One more rule is needed to understand how a match is determined for the
2984 whole regular expression: a match at an earlier position is always better
2985 than a match at a later position.
2986
2987 =head2 Creating Custom RE Engines
2988
2989 As of Perl 5.10.0, one can create custom regular expression engines.  This
2990 is not for the faint of heart, as they have to plug in at the C level.  See
2991 L<perlreapi> for more details.
2992
2993 As an alternative, overloaded constants (see L<overload>) provide a simple
2994 way to extend the functionality of the RE engine, by substituting one
2995 pattern for another.
2996
2997 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2998 matches at a boundary between whitespace characters and non-whitespace
2999 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
3000 at these positions, so we want to have each C<\Y|> in the place of the
3001 more complicated version.  We can create a module C<customre> to do
3002 this:
3003
3004     package customre;
3005     use overload;
3006
3007     sub import {
3008       shift;
3009       die "No argument to customre::import allowed" if @_;
3010       overload::constant 'qr' => \&convert;
3011     }
3012
3013     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
3014
3015     # We must also take care of not escaping the legitimate \\Y|
3016     # sequence, hence the presence of '\\' in the conversion rules.
3017     my %rules = ( '\\' => '\\\\',
3018                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
3019     sub convert {
3020       my $re = shift;
3021       $re =~ s{
3022                 \\ ( \\ | Y . )
3023               }
3024               { $rules{$1} or invalid($re,$1) }sgex;
3025       return $re;
3026     }
3027
3028 Now C<use customre> enables the new escape in constant regular
3029 expressions, I<i.e.>, those without any runtime variable interpolations.
3030 As documented in L<overload>, this conversion will work only over
3031 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
3032 part of this regular expression needs to be converted explicitly
3033 (but only if the special meaning of C<\Y|> should be enabled inside C<$re>):
3034
3035     use customre;
3036     $re = <>;
3037     chomp $re;
3038     $re = customre::convert $re;
3039     /\Y|$re\Y|/;
3040
3041 =head2 Embedded Code Execution Frequency
3042
3043 The exact rules for how often C<(??{})> and C<(?{})> are executed in a pattern
3044 are unspecified.  In the case of a successful match you can assume that
3045 they DWIM and will be executed in left to right order the appropriate
3046 number of times in the accepting path of the pattern as would any other
3047 meta-pattern.  How non-accepting pathways and match failures affect the
3048 number of times a pattern is executed is specifically unspecified and
3049 may vary depending on what optimizations can be applied to the pattern
3050 and is likely to change from version to version.
3051
3052 For instance in
3053
3054   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
3055
3056 the exact number of times "a" or "b" are printed out is unspecified for
3057 failure, but you may assume they will be printed at least once during
3058 a successful match, additionally you may assume that if "b" is printed,
3059 it will be preceded by at least one "a".
3060
3061 In the case of branching constructs like the following:
3062
3063   /a(b|(?{ print "a" }))c(?{ print "c" })/;
3064
3065 you can assume that the input "ac" will output "ac", and that "abc"
3066 will output only "c".
3067
3068 When embedded code is quantified, successful matches will call the
3069 code once for each matched iteration of the quantifier.  For
3070 example:
3071
3072   "good" =~ /g(?:o(?{print "o"}))*d/;
3073
3074 will output "o" twice.
3075
3076 =head2 PCRE/Python Support
3077
3078 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
3079 to the regex syntax. While Perl programmers are encouraged to use the
3080 Perl-specific syntax, the following are also accepted:
3081
3082 =over 4
3083
3084 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
3085
3086 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
3087
3088 =item C<< (?P=NAME) >>
3089
3090 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
3091
3092 =item C<< (?P>NAME) >>
3093
3094 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
3095
3096 =back
3097
3098 =head1 BUGS
3099
3100 There are a number of issues with regard to case-insensitive matching
3101 in Unicode rules.  See C<"i"> under L</Modifiers> above.
3102
3103 This document varies from difficult to understand to completely
3104 and utterly opaque.  The wandering prose riddled with jargon is
3105 hard to fathom in several places.
3106
3107 This document needs a rewrite that separates the tutorial content
3108 from the reference content.
3109
3110 =head1 SEE ALSO
3111
3112 The syntax of patterns used in Perl pattern matching evolved from those
3113 supplied in the Bell Labs Research Unix 8th Edition (Version 8) regex
3114 routines.  (The code is actually derived (distantly) from Henry
3115 Spencer's freely redistributable reimplementation of those V8 routines.)
3116
3117 L<perlrequick>.
3118
3119 L<perlretut>.
3120
3121 L<perlop/"Regexp Quote-Like Operators">.
3122
3123 L<perlop/"Gory details of parsing quoted constructs">.
3124
3125 L<perlfaq6>.
3126
3127 L<perlfunc/pos>.
3128
3129 L<perllocale>.
3130
3131 L<perlebcdic>.
3132
3133 I<Mastering Regular Expressions> by Jeffrey Friedl, published
3134 by O'Reilly and Associates.