This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[perl #115066] Fix wrongly nested ‘use’ deparsing
[perl5.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPf_PARENS
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER OPpREPEAT_DOLIST
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          SVpad_TYPED
21          CVf_METHOD CVf_LVALUE
22          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
23          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED PMf_EXTENDED_MORE);
24 $VERSION = '1.30';
25 use strict;
26 use vars qw/$AUTOLOAD/;
27 use warnings ();
28 require feature;
29
30 BEGIN {
31     # List version-specific constants here.
32     # Easiest way to keep this code portable between version looks to
33     # be to fake up a dummy constant that will never actually be true.
34     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
35                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
36                 RXf_PMf_CHARSET RXf_PMf_KEEPCOPY
37                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
38                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES
39                 OPpLVREF_TYPE OPpLVREF_SV OPpLVREF_AV OPpLVREF_HV
40                 OPpLVREF_CV OPpLVREF_ELEM SVpad_STATE)) {
41         eval { import B $_ };
42         no strict 'refs';
43         *{$_} = sub () {0} unless *{$_}{CODE};
44     }
45 }
46
47 # Changes between 0.50 and 0.51:
48 # - fixed nulled leave with live enter in sort { }
49 # - fixed reference constants (\"str")
50 # - handle empty programs gracefully
51 # - handle infinite loops (for (;;) {}, while (1) {})
52 # - differentiate between 'for my $x ...' and 'my $x; for $x ...'
53 # - various minor cleanups
54 # - moved globals into an object
55 # - added '-u', like B::C
56 # - package declarations using cop_stash
57 # - subs, formats and code sorted by cop_seq
58 # Changes between 0.51 and 0.52:
59 # - added pp_threadsv (special variables under USE_5005THREADS)
60 # - added documentation
61 # Changes between 0.52 and 0.53:
62 # - many changes adding precedence contexts and associativity
63 # - added '-p' and '-s' output style options
64 # - various other minor fixes
65 # Changes between 0.53 and 0.54:
66 # - added support for new 'for (1..100)' optimization,
67 #   thanks to Gisle Aas
68 # Changes between 0.54 and 0.55:
69 # - added support for new qr// construct
70 # - added support for new pp_regcreset OP
71 # Changes between 0.55 and 0.56:
72 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
73 # - fixed $# on non-lexicals broken in last big rewrite
74 # - added temporary fix for change in opcode of OP_STRINGIFY
75 # - fixed problem in 0.54's for() patch in 'for (@ary)'
76 # - fixed precedence in conditional of ?:
77 # - tweaked list paren elimination in 'my($x) = @_'
78 # - made continue-block detection trickier wrt. null ops
79 # - fixed various prototype problems in pp_entersub
80 # - added support for sub prototypes that never get GVs
81 # - added unquoting for special filehandle first arg in truncate
82 # - print doubled rv2gv (a bug) as '*{*GV}' instead of illegal '**GV'
83 # - added semicolons at the ends of blocks
84 # - added -l '#line' declaration option -- fixes cmd/subval.t 27,28
85 # Changes between 0.56 and 0.561:
86 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
87 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
88 # Changes between 0.561 and 0.57:
89 # - stylistic changes to symbolic constant stuff
90 # - handled scope in s///e replacement code
91 # - added unquote option for expanding "" into concats, etc.
92 # - split method and proto parts of pp_entersub into separate functions
93 # - various minor cleanups
94 # Changes after 0.57:
95 # - added parens in \&foo (patch by Albert Dvornik)
96 # Changes between 0.57 and 0.58:
97 # - fixed '0' statements that weren't being printed
98 # - added methods for use from other programs
99 #   (based on patches from James Duncan and Hugo van der Sanden)
100 # - added -si and -sT to control indenting (also based on a patch from Hugo)
101 # - added -sv to print something else instead of '???'
102 # - preliminary version of utf8 tr/// handling
103 # Changes after 0.58:
104 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
105 # - added support for Hugo's new OP_SETSTATE (like nextstate)
106 # Changes between 0.58 and 0.59
107 # - added support for Chip's OP_METHOD_NAMED
108 # - added support for Ilya's OPpTARGET_MY optimization
109 # - elided arrows before '()' subscripts when possible
110 # Changes between 0.59 and 0.60
111 # - support for method attributes was added
112 # - some warnings fixed
113 # - separate recognition of constant subs
114 # - rewrote continue block handling, now recognizing for loops
115 # - added more control of expanding control structures
116 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
117 # - many bug-fixes
118 # - support for pragmas and 'use'
119 # - support for the little-used $[ variable
120 # - support for __DATA__ sections
121 # - UTF8 support
122 # - BEGIN, CHECK, INIT and END blocks
123 # - scoping of subroutine declarations fixed
124 # - compile-time output from the input program can be suppressed, so that the
125 #   output is just the deparsed code. (a change to O.pm in fact)
126 # - our() declarations
127 # - *all* the known bugs are now listed in the BUGS section
128 # - comprehensive test mechanism (TEST -deparse)
129 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
130 # - bug-fixes
131 # - new switch -P
132 # - support for command-line switches (-l, -0, etc.)
133 # Changes between 0.63 and 0.64
134 # - support for //, CHECK blocks, and assertions
135 # - improved handling of foreach loops and lexicals
136 # - option to use Data::Dumper for constants
137 # - more bug fixes
138 # - discovered lots more bugs not yet fixed
139 #
140 # ...
141 #
142 # Changes between 0.72 and 0.73
143 # - support new switch constructs
144
145 # Todo:
146 #  (See also BUGS section at the end of this file)
147 #
148 # - finish tr/// changes
149 # - add option for even more parens (generalize \&foo change)
150 # - left/right context
151 # - copy comments (look at real text with $^P?)
152 # - avoid semis in one-statement blocks
153 # - associativity of &&=, ||=, ?:
154 # - ',' => '=>' (auto-unquote?)
155 # - break long lines ("\r" as discretionary break?)
156 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
157 # - more style options: brace style, hex vs. octal, quotes, ...
158 # - print big ints as hex/octal instead of decimal (heuristic?)
159 # - handle 'my $x if 0'?
160 # - version using op_next instead of op_first/sibling?
161 # - avoid string copies (pass arrays, one big join?)
162 # - here-docs?
163
164 # Current test.deparse failures
165 # comp/hints 6 - location of BEGIN blocks wrt. block openings
166 # run/switchI 1 - missing -I switches entirely
167 #    perl -Ifoo -e 'print @INC'
168 # op/caller 2 - warning mask propagates backwards before warnings::register
169 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
170 # op/getpid 2 - can't assign to shared my() declaration (threads only)
171 #    'my $x : shared = 5'
172 # op/override 7 - parens on overridden require change v-string interpretation
173 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
174 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
175 # op/pat 774 - losing Unicode-ness of Latin1-only strings
176 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
177 # op/recurse 12 - missing parens on recursive call makes it look like method
178 #    'sub f { f($x) }'
179 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
180 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
181 # op/tiehandle compile - "use strict" deparsed in the wrong place
182 # uni/tr_ several
183 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
184 # ext/Data/Dumper/t/dumper compile
185 # ext/DB_file/several
186 # ext/Encode/several
187 # ext/Ernno/Errno warnings
188 # ext/IO/lib/IO/t/io_sel 23
189 # ext/PerlIO/t/encoding compile
190 # ext/POSIX/t/posix 6
191 # ext/Socket/Socket 8
192 # ext/Storable/t/croak compile
193 # lib/Attribute/Handlers/t/multi compile
194 # lib/bignum/ several
195 # lib/charnames 35
196 # lib/constant 32
197 # lib/English 40
198 # lib/ExtUtils/t/bytes 4
199 # lib/File/DosGlob compile
200 # lib/Filter/Simple/t/data 1
201 # lib/Math/BigInt/t/constant 1
202 # lib/Net/t/config Deparse-warning
203 # lib/overload compile
204 # lib/Switch/ several
205 # lib/Symbol 4
206 # lib/Test/Simple several
207 # lib/Term/Complete
208 # lib/Tie/File/t/29_downcopy 5
209 # lib/vars 22
210
211 # Object fields (were globals):
212 #
213 # avoid_local:
214 # (local($a), local($b)) and local($a, $b) have the same internal
215 # representation but the short form looks better. We notice we can
216 # use a large-scale local when checking the list, but need to prevent
217 # individual locals too. This hash holds the addresses of OPs that
218 # have already had their local-ness accounted for. The same thing
219 # is done with my().
220 #
221 # curcv:
222 # CV for current sub (or main program) being deparsed
223 #
224 # curcvlex:
225 # Cached hash of lexical variables for curcv: keys are
226 # names prefixed with "m" or "o" (representing my/our), and
227 # each value is an array with two elements indicating the cop_seq
228 # of scopes in which a var of that name is valid and a third ele-
229 # ment referencing the pad name.
230 #
231 # curcop:
232 # COP for statement being deparsed
233 #
234 # curstash:
235 # name of the current package for deparsed code
236 #
237 # subs_todo:
238 # array of [cop_seq, CV, is_format?] for subs and formats we still
239 # want to deparse
240 #
241 # protos_todo:
242 # as above, but [name, prototype] for subs that never got a GV
243 #
244 # subs_done, forms_done:
245 # keys are addresses of GVs for subs and formats we've already
246 # deparsed (or at least put into subs_todo)
247 #
248 # subs_declared
249 # keys are names of subs for which we've printed declarations.
250 # That means we can omit parentheses from the arguments. It also means we
251 # need to put CORE:: on core functions of the same name.
252 #
253 # subs_deparsed
254 # Keeps track of fully qualified names of all deparsed subs.
255 #
256 # in_subst_repl
257 # True when deparsing the replacement part of a substitution.
258 #
259 # in_refgen
260 # True when deparsing the argument to \.
261 #
262 # parens: -p
263 # linenums: -l
264 # unquote: -q
265 # cuddle: ' ' or '\n', depending on -sC
266 # indent_size: -si
267 # use_tabs: -sT
268 # ex_const: -sv
269
270 # A little explanation of how precedence contexts and associativity
271 # work:
272 #
273 # deparse() calls each per-op subroutine with an argument $cx (short
274 # for context, but not the same as the cx* in the perl core), which is
275 # a number describing the op's parents in terms of precedence, whether
276 # they're inside an expression or at statement level, etc.  (see
277 # chart below). When ops with children call deparse on them, they pass
278 # along their precedence. Fractional values are used to implement
279 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
280 # parentheses hacks. The major disadvantage of this scheme is that
281 # it doesn't know about right sides and left sides, so say if you
282 # assign a listop to a variable, it can't tell it's allowed to leave
283 # the parens off the listop.
284
285 # Precedences:
286 # 26             [TODO] inside interpolation context ("")
287 # 25 left        terms and list operators (leftward)
288 # 24 left        ->
289 # 23 nonassoc    ++ --
290 # 22 right       **
291 # 21 right       ! ~ \ and unary + and -
292 # 20 left        =~ !~
293 # 19 left        * / % x
294 # 18 left        + - .
295 # 17 left        << >>
296 # 16 nonassoc    named unary operators
297 # 15 nonassoc    < > <= >= lt gt le ge
298 # 14 nonassoc    == != <=> eq ne cmp
299 # 13 left        &
300 # 12 left        | ^
301 # 11 left        &&
302 # 10 left        ||
303 #  9 nonassoc    ..  ...
304 #  8 right       ?:
305 #  7 right       = += -= *= etc.
306 #  6 left        , =>
307 #  5 nonassoc    list operators (rightward)
308 #  4 right       not
309 #  3 left        and
310 #  2 left        or xor
311 #  1             statement modifiers
312 #  0.5           statements, but still print scopes as do { ... }
313 #  0             statement level
314 # -1             format body
315
316 # Nonprinting characters with special meaning:
317 # \cS - steal parens (see maybe_parens_unop)
318 # \n - newline and indent
319 # \t - increase indent
320 # \b - decrease indent ('outdent')
321 # \f - flush left (no indent)
322 # \cK - kill following semicolon, if any
323
324
325
326 BEGIN { for (qw[ const stringify rv2sv list glob pushmark null aelem
327                  custom ]) {
328     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
329 }}
330
331 # _pessimise_walk(): recursively walk the optree of a sub,
332 # possibly undoing optimisations along the way.
333
334 sub _pessimise_walk {
335     my ($self, $startop) = @_;
336
337     return unless $$startop;
338     my ($op, $prevop);
339     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
340         my $ppname = $op->name;
341
342         # pessimisations start here
343
344         if ($ppname eq "padrange") {
345             # remove PADRANGE:
346             # the original optimisation either (1) changed this:
347             #    pushmark -> (various pad and list and null ops) -> the_rest
348             # or (2), for the = @_ case, changed this:
349             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
350             # into this:
351             #    padrange ----------------------------------------> the_rest
352             # so we just need to convert the padrange back into a
353             # pushmark, and in case (1), set its op_next to op_sibling,
354             # which is the head of the original chain of optimised-away
355             # pad ops, or for (2), set it to sibling->first, which is
356             # the original gv[_].
357
358             $B::overlay->{$$op} = {
359                     type => OP_PUSHMARK,
360                     name => 'pushmark',
361                     private => ($op->private & OPpLVAL_INTRO),
362             };
363         }
364
365         # pessimisations end here
366
367         if (class($op) eq 'PMOP'
368             && ref($op->pmreplroot)
369             && ${$op->pmreplroot}
370             && $op->pmreplroot->isa( 'B::OP' ))
371         {
372             $self-> _pessimise_walk($op->pmreplroot);
373         }
374
375         if ($op->flags & OPf_KIDS) {
376             $self-> _pessimise_walk($op->first);
377         }
378
379     }
380 }
381
382
383 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
384 # possibly undoing optimisations along the way.
385
386 sub _pessimise_walk_exe {
387     my ($self, $startop, $visited) = @_;
388
389     return unless $$startop;
390     return if $visited->{$$startop};
391     my ($op, $prevop);
392     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
393         last if $visited->{$$op};
394         $visited->{$$op} = 1;
395         my $ppname = $op->name;
396         if ($ppname =~
397             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
398             # entertry is also a logop, but its op_other invariably points
399             # into the same chain as the main execution path, so we skip it
400         ) {
401             $self->_pessimise_walk_exe($op->other, $visited);
402         }
403         elsif ($ppname eq "subst") {
404             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
405         }
406         elsif ($ppname =~ /^(enter(loop|iter))$/) {
407             # redoop and nextop will already be covered by the main block
408             # of the loop
409             $self->_pessimise_walk_exe($op->lastop, $visited);
410         }
411
412         # pessimisations start here
413     }
414 }
415
416 # Go through an optree and "remove" some optimisations by using an
417 # overlay to selectively modify or un-null some ops. Deparsing in the
418 # absence of those optimisations is then easier.
419 #
420 # Note that older optimisations are not removed, as Deparse was already
421 # written to recognise them before the pessimise/overlay system was added.
422
423 sub pessimise {
424     my ($self, $root, $start) = @_;
425
426     # walk tree in root-to-branch order
427     $self->_pessimise_walk($root);
428
429     my %visited;
430     # walk tree in execution order
431     $self->_pessimise_walk_exe($start, \%visited);
432 }
433
434
435 sub null {
436     my $op = shift;
437     return class($op) eq "NULL";
438 }
439
440 sub todo {
441     my $self = shift;
442     my($cv, $is_form) = @_;
443     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
444     my $seq;
445     if ($cv->OUTSIDE_SEQ) {
446         $seq = $cv->OUTSIDE_SEQ;
447     } elsif (!null($cv->START) and is_state($cv->START)) {
448         $seq = $cv->START->cop_seq;
449     } else {
450         $seq = 0;
451     }
452     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
453     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
454         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
455     }
456 }
457
458 sub next_todo {
459     my $self = shift;
460     my $ent = shift @{$self->{'subs_todo'}};
461     my $cv = $ent->[1];
462     my $gv = $cv->GV;
463     my $name = $self->gv_name($gv);
464     if ($ent->[2]) {
465         return $self->keyword("format") . " $name =\n"
466             . $self->deparse_format($ent->[1]). "\n";
467     } else {
468         $self->{'subs_declared'}{$name} = 1;
469         if ($name eq "BEGIN") {
470             my $use_dec = $self->begin_is_use($cv);
471             if (defined ($use_dec) and $self->{'expand'} < 5) {
472                 return () if 0 == length($use_dec);
473                 $use_dec =~ s/^(use|no)\b/$self->keyword($1)/e;
474                 return $use_dec;
475             }
476         }
477         my $l = '';
478         if ($self->{'linenums'}) {
479             my $line = $gv->LINE;
480             my $file = $gv->FILE;
481             $l = "\n\f#line $line \"$file\"\n";
482         }
483         my $p = '';
484         if (class($cv->STASH) ne "SPECIAL") {
485             my $stash = $cv->STASH->NAME;
486             if ($stash ne $self->{'curstash'}) {
487                 $p = $self->keyword("package") . " $stash;\n";
488                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
489                 $self->{'curstash'} = $stash;
490             }
491             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
492         }
493         return "${p}${l}" . $self->keyword("sub") . " $name "
494               . $self->deparse_sub($cv);
495     }
496 }
497
498 # Return a "use" declaration for this BEGIN block, if appropriate
499 sub begin_is_use {
500     my ($self, $cv) = @_;
501     my $root = $cv->ROOT;
502     local @$self{qw'curcv curcvlex'} = ($cv);
503     local $B::overlay = {};
504     $self->pessimise($root, $cv->START);
505 #require B::Debug;
506 #B::walkoptree($cv->ROOT, "debug");
507     my $lineseq = $root->first;
508     return if $lineseq->name ne "lineseq";
509
510     my $req_op = $lineseq->first->sibling;
511     return if $req_op->name ne "require";
512
513     my $module;
514     if ($req_op->first->private & OPpCONST_BARE) {
515         # Actually it should always be a bareword
516         $module = $self->const_sv($req_op->first)->PV;
517         $module =~ s[/][::]g;
518         $module =~ s/.pm$//;
519     }
520     else {
521         $module = $self->const($self->const_sv($req_op->first), 6);
522     }
523
524     my $version;
525     my $version_op = $req_op->sibling;
526     return if class($version_op) eq "NULL";
527     if ($version_op->name eq "lineseq") {
528         # We have a version parameter; skip nextstate & pushmark
529         my $constop = $version_op->first->next->next;
530
531         return unless $self->const_sv($constop)->PV eq $module;
532         $constop = $constop->sibling;
533         $version = $self->const_sv($constop);
534         if (class($version) eq "IV") {
535             $version = $version->int_value;
536         } elsif (class($version) eq "NV") {
537             $version = $version->NV;
538         } elsif (class($version) ne "PVMG") {
539             # Includes PVIV and PVNV
540             $version = $version->PV;
541         } else {
542             # version specified as a v-string
543             $version = 'v'.join '.', map ord, split //, $version->PV;
544         }
545         $constop = $constop->sibling;
546         return if $constop->name ne "method_named";
547         return if $self->meth_sv($constop)->PV ne "VERSION";
548     }
549
550     $lineseq = $version_op->sibling;
551     return if $lineseq->name ne "lineseq";
552     my $entersub = $lineseq->first->sibling;
553     if ($entersub->name eq "stub") {
554         return "use $module $version ();\n" if defined $version;
555         return "use $module ();\n";
556     }
557     return if $entersub->name ne "entersub";
558
559     # See if there are import arguments
560     my $args = '';
561
562     my $svop = $entersub->first->sibling; # Skip over pushmark
563     return unless $self->const_sv($svop)->PV eq $module;
564
565     # Pull out the arguments
566     for ($svop=$svop->sibling; $svop->name ne "method_named";
567                 $svop = $svop->sibling) {
568         $args .= ", " if length($args);
569         $args .= $self->deparse($svop, 6);
570     }
571
572     my $use = 'use';
573     my $method_named = $svop;
574     return if $method_named->name ne "method_named";
575     my $method_name = $self->meth_sv($method_named)->PV;
576
577     if ($method_name eq "unimport") {
578         $use = 'no';
579     }
580
581     # Certain pragmas are dealt with using hint bits,
582     # so we ignore them here
583     if ($module eq 'strict' || $module eq 'integer'
584         || $module eq 'bytes' || $module eq 'warnings'
585         || $module eq 'feature') {
586         return "";
587     }
588
589     if (defined $version && length $args) {
590         return "$use $module $version ($args);\n";
591     } elsif (defined $version) {
592         return "$use $module $version;\n";
593     } elsif (length $args) {
594         return "$use $module ($args);\n";
595     } else {
596         return "$use $module;\n";
597     }
598 }
599
600 sub stash_subs {
601     my ($self, $pack, $seen) = @_;
602     my (@ret, $stash);
603     if (!defined $pack) {
604         $pack = '';
605         $stash = \%::;
606     }
607     else {
608         $pack =~ s/(::)?$/::/;
609         no strict 'refs';
610         $stash = \%{"main::$pack"};
611     }
612     return
613         if ($seen ||= {})->{
614             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
615            }++;
616     my %stash = svref_2object($stash)->ARRAY;
617     while (my ($key, $val) = each %stash) {
618         my $class = class($val);
619         if ($class eq "PV") {
620             # Just a prototype. As an ugly but fairly effective way
621             # to find out if it belongs here is to see if the AUTOLOAD
622             # (if any) for the stash was defined in one of our files.
623             my $A = $stash{"AUTOLOAD"};
624             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
625                 && class($A->CV) eq "CV") {
626                 my $AF = $A->FILE;
627                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
628             }
629             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
630         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
631             # Just a name. As above.
632             # But skip proxy constant subroutines, as some form of perl-space
633             # visible code must have created them, be it a use statement, or
634             # some direct symbol-table manipulation code that we will Deparse
635             my $A = $stash{"AUTOLOAD"};
636             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
637                 && class($A->CV) eq "CV") {
638                 my $AF = $A->FILE;
639                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
640             }
641             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
642         } elsif ($class eq "IV") {
643             # A reference.  Dump this if it is a reference to a CV.
644             if (class(my $cv = $val->RV) eq "CV") {
645                 $self->todo($cv, 0);
646             }
647         } elsif ($class eq "GV") {
648             if (class(my $cv = $val->CV) ne "SPECIAL") {
649                 next if $self->{'subs_done'}{$$val}++;
650                 next if $$val != ${$cv->GV};   # Ignore imposters
651                 $self->todo($cv, 0);
652             }
653             if (class(my $cv = $val->FORM) ne "SPECIAL") {
654                 next if $self->{'forms_done'}{$$val}++;
655                 next if $$val != ${$cv->GV};   # Ignore imposters
656                 $self->todo($cv, 1);
657             }
658             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
659                 $self->stash_subs($pack . $key, $seen);
660             }
661         }
662     }
663 }
664
665 sub print_protos {
666     my $self = shift;
667     my $ar;
668     my @ret;
669     foreach $ar (@{$self->{'protos_todo'}}) {
670         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
671         push @ret, "sub " . $ar->[0] .  "$proto;\n";
672     }
673     delete $self->{'protos_todo'};
674     return @ret;
675 }
676
677 sub style_opts {
678     my $self = shift;
679     my $opts = shift;
680     my $opt;
681     while (length($opt = substr($opts, 0, 1))) {
682         if ($opt eq "C") {
683             $self->{'cuddle'} = " ";
684             $opts = substr($opts, 1);
685         } elsif ($opt eq "i") {
686             $opts =~ s/^i(\d+)//;
687             $self->{'indent_size'} = $1;
688         } elsif ($opt eq "T") {
689             $self->{'use_tabs'} = 1;
690             $opts = substr($opts, 1);
691         } elsif ($opt eq "v") {
692             $opts =~ s/^v([^.]*)(.|$)//;
693             $self->{'ex_const'} = $1;
694         }
695     }
696 }
697
698 sub new {
699     my $class = shift;
700     my $self = bless {}, $class;
701     $self->{'cuddle'} = "\n";
702     $self->{'curcop'} = undef;
703     $self->{'curstash'} = "main";
704     $self->{'ex_const'} = "'???'";
705     $self->{'expand'} = 0;
706     $self->{'files'} = {};
707     $self->{'indent_size'} = 4;
708     $self->{'linenums'} = 0;
709     $self->{'parens'} = 0;
710     $self->{'subs_todo'} = [];
711     $self->{'unquote'} = 0;
712     $self->{'use_dumper'} = 0;
713     $self->{'use_tabs'} = 0;
714
715     $self->{'ambient_arybase'} = 0;
716     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
717     $self->{'ambient_hints'} = 0;
718     $self->{'ambient_hinthash'} = undef;
719     $self->init();
720
721     while (my $arg = shift @_) {
722         if ($arg eq "-d") {
723             $self->{'use_dumper'} = 1;
724             require Data::Dumper;
725         } elsif ($arg =~ /^-f(.*)/) {
726             $self->{'files'}{$1} = 1;
727         } elsif ($arg eq "-l") {
728             $self->{'linenums'} = 1;
729         } elsif ($arg eq "-p") {
730             $self->{'parens'} = 1;
731         } elsif ($arg eq "-P") {
732             $self->{'noproto'} = 1;
733         } elsif ($arg eq "-q") {
734             $self->{'unquote'} = 1;
735         } elsif (substr($arg, 0, 2) eq "-s") {
736             $self->style_opts(substr $arg, 2);
737         } elsif ($arg =~ /^-x(\d)$/) {
738             $self->{'expand'} = $1;
739         }
740     }
741     return $self;
742 }
743
744 {
745     # Mask out the bits that L<warnings::register> uses
746     my $WARN_MASK;
747     BEGIN {
748         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
749     }
750     sub WARN_MASK () {
751         return $WARN_MASK;
752     }
753 }
754
755 # Initialise the contextual information, either from
756 # defaults provided with the ambient_pragmas method,
757 # or from perl's own defaults otherwise.
758 sub init {
759     my $self = shift;
760
761     $self->{'arybase'}  = $self->{'ambient_arybase'};
762     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
763                                 ? $self->{'ambient_warnings'} & WARN_MASK
764                                 : undef;
765     $self->{'hints'}    = $self->{'ambient_hints'};
766     $self->{'hints'} &= 0xFF if $] < 5.009;
767     $self->{'hinthash'} = $self->{'ambient_hinthash'};
768
769     # also a convenient place to clear out subs_declared
770     delete $self->{'subs_declared'};
771 }
772
773 sub compile {
774     my(@args) = @_;
775     return sub {
776         my $self = B::Deparse->new(@args);
777         # First deparse command-line args
778         if (defined $^I) { # deparse -i
779             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
780         }
781         if ($^W) { # deparse -w
782             print qq(BEGIN { \$^W = $^W; }\n);
783         }
784         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
785             my $fs = perlstring($/) || 'undef';
786             my $bs = perlstring($O::savebackslash) || 'undef';
787             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
788         }
789         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
790         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
791             ? B::unitcheck_av->ARRAY
792             : ();
793         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
794         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
795         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
796         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
797             $self->todo($block, 0);
798         }
799         $self->stash_subs();
800         local($SIG{"__DIE__"}) =
801           sub {
802               if ($self->{'curcop'}) {
803                   my $cop = $self->{'curcop'};
804                   my($line, $file) = ($cop->line, $cop->file);
805                   print STDERR "While deparsing $file near line $line,\n";
806               }
807             };
808         $self->{'curcv'} = main_cv;
809         $self->{'curcvlex'} = undef;
810         print $self->print_protos;
811         @{$self->{'subs_todo'}} =
812           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
813         my $root = main_root;
814         local $B::overlay = {};
815         unless (null $root) {
816             $self->pessimise($root, main_start);
817             print $self->indent($self->deparse_root($root)), "\n";
818         }
819         my @text;
820         while (scalar(@{$self->{'subs_todo'}})) {
821             push @text, $self->next_todo;
822         }
823         print $self->indent(join("", @text)), "\n" if @text;
824
825         # Print __DATA__ section, if necessary
826         no strict 'refs';
827         my $laststash = defined $self->{'curcop'}
828             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
829         if (defined *{$laststash."::DATA"}{IO}) {
830             print $self->keyword("package") . " $laststash;\n"
831                 unless $laststash eq $self->{'curstash'};
832             print $self->keyword("__DATA__") . "\n";
833             print readline(*{$laststash."::DATA"});
834         }
835     }
836 }
837
838 sub coderef2text {
839     my $self = shift;
840     my $sub = shift;
841     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
842
843     $self->init();
844     return $self->indent($self->deparse_sub(svref_2object($sub)));
845 }
846
847 my %strict_bits = do {
848     local $^H;
849     map +($_ => strict::bits($_)), qw/refs subs vars/
850 };
851
852 sub ambient_pragmas {
853     my $self = shift;
854     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
855
856     while (@_ > 1) {
857         my $name = shift();
858         my $val  = shift();
859
860         if ($name eq 'strict') {
861             require strict;
862
863             if ($val eq 'none') {
864                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
865                 next();
866             }
867
868             my @names;
869             if ($val eq "all") {
870                 @names = qw/refs subs vars/;
871             }
872             elsif (ref $val) {
873                 @names = @$val;
874             }
875             else {
876                 @names = split' ', $val;
877             }
878             $hint_bits |= $strict_bits{$_} for @names;
879         }
880
881         elsif ($name eq '$[') {
882             if (OPpCONST_ARYBASE) {
883                 $arybase = $val;
884             } else {
885                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
886             }
887         }
888
889         elsif ($name eq 'integer'
890             || $name eq 'bytes'
891             || $name eq 'utf8') {
892             require "$name.pm";
893             if ($val) {
894                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
895             }
896             else {
897                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
898             }
899         }
900
901         elsif ($name eq 're') {
902             require re;
903             if ($val eq 'none') {
904                 $hint_bits &= ~re::bits(qw/taint eval/);
905                 next();
906             }
907
908             my @names;
909             if ($val eq 'all') {
910                 @names = qw/taint eval/;
911             }
912             elsif (ref $val) {
913                 @names = @$val;
914             }
915             else {
916                 @names = split' ',$val;
917             }
918             $hint_bits |= re::bits(@names);
919         }
920
921         elsif ($name eq 'warnings') {
922             if ($val eq 'none') {
923                 $warning_bits = $warnings::NONE;
924                 next();
925             }
926
927             my @names;
928             if (ref $val) {
929                 @names = @$val;
930             }
931             else {
932                 @names = split/\s+/, $val;
933             }
934
935             $warning_bits = $warnings::NONE if !defined ($warning_bits);
936             $warning_bits |= warnings::bits(@names);
937         }
938
939         elsif ($name eq 'warning_bits') {
940             $warning_bits = $val;
941         }
942
943         elsif ($name eq 'hint_bits') {
944             $hint_bits = $val;
945         }
946
947         elsif ($name eq '%^H') {
948             $hinthash = $val;
949         }
950
951         else {
952             croak "Unknown pragma type: $name";
953         }
954     }
955     if (@_) {
956         croak "The ambient_pragmas method expects an even number of args";
957     }
958
959     $self->{'ambient_arybase'} = $arybase;
960     $self->{'ambient_warnings'} = $warning_bits;
961     $self->{'ambient_hints'} = $hint_bits;
962     $self->{'ambient_hinthash'} = $hinthash;
963 }
964
965 # This method is the inner loop, so try to keep it simple
966 sub deparse {
967     my $self = shift;
968     my($op, $cx) = @_;
969
970     Carp::confess("Null op in deparse") if !defined($op)
971                                         || class($op) eq "NULL";
972     my $meth = "pp_" . $op->name;
973     return $self->$meth($op, $cx);
974 }
975
976 sub indent {
977     my $self = shift;
978     my $txt = shift;
979     my @lines = split(/\n/, $txt);
980     my $leader = "";
981     my $level = 0;
982     my $line;
983     for $line (@lines) {
984         my $cmd = substr($line, 0, 1);
985         if ($cmd eq "\t" or $cmd eq "\b") {
986             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
987             if ($self->{'use_tabs'}) {
988                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
989             } else {
990                 $leader = " " x $level;
991             }
992             $line = substr($line, 1);
993         }
994         if (index($line, "\f") > 0) {
995                 $line =~ s/\f/\n/;
996         }
997         if (substr($line, 0, 1) eq "\f") {
998             $line = substr($line, 1); # no indent
999         } else {
1000             $line = $leader . $line;
1001         }
1002         $line =~ s/\cK;?//g;
1003     }
1004     return join("\n", @lines);
1005 }
1006
1007 sub deparse_sub {
1008     my $self = shift;
1009     my $cv = shift;
1010     my $proto = "";
1011 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
1012 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
1013     local $self->{'curcop'} = $self->{'curcop'};
1014     if ($cv->FLAGS & SVf_POK) {
1015         $proto = "(". $cv->PV . ") ";
1016     }
1017     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
1018         $proto .= ": ";
1019         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
1020         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
1021         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
1022     }
1023
1024     local($self->{'curcv'}) = $cv;
1025     local($self->{'curcvlex'});
1026     local(@$self{qw'curstash warnings hints hinthash'})
1027                 = @$self{qw'curstash warnings hints hinthash'};
1028     my $body;
1029     my $root = $cv->ROOT;
1030     local $B::overlay = {};
1031     if (not null $root) {
1032         $self->pessimise($root, $cv->START);
1033         my $lineseq = $root->first;
1034         if ($lineseq->name eq "lineseq") {
1035             my @ops;
1036             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
1037                 push @ops, $o;
1038             }
1039             $body = $self->lineseq(undef, 0, @ops).";";
1040             my $scope_en = $self->find_scope_en($lineseq);
1041             if (defined $scope_en) {
1042                 my $subs = join"", $self->seq_subs($scope_en);
1043                 $body .= ";\n$subs" if length($subs);
1044             }
1045         }
1046         else {
1047             $body = $self->deparse($root->first, 0);
1048         }
1049     }
1050     else {
1051         my $sv = $cv->const_sv;
1052         if ($$sv) {
1053             # uh-oh. inlinable sub... format it differently
1054             return $proto . "{ " . $self->const($sv, 0) . " }\n";
1055         } else { # XSUB? (or just a declaration)
1056             return "$proto;\n";
1057         }
1058     }
1059     return $proto ."{\n\t$body\n\b}" ."\n";
1060 }
1061
1062 sub deparse_format {
1063     my $self = shift;
1064     my $form = shift;
1065     my @text;
1066     local($self->{'curcv'}) = $form;
1067     local($self->{'curcvlex'});
1068     local($self->{'in_format'}) = 1;
1069     local(@$self{qw'curstash warnings hints hinthash'})
1070                 = @$self{qw'curstash warnings hints hinthash'};
1071     my $op = $form->ROOT;
1072     local $B::overlay = {};
1073     $self->pessimise($op, $form->START);
1074     my $kid;
1075     return "\f." if $op->first->name eq 'stub'
1076                 || $op->first->name eq 'nextstate';
1077     $op = $op->first->first; # skip leavewrite, lineseq
1078     while (not null $op) {
1079         $op = $op->sibling; # skip nextstate
1080         my @exprs;
1081         $kid = $op->first->sibling; # skip pushmark
1082         push @text, "\f".$self->const_sv($kid)->PV;
1083         $kid = $kid->sibling;
1084         for (; not null $kid; $kid = $kid->sibling) {
1085             push @exprs, $self->deparse($kid, -1);
1086             $exprs[-1] =~ s/;\z//;
1087         }
1088         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1089         $op = $op->sibling;
1090     }
1091     return join("", @text) . "\f.";
1092 }
1093
1094 sub is_scope {
1095     my $op = shift;
1096     return $op->name eq "leave" || $op->name eq "scope"
1097       || $op->name eq "lineseq"
1098         || ($op->name eq "null" && class($op) eq "UNOP"
1099             && (is_scope($op->first) || $op->first->name eq "enter"));
1100 }
1101
1102 sub is_state {
1103     my $name = $_[0]->name;
1104     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1105 }
1106
1107 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1108     my $op = shift;
1109     return (!null($op) and null($op->sibling)
1110             and $op->name eq "null" and class($op) eq "UNOP"
1111             and (($op->first->name =~ /^(and|or)$/
1112                   and $op->first->first->sibling->name eq "lineseq")
1113                  or ($op->first->name eq "lineseq"
1114                      and not null $op->first->first->sibling
1115                      and $op->first->first->sibling->name eq "unstack")
1116                  ));
1117 }
1118
1119 # Check if the op and its sibling are the initialization and the rest of a
1120 # for (..;..;..) { ... } loop
1121 sub is_for_loop {
1122     my $op = shift;
1123     # This OP might be almost anything, though it won't be a
1124     # nextstate. (It's the initialization, so in the canonical case it
1125     # will be an sassign.) The sibling is (old style) a lineseq whose
1126     # first child is a nextstate and whose second is a leaveloop, or
1127     # (new style) an unstack whose sibling is a leaveloop.
1128     my $lseq = $op->sibling;
1129     return 0 unless !is_state($op) and !null($lseq);
1130     if ($lseq->name eq "lineseq") {
1131         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1132             && (my $sib = $lseq->first->sibling)) {
1133             return (!null($sib) && $sib->name eq "leaveloop");
1134         }
1135     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1136         my $sib = $lseq->sibling;
1137         return $sib && !null($sib) && $sib->name eq "leaveloop";
1138     }
1139     return 0;
1140 }
1141
1142 sub is_scalar {
1143     my $op = shift;
1144     return ($op->name eq "rv2sv" or
1145             $op->name eq "padsv" or
1146             $op->name eq "gv" or # only in array/hash constructs
1147             $op->flags & OPf_KIDS && !null($op->first)
1148               && $op->first->name eq "gvsv");
1149 }
1150
1151 sub maybe_parens {
1152     my $self = shift;
1153     my($text, $cx, $prec) = @_;
1154     if ($prec < $cx              # unary ops nest just fine
1155         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1156         or $self->{'parens'})
1157     {
1158         $text = "($text)";
1159         # In a unop, let parent reuse our parens; see maybe_parens_unop
1160         $text = "\cS" . $text if $cx == 16;
1161         return $text;
1162     } else {
1163         return $text;
1164     }
1165 }
1166
1167 # same as above, but get around the 'if it looks like a function' rule
1168 sub maybe_parens_unop {
1169     my $self = shift;
1170     my($name, $kid, $cx) = @_;
1171     if ($cx > 16 or $self->{'parens'}) {
1172         $kid =  $self->deparse($kid, 1);
1173         if ($name eq "umask" && $kid =~ /^\d+$/) {
1174             $kid = sprintf("%#o", $kid);
1175         }
1176         return $self->keyword($name) . "($kid)";
1177     } else {
1178         $kid = $self->deparse($kid, 16);
1179         if ($name eq "umask" && $kid =~ /^\d+$/) {
1180             $kid = sprintf("%#o", $kid);
1181         }
1182         $name = $self->keyword($name);
1183         if (substr($kid, 0, 1) eq "\cS") {
1184             # use kid's parens
1185             return $name . substr($kid, 1);
1186         } elsif (substr($kid, 0, 1) eq "(") {
1187             # avoid looks-like-a-function trap with extra parens
1188             # ('+' can lead to ambiguities)
1189             return "$name(" . $kid  . ")";
1190         } else {
1191             return "$name $kid";
1192         }
1193     }
1194 }
1195
1196 sub maybe_parens_func {
1197     my $self = shift;
1198     my($func, $text, $cx, $prec) = @_;
1199     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1200         return "$func($text)";
1201     } else {
1202         return "$func $text";
1203     }
1204 }
1205
1206 sub find_our_type {
1207     my ($self, $name) = @_;
1208     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1209     my $seq = $self->{'curcop'} ? $self->{'curcop'}->cop_seq : 0;
1210     for my $a (@{$self->{'curcvlex'}{"o$name"}}) {
1211         my ($st, undef, $padname) = @$a;
1212         if ($st >= $seq && $padname->FLAGS & SVpad_TYPED) {
1213             return $padname->SvSTASH->NAME;
1214         }
1215     }
1216     return '';
1217 }
1218
1219 sub maybe_local {
1220     my $self = shift;
1221     my($op, $cx, $text) = @_;
1222     my $name = $op->name;
1223     my $our_intro = ($name =~ /^(?:(?:gv|rv2)[ash]v|split|refassign
1224                                   |lv(?:av)?ref)$/x)
1225                         ? OPpOUR_INTRO
1226                         : 0;
1227     my $lval_intro = $name eq 'split' ? 0 : OPpLVAL_INTRO;
1228     # The @a in \(@a) isn't in ref context, but only when the
1229     # parens are there.
1230     my $need_parens = $self->{'in_refgen'} && $name =~ /[ah]v\z/
1231                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1232     if ((my $priv = $op->private) & ($lval_intro|$our_intro)) {
1233         my @our_local;
1234         push @our_local, "local" if $priv & $lval_intro;
1235         push @our_local, "our"   if $priv & $our_intro;
1236         my $our_local = join " ", map $self->keyword($_), @our_local;
1237         if( $our_local[-1] eq 'our' ) {
1238             if ( $text !~ /^\W(\w+::)*\w+\z/
1239              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1240             ) {
1241                 die "Unexpected our($text)\n";
1242             }
1243             $text =~ s/(\w+::)+//;
1244
1245             if (my $type = $self->find_our_type($text)) {
1246                 $our_local .= ' ' . $type;
1247             }
1248         }
1249         return $need_parens ? "($text)" : $text
1250             if $self->{'avoid_local'}{$$op};
1251         if ($need_parens) {
1252             return "$our_local($text)";
1253         } elsif (want_scalar($op)) {
1254             return "$our_local $text";
1255         } else {
1256             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1257         }
1258     } else {
1259         return $need_parens ? "($text)" : $text;
1260     }
1261 }
1262
1263 sub maybe_targmy {
1264     my $self = shift;
1265     my($op, $cx, $func, @args) = @_;
1266     if ($op->private & OPpTARGET_MY) {
1267         my $var = $self->padname($op->targ);
1268         my $val = $func->($self, $op, 7, @args);
1269         return $self->maybe_parens("$var = $val", $cx, 7);
1270     } else {
1271         return $func->($self, $op, $cx, @args);
1272     }
1273 }
1274
1275 sub padname_sv {
1276     my $self = shift;
1277     my $targ = shift;
1278     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1279 }
1280
1281 sub maybe_my {
1282     my $self = shift;
1283     my($op, $cx, $text, $padname, $forbid_parens) = @_;
1284     # The @a in \(@a) isn't in ref context, but only when the
1285     # parens are there.
1286     my $need_parens = !$forbid_parens && $self->{'in_refgen'}
1287                    && $op->name =~ /[ah]v\z/
1288                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1289     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1290         # Check $padname->FLAGS for statehood, rather than $op->private,
1291         # because enteriter ops do not carry the flag.
1292         my $my =
1293             $self->keyword($padname->FLAGS & SVpad_STATE ? "state" : "my");
1294         if ($padname->FLAGS & SVpad_TYPED) {
1295             $my .= ' ' . $padname->SvSTASH->NAME;
1296         }
1297         if ($need_parens) {
1298             return "$my($text)";
1299         } elsif ($forbid_parens || want_scalar($op)) {
1300             return "$my $text";
1301         } else {
1302             return $self->maybe_parens_func($my, $text, $cx, 16);
1303         }
1304     } else {
1305         return $need_parens ? "($text)" : $text;
1306     }
1307 }
1308
1309 # The following OPs don't have functions:
1310
1311 # pp_padany -- does not exist after parsing
1312
1313 sub AUTOLOAD {
1314     if ($AUTOLOAD =~ s/^.*::pp_//) {
1315         warn "unexpected OP_".
1316           ($_[1]->type == OP_CUSTOM ? "CUSTOM ($AUTOLOAD)" : uc $AUTOLOAD);
1317         return "XXX";
1318     } else {
1319         die "Undefined subroutine $AUTOLOAD called";
1320     }
1321 }
1322
1323 sub DESTROY {}  #       Do not AUTOLOAD
1324
1325 # $root should be the op which represents the root of whatever
1326 # we're sequencing here. If it's undefined, then we don't append
1327 # any subroutine declarations to the deparsed ops, otherwise we
1328 # append appropriate declarations.
1329 sub lineseq {
1330     my($self, $root, $cx, @ops) = @_;
1331     my($expr, @exprs);
1332
1333     my $out_cop = $self->{'curcop'};
1334     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1335     my $limit_seq;
1336     if (defined $root) {
1337         $limit_seq = $out_seq;
1338         my $nseq;
1339         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1340         $limit_seq = $nseq if !defined($limit_seq)
1341                            or defined($nseq) && $nseq < $limit_seq;
1342     }
1343     $limit_seq = $self->{'limit_seq'}
1344         if defined($self->{'limit_seq'})
1345         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1346     local $self->{'limit_seq'} = $limit_seq;
1347
1348     $self->walk_lineseq($root, \@ops,
1349                        sub { push @exprs, $_[0]} );
1350
1351     my $sep = $cx ? '; ' : ";\n";
1352     my $body = join($sep, grep {length} @exprs);
1353     my $subs = "";
1354     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1355         $subs = join "\n", $self->seq_subs($limit_seq);
1356     }
1357     return join($sep, grep {length} $body, $subs);
1358 }
1359
1360 sub scopeop {
1361     my($real_block, $self, $op, $cx) = @_;
1362     my $kid;
1363     my @kids;
1364
1365     local(@$self{qw'curstash warnings hints hinthash'})
1366                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1367     if ($real_block) {
1368         $kid = $op->first->sibling; # skip enter
1369         if (is_miniwhile($kid)) {
1370             my $top = $kid->first;
1371             my $name = $top->name;
1372             if ($name eq "and") {
1373                 $name = $self->keyword("while");
1374             } elsif ($name eq "or") {
1375                 $name = $self->keyword("until");
1376             } else { # no conditional -> while 1 or until 0
1377                 return $self->deparse($top->first, 1) . " "
1378                      . $self->keyword("while") . " 1";
1379             }
1380             my $cond = $top->first;
1381             my $body = $cond->sibling->first; # skip lineseq
1382             $cond = $self->deparse($cond, 1);
1383             $body = $self->deparse($body, 1);
1384             return "$body $name $cond";
1385         }
1386     } else {
1387         $kid = $op->first;
1388     }
1389     for (; !null($kid); $kid = $kid->sibling) {
1390         push @kids, $kid;
1391     }
1392     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1393         my $body = $self->lineseq($op, 0, @kids);
1394         return is_lexical_subs(@kids)
1395                 ? $body
1396                 : ($self->lex_in_scope("&do") ? "CORE::do" : "do")
1397                  . " {\n\t$body\n\b}";
1398     } else {
1399         my $lineseq = $self->lineseq($op, $cx, @kids);
1400         return (length ($lineseq) ? "$lineseq;" : "");
1401     }
1402 }
1403
1404 sub pp_scope { scopeop(0, @_); }
1405 sub pp_lineseq { scopeop(0, @_); }
1406 sub pp_leave { scopeop(1, @_); }
1407
1408 # This is a special case of scopeop and lineseq, for the case of the
1409 # main_root. The difference is that we print the output statements as
1410 # soon as we get them, for the sake of impatient users.
1411 sub deparse_root {
1412     my $self = shift;
1413     my($op) = @_;
1414     local(@$self{qw'curstash warnings hints hinthash'})
1415       = @$self{qw'curstash warnings hints hinthash'};
1416     my @kids;
1417     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1418     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1419         push @kids, $kid;
1420     }
1421     $self->walk_lineseq($op, \@kids,
1422                         sub { print $self->indent($_[0].';');
1423                               print "\n" unless $_[1] == $#kids;
1424                           });
1425 }
1426
1427 sub walk_lineseq {
1428     my ($self, $op, $kids, $callback) = @_;
1429     my @kids = @$kids;
1430     for (my $i = 0; $i < @kids; $i++) {
1431         my $expr = "";
1432         if (is_state $kids[$i]) {
1433             $expr = $self->deparse($kids[$i++], 0);
1434             if ($i > $#kids) {
1435                 $callback->($expr, $i);
1436                 last;
1437             }
1438         }
1439         if (is_for_loop($kids[$i])) {
1440             $callback->($expr . $self->for_loop($kids[$i], 0),
1441                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1442             next;
1443         }
1444         my $expr2 = $self->deparse($kids[$i], (@kids != 1)/2);
1445         $expr2 =~ s/^sub :/+sub :/; # statement label otherwise
1446         $expr .= $expr2;
1447         $expr =~ s/;\n?\z//;
1448         $callback->($expr, $i);
1449     }
1450 }
1451
1452 # The BEGIN {} is used here because otherwise this code isn't executed
1453 # when you run B::Deparse on itself.
1454 my %globalnames;
1455 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1456             "ENV", "ARGV", "ARGVOUT", "_"); }
1457
1458 sub gv_name {
1459     my $self = shift;
1460     my $gv = shift;
1461     my $raw = shift;
1462 #Carp::confess() unless ref($gv) eq "B::GV";
1463     my $cv = $gv->FLAGS & SVf_ROK ? $gv->RV : 0;
1464     my $stash = ($cv || $gv)->STASH->NAME;
1465     my $name = $raw
1466         ? $cv ? $cv->NAME_HEK || $cv->GV->NAME : $gv->NAME
1467         : $cv
1468             ? B::safename($cv->NAME_HEK || $cv->GV->NAME)
1469             : $gv->SAFENAME;
1470     if ($stash eq 'main' && $name =~ /^::/) {
1471         $stash = '::';
1472     }
1473     elsif (($stash eq 'main'
1474             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1475         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1476             && ($stash eq 'main' || $name !~ /::/))
1477           )
1478     {
1479         $stash = "";
1480     } else {
1481         $stash = $stash . "::";
1482     }
1483     if (!$raw and $name =~ /^(\^..|{)/) {
1484         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1485     }
1486     return $stash . $name;
1487 }
1488
1489 # Return the name to use for a stash variable.
1490 # If a lexical with the same name is in scope, or
1491 # if strictures are enabled, it may need to be
1492 # fully-qualified.
1493 sub stash_variable {
1494     my ($self, $prefix, $name, $cx) = @_;
1495
1496     return "$prefix$name" if $name =~ /::/;
1497
1498     unless ($prefix eq '$' || $prefix eq '@' || #'
1499             $prefix eq '%' || $prefix eq '$#') {
1500         return "$prefix$name";
1501     }
1502
1503     if ($name =~ /^[^\w+-]$/) {
1504       if (defined $cx && $cx == 26) {
1505         if ($prefix eq '@') {
1506             return "$prefix\{$name}";
1507         }
1508         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1509       }
1510       if ($prefix eq '$#') {
1511         return "\$#{$name}";
1512       }
1513     }
1514
1515     return $prefix . $self->maybe_qualify($prefix, $name);
1516 }
1517
1518 # Return just the name, without the prefix.  It may be returned as a quoted
1519 # string.  The second return value is a boolean indicating that.
1520 sub stash_variable_name {
1521     my($self, $prefix, $gv) = @_;
1522     my $name = $self->gv_name($gv, 1);
1523     $name = $self->maybe_qualify($prefix,$name);
1524     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1525         $name =~ s/^([\ca-\cz])/'^'.($1|'@')/e;
1526         $name =~ /^(\^..|{)/ and $name = "{$name}";
1527         return $name, 0; # not quoted
1528     }
1529     else {
1530         single_delim("q", "'", $name, $self), 1;
1531     }
1532 }
1533
1534 sub maybe_qualify {
1535     my ($self,$prefix,$name) = @_;
1536     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1537     return $name if !$prefix || $name =~ /::/;
1538     return $self->{'curstash'}.'::'. $name
1539         if
1540             $name =~ /^(?!\d)\w/         # alphabetic
1541          && $v    !~ /^\$[ab]\z/         # not $a or $b
1542          && !$globalnames{$name}         # not a global name
1543          && $self->{hints} & $strict_bits{vars}  # strict vars
1544          && !$self->lex_in_scope($v,1)   # no "our"
1545       or $self->lex_in_scope($v);        # conflicts with "my" variable
1546     return $name;
1547 }
1548
1549 sub lex_in_scope {
1550     my ($self, $name, $our) = @_;
1551     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1552     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1553
1554     return 0 if !defined($self->{'curcop'});
1555     my $seq = $self->{'curcop'}->cop_seq;
1556     return 0 if !exists $self->{'curcvlex'}{$name};
1557     for my $a (@{$self->{'curcvlex'}{$name}}) {
1558         my ($st, $en) = @$a;
1559         return 1 if $seq > $st && $seq <= $en;
1560     }
1561     return 0;
1562 }
1563
1564 sub populate_curcvlex {
1565     my $self = shift;
1566     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1567         my $padlist = $cv->PADLIST;
1568         # an undef CV still in lexical chain
1569         next if class($padlist) eq "SPECIAL";
1570         my @padlist = $padlist->ARRAY;
1571         my @ns = $padlist[0]->ARRAY;
1572
1573         for (my $i=0; $i<@ns; ++$i) {
1574             next if class($ns[$i]) eq "SPECIAL";
1575             if (class($ns[$i]) eq "PV") {
1576                 # Probably that pesky lexical @_
1577                 next;
1578             }
1579             my $name = $ns[$i]->PVX;
1580             my ($seq_st, $seq_en) =
1581                 ($ns[$i]->FLAGS & SVf_FAKE)
1582                     ? (0, 999999)
1583                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1584
1585             push @{$self->{'curcvlex'}{
1586                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1587                   }}, [$seq_st, $seq_en, $ns[$i]];
1588         }
1589     }
1590 }
1591
1592 sub find_scope_st { ((find_scope(@_))[0]); }
1593 sub find_scope_en { ((find_scope(@_))[1]); }
1594
1595 # Recurses down the tree, looking for pad variable introductions and COPs
1596 sub find_scope {
1597     my ($self, $op, $scope_st, $scope_en) = @_;
1598     carp("Undefined op in find_scope") if !defined $op;
1599     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1600
1601     my @queue = ($op);
1602     while(my $op = shift @queue ) {
1603         for (my $o=$op->first; $$o; $o=$o->sibling) {
1604             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1605                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1606                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1607                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1608                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1609                 return ($scope_st, $scope_en);
1610             }
1611             elsif (is_state($o)) {
1612                 my $c = $o->cop_seq;
1613                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1614                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1615                 return ($scope_st, $scope_en);
1616             }
1617             elsif ($o->flags & OPf_KIDS) {
1618                 unshift (@queue, $o);
1619             }
1620         }
1621     }
1622
1623     return ($scope_st, $scope_en);
1624 }
1625
1626 # Returns a list of subs which should be inserted before the COP
1627 sub cop_subs {
1628     my ($self, $op, $out_seq) = @_;
1629     my $seq = $op->cop_seq;
1630     if ($] < 5.021006) {
1631       # If we have nephews, then our sequence number indicates
1632       # the cop_seq of the end of some sort of scope.
1633       if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1634         and my $nseq = $self->find_scope_st($op->sibling) ) {
1635         $seq = $nseq;
1636       }
1637     }
1638     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1639     return $self->seq_subs($seq);
1640 }
1641
1642 sub seq_subs {
1643     my ($self, $seq) = @_;
1644     my @text;
1645 #push @text, "# ($seq)\n";
1646
1647     return "" if !defined $seq;
1648     my @pending;
1649     while (scalar(@{$self->{'subs_todo'}})
1650            and $seq > $self->{'subs_todo'}[0][0]) {
1651         my $cv = $self->{'subs_todo'}[0][1];
1652         my $outside = $cv && $cv->OUTSIDE;
1653         if ($cv and ${$cv->OUTSIDE || \0} != ${$self->{'curcv'}}) {
1654             push @pending, shift @{$self->{'subs_todo'}};
1655             next;
1656         }
1657         push @text, $self->next_todo;
1658     }
1659     unshift @{$self->{'subs_todo'}}, @pending;
1660     return @text;
1661 }
1662
1663 sub _features_from_bundle {
1664     my ($hints, $hh) = @_;
1665     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
1666         $hh->{$feature::feature{$_}} = 1;
1667     }
1668     return $hh;
1669 }
1670
1671 # Notice how subs and formats are inserted between statements here;
1672 # also $[ assignments and pragmas.
1673 sub pp_nextstate {
1674     my $self = shift;
1675     my($op, $cx) = @_;
1676     $self->{'curcop'} = $op;
1677     my @text;
1678     push @text, $self->cop_subs($op);
1679     my $stash = $op->stashpv;
1680     if ($stash ne $self->{'curstash'}) {
1681         push @text, $self->keyword("package") . " $stash;\n";
1682         $self->{'curstash'} = $stash;
1683     }
1684
1685     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1686         push @text, '$[ = '. $op->arybase .";\n";
1687         $self->{'arybase'} = $op->arybase;
1688     }
1689
1690     my $warnings = $op->warnings;
1691     my $warning_bits;
1692     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1693         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1694     }
1695     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1696         $warning_bits = $warnings::NONE;
1697     }
1698     elsif ($warnings->isa("B::SPECIAL")) {
1699         $warning_bits = undef;
1700     }
1701     else {
1702         $warning_bits = $warnings->PV & WARN_MASK;
1703     }
1704
1705     if (defined ($warning_bits) and
1706        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1707         push @text,
1708             $self->declare_warnings($self->{'warnings'}, $warning_bits);
1709         $self->{'warnings'} = $warning_bits;
1710     }
1711
1712     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1713     my $old_hints = $self->{'hints'};
1714     if ($self->{'hints'} != $hints) {
1715         push @text, $self->declare_hints($self->{'hints'}, $hints);
1716         $self->{'hints'} = $hints;
1717     }
1718
1719     my $newhh;
1720     if ($] > 5.009) {
1721         $newhh = $op->hints_hash->HASH;
1722     }
1723
1724     if ($] >= 5.015006) {
1725         # feature bundle hints
1726         my $from = $old_hints & $feature::hint_mask;
1727         my $to   = $    hints & $feature::hint_mask;
1728         if ($from != $to) {
1729             if ($to == $feature::hint_mask) {
1730                 if ($self->{'hinthash'}) {
1731                     delete $self->{'hinthash'}{$_}
1732                         for grep /^feature_/, keys %{$self->{'hinthash'}};
1733                 }
1734                 else { $self->{'hinthash'} = {} }
1735                 $self->{'hinthash'}
1736                     = _features_from_bundle($from, $self->{'hinthash'});
1737             }
1738             else {
1739                 my $bundle =
1740                     $feature::hint_bundles[$to >> $feature::hint_shift];
1741                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
1742                 push @text,
1743                     $self->keyword("no") . " feature;\n",
1744                     $self->keyword("use") . " feature ':$bundle';\n";
1745             }
1746         }
1747     }
1748
1749     if ($] > 5.009) {
1750         push @text, $self->declare_hinthash(
1751             $self->{'hinthash'}, $newhh,
1752             $self->{indent_size}, $self->{hints},
1753         );
1754         $self->{'hinthash'} = $newhh;
1755     }
1756
1757     # This should go after of any branches that add statements, to
1758     # increase the chances that it refers to the same line it did in
1759     # the original program.
1760     if ($self->{'linenums'}) {
1761         push @text, "\f#line " . $op->line .
1762           ' "' . $op->file, qq'"\n';
1763     }
1764
1765     push @text, $op->label . ": " if $op->label;
1766
1767     return join("", @text);
1768 }
1769
1770 sub declare_warnings {
1771     my ($self, $from, $to) = @_;
1772     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1773         return $self->keyword("use") . " warnings;\n";
1774     }
1775     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1776         return $self->keyword("no") . " warnings;\n";
1777     }
1778     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1779 }
1780
1781 sub declare_hints {
1782     my ($self, $from, $to) = @_;
1783     my $use = $to   & ~$from;
1784     my $no  = $from & ~$to;
1785     my $decls = "";
1786     for my $pragma (hint_pragmas($use)) {
1787         $decls .= $self->keyword("use") . " $pragma;\n";
1788     }
1789     for my $pragma (hint_pragmas($no)) {
1790         $decls .= $self->keyword("no") . " $pragma;\n";
1791     }
1792     return $decls;
1793 }
1794
1795 # Internal implementation hints that the core sets automatically, so don't need
1796 # (or want) to be passed back to the user
1797 my %ignored_hints = (
1798     'open<' => 1,
1799     'open>' => 1,
1800     ':'     => 1,
1801     'strict/refs' => 1,
1802     'strict/subs' => 1,
1803     'strict/vars' => 1,
1804 );
1805
1806 my %rev_feature;
1807
1808 sub declare_hinthash {
1809     my ($self, $from, $to, $indent, $hints) = @_;
1810     my $doing_features =
1811         ($hints & $feature::hint_mask) == $feature::hint_mask;
1812     my @decls;
1813     my @features;
1814     my @unfeatures; # bugs?
1815     for my $key (sort keys %$to) {
1816         next if $ignored_hints{$key};
1817         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1818         next if $is_feature and not $doing_features;
1819         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
1820             push(@features, $key), next if $is_feature;
1821             push @decls,
1822                 qq(\$^H{) . single_delim("q", "'", $key, $self) . qq(} = )
1823               . (
1824                    defined $to->{$key}
1825                         ? single_delim("q", "'", $to->{$key}, $self)
1826                         : 'undef'
1827                 )
1828               . qq(;);
1829         }
1830     }
1831     for my $key (sort keys %$from) {
1832         next if $ignored_hints{$key};
1833         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1834         next if $is_feature and not $doing_features;
1835         if (!exists $to->{$key}) {
1836             push(@unfeatures, $key), next if $is_feature;
1837             push @decls, qq(delete \$^H{'$key'};);
1838         }
1839     }
1840     my @ret;
1841     if (@features || @unfeatures) {
1842         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
1843     }
1844     if (@features) {
1845         push @ret, $self->keyword("use") . " feature "
1846                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
1847     }
1848     if (@unfeatures) {
1849         push @ret, $self->keyword("no") . " feature "
1850                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
1851                  . ";\n";
1852     }
1853     @decls and
1854         push @ret,
1855              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1856     return @ret;
1857 }
1858
1859 sub hint_pragmas {
1860     my ($bits) = @_;
1861     my (@pragmas, @strict);
1862     push @pragmas, "integer" if $bits & 0x1;
1863     for (sort keys %strict_bits) {
1864         push @strict, "'$_'" if $bits & $strict_bits{$_};
1865     }
1866     if (@strict == keys %strict_bits) {
1867         push @pragmas, "strict";
1868     }
1869     elsif (@strict) {
1870         push @pragmas, "strict " . join ', ', @strict;
1871     }
1872     push @pragmas, "bytes" if $bits & 0x8;
1873     return @pragmas;
1874 }
1875
1876 sub pp_dbstate { pp_nextstate(@_) }
1877 sub pp_setstate { pp_nextstate(@_) }
1878
1879 sub pp_unstack { return "" } # see also leaveloop
1880
1881 my %feature_keywords = (
1882   # keyword => 'feature',
1883     state   => 'state',
1884     say     => 'say',
1885     given   => 'switch',
1886     when    => 'switch',
1887     default => 'switch',
1888     break   => 'switch',
1889     evalbytes=>'evalbytes',
1890     __SUB__ => '__SUB__',
1891    fc       => 'fc',
1892 );
1893
1894 # keywords that are strong and also have a prototype
1895 #
1896 my %strong_proto_keywords = map { $_ => 1 } qw(
1897     pos
1898     prototype
1899     scalar
1900     study
1901     undef
1902 );
1903
1904 sub feature_enabled {
1905         my($self,$name) = @_;
1906         my $hh;
1907         my $hints = $self->{hints} & $feature::hint_mask;
1908         if ($hints && $hints != $feature::hint_mask) {
1909             $hh = _features_from_bundle($hints);
1910         }
1911         elsif ($hints) { $hh = $self->{'hinthash'} }
1912         return $hh && $hh->{"feature_$feature_keywords{$name}"}
1913 }
1914
1915 sub keyword {
1916     my $self = shift;
1917     my $name = shift;
1918     return $name if $name =~ /^CORE::/; # just in case
1919     if (exists $feature_keywords{$name}) {
1920         return "CORE::$name" if not $self->feature_enabled($name);
1921     }
1922     # This sub may be called for a program that has no nextstate ops.  In
1923     # that case we may have a lexical sub named no/use/sub in scope but
1924     # but $self->lex_in_scope will return false because it depends on the
1925     # current nextstate op.  So we need this alternate method if there is
1926     # no current cop.
1927     if (!$self->{'curcop'}) {
1928         $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1929         return "CORE::$name" if exists $self->{'curcvlex'}{"m&$name"}
1930                              || exists $self->{'curcvlex'}{"o&$name"};
1931     } elsif ($self->lex_in_scope("&$name")
1932           || $self->lex_in_scope("&$name", 1)) {
1933         return "CORE::$name";
1934     }
1935     if ($strong_proto_keywords{$name}
1936         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1937             && !defined eval{prototype "CORE::$name"})
1938     ) { return $name }
1939     if (
1940         exists $self->{subs_declared}{$name}
1941          or
1942         exists &{"$self->{curstash}::$name"}
1943     ) {
1944         return "CORE::$name"
1945     }
1946     return $name;
1947 }
1948
1949 sub baseop {
1950     my $self = shift;
1951     my($op, $cx, $name) = @_;
1952     return $self->keyword($name);
1953 }
1954
1955 sub pp_stub {
1956     my $self = shift;
1957     my($op, $cx, $name) = @_;
1958     if ($cx >= 1) {
1959         return "()";
1960     }
1961     else {
1962         return "();";
1963     }
1964 }
1965 sub pp_wantarray { baseop(@_, "wantarray") }
1966 sub pp_fork { baseop(@_, "fork") }
1967 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1968 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1969 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1970 sub pp_tms { baseop(@_, "times") }
1971 sub pp_ghostent { baseop(@_, "gethostent") }
1972 sub pp_gnetent { baseop(@_, "getnetent") }
1973 sub pp_gprotoent { baseop(@_, "getprotoent") }
1974 sub pp_gservent { baseop(@_, "getservent") }
1975 sub pp_ehostent { baseop(@_, "endhostent") }
1976 sub pp_enetent { baseop(@_, "endnetent") }
1977 sub pp_eprotoent { baseop(@_, "endprotoent") }
1978 sub pp_eservent { baseop(@_, "endservent") }
1979 sub pp_gpwent { baseop(@_, "getpwent") }
1980 sub pp_spwent { baseop(@_, "setpwent") }
1981 sub pp_epwent { baseop(@_, "endpwent") }
1982 sub pp_ggrent { baseop(@_, "getgrent") }
1983 sub pp_sgrent { baseop(@_, "setgrent") }
1984 sub pp_egrent { baseop(@_, "endgrent") }
1985 sub pp_getlogin { baseop(@_, "getlogin") }
1986
1987 sub POSTFIX () { 1 }
1988
1989 # I couldn't think of a good short name, but this is the category of
1990 # symbolic unary operators with interesting precedence
1991
1992 sub pfixop {
1993     my $self = shift;
1994     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1995     my $kid = $op->first;
1996     $kid = $self->deparse($kid, $prec);
1997     return $self->maybe_parens(($flags & POSTFIX)
1998                                  ? "$kid$name"
1999                                    # avoid confusion with filetests
2000                                  : $name eq '-'
2001                                    && $kid =~ /^[a-zA-Z](?!\w)/
2002                                         ? "$name($kid)"
2003                                         : "$name$kid",
2004                                $cx, $prec);
2005 }
2006
2007 sub pp_preinc { pfixop(@_, "++", 23) }
2008 sub pp_predec { pfixop(@_, "--", 23) }
2009 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2010 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2011 sub pp_i_preinc { pfixop(@_, "++", 23) }
2012 sub pp_i_predec { pfixop(@_, "--", 23) }
2013 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2014 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2015 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
2016
2017 sub pp_negate { maybe_targmy(@_, \&real_negate) }
2018 sub real_negate {
2019     my $self = shift;
2020     my($op, $cx) = @_;
2021     if ($op->first->name =~ /^(i_)?negate$/) {
2022         # avoid --$x
2023         $self->pfixop($op, $cx, "-", 21.5);
2024     } else {
2025         $self->pfixop($op, $cx, "-", 21);       
2026     }
2027 }
2028 sub pp_i_negate { pp_negate(@_) }
2029
2030 sub pp_not {
2031     my $self = shift;
2032     my($op, $cx) = @_;
2033     if ($cx <= 4) {
2034         $self->listop($op, $cx, "not", $op->first);
2035     } else {
2036         $self->pfixop($op, $cx, "!", 21);       
2037     }
2038 }
2039
2040 sub unop {
2041     my $self = shift;
2042     my($op, $cx, $name, $nollafr) = @_;
2043     my $kid;
2044     if ($op->flags & OPf_KIDS) {
2045         $kid = $op->first;
2046         if (not $name) {
2047             # this deals with 'boolkeys' right now
2048             return $self->deparse($kid,$cx);
2049         }
2050         my $builtinname = $name;
2051         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
2052         if (defined prototype($builtinname)
2053            && prototype($builtinname) =~ /^;?\*/
2054            && $kid->name eq "rv2gv") {
2055             $kid = $kid->first;
2056         }
2057
2058         if ($nollafr) {
2059             ($kid = $self->deparse($kid, 16)) =~ s/^\cS//;
2060             return $self->maybe_parens(
2061                         $self->keyword($name) . " $kid", $cx, 16
2062                    );
2063         }   
2064         return $self->maybe_parens_unop($name, $kid, $cx);
2065     } else {
2066         return $self->maybe_parens(
2067             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
2068             $cx, 16,
2069         );
2070     }
2071 }
2072
2073 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
2074 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
2075 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
2076 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
2077 sub pp_defined { unop(@_, "defined") }
2078 sub pp_undef { unop(@_, "undef") }
2079 sub pp_study { unop(@_, "study") }
2080 sub pp_ref { unop(@_, "ref") }
2081 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
2082
2083 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
2084 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
2085 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
2086 sub pp_srand { unop(@_, "srand") }
2087 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
2088 sub pp_log { maybe_targmy(@_, \&unop, "log") }
2089 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
2090 sub pp_int { maybe_targmy(@_, \&unop, "int") }
2091 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
2092 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
2093 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
2094
2095 sub pp_length { maybe_targmy(@_, \&unop, "length") }
2096 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
2097 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
2098
2099 sub pp_each { unop(@_, "each") }
2100 sub pp_values { unop(@_, "values") }
2101 sub pp_keys { unop(@_, "keys") }
2102 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2103 sub pp_boolkeys { 
2104     # no name because its an optimisation op that has no keyword
2105     unop(@_,"");
2106 }
2107 sub pp_aeach { unop(@_, "each") }
2108 sub pp_avalues { unop(@_, "values") }
2109 sub pp_akeys { unop(@_, "keys") }
2110 sub pp_pop { unop(@_, "pop") }
2111 sub pp_shift { unop(@_, "shift") }
2112
2113 sub pp_caller { unop(@_, "caller") }
2114 sub pp_reset { unop(@_, "reset") }
2115 sub pp_exit { unop(@_, "exit") }
2116 sub pp_prototype { unop(@_, "prototype") }
2117
2118 sub pp_close { unop(@_, "close") }
2119 sub pp_fileno { unop(@_, "fileno") }
2120 sub pp_umask { unop(@_, "umask") }
2121 sub pp_untie { unop(@_, "untie") }
2122 sub pp_tied { unop(@_, "tied") }
2123 sub pp_dbmclose { unop(@_, "dbmclose") }
2124 sub pp_getc { unop(@_, "getc") }
2125 sub pp_eof { unop(@_, "eof") }
2126 sub pp_tell { unop(@_, "tell") }
2127 sub pp_getsockname { unop(@_, "getsockname") }
2128 sub pp_getpeername { unop(@_, "getpeername") }
2129
2130 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
2131 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2132 sub pp_readlink { unop(@_, "readlink") }
2133 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2134 sub pp_readdir { unop(@_, "readdir") }
2135 sub pp_telldir { unop(@_, "telldir") }
2136 sub pp_rewinddir { unop(@_, "rewinddir") }
2137 sub pp_closedir { unop(@_, "closedir") }
2138 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2139 sub pp_localtime { unop(@_, "localtime") }
2140 sub pp_gmtime { unop(@_, "gmtime") }
2141 sub pp_alarm { unop(@_, "alarm") }
2142 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2143
2144 sub pp_dofile {
2145     my $code = unop(@_, "do", 1); # llafr does not apply
2146     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2147     $code;
2148 }
2149 sub pp_entereval {
2150     unop(
2151       @_,
2152       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
2153     )
2154 }
2155
2156 sub pp_ghbyname { unop(@_, "gethostbyname") }
2157 sub pp_gnbyname { unop(@_, "getnetbyname") }
2158 sub pp_gpbyname { unop(@_, "getprotobyname") }
2159 sub pp_shostent { unop(@_, "sethostent") }
2160 sub pp_snetent { unop(@_, "setnetent") }
2161 sub pp_sprotoent { unop(@_, "setprotoent") }
2162 sub pp_sservent { unop(@_, "setservent") }
2163 sub pp_gpwnam { unop(@_, "getpwnam") }
2164 sub pp_gpwuid { unop(@_, "getpwuid") }
2165 sub pp_ggrnam { unop(@_, "getgrnam") }
2166 sub pp_ggrgid { unop(@_, "getgrgid") }
2167
2168 sub pp_lock { unop(@_, "lock") }
2169
2170 sub pp_continue { unop(@_, "continue"); }
2171 sub pp_break { unop(@_, "break"); }
2172
2173 sub givwhen {
2174     my $self = shift;
2175     my($op, $cx, $givwhen) = @_;
2176
2177     my $enterop = $op->first;
2178     my ($head, $block);
2179     if ($enterop->flags & OPf_SPECIAL) {
2180         $head = $self->keyword("default");
2181         $block = $self->deparse($enterop->first, 0);
2182     }
2183     else {
2184         my $cond = $enterop->first;
2185         my $cond_str = $self->deparse($cond, 1);
2186         $head = "$givwhen ($cond_str)";
2187         $block = $self->deparse($cond->sibling, 0);
2188     }
2189
2190     return "$head {\n".
2191         "\t$block\n".
2192         "\b}\cK";
2193 }
2194
2195 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2196 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2197
2198 sub pp_exists {
2199     my $self = shift;
2200     my($op, $cx) = @_;
2201     my $arg;
2202     my $name = $self->keyword("exists");
2203     if ($op->private & OPpEXISTS_SUB) {
2204         # Checking for the existence of a subroutine
2205         return $self->maybe_parens_func($name,
2206                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2207     }
2208     if ($op->flags & OPf_SPECIAL) {
2209         # Array element, not hash element
2210         return $self->maybe_parens_func($name,
2211                                 $self->pp_aelem($op->first, 16), $cx, 16);
2212     }
2213     return $self->maybe_parens_func($name, $self->pp_helem($op->first, 16),
2214                                     $cx, 16);
2215 }
2216
2217 sub pp_delete {
2218     my $self = shift;
2219     my($op, $cx) = @_;
2220     my $arg;
2221     my $name = $self->keyword("delete");
2222     if ($op->private & OPpSLICE) {
2223         if ($op->flags & OPf_SPECIAL) {
2224             # Deleting from an array, not a hash
2225             return $self->maybe_parens_func($name,
2226                                         $self->pp_aslice($op->first, 16),
2227                                         $cx, 16);
2228         }
2229         return $self->maybe_parens_func($name,
2230                                         $self->pp_hslice($op->first, 16),
2231                                         $cx, 16);
2232     } else {
2233         if ($op->flags & OPf_SPECIAL) {
2234             # Deleting from an array, not a hash
2235             return $self->maybe_parens_func($name,
2236                                         $self->pp_aelem($op->first, 16),
2237                                         $cx, 16);
2238         }
2239         return $self->maybe_parens_func($name,
2240                                         $self->pp_helem($op->first, 16),
2241                                         $cx, 16);
2242     }
2243 }
2244
2245 sub pp_require {
2246     my $self = shift;
2247     my($op, $cx) = @_;
2248     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2249     if (class($op) eq "UNOP" and $op->first->name eq "const"
2250         and $op->first->private & OPpCONST_BARE)
2251     {
2252         my $name = $self->const_sv($op->first)->PV;
2253         $name =~ s[/][::]g;
2254         $name =~ s/\.pm//g;
2255         return $self->maybe_parens("$opname $name", $cx, 16);
2256     } else {    
2257         $self->unop(
2258             $op, $cx,
2259             $op->first->name eq 'const'
2260              && $op->first->private & OPpCONST_NOVER
2261                  ? "no"
2262                  : $opname,
2263             1, # llafr does not apply
2264         );
2265     }
2266 }
2267
2268 sub pp_scalar {
2269     my $self = shift;
2270     my($op, $cx) = @_;
2271     my $kid = $op->first;
2272     if (not null $kid->sibling) {
2273         # XXX Was a here-doc
2274         return $self->dquote($op);
2275     }
2276     $self->unop(@_, "scalar");
2277 }
2278
2279
2280 sub padval {
2281     my $self = shift;
2282     my $targ = shift;
2283     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2284 }
2285
2286 sub anon_hash_or_list {
2287     my $self = shift;
2288     my($op, $cx) = @_;
2289
2290     my($pre, $post) = @{{"anonlist" => ["[","]"],
2291                          "anonhash" => ["{","}"]}->{$op->name}};
2292     my($expr, @exprs);
2293     $op = $op->first->sibling; # skip pushmark
2294     for (; !null($op); $op = $op->sibling) {
2295         $expr = $self->deparse($op, 6);
2296         push @exprs, $expr;
2297     }
2298     if ($pre eq "{" and $cx < 1) {
2299         # Disambiguate that it's not a block
2300         $pre = "+{";
2301     }
2302     return $pre . join(", ", @exprs) . $post;
2303 }
2304
2305 sub pp_anonlist {
2306     my $self = shift;
2307     my ($op, $cx) = @_;
2308     if ($op->flags & OPf_SPECIAL) {
2309         return $self->anon_hash_or_list($op, $cx);
2310     }
2311     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2312     return 'XXX';
2313 }
2314
2315 *pp_anonhash = \&pp_anonlist;
2316
2317 sub pp_refgen {
2318     my $self = shift;   
2319     my($op, $cx) = @_;
2320     my $kid = $op->first;
2321     if ($kid->name eq "null") {
2322         my $anoncode = $kid = $kid->first;
2323         if ($anoncode->name eq "anoncode"
2324          or !null($anoncode = $kid->sibling) and
2325                  $anoncode->name eq "anoncode") {
2326             return $self->e_anoncode({ code => $self->padval($anoncode->targ) });
2327         } elsif ($kid->name eq "pushmark") {
2328             my $sib_name = $kid->sibling->name;
2329             if ($sib_name eq 'entersub') {
2330                 my $text = $self->deparse($kid->sibling, 1);
2331                 # Always show parens for \(&func()), but only with -p otherwise
2332                 $text = "($text)" if $self->{'parens'}
2333                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2334                 return "\\$text";
2335             }
2336         }
2337     }
2338     local $self->{'in_refgen'} = 1;
2339     $self->pfixop($op, $cx, "\\", 20);
2340 }
2341
2342 sub e_anoncode {
2343     my ($self, $info) = @_;
2344     my $text = $self->deparse_sub($info->{code});
2345     return $self->keyword("sub") . " $text";
2346 }
2347
2348 sub pp_srefgen { pp_refgen(@_) }
2349
2350 sub pp_readline {
2351     my $self = shift;
2352     my($op, $cx) = @_;
2353     my $kid = $op->first;
2354     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
2355     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
2356     return $self->unop($op, $cx, "readline");
2357 }
2358
2359 sub pp_rcatline {
2360     my $self = shift;
2361     my($op) = @_;
2362     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2363 }
2364
2365 # Unary operators that can occur as pseudo-listops inside double quotes
2366 sub dq_unop {
2367     my $self = shift;
2368     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2369     my $kid;
2370     if ($op->flags & OPf_KIDS) {
2371        $kid = $op->first;
2372        # If there's more than one kid, the first is an ex-pushmark.
2373        $kid = $kid->sibling if not null $kid->sibling;
2374        return $self->maybe_parens_unop($name, $kid, $cx);
2375     } else {
2376        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2377     }
2378 }
2379
2380 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2381 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2382 sub pp_uc { dq_unop(@_, "uc") }
2383 sub pp_lc { dq_unop(@_, "lc") }
2384 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2385 sub pp_fc { dq_unop(@_, "fc") }
2386
2387 sub loopex {
2388     my $self = shift;
2389     my ($op, $cx, $name) = @_;
2390     if (class($op) eq "PVOP") {
2391         $name .= " " . $op->pv;
2392     } elsif (class($op) eq "OP") {
2393         # no-op
2394     } elsif (class($op) eq "UNOP") {
2395         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2396         $name .= " $kid";
2397     }
2398     return $self->maybe_parens($name, $cx, 7);
2399 }
2400
2401 sub pp_last { loopex(@_, "last") }
2402 sub pp_next { loopex(@_, "next") }
2403 sub pp_redo { loopex(@_, "redo") }
2404 sub pp_goto { loopex(@_, "goto") }
2405 sub pp_dump { loopex(@_, "CORE::dump") }
2406
2407 sub ftst {
2408     my $self = shift;
2409     my($op, $cx, $name) = @_;
2410     if (class($op) eq "UNOP") {
2411         # Genuine '-X' filetests are exempt from the LLAFR, but not
2412         # l?stat()
2413         if ($name =~ /^-/) {
2414             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2415             return $self->maybe_parens("$name $kid", $cx, 16);
2416         }
2417         return $self->maybe_parens_unop($name, $op->first, $cx);
2418     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2419         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2420     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2421         return $name;
2422     }
2423 }
2424
2425 sub pp_lstat    { ftst(@_, "lstat") }
2426 sub pp_stat     { ftst(@_, "stat") }
2427 sub pp_ftrread  { ftst(@_, "-R") }
2428 sub pp_ftrwrite { ftst(@_, "-W") }
2429 sub pp_ftrexec  { ftst(@_, "-X") }
2430 sub pp_fteread  { ftst(@_, "-r") }
2431 sub pp_ftewrite { ftst(@_, "-w") }
2432 sub pp_fteexec  { ftst(@_, "-x") }
2433 sub pp_ftis     { ftst(@_, "-e") }
2434 sub pp_fteowned { ftst(@_, "-O") }
2435 sub pp_ftrowned { ftst(@_, "-o") }
2436 sub pp_ftzero   { ftst(@_, "-z") }
2437 sub pp_ftsize   { ftst(@_, "-s") }
2438 sub pp_ftmtime  { ftst(@_, "-M") }
2439 sub pp_ftatime  { ftst(@_, "-A") }
2440 sub pp_ftctime  { ftst(@_, "-C") }
2441 sub pp_ftsock   { ftst(@_, "-S") }
2442 sub pp_ftchr    { ftst(@_, "-c") }
2443 sub pp_ftblk    { ftst(@_, "-b") }
2444 sub pp_ftfile   { ftst(@_, "-f") }
2445 sub pp_ftdir    { ftst(@_, "-d") }
2446 sub pp_ftpipe   { ftst(@_, "-p") }
2447 sub pp_ftlink   { ftst(@_, "-l") }
2448 sub pp_ftsuid   { ftst(@_, "-u") }
2449 sub pp_ftsgid   { ftst(@_, "-g") }
2450 sub pp_ftsvtx   { ftst(@_, "-k") }
2451 sub pp_fttty    { ftst(@_, "-t") }
2452 sub pp_fttext   { ftst(@_, "-T") }
2453 sub pp_ftbinary { ftst(@_, "-B") }
2454
2455 sub SWAP_CHILDREN () { 1 }
2456 sub ASSIGN () { 2 } # has OP= variant
2457 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2458
2459 my(%left, %right);
2460
2461 sub assoc_class {
2462     my $op = shift;
2463     my $name = $op->name;
2464     if ($name eq "concat" and $op->first->name eq "concat") {
2465         # avoid spurious '=' -- see comment in pp_concat
2466         return "concat";
2467     }
2468     if ($name eq "null" and class($op) eq "UNOP"
2469         and $op->first->name =~ /^(and|x?or)$/
2470         and null $op->first->sibling)
2471     {
2472         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2473         # with a null that's used as the common end point of the two
2474         # flows of control. For precedence purposes, ignore it.
2475         # (COND_EXPRs have these too, but we don't bother with
2476         # their associativity).
2477         return assoc_class($op->first);
2478     }
2479     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2480 }
2481
2482 # Left associative operators, like '+', for which
2483 # $a + $b + $c is equivalent to ($a + $b) + $c
2484
2485 BEGIN {
2486     %left = ('multiply' => 19, 'i_multiply' => 19,
2487              'divide' => 19, 'i_divide' => 19,
2488              'modulo' => 19, 'i_modulo' => 19,
2489              'repeat' => 19,
2490              'add' => 18, 'i_add' => 18,
2491              'subtract' => 18, 'i_subtract' => 18,
2492              'concat' => 18,
2493              'left_shift' => 17, 'right_shift' => 17,
2494              'bit_and' => 13,
2495              'bit_or' => 12, 'bit_xor' => 12,
2496              'and' => 3,
2497              'or' => 2, 'xor' => 2,
2498             );
2499 }
2500
2501 sub deparse_binop_left {
2502     my $self = shift;
2503     my($op, $left, $prec) = @_;
2504     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2505         and $left{assoc_class($op)} == $left{assoc_class($left)})
2506     {
2507         return $self->deparse($left, $prec - .00001);
2508     } else {
2509         return $self->deparse($left, $prec);    
2510     }
2511 }
2512
2513 # Right associative operators, like '=', for which
2514 # $a = $b = $c is equivalent to $a = ($b = $c)
2515
2516 BEGIN {
2517     %right = ('pow' => 22,
2518               'sassign=' => 7, 'aassign=' => 7,
2519               'multiply=' => 7, 'i_multiply=' => 7,
2520               'divide=' => 7, 'i_divide=' => 7,
2521               'modulo=' => 7, 'i_modulo=' => 7,
2522               'repeat=' => 7, 'refassign' => 7, 'refassign=' => 7,
2523               'add=' => 7, 'i_add=' => 7,
2524               'subtract=' => 7, 'i_subtract=' => 7,
2525               'concat=' => 7,
2526               'left_shift=' => 7, 'right_shift=' => 7,
2527               'bit_and=' => 7,
2528               'bit_or=' => 7, 'bit_xor=' => 7,
2529               'andassign' => 7,
2530               'orassign' => 7,
2531              );
2532 }
2533
2534 sub deparse_binop_right {
2535     my $self = shift;
2536     my($op, $right, $prec) = @_;
2537     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2538         and $right{assoc_class($op)} == $right{assoc_class($right)})
2539     {
2540         return $self->deparse($right, $prec - .00001);
2541     } else {
2542         return $self->deparse($right, $prec);   
2543     }
2544 }
2545
2546 sub binop {
2547     my $self = shift;
2548     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2549     my $left = $op->first;
2550     my $right = $op->last;
2551     my $eq = "";
2552     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2553         $eq = "=";
2554         $prec = 7;
2555     }
2556     if ($flags & SWAP_CHILDREN) {
2557         ($left, $right) = ($right, $left);
2558     }
2559     my $leftop = $left;
2560     $left = $self->deparse_binop_left($op, $left, $prec);
2561     $left = "($left)" if $flags & LIST_CONTEXT
2562                      and    $left !~ /^(my|our|local|)[\@\(]/
2563                          || do {
2564                                 # Parenthesize if the left argument is a
2565                                 # lone repeat op.
2566                                 my $left = $leftop->first->sibling;
2567                                 $left->name eq 'repeat'
2568                                     && null($left->sibling);
2569                             };
2570     $right = $self->deparse_binop_right($op, $right, $prec);
2571     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2572 }
2573
2574 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2575 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2576 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2577 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2578 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2579 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2580 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2581 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2582 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2583 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2584 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2585
2586 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2587 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2588 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2589 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2590 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2591
2592 sub pp_eq { binop(@_, "==", 14) }
2593 sub pp_ne { binop(@_, "!=", 14) }
2594 sub pp_lt { binop(@_, "<", 15) }
2595 sub pp_gt { binop(@_, ">", 15) }
2596 sub pp_ge { binop(@_, ">=", 15) }
2597 sub pp_le { binop(@_, "<=", 15) }
2598 sub pp_ncmp { binop(@_, "<=>", 14) }
2599 sub pp_i_eq { binop(@_, "==", 14) }
2600 sub pp_i_ne { binop(@_, "!=", 14) }
2601 sub pp_i_lt { binop(@_, "<", 15) }
2602 sub pp_i_gt { binop(@_, ">", 15) }
2603 sub pp_i_ge { binop(@_, ">=", 15) }
2604 sub pp_i_le { binop(@_, "<=", 15) }
2605 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2606
2607 sub pp_seq { binop(@_, "eq", 14) }
2608 sub pp_sne { binop(@_, "ne", 14) }
2609 sub pp_slt { binop(@_, "lt", 15) }
2610 sub pp_sgt { binop(@_, "gt", 15) }
2611 sub pp_sge { binop(@_, "ge", 15) }
2612 sub pp_sle { binop(@_, "le", 15) }
2613 sub pp_scmp { binop(@_, "cmp", 14) }
2614
2615 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2616 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2617
2618 sub pp_smartmatch {
2619     my ($self, $op, $cx) = @_;
2620     if ($op->flags & OPf_SPECIAL) {
2621         return $self->deparse($op->last, $cx);
2622     }
2623     else {
2624         binop(@_, "~~", 14);
2625     }
2626 }
2627
2628 # '.' is special because concats-of-concats are optimized to save copying
2629 # by making all but the first concat stacked. The effect is as if the
2630 # programmer had written '($a . $b) .= $c', except legal.
2631 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2632 sub real_concat {
2633     my $self = shift;
2634     my($op, $cx) = @_;
2635     my $left = $op->first;
2636     my $right = $op->last;
2637     my $eq = "";
2638     my $prec = 18;
2639     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2640         $eq = "=";
2641         $prec = 7;
2642     }
2643     $left = $self->deparse_binop_left($op, $left, $prec);
2644     $right = $self->deparse_binop_right($op, $right, $prec);
2645     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2646 }
2647
2648 sub pp_repeat { maybe_targmy(@_, \&repeat) }
2649
2650 # 'x' is weird when the left arg is a list
2651 sub repeat {
2652     my $self = shift;
2653     my($op, $cx) = @_;
2654     my $left = $op->first;
2655     my $right = $op->last;
2656     my $eq = "";
2657     my $prec = 19;
2658     if ($op->flags & OPf_STACKED) {
2659         $eq = "=";
2660         $prec = 7;
2661     }
2662     if (null($right)) { # list repeat; count is inside left-side ex-list
2663                         # in 5.21.5 and earlier
2664         my $kid = $left->first->sibling; # skip pushmark
2665         my @exprs;
2666         for (; !null($kid->sibling); $kid = $kid->sibling) {
2667             push @exprs, $self->deparse($kid, 6);
2668         }
2669         $right = $kid;
2670         $left = "(" . join(", ", @exprs). ")";
2671     } else {
2672         my $dolist = $op->private & OPpREPEAT_DOLIST;
2673         $left = $self->deparse_binop_left($op, $left, $dolist ? 1 : $prec);
2674         if ($dolist) {
2675             $left = "($left)";
2676         }
2677     }
2678     $right = $self->deparse_binop_right($op, $right, $prec);
2679     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2680 }
2681
2682 sub range {
2683     my $self = shift;
2684     my ($op, $cx, $type) = @_;
2685     my $left = $op->first;
2686     my $right = $left->sibling;
2687     $left = $self->deparse($left, 9);
2688     $right = $self->deparse($right, 9);
2689     return $self->maybe_parens("$left $type $right", $cx, 9);
2690 }
2691
2692 sub pp_flop {
2693     my $self = shift;
2694     my($op, $cx) = @_;
2695     my $flip = $op->first;
2696     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2697     return $self->range($flip->first, $cx, $type);
2698 }
2699
2700 # one-line while/until is handled in pp_leave
2701
2702 sub logop {
2703     my $self = shift;
2704     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2705     my $left = $op->first;
2706     my $right = $op->first->sibling;
2707     $blockname &&= $self->keyword($blockname);
2708     if ($cx < 1 and is_scope($right) and $blockname
2709         and $self->{'expand'} < 7)
2710     { # if ($a) {$b}
2711         $left = $self->deparse($left, 1);
2712         $right = $self->deparse($right, 0);
2713         return "$blockname ($left) {\n\t$right\n\b}\cK";
2714     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2715              and $self->{'expand'} < 7) { # $b if $a
2716         $right = $self->deparse($right, 1);
2717         $left = $self->deparse($left, 1);
2718         return "$right $blockname $left";
2719     } elsif ($cx > $lowprec and $highop) { # $a && $b
2720         $left = $self->deparse_binop_left($op, $left, $highprec);
2721         $right = $self->deparse_binop_right($op, $right, $highprec);
2722         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2723     } else { # $a and $b
2724         $left = $self->deparse_binop_left($op, $left, $lowprec);
2725         $right = $self->deparse_binop_right($op, $right, $lowprec);
2726         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2727     }
2728 }
2729
2730 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2731 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2732 sub pp_dor { logop(@_, "//", 10) }
2733
2734 # xor is syntactically a logop, but it's really a binop (contrary to
2735 # old versions of opcode.pl). Syntax is what matters here.
2736 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2737
2738 sub logassignop {
2739     my $self = shift;
2740     my ($op, $cx, $opname) = @_;
2741     my $left = $op->first;
2742     my $right = $op->first->sibling->first; # skip sassign
2743     $left = $self->deparse($left, 7);
2744     $right = $self->deparse($right, 7);
2745     return $self->maybe_parens("$left $opname $right", $cx, 7);
2746 }
2747
2748 sub pp_andassign { logassignop(@_, "&&=") }
2749 sub pp_orassign  { logassignop(@_, "||=") }
2750 sub pp_dorassign { logassignop(@_, "//=") }
2751
2752 sub rv2gv_or_string {
2753     my($self,$op) = @_;
2754     if ($op->name eq "gv") { # could be open("open") or open("###")
2755         my($name,$quoted) =
2756             $self->stash_variable_name("", $self->gv_or_padgv($op));
2757         $quoted ? $name : "*$name";
2758     }
2759     else {
2760         $self->deparse($op, 6);
2761     }
2762 }
2763
2764 sub listop {
2765     my $self = shift;
2766     my($op, $cx, $name, $kid, $nollafr) = @_;
2767     my(@exprs);
2768     my $parens = ($cx >= 5) || $self->{'parens'};
2769     $kid ||= $op->first->sibling;
2770     # If there are no arguments, add final parentheses (or parenthesize the
2771     # whole thing if the llafr does not apply) to account for cases like
2772     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
2773     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
2774     if (null $kid) {
2775         return $nollafr
2776                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
2777                 : $self->keyword($name) . '()' x (7 < $cx);
2778     }
2779     my $first;
2780     my $fullname = $self->keyword($name);
2781     my $proto = prototype("CORE::$name");
2782     if (
2783          (     (defined $proto && $proto =~ /^;?\*/)
2784             || $name eq 'select' # select(F) doesn't have a proto
2785          )
2786          && $kid->name eq "rv2gv"
2787          && !($kid->private & OPpLVAL_INTRO)
2788     ) {
2789         $first = $self->rv2gv_or_string($kid->first);
2790     }
2791     else {
2792         $first = $self->deparse($kid, 6);
2793     }
2794     if ($name eq "chmod" && $first =~ /^\d+$/) {
2795         $first = sprintf("%#o", $first);
2796     }
2797     $first = "+$first"
2798         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
2799     push @exprs, $first;
2800     $kid = $kid->sibling;
2801     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
2802          && !($kid->private & OPpLVAL_INTRO)) {
2803         push @exprs, $first = $self->rv2gv_or_string($kid->first);
2804         $kid = $kid->sibling;
2805     }
2806     for (; !null($kid); $kid = $kid->sibling) {
2807         push @exprs, $self->deparse($kid, 6);
2808     }
2809     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2810         return "$exprs[0] = $fullname"
2811                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2812     }
2813     if ($name =~ /^(system|exec)$/
2814         && ($op->flags & OPf_STACKED)
2815         && @exprs > 1)
2816     {
2817         # handle the "system prog a1,a2,.." form
2818         my $prog = shift @exprs;
2819         $exprs[0] = "$prog $exprs[0]";
2820     }
2821
2822     if ($parens && $nollafr) {
2823         return "($fullname " . join(", ", @exprs) . ")";
2824     } elsif ($parens) {
2825         return "$fullname(" . join(", ", @exprs) . ")";
2826     } else {
2827         return "$fullname " . join(", ", @exprs);
2828     }
2829 }
2830
2831 sub pp_bless { listop(@_, "bless") }
2832 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2833 sub pp_substr {
2834     my ($self,$op,$cx) = @_;
2835     if ($op->private & OPpSUBSTR_REPL_FIRST) {
2836         return
2837            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
2838          . " = "
2839          . $self->deparse($op->first->sibling, 7);
2840     }
2841     maybe_local(@_, listop(@_, "substr"))
2842 }
2843 sub pp_vec { maybe_targmy(@_, \&maybe_local, listop(@_, "vec")) }
2844 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2845 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2846 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2847 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2848 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2849 sub pp_unpack { listop(@_, "unpack") }
2850 sub pp_pack { listop(@_, "pack") }
2851 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2852 sub pp_splice { listop(@_, "splice") }
2853 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2854 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2855 sub pp_reverse { listop(@_, "reverse") }
2856 sub pp_warn { listop(@_, "warn") }
2857 sub pp_die { listop(@_, "die") }
2858 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
2859 sub pp_open { listop(@_, "open") }
2860 sub pp_pipe_op { listop(@_, "pipe") }
2861 sub pp_tie { listop(@_, "tie") }
2862 sub pp_binmode { listop(@_, "binmode") }
2863 sub pp_dbmopen { listop(@_, "dbmopen") }
2864 sub pp_sselect { listop(@_, "select") }
2865 sub pp_select { listop(@_, "select") }
2866 sub pp_read { listop(@_, "read") }
2867 sub pp_sysopen { listop(@_, "sysopen") }
2868 sub pp_sysseek { listop(@_, "sysseek") }
2869 sub pp_sysread { listop(@_, "sysread") }
2870 sub pp_syswrite { listop(@_, "syswrite") }
2871 sub pp_send { listop(@_, "send") }
2872 sub pp_recv { listop(@_, "recv") }
2873 sub pp_seek { listop(@_, "seek") }
2874 sub pp_fcntl { listop(@_, "fcntl") }
2875 sub pp_ioctl { listop(@_, "ioctl") }
2876 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2877 sub pp_socket { listop(@_, "socket") }
2878 sub pp_sockpair { listop(@_, "socketpair") }
2879 sub pp_bind { listop(@_, "bind") }
2880 sub pp_connect { listop(@_, "connect") }
2881 sub pp_listen { listop(@_, "listen") }
2882 sub pp_accept { listop(@_, "accept") }
2883 sub pp_shutdown { listop(@_, "shutdown") }
2884 sub pp_gsockopt { listop(@_, "getsockopt") }
2885 sub pp_ssockopt { listop(@_, "setsockopt") }
2886 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2887 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2888 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2889 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2890 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2891 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2892 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2893 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2894 sub pp_open_dir { listop(@_, "opendir") }
2895 sub pp_seekdir { listop(@_, "seekdir") }
2896 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2897 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2898 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2899 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2900 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2901 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2902 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2903 sub pp_shmget { listop(@_, "shmget") }
2904 sub pp_shmctl { listop(@_, "shmctl") }
2905 sub pp_shmread { listop(@_, "shmread") }
2906 sub pp_shmwrite { listop(@_, "shmwrite") }
2907 sub pp_msgget { listop(@_, "msgget") }
2908 sub pp_msgctl { listop(@_, "msgctl") }
2909 sub pp_msgsnd { listop(@_, "msgsnd") }
2910 sub pp_msgrcv { listop(@_, "msgrcv") }
2911 sub pp_semget { listop(@_, "semget") }
2912 sub pp_semctl { listop(@_, "semctl") }
2913 sub pp_semop { listop(@_, "semop") }
2914 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2915 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2916 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2917 sub pp_gsbyname { listop(@_, "getservbyname") }
2918 sub pp_gsbyport { listop(@_, "getservbyport") }
2919 sub pp_syscall { listop(@_, "syscall") }
2920
2921 sub pp_glob {
2922     my $self = shift;
2923     my($op, $cx) = @_;
2924     my $kid = $op->first->sibling;  # skip pushmark
2925     my $keyword =
2926         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2927     my $text;
2928     if ($keyword =~ /^CORE::/
2929         or $kid->name ne 'const'
2930         or ($text = $self->dq($kid))
2931              =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2932         or $text =~ /[<>]/) {
2933         $text = $self->deparse($kid);
2934         return $cx >= 5 || $self->{'parens'}
2935             ? "$keyword($text)"
2936             : "$keyword $text";
2937     } else {
2938         return '<' . $text . '>';
2939     }
2940 }
2941
2942 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2943 # be a filehandle. This could probably be better fixed in the core
2944 # by moving the GV lookup into ck_truc.
2945
2946 sub pp_truncate {
2947     my $self = shift;
2948     my($op, $cx) = @_;
2949     my(@exprs);
2950     my $parens = ($cx >= 5) || $self->{'parens'};
2951     my $kid = $op->first->sibling;
2952     my $fh;
2953     if ($op->flags & OPf_SPECIAL) {
2954         # $kid is an OP_CONST
2955         $fh = $self->const_sv($kid)->PV;
2956     } else {
2957         $fh = $self->deparse($kid, 6);
2958         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2959     }
2960     my $len = $self->deparse($kid->sibling, 6);
2961     my $name = $self->keyword('truncate');
2962     if ($parens) {
2963         return "$name($fh, $len)";
2964     } else {
2965         return "$name $fh, $len";
2966     }
2967 }
2968
2969 sub indirop {
2970     my $self = shift;
2971     my($op, $cx, $name) = @_;
2972     my($expr, @exprs);
2973     my $firstkid = my $kid = $op->first->sibling;
2974     my $indir = "";
2975     if ($op->flags & OPf_STACKED) {
2976         $indir = $kid;
2977         $indir = $indir->first; # skip rv2gv
2978         if (is_scope($indir)) {
2979             $indir = "{" . $self->deparse($indir, 0) . "}";
2980             $indir = "{;}" if $indir eq "{}";
2981         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2982             $indir = $self->const_sv($indir)->PV;
2983         } else {
2984             $indir = $self->deparse($indir, 24);
2985         }
2986         $indir = $indir . " ";
2987         $kid = $kid->sibling;
2988     }
2989     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2990         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2991                                                   : '{$a <=> $b} ';
2992     }
2993     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2994         $indir = '{$b cmp $a} ';
2995     }
2996     for (; !null($kid); $kid = $kid->sibling) {
2997         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2998         push @exprs, $expr;
2999     }
3000     my $name2;
3001     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
3002         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
3003     }
3004     else { $name2 = $self->keyword($name) }
3005     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
3006         return "$exprs[0] = $name2 $indir $exprs[0]";
3007     }
3008
3009     my $args = $indir . join(", ", @exprs);
3010     if ($indir ne "" && $name eq "sort") {
3011         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
3012         # give bareword warnings in that case. Therefore if context
3013         # requires, we'll put parens around the outside "(sort f 1, 2,
3014         # 3)". Unfortunately, we'll currently think the parens are
3015         # necessary more often that they really are, because we don't
3016         # distinguish which side of an assignment we're on.
3017         if ($cx >= 5) {
3018             return "($name2 $args)";
3019         } else {
3020             return "$name2 $args";
3021         }
3022     } elsif (
3023         !$indir && $name eq "sort"
3024       && !null($op->first->sibling)
3025       && $op->first->sibling->name eq 'entersub'
3026     ) {
3027         # We cannot say sort foo(bar), as foo will be interpreted as a
3028         # comparison routine.  We have to say sort(...) in that case.
3029         return "$name2($args)";
3030     } else {
3031         return $self->maybe_parens_func($name2, $args, $cx, 5);
3032     }
3033
3034 }
3035
3036 sub pp_prtf { indirop(@_, "printf") }
3037 sub pp_print { indirop(@_, "print") }
3038 sub pp_say  { indirop(@_, "say") }
3039 sub pp_sort { indirop(@_, "sort") }
3040
3041 sub mapop {
3042     my $self = shift;
3043     my($op, $cx, $name) = @_;
3044     my($expr, @exprs);
3045     my $kid = $op->first; # this is the (map|grep)start
3046     $kid = $kid->first->sibling; # skip a pushmark
3047     my $code = $kid->first; # skip a null
3048     if (is_scope $code) {
3049         $code = "{" . $self->deparse($code, 0) . "} ";
3050     } else {
3051         $code = $self->deparse($code, 24);
3052         $code .= ", " if !null($kid->sibling);
3053     }
3054     $kid = $kid->sibling;
3055     for (; !null($kid); $kid = $kid->sibling) {
3056         $expr = $self->deparse($kid, 6);
3057         push @exprs, $expr if defined $expr;
3058     }
3059     return $self->maybe_parens_func($self->keyword($name),
3060                                     $code . join(", ", @exprs), $cx, 5);
3061 }
3062
3063 sub pp_mapwhile { mapop(@_, "map") }
3064 sub pp_grepwhile { mapop(@_, "grep") }
3065 sub pp_mapstart { baseop(@_, "map") }
3066 sub pp_grepstart { baseop(@_, "grep") }
3067
3068 my %uses_intro;
3069 BEGIN {
3070     @uses_intro{
3071         eval { require B::Op_private }
3072           ? @{$B::Op_private::ops_using{OPpLVAL_INTRO}}
3073           : qw(gvsv rv2sv rv2hv rv2gv rv2av aelem helem aslice
3074                hslice delete padsv padav padhv enteriter entersub padrange
3075                pushmark cond_expr refassign list)
3076     } = ();
3077     delete @uses_intro{qw( lvref lvrefslice lvavref )};
3078 }
3079
3080 sub pp_list {
3081     my $self = shift;
3082     my($op, $cx) = @_;
3083     my($expr, @exprs);
3084     my $kid = $op->first->sibling; # skip pushmark
3085     return '' if class($kid) eq 'NULL';
3086     my $lop;
3087     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
3088     my $type;
3089     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3090         my $lopname = $lop->name;
3091         my $loppriv = $lop->private;
3092         my $newtype;
3093         if ($lopname =~ /^pad[ash]v$/ && $loppriv & OPpLVAL_INTRO) {
3094             if ($loppriv & OPpPAD_STATE) { # state()
3095                 ($local = "", last) if $local !~ /^(?:either|state)$/;
3096                 $local = "state";
3097             } else { # my()
3098                 ($local = "", last) if $local !~ /^(?:either|my)$/;
3099                 $local = "my";
3100             }
3101             my $padname = $self->padname_sv($lop->targ);
3102             if ($padname->FLAGS & SVpad_TYPED) {
3103                 $newtype = $padname->SvSTASH->NAME;
3104             }
3105         } elsif ($lopname =~ /^(?:gv|rv2)([ash])v$/
3106                         && $loppriv & OPpOUR_INTRO
3107                 or $lopname eq "null" && $lop->first->name eq "gvsv"
3108                         && $lop->first->private & OPpOUR_INTRO) { # our()
3109             my $newlocal = "local " x !!($loppriv & OPpLVAL_INTRO) . "our";
3110             ($local = "", last)
3111                 if $local ne 'either' && $local ne $newlocal;
3112             $local = $newlocal;
3113             my $funny = !$1 || $1 eq 's' ? '$' : $1 eq 'a' ? '@' : '%';
3114             if (my $t = $self->find_our_type(
3115                     $funny . $self->gv_or_padgv($lop->first)->NAME
3116                )) {
3117                 $newtype = $t;
3118             }
3119         } elsif ($lopname ne 'undef'
3120            and    !($loppriv & OPpLVAL_INTRO)
3121                || !exists $uses_intro{$lopname eq 'null'
3122                                         ? substr B::ppname($lop->targ), 3
3123                                         : $lopname})
3124         {
3125             $local = ""; # or not
3126             last;
3127         } elsif ($lopname ne "undef")
3128         {
3129             # local()
3130             ($local = "", last) if $local !~ /^(?:either|local)$/;
3131             $local = "local";
3132         }
3133         if (defined $type && defined $newtype && $newtype ne $type) {
3134             $local = '';
3135             last;
3136         }
3137         $type = $newtype;
3138     }
3139     $local = "" if $local eq "either"; # no point if it's all undefs
3140     $local &&= join ' ', map $self->keyword($_), split / /, $local;
3141     $local .= " $type " if $local && length $type;
3142     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
3143     for (; !null($kid); $kid = $kid->sibling) {
3144         if ($local) {
3145             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3146                 $lop = $kid->first;
3147             } else {
3148                 $lop = $kid;
3149             }
3150             $self->{'avoid_local'}{$$lop}++;
3151             $expr = $self->deparse($kid, 6);
3152             delete $self->{'avoid_local'}{$$lop};
3153         } else {
3154             $expr = $self->deparse($kid, 6);
3155         }
3156         push @exprs, $expr;
3157     }
3158     if ($local) {
3159         return "$local(" . join(", ", @exprs) . ")";
3160     } else {
3161         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3162     }
3163 }
3164
3165 sub is_ifelse_cont {
3166     my $op = shift;
3167     return ($op->name eq "null" and class($op) eq "UNOP"
3168             and $op->first->name =~ /^(and|cond_expr)$/
3169             and is_scope($op->first->first->sibling));
3170 }
3171
3172 sub pp_cond_expr {
3173     my $self = shift;
3174     my($op, $cx) = @_;
3175     my $cond = $op->first;
3176     my $true = $cond->sibling;
3177     my $false = $true->sibling;
3178     my $cuddle = $self->{'cuddle'};
3179     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3180             (is_scope($false) || is_ifelse_cont($false))
3181             and $self->{'expand'} < 7) {
3182         $cond = $self->deparse($cond, 8);
3183         $true = $self->deparse($true, 6);
3184         $false = $self->deparse($false, 8);
3185         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3186     }
3187
3188     $cond = $self->deparse($cond, 1);
3189     $true = $self->deparse($true, 0);
3190     my $head = $self->keyword("if") . " ($cond) {\n\t$true\n\b}";
3191     my @elsifs;
3192     my $elsif;
3193     while (!null($false) and is_ifelse_cont($false)) {
3194         my $newop = $false->first;
3195         my $newcond = $newop->first;
3196         my $newtrue = $newcond->sibling;
3197         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3198         if ($newcond->name eq "lineseq")
3199         {
3200             # lineseq to ensure correct line numbers in elsif()
3201             # Bug #37302 fixed by change #33710.
3202             $newcond = $newcond->first->sibling;
3203         }
3204         $newcond = $self->deparse($newcond, 1);
3205         $newtrue = $self->deparse($newtrue, 0);
3206         $elsif ||= $self->keyword("elsif");
3207         push @elsifs, "$elsif ($newcond) {\n\t$newtrue\n\b}";
3208     }
3209     if (!null($false)) {
3210         $false = $cuddle . $self->keyword("else") . " {\n\t" .
3211           $self->deparse($false, 0) . "\n\b}\cK";
3212     } else {
3213         $false = "\cK";
3214     }
3215     return $head . join($cuddle, "", @elsifs) . $false;
3216 }
3217
3218 sub pp_once {
3219     my ($self, $op, $cx) = @_;
3220     my $cond = $op->first;
3221     my $true = $cond->sibling;
3222
3223     my $ret = $self->deparse($true, $cx);
3224     $ret =~ s/^(\(?)\$/$1 . $self->keyword("state") . ' $'/e;
3225     $ret;
3226 }
3227
3228 sub loop_common {
3229     my $self = shift;
3230     my($op, $cx, $init) = @_;
3231     my $enter = $op->first;
3232     my $kid = $enter->sibling;
3233     local(@$self{qw'curstash warnings hints hinthash'})
3234                 = @$self{qw'curstash warnings hints hinthash'};
3235     my $head = "";
3236     my $bare = 0;
3237     my $body;
3238     my $cond = undef;
3239     my $name;
3240     if ($kid->name eq "lineseq") { # bare or infinite loop
3241         if ($kid->last->name eq "unstack") { # infinite
3242             $head = "while (1) "; # Can't use for(;;) if there's a continue
3243             $cond = "";
3244         } else {
3245             $bare = 1;
3246         }
3247         $body = $kid;
3248     } elsif ($enter->name eq "enteriter") { # foreach
3249         my $ary = $enter->first->sibling; # first was pushmark
3250         my $var = $ary->sibling;
3251         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3252             # "reverse" was optimised away
3253             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3254         } elsif ($enter->flags & OPf_STACKED
3255             and not null $ary->first->sibling->sibling)
3256         {
3257             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3258               $self->deparse($ary->first->sibling->sibling, 9);
3259         } else {
3260             $ary = $self->deparse($ary, 1);
3261         }
3262         if (null $var) {
3263             $var = $self->pp_padsv($enter, 1, 1);
3264         } elsif ($var->name eq "rv2gv") {
3265             $var = $self->pp_rv2sv($var, 1);
3266             if ($enter->private & OPpOUR_INTRO) {
3267                 # our declarations don't have package names
3268                 $var =~ s/^(.).*::/$1/;
3269                 $var = "our $var";
3270             }
3271         } elsif ($var->name eq "gv") {
3272             $var = "\$" . $self->deparse($var, 1);
3273         } else {
3274             $var = $self->deparse($var, 1);
3275         }
3276         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3277         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3278             confess unless $var eq '$_';
3279             $body = $body->first;
3280             return $self->deparse($body, 2) . " "
3281                  . $self->keyword("foreach") . " ($ary)";
3282         }
3283         $head = "foreach $var ($ary) ";
3284     } elsif ($kid->name eq "null") { # while/until
3285         $kid = $kid->first;
3286         $name = {"and" => "while", "or" => "until"}->{$kid->name};
3287         $cond = $kid->first;
3288         $body = $kid->first->sibling;
3289     } elsif ($kid->name eq "stub") { # bare and empty
3290         return "{;}"; # {} could be a hashref
3291     }
3292     # If there isn't a continue block, then the next pointer for the loop
3293     # will point to the unstack, which is kid's last child, except
3294     # in a bare loop, when it will point to the leaveloop. When neither of
3295     # these conditions hold, then the second-to-last child is the continue
3296     # block (or the last in a bare loop).
3297     my $cont_start = $enter->nextop;
3298     my $cont;
3299     my $precond;
3300     my $postcond;
3301     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3302         if ($bare) {
3303             $cont = $body->last;
3304         } else {
3305             $cont = $body->first;
3306             while (!null($cont->sibling->sibling)) {
3307                 $cont = $cont->sibling;
3308             }
3309         }
3310         my $state = $body->first;
3311         my $cuddle = $self->{'cuddle'};
3312         my @states;
3313         for (; $$state != $$cont; $state = $state->sibling) {
3314             push @states, $state;
3315         }
3316         $body = $self->lineseq(undef, 0, @states);
3317         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3318             $precond = "for ($init; ";
3319             $postcond = "; " . $self->deparse($cont, 1) .") ";
3320             $cont = "\cK";
3321         } else {
3322             $cont = $cuddle . "continue {\n\t" .
3323               $self->deparse($cont, 0) . "\n\b}\cK";
3324         }
3325     } else {
3326         return "" if !defined $body;
3327         if (length $init) {
3328             $precond = "for ($init; ";
3329             $postcond = ";) ";
3330         }
3331         $cont = "\cK";
3332         $body = $self->deparse($body, 0);
3333     }
3334     if ($precond) { # for(;;)
3335         $cond &&= $name eq 'until'
3336                     ? listop($self, undef, 1, "not", $cond->first)
3337                     : $self->deparse($cond, 1);
3338         $head = "$precond$cond$postcond";
3339     }
3340     if ($name && !$head) {
3341         ref $cond and $cond = $self->deparse($cond, 1);
3342         $head = "$name ($cond) ";
3343     }
3344     $head =~ s/^(for(?:each)?|while|until)/$self->keyword($1)/e;
3345     $body =~ s/;?$/;\n/;
3346
3347     return $head . "{\n\t" . $body . "\b}" . $cont;
3348 }
3349
3350 sub pp_leaveloop { shift->loop_common(@_, "") }
3351
3352 sub for_loop {
3353     my $self = shift;
3354     my($op, $cx) = @_;
3355     my $init = $self->deparse($op, 1);
3356     my $s = $op->sibling;
3357     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3358     return $self->loop_common($ll, $cx, $init);
3359 }
3360
3361 sub pp_leavetry {
3362     my $self = shift;
3363     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3364 }
3365
3366 sub _op_is_or_was {
3367   my ($op, $expect_type) = @_;
3368   my $type = $op->type;
3369   return($type == $expect_type
3370          || ($type == OP_NULL && $op->targ == $expect_type));
3371 }
3372
3373 sub pp_null {
3374     my $self = shift;
3375     my($op, $cx) = @_;
3376     if (class($op) eq "OP") {
3377         # old value is lost
3378         return $self->{'ex_const'} if $op->targ == OP_CONST;
3379     } elsif ($op->first->name eq 'pushmark'
3380              or $op->first->name eq 'null'
3381                 && $op->first->targ == OP_PUSHMARK
3382                 && _op_is_or_was($op, OP_LIST)) {
3383         return $self->pp_list($op, $cx);
3384     } elsif ($op->first->name eq "enter") {
3385         return $self->pp_leave($op, $cx);
3386     } elsif ($op->first->name eq "leave") {
3387         return $self->pp_leave($op->first, $cx);
3388     } elsif ($op->first->name eq "scope") {
3389         return $self->pp_scope($op->first, $cx);
3390     } elsif ($op->targ == OP_STRINGIFY) {
3391         return $self->dquote($op, $cx);
3392     } elsif ($op->targ == OP_GLOB) {
3393         return $self->pp_glob(
3394                  $op->first    # entersub
3395                     ->first    # ex-list
3396                     ->first    # pushmark
3397                     ->sibling, # glob
3398                  $cx
3399                );
3400     } elsif (!null($op->first->sibling) and
3401              $op->first->sibling->name eq "readline" and
3402              $op->first->sibling->flags & OPf_STACKED) {
3403         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
3404                                    . $self->deparse($op->first->sibling, 7),
3405                                    $cx, 7);
3406     } elsif (!null($op->first->sibling) and
3407              $op->first->sibling->name eq "trans" and
3408              $op->first->sibling->flags & OPf_STACKED) {
3409         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
3410                                    . $self->deparse($op->first->sibling, 20),
3411                                    $cx, 20);
3412     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
3413         return ($self->lex_in_scope("&do") ? "CORE::do" : "do")
3414              . " {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
3415     } elsif (!null($op->first->sibling) and
3416              $op->first->sibling->name eq "null" and
3417              class($op->first->sibling) eq "UNOP" and
3418              $op->first->sibling->first->flags & OPf_STACKED and
3419              $op->first->sibling->first->name eq "rcatline") {
3420         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
3421                                    . $self->deparse($op->first->sibling, 18),
3422                                    $cx, 18);
3423     } else {
3424         return $self->deparse($op->first, $cx);
3425     }
3426 }
3427
3428 sub padname {
3429     my $self = shift;
3430     my $targ = shift;
3431     return $self->padname_sv($targ)->PVX;
3432 }
3433
3434 sub padany {
3435     my $self = shift;
3436     my $op = shift;
3437     return substr($self->padname($op->targ), 1); # skip $/@/%
3438 }
3439
3440 sub pp_padsv {
3441     my $self = shift;
3442     my($op, $cx, $forbid_parens) = @_;
3443     my $targ = $op->targ;
3444     return $self->maybe_my($op, $cx, $self->padname($targ),
3445                            $self->padname_sv($targ),
3446                            $forbid_parens);
3447 }
3448
3449 sub pp_padav { pp_padsv(@_) }
3450 sub pp_padhv { pp_padsv(@_) }
3451
3452 sub gv_or_padgv {
3453     my $self = shift;
3454     my $op = shift;
3455     if (class($op) eq "PADOP") {
3456         return $self->padval($op->padix);
3457     } else { # class($op) eq "SVOP"
3458         return $op->gv;
3459     }
3460 }
3461
3462 sub pp_gvsv {
3463     my $self = shift;
3464     my($op, $cx) = @_;
3465     my $gv = $self->gv_or_padgv($op);
3466     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
3467                                  $self->gv_name($gv), $cx));
3468 }
3469
3470 sub pp_gv {
3471     my $self = shift;
3472     my($op, $cx) = @_;
3473     my $gv = $self->gv_or_padgv($op);
3474     return $self->gv_name($gv);
3475 }
3476
3477 sub pp_aelemfast_lex {
3478     my $self = shift;
3479     my($op, $cx) = @_;
3480     my $name = $self->padname($op->targ);
3481     $name =~ s/^@/\$/;
3482     my $i = $op->private;
3483     $i -= 256 if $i > 127;
3484     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
3485 }
3486
3487 sub pp_aelemfast {
3488     my $self = shift;
3489     my($op, $cx) = @_;
3490     # optimised PADAV, pre 5.15
3491     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
3492
3493     my $gv = $self->gv_or_padgv($op);
3494     my($name,$quoted) = $self->stash_variable_name('@',$gv);
3495     $name = $quoted ? "$name->" : '$' . $name;
3496     my $i = $op->private;
3497     $i -= 256 if $i > 127;
3498     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
3499 }
3500
3501 sub rv2x {
3502     my $self = shift;
3503     my($op, $cx, $type) = @_;
3504
3505     if (class($op) eq 'NULL' || !$op->can("first")) {
3506         carp("Unexpected op in pp_rv2x");
3507         return 'XXX';
3508     }
3509     my $kid = $op->first;
3510     if ($kid->name eq "gv") {
3511         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
3512     } elsif (is_scalar $kid) {
3513         my $str = $self->deparse($kid, 0);
3514         if ($str =~ /^\$([^\w\d])\z/) {
3515             # "$$+" isn't a legal way to write the scalar dereference
3516             # of $+, since the lexer can't tell you aren't trying to
3517             # do something like "$$ + 1" to get one more than your
3518             # PID. Either "${$+}" or "$${+}" are workable
3519             # disambiguations, but if the programmer did the former,
3520             # they'd be in the "else" clause below rather than here.
3521             # It's not clear if this should somehow be unified with
3522             # the code in dq and re_dq that also adds lexer
3523             # disambiguation braces.
3524             $str = '$' . "{$1}"; #'
3525         }
3526         return $type . $str;
3527     } else {
3528         return $type . "{" . $self->deparse($kid, 0) . "}";
3529     }
3530 }
3531
3532 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3533 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3534 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3535
3536 # skip rv2av
3537 sub pp_av2arylen {
3538     my $self = shift;
3539     my($op, $cx) = @_;
3540     if ($op->first->name eq "padav") {
3541         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3542     } else {
3543         return $self->maybe_local($op, $cx,
3544                                   $self->rv2x($op->first, $cx, '$#'));
3545     }
3546 }
3547
3548 # skip down to the old, ex-rv2cv
3549 sub pp_rv2cv {
3550     my ($self, $op, $cx) = @_;
3551     if (!null($op->first) && $op->first->name eq 'null' &&
3552         $op->first->targ == OP_LIST)
3553     {
3554         return $self->rv2x($op->first->first->sibling, $cx, "&")
3555     }
3556     else {
3557         return $self->rv2x($op, $cx, "")
3558     }
3559 }
3560
3561 sub list_const {
3562     my $self = shift;
3563     my($cx, @list) = @_;
3564     my @a = map $self->const($_, 6), @list;
3565     if (@a == 0) {
3566         return "()";
3567     } elsif (@a == 1) {
3568         return $a[0];
3569     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3570         # collapse (-1,0,1,2) into (-1..2)
3571         my ($s, $e) = @a[0,-1];
3572         my $i = $s;
3573         return $self->maybe_parens("$s..$e", $cx, 9)
3574           unless grep $i++ != $_, @a;
3575     }
3576     return $self->maybe_parens(join(", ", @a), $cx, 6);
3577 }
3578
3579 sub pp_rv2av {
3580     my $self = shift;
3581     my($op, $cx) = @_;
3582     my $kid = $op->first;
3583     if ($kid->name eq "const") { # constant list
3584         my $av = $self->const_sv($kid);
3585         return $self->list_const($cx, $av->ARRAY);
3586     } else {
3587         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3588     }
3589  }
3590
3591 sub is_subscriptable {
3592     my $op = shift;
3593     if ($op->name =~ /^[ahg]elem/) {
3594         return 1;
3595     } elsif ($op->name eq "entersub") {
3596         my $kid = $op->first;
3597         return 0 unless null $kid->sibling;
3598         $kid = $kid->first;
3599         $kid = $kid->sibling until null $kid->sibling;
3600         return 0 if is_scope($kid);
3601         $kid = $kid->first;
3602         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
3603         return 0 if is_scalar($kid);
3604         return is_subscriptable($kid);  
3605     } else {
3606         return 0;
3607     }
3608 }
3609
3610 sub elem_or_slice_array_name
3611 {
3612     my $self = shift;
3613     my ($array, $left, $padname, $allow_arrow) = @_;
3614
3615     if ($array->name eq $padname) {
3616         return $self->padany($array);
3617     } elsif (is_scope($array)) { # ${expr}[0]
3618         return "{" . $self->deparse($array, 0) . "}";
3619     } elsif ($array->name eq "gv") {
3620         ($array, my $quoted) =
3621             $self->stash_variable_name(
3622                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
3623             );
3624         if (!$allow_arrow && $quoted) {
3625             # This cannot happen.
3626             die "Invalid variable name $array for slice";
3627         }
3628         return $quoted ? "$array->" : $array;
3629     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3630         return $self->deparse($array, 24);
3631     } else {
3632         return undef;
3633     }
3634 }
3635
3636 sub elem_or_slice_single_index
3637 {
3638     my $self = shift;
3639     my ($idx) = @_;
3640
3641     $idx = $self->deparse($idx, 1);
3642
3643     # Outer parens in an array index will confuse perl
3644     # if we're interpolating in a regular expression, i.e.
3645     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3646     #
3647     # If $self->{parens}, then an initial '(' will
3648     # definitely be paired with a final ')'. If
3649     # !$self->{parens}, the misleading parens won't
3650     # have been added in the first place.
3651     #
3652     # [You might think that we could get "(...)...(...)"
3653     # where the initial and final parens do not match
3654     # each other. But we can't, because the above would
3655     # only happen if there's an infix binop between the
3656     # two pairs of parens, and *that* means that the whole
3657     # expression would be parenthesized as well.]
3658     #
3659     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3660
3661     # Hash-element braces will autoquote a bareword inside themselves.
3662     # We need to make sure that C<$hash{warn()}> doesn't come out as
3663     # C<$hash{warn}>, which has a quite different meaning. Currently
3664     # B::Deparse will always quote strings, even if the string was a
3665     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3666     # for constant strings.) So we can cheat slightly here - if we see
3667     # a bareword, we know that it is supposed to be a function call.
3668     #
3669     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3670
3671     return $idx;
3672 }
3673
3674 sub elem {
3675     my $self = shift;
3676     my ($op, $cx, $left, $right, $padname) = @_;
3677     my($array, $idx) = ($op->first, $op->first->sibling);
3678
3679     $idx = $self->elem_or_slice_single_index($idx);
3680
3681     unless ($array->name eq $padname) { # Maybe this has been fixed     
3682         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3683     }
3684     if (my $array_name=$self->elem_or_slice_array_name
3685             ($array, $left, $padname, 1)) {
3686         return ($array_name =~ /->\z/
3687                     ? $array_name
3688                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
3689               . $left . $idx . $right;
3690     } else {
3691         # $x[20][3]{hi} or expr->[20]
3692         my $arrow = is_subscriptable($array) ? "" : "->";
3693         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3694     }
3695
3696 }
3697
3698 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3699 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3700
3701 sub pp_gelem {
3702     my $self = shift;
3703     my($op, $cx) = @_;
3704     my($glob, $part) = ($op->first, $op->last);
3705     $glob = $glob->first; # skip rv2gv
3706     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3707     my $scope = is_scope($glob);
3708     $glob = $self->deparse($glob, 0);
3709     $part = $self->deparse($part, 1);
3710     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3711 }
3712
3713 sub slice {
3714     my $self = shift;
3715     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3716     my $last;
3717     my(@elems, $kid, $array, $list);
3718     if (class($op) eq "LISTOP") {
3719         $last = $op->last;
3720     } else { # ex-hslice inside delete()
3721         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3722         $last = $kid;
3723     }
3724     $array = $last;
3725     $array = $array->first
3726         if $array->name eq $regname or $array->name eq "null";
3727     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3728     $kid = $op->first->sibling; # skip pushmark
3729     if ($kid->name eq "list") {
3730         $kid = $kid->first->sibling; # skip list, pushmark
3731         for (; !null $kid; $kid = $kid->sibling) {
3732             push @elems, $self->deparse($kid, 6);
3733         }
3734         $list = join(", ", @elems);
3735     } else {
3736         $list = $self->elem_or_slice_single_index($kid);
3737     }
3738     my $lead = '@';
3739     $lead = '%' if $op->name =~ /^kv/i;
3740     return $lead . $array . $left . $list . $right;
3741 }
3742
3743 sub pp_aslice   { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3744 sub pp_kvaslice {                 slice(@_, "[", "]", "rv2av", "padav")  }
3745 sub pp_hslice   { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3746 sub pp_kvhslice {                 slice(@_, "{", "}", "rv2hv", "padhv")  }
3747
3748 sub pp_lslice {
3749     my $self = shift;
3750     my($op, $cx) = @_;
3751     my $idx = $op->first;
3752     my $list = $op->last;
3753     my(@elems, $kid);
3754     $list = $self->deparse($list, 1);
3755     $idx = $self->deparse($idx, 1);
3756     return "($list)" . "[$idx]";
3757 }
3758
3759 sub want_scalar {
3760     my $op = shift;
3761     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3762 }
3763
3764 sub want_list {
3765     my $op = shift;
3766     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3767 }
3768
3769 sub _method {
3770     my $self = shift;
3771     my($op, $cx) = @_;
3772     my $kid = $op->first->sibling; # skip pushmark
3773     my($meth, $obj, @exprs);
3774     if ($kid->name eq "list" and want_list $kid) {
3775         # When an indirect object isn't a bareword but the args are in
3776         # parens, the parens aren't part of the method syntax (the LLAFR
3777         # doesn't apply), but they make a list with OPf_PARENS set that
3778         # doesn't get flattened by the append_elem that adds the method,
3779         # making a (object, arg1, arg2, ...) list where the object
3780         # usually is. This can be distinguished from
3781         # '($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3782         # object) because in the later the list is in scalar context
3783         # as the left side of -> always is, while in the former
3784         # the list is in list context as method arguments always are.
3785         # (Good thing there aren't method prototypes!)
3786         $meth = $kid->sibling;
3787         $kid = $kid->first->sibling; # skip pushmark
3788         $obj = $kid;
3789         $kid = $kid->sibling;
3790         for (; not null $kid; $kid = $kid->sibling) {
3791             push @exprs, $kid;
3792         }
3793     } else {
3794         $obj = $kid;
3795         $kid = $kid->sibling;
3796         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3797               $kid = $kid->sibling) {
3798             push @exprs, $kid
3799         }
3800         $meth = $kid;
3801     }
3802
3803     if ($meth->name eq "method_named") {
3804         $meth = $self->meth_sv($meth)->PV;
3805     } else {
3806         $meth = $meth->first;
3807         if ($meth->name eq "const") {
3808             # As of 5.005_58, this case is probably obsoleted by the
3809             # method_named case above
3810             $meth = $self->const_sv($meth)->PV; # needs to be bare
3811         }
3812     }
3813
3814     return { method => $meth, variable_method => ref($meth),
3815              object => $obj, args => \@exprs  },
3816            $cx;
3817 }
3818
3819 # compat function only
3820 sub method {
3821     my $self = shift;
3822     my $info = $self->_method(@_);
3823     return $self->e_method( $self->_method(@_) );
3824 }
3825
3826 sub e_method {
3827     my ($self, $info, $cx) = @_;
3828     my $obj = $self->deparse($info->{object}, 24);
3829
3830     my $meth = $info->{method};
3831     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3832     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3833     if ($info->{object}->name eq 'scope' && want_list $info->{object}) {
3834         # method { $object }
3835         # This must be deparsed this way to preserve list context
3836         # of $object.
3837         my $need_paren = $cx >= 6;
3838         return '(' x $need_paren
3839              . $meth . substr($obj,2) # chop off the "do"
3840              . " $args"
3841              . ')' x $need_paren;
3842     }
3843     my $kid = $obj . "->" . $meth;
3844     if (length $args) {
3845         return $kid . "(" . $args . ")"; # parens mandatory
3846     } else {
3847         return $kid;
3848     }
3849 }
3850
3851 # returns "&" if the prototype doesn't match the args,
3852 # or ("", $args_after_prototype_demunging) if it does.
3853 sub check_proto {
3854     my $self = shift;
3855     return "&" if $self->{'noproto'};
3856     my($proto, @args) = @_;
3857     my($arg, $real);
3858     my $doneok = 0;
3859     my @reals;
3860     # An unbackslashed @ or % gobbles up the rest of the args
3861     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3862     $proto =~ s/^\s*//;
3863     while ($proto) {
3864         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)\s*//;
3865         my $chr = $1;
3866         if ($chr eq "") {
3867             return "&" if @args;
3868         } elsif ($chr eq ";") {
3869             $doneok = 1;
3870         } elsif ($chr eq "@" or $chr eq "%") {
3871             push @reals, map($self->deparse($_, 6), @args);
3872             @args = ();
3873         } else {
3874             $arg = shift @args;
3875             last unless $arg;
3876             if ($chr eq "\$" || $chr eq "_") {
3877                 if (want_scalar $arg) {
3878                     push @reals, $self->deparse($arg, 6);
3879                 } else {
3880                     return "&";
3881                 }
3882             } elsif ($chr eq "&") {
3883                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3884                     push @reals, $self->deparse($arg, 6);
3885                 } else {
3886                     return "&";
3887                 }
3888             } elsif ($chr eq "*") {
3889                 if ($arg->name =~ /^s?refgen$/
3890                     and $arg->first->first->name eq "rv2gv")
3891                   {
3892                       $real = $arg->first->first; # skip refgen, null
3893                       if ($real->first->name eq "gv") {
3894                           push @reals, $self->deparse($real, 6);
3895                       } else {
3896                           push @reals, $self->deparse($real->first, 6);
3897                       }
3898                   } else {
3899                       return "&";
3900                   }
3901             } elsif (substr($chr, 0, 1) eq "\\") {
3902                 $chr =~ tr/\\[]//d;
3903                 if ($arg->name =~ /^s?refgen$/ and
3904                     !null($real = $arg->first) and
3905                     ($chr =~ /\$/ && is_scalar($real->first)
3906                      or ($chr =~ /@/
3907                          && class($real->first->sibling) ne 'NULL'
3908                          && $real->first->sibling->name
3909                          =~ /^(rv2|pad)av$/)
3910                      or ($chr =~ /%/
3911                          && class($real->first->sibling) ne 'NULL'
3912                          && $real->first->sibling->name
3913                          =~ /^(rv2|pad)hv$/)
3914                      #or ($chr =~ /&/ # This doesn't work
3915                      #   && $real->first->name eq "rv2cv")
3916                      or ($chr =~ /\*/
3917                          && $real->first->name eq "rv2gv")))
3918                   {
3919                       push @reals, $self->deparse($real, 6);
3920                   } else {
3921                       return "&";
3922                   }
3923             }
3924        }
3925     }
3926     return "&" if $proto and !$doneok; # too few args and no ';'
3927     return "&" if @args;               # too many args
3928     return ("", join ", ", @reals);
3929 }
3930
3931 sub pp_entersub {
3932     my $self = shift;
3933     my($op, $cx) = @_;
3934     return $self->e_method($self->_method($op, $cx))
3935         unless null $op->first->sibling;
3936     my $prefix = "";
3937     my $amper = "";
3938     my($kid, @exprs);
3939     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3940         $prefix = "do ";
3941     } elsif ($op->private & OPpENTERSUB_AMPER) {
3942         $amper = "&";
3943     }
3944     $kid = $op->first;
3945     $kid = $kid->first->sibling; # skip ex-list, pushmark
3946     for (; not null $kid->sibling; $kid = $kid->sibling) {
3947         push @exprs, $kid;
3948     }
3949     my $simple = 0;
3950     my $proto = undef;
3951     if (is_scope($kid)) {
3952         $amper = "&";
3953         $kid = "{" . $self->deparse($kid, 0) . "}";
3954     } elsif ($kid->first->name eq "gv") {
3955         my $gv = $self->gv_or_padgv($kid->first);
3956         my $cv;
3957         if (class($gv) eq 'GV' && class($cv = $gv->CV) ne "SPECIAL"
3958          || $gv->FLAGS & SVf_ROK && class($cv = $gv->RV) eq 'CV') {
3959             $proto = $cv->PV if $cv->FLAGS & SVf_POK;
3960         }
3961         $simple = 1; # only calls of named functions can be prototyped
3962         $kid = $self->deparse($kid, 24);
3963         if (!$amper) {
3964             if ($kid eq 'main::') {
3965                 $kid = '::';
3966             }
3967             else {
3968               if ($kid !~ /::/ && $kid ne 'x') {
3969                 # Fully qualify any sub name that is also a keyword.  While
3970                 # we could check the import flag, we cannot guarantee that
3971                 # the code deparsed so far would set that flag, so we qual-
3972                 # ify the names regardless of importation.
3973                 my $fq;
3974                 if (exists $feature_keywords{$kid}) {
3975                     $fq++ if $self->feature_enabled($kid);
3976                 } elsif (do { local $@; local $SIG{__DIE__};
3977                               eval { () = prototype "CORE::$kid"; 1 } }) {
3978                     $fq++
3979                 }
3980                 $fq and substr $kid, 0, 0, = $self->{'curstash'}.'::';
3981               }
3982               if ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3983                 $kid = single_delim("q", "'", $kid, $self) . '->';
3984               }
3985             }
3986         }
3987     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3988         $amper = "&";
3989         $kid = $self->deparse($kid, 24);
3990     } else {
3991         $prefix = "";
3992         my $arrow = is_subscriptable($kid->first) || $kid->first->name eq "padcv" ? "" : "->";
3993         $kid = $self->deparse($kid, 24) . $arrow;
3994     }
3995
3996     # Doesn't matter how many prototypes there are, if
3997     # they haven't happened yet!
3998     my $declared;
3999     {
4000         no strict 'refs';
4001         no warnings 'uninitialized';
4002         $declared = exists $self->{'subs_declared'}{$kid}
4003             || (
4004                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
4005                  && !exists
4006                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
4007                  && defined prototype $self->{'curstash'}."::".$kid
4008                );
4009         if (!$declared && defined($proto)) {
4010             # Avoid "too early to check prototype" warning
4011             ($amper, $proto) = ('&');
4012         }
4013     }
4014
4015     my $args;
4016     if ($declared and defined $proto and not $amper) {
4017         ($amper, $args) = $self->check_proto($proto, @exprs);
4018         if ($amper eq "&") {
4019             $args = join(", ", map($self->deparse($_, 6), @exprs));
4020         }
4021     } else {
4022         $args = join(", ", map($self->deparse($_, 6), @exprs));
4023     }
4024     if ($prefix or $amper) {
4025         if ($kid eq '&') { $kid = "{$kid}" } # &{&} cannot be written as &&
4026         if ($op->flags & OPf_STACKED) {
4027             return $prefix . $amper . $kid . "(" . $args . ")";
4028         } else {
4029             return $prefix . $amper. $kid;
4030         }
4031     } else {
4032         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
4033         # so it must have been translated from a keyword call. Translate
4034         # it back.
4035         $kid =~ s/^CORE::GLOBAL:://;
4036
4037         my $dproto = defined($proto) ? $proto : "undefined";
4038         if (!$declared) {
4039             return "$kid(" . $args . ")";
4040         } elsif ($dproto =~ /^\s*\z/) {
4041             return $kid;
4042         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
4043             # is_scalar is an excessively conservative test here:
4044             # really, we should be comparing to the precedence of the
4045             # top operator of $exprs[0] (ala unop()), but that would
4046             # take some major code restructuring to do right.
4047             return $self->maybe_parens_func($kid, $args, $cx, 16);
4048         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
4049             return $self->maybe_parens_func($kid, $args, $cx, 5);
4050         } else {
4051             return "$kid(" . $args . ")";
4052         }
4053     }
4054 }
4055
4056 sub pp_enterwrite { unop(@_, "write") }
4057
4058 # escape things that cause interpolation in double quotes,
4059 # but not character escapes
4060 sub uninterp {
4061     my($str) = @_;
4062     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
4063     return $str;
4064 }
4065
4066 {
4067 my $bal;
4068 BEGIN {
4069     use re "eval";
4070     # Matches any string which is balanced with respect to {braces}
4071     $bal = qr(
4072       (?:
4073         [^\\{}]
4074       | \\\\
4075       | \\[{}]
4076       | \{(??{$bal})\}
4077       )*
4078     )x;
4079 }
4080
4081 # the same, but treat $|, $), $( and $ at the end of the string differently
4082 sub re_uninterp {
4083     my($str) = @_;
4084
4085     $str =~ s/
4086           ( ^|\G                  # $1
4087           | [^\\]
4088           )
4089
4090           (                       # $2
4091             (?:\\\\)*
4092           )
4093
4094           (                       # $3
4095             (\(\?\??\{$bal\}\))   # $4
4096           | [\$\@]
4097             (?!\||\)|\(|$)
4098           | \\[uUlLQE]
4099           )
4100
4101         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
4102
4103     return $str;
4104 }
4105
4106 # This is for regular expressions with the /x modifier
4107 # We have to leave comments unmangled.
4108 sub re_uninterp_extended {
4109     my($str) = @_;
4110
4111     $str =~ s/
4112           ( ^|\G                  # $1
4113           | [^\\]
4114           )
4115
4116           (                       # $2
4117             (?:\\\\)*
4118           )
4119
4120           (                       # $3
4121             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
4122             | \#[^\n]*            #     (skip over comments)
4123             )
4124           | [\$\@]
4125             (?!\||\)|\(|$|\s)
4126           | \\[uUlLQE]
4127           )
4128
4129         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
4130
4131     return $str;
4132 }
4133 }
4134
4135 my %unctrl = # portable to EBCDIC
4136     (
4137      "\c@" => '\c@',    # unused
4138      "\cA" => '\cA',
4139      "\cB" => '\cB',
4140      "\cC" => '\cC',
4141      "\cD" => '\cD',
4142      "\cE" => '\cE',
4143      "\cF" => '\cF',
4144      "\cG" => '\cG',
4145      "\cH" => '\cH',
4146      "\cI" => '\cI',
4147      "\cJ" => '\cJ',
4148      "\cK" => '\cK',
4149      "\cL" => '\cL',
4150      "\cM" => '\cM',
4151      "\cN" => '\cN',
4152      "\cO" => '\cO',
4153      "\cP" => '\cP',
4154      "\cQ" => '\cQ',
4155      "\cR" => '\cR',
4156      "\cS" => '\cS',
4157      "\cT" => '\cT',
4158      "\cU" => '\cU',
4159      "\cV" => '\cV',
4160      "\cW" => '\cW',
4161      "\cX" => '\cX',
4162      "\cY" => '\cY',
4163      "\cZ" => '\cZ',
4164      "\c[" => '\c[',    # unused
4165      "\c\\" => '\c\\',  # unused
4166      "\c]" => '\c]',    # unused
4167      "\c_" => '\c_',    # unused
4168     );
4169
4170 # character escapes, but not delimiters that might need to be escaped
4171 sub escape_str { # ASCII, UTF8
4172     my($str) = @_;
4173     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4174     $str =~ s/\a/\\a/g;
4175 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
4176     $str =~ s/\t/\\t/g;
4177     $str =~ s/\n/\\n/g;
4178     $str =~ s/\e/\\e/g;
4179     $str =~ s/\f/\\f/g;
4180     $str =~ s/\r/\\r/g;
4181     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
4182     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
4183     return $str;
4184 }
4185
4186 # For regexes with the /x modifier.
4187 # Leave whitespace unmangled.
4188 sub escape_extended_re {
4189     my($str) = @_;
4190     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4191     $str =~ s/([[:^print:]])/
4192         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
4193     $str =~ s/\n/\n\f/g;
4194     return $str;
4195 }
4196
4197 # Don't do this for regexen
4198 sub unback {
4199     my($str) = @_;
4200     $str =~ s/\\/\\\\/g;
4201     return $str;
4202 }
4203
4204 # Remove backslashes which precede literal control characters,
4205 # to avoid creating ambiguity when we escape the latter.
4206 sub re_unback {
4207     my($str) = @_;
4208
4209     # the insane complexity here is due to the behaviour of "\c\"
4210     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
4211     return $str;
4212 }
4213
4214 sub balanced_delim {
4215     my($str) = @_;
4216     my @str = split //, $str;
4217     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
4218     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
4219         ($open, $close) = @$ar;
4220         $fail = 0; $cnt = 0; $last_bs = 0;
4221         for $c (@str) {
4222             if ($c eq $open) {
4223                 $fail = 1 if $last_bs;
4224                 $cnt++;
4225             } elsif ($c eq $close) {
4226                 $fail = 1 if $last_bs;
4227                 $cnt--;
4228                 if ($cnt < 0) {
4229                     # qq()() isn't ")("
4230                     $fail = 1;
4231                     last;
4232                 }
4233             }
4234             $last_bs = $c eq '\\';
4235         }
4236         $fail = 1 if $cnt != 0;
4237         return ($open, "$open$str$close") if not $fail;
4238     }
4239     return ("", $str);
4240 }
4241
4242 sub single_delim {
4243     my($q, $default, $str, $self) = @_;
4244     return "$default$str$default" if $default and index($str, $default) == -1;
4245     my $coreq = $self->keyword($q); # maybe CORE::q
4246     if ($q ne 'qr') {
4247         (my $succeed, $str) = balanced_delim($str);
4248         return "$coreq$str" if $succeed;
4249     }
4250     for my $delim ('/', '"', '#') {
4251         return "$coreq$delim" . $str . $delim if index($str, $delim) == -1;
4252     }
4253     if ($default) {
4254         $str =~ s/$default/\\$default/g;
4255         return "$default$str$default";
4256     } else {
4257         $str =~ s[/][\\/]g;
4258         return "$coreq/$str/";
4259     }
4260 }
4261
4262 my $max_prec;
4263 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
4264
4265 # Split a floating point number into an integer mantissa and a binary
4266 # exponent. Assumes you've already made sure the number isn't zero or
4267 # some weird infinity or NaN.
4268 sub split_float {
4269     my($f) = @_;
4270     my $exponent = 0;
4271     if ($f == int($f)) {
4272         while ($f % 2 == 0) {
4273             $f /= 2;
4274             $exponent++;
4275         }
4276     } else {
4277         while ($f != int($f)) {
4278             $f *= 2;
4279             $exponent--;
4280         }
4281     }
4282     my $mantissa = sprintf("%.0f", $f);
4283     return ($mantissa, $exponent);
4284 }
4285
4286 sub const {
4287     my $self = shift;
4288     my($sv, $cx) = @_;
4289     if ($self->{'use_dumper'}) {
4290         return $self->const_dumper($sv, $cx);
4291     }
4292     if (class($sv) eq "SPECIAL") {
4293         # sv_undef, sv_yes, sv_no
4294         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
4295     }
4296     if (class($sv) eq "NULL") {
4297        return 'undef';
4298     }
4299     # convert a version object into the "v1.2.3" string in its V magic
4300     if ($sv->FLAGS & SVs_RMG) {
4301         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4302             return $mg->PTR if $mg->TYPE eq 'V';
4303         }
4304     }
4305
4306     if ($sv->FLAGS & SVf_IOK) {
4307         my $str = $sv->int_value;
4308         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
4309         return $str;
4310     } elsif ($sv->FLAGS & SVf_NOK) {
4311         my $nv = $sv->NV;
4312         if ($nv == 0) {
4313             if (pack("F", $nv) eq pack("F", 0)) {
4314                 # positive zero
4315                 return "0";
4316             } else {
4317                 # negative zero
4318                 return $self->maybe_parens("-.0", $cx, 21);
4319             }
4320         } elsif (1/$nv == 0) {
4321             if ($nv > 0) {
4322                 # positive infinity
4323                 return $self->maybe_parens("9**9**9", $cx, 22);
4324             } else {
4325                 # negative infinity
4326                 return $self->maybe_parens("-9**9**9", $cx, 21);
4327             }
4328         } elsif ($nv != $nv) {
4329             # NaN
4330             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
4331                 # the normal kind
4332                 return "sin(9**9**9)";
4333             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
4334                 # the inverted kind
4335                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
4336             } else {
4337                 # some other kind
4338                 my $hex = unpack("h*", pack("F", $nv));
4339                 return qq'unpack("F", pack("h*", "$hex"))';
4340             }
4341         }
4342         # first, try the default stringification
4343         my $str = "$nv";
4344         if ($str != $nv) {
4345             # failing that, try using more precision
4346             $str = sprintf("%.${max_prec}g", $nv);
4347 #           if (pack("F", $str) ne pack("F", $nv)) {
4348             if ($str != $nv) {
4349                 # not representable in decimal with whatever sprintf()
4350                 # and atof() Perl is using here.
4351                 my($mant, $exp) = split_float($nv);
4352                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
4353             }
4354         }
4355         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
4356         return $str;
4357     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
4358         my $ref = $sv->RV;
4359         if (class($ref) eq "AV") {
4360             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
4361         } elsif (class($ref) eq "HV") {
4362             my %hash = $ref->ARRAY;
4363             my @elts;
4364             for my $k (sort keys %hash) {
4365                 push @elts, "$k => " . $self->const($hash{$k}, 6);
4366             }
4367             return "{" . join(", ", @elts) . "}";
4368         } elsif (class($ref) eq "CV") {
4369             BEGIN {
4370                 if ($] > 5.0150051) {
4371                     require overloading;
4372                     unimport overloading;
4373                 }
4374             }
4375             if ($] > 5.0150051 && $self->{curcv} &&
4376                  $self->{curcv}->object_2svref == $ref->object_2svref) {
4377                 return $self->keyword("__SUB__");
4378             }
4379             return "sub " . $self->deparse_sub($ref);
4380         }
4381         if ($ref->FLAGS & SVs_SMG) {
4382             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4383                 if ($mg->TYPE eq 'r') {
4384                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
4385                     return single_delim("qr", "", $re, $self);
4386                 }
4387             }
4388         }
4389         
4390         my $const = $self->const($ref, 20);
4391         if ($self->{in_subst_repl} && $const =~ /^[0-9]/) {
4392             $const = "($const)";
4393         }
4394         return $self->maybe_parens("\\$const", $cx, 20);
4395     } elsif ($sv->FLAGS & SVf_POK) {
4396         my $str = $sv->PV;
4397         if ($str =~ /[[:^print:]]/) {
4398             return single_delim("qq", '"',
4399                                  uninterp(escape_str unback $str), $self);
4400         } else {
4401             return single_delim("q", "'", unback($str), $self);
4402         }
4403     } else {
4404         return "undef";
4405     }
4406 }
4407
4408 sub const_dumper {
4409     my $self = shift;
4410     my($sv, $cx) = @_;
4411     my $ref = $sv->object_2svref();
4412     my $dumper = Data::Dumper->new([$$ref], ['$v']);
4413     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
4414     my $str = $dumper->Dump();
4415     if ($str =~ /^\$v/) {
4416         return '${my ' . $str . ' \$v}';
4417     } else {
4418         return $str;
4419     }
4420 }
4421
4422 sub const_sv {
4423     my $self = shift;
4424     my $op = shift;
4425     my $sv = $op->sv;
4426     # the constant could be in the pad (under useithreads)
4427     $sv = $self->padval($op->targ) unless $$sv;
4428     return $sv;
4429 }
4430
4431 sub meth_sv {
4432     my $self = shift;
4433     my $op = shift;
4434     my $sv = $op->meth_sv;
4435     # the constant could be in the pad (under useithreads)
4436     $sv = $self->padval($op->targ) unless $$sv;
4437     return $sv;
4438 }
4439
4440 sub pp_const {
4441     my $self = shift;
4442     my($op, $cx) = @_;
4443     if ($op->private & OPpCONST_ARYBASE) {
4444         return '$[';
4445     }
4446 #    if ($op->private & OPpCONST_BARE) { # trouble with '=>' autoquoting
4447 #       return $self->const_sv($op)->PV;
4448 #    }
4449     my $sv = $self->const_sv($op);
4450     return $self->const($sv, $cx);
4451 }
4452
4453 sub dq {
4454     my $self = shift;
4455     my $op = shift;
4456     my $type = $op->name;
4457     if ($type eq "const") {
4458         return '$[' if $op->private & OPpCONST_ARYBASE;
4459         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
4460     } elsif ($type eq "concat") {
4461         my $first = $self->dq($op->first);
4462         my $last  = $self->dq($op->last);
4463
4464         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
4465         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4466             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4467             || ($last =~ /^[:'{\[\w_]/ && #'
4468                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4469
4470         return $first . $last;
4471     } elsif ($type eq "uc") {
4472         return '\U' . $self->dq($op->first->sibling) . '\E';
4473     } elsif ($type eq "lc") {
4474         return '\L' . $self->dq($op->first->sibling) . '\E';
4475     } elsif ($type eq "ucfirst") {
4476         return '\u' . $self->dq($op->first->sibling);
4477     } elsif ($type eq "lcfirst") {
4478         return '\l' . $self->dq($op->first->sibling);
4479     } elsif ($type eq "quotemeta") {
4480         return '\Q' . $self->dq($op->first->sibling) . '\E';
4481     } elsif ($type eq "fc") {
4482         return '\F' . $self->dq($op->first->sibling) . '\E';
4483     } elsif ($type eq "join") {
4484         return $self->deparse($op->last, 26); # was join($", @ary)
4485     } else {
4486         return $self->deparse($op, 26);
4487     }
4488 }
4489
4490 sub pp_backtick {
4491     my $self = shift;
4492     my($op, $cx) = @_;
4493     # skip pushmark if it exists (readpipe() vs ``)
4494     my $child = $op->first->sibling->isa('B::NULL')
4495         ? $op->first : $op->first->sibling;
4496     if ($self->pure_string($child)) {