This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
d730b43e47eecc667f68e74104209479d4c7f56e
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 An named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
204 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
238 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<unlink>,
239 C<utime>, C<wait>, C<waitpid>
240
241 For more information about the portability of these functions, see
242 L<perlport> and other available platform-specific documentation.
243
244 =head2 Alphabetical Listing of Perl Functions
245
246 =over 8
247
248 =item I<-X> FILEHANDLE
249
250 =item I<-X> EXPR
251
252 =item I<-X>
253
254 A file test, where X is one of the letters listed below.  This unary
255 operator takes one argument, either a filename or a filehandle, and
256 tests the associated file to see if something is true about it.  If the
257 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
258 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
259 the undefined value if the file doesn't exist.  Despite the funny
260 names, precedence is the same as any other named unary operator, and
261 the argument may be parenthesized like any other unary operator.  The
262 operator may be any of:
263 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
264 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
265
266     -r  File is readable by effective uid/gid.
267     -w  File is writable by effective uid/gid.
268     -x  File is executable by effective uid/gid.
269     -o  File is owned by effective uid.
270
271     -R  File is readable by real uid/gid.
272     -W  File is writable by real uid/gid.
273     -X  File is executable by real uid/gid.
274     -O  File is owned by real uid.
275
276     -e  File exists.
277     -z  File has zero size.
278     -s  File has nonzero size (returns size).
279
280     -f  File is a plain file.
281     -d  File is a directory.
282     -l  File is a symbolic link.
283     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
284     -S  File is a socket.
285     -b  File is a block special file.
286     -c  File is a character special file.
287     -t  Filehandle is opened to a tty.
288
289     -u  File has setuid bit set.
290     -g  File has setgid bit set.
291     -k  File has sticky bit set.
292
293     -T  File is an ASCII text file.
294     -B  File is a "binary" file (opposite of -T).
295
296     -M  Age of file in days when script started.
297     -A  Same for access time.
298     -C  Same for inode change time.
299
300 Example:
301
302     while (<>) {
303         chop;
304         next unless -f $_;      # ignore specials
305         #...
306     }
307
308 The interpretation of the file permission operators C<-r>, C<-R>,
309 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
310 of the file and the uids and gids of the user.  There may be other
311 reasons you can't actually read, write, or execute the file.  Such
312 reasons may be for example network filesystem access controls, ACLs
313 (access control lists), read-only filesystems, and unrecognized
314 executable formats.
315
316 Also note that, for the superuser on the local filesystems, the C<-r>,
317 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
318 if any execute bit is set in the mode.  Scripts run by the superuser
319 may thus need to do a stat() to determine the actual mode of the file,
320 or temporarily set their effective uid to something else.
321
322 If you are using ACLs, there is a pragma called C<filetest> that may
323 produce more accurate results than the bare stat() mode bits.
324 When under the C<use filetest 'access'> the above-mentioned filetests
325 will test whether the permission can (not) be granted using the
326 access() family of system calls.  Also note that the C<-x> and C<-X> may
327 under this pragma return true even if there are no execute permission
328 bits set (nor any extra execute permission ACLs).  This strangeness is
329 due to the underlying system calls' definitions.  Read the
330 documentation for the C<filetest> pragma for more information.
331
332 Note that C<-s/a/b/> does not do a negated substitution.  Saying
333 C<-exp($foo)> still works as expected, however--only single letters
334 following a minus are interpreted as file tests.
335
336 The C<-T> and C<-B> switches work as follows.  The first block or so of the
337 file is examined for odd characters such as strange control codes or
338 characters with the high bit set.  If too many strange characters (E<gt>30%)
339 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
340 containing null in the first block is considered a binary file.  If C<-T>
341 or C<-B> is used on a filehandle, the current stdio buffer is examined
342 rather than the first block.  Both C<-T> and C<-B> return true on a null
343 file, or a file at EOF when testing a filehandle.  Because you have to
344 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
345 against the file first, as in C<next unless -f $file && -T $file>.
346
347 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
348 the special filehandle consisting of a solitary underline, then the stat
349 structure of the previous file test (or stat operator) is used, saving
350 a system call.  (This doesn't work with C<-t>, and you need to remember
351 that lstat() and C<-l> will leave values in the stat structure for the
352 symbolic link, not the real file.)  Example:
353
354     print "Can do.\n" if -r $a || -w _ || -x _;
355
356     stat($filename);
357     print "Readable\n" if -r _;
358     print "Writable\n" if -w _;
359     print "Executable\n" if -x _;
360     print "Setuid\n" if -u _;
361     print "Setgid\n" if -g _;
362     print "Sticky\n" if -k _;
363     print "Text\n" if -T _;
364     print "Binary\n" if -B _;
365
366 =item abs VALUE
367
368 =item abs
369
370 Returns the absolute value of its argument.
371 If VALUE is omitted, uses C<$_>.
372
373 =item accept NEWSOCKET,GENERICSOCKET
374
375 Accepts an incoming socket connect, just as the accept(2) system call
376 does.  Returns the packed address if it succeeded, false otherwise.
377 See the example in L<perlipc/"Sockets: Client/Server Communication">.
378
379 =item alarm SECONDS
380
381 =item alarm
382
383 Arranges to have a SIGALRM delivered to this process after the
384 specified number of seconds have elapsed.  If SECONDS is not specified,
385 the value stored in C<$_> is used. (On some machines,
386 unfortunately, the elapsed time may be up to one second less than you
387 specified because of how seconds are counted.)  Only one timer may be
388 counting at once.  Each call disables the previous timer, and an
389 argument of C<0> may be supplied to cancel the previous timer without
390 starting a new one.  The returned value is the amount of time remaining
391 on the previous timer.
392
393 For delays of finer granularity than one second, you may use Perl's
394 four-argument version of select() leaving the first three arguments
395 undefined, or you might be able to use the C<syscall> interface to
396 access setitimer(2) if your system supports it.  The Time::HiRes module
397 from CPAN may also prove useful.
398
399 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
400 (C<sleep> may be internally implemented in your system with C<alarm>)
401
402 If you want to use C<alarm> to time out a system call you need to use an
403 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
404 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
405 restart system calls on some systems.  Using C<eval>/C<die> always works,
406 modulo the caveats given in L<perlipc/"Signals">.
407
408     eval {
409         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
410         alarm $timeout;
411         $nread = sysread SOCKET, $buffer, $size;
412         alarm 0;
413     };
414     if ($@) {
415         die unless $@ eq "alarm\n";   # propagate unexpected errors
416         # timed out
417     }
418     else {
419         # didn't
420     }
421
422 =item atan2 Y,X
423
424 Returns the arctangent of Y/X in the range -PI to PI.
425
426 For the tangent operation, you may use the C<POSIX::tan()>
427 function, or use the familiar relation:
428
429     sub tan { sin($_[0]) / cos($_[0])  }
430
431 =item bind SOCKET,NAME
432
433 Binds a network address to a socket, just as the bind system call
434 does.  Returns true if it succeeded, false otherwise.  NAME should be a
435 packed address of the appropriate type for the socket.  See the examples in
436 L<perlipc/"Sockets: Client/Server Communication">.
437
438 =item binmode FILEHANDLE
439
440 Arranges for FILEHANDLE to be read or written in "binary" mode on
441 systems whose run-time libraries force the programmer to guess
442 between binary and text files.  If FILEHANDLE is an expression, the
443 value is taken as the name of the filehandle.  binmode() should be
444 called after the C<open> but before any I/O is done on the filehandle.
445 The only way to reset binary mode on a filehandle is to reopen the
446 file.
447
448 The operating system, device drivers, C libraries, and Perl run-time
449 system all conspire to let the programmer conveniently treat a
450 simple, one-byte C<\n> as the line terminator, irrespective of its
451 external representation.  On Unix and its brethren, the native file
452 representation exactly matches the internal representation, making
453 everyone's lives unbelievably simpler.  Consequently, L<binmode>
454 has no effect under Unix, Plan9, or Mac OS, all of which use C<\n>
455 to end each line.  (Unix and Plan9 think C<\n> means C<\cJ> and
456 C<\r> means C<\cM>, whereas the Mac goes the other way--it uses
457 C<\cM> for c<\n> and C<\cJ> to mean C<\r>.  But that's ok, because
458 it's only one byte, and the internal and external representations
459 match.)
460
461 In legacy systems like MS-DOS and its embellishments, your program
462 sees a C<\n> as a simple C<\cJ> (just as in Unix), but oddly enough,
463 that's not what's physically stored on disk.  What's worse, these
464 systems refuse to help you with this; it's up to you to remember
465 what to do.  And you mustn't go applying binmode() with wild abandon,
466 either, because if your system does care about binmode(), then using
467 it when you shouldn't is just as perilous as failing to use it when
468 you should.
469
470 That means that on any version of Microsoft WinXX that you might
471 care to name (or not), binmode() causes C<\cM\cJ> sequences on disk
472 to be converted to C<\n> when read into your program, and causes
473 any C<\n> in your program to be converted back to C<\cM\cJ> on
474 output to disk.  This sad discrepancy leads to no end of
475 problems in not just the readline operator, but also when using
476 seek(), tell(), and read() calls.  See L<perlport> for other painful
477 details.  See the C<$/> and C<$\> variables in L<perlvar> for how
478 to manually set your input and output line-termination sequences.
479
480 =item bless REF,CLASSNAME
481
482 =item bless REF
483
484 This function tells the thingy referenced by REF that it is now an object
485 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
486 is used.  Because a C<bless> is often the last thing in a constructor,
487 it returns the reference for convenience.  Always use the two-argument
488 version if the function doing the blessing might be inherited by a
489 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
490 (and blessings) of objects.
491
492 Consider always blessing objects in CLASSNAMEs that are mixed case.
493 Namespaces with all lowercase names are considered reserved for
494 Perl pragmata.  Builtin types have all uppercase names, so to prevent
495 confusion, you may wish to avoid such package names as well.  Make sure
496 that CLASSNAME is a true value.
497
498 See L<perlmod/"Perl Modules">.
499
500 =item caller EXPR
501
502 =item caller
503
504 Returns the context of the current subroutine call.  In scalar context,
505 returns the caller's package name if there is a caller, that is, if
506 we're in a subroutine or C<eval> or C<require>, and the undefined value
507 otherwise.  In list context, returns
508
509     ($package, $filename, $line) = caller;
510
511 With EXPR, it returns some extra information that the debugger uses to
512 print a stack trace.  The value of EXPR indicates how many call frames
513 to go back before the current one.
514
515     ($package, $filename, $line, $subroutine, $hasargs,
516     $wantarray, $evaltext, $is_require, $hints) = caller($i);
517
518 Here $subroutine may be C<(eval)> if the frame is not a subroutine
519 call, but an C<eval>.  In such a case additional elements $evaltext and
520 C<$is_require> are set: C<$is_require> is true if the frame is created by a
521 C<require> or C<use> statement, $evaltext contains the text of the
522 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
523 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
524 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
525 frame.  C<$hints> contains pragmatic hints that the caller was
526 compiled with.  It currently only reflects the hint corresponding to
527 C<use utf8>.
528
529 Furthermore, when called from within the DB package, caller returns more
530 detailed information: it sets the list variable C<@DB::args> to be the
531 arguments with which the subroutine was invoked.
532
533 Be aware that the optimizer might have optimized call frames away before
534 C<caller> had a chance to get the information.  That means that C<caller(N)>
535 might not return information about the call frame you expect it do, for
536 C<N E<gt> 1>.  In particular, C<@DB::args> might have information from the 
537 previous time C<caller> was called.
538
539 =item chdir EXPR
540
541 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
542 changes to the user's home directory.  Returns true upon success,
543 false otherwise.  See the example under C<die>.
544
545 =item chmod LIST
546
547 Changes the permissions of a list of files.  The first element of the
548 list must be the numerical mode, which should probably be an octal
549 number, and which definitely should I<not> a string of octal digits:
550 C<0644> is okay, C<'0644'> is not.  Returns the number of files
551 successfully changed.  See also L</oct>, if all you have is a string.
552
553     $cnt = chmod 0755, 'foo', 'bar';
554     chmod 0755, @executables;
555     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
556                                              # --w----r-T
557     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
558     $mode = 0644;   chmod $mode, 'foo';      # this is best
559
560 =item chomp VARIABLE
561
562 =item chomp LIST
563
564 =item chomp
565
566 This safer version of L</chop> removes any trailing string
567 that corresponds to the current value of C<$/> (also known as
568 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
569 number of characters removed from all its arguments.  It's often used to
570 remove the newline from the end of an input record when you're worried
571 that the final record may be missing its newline.  When in paragraph
572 mode (C<$/ = "">), it removes all trailing newlines from the string.
573 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
574 a reference to an integer or the like, see L<perlvar>) chomp() won't
575 remove anything.  
576 If VARIABLE is omitted, it chomps C<$_>.  Example:
577
578     while (<>) {
579         chomp;  # avoid \n on last field
580         @array = split(/:/);
581         # ...
582     }
583
584 You can actually chomp anything that's an lvalue, including an assignment:
585
586     chomp($cwd = `pwd`);
587     chomp($answer = <STDIN>);
588
589 If you chomp a list, each element is chomped, and the total number of
590 characters removed is returned.
591
592 =item chop VARIABLE
593
594 =item chop LIST
595
596 =item chop
597
598 Chops off the last character of a string and returns the character
599 chopped.  It's used primarily to remove the newline from the end of an
600 input record, but is much more efficient than C<s/\n//> because it neither
601 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
602 Example:
603
604     while (<>) {
605         chop;   # avoid \n on last field
606         @array = split(/:/);
607         #...
608     }
609
610 You can actually chop anything that's an lvalue, including an assignment:
611
612     chop($cwd = `pwd`);
613     chop($answer = <STDIN>);
614
615 If you chop a list, each element is chopped.  Only the value of the
616 last C<chop> is returned.
617
618 Note that C<chop> returns the last character.  To return all but the last
619 character, use C<substr($string, 0, -1)>.
620
621 =item chown LIST
622
623 Changes the owner (and group) of a list of files.  The first two
624 elements of the list must be the I<numeric> uid and gid, in that
625 order.  A value of -1 in either position is interpreted by most
626 systems to leave that value unchanged.  Returns the number of files
627 successfully changed.
628
629     $cnt = chown $uid, $gid, 'foo', 'bar';
630     chown $uid, $gid, @filenames;
631
632 Here's an example that looks up nonnumeric uids in the passwd file:
633
634     print "User: ";
635     chomp($user = <STDIN>);
636     print "Files: ";
637     chomp($pattern = <STDIN>);
638
639     ($login,$pass,$uid,$gid) = getpwnam($user)
640         or die "$user not in passwd file";
641
642     @ary = glob($pattern);      # expand filenames
643     chown $uid, $gid, @ary;
644
645 On most systems, you are not allowed to change the ownership of the
646 file unless you're the superuser, although you should be able to change
647 the group to any of your secondary groups.  On insecure systems, these
648 restrictions may be relaxed, but this is not a portable assumption.
649 On POSIX systems, you can detect this condition this way:
650
651     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
652     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
653
654 =item chr NUMBER
655
656 =item chr
657
658 Returns the character represented by that NUMBER in the character set.
659 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
660 chr(0x263a) is a Unicode smiley face (but only within the scope of
661 a C<use utf8>).  For the reverse, use L</ord>.  
662 See L<utf8> for more about Unicode.
663
664 If NUMBER is omitted, uses C<$_>.
665
666 =item chroot FILENAME
667
668 =item chroot
669
670 This function works like the system call by the same name: it makes the
671 named directory the new root directory for all further pathnames that
672 begin with a C</> by your process and all its children.  (It doesn't
673 change your current working directory, which is unaffected.)  For security
674 reasons, this call is restricted to the superuser.  If FILENAME is
675 omitted, does a C<chroot> to C<$_>.
676
677 =item close FILEHANDLE
678
679 =item close
680
681 Closes the file or pipe associated with the file handle, returning true
682 only if stdio successfully flushes buffers and closes the system file
683 descriptor.  Closes the currently selected filehandle if the argument
684 is omitted.
685
686 You don't have to close FILEHANDLE if you are immediately going to do
687 another C<open> on it, because C<open> will close it for you.  (See
688 C<open>.)  However, an explicit C<close> on an input file resets the line
689 counter (C<$.>), while the implicit close done by C<open> does not.
690
691 If the file handle came from a piped open C<close> will additionally
692 return false if one of the other system calls involved fails or if the
693 program exits with non-zero status.  (If the only problem was that the
694 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe 
695 also waits for the process executing on the pipe to complete, in case you
696 want to look at the output of the pipe afterwards, and 
697 implicitly puts the exit status value of that command into C<$?>.
698
699 Prematurely closing the read end of a pipe (i.e. before the process
700 writing to it at the other end has closed it) will result in a
701 SIGPIPE being delivered to the writer.  If the other end can't
702 handle that, be sure to read all the data before closing the pipe.
703
704 Example:
705
706     open(OUTPUT, '|sort >foo')  # pipe to sort
707         or die "Can't start sort: $!";
708     #...                        # print stuff to output
709     close OUTPUT                # wait for sort to finish
710         or warn $! ? "Error closing sort pipe: $!"
711                    : "Exit status $? from sort";
712     open(INPUT, 'foo')          # get sort's results
713         or die "Can't open 'foo' for input: $!";
714
715 FILEHANDLE may be an expression whose value can be used as an indirect
716 filehandle, usually the real filehandle name.
717
718 =item closedir DIRHANDLE
719
720 Closes a directory opened by C<opendir> and returns the success of that
721 system call.
722
723 DIRHANDLE may be an expression whose value can be used as an indirect
724 dirhandle, usually the real dirhandle name.
725
726 =item connect SOCKET,NAME
727
728 Attempts to connect to a remote socket, just as the connect system call
729 does.  Returns true if it succeeded, false otherwise.  NAME should be a
730 packed address of the appropriate type for the socket.  See the examples in
731 L<perlipc/"Sockets: Client/Server Communication">.
732
733 =item continue BLOCK
734
735 Actually a flow control statement rather than a function.  If there is a
736 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
737 C<foreach>), it is always executed just before the conditional is about to
738 be evaluated again, just like the third part of a C<for> loop in C.  Thus
739 it can be used to increment a loop variable, even when the loop has been
740 continued via the C<next> statement (which is similar to the C C<continue>
741 statement).
742
743 C<last>, C<next>, or C<redo> may appear within a C<continue>
744 block.  C<last> and C<redo> will behave as if they had been executed within
745 the main block.  So will C<next>, but since it will execute a C<continue>
746 block, it may be more entertaining.
747
748     while (EXPR) {
749         ### redo always comes here
750         do_something;
751     } continue {
752         ### next always comes here
753         do_something_else;
754         # then back the top to re-check EXPR
755     }
756     ### last always comes here
757
758 Omitting the C<continue> section is semantically equivalent to using an
759 empty one, logically enough.  In that case, C<next> goes directly back
760 to check the condition at the top of the loop.
761
762 =item cos EXPR
763
764 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
765 takes cosine of C<$_>.
766
767 For the inverse cosine operation, you may use the C<POSIX::acos()>
768 function, or use this relation:
769
770     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
771
772 =item crypt PLAINTEXT,SALT
773
774 Encrypts a string exactly like the crypt(3) function in the C library
775 (assuming that you actually have a version there that has not been
776 extirpated as a potential munition).  This can prove useful for checking
777 the password file for lousy passwords, amongst other things.  Only the
778 guys wearing white hats should do this.
779
780 Note that C<crypt> is intended to be a one-way function, much like breaking
781 eggs to make an omelette.  There is no (known) corresponding decrypt
782 function.  As a result, this function isn't all that useful for
783 cryptography.  (For that, see your nearby CPAN mirror.)
784
785 When verifying an existing encrypted string you should use the encrypted
786 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
787 allows your code to work with the standard C<crypt> and with more
788 exotic implementations.  When choosing a new salt create a random two
789 character string whose characters come from the set C<[./0-9A-Za-z]>
790 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
791
792 Here's an example that makes sure that whoever runs this program knows
793 their own password:
794
795     $pwd = (getpwuid($<))[1];
796
797     system "stty -echo";
798     print "Password: ";
799     chomp($word = <STDIN>);
800     print "\n";
801     system "stty echo";
802
803     if (crypt($word, $pwd) ne $pwd) {
804         die "Sorry...\n";
805     } else {
806         print "ok\n";
807     }
808
809 Of course, typing in your own password to whoever asks you
810 for it is unwise.
811
812 The L<crypt> function is unsuitable for encrypting large quantities
813 of data, not least of all because you can't get the information
814 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
815 on your favorite CPAN mirror for a slew of potentially useful
816 modules.
817
818 =item dbmclose HASH
819
820 [This function has been largely superseded by the C<untie> function.]
821
822 Breaks the binding between a DBM file and a hash.
823
824 =item dbmopen HASH,DBNAME,MASK
825
826 [This function has been largely superseded by the C<tie> function.]
827
828 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
829 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
830 argument is I<not> a filehandle, even though it looks like one).  DBNAME
831 is the name of the database (without the F<.dir> or F<.pag> extension if
832 any).  If the database does not exist, it is created with protection
833 specified by MASK (as modified by the C<umask>).  If your system supports
834 only the older DBM functions, you may perform only one C<dbmopen> in your
835 program.  In older versions of Perl, if your system had neither DBM nor
836 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
837 sdbm(3).
838
839 If you don't have write access to the DBM file, you can only read hash
840 variables, not set them.  If you want to test whether you can write,
841 either use file tests or try setting a dummy hash entry inside an C<eval>,
842 which will trap the error.
843
844 Note that functions such as C<keys> and C<values> may return huge lists
845 when used on large DBM files.  You may prefer to use the C<each>
846 function to iterate over large DBM files.  Example:
847
848     # print out history file offsets
849     dbmopen(%HIST,'/usr/lib/news/history',0666);
850     while (($key,$val) = each %HIST) {
851         print $key, ' = ', unpack('L',$val), "\n";
852     }
853     dbmclose(%HIST);
854
855 See also L<AnyDBM_File> for a more general description of the pros and
856 cons of the various dbm approaches, as well as L<DB_File> for a particularly
857 rich implementation.
858
859 You can control which DBM library you use by loading that library
860 before you call dbmopen():
861
862     use DB_File;
863     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
864         or die "Can't open netscape history file: $!";
865
866 =item defined EXPR
867
868 =item defined
869
870 Returns a Boolean value telling whether EXPR has a value other than
871 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
872 checked.
873
874 Many operations return C<undef> to indicate failure, end of file,
875 system error, uninitialized variable, and other exceptional
876 conditions.  This function allows you to distinguish C<undef> from
877 other values.  (A simple Boolean test will not distinguish among
878 C<undef>, zero, the empty string, and C<"0">, which are all equally
879 false.)  Note that since C<undef> is a valid scalar, its presence
880 doesn't I<necessarily> indicate an exceptional condition: C<pop>
881 returns C<undef> when its argument is an empty array, I<or> when the
882 element to return happens to be C<undef>.
883
884 You may also use C<defined(&func)> to check whether subroutine C<&func>
885 has ever been defined.  The return value is unaffected by any forward
886 declarations of C<&foo>.
887
888 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
889 used to report whether memory for that aggregate has ever been
890 allocated.  This behavior may disappear in future versions of Perl.
891 You should instead use a simple test for size:
892
893     if (@an_array) { print "has array elements\n" }
894     if (%a_hash)   { print "has hash members\n"   }
895
896 When used on a hash element, it tells you whether the value is defined,
897 not whether the key exists in the hash.  Use L</exists> for the latter
898 purpose.
899
900 Examples:
901
902     print if defined $switch{'D'};
903     print "$val\n" while defined($val = pop(@ary));
904     die "Can't readlink $sym: $!"
905         unless defined($value = readlink $sym);
906     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
907     $debugging = 0 unless defined $debugging;
908
909 Note:  Many folks tend to overuse C<defined>, and then are surprised to
910 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
911 defined values.  For example, if you say
912
913     "ab" =~ /a(.*)b/;
914
915 The pattern match succeeds, and C<$1> is defined, despite the fact that it
916 matched "nothing".  But it didn't really match nothing--rather, it
917 matched something that happened to be zero characters long.  This is all
918 very above-board and honest.  When a function returns an undefined value,
919 it's an admission that it couldn't give you an honest answer.  So you
920 should use C<defined> only when you're questioning the integrity of what
921 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
922 what you want.
923
924 See also L</undef>, L</exists>, L</ref>.
925
926 =item delete EXPR
927
928 Given an expression that specifies a hash element, array element, hash slice,
929 or array slice, deletes the specified element(s) from the hash or array.
930 If the array elements happen to be at the end of the array, the size
931 of the array will shrink by that number of elements.
932
933 Returns each element so deleted or the undefined value if there was no such
934 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
935 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
936 from a C<tie>d hash or array may not necessarily return anything.
937
938 Deleting an array element effectively returns that position of the array
939 to its initial, uninitialized state.  Subsequently testing for the same
940 element with exists() will return false.  See L</exists>.
941
942 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
943
944     foreach $key (keys %HASH) {
945         delete $HASH{$key};
946     }
947
948     foreach $index (0 .. $#ARRAY) {
949         delete $ARRAY[$index];
950     }
951
952 And so do these:
953
954     delete @HASH{keys %HASH};
955
956     delete @ARRAY[0 .. $#ARRAY];
957
958 But both of these are slower than just assigning the empty list
959 or undefining %HASH or @ARRAY:
960
961     %HASH = ();         # completely empty %HASH
962     undef %HASH;        # forget %HASH ever existed
963
964     @ARRAY = ();        # completely empty @ARRAY
965     undef @ARRAY;       # forget @ARRAY ever existed
966
967 Note that the EXPR can be arbitrarily complicated as long as the final
968 operation is a hash element, array element,  hash slice, or array slice
969 lookup:
970
971     delete $ref->[$x][$y]{$key};
972     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
973
974     delete $ref->[$x][$y][$index];
975     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
976
977 =item die LIST
978
979 Outside an C<eval>, prints the value of LIST to C<STDERR> and
980 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
981 exits with the value of C<($? E<gt>E<gt> 8)> (backtick `command`
982 status).  If C<($? E<gt>E<gt> 8)> is C<0>, exits with C<255>.  Inside
983 an C<eval(),> the error message is stuffed into C<$@> and the
984 C<eval> is terminated with the undefined value.  This makes
985 C<die> the way to raise an exception.
986
987 Equivalent examples:
988
989     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
990     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
991
992 If the value of EXPR does not end in a newline, the current script line
993 number and input line number (if any) are also printed, and a newline
994 is supplied.  Note that the "input line number" (also known as "chunk")
995 is subject to whatever notion of "line" happens to be currently in
996 effect, and is also available as the special variable C<$.>.
997 See L<perlvar/"$/"> and L<perlvar/"$.">.
998
999 Hint: sometimes appending C<", stopped"> to your message
1000 will cause it to make better sense when the string C<"at foo line 123"> is
1001 appended.  Suppose you are running script "canasta".
1002
1003     die "/etc/games is no good";
1004     die "/etc/games is no good, stopped";
1005
1006 produce, respectively
1007
1008     /etc/games is no good at canasta line 123.
1009     /etc/games is no good, stopped at canasta line 123.
1010
1011 See also exit(), warn(), and the Carp module.
1012
1013 If LIST is empty and C<$@> already contains a value (typically from a
1014 previous eval) that value is reused after appending C<"\t...propagated">.
1015 This is useful for propagating exceptions:
1016
1017     eval { ... };
1018     die unless $@ =~ /Expected exception/;
1019
1020 If C<$@> is empty then the string C<"Died"> is used.
1021
1022 die() can also be called with a reference argument.  If this happens to be
1023 trapped within an eval(), $@ contains the reference.  This behavior permits
1024 a more elaborate exception handling implementation using objects that
1025 maintain arbitary state about the nature of the exception.  Such a scheme
1026 is sometimes preferable to matching particular string values of $@ using
1027 regular expressions.  Here's an example:
1028
1029     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1030     if ($@) {
1031         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1032             # handle Some::Module::Exception
1033         }
1034         else {
1035             # handle all other possible exceptions
1036         }
1037     }
1038
1039 Because perl will stringify uncaught exception messages before displaying
1040 them, you may want to overload stringification operations on such custom
1041 exception objects.  See L<overload> for details about that.
1042
1043 You can arrange for a callback to be run just before the C<die>
1044 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1045 handler will be called with the error text and can change the error
1046 message, if it sees fit, by calling C<die> again.  See
1047 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1048 L<"eval BLOCK"> for some examples.  Although this feature was meant
1049 to be run only right before your program was to exit, this is not
1050 currently the case--the C<$SIG{__DIE__}> hook is currently called
1051 even inside eval()ed blocks/strings!  If one wants the hook to do
1052 nothing in such situations, put
1053
1054         die @_ if $^S;
1055
1056 as the first line of the handler (see L<perlvar/$^S>).  Because
1057 this promotes strange action at a distance, this counterintuitive
1058 behavior may be fixed in a future release.  
1059
1060 =item do BLOCK
1061
1062 Not really a function.  Returns the value of the last command in the
1063 sequence of commands indicated by BLOCK.  When modified by a loop
1064 modifier, executes the BLOCK once before testing the loop condition.
1065 (On other statements the loop modifiers test the conditional first.)
1066
1067 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1068 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1069 See L<perlsyn> for alternative strategies.
1070
1071 =item do SUBROUTINE(LIST)
1072
1073 A deprecated form of subroutine call.  See L<perlsub>.
1074
1075 =item do EXPR
1076
1077 Uses the value of EXPR as a filename and executes the contents of the
1078 file as a Perl script.  Its primary use is to include subroutines
1079 from a Perl subroutine library.
1080
1081     do 'stat.pl';
1082
1083 is just like
1084
1085     scalar eval `cat stat.pl`;
1086
1087 except that it's more efficient and concise, keeps track of the current
1088 filename for error messages, searches the @INC libraries, and updates
1089 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1090 variables.  It also differs in that code evaluated with C<do FILENAME>
1091 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1092 same, however, in that it does reparse the file every time you call it,
1093 so you probably don't want to do this inside a loop.
1094
1095 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1096 error.  If C<do> can read the file but cannot compile it, it
1097 returns undef and sets an error message in C<$@>.   If the file is
1098 successfully compiled, C<do> returns the value of the last expression
1099 evaluated.
1100
1101 Note that inclusion of library modules is better done with the
1102 C<use> and C<require> operators, which also do automatic error checking
1103 and raise an exception if there's a problem.
1104
1105 You might like to use C<do> to read in a program configuration
1106 file.  Manual error checking can be done this way:
1107
1108     # read in config files: system first, then user 
1109     for $file ("/share/prog/defaults.rc",
1110                "$ENV{HOME}/.someprogrc") 
1111    {
1112         unless ($return = do $file) {
1113             warn "couldn't parse $file: $@" if $@;
1114             warn "couldn't do $file: $!"    unless defined $return;
1115             warn "couldn't run $file"       unless $return;
1116         }
1117     }
1118
1119 =item dump LABEL
1120
1121 =item dump
1122
1123 This function causes an immediate core dump.  See also the B<-u>
1124 command-line switch in L<perlrun>, which does the same thing.
1125 Primarily this is so that you can use the B<undump> program (not
1126 supplied) to turn your core dump into an executable binary after
1127 having initialized all your variables at the beginning of the
1128 program.  When the new binary is executed it will begin by executing
1129 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1130 Think of it as a goto with an intervening core dump and reincarnation.
1131 If C<LABEL> is omitted, restarts the program from the top.
1132
1133 B<WARNING>: Any files opened at the time of the dump will I<not>
1134 be open any more when the program is reincarnated, with possible
1135 resulting confusion on the part of Perl.  
1136
1137 This function is now largely obsolete, partly because it's very
1138 hard to convert a core file into an executable, and because the
1139 real compiler backends for generating portable bytecode and compilable
1140 C code have superseded it.
1141
1142 If you're looking to use L<dump> to speed up your program, consider
1143 generating bytecode or native C code as described in L<perlcc>.  If
1144 you're just trying to accelerate a CGI script, consider using the
1145 C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI.
1146 You might also consider autoloading or selfloading, which at least
1147 make your program I<appear> to run faster.  
1148
1149 =item each HASH
1150
1151 When called in list context, returns a 2-element list consisting of the
1152 key and value for the next element of a hash, so that you can iterate over
1153 it.  When called in scalar context, returns the key for only the "next"
1154 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
1155 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
1156 for this reason.)
1157
1158 Entries are returned in an apparently random order.  The actual random
1159 order is subject to change in future versions of perl, but it is guaranteed
1160 to be in the same order as either the C<keys> or C<values> function
1161 would produce on the same (unmodified) hash.
1162
1163 When the hash is entirely read, a null array is returned in list context
1164 (which when assigned produces a false (C<0>) value), and C<undef> in
1165 scalar context.  The next call to C<each> after that will start iterating
1166 again.  There is a single iterator for each hash, shared by all C<each>,
1167 C<keys>, and C<values> function calls in the program; it can be reset by
1168 reading all the elements from the hash, or by evaluating C<keys HASH> or
1169 C<values HASH>.  If you add or delete elements of a hash while you're
1170 iterating over it, you may get entries skipped or duplicated, so don't.
1171
1172 The following prints out your environment like the printenv(1) program,
1173 only in a different order:
1174
1175     while (($key,$value) = each %ENV) {
1176         print "$key=$value\n";
1177     }
1178
1179 See also C<keys>, C<values> and C<sort>.
1180
1181 =item eof FILEHANDLE
1182
1183 =item eof ()
1184
1185 =item eof
1186
1187 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1188 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1189 gives the real filehandle.  (Note that this function actually
1190 reads a character and then C<ungetc>s it, so isn't very useful in an
1191 interactive context.)  Do not read from a terminal file (or call
1192 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1193 as terminals may lose the end-of-file condition if you do.
1194
1195 An C<eof> without an argument uses the last file read.  Using C<eof()>
1196 with empty parentheses is very different.  It refers to the pseudo file
1197 formed from the files listed on the command line and accessed via the
1198 C<E<lt>E<gt>> operator.  Since C<E<lt>E<gt>> isn't explicitly opened,
1199 as a normal filehandle is, an C<eof()> before C<E<lt>E<gt>> has been
1200 used will cause C<@ARGV> to be examined to determine if input is
1201 available.
1202
1203 In a C<while (E<lt>E<gt>)> loop, C<eof> or C<eof(ARGV)> can be used to
1204 detect the end of each file, C<eof()> will only detect the end of the
1205 last file.  Examples:
1206
1207     # reset line numbering on each input file
1208     while (<>) {
1209         next if /^\s*#/;        # skip comments 
1210         print "$.\t$_";
1211     } continue {
1212         close ARGV  if eof;     # Not eof()!
1213     }
1214
1215     # insert dashes just before last line of last file
1216     while (<>) {
1217         if (eof()) {            # check for end of current file
1218             print "--------------\n";
1219             close(ARGV);        # close or last; is needed if we
1220                                 # are reading from the terminal
1221         }
1222         print;
1223     }
1224
1225 Practical hint: you almost never need to use C<eof> in Perl, because the
1226 input operators typically return C<undef> when they run out of data, or if
1227 there was an error.
1228
1229 =item eval EXPR
1230
1231 =item eval BLOCK
1232
1233 In the first form, the return value of EXPR is parsed and executed as if it
1234 were a little Perl program.  The value of the expression (which is itself
1235 determined within scalar context) is first parsed, and if there weren't any
1236 errors, executed in the context of the current Perl program, so that any
1237 variable settings or subroutine and format definitions remain afterwards.
1238 Note that the value is parsed every time the eval executes.  If EXPR is
1239 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1240 and subsequent execution of the text of EXPR until run time.
1241
1242 In the second form, the code within the BLOCK is parsed only once--at the
1243 same time the code surrounding the eval itself was parsed--and executed
1244 within the context of the current Perl program.  This form is typically
1245 used to trap exceptions more efficiently than the first (see below), while
1246 also providing the benefit of checking the code within BLOCK at compile
1247 time.
1248
1249 The final semicolon, if any, may be omitted from the value of EXPR or within
1250 the BLOCK.
1251
1252 In both forms, the value returned is the value of the last expression
1253 evaluated inside the mini-program; a return statement may be also used, just
1254 as with subroutines.  The expression providing the return value is evaluated
1255 in void, scalar, or list context, depending on the context of the eval itself.
1256 See L</wantarray> for more on how the evaluation context can be determined.
1257
1258 If there is a syntax error or runtime error, or a C<die> statement is
1259 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1260 error message.  If there was no error, C<$@> is guaranteed to be a null
1261 string.  Beware that using C<eval> neither silences perl from printing
1262 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1263 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1264 L</warn> and L<perlvar>.
1265
1266 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1267 determining whether a particular feature (such as C<socket> or C<symlink>)
1268 is implemented.  It is also Perl's exception trapping mechanism, where
1269 the die operator is used to raise exceptions.
1270
1271 If the code to be executed doesn't vary, you may use the eval-BLOCK
1272 form to trap run-time errors without incurring the penalty of
1273 recompiling each time.  The error, if any, is still returned in C<$@>.
1274 Examples:
1275
1276     # make divide-by-zero nonfatal
1277     eval { $answer = $a / $b; }; warn $@ if $@;
1278
1279     # same thing, but less efficient
1280     eval '$answer = $a / $b'; warn $@ if $@;
1281
1282     # a compile-time error
1283     eval { $answer = };                 # WRONG
1284
1285     # a run-time error
1286     eval '$answer =';   # sets $@
1287
1288 Due to the current arguably broken state of C<__DIE__> hooks, when using
1289 the C<eval{}> form as an exception trap in libraries, you may wish not
1290 to trigger any C<__DIE__> hooks that user code may have installed.
1291 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1292 as shown in this example:
1293
1294     # a very private exception trap for divide-by-zero
1295     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1296     warn $@ if $@;
1297
1298 This is especially significant, given that C<__DIE__> hooks can call
1299 C<die> again, which has the effect of changing their error messages:
1300
1301     # __DIE__ hooks may modify error messages
1302     {
1303        local $SIG{'__DIE__'} =
1304               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1305        eval { die "foo lives here" };
1306        print $@ if $@;                # prints "bar lives here"
1307     }
1308
1309 Because this promotes action at a distance, this counterintuitive behavior
1310 may be fixed in a future release.
1311
1312 With an C<eval>, you should be especially careful to remember what's
1313 being looked at when:
1314
1315     eval $x;            # CASE 1
1316     eval "$x";          # CASE 2
1317
1318     eval '$x';          # CASE 3
1319     eval { $x };        # CASE 4
1320
1321     eval "\$$x++";      # CASE 5
1322     $$x++;              # CASE 6
1323
1324 Cases 1 and 2 above behave identically: they run the code contained in
1325 the variable $x.  (Although case 2 has misleading double quotes making
1326 the reader wonder what else might be happening (nothing is).)  Cases 3
1327 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1328 does nothing but return the value of $x.  (Case 4 is preferred for
1329 purely visual reasons, but it also has the advantage of compiling at
1330 compile-time instead of at run-time.)  Case 5 is a place where
1331 normally you I<would> like to use double quotes, except that in this
1332 particular situation, you can just use symbolic references instead, as
1333 in case 6.
1334
1335 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1336 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1337
1338 =item exec LIST
1339
1340 =item exec PROGRAM LIST
1341
1342 The C<exec> function executes a system command I<and never returns>--
1343 use C<system> instead of C<exec> if you want it to return.  It fails and
1344 returns false only if the command does not exist I<and> it is executed
1345 directly instead of via your system's command shell (see below).
1346
1347 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1348 warns you if there is a following statement which isn't C<die>, C<warn>,
1349 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1350 I<really> want to follow an C<exec> with some other statement, you
1351 can use one of these styles to avoid the warning:
1352
1353     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1354     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1355
1356 If there is more than one argument in LIST, or if LIST is an array
1357 with more than one value, calls execvp(3) with the arguments in LIST.
1358 If there is only one scalar argument or an array with one element in it,
1359 the argument is checked for shell metacharacters, and if there are any,
1360 the entire argument is passed to the system's command shell for parsing
1361 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1362 If there are no shell metacharacters in the argument, it is split into
1363 words and passed directly to C<execvp>, which is more efficient.  
1364 Examples:
1365
1366     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1367     exec "sort $outfile | uniq";
1368
1369 If you don't really want to execute the first argument, but want to lie
1370 to the program you are executing about its own name, you can specify
1371 the program you actually want to run as an "indirect object" (without a
1372 comma) in front of the LIST.  (This always forces interpretation of the
1373 LIST as a multivalued list, even if there is only a single scalar in
1374 the list.)  Example:
1375
1376     $shell = '/bin/csh';
1377     exec $shell '-sh';          # pretend it's a login shell
1378
1379 or, more directly,
1380
1381     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1382
1383 When the arguments get executed via the system shell, results will
1384 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1385 for details.
1386
1387 Using an indirect object with C<exec> or C<system> is also more
1388 secure.  This usage (which also works fine with system()) forces
1389 interpretation of the arguments as a multivalued list, even if the
1390 list had just one argument.  That way you're safe from the shell
1391 expanding wildcards or splitting up words with whitespace in them.
1392
1393     @args = ( "echo surprise" );
1394
1395     exec @args;               # subject to shell escapes
1396                                 # if @args == 1
1397     exec { $args[0] } @args;  # safe even with one-arg list
1398
1399 The first version, the one without the indirect object, ran the I<echo>
1400 program, passing it C<"surprise"> an argument.  The second version
1401 didn't--it tried to run a program literally called I<"echo surprise">,
1402 didn't find it, and set C<$?> to a non-zero value indicating failure.
1403
1404 Note that C<exec> will not call your C<END> blocks, nor will it call
1405 any C<DESTROY> methods in your objects.
1406
1407 =item exists EXPR
1408
1409 Given an expression that specifies a hash element or array element,
1410 returns true if the specified element in the hash or array has ever
1411 been initialized, even if the corresponding value is undefined.  The
1412 element is not autovivified if it doesn't exist.
1413
1414     print "Exists\n"    if exists $hash{$key};
1415     print "Defined\n"   if defined $hash{$key};
1416     print "True\n"      if $hash{$key};
1417
1418     print "Exists\n"    if exists $array[$index];
1419     print "Defined\n"   if defined $array[$index];
1420     print "True\n"      if $array[$index];
1421
1422 A hash or array element can be true only if it's defined, and defined if
1423 it exists, but the reverse doesn't necessarily hold true.
1424
1425 Note that the EXPR can be arbitrarily complicated as long as the final
1426 operation is a hash or array key lookup:
1427
1428     if (exists $ref->{A}->{B}->{$key})  { }
1429     if (exists $hash{A}{B}{$key})       { }
1430
1431     if (exists $ref->{A}->{B}->[$ix])   { }
1432     if (exists $hash{A}{B}[$ix])        { }
1433
1434 Although the deepest nested array or hash will not spring into existence
1435 just because its existence was tested, any intervening ones will.
1436 Thus C<$ref-E<gt>{"A"}> and C<$ref-E<gt>{"A"}-E<gt>{"B"}> will spring
1437 into existence due to the existence test for the $key element above.
1438 This happens anywhere the arrow operator is used, including even:
1439
1440     undef $ref;
1441     if (exists $ref->{"Some key"})      { }
1442     print $ref;             # prints HASH(0x80d3d5c)
1443
1444 This surprising autovivification in what does not at first--or even
1445 second--glance appear to be an lvalue context may be fixed in a future
1446 release.
1447
1448 See L<perlref/"Pseudo-hashes"> for specifics on how exists() acts when
1449 used on a pseudo-hash.
1450
1451 =item exit EXPR
1452
1453 Evaluates EXPR and exits immediately with that value.    Example:
1454
1455     $ans = <STDIN>;
1456     exit 0 if $ans =~ /^[Xx]/;
1457
1458 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1459 universally recognized values for EXPR are C<0> for success and C<1>
1460 for error; other values are subject to interpretation depending on the
1461 environment in which the Perl program is running.  For example, exiting
1462 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1463 the mailer to return the item undelivered, but that's not true everywhere.
1464
1465 Don't use C<exit> to abort a subroutine if there's any chance that
1466 someone might want to trap whatever error happened.  Use C<die> instead,
1467 which can be trapped by an C<eval>.
1468
1469 The exit() function does not always exit immediately.  It calls any
1470 defined C<END> routines first, but these C<END> routines may not
1471 themselves abort the exit.  Likewise any object destructors that need to
1472 be called are called before the real exit.  If this is a problem, you
1473 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1474 See L<perlmod> for details.
1475
1476 =item exp EXPR
1477
1478 =item exp
1479
1480 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1481 If EXPR is omitted, gives C<exp($_)>.
1482
1483 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1484
1485 Implements the fcntl(2) function.  You'll probably have to say
1486
1487     use Fcntl;
1488
1489 first to get the correct constant definitions.  Argument processing and
1490 value return works just like C<ioctl> below.  
1491 For example:
1492
1493     use Fcntl;
1494     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1495         or die "can't fcntl F_GETFL: $!";
1496
1497 You don't have to check for C<defined> on the return from C<fnctl>.
1498 Like C<ioctl>, it maps a C<0> return from the system call into
1499 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1500 in numeric context.  It is also exempt from the normal B<-w> warnings
1501 on improper numeric conversions.
1502
1503 Note that C<fcntl> will produce a fatal error if used on a machine that
1504 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1505 manpage to learn what functions are available on your system.
1506
1507 =item fileno FILEHANDLE
1508
1509 Returns the file descriptor for a filehandle, or undefined if the
1510 filehandle is not open.  This is mainly useful for constructing
1511 bitmaps for C<select> and low-level POSIX tty-handling operations.
1512 If FILEHANDLE is an expression, the value is taken as an indirect
1513 filehandle, generally its name.
1514
1515 You can use this to find out whether two handles refer to the 
1516 same underlying descriptor:
1517
1518     if (fileno(THIS) == fileno(THAT)) {
1519         print "THIS and THAT are dups\n";
1520     } 
1521
1522 =item flock FILEHANDLE,OPERATION
1523
1524 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1525 for success, false on failure.  Produces a fatal error if used on a
1526 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1527 C<flock> is Perl's portable file locking interface, although it locks
1528 only entire files, not records.
1529
1530 Two potentially non-obvious but traditional C<flock> semantics are
1531 that it waits indefinitely until the lock is granted, and that its locks
1532 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1533 fewer guarantees.  This means that files locked with C<flock> may be
1534 modified by programs that do not also use C<flock>.  See L<perlport>,
1535 your port's specific documentation, or your system-specific local manpages
1536 for details.  It's best to assume traditional behavior if you're writing
1537 portable programs.  (But if you're not, you should as always feel perfectly
1538 free to write for your own system's idiosyncrasies (sometimes called
1539 "features").  Slavish adherence to portability concerns shouldn't get
1540 in the way of your getting your job done.)
1541
1542 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1543 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1544 you can use the symbolic names if import them from the Fcntl module,
1545 either individually, or as a group using the ':flock' tag.  LOCK_SH
1546 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1547 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1548 LOCK_EX then C<flock> will return immediately rather than blocking
1549 waiting for the lock (check the return status to see if you got it).
1550
1551 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1552 before locking or unlocking it.
1553
1554 Note that the emulation built with lockf(3) doesn't provide shared
1555 locks, and it requires that FILEHANDLE be open with write intent.  These
1556 are the semantics that lockf(3) implements.  Most if not all systems
1557 implement lockf(3) in terms of fcntl(2) locking, though, so the
1558 differing semantics shouldn't bite too many people.
1559
1560 Note also that some versions of C<flock> cannot lock things over the
1561 network; you would need to use the more system-specific C<fcntl> for
1562 that.  If you like you can force Perl to ignore your system's flock(2)
1563 function, and so provide its own fcntl(2)-based emulation, by passing
1564 the switch C<-Ud_flock> to the F<Configure> program when you configure
1565 perl.
1566
1567 Here's a mailbox appender for BSD systems.
1568
1569     use Fcntl ':flock'; # import LOCK_* constants
1570
1571     sub lock {
1572         flock(MBOX,LOCK_EX);
1573         # and, in case someone appended
1574         # while we were waiting...
1575         seek(MBOX, 0, 2);
1576     }
1577
1578     sub unlock {
1579         flock(MBOX,LOCK_UN);
1580     }
1581
1582     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1583             or die "Can't open mailbox: $!";
1584
1585     lock();
1586     print MBOX $msg,"\n\n";
1587     unlock();
1588
1589 On systems that support a real flock(), locks are inherited across fork()
1590 calls, whereas those that must resort to the more capricious fcntl()
1591 function lose the locks, making it harder to write servers.
1592
1593 See also L<DB_File> for other flock() examples.
1594
1595 =item fork
1596
1597 Does a fork(2) system call to create a new process running the
1598 same program at the same point.  It returns the child pid to the
1599 parent process, C<0> to the child process, or C<undef> if the fork is
1600 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1601 are shared, while everything else is copied.  On most systems supporting
1602 fork(), great care has gone into making it extremely efficient (for
1603 example, using copy-on-write technology on data pages), making it the
1604 dominant paradigm for multitasking over the last few decades.
1605
1606 All files opened for output are flushed before forking the child process.
1607
1608 If you C<fork> without ever waiting on your children, you will
1609 accumulate zombies.  On some systems, you can avoid this by setting
1610 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1611 forking and reaping moribund children.
1612
1613 Note that if your forked child inherits system file descriptors like
1614 STDIN and STDOUT that are actually connected by a pipe or socket, even
1615 if you exit, then the remote server (such as, say, a CGI script or a
1616 backgrounded job launched from a remote shell) won't think you're done.
1617 You should reopen those to F</dev/null> if it's any issue.
1618
1619 =item format
1620
1621 Declare a picture format for use by the C<write> function.  For
1622 example:
1623
1624     format Something =
1625         Test: @<<<<<<<< @||||| @>>>>>
1626               $str,     $%,    '$' . int($num)
1627     .
1628
1629     $str = "widget";
1630     $num = $cost/$quantity;
1631     $~ = 'Something';
1632     write;
1633
1634 See L<perlform> for many details and examples.
1635
1636 =item formline PICTURE,LIST
1637
1638 This is an internal function used by C<format>s, though you may call it,
1639 too.  It formats (see L<perlform>) a list of values according to the
1640 contents of PICTURE, placing the output into the format output
1641 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1642 Eventually, when a C<write> is done, the contents of
1643 C<$^A> are written to some filehandle, but you could also read C<$^A>
1644 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1645 does one C<formline> per line of form, but the C<formline> function itself
1646 doesn't care how many newlines are embedded in the PICTURE.  This means
1647 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1648 You may therefore need to use multiple formlines to implement a single
1649 record format, just like the format compiler.
1650
1651 Be careful if you put double quotes around the picture, because an C<@>
1652 character may be taken to mean the beginning of an array name.
1653 C<formline> always returns true.  See L<perlform> for other examples.
1654
1655 =item getc FILEHANDLE
1656
1657 =item getc
1658
1659 Returns the next character from the input file attached to FILEHANDLE,
1660 or the undefined value at end of file, or if there was an error.
1661 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1662 efficient.  However, it cannot be used by itself to fetch single
1663 characters without waiting for the user to hit enter.  For that, try
1664 something more like:
1665
1666     if ($BSD_STYLE) {
1667         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1668     }
1669     else {
1670         system "stty", '-icanon', 'eol', "\001";
1671     }
1672
1673     $key = getc(STDIN);
1674
1675     if ($BSD_STYLE) {
1676         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1677     }
1678     else {
1679         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1680     }
1681     print "\n";
1682
1683 Determination of whether $BSD_STYLE should be set
1684 is left as an exercise to the reader.
1685
1686 The C<POSIX::getattr> function can do this more portably on
1687 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1688 module from your nearest CPAN site; details on CPAN can be found on
1689 L<perlmodlib/CPAN>.
1690
1691 =item getlogin
1692
1693 Implements the C library function of the same name, which on most
1694 systems returns the current login from F</etc/utmp>, if any.  If null,
1695 use C<getpwuid>.
1696
1697     $login = getlogin || getpwuid($<) || "Kilroy";
1698
1699 Do not consider C<getlogin> for authentication: it is not as
1700 secure as C<getpwuid>.
1701
1702 =item getpeername SOCKET
1703
1704 Returns the packed sockaddr address of other end of the SOCKET connection.
1705
1706     use Socket;
1707     $hersockaddr    = getpeername(SOCK);
1708     ($port, $iaddr) = sockaddr_in($hersockaddr);
1709     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1710     $herstraddr     = inet_ntoa($iaddr);
1711
1712 =item getpgrp PID
1713
1714 Returns the current process group for the specified PID.  Use
1715 a PID of C<0> to get the current process group for the
1716 current process.  Will raise an exception if used on a machine that
1717 doesn't implement getpgrp(2).  If PID is omitted, returns process
1718 group of current process.  Note that the POSIX version of C<getpgrp>
1719 does not accept a PID argument, so only C<PID==0> is truly portable.
1720
1721 =item getppid
1722
1723 Returns the process id of the parent process.
1724
1725 =item getpriority WHICH,WHO
1726
1727 Returns the current priority for a process, a process group, or a user.
1728 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1729 machine that doesn't implement getpriority(2).
1730
1731 =item getpwnam NAME
1732
1733 =item getgrnam NAME
1734
1735 =item gethostbyname NAME
1736
1737 =item getnetbyname NAME
1738
1739 =item getprotobyname NAME
1740
1741 =item getpwuid UID
1742
1743 =item getgrgid GID
1744
1745 =item getservbyname NAME,PROTO
1746
1747 =item gethostbyaddr ADDR,ADDRTYPE
1748
1749 =item getnetbyaddr ADDR,ADDRTYPE
1750
1751 =item getprotobynumber NUMBER
1752
1753 =item getservbyport PORT,PROTO
1754
1755 =item getpwent
1756
1757 =item getgrent
1758
1759 =item gethostent
1760
1761 =item getnetent
1762
1763 =item getprotoent
1764
1765 =item getservent
1766
1767 =item setpwent
1768
1769 =item setgrent
1770
1771 =item sethostent STAYOPEN
1772
1773 =item setnetent STAYOPEN
1774
1775 =item setprotoent STAYOPEN
1776
1777 =item setservent STAYOPEN
1778
1779 =item endpwent
1780
1781 =item endgrent
1782
1783 =item endhostent
1784
1785 =item endnetent
1786
1787 =item endprotoent
1788
1789 =item endservent
1790
1791 These routines perform the same functions as their counterparts in the
1792 system library.  In list context, the return values from the
1793 various get routines are as follows:
1794
1795     ($name,$passwd,$uid,$gid,
1796        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1797     ($name,$passwd,$gid,$members) = getgr*
1798     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1799     ($name,$aliases,$addrtype,$net) = getnet*
1800     ($name,$aliases,$proto) = getproto*
1801     ($name,$aliases,$port,$proto) = getserv*
1802
1803 (If the entry doesn't exist you get a null list.)
1804
1805 In scalar context, you get the name, unless the function was a
1806 lookup by name, in which case you get the other thing, whatever it is.
1807 (If the entry doesn't exist you get the undefined value.)  For example:
1808
1809     $uid   = getpwnam($name);
1810     $name  = getpwuid($num);
1811     $name  = getpwent();
1812     $gid   = getgrnam($name);
1813     $name  = getgrgid($num;
1814     $name  = getgrent();
1815     #etc.
1816
1817 In I<getpw*()> the fields $quota, $comment, and $expire are
1818 special cases in the sense that in many systems they are unsupported.
1819 If the $quota is unsupported, it is an empty scalar.  If it is
1820 supported, it usually encodes the disk quota.  If the $comment
1821 field is unsupported, it is an empty scalar.  If it is supported it
1822 usually encodes some administrative comment about the user.  In some
1823 systems the $quota field may be $change or $age, fields that have
1824 to do with password aging.  In some systems the $comment field may
1825 be $class.  The $expire field, if present, encodes the expiration
1826 period of the account or the password.  For the availability and the
1827 exact meaning of these fields in your system, please consult your
1828 getpwnam(3) documentation and your F<pwd.h> file.  You can also find
1829 out from within Perl what your $quota and $comment fields mean
1830 and whether you have the $expire field by using the C<Config> module
1831 and the values C<d_pwquota>, C<d_pwage>, C<d_pwchange>, C<d_pwcomment>,
1832 and C<d_pwexpire>.  Shadow password files are only supported if your
1833 vendor has implemented them in the intuitive fashion that calling the
1834 regular C library routines gets the shadow versions if you're running
1835 under privilege.  Those that incorrectly implement a separate library
1836 call are not supported.
1837
1838 The $members value returned by I<getgr*()> is a space separated list of
1839 the login names of the members of the group.
1840
1841 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1842 C, it will be returned to you via C<$?> if the function call fails.  The
1843 C<@addrs> value returned by a successful call is a list of the raw
1844 addresses returned by the corresponding system library call.  In the
1845 Internet domain, each address is four bytes long and you can unpack it
1846 by saying something like:
1847
1848     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1849
1850 The Socket library makes this slightly easier:
1851
1852     use Socket;
1853     $iaddr = inet_aton("127.1"); # or whatever address
1854     $name  = gethostbyaddr($iaddr, AF_INET);
1855
1856     # or going the other way
1857     $straddr = inet_ntoa($iaddr);
1858
1859 If you get tired of remembering which element of the return list
1860 contains which return value, by-name interfaces are provided
1861 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1862 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1863 and C<User::grent>.  These override the normal built-ins, supplying
1864 versions that return objects with the appropriate names
1865 for each field.  For example:
1866
1867    use File::stat;
1868    use User::pwent;
1869    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1870
1871 Even though it looks like they're the same method calls (uid), 
1872 they aren't, because a C<File::stat> object is different from 
1873 a C<User::pwent> object.
1874
1875 =item getsockname SOCKET
1876
1877 Returns the packed sockaddr address of this end of the SOCKET connection,
1878 in case you don't know the address because you have several different
1879 IPs that the connection might have come in on.
1880
1881     use Socket;
1882     $mysockaddr = getsockname(SOCK);
1883     ($port, $myaddr) = sockaddr_in($mysockaddr);
1884     printf "Connect to %s [%s]\n", 
1885        scalar gethostbyaddr($myaddr, AF_INET),
1886        inet_ntoa($myaddr);
1887
1888 =item getsockopt SOCKET,LEVEL,OPTNAME
1889
1890 Returns the socket option requested, or undef if there is an error.
1891
1892 =item glob EXPR
1893
1894 =item glob
1895
1896 Returns the value of EXPR with filename expansions such as the
1897 standard Unix shell F</bin/csh> would do.  This is the internal function
1898 implementing the C<E<lt>*.cE<gt>> operator, but you can use it directly.
1899 If EXPR is omitted, C<$_> is used.  The C<E<lt>*.cE<gt>> operator is
1900 discussed in more detail in L<perlop/"I/O Operators">.
1901
1902 =item gmtime EXPR
1903
1904 Converts a time as returned by the time function to a 9-element list
1905 with the time localized for the standard Greenwich time zone.
1906 Typically used as follows:
1907
1908     #  0    1    2     3     4    5     6     7     8
1909     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1910                                             gmtime(time);
1911
1912 All list elements are numeric, and come straight out of a struct tm.
1913 In particular this means that $mon has the range C<0..11> and $wday
1914 has the range C<0..6> with sunday as day C<0>.  Also, $year is the
1915 number of years since 1900, that is, $year is C<123> in year 2023,
1916 I<not> simply the last two digits of the year.  If you assume it is,
1917 then you create non-Y2K-compliant programs--and you wouldn't want to do
1918 that, would you?
1919
1920 The proper way to get a complete 4-digit year is simply:
1921
1922         $year += 1900;
1923
1924 And to get the last two digits of the year (e.g., '01' in 2001) do:
1925
1926         $year = sprintf("%02d", $year % 100);
1927
1928 If EXPR is omitted, does C<gmtime(time())>.
1929
1930 In scalar context, returns the ctime(3) value:
1931
1932     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1933
1934 Also see the C<timegm> function provided by the C<Time::Local> module,
1935 and the strftime(3) function available via the POSIX module.
1936
1937 This scalar value is B<not> locale dependent (see L<perllocale>), but
1938 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
1939 strftime(3) and mktime(3) functions available via the POSIX module.  To
1940 get somewhat similar but locale dependent date strings, set up your
1941 locale environment variables appropriately (please see L<perllocale>)
1942 and try for example:
1943
1944     use POSIX qw(strftime);
1945     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1946
1947 Note that the C<%a> and C<%b> escapes, which represent the short forms
1948 of the day of the week and the month of the year, may not necessarily
1949 be three characters wide in all locales.
1950
1951 =item goto LABEL
1952
1953 =item goto EXPR
1954
1955 =item goto &NAME
1956
1957 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1958 execution there.  It may not be used to go into any construct that
1959 requires initialization, such as a subroutine or a C<foreach> loop.  It
1960 also can't be used to go into a construct that is optimized away,
1961 or to get out of a block or subroutine given to C<sort>.
1962 It can be used to go almost anywhere else within the dynamic scope,
1963 including out of subroutines, but it's usually better to use some other
1964 construct such as C<last> or C<die>.  The author of Perl has never felt the
1965 need to use this form of C<goto> (in Perl, that is--C is another matter).
1966
1967 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1968 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1969 necessarily recommended if you're optimizing for maintainability:
1970
1971     goto ("FOO", "BAR", "GLARCH")[$i];
1972
1973 The C<goto-&NAME> form is quite different from the other forms of C<goto>.
1974 In fact, it isn't a goto in the normal sense at all, and doesn't have
1975 the stigma associated with other gotos.  Instead, it
1976 substitutes a call to the named subroutine for the currently running
1977 subroutine.  This is used by C<AUTOLOAD> subroutines that wish to load
1978 another subroutine and then pretend that the other subroutine had been
1979 called in the first place (except that any modifications to C<@_>
1980 in the current subroutine are propagated to the other subroutine.)
1981 After the C<goto>, not even C<caller> will be able to tell that this
1982 routine was called first.
1983
1984 NAME needn't be the name of a subroutine; it can be a scalar variable
1985 containing a code reference, or a block which evaluates to a code
1986 reference.
1987
1988 =item grep BLOCK LIST
1989
1990 =item grep EXPR,LIST
1991
1992 This is similar in spirit to, but not the same as, grep(1) and its
1993 relatives.  In particular, it is not limited to using regular expressions.
1994
1995 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1996 C<$_> to each element) and returns the list value consisting of those
1997 elements for which the expression evaluated to true.  In scalar
1998 context, returns the number of times the expression was true.
1999
2000     @foo = grep(!/^#/, @bar);    # weed out comments
2001
2002 or equivalently,
2003
2004     @foo = grep {!/^#/} @bar;    # weed out comments
2005
2006 Note that, because C<$_> is a reference into the list value, it can
2007 be used to modify the elements of the array.  While this is useful and
2008 supported, it can cause bizarre results if the LIST is not a named array.
2009 Similarly, grep returns aliases into the original list, much as a for
2010 loop's index variable aliases the list elements.  That is, modifying an
2011 element of a list returned by grep (for example, in a C<foreach>, C<map>
2012 or another C<grep>) actually modifies the element in the original list.
2013 This is usually something to be avoided when writing clear code.
2014
2015 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2016
2017 =item hex EXPR
2018
2019 =item hex
2020
2021 Interprets EXPR as a hex string and returns the corresponding value.
2022 (To convert strings that might start with either 0, 0x, or 0b, see
2023 L</oct>.)  If EXPR is omitted, uses C<$_>.
2024
2025     print hex '0xAf'; # prints '175'
2026     print hex 'aF';   # same
2027
2028 Hex strings may only represent integers.  Strings that would cause
2029 integer overflow trigger a warning.
2030
2031 =item import
2032
2033 There is no builtin C<import> function.  It is just an ordinary
2034 method (subroutine) defined (or inherited) by modules that wish to export
2035 names to another module.  The C<use> function calls the C<import> method
2036 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
2037
2038 =item index STR,SUBSTR,POSITION
2039
2040 =item index STR,SUBSTR
2041
2042 The index function searches for one string within another, but without
2043 the wildcard-like behavior of a full regular-expression pattern match.
2044 It returns the position of the first occurrence of SUBSTR in STR at
2045 or after POSITION.  If POSITION is omitted, starts searching from the
2046 beginning of the string.  The return value is based at C<0> (or whatever
2047 you've set the C<$[> variable to--but don't do that).  If the substring
2048 is not found, returns one less than the base, ordinarily C<-1>.
2049
2050 =item int EXPR
2051
2052 =item int
2053
2054 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2055 You should not use this function for rounding: one because it truncates
2056 towards C<0>, and two because machine representations of floating point
2057 numbers can sometimes produce counterintuitive results.  For example,
2058 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2059 because it's really more like -268.99999999999994315658 instead.  Usually,
2060 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2061 functions will serve you better than will int().
2062
2063 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2064
2065 Implements the ioctl(2) function.  You'll probably first have to say
2066
2067     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2068
2069 to get the correct function definitions.  If F<ioctl.ph> doesn't
2070 exist or doesn't have the correct definitions you'll have to roll your
2071 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
2072 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2073 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2074 written depending on the FUNCTION--a pointer to the string value of SCALAR
2075 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2076 has no string value but does have a numeric value, that value will be
2077 passed rather than a pointer to the string value.  To guarantee this to be
2078 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2079 functions may be needed to manipulate the values of structures used by
2080 C<ioctl>.  
2081
2082 The return value of C<ioctl> (and C<fcntl>) is as follows:
2083
2084         if OS returns:          then Perl returns:
2085             -1                    undefined value
2086              0                  string "0 but true"
2087         anything else               that number
2088
2089 Thus Perl returns true on success and false on failure, yet you can
2090 still easily determine the actual value returned by the operating
2091 system:
2092
2093     $retval = ioctl(...) || -1;
2094     printf "System returned %d\n", $retval;
2095
2096 The special string "C<0> but true" is exempt from B<-w> complaints
2097 about improper numeric conversions.
2098
2099 Here's an example of setting a filehandle named C<REMOTE> to be
2100 non-blocking at the system level.  You'll have to negotiate C<$|>
2101 on your own, though.
2102
2103     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2104
2105     $flags = fcntl(REMOTE, F_GETFL, 0)
2106                 or die "Can't get flags for the socket: $!\n";
2107
2108     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2109                 or die "Can't set flags for the socket: $!\n";
2110
2111 =item join EXPR,LIST
2112
2113 Joins the separate strings of LIST into a single string with fields
2114 separated by the value of EXPR, and returns that new string.  Example:
2115
2116     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2117
2118 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2119 first argument.  Compare L</split>.
2120
2121 =item keys HASH
2122
2123 Returns a list consisting of all the keys of the named hash.  (In
2124 scalar context, returns the number of keys.)  The keys are returned in
2125 an apparently random order.  The actual random order is subject to
2126 change in future versions of perl, but it is guaranteed to be the same
2127 order as either the C<values> or C<each> function produces (given
2128 that the hash has not been modified).  As a side effect, it resets
2129 HASH's iterator.
2130
2131 Here is yet another way to print your environment:
2132
2133     @keys = keys %ENV;
2134     @values = values %ENV;
2135     while (@keys) { 
2136         print pop(@keys), '=', pop(@values), "\n";
2137     }
2138
2139 or how about sorted by key:
2140
2141     foreach $key (sort(keys %ENV)) {
2142         print $key, '=', $ENV{$key}, "\n";
2143     }
2144
2145 To sort a hash by value, you'll need to use a C<sort> function.
2146 Here's a descending numeric sort of a hash by its values:
2147
2148     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2149         printf "%4d %s\n", $hash{$key}, $key;
2150     }
2151
2152 As an lvalue C<keys> allows you to increase the number of hash buckets
2153 allocated for the given hash.  This can gain you a measure of efficiency if
2154 you know the hash is going to get big.  (This is similar to pre-extending
2155 an array by assigning a larger number to $#array.)  If you say
2156
2157     keys %hash = 200;
2158
2159 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2160 in fact, since it rounds up to the next power of two.  These
2161 buckets will be retained even if you do C<%hash = ()>, use C<undef
2162 %hash> if you want to free the storage while C<%hash> is still in scope.
2163 You can't shrink the number of buckets allocated for the hash using
2164 C<keys> in this way (but you needn't worry about doing this by accident,
2165 as trying has no effect).
2166
2167 See also C<each>, C<values> and C<sort>.
2168
2169 =item kill SIGNAL, LIST
2170
2171 Sends a signal to a list of processes.  Returns the number of
2172 processes successfully signaled (which is not necessarily the
2173 same as the number actually killed).
2174
2175     $cnt = kill 1, $child1, $child2;
2176     kill 9, @goners;
2177
2178 If SIGNAL is zero, no signal is sent to the process.  This is a
2179 useful way to check that the process is alive and hasn't changed
2180 its UID.  See L<perlport> for notes on the portability of this
2181 construct.
2182
2183 Unlike in the shell, if SIGNAL is negative, it kills
2184 process groups instead of processes.  (On System V, a negative I<PROCESS>
2185 number will also kill process groups, but that's not portable.)  That
2186 means you usually want to use positive not negative signals.  You may also
2187 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2188
2189 =item last LABEL
2190
2191 =item last
2192
2193 The C<last> command is like the C<break> statement in C (as used in
2194 loops); it immediately exits the loop in question.  If the LABEL is
2195 omitted, the command refers to the innermost enclosing loop.  The
2196 C<continue> block, if any, is not executed:
2197
2198     LINE: while (<STDIN>) {
2199         last LINE if /^$/;      # exit when done with header
2200         #...
2201     }
2202
2203 C<last> cannot be used to exit a block which returns a value such as
2204 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2205 a grep() or map() operation.
2206
2207 Note that a block by itself is semantically identical to a loop
2208 that executes once.  Thus C<last> can be used to effect an early
2209 exit out of such a block.
2210
2211 See also L</continue> for an illustration of how C<last>, C<next>, and
2212 C<redo> work.
2213
2214 =item lc EXPR
2215
2216 =item lc
2217
2218 Returns an lowercased version of EXPR.  This is the internal function
2219 implementing the C<\L> escape in double-quoted strings.
2220 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2221 and L<utf8>.
2222
2223 If EXPR is omitted, uses C<$_>.
2224
2225 =item lcfirst EXPR
2226
2227 =item lcfirst
2228
2229 Returns the value of EXPR with the first character lowercased.  This is
2230 the internal function implementing the C<\l> escape in double-quoted strings.
2231 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2232
2233 If EXPR is omitted, uses C<$_>.
2234
2235 =item length EXPR
2236
2237 =item length
2238
2239 Returns the length in characters of the value of EXPR.  If EXPR is
2240 omitted, returns length of C<$_>.  Note that this cannot be used on 
2241 an entire array or hash to find out how many elements these have.
2242 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2243
2244 =item link OLDFILE,NEWFILE
2245
2246 Creates a new filename linked to the old filename.  Returns true for
2247 success, false otherwise. 
2248
2249 =item listen SOCKET,QUEUESIZE
2250
2251 Does the same thing that the listen system call does.  Returns true if
2252 it succeeded, false otherwise.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2253
2254 =item local EXPR
2255
2256 You really probably want to be using C<my> instead, because C<local> isn't
2257 what most people think of as "local".  See L<perlsub/"Private Variables
2258 via my()"> for details.
2259
2260 A local modifies the listed variables to be local to the enclosing
2261 block, file, or eval.  If more than one value is listed, the list must
2262 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2263 for details, including issues with tied arrays and hashes.
2264
2265 =item localtime EXPR
2266
2267 Converts a time as returned by the time function to a 9-element list
2268 with the time analyzed for the local time zone.  Typically used as
2269 follows:
2270
2271     #  0    1    2     3     4    5     6     7     8
2272     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2273                                                 localtime(time);
2274
2275 All list elements are numeric, and come straight out of a struct tm.
2276 In particular this means that $mon has the range C<0..11> and $wday
2277 has the range C<0..6> with sunday as day C<0>.  Also, $year is the
2278 number of years since 1900, that is, $year is C<123> in year 2023,
2279 and I<not> simply the last two digits of the year.  If you assume it is,
2280 then you create non-Y2K-compliant programs--and you wouldn't want to do
2281 that, would you?
2282
2283 The proper way to get a complete 4-digit year is simply:
2284
2285         $year += 1900;
2286
2287 And to get the last two digits of the year (e.g., '01' in 2001) do:
2288
2289         $year = sprintf("%02d", $year % 100);
2290
2291 If EXPR is omitted, uses the current time (C<localtime(time)>).
2292
2293 In scalar context, returns the ctime(3) value:
2294
2295     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2296
2297 This scalar value is B<not> locale dependent, see L<perllocale>, but
2298 instead a Perl builtin.  Also see the C<Time::Local> module
2299 (to convert the second, minutes, hours, ... back to seconds since the
2300 stroke of midnight the 1st of January 1970, the value returned by
2301 time()), and the strftime(3) and mktime(3) function available via the
2302 POSIX module.  To get somewhat similar but locale dependent date
2303 strings, set up your locale environment variables appropriately
2304 (please see L<perllocale>) and try for example:
2305
2306     use POSIX qw(strftime);
2307     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2308
2309 Note that the C<%a> and C<%b>, the short forms of the day of the week
2310 and the month of the year, may not necessarily be three characters wide.
2311
2312 =item lock
2313
2314     lock I<THING>
2315
2316 This function places an advisory lock on a variable, subroutine,
2317 or referenced object contained in I<THING> until the lock goes out
2318 of scope.  This is a built-in function only if your version of Perl
2319 was built with threading enabled, and if you've said C<use Threads>.
2320 Otherwise a user-defined function by this name will be called.  See
2321 L<Thread>.
2322
2323 =item log EXPR
2324
2325 =item log
2326
2327 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2328 returns log of C<$_>.  To get the log of another base, use basic algebra:
2329 The base-N log of a number is equal to the natural log of that number
2330 divided by the natural log of N.  For example:
2331
2332     sub log10 {
2333         my $n = shift;
2334         return log($n)/log(10);
2335     } 
2336
2337 See also L</exp> for the inverse operation.
2338
2339 =item lstat FILEHANDLE
2340
2341 =item lstat EXPR
2342
2343 =item lstat
2344
2345 Does the same thing as the C<stat> function (including setting the
2346 special C<_> filehandle) but stats a symbolic link instead of the file
2347 the symbolic link points to.  If symbolic links are unimplemented on
2348 your system, a normal C<stat> is done.
2349
2350 If EXPR is omitted, stats C<$_>.
2351
2352 =item m//
2353
2354 The match operator.  See L<perlop>.
2355
2356 =item map BLOCK LIST
2357
2358 =item map EXPR,LIST
2359
2360 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2361 C<$_> to each element) and returns the list value composed of the
2362 results of each such evaluation.  In scalar context, returns the
2363 total number of elements so generated.  Evaluates BLOCK or EXPR in
2364 list context, so each element of LIST may produce zero, one, or
2365 more elements in the returned value.
2366
2367     @chars = map(chr, @nums);
2368
2369 translates a list of numbers to the corresponding characters.  And
2370
2371     %hash = map { getkey($_) => $_ } @array;
2372
2373 is just a funny way to write
2374
2375     %hash = ();
2376     foreach $_ (@array) {
2377         $hash{getkey($_)} = $_;
2378     }
2379
2380 Note that, because C<$_> is a reference into the list value, it can
2381 be used to modify the elements of the array.  While this is useful and
2382 supported, it can cause bizarre results if the LIST is not a named array.
2383 Using a regular C<foreach> loop for this purpose would be clearer in
2384 most cases.  See also L</grep> for an array composed of those items of
2385 the original list for which the BLOCK or EXPR evaluates to true.
2386
2387 =item mkdir FILENAME,MASK
2388
2389 Creates the directory specified by FILENAME, with permissions
2390 specified by MASK (as modified by C<umask>).  If it succeeds it
2391 returns true, otherwise it returns false and sets C<$!> (errno).
2392
2393 In general, it is better to create directories with permissive MASK,
2394 and let the user modify that with their C<umask>, than it is to supply
2395 a restrictive MASK and give the user no way to be more permissive.
2396 The exceptions to this rule are when the file or directory should be
2397 kept private (mail files, for instance).  The perlfunc(1) entry on
2398 C<umask> discusses the choice of MASK in more detail.
2399
2400 =item msgctl ID,CMD,ARG
2401
2402 Calls the System V IPC function msgctl(2).  You'll probably have to say
2403
2404     use IPC::SysV;
2405
2406 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2407 then ARG must be a variable which will hold the returned C<msqid_ds>
2408 structure.  Returns like C<ioctl>: the undefined value for error,
2409 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2410 C<IPC::SysV> and C<IPC::Semaphore> documentation.
2411
2412 =item msgget KEY,FLAGS
2413
2414 Calls the System V IPC function msgget(2).  Returns the message queue
2415 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2416 and C<IPC::Msg> documentation.
2417
2418 =item msgsnd ID,MSG,FLAGS
2419
2420 Calls the System V IPC function msgsnd to send the message MSG to the
2421 message queue ID.  MSG must begin with the long integer message type,
2422 which may be created with C<pack("l", $type)>.  Returns true if
2423 successful, or false if there is an error.  See also C<IPC::SysV>
2424 and C<IPC::SysV::Msg> documentation.
2425
2426 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2427
2428 Calls the System V IPC function msgrcv to receive a message from
2429 message queue ID into variable VAR with a maximum message size of
2430 SIZE.  Note that if a message is received, the message type will be
2431 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2432 size of the message type.  Returns true if successful, or false if
2433 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2434
2435 =item my EXPR
2436
2437 =item my EXPR : ATTRIBUTES
2438
2439 A C<my> declares the listed variables to be local (lexically) to the
2440 enclosing block, file, or C<eval>.  If
2441 more than one value is listed, the list must be placed in parentheses.  See
2442 L<perlsub/"Private Variables via my()"> for details.
2443
2444 =item next LABEL
2445
2446 =item next
2447
2448 The C<next> command is like the C<continue> statement in C; it starts
2449 the next iteration of the loop:
2450
2451     LINE: while (<STDIN>) {
2452         next LINE if /^#/;      # discard comments
2453         #...
2454     }
2455
2456 Note that if there were a C<continue> block on the above, it would get
2457 executed even on discarded lines.  If the LABEL is omitted, the command
2458 refers to the innermost enclosing loop.
2459
2460 C<next> cannot be used to exit a block which returns a value such as
2461 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2462 a grep() or map() operation.
2463
2464 Note that a block by itself is semantically identical to a loop
2465 that executes once.  Thus C<next> will exit such a block early.
2466
2467 See also L</continue> for an illustration of how C<last>, C<next>, and
2468 C<redo> work.
2469
2470 =item no Module LIST
2471
2472 See the L</use> function, which C<no> is the opposite of.
2473
2474 =item oct EXPR
2475
2476 =item oct
2477
2478 Interprets EXPR as an octal string and returns the corresponding
2479 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2480 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2481 binary string.)  The following will handle decimal, binary, octal, and
2482 hex in the standard Perl or C notation:
2483
2484     $val = oct($val) if $val =~ /^0/;
2485
2486 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2487 in octal), use sprintf() or printf():
2488
2489     $perms = (stat("filename"))[2] & 07777;
2490     $oct_perms = sprintf "%lo", $perms;
2491
2492 The oct() function is commonly used when a string such as C<644> needs
2493 to be converted into a file mode, for example. (Although perl will
2494 automatically convert strings into numbers as needed, this automatic
2495 conversion assumes base 10.)
2496
2497 =item open FILEHANDLE,MODE,EXPR
2498
2499 =item open FILEHANDLE,EXPR
2500
2501 =item open FILEHANDLE
2502
2503 Opens the file whose filename is given by EXPR, and associates it with
2504 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2505 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2506 variable of the same name as the FILEHANDLE contains the filename.
2507 (Note that lexical variables--those declared with C<my>--will not work
2508 for this purpose; so if you're using C<my>, specify EXPR in your call
2509 to open.)  See L<perlopentut> for a kinder, gentler explanation of opening
2510 files.
2511
2512 If MODE is C<'E<lt>'> or nothing, the file is opened for input.
2513 If MODE is C<'E<gt>'>, the file is truncated and opened for
2514 output, being created if necessary.  If MODE is C<'E<gt>E<gt>'>,
2515 the file is opened for appending, again being created if necessary. 
2516 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2517 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2518 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2519 file first.  You can't usually use either read-write mode for updating
2520 textfiles, since they have variable length records.  See the B<-i>
2521 switch in L<perlrun> for a better approach.  The file is created with
2522 permissions of C<0666> modified by the process' C<umask> value.
2523
2524 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, C<'w'>,
2525 C<'w+'>, C<'a'>, and C<'a+'>.
2526
2527 In the 2-arguments (and 1-argument) form of the call the mode and
2528 filename should be concatenated (in this order), possibly separated by
2529 spaces.  It is possible to omit the mode if the mode is C<'E<lt>'>.
2530
2531 If the filename begins with C<'|'>, the filename is interpreted as a
2532 command to which output is to be piped, and if the filename ends with a
2533 C<'|'>, the filename is interpreted as a command which pipes output to
2534 us.  See L<perlipc/"Using open() for IPC">
2535 for more examples of this.  (You are not allowed to C<open> to a command
2536 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2537 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2538
2539 If MODE is C<'|-'>, the filename is interpreted as a
2540 command to which output is to be piped, and if MODE is
2541 C<'-|'>, the filename is interpreted as a command which pipes output to
2542 us.  In the 2-arguments (and 1-argument) form one should replace dash
2543 (C<'-'>) with the command.  See L<perlipc/"Using open() for IPC">
2544 for more examples of this.  (You are not allowed to C<open> to a command
2545 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2546 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2547
2548 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2549 and opening C<'E<gt>-'> opens STDOUT.  
2550
2551 Open returns
2552 nonzero upon success, the undefined value otherwise.  If the C<open>
2553 involved a pipe, the return value happens to be the pid of the
2554 subprocess.
2555
2556 If you're unfortunate enough to be running Perl on a system that
2557 distinguishes between text files and binary files (modern operating
2558 systems don't care), then you should check out L</binmode> for tips for
2559 dealing with this.  The key distinction between systems that need C<binmode>
2560 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2561 Plan9, which delimit lines with a single character, and which encode that
2562 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2563
2564 When opening a file, it's usually a bad idea to continue normal execution
2565 if the request failed, so C<open> is frequently used in connection with
2566 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2567 where you want to make a nicely formatted error message (but there are
2568 modules that can help with that problem)) you should always check
2569 the return value from opening a file.  The infrequent exception is when
2570 working with an unopened filehandle is actually what you want to do.
2571
2572 Examples:
2573
2574     $ARTICLE = 100;
2575     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2576     while (<ARTICLE>) {...
2577
2578     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2579     # if the open fails, output is discarded
2580
2581     open(DBASE, '+<', 'dbase.mine')             # open for update
2582         or die "Can't open 'dbase.mine' for update: $!";
2583
2584     open(DBASE, '+<dbase.mine')                 # ditto
2585         or die "Can't open 'dbase.mine' for update: $!";
2586
2587     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2588         or die "Can't start caesar: $!";
2589
2590     open(ARTICLE, "caesar <$article |")         # ditto
2591         or die "Can't start caesar: $!";
2592
2593     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2594         or die "Can't start sort: $!";
2595
2596     # process argument list of files along with any includes
2597
2598     foreach $file (@ARGV) {
2599         process($file, 'fh00');
2600     }
2601
2602     sub process {
2603         my($filename, $input) = @_;
2604         $input++;               # this is a string increment
2605         unless (open($input, $filename)) {
2606             print STDERR "Can't open $filename: $!\n";
2607             return;
2608         }
2609
2610         local $_;
2611         while (<$input>) {              # note use of indirection
2612             if (/^#include "(.*)"/) {
2613                 process($1, $input);
2614                 next;
2615             }
2616             #...                # whatever
2617         }
2618     }
2619
2620 You may also, in the Bourne shell tradition, specify an EXPR beginning
2621 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2622 name of a filehandle (or file descriptor, if numeric) to be
2623 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>,
2624 C<E<lt>>, C<+E<gt>>, C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2625 mode you specify should match the mode of the original filehandle.
2626 (Duping a filehandle does not take into account any existing contents of
2627 stdio buffers.)  Duping file handles is not yet supported for 3-argument
2628 open().
2629
2630 Here is a script that saves, redirects, and restores STDOUT and
2631 STDERR:
2632
2633     #!/usr/bin/perl
2634     open(OLDOUT, ">&STDOUT");
2635     open(OLDERR, ">&STDERR");
2636
2637     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2638     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2639
2640     select(STDERR); $| = 1;     # make unbuffered
2641     select(STDOUT); $| = 1;     # make unbuffered
2642
2643     print STDOUT "stdout 1\n";  # this works for
2644     print STDERR "stderr 1\n";  # subprocesses too
2645
2646     close(STDOUT);
2647     close(STDERR);
2648
2649     open(STDOUT, ">&OLDOUT");
2650     open(STDERR, ">&OLDERR");
2651
2652     print STDOUT "stdout 2\n";
2653     print STDERR "stderr 2\n";
2654
2655 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2656 equivalent of C's C<fdopen> of that file descriptor; this is more
2657 parsimonious of file descriptors.  For example:
2658
2659     open(FILEHANDLE, "<&=$fd")
2660
2661 Note that this feature depends on the fdopen() C library function.
2662 On many UNIX systems, fdopen() is known to fail when file descriptors
2663 exceed a certain value, typically 255. If you need more file
2664 descriptors than that, consider rebuilding Perl to use the C<sfio>
2665 library.
2666
2667 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2668 with 2-arguments (or 1-argument) form of open(), then
2669 there is an implicit fork done, and the return value of open is the pid
2670 of the child within the parent process, and C<0> within the child
2671 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2672 The filehandle behaves normally for the parent, but i/o to that
2673 filehandle is piped from/to the STDOUT/STDIN of the child process.
2674 In the child process the filehandle isn't opened--i/o happens from/to
2675 the new STDOUT or STDIN.  Typically this is used like the normal
2676 piped open when you want to exercise more control over just how the
2677 pipe command gets executed, such as when you are running setuid, and
2678 don't want to have to scan shell commands for metacharacters.
2679 The following triples are more or less equivalent:
2680
2681     open(FOO, "|tr '[a-z]' '[A-Z]'");
2682     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2683     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2684
2685     open(FOO, "cat -n '$file'|");
2686     open(FOO, '-|', "cat -n '$file'");
2687     open(FOO, '-|') || exec 'cat', '-n', $file;
2688
2689 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2690
2691 NOTE: On any operation that may do a fork, all files opened for output
2692 are flushed before the fork is attempted.  On systems that support a
2693 close-on-exec flag on files, the flag will be set for the newly opened
2694 file descriptor as determined by the value of $^F.  See L<perlvar/$^F>.
2695
2696 Closing any piped filehandle causes the parent process to wait for the
2697 child to finish, and returns the status value in C<$?>.
2698
2699 The filename passed to 2-argument (or 1-argument) form of open()
2700 will have leading and trailing
2701 whitespace deleted, and the normal redirection characters
2702 honored.  This property, known as "magic open", 
2703 can often be used to good effect.  A user could specify a filename of
2704 F<"rsh cat file |">, or you could change certain filenames as needed:
2705
2706     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2707     open(FH, $filename) or die "Can't open $filename: $!";
2708
2709 Use 3-argument form to open a file with arbitrary weird characters in it,
2710
2711     open(FOO, '<', $file);
2712
2713 otherwise it's necessary to protect any leading and trailing whitespace:
2714
2715     $file =~ s#^(\s)#./$1#;
2716     open(FOO, "< $file\0");
2717
2718 (this may not work on some bizzare filesystems).  One should
2719 conscientiously choose between the the I<magic> and 3-arguments form
2720 of open():
2721
2722     open IN, $ARGV[0];
2723
2724 will allow the user to specify an argument of the form C<"rsh cat file |">,
2725 but will not work on a filename which happens to have a trailing space, while
2726
2727     open IN, '<', $ARGV[0];
2728
2729 will have exactly the opposite restrictions.
2730
2731 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2732 should use the C<sysopen> function, which involves no such magic (but
2733 may use subtly different filemodes than Perl open(), which is mapped
2734 to C fopen()).  This is
2735 another way to protect your filenames from interpretation.  For example:
2736
2737     use IO::Handle;
2738     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2739         or die "sysopen $path: $!";
2740     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2741     print HANDLE "stuff $$\n");
2742     seek(HANDLE, 0, 0);
2743     print "File contains: ", <HANDLE>;
2744
2745 Using the constructor from the C<IO::Handle> package (or one of its
2746 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2747 filehandles that have the scope of whatever variables hold references to
2748 them, and automatically close whenever and however you leave that scope:
2749
2750     use IO::File;
2751     #...
2752     sub read_myfile_munged {
2753         my $ALL = shift;
2754         my $handle = new IO::File;
2755         open($handle, "myfile") or die "myfile: $!";
2756         $first = <$handle>
2757             or return ();     # Automatically closed here.
2758         mung $first or die "mung failed";       # Or here.
2759         return $first, <$handle> if $ALL;       # Or here.
2760         $first;                                 # Or here.
2761     }
2762
2763 See L</seek> for some details about mixing reading and writing.
2764
2765 =item opendir DIRHANDLE,EXPR
2766
2767 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
2768 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
2769 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2770
2771 =item ord EXPR
2772
2773 =item ord
2774
2775 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2776 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2777 See L<utf8> for more about Unicode.
2778
2779 =item our EXPR
2780
2781 An C<our> declares the listed variables to be valid globals within
2782 the enclosing block, file, or C<eval>.  That is, it has the same
2783 scoping rules as a "my" declaration, but does not create a local
2784 variable.  If more than one value is listed, the list must be placed
2785 in parentheses.  The C<our> declaration has no semantic effect unless
2786 "use strict vars" is in effect, in which case it lets you use the
2787 declared global variable without qualifying it with a package name.
2788 (But only within the lexical scope of the C<our> declaration.  In this
2789 it differs from "use vars", which is package scoped.)
2790
2791 An C<our> declaration declares a global variable that will be visible
2792 across its entire lexical scope, even across package boundaries.  The
2793 package in which the variable is entered is determined at the point
2794 of the declaration, not at the point of use.  This means the following
2795 behavior holds:
2796
2797     package Foo;
2798     our $bar;           # declares $Foo::bar for rest of lexical scope
2799     $bar = 20;
2800
2801     package Bar;
2802     print $bar;         # prints 20
2803
2804 Multiple C<our> declarations in the same lexical scope are allowed
2805 if they are in different packages.  If they happened to be in the same
2806 package, Perl will emit warnings if you have asked for them.
2807
2808     use warnings;
2809     package Foo;
2810     our $bar;           # declares $Foo::bar for rest of lexical scope
2811     $bar = 20;
2812
2813     package Bar;
2814     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
2815     print $bar;         # prints 30
2816
2817     our $bar;           # emits warning
2818
2819 =item pack TEMPLATE,LIST
2820
2821 Takes a LIST of values and converts it into a string using the rules
2822 given by the TEMPLATE.  The resulting string is the concatenation of
2823 the converted values.  Typically, each converted value looks
2824 like its machine-level representation.  For example, on 32-bit machines
2825 a converted integer may be represented by a sequence of 4 bytes.
2826
2827 The TEMPLATE is a
2828 sequence of characters that give the order and type of values, as
2829 follows:
2830
2831     a   A string with arbitrary binary data, will be null padded.
2832     A   An ascii string, will be space padded.
2833     Z   A null terminated (asciz) string, will be null padded.
2834
2835     b   A bit string (ascending bit order inside each byte, like vec()).
2836     B   A bit string (descending bit order inside each byte).
2837     h   A hex string (low nybble first).
2838     H   A hex string (high nybble first).
2839
2840     c   A signed char value.
2841     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2842
2843     s   A signed short value.
2844     S   An unsigned short value.
2845           (This 'short' is _exactly_ 16 bits, which may differ from
2846            what a local C compiler calls 'short'.  If you want
2847            native-length shorts, use the '!' suffix.)
2848
2849     i   A signed integer value.
2850     I   An unsigned integer value.
2851           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2852            size depends on what a local C compiler calls 'int',
2853            and may even be larger than the 'long' described in
2854            the next item.)
2855
2856     l   A signed long value.
2857     L   An unsigned long value.
2858           (This 'long' is _exactly_ 32 bits, which may differ from
2859            what a local C compiler calls 'long'.  If you want
2860            native-length longs, use the '!' suffix.)
2861
2862     n   An unsigned short in "network" (big-endian) order.
2863     N   An unsigned long in "network" (big-endian) order.
2864     v   An unsigned short in "VAX" (little-endian) order.
2865     V   An unsigned long in "VAX" (little-endian) order.
2866           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2867            _exactly_ 32 bits, respectively.)
2868
2869     q   A signed quad (64-bit) value.
2870     Q   An unsigned quad value.
2871           (Quads are available only if your system supports 64-bit
2872            integer values _and_ if Perl has been compiled to support those.
2873            Causes a fatal error otherwise.)
2874
2875     f   A single-precision float in the native format.
2876     d   A double-precision float in the native format.
2877
2878     p   A pointer to a null-terminated string.
2879     P   A pointer to a structure (fixed-length string).
2880
2881     u   A uuencoded string.
2882     U   A Unicode character number.  Encodes to UTF-8 internally.
2883         Works even if C<use utf8> is not in effect.
2884
2885     w   A BER compressed integer.  Its bytes represent an unsigned
2886         integer in base 128, most significant digit first, with as
2887         few digits as possible.  Bit eight (the high bit) is set
2888         on each byte except the last.
2889
2890     x   A null byte.
2891     X   Back up a byte.
2892     @   Null fill to absolute position.
2893
2894 The following rules apply:
2895
2896 =over 8
2897
2898 =item *
2899
2900 Each letter may optionally be followed by a number giving a repeat
2901 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
2902 C<H>, and C<P> the pack function will gobble up that many values from
2903 the LIST.  A C<*> for the repeat count means to use however many items are
2904 left, except for C<@>, C<x>, C<X>, where it is equivalent
2905 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
2906 same).
2907
2908 When used with C<Z>, C<*> results in the addition of a trailing null
2909 byte (so the packed result will be one longer than the byte C<length>
2910 of the item).
2911
2912 The repeat count for C<u> is interpreted as the maximal number of bytes
2913 to encode per line of output, with 0 and 1 replaced by 45.
2914
2915 =item *
2916
2917 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
2918 string of length count, padding with nulls or spaces as necessary.  When
2919 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
2920 after the first null, and C<a> returns data verbatim.  When packing,
2921 C<a>, and C<Z> are equivalent.
2922
2923 If the value-to-pack is too long, it is truncated.  If too long and an
2924 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
2925 by a null byte.  Thus C<Z> always packs a trailing null byte under
2926 all circumstances.
2927
2928 =item *
2929
2930 Likewise, the C<b> and C<B> fields pack a string that many bits long.
2931 Each byte of the input field of pack() generates 1 bit of the result.
2932 Each result bit is based on the least-significant bit of the corresponding
2933 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
2934 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
2935
2936 Starting from the beginning of the input string of pack(), each 8-tuple
2937 of bytes is converted to 1 byte of output.  With format C<b>
2938 the first byte of the 8-tuple determines the least-significant bit of a
2939 byte, and with format C<B> it determines the most-significant bit of
2940 a byte.
2941
2942 If the length of the input string is not exactly divisible by 8, the
2943 remainder is packed as if the input string were padded by null bytes
2944 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
2945
2946 If the input string of pack() is longer than needed, extra bytes are ignored.
2947 A C<*> for the repeat count of pack() means to use all the bytes of
2948 the input field.  On unpack()ing the bits are converted to a string
2949 of C<"0">s and C<"1">s.
2950
2951 =item *
2952
2953 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
2954 representable as hexadecimal digits, 0-9a-f) long.
2955
2956 Each byte of the input field of pack() generates 4 bits of the result.
2957 For non-alphabetical bytes the result is based on the 4 least-significant
2958 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
2959 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
2960 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
2961 is compatible with the usual hexadecimal digits, so that C<"a"> and
2962 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
2963 C<"g".."z"> and C<"G".."Z"> is not well-defined.
2964
2965 Starting from the beginning of the input string of pack(), each pair
2966 of bytes is converted to 1 byte of output.  With format C<h> the
2967 first byte of the pair determines the least-significant nybble of the
2968 output byte, and with format C<H> it determines the most-significant
2969 nybble.
2970
2971 If the length of the input string is not even, it behaves as if padded
2972 by a null byte at the end.  Similarly, during unpack()ing the "extra"
2973 nybbles are ignored.
2974
2975 If the input string of pack() is longer than needed, extra bytes are ignored.
2976 A C<*> for the repeat count of pack() means to use all the bytes of
2977 the input field.  On unpack()ing the bits are converted to a string
2978 of hexadecimal digits.
2979
2980 =item *
2981
2982 The C<p> type packs a pointer to a null-terminated string.  You are
2983 responsible for ensuring the string is not a temporary value (which can
2984 potentially get deallocated before you get around to using the packed result).
2985 The C<P> type packs a pointer to a structure of the size indicated by the
2986 length.  A NULL pointer is created if the corresponding value for C<p> or
2987 C<P> is C<undef>, similarly for unpack().
2988
2989 =item *
2990
2991 The C</> template character allows packing and unpacking of strings where
2992 the packed structure contains a byte count followed by the string itself.
2993 You write I<length-item>C</>I<string-item>.
2994
2995 The I<length-item> can be any C<pack> template letter,
2996 and describes how the length value is packed.
2997 The ones likely to be of most use are integer-packing ones like
2998 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
2999 and C<N> (for Sun XDR).
3000
3001 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3002 For C<unpack> the length of the string is obtained from the I<length-item>,
3003 but if you put in the '*' it will be ignored.
3004
3005     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3006     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3007     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3008
3009 The I<length-item> is not returned explicitly from C<unpack>.
3010
3011 Adding a count to the I<length-item> letter is unlikely to do anything
3012 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3013 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3014 which Perl does not regard as legal in numeric strings.
3015
3016 =item *
3017
3018 The integer types C<s>, C<S>, C<l>, and C<L> may be
3019 immediately followed by a C<!> suffix to signify native shorts or
3020 longs--as you can see from above for example a bare C<l> does mean
3021 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3022 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3023 see whether using C<!> makes any difference by
3024
3025         print length(pack("s")), " ", length(pack("s!")), "\n";
3026         print length(pack("l")), " ", length(pack("l!")), "\n";
3027
3028 C<i!> and C<I!> also work but only because of completeness;
3029 they are identical to C<i> and C<I>.
3030
3031 The actual sizes (in bytes) of native shorts, ints, longs, and long
3032 longs on the platform where Perl was built are also available via
3033 L<Config>:
3034
3035        use Config;
3036        print $Config{shortsize},    "\n";
3037        print $Config{intsize},      "\n";
3038        print $Config{longsize},     "\n";
3039        print $Config{longlongsize}, "\n";
3040
3041 (The C<$Config{longlongsize}> will be undefine if your system does
3042 not support long longs.) 
3043
3044 =item *
3045
3046 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3047 are inherently non-portable between processors and operating systems
3048 because they obey the native byteorder and endianness.  For example a
3049 4-byte integer 0x12345678 (305419896 decimal) be ordered natively
3050 (arranged in and handled by the CPU registers) into bytes as
3051  
3052         0x12 0x34 0x56 0x78     # little-endian
3053         0x78 0x56 0x34 0x12     # big-endian
3054  
3055 Basically, the Intel, Alpha, and VAX CPUs are little-endian, while
3056 everybody else, for example Motorola m68k/88k, PPC, Sparc, HP PA,
3057 Power, and Cray are big-endian.  MIPS can be either: Digital used it
3058 in little-endian mode; SGI uses it in big-endian mode.
3059
3060 The names `big-endian' and `little-endian' are comic references to
3061 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3062 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3063 the egg-eating habits of the Lilliputians.
3064  
3065 Some systems may have even weirder byte orders such as
3066  
3067         0x56 0x78 0x12 0x34
3068         0x34 0x12 0x78 0x56
3069  
3070 You can see your system's preference with
3071
3072         print join(" ", map { sprintf "%#02x", $_ }
3073                             unpack("C*",pack("L",0x12345678))), "\n";
3074
3075 The byteorder on the platform where Perl was built is also available
3076 via L<Config>:
3077
3078         use Config;
3079         print $Config{byteorder}, "\n";
3080
3081 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3082 and C<'87654321'> are big-endian.
3083
3084 If you want portable packed integers use the formats C<n>, C<N>,
3085 C<v>, and C<V>, their byte endianness and size is known.
3086 See also L<perlport>.
3087
3088 =item *
3089
3090 Real numbers (floats and doubles) are in the native machine format only;
3091 due to the multiplicity of floating formats around, and the lack of a
3092 standard "network" representation, no facility for interchange has been
3093 made.  This means that packed floating point data written on one machine
3094 may not be readable on another - even if both use IEEE floating point
3095 arithmetic (as the endian-ness of the memory representation is not part
3096 of the IEEE spec).  See also L<perlport>.
3097
3098 Note that Perl uses doubles internally for all numeric calculation, and
3099 converting from double into float and thence back to double again will
3100 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3101 equal $foo).
3102
3103 =item *
3104
3105 You must yourself do any alignment or padding by inserting for example
3106 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3107 could know where the bytes are going to or coming from.  Therefore
3108 C<pack> (and C<unpack>) handle their output and input as flat
3109 sequences of bytes.
3110
3111 =item *
3112
3113 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3114
3115 =item *
3116
3117 If TEMPLATE requires more arguments to pack() than actually given, pack()
3118 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3119 to pack() than actually given, extra arguments are ignored.
3120
3121 =back
3122
3123 Examples:
3124
3125     $foo = pack("CCCC",65,66,67,68);
3126     # foo eq "ABCD"
3127     $foo = pack("C4",65,66,67,68);
3128     # same thing
3129     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3130     # same thing with Unicode circled letters
3131
3132     $foo = pack("ccxxcc",65,66,67,68);
3133     # foo eq "AB\0\0CD"
3134
3135     # note: the above examples featuring "C" and "c" are true
3136     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3137     # and UTF-8.  In EBCDIC the first example would be
3138     # $foo = pack("CCCC",193,194,195,196);
3139
3140     $foo = pack("s2",1,2);
3141     # "\1\0\2\0" on little-endian
3142     # "\0\1\0\2" on big-endian
3143
3144     $foo = pack("a4","abcd","x","y","z");
3145     # "abcd"
3146
3147     $foo = pack("aaaa","abcd","x","y","z");
3148     # "axyz"
3149
3150     $foo = pack("a14","abcdefg");
3151     # "abcdefg\0\0\0\0\0\0\0"
3152
3153     $foo = pack("i9pl", gmtime);
3154     # a real struct tm (on my system anyway)
3155
3156     $utmp_template = "Z8 Z8 Z16 L";
3157     $utmp = pack($utmp_template, @utmp1);
3158     # a struct utmp (BSDish)
3159
3160     @utmp2 = unpack($utmp_template, $utmp);
3161     # "@utmp1" eq "@utmp2"
3162
3163     sub bintodec {
3164         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3165     }
3166
3167     $foo = pack('sx2l', 12, 34);
3168     # short 12, two zero bytes padding, long 34
3169     $bar = pack('s@4l', 12, 34);
3170     # short 12, zero fill to position 4, long 34
3171     # $foo eq $bar
3172
3173 The same template may generally also be used in unpack().
3174
3175 =item package 
3176
3177 =item package NAMESPACE
3178
3179 Declares the compilation unit as being in the given namespace.  The scope
3180 of the package declaration is from the declaration itself through the end
3181 of the enclosing block, file, or eval (the same as the C<my> operator).
3182 All further unqualified dynamic identifiers will be in this namespace.
3183 A package statement affects only dynamic variables--including those
3184 you've used C<local> on--but I<not> lexical variables, which are created
3185 with C<my>.  Typically it would be the first declaration in a file to
3186 be included by the C<require> or C<use> operator.  You can switch into a
3187 package in more than one place; it merely influences which symbol table
3188 is used by the compiler for the rest of that block.  You can refer to
3189 variables and filehandles in other packages by prefixing the identifier
3190 with the package name and a double colon:  C<$Package::Variable>.
3191 If the package name is null, the C<main> package as assumed.  That is,
3192 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3193 still seen in older code).
3194
3195 If NAMESPACE is omitted, then there is no current package, and all
3196 identifiers must be fully qualified or lexicals.  This is stricter
3197 than C<use strict>, since it also extends to function names.
3198
3199 See L<perlmod/"Packages"> for more information about packages, modules,
3200 and classes.  See L<perlsub> for other scoping issues.
3201
3202 =item pipe READHANDLE,WRITEHANDLE
3203
3204 Opens a pair of connected pipes like the corresponding system call.
3205 Note that if you set up a loop of piped processes, deadlock can occur
3206 unless you are very careful.  In addition, note that Perl's pipes use
3207 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3208 after each command, depending on the application.
3209
3210 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3211 for examples of such things.
3212
3213 On systems that support a close-on-exec flag on files, the flag will be set
3214 for the newly opened file descriptors as determined by the value of $^F.
3215 See L<perlvar/$^F>.
3216
3217 =item pop ARRAY
3218
3219 =item pop
3220
3221 Pops and returns the last value of the array, shortening the array by
3222 one element.  Has an effect similar to
3223
3224     $ARRAY[$#ARRAY--]
3225
3226 If there are no elements in the array, returns the undefined value
3227 (although this may happen at other times as well).  If ARRAY is
3228 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3229 array in subroutines, just like C<shift>.
3230
3231 =item pos SCALAR
3232
3233 =item pos
3234
3235 Returns the offset of where the last C<m//g> search left off for the variable
3236 is in question (C<$_> is used when the variable is not specified).  May be
3237 modified to change that offset.  Such modification will also influence
3238 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3239 L<perlop>.
3240
3241 =item print FILEHANDLE LIST
3242
3243 =item print LIST
3244
3245 =item print
3246
3247 Prints a string or a list of strings.  Returns true if successful.
3248 FILEHANDLE may be a scalar variable name, in which case the variable
3249 contains the name of or a reference to the filehandle, thus introducing
3250 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3251 the next token is a term, it may be misinterpreted as an operator
3252 unless you interpose a C<+> or put parentheses around the arguments.)
3253 If FILEHANDLE is omitted, prints by default to standard output (or
3254 to the last selected output channel--see L</select>).  If LIST is
3255 also omitted, prints C<$_> to the currently selected output channel.
3256 To set the default output channel to something other than STDOUT
3257 use the select operation.  The current value of C<$,> (if any) is
3258 printed between each LIST item.  The current value of C<$\> (if
3259 any) is printed after the entire LIST has been printed.  Because
3260 print takes a LIST, anything in the LIST is evaluated in list
3261 context, and any subroutine that you call will have one or more of
3262 its expressions evaluated in list context.  Also be careful not to
3263 follow the print keyword with a left parenthesis unless you want
3264 the corresponding right parenthesis to terminate the arguments to
3265 the print--interpose a C<+> or put parentheses around all the
3266 arguments.
3267
3268 Note that if you're storing FILEHANDLES in an array or other expression,
3269 you will have to use a block returning its value instead:
3270
3271     print { $files[$i] } "stuff\n";
3272     print { $OK ? STDOUT : STDERR } "stuff\n";
3273
3274 =item printf FILEHANDLE FORMAT, LIST
3275
3276 =item printf FORMAT, LIST
3277
3278 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3279 (the output record separator) is not appended.  The first argument
3280 of the list will be interpreted as the C<printf> format.  If C<use locale> is
3281 in effect, the character used for the decimal point in formatted real numbers
3282 is affected by the LC_NUMERIC locale.  See L<perllocale>.
3283
3284 Don't fall into the trap of using a C<printf> when a simple
3285 C<print> would do.  The C<print> is more efficient and less
3286 error prone.
3287
3288 =item prototype FUNCTION
3289
3290 Returns the prototype of a function as a string (or C<undef> if the
3291 function has no prototype).  FUNCTION is a reference to, or the name of,
3292 the function whose prototype you want to retrieve.
3293
3294 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3295 name for Perl builtin.  If the builtin is not I<overridable> (such as
3296 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3297 C<system>) returns C<undef> because the builtin does not really behave
3298 like a Perl function.  Otherwise, the string describing the equivalent
3299 prototype is returned.
3300
3301 =item push ARRAY,LIST
3302
3303 Treats ARRAY as a stack, and pushes the values of LIST
3304 onto the end of ARRAY.  The length of ARRAY increases by the length of
3305 LIST.  Has the same effect as
3306
3307     for $value (LIST) {
3308         $ARRAY[++$#ARRAY] = $value;
3309     }
3310
3311 but is more efficient.  Returns the new number of elements in the array.
3312
3313 =item q/STRING/
3314
3315 =item qq/STRING/
3316
3317 =item qr/STRING/
3318
3319 =item qx/STRING/
3320
3321 =item qw/STRING/
3322
3323 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3324
3325 =item quotemeta EXPR
3326
3327 =item quotemeta
3328
3329 Returns the value of EXPR with all non-alphanumeric
3330 characters backslashed.  (That is, all characters not matching
3331 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3332 returned string, regardless of any locale settings.)
3333 This is the internal function implementing
3334 the C<\Q> escape in double-quoted strings.
3335
3336 If EXPR is omitted, uses C<$_>.
3337
3338 =item rand EXPR
3339
3340 =item rand
3341
3342 Returns a random fractional number greater than or equal to C<0> and less
3343 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3344 omitted, the value C<1> is used.  Automatically calls C<srand> unless
3345 C<srand> has already been called.  See also C<srand>.
3346
3347 (Note: If your rand function consistently returns numbers that are too
3348 large or too small, then your version of Perl was probably compiled
3349 with the wrong number of RANDBITS.)
3350
3351 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3352
3353 =item read FILEHANDLE,SCALAR,LENGTH
3354
3355 Attempts to read LENGTH bytes of data into variable SCALAR from the
3356 specified FILEHANDLE.  Returns the number of bytes actually read,
3357 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
3358 or shrunk to the length actually read.  An OFFSET may be specified to
3359 place the read data at some other place than the beginning of the
3360 string.  This call is actually implemented in terms of stdio's fread(3)
3361 call.  To get a true read(2) system call, see C<sysread>.
3362
3363 =item readdir DIRHANDLE
3364
3365 Returns the next directory entry for a directory opened by C<opendir>.
3366 If used in list context, returns all the rest of the entries in the
3367 directory.  If there are no more entries, returns an undefined value in
3368 scalar context or a null list in list context.
3369
3370 If you're planning to filetest the return values out of a C<readdir>, you'd
3371 better prepend the directory in question.  Otherwise, because we didn't
3372 C<chdir> there, it would have been testing the wrong file.
3373
3374     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3375     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3376     closedir DIR;
3377
3378 =item readline EXPR
3379
3380 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3381 context, each call reads and returns the next line, until end-of-file is
3382 reached, whereupon the subsequent call returns undef.  In list context,
3383 reads until end-of-file is reached and returns a list of lines.  Note that
3384 the notion of "line" used here is however you may have defined it
3385 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3386
3387 When C<$/> is set to C<undef>, when readline() is in scalar
3388 context (i.e. file slurp mode), and when an empty file is read, it
3389 returns C<''> the first time, followed by C<undef> subsequently.
3390
3391 This is the internal function implementing the C<E<lt>EXPRE<gt>>
3392 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
3393 operator is discussed in more detail in L<perlop/"I/O Operators">.
3394
3395     $line = <STDIN>;
3396     $line = readline(*STDIN);           # same thing
3397
3398 =item readlink EXPR
3399
3400 =item readlink
3401
3402 Returns the value of a symbolic link, if symbolic links are
3403 implemented.  If not, gives a fatal error.  If there is some system
3404 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3405 omitted, uses C<$_>.
3406
3407 =item readpipe EXPR
3408
3409 EXPR is executed as a system command.
3410 The collected standard output of the command is returned.
3411 In scalar context, it comes back as a single (potentially
3412 multi-line) string.  In list context, returns a list of lines
3413 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3414 This is the internal function implementing the C<qx/EXPR/>
3415 operator, but you can use it directly.  The C<qx/EXPR/>
3416 operator is discussed in more detail in L<perlop/"I/O Operators">.
3417
3418 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3419
3420 Receives a message on a socket.  Attempts to receive LENGTH bytes of
3421 data into variable SCALAR from the specified SOCKET filehandle.  SCALAR
3422 will be grown or shrunk to the length actually read.  Takes the same
3423 flags as the system call of the same name.  Returns the address of the
3424 sender if SOCKET's protocol supports this; returns an empty string
3425 otherwise.  If there's an error, returns the undefined value.  This call
3426 is actually implemented in terms of recvfrom(2) system call.  See
3427 L<perlipc/"UDP: Message Passing"> for examples.
3428
3429 =item redo LABEL
3430
3431 =item redo
3432
3433 The C<redo> command restarts the loop block without evaluating the
3434 conditional again.  The C<continue> block, if any, is not executed.  If
3435 the LABEL is omitted, the command refers to the innermost enclosing
3436 loop.  This command is normally used by programs that want to lie to
3437 themselves about what was just input:
3438
3439     # a simpleminded Pascal comment stripper
3440     # (warning: assumes no { or } in strings)
3441     LINE: while (<STDIN>) {
3442         while (s|({.*}.*){.*}|$1 |) {}
3443         s|{.*}| |;
3444         if (s|{.*| |) {
3445             $front = $_;
3446             while (<STDIN>) {
3447                 if (/}/) {      # end of comment?
3448                     s|^|$front\{|;
3449                     redo LINE;
3450                 }
3451             }
3452         }
3453         print;
3454     }
3455
3456 C<redo> cannot be used to retry a block which returns a value such as
3457 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3458 a grep() or map() operation.
3459
3460 Note that a block by itself is semantically identical to a loop
3461 that executes once.  Thus C<redo> inside such a block will effectively
3462 turn it into a looping construct.
3463
3464 See also L</continue> for an illustration of how C<last>, C<next>, and
3465 C<redo> work.
3466
3467 =item ref EXPR
3468
3469 =item ref
3470
3471 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3472 is not specified, C<$_> will be used.  The value returned depends on the
3473 type of thing the reference is a reference to.
3474 Builtin types include:
3475
3476     SCALAR
3477     ARRAY
3478     HASH
3479     CODE
3480     REF
3481     GLOB
3482     LVALUE
3483
3484 If the referenced object has been blessed into a package, then that package
3485 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3486
3487     if (ref($r) eq "HASH") {
3488         print "r is a reference to a hash.\n";
3489     }
3490     unless (ref($r)) {
3491         print "r is not a reference at all.\n";
3492     }
3493     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3494         print "r is a reference to something that isa hash.\n";
3495     } 
3496
3497 See also L<perlref>.
3498
3499 =item rename OLDNAME,NEWNAME
3500
3501 Changes the name of a file; an existing file NEWNAME will be
3502 clobbered.  Returns true for success, false otherwise.
3503
3504 Behavior of this function varies wildly depending on your system
3505 implementation.  For example, it will usually not work across file system
3506 boundaries, even though the system I<mv> command sometimes compensates
3507 for this.  Other restrictions include whether it works on directories,
3508 open files, or pre-existing files.  Check L<perlport> and either the
3509 rename(2) manpage or equivalent system documentation for details.
3510
3511 =item require EXPR
3512
3513 =item require
3514
3515 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
3516 supplied.  If EXPR is numeric, demands that the current version of Perl
3517 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
3518
3519 Otherwise, demands that a library file be included if it hasn't already
3520 been included.  The file is included via the do-FILE mechanism, which is
3521 essentially just a variety of C<eval>.  Has semantics similar to the following
3522 subroutine:
3523
3524     sub require {
3525         my($filename) = @_;
3526         return 1 if $INC{$filename};
3527         my($realfilename,$result);
3528         ITER: {
3529             foreach $prefix (@INC) {
3530                 $realfilename = "$prefix/$filename";
3531                 if (-f $realfilename) {
3532                     $INC{$filename} = $realfilename;
3533                     $result = do $realfilename;
3534                     last ITER;
3535                 }
3536             }
3537             die "Can't find $filename in \@INC";
3538         }
3539         delete $INC{$filename} if $@ || !$result;
3540         die $@ if $@;
3541         die "$filename did not return true value" unless $result;
3542         return $result;
3543     }
3544
3545 Note that the file will not be included twice under the same specified
3546 name.  The file must return true as the last statement to indicate
3547 successful execution of any initialization code, so it's customary to
3548 end such a file with C<1;> unless you're sure it'll return true
3549 otherwise.  But it's better just to put the C<1;>, in case you add more
3550 statements.
3551
3552 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3553 replaces "F<::>" with "F</>" in the filename for you,
3554 to make it easy to load standard modules.  This form of loading of
3555 modules does not risk altering your namespace.
3556
3557 In other words, if you try this:
3558
3559         require Foo::Bar;    # a splendid bareword 
3560
3561 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3562 directories specified in the C<@INC> array.
3563
3564 But if you try this:
3565
3566         $class = 'Foo::Bar';
3567         require $class;      # $class is not a bareword
3568     #or
3569         require "Foo::Bar";  # not a bareword because of the ""
3570
3571 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3572 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3573
3574         eval "require $class";
3575
3576 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3577
3578 =item reset EXPR
3579
3580 =item reset
3581
3582 Generally used in a C<continue> block at the end of a loop to clear
3583 variables and reset C<??> searches so that they work again.  The
3584 expression is interpreted as a list of single characters (hyphens
3585 allowed for ranges).  All variables and arrays beginning with one of
3586 those letters are reset to their pristine state.  If the expression is
3587 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3588 only variables or searches in the current package.  Always returns
3589 1.  Examples:
3590
3591     reset 'X';          # reset all X variables
3592     reset 'a-z';        # reset lower case variables
3593     reset;              # just reset ?one-time? searches
3594
3595 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3596 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3597 variables--lexical variables are unaffected, but they clean themselves
3598 up on scope exit anyway, so you'll probably want to use them instead.
3599 See L</my>.
3600
3601 =item return EXPR
3602
3603 =item return
3604
3605 Returns from a subroutine, C<eval>, or C<do FILE> with the value 
3606 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3607 context, depending on how the return value will be used, and the context
3608 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3609 is given, returns an empty list in list context, the undefined value in
3610 scalar context, and (of course) nothing at all in a void context.
3611
3612 (Note that in the absence of a explicit C<return>, a subroutine, eval,
3613 or do FILE will automatically return the value of the last expression
3614 evaluated.)
3615
3616 =item reverse LIST
3617
3618 In list context, returns a list value consisting of the elements
3619 of LIST in the opposite order.  In scalar context, concatenates the
3620 elements of LIST and returns a string value with all characters
3621 in the opposite order.
3622
3623     print reverse <>;           # line tac, last line first
3624
3625     undef $/;                   # for efficiency of <>
3626     print scalar reverse <>;    # character tac, last line tsrif
3627
3628 This operator is also handy for inverting a hash, although there are some
3629 caveats.  If a value is duplicated in the original hash, only one of those
3630 can be represented as a key in the inverted hash.  Also, this has to
3631 unwind one hash and build a whole new one, which may take some time
3632 on a large hash, such as from a DBM file.
3633
3634     %by_name = reverse %by_address;     # Invert the hash
3635
3636 =item rewinddir DIRHANDLE
3637
3638 Sets the current position to the beginning of the directory for the
3639 C<readdir> routine on DIRHANDLE.
3640
3641 =item rindex STR,SUBSTR,POSITION
3642
3643 =item rindex STR,SUBSTR
3644
3645 Works just like index() except that it returns the position of the LAST
3646 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3647 last occurrence at or before that position.
3648
3649 =item rmdir FILENAME
3650
3651 =item rmdir
3652
3653 Deletes the directory specified by FILENAME if that directory is empty.  If it
3654 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
3655 FILENAME is omitted, uses C<$_>.
3656
3657 =item s///
3658
3659 The substitution operator.  See L<perlop>.
3660
3661 =item scalar EXPR
3662
3663 Forces EXPR to be interpreted in scalar context and returns the value
3664 of EXPR.
3665
3666     @counts = ( scalar @a, scalar @b, scalar @c );
3667
3668 There is no equivalent operator to force an expression to
3669 be interpolated in list context because in practice, this is never
3670 needed.  If you really wanted to do so, however, you could use
3671 the construction C<@{[ (some expression) ]}>, but usually a simple
3672 C<(some expression)> suffices.
3673
3674 Because C<scalar> is unary operator, if you accidentally use for EXPR a
3675 parenthesized list, this behaves as a scalar comma expression, evaluating
3676 all but the last element in void context and returning the final element
3677 evaluated in scalar context.  This is seldom what you want.
3678
3679 The following single statement:
3680
3681         print uc(scalar(&foo,$bar)),$baz;
3682
3683 is the moral equivalent of these two:
3684
3685         &foo;
3686         print(uc($bar),$baz);
3687
3688 See L<perlop> for more details on unary operators and the comma operator.
3689
3690 =item seek FILEHANDLE,POSITION,WHENCE
3691
3692 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
3693 FILEHANDLE may be an expression whose value gives the name of the
3694 filehandle.  The values for WHENCE are C<0> to set the new position to
3695 POSITION, C<1> to set it to the current position plus POSITION, and
3696 C<2> to set it to EOF plus POSITION (typically negative).  For WHENCE
3697 you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END>
3698 (start of the file, current position, end of the file) from any of the
3699 modules Fcntl, C<IO::Seekable>, or POSIX.  Returns C<1> upon success,
3700 C<0> otherwise.
3701
3702 If you want to position file for C<sysread> or C<syswrite>, don't use
3703 C<seek>--buffering makes its effect on the file's system position
3704 unpredictable and non-portable.  Use C<sysseek> instead.
3705
3706 Due to the rules and rigors of ANSI C, on some systems you have to do a
3707 seek whenever you switch between reading and writing.  Amongst other
3708 things, this may have the effect of calling stdio's clearerr(3).
3709 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
3710
3711     seek(TEST,0,1);
3712
3713 This is also useful for applications emulating C<tail -f>.  Once you hit
3714 EOF on your read, and then sleep for a while, you might have to stick in a
3715 seek() to reset things.  The C<seek> doesn't change the current position,
3716 but it I<does> clear the end-of-file condition on the handle, so that the
3717 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
3718
3719 If that doesn't work (some stdios are particularly cantankerous), then
3720 you may need something more like this:
3721
3722     for (;;) {
3723         for ($curpos = tell(FILE); $_ = <FILE>;
3724              $curpos = tell(FILE)) {
3725             # search for some stuff and put it into files
3726         }
3727         sleep($for_a_while);
3728         seek(FILE, $curpos, 0);
3729     }
3730
3731 =item seekdir DIRHANDLE,POS
3732
3733 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
3734 must be a value returned by C<telldir>.  Has the same caveats about
3735 possible directory compaction as the corresponding system library
3736 routine.
3737
3738 =item select FILEHANDLE
3739
3740 =item select
3741
3742 Returns the currently selected filehandle.  Sets the current default
3743 filehandle for output, if FILEHANDLE is supplied.  This has two
3744 effects: first, a C<write> or a C<print> without a filehandle will
3745 default to this FILEHANDLE.  Second, references to variables related to
3746 output will refer to this output channel.  For example, if you have to
3747 set the top of form format for more than one output channel, you might
3748 do the following:
3749
3750     select(REPORT1);
3751     $^ = 'report1_top';
3752     select(REPORT2);
3753     $^ = 'report2_top';
3754
3755 FILEHANDLE may be an expression whose value gives the name of the
3756 actual filehandle.  Thus:
3757
3758     $oldfh = select(STDERR); $| = 1; select($oldfh);
3759
3760 Some programmers may prefer to think of filehandles as objects with
3761 methods, preferring to write the last example as:
3762
3763     use IO::Handle;
3764     STDERR->autoflush(1);
3765
3766 =item select RBITS,WBITS,EBITS,TIMEOUT
3767
3768 This calls the select(2) system call with the bit masks specified, which
3769 can be constructed using C<fileno> and C<vec>, along these lines:
3770
3771     $rin = $win = $ein = '';
3772     vec($rin,fileno(STDIN),1) = 1;
3773     vec($win,fileno(STDOUT),1) = 1;
3774     $ein = $rin | $win;
3775
3776 If you want to select on many filehandles you might wish to write a
3777 subroutine:
3778
3779     sub fhbits {
3780         my(@fhlist) = split(' ',$_[0]);
3781         my($bits);
3782         for (@fhlist) {
3783             vec($bits,fileno($_),1) = 1;
3784         }
3785         $bits;
3786     }
3787     $rin = fhbits('STDIN TTY SOCK');
3788
3789 The usual idiom is:
3790
3791     ($nfound,$timeleft) =
3792       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3793
3794 or to block until something becomes ready just do this
3795
3796     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3797
3798 Most systems do not bother to return anything useful in $timeleft, so
3799 calling select() in scalar context just returns $nfound.
3800
3801 Any of the bit masks can also be undef.  The timeout, if specified, is
3802 in seconds, which may be fractional.  Note: not all implementations are
3803 capable of returning the$timeleft.  If not, they always return
3804 $timeleft equal to the supplied $timeout.
3805
3806 You can effect a sleep of 250 milliseconds this way:
3807
3808     select(undef, undef, undef, 0.25);
3809
3810 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
3811 or E<lt>FHE<gt>) with C<select>, except as permitted by POSIX, and even
3812 then only on POSIX systems.  You have to use C<sysread> instead.
3813
3814 =item semctl ID,SEMNUM,CMD,ARG
3815
3816 Calls the System V IPC function C<semctl>.  You'll probably have to say
3817
3818     use IPC::SysV;
3819
3820 first to get the correct constant definitions.  If CMD is IPC_STAT or
3821 GETALL, then ARG must be a variable which will hold the returned
3822 semid_ds structure or semaphore value array.  Returns like C<ioctl>: the
3823 undefined value for error, "C<0 but true>" for zero, or the actual return
3824 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3825
3826 =item semget KEY,NSEMS,FLAGS
3827
3828 Calls the System V IPC function semget.  Returns the semaphore id, or
3829 the undefined value if there is an error.  See also C<IPC::SysV> and
3830 C<IPC::SysV::Semaphore> documentation.
3831
3832 =item semop KEY,OPSTRING
3833
3834 Calls the System V IPC function semop to perform semaphore operations
3835 such as signaling and waiting.  OPSTRING must be a packed array of
3836 semop structures.  Each semop structure can be generated with
3837 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3838 operations is implied by the length of OPSTRING.  Returns true if
3839 successful, or false if there is an error.  As an example, the
3840 following code waits on semaphore $semnum of semaphore id $semid:
3841
3842     $semop = pack("sss", $semnum, -1, 0);
3843     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3844
3845 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3846 and C<IPC::SysV::Semaphore> documentation.
3847
3848 =item send SOCKET,MSG,FLAGS,TO
3849
3850 =item send SOCKET,MSG,FLAGS
3851
3852 Sends a message on a socket.  Takes the same flags as the system call
3853 of the same name.  On unconnected sockets you must specify a
3854 destination to send TO, in which case it does a C C<sendto>.  Returns
3855 the number of characters sent, or the undefined value if there is an
3856 error.  The C system call sendmsg(2) is currently unimplemented.
3857 See L<perlipc/"UDP: Message Passing"> for examples.
3858
3859 =item setpgrp PID,PGRP
3860
3861 Sets the current process group for the specified PID, C<0> for the current
3862 process.  Will produce a fatal error if used on a machine that doesn't
3863 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
3864 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
3865 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
3866 C<POSIX::setsid()>.
3867
3868 =item setpriority WHICH,WHO,PRIORITY
3869
3870 Sets the current priority for a process, a process group, or a user.
3871 (See setpriority(2).)  Will produce a fatal error if used on a machine
3872 that doesn't implement setpriority(2).
3873
3874 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3875
3876 Sets the socket option requested.  Returns undefined if there is an
3877 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3878 argument.
3879
3880 =item shift ARRAY
3881
3882 =item shift
3883
3884 Shifts the first value of the array off and returns it, shortening the
3885 array by 1 and moving everything down.  If there are no elements in the
3886 array, returns the undefined value.  If ARRAY is omitted, shifts the
3887 C<@_> array within the lexical scope of subroutines and formats, and the
3888 C<@ARGV> array at file scopes or within the lexical scopes established by
3889 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<STOP {}>, and C<END {}>
3890 constructs.
3891
3892 See also C<unshift>, C<push>, and C<pop>.  C<Shift()> and C<unshift> do the
3893 same thing to the left end of an array that C<pop> and C<push> do to the
3894 right end.
3895
3896 =item shmctl ID,CMD,ARG
3897
3898 Calls the System V IPC function shmctl.  You'll probably have to say
3899
3900     use IPC::SysV;
3901
3902 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3903 then ARG must be a variable which will hold the returned C<shmid_ds>
3904 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3905 true" for zero, or the actual return value otherwise.
3906 See also C<IPC::SysV> documentation.
3907
3908 =item shmget KEY,SIZE,FLAGS
3909
3910 Calls the System V IPC function shmget.  Returns the shared memory
3911 segment id, or the undefined value if there is an error.
3912 See also C<IPC::SysV> documentation.
3913
3914 =item shmread ID,VAR,POS,SIZE
3915
3916 =item shmwrite ID,STRING,POS,SIZE
3917
3918 Reads or writes the System V shared memory segment ID starting at
3919 position POS for size SIZE by attaching to it, copying in/out, and
3920 detaching from it.  When reading, VAR must be a variable that will
3921 hold the data read.  When writing, if STRING is too long, only SIZE
3922 bytes are used; if STRING is too short, nulls are written to fill out
3923 SIZE bytes.  Return true if successful, or false if there is an error.
3924 See also C<IPC::SysV> documentation and the C<IPC::Shareable> module
3925 from CPAN.
3926
3927 =item shutdown SOCKET,HOW
3928
3929 Shuts down a socket connection in the manner indicated by HOW, which
3930 has the same interpretation as in the system call of the same name.
3931
3932     shutdown(SOCKET, 0);    # I/we have stopped reading data
3933     shutdown(SOCKET, 1);    # I/we have stopped writing data
3934     shutdown(SOCKET, 2);    # I/we have stopped using this socket
3935
3936 This is useful with sockets when you want to tell the other
3937 side you're done writing but not done reading, or vice versa.
3938 It's also a more insistent form of close because it also 
3939 disables the file descriptor in any forked copies in other
3940 processes.
3941
3942 =item sin EXPR
3943
3944 =item sin
3945
3946 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3947 returns sine of C<$_>.
3948
3949 For the inverse sine operation, you may use the C<POSIX::asin>
3950 function, or use this relation:
3951
3952     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3953
3954 =item sleep EXPR
3955
3956 =item sleep
3957
3958 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3959 May be interrupted if the process receives a signal such as C<SIGALRM>.
3960 Returns the number of seconds actually slept.  You probably cannot
3961 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
3962 using C<alarm>.
3963
3964 On some older systems, it may sleep up to a full second less than what
3965 you requested, depending on how it counts seconds.  Most modern systems
3966 always sleep the full amount.  They may appear to sleep longer than that,
3967 however, because your process might not be scheduled right away in a
3968 busy multitasking system.
3969
3970 For delays of finer granularity than one second, you may use Perl's
3971 C<syscall> interface to access setitimer(2) if your system supports
3972 it, or else see L</select> above.  The Time::HiRes module from CPAN
3973 may also help.
3974
3975 See also the POSIX module's C<sigpause> function.
3976
3977 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3978
3979 Opens a socket of the specified kind and attaches it to filehandle
3980 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
3981 the system call of the same name.  You should C<use Socket> first
3982 to get the proper definitions imported.  See the examples in
3983 L<perlipc/"Sockets: Client/Server Communication">.
3984
3985 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
3986
3987 Creates an unnamed pair of sockets in the specified domain, of the
3988 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
3989 for the system call of the same name.  If unimplemented, yields a fatal
3990 error.  Returns true if successful.
3991
3992 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
3993 to C<pipe(Rdr, Wtr)> is essentially:
3994
3995     use Socket;
3996     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
3997     shutdown(Rdr, 1);        # no more writing for reader
3998     shutdown(Wtr, 0);        # no more reading for writer
3999
4000 See L<perlipc> for an example of socketpair use.
4001
4002 =item sort SUBNAME LIST
4003
4004 =item sort BLOCK LIST
4005
4006 =item sort LIST
4007
4008 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4009 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4010 specified, it gives the name of a subroutine that returns an integer
4011 less than, equal to, or greater than C<0>, depending on how the elements
4012 of the list are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
4013 operators are extremely useful in such routines.)  SUBNAME may be a
4014 scalar variable name (unsubscripted), in which case the value provides
4015 the name of (or a reference to) the actual subroutine to use.  In place
4016 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4017 subroutine.
4018
4019 If the subroutine's prototype is C<($$)>, the elements to be compared
4020 are passed by reference in C<@_>, as for a normal subroutine.  If not,
4021 the normal calling code for subroutines is bypassed in the interests of
4022 efficiency, and the elements to be compared are passed into the subroutine
4023 as the package global variables $a and $b (see example below).  Note that
4024 in the latter case, it is usually counter-productive to declare $a and
4025 $b as lexicals.
4026
4027 In either case, the subroutine may not be recursive.  The values to be
4028 compared are always passed by reference, so don't modify them.
4029
4030 You also cannot exit out of the sort block or subroutine using any of the
4031 loop control operators described in L<perlsyn> or with C<goto>.
4032
4033 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4034 current collation locale.  See L<perllocale>.
4035
4036 Examples:
4037
4038     # sort lexically
4039     @articles = sort @files;
4040
4041     # same thing, but with explicit sort routine
4042     @articles = sort {$a cmp $b} @files;
4043
4044     # now case-insensitively
4045     @articles = sort {uc($a) cmp uc($b)} @files;
4046
4047     # same thing in reversed order
4048     @articles = sort {$b cmp $a} @files;
4049
4050     # sort numerically ascending
4051     @articles = sort {$a <=> $b} @files;
4052
4053     # sort numerically descending
4054     @articles = sort {$b <=> $a} @files;
4055
4056     # this sorts the %age hash by value instead of key
4057     # using an in-line function
4058     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4059
4060     # sort using explicit subroutine name
4061     sub byage {
4062         $age{$a} <=> $age{$b};  # presuming numeric
4063     }
4064     @sortedclass = sort byage @class;
4065
4066     sub backwards { $b cmp $a }
4067     @harry  = qw(dog cat x Cain Abel);
4068     @george = qw(gone chased yz Punished Axed);
4069     print sort @harry;
4070             # prints AbelCaincatdogx
4071     print sort backwards @harry;
4072             # prints xdogcatCainAbel
4073     print sort @george, 'to', @harry;
4074             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4075
4076     # inefficiently sort by descending numeric compare using
4077     # the first integer after the first = sign, or the
4078     # whole record case-insensitively otherwise
4079
4080     @new = sort {
4081         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4082                             ||
4083                     uc($a)  cmp  uc($b)
4084     } @old;
4085
4086     # same thing, but much more efficiently;
4087     # we'll build auxiliary indices instead
4088     # for speed
4089     @nums = @caps = ();
4090     for (@old) {
4091         push @nums, /=(\d+)/;
4092         push @caps, uc($_);
4093     }
4094
4095     @new = @old[ sort {
4096                         $nums[$b] <=> $nums[$a]
4097                                  ||
4098                         $caps[$a] cmp $caps[$b]
4099                        } 0..$#old
4100                ];
4101
4102     # same thing, but without any temps
4103     @new = map { $_->[0] }
4104            sort { $b->[1] <=> $a->[1]
4105                            ||
4106                   $a->[2] cmp $b->[2]
4107            } map { [$_, /=(\d+)/, uc($_)] } @old;
4108     
4109     # using a prototype allows you to use any comparison subroutine
4110     # as a sort subroutine (including other package's subroutines)
4111     package other;
4112     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4113
4114     package main;
4115     @new = sort other::backwards @old;
4116
4117 If you're using strict, you I<must not> declare $a
4118 and $b as lexicals.  They are package globals.  That means
4119 if you're in the C<main> package, it's
4120
4121     @articles = sort {$main::b <=> $main::a} @files;
4122
4123 or just
4124
4125     @articles = sort {$::b <=> $::a} @files;
4126
4127 but if you're in the C<FooPack> package, it's
4128
4129     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4130
4131 The comparison function is required to behave.  If it returns
4132 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4133 sometimes saying the opposite, for example) the results are not
4134 well-defined.
4135
4136 =item splice ARRAY,OFFSET,LENGTH,LIST
4137
4138 =item splice ARRAY,OFFSET,LENGTH
4139
4140 =item splice ARRAY,OFFSET
4141
4142 Removes the elements designated by OFFSET and LENGTH from an array, and
4143 replaces them with the elements of LIST, if any.  In list context,
4144 returns the elements removed from the array.  In scalar context,
4145 returns the last element removed, or C<undef> if no elements are
4146 removed.  The array grows or shrinks as necessary.
4147 If OFFSET is negative then it starts that far from the end of the array.
4148 If LENGTH is omitted, removes everything from OFFSET onward.
4149 If LENGTH is negative, leave that many elements off the end of the array.
4150 The following equivalences hold (assuming C<$[ == 0>):
4151
4152     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4153     pop(@a)             splice(@a,-1)
4154     shift(@a)           splice(@a,0,1)
4155     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4156     $a[$x] = $y         splice(@a,$x,1,$y)
4157
4158 Example, assuming array lengths are passed before arrays:
4159
4160     sub aeq {   # compare two list values
4161         my(@a) = splice(@_,0,shift);
4162         my(@b) = splice(@_,0,shift);
4163         return 0 unless @a == @b;       # same len?
4164         while (@a) {
4165             return 0 if pop(@a) ne pop(@b);
4166         }
4167         return 1;
4168     }
4169     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4170
4171 =item split /PATTERN/,EXPR,LIMIT
4172
4173 =item split /PATTERN/,EXPR
4174
4175 =item split /PATTERN/
4176
4177 =item split
4178
4179 Splits a string into a list of strings and returns that list.  By default,
4180 empty leading fields are preserved, and empty trailing ones are deleted.
4181
4182 If not in list context, returns the number of fields found and splits into
4183 the C<@_> array.  (In list context, you can force the split into C<@_> by
4184 using C<??> as the pattern delimiters, but it still returns the list
4185 value.)  The use of implicit split to C<@_> is deprecated, however, because
4186 it clobbers your subroutine arguments.
4187
4188 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4189 splits on whitespace (after skipping any leading whitespace).  Anything
4190 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4191 that the delimiter may be longer than one character.)
4192
4193 If LIMIT is specified and positive, splits into no more than that
4194 many fields (though it may split into fewer).  If LIMIT is unspecified
4195 or zero, trailing null fields are stripped (which potential users
4196 of C<pop> would do well to remember).  If LIMIT is negative, it is
4197 treated as if an arbitrarily large LIMIT had been specified.
4198
4199 A pattern matching the null string (not to be confused with
4200 a null pattern C<//>, which is just one member of the set of patterns
4201 matching a null string) will split the value of EXPR into separate
4202 characters at each point it matches that way.  For example:
4203
4204     print join(':', split(/ */, 'hi there'));
4205
4206 produces the output 'h:i:t:h:e:r:e'.
4207
4208 The LIMIT parameter can be used to split a line partially
4209
4210     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4211
4212 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
4213 one larger than the number of variables in the list, to avoid
4214 unnecessary work.  For the list above LIMIT would have been 4 by
4215 default.  In time critical applications it behooves you not to split
4216 into more fields than you really need.
4217
4218 If the PATTERN contains parentheses, additional list elements are
4219 created from each matching substring in the delimiter.
4220
4221     split(/([,-])/, "1-10,20", 3);
4222
4223 produces the list value
4224
4225     (1, '-', 10, ',', 20)
4226
4227 If you had the entire header of a normal Unix email message in $header,
4228 you could split it up into fields and their values this way:
4229
4230     $header =~ s/\n\s+/ /g;  # fix continuation lines
4231     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4232
4233 The pattern C</PATTERN/> may be replaced with an expression to specify
4234 patterns that vary at runtime.  (To do runtime compilation only once,
4235 use C</$variable/o>.)
4236
4237 As a special case, specifying a PATTERN of space (C<' '>) will split on
4238 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
4239 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
4240 will give you as many null initial fields as there are leading spaces.
4241 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
4242 whitespace produces a null first field.  A C<split> with no arguments
4243 really does a C<split(' ', $_)> internally.
4244
4245 Example:
4246
4247     open(PASSWD, '/etc/passwd');
4248     while (<PASSWD>) {
4249         ($login, $passwd, $uid, $gid,
4250          $gcos, $home, $shell) = split(/:/);
4251         #...
4252     }
4253
4254 (Note that $shell above will still have a newline on it.  See L</chop>,
4255 L</chomp>, and L</join>.)
4256
4257 =item sprintf FORMAT, LIST
4258
4259 Returns a string formatted by the usual C<printf> conventions of the
4260 C library function C<sprintf>.  See L<sprintf(3)> or L<printf(3)>
4261 on your system for an explanation of the general principles.
4262
4263 Perl does its own C<sprintf> formatting--it emulates the C
4264 function C<sprintf>, but it doesn't use it (except for floating-point
4265 numbers, and even then only the standard modifiers are allowed).  As a
4266 result, any non-standard extensions in your local C<sprintf> are not
4267 available from Perl.
4268
4269 Perl's C<sprintf> permits the following universally-known conversions:
4270
4271    %%   a percent sign
4272    %c   a character with the given number
4273    %s   a string
4274    %d   a signed integer, in decimal
4275    %u   an unsigned integer, in decimal
4276    %o   an unsigned integer, in octal
4277    %x   an unsigned integer, in hexadecimal
4278    %e   a floating-point number, in scientific notation
4279    %f   a floating-point number, in fixed decimal notation
4280    %g   a floating-point number, in %e or %f notation
4281
4282 In addition, Perl permits the following widely-supported conversions:
4283
4284    %X   like %x, but using upper-case letters
4285    %E   like %e, but using an upper-case "E"
4286    %G   like %g, but with an upper-case "E" (if applicable)
4287    %b   an unsigned integer, in binary
4288    %p   a pointer (outputs the Perl value's address in hexadecimal)
4289    %n   special: *stores* the number of characters output so far
4290         into the next variable in the parameter list 
4291
4292 Finally, for backward (and we do mean "backward") compatibility, Perl
4293 permits these unnecessary but widely-supported conversions:
4294
4295    %i   a synonym for %d
4296    %D   a synonym for %ld
4297    %U   a synonym for %lu
4298    %O   a synonym for %lo
4299    %F   a synonym for %f
4300
4301 Perl permits the following universally-known flags between the C<%>
4302 and the conversion letter:
4303
4304    space   prefix positive number with a space
4305    +       prefix positive number with a plus sign
4306    -       left-justify within the field
4307    0       use zeros, not spaces, to right-justify
4308    #       prefix non-zero octal with "0", non-zero hex with "0x"
4309    number  minimum field width
4310    .number "precision": digits after decimal point for
4311            floating-point, max length for string, minimum length
4312            for integer
4313    l       interpret integer as C type "long" or "unsigned long"
4314    h       interpret integer as C type "short" or "unsigned short"
4315            If no flags, interpret integer as C type "int" or "unsigned"
4316
4317 There is also one Perl-specific flag:
4318
4319    V       interpret integer as Perl's standard integer type
4320
4321 Where a number would appear in the flags, an asterisk (C<*>) may be
4322 used instead, in which case Perl uses the next item in the parameter
4323 list as the given number (that is, as the field width or precision).
4324 If a field width obtained through C<*> is negative, it has the same
4325 effect as the C<-> flag: left-justification.
4326
4327 If C<use locale> is in effect, the character used for the decimal
4328 point in formatted real numbers is affected by the LC_NUMERIC locale.
4329 See L<perllocale>.
4330
4331 If Perl understands "quads" (64-bit integers) (this requires
4332 either that the platform natively supports quads or that Perl
4333 has been specifically compiled to support quads), the characters
4334
4335         d u o x X b i D U O
4336
4337 print quads, and they may optionally be preceded by
4338
4339         ll L q
4340
4341 For example
4342
4343         %lld %16LX %qo
4344
4345 You can find out whether your Perl supports quads via L<Config>:
4346
4347         use Config;
4348         ($Config{use64bits} eq 'define' || $Config{longsize} == 8) &&
4349                 print "quads\n";
4350
4351 If Perl understands "long doubles" (this requires that the platform
4352 supports long doubles), the flags
4353
4354         e f g E F G
4355
4356 may optionally be preceded by
4357
4358         ll L
4359
4360 For example
4361
4362         %llf %Lg
4363
4364 You can find out whether your Perl supports long doubles via L<Config>:
4365
4366         use Config;
4367         $Config{d_longdbl} eq 'define' && print "long doubles\n";
4368
4369 =item sqrt EXPR
4370
4371 =item sqrt
4372
4373 Return the square root of EXPR.  If EXPR is omitted, returns square
4374 root of C<$_>.  Only works on non-negative operands, unless you've
4375 loaded the standard Math::Complex module.
4376
4377     use Math::Complex;
4378     print sqrt(-2);    # prints 1.4142135623731i
4379
4380 =item srand EXPR
4381
4382 =item srand
4383
4384 Sets the random number seed for the C<rand> operator.  If EXPR is
4385 omitted, uses a semi-random value supplied by the kernel (if it supports
4386 the F</dev/urandom> device) or based on the current time and process
4387 ID, among other things.  In versions of Perl prior to 5.004 the default
4388 seed was just the current C<time>.  This isn't a particularly good seed,
4389 so many old programs supply their own seed value (often C<time ^ $$> or
4390 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
4391
4392 In fact, it's usually not necessary to call C<srand> at all, because if
4393 it is not called explicitly, it is called implicitly at the first use of
4394 the C<rand> operator.  However, this was not the case in version of Perl
4395 before 5.004, so if your script will run under older Perl versions, it
4396 should call C<srand>.
4397
4398 Note that you need something much more random than the default seed for
4399 cryptographic purposes.  Checksumming the compressed output of one or more
4400 rapidly changing operating system status programs is the usual method.  For
4401 example:
4402
4403     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
4404
4405 If you're particularly concerned with this, see the C<Math::TrulyRandom>
4406 module in CPAN.
4407
4408 Do I<not> call C<srand> multiple times in your program unless you know
4409 exactly what you're doing and why you're doing it.  The point of the
4410 function is to "seed" the C<rand> function so that C<rand> can produce
4411 a different sequence each time you run your program.  Just do it once at the
4412 top of your program, or you I<won't> get random numbers out of C<rand>!
4413
4414 Frequently called programs (like CGI scripts) that simply use
4415
4416     time ^ $$
4417
4418 for a seed can fall prey to the mathematical property that
4419
4420     a^b == (a+1)^(b+1)
4421
4422 one-third of the time.  So don't do that.
4423
4424 =item stat FILEHANDLE
4425
4426 =item stat EXPR
4427
4428 =item stat
4429
4430 Returns a 13-element list giving the status info for a file, either
4431 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
4432 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
4433 as follows:
4434
4435     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
4436        $atime,$mtime,$ctime,$blksize,$blocks)
4437            = stat($filename);
4438
4439 Not all fields are supported on all filesystem types.  Here are the
4440 meaning of the fields:
4441
4442   0 dev      device number of filesystem
4443   1 ino      inode number
4444   2 mode     file mode  (type and permissions)
4445   3 nlink    number of (hard) links to the file
4446   4 uid      numeric user ID of file's owner
4447   5 gid      numeric group ID of file's owner
4448   6 rdev     the device identifier (special files only)
4449   7 size     total size of file, in bytes
4450   8 atime    last access time in seconds since the epoch
4451   9 mtime    last modify time in seconds since the epoch
4452  10 ctime    inode change time (NOT creation time!) in seconds since the epoch
4453  11 blksize  preferred block size for file system I/O
4454  12 blocks   actual number of blocks allocated
4455
4456 (The epoch was at 00:00 January 1, 1970 GMT.)
4457
4458 If stat is passed the special filehandle consisting of an underline, no
4459 stat is done, but the current contents of the stat structure from the
4460 last stat or filetest are returned.  Example:
4461
4462     if (-x $file && (($d) = stat(_)) && $d < 0) {
4463         print "$file is executable NFS file\n";
4464     }
4465
4466 (This works on machines only for which the device number is negative under NFS.)
4467
4468 Because the mode contains both the file type and its permissions, you
4469 should mask off the file type portion and (s)printf using a C<"%o"> 
4470 if you want to see the real permissions.
4471
4472     $mode = (stat($filename))[2];
4473     printf "Permissions are %04o\n", $mode & 07777;
4474
4475 In scalar context, C<stat> returns a boolean value indicating success
4476 or failure, and, if successful, sets the information associated with
4477 the special filehandle C<_>.
4478
4479 The File::stat module provides a convenient, by-name access mechanism:
4480
4481     use File::stat;
4482     $sb = stat($filename);
4483     printf "File is %s, size is %s, perm %04o, mtime %s\n", 
4484         $filename, $sb->size, $sb->mode & 07777,
4485         scalar localtime $sb->mtime;
4486
4487 =item study SCALAR
4488
4489 =item study
4490
4491 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
4492 doing many pattern matches on the string before it is next modified.
4493 This may or may not save time, depending on the nature and number of
4494 patterns you are searching on, and on the distribution of character
4495 frequencies in the string to be searched--you probably want to compare
4496 run times with and without it to see which runs faster.  Those loops
4497 which scan for many short constant strings (including the constant
4498 parts of more complex patterns) will benefit most.  You may have only
4499 one C<study> active at a time--if you study a different scalar the first
4500 is "unstudied".  (The way C<study> works is this: a linked list of every
4501 character in the string to be searched is made, so we know, for
4502 example, where all the C<'k'> characters are.  From each search string,
4503 the rarest character is selected, based on some static frequency tables
4504 constructed from some C programs and English text.  Only those places
4505 that contain this "rarest" character are examined.)
4506
4507 For example, here is a loop that inserts index producing entries
4508 before any line containing a certain pattern:
4509
4510     while (<>) {
4511         study;
4512         print ".IX foo\n"       if /\bfoo\b/;
4513         print ".IX bar\n"       if /\bbar\b/;
4514         print ".IX blurfl\n"    if /\bblurfl\b/;
4515         # ...
4516         print;
4517     }
4518
4519 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<f>
4520 will be looked at, because C<f> is rarer than C<o>.  In general, this is
4521 a big win except in pathological cases.  The only question is whether
4522 it saves you more time than it took to build the linked list in the
4523 first place.
4524
4525 Note that if you have to look for strings that you don't know till
4526 runtime, you can build an entire loop as a string and C<eval> that to
4527 avoid recompiling all your patterns all the time.  Together with
4528 undefining C<$/> to input entire files as one record, this can be very
4529 fast, often faster than specialized programs like fgrep(1).  The following
4530 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
4531 out the names of those files that contain a match:
4532
4533     $search = 'while (<>) { study;';
4534     foreach $word (@words) {
4535         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
4536     }
4537     $search .= "}";
4538     @ARGV = @files;
4539     undef $/;
4540     eval $search;               # this screams
4541     $/ = "\n";          # put back to normal input delimiter
4542     foreach $file (sort keys(%seen)) {
4543         print $file, "\n";
4544     }
4545
4546 =item sub BLOCK
4547
4548 =item sub NAME
4549
4550 =item sub NAME BLOCK
4551
4552 This is subroutine definition, not a real function I<per se>.  With just a
4553 NAME (and possibly prototypes or attributes), it's just a forward declaration.
4554 Without a NAME, it's an anonymous function declaration, and does actually
4555 return a value: the CODE ref of the closure you just created.  See L<perlsub>
4556 and L<perlref> for details.
4557
4558 =item substr EXPR,OFFSET,LENGTH,REPLACEMENT
4559
4560 =item substr EXPR,OFFSET,LENGTH
4561
4562 =item substr EXPR,OFFSET
4563
4564 Extracts a substring out of EXPR and returns it.  First character is at
4565 offset C<0>, or whatever you've set C<$[> to (but don't do that).
4566 If OFFSET is negative (or more precisely, less than C<$[>), starts
4567 that far from the end of the string.  If LENGTH is omitted, returns
4568 everything to the end of the string.  If LENGTH is negative, leaves that
4569 many characters off the end of the string.
4570
4571 You can use the substr() function as an lvalue, in which case EXPR
4572 must itself be an lvalue.  If you assign something shorter than LENGTH,
4573 the string will shrink, and if you assign something longer than LENGTH,
4574 the string will grow to accommodate it.  To keep the string the same
4575 length you may need to pad or chop your value using C<sprintf>.
4576
4577 If OFFSET and LENGTH specify a substring that is partly outside the
4578 string, only the part within the string is returned.  If the substring
4579 is beyond either end of the string, substr() returns the undefined
4580 value and produces a warning.  When used as an lvalue, specifying a
4581 substring that is entirely outside the string is a fatal error.
4582 Here's an example showing the behavior for boundary cases:
4583
4584     my $name = 'fred';
4585     substr($name, 4) = 'dy';            # $name is now 'freddy'
4586     my $null = substr $name, 6, 2;      # returns '' (no warning)
4587     my $oops = substr $name, 7;         # returns undef, with warning
4588     substr($name, 7) = 'gap';           # fatal error
4589
4590 An alternative to using substr() as an lvalue is to specify the
4591 replacement string as the 4th argument.  This allows you to replace
4592 parts of the EXPR and return what was there before in one operation,
4593 just as you can with splice().
4594
4595 =item symlink OLDFILE,NEWFILE
4596
4597 Creates a new filename symbolically linked to the old filename.
4598 Returns C<1> for success, C<0> otherwise.  On systems that don't support
4599 symbolic links, produces a fatal error at run time.  To check for that,
4600 use eval:
4601
4602     $symlink_exists = eval { symlink("",""); 1 };
4603
4604 =item syscall LIST
4605
4606 Calls the system call specified as the first element of the list,
4607 passing the remaining elements as arguments to the system call.  If
4608 unimplemented, produces a fatal error.  The arguments are interpreted
4609 as follows: if a given argument is numeric, the argument is passed as
4610 an int.  If not, the pointer to the string value is passed.  You are
4611 responsible to make sure a string is pre-extended long enough to
4612 receive any result that might be written into a string.  You can't use a
4613 string literal (or other read-only string) as an argument to C<syscall>
4614 because Perl has to assume that any string pointer might be written
4615 through.  If your
4616 integer arguments are not literals and have never been interpreted in a
4617 numeric context, you may need to add C<0> to them to force them to look
4618 like numbers.  This emulates the C<syswrite> function (or vice versa):
4619
4620     require 'syscall.ph';               # may need to run h2ph
4621     $s = "hi there\n";
4622     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
4623
4624 Note that Perl supports passing of up to only 14 arguments to your system call,
4625 which in practice should usually suffice.
4626
4627 Syscall returns whatever value returned by the system call it calls.
4628 If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno).
4629 Note that some system calls can legitimately return C<-1>.  The proper
4630 way to handle such calls is to assign C<$!=0;> before the call and
4631 check the value of C<$!> if syscall returns C<-1>.
4632
4633 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
4634 number of the read end of the pipe it creates.  There is no way
4635 to retrieve the file number of the other end.  You can avoid this 
4636 problem by using C<pipe> instead.
4637
4638 =item sysopen FILEHANDLE,FILENAME,MODE
4639
4640 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
4641
4642 Opens the file whose filename is given by FILENAME, and associates it
4643 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
4644 the name of the real filehandle wanted.  This function calls the
4645 underlying operating system's C<open> function with the parameters
4646