This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Revert "Upgrade Socket to CPAN version 2.008"
[perl5.git] / cpan / Socket / Makefile.PL
1 #!perl
2 use strict;
3 use warnings;
4
5 use ExtUtils::MakeMaker;
6 use ExtUtils::Constant 0.23 'WriteConstants';
7 use Config;
8
9 my @DEFINES;
10
11 my $cb;
12 my $seq = 0;
13 sub check_for
14 {
15     my %args = @_;
16     return if exists $Config{$args{confkey}};
17
18     require ExtUtils::CBuilder;
19     $cb ||= ExtUtils::CBuilder->new( quiet => 1 );
20
21     my $main = $args{main};
22
23     print "Checking $args{define}...\n";
24
25     my $file_base = "test-$seq"; $seq++;
26
27     my $file_source = "$file_base.c";
28
29     {
30         open( my $file_source_fh, ">", $file_source ) or die "Cannot write $file_source - $!";
31         print $file_source_fh <<"EOF";
32 #include <sys/types.h>
33 #ifdef WIN32
34 # include <ws2tcpip.h>
35 # include <winsock.h>
36 #else
37 # include <sys/socket.h>
38 # include <netdb.h>
39 # include <netinet/in.h>
40 # include <arpa/inet.h>
41 #endif
42 int main(int argc, char *argv[])
43   {
44     (void)argc;
45     (void)argv;
46     $main
47     return 0;
48   }
49 EOF
50     }
51
52     my $file_obj = eval { $cb->compile( source => $file_source ) };
53     unlink $file_source;
54
55     return 0 unless defined $file_obj;
56
57     my $file_exe = eval { $cb->link_executable( objects => $file_obj ) };
58     unlink $file_obj;
59
60     return 0 unless defined $file_exe;
61
62     # Don't need to try running it
63     unlink $file_exe;
64
65     push @DEFINES, $args{define};
66 }
67
68 sub check_for_func
69 {
70     my %args = @_;
71     my $func = delete $args{func};
72     check_for( %args, main => "void *p = &$func; (void)p;" );
73 }
74
75 my %defines = (
76     # -Dfoo               func()        $Config{key}
77     HAS_GETADDRINFO => [ "getaddrinfo", "d_getaddrinfo" ],
78     HAS_GETNAMEINFO => [ "getnameinfo", "d_getnameinfo" ],
79     HAS_INET_ATON   => [ "inet_aton",   "d_inetaton" ],
80     HAS_INETNTOP    => [ "inet_ntop",   "d_inetntop" ],
81     HAS_INETPTON    => [ "inet_pton",   "d_inetpton" ],
82 );
83
84 foreach my $define ( sort keys %defines ) {
85     my ( $func, $key ) = @{$defines{$define}};
86     check_for_func( 
87         confkey => $key,
88         define  => $define,
89         func    => $func
90     );
91 }
92
93 check_for(
94     confkey => "d_sockaddr_sa_len",
95     define  => "HAS_SOCKADDR_SA_LEN",
96     main    => "struct sockaddr sa; sa.sa_len = 0;"
97 );
98
99 check_for(
100     confkey => "d_sockaddr_in6",
101     define  => "HAS_SOCKADDR_IN6",
102     main    => "struct sockaddr_in6 sin6; sin6.sin6_family = AF_INET6;"
103 );
104
105 check_for(
106     confkey => "d_sin6_scope_id",
107     define  => "HAS_SIN6_SCOPE_ID",
108     main    => "struct sockaddr_in6 sin6; sin6.sin6_scope_id = 0;"
109 );
110
111 check_for(
112     confkey => "d_ip_mreq",
113     define  => "HAS_IP_MREQ",
114     main    => "struct ip_mreq mreq; mreq.imr_multiaddr.s_addr = INADDR_ANY;"
115 );
116
117 # TODO: Needs adding to perl5 core before importing dual-life again
118 check_for(
119     confkey => "d_ip_mreq_source",
120     define  => "HAS_IP_MREQ_SOURCE",
121     main    => "struct ip_mreq_source mreq; mreq.imr_multiaddr.s_addr = INADDR_ANY;"
122 );
123
124 check_for(
125     confkey => "d_ipv6_mreq",
126     define  => "HAS_IPV6_MREQ",
127     main    => "struct ipv6_mreq mreq; mreq.ipv6mr_interface = 0;"
128 );
129
130 my %makefile_args;
131
132 # Since we're providing a later version of a core module, before 5.12 the
133 # @INC order is wrong so we'll have to go in perl rather than site dirs
134 $makefile_args{INSTALLDIRS} = "perl" if $] < 5.012;
135
136 WriteMakefile(
137     NAME          => 'Socket',
138     VERSION_FROM  => 'Socket.pm',
139     # ABSTRACT_FROM gets confused by C<Socket>
140     ABSTRACT      => 'networking constants and support functions',
141    ($Config{libs} =~ /(-lsocks\S*)/ ? (LIBS => [ "$1" ] ) : ()),
142     XSPROTOARG    => '-noprototypes',           # XXX remove later?
143     realclean     => {FILES=> 'const-c.inc const-xs.inc'},
144     DEFINE        => join( " ", map { "-D$_" } @DEFINES ),
145     CONFIGURE_REQUIRES => {
146         'ExtUtils::CBuilder' => 0,
147         'ExtUtils::Constant' => '0.23',
148     },
149     MIN_PERL_VERSION => '5.006001',
150     LICENSE       => 'perl',
151     %makefile_args,
152 );
153 my @names = (
154     qw(
155         AF_802 AF_AAL AF_APPLETALK AF_CCITT AF_CHAOS AF_CTF AF_DATAKIT
156         AF_DECnet AF_DLI AF_ECMA AF_GOSIP AF_HYLINK AF_IMPLINK AF_INET AF_INET6
157         AF_ISO AF_KEY AF_LAST AF_LAT AF_LINK AF_MAX AF_NBS AF_NIT AF_NS AF_OSI
158         AF_OSINET AF_PUP AF_ROUTE AF_SNA AF_UNIX AF_UNSPEC AF_USER AF_WAN
159         AF_X25
160
161         AI_ADDRCONFIG AI_ALL AI_CANONIDN AI_CANONNAME AI_IDN
162         AI_IDN_ALLOW_UNASSIGNED AI_IDN_USE_STD3_ASCII_RULES AI_NUMERICHOST
163         AI_NUMERICSERV AI_PASSIVE AI_V4MAPPED
164
165         EAI_ADDRFAMILY EAI_AGAIN EAI_BADFLAGS EAI_BADHINTS EAI_FAIL EAI_FAMILY
166         EAI_NODATA EAI_NONAME EAI_PROTOCOL EAI_SERVICE EAI_SOCKTYPE EAI_SYSTEM
167
168         IOV_MAX
169
170         IP_ADD_MEMBERSHIP IP_ADD_SOURCE_MEMBERSHIP IP_DROP_MEMBERSHIP
171         IP_DROP_SOURCE_MEMBERSHIP IP_HDRINCL IP_MULTICAST_IF IP_MULTICAST_LOOP
172         IP_MULTICAST_TTL IP_OPTIONS IP_RECVOPTS IP_RECVRETOPTS IP_RETOPTS IP_TOS
173         IP_TTL 
174
175         IPV6_ADD_MEMBERSHIP IPV6_DROP_MEMBERSHIP IPV6_JOIN_GROUP
176         IPV6_LEAVE_GROUP IPV6_MTU IPV6_MTU_DISCOVER IPV6_MULTICAST_HOPS
177         IPV6_MULTICAST_IF IPV6_MULTICAST_LOOP IPV6_UNICAST_HOPS IPV6_V6ONLY
178
179         MSG_BCAST MSG_BTAG MSG_CTLFLAGS MSG_CTLIGNORE MSG_DONTWAIT MSG_EOF
180         MSG_EOR MSG_ERRQUEUE MSG_ETAG MSG_FIN MSG_MAXIOVLEN MSG_MCAST
181         MSG_NOSIGNAL MSG_RST MSG_SYN MSG_TRUNC MSG_URG MSG_WAITALL MSG_WIRE
182
183         NI_DGRAM NI_IDN NI_IDN_ALLOW_UNASSIGNED NI_IDN_USE_STD3_ASCII_RULES
184         NI_NAMEREQD NI_NOFQDN NI_NUMERICHOST NI_NUMERICSERV
185
186         PF_802 PF_AAL PF_APPLETALK PF_CCITT PF_CHAOS PF_CTF PF_DATAKIT
187         PF_DECnet PF_DLI PF_ECMA PF_GOSIP PF_HYLINK PF_IMPLINK PF_INET PF_INET6
188         PF_ISO PF_KEY PF_LAST PF_LAT PF_LINK PF_MAX PF_NBS PF_NIT PF_NS PF_OSI
189         PF_OSINET PF_PUP PF_ROUTE PF_SNA PF_UNIX PF_UNSPEC PF_USER PF_WAN
190         PF_X25
191
192         SCM_CONNECT SCM_CREDENTIALS SCM_CREDS SCM_TIMESTAMP
193
194         SOCK_DGRAM SOCK_RAW SOCK_RDM SOCK_SEQPACKET SOCK_STREAM
195         SOCK_NONBLOCK SOCK_CLOEXEC
196
197         SOL_SOCKET 
198
199         SOMAXCONN
200
201         SO_ACCEPTCONN SO_ATTACH_FILTER SO_BACKLOG SO_BROADCAST SO_CHAMELEON
202         SO_DEBUG SO_DETACH_FILTER SO_DGRAM_ERRIND SO_DOMAIN SO_DONTLINGER
203         SO_DONTROUTE SO_ERROR SO_FAMILY SO_KEEPALIVE SO_LINGER SO_OOBINLINE
204         SO_PASSCRED SO_PASSIFNAME SO_PEERCRED SO_PROTOCOL SO_PROTOTYPE
205         SO_RCVBUF SO_RCVLOWAT SO_RCVTIMEO SO_REUSEADDR SO_REUSEPORT
206         SO_SECURITY_AUTHENTICATION SO_SECURITY_ENCRYPTION_NETWORK
207         SO_SECURITY_ENCRYPTION_TRANSPORT SO_SNDBUF SO_SNDLOWAT SO_SNDTIMEO
208         SO_STATE SO_TYPE SO_USELOOPBACK SO_XOPEN SO_XSE
209
210         TCP_CONGESTION TCP_CONNECTIONTIMEOUT TCP_CORK TCP_DEFER_ACCEPT TCP_INFO
211         TCP_INIT_CWND TCP_KEEPALIVE TCP_KEEPCNT TCP_KEEPIDLE TCP_KEEPINTVL
212         TCP_LINGER2 TCP_MAXRT TCP_MAXSEG TCP_MD5SIG TCP_NODELAY TCP_NOOPT
213         TCP_NOPUSH TCP_QUICKACK TCP_SACK_ENABLE TCP_STDURG TCP_SYNCNT
214         TCP_WINDOW_CLAMP
215
216         UIO_MAXIOV
217     ),
218     {name=>"IPPROTO_IP",   type=>"IV", default=>["IV",   0]},
219     {name=>"IPPROTO_IPV6", type=>"IV", default=>["IV",  41]},
220     {name=>"IPPROTO_RAW",  type=>"IV", default=>["IV", 255]},
221     {name=>"IPPROTO_ICMP", type=>"IV", default=>["IV",  1]},
222     {name=>"IPPROTO_TCP",  type=>"IV", default=>["IV",  6]},
223     {name=>"IPPROTO_UDP",  type=>"IV", default=>["IV", 17]},
224     {name=>"SHUT_RD",   type=>"IV", default=>["IV", "0"]},
225     {name=>"SHUT_WR",   type=>"IV", default=>["IV", "1"]},
226     {name=>"SHUT_RDWR", type=>"IV", default=>["IV", "2"]},
227 );
228
229 push @names, {
230     name  => $_,
231     type  => "IV",
232     macro => [ "#if defined($_) || defined(HAS_$_) /* might be an enum */\n",
233                "#endif\n" ]
234 } foreach qw (MSG_CTRUNC MSG_DONTROUTE MSG_OOB MSG_PEEK MSG_PROXY SCM_RIGHTS);
235
236 push @names, {
237     name  => $_,
238     type  => "SV",
239     pre   => "struct in_addr ip_address; ip_address.s_addr = htonl($_);",
240     value => "newSVpvn_flags((char *)&ip_address,sizeof(ip_address), SVs_TEMP)",
241 } foreach qw(INADDR_ANY INADDR_LOOPBACK INADDR_NONE INADDR_BROADCAST);
242
243 push @names, {
244     name  => $_,
245     type  => "SV",
246     macro => [ "#ifdef ${_}_INIT\n",
247                "#endif\n" ],
248     pre   => "struct in6_addr ip6_address = ${_}_INIT;",
249     value => "newSVpvn_flags((char *)&ip6_address,sizeof(ip6_address), SVs_TEMP)",
250 } foreach qw(IN6ADDR_ANY IN6ADDR_LOOPBACK);
251
252 # Work around an old Perl core bug that affects ExtUtils::Constants on
253 # pre-5.8.2 Perls.  EU:C should be amended to work around this itself.
254 if("$]" < 5.008002) {
255     require ExtUtils::Constant::ProxySubs;
256     no warnings "once";
257     $ExtUtils::Constant::ProxySubs::type_to_C_value{$_} = sub { () }
258         foreach qw(YES NO UNDEF), "";
259 }
260
261 WriteConstants(
262     PROXYSUBS => {autoload => 1},
263     NAME => 'Socket',
264     NAMES => \@names,
265 );