This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
better document version check aspect of "use"
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance,
20 L<C<splice>|/splice ARRAY,OFFSET,LENGTH,LIST> has three scalar arguments
21 followed by a list, whereas L<C<gethostbyname>|/gethostbyname NAME> has
22 four scalar arguments.
23
24 In the syntax descriptions that follow, list operators that expect a
25 list (and provide list context for elements of the list) are shown
26 with LIST as an argument.  Such a list may consist of any combination
27 of scalar arguments or list values; the list values will be included
28 in the list as if each individual element were interpolated at that
29 point in the list, forming a longer single-dimensional list value.
30 Commas should separate literal elements of the LIST.
31
32 Any function in the list below may be used either with or without
33 parentheses around its arguments.  (The syntax descriptions omit the
34 parentheses.)  If you use parentheses, the simple but occasionally
35 surprising rule is this: It I<looks> like a function, therefore it I<is> a
36 function, and precedence doesn't matter.  Otherwise it's a list
37 operator or unary operator, and precedence does matter.  Whitespace
38 between the function and left parenthesis doesn't count, so sometimes
39 you need to be careful:
40
41     print 1+2+4;      # Prints 7.
42     print(1+2) + 4;   # Prints 3.
43     print (1+2)+4;    # Also prints 3!
44     print +(1+2)+4;   # Prints 7.
45     print ((1+2)+4);  # Prints 7.
46
47 If you run Perl with the L<C<use warnings>|warnings> pragma, it can warn
48 you about this.  For example, the third line above produces:
49
50     print (...) interpreted as function at - line 1.
51     Useless use of integer addition in void context at - line 1.
52
53 A few functions take no arguments at all, and therefore work as neither
54 unary nor list operators.  These include such functions as
55 L<C<time>|/time> and L<C<endpwent>|/endpwent>.  For example,
56 C<time+86_400> always means C<time() + 86_400>.
57
58 For functions that can be used in either a scalar or list context,
59 nonabortive failure is generally indicated in scalar context by
60 returning the undefined value, and in list context by returning the
61 empty list.
62
63 Remember the following important rule: There is B<no rule> that relates
64 the behavior of an expression in list context to its behavior in scalar
65 context, or vice versa.  It might do two totally different things.
66 Each operator and function decides which sort of value would be most
67 appropriate to return in scalar context.  Some operators return the
68 length of the list that would have been returned in list context.  Some
69 operators return the first value in the list.  Some operators return the
70 last value in the list.  Some operators return a count of successful
71 operations.  In general, they do what you want, unless you want
72 consistency.
73 X<context>
74
75 A named array in scalar context is quite different from what would at
76 first glance appear to be a list in scalar context.  You can't get a list
77 like C<(1,2,3)> into being in scalar context, because the compiler knows
78 the context at compile time.  It would generate the scalar comma operator
79 there, not the list concatenation version of the comma.  That means it
80 was never a list to start with.
81
82 In general, functions in Perl that serve as wrappers for system calls
83 ("syscalls") of the same name (like L<chown(2)>, L<fork(2)>,
84 L<closedir(2)>, etc.) return true when they succeed and
85 L<C<undef>|/undef EXPR> otherwise, as is usually mentioned in the
86 descriptions below.  This is different from the C interfaces, which
87 return C<-1> on failure.  Exceptions to this rule include
88 L<C<wait>|/wait>, L<C<waitpid>|/waitpid PID,FLAGS>, and
89 L<C<syscall>|/syscall NUMBER, LIST>.  System calls also set the special
90 L<C<$!>|perlvar/$!> variable on failure.  Other functions do not, except
91 accidentally.
92
93 Extension modules can also hook into the Perl parser to define new
94 kinds of keyword-headed expression.  These may look like functions, but
95 may also look completely different.  The syntax following the keyword
96 is defined entirely by the extension.  If you are an implementor, see
97 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
98 a module, see the module's documentation for details of the syntax that
99 it defines.
100
101 =head2 Perl Functions by Category
102 X<function>
103
104 Here are Perl's functions (including things that look like
105 functions, like some keywords and named operators)
106 arranged by category.  Some functions appear in more
107 than one place.
108
109 =over 4
110
111 =item Functions for SCALARs or strings
112 X<scalar> X<string> X<character>
113
114 =for Pod::Functions =String
115
116 L<C<chomp>|/chomp VARIABLE>, L<C<chop>|/chop VARIABLE>,
117 L<C<chr>|/chr NUMBER>, L<C<crypt>|/crypt PLAINTEXT,SALT>,
118 L<C<fc>|/fc EXPR>, L<C<hex>|/hex EXPR>,
119 L<C<index>|/index STR,SUBSTR,POSITION>, L<C<lc>|/lc EXPR>,
120 L<C<lcfirst>|/lcfirst EXPR>, L<C<length>|/length EXPR>,
121 L<C<oct>|/oct EXPR>, L<C<ord>|/ord EXPR>,
122 L<C<pack>|/pack TEMPLATE,LIST>,
123 L<C<qE<sol>E<sol>>|/qE<sol>STRINGE<sol>>,
124 L<C<qqE<sol>E<sol>>|/qqE<sol>STRINGE<sol>>, L<C<reverse>|/reverse LIST>,
125 L<C<rindex>|/rindex STR,SUBSTR,POSITION>,
126 L<C<sprintf>|/sprintf FORMAT, LIST>,
127 L<C<substr>|/substr EXPR,OFFSET,LENGTH,REPLACEMENT>,
128 L<C<trE<sol>E<sol>E<sol>>|/trE<sol>E<sol>E<sol>>, L<C<uc>|/uc EXPR>,
129 L<C<ucfirst>|/ucfirst EXPR>,
130 L<C<yE<sol>E<sol>E<sol>>|/yE<sol>E<sol>E<sol>>
131
132 L<C<fc>|/fc EXPR> is available only if the
133 L<C<"fc"> feature|feature/The 'fc' feature> is enabled or if it is
134 prefixed with C<CORE::>.  The
135 L<C<"fc"> feature|feature/The 'fc' feature> is enabled automatically
136 with a C<use v5.16> (or higher) declaration in the current scope.
137
138 =item Regular expressions and pattern matching
139 X<regular expression> X<regex> X<regexp>
140
141 =for Pod::Functions =Regexp
142
143 L<C<mE<sol>E<sol>>|/mE<sol>E<sol>>, L<C<pos>|/pos SCALAR>,
144 L<C<qrE<sol>E<sol>>|/qrE<sol>STRINGE<sol>>,
145 L<C<quotemeta>|/quotemeta EXPR>,
146 L<C<sE<sol>E<sol>E<sol>>|/sE<sol>E<sol>E<sol>>,
147 L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>,
148 L<C<study>|/study SCALAR>
149
150 =item Numeric functions
151 X<numeric> X<number> X<trigonometric> X<trigonometry>
152
153 =for Pod::Functions =Math
154
155 L<C<abs>|/abs VALUE>, L<C<atan2>|/atan2 Y,X>, L<C<cos>|/cos EXPR>,
156 L<C<exp>|/exp EXPR>, L<C<hex>|/hex EXPR>, L<C<int>|/int EXPR>,
157 L<C<log>|/log EXPR>, L<C<oct>|/oct EXPR>, L<C<rand>|/rand EXPR>,
158 L<C<sin>|/sin EXPR>, L<C<sqrt>|/sqrt EXPR>, L<C<srand>|/srand EXPR>
159
160 =item Functions for real @ARRAYs
161 X<array>
162
163 =for Pod::Functions =ARRAY
164
165 L<C<each>|/each HASH>, L<C<keys>|/keys HASH>, L<C<pop>|/pop ARRAY>,
166 L<C<push>|/push ARRAY,LIST>, L<C<shift>|/shift ARRAY>,
167 L<C<splice>|/splice ARRAY,OFFSET,LENGTH,LIST>,
168 L<C<unshift>|/unshift ARRAY,LIST>, L<C<values>|/values HASH>
169
170 =item Functions for list data
171 X<list>
172
173 =for Pod::Functions =LIST
174
175 L<C<grep>|/grep BLOCK LIST>, L<C<join>|/join EXPR,LIST>,
176 L<C<map>|/map BLOCK LIST>, L<C<qwE<sol>E<sol>>|/qwE<sol>STRINGE<sol>>,
177 L<C<reverse>|/reverse LIST>, L<C<sort>|/sort SUBNAME LIST>,
178 L<C<unpack>|/unpack TEMPLATE,EXPR>
179
180 =item Functions for real %HASHes
181 X<hash>
182
183 =for Pod::Functions =HASH
184
185 L<C<delete>|/delete EXPR>, L<C<each>|/each HASH>,
186 L<C<exists>|/exists EXPR>, L<C<keys>|/keys HASH>,
187 L<C<values>|/values HASH>
188
189 =item Input and output functions
190 X<I/O> X<input> X<output> X<dbm>
191
192 =for Pod::Functions =I/O
193
194 L<C<binmode>|/binmode FILEHANDLE, LAYER>, L<C<close>|/close FILEHANDLE>,
195 L<C<closedir>|/closedir DIRHANDLE>, L<C<dbmclose>|/dbmclose HASH>,
196 L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>, L<C<die>|/die LIST>,
197 L<C<eof>|/eof FILEHANDLE>, L<C<fileno>|/fileno FILEHANDLE>,
198 L<C<flock>|/flock FILEHANDLE,OPERATION>, L<C<format>|/format>,
199 L<C<getc>|/getc FILEHANDLE>, L<C<print>|/print FILEHANDLE LIST>,
200 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>,
201 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
202 L<C<readdir>|/readdir DIRHANDLE>, L<C<readline>|/readline EXPR>,
203 L<C<rewinddir>|/rewinddir DIRHANDLE>, L<C<say>|/say FILEHANDLE LIST>,
204 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE>,
205 L<C<seekdir>|/seekdir DIRHANDLE,POS>,
206 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT>,
207 L<C<syscall>|/syscall NUMBER, LIST>,
208 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
209 L<C<sysseek>|/sysseek FILEHANDLE,POSITION,WHENCE>,
210 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET>,
211 L<C<tell>|/tell FILEHANDLE>, L<C<telldir>|/telldir DIRHANDLE>,
212 L<C<truncate>|/truncate FILEHANDLE,LENGTH>, L<C<warn>|/warn LIST>,
213 L<C<write>|/write FILEHANDLE>
214
215 L<C<say>|/say FILEHANDLE LIST> is available only if the
216 L<C<"say"> feature|feature/The 'say' feature> is enabled or if it is
217 prefixed with C<CORE::>.  The
218 L<C<"say"> feature|feature/The 'say' feature> is enabled automatically
219 with a C<use v5.10> (or higher) declaration in the current scope.
220
221 =item Functions for fixed-length data or records
222
223 =for Pod::Functions =Binary
224
225 L<C<pack>|/pack TEMPLATE,LIST>,
226 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
227 L<C<syscall>|/syscall NUMBER, LIST>,
228 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
229 L<C<sysseek>|/sysseek FILEHANDLE,POSITION,WHENCE>,
230 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET>,
231 L<C<unpack>|/unpack TEMPLATE,EXPR>, L<C<vec>|/vec EXPR,OFFSET,BITS>
232
233 =item Functions for filehandles, files, or directories
234 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
235
236 =for Pod::Functions =File
237
238 L<C<-I<X>>|/-X FILEHANDLE>, L<C<chdir>|/chdir EXPR>,
239 L<C<chmod>|/chmod LIST>, L<C<chown>|/chown LIST>,
240 L<C<chroot>|/chroot FILENAME>,
241 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>, L<C<glob>|/glob EXPR>,
242 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>,
243 L<C<link>|/link OLDFILE,NEWFILE>, L<C<lstat>|/lstat FILEHANDLE>,
244 L<C<mkdir>|/mkdir FILENAME,MODE>, L<C<open>|/open FILEHANDLE,EXPR>,
245 L<C<opendir>|/opendir DIRHANDLE,EXPR>, L<C<readlink>|/readlink EXPR>,
246 L<C<rename>|/rename OLDNAME,NEWNAME>, L<C<rmdir>|/rmdir FILENAME>,
247 L<C<select>|/select FILEHANDLE>, L<C<stat>|/stat FILEHANDLE>,
248 L<C<symlink>|/symlink OLDFILE,NEWFILE>,
249 L<C<sysopen>|/sysopen FILEHANDLE,FILENAME,MODE>,
250 L<C<umask>|/umask EXPR>, L<C<unlink>|/unlink LIST>,
251 L<C<utime>|/utime LIST>
252
253 =item Keywords related to the control flow of your Perl program
254 X<control flow>
255
256 =for Pod::Functions =Flow
257
258 L<C<break>|/break>, L<C<caller>|/caller EXPR>,
259 L<C<continue>|/continue BLOCK>, L<C<die>|/die LIST>, L<C<do>|/do BLOCK>,
260 L<C<dump>|/dump LABEL>, L<C<eval>|/eval EXPR>,
261 L<C<evalbytes>|/evalbytes EXPR>, L<C<exit>|/exit EXPR>,
262 L<C<__FILE__>|/__FILE__>, L<C<goto>|/goto LABEL>,
263 L<C<last>|/last LABEL>, L<C<__LINE__>|/__LINE__>,
264 L<C<next>|/next LABEL>, L<C<__PACKAGE__>|/__PACKAGE__>,
265 L<C<redo>|/redo LABEL>, L<C<return>|/return EXPR>,
266 L<C<sub>|/sub NAME BLOCK>, L<C<__SUB__>|/__SUB__>,
267 L<C<wantarray>|/wantarray>
268
269 L<C<break>|/break> is available only if you enable the experimental
270 L<C<"switch"> feature|feature/The 'switch' feature> or use the C<CORE::>
271 prefix.  The L<C<"switch"> feature|feature/The 'switch' feature> also
272 enables the C<default>, C<given> and C<when> statements, which are
273 documented in L<perlsyn/"Switch Statements">.
274 The L<C<"switch"> feature|feature/The 'switch' feature> is enabled
275 automatically with a C<use v5.10> (or higher) declaration in the current
276 scope.  In Perl v5.14 and earlier, L<C<continue>|/continue BLOCK>
277 required the L<C<"switch"> feature|feature/The 'switch' feature>, like
278 the other keywords.
279
280 L<C<evalbytes>|/evalbytes EXPR> is only available with the
281 L<C<"evalbytes"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
282 (see L<feature>) or if prefixed with C<CORE::>.  L<C<__SUB__>|/__SUB__>
283 is only available with the
284 L<C<"current_sub"> feature|feature/The 'current_sub' feature> or if
285 prefixed with C<CORE::>.  Both the
286 L<C<"evalbytes">|feature/The 'unicode_eval' and 'evalbytes' features>
287 and L<C<"current_sub">|feature/The 'current_sub' feature> features are
288 enabled automatically with a C<use v5.16> (or higher) declaration in the
289 current scope.
290
291 =item Keywords related to scoping
292
293 =for Pod::Functions =Namespace
294
295 L<C<caller>|/caller EXPR>, L<C<import>|/import LIST>,
296 L<C<local>|/local EXPR>, L<C<my>|/my VARLIST>, L<C<our>|/our VARLIST>,
297 L<C<package>|/package NAMESPACE>, L<C<state>|/state VARLIST>,
298 L<C<use>|/use Module VERSION LIST>
299
300 L<C<state>|/state VARLIST> is available only if the
301 L<C<"state"> feature|feature/The 'state' feature> is enabled or if it is
302 prefixed with C<CORE::>.  The
303 L<C<"state"> feature|feature/The 'state' feature> is enabled
304 automatically with a C<use v5.10> (or higher) declaration in the current
305 scope.
306
307 =item Miscellaneous functions
308
309 =for Pod::Functions =Misc
310
311 L<C<defined>|/defined EXPR>, L<C<formline>|/formline PICTURE,LIST>,
312 L<C<lock>|/lock THING>, L<C<prototype>|/prototype FUNCTION>,
313 L<C<reset>|/reset EXPR>, L<C<scalar>|/scalar EXPR>,
314 L<C<undef>|/undef EXPR>
315
316 =item Functions for processes and process groups
317 X<process> X<pid> X<process id>
318
319 =for Pod::Functions =Process
320
321 L<C<alarm>|/alarm SECONDS>, L<C<exec>|/exec LIST>, L<C<fork>|/fork>,
322 L<C<getpgrp>|/getpgrp PID>, L<C<getppid>|/getppid>,
323 L<C<getpriority>|/getpriority WHICH,WHO>, L<C<kill>|/kill SIGNAL, LIST>,
324 L<C<pipe>|/pipe READHANDLE,WRITEHANDLE>,
325 L<C<qxE<sol>E<sol>>|/qxE<sol>STRINGE<sol>>,
326 L<C<readpipe>|/readpipe EXPR>, L<C<setpgrp>|/setpgrp PID,PGRP>,
327 L<C<setpriority>|/setpriority WHICH,WHO,PRIORITY>,
328 L<C<sleep>|/sleep EXPR>, L<C<system>|/system LIST>, L<C<times>|/times>,
329 L<C<wait>|/wait>, L<C<waitpid>|/waitpid PID,FLAGS>
330
331 =item Keywords related to Perl modules
332 X<module>
333
334 =for Pod::Functions =Modules
335
336 L<C<do>|/do EXPR>, L<C<import>|/import LIST>,
337 L<C<no>|/no MODULE VERSION LIST>, L<C<package>|/package NAMESPACE>,
338 L<C<require>|/require VERSION>, L<C<use>|/use Module VERSION LIST>
339
340 =item Keywords related to classes and object-orientation
341 X<object> X<class> X<package>
342
343 =for Pod::Functions =Objects
344
345 L<C<bless>|/bless REF,CLASSNAME>, L<C<dbmclose>|/dbmclose HASH>,
346 L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>,
347 L<C<package>|/package NAMESPACE>, L<C<ref>|/ref EXPR>,
348 L<C<tie>|/tie VARIABLE,CLASSNAME,LIST>, L<C<tied>|/tied VARIABLE>,
349 L<C<untie>|/untie VARIABLE>, L<C<use>|/use Module VERSION LIST>
350
351 =item Low-level socket functions
352 X<socket> X<sock>
353
354 =for Pod::Functions =Socket
355
356 L<C<accept>|/accept NEWSOCKET,GENERICSOCKET>,
357 L<C<bind>|/bind SOCKET,NAME>, L<C<connect>|/connect SOCKET,NAME>,
358 L<C<getpeername>|/getpeername SOCKET>,
359 L<C<getsockname>|/getsockname SOCKET>,
360 L<C<getsockopt>|/getsockopt SOCKET,LEVEL,OPTNAME>,
361 L<C<listen>|/listen SOCKET,QUEUESIZE>,
362 L<C<recv>|/recv SOCKET,SCALAR,LENGTH,FLAGS>,
363 L<C<send>|/send SOCKET,MSG,FLAGS,TO>,
364 L<C<setsockopt>|/setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL>,
365 L<C<shutdown>|/shutdown SOCKET,HOW>,
366 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL>,
367 L<C<socketpair>|/socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL>
368
369 =item System V interprocess communication functions
370 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
371
372 =for Pod::Functions =SysV
373
374 L<C<msgctl>|/msgctl ID,CMD,ARG>, L<C<msgget>|/msgget KEY,FLAGS>,
375 L<C<msgrcv>|/msgrcv ID,VAR,SIZE,TYPE,FLAGS>,
376 L<C<msgsnd>|/msgsnd ID,MSG,FLAGS>,
377 L<C<semctl>|/semctl ID,SEMNUM,CMD,ARG>,
378 L<C<semget>|/semget KEY,NSEMS,FLAGS>, L<C<semop>|/semop KEY,OPSTRING>,
379 L<C<shmctl>|/shmctl ID,CMD,ARG>, L<C<shmget>|/shmget KEY,SIZE,FLAGS>,
380 L<C<shmread>|/shmread ID,VAR,POS,SIZE>,
381 L<C<shmwrite>|/shmwrite ID,STRING,POS,SIZE>
382
383 =item Fetching user and group info
384 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
385
386 =for Pod::Functions =User
387
388 L<C<endgrent>|/endgrent>, L<C<endhostent>|/endhostent>,
389 L<C<endnetent>|/endnetent>, L<C<endpwent>|/endpwent>,
390 L<C<getgrent>|/getgrent>, L<C<getgrgid>|/getgrgid GID>,
391 L<C<getgrnam>|/getgrnam NAME>, L<C<getlogin>|/getlogin>,
392 L<C<getpwent>|/getpwent>, L<C<getpwnam>|/getpwnam NAME>,
393 L<C<getpwuid>|/getpwuid UID>, L<C<setgrent>|/setgrent>,
394 L<C<setpwent>|/setpwent>
395
396 =item Fetching network info
397 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
398
399 =for Pod::Functions =Network
400
401 L<C<endprotoent>|/endprotoent>, L<C<endservent>|/endservent>,
402 L<C<gethostbyaddr>|/gethostbyaddr ADDR,ADDRTYPE>,
403 L<C<gethostbyname>|/gethostbyname NAME>, L<C<gethostent>|/gethostent>,
404 L<C<getnetbyaddr>|/getnetbyaddr ADDR,ADDRTYPE>,
405 L<C<getnetbyname>|/getnetbyname NAME>, L<C<getnetent>|/getnetent>,
406 L<C<getprotobyname>|/getprotobyname NAME>,
407 L<C<getprotobynumber>|/getprotobynumber NUMBER>,
408 L<C<getprotoent>|/getprotoent>,
409 L<C<getservbyname>|/getservbyname NAME,PROTO>,
410 L<C<getservbyport>|/getservbyport PORT,PROTO>,
411 L<C<getservent>|/getservent>, L<C<sethostent>|/sethostent STAYOPEN>,
412 L<C<setnetent>|/setnetent STAYOPEN>,
413 L<C<setprotoent>|/setprotoent STAYOPEN>,
414 L<C<setservent>|/setservent STAYOPEN>
415
416 =item Time-related functions
417 X<time> X<date>
418
419 =for Pod::Functions =Time
420
421 L<C<gmtime>|/gmtime EXPR>, L<C<localtime>|/localtime EXPR>,
422 L<C<time>|/time>, L<C<times>|/times>
423
424 =item Non-function keywords
425
426 =for Pod::Functions =!Non-functions
427
428 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
429 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
430 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
431 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
432 C<while>, C<x>, C<xor>
433
434 =back
435
436 =head2 Portability
437 X<portability> X<Unix> X<portable>
438
439 Perl was born in Unix and can therefore access all common Unix
440 system calls.  In non-Unix environments, the functionality of some
441 Unix system calls may not be available or details of the available
442 functionality may differ slightly.  The Perl functions affected
443 by this are:
444
445 L<C<-I<X>>|/-X FILEHANDLE>, L<C<binmode>|/binmode FILEHANDLE, LAYER>,
446 L<C<chmod>|/chmod LIST>, L<C<chown>|/chown LIST>,
447 L<C<chroot>|/chroot FILENAME>, L<C<crypt>|/crypt PLAINTEXT,SALT>,
448 L<C<dbmclose>|/dbmclose HASH>, L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>,
449 L<C<dump>|/dump LABEL>, L<C<endgrent>|/endgrent>,
450 L<C<endhostent>|/endhostent>, L<C<endnetent>|/endnetent>,
451 L<C<endprotoent>|/endprotoent>, L<C<endpwent>|/endpwent>,
452 L<C<endservent>|/endservent>, L<C<exec>|/exec LIST>,
453 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>,
454 L<C<flock>|/flock FILEHANDLE,OPERATION>, L<C<fork>|/fork>,
455 L<C<getgrent>|/getgrent>, L<C<getgrgid>|/getgrgid GID>,
456 L<C<gethostbyname>|/gethostbyname NAME>, L<C<gethostent>|/gethostent>,
457 L<C<getlogin>|/getlogin>,
458 L<C<getnetbyaddr>|/getnetbyaddr ADDR,ADDRTYPE>,
459 L<C<getnetbyname>|/getnetbyname NAME>, L<C<getnetent>|/getnetent>,
460 L<C<getppid>|/getppid>, L<C<getpgrp>|/getpgrp PID>,
461 L<C<getpriority>|/getpriority WHICH,WHO>,
462 L<C<getprotobynumber>|/getprotobynumber NUMBER>,
463 L<C<getprotoent>|/getprotoent>, L<C<getpwent>|/getpwent>,
464 L<C<getpwnam>|/getpwnam NAME>, L<C<getpwuid>|/getpwuid UID>,
465 L<C<getservbyport>|/getservbyport PORT,PROTO>,
466 L<C<getservent>|/getservent>,
467 L<C<getsockopt>|/getsockopt SOCKET,LEVEL,OPTNAME>,
468 L<C<glob>|/glob EXPR>, L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>,
469 L<C<kill>|/kill SIGNAL, LIST>, L<C<link>|/link OLDFILE,NEWFILE>,
470 L<C<lstat>|/lstat FILEHANDLE>, L<C<msgctl>|/msgctl ID,CMD,ARG>,
471 L<C<msgget>|/msgget KEY,FLAGS>,
472 L<C<msgrcv>|/msgrcv ID,VAR,SIZE,TYPE,FLAGS>,
473 L<C<msgsnd>|/msgsnd ID,MSG,FLAGS>, L<C<open>|/open FILEHANDLE,EXPR>,
474 L<C<pipe>|/pipe READHANDLE,WRITEHANDLE>, L<C<readlink>|/readlink EXPR>,
475 L<C<rename>|/rename OLDNAME,NEWNAME>,
476 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT>,
477 L<C<semctl>|/semctl ID,SEMNUM,CMD,ARG>,
478 L<C<semget>|/semget KEY,NSEMS,FLAGS>, L<C<semop>|/semop KEY,OPSTRING>,
479 L<C<setgrent>|/setgrent>, L<C<sethostent>|/sethostent STAYOPEN>,
480 L<C<setnetent>|/setnetent STAYOPEN>, L<C<setpgrp>|/setpgrp PID,PGRP>,
481 L<C<setpriority>|/setpriority WHICH,WHO,PRIORITY>,
482 L<C<setprotoent>|/setprotoent STAYOPEN>, L<C<setpwent>|/setpwent>,
483 L<C<setservent>|/setservent STAYOPEN>,
484 L<C<setsockopt>|/setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL>,
485 L<C<shmctl>|/shmctl ID,CMD,ARG>, L<C<shmget>|/shmget KEY,SIZE,FLAGS>,
486 L<C<shmread>|/shmread ID,VAR,POS,SIZE>,
487 L<C<shmwrite>|/shmwrite ID,STRING,POS,SIZE>,
488 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL>,
489 L<C<socketpair>|/socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL>,
490 L<C<stat>|/stat FILEHANDLE>, L<C<symlink>|/symlink OLDFILE,NEWFILE>,
491 L<C<syscall>|/syscall NUMBER, LIST>,
492 L<C<sysopen>|/sysopen FILEHANDLE,FILENAME,MODE>,
493 L<C<system>|/system LIST>, L<C<times>|/times>,
494 L<C<truncate>|/truncate FILEHANDLE,LENGTH>, L<C<umask>|/umask EXPR>,
495 L<C<unlink>|/unlink LIST>, L<C<utime>|/utime LIST>, L<C<wait>|/wait>,
496 L<C<waitpid>|/waitpid PID,FLAGS>
497
498 For more information about the portability of these functions, see
499 L<perlport> and other available platform-specific documentation.
500
501 =head2 Alphabetical Listing of Perl Functions
502
503 =over
504
505 =item -X FILEHANDLE
506 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
507 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
508
509 =item -X EXPR
510
511 =item -X DIRHANDLE
512
513 =item -X
514
515 =for Pod::Functions a file test (-r, -x, etc)
516
517 A file test, where X is one of the letters listed below.  This unary
518 operator takes one argument, either a filename, a filehandle, or a dirhandle,
519 and tests the associated file to see if something is true about it.  If the
520 argument is omitted, tests L<C<$_>|perlvar/$_>, except for C<-t>, which
521 tests STDIN.  Unless otherwise documented, it returns C<1> for true and
522 C<''> for false.  If the file doesn't exist or can't be examined, it
523 returns L<C<undef>|/undef EXPR> and sets L<C<$!>|perlvar/$!> (errno).
524 Despite the funny names, precedence is the same as any other named unary
525 operator.  The operator may be any of:
526
527     -r  File is readable by effective uid/gid.
528     -w  File is writable by effective uid/gid.
529     -x  File is executable by effective uid/gid.
530     -o  File is owned by effective uid.
531
532     -R  File is readable by real uid/gid.
533     -W  File is writable by real uid/gid.
534     -X  File is executable by real uid/gid.
535     -O  File is owned by real uid.
536
537     -e  File exists.
538     -z  File has zero size (is empty).
539     -s  File has nonzero size (returns size in bytes).
540
541     -f  File is a plain file.
542     -d  File is a directory.
543     -l  File is a symbolic link (false if symlinks aren't
544         supported by the file system).
545     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
546     -S  File is a socket.
547     -b  File is a block special file.
548     -c  File is a character special file.
549     -t  Filehandle is opened to a tty.
550
551     -u  File has setuid bit set.
552     -g  File has setgid bit set.
553     -k  File has sticky bit set.
554
555     -T  File is an ASCII or UTF-8 text file (heuristic guess).
556     -B  File is a "binary" file (opposite of -T).
557
558     -M  Script start time minus file modification time, in days.
559     -A  Same for access time.
560     -C  Same for inode change time (Unix, may differ for other
561         platforms)
562
563 Example:
564
565     while (<>) {
566         chomp;
567         next unless -f $_;  # ignore specials
568         #...
569     }
570
571 Note that C<-s/a/b/> does not do a negated substitution.  Saying
572 C<-exp($foo)> still works as expected, however: only single letters
573 following a minus are interpreted as file tests.
574
575 These operators are exempt from the "looks like a function rule" described
576 above.  That is, an opening parenthesis after the operator does not affect
577 how much of the following code constitutes the argument.  Put the opening
578 parentheses before the operator to separate it from code that follows (this
579 applies only to operators with higher precedence than unary operators, of
580 course):
581
582     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
583     (-s $file) + 1024  # correct
584
585 The interpretation of the file permission operators C<-r>, C<-R>,
586 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
587 of the file and the uids and gids of the user.  There may be other
588 reasons you can't actually read, write, or execute the file: for
589 example network filesystem access controls, ACLs (access control lists),
590 read-only filesystems, and unrecognized executable formats.  Note
591 that the use of these six specific operators to verify if some operation
592 is possible is usually a mistake, because it may be open to race
593 conditions.
594
595 Also note that, for the superuser on the local filesystems, the C<-r>,
596 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
597 if any execute bit is set in the mode.  Scripts run by the superuser
598 may thus need to do a L<C<stat>|/stat FILEHANDLE> to determine the
599 actual mode of the file, or temporarily set their effective uid to
600 something else.
601
602 If you are using ACLs, there is a pragma called L<C<filetest>|filetest>
603 that may produce more accurate results than the bare
604 L<C<stat>|/stat FILEHANDLE> mode bits.
605 When under C<use filetest 'access'>, the above-mentioned filetests
606 test whether the permission can(not) be granted using the L<access(2)>
607 family of system calls.  Also note that the C<-x> and C<-X> tests may
608 under this pragma return true even if there are no execute permission
609 bits set (nor any extra execute permission ACLs).  This strangeness is
610 due to the underlying system calls' definitions.  Note also that, due to
611 the implementation of C<use filetest 'access'>, the C<_> special
612 filehandle won't cache the results of the file tests when this pragma is
613 in effect.  Read the documentation for the L<C<filetest>|filetest>
614 pragma for more information.
615
616 The C<-T> and C<-B> tests work as follows.  The first block or so of
617 the file is examined to see if it is valid UTF-8 that includes non-ASCII
618 characters.  If so, it's a C<-T> file.  Otherwise, that same portion of
619 the file is examined for odd characters such as strange control codes or
620 characters with the high bit set.  If more than a third of the
621 characters are strange, it's a C<-B> file; otherwise it's a C<-T> file.
622 Also, any file containing a zero byte in the examined portion is
623 considered a binary file.  (If executed within the scope of a L<S<use
624 locale>|perllocale> which includes C<LC_CTYPE>, odd characters are
625 anything that isn't a printable nor space in the current locale.)  If
626 C<-T> or C<-B> is used on a filehandle, the current IO buffer is
627 examined
628 rather than the first block.  Both C<-T> and C<-B> return true on an empty
629 file, or a file at EOF when testing a filehandle.  Because you have to
630 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
631 against the file first, as in C<next unless -f $file && -T $file>.
632
633 If any of the file tests (or either the L<C<stat>|/stat FILEHANDLE> or
634 L<C<lstat>|/lstat FILEHANDLE> operator) is given the special filehandle
635 consisting of a solitary underline, then the stat structure of the
636 previous file test (or L<C<stat>|/stat FILEHANDLE> operator) is used,
637 saving a system call.  (This doesn't work with C<-t>, and you need to
638 remember that L<C<lstat>|/lstat FILEHANDLE> and C<-l> leave values in
639 the stat structure for the symbolic link, not the real file.)  (Also, if
640 the stat buffer was filled by an L<C<lstat>|/lstat FILEHANDLE> call,
641 C<-T> and C<-B> will reset it with the results of C<stat _>).
642 Example:
643
644     print "Can do.\n" if -r $a || -w _ || -x _;
645
646     stat($filename);
647     print "Readable\n" if -r _;
648     print "Writable\n" if -w _;
649     print "Executable\n" if -x _;
650     print "Setuid\n" if -u _;
651     print "Setgid\n" if -g _;
652     print "Sticky\n" if -k _;
653     print "Text\n" if -T _;
654     print "Binary\n" if -B _;
655
656 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
657 test operators, in a way that C<-f -w -x $file> is equivalent to
658 C<-x $file && -w _ && -f _>.  (This is only fancy syntax: if you use
659 the return value of C<-f $file> as an argument to another filetest
660 operator, no special magic will happen.)
661
662 Portability issues: L<perlport/-X>.
663
664 To avoid confusing would-be users of your code with mysterious
665 syntax errors, put something like this at the top of your script:
666
667     use 5.010;  # so filetest ops can stack
668
669 =item abs VALUE
670 X<abs> X<absolute>
671
672 =item abs
673
674 =for Pod::Functions absolute value function
675
676 Returns the absolute value of its argument.
677 If VALUE is omitted, uses L<C<$_>|perlvar/$_>.
678
679 =item accept NEWSOCKET,GENERICSOCKET
680 X<accept>
681
682 =for Pod::Functions accept an incoming socket connect
683
684 Accepts an incoming socket connect, just as L<accept(2)>
685 does.  Returns the packed address if it succeeded, false otherwise.
686 See the example in L<perlipc/"Sockets: Client/Server Communication">.
687
688 On systems that support a close-on-exec flag on files, the flag will
689 be set for the newly opened file descriptor, as determined by the
690 value of L<C<$^F>|perlvar/$^F>.  See L<perlvar/$^F>.
691
692 =item alarm SECONDS
693 X<alarm>
694 X<SIGALRM>
695 X<timer>
696
697 =item alarm
698
699 =for Pod::Functions schedule a SIGALRM
700
701 Arranges to have a SIGALRM delivered to this process after the
702 specified number of wallclock seconds has elapsed.  If SECONDS is not
703 specified, the value stored in L<C<$_>|perlvar/$_> is used.  (On some
704 machines, unfortunately, the elapsed time may be up to one second less
705 or more than you specified because of how seconds are counted, and
706 process scheduling may delay the delivery of the signal even further.)
707
708 Only one timer may be counting at once.  Each call disables the
709 previous timer, and an argument of C<0> may be supplied to cancel the
710 previous timer without starting a new one.  The returned value is the
711 amount of time remaining on the previous timer.
712
713 For delays of finer granularity than one second, the L<Time::HiRes> module
714 (from CPAN, and starting from Perl 5.8 part of the standard
715 distribution) provides
716 L<C<ualarm>|Time::HiRes/ualarm ( $useconds [, $interval_useconds ] )>.
717 You may also use Perl's four-argument version of
718 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT> leaving the first three
719 arguments undefined, or you might be able to use the
720 L<C<syscall>|/syscall NUMBER, LIST> interface to access L<setitimer(2)>
721 if your system supports it.  See L<perlfaq8> for details.
722
723 It is usually a mistake to intermix L<C<alarm>|/alarm SECONDS> and
724 L<C<sleep>|/sleep EXPR> calls, because L<C<sleep>|/sleep EXPR> may be
725 internally implemented on your system with L<C<alarm>|/alarm SECONDS>.
726
727 If you want to use L<C<alarm>|/alarm SECONDS> to time out a system call
728 you need to use an L<C<eval>|/eval EXPR>/L<C<die>|/die LIST> pair.  You
729 can't rely on the alarm causing the system call to fail with
730 L<C<$!>|perlvar/$!> set to C<EINTR> because Perl sets up signal handlers
731 to restart system calls on some systems.  Using
732 L<C<eval>|/eval EXPR>/L<C<die>|/die LIST> always works, modulo the
733 caveats given in L<perlipc/"Signals">.
734
735     eval {
736         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
737         alarm $timeout;
738         my $nread = sysread $socket, $buffer, $size;
739         alarm 0;
740     };
741     if ($@) {
742         die unless $@ eq "alarm\n";   # propagate unexpected errors
743         # timed out
744     }
745     else {
746         # didn't
747     }
748
749 For more information see L<perlipc>.
750
751 Portability issues: L<perlport/alarm>.
752
753 =item atan2 Y,X
754 X<atan2> X<arctangent> X<tan> X<tangent>
755
756 =for Pod::Functions arctangent of Y/X in the range -PI to PI
757
758 Returns the arctangent of Y/X in the range -PI to PI.
759
760 For the tangent operation, you may use the
761 L<C<Math::Trig::tan>|Math::Trig/B<tan>> function, or use the familiar
762 relation:
763
764     sub tan { sin($_[0]) / cos($_[0])  }
765
766 The return value for C<atan2(0,0)> is implementation-defined; consult
767 your L<atan2(3)> manpage for more information.
768
769 Portability issues: L<perlport/atan2>.
770
771 =item bind SOCKET,NAME
772 X<bind>
773
774 =for Pod::Functions binds an address to a socket
775
776 Binds a network address to a socket, just as L<bind(2)>
777 does.  Returns true if it succeeded, false otherwise.  NAME should be a
778 packed address of the appropriate type for the socket.  See the examples in
779 L<perlipc/"Sockets: Client/Server Communication">.
780
781 =item binmode FILEHANDLE, LAYER
782 X<binmode> X<binary> X<text> X<DOS> X<Windows>
783
784 =item binmode FILEHANDLE
785
786 =for Pod::Functions prepare binary files for I/O
787
788 Arranges for FILEHANDLE to be read or written in "binary" or "text"
789 mode on systems where the run-time libraries distinguish between
790 binary and text files.  If FILEHANDLE is an expression, the value is
791 taken as the name of the filehandle.  Returns true on success,
792 otherwise it returns L<C<undef>|/undef EXPR> and sets
793 L<C<$!>|perlvar/$!> (errno).
794
795 On some systems (in general, DOS- and Windows-based systems)
796 L<C<binmode>|/binmode FILEHANDLE, LAYER> is necessary when you're not
797 working with a text file.  For the sake of portability it is a good idea
798 always to use it when appropriate, and never to use it when it isn't
799 appropriate.  Also, people can set their I/O to be by default
800 UTF8-encoded Unicode, not bytes.
801
802 In other words: regardless of platform, use
803 L<C<binmode>|/binmode FILEHANDLE, LAYER> on binary data, like images,
804 for example.
805
806 If LAYER is present it is a single string, but may contain multiple
807 directives.  The directives alter the behaviour of the filehandle.
808 When LAYER is present, using binmode on a text file makes sense.
809
810 If LAYER is omitted or specified as C<:raw> the filehandle is made
811 suitable for passing binary data.  This includes turning off possible CRLF
812 translation and marking it as bytes (as opposed to Unicode characters).
813 Note that, despite what may be implied in I<"Programming Perl"> (the
814 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
815 Other layers that would affect the binary nature of the stream are
816 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
817 PERLIO environment variable.
818
819 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
820 form C<:...>, are called I/O I<layers>.  The L<open> pragma can be used to
821 establish default I/O layers.
822
823 I<The LAYER parameter of the L<C<binmode>|/binmode FILEHANDLE, LAYER>
824 function is described as "DISCIPLINE" in "Programming Perl, 3rd
825 Edition".  However, since the publishing of this book, by many known as
826 "Camel III", the consensus of the naming of this functionality has moved
827 from "discipline" to "layer".  All documentation of this version of Perl
828 therefore refers to "layers" rather than to "disciplines".  Now back to
829 the regularly scheduled documentation...>
830
831 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
832 C<:utf8> just marks the data as UTF-8 without further checking,
833 while C<:encoding(UTF-8)> checks the data for actually being valid
834 UTF-8.  More details can be found in L<PerlIO::encoding>.
835
836 In general, L<C<binmode>|/binmode FILEHANDLE, LAYER> should be called
837 after L<C<open>|/open FILEHANDLE,EXPR> but before any I/O is done on the
838 filehandle.  Calling L<C<binmode>|/binmode FILEHANDLE, LAYER> normally
839 flushes any pending buffered output data (and perhaps pending input
840 data) on the handle.  An exception to this is the C<:encoding> layer
841 that changes the default character encoding of the handle.
842 The C<:encoding> layer sometimes needs to be called in
843 mid-stream, and it doesn't flush the stream.  C<:encoding>
844 also implicitly pushes on top of itself the C<:utf8> layer because
845 internally Perl operates on UTF8-encoded Unicode characters.
846
847 The operating system, device drivers, C libraries, and Perl run-time
848 system all conspire to let the programmer treat a single
849 character (C<\n>) as the line terminator, irrespective of external
850 representation.  On many operating systems, the native text file
851 representation matches the internal representation, but on some
852 platforms the external representation of C<\n> is made up of more than
853 one character.
854
855 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
856 a single character to end each line in the external representation of text
857 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
858 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
859 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
860 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
861 two characters C<\cM\cJ>.  That means that if you don't use
862 L<C<binmode>|/binmode FILEHANDLE, LAYER> on these systems, C<\cM\cJ>
863 sequences on disk will be converted to C<\n> on input, and any C<\n> in
864 your program will be converted back to C<\cM\cJ> on output.  This is
865 what you want for text files, but it can be disastrous for binary files.
866
867 Another consequence of using L<C<binmode>|/binmode FILEHANDLE, LAYER>
868 (on some systems) is that special end-of-file markers will be seen as
869 part of the data stream.  For systems from the Microsoft family this
870 means that, if your binary data contain C<\cZ>, the I/O subsystem will
871 regard it as the end of the file, unless you use
872 L<C<binmode>|/binmode FILEHANDLE, LAYER>.
873
874 L<C<binmode>|/binmode FILEHANDLE, LAYER> is important not only for
875 L<C<readline>|/readline EXPR> and L<C<print>|/print FILEHANDLE LIST>
876 operations, but also when using
877 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
878 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE>,
879 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
880 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET> and
881 L<C<tell>|/tell FILEHANDLE> (see L<perlport> for more details).  See the
882 L<C<$E<sol>>|perlvar/$E<sol>> and L<C<$\>|perlvar/$\> variables in
883 L<perlvar> for how to manually set your input and output
884 line-termination sequences.
885
886 Portability issues: L<perlport/binmode>.
887
888 =item bless REF,CLASSNAME
889 X<bless>
890
891 =item bless REF
892
893 =for Pod::Functions create an object
894
895 This function tells the thingy referenced by REF that it is now an object
896 in the CLASSNAME package.  If CLASSNAME is an empty string, it is
897 interpreted as referring to the C<main> package.
898 If CLASSNAME is omitted, the current package
899 is used.  Because a L<C<bless>|/bless REF,CLASSNAME> is often the last
900 thing in a constructor, it returns the reference for convenience.
901 Always use the two-argument version if a derived class might inherit the
902 method doing the blessing.  See L<perlobj> for more about the blessing
903 (and blessings) of objects.
904
905 Consider always blessing objects in CLASSNAMEs that are mixed case.
906 Namespaces with all lowercase names are considered reserved for
907 Perl pragmas.  Builtin types have all uppercase names.  To prevent
908 confusion, you may wish to avoid such package names as well.
909 It is advised to avoid the class name C<0>, because much code erroneously
910 uses the result of L<C<ref>|/ref EXPR> as a truth value.
911
912 See L<perlmod/"Perl Modules">.
913
914 =item break
915
916 =for Pod::Functions +switch break out of a C<given> block
917
918 Break out of a C<given> block.
919
920 L<C<break>|/break> is available only if the
921 L<C<"switch"> feature|feature/The 'switch' feature> is enabled or if it
922 is prefixed with C<CORE::>. The
923 L<C<"switch"> feature|feature/The 'switch' feature> is enabled
924 automatically with a C<use v5.10> (or higher) declaration in the current
925 scope.
926
927 =item caller EXPR
928 X<caller> X<call stack> X<stack> X<stack trace>
929
930 =item caller
931
932 =for Pod::Functions get context of the current subroutine call
933
934 Returns the context of the current pure perl subroutine call.  In scalar
935 context, returns the caller's package name if there I<is> a caller (that is, if
936 we're in a subroutine or L<C<eval>|/eval EXPR> or
937 L<C<require>|/require VERSION>) and the undefined value otherwise.
938 caller never returns XS subs and they are skipped.  The next pure perl
939 sub will appear instead of the XS sub in caller's return values.  In
940 list context, caller returns
941
942        # 0         1          2
943     my ($package, $filename, $line) = caller;
944
945 With EXPR, it returns some extra information that the debugger uses to
946 print a stack trace.  The value of EXPR indicates how many call frames
947 to go back before the current one.
948
949     #  0         1          2      3            4
950  my ($package, $filename, $line, $subroutine, $hasargs,
951
952     #  5          6          7            8       9         10
953     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
954   = caller($i);
955
956 Here, $subroutine is the function that the caller called (rather than the
957 function containing the caller).  Note that $subroutine may be C<(eval)> if
958 the frame is not a subroutine call, but an L<C<eval>|/eval EXPR>.  In
959 such a case additional elements $evaltext and C<$is_require> are set:
960 C<$is_require> is true if the frame is created by a
961 L<C<require>|/require VERSION> or L<C<use>|/use Module VERSION LIST>
962 statement, $evaltext contains the text of the C<eval EXPR> statement.
963 In particular, for an C<eval BLOCK> statement, $subroutine is C<(eval)>,
964 but $evaltext is undefined.  (Note also that each
965 L<C<use>|/use Module VERSION LIST> statement creates a
966 L<C<require>|/require VERSION> frame inside an C<eval EXPR> frame.)
967 $subroutine may also be C<(unknown)> if this particular subroutine
968 happens to have been deleted from the symbol table.  C<$hasargs> is true
969 if a new instance of L<C<@_>|perlvar/@_> was set up for the frame.
970 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
971 compiled with.  C<$hints> corresponds to L<C<$^H>|perlvar/$^H>, and
972 C<$bitmask> corresponds to
973 L<C<${^WARNING_BITS}>|perlvar/${^WARNING_BITS}>.  The C<$hints> and
974 C<$bitmask> values are subject to change between versions of Perl, and
975 are not meant for external use.
976
977 C<$hinthash> is a reference to a hash containing the value of
978 L<C<%^H>|perlvar/%^H> when the caller was compiled, or
979 L<C<undef>|/undef EXPR> if L<C<%^H>|perlvar/%^H> was empty.  Do not
980 modify the values of this hash, as they are the actual values stored in
981 the optree.
982
983 Furthermore, when called from within the DB package in
984 list context, and with an argument, caller returns more
985 detailed information: it sets the list variable C<@DB::args> to be the
986 arguments with which the subroutine was invoked.
987
988 Be aware that the optimizer might have optimized call frames away before
989 L<C<caller>|/caller EXPR> had a chance to get the information.  That
990 means that C<caller(N)> might not return information about the call
991 frame you expect it to, for C<< N > 1 >>.  In particular, C<@DB::args>
992 might have information from the previous time L<C<caller>|/caller EXPR>
993 was called.
994
995 Be aware that setting C<@DB::args> is I<best effort>, intended for
996 debugging or generating backtraces, and should not be relied upon.  In
997 particular, as L<C<@_>|perlvar/@_> contains aliases to the caller's
998 arguments, Perl does not take a copy of L<C<@_>|perlvar/@_>, so
999 C<@DB::args> will contain modifications the subroutine makes to
1000 L<C<@_>|perlvar/@_> or its contents, not the original values at call
1001 time.  C<@DB::args>, like L<C<@_>|perlvar/@_>, does not hold explicit
1002 references to its elements, so under certain cases its elements may have
1003 become freed and reallocated for other variables or temporary values.
1004 Finally, a side effect of the current implementation is that the effects
1005 of C<shift @_> can I<normally> be undone (but not C<pop @_> or other
1006 splicing, I<and> not if a reference to L<C<@_>|perlvar/@_> has been
1007 taken, I<and> subject to the caveat about reallocated elements), so
1008 C<@DB::args> is actually a hybrid of the current state and initial state
1009 of L<C<@_>|perlvar/@_>.  Buyer beware.
1010
1011 =item chdir EXPR
1012 X<chdir>
1013 X<cd>
1014 X<directory, change>
1015
1016 =item chdir FILEHANDLE
1017
1018 =item chdir DIRHANDLE
1019
1020 =item chdir
1021
1022 =for Pod::Functions change your current working directory
1023
1024 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
1025 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
1026 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
1027 variable C<$ENV{'SYS$LOGIN'}> is also checked, and used if it is set.)  If
1028 neither is set, L<C<chdir>|/chdir EXPR> does nothing and fails.  It
1029 returns true on success, false otherwise.  See the example under
1030 L<C<die>|/die LIST>.
1031
1032 On systems that support L<fchdir(2)>, you may pass a filehandle or
1033 directory handle as the argument.  On systems that don't support L<fchdir(2)>,
1034 passing handles raises an exception.
1035
1036 =item chmod LIST
1037 X<chmod> X<permission> X<mode>
1038
1039 =for Pod::Functions changes the permissions on a list of files
1040
1041 Changes the permissions of a list of files.  The first element of the
1042 list must be the numeric mode, which should probably be an octal
1043 number, and which definitely should I<not> be a string of octal digits:
1044 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
1045 successfully changed.  See also L<C<oct>|/oct EXPR> if all you have is a
1046 string.
1047
1048     my $cnt = chmod 0755, "foo", "bar";
1049     chmod 0755, @executables;
1050     my $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
1051                                                 # --w----r-T
1052     my $mode = "0644"; chmod oct($mode), "foo"; # this is better
1053     my $mode = 0644;   chmod $mode, "foo";      # this is best
1054
1055 On systems that support L<fchmod(2)>, you may pass filehandles among the
1056 files.  On systems that don't support L<fchmod(2)>, passing filehandles raises
1057 an exception.  Filehandles must be passed as globs or glob references to be
1058 recognized; barewords are considered filenames.
1059
1060     open(my $fh, "<", "foo");
1061     my $perm = (stat $fh)[2] & 07777;
1062     chmod($perm | 0600, $fh);
1063
1064 You can also import the symbolic C<S_I*> constants from the
1065 L<C<Fcntl>|Fcntl> module:
1066
1067     use Fcntl qw( :mode );
1068     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
1069     # Identical to the chmod 0755 of the example above.
1070
1071 Portability issues: L<perlport/chmod>.
1072
1073 =item chomp VARIABLE
1074 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
1075
1076 =item chomp( LIST )
1077
1078 =item chomp
1079
1080 =for Pod::Functions remove a trailing record separator from a string
1081
1082 This safer version of L<C<chop>|/chop VARIABLE> removes any trailing
1083 string that corresponds to the current value of
1084 L<C<$E<sol>>|perlvar/$E<sol>> (also known as C<$INPUT_RECORD_SEPARATOR>
1085 in the L<C<English>|English> module).  It returns the total
1086 number of characters removed from all its arguments.  It's often used to
1087 remove the newline from the end of an input record when you're worried
1088 that the final record may be missing its newline.  When in paragraph
1089 mode (C<$/ = ''>), it removes all trailing newlines from the string.
1090 When in slurp mode (C<$/ = undef>) or fixed-length record mode
1091 (L<C<$E<sol>>|perlvar/$E<sol>> is a reference to an integer or the like;
1092 see L<perlvar>), L<C<chomp>|/chomp VARIABLE> won't remove anything.
1093 If VARIABLE is omitted, it chomps L<C<$_>|perlvar/$_>.  Example:
1094
1095     while (<>) {
1096         chomp;  # avoid \n on last field
1097         my @array = split(/:/);
1098         # ...
1099     }
1100
1101 If VARIABLE is a hash, it chomps the hash's values, but not its keys,
1102 resetting the L<C<each>|/each HASH> iterator in the process.
1103
1104 You can actually chomp anything that's an lvalue, including an assignment:
1105
1106     chomp(my $cwd = `pwd`);
1107     chomp(my $answer = <STDIN>);
1108
1109 If you chomp a list, each element is chomped, and the total number of
1110 characters removed is returned.
1111
1112 Note that parentheses are necessary when you're chomping anything
1113 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
1114 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
1115 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
1116 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
1117 as C<chomp($a, $b)>.
1118
1119 =item chop VARIABLE
1120 X<chop>
1121
1122 =item chop( LIST )
1123
1124 =item chop
1125
1126 =for Pod::Functions remove the last character from a string
1127
1128 Chops off the last character of a string and returns the character
1129 chopped.  It is much more efficient than C<s/.$//s> because it neither
1130 scans nor copies the string.  If VARIABLE is omitted, chops
1131 L<C<$_>|perlvar/$_>.
1132 If VARIABLE is a hash, it chops the hash's values, but not its keys,
1133 resetting the L<C<each>|/each HASH> iterator in the process.
1134
1135 You can actually chop anything that's an lvalue, including an assignment.
1136
1137 If you chop a list, each element is chopped.  Only the value of the
1138 last L<C<chop>|/chop VARIABLE> is returned.
1139
1140 Note that L<C<chop>|/chop VARIABLE> returns the last character.  To
1141 return all but the last character, use C<substr($string, 0, -1)>.
1142
1143 See also L<C<chomp>|/chomp VARIABLE>.
1144
1145 =item chown LIST
1146 X<chown> X<owner> X<user> X<group>
1147
1148 =for Pod::Functions change the ownership on a list of files
1149
1150 Changes the owner (and group) of a list of files.  The first two
1151 elements of the list must be the I<numeric> uid and gid, in that
1152 order.  A value of -1 in either position is interpreted by most
1153 systems to leave that value unchanged.  Returns the number of files
1154 successfully changed.
1155
1156     my $cnt = chown $uid, $gid, 'foo', 'bar';
1157     chown $uid, $gid, @filenames;
1158
1159 On systems that support L<fchown(2)>, you may pass filehandles among the
1160 files.  On systems that don't support L<fchown(2)>, passing filehandles raises
1161 an exception.  Filehandles must be passed as globs or glob references to be
1162 recognized; barewords are considered filenames.
1163
1164 Here's an example that looks up nonnumeric uids in the passwd file:
1165
1166     print "User: ";
1167     chomp(my $user = <STDIN>);
1168     print "Files: ";
1169     chomp(my $pattern = <STDIN>);
1170
1171     my ($login,$pass,$uid,$gid) = getpwnam($user)
1172         or die "$user not in passwd file";
1173
1174     my @ary = glob($pattern);  # expand filenames
1175     chown $uid, $gid, @ary;
1176
1177 On most systems, you are not allowed to change the ownership of the
1178 file unless you're the superuser, although you should be able to change
1179 the group to any of your secondary groups.  On insecure systems, these
1180 restrictions may be relaxed, but this is not a portable assumption.
1181 On POSIX systems, you can detect this condition this way:
1182
1183     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
1184     my $can_chown_giveaway = ! sysconf(_PC_CHOWN_RESTRICTED);
1185
1186 Portability issues: L<perlport/chown>.
1187
1188 =item chr NUMBER
1189 X<chr> X<character> X<ASCII> X<Unicode>
1190
1191 =item chr
1192
1193 =for Pod::Functions get character this number represents
1194
1195 Returns the character represented by that NUMBER in the character set.
1196 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
1197 chr(0x263a) is a Unicode smiley face.
1198
1199 Negative values give the Unicode replacement character (chr(0xfffd)),
1200 except under the L<bytes> pragma, where the low eight bits of the value
1201 (truncated to an integer) are used.
1202
1203 If NUMBER is omitted, uses L<C<$_>|perlvar/$_>.
1204
1205 For the reverse, use L<C<ord>|/ord EXPR>.
1206
1207 Note that characters from 128 to 255 (inclusive) are by default
1208 internally not encoded as UTF-8 for backward compatibility reasons.
1209
1210 See L<perlunicode> for more about Unicode.
1211
1212 =item chroot FILENAME
1213 X<chroot> X<root>
1214
1215 =item chroot
1216
1217 =for Pod::Functions make directory new root for path lookups
1218
1219 This function works like the system call by the same name: it makes the
1220 named directory the new root directory for all further pathnames that
1221 begin with a C</> by your process and all its children.  (It doesn't
1222 change your current working directory, which is unaffected.)  For security
1223 reasons, this call is restricted to the superuser.  If FILENAME is
1224 omitted, does a L<C<chroot>|/chroot FILENAME> to L<C<$_>|perlvar/$_>.
1225
1226 B<NOTE:>  It is good security practice to do C<chdir("/")>
1227 (L<C<chdir>|/chdir EXPR> to the root directory) immediately after a
1228 L<C<chroot>|/chroot FILENAME>.
1229
1230 Portability issues: L<perlport/chroot>.
1231
1232 =item close FILEHANDLE
1233 X<close>
1234
1235 =item close
1236
1237 =for Pod::Functions close file (or pipe or socket) handle
1238
1239 Closes the file or pipe associated with the filehandle, flushes the IO
1240 buffers, and closes the system file descriptor.  Returns true if those
1241 operations succeed and if no error was reported by any PerlIO
1242 layer.  Closes the currently selected filehandle if the argument is
1243 omitted.
1244
1245 You don't have to close FILEHANDLE if you are immediately going to do
1246 another L<C<open>|/open FILEHANDLE,EXPR> on it, because
1247 L<C<open>|/open FILEHANDLE,EXPR> closes it for you.  (See
1248 L<C<open>|/open FILEHANDLE,EXPR>.) However, an explicit
1249 L<C<close>|/close FILEHANDLE> on an input file resets the line counter
1250 (L<C<$.>|perlvar/$.>), while the implicit close done by
1251 L<C<open>|/open FILEHANDLE,EXPR> does not.
1252
1253 If the filehandle came from a piped open, L<C<close>|/close FILEHANDLE>
1254 returns false if one of the other syscalls involved fails or if its
1255 program exits with non-zero status.  If the only problem was that the
1256 program exited non-zero, L<C<$!>|perlvar/$!> will be set to C<0>.
1257 Closing a pipe also waits for the process executing on the pipe to
1258 exit--in case you wish to look at the output of the pipe afterwards--and
1259 implicitly puts the exit status value of that command into
1260 L<C<$?>|perlvar/$?> and
1261 L<C<${^CHILD_ERROR_NATIVE}>|perlvar/${^CHILD_ERROR_NATIVE}>.
1262
1263 If there are multiple threads running, L<C<close>|/close FILEHANDLE> on
1264 a filehandle from a piped open returns true without waiting for the
1265 child process to terminate, if the filehandle is still open in another
1266 thread.
1267
1268 Closing the read end of a pipe before the process writing to it at the
1269 other end is done writing results in the writer receiving a SIGPIPE.  If
1270 the other end can't handle that, be sure to read all the data before
1271 closing the pipe.
1272
1273 Example:
1274
1275     open(OUTPUT, '|sort >foo')  # pipe to sort
1276         or die "Can't start sort: $!";
1277     #...                        # print stuff to output
1278     close OUTPUT                # wait for sort to finish
1279         or warn $! ? "Error closing sort pipe: $!"
1280                    : "Exit status $? from sort";
1281     open(INPUT, 'foo')          # get sort's results
1282         or die "Can't open 'foo' for input: $!";
1283
1284 FILEHANDLE may be an expression whose value can be used as an indirect
1285 filehandle, usually the real filehandle name or an autovivified handle.
1286
1287 =item closedir DIRHANDLE
1288 X<closedir>
1289
1290 =for Pod::Functions close directory handle
1291
1292 Closes a directory opened by L<C<opendir>|/opendir DIRHANDLE,EXPR> and
1293 returns the success of that system call.
1294
1295 =item connect SOCKET,NAME
1296 X<connect>
1297
1298 =for Pod::Functions connect to a remote socket
1299
1300 Attempts to connect to a remote socket, just like L<connect(2)>.
1301 Returns true if it succeeded, false otherwise.  NAME should be a
1302 packed address of the appropriate type for the socket.  See the examples in
1303 L<perlipc/"Sockets: Client/Server Communication">.
1304
1305 =item continue BLOCK
1306 X<continue>
1307
1308 =item continue
1309
1310 =for Pod::Functions optional trailing block in a while or foreach
1311
1312 When followed by a BLOCK, L<C<continue>|/continue BLOCK> is actually a
1313 flow control statement rather than a function.  If there is a
1314 L<C<continue>|/continue BLOCK> BLOCK attached to a BLOCK (typically in a
1315 C<while> or C<foreach>), it is always executed just before the
1316 conditional is about to be evaluated again, just like the third part of
1317 a C<for> loop in C.  Thus it can be used to increment a loop variable,
1318 even when the loop has been continued via the L<C<next>|/next LABEL>
1319 statement (which is similar to the C L<C<continue>|/continue BLOCK>
1320 statement).
1321
1322 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, or
1323 L<C<redo>|/redo LABEL> may appear within a
1324 L<C<continue>|/continue BLOCK> block; L<C<last>|/last LABEL> and
1325 L<C<redo>|/redo LABEL> behave as if they had been executed within the
1326 main block.  So will L<C<next>|/next LABEL>, but since it will execute a
1327 L<C<continue>|/continue BLOCK> block, it may be more entertaining.
1328
1329     while (EXPR) {
1330         ### redo always comes here
1331         do_something;
1332     } continue {
1333         ### next always comes here
1334         do_something_else;
1335         # then back the top to re-check EXPR
1336     }
1337     ### last always comes here
1338
1339 Omitting the L<C<continue>|/continue BLOCK> section is equivalent to
1340 using an empty one, logically enough, so L<C<next>|/next LABEL> goes
1341 directly back to check the condition at the top of the loop.
1342
1343 When there is no BLOCK, L<C<continue>|/continue BLOCK> is a function
1344 that falls through the current C<when> or C<default> block instead of
1345 iterating a dynamically enclosing C<foreach> or exiting a lexically
1346 enclosing C<given>.  In Perl 5.14 and earlier, this form of
1347 L<C<continue>|/continue BLOCK> was only available when the
1348 L<C<"switch"> feature|feature/The 'switch' feature> was enabled.  See
1349 L<feature> and L<perlsyn/"Switch Statements"> for more information.
1350
1351 =item cos EXPR
1352 X<cos> X<cosine> X<acos> X<arccosine>
1353
1354 =item cos
1355
1356 =for Pod::Functions cosine function
1357
1358 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1359 takes the cosine of L<C<$_>|perlvar/$_>.
1360
1361 For the inverse cosine operation, you may use the
1362 L<C<Math::Trig::acos>|Math::Trig> function, or use this relation:
1363
1364     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1365
1366 =item crypt PLAINTEXT,SALT
1367 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1368 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1369
1370 =for Pod::Functions one-way passwd-style encryption
1371
1372 Creates a digest string exactly like the L<crypt(3)> function in the C
1373 library (assuming that you actually have a version there that has not
1374 been extirpated as a potential munition).
1375
1376 L<C<crypt>|/crypt PLAINTEXT,SALT> is a one-way hash function.  The
1377 PLAINTEXT and SALT are turned
1378 into a short string, called a digest, which is returned.  The same
1379 PLAINTEXT and SALT will always return the same string, but there is no
1380 (known) way to get the original PLAINTEXT from the hash.  Small
1381 changes in the PLAINTEXT or SALT will result in large changes in the
1382 digest.
1383
1384 There is no decrypt function.  This function isn't all that useful for
1385 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1386 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1387 primarily used to check if two pieces of text are the same without
1388 having to transmit or store the text itself.  An example is checking
1389 if a correct password is given.  The digest of the password is stored,
1390 not the password itself.  The user types in a password that is
1391 L<C<crypt>|/crypt PLAINTEXT,SALT>'d with the same salt as the stored
1392 digest.  If the two digests match, the password is correct.
1393
1394 When verifying an existing digest string you should use the digest as
1395 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1396 to create the digest is visible as part of the digest.  This ensures
1397 L<C<crypt>|/crypt PLAINTEXT,SALT> will hash the new string with the same
1398 salt as the digest.  This allows your code to work with the standard
1399 L<C<crypt>|/crypt PLAINTEXT,SALT> and with more exotic implementations.
1400 In other words, assume nothing about the returned string itself nor
1401 about how many bytes of SALT may matter.
1402
1403 Traditionally the result is a string of 13 bytes: two first bytes of
1404 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1405 the first eight bytes of PLAINTEXT mattered.  But alternative
1406 hashing schemes (like MD5), higher level security schemes (like C2),
1407 and implementations on non-Unix platforms may produce different
1408 strings.
1409
1410 When choosing a new salt create a random two character string whose
1411 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1412 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1413 characters is just a recommendation; the characters allowed in
1414 the salt depend solely on your system's crypt library, and Perl can't
1415 restrict what salts L<C<crypt>|/crypt PLAINTEXT,SALT> accepts.
1416
1417 Here's an example that makes sure that whoever runs this program knows
1418 their password:
1419
1420     my $pwd = (getpwuid($<))[1];
1421
1422     system "stty -echo";
1423     print "Password: ";
1424     chomp(my $word = <STDIN>);
1425     print "\n";
1426     system "stty echo";
1427
1428     if (crypt($word, $pwd) ne $pwd) {
1429         die "Sorry...\n";
1430     } else {
1431         print "ok\n";
1432     }
1433
1434 Of course, typing in your own password to whoever asks you
1435 for it is unwise.
1436
1437 The L<C<crypt>|/crypt PLAINTEXT,SALT> function is unsuitable for hashing
1438 large quantities of data, not least of all because you can't get the
1439 information back.  Look at the L<Digest> module for more robust
1440 algorithms.
1441
1442 If using L<C<crypt>|/crypt PLAINTEXT,SALT> on a Unicode string (which
1443 I<potentially> has characters with codepoints above 255), Perl tries to
1444 make sense of the situation by trying to downgrade (a copy of) the
1445 string back to an eight-bit byte string before calling
1446 L<C<crypt>|/crypt PLAINTEXT,SALT> (on that copy).  If that works, good.
1447 If not, L<C<crypt>|/crypt PLAINTEXT,SALT> dies with
1448 L<C<Wide character in crypt>|perldiag/Wide character in %s>.
1449
1450 Portability issues: L<perlport/crypt>.
1451
1452 =item dbmclose HASH
1453 X<dbmclose>
1454
1455 =for Pod::Functions breaks binding on a tied dbm file
1456
1457 [This function has been largely superseded by the
1458 L<C<untie>|/untie VARIABLE> function.]
1459
1460 Breaks the binding between a DBM file and a hash.
1461
1462 Portability issues: L<perlport/dbmclose>.
1463
1464 =item dbmopen HASH,DBNAME,MASK
1465 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1466
1467 =for Pod::Functions create binding on a tied dbm file
1468
1469 [This function has been largely superseded by the
1470 L<C<tie>|/tie VARIABLE,CLASSNAME,LIST> function.]
1471
1472 This binds a L<dbm(3)>, L<ndbm(3)>, L<sdbm(3)>, L<gdbm(3)>, or Berkeley
1473 DB file to a hash.  HASH is the name of the hash.  (Unlike normal
1474 L<C<open>|/open FILEHANDLE,EXPR>, the first argument is I<not> a
1475 filehandle, even though it looks like one).  DBNAME is the name of the
1476 database (without the F<.dir> or F<.pag> extension if any).  If the
1477 database does not exist, it is created with protection specified by MASK
1478 (as modified by the L<C<umask>|/umask EXPR>).  To prevent creation of
1479 the database if it doesn't exist, you may specify a MODE of 0, and the
1480 function will return a false value if it can't find an existing
1481 database.  If your system supports only the older DBM functions, you may
1482 make only one L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK> call in your
1483 program.  In older versions of Perl, if your system had neither DBM nor
1484 ndbm, calling L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK> produced a fatal
1485 error; it now falls back to L<sdbm(3)>.
1486
1487 If you don't have write access to the DBM file, you can only read hash
1488 variables, not set them.  If you want to test whether you can write,
1489 either use file tests or try setting a dummy hash entry inside an
1490 L<C<eval>|/eval EXPR> to trap the error.
1491
1492 Note that functions such as L<C<keys>|/keys HASH> and
1493 L<C<values>|/values HASH> may return huge lists when used on large DBM
1494 files.  You may prefer to use the L<C<each>|/each HASH> function to
1495 iterate over large DBM files.  Example:
1496
1497     # print out history file offsets
1498     dbmopen(%HIST,'/usr/lib/news/history',0666);
1499     while (($key,$val) = each %HIST) {
1500         print $key, ' = ', unpack('L',$val), "\n";
1501     }
1502     dbmclose(%HIST);
1503
1504 See also L<AnyDBM_File> for a more general description of the pros and
1505 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1506 rich implementation.
1507
1508 You can control which DBM library you use by loading that library
1509 before you call L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>:
1510
1511     use DB_File;
1512     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1513         or die "Can't open netscape history file: $!";
1514
1515 Portability issues: L<perlport/dbmopen>.
1516
1517 =item defined EXPR
1518 X<defined> X<undef> X<undefined>
1519
1520 =item defined
1521
1522 =for Pod::Functions test whether a value, variable, or function is defined
1523
1524 Returns a Boolean value telling whether EXPR has a value other than the
1525 undefined value L<C<undef>|/undef EXPR>.  If EXPR is not present,
1526 L<C<$_>|perlvar/$_> is checked.
1527
1528 Many operations return L<C<undef>|/undef EXPR> to indicate failure, end
1529 of file, system error, uninitialized variable, and other exceptional
1530 conditions.  This function allows you to distinguish
1531 L<C<undef>|/undef EXPR> from other values.  (A simple Boolean test will
1532 not distinguish among L<C<undef>|/undef EXPR>, zero, the empty string,
1533 and C<"0">, which are all equally false.)  Note that since
1534 L<C<undef>|/undef EXPR> is a valid scalar, its presence doesn't
1535 I<necessarily> indicate an exceptional condition: L<C<pop>|/pop ARRAY>
1536 returns L<C<undef>|/undef EXPR> when its argument is an empty array,
1537 I<or> when the element to return happens to be L<C<undef>|/undef EXPR>.
1538
1539 You may also use C<defined(&func)> to check whether subroutine C<func>
1540 has ever been defined.  The return value is unaffected by any forward
1541 declarations of C<func>.  A subroutine that is not defined
1542 may still be callable: its package may have an C<AUTOLOAD> method that
1543 makes it spring into existence the first time that it is called; see
1544 L<perlsub>.
1545
1546 Use of L<C<defined>|/defined EXPR> on aggregates (hashes and arrays) is
1547 no longer supported. It used to report whether memory for that
1548 aggregate had ever been allocated.  You should instead use a simple
1549 test for size:
1550
1551     if (@an_array) { print "has array elements\n" }
1552     if (%a_hash)   { print "has hash members\n"   }
1553
1554 When used on a hash element, it tells you whether the value is defined,
1555 not whether the key exists in the hash.  Use L<C<exists>|/exists EXPR>
1556 for the latter purpose.
1557
1558 Examples:
1559
1560     print if defined $switch{D};
1561     print "$val\n" while defined($val = pop(@ary));
1562     die "Can't readlink $sym: $!"
1563         unless defined($value = readlink $sym);
1564     sub foo { defined &$bar ? $bar->(@_) : die "No bar"; }
1565     $debugging = 0 unless defined $debugging;
1566
1567 Note:  Many folks tend to overuse L<C<defined>|/defined EXPR> and are
1568 then surprised to discover that the number C<0> and C<""> (the
1569 zero-length string) are, in fact, defined values.  For example, if you
1570 say
1571
1572     "ab" =~ /a(.*)b/;
1573
1574 The pattern match succeeds and C<$1> is defined, although it
1575 matched "nothing".  It didn't really fail to match anything.  Rather, it
1576 matched something that happened to be zero characters long.  This is all
1577 very above-board and honest.  When a function returns an undefined value,
1578 it's an admission that it couldn't give you an honest answer.  So you
1579 should use L<C<defined>|/defined EXPR> only when questioning the
1580 integrity of what you're trying to do.  At other times, a simple
1581 comparison to C<0> or C<""> is what you want.
1582
1583 See also L<C<undef>|/undef EXPR>, L<C<exists>|/exists EXPR>,
1584 L<C<ref>|/ref EXPR>.
1585
1586 =item delete EXPR
1587 X<delete>
1588
1589 =for Pod::Functions deletes a value from a hash
1590
1591 Given an expression that specifies an element or slice of a hash,
1592 L<C<delete>|/delete EXPR> deletes the specified elements from that hash
1593 so that L<C<exists>|/exists EXPR> on that element no longer returns
1594 true.  Setting a hash element to the undefined value does not remove its
1595 key, but deleting it does; see L<C<exists>|/exists EXPR>.
1596
1597 In list context, returns the value or values deleted, or the last such
1598 element in scalar context.  The return list's length always matches that of
1599 the argument list: deleting non-existent elements returns the undefined value
1600 in their corresponding positions.
1601
1602 L<C<delete>|/delete EXPR> may also be used on arrays and array slices,
1603 but its behavior is less straightforward.  Although
1604 L<C<exists>|/exists EXPR> will return false for deleted entries,
1605 deleting array elements never changes indices of existing values; use
1606 L<C<shift>|/shift ARRAY> or L<C<splice>|/splice
1607 ARRAY,OFFSET,LENGTH,LIST> for that.  However, if any deleted elements
1608 fall at the end of an array, the array's size shrinks to the position of
1609 the highest element that still tests true for L<C<exists>|/exists EXPR>,
1610 or to 0 if none do.  In other words, an array won't have trailing
1611 nonexistent elements after a delete.
1612
1613 B<WARNING:> Calling L<C<delete>|/delete EXPR> on array values is
1614 strongly discouraged.  The
1615 notion of deleting or checking the existence of Perl array elements is not
1616 conceptually coherent, and can lead to surprising behavior.
1617
1618 Deleting from L<C<%ENV>|perlvar/%ENV> modifies the environment.
1619 Deleting from a hash tied to a DBM file deletes the entry from the DBM
1620 file.  Deleting from a L<C<tied>|/tied VARIABLE> hash or array may not
1621 necessarily return anything; it depends on the implementation of the
1622 L<C<tied>|/tied VARIABLE> package's DELETE method, which may do whatever
1623 it pleases.
1624
1625 The C<delete local EXPR> construct localizes the deletion to the current
1626 block at run time.  Until the block exits, elements locally deleted
1627 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1628 of composite types">.
1629
1630     my %hash = (foo => 11, bar => 22, baz => 33);
1631     my $scalar = delete $hash{foo};         # $scalar is 11
1632     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1633     my @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1634
1635 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1636
1637     foreach my $key (keys %HASH) {
1638         delete $HASH{$key};
1639     }
1640
1641     foreach my $index (0 .. $#ARRAY) {
1642         delete $ARRAY[$index];
1643     }
1644
1645 And so do these:
1646
1647     delete @HASH{keys %HASH};
1648
1649     delete @ARRAY[0 .. $#ARRAY];
1650
1651 But both are slower than assigning the empty list
1652 or undefining %HASH or @ARRAY, which is the customary
1653 way to empty out an aggregate:
1654
1655     %HASH = ();     # completely empty %HASH
1656     undef %HASH;    # forget %HASH ever existed
1657
1658     @ARRAY = ();    # completely empty @ARRAY
1659     undef @ARRAY;   # forget @ARRAY ever existed
1660
1661 The EXPR can be arbitrarily complicated provided its
1662 final operation is an element or slice of an aggregate:
1663
1664     delete $ref->[$x][$y]{$key};
1665     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1666
1667     delete $ref->[$x][$y][$index];
1668     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1669
1670 =item die LIST
1671 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1672
1673 =for Pod::Functions raise an exception or bail out
1674
1675 L<C<die>|/die LIST> raises an exception.  Inside an
1676 L<C<eval>|/eval EXPR> the error message is stuffed into
1677 L<C<$@>|perlvar/$@> and the L<C<eval>|/eval EXPR> is terminated with the
1678 undefined value.  If the exception is outside of all enclosing
1679 L<C<eval>|/eval EXPR>s, then the uncaught exception prints LIST to
1680 C<STDERR> and exits with a non-zero value.  If you need to exit the
1681 process with a specific exit code, see L<C<exit>|/exit EXPR>.
1682
1683 Equivalent examples:
1684
1685     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1686     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1687
1688 If the last element of LIST does not end in a newline, the current
1689 script line number and input line number (if any) are also printed,
1690 and a newline is supplied.  Note that the "input line number" (also
1691 known as "chunk") is subject to whatever notion of "line" happens to
1692 be currently in effect, and is also available as the special variable
1693 L<C<$.>|perlvar/$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1694
1695 Hint: sometimes appending C<", stopped"> to your message will cause it
1696 to make better sense when the string C<"at foo line 123"> is appended.
1697 Suppose you are running script "canasta".
1698
1699     die "/etc/games is no good";
1700     die "/etc/games is no good, stopped";
1701
1702 produce, respectively
1703
1704     /etc/games is no good at canasta line 123.
1705     /etc/games is no good, stopped at canasta line 123.
1706
1707 If the output is empty and L<C<$@>|perlvar/$@> already contains a value
1708 (typically from a previous L<C<eval>|/eval EXPR>) that value is reused after
1709 appending C<"\t...propagated">.  This is useful for propagating exceptions:
1710
1711     eval { ... };
1712     die unless $@ =~ /Expected exception/;
1713
1714 If the output is empty and L<C<$@>|perlvar/$@> contains an object
1715 reference that has a C<PROPAGATE> method, that method will be called
1716 with additional file and line number parameters.  The return value
1717 replaces the value in L<C<$@>|perlvar/$@>;  i.e., as if
1718 C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >> were called.
1719
1720 If L<C<$@>|perlvar/$@> is empty, then the string C<"Died"> is used.
1721
1722 If an uncaught exception results in interpreter exit, the exit code is
1723 determined from the values of L<C<$!>|perlvar/$!> and
1724 L<C<$?>|perlvar/$?> with this pseudocode:
1725
1726     exit $! if $!;              # errno
1727     exit $? >> 8 if $? >> 8;    # child exit status
1728     exit 255;                   # last resort
1729
1730 As with L<C<exit>|/exit EXPR>, L<C<$?>|perlvar/$?> is set prior to
1731 unwinding the call stack; any C<DESTROY> or C<END> handlers can then
1732 alter this value, and thus Perl's exit code.
1733
1734 The intent is to squeeze as much possible information about the likely cause
1735 into the limited space of the system exit code.  However, as
1736 L<C<$!>|perlvar/$!> is the value of C's C<errno>, which can be set by
1737 any system call, this means that the value of the exit code used by
1738 L<C<die>|/die LIST> can be non-predictable, so should not be relied
1739 upon, other than to be non-zero.
1740
1741 You can also call L<C<die>|/die LIST> with a reference argument, and if
1742 this is trapped within an L<C<eval>|/eval EXPR>, L<C<$@>|perlvar/$@>
1743 contains that reference.  This permits more elaborate exception handling
1744 using objects that maintain arbitrary state about the exception.  Such a
1745 scheme is sometimes preferable to matching particular string values of
1746 L<C<$@>|perlvar/$@> with regular expressions.  Because
1747 L<C<$@>|perlvar/$@> is a global variable and L<C<eval>|/eval EXPR> may
1748 be used within object implementations, be careful that analyzing the
1749 error object doesn't replace the reference in the global variable.  It's
1750 easiest to make a local copy of the reference before any manipulations.
1751 Here's an example:
1752
1753     use Scalar::Util "blessed";
1754
1755     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1756     if (my $ev_err = $@) {
1757         if (blessed($ev_err)
1758             && $ev_err->isa("Some::Module::Exception")) {
1759             # handle Some::Module::Exception
1760         }
1761         else {
1762             # handle all other possible exceptions
1763         }
1764     }
1765
1766 Because Perl stringifies uncaught exception messages before display,
1767 you'll probably want to overload stringification operations on
1768 exception objects.  See L<overload> for details about that.
1769
1770 You can arrange for a callback to be run just before the
1771 L<C<die>|/die LIST> does its deed, by setting the
1772 L<C<$SIG{__DIE__}>|perlvar/%SIG> hook.  The associated handler is called
1773 with the error text and can change the error message, if it sees fit, by
1774 calling L<C<die>|/die LIST> again.  See L<perlvar/%SIG> for details on
1775 setting L<C<%SIG>|perlvar/%SIG> entries, and L<C<eval>|/eval EXPR> for some
1776 examples.  Although this feature was to be run only right before your
1777 program was to exit, this is not currently so: the
1778 L<C<$SIG{__DIE__}>|perlvar/%SIG> hook is currently called even inside
1779 L<C<eval>|/eval EXPR>ed blocks/strings!  If one wants the hook to do
1780 nothing in such situations, put
1781
1782     die @_ if $^S;
1783
1784 as the first line of the handler (see L<perlvar/$^S>).  Because
1785 this promotes strange action at a distance, this counterintuitive
1786 behavior may be fixed in a future release.
1787
1788 See also L<C<exit>|/exit EXPR>, L<C<warn>|/warn LIST>, and the L<Carp>
1789 module.
1790
1791 =item do BLOCK
1792 X<do> X<block>
1793
1794 =for Pod::Functions turn a BLOCK into a TERM
1795
1796 Not really a function.  Returns the value of the last command in the
1797 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1798 C<until> loop modifier, executes the BLOCK once before testing the loop
1799 condition.  (On other statements the loop modifiers test the conditional
1800 first.)
1801
1802 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1803 L<C<next>|/next LABEL>, L<C<last>|/last LABEL>, or
1804 L<C<redo>|/redo LABEL> cannot be used to leave or restart the block.
1805 See L<perlsyn> for alternative strategies.
1806
1807 =item do EXPR
1808 X<do>
1809
1810 Uses the value of EXPR as a filename and executes the contents of the
1811 file as a Perl script:
1812
1813     # load the exact specified file (./ and ../ special-cased)
1814     do '/foo/stat.pl';
1815     do './stat.pl';
1816     do '../foo/stat.pl';
1817
1818     # search for the named file within @INC
1819     do 'stat.pl';
1820     do 'foo/stat.pl';
1821
1822 C<do './stat.pl'> is largely like
1823
1824     eval `cat stat.pl`;
1825
1826 except that it's more concise, runs no external processes, and keeps
1827 track of the current filename for error messages. It also differs in that
1828 code evaluated with C<do FILE> cannot see lexicals in the enclosing
1829 scope; C<eval STRING> does.  It's the same, however, in that it does
1830 reparse the file every time you call it, so you probably don't want
1831 to do this inside a loop.
1832
1833 Using C<do> with a relative path (except for F<./> and F<../>), like
1834
1835     do 'foo/stat.pl';
1836
1837 will search the L<C<@INC>|perlvar/@INC> directories, and update
1838 L<C<%INC>|perlvar/%INC> if the file is found.  See L<perlvar/@INC>
1839 and L<perlvar/%INC> for these variables. In particular, note that
1840 whilst historically L<C<@INC>|perlvar/@INC> contained '.' (the
1841 current directory) making these two cases equivalent, that is no
1842 longer necessarily the case, as '.' is not included in C<@INC> by default
1843 in perl versions 5.26.0 onwards. Instead, perl will now warn:
1844
1845     do "stat.pl" failed, '.' is no longer in @INC;
1846     did you mean do "./stat.pl"?
1847
1848 If L<C<do>|/do EXPR> can read the file but cannot compile it, it
1849 returns L<C<undef>|/undef EXPR> and sets an error message in
1850 L<C<$@>|perlvar/$@>.  If L<C<do>|/do EXPR> cannot read the file, it
1851 returns undef and sets L<C<$!>|perlvar/$!> to the error.  Always check
1852 L<C<$@>|perlvar/$@> first, as compilation could fail in a way that also
1853 sets L<C<$!>|perlvar/$!>.  If the file is successfully compiled,
1854 L<C<do>|/do EXPR> returns the value of the last expression evaluated.
1855
1856 Inclusion of library modules is better done with the
1857 L<C<use>|/use Module VERSION LIST> and L<C<require>|/require VERSION>
1858 operators, which also do automatic error checking and raise an exception
1859 if there's a problem.
1860
1861 You might like to use L<C<do>|/do EXPR> to read in a program
1862 configuration file.  Manual error checking can be done this way:
1863
1864     # Read in config files: system first, then user.
1865     # Beware of using relative pathnames here.
1866     for $file ("/share/prog/defaults.rc",
1867                "$ENV{HOME}/.someprogrc")
1868     {
1869         unless ($return = do $file) {
1870             warn "couldn't parse $file: $@" if $@;
1871             warn "couldn't do $file: $!"    unless defined $return;
1872             warn "couldn't run $file"       unless $return;
1873         }
1874     }
1875
1876 =item dump LABEL
1877 X<dump> X<core> X<undump>
1878
1879 =item dump EXPR
1880
1881 =item dump
1882
1883 =for Pod::Functions create an immediate core dump
1884
1885 This function causes an immediate core dump.  See also the B<-u>
1886 command-line switch in L<perlrun>, which does the same thing.
1887 Primarily this is so that you can use the B<undump> program (not
1888 supplied) to turn your core dump into an executable binary after
1889 having initialized all your variables at the beginning of the
1890 program.  When the new binary is executed it will begin by executing
1891 a C<goto LABEL> (with all the restrictions that L<C<goto>|/goto LABEL>
1892 suffers).
1893 Think of it as a goto with an intervening core dump and reincarnation.
1894 If C<LABEL> is omitted, restarts the program from the top.  The
1895 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1896 computed at run time, being otherwise identical to C<dump LABEL>.
1897
1898 B<WARNING>: Any files opened at the time of the dump will I<not>
1899 be open any more when the program is reincarnated, with possible
1900 resulting confusion by Perl.
1901
1902 This function is now largely obsolete, mostly because it's very hard to
1903 convert a core file into an executable.  That's why you should now invoke
1904 it as C<CORE::dump()> if you don't want to be warned against a possible
1905 typo.
1906
1907 Unlike most named operators, this has the same precedence as assignment.
1908 It is also exempt from the looks-like-a-function rule, so
1909 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1910 L<C<dump>|/dump LABEL>.
1911
1912 Portability issues: L<perlport/dump>.
1913
1914 =item each HASH
1915 X<each> X<hash, iterator>
1916
1917 =item each ARRAY
1918 X<array, iterator>
1919
1920 =for Pod::Functions retrieve the next key/value pair from a hash
1921
1922 When called on a hash in list context, returns a 2-element list
1923 consisting of the key and value for the next element of a hash.  In Perl
1924 5.12 and later only, it will also return the index and value for the next
1925 element of an array so that you can iterate over it; older Perls consider
1926 this a syntax error.  When called in scalar context, returns only the key
1927 (not the value) in a hash, or the index in an array.
1928
1929 Hash entries are returned in an apparently random order.  The actual random
1930 order is specific to a given hash; the exact same series of operations
1931 on two hashes may result in a different order for each hash.  Any insertion
1932 into the hash may change the order, as will any deletion, with the exception
1933 that the most recent key returned by L<C<each>|/each HASH> or
1934 L<C<keys>|/keys HASH> may be deleted without changing the order.  So
1935 long as a given hash is unmodified you may rely on
1936 L<C<keys>|/keys HASH>, L<C<values>|/values HASH> and
1937 L<C<each>|/each HASH> to repeatedly return the same order
1938 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
1939 details on why hash order is randomized.  Aside from the guarantees
1940 provided here the exact details of Perl's hash algorithm and the hash
1941 traversal order are subject to change in any release of Perl.
1942
1943 After L<C<each>|/each HASH> has returned all entries from the hash or
1944 array, the next call to L<C<each>|/each HASH> returns the empty list in
1945 list context and L<C<undef>|/undef EXPR> in scalar context; the next
1946 call following I<that> one restarts iteration.  Each hash or array has
1947 its own internal iterator, accessed by L<C<each>|/each HASH>,
1948 L<C<keys>|/keys HASH>, and L<C<values>|/values HASH>.  The iterator is
1949 implicitly reset when L<C<each>|/each HASH> has reached the end as just
1950 described; it can be explicitly reset by calling L<C<keys>|/keys HASH>
1951 or L<C<values>|/values HASH> on the hash or array.  If you add or delete
1952 a hash's elements while iterating over it, the effect on the iterator is
1953 unspecified; for example, entries may be skipped or duplicated--so don't
1954 do that.  Exception: It is always safe to delete the item most recently
1955 returned by L<C<each>|/each HASH>, so the following code works properly:
1956
1957     while (my ($key, $value) = each %hash) {
1958         print $key, "\n";
1959         delete $hash{$key};   # This is safe
1960     }
1961
1962 Tied hashes may have a different ordering behaviour to perl's hash
1963 implementation.
1964
1965 This prints out your environment like the L<printenv(1)> program,
1966 but in a different order:
1967
1968     while (my ($key,$value) = each %ENV) {
1969         print "$key=$value\n";
1970     }
1971
1972 Starting with Perl 5.14, an experimental feature allowed
1973 L<C<each>|/each HASH> to take a scalar expression. This experiment has
1974 been deemed unsuccessful, and was removed as of Perl 5.24.
1975
1976 As of Perl 5.18 you can use a bare L<C<each>|/each HASH> in a C<while>
1977 loop, which will set L<C<$_>|perlvar/$_> on every iteration.
1978
1979     while (each %ENV) {
1980         print "$_=$ENV{$_}\n";
1981     }
1982
1983 To avoid confusing would-be users of your code who are running earlier
1984 versions of Perl with mysterious syntax errors, put this sort of thing at
1985 the top of your file to signal that your code will work I<only> on Perls of
1986 a recent vintage:
1987
1988     use 5.012;  # so keys/values/each work on arrays
1989     use 5.018;  # so each assigns to $_ in a lone while test
1990
1991 See also L<C<keys>|/keys HASH>, L<C<values>|/values HASH>, and
1992 L<C<sort>|/sort SUBNAME LIST>.
1993
1994 =item eof FILEHANDLE
1995 X<eof>
1996 X<end of file>
1997 X<end-of-file>
1998
1999 =item eof ()
2000
2001 =item eof
2002
2003 =for Pod::Functions test a filehandle for its end
2004
2005 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
2006 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
2007 gives the real filehandle.  (Note that this function actually
2008 reads a character and then C<ungetc>s it, so isn't useful in an
2009 interactive context.)  Do not read from a terminal file (or call
2010 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
2011 as terminals may lose the end-of-file condition if you do.
2012
2013 An L<C<eof>|/eof FILEHANDLE> without an argument uses the last file
2014 read.  Using L<C<eof()>|/eof FILEHANDLE> with empty parentheses is
2015 different.  It refers to the pseudo file formed from the files listed on
2016 the command line and accessed via the C<< <> >> operator.  Since
2017 C<< <> >> isn't explicitly opened, as a normal filehandle is, an
2018 L<C<eof()>|/eof FILEHANDLE> before C<< <> >> has been used will cause
2019 L<C<@ARGV>|perlvar/@ARGV> to be examined to determine if input is
2020 available.   Similarly, an L<C<eof()>|/eof FILEHANDLE> after C<< <> >>
2021 has returned end-of-file will assume you are processing another
2022 L<C<@ARGV>|perlvar/@ARGV> list, and if you haven't set
2023 L<C<@ARGV>|perlvar/@ARGV>, will read input from C<STDIN>; see
2024 L<perlop/"I/O Operators">.
2025
2026 In a C<< while (<>) >> loop, L<C<eof>|/eof FILEHANDLE> or C<eof(ARGV)>
2027 can be used to detect the end of each file, whereas
2028 L<C<eof()>|/eof FILEHANDLE> will detect the end of the very last file
2029 only.  Examples:
2030
2031     # reset line numbering on each input file
2032     while (<>) {
2033         next if /^\s*#/;  # skip comments
2034         print "$.\t$_";
2035     } continue {
2036         close ARGV if eof;  # Not eof()!
2037     }
2038
2039     # insert dashes just before last line of last file
2040     while (<>) {
2041         if (eof()) {  # check for end of last file
2042             print "--------------\n";
2043         }
2044         print;
2045         last if eof();     # needed if we're reading from a terminal
2046     }
2047
2048 Practical hint: you almost never need to use L<C<eof>|/eof FILEHANDLE>
2049 in Perl, because the input operators typically return L<C<undef>|/undef
2050 EXPR> when they run out of data or encounter an error.
2051
2052 =item eval EXPR
2053 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
2054 X<error, handling> X<exception, handling>
2055
2056 =item eval BLOCK
2057
2058 =item eval
2059
2060 =for Pod::Functions catch exceptions or compile and run code
2061
2062 C<eval> in all its forms is used to execute a little Perl program,
2063 trapping any errors encountered so they don't crash the calling program.
2064
2065 Plain C<eval> with no argument is just C<eval EXPR>, where the
2066 expression is understood to be contained in L<C<$_>|perlvar/$_>.  Thus
2067 there are only two real C<eval> forms; the one with an EXPR is often
2068 called "string eval".  In a string eval, the value of the expression
2069 (which is itself determined within scalar context) is first parsed, and
2070 if there were no errors, executed as a block within the lexical context
2071 of the current Perl program.  This form is typically used to delay
2072 parsing and subsequent execution of the text of EXPR until run time.
2073 Note that the value is parsed every time the C<eval> executes.
2074
2075 The other form is called "block eval".  It is less general than string
2076 eval, but the code within the BLOCK is parsed only once (at the same
2077 time the code surrounding the C<eval> itself was parsed) and executed
2078 within the context of the current Perl program.  This form is typically
2079 used to trap exceptions more efficiently than the first, while also
2080 providing the benefit of checking the code within BLOCK at compile time.
2081 BLOCK is parsed and compiled just once.  Since errors are trapped, it
2082 often is used to check if a given feature is available.
2083
2084 In both forms, the value returned is the value of the last expression
2085 evaluated inside the mini-program; a return statement may also be used, just
2086 as with subroutines.  The expression providing the return value is evaluated
2087 in void, scalar, or list context, depending on the context of the
2088 C<eval> itself.  See L<C<wantarray>|/wantarray> for more
2089 on how the evaluation context can be determined.
2090
2091 If there is a syntax error or runtime error, or a L<C<die>|/die LIST>
2092 statement is executed, C<eval> returns
2093 L<C<undef>|/undef EXPR> in scalar context, or an empty list in list
2094 context, and L<C<$@>|perlvar/$@> is set to the error message.  (Prior to
2095 5.16, a bug caused L<C<undef>|/undef EXPR> to be returned in list
2096 context for syntax errors, but not for runtime errors.) If there was no
2097 error, L<C<$@>|perlvar/$@> is set to the empty string.  A control flow
2098 operator like L<C<last>|/last LABEL> or L<C<goto>|/goto LABEL> can
2099 bypass the setting of L<C<$@>|perlvar/$@>.  Beware that using
2100 C<eval> neither silences Perl from printing warnings to
2101 STDERR, nor does it stuff the text of warning messages into
2102 L<C<$@>|perlvar/$@>.  To do either of those, you have to use the
2103 L<C<$SIG{__WARN__}>|perlvar/%SIG> facility, or turn off warnings inside
2104 the BLOCK or EXPR using S<C<no warnings 'all'>>.  See
2105 L<C<warn>|/warn LIST>, L<perlvar>, and L<warnings>.
2106
2107 Note that, because C<eval> traps otherwise-fatal errors,
2108 it is useful for determining whether a particular feature (such as
2109 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL> or
2110 L<C<symlink>|/symlink OLDFILE,NEWFILE>) is implemented.  It is also
2111 Perl's exception-trapping mechanism, where the L<C<die>|/die LIST>
2112 operator is used to raise exceptions.
2113
2114 Before Perl 5.14, the assignment to L<C<$@>|perlvar/$@> occurred before
2115 restoration
2116 of localized variables, which means that for your code to run on older
2117 versions, a temporary is required if you want to mask some, but not all
2118 errors:
2119
2120  # alter $@ on nefarious repugnancy only
2121  {
2122     my $e;
2123     {
2124       local $@; # protect existing $@
2125       eval { test_repugnancy() };
2126       # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
2127       $@ =~ /nefarious/ and $e = $@;
2128     }
2129     die $e if defined $e
2130  }
2131
2132 There are some different considerations for each form:
2133
2134 =over 4
2135
2136 =item String eval
2137
2138 Since the return value of EXPR is executed as a block within the lexical
2139 context of the current Perl program, any outer lexical variables are
2140 visible to it, and any package variable settings or subroutine and
2141 format definitions remain afterwards.
2142
2143 =over 4
2144
2145 =item Under the L<C<"unicode_eval"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
2146
2147 If this feature is enabled (which is the default under a C<use 5.16> or
2148 higher declaration), EXPR is considered to be
2149 in the same encoding as the surrounding program.  Thus if
2150 S<L<C<use utf8>|utf8>> is in effect, the string will be treated as being
2151 UTF-8 encoded.  Otherwise, the string is considered to be a sequence of
2152 independent bytes.  Bytes that correspond to ASCII-range code points
2153 will have their normal meanings for operators in the string.  The
2154 treatment of the other bytes depends on if the
2155 L<C<'unicode_strings"> feature|feature/The 'unicode_strings' feature> is
2156 in effect.
2157
2158 In a plain C<eval> without an EXPR argument, being in S<C<use utf8>> or
2159 not is irrelevant; the UTF-8ness of C<$_> itself determines the
2160 behavior.
2161
2162 Any S<C<use utf8>> or S<C<no utf8>> declarations within the string have
2163 no effect, and source filters are forbidden.  (C<unicode_strings>,
2164 however, can appear within the string.)  See also the
2165 L<C<evalbytes>|/evalbytes EXPR> operator, which works properly with
2166 source filters.
2167
2168 Variables defined outside the C<eval> and used inside it retain their
2169 original UTF-8ness.  Everything inside the string follows the normal
2170 rules for a Perl program with the given state of S<C<use utf8>>.
2171
2172 =item Outside the C<"unicode_eval"> feature
2173
2174 In this case, the behavior is problematic and is not so easily
2175 described.  Here are two bugs that cannot easily be fixed without
2176 breaking existing programs:
2177
2178 =over 4
2179
2180 =item *
2181
2182 It can lose track of whether something should be encoded as UTF-8 or
2183 not.
2184
2185 =item *
2186
2187 Source filters activated within C<eval> leak out into whichever file
2188 scope is currently being compiled.  To give an example with the CPAN module
2189 L<Semi::Semicolons>:
2190
2191  BEGIN { eval "use Semi::Semicolons; # not filtered" }
2192  # filtered here!
2193
2194 L<C<evalbytes>|/evalbytes EXPR> fixes that to work the way one would
2195 expect:
2196
2197  use feature "evalbytes";
2198  BEGIN { evalbytes "use Semi::Semicolons; # filtered" }
2199  # not filtered
2200
2201 =back
2202
2203 =back
2204
2205 Problems can arise if the string expands a scalar containing a floating
2206 point number.  That scalar can expand to letters, such as C<"NaN"> or
2207 C<"Infinity">; or, within the scope of a L<C<use locale>|locale>, the
2208 decimal point character may be something other than a dot (such as a
2209 comma).  None of these are likely to parse as you are likely expecting.
2210
2211 You should be especially careful to remember what's being looked at
2212 when:
2213
2214     eval $x;        # CASE 1
2215     eval "$x";      # CASE 2
2216
2217     eval '$x';      # CASE 3
2218     eval { $x };    # CASE 4
2219
2220     eval "\$$x++";  # CASE 5
2221     $$x++;          # CASE 6
2222
2223 Cases 1 and 2 above behave identically: they run the code contained in
2224 the variable $x.  (Although case 2 has misleading double quotes making
2225 the reader wonder what else might be happening (nothing is).)  Cases 3
2226 and 4 likewise behave in the same way: they run the code C<'$x'>, which
2227 does nothing but return the value of $x.  (Case 4 is preferred for
2228 purely visual reasons, but it also has the advantage of compiling at
2229 compile-time instead of at run-time.)  Case 5 is a place where
2230 normally you I<would> like to use double quotes, except that in this
2231 particular situation, you can just use symbolic references instead, as
2232 in case 6.
2233
2234 An C<eval ''> executed within a subroutine defined
2235 in the C<DB> package doesn't see the usual
2236 surrounding lexical scope, but rather the scope of the first non-DB piece
2237 of code that called it.  You don't normally need to worry about this unless
2238 you are writing a Perl debugger.
2239
2240 The final semicolon, if any, may be omitted from the value of EXPR.
2241
2242 =item Block eval
2243
2244 If the code to be executed doesn't vary, you may use the eval-BLOCK
2245 form to trap run-time errors without incurring the penalty of
2246 recompiling each time.  The error, if any, is still returned in
2247 L<C<$@>|perlvar/$@>.
2248 Examples:
2249
2250     # make divide-by-zero nonfatal
2251     eval { $answer = $a / $b; }; warn $@ if $@;
2252
2253     # same thing, but less efficient
2254     eval '$answer = $a / $b'; warn $@ if $@;
2255
2256     # a compile-time error
2257     eval { $answer = }; # WRONG
2258
2259     # a run-time error
2260     eval '$answer =';   # sets $@
2261
2262 If you want to trap errors when loading an XS module, some problems with
2263 the binary interface (such as Perl version skew) may be fatal even with
2264 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See
2265 L<perlrun>.
2266
2267 Using the C<eval {}> form as an exception trap in libraries does have some
2268 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
2269 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
2270 You can use the C<local $SIG{__DIE__}> construct for this purpose,
2271 as this example shows:
2272
2273     # a private exception trap for divide-by-zero
2274     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
2275     warn $@ if $@;
2276
2277 This is especially significant, given that C<__DIE__> hooks can call
2278 L<C<die>|/die LIST> again, which has the effect of changing their error
2279 messages:
2280
2281     # __DIE__ hooks may modify error messages
2282     {
2283        local $SIG{'__DIE__'} =
2284               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
2285        eval { die "foo lives here" };
2286        print $@ if $@;                # prints "bar lives here"
2287     }
2288
2289 Because this promotes action at a distance, this counterintuitive behavior
2290 may be fixed in a future release.
2291
2292 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
2293 L<C<next>|/next LABEL>, L<C<last>|/last LABEL>, or
2294 L<C<redo>|/redo LABEL> cannot be used to leave or restart the block.
2295
2296 The final semicolon, if any, may be omitted from within the BLOCK.
2297
2298 =back
2299
2300 =item evalbytes EXPR
2301 X<evalbytes>
2302
2303 =item evalbytes
2304
2305 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
2306
2307 This function is similar to a L<string eval|/eval EXPR>, except it
2308 always parses its argument (or L<C<$_>|perlvar/$_> if EXPR is omitted)
2309 as a string of independent bytes.
2310
2311 If called when S<C<use utf8>> is in effect, the string will be assumed
2312 to be encoded in UTF-8, and C<evalbytes> will make a temporary copy to
2313 work from, downgraded to non-UTF-8.  If this is not possible
2314 (because one or more characters in it require UTF-8), the C<evalbytes>
2315 will fail with the error stored in C<$@>.
2316
2317 Bytes that correspond to ASCII-range code points will have their normal
2318 meanings for operators in the string.  The treatment of the other bytes
2319 depends on if the L<C<'unicode_strings"> feature|feature/The
2320 'unicode_strings' feature> is in effect.
2321
2322 Of course, variables that are UTF-8 and are referred to in the string
2323 retain that:
2324
2325  my $a = "\x{100}";
2326  evalbytes 'print ord $a, "\n"';
2327
2328 prints
2329
2330  256
2331
2332 and C<$@> is empty.
2333
2334 Source filters activated within the evaluated code apply to the code
2335 itself.
2336
2337 L<C<evalbytes>|/evalbytes EXPR> is available starting in Perl v5.16.  To
2338 access it, you must say C<CORE::evalbytes>, but you can omit the
2339 C<CORE::> if the
2340 L<C<"evalbytes"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
2341 is enabled.  This is enabled automatically with a C<use v5.16> (or
2342 higher) declaration in the current scope.
2343
2344 =item exec LIST
2345 X<exec> X<execute>
2346
2347 =item exec PROGRAM LIST
2348
2349 =for Pod::Functions abandon this program to run another
2350
2351 The L<C<exec>|/exec LIST> function executes a system command I<and never
2352 returns>; use L<C<system>|/system LIST> instead of L<C<exec>|/exec LIST>
2353 if you want it to return.  It fails and
2354 returns false only if the command does not exist I<and> it is executed
2355 directly instead of via your system's command shell (see below).
2356
2357 Since it's a common mistake to use L<C<exec>|/exec LIST> instead of
2358 L<C<system>|/system LIST>, Perl warns you if L<C<exec>|/exec LIST> is
2359 called in void context and if there is a following statement that isn't
2360 L<C<die>|/die LIST>, L<C<warn>|/warn LIST>, or L<C<exit>|/exit EXPR> (if
2361 L<warnings> are enabled--but you always do that, right?).  If you
2362 I<really> want to follow an L<C<exec>|/exec LIST> with some other
2363 statement, you can use one of these styles to avoid the warning:
2364
2365     exec ('foo')   or print STDERR "couldn't exec foo: $!";
2366     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
2367
2368 If there is more than one argument in LIST, this calls L<execvp(3)> with the
2369 arguments in LIST.  If there is only one element in LIST, the argument is
2370 checked for shell metacharacters, and if there are any, the entire
2371 argument is passed to the system's command shell for parsing (this is
2372 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
2373 there are no shell metacharacters in the argument, it is split into words
2374 and passed directly to C<execvp>, which is more efficient.  Examples:
2375
2376     exec '/bin/echo', 'Your arguments are: ', @ARGV;
2377     exec "sort $outfile | uniq";
2378
2379 If you don't really want to execute the first argument, but want to lie
2380 to the program you are executing about its own name, you can specify
2381 the program you actually want to run as an "indirect object" (without a
2382 comma) in front of the LIST, as in C<exec PROGRAM LIST>.  (This always
2383 forces interpretation of the LIST as a multivalued list, even if there
2384 is only a single scalar in the list.)  Example:
2385
2386     my $shell = '/bin/csh';
2387     exec $shell '-sh';    # pretend it's a login shell
2388
2389 or, more directly,
2390
2391     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
2392
2393 When the arguments get executed via the system shell, results are
2394 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
2395 for details.
2396
2397 Using an indirect object with L<C<exec>|/exec LIST> or
2398 L<C<system>|/system LIST> is also more secure.  This usage (which also
2399 works fine with L<C<system>|/system LIST>) forces
2400 interpretation of the arguments as a multivalued list, even if the
2401 list had just one argument.  That way you're safe from the shell
2402 expanding wildcards or splitting up words with whitespace in them.
2403
2404     my @args = ( "echo surprise" );
2405
2406     exec @args;               # subject to shell escapes
2407                                 # if @args == 1
2408     exec { $args[0] } @args;  # safe even with one-arg list
2409
2410 The first version, the one without the indirect object, ran the I<echo>
2411 program, passing it C<"surprise"> an argument.  The second version didn't;
2412 it tried to run a program named I<"echo surprise">, didn't find it, and set
2413 L<C<$?>|perlvar/$?> to a non-zero value indicating failure.
2414
2415 On Windows, only the C<exec PROGRAM LIST> indirect object syntax will
2416 reliably avoid using the shell; C<exec LIST>, even with more than one
2417 element, will fall back to the shell if the first spawn fails.
2418
2419 Perl attempts to flush all files opened for output before the exec,
2420 but this may not be supported on some platforms (see L<perlport>).
2421 To be safe, you may need to set L<C<$E<verbar>>|perlvar/$E<verbar>>
2422 (C<$AUTOFLUSH> in L<English>) or call the C<autoflush> method of
2423 L<C<IO::Handle>|IO::Handle/METHODS> on any open handles to avoid lost
2424 output.
2425
2426 Note that L<C<exec>|/exec LIST> will not call your C<END> blocks, nor
2427 will it invoke C<DESTROY> methods on your objects.
2428
2429 Portability issues: L<perlport/exec>.
2430
2431 =item exists EXPR
2432 X<exists> X<autovivification>
2433
2434 =for Pod::Functions test whether a hash key is present
2435
2436 Given an expression that specifies an element of a hash, returns true if the
2437 specified element in the hash has ever been initialized, even if the
2438 corresponding value is undefined.
2439
2440     print "Exists\n"    if exists $hash{$key};
2441     print "Defined\n"   if defined $hash{$key};
2442     print "True\n"      if $hash{$key};
2443
2444 exists may also be called on array elements, but its behavior is much less
2445 obvious and is strongly tied to the use of L<C<delete>|/delete EXPR> on
2446 arrays.
2447
2448 B<WARNING:> Calling L<C<exists>|/exists EXPR> on array values is
2449 strongly discouraged.  The
2450 notion of deleting or checking the existence of Perl array elements is not
2451 conceptually coherent, and can lead to surprising behavior.
2452
2453     print "Exists\n"    if exists $array[$index];
2454     print "Defined\n"   if defined $array[$index];
2455     print "True\n"      if $array[$index];
2456
2457 A hash or array element can be true only if it's defined and defined only if
2458 it exists, but the reverse doesn't necessarily hold true.
2459
2460 Given an expression that specifies the name of a subroutine,
2461 returns true if the specified subroutine has ever been declared, even
2462 if it is undefined.  Mentioning a subroutine name for exists or defined
2463 does not count as declaring it.  Note that a subroutine that does not
2464 exist may still be callable: its package may have an C<AUTOLOAD>
2465 method that makes it spring into existence the first time that it is
2466 called; see L<perlsub>.
2467
2468     print "Exists\n"  if exists &subroutine;
2469     print "Defined\n" if defined &subroutine;
2470
2471 Note that the EXPR can be arbitrarily complicated as long as the final
2472 operation is a hash or array key lookup or subroutine name:
2473
2474     if (exists $ref->{A}->{B}->{$key})  { }
2475     if (exists $hash{A}{B}{$key})       { }
2476
2477     if (exists $ref->{A}->{B}->[$ix])   { }
2478     if (exists $hash{A}{B}[$ix])        { }
2479
2480     if (exists &{$ref->{A}{B}{$key}})   { }
2481
2482 Although the most deeply nested array or hash element will not spring into
2483 existence just because its existence was tested, any intervening ones will.
2484 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2485 into existence due to the existence test for the C<$key> element above.
2486 This happens anywhere the arrow operator is used, including even here:
2487
2488     undef $ref;
2489     if (exists $ref->{"Some key"})    { }
2490     print $ref;  # prints HASH(0x80d3d5c)
2491
2492 Use of a subroutine call, rather than a subroutine name, as an argument
2493 to L<C<exists>|/exists EXPR> is an error.
2494
2495     exists &sub;    # OK
2496     exists &sub();  # Error
2497
2498 =item exit EXPR
2499 X<exit> X<terminate> X<abort>
2500
2501 =item exit
2502
2503 =for Pod::Functions terminate this program
2504
2505 Evaluates EXPR and exits immediately with that value.    Example:
2506
2507     my $ans = <STDIN>;
2508     exit 0 if $ans =~ /^[Xx]/;
2509
2510 See also L<C<die>|/die LIST>.  If EXPR is omitted, exits with C<0>
2511 status.  The only
2512 universally recognized values for EXPR are C<0> for success and C<1>
2513 for error; other values are subject to interpretation depending on the
2514 environment in which the Perl program is running.  For example, exiting
2515 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2516 the mailer to return the item undelivered, but that's not true everywhere.
2517
2518 Don't use L<C<exit>|/exit EXPR> to abort a subroutine if there's any
2519 chance that someone might want to trap whatever error happened.  Use
2520 L<C<die>|/die LIST> instead, which can be trapped by an
2521 L<C<eval>|/eval EXPR>.
2522
2523 The L<C<exit>|/exit EXPR> function does not always exit immediately.  It
2524 calls any defined C<END> routines first, but these C<END> routines may
2525 not themselves abort the exit.  Likewise any object destructors that
2526 need to be called are called before the real exit.  C<END> routines and
2527 destructors can change the exit status by modifying L<C<$?>|perlvar/$?>.
2528 If this is a problem, you can call
2529 L<C<POSIX::_exit($status)>|POSIX/C<_exit>> to avoid C<END> and destructor
2530 processing.  See L<perlmod> for details.
2531
2532 Portability issues: L<perlport/exit>.
2533
2534 =item exp EXPR
2535 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2536
2537 =item exp
2538
2539 =for Pod::Functions raise I<e> to a power
2540
2541 Returns I<e> (the natural logarithm base) to the power of EXPR.
2542 If EXPR is omitted, gives C<exp($_)>.
2543
2544 =item fc EXPR
2545 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2546
2547 =item fc
2548
2549 =for Pod::Functions +fc return casefolded version of a string
2550
2551 Returns the casefolded version of EXPR.  This is the internal function
2552 implementing the C<\F> escape in double-quoted strings.
2553
2554 Casefolding is the process of mapping strings to a form where case
2555 differences are erased; comparing two strings in their casefolded
2556 form is effectively a way of asking if two strings are equal,
2557 regardless of case.
2558
2559 Roughly, if you ever found yourself writing this
2560
2561     lc($this) eq lc($that)    # Wrong!
2562         # or
2563     uc($this) eq uc($that)    # Also wrong!
2564         # or
2565     $this =~ /^\Q$that\E\z/i  # Right!
2566
2567 Now you can write
2568
2569     fc($this) eq fc($that)
2570
2571 And get the correct results.
2572
2573 Perl only implements the full form of casefolding, but you can access
2574 the simple folds using L<Unicode::UCD/B<casefold()>> and
2575 L<Unicode::UCD/B<prop_invmap()>>.
2576 For further information on casefolding, refer to
2577 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2578 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2579 available at L<http://www.unicode.org/versions/latest/>, as well as the
2580 Case Charts available at L<http://www.unicode.org/charts/case/>.
2581
2582 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
2583
2584 This function behaves the same way under various pragmas, such as within
2585 L<S<C<"use feature 'unicode_strings">>|feature/The 'unicode_strings' feature>,
2586 as L<C<lc>|/lc EXPR> does, with the single exception of
2587 L<C<fc>|/fc EXPR> of I<LATIN CAPITAL LETTER SHARP S> (U+1E9E) within the
2588 scope of L<S<C<use locale>>|locale>.  The foldcase of this character
2589 would normally be C<"ss">, but as explained in the L<C<lc>|/lc EXPR>
2590 section, case
2591 changes that cross the 255/256 boundary are problematic under locales,
2592 and are hence prohibited.  Therefore, this function under locale returns
2593 instead the string C<"\x{17F}\x{17F}">, which is the I<LATIN SMALL LETTER
2594 LONG S>.  Since that character itself folds to C<"s">, the string of two
2595 of them together should be equivalent to a single U+1E9E when foldcased.
2596
2597 While the Unicode Standard defines two additional forms of casefolding,
2598 one for Turkic languages and one that never maps one character into multiple
2599 characters, these are not provided by the Perl core.  However, the CPAN module
2600 L<C<Unicode::Casing>|Unicode::Casing> may be used to provide an implementation.
2601
2602 L<C<fc>|/fc EXPR> is available only if the
2603 L<C<"fc"> feature|feature/The 'fc' feature> is enabled or if it is
2604 prefixed with C<CORE::>.  The
2605 L<C<"fc"> feature|feature/The 'fc' feature> is enabled automatically
2606 with a C<use v5.16> (or higher) declaration in the current scope.
2607
2608 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2609 X<fcntl>
2610
2611 =for Pod::Functions file control system call
2612
2613 Implements the L<fcntl(2)> function.  You'll probably have to say
2614
2615     use Fcntl;
2616
2617 first to get the correct constant definitions.  Argument processing and
2618 value returned work just like L<C<ioctl>|/ioctl
2619 FILEHANDLE,FUNCTION,SCALAR> below.  For example:
2620
2621     use Fcntl;
2622     my $flags = fcntl($filehandle, F_GETFL, 0)
2623         or die "Can't fcntl F_GETFL: $!";
2624
2625 You don't have to check for L<C<defined>|/defined EXPR> on the return
2626 from L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>.  Like
2627 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>, it maps a C<0> return
2628 from the system call into C<"0 but true"> in Perl.  This string is true
2629 in boolean context and C<0> in numeric context.  It is also exempt from
2630 the normal
2631 L<C<Argument "..." isn't numeric>|perldiag/Argument "%s" isn't numeric%s>
2632 L<warnings> on improper numeric conversions.
2633
2634 Note that L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR> raises an
2635 exception if used on a machine that doesn't implement L<fcntl(2)>.  See
2636 the L<Fcntl> module or your L<fcntl(2)> manpage to learn what functions
2637 are available on your system.
2638
2639 Here's an example of setting a filehandle named C<$REMOTE> to be
2640 non-blocking at the system level.  You'll have to negotiate
2641 L<C<$E<verbar>>|perlvar/$E<verbar>> on your own, though.
2642
2643     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2644
2645     my $flags = fcntl($REMOTE, F_GETFL, 0)
2646         or die "Can't get flags for the socket: $!\n";
2647
2648     fcntl($REMOTE, F_SETFL, $flags | O_NONBLOCK)
2649         or die "Can't set flags for the socket: $!\n";
2650
2651 Portability issues: L<perlport/fcntl>.
2652
2653 =item __FILE__
2654 X<__FILE__>
2655
2656 =for Pod::Functions the name of the current source file
2657
2658 A special token that returns the name of the file in which it occurs.
2659
2660 =item fileno FILEHANDLE
2661 X<fileno>
2662
2663 =item fileno DIRHANDLE
2664
2665 =for Pod::Functions return file descriptor from filehandle
2666
2667 Returns the file descriptor for a filehandle or directory handle,
2668 or undefined if the
2669 filehandle is not open.  If there is no real file descriptor at the OS
2670 level, as can happen with filehandles connected to memory objects via
2671 L<C<open>|/open FILEHANDLE,EXPR> with a reference for the third
2672 argument, -1 is returned.
2673
2674 This is mainly useful for constructing bitmaps for
2675 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT> and low-level POSIX
2676 tty-handling operations.
2677 If FILEHANDLE is an expression, the value is taken as an indirect
2678 filehandle, generally its name.
2679
2680 You can use this to find out whether two handles refer to the
2681 same underlying descriptor:
2682
2683     if (fileno($this) != -1 && fileno($this) == fileno($that)) {
2684         print "\$this and \$that are dups\n";
2685     } elsif (fileno($this) != -1 && fileno($that) != -1) {
2686         print "\$this and \$that have different " .
2687             "underlying file descriptors\n";
2688     } else {
2689         print "At least one of \$this and \$that does " .
2690             "not have a real file descriptor\n";
2691     }
2692
2693 The behavior of L<C<fileno>|/fileno FILEHANDLE> on a directory handle
2694 depends on the operating system.  On a system with L<dirfd(3)> or
2695 similar, L<C<fileno>|/fileno FILEHANDLE> on a directory
2696 handle returns the underlying file descriptor associated with the
2697 handle; on systems with no such support, it returns the undefined value,
2698 and sets L<C<$!>|perlvar/$!> (errno).
2699
2700 =item flock FILEHANDLE,OPERATION
2701 X<flock> X<lock> X<locking>
2702
2703 =for Pod::Functions lock an entire file with an advisory lock
2704
2705 Calls L<flock(2)>, or an emulation of it, on FILEHANDLE.  Returns true
2706 for success, false on failure.  Produces a fatal error if used on a
2707 machine that doesn't implement L<flock(2)>, L<fcntl(2)> locking, or
2708 L<lockf(3)>.  L<C<flock>|/flock FILEHANDLE,OPERATION> is Perl's portable
2709 file-locking interface, although it locks entire files only, not
2710 records.
2711
2712 Two potentially non-obvious but traditional L<C<flock>|/flock
2713 FILEHANDLE,OPERATION> semantics are
2714 that it waits indefinitely until the lock is granted, and that its locks
2715 are B<merely advisory>.  Such discretionary locks are more flexible, but
2716 offer fewer guarantees.  This means that programs that do not also use
2717 L<C<flock>|/flock FILEHANDLE,OPERATION> may modify files locked with
2718 L<C<flock>|/flock FILEHANDLE,OPERATION>.  See L<perlport>,
2719 your port's specific documentation, and your system-specific local manpages
2720 for details.  It's best to assume traditional behavior if you're writing
2721 portable programs.  (But if you're not, you should as always feel perfectly
2722 free to write for your own system's idiosyncrasies (sometimes called
2723 "features").  Slavish adherence to portability concerns shouldn't get
2724 in the way of your getting your job done.)
2725
2726 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2727 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2728 you can use the symbolic names if you import them from the L<Fcntl> module,
2729 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2730 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2731 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2732 LOCK_SH or LOCK_EX, then L<C<flock>|/flock FILEHANDLE,OPERATION> returns
2733 immediately rather than blocking waiting for the lock; check the return
2734 status to see if you got it.
2735
2736 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2737 before locking or unlocking it.
2738
2739 Note that the emulation built with L<lockf(3)> doesn't provide shared
2740 locks, and it requires that FILEHANDLE be open with write intent.  These
2741 are the semantics that L<lockf(3)> implements.  Most if not all systems
2742 implement L<lockf(3)> in terms of L<fcntl(2)> locking, though, so the
2743 differing semantics shouldn't bite too many people.
2744
2745 Note that the L<fcntl(2)> emulation of L<flock(3)> requires that FILEHANDLE
2746 be open with read intent to use LOCK_SH and requires that it be open
2747 with write intent to use LOCK_EX.
2748
2749 Note also that some versions of L<C<flock>|/flock FILEHANDLE,OPERATION>
2750 cannot lock things over the network; you would need to use the more
2751 system-specific L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR> for
2752 that.  If you like you can force Perl to ignore your system's L<flock(2)>
2753 function, and so provide its own L<fcntl(2)>-based emulation, by passing
2754 the switch C<-Ud_flock> to the F<Configure> program when you configure
2755 and build a new Perl.
2756
2757 Here's a mailbox appender for BSD systems.
2758
2759     # import LOCK_* and SEEK_END constants
2760     use Fcntl qw(:flock SEEK_END);
2761
2762     sub lock {
2763         my ($fh) = @_;
2764         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2765         # and, in case we're running on a very old UNIX
2766         # variant without the modern O_APPEND semantics...
2767         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2768     }
2769
2770     sub unlock {
2771         my ($fh) = @_;
2772         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2773     }
2774
2775     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2776         or die "Can't open mailbox: $!";
2777
2778     lock($mbox);
2779     print $mbox $msg,"\n\n";
2780     unlock($mbox);
2781
2782 On systems that support a real L<flock(2)>, locks are inherited across
2783 L<C<fork>|/fork> calls, whereas those that must resort to the more
2784 capricious L<fcntl(2)> function lose their locks, making it seriously
2785 harder to write servers.
2786
2787 See also L<DB_File> for other L<C<flock>|/flock FILEHANDLE,OPERATION>
2788 examples.
2789
2790 Portability issues: L<perlport/flock>.
2791
2792 =item fork
2793 X<fork> X<child> X<parent>
2794
2795 =for Pod::Functions create a new process just like this one
2796
2797 Does a L<fork(2)> system call to create a new process running the
2798 same program at the same point.  It returns the child pid to the
2799 parent process, C<0> to the child process, or L<C<undef>|/undef EXPR> if
2800 the fork is
2801 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2802 are shared, while everything else is copied.  On most systems supporting
2803 L<fork(2)>, great care has gone into making it extremely efficient (for
2804 example, using copy-on-write technology on data pages), making it the
2805 dominant paradigm for multitasking over the last few decades.
2806
2807 Perl attempts to flush all files opened for output before forking the
2808 child process, but this may not be supported on some platforms (see
2809 L<perlport>).  To be safe, you may need to set
2810 L<C<$E<verbar>>|perlvar/$E<verbar>> (C<$AUTOFLUSH> in L<English>) or
2811 call the C<autoflush> method of L<C<IO::Handle>|IO::Handle/METHODS> on
2812 any open handles to avoid duplicate output.
2813
2814 If you L<C<fork>|/fork> without ever waiting on your children, you will
2815 accumulate zombies.  On some systems, you can avoid this by setting
2816 L<C<$SIG{CHLD}>|perlvar/%SIG> to C<"IGNORE">.  See also L<perlipc> for
2817 more examples of forking and reaping moribund children.
2818
2819 Note that if your forked child inherits system file descriptors like
2820 STDIN and STDOUT that are actually connected by a pipe or socket, even
2821 if you exit, then the remote server (such as, say, a CGI script or a
2822 backgrounded job launched from a remote shell) won't think you're done.
2823 You should reopen those to F</dev/null> if it's any issue.
2824
2825 On some platforms such as Windows, where the L<fork(2)> system call is
2826 not available, Perl can be built to emulate L<C<fork>|/fork> in the Perl
2827 interpreter.  The emulation is designed, at the level of the Perl
2828 program, to be as compatible as possible with the "Unix" L<fork(2)>.
2829 However it has limitations that have to be considered in code intended
2830 to be portable.  See L<perlfork> for more details.
2831
2832 Portability issues: L<perlport/fork>.
2833
2834 =item format
2835 X<format>
2836
2837 =for Pod::Functions declare a picture format with use by the write() function
2838
2839 Declare a picture format for use by the L<C<write>|/write FILEHANDLE>
2840 function.  For example:
2841
2842     format Something =
2843         Test: @<<<<<<<< @||||| @>>>>>
2844               $str,     $%,    '$' . int($num)
2845     .
2846
2847     $str = "widget";
2848     $num = $cost/$quantity;
2849     $~ = 'Something';
2850     write;
2851
2852 See L<perlform> for many details and examples.
2853
2854 =item formline PICTURE,LIST
2855 X<formline>
2856
2857 =for Pod::Functions internal function used for formats
2858
2859 This is an internal function used by L<C<format>|/format>s, though you
2860 may call it, too.  It formats (see L<perlform>) a list of values
2861 according to the contents of PICTURE, placing the output into the format
2862 output accumulator, L<C<$^A>|perlvar/$^A> (or C<$ACCUMULATOR> in
2863 L<English>).  Eventually, when a L<C<write>|/write FILEHANDLE> is done,
2864 the contents of L<C<$^A>|perlvar/$^A> are written to some filehandle.
2865 You could also read L<C<$^A>|perlvar/$^A> and then set
2866 L<C<$^A>|perlvar/$^A> back to C<"">.  Note that a format typically does
2867 one L<C<formline>|/formline PICTURE,LIST> per line of form, but the
2868 L<C<formline>|/formline PICTURE,LIST> function itself doesn't care how
2869 many newlines are embedded in the PICTURE.  This means that the C<~> and
2870 C<~~> tokens treat the entire PICTURE as a single line.  You may
2871 therefore need to use multiple formlines to implement a single record
2872 format, just like the L<C<format>|/format> compiler.
2873
2874 Be careful if you put double quotes around the picture, because an C<@>
2875 character may be taken to mean the beginning of an array name.
2876 L<C<formline>|/formline PICTURE,LIST> always returns true.  See
2877 L<perlform> for other examples.
2878
2879 If you are trying to use this instead of L<C<write>|/write FILEHANDLE>
2880 to capture the output, you may find it easier to open a filehandle to a
2881 scalar (C<< open my $fh, ">", \$output >>) and write to that instead.
2882
2883 =item getc FILEHANDLE
2884 X<getc> X<getchar> X<character> X<file, read>
2885
2886 =item getc
2887
2888 =for Pod::Functions get the next character from the filehandle
2889
2890 Returns the next character from the input file attached to FILEHANDLE,
2891 or the undefined value at end of file or if there was an error (in
2892 the latter case L<C<$!>|perlvar/$!> is set).  If FILEHANDLE is omitted,
2893 reads from
2894 STDIN.  This is not particularly efficient.  However, it cannot be
2895 used by itself to fetch single characters without waiting for the user
2896 to hit enter.  For that, try something more like:
2897
2898     if ($BSD_STYLE) {
2899         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2900     }
2901     else {
2902         system "stty", '-icanon', 'eol', "\001";
2903     }
2904
2905     my $key = getc(STDIN);
2906
2907     if ($BSD_STYLE) {
2908         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2909     }
2910     else {
2911         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2912     }
2913     print "\n";
2914
2915 Determination of whether C<$BSD_STYLE> should be set is left as an
2916 exercise to the reader.
2917
2918 The L<C<POSIX::getattr>|POSIX/C<getattr>> function can do this more
2919 portably on systems purporting POSIX compliance.  See also the
2920 L<C<Term::ReadKey>|Term::ReadKey> module on CPAN.
2921
2922 =item getlogin
2923 X<getlogin> X<login>
2924
2925 =for Pod::Functions return who logged in at this tty
2926
2927 This implements the C library function of the same name, which on most
2928 systems returns the current login from F</etc/utmp>, if any.  If it
2929 returns the empty string, use L<C<getpwuid>|/getpwuid UID>.
2930
2931     my $login = getlogin || getpwuid($<) || "Kilroy";
2932
2933 Do not consider L<C<getlogin>|/getlogin> for authentication: it is not
2934 as secure as L<C<getpwuid>|/getpwuid UID>.
2935
2936 Portability issues: L<perlport/getlogin>.
2937
2938 =item getpeername SOCKET
2939 X<getpeername> X<peer>
2940
2941 =for Pod::Functions find the other end of a socket connection
2942
2943 Returns the packed sockaddr address of the other end of the SOCKET
2944 connection.
2945
2946     use Socket;
2947     my $hersockaddr    = getpeername($sock);
2948     my ($port, $iaddr) = sockaddr_in($hersockaddr);
2949     my $herhostname    = gethostbyaddr($iaddr, AF_INET);
2950     my $herstraddr     = inet_ntoa($iaddr);
2951
2952 =item getpgrp PID
2953 X<getpgrp> X<group>
2954
2955 =for Pod::Functions get process group
2956
2957 Returns the current process group for the specified PID.  Use
2958 a PID of C<0> to get the current process group for the
2959 current process.  Will raise an exception if used on a machine that
2960 doesn't implement L<getpgrp(2)>.  If PID is omitted, returns the process
2961 group of the current process.  Note that the POSIX version of
2962 L<C<getpgrp>|/getpgrp PID> does not accept a PID argument, so only
2963 C<PID==0> is truly portable.
2964
2965 Portability issues: L<perlport/getpgrp>.
2966
2967 =item getppid
2968 X<getppid> X<parent> X<pid>
2969
2970 =for Pod::Functions get parent process ID
2971
2972 Returns the process id of the parent process.
2973
2974 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2975 around non-POSIX thread semantics the minority of Linux systems (and
2976 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2977 has since been removed.  See the documentation for L<$$|perlvar/$$> for
2978 details.
2979
2980 Portability issues: L<perlport/getppid>.
2981
2982 =item getpriority WHICH,WHO
2983 X<getpriority> X<priority> X<nice>
2984
2985 =for Pod::Functions get current nice value
2986
2987 Returns the current priority for a process, a process group, or a user.
2988 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2989 machine that doesn't implement L<getpriority(2)>.
2990
2991 C<WHICH> can be any of C<PRIO_PROCESS>, C<PRIO_PGRP> or C<PRIO_USER>
2992 imported from L<POSIX/RESOURCE CONSTANTS>.
2993
2994 Portability issues: L<perlport/getpriority>.
2995
2996 =item getpwnam NAME
2997 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2998 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2999 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
3000 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
3001 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
3002 X<endnetent> X<endprotoent> X<endservent>
3003
3004 =for Pod::Functions get passwd record given user login name
3005
3006 =item getgrnam NAME
3007
3008 =for Pod::Functions get group record given group name
3009
3010 =item gethostbyname NAME
3011
3012 =for Pod::Functions get host record given name
3013
3014 =item getnetbyname NAME
3015
3016 =for Pod::Functions get networks record given name
3017
3018 =item getprotobyname NAME
3019
3020 =for Pod::Functions get protocol record given name
3021
3022 =item getpwuid UID
3023
3024 =for Pod::Functions get passwd record given user ID
3025
3026 =item getgrgid GID
3027
3028 =for Pod::Functions get group record given group user ID
3029
3030 =item getservbyname NAME,PROTO
3031
3032 =for Pod::Functions get services record given its name
3033
3034 =item gethostbyaddr ADDR,ADDRTYPE
3035
3036 =for Pod::Functions get host record given its address
3037
3038 =item getnetbyaddr ADDR,ADDRTYPE
3039
3040 =for Pod::Functions get network record given its address
3041
3042 =item getprotobynumber NUMBER
3043
3044 =for Pod::Functions get protocol record numeric protocol
3045
3046 =item getservbyport PORT,PROTO
3047
3048 =for Pod::Functions get services record given numeric port
3049
3050 =item getpwent
3051
3052 =for Pod::Functions get next passwd record
3053
3054 =item getgrent
3055
3056 =for Pod::Functions get next group record
3057
3058 =item gethostent
3059
3060 =for Pod::Functions get next hosts record
3061
3062 =item getnetent
3063
3064 =for Pod::Functions get next networks record
3065
3066 =item getprotoent
3067
3068 =for Pod::Functions get next protocols record
3069
3070 =item getservent
3071
3072 =for Pod::Functions get next services record
3073
3074 =item setpwent
3075
3076 =for Pod::Functions prepare passwd file for use
3077
3078 =item setgrent
3079
3080 =for Pod::Functions prepare group file for use
3081
3082 =item sethostent STAYOPEN
3083
3084 =for Pod::Functions prepare hosts file for use
3085
3086 =item setnetent STAYOPEN
3087
3088 =for Pod::Functions prepare networks file for use
3089
3090 =item setprotoent STAYOPEN
3091
3092 =for Pod::Functions prepare protocols file for use
3093
3094 =item setservent STAYOPEN
3095
3096 =for Pod::Functions prepare services file for use
3097
3098 =item endpwent
3099
3100 =for Pod::Functions be done using passwd file
3101
3102 =item endgrent
3103
3104 =for Pod::Functions be done using group file
3105
3106 =item endhostent
3107
3108 =for Pod::Functions be done using hosts file
3109
3110 =item endnetent
3111
3112 =for Pod::Functions be done using networks file
3113
3114 =item endprotoent
3115
3116 =for Pod::Functions be done using protocols file
3117
3118 =item endservent
3119
3120 =for Pod::Functions be done using services file
3121
3122 These routines are the same as their counterparts in the
3123 system C library.  In list context, the return values from the
3124 various get routines are as follows:
3125
3126  #    0        1          2           3         4
3127  my ( $name,   $passwd,   $gid,       $members  ) = getgr*
3128  my ( $name,   $aliases,  $addrtype,  $net      ) = getnet*
3129  my ( $name,   $aliases,  $port,      $proto    ) = getserv*
3130  my ( $name,   $aliases,  $proto                ) = getproto*
3131  my ( $name,   $aliases,  $addrtype,  $length,  @addrs ) = gethost*
3132  my ( $name,   $passwd,   $uid,       $gid,     $quota,
3133     $comment,  $gcos,     $dir,       $shell,   $expire ) = getpw*
3134  #    5        6          7           8         9
3135
3136 (If the entry doesn't exist, the return value is a single meaningless true
3137 value.)
3138
3139 The exact meaning of the $gcos field varies but it usually contains
3140 the real name of the user (as opposed to the login name) and other
3141 information pertaining to the user.  Beware, however, that in many
3142 system users are able to change this information and therefore it
3143 cannot be trusted and therefore the $gcos is tainted (see
3144 L<perlsec>).  The $passwd and $shell, user's encrypted password and
3145 login shell, are also tainted, for the same reason.
3146
3147 In scalar context, you get the name, unless the function was a
3148 lookup by name, in which case you get the other thing, whatever it is.
3149 (If the entry doesn't exist you get the undefined value.)  For example:
3150
3151     my $uid   = getpwnam($name);
3152     my $name  = getpwuid($num);
3153     my $name  = getpwent();
3154     my $gid   = getgrnam($name);
3155     my $name  = getgrgid($num);
3156     my $name  = getgrent();
3157     # etc.
3158
3159 In I<getpw*()> the fields $quota, $comment, and $expire are special
3160 in that they are unsupported on many systems.  If the
3161 $quota is unsupported, it is an empty scalar.  If it is supported, it
3162 usually encodes the disk quota.  If the $comment field is unsupported,
3163 it is an empty scalar.  If it is supported it usually encodes some
3164 administrative comment about the user.  In some systems the $quota
3165 field may be $change or $age, fields that have to do with password
3166 aging.  In some systems the $comment field may be $class.  The $expire
3167 field, if present, encodes the expiration period of the account or the
3168 password.  For the availability and the exact meaning of these fields
3169 in your system, please consult L<getpwnam(3)> and your system's
3170 F<pwd.h> file.  You can also find out from within Perl what your
3171 $quota and $comment fields mean and whether you have the $expire field
3172 by using the L<C<Config>|Config> module and the values C<d_pwquota>, C<d_pwage>,
3173 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
3174 files are supported only if your vendor has implemented them in the
3175 intuitive fashion that calling the regular C library routines gets the
3176 shadow versions if you're running under privilege or if there exists
3177 the L<shadow(3)> functions as found in System V (this includes Solaris
3178 and Linux).  Those systems that implement a proprietary shadow password
3179 facility are unlikely to be supported.
3180
3181 The $members value returned by I<getgr*()> is a space-separated list of
3182 the login names of the members of the group.
3183
3184 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
3185 C, it will be returned to you via L<C<$?>|perlvar/$?> if the function
3186 call fails.  The
3187 C<@addrs> value returned by a successful call is a list of raw
3188 addresses returned by the corresponding library call.  In the
3189 Internet domain, each address is four bytes long; you can unpack it
3190 by saying something like:
3191
3192     my ($w,$x,$y,$z) = unpack('W4',$addr[0]);
3193
3194 The Socket library makes this slightly easier:
3195
3196     use Socket;
3197     my $iaddr = inet_aton("127.1"); # or whatever address
3198     my $name  = gethostbyaddr($iaddr, AF_INET);
3199
3200     # or going the other way
3201     my $straddr = inet_ntoa($iaddr);
3202
3203 In the opposite way, to resolve a hostname to the IP address
3204 you can write this:
3205
3206     use Socket;
3207     my $packed_ip = gethostbyname("www.perl.org");
3208     my $ip_address;
3209     if (defined $packed_ip) {
3210         $ip_address = inet_ntoa($packed_ip);
3211     }
3212
3213 Make sure L<C<gethostbyname>|/gethostbyname NAME> is called in SCALAR
3214 context and that its return value is checked for definedness.
3215
3216 The L<C<getprotobynumber>|/getprotobynumber NUMBER> function, even
3217 though it only takes one argument, has the precedence of a list
3218 operator, so beware:
3219
3220     getprotobynumber $number eq 'icmp'   # WRONG
3221     getprotobynumber($number eq 'icmp')  # actually means this
3222     getprotobynumber($number) eq 'icmp'  # better this way
3223
3224 If you get tired of remembering which element of the return list
3225 contains which return value, by-name interfaces are provided in standard
3226 modules: L<C<File::stat>|File::stat>, L<C<Net::hostent>|Net::hostent>,
3227 L<C<Net::netent>|Net::netent>, L<C<Net::protoent>|Net::protoent>,
3228 L<C<Net::servent>|Net::servent>, L<C<Time::gmtime>|Time::gmtime>,
3229 L<C<Time::localtime>|Time::localtime>, and
3230 L<C<User::grent>|User::grent>.  These override the normal built-ins,
3231 supplying versions that return objects with the appropriate names for
3232 each field.  For example:
3233
3234    use File::stat;
3235    use User::pwent;
3236    my $is_his = (stat($filename)->uid == pwent($whoever)->uid);
3237
3238 Even though it looks as though they're the same method calls (uid),
3239 they aren't, because a C<File::stat> object is different from
3240 a C<User::pwent> object.
3241
3242 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
3243
3244 =item getsockname SOCKET
3245 X<getsockname>
3246
3247 =for Pod::Functions retrieve the sockaddr for a given socket
3248
3249 Returns the packed sockaddr address of this end of the SOCKET connection,
3250 in case you don't know the address because you have several different
3251 IPs that the connection might have come in on.
3252
3253     use Socket;
3254     my $mysockaddr = getsockname($sock);
3255     my ($port, $myaddr) = sockaddr_in($mysockaddr);
3256     printf "Connect to %s [%s]\n",
3257        scalar gethostbyaddr($myaddr, AF_INET),
3258        inet_ntoa($myaddr);
3259
3260 =item getsockopt SOCKET,LEVEL,OPTNAME
3261 X<getsockopt>
3262
3263 =for Pod::Functions get socket options on a given socket
3264
3265 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
3266 Options may exist at multiple protocol levels depending on the socket
3267 type, but at least the uppermost socket level SOL_SOCKET (defined in the
3268 L<C<Socket>|Socket> module) will exist.  To query options at another
3269 level the protocol number of the appropriate protocol controlling the
3270 option should be supplied.  For example, to indicate that an option is
3271 to be interpreted by the TCP protocol, LEVEL should be set to the
3272 protocol number of TCP, which you can get using
3273 L<C<getprotobyname>|/getprotobyname NAME>.
3274
3275 The function returns a packed string representing the requested socket
3276 option, or L<C<undef>|/undef EXPR> on error, with the reason for the
3277 error placed in L<C<$!>|perlvar/$!>.  Just what is in the packed string
3278 depends on LEVEL and OPTNAME; consult L<getsockopt(2)> for details.  A
3279 common case is that the option is an integer, in which case the result
3280 is a packed integer, which you can decode using
3281 L<C<unpack>|/unpack TEMPLATE,EXPR> with the C<i> (or C<I>) format.
3282
3283 Here's an example to test whether Nagle's algorithm is enabled on a socket:
3284
3285     use Socket qw(:all);
3286
3287     defined(my $tcp = getprotobyname("tcp"))
3288         or die "Could not determine the protocol number for tcp";
3289     # my $tcp = IPPROTO_TCP; # Alternative
3290     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
3291         or die "getsockopt TCP_NODELAY: $!";
3292     my $nodelay = unpack("I", $packed);
3293     print "Nagle's algorithm is turned ",
3294            $nodelay ? "off\n" : "on\n";
3295
3296 Portability issues: L<perlport/getsockopt>.
3297
3298 =item glob EXPR
3299 X<glob> X<wildcard> X<filename, expansion> X<expand>
3300
3301 =item glob
3302
3303 =for Pod::Functions expand filenames using wildcards
3304
3305 In list context, returns a (possibly empty) list of filename expansions on
3306 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
3307 scalar context, glob iterates through such filename expansions, returning
3308 undef when the list is exhausted.  This is the internal function
3309 implementing the C<< <*.c> >> operator, but you can use it directly.  If
3310 EXPR is omitted, L<C<$_>|perlvar/$_> is used.  The C<< <*.c> >> operator
3311 is discussed in more detail in L<perlop/"I/O Operators">.
3312
3313 Note that L<C<glob>|/glob EXPR> splits its arguments on whitespace and
3314 treats
3315 each segment as separate pattern.  As such, C<glob("*.c *.h")>
3316 matches all files with a F<.c> or F<.h> extension.  The expression
3317 C<glob(".* *")> matches all files in the current working directory.
3318 If you want to glob filenames that might contain whitespace, you'll
3319 have to use extra quotes around the spacey filename to protect it.
3320 For example, to glob filenames that have an C<e> followed by a space
3321 followed by an C<f>, use one of:
3322
3323     my @spacies = <"*e f*">;
3324     my @spacies = glob '"*e f*"';
3325     my @spacies = glob q("*e f*");
3326
3327 If you had to get a variable through, you could do this:
3328
3329     my @spacies = glob "'*${var}e f*'";
3330     my @spacies = glob qq("*${var}e f*");
3331
3332 If non-empty braces are the only wildcard characters used in the
3333 L<C<glob>|/glob EXPR>, no filenames are matched, but potentially many
3334 strings are returned.  For example, this produces nine strings, one for
3335 each pairing of fruits and colors:
3336
3337     my @many = glob "{apple,tomato,cherry}={green,yellow,red}";
3338
3339 This operator is implemented using the standard C<File::Glob> extension.
3340 See L<File::Glob> for details, including
3341 L<C<bsd_glob>|File::Glob/C<bsd_glob>>, which does not treat whitespace
3342 as a pattern separator.
3343
3344 Portability issues: L<perlport/glob>.
3345
3346 =item gmtime EXPR
3347 X<gmtime> X<UTC> X<Greenwich>
3348
3349 =item gmtime
3350
3351 =for Pod::Functions convert UNIX time into record or string using Greenwich time
3352
3353 Works just like L<C<localtime>|/localtime EXPR> but the returned values
3354 are localized for the standard Greenwich time zone.
3355
3356 Note: When called in list context, $isdst, the last value
3357 returned by gmtime, is always C<0>.  There is no
3358 Daylight Saving Time in GMT.
3359
3360 Portability issues: L<perlport/gmtime>.
3361
3362 =item goto LABEL
3363 X<goto> X<jump> X<jmp>
3364
3365 =item goto EXPR
3366
3367 =item goto &NAME
3368
3369 =for Pod::Functions create spaghetti code
3370
3371 The C<goto LABEL> form finds the statement labeled with LABEL and
3372 resumes execution there.  It can't be used to get out of a block or
3373 subroutine given to L<C<sort>|/sort SUBNAME LIST>.  It can be used to go
3374 almost anywhere else within the dynamic scope, including out of
3375 subroutines, but it's usually better to use some other construct such as
3376 L<C<last>|/last LABEL> or L<C<die>|/die LIST>.  The author of Perl has
3377 never felt the need to use this form of L<C<goto>|/goto LABEL> (in Perl,
3378 that is; C is another matter).  (The difference is that C does not offer
3379 named loops combined with loop control.  Perl does, and this replaces
3380 most structured uses of L<C<goto>|/goto LABEL> in other languages.)
3381
3382 The C<goto EXPR> form expects to evaluate C<EXPR> to a code reference or
3383 a label name.  If it evaluates to a code reference, it will be handled
3384 like C<goto &NAME>, below.  This is especially useful for implementing
3385 tail recursion via C<goto __SUB__>.
3386
3387 If the expression evaluates to a label name, its scope will be resolved
3388 dynamically.  This allows for computed L<C<goto>|/goto LABEL>s per
3389 FORTRAN, but isn't necessarily recommended if you're optimizing for
3390 maintainability:
3391
3392     goto ("FOO", "BAR", "GLARCH")[$i];
3393
3394 As shown in this example, C<goto EXPR> is exempt from the "looks like a
3395 function" rule.  A pair of parentheses following it does not (necessarily)
3396 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
3397 Also, unlike most named operators, this has the same precedence as
3398 assignment.
3399
3400 Use of C<goto LABEL> or C<goto EXPR> to jump into a construct is
3401 deprecated and will issue a warning.  Even then, it may not be used to
3402 go into any construct that requires initialization, such as a
3403 subroutine, a C<foreach> loop, or a C<given>
3404 block.  It also can't be used to go into a
3405 construct that is optimized away.
3406
3407 The C<goto &NAME> form is quite different from the other forms of
3408 L<C<goto>|/goto LABEL>.  In fact, it isn't a goto in the normal sense at
3409 all, and doesn't have the stigma associated with other gotos.  Instead,
3410 it exits the current subroutine (losing any changes set by
3411 L<C<local>|/local EXPR>) and immediately calls in its place the named
3412 subroutine using the current value of L<C<@_>|perlvar/@_>.  This is used
3413 by C<AUTOLOAD> subroutines that wish to load another subroutine and then
3414 pretend that the other subroutine had been called in the first place
3415 (except that any modifications to L<C<@_>|perlvar/@_> in the current
3416 subroutine are propagated to the other subroutine.) After the
3417 L<C<goto>|/goto LABEL>, not even L<C<caller>|/caller EXPR> will be able
3418 to tell that this routine was called first.
3419
3420 NAME needn't be the name of a subroutine; it can be a scalar variable
3421 containing a code reference or a block that evaluates to a code
3422 reference.
3423
3424 =item grep BLOCK LIST
3425 X<grep>
3426
3427 =item grep EXPR,LIST
3428
3429 =for Pod::Functions locate elements in a list test true against a given criterion
3430
3431 This is similar in spirit to, but not the same as, L<grep(1)> and its
3432 relatives.  In particular, it is not limited to using regular expressions.
3433
3434 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3435 L<C<$_>|perlvar/$_> to each element) and returns the list value
3436 consisting of those
3437 elements for which the expression evaluated to true.  In scalar
3438 context, returns the number of times the expression was true.
3439
3440     my @foo = grep(!/^#/, @bar);    # weed out comments
3441
3442 or equivalently,
3443
3444     my @foo = grep {!/^#/} @bar;    # weed out comments
3445
3446 Note that L<C<$_>|perlvar/$_> is an alias to the list value, so it can
3447 be used to
3448 modify the elements of the LIST.  While this is useful and supported,
3449 it can cause bizarre results if the elements of LIST are not variables.
3450 Similarly, grep returns aliases into the original list, much as a for
3451 loop's index variable aliases the list elements.  That is, modifying an
3452 element of a list returned by grep (for example, in a C<foreach>,
3453 L<C<map>|/map BLOCK LIST> or another L<C<grep>|/grep BLOCK LIST>)
3454 actually modifies the element in the original list.
3455 This is usually something to be avoided when writing clear code.
3456
3457 See also L<C<map>|/map BLOCK LIST> for a list composed of the results of
3458 the BLOCK or EXPR.
3459
3460 =item hex EXPR
3461 X<hex> X<hexadecimal>
3462
3463 =item hex
3464
3465 =for Pod::Functions convert a hexadecimal string to a number
3466
3467 Interprets EXPR as a hex string and returns the corresponding numeric value.
3468 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3469
3470     print hex '0xAf'; # prints '175'
3471     print hex 'aF';   # same
3472     $valid_input =~ /\A(?:0?[xX])?(?:_?[0-9a-fA-F])*\z/
3473
3474 A hex string consists of hex digits and an optional C<0x> or C<x> prefix.
3475 Each hex digit may be preceded by a single underscore, which will be ignored.
3476 Any other character triggers a warning and causes the rest of the string
3477 to be ignored (even leading whitespace, unlike L<C<oct>|/oct EXPR>).
3478 Only integers can be represented, and integer overflow triggers a warning.
3479
3480 To convert strings that might start with any of C<0>, C<0x>, or C<0b>,
3481 see L<C<oct>|/oct EXPR>.  To present something as hex, look into
3482 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>,
3483 L<C<sprintf>|/sprintf FORMAT, LIST>, and
3484 L<C<unpack>|/unpack TEMPLATE,EXPR>.
3485
3486 =item import LIST
3487 X<import>
3488
3489 =for Pod::Functions patch a module's namespace into your own
3490
3491 There is no builtin L<C<import>|/import LIST> function.  It is just an
3492 ordinary method (subroutine) defined (or inherited) by modules that wish
3493 to export names to another module.  The
3494 L<C<use>|/use Module VERSION LIST> function calls the
3495 L<C<import>|/import LIST> method for the package used.  See also
3496 L<C<use>|/use Module VERSION LIST>, L<perlmod>, and L<Exporter>.
3497
3498 =item index STR,SUBSTR,POSITION
3499 X<index> X<indexOf> X<InStr>
3500
3501 =item index STR,SUBSTR
3502
3503 =for Pod::Functions find a substring within a string
3504
3505 The index function searches for one string within another, but without
3506 the wildcard-like behavior of a full regular-expression pattern match.
3507 It returns the position of the first occurrence of SUBSTR in STR at
3508 or after POSITION.  If POSITION is omitted, starts searching from the
3509 beginning of the string.  POSITION before the beginning of the string
3510 or after its end is treated as if it were the beginning or the end,
3511 respectively.  POSITION and the return value are based at zero.
3512 If the substring is not found, L<C<index>|/index STR,SUBSTR,POSITION>
3513 returns -1.
3514
3515 =item int EXPR
3516 X<int> X<integer> X<truncate> X<trunc> X<floor>
3517
3518 =item int
3519
3520 =for Pod::Functions get the integer portion of a number
3521
3522 Returns the integer portion of EXPR.  If EXPR is omitted, uses
3523 L<C<$_>|perlvar/$_>.
3524 You should not use this function for rounding: one because it truncates
3525 towards C<0>, and two because machine representations of floating-point
3526 numbers can sometimes produce counterintuitive results.  For example,
3527 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3528 because it's really more like -268.99999999999994315658 instead.  Usually,
3529 the L<C<sprintf>|/sprintf FORMAT, LIST>,
3530 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>, or the
3531 L<C<POSIX::floor>|POSIX/C<floor>> and L<C<POSIX::ceil>|POSIX/C<ceil>>
3532 functions will serve you better than will L<C<int>|/int EXPR>.
3533
3534 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3535 X<ioctl>
3536
3537 =for Pod::Functions system-dependent device control system call
3538
3539 Implements the L<ioctl(2)> function.  You'll probably first have to say
3540
3541     require "sys/ioctl.ph";  # probably in
3542                              # $Config{archlib}/sys/ioctl.ph
3543
3544 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3545 exist or doesn't have the correct definitions you'll have to roll your
3546 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3547 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3548 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3549 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3550 will be passed as the third argument of the actual
3551 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR> call.  (If SCALAR
3552 has no string value but does have a numeric value, that value will be
3553 passed rather than a pointer to the string value.  To guarantee this to be
3554 true, add a C<0> to the scalar before using it.)  The
3555 L<C<pack>|/pack TEMPLATE,LIST> and L<C<unpack>|/unpack TEMPLATE,EXPR>
3556 functions may be needed to manipulate the values of structures used by
3557 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>.
3558
3559 The return value of L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR> (and
3560 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>) is as follows:
3561
3562     if OS returns:      then Perl returns:
3563         -1               undefined value
3564          0              string "0 but true"
3565     anything else           that number
3566
3567 Thus Perl returns true on success and false on failure, yet you can
3568 still easily determine the actual value returned by the operating
3569 system:
3570
3571     my $retval = ioctl(...) || -1;
3572     printf "System returned %d\n", $retval;
3573
3574 The special string C<"0 but true"> is exempt from
3575 L<C<Argument "..." isn't numeric>|perldiag/Argument "%s" isn't numeric%s>
3576 L<warnings> on improper numeric conversions.
3577
3578 Portability issues: L<perlport/ioctl>.
3579
3580 =item join EXPR,LIST
3581 X<join>
3582
3583 =for Pod::Functions join a list into a string using a separator
3584
3585 Joins the separate strings of LIST into a single string with fields
3586 separated by the value of EXPR, and returns that new string.  Example:
3587
3588    my $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3589
3590 Beware that unlike L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>,
3591 L<C<join>|/join EXPR,LIST> doesn't take a pattern as its first argument.
3592 Compare L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>.
3593
3594 =item keys HASH
3595 X<keys> X<key>
3596
3597 =item keys ARRAY
3598
3599 =for Pod::Functions retrieve list of indices from a hash
3600
3601 Called in list context, returns a list consisting of all the keys of the
3602 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3603 releases prior to 5.12 will produce a syntax error if you try to use an
3604 array argument.  In scalar context, returns the number of keys or indices.
3605
3606 Hash entries are returned in an apparently random order.  The actual random
3607 order is specific to a given hash; the exact same series of operations
3608 on two hashes may result in a different order for each hash.  Any insertion
3609 into the hash may change the order, as will any deletion, with the exception
3610 that the most recent key returned by L<C<each>|/each HASH> or
3611 L<C<keys>|/keys HASH> may be deleted without changing the order.  So
3612 long as a given hash is unmodified you may rely on
3613 L<C<keys>|/keys HASH>, L<C<values>|/values HASH> and L<C<each>|/each
3614 HASH> to repeatedly return the same order
3615 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
3616 details on why hash order is randomized.  Aside from the guarantees
3617 provided here the exact details of Perl's hash algorithm and the hash
3618 traversal order are subject to change in any release of Perl.  Tied hashes
3619 may behave differently to Perl's hashes with respect to changes in order on
3620 insertion and deletion of items.
3621
3622 As a side effect, calling L<C<keys>|/keys HASH> resets the internal
3623 iterator of the HASH or ARRAY (see L<C<each>|/each HASH>).  In
3624 particular, calling L<C<keys>|/keys HASH> in void context resets the
3625 iterator with no other overhead.
3626
3627 Here is yet another way to print your environment:
3628
3629     my @keys = keys %ENV;
3630     my @values = values %ENV;
3631     while (@keys) {
3632         print pop(@keys), '=', pop(@values), "\n";
3633     }
3634
3635 or how about sorted by key:
3636
3637     foreach my $key (sort(keys %ENV)) {
3638         print $key, '=', $ENV{$key}, "\n";
3639     }
3640
3641 The returned values are copies of the original keys in the hash, so
3642 modifying them will not affect the original hash.  Compare
3643 L<C<values>|/values HASH>.
3644
3645 To sort a hash by value, you'll need to use a
3646 L<C<sort>|/sort SUBNAME LIST> function.  Here's a descending numeric
3647 sort of a hash by its values:
3648
3649     foreach my $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3650         printf "%4d %s\n", $hash{$key}, $key;
3651     }
3652
3653 Used as an lvalue, L<C<keys>|/keys HASH> allows you to increase the
3654 number of hash buckets
3655 allocated for the given hash.  This can gain you a measure of efficiency if
3656 you know the hash is going to get big.  (This is similar to pre-extending
3657 an array by assigning a larger number to $#array.)  If you say
3658
3659     keys %hash = 200;
3660
3661 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3662 in fact, since it rounds up to the next power of two.  These
3663 buckets will be retained even if you do C<%hash = ()>, use C<undef
3664 %hash> if you want to free the storage while C<%hash> is still in scope.
3665 You can't shrink the number of buckets allocated for the hash using
3666 L<C<keys>|/keys HASH> in this way (but you needn't worry about doing
3667 this by accident, as trying has no effect).  C<keys @array> in an lvalue
3668 context is a syntax error.
3669
3670 Starting with Perl 5.14, an experimental feature allowed
3671 L<C<keys>|/keys HASH> to take a scalar expression. This experiment has
3672 been deemed unsuccessful, and was removed as of Perl 5.24.
3673
3674 To avoid confusing would-be users of your code who are running earlier
3675 versions of Perl with mysterious syntax errors, put this sort of thing at
3676 the top of your file to signal that your code will work I<only> on Perls of
3677 a recent vintage:
3678
3679     use 5.012;  # so keys/values/each work on arrays
3680
3681 See also L<C<each>|/each HASH>, L<C<values>|/values HASH>, and
3682 L<C<sort>|/sort SUBNAME LIST>.
3683
3684 =item kill SIGNAL, LIST
3685
3686 =item kill SIGNAL
3687 X<kill> X<signal>
3688
3689 =for Pod::Functions send a signal to a process or process group
3690
3691 Sends a signal to a list of processes.  Returns the number of arguments
3692 that were successfully used to signal (which is not necessarily the same
3693 as the number of processes actually killed, e.g. where a process group is
3694 killed).
3695
3696     my $cnt = kill 'HUP', $child1, $child2;
3697     kill 'KILL', @goners;
3698
3699 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3700 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3701 same signal.  The string form of SIGNAL is recommended for portability because
3702 the same signal may have different numbers in different operating systems.
3703
3704 A list of signal names supported by the current platform can be found in
3705 C<$Config{sig_name}>, which is provided by the L<C<Config>|Config>
3706 module.  See L<Config> for more details.
3707
3708 A negative signal name is the same as a negative signal number, killing process
3709 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3710 C<kill -9, $pgrp> will send C<SIGKILL> to
3711 the entire process group specified.  That
3712 means you usually want to use positive not negative signals.
3713
3714 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZERO>),
3715 no signal is sent to the process, but L<C<kill>|/kill SIGNAL, LIST>
3716 checks whether it's I<possible> to send a signal to it
3717 (that means, to be brief, that the process is owned by the same user, or we are
3718 the super-user).  This is useful to check that a child process is still
3719 alive (even if only as a zombie) and hasn't changed its UID.  See
3720 L<perlport> for notes on the portability of this construct.
3721
3722 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3723 the operating system.  For example, on POSIX-conforming systems, zero will
3724 signal the current process group, -1 will signal all processes, and any
3725 other negative PROCESS number will act as a negative signal number and
3726 kill the entire process group specified.
3727
3728 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3729 A warning may be produced in a future version.
3730
3731 See L<perlipc/"Signals"> for more details.
3732
3733 On some platforms such as Windows where the L<fork(2)> system call is not
3734 available, Perl can be built to emulate L<C<fork>|/fork> at the
3735 interpreter level.
3736 This emulation has limitations related to kill that have to be considered,
3737 for code running on Windows and in code intended to be portable.
3738
3739 See L<perlfork> for more details.
3740
3741 If there is no I<LIST> of processes, no signal is sent, and the return
3742 value is 0.  This form is sometimes used, however, because it causes
3743 tainting checks to be run.  But see
3744 L<perlsec/Laundering and Detecting Tainted Data>.
3745
3746 Portability issues: L<perlport/kill>.
3747
3748 =item last LABEL
3749 X<last> X<break>
3750
3751 =item last EXPR
3752
3753 =item last
3754
3755 =for Pod::Functions exit a block prematurely
3756
3757 The L<C<last>|/last LABEL> command is like the C<break> statement in C
3758 (as used in
3759 loops); it immediately exits the loop in question.  If the LABEL is
3760 omitted, the command refers to the innermost enclosing
3761 loop.  The C<last EXPR> form, available starting in Perl
3762 5.18.0, allows a label name to be computed at run time,
3763 and is otherwise identical to C<last LABEL>.  The
3764 L<C<continue>|/continue BLOCK> block, if any, is not executed:
3765
3766     LINE: while (<STDIN>) {
3767         last LINE if /^$/;  # exit when done with header
3768         #...
3769     }
3770
3771 L<C<last>|/last LABEL> cannot be used to exit a block that returns a
3772 value such as C<eval {}>, C<sub {}>, or C<do {}>, and should not be used
3773 to exit a L<C<grep>|/grep BLOCK LIST> or L<C<map>|/map BLOCK LIST>
3774 operation.
3775
3776 Note that a block by itself is semantically identical to a loop
3777 that executes once.  Thus L<C<last>|/last LABEL> can be used to effect
3778 an early exit out of such a block.
3779
3780 See also L<C<continue>|/continue BLOCK> for an illustration of how
3781 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, and
3782 L<C<redo>|/redo LABEL> work.
3783
3784 Unlike most named operators, this has the same precedence as assignment.
3785 It is also exempt from the looks-like-a-function rule, so
3786 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3787 L<C<last>|/last LABEL>.
3788
3789 =item lc EXPR
3790 X<lc> X<lowercase>
3791
3792 =item lc
3793
3794 =for Pod::Functions return lower-case version of a string
3795
3796 Returns a lowercased version of EXPR.  This is the internal function
3797 implementing the C<\L> escape in double-quoted strings.
3798
3799 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3800
3801 What gets returned depends on several factors:
3802
3803 =over
3804
3805 =item If C<use bytes> is in effect:
3806
3807 The results follow ASCII rules.  Only the characters C<A-Z> change,
3808 to C<a-z> respectively.
3809
3810 =item Otherwise, if C<use locale> for C<LC_CTYPE> is in effect:
3811
3812 Respects current C<LC_CTYPE> locale for code points < 256; and uses Unicode
3813 rules for the remaining code points (this last can only happen if
3814 the UTF8 flag is also set).  See L<perllocale>.
3815
3816 Starting in v5.20, Perl uses full Unicode rules if the locale is
3817 UTF-8.  Otherwise, there is a deficiency in this scheme, which is that
3818 case changes that cross the 255/256
3819 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3820 LETTER SHARP S (U+1E9E) in Unicode rules is U+00DF (on ASCII
3821 platforms).   But under C<use locale> (prior to v5.20 or not a UTF-8
3822 locale), the lower case of U+1E9E is
3823 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3824 current locale, and Perl has no way of knowing if that character even
3825 exists in the locale, much less what code point it is.  Perl returns
3826 a result that is above 255 (almost always the input character unchanged),
3827 for all instances (and there aren't many) where the 255/256 boundary
3828 would otherwise be crossed; and starting in v5.22, it raises a
3829 L<locale|perldiag/Can't do %s("%s") on non-UTF-8 locale; resolved to "%s".> warning.
3830
3831 =item Otherwise, If EXPR has the UTF8 flag set:
3832
3833 Unicode rules are used for the case change.
3834
3835 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3836
3837 Unicode rules are used for the case change.
3838
3839 =item Otherwise:
3840
3841 ASCII rules are used for the case change.  The lowercase of any character
3842 outside the ASCII range is the character itself.
3843
3844 =back
3845
3846 =item lcfirst EXPR
3847 X<lcfirst> X<lowercase>
3848
3849 =item lcfirst
3850
3851 =for Pod::Functions return a string with just the next letter in lower case
3852
3853 Returns the value of EXPR with the first character lowercased.  This
3854 is the internal function implementing the C<\l> escape in
3855 double-quoted strings.
3856
3857 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3858
3859 This function behaves the same way under various pragmas, such as in a locale,
3860 as L<C<lc>|/lc EXPR> does.
3861
3862 =item length EXPR
3863 X<length> X<size>
3864
3865 =item length
3866
3867 =for Pod::Functions return the number of characters in a string
3868
3869 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3870 omitted, returns the length of L<C<$_>|perlvar/$_>.  If EXPR is
3871 undefined, returns L<C<undef>|/undef EXPR>.
3872
3873 This function cannot be used on an entire array or hash to find out how
3874 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3875 %hash>, respectively.
3876
3877 Like all Perl character operations, L<C<length>|/length EXPR> normally
3878 deals in logical
3879 characters, not physical bytes.  For how many bytes a string encoded as
3880 UTF-8 would take up, use C<length(Encode::encode('UTF-8', EXPR))>
3881 (you'll have to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3882
3883 =item __LINE__
3884 X<__LINE__>
3885
3886 =for Pod::Functions the current source line number
3887
3888 A special token that compiles to the current line number.
3889
3890 =item link OLDFILE,NEWFILE
3891 X<link>
3892
3893 =for Pod::Functions create a hard link in the filesystem
3894
3895 Creates a new filename linked to the old filename.  Returns true for
3896 success, false otherwise.
3897
3898 Portability issues: L<perlport/link>.
3899
3900 =item listen SOCKET,QUEUESIZE
3901 X<listen>
3902
3903 =for Pod::Functions register your socket as a server
3904
3905 Does the same thing that the L<listen(2)> system call does.  Returns true if
3906 it succeeded, false otherwise.  See the example in
3907 L<perlipc/"Sockets: Client/Server Communication">.
3908
3909 =item local EXPR
3910 X<local>
3911
3912 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3913
3914 You really probably want to be using L<C<my>|/my VARLIST> instead,
3915 because L<C<local>|/local EXPR> isn't what most people think of as
3916 "local".  See L<perlsub/"Private Variables via my()"> for details.
3917
3918 A local modifies the listed variables to be local to the enclosing
3919 block, file, or eval.  If more than one value is listed, the list must
3920 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3921 for details, including issues with tied arrays and hashes.
3922
3923 The C<delete local EXPR> construct can also be used to localize the deletion
3924 of array/hash elements to the current block.
3925 See L<perlsub/"Localized deletion of elements of composite types">.
3926
3927 =item localtime EXPR
3928 X<localtime> X<ctime>
3929
3930 =item localtime
3931
3932 =for Pod::Functions convert UNIX time into record or string using local time
3933
3934 Converts a time as returned by the time function to a 9-element list
3935 with the time analyzed for the local time zone.  Typically used as
3936 follows:
3937
3938     #     0    1    2     3     4    5     6     7     8
3939     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3940                                                 localtime(time);
3941
3942 All list elements are numeric and come straight out of the C `struct
3943 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3944 of the specified time.
3945
3946 C<$mday> is the day of the month and C<$mon> the month in
3947 the range C<0..11>, with 0 indicating January and 11 indicating December.
3948 This makes it easy to get a month name from a list:
3949
3950     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3951     print "$abbr[$mon] $mday";
3952     # $mon=9, $mday=18 gives "Oct 18"
3953
3954 C<$year> contains the number of years since 1900.  To get a 4-digit
3955 year write:
3956
3957     $year += 1900;
3958
3959 To get the last two digits of the year (e.g., "01" in 2001) do:
3960
3961     $year = sprintf("%02d", $year % 100);
3962
3963 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3964 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3965 (or C<0..365> in leap years.)
3966
3967 C<$isdst> is true if the specified time occurs during Daylight Saving
3968 Time, false otherwise.
3969
3970 If EXPR is omitted, L<C<localtime>|/localtime EXPR> uses the current
3971 time (as returned by L<C<time>|/time>).
3972
3973 In scalar context, L<C<localtime>|/localtime EXPR> returns the
3974 L<ctime(3)> value:
3975
3976     my $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3977
3978 The format of this scalar value is B<not> locale-dependent but built
3979 into Perl.  For GMT instead of local time use the
3980 L<C<gmtime>|/gmtime EXPR> builtin.  See also the
3981 L<C<Time::Local>|Time::Local> module (for converting seconds, minutes,
3982 hours, and such back to the integer value returned by L<C<time>|/time>),
3983 and the L<POSIX> module's L<C<strftime>|POSIX/C<strftime>> and
3984 L<C<mktime>|POSIX/C<mktime>> functions.
3985
3986 To get somewhat similar but locale-dependent date strings, set up your
3987 locale environment variables appropriately (please see L<perllocale>) and
3988 try for example:
3989
3990     use POSIX qw(strftime);
3991     my $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3992     # or for GMT formatted appropriately for your locale:
3993     my $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3994
3995 Note that C<%a> and C<%b>, the short forms of the day of the week
3996 and the month of the year, may not necessarily be three characters wide.
3997
3998 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3999 by-name access mechanism to the L<C<gmtime>|/gmtime EXPR> and
4000 L<C<localtime>|/localtime EXPR> functions, respectively.
4001
4002 For a comprehensive date and time representation look at the
4003 L<DateTime> module on CPAN.
4004
4005 Portability issues: L<perlport/localtime>.
4006
4007 =item lock THING
4008 X<lock>
4009
4010 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
4011
4012 This function places an advisory lock on a shared variable or referenced
4013 object contained in I<THING> until the lock goes out of scope.
4014
4015 The value returned is the scalar itself, if the argument is a scalar, or a
4016 reference, if the argument is a hash, array or subroutine.
4017
4018 L<C<lock>|/lock THING> is a "weak keyword"; this means that if you've
4019 defined a function
4020 by this name (before any calls to it), that function will be called
4021 instead.  If you are not under C<use threads::shared> this does nothing.
4022 See L<threads::shared>.
4023
4024 =item log EXPR
4025 X<log> X<logarithm> X<e> X<ln> X<base>
4026
4027 =item log
4028
4029 =for Pod::Functions retrieve the natural logarithm for a number
4030
4031 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
4032 returns the log of L<C<$_>|perlvar/$_>.  To get the
4033 log of another base, use basic algebra:
4034 The base-N log of a number is equal to the natural log of that number
4035 divided by the natural log of N.  For example:
4036
4037     sub log10 {
4038         my $n = shift;
4039         return log($n)/log(10);
4040     }
4041
4042 See also L<C<exp>|/exp EXPR> for the inverse operation.
4043
4044 =item lstat FILEHANDLE
4045 X<lstat>
4046
4047 =item lstat EXPR
4048
4049 =item lstat DIRHANDLE
4050
4051 =item lstat
4052
4053 =for Pod::Functions stat a symbolic link
4054
4055 Does the same thing as the L<C<stat>|/stat FILEHANDLE> function
4056 (including setting the special C<_> filehandle) but stats a symbolic
4057 link instead of the file the symbolic link points to.  If symbolic links
4058 are unimplemented on your system, a normal L<C<stat>|/stat FILEHANDLE>
4059 is done.  For much more detailed information, please see the
4060 documentation for L<C<stat>|/stat FILEHANDLE>.
4061
4062 If EXPR is omitted, stats L<C<$_>|perlvar/$_>.
4063
4064 Portability issues: L<perlport/lstat>.
4065
4066 =item m//
4067
4068 =for Pod::Functions match a string with a regular expression pattern
4069
4070 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
4071
4072 =item map BLOCK LIST
4073 X<map>
4074
4075 =item map EXPR,LIST
4076
4077 =for Pod::Functions apply a change to a list to get back a new list with the changes
4078
4079 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
4080 L<C<$_>|perlvar/$_> to each element) and composes a list of the results of
4081 each such evaluation.  Each element of LIST may produce zero, one, or more
4082 elements in the generated list, so the number of elements in the generated
4083 list may differ from that in LIST.  In scalar context, returns the total
4084 number of elements so generated.  In list context, returns the generated list.
4085
4086     my @chars = map(chr, @numbers);
4087
4088 translates a list of numbers to the corresponding characters.
4089
4090     my @squares = map { $_ * $_ } @numbers;
4091
4092 translates a list of numbers to their squared values.
4093
4094     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
4095
4096 shows that number of returned elements can differ from the number of
4097 input elements.  To omit an element, return an empty list ().
4098 This could also be achieved by writing
4099
4100     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
4101
4102 which makes the intention more clear.
4103
4104 Map always returns a list, which can be
4105 assigned to a hash such that the elements
4106 become key/value pairs.  See L<perldata> for more details.
4107
4108     my %hash = map { get_a_key_for($_) => $_ } @array;
4109
4110 is just a funny way to write
4111
4112     my %hash;
4113     foreach (@array) {
4114         $hash{get_a_key_for($_)} = $_;
4115     }
4116
4117 Note that L<C<$_>|perlvar/$_> is an alias to the list value, so it can
4118 be used to modify the elements of the LIST.  While this is useful and
4119 supported, it can cause bizarre results if the elements of LIST are not
4120 variables.  Using a regular C<foreach> loop for this purpose would be
4121 clearer in most cases.  See also L<C<grep>|/grep BLOCK LIST> for a
4122 list composed of those items of the original list for which the BLOCK
4123 or EXPR evaluates to true.
4124
4125 C<{> starts both hash references and blocks, so C<map { ...> could be either
4126 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
4127 ahead for the closing C<}> it has to take a guess at which it's dealing with
4128 based on what it finds just after the
4129 C<{>.  Usually it gets it right, but if it
4130 doesn't it won't realize something is wrong until it gets to the C<}> and
4131 encounters the missing (or unexpected) comma.  The syntax error will be
4132 reported close to the C<}>, but you'll need to change something near the C<{>
4133 such as using a unary C<+> or semicolon to give Perl some help:
4134
4135  my %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
4136  my %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
4137  my %hash = map {; "\L$_" => 1  } @array # this also works
4138  my %hash = map { ("\L$_" => 1) } @array # as does this
4139  my %hash = map {  lc($_) => 1  } @array # and this.
4140  my %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
4141
4142  my %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
4143
4144 or to force an anon hash constructor use C<+{>:
4145
4146     my @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
4147                                               # comma at end
4148
4149 to get a list of anonymous hashes each with only one entry apiece.
4150
4151 =item mkdir FILENAME,MODE
4152 X<mkdir> X<md> X<directory, create>
4153
4154 =item mkdir FILENAME
4155
4156 =item mkdir
4157
4158 =for Pod::Functions create a directory
4159
4160 Creates the directory specified by FILENAME, with permissions
4161 specified by MODE (as modified by L<C<umask>|/umask EXPR>).  If it
4162 succeeds it returns true; otherwise it returns false and sets
4163 L<C<$!>|perlvar/$!> (errno).
4164 MODE defaults to 0777 if omitted, and FILENAME defaults
4165 to L<C<$_>|perlvar/$_> if omitted.
4166
4167 In general, it is better to create directories with a permissive MODE
4168 and let the user modify that with their L<C<umask>|/umask EXPR> than it
4169 is to supply
4170 a restrictive MODE and give the user no way to be more permissive.
4171 The exceptions to this rule are when the file or directory should be
4172 kept private (mail files, for instance).  The documentation for
4173 L<C<umask>|/umask EXPR> discusses the choice of MODE in more detail.
4174
4175 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
4176 number of trailing slashes.  Some operating and filesystems do not get
4177 this right, so Perl automatically removes all trailing slashes to keep
4178 everyone happy.
4179
4180 To recursively create a directory structure, look at
4181 the L<C<make_path>|File::Path/make_path( $dir1, $dir2, .... )> function
4182 of the L<File::Path> module.
4183
4184 =item msgctl ID,CMD,ARG
4185 X<msgctl>
4186
4187 =for Pod::Functions SysV IPC message control operations
4188
4189 Calls the System V IPC function L<msgctl(2)>.  You'll probably have to say
4190
4191     use IPC::SysV;
4192
4193 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4194 then ARG must be a variable that will hold the returned C<msqid_ds>
4195 structure.  Returns like L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>:
4196 the undefined value for error, C<"0 but true"> for zero, or the actual
4197 return value otherwise.  See also L<perlipc/"SysV IPC"> and the
4198 documentation for L<C<IPC::SysV>|IPC::SysV> and
4199 L<C<IPC::Semaphore>|IPC::Semaphore>.
4200
4201 Portability issues: L<perlport/msgctl>.
4202
4203 =item msgget KEY,FLAGS
4204 X<msgget>
4205
4206 =for Pod::Functions get SysV IPC message queue
4207
4208 Calls the System V IPC function L<msgget(2)>.  Returns the message queue
4209 id, or L<C<undef>|/undef EXPR> on error.  See also L<perlipc/"SysV IPC">
4210 and the documentation for L<C<IPC::SysV>|IPC::SysV> and
4211 L<C<IPC::Msg>|IPC::Msg>.
4212
4213 Portability issues: L<perlport/msgget>.
4214
4215 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
4216 X<msgrcv>
4217
4218 =for Pod::Functions receive a SysV IPC message from a message queue
4219
4220 Calls the System V IPC function msgrcv to receive a message from
4221 message queue ID into variable VAR with a maximum message size of
4222 SIZE.  Note that when a message is received, the message type as a
4223 native long integer will be the first thing in VAR, followed by the
4224 actual message.  This packing may be opened with C<unpack("l! a*")>.
4225 Taints the variable.  Returns true if successful, false
4226 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
4227 L<C<IPC::SysV>|IPC::SysV> and L<C<IPC::Msg>|IPC::Msg>.
4228
4229 Portability issues: L<perlport/msgrcv>.
4230
4231 =item msgsnd ID,MSG,FLAGS
4232 X<msgsnd>
4233
4234 =for Pod::Functions send a SysV IPC message to a message queue
4235
4236 Calls the System V IPC function msgsnd to send the message MSG to the
4237 message queue ID.  MSG must begin with the native long integer message
4238 type, be followed by the length of the actual message, and then finally
4239 the message itself.  This kind of packing can be achieved with
4240 C<pack("l! a*", $type, $message)>.  Returns true if successful,
4241 false on error.  See also L<perlipc/"SysV IPC"> and the documentation
4242 for L<C<IPC::SysV>|IPC::SysV> and L<C<IPC::Msg>|IPC::Msg>.
4243
4244 Portability issues: L<perlport/msgsnd>.
4245
4246 =item my VARLIST
4247 X<my>
4248
4249 =item my TYPE VARLIST
4250
4251 =item my VARLIST : ATTRS
4252
4253 =item my TYPE VARLIST : ATTRS
4254
4255 =for Pod::Functions declare and assign a local variable (lexical scoping)
4256
4257 A L<C<my>|/my VARLIST> declares the listed variables to be local
4258 (lexically) to the enclosing block, file, or L<C<eval>|/eval EXPR>.  If
4259 more than one variable is listed, the list must be placed in
4260 parentheses.
4261
4262 The exact semantics and interface of TYPE and ATTRS are still
4263 evolving.  TYPE may be a bareword, a constant declared
4264 with L<C<use constant>|constant>, or L<C<__PACKAGE__>|/__PACKAGE__>.  It
4265 is
4266 currently bound to the use of the L<fields> pragma,
4267 and attributes are handled using the L<attributes> pragma, or starting
4268 from Perl 5.8.0 also via the L<Attribute::Handlers> module.  See
4269 L<perlsub/"Private Variables via my()"> for details.
4270
4271 Note that with a parenthesised list, L<C<undef>|/undef EXPR> can be used
4272 as a dummy placeholder, for example to skip assignment of initial
4273 values:
4274
4275     my ( undef, $min, $hour ) = localtime;
4276
4277 =item next LABEL
4278 X<next> X<continue>
4279
4280 =item next EXPR
4281
4282 =item next
4283
4284 =for Pod::Functions iterate a block prematurely
4285
4286 The L<C<next>|/next LABEL> command is like the C<continue> statement in
4287 C; it starts the next iteration of the loop:
4288
4289     LINE: while (<STDIN>) {
4290         next LINE if /^#/;  # discard comments
4291         #...
4292     }
4293
4294 Note that if there were a L<C<continue>|/continue BLOCK> block on the
4295 above, it would get
4296 executed even on discarded lines.  If LABEL is omitted, the command
4297 refers to the innermost enclosing loop.  The C<next EXPR> form, available
4298 as of Perl 5.18.0, allows a label name to be computed at run time, being
4299 otherwise identical to C<next LABEL>.
4300
4301 L<C<next>|/next LABEL> cannot be used to exit a block which returns a
4302 value such as C<eval {}>, C<sub {}>, or C<do {}>, and should not be used
4303 to exit a L<C<grep>|/grep BLOCK LIST> or L<C<map>|/map BLOCK LIST>
4304 operation.
4305
4306 Note that a block by itself is semantically identical to a loop
4307 that executes once.  Thus L<C<next>|/next LABEL> will exit such a block
4308 early.
4309
4310 See also L<C<continue>|/continue BLOCK> for an illustration of how
4311 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, and
4312 L<C<redo>|/redo LABEL> work.
4313
4314 Unlike most named operators, this has the same precedence as assignment.
4315 It is also exempt from the looks-like-a-function rule, so
4316 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
4317 L<C<next>|/next LABEL>.
4318
4319 =item no MODULE VERSION LIST
4320 X<no declarations>
4321 X<unimporting>
4322
4323 =item no MODULE VERSION
4324
4325 =item no MODULE LIST
4326
4327 =item no MODULE
4328
4329 =item no VERSION
4330
4331 =for Pod::Functions unimport some module symbols or semantics at compile time
4332
4333 See the L<C<use>|/use Module VERSION LIST> function, of which
4334 L<C<no>|/no MODULE VERSION LIST> is the opposite.
4335
4336 =item oct EXPR
4337 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
4338
4339 =item oct
4340
4341 =for Pod::Functions convert a string to an octal number
4342
4343 Interprets EXPR as an octal string and returns the corresponding
4344 value.  (If EXPR happens to start off with C<0x>, interprets it as a
4345 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
4346 binary string.  Leading whitespace is ignored in all three cases.)
4347 The following will handle decimal, binary, octal, and hex in standard
4348 Perl notation:
4349
4350     $val = oct($val) if $val =~ /^0/;
4351
4352 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.   To go the other way
4353 (produce a number in octal), use L<C<sprintf>|/sprintf FORMAT, LIST> or
4354 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>:
4355
4356     my $dec_perms = (stat("filename"))[2] & 07777;
4357     my $oct_perm_str = sprintf "%o", $perms;
4358
4359 The L<C<oct>|/oct EXPR> function is commonly used when a string such as
4360 C<644> needs
4361 to be converted into a file mode, for example.  Although Perl
4362 automatically converts strings into numbers as needed, this automatic
4363 conversion assumes base 10.
4364
4365 Leading white space is ignored without warning, as too are any trailing
4366 non-digits, such as a decimal point (L<C<oct>|/oct EXPR> only handles
4367 non-negative integers, not negative integers or floating point).
4368
4369 =item open FILEHANDLE,EXPR
4370 X<open> X<pipe> X<file, open> X<fopen>
4371
4372 =item open FILEHANDLE,MODE,EXPR
4373
4374 =item open FILEHANDLE,MODE,EXPR,LIST
4375
4376 =item open FILEHANDLE,MODE,REFERENCE
4377
4378 =item open FILEHANDLE
4379
4380 =for Pod::Functions open a file, pipe, or descriptor
4381
4382 Opens the file whose filename is given by EXPR, and associates it with
4383 FILEHANDLE.
4384
4385 Simple examples to open a file for reading:
4386
4387     open(my $fh, "<", "input.txt")
4388         or die "Can't open < input.txt: $!";
4389
4390 and for writing:
4391
4392     open(my $fh, ">", "output.txt")
4393         or die "Can't open > output.txt: $!";
4394
4395 (The following is a comprehensive reference to
4396 L<C<open>|/open FILEHANDLE,EXPR>: for a gentler introduction you may
4397 consider L<perlopentut>.)
4398
4399 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
4400 new filehandle is autovivified, meaning that the variable is assigned a
4401 reference to a newly allocated anonymous filehandle.  Otherwise if
4402 FILEHANDLE is an expression, its value is the real filehandle.  (This is
4403 considered a symbolic reference, so C<use strict "refs"> should I<not> be
4404 in effect.)
4405
4406 If three (or more) arguments are specified, the open mode (including
4407 optional encoding) in the second argument are distinct from the filename in
4408 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
4409 If MODE is C<< > >>, the file is opened for output, with existing files
4410 first being truncated ("clobbered") and nonexisting files newly created.
4411 If MODE is C<<< >> >>>, the file is opened for appending, again being
4412 created if necessary.
4413
4414 You can put a C<+> in front of the C<< > >> or C<< < >> to
4415 indicate that you want both read and write access to the file; thus
4416 C<< +< >> is almost always preferred for read/write updates--the
4417 C<< +> >> mode would clobber the file first.  You can't usually use
4418 either read-write mode for updating textfiles, since they have
4419 variable-length records.  See the B<-i> switch in L<perlrun> for a
4420 better approach.  The file is created with permissions of C<0666>
4421 modified by the process's L<C<umask>|/umask EXPR> value.
4422
4423 These various prefixes correspond to the L<fopen(3)> modes of C<r>,
4424 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
4425
4426 In the one- and two-argument forms of the call, the mode and filename
4427 should be concatenated (in that order), preferably separated by white
4428 space.  You can--but shouldn't--omit the mode in these forms when that mode
4429 is C<< < >>.  It is safe to use the two-argument form of
4430 L<C<open>|/open FILEHANDLE,EXPR> if the filename argument is a known literal.
4431
4432 For three or more arguments if MODE is C<|->, the filename is
4433 interpreted as a command to which output is to be piped, and if MODE
4434 is C<-|>, the filename is interpreted as a command that pipes
4435 output to us.  In the two-argument (and one-argument) form, one should
4436 replace dash (C<->) with the command.
4437 See L<perlipc/"Using open() for IPC"> for more examples of this.
4438 (You are not allowed to L<C<open>|/open FILEHANDLE,EXPR> to a command
4439 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>, and
4440 L<perlipc/"Bidirectional Communication with Another Process"> for
4441 alternatives.)
4442
4443 In the form of pipe opens taking three or more arguments, if LIST is specified
4444 (extra arguments after the command name) then LIST becomes arguments
4445 to the command invoked if the platform supports it.  The meaning of
4446 L<C<open>|/open FILEHANDLE,EXPR> with more than three arguments for
4447 non-pipe modes is not yet defined, but experimental "layers" may give
4448 extra LIST arguments meaning.
4449
4450 In the two-argument (and one-argument) form, opening C<< <- >>
4451 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
4452
4453 You may (and usually should) use the three-argument form of open to specify
4454 I/O layers (sometimes referred to as "disciplines") to apply to the handle
4455 that affect how the input and output are processed (see L<open> and
4456 L<PerlIO> for more details).  For example:
4457
4458   open(my $fh, "<:encoding(UTF-8)", $filename)
4459     || die "Can't open UTF-8 encoded $filename: $!";
4460
4461 opens the UTF8-encoded file containing Unicode characters;
4462 see L<perluniintro>.  Note that if layers are specified in the
4463 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
4464 usually set by the L<open> pragma or the switch C<-CioD>) are ignored.
4465 Those layers will also be ignored if you specify a colon with no name
4466 following it.  In that case the default layer for the operating system
4467 (:raw on Unix, :crlf on Windows) is used.
4468
4469 Open returns nonzero on success, the undefined value otherwise.  If
4470 the L<C<open>|/open FILEHANDLE,EXPR> involved a pipe, the return value
4471 happens to be the pid of the subprocess.
4472
4473 On some systems (in general, DOS- and Windows-based systems)
4474 L<C<binmode>|/binmode FILEHANDLE, LAYER> is necessary when you're not
4475 working with a text file.  For the sake of portability it is a good idea
4476 always to use it when appropriate, and never to use it when it isn't
4477 appropriate.  Also, people can set their I/O to be by default
4478 UTF8-encoded Unicode, not bytes.
4479
4480 When opening a file, it's seldom a good idea to continue
4481 if the request failed, so L<C<open>|/open FILEHANDLE,EXPR> is frequently
4482 used with L<C<die>|/die LIST>.  Even if L<C<die>|/die LIST> won't do
4483 what you want (say, in a CGI script,
4484 where you want to format a suitable error message (but there are
4485 modules that can help with that problem)) always check
4486 the return value from opening a file.
4487
4488 The filehandle will be closed when its reference count reaches zero.
4489 If it is a lexically scoped variable declared with L<C<my>|/my VARLIST>,
4490 that usually
4491 means the end of the enclosing scope.  However, this automatic close
4492 does not check for errors, so it is better to explicitly close
4493 filehandles, especially those used for writing:
4494
4495     close($handle)
4496        || warn "close failed: $!";
4497
4498 An older style is to use a bareword as the filehandle, as
4499
4500     open(FH, "<", "input.txt")
4501        or die "Can't open < input.txt: $!";
4502
4503 Then you can use C<FH> as the filehandle, in C<< close FH >> and C<<
4504 <FH> >> and so on.  Note that it's a global variable, so this form is
4505 not recommended in new code.
4506
4507 As a shortcut a one-argument call takes the filename from the global
4508 scalar variable of the same name as the filehandle:
4509
4510     $ARTICLE = 100;
4511     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
4512
4513 Here C<$ARTICLE> must be a global (package) scalar variable - not one
4514 declared with L<C<my>|/my VARLIST> or L<C<state>|/state VARLIST>.
4515
4516 As a special case the three-argument form with a read/write mode and the third
4517 argument being L<C<undef>|/undef EXPR>:
4518
4519     open(my $tmp, "+>", undef) or die ...
4520
4521 opens a filehandle to a newly created empty anonymous temporary file.
4522 (This happens under any mode, which makes C<< +> >> the only useful and
4523 sensible mode to use.)  You will need to
4524 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE> to do the reading.
4525
4526 Perl is built using PerlIO by default.  Unless you've
4527 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
4528 open filehandles directly to Perl scalars via:
4529
4530     open(my $fh, ">", \$variable) || ..
4531
4532 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
4533
4534     close STDOUT;
4535     open(STDOUT, ">", \$variable)
4536         or die "Can't open STDOUT: $!";
4537
4538 The scalars for in-memory files are treated as octet strings: unless
4539 the file is being opened with truncation the scalar may not contain
4540 any code points over 0xFF.
4541
4542 Opening in-memory files I<can> fail for a variety of reasons.  As with
4543 any other C<open>, check the return value for success.
4544
4545 See L<perliol> for detailed info on PerlIO.
4546
4547 General examples:
4548
4549  open(my $log, ">>", "/usr/spool/news/twitlog");
4550  # if the open fails, output is discarded
4551
4552  open(my $dbase, "+<", "dbase.mine")      # open for update
4553      or die "Can't open 'dbase.mine' for update: $!";
4554
4555  open(my $dbase, "+<dbase.mine")          # ditto
4556      or die "Can't open 'dbase.mine' for update: $!";
4557
4558  open(my $article_fh, "-|", "caesar <$article")  # decrypt
4559                                                  # article
4560      or die "Can't start caesar: $!";
4561
4562  open(my $article_fh, "caesar <$article |")      # ditto
4563      or die "Can't start caesar: $!";
4564
4565  open(my $out_fh, "|-", "sort >Tmp$$")    # $$ is our process id
4566      or die "Can't start sort: $!";
4567
4568  # in-memory files
4569  open(my $memory, ">", \$var)
4570      or die "Can't open memory file: $!";
4571  print $memory "foo!\n";              # output will appear in $var
4572
4573 You may also, in the Bourne shell tradition, specify an EXPR beginning
4574 with C<< >& >>, in which case the rest of the string is interpreted
4575 as the name of a filehandle (or file descriptor, if numeric) to be
4576 duped (as in L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4577 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4578 The mode you specify should match the mode of the original filehandle.
4579 (Duping a filehandle does not take into account any existing contents
4580 of IO buffers.)  If you use the three-argument
4581 form, then you can pass either a
4582 number, the name of a filehandle, or the normal "reference to a glob".
4583
4584 Here is a script that saves, redirects, and restores C<STDOUT> and
4585 C<STDERR> using various methods:
4586
4587     #!/usr/bin/perl
4588     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4589     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4590
4591     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4592     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4593
4594     select STDERR; $| = 1;  # make unbuffered
4595     select STDOUT; $| = 1;  # make unbuffered
4596
4597     print STDOUT "stdout 1\n";  # this works for
4598     print STDERR "stderr 1\n";  # subprocesses too
4599
4600     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4601     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4602
4603     print STDOUT "stdout 2\n";
4604     print STDERR "stderr 2\n";
4605
4606 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4607 or a filehandle, then Perl will do an equivalent of C's L<fdopen(3)> of
4608 that file descriptor (and not call L<dup(2)>); this is more
4609 parsimonious of file descriptors.  For example:
4610
4611     # open for input, reusing the fileno of $fd
4612     open(my $fh, "<&=", $fd)
4613
4614 or
4615
4616     open(my $fh, "<&=$fd")
4617
4618 or
4619
4620     # open for append, using the fileno of $oldfh
4621     open(my $fh, ">>&=", $oldfh)
4622
4623 Being parsimonious on filehandles is also useful (besides being
4624 parsimonious) for example when something is dependent on file
4625 descriptors, like for example locking using
4626 L<C<flock>|/flock FILEHANDLE,OPERATION>.  If you do just
4627 C<< open(my $A, ">>&", $B) >>, the filehandle C<$A> will not have the
4628 same file descriptor as C<$B>, and therefore C<flock($A)> will not
4629 C<flock($B)> nor vice versa.  But with C<< open(my $A, ">>&=", $B) >>,
4630 the filehandles will share the same underlying system file descriptor.
4631
4632 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4633 L<fdopen(3)> to implement the C<=> functionality.  On many Unix systems,
4634 L<fdopen(3)> fails when file descriptors exceed a certain value, typically 255.
4635 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4636
4637 You can see whether your Perl was built with PerlIO by running
4638 C<perl -V:useperlio>.  If it says C<'define'>, you have PerlIO;
4639 otherwise you don't.
4640
4641 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4642 with the one- or two-argument forms of
4643 L<C<open>|/open FILEHANDLE,EXPR>), an implicit L<C<fork>|/fork> is done,
4644 so L<C<open>|/open FILEHANDLE,EXPR> returns twice: in the parent process
4645 it returns the pid
4646 of the child process, and in the child process it returns (a defined) C<0>.
4647 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4648
4649 For example, use either
4650
4651    my $child_pid = open(my $from_kid, "-|") // die "Can't fork: $!";
4652
4653 or
4654
4655    my $child_pid = open(my $to_kid,   "|-") // die "Can't fork: $!";
4656
4657 followed by
4658
4659     if ($child_pid) {
4660         # am the parent:
4661         # either write $to_kid or else read $from_kid
4662         ...
4663        waitpid $child_pid, 0;
4664     } else {
4665         # am the child; use STDIN/STDOUT normally
4666         ...
4667         exit;
4668     }
4669
4670 The filehandle behaves normally for the parent, but I/O to that
4671 filehandle is piped from/to the STDOUT/STDIN of the child process.
4672 In the child process, the filehandle isn't opened--I/O happens from/to
4673 the new STDOUT/STDIN.  Typically this is used like the normal
4674 piped open when you want to exercise more control over just how the
4675 pipe command gets executed, such as when running setuid and
4676 you don't want to have to scan shell commands for metacharacters.
4677
4678 The following blocks are more or less equivalent:
4679
4680     open(my $fh, "|tr '[a-z]' '[A-Z]'");
4681     open(my $fh, "|-", "tr '[a-z]' '[A-Z]'");
4682     open(my $fh, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4683     open(my $fh, "|-", "tr", '[a-z]', '[A-Z]');
4684
4685     open(my $fh, "cat -n '$file'|");
4686     open(my $fh, "-|", "cat -n '$file'");
4687     open(my $fh, "-|") || exec "cat", "-n", $file;
4688     open(my $fh, "-|", "cat", "-n", $file);
4689
4690 The last two examples in each block show the pipe as "list form", which is
4691 not yet supported on all platforms.  A good rule of thumb is that if
4692 your platform has a real L<C<fork>|/fork> (in other words, if your platform is
4693 Unix, including Linux and MacOS X), you can use the list form.  You would
4694 want to use the list form of the pipe so you can pass literal arguments
4695 to the command without risk of the shell interpreting any shell metacharacters
4696 in them.  However, this also bars you from opening pipes to commands
4697 that intentionally contain shell metacharacters, such as: