lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_05';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     $CommandSet
 631     $CreateTTY
 632     $DBGR
 633     @dbline
 634     $dbline
 635     %dbline
 636     $dieLevel
 637     $filename
 638     $histfile
 639     $histsize
 640     $IN
 641     $inhibit_exit
 642     @ini_INC
 643     $ini_warn
 644     $maxtrace
 645     $od
 646     @options
 647     $osingle
 648     $otrace
 649     $pager
 650     $post
 651     %postponed
 652     $prc
 653     $pre
 654     $pretype
 655     $psh
 656     @RememberOnROptions
 657     $remoteport
 658     @res
 659     $rl
 660     @saved
 661     $signalLevel
 662     $sub
 663     $term
 664     $usercontext
 665     $warnLevel
 666 );
 667
 668 our (
 669     @cmdfhs,
 670     $evalarg,
 671     $frame,
 672     $hist,
 673     $ImmediateStop,
 674     $line,
 675     $onetimeDump,
 676     $onetimedumpDepth,
 677     %option,
 678     $OUT,
 679     $packname,
 680     $signal,
 681     $single,
 682     $start,
 683     %sub,
 684     $subname,
 685     $trace,
 686     $window,
 687 );
 688
 689 # Used to save @ARGV and extract any debugger-related flags.
 690 use vars qw(@ARGS);
 691
 692 # Used to prevent multiple entries to diesignal()
 693 # (if for instance diesignal() itself dies)
 694 use vars qw($panic);
 695
 696 # Used to prevent the debugger from running nonstop
 697 # after a restart
 698 our ($second_time);
 699
 700 sub _calc_usercontext {
 701     my ($package) = @_;
 702
 703     # Cancel strict completely for the evaluated code, so the code
 704     # the user evaluates won't be affected by it. (Shlomi Fish)
 705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 706     . "package $package;";    # this won't let them modify, alas
 707 }
 708
 709 sub eval {
 710
 711     # 'my' would make it visible from user code
 712     #    but so does local! --tchrist
 713     # Remember: this localizes @DB::res, not @main::res.
 714     local @res;
 715     {
 716
 717         # Try to keep the user code from messing  with us. Save these so that
 718         # even if the eval'ed code changes them, we can put them back again.
 719         # Needed because the user could refer directly to the debugger's
 720         # package globals (and any 'my' variables in this containing scope)
 721         # inside the eval(), and we want to try to stay safe.
 722         local $otrace  = $trace;
 723         local $osingle = $single;
 724         local $od      = $^D;
 725
 726         # Untaint the incoming eval() argument.
 727         { ($evalarg) = $evalarg =~ /(.*)/s; }
 728
 729         # $usercontext built in DB::DB near the comment
 730         # "set up the context for DB::eval ..."
 731         # Evaluate and save any results.
 732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 733
 734         # Restore those old values.
 735         $trace  = $otrace;
 736         $single = $osingle;
 737         $^D     = $od;
 738     }
 739
 740     # Save the current value of $@, and preserve it in the debugger's copy
 741     # of the saved precious globals.
 742     my $at = $@;
 743
 744     # Since we're only saving $@, we only have to localize the array element
 745     # that it will be stored in.
 746     local $saved[0];    # Preserve the old value of $@
 747     eval { DB::save() };
 748
 749     # Now see whether we need to report an error back to the user.
 750     if ($at) {
 751         local $\ = '';
 752         print $OUT $at;
 753     }
 754
 755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 756     # are package globals.
 757     elsif ($onetimeDump) {
 758         if ( $onetimeDump eq 'dump' ) {
 759             local $option{dumpDepth} = $onetimedumpDepth
 760               if defined $onetimedumpDepth;
 761             dumpit( $OUT, \@res );
 762         }
 763         elsif ( $onetimeDump eq 'methods' ) {
 764             methods( $res[0] );
 765         }
 766     } ## end elsif ($onetimeDump)
 767     @res;
 768 } ## end sub eval
 769
 770 ############################################## End lexical danger zone
 771
 772 # After this point it is safe to introduce lexicals.
 773 # The code being debugged will be executing in its own context, and
 774 # can't see the inside of the debugger.
 775 #
 776 # However, one should not overdo it: leave as much control from outside as
 777 # possible. If you make something a lexical, it's not going to be addressable
 778 # from outside the debugger even if you know its name.
 779
 780 # This file is automatically included if you do perl -d.
 781 # It's probably not useful to include this yourself.
 782 #
 783 # Before venturing further into these twisty passages, it is
 784 # wise to read the perldebguts man page or risk the ire of dragons.
 785 #
 786 # (It should be noted that perldebguts will tell you a lot about
 787 # the underlying mechanics of how the debugger interfaces into the
 788 # Perl interpreter, but not a lot about the debugger itself. The new
 789 # comments in this code try to address this problem.)
 790
 791 # Note that no subroutine call is possible until &DB::sub is defined
 792 # (for subroutines defined outside of the package DB). In fact the same is
 793 # true if $deep is not defined.
 794
 795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 796
 797 # modified Perl debugger, to be run from Emacs in perldb-mode
 798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 799 # Johan Vromans -- upgrade to 4.0 pl 10
 800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 801 ########################################################################
 802
 803 =head1 DEBUGGER INITIALIZATION
 804
 805 The debugger starts up in phases.
 806
 807 =head2 BASIC SETUP
 808
 809 First, it initializes the environment it wants to run in: turning off
 810 warnings during its own compilation, defining variables which it will need
 811 to avoid warnings later, setting itself up to not exit when the program
 812 terminates, and defaulting to printing return values for the C<r> command.
 813
 814 =cut
 815
 816 # Needed for the statement after exec():
 817 #
 818 # This BEGIN block is simply used to switch off warnings during debugger
 819 # compilation. Probably it would be better practice to fix the warnings,
 820 # but this is how it's done at the moment.
 821
 822 BEGIN {
 823     $ini_warn = $^W;
 824     $^W       = 0;
 825 }    # Switch compilation warnings off until another BEGIN.
 826
 827 local ($^W) = 0;    # Switch run-time warnings off during init.
 828
 829 =head2 THREADS SUPPORT
 830
 831 If we are running under a threaded Perl, we require threads and threads::shared
 832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 833 threaded debugger control.  C<-dt> can also be used to set this.
 834
 835 Each new thread will be announced and the debugger prompt will always inform
 836 you of each new thread created.  It will also indicate the thread id in which
 837 we are currently running within the prompt like this:
 838
 839     [tid] DB<$i>
 840
 841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 842 command prompt.  The prompt will show: C<[0]> when running under threads, but
 843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 844
 845 While running under threads, when you set or delete a breakpoint (etc.), this
 846 will apply to all threads, not just the currently running one.  When you are
 847 in a currently executing thread, you will stay there until it completes.  With
 848 the current implementation it is not currently possible to hop from one thread
 849 to another.
 850
 851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 852
 853 Note that threading support was built into the debugger as of Perl version
 854 C<5.8.6> and debugger version C<1.2.8>.
 855
 856 =cut
 857
 858 BEGIN {
 859     # ensure we can share our non-threaded variables or no-op
 860     if ($ENV{PERL5DB_THREADED}) {
 861         require threads;
 862         require threads::shared;
 863         import threads::shared qw(share);
 864         $DBGR;
 865         share(\$DBGR);
 866         lock($DBGR);
 867         print "Threads support enabled\n";
 868     } else {
 869         *share = sub(\[$@%]) {};
 870     }
 871 }
 872
 873 # These variables control the execution of 'dumpvar.pl'.
 874 {
 875     package dumpvar;
 876     use vars qw(
 877     $hashDepth
 878     $arrayDepth
 879     $dumpDBFiles
 880     $dumpPackages
 881     $quoteHighBit
 882     $printUndef
 883     $globPrint
 884     $usageOnly
 885     );
 886 }
 887
 888 # used to control die() reporting in diesignal()
 889 {
 890     package Carp;
 891     use vars qw($CarpLevel);
 892 }
 893
 894 # without threads, $filename is not defined until DB::DB is called
 895 share($main::{'_<'.$filename}) if defined $filename;
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 our ($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(%postponed_file @typeahead);
1381
1382 our (@hist, @truehist);
1383
1384 sub _restore_shared_globals_after_restart
1385 {
1386     @hist          = get_list('PERLDB_HIST');
1387     %break_on_load = get_list("PERLDB_ON_LOAD");
1388     %postponed     = get_list("PERLDB_POSTPONE");
1389
1390     share(@hist);
1391     share(@truehist);
1392     share(%break_on_load);
1393     share(%postponed);
1394 }
1395
1396 sub _restore_breakpoints_and_actions {
1397
1398     my @had_breakpoints = get_list("PERLDB_VISITED");
1399
1400     for my $file_idx ( 0 .. $#had_breakpoints ) {
1401         my $filename = $had_breakpoints[$file_idx];
1402         my %pf = get_list("PERLDB_FILE_$file_idx");
1403         $postponed_file{ $filename } = \%pf if %pf;
1404         my @lines = sort {$a <=> $b} keys(%pf);
1405         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1406         for my $line_idx (0 .. $#lines) {
1407             _set_breakpoint_enabled_status(
1408                 $filename,
1409                 $lines[$line_idx],
1410                 ($enabled_statuses[$line_idx] ? 1 : ''),
1411             );
1412         }
1413     }
1414
1415     return;
1416 }
1417
1418 sub _restore_options_after_restart
1419 {
1420     my %options_map = get_list("PERLDB_OPT");
1421
1422     while ( my ( $opt, $val ) = each %options_map ) {
1423         $val =~ s/[\\\']/\\$1/g;
1424         parse_options("$opt'$val'");
1425     }
1426
1427     return;
1428 }
1429
1430 sub _restore_globals_after_restart
1431 {
1432     # restore original @INC
1433     @INC     = get_list("PERLDB_INC");
1434     @ini_INC = @INC;
1435
1436     # return pre/postprompt actions and typeahead buffer
1437     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1438     $pre       = [ get_list("PERLDB_PRE") ];
1439     $post      = [ get_list("PERLDB_POST") ];
1440     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1441
1442     return;
1443 }
1444
1445
1446 if ( exists $ENV{PERLDB_RESTART} ) {
1447
1448     # We're restarting, so we don't need the flag that says to restart anymore.
1449     delete $ENV{PERLDB_RESTART};
1450
1451     # $restart = 1;
1452     _restore_shared_globals_after_restart();
1453
1454     _restore_breakpoints_and_actions();
1455
1456     # restore options
1457     _restore_options_after_restart();
1458
1459     _restore_globals_after_restart();
1460 } ## end if (exists $ENV{PERLDB_RESTART...
1461
1462 =head2 SETTING UP THE TERMINAL
1463
1464 Now, we'll decide how the debugger is going to interact with the user.
1465 If there's no TTY, we set the debugger to run non-stop; there's not going
1466 to be anyone there to enter commands.
1467
1468 =cut
1469
1470 use vars qw($notty $console $tty $LINEINFO);
1471 use vars qw($lineinfo $doccmd);
1472
1473 our ($runnonstop);
1474
1475 if ($notty) {
1476     $runnonstop = 1;
1477     share($runnonstop);
1478 }
1479
1480 =pod
1481
1482 If there is a TTY, we have to determine who it belongs to before we can
1483 proceed. If this is a slave editor or graphical debugger (denoted by
1484 the first command-line switch being '-emacs'), we shift this off and
1485 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1486
1487 =cut
1488
1489 else {
1490
1491     # Is Perl being run from a slave editor or graphical debugger?
1492     # If so, don't use readline, and set $slave_editor = 1.
1493     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1494         $rl = 0;
1495         shift(@main::ARGV);
1496     }
1497
1498     #require Term::ReadLine;
1499
1500 =pod
1501
1502 We then determine what the console should be on various systems:
1503
1504 =over 4
1505
1506 =item * Cygwin - We use C<stdin> instead of a separate device.
1507
1508 =cut
1509
1510     if ( $^O eq 'cygwin' ) {
1511
1512         # /dev/tty is binary. use stdin for textmode
1513         undef $console;
1514     }
1515
1516 =item * Unix - use C</dev/tty>.
1517
1518 =cut
1519
1520     elsif ( -e "/dev/tty" ) {
1521         $console = "/dev/tty";
1522     }
1523
1524 =item * Windows or MSDOS - use C<con>.
1525
1526 =cut
1527
1528     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1529         $console = "con";
1530     }
1531
1532 =item * VMS - use C<sys$command>.
1533
1534 =cut
1535
1536     else {
1537
1538         # everything else is ...
1539         $console = "sys\$command";
1540     }
1541
1542 =pod
1543
1544 =back
1545
1546 Several other systems don't use a specific console. We C<undef $console>
1547 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1548 with a slave editor, Epoc).
1549
1550 =cut
1551
1552     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1553
1554         # /dev/tty is binary. use stdin for textmode
1555         $console = undef;
1556     }
1557
1558     if ( $^O eq 'NetWare' ) {
1559
1560         # /dev/tty is binary. use stdin for textmode
1561         $console = undef;
1562     }
1563
1564     # In OS/2, we need to use STDIN to get textmode too, even though
1565     # it pretty much looks like Unix otherwise.
1566     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1567     {    # In OS/2
1568         $console = undef;
1569     }
1570
1571     # EPOC also falls into the 'got to use STDIN' camp.
1572     if ( $^O eq 'epoc' ) {
1573         $console = undef;
1574     }
1575
1576 =pod
1577
1578 If there is a TTY hanging around from a parent, we use that as the console.
1579
1580 =cut
1581
1582     $console = $tty if defined $tty;
1583
1584 =head2 SOCKET HANDLING
1585
1586 The debugger is capable of opening a socket and carrying out a debugging
1587 session over the socket.
1588
1589 If C<RemotePort> was defined in the options, the debugger assumes that it
1590 should try to start a debugging session on that port. It builds the socket
1591 and then tries to connect the input and output filehandles to it.
1592
1593 =cut
1594
1595     # Handle socket stuff.
1596
1597     if ( defined $remoteport ) {
1598
1599         # If RemotePort was defined in the options, connect input and output
1600         # to the socket.
1601         $IN = $OUT = connect_remoteport();
1602     } ## end if (defined $remoteport)
1603
1604 =pod
1605
1606 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1607 this is probably a situation where multiple debuggers are running (for example,
1608 a backticked command that starts up another debugger). We create a new IN and
1609 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1610 and if we can.
1611
1612 =cut
1613
1614     # Non-socket.
1615     else {
1616
1617         # Two debuggers running (probably a system or a backtick that invokes
1618         # the debugger itself under the running one). create a new IN and OUT
1619         # filehandle, and do the necessary mojo to create a new tty if we
1620         # know how, and we can.
1621         create_IN_OUT(4) if $CreateTTY & 4;
1622         if ($console) {
1623
1624             # If we have a console, check to see if there are separate ins and
1625             # outs to open. (They are assumed identical if not.)
1626
1627             my ( $i, $o ) = split /,/, $console;
1628             $o = $i unless defined $o;
1629
1630             # read/write on in, or just read, or read on STDIN.
1631             open( IN,      "+<$i" )
1632               || open( IN, "<$i" )
1633               || open( IN, "<&STDIN" );
1634
1635             # read/write/create/clobber out, or write/create/clobber out,
1636             # or merge with STDERR, or merge with STDOUT.
1637                  open( OUT, "+>$o" )
1638               || open( OUT, ">$o" )
1639               || open( OUT, ">&STDERR" )
1640               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1641
1642         } ## end if ($console)
1643         elsif ( not defined $console ) {
1644
1645             # No console. Open STDIN.
1646             open( IN, "<&STDIN" );
1647
1648             # merge with STDERR, or with STDOUT.
1649             open( OUT,      ">&STDERR" )
1650               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1651             $console = 'STDIN/OUT';
1652         } ## end elsif (not defined $console)
1653
1654         # Keep copies of the filehandles so that when the pager runs, it
1655         # can close standard input without clobbering ours.
1656         if ($console or (not defined($console))) {
1657             $IN = \*IN;
1658             $OUT = \*OUT;
1659         }
1660     } ## end elsif (from if(defined $remoteport))
1661
1662     # Unbuffer DB::OUT. We need to see responses right away.
1663     $OUT->autoflush(1);
1664
1665     # Line info goes to debugger output unless pointed elsewhere.
1666     # Pointing elsewhere makes it possible for slave editors to
1667     # keep track of file and position. We have both a filehandle
1668     # and a I/O description to keep track of.
1669     $LINEINFO = $OUT     unless defined $LINEINFO;
1670     $lineinfo = $console unless defined $lineinfo;
1671     # share($LINEINFO); # <- unable to share globs
1672     share($lineinfo);   #
1673
1674 =pod
1675
1676 To finish initialization, we show the debugger greeting,
1677 and then call the C<afterinit()> subroutine if there is one.
1678
1679 =cut
1680
1681     # Show the debugger greeting.
1682     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1683     unless ($runnonstop) {
1684         local $\ = '';
1685         local $, = '';
1686         if ( $term_pid eq '-1' ) {
1687             print $OUT "\nDaughter DB session started...\n";
1688         }
1689         else {
1690             print $OUT "\nLoading DB routines from $header\n";
1691             print $OUT (
1692                 "Editor support ",
1693                 $slave_editor ? "enabled" : "available", ".\n"
1694             );
1695             print $OUT
1696 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1697         } ## end else [ if ($term_pid eq '-1')
1698     } ## end unless ($runnonstop)
1699 } ## end else [ if ($notty)
1700
1701 # XXX This looks like a bug to me.
1702 # Why copy to @ARGS and then futz with @args?
1703 @ARGS = @ARGV;
1704 # for (@args) {
1705     # Make sure backslashes before single quotes are stripped out, and
1706     # keep args unless they are numeric (XXX why?)
1707     # s/\'/\\\'/g;                      # removed while not justified understandably
1708     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1709 # }
1710
1711 # If there was an afterinit() sub defined, call it. It will get
1712 # executed in our scope, so it can fiddle with debugger globals.
1713 if ( defined &afterinit ) {    # May be defined in $rcfile
1714     afterinit();
1715 }
1716
1717 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1718 use vars qw($I_m_init);
1719
1720 $I_m_init = 1;
1721
1722 ############################################################ Subroutines
1723
1724 =head1 SUBROUTINES
1725
1726 =head2 DB
1727
1728 This gigantic subroutine is the heart of the debugger. Called before every
1729 statement, its job is to determine if a breakpoint has been reached, and
1730 stop if so; read commands from the user, parse them, and execute
1731 them, and then send execution off to the next statement.
1732
1733 Note that the order in which the commands are processed is very important;
1734 some commands earlier in the loop will actually alter the C<$cmd> variable
1735 to create other commands to be executed later. This is all highly I<optimized>
1736 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1737 see what's happening in any given command.
1738
1739 =cut
1740
1741 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1742
1743 use vars qw(
1744     $action
1745     $cmd
1746     $file
1747     $filename_ini
1748     $finished
1749     %had_breakpoints
1750     $level
1751     $max
1752     $package
1753     $try
1754 );
1755
1756 our (
1757     %alias,
1758     $doret,
1759     $end,
1760     $fall_off_end,
1761     $incr,
1762     $laststep,
1763     $rc,
1764     $sh,
1765     $stack_depth,
1766     @stack,
1767     @to_watch,
1768     @old_watch,
1769 );
1770
1771 sub _DB__determine_if_we_should_break
1772 {
1773     # if we have something here, see if we should break.
1774     # $stop is lexical and local to this block - $action on the other hand
1775     # is global.
1776     my $stop;
1777
1778     if ( $dbline{$line}
1779         && _is_breakpoint_enabled($filename, $line)
1780         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1781     {
1782
1783         # Stop if the stop criterion says to just stop.
1784         if ( $stop eq '1' ) {
1785             $signal |= 1;
1786         }
1787
1788         # It's a conditional stop; eval it in the user's context and
1789         # see if we should stop. If so, remove the one-time sigil.
1790         elsif ($stop) {
1791             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1792             DB::eval();
1793             # If the breakpoint is temporary, then delete its enabled status.
1794             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1795                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1796             }
1797         }
1798     } ## end if ($dbline{$line} && ...
1799 }
1800
1801 sub _DB__is_finished {
1802     if ($finished and $level <= 1) {
1803         end_report();
1804         return 1;
1805     }
1806     else {
1807         return;
1808     }
1809 }
1810
1811 sub _DB__read_next_cmd
1812 {
1813     my ($tid) = @_;
1814
1815     # We have a terminal, or can get one ...
1816     if (!$term) {
1817         setterm();
1818     }
1819
1820     # ... and it belogs to this PID or we get one for this PID ...
1821     if ($term_pid != $$) {
1822         resetterm(1);
1823     }
1824
1825     # ... and we got a line of command input ...
1826     $cmd = DB::readline(
1827         "$pidprompt $tid DB"
1828         . ( '<' x $level )
1829         . ( $#hist + 1 )
1830         . ( '>' x $level ) . " "
1831     );
1832
1833     return defined($cmd);
1834 }
1835
1836 sub _DB__trim_command_and_return_first_component {
1837     my ($obj) = @_;
1838
1839     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1840     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1841
1842     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1843
1844     $obj->cmd_verb($verb);
1845     $obj->cmd_args($args);
1846
1847     return;
1848 }
1849
1850 sub _DB__handle_f_command {
1851     my ($obj) = @_;
1852
1853     if ($file = $obj->cmd_args) {
1854         # help for no arguments (old-style was return from sub).
1855         if ( !$file ) {
1856             print $OUT
1857             "The old f command is now the r command.\n";    # hint
1858             print $OUT "The new f command switches filenames.\n";
1859             next CMD;
1860         } ## end if (!$file)
1861
1862         # if not in magic file list, try a close match.
1863         if ( !defined $main::{ '_<' . $file } ) {
1864             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1865                 {
1866                     $try = substr( $try, 2 );
1867                     print $OUT "Choosing $try matching '$file':\n";
1868                     $file = $try;
1869                 }
1870             } ## end if (($try) = grep(m#^_<.*$file#...
1871         } ## end if (!defined $main::{ ...
1872
1873         # If not successfully switched now, we failed.
1874         if ( !defined $main::{ '_<' . $file } ) {
1875             print $OUT "No file matching '$file' is loaded.\n";
1876             next CMD;
1877         }
1878
1879         # We switched, so switch the debugger internals around.
1880         elsif ( $file ne $filename ) {
1881             *dbline   = $main::{ '_<' . $file };
1882             $max      = $#dbline;
1883             $filename = $file;
1884             $start    = 1;
1885             $cmd      = "l";
1886         } ## end elsif ($file ne $filename)
1887
1888         # We didn't switch; say we didn't.
1889         else {
1890             print $OUT "Already in $file.\n";
1891             next CMD;
1892         }
1893     }
1894
1895     return;
1896 }
1897
1898 sub _DB__handle_dot_command {
1899     my ($obj) = @_;
1900
1901     # . command.
1902     if ($obj->_is_full('.')) {
1903         $incr = -1;    # stay at current line
1904
1905         # Reset everything to the old location.
1906         $start    = $line;
1907         $filename = $filename_ini;
1908         *dbline   = $main::{ '_<' . $filename };
1909         $max      = $#dbline;
1910
1911         # Now where are we?
1912         print_lineinfo($obj->position());
1913         next CMD;
1914     }
1915
1916     return;
1917 }
1918
1919 sub _DB__handle_y_command {
1920     my ($obj) = @_;
1921
1922     if (my ($match_level, $match_vars)
1923         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1924
1925         # See if we've got the necessary support.
1926         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1927             my $Err = $@;
1928             _db_warn(
1929                 $Err =~ /locate/
1930                 ? "PadWalker module not found - please install\n"
1931                 : $Err
1932             );
1933             next CMD;
1934         }
1935
1936         # Load up dumpvar if we don't have it. If we can, that is.
1937         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1938         defined &main::dumpvar
1939             or print $OUT "dumpvar.pl not available.\n"
1940             and next CMD;
1941
1942         # Got all the modules we need. Find them and print them.
1943         my @vars = split( ' ', $match_vars || '' );
1944
1945         # Find the pad.
1946         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1947
1948         # Oops. Can't find it.
1949         if (my $Err = $@) {
1950             $Err =~ s/ at .*//;
1951             _db_warn($Err);
1952             next CMD;
1953         }
1954
1955         # Show the desired vars with dumplex().
1956         my $savout = select($OUT);
1957
1958         # Have dumplex dump the lexicals.
1959         foreach my $key (sort keys %$h) {
1960             dumpvar::dumplex( $key, $h->{$key},
1961                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1962                 @vars );
1963         }
1964         select($savout);
1965         next CMD;
1966     }
1967 }
1968
1969 sub _DB__handle_c_command {
1970     my ($obj) = @_;
1971
1972     my $i = $obj->cmd_args;
1973
1974     if ($i =~ m#\A[\w:]*\z#) {
1975
1976         # Hey, show's over. The debugged program finished
1977         # executing already.
1978         next CMD if _DB__is_finished();
1979
1980         # Capture the place to put a one-time break.
1981         $subname = $i;
1982
1983         #  Probably not needed, since we finish an interactive
1984         #  sub-session anyway...
1985         # local $filename = $filename;
1986         # local *dbline = *dbline; # XXX Would this work?!
1987         #
1988         # The above question wonders if localizing the alias
1989         # to the magic array works or not. Since it's commented
1990         # out, we'll just leave that to speculation for now.
1991
1992         # If the "subname" isn't all digits, we'll assume it
1993         # is a subroutine name, and try to find it.
1994         if ( $subname =~ /\D/ ) {    # subroutine name
1995             # Qualify it to the current package unless it's
1996             # already qualified.
1997             $subname = $package . "::" . $subname
1998             unless $subname =~ /::/;
1999
2000             # find_sub will return "file:line_number" corresponding
2001             # to where the subroutine is defined; we call find_sub,
2002             # break up the return value, and assign it in one
2003             # operation.
2004             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2005
2006             # Force the line number to be numeric.
2007             $i = $i + 0;
2008
2009             # If we got a line number, we found the sub.
2010             if ($i) {
2011
2012                 # Switch all the debugger's internals around so
2013                 # we're actually working with that file.
2014                 $filename = $file;
2015                 *dbline   = $main::{ '_<' . $filename };
2016
2017                 # Mark that there's a breakpoint in this file.
2018                 $had_breakpoints{$filename} |= 1;
2019
2020                 # Scan forward to the first executable line
2021                 # after the 'sub whatever' line.
2022                 $max = $#dbline;
2023                 my $_line_num = $i;
2024                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2025                 {
2026                     $_line_num++;
2027                 }
2028                 $i = $_line_num;
2029             } ## end if ($i)
2030
2031             # We didn't find a sub by that name.
2032             else {
2033                 print $OUT "Subroutine $subname not found.\n";
2034                 next CMD;
2035             }
2036         } ## end if ($subname =~ /\D/)
2037
2038         # At this point, either the subname was all digits (an
2039         # absolute line-break request) or we've scanned through
2040         # the code following the definition of the sub, looking
2041         # for an executable, which we may or may not have found.
2042         #
2043         # If $i (which we set $subname from) is non-zero, we
2044         # got a request to break at some line somewhere. On
2045         # one hand, if there wasn't any real subroutine name
2046         # involved, this will be a request to break in the current
2047         # file at the specified line, so we have to check to make
2048         # sure that the line specified really is breakable.
2049         #
2050         # On the other hand, if there was a subname supplied, the
2051         # preceding block has moved us to the proper file and
2052         # location within that file, and then scanned forward
2053         # looking for the next executable line. We have to make
2054         # sure that one was found.
2055         #
2056         # On the gripping hand, we can't do anything unless the
2057         # current value of $i points to a valid breakable line.
2058         # Check that.
2059         if ($i) {
2060
2061             # Breakable?
2062             if ( $dbline[$i] == 0 ) {
2063                 print $OUT "Line $i not breakable.\n";
2064                 next CMD;
2065             }
2066
2067             # Yes. Set up the one-time-break sigil.
2068             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2069             _enable_breakpoint_temp_enabled_status($filename, $i);
2070         } ## end if ($i)
2071
2072         # Turn off stack tracing from here up.
2073         for my $j (0 .. $stack_depth) {
2074             $stack[ $j ] &= ~1;
2075         }
2076         last CMD;
2077     }
2078
2079     return;
2080 }
2081
2082 sub _DB__handle_forward_slash_command {
2083     my ($obj) = @_;
2084
2085     # The pattern as a string.
2086     use vars qw($inpat);
2087
2088     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2089
2090         # Remove the final slash.
2091         $inpat =~ s:([^\\])/$:$1:;
2092
2093         # If the pattern isn't null ...
2094         if ( $inpat ne "" ) {
2095
2096             # Turn of warn and die procesing for a bit.
2097             local $SIG{__DIE__};
2098             local $SIG{__WARN__};
2099
2100             # Create the pattern.
2101             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2102             if ( $@ ne "" ) {
2103
2104                 # Oops. Bad pattern. No biscuit.
2105                 # Print the eval error and go back for more
2106                 # commands.
2107                 print $OUT "$@";
2108                 next CMD;
2109             }
2110             $obj->pat($inpat);
2111         } ## end if ($inpat ne "")
2112
2113         # Set up to stop on wrap-around.
2114         $end = $start;
2115
2116         # Don't move off the current line.
2117         $incr = -1;
2118
2119         my $pat = $obj->pat;
2120
2121         # Done in eval so nothing breaks if the pattern
2122         # does something weird.
2123         eval
2124         {
2125             no strict q/vars/;
2126             for (;;) {
2127                 # Move ahead one line.
2128                 ++$start;
2129
2130                 # Wrap if we pass the last line.
2131                 $start = 1 if ($start > $max);
2132
2133                 # Stop if we have gotten back to this line again,
2134                 last if ($start == $end);
2135
2136                 # A hit! (Note, though, that we are doing
2137                 # case-insensitive matching. Maybe a qr//
2138                 # expression would be better, so the user could
2139                 # do case-sensitive matching if desired.
2140                 if ($dbline[$start] =~ m/$pat/i) {
2141                     if ($slave_editor) {
2142                         # Handle proper escaping in the slave.
2143                         print $OUT "\032\032$filename:$start:0\n";
2144                     }
2145                     else {
2146                         # Just print the line normally.
2147                         print $OUT "$start:\t",$dbline[$start],"\n";
2148                     }
2149                     # And quit since we found something.
2150                     last;
2151                 }
2152             }
2153         };
2154
2155         if ($@) {
2156             warn $@;
2157         }
2158
2159         # If we wrapped, there never was a match.
2160         if ( $start == $end ) {
2161             print {$OUT} "/$pat/: not found\n";
2162         }
2163         next CMD;
2164     }
2165
2166     return;
2167 }
2168
2169 sub _DB__handle_question_mark_command {
2170     my ($obj) = @_;
2171
2172     # ? - backward pattern search.
2173     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2174
2175         # Get the pattern, remove trailing question mark.
2176         $inpat =~ s:([^\\])\?$:$1:;
2177
2178         # If we've got one ...
2179         if ( $inpat ne "" ) {
2180
2181             # Turn off die & warn handlers.
2182             local $SIG{__DIE__};
2183             local $SIG{__WARN__};
2184             eval '$inpat =~ m' . "\a$inpat\a";
2185
2186             if ( $@ ne "" ) {
2187
2188                 # Ouch. Not good. Print the error.
2189                 print $OUT $@;
2190                 next CMD;
2191             }
2192             $obj->pat($inpat);
2193         } ## end if ($inpat ne "")
2194
2195         # Where we are now is where to stop after wraparound.
2196         $end = $start;
2197
2198         # Don't move away from this line.
2199         $incr = -1;
2200
2201         my $pat = $obj->pat;
2202         # Search inside the eval to prevent pattern badness
2203         # from killing us.
2204         eval {
2205             no strict q/vars/;
2206             for (;;) {
2207                 # Back up a line.
2208                 --$start;
2209
2210                 # Wrap if we pass the first line.
2211
2212                 $start = $max if ($start <= 0);
2213
2214                 # Quit if we get back where we started,
2215                 last if ($start == $end);
2216
2217                 # Match?
2218                 if ($dbline[$start] =~ m/$pat/i) {
2219                     if ($slave_editor) {
2220                         # Yep, follow slave editor requirements.
2221                         print $OUT "\032\032$filename:$start:0\n";
2222                     }
2223                     else {
2224                         # Yep, just print normally.
2225                         print $OUT "$start:\t",$dbline[$start],"\n";
2226                     }
2227
2228                     # Found, so done.
2229                     last;
2230                 }
2231             }
2232         };
2233
2234         # Say we failed if the loop never found anything,
2235         if ( $start == $end ) {
2236             print {$OUT} "?$pat?: not found\n";
2237         }
2238         next CMD;
2239     }
2240
2241     return;
2242 }
2243
2244 sub _DB__handle_restart_and_rerun_commands {
2245     my ($obj) = @_;
2246
2247     my $cmd_cmd = $obj->cmd_verb;
2248     my $cmd_params = $obj->cmd_args;
2249     # R - restart execution.
2250     # rerun - controlled restart execution.
2251     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2252         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2253
2254         # Close all non-system fds for a clean restart.  A more
2255         # correct method would be to close all fds that were not
2256         # open when the process started, but this seems to be
2257         # hard.  See "debugger 'R'estart and open database
2258         # connections" on p5p.
2259
2260         my $max_fd = 1024; # default if POSIX can't be loaded
2261         if (eval { require POSIX }) {
2262             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2263         }
2264
2265         if (defined $max_fd) {
2266             foreach ($^F+1 .. $max_fd-1) {
2267                 next unless open FD_TO_CLOSE, "<&=$_";
2268                 close(FD_TO_CLOSE);
2269             }
2270         }
2271
2272         # And run Perl again.  We use exec() to keep the
2273         # PID stable (and that way $ini_pids is still valid).
2274         exec(@args) or print {$OUT} "exec failed: $!\n";
2275
2276         last CMD;
2277     }
2278
2279     return;
2280 }
2281
2282 sub _DB__handle_run_command_in_pager_command {
2283     my ($obj) = @_;
2284
2285     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2286         if ( $pager =~ /^\|/ ) {
2287
2288             # Default pager is into a pipe. Redirect I/O.
2289             open( SAVEOUT, ">&STDOUT" )
2290             || _db_warn("Can't save STDOUT");
2291             open( STDOUT, ">&OUT" )
2292             || _db_warn("Can't redirect STDOUT");
2293         } ## end if ($pager =~ /^\|/)
2294         else {
2295
2296             # Not into a pipe. STDOUT is safe.
2297             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2298         }
2299
2300         # Fix up environment to record we have less if so.
2301         fix_less();
2302
2303         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2304
2305             # Couldn't open pipe to pager.
2306             _db_warn("Can't pipe output to '$pager'");
2307             if ( $pager =~ /^\|/ ) {
2308
2309                 # Redirect I/O back again.
2310                 open( OUT, ">&STDOUT" )    # XXX: lost message
2311                 || _db_warn("Can't restore DB::OUT");
2312                 open( STDOUT, ">&SAVEOUT" )
2313                 || _db_warn("Can't restore STDOUT");
2314                 close(SAVEOUT);
2315             } ## end if ($pager =~ /^\|/)
2316             else {
2317
2318                 # Redirect I/O. STDOUT already safe.
2319                 open( OUT, ">&STDOUT" )    # XXX: lost message
2320                 || _db_warn("Can't restore DB::OUT");
2321             }
2322             next CMD;
2323         } ## end unless ($piped = open(OUT,...
2324
2325         # Set up broken-pipe handler if necessary.
2326         $SIG{PIPE} = \&DB::catch
2327         if $pager =~ /^\|/
2328         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2329
2330         OUT->autoflush(1);
2331         # Save current filehandle, and put it back.
2332         $obj->selected(scalar( select(OUT) ));
2333         # Don't put it back if pager was a pipe.
2334         if ($cmd !~ /\A\|\|/)
2335         {
2336             select($obj->selected());
2337             $obj->selected("");
2338         }
2339
2340         # Trim off the pipe symbols and run the command now.
2341         $cmd =~ s#\A\|+\s*##;
2342         redo PIPE;
2343     }
2344
2345     return;
2346 }
2347
2348 sub _DB__handle_m_command {
2349     my ($obj) = @_;
2350
2351     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2352         methods($1);
2353         next CMD;
2354     }
2355
2356     # m expr - set up DB::eval to do the work
2357     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2358         $onetimeDump = 'methods';   #  method output gets used there
2359     }
2360
2361     return;
2362 }
2363
2364 sub _DB__at_end_of_every_command {
2365     my ($obj) = @_;
2366
2367     # At the end of every command:
2368     if ($obj->piped) {
2369
2370         # Unhook the pipe mechanism now.
2371         if ( $pager =~ /^\|/ ) {
2372
2373             # No error from the child.
2374             $? = 0;
2375
2376             # we cannot warn here: the handle is missing --tchrist
2377             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2378
2379             # most of the $? crud was coping with broken cshisms
2380             # $? is explicitly set to 0, so this never runs.
2381             if ($?) {
2382                 print SAVEOUT "Pager '$pager' failed: ";
2383                 if ( $? == -1 ) {
2384                     print SAVEOUT "shell returned -1\n";
2385                 }
2386                 elsif ( $? >> 8 ) {
2387                     print SAVEOUT ( $? & 127 )
2388                     ? " (SIG#" . ( $? & 127 ) . ")"
2389                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2390                 }
2391                 else {
2392                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2393                 }
2394             } ## end if ($?)
2395
2396             # Reopen filehandle for our output (if we can) and
2397             # restore STDOUT (if we can).
2398             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2399             open( STDOUT, ">&SAVEOUT" )
2400             || _db_warn("Can't restore STDOUT");
2401
2402             # Turn off pipe exception handler if necessary.
2403             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2404
2405             # Will stop ignoring SIGPIPE if done like nohup(1)
2406             # does SIGINT but Perl doesn't give us a choice.
2407         } ## end if ($pager =~ /^\|/)
2408         else {
2409
2410             # Non-piped "pager". Just restore STDOUT.
2411             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2412         }
2413
2414         # Close filehandle pager was using, restore the normal one
2415         # if necessary,
2416         close(SAVEOUT);
2417
2418         if ($obj->selected() ne "") {
2419             select($obj->selected);
2420             $obj->selected("");
2421         }
2422
2423         # No pipes now.
2424         $obj->piped("");
2425     } ## end if ($piped)
2426
2427     return;
2428 }
2429
2430 # 't' is type.
2431 # 'm' is method.
2432 # 'v' is the value (i.e: method name or subroutine ref).
2433 # 's' is subroutine.
2434 my %cmd_lookup =
2435 (
2436     '-' => { t => 'm', v => '_handle_dash_command', },
2437     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2438     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2439     'H' => { t => 'm', v => '_handle_H_command', },
2440     'S' => { t => 'm', v => '_handle_S_command', },
2441     'T' => { t => 'm', v => '_handle_T_command', },
2442     'W' => { t => 'm', v => '_handle_W_command', },
2443     'c' => { t => 's', v => \&_DB__handle_c_command, },
2444     'f' => { t => 's', v => \&_DB__handle_f_command, },
2445     'm' => { t => 's', v => \&_DB__handle_m_command, },
2446     'n' => { t => 'm', v => '_handle_n_command', },
2447     'p' => { t => 'm', v => '_handle_p_command', },
2448     'q' => { t => 'm', v => '_handle_q_command', },
2449     'r' => { t => 'm', v => '_handle_r_command', },
2450     's' => { t => 'm', v => '_handle_s_command', },
2451     'save' => { t => 'm', v => '_handle_save_command', },
2452     'source' => { t => 'm', v => '_handle_source_command', },
2453     't' => { t => 'm', v => '_handle_t_command', },
2454     'w' => { t => 'm', v => '_handle_w_command', },
2455     'x' => { t => 'm', v => '_handle_x_command', },
2456     'y' => { t => 's', v => \&_DB__handle_y_command, },
2457     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2458         ('X', 'V')),
2459     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2460         qw(enable disable)),
2461     (map { $_ =>
2462         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2463         } qw(R rerun)),
2464     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2465     qw(a A b B e E h i l L M o O P v w W)),
2466 );
2467
2468 sub DB {
2469
2470     # lock the debugger and get the thread id for the prompt
2471     lock($DBGR);
2472     my $tid;
2473     my $position;
2474     my ($prefix, $after, $infix);
2475     my $pat;
2476     my $explicit_stop;
2477     my $piped;
2478     my $selected;
2479
2480     if ($ENV{PERL5DB_THREADED}) {
2481         $tid = eval { "[".threads->tid."]" };
2482     }
2483
2484     my $cmd_verb;
2485     my $cmd_args;
2486
2487     my $obj = DB::Obj->new(
2488         {
2489             position => \$position,
2490             prefix => \$prefix,
2491             after => \$after,
2492             explicit_stop => \$explicit_stop,
2493             infix => \$infix,
2494             cmd_args => \$cmd_args,
2495             cmd_verb => \$cmd_verb,
2496             pat => \$pat,
2497             piped => \$piped,
2498             selected => \$selected,
2499         },
2500     );
2501
2502     $obj->_DB_on_init__initialize_globals(@_);
2503
2504     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2505     # The code being debugged may have altered them.
2506     DB::save();
2507
2508     # Since DB::DB gets called after every line, we can use caller() to
2509     # figure out where we last were executing. Sneaky, eh? This works because
2510     # caller is returning all the extra information when called from the
2511     # debugger.
2512     local ( $package, $filename, $line ) = caller;
2513     $filename_ini = $filename;
2514
2515     # set up the context for DB::eval, so it can properly execute
2516     # code on behalf of the user. We add the package in so that the
2517     # code is eval'ed in the proper package (not in the debugger!).
2518     local $usercontext = _calc_usercontext($package);
2519
2520     # Create an alias to the active file magical array to simplify
2521     # the code here.
2522     local (*dbline) = $main::{ '_<' . $filename };
2523
2524     # Last line in the program.
2525     $max = $#dbline;
2526
2527     _DB__determine_if_we_should_break(@_);
2528
2529     # Preserve the current stop-or-not, and see if any of the W
2530     # (watch expressions) has changed.
2531     my $was_signal = $signal;
2532
2533     # If we have any watch expressions ...
2534     $obj->_DB__handle_watch_expressions(@_);
2535
2536 =head2 C<watchfunction()>
2537
2538 C<watchfunction()> is a function that can be defined by the user; it is a
2539 function which will be run on each entry to C<DB::DB>; it gets the
2540 current package, filename, and line as its parameters.
2541
2542 The watchfunction can do anything it likes; it is executing in the
2543 debugger's context, so it has access to all of the debugger's internal
2544 data structures and functions.
2545
2546 C<watchfunction()> can control the debugger's actions. Any of the following
2547 will cause the debugger to return control to the user's program after
2548 C<watchfunction()> executes:
2549
2550 =over 4
2551
2552 =item *
2553
2554 Returning a false value from the C<watchfunction()> itself.
2555
2556 =item *
2557
2558 Altering C<$single> to a false value.
2559
2560 =item *
2561
2562 Altering C<$signal> to a false value.
2563
2564 =item *
2565
2566 Turning off the C<4> bit in C<$trace> (this also disables the
2567 check for C<watchfunction()>. This can be done with
2568
2569     $trace &= ~4;
2570
2571 =back
2572
2573 =cut
2574
2575     # If there's a user-defined DB::watchfunction, call it with the
2576     # current package, filename, and line. The function executes in
2577     # the DB:: package.
2578     if ( $trace & 4 ) {    # User-installed watch
2579         return
2580           if watchfunction( $package, $filename, $line )
2581           and not $single
2582           and not $was_signal
2583           and not( $trace & ~4 );
2584     } ## end if ($trace & 4)
2585
2586     # Pick up any alteration to $signal in the watchfunction, and
2587     # turn off the signal now.
2588     $was_signal = $signal;
2589     $signal     = 0;
2590
2591 =head2 GETTING READY TO EXECUTE COMMANDS
2592
2593 The debugger decides to take control if single-step mode is on, the
2594 C<t> command was entered, or the user generated a signal. If the program
2595 has fallen off the end, we set things up so that entering further commands
2596 won't cause trouble, and we say that the program is over.
2597
2598 =cut
2599
2600     # Make sure that we always print if asked for explicitly regardless
2601     # of $trace_to_depth .
2602     $explicit_stop = ($single || $was_signal);
2603
2604     # Check to see if we should grab control ($single true,
2605     # trace set appropriately, or we got a signal).
2606     if ( $explicit_stop || ( $trace & 1 ) ) {
2607         $obj->_DB__grab_control(@_);
2608     } ## end if ($single || ($trace...
2609
2610 =pod
2611
2612 If there's an action to be executed for the line we stopped at, execute it.
2613 If there are any preprompt actions, execute those as well.
2614
2615 =cut
2616
2617     # If there's an action, do it now.
2618     if ($action) {
2619         $evalarg = $action;
2620         DB::eval();
2621     }
2622
2623     # Are we nested another level (e.g., did we evaluate a function
2624     # that had a breakpoint in it at the debugger prompt)?
2625     if ( $single || $was_signal ) {
2626
2627         # Yes, go down a level.
2628         local $level = $level + 1;
2629
2630         # Do any pre-prompt actions.
2631         foreach $evalarg (@$pre) {
2632             DB::eval();
2633         }
2634
2635         # Complain about too much recursion if we passed the limit.
2636         if ($single & 4) {
2637             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2638         }
2639
2640         # The line we're currently on. Set $incr to -1 to stay here
2641         # until we get a command that tells us to advance.
2642         $start = $line;
2643         $incr  = -1;      # for backward motion.
2644
2645         # Tack preprompt debugger actions ahead of any actual input.
2646         @typeahead = ( @$pretype, @typeahead );
2647
2648 =head2 WHERE ARE WE?
2649
2650 XXX Relocate this section?
2651
2652 The debugger normally shows the line corresponding to the current line of
2653 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2654 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2655
2656 C<$incr> controls by how many lines the I<current> line should move forward
2657 after a command is executed. If set to -1, this indicates that the I<current>
2658 line shouldn't change.
2659
2660 C<$start> is the I<current> line. It is used for things like knowing where to
2661 move forwards or backwards from when doing an C<L> or C<-> command.
2662
2663 C<$max> tells the debugger where the last line of the current file is. It's
2664 used to terminate loops most often.
2665
2666 =head2 THE COMMAND LOOP
2667
2668 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2669 in two parts:
2670
2671 =over 4
2672
2673 =item *
2674
2675 The outer part of the loop, starting at the C<CMD> label. This loop
2676 reads a command and then executes it.
2677
2678 =item *
2679
2680 The inner part of the loop, starting at the C<PIPE> label. This part
2681 is wholly contained inside the C<CMD> block and only executes a command.
2682 Used to handle commands running inside a pager.
2683
2684 =back
2685
2686 So why have two labels to restart the loop? Because sometimes, it's easier to
2687 have a command I<generate> another command and then re-execute the loop to do
2688 the new command. This is faster, but perhaps a bit more convoluted.
2689
2690 =cut
2691
2692         # The big command dispatch loop. It keeps running until the
2693         # user yields up control again.
2694         #
2695         # If we have a terminal for input, and we get something back
2696         # from readline(), keep on processing.
2697
2698       CMD:
2699         while (_DB__read_next_cmd($tid))
2700         {
2701
2702             share($cmd);
2703             # ... try to execute the input as debugger commands.
2704
2705             # Don't stop running.
2706             $single = 0;
2707
2708             # No signal is active.
2709             $signal = 0;
2710
2711             # Handle continued commands (ending with \):
2712             if ($cmd =~ s/\\\z/\n/) {
2713                 $cmd .= DB::readline("  cont: ");
2714                 redo CMD;
2715             }
2716
2717 =head4 The null command
2718
2719 A newline entered by itself means I<re-execute the last command>. We grab the
2720 command out of C<$laststep> (where it was recorded previously), and copy it
2721 back into C<$cmd> to be executed below. If there wasn't any previous command,
2722 we'll do nothing below (no command will match). If there was, we also save it
2723 in the command history and fall through to allow the command parsing to pick
2724 it up.
2725
2726 =cut
2727
2728             # Empty input means repeat the last command.
2729             if ($cmd eq '') {
2730                 $cmd = $laststep;
2731             }
2732             chomp($cmd);    # get rid of the annoying extra newline
2733             if (length($cmd) >= 2) {
2734                 push( @hist, $cmd );
2735             }
2736             push( @truehist, $cmd );
2737             share(@hist);
2738             share(@truehist);
2739
2740             # This is a restart point for commands that didn't arrive
2741             # via direct user input. It allows us to 'redo PIPE' to
2742             # re-execute command processing without reading a new command.
2743           PIPE: {
2744                 _DB__trim_command_and_return_first_component($obj);
2745
2746 =head3 COMMAND ALIASES
2747
2748 The debugger can create aliases for commands (these are stored in the
2749 C<%alias> hash). Before a command is executed, the command loop looks it up
2750 in the alias hash and substitutes the contents of the alias for the command,
2751 completely replacing it.
2752
2753 =cut
2754
2755                 # See if there's an alias for the command, and set it up if so.
2756                 if ( $alias{$cmd_verb} ) {
2757
2758                     # Squelch signal handling; we want to keep control here
2759                     # if something goes loco during the alias eval.
2760                     local $SIG{__DIE__};
2761                     local $SIG{__WARN__};
2762
2763                     # This is a command, so we eval it in the DEBUGGER's
2764                     # scope! Otherwise, we can't see the special debugger
2765                     # variables, or get to the debugger's subs. (Well, we
2766                     # _could_, but why make it even more complicated?)
2767                     eval "\$cmd =~ $alias{$cmd_verb}";
2768                     if ($@) {
2769                         local $\ = '';
2770                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2771                         next CMD;
2772                     }
2773                     _DB__trim_command_and_return_first_component($obj);
2774                 } ## end if ($alias{$cmd_verb})
2775
2776 =head3 MAIN-LINE COMMANDS
2777
2778 All of these commands work up to and after the program being debugged has
2779 terminated.
2780
2781 =head4 C<q> - quit
2782
2783 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2784 try to execute further, cleaning any restart-related stuff out of the
2785 environment, and executing with the last value of C<$?>.
2786
2787 =cut
2788
2789                 # All of these commands were remapped in perl 5.8.0;
2790                 # we send them off to the secondary dispatcher (see below).
2791                 $obj->_handle_special_char_cmd_wrapper_commands;
2792                 _DB__trim_command_and_return_first_component($obj);
2793
2794                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2795                     my $type = $cmd_rec->{t};
2796                     my $val = $cmd_rec->{v};
2797                     if ($type eq 'm') {
2798                         $obj->$val();
2799                     }
2800                     elsif ($type eq 's') {
2801                         $val->($obj);
2802                     }
2803                 }
2804
2805 =head4 C<t> - trace [n]
2806
2807 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2808 If level is specified, set C<$trace_to_depth>.
2809
2810 =head4 C<S> - list subroutines matching/not matching a pattern
2811
2812 Walks through C<%sub>, checking to see whether or not to print the name.
2813
2814 =head4 C<X> - list variables in current package
2815
2816 Since the C<V> command actually processes this, just change this to the
2817 appropriate C<V> command and fall through.
2818
2819 =head4 C<V> - list variables
2820
2821 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2822
2823 =head4 C<x> - evaluate and print an expression
2824
2825 Hands the expression off to C<DB::eval>, setting it up to print the value
2826 via C<dumpvar.pl> instead of just printing it directly.
2827
2828 =head4 C<m> - print methods
2829
2830 Just uses C<DB::methods> to determine what methods are available.
2831
2832 =head4 C<f> - switch files
2833
2834 Switch to a different filename.
2835
2836 =head4 C<.> - return to last-executed line.
2837
2838 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2839 and then we look up the line in the magical C<%dbline> hash.
2840
2841 =head4 C<-> - back one window
2842
2843 We change C<$start> to be one window back; if we go back past the first line,
2844 we set it to be the first line. We ser C<$incr> to put us back at the
2845 currently-executing line, and then put a C<l $start +> (list one window from
2846 C<$start>) in C<$cmd> to be executed later.
2847
2848 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2849
2850 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2851 problems, most notably that the default case of several commands destroying
2852 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2853 retain the old commands for those who were used to using them or who preferred
2854 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2855 deal with them instead of processing them in-line.
2856
2857 =head4 C<y> - List lexicals in higher scope
2858
2859 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2860 above the current one and then displays then using C<dumpvar.pl>.
2861
2862 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2863
2864 All of the commands below this point don't work after the program being
2865 debugged has ended. All of them check to see if the program has ended; this
2866 allows the commands to be relocated without worrying about a 'line of
2867 demarcation' above which commands can be entered anytime, and below which
2868 they can't.
2869
2870 =head4 C<n> - single step, but don't trace down into subs
2871
2872 Done by setting C<$single> to 2, which forces subs to execute straight through
2873 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2874 so a null command knows what to re-execute.
2875
2876 =head4 C<s> - single-step, entering subs
2877
2878 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2879 subs. Also saves C<s> as C<$lastcmd>.
2880
2881 =head4 C<c> - run continuously, setting an optional breakpoint
2882
2883 Most of the code for this command is taken up with locating the optional
2884 breakpoint, which is either a subroutine name or a line number. We set
2885 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2886 in this and all call levels above this one.
2887
2888 =head4 C<r> - return from a subroutine
2889
2890 For C<r> to work properly, the debugger has to stop execution again
2891 immediately after the return is executed. This is done by forcing
2892 single-stepping to be on in the call level above the current one. If
2893 we are printing return values when a C<r> is executed, set C<$doret>
2894 appropriately, and force us out of the command loop.
2895
2896 =head4 C<T> - stack trace
2897
2898 Just calls C<DB::print_trace>.
2899
2900 =head4 C<w> - List window around current line.
2901
2902 Just calls C<DB::cmd_w>.
2903
2904 =head4 C<W> - watch-expression processing.
2905
2906 Just calls C<DB::cmd_W>.
2907
2908 =head4 C</> - search forward for a string in the source
2909
2910 We take the argument and treat it as a pattern. If it turns out to be a
2911 bad one, we return the error we got from trying to C<eval> it and exit.
2912 If not, we create some code to do the search and C<eval> it so it can't
2913 mess us up.
2914
2915 =cut
2916
2917                 _DB__handle_forward_slash_command($obj);
2918
2919 =head4 C<?> - search backward for a string in the source
2920
2921 Same as for C</>, except the loop runs backwards.
2922
2923 =cut
2924
2925                 _DB__handle_question_mark_command($obj);
2926
2927 =head4 C<$rc> - Recall command
2928
2929 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2930 that the terminal supports history). It find the the command required, puts it
2931 into C<$cmd>, and redoes the loop to execute it.
2932
2933 =cut
2934
2935                 # $rc - recall command.
2936                 $obj->_handle_rc_recall_command;
2937
2938 =head4 C<$sh$sh> - C<system()> command
2939
2940 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
2941 C<STDOUT> from getting messed up.
2942
2943 =cut
2944
2945                 $obj->_handle_sh_command;
2946
2947 =head4 C<$rc I<pattern> $rc> - Search command history
2948
2949 Another command to manipulate C<@hist>: this one searches it with a pattern.
2950 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2951
2952 =cut
2953
2954                 $obj->_handle_rc_search_history_command;
2955
2956 =head4 C<$sh> - Invoke a shell
2957
2958 Uses C<_db_system()> to invoke a shell.
2959
2960 =cut
2961
2962 =head4 C<$sh I<command>> - Force execution of a command in a shell
2963
2964 Like the above, but the command is passed to the shell. Again, we use
2965 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
2966
2967 =head4 C<H> - display commands in history
2968
2969 Prints the contents of C<@hist> (if any).
2970
2971 =head4 C<man, doc, perldoc> - look up documentation
2972
2973 Just calls C<runman()> to print the appropriate document.
2974
2975 =cut
2976
2977                 $obj->_handle_doc_command;
2978
2979 =head4 C<p> - print
2980
2981 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2982 the bottom of the loop.
2983
2984 =head4 C<=> - define command alias
2985
2986 Manipulates C<%alias> to add or list command aliases.
2987
2988 =head4 C<source> - read commands from a file.
2989
2990 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
2991 pick it up.
2992
2993 =head4 C<enable> C<disable> - enable or disable breakpoints
2994
2995 This enables or disables breakpoints.
2996
2997 =head4 C<save> - send current history to a file
2998
2999 Takes the complete history, (not the shrunken version you see with C<H>),
3000 and saves it to the given filename, so it can be replayed using C<source>.
3001
3002 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3003
3004 =head4 C<R> - restart
3005
3006 Restart the debugger session.
3007
3008 =head4 C<rerun> - rerun the current session
3009
3010 Return to any given position in the B<true>-history list
3011
3012 =head4 C<|, ||> - pipe output through the pager.
3013
3014 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3015 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3016 pipe to the pager (restoring the output filehandles if this fails). If this
3017 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3018 set C<$signal>, sending us back into the debugger.
3019
3020 We then trim off the pipe symbols and C<redo> the command loop at the
3021 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3022 reading another.
3023
3024 =cut
3025
3026                 # || - run command in the pager, with output to DB::OUT.
3027                 _DB__handle_run_command_in_pager_command($obj);
3028
3029 =head3 END OF COMMAND PARSING
3030
3031 Anything left in C<$cmd> at this point is a Perl expression that we want to
3032 evaluate. We'll always evaluate in the user's context, and fully qualify
3033 any variables we might want to address in the C<DB> package.
3034
3035 =cut
3036
3037             }    # PIPE:
3038
3039             # Make sure the flag that says "the debugger's running" is
3040             # still on, to make sure we get control again.
3041             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3042
3043             # Run *our* eval that executes in the caller's context.
3044             DB::eval();
3045
3046             # Turn off the one-time-dump stuff now.
3047             if ($onetimeDump) {
3048                 $onetimeDump      = undef;
3049                 $onetimedumpDepth = undef;
3050             }
3051             elsif ( $term_pid == $$ ) {
3052                 eval { # May run under miniperl, when not available...
3053                     STDOUT->flush();
3054                     STDERR->flush();
3055                 };
3056
3057                 # XXX If this is the master pid, print a newline.
3058                 print {$OUT} "\n";
3059             }
3060         } ## end while (($term || &setterm...
3061
3062 =head3 POST-COMMAND PROCESSING
3063
3064 After each command, we check to see if the command output was piped anywhere.
3065 If so, we go through the necessary code to unhook the pipe and go back to
3066 our standard filehandles for input and output.
3067
3068 =cut
3069
3070         continue {    # CMD:
3071             _DB__at_end_of_every_command($obj);
3072         }    # CMD:
3073
3074 =head3 COMMAND LOOP TERMINATION
3075
3076 When commands have finished executing, we come here. If the user closed the
3077 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3078 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3079 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3080 The interpreter will then execute the next line and then return control to us
3081 again.
3082
3083 =cut
3084
3085         # No more commands? Quit.
3086         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3087
3088         # Evaluate post-prompt commands.
3089         foreach $evalarg (@$post) {
3090             DB::eval();
3091         }
3092     }    # if ($single || $signal)
3093
3094     # Put the user's globals back where you found them.
3095     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3096     ();
3097 } ## end sub DB
3098
3099 package DB::Obj;
3100
3101 sub new {
3102     my $class = shift;
3103
3104     my $self = bless {}, $class;
3105
3106     $self->_init(@_);
3107
3108     return $self;
3109 }
3110
3111 sub _init {
3112     my ($self, $args) = @_;
3113
3114     %{$self} = (%$self, %$args);
3115
3116     return;
3117 }
3118
3119 {
3120     no strict 'refs';
3121     foreach my $slot_name (qw(
3122         after explicit_stop infix pat piped position prefix selected cmd_verb
3123         cmd_args
3124         )) {
3125         my $slot = $slot_name;
3126         *{$slot} = sub {
3127             my $self = shift;
3128
3129             if (@_) {
3130                 ${ $self->{$slot} } = shift;
3131             }
3132
3133             return ${ $self->{$slot} };
3134         };
3135
3136         *{"append_to_$slot"} = sub {
3137             my $self = shift;
3138             my $s = shift;
3139
3140             return $self->$slot($self->$slot . $s);
3141         };
3142     }
3143 }
3144
3145 sub _DB_on_init__initialize_globals
3146 {
3147     my $self = shift;
3148
3149     # Check for whether we should be running continuously or not.
3150     # _After_ the perl program is compiled, $single is set to 1:
3151     if ( $single and not $second_time++ ) {
3152
3153         # Options say run non-stop. Run until we get an interrupt.
3154         if ($runnonstop) {    # Disable until signal
3155                 # If there's any call stack in place, turn off single
3156                 # stepping into subs throughout the stack.
3157             for my $i (0 .. $stack_depth) {
3158                 $stack[ $i ] &= ~1;
3159             }
3160
3161             # And we are now no longer in single-step mode.
3162             $single = 0;
3163
3164             # If we simply returned at this point, we wouldn't get
3165             # the trace info. Fall on through.
3166             # return;
3167         } ## end if ($runnonstop)
3168
3169         elsif ($ImmediateStop) {
3170
3171             # We are supposed to stop here; XXX probably a break.
3172             $ImmediateStop = 0;    # We've processed it; turn it off
3173             $signal        = 1;    # Simulate an interrupt to force
3174                                    # us into the command loop
3175         }
3176     } ## end if ($single and not $second_time...
3177
3178     # If we're in single-step mode, or an interrupt (real or fake)
3179     # has occurred, turn off non-stop mode.
3180     $runnonstop = 0 if $single or $signal;
3181
3182     return;
3183 }
3184
3185 sub _DB__handle_watch_expressions
3186 {
3187     my $self = shift;
3188
3189     if ( $trace & 2 ) {
3190         for my $n (0 .. $#to_watch) {
3191             $evalarg = $to_watch[$n];
3192             local $onetimeDump;    # Tell DB::eval() to not output results
3193
3194             # Fix context DB::eval() wants to return an array, but
3195             # we need a scalar here.
3196             my ($val) = join( "', '", DB::eval() );
3197             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3198
3199             # Did it change?
3200             if ( $val ne $old_watch[$n] ) {
3201
3202                 # Yep! Show the difference, and fake an interrupt.
3203                 $signal = 1;
3204                 print {$OUT} <<EOP;
3205 Watchpoint $n:\t$to_watch[$n] changed:
3206     old value:\t$old_watch[$n]
3207     new value:\t$val
3208 EOP
3209                 $old_watch[$n] = $val;
3210             } ## end if ($val ne $old_watch...
3211         } ## end for my $n (0 ..
3212     } ## end if ($trace & 2)
3213
3214     return;
3215 }
3216
3217 sub _my_print_lineinfo
3218 {
3219     my ($self, $i, $incr_pos) = @_;
3220
3221     if ($frame) {
3222         # Print it indented if tracing is on.
3223         DB::print_lineinfo( ' ' x $stack_depth,
3224             "$i:\t$DB::dbline[$i]" . $self->after );
3225     }
3226     else {
3227         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3228     }
3229 }
3230
3231 sub _curr_line {
3232     return $DB::dbline[$line];
3233 }
3234
3235 sub _is_full {
3236     my ($self, $letter) = @_;
3237
3238     return ($DB::cmd eq $letter);
3239 }
3240
3241 sub _DB__grab_control
3242 {
3243     my $self = shift;
3244
3245     # Yes, grab control.
3246     if ($slave_editor) {
3247
3248         # Tell the editor to update its position.
3249         $self->position("\032\032${DB::filename}:$line:0\n");
3250         DB::print_lineinfo($self->position());
3251     }
3252
3253 =pod
3254
3255 Special check: if we're in package C<DB::fake>, we've gone through the
3256 C<END> block at least once. We set up everything so that we can continue
3257 to enter commands and have a valid context to be in.
3258
3259 =cut
3260
3261     elsif ( $DB::package eq 'DB::fake' ) {
3262
3263         # Fallen off the end already.
3264         if (!$DB::term) {
3265             DB::setterm();
3266         }
3267
3268         DB::print_help(<<EOP);
3269 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3270 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3271 B<h q>, B<h R> or B<h o> to get additional info.
3272 EOP
3273
3274         # Set the DB::eval context appropriately.
3275         $DB::package     = 'main';
3276         $DB::usercontext = DB::_calc_usercontext($DB::package);
3277     } ## end elsif ($package eq 'DB::fake')
3278
3279 =pod
3280
3281 If the program hasn't finished executing, we scan forward to the
3282 next executable line, print that out, build the prompt from the file and line
3283 number information, and print that.
3284
3285 =cut
3286
3287     else {
3288
3289
3290         # Still somewhere in the midst of execution. Set up the
3291         #  debugger prompt.
3292         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3293                              # Perl 5 ones (sorry, we don't print Klingon
3294                              #module names)
3295
3296         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3297         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3298         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3299
3300         # Break up the prompt if it's really long.
3301         if ( length($self->prefix()) > 30 ) {
3302             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3303             $self->prefix("");
3304             $self->infix(":\t");
3305         }
3306         else {
3307             $self->infix("):\t");
3308             $self->position(
3309                 $self->prefix . $line. $self->infix
3310                 . $self->_curr_line . $self->after
3311             );
3312         }
3313
3314         # Print current line info, indenting if necessary.
3315         $self->_my_print_lineinfo($line, $self->position);
3316
3317         my $i;
3318         my $line_i = sub { return $DB::dbline[$i]; };
3319
3320         # Scan forward, stopping at either the end or the next
3321         # unbreakable line.
3322         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3323         {    #{ vi
3324
3325             # Drop out on null statements, block closers, and comments.
3326             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3327
3328             # Drop out if the user interrupted us.
3329             last if $signal;
3330
3331             # Append a newline if the line doesn't have one. Can happen
3332             # in eval'ed text, for instance.
3333             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3334
3335             # Next executable line.
3336             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3337                 . $self->after;
3338             $self->append_to_position($incr_pos);
3339             $self->_my_print_lineinfo($i, $incr_pos);
3340         } ## end for ($i = $line + 1 ; $i...
3341     } ## end else [ if ($slave_editor)
3342
3343     return;
3344 }
3345
3346 sub _handle_t_command {
3347     my $self = shift;
3348
3349     my $levels = $self->cmd_args();
3350
3351     if ((!length($levels)) or ($levels !~ /\D/)) {
3352         $trace ^= 1;
3353         local $\ = '';
3354         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3355         print {$OUT} "Trace = "
3356         . ( ( $trace & 1 )
3357             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3358             : "off" ) . "\n";
3359         next CMD;
3360     }
3361
3362     return;
3363 }
3364
3365
3366 sub _handle_S_command {
3367     my $self = shift;
3368
3369     if (my ($print_all_subs, $should_reverse, $Spatt)
3370         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3371         # $Spatt is the pattern (if any) to use.
3372         # Reverse scan?
3373         my $Srev     = defined $should_reverse;
3374         # No args - print all subs.
3375         my $Snocheck = !defined $print_all_subs;
3376
3377         # Need to make these sane here.
3378         local $\ = '';
3379         local $, = '';
3380
3381         # Search through the debugger's magical hash of subs.
3382         # If $nocheck is true, just print the sub name.
3383         # Otherwise, check it against the pattern. We then use
3384         # the XOR trick to reverse the condition as required.
3385         foreach $subname ( sort( keys %sub ) ) {
3386             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3387                 print $OUT $subname, "\n";
3388             }
3389         }
3390         next CMD;
3391     }
3392
3393     return;
3394 }
3395
3396 sub _handle_V_command_and_X_command {
3397     my $self = shift;
3398
3399     $DB::cmd =~ s/^X\b/V $DB::package/;
3400
3401     # Bare V commands get the currently-being-debugged package
3402     # added.
3403     if ($self->_is_full('V')) {
3404         $DB::cmd = "V $DB::package";
3405     }
3406
3407     # V - show variables in package.
3408     if (my ($new_packname, $new_vars_str) =
3409         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3410
3411         # Save the currently selected filehandle and
3412         # force output to debugger's filehandle (dumpvar
3413         # just does "print" for output).
3414         my $savout = select($OUT);
3415
3416         # Grab package name and variables to dump.
3417         $packname = $new_packname;
3418         my @vars     = split( ' ', $new_vars_str );
3419
3420         # If main::dumpvar isn't here, get it.
3421         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3422         if ( defined &main::dumpvar ) {
3423
3424             # We got it. Turn off subroutine entry/exit messages
3425             # for the moment, along with return values.
3426             local $frame = 0;
3427             local $doret = -2;
3428
3429             # must detect sigpipe failures  - not catching
3430             # then will cause the debugger to die.
3431             eval {
3432                 main::dumpvar(
3433                     $packname,
3434                     defined $option{dumpDepth}
3435                     ? $option{dumpDepth}
3436                     : -1,    # assume -1 unless specified
3437                     @vars
3438                 );
3439             };
3440
3441             # The die doesn't need to include the $@, because
3442             # it will automatically get propagated for us.
3443             if ($@) {
3444                 die unless $@ =~ /dumpvar print failed/;
3445             }
3446         } ## end if (defined &main::dumpvar)
3447         else {
3448
3449             # Couldn't load dumpvar.
3450             print $OUT "dumpvar.pl not available.\n";
3451         }
3452
3453         # Restore the output filehandle, and go round again.
3454         select($savout);
3455         next CMD;
3456     }
3457
3458     return;
3459 }
3460
3461 sub _handle_dash_command {
3462     my $self = shift;
3463
3464     if ($self->_is_full('-')) {
3465
3466         # back up by a window; go to 1 if back too far.
3467         $start -= $incr + $window + 1;
3468         $start = 1 if $start <= 0;
3469         $incr  = $window - 1;
3470
3471         # Generate and execute a "l +" command (handled below).
3472         $DB::cmd = 'l ' . ($start) . '+';
3473         redo CMD;
3474     }
3475     return;
3476 }
3477
3478 sub _n_or_s_commands_generic {
3479     my ($self, $new_val) = @_;
3480     # n - next
3481     next CMD if DB::_DB__is_finished();
3482
3483     # Single step, but don't enter subs.
3484     $single = $new_val;
3485
3486     # Save for empty command (repeat last).
3487     $laststep = $DB::cmd;
3488     last CMD;
3489 }
3490
3491 sub _n_or_s {
3492     my ($self, $letter, $new_val) = @_;
3493
3494     if ($self->_is_full($letter)) {
3495         $self->_n_or_s_commands_generic($new_val);
3496     }
3497     else {
3498         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3499     }
3500
3501     return;
3502 }
3503
3504 sub _handle_n_command {
3505     my $self = shift;
3506
3507     return $self->_n_or_s('n', 2);
3508 }
3509
3510 sub _handle_s_command {
3511     my $self = shift;
3512
3513     return $self->_n_or_s('s', 1);
3514 }
3515
3516 sub _handle_r_command {
3517     my $self = shift;
3518
3519     # r - return from the current subroutine.
3520     if ($self->_is_full('r')) {
3521
3522         # Can't do anything if the program's over.
3523         next CMD if DB::_DB__is_finished();
3524
3525         # Turn on stack trace.
3526         $stack[$stack_depth] |= 1;
3527
3528         # Print return value unless the stack is empty.
3529         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3530         last CMD;
3531     }
3532
3533     return;
3534 }
3535
3536 sub _handle_T_command {
3537     my $self = shift;
3538
3539     if ($self->_is_full('T')) {
3540         DB::print_trace( $OUT, 1 );    # skip DB
3541         next CMD;
3542     }
3543
3544     return;
3545 }
3546
3547 sub _handle_w_command {
3548     my $self = shift;
3549
3550     DB::cmd_w( 'w', $self->cmd_args() );
3551     next CMD;
3552
3553     return;
3554 }
3555
3556 sub _handle_W_command {
3557     my $self = shift;
3558
3559     if (my $arg = $self->cmd_args) {
3560         DB::cmd_W( 'W', $arg );
3561         next CMD;
3562     }
3563
3564     return;
3565 }
3566
3567 sub _handle_rc_recall_command {
3568     my $self = shift;
3569
3570     # $rc - recall command.
3571     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3572
3573         # No arguments, take one thing off history.
3574         pop(@hist) if length($DB::cmd) > 1;
3575
3576         # Relative (- found)?
3577         #  Y - index back from most recent (by 1 if bare minus)
3578         #  N - go to that particular command slot or the last
3579         #      thing if nothing following.
3580
3581         $self->cmd_verb(
3582             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3583         );
3584
3585         # Pick out the command desired.
3586         $DB::cmd = $hist[$self->cmd_verb];
3587
3588         # Print the command to be executed and restart the loop
3589         # with that command in the buffer.
3590         print {$OUT} $DB::cmd, "\n";
3591         redo CMD;
3592     }
3593
3594     return;
3595 }
3596
3597 sub _handle_rc_search_history_command {
3598     my $self = shift;
3599
3600     # $rc pattern $rc - find a command in the history.
3601     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3602
3603         # Create the pattern to use.
3604         my $pat = "^$arg";
3605         $self->pat($pat);
3606
3607         # Toss off last entry if length is >1 (and it always is).
3608         pop(@hist) if length($DB::cmd) > 1;
3609
3610         my $i;
3611
3612         # Look backward through the history.
3613         SEARCH_HIST:
3614         for ( $i = $#hist ; $i ; --$i ) {
3615             # Stop if we find it.
3616             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3617         }
3618
3619         if ( !$i ) {
3620
3621             # Never found it.
3622             print $OUT "No such command!\n\n";
3623             next CMD;
3624         }
3625
3626         # Found it. Put it in the buffer, print it, and process it.
3627         $DB::cmd = $hist[$i];
3628         print $OUT $DB::cmd, "\n";
3629         redo CMD;
3630     }
3631
3632     return;
3633 }
3634
3635 sub _handle_H_command {
3636     my $self = shift;
3637
3638     if ($self->cmd_args =~ m#\A\*#) {
3639         @hist = @truehist = ();
3640         print $OUT "History cleansed\n";
3641         next CMD;
3642     }
3643
3644     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3645
3646         # Anything other than negative numbers is ignored by
3647         # the (incorrect) pattern, so this test does nothing.
3648         $end = $num ? ( $#hist - $num ) : 0;
3649
3650         # Set to the minimum if less than zero.
3651         $hist = 0 if $hist < 0;
3652
3653         # Start at the end of the array.
3654         # Stay in while we're still above the ending value.
3655         # Tick back by one each time around the loop.
3656         my $i;
3657
3658         for ( $i = $#hist ; $i > $end ; $i-- ) {
3659
3660             # Print the command  unless it has no arguments.
3661             print $OUT "$i: ", $hist[$i], "\n"
3662             unless $hist[$i] =~ /^.?$/;
3663         }
3664
3665         next CMD;
3666     }
3667
3668     return;
3669 }
3670
3671 sub _handle_doc_command {
3672     my $self = shift;
3673
3674     # man, perldoc, doc - show manual pages.
3675     if (my ($man_page)
3676         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3677         runman($man_page);
3678         next CMD;
3679     }
3680
3681     return;
3682 }
3683
3684 sub _handle_p_command {
3685     my $self = shift;
3686
3687     my $print_cmd = 'print {$DB::OUT} ';
3688     # p - print (no args): print $_.
3689     if ($self->_is_full('p')) {
3690         $DB::cmd = $print_cmd . '$_';
3691     }
3692     else {
3693         # p - print the given expression.
3694         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3695     }
3696
3697     return;
3698 }
3699
3700 sub _handle_equal_sign_command {
3701     my $self = shift;
3702
3703     if ($DB::cmd =~ s/\A=\s*//) {
3704         my @keys;
3705         if ( length $DB::cmd == 0 ) {
3706
3707             # No args, get current aliases.
3708             @keys = sort keys %alias;
3709         }
3710         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3711
3712             # Creating a new alias. $k is alias name, $v is
3713             # alias value.
3714
3715             # can't use $_ or kill //g state
3716             for my $x ( $k, $v ) {
3717
3718                 # Escape "alarm" characters.
3719                 $x =~ s/\a/\\a/g;
3720             }
3721
3722             # Substitute key for value, using alarm chars
3723             # as separators (which is why we escaped them in
3724             # the command).
3725             $alias{$k} = "s\a$k\a$v\a";
3726
3727             # Turn off standard warn and die behavior.
3728             local $SIG{__DIE__};
3729             local $SIG{__WARN__};
3730
3731             # Is it valid Perl?
3732             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3733
3734                 # Nope. Bad alias. Say so and get out.
3735                 print $OUT "Can't alias $k to $v: $@\n";
3736                 delete $alias{$k};
3737                 next CMD;
3738             }
3739
3740             # We'll only list the new one.
3741             @keys = ($k);
3742         } ## end elsif (my ($k, $v) = ($DB::cmd...
3743
3744         # The argument is the alias to list.
3745         else {
3746             @keys = ($DB::cmd);
3747         }
3748
3749         # List aliases.
3750         for my $k (@keys) {
3751
3752             # Messy metaquoting: Trim the substitution code off.
3753             # We use control-G as the delimiter because it's not
3754             # likely to appear in the alias.
3755             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3756
3757                 # Print the alias.
3758                 print $OUT "$k\t= $1\n";
3759             }
3760             elsif ( defined $alias{$k} ) {
3761
3762                 # Couldn't trim it off; just print the alias code.
3763                 print $OUT "$k\t$alias{$k}\n";
3764             }
3765             else {
3766
3767                 # No such, dude.
3768                 print "No alias for $k\n";
3769             }
3770         } ## end for my $k (@keys)
3771         next CMD;
3772     }
3773
3774     return;
3775 }
3776
3777 sub _handle_source_command {
3778     my $self = shift;
3779
3780     # source - read commands from a file (or pipe!) and execute.
3781     if (my $sourced_fn = $self->cmd_args) {
3782         if ( open my $fh, $sourced_fn ) {
3783
3784             # Opened OK; stick it in the list of file handles.
3785             push @cmdfhs, $fh;
3786         }
3787         else {
3788
3789             # Couldn't open it.
3790             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3791         }
3792         next CMD;
3793     }
3794
3795     return;
3796 }
3797
3798 sub _handle_enable_disable_commands {
3799     my $self = shift;
3800
3801     my $which_cmd = $self->cmd_verb;
3802     my $position = $self->cmd_args;
3803
3804     if ($position !~ /\s/) {
3805         my ($fn, $line_num);
3806         if ($position =~ m{\A\d+\z})
3807         {
3808             $fn = $DB::filename;
3809             $line_num = $position;
3810         }
3811         elsif (my ($new_fn, $new_line_num)
3812             = $position =~ m{\A(.*):(\d+)\z}) {
3813             ($fn, $line_num) = ($new_fn, $new_line_num);
3814         }
3815         else
3816         {
3817             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3818         }
3819
3820         if (defined($fn)) {
3821             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3822                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3823                     ($which_cmd eq 'enable' ? 1 : '')
3824                 );
3825             }
3826             else {
3827                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3828             }
3829         }
3830
3831         next CMD;
3832     }
3833
3834     return;
3835 }
3836
3837 sub _handle_save_command {
3838     my $self = shift;
3839
3840     if (my $new_fn = $self->cmd_args) {
3841         my $filename = $new_fn || '.perl5dbrc';    # default?
3842         if ( open my $fh, '>', $filename ) {
3843
3844             # chomp to remove extraneous newlines from source'd files
3845             chomp( my @truelist =
3846                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3847                 @truehist );
3848             print {$fh} join( "\n", @truelist );
3849             print "commands saved in $filename\n";
3850         }
3851         else {
3852             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3853         }
3854         next CMD;
3855     }
3856
3857     return;
3858 }
3859
3860 sub _n_or_s_and_arg_commands_generic {
3861     my ($self, $letter, $new_val) = @_;
3862
3863     # s - single-step. Remember the last command was 's'.
3864     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3865         $laststep = $letter;
3866     }
3867
3868     return;
3869 }
3870
3871 sub _handle_sh_command {
3872     my $self = shift;
3873
3874     # $sh$sh - run a shell command (if it's all ASCII).
3875     # Can't run shell commands with Unicode in the debugger, hmm.
3876     my $my_cmd = $DB::cmd;
3877     if ($my_cmd =~ m#\A$sh#gms) {
3878
3879         if ($my_cmd =~ m#\G\z#cgms) {
3880             # Run the user's shell. If none defined, run Bourne.
3881             # We resume execution when the shell terminates.
3882             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3883             next CMD;
3884         }
3885         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3886             # System it.
3887             DB::_db_system($1);
3888             next CMD;
3889         }
3890         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3891             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3892             next CMD;
3893         }
3894     }
3895 }
3896
3897 sub _handle_x_command {
3898     my $self = shift;
3899
3900     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3901         $onetimeDump = 'dump';    # main::dumpvar shows the output
3902
3903         # handle special  "x 3 blah" syntax XXX propagate
3904         # doc back to special variables.
3905         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3906             $onetimedumpDepth = $1;
3907         }
3908     }
3909
3910     return;
3911 }
3912
3913 sub _handle_q_command {
3914     my $self = shift;
3915
3916     if ($self->_is_full('q')) {
3917         $fall_off_end = 1;
3918         DB::clean_ENV();
3919         exit $?;
3920     }
3921
3922     return;
3923 }
3924
3925 sub _handle_cmd_wrapper_commands {
3926     my $self = shift;
3927
3928     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
3929     next CMD;
3930 }
3931
3932 sub _handle_special_char_cmd_wrapper_commands {
3933     my $self = shift;
3934
3935     # All of these commands were remapped in perl 5.8.0;
3936     # we send them off to the secondary dispatcher (see below).
3937     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
3938         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
3939         next CMD;
3940     }
3941
3942     return;
3943 }
3944
3945 package DB;
3946
3947 # The following code may be executed now:
3948 # BEGIN {warn 4}
3949
3950 =head2 sub
3951
3952 C<sub> is called whenever a subroutine call happens in the program being
3953 debugged. The variable C<$DB::sub> contains the name of the subroutine
3954 being called.
3955
3956 The core function of this subroutine is to actually call the sub in the proper
3957 context, capturing its output. This of course causes C<DB::DB> to get called
3958 again, repeating until the subroutine ends and returns control to C<DB::sub>
3959 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3960 return value, and returns its captured copy of the return value as its own
3961 return value. The value then feeds back into the program being debugged as if
3962 C<DB::sub> hadn't been there at all.
3963
3964 C<sub> does all the work of printing the subroutine entry and exit messages
3965 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3966 and also prints the return value if needed (for the C<r> command and if
3967 the 16 bit is set in C<$frame>).
3968
3969 It also tracks the subroutine call depth by saving the current setting of
3970 C<$single> in the C<@stack> package global; if this exceeds the value in
3971 C<$deep>, C<sub> automatically turns on printing of the current depth by
3972 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3973 of stop/don't stop on entry to subs set as it currently is set.
3974
3975 =head3 C<caller()> support
3976
3977 If C<caller()> is called from the package C<DB>, it provides some
3978 additional data, in the following order:
3979
3980 =over 4
3981
3982 =item * C<$package>
3983
3984 The package name the sub was in
3985
3986 =item * C<$filename>
3987
3988 The filename it was defined in
3989
3990 =item * C<$line>
3991
3992 The line number it was defined on
3993
3994 =item * C<$subroutine>
3995
3996 The subroutine name; C<(eval)> if an C<eval>().
3997
3998 =item * C<$hasargs>
3999
4000 1 if it has arguments, 0 if not
4001
4002 =item * C<$wantarray>
4003
4004 1 if array context, 0 if scalar context
4005
4006 =item * C<$evaltext>
4007
4008 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4009
4010 =item * C<$is_require>
4011
4012 frame was created by a C<use> or C<require> statement
4013
4014 =item * C<$hints>
4015
4016 pragma information; subject to change between versions
4017
4018 =item * C<$bitmask>
4019
4020 pragma information; subject to change between versions
4021
4022 =item * C<@DB::args>
4023
4024 arguments with which the subroutine was invoked
4025
4026 =back
4027
4028 =cut
4029
4030 use vars qw($deep);
4031
4032 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4033 # happy. -- Shlomi Fish
4034
4035 sub _indent_print_line_info {
4036     my ($offset, $str) = @_;
4037
4038     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4039
4040     return;
4041 }
4042
4043 sub _print_frame_message {
4044     my ($al) = @_;
4045
4046     if ($frame) {
4047         if ($frame & 4) {   # Extended frame entry message
4048             _indent_print_line_info(-1, "in  ");
4049
4050             # Why -1? But it works! :-(
4051             # Because print_trace will call add 1 to it and then call
4052             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4053             # in dump_trace.
4054             #
4055             # Now it's 0 because we extracted a function.
4056             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4057         }
4058         else {
4059             _indent_print_line_info(-1, "entering $sub$al\n" );
4060         }
4061     }
4062
4063     return;
4064 }
4065
4066 sub DB::sub {
4067     # Do not use a regex in this subroutine -> results in corrupted memory
4068     # See: [perl #66110]
4069
4070     # lock ourselves under threads
4071     lock($DBGR);
4072
4073     # Whether or not the autoloader was running, a scalar to put the
4074     # sub's return value in (if needed), and an array to put the sub's
4075     # return value in (if needed).
4076     my ( $al, $ret, @ret ) = "";
4077     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4078         print "creating new thread\n";
4079     }
4080
4081     # If the last ten characters are '::AUTOLOAD', note we've traced
4082     # into AUTOLOAD for $sub.
4083     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4084         no strict 'refs';
4085         $al = " for $$sub" if defined $$sub;
4086     }
4087
4088     # We stack the stack pointer and then increment it to protect us
4089     # from a situation that might unwind a whole bunch of call frames
4090     # at once. Localizing the stack pointer means that it will automatically
4091     # unwind the same amount when multiple stack frames are unwound.
4092     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4093
4094     # Expand @stack.
4095     $#stack = $stack_depth;
4096
4097     # Save current single-step setting.
4098     $stack[-1] = $single;
4099
4100     # Turn off all flags except single-stepping.
4101     $single &= 1;
4102
4103     # If we've gotten really deeply recursed, turn on the flag that will
4104     # make us stop with the 'deep recursion' message.
4105     $single |= 4 if $stack_depth == $deep;
4106
4107     # If frame messages are on ...
4108
4109     _print_frame_message($al);
4110     # standard frame entry message
4111
4112     my $print_exit_msg = sub {
4113         # Check for exit trace messages...
4114         if ($frame & 2)
4115         {
4116             if ($frame & 4)    # Extended exit message
4117             {
4118                 _indent_print_line_info(0, "out ");
4119                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4120             }
4121             else
4122             {
4123                 _indent_print_line_info(0, "exited $sub$al\n" );
4124             }
4125         }
4126         return;
4127     };
4128
4129     # Determine the sub's return type, and capture appropriately.
4130     if (wantarray) {
4131
4132         # Called in array context. call sub and capture output.
4133         # DB::DB will recursively get control again if appropriate; we'll come
4134         # back here when the sub is finished.
4135         {
4136             no strict 'refs';
4137             @ret = &$sub;
4138         }
4139
4140         # Pop the single-step value back off the stack.
4141         $single |= $stack[ $stack_depth-- ];
4142
4143         $print_exit_msg->();
4144
4145         # Print the return info if we need to.
4146         if ( $doret eq $stack_depth or $frame & 16 ) {
4147
4148             # Turn off output record separator.
4149             local $\ = '';
4150             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4151
4152             # Indent if we're printing because of $frame tracing.
4153             if ($frame & 16)
4154             {
4155                 print {$fh} ' ' x $stack_depth;
4156             }
4157
4158             # Print the return value.
4159             print {$fh} "list context return from $sub:\n";
4160             dumpit( $fh, \@ret );
4161
4162             # And don't print it again.
4163             $doret = -2;
4164         } ## end if ($doret eq $stack_depth...
4165             # And we have to return the return value now.
4166         @ret;
4167     } ## end if (wantarray)
4168
4169     # Scalar context.
4170     else {
4171         if ( defined wantarray ) {
4172             no strict 'refs';
4173             # Save the value if it's wanted at all.
4174             $ret = &$sub;
4175         }
4176         else {
4177             no strict 'refs';
4178             # Void return, explicitly.
4179             &$sub;
4180             undef $ret;
4181         }
4182
4183         # Pop the single-step value off the stack.
4184         $single |= $stack[ $stack_depth-- ];
4185
4186         # If we're doing exit messages...
4187         $print_exit_msg->();
4188
4189         # If we are supposed to show the return value... same as before.
4190         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4191             local $\ = '';
4192             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4193             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4194             print $fh (
4195                 defined wantarray
4196                 ? "scalar context return from $sub: "
4197                 : "void context return from $sub\n"
4198             );
4199             dumpit( $fh, $ret ) if defined wantarray;
4200             $doret = -2;
4201         } ## end if ($doret eq $stack_depth...
4202
4203         # Return the appropriate scalar value.
4204         $ret;
4205     } ## end else [ if (wantarray)
4206 } ## end sub _sub
4207
4208 sub lsub : lvalue {
4209
4210     no strict 'refs';
4211
4212     # lock ourselves under threads
4213     lock($DBGR);
4214
4215     # Whether or not the autoloader was running, a scalar to put the
4216     # sub's return value in (if needed), and an array to put the sub's
4217     # return value in (if needed).
4218     my ( $al, $ret, @ret ) = "";
4219     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4220         print "creating new thread\n";
4221     }
4222
4223     # If the last ten characters are C'::AUTOLOAD', note we've traced
4224     # into AUTOLOAD for $sub.
4225     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4226         $al = " for $$sub";
4227     }
4228
4229     # We stack the stack pointer and then increment it to protect us
4230     # from a situation that might unwind a whole bunch of call frames
4231     # at once. Localizing the stack pointer means that it will automatically
4232     # unwind the same amount when multiple stack frames are unwound.
4233     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4234
4235     # Expand @stack.
4236     $#stack = $stack_depth;
4237
4238     # Save current single-step setting.
4239     $stack[-1] = $single;
4240
4241     # Turn off all flags except single-stepping.
4242     $single &= 1;
4243
4244     # If we've gotten really deeply recursed, turn on the flag that will
4245     # make us stop with the 'deep recursion' message.
4246     $single |= 4 if $stack_depth == $deep;
4247
4248     # If frame messages are on ...
4249     _print_frame_message($al);
4250
4251     # Pop the single-step value back off the stack.
4252     $single |= $stack[ $stack_depth-- ];
4253
4254     # call the original lvalue sub.
4255     &$sub;
4256 }
4257
4258 # Abstracting common code from multiple places elsewhere:
4259 sub depth_print_lineinfo {
4260     my $always_print = shift;
4261
4262     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4263 }
4264
4265 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4266
4267 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4268 Most of the changes were to systematize the command structure and to eliminate
4269 commands that threw away user input without checking.
4270
4271 The following sections describe the code added to make it easy to support
4272 multiple command sets with conflicting command names. This section is a start
4273 at unifying all command processing to make it simpler to develop commands.
4274
4275 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4276 number, and C<$dbline> (the current line) as arguments.
4277
4278 Support functions in this section which have multiple modes of failure C<die>
4279 on error; the rest simply return a false value.
4280
4281 The user-interface functions (all of the C<cmd_*> functions) just output
4282 error messages.
4283
4284 =head2 C<%set>
4285
4286 The C<%set> hash defines the mapping from command letter to subroutine
4287 name suffix.
4288
4289 C<%set> is a two-level hash, indexed by set name and then by command name.
4290 Note that trying to set the CommandSet to C<foobar> simply results in the
4291 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4292
4293 =cut
4294
4295 ### The API section
4296
4297 my %set = (    #
4298     'pre580' => {
4299         'a' => 'pre580_a',
4300         'A' => 'pre580_null',
4301         'b' => 'pre580_b',
4302         'B' => 'pre580_null',
4303         'd' => 'pre580_null',
4304         'D' => 'pre580_D',
4305         'h' => 'pre580_h',
4306         'M' => 'pre580_null',
4307         'O' => 'o',
4308         'o' => 'pre580_null',
4309         'v' => 'M',
4310         'w' => 'v',
4311         'W' => 'pre580_W',
4312     },
4313     'pre590' => {
4314         '<'  => 'pre590_prepost',
4315         '<<' => 'pre590_prepost',
4316         '>'  => 'pre590_prepost',
4317         '>>' => 'pre590_prepost',
4318         '{'  => 'pre590_prepost',
4319         '{{' => 'pre590_prepost',
4320     },
4321 );
4322
4323 my %breakpoints_data;
4324
4325 sub _has_breakpoint_data_ref {
4326     my ($filename, $line) = @_;
4327
4328     return (
4329         exists( $breakpoints_data{$filename} )
4330             and
4331         exists( $breakpoints_data{$filename}{$line} )
4332     );
4333 }
4334
4335 sub _get_breakpoint_data_ref {
4336     my ($filename, $line) = @_;
4337
4338     return ($breakpoints_data{$filename}{$line} ||= +{});
4339 }
4340
4341 sub _delete_breakpoint_data_ref {
4342     my ($filename, $line) = @_;
4343
4344     delete($breakpoints_data{$filename}{$line});
4345     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4346         delete($breakpoints_data{$filename});
4347     }
4348
4349     return;
4350 }
4351
4352 sub _set_breakpoint_enabled_status {
4353     my ($filename, $line, $status) = @_;
4354
4355     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4356         ($status ? 1 : '')
4357         ;
4358
4359     return;
4360 }
4361
4362 sub _enable_breakpoint_temp_enabled_status {
4363     my ($filename, $line) = @_;
4364
4365     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4366
4367     return;
4368 }
4369
4370 sub _cancel_breakpoint_temp_enabled_status {
4371     my ($filename, $line) = @_;
4372
4373     my $ref = _get_breakpoint_data_ref($filename, $line);
4374
4375     delete ($ref->{'temp_enabled'});
4376
4377     if (! %$ref) {
4378         _delete_breakpoint_data_ref($filename, $line);
4379     }
4380
4381     return;
4382 }
4383
4384 sub _is_breakpoint_enabled {
4385     my ($filename, $line) = @_;
4386
4387     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4388     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4389 }
4390
4391 =head2 C<cmd_wrapper()> (API)
4392
4393 C<cmd_wrapper()> allows the debugger to switch command sets
4394 depending on the value of the C<CommandSet> option.
4395
4396 It tries to look up the command in the C<%set> package-level I<lexical>
4397 (which means external entities can't fiddle with it) and create the name of
4398 the sub to call based on the value found in the hash (if it's there). I<All>
4399 of the commands to be handled in a set have to be added to C<%set>; if they
4400 aren't found, the 5.8.0 equivalent is called (if there is one).
4401
4402 This code uses symbolic references.
4403
4404 =cut
4405
4406 sub cmd_wrapper {
4407     my $cmd      = shift;
4408     my $line     = shift;
4409     my $dblineno = shift;
4410
4411     # Assemble the command subroutine's name by looking up the
4412     # command set and command name in %set. If we can't find it,
4413     # default to the older version of the command.
4414     my $call = 'cmd_'
4415       . ( $set{$CommandSet}{$cmd}
4416           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4417
4418     # Call the command subroutine, call it by name.
4419     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4420 } ## end sub cmd_wrapper
4421
4422 =head3 C<cmd_a> (command)
4423
4424 The C<a> command handles pre-execution actions. These are associated with a
4425 particular line, so they're stored in C<%dbline>. We default to the current
4426 line if none is specified.
4427
4428 =cut
4429
4430 sub cmd_a {
4431     my $cmd    = shift;
4432     my $line   = shift || '';    # [.|line] expr
4433     my $dbline = shift;
4434
4435     # If it's dot (here), or not all digits,  use the current line.
4436     $line =~ s/\A\./$dbline/;
4437
4438     # Should be a line number followed by an expression.
4439     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4440
4441         if (! length($lineno)) {
4442             $lineno = $dbline;
4443         }
4444
4445         # If we have an expression ...
4446         if ( length $expr ) {
4447
4448             # ... but the line isn't breakable, complain.
4449             if ( $dbline[$lineno] == 0 ) {
4450                 print $OUT
4451                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4452             }
4453             else {
4454
4455                 # It's executable. Record that the line has an action.
4456                 $had_breakpoints{$filename} |= 2;
4457
4458                 # Remove any action, temp breakpoint, etc.
4459                 $dbline{$lineno} =~ s/\0[^\0]*//;
4460
4461                 # Add the action to the line.
4462                 $dbline{$lineno} .= "\0" . action($expr);
4463
4464                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4465             }
4466         } ## end if (length $expr)
4467     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4468     else {
4469
4470         # Syntax wrong.
4471         print $OUT
4472           "Adding an action requires an optional lineno and an expression\n"
4473           ;    # hint
4474     }
4475 } ## end sub cmd_a
4476
4477 =head3 C<cmd_A> (command)
4478
4479 Delete actions. Similar to above, except the delete code is in a separate
4480 subroutine, C<delete_action>.
4481
4482 =cut
4483
4484 sub cmd_A {
4485     my $cmd    = shift;
4486     my $line   = shift || '';
4487     my $dbline = shift;
4488
4489     # Dot is this line.
4490     $line =~ s/^\./$dbline/;
4491
4492     # Call delete_action with a null param to delete them all.
4493     # The '1' forces the eval to be true. It'll be false only
4494     # if delete_action blows up for some reason, in which case
4495     # we print $@ and get out.
4496     if ( $line eq '*' ) {
4497         if (! eval { _delete_all_actions(); 1 }) {
4498             print {$OUT} $@;
4499             return;
4500         }
4501     }
4502
4503     # There's a real line  number. Pass it to delete_action.
4504     # Error trapping is as above.
4505     elsif ( $line =~ /^(\S.*)/ ) {
4506         if (! eval { delete_action($1); 1 }) {
4507             print {$OUT} $@;
4508             return;
4509         }
4510     }
4511
4512     # Swing and a miss. Bad syntax.
4513     else {
4514         print $OUT
4515           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4516     }
4517 } ## end sub cmd_A
4518
4519 =head3 C<delete_action> (API)
4520
4521 C<delete_action> accepts either a line number or C<undef>. If a line number
4522 is specified, we check for the line being executable (if it's not, it
4523 couldn't have had an  action). If it is, we just take the action off (this
4524 will get any kind of an action, including breakpoints).
4525
4526 =cut
4527
4528 sub _remove_action_from_dbline {
4529     my $i = shift;
4530
4531     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4532     delete $dbline{$i} if $dbline{$i} eq '';
4533
4534     return;
4535 }
4536
4537 sub _delete_all_actions {
4538     print {$OUT} "Deleting all actions...\n";
4539
4540     for my $file ( keys %had_breakpoints ) {
4541         local *dbline = $main::{ '_<' . $file };
4542         $max = $#dbline;
4543         my $was;
4544         for my $i (1 .. $max) {
4545             if ( defined $dbline{$i} ) {
4546                 _remove_action_from_dbline($i);
4547             }
4548         }
4549
4550         unless ( $had_breakpoints{$file} &= ~2 ) {
4551             delete $had_breakpoints{$file};
4552         }
4553     }
4554
4555     return;
4556 }
4557
4558 sub delete_action {
4559     my $i = shift;
4560
4561     if ( defined($i) ) {
4562         # Can there be one?
4563         die "Line $i has no action .\n" if $dbline[$i] == 0;
4564
4565         # Nuke whatever's there.
4566         _remove_action_from_dbline($i);
4567     }
4568     else {
4569         _delete_all_actions();
4570     }
4571 }
4572
4573 =head3 C<cmd_b> (command)
4574
4575 Set breakpoints. Since breakpoints can be set in so many places, in so many
4576 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4577 we try to parse the command type, and then shuttle it off to an appropriate
4578 subroutine to actually do the work of setting the breakpoint in the right
4579 place.
4580
4581 =cut
4582
4583 sub cmd_b {
4584     my $cmd    = shift;
4585     my $line   = shift;    # [.|line] [cond]
4586     my $dbline = shift;
4587
4588     my $default_cond = sub {
4589         my $cond = shift;
4590         return length($cond) ? $cond : '1';
4591     };
4592
4593     # Make . the current line number if it's there..
4594     $line =~ s/^\.(\s|\z)/$dbline$1/;
4595
4596     # No line number, no condition. Simple break on current line.
4597     if ( $line =~ /^\s*$/ ) {
4598         cmd_b_line( $dbline, 1 );
4599     }
4600
4601     # Break on load for a file.
4602     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4603         $file =~ s/\s+\z//;
4604         cmd_b_load($file);
4605     }
4606
4607     # b compile|postpone <some sub> [<condition>]
4608     # The interpreter actually traps this one for us; we just put the
4609     # necessary condition in the %postponed hash.
4610     elsif ( my ($action, $subname, $cond)
4611         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4612
4613         # De-Perl4-ify the name - ' separators to ::.
4614         $subname =~ s/'/::/g;
4615
4616         # Qualify it into the current package unless it's already qualified.
4617         $subname = "${package}::" . $subname unless $subname =~ /::/;
4618
4619         # Add main if it starts with ::.
4620         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4621
4622         # Save the break type for this sub.
4623         $postponed{$subname} = (($action eq 'postpone')
4624             ? ( "break +0 if " . $default_cond->($cond) )
4625             : "compile");
4626     } ## end elsif ($line =~ ...
4627     # b <filename>:<line> [<condition>]
4628     elsif (my ($filename, $line_num, $cond)
4629         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4630         cmd_b_filename_line(
4631             $filename,
4632             $line_num,
4633             (length($cond) ? $cond : '1'),
4634         );
4635     }
4636     # b <sub name> [<condition>]
4637     elsif ( my ($new_subname, $new_cond) =
4638         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4639
4640         #
4641         $subname = $new_subname;
4642         cmd_b_sub( $subname, $default_cond->($new_cond) );
4643     }
4644
4645     # b <line> [<condition>].
4646     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4647
4648         # Capture the line. If none, it's the current line.
4649         $line = $line_n || $dbline;
4650
4651         # Break on line.
4652         cmd_b_line( $line, $default_cond->($cond) );
4653     }
4654
4655     # Line didn't make sense.
4656     else {
4657         print "confused by line($line)?\n";
4658     }
4659
4660     return;
4661 } ## end sub cmd_b
4662
4663 =head3 C<break_on_load> (API)
4664
4665 We want to break when this file is loaded. Mark this file in the
4666 C<%break_on_load> hash, and note that it has a breakpoint in
4667 C<%had_breakpoints>.
4668
4669 =cut
4670
4671 sub break_on_load {
4672     my $file = shift;
4673     $break_on_load{$file} = 1;
4674     $had_breakpoints{$file} |= 1;
4675 }
4676
4677 =head3 C<report_break_on_load> (API)
4678
4679 Gives us an array of filenames that are set to break on load. Note that
4680 only files with break-on-load are in here, so simply showing the keys
4681 suffices.
4682
4683 =cut
4684
4685 sub report_break_on_load {
4686     sort keys %break_on_load;
4687 }
4688
4689 =head3 C<cmd_b_load> (command)
4690
4691 We take the file passed in and try to find it in C<%INC> (which maps modules
4692 to files they came from). We mark those files for break-on-load via
4693 C<break_on_load> and then report that it was done.
4694
4695 =cut
4696
4697 sub cmd_b_load {
4698     my $file = shift;
4699     my @files;
4700
4701     # This is a block because that way we can use a redo inside it
4702     # even without there being any looping structure at all outside it.
4703     {
4704
4705         # Save short name and full path if found.
4706         push @files, $file;
4707         push @files, $::INC{$file} if $::INC{$file};
4708
4709         # Tack on .pm and do it again unless there was a '.' in the name
4710         # already.
4711         $file .= '.pm', redo unless $file =~ /\./;
4712     }
4713
4714     # Do the real work here.
4715     break_on_load($_) for @files;
4716
4717     # All the files that have break-on-load breakpoints.
4718     @files = report_break_on_load;
4719
4720     # Normalize for the purposes of our printing this.
4721     local $\ = '';
4722     local $" = ' ';
4723     print $OUT "Will stop on load of '@files'.\n";
4724 } ## end sub cmd_b_load
4725
4726 =head3 C<$filename_error> (API package global)
4727
4728 Several of the functions we need to implement in the API need to work both
4729 on the current file and on other files. We don't want to duplicate code, so
4730 C<$filename_error> is used to contain the name of the file that's being
4731 worked on (if it's not the current one).
4732
4733 We can now build functions in pairs: the basic function works on the current
4734 file, and uses C<$filename_error> as part of its error message. Since this is
4735 initialized to C<"">, no filename will appear when we are working on the
4736 current file.
4737
4738 The second function is a wrapper which does the following:
4739
4740 =over 4
4741
4742 =item *
4743
4744 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4745
4746 =item *
4747
4748 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4749
4750 =item *
4751
4752 Calls the first function.
4753
4754 The first function works on the I<current> file (i.e., the one we changed to),
4755 and prints C<$filename_error> in the error message (the name of the other file)
4756 if it needs to. When the functions return, C<*dbline> is restored to point
4757 to the actual current file (the one we're executing in) and
4758 C<$filename_error> is restored to C<"">. This restores everything to
4759 the way it was before the second function was called at all.
4760
4761 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4762 details.
4763
4764 =back
4765
4766 =cut
4767
4768 use vars qw($filename_error);
4769 $filename_error = '';
4770
4771 =head3 breakable_line(from, to) (API)
4772
4773 The subroutine decides whether or not a line in the current file is breakable.
4774 It walks through C<@dbline> within the range of lines specified, looking for
4775 the first line that is breakable.
4776
4777 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4778 first line I<after> C<$to> that's breakable, if there is one.
4779
4780 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4781 first line I<before> C<$to> that's breakable, if there is one.
4782
4783 =cut
4784
4785 sub breakable_line {
4786
4787     my ( $from, $to ) = @_;
4788
4789     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4790     my $i = $from;
4791
4792     # If there are at least 2 arguments, we're trying to search a range.
4793     if ( @_ >= 2 ) {
4794
4795         # $delta is positive for a forward search, negative for a backward one.
4796         my $delta = $from < $to ? +1 : -1;
4797
4798         # Keep us from running off the ends of the file.
4799         my $limit = $delta > 0 ? $#dbline : 1;
4800
4801         # Clever test. If you're a mathematician, it's obvious why this
4802         # test works. If not:
4803         # If $delta is positive (going forward), $limit will be $#dbline.
4804         #    If $to is less than $limit, ($limit - $to) will be positive, times
4805         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4806         #    as the stopping point.
4807         #
4808         #    If $to is greater than $limit, ($limit - $to) is negative,
4809         #    times $delta of 1 (positive), so the result is < 0 and we should
4810         #    use $limit ($#dbline) as the stopping point.
4811         #
4812         # If $delta is negative (going backward), $limit will be 1.
4813         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4814         #    (negative) so the result is > 0, and we use $to as the stopping
4815         #    point.
4816         #
4817         #    If $to is less than zero, ($limit - $to) will be positive,
4818         #    times $delta of -1 (negative), so the result is not > 0, and
4819         #    we use $limit (1) as the stopping point.
4820         #
4821         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4822         #    (negative), still giving zero; the result is not > 0, and
4823         #    we use $limit (1) as the stopping point.
4824         #
4825         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4826         #    (negative), giving a positive (>0) value, so we'll set $limit to
4827         #    $to.
4828
4829         $limit = $to if ( $limit - $to ) * $delta > 0;
4830
4831         # The real search loop.
4832         # $i starts at $from (the point we want to start searching from).
4833         # We move through @dbline in the appropriate direction (determined
4834         # by $delta: either -1 (back) or +1 (ahead).
4835         # We stay in as long as we haven't hit an executable line
4836         # ($dbline[$i] == 0 means not executable) and we haven't reached
4837         # the limit yet (test similar to the above).
4838         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4839
4840     } ## end if (@_ >= 2)
4841
4842     # If $i points to a line that is executable, return that.
4843     return $i unless $dbline[$i] == 0;
4844
4845     # Format the message and print it: no breakable lines in range.
4846     my ( $pl, $upto ) = ( '', '' );
4847     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4848
4849     # If there's a filename in filename_error, we'll see it.
4850     # If not, not.
4851     die "Line$pl $from$upto$filename_error not breakable\n";
4852 } ## end sub breakable_line
4853
4854 =head3 breakable_line_in_filename(file, from, to) (API)
4855
4856 Like C<breakable_line>, but look in another file.
4857
4858 =cut