t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still current
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17 # Measure the elapsed wallclock time.
  18 my $t0 = time();
  19
  20 # If we're doing deparse tests, ignore failures for these
  21 my $deparse_failures;
  22
  23 # And skip even running these
  24 my $deparse_skips;
  25
  26 # directories with special sets of test switches
  27 my %dir_to_switch =
  28     (base => '',
  29      comp => '',
  30      run => '',
  31      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  32      );
  33
  34 # "not absolute" is the default, as it saves some fakery within TestInit
  35 # which can perturb tests, and takes CPU. Working with the upstream author of
  36 # any of these, to figure out how to remove them from this list, considered
  37 # "a good thing".
  38 my %abs = (
  39            '../cpan/Archive-Tar' => 1,
  40            '../cpan/AutoLoader' => 1,
  41            '../cpan/CPAN' => 1,
  42            '../cpan/Devel-PPPort' => 1,
  43            '../cpan/Encode' => 1,
  44            '../cpan/ExtUtils-Constant' => 1,
  45            '../cpan/ExtUtils-Install' => 1,
  46            '../cpan/ExtUtils-MakeMaker' => 1,
  47            '../cpan/ExtUtils-Manifest' => 1,
  48            '../cpan/File-Fetch' => 1,
  49            '../cpan/IPC-Cmd' => 1,
  50            '../cpan/IPC-SysV' => 1,
  51            '../cpan/Locale-Codes' => 1,
  52            '../cpan/Module-Load' => 1,
  53            '../cpan/Module-Load-Conditional' => 1,
  54            '../cpan/Pod-Simple' => 1,
  55            '../cpan/Test-Simple' => 1,
  56            '../cpan/podlators' => 1,
  57            '../dist/Cwd' => 1,
  58            '../dist/ExtUtils-ParseXS' => 1,
  59            '../dist/Tie-File' => 1,
  60           );
  61
  62 my %temp_no_core =
  63     ('../cpan/B-Debug' => 1,
  64      '../cpan/Compress-Raw-Bzip2' => 1,
  65      '../cpan/Compress-Raw-Zlib' => 1,
  66      '../cpan/Devel-PPPort' => 1,
  67      '../cpan/Getopt-Long' => 1,
  68      '../cpan/IO-Compress' => 1,
  69      '../cpan/MIME-Base64' => 1,
  70      '../cpan/parent' => 1,
  71      '../cpan/Pod-Simple' => 1,
  72      '../cpan/podlators' => 1,
  73      '../cpan/Test-Simple' => 1,
  74      '../cpan/Tie-RefHash' => 1,
  75      '../cpan/Unicode-Collate' => 1,
  76      '../dist/Unicode-Normalize' => 1,
  77     );
  78
  79 # delete env vars that may influence the results
  80 # but allow override via *_TEST env var if wanted
  81 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  82 my @bad_env_vars = qw(
  83     PERL5LIB PERLLIB PERL5OPT
  84     PERL_YAML_BACKEND PERL_JSON_BACKEND
  85 );
  86
  87 for my $envname (@bad_env_vars) {
  88     my $override = $ENV{"${envname}_TEST"};
  89     if (defined $override) {
  90         warn "$0: $envname=$override\n";
  91         $ENV{$envname} = $override;
  92     }
  93     else {
  94         delete $ENV{$envname};
  95     }
  96 }
  97
  98 # Location to put the Valgrind log.
  99 our $Valgrind_Log;
 100
 101 my %skip = (
 102             '.' => 1,
 103             '..' => 1,
 104             'CVS' => 1,
 105             'RCS' => 1,
 106             'SCCS' => 1,
 107             '.svn' => 1,
 108            );
 109
 110
 111 if ($::do_nothing) {
 112     return 1;
 113 }
 114
 115 $| = 1;
 116
 117 # for testing TEST only
 118 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 119 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 120
 121 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 122 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 123
 124 # String eval to avoid loading File::Glob on non-miniperl.
 125 # (Windows only uses this script for miniperl.)
 126 @ARGV = eval 'map glob, @ARGV' if $^O eq 'MSWin32';
 127
 128 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 129
 130 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 131 # can't rely on require working.
 132 {
 133     my @argv = ();
 134     foreach my $idx (0..$#ARGV) {
 135         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 136         $::benchmark = 1 if $1 eq 'benchmark';
 137         $::core    = 1 if $1 eq 'core';
 138         $::verbose = 1 if $1 eq 'v';
 139         $::torture = 1 if $1 eq 'torture';
 140         $::with_utf8 = 1 if $1 eq 'utf8';
 141         $::with_utf16 = 1 if $1 eq 'utf16';
 142         $::taintwarn = 1 if $1 eq 'taintwarn';
 143         if ($1 =~ /^deparse(,.+)?$/) {
 144             $::deparse = 1;
 145             $::deparse_opts = $1;
 146             _process_deparse_config();
 147         }
 148     }
 149     @ARGV = @argv;
 150 }
 151
 152 chdir 't' if -f 't/TEST';
 153 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 154     @INC = '../lib';
 155 }
 156
 157 die "You need to run \"make test_prep\" first to set things up.\n"
 158   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 159
 160 # check leakage for embedders
 161 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 162 # check existence of all symbols
 163 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
 164
 165 $ENV{EMXSHELL} = 'sh';        # For OS/2
 166
 167 if ($show_elapsed_time) { require Time::HiRes }
 168 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
 169
 170 # Roll your own File::Find!
 171 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
 172 sub _find_files {
 173     my($patt, @dirs) = @_;
 174     for my $dir (@dirs) {
 175         opendir DIR, $dir or die "Trouble opening $dir: $!";
 176         foreach my $f (sort { $a cmp $b } readdir DIR) {
 177             next if $skip{$f};
 178
 179             my $fullpath = "$dir/$f";
 180
 181             if (-d $fullpath) {
 182                 _find_files($patt, $fullpath);
 183             } elsif ($f =~ /$patt/) {
 184                 push @found, $fullpath;
 185             }
 186         }
 187     }
 188     @found;
 189 }
 190
 191
 192 # Scan the text of the test program to find switches and special options
 193 # we might need to apply.
 194 sub _scan_test {
 195     my($test, $type) = @_;
 196
 197     open(my $script, "<", $test) or die "Can't read $test.\n";
 198     my $first_line = <$script>;
 199
 200     $first_line =~ tr/\0//d if $::with_utf16;
 201
 202     my $switch = "";
 203     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 204         $switch = "-$1";
 205     } else {
 206         if ($::taintwarn) {
 207             # not all tests are expected to pass with this option
 208             $switch = '-t';
 209         } else {
 210             $switch = '';
 211         }
 212     }
 213
 214     my $file_opts = "";
 215     if ($type eq 'deparse') {
 216         # Look for #line directives which change the filename
 217         while (<$script>) {
 218             $file_opts = $file_opts . ",-f$3$4"
 219               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 220         }
 221     }
 222
 223     close $script;
 224
 225     my $perl = $^O eq 'MSWin32' ? '.\perl' : './perl';
 226     my $lib  = '../lib';
 227     my $run_dir;
 228     my $return_dir;
 229
 230     $test =~ /^(.+)\/[^\/]+/;
 231     my $dir = $1;
 232     my $testswitch = $dir_to_switch{$dir};
 233     if (!defined $testswitch) {
 234         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 235             $run_dir = $1;
 236             $return_dir = '../../t';
 237             $lib = '../../lib';
 238             $perl = '../../t/perl';
 239             $testswitch = "-I../.. -MTestInit=U2T";
 240             if ($2 eq 'cpan' || $2 eq 'dist') {
 241                 if($abs{$run_dir}) {
 242                     $testswitch = $testswitch . ',A';
 243                 }
 244                 if ($temp_no_core{$run_dir}) {
 245                     $testswitch = $testswitch . ',NC';
 246                 }
 247             }
 248         } elsif ($test =~ m!^\.\./lib!) {
 249             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 250         } else {
 251             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 252         }
 253     }
 254
 255     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 256
 257     my %options = (
 258         perl => $perl,
 259         lib => $lib,
 260         test => $test,
 261         run_dir => $run_dir,
 262         return_dir => $return_dir,
 263         testswitch => $testswitch,
 264         utf8 => $utf8,
 265         file => $file_opts,
 266         switch => $switch,
 267     );
 268
 269     return \%options;
 270 }
 271
 272 sub _cmd {
 273     my($options, $type) = @_;
 274
 275     my $test = $options->{test};
 276
 277     my $cmd;
 278     if ($type eq 'deparse') {
 279         my $perl = "$options->{perl} $options->{testswitch}";
 280         my $lib = $options->{lib};
 281
 282         $cmd = (
 283           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 284           "-l$::deparse_opts$options->{file} ".
 285           "$test > $test.dp ".
 286           "&& $perl $options->{switch} -I$lib $test.dp"
 287         );
 288     }
 289     elsif ($type eq 'perl') {
 290         my $perl = $options->{perl};
 291         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 292
 293         if ($ENV{PERL_VALGRIND}) {
 294             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 295             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
 296             if ($options->{run_dir}) {
 297                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 298             }
 299             my $vg_opts = $ENV{VG_OPTS}
 300                //   "--log-file=$Valgrind_Log "
 301                   . "--suppressions=$perl_supp --leak-check=yes "
 302                   . "--leak-resolution=high --show-reachable=yes "
 303                   . "--num-callers=50 --track-origins=yes";
 304             # Force logging if not asked for (so cachegrind reporting works below)
 305             if ($vg_opts !~ /--log-file/) {
 306                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
 307             }
 308             $perl = "$valgrind_exe $vg_opts $perl";
 309         }
 310
 311         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 312         $cmd = $perl . _quote_args($args) . " $test $redir";
 313     }
 314     return $cmd;
 315 }
 316
 317 sub _before_fork {
 318     my ($options) = @_;
 319
 320     if ($options->{run_dir}) {
 321         my $run_dir = $options->{run_dir};
 322         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 323     }
 324
 325     # Remove previous valgrind output otherwise it will interfere
 326     my $test = $options->{test};
 327
 328     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 329
 330     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
 331         unlink $Valgrind_Log
 332             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 333     }
 334
 335     return;
 336 }
 337
 338 sub _after_fork {
 339     my ($options) = @_;
 340
 341     if ($options->{return_dir}) {
 342         my $return_dir = $options->{return_dir};
 343         chdir $return_dir
 344            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 345     }
 346
 347     return;
 348 }
 349
 350 sub _run_test {
 351     my ($test, $type) = @_;
 352
 353     my $options = _scan_test($test, $type);
 354     # $test might have changed if we're in ext/Foo, so don't use it anymore
 355     # from now on. Use $options->{test} instead.
 356
 357     _before_fork($options);
 358
 359     my $cmd = _cmd($options, $type);
 360
 361     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 362
 363     _after_fork($options);
 364
 365     # Our environment may force us to use UTF-8, but we can't be sure that
 366     # anything we're reading from will be generating (well formed) UTF-8
 367     # This may not be the best way - possibly we should unset ${^OPEN} up
 368     # top?
 369     binmode $results;
 370
 371     return $results;
 372 }
 373
 374 sub _quote_args {
 375     my ($args) = @_;
 376     my $argstring = '';
 377
 378     foreach (split(/\s+/,$args)) {
 379        # In VMS protect with doublequotes because otherwise
 380        # DCL will lowercase -- unless already doublequoted.
 381        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 382        $argstring = $argstring . ' ' . $_;
 383     }
 384     return $argstring;
 385 }
 386
 387 sub _populate_hash {
 388     return unless defined $_[0];
 389     return map {$_, 1} split /\s+/, $_[0];
 390 }
 391
 392 sub _tests_from_manifest {
 393     my ($extensions, $known_extensions) = @_;
 394     my %skip;
 395     my %extensions = _populate_hash($extensions);
 396     my %known_extensions = _populate_hash($known_extensions);
 397
 398     foreach (keys %known_extensions) {
 399         $skip{$_} = 1 unless $extensions{$_};
 400     }
 401
 402     my @results;
 403     my $mani = '../MANIFEST';
 404     if (open(MANI, $mani)) {
 405         while (<MANI>) {
 406             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 407                 my $t = $1;
 408                 my $extension = $2;
 409
 410                 # XXX Generates way too many error lines currently.  Skip for
 411                 # v5.22
 412                 next if $t =~ /^cpan/ && ord("A") != 65;
 413
 414                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 415                     if (defined $extension) {
 416                         $extension =~ s!/t(:?/\S+)*$!!;
 417                         # XXX Do I want to warn that I'm skipping these?
 418                         next if $skip{$extension};
 419                         my $flat_extension = $extension;
 420                         $flat_extension =~ s!-!/!g;
 421                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 422                     }
 423                     my $path = "../$t";
 424                     push @results, $path;
 425                     $::path_to_name{$path} = $t;
 426                 }
 427             }
 428         }
 429         close MANI;
 430     } else {
 431         warn "$0: cannot open $mani: $!\n";
 432     }
 433     return @results;
 434 }
 435
 436 unless (@ARGV) {
 437     # base first, as TEST bails out if that can't run
 438     # then comp, to validate that require works
 439     # then run, to validate that -M works
 440     # then we know we can -MTestInit for everything else, making life simpler
 441     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro perf)) {
 442         _find_tests($dir);
 443     }
 444     unless ($::core) {
 445         _find_tests('porting');
 446         _find_tests("lib");
 447     }
 448     # Config.pm may be broken for make minitest. And this is only a refinement
 449     # for skipping tests on non-default builds, so it is allowed to fail.
 450     # What we want to to is make a list of extensions which we did not build.
 451     my $configsh = '../config.sh';
 452     my ($extensions, $known_extensions);
 453     if (-f $configsh) {
 454         open FH, $configsh or die "Can't open $configsh: $!";
 455         while (<FH>) {
 456             if (/^extensions=['"](.*)['"]$/) {
 457                 $extensions = $1;
 458             }
 459             elsif (/^known_extensions=['"](.*)['"]$/) {
 460                 $known_extensions = $1;
 461             }
 462         }
 463         if (!defined $known_extensions) {
 464             warn "No known_extensions line found in $configsh";
 465         }
 466         if (!defined $extensions) {
 467             warn "No extensions line found in $configsh";
 468         }
 469     }
 470     # The "complex" constructions of list return from a subroutine, and push of
 471     # a list, might fail if perl is really hosed, but they aren't needed for
 472     # make minitest, and the building of extensions will likely also fail if
 473     # something is that badly wrong.
 474     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 475     unless ($::core) {
 476         _find_tests('japh') if $::torture;
 477         _find_tests('benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 478         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
 479     }
 480 }
 481
 482 if ($::deparse) {
 483     _testprogs('deparse', '',   @ARGV);
 484 }
 485 elsif ($::with_utf16) {
 486     for my $e (0, 1) {
 487         for my $b (0, 1) {
 488             print STDERR "# ENDIAN $e BOM $b\n";
 489             my @UARGV;
 490             for my $a (@ARGV) {
 491                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 492                 my $f = $e ? "v" : "n";
 493                 push @UARGV, $u;
 494                 unlink($u);
 495                 if (open(A, $a)) {
 496                     if (open(U, ">$u")) {
 497                         print U pack("$f", 0xFEFF) if $b;
 498                         while (<A>) {
 499                             print U pack("$f*", unpack("C*", $_));
 500                         }
 501                         close(U);
 502                     }
 503                     close(A);
 504                 }
 505             }
 506             _testprogs('perl', '', @UARGV);
 507             unlink(@UARGV);
 508         }
 509     }
 510 }
 511 else {
 512     _testprogs('perl',    '',   @ARGV);
 513 }
 514
 515 sub _testprogs {
 516     my ($type, $args, @tests) = @_;
 517
 518     print <<'EOT' if ($type eq 'deparse');
 519 ------------------------------------------------------------------------------
 520 TESTING DEPARSER
 521 ------------------------------------------------------------------------------
 522 EOT
 523
 524     $::bad_files = 0;
 525
 526     foreach my $t (@tests) {
 527       unless (exists $::path_to_name{$t}) {
 528         my $tname = "t/$t";
 529         $::path_to_name{$t} = $tname;
 530       }
 531     }
 532     my $maxlen = 0;
 533     foreach (@::path_to_name{@tests}) {
 534         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
 535         my $len = length ;
 536         $maxlen = $len if $len > $maxlen;
 537     }
 538     # + 3 : we want three dots between the test name and the "ok"
 539     my $dotdotdot = $maxlen + 3 ;
 540     my $grind_ct = 0;           # count of non-empty valgrind reports
 541     my $total_files = @tests;
 542     my $good_files = 0;
 543     my $tested_files  = 0;
 544     my $totmax = 0;
 545     my %failed_tests;
 546     my $toolnm;         # valgrind, cachegrind, perf
 547
 548     while (my $test = shift @tests) {
 549         my ($test_start_time, @starttimes) = 0;
 550         if ($show_elapsed_time) {
 551             $test_start_time = Time::HiRes::time();
 552             # times() reports usage by TEST, but we want usage of each
 553             # testprog it calls, so record accumulated times now,
 554             # subtract them out afterwards.  Ideally, we'd take times
 555             # in BEGIN/END blocks (giving better visibility of self vs
 556             # children of each testprog), but that would require some
 557             # IPC to send results back here, or a completely different
 558             # collection scheme (Storable isn't tuned for incremental use)
 559             @starttimes = times;
 560         }
 561         if ($test =~ /^$/) {
 562             next;
 563         }
 564         if ($type eq 'deparse' && $test =~ $deparse_skips) {
 565             next;
 566         }
 567         my $te = $::path_to_name{$test} . '.'
 568                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
 569
 570         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 571             print $te;
 572             $te = '';
 573         }
 574
 575         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 576
 577         my $results = _run_test($test, $type);
 578
 579         my $failure;
 580         my $next = 0;
 581         my $seen_leader = 0;
 582         my $seen_ok = 0;
 583         my $trailing_leader = 0;
 584         my $max;
 585         my %todo;
 586         while (<$results>) {
 587             next if /^\s*$/; # skip blank lines
 588             if (/^1..$/ && ($^O eq 'VMS')) {
 589                 # VMS pipe bug inserts blank lines.
 590                 my $l2 = <$results>;
 591                 if ($l2 =~ /^\s*$/) {
 592                     $l2 = <$results>;
 593                 }
 594                 $_ = '1..' . $l2;
 595             }
 596             if ($::verbose) {
 597                 print $_;
 598             }
 599             unless (/^\#/) {
 600                 if ($trailing_leader) {
 601                     # shouldn't be anything following a postfix 1..n
 602                     $failure = 'FAILED--extra output after trailing 1..n';
 603                     last;
 604                 }
 605                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 606                     if ($seen_leader) {
 607                         $failure = 'FAILED--seen duplicate leader';
 608                         last;
 609                     }
 610                     $max = $1;
 611                     %todo = map { $_ => 1 } split / /, $3 if $3;
 612                     $totmax = $totmax + $max;
 613                     $tested_files = $tested_files + 1;
 614                     if ($seen_ok) {
 615                         # 1..n appears at end of file
 616                         $trailing_leader = 1;
 617                         if ($next != $max) {
 618                             $failure = "FAILED--expected $max tests, saw $next";
 619                             last;
 620                         }
 621                     }
 622                     else {
 623                         $next = 0;
 624                     }
 625                     $seen_leader = 1;
 626                 }
 627                 else {
 628                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 629                         unless ($seen_leader) {
 630                             unless ($seen_ok) {
 631                                 $next = 0;
 632                             }
 633                         }
 634                         $seen_ok = 1;
 635                         $next = $next + 1;
 636                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 637                         $num = $next unless $num;
 638
 639                         if ($num == $next) {
 640
 641                             # SKIP is essentially the same as TODO for t/TEST
 642                             # this still conforms to TAP:
 643                             # http://testanything.org/wiki/index.php/TAP_specification
 644                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 645                             $istodo = 1 if $todo{$num};
 646
 647                             if( $not && !$istodo ) {
 648                                 $failure = "FAILED at test $num";
 649                                 last;
 650                             }
 651                         }
 652                         else {
 653                             $failure ="FAILED--expected test $next, saw test $num";
 654                             last;
 655                         }
 656                     }
 657                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 658                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 659                     }
 660                     else {
 661                         # module tests are allowed extra output,
 662                         # because Test::Harness allows it
 663                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 664                         $failure = "FAILED--unexpected output at test $next";
 665                         last;
 666                     }
 667                 }
 668             }
 669         }
 670         my  @junk = <$results>;  # dump remaining output to prevent SIGPIPE
 671                                  # (so far happens only on os390)
 672         close $results;
 673         undef @junk;
 674
 675         if (not defined $failure) {
 676             $failure = 'FAILED--no leader found' unless $seen_leader;
 677         }
 678
 679         _check_valgrind(\$toolnm, \$grind_ct, \$test);
 680
 681         if ($type eq 'deparse' && !$ENV{KEEP_DEPARSE_FILES}) {
 682             unlink "./$test.dp";
 683         }
 684         if (not defined $failure and $next != $max) {
 685             $failure="FAILED--expected $max tests, saw $next";
 686         }
 687
 688         if( !defined $failure  # don't mask a test failure
 689             and $? )
 690         {
 691             $failure = "FAILED--non-zero wait status: $?";
 692         }
 693
 694         # Deparse? Should it have passed or failed?
 695         if ($type eq 'deparse' && $test =~ $deparse_failures) {
 696             if (!$failure) {
 697                 # Wait, it didn't fail? Great news! Tell someone!
 698                 $failure = "FAILED--all tests passed but test should have failed";
 699             } else {
 700                 # Bah, still failing. Mask it.
 701                 print "${te}skipped\n";
 702                 $tested_files = $tested_files - 1;
 703                 next;
 704             }
 705         }
 706
 707         if (defined $failure) {
 708             print "${te}$failure\n";
 709             $::bad_files = $::bad_files + 1;
 710             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
 711                 # Die if running under minitest (no DynaLoader).  Otherwise
 712                 # keep going, as  we know that Perl basically works, or we
 713                 # would not have been able to actually compile it all the way.
 714                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
 715             }
 716             $failed_tests{$test} = 1;
 717         }
 718         else {
 719             if ($max) {
 720                 my ($elapsed, $etms) = ("", 0);
 721                 if ( $show_elapsed_time ) {
 722                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
 723                     $elapsed = sprintf(" %8.0f ms", $etms);
 724
 725                     my (@endtimes) = times;
 726                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
 727                     splice @endtimes, 0, 2;    # drop self/harness times
 728                     $_ *= 1000 for @endtimes;  # and scale to ms
 729                     $timings{$test} = [$etms,@endtimes];
 730                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
 731                 }
 732                 print "${te}ok$elapsed\n";
 733                 $good_files = $good_files + 1;
 734             }
 735             else {
 736                 print "${te}skipped\n";
 737                 $tested_files = $tested_files - 1;
 738             }
 739         }
 740     } # while tests
 741
 742     if ($::bad_files == 0) {
 743         if ($good_files) {
 744             print "All tests successful.\n";
 745             # XXX add mention of 'perlbug -ok' ?
 746         }
 747         else {
 748             die "FAILED--no tests were run for some reason.\n";
 749         }
 750     }
 751     else {
 752         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 753         my $s = $::bad_files == 1 ? "" : "s";
 754         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 755         for my $test ( sort keys %failed_tests ) {
 756             print "\t$test\n";
 757         }
 758         warn <<'SHRDLU_1';
 759 ### Since not all tests were successful, you may want to run some of
 760 ### them individually and examine any diagnostic messages they produce.
 761 ### See the INSTALL document's section on "make test".
 762 SHRDLU_1
 763         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 764 ### You have a good chance to get more information by running
 765 ###   ./perl harness
 766 ### in the 't' directory since most (>=80%) of the tests succeeded.
 767 SHRDLU_2
 768         if (eval {require Config; import Config; 1}) {
 769             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 770                 warn <<SHRDLU_3;
 771 ### You may have to set your dynamic library search path,
 772 ### $p, to point to the build directory:
 773 SHRDLU_3
 774                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 775                     warn <<SHRDLU_4a;
 776 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 777 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 778 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 779 SHRDLU_4a
 780                 } else {
 781                     warn <<SHRDLU_4b;
 782 ###   setenv $p `pwd`; cd t; ./perl harness
 783 ###   $p=`pwd`; export $p; cd t; ./perl harness
 784 ###   export $p=`pwd`; cd t; ./perl harness
 785 SHRDLU_4b
 786                 }
 787                 warn <<SHRDLU_5;
 788 ### for csh-style shells, like tcsh; or for traditional/modern
 789 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 790 SHRDLU_5
 791             }
 792         }
 793     }
 794     printf "Elapsed: %d sec\n", time() - $t0;
 795     my ($user,$sys,$cuser,$csys) = times;
 796     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
 797                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
 798     print "$tot\n";
 799     if ($good_files) {
 800         if (-d $show_elapsed_time) {
 801             # HARNESS_TIMER = <a-directory>.  Save timings etc to
 802             # storable file there.  NB: the test cds to ./t/, so
 803             # relative path must account for that, ie ../../perf
 804             # points to dir next to source tree.
 805             require Storable;
 806             my @dt = localtime;
 807             $dt[5] += 1900; $dt[4] += 1; # fix year, month
 808             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
 809             Storable::store({ perf => \%timings,
 810                               gather_conf_platform_info(),
 811                               total => $tot,
 812                             }, $fn);
 813             print "wrote storable file: $fn\n";
 814         }
 815     }
 816
 817     _cleanup_valgrind(\$toolnm, \$grind_ct);
 818 }
 819 exit ($::bad_files != 0);
 820
 821 # Collect platform, config data that should allow comparing
 822 # performance data between different machines.  With enough data,
 823 # and/or clever statistical analysis, it should be possible to
 824 # determine the effect of config choices, more memory, etc
 825
 826 sub gather_conf_platform_info {
 827     # currently rather quick & dirty, and subject to change
 828     # for both content and format.
 829     require Config;
 830     my (%conf, @platform) = ();
 831     $conf{$_} = $Config::Config{$_} for
 832         grep /cc|git|config_arg\d+/, keys %Config::Config;
 833     if (-f '/proc/cpuinfo') {
 834         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
 835         @platform = grep /name|cpu/, <$fh>;
 836         chomp $_ for @platform;
 837     }
 838     unshift @platform, $^O;
 839
 840     return (
 841         conf => \%conf,
 842         platform => {cpu => \@platform,
 843                      mem => [ grep s/\s+/ /,
 844                               grep chomp, `free` ],
 845                      load => [ grep chomp, `uptime` ],
 846         },
 847         host => (grep chomp, `hostname -f`),
 848         version => '0.03', # bump for conf, platform, or data collection changes
 849         );
 850 }
 851
 852 sub _check_valgrind {
 853     return unless $ENV{PERL_VALGRIND};
 854
 855     my ($toolnm, $grind_ct, $test) = @_;
 856
 857     $$toolnm = $ENV{VALGRIND};
 858     $$toolnm =~ s|.*/||;  # keep basename
 859     my @valgrind;       # gets content of file
 860     if (-e $Valgrind_Log) {
 861         if (open(V, $Valgrind_Log)) {
 862             @valgrind = <V>;
 863             close V;
 864         } else {
 865             warn "$0: Failed to open '$Valgrind_Log': $!\n";
 866         }
 867     }
 868     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
 869         $$toolnm = $1;
 870         if ($$toolnm eq 'perf') {
 871             # append perfs subcommand, not just stat
 872             my ($sub) = split /\s/, $ENV{VG_OPTS};
 873             $$toolnm .= "-$sub";
 874         }
 875         if (rename $Valgrind_Log, "$$test.$$toolnm") {
 876             $$grind_ct++;
 877         } else {
 878             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
 879         }
 880     }
 881     elsif (@valgrind) {
 882         my $leaks = 0;
 883         my $errors = 0;
 884         for my $i (0..$#valgrind) {
 885             local $_ = $valgrind[$i];
 886             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 887                 $errors = $errors + $1;   # there may be multiple error summaries
 888             } elsif (/^==\d+== LEAK SUMMARY:/) {
 889                 for my $off (1 .. 4) {
 890                     if ($valgrind[$i+$off] =~
 891                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 892                             $leaks = $leaks + $1;
 893                     }
 894                 }
 895             }
 896         }
 897         if ($errors or $leaks) {
 898             if (rename $Valgrind_Log, "$$test.valgrind") {
 899                 $$grind_ct = $$grind_ct + 1;
 900             } else {
 901                 warn "$0: Failed to create '$$test.valgrind': $!\n";
 902             }
 903         }
 904     } else {
 905         # Quiet wasn't asked for? Something may be amiss
 906         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
 907             warn "No valgrind output?\n";
 908         }
 909     }
 910     if (-e $Valgrind_Log) {
 911         unlink $Valgrind_Log
 912             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 913     }
 914 }
 915
 916 sub _cleanup_valgrind {
 917     return unless $ENV{PERL_VALGRIND};
 918
 919     my ($toolnm, $grind_ct) = @_;
 920     my $s = $$grind_ct == 1 ? '' : 's';
 921     print "$$grind_ct valgrind report$s created.\n", ;
 922     if ($$toolnm eq 'cachegrind') {
 923         # cachegrind leaves a lot of cachegrind.out.$pid litter
 924         # around the tree, find and delete them
 925         unlink _find_files('cachegrind.out.\d+$',
 926                      qw ( ../t ../cpan ../ext ../dist/ ));
 927     }
 928 }
 929
 930 # Generate regexps of known bad filenames / skips from Porting/deparse-skips.txt
 931 my $in;
 932
 933 sub _process_deparse_config {
 934     my @deparse_failures;
 935     my @deparse_skips;
 936
 937     my $f = '../Porting/deparse-skips.txt';
 938
 939     my $skips;
 940     if (!open($skips, '<', $f)) {
 941         warn "Failed to find $f: $!\n";
 942         return;
 943     }
 944
 945     while(<$skips>) {
 946         if (/__DEPARSE_FAILURES__/) {
 947             $in = \@deparse_failures; next;
 948         } elsif (/__DEPARSE_SKIPS__/) {
 949             $in = \@deparse_skips; next;
 950         } elsif (!$in) {
 951             next;
 952         }
 953
 954         s/#.*$//; # Kill comments
 955         s/\s+$//; # And trailing whitespace
 956
 957         next unless $_;
 958
 959         push @$in, $_;
 960     }
 961
 962     for my $f (@deparse_failures, @deparse_skips) {
 963         if ($f =~ m|/$|) { # Dir? Skip everything below it
 964             $f = qr/\Q$f\E.*/;
 965         } else {
 966             $f = qr/\Q$f\E/;
 967         }
 968     }
 969
 970     $deparse_failures = join('|', @deparse_failures);
 971     $deparse_failures = qr/^(?:$deparse_failures)$/;
 972
 973     $deparse_skips = join('|', @deparse_skips);
 974     $deparse_skips = qr/^(?:$deparse_skips)$/;
 975 }
 976
 977 # ex: set ts=8 sts=4 sw=4 noet: