This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perldata: Only one "_" is allowed between each digit pair
[perl5.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8 X<variable, name> X<variable name> X<data type> X<type>
9
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes".  A scalar is a 
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>).  Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0.  Hashes are unordered collections of scalar 
16 values indexed by their associated string key.
17
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers.  The rest of the name tells you the particular
21 value to which it refers.  Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits.  In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details).  It's possible to substitute
28 for a simple identifier, an expression that produces a reference
29 to the value at runtime.   This is described in more detail below
30 and in L<perlref>.
31 X<identifier>
32
33 Perl also has its own built-in variables whose names don't follow
34 these rules.  They have strange names so they don't accidentally
35 collide with one of your normal variables.  Strings that match
36 parenthesized parts of a regular expression are saved under names
37 containing only digits after the C<$> (see L<perlop> and L<perlre>).
38 In addition, several special variables that provide windows into
39 the inner working of Perl have names containing punctuation characters
40 and control characters.  These are documented in L<perlvar>.
41 X<variable, built-in>
42
43 Scalar values are always named with '$', even when referring to a
44 scalar that is part of an array or a hash.  The '$' symbol works
45 semantically like the English word "the" in that it indicates a
46 single value is expected.
47 X<scalar>
48
49     $days               # the simple scalar value "days"
50     $days[28]           # the 29th element of array @days
51     $days{'Feb'}        # the 'Feb' value from hash %days
52     $#days              # the last index of array @days
53
54 Entire arrays (and slices of arrays and hashes) are denoted by '@',
55 which works much as the word "these" or "those" does in English,
56 in that it indicates multiple values are expected.
57 X<array>
58
59     @days               # ($days[0], $days[1],... $days[n])
60     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
61     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
62
63 Entire hashes are denoted by '%':
64 X<hash>
65
66     %days               # (key1, val1, key2, val2 ...)
67
68 In addition, subroutines are named with an initial '&', though this
69 is optional when unambiguous, just as the word "do" is often redundant
70 in English.  Symbol table entries can be named with an initial '*',
71 but you don't really care about that yet (if ever :-).
72
73 Every variable type has its own namespace, as do several
74 non-variable identifiers.  This means that you can, without fear
75 of conflict, use the same name for a scalar variable, an array, or
76 a hash--or, for that matter, for a filehandle, a directory handle, a
77 subroutine name, a format name, or a label.  This means that $foo
78 and @foo are two different variables.  It also means that C<$foo[1]>
79 is a part of @foo, not a part of $foo.  This may seem a bit weird,
80 but that's okay, because it is weird.
81 X<namespace>
82
83 Because variable references always start with '$', '@', or '%', the
84 "reserved" words aren't in fact reserved with respect to variable
85 names.  They I<are> reserved with respect to labels and filehandles,
86 however, which don't have an initial special character.  You can't
87 have a filehandle named "log", for instance.  Hint: you could say
88 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
89 uppercase filehandles also improves readability and protects you
90 from conflict with future reserved words.  Case I<is> significant--"FOO",
91 "Foo", and "foo" are all different names.  Names that start with a
92 letter or underscore may also contain digits and underscores.
93 X<identifier, case sensitivity>
94 X<case>
95
96 It is possible to replace such an alphanumeric name with an expression
97 that returns a reference to the appropriate type.  For a description
98 of this, see L<perlref>.
99
100 Names that start with a digit may contain only more digits.  Names
101 that do not start with a letter, underscore, digit or a caret (i.e.
102 a control character) are limited to one character, e.g.,  C<$%> or
103 C<$$>.  (Most of these one character names have a predefined
104 significance to Perl.  For instance, C<$$> is the current process
105 id.)
106
107 =head2 Context
108 X<context> X<scalar context> X<list context>
109
110 The interpretation of operations and values in Perl sometimes depends
111 on the requirements of the context around the operation or value.
112 There are two major contexts: list and scalar.  Certain operations
113 return list values in contexts wanting a list, and scalar values
114 otherwise.  If this is true of an operation it will be mentioned in
115 the documentation for that operation.  In other words, Perl overloads
116 certain operations based on whether the expected return value is
117 singular or plural.  Some words in English work this way, like "fish"
118 and "sheep".
119
120 In a reciprocal fashion, an operation provides either a scalar or a
121 list context to each of its arguments.  For example, if you say
122
123     int( <STDIN> )
124
125 the integer operation provides scalar context for the <>
126 operator, which responds by reading one line from STDIN and passing it
127 back to the integer operation, which will then find the integer value
128 of that line and return that.  If, on the other hand, you say
129
130     sort( <STDIN> )
131
132 then the sort operation provides list context for <>, which
133 will proceed to read every line available up to the end of file, and
134 pass that list of lines back to the sort routine, which will then
135 sort those lines and return them as a list to whatever the context
136 of the sort was.
137
138 Assignment is a little bit special in that it uses its left argument
139 to determine the context for the right argument.  Assignment to a
140 scalar evaluates the right-hand side in scalar context, while
141 assignment to an array or hash evaluates the righthand side in list
142 context.  Assignment to a list (or slice, which is just a list
143 anyway) also evaluates the right-hand side in list context.
144
145 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
146 option, you may see warnings
147 about useless uses of constants or functions in "void context".
148 Void context just means the value has been discarded, such as a
149 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
150 counts as scalar context for functions that care whether or not
151 they're being called in list context.
152
153 User-defined subroutines may choose to care whether they are being
154 called in a void, scalar, or list context.  Most subroutines do not
155 need to bother, though.  That's because both scalars and lists are
156 automatically interpolated into lists.  See L<perlfunc/wantarray>
157 for how you would dynamically discern your function's calling
158 context.
159
160 =head2 Scalar values
161 X<scalar> X<number> X<string> X<reference>
162
163 All data in Perl is a scalar, an array of scalars, or a hash of
164 scalars.  A scalar may contain one single value in any of three
165 different flavors: a number, a string, or a reference.  In general,
166 conversion from one form to another is transparent.  Although a
167 scalar may not directly hold multiple values, it may contain a
168 reference to an array or hash which in turn contains multiple values.
169
170 Scalars aren't necessarily one thing or another.  There's no place
171 to declare a scalar variable to be of type "string", type "number",
172 type "reference", or anything else.  Because of the automatic
173 conversion of scalars, operations that return scalars don't need
174 to care (and in fact, cannot care) whether their caller is looking
175 for a string, a number, or a reference.  Perl is a contextually
176 polymorphic language whose scalars can be strings, numbers, or
177 references (which includes objects).  Although strings and numbers
178 are considered pretty much the same thing for nearly all purposes,
179 references are strongly-typed, uncastable pointers with builtin
180 reference-counting and destructor invocation.
181
182 A scalar value is interpreted as TRUE in the Boolean sense if it is not
183 the null string or the number 0 (or its string equivalent, "0").  The
184 Boolean context is just a special kind of scalar context where no 
185 conversion to a string or a number is ever performed.
186 X<boolean> X<bool> X<true> X<false> X<truth>
187
188 There are actually two varieties of null strings (sometimes referred
189 to as "empty" strings), a defined one and an undefined one.  The
190 defined version is just a string of length zero, such as C<"">.
191 The undefined version is the value that indicates that there is
192 no real value for something, such as when there was an error, or
193 at end of file, or when you refer to an uninitialized variable or
194 element of an array or hash.  Although in early versions of Perl,
195 an undefined scalar could become defined when first used in a
196 place expecting a defined value, this no longer happens except for
197 rare cases of autovivification as explained in L<perlref>.  You can
198 use the defined() operator to determine whether a scalar value is
199 defined (this has no meaning on arrays or hashes), and the undef()
200 operator to produce an undefined value.
201 X<defined> X<undefined> X<undef> X<null> X<string, null>
202
203 To find out whether a given string is a valid non-zero number, it's
204 sometimes enough to test it against both numeric 0 and also lexical
205 "0" (although this will cause noises if warnings are on).  That's 
206 because strings that aren't numbers count as 0, just as they do in B<awk>:
207
208     if ($str == 0 && $str ne "0")  {
209         warn "That doesn't look like a number";
210     }
211
212 That method may be best because otherwise you won't treat IEEE
213 notations like C<NaN> or C<Infinity> properly.  At other times, you
214 might prefer to determine whether string data can be used numerically
215 by calling the POSIX::strtod() function or by inspecting your string
216 with a regular expression (as documented in L<perlre>).
217
218     warn "has nondigits"        if     /\D/;
219     warn "not a natural number" unless /^\d+$/;             # rejects -3
220     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
221     warn "not an integer"       unless /^[+-]?\d+$/;
222     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
223     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
224     warn "not a C float"
225         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
226
227 The length of an array is a scalar value.  You may find the length
228 of array @days by evaluating C<$#days>, as in B<csh>.  However, this
229 isn't the length of the array; it's the subscript of the last element,
230 which is a different value since there is ordinarily a 0th element.
231 Assigning to C<$#days> actually changes the length of the array.
232 Shortening an array this way destroys intervening values.  Lengthening
233 an array that was previously shortened does not recover values
234 that were in those elements.  (It used to do so in Perl 4, but we
235 had to break this to make sure destructors were called when expected.)
236 X<$#> X<array, length>
237
238 You can also gain some minuscule measure of efficiency by pre-extending
239 an array that is going to get big.  You can also extend an array
240 by assigning to an element that is off the end of the array.  You
241 can truncate an array down to nothing by assigning the null list
242 () to it.  The following are equivalent:
243
244     @whatever = ();
245     $#whatever = -1;
246
247 If you evaluate an array in scalar context, it returns the length
248 of the array.  (Note that this is not true of lists, which return
249 the last value, like the C comma operator, nor of built-in functions,
250 which return whatever they feel like returning.)  The following is
251 always true:
252 X<array, length>
253
254     scalar(@whatever) == $#whatever + 1;
255
256 Some programmers choose to use an explicit conversion so as to 
257 leave nothing to doubt:
258
259     $element_count = scalar(@whatever);
260
261 If you evaluate a hash in scalar context, it returns false if the
262 hash is empty.  If there are any key/value pairs, it returns true;
263 more precisely, the value returned is a string consisting of the
264 number of used buckets and the number of allocated buckets, separated
265 by a slash.  This is pretty much useful only to find out whether
266 Perl's internal hashing algorithm is performing poorly on your data
267 set.  For example, you stick 10,000 things in a hash, but evaluating
268 %HASH in scalar context reveals C<"1/16">, which means only one out
269 of sixteen buckets has been touched, and presumably contains all
270 10,000 of your items.  This isn't supposed to happen.  If a tied hash
271 is evaluated in scalar context, the C<SCALAR> method is called (with a
272 fallback to C<FIRSTKEY>).
273 X<hash, scalar context> X<hash, bucket> X<bucket>
274
275 You can preallocate space for a hash by assigning to the keys() function.
276 This rounds up the allocated buckets to the next power of two:
277
278     keys(%users) = 1000;                # allocate 1024 buckets
279
280 =head2 Scalar value constructors
281 X<scalar, literal> X<scalar, constant>
282
283 Numeric literals are specified in any of the following floating point or
284 integer formats:
285
286     12345
287     12345.67
288     .23E-10             # a very small number
289     3.14_15_92          # a very important number
290     4_294_967_296       # underscore for legibility
291     0xff                # hex
292     0xdead_beef         # more hex   
293     0377                # octal (only numbers, begins with 0)
294     0b011011            # binary
295
296 You are allowed to use underscores (underbars) in numeric literals
297 between digits for legibility (but not multiple underscores in a row:
298 C<23__500> is not legal; C<23_500> is).
299 You could, for example, group binary
300 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
301 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
302 X<number, literal>
303
304 String literals are usually delimited by either single or double
305 quotes.  They work much like quotes in the standard Unix shells:
306 double-quoted string literals are subject to backslash and variable
307 substitution; single-quoted strings are not (except for C<\'> and
308 C<\\>).  The usual C-style backslash rules apply for making
309 characters such as newline, tab, etc., as well as some more exotic
310 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
311 X<string, literal>
312
313 Hexadecimal, octal, or binary, representations in string literals
314 (e.g. '0xff') are not automatically converted to their integer
315 representation.  The hex() and oct() functions make these conversions
316 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
317
318 You can also embed newlines directly in your strings, i.e., they can end
319 on a different line than they begin.  This is nice, but if you forget
320 your trailing quote, the error will not be reported until Perl finds
321 another line containing the quote character, which may be much further
322 on in the script.  Variable substitution inside strings is limited to
323 scalar variables, arrays, and array or hash slices.  (In other words,
324 names beginning with $ or @, followed by an optional bracketed
325 expression as a subscript.)  The following code segment prints out "The
326 price is $Z<>100."
327 X<interpolation>
328
329     $Price = '$100';    # not interpolated
330     print "The price is $Price.\n";     # interpolated
331
332 There is no double interpolation in Perl, so the C<$100> is left as is.
333
334 By default floating point numbers substituted inside strings use the
335 dot (".")  as the decimal separator.  If C<use locale> is in effect,
336 and POSIX::setlocale() has been called, the character used for the
337 decimal separator is affected by the LC_NUMERIC locale.
338 See L<perllocale> and L<POSIX>.
339
340 As in some shells, you can enclose the variable name in braces to
341 disambiguate it from following alphanumerics (and underscores).
342 You must also do
343 this when interpolating a variable into a string to separate the
344 variable name from a following double-colon or an apostrophe, since
345 these would be otherwise treated as a package separator:
346 X<interpolation>
347
348     $who = "Larry";
349     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
350     print "We use ${who}speak when ${who}'s here.\n";
351
352 Without the braces, Perl would have looked for a $whospeak, a
353 C<$who::0>, and a C<$who's> variable.  The last two would be the
354 $0 and the $s variables in the (presumably) non-existent package
355 C<who>.
356
357 In fact, an identifier within such curlies is forced to be a string,
358 as is any simple identifier within a hash subscript.  Neither need
359 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
360 C<$days{Feb}> and the quotes will be assumed automatically.  But
361 anything more complicated in the subscript will be interpreted as an
362 expression.  This means for example that C<$version{2.0}++> is
363 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
364
365 =head3 Version Strings
366 X<version string> X<vstring> X<v-string>
367
368 A literal of the form C<v1.20.300.4000> is parsed as a string composed
369 of characters with the specified ordinals.  This form, known as
370 v-strings, provides an alternative, more readable way to construct
371 strings, rather than use the somewhat less readable interpolation form
372 C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful for representing
373 Unicode strings, and for comparing version "numbers" using the string
374 comparison operators, C<cmp>, C<gt>, C<lt> etc.  If there are two or
375 more dots in the literal, the leading C<v> may be omitted.
376
377     print v9786;              # prints SMILEY, "\x{263a}"
378     print v102.111.111;       # prints "foo"
379     print 102.111.111;        # same
380
381 Such literals are accepted by both C<require> and C<use> for
382 doing a version check.  Note that using the v-strings for IPv4
383 addresses is not portable unless you also use the
384 inet_aton()/inet_ntoa() routines of the Socket package.
385
386 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
387 are not v-strings before the C<< => >> operator (which is usually used
388 to separate a hash key from a hash value); instead they are interpreted
389 as literal strings ('v65').  They were v-strings from Perl 5.6.0 to
390 Perl 5.8.0, but that caused more confusion and breakage than good.
391 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
392 be v-strings always.
393
394 =head3 Special Literals
395 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
396 X<end> X<data> X<^D> X<^Z>
397
398 The special literals __FILE__, __LINE__, and __PACKAGE__
399 represent the current filename, line number, and package name at that
400 point in your program.  They may be used only as separate tokens; they
401 will not be interpolated into strings.  If there is no current package
402 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
403 value. (But the empty C<package;> is no longer supported, as of version
404 5.10.)
405 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<line> X<file> X<package>
406
407 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
408 may be used to indicate the logical end of the script before the actual
409 end of file.  Any following text is ignored.
410
411 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
412 where C<PACKNAME> is the package that was current when the __DATA__
413 token was encountered.  The filehandle is left open pointing to the
414 line after __DATA__.  It is the program's responsibility to
415 C<close DATA> when it is done reading from it.  For compatibility with
416 older scripts written before __DATA__ was introduced, __END__ behaves
417 like __DATA__ in the top level script (but not in files loaded with
418 C<require> or C<do>) and leaves the remaining contents of the
419 file accessible via C<main::DATA>.
420
421 See L<SelfLoader> for more description of __DATA__, and
422 an example of its use.  Note that you cannot read from the DATA
423 filehandle in a BEGIN block: the BEGIN block is executed as soon
424 as it is seen (during compilation), at which point the corresponding
425 __DATA__ (or __END__) token has not yet been seen.
426
427 =head3 Barewords
428 X<bareword>
429
430 A word that has no other interpretation in the grammar will
431 be treated as if it were a quoted string.  These are known as
432 "barewords".  As with filehandles and labels, a bareword that consists
433 entirely of lowercase letters risks conflict with future reserved
434 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
435 Perl will warn you about any such words.  Perl limits barewords (like
436 identifiers) to about 250 characters.  Future versions of Perl are likely
437 to eliminate these arbitrary limitations.
438
439 Some people may wish to outlaw barewords entirely.  If you
440 say
441
442     use strict 'subs';
443
444 then any bareword that would NOT be interpreted as a subroutine call
445 produces a compile-time error instead.  The restriction lasts to the
446 end of the enclosing block.  An inner block may countermand this
447 by saying C<no strict 'subs'>.
448
449 =head3 Array Interpolation
450 X<array, interpolation> X<interpolation, array> X<$">
451
452 Arrays and slices are interpolated into double-quoted strings
453 by joining the elements with the delimiter specified in the C<$">
454 variable (C<$LIST_SEPARATOR> if "use English;" is specified), 
455 space by default.  The following are equivalent:
456
457     $temp = join($", @ARGV);
458     system "echo $temp";
459
460     system "echo @ARGV";
461
462 Within search patterns (which also undergo double-quotish substitution)
463 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
464 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
465 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
466 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
467 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
468 and is almost always right.  If it does guess wrong, or if you're just
469 plain paranoid, you can force the correct interpretation with curly
470 braces as above.
471
472 If you're looking for the information on how to use here-documents,
473 which used to be here, that's been moved to
474 L<perlop/Quote and Quote-like Operators>.
475
476 =head2 List value constructors
477 X<list>
478
479 List values are denoted by separating individual values by commas
480 (and enclosing the list in parentheses where precedence requires it):
481
482     (LIST)
483
484 In a context not requiring a list value, the value of what appears
485 to be a list literal is simply the value of the final element, as
486 with the C comma operator.  For example,
487
488     @foo = ('cc', '-E', $bar);
489
490 assigns the entire list value to array @foo, but
491
492     $foo = ('cc', '-E', $bar);
493
494 assigns the value of variable $bar to the scalar variable $foo.
495 Note that the value of an actual array in scalar context is the
496 length of the array; the following assigns the value 3 to $foo:
497
498     @foo = ('cc', '-E', $bar);
499     $foo = @foo;                # $foo gets 3
500
501 You may have an optional comma before the closing parenthesis of a
502 list literal, so that you can say:
503
504     @foo = (
505         1,
506         2,
507         3,
508     );
509
510 To use a here-document to assign an array, one line per element,
511 you might use an approach like this:
512
513     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
514         normal tomato
515         spicy tomato
516         green chile
517         pesto
518         white wine
519     End_Lines
520
521 LISTs do automatic interpolation of sublists.  That is, when a LIST is
522 evaluated, each element of the list is evaluated in list context, and
523 the resulting list value is interpolated into LIST just as if each
524 individual element were a member of LIST.  Thus arrays and hashes lose their
525 identity in a LIST--the list
526
527     (@foo,@bar,&SomeSub,%glarch)
528
529 contains all the elements of @foo followed by all the elements of @bar,
530 followed by all the elements returned by the subroutine named SomeSub 
531 called in list context, followed by the key/value pairs of %glarch.
532 To make a list reference that does I<NOT> interpolate, see L<perlref>.
533
534 The null list is represented by ().  Interpolating it in a list
535 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
536 interpolating an array with no elements is the same as if no
537 array had been interpolated at that point.
538
539 This interpolation combines with the facts that the opening
540 and closing parentheses are optional (except when necessary for
541 precedence) and lists may end with an optional comma to mean that
542 multiple commas within lists are legal syntax. The list C<1,,3> is a
543 concatenation of two lists, C<1,> and C<3>, the first of which ends
544 with that optional comma.  C<1,,3> is C<(1,),(3)> is C<1,3> (And
545 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.)  Not that
546 we'd advise you to use this obfuscation.
547
548 A list value may also be subscripted like a normal array.  You must
549 put the list in parentheses to avoid ambiguity.  For example:
550
551     # Stat returns list value.
552     $time = (stat($file))[8];
553
554     # SYNTAX ERROR HERE.
555     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
556
557     # Find a hex digit.
558     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
559
560     # A "reverse comma operator".
561     return (pop(@foo),pop(@foo))[0];
562
563 Lists may be assigned to only when each element of the list
564 is itself legal to assign to:
565
566     ($a, $b, $c) = (1, 2, 3);
567
568     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
569
570 An exception to this is that you may assign to C<undef> in a list.
571 This is useful for throwing away some of the return values of a
572 function:
573
574     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
575
576 List assignment in scalar context returns the number of elements
577 produced by the expression on the right side of the assignment:
578
579     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
580     $x = (($foo,$bar) = f());           # set $x to f()'s return count
581
582 This is handy when you want to do a list assignment in a Boolean
583 context, because most list functions return a null list when finished,
584 which when assigned produces a 0, which is interpreted as FALSE.
585
586 It's also the source of a useful idiom for executing a function or
587 performing an operation in list context and then counting the number of
588 return values, by assigning to an empty list and then using that
589 assignment in scalar context. For example, this code:
590
591     $count = () = $string =~ /\d+/g;
592
593 will place into $count the number of digit groups found in $string.
594 This happens because the pattern match is in list context (since it
595 is being assigned to the empty list), and will therefore return a list
596 of all matching parts of the string. The list assignment in scalar
597 context will translate that into the number of elements (here, the
598 number of times the pattern matched) and assign that to $count. Note
599 that simply using
600
601     $count = $string =~ /\d+/g;
602
603 would not have worked, since a pattern match in scalar context will
604 only return true or false, rather than a count of matches.
605
606 The final element of a list assignment may be an array or a hash:
607
608     ($a, $b, @rest) = split;
609     my($a, $b, %rest) = @_;
610
611 You can actually put an array or hash anywhere in the list, but the first one
612 in the list will soak up all the values, and anything after it will become
613 undefined.  This may be useful in a my() or local().
614
615 A hash can be initialized using a literal list holding pairs of
616 items to be interpreted as a key and a value:
617
618     # same as map assignment above
619     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
620
621 While literal lists and named arrays are often interchangeable, that's
622 not the case for hashes.  Just because you can subscript a list value like
623 a normal array does not mean that you can subscript a list value as a
624 hash.  Likewise, hashes included as parts of other lists (including
625 parameters lists and return lists from functions) always flatten out into
626 key/value pairs.  That's why it's good to use references sometimes.
627
628 It is often more readable to use the C<< => >> operator between key/value
629 pairs.  The C<< => >> operator is mostly just a more visually distinctive
630 synonym for a comma, but it also arranges for its left-hand operand to be
631 interpreted as a string if it's a bareword that would be a legal simple
632 identifier. C<< => >> doesn't quote compound identifiers, that contain
633 double colons. This makes it nice for initializing hashes:
634
635     %map = (
636                  red   => 0x00f,
637                  blue  => 0x0f0,
638                  green => 0xf00,
639    );
640
641 or for initializing hash references to be used as records:
642
643     $rec = {
644                 witch => 'Mable the Merciless',
645                 cat   => 'Fluffy the Ferocious',
646                 date  => '10/31/1776',
647     };
648
649 or for using call-by-named-parameter to complicated functions:
650
651    $field = $query->radio_group(
652                name      => 'group_name',
653                values    => ['eenie','meenie','minie'],
654                default   => 'meenie',
655                linebreak => 'true',
656                labels    => \%labels
657    );
658
659 Note that just because a hash is initialized in that order doesn't
660 mean that it comes out in that order.  See L<perlfunc/sort> for examples
661 of how to arrange for an output ordering.
662
663 =head2 Subscripts
664
665 An array can be accessed one scalar at a
666 time by specifying a dollar sign (C<$>), then the
667 name of the array (without the leading C<@>), then the subscript inside
668 square brackets.  For example:
669
670     @myarray = (5, 50, 500, 5000);
671     print "The Third Element is", $myarray[2], "\n";
672
673 The array indices start with 0. A negative subscript retrieves its 
674 value from the end.  In our example, C<$myarray[-1]> would have been 
675 5000, and C<$myarray[-2]> would have been 500.
676
677 Hash subscripts are similar, only instead of square brackets curly brackets
678 are used. For example:
679
680     %scientists = 
681     (
682         "Newton" => "Isaac",
683         "Einstein" => "Albert",
684         "Darwin" => "Charles",
685         "Feynman" => "Richard",
686     );
687
688     print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
689
690 You can also subscript a list to get a single element from it:
691
692     $dir = (getpwnam("daemon"))[7];
693
694 =head2 Multi-dimensional array emulation
695
696 Multidimensional arrays may be emulated by subscripting a hash with a
697 list. The elements of the list are joined with the subscript separator
698 (see L<perlvar/$;>).
699
700     $foo{$a,$b,$c}
701
702 is equivalent to
703
704     $foo{join($;, $a, $b, $c)}
705
706 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
707
708 =head2 Slices
709 X<slice> X<array, slice> X<hash, slice>
710
711 A slice accesses several elements of a list, an array, or a hash
712 simultaneously using a list of subscripts.  It's more convenient
713 than writing out the individual elements as a list of separate
714 scalar values.
715
716     ($him, $her)   = @folks[0,-1];              # array slice
717     @them          = @folks[0 .. 3];            # array slice
718     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
719     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
720
721 Since you can assign to a list of variables, you can also assign to
722 an array or hash slice.
723
724     @days[3..5]    = qw/Wed Thu Fri/;
725     @colors{'red','blue','green'} 
726                    = (0xff0000, 0x0000ff, 0x00ff00);
727     @folks[0, -1]  = @folks[-1, 0];
728
729 The previous assignments are exactly equivalent to
730
731     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
732     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
733                    = (0xff0000, 0x0000ff, 0x00ff00);
734     ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
735
736 Since changing a slice changes the original array or hash that it's
737 slicing, a C<foreach> construct will alter some--or even all--of the
738 values of the array or hash.
739
740     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
741
742     foreach (@hash{qw[key1 key2]}) {
743         s/^\s+//;           # trim leading whitespace
744         s/\s+$//;           # trim trailing whitespace
745         s/(\w+)/\u\L$1/g;   # "titlecase" words
746     }
747
748 A slice of an empty list is still an empty list.  Thus:
749
750     @a = ()[1,0];           # @a has no elements
751     @b = (@a)[0,1];         # @b has no elements
752     @c = (0,1)[2,3];        # @c has no elements
753
754 But:
755
756     @a = (1)[1,0];          # @a has two elements
757     @b = (1,undef)[1,0,2];  # @b has three elements
758
759 This makes it easy to write loops that terminate when a null list
760 is returned:
761
762     while ( ($home, $user) = (getpwent)[7,0]) {
763         printf "%-8s %s\n", $user, $home;
764     }
765
766 As noted earlier in this document, the scalar sense of list assignment
767 is the number of elements on the right-hand side of the assignment.
768 The null list contains no elements, so when the password file is
769 exhausted, the result is 0, not 2.
770
771 Slices in scalar context return the last item of the slice.
772
773     @a = qw/first second third/;
774     %h = (first => 'A', second => 'B');
775     $t = @a[0, 1];                  # $t is now 'second'
776     $u = @h{'first', 'second'};     # $u is now 'B'
777
778 If you're confused about why you use an '@' there on a hash slice
779 instead of a '%', think of it like this.  The type of bracket (square
780 or curly) governs whether it's an array or a hash being looked at.
781 On the other hand, the leading symbol ('$' or '@') on the array or
782 hash indicates whether you are getting back a singular value (a
783 scalar) or a plural one (a list).
784
785 =head2 Typeglobs and Filehandles
786 X<typeglob> X<filehandle> X<*>
787
788 Perl uses an internal type called a I<typeglob> to hold an entire
789 symbol table entry.  The type prefix of a typeglob is a C<*>, because
790 it represents all types.  This used to be the preferred way to
791 pass arrays and hashes by reference into a function, but now that
792 we have real references, this is seldom needed.  
793
794 The main use of typeglobs in modern Perl is create symbol table aliases.
795 This assignment:
796
797     *this = *that;
798
799 makes $this an alias for $that, @this an alias for @that, %this an alias
800 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
801 This:
802
803     local *Here::blue = \$There::green;
804
805 temporarily makes $Here::blue an alias for $There::green, but doesn't
806 make @Here::blue an alias for @There::green, or %Here::blue an alias for
807 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
808 of this.  Strange though this may seem, this is the basis for the whole
809 module import/export system.
810
811 Another use for typeglobs is to pass filehandles into a function or
812 to create new filehandles.  If you need to use a typeglob to save away
813 a filehandle, do it this way:
814
815     $fh = *STDOUT;
816
817 or perhaps as a real reference, like this:
818
819     $fh = \*STDOUT;
820
821 See L<perlsub> for examples of using these as indirect filehandles
822 in functions.
823
824 Typeglobs are also a way to create a local filehandle using the local()
825 operator.  These last until their block is exited, but may be passed back.
826 For example:
827
828     sub newopen {
829         my $path = shift;
830         local  *FH;  # not my!
831         open   (FH, $path)          or  return undef;
832         return *FH;
833     }
834     $fh = newopen('/etc/passwd');
835
836 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
837 for filehandle manipulations, although they're still needed to pass brand
838 new file and directory handles into or out of functions. That's because
839 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
840 In other words, C<*FH> must be used to create new symbol table entries;
841 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
842
843 All functions that are capable of creating filehandles (open(),
844 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
845 automatically create an anonymous filehandle if the handle passed to
846 them is an uninitialized scalar variable. This allows the constructs
847 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
848 create filehandles that will conveniently be closed automatically when
849 the scope ends, provided there are no other references to them. This
850 largely eliminates the need for typeglobs when opening filehandles
851 that must be passed around, as in the following example:
852
853     sub myopen {
854         open my $fh, "@_"
855              or die "Can't open '@_': $!";
856         return $fh;
857     }
858
859     {
860         my $f = myopen("</etc/motd");
861         print <$f>;
862         # $f implicitly closed here
863     }
864
865 Note that if an initialized scalar variable is used instead the
866 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
867 to C<open( *{'zzz'}, ...)>.
868 C<use strict 'refs'> forbids such practice.
869
870 Another way to create anonymous filehandles is with the Symbol
871 module or with the IO::Handle module and its ilk.  These modules
872 have the advantage of not hiding different types of the same name
873 during the local().  See the bottom of L<perlfunc/open> for an
874 example.
875
876 =head1 SEE ALSO
877
878 See L<perlvar> for a description of Perl's built-in variables and
879 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
880 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
881 the C<*foo{THING}> syntax.