dist/B-Deparse/Deparse.pm

   1 # B::Deparse.pm
   2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
   3 # All rights reserved.
   4 # This module is free software; you can redistribute and/or modify
   5 # it under the same terms as Perl itself.
   6
   7 # This is based on the module of the same name by Malcolm Beattie,
   8 # but essentially none of his code remains.
   9
  10 package B::Deparse;
  11 use Carp;
  12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
  13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
  14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
  15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
  16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
  17          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
  18          OPpSORT_REVERSE
  19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
  20          CVf_METHOD CVf_LVALUE
  21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
  22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED),
  23          ($] < 5.008004 ? () : 'OPpSORT_INPLACE'),
  24          ($] < 5.008006 ? () : qw(OPpSORT_DESCEND OPpITER_REVERSED)),
  25          ($] < 5.008009 ? () : qw(OPpCONST_NOVER OPpPAD_STATE)),
  26          ($] < 5.009 ? 'PMf_SKIPWHITE' : qw(RXf_SKIPWHITE)),
  27          ($] < 5.011 ? 'CVf_LOCKED' : 'OPpREVERSE_INPLACE'),
  28          ($] < 5.013 ? () : 'PMf_NONDESTRUCT');
  29 $VERSION = "1.06";
  30 use strict;
  31 use vars qw/$AUTOLOAD/;
  32 use warnings ();
  33
  34 BEGIN {
  35     # Easiest way to keep this code portable between version looks to
  36     # be to fake up a dummy constant that will never actually be true.
  37     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
  38                 OPpPAD_STATE RXf_SKIPWHITE CVf_LOCKED OPpREVERSE_INPLACE
  39                 PMf_NONDESTRUCT)) {
  40         no strict 'refs';
  41         *{$_} = sub () {0} unless *{$_}{CODE};
  42     }
  43 }
  44
  45 # Changes between 0.50 and 0.51:
  46 # - fixed nulled leave with live enter in sort { }
  47 # - fixed reference constants (\"str")
  48 # - handle empty programs gracefully
  49 # - handle infinite loops (for (;;) {}, while (1) {})
  50 # - differentiate between `for my $x ...' and `my $x; for $x ...'
  51 # - various minor cleanups
  52 # - moved globals into an object
  53 # - added `-u', like B::C
  54 # - package declarations using cop_stash
  55 # - subs, formats and code sorted by cop_seq
  56 # Changes between 0.51 and 0.52:
  57 # - added pp_threadsv (special variables under USE_5005THREADS)
  58 # - added documentation
  59 # Changes between 0.52 and 0.53:
  60 # - many changes adding precedence contexts and associativity
  61 # - added `-p' and `-s' output style options
  62 # - various other minor fixes
  63 # Changes between 0.53 and 0.54:
  64 # - added support for new `for (1..100)' optimization,
  65 #   thanks to Gisle Aas
  66 # Changes between 0.54 and 0.55:
  67 # - added support for new qr// construct
  68 # - added support for new pp_regcreset OP
  69 # Changes between 0.55 and 0.56:
  70 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
  71 # - fixed $# on non-lexicals broken in last big rewrite
  72 # - added temporary fix for change in opcode of OP_STRINGIFY
  73 # - fixed problem in 0.54's for() patch in `for (@ary)'
  74 # - fixed precedence in conditional of ?:
  75 # - tweaked list paren elimination in `my($x) = @_'
  76 # - made continue-block detection trickier wrt. null ops
  77 # - fixed various prototype problems in pp_entersub
  78 # - added support for sub prototypes that never get GVs
  79 # - added unquoting for special filehandle first arg in truncate
  80 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
  81 # - added semicolons at the ends of blocks
  82 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
  83 # Changes between 0.56 and 0.561:
  84 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
  85 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
  86 # Changes between 0.561 and 0.57:
  87 # - stylistic changes to symbolic constant stuff
  88 # - handled scope in s///e replacement code
  89 # - added unquote option for expanding "" into concats, etc.
  90 # - split method and proto parts of pp_entersub into separate functions
  91 # - various minor cleanups
  92 # Changes after 0.57:
  93 # - added parens in \&foo (patch by Albert Dvornik)
  94 # Changes between 0.57 and 0.58:
  95 # - fixed `0' statements that weren't being printed
  96 # - added methods for use from other programs
  97 #   (based on patches from James Duncan and Hugo van der Sanden)
  98 # - added -si and -sT to control indenting (also based on a patch from Hugo)
  99 # - added -sv to print something else instead of '???'
 100 # - preliminary version of utf8 tr/// handling
 101 # Changes after 0.58:
 102 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
 103 # - added support for Hugo's new OP_SETSTATE (like nextstate)
 104 # Changes between 0.58 and 0.59
 105 # - added support for Chip's OP_METHOD_NAMED
 106 # - added support for Ilya's OPpTARGET_MY optimization
 107 # - elided arrows before `()' subscripts when possible
 108 # Changes between 0.59 and 0.60
 109 # - support for method attributes was added
 110 # - some warnings fixed
 111 # - separate recognition of constant subs
 112 # - rewrote continue block handling, now recognizing for loops
 113 # - added more control of expanding control structures
 114 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
 115 # - many bug-fixes
 116 # - support for pragmas and 'use'
 117 # - support for the little-used $[ variable
 118 # - support for __DATA__ sections
 119 # - UTF8 support
 120 # - BEGIN, CHECK, INIT and END blocks
 121 # - scoping of subroutine declarations fixed
 122 # - compile-time output from the input program can be suppressed, so that the
 123 #   output is just the deparsed code. (a change to O.pm in fact)
 124 # - our() declarations
 125 # - *all* the known bugs are now listed in the BUGS section
 126 # - comprehensive test mechanism (TEST -deparse)
 127 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
 128 # - bug-fixes
 129 # - new switch -P
 130 # - support for command-line switches (-l, -0, etc.)
 131 # Changes between 0.63 and 0.64
 132 # - support for //, CHECK blocks, and assertions
 133 # - improved handling of foreach loops and lexicals
 134 # - option to use Data::Dumper for constants
 135 # - more bug fixes
 136 # - discovered lots more bugs not yet fixed
 137 #
 138 # ...
 139 #
 140 # Changes between 0.72 and 0.73
 141 # - support new switch constructs
 142
 143 # Todo:
 144 #  (See also BUGS section at the end of this file)
 145 #
 146 # - finish tr/// changes
 147 # - add option for even more parens (generalize \&foo change)
 148 # - left/right context
 149 # - copy comments (look at real text with $^P?)
 150 # - avoid semis in one-statement blocks
 151 # - associativity of &&=, ||=, ?:
 152 # - ',' => '=>' (auto-unquote?)
 153 # - break long lines ("\r" as discretionary break?)
 154 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
 155 # - more style options: brace style, hex vs. octal, quotes, ...
 156 # - print big ints as hex/octal instead of decimal (heuristic?)
 157 # - handle `my $x if 0'?
 158 # - version using op_next instead of op_first/sibling?
 159 # - avoid string copies (pass arrays, one big join?)
 160 # - here-docs?
 161
 162 # Current test.deparse failures
 163 # comp/hints 6 - location of BEGIN blocks wrt. block openings
 164 # run/switchI 1 - missing -I switches entirely
 165 #    perl -Ifoo -e 'print @INC'
 166 # op/caller 2 - warning mask propagates backwards before warnings::register
 167 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
 168 # op/getpid 2 - can't assign to shared my() declaration (threads only)
 169 #    'my $x : shared = 5'
 170 # op/override 7 - parens on overridden require change v-string interpretation
 171 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
 172 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
 173 # op/pat 774 - losing Unicode-ness of Latin1-only strings
 174 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
 175 # op/recurse 12 - missing parens on recursive call makes it look like method
 176 #    'sub f { f($x) }'
 177 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
 178 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
 179 # op/tiehandle compile - "use strict" deparsed in the wrong place
 180 # uni/tr_ several
 181 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
 182 # ext/Data/Dumper/t/dumper compile
 183 # ext/DB_file/several
 184 # ext/Encode/several
 185 # ext/Ernno/Errno warnings
 186 # ext/IO/lib/IO/t/io_sel 23
 187 # ext/PerlIO/t/encoding compile
 188 # ext/POSIX/t/posix 6
 189 # ext/Socket/Socket 8
 190 # ext/Storable/t/croak compile
 191 # lib/Attribute/Handlers/t/multi compile
 192 # lib/bignum/ several
 193 # lib/charnames 35
 194 # lib/constant 32
 195 # lib/English 40
 196 # lib/ExtUtils/t/bytes 4
 197 # lib/File/DosGlob compile
 198 # lib/Filter/Simple/t/data 1
 199 # lib/Math/BigInt/t/constant 1
 200 # lib/Net/t/config Deparse-warning
 201 # lib/overload compile
 202 # lib/Switch/ several
 203 # lib/Symbol 4
 204 # lib/Test/Simple several
 205 # lib/Term/Complete
 206 # lib/Tie/File/t/29_downcopy 5
 207 # lib/vars 22
 208
 209 # Object fields (were globals):
 210 #
 211 # avoid_local:
 212 # (local($a), local($b)) and local($a, $b) have the same internal
 213 # representation but the short form looks better. We notice we can
 214 # use a large-scale local when checking the list, but need to prevent
 215 # individual locals too. This hash holds the addresses of OPs that
 216 # have already had their local-ness accounted for. The same thing
 217 # is done with my().
 218 #
 219 # curcv:
 220 # CV for current sub (or main program) being deparsed
 221 #
 222 # curcvlex:
 223 # Cached hash of lexical variables for curcv: keys are names,
 224 # each value is an array of pairs, indicating the cop_seq of scopes
 225 # in which a var of that name is valid.
 226 #
 227 # curcop:
 228 # COP for statement being deparsed
 229 #
 230 # curstash:
 231 # name of the current package for deparsed code
 232 #
 233 # subs_todo:
 234 # array of [cop_seq, CV, is_format?] for subs and formats we still
 235 # want to deparse
 236 #
 237 # protos_todo:
 238 # as above, but [name, prototype] for subs that never got a GV
 239 #
 240 # subs_done, forms_done:
 241 # keys are addresses of GVs for subs and formats we've already
 242 # deparsed (or at least put into subs_todo)
 243 #
 244 # subs_declared
 245 # keys are names of subs for which we've printed declarations.
 246 # That means we can omit parentheses from the arguments. It also means we
 247 # need to put CORE:: on core functions of the same name.
 248 #
 249 # subs_deparsed
 250 # Keeps track of fully qualified names of all deparsed subs.
 251 #
 252 # parens: -p
 253 # linenums: -l
 254 # unquote: -q
 255 # cuddle: ` ' or `\n', depending on -sC
 256 # indent_size: -si
 257 # use_tabs: -sT
 258 # ex_const: -sv
 259
 260 # A little explanation of how precedence contexts and associativity
 261 # work:
 262 #
 263 # deparse() calls each per-op subroutine with an argument $cx (short
 264 # for context, but not the same as the cx* in the perl core), which is
 265 # a number describing the op's parents in terms of precedence, whether
 266 # they're inside an expression or at statement level, etc.  (see
 267 # chart below). When ops with children call deparse on them, they pass
 268 # along their precedence. Fractional values are used to implement
 269 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
 270 # parentheses hacks. The major disadvantage of this scheme is that
 271 # it doesn't know about right sides and left sides, so say if you
 272 # assign a listop to a variable, it can't tell it's allowed to leave
 273 # the parens off the listop.
 274
 275 # Precedences:
 276 # 26             [TODO] inside interpolation context ("")
 277 # 25 left        terms and list operators (leftward)
 278 # 24 left        ->
 279 # 23 nonassoc    ++ --
 280 # 22 right       **
 281 # 21 right       ! ~ \ and unary + and -
 282 # 20 left        =~ !~
 283 # 19 left        * / % x
 284 # 18 left        + - .
 285 # 17 left        << >>
 286 # 16 nonassoc    named unary operators
 287 # 15 nonassoc    < > <= >= lt gt le ge
 288 # 14 nonassoc    == != <=> eq ne cmp
 289 # 13 left        &
 290 # 12 left        | ^
 291 # 11 left        &&
 292 # 10 left        ||
 293 #  9 nonassoc    ..  ...
 294 #  8 right       ?:
 295 #  7 right       = += -= *= etc.
 296 #  6 left        , =>
 297 #  5 nonassoc    list operators (rightward)
 298 #  4 right       not
 299 #  3 left        and
 300 #  2 left        or xor
 301 #  1             statement modifiers
 302 #  0.5           statements, but still print scopes as do { ... }
 303 #  0             statement level
 304
 305 # Nonprinting characters with special meaning:
 306 # \cS - steal parens (see maybe_parens_unop)
 307 # \n - newline and indent
 308 # \t - increase indent
 309 # \b - decrease indent (`outdent')
 310 # \f - flush left (no indent)
 311 # \cK - kill following semicolon, if any
 312
 313 sub null {
 314     my $op = shift;
 315     return class($op) eq "NULL";
 316 }
 317
 318 sub todo {
 319     my $self = shift;
 320     my($cv, $is_form) = @_;
 321     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
 322     my $seq;
 323     if ($cv->OUTSIDE_SEQ) {
 324         $seq = $cv->OUTSIDE_SEQ;
 325     } elsif (!null($cv->START) and is_state($cv->START)) {
 326         $seq = $cv->START->cop_seq;
 327     } else {
 328         $seq = 0;
 329     }
 330     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
 331     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
 332         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
 333     }
 334 }
 335
 336 sub next_todo {
 337     my $self = shift;
 338     my $ent = shift @{$self->{'subs_todo'}};
 339     my $cv = $ent->[1];
 340     my $gv = $cv->GV;
 341     my $name = $self->gv_name($gv);
 342     if ($ent->[2]) {
 343         return "format $name =\n"
 344             . $self->deparse_format($ent->[1]). "\n";
 345     } else {
 346         $self->{'subs_declared'}{$name} = 1;
 347         if ($name eq "BEGIN") {
 348             my $use_dec = $self->begin_is_use($cv);
 349             if (defined ($use_dec) and $self->{'expand'} < 5) {
 350                 return () if 0 == length($use_dec);
 351                 return $use_dec;
 352             }
 353         }
 354         my $l = '';
 355         if ($self->{'linenums'}) {
 356             my $line = $gv->LINE;
 357             my $file = $gv->FILE;
 358             $l = "\n\f#line $line \"$file\"\n";
 359         }
 360         my $p = '';
 361         if (class($cv->STASH) ne "SPECIAL") {
 362             my $stash = $cv->STASH->NAME;
 363             if ($stash ne $self->{'curstash'}) {
 364                 $p = "package $stash;\n";
 365                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
 366                 $self->{'curstash'} = $stash;
 367             }
 368             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
 369         }
 370         return "${p}${l}sub $name " . $self->deparse_sub($cv);
 371     }
 372 }
 373
 374 # Return a "use" declaration for this BEGIN block, if appropriate
 375 sub begin_is_use {
 376     my ($self, $cv) = @_;
 377     my $root = $cv->ROOT;
 378     local @$self{qw'curcv curcvlex'} = ($cv);
 379 #require B::Debug;
 380 #B::walkoptree($cv->ROOT, "debug");
 381     my $lineseq = $root->first;
 382     return if $lineseq->name ne "lineseq";
 383
 384     my $req_op = $lineseq->first->sibling;
 385     return if $req_op->name ne "require";
 386
 387     my $module;
 388     if ($req_op->first->private & OPpCONST_BARE) {
 389         # Actually it should always be a bareword
 390         $module = $self->const_sv($req_op->first)->PV;
 391         $module =~ s[/][::]g;
 392         $module =~ s/.pm$//;
 393     }
 394     else {
 395         $module = $self->const($self->const_sv($req_op->first), 6);
 396     }
 397
 398     my $version;
 399     my $version_op = $req_op->sibling;
 400     return if class($version_op) eq "NULL";
 401     if ($version_op->name eq "lineseq") {
 402         # We have a version parameter; skip nextstate & pushmark
 403         my $constop = $version_op->first->next->next;
 404
 405         return unless $self->const_sv($constop)->PV eq $module;
 406         $constop = $constop->sibling;
 407         $version = $self->const_sv($constop);
 408         if (class($version) eq "IV") {
 409             $version = $version->int_value;
 410         } elsif (class($version) eq "NV") {
 411             $version = $version->NV;
 412         } elsif (class($version) ne "PVMG") {
 413             # Includes PVIV and PVNV
 414             $version = $version->PV;
 415         } else {
 416             # version specified as a v-string
 417             $version = 'v'.join '.', map ord, split //, $version->PV;
 418         }
 419         $constop = $constop->sibling;
 420         return if $constop->name ne "method_named";
 421         return if $self->const_sv($constop)->PV ne "VERSION";
 422     }
 423
 424     $lineseq = $version_op->sibling;
 425     return if $lineseq->name ne "lineseq";
 426     my $entersub = $lineseq->first->sibling;
 427     if ($entersub->name eq "stub") {
 428         return "use $module $version ();\n" if defined $version;
 429         return "use $module ();\n";
 430     }
 431     return if $entersub->name ne "entersub";
 432
 433     # See if there are import arguments
 434     my $args = '';
 435
 436     my $svop = $entersub->first->sibling; # Skip over pushmark
 437     return unless $self->const_sv($svop)->PV eq $module;
 438
 439     # Pull out the arguments
 440     for ($svop=$svop->sibling; $svop->name ne "method_named";
 441                 $svop = $svop->sibling) {
 442         $args .= ", " if length($args);
 443         $args .= $self->deparse($svop, 6);
 444     }
 445
 446     my $use = 'use';
 447     my $method_named = $svop;
 448     return if $method_named->name ne "method_named";
 449     my $method_name = $self->const_sv($method_named)->PV;
 450
 451     if ($method_name eq "unimport") {
 452         $use = 'no';
 453     }
 454
 455     # Certain pragmas are dealt with using hint bits,
 456     # so we ignore them here
 457     if ($module eq 'strict' || $module eq 'integer'
 458         || $module eq 'bytes' || $module eq 'warnings'
 459         || $module eq 'feature') {
 460         return "";
 461     }
 462
 463     if (defined $version && length $args) {
 464         return "$use $module $version ($args);\n";
 465     } elsif (defined $version) {
 466         return "$use $module $version;\n";
 467     } elsif (length $args) {
 468         return "$use $module ($args);\n";
 469     } else {
 470         return "$use $module;\n";
 471     }
 472 }
 473
 474 sub stash_subs {
 475     my ($self, $pack) = @_;
 476     my (@ret, $stash);
 477     if (!defined $pack) {
 478         $pack = '';
 479         $stash = \%::;
 480     }
 481     else {
 482         $pack =~ s/(::)?$/::/;
 483         no strict 'refs';
 484         $stash = \%{"main::$pack"};
 485     }
 486     my %stash = svref_2object($stash)->ARRAY;
 487     while (my ($key, $val) = each %stash) {
 488         my $class = class($val);
 489         if ($class eq "PV") {
 490             # Just a prototype. As an ugly but fairly effective way
 491             # to find out if it belongs here is to see if the AUTOLOAD
 492             # (if any) for the stash was defined in one of our files.
 493             my $A = $stash{"AUTOLOAD"};
 494             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 495                 && class($A->CV) eq "CV") {
 496                 my $AF = $A->FILE;
 497                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 498             }
 499             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
 500         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
 501             # Just a name. As above.
 502             # But skip proxy constant subroutines, as some form of perl-space
 503             # visible code must have created them, be it a use statement, or
 504             # some direct symbol-table manipulation code that we will Deparse
 505             my $A = $stash{"AUTOLOAD"};
 506             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 507                 && class($A->CV) eq "CV") {
 508                 my $AF = $A->FILE;
 509                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 510             }
 511             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
 512         } elsif ($class eq "GV") {
 513             if (class(my $cv = $val->CV) ne "SPECIAL") {
 514                 next if $self->{'subs_done'}{$$val}++;
 515                 next if $$val != ${$cv->GV};   # Ignore imposters
 516                 $self->todo($cv, 0);
 517             }
 518             if (class(my $cv = $val->FORM) ne "SPECIAL") {
 519                 next if $self->{'forms_done'}{$$val}++;
 520                 next if $$val != ${$cv->GV};   # Ignore imposters
 521                 $self->todo($cv, 1);
 522             }
 523             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
 524                 $self->stash_subs($pack . $key)
 525                     unless $pack eq '' && $key eq 'main::';
 526                     # avoid infinite recursion
 527             }
 528         }
 529     }
 530 }
 531
 532 sub print_protos {
 533     my $self = shift;
 534     my $ar;
 535     my @ret;
 536     foreach $ar (@{$self->{'protos_todo'}}) {
 537         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
 538         push @ret, "sub " . $ar->[0] .  "$proto;\n";
 539     }
 540     delete $self->{'protos_todo'};
 541     return @ret;
 542 }
 543
 544 sub style_opts {
 545     my $self = shift;
 546     my $opts = shift;
 547     my $opt;
 548     while (length($opt = substr($opts, 0, 1))) {
 549         if ($opt eq "C") {
 550             $self->{'cuddle'} = " ";
 551             $opts = substr($opts, 1);
 552         } elsif ($opt eq "i") {
 553             $opts =~ s/^i(\d+)//;
 554             $self->{'indent_size'} = $1;
 555         } elsif ($opt eq "T") {
 556             $self->{'use_tabs'} = 1;
 557             $opts = substr($opts, 1);
 558         } elsif ($opt eq "v") {
 559             $opts =~ s/^v([^.]*)(.|$)//;
 560             $self->{'ex_const'} = $1;
 561         }
 562     }
 563 }
 564
 565 sub new {
 566     my $class = shift;
 567     my $self = bless {}, $class;
 568     $self->{'cuddle'} = "\n";
 569     $self->{'curcop'} = undef;
 570     $self->{'curstash'} = "main";
 571     $self->{'ex_const'} = "'???'";
 572     $self->{'expand'} = 0;
 573     $self->{'files'} = {};
 574     $self->{'indent_size'} = 4;
 575     $self->{'linenums'} = 0;
 576     $self->{'parens'} = 0;
 577     $self->{'subs_todo'} = [];
 578     $self->{'unquote'} = 0;
 579     $self->{'use_dumper'} = 0;
 580     $self->{'use_tabs'} = 0;
 581
 582     $self->{'ambient_arybase'} = 0;
 583     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
 584     $self->{'ambient_hints'} = 0;
 585     $self->{'ambient_hinthash'} = undef;
 586     $self->init();
 587
 588     while (my $arg = shift @_) {
 589         if ($arg eq "-d") {
 590             $self->{'use_dumper'} = 1;
 591             require Data::Dumper;
 592         } elsif ($arg =~ /^-f(.*)/) {
 593             $self->{'files'}{$1} = 1;
 594         } elsif ($arg eq "-l") {
 595             $self->{'linenums'} = 1;
 596         } elsif ($arg eq "-p") {
 597             $self->{'parens'} = 1;
 598         } elsif ($arg eq "-P") {
 599             $self->{'noproto'} = 1;
 600         } elsif ($arg eq "-q") {
 601             $self->{'unquote'} = 1;
 602         } elsif (substr($arg, 0, 2) eq "-s") {
 603             $self->style_opts(substr $arg, 2);
 604         } elsif ($arg =~ /^-x(\d)$/) {
 605             $self->{'expand'} = $1;
 606         }
 607     }
 608     return $self;
 609 }
 610
 611 {
 612     # Mask out the bits that L<warnings::register> uses
 613     my $WARN_MASK;
 614     BEGIN {
 615         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
 616     }
 617     sub WARN_MASK () {
 618         return $WARN_MASK;
 619     }
 620 }
 621
 622 # Initialise the contextual information, either from
 623 # defaults provided with the ambient_pragmas method,
 624 # or from perl's own defaults otherwise.
 625 sub init {
 626     my $self = shift;
 627
 628     $self->{'arybase'}  = $self->{'ambient_arybase'};
 629     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
 630                                 ? $self->{'ambient_warnings'} & WARN_MASK
 631                                 : undef;
 632     $self->{'hints'}    = $self->{'ambient_hints'};
 633     $self->{'hints'} &= 0xFF if $] < 5.009;
 634     $self->{'hinthash'} = $self->{'ambient_hinthash'};
 635
 636     # also a convenient place to clear out subs_declared
 637     delete $self->{'subs_declared'};
 638 }
 639
 640 sub compile {
 641     my(@args) = @_;
 642     return sub {
 643         my $self = B::Deparse->new(@args);
 644         # First deparse command-line args
 645         if (defined $^I) { # deparse -i
 646             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
 647         }
 648         if ($^W) { # deparse -w
 649             print qq(BEGIN { \$^W = $^W; }\n);
 650         }
 651         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
 652             my $fs = perlstring($/) || 'undef';
 653             my $bs = perlstring($O::savebackslash) || 'undef';
 654             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
 655         }
 656         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
 657         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
 658             ? B::unitcheck_av->ARRAY
 659             : ();
 660         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
 661         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
 662         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
 663         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
 664             $self->todo($block, 0);
 665         }
 666         $self->stash_subs();
 667         local($SIG{"__DIE__"}) =
 668           sub {
 669               if ($self->{'curcop'}) {
 670                   my $cop = $self->{'curcop'};
 671                   my($line, $file) = ($cop->line, $cop->file);
 672                   print STDERR "While deparsing $file near line $line,\n";
 673               }
 674             };
 675         $self->{'curcv'} = main_cv;
 676         $self->{'curcvlex'} = undef;
 677         print $self->print_protos;
 678         @{$self->{'subs_todo'}} =
 679           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
 680         print $self->indent($self->deparse_root(main_root)), "\n"
 681           unless null main_root;
 682         my @text;
 683         while (scalar(@{$self->{'subs_todo'}})) {
 684             push @text, $self->next_todo;
 685         }
 686         print $self->indent(join("", @text)), "\n" if @text;
 687
 688         # Print __DATA__ section, if necessary
 689         no strict 'refs';
 690         my $laststash = defined $self->{'curcop'}
 691             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
 692         if (defined *{$laststash."::DATA"}{IO}) {
 693             print "package $laststash;\n"
 694                 unless $laststash eq $self->{'curstash'};
 695             print "__DATA__\n";
 696             print readline(*{$laststash."::DATA"});
 697         }
 698     }
 699 }
 700
 701 sub coderef2text {
 702     my $self = shift;
 703     my $sub = shift;
 704     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
 705
 706     $self->init();
 707     return $self->indent($self->deparse_sub(svref_2object($sub)));
 708 }
 709
 710 sub ambient_pragmas {
 711     my $self = shift;
 712     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
 713
 714     while (@_ > 1) {
 715         my $name = shift();
 716         my $val  = shift();
 717
 718         if ($name eq 'strict') {
 719             require strict;
 720
 721             if ($val eq 'none') {
 722                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
 723                 next();
 724             }
 725
 726             my @names;
 727             if ($val eq "all") {
 728                 @names = qw/refs subs vars/;
 729             }
 730             elsif (ref $val) {
 731                 @names = @$val;
 732             }
 733             else {
 734                 @names = split' ', $val;
 735             }
 736             $hint_bits |= strict::bits(@names);
 737         }
 738
 739         elsif ($name eq '$[') {
 740             $arybase = $val;
 741         }
 742
 743         elsif ($name eq 'integer'
 744             || $name eq 'bytes'
 745             || $name eq 'utf8') {
 746             require "$name.pm";
 747             if ($val) {
 748                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
 749             }
 750             else {
 751                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
 752             }
 753         }
 754
 755         elsif ($name eq 're') {
 756             require re;
 757             if ($val eq 'none') {
 758                 $hint_bits &= ~re::bits(qw/taint eval/);
 759                 next();
 760             }
 761
 762             my @names;
 763             if ($val eq 'all') {
 764                 @names = qw/taint eval/;
 765             }
 766             elsif (ref $val) {
 767                 @names = @$val;
 768             }
 769             else {
 770                 @names = split' ',$val;
 771             }
 772             $hint_bits |= re::bits(@names);
 773         }
 774
 775         elsif ($name eq 'warnings') {
 776             if ($val eq 'none') {
 777                 $warning_bits = $warnings::NONE;
 778                 next();
 779             }
 780
 781             my @names;
 782             if (ref $val) {
 783                 @names = @$val;
 784             }
 785             else {
 786                 @names = split/\s+/, $val;
 787             }
 788
 789             $warning_bits = $warnings::NONE if !defined ($warning_bits);
 790             $warning_bits |= warnings::bits(@names);
 791         }
 792
 793         elsif ($name eq 'warning_bits') {
 794             $warning_bits = $val;
 795         }
 796
 797         elsif ($name eq 'hint_bits') {
 798             $hint_bits = $val;
 799         }
 800
 801         elsif ($name eq '%^H') {
 802             $hinthash = $val;
 803         }
 804
 805         else {
 806             croak "Unknown pragma type: $name";
 807         }
 808     }
 809     if (@_) {
 810         croak "The ambient_pragmas method expects an even number of args";
 811     }
 812
 813     $self->{'ambient_arybase'} = $arybase;
 814     $self->{'ambient_warnings'} = $warning_bits;
 815     $self->{'ambient_hints'} = $hint_bits;
 816     $self->{'ambient_hinthash'} = $hinthash;
 817 }
 818
 819 # This method is the inner loop, so try to keep it simple
 820 sub deparse {
 821     my $self = shift;
 822     my($op, $cx) = @_;
 823
 824     Carp::confess("Null op in deparse") if !defined($op)
 825                                         || class($op) eq "NULL";
 826     my $meth = "pp_" . $op->name;
 827     return $self->$meth($op, $cx);
 828 }
 829
 830 sub indent {
 831     my $self = shift;
 832     my $txt = shift;
 833     my @lines = split(/\n/, $txt);
 834     my $leader = "";
 835     my $level = 0;
 836     my $line;
 837     for $line (@lines) {
 838         my $cmd = substr($line, 0, 1);
 839         if ($cmd eq "\t" or $cmd eq "\b") {
 840             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
 841             if ($self->{'use_tabs'}) {
 842                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
 843             } else {
 844                 $leader = " " x $level;
 845             }
 846             $line = substr($line, 1);
 847         }
 848         if (substr($line, 0, 1) eq "\f") {
 849             $line = substr($line, 1); # no indent
 850         } else {
 851             $line = $leader . $line;
 852         }
 853         $line =~ s/\cK;?//g;
 854     }
 855     return join("\n", @lines);
 856 }
 857
 858 sub deparse_sub {
 859     my $self = shift;
 860     my $cv = shift;
 861     my $proto = "";
 862 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
 863 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
 864     local $self->{'curcop'} = $self->{'curcop'};
 865     if ($cv->FLAGS & SVf_POK) {
 866         $proto = "(". $cv->PV . ") ";
 867     }
 868     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
 869         $proto .= ": ";
 870         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
 871         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
 872         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
 873     }
 874
 875     local($self->{'curcv'}) = $cv;
 876     local($self->{'curcvlex'});
 877     local(@$self{qw'curstash warnings hints hinthash'})
 878                 = @$self{qw'curstash warnings hints hinthash'};
 879     my $body;
 880     if (not null $cv->ROOT) {
 881         my $lineseq = $cv->ROOT->first;
 882         if ($lineseq->name eq "lineseq") {
 883             my @ops;
 884             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
 885                 push @ops, $o;
 886             }
 887             $body = $self->lineseq(undef, @ops).";";
 888             my $scope_en = $self->find_scope_en($lineseq);
 889             if (defined $scope_en) {
 890                 my $subs = join"", $self->seq_subs($scope_en);
 891                 $body .= ";\n$subs" if length($subs);
 892             }
 893         }
 894         else {
 895             $body = $self->deparse($cv->ROOT->first, 0);
 896         }
 897     }
 898     else {
 899         my $sv = $cv->const_sv;
 900         if ($$sv) {
 901             # uh-oh. inlinable sub... format it differently
 902             return $proto . "{ " . $self->const($sv, 0) . " }\n";
 903         } else { # XSUB? (or just a declaration)
 904             return "$proto;\n";
 905         }
 906     }
 907     return $proto ."{\n\t$body\n\b}" ."\n";
 908 }
 909
 910 sub deparse_format {
 911     my $self = shift;
 912     my $form = shift;
 913     my @text;
 914     local($self->{'curcv'}) = $form;
 915     local($self->{'curcvlex'});
 916     local($self->{'in_format'}) = 1;
 917     local(@$self{qw'curstash warnings hints hinthash'})
 918                 = @$self{qw'curstash warnings hints hinthash'};
 919     my $op = $form->ROOT;
 920     my $kid;
 921     return "\f." if $op->first->name eq 'stub'
 922                 || $op->first->name eq 'nextstate';
 923     $op = $op->first->first; # skip leavewrite, lineseq
 924     while (not null $op) {
 925         $op = $op->sibling; # skip nextstate
 926         my @exprs;
 927         $kid = $op->first->sibling; # skip pushmark
 928         push @text, "\f".$self->const_sv($kid)->PV;
 929         $kid = $kid->sibling;
 930         for (; not null $kid; $kid = $kid->sibling) {
 931             push @exprs, $self->deparse($kid, 0);
 932         }
 933         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
 934         $op = $op->sibling;
 935     }
 936     return join("", @text) . "\f.";
 937 }
 938
 939 sub is_scope {
 940     my $op = shift;
 941     return $op->name eq "leave" || $op->name eq "scope"
 942       || $op->name eq "lineseq"
 943         || ($op->name eq "null" && class($op) eq "UNOP"
 944             && (is_scope($op->first) || $op->first->name eq "enter"));
 945 }
 946
 947 sub is_state {
 948     my $name = $_[0]->name;
 949     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
 950 }
 951
 952 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
 953     my $op = shift;
 954     return (!null($op) and null($op->sibling)
 955             and $op->name eq "null" and class($op) eq "UNOP"
 956             and (($op->first->name =~ /^(and|or)$/
 957                   and $op->first->first->sibling->name eq "lineseq")
 958                  or ($op->first->name eq "lineseq"
 959                      and not null $op->first->first->sibling
 960                      and $op->first->first->sibling->name eq "unstack")
 961                  ));
 962 }
 963
 964 # Check if the op and its sibling are the initialization and the rest of a
 965 # for (..;..;..) { ... } loop
 966 sub is_for_loop {
 967     my $op = shift;
 968     # This OP might be almost anything, though it won't be a
 969     # nextstate. (It's the initialization, so in the canonical case it
 970     # will be an sassign.) The sibling is (old style) a lineseq whose
 971     # first child is a nextstate and whose second is a leaveloop, or
 972     # (new style) an unstack whose sibling is a leaveloop.
 973     my $lseq = $op->sibling;
 974     return 0 unless !is_state($op) and !null($lseq);
 975     if ($lseq->name eq "lineseq") {
 976         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
 977             && (my $sib = $lseq->first->sibling)) {
 978             return (!null($sib) && $sib->name eq "leaveloop");
 979         }
 980     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
 981         my $sib = $lseq->sibling;
 982         return $sib && !null($sib) && $sib->name eq "leaveloop";
 983     }
 984     return 0;
 985 }
 986
 987 sub is_scalar {
 988     my $op = shift;
 989     return ($op->name eq "rv2sv" or
 990             $op->name eq "padsv" or
 991             $op->name eq "gv" or # only in array/hash constructs
 992             $op->flags & OPf_KIDS && !null($op->first)
 993               && $op->first->name eq "gvsv");
 994 }
 995
 996 sub maybe_parens {
 997     my $self = shift;
 998     my($text, $cx, $prec) = @_;
 999     if ($prec < $cx              # unary ops nest just fine
1000         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1001         or $self->{'parens'})
1002     {
1003         $text = "($text)";
1004         # In a unop, let parent reuse our parens; see maybe_parens_unop
1005         $text = "\cS" . $text if $cx == 16;
1006         return $text;
1007     } else {
1008         return $text;
1009     }
1010 }
1011
1012 # same as above, but get around the `if it looks like a function' rule
1013 sub maybe_parens_unop {
1014     my $self = shift;
1015     my($name, $kid, $cx) = @_;
1016     if ($cx > 16 or $self->{'parens'}) {
1017         $kid =  $self->deparse($kid, 1);
1018         if ($name eq "umask" && $kid =~ /^\d+$/) {
1019             $kid = sprintf("%#o", $kid);
1020         }
1021         return $self->keyword($name) . "($kid)";
1022     } else {
1023         $kid = $self->deparse($kid, 16);
1024         if ($name eq "umask" && $kid =~ /^\d+$/) {
1025             $kid = sprintf("%#o", $kid);
1026         }
1027         $name = $self->keyword($name);
1028         if (substr($kid, 0, 1) eq "\cS") {
1029             # use kid's parens
1030             return $name . substr($kid, 1);
1031         } elsif (substr($kid, 0, 1) eq "(") {
1032             # avoid looks-like-a-function trap with extra parens
1033             # (`+' can lead to ambiguities)
1034             return "$name(" . $kid  . ")";
1035         } else {
1036             return "$name $kid";
1037         }
1038     }
1039 }
1040
1041 sub maybe_parens_func {
1042     my $self = shift;
1043     my($func, $text, $cx, $prec) = @_;
1044     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1045         return "$func($text)";
1046     } else {
1047         return "$func $text";
1048     }
1049 }
1050
1051 sub maybe_local {
1052     my $self = shift;
1053     my($op, $cx, $text) = @_;
1054     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1055     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1056         and not $self->{'avoid_local'}{$$op}) {
1057         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1058         if( $our_local eq 'our' ) {
1059             if ( $text !~ /^\W(\w+::)*\w+\z/
1060              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1061             ) {
1062                 die "Unexpected our($text)\n";
1063             }
1064             $text =~ s/(\w+::)+//;
1065         }
1066         if (want_scalar($op)) {
1067             return "$our_local $text";
1068         } else {
1069             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1070         }
1071     } else {
1072         return $text;
1073     }
1074 }
1075
1076 sub maybe_targmy {
1077     my $self = shift;
1078     my($op, $cx, $func, @args) = @_;
1079     if ($op->private & OPpTARGET_MY) {
1080         my $var = $self->padname($op->targ);
1081         my $val = $func->($self, $op, 7, @args);
1082         return $self->maybe_parens("$var = $val", $cx, 7);
1083     } else {
1084         return $func->($self, $op, $cx, @args);
1085     }
1086 }
1087
1088 sub padname_sv {
1089     my $self = shift;
1090     my $targ = shift;
1091     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1092 }
1093
1094 sub maybe_my {
1095     my $self = shift;
1096     my($op, $cx, $text) = @_;
1097     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1098         my $my = $op->private & OPpPAD_STATE
1099             ? $self->keyword("state")
1100             : "my";
1101         if (want_scalar($op)) {
1102             return "$my $text";
1103         } else {
1104             return $self->maybe_parens_func($my, $text, $cx, 16);
1105         }
1106     } else {
1107         return $text;
1108     }
1109 }
1110
1111 # The following OPs don't have functions:
1112
1113 # pp_padany -- does not exist after parsing
1114
1115 sub AUTOLOAD {
1116     if ($AUTOLOAD =~ s/^.*::pp_//) {
1117         warn "unexpected OP_".uc $AUTOLOAD;
1118         return "XXX";
1119     } else {
1120         die "Undefined subroutine $AUTOLOAD called";
1121     }
1122 }
1123
1124 sub DESTROY {}  #       Do not AUTOLOAD
1125
1126 # $root should be the op which represents the root of whatever
1127 # we're sequencing here. If it's undefined, then we don't append
1128 # any subroutine declarations to the deparsed ops, otherwise we
1129 # append appropriate declarations.
1130 sub lineseq {
1131     my($self, $root, @ops) = @_;
1132     my($expr, @exprs);
1133
1134     my $out_cop = $self->{'curcop'};
1135     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1136     my $limit_seq;
1137     if (defined $root) {
1138         $limit_seq = $out_seq;
1139         my $nseq;
1140         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1141         $limit_seq = $nseq if !defined($limit_seq)
1142                            or defined($nseq) && $nseq < $limit_seq;
1143     }
1144     $limit_seq = $self->{'limit_seq'}
1145         if defined($self->{'limit_seq'})
1146         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1147     local $self->{'limit_seq'} = $limit_seq;
1148
1149     $self->walk_lineseq($root, \@ops,
1150                        sub { push @exprs, $_[0]} );
1151
1152     my $body = join(";\n", grep {length} @exprs);
1153     my $subs = "";
1154     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1155         $subs = join "\n", $self->seq_subs($limit_seq);
1156     }
1157     return join(";\n", grep {length} $body, $subs);
1158 }
1159
1160 sub scopeop {
1161     my($real_block, $self, $op, $cx) = @_;
1162     my $kid;
1163     my @kids;
1164
1165     local(@$self{qw'curstash warnings hints hinthash'})
1166                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1167     if ($real_block) {
1168         $kid = $op->first->sibling; # skip enter
1169         if (is_miniwhile($kid)) {
1170             my $top = $kid->first;
1171             my $name = $top->name;
1172             if ($name eq "and") {
1173                 $name = "while";
1174             } elsif ($name eq "or") {
1175                 $name = "until";
1176             } else { # no conditional -> while 1 or until 0
1177                 return $self->deparse($top->first, 1) . " while 1";
1178             }
1179             my $cond = $top->first;
1180             my $body = $cond->sibling->first; # skip lineseq
1181             $cond = $self->deparse($cond, 1);
1182             $body = $self->deparse($body, 1);
1183             return "$body $name $cond";
1184         }
1185     } else {
1186         $kid = $op->first;
1187     }
1188     for (; !null($kid); $kid = $kid->sibling) {
1189         push @kids, $kid;
1190     }
1191     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1192         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1193     } else {
1194         my $lineseq = $self->lineseq($op, @kids);
1195         return (length ($lineseq) ? "$lineseq;" : "");
1196     }
1197 }
1198
1199 sub pp_scope { scopeop(0, @_); }
1200 sub pp_lineseq { scopeop(0, @_); }
1201 sub pp_leave { scopeop(1, @_); }
1202
1203 # This is a special case of scopeop and lineseq, for the case of the
1204 # main_root. The difference is that we print the output statements as
1205 # soon as we get them, for the sake of impatient users.
1206 sub deparse_root {
1207     my $self = shift;
1208     my($op) = @_;
1209     local(@$self{qw'curstash warnings hints hinthash'})
1210       = @$self{qw'curstash warnings hints hinthash'};
1211     my @kids;
1212     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1213     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1214         push @kids, $kid;
1215     }
1216     $self->walk_lineseq($op, \@kids,
1217                         sub { print $self->indent($_[0].';');
1218                               print "\n" unless $_[1] == $#kids;
1219                           });
1220 }
1221
1222 sub walk_lineseq {
1223     my ($self, $op, $kids, $callback) = @_;
1224     my @kids = @$kids;
1225     for (my $i = 0; $i < @kids; $i++) {
1226         my $expr = "";
1227         if (is_state $kids[$i]) {
1228             $expr = $self->deparse($kids[$i++], 0);
1229             if ($i > $#kids) {
1230                 $callback->($expr, $i);
1231                 last;
1232             }
1233         }
1234         if (is_for_loop($kids[$i])) {
1235             $callback->($expr . $self->for_loop($kids[$i], 0),
1236                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1237             next;
1238         }
1239         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1240         $expr =~ s/;\n?\z//;
1241         $callback->($expr, $i);
1242     }
1243 }
1244
1245 # The BEGIN {} is used here because otherwise this code isn't executed
1246 # when you run B::Deparse on itself.
1247 my %globalnames;
1248 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1249             "ENV", "ARGV", "ARGVOUT", "_"); }
1250
1251 sub gv_name {
1252     my $self = shift;
1253     my $gv = shift;
1254 Carp::confess() unless ref($gv) eq "B::GV";
1255     my $stash = $gv->STASH->NAME;
1256     my $name = $gv->SAFENAME;
1257     if ($stash eq 'main' && $name =~ /^::/) {
1258         $stash = '::';
1259     }
1260     elsif (($stash eq 'main' && $globalnames{$name})
1261         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1262             && ($stash eq 'main' || $name !~ /::/))
1263         or $name =~ /^[^A-Za-z_:]/)
1264     {
1265         $stash = "";
1266     } else {
1267         $stash = $stash . "::";
1268     }
1269     if ($name =~ /^(\^..|{)/) {
1270         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1271     }
1272     return $stash . $name;
1273 }
1274
1275 # Return the name to use for a stash variable.
1276 # If a lexical with the same name is in scope, it may need to be
1277 # fully-qualified.
1278 sub stash_variable {
1279     my ($self, $prefix, $name, $cx) = @_;
1280
1281     return "$prefix$name" if $name =~ /::/;
1282
1283     unless ($prefix eq '$' || $prefix eq '@' || #'
1284             $prefix eq '%' || $prefix eq '$#') {
1285         return "$prefix$name";
1286     }
1287
1288     if (defined $cx && $cx == 26) {
1289         if ($prefix eq '@' && $name =~ /^[^\w+-]$/) {
1290             return "$prefix\{$name}";
1291         }
1292     }
1293
1294     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1295     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1296     return "$prefix$name";
1297 }
1298
1299 sub lex_in_scope {
1300     my ($self, $name) = @_;
1301     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1302
1303     return 0 if !defined($self->{'curcop'});
1304     my $seq = $self->{'curcop'}->cop_seq;
1305     return 0 if !exists $self->{'curcvlex'}{$name};
1306     for my $a (@{$self->{'curcvlex'}{$name}}) {
1307         my ($st, $en) = @$a;
1308         return 1 if $seq > $st && $seq <= $en;
1309     }
1310     return 0;
1311 }
1312
1313 sub populate_curcvlex {
1314     my $self = shift;
1315     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1316         my $padlist = $cv->PADLIST;
1317         # an undef CV still in lexical chain
1318         next if class($padlist) eq "SPECIAL";
1319         my @padlist = $padlist->ARRAY;
1320         my @ns = $padlist[0]->ARRAY;
1321
1322         for (my $i=0; $i<@ns; ++$i) {
1323             next if class($ns[$i]) eq "SPECIAL";
1324             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1325             if (class($ns[$i]) eq "PV") {
1326                 # Probably that pesky lexical @_
1327                 next;
1328             }
1329             my $name = $ns[$i]->PVX;
1330             my ($seq_st, $seq_en) =
1331                 ($ns[$i]->FLAGS & SVf_FAKE)
1332                     ? (0, 999999)
1333                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1334
1335             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1336         }
1337     }
1338 }
1339
1340 sub find_scope_st { ((find_scope(@_))[0]); }
1341 sub find_scope_en { ((find_scope(@_))[1]); }
1342
1343 # Recurses down the tree, looking for pad variable introductions and COPs
1344 sub find_scope {
1345     my ($self, $op, $scope_st, $scope_en) = @_;
1346     carp("Undefined op in find_scope") if !defined $op;
1347     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1348
1349     my @queue = ($op);
1350     while(my $op = shift @queue ) {
1351         for (my $o=$op->first; $$o; $o=$o->sibling) {
1352             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1353                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1354                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1355                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1356                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1357                 return ($scope_st, $scope_en);
1358             }
1359             elsif (is_state($o)) {
1360                 my $c = $o->cop_seq;
1361                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1362                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1363                 return ($scope_st, $scope_en);
1364             }
1365             elsif ($o->flags & OPf_KIDS) {
1366                 unshift (@queue, $o);
1367             }
1368         }
1369     }
1370
1371     return ($scope_st, $scope_en);
1372 }
1373
1374 # Returns a list of subs which should be inserted before the COP
1375 sub cop_subs {
1376     my ($self, $op, $out_seq) = @_;
1377     my $seq = $op->cop_seq;
1378     # If we have nephews, then our sequence number indicates
1379     # the cop_seq of the end of some sort of scope.
1380     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1381         and my $nseq = $self->find_scope_st($op->sibling) ) {
1382         $seq = $nseq;
1383     }
1384     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1385     return $self->seq_subs($seq);
1386 }
1387
1388 sub seq_subs {
1389     my ($self, $seq) = @_;
1390     my @text;
1391 #push @text, "# ($seq)\n";
1392
1393     return "" if !defined $seq;
1394     while (scalar(@{$self->{'subs_todo'}})
1395            and $seq > $self->{'subs_todo'}[0][0]) {
1396         push @text, $self->next_todo;
1397     }
1398     return @text;
1399 }
1400
1401 # Notice how subs and formats are inserted between statements here;
1402 # also $[ assignments and pragmas.
1403 sub pp_nextstate {
1404     my $self = shift;
1405     my($op, $cx) = @_;
1406     $self->{'curcop'} = $op;
1407     my @text;
1408     push @text, $self->cop_subs($op);
1409     my $stash = $op->stashpv;
1410     if ($stash ne $self->{'curstash'}) {
1411         push @text, "package $stash;\n";
1412         $self->{'curstash'} = $stash;
1413     }
1414
1415     if ($self->{'arybase'} != $op->arybase) {
1416         push @text, '$[ = '. $op->arybase .";\n";
1417         $self->{'arybase'} = $op->arybase;
1418     }
1419
1420     my $warnings = $op->warnings;
1421     my $warning_bits;
1422     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1423         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1424     }
1425     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1426         $warning_bits = $warnings::NONE;
1427     }
1428     elsif ($warnings->isa("B::SPECIAL")) {
1429         $warning_bits = undef;
1430     }
1431     else {
1432         $warning_bits = $warnings->PV & WARN_MASK;
1433     }
1434
1435     if (defined ($warning_bits) and
1436        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1437         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1438         $self->{'warnings'} = $warning_bits;
1439     }
1440
1441     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1442     if ($self->{'hints'} != $hints) {
1443         push @text, declare_hints($self->{'hints'}, $hints);
1444         $self->{'hints'} = $hints;
1445     }
1446
1447     # hack to check that the hint hash hasn't changed
1448     if ($] > 5.009 &&
1449         "@{[sort %{$self->{'hinthash'} || {}}]}"
1450         ne "@{[sort %{$op->hints_hash->HASH || {}}]}") {
1451         push @text, declare_hinthash($self->{'hinthash'}, $op->hints_hash->HASH, $self->{indent_size});
1452         $self->{'hinthash'} = $op->hints_hash->HASH;
1453     }
1454
1455     # This should go after of any branches that add statements, to
1456     # increase the chances that it refers to the same line it did in
1457     # the original program.
1458     if ($self->{'linenums'}) {
1459         push @text, "\f#line " . $op->line .
1460           ' "' . $op->file, qq'"\n';
1461     }
1462
1463     push @text, $op->label . ": " if $op->label;
1464
1465     return join("", @text);
1466 }
1467
1468 sub declare_warnings {
1469     my ($from, $to) = @_;
1470     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1471         return "use warnings;\n";
1472     }
1473     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1474         return "no warnings;\n";
1475     }
1476     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1477 }
1478
1479 sub declare_hints {
1480     my ($from, $to) = @_;
1481     my $use = $to   & ~$from;
1482     my $no  = $from & ~$to;
1483     my $decls = "";
1484     for my $pragma (hint_pragmas($use)) {
1485         $decls .= "use $pragma;\n";
1486     }
1487     for my $pragma (hint_pragmas($no)) {
1488         $decls .= "no $pragma;\n";
1489     }
1490     return $decls;
1491 }
1492
1493 # Internal implementation hints that the core sets automatically, so don't need
1494 # (or want) to be passed back to the user
1495 my %ignored_hints = (
1496     'open<' => 1,
1497     'open>' => 1,
1498     ':'     => 1,
1499 );
1500
1501 sub declare_hinthash {
1502     my ($from, $to, $indent) = @_;
1503     my @decls;
1504     for my $key (keys %$to) {
1505         next if $ignored_hints{$key};
1506         if (!defined $from->{$key} or $from->{$key} ne $to->{$key}) {
1507             push @decls, qq(\$^H{'$key'} = q($to->{$key}););
1508         }
1509     }
1510     for my $key (keys %$from) {
1511         next if $ignored_hints{$key};
1512         if (!exists $to->{$key}) {
1513             push @decls, qq(delete \$^H{'$key'};);
1514         }
1515     }
1516     @decls or return '';
1517     return join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1518 }
1519
1520 sub hint_pragmas {
1521     my ($bits) = @_;
1522     my @pragmas;
1523     push @pragmas, "integer" if $bits & 0x1;
1524     push @pragmas, "strict 'refs'" if $bits & 0x2;
1525     push @pragmas, "bytes" if $bits & 0x8;
1526     return @pragmas;
1527 }
1528
1529 sub pp_dbstate { pp_nextstate(@_) }
1530 sub pp_setstate { pp_nextstate(@_) }
1531
1532 sub pp_unstack { return "" } # see also leaveloop
1533
1534 my %feature_keywords = (
1535   # keyword => 'feature',
1536     state   => 'state',
1537     say     => 'say',
1538     given   => 'switch',
1539     when    => 'switch',
1540     default => 'switch',
1541     break   => 'switch',
1542 );
1543
1544 sub keyword {
1545     my $self = shift;
1546     my $name = shift;
1547     return $name if $name =~ /^CORE::/; # just in case
1548     if (exists $feature_keywords{$name}) {
1549         return
1550           $self->{'hinthash'}
1551            && $self->{'hinthash'}{"feature_$feature_keywords{$name}"}
1552             ? $name
1553             : "CORE::$name";
1554     }
1555     if (
1556       $name !~ /^(?:chom?p|exec|system)\z/
1557        && !defined eval{prototype "CORE::$name"}
1558     ) { return $name }
1559     if (
1560         exists $self->{subs_declared}{$name}
1561          or
1562         exists &{"$self->{curstash}::$name"}
1563     ) {
1564         return "CORE::$name"
1565     }
1566     return $name;
1567 }
1568
1569 sub baseop {
1570     my $self = shift;
1571     my($op, $cx, $name) = @_;
1572     return $self->keyword($name);
1573 }
1574
1575 sub pp_stub {
1576     my $self = shift;
1577     my($op, $cx, $name) = @_;
1578     if ($cx >= 1) {
1579         return "()";
1580     }
1581     else {
1582         return "();";
1583     }
1584 }
1585 sub pp_wantarray { baseop(@_, "wantarray") }
1586 sub pp_fork { baseop(@_, "fork") }
1587 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1588 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1589 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1590 sub pp_tms { baseop(@_, "times") }
1591 sub pp_ghostent { baseop(@_, "gethostent") }
1592 sub pp_gnetent { baseop(@_, "getnetent") }
1593 sub pp_gprotoent { baseop(@_, "getprotoent") }
1594 sub pp_gservent { baseop(@_, "getservent") }
1595 sub pp_ehostent { baseop(@_, "endhostent") }
1596 sub pp_enetent { baseop(@_, "endnetent") }
1597 sub pp_eprotoent { baseop(@_, "endprotoent") }
1598 sub pp_eservent { baseop(@_, "endservent") }
1599 sub pp_gpwent { baseop(@_, "getpwent") }
1600 sub pp_spwent { baseop(@_, "setpwent") }
1601 sub pp_epwent { baseop(@_, "endpwent") }
1602 sub pp_ggrent { baseop(@_, "getgrent") }
1603 sub pp_sgrent { baseop(@_, "setgrent") }
1604 sub pp_egrent { baseop(@_, "endgrent") }
1605 sub pp_getlogin { baseop(@_, "getlogin") }
1606
1607 sub POSTFIX () { 1 }
1608
1609 # I couldn't think of a good short name, but this is the category of
1610 # symbolic unary operators with interesting precedence
1611
1612 sub pfixop {
1613     my $self = shift;
1614     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1615     my $kid = $op->first;
1616     $kid = $self->deparse($kid, $prec);
1617     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1618                                $cx, $prec);
1619 }
1620
1621 sub pp_preinc { pfixop(@_, "++", 23) }
1622 sub pp_predec { pfixop(@_, "--", 23) }
1623 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1624 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1625 sub pp_i_preinc { pfixop(@_, "++", 23) }
1626 sub pp_i_predec { pfixop(@_, "--", 23) }
1627 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1628 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1629 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1630
1631 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1632 sub real_negate {
1633     my $self = shift;
1634     my($op, $cx) = @_;
1635     if ($op->first->name =~ /^(i_)?negate$/) {
1636         # avoid --$x
1637         $self->pfixop($op, $cx, "-", 21.5);
1638     } else {
1639         $self->pfixop($op, $cx, "-", 21);
1640     }
1641 }
1642 sub pp_i_negate { pp_negate(@_) }
1643
1644 sub pp_not {
1645     my $self = shift;
1646     my($op, $cx) = @_;
1647     if ($cx <= 4) {
1648         $self->pfixop($op, $cx, $self->keyword("not")." ", 4);
1649     } else {
1650         $self->pfixop($op, $cx, "!", 21);
1651     }
1652 }
1653
1654 sub unop {
1655     my $self = shift;
1656     my($op, $cx, $name) = @_;
1657     my $kid;
1658     if ($op->flags & OPf_KIDS) {
1659         $kid = $op->first;
1660         if (not $name) {
1661             # this deals with 'boolkeys' right now
1662             return $self->deparse($kid,$cx);
1663         }
1664         my $builtinname = $name;
1665         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1666         if (defined prototype($builtinname)
1667            && prototype($builtinname) =~ /^;?\*/
1668            && $kid->name eq "rv2gv") {
1669             $kid = $kid->first;
1670         }
1671
1672         return $self->maybe_parens_unop($name, $kid, $cx);
1673     } else {
1674         return $self->keyword($name)
1675           . ($op->flags & OPf_SPECIAL ? "()" : "");
1676     }
1677 }
1678
1679 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1680 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1681 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1682 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1683 sub pp_defined { unop(@_, "defined") }
1684 sub pp_undef { unop(@_, "undef") }
1685 sub pp_study { unop(@_, "study") }
1686 sub pp_ref { unop(@_, "ref") }
1687 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1688
1689 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1690 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1691 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1692 sub pp_srand { unop(@_, "srand") }
1693 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1694 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1695 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1696 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1697 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1698 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1699 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1700
1701 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1702 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1703 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1704
1705 sub pp_each { unop(@_, "each") }
1706 sub pp_values { unop(@_, "values") }
1707 sub pp_keys { unop(@_, "keys") }
1708 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
1709 sub pp_boolkeys {
1710     # no name because its an optimisation op that has no keyword
1711     unop(@_,"");
1712 }
1713 sub pp_aeach { unop(@_, "each") }
1714 sub pp_avalues { unop(@_, "values") }
1715 sub pp_akeys { unop(@_, "keys") }
1716 sub pp_pop { unop(@_, "pop") }
1717 sub pp_shift { unop(@_, "shift") }
1718
1719 sub pp_caller { unop(@_, "caller") }
1720 sub pp_reset { unop(@_, "reset") }
1721 sub pp_exit { unop(@_, "exit") }
1722 sub pp_prototype { unop(@_, "prototype") }
1723
1724 sub pp_close { unop(@_, "close") }
1725 sub pp_fileno { unop(@_, "fileno") }
1726 sub pp_umask { unop(@_, "umask") }
1727 sub pp_untie { unop(@_, "untie") }
1728 sub pp_tied { unop(@_, "tied") }
1729 sub pp_dbmclose { unop(@_, "dbmclose") }
1730 sub pp_getc { unop(@_, "getc") }
1731 sub pp_eof { unop(@_, "eof") }
1732 sub pp_tell { unop(@_, "tell") }
1733 sub pp_getsockname { unop(@_, "getsockname") }
1734 sub pp_getpeername { unop(@_, "getpeername") }
1735
1736 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1737 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1738 sub pp_readlink { unop(@_, "readlink") }
1739 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1740 sub pp_readdir { unop(@_, "readdir") }
1741 sub pp_telldir { unop(@_, "telldir") }
1742 sub pp_rewinddir { unop(@_, "rewinddir") }
1743 sub pp_closedir { unop(@_, "closedir") }
1744 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1745 sub pp_localtime { unop(@_, "localtime") }
1746 sub pp_gmtime { unop(@_, "gmtime") }
1747 sub pp_alarm { unop(@_, "alarm") }
1748 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1749
1750 sub pp_dofile { unop(@_, "do") }
1751 sub pp_entereval { unop(@_, "eval") }
1752
1753 sub pp_ghbyname { unop(@_, "gethostbyname") }
1754 sub pp_gnbyname { unop(@_, "getnetbyname") }
1755 sub pp_gpbyname { unop(@_, "getprotobyname") }
1756 sub pp_shostent { unop(@_, "sethostent") }
1757 sub pp_snetent { unop(@_, "setnetent") }
1758 sub pp_sprotoent { unop(@_, "setprotoent") }
1759 sub pp_sservent { unop(@_, "setservent") }
1760 sub pp_gpwnam { unop(@_, "getpwnam") }
1761 sub pp_gpwuid { unop(@_, "getpwuid") }
1762 sub pp_ggrnam { unop(@_, "getgrnam") }
1763 sub pp_ggrgid { unop(@_, "getgrgid") }
1764
1765 sub pp_lock { unop(@_, "lock") }
1766
1767 sub pp_continue { unop(@_, "continue"); }
1768 sub pp_break { unop(@_, "break"); }
1769
1770 sub givwhen {
1771     my $self = shift;
1772     my($op, $cx, $givwhen) = @_;
1773
1774     my $enterop = $op->first;
1775     my ($head, $block);
1776     if ($enterop->flags & OPf_SPECIAL) {
1777         $head = $self->keyword("default");
1778         $block = $self->deparse($enterop->first, 0);
1779     }
1780     else {
1781         my $cond = $enterop->first;
1782         my $cond_str = $self->deparse($cond, 1);
1783         $head = "$givwhen ($cond_str)";
1784         $block = $self->deparse($cond->sibling, 0);
1785     }
1786
1787     return "$head {\n".
1788         "\t$block\n".
1789         "\b}\cK";
1790 }
1791
1792 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
1793 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
1794
1795 sub pp_exists {
1796     my $self = shift;
1797     my($op, $cx) = @_;
1798     my $arg;
1799     if ($op->private & OPpEXISTS_SUB) {
1800         # Checking for the existence of a subroutine
1801         return $self->maybe_parens_func("exists",
1802                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1803     }
1804     if ($op->flags & OPf_SPECIAL) {
1805         # Array element, not hash element
1806         return $self->maybe_parens_func("exists",
1807                                 $self->pp_aelem($op->first, 16), $cx, 16);
1808     }
1809     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1810                                     $cx, 16);
1811 }
1812
1813 sub pp_delete {
1814     my $self = shift;
1815     my($op, $cx) = @_;
1816     my $arg;
1817     if ($op->private & OPpSLICE) {
1818         if ($op->flags & OPf_SPECIAL) {
1819             # Deleting from an array, not a hash
1820             return $self->maybe_parens_func("delete",
1821                                         $self->pp_aslice($op->first, 16),
1822                                         $cx, 16);
1823         }
1824         return $self->maybe_parens_func("delete",
1825                                         $self->pp_hslice($op->first, 16),
1826                                         $cx, 16);
1827     } else {
1828         if ($op->flags & OPf_SPECIAL) {
1829             # Deleting from an array, not a hash
1830             return $self->maybe_parens_func("delete",
1831                                         $self->pp_aelem($op->first, 16),
1832                                         $cx, 16);
1833         }
1834         return $self->maybe_parens_func("delete",
1835                                         $self->pp_helem($op->first, 16),
1836                                         $cx, 16);
1837     }
1838 }
1839
1840 sub pp_require {
1841     my $self = shift;
1842     my($op, $cx) = @_;
1843     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1844     if (class($op) eq "UNOP" and $op->first->name eq "const"
1845         and $op->first->private & OPpCONST_BARE)
1846     {
1847         my $name = $self->const_sv($op->first)->PV;
1848         $name =~ s[/][::]g;
1849         $name =~ s/\.pm//g;
1850         return "$opname $name";
1851     } else {
1852         $self->unop($op, $cx, $op->first->private & OPpCONST_NOVER ? "no" : $opname);
1853     }
1854 }
1855
1856 sub pp_scalar {
1857     my $self = shift;
1858     my($op, $cx) = @_;
1859     my $kid = $op->first;
1860     if (not null $kid->sibling) {
1861         # XXX Was a here-doc
1862         return $self->dquote($op);
1863     }
1864     $self->unop(@_, "scalar");
1865 }
1866
1867
1868 sub padval {
1869     my $self = shift;
1870     my $targ = shift;
1871     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1872 }
1873
1874 sub anon_hash_or_list {
1875     my $self = shift;
1876     my($op, $cx) = @_;
1877
1878     my($pre, $post) = @{{"anonlist" => ["[","]"],
1879                          "anonhash" => ["{","}"]}->{$op->name}};
1880     my($expr, @exprs);
1881     $op = $op->first->sibling; # skip pushmark
1882     for (; !null($op); $op = $op->sibling) {
1883         $expr = $self->deparse($op, 6);
1884         push @exprs, $expr;
1885     }
1886     if ($pre eq "{" and $cx < 1) {
1887         # Disambiguate that it's not a block
1888         $pre = "+{";
1889     }
1890     return $pre . join(", ", @exprs) . $post;
1891 }
1892
1893 sub pp_anonlist {
1894     my $self = shift;
1895     my ($op, $cx) = @_;
1896     if ($op->flags & OPf_SPECIAL) {
1897         return $self->anon_hash_or_list($op, $cx);
1898     }
1899     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
1900     return 'XXX';
1901 }
1902
1903 *pp_anonhash = \&pp_anonlist;
1904
1905 sub pp_refgen {
1906     my $self = shift;
1907     my($op, $cx) = @_;
1908     my $kid = $op->first;
1909     if ($kid->name eq "null") {
1910         $kid = $kid->first;
1911         if (!null($kid->sibling) and
1912                  $kid->sibling->name eq "anoncode") {
1913             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
1914         } elsif ($kid->name eq "pushmark") {
1915             my $sib_name = $kid->sibling->name;
1916             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1917                 and not $kid->sibling->flags & OPf_REF)
1918             {
1919                 # The @a in \(@a) isn't in ref context, but only when the
1920                 # parens are there.
1921                 return "\\(" . $self->pp_list($op->first) . ")";
1922             } elsif ($sib_name eq 'entersub') {
1923                 my $text = $self->deparse($kid->sibling, 1);
1924                 # Always show parens for \(&func()), but only with -p otherwise
1925                 $text = "($text)" if $self->{'parens'}
1926                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1927                 return "\\$text";
1928             }
1929         }
1930     }
1931     $self->pfixop($op, $cx, "\\", 20);
1932 }
1933
1934 sub e_anoncode {
1935     my ($self, $info) = @_;
1936     my $text = $self->deparse_sub($info->{code});
1937     return "sub " . $text;
1938 }
1939
1940 sub pp_srefgen { pp_refgen(@_) }
1941
1942 sub pp_readline {
1943     my $self = shift;
1944     my($op, $cx) = @_;
1945     my $kid = $op->first;
1946     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1947     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1948     return $self->unop($op, $cx, "readline");
1949 }
1950
1951 sub pp_rcatline {
1952     my $self = shift;
1953     my($op) = @_;
1954     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1955 }
1956
1957 # Unary operators that can occur as pseudo-listops inside double quotes
1958 sub dq_unop {
1959     my $self = shift;
1960     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1961     my $kid;
1962     if ($op->flags & OPf_KIDS) {
1963        $kid = $op->first;
1964        # If there's more than one kid, the first is an ex-pushmark.
1965        $kid = $kid->sibling if not null $kid->sibling;
1966        return $self->maybe_parens_unop($name, $kid, $cx);
1967     } else {
1968        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1969     }
1970 }
1971
1972 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1973 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1974 sub pp_uc { dq_unop(@_, "uc") }
1975 sub pp_lc { dq_unop(@_, "lc") }
1976 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1977
1978 sub loopex {
1979     my $self = shift;
1980     my ($op, $cx, $name) = @_;
1981     if (class($op) eq "PVOP") {
1982         return "$name " . $op->pv;
1983     } elsif (class($op) eq "OP") {
1984         return $name;
1985     } elsif (class($op) eq "UNOP") {
1986         # Note -- loop exits are actually exempt from the
1987         # looks-like-a-func rule, but a few extra parens won't hurt
1988         return $self->maybe_parens_unop($name, $op->first, $cx);
1989     }
1990 }
1991
1992 sub pp_last { loopex(@_, "last") }
1993 sub pp_next { loopex(@_, "next") }
1994 sub pp_redo { loopex(@_, "redo") }
1995 sub pp_goto { loopex(@_, "goto") }
1996 sub pp_dump { loopex(@_, $_[0]->keyword("dump")) }
1997
1998 sub ftst {
1999     my $self = shift;
2000     my($op, $cx, $name) = @_;
2001     if (class($op) eq "UNOP") {
2002         # Genuine `-X' filetests are exempt from the LLAFR, but not
2003         # l?stat(); for the sake of clarity, give'em all parens
2004         return $self->maybe_parens_unop($name, $op->first, $cx);
2005     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2006         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2007     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2008         return $name;
2009     }
2010 }
2011
2012 sub pp_lstat    { ftst(@_, "lstat") }
2013 sub pp_stat     { ftst(@_, "stat") }
2014 sub pp_ftrread  { ftst(@_, "-R") }
2015 sub pp_ftrwrite { ftst(@_, "-W") }
2016 sub pp_ftrexec  { ftst(@_, "-X") }
2017 sub pp_fteread  { ftst(@_, "-r") }
2018 sub pp_ftewrite { ftst(@_, "-w") }
2019 sub pp_fteexec  { ftst(@_, "-x") }
2020 sub pp_ftis     { ftst(@_, "-e") }
2021 sub pp_fteowned { ftst(@_, "-O") }
2022 sub pp_ftrowned { ftst(@_, "-o") }
2023 sub pp_ftzero   { ftst(@_, "-z") }
2024 sub pp_ftsize   { ftst(@_, "-s") }
2025 sub pp_ftmtime  { ftst(@_, "-M") }
2026 sub pp_ftatime  { ftst(@_, "-A") }
2027 sub pp_ftctime  { ftst(@_, "-C") }
2028 sub pp_ftsock   { ftst(@_, "-S") }
2029 sub pp_ftchr    { ftst(@_, "-c") }
2030 sub pp_ftblk    { ftst(@_, "-b") }
2031 sub pp_ftfile   { ftst(@_, "-f") }
2032 sub pp_ftdir    { ftst(@_, "-d") }
2033 sub pp_ftpipe   { ftst(@_, "-p") }
2034 sub pp_ftlink   { ftst(@_, "-l") }
2035 sub pp_ftsuid   { ftst(@_, "-u") }
2036 sub pp_ftsgid   { ftst(@_, "-g") }
2037 sub pp_ftsvtx   { ftst(@_, "-k") }
2038 sub pp_fttty    { ftst(@_, "-t") }
2039 sub pp_fttext   { ftst(@_, "-T") }
2040 sub pp_ftbinary { ftst(@_, "-B") }
2041
2042 sub SWAP_CHILDREN () { 1 }
2043 sub ASSIGN () { 2 } # has OP= variant
2044 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2045
2046 my(%left, %right);
2047
2048 sub assoc_class {
2049     my $op = shift;
2050     my $name = $op->name;
2051     if ($name eq "concat" and $op->first->name eq "concat") {
2052         # avoid spurious `=' -- see comment in pp_concat
2053         return "concat";
2054     }
2055     if ($name eq "null" and class($op) eq "UNOP"
2056         and $op->first->name =~ /^(and|x?or)$/
2057         and null $op->first->sibling)
2058     {
2059         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2060         # with a null that's used as the common end point of the two
2061         # flows of control. For precedence purposes, ignore it.
2062         # (COND_EXPRs have these too, but we don't bother with
2063         # their associativity).
2064         return assoc_class($op->first);
2065     }
2066     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2067 }
2068
2069 # Left associative operators, like `+', for which
2070 # $a + $b + $c is equivalent to ($a + $b) + $c
2071
2072 BEGIN {
2073     %left = ('multiply' => 19, 'i_multiply' => 19,
2074              'divide' => 19, 'i_divide' => 19,
2075              'modulo' => 19, 'i_modulo' => 19,
2076              'repeat' => 19,
2077              'add' => 18, 'i_add' => 18,
2078              'subtract' => 18, 'i_subtract' => 18,
2079              'concat' => 18,
2080              'left_shift' => 17, 'right_shift' => 17,
2081              'bit_and' => 13,
2082              'bit_or' => 12, 'bit_xor' => 12,
2083              'and' => 3,
2084              'or' => 2, 'xor' => 2,
2085             );
2086 }
2087
2088 sub deparse_binop_left {
2089     my $self = shift;
2090     my($op, $left, $prec) = @_;
2091     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2092         and $left{assoc_class($op)} == $left{assoc_class($left)})
2093     {
2094         return $self->deparse($left, $prec - .00001);
2095     } else {
2096         return $self->deparse($left, $prec);
2097     }
2098 }
2099
2100 # Right associative operators, like `=', for which
2101 # $a = $b = $c is equivalent to $a = ($b = $c)
2102
2103 BEGIN {
2104     %right = ('pow' => 22,
2105               'sassign=' => 7, 'aassign=' => 7,
2106               'multiply=' => 7, 'i_multiply=' => 7,
2107               'divide=' => 7, 'i_divide=' => 7,
2108               'modulo=' => 7, 'i_modulo=' => 7,
2109               'repeat=' => 7,
2110               'add=' => 7, 'i_add=' => 7,
2111               'subtract=' => 7, 'i_subtract=' => 7,
2112               'concat=' => 7,
2113               'left_shift=' => 7, 'right_shift=' => 7,
2114               'bit_and=' => 7,
2115               'bit_or=' => 7, 'bit_xor=' => 7,
2116               'andassign' => 7,
2117               'orassign' => 7,
2118              );
2119 }
2120
2121 sub deparse_binop_right {
2122     my $self = shift;
2123     my($op, $right, $prec) = @_;
2124     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2125         and $right{assoc_class($op)} == $right{assoc_class($right)})
2126     {
2127         return $self->deparse($right, $prec - .00001);
2128     } else {
2129         return $self->deparse($right, $prec);
2130     }
2131 }
2132
2133 sub binop {
2134     my $self = shift;
2135     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2136     my $left = $op->first;
2137     my $right = $op->last;
2138     my $eq = "";
2139     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2140         $eq = "=";
2141         $prec = 7;
2142     }
2143     if ($flags & SWAP_CHILDREN) {
2144         ($left, $right) = ($right, $left);
2145     }
2146     $left = $self->deparse_binop_left($op, $left, $prec);
2147     $left = "($left)" if $flags & LIST_CONTEXT
2148                 && $left !~ /^(my|our|local|)[\@\(]/;
2149     $right = $self->deparse_binop_right($op, $right, $prec);
2150     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2151 }
2152
2153 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2154 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2155 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2156 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2157 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2158 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2159 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2160 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2161 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2162 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2163 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2164
2165 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2166 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2167 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2168 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2169 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2170
2171 sub pp_eq { binop(@_, "==", 14) }
2172 sub pp_ne { binop(@_, "!=", 14) }
2173 sub pp_lt { binop(@_, "<", 15) }
2174 sub pp_gt { binop(@_, ">", 15) }
2175 sub pp_ge { binop(@_, ">=", 15) }
2176 sub pp_le { binop(@_, "<=", 15) }
2177 sub pp_ncmp { binop(@_, "<=>", 14) }
2178 sub pp_i_eq { binop(@_, "==", 14) }
2179 sub pp_i_ne { binop(@_, "!=", 14) }
2180 sub pp_i_lt { binop(@_, "<", 15) }
2181 sub pp_i_gt { binop(@_, ">", 15) }
2182 sub pp_i_ge { binop(@_, ">=", 15) }
2183 sub pp_i_le { binop(@_, "<=", 15) }
2184 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2185
2186 sub pp_seq { binop(@_, "eq", 14) }
2187 sub pp_sne { binop(@_, "ne", 14) }
2188 sub pp_slt { binop(@_, "lt", 15) }
2189 sub pp_sgt { binop(@_, "gt", 15) }
2190 sub pp_sge { binop(@_, "ge", 15) }
2191 sub pp_sle { binop(@_, "le", 15) }
2192 sub pp_scmp { binop(@_, "cmp", 14) }
2193
2194 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2195 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2196
2197 sub pp_smartmatch {
2198     my ($self, $op, $cx) = @_;
2199     if ($op->flags & OPf_SPECIAL) {
2200         return $self->deparse($op->last, $cx);
2201     }
2202     else {
2203         binop(@_, "~~", 14);
2204     }
2205 }
2206
2207 # `.' is special because concats-of-concats are optimized to save copying
2208 # by making all but the first concat stacked. The effect is as if the
2209 # programmer had written `($a . $b) .= $c', except legal.
2210 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2211 sub real_concat {
2212     my $self = shift;
2213     my($op, $cx) = @_;
2214     my $left = $op->first;
2215     my $right = $op->last;
2216     my $eq = "";
2217     my $prec = 18;
2218     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2219         $eq = "=";
2220         $prec = 7;
2221     }
2222     $left = $self->deparse_binop_left($op, $left, $prec);
2223     $right = $self->deparse_binop_right($op, $right, $prec);
2224     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2225 }
2226
2227 # `x' is weird when the left arg is a list
2228 sub pp_repeat {
2229     my $self = shift;
2230     my($op, $cx) = @_;
2231     my $left = $op->first;
2232     my $right = $op->last;
2233     my $eq = "";
2234     my $prec = 19;
2235     if ($op->flags & OPf_STACKED) {
2236         $eq = "=";
2237         $prec = 7;
2238     }
2239     if (null($right)) { # list repeat; count is inside left-side ex-list
2240         my $kid = $left->first->sibling; # skip pushmark
2241         my @exprs;
2242         for (; !null($kid->sibling); $kid = $kid->sibling) {
2243             push @exprs, $self->deparse($kid, 6);
2244         }
2245         $right = $kid;
2246         $left = "(" . join(", ", @exprs). ")";
2247     } else {
2248         $left = $self->deparse_binop_left($op, $left, $prec);
2249     }
2250     $right = $self->deparse_binop_right($op, $right, $prec);
2251     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2252 }
2253
2254 sub range {
2255     my $self = shift;
2256     my ($op, $cx, $type) = @_;
2257     my $left = $op->first;
2258     my $right = $left->sibling;
2259     $left = $self->deparse($left, 9);
2260     $right = $self->deparse($right, 9);
2261     return $self->maybe_parens("$left $type $right", $cx, 9);
2262 }
2263
2264 sub pp_flop {
2265     my $self = shift;
2266     my($op, $cx) = @_;
2267     my $flip = $op->first;
2268     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2269     return $self->range($flip->first, $cx, $type);
2270 }
2271
2272 # one-line while/until is handled in pp_leave
2273
2274 sub logop {
2275     my $self = shift;
2276     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2277     my $left = $op->first;
2278     my $right = $op->first->sibling;
2279     if ($cx < 1 and is_scope($right) and $blockname
2280         and $self->{'expand'} < 7)
2281     { # if ($a) {$b}
2282         $left = $self->deparse($left, 1);
2283         $right = $self->deparse($right, 0);
2284         return "$blockname ($left) {\n\t$right\n\b}\cK";
2285     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2286              and $self->{'expand'} < 7) { # $b if $a
2287         $right = $self->deparse($right, 1);
2288         $left = $self->deparse($left, 1);
2289         return "$right $blockname $left";
2290     } elsif ($cx > $lowprec and $highop) { # $a && $b
2291         $left = $self->deparse_binop_left($op, $left, $highprec);
2292         $right = $self->deparse_binop_right($op, $right, $highprec);
2293         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2294     } else { # $a and $b
2295         $left = $self->deparse_binop_left($op, $left, $lowprec);
2296         $right = $self->deparse_binop_right($op, $right, $lowprec);
2297         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2298     }
2299 }
2300
2301 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2302 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2303 sub pp_dor { logop(@_, "//", 10) }
2304
2305 # xor is syntactically a logop, but it's really a binop (contrary to
2306 # old versions of opcode.pl). Syntax is what matters here.
2307 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2308
2309 sub logassignop {
2310     my $self = shift;
2311     my ($op, $cx, $opname) = @_;
2312     my $left = $op->first;
2313     my $right = $op->first->sibling->first; # skip sassign
2314     $left = $self->deparse($left, 7);
2315     $right = $self->deparse($right, 7);
2316     return $self->maybe_parens("$left $opname $right", $cx, 7);
2317 }
2318
2319 sub pp_andassign { logassignop(@_, "&&=") }
2320 sub pp_orassign  { logassignop(@_, "||=") }
2321 sub pp_dorassign { logassignop(@_, "//=") }
2322
2323 sub listop {
2324     my $self = shift;
2325     my($op, $cx, $name) = @_;
2326     my(@exprs);
2327     my $parens = ($cx >= 5) || $self->{'parens'};
2328     my $kid = $op->first->sibling;
2329     return $self->keyword($name) if null $kid;
2330     my $first;
2331     $name = "socketpair" if $name eq "sockpair";
2332     my $fullname = $self->keyword($name);
2333     my $proto = prototype("CORE::$name");
2334     if (defined $proto
2335         && $proto =~ /^;?\*/
2336         && $kid->name eq "rv2gv") {
2337         $first = $self->deparse($kid->first, 6);
2338     }
2339     else {
2340         $first = $self->deparse($kid, 6);
2341     }
2342     if ($name eq "chmod" && $first =~ /^\d+$/) {
2343         $first = sprintf("%#o", $first);
2344     }
2345     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2346     push @exprs, $first;
2347     $kid = $kid->sibling;
2348     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2349         push @exprs, $self->deparse($kid->first, 6);
2350         $kid = $kid->sibling;
2351     }
2352     for (; !null($kid); $kid = $kid->sibling) {
2353         push @exprs, $self->deparse($kid, 6);
2354     }
2355     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2356         return "$exprs[0] = $fullname"
2357                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2358     }
2359     if ($parens) {
2360         return "$fullname(" . join(", ", @exprs) . ")";
2361     } else {
2362         return "$fullname " . join(", ", @exprs);
2363     }
2364 }
2365
2366 sub pp_bless { listop(@_, "bless") }
2367 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2368 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2369 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2370 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2371 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2372 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2373 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2374 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2375 sub pp_unpack { listop(@_, "unpack") }
2376 sub pp_pack { listop(@_, "pack") }
2377 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2378 sub pp_splice { listop(@_, "splice") }
2379 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2380 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2381 sub pp_reverse { listop(@_, "reverse") }
2382 sub pp_warn { listop(@_, "warn") }
2383 sub pp_die { listop(@_, "die") }
2384 # Actually, return is exempt from the LLAFR (see examples in this very
2385 # module!), but for consistency's sake, ignore that fact
2386 sub pp_return { listop(@_, "return") }
2387 sub pp_open { listop(@_, "open") }
2388 sub pp_pipe_op { listop(@_, "pipe") }
2389 sub pp_tie { listop(@_, "tie") }
2390 sub pp_binmode { listop(@_, "binmode") }
2391 sub pp_dbmopen { listop(@_, "dbmopen") }
2392 sub pp_sselect { listop(@_, "select") }
2393 sub pp_select { listop(@_, "select") }
2394 sub pp_read { listop(@_, "read") }
2395 sub pp_sysopen { listop(@_, "sysopen") }
2396 sub pp_sysseek { listop(@_, "sysseek") }
2397 sub pp_sysread { listop(@_, "sysread") }
2398 sub pp_syswrite { listop(@_, "syswrite") }
2399 sub pp_send { listop(@_, "send") }
2400 sub pp_recv { listop(@_, "recv") }
2401 sub pp_seek { listop(@_, "seek") }
2402 sub pp_fcntl { listop(@_, "fcntl") }
2403 sub pp_ioctl { listop(@_, "ioctl") }
2404 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2405 sub pp_socket { listop(@_, "socket") }
2406 sub pp_sockpair { listop(@_, "sockpair") }
2407 sub pp_bind { listop(@_, "bind") }
2408 sub pp_connect { listop(@_, "connect") }
2409 sub pp_listen { listop(@_, "listen") }
2410 sub pp_accept { listop(@_, "accept") }
2411 sub pp_shutdown { listop(@_, "shutdown") }
2412 sub pp_gsockopt { listop(@_, "getsockopt") }
2413 sub pp_ssockopt { listop(@_, "setsockopt") }
2414 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2415 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2416 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2417 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2418 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2419 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2420 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2421 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2422 sub pp_open_dir { listop(@_, "opendir") }
2423 sub pp_seekdir { listop(@_, "seekdir") }
2424 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2425 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2426 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2427 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2428 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2429 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2430 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2431 sub pp_shmget { listop(@_, "shmget") }
2432 sub pp_shmctl { listop(@_, "shmctl") }
2433 sub pp_shmread { listop(@_, "shmread") }
2434 sub pp_shmwrite { listop(@_, "shmwrite") }
2435 sub pp_msgget { listop(@_, "msgget") }
2436 sub pp_msgctl { listop(@_, "msgctl") }
2437 sub pp_msgsnd { listop(@_, "msgsnd") }
2438 sub pp_msgrcv { listop(@_, "msgrcv") }
2439 sub pp_semget { listop(@_, "semget") }
2440 sub pp_semctl { listop(@_, "semctl") }
2441 sub pp_semop { listop(@_, "semop") }
2442 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2443 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2444 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2445 sub pp_gsbyname { listop(@_, "getservbyname") }
2446 sub pp_gsbyport { listop(@_, "getservbyport") }
2447 sub pp_syscall { listop(@_, "syscall") }
2448
2449 sub pp_glob {
2450     my $self = shift;
2451     my($op, $cx) = @_;
2452     my $text = $self->dq($op->first->sibling);  # skip pushmark
2453     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2454         or $text =~ /[<>]/) {
2455         return 'glob(' . single_delim('qq', '"', $text) . ')';
2456     } else {
2457         return '<' . $text . '>';
2458     }
2459 }
2460
2461 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2462 # be a filehandle. This could probably be better fixed in the core
2463 # by moving the GV lookup into ck_truc.
2464
2465 sub pp_truncate {
2466     my $self = shift;
2467     my($op, $cx) = @_;
2468     my(@exprs);
2469     my $parens = ($cx >= 5) || $self->{'parens'};
2470     my $kid = $op->first->sibling;
2471     my $fh;
2472     if ($op->flags & OPf_SPECIAL) {
2473         # $kid is an OP_CONST
2474         $fh = $self->const_sv($kid)->PV;
2475     } else {
2476         $fh = $self->deparse($kid, 6);
2477         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2478     }
2479     my $len = $self->deparse($kid->sibling, 6);
2480     my $name = $self->keyword('truncate');
2481     if ($parens) {
2482         return "$name($fh, $len)";
2483     } else {
2484         return "$name $fh, $len";
2485     }
2486 }
2487
2488 sub indirop {
2489     my $self = shift;
2490     my($op, $cx, $name) = @_;
2491     my($expr, @exprs);
2492     my $kid = $op->first->sibling;
2493     my $indir = "";
2494     if ($op->flags & OPf_STACKED) {
2495         $indir = $kid;
2496         $indir = $indir->first; # skip rv2gv
2497         if (is_scope($indir)) {
2498             $indir = "{" . $self->deparse($indir, 0) . "}";
2499             $indir = "{;}" if $indir eq "{}";
2500         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2501             $indir = $self->const_sv($indir)->PV;
2502         } else {
2503             $indir = $self->deparse($indir, 24);
2504         }
2505         $indir = $indir . " ";
2506         $kid = $kid->sibling;
2507     }
2508     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2509         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2510                                                   : '{$a <=> $b} ';
2511     }
2512     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2513         $indir = '{$b cmp $a} ';
2514     }
2515     for (; !null($kid); $kid = $kid->sibling) {
2516         $expr = $self->deparse($kid, 6);
2517         push @exprs, $expr;
2518     }
2519     my $name2;
2520     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2521         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2522     }
2523     else { $name2 = $self->keyword($name) }
2524     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2525         return "$exprs[0] = $name2 $indir $exprs[0]";
2526     }
2527
2528     my $args = $indir . join(", ", @exprs);
2529     if ($indir ne "" and $name eq "sort") {
2530         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2531         # give bareword warnings in that case. Therefore if context
2532         # requires, we'll put parens around the outside "(sort f 1, 2,
2533         # 3)". Unfortunately, we'll currently think the parens are
2534         # necessary more often that they really are, because we don't
2535         # distinguish which side of an assignment we're on.
2536         if ($cx >= 5) {
2537             return "($name2 $args)";
2538         } else {
2539             return "$name2 $args";
2540         }
2541     } else {
2542         return $self->maybe_parens_func($name2, $args, $cx, 5);
2543     }
2544
2545 }
2546
2547 sub pp_prtf { indirop(@_, "printf") }
2548 sub pp_print { indirop(@_, "print") }
2549 sub pp_say  { indirop(@_, "say") }
2550 sub pp_sort { indirop(@_, "sort") }
2551
2552 sub mapop {
2553     my $self = shift;
2554     my($op, $cx, $name) = @_;
2555     my($expr, @exprs);
2556     my $kid = $op->first; # this is the (map|grep)start
2557     $kid = $kid->first->sibling; # skip a pushmark
2558     my $code = $kid->first; # skip a null
2559     if (is_scope $code) {
2560         $code = "{" . $self->deparse($code, 0) . "} ";
2561     } else {
2562         $code = $self->deparse($code, 24) . ", ";
2563     }
2564     $kid = $kid->sibling;
2565     for (; !null($kid); $kid = $kid->sibling) {
2566         $expr = $self->deparse($kid, 6);
2567         push @exprs, $expr if defined $expr;
2568     }
2569     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2570 }
2571
2572 sub pp_mapwhile { mapop(@_, "map") }
2573 sub pp_grepwhile { mapop(@_, "grep") }
2574 sub pp_mapstart { baseop(@_, "map") }
2575 sub pp_grepstart { baseop(@_, "grep") }
2576
2577 sub pp_list {
2578     my $self = shift;
2579     my($op, $cx) = @_;
2580     my($expr, @exprs);
2581     my $kid = $op->first->sibling; # skip pushmark
2582     my $lop;
2583     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2584     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2585         # This assumes that no other private flags equal 128, and that
2586         # OPs that store things other than flags in their op_private,
2587         # like OP_AELEMFAST, won't be immediate children of a list.
2588         #
2589         # OP_ENTERSUB can break this logic, so check for it.
2590         # I suspect that open and exit can too.
2591
2592         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2593                 or $lop->name eq "undef")
2594             or $lop->name eq "entersub"
2595             or $lop->name eq "exit"
2596             or $lop->name eq "open")
2597         {
2598             $local = ""; # or not
2599             last;
2600         }
2601         if ($lop->name =~ /^pad[ash]v$/) {
2602             if ($lop->private & OPpPAD_STATE) { # state()
2603                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2604                 $local = "state";
2605             } else { # my()
2606                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2607                 $local = "my";
2608             }
2609         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2610                         && $lop->private & OPpOUR_INTRO
2611                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2612                         && $lop->first->private & OPpOUR_INTRO) { # our()
2613             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2614             $local = "our";
2615         } elsif ($lop->name ne "undef"
2616                 # specifically avoid the "reverse sort" optimisation,
2617                 # where "reverse" is nullified
2618                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2619         {
2620             # local()
2621             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2622             $local = "local";
2623         }
2624     }
2625     $local = "" if $local eq "either"; # no point if it's all undefs
2626     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2627     for (; !null($kid); $kid = $kid->sibling) {
2628         if ($local) {
2629             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2630                 $lop = $kid->first;
2631             } else {
2632                 $lop = $kid;
2633             }
2634             $self->{'avoid_local'}{$$lop}++;
2635             $expr = $self->deparse($kid, 6);
2636             delete $self->{'avoid_local'}{$$lop};
2637         } else {
2638             $expr = $self->deparse($kid, 6);
2639         }
2640         push @exprs, $expr;
2641     }
2642     if ($local) {
2643         return "$local(" . join(", ", @exprs) . ")";
2644     } else {
2645         return $self->maybe_parens( join(", ", @exprs), $cx, 6);
2646     }
2647 }
2648
2649 sub is_ifelse_cont {
2650     my $op = shift;
2651     return ($op->name eq "null" and class($op) eq "UNOP"
2652             and $op->first->name =~ /^(and|cond_expr)$/
2653             and is_scope($op->first->first->sibling));
2654 }
2655
2656 sub pp_cond_expr {
2657     my $self = shift;
2658     my($op, $cx) = @_;
2659     my $cond = $op->first;
2660     my $true = $cond->sibling;
2661     my $false = $true->sibling;
2662     my $cuddle = $self->{'cuddle'};
2663     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2664             (is_scope($false) || is_ifelse_cont($false))
2665             and $self->{'expand'} < 7) {
2666         $cond = $self->deparse($cond, 8);
2667         $true = $self->deparse($true, 6);
2668         $false = $self->deparse($false, 8);
2669         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2670     }
2671
2672     $cond = $self->deparse($cond, 1);
2673     $true = $self->deparse($true, 0);
2674     my $head = "if ($cond) {\n\t$true\n\b}";
2675     my @elsifs;
2676     while (!null($false) and is_ifelse_cont($false)) {
2677         my $newop = $false->first;
2678         my $newcond = $newop->first;
2679         my $newtrue = $newcond->sibling;
2680         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2681         if ($newcond->name eq "lineseq")
2682         {
2683             # lineseq to ensure correct line numbers in elsif()
2684             # Bug #37302 fixed by change #33710.
2685             $newcond = $newcond->first->sibling;
2686         }
2687         $newcond = $self->deparse($newcond, 1);
2688         $newtrue = $self->deparse($newtrue, 0);
2689         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2690     }
2691     if (!null($false)) {
2692         $false = $cuddle . "else {\n\t" .
2693           $self->deparse($false, 0) . "\n\b}\cK";
2694     } else {
2695         $false = "\cK";
2696     }
2697     return $head . join($cuddle, "", @elsifs) . $false;
2698 }
2699
2700 sub pp_once {
2701     my ($self, $op, $cx) = @_;
2702     my $cond = $op->first;
2703     my $true = $cond->sibling;
2704
2705     return $self->deparse($true, $cx);
2706 }
2707
2708 sub loop_common {
2709     my $self = shift;
2710     my($op, $cx, $init) = @_;
2711     my $enter = $op->first;
2712     my $kid = $enter->sibling;
2713     local(@$self{qw'curstash warnings hints hinthash'})
2714                 = @$self{qw'curstash warnings hints hinthash'};
2715     my $head = "";
2716     my $bare = 0;
2717     my $body;
2718     my $cond = undef;
2719     if ($kid->name eq "lineseq") { # bare or infinite loop
2720         if ($kid->last->name eq "unstack") { # infinite
2721             $head = "while (1) "; # Can't use for(;;) if there's a continue
2722             $cond = "";
2723         } else {
2724             $bare = 1;
2725         }
2726         $body = $kid;
2727     } elsif ($enter->name eq "enteriter") { # foreach
2728         my $ary = $enter->first->sibling; # first was pushmark
2729         my $var = $ary->sibling;
2730         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2731             # "reverse" was optimised away
2732             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2733         } elsif ($enter->flags & OPf_STACKED
2734             and not null $ary->first->sibling->sibling)
2735         {
2736             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2737               $self->deparse($ary->first->sibling->sibling, 9);
2738         } else {
2739             $ary = $self->deparse($ary, 1);
2740         }
2741         if (null $var) {
2742             if (($enter->flags & OPf_SPECIAL) && ($] < 5.009)) {
2743                 # thread special var, under 5005threads
2744                 $var = $self->pp_threadsv($enter, 1);
2745             } else { # regular my() variable
2746                 $var = $self->pp_padsv($enter, 1);
2747             }
2748         } elsif ($var->name eq "rv2gv") {
2749             $var = $self->pp_rv2sv($var, 1);
2750             if ($enter->private & OPpOUR_INTRO) {
2751                 # our declarations don't have package names
2752                 $var =~ s/^(.).*::/$1/;
2753                 $var = "our $var";
2754             }
2755         } elsif ($var->name eq "gv") {
2756             $var = "\$" . $self->deparse($var, 1);
2757         }
2758         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2759         if (!is_state $body->first and $body->first->name ne "stub") {
2760             confess unless $var eq '$_';
2761             $body = $body->first;
2762             return $self->deparse($body, 2) . " foreach ($ary)";
2763         }
2764         $head = "foreach $var ($ary) ";
2765     } elsif ($kid->name eq "null") { # while/until
2766         $kid = $kid->first;
2767         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2768         $cond = $self->deparse($kid->first, 1);
2769         $head = "$name ($cond) ";
2770         $body = $kid->first->sibling;
2771     } elsif ($kid->name eq "stub") { # bare and empty
2772         return "{;}"; # {} could be a hashref
2773     }
2774     # If there isn't a continue block, then the next pointer for the loop
2775     # will point to the unstack, which is kid's last child, except
2776     # in a bare loop, when it will point to the leaveloop. When neither of
2777     # these conditions hold, then the second-to-last child is the continue
2778     # block (or the last in a bare loop).
2779     my $cont_start = $enter->nextop;
2780     my $cont;
2781     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2782         if ($bare) {
2783             $cont = $body->last;
2784         } else {
2785             $cont = $body->first;
2786             while (!null($cont->sibling->sibling)) {
2787                 $cont = $cont->sibling;
2788             }
2789         }
2790         my $state = $body->first;
2791         my $cuddle = $self->{'cuddle'};
2792         my @states;
2793         for (; $$state != $$cont; $state = $state->sibling) {
2794             push @states, $state;
2795         }
2796         $body = $self->lineseq(undef, @states);
2797         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2798             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2799             $cont = "\cK";
2800         } else {
2801             $cont = $cuddle . "continue {\n\t" .
2802               $self->deparse($cont, 0) . "\n\b}\cK";
2803         }
2804     } else {
2805         return "" if !defined $body;
2806         if (length $init) {
2807             $head = "for ($init; $cond;) ";
2808         }
2809         $cont = "\cK";
2810         $body = $self->deparse($body, 0);
2811     }
2812     $body =~ s/;?$/;\n/;
2813
2814     return $head . "{\n\t" . $body . "\b}" . $cont;
2815 }
2816
2817 sub pp_leaveloop { shift->loop_common(@_, "") }
2818
2819 sub for_loop {
2820     my $self = shift;
2821     my($op, $cx) = @_;
2822     my $init = $self->deparse($op, 1);
2823     my $s = $op->sibling;
2824     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
2825     return $self->loop_common($ll, $cx, $init);
2826 }
2827
2828 sub pp_leavetry {
2829     my $self = shift;
2830     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2831 }
2832
2833 BEGIN { for (qw[ const stringify rv2sv list glob ]) {
2834     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
2835 }}
2836
2837 sub pp_null {
2838     my $self = shift;
2839     my($op, $cx) = @_;
2840     if (class($op) eq "OP") {
2841         # old value is lost
2842         return $self->{'ex_const'} if $op->targ == OP_CONST;
2843     } elsif ($op->first->name eq "pushmark") {
2844         return $self->pp_list($op, $cx);
2845     } elsif ($op->first->name eq "enter") {
2846         return $self->pp_leave($op, $cx);
2847     } elsif ($op->first->name eq "leave") {
2848         return $self->pp_leave($op->first, $cx);
2849     } elsif ($op->first->name eq "scope") {
2850         return $self->pp_scope($op->first, $cx);
2851     } elsif ($op->targ == OP_STRINGIFY) {
2852         return $self->dquote($op, $cx);
2853     } elsif ($op->targ == OP_GLOB) {
2854         return $self->pp_glob(
2855                  $op->first    # entersub
2856                     ->first    # ex-list
2857                     ->first    # pushmark
2858                     ->sibling, # glob
2859                  $cx
2860                );
2861     } elsif (!null($op->first->sibling) and
2862              $op->first->sibling->name eq "readline" and
2863              $op->first->sibling->flags & OPf_STACKED) {
2864         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2865                                    . $self->deparse($op->first->sibling, 7),
2866                                    $cx, 7);
2867     } elsif (!null($op->first->sibling) and
2868              $op->first->sibling->name eq "trans" and
2869              $op->first->sibling->flags & OPf_STACKED) {
2870         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2871                                    . $self->deparse($op->first->sibling, 20),
2872                                    $cx, 20);
2873     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2874         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2875     } elsif (!null($op->first->sibling) and
2876              $op->first->sibling->name eq "null" and
2877              class($op->first->sibling) eq "UNOP" and
2878              $op->first->sibling->first->flags & OPf_STACKED and
2879              $op->first->sibling->first->name eq "rcatline") {
2880         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2881                                    . $self->deparse($op->first->sibling, 18),
2882                                    $cx, 18);
2883     } else {
2884         return $self->deparse($op->first, $cx);
2885     }
2886 }
2887
2888 sub padname {
2889     my $self = shift;
2890     my $targ = shift;
2891     return $self->padname_sv($targ)->PVX;
2892 }
2893
2894 sub padany {
2895     my $self = shift;
2896     my $op = shift;
2897     return substr($self->padname($op->targ), 1); # skip $/@/%
2898 }
2899
2900 sub pp_padsv {
2901     my $self = shift;
2902     my($op, $cx) = @_;
2903     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2904 }
2905
2906 sub pp_padav { pp_padsv(@_) }
2907 sub pp_padhv { pp_padsv(@_) }
2908
2909 my @threadsv_names = B::threadsv_names;
2910 sub pp_threadsv {
2911     my $self = shift;
2912     my($op, $cx) = @_;
2913     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2914 }
2915
2916 sub gv_or_padgv {
2917     my $self = shift;
2918     my $op = shift;
2919     if (class($op) eq "PADOP") {
2920         return $self->padval($op->padix);
2921     } else { # class($op) eq "SVOP"
2922         return $op->gv;
2923     }
2924 }
2925
2926 sub pp_gvsv {
2927     my $self = shift;
2928     my($op, $cx) = @_;
2929     my $gv = $self->gv_or_padgv($op);
2930     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2931                                  $self->gv_name($gv), $cx));
2932 }
2933
2934 sub pp_gv {
2935     my $self = shift;
2936     my($op, $cx) = @_;
2937     my $gv = $self->gv_or_padgv($op);
2938     return $self->gv_name($gv);
2939 }
2940
2941 sub pp_aelemfast_lex {
2942     my $self = shift;
2943     my($op, $cx) = @_;
2944     my $name = $self->padname($op->targ);
2945     $name =~ s/^@/\$/;
2946     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2947 }
2948
2949 sub pp_aelemfast {
2950     my $self = shift;
2951     my($op, $cx) = @_;
2952     # optimised PADAV, pre 5.15
2953     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
2954
2955     my $gv = $self->gv_or_padgv($op);
2956     my $name = $self->gv_name($gv);
2957     $name = $self->{'curstash'}."::$name"
2958         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2959     $name = '$' . $name;
2960     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2961 }
2962
2963 sub rv2x {
2964     my $self = shift;
2965     my($op, $cx, $type) = @_;
2966
2967     if (class($op) eq 'NULL' || !$op->can("first")) {
2968         carp("Unexpected op in pp_rv2x");
2969         return 'XXX';
2970     }
2971     my $kid = $op->first;
2972     if ($kid->name eq "gv") {
2973         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
2974     } elsif (is_scalar $kid) {
2975         my $str = $self->deparse($kid, 0);
2976         if ($str =~ /^\$([^\w\d])\z/) {
2977             # "$$+" isn't a legal way to write the scalar dereference
2978             # of $+, since the lexer can't tell you aren't trying to
2979             # do something like "$$ + 1" to get one more than your
2980             # PID. Either "${$+}" or "$${+}" are workable
2981             # disambiguations, but if the programmer did the former,
2982             # they'd be in the "else" clause below rather than here.
2983             # It's not clear if this should somehow be unified with
2984             # the code in dq and re_dq that also adds lexer
2985             # disambiguation braces.
2986             $str = '$' . "{$1}"; #'
2987         }
2988         return $type . $str;
2989     } else {
2990         return $type . "{" . $self->deparse($kid, 0) . "}";
2991     }
2992 }
2993
2994 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2995 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2996 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2997
2998 # skip rv2av
2999 sub pp_av2arylen {
3000     my $self = shift;
3001     my($op, $cx) = @_;
3002     if ($op->first->name eq "padav") {
3003         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3004     } else {
3005         return $self->maybe_local($op, $cx,
3006                                   $self->rv2x($op->first, $cx, '$#'));
3007     }
3008 }
3009
3010 # skip down to the old, ex-rv2cv
3011 sub pp_rv2cv {
3012     my ($self, $op, $cx) = @_;
3013     if (!null($op->first) && $op->first->name eq 'null' &&
3014         $op->first->targ eq OP_LIST)
3015     {
3016         return $self->rv2x($op->first->first->sibling, $cx, "&")
3017     }
3018     else {
3019         return $self->rv2x($op, $cx, "")
3020     }
3021 }
3022
3023 sub list_const {
3024     my $self = shift;
3025     my($cx, @list) = @_;
3026     my @a = map $self->const($_, 6), @list;
3027     if (@a == 0) {
3028         return "()";
3029     } elsif (@a == 1) {
3030         return $a[0];
3031     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3032         # collapse (-1,0,1,2) into (-1..2)
3033         my ($s, $e) = @a[0,-1];
3034         my $i = $s;
3035         return $self->maybe_parens("$s..$e", $cx, 9)
3036           unless grep $i++ != $_, @a;
3037     }
3038     return $self->maybe_parens(join(", ", @a), $cx, 6);
3039 }
3040
3041 sub pp_rv2av {
3042     my $self = shift;
3043     my($op, $cx) = @_;
3044     my $kid = $op->first;
3045     if ($kid->name eq "const") { # constant list
3046         my $av = $self->const_sv($kid);
3047         return $self->list_const($cx, $av->ARRAY);
3048     } else {
3049         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3050     }
3051  }
3052
3053 sub is_subscriptable {
3054     my $op = shift;
3055     if ($op->name =~ /^[ahg]elem/) {
3056         return 1;
3057     } elsif ($op->name eq "entersub") {
3058         my $kid = $op->first;
3059         return 0 unless null $kid->sibling;
3060         $kid = $kid->first;
3061         $kid = $kid->sibling until null $kid->sibling;
3062         return 0 if is_scope($kid);
3063         $kid = $kid->first;
3064         return 0 if $kid->name eq "gv";
3065         return 0 if is_scalar($kid);
3066         return is_subscriptable($kid);
3067     } else {
3068         return 0;
3069     }
3070 }
3071
3072 sub elem_or_slice_array_name
3073 {
3074     my $self = shift;
3075     my ($array, $left, $padname, $allow_arrow) = @_;
3076
3077     if ($array->name eq $padname) {
3078         return $self->padany($array);
3079     } elsif (is_scope($array)) { # ${expr}[0]
3080         return "{" . $self->deparse($array, 0) . "}";
3081     } elsif ($array->name eq "gv") {
3082         $array = $self->gv_name($self->gv_or_padgv($array));
3083         if ($array !~ /::/) {
3084             my $prefix = ($left eq '[' ? '@' : '%');
3085             $array = $self->{curstash}.'::'.$array
3086                 if $self->lex_in_scope($prefix . $array);
3087         }
3088         return $array;
3089     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3090         return $self->deparse($array, 24);
3091     } else {
3092         return undef;
3093     }
3094 }
3095
3096 sub elem_or_slice_single_index
3097 {
3098     my $self = shift;
3099     my ($idx) = @_;
3100
3101     $idx = $self->deparse($idx, 1);
3102
3103     # Outer parens in an array index will confuse perl
3104     # if we're interpolating in a regular expression, i.e.
3105     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3106     #
3107     # If $self->{parens}, then an initial '(' will
3108     # definitely be paired with a final ')'. If
3109     # !$self->{parens}, the misleading parens won't
3110     # have been added in the first place.
3111     #
3112     # [You might think that we could get "(...)...(...)"
3113     # where the initial and final parens do not match
3114     # each other. But we can't, because the above would
3115     # only happen if there's an infix binop between the
3116     # two pairs of parens, and *that* means that the whole
3117     # expression would be parenthesized as well.]
3118     #
3119     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3120
3121     # Hash-element braces will autoquote a bareword inside themselves.
3122     # We need to make sure that C<$hash{warn()}> doesn't come out as
3123     # C<$hash{warn}>, which has a quite different meaning. Currently
3124     # B::Deparse will always quote strings, even if the string was a
3125     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3126     # for constant strings.) So we can cheat slightly here - if we see
3127     # a bareword, we know that it is supposed to be a function call.
3128     #
3129     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3130
3131     return $idx;
3132 }
3133
3134 sub elem {
3135     my $self = shift;
3136     my ($op, $cx, $left, $right, $padname) = @_;
3137     my($array, $idx) = ($op->first, $op->first->sibling);
3138
3139     $idx = $self->elem_or_slice_single_index($idx);
3140
3141     unless ($array->name eq $padname) { # Maybe this has been fixed
3142         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3143     }
3144     if (my $array_name=$self->elem_or_slice_array_name
3145             ($array, $left, $padname, 1)) {
3146         return "\$" . $array_name . $left . $idx . $right;
3147     } else {
3148         # $x[20][3]{hi} or expr->[20]
3149         my $arrow = is_subscriptable($array) ? "" : "->";
3150         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3151     }
3152
3153 }
3154
3155 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3156 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3157
3158 sub pp_gelem {
3159     my $self = shift;
3160     my($op, $cx) = @_;
3161     my($glob, $part) = ($op->first, $op->last);
3162     $glob = $glob->first; # skip rv2gv
3163     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3164     my $scope = is_scope($glob);
3165     $glob = $self->deparse($glob, 0);
3166     $part = $self->deparse($part, 1);
3167     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3168 }
3169
3170 sub slice {
3171     my $self = shift;
3172     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3173     my $last;
3174     my(@elems, $kid, $array, $list);
3175     if (class($op) eq "LISTOP") {
3176         $last = $op->last;
3177     } else { # ex-hslice inside delete()
3178         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3179         $last = $kid;
3180     }
3181     $array = $last;
3182     $array = $array->first
3183         if $array->name eq $regname or $array->name eq "null";
3184     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3185     $kid = $op->first->sibling; # skip pushmark
3186     if ($kid->name eq "list") {
3187         $kid = $kid->first->sibling; # skip list, pushmark
3188         for (; !null $kid; $kid = $kid->sibling) {
3189             push @elems, $self->deparse($kid, 6);
3190         }
3191         $list = join(", ", @elems);
3192     } else {
3193         $list = $self->elem_or_slice_single_index($kid);
3194     }
3195     return "\@" . $array . $left . $list . $right;
3196 }
3197
3198 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3199 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3200
3201 sub pp_lslice {
3202     my $self = shift;
3203     my($op, $cx) = @_;
3204     my $idx = $op->first;
3205     my $list = $op->last;
3206     my(@elems, $kid);
3207     $list = $self->deparse($list, 1);
3208     $idx = $self->deparse($idx, 1);
3209     return "($list)" . "[$idx]";
3210 }
3211
3212 sub want_scalar {
3213     my $op = shift;
3214     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3215 }
3216
3217 sub want_list {
3218     my $op = shift;
3219     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3220 }
3221
3222 sub _method {
3223     my $self = shift;
3224     my($op, $cx) = @_;
3225     my $kid = $op->first->sibling; # skip pushmark
3226     my($meth, $obj, @exprs);
3227     if ($kid->name eq "list" and want_list $kid) {
3228         # When an indirect object isn't a bareword but the args are in
3229         # parens, the parens aren't part of the method syntax (the LLAFR
3230         # doesn't apply), but they make a list with OPf_PARENS set that
3231         # doesn't get flattened by the append_elem that adds the method,
3232         # making a (object, arg1, arg2, ...) list where the object
3233         # usually is. This can be distinguished from
3234         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3235         # object) because in the later the list is in scalar context
3236         # as the left side of -> always is, while in the former
3237         # the list is in list context as method arguments always are.
3238         # (Good thing there aren't method prototypes!)
3239         $meth = $kid->sibling;
3240         $kid = $kid->first->sibling; # skip pushmark
3241         $obj = $kid;
3242         $kid = $kid->sibling;
3243         for (; not null $kid; $kid = $kid->sibling) {
3244             push @exprs, $kid;
3245         }
3246     } else {
3247         $obj = $kid;
3248         $kid = $kid->sibling;
3249         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3250               $kid = $kid->sibling) {
3251             push @exprs, $kid
3252         }
3253         $meth = $kid;
3254     }
3255
3256     if ($meth->name eq "method_named") {
3257         $meth = $self->const_sv($meth)->PV;
3258     } else {
3259         $meth = $meth->first;
3260         if ($meth->name eq "const") {
3261             # As of 5.005_58, this case is probably obsoleted by the
3262             # method_named case above
3263             $meth = $self->const_sv($meth)->PV; # needs to be bare
3264         }
3265     }
3266
3267     return { method => $meth, variable_method => ref($meth),
3268              object => $obj, args => \@exprs  };
3269 }
3270
3271 # compat function only
3272 sub method {
3273     my $self = shift;
3274     my $info = $self->_method(@_);
3275     return $self->e_method( $self->_method(@_) );
3276 }
3277
3278 sub e_method {
3279     my ($self, $info) = @_;
3280     my $obj = $self->deparse($info->{object}, 24);
3281
3282     my $meth = $info->{method};
3283     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3284     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3285     my $kid = $obj . "->" . $meth;
3286     if (length $args) {
3287         return $kid . "(" . $args . ")"; # parens mandatory
3288     } else {
3289         return $kid;
3290     }
3291 }
3292
3293 # returns "&" if the prototype doesn't match the args,
3294 # or ("", $args_after_prototype_demunging) if it does.
3295 sub check_proto {
3296     my $self = shift;
3297     return "&" if $self->{'noproto'};
3298     my($proto, @args) = @_;
3299     my($arg, $real);
3300     my $doneok = 0;
3301     my @reals;
3302     # An unbackslashed @ or % gobbles up the rest of the args
3303     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3304     while ($proto) {
3305         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3306         my $chr = $1;
3307         if ($chr eq "") {
3308             return "&" if @args;
3309         } elsif ($chr eq ";") {
3310             $doneok = 1;
3311         } elsif ($chr eq "@" or $chr eq "%") {
3312             push @reals, map($self->deparse($_, 6), @args);
3313             @args = ();
3314         } else {
3315             $arg = shift @args;
3316             last unless $arg;
3317             if ($chr eq "\$" || $chr eq "_") {
3318                 if (want_scalar $arg) {
3319                     push @reals, $self->deparse($arg, 6);
3320                 } else {
3321                     return "&";
3322                 }
3323             } elsif ($chr eq "&") {
3324                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3325                     push @reals, $self->deparse($arg, 6);
3326                 } else {
3327                     return "&";
3328                 }
3329             } elsif ($chr eq "*") {
3330                 if ($arg->name =~ /^s?refgen$/
3331                     and $arg->first->first->name eq "rv2gv")
3332                   {
3333                       $real = $arg->first->first; # skip refgen, null
3334                       if ($real->first->name eq "gv") {
3335                           push @reals, $self->deparse($real, 6);
3336                       } else {
3337                           push @reals, $self->deparse($real->first, 6);
3338                       }
3339                   } else {
3340                       return "&";
3341                   }
3342             } elsif (substr($chr, 0, 1) eq "\\") {
3343                 $chr =~ tr/\\[]//d;
3344                 if ($arg->name =~ /^s?refgen$/ and
3345                     !null($real = $arg->first) and
3346                     ($chr =~ /\$/ && is_scalar($real->first)
3347                      or ($chr =~ /@/
3348                          && class($real->first->sibling) ne 'NULL'
3349                          && $real->first->sibling->name
3350                          =~ /^(rv2|pad)av$/)
3351                      or ($chr =~ /%/
3352                          && class($real->first->sibling) ne 'NULL'
3353                          && $real->first->sibling->name
3354                          =~ /^(rv2|pad)hv$/)
3355                      #or ($chr =~ /&/ # This doesn't work
3356                      #   && $real->first->name eq "rv2cv")
3357                      or ($chr =~ /\*/
3358                          && $real->first->name eq "rv2gv")))
3359                   {
3360                       push @reals, $self->deparse($real, 6);
3361                   } else {
3362                       return "&";
3363                   }
3364             }
3365        }
3366     }
3367     return "&" if $proto and !$doneok; # too few args and no `;'
3368     return "&" if @args;               # too many args
3369     return ("", join ", ", @reals);
3370 }
3371
3372 sub pp_entersub {
3373     my $self = shift;
3374     my($op, $cx) = @_;
3375     return $self->e_method($self->_method($op, $cx))
3376         unless null $op->first->sibling;
3377     my $prefix = "";
3378     my $amper = "";
3379     my($kid, @exprs);
3380     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3381         $prefix = "do ";
3382     } elsif ($op->private & OPpENTERSUB_AMPER) {
3383         $amper = "&";
3384     }
3385     $kid = $op->first;
3386     $kid = $kid->first->sibling; # skip ex-list, pushmark
3387     for (; not null $kid->sibling; $kid = $kid->sibling) {
3388         push @exprs, $kid;
3389     }
3390     my $simple = 0;
3391     my $proto = undef;
3392     if (is_scope($kid)) {
3393         $amper = "&";
3394         $kid = "{" . $self->deparse($kid, 0) . "}";
3395     } elsif ($kid->first->name eq "gv") {
3396         my $gv = $self->gv_or_padgv($kid->first);
3397         if (class($gv->CV) ne "SPECIAL") {
3398             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3399         }
3400         $simple = 1; # only calls of named functions can be prototyped
3401         $kid = $self->deparse($kid, 24);
3402         if (!$amper) {
3403             if ($kid eq 'main::') {
3404                 $kid = '::';
3405             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3406                 $kid = single_delim("q", "'", $kid) . '->';
3407             }
3408         }
3409     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3410         $amper = "&";
3411         $kid = $self->deparse($kid, 24);
3412     } else {
3413         $prefix = "";
3414         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3415         $kid = $self->deparse($kid, 24) . $arrow;
3416     }
3417
3418     # Doesn't matter how many prototypes there are, if
3419     # they haven't happened yet!
3420     my $declared;
3421     {
3422         no strict 'refs';
3423         no warnings 'uninitialized';
3424         $declared = exists $self->{'subs_declared'}{$kid}
3425             || (
3426                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3427                  && !exists
3428                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3429                  && defined prototype $self->{'curstash'}."::".$kid
3430                );
3431         if (!$declared && defined($proto)) {
3432             # Avoid "too early to check prototype" warning
3433             ($amper, $proto) = ('&');
3434         }
3435     }
3436
3437     my $args;
3438     if ($declared and defined $proto and not $amper) {
3439         ($amper, $args) = $self->check_proto($proto, @exprs);
3440         if ($amper eq "&") {
3441             $args = join(", ", map($self->deparse($_, 6), @exprs));
3442         }
3443     } else {
3444         $args = join(", ", map($self->deparse($_, 6), @exprs));
3445     }
3446     if ($prefix or $amper) {
3447         if ($op->flags & OPf_STACKED) {
3448             return $prefix . $amper . $kid . "(" . $args . ")";
3449         } else {
3450             return $prefix . $amper. $kid;
3451         }
3452     } else {
3453         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3454         # so it must have been translated from a keyword call. Translate
3455         # it back.
3456         $kid =~ s/^CORE::GLOBAL:://;
3457
3458         my $dproto = defined($proto) ? $proto : "undefined";
3459         if (!$declared) {
3460             return "$kid(" . $args . ")";
3461         } elsif ($dproto eq "") {
3462             return $kid;
3463         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3464             # is_scalar is an excessively conservative test here:
3465             # really, we should be comparing to the precedence of the
3466             # top operator of $exprs[0] (ala unop()), but that would
3467             # take some major code restructuring to do right.
3468             return $self->maybe_parens_func($kid, $args, $cx, 16);
3469         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3470             return $self->maybe_parens_func($kid, $args, $cx, 5);
3471         } else {
3472             return "$kid(" . $args . ")";
3473         }
3474     }
3475 }
3476
3477 sub pp_enterwrite { unop(@_, "write") }
3478
3479 # escape things that cause interpolation in double quotes,
3480 # but not character escapes
3481 sub uninterp {
3482     my($str) = @_;
3483     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3484     return $str;
3485 }
3486
3487 {
3488 my $bal;
3489 BEGIN {
3490     use re "eval";
3491     # Matches any string which is balanced with respect to {braces}
3492     $bal = qr(
3493       (?:
3494         [^\\{}]
3495       | \\\\
3496       | \\[{}]
3497       | \{(??{$bal})\}
3498       )*
3499     )x;
3500 }
3501
3502 # the same, but treat $|, $), $( and $ at the end of the string differently
3503 sub re_uninterp {
3504     my($str) = @_;
3505
3506     $str =~ s/
3507           ( ^|\G                  # $1
3508           | [^\\]
3509           )
3510
3511           (                       # $2
3512             (?:\\\\)*
3513           )
3514
3515           (                       # $3
3516             (\(\?\??\{$bal\}\))   # $4
3517           | [\$\@]
3518             (?!\||\)|\(|$)
3519           | \\[uUlLQE]
3520           )
3521
3522         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3523
3524     return $str;
3525 }
3526
3527 # This is for regular expressions with the /x modifier
3528 # We have to leave comments unmangled.
3529 sub re_uninterp_extended {
3530     my($str) = @_;
3531
3532     $str =~ s/
3533           ( ^|\G                  # $1
3534           | [^\\]
3535           )
3536
3537           (                       # $2
3538             (?:\\\\)*
3539           )
3540
3541           (                       # $3
3542             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3543             | \#[^\n]*            #     (skip over comments)
3544             )
3545           | [\$\@]
3546             (?!\||\)|\(|$|\s)
3547           | \\[uUlLQE]
3548           )
3549
3550         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3551
3552     return $str;
3553 }
3554 }
3555
3556 my %unctrl = # portable to to EBCDIC
3557     (
3558      "\c@" => '\c@',    # unused
3559      "\cA" => '\cA',
3560      "\cB" => '\cB',
3561      "\cC" => '\cC',
3562      "\cD" => '\cD',
3563      "\cE" => '\cE',
3564      "\cF" => '\cF',
3565      "\cG" => '\cG',
3566      "\cH" => '\cH',
3567      "\cI" => '\cI',
3568      "\cJ" => '\cJ',
3569      "\cK" => '\cK',
3570      "\cL" => '\cL',
3571      "\cM" => '\cM',
3572      "\cN" => '\cN',
3573      "\cO" => '\cO',
3574      "\cP" => '\cP',
3575      "\cQ" => '\cQ',
3576      "\cR" => '\cR',
3577      "\cS" => '\cS',
3578      "\cT" => '\cT',
3579      "\cU" => '\cU',
3580      "\cV" => '\cV',
3581      "\cW" => '\cW',
3582      "\cX" => '\cX',
3583      "\cY" => '\cY',
3584      "\cZ" => '\cZ',
3585      "\c[" => '\c[',    # unused
3586      "\c\\" => '\c\\',  # unused
3587      "\c]" => '\c]',    # unused
3588      "\c_" => '\c_',    # unused
3589     );
3590
3591 # character escapes, but not delimiters that might need to be escaped
3592 sub escape_str { # ASCII, UTF8
3593     my($str) = @_;
3594     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3595     $str =~ s/\a/\\a/g;
3596 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3597     $str =~ s/\t/\\t/g;
3598     $str =~ s/\n/\\n/g;
3599     $str =~ s/\e/\\e/g;
3600     $str =~ s/\f/\\f/g;
3601     $str =~ s/\r/\\r/g;
3602     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3603     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3604     return $str;
3605 }
3606
3607 # For regexes with the /x modifier.
3608 # Leave whitespace unmangled.
3609 sub escape_extended_re {
3610     my($str) = @_;
3611     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3612     $str =~ s/([[:^print:]])/
3613         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3614     $str =~ s/\n/\n\f/g;
3615     return $str;
3616 }
3617
3618 # Don't do this for regexen
3619 sub unback {
3620     my($str) = @_;
3621     $str =~ s/\\/\\\\/g;
3622     return $str;
3623 }
3624
3625 # Remove backslashes which precede literal control characters,
3626 # to avoid creating ambiguity when we escape the latter.
3627 sub re_unback {
3628     my($str) = @_;
3629
3630     # the insane complexity here is due to the behaviour of "\c\"
3631     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3632     return $str;
3633 }
3634
3635 sub balanced_delim {
3636     my($str) = @_;
3637     my @str = split //, $str;
3638     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3639     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3640         ($open, $close) = @$ar;
3641         $fail = 0; $cnt = 0; $last_bs = 0;
3642         for $c (@str) {
3643             if ($c eq $open) {
3644                 $fail = 1 if $last_bs;
3645                 $cnt++;
3646             } elsif ($c eq $close) {
3647                 $fail = 1 if $last_bs;
3648                 $cnt--;
3649                 if ($cnt < 0) {
3650                     # qq()() isn't ")("
3651                     $fail = 1;
3652                     last;
3653                 }
3654             }
3655             $last_bs = $c eq '\\';
3656         }
3657         $fail = 1 if $cnt != 0;
3658         return ($open, "$open$str$close") if not $fail;
3659     }
3660     return ("", $str);
3661 }
3662
3663 sub single_delim {
3664     my($q, $default, $str) = @_;
3665     return "$default$str$default" if $default and index($str, $default) == -1;
3666     if ($q ne 'qr') {
3667         (my $succeed, $str) = balanced_delim($str);
3668         return "$q$str" if $succeed;
3669     }
3670     for my $delim ('/', '"', '#') {
3671         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3672     }
3673     if ($default) {
3674         $str =~ s/$default/\\$default/g;
3675         return "$default$str$default";
3676     } else {
3677         $str =~ s[/][\\/]g;
3678         return "$q/$str/";
3679     }
3680 }
3681
3682 my $max_prec;
3683 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3684
3685 # Split a floating point number into an integer mantissa and a binary
3686 # exponent. Assumes you've already made sure the number isn't zero or
3687 # some weird infinity or NaN.
3688 sub split_float {
3689     my($f) = @_;
3690     my $exponent = 0;
3691     if ($f == int($f)) {
3692         while ($f % 2 == 0) {
3693             $f /= 2;
3694             $exponent++;
3695         }
3696     } else {
3697         while ($f != int($f)) {
3698             $f *= 2;
3699             $exponent--;
3700         }
3701     }
3702     my $mantissa = sprintf("%.0f", $f);
3703     return ($mantissa, $exponent);
3704 }
3705
3706 sub const {
3707     my $self = shift;
3708     my($sv, $cx) = @_;
3709     if ($self->{'use_dumper'}) {
3710         return $self->const_dumper($sv, $cx);
3711     }
3712     if (class($sv) eq "SPECIAL") {
3713         # sv_undef, sv_yes, sv_no
3714         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3715     }
3716     if (class($sv) eq "NULL") {
3717        return 'undef';
3718     }
3719     # convert a version object into the "v1.2.3" string in its V magic
3720     if ($sv->FLAGS & SVs_RMG) {
3721         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3722             return $mg->PTR if $mg->TYPE eq 'V';
3723         }
3724     }
3725
3726     if ($sv->FLAGS & SVf_IOK) {
3727         my $str = $sv->int_value;
3728         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3729         return $str;
3730     } elsif ($sv->FLAGS & SVf_NOK) {
3731         my $nv = $sv->NV;
3732         if ($nv == 0) {
3733             if (pack("F", $nv) eq pack("F", 0)) {
3734                 # positive zero
3735                 return "0";
3736             } else {
3737                 # negative zero
3738                 return $self->maybe_parens("-.0", $cx, 21);
3739             }
3740         } elsif (1/$nv == 0) {
3741             if ($nv > 0) {
3742                 # positive infinity
3743                 return $self->maybe_parens("9**9**9", $cx, 22);
3744             } else {
3745                 # negative infinity
3746                 return $self->maybe_parens("-9**9**9", $cx, 21);
3747             }
3748         } elsif ($nv != $nv) {
3749             # NaN
3750             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3751                 # the normal kind
3752                 return "sin(9**9**9)";
3753             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3754                 # the inverted kind
3755                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3756             } else {
3757                 # some other kind
3758                 my $hex = unpack("h*", pack("F", $nv));
3759                 return qq'unpack("F", pack("h*", "$hex"))';
3760             }
3761         }
3762         # first, try the default stringification
3763         my $str = "$nv";
3764         if ($str != $nv) {
3765             # failing that, try using more precision
3766             $str = sprintf("%.${max_prec}g", $nv);
3767 #           if (pack("F", $str) ne pack("F", $nv)) {
3768             if ($str != $nv) {
3769                 # not representable in decimal with whatever sprintf()
3770                 # and atof() Perl is using here.
3771                 my($mant, $exp) = split_float($nv);
3772                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3773             }
3774         }
3775         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3776         return $str;
3777     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3778         my $ref = $sv->RV;
3779         if (class($ref) eq "AV") {
3780             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3781         } elsif (class($ref) eq "HV") {
3782             my %hash = $ref->ARRAY;
3783             my @elts;
3784             for my $k (sort keys %hash) {
3785                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3786             }
3787             return "{" . join(", ", @elts) . "}";
3788         } elsif (class($ref) eq "CV") {
3789             return "sub " . $self->deparse_sub($ref);
3790         }
3791         if ($ref->FLAGS & SVs_SMG) {
3792             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3793                 if ($mg->TYPE eq 'r') {
3794                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3795                     return single_delim("qr", "", $re);
3796                 }
3797             }
3798         }
3799
3800         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3801     } elsif ($sv->FLAGS & SVf_POK) {
3802         my $str = $sv->PV;
3803         if ($str =~ /[[:^print:]]/) {
3804             return single_delim("qq", '"', uninterp escape_str unback $str);
3805         } else {
3806             return single_delim("q", "'", unback $str);
3807         }
3808     } else {
3809         return "undef";
3810     }
3811 }
3812
3813 sub const_dumper {
3814     my $self = shift;
3815     my($sv, $cx) = @_;
3816     my $ref = $sv->object_2svref();
3817     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3818     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3819     my $str = $dumper->Dump();
3820     if ($str =~ /^\$v/) {
3821         return '${my ' . $str . ' \$v}';
3822     } else {
3823         return $str;
3824     }
3825 }
3826
3827 sub const_sv {
3828     my $self = shift;
3829     my $op = shift;
3830     my $sv = $op->sv;
3831     # the constant could be in the pad (under useithreads)
3832     $sv = $self->padval($op->targ) unless $$sv;
3833     return $sv;
3834 }
3835
3836 sub pp_const {
3837     my $self = shift;
3838     my($op, $cx) = @_;
3839     if ($op->private & OPpCONST_ARYBASE) {
3840         return '$[';
3841     }
3842 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3843 #       return $self->const_sv($op)->PV;
3844 #    }
3845     my $sv = $self->const_sv($op);
3846     return $self->const($sv, $cx);
3847 }
3848
3849 sub dq {
3850     my $self = shift;
3851     my $op = shift;
3852     my $type = $op->name;
3853     if ($type eq "const") {
3854         return '$[' if $op->private & OPpCONST_ARYBASE;
3855         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3856     } elsif ($type eq "concat") {
3857         my $first = $self->dq($op->first);
3858         my $last  = $self->dq($op->last);
3859
3860         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3861         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3862             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3863             || ($last =~ /^[:'{\[\w_]/ && #'
3864                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3865
3866         return $first . $last;
3867     } elsif ($type eq "uc") {
3868         return '\U' . $self->dq($op->first->sibling) . '\E';
3869     } elsif ($type eq "lc") {
3870         return '\L' . $self->dq($op->first->sibling) . '\E';
3871     } elsif ($type eq "ucfirst") {
3872         return '\u' . $self->dq($op->first->sibling);
3873     } elsif ($type eq "lcfirst") {
3874         return '\l' . $self->dq($op->first->sibling);
3875     } elsif ($type eq "quotemeta") {
3876         return '\Q' . $self->dq($op->first->sibling) . '\E';
3877     } elsif ($type eq "join") {
3878         return $self->deparse($op->last, 26); # was join($", @ary)
3879     } else {
3880         return $self->deparse($op, 26);
3881     }
3882 }
3883
3884 sub pp_backtick {
3885     my $self = shift;
3886     my($op, $cx) = @_;
3887     # skip pushmark if it exists (readpipe() vs ``)
3888     my $child = $op->first->sibling->isa('B::NULL')
3889         ? $op->first : $op->first->sibling;
3890     if ($self->pure_string($child)) {
3891         return single_delim("qx", '`', $self->dq($child, 1));
3892     }
3893     unop($self, @_, "readpipe");
3894 }
3895
3896 sub dquote {
3897     my $self = shift;
3898     my($op, $cx) = @_;
3899     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3900     return $self->deparse($kid, $cx) if $self->{'unquote'};
3901     $self->maybe_targmy($kid, $cx,
3902                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3903 }
3904
3905 # OP_STRINGIFY is a listop, but it only ever has one arg
3906 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3907
3908 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3909 # note that tr(from)/to/ is OK, but not tr/from/(to)
3910 sub double_delim {
3911     my($from, $to) = @_;
3912     my($succeed, $delim);
3913     if ($from !~ m[/] and $to !~ m[/]) {
3914         return "/$from/$to/";
3915     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3916         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3917             return "$from$to";
3918         } else {
3919             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3920                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3921             }
3922             $to =~ s[/][\\/]g;
3923             return "$from/$to/";
3924         }
3925     } else {
3926         for $delim ('/', '"', '#') { # note no '
3927             return "$delim$from$delim$to$delim"
3928                 if index($to . $from, $delim) == -1;
3929         }
3930         $from =~ s[/][\\/]g;
3931         $to =~ s[/][\\/]g;
3932         return "/$from/$to/";
3933     }
3934 }
3935
3936 # Only used by tr///, so backslashes hyphens
3937 sub pchr { # ASCII
3938     my($n) = @_;
3939     if ($n == ord '\\') {
3940         return '\\\\';
3941     } elsif ($n == ord "-") {
3942         return "\\-";
3943     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3944         return chr($n);
3945     } elsif ($n == ord "\a") {
3946         return '\\a';
3947     } elsif ($n == ord "\b") {
3948         return '\\b';
3949     } elsif ($n == ord "\t") {
3950         return '\\t';
3951     } elsif ($n == ord "\n") {
3952         return '\\n';
3953     } elsif ($n == ord "\e") {
3954         return '\\e';
3955     } elsif ($n == ord "\f") {
3956         return '\\f';
3957     } elsif ($n == ord "\r") {
3958         return '\\r';
3959     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3960         return '\\c' . chr(ord("@") + $n);
3961     } else {
3962 #       return '\x' . sprintf("%02x", $n);
3963         return '\\' . sprintf("%03o", $n);
3964     }
3965 }
3966
3967 sub collapse {
3968     my(@chars) = @_;
3969     my($str, $c, $tr) = ("");
3970     for ($c = 0; $c < @chars; $c++) {
3971         $tr = $chars[$c];
3972         $str .= pchr($tr);
3973         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3974             $chars[$c + 2] == $tr + 2)
3975         {
3976             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3977               {}
3978             $str .= "-";
3979             $str .= pchr($chars[$c]);
3980         }
3981     }
3982     return $str;
3983 }
3984
3985 sub tr_decode_byte {
3986     my($table, $flags) = @_;
3987     my(@table) = unpack("s*", $table);
3988     splice @table, 0x100, 1;   # Number of subsequent elements
3989     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3990     if ($table[ord "-"] != -1 and
3991         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3992     {
3993         $tr = $table[ord "-"];
3994         $table[ord "-"] = -1;
3995         if ($tr >= 0) {
3996             @from = ord("-");
3997             @to = $tr;
3998         } else { # -2 ==> delete
3999             $delhyphen = 1;
4000         }
4001     }
4002     for ($c = 0; $c < @table; $c++) {
4003         $tr = $table[$c];
4004         if ($tr >= 0) {
4005             push @from, $c; push @to, $tr;
4006         } elsif ($tr == -2) {
4007             push @delfrom, $c;
4008         }
4009     }
4010     @from = (@from, @delfrom);
4011     if ($flags & OPpTRANS_COMPLEMENT) {
4012         my @newfrom = ();
4013         my %from;
4014         @from{@from} = (1) x @from;
4015         for ($c = 0; $c < 256; $c++) {
4016             push @newfrom, $c unless $from{$c};
4017         }
4018         @from = @newfrom;
4019     }
4020     unless ($flags & OPpTRANS_DELETE || !@to) {
4021         pop @to while $#to and $to[$#to] == $to[$#to -1];
4022     }
4023     my($from, $to);
4024     $from = collapse(@from);
4025     $to = collapse(@to);
4026     $from .= "-" if $delhyphen;
4027     return ($from, $to);
4028 }
4029
4030 sub tr_chr {
4031     my $x = shift;
4032     if ($x == ord "-") {
4033         return "\\-";
4034     } elsif ($x == ord "\\") {
4035         return "\\\\";
4036     } else {
4037         return chr $x;
4038     }
4039 }
4040
4041 # XXX This doesn't yet handle all cases correctly either
4042
4043 sub tr_decode_utf8 {
4044     my($swash_hv, $flags) = @_;
4045     my %swash = $swash_hv->ARRAY;
4046     my $final = undef;
4047     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4048     my $none = $swash{"NONE"}->IV;
4049     my $extra = $none + 1;
4050     my(@from, @delfrom, @to);
4051     my $line;
4052     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4053         my($min, $max, $result) = split(/\t/, $line);
4054         $min = hex $min;
4055         if (length $max) {
4056             $max = hex $max;
4057         } else {
4058             $max = $min;
4059         }
4060         $result = hex $result;
4061         if ($result == $extra) {
4062             push @delfrom, [$min, $max];
4063         } else {
4064             push @from, [$min, $max];
4065             push @to, [$result, $result + $max - $min];
4066         }
4067     }
4068     for my $i (0 .. $#from) {
4069         if ($from[$i][0] == ord '-') {
4070             unshift @from, splice(@from, $i, 1);
4071             unshift @to, splice(@to, $i, 1);
4072             last;
4073         } elsif ($from[$i][1] == ord '-') {
4074             $from[$i][1]--;
4075             $to[$i][1]--;
4076             unshift @from, ord '-';
4077             unshift @to, ord '-';
4078             last;
4079         }
4080     }
4081     for my $i (0 .. $#delfrom) {
4082         if ($delfrom[$i][0] == ord '-') {
4083             push @delfrom, splice(@delfrom, $i, 1);
4084             last;
4085         } elsif ($delfrom[$i][1] == ord '-') {
4086             $delfrom[$i][1]--;
4087             push @delfrom, ord '-';
4088             last;
4089         }
4090     }
4091     if (defined $final and $to[$#to][1] != $final) {
4092         push @to, [$final, $final];
4093     }
4094     push @from, @delfrom;
4095     if ($flags & OPpTRANS_COMPLEMENT) {
4096         my @newfrom;
4097         my $next = 0;
4098         for my $i (0 .. $#from) {
4099             push @newfrom, [$next, $from[$i][0] - 1];
4100             $next = $from[$i][1] + 1;
4101         }
4102         @from = ();
4103         for my $range (@newfrom) {
4104             if ($range->[0] <= $range->[1]) {
4105                 push @from, $range;
4106             }
4107         }
4108     }
4109     my($from, $to, $diff);
4110     for my $chunk (@from) {
4111         $diff = $chunk->[1] - $chunk->[0];
4112         if ($diff > 1) {
4113             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4114         } elsif ($diff == 1) {
4115             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4116         } else {
4117             $from .= tr_chr($chunk->[0]);
4118         }
4119     }
4120     for my $chunk (@to) {
4121         $diff = $chunk->[1] - $chunk->[0];
4122         if ($diff > 1) {
4123             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4124         } elsif ($diff == 1) {
4125             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4126         } else {
4127             $to .= tr_chr($chunk->[0]);
4128         }
4129     }
4130     #$final = sprintf("%04x", $final) if defined $final;
4131     #$none = sprintf("%04x", $none) if defined $none;
4132     #$extra = sprintf("%04x", $extra) if defined $extra;
4133     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
4134     #print STDERR $swash{'LIST'}->PV;
4135     return (escape_str($from), escape_str($to));
4136 }
4137
4138 sub pp_trans {
4139     my $self = shift;
4140     my($op, $cx) = @_;
4141     my($from, $to);
4142     my $class = class($op);
4143     my $priv_flags = $op->private;
4144     if ($class eq "PVOP") {
4145         ($from, $to) = tr_decode_byte($op->pv, $priv_flags);
4146     } elsif ($class eq "PADOP") {
4147         ($from, $to)
4148           = tr_decode_utf8($self->padval($op->padix)->RV, $priv_flags);
4149     } else { # class($op) eq "SVOP"
4150         ($from, $to) = tr_decode_utf8($op->sv->RV, $priv_flags);
4151     }
4152     my $flags = "";
4153     $flags .= "c" if $priv_flags & OPpTRANS_COMPLEMENT;
4154     $flags .= "d" if $priv_flags & OPpTRANS_DELETE;
4155     $to = "" if $from eq $to and $flags eq "";
4156     $flags .= "s" if $priv_flags & OPpTRANS_SQUASH;
4157     return "tr" . double_delim($from, $to) . $flags;
4158 }
4159
4160 sub pp_transr { &pp_trans . 'r' }
4161
4162 sub re_dq_disambiguate {
4163     my ($first, $last) = @_;
4164     # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
4165     ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4166         $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4167         || ($last =~ /^[{\[\w_]/ &&
4168             $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4169     return $first . $last;
4170 }
4171
4172 # Like dq(), but different
4173 sub re_dq {
4174     my $self = shift;
4175     my ($op, $extended) = @_;
4176
4177     my $type = $op->name;
4178     if ($type eq "const") {
4179         return '$[' if $op->private & OPpCONST_ARYBASE;
4180         my $unbacked = re_unback($self->const_sv($op)->as_string);
4181         return re_uninterp_extended(escape_extended_re($unbacked))
4182             if $extended;
4183         return re_uninterp(escape_str($unbacked));
4184     } elsif ($type eq "concat") {
4185         my $first = $self->re_dq($op->first, $extended);
4186         my $last  = $self->re_dq($op->last,  $extended);
4187         return re_dq_disambiguate($first, $last);
4188     } elsif ($type eq "uc") {
4189         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
4190     } elsif ($type eq "lc") {
4191         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
4192     } elsif ($type eq "ucfirst") {
4193         return '\u' . $self->re_dq($op->first->sibling, $extended);
4194     } elsif ($type eq "lcfirst") {
4195         return '\l' . $self->re_dq($op->first->sibling, $extended);
4196     } elsif ($type eq "quotemeta") {
4197         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
4198     } elsif ($type eq "join") {
4199         return $self->deparse($op->last, 26); # was join($", @ary)
4200     } else {
4201         return $self->deparse($op, 26);
4202     }
4203 }
4204
4205 sub pure_string {
4206     my ($self, $op) = @_;
4207     return 0 if null $op;
4208     my $type = $op->name;
4209
4210     if ($type eq 'const') {
4211         return 1;
4212     }
4213     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
4214         return $self->pure_string($op->first->sibling);
4215     }
4216     elsif ($type eq 'join') {
4217         my $join_op = $op->first->sibling;  # Skip pushmark
4218         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
4219
4220         my $gvop = $join_op->first;
4221         return 0 unless $gvop->name eq 'gvsv';
4222         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
4223
4224         return 0 unless ${$join_op->sibling} eq ${$op->last};
4225         return 0 unless $op->last->name =~ /^(?:[ah]slice|(?:rv2|pad)av)$/;
4226     }
4227     elsif ($type eq 'concat') {
4228         return $self->pure_string($op->first)
4229             && $self->pure_string($op->last);
4230     }
4231     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
4232         return 1;
4233     }
4234     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4235            $op->first->name eq "null" and $op->first->can('first')
4236            and not null $op->first->first and
4237            $op->first->first->name eq "aelemfast") {
4238         return 1;
4239     }
4240     else {
4241         return 0;
4242     }
4243
4244     return 1;
4245 }
4246
4247 sub regcomp {
4248     my $self = shift;
4249     my($op, $cx, $extended) = @_;
4250     my $kid = $op->first;
4251     $kid = $kid->first if $kid->name eq "regcmaybe";
4252     $kid = $kid->first if $kid->name eq "regcreset";
4253     if ($kid->name eq "null" and !null($kid->first)
4254         and $kid->first->name eq 'pushmark')
4255     {
4256         my $str = '';
4257         $kid = $kid->first->sibling;
4258         while (!null($kid)) {
4259             my $first = $str;
4260             my $last = $self->re_dq($kid, $extended);
4261             $str = re_dq_disambiguate($first, $last);
4262             $kid = $kid->sibling;
4263         }
4264         return $str, 1;
4265     }
4266
4267     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
4268     return ($self->deparse($kid, $cx), 0);
4269 }
4270
4271 sub pp_regcomp {
4272     my ($self, $op, $cx) = @_;
4273     return (($self->regcomp($op, $cx, 0))[0]);
4274 }
4275
4276 # osmic acid -- see osmium tetroxide
4277
4278 my %matchwords;
4279 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
4280     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
4281     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
4282
4283 sub matchop {
4284     my $self = shift;
4285     my($op, $cx, $name, $delim) = @_;
4286     my $kid = $op->first;
4287     my ($binop, $var, $re) = ("", "", "");
4288     if ($op->flags & OPf_STACKED) {
4289         $binop = 1;
4290         $var = $self->deparse($kid, 20);
4291         $kid = $kid->sibling;
4292     }
4293     my $quote = 1;
4294     my $extended = ($op->pmflags & PMf_EXTENDED);
4295     my $rhs_bound_to_defsv;
4296     if (null $kid) {
4297         my $unbacked = re_unback($op->precomp);
4298         if ($extended) {
4299             $re = re_uninterp_extended(escape_extended_re($unbacked));
4300         } else {
4301             $re = re_uninterp(escape_str(re_unback($op->precomp)));
4302         }
4303     } elsif ($kid->name ne 'regcomp') {
4304         carp("found ".$kid->name." where regcomp expected");
4305     } else {
4306         ($re, $quote) = $self->regcomp($kid, 21, $extended);
4307         $rhs_bound_to_defsv = 1 if $kid->first->first->flags & OPf_SPECIAL;
4308     }
4309     my $flags = "";
4310     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
4311     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4312     $flags .= "i" if $op->pmflags & PMf_FOLD;
4313     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4314     $flags .= "o" if $op->pmflags & PMf_KEEP;
4315     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4316     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
4317     $flags = $matchwords{$flags} if $matchwords{$flags};
4318     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
4319         $re =~ s/\?/\\?/g;
4320         $re = "?$re?";
4321     } elsif ($quote) {
4322         $re = single_delim($name, $delim, $re);
4323     }
4324     $re = $re . $flags if $quote;
4325     if ($binop) {
4326         return
4327          $self->maybe_parens(
4328           $rhs_bound_to_defsv
4329            ? "$var =~ (\$_ =~ $re)"
4330            : "$var =~ $re",
4331           $cx, 20
4332          );
4333     } else {
4334         return $re;
4335     }
4336 }
4337
4338 sub pp_match { matchop(@_, "m", "/") }
4339 sub pp_pushre { matchop(@_, "m", "/") }
4340 sub pp_qr { matchop(@_, "qr", "") }
4341
4342 sub pp_split {
4343     my $self = shift;
4344     my($op, $cx) = @_;
4345     my($kid, @exprs, $ary, $expr);
4346     $kid = $op->first;
4347
4348     # For our kid (an OP_PUSHRE), pmreplroot is never actually the
4349     # root of a replacement; it's either empty, or abused to point to
4350     # the GV for an array we split into (an optimization to save
4351     # assignment overhead). Depending on whether we're using ithreads,
4352     # this OP* holds either a GV* or a PADOFFSET. Luckily, B.xs
4353     # figures out for us which it is.
4354     my $replroot = $kid->pmreplroot;
4355     my $gv = 0;
4356     if (ref($replroot) eq "B::GV") {
4357         $gv = $replroot;
4358     } elsif (!ref($replroot) and $replroot > 0) {
4359         $gv = $self->padval($replroot);
4360     }
4361     $ary = $self->stash_variable('@', $self->gv_name($gv), $cx) if $gv;
4362
4363     for (; !null($kid); $kid = $kid->sibling) {
4364         push @exprs, $self->deparse($kid, 6);
4365     }
4366
4367     # handle special case of split(), and split(' ') that compiles to /\s+/
4368     # Under 5.10, the reflags may be undef if the split regexp isn't a constant
4369     $kid = $op->first;
4370     if ( $kid->flags & OPf_SPECIAL
4371          and ( $] < 5.009 ? $kid->pmflags & PMf_SKIPWHITE()
4372               : ($kid->reflags || 0) & RXf_SKIPWHITE() ) ) {
4373         $exprs[0] = "' '";
4374     }
4375