This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
d8470eccccb121268125528331bf8ec84df28229
[perl5.git] / pod / perlsec.pod
1 =head1 NAME
2
3 perlsec - Perl security
4
5 =head1 DESCRIPTION
6
7 Perl is designed to make it easy to program securely even when running
8 with extra privileges, like setuid or setgid programs.  Unlike most
9 command line shells, which are based on multiple substitution passes on
10 each line of the script, Perl uses a more conventional evaluation scheme
11 with fewer hidden snags.  Additionally, because the language has more
12 builtin functionality, it can rely less upon external (and possibly
13 untrustworthy) programs to accomplish its purposes.
14
15 =head1 SECURITY VULNERABILITY CONTACT INFORMATION
16
17 If you believe you have found a security vulnerability in Perl, please email
18 perl5-security-report@perl.org with details.  This points to a closed
19 subscription, unarchived mailing list.  Please only use this address for
20 security issues in the Perl core, not for modules independently distributed on
21 CPAN.
22
23 =head1 SECURITY MECHANISMS AND CONCERNS
24
25 =head2 Taint mode
26
27 Perl automatically enables a set of special security checks, called I<taint
28 mode>, when it detects its program running with differing real and effective
29 user or group IDs.  The setuid bit in Unix permissions is mode 04000, the
30 setgid bit mode 02000; either or both may be set.  You can also enable taint
31 mode explicitly by using the B<-T> command line flag. This flag is
32 I<strongly> suggested for server programs and any program run on behalf of
33 someone else, such as a CGI script. Once taint mode is on, it's on for
34 the remainder of your script.
35
36 While in this mode, Perl takes special precautions called I<taint
37 checks> to prevent both obvious and subtle traps.  Some of these checks
38 are reasonably simple, such as verifying that path directories aren't
39 writable by others; careful programmers have always used checks like
40 these.  Other checks, however, are best supported by the language itself,
41 and it is these checks especially that contribute to making a set-id Perl
42 program more secure than the corresponding C program.
43
44 You may not use data derived from outside your program to affect
45 something else outside your program--at least, not by accident.  All
46 command line arguments, environment variables, locale information (see
47 L<perllocale>), results of certain system calls (C<readdir()>,
48 C<readlink()>, the variable of C<shmread()>, the messages returned by
49 C<msgrcv()>, the password, gcos and shell fields returned by the
50 C<getpwxxx()> calls), and all file input are marked as "tainted".
51 Tainted data may not be used directly or indirectly in any command
52 that invokes a sub-shell, nor in any command that modifies files,
53 directories, or processes, B<with the following exceptions>:
54
55 =over 4
56
57 =item *
58
59 Arguments to C<print> and C<syswrite> are B<not> checked for taintedness.
60
61 =item *
62
63 Symbolic methods
64
65     $obj->$method(@args);
66
67 and symbolic sub references
68
69     &{$foo}(@args);
70     $foo->(@args);
71
72 are not checked for taintedness.  This requires extra carefulness
73 unless you want external data to affect your control flow.  Unless
74 you carefully limit what these symbolic values are, people are able
75 to call functions B<outside> your Perl code, such as POSIX::system,
76 in which case they are able to run arbitrary external code.
77
78 =item *
79
80 Hash keys are B<never> tainted.
81
82 =back
83
84 For efficiency reasons, Perl takes a conservative view of
85 whether data is tainted.  If an expression contains tainted data,
86 any subexpression may be considered tainted, even if the value
87 of the subexpression is not itself affected by the tainted data.
88
89 Because taintedness is associated with each scalar value, some
90 elements of an array or hash can be tainted and others not.
91 The keys of a hash are B<never> tainted.
92
93 For example:
94
95     $arg = shift;               # $arg is tainted
96     $hid = $arg, 'bar';         # $hid is also tainted
97     $line = <>;                 # Tainted
98     $line = <STDIN>;            # Also tainted
99     open FOO, "/home/me/bar" or die $!;
100     $line = <FOO>;              # Still tainted
101     $path = $ENV{'PATH'};       # Tainted, but see below
102     $data = 'abc';              # Not tainted
103
104     system "echo $arg";         # Insecure
105     system "/bin/echo", $arg;   # Considered insecure
106                                 # (Perl doesn't know about /bin/echo)
107     system "echo $hid";         # Insecure
108     system "echo $data";        # Insecure until PATH set
109
110     $path = $ENV{'PATH'};       # $path now tainted
111
112     $ENV{'PATH'} = '/bin:/usr/bin';
113     delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};
114
115     $path = $ENV{'PATH'};       # $path now NOT tainted
116     system "echo $data";        # Is secure now!
117
118     open(FOO, "< $arg");        # OK - read-only file
119     open(FOO, "> $arg");        # Not OK - trying to write
120
121     open(FOO,"echo $arg|");     # Not OK
122     open(FOO,"-|")
123         or exec 'echo', $arg;   # Also not OK
124
125     $shout = `echo $arg`;       # Insecure, $shout now tainted
126
127     unlink $data, $arg;         # Insecure
128     umask $arg;                 # Insecure
129
130     exec "echo $arg";           # Insecure
131     exec "echo", $arg;          # Insecure
132     exec "sh", '-c', $arg;      # Very insecure!
133
134     @files = <*.c>;             # insecure (uses readdir() or similar)
135     @files = glob('*.c');       # insecure (uses readdir() or similar)
136
137     # In Perl releases older than 5.6.0 the <*.c> and glob('*.c') would
138     # have used an external program to do the filename expansion; but in
139     # either case the result is tainted since the list of filenames comes
140     # from outside of the program.
141
142     $bad = ($arg, 23);          # $bad will be tainted
143     $arg, `true`;               # Insecure (although it isn't really)
144
145 If you try to do something insecure, you will get a fatal error saying
146 something like "Insecure dependency" or "Insecure $ENV{PATH}".
147
148 The exception to the principle of "one tainted value taints the whole
149 expression" is with the ternary conditional operator C<?:>.  Since code
150 with a ternary conditional
151
152     $result = $tainted_value ? "Untainted" : "Also untainted";
153
154 is effectively
155
156     if ( $tainted_value ) {
157         $result = "Untainted";
158     } else {
159         $result = "Also untainted";
160     }
161
162 it doesn't make sense for C<$result> to be tainted.
163
164 =head2 Laundering and Detecting Tainted Data
165
166 To test whether a variable contains tainted data, and whose use would
167 thus trigger an "Insecure dependency" message, you can use the
168 C<tainted()> function of the Scalar::Util module, available in your
169 nearby CPAN mirror, and included in Perl starting from the release 5.8.0.
170 Or you may be able to use the following C<is_tainted()> function.
171
172     sub is_tainted {
173         local $@;   # Don't pollute caller's value.
174         return ! eval { eval("#" . substr(join("", @_), 0, 0)); 1 };
175     }
176
177 This function makes use of the fact that the presence of tainted data
178 anywhere within an expression renders the entire expression tainted.  It
179 would be inefficient for every operator to test every argument for
180 taintedness.  Instead, the slightly more efficient and conservative
181 approach is used that if any tainted value has been accessed within the
182 same expression, the whole expression is considered tainted.
183
184 But testing for taintedness gets you only so far.  Sometimes you have just
185 to clear your data's taintedness.  Values may be untainted by using them
186 as keys in a hash; otherwise the only way to bypass the tainting
187 mechanism is by referencing subpatterns from a regular expression match.
188 Perl presumes that if you reference a substring using $1, $2, etc., that
189 you knew what you were doing when you wrote the pattern.  That means using
190 a bit of thought--don't just blindly untaint anything, or you defeat the
191 entire mechanism.  It's better to verify that the variable has only good
192 characters (for certain values of "good") rather than checking whether it
193 has any bad characters.  That's because it's far too easy to miss bad
194 characters that you never thought of.
195
196 Here's a test to make sure that the data contains nothing but "word"
197 characters (alphabetics, numerics, and underscores), a hyphen, an at sign,
198 or a dot.
199
200     if ($data =~ /^([-\@\w.]+)$/) {
201         $data = $1;                     # $data now untainted
202     } else {
203         die "Bad data in '$data'";      # log this somewhere
204     }
205
206 This is fairly secure because C</\w+/> doesn't normally match shell
207 metacharacters, nor are dot, dash, or at going to mean something special
208 to the shell.  Use of C</.+/> would have been insecure in theory because
209 it lets everything through, but Perl doesn't check for that.  The lesson
210 is that when untainting, you must be exceedingly careful with your patterns.
211 Laundering data using regular expression is the I<only> mechanism for
212 untainting dirty data, unless you use the strategy detailed below to fork
213 a child of lesser privilege.
214
215 The example does not untaint C<$data> if C<use locale> is in effect,
216 because the characters matched by C<\w> are determined by the locale.
217 Perl considers that locale definitions are untrustworthy because they
218 contain data from outside the program.  If you are writing a
219 locale-aware program, and want to launder data with a regular expression
220 containing C<\w>, put C<no locale> ahead of the expression in the same
221 block.  See L<perllocale/SECURITY> for further discussion and examples.
222
223 =head2 Switches On the "#!" Line
224
225 When you make a script executable, in order to make it usable as a
226 command, the system will pass switches to perl from the script's #!
227 line.  Perl checks that any command line switches given to a setuid
228 (or setgid) script actually match the ones set on the #! line.  Some
229 Unix and Unix-like environments impose a one-switch limit on the #!
230 line, so you may need to use something like C<-wU> instead of C<-w -U>
231 under such systems.  (This issue should arise only in Unix or
232 Unix-like environments that support #! and setuid or setgid scripts.)
233
234 =head2 Taint mode and @INC
235
236 When the taint mode (C<-T>) is in effect, the "." directory is removed
237 from C<@INC>, and the environment variables C<PERL5LIB> and C<PERLLIB>
238 are ignored by Perl. You can still adjust C<@INC> from outside the
239 program by using the C<-I> command line option as explained in
240 L<perlrun>. The two environment variables are ignored because
241 they are obscured, and a user running a program could be unaware that
242 they are set, whereas the C<-I> option is clearly visible and
243 therefore permitted.
244
245 Another way to modify C<@INC> without modifying the program, is to use
246 the C<lib> pragma, e.g.:
247
248   perl -Mlib=/foo program
249
250 The benefit of using C<-Mlib=/foo> over C<-I/foo>, is that the former
251 will automagically remove any duplicated directories, while the later
252 will not.
253
254 Note that if a tainted string is added to C<@INC>, the following
255 problem will be reported:
256
257   Insecure dependency in require while running with -T switch
258
259 =head2 Cleaning Up Your Path
260
261 For "Insecure C<$ENV{PATH}>" messages, you need to set C<$ENV{'PATH'}> to
262 a known value, and each directory in the path must be absolute and
263 non-writable by others than its owner and group.  You may be surprised to
264 get this message even if the pathname to your executable is fully
265 qualified.  This is I<not> generated because you didn't supply a full path
266 to the program; instead, it's generated because you never set your PATH
267 environment variable, or you didn't set it to something that was safe.
268 Because Perl can't guarantee that the executable in question isn't itself
269 going to turn around and execute some other program that is dependent on
270 your PATH, it makes sure you set the PATH.
271
272 The PATH isn't the only environment variable which can cause problems.
273 Because some shells may use the variables IFS, CDPATH, ENV, and
274 BASH_ENV, Perl checks that those are either empty or untainted when
275 starting subprocesses. You may wish to add something like this to your
276 setid and taint-checking scripts.
277
278     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};   # Make %ENV safer
279
280 It's also possible to get into trouble with other operations that don't
281 care whether they use tainted values.  Make judicious use of the file
282 tests in dealing with any user-supplied filenames.  When possible, do
283 opens and such B<after> properly dropping any special user (or group!)
284 privileges. Perl doesn't prevent you from opening tainted filenames for reading,
285 so be careful what you print out.  The tainting mechanism is intended to
286 prevent stupid mistakes, not to remove the need for thought.
287
288 Perl does not call the shell to expand wild cards when you pass C<system>
289 and C<exec> explicit parameter lists instead of strings with possible shell
290 wildcards in them.  Unfortunately, the C<open>, C<glob>, and
291 backtick functions provide no such alternate calling convention, so more
292 subterfuge will be required.
293
294 Perl provides a reasonably safe way to open a file or pipe from a setuid
295 or setgid program: just create a child process with reduced privilege who
296 does the dirty work for you.  First, fork a child using the special
297 C<open> syntax that connects the parent and child by a pipe.  Now the
298 child resets its ID set and any other per-process attributes, like
299 environment variables, umasks, current working directories, back to the
300 originals or known safe values.  Then the child process, which no longer
301 has any special permissions, does the C<open> or other system call.
302 Finally, the child passes the data it managed to access back to the
303 parent.  Because the file or pipe was opened in the child while running
304 under less privilege than the parent, it's not apt to be tricked into
305 doing something it shouldn't.
306
307 Here's a way to do backticks reasonably safely.  Notice how the C<exec> is
308 not called with a string that the shell could expand.  This is by far the
309 best way to call something that might be subjected to shell escapes: just
310 never call the shell at all.  
311
312         use English '-no_match_vars';
313         die "Can't fork: $!" unless defined($pid = open(KID, "-|"));
314         if ($pid) {           # parent
315             while (<KID>) {
316                 # do something
317             }
318             close KID;
319         } else {
320             my @temp     = ($EUID, $EGID);
321             my $orig_uid = $UID;
322             my $orig_gid = $GID;
323             $EUID = $UID;
324             $EGID = $GID;
325             # Drop privileges
326             $UID  = $orig_uid;
327             $GID  = $orig_gid;
328             # Make sure privs are really gone
329             ($EUID, $EGID) = @temp;
330             die "Can't drop privileges"
331                 unless $UID == $EUID  && $GID eq $EGID;
332             $ENV{PATH} = "/bin:/usr/bin"; # Minimal PATH.
333             # Consider sanitizing the environment even more.
334             exec 'myprog', 'arg1', 'arg2'
335                 or die "can't exec myprog: $!";
336         }
337
338 A similar strategy would work for wildcard expansion via C<glob>, although
339 you can use C<readdir> instead.
340
341 Taint checking is most useful when although you trust yourself not to have
342 written a program to give away the farm, you don't necessarily trust those
343 who end up using it not to try to trick it into doing something bad.  This
344 is the kind of security checking that's useful for set-id programs and
345 programs launched on someone else's behalf, like CGI programs.
346
347 This is quite different, however, from not even trusting the writer of the
348 code not to try to do something evil.  That's the kind of trust needed
349 when someone hands you a program you've never seen before and says, "Here,
350 run this."  For that kind of safety, you might want to check out the Safe
351 module, included standard in the Perl distribution.  This module allows the
352 programmer to set up special compartments in which all system operations
353 are trapped and namespace access is carefully controlled.  Safe should
354 not be considered bullet-proof, though: it will not prevent the foreign
355 code to set up infinite loops, allocate gigabytes of memory, or even
356 abusing perl bugs to make the host interpreter crash or behave in
357 unpredictable ways. In any case it's better avoided completely if you're
358 really concerned about security.
359
360 =head2 Security Bugs
361
362 Beyond the obvious problems that stem from giving special privileges to
363 systems as flexible as scripts, on many versions of Unix, set-id scripts
364 are inherently insecure right from the start.  The problem is a race
365 condition in the kernel.  Between the time the kernel opens the file to
366 see which interpreter to run and when the (now-set-id) interpreter turns
367 around and reopens the file to interpret it, the file in question may have
368 changed, especially if you have symbolic links on your system.
369
370 Fortunately, sometimes this kernel "feature" can be disabled.
371 Unfortunately, there are two ways to disable it.  The system can simply
372 outlaw scripts with any set-id bit set, which doesn't help much.
373 Alternately, it can simply ignore the set-id bits on scripts.
374
375 However, if the kernel set-id script feature isn't disabled, Perl will
376 complain loudly that your set-id script is insecure.  You'll need to
377 either disable the kernel set-id script feature, or put a C wrapper around
378 the script.  A C wrapper is just a compiled program that does nothing
379 except call your Perl program.   Compiled programs are not subject to the
380 kernel bug that plagues set-id scripts.  Here's a simple wrapper, written
381 in C:
382
383     #define REAL_PATH "/path/to/script"
384     main(ac, av)
385         char **av;
386     {
387         execv(REAL_PATH, av);
388     }
389
390 Compile this wrapper into a binary executable and then make I<it> rather
391 than your script setuid or setgid.
392
393 In recent years, vendors have begun to supply systems free of this
394 inherent security bug.  On such systems, when the kernel passes the name
395 of the set-id script to open to the interpreter, rather than using a
396 pathname subject to meddling, it instead passes I</dev/fd/3>.  This is a
397 special file already opened on the script, so that there can be no race
398 condition for evil scripts to exploit.  On these systems, Perl should be
399 compiled with C<-DSETUID_SCRIPTS_ARE_SECURE_NOW>.  The F<Configure>
400 program that builds Perl tries to figure this out for itself, so you
401 should never have to specify this yourself.  Most modern releases of
402 SysVr4 and BSD 4.4 use this approach to avoid the kernel race condition.
403
404 =head2 Protecting Your Programs
405
406 There are a number of ways to hide the source to your Perl programs,
407 with varying levels of "security".
408
409 First of all, however, you I<can't> take away read permission, because
410 the source code has to be readable in order to be compiled and
411 interpreted.  (That doesn't mean that a CGI script's source is
412 readable by people on the web, though.)  So you have to leave the
413 permissions at the socially friendly 0755 level.  This lets 
414 people on your local system only see your source.
415
416 Some people mistakenly regard this as a security problem.  If your program does
417 insecure things, and relies on people not knowing how to exploit those
418 insecurities, it is not secure.  It is often possible for someone to
419 determine the insecure things and exploit them without viewing the
420 source.  Security through obscurity, the name for hiding your bugs
421 instead of fixing them, is little security indeed.
422
423 You can try using encryption via source filters (Filter::* from CPAN,
424 or Filter::Util::Call and Filter::Simple since Perl 5.8).
425 But crackers might be able to decrypt it.  You can try using the byte
426 code compiler and interpreter described below, but crackers might be
427 able to de-compile it.  You can try using the native-code compiler
428 described below, but crackers might be able to disassemble it.  These
429 pose varying degrees of difficulty to people wanting to get at your
430 code, but none can definitively conceal it (this is true of every
431 language, not just Perl).
432
433 If you're concerned about people profiting from your code, then the
434 bottom line is that nothing but a restrictive license will give you
435 legal security.  License your software and pepper it with threatening
436 statements like "This is unpublished proprietary software of XYZ Corp.
437 Your access to it does not give you permission to use it blah blah
438 blah."  You should see a lawyer to be sure your license's wording will
439 stand up in court.
440
441 =head2 Unicode
442
443 Unicode is a new and complex technology and one may easily overlook
444 certain security pitfalls.  See L<perluniintro> for an overview and
445 L<perlunicode> for details, and L<perlunicode/"Security Implications
446 of Unicode"> for security implications in particular.
447
448 =head2 Algorithmic Complexity Attacks
449
450 Certain internal algorithms used in the implementation of Perl can
451 be attacked by choosing the input carefully to consume large amounts
452 of either time or space or both.  This can lead into the so-called
453 I<Denial of Service> (DoS) attacks.
454
455 =over 4
456
457 =item *
458
459 Hash Function - the algorithm used to "order" hash elements has been
460 changed several times during the development of Perl, mainly to be
461 reasonably fast.  In Perl 5.8.1 also the security aspect was taken
462 into account.
463
464 In Perls before 5.8.1 one could rather easily generate data that as
465 hash keys would cause Perl to consume large amounts of time because
466 internal structure of hashes would badly degenerate.  In Perl 5.8.1
467 the hash function is randomly perturbed by a pseudorandom seed which
468 makes generating such naughty hash keys harder.
469 See L<perlrun/PERL_HASH_SEED> for more information.
470
471 In Perl 5.8.1 the random perturbation was done by default, but as of
472 5.8.2 it is only used on individual hashes if the internals detect the
473 insertion of pathological data. If one wants for some reason emulate the
474 old behaviour (and expose oneself to DoS attacks) one can set the
475 environment variable PERL_HASH_SEED to zero to disable the protection
476 (or any other integer to force a known perturbation, rather than random). 
477 One possible reason for wanting to emulate the old behaviour is that in the
478 new behaviour consecutive runs of Perl will order hash keys differently,
479 which may confuse some applications (like Data::Dumper: the outputs of two
480 different runs are no longer identical).
481
482 B<Perl has never guaranteed any ordering of the hash keys>, and the
483 ordering has already changed several times during the lifetime of
484 Perl 5.  Also, the ordering of hash keys has always been, and
485 continues to be, affected by the insertion order.
486
487 Also note that while the order of the hash elements might be
488 randomised, this "pseudoordering" should B<not> be used for
489 applications like shuffling a list randomly (use List::Util::shuffle()
490 for that, see L<List::Util>, a standard core module since Perl 5.8.0;
491 or the CPAN module Algorithm::Numerical::Shuffle), or for generating
492 permutations (use e.g. the CPAN modules Algorithm::Permute or
493 Algorithm::FastPermute), or for any cryptographic applications.
494
495 =item *
496
497 Regular expressions - Perl's regular expression engine is so called NFA
498 (Non-deterministic Finite Automaton), which among other things means that
499 it can rather easily consume large amounts of both time and space if the
500 regular expression may match in several ways.  Careful crafting of the
501 regular expressions can help but quite often there really isn't much
502 one can do (the book "Mastering Regular Expressions" is required
503 reading, see L<perlfaq2>).  Running out of space manifests itself by
504 Perl running out of memory.
505
506 =item *
507
508 Sorting - the quicksort algorithm used in Perls before 5.8.0 to
509 implement the sort() function is very easy to trick into misbehaving
510 so that it consumes a lot of time.  Starting from Perl 5.8.0 a different
511 sorting algorithm, mergesort, is used by default.  Mergesort cannot
512 misbehave on any input.
513
514 =back
515
516 See L<http://www.cs.rice.edu/~scrosby/hash/> for more information,
517 and any computer science textbook on algorithmic complexity.
518
519 =head1 SEE ALSO
520
521 L<perlrun> for its description of cleaning up environment variables.