This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlretut: Emphasize difference of /r
[perl5.git] / pod / perlretut.pod
1 =head1 NAME
2
3 perlretut - Perl regular expressions tutorial
4
5 =head1 DESCRIPTION
6
7 This page provides a basic tutorial on understanding, creating and
8 using regular expressions in Perl.  It serves as a complement to the
9 reference page on regular expressions L<perlre>.  Regular expressions
10 are an integral part of the C<m//>, C<s///>, C<qr//> and C<split>
11 operators and so this tutorial also overlaps with
12 L<perlop/"Regexp Quote-Like Operators"> and L<perlfunc/split>.
13
14 Perl is widely renowned for excellence in text processing, and regular
15 expressions are one of the big factors behind this fame.  Perl regular
16 expressions display an efficiency and flexibility unknown in most
17 other computer languages.  Mastering even the basics of regular
18 expressions will allow you to manipulate text with surprising ease.
19
20 What is a regular expression?  A regular expression is simply a string
21 that describes a pattern.  Patterns are in common use these days;
22 examples are the patterns typed into a search engine to find web pages
23 and the patterns used to list files in a directory, e.g., C<ls *.txt>
24 or C<dir *.*>.  In Perl, the patterns described by regular expressions
25 are used to search strings, extract desired parts of strings, and to
26 do search and replace operations.
27
28 Regular expressions have the undeserved reputation of being abstract
29 and difficult to understand.  Regular expressions are constructed using
30 simple concepts like conditionals and loops and are no more difficult
31 to understand than the corresponding C<if> conditionals and C<while>
32 loops in the Perl language itself.  In fact, the main challenge in
33 learning regular expressions is just getting used to the terse
34 notation used to express these concepts.
35
36 This tutorial flattens the learning curve by discussing regular
37 expression concepts, along with their notation, one at a time and with
38 many examples.  The first part of the tutorial will progress from the
39 simplest word searches to the basic regular expression concepts.  If
40 you master the first part, you will have all the tools needed to solve
41 about 98% of your needs.  The second part of the tutorial is for those
42 comfortable with the basics and hungry for more power tools.  It
43 discusses the more advanced regular expression operators and
44 introduces the latest cutting-edge innovations.
45
46 A note: to save time, 'regular expression' is often abbreviated as
47 regexp or regex.  Regexp is a more natural abbreviation than regex, but
48 is harder to pronounce.  The Perl pod documentation is evenly split on
49 regexp vs regex; in Perl, there is more than one way to abbreviate it.
50 We'll use regexp in this tutorial.
51
52 =head1 Part 1: The basics
53
54 =head2 Simple word matching
55
56 The simplest regexp is simply a word, or more generally, a string of
57 characters.  A regexp consisting of a word matches any string that
58 contains that word:
59
60     "Hello World" =~ /World/;  # matches
61
62 What is this Perl statement all about? C<"Hello World"> is a simple
63 double-quoted string.  C<World> is the regular expression and the
64 C<//> enclosing C</World/> tells Perl to search a string for a match.
65 The operator C<=~> associates the string with the regexp match and
66 produces a true value if the regexp matched, or false if the regexp
67 did not match.  In our case, C<World> matches the second word in
68 C<"Hello World">, so the expression is true.  Expressions like this
69 are useful in conditionals:
70
71     if ("Hello World" =~ /World/) {
72         print "It matches\n";
73     }
74     else {
75         print "It doesn't match\n";
76     }
77
78 There are useful variations on this theme.  The sense of the match can
79 be reversed by using the C<!~> operator:
80
81     if ("Hello World" !~ /World/) {
82         print "It doesn't match\n";
83     }
84     else {
85         print "It matches\n";
86     }
87
88 The literal string in the regexp can be replaced by a variable:
89
90     $greeting = "World";
91     if ("Hello World" =~ /$greeting/) {
92         print "It matches\n";
93     }
94     else {
95         print "It doesn't match\n";
96     }
97
98 If you're matching against the special default variable C<$_>, the
99 C<$_ =~> part can be omitted:
100
101     $_ = "Hello World";
102     if (/World/) {
103         print "It matches\n";
104     }
105     else {
106         print "It doesn't match\n";
107     }
108
109 And finally, the C<//> default delimiters for a match can be changed
110 to arbitrary delimiters by putting an C<'m'> out front:
111
112     "Hello World" =~ m!World!;   # matches, delimited by '!'
113     "Hello World" =~ m{World};   # matches, note the matching '{}'
114     "/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
115                                  # '/' becomes an ordinary char
116
117 C</World/>, C<m!World!>, and C<m{World}> all represent the
118 same thing.  When, e.g., the quote (C<">) is used as a delimiter, the forward
119 slash C<'/'> becomes an ordinary character and can be used in this regexp
120 without trouble.
121
122 Let's consider how different regexps would match C<"Hello World">:
123
124     "Hello World" =~ /world/;  # doesn't match
125     "Hello World" =~ /o W/;    # matches
126     "Hello World" =~ /oW/;     # doesn't match
127     "Hello World" =~ /World /; # doesn't match
128
129 The first regexp C<world> doesn't match because regexps are
130 case-sensitive.  The second regexp matches because the substring
131 S<C<'o W'>> occurs in the string S<C<"Hello World">>.  The space
132 character ' ' is treated like any other character in a regexp and is
133 needed to match in this case.  The lack of a space character is the
134 reason the third regexp C<'oW'> doesn't match.  The fourth regexp
135 C<'World '> doesn't match because there is a space at the end of the
136 regexp, but not at the end of the string.  The lesson here is that
137 regexps must match a part of the string I<exactly> in order for the
138 statement to be true.
139
140 If a regexp matches in more than one place in the string, Perl will
141 always match at the earliest possible point in the string:
142
143     "Hello World" =~ /o/;       # matches 'o' in 'Hello'
144     "That hat is red" =~ /hat/; # matches 'hat' in 'That'
145
146 With respect to character matching, there are a few more points you
147 need to know about.   First of all, not all characters can be used 'as
148 is' in a match.  Some characters, called I<metacharacters>, are reserved
149 for use in regexp notation.  The metacharacters are
150
151     {}[]()^$.|*+?\
152
153 The significance of each of these will be explained
154 in the rest of the tutorial, but for now, it is important only to know
155 that a metacharacter can be matched by putting a backslash before it:
156
157     "2+2=4" =~ /2+2/;    # doesn't match, + is a metacharacter
158     "2+2=4" =~ /2\+2/;   # matches, \+ is treated like an ordinary +
159     "The interval is [0,1)." =~ /[0,1)./     # is a syntax error!
160     "The interval is [0,1)." =~ /\[0,1\)\./  # matches
161     "#!/usr/bin/perl" =~ /#!\/usr\/bin\/perl/;  # matches
162
163 In the last regexp, the forward slash C<'/'> is also backslashed,
164 because it is used to delimit the regexp.  This can lead to LTS
165 (leaning toothpick syndrome), however, and it is often more readable
166 to change delimiters.
167
168     "#!/usr/bin/perl" =~ m!#\!/usr/bin/perl!;  # easier to read
169
170 The backslash character C<'\'> is a metacharacter itself and needs to
171 be backslashed:
172
173     'C:\WIN32' =~ /C:\\WIN/;   # matches
174
175 In addition to the metacharacters, there are some ASCII characters
176 which don't have printable character equivalents and are instead
177 represented by I<escape sequences>.  Common examples are C<\t> for a
178 tab, C<\n> for a newline, C<\r> for a carriage return and C<\a> for a
179 bell (or alert).  If your string is better thought of as a sequence of arbitrary
180 bytes, the octal escape sequence, e.g., C<\033>, or hexadecimal escape
181 sequence, e.g., C<\x1B> may be a more natural representation for your
182 bytes.  Here are some examples of escapes:
183
184     "1000\t2000" =~ m(0\t2)   # matches
185     "1000\n2000" =~ /0\n20/   # matches
186     "1000\t2000" =~ /\000\t2/ # doesn't match, "0" ne "\000"
187     "cat"   =~ /\o{143}\x61\x74/ # matches in ASCII, but a weird way
188                                  # to spell cat
189
190 If you've been around Perl a while, all this talk of escape sequences
191 may seem familiar.  Similar escape sequences are used in double-quoted
192 strings and in fact the regexps in Perl are mostly treated as
193 double-quoted strings.  This means that variables can be used in
194 regexps as well.  Just like double-quoted strings, the values of the
195 variables in the regexp will be substituted in before the regexp is
196 evaluated for matching purposes.  So we have:
197
198     $foo = 'house';
199     'housecat' =~ /$foo/;      # matches
200     'cathouse' =~ /cat$foo/;   # matches
201     'housecat' =~ /${foo}cat/; # matches
202
203 So far, so good.  With the knowledge above you can already perform
204 searches with just about any literal string regexp you can dream up.
205 Here is a I<very simple> emulation of the Unix grep program:
206
207     % cat > simple_grep
208     #!/usr/bin/perl
209     $regexp = shift;
210     while (<>) {
211         print if /$regexp/;
212     }
213     ^D
214
215     % chmod +x simple_grep
216
217     % simple_grep abba /usr/dict/words
218     Babbage
219     cabbage
220     cabbages
221     sabbath
222     Sabbathize
223     Sabbathizes
224     sabbatical
225     scabbard
226     scabbards
227
228 This program is easy to understand.  C<#!/usr/bin/perl> is the standard
229 way to invoke a perl program from the shell.
230 S<C<$regexp = shift;>> saves the first command line argument as the
231 regexp to be used, leaving the rest of the command line arguments to
232 be treated as files.  S<C<< while (<>) >>> loops over all the lines in
233 all the files.  For each line, S<C<print if /$regexp/;>> prints the
234 line if the regexp matches the line.  In this line, both C<print> and
235 C</$regexp/> use the default variable C<$_> implicitly.
236
237 With all of the regexps above, if the regexp matched anywhere in the
238 string, it was considered a match.  Sometimes, however, we'd like to
239 specify I<where> in the string the regexp should try to match.  To do
240 this, we would use the I<anchor> metacharacters C<^> and C<$>.  The
241 anchor C<^> means match at the beginning of the string and the anchor
242 C<$> means match at the end of the string, or before a newline at the
243 end of the string.  Here is how they are used:
244
245     "housekeeper" =~ /keeper/;    # matches
246     "housekeeper" =~ /^keeper/;   # doesn't match
247     "housekeeper" =~ /keeper$/;   # matches
248     "housekeeper\n" =~ /keeper$/; # matches
249
250 The second regexp doesn't match because C<^> constrains C<keeper> to
251 match only at the beginning of the string, but C<"housekeeper"> has
252 keeper starting in the middle.  The third regexp does match, since the
253 C<$> constrains C<keeper> to match only at the end of the string.
254
255 When both C<^> and C<$> are used at the same time, the regexp has to
256 match both the beginning and the end of the string, i.e., the regexp
257 matches the whole string.  Consider
258
259     "keeper" =~ /^keep$/;      # doesn't match
260     "keeper" =~ /^keeper$/;    # matches
261     ""       =~ /^$/;          # ^$ matches an empty string
262
263 The first regexp doesn't match because the string has more to it than
264 C<keep>.  Since the second regexp is exactly the string, it
265 matches.  Using both C<^> and C<$> in a regexp forces the complete
266 string to match, so it gives you complete control over which strings
267 match and which don't.  Suppose you are looking for a fellow named
268 bert, off in a string by himself:
269
270     "dogbert" =~ /bert/;   # matches, but not what you want
271
272     "dilbert" =~ /^bert/;  # doesn't match, but ..
273     "bertram" =~ /^bert/;  # matches, so still not good enough
274
275     "bertram" =~ /^bert$/; # doesn't match, good
276     "dilbert" =~ /^bert$/; # doesn't match, good
277     "bert"    =~ /^bert$/; # matches, perfect
278
279 Of course, in the case of a literal string, one could just as easily
280 use the string comparison S<C<$string eq 'bert'>> and it would be
281 more efficient.   The  C<^...$> regexp really becomes useful when we
282 add in the more powerful regexp tools below.
283
284 =head2 Using character classes
285
286 Although one can already do quite a lot with the literal string
287 regexps above, we've only scratched the surface of regular expression
288 technology.  In this and subsequent sections we will introduce regexp
289 concepts (and associated metacharacter notations) that will allow a
290 regexp to represent not just a single character sequence, but a I<whole
291 class> of them.
292
293 One such concept is that of a I<character class>.  A character class
294 allows a set of possible characters, rather than just a single
295 character, to match at a particular point in a regexp.  Character
296 classes are denoted by brackets C<[...]>, with the set of characters
297 to be possibly matched inside.  Here are some examples:
298
299     /cat/;       # matches 'cat'
300     /[bcr]at/;   # matches 'bat, 'cat', or 'rat'
301     /item[0123456789]/;  # matches 'item0' or ... or 'item9'
302     "abc" =~ /[cab]/;    # matches 'a'
303
304 In the last statement, even though C<'c'> is the first character in
305 the class, C<'a'> matches because the first character position in the
306 string is the earliest point at which the regexp can match.
307
308     /[yY][eE][sS]/;      # match 'yes' in a case-insensitive way
309                          # 'yes', 'Yes', 'YES', etc.
310
311 This regexp displays a common task: perform a case-insensitive
312 match.  Perl provides a way of avoiding all those brackets by simply
313 appending an C<'i'> to the end of the match.  Then C</[yY][eE][sS]/;>
314 can be rewritten as C</yes/i;>.  The C<'i'> stands for
315 case-insensitive and is an example of a I<modifier> of the matching
316 operation.  We will meet other modifiers later in the tutorial.
317
318 We saw in the section above that there were ordinary characters, which
319 represented themselves, and special characters, which needed a
320 backslash C<\> to represent themselves.  The same is true in a
321 character class, but the sets of ordinary and special characters
322 inside a character class are different than those outside a character
323 class.  The special characters for a character class are C<-]\^$> (and
324 the pattern delimiter, whatever it is).
325 C<]> is special because it denotes the end of a character class.  C<$> is
326 special because it denotes a scalar variable.  C<\> is special because
327 it is used in escape sequences, just like above.  Here is how the
328 special characters C<]$\> are handled:
329
330    /[\]c]def/; # matches ']def' or 'cdef'
331    $x = 'bcr';
332    /[$x]at/;   # matches 'bat', 'cat', or 'rat'
333    /[\$x]at/;  # matches '$at' or 'xat'
334    /[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'
335
336 The last two are a little tricky.  In C<[\$x]>, the backslash protects
337 the dollar sign, so the character class has two members C<$> and C<x>.
338 In C<[\\$x]>, the backslash is protected, so C<$x> is treated as a
339 variable and substituted in double quote fashion.
340
341 The special character C<'-'> acts as a range operator within character
342 classes, so that a contiguous set of characters can be written as a
343 range.  With ranges, the unwieldy C<[0123456789]> and C<[abc...xyz]>
344 become the svelte C<[0-9]> and C<[a-z]>.  Some examples are
345
346     /item[0-9]/;  # matches 'item0' or ... or 'item9'
347     /[0-9bx-z]aa/;  # matches '0aa', ..., '9aa',
348                     # 'baa', 'xaa', 'yaa', or 'zaa'
349     /[0-9a-fA-F]/;  # matches a hexadecimal digit
350     /[0-9a-zA-Z_]/; # matches a "word" character,
351                     # like those in a Perl variable name
352
353 If C<'-'> is the first or last character in a character class, it is
354 treated as an ordinary character; C<[-ab]>, C<[ab-]> and C<[a\-b]> are
355 all equivalent.
356
357 The special character C<^> in the first position of a character class
358 denotes a I<negated character class>, which matches any character but
359 those in the brackets.  Both C<[...]> and C<[^...]> must match a
360 character, or the match fails.  Then
361
362     /[^a]at/;  # doesn't match 'aat' or 'at', but matches
363                # all other 'bat', 'cat, '0at', '%at', etc.
364     /[^0-9]/;  # matches a non-numeric character
365     /[a^]at/;  # matches 'aat' or '^at'; here '^' is ordinary
366
367 Now, even C<[0-9]> can be a bother to write multiple times, so in the
368 interest of saving keystrokes and making regexps more readable, Perl
369 has several abbreviations for common character classes, as shown below.
370 Since the introduction of Unicode, these character classes match more
371 than just a few characters in the ISO 8859-1 range.
372
373 =over 4
374
375 =item *
376
377 \d matches a digit, not just [0-9] but also digits from non-roman scripts
378
379 =item *
380
381 \s matches a whitespace character, the set [\ \t\r\n\f] and others
382
383 =item *
384
385 \w matches a word character (alphanumeric or _), not just [0-9a-zA-Z_]
386 but also digits and characters from non-roman scripts
387
388 =item *
389
390 \D is a negated \d; it represents any other character than a digit, or [^\d]
391
392 =item *
393
394 \S is a negated \s; it represents any non-whitespace character [^\s]
395
396 =item *
397
398 \W is a negated \w; it represents any non-word character [^\w]
399
400 =item *
401
402 The period '.' matches any character but "\n" (unless the modifier C<//s> is
403 in effect, as explained below).
404
405 =item *
406
407 \N, like the period, matches any character but "\n", but it does so
408 regardless of whether the modifier C<//s> is in effect.
409
410 =back
411
412 The C<\d\s\w\D\S\W> abbreviations can be used both inside and outside
413 of character classes.  Here are some in use:
414
415     /\d\d:\d\d:\d\d/; # matches a hh:mm:ss time format
416     /[\d\s]/;         # matches any digit or whitespace character
417     /\w\W\w/;         # matches a word char, followed by a
418                       # non-word char, followed by a word char
419     /..rt/;           # matches any two chars, followed by 'rt'
420     /end\./;          # matches 'end.'
421     /end[.]/;         # same thing, matches 'end.'
422
423 Because a period is a metacharacter, it needs to be escaped to match
424 as an ordinary period. Because, for example, C<\d> and C<\w> are sets
425 of characters, it is incorrect to think of C<[^\d\w]> as C<[\D\W]>; in
426 fact C<[^\d\w]> is the same as C<[^\w]>, which is the same as
427 C<[\W]>. Think DeMorgan's laws.
428
429 An anchor useful in basic regexps is the I<word anchor>
430 C<\b>.  This matches a boundary between a word character and a non-word
431 character C<\w\W> or C<\W\w>:
432
433     $x = "Housecat catenates house and cat";
434     $x =~ /cat/;    # matches cat in 'housecat'
435     $x =~ /\bcat/;  # matches cat in 'catenates'
436     $x =~ /cat\b/;  # matches cat in 'housecat'
437     $x =~ /\bcat\b/;  # matches 'cat' at end of string
438
439 Note in the last example, the end of the string is considered a word
440 boundary.
441
442 You might wonder why C<'.'> matches everything but C<"\n"> - why not
443 every character? The reason is that often one is matching against
444 lines and would like to ignore the newline characters.  For instance,
445 while the string C<"\n"> represents one line, we would like to think
446 of it as empty.  Then
447
448     ""   =~ /^$/;    # matches
449     "\n" =~ /^$/;    # matches, $ anchors before "\n"
450
451     ""   =~ /./;      # doesn't match; it needs a char
452     ""   =~ /^.$/;    # doesn't match; it needs a char
453     "\n" =~ /^.$/;    # doesn't match; it needs a char other than "\n"
454     "a"  =~ /^.$/;    # matches
455     "a\n"  =~ /^.$/;  # matches, $ anchors before "\n"
456
457 This behavior is convenient, because we usually want to ignore
458 newlines when we count and match characters in a line.  Sometimes,
459 however, we want to keep track of newlines.  We might even want C<^>
460 and C<$> to anchor at the beginning and end of lines within the
461 string, rather than just the beginning and end of the string.  Perl
462 allows us to choose between ignoring and paying attention to newlines
463 by using the C<//s> and C<//m> modifiers.  C<//s> and C<//m> stand for
464 single line and multi-line and they determine whether a string is to
465 be treated as one continuous string, or as a set of lines.  The two
466 modifiers affect two aspects of how the regexp is interpreted: 1) how
467 the C<'.'> character class is defined, and 2) where the anchors C<^>
468 and C<$> are able to match.  Here are the four possible combinations:
469
470 =over 4
471
472 =item *
473
474 no modifiers (//): Default behavior.  C<'.'> matches any character
475 except C<"\n">.  C<^> matches only at the beginning of the string and
476 C<$> matches only at the end or before a newline at the end.
477
478 =item *
479
480 s modifier (//s): Treat string as a single long line.  C<'.'> matches
481 any character, even C<"\n">.  C<^> matches only at the beginning of
482 the string and C<$> matches only at the end or before a newline at the
483 end.
484
485 =item *
486
487 m modifier (//m): Treat string as a set of multiple lines.  C<'.'>
488 matches any character except C<"\n">.  C<^> and C<$> are able to match
489 at the start or end of I<any> line within the string.
490
491 =item *
492
493 both s and m modifiers (//sm): Treat string as a single long line, but
494 detect multiple lines.  C<'.'> matches any character, even
495 C<"\n">.  C<^> and C<$>, however, are able to match at the start or end
496 of I<any> line within the string.
497
498 =back
499
500 Here are examples of C<//s> and C<//m> in action:
501
502     $x = "There once was a girl\nWho programmed in Perl\n";
503
504     $x =~ /^Who/;   # doesn't match, "Who" not at start of string
505     $x =~ /^Who/s;  # doesn't match, "Who" not at start of string
506     $x =~ /^Who/m;  # matches, "Who" at start of second line
507     $x =~ /^Who/sm; # matches, "Who" at start of second line
508
509     $x =~ /girl.Who/;   # doesn't match, "." doesn't match "\n"
510     $x =~ /girl.Who/s;  # matches, "." matches "\n"
511     $x =~ /girl.Who/m;  # doesn't match, "." doesn't match "\n"
512     $x =~ /girl.Who/sm; # matches, "." matches "\n"
513
514 Most of the time, the default behavior is what is wanted, but C<//s> and
515 C<//m> are occasionally very useful.  If C<//m> is being used, the start
516 of the string can still be matched with C<\A> and the end of the string
517 can still be matched with the anchors C<\Z> (matches both the end and
518 the newline before, like C<$>), and C<\z> (matches only the end):
519
520     $x =~ /^Who/m;   # matches, "Who" at start of second line
521     $x =~ /\AWho/m;  # doesn't match, "Who" is not at start of string
522
523     $x =~ /girl$/m;  # matches, "girl" at end of first line
524     $x =~ /girl\Z/m; # doesn't match, "girl" is not at end of string
525
526     $x =~ /Perl\Z/m; # matches, "Perl" is at newline before end
527     $x =~ /Perl\z/m; # doesn't match, "Perl" is not at end of string
528
529 We now know how to create choices among classes of characters in a
530 regexp.  What about choices among words or character strings? Such
531 choices are described in the next section.
532
533 =head2 Matching this or that
534
535 Sometimes we would like our regexp to be able to match different
536 possible words or character strings.  This is accomplished by using
537 the I<alternation> metacharacter C<|>.  To match C<dog> or C<cat>, we
538 form the regexp C<dog|cat>.  As before, Perl will try to match the
539 regexp at the earliest possible point in the string.  At each
540 character position, Perl will first try to match the first
541 alternative, C<dog>.  If C<dog> doesn't match, Perl will then try the
542 next alternative, C<cat>.  If C<cat> doesn't match either, then the
543 match fails and Perl moves to the next position in the string.  Some
544 examples:
545
546     "cats and dogs" =~ /cat|dog|bird/;  # matches "cat"
547     "cats and dogs" =~ /dog|cat|bird/;  # matches "cat"
548
549 Even though C<dog> is the first alternative in the second regexp,
550 C<cat> is able to match earlier in the string.
551
552     "cats"          =~ /c|ca|cat|cats/; # matches "c"
553     "cats"          =~ /cats|cat|ca|c/; # matches "cats"
554
555 Here, all the alternatives match at the first string position, so the
556 first alternative is the one that matches.  If some of the
557 alternatives are truncations of the others, put the longest ones first
558 to give them a chance to match.
559
560     "cab" =~ /a|b|c/ # matches "c"
561                      # /a|b|c/ == /[abc]/
562
563 The last example points out that character classes are like
564 alternations of characters.  At a given character position, the first
565 alternative that allows the regexp match to succeed will be the one
566 that matches.
567
568 =head2 Grouping things and hierarchical matching
569
570 Alternation allows a regexp to choose among alternatives, but by
571 itself it is unsatisfying.  The reason is that each alternative is a whole
572 regexp, but sometime we want alternatives for just part of a
573 regexp.  For instance, suppose we want to search for housecats or
574 housekeepers.  The regexp C<housecat|housekeeper> fits the bill, but is
575 inefficient because we had to type C<house> twice.  It would be nice to
576 have parts of the regexp be constant, like C<house>, and some
577 parts have alternatives, like C<cat|keeper>.
578
579 The I<grouping> metacharacters C<()> solve this problem.  Grouping
580 allows parts of a regexp to be treated as a single unit.  Parts of a
581 regexp are grouped by enclosing them in parentheses.  Thus we could solve
582 the C<housecat|housekeeper> by forming the regexp as
583 C<house(cat|keeper)>.  The regexp C<house(cat|keeper)> means match
584 C<house> followed by either C<cat> or C<keeper>.  Some more examples
585 are
586
587     /(a|b)b/;    # matches 'ab' or 'bb'
588     /(ac|b)b/;   # matches 'acb' or 'bb'
589     /(^a|b)c/;   # matches 'ac' at start of string or 'bc' anywhere
590     /(a|[bc])d/; # matches 'ad', 'bd', or 'cd'
591
592     /house(cat|)/;  # matches either 'housecat' or 'house'
593     /house(cat(s|)|)/;  # matches either 'housecats' or 'housecat' or
594                         # 'house'.  Note groups can be nested.
595
596     /(19|20|)\d\d/;  # match years 19xx, 20xx, or the Y2K problem, xx
597     "20" =~ /(19|20|)\d\d/;  # matches the null alternative '()\d\d',
598                              # because '20\d\d' can't match
599
600 Alternations behave the same way in groups as out of them: at a given
601 string position, the leftmost alternative that allows the regexp to
602 match is taken.  So in the last example at the first string position,
603 C<"20"> matches the second alternative, but there is nothing left over
604 to match the next two digits C<\d\d>.  So Perl moves on to the next
605 alternative, which is the null alternative and that works, since
606 C<"20"> is two digits.
607
608 The process of trying one alternative, seeing if it matches, and
609 moving on to the next alternative, while going back in the string
610 from where the previous alternative was tried, if it doesn't, is called
611 I<backtracking>.  The term 'backtracking' comes from the idea that
612 matching a regexp is like a walk in the woods.  Successfully matching
613 a regexp is like arriving at a destination.  There are many possible
614 trailheads, one for each string position, and each one is tried in
615 order, left to right.  From each trailhead there may be many paths,
616 some of which get you there, and some which are dead ends.  When you
617 walk along a trail and hit a dead end, you have to backtrack along the
618 trail to an earlier point to try another trail.  If you hit your
619 destination, you stop immediately and forget about trying all the
620 other trails.  You are persistent, and only if you have tried all the
621 trails from all the trailheads and not arrived at your destination, do
622 you declare failure.  To be concrete, here is a step-by-step analysis
623 of what Perl does when it tries to match the regexp
624
625     "abcde" =~ /(abd|abc)(df|d|de)/;
626
627 =over 4
628
629 =item 0
630
631 Start with the first letter in the string 'a'.
632
633 =item 1
634
635 Try the first alternative in the first group 'abd'.
636
637 =item 2
638
639 Match 'a' followed by 'b'. So far so good.
640
641 =item 3
642
643 'd' in the regexp doesn't match 'c' in the string - a dead
644 end.  So backtrack two characters and pick the second alternative in
645 the first group 'abc'.
646
647 =item 4
648
649 Match 'a' followed by 'b' followed by 'c'.  We are on a roll
650 and have satisfied the first group. Set $1 to 'abc'.
651
652 =item 5
653
654 Move on to the second group and pick the first alternative
655 'df'.
656
657 =item 6
658
659 Match the 'd'.
660
661 =item 7
662
663 'f' in the regexp doesn't match 'e' in the string, so a dead
664 end.  Backtrack one character and pick the second alternative in the
665 second group 'd'.
666
667 =item 8
668
669 'd' matches. The second grouping is satisfied, so set $2 to
670 'd'.
671
672 =item 9
673
674 We are at the end of the regexp, so we are done! We have
675 matched 'abcd' out of the string "abcde".
676
677 =back
678
679 There are a couple of things to note about this analysis.  First, the
680 third alternative in the second group 'de' also allows a match, but we
681 stopped before we got to it - at a given character position, leftmost
682 wins.  Second, we were able to get a match at the first character
683 position of the string 'a'.  If there were no matches at the first
684 position, Perl would move to the second character position 'b' and
685 attempt the match all over again.  Only when all possible paths at all
686 possible character positions have been exhausted does Perl give
687 up and declare S<C<$string =~ /(abd|abc)(df|d|de)/;>> to be false.
688
689 Even with all this work, regexp matching happens remarkably fast.  To
690 speed things up, Perl compiles the regexp into a compact sequence of
691 opcodes that can often fit inside a processor cache.  When the code is
692 executed, these opcodes can then run at full throttle and search very
693 quickly.
694
695 =head2 Extracting matches
696
697 The grouping metacharacters C<()> also serve another completely
698 different function: they allow the extraction of the parts of a string
699 that matched.  This is very useful to find out what matched and for
700 text processing in general.  For each grouping, the part that matched
701 inside goes into the special variables C<$1>, C<$2>, etc.  They can be
702 used just as ordinary variables:
703
704     # extract hours, minutes, seconds
705     if ($time =~ /(\d\d):(\d\d):(\d\d)/) {    # match hh:mm:ss format
706         $hours = $1;
707         $minutes = $2;
708         $seconds = $3;
709     }
710
711 Now, we know that in scalar context,
712 S<C<$time =~ /(\d\d):(\d\d):(\d\d)/>> returns a true or false
713 value.  In list context, however, it returns the list of matched values
714 C<($1,$2,$3)>.  So we could write the code more compactly as
715
716     # extract hours, minutes, seconds
717     ($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);
718
719 If the groupings in a regexp are nested, C<$1> gets the group with the
720 leftmost opening parenthesis, C<$2> the next opening parenthesis,
721 etc.  Here is a regexp with nested groups:
722
723     /(ab(cd|ef)((gi)|j))/;
724      1  2      34
725
726 If this regexp matches, C<$1> contains a string starting with
727 C<'ab'>, C<$2> is either set to C<'cd'> or C<'ef'>, C<$3> equals either
728 C<'gi'> or C<'j'>, and C<$4> is either set to C<'gi'>, just like C<$3>,
729 or it remains undefined.
730
731 For convenience, Perl sets C<$+> to the string held by the highest numbered
732 C<$1>, C<$2>,... that got assigned (and, somewhat related, C<$^N> to the
733 value of the C<$1>, C<$2>,... most-recently assigned; i.e. the C<$1>,
734 C<$2>,... associated with the rightmost closing parenthesis used in the
735 match).
736
737
738 =head2 Backreferences
739
740 Closely associated with the matching variables C<$1>, C<$2>, ... are
741 the I<backreferences> C<\g1>, C<\g2>,...  Backreferences are simply
742 matching variables that can be used I<inside> a regexp.  This is a
743 really nice feature; what matches later in a regexp is made to depend on
744 what matched earlier in the regexp.  Suppose we wanted to look
745 for doubled words in a text, like 'the the'.  The following regexp finds
746 all 3-letter doubles with a space in between:
747
748     /\b(\w\w\w)\s\g1\b/;
749
750 The grouping assigns a value to \g1, so that the same 3-letter sequence
751 is used for both parts.
752
753 A similar task is to find words consisting of two identical parts:
754
755     % simple_grep '^(\w\w\w\w|\w\w\w|\w\w|\w)\g1$' /usr/dict/words
756     beriberi
757     booboo
758     coco
759     mama
760     murmur
761     papa
762
763 The regexp has a single grouping which considers 4-letter
764 combinations, then 3-letter combinations, etc., and uses C<\g1> to look for
765 a repeat.  Although C<$1> and C<\g1> represent the same thing, care should be
766 taken to use matched variables C<$1>, C<$2>,... only I<outside> a regexp
767 and backreferences C<\g1>, C<\g2>,... only I<inside> a regexp; not doing
768 so may lead to surprising and unsatisfactory results.
769
770
771 =head2 Relative backreferences
772
773 Counting the opening parentheses to get the correct number for a
774 backreference is errorprone as soon as there is more than one
775 capturing group.  A more convenient technique became available
776 with Perl 5.10: relative backreferences. To refer to the immediately
777 preceding capture group one now may write C<\g{-1}>, the next but
778 last is available via C<\g{-2}>, and so on.
779
780 Another good reason in addition to readability and maintainability
781 for using relative backreferences is illustrated by the following example,
782 where a simple pattern for matching peculiar strings is used:
783
784     $a99a = '([a-z])(\d)\g2\g1';   # matches a11a, g22g, x33x, etc.
785
786 Now that we have this pattern stored as a handy string, we might feel
787 tempted to use it as a part of some other pattern:
788
789     $line = "code=e99e";
790     if ($line =~ /^(\w+)=$a99a$/){   # unexpected behavior!
791         print "$1 is valid\n";
792     } else {
793         print "bad line: '$line'\n";
794     }
795
796 But this doesn't match, at least not the way one might expect. Only
797 after inserting the interpolated C<$a99a> and looking at the resulting
798 full text of the regexp is it obvious that the backreferences have
799 backfired. The subexpression C<(\w+)> has snatched number 1 and
800 demoted the groups in C<$a99a> by one rank. This can be avoided by
801 using relative backreferences:
802
803     $a99a = '([a-z])(\d)\g{-1}\g{-2}';  # safe for being interpolated
804
805
806 =head2 Named backreferences
807
808 Perl 5.10 also introduced named capture groups and named backreferences.
809 To attach a name to a capturing group, you write either
810 C<< (?<name>...) >> or C<< (?'name'...) >>.  The backreference may
811 then be written as C<\g{name}>.  It is permissible to attach the
812 same name to more than one group, but then only the leftmost one of the
813 eponymous set can be referenced.  Outside of the pattern a named
814 capture group is accessible through the C<%+> hash.
815
816 Assuming that we have to match calendar dates which may be given in one
817 of the three formats yyyy-mm-dd, mm/dd/yyyy or dd.mm.yyyy, we can write
818 three suitable patterns where we use 'd', 'm' and 'y' respectively as the
819 names of the groups capturing the pertaining components of a date. The
820 matching operation combines the three patterns as alternatives:
821
822     $fmt1 = '(?<y>\d\d\d\d)-(?<m>\d\d)-(?<d>\d\d)';
823     $fmt2 = '(?<m>\d\d)/(?<d>\d\d)/(?<y>\d\d\d\d)';
824     $fmt3 = '(?<d>\d\d)\.(?<m>\d\d)\.(?<y>\d\d\d\d)';
825     for my $d qw( 2006-10-21 15.01.2007 10/31/2005 ){
826         if ( $d =~ m{$fmt1|$fmt2|$fmt3} ){
827             print "day=$+{d} month=$+{m} year=$+{y}\n";
828         }
829     }
830
831 If any of the alternatives matches, the hash C<%+> is bound to contain the
832 three key-value pairs.
833
834
835 =head2 Alternative capture group numbering
836
837 Yet another capturing group numbering technique (also as from Perl 5.10)
838 deals with the problem of referring to groups within a set of alternatives.
839 Consider a pattern for matching a time of the day, civil or military style:
840
841     if ( $time =~ /(\d\d|\d):(\d\d)|(\d\d)(\d\d)/ ){
842         # process hour and minute
843     }
844
845 Processing the results requires an additional if statement to determine
846 whether C<$1> and C<$2> or C<$3> and C<$4> contain the goodies. It would
847 be easier if we could use group numbers 1 and 2 in second alternative as
848 well, and this is exactly what the parenthesized construct C<(?|...)>,
849 set around an alternative achieves. Here is an extended version of the
850 previous pattern:
851
852     if ( $time =~ /(?|(\d\d|\d):(\d\d)|(\d\d)(\d\d))\s+([A-Z][A-Z][A-Z])/ ){
853         print "hour=$1 minute=$2 zone=$3\n";
854     }
855
856 Within the alternative numbering group, group numbers start at the same
857 position for each alternative. After the group, numbering continues
858 with one higher than the maximum reached across all the alternatives.
859
860 =head2 Position information
861
862 In addition to what was matched, Perl (since 5.6.0) also provides the
863 positions of what was matched as contents of the C<@-> and C<@+>
864 arrays. C<$-[0]> is the position of the start of the entire match and
865 C<$+[0]> is the position of the end. Similarly, C<$-[n]> is the
866 position of the start of the C<$n> match and C<$+[n]> is the position
867 of the end. If C<$n> is undefined, so are C<$-[n]> and C<$+[n]>. Then
868 this code
869
870     $x = "Mmm...donut, thought Homer";
871     $x =~ /^(Mmm|Yech)\.\.\.(donut|peas)/; # matches
872     foreach $expr (1..$#-) {
873         print "Match $expr: '${$expr}' at position ($-[$expr],$+[$expr])\n";
874     }
875
876 prints
877
878     Match 1: 'Mmm' at position (0,3)
879     Match 2: 'donut' at position (6,11)
880
881 Even if there are no groupings in a regexp, it is still possible to
882 find out what exactly matched in a string.  If you use them, Perl
883 will set C<$`> to the part of the string before the match, will set C<$&>
884 to the part of the string that matched, and will set C<$'> to the part
885 of the string after the match.  An example:
886
887     $x = "the cat caught the mouse";
888     $x =~ /cat/;  # $` = 'the ', $& = 'cat', $' = ' caught the mouse'
889     $x =~ /the/;  # $` = '', $& = 'the', $' = ' cat caught the mouse'
890
891 In the second match, C<$`> equals C<''> because the regexp matched at the
892 first character position in the string and stopped; it never saw the
893 second 'the'.  It is important to note that using C<$`> and C<$'>
894 slows down regexp matching quite a bit, while C<$&> slows it down to a
895 lesser extent, because if they are used in one regexp in a program,
896 they are generated for I<all> regexps in the program.  So if raw
897 performance is a goal of your application, they should be avoided.
898 If you need to extract the corresponding substrings, use C<@-> and
899 C<@+> instead:
900
901     $` is the same as substr( $x, 0, $-[0] )
902     $& is the same as substr( $x, $-[0], $+[0]-$-[0] )
903     $' is the same as substr( $x, $+[0] )
904
905 As of Perl 5.10, the C<${^PREMATCH}>, C<${^MATCH}> and C<${^POSTMATCH}>
906 variables may be used. These are only set if the C</p> modifier is present.
907 Consequently they do not penalize the rest of the program.
908
909 =head2 Non-capturing groupings
910
911 A group that is required to bundle a set of alternatives may or may not be
912 useful as a capturing group.  If it isn't, it just creates a superfluous
913 addition to the set of available capture group values, inside as well as
914 outside the regexp.  Non-capturing groupings, denoted by C<(?:regexp)>,
915 still allow the regexp to be treated as a single unit, but don't establish
916 a capturing group at the same time.  Both capturing and non-capturing
917 groupings are allowed to co-exist in the same regexp.  Because there is
918 no extraction, non-capturing groupings are faster than capturing
919 groupings.  Non-capturing groupings are also handy for choosing exactly
920 which parts of a regexp are to be extracted to matching variables:
921
922     # match a number, $1-$4 are set, but we only want $1
923     /([+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?)/;
924
925     # match a number faster , only $1 is set
926     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE][+-]?\d+)?)/;
927
928     # match a number, get $1 = whole number, $2 = exponent
929     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE]([+-]?\d+))?)/;
930
931 Non-capturing groupings are also useful for removing nuisance
932 elements gathered from a split operation where parentheses are
933 required for some reason:
934
935     $x = '12aba34ba5';
936     @num = split /(a|b)+/, $x;    # @num = ('12','a','34','a','5')
937     @num = split /(?:a|b)+/, $x;  # @num = ('12','34','5')
938
939
940 =head2 Matching repetitions
941
942 The examples in the previous section display an annoying weakness.  We
943 were only matching 3-letter words, or chunks of words of 4 letters or
944 less.  We'd like to be able to match words or, more generally, strings
945 of any length, without writing out tedious alternatives like
946 C<\w\w\w\w|\w\w\w|\w\w|\w>.
947
948 This is exactly the problem the I<quantifier> metacharacters C<?>,
949 C<*>, C<+>, and C<{}> were created for.  They allow us to delimit the
950 number of repeats for a portion of a regexp we consider to be a
951 match.  Quantifiers are put immediately after the character, character
952 class, or grouping that we want to specify.  They have the following
953 meanings:
954
955 =over 4
956
957 =item *
958
959 C<a?> means: match 'a' 1 or 0 times
960
961 =item *
962
963 C<a*> means: match 'a' 0 or more times, i.e., any number of times
964
965 =item *
966
967 C<a+> means: match 'a' 1 or more times, i.e., at least once
968
969 =item *
970
971 C<a{n,m}> means: match at least C<n> times, but not more than C<m>
972 times.
973
974 =item *
975
976 C<a{n,}> means: match at least C<n> or more times
977
978 =item *
979
980 C<a{n}> means: match exactly C<n> times
981
982 =back
983
984 Here are some examples:
985
986     /[a-z]+\s+\d*/;  # match a lowercase word, at least one space, and
987                      # any number of digits
988     /(\w+)\s+\g1/;    # match doubled words of arbitrary length
989     /y(es)?/i;       # matches 'y', 'Y', or a case-insensitive 'yes'
990     $year =~ /^\d{2,4}$/;  # make sure year is at least 2 but not more
991                            # than 4 digits
992     $year =~ /^\d{4}$|^\d{2}$/;    # better match; throw out 3-digit dates
993     $year =~ /^\d{2}(\d{2})?$/;  # same thing written differently. However,
994                                  # this captures the last two digits in $1
995                                  # and the other does not.
996
997     % simple_grep '^(\w+)\g1$' /usr/dict/words   # isn't this easier?
998     beriberi
999     booboo
1000     coco
1001     mama
1002     murmur
1003     papa
1004
1005 For all of these quantifiers, Perl will try to match as much of the
1006 string as possible, while still allowing the regexp to succeed.  Thus
1007 with C</a?.../>, Perl will first try to match the regexp with the C<a>
1008 present; if that fails, Perl will try to match the regexp without the
1009 C<a> present.  For the quantifier C<*>, we get the following:
1010
1011     $x = "the cat in the hat";
1012     $x =~ /^(.*)(cat)(.*)$/; # matches,
1013                              # $1 = 'the '
1014                              # $2 = 'cat'
1015                              # $3 = ' in the hat'
1016
1017 Which is what we might expect, the match finds the only C<cat> in the
1018 string and locks onto it.  Consider, however, this regexp:
1019
1020     $x =~ /^(.*)(at)(.*)$/; # matches,
1021                             # $1 = 'the cat in the h'
1022                             # $2 = 'at'
1023                             # $3 = ''   (0 characters match)
1024
1025 One might initially guess that Perl would find the C<at> in C<cat> and
1026 stop there, but that wouldn't give the longest possible string to the
1027 first quantifier C<.*>.  Instead, the first quantifier C<.*> grabs as
1028 much of the string as possible while still having the regexp match.  In
1029 this example, that means having the C<at> sequence with the final C<at>
1030 in the string.  The other important principle illustrated here is that,
1031 when there are two or more elements in a regexp, the I<leftmost>
1032 quantifier, if there is one, gets to grab as much of the string as
1033 possible, leaving the rest of the regexp to fight over scraps.  Thus in
1034 our example, the first quantifier C<.*> grabs most of the string, while
1035 the second quantifier C<.*> gets the empty string.   Quantifiers that
1036 grab as much of the string as possible are called I<maximal match> or
1037 I<greedy> quantifiers.
1038
1039 When a regexp can match a string in several different ways, we can use
1040 the principles above to predict which way the regexp will match:
1041
1042 =over 4
1043
1044 =item *
1045
1046 Principle 0: Taken as a whole, any regexp will be matched at the
1047 earliest possible position in the string.
1048
1049 =item *
1050
1051 Principle 1: In an alternation C<a|b|c...>, the leftmost alternative
1052 that allows a match for the whole regexp will be the one used.
1053
1054 =item *
1055
1056 Principle 2: The maximal matching quantifiers C<?>, C<*>, C<+> and
1057 C<{n,m}> will in general match as much of the string as possible while
1058 still allowing the whole regexp to match.
1059
1060 =item *
1061
1062 Principle 3: If there are two or more elements in a regexp, the
1063 leftmost greedy quantifier, if any, will match as much of the string
1064 as possible while still allowing the whole regexp to match.  The next
1065 leftmost greedy quantifier, if any, will try to match as much of the
1066 string remaining available to it as possible, while still allowing the
1067 whole regexp to match.  And so on, until all the regexp elements are
1068 satisfied.
1069
1070 =back
1071
1072 As we have seen above, Principle 0 overrides the others. The regexp
1073 will be matched as early as possible, with the other principles
1074 determining how the regexp matches at that earliest character
1075 position.
1076
1077 Here is an example of these principles in action:
1078
1079     $x = "The programming republic of Perl";
1080     $x =~ /^(.+)(e|r)(.*)$/;  # matches,
1081                               # $1 = 'The programming republic of Pe'
1082                               # $2 = 'r'
1083                               # $3 = 'l'
1084
1085 This regexp matches at the earliest string position, C<'T'>.  One
1086 might think that C<e>, being leftmost in the alternation, would be
1087 matched, but C<r> produces the longest string in the first quantifier.
1088
1089     $x =~ /(m{1,2})(.*)$/;  # matches,
1090                             # $1 = 'mm'
1091                             # $2 = 'ing republic of Perl'
1092
1093 Here, The earliest possible match is at the first C<'m'> in
1094 C<programming>. C<m{1,2}> is the first quantifier, so it gets to match
1095 a maximal C<mm>.
1096
1097     $x =~ /.*(m{1,2})(.*)$/;  # matches,
1098                               # $1 = 'm'
1099                               # $2 = 'ing republic of Perl'
1100
1101 Here, the regexp matches at the start of the string. The first
1102 quantifier C<.*> grabs as much as possible, leaving just a single
1103 C<'m'> for the second quantifier C<m{1,2}>.
1104
1105     $x =~ /(.?)(m{1,2})(.*)$/;  # matches,
1106                                 # $1 = 'a'
1107                                 # $2 = 'mm'
1108                                 # $3 = 'ing republic of Perl'
1109
1110 Here, C<.?> eats its maximal one character at the earliest possible
1111 position in the string, C<'a'> in C<programming>, leaving C<m{1,2}>
1112 the opportunity to match both C<m>'s. Finally,
1113
1114     "aXXXb" =~ /(X*)/; # matches with $1 = ''
1115
1116 because it can match zero copies of C<'X'> at the beginning of the
1117 string.  If you definitely want to match at least one C<'X'>, use
1118 C<X+>, not C<X*>.
1119
1120 Sometimes greed is not good.  At times, we would like quantifiers to
1121 match a I<minimal> piece of string, rather than a maximal piece.  For
1122 this purpose, Larry Wall created the I<minimal match> or
1123 I<non-greedy> quantifiers C<??>, C<*?>, C<+?>, and C<{}?>.  These are
1124 the usual quantifiers with a C<?> appended to them.  They have the
1125 following meanings:
1126
1127 =over 4
1128
1129 =item *
1130
1131 C<a??> means: match 'a' 0 or 1 times. Try 0 first, then 1.
1132
1133 =item *
1134
1135 C<a*?> means: match 'a' 0 or more times, i.e., any number of times,
1136 but as few times as possible
1137
1138 =item *
1139
1140 C<a+?> means: match 'a' 1 or more times, i.e., at least once, but
1141 as few times as possible
1142
1143 =item *
1144
1145 C<a{n,m}?> means: match at least C<n> times, not more than C<m>
1146 times, as few times as possible
1147
1148 =item *
1149
1150 C<a{n,}?> means: match at least C<n> times, but as few times as
1151 possible
1152
1153 =item *
1154
1155 C<a{n}?> means: match exactly C<n> times.  Because we match exactly
1156 C<n> times, C<a{n}?> is equivalent to C<a{n}> and is just there for
1157 notational consistency.
1158
1159 =back
1160
1161 Let's look at the example above, but with minimal quantifiers:
1162
1163     $x = "The programming republic of Perl";
1164     $x =~ /^(.+?)(e|r)(.*)$/; # matches,
1165                               # $1 = 'Th'
1166                               # $2 = 'e'
1167                               # $3 = ' programming republic of Perl'
1168
1169 The minimal string that will allow both the start of the string C<^>
1170 and the alternation to match is C<Th>, with the alternation C<e|r>
1171 matching C<e>.  The second quantifier C<.*> is free to gobble up the
1172 rest of the string.
1173
1174     $x =~ /(m{1,2}?)(.*?)$/;  # matches,
1175                               # $1 = 'm'
1176                               # $2 = 'ming republic of Perl'
1177
1178 The first string position that this regexp can match is at the first
1179 C<'m'> in C<programming>. At this position, the minimal C<m{1,2}?>
1180 matches just one C<'m'>.  Although the second quantifier C<.*?> would
1181 prefer to match no characters, it is constrained by the end-of-string
1182 anchor C<$> to match the rest of the string.
1183
1184     $x =~ /(.*?)(m{1,2}?)(.*)$/;  # matches,
1185                                   # $1 = 'The progra'
1186                                   # $2 = 'm'
1187                                   # $3 = 'ming republic of Perl'
1188
1189 In this regexp, you might expect the first minimal quantifier C<.*?>
1190 to match the empty string, because it is not constrained by a C<^>
1191 anchor to match the beginning of the word.  Principle 0 applies here,
1192 however.  Because it is possible for the whole regexp to match at the
1193 start of the string, it I<will> match at the start of the string.  Thus
1194 the first quantifier has to match everything up to the first C<m>.  The
1195 second minimal quantifier matches just one C<m> and the third
1196 quantifier matches the rest of the string.
1197
1198     $x =~ /(.??)(m{1,2})(.*)$/;  # matches,
1199                                  # $1 = 'a'
1200                                  # $2 = 'mm'
1201                                  # $3 = 'ing republic of Perl'
1202
1203 Just as in the previous regexp, the first quantifier C<.??> can match
1204 earliest at position C<'a'>, so it does.  The second quantifier is
1205 greedy, so it matches C<mm>, and the third matches the rest of the
1206 string.
1207
1208 We can modify principle 3 above to take into account non-greedy
1209 quantifiers:
1210
1211 =over 4
1212
1213 =item *
1214
1215 Principle 3: If there are two or more elements in a regexp, the
1216 leftmost greedy (non-greedy) quantifier, if any, will match as much
1217 (little) of the string as possible while still allowing the whole
1218 regexp to match.  The next leftmost greedy (non-greedy) quantifier, if
1219 any, will try to match as much (little) of the string remaining
1220 available to it as possible, while still allowing the whole regexp to
1221 match.  And so on, until all the regexp elements are satisfied.
1222
1223 =back
1224
1225 Just like alternation, quantifiers are also susceptible to
1226 backtracking.  Here is a step-by-step analysis of the example
1227
1228     $x = "the cat in the hat";
1229     $x =~ /^(.*)(at)(.*)$/; # matches,
1230                             # $1 = 'the cat in the h'
1231                             # $2 = 'at'
1232                             # $3 = ''   (0 matches)
1233
1234 =over 4
1235
1236 =item 0
1237
1238 Start with the first letter in the string 't'.
1239
1240 =item 1
1241
1242 The first quantifier '.*' starts out by matching the whole
1243 string 'the cat in the hat'.
1244
1245 =item 2
1246
1247 'a' in the regexp element 'at' doesn't match the end of the
1248 string.  Backtrack one character.
1249
1250 =item 3
1251
1252 'a' in the regexp element 'at' still doesn't match the last
1253 letter of the string 't', so backtrack one more character.
1254
1255 =item 4
1256
1257 Now we can match the 'a' and the 't'.
1258
1259 =item 5
1260
1261 Move on to the third element '.*'.  Since we are at the end of
1262 the string and '.*' can match 0 times, assign it the empty string.
1263
1264 =item 6
1265
1266 We are done!
1267
1268 =back
1269
1270 Most of the time, all this moving forward and backtracking happens
1271 quickly and searching is fast. There are some pathological regexps,
1272 however, whose execution time exponentially grows with the size of the
1273 string.  A typical structure that blows up in your face is of the form
1274
1275     /(a|b+)*/;
1276
1277 The problem is the nested indeterminate quantifiers.  There are many
1278 different ways of partitioning a string of length n between the C<+>
1279 and C<*>: one repetition with C<b+> of length n, two repetitions with
1280 the first C<b+> length k and the second with length n-k, m repetitions
1281 whose bits add up to length n, etc.  In fact there are an exponential
1282 number of ways to partition a string as a function of its length.  A
1283 regexp may get lucky and match early in the process, but if there is
1284 no match, Perl will try I<every> possibility before giving up.  So be
1285 careful with nested C<*>'s, C<{n,m}>'s, and C<+>'s.  The book
1286 I<Mastering Regular Expressions> by Jeffrey Friedl gives a wonderful
1287 discussion of this and other efficiency issues.
1288
1289
1290 =head2 Possessive quantifiers
1291
1292 Backtracking during the relentless search for a match may be a waste
1293 of time, particularly when the match is bound to fail.  Consider
1294 the simple pattern
1295
1296     /^\w+\s+\w+$/; # a word, spaces, a word
1297
1298 Whenever this is applied to a string which doesn't quite meet the
1299 pattern's expectations such as S<C<"abc  ">> or S<C<"abc  def ">>,
1300 the regex engine will backtrack, approximately once for each character
1301 in the string.  But we know that there is no way around taking I<all>
1302 of the initial word characters to match the first repetition, that I<all>
1303 spaces must be eaten by the middle part, and the same goes for the second
1304 word.
1305
1306 With the introduction of the I<possessive quantifiers> in Perl 5.10, we
1307 have a way of instructing the regex engine not to backtrack, with the
1308 usual quantifiers with a C<+> appended to them.  This makes them greedy as
1309 well as stingy; once they succeed they won't give anything back to permit
1310 another solution. They have the following meanings:
1311
1312 =over 4
1313
1314 =item *
1315
1316 C<a{n,m}+> means: match at least C<n> times, not more than C<m> times,
1317 as many times as possible, and don't give anything up. C<a?+> is short
1318 for C<a{0,1}+>
1319
1320 =item *
1321
1322 C<a{n,}+> means: match at least C<n> times, but as many times as possible,
1323 and don't give anything up. C<a*+> is short for C<a{0,}+> and C<a++> is
1324 short for C<a{1,}+>.
1325
1326 =item *
1327
1328 C<a{n}+> means: match exactly C<n> times.  It is just there for
1329 notational consistency.
1330
1331 =back
1332
1333 These possessive quantifiers represent a special case of a more general
1334 concept, the I<independent subexpression>, see below.
1335
1336 As an example where a possessive quantifier is suitable we consider
1337 matching a quoted string, as it appears in several programming languages.
1338 The backslash is used as an escape character that indicates that the
1339 next character is to be taken literally, as another character for the
1340 string.  Therefore, after the opening quote, we expect a (possibly
1341 empty) sequence of alternatives: either some character except an
1342 unescaped quote or backslash or an escaped character.
1343
1344     /"(?:[^"\\]++|\\.)*+"/;
1345
1346
1347 =head2 Building a regexp
1348
1349 At this point, we have all the basic regexp concepts covered, so let's
1350 give a more involved example of a regular expression.  We will build a
1351 regexp that matches numbers.
1352
1353 The first task in building a regexp is to decide what we want to match
1354 and what we want to exclude.  In our case, we want to match both
1355 integers and floating point numbers and we want to reject any string
1356 that isn't a number.
1357
1358 The next task is to break the problem down into smaller problems that
1359 are easily converted into a regexp.
1360
1361 The simplest case is integers.  These consist of a sequence of digits,
1362 with an optional sign in front.  The digits we can represent with
1363 C<\d+> and the sign can be matched with C<[+-]>.  Thus the integer
1364 regexp is
1365
1366     /[+-]?\d+/;  # matches integers
1367
1368 A floating point number potentially has a sign, an integral part, a
1369 decimal point, a fractional part, and an exponent.  One or more of these
1370 parts is optional, so we need to check out the different
1371 possibilities.  Floating point numbers which are in proper form include
1372 123., 0.345, .34, -1e6, and 25.4E-72.  As with integers, the sign out
1373 front is completely optional and can be matched by C<[+-]?>.  We can
1374 see that if there is no exponent, floating point numbers must have a
1375 decimal point, otherwise they are integers.  We might be tempted to
1376 model these with C<\d*\.\d*>, but this would also match just a single
1377 decimal point, which is not a number.  So the three cases of floating
1378 point number without exponent are
1379
1380    /[+-]?\d+\./;  # 1., 321., etc.
1381    /[+-]?\.\d+/;  # .1, .234, etc.
1382    /[+-]?\d+\.\d+/;  # 1.0, 30.56, etc.
1383
1384 These can be combined into a single regexp with a three-way alternation:
1385
1386    /[+-]?(\d+\.\d+|\d+\.|\.\d+)/;  # floating point, no exponent
1387
1388 In this alternation, it is important to put C<'\d+\.\d+'> before
1389 C<'\d+\.'>.  If C<'\d+\.'> were first, the regexp would happily match that
1390 and ignore the fractional part of the number.
1391
1392 Now consider floating point numbers with exponents.  The key
1393 observation here is that I<both> integers and numbers with decimal
1394 points are allowed in front of an exponent.  Then exponents, like the
1395 overall sign, are independent of whether we are matching numbers with
1396 or without decimal points, and can be 'decoupled' from the
1397 mantissa.  The overall form of the regexp now becomes clear:
1398
1399     /^(optional sign)(integer | f.p. mantissa)(optional exponent)$/;
1400
1401 The exponent is an C<e> or C<E>, followed by an integer.  So the
1402 exponent regexp is
1403
1404    /[eE][+-]?\d+/;  # exponent
1405
1406 Putting all the parts together, we get a regexp that matches numbers:
1407
1408    /^[+-]?(\d+\.\d+|\d+\.|\.\d+|\d+)([eE][+-]?\d+)?$/;  # Ta da!
1409
1410 Long regexps like this may impress your friends, but can be hard to
1411 decipher.  In complex situations like this, the C<//x> modifier for a
1412 match is invaluable.  It allows one to put nearly arbitrary whitespace
1413 and comments into a regexp without affecting their meaning.  Using it,
1414 we can rewrite our 'extended' regexp in the more pleasing form
1415
1416    /^
1417       [+-]?         # first, match an optional sign
1418       (             # then match integers or f.p. mantissas:
1419           \d+\.\d+  # mantissa of the form a.b
1420          |\d+\.     # mantissa of the form a.
1421          |\.\d+     # mantissa of the form .b
1422          |\d+       # integer of the form a
1423       )
1424       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1425    $/x;
1426
1427 If whitespace is mostly irrelevant, how does one include space
1428 characters in an extended regexp? The answer is to backslash it
1429 S<C<'\ '>> or put it in a character class S<C<[ ]>>.  The same thing
1430 goes for pound signs: use C<\#> or C<[#]>.  For instance, Perl allows
1431 a space between the sign and the mantissa or integer, and we could add
1432 this to our regexp as follows:
1433
1434    /^
1435       [+-]?\ *      # first, match an optional sign *and space*
1436       (             # then match integers or f.p. mantissas:
1437           \d+\.\d+  # mantissa of the form a.b
1438          |\d+\.     # mantissa of the form a.
1439          |\.\d+     # mantissa of the form .b
1440          |\d+       # integer of the form a
1441       )
1442       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1443    $/x;
1444
1445 In this form, it is easier to see a way to simplify the
1446 alternation.  Alternatives 1, 2, and 4 all start with C<\d+>, so it
1447 could be factored out:
1448
1449    /^
1450       [+-]?\ *      # first, match an optional sign
1451       (             # then match integers or f.p. mantissas:
1452           \d+       # start out with a ...
1453           (
1454               \.\d* # mantissa of the form a.b or a.
1455           )?        # ? takes care of integers of the form a
1456          |\.\d+     # mantissa of the form .b
1457       )
1458       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1459    $/x;
1460
1461 or written in the compact form,
1462
1463     /^[+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?$/;
1464
1465 This is our final regexp.  To recap, we built a regexp by
1466
1467 =over 4
1468
1469 =item *
1470
1471 specifying the task in detail,
1472
1473 =item *
1474
1475 breaking down the problem into smaller parts,
1476
1477 =item *
1478
1479 translating the small parts into regexps,
1480
1481 =item *
1482
1483 combining the regexps,
1484
1485 =item *
1486
1487 and optimizing the final combined regexp.
1488
1489 =back
1490
1491 These are also the typical steps involved in writing a computer
1492 program.  This makes perfect sense, because regular expressions are
1493 essentially programs written in a little computer language that specifies
1494 patterns.
1495
1496 =head2 Using regular expressions in Perl
1497
1498 The last topic of Part 1 briefly covers how regexps are used in Perl
1499 programs.  Where do they fit into Perl syntax?
1500
1501 We have already introduced the matching operator in its default
1502 C</regexp/> and arbitrary delimiter C<m!regexp!> forms.  We have used
1503 the binding operator C<=~> and its negation C<!~> to test for string
1504 matches.  Associated with the matching operator, we have discussed the
1505 single line C<//s>, multi-line C<//m>, case-insensitive C<//i> and
1506 extended C<//x> modifiers.  There are a few more things you might
1507 want to know about matching operators.
1508
1509 =head3 Optimizing pattern evaluation
1510
1511 We pointed out earlier that variables in regexps are substituted
1512 before the regexp is evaluated:
1513
1514     $pattern = 'Seuss';
1515     while (<>) {
1516         print if /$pattern/;
1517     }
1518
1519 This will print any lines containing the word C<Seuss>.  It is not as
1520 efficient as it could be, however, because Perl has to re-evaluate
1521 (or compile) C<$pattern> each time through the loop.  If C<$pattern> won't be
1522 changing over the lifetime of the script, we can add the C<//o>
1523 modifier, which directs Perl to only perform variable substitutions
1524 once:
1525
1526     #!/usr/bin/perl
1527     #    Improved simple_grep
1528     $regexp = shift;
1529     while (<>) {
1530         print if /$regexp/o;  # a good deal faster
1531     }
1532
1533
1534 =head3 Prohibiting substitution
1535
1536 If you change C<$pattern> after the first substitution happens, Perl
1537 will ignore it.  If you don't want any substitutions at all, use the
1538 special delimiter C<m''>:
1539
1540     @pattern = ('Seuss');
1541     while (<>) {
1542         print if m'@pattern';  # matches literal '@pattern', not 'Seuss'
1543     }
1544
1545 Similar to strings, C<m''> acts like apostrophes on a regexp; all other
1546 C<m> delimiters act like quotes.  If the regexp evaluates to the empty string,
1547 the regexp in the I<last successful match> is used instead.  So we have
1548
1549     "dog" =~ /d/;  # 'd' matches
1550     "dogbert =~ //;  # this matches the 'd' regexp used before
1551
1552
1553 =head3 Global matching
1554
1555 The final two modifiers C<//g> and C<//c> concern multiple matches.
1556 The modifier C<//g> stands for global matching and allows the
1557 matching operator to match within a string as many times as possible.
1558 In scalar context, successive invocations against a string will have
1559 C<//g> jump from match to match, keeping track of position in the
1560 string as it goes along.  You can get or set the position with the
1561 C<pos()> function.
1562
1563 The use of C<//g> is shown in the following example.  Suppose we have
1564 a string that consists of words separated by spaces.  If we know how
1565 many words there are in advance, we could extract the words using
1566 groupings:
1567
1568     $x = "cat dog house"; # 3 words
1569     $x =~ /^\s*(\w+)\s+(\w+)\s+(\w+)\s*$/; # matches,
1570                                            # $1 = 'cat'
1571                                            # $2 = 'dog'
1572                                            # $3 = 'house'
1573
1574 But what if we had an indeterminate number of words? This is the sort
1575 of task C<//g> was made for.  To extract all words, form the simple
1576 regexp C<(\w+)> and loop over all matches with C</(\w+)/g>:
1577
1578     while ($x =~ /(\w+)/g) {
1579         print "Word is $1, ends at position ", pos $x, "\n";
1580     }
1581
1582 prints
1583
1584     Word is cat, ends at position 3
1585     Word is dog, ends at position 7
1586     Word is house, ends at position 13
1587
1588 A failed match or changing the target string resets the position.  If
1589 you don't want the position reset after failure to match, add the
1590 C<//c>, as in C</regexp/gc>.  The current position in the string is
1591 associated with the string, not the regexp.  This means that different
1592 strings have different positions and their respective positions can be
1593 set or read independently.
1594
1595 In list context, C<//g> returns a list of matched groupings, or if
1596 there are no groupings, a list of matches to the whole regexp.  So if
1597 we wanted just the words, we could use
1598
1599     @words = ($x =~ /(\w+)/g);  # matches,
1600                                 # $word[0] = 'cat'
1601                                 # $word[1] = 'dog'
1602                                 # $word[2] = 'house'
1603
1604 Closely associated with the C<//g> modifier is the C<\G> anchor.  The
1605 C<\G> anchor matches at the point where the previous C<//g> match left
1606 off.  C<\G> allows us to easily do context-sensitive matching:
1607
1608     $metric = 1;  # use metric units
1609     ...
1610     $x = <FILE>;  # read in measurement
1611     $x =~ /^([+-]?\d+)\s*/g;  # get magnitude
1612     $weight = $1;
1613     if ($metric) { # error checking
1614         print "Units error!" unless $x =~ /\Gkg\./g;
1615     }
1616     else {
1617         print "Units error!" unless $x =~ /\Glbs\./g;
1618     }
1619     $x =~ /\G\s+(widget|sprocket)/g;  # continue processing
1620
1621 The combination of C<//g> and C<\G> allows us to process the string a
1622 bit at a time and use arbitrary Perl logic to decide what to do next.
1623 Currently, the C<\G> anchor is only fully supported when used to anchor
1624 to the start of the pattern.
1625
1626 C<\G> is also invaluable in processing fixed-length records with
1627 regexps.  Suppose we have a snippet of coding region DNA, encoded as
1628 base pair letters C<ATCGTTGAAT...> and we want to find all the stop
1629 codons C<TGA>.  In a coding region, codons are 3-letter sequences, so
1630 we can think of the DNA snippet as a sequence of 3-letter records.  The
1631 naive regexp
1632
1633     # expanded, this is "ATC GTT GAA TGC AAA TGA CAT GAC"
1634     $dna = "ATCGTTGAATGCAAATGACATGAC";
1635     $dna =~ /TGA/;
1636
1637 doesn't work; it may match a C<TGA>, but there is no guarantee that
1638 the match is aligned with codon boundaries, e.g., the substring
1639 S<C<GTT GAA>> gives a match.  A better solution is
1640
1641     while ($dna =~ /(\w\w\w)*?TGA/g) {  # note the minimal *?
1642         print "Got a TGA stop codon at position ", pos $dna, "\n";
1643     }
1644
1645 which prints
1646
1647     Got a TGA stop codon at position 18
1648     Got a TGA stop codon at position 23
1649
1650 Position 18 is good, but position 23 is bogus.  What happened?
1651
1652 The answer is that our regexp works well until we get past the last
1653 real match.  Then the regexp will fail to match a synchronized C<TGA>
1654 and start stepping ahead one character position at a time, not what we
1655 want.  The solution is to use C<\G> to anchor the match to the codon
1656 alignment:
1657
1658     while ($dna =~ /\G(\w\w\w)*?TGA/g) {
1659         print "Got a TGA stop codon at position ", pos $dna, "\n";
1660     }
1661
1662 This prints
1663
1664     Got a TGA stop codon at position 18
1665
1666 which is the correct answer.  This example illustrates that it is
1667 important not only to match what is desired, but to reject what is not
1668 desired.
1669
1670 =head3 Search and replace
1671
1672 Regular expressions also play a big role in I<search and replace>
1673 operations in Perl.  Search and replace is accomplished with the
1674 C<s///> operator.  The general form is
1675 C<s/regexp/replacement/modifiers>, with everything we know about
1676 regexps and modifiers applying in this case as well.  The
1677 C<replacement> is a Perl double-quoted string that replaces in the
1678 string whatever is matched with the C<regexp>.  The operator C<=~> is
1679 also used here to associate a string with C<s///>.  If matching
1680 against C<$_>, the S<C<$_ =~>> can be dropped.  If there is a match,
1681 C<s///> returns the number of substitutions made; otherwise it returns
1682 false.  Here are a few examples:
1683
1684     $x = "Time to feed the cat!";
1685     $x =~ s/cat/hacker/;   # $x contains "Time to feed the hacker!"
1686     if ($x =~ s/^(Time.*hacker)!$/$1 now!/) {
1687         $more_insistent = 1;
1688     }
1689     $y = "'quoted words'";
1690     $y =~ s/^'(.*)'$/$1/;  # strip single quotes,
1691                            # $y contains "quoted words"
1692
1693 In the last example, the whole string was matched, but only the part
1694 inside the single quotes was grouped.  With the C<s///> operator, the
1695 matched variables C<$1>, C<$2>, etc. are immediately available for use
1696 in the replacement expression, so we use C<$1> to replace the quoted
1697 string with just what was quoted.  With the global modifier, C<s///g>
1698 will search and replace all occurrences of the regexp in the string:
1699
1700     $x = "I batted 4 for 4";
1701     $x =~ s/4/four/;   # doesn't do it all:
1702                        # $x contains "I batted four for 4"
1703     $x = "I batted 4 for 4";
1704     $x =~ s/4/four/g;  # does it all:
1705                        # $x contains "I batted four for four"
1706
1707 If you prefer 'regex' over 'regexp' in this tutorial, you could use
1708 the following program to replace it:
1709
1710     % cat > simple_replace
1711     #!/usr/bin/perl
1712     $regexp = shift;
1713     $replacement = shift;
1714     while (<>) {
1715         s/$regexp/$replacement/go;
1716         print;
1717     }
1718     ^D
1719
1720     % simple_replace regexp regex perlretut.pod
1721
1722 In C<simple_replace> we used the C<s///g> modifier to replace all
1723 occurrences of the regexp on each line and the C<s///o> modifier to
1724 compile the regexp only once.  As with C<simple_grep>, both the
1725 C<print> and the C<s/$regexp/$replacement/go> use C<$_> implicitly.
1726
1727 If you don't want C<s///> to change your original variable you can use
1728 the non-destructive substitute modifier, C<s///r>.  This changes the
1729 behavior so that C<s///r> returns the final substituted string
1730 (instead of the number of substitutions):
1731
1732     $x = "I like dogs.";
1733     $y = $x =~ s/dogs/cats/r;
1734     print "$x $y\n";
1735
1736 That example will print "I like dogs. I like cats". Notice the original
1737 C<$x> variable has not been affected. The overall
1738 result of the substitution is instead stored in C<$y>. If the
1739 substitution doesn't affect anything then the original string is
1740 returned:
1741
1742     $x = "I like dogs.";
1743     $y = $x =~ s/elephants/cougars/r;
1744     print "$x $y\n"; # prints "I like dogs. I like dogs."
1745
1746 One other interesting thing that the C<s///r> flag allows is chaining
1747 substitutions:
1748
1749     $x = "Cats are great.";
1750     print $x =~ s/Cats/Dogs/r =~ s/Dogs/Frogs/r =~ s/Frogs/Hedgehogs/r, "\n";
1751     # prints "Hedgehogs are great."
1752
1753 A modifier available specifically to search and replace is the
1754 C<s///e> evaluation modifier.  C<s///e> treats the
1755 replacement text as Perl code, rather than a double-quoted
1756 string.  The value that the code returns is substituted for the
1757 matched substring.  C<s///e> is useful if you need to do a bit of
1758 computation in the process of replacing text.  This example counts
1759 character frequencies in a line:
1760
1761     $x = "Bill the cat";
1762     $x =~ s/(.)/$chars{$1}++;$1/eg;  # final $1 replaces char with itself
1763     print "frequency of '$_' is $chars{$_}\n"
1764         foreach (sort {$chars{$b} <=> $chars{$a}} keys %chars);
1765
1766 This prints
1767
1768     frequency of ' ' is 2
1769     frequency of 't' is 2
1770     frequency of 'l' is 2
1771     frequency of 'B' is 1
1772     frequency of 'c' is 1
1773     frequency of 'e' is 1
1774     frequency of 'h' is 1
1775     frequency of 'i' is 1
1776     frequency of 'a' is 1
1777
1778 As with the match C<m//> operator, C<s///> can use other delimiters,
1779 such as C<s!!!> and C<s{}{}>, and even C<s{}//>.  If single quotes are
1780 used C<s'''>, then the regexp and replacement are
1781 treated as single-quoted strings and there are no
1782 variable substitutions.  C<s///> in list context
1783 returns the same thing as in scalar context, i.e., the number of
1784 matches.
1785
1786 =head3 The split function
1787
1788 The C<split()> function is another place where a regexp is used.
1789 C<split /regexp/, string, limit> separates the C<string> operand into
1790 a list of substrings and returns that list.  The regexp must be designed
1791 to match whatever constitutes the separators for the desired substrings.
1792 The C<limit>, if present, constrains splitting into no more than C<limit>
1793 number of strings.  For example, to split a string into words, use
1794
1795     $x = "Calvin and Hobbes";
1796     @words = split /\s+/, $x;  # $word[0] = 'Calvin'
1797                                # $word[1] = 'and'
1798                                # $word[2] = 'Hobbes'
1799
1800 If the empty regexp C<//> is used, the regexp always matches and
1801 the string is split into individual characters.  If the regexp has
1802 groupings, then the resulting list contains the matched substrings from the
1803 groupings as well.  For instance,
1804
1805     $x = "/usr/bin/perl";
1806     @dirs = split m!/!, $x;  # $dirs[0] = ''
1807                              # $dirs[1] = 'usr'
1808                              # $dirs[2] = 'bin'
1809                              # $dirs[3] = 'perl'
1810     @parts = split m!(/)!, $x;  # $parts[0] = ''
1811                                 # $parts[1] = '/'
1812                                 # $parts[2] = 'usr'
1813                                 # $parts[3] = '/'
1814                                 # $parts[4] = 'bin'
1815                                 # $parts[5] = '/'
1816                                 # $parts[6] = 'perl'
1817
1818 Since the first character of $x matched the regexp, C<split> prepended
1819 an empty initial element to the list.
1820
1821 If you have read this far, congratulations! You now have all the basic
1822 tools needed to use regular expressions to solve a wide range of text
1823 processing problems.  If this is your first time through the tutorial,
1824 why not stop here and play around with regexps a while....  S<Part 2>
1825 concerns the more esoteric aspects of regular expressions and those
1826 concepts certainly aren't needed right at the start.
1827
1828 =head1 Part 2: Power tools
1829
1830 OK, you know the basics of regexps and you want to know more.  If
1831 matching regular expressions is analogous to a walk in the woods, then
1832 the tools discussed in Part 1 are analogous to topo maps and a
1833 compass, basic tools we use all the time.  Most of the tools in part 2
1834 are analogous to flare guns and satellite phones.  They aren't used
1835 too often on a hike, but when we are stuck, they can be invaluable.
1836
1837 What follows are the more advanced, less used, or sometimes esoteric
1838 capabilities of Perl regexps.  In Part 2, we will assume you are
1839 comfortable with the basics and concentrate on the advanced features.
1840
1841 =head2 More on characters, strings, and character classes
1842
1843 There are a number of escape sequences and character classes that we
1844 haven't covered yet.
1845
1846 There are several escape sequences that convert characters or strings
1847 between upper and lower case, and they are also available within
1848 patterns.  C<\l> and C<\u> convert the next character to lower or
1849 upper case, respectively:
1850
1851     $x = "perl";
1852     $string =~ /\u$x/;  # matches 'Perl' in $string
1853     $x = "M(rs?|s)\\."; # note the double backslash
1854     $string =~ /\l$x/;  # matches 'mr.', 'mrs.', and 'ms.',
1855
1856 A C<\L> or C<\U> indicates a lasting conversion of case, until
1857 terminated by C<\E> or thrown over by another C<\U> or C<\L>:
1858
1859     $x = "This word is in lower case:\L SHOUT\E";
1860     $x =~ /shout/;       # matches
1861     $x = "I STILL KEYPUNCH CARDS FOR MY 360"
1862     $x =~ /\Ukeypunch/;  # matches punch card string
1863
1864 If there is no C<\E>, case is converted until the end of the
1865 string. The regexps C<\L\u$word> or C<\u\L$word> convert the first
1866 character of C<$word> to uppercase and the rest of the characters to
1867 lowercase.
1868
1869 Control characters can be escaped with C<\c>, so that a control-Z
1870 character would be matched with C<\cZ>.  The escape sequence
1871 C<\Q>...C<\E> quotes, or protects most non-alphabetic characters.   For
1872 instance,
1873
1874     $x = "\QThat !^*&%~& cat!";
1875     $x =~ /\Q!^*&%~&\E/;  # check for rough language
1876
1877 It does not protect C<$> or C<@>, so that variables can still be
1878 substituted.
1879
1880 C<\Q>, C<\L>, C<\l>, C<\U>, C<\u> and C<\E> are actually part of
1881 double-quotish syntax, and not part of regexp syntax proper.  They will
1882 work if they appear in a regular expression embeddded directly in a
1883 program, but not when contained in a string that is interpolated in a
1884 pattern.
1885
1886 With the advent of 5.6.0, Perl regexps can handle more than just the
1887 standard ASCII character set.  Perl now supports I<Unicode>, a standard
1888 for representing the alphabets from virtually all of the world's written
1889 languages, and a host of symbols.  Perl's text strings are Unicode strings, so
1890 they can contain characters with a value (codepoint or character number) higher
1891 than 255.
1892
1893 What does this mean for regexps? Well, regexp users don't need to know
1894 much about Perl's internal representation of strings.  But they do need
1895 to know 1) how to represent Unicode characters in a regexp and 2) that
1896 a matching operation will treat the string to be searched as a sequence
1897 of characters, not bytes.  The answer to 1) is that Unicode characters
1898 greater than C<chr(255)> are represented using the C<\x{hex}> notation, because
1899 \x hex (without curly braces) doesn't go further than 255.  Starting in Perl
1900 5.14, if you're an octal fan, you can also use C<\o{oct}>.
1901
1902     /\x{263a}/;  # match a Unicode smiley face :)
1903
1904 B<NOTE>: In Perl 5.6.0 it used to be that one needed to say C<use
1905 utf8> to use any Unicode features.  This is no more the case: for
1906 almost all Unicode processing, the explicit C<utf8> pragma is not
1907 needed.  (The only case where it matters is if your Perl script is in
1908 Unicode and encoded in UTF-8, then an explicit C<use utf8> is needed.)
1909
1910 Figuring out the hexadecimal sequence of a Unicode character you want
1911 or deciphering someone else's hexadecimal Unicode regexp is about as
1912 much fun as programming in machine code.  So another way to specify
1913 Unicode characters is to use the I<named character> escape
1914 sequence C<\N{I<name>}>.  I<name> is a name for the Unicode character, as
1915 specified in the Unicode standard.  For instance, if we wanted to
1916 represent or match the astrological sign for the planet Mercury, we
1917 could use
1918
1919     use charnames ":full"; # use named chars with Unicode full names
1920     $x = "abc\N{MERCURY}def";
1921     $x =~ /\N{MERCURY}/;   # matches
1922
1923 One can also use short names or restrict names to a certain alphabet:
1924
1925     use charnames ':full';
1926     print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
1927
1928     use charnames ":short";
1929     print "\N{greek:Sigma} is an upper-case sigma.\n";
1930
1931     use charnames qw(greek);
1932     print "\N{sigma} is Greek sigma\n";
1933
1934 A list of full names can be found in F<NamesList.txt> in the Unicode standard
1935 (available at L<http://www.unicode.org/Public/UNIDATA/>).
1936
1937 The answer to requirement 2), as of 5.6.0, is that a regexp uses Unicode
1938 characters. Internally, this is encoded to bytes using either UTF-8 or a
1939 native 8 bit encoding, depending on the history of the string, but
1940 conceptually it is a sequence of characters, not bytes. See
1941 L<perlunitut> for a tutorial about that.
1942
1943 Let us now discuss Unicode character classes.  Just as with Unicode
1944 characters, there are named Unicode character classes represented by the
1945 C<\p{name}> escape sequence.  Closely associated is the C<\P{name}>
1946 character class, which is the negation of the C<\p{name}> class.  For
1947 example, to match lower and uppercase characters,
1948
1949     use charnames ":full"; # use named chars with Unicode full names
1950     $x = "BOB";
1951     $x =~ /^\p{IsUpper}/;   # matches, uppercase char class
1952     $x =~ /^\P{IsUpper}/;   # doesn't match, char class sans uppercase
1953     $x =~ /^\p{IsLower}/;   # doesn't match, lowercase char class
1954     $x =~ /^\P{IsLower}/;   # matches, char class sans lowercase
1955
1956 Here is the association between some Perl named classes and the
1957 traditional Unicode classes:
1958
1959     Perl class name  Unicode class name or regular expression
1960
1961     IsAlpha          /^[LM]/
1962     IsAlnum          /^[LMN]/
1963     IsASCII          $code <= 127
1964     IsCntrl          /^C/
1965     IsBlank          $code =~ /^(0020|0009)$/ || /^Z[^lp]/
1966     IsDigit          Nd
1967     IsGraph          /^([LMNPS]|Co)/
1968     IsLower          Ll
1969     IsPrint          /^([LMNPS]|Co|Zs)/
1970     IsPunct          /^P/
1971     IsSpace          /^Z/ || ($code =~ /^(0009|000A|000B|000C|000D)$/
1972     IsSpacePerl      /^Z/ || ($code =~ /^(0009|000A|000C|000D|0085|2028|2029)$/
1973     IsUpper          /^L[ut]/
1974     IsWord           /^[LMN]/ || $code eq "005F"
1975     IsXDigit         $code =~ /^00(3[0-9]|[46][1-6])$/
1976
1977 You can also use the official Unicode class names with C<\p> and
1978 C<\P>, like C<\p{L}> for Unicode 'letters', C<\p{Lu}> for uppercase
1979 letters, or C<\P{Nd}> for non-digits.  If a C<name> is just one
1980 letter, the braces can be dropped.  For instance, C<\pM> is the
1981 character class of Unicode 'marks', for example accent marks.
1982 For the full list see L<perlunicode>.
1983
1984 Unicode has also been separated into various sets of characters
1985 which you can test with C<\p{...}> (in) and C<\P{...}> (not in).
1986 To test whether a character is (or is not) an element of a script
1987 you would use the script name, for example C<\p{Latin}>, C<\p{Greek}>,
1988 or C<\P{Katakana}>. Other sets are the Unicode blocks, the names
1989 of which begin with "In". One such block is dedicated to mathematical
1990 operators, and its pattern formula is <C\p{InMathematicalOperators>}>.
1991 For the full list see L<perluniprops>.
1992
1993 What we have described so far is the single form of the C<\p{...}> character
1994 classes.  There is also a compound form which you may run into.  These
1995 look like C<\p{name=value}> or C<\p{name:value}> (the equals sign and colon
1996 can be used interchangeably).  These are more general than the single form,
1997 and in fact most of the single forms are just Perl-defined shortcuts for common
1998 compound forms.  For example, the script examples in the previous paragraph
1999 could be written equivalently as C<\p{Script=Latin}>, C<\p{Script:Greek}>, and
2000 C<\P{script=katakana}> (case is irrelevant between the C<{}> braces).  You may
2001 never have to use the compound forms, but sometimes it is necessary, and their
2002 use can make your code easier to understand.
2003
2004 C<\X> is an abbreviation for a character class that comprises
2005 a Unicode I<extended grapheme cluster>.  This represents a "logical character",
2006 what appears to be a single character, but may be represented internally by more
2007 than one.  As an example, using the Unicode full names, e.g., S<C<A + COMBINING
2008 RING>> is a grapheme cluster with base character C<A> and combining character
2009 S<C<COMBINING RING>>, which translates in Danish to A with the circle atop it,
2010 as in the word Angstrom.
2011
2012 For the full and latest information about Unicode see the latest
2013 Unicode standard, or the Unicode Consortium's website L<http://www.unicode.org>
2014
2015 As if all those classes weren't enough, Perl also defines POSIX-style
2016 character classes.  These have the form C<[:name:]>, with C<name> the
2017 name of the POSIX class.  The POSIX classes are C<alpha>, C<alnum>,
2018 C<ascii>, C<cntrl>, C<digit>, C<graph>, C<lower>, C<print>, C<punct>,
2019 C<space>, C<upper>, and C<xdigit>, and two extensions, C<word> (a Perl
2020 extension to match C<\w>), and C<blank> (a GNU extension).  If
2021 Unicode is enabled (see C<perlunicode/The "Unicode Bug">),
2022 then these classes are defined the same as their
2023 corresponding Perl Unicode classes: C<[:upper:]> is the same as
2024 C<\p{IsUpper}>, etc.  The C<[:digit:]>, C<[:word:]>, and
2025 C<[:space:]> correspond to the familiar C<\d>, C<\w>, and C<\s>
2026 character classes.  To negate a POSIX class, put a C<^> in front of
2027 the name, so that, e.g., C<[:^digit:]> corresponds to C<\D> and, under
2028 Unicode, C<\P{IsDigit}>.  The Unicode and POSIX character classes can
2029 be used just like C<\d>, with the exception that POSIX character
2030 classes can only be used inside of a character class:
2031
2032     /\s+[abc[:digit:]xyz]\s*/;  # match a,b,c,x,y,z, or a digit
2033     /^=item\s[[:digit:]]/;      # match '=item',
2034                                 # followed by a space and a digit
2035     /\s+[abc\p{IsDigit}xyz]\s+/;  # match a,b,c,x,y,z, or a digit
2036     /^=item\s\p{IsDigit}/;        # match '=item',
2037                                   # followed by a space and a digit
2038
2039 Whew! That is all the rest of the characters and character classes.
2040
2041 =head2 Compiling and saving regular expressions
2042
2043 In Part 1 we discussed the C<//o> modifier, which compiles a regexp
2044 just once.  This suggests that a compiled regexp is some data structure
2045 that can be stored once and used again and again.  The regexp quote
2046 C<qr//> does exactly that: C<qr/string/> compiles the C<string> as a
2047 regexp and transforms the result into a form that can be assigned to a
2048 variable:
2049
2050     $reg = qr/foo+bar?/;  # reg contains a compiled regexp
2051
2052 Then C<$reg> can be used as a regexp:
2053
2054     $x = "fooooba";
2055     $x =~ $reg;     # matches, just like /foo+bar?/
2056     $x =~ /$reg/;   # same thing, alternate form
2057
2058 C<$reg> can also be interpolated into a larger regexp:
2059
2060     $x =~ /(abc)?$reg/;  # still matches
2061
2062 As with the matching operator, the regexp quote can use different
2063 delimiters, e.g., C<qr!!>, C<qr{}> or C<qr~~>.  Apostrophes
2064 as delimiters (C<qr''>) inhibit any interpolation.
2065
2066 Pre-compiled regexps are useful for creating dynamic matches that
2067 don't need to be recompiled each time they are encountered.  Using
2068 pre-compiled regexps, we write a C<grep_step> program which greps
2069 for a sequence of patterns, advancing to the next pattern as soon
2070 as one has been satisfied.
2071
2072     % cat > grep_step
2073     #!/usr/bin/perl
2074     # grep_step - match <number> regexps, one after the other
2075     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2076
2077     $number = shift;
2078     $regexp[$_] = shift foreach (0..$number-1);
2079     @compiled = map qr/$_/, @regexp;
2080     while ($line = <>) {
2081         if ($line =~ /$compiled[0]/) {
2082             print $line;
2083             shift @compiled;
2084             last unless @compiled;
2085         }
2086     }
2087     ^D
2088
2089     % grep_step 3 shift print last grep_step
2090     $number = shift;
2091             print $line;
2092             last unless @compiled;
2093
2094 Storing pre-compiled regexps in an array C<@compiled> allows us to
2095 simply loop through the regexps without any recompilation, thus gaining
2096 flexibility without sacrificing speed.
2097
2098
2099 =head2 Composing regular expressions at runtime
2100
2101 Backtracking is more efficient than repeated tries with different regular
2102 expressions.  If there are several regular expressions and a match with
2103 any of them is acceptable, then it is possible to combine them into a set
2104 of alternatives.  If the individual expressions are input data, this
2105 can be done by programming a join operation.  We'll exploit this idea in
2106 an improved version of the C<simple_grep> program: a program that matches
2107 multiple patterns:
2108
2109     % cat > multi_grep
2110     #!/usr/bin/perl
2111     # multi_grep - match any of <number> regexps
2112     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2113
2114     $number = shift;
2115     $regexp[$_] = shift foreach (0..$number-1);
2116     $pattern = join '|', @regexp;
2117
2118     while ($line = <>) {
2119         print $line if $line =~ /$pattern/o;
2120     }
2121     ^D
2122
2123     % multi_grep 2 shift for multi_grep
2124     $number = shift;
2125     $regexp[$_] = shift foreach (0..$number-1);
2126
2127 Sometimes it is advantageous to construct a pattern from the I<input>
2128 that is to be analyzed and use the permissible values on the left
2129 hand side of the matching operations.  As an example for this somewhat
2130 paradoxical situation, let's assume that our input contains a command
2131 verb which should match one out of a set of available command verbs,
2132 with the additional twist that commands may be abbreviated as long as
2133 the given string is unique. The program below demonstrates the basic
2134 algorithm.
2135
2136     % cat > keymatch
2137     #!/usr/bin/perl
2138     $kwds = 'copy compare list print';
2139     while( $command = <> ){
2140         $command =~ s/^\s+|\s+$//g;  # trim leading and trailing spaces
2141         if( ( @matches = $kwds =~ /\b$command\w*/g ) == 1 ){
2142             print "command: '@matches'\n";
2143         } elsif( @matches == 0 ){
2144             print "no such command: '$command'\n";
2145         } else {
2146             print "not unique: '$command' (could be one of: @matches)\n";
2147         }
2148     }
2149     ^D
2150
2151     % keymatch
2152     li
2153     command: 'list'
2154     co
2155     not unique: 'co' (could be one of: copy compare)
2156     printer
2157     no such command: 'printer'
2158
2159 Rather than trying to match the input against the keywords, we match the
2160 combined set of keywords against the input.  The pattern matching
2161 operation S<C<$kwds =~ /\b($command\w*)/g>> does several things at the
2162 same time. It makes sure that the given command begins where a keyword
2163 begins (C<\b>). It tolerates abbreviations due to the added C<\w*>. It
2164 tells us the number of matches (C<scalar @matches>) and all the keywords
2165 that were actually matched.  You could hardly ask for more.
2166
2167 =head2 Embedding comments and modifiers in a regular expression
2168
2169 Starting with this section, we will be discussing Perl's set of
2170 I<extended patterns>.  These are extensions to the traditional regular
2171 expression syntax that provide powerful new tools for pattern
2172 matching.  We have already seen extensions in the form of the minimal
2173 matching constructs C<??>, C<*?>, C<+?>, C<{n,m}?>, and C<{n,}?>.  Most
2174 of the extensions below have the form C<(?char...)>, where the
2175 C<char> is a character that determines the type of extension.
2176
2177 The first extension is an embedded comment C<(?#text)>.  This embeds a
2178 comment into the regular expression without affecting its meaning.  The
2179 comment should not have any closing parentheses in the text.  An
2180 example is
2181
2182     /(?# Match an integer:)[+-]?\d+/;
2183
2184 This style of commenting has been largely superseded by the raw,
2185 freeform commenting that is allowed with the C<//x> modifier.
2186
2187 The modifiers C<//i>, C<//m>, C<//s> and C<//x> (or any
2188 combination thereof) can also be embedded in
2189 a regexp using C<(?i)>, C<(?m)>, C<(?s)>, and C<(?x)>.  For instance,
2190
2191     /(?i)yes/;  # match 'yes' case insensitively
2192     /yes/i;     # same thing
2193     /(?x)(          # freeform version of an integer regexp
2194              [+-]?  # match an optional sign
2195              \d+    # match a sequence of digits
2196          )
2197     /x;
2198
2199 Embedded modifiers can have two important advantages over the usual
2200 modifiers.  Embedded modifiers allow a custom set of modifiers to
2201 I<each> regexp pattern.  This is great for matching an array of regexps
2202 that must have different modifiers:
2203
2204     $pattern[0] = '(?i)doctor';
2205     $pattern[1] = 'Johnson';
2206     ...
2207     while (<>) {
2208         foreach $patt (@pattern) {
2209             print if /$patt/;
2210         }
2211     }
2212
2213 The second advantage is that embedded modifiers (except C<//p>, which
2214 modifies the entire regexp) only affect the regexp
2215 inside the group the embedded modifier is contained in.  So grouping
2216 can be used to localize the modifier's effects:
2217
2218     /Answer: ((?i)yes)/;  # matches 'Answer: yes', 'Answer: YES', etc.
2219
2220 Embedded modifiers can also turn off any modifiers already present
2221 by using, e.g., C<(?-i)>.  Modifiers can also be combined into
2222 a single expression, e.g., C<(?s-i)> turns on single line mode and
2223 turns off case insensitivity.
2224
2225 Embedded modifiers may also be added to a non-capturing grouping.
2226 C<(?i-m:regexp)> is a non-capturing grouping that matches C<regexp>
2227 case insensitively and turns off multi-line mode.
2228
2229
2230 =head2 Looking ahead and looking behind
2231
2232 This section concerns the lookahead and lookbehind assertions.  First,
2233 a little background.
2234
2235 In Perl regular expressions, most regexp elements 'eat up' a certain
2236 amount of string when they match.  For instance, the regexp element
2237 C<[abc}]> eats up one character of the string when it matches, in the
2238 sense that Perl moves to the next character position in the string
2239 after the match.  There are some elements, however, that don't eat up
2240 characters (advance the character position) if they match.  The examples
2241 we have seen so far are the anchors.  The anchor C<^> matches the
2242 beginning of the line, but doesn't eat any characters.  Similarly, the
2243 word boundary anchor C<\b> matches wherever a character matching C<\w>
2244 is next to a character that doesn't, but it doesn't eat up any
2245 characters itself.  Anchors are examples of I<zero-width assertions>:
2246 zero-width, because they consume
2247 no characters, and assertions, because they test some property of the
2248 string.  In the context of our walk in the woods analogy to regexp
2249 matching, most regexp elements move us along a trail, but anchors have
2250 us stop a moment and check our surroundings.  If the local environment
2251 checks out, we can proceed forward.  But if the local environment
2252 doesn't satisfy us, we must backtrack.
2253
2254 Checking the environment entails either looking ahead on the trail,
2255 looking behind, or both.  C<^> looks behind, to see that there are no
2256 characters before.  C<$> looks ahead, to see that there are no
2257 characters after.  C<\b> looks both ahead and behind, to see if the
2258 characters on either side differ in their "word-ness".
2259
2260 The lookahead and lookbehind assertions are generalizations of the
2261 anchor concept.  Lookahead and lookbehind are zero-width assertions
2262 that let us specify which characters we want to test for.  The
2263 lookahead assertion is denoted by C<(?=regexp)> and the lookbehind
2264 assertion is denoted by C<< (?<=fixed-regexp) >>.  Some examples are
2265
2266     $x = "I catch the housecat 'Tom-cat' with catnip";
2267     $x =~ /cat(?=\s)/;   # matches 'cat' in 'housecat'
2268     @catwords = ($x =~ /(?<=\s)cat\w+/g);  # matches,
2269                                            # $catwords[0] = 'catch'
2270                                            # $catwords[1] = 'catnip'
2271     $x =~ /\bcat\b/;  # matches 'cat' in 'Tom-cat'
2272     $x =~ /(?<=\s)cat(?=\s)/; # doesn't match; no isolated 'cat' in
2273                               # middle of $x
2274
2275 Note that the parentheses in C<(?=regexp)> and C<< (?<=regexp) >> are
2276 non-capturing, since these are zero-width assertions.  Thus in the
2277 second regexp, the substrings captured are those of the whole regexp
2278 itself.  Lookahead C<(?=regexp)> can match arbitrary regexps, but
2279 lookbehind C<< (?<=fixed-regexp) >> only works for regexps of fixed
2280 width, i.e., a fixed number of characters long.  Thus
2281 C<< (?<=(ab|bc)) >> is fine, but C<< (?<=(ab)*) >> is not.  The
2282 negated versions of the lookahead and lookbehind assertions are
2283 denoted by C<(?!regexp)> and C<< (?<!fixed-regexp) >> respectively.
2284 They evaluate true if the regexps do I<not> match:
2285
2286     $x = "foobar";
2287     $x =~ /foo(?!bar)/;  # doesn't match, 'bar' follows 'foo'
2288     $x =~ /foo(?!baz)/;  # matches, 'baz' doesn't follow 'foo'
2289     $x =~ /(?<!\s)foo/;  # matches, there is no \s before 'foo'
2290
2291 The C<\C> is unsupported in lookbehind, because the already
2292 treacherous definition of C<\C> would become even more so
2293 when going backwards.
2294
2295 Here is an example where a string containing blank-separated words,
2296 numbers and single dashes is to be split into its components.
2297 Using C</\s+/> alone won't work, because spaces are not required between
2298 dashes, or a word or a dash. Additional places for a split are established
2299 by looking ahead and behind:
2300
2301     $str = "one two - --6-8";
2302     @toks = split / \s+              # a run of spaces
2303                   | (?<=\S) (?=-)    # any non-space followed by '-'
2304                   | (?<=-)  (?=\S)   # a '-' followed by any non-space
2305                   /x, $str;          # @toks = qw(one two - - - 6 - 8)
2306
2307
2308 =head2 Using independent subexpressions to prevent backtracking
2309
2310 I<Independent subexpressions> are regular expressions, in the
2311 context of a larger regular expression, that function independently of
2312 the larger regular expression.  That is, they consume as much or as
2313 little of the string as they wish without regard for the ability of
2314 the larger regexp to match.  Independent subexpressions are represented
2315 by C<< (?>regexp) >>.  We can illustrate their behavior by first
2316 considering an ordinary regexp:
2317
2318     $x = "ab";
2319     $x =~ /a*ab/;  # matches
2320
2321 This obviously matches, but in the process of matching, the
2322 subexpression C<a*> first grabbed the C<a>.  Doing so, however,
2323 wouldn't allow the whole regexp to match, so after backtracking, C<a*>
2324 eventually gave back the C<a> and matched the empty string.  Here, what
2325 C<a*> matched was I<dependent> on what the rest of the regexp matched.
2326
2327 Contrast that with an independent subexpression:
2328
2329     $x =~ /(?>a*)ab/;  # doesn't match!
2330
2331 The independent subexpression C<< (?>a*) >> doesn't care about the rest
2332 of the regexp, so it sees an C<a> and grabs it.  Then the rest of the
2333 regexp C<ab> cannot match.  Because C<< (?>a*) >> is independent, there
2334 is no backtracking and the independent subexpression does not give
2335 up its C<a>.  Thus the match of the regexp as a whole fails.  A similar
2336 behavior occurs with completely independent regexps:
2337
2338     $x = "ab";
2339     $x =~ /a*/g;   # matches, eats an 'a'
2340     $x =~ /\Gab/g; # doesn't match, no 'a' available
2341
2342 Here C<//g> and C<\G> create a 'tag team' handoff of the string from
2343 one regexp to the other.  Regexps with an independent subexpression are
2344 much like this, with a handoff of the string to the independent
2345 subexpression, and a handoff of the string back to the enclosing
2346 regexp.
2347
2348 The ability of an independent subexpression to prevent backtracking
2349 can be quite useful.  Suppose we want to match a non-empty string
2350 enclosed in parentheses up to two levels deep.  Then the following
2351 regexp matches:
2352
2353     $x = "abc(de(fg)h";  # unbalanced parentheses
2354     $x =~ /\( ( [^()]+ | \([^()]*\) )+ \)/x;
2355
2356 The regexp matches an open parenthesis, one or more copies of an
2357 alternation, and a close parenthesis.  The alternation is two-way, with
2358 the first alternative C<[^()]+> matching a substring with no
2359 parentheses and the second alternative C<\([^()]*\)>  matching a
2360 substring delimited by parentheses.  The problem with this regexp is
2361 that it is pathological: it has nested indeterminate quantifiers
2362 of the form C<(a+|b)+>.  We discussed in Part 1 how nested quantifiers
2363 like this could take an exponentially long time to execute if there
2364 was no match possible.  To prevent the exponential blowup, we need to
2365 prevent useless backtracking at some point.  This can be done by
2366 enclosing the inner quantifier as an independent subexpression:
2367
2368     $x =~ /\( ( (?>[^()]+) | \([^()]*\) )+ \)/x;
2369
2370 Here, C<< (?>[^()]+) >> breaks the degeneracy of string partitioning
2371 by gobbling up as much of the string as possible and keeping it.   Then
2372 match failures fail much more quickly.
2373
2374
2375 =head2 Conditional expressions
2376
2377 A I<conditional expression> is a form of if-then-else statement
2378 that allows one to choose which patterns are to be matched, based on
2379 some condition.  There are two types of conditional expression:
2380 C<(?(condition)yes-regexp)> and
2381 C<(?(condition)yes-regexp|no-regexp)>.  C<(?(condition)yes-regexp)> is
2382 like an S<C<'if () {}'>> statement in Perl.  If the C<condition> is true,
2383 the C<yes-regexp> will be matched.  If the C<condition> is false, the
2384 C<yes-regexp> will be skipped and Perl will move onto the next regexp
2385 element.  The second form is like an S<C<'if () {} else {}'>> statement
2386 in Perl.  If the C<condition> is true, the C<yes-regexp> will be
2387 matched, otherwise the C<no-regexp> will be matched.
2388
2389 The C<condition> can have several forms.  The first form is simply an
2390 integer in parentheses C<(integer)>.  It is true if the corresponding
2391 backreference C<\integer> matched earlier in the regexp.  The same
2392 thing can be done with a name associated with a capture group, written
2393 as C<< (<name>) >> or C<< ('name') >>.  The second form is a bare
2394 zero-width assertion C<(?...)>, either a lookahead, a lookbehind, or a
2395 code assertion (discussed in the next section).  The third set of forms
2396 provides tests that return true if the expression is executed within
2397 a recursion (C<(R)>) or is being called from some capturing group,
2398 referenced either by number (C<(R1)>, C<(R2)>,...) or by name
2399 (C<(R&name)>).
2400
2401 The integer or name form of the C<condition> allows us to choose,
2402 with more flexibility, what to match based on what matched earlier in the
2403 regexp. This searches for words of the form C<"$x$x"> or C<"$x$y$y$x">:
2404
2405     % simple_grep '^(\w+)(\w+)?(?(2)\g2\g1|\g1)$' /usr/dict/words
2406     beriberi
2407     coco
2408     couscous
2409     deed
2410     ...
2411     toot
2412     toto
2413     tutu
2414
2415 The lookbehind C<condition> allows, along with backreferences,
2416 an earlier part of the match to influence a later part of the
2417 match.  For instance,
2418
2419     /[ATGC]+(?(?<=AA)G|C)$/;
2420
2421 matches a DNA sequence such that it either ends in C<AAG>, or some
2422 other base pair combination and C<C>.  Note that the form is
2423 C<< (?(?<=AA)G|C) >> and not C<< (?((?<=AA))G|C) >>; for the
2424 lookahead, lookbehind or code assertions, the parentheses around the
2425 conditional are not needed.
2426
2427
2428 =head2 Defining named patterns
2429
2430 Some regular expressions use identical subpatterns in several places.
2431 Starting with Perl 5.10, it is possible to define named subpatterns in
2432 a section of the pattern so that they can be called up by name
2433 anywhere in the pattern.  This syntactic pattern for this definition
2434 group is C<< (?(DEFINE)(?<name>pattern)...) >>.  An insertion
2435 of a named pattern is written as C<(?&name)>.
2436
2437 The example below illustrates this feature using the pattern for
2438 floating point numbers that was presented earlier on.  The three
2439 subpatterns that are used more than once are the optional sign, the
2440 digit sequence for an integer and the decimal fraction.  The DEFINE
2441 group at the end of the pattern contains their definition.  Notice
2442 that the decimal fraction pattern is the first place where we can
2443 reuse the integer pattern.
2444
2445    /^ (?&osg)\ * ( (?&int)(?&dec)? | (?&dec) )
2446       (?: [eE](?&osg)(?&int) )?
2447     $
2448     (?(DEFINE)
2449       (?<osg>[-+]?)         # optional sign
2450       (?<int>\d++)          # integer
2451       (?<dec>\.(?&int))     # decimal fraction
2452     )/x
2453
2454
2455 =head2 Recursive patterns
2456
2457 This feature (introduced in Perl 5.10) significantly extends the
2458 power of Perl's pattern matching.  By referring to some other
2459 capture group anywhere in the pattern with the construct
2460 C<(?group-ref)>, the I<pattern> within the referenced group is used
2461 as an independent subpattern in place of the group reference itself.
2462 Because the group reference may be contained I<within> the group it
2463 refers to, it is now possible to apply pattern matching to tasks that
2464 hitherto required a recursive parser.
2465
2466 To illustrate this feature, we'll design a pattern that matches if
2467 a string contains a palindrome. (This is a word or a sentence that,
2468 while ignoring spaces, interpunctuation and case, reads the same backwards
2469 as forwards. We begin by observing that the empty string or a string
2470 containing just one word character is a palindrome. Otherwise it must
2471 have a word character up front and the same at its end, with another
2472 palindrome in between.
2473
2474     /(?: (\w) (?...Here be a palindrome...) \g{-1} | \w? )/x
2475
2476 Adding C<\W*> at either end to eliminate what is to be ignored, we already
2477 have the full pattern:
2478
2479     my $pp = qr/^(\W* (?: (\w) (?1) \g{-1} | \w? ) \W*)$/ix;
2480     for $s ( "saippuakauppias", "A man, a plan, a canal: Panama!" ){
2481         print "'$s' is a palindrome\n" if $s =~ /$pp/;
2482     }
2483
2484 In C<(?...)> both absolute and relative backreferences may be used.
2485 The entire pattern can be reinserted with C<(?R)> or C<(?0)>.
2486 If you prefer to name your groups, you can use C<(?&name)> to
2487 recurse into that group.
2488
2489
2490 =head2 A bit of magic: executing Perl code in a regular expression
2491
2492 Normally, regexps are a part of Perl expressions.
2493 I<Code evaluation> expressions turn that around by allowing
2494 arbitrary Perl code to be a part of a regexp.  A code evaluation
2495 expression is denoted C<(?{code})>, with I<code> a string of Perl
2496 statements.
2497
2498 Be warned that this feature is considered experimental, and may be
2499 changed without notice.
2500
2501 Code expressions are zero-width assertions, and the value they return
2502 depends on their environment.  There are two possibilities: either the
2503 code expression is used as a conditional in a conditional expression
2504 C<(?(condition)...)>, or it is not.  If the code expression is a
2505 conditional, the code is evaluated and the result (i.e., the result of
2506 the last statement) is used to determine truth or falsehood.  If the
2507 code expression is not used as a conditional, the assertion always
2508 evaluates true and the result is put into the special variable
2509 C<$^R>.  The variable C<$^R> can then be used in code expressions later
2510 in the regexp.  Here are some silly examples:
2511
2512     $x = "abcdef";
2513     $x =~ /abc(?{print "Hi Mom!";})def/; # matches,
2514                                          # prints 'Hi Mom!'
2515     $x =~ /aaa(?{print "Hi Mom!";})def/; # doesn't match,
2516                                          # no 'Hi Mom!'
2517
2518 Pay careful attention to the next example:
2519
2520     $x =~ /abc(?{print "Hi Mom!";})ddd/; # doesn't match,
2521                                          # no 'Hi Mom!'
2522                                          # but why not?
2523
2524 At first glance, you'd think that it shouldn't print, because obviously
2525 the C<ddd> isn't going to match the target string. But look at this
2526 example:
2527
2528     $x =~ /abc(?{print "Hi Mom!";})[dD]dd/; # doesn't match,
2529                                             # but _does_ print
2530
2531 Hmm. What happened here? If you've been following along, you know that
2532 the above pattern should be effectively (almost) the same as the last one;
2533 enclosing the C<d> in a character class isn't going to change what it
2534 matches. So why does the first not print while the second one does?
2535
2536 The answer lies in the optimizations the regex engine makes. In the first
2537 case, all the engine sees are plain old characters (aside from the
2538 C<?{}> construct). It's smart enough to realize that the string 'ddd'
2539 doesn't occur in our target string before actually running the pattern
2540 through. But in the second case, we've tricked it into thinking that our
2541 pattern is more complicated. It takes a look, sees our
2542 character class, and decides that it will have to actually run the
2543 pattern to determine whether or not it matches, and in the process of
2544 running it hits the print statement before it discovers that we don't
2545 have a match.
2546
2547 To take a closer look at how the engine does optimizations, see the
2548 section L<"Pragmas and debugging"> below.
2549
2550 More fun with C<?{}>:
2551
2552     $x =~ /(?{print "Hi Mom!";})/;       # matches,
2553                                          # prints 'Hi Mom!'
2554     $x =~ /(?{$c = 1;})(?{print "$c";})/;  # matches,
2555                                            # prints '1'
2556     $x =~ /(?{$c = 1;})(?{print "$^R";})/; # matches,
2557                                            # prints '1'
2558
2559 The bit of magic mentioned in the section title occurs when the regexp
2560 backtracks in the process of searching for a match.  If the regexp
2561 backtracks over a code expression and if the variables used within are
2562 localized using C<local>, the changes in the variables produced by the
2563 code expression are undone! Thus, if we wanted to count how many times
2564 a character got matched inside a group, we could use, e.g.,
2565
2566     $x = "aaaa";
2567     $count = 0;  # initialize 'a' count
2568     $c = "bob";  # test if $c gets clobbered
2569     $x =~ /(?{local $c = 0;})         # initialize count
2570            ( a                        # match 'a'
2571              (?{local $c = $c + 1;})  # increment count
2572            )*                         # do this any number of times,
2573            aa                         # but match 'aa' at the end
2574            (?{$count = $c;})          # copy local $c var into $count
2575           /x;
2576     print "'a' count is $count, \$c variable is '$c'\n";
2577
2578 This prints
2579
2580     'a' count is 2, $c variable is 'bob'
2581
2582 If we replace the S<C< (?{local $c = $c + 1;})>> with
2583 S<C< (?{$c = $c + 1;})>>, the variable changes are I<not> undone
2584 during backtracking, and we get
2585
2586     'a' count is 4, $c variable is 'bob'
2587
2588 Note that only localized variable changes are undone.  Other side
2589 effects of code expression execution are permanent.  Thus
2590
2591     $x = "aaaa";
2592     $x =~ /(a(?{print "Yow\n";}))*aa/;
2593
2594 produces
2595
2596    Yow
2597    Yow
2598    Yow
2599    Yow
2600
2601 The result C<$^R> is automatically localized, so that it will behave
2602 properly in the presence of backtracking.
2603
2604 This example uses a code expression in a conditional to match a
2605 definite article, either 'the' in English or 'der|die|das' in German:
2606
2607     $lang = 'DE';  # use German
2608     ...
2609     $text = "das";
2610     print "matched\n"
2611         if $text =~ /(?(?{
2612                           $lang eq 'EN'; # is the language English?
2613                          })
2614                        the |             # if so, then match 'the'
2615                        (der|die|das)     # else, match 'der|die|das'
2616                      )
2617                     /xi;
2618
2619 Note that the syntax here is C<(?(?{...})yes-regexp|no-regexp)>, not
2620 C<(?((?{...}))yes-regexp|no-regexp)>.  In other words, in the case of a
2621 code expression, we don't need the extra parentheses around the
2622 conditional.
2623
2624 If you try to use code expressions with interpolating variables, Perl
2625 may surprise you:
2626
2627     $bar = 5;
2628     $pat = '(?{ 1 })';
2629     /foo(?{ $bar })bar/; # compiles ok, $bar not interpolated
2630     /foo(?{ 1 })$bar/;   # compile error!
2631     /foo${pat}bar/;      # compile error!
2632
2633     $pat = qr/(?{ $foo = 1 })/;  # precompile code regexp
2634     /foo${pat}bar/;      # compiles ok
2635
2636 If a regexp has (1) code expressions and interpolating variables, or
2637 (2) a variable that interpolates a code expression, Perl treats the
2638 regexp as an error. If the code expression is precompiled into a
2639 variable, however, interpolating is ok. The question is, why is this
2640 an error?
2641
2642 The reason is that variable interpolation and code expressions
2643 together pose a security risk.  The combination is dangerous because
2644 many programmers who write search engines often take user input and
2645 plug it directly into a regexp:
2646
2647     $regexp = <>;       # read user-supplied regexp
2648     $chomp $regexp;     # get rid of possible newline
2649     $text =~ /$regexp/; # search $text for the $regexp
2650
2651 If the C<$regexp> variable contains a code expression, the user could
2652 then execute arbitrary Perl code.  For instance, some joker could
2653 search for S<C<system('rm -rf *');>> to erase your files.  In this
2654 sense, the combination of interpolation and code expressions I<taints>
2655 your regexp.  So by default, using both interpolation and code
2656 expressions in the same regexp is not allowed.  If you're not
2657 concerned about malicious users, it is possible to bypass this
2658 security check by invoking S<C<use re 'eval'>>:
2659
2660     use re 'eval';       # throw caution out the door
2661     $bar = 5;
2662     $pat = '(?{ 1 })';
2663     /foo(?{ 1 })$bar/;   # compiles ok
2664     /foo${pat}bar/;      # compiles ok
2665
2666 Another form of code expression is the I<pattern code expression>.
2667 The pattern code expression is like a regular code expression, except
2668 that the result of the code evaluation is treated as a regular
2669 expression and matched immediately.  A simple example is
2670
2671     $length = 5;
2672     $char = 'a';
2673     $x = 'aaaaabb';
2674     $x =~ /(??{$char x $length})/x; # matches, there are 5 of 'a'
2675
2676
2677 This final example contains both ordinary and pattern code
2678 expressions.  It detects whether a binary string C<1101010010001...> has a
2679 Fibonacci spacing 0,1,1,2,3,5,...  of the C<1>'s:
2680
2681     $x = "1101010010001000001";
2682     $z0 = ''; $z1 = '0';   # initial conditions
2683     print "It is a Fibonacci sequence\n"
2684         if $x =~ /^1         # match an initial '1'
2685                     (?:
2686                        ((??{ $z0 })) # match some '0'
2687                        1             # and then a '1'
2688                        (?{ $z0 = $z1; $z1 .= $^N; })
2689                     )+   # repeat as needed
2690                   $      # that is all there is
2691                  /x;
2692     printf "Largest sequence matched was %d\n", length($z1)-length($z0);
2693
2694 Remember that C<$^N> is set to whatever was matched by the last
2695 completed capture group. This prints
2696
2697     It is a Fibonacci sequence
2698     Largest sequence matched was 5
2699
2700 Ha! Try that with your garden variety regexp package...
2701
2702 Note that the variables C<$z0> and C<$z1> are not substituted when the
2703 regexp is compiled, as happens for ordinary variables outside a code
2704 expression.  Rather, the code expressions are evaluated when Perl
2705 encounters them during the search for a match.
2706
2707 The regexp without the C<//x> modifier is
2708
2709     /^1(?:((??{ $z0 }))1(?{ $z0 = $z1; $z1 .= $^N; }))+$/
2710
2711 which shows that spaces are still possible in the code parts. Nevertheless,
2712 when working with code and conditional expressions, the extended form of
2713 regexps is almost necessary in creating and debugging regexps.
2714
2715
2716 =head2 Backtracking control verbs
2717
2718 Perl 5.10 introduced a number of control verbs intended to provide
2719 detailed control over the backtracking process, by directly influencing
2720 the regexp engine and by providing monitoring techniques.  As all
2721 the features in this group are experimental and subject to change or
2722 removal in a future version of Perl, the interested reader is
2723 referred to L<perlre/"Special Backtracking Control Verbs"> for a
2724 detailed description.
2725
2726 Below is just one example, illustrating the control verb C<(*FAIL)>,
2727 which may be abbreviated as C<(*F)>. If this is inserted in a regexp
2728 it will cause it to fail, just as it would at some
2729 mismatch between the pattern and the string. Processing
2730 of the regexp continues as it would after any "normal"
2731 failure, so that, for instance, the next position in the string or another
2732 alternative will be tried. As failing to match doesn't preserve capture
2733 groups or produce results, it may be necessary to use this in
2734 combination with embedded code.
2735
2736    %count = ();
2737    "supercalifragilisticexpialidoceous" =~
2738        /([aeiou])(?{ $count{$1}++; })(*FAIL)/oi;
2739    printf "%3d '%s'\n", $count{$_}, $_ for (sort keys %count);
2740
2741 The pattern begins with a class matching a subset of letters.  Whenever
2742 this matches, a statement like C<$count{'a'}++;> is executed, incrementing
2743 the letter's counter. Then C<(*FAIL)> does what it says, and
2744 the regexp engine proceeds according to the book: as long as the end of
2745 the string hasn't been reached, the position is advanced before looking
2746 for another vowel. Thus, match or no match makes no difference, and the
2747 regexp engine proceeds until the entire string has been inspected.
2748 (It's remarkable that an alternative solution using something like
2749
2750    $count{lc($_)}++ for split('', "supercalifragilisticexpialidoceous");
2751    printf "%3d '%s'\n", $count2{$_}, $_ for ( qw{ a e i o u } );
2752
2753 is considerably slower.)
2754
2755
2756 =head2 Pragmas and debugging
2757
2758 Speaking of debugging, there are several pragmas available to control
2759 and debug regexps in Perl.  We have already encountered one pragma in
2760 the previous section, S<C<use re 'eval';>>, that allows variable
2761 interpolation and code expressions to coexist in a regexp.  The other
2762 pragmas are
2763
2764     use re 'taint';
2765     $tainted = <>;
2766     @parts = ($tainted =~ /(\w+)\s+(\w+)/; # @parts is now tainted
2767
2768 The C<taint> pragma causes any substrings from a match with a tainted
2769 variable to be tainted as well.  This is not normally the case, as
2770 regexps are often used to extract the safe bits from a tainted
2771 variable.  Use C<taint> when you are not extracting safe bits, but are
2772 performing some other processing.  Both C<taint> and C<eval> pragmas
2773 are lexically scoped, which means they are in effect only until
2774 the end of the block enclosing the pragmas.
2775
2776     use re '/m';  # or any other flags
2777     $multiline_string =~ /^foo/; # /m is implied
2778
2779 The C<re '/flags'> pragma (introduced in Perl
2780 5.14) turns on the given regular expression flags
2781 until the end of the lexical scope.  See C<re/"'/flags' mode"> for more
2782 detail.
2783
2784     use re 'debug';
2785     /^(.*)$/s;       # output debugging info
2786
2787     use re 'debugcolor';
2788     /^(.*)$/s;       # output debugging info in living color
2789
2790 The global C<debug> and C<debugcolor> pragmas allow one to get
2791 detailed debugging info about regexp compilation and
2792 execution.  C<debugcolor> is the same as debug, except the debugging
2793 information is displayed in color on terminals that can display
2794 termcap color sequences.  Here is example output:
2795
2796     % perl -e 'use re "debug"; "abc" =~ /a*b+c/;'
2797     Compiling REx `a*b+c'
2798     size 9 first at 1
2799        1: STAR(4)
2800        2:   EXACT <a>(0)
2801        4: PLUS(7)
2802        5:   EXACT <b>(0)
2803        7: EXACT <c>(9)
2804        9: END(0)
2805     floating `bc' at 0..2147483647 (checking floating) minlen 2
2806     Guessing start of match, REx `a*b+c' against `abc'...
2807     Found floating substr `bc' at offset 1...
2808     Guessed: match at offset 0
2809     Matching REx `a*b+c' against `abc'
2810       Setting an EVAL scope, savestack=3
2811        0 <> <abc>             |  1:  STAR
2812                                EXACT <a> can match 1 times out of 32767...
2813       Setting an EVAL scope, savestack=3
2814        1 <a> <bc>             |  4:    PLUS
2815                                EXACT <b> can match 1 times out of 32767...
2816       Setting an EVAL scope, savestack=3
2817        2 <ab> <c>             |  7:      EXACT <c>
2818        3 <abc> <>             |  9:      END
2819     Match successful!
2820     Freeing REx: `a*b+c'
2821
2822 If you have gotten this far into the tutorial, you can probably guess
2823 what the different parts of the debugging output tell you.  The first
2824 part
2825
2826     Compiling REx `a*b+c'
2827     size 9 first at 1
2828        1: STAR(4)
2829        2:   EXACT <a>(0)
2830        4: PLUS(7)
2831        5:   EXACT <b>(0)
2832        7: EXACT <c>(9)
2833        9: END(0)
2834
2835 describes the compilation stage.  C<STAR(4)> means that there is a
2836 starred object, in this case C<'a'>, and if it matches, goto line 4,
2837 i.e., C<PLUS(7)>.  The middle lines describe some heuristics and
2838 optimizations performed before a match:
2839
2840     floating `bc' at 0..2147483647 (checking floating) minlen 2
2841     Guessing start of match, REx `a*b+c' against `abc'...
2842     Found floating substr `bc' at offset 1...
2843     Guessed: match at offset 0
2844
2845 Then the match is executed and the remaining lines describe the
2846 process:
2847
2848     Matching REx `a*b+c' against `abc'
2849       Setting an EVAL scope, savestack=3
2850        0 <> <abc>             |  1:  STAR
2851                                EXACT <a> can match 1 times out of 32767...
2852       Setting an EVAL scope, savestack=3
2853        1 <a> <bc>             |  4:    PLUS
2854                                EXACT <b> can match 1 times out of 32767...
2855       Setting an EVAL scope, savestack=3
2856        2 <ab> <c>             |  7:      EXACT <c>
2857        3 <abc> <>             |  9:      END
2858     Match successful!
2859     Freeing REx: `a*b+c'
2860
2861 Each step is of the form S<C<< n <x> <y> >>>, with C<< <x> >> the
2862 part of the string matched and C<< <y> >> the part not yet
2863 matched.  The S<C<< |  1:  STAR >>> says that Perl is at line number 1
2864 in the compilation list above.  See
2865 L<perldebguts/"Debugging Regular Expressions"> for much more detail.
2866
2867 An alternative method of debugging regexps is to embed C<print>
2868 statements within the regexp.  This provides a blow-by-blow account of
2869 the backtracking in an alternation:
2870
2871     "that this" =~ m@(?{print "Start at position ", pos, "\n";})
2872                      t(?{print "t1\n";})
2873                      h(?{print "h1\n";})
2874                      i(?{print "i1\n";})
2875                      s(?{print "s1\n";})
2876                          |
2877                      t(?{print "t2\n";})
2878                      h(?{print "h2\n";})
2879                      a(?{print "a2\n";})
2880                      t(?{print "t2\n";})
2881                      (?{print "Done at position ", pos, "\n";})
2882                     @x;
2883
2884 prints
2885
2886     Start at position 0
2887     t1
2888     h1
2889     t2
2890     h2
2891     a2
2892     t2
2893     Done at position 4
2894
2895 =head1 BUGS
2896
2897 Code expressions, conditional expressions, and independent expressions
2898 are I<experimental>.  Don't use them in production code.  Yet.
2899
2900 =head1 SEE ALSO
2901
2902 This is just a tutorial.  For the full story on Perl regular
2903 expressions, see the L<perlre> regular expressions reference page.
2904
2905 For more information on the matching C<m//> and substitution C<s///>
2906 operators, see L<perlop/"Regexp Quote-Like Operators">.  For
2907 information on the C<split> operation, see L<perlfunc/split>.
2908
2909 For an excellent all-around resource on the care and feeding of
2910 regular expressions, see the book I<Mastering Regular Expressions> by
2911 Jeffrey Friedl (published by O'Reilly, ISBN 1556592-257-3).
2912
2913 =head1 AUTHOR AND COPYRIGHT
2914
2915 Copyright (c) 2000 Mark Kvale
2916 All rights reserved.
2917
2918 This document may be distributed under the same terms as Perl itself.
2919
2920 =head2 Acknowledgments
2921
2922 The inspiration for the stop codon DNA example came from the ZIP
2923 code example in chapter 7 of I<Mastering Regular Expressions>.
2924
2925 The author would like to thank Jeff Pinyan, Andrew Johnson, Peter
2926 Haworth, Ronald J Kimball, and Joe Smith for all their helpful
2927 comments.
2928
2929 =cut
2930