This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
t/re/regexp_unicode_prop.t: Add check no warnings generated
[perl5.git] / t / re / regexp_unicode_prop.t
1 #!./perl
2 #
3 # Tests that have to do with checking whether characters have (or not have)
4 # certain Unicode properties; belong (or not belong) to blocks, scripts, etc.
5 #
6
7 use strict;
8 use warnings;
9 use 5.010;
10
11 my @warnings;
12 local $SIG {__WARN__} = sub {push @warnings, "@_"};
13
14 BEGIN {
15     chdir 't' if -d 't';
16     require './test.pl';
17     skip_all_if_miniperl("no dynamic loading on miniperl, no File::Spec (used by charnames)");
18 }
19
20 sub run_tests;
21
22 sub get_str_name($) {
23     my $char = shift;
24
25     my ($str, $name);
26
27     if ($char =~ /^\\/) {
28         $str  = eval qq ["$char"];
29         $name =      qq ["$char"];
30     }
31     elsif ($char =~ /^0x([0-9A-Fa-f]+)$/) {
32         $str  =  chr hex $1;
33         $name = "chr ($char)";
34     }
35     else {
36         $str  =      $char;
37         $name = qq ["$char"];
38     }
39
40     return ($str, $name);
41 }
42
43 #
44 # This is the data to test.
45 #
46 # This is a hash; keys are the property to test.
47 # Values are arrays containing characters to test. The characters can
48 # have the following formats:
49 #   '\N{CHARACTER NAME}'  -  Use character with that name
50 #   '\x{1234}'            -  Use character with that hex escape
51 #   '0x1234'              -  Use chr() to get that character
52 #   "a"                   -  Character to use
53 #
54 # If a character entry starts with ! the character does not belong to the class
55 #
56 # If the class is just single letter, we use both \pL and \p{L}
57 #
58
59 use charnames ':full';
60
61 my @CLASSES = (
62     L                         => ["a", "A"],
63     Ll                        => ["b", "!B"],
64     Lu                        => ["!c", "C"],
65     IsLl                      => ["d", "!D"],
66     IsLu                      => ["!e", "E"],
67     LC                        => ["f", "!1"],
68    'L&'                       => ["g", "!2"],
69    'Lowercase Letter'         => ["h", "!H"],
70
71     Common                    => ["!i", "3"],
72     Inherited                 => ["!j", '\x{300}'],
73
74     InBasicLatin              => ['\N{LATIN CAPITAL LETTER A}'],
75     InLatin1Supplement        => ['\N{LATIN CAPITAL LETTER A WITH GRAVE}'],
76     InLatinExtendedA          => ['\N{LATIN CAPITAL LETTER A WITH MACRON}'],
77     InLatinExtendedB          => ['\N{LATIN SMALL LETTER B WITH STROKE}'],
78     InKatakana                => ['\N{KATAKANA LETTER SMALL A}'],
79     IsLatin                   => ["0x100", "0x212b"],
80     IsHebrew                  => ["0x5d0", "0xfb4f"],
81     IsGreek                   => ["0x37a", "0x386", "!0x387", "0x388",
82                                   "0x38a", "!0x38b", "0x38c"],
83     HangulSyllables           => ['\x{AC00}'],
84    'Script=Latin'             => ['\x{0100}'],
85    'Block=LatinExtendedA'     => ['\x{0100}'],
86    'Category=UppercaseLetter' => ['\x{0100}'],
87
88     #
89     # It's ok to repeat class names.
90     #
91     InLatin1Supplement        =>
92                             ['!\N{U+7f}',  '\N{U+80}',  '\N{U+ff}', '!\x{100}'],
93     InLatinExtendedA          =>
94                             ['!\N{U+7f}', '!\N{U+80}', '!\N{U+ff}',  '\x{100}'],
95
96     #
97     # Properties are case-insensitive, and may have whitespace,
98     # dashes and underscores.
99     #
100    'in-latin1_SUPPLEMENT'     => ['\N{U+80}',
101                                   '\N{LATIN SMALL LETTER Y WITH DIAERESIS}'],
102    '  ^  In Latin 1 Supplement  '
103                               => ['!\N{U+80}', '\N{COFFIN}'],
104    'latin-1   supplement'     => ['\N{U+80}', "0xDF"],
105
106 );
107
108     my @USER_DEFINED_PROPERTIES = (
109         #
110         # User defined properties
111         #
112         InKana1                   => ['\x{3040}', '!\x{303F}'],
113         InKana2                   => ['\x{3040}', '!\x{303F}'],
114         InKana3                   => ['\x{3041}', '!\x{3040}'],
115         InNotKana                 => ['\x{3040}', '!\x{3041}'],
116         InConsonant               => ['d',        '!e'],
117         IsSyriac1                 => ['\x{0712}', '!\x{072F}'],
118         IsSyriac1KanaMark         => ['\x{309A}', '!\x{3090}'],
119         IsSyriac1KanaMark         => ['\x{0730}', '!\x{0712}'],
120         '# User-defined character properties may lack \n at the end',
121         InGreekSmall              => ['\N{GREEK SMALL LETTER PI}',
122                                         '\N{GREEK SMALL LETTER FINAL SIGMA}'],
123         InGreekCapital            => ['\N{GREEK CAPITAL LETTER PI}', '!\x{03A2}'],
124         Dash                      => ['-'],
125         ASCII_Hex_Digit           => ['!-', 'A'],
126         IsAsciiHexAndDash         => ['-', 'A'],
127
128         # This overrides the official one
129         InLatin1                  => ['\x{0100}', '!\x{00FF}'],
130     );
131
132     my @USER_CASELESS_PROPERTIES = (
133         #
134         # User defined properties which differ depending on /i.  Second entry
135         # is false normally, true under /i
136         #
137         'IsMyUpper'                => ["M", "!m" ],
138     );
139
140
141 #
142 # From the short properties we populate POSIX-like classes.
143 #
144 my %SHORT_PROPERTIES = (
145     'Ll'  => ['m', '\N{CYRILLIC SMALL LETTER A}'],
146     'Lu'  => ['M', '\N{GREEK CAPITAL LETTER ALPHA}'],
147     'Lo'  => ['\N{HIRAGANA LETTER SMALL A}'],
148     # is also in other alphabetic
149     'Mn'  => ['\N{HEBREW POINT RAFE}'],
150     'Nd'  => ["0", '\N{ARABIC-INDIC DIGIT ZERO}'],
151     'Pc'  => ["_"],
152     'Po'  => ["!"],
153     'Zs'  => [" "],
154     'Cc'  => ['\x{00}'],
155 );
156
157 #
158 # Illegal properties
159 #
160 my @ILLEGAL_PROPERTIES =
161     qw[q qrst f foo isfoo infoo ISfoo INfoo Is::foo In::foo];
162
163 my %d;
164
165 while (my ($class, $chars) = each %SHORT_PROPERTIES) {
166     push @{$d {IsAlpha}} => map {$class =~ /^[LM]/   ? $_ : "!$_"} @$chars;
167     push @{$d {IsAlnum}} => map {$class =~ /^[LMN]./ ? $_ : "!$_"} @$chars;
168     push @{$d {IsASCII}} => map {length ($_) == 1 || $_ eq '\x{00}'
169                                                      ? $_ : "!$_"} @$chars;
170     push @{$d {IsCntrl}} => map {$class =~ /^C/      ? $_ : "!$_"} @$chars;
171     push @{$d {IsBlank}} => map {$class =~ /^Z[lps]/ ? $_ : "!$_"} @$chars;
172     push @{$d {IsDigit}} => map {$class =~ /^Nd$/    ? $_ : "!$_"} @$chars;
173     push @{$d {IsGraph}} => map {$class =~ /^([LMNPS]|Co)/
174                                                      ? $_ : "!$_"} @$chars;
175     push @{$d {IsPrint}} => map {$class =~ /^([LMNPS]|Co|Zs)/
176                                                      ? $_ : "!$_"} @$chars;
177     push @{$d {IsLower}} => map {$class =~ /^Ll$/    ? $_ : "!$_"} @$chars;
178     push @{$d {IsUpper}} => map {$class =~ /^L[ut]/  ? $_ : "!$_"} @$chars;
179     push @{$d {IsPunct}} => map {$class =~ /^P/      ? $_ : "!$_"} @$chars;
180     push @{$d {IsWord}}  => map {$class =~ /^[LMN]/ || $_ eq "_"
181                                                      ? $_ : "!$_"} @$chars;
182     push @{$d {IsSpace}} => map {$class =~ /^Z/ ||
183                                  length ($_) == 1 && utf8::native_to_unicode(ord ($_)) >= 0x09
184                                                   && utf8::native_to_unicode(ord ($_)) <= 0x0D
185                                                      ? $_ : "!$_"} @$chars;
186 }
187
188 push @CLASSES => "# Short properties"        => %SHORT_PROPERTIES,
189                  "# POSIX like properties"   => %d,
190                  "# User defined properties" => @USER_DEFINED_PROPERTIES;
191
192
193 #
194 # Calculate the number of tests.
195 #
196 my $count = 0;
197 for (my $i = 0; $i < @CLASSES; $i += 2) {
198     $i ++, redo if $CLASSES [$i] =~ /^\h*#\h*(.*)/;
199     $count += 2 * (length $CLASSES [$i] == 1 ? 4 : 2) * @{$CLASSES [$i + 1]};
200 }
201 $count += 4 * @ILLEGAL_PROPERTIES;
202 $count += 4 * grep {length $_ == 1} @ILLEGAL_PROPERTIES;
203 $count += 8 * @USER_CASELESS_PROPERTIES;
204 $count += 1;    # Test for pkg:IsMyLower
205 $count += 1;    # No warnings generated
206
207 plan(tests => $count);
208
209 run_tests unless caller ();
210
211 sub match {
212     my ($char, $match, $nomatch, $caseless) = @_;
213     $caseless = "" unless defined $caseless;
214     $caseless = 'i' if $caseless;
215
216     my ($str, $name) = get_str_name($char);
217
218     undef $@;
219     my $pat = "qr/$match/$caseless";
220     my $match_pat = eval $pat;
221     is($@, '', "$pat compiled correctly to a regexp: $@");
222     like($str, $match_pat, "$name correctly matched");
223
224     undef $@;
225     $pat = "qr/$nomatch/$caseless";
226     my $nomatch_pat = eval $pat;
227     is($@, '', "$pat compiled correctly to a regexp: $@");
228     unlike($str, $nomatch_pat, "$name correctly did not match");
229 }
230
231 sub run_tests {
232
233     while (@CLASSES) {
234         my $class = shift @CLASSES;
235         if ($class =~ /^\h*#\h*(.*)/) {
236             print "# $1\n";
237             next;
238         }
239         last unless @CLASSES;
240         my $chars   = shift @CLASSES;
241         my @in      =                       grep {!/^!./} @$chars;
242         my @out     = map {s/^!(?=.)//; $_} grep { /^!./} @$chars;
243         my $in_pat  = eval qq ['\\p{$class}'];
244         my $out_pat = eval qq ['\\P{$class}'];
245
246         match $_, $in_pat,  $out_pat for @in;
247         match $_, $out_pat, $in_pat  for @out;
248
249         if (1 == length $class) {   # Repeat without braces if name length 1
250             my $in_pat  = eval qq ['\\p$class'];
251             my $out_pat = eval qq ['\\P$class'];
252
253             match $_, $in_pat,  $out_pat for @in;
254             match $_, $out_pat, $in_pat  for @out;
255         }
256     }
257
258
259     print "# Illegal properties\n";
260     foreach my $p (@ILLEGAL_PROPERTIES) {
261         my $pat;
262         if ($p =~ /::/) {
263             $pat = qr /^Illegal user-defined property name/;
264         }
265         else {
266             $pat = qr /^Can't find Unicode property definition/;
267         }
268
269         undef $@;
270         my $r = eval "'a' =~ /\\p{$p}/; 1";
271         is($r, undef, "Unknown Unicode property \\p{$p}");
272         like($@, $pat, "Unknown Unicode property \\p{$p}");
273         undef $@;
274         my $s = eval "'a' =~ /\\P{$p}/; 1";
275         is($s, undef, "Unknown Unicode property \\p{$p}");
276         like($@, $pat, "Unknown Unicode property \\p{$p}");
277         if (length $p == 1) {
278             undef $@;
279             my $r = eval "'a' =~ /\\p$p/; 1";
280             is($r, undef, "Unknown Unicode property \\p$p");
281             like($@, $pat, "Unknown Unicode property \\p$p");
282             undef $@;
283             my $s = eval "'a' =~ /\\P$p/; 1";
284             is($r, undef, "Unknown Unicode property \\P$p");
285             like($@, $pat, "Unknown Unicode property \\P$p");
286         }
287     }
288
289     print "# User-defined properties with /i differences\n";
290     while (my $class = shift @USER_CASELESS_PROPERTIES) {
291         my $chars_ref = shift @USER_CASELESS_PROPERTIES;
292         my @in      =                       grep {!/^!./} @$chars_ref;
293         my @out     = map {s/^!(?=.)//; $_} grep { /^!./} @$chars_ref;
294         my $in_pat  = eval qq ['\\p{$class}'];
295         my $out_pat = eval qq ['\\P{$class}'];
296
297         # Verify works as regularly for not /i
298         match $_, $in_pat,  $out_pat for @in;
299         match $_, $out_pat, $in_pat  for @out;
300
301         # Verify that adding /i doesn't change the in set.
302         match $_, $in_pat,  $out_pat, 'i' for @in;
303
304         # Verify that adding /i does change the out set to match.
305         match $_, $in_pat,  $out_pat, 'i' for @out;
306     }
307 }
308
309
310 #
311 # User defined properties
312 #
313
314 sub InKana1 {<<'--'}
315 3040    309F
316 30A0    30FF
317 --
318
319 sub InKana2 {<<'--'}
320 +utf8::InHiragana
321 +utf8::InKatakana
322 --
323
324 sub InKana3 {<<'--'}
325 +utf8::InHiragana
326 +utf8::InKatakana
327 -utf8::IsCn
328 --
329
330 sub InNotKana {<<'--'}
331 !utf8::InHiragana
332 -utf8::InKatakana
333 +utf8::IsCn
334 --
335
336 sub InConsonant {
337
338     my $return = "+utf8::Lowercase\n&utf8::ASCII\n";
339     $return .= sprintf("-%X\n", ord "a");
340     $return .= sprintf("-%X\n", ord "e");
341     $return .= sprintf("-%X\n", ord "i");
342     $return .= sprintf("-%X\n", ord "o");
343     $return .= sprintf("-%X\n", ord "u");
344     return $return;
345 }
346
347 sub IsSyriac1 {<<'--'}
348 0712    072C
349 0730    074A
350 --
351
352 sub InGreekSmall   {return "03B1\t03C9"}
353 sub InGreekCapital {return "0391\t03A9\n-03A2"}
354
355 sub IsAsciiHexAndDash {<<'--'}
356 +utf8::ASCII_Hex_Digit
357 +utf8::Dash
358 --
359
360 sub InLatin1 {
361     return "0100\t10FFFF";
362 }
363
364 sub IsMyUpper {
365     my $caseless = shift;
366     return "+utf8::"
367            . (($caseless)
368                ? 'Alphabetic'
369                : 'Uppercase')
370            . "\n&utf8::ASCII";
371 }
372
373 {   # This has to be done here and not like the others, because we have to
374     # make sure that the property is not known until after the regex is
375     # compiled.  It was previously getting confused about the pkg and /i
376     # combination
377
378     my $mylower = qr/\p{pkg::IsMyLower}/i;
379
380 sub pkg::IsMyLower {
381     my $caseless = shift;
382     return "+utf8::"
383         . (($caseless)
384             ? 'Alphabetic'
385             : 'Lowercase')
386         . "\n&utf8::ASCII";
387 }
388
389     like("A", $mylower, "Not available until runtime user-defined property with pkg:: and /i works");
390
391 }
392
393 # Verify that can use user-defined properties inside another one
394 sub IsSyriac1KanaMark {<<'--'}
395 +main::IsSyriac1
396 +main::InKana3
397 &utf8::IsMark
398 --
399
400 # fake user-defined properties; these subs shouldn't be called, because
401 # their names don't start with In or Is
402
403 sub f       { die }
404 sub foo     { die }
405 sub isfoo   { die }
406 sub infoo   { die }
407 sub ISfoo   { die }
408 sub INfoo   { die }
409 sub Is::foo { die }
410 sub In::foo { die }
411
412 if (! is(@warnings, 0, "No warnings were generated")) {
413     diag join "\n", @warnings, "\n";
414 }
415
416 1;
417 __END__