lib/overload.pm

   1 package overload;
   2
   3 $overload::hint_bits = 0x20000;
   4
   5 sub nil {}
   6
   7 sub OVERLOAD {
   8   $package = shift;
   9   my %arg = @_;
  10   my ($sub, $fb);
  11   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
  12   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
  13   for (keys %arg) {
  14     if ($_ eq 'fallback') {
  15       $fb = $arg{$_};
  16     } else {
  17       $sub = $arg{$_};
  18       if (not ref $sub and $sub !~ /::/) {
  19         $ {$package . "::(" . $_} = $sub;
  20         $sub = \&nil;
  21       }
  22       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
  23       *{$package . "::(" . $_} = \&{ $sub };
  24     }
  25   }
  26   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
  27 }
  28
  29 sub import {
  30   $package = (caller())[0];
  31   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
  32   shift;
  33   $package->overload::OVERLOAD(@_);
  34 }
  35
  36 sub unimport {
  37   $package = (caller())[0];
  38   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
  39   shift;
  40   for (@_) {
  41     if ($_ eq 'fallback') {
  42       undef $ {$package . "::()"};
  43     } else {
  44       delete $ {$package . "::"}{"(" . $_};
  45     }
  46   }
  47 }
  48
  49 sub Overloaded {
  50   my $package = shift;
  51   $package = ref $package if ref $package;
  52   $package->can('()');
  53 }
  54
  55 sub ov_method {
  56   my $globref = shift;
  57   return undef unless $globref;
  58   my $sub = \&{*$globref};
  59   return $sub if $sub ne \&nil;
  60   return shift->can($ {*$globref});
  61 }
  62
  63 sub OverloadedStringify {
  64   my $package = shift;
  65   $package = ref $package if ref $package;
  66   #$package->can('(""')
  67   ov_method mycan($package, '(""'), $package
  68     or ov_method mycan($package, '(0+'), $package
  69     or ov_method mycan($package, '(bool'), $package
  70     or ov_method mycan($package, '(nomethod'), $package;
  71 }
  72
  73 sub Method {
  74   my $package = shift;
  75   $package = ref $package if ref $package;
  76   #my $meth = $package->can('(' . shift);
  77   ov_method mycan($package, '(' . shift), $package;
  78   #return $meth if $meth ne \&nil;
  79   #return $ {*{$meth}};
  80 }
  81
  82 sub AddrRef {
  83   my $package = ref $_[0];
  84   return "$_[0]" unless $package;
  85   bless $_[0], overload::Fake;  # Non-overloaded package
  86   my $str = "$_[0]";
  87   bless $_[0], $package;        # Back
  88   $package . substr $str, index $str, '=';
  89 }
  90
  91 sub StrVal {
  92   (OverloadedStringify($_[0]) or ref($_[0]) eq 'Regexp') ?
  93     (AddrRef(shift)) :
  94     "$_[0]";
  95 }
  96
  97 sub mycan {                             # Real can would leave stubs.
  98   my ($package, $meth) = @_;
  99   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
 100   my $p;
 101   foreach $p (@{$package . "::ISA"}) {
 102     my $out = mycan($p, $meth);
 103     return $out if $out;
 104   }
 105   return undef;
 106 }
 107
 108 %constants = (
 109               'integer'   =>  0x1000,
 110               'float'     =>  0x2000,
 111               'binary'    =>  0x4000,
 112               'q'         =>  0x8000,
 113               'qr'        => 0x10000,
 114              );
 115
 116 %ops = ( with_assign      => "+ - * / % ** << >> x .",
 117          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
 118          num_comparison   => "< <= >  >= == !=",
 119          '3way_comparison'=> "<=> cmp",
 120          str_comparison   => "lt le gt ge eq ne",
 121          binary           => "& | ^",
 122          unary            => "neg ! ~",
 123          mutators         => '++ --',
 124          func             => "atan2 cos sin exp abs log sqrt",
 125          conversion       => 'bool "" 0+',
 126          iterators        => '<>',
 127          dereferencing    => '${} @{} %{} &{} *{}',
 128          special          => 'nomethod fallback =');
 129
 130 sub constant {
 131   # Arguments: what, sub
 132   while (@_) {
 133     $^H{$_[0]} = $_[1];
 134     $^H |= $constants{$_[0]} | $overload::hint_bits;
 135     shift, shift;
 136   }
 137 }
 138
 139 sub remove_constant {
 140   # Arguments: what, sub
 141   while (@_) {
 142     delete $^H{$_[0]};
 143     $^H &= ~ $constants{$_[0]};
 144     shift, shift;
 145   }
 146 }
 147
 148 1;
 149
 150 __END__
 151
 152 =head1 NAME
 153
 154 overload - Package for overloading perl operations
 155
 156 =head1 SYNOPSIS
 157
 158     package SomeThing;
 159
 160     use overload
 161         '+' => \&myadd,
 162         '-' => \&mysub;
 163         # etc
 164     ...
 165
 166     package main;
 167     $a = new SomeThing 57;
 168     $b=5+$a;
 169     ...
 170     if (overload::Overloaded $b) {...}
 171     ...
 172     $strval = overload::StrVal $b;
 173
 174 =head1 DESCRIPTION
 175
 176 =head2 Declaration of overloaded functions
 177
 178 The compilation directive
 179
 180     package Number;
 181     use overload
 182         "+" => \&add,
 183         "*=" => "muas";
 184
 185 declares function Number::add() for addition, and method muas() in
 186 the "class" C<Number> (or one of its base classes)
 187 for the assignment form C<*=> of multiplication.
 188
 189 Arguments of this directive come in (key, value) pairs.  Legal values
 190 are values legal inside a C<&{ ... }> call, so the name of a
 191 subroutine, a reference to a subroutine, or an anonymous subroutine
 192 will all work.  Note that values specified as strings are
 193 interpreted as methods, not subroutines.  Legal keys are listed below.
 194
 195 The subroutine C<add> will be called to execute C<$a+$b> if $a
 196 is a reference to an object blessed into the package C<Number>, or if $a is
 197 not an object from a package with defined mathemagic addition, but $b is a
 198 reference to a C<Number>.  It can also be called in other situations, like
 199 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
 200 methods refer to methods triggered by an overloaded mathematical
 201 operator.)
 202
 203 Since overloading respects inheritance via the @ISA hierarchy, the
 204 above declaration would also trigger overloading of C<+> and C<*=> in
 205 all the packages which inherit from C<Number>.
 206
 207 =head2 Calling Conventions for Binary Operations
 208
 209 The functions specified in the C<use overload ...> directive are called
 210 with three (in one particular case with four, see L<Last Resort>)
 211 arguments.  If the corresponding operation is binary, then the first
 212 two arguments are the two arguments of the operation.  However, due to
 213 general object calling conventions, the first argument should always be
 214 an object in the package, so in the situation of C<7+$a>, the
 215 order of the arguments is interchanged.  It probably does not matter
 216 when implementing the addition method, but whether the arguments
 217 are reversed is vital to the subtraction method.  The method can
 218 query this information by examining the third argument, which can take
 219 three different values:
 220
 221 =over 7
 222
 223 =item FALSE
 224
 225 the order of arguments is as in the current operation.
 226
 227 =item TRUE
 228
 229 the arguments are reversed.
 230
 231 =item C<undef>
 232
 233 the current operation is an assignment variant (as in
 234 C<$a+=7>), but the usual function is called instead.  This additional
 235 information can be used to generate some optimizations.  Compare
 236 L<Calling Conventions for Mutators>.
 237
 238 =back
 239
 240 =head2 Calling Conventions for Unary Operations
 241
 242 Unary operation are considered binary operations with the second
 243 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
 244 is called with arguments C<($a,undef,'')> when $a++ is executed.
 245
 246 =head2 Calling Conventions for Mutators
 247
 248 Two types of mutators have different calling conventions:
 249
 250 =over
 251
 252 =item C<++> and C<-->
 253
 254 The routines which implement these operators are expected to actually
 255 I<mutate> their arguments.  So, assuming that $obj is a reference to a
 256 number,
 257
 258   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
 259
 260 is an appropriate implementation of overloaded C<++>.  Note that
 261
 262   sub incr { ++$ {$_[0]} ; shift }
 263
 264 is OK if used with preincrement and with postincrement. (In the case
 265 of postincrement a copying will be performed, see L<Copy Constructor>.)
 266
 267 =item C<x=> and other assignment versions
 268
 269 There is nothing special about these methods.  They may change the
 270 value of their arguments, and may leave it as is.  The result is going
 271 to be assigned to the value in the left-hand-side if different from
 272 this value.
 273
 274 This allows for the same method to be used as overloaded C<+=> and
 275 C<+>.  Note that this is I<allowed>, but not recommended, since by the
 276 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
 277 if C<+=> is not overloaded.
 278
 279 =back
 280
 281 B<Warning.>  Due to the presense of assignment versions of operations,
 282 routines which may be called in assignment context may create
 283 self-referential structures.  Currently Perl will not free self-referential
 284 structures until cycles are C<explicitly> broken.  You may get problems
 285 when traversing your structures too.
 286
 287 Say,
 288
 289   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
 290
 291 is asking for trouble, since for code C<$obj += $foo> the subroutine
 292 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
 293 \$foo]>.  If using such a subroutine is an important optimization, one
 294 can overload C<+=> explicitly by a non-"optimized" version, or switch
 295 to non-optimized version if C<not defined $_[2]> (see
 296 L<Calling Conventions for Binary Operations>).
 297
 298 Even if no I<explicit> assignment-variants of operators are present in
 299 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
 300 C<',' . $obj . ','> may be both optimized to
 301
 302   my $tmp = ',' . $obj;    $tmp .= ',';
 303
 304 =head2 Overloadable Operations
 305
 306 The following symbols can be specified in C<use overload> directive:
 307
 308 =over 5
 309
 310 =item * I<Arithmetic operations>
 311
 312     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
 313     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
 314
 315 For these operations a substituted non-assignment variant can be called if
 316 the assignment variant is not available.  Methods for operations "C<+>",
 317 "C<->", "C<+=>", and "C<-=>" can be called to automatically generate
 318 increment and decrement methods.  The operation "C<->" can be used to
 319 autogenerate missing methods for unary minus or C<abs>.
 320
 321 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
 322 L<"Calling Conventions for Binary Operations">) for details of these
 323 substitutions.
 324
 325 =item * I<Comparison operations>
 326
 327     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
 328     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
 329
 330 If the corresponding "spaceship" variant is available, it can be
 331 used to substitute for the missing operation.  During C<sort>ing
 332 arrays, C<cmp> is used to compare values subject to C<use overload>.
 333
 334 =item * I<Bit operations>
 335
 336     "&", "^", "|", "neg", "!", "~",
 337
 338 "C<neg>" stands for unary minus.  If the method for C<neg> is not
 339 specified, it can be autogenerated using the method for
 340 subtraction. If the method for "C<!>" is not specified, it can be
 341 autogenerated using the methods for "C<bool>", or "C<\"\">", or "C<0+>".
 342
 343 =item * I<Increment and decrement>
 344
 345     "++", "--",
 346
 347 If undefined, addition and subtraction methods can be
 348 used instead.  These operations are called both in prefix and
 349 postfix form.
 350
 351 =item * I<Transcendental functions>
 352
 353     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt",
 354
 355 If C<abs> is unavailable, it can be autogenerated using methods
 356 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
 357
 358 =item * I<Boolean, string and numeric conversion>
 359
 360     "bool", "\"\"", "0+",
 361
 362 If one or two of these operations are not overloaded, the remaining ones can
 363 be used instead.  C<bool> is used in the flow control operators
 364 (like C<while>) and for the ternary "C<?:>" operation.  These functions can
 365 return any arbitrary Perl value.  If the corresponding operation for this value
 366 is overloaded too, that operation will be called again with this value.
 367
 368 =item * I<Iteration>
 369
 370     "<>"
 371
 372 If not overloaded, the argument will be converted to a filehandle or
 373 glob (which may require a stringification).  The same overloading
 374 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
 375 I<globbing> syntax C<E<lt>${var}E<gt>>.
 376
 377 =item * I<Dereferencing>
 378
 379     '${}', '@{}', '%{}', '&{}', '*{}'.
 380
 381 If not overloaded, the argument will be dereferenced I<as is>, thus
 382 should be of correct type.  These functions should return a reference
 383 of correct type, or another object with overloaded dereferencing.
 384
 385 =item * I<Special>
 386
 387     "nomethod", "fallback", "=",
 388
 389 see L<SPECIAL SYMBOLS FOR C<use overload>>.
 390
 391 =back
 392
 393 See L<"Fallback"> for an explanation of when a missing method can be
 394 autogenerated.
 395
 396 A computer-readable form of the above table is available in the hash
 397 %overload::ops, with values being space-separated lists of names:
 398
 399  with_assign      => '+ - * / % ** << >> x .',
 400  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
 401  num_comparison   => '< <= > >= == !=',
 402  '3way_comparison'=> '<=> cmp',
 403  str_comparison   => 'lt le gt ge eq ne',
 404  binary           => '& | ^',
 405  unary            => 'neg ! ~',
 406  mutators         => '++ --',
 407  func             => 'atan2 cos sin exp abs log sqrt',
 408  conversion       => 'bool "" 0+',
 409  iterators        => '<>',
 410  dereferencing    => '${} @{} %{} &{} *{}',
 411  special          => 'nomethod fallback ='
 412
 413 =head2 Inheritance and overloading
 414
 415 Inheritance interacts with overloading in two ways.
 416
 417 =over
 418
 419 =item Strings as values of C<use overload> directive
 420
 421 If C<value> in
 422
 423   use overload key => value;
 424
 425 is a string, it is interpreted as a method name.
 426
 427 =item Overloading of an operation is inherited by derived classes
 428
 429 Any class derived from an overloaded class is also overloaded.  The
 430 set of overloaded methods is the union of overloaded methods of all
 431 the ancestors. If some method is overloaded in several ancestor, then
 432 which description will be used is decided by the usual inheritance
 433 rules:
 434
 435 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
 436 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
 437 then the subroutine C<D::plus_sub> will be called to implement
 438 operation C<+> for an object in package C<A>.
 439
 440 =back
 441
 442 Note that since the value of the C<fallback> key is not a subroutine,
 443 its inheritance is not governed by the above rules.  In the current
 444 implementation, the value of C<fallback> in the first overloaded
 445 ancestor is used, but this is accidental and subject to change.
 446
 447 =head1 SPECIAL SYMBOLS FOR C<use overload>
 448
 449 Three keys are recognized by Perl that are not covered by the above
 450 description.
 451
 452 =head2 Last Resort
 453
 454 C<"nomethod"> should be followed by a reference to a function of four
 455 parameters.  If defined, it is called when the overloading mechanism
 456 cannot find a method for some operation.  The first three arguments of
 457 this function coincide with the arguments for the corresponding method if
 458 it were found, the fourth argument is the symbol
 459 corresponding to the missing method.  If several methods are tried,
 460 the last one is used.  Say, C<1-$a> can be equivalent to
 461
 462         &nomethodMethod($a,1,1,"-")
 463
 464 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
 465 C<use overload> directive.
 466
 467 If some operation cannot be resolved, and there is no function
 468 assigned to C<"nomethod">, then an exception will be raised via die()--
 469 unless C<"fallback"> was specified as a key in C<use overload> directive.
 470
 471 =head2 Fallback
 472
 473 The key C<"fallback"> governs what to do if a method for a particular
 474 operation is not found.  Three different cases are possible depending on
 475 the value of C<"fallback">:
 476
 477 =over 16
 478
 479 =item * C<undef>
 480
 481 Perl tries to use a
 482 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
 483 then tries to calls C<"nomethod"> value; if missing, an exception
 484 will be raised.
 485
 486 =item * TRUE
 487
 488 The same as for the C<undef> value, but no exception is raised.  Instead,
 489 it silently reverts to what it would have done were there no C<use overload>
 490 present.
 491
 492 =item * defined, but FALSE
 493
 494 No autogeneration is tried.  Perl tries to call
 495 C<"nomethod"> value, and if this is missing, raises an exception.
 496
 497 =back
 498
 499 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
 500 yet, see L<"Inheritance and overloading">.
 501
 502 =head2 Copy Constructor
 503
 504 The value for C<"="> is a reference to a function with three
 505 arguments, i.e., it looks like the other values in C<use
 506 overload>. However, it does not overload the Perl assignment
 507 operator. This would go against Camel hair.
 508
 509 This operation is called in the situations when a mutator is applied
 510 to a reference that shares its object with some other reference, such
 511 as
 512
 513         $a=$b;
 514         ++$a;
 515
 516 To make this change $a and not change $b, a copy of C<$$a> is made,
 517 and $a is assigned a reference to this new object.  This operation is
 518 done during execution of the C<++$a>, and not during the assignment,
 519 (so before the increment C<$$a> coincides with C<$$b>).  This is only
 520 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
 521 C<nomethod>).  Note that if this operation is expressed via C<'+'>
 522 a nonmutator, i.e., as in
 523
 524         $a=$b;
 525         $a=$a+1;
 526
 527 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
 528 appear as lvalue when the above code is executed.
 529
 530 If the copy constructor is required during the execution of some mutator,
 531 but a method for C<'='> was not specified, it can be autogenerated as a
 532 string copy if the object is a plain scalar.
 533
 534 =over 5
 535
 536 =item B<Example>
 537
 538 The actually executed code for
 539
 540         $a=$b;
 541         Something else which does not modify $a or $b....
 542         ++$a;
 543
 544 may be
 545
 546         $a=$b;
 547         Something else which does not modify $a or $b....
 548         $a = $a->clone(undef,"");
 549         $a->incr(undef,"");
 550
 551 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
 552 C<'='> was overloaded with C<\&clone>.
 553
 554 =back
 555
 556 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
 557 C<$b = $a; ++$a>.
 558
 559 =head1 MAGIC AUTOGENERATION
 560
 561 If a method for an operation is not found, and the value for  C<"fallback"> is
 562 TRUE or undefined, Perl tries to autogenerate a substitute method for
 563 the missing operation based on the defined operations.  Autogenerated method
 564 substitutions are possible for the following operations:
 565
 566 =over 16
 567
 568 =item I<Assignment forms of arithmetic operations>
 569
 570 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
 571 is not defined.
 572
 573 =item I<Conversion operations>
 574
 575 String, numeric, and boolean conversion are calculated in terms of one
 576 another if not all of them are defined.
 577
 578 =item I<Increment and decrement>
 579
 580 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
 581 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
 582
 583 =item C<abs($a)>
 584
 585 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
 586
 587 =item I<Unary minus>
 588
 589 can be expressed in terms of subtraction.
 590
 591 =item I<Negation>
 592
 593 C<!> and C<not> can be expressed in terms of boolean conversion, or
 594 string or numerical conversion.
 595
 596 =item I<Concatenation>
 597
 598 can be expressed in terms of string conversion.
 599
 600 =item I<Comparison operations>
 601
 602 can be expressed in terms of its "spaceship" counterpart: either
 603 C<E<lt>=E<gt>> or C<cmp>:
 604
 605     <, >, <=, >=, ==, !=        in terms of <=>
 606     lt, gt, le, ge, eq, ne      in terms of cmp
 607
 608 =item I<Iterator>
 609
 610     <>                          in terms of builtin operations
 611
 612 =item I<Dereferencing>
 613
 614     ${} @{} %{} &{} *{}         in terms of builtin operations
 615
 616 =item I<Copy operator>
 617
 618 can be expressed in terms of an assignment to the dereferenced value, if this
 619 value is a scalar and not a reference.
 620
 621 =back
 622
 623 =head1 Losing overloading
 624
 625 The restriction for the comparison operation is that even if, for example,
 626 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
 627 function will produce only a standard logical value based on the
 628 numerical value of the result of `C<cmp>'.  In particular, a working
 629 numeric conversion is needed in this case (possibly expressed in terms of
 630 other conversions).
 631
 632 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
 633 if the string conversion substitution is applied.
 634
 635 When you chop() a mathemagical object it is promoted to a string and its
 636 mathemagical properties are lost.  The same can happen with other
 637 operations as well.
 638
 639 =head1 Run-time Overloading
 640
 641 Since all C<use> directives are executed at compile-time, the only way to
 642 change overloading during run-time is to
 643
 644     eval 'use overload "+" => \&addmethod';
 645
 646 You can also use
 647
 648     eval 'no overload "+", "--", "<="';
 649
 650 though the use of these constructs during run-time is questionable.
 651
 652 =head1 Public functions
 653
 654 Package C<overload.pm> provides the following public functions:
 655
 656 =over 5
 657
 658 =item overload::StrVal(arg)
 659
 660 Gives string value of C<arg> as in absence of stringify overloading.
 661
 662 =item overload::Overloaded(arg)
 663
 664 Returns true if C<arg> is subject to overloading of some operations.
 665
 666 =item overload::Method(obj,op)
 667
 668 Returns C<undef> or a reference to the method that implements C<op>.
 669
 670 =back
 671
 672 =head1 Overloading constants
 673
 674 For some application Perl parser mangles constants too much.  It is possible
 675 to hook into this process via overload::constant() and overload::remove_constant()
 676 functions.
 677
 678 These functions take a hash as an argument.  The recognized keys of this hash
 679 are
 680
 681 =over 8
 682
 683 =item integer
 684
 685 to overload integer constants,
 686
 687 =item float
 688
 689 to overload floating point constants,
 690
 691 =item binary
 692
 693 to overload octal and hexadecimal constants,
 694
 695 =item q
 696
 697 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
 698 strings and here-documents,
 699
 700 =item qr
 701
 702 to overload constant pieces of regular expressions.
 703
 704 =back
 705
 706 The corresponding values are references to functions which take three arguments:
 707 the first one is the I<initial> string form of the constant, the second one
 708 is how Perl interprets this constant, the third one is how the constant is used.
 709 Note that the initial string form does not
 710 contain string delimiters, and has backslashes in backslash-delimiter
 711 combinations stripped (thus the value of delimiter is not relevant for
 712 processing of this string).  The return value of this function is how this
 713 constant is going to be interpreted by Perl.  The third argument is undefined
 714 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
 715 context (comes from strings, regular expressions, and single-quote HERE
 716 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
 717 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
 718
 719 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
 720 it is expected that overloaded constant strings are equipped with reasonable
 721 overloaded catenation operator, otherwise absurd results will result.
 722 Similarly, negative numbers are considered as negations of positive constants.
 723
 724 Note that it is probably meaningless to call the functions overload::constant()
 725 and overload::remove_constant() from anywhere but import() and unimport() methods.
 726 From these methods they may be called as
 727
 728         sub import {
 729           shift;
 730           return unless @_;
 731           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
 732           overload::constant integer => sub {Math::BigInt->new(shift)};
 733         }
 734
 735 B<BUGS> Currently overloaded-ness of constants does not propagate
 736 into C<eval '...'>.
 737
 738 =head1 IMPLEMENTATION
 739
 740 What follows is subject to change RSN.
 741
 742 The table of methods for all operations is cached in magic for the
 743 symbol table hash for the package.  The cache is invalidated during
 744 processing of C<use overload>, C<no overload>, new function
 745 definitions, and changes in @ISA. However, this invalidation remains
 746 unprocessed until the next C<bless>ing into the package. Hence if you
 747 want to change overloading structure dynamically, you'll need an
 748 additional (fake) C<bless>ing to update the table.
 749
 750 (Every SVish thing has a magic queue, and magic is an entry in that
 751 queue.  This is how a single variable may participate in multiple
 752 forms of magic simultaneously.  For instance, environment variables
 753 regularly have two forms at once: their %ENV magic and their taint
 754 magic. However, the magic which implements overloading is applied to
 755 the stashes, which are rarely used directly, thus should not slow down
 756 Perl.)
 757
 758 If an object belongs to a package using overload, it carries a special
 759 flag.  Thus the only speed penalty during arithmetic operations without
 760 overloading is the checking of this flag.
 761
 762 In fact, if C<use overload> is not present, there is almost no overhead
 763 for overloadable operations, so most programs should not suffer
 764 measurable performance penalties.  A considerable effort was made to
 765 minimize the overhead when overload is used in some package, but the
 766 arguments in question do not belong to packages using overload.  When
 767 in doubt, test your speed with C<use overload> and without it.  So far
 768 there have been no reports of substantial speed degradation if Perl is
 769 compiled with optimization turned on.
 770
 771 There is no size penalty for data if overload is not used. The only
 772 size penalty if overload is used in some package is that I<all> the
 773 packages acquire a magic during the next C<bless>ing into the
 774 package. This magic is three-words-long for packages without
 775 overloading, and carries the cache table if the package is overloaded.
 776
 777 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
 778 carried out before any operation that can imply an assignment to the
 779 object $a (or $b) refers to, like C<$a++>.  You can override this
 780 behavior by defining your own copy constructor (see L<"Copy Constructor">).
 781
 782 It is expected that arguments to methods that are not explicitly supposed
 783 to be changed are constant (but this is not enforced).
 784
 785 =head1 Metaphor clash
 786
 787 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
 788 If it I<looks> counter intuitive to you, you are subject to a metaphor
 789 clash.
 790
 791 Here is a Perl object metaphor:
 792
 793 I<  object is a reference to blessed data>
 794
 795 and an arithmetic metaphor:
 796
 797 I<  object is a thing by itself>.
 798
 799 The I<main> problem of overloading C<=> is the fact that these metaphors
 800 imply different actions on the assignment C<$a = $b> if $a and $b are
 801 objects.  Perl-think implies that $a becomes a reference to whatever
 802 $b was referencing.  Arithmetic-think implies that the value of "object"
 803 $a is changed to become the value of the object $b, preserving the fact
 804 that $a and $b are separate entities.
 805
 806 The difference is not relevant in the absence of mutators.  After
 807 a Perl-way assignment an operation which mutates the data referenced by $a
 808 would change the data referenced by $b too.  Effectively, after
 809 C<$a = $b> values of $a and $b become I<indistinguishable>.
 810
 811 On the other hand, anyone who has used algebraic notation knows the
 812 expressive power of the arithmetic metaphor.  Overloading works hard
 813 to enable this metaphor while preserving the Perlian way as far as
 814 possible.  Since it is not not possible to freely mix two contradicting
 815 metaphors, overloading allows the arithmetic way to write things I<as
 816 far as all the mutators are called via overloaded access only>.  The
 817 way it is done is described in L<Copy Constructor>.
 818
 819 If some mutator methods are directly applied to the overloaded values,
 820 one may need to I<explicitly unlink> other values which references the
 821 same value:
 822
 823     $a = new Data 23;
 824     ...
 825     $b = $a;            # $b is "linked" to $a
 826     ...
 827     $a = $a->clone;     # Unlink $b from $a
 828     $a->increment_by(4);
 829
 830 Note that overloaded access makes this transparent:
 831
 832     $a = new Data 23;
 833     $b = $a;            # $b is "linked" to $a
 834     $a += 4;            # would unlink $b automagically
 835
 836 However, it would not make
 837
 838     $a = new Data 23;
 839     $a = 4;             # Now $a is a plain 4, not 'Data'
 840
 841 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
 842 to an object do whatever you want.  It is just not the overload, but
 843 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
 844 which returns the object itself, and STORE() method which changes the
 845 value of the object, one can reproduce the arithmetic metaphor in its
 846 completeness, at least for variables which were tie()d from the start.
 847
 848 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
 849
 850 =head1 Cookbook
 851
 852 Please add examples to what follows!
 853
 854 =head2 Two-face scalars
 855
 856 Put this in F<two_face.pm> in your Perl library directory:
 857
 858   package two_face;             # Scalars with separate string and
 859                                 # numeric values.
 860   sub new { my $p = shift; bless [@_], $p }
 861   use overload '""' => \&str, '0+' => \&num, fallback => 1;
 862   sub num {shift->[1]}
 863   sub str {shift->[0]}
 864
 865 Use it as follows:
 866
 867   require two_face;
 868   my $seven = new two_face ("vii", 7);
 869   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
 870   print "seven contains `i'\n" if $seven =~ /i/;
 871
 872 (The second line creates a scalar which has both a string value, and a
 873 numeric value.)  This prints:
 874
 875   seven=vii, seven=7, eight=8
 876   seven contains `i'
 877
 878 =head2 Two-face references
 879
 880 Suppose you want to create an object which is accessible as both an
 881 array reference, and a hash reference, similar to the builtin
 882 L<array-accessible-as-a-hash|perlref/"Pseudo-hashes: Using an array as
 883 a hash"> builtin Perl type.  Let us make it better than the builtin
 884 type, there will be no restriction that you cannot use the index 0 of
 885 your array.
 886
 887   package two_refs;
 888   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
 889   sub new {
 890     my $p = shift;
 891     bless \ [@_], $p;
 892   }
 893   sub gethash {
 894     my %h;
 895     my $self = shift;
 896     tie %h, ref $self, $self;
 897     \%h;
 898   }
 899
 900   sub TIEHASH { my $p = shift; bless \ shift, $p }
 901   my %fields;
 902   my $i = 0;
 903   $fields{$_} = $i++ foreach qw{zero one two three};
 904   sub STORE {
 905     my $self = ${shift()};
 906     my $key = $fields{shift()};
 907     defined $key or die "Out of band access";
 908     $$self->[$key] = shift;
 909   }
 910   sub FETCH {
 911     my $self = ${shift()};
 912     my $key = $fields{shift()};
 913     defined $key or die "Out of band access";
 914     $$self->[$key];
 915   }
 916
 917 Now one can access an object using both the array and hash syntax:
 918
 919   my $bar = new two_refs 3,4,5,6;
 920   $bar->[2] = 11;
 921   $bar->{two} == 11 or die 'bad hash fetch';
 922
 923 Note several important features of this example.  First of all, the
 924 I<actual> type of $bar is a scalar reference, and we do not overload
 925 the scalar dereference.  Thus we can get the I<actual> non-overloaded
 926 contents of $bar by just using C<$$bar> (what we do in functions which
 927 overload dereference).  Similarly, the object returned by the
 928 TIEHASH() method is a scalar reference.
 929
 930 Second, we create a new tied hash each time the hash syntax is used.
 931 This allows us not to worry about a possibility of a reference loop,
 932 would would lead to a memory leak.
 933
 934 Both these problems can be cured.  Say, if we want to overload hash
 935 dereference on a reference to an object which is I<implemented> as a
 936 hash itself, the only problem one has to circumvent is how to access
 937 this I<actual> hash (as opposed to the I<virtual> exhibited by
 938 overloaded dereference operator).  Here is one possible fetching routine:
 939
 940   sub access_hash {
 941     my ($self, $key) = (shift, shift);
 942     my $class = ref $self;
 943     bless $self, 'overload::dummy'; # Disable overloading of %{}
 944     my $out = $self->{$key};
 945     bless $self, $class;        # Restore overloading
 946     $out;
 947   }
 948
 949 To move creation of the tied hash on each access, one may an extra
 950 level of indirection which allows a non-circular structure of references:
 951
 952   package two_refs1;
 953   use overload '%{}' => sub { ${shift()}->[1] },
 954                '@{}' => sub { ${shift()}->[0] };
 955   sub new {
 956     my $p = shift;
 957     my $a = [@_];
 958     my %h;
 959     tie %h, $p, $a;
 960     bless \ [$a, \%h], $p;
 961   }
 962   sub gethash {
 963     my %h;
 964     my $self = shift;
 965     tie %h, ref $self, $self;
 966     \%h;
 967   }
 968
 969   sub TIEHASH { my $p = shift; bless \ shift, $p }
 970   my %fields;
 971   my $i = 0;
 972   $fields{$_} = $i++ foreach qw{zero one two three};
 973   sub STORE {
 974     my $a = ${shift()};
 975     my $key = $fields{shift()};
 976     defined $key or die "Out of band access";
 977     $a->[$key] = shift;
 978   }
 979   sub FETCH {
 980     my $a = ${shift()};
 981     my $key = $fields{shift()};
 982     defined $key or die "Out of band access";
 983     $a->[$key];
 984   }
 985
 986 Now if $baz is overloaded like this, then C<$bar> is a reference to a
 987 reference to the intermediate array, which keeps a reference to an
 988 actual array, and the access hash.  The tie()ing object for the access
 989 hash is also a reference to a reference to the actual array, so
 990
 991 =over
 992
 993 =item *
 994
 995 There are no loops of references.
 996
 997 =item *
 998
 999 Both "objects" which are blessed into the class C<two_refs1> are
1000 references to a reference to an array, thus references to a I<scalar>.
1001 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1002 overloaded operations.
1003
1004 =back
1005
1006 =head2 Symbolic calculator
1007
1008 Put this in F<symbolic.pm> in your Perl library directory:
1009
1010   package symbolic;             # Primitive symbolic calculator
1011   use overload nomethod => \&wrap;
1012
1013   sub new { shift; bless ['n', @_] }
1014   sub wrap {
1015     my ($obj, $other, $inv, $meth) = @_;
1016     ($obj, $other) = ($other, $obj) if $inv;
1017     bless [$meth, $obj, $other];
1018   }
1019
1020 This module is very unusual as overloaded modules go: it does not
1021 provide any usual overloaded operators, instead it provides the L<Last
1022 Resort> operator C<nomethod>.  In this example the corresponding
1023 subroutine returns an object which encapsulates operations done over
1024 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1025 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1026
1027 Here is an example of the script which "calculates" the side of
1028 circumscribed octagon using the above package:
1029
1030   require symbolic;
1031   my $iter = 1;                 # 2**($iter+2) = 8
1032   my $side = new symbolic 1;
1033   my $cnt = $iter;
1034
1035   while ($cnt--) {
1036     $side = (sqrt(1 + $side**2) - 1)/$side;
1037   }
1038   print "OK\n";
1039
1040 The value of $side is
1041
1042   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1043                        undef], 1], ['n', 1]]
1044
1045 Note that while we obtained this value using a nice little script,
1046 there is no simple way to I<use> this value.  In fact this value may
1047 be inspected in debugger (see L<perldebug>), but ony if
1048 C<bareStringify> B<O>ption is set, and not via C<p> command.
1049
1050 If one attempts to print this value, then the overloaded operator
1051 C<""> will be called, which will call C<nomethod> operator.  The
1052 result of this operator will be stringified again, but this result is
1053 again of type C<symbolic>, which will lead to an infinite loop.
1054
1055 Add a pretty-printer method to the module F<symbolic.pm>:
1056
1057   sub pretty {
1058     my ($meth, $a, $b) = @{+shift};
1059     $a = 'u' unless defined $a;
1060     $b = 'u' unless defined $b;
1061     $a = $a->pretty if ref $a;
1062     $b = $b->pretty if ref $b;
1063     "[$meth $a $b]";
1064   }
1065
1066 Now one can finish the script by
1067
1068   print "side = ", $side->pretty, "\n";
1069
1070 The method C<pretty> is doing object-to-string conversion, so it
1071 is natural to overload the operator C<""> using this method.  However,
1072 inside such a method it is not necessary to pretty-print the
1073 I<components> $a and $b of an object.  In the above subroutine
1074 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1075 and $b.  If these components use overloading, the catenation operator
1076 will look for an overloaded operator C<.>, if not present, it will
1077 look for an overloaded operator C<"">.  Thus it is enough to use
1078
1079   use overload nomethod => \&wrap, '""' => \&str;
1080   sub str {
1081     my ($meth, $a, $b) = @{+shift};
1082     $a = 'u' unless defined $a;
1083     $b = 'u' unless defined $b;
1084     "[$meth $a $b]";
1085   }
1086
1087 Now one can change the last line of the script to
1088
1089   print "side = $side\n";
1090
1091 which outputs
1092
1093   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1094
1095 and one can inspect the value in debugger using all the possible
1096 methods.
1097
1098 Something is is still amiss: consider the loop variable $cnt of the
1099 script.  It was a number, not an object.  We cannot make this value of
1100 type C<symbolic>, since then the loop will not terminate.
1101
1102 Indeed, to terminate the cycle, the $cnt should become false.
1103 However, the operator C<bool> for checking falsity is overloaded (this
1104 time via overloaded C<"">), and returns a long string, thus any object
1105 of type C<symbolic> is true.  To overcome this, we need a way to
1106 compare an object to 0.  In fact, it is easier to write a numeric
1107 conversion routine.
1108
1109 Here is the text of F<symbolic.pm> with such a routine added (and
1110 slightly modified str()):
1111
1112   package symbolic;             # Primitive symbolic calculator
1113   use overload
1114     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1115
1116   sub new { shift; bless ['n', @_] }
1117   sub wrap {
1118     my ($obj, $other, $inv, $meth) = @_;
1119     ($obj, $other) = ($other, $obj) if $inv;
1120     bless [$meth, $obj, $other];
1121   }
1122   sub str {
1123     my ($meth, $a, $b) = @{+shift};
1124     $a = 'u' unless defined $a;
1125     if (defined $b) {
1126       "[$meth $a $b]";
1127     } else {
1128       "[$meth $a]";
1129     }
1130   }
1131   my %subr = ( n => sub {$_[0]},
1132                sqrt => sub {sqrt $_[0]},
1133                '-' => sub {shift() - shift()},
1134                '+' => sub {shift() + shift()},
1135                '/' => sub {shift() / shift()},
1136                '*' => sub {shift() * shift()},
1137                '**' => sub {shift() ** shift()},
1138              );
1139   sub num {
1140     my ($meth, $a, $b) = @{+shift};
1141     my $subr = $subr{$meth}
1142       or die "Do not know how to ($meth) in symbolic";
1143     $a = $a->num if ref $a eq __PACKAGE__;
1144     $b = $b->num if ref $b eq __PACKAGE__;
1145     $subr->($a,$b);
1146   }
1147
1148 All the work of numeric conversion is done in %subr and num().  Of
1149 course, %subr is not complete, it contains only operators used in the
1150 example below.  Here is the extra-credit question: why do we need an
1151 explicit recursion in num()?  (Answer is at the end of this section.)
1152
1153 Use this module like this:
1154
1155   require symbolic;
1156   my $iter = new symbolic 2;    # 16-gon
1157   my $side = new symbolic 1;
1158   my $cnt = $iter;
1159
1160   while ($cnt) {
1161     $cnt = $cnt - 1;            # Mutator `--' not implemented
1162     $side = (sqrt(1 + $side**2) - 1)/$side;
1163   }
1164   printf "%s=%f\n", $side, $side;
1165   printf "pi=%f\n", $side*(2**($iter+2));
1166
1167 It prints (without so many line breaks)
1168
1169   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1170                           [n 1]] 2]]] 1]
1171      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1172   pi=3.182598
1173
1174 The above module is very primitive.  It does not implement
1175 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1176 (not required without mutators!), and implements only those arithmetic
1177 operations which are used in the example.
1178
1179 To implement most arithmetic operations is easy, one should just use
1180 the tables of operations, and change the code which fills %subr to
1181
1182   my %subr = ( 'n' => sub {$_[0]} );
1183   foreach my $op (split " ", $overload::ops{with_assign}) {
1184     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1185   }
1186   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1187   foreach my $op (split " ", "@overload::ops{ @bins }") {
1188     $subr{$op} = eval "sub {shift() $op shift()}";
1189   }
1190   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1191     print "defining `$op'\n";
1192     $subr{$op} = eval "sub {$op shift()}";
1193   }
1194
1195 Due to L<Calling Conventions for Mutators>, we do not need anything
1196 special to make C<+=> and friends work, except filling C<+=> entry of
1197 %subr, and defining a copy constructor (needed since Perl has no
1198 way to know that the implementation of C<'+='> does not mutate
1199 the argument, compare L<Copy Constructor>).
1200
1201 To implement a copy constructor, add C<'=' => \&cpy> to C<use overload>
1202 line, and code (this code assumes that mutators change things one level
1203 deep only, so recursive copying is not needed):
1204
1205   sub cpy {
1206     my $self = shift;
1207     bless [@$self], ref $self;
1208   }
1209
1210 To make C<++> and C<--> work, we need to implement actual mutators,
1211 either directly, or in C<nomethod>.  We continue to do things inside
1212 C<nomethod>, thus add
1213
1214     if ($meth eq '++' or $meth eq '--') {
1215       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1216       return $obj;
1217     }
1218
1219 after the first line of wrap().  This is not a most effective
1220 implementation, one may consider
1221
1222   sub inc { $_[0] = bless ['++', shift, 1]; }
1223
1224 instead.
1225
1226 As a final remark, note that one can fill %subr by
1227
1228   my %subr = ( 'n' => sub {$_[0]} );
1229   foreach my $op (split " ", $overload::ops{with_assign}) {
1230     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1231   }
1232   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1233   foreach my $op (split " ", "@overload::ops{ @bins }") {
1234     $subr{$op} = eval "sub {shift() $op shift()}";
1235   }
1236   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1237     $subr{$op} = eval "sub {$op shift()}";
1238   }
1239   $subr{'++'} = $subr{'+'};
1240   $subr{'--'} = $subr{'-'};
1241
1242 This finishes implementation of a primitive symbolic calculator in
1243 50 lines of Perl code.  Since the numeric values of subexpressions
1244 are not cached, the calculator is very slow.
1245
1246 Here is the answer for the exercise: In the case of str(), we need no
1247 explicit recursion since the overloaded C<.>-operator will fall back
1248 to an existing overloaded operator C<"">.  Overloaded arithmetic
1249 operators I<do not> fall back to numeric conversion if C<fallback> is
1250 not explicitly requested.  Thus without an explicit recursion num()
1251 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1252 the argument of num().
1253
1254 If you wonder why defaults for conversion are different for str() and
1255 num(), note how easy it was to write the symbolic calculator.  This
1256 simplicity is due to an appropriate choice of defaults.  One extra
1257 note: due to the explicit recursion num() is more fragile than sym():
1258 we need to explicitly check for the type of $a and $b.  If components
1259 $a and $b happen to be of some related type, this may lead to problems.
1260
1261 =head2 I<Really> symbolic calculator
1262
1263 One may wonder why we call the above calculator symbolic.  The reason
1264 is that the actual calculation of the value of expression is postponed
1265 until the value is I<used>.
1266
1267 To see it in action, add a method
1268
1269   sub STORE {
1270     my $obj = shift;
1271     $#$obj = 1;
1272     @$obj->[0,1] = ('=', shift);
1273   }
1274
1275 to the package C<symbolic>.  After this change one can do
1276
1277   my $a = new symbolic 3;
1278   my $b = new symbolic 4;
1279   my $c = sqrt($a**2 + $b**2);
1280
1281 and the numeric value of $c becomes 5.  However, after calling
1282
1283   $a->STORE(12);  $b->STORE(5);
1284
1285 the numeric value of $c becomes 13.  There is no doubt now that the module
1286 symbolic provides a I<symbolic> calculator indeed.
1287
1288 To hide the rough edges under the hood, provide a tie()d interface to the
1289 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1290
1291   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1292   sub FETCH { shift }
1293   sub nop {  }          # Around a bug
1294
1295 (the bug is described in L<"BUGS">).  One can use this new interface as
1296
1297   tie $a, 'symbolic', 3;
1298   tie $b, 'symbolic', 4;
1299   $a->nop;  $b->nop;    # Around a bug
1300
1301   my $c = sqrt($a**2 + $b**2);
1302
1303 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1304 of $c becomes 13.  To insulate the user of the module add a method
1305
1306   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1307
1308 Now
1309
1310   my ($a, $b);
1311   symbolic->vars($a, $b);
1312   my $c = sqrt($a**2 + $b**2);
1313
1314   $a = 3; $b = 4;
1315   printf "c5  %s=%f\n", $c, $c;
1316
1317   $a = 12; $b = 5;
1318   printf "c13  %s=%f\n", $c, $c;
1319
1320 shows that the numeric value of $c follows changes to the values of $a
1321 and $b.
1322
1323 =head1 AUTHOR
1324
1325 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1326
1327 =head1 DIAGNOSTICS
1328
1329 When Perl is run with the B<-Do> switch or its equivalent, overloading
1330 induces diagnostic messages.
1331
1332 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1333 deduce which operations are overloaded (and which ancestor triggers
1334 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1335 is shown by debugger. The method C<()> corresponds to the C<fallback>
1336 key (in fact a presence of this method shows that this package has
1337 overloading enabled, and it is what is used by the C<Overloaded>
1338 function of module C<overload>).
1339
1340 =head1 BUGS
1341
1342 Because it is used for overloading, the per-package hash %OVERLOAD now
1343 has a special meaning in Perl. The symbol table is filled with names
1344 looking like line-noise.
1345
1346 For the purpose of inheritance every overloaded package behaves as if
1347 C<fallback> is present (possibly undefined). This may create
1348 interesting effects if some package is not overloaded, but inherits
1349 from two overloaded packages.
1350
1351 Relation between overloading and tie()ing is broken.  Overloading is
1352 triggered or not basing on the I<previous> class of tie()d value.
1353
1354 This happens because the presence of overloading is checked too early,
1355 before any tie()d access is attempted.  If the FETCH()ed class of the
1356 tie()d value does not change, a simple workaround is to access the value
1357 immediately after tie()ing, so that after this call the I<previous> class
1358 coincides with the current one.
1359
1360 B<Needed:> a way to fix this without a speed penalty.
1361
1362 Barewords are not covered by overloaded string constants.
1363
1364 This document is confusing.  There are grammos and misleading language
1365 used in places.  It would seem a total rewrite is needed.
1366
1367 =cut
1368