This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
d48143e2c6fd06267befa756b8cf9d51a3a7d286
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore most whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
93 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
99 whether space interpretation within a single multi-character construct.  For
100 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
101 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
102 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
103 but can between the C<(> and C<?>.  Within any delimiters for such a
104 construct, allowed spaces are not affected by C</x>, and depend on the
105 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
106 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
107 in C<\p{...}>  there can be spaces that follow the Unicode rules, for which see
108 L<perluniprops/Properties accessible through \p{} and \P{}>.
109 X</x>
110
111 =head2 Regular Expressions
112
113 =head3 Metacharacters
114
115 The patterns used in Perl pattern matching evolved from those supplied in
116 the Version 8 regex routines.  (The routines are derived
117 (distantly) from Henry Spencer's freely redistributable reimplementation
118 of the V8 routines.)  See L<Version 8 Regular Expressions> for
119 details.
120
121 In particular the following metacharacters have their standard I<egrep>-ish
122 meanings:
123 X<metacharacter>
124 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
125
126
127     \        Quote the next metacharacter
128     ^        Match the beginning of the line
129     .        Match any character (except newline)
130     $        Match the end of the line (or before newline at the end)
131     |        Alternation
132     ()       Grouping
133     []       Bracketed Character class
134
135 By default, the "^" character is guaranteed to match only the
136 beginning of the string, the "$" character only the end (or before the
137 newline at the end), and Perl does certain optimizations with the
138 assumption that the string contains only one line.  Embedded newlines
139 will not be matched by "^" or "$".  You may, however, wish to treat a
140 string as a multi-line buffer, such that the "^" will match after any
141 newline within the string (except if the newline is the last character in
142 the string), and "$" will match before any newline.  At the
143 cost of a little more overhead, you can do this by using the /m modifier
144 on the pattern match operator.  (Older programs did this by setting C<$*>,
145 but this practice has been removed in perl 5.9.)
146 X<^> X<$> X</m>
147
148 To simplify multi-line substitutions, the "." character never matches a
149 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
150 the string is a single line--even if it isn't.
151 X<.> X</s>
152
153 =head3 Quantifiers
154
155 The following standard quantifiers are recognized:
156 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
157
158     *           Match 0 or more times
159     +           Match 1 or more times
160     ?           Match 1 or 0 times
161     {n}         Match exactly n times
162     {n,}        Match at least n times
163     {n,m}       Match at least n but not more than m times
164
165 (If a curly bracket occurs in any other context, it is treated
166 as a regular character.  In particular, the lower bound
167 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
168 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
169 to non-negative integral values less than a preset limit defined when perl is built.
170 This is usually 32766 on the most common platforms.  The actual limit can
171 be seen in the error message generated by code such as this:
172
173     $_ **= $_ , / {$_} / for 2 .. 42;
174
175 By default, a quantified subpattern is "greedy", that is, it will match as
176 many times as possible (given a particular starting location) while still
177 allowing the rest of the pattern to match.  If you want it to match the
178 minimum number of times possible, follow the quantifier with a "?".  Note
179 that the meanings don't change, just the "greediness":
180 X<metacharacter> X<greedy> X<greediness>
181 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
182
183     *?        Match 0 or more times, not greedily
184     +?        Match 1 or more times, not greedily
185     ??        Match 0 or 1 time, not greedily
186     {n}?      Match exactly n times, not greedily
187     {n,}?     Match at least n times, not greedily
188     {n,m}?    Match at least n but not more than m times, not greedily
189
190 By default, when a quantified subpattern does not allow the rest of the
191 overall pattern to match, Perl will backtrack. However, this behaviour is
192 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
193 as well.
194
195  *+     Match 0 or more times and give nothing back
196  ++     Match 1 or more times and give nothing back
197  ?+     Match 0 or 1 time and give nothing back
198  {n}+   Match exactly n times and give nothing back (redundant)
199  {n,}+  Match at least n times and give nothing back
200  {n,m}+ Match at least n but not more than m times and give nothing back
201
202 For instance,
203
204    'aaaa' =~ /a++a/
205
206 will never match, as the C<a++> will gobble up all the C<a>'s in the
207 string and won't leave any for the remaining part of the pattern. This
208 feature can be extremely useful to give perl hints about where it
209 shouldn't backtrack. For instance, the typical "match a double-quoted
210 string" problem can be most efficiently performed when written as:
211
212    /"(?:[^"\\]++|\\.)*+"/
213
214 as we know that if the final quote does not match, backtracking will not
215 help. See the independent subexpression C<< (?>...) >> for more details;
216 possessive quantifiers are just syntactic sugar for that construct. For
217 instance the above example could also be written as follows:
218
219    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
220
221 =head3 Escape sequences
222
223 Because patterns are processed as double quoted strings, the following
224 also work:
225
226  \t          tab                   (HT, TAB)
227  \n          newline               (LF, NL)
228  \r          return                (CR)
229  \f          form feed             (FF)
230  \a          alarm (bell)          (BEL)
231  \e          escape (think troff)  (ESC)
232  \033        octal char            (example: ESC)
233  \x1B        hex char              (example: ESC)
234  \x{263a}    long hex char         (example: Unicode SMILEY)
235  \cK         control char          (example: VT)
236  \N{name}    named Unicode character
237  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
238  \l          lowercase next char (think vi)
239  \u          uppercase next char (think vi)
240  \L          lowercase till \E (think vi)
241  \U          uppercase till \E (think vi)
242  \Q          quote (disable) pattern metacharacters till \E
243  \E          end either case modification or quoted section, think vi
244
245 Details are in L<perlop/Quote and Quote-like Operators>.
246
247 =head3 Character Classes and other Special Escapes
248
249 In addition, Perl defines the following:
250 X<\g> X<\k> X<\K> X<backreference>
251
252  Sequence   Note    Description
253   [...]     [1]  Match a character according to the rules of the
254                    bracketed character class defined by the "...".
255                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
256   [[:...:]] [2]  Match a character according to the rules of the POSIX
257                    character class "..." within the outer bracketed
258                    character class.  Example: [[:upper:]] matches any
259                    uppercase character.
260   \w        [3]  Match a "word" character (alphanumeric plus "_")
261   \W        [3]  Match a non-"word" character
262   \s        [3]  Match a whitespace character
263   \S        [3]  Match a non-whitespace character
264   \d        [3]  Match a decimal digit character
265   \D        [3]  Match a non-digit character
266   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
267   \PP       [3]  Match non-P
268   \X        [4]  Match Unicode "eXtended grapheme cluster"
269   \C             Match a single C-language char (octet) even if that is
270                    part of a larger UTF-8 character.  Thus it breaks up
271                    characters into their UTF-8 bytes, so you may end up
272                    with malformed pieces of UTF-8.  Unsupported in
273                    lookbehind.
274   \1        [5]  Backreference to a specific capture buffer or group.
275                    '1' may actually be any positive integer.
276   \g1       [5]  Backreference to a specific or previous group,
277   \g{-1}    [5]  The number may be negative indicating a relative
278                    previous buffer and may optionally be wrapped in
279                    curly brackets for safer parsing.
280   \g{name}  [5]  Named backreference
281   \k<name>  [5]  Named backreference
282   \K        [6]  Keep the stuff left of the \K, don't include it in $&
283   \N        [7]  Any character but \n (experimental).  Not affected by
284                    /s modifier
285   \v        [3]  Vertical whitespace
286   \V        [3]  Not vertical whitespace
287   \h        [3]  Horizontal whitespace
288   \H        [3]  Not horizontal whitespace
289   \R        [4]  Linebreak
290
291 =over 4
292
293 =item [1]
294
295 See L<perlrecharclass/Bracketed Character Classes> for details.
296
297 =item [2]
298
299 See L<perlrecharclass/POSIX Character Classes> for details.
300
301 =item [3]
302
303 See L<perlrecharclass/Backslash sequences> for details.
304
305 =item [4]
306
307 See L<perlrebackslash/Misc> for details.
308
309 =item [5]
310
311 See L</Capture buffers> below for details.
312
313 =item [6]
314
315 See L</Extended Patterns> below for details.
316
317 =item [7]
318
319 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
320 character whose name is C<NAME>; and similarly when of the form
321 C<\N{U+I<wide hex char>}>, it matches the character whose Unicode ordinal is
322 I<wide hex char>.  Otherwise it matches any character but C<\n>.
323
324 =back
325
326 =head3 Assertions
327
328 Perl defines the following zero-width assertions:
329 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
330 X<regexp, zero-width assertion>
331 X<regular expression, zero-width assertion>
332 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
333
334     \b  Match a word boundary
335     \B  Match except at a word boundary
336     \A  Match only at beginning of string
337     \Z  Match only at end of string, or before newline at the end
338     \z  Match only at end of string
339     \G  Match only at pos() (e.g. at the end-of-match position
340         of prior m//g)
341
342 A word boundary (C<\b>) is a spot between two characters
343 that has a C<\w> on one side of it and a C<\W> on the other side
344 of it (in either order), counting the imaginary characters off the
345 beginning and end of the string as matching a C<\W>.  (Within
346 character classes C<\b> represents backspace rather than a word
347 boundary, just as it normally does in any double-quoted string.)
348 The C<\A> and C<\Z> are just like "^" and "$", except that they
349 won't match multiple times when the C</m> modifier is used, while
350 "^" and "$" will match at every internal line boundary.  To match
351 the actual end of the string and not ignore an optional trailing
352 newline, use C<\z>.
353 X<\b> X<\A> X<\Z> X<\z> X</m>
354
355 The C<\G> assertion can be used to chain global matches (using
356 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
357 It is also useful when writing C<lex>-like scanners, when you have
358 several patterns that you want to match against consequent substrings
359 of your string, see the previous reference.  The actual location
360 where C<\G> will match can also be influenced by using C<pos()> as
361 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
362 matches is modified somewhat, in that contents to the left of C<\G> is
363 not counted when determining the length of the match. Thus the following
364 will not match forever:
365 X<\G>
366
367     $str = 'ABC';
368     pos($str) = 1;
369     while (/.\G/g) {
370         print $&;
371     }
372
373 It will print 'A' and then terminate, as it considers the match to
374 be zero-width, and thus will not match at the same position twice in a
375 row.
376
377 It is worth noting that C<\G> improperly used can result in an infinite
378 loop. Take care when using patterns that include C<\G> in an alternation.
379
380 =head3 Capture buffers
381
382 The bracketing construct C<( ... )> creates capture buffers. To refer
383 to the current contents of a buffer later on, within the same pattern,
384 use \1 for the first, \2 for the second, and so on.
385 Outside the match use "$" instead of "\".  (The
386 \<digit> notation works in certain circumstances outside
387 the match.  See the warning below about \1 vs $1 for details.)
388 Referring back to another part of the match is called a
389 I<backreference>.
390 X<regex, capture buffer> X<regexp, capture buffer>
391 X<regular expression, capture buffer> X<backreference>
392
393 There is no limit to the number of captured substrings that you may
394 use.  However Perl also uses \10, \11, etc. as aliases for \010,
395 \011, etc.  (Recall that 0 means octal, so \011 is the character at
396 number 9 in your coded character set; which would be the 10th character,
397 a horizontal tab under ASCII.)  Perl resolves this
398 ambiguity by interpreting \10 as a backreference only if at least 10
399 left parentheses have opened before it.  Likewise \11 is a
400 backreference only if at least 11 left parentheses have opened
401 before it.  And so on.  \1 through \9 are always interpreted as
402 backreferences.
403 If the bracketing group did not match, the associated backreference won't
404 match either. (This can happen if the bracketing group is optional, or
405 in a different branch of an alternation.)
406
407 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
408 In order to provide a safer and easier way to construct patterns using
409 backreferences, Perl provides the C<\g{N}> notation (starting with perl
410 5.10.0). The curly brackets are optional, however omitting them is less
411 safe as the meaning of the pattern can be changed by text (such as digits)
412 following it. When N is a positive integer the C<\g{N}> notation is
413 exactly equivalent to using normal backreferences. When N is a negative
414 integer then it is a relative backreference referring to the previous N'th
415 capturing group. When the bracket form is used and N is not an integer, it
416 is treated as a reference to a named buffer.
417
418 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
419 buffer before that. For example:
420
421         /
422          (Y)            # buffer 1
423          (              # buffer 2
424             (X)         # buffer 3
425             \g{-1}      # backref to buffer 3
426             \g{-3}      # backref to buffer 1
427          )
428         /x
429
430 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
431
432 Additionally, as of Perl 5.10.0 you may use named capture buffers and named
433 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
434 to reference. You may also use apostrophes instead of angle brackets to delimit the
435 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
436 It's possible to refer to a named capture buffer by absolute and relative number as well.
437 Outside the pattern, a named capture buffer is available via the C<%+> hash.
438 When different buffers within the same pattern have the same name, C<$+{name}>
439 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
440 to do things with named capture buffers that would otherwise require C<(??{})>
441 code to accomplish.)
442 X<named capture buffer> X<regular expression, named capture buffer>
443 X<%+> X<$+{name}> X<< \k<name> >>
444
445 Examples:
446
447     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
448
449     /(.)\1/                         # find first doubled char
450          and print "'$1' is the first doubled character\n";
451
452     /(?<char>.)\k<char>/            # ... a different way
453          and print "'$+{char}' is the first doubled character\n";
454
455     /(?'char'.)\1/                  # ... mix and match
456          and print "'$1' is the first doubled character\n";
457
458     if (/Time: (..):(..):(..)/) {   # parse out values
459         $hours = $1;
460         $minutes = $2;
461         $seconds = $3;
462     }
463
464 Several special variables also refer back to portions of the previous
465 match.  C<$+> returns whatever the last bracket match matched.
466 C<$&> returns the entire matched string.  (At one point C<$0> did
467 also, but now it returns the name of the program.)  C<$`> returns
468 everything before the matched string.  C<$'> returns everything
469 after the matched string. And C<$^N> contains whatever was matched by
470 the most-recently closed group (submatch). C<$^N> can be used in
471 extended patterns (see below), for example to assign a submatch to a
472 variable.
473 X<$+> X<$^N> X<$&> X<$`> X<$'>
474
475 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
476 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
477 until the end of the enclosing block or until the next successful
478 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
479 X<$+> X<$^N> X<$&> X<$`> X<$'>
480 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
481
482
483 B<NOTE>: Failed matches in Perl do not reset the match variables,
484 which makes it easier to write code that tests for a series of more
485 specific cases and remembers the best match.
486
487 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
488 C<$'> anywhere in the program, it has to provide them for every
489 pattern match.  This may substantially slow your program.  Perl
490 uses the same mechanism to produce $1, $2, etc, so you also pay a
491 price for each pattern that contains capturing parentheses.  (To
492 avoid this cost while retaining the grouping behaviour, use the
493 extended regular expression C<(?: ... )> instead.)  But if you never
494 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
495 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
496 if you can, but if you can't (and some algorithms really appreciate
497 them), once you've used them once, use them at will, because you've
498 already paid the price.  As of 5.005, C<$&> is not so costly as the
499 other two.
500 X<$&> X<$`> X<$'>
501
502 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
503 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
504 and C<$'>, B<except> that they are only guaranteed to be defined after a
505 successful match that was executed with the C</p> (preserve) modifier.
506 The use of these variables incurs no global performance penalty, unlike
507 their punctuation char equivalents, however at the trade-off that you
508 have to tell perl when you want to use them.
509 X</p> X<p modifier>
510
511 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
512 C<\w>, C<\n>.  Unlike some other regular expression languages, there
513 are no backslashed symbols that aren't alphanumeric.  So anything
514 that looks like \\, \(, \), \<, \>, \{, or \} is always
515 interpreted as a literal character, not a metacharacter.  This was
516 once used in a common idiom to disable or quote the special meanings
517 of regular expression metacharacters in a string that you want to
518 use for a pattern. Simply quote all non-"word" characters:
519
520     $pattern =~ s/(\W)/\\$1/g;
521
522 (If C<use locale> is set, then this depends on the current locale.)
523 Today it is more common to use the quotemeta() function or the C<\Q>
524 metaquoting escape sequence to disable all metacharacters' special
525 meanings like this:
526
527     /$unquoted\Q$quoted\E$unquoted/
528
529 Beware that if you put literal backslashes (those not inside
530 interpolated variables) between C<\Q> and C<\E>, double-quotish
531 backslash interpolation may lead to confusing results.  If you
532 I<need> to use literal backslashes within C<\Q...\E>,
533 consult L<perlop/"Gory details of parsing quoted constructs">.
534
535 =head2 Extended Patterns
536
537 Perl also defines a consistent extension syntax for features not
538 found in standard tools like B<awk> and B<lex>.  The syntax is a
539 pair of parentheses with a question mark as the first thing within
540 the parentheses.  The character after the question mark indicates
541 the extension.
542
543 The stability of these extensions varies widely.  Some have been
544 part of the core language for many years.  Others are experimental
545 and may change without warning or be completely removed.  Check
546 the documentation on an individual feature to verify its current
547 status.
548
549 A question mark was chosen for this and for the minimal-matching
550 construct because 1) question marks are rare in older regular
551 expressions, and 2) whenever you see one, you should stop and
552 "question" exactly what is going on.  That's psychology...
553
554 =over 10
555
556 =item C<(?#text)>
557 X<(?#)>
558
559 A comment.  The text is ignored.  If the C</x> modifier enables
560 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
561 the comment as soon as it sees a C<)>, so there is no way to put a literal
562 C<)> in the comment.
563
564 =item C<(?pimsx-imsx)>
565 X<(?)>
566
567 One or more embedded pattern-match modifiers, to be turned on (or
568 turned off, if preceded by C<->) for the remainder of the pattern or
569 the remainder of the enclosing pattern group (if any). This is
570 particularly useful for dynamic patterns, such as those read in from a
571 configuration file, taken from an argument, or specified in a table
572 somewhere.  Consider the case where some patterns want to be case
573 sensitive and some do not:  The case insensitive ones merely need to
574 include C<(?i)> at the front of the pattern.  For example:
575
576     $pattern = "foobar";
577     if ( /$pattern/i ) { }
578
579     # more flexible:
580
581     $pattern = "(?i)foobar";
582     if ( /$pattern/ ) { }
583
584 These modifiers are restored at the end of the enclosing group. For example,
585
586     ( (?i) blah ) \s+ \1
587
588 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
589 repetition of the previous word, assuming the C</x> modifier, and no C</i>
590 modifier outside this group.
591
592 These modifiers do not carry over into named subpatterns called in the
593 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
594 change the case-sensitivity of the "NAME" pattern.
595
596 Note that the C<p> modifier is special in that it can only be enabled,
597 not disabled, and that its presence anywhere in a pattern has a global
598 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
599 when executed under C<use warnings>.
600
601 =item C<(?:pattern)>
602 X<(?:)>
603
604 =item C<(?imsx-imsx:pattern)>
605
606 This is for clustering, not capturing; it groups subexpressions like
607 "()", but doesn't make backreferences as "()" does.  So
608
609     @fields = split(/\b(?:a|b|c)\b/)
610
611 is like
612
613     @fields = split(/\b(a|b|c)\b/)
614
615 but doesn't spit out extra fields.  It's also cheaper not to capture
616 characters if you don't need to.
617
618 Any letters between C<?> and C<:> act as flags modifiers as with
619 C<(?imsx-imsx)>.  For example,
620
621     /(?s-i:more.*than).*million/i
622
623 is equivalent to the more verbose
624
625     /(?:(?s-i)more.*than).*million/i
626
627 =item C<(?|pattern)>
628 X<(?|)> X<Branch reset>
629
630 This is the "branch reset" pattern, which has the special property
631 that the capture buffers are numbered from the same starting point
632 in each alternation branch. It is available starting from perl 5.10.0.
633
634 Capture buffers are numbered from left to right, but inside this
635 construct the numbering is restarted for each branch.
636
637 The numbering within each branch will be as normal, and any buffers
638 following this construct will be numbered as though the construct
639 contained only one branch, that being the one with the most capture
640 buffers in it.
641
642 This construct will be useful when you want to capture one of a
643 number of alternative matches.
644
645 Consider the following pattern.  The numbers underneath show in
646 which buffer the captured content will be stored.
647
648
649     # before  ---------------branch-reset----------- after        
650     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
651     # 1            2         2  3        2     3     4  
652
653 Be careful when using the branch reset pattern in combination with 
654 named captures. Named captures are implemented as being aliases to 
655 numbered buffers holding the captures, and that interferes with the
656 implementation of the branch reset pattern. If you are using named
657 captures in a branch reset pattern, it's best to use the same names,
658 in the same order, in each of the alternations:
659
660    /(?|  (?<a> x ) (?<b> y )
661       |  (?<a> z ) (?<b> w )) /x
662
663 Not doing so may lead to surprises:
664
665   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
666   say $+ {a};   # Prints '12'
667   say $+ {b};   # *Also* prints '12'.
668
669 The problem here is that both the buffer named C<< a >> and the buffer
670 named C<< b >> are aliases for the buffer belonging to C<< $1 >>.
671
672 =item Look-Around Assertions
673 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
674
675 Look-around assertions are zero width patterns which match a specific
676 pattern without including it in C<$&>. Positive assertions match when
677 their subpattern matches, negative assertions match when their subpattern
678 fails. Look-behind matches text up to the current match position,
679 look-ahead matches text following the current match position.
680
681 =over 4
682
683 =item C<(?=pattern)>
684 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
685
686 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
687 matches a word followed by a tab, without including the tab in C<$&>.
688
689 =item C<(?!pattern)>
690 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
691
692 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
693 matches any occurrence of "foo" that isn't followed by "bar".  Note
694 however that look-ahead and look-behind are NOT the same thing.  You cannot
695 use this for look-behind.
696
697 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
698 will not do what you want.  That's because the C<(?!foo)> is just saying that
699 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
700 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
701 say "like" because there's the case of your "bar" not having three characters
702 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
703 Sometimes it's still easier just to say:
704
705     if (/bar/ && $` !~ /foo$/)
706
707 For look-behind see below.
708
709 =item C<(?<=pattern)> C<\K>
710 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
711
712 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
713 matches a word that follows a tab, without including the tab in C<$&>.
714 Works only for fixed-width look-behind.
715
716 There is a special form of this construct, called C<\K>, which causes the
717 regex engine to "keep" everything it had matched prior to the C<\K> and
718 not include it in C<$&>. This effectively provides variable length
719 look-behind. The use of C<\K> inside of another look-around assertion
720 is allowed, but the behaviour is currently not well defined.
721
722 For various reasons C<\K> may be significantly more efficient than the
723 equivalent C<< (?<=...) >> construct, and it is especially useful in
724 situations where you want to efficiently remove something following
725 something else in a string. For instance
726
727   s/(foo)bar/$1/g;
728
729 can be rewritten as the much more efficient
730
731   s/foo\Kbar//g;
732
733 =item C<(?<!pattern)>
734 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
735
736 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
737 matches any occurrence of "foo" that does not follow "bar".  Works
738 only for fixed-width look-behind.
739
740 =back
741
742 =item C<(?'NAME'pattern)>
743
744 =item C<< (?<NAME>pattern) >>
745 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
746
747 A named capture buffer. Identical in every respect to normal capturing
748 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
749 used after a successful match to refer to a named buffer. See C<perlvar>
750 for more details on the C<%+> and C<%-> hashes.
751
752 If multiple distinct capture buffers have the same name then the
753 $+{NAME} will refer to the leftmost defined buffer in the match.
754
755 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
756
757 B<NOTE:> While the notation of this construct is the same as the similar
758 function in .NET regexes, the behavior is not. In Perl the buffers are
759 numbered sequentially regardless of being named or not. Thus in the
760 pattern
761
762   /(x)(?<foo>y)(z)/
763
764 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
765 the opposite which is what a .NET regex hacker might expect.
766
767 Currently NAME is restricted to simple identifiers only.
768 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
769 its Unicode extension (see L<utf8>),
770 though it isn't extended by the locale (see L<perllocale>).
771
772 B<NOTE:> In order to make things easier for programmers with experience
773 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
774 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
775 support the use of single quotes as a delimiter for the name.
776
777 =item C<< \k<NAME> >>
778
779 =item C<< \k'NAME' >>
780
781 Named backreference. Similar to numeric backreferences, except that
782 the group is designated by name and not number. If multiple groups
783 have the same name then it refers to the leftmost defined group in
784 the current match.
785
786 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
787 earlier in the pattern.
788
789 Both forms are equivalent.
790
791 B<NOTE:> In order to make things easier for programmers with experience
792 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
793 may be used instead of C<< \k<NAME> >>.
794
795 =item C<(?{ code })>
796 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
797
798 B<WARNING>: This extended regular expression feature is considered
799 experimental, and may be changed without notice. Code executed that
800 has side effects may not perform identically from version to version
801 due to the effect of future optimisations in the regex engine.
802
803 This zero-width assertion evaluates any embedded Perl code.  It
804 always succeeds, and its C<code> is not interpolated.  Currently,
805 the rules to determine where the C<code> ends are somewhat convoluted.
806
807 This feature can be used together with the special variable C<$^N> to
808 capture the results of submatches in variables without having to keep
809 track of the number of nested parentheses. For example:
810
811   $_ = "The brown fox jumps over the lazy dog";
812   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
813   print "color = $color, animal = $animal\n";
814
815 Inside the C<(?{...})> block, C<$_> refers to the string the regular
816 expression is matching against. You can also use C<pos()> to know what is
817 the current position of matching within this string.
818
819 The C<code> is properly scoped in the following sense: If the assertion
820 is backtracked (compare L<"Backtracking">), all changes introduced after
821 C<local>ization are undone, so that
822
823   $_ = 'a' x 8;
824   m<
825      (?{ $cnt = 0 })                   # Initialize $cnt.
826      (
827        a
828        (?{
829            local $cnt = $cnt + 1;      # Update $cnt, backtracking-safe.
830        })
831      )*
832      aaaa
833      (?{ $res = $cnt })                # On success copy to
834                                        # non-localized location.
835    >x;
836
837 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
838 introduced value, because the scopes that restrict C<local> operators
839 are unwound.
840
841 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
842 switch.  If I<not> used in this way, the result of evaluation of
843 C<code> is put into the special variable C<$^R>.  This happens
844 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
845 inside the same regular expression.
846
847 The assignment to C<$^R> above is properly localized, so the old
848 value of C<$^R> is restored if the assertion is backtracked; compare
849 L<"Backtracking">.
850
851 For reasons of security, this construct is forbidden if the regular
852 expression involves run-time interpolation of variables, unless the
853 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
854 variables contain results of C<qr//> operator (see
855 L<perlop/"qr/STRINGE<sol>msixpo">).
856
857 This restriction is due to the wide-spread and remarkably convenient
858 custom of using run-time determined strings as patterns.  For example:
859
860     $re = <>;
861     chomp $re;
862     $string =~ /$re/;
863
864 Before Perl knew how to execute interpolated code within a pattern,
865 this operation was completely safe from a security point of view,
866 although it could raise an exception from an illegal pattern.  If
867 you turn on the C<use re 'eval'>, though, it is no longer secure,
868 so you should only do so if you are also using taint checking.
869 Better yet, use the carefully constrained evaluation within a Safe
870 compartment.  See L<perlsec> for details about both these mechanisms.
871
872 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
873 broken. The result is unpredictable and will make perl unstable. The
874 workaround is to use global (C<our>) variables.
875
876 B<WARNING>: Because Perl's regex engine is currently not re-entrant,
877 interpolated code may not invoke the regex engine either directly with
878 C<m//> or C<s///>), or indirectly with functions such as
879 C<split>. Invoking the regex engine in these blocks will make perl
880 unstable.
881
882 =item C<(??{ code })>
883 X<(??{})>
884 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
885
886 B<WARNING>: This extended regular expression feature is considered
887 experimental, and may be changed without notice. Code executed that
888 has side effects may not perform identically from version to version
889 due to the effect of future optimisations in the regex engine.
890
891 This is a "postponed" regular subexpression.  The C<code> is evaluated
892 at run time, at the moment this subexpression may match.  The result
893 of evaluation is considered as a regular expression and matched as
894 if it were inserted instead of this construct.  Note that this means
895 that the contents of capture buffers defined inside an eval'ed pattern
896 are not available outside of the pattern, and vice versa, there is no
897 way for the inner pattern to refer to a capture buffer defined outside.
898 Thus,
899
900     ('a' x 100)=~/(??{'(.)' x 100})/
901
902 B<will> match, it will B<not> set $1.
903
904 The C<code> is not interpolated.  As before, the rules to determine
905 where the C<code> ends are currently somewhat convoluted.
906
907 The following pattern matches a parenthesized group:
908
909   $re = qr{
910              \(
911              (?:
912                 (?> [^()]+ )       # Non-parens without backtracking
913               |
914                 (??{ $re })        # Group with matching parens
915              )*
916              \)
917           }x;
918
919 See also C<(?PARNO)> for a different, more efficient way to accomplish
920 the same task.
921
922 For reasons of security, this construct is forbidden if the regular
923 expression involves run-time interpolation of variables, unless the
924 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
925 variables contain results of C<qr//> operator (see
926 L<perlop/"qrE<sol>STRINGE<sol>msixpo">).
927
928 Because perl's regex engine is not currently re-entrant, delayed
929 code may not invoke the regex engine either directly with C<m//> or C<s///>),
930 or indirectly with functions such as C<split>.
931
932 Recursing deeper than 50 times without consuming any input string will
933 result in a fatal error.  The maximum depth is compiled into perl, so
934 changing it requires a custom build.
935
936 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
937 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
938 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
939 X<regex, relative recursion>
940
941 Similar to C<(??{ code })> except it does not involve compiling any code,
942 instead it treats the contents of a capture buffer as an independent
943 pattern that must match at the current position.  Capture buffers
944 contained by the pattern will have the value as determined by the
945 outermost recursion.
946
947 PARNO is a sequence of digits (not starting with 0) whose value reflects
948 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
949 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
950 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
951 to be relative, with negative numbers indicating preceding capture buffers
952 and positive ones following. Thus C<(?-1)> refers to the most recently
953 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
954 Note that the counting for relative recursion differs from that of
955 relative backreferences, in that with recursion unclosed buffers B<are>
956 included.
957
958 The following pattern matches a function foo() which may contain
959 balanced parentheses as the argument.
960
961   $re = qr{ (                    # paren group 1 (full function)
962               foo
963               (                  # paren group 2 (parens)
964                 \(
965                   (              # paren group 3 (contents of parens)
966                   (?:
967                    (?> [^()]+ )  # Non-parens without backtracking
968                   |
969                    (?2)          # Recurse to start of paren group 2
970                   )*
971                   )
972                 \)
973               )
974             )
975           }x;
976
977 If the pattern was used as follows
978
979     'foo(bar(baz)+baz(bop))'=~/$re/
980         and print "\$1 = $1\n",
981                   "\$2 = $2\n",
982                   "\$3 = $3\n";
983
984 the output produced should be the following:
985
986     $1 = foo(bar(baz)+baz(bop))
987     $2 = (bar(baz)+baz(bop))
988     $3 = bar(baz)+baz(bop)
989
990 If there is no corresponding capture buffer defined, then it is a
991 fatal error.  Recursing deeper than 50 times without consuming any input
992 string will also result in a fatal error.  The maximum depth is compiled
993 into perl, so changing it requires a custom build.
994
995 The following shows how using negative indexing can make it
996 easier to embed recursive patterns inside of a C<qr//> construct
997 for later use:
998
999     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1000     if (/foo $parens \s+ + \s+ bar $parens/x) {
1001        # do something here...
1002     }
1003
1004 B<Note> that this pattern does not behave the same way as the equivalent
1005 PCRE or Python construct of the same form. In Perl you can backtrack into
1006 a recursed group, in PCRE and Python the recursed into group is treated
1007 as atomic. Also, modifiers are resolved at compile time, so constructs
1008 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1009 be processed.
1010
1011 =item C<(?&NAME)>
1012 X<(?&NAME)>
1013
1014 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1015 parenthesis to recurse to is determined by name. If multiple parentheses have
1016 the same name, then it recurses to the leftmost.
1017
1018 It is an error to refer to a name that is not declared somewhere in the
1019 pattern.
1020
1021 B<NOTE:> In order to make things easier for programmers with experience
1022 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1023 may be used instead of C<< (?&NAME) >>.
1024
1025 =item C<(?(condition)yes-pattern|no-pattern)>
1026 X<(?()>
1027
1028 =item C<(?(condition)yes-pattern)>
1029
1030 Conditional expression.  C<(condition)> should be either an integer in
1031 parentheses (which is valid if the corresponding pair of parentheses
1032 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1033 name in angle brackets or single quotes (which is valid if a buffer
1034 with the given name matched), or the special symbol (R) (true when
1035 evaluated inside of recursion or eval). Additionally the R may be
1036 followed by a number, (which will be true when evaluated when recursing
1037 inside of the appropriate group), or by C<&NAME>, in which case it will
1038 be true only when evaluated during recursion in the named group.
1039
1040 Here's a summary of the possible predicates:
1041
1042 =over 4
1043
1044 =item (1) (2) ...
1045
1046 Checks if the numbered capturing buffer has matched something.
1047
1048 =item (<NAME>) ('NAME')
1049
1050 Checks if a buffer with the given name has matched something.
1051
1052 =item (?{ CODE })
1053
1054 Treats the code block as the condition.
1055
1056 =item (R)
1057
1058 Checks if the expression has been evaluated inside of recursion.
1059
1060 =item (R1) (R2) ...
1061
1062 Checks if the expression has been evaluated while executing directly
1063 inside of the n-th capture group. This check is the regex equivalent of
1064
1065   if ((caller(0))[3] eq 'subname') { ... }
1066
1067 In other words, it does not check the full recursion stack.
1068
1069 =item (R&NAME)
1070
1071 Similar to C<(R1)>, this predicate checks to see if we're executing
1072 directly inside of the leftmost group with a given name (this is the same
1073 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1074 stack, but only the name of the innermost active recursion.
1075
1076 =item (DEFINE)
1077
1078 In this case, the yes-pattern is never directly executed, and no
1079 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1080 See below for details.
1081
1082 =back
1083
1084 For example:
1085
1086     m{ ( \( )?
1087        [^()]+
1088        (?(1) \) )
1089      }x
1090
1091 matches a chunk of non-parentheses, possibly included in parentheses
1092 themselves.
1093
1094 A special form is the C<(DEFINE)> predicate, which never executes directly
1095 its yes-pattern, and does not allow a no-pattern. This allows to define
1096 subpatterns which will be executed only by using the recursion mechanism.
1097 This way, you can define a set of regular expression rules that can be
1098 bundled into any pattern you choose.
1099
1100 It is recommended that for this usage you put the DEFINE block at the
1101 end of the pattern, and that you name any subpatterns defined within it.
1102
1103 Also, it's worth noting that patterns defined this way probably will
1104 not be as efficient, as the optimiser is not very clever about
1105 handling them.
1106
1107 An example of how this might be used is as follows:
1108
1109   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1110    (?(DEFINE)
1111      (?<NAME_PAT>....)
1112      (?<ADRESS_PAT>....)
1113    )/x
1114
1115 Note that capture buffers matched inside of recursion are not accessible
1116 after the recursion returns, so the extra layer of capturing buffers is
1117 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1118 C<$+{NAME}> would be.
1119
1120 =item C<< (?>pattern) >>
1121 X<backtrack> X<backtracking> X<atomic> X<possessive>
1122
1123 An "independent" subexpression, one which matches the substring
1124 that a I<standalone> C<pattern> would match if anchored at the given
1125 position, and it matches I<nothing other than this substring>.  This
1126 construct is useful for optimizations of what would otherwise be
1127 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1128 It may also be useful in places where the "grab all you can, and do not
1129 give anything back" semantic is desirable.
1130
1131 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1132 (anchored at the beginning of string, as above) will match I<all>
1133 characters C<a> at the beginning of string, leaving no C<a> for
1134 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1135 since the match of the subgroup C<a*> is influenced by the following
1136 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1137 C<a*ab> will match fewer characters than a standalone C<a*>, since
1138 this makes the tail match.
1139
1140 An effect similar to C<< (?>pattern) >> may be achieved by writing
1141 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1142 C<a+>, and the following C<\1> eats the matched string; it therefore
1143 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1144 (The difference between these two constructs is that the second one
1145 uses a capturing group, thus shifting ordinals of backreferences
1146 in the rest of a regular expression.)
1147
1148 Consider this pattern:
1149
1150     m{ \(
1151           (
1152             [^()]+           # x+
1153           |
1154             \( [^()]* \)
1155           )+
1156        \)
1157      }x
1158
1159 That will efficiently match a nonempty group with matching parentheses
1160 two levels deep or less.  However, if there is no such group, it
1161 will take virtually forever on a long string.  That's because there
1162 are so many different ways to split a long string into several
1163 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1164 to a subpattern of the above pattern.  Consider how the pattern
1165 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1166 seconds, but that each extra letter doubles this time.  This
1167 exponential performance will make it appear that your program has
1168 hung.  However, a tiny change to this pattern
1169
1170     m{ \(
1171           (
1172             (?> [^()]+ )        # change x+ above to (?> x+ )
1173           |
1174             \( [^()]* \)
1175           )+
1176        \)
1177      }x
1178
1179 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1180 this yourself would be a productive exercise), but finishes in a fourth
1181 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1182 however, that this pattern currently triggers a warning message under
1183 the C<use warnings> pragma or B<-w> switch saying it
1184 C<"matches null string many times in regex">.
1185
1186 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1187 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1188 This was only 4 times slower on a string with 1000000 C<a>s.
1189
1190 The "grab all you can, and do not give anything back" semantic is desirable
1191 in many situations where on the first sight a simple C<()*> looks like
1192 the correct solution.  Suppose we parse text with comments being delimited
1193 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1194 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1195 the comment delimiter, because it may "give up" some whitespace if
1196 the remainder of the pattern can be made to match that way.  The correct
1197 answer is either one of these:
1198
1199     (?>#[ \t]*)
1200     #[ \t]*(?![ \t])
1201
1202 For example, to grab non-empty comments into $1, one should use either
1203 one of these:
1204
1205     / (?> \# [ \t]* ) (        .+ ) /x;
1206     /     \# [ \t]*   ( [^ \t] .* ) /x;
1207
1208 Which one you pick depends on which of these expressions better reflects
1209 the above specification of comments.
1210
1211 In some literature this construct is called "atomic matching" or
1212 "possessive matching".
1213
1214 Possessive quantifiers are equivalent to putting the item they are applied
1215 to inside of one of these constructs. The following equivalences apply:
1216
1217     Quantifier Form     Bracketing Form
1218     ---------------     ---------------
1219     PAT*+               (?>PAT*)
1220     PAT++               (?>PAT+)
1221     PAT?+               (?>PAT?)
1222     PAT{min,max}+       (?>PAT{min,max})
1223
1224 =back
1225
1226 =head2 Special Backtracking Control Verbs
1227
1228 B<WARNING:> These patterns are experimental and subject to change or
1229 removal in a future version of Perl. Their usage in production code should
1230 be noted to avoid problems during upgrades.
1231
1232 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1233 otherwise stated the ARG argument is optional; in some cases, it is
1234 forbidden.
1235
1236 Any pattern containing a special backtracking verb that allows an argument
1237 has the special behaviour that when executed it sets the current package's
1238 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1239 rules apply:
1240
1241 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1242 verb pattern, if the verb was involved in the failure of the match. If the
1243 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1244 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1245 none. Also, the C<$REGMARK> variable will be set to FALSE.
1246
1247 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1248 the C<$REGMARK> variable will be set to the name of the last
1249 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1250 C<(*MARK:NAME)> verb below for more details.
1251
1252 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1253 and most other regex related variables. They are not local to a scope, nor
1254 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1255 Use C<local> to localize changes to them to a specific scope if necessary.
1256
1257 If a pattern does not contain a special backtracking verb that allows an
1258 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1259
1260 =over 4
1261
1262 =item Verbs that take an argument
1263
1264 =over 4
1265
1266 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1267 X<(*PRUNE)> X<(*PRUNE:NAME)>
1268
1269 This zero-width pattern prunes the backtracking tree at the current point
1270 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1271 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1272 A may backtrack as necessary to match. Once it is reached, matching
1273 continues in B, which may also backtrack as necessary; however, should B
1274 not match, then no further backtracking will take place, and the pattern
1275 will fail outright at the current starting position.
1276
1277 The following example counts all the possible matching strings in a
1278 pattern (without actually matching any of them).
1279
1280     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1281     print "Count=$count\n";
1282
1283 which produces:
1284
1285     aaab
1286     aaa
1287     aa
1288     a
1289     aab
1290     aa
1291     a
1292     ab
1293     a
1294     Count=9
1295
1296 If we add a C<(*PRUNE)> before the count like the following
1297
1298     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1299     print "Count=$count\n";
1300
1301 we prevent backtracking and find the count of the longest matching
1302 at each matching starting point like so:
1303
1304     aaab
1305     aab
1306     ab
1307     Count=3
1308
1309 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1310
1311 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1312 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1313 replaced with a C<< (?>pattern) >> with no functional difference; however,
1314 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1315 C<< (?>pattern) >> alone.
1316
1317
1318 =item C<(*SKIP)> C<(*SKIP:NAME)>
1319 X<(*SKIP)>
1320
1321 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1322 failure it also signifies that whatever text that was matched leading up
1323 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1324 of this pattern. This effectively means that the regex engine "skips" forward
1325 to this position on failure and tries to match again, (assuming that
1326 there is sufficient room to match).
1327
1328 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1329 C<(*MARK:NAME)> was encountered while matching, then it is that position
1330 which is used as the "skip point". If no C<(*MARK)> of that name was
1331 encountered, then the C<(*SKIP)> operator has no effect. When used
1332 without a name the "skip point" is where the match point was when
1333 executing the (*SKIP) pattern.
1334
1335 Compare the following to the examples in C<(*PRUNE)>, note the string
1336 is twice as long:
1337
1338     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1339     print "Count=$count\n";
1340
1341 outputs
1342
1343     aaab
1344     aaab
1345     Count=2
1346
1347 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1348 executed, the next starting point will be where the cursor was when the
1349 C<(*SKIP)> was executed.
1350
1351 =item C<(*MARK:NAME)> C<(*:NAME)>
1352 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1353
1354 This zero-width pattern can be used to mark the point reached in a string
1355 when a certain part of the pattern has been successfully matched. This
1356 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1357 forward to that point if backtracked into on failure. Any number of
1358 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1359
1360 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1361 can be used to "label" a pattern branch, so that after matching, the
1362 program can determine which branches of the pattern were involved in the
1363 match.
1364
1365 When a match is successful, the C<$REGMARK> variable will be set to the
1366 name of the most recently executed C<(*MARK:NAME)> that was involved
1367 in the match.
1368
1369 This can be used to determine which branch of a pattern was matched
1370 without using a separate capture buffer for each branch, which in turn
1371 can result in a performance improvement, as perl cannot optimize
1372 C</(?:(x)|(y)|(z))/> as efficiently as something like
1373 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1374
1375 When a match has failed, and unless another verb has been involved in
1376 failing the match and has provided its own name to use, the C<$REGERROR>
1377 variable will be set to the name of the most recently executed
1378 C<(*MARK:NAME)>.
1379
1380 See C<(*SKIP)> for more details.
1381
1382 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1383
1384 =item C<(*THEN)> C<(*THEN:NAME)>
1385
1386 This is similar to the "cut group" operator C<::> from Perl 6. Like
1387 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1388 failure, it causes the regex engine to try the next alternation in the
1389 innermost enclosing group (capturing or otherwise).
1390
1391 Its name comes from the observation that this operation combined with the
1392 alternation operator (C<|>) can be used to create what is essentially a
1393 pattern-based if/then/else block:
1394
1395   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1396
1397 Note that if this operator is used and NOT inside of an alternation then
1398 it acts exactly like the C<(*PRUNE)> operator.
1399
1400   / A (*PRUNE) B /
1401
1402 is the same as
1403
1404   / A (*THEN) B /
1405
1406 but
1407
1408   / ( A (*THEN) B | C (*THEN) D ) /
1409
1410 is not the same as
1411
1412   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1413
1414 as after matching the A but failing on the B the C<(*THEN)> verb will
1415 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1416
1417 =item C<(*COMMIT)>
1418 X<(*COMMIT)>
1419
1420 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1421 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1422 into on failure it causes the match to fail outright. No further attempts
1423 to find a valid match by advancing the start pointer will occur again.
1424 For example,
1425
1426     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1427     print "Count=$count\n";
1428
1429 outputs
1430
1431     aaab
1432     Count=1
1433
1434 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1435 does not match, the regex engine will not try any further matching on the
1436 rest of the string.
1437
1438 =back
1439
1440 =item Verbs without an argument
1441
1442 =over 4
1443
1444 =item C<(*FAIL)> C<(*F)>
1445 X<(*FAIL)> X<(*F)>
1446
1447 This pattern matches nothing and always fails. It can be used to force the
1448 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1449 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1450
1451 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1452
1453 =item C<(*ACCEPT)>
1454 X<(*ACCEPT)>
1455
1456 B<WARNING:> This feature is highly experimental. It is not recommended
1457 for production code.
1458
1459 This pattern matches nothing and causes the end of successful matching at
1460 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1461 whether there is actually more to match in the string. When inside of a
1462 nested pattern, such as recursion, or in a subpattern dynamically generated
1463 via C<(??{})>, only the innermost pattern is ended immediately.
1464
1465 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1466 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1467 For instance:
1468
1469   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1470
1471 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1472 be set. If another branch in the inner parentheses were matched, such as in the
1473 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1474
1475 =back
1476
1477 =back
1478
1479 =head2 Backtracking
1480 X<backtrack> X<backtracking>
1481
1482 NOTE: This section presents an abstract approximation of regular
1483 expression behavior.  For a more rigorous (and complicated) view of
1484 the rules involved in selecting a match among possible alternatives,
1485 see L<Combining RE Pieces>.
1486
1487 A fundamental feature of regular expression matching involves the
1488 notion called I<backtracking>, which is currently used (when needed)
1489 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1490 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1491 internally, but the general principle outlined here is valid.
1492
1493 For a regular expression to match, the I<entire> regular expression must
1494 match, not just part of it.  So if the beginning of a pattern containing a
1495 quantifier succeeds in a way that causes later parts in the pattern to
1496 fail, the matching engine backs up and recalculates the beginning
1497 part--that's why it's called backtracking.
1498
1499 Here is an example of backtracking:  Let's say you want to find the
1500 word following "foo" in the string "Food is on the foo table.":
1501
1502     $_ = "Food is on the foo table.";
1503     if ( /\b(foo)\s+(\w+)/i ) {
1504         print "$2 follows $1.\n";
1505     }
1506
1507 When the match runs, the first part of the regular expression (C<\b(foo)>)
1508 finds a possible match right at the beginning of the string, and loads up
1509 $1 with "Foo".  However, as soon as the matching engine sees that there's
1510 no whitespace following the "Foo" that it had saved in $1, it realizes its
1511 mistake and starts over again one character after where it had the
1512 tentative match.  This time it goes all the way until the next occurrence
1513 of "foo". The complete regular expression matches this time, and you get
1514 the expected output of "table follows foo."
1515
1516 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1517 everything between "foo" and "bar".  Initially, you write something
1518 like this:
1519
1520     $_ =  "The food is under the bar in the barn.";
1521     if ( /foo(.*)bar/ ) {
1522         print "got <$1>\n";
1523     }
1524
1525 Which perhaps unexpectedly yields:
1526
1527   got <d is under the bar in the >
1528
1529 That's because C<.*> was greedy, so you get everything between the
1530 I<first> "foo" and the I<last> "bar".  Here it's more effective
1531 to use minimal matching to make sure you get the text between a "foo"
1532 and the first "bar" thereafter.
1533
1534     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1535   got <d is under the >
1536
1537 Here's another example. Let's say you'd like to match a number at the end
1538 of a string, and you also want to keep the preceding part of the match.
1539 So you write this:
1540
1541     $_ = "I have 2 numbers: 53147";
1542     if ( /(.*)(\d*)/ ) {                                # Wrong!
1543         print "Beginning is <$1>, number is <$2>.\n";
1544     }
1545
1546 That won't work at all, because C<.*> was greedy and gobbled up the
1547 whole string. As C<\d*> can match on an empty string the complete
1548 regular expression matched successfully.
1549
1550     Beginning is <I have 2 numbers: 53147>, number is <>.
1551
1552 Here are some variants, most of which don't work:
1553
1554     $_ = "I have 2 numbers: 53147";
1555     @pats = qw{
1556         (.*)(\d*)
1557         (.*)(\d+)
1558         (.*?)(\d*)
1559         (.*?)(\d+)
1560         (.*)(\d+)$
1561         (.*?)(\d+)$
1562         (.*)\b(\d+)$
1563         (.*\D)(\d+)$
1564     };
1565
1566     for $pat (@pats) {
1567         printf "%-12s ", $pat;
1568         if ( /$pat/ ) {
1569             print "<$1> <$2>\n";
1570         } else {
1571             print "FAIL\n";
1572         }
1573     }
1574
1575 That will print out:
1576
1577     (.*)(\d*)    <I have 2 numbers: 53147> <>
1578     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1579     (.*?)(\d*)   <> <>
1580     (.*?)(\d+)   <I have > <2>
1581     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1582     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1583     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1584     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1585
1586 As you see, this can be a bit tricky.  It's important to realize that a
1587 regular expression is merely a set of assertions that gives a definition
1588 of success.  There may be 0, 1, or several different ways that the
1589 definition might succeed against a particular string.  And if there are
1590 multiple ways it might succeed, you need to understand backtracking to
1591 know which variety of success you will achieve.
1592
1593 When using look-ahead assertions and negations, this can all get even
1594 trickier.  Imagine you'd like to find a sequence of non-digits not
1595 followed by "123".  You might try to write that as
1596
1597     $_ = "ABC123";
1598     if ( /^\D*(?!123)/ ) {                # Wrong!
1599         print "Yup, no 123 in $_\n";
1600     }
1601
1602 But that isn't going to match; at least, not the way you're hoping.  It
1603 claims that there is no 123 in the string.  Here's a clearer picture of
1604 why that pattern matches, contrary to popular expectations:
1605
1606     $x = 'ABC123';
1607     $y = 'ABC445';
1608
1609     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1610     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1611
1612     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1613     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1614
1615 This prints
1616
1617     2: got ABC
1618     3: got AB
1619     4: got ABC
1620
1621 You might have expected test 3 to fail because it seems to a more
1622 general purpose version of test 1.  The important difference between
1623 them is that test 3 contains a quantifier (C<\D*>) and so can use
1624 backtracking, whereas test 1 will not.  What's happening is
1625 that you've asked "Is it true that at the start of $x, following 0 or more
1626 non-digits, you have something that's not 123?"  If the pattern matcher had
1627 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1628 fail.
1629
1630 The search engine will initially match C<\D*> with "ABC".  Then it will
1631 try to match C<(?!123> with "123", which fails.  But because
1632 a quantifier (C<\D*>) has been used in the regular expression, the
1633 search engine can backtrack and retry the match differently
1634 in the hope of matching the complete regular expression.
1635
1636 The pattern really, I<really> wants to succeed, so it uses the
1637 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1638 time.  Now there's indeed something following "AB" that is not
1639 "123".  It's "C123", which suffices.
1640
1641 We can deal with this by using both an assertion and a negation.
1642 We'll say that the first part in $1 must be followed both by a digit
1643 and by something that's not "123".  Remember that the look-aheads
1644 are zero-width expressions--they only look, but don't consume any
1645 of the string in their match.  So rewriting this way produces what
1646 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1647
1648     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1649     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1650
1651     6: got ABC
1652
1653 In other words, the two zero-width assertions next to each other work as though
1654 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1655 matches only if you're at the beginning of the line AND the end of the
1656 line simultaneously.  The deeper underlying truth is that juxtaposition in
1657 regular expressions always means AND, except when you write an explicit OR
1658 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1659 although the attempted matches are made at different positions because "a"
1660 is not a zero-width assertion, but a one-width assertion.
1661
1662 B<WARNING>: Particularly complicated regular expressions can take
1663 exponential time to solve because of the immense number of possible
1664 ways they can use backtracking to try for a match.  For example, without
1665 internal optimizations done by the regular expression engine, this will
1666 take a painfully long time to run:
1667
1668     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1669
1670 And if you used C<*>'s in the internal groups instead of limiting them
1671 to 0 through 5 matches, then it would take forever--or until you ran
1672 out of stack space.  Moreover, these internal optimizations are not
1673 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1674 on the external group, no current optimization is applicable, and the
1675 match takes a long time to finish.
1676
1677 A powerful tool for optimizing such beasts is what is known as an
1678 "independent group",
1679 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1680 zero-length look-ahead/look-behind assertions will not backtrack to make
1681 the tail match, since they are in "logical" context: only
1682 whether they match is considered relevant.  For an example
1683 where side-effects of look-ahead I<might> have influenced the
1684 following match, see L<C<< (?>pattern) >>>.
1685
1686 =head2 Version 8 Regular Expressions
1687 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1688
1689 In case you're not familiar with the "regular" Version 8 regex
1690 routines, here are the pattern-matching rules not described above.
1691
1692 Any single character matches itself, unless it is a I<metacharacter>
1693 with a special meaning described here or above.  You can cause
1694 characters that normally function as metacharacters to be interpreted
1695 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1696 character; "\\" matches a "\"). This escape mechanism is also required
1697 for the character used as the pattern delimiter.
1698
1699 A series of characters matches that series of characters in the target
1700 string, so the pattern  C<blurfl> would match "blurfl" in the target
1701 string.
1702
1703 You can specify a character class, by enclosing a list of characters
1704 in C<[]>, which will match any character from the list.  If the
1705 first character after the "[" is "^", the class matches any character not
1706 in the list.  Within a list, the "-" character specifies a
1707 range, so that C<a-z> represents all characters between "a" and "z",
1708 inclusive.  If you want either "-" or "]" itself to be a member of a
1709 class, put it at the start of the list (possibly after a "^"), or
1710 escape it with a backslash.  "-" is also taken literally when it is
1711 at the end of the list, just before the closing "]".  (The
1712 following all specify the same class of three characters: C<[-az]>,
1713 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1714 specifies a class containing twenty-six characters, even on EBCDIC-based
1715 character sets.)  Also, if you try to use the character
1716 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1717 a range, the "-" is understood literally.
1718
1719 Note also that the whole range idea is rather unportable between
1720 character sets--and even within character sets they may cause results
1721 you probably didn't expect.  A sound principle is to use only ranges
1722 that begin from and end at either alphabetics of equal case ([a-e],
1723 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1724 spell out the character sets in full.
1725
1726 Characters may be specified using a metacharacter syntax much like that
1727 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1728 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1729 of octal digits, matches the character whose coded character set value
1730 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1731 matches the character whose numeric value is I<nn>. The expression \cI<x>
1732 matches the character control-I<x>.  Finally, the "." metacharacter
1733 matches any character except "\n" (unless you use C</s>).
1734
1735 You can specify a series of alternatives for a pattern using "|" to
1736 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1737 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1738 first alternative includes everything from the last pattern delimiter
1739 ("(", "[", or the beginning of the pattern) up to the first "|", and
1740 the last alternative contains everything from the last "|" to the next
1741 pattern delimiter.  That's why it's common practice to include
1742 alternatives in parentheses: to minimize confusion about where they
1743 start and end.
1744
1745 Alternatives are tried from left to right, so the first
1746 alternative found for which the entire expression matches, is the one that
1747 is chosen. This means that alternatives are not necessarily greedy. For
1748 example: when matching C<foo|foot> against "barefoot", only the "foo"
1749 part will match, as that is the first alternative tried, and it successfully
1750 matches the target string. (This might not seem important, but it is
1751 important when you are capturing matched text using parentheses.)
1752
1753 Also remember that "|" is interpreted as a literal within square brackets,
1754 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1755
1756 Within a pattern, you may designate subpatterns for later reference
1757 by enclosing them in parentheses, and you may refer back to the
1758 I<n>th subpattern later in the pattern using the metacharacter
1759 \I<n>.  Subpatterns are numbered based on the left to right order
1760 of their opening parenthesis.  A backreference matches whatever
1761 actually matched the subpattern in the string being examined, not
1762 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1763 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1764 1 matched "0x", even though the rule C<0|0x> could potentially match
1765 the leading 0 in the second number.
1766
1767 =head2 Warning on \1 Instead of $1
1768
1769 Some people get too used to writing things like:
1770
1771     $pattern =~ s/(\W)/\\\1/g;
1772
1773 This is grandfathered for the RHS of a substitute to avoid shocking the
1774 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1775 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1776 the usual double-quoted string means a control-A.  The customary Unix
1777 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1778 of doing that, you get yourself into trouble if you then add an C</e>
1779 modifier.
1780
1781     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
1782
1783 Or if you try to do
1784
1785     s/(\d+)/\1000/;
1786
1787 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1788 C<${1}000>.  The operation of interpolation should not be confused
1789 with the operation of matching a backreference.  Certainly they mean two
1790 different things on the I<left> side of the C<s///>.
1791
1792 =head2 Repeated Patterns Matching a Zero-length Substring
1793
1794 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1795
1796 Regular expressions provide a terse and powerful programming language.  As
1797 with most other power tools, power comes together with the ability
1798 to wreak havoc.
1799
1800 A common abuse of this power stems from the ability to make infinite
1801 loops using regular expressions, with something as innocuous as:
1802
1803     'foo' =~ m{ ( o? )* }x;
1804
1805 The C<o?> matches at the beginning of C<'foo'>, and since the position
1806 in the string is not moved by the match, C<o?> would match again and again
1807 because of the C<*> quantifier.  Another common way to create a similar cycle
1808 is with the looping modifier C<//g>:
1809
1810     @matches = ( 'foo' =~ m{ o? }xg );
1811
1812 or
1813
1814     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1815
1816 or the loop implied by split().
1817
1818 However, long experience has shown that many programming tasks may
1819 be significantly simplified by using repeated subexpressions that
1820 may match zero-length substrings.  Here's a simple example being:
1821
1822     @chars = split //, $string;                  # // is not magic in split
1823     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1824
1825 Thus Perl allows such constructs, by I<forcefully breaking
1826 the infinite loop>.  The rules for this are different for lower-level
1827 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1828 ones like the C</g> modifier or split() operator.
1829
1830 The lower-level loops are I<interrupted> (that is, the loop is
1831 broken) when Perl detects that a repeated expression matched a
1832 zero-length substring.   Thus
1833
1834    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1835
1836 is made equivalent to
1837
1838    m{   (?: NON_ZERO_LENGTH )*
1839       |
1840         (?: ZERO_LENGTH )?
1841     }x;
1842
1843 The higher level-loops preserve an additional state between iterations:
1844 whether the last match was zero-length.  To break the loop, the following
1845 match after a zero-length match is prohibited to have a length of zero.
1846 This prohibition interacts with backtracking (see L<"Backtracking">),
1847 and so the I<second best> match is chosen if the I<best> match is of
1848 zero length.
1849
1850 For example:
1851
1852     $_ = 'bar';
1853     s/\w??/<$&>/g;
1854
1855 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1856 match given by non-greedy C<??> is the zero-length match, and the I<second
1857 best> match is what is matched by C<\w>.  Thus zero-length matches
1858 alternate with one-character-long matches.
1859
1860 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1861 position one notch further in the string.
1862
1863 The additional state of being I<matched with zero-length> is associated with
1864 the matched string, and is reset by each assignment to pos().
1865 Zero-length matches at the end of the previous match are ignored
1866 during C<split>.
1867
1868 =head2 Combining RE Pieces
1869
1870 Each of the elementary pieces of regular expressions which were described
1871 before (such as C<ab> or C<\Z>) could match at most one substring
1872 at the given position of the input string.  However, in a typical regular
1873 expression these elementary pieces are combined into more complicated
1874 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1875 (in these examples C<S> and C<T> are regular subexpressions).
1876
1877 Such combinations can include alternatives, leading to a problem of choice:
1878 if we match a regular expression C<a|ab> against C<"abc">, will it match
1879 substring C<"a"> or C<"ab">?  One way to describe which substring is
1880 actually matched is the concept of backtracking (see L<"Backtracking">).
1881 However, this description is too low-level and makes you think
1882 in terms of a particular implementation.
1883
1884 Another description starts with notions of "better"/"worse".  All the
1885 substrings which may be matched by the given regular expression can be
1886 sorted from the "best" match to the "worst" match, and it is the "best"
1887 match which is chosen.  This substitutes the question of "what is chosen?"
1888 by the question of "which matches are better, and which are worse?".
1889
1890 Again, for elementary pieces there is no such question, since at most
1891 one match at a given position is possible.  This section describes the
1892 notion of better/worse for combining operators.  In the description
1893 below C<S> and C<T> are regular subexpressions.
1894
1895 =over 4
1896
1897 =item C<ST>
1898
1899 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1900 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1901 which can be matched by C<T>.
1902
1903 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1904 match than C<A'B'>.
1905
1906 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1907 C<B> is better match for C<T> than C<B'>.
1908
1909 =item C<S|T>
1910
1911 When C<S> can match, it is a better match than when only C<T> can match.
1912
1913 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1914 two matches for C<T>.
1915
1916 =item C<S{REPEAT_COUNT}>
1917
1918 Matches as C<SSS...S> (repeated as many times as necessary).
1919
1920 =item C<S{min,max}>
1921
1922 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1923
1924 =item C<S{min,max}?>
1925
1926 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1927
1928 =item C<S?>, C<S*>, C<S+>
1929
1930 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1931
1932 =item C<S??>, C<S*?>, C<S+?>
1933
1934 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1935
1936 =item C<< (?>S) >>
1937
1938 Matches the best match for C<S> and only that.
1939
1940 =item C<(?=S)>, C<(?<=S)>
1941
1942 Only the best match for C<S> is considered.  (This is important only if
1943 C<S> has capturing parentheses, and backreferences are used somewhere
1944 else in the whole regular expression.)
1945
1946 =item C<(?!S)>, C<(?<!S)>
1947
1948 For this grouping operator there is no need to describe the ordering, since
1949 only whether or not C<S> can match is important.
1950
1951 =item C<(??{ EXPR })>, C<(?PARNO)>
1952
1953 The ordering is the same as for the regular expression which is
1954 the result of EXPR, or the pattern contained by capture buffer PARNO.
1955
1956 =item C<(?(condition)yes-pattern|no-pattern)>
1957
1958 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1959 already determined.  The ordering of the matches is the same as for the
1960 chosen subexpression.
1961
1962 =back
1963
1964 The above recipes describe the ordering of matches I<at a given position>.
1965 One more rule is needed to understand how a match is determined for the
1966 whole regular expression: a match at an earlier position is always better
1967 than a match at a later position.
1968
1969 =head2 Creating Custom RE Engines
1970
1971 Overloaded constants (see L<overload>) provide a simple way to extend
1972 the functionality of the RE engine.
1973
1974 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1975 matches at a boundary between whitespace characters and non-whitespace
1976 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1977 at these positions, so we want to have each C<\Y|> in the place of the
1978 more complicated version.  We can create a module C<customre> to do
1979 this:
1980
1981     package customre;
1982     use overload;
1983
1984     sub import {
1985       shift;
1986       die "No argument to customre::import allowed" if @_;
1987       overload::constant 'qr' => \&convert;
1988     }
1989
1990     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
1991
1992     # We must also take care of not escaping the legitimate \\Y|
1993     # sequence, hence the presence of '\\' in the conversion rules.
1994     my %rules = ( '\\' => '\\\\',
1995                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
1996     sub convert {
1997       my $re = shift;
1998       $re =~ s{
1999                 \\ ( \\ | Y . )
2000               }
2001               { $rules{$1} or invalid($re,$1) }sgex;
2002       return $re;
2003     }
2004
2005 Now C<use customre> enables the new escape in constant regular
2006 expressions, i.e., those without any runtime variable interpolations.
2007 As documented in L<overload>, this conversion will work only over
2008 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2009 part of this regular expression needs to be converted explicitly
2010 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2011
2012     use customre;
2013     $re = <>;
2014     chomp $re;
2015     $re = customre::convert $re;
2016     /\Y|$re\Y|/;
2017
2018 =head1 PCRE/Python Support
2019
2020 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2021 to the regex syntax. While Perl programmers are encouraged to use the
2022 Perl specific syntax, the following are also accepted:
2023
2024 =over 4
2025
2026 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2027
2028 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2029
2030 =item C<< (?P=NAME) >>
2031
2032 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2033
2034 =item C<< (?P>NAME) >>
2035
2036 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2037
2038 =back
2039
2040 =head1 BUGS
2041
2042 There are numerous problems with case insensitive matching of characters
2043 outside the ASCII range, especially with those whose folds are multiple
2044 characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2045
2046 In a bracketed character class with case insensitive matching, ranges only work
2047 for ASCII characters.  For example,
2048 C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2049 doesn't match all the Russian upper and lower case letters.
2050
2051 Many regular expression constructs don't work on EBCDIC platforms.
2052
2053 This document varies from difficult to understand to completely
2054 and utterly opaque.  The wandering prose riddled with jargon is
2055 hard to fathom in several places.
2056
2057 This document needs a rewrite that separates the tutorial content
2058 from the reference content.
2059
2060 =head1 SEE ALSO
2061
2062 L<perlrequick>.
2063
2064 L<perlretut>.
2065
2066 L<perlop/"Regexp Quote-Like Operators">.
2067
2068 L<perlop/"Gory details of parsing quoted constructs">.
2069
2070 L<perlfaq6>.
2071
2072 L<perlfunc/pos>.
2073
2074 L<perllocale>.
2075
2076 L<perlebcdic>.
2077
2078 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2079 by O'Reilly and Associates.