This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Rmv extraneous sub return value
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # There was an attempt when this was first rewritten to make it 5.8
8 # compatible, but that has now been abandoned, and newer constructs are used
9 # as convenient.
10
11 my $start_time;
12 BEGIN { # Get the time the script started running; do it at compilation to
13         # get it as close as possible
14     $start_time= time;
15 }
16
17 require 5.010_001;
18 use strict;
19 use warnings;
20 use Carp;
21 use Config;
22 use File::Find;
23 use File::Path;
24 use File::Spec;
25 use Text::Tabs;
26 use re "/aa";
27
28 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
29 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
30
31 sub NON_ASCII_PLATFORM { ord("A") != 65 }
32
33 ##########################################################################
34 #
35 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
36 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
37 # a pod file and .t files, depending on option parameters.
38 #
39 # The structure of this file is:
40 #   First these introductory comments; then
41 #   code needed for everywhere, such as debugging stuff; then
42 #   code to handle input parameters; then
43 #   data structures likely to be of external interest (some of which depend on
44 #       the input parameters, so follows them; then
45 #   more data structures and subroutine and package (class) definitions; then
46 #   the small actual loop to process the input files and finish up; then
47 #   a __DATA__ section, for the .t tests
48 #
49 # This program works on all releases of Unicode so far.  The outputs have been
50 # scrutinized most intently for release 5.1.  The others have been checked for
51 # somewhat more than just sanity.  It can handle all non-provisional Unicode
52 # character properties in those releases.
53 #
54 # This program is mostly about Unicode character (or code point) properties.
55 # A property describes some attribute or quality of a code point, like if it
56 # is lowercase or not, its name, what version of Unicode it was first defined
57 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
58 # possibilities by making all properties into mappings from each code point
59 # into some corresponding value.  In the case of it being lowercase or not,
60 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
61 # property maps each Unicode code point to a single value, called a "property
62 # value".  (Some more recently defined properties, map a code point to a set
63 # of values.)
64 #
65 # When using a property in a regular expression, what is desired isn't the
66 # mapping of the code point to its property's value, but the reverse (or the
67 # mathematical "inverse relation"): starting with the property value, "Does a
68 # code point map to it?"  These are written in a "compound" form:
69 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
70 # files containing the lists of code points that map to each such regular
71 # expression property value, one file per list
72 #
73 # There is also a single form shortcut that Perl adds for many of the commonly
74 # used properties.  This happens for all binary properties, plus script,
75 # general_category, and block properties.
76 #
77 # Thus the outputs of this program are files.  There are map files, mostly in
78 # the 'To' directory; and there are list files for use in regular expression
79 # matching, all in subdirectories of the 'lib' directory, with each
80 # subdirectory being named for the property that the lists in it are for.
81 # Bookkeeping, test, and documentation files are also generated.
82
83 my $matches_directory = 'lib';   # Where match (\p{}) files go.
84 my $map_directory = 'To';        # Where map files go.
85
86 # DATA STRUCTURES
87 #
88 # The major data structures of this program are Property, of course, but also
89 # Table.  There are two kinds of tables, very similar to each other.
90 # "Match_Table" is the data structure giving the list of code points that have
91 # a particular property value, mentioned above.  There is also a "Map_Table"
92 # data structure which gives the property's mapping from code point to value.
93 # There are two structures because the match tables need to be combined in
94 # various ways, such as constructing unions, intersections, complements, etc.,
95 # and the map ones don't.  And there would be problems, perhaps subtle, if
96 # a map table were inadvertently operated on in some of those ways.
97 # The use of separate classes with operations defined on one but not the other
98 # prevents accidentally confusing the two.
99 #
100 # At the heart of each table's data structure is a "Range_List", which is just
101 # an ordered list of "Ranges", plus ancillary information, and methods to
102 # operate on them.  A Range is a compact way to store property information.
103 # Each range has a starting code point, an ending code point, and a value that
104 # is meant to apply to all the code points between the two end points,
105 # inclusive.  For a map table, this value is the property value for those
106 # code points.  Two such ranges could be written like this:
107 #   0x41 .. 0x5A, 'Upper',
108 #   0x61 .. 0x7A, 'Lower'
109 #
110 # Each range also has a type used as a convenience to classify the values.
111 # Most ranges in this program will be Type 0, or normal, but there are some
112 # ranges that have a non-zero type.  These are used only in map tables, and
113 # are for mappings that don't fit into the normal scheme of things.  Mappings
114 # that require a hash entry to communicate with utf8.c are one example;
115 # another example is mappings for charnames.pm to use which indicate a name
116 # that is algorithmically determinable from its code point (and the reverse).
117 # These are used to significantly compact these tables, instead of listing
118 # each one of the tens of thousands individually.
119 #
120 # In a match table, the value of a range is irrelevant (and hence the type as
121 # well, which will always be 0), and arbitrarily set to the null string.
122 # Using the example above, there would be two match tables for those two
123 # entries, one named Upper would contain the 0x41..0x5A range, and the other
124 # named Lower would contain 0x61..0x7A.
125 #
126 # Actually, there are two types of range lists, "Range_Map" is the one
127 # associated with map tables, and "Range_List" with match tables.
128 # Again, this is so that methods can be defined on one and not the others so
129 # as to prevent operating on them in incorrect ways.
130 #
131 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
132 # in the perl core.  All tables could in theory be written, but some are
133 # suppressed because there is no current practical use for them.  It is easy
134 # to change which get written by changing various lists that are near the top
135 # of the actual code in this file.  The table data structures contain enough
136 # ancillary information to allow them to be treated as separate entities for
137 # writing, such as the path to each one's file.  There is a heading in each
138 # map table that gives the format of its entries, and what the map is for all
139 # the code points missing from it.  (This allows tables to be more compact.)
140 #
141 # The Property data structure contains one or more tables.  All properties
142 # contain a map table (except the $perl property which is a
143 # pseudo-property containing only match tables), and any properties that
144 # are usable in regular expression matches also contain various matching
145 # tables, one for each value the property can have.  A binary property can
146 # have two values, True and False (or Y and N, which are preferred by Unicode
147 # terminology).  Thus each of these properties will have a map table that
148 # takes every code point and maps it to Y or N (but having ranges cuts the
149 # number of entries in that table way down), and two match tables, one
150 # which has a list of all the code points that map to Y, and one for all the
151 # code points that map to N.  (For each binary property, a third table is also
152 # generated for the pseudo Perl property.  It contains the identical code
153 # points as the Y table, but can be written in regular expressions, not in the
154 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
155 # properties are binary, but some properties have several possible values,
156 # some have many, and properties like Name have a different value for every
157 # named code point.  Those will not, unless the controlling lists are changed,
158 # have their match tables written out.  But all the ones which can be used in
159 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
160 # a property would have either its map table or its match tables written but
161 # not both.  Again, what gets written is controlled by lists which can easily
162 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
163 # tables needed to reconstruct the Unicode db are now written out, while
164 # suppressing the Unicode .txt files that contain the data.  Our tables are
165 # much more compact than the .txt files, so a significant space savings was
166 # achieved.  Also, tables are not written out that are trivially derivable
167 # from tables that do get written.  So, there typically is no file containing
168 # the code points not matched by a binary property (the table for \P{} versus
169 # lowercase \p{}), since you just need to invert the True table to get the
170 # False table.
171
172 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
173 # how many match tables there are and the content of the maps.  This 'Type' is
174 # different than a range 'Type', so don't get confused by the two concepts
175 # having the same name.
176 #
177 # For information about the Unicode properties, see Unicode's UAX44 document:
178
179 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
180
181 # As stated earlier, this program will work on any release of Unicode so far.
182 # Most obvious problems in earlier data have NOT been corrected except when
183 # necessary to make Perl or this program work reasonably, and to keep out
184 # potential security issues.  For example, no folding information was given in
185 # early releases, so this program substitutes lower case instead, just so that
186 # a regular expression with the /i option will do something that actually
187 # gives the right results in many cases.  There are also a couple other
188 # corrections for version 1.1.5, commented at the point they are made.  As an
189 # example of corrections that weren't made (but could be) is this statement
190 # from DerivedAge.txt: "The supplementary private use code points and the
191 # non-character code points were assigned in version 2.0, but not specifically
192 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
193 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
194 # further down in these introductory comments.
195 #
196 # This program works on all non-provisional properties as of the current
197 # Unicode release, though the files for some are suppressed for various
198 # reasons.  You can change which are output by changing lists in this program.
199 #
200 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
201 # loose matchings rules (from Unicode TR18):
202 #
203 #    The recommended names for UCD properties and property values are in
204 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
205 #    [PropValue]. There are both abbreviated names and longer, more
206 #    descriptive names. It is strongly recommended that both names be
207 #    recognized, and that loose matching of property names be used,
208 #    whereby the case distinctions, whitespace, hyphens, and underbar
209 #    are ignored.
210 #
211 # The program still allows Fuzzy to override its determination of if loose
212 # matching should be used, but it isn't currently used, as it is no longer
213 # needed; the calculations it makes are good enough.
214 #
215 # SUMMARY OF HOW IT WORKS:
216 #
217 #   Process arguments
218 #
219 #   A list is constructed containing each input file that is to be processed
220 #
221 #   Each file on the list is processed in a loop, using the associated handler
222 #   code for each:
223 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
224 #            first.  These files name the properties and property values.
225 #            Objects are created of all the property and property value names
226 #            that the rest of the input should expect, including all synonyms.
227 #        The other input files give mappings from properties to property
228 #           values.  That is, they list code points and say what the mapping
229 #           is under the given property.  Some files give the mappings for
230 #           just one property; and some for many.  This program goes through
231 #           each file and populates the properties and their map tables from
232 #           them.  Some properties are listed in more than one file, and
233 #           Unicode has set up a precedence as to which has priority if there
234 #           is a conflict.  Thus the order of processing matters, and this
235 #           program handles the conflict possibility by processing the
236 #           overriding input files last, so that if necessary they replace
237 #           earlier values.
238 #        After this is all done, the program creates the property mappings not
239 #            furnished by Unicode, but derivable from what it does give.
240 #        The tables of code points that match each property value in each
241 #            property that is accessible by regular expressions are created.
242 #        The Perl-defined properties are created and populated.  Many of these
243 #            require data determined from the earlier steps
244 #        Any Perl-defined synonyms are created, and name clashes between Perl
245 #            and Unicode are reconciled and warned about.
246 #        All the properties are written to files
247 #        Any other files are written, and final warnings issued.
248 #
249 # For clarity, a number of operators have been overloaded to work on tables:
250 #   ~ means invert (take all characters not in the set).  The more
251 #       conventional '!' is not used because of the possibility of confusing
252 #       it with the actual boolean operation.
253 #   + means union
254 #   - means subtraction
255 #   & means intersection
256 # The precedence of these is the order listed.  Parentheses should be
257 # copiously used.  These are not a general scheme.  The operations aren't
258 # defined for a number of things, deliberately, to avoid getting into trouble.
259 # Operations are done on references and affect the underlying structures, so
260 # that the copy constructors for them have been overloaded to not return a new
261 # clone, but the input object itself.
262 #
263 # The bool operator is deliberately not overloaded to avoid confusion with
264 # "should it mean if the object merely exists, or also is non-empty?".
265 #
266 # WHY CERTAIN DESIGN DECISIONS WERE MADE
267 #
268 # This program needs to be able to run under miniperl.  Therefore, it uses a
269 # minimum of other modules, and hence implements some things itself that could
270 # be gotten from CPAN
271 #
272 # This program uses inputs published by the Unicode Consortium.  These can
273 # change incompatibly between releases without the Perl maintainers realizing
274 # it.  Therefore this program is now designed to try to flag these.  It looks
275 # at the directories where the inputs are, and flags any unrecognized files.
276 # It keeps track of all the properties in the files it handles, and flags any
277 # that it doesn't know how to handle.  It also flags any input lines that
278 # don't match the expected syntax, among other checks.
279 #
280 # It is also designed so if a new input file matches one of the known
281 # templates, one hopefully just needs to add it to a list to have it
282 # processed.
283 #
284 # As mentioned earlier, some properties are given in more than one file.  In
285 # particular, the files in the extracted directory are supposedly just
286 # reformattings of the others.  But they contain information not easily
287 # derivable from the other files, including results for Unihan (which isn't
288 # usually available to this program) and for unassigned code points.  They
289 # also have historically had errors or been incomplete.  In an attempt to
290 # create the best possible data, this program thus processes them first to
291 # glean information missing from the other files; then processes those other
292 # files to override any errors in the extracted ones.  Much of the design was
293 # driven by this need to store things and then possibly override them.
294 #
295 # It tries to keep fatal errors to a minimum, to generate something usable for
296 # testing purposes.  It always looks for files that could be inputs, and will
297 # warn about any that it doesn't know how to handle (the -q option suppresses
298 # the warning).
299 #
300 # Why is there more than one type of range?
301 #   This simplified things.  There are some very specialized code points that
302 #   have to be handled specially for output, such as Hangul syllable names.
303 #   By creating a range type (done late in the development process), it
304 #   allowed this to be stored with the range, and overridden by other input.
305 #   Originally these were stored in another data structure, and it became a
306 #   mess trying to decide if a second file that was for the same property was
307 #   overriding the earlier one or not.
308 #
309 # Why are there two kinds of tables, match and map?
310 #   (And there is a base class shared by the two as well.)  As stated above,
311 #   they actually are for different things.  Development proceeded much more
312 #   smoothly when I (khw) realized the distinction.  Map tables are used to
313 #   give the property value for every code point (actually every code point
314 #   that doesn't map to a default value).  Match tables are used for regular
315 #   expression matches, and are essentially the inverse mapping.  Separating
316 #   the two allows more specialized methods, and error checks so that one
317 #   can't just take the intersection of two map tables, for example, as that
318 #   is nonsensical.
319 #
320 # What about 'fate' and 'status'.  The concept of a table's fate was created
321 #   late when it became clear that something more was needed.  The difference
322 #   between this and 'status' is unclean, and could be improved if someone
323 #   wanted to spend the effort.
324 #
325 # DEBUGGING
326 #
327 # This program is written so it will run under miniperl.  Occasionally changes
328 # will cause an error where the backtrace doesn't work well under miniperl.
329 # To diagnose the problem, you can instead run it under regular perl, if you
330 # have one compiled.
331 #
332 # There is a good trace facility.  To enable it, first sub DEBUG must be set
333 # to return true.  Then a line like
334 #
335 # local $to_trace = 1 if main::DEBUG;
336 #
337 # can be added to enable tracing in its lexical scope (plus dynamic) or until
338 # you insert another line:
339 #
340 # local $to_trace = 0 if main::DEBUG;
341 #
342 # To actually trace, use a line like "trace $a, @b, %c, ...;
343 #
344 # Some of the more complex subroutines already have trace statements in them.
345 # Permanent trace statements should be like:
346 #
347 # trace ... if main::DEBUG && $to_trace;
348 #
349 # If there is just one or a few files that you're debugging, you can easily
350 # cause most everything else to be skipped.  Change the line
351 #
352 # my $debug_skip = 0;
353 #
354 # to 1, and every file whose object is in @input_file_objects and doesn't have
355 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
356 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
357 #
358 # To compare the output tables, it may be useful to specify the -annotate
359 # flag.  (As of this writing, this can't be done on a clean workspace, due to
360 # requirements in Text::Tabs used in this option; so first run mktables
361 # without this option.)  This option adds comment lines to each table, one for
362 # each non-algorithmically named character giving, currently its code point,
363 # name, and graphic representation if printable (and you have a font that
364 # knows about it).  This makes it easier to see what the particular code
365 # points are in each output table.  Non-named code points are annotated with a
366 # description of their status, and contiguous ones with the same description
367 # will be output as a range rather than individually.  Algorithmically named
368 # characters are also output as ranges, except when there are just a few
369 # contiguous ones.
370 #
371 # FUTURE ISSUES
372 #
373 # The program would break if Unicode were to change its names so that
374 # interior white space, underscores, or dashes differences were significant
375 # within property and property value names.
376 #
377 # It might be easier to use the xml versions of the UCD if this program ever
378 # would need heavy revision, and the ability to handle old versions was not
379 # required.
380 #
381 # There is the potential for name collisions, in that Perl has chosen names
382 # that Unicode could decide it also likes.  There have been such collisions in
383 # the past, with mostly Perl deciding to adopt the Unicode definition of the
384 # name.  However in the 5.2 Unicode beta testing, there were a number of such
385 # collisions, which were withdrawn before the final release, because of Perl's
386 # and other's protests.  These all involved new properties which began with
387 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
388 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
389 # Unicode document, so they are unlikely to be used by Unicode for another
390 # purpose.  However, they might try something beginning with 'In', or use any
391 # of the other Perl-defined properties.  This program will warn you of name
392 # collisions, and refuse to generate tables with them, but manual intervention
393 # will be required in this event.  One scheme that could be implemented, if
394 # necessary, would be to have this program generate another file, or add a
395 # field to mktables.lst that gives the date of first definition of a property.
396 # Each new release of Unicode would use that file as a basis for the next
397 # iteration.  And the Perl synonym addition code could sort based on the age
398 # of the property, so older properties get priority, and newer ones that clash
399 # would be refused; hence existing code would not be impacted, and some other
400 # synonym would have to be used for the new property.  This is ugly, and
401 # manual intervention would certainly be easier to do in the short run; lets
402 # hope it never comes to this.
403 #
404 # A NOTE ON UNIHAN
405 #
406 # This program can generate tables from the Unihan database.  But it doesn't
407 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
408 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
409 # database was split into 8 different files, all beginning with the letters
410 # 'Unihan'.  This program will read those file(s) if present, but it needs to
411 # know which of the many properties in the file(s) should have tables created
412 # for them.  It will create tables for any properties listed in
413 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
414 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
415 # property you want is not in those files of the release you are building
416 # against, you must add it to those two arrays.  Starting in 4.0, the
417 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
418 # is present in the directory, a table will be generated for that property.
419 # In 5.2, several more properties were added.  For your convenience, the two
420 # arrays are initialized with all the 6.0 listed properties that are also in
421 # earlier releases.  But these are commented out.  You can just uncomment the
422 # ones you want, or use them as a template for adding entries for other
423 # properties.
424 #
425 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
426 # and filter_unihan_line() are the functions where this is done.  This program
427 # already does some adjusting to make the lines look more like the rest of the
428 # Unicode DB;  You can see what that is in filter_unihan_line()
429 #
430 # There is a bug in the 3.2 data file in which some values for the
431 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
432 # could be added to correct these; or for a particular installation, the
433 # Unihan.txt file could be edited to fix them.
434 #
435 # HOW TO ADD A FILE TO BE PROCESSED
436 #
437 # A new file from Unicode needs to have an object constructed for it in
438 # @input_file_objects, probably at the end or at the end of the extracted
439 # ones.  The program should warn you if its name will clash with others on
440 # restrictive file systems, like DOS.  If so, figure out a better name, and
441 # add lines to the README.perl file giving that.  If the file is a character
442 # property, it should be in the format that Unicode has implicitly
443 # standardized for such files for the more recently introduced ones.
444 # If so, the Input_file constructor for @input_file_objects can just be the
445 # file name and release it first appeared in.  If not, then it should be
446 # possible to construct an each_line_handler() to massage the line into the
447 # standardized form.
448 #
449 # For non-character properties, more code will be needed.  You can look at
450 # the existing entries for clues.
451 #
452 # UNICODE VERSIONS NOTES
453 #
454 # The Unicode UCD has had a number of errors in it over the versions.  And
455 # these remain, by policy, in the standard for that version.  Therefore it is
456 # risky to correct them, because code may be expecting the error.  So this
457 # program doesn't generally make changes, unless the error breaks the Perl
458 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
459 # for U+1105, which causes real problems for the algorithms for Jamo
460 # calculations, so it is changed here.
461 #
462 # But it isn't so clear cut as to what to do about concepts that are
463 # introduced in a later release; should they extend back to earlier releases
464 # where the concept just didn't exist?  It was easier to do this than to not,
465 # so that's what was done.  For example, the default value for code points not
466 # in the files for various properties was probably undefined until changed by
467 # some version.  No_Block for blocks is such an example.  This program will
468 # assign No_Block even in Unicode versions that didn't have it.  This has the
469 # benefit that code being written doesn't have to special case earlier
470 # versions; and the detriment that it doesn't match the Standard precisely for
471 # the affected versions.
472 #
473 # Here are some observations about some of the issues in early versions:
474 #
475 # Prior to version 3.0, there were 3 character decompositions.  These are not
476 # handled by Unicode::Normalize, nor will it compile when presented a version
477 # that has them.  However, you can trivially get it to compile by simply
478 # ignoring those decompositions, by changing the croak to a carp.  At the time
479 # of this writing, the line (in cpan/Unicode-Normalize/Normalize.pm or
480 # cpan/Unicode-Normalize/mkheader) reads
481 #
482 #   croak("Weird Canonical Decomposition of U+$h");
483 #
484 # Simply comment it out.  It will compile, but will not know about any three
485 # character decompositions.
486
487 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
488 # that the reason is that the CJK block starting at 4E00 was removed from
489 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
490 # single property name \p{alpha}) has the correct values.  But the compound
491 # form is simply not generated until 3.1, as it can be argued that prior to
492 # this release, this was not an official property.  The comments for
493 # filter_old_style_proplist() give more details.
494 #
495 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
496 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
497 # reason is that 3.2 introduced U+205F=medium math space, which was not
498 # classed as white space, but Perl figured out that it should have been. 4.0
499 # reclassified it correctly.
500 #
501 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
502 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
503 # became 202, and ATBL was left with no code points, as all the ones that
504 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
505 # name for the class, it would not have been affected, but if it used the
506 # mnemonic, it would have been.
507 #
508 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that, code
509 # points which eventually came to have this script property value, instead
510 # mapped to "Unknown".  But in the next release all these code points were
511 # moved to \p{sc=common} instead.
512
513 # The tests furnished  by Unicode for testing WordBreak and SentenceBreak
514 # generate errors in 5.0 and earlier.
515 #
516 # The default for missing code points for BidiClass is complicated.  Starting
517 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
518 # tries to do the best it can for earlier releases.  It is done in
519 # process_PropertyAliases()
520 #
521 # In version 2.1.2, the entry in UnicodeData.txt:
522 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
523 # should instead be
524 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
525 # Without this change, there are casing problems for this character.
526 #
527 # Search for $string_compare_versions to see how to compare changes to
528 # properties between Unicode versions
529 #
530 ##############################################################################
531
532 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
533                         # and errors
534 my $MAX_LINE_WIDTH = 78;
535
536 # Debugging aid to skip most files so as to not be distracted by them when
537 # concentrating on the ones being debugged.  Add
538 # non_skip => 1,
539 # to the constructor for those files you want processed when you set this.
540 # Files with a first version number of 0 are special: they are always
541 # processed regardless of the state of this flag.  Generally, Jamo.txt and
542 # UnicodeData.txt must not be skipped if you want this program to not die
543 # before normal completion.
544 my $debug_skip = 0;
545
546
547 # Normally these are suppressed.
548 my $write_Unicode_deprecated_tables = 0;
549
550 # Set to 1 to enable tracing.
551 our $to_trace = 0;
552
553 { # Closure for trace: debugging aid
554     my $print_caller = 1;        # ? Include calling subroutine name
555     my $main_with_colon = 'main::';
556     my $main_colon_length = length($main_with_colon);
557
558     sub trace {
559         return unless $to_trace;        # Do nothing if global flag not set
560
561         my @input = @_;
562
563         local $DB::trace = 0;
564         $DB::trace = 0;          # Quiet 'used only once' message
565
566         my $line_number;
567
568         # Loop looking up the stack to get the first non-trace caller
569         my $caller_line;
570         my $caller_name;
571         my $i = 0;
572         do {
573             $line_number = $caller_line;
574             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
575             $caller = $main_with_colon unless defined $caller;
576
577             $caller_name = $caller;
578
579             # get rid of pkg
580             $caller_name =~ s/.*:://;
581             if (substr($caller_name, 0, $main_colon_length)
582                 eq $main_with_colon)
583             {
584                 $caller_name = substr($caller_name, $main_colon_length);
585             }
586
587         } until ($caller_name ne 'trace');
588
589         # If the stack was empty, we were called from the top level
590         $caller_name = 'main' if ($caller_name eq ""
591                                     || $caller_name eq 'trace');
592
593         my $output = "";
594         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
595         foreach my $string (@input) {
596             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
597                 $output .= simple_dumper($string);
598             }
599             else {
600                 $string = "$string" if ref $string;
601                 $string = $UNDEF unless defined $string;
602                 chomp $string;
603                 $string = '""' if $string eq "";
604                 $output .= " " if $output ne ""
605                                 && $string ne ""
606                                 && substr($output, -1, 1) ne " "
607                                 && substr($string, 0, 1) ne " ";
608                 $output .= $string;
609             }
610         }
611
612         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
613         print STDERR "$caller_name: " if $print_caller;
614         print STDERR $output, "\n";
615         return;
616     }
617 }
618
619 # This is for a rarely used development feature that allows you to compare two
620 # versions of the Unicode standard without having to deal with changes caused
621 # by the code points introduced in the later version.  You probably also want
622 # to use the -annotate option when using this.  Change the 0 to a string
623 # containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only code
624 # points introduced in that release and earlier will be used; later ones are
625 # thrown away.  You use the version number of the earliest one you want to
626 # compare; then run this program on directory structures containing each
627 # release, and compare the outputs.  These outputs will therefore include only
628 # the code points common to both releases, and you can see the changes caused
629 # just by the underlying release semantic changes.  For versions earlier than
630 # 3.2, you must copy a version of DAge.txt into the directory.
631 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
632 my $compare_versions = DEBUG
633                        && $string_compare_versions
634                        && pack "C*", split /\./, $string_compare_versions;
635
636 sub uniques {
637     # Returns non-duplicated input values.  From "Perl Best Practices:
638     # Encapsulated Cleverness".  p. 455 in first edition.
639
640     my %seen;
641     # Arguably this breaks encapsulation, if the goal is to permit multiple
642     # distinct objects to stringify to the same value, and be interchangeable.
643     # However, for this program, no two objects stringify identically, and all
644     # lists passed to this function are either objects or strings. So this
645     # doesn't affect correctness, but it does give a couple of percent speedup.
646     no overloading;
647     return grep { ! $seen{$_}++ } @_;
648 }
649
650 $0 = File::Spec->canonpath($0);
651
652 my $make_test_script = 0;      # ? Should we output a test script
653 my $make_norm_test_script = 0; # ? Should we output a normalization test script
654 my $write_unchanged_files = 0; # ? Should we update the output files even if
655                                #    we don't think they have changed
656 my $use_directory = "";        # ? Should we chdir somewhere.
657 my $pod_directory;             # input directory to store the pod file.
658 my $pod_file = 'perluniprops';
659 my $t_path;                     # Path to the .t test file
660 my $file_list = 'mktables.lst'; # File to store input and output file names.
661                                # This is used to speed up the build, by not
662                                # executing the main body of the program if
663                                # nothing on the list has changed since the
664                                # previous build
665 my $make_list = 1;             # ? Should we write $file_list.  Set to always
666                                # make a list so that when the pumpking is
667                                # preparing a release, s/he won't have to do
668                                # special things
669 my $glob_list = 0;             # ? Should we try to include unknown .txt files
670                                # in the input.
671 my $output_range_counts = $debugging_build;   # ? Should we include the number
672                                               # of code points in ranges in
673                                               # the output
674 my $annotate = 0;              # ? Should character names be in the output
675
676 # Verbosity levels; 0 is quiet
677 my $NORMAL_VERBOSITY = 1;
678 my $PROGRESS = 2;
679 my $VERBOSE = 3;
680
681 my $verbosity = $NORMAL_VERBOSITY;
682
683 # Stored in mktables.lst so that if this program is called with different
684 # options, will regenerate even if the files otherwise look like they're
685 # up-to-date.
686 my $command_line_arguments = join " ", @ARGV;
687
688 # Process arguments
689 while (@ARGV) {
690     my $arg = shift @ARGV;
691     if ($arg eq '-v') {
692         $verbosity = $VERBOSE;
693     }
694     elsif ($arg eq '-p') {
695         $verbosity = $PROGRESS;
696         $| = 1;     # Flush buffers as we go.
697     }
698     elsif ($arg eq '-q') {
699         $verbosity = 0;
700     }
701     elsif ($arg eq '-w') {
702         $write_unchanged_files = 1; # update the files even if havent changed
703     }
704     elsif ($arg eq '-check') {
705         my $this = shift @ARGV;
706         my $ok = shift @ARGV;
707         if ($this ne $ok) {
708             print "Skipping as check params are not the same.\n";
709             exit(0);
710         }
711     }
712     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
713         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
714     }
715     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
716     {
717         $make_test_script = 1;
718     }
719     elsif ($arg eq '-makenormtest')
720     {
721         $make_norm_test_script = 1;
722     }
723     elsif ($arg eq '-makelist') {
724         $make_list = 1;
725     }
726     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
727         -d $use_directory or croak "Unknown directory '$use_directory'";
728     }
729     elsif ($arg eq '-L') {
730
731         # Existence not tested until have chdir'd
732         $file_list = shift;
733     }
734     elsif ($arg eq '-globlist') {
735         $glob_list = 1;
736     }
737     elsif ($arg eq '-c') {
738         $output_range_counts = ! $output_range_counts
739     }
740     elsif ($arg eq '-annotate') {
741         $annotate = 1;
742         $debugging_build = 1;
743         $output_range_counts = 1;
744     }
745     else {
746         my $with_c = 'with';
747         $with_c .= 'out' if $output_range_counts;   # Complements the state
748         croak <<END;
749 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
750           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
751           [-check A B ]
752   -c          : Output comments $with_c number of code points in ranges
753   -q          : Quiet Mode: Only output serious warnings.
754   -p          : Set verbosity level to normal plus show progress.
755   -v          : Set Verbosity level high:  Show progress and non-serious
756                 warnings
757   -w          : Write files regardless
758   -C dir      : Change to this directory before proceeding. All relative paths
759                 except those specified by the -P and -T options will be done
760                 with respect to this directory.
761   -P dir      : Output $pod_file file to directory 'dir'.
762   -T path     : Create a test script as 'path'; overrides -maketest
763   -L filelist : Use alternate 'filelist' instead of standard one
764   -globlist   : Take as input all non-Test *.txt files in current and sub
765                 directories
766   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
767                 overrides -T
768   -makelist   : Rewrite the file list $file_list based on current setup
769   -annotate   : Output an annotation for each character in the table files;
770                 useful for debugging mktables, looking at diffs; but is slow
771                 and memory intensive
772   -check A B  : Executes $0 only if A and B are the same
773 END
774     }
775 }
776
777 # Stores the most-recently changed file.  If none have changed, can skip the
778 # build
779 my $most_recent = (stat $0)[9];   # Do this before the chdir!
780
781 # Change directories now, because need to read 'version' early.
782 if ($use_directory) {
783     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
784         $pod_directory = File::Spec->rel2abs($pod_directory);
785     }
786     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
787         $t_path = File::Spec->rel2abs($t_path);
788     }
789     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
790     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
791         $pod_directory = File::Spec->abs2rel($pod_directory);
792     }
793     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
794         $t_path = File::Spec->abs2rel($t_path);
795     }
796 }
797
798 # Get Unicode version into regular and v-string.  This is done now because
799 # various tables below get populated based on it.  These tables are populated
800 # here to be near the top of the file, and so easily seeable by those needing
801 # to modify things.
802 open my $VERSION, "<", "version"
803                     or croak "$0: can't open required file 'version': $!\n";
804 my $string_version = <$VERSION>;
805 close $VERSION;
806 chomp $string_version;
807 my $v_version = pack "C*", split /\./, $string_version;        # v string
808
809 # The following are the complete names of properties with property values that
810 # are known to not match any code points in some versions of Unicode, but that
811 # may change in the future so they should be matchable, hence an empty file is
812 # generated for them.
813 my @tables_that_may_be_empty;
814 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
815                                                     if $v_version lt v6.3.0;
816 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
817 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
818 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
819                                                     if $v_version ge v4.1.0;
820 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
821                                                     if $v_version ge v6.0.0;
822 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
823                                                     if $v_version ge v6.1.0;
824 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
825                                                     if $v_version ge v6.2.0;
826
827 # The lists below are hashes, so the key is the item in the list, and the
828 # value is the reason why it is in the list.  This makes generation of
829 # documentation easier.
830
831 my %why_suppressed;  # No file generated for these.
832
833 # Files aren't generated for empty extraneous properties.  This is arguable.
834 # Extraneous properties generally come about because a property is no longer
835 # used in a newer version of Unicode.  If we generated a file without code
836 # points, programs that used to work on that property will still execute
837 # without errors.  It just won't ever match (or will always match, with \P{}).
838 # This means that the logic is now likely wrong.  I (khw) think its better to
839 # find this out by getting an error message.  Just move them to the table
840 # above to change this behavior
841 my %why_suppress_if_empty_warn_if_not = (
842
843    # It is the only property that has ever officially been removed from the
844    # Standard.  The database never contained any code points for it.
845    'Special_Case_Condition' => 'Obsolete',
846
847    # Apparently never official, but there were code points in some versions of
848    # old-style PropList.txt
849    'Non_Break' => 'Obsolete',
850 );
851
852 # These would normally go in the warn table just above, but they were changed
853 # a long time before this program was written, so warnings about them are
854 # moot.
855 if ($v_version gt v3.2.0) {
856     push @tables_that_may_be_empty,
857                                 'Canonical_Combining_Class=Attached_Below_Left'
858 }
859
860 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
861 # unless explicitly added.
862 if ($v_version ge v5.2.0 && ! $write_Unicode_deprecated_tables) {
863     my $unihan = 'Unihan; remove from list if using Unihan';
864     foreach my $table (qw (
865                            kAccountingNumeric
866                            kOtherNumeric
867                            kPrimaryNumeric
868                            kCompatibilityVariant
869                            kIICore
870                            kIRG_GSource
871                            kIRG_HSource
872                            kIRG_JSource
873                            kIRG_KPSource
874                            kIRG_MSource
875                            kIRG_KSource
876                            kIRG_TSource
877                            kIRG_USource
878                            kIRG_VSource
879                            kRSUnicode
880                         ))
881     {
882         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
883     }
884 }
885
886 # Enum values for to_output_map() method in the Map_Table package. (0 is don't
887 # output)
888 my $EXTERNAL_MAP = 1;
889 my $INTERNAL_MAP = 2;
890 my $OUTPUT_ADJUSTED = 3;
891
892 # To override computed values for writing the map tables for these properties.
893 # The default for enum map tables is to write them out, so that the Unicode
894 # .txt files can be removed, but all the data to compute any property value
895 # for any code point is available in a more compact form.
896 my %global_to_output_map = (
897     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
898     # get stuck supporting it if things change.  Since it is a STRING
899     # property, it normally would be listed in the pod, but INTERNAL_MAP
900     # suppresses that.
901     Unicode_1_Name => $INTERNAL_MAP,
902
903     Present_In => 0,                # Suppress, as easily computed from Age
904     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
905                                             # retained, but needed for
906                                             # non-ASCII
907
908     # Suppress, as mapping can be found instead from the
909     # Perl_Decomposition_Mapping file
910     Decomposition_Type => 0,
911 );
912
913 # Properties that this program ignores.
914 my @unimplemented_properties;
915
916 # With this release, it is automatically handled if the Unihan db is
917 # downloaded
918 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version lt v5.2.0;
919
920 # There are several types of obsolete properties defined by Unicode.  These
921 # must be hand-edited for every new Unicode release.
922 my %why_deprecated;  # Generates a deprecated warning message if used.
923 my %why_stabilized;  # Documentation only
924 my %why_obsolete;    # Documentation only
925
926 {   # Closure
927     my $simple = 'Perl uses the more complete version';
928     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
929
930     my $other_properties = 'other properties';
931     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
932     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
933
934     %why_deprecated = (
935         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
936         'Jamo_Short_Name' => $contributory,
937         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
938         'Other_Alphabetic' => $contributory,
939         'Other_Default_Ignorable_Code_Point' => $contributory,
940         'Other_Grapheme_Extend' => $contributory,
941         'Other_ID_Continue' => $contributory,
942         'Other_ID_Start' => $contributory,
943         'Other_Lowercase' => $contributory,
944         'Other_Math' => $contributory,
945         'Other_Uppercase' => $contributory,
946         'Expands_On_NFC' => $why_no_expand,
947         'Expands_On_NFD' => $why_no_expand,
948         'Expands_On_NFKC' => $why_no_expand,
949         'Expands_On_NFKD' => $why_no_expand,
950     );
951
952     %why_suppressed = (
953         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
954         # contains the same information, but without the algorithmically
955         # determinable Hangul syllables'.  This file is not published, so it's
956         # existence is not noted in the comment.
957         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
958
959         'Indic_Matra_Category' => "Withdrawn by Unicode while still provisional",
960
961         # Don't suppress ISO_Comment, as otherwise special handling is needed
962         # to differentiate between it and gc=c, which can be written as 'isc',
963         # which is the same characters as ISO_Comment's short name.
964
965         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
966
967         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
968         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
969         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
970         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
971
972         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
973     );
974
975     foreach my $property (
976
977             # The following are suppressed because they were made contributory
978             # or deprecated by Unicode before Perl ever thought about
979             # supporting them.
980             'Jamo_Short_Name',
981             'Grapheme_Link',
982             'Expands_On_NFC',
983             'Expands_On_NFD',
984             'Expands_On_NFKC',
985             'Expands_On_NFKD',
986
987             # The following are suppressed because they have been marked
988             # as deprecated for a sufficient amount of time
989             'Other_Alphabetic',
990             'Other_Default_Ignorable_Code_Point',
991             'Other_Grapheme_Extend',
992             'Other_ID_Continue',
993             'Other_ID_Start',
994             'Other_Lowercase',
995             'Other_Math',
996             'Other_Uppercase',
997     ) {
998         $why_suppressed{$property} = $why_deprecated{$property};
999     }
1000
1001     # Customize the message for all the 'Other_' properties
1002     foreach my $property (keys %why_deprecated) {
1003         next if (my $main_property = $property) !~ s/^Other_//;
1004         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1005     }
1006 }
1007
1008 if ($write_Unicode_deprecated_tables) {
1009     foreach my $property (keys %why_suppressed) {
1010         delete $why_suppressed{$property} if $property =~
1011                                                     / ^ Other | Grapheme /x;
1012     }
1013 }
1014
1015 if ($v_version ge 4.0.0) {
1016     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1017     if ($v_version ge 6.0.0) {
1018         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1019     }
1020 }
1021 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1022     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1023     if ($v_version ge 6.0.0) {
1024         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1025     }
1026 }
1027
1028 # Probably obsolete forever
1029 if ($v_version ge v4.1.0) {
1030     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1031 }
1032 if ($v_version ge v6.0.0) {
1033     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1034     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1035 }
1036
1037 # This program can create files for enumerated-like properties, such as
1038 # 'Numeric_Type'.  This file would be the same format as for a string
1039 # property, with a mapping from code point to its value, so you could look up,
1040 # for example, the script a code point is in.  But no one so far wants this
1041 # mapping, or they have found another way to get it since this is a new
1042 # feature.  So no file is generated except if it is in this list.
1043 my @output_mapped_properties = split "\n", <<END;
1044 END
1045
1046 # If you are using the Unihan database in a Unicode version before 5.2, you
1047 # need to add the properties that you want to extract from it to this table.
1048 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
1049 # listed, commented out
1050 my @cjk_properties = split "\n", <<'END';
1051 #cjkAccountingNumeric; kAccountingNumeric
1052 #cjkOtherNumeric; kOtherNumeric
1053 #cjkPrimaryNumeric; kPrimaryNumeric
1054 #cjkCompatibilityVariant; kCompatibilityVariant
1055 #cjkIICore ; kIICore
1056 #cjkIRG_GSource; kIRG_GSource
1057 #cjkIRG_HSource; kIRG_HSource
1058 #cjkIRG_JSource; kIRG_JSource
1059 #cjkIRG_KPSource; kIRG_KPSource
1060 #cjkIRG_KSource; kIRG_KSource
1061 #cjkIRG_TSource; kIRG_TSource
1062 #cjkIRG_USource; kIRG_USource
1063 #cjkIRG_VSource; kIRG_VSource
1064 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1065 END
1066
1067 # Similarly for the property values.  For your convenience, the lines in the
1068 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1069 # '#' marks (for Unicode versions before 5.2)
1070 my @cjk_property_values = split "\n", <<'END';
1071 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1072 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1073 ## @missing: 0000..10FFFF; cjkIICore; <none>
1074 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1075 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1076 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1077 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1078 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1079 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1080 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1081 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1082 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1083 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1084 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1085 END
1086
1087 # The input files don't list every code point.  Those not listed are to be
1088 # defaulted to some value.  Below are hard-coded what those values are for
1089 # non-binary properties as of 5.1.  Starting in 5.0, there are
1090 # machine-parsable comment lines in the files that give the defaults; so this
1091 # list shouldn't have to be extended.  The claim is that all missing entries
1092 # for binary properties will default to 'N'.  Unicode tried to change that in
1093 # 5.2, but the beta period produced enough protest that they backed off.
1094 #
1095 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1096 # be in the form that it expects.  The others may be synonyms.
1097 my $CODE_POINT = '<code point>';
1098 my %default_mapping = (
1099     Age => "Unassigned",
1100     # Bidi_Class => Complicated; set in code
1101     Bidi_Mirroring_Glyph => "",
1102     Block => 'No_Block',
1103     Canonical_Combining_Class => 0,
1104     Case_Folding => $CODE_POINT,
1105     Decomposition_Mapping => $CODE_POINT,
1106     Decomposition_Type => 'None',
1107     East_Asian_Width => "Neutral",
1108     FC_NFKC_Closure => $CODE_POINT,
1109     General_Category => ($v_version le 6.3.0) ? 'Cn' : 'Unassigned',
1110     Grapheme_Cluster_Break => 'Other',
1111     Hangul_Syllable_Type => 'NA',
1112     ISO_Comment => "",
1113     Jamo_Short_Name => "",
1114     Joining_Group => "No_Joining_Group",
1115     # Joining_Type => Complicated; set in code
1116     kIICore => 'N',   #                       Is converted to binary
1117     #Line_Break => Complicated; set in code
1118     Lowercase_Mapping => $CODE_POINT,
1119     Name => "",
1120     Name_Alias => "",
1121     NFC_QC => 'Yes',
1122     NFD_QC => 'Yes',
1123     NFKC_QC => 'Yes',
1124     NFKD_QC => 'Yes',
1125     Numeric_Type => 'None',
1126     Numeric_Value => 'NaN',
1127     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1128     Sentence_Break => 'Other',
1129     Simple_Case_Folding => $CODE_POINT,
1130     Simple_Lowercase_Mapping => $CODE_POINT,
1131     Simple_Titlecase_Mapping => $CODE_POINT,
1132     Simple_Uppercase_Mapping => $CODE_POINT,
1133     Titlecase_Mapping => $CODE_POINT,
1134     Unicode_1_Name => "",
1135     Unicode_Radical_Stroke => "",
1136     Uppercase_Mapping => $CODE_POINT,
1137     Word_Break => 'Other',
1138 );
1139
1140 # Below are files that Unicode furnishes, but this program ignores, and why.
1141 # NormalizationCorrections.txt requires some more explanation.  It documents
1142 # the cumulative fixes to erroneous normalizations in earlier Unicode
1143 # versions.  Its main purpose is so that someone running on an earlier version
1144 # can use this file to override what got published in that earlier release.
1145 # It would be easy for mktables to read and handle this file.  But all the
1146 # corrections in it should already be in the other files for the release it
1147 # is.  To get it to actually mean something useful, someone would have to be
1148 # using an earlier Unicode release, and copy it to the files for that release
1149 # and recomplile.  So far there has been no demand to do that, so this hasn't
1150 # been implemented.
1151 my %ignored_files = (
1152     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1153     'Index.txt' => 'Alphabetical index of Unicode characters',
1154     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1155     'NamesList.txt' => 'Annotated list of characters',
1156     'NamesList.html' => 'Describes the format and contents of F<NamesList.txt>',
1157     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1158     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1159     'ReadMe.txt' => 'Documentation',
1160     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1161     'StandardizedVariants.html' => 'Provides a visual display of the standard variant sequences derived from F<StandardizedVariants.txt>.',
1162     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1163     'USourceData.txt' => 'Documentation of status and cross reference of proposals for encoding by Unicode of Unihan characters',
1164     'USourceGlyphs.pdf' => 'Pictures of the characters in F<USourceData.txt>',
1165     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1166     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1167     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1168     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1169 );
1170
1171 my %skipped_files;  # List of files that we skip
1172
1173 ### End of externally interesting definitions, except for @input_file_objects
1174
1175 my $HEADER=<<"EOF";
1176 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1177 # This file is machine-generated by $0 from the Unicode
1178 # database, Version $string_version.  Any changes made here will be lost!
1179 EOF
1180
1181 my $INTERNAL_ONLY_HEADER = <<"EOF";
1182
1183 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1184 # This file is for internal use by core Perl only.  The format and even the
1185 # name or existence of this file are subject to change without notice.  Don't
1186 # use it directly.  Use Unicode::UCD to access the Unicode character data
1187 # base.
1188 EOF
1189
1190 my $DEVELOPMENT_ONLY=<<"EOF";
1191 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1192 # This file contains information artificially constrained to code points
1193 # present in Unicode release $string_compare_versions.
1194 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1195 # not be used for production.
1196
1197 EOF
1198
1199 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1200                                    ? "10FFFF"
1201                                    : "FFFF";
1202 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1203 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1204
1205 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1206 # that high, above IV_MAX, some operations don't work, and you can easily get
1207 # overflow.  Therefore for internal use, we use a much smaller number,
1208 # translating it to UV_MAX only for output.  The exact number is immaterial
1209 # (all Unicode code points are treated exactly the same), but the algorithm
1210 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1211 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1212 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1213 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1214
1215 my $MAX_PLATFORM_CODEPOINT = ~0;
1216
1217 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1218 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1219 # to decrease backtracking.  The first regex allows the code point to be at
1220 # the end of a word, but to work properly, the word shouldn't end with a valid
1221 # hex character.  The second one won't match a code point at the end of a
1222 # word, and doesn't have the run-on issue
1223 my $run_on_code_point_re =
1224             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1225 my $code_point_re = qr/\b$run_on_code_point_re/;
1226
1227 # This matches the beginning of the line in the Unicode db files that give the
1228 # defaults for code points not listed (i.e., missing) in the file.  The code
1229 # depends on this ending with a semi-colon, so it can assume it is a valid
1230 # field when the line is split() by semi-colons
1231 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1232
1233 # Property types.  Unicode has more types, but these are sufficient for our
1234 # purposes.
1235 my $UNKNOWN = -1;   # initialized to illegal value
1236 my $NON_STRING = 1; # Either binary or enum
1237 my $BINARY = 2;
1238 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1239                        # tables, additional true and false tables are
1240                        # generated so that false is anything matching the
1241                        # default value, and true is everything else.
1242 my $ENUM = 4;       # Include catalog
1243 my $STRING = 5;     # Anything else: string or misc
1244
1245 # Some input files have lines that give default values for code points not
1246 # contained in the file.  Sometimes these should be ignored.
1247 my $NO_DEFAULTS = 0;        # Must evaluate to false
1248 my $NOT_IGNORED = 1;
1249 my $IGNORED = 2;
1250
1251 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1252 # and will appear in the main body of the tables in the output files, but
1253 # there are other types of ranges as well, listed below, that are specially
1254 # handled.   There are pseudo-types as well that will never be stored as a
1255 # type, but will affect the calculation of the type.
1256
1257 # 0 is for normal, non-specials
1258 my $MULTI_CP = 1;           # Sequence of more than code point
1259 my $HANGUL_SYLLABLE = 2;
1260 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1261 my $NULL = 4;               # The map is to the null string; utf8.c can't
1262                             # handle these, nor is there an accepted syntax
1263                             # for them in \p{} constructs
1264 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1265                              # otherwise be $MULTI_CP type are instead type 0
1266
1267 # process_generic_property_file() can accept certain overrides in its input.
1268 # Each of these must begin AND end with $CMD_DELIM.
1269 my $CMD_DELIM = "\a";
1270 my $REPLACE_CMD = 'replace';    # Override the Replace
1271 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1272
1273 my $NO = 0;
1274 my $YES = 1;
1275
1276 # Values for the Replace argument to add_range.
1277 # $NO                      # Don't replace; add only the code points not
1278                            # already present.
1279 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1280                            # the comments at the subroutine definition.
1281 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1282 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1283                            # already there
1284 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1285                            # already there
1286 my $CROAK = 6;             # Die with an error if is already there
1287
1288 # Flags to give property statuses.  The phrases are to remind maintainers that
1289 # if the flag is changed, the indefinite article referring to it in the
1290 # documentation may need to be as well.
1291 my $NORMAL = "";
1292 my $DEPRECATED = 'D';
1293 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1294 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1295 my $DISCOURAGED = 'X';
1296 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1297 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1298 my $STRICTER = 'T';
1299 my $a_bold_stricter = "a 'B<$STRICTER>'";
1300 my $A_bold_stricter = "A 'B<$STRICTER>'";
1301 my $STABILIZED = 'S';
1302 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1303 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1304 my $OBSOLETE = 'O';
1305 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1306 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1307
1308 # Aliases can also have an extra status:
1309 my $INTERNAL_ALIAS = 'P';
1310
1311 my %status_past_participles = (
1312     $DISCOURAGED => 'discouraged',
1313     $STABILIZED => 'stabilized',
1314     $OBSOLETE => 'obsolete',
1315     $DEPRECATED => 'deprecated',
1316     $INTERNAL_ALIAS => 'reserved for Perl core internal use only',
1317 );
1318
1319 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1320 # externally documented.
1321 my $ORDINARY = 0;       # The normal fate.
1322 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1323                         # but there is a file written that can be used to
1324                         # reconstruct this table
1325 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1326                         # for Perl's internal use only
1327 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1328                         # Is for backwards compatibility for applications that
1329                         # read the file directly, so it's format is
1330                         # unchangeable.
1331 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1332                         # result, we don't bother to do many computations on
1333                         # it.
1334 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1335                         # computations anyway, as the values are needed for
1336                         # things to work.  This happens when we have Perl
1337                         # extensions that depend on Unicode tables that
1338                         # wouldn't normally be in a given Unicode version.
1339
1340 # The format of the values of the tables:
1341 my $EMPTY_FORMAT = "";
1342 my $BINARY_FORMAT = 'b';
1343 my $DECIMAL_FORMAT = 'd';
1344 my $FLOAT_FORMAT = 'f';
1345 my $INTEGER_FORMAT = 'i';
1346 my $HEX_FORMAT = 'x';
1347 my $RATIONAL_FORMAT = 'r';
1348 my $STRING_FORMAT = 's';
1349 my $ADJUST_FORMAT = 'a';
1350 my $HEX_ADJUST_FORMAT = 'ax';
1351 my $DECOMP_STRING_FORMAT = 'c';
1352 my $STRING_WHITE_SPACE_LIST = 'sw';
1353
1354 my %map_table_formats = (
1355     $BINARY_FORMAT => 'binary',
1356     $DECIMAL_FORMAT => 'single decimal digit',
1357     $FLOAT_FORMAT => 'floating point number',
1358     $INTEGER_FORMAT => 'integer',
1359     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1360     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1361     $STRING_FORMAT => 'string',
1362     $ADJUST_FORMAT => 'some entries need adjustment',
1363     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1364     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1365     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1366 );
1367
1368 # Unicode didn't put such derived files in a separate directory at first.
1369 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1370 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1371 my $AUXILIARY = 'auxiliary';
1372
1373 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1374 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1375 my %loose_to_file_of;       # loosely maps table names to their respective
1376                             # files
1377 my %stricter_to_file_of;    # same; but for stricter mapping.
1378 my %loose_property_to_file_of; # Maps a loose property name to its map file
1379 my %strict_property_to_file_of; # Same, but strict
1380 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1381                             # inversion list.  When a definition is inlined,
1382                             # its value in the hash it's in (one of the two
1383                             # defined just above) will include an index into
1384                             # this array.  The 0th element is initialized to
1385                             # the definition for a zero length inversion list
1386 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1387                             # in the hash %utf8::SwashInfo
1388 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1389                              # their rational equivalent
1390 my %loose_property_name_of; # Loosely maps (non_string) property names to
1391                             # standard form
1392 my %strict_property_name_of; # Strictly maps (non_string) property names to
1393                             # standard form
1394 my %string_property_loose_to_name; # Same, for string properties.
1395 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1396                             # the property name in standard loose form, and
1397                             # 'value' is the default value for that property,
1398                             # also in standard loose form.
1399 my %loose_to_standard_value; # loosely maps table names to the canonical
1400                             # alias for them
1401 my %ambiguous_names;        # keys are alias names (in standard form) that
1402                             # have more than one possible meaning.
1403 my %combination_property;   # keys are alias names (in standard form) that
1404                             # have both a map table, and a binary one that
1405                             # yields true for all non-null maps.
1406 my %prop_aliases;           # Keys are standard property name; values are each
1407                             # one's aliases
1408 my %prop_value_aliases;     # Keys of top level are standard property name;
1409                             # values are keys to another hash,  Each one is
1410                             # one of the property's values, in standard form.
1411                             # The values are that prop-val's aliases.
1412 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1413
1414 # Most properties are immune to caseless matching, otherwise you would get
1415 # nonsensical results, as properties are a function of a code point, not
1416 # everything that is caselessly equivalent to that code point.  For example,
1417 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1418 # be true because 's' and 'S' are equivalent caselessly.  However,
1419 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1420 # extend that concept to those very few properties that are like this.  Each
1421 # such property will match the full range caselessly.  They are hard-coded in
1422 # the program; it's not worth trying to make it general as it's extremely
1423 # unlikely that they will ever change.
1424 my %caseless_equivalent_to;
1425
1426 # These constants names and values were taken from the Unicode standard,
1427 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1428 # syllables.  The '_string' versions are so generated tables can retain the
1429 # hex format, which is the more familiar value
1430 my $SBase_string = "0xAC00";
1431 my $SBase = CORE::hex $SBase_string;
1432 my $LBase_string = "0x1100";
1433 my $LBase = CORE::hex $LBase_string;
1434 my $VBase_string = "0x1161";
1435 my $VBase = CORE::hex $VBase_string;
1436 my $TBase_string = "0x11A7";
1437 my $TBase = CORE::hex $TBase_string;
1438 my $SCount = 11172;
1439 my $LCount = 19;
1440 my $VCount = 21;
1441 my $TCount = 28;
1442 my $NCount = $VCount * $TCount;
1443
1444 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1445 # with the above published constants.
1446 my %Jamo;
1447 my %Jamo_L;     # Leading consonants
1448 my %Jamo_V;     # Vowels
1449 my %Jamo_T;     # Trailing consonants
1450
1451 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1452 # The key is the base name of the code point, and the value is an
1453 # array giving all the ranges that use this base name.  Each range
1454 # is actually a hash giving the 'low' and 'high' values of it.
1455 my %names_ending_in_code_point;
1456 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1457                                         # removed from the names
1458 # Inverse mapping.  The list of ranges that have these kinds of
1459 # names.  Each element contains the low, high, and base names in an
1460 # anonymous hash.
1461 my @code_points_ending_in_code_point;
1462
1463 # To hold Unicode's normalization test suite
1464 my @normalization_tests;
1465
1466 # Boolean: does this Unicode version have the hangul syllables, and are we
1467 # writing out a table for them?
1468 my $has_hangul_syllables = 0;
1469
1470 # Does this Unicode version have code points whose names end in their
1471 # respective code points, and are we writing out a table for them?  0 for no;
1472 # otherwise points to first property that a table is needed for them, so that
1473 # if multiple tables are needed, we don't create duplicates
1474 my $needing_code_points_ending_in_code_point = 0;
1475
1476 my @backslash_X_tests;     # List of tests read in for testing \X
1477 my @SB_tests;              # List of tests read in for testing \b{sb}
1478 my @WB_tests;              # List of tests read in for testing \b{wb}
1479 my @unhandled_properties;  # Will contain a list of properties found in
1480                            # the input that we didn't process.
1481 my @match_properties;      # Properties that have match tables, to be
1482                            # listed in the pod
1483 my @map_properties;        # Properties that get map files written
1484 my @named_sequences;       # NamedSequences.txt contents.
1485 my %potential_files;       # Generated list of all .txt files in the directory
1486                            # structure so we can warn if something is being
1487                            # ignored.
1488 my @files_actually_output; # List of files we generated.
1489 my @more_Names;            # Some code point names are compound; this is used
1490                            # to store the extra components of them.
1491 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1492                            # the minimum before we consider it equivalent to a
1493                            # candidate rational
1494 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1495
1496 # These store references to certain commonly used property objects
1497 my $ccc;
1498 my $gc;
1499 my $perl;
1500 my $block;
1501 my $perl_charname;
1502 my $print;
1503 my $All;
1504 my $Assigned;   # All assigned characters in this Unicode release
1505 my $script;
1506
1507 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1508 my $has_In_conflicts = 0;
1509 my $has_Is_conflicts = 0;
1510
1511 sub internal_file_to_platform ($) {
1512     # Convert our file paths which have '/' separators to those of the
1513     # platform.
1514
1515     my $file = shift;
1516     return undef unless defined $file;
1517
1518     return File::Spec->join(split '/', $file);
1519 }
1520
1521 sub file_exists ($) {   # platform independent '-e'.  This program internally
1522                         # uses slash as a path separator.
1523     my $file = shift;
1524     return 0 if ! defined $file;
1525     return -e internal_file_to_platform($file);
1526 }
1527
1528 sub objaddr($) {
1529     # Returns the address of the blessed input object.
1530     # It doesn't check for blessedness because that would do a string eval
1531     # every call, and the program is structured so that this is never called
1532     # for a non-blessed object.
1533
1534     no overloading; # If overloaded, numifying below won't work.
1535
1536     # Numifying a ref gives its address.
1537     return pack 'J', $_[0];
1538 }
1539
1540 # These are used only if $annotate is true.
1541 # The entire range of Unicode characters is examined to populate these
1542 # after all the input has been processed.  But most can be skipped, as they
1543 # have the same descriptive phrases, such as being unassigned
1544 my @viacode;            # Contains the 1 million character names
1545 my @printable;          # boolean: And are those characters printable?
1546 my @annotate_char_type; # Contains a type of those characters, specifically
1547                         # for the purposes of annotation.
1548 my $annotate_ranges;    # A map of ranges of code points that have the same
1549                         # name for the purposes of annotation.  They map to the
1550                         # upper edge of the range, so that the end point can
1551                         # be immediately found.  This is used to skip ahead to
1552                         # the end of a range, and avoid processing each
1553                         # individual code point in it.
1554 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1555                                    # characters, but excluding those which are
1556                                    # also noncharacter code points
1557
1558 # The annotation types are an extension of the regular range types, though
1559 # some of the latter are folded into one.  Make the new types negative to
1560 # avoid conflicting with the regular types
1561 my $SURROGATE_TYPE = -1;
1562 my $UNASSIGNED_TYPE = -2;
1563 my $PRIVATE_USE_TYPE = -3;
1564 my $NONCHARACTER_TYPE = -4;
1565 my $CONTROL_TYPE = -5;
1566 my $ABOVE_UNICODE_TYPE = -6;
1567 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1568
1569 sub populate_char_info ($) {
1570     # Used only with the $annotate option.  Populates the arrays with the
1571     # input code point's info that are needed for outputting more detailed
1572     # comments.  If calling context wants a return, it is the end point of
1573     # any contiguous range of characters that share essentially the same info
1574
1575     my $i = shift;
1576     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1577
1578     $viacode[$i] = $perl_charname->value_of($i) || "";
1579
1580     # A character is generally printable if Unicode says it is,
1581     # but below we make sure that most Unicode general category 'C' types
1582     # aren't.
1583     $printable[$i] = $print->contains($i);
1584
1585     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1586
1587     # Only these two regular types are treated specially for annotations
1588     # purposes
1589     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1590                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1591
1592     # Give a generic name to all code points that don't have a real name.
1593     # We output ranges, if applicable, for these.  Also calculate the end
1594     # point of the range.
1595     my $end;
1596     if (! $viacode[$i]) {
1597         my $nonchar;
1598         if ($i > $MAX_UNICODE_CODEPOINT) {
1599             $viacode[$i] = 'Above-Unicode';
1600             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1601             $printable[$i] = 0;
1602             $end = $MAX_WORKING_CODEPOINT;
1603         }
1604         elsif ($gc-> table('Private_use')->contains($i)) {
1605             $viacode[$i] = 'Private Use';
1606             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1607             $printable[$i] = 0;
1608             $end = $gc->table('Private_Use')->containing_range($i)->end;
1609         }
1610         elsif ((defined ($nonchar =
1611                             Property::property_ref('Noncharacter_Code_Point'))
1612                && $nonchar->table('Y')->contains($i)))
1613         {
1614             $viacode[$i] = 'Noncharacter';
1615             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1616             $printable[$i] = 0;
1617             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1618                                                     containing_range($i)->end;
1619         }
1620         elsif ($gc-> table('Control')->contains($i)) {
1621             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1622             $annotate_char_type[$i] = $CONTROL_TYPE;
1623             $printable[$i] = 0;
1624         }
1625         elsif ($gc-> table('Unassigned')->contains($i)) {
1626             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1627             $printable[$i] = 0;
1628             if ($v_version lt v2.0.0) { # No blocks in earliest releases
1629                 $viacode[$i] = 'Unassigned';
1630                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1631             }
1632             else {
1633                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1634
1635                 # Because we name the unassigned by the blocks they are in, it
1636                 # can't go past the end of that block, and it also can't go
1637                 # past the unassigned range it is in.  The special table makes
1638                 # sure that the non-characters, which are unassigned, are
1639                 # separated out.
1640                 $end = min($block->containing_range($i)->end,
1641                            $unassigned_sans_noncharacters->
1642                                                     containing_range($i)->end);
1643             }
1644         }
1645         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1646             $viacode[$i] = 'Surrogate';
1647             $annotate_char_type[$i] = $SURROGATE_TYPE;
1648             $printable[$i] = 0;
1649             $end = $gc->table('Surrogate')->containing_range($i)->end;
1650         }
1651         else {
1652             Carp::my_carp_bug("Can't figure out how to annotate "
1653                               . sprintf("U+%04X", $i)
1654                               . ".  Proceeding anyway.");
1655             $viacode[$i] = 'UNKNOWN';
1656             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1657             $printable[$i] = 0;
1658         }
1659     }
1660
1661     # Here, has a name, but if it's one in which the code point number is
1662     # appended to the name, do that.
1663     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1664         $viacode[$i] .= sprintf("-%04X", $i);
1665         $end = $perl_charname->containing_range($i)->end;
1666     }
1667
1668     # And here, has a name, but if it's a hangul syllable one, replace it with
1669     # the correct name from the Unicode algorithm
1670     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1671         use integer;
1672         my $SIndex = $i - $SBase;
1673         my $L = $LBase + $SIndex / $NCount;
1674         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1675         my $T = $TBase + $SIndex % $TCount;
1676         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1677         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1678         $end = $perl_charname->containing_range($i)->end;
1679     }
1680
1681     return if ! defined wantarray;
1682     return $i if ! defined $end;    # If not a range, return the input
1683
1684     # Save this whole range so can find the end point quickly
1685     $annotate_ranges->add_map($i, $end, $end);
1686
1687     return $end;
1688 }
1689
1690 # Commented code below should work on Perl 5.8.
1691 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1692 ## the native perl version of it (which is what would operate under miniperl)
1693 ## is extremely slow, as it does a string eval every call.
1694 #my $has_fast_scalar_util = $^X !~ /miniperl/
1695 #                            && defined eval "require Scalar::Util";
1696 #
1697 #sub objaddr($) {
1698 #    # Returns the address of the blessed input object.  Uses the XS version if
1699 #    # available.  It doesn't check for blessedness because that would do a
1700 #    # string eval every call, and the program is structured so that this is
1701 #    # never called for a non-blessed object.
1702 #
1703 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1704 #
1705 #    # Check at least that is a ref.
1706 #    my $pkg = ref($_[0]) or return undef;
1707 #
1708 #    # Change to a fake package to defeat any overloaded stringify
1709 #    bless $_[0], 'main::Fake';
1710 #
1711 #    # Numifying a ref gives its address.
1712 #    my $addr = pack 'J', $_[0];
1713 #
1714 #    # Return to original class
1715 #    bless $_[0], $pkg;
1716 #    return $addr;
1717 #}
1718
1719 sub max ($$) {
1720     my $a = shift;
1721     my $b = shift;
1722     return $a if $a >= $b;
1723     return $b;
1724 }
1725
1726 sub min ($$) {
1727     my $a = shift;
1728     my $b = shift;
1729     return $a if $a <= $b;
1730     return $b;
1731 }
1732
1733 sub clarify_number ($) {
1734     # This returns the input number with underscores inserted every 3 digits
1735     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1736     # checked.
1737
1738     my $number = shift;
1739     my $pos = length($number) - 3;
1740     return $number if $pos <= 1;
1741     while ($pos > 0) {
1742         substr($number, $pos, 0) = '_';
1743         $pos -= 3;
1744     }
1745     return $number;
1746 }
1747
1748 sub clarify_code_point_count ($) {
1749     # This is like clarify_number(), but the input is assumed to be a count of
1750     # code points, rather than a generic number.
1751
1752     my $append = "";
1753
1754     my $number = shift;
1755     if ($number > $MAX_UNICODE_CODEPOINTS) {
1756         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1757         return "All above-Unicode code points" if $number == 0;
1758         $append = " + all above-Unicode code points";
1759     }
1760     return clarify_number($number) . $append;
1761 }
1762
1763 package Carp;
1764
1765 # These routines give a uniform treatment of messages in this program.  They
1766 # are placed in the Carp package to cause the stack trace to not include them,
1767 # although an alternative would be to use another package and set @CARP_NOT
1768 # for it.
1769
1770 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1771
1772 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1773 # and overload trying to load Scalar:Util under miniperl.  See
1774 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1775 undef $overload::VERSION;
1776
1777 sub my_carp {
1778     my $message = shift || "";
1779     my $nofold = shift || 0;
1780
1781     if ($message) {
1782         $message = main::join_lines($message);
1783         $message =~ s/^$0: *//;     # Remove initial program name
1784         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1785         $message = "\n$0: $message;";
1786
1787         # Fold the message with program name, semi-colon end punctuation
1788         # (which looks good with the message that carp appends to it), and a
1789         # hanging indent for continuation lines.
1790         $message = main::simple_fold($message, "", 4) unless $nofold;
1791         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1792                                     # appends is to the same line
1793     }
1794
1795     return $message if defined wantarray;   # If a caller just wants the msg
1796
1797     carp $message;
1798     return;
1799 }
1800
1801 sub my_carp_bug {
1802     # This is called when it is clear that the problem is caused by a bug in
1803     # this program.
1804
1805     my $message = shift;
1806     $message =~ s/^$0: *//;
1807     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1808     carp $message;
1809     return;
1810 }
1811
1812 sub carp_too_few_args {
1813     if (@_ != 2) {
1814         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1815         return;
1816     }
1817
1818     my $args_ref = shift;
1819     my $count = shift;
1820
1821     my_carp_bug("Need at least $count arguments to "
1822         . (caller 1)[3]
1823         . ".  Instead got: '"
1824         . join ', ', @$args_ref
1825         . "'.  No action taken.");
1826     return;
1827 }
1828
1829 sub carp_extra_args {
1830     my $args_ref = shift;
1831     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1832
1833     unless (ref $args_ref) {
1834         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1835         return;
1836     }
1837     my ($package, $file, $line) = caller;
1838     my $subroutine = (caller 1)[3];
1839
1840     my $list;
1841     if (ref $args_ref eq 'HASH') {
1842         foreach my $key (keys %$args_ref) {
1843             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1844         }
1845         $list = join ', ', each %{$args_ref};
1846     }
1847     elsif (ref $args_ref eq 'ARRAY') {
1848         foreach my $arg (@$args_ref) {
1849             $arg = $UNDEF unless defined $arg;
1850         }
1851         $list = join ', ', @$args_ref;
1852     }
1853     else {
1854         my_carp_bug("Can't cope with ref "
1855                 . ref($args_ref)
1856                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1857         return;
1858     }
1859
1860     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1861     return;
1862 }
1863
1864 package main;
1865
1866 { # Closure
1867
1868     # This program uses the inside-out method for objects, as recommended in
1869     # "Perl Best Practices".  (This is the best solution still, since this has
1870     # to run under miniperl.)  This closure aids in generating those.  There
1871     # are two routines.  setup_package() is called once per package to set
1872     # things up, and then set_access() is called for each hash representing a
1873     # field in the object.  These routines arrange for the object to be
1874     # properly destroyed when no longer used, and for standard accessor
1875     # functions to be generated.  If you need more complex accessors, just
1876     # write your own and leave those accesses out of the call to set_access().
1877     # More details below.
1878
1879     my %constructor_fields; # fields that are to be used in constructors; see
1880                             # below
1881
1882     # The values of this hash will be the package names as keys to other
1883     # hashes containing the name of each field in the package as keys, and
1884     # references to their respective hashes as values.
1885     my %package_fields;
1886
1887     sub setup_package {
1888         # Sets up the package, creating standard DESTROY and dump methods
1889         # (unless already defined).  The dump method is used in debugging by
1890         # simple_dumper().
1891         # The optional parameters are:
1892         #   a)  a reference to a hash, that gets populated by later
1893         #       set_access() calls with one of the accesses being
1894         #       'constructor'.  The caller can then refer to this, but it is
1895         #       not otherwise used by these two routines.
1896         #   b)  a reference to a callback routine to call during destruction
1897         #       of the object, before any fields are actually destroyed
1898
1899         my %args = @_;
1900         my $constructor_ref = delete $args{'Constructor_Fields'};
1901         my $destroy_callback = delete $args{'Destroy_Callback'};
1902         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1903
1904         my %fields;
1905         my $package = (caller)[0];
1906
1907         $package_fields{$package} = \%fields;
1908         $constructor_fields{$package} = $constructor_ref;
1909
1910         unless ($package->can('DESTROY')) {
1911             my $destroy_name = "${package}::DESTROY";
1912             no strict "refs";
1913
1914             # Use typeglob to give the anonymous subroutine the name we want
1915             *$destroy_name = sub {
1916                 my $self = shift;
1917                 my $addr = do { no overloading; pack 'J', $self; };
1918
1919                 $self->$destroy_callback if $destroy_callback;
1920                 foreach my $field (keys %{$package_fields{$package}}) {
1921                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1922                     delete $package_fields{$package}{$field}{$addr};
1923                 }
1924                 return;
1925             }
1926         }
1927
1928         unless ($package->can('dump')) {
1929             my $dump_name = "${package}::dump";
1930             no strict "refs";
1931             *$dump_name = sub {
1932                 my $self = shift;
1933                 return dump_inside_out($self, $package_fields{$package}, @_);
1934             }
1935         }
1936         return;
1937     }
1938
1939     sub set_access {
1940         # Arrange for the input field to be garbage collected when no longer
1941         # needed.  Also, creates standard accessor functions for the field
1942         # based on the optional parameters-- none if none of these parameters:
1943         #   'addable'    creates an 'add_NAME()' accessor function.
1944         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1945         #                function.
1946         #   'settable'   creates a 'set_NAME()' accessor function.
1947         #   'constructor' doesn't create an accessor function, but adds the
1948         #                field to the hash that was previously passed to
1949         #                setup_package();
1950         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1951         # 'add' etc. all mean 'addable'.
1952         # The read accessor function will work on both array and scalar
1953         # values.  If another accessor in the parameter list is 'a', the read
1954         # access assumes an array.  You can also force it to be array access
1955         # by specifying 'readable_array' instead of 'readable'
1956         #
1957         # A sort-of 'protected' access can be set-up by preceding the addable,
1958         # readable or settable with some initial portion of 'protected_' (but,
1959         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1960         # "protection" is only by convention.  All that happens is that the
1961         # accessor functions' names begin with an underscore.  So instead of
1962         # calling set_foo, the call is _set_foo.  (Real protection could be
1963         # accomplished by having a new subroutine, end_package, called at the
1964         # end of each package, and then storing the __LINE__ ranges and
1965         # checking them on every accessor.  But that is way overkill.)
1966
1967         # We create anonymous subroutines as the accessors and then use
1968         # typeglobs to assign them to the proper package and name
1969
1970         my $name = shift;   # Name of the field
1971         my $field = shift;  # Reference to the inside-out hash containing the
1972                             # field
1973
1974         my $package = (caller)[0];
1975
1976         if (! exists $package_fields{$package}) {
1977             croak "$0: Must call 'setup_package' before 'set_access'";
1978         }
1979
1980         # Stash the field so DESTROY can get it.
1981         $package_fields{$package}{$name} = $field;
1982
1983         # Remaining arguments are the accessors.  For each...
1984         foreach my $access (@_) {
1985             my $access = lc $access;
1986
1987             my $protected = "";
1988
1989             # Match the input as far as it goes.
1990             if ($access =~ /^(p[^_]*)_/) {
1991                 $protected = $1;
1992                 if (substr('protected_', 0, length $protected)
1993                     eq $protected)
1994                 {
1995
1996                     # Add 1 for the underscore not included in $protected
1997                     $access = substr($access, length($protected) + 1);
1998                     $protected = '_';
1999                 }
2000                 else {
2001                     $protected = "";
2002                 }
2003             }
2004
2005             if (substr('addable', 0, length $access) eq $access) {
2006                 my $subname = "${package}::${protected}add_$name";
2007                 no strict "refs";
2008
2009                 # add_ accessor.  Don't add if already there, which we
2010                 # determine using 'eq' for scalars and '==' otherwise.
2011                 *$subname = sub {
2012                     use strict "refs";
2013                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2014                     my $self = shift;
2015                     my $value = shift;
2016                     my $addr = do { no overloading; pack 'J', $self; };
2017                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2018                     if (ref $value) {
2019                         return if grep { $value == $_ } @{$field->{$addr}};
2020                     }
2021                     else {
2022                         return if grep { $value eq $_ } @{$field->{$addr}};
2023                     }
2024                     push @{$field->{$addr}}, $value;
2025                     return;
2026                 }
2027             }
2028             elsif (substr('constructor', 0, length $access) eq $access) {
2029                 if ($protected) {
2030                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
2031                 }
2032                 else {
2033                     $constructor_fields{$package}{$name} = $field;
2034                 }
2035             }
2036             elsif (substr('readable_array', 0, length $access) eq $access) {
2037
2038                 # Here has read access.  If one of the other parameters for
2039                 # access is array, or this one specifies array (by being more
2040                 # than just 'readable_'), then create a subroutine that
2041                 # assumes the data is an array.  Otherwise just a scalar
2042                 my $subname = "${package}::${protected}$name";
2043                 if (grep { /^a/i } @_
2044                     or length($access) > length('readable_'))
2045                 {
2046                     no strict "refs";
2047                     *$subname = sub {
2048                         use strict "refs";
2049                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2050                         my $addr = do { no overloading; pack 'J', $_[0]; };
2051                         if (ref $field->{$addr} ne 'ARRAY') {
2052                             my $type = ref $field->{$addr};
2053                             $type = 'scalar' unless $type;
2054                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
2055                             return;
2056                         }
2057                         return scalar @{$field->{$addr}} unless wantarray;
2058
2059                         # Make a copy; had problems with caller modifying the
2060                         # original otherwise
2061                         my @return = @{$field->{$addr}};
2062                         return @return;
2063                     }
2064                 }
2065                 else {
2066
2067                     # Here not an array value, a simpler function.
2068                     no strict "refs";
2069                     *$subname = sub {
2070                         use strict "refs";
2071                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2072                         no overloading;
2073                         return $field->{pack 'J', $_[0]};
2074                     }
2075                 }
2076             }
2077             elsif (substr('settable', 0, length $access) eq $access) {
2078                 my $subname = "${package}::${protected}set_$name";
2079                 no strict "refs";
2080                 *$subname = sub {
2081                     use strict "refs";
2082                     if (main::DEBUG) {
2083                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2084                         Carp::carp_extra_args(\@_) if @_ > 2;
2085                     }
2086                     # $self is $_[0]; $value is $_[1]
2087                     no overloading;
2088                     $field->{pack 'J', $_[0]} = $_[1];
2089                     return;
2090                 }
2091             }
2092             else {
2093                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2094             }
2095         }
2096         return;
2097     }
2098 }
2099
2100 package Input_file;
2101
2102 # All input files use this object, which stores various attributes about them,
2103 # and provides for convenient, uniform handling.  The run method wraps the
2104 # processing.  It handles all the bookkeeping of opening, reading, and closing
2105 # the file, returning only significant input lines.
2106 #
2107 # Each object gets a handler which processes the body of the file, and is
2108 # called by run().  All character property files must use the generic,
2109 # default handler, which has code scrubbed to handle things you might not
2110 # expect, including automatic EBCDIC handling.  For files that don't deal with
2111 # mapping code points to a property value, such as test files,
2112 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2113 # handler to be a custom one.  Such a handler should basically be a
2114 # while(next_line()) {...} loop.
2115 #
2116 # You can also set up handlers to
2117 #   1) call before the first line is read, for pre processing
2118 #   2) call to adjust each line of the input before the main handler gets
2119 #      them.  This can be automatically generated, if appropriately simple
2120 #      enough, by specifiying a Properties parameter in the constructor.
2121 #   3) call upon EOF before the main handler exits its loop
2122 #   4) call at the end, for post processing
2123 #
2124 # $_ is used to store the input line, and is to be filtered by the
2125 # each_line_handler()s.  So, if the format of the line is not in the desired
2126 # format for the main handler, these are used to do that adjusting.  They can
2127 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2128 # so the $_ output of one is used as the input to the next.  None of the other
2129 # handlers are stackable, but could easily be changed to be so.
2130 #
2131 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2132 # which insert the parameters as lines to be processed before the next input
2133 # file line is read.  This allows the EOF handler to flush buffers, for
2134 # example.  The difference between the two routines is that the lines inserted
2135 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2136 # called it from such a handler, you would get infinite recursion without some
2137 # mechanism to prevent that.)  Lines inserted by insert_adjusted_lines() go
2138 # directly to the main handler without any adjustments.  If the
2139 # post-processing handler calls any of these, there will be no effect.  Some
2140 # error checking for these conditions could be added, but it hasn't been done.
2141 #
2142 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2143 # to prevent further processing of the line.  This routine will output the
2144 # message as a warning once, and then keep a count of the lines that have the
2145 # same message, and output that count at the end of the file's processing.
2146 # This keeps the number of messages down to a manageable amount.
2147 #
2148 # get_missings() should be called to retrieve any @missing input lines.
2149 # Messages will be raised if this isn't done if the options aren't to ignore
2150 # missings.
2151
2152 sub trace { return main::trace(@_); }
2153
2154 { # Closure
2155     # Keep track of fields that are to be put into the constructor.
2156     my %constructor_fields;
2157
2158     main::setup_package(Constructor_Fields => \%constructor_fields);
2159
2160     my %file; # Input file name, required
2161     main::set_access('file', \%file, qw{ c r });
2162
2163     my %first_released; # Unicode version file was first released in, required
2164     main::set_access('first_released', \%first_released, qw{ c r });
2165
2166     my %handler;    # Subroutine to process the input file, defaults to
2167                     # 'process_generic_property_file'
2168     main::set_access('handler', \%handler, qw{ c });
2169
2170     my %property;
2171     # name of property this file is for.  defaults to none, meaning not
2172     # applicable, or is otherwise determinable, for example, from each line.
2173     main::set_access('property', \%property, qw{ c r });
2174
2175     my %optional;
2176     # If this is true, the file is optional.  If not present, no warning is
2177     # output.  If it is present, the string given by this parameter is
2178     # evaluated, and if false the file is not processed.
2179     main::set_access('optional', \%optional, 'c', 'r');
2180
2181     my %non_skip;
2182     # This is used for debugging, to skip processing of all but a few input
2183     # files.  Add 'non_skip => 1' to the constructor for those files you want
2184     # processed when you set the $debug_skip global.
2185     main::set_access('non_skip', \%non_skip, 'c');
2186
2187     my %skip;
2188     # This is used to skip processing of this input file semi-permanently,
2189     # when it evaluates to true.  The value should be the reason the file is
2190     # being skipped.  It is used for files that we aren't planning to process
2191     # anytime soon, but want to allow to be in the directory and not raise a
2192     # message that we are not handling.  Mostly for test files.  This is in
2193     # contrast to the non_skip element, which is supposed to be used very
2194     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2195     # pretty much will never look at can be placed in the global
2196     # %ignored_files instead.  Ones used here will be added to %skipped files
2197     main::set_access('skip', \%skip, 'c');
2198
2199     my %each_line_handler;
2200     # list of subroutines to look at and filter each non-comment line in the
2201     # file.  defaults to none.  The subroutines are called in order, each is
2202     # to adjust $_ for the next one, and the final one adjusts it for
2203     # 'handler'
2204     main::set_access('each_line_handler', \%each_line_handler, 'c');
2205
2206     my %properties; # Optional ordered list of the properties that occur in each
2207     # meaningful line of the input file.  If present, an appropriate
2208     # each_line_handler() is automatically generated and pushed onto the stack
2209     # of such handlers.  This is useful when a file contains multiple
2210     # proerties per line, but no other special considerations are necessary.
2211     # The special value "<ignored>" means to discard the corresponding input
2212     # field.
2213     # Any @missing lines in the file should also match this syntax; no such
2214     # files exist as of 6.3.  But if it happens in a future release, the code
2215     # could be expanded to properly parse them.
2216     main::set_access('properties', \%properties, qw{ c r });
2217
2218     my %has_missings_defaults;
2219     # ? Are there lines in the file giving default values for code points
2220     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2221     # the norm, but IGNORED means it has such lines, but the handler doesn't
2222     # use them.  Having these three states allows us to catch changes to the
2223     # UCD that this program should track.  XXX This could be expanded to
2224     # specify the syntax for such lines, like %properties above.
2225     main::set_access('has_missings_defaults',
2226                                         \%has_missings_defaults, qw{ c r });
2227
2228     my %pre_handler;
2229     # Subroutine to call before doing anything else in the file.  If undef, no
2230     # such handler is called.
2231     main::set_access('pre_handler', \%pre_handler, qw{ c });
2232
2233     my %eof_handler;
2234     # Subroutine to call upon getting an EOF on the input file, but before
2235     # that is returned to the main handler.  This is to allow buffers to be
2236     # flushed.  The handler is expected to call insert_lines() or
2237     # insert_adjusted() with the buffered material
2238     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2239
2240     my %post_handler;
2241     # Subroutine to call after all the lines of the file are read in and
2242     # processed.  If undef, no such handler is called.  Note that this cannot
2243     # add lines to be processed; instead use eof_handler
2244     main::set_access('post_handler', \%post_handler, qw{ c });
2245
2246     my %progress_message;
2247     # Message to print to display progress in lieu of the standard one
2248     main::set_access('progress_message', \%progress_message, qw{ c });
2249
2250     my %handle;
2251     # cache open file handle, internal.  Is undef if file hasn't been
2252     # processed at all, empty if has;
2253     main::set_access('handle', \%handle);
2254
2255     my %added_lines;
2256     # cache of lines added virtually to the file, internal
2257     main::set_access('added_lines', \%added_lines);
2258
2259     my %remapped_lines;
2260     # cache of lines added virtually to the file, internal
2261     main::set_access('remapped_lines', \%remapped_lines);
2262
2263     my %errors;
2264     # cache of errors found, internal
2265     main::set_access('errors', \%errors);
2266
2267     my %missings;
2268     # storage of '@missing' defaults lines
2269     main::set_access('missings', \%missings);
2270
2271     sub _next_line;
2272     sub _next_line_with_remapped_range;
2273
2274     sub new {
2275         my $class = shift;
2276
2277         my $self = bless \do{ my $anonymous_scalar }, $class;
2278         my $addr = do { no overloading; pack 'J', $self; };
2279
2280         # Set defaults
2281         $handler{$addr} = \&main::process_generic_property_file;
2282         $non_skip{$addr} = 0;
2283         $skip{$addr} = 0;
2284         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2285         $handle{$addr} = undef;
2286         $added_lines{$addr} = [ ];
2287         $remapped_lines{$addr} = [ ];
2288         $each_line_handler{$addr} = [ ];
2289         $errors{$addr} = { };
2290         $missings{$addr} = [ ];
2291
2292         # Two positional parameters.
2293         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2294         $file{$addr} = main::internal_file_to_platform(shift);
2295         $first_released{$addr} = shift;
2296
2297         undef $file{$addr} if $first_released{$addr} gt $v_version;
2298
2299         # The rest of the arguments are key => value pairs
2300         # %constructor_fields has been set up earlier to list all possible
2301         # ones.  Either set or push, depending on how the default has been set
2302         # up just above.
2303         my %args = @_;
2304         foreach my $key (keys %args) {
2305             my $argument = $args{$key};
2306
2307             # Note that the fields are the lower case of the constructor keys
2308             my $hash = $constructor_fields{lc $key};
2309             if (! defined $hash) {
2310                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2311                 next;
2312             }
2313             if (ref $hash->{$addr} eq 'ARRAY') {
2314                 if (ref $argument eq 'ARRAY') {
2315                     foreach my $argument (@{$argument}) {
2316                         next if ! defined $argument;
2317                         push @{$hash->{$addr}}, $argument;
2318                     }
2319                 }
2320                 else {
2321                     push @{$hash->{$addr}}, $argument if defined $argument;
2322                 }
2323             }
2324             else {
2325                 $hash->{$addr} = $argument;
2326             }
2327             delete $args{$key};
2328         };
2329
2330         # If the file has a property for it, it means that the property is not
2331         # listed in the file's entries.  So add a handler to the list of line
2332         # handlers to insert the property name into the lines, to provide a
2333         # uniform interface to the final processing subroutine.
2334         # the final code doesn't have to worry about that.
2335         if ($property{$addr}) {
2336             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2337         }
2338
2339         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2340             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2341         }
2342
2343         # If skipping, set to optional, and add to list of ignored files,
2344         # including its reason
2345         if ($skip{$addr}) {
2346             $optional{$addr} = 1;
2347             $skipped_files{$file{$addr}} = $skip{$addr} if $file{$addr};
2348         }
2349         elsif ($properties{$addr}) {
2350
2351             # Similarly, there may be more than one property represented on
2352             # each line, with no clue but the constructor input what those
2353             # might be.  Add a handler for each line in the input so that it
2354             # creates a separate input line for each property in those input
2355             # lines, thus making them suitable to handle generically.
2356
2357             push @{$each_line_handler{$addr}},
2358                  sub {
2359                     my $file = shift;
2360                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2361
2362                     my @fields = split /\s*;\s*/, $_, -1;
2363
2364                     if (@fields - 1 > @{$properties{$addr}}) {
2365                         $file->carp_bad_line('Extra fields');
2366                         $_ = "";
2367                         return;
2368                     }
2369                     my $range = shift @fields;  # 0th element is always the
2370                                                 # range
2371
2372                     # The next fields in the input line correspond
2373                     # respectively to the stored properties.
2374                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2375                         my $property_name = $properties{$addr}[$i];
2376                         next if $property_name eq '<ignored>';
2377                         $file->insert_adjusted_lines(
2378                               "$range; $property_name; $fields[$i]");
2379                     }
2380                     $_ = "";
2381
2382                     return;
2383                 };
2384         }
2385
2386         {   # On non-ascii platforms, we use a special pre-handler
2387             no strict;
2388             no warnings 'once';
2389             *next_line = (main::NON_ASCII_PLATFORM)
2390                          ? *_next_line_with_remapped_range
2391                          : *_next_line;
2392         }
2393
2394         return $self;
2395     }
2396
2397
2398     use overload
2399         fallback => 0,
2400         qw("") => "_operator_stringify",
2401         "." => \&main::_operator_dot,
2402         ".=" => \&main::_operator_dot_equal,
2403     ;
2404
2405     sub _operator_stringify {
2406         my $self = shift;
2407
2408         return __PACKAGE__ . " object for " . $self->file;
2409     }
2410
2411     # flag to make sure extracted files are processed early
2412     my $seen_non_extracted_non_age = 0;
2413
2414     sub run {
2415         # Process the input object $self.  This opens and closes the file and
2416         # calls all the handlers for it.  Currently,  this can only be called
2417         # once per file, as it destroy's the EOF handler
2418
2419         my $self = shift;
2420         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2421
2422         my $addr = do { no overloading; pack 'J', $self; };
2423
2424         my $file = $file{$addr};
2425
2426         # Don't process if not expecting this file (because released later
2427         # than this Unicode version), and isn't there.  This means if someone
2428         # copies it into an earlier version's directory, we will go ahead and
2429         # process it.
2430         return if $first_released{$addr} gt $v_version
2431                   && (! defined $file || ! -e $file);
2432
2433         # If in debugging mode and this file doesn't have the non-skip
2434         # flag set, and isn't one of the critical files, skip it.
2435         if ($debug_skip
2436             && $first_released{$addr} ne v0
2437             && ! $non_skip{$addr})
2438         {
2439             print "Skipping $file in debugging\n" if $verbosity;
2440             return;
2441         }
2442
2443         # File could be optional
2444         if ($optional{$addr}) {
2445             return unless -e $file;
2446             my $result = eval $optional{$addr};
2447             if (! defined $result) {
2448                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2449                 return;
2450             }
2451             if (! $result) {
2452                 if ($verbosity) {
2453                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2454                 }
2455                 return;
2456             }
2457         }
2458
2459         if (! defined $file || ! -e $file) {
2460
2461             # If the file doesn't exist, see if have internal data for it
2462             # (based on first_released being 0).
2463             if ($first_released{$addr} eq v0) {
2464                 $handle{$addr} = 'pretend_is_open';
2465             }
2466             else {
2467                 if (! $optional{$addr}  # File could be optional
2468                     && $v_version ge $first_released{$addr})
2469                 {
2470                     print STDERR "Skipping processing input file '$file' because not found\n";
2471                 }
2472                 return;
2473             }
2474         }
2475         else {
2476             if ($seen_non_extracted_non_age) {
2477                 if ($file =~ /$EXTRACTED/i) # Some platforms may change the
2478                                             # case of the file's name
2479                 {
2480                     Carp::my_carp_bug(main::join_lines(<<END
2481 $file should be processed just after the 'Prop...Alias' files, and before
2482 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2483 have subtle problems
2484 END
2485                     ));
2486                 }
2487             }
2488             elsif ($EXTRACTED_DIR
2489                     && $first_released{$addr} ne v0
2490                     && $file !~ /$EXTRACTED/i
2491                     && lc($file) ne 'dage.txt')
2492             {
2493                 # We don't set this (by the 'if' above) if we have no
2494                 # extracted directory, so if running on an early version,
2495                 # this test won't work.  Not worth worrying about.
2496                 $seen_non_extracted_non_age = 1;
2497             }
2498
2499             # Mark the file as having being processed, and warn if it
2500             # isn't a file we are expecting.  As we process the files,
2501             # they are deleted from the hash, so any that remain at the
2502             # end of the program are files that we didn't process.
2503             my $fkey = File::Spec->rel2abs($file);
2504             my $expecting = delete $potential_files{lc($fkey)};
2505
2506             Carp::my_carp("Was not expecting '$file'.") if
2507                     ! $expecting
2508                     && ! defined $handle{$addr};
2509
2510             # Having deleted from expected files, we can quit if not to do
2511             # anything.  Don't print progress unless really want verbosity
2512             if ($skip{$addr}) {
2513                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2514                 return;
2515             }
2516
2517             # Here, we are going to process the file.  Open it, converting the
2518             # slashes used in this program into the proper form for the OS
2519             my $file_handle;
2520             if (not open $file_handle, "<", $file) {
2521                 Carp::my_carp("Can't open $file.  Skipping: $!");
2522                 return;
2523             }
2524             $handle{$addr} = $file_handle; # Cache the open file handle
2525
2526             if ($v_version ge v3.2.0 && lc($file) ne 'unicodedata.txt') {
2527
2528                 # UnicodeData.txt has no version marker; the others started
2529                 # getting it in 3.2.  Unihan files have the version somewhere
2530                 # in the first comment block; the other files have it as the
2531                 # very first line
2532                 if ($file !~ /^Unihan/i) {
2533                     $_ = <$file_handle>;
2534                     if ($_ !~ / - $string_version \. /x) {
2535                         chomp;
2536                         $_ =~ s/^#\s*//;
2537                         die Carp::my_carp("File '$file' is version '$_'.  It should be version $string_version");
2538                     }
2539                 }
2540                 else {
2541                     while (<$file_handle>) {
2542                         if ($_ !~ /^#/) {
2543                             Carp::my_carp_bug("Could not find the expected version info in file '$file'");
2544                             last;
2545                         }
2546                         chomp;
2547                         $_ =~ s/^#\s*//;
2548                         next if $_ !~ / version: /x;
2549                         last if $_ =~ /$string_version/;
2550                         die Carp::my_carp("File '$file' is '$_'.  It should be version $string_version");
2551                     }
2552                 }
2553             }
2554         }
2555
2556         if ($verbosity >= $PROGRESS) {
2557             if ($progress_message{$addr}) {
2558                 print "$progress_message{$addr}\n";
2559             }
2560             else {
2561                 # If using a virtual file, say so.
2562                 print "Processing ", (-e $file)
2563                                        ? $file
2564                                        : "substitute $file",
2565                                      "\n";
2566             }
2567         }
2568
2569
2570         # Call any special handler for before the file.
2571         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2572
2573         # Then the main handler
2574         &{$handler{$addr}}($self);
2575
2576         # Then any special post-file handler.
2577         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2578
2579         # If any errors have been accumulated, output the counts (as the first
2580         # error message in each class was output when it was encountered).
2581         if ($errors{$addr}) {
2582             my $total = 0;
2583             my $types = 0;
2584             foreach my $error (keys %{$errors{$addr}}) {
2585                 $total += $errors{$addr}->{$error};
2586                 delete $errors{$addr}->{$error};
2587                 $types++;
2588             }
2589             if ($total > 1) {
2590                 my $message
2591                         = "A total of $total lines had errors in $file.  ";
2592
2593                 $message .= ($types == 1)
2594                             ? '(Only the first one was displayed.)'
2595                             : '(Only the first of each type was displayed.)';
2596                 Carp::my_carp($message);
2597             }
2598         }
2599
2600         if (@{$missings{$addr}}) {
2601             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2602         }
2603
2604         # If a real file handle, close it.
2605         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2606                                                         ref $handle{$addr};
2607         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2608                                # the file, as opposed to undef
2609         return;
2610     }
2611
2612     sub _next_line {
2613         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2614         # if such a line exists.  'logical' means that any lines that have
2615         # been added via insert_lines() will be returned in $_ before the file
2616         # is read again.
2617
2618         my $self = shift;
2619         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2620
2621         my $addr = do { no overloading; pack 'J', $self; };
2622
2623         # Here the file is open (or if the handle is not a ref, is an open
2624         # 'virtual' file).  Get the next line; any inserted lines get priority
2625         # over the file itself.
2626         my $adjusted;
2627
2628         LINE:
2629         while (1) { # Loop until find non-comment, non-empty line
2630             #local $to_trace = 1 if main::DEBUG;
2631             my $inserted_ref = shift @{$added_lines{$addr}};
2632             if (defined $inserted_ref) {
2633                 ($adjusted, $_) = @{$inserted_ref};
2634                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2635                 return 1 if $adjusted;
2636             }
2637             else {
2638                 last if ! ref $handle{$addr}; # Don't read unless is real file
2639                 last if ! defined ($_ = readline $handle{$addr});
2640             }
2641             chomp;
2642             trace $_ if main::DEBUG && $to_trace;
2643
2644             # See if this line is the comment line that defines what property
2645             # value that code points that are not listed in the file should
2646             # have.  The format or existence of these lines is not guaranteed
2647             # by Unicode since they are comments, but the documentation says
2648             # that this was added for machine-readability, so probably won't
2649             # change.  This works starting in Unicode Version 5.0.  They look
2650             # like:
2651             #
2652             # @missing: 0000..10FFFF; Not_Reordered
2653             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2654             # @missing: 0000..10FFFF; ; NaN
2655             #
2656             # Save the line for a later get_missings() call.
2657             if (/$missing_defaults_prefix/) {
2658                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2659                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2660                 }
2661                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2662                     my @defaults = split /\s* ; \s*/x, $_;
2663
2664                     # The first field is the @missing, which ends in a
2665                     # semi-colon, so can safely shift.
2666                     shift @defaults;
2667
2668                     # Some of these lines may have empty field placeholders
2669                     # which get in the way.  An example is:
2670                     # @missing: 0000..10FFFF; ; NaN
2671                     # Remove them.  Process starting from the top so the
2672                     # splice doesn't affect things still to be looked at.
2673                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2674                         next if $defaults[$i] ne "";
2675                         splice @defaults, $i, 1;
2676                     }
2677
2678                     # What's left should be just the property (maybe) and the
2679                     # default.  Having only one element means it doesn't have
2680                     # the property.
2681                     my $default;
2682                     my $property;
2683                     if (@defaults >= 1) {
2684                         if (@defaults == 1) {
2685                             $default = $defaults[0];
2686                         }
2687                         else {
2688                             $property = $defaults[0];
2689                             $default = $defaults[1];
2690                         }
2691                     }
2692
2693                     if (@defaults < 1
2694                         || @defaults > 2
2695                         || ($default =~ /^</
2696                             && $default !~ /^<code *point>$/i
2697                             && $default !~ /^<none>$/i
2698                             && $default !~ /^<script>$/i))
2699                     {
2700                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2701                     }
2702                     else {
2703
2704                         # If the property is missing from the line, it should
2705                         # be the one for the whole file
2706                         $property = $property{$addr} if ! defined $property;
2707
2708                         # Change <none> to the null string, which is what it
2709                         # really means.  If the default is the code point
2710                         # itself, set it to <code point>, which is what
2711                         # Unicode uses (but sometimes they've forgotten the
2712                         # space)
2713                         if ($default =~ /^<none>$/i) {
2714                             $default = "";
2715                         }
2716                         elsif ($default =~ /^<code *point>$/i) {
2717                             $default = $CODE_POINT;
2718                         }
2719                         elsif ($default =~ /^<script>$/i) {
2720
2721                             # Special case this one.  Currently is from
2722                             # ScriptExtensions.txt, and means for all unlisted
2723                             # code points, use their Script property values.
2724                             # For the code points not listed in that file, the
2725                             # default value is 'Unknown'.
2726                             $default = "Unknown";
2727                         }
2728
2729                         # Store them as a sub-arrays with both components.
2730                         push @{$missings{$addr}}, [ $default, $property ];
2731                     }
2732                 }
2733
2734                 # There is nothing for the caller to process on this comment
2735                 # line.
2736                 next;
2737             }
2738
2739             # Remove comments and trailing space, and skip this line if the
2740             # result is empty
2741             s/#.*//;
2742             s/\s+$//;
2743             next if /^$/;
2744
2745             # Call any handlers for this line, and skip further processing of
2746             # the line if the handler sets the line to null.
2747             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2748                 &{$sub_ref}($self);
2749                 next LINE if /^$/;
2750             }
2751
2752             # Here the line is ok.  return success.
2753             return 1;
2754         } # End of looping through lines.
2755
2756         # If there is an EOF handler, call it (only once) and if it generates
2757         # more lines to process go back in the loop to handle them.
2758         if ($eof_handler{$addr}) {
2759             &{$eof_handler{$addr}}($self);
2760             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2761             goto LINE if $added_lines{$addr};
2762         }
2763
2764         # Return failure -- no more lines.
2765         return 0;
2766
2767     }
2768
2769     sub _next_line_with_remapped_range {
2770         my $self = shift;
2771         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2772
2773         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2774         # to be the next logical input line, if any.  Returns non-zero if such
2775         # a line exists.  'logical' means that any lines that have been added
2776         # via insert_lines() will be returned in $_ before the file is read
2777         # again.
2778         #
2779         # The difference from _next_line() is that this remaps the Unicode
2780         # code points in the input to those of the native platform.  Each
2781         # input line contains a single code point, or a single contiguous
2782         # range of them  This routine splits each range into its individual
2783         # code points and caches them.  It returns the cached values,
2784         # translated into their native equivalents, one at a time, for each
2785         # call, before reading the next line.  Since native values can only be
2786         # a single byte wide, no translation is needed for code points above
2787         # 0xFF, and ranges that are entirely above that number are not split.
2788         # If an input line contains the range 254-1000, it would be split into
2789         # three elements: 254, 255, and 256-1000.  (The downstream table
2790         # insertion code will sort and coalesce the individual code points
2791         # into appropriate ranges.)
2792
2793         my $addr = do { no overloading; pack 'J', $self; };
2794
2795         while (1) {
2796
2797             # Look in cache before reading the next line.  Return any cached
2798             # value, translated
2799             my $inserted = shift @{$remapped_lines{$addr}};
2800             if (defined $inserted) {
2801                 trace $inserted if main::DEBUG && $to_trace;
2802                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
2803                 trace $_ if main::DEBUG && $to_trace;
2804                 return 1;
2805             }
2806
2807             # Get the next line.
2808             return 0 unless _next_line($self);
2809
2810             # If there is a special handler for it, return the line,
2811             # untranslated.  This should happen only for files that are
2812             # special, not being code-point related, such as property names.
2813             return 1 if $handler{$addr}
2814                                     != \&main::process_generic_property_file;
2815
2816             my ($range, $property_name, $map, @remainder)
2817                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
2818
2819             if (@remainder
2820                 || ! defined $property_name
2821                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
2822             {
2823                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
2824             }
2825
2826             my $low = hex $1;
2827             my $high = (defined $2) ? hex $2 : $low;
2828
2829             # If the input maps the range to another code point, remap the
2830             # target if it is between 0 and 255.
2831             my $tail;
2832             if (defined $map) {
2833                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
2834                 $tail = "$property_name; $map";
2835                 $_ = "$range; $tail";
2836             }
2837             else {
2838                 $tail = $property_name;
2839             }
2840
2841             # If entire range is above 255, just return it, unchanged (except
2842             # any mapped-to code point, already changed above)
2843             return 1 if $low > 255;
2844
2845             # Cache an entry for every code point < 255.  For those in the
2846             # range above 255, return a dummy entry for just that portion of
2847             # the range.  Note that this will be out-of-order, but that is not
2848             # a problem.
2849             foreach my $code_point ($low .. $high) {
2850                 if ($code_point > 255) {
2851                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
2852                     return 1;
2853                 }
2854                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
2855             }
2856         } # End of looping through lines.
2857
2858         # NOTREACHED
2859     }
2860
2861 #   Not currently used, not fully tested.
2862 #    sub peek {
2863 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2864 #        # record.  Not callable from an each_line_handler(), nor does it call
2865 #        # an each_line_handler() on the line.
2866 #
2867 #        my $self = shift;
2868 #        my $addr = do { no overloading; pack 'J', $self; };
2869 #
2870 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2871 #            my ($adjusted, $line) = @{$inserted_ref};
2872 #            next if $adjusted;
2873 #
2874 #            # Remove comments and trailing space, and return a non-empty
2875 #            # resulting line
2876 #            $line =~ s/#.*//;
2877 #            $line =~ s/\s+$//;
2878 #            return $line if $line ne "";
2879 #        }
2880 #
2881 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2882 #        while (1) { # Loop until find non-comment, non-empty line
2883 #            local $to_trace = 1 if main::DEBUG;
2884 #            trace $_ if main::DEBUG && $to_trace;
2885 #            return if ! defined (my $line = readline $handle{$addr});
2886 #            chomp $line;
2887 #            push @{$added_lines{$addr}}, [ 0, $line ];
2888 #
2889 #            $line =~ s/#.*//;
2890 #            $line =~ s/\s+$//;
2891 #            return $line if $line ne "";
2892 #        }
2893 #
2894 #        return;
2895 #    }
2896
2897
2898     sub insert_lines {
2899         # Lines can be inserted so that it looks like they were in the input
2900         # file at the place it was when this routine is called.  See also
2901         # insert_adjusted_lines().  Lines inserted via this routine go through
2902         # any each_line_handler()
2903
2904         my $self = shift;
2905
2906         # Each inserted line is an array, with the first element being 0 to
2907         # indicate that this line hasn't been adjusted, and needs to be
2908         # processed.
2909         no overloading;
2910         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2911         return;
2912     }
2913
2914     sub insert_adjusted_lines {
2915         # Lines can be inserted so that it looks like they were in the input
2916         # file at the place it was when this routine is called.  See also
2917         # insert_lines().  Lines inserted via this routine are already fully
2918         # adjusted, ready to be processed; each_line_handler()s handlers will
2919         # not be called.  This means this is not a completely general
2920         # facility, as only the last each_line_handler on the stack should
2921         # call this.  It could be made more general, by passing to each of the
2922         # line_handlers their position on the stack, which they would pass on
2923         # to this routine, and that would replace the boolean first element in
2924         # the anonymous array pushed here, so that the next_line routine could
2925         # use that to call only those handlers whose index is after it on the
2926         # stack.  But this is overkill for what is needed now.
2927
2928         my $self = shift;
2929         trace $_[0] if main::DEBUG && $to_trace;
2930
2931         # Each inserted line is an array, with the first element being 1 to
2932         # indicate that this line has been adjusted
2933         no overloading;
2934         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2935         return;
2936     }
2937
2938     sub get_missings {
2939         # Returns the stored up @missings lines' values, and clears the list.
2940         # The values are in an array, consisting of the default in the first
2941         # element, and the property in the 2nd.  However, since these lines
2942         # can be stacked up, the return is an array of all these arrays.
2943
2944         my $self = shift;
2945         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2946
2947         my $addr = do { no overloading; pack 'J', $self; };
2948
2949         # If not accepting a list return, just return the first one.
2950         return shift @{$missings{$addr}} unless wantarray;
2951
2952         my @return = @{$missings{$addr}};
2953         undef @{$missings{$addr}};
2954         return @return;
2955     }
2956
2957     sub _insert_property_into_line {
2958         # Add a property field to $_, if this file requires it.
2959
2960         my $self = shift;
2961         my $addr = do { no overloading; pack 'J', $self; };
2962         my $property = $property{$addr};
2963         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2964
2965         $_ =~ s/(;|$)/; $property$1/;
2966         return;
2967     }
2968
2969     sub carp_bad_line {
2970         # Output consistent error messages, using either a generic one, or the
2971         # one given by the optional parameter.  To avoid gazillions of the
2972         # same message in case the syntax of a  file is way off, this routine
2973         # only outputs the first instance of each message, incrementing a
2974         # count so the totals can be output at the end of the file.
2975
2976         my $self = shift;
2977         my $message = shift;
2978         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2979
2980         my $addr = do { no overloading; pack 'J', $self; };
2981
2982         $message = 'Unexpected line' unless $message;
2983
2984         # No trailing punctuation so as to fit with our addenda.
2985         $message =~ s/[.:;,]$//;
2986
2987         # If haven't seen this exact message before, output it now.  Otherwise
2988         # increment the count of how many times it has occurred
2989         unless ($errors{$addr}->{$message}) {
2990             Carp::my_carp("$message in '$_' in "
2991                             . $file{$addr}
2992                             . " at line $..  Skipping this line;");
2993             $errors{$addr}->{$message} = 1;
2994         }
2995         else {
2996             $errors{$addr}->{$message}++;
2997         }
2998
2999         # Clear the line to prevent any further (meaningful) processing of it.
3000         $_ = "";
3001
3002         return;
3003     }
3004 } # End closure
3005
3006 package Multi_Default;
3007
3008 # Certain properties in early versions of Unicode had more than one possible
3009 # default for code points missing from the files.  In these cases, one
3010 # default applies to everything left over after all the others are applied,
3011 # and for each of the others, there is a description of which class of code
3012 # points applies to it.  This object helps implement this by storing the
3013 # defaults, and for all but that final default, an eval string that generates
3014 # the class that it applies to.
3015
3016
3017 {   # Closure
3018
3019     main::setup_package();
3020
3021     my %class_defaults;
3022     # The defaults structure for the classes
3023     main::set_access('class_defaults', \%class_defaults);
3024
3025     my %other_default;
3026     # The default that applies to everything left over.
3027     main::set_access('other_default', \%other_default, 'r');
3028
3029
3030     sub new {
3031         # The constructor is called with default => eval pairs, terminated by
3032         # the left-over default. e.g.
3033         # Multi_Default->new(
3034         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3035         #               -  0x200D',
3036         #        'R' => 'some other expression that evaluates to code points',
3037         #        .
3038         #        .
3039         #        .
3040         #        'U'));
3041
3042         my $class = shift;
3043
3044         my $self = bless \do{my $anonymous_scalar}, $class;
3045         my $addr = do { no overloading; pack 'J', $self; };
3046
3047         while (@_ > 1) {
3048             my $default = shift;
3049             my $eval = shift;
3050             $class_defaults{$addr}->{$default} = $eval;
3051         }
3052
3053         $other_default{$addr} = shift;
3054
3055         return $self;
3056     }
3057
3058     sub get_next_defaults {
3059         # Iterates and returns the next class of defaults.
3060         my $self = shift;
3061         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3062
3063         my $addr = do { no overloading; pack 'J', $self; };
3064
3065         return each %{$class_defaults{$addr}};
3066     }
3067 }
3068
3069 package Alias;
3070
3071 # An alias is one of the names that a table goes by.  This class defines them
3072 # including some attributes.  Everything is currently setup in the
3073 # constructor.
3074
3075
3076 {   # Closure
3077
3078     main::setup_package();
3079
3080     my %name;
3081     main::set_access('name', \%name, 'r');
3082
3083     my %loose_match;
3084     # Should this name match loosely or not.
3085     main::set_access('loose_match', \%loose_match, 'r');
3086
3087     my %make_re_pod_entry;
3088     # Some aliases should not get their own entries in the re section of the
3089     # pod, because they are covered by a wild-card, and some we want to
3090     # discourage use of.  Binary
3091     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3092
3093     my %ucd;
3094     # Is this documented to be accessible via Unicode::UCD
3095     main::set_access('ucd', \%ucd, 'r', 's');
3096
3097     my %status;
3098     # Aliases have a status, like deprecated, or even suppressed (which means
3099     # they don't appear in documentation).  Enum
3100     main::set_access('status', \%status, 'r');
3101
3102     my %ok_as_filename;
3103     # Similarly, some aliases should not be considered as usable ones for
3104     # external use, such as file names, or we don't want documentation to
3105     # recommend them.  Boolean
3106     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3107
3108     sub new {
3109         my $class = shift;
3110
3111         my $self = bless \do { my $anonymous_scalar }, $class;
3112         my $addr = do { no overloading; pack 'J', $self; };
3113
3114         $name{$addr} = shift;
3115         $loose_match{$addr} = shift;
3116         $make_re_pod_entry{$addr} = shift;
3117         $ok_as_filename{$addr} = shift;
3118         $status{$addr} = shift;
3119         $ucd{$addr} = shift;
3120
3121         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3122
3123         # Null names are never ok externally
3124         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3125
3126         return $self;
3127     }
3128 }
3129
3130 package Range;
3131
3132 # A range is the basic unit for storing code points, and is described in the
3133 # comments at the beginning of the program.  Each range has a starting code
3134 # point; an ending code point (not less than the starting one); a value
3135 # that applies to every code point in between the two end-points, inclusive;
3136 # and an enum type that applies to the value.  The type is for the user's
3137 # convenience, and has no meaning here, except that a non-zero type is
3138 # considered to not obey the normal Unicode rules for having standard forms.
3139 #
3140 # The same structure is used for both map and match tables, even though in the
3141 # latter, the value (and hence type) is irrelevant and could be used as a
3142 # comment.  In map tables, the value is what all the code points in the range
3143 # map to.  Type 0 values have the standardized version of the value stored as
3144 # well, so as to not have to recalculate it a lot.
3145
3146 sub trace { return main::trace(@_); }
3147
3148 {   # Closure
3149
3150     main::setup_package();
3151
3152     my %start;
3153     main::set_access('start', \%start, 'r', 's');
3154
3155     my %end;
3156     main::set_access('end', \%end, 'r', 's');
3157
3158     my %value;
3159     main::set_access('value', \%value, 'r');
3160
3161     my %type;
3162     main::set_access('type', \%type, 'r');
3163
3164     my %standard_form;
3165     # The value in internal standard form.  Defined only if the type is 0.
3166     main::set_access('standard_form', \%standard_form);
3167
3168     # Note that if these fields change, the dump() method should as well
3169
3170     sub new {
3171         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3172         my $class = shift;
3173
3174         my $self = bless \do { my $anonymous_scalar }, $class;
3175         my $addr = do { no overloading; pack 'J', $self; };
3176
3177         $start{$addr} = shift;
3178         $end{$addr} = shift;
3179
3180         my %args = @_;
3181
3182         my $value = delete $args{'Value'};  # Can be 0
3183         $value = "" unless defined $value;
3184         $value{$addr} = $value;
3185
3186         $type{$addr} = delete $args{'Type'} || 0;
3187
3188         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3189
3190         return $self;
3191     }
3192
3193     use overload
3194         fallback => 0,
3195         qw("") => "_operator_stringify",
3196         "." => \&main::_operator_dot,
3197         ".=" => \&main::_operator_dot_equal,
3198     ;
3199
3200     sub _operator_stringify {
3201         my $self = shift;
3202         my $addr = do { no overloading; pack 'J', $self; };
3203
3204         # Output it like '0041..0065 (value)'
3205         my $return = sprintf("%04X", $start{$addr})
3206                         .  '..'
3207                         . sprintf("%04X", $end{$addr});
3208         my $value = $value{$addr};
3209         my $type = $type{$addr};
3210         $return .= ' (';
3211         $return .= "$value";
3212         $return .= ", Type=$type" if $type != 0;
3213         $return .= ')';
3214
3215         return $return;
3216     }
3217
3218     sub standard_form {
3219         # Calculate the standard form only if needed, and cache the result.
3220         # The standard form is the value itself if the type is special.
3221         # This represents a considerable CPU and memory saving - at the time
3222         # of writing there are 368676 non-special objects, but the standard
3223         # form is only requested for 22047 of them - ie about 6%.
3224
3225         my $self = shift;
3226         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3227
3228         my $addr = do { no overloading; pack 'J', $self; };
3229
3230         return $standard_form{$addr} if defined $standard_form{$addr};
3231
3232         my $value = $value{$addr};
3233         return $value if $type{$addr};
3234         return $standard_form{$addr} = main::standardize($value);
3235     }
3236
3237     sub dump {
3238         # Human, not machine readable.  For machine readable, comment out this
3239         # entire routine and let the standard one take effect.
3240         my $self = shift;
3241         my $indent = shift;
3242         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3243
3244         my $addr = do { no overloading; pack 'J', $self; };
3245
3246         my $return = $indent
3247                     . sprintf("%04X", $start{$addr})
3248                     . '..'
3249                     . sprintf("%04X", $end{$addr})
3250                     . " '$value{$addr}';";
3251         if (! defined $standard_form{$addr}) {
3252             $return .= "(type=$type{$addr})";
3253         }
3254         elsif ($standard_form{$addr} ne $value{$addr}) {
3255             $return .= "(standard '$standard_form{$addr}')";
3256         }
3257         return $return;
3258     }
3259 } # End closure
3260
3261 package _Range_List_Base;
3262
3263 # Base class for range lists.  A range list is simply an ordered list of
3264 # ranges, so that the ranges with the lowest starting numbers are first in it.
3265 #
3266 # When a new range is added that is adjacent to an existing range that has the
3267 # same value and type, it merges with it to form a larger range.
3268 #
3269 # Ranges generally do not overlap, except that there can be multiple entries
3270 # of single code point ranges.  This is because of NameAliases.txt.
3271 #
3272 # In this program, there is a standard value such that if two different
3273 # values, have the same standard value, they are considered equivalent.  This
3274 # value was chosen so that it gives correct results on Unicode data
3275
3276 # There are a number of methods to manipulate range lists, and some operators
3277 # are overloaded to handle them.
3278
3279 sub trace { return main::trace(@_); }
3280
3281 { # Closure
3282
3283     our $addr;
3284
3285     # Max is initialized to a negative value that isn't adjacent to 0, for
3286     # simpler tests
3287     my $max_init = -2;
3288
3289     main::setup_package();
3290
3291     my %ranges;
3292     # The list of ranges
3293     main::set_access('ranges', \%ranges, 'readable_array');
3294
3295     my %max;
3296     # The highest code point in the list.  This was originally a method, but
3297     # actual measurements said it was used a lot.
3298     main::set_access('max', \%max, 'r');
3299
3300     my %each_range_iterator;
3301     # Iterator position for each_range()
3302     main::set_access('each_range_iterator', \%each_range_iterator);
3303
3304     my %owner_name_of;
3305     # Name of parent this is attached to, if any.  Solely for better error
3306     # messages.
3307     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3308
3309     my %_search_ranges_cache;
3310     # A cache of the previous result from _search_ranges(), for better
3311     # performance
3312     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3313
3314     sub new {
3315         my $class = shift;
3316         my %args = @_;
3317
3318         # Optional initialization data for the range list.
3319         my $initialize = delete $args{'Initialize'};
3320
3321         my $self;
3322
3323         # Use _union() to initialize.  _union() returns an object of this
3324         # class, which means that it will call this constructor recursively.
3325         # But it won't have this $initialize parameter so that it won't
3326         # infinitely loop on this.
3327         return _union($class, $initialize, %args) if defined $initialize;
3328
3329         $self = bless \do { my $anonymous_scalar }, $class;
3330         my $addr = do { no overloading; pack 'J', $self; };
3331
3332         # Optional parent object, only for debug info.
3333         $owner_name_of{$addr} = delete $args{'Owner'};
3334         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3335
3336         # Stringify, in case it is an object.
3337         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3338
3339         # This is used only for error messages, and so a colon is added
3340         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3341
3342         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3343
3344         $max{$addr} = $max_init;
3345
3346         $_search_ranges_cache{$addr} = 0;
3347         $ranges{$addr} = [];
3348
3349         return $self;
3350     }
3351
3352     use overload
3353         fallback => 0,
3354         qw("") => "_operator_stringify",
3355         "." => \&main::_operator_dot,
3356         ".=" => \&main::_operator_dot_equal,
3357     ;
3358
3359     sub _operator_stringify {
3360         my $self = shift;
3361         my $addr = do { no overloading; pack 'J', $self; };
3362
3363         return "Range_List attached to '$owner_name_of{$addr}'"
3364                                                 if $owner_name_of{$addr};
3365         return "anonymous Range_List " . \$self;
3366     }
3367
3368     sub _union {
3369         # Returns the union of the input code points.  It can be called as
3370         # either a constructor or a method.  If called as a method, the result
3371         # will be a new() instance of the calling object, containing the union
3372         # of that object with the other parameter's code points;  if called as
3373         # a constructor, the first parameter gives the class that the new object
3374         # should be, and the second parameter gives the code points to go into
3375         # it.
3376         # In either case, there are two parameters looked at by this routine;
3377         # any additional parameters are passed to the new() constructor.
3378         #
3379         # The code points can come in the form of some object that contains
3380         # ranges, and has a conventionally named method to access them; or
3381         # they can be an array of individual code points (as integers); or
3382         # just a single code point.
3383         #
3384         # If they are ranges, this routine doesn't make any effort to preserve
3385         # the range values and types of one input over the other.  Therefore
3386         # this base class should not allow _union to be called from other than
3387         # initialization code, so as to prevent two tables from being added
3388         # together where the range values matter.  The general form of this
3389         # routine therefore belongs in a derived class, but it was moved here
3390         # to avoid duplication of code.  The failure to overload this in this
3391         # class keeps it safe.
3392         #
3393         # It does make the effort during initialization to accept tables with
3394         # multiple values for the same code point, and to preserve the order
3395         # of these.  If there is only one input range or range set, it doesn't
3396         # sort (as it should already be sorted to the desired order), and will
3397         # accept multiple values per code point.  Otherwise it will merge
3398         # multiple values into a single one.
3399
3400         my $self;
3401         my @args;   # Arguments to pass to the constructor
3402
3403         my $class = shift;
3404
3405         # If a method call, will start the union with the object itself, and
3406         # the class of the new object will be the same as self.
3407         if (ref $class) {
3408             $self = $class;
3409             $class = ref $self;
3410             push @args, $self;
3411         }
3412
3413         # Add the other required parameter.
3414         push @args, shift;
3415         # Rest of parameters are passed on to the constructor
3416
3417         # Accumulate all records from both lists.
3418         my @records;
3419         my $input_count = 0;
3420         for my $arg (@args) {
3421             #local $to_trace = 0 if main::DEBUG;
3422             trace "argument = $arg" if main::DEBUG && $to_trace;
3423             if (! defined $arg) {
3424                 my $message = "";
3425                 if (defined $self) {
3426                     no overloading;
3427                     $message .= $owner_name_of{pack 'J', $self};
3428                 }
3429                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3430                 return;
3431             }
3432
3433             $arg = [ $arg ] if ! ref $arg;
3434             my $type = ref $arg;
3435             if ($type eq 'ARRAY') {
3436                 foreach my $element (@$arg) {
3437                     push @records, Range->new($element, $element);
3438                     $input_count++;
3439                 }
3440             }
3441             elsif ($arg->isa('Range')) {
3442                 push @records, $arg;
3443                 $input_count++;
3444             }
3445             elsif ($arg->can('ranges')) {
3446                 push @records, $arg->ranges;
3447                 $input_count++;
3448             }
3449             else {
3450                 my $message = "";
3451                 if (defined $self) {
3452                     no overloading;
3453                     $message .= $owner_name_of{pack 'J', $self};
3454                 }
3455                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3456                 return;
3457             }
3458         }
3459
3460         # Sort with the range containing the lowest ordinal first, but if
3461         # two ranges start at the same code point, sort with the bigger range
3462         # of the two first, because it takes fewer cycles.
3463         if ($input_count > 1) {
3464             @records = sort { ($a->start <=> $b->start)
3465                                       or
3466                                     # if b is shorter than a, b->end will be
3467                                     # less than a->end, and we want to select
3468                                     # a, so want to return -1
3469                                     ($b->end <=> $a->end)
3470                                    } @records;
3471         }
3472
3473         my $new = $class->new(@_);
3474
3475         # Fold in records so long as they add new information.
3476         for my $set (@records) {
3477             my $start = $set->start;
3478             my $end   = $set->end;
3479             my $value = $set->value;
3480             my $type  = $set->type;
3481             if ($start > $new->max) {
3482                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3483             }
3484             elsif ($end > $new->max) {
3485                 $new->_add_delete('+', $new->max +1, $end, $value,
3486                                                                 Type => $type);
3487             }
3488             elsif ($input_count == 1) {
3489                 # Here, overlaps existing range, but is from a single input,
3490                 # so preserve the multiple values from that input.
3491                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3492                                                 Replace => $MULTIPLE_AFTER);
3493             }
3494         }
3495
3496         return $new;
3497     }
3498
3499     sub range_count {        # Return the number of ranges in the range list
3500         my $self = shift;
3501         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3502
3503         no overloading;
3504         return scalar @{$ranges{pack 'J', $self}};
3505     }
3506
3507     sub min {
3508         # Returns the minimum code point currently in the range list, or if
3509         # the range list is empty, 2 beyond the max possible.  This is a
3510         # method because used so rarely, that not worth saving between calls,
3511         # and having to worry about changing it as ranges are added and
3512         # deleted.
3513
3514         my $self = shift;
3515         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3516
3517         my $addr = do { no overloading; pack 'J', $self; };
3518
3519         # If the range list is empty, return a large value that isn't adjacent
3520         # to any that could be in the range list, for simpler tests
3521         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3522         return $ranges{$addr}->[0]->start;
3523     }
3524
3525     sub contains {
3526         # Boolean: Is argument in the range list?  If so returns $i such that:
3527         #   range[$i]->end < $codepoint <= range[$i+1]->end
3528         # which is one beyond what you want; this is so that the 0th range
3529         # doesn't return false
3530         my $self = shift;
3531         my $codepoint = shift;
3532         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3533
3534         my $i = $self->_search_ranges($codepoint);
3535         return 0 unless defined $i;
3536
3537         # The search returns $i, such that
3538         #   range[$i-1]->end < $codepoint <= range[$i]->end
3539         # So is in the table if and only iff it is at least the start position
3540         # of range $i.
3541         no overloading;
3542         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3543         return $i + 1;
3544     }
3545
3546     sub containing_range {
3547         # Returns the range object that contains the code point, undef if none
3548
3549         my $self = shift;
3550         my $codepoint = shift;
3551         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3552
3553         my $i = $self->contains($codepoint);
3554         return unless $i;
3555
3556         # contains() returns 1 beyond where we should look
3557         no overloading;
3558         return $ranges{pack 'J', $self}->[$i-1];
3559     }
3560
3561     sub value_of {
3562         # Returns the value associated with the code point, undef if none
3563
3564         my $self = shift;
3565         my $codepoint = shift;
3566         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3567
3568         my $range = $self->containing_range($codepoint);
3569         return unless defined $range;
3570
3571         return $range->value;
3572     }
3573
3574     sub type_of {
3575         # Returns the type of the range containing the code point, undef if
3576         # the code point is not in the table
3577
3578         my $self = shift;
3579         my $codepoint = shift;
3580         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3581
3582         my $range = $self->containing_range($codepoint);
3583         return unless defined $range;
3584
3585         return $range->type;
3586     }
3587
3588     sub _search_ranges {
3589         # Find the range in the list which contains a code point, or where it
3590         # should go if were to add it.  That is, it returns $i, such that:
3591         #   range[$i-1]->end < $codepoint <= range[$i]->end
3592         # Returns undef if no such $i is possible (e.g. at end of table), or
3593         # if there is an error.
3594
3595         my $self = shift;
3596         my $code_point = shift;
3597         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3598
3599         my $addr = do { no overloading; pack 'J', $self; };
3600
3601         return if $code_point > $max{$addr};
3602         my $r = $ranges{$addr};                # The current list of ranges
3603         my $range_list_size = scalar @$r;
3604         my $i;
3605
3606         use integer;        # want integer division
3607
3608         # Use the cached result as the starting guess for this one, because,
3609         # an experiment on 5.1 showed that 90% of the time the cache was the
3610         # same as the result on the next call (and 7% it was one less).
3611         $i = $_search_ranges_cache{$addr};
3612         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3613                                             # from an intervening deletion
3614         #local $to_trace = 1 if main::DEBUG;
3615         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3616         return $i if $code_point <= $r->[$i]->end
3617                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3618
3619         # Here the cache doesn't yield the correct $i.  Try adding 1.
3620         if ($i < $range_list_size - 1
3621             && $r->[$i]->end < $code_point &&
3622             $code_point <= $r->[$i+1]->end)
3623         {
3624             $i++;
3625             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3626             $_search_ranges_cache{$addr} = $i;
3627             return $i;
3628         }
3629
3630         # Here, adding 1 also didn't work.  We do a binary search to
3631         # find the correct position, starting with current $i
3632         my $lower = 0;
3633         my $upper = $range_list_size - 1;
3634         while (1) {
3635             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3636
3637             if ($code_point <= $r->[$i]->end) {
3638
3639                 # Here we have met the upper constraint.  We can quit if we
3640                 # also meet the lower one.
3641                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3642
3643                 $upper = $i;        # Still too high.
3644
3645             }
3646             else {
3647
3648                 # Here, $r[$i]->end < $code_point, so look higher up.
3649                 $lower = $i;
3650             }
3651
3652             # Split search domain in half to try again.
3653             my $temp = ($upper + $lower) / 2;
3654
3655             # No point in continuing unless $i changes for next time
3656             # in the loop.
3657             if ($temp == $i) {
3658
3659                 # We can't reach the highest element because of the averaging.
3660                 # So if one below the upper edge, force it there and try one
3661                 # more time.
3662                 if ($i == $range_list_size - 2) {
3663
3664                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3665                     $i = $range_list_size - 1;
3666
3667                     # Change $lower as well so if fails next time through,
3668                     # taking the average will yield the same $i, and we will
3669                     # quit with the error message just below.
3670                     $lower = $i;
3671                     next;
3672                 }
3673                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3674                 return;
3675             }
3676             $i = $temp;
3677         } # End of while loop
3678
3679         if (main::DEBUG && $to_trace) {
3680             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3681             trace "i=  [ $i ]", $r->[$i];
3682             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3683         }
3684
3685         # Here we have found the offset.  Cache it as a starting point for the
3686         # next call.
3687         $_search_ranges_cache{$addr} = $i;
3688         return $i;
3689     }
3690
3691     sub _add_delete {
3692         # Add, replace or delete ranges to or from a list.  The $type
3693         # parameter gives which:
3694         #   '+' => insert or replace a range, returning a list of any changed
3695         #          ranges.
3696         #   '-' => delete a range, returning a list of any deleted ranges.
3697         #
3698         # The next three parameters give respectively the start, end, and
3699         # value associated with the range.  'value' should be null unless the
3700         # operation is '+';
3701         #
3702         # The range list is kept sorted so that the range with the lowest
3703         # starting position is first in the list, and generally, adjacent
3704         # ranges with the same values are merged into a single larger one (see
3705         # exceptions below).
3706         #
3707         # There are more parameters; all are key => value pairs:
3708         #   Type    gives the type of the value.  It is only valid for '+'.
3709         #           All ranges have types; if this parameter is omitted, 0 is
3710         #           assumed.  Ranges with type 0 are assumed to obey the
3711         #           Unicode rules for casing, etc; ranges with other types are
3712         #           not.  Otherwise, the type is arbitrary, for the caller's
3713         #           convenience, and looked at only by this routine to keep
3714         #           adjacent ranges of different types from being merged into
3715         #           a single larger range, and when Replace =>
3716         #           $IF_NOT_EQUIVALENT is specified (see just below).
3717         #   Replace  determines what to do if the range list already contains
3718         #            ranges which coincide with all or portions of the input
3719         #            range.  It is only valid for '+':
3720         #       => $NO            means that the new value is not to replace
3721         #                         any existing ones, but any empty gaps of the
3722         #                         range list coinciding with the input range
3723         #                         will be filled in with the new value.
3724         #       => $UNCONDITIONALLY  means to replace the existing values with
3725         #                         this one unconditionally.  However, if the
3726         #                         new and old values are identical, the
3727         #                         replacement is skipped to save cycles
3728         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3729         #          (the default)  with this one if they are not equivalent.
3730         #                         Ranges are equivalent if their types are the
3731         #                         same, and they are the same string; or if
3732         #                         both are type 0 ranges, if their Unicode
3733         #                         standard forms are identical.  In this last
3734         #                         case, the routine chooses the more "modern"
3735         #                         one to use.  This is because some of the
3736         #                         older files are formatted with values that
3737         #                         are, for example, ALL CAPs, whereas the
3738         #                         derived files have a more modern style,
3739         #                         which looks better.  By looking for this
3740         #                         style when the pre-existing and replacement
3741         #                         standard forms are the same, we can move to
3742         #                         the modern style
3743         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3744         #                         existing one, but has a different value,
3745         #                         don't replace the existing one, but insert
3746         #                         this one so that the same range can occur
3747         #                         multiple times.  They are stored LIFO, so
3748         #                         that the final one inserted is the first one
3749         #                         returned in an ordered search of the table.
3750         #                         If this is an exact duplicate, including the
3751         #                         value, the original will be moved to be
3752         #                         first, before any other duplicate ranges
3753         #                         with different values.
3754         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3755         #                         FIFO, so that this one is inserted after all
3756         #                         others that currently exist.  If this is an
3757         #                         exact duplicate, including value, of an
3758         #                         existing range, this one is discarded
3759         #                         (leaving the existing one in its original,
3760         #                         higher priority position
3761         #       => $CROAK         Die with an error if is already there
3762         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3763         #
3764         # "same value" means identical for non-type-0 ranges, and it means
3765         # having the same standard forms for type-0 ranges.
3766
3767         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3768
3769         my $self = shift;
3770         my $operation = shift;   # '+' for add/replace; '-' for delete;
3771         my $start = shift;
3772         my $end   = shift;
3773         my $value = shift;
3774
3775         my %args = @_;
3776
3777         $value = "" if not defined $value;        # warning: $value can be "0"
3778
3779         my $replace = delete $args{'Replace'};
3780         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3781
3782         my $type = delete $args{'Type'};
3783         $type = 0 unless defined $type;
3784
3785         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3786
3787         my $addr = do { no overloading; pack 'J', $self; };
3788
3789         if ($operation ne '+' && $operation ne '-') {
3790             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3791             return;
3792         }
3793         unless (defined $start && defined $end) {
3794             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3795             return;
3796         }
3797         unless ($end >= $start) {
3798             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3799             return;
3800         }
3801         #local $to_trace = 1 if main::DEBUG;
3802
3803         if ($operation eq '-') {
3804             if ($replace != $IF_NOT_EQUIVALENT) {
3805                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3806                 $replace = $IF_NOT_EQUIVALENT;
3807             }
3808             if ($type) {
3809                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3810                 $type = 0;
3811             }
3812             if ($value ne "") {
3813                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3814                 $value = "";
3815             }
3816         }
3817
3818         my $r = $ranges{$addr};               # The current list of ranges
3819         my $range_list_size = scalar @$r;     # And its size
3820         my $max = $max{$addr};                # The current high code point in
3821                                               # the list of ranges
3822
3823         # Do a special case requiring fewer machine cycles when the new range
3824         # starts after the current highest point.  The Unicode input data is
3825         # structured so this is common.
3826         if ($start > $max) {
3827
3828             trace "$owner_name_of{$addr} $operation", sprintf("%04X..%04X (%s) type=%d; prev max=%04X", $start, $end, $value, $type, $max) if main::DEBUG && $to_trace;
3829             return if $operation eq '-'; # Deleting a non-existing range is a
3830                                          # no-op
3831
3832             # If the new range doesn't logically extend the current final one
3833             # in the range list, create a new range at the end of the range
3834             # list.  (max cleverly is initialized to a negative number not
3835             # adjacent to 0 if the range list is empty, so even adding a range
3836             # to an empty range list starting at 0 will have this 'if'
3837             # succeed.)
3838             if ($start > $max + 1        # non-adjacent means can't extend.
3839                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3840                 || @{$r}[-1]->type != $type # types differ, can't extend.
3841             ) {
3842                 push @$r, Range->new($start, $end,
3843                                      Value => $value,
3844                                      Type => $type);
3845             }
3846             else {
3847
3848                 # Here, the new range starts just after the current highest in
3849                 # the range list, and they have the same type and value.
3850                 # Extend the existing range to incorporate the new one.
3851                 @{$r}[-1]->set_end($end);
3852             }
3853
3854             # This becomes the new maximum.
3855             $max{$addr} = $end;
3856
3857             return;
3858         }
3859         #local $to_trace = 0 if main::DEBUG;
3860
3861         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3862
3863         # Here, the input range isn't after the whole rest of the range list.
3864         # Most likely 'splice' will be needed.  The rest of the routine finds
3865         # the needed splice parameters, and if necessary, does the splice.
3866         # First, find the offset parameter needed by the splice function for
3867         # the input range.  Note that the input range may span multiple
3868         # existing ones, but we'll worry about that later.  For now, just find
3869         # the beginning.  If the input range is to be inserted starting in a
3870         # position not currently in the range list, it must (obviously) come
3871         # just after the range below it, and just before the range above it.
3872         # Slightly less obviously, it will occupy the position currently
3873         # occupied by the range that is to come after it.  More formally, we
3874         # are looking for the position, $i, in the array of ranges, such that:
3875         #
3876         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3877         #
3878         # (The ordered relationships within existing ranges are also shown in
3879         # the equation above).  However, if the start of the input range is
3880         # within an existing range, the splice offset should point to that
3881         # existing range's position in the list; that is $i satisfies a
3882         # somewhat different equation, namely:
3883         #
3884         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3885         #
3886         # More briefly, $start can come before or after r[$i]->start, and at
3887         # this point, we don't know which it will be.  However, these
3888         # two equations share these constraints:
3889         #
3890         #   r[$i-1]->end < $start <= r[$i]->end
3891         #
3892         # And that is good enough to find $i.
3893
3894         my $i = $self->_search_ranges($start);
3895         if (! defined $i) {
3896             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3897             return;
3898         }
3899
3900         # The search function returns $i such that:
3901         #
3902         # r[$i-1]->end < $start <= r[$i]->end
3903         #
3904         # That means that $i points to the first range in the range list
3905         # that could possibly be affected by this operation.  We still don't
3906         # know if the start of the input range is within r[$i], or if it
3907         # points to empty space between r[$i-1] and r[$i].
3908         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3909
3910         # Special case the insertion of data that is not to replace any
3911         # existing data.
3912         if ($replace == $NO) {  # If $NO, has to be operation '+'
3913             #local $to_trace = 1 if main::DEBUG;
3914             trace "Doesn't replace" if main::DEBUG && $to_trace;
3915
3916             # Here, the new range is to take effect only on those code points
3917             # that aren't already in an existing range.  This can be done by
3918             # looking through the existing range list and finding the gaps in
3919             # the ranges that this new range affects, and then calling this
3920             # function recursively on each of those gaps, leaving untouched
3921             # anything already in the list.  Gather up a list of the changed
3922             # gaps first so that changes to the internal state as new ranges
3923             # are added won't be a problem.
3924             my @gap_list;
3925
3926             # First, if the starting point of the input range is outside an
3927             # existing one, there is a gap from there to the beginning of the
3928             # existing range -- add a span to fill the part that this new
3929             # range occupies
3930             if ($start < $r->[$i]->start) {
3931                 push @gap_list, Range->new($start,
3932                                            main::min($end,
3933                                                      $r->[$i]->start - 1),
3934                                            Type => $type);
3935                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3936             }
3937
3938             # Then look through the range list for other gaps until we reach
3939             # the highest range affected by the input one.
3940             my $j;
3941             for ($j = $i+1; $j < $range_list_size; $j++) {
3942                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3943                 last if $end < $r->[$j]->start;
3944
3945                 # If there is a gap between when this range starts and the
3946                 # previous one ends, add a span to fill it.  Note that just
3947                 # because there are two ranges doesn't mean there is a
3948                 # non-zero gap between them.  It could be that they have
3949                 # different values or types
3950                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3951                     push @gap_list,
3952                         Range->new($r->[$j-1]->end + 1,
3953                                    $r->[$j]->start - 1,
3954                                    Type => $type);
3955                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3956                 }
3957             }
3958
3959             # Here, we have either found an existing range in the range list,
3960             # beyond the area affected by the input one, or we fell off the
3961             # end of the loop because the input range affects the whole rest
3962             # of the range list.  In either case, $j is 1 higher than the
3963             # highest affected range.  If $j == $i, it means that there are no
3964             # affected ranges, that the entire insertion is in the gap between
3965             # r[$i-1], and r[$i], which we already have taken care of before
3966             # the loop.
3967             # On the other hand, if there are affected ranges, it might be
3968             # that there is a gap that needs filling after the final such
3969             # range to the end of the input range
3970             if ($r->[$j-1]->end < $end) {
3971                     push @gap_list, Range->new(main::max($start,
3972                                                          $r->[$j-1]->end + 1),
3973                                                $end,
3974                                                Type => $type);
3975                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3976             }
3977
3978             # Call recursively to fill in all the gaps.
3979             foreach my $gap (@gap_list) {
3980                 $self->_add_delete($operation,
3981                                    $gap->start,
3982                                    $gap->end,
3983                                    $value,
3984                                    Type => $type);
3985             }
3986
3987             return;
3988         }
3989
3990         # Here, we have taken care of the case where $replace is $NO.
3991         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3992         # If inserting a multiple record, this is where it goes, before the
3993         # first (if any) existing one if inserting LIFO.  (If this is to go
3994         # afterwards, FIFO, we below move the pointer to there.)  These imply
3995         # an insertion, and no change to any existing ranges.  Note that $i
3996         # can be -1 if this new range doesn't actually duplicate any existing,
3997         # and comes at the beginning of the list.
3998         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3999
4000             if ($start != $end) {
4001                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
4002                 return;
4003             }
4004
4005             # If the new code point is within a current range ...
4006             if ($end >= $r->[$i]->start) {
4007
4008        &nbs