This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
d2a4971edda438c0a6b24184a49bd39f99a7439e
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $filename
639     $hist
640     $histfile
641     $histsize
642     $IN
643     $inhibit_exit
644     @ini_INC
645     $ini_warn
646     $maxtrace
647     $od
648     $onetimedumpDepth
649     %option
650     @options
651     $osingle
652     $otrace
653     $packname
654     $pager
655     $post
656     %postponed
657     $prc
658     $pre
659     $pretype
660     $psh
661     @RememberOnROptions
662     $remoteport
663     @res
664     $rl
665     @saved
666     $signalLevel
667     $start
668     $sub
669     %sub
670     $subname
671     $term
672     $usercontext
673     $warnLevel
674     $window
675 );
676
677 our ($trace, $single, $signal, $ImmediateStop, $evalarg, $onetimeDump,
678     $OUT, $frame, $line,
679 );
680
681 # Used to save @ARGV and extract any debugger-related flags.
682 use vars qw(@ARGS);
683
684 # Used to prevent multiple entries to diesignal()
685 # (if for instance diesignal() itself dies)
686 use vars qw($panic);
687
688 # Used to prevent the debugger from running nonstop
689 # after a restart
690 our ($second_time);
691
692 sub _calc_usercontext {
693     my ($package) = @_;
694
695     # Cancel strict completely for the evaluated code, so the code
696     # the user evaluates won't be affected by it. (Shlomi Fish)
697     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
698     . "package $package;";    # this won't let them modify, alas
699 }
700
701 sub eval {
702
703     # 'my' would make it visible from user code
704     #    but so does local! --tchrist
705     # Remember: this localizes @DB::res, not @main::res.
706     local @res;
707     {
708
709         # Try to keep the user code from messing  with us. Save these so that
710         # even if the eval'ed code changes them, we can put them back again.
711         # Needed because the user could refer directly to the debugger's
712         # package globals (and any 'my' variables in this containing scope)
713         # inside the eval(), and we want to try to stay safe.
714         local $otrace  = $trace;
715         local $osingle = $single;
716         local $od      = $^D;
717
718         # Untaint the incoming eval() argument.
719         { ($evalarg) = $evalarg =~ /(.*)/s; }
720
721         # $usercontext built in DB::DB near the comment
722         # "set up the context for DB::eval ..."
723         # Evaluate and save any results.
724         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
725
726         # Restore those old values.
727         $trace  = $otrace;
728         $single = $osingle;
729         $^D     = $od;
730     }
731
732     # Save the current value of $@, and preserve it in the debugger's copy
733     # of the saved precious globals.
734     my $at = $@;
735
736     # Since we're only saving $@, we only have to localize the array element
737     # that it will be stored in.
738     local $saved[0];    # Preserve the old value of $@
739     eval { DB::save() };
740
741     # Now see whether we need to report an error back to the user.
742     if ($at) {
743         local $\ = '';
744         print $OUT $at;
745     }
746
747     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
748     # are package globals.
749     elsif ($onetimeDump) {
750         if ( $onetimeDump eq 'dump' ) {
751             local $option{dumpDepth} = $onetimedumpDepth
752               if defined $onetimedumpDepth;
753             dumpit( $OUT, \@res );
754         }
755         elsif ( $onetimeDump eq 'methods' ) {
756             methods( $res[0] );
757         }
758     } ## end elsif ($onetimeDump)
759     @res;
760 } ## end sub eval
761
762 ############################################## End lexical danger zone
763
764 # After this point it is safe to introduce lexicals.
765 # The code being debugged will be executing in its own context, and
766 # can't see the inside of the debugger.
767 #
768 # However, one should not overdo it: leave as much control from outside as
769 # possible. If you make something a lexical, it's not going to be addressable
770 # from outside the debugger even if you know its name.
771
772 # This file is automatically included if you do perl -d.
773 # It's probably not useful to include this yourself.
774 #
775 # Before venturing further into these twisty passages, it is
776 # wise to read the perldebguts man page or risk the ire of dragons.
777 #
778 # (It should be noted that perldebguts will tell you a lot about
779 # the underlying mechanics of how the debugger interfaces into the
780 # Perl interpreter, but not a lot about the debugger itself. The new
781 # comments in this code try to address this problem.)
782
783 # Note that no subroutine call is possible until &DB::sub is defined
784 # (for subroutines defined outside of the package DB). In fact the same is
785 # true if $deep is not defined.
786
787 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
788
789 # modified Perl debugger, to be run from Emacs in perldb-mode
790 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
791 # Johan Vromans -- upgrade to 4.0 pl 10
792 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
793 ########################################################################
794
795 =head1 DEBUGGER INITIALIZATION
796
797 The debugger starts up in phases.
798
799 =head2 BASIC SETUP
800
801 First, it initializes the environment it wants to run in: turning off
802 warnings during its own compilation, defining variables which it will need
803 to avoid warnings later, setting itself up to not exit when the program
804 terminates, and defaulting to printing return values for the C<r> command.
805
806 =cut
807
808 # Needed for the statement after exec():
809 #
810 # This BEGIN block is simply used to switch off warnings during debugger
811 # compilation. Probably it would be better practice to fix the warnings,
812 # but this is how it's done at the moment.
813
814 BEGIN {
815     $ini_warn = $^W;
816     $^W       = 0;
817 }    # Switch compilation warnings off until another BEGIN.
818
819 local ($^W) = 0;    # Switch run-time warnings off during init.
820
821 =head2 THREADS SUPPORT
822
823 If we are running under a threaded Perl, we require threads and threads::shared
824 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
825 threaded debugger control.  C<-dt> can also be used to set this.
826
827 Each new thread will be announced and the debugger prompt will always inform
828 you of each new thread created.  It will also indicate the thread id in which
829 we are currently running within the prompt like this:
830
831     [tid] DB<$i>
832
833 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
834 command prompt.  The prompt will show: C<[0]> when running under threads, but
835 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
836
837 While running under threads, when you set or delete a breakpoint (etc.), this
838 will apply to all threads, not just the currently running one.  When you are
839 in a currently executing thread, you will stay there until it completes.  With
840 the current implementation it is not currently possible to hop from one thread
841 to another.
842
843 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
844
845 Note that threading support was built into the debugger as of Perl version
846 C<5.8.6> and debugger version C<1.2.8>.
847
848 =cut
849
850 BEGIN {
851     # ensure we can share our non-threaded variables or no-op
852     if ($ENV{PERL5DB_THREADED}) {
853         require threads;
854         require threads::shared;
855         import threads::shared qw(share);
856         $DBGR;
857         share(\$DBGR);
858         lock($DBGR);
859         print "Threads support enabled\n";
860     } else {
861         *lock  = sub(*) {};
862         *share = sub(*) {};
863     }
864 }
865
866 # These variables control the execution of 'dumpvar.pl'.
867 {
868     package dumpvar;
869     use vars qw(
870     $hashDepth
871     $arrayDepth
872     $dumpDBFiles
873     $dumpPackages
874     $quoteHighBit
875     $printUndef
876     $globPrint
877     $usageOnly
878     );
879 }
880
881 # used to control die() reporting in diesignal()
882 {
883     package Carp;
884     use vars qw($CarpLevel);
885 }
886
887 # without threads, $filename is not defined until DB::DB is called
888 foreach my $k (keys (%INC)) {
889     share(\$main::{'_<'.$filename}) if defined $filename;
890 };
891
892 # Command-line + PERLLIB:
893 # Save the contents of @INC before they are modified elsewhere.
894 @ini_INC = @INC;
895
896 # This was an attempt to clear out the previous values of various
897 # trapped errors. Apparently it didn't help. XXX More info needed!
898 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
899
900 # We set these variables to safe values. We don't want to blindly turn
901 # off warnings, because other packages may still want them.
902 $trace = $signal = $single = 0;    # Uninitialized warning suppression
903                                    # (local $^W cannot help - other packages!).
904
905 # Default to not exiting when program finishes; print the return
906 # value when the 'r' command is used to return from a subroutine.
907 $inhibit_exit = $option{PrintRet} = 1;
908
909 use vars qw($trace_to_depth);
910
911 # Default to 1E9 so it won't be limited to a certain recursion depth.
912 $trace_to_depth = 1E9;
913
914 =head1 OPTION PROCESSING
915
916 The debugger's options are actually spread out over the debugger itself and
917 C<dumpvar.pl>; some of these are variables to be set, while others are
918 subs to be called with a value. To try to make this a little easier to
919 manage, the debugger uses a few data structures to define what options
920 are legal and how they are to be processed.
921
922 First, the C<@options> array defines the I<names> of all the options that
923 are to be accepted.
924
925 =cut
926
927 @options = qw(
928   CommandSet   HistFile      HistSize
929   hashDepth    arrayDepth    dumpDepth
930   DumpDBFiles  DumpPackages  DumpReused
931   compactDump  veryCompact   quote
932   HighBit      undefPrint    globPrint
933   PrintRet     UsageOnly     frame
934   AutoTrace    TTY           noTTY
935   ReadLine     NonStop       LineInfo
936   maxTraceLen  recallCommand ShellBang
937   pager        tkRunning     ornaments
938   signalLevel  warnLevel     dieLevel
939   inhibit_exit ImmediateStop bareStringify
940   CreateTTY    RemotePort    windowSize
941   DollarCaretP
942 );
943
944 @RememberOnROptions = qw(DollarCaretP);
945
946 =pod
947
948 Second, C<optionVars> lists the variables that each option uses to save its
949 state.
950
951 =cut
952
953 use vars qw(%optionVars);
954
955 %optionVars = (
956     hashDepth     => \$dumpvar::hashDepth,
957     arrayDepth    => \$dumpvar::arrayDepth,
958     CommandSet    => \$CommandSet,
959     DumpDBFiles   => \$dumpvar::dumpDBFiles,
960     DumpPackages  => \$dumpvar::dumpPackages,
961     DumpReused    => \$dumpvar::dumpReused,
962     HighBit       => \$dumpvar::quoteHighBit,
963     undefPrint    => \$dumpvar::printUndef,
964     globPrint     => \$dumpvar::globPrint,
965     UsageOnly     => \$dumpvar::usageOnly,
966     CreateTTY     => \$CreateTTY,
967     bareStringify => \$dumpvar::bareStringify,
968     frame         => \$frame,
969     AutoTrace     => \$trace,
970     inhibit_exit  => \$inhibit_exit,
971     maxTraceLen   => \$maxtrace,
972     ImmediateStop => \$ImmediateStop,
973     RemotePort    => \$remoteport,
974     windowSize    => \$window,
975     HistFile      => \$histfile,
976     HistSize      => \$histsize,
977 );
978
979 =pod
980
981 Third, C<%optionAction> defines the subroutine to be called to process each
982 option.
983
984 =cut
985
986 use vars qw(%optionAction);
987
988 %optionAction = (
989     compactDump   => \&dumpvar::compactDump,
990     veryCompact   => \&dumpvar::veryCompact,
991     quote         => \&dumpvar::quote,
992     TTY           => \&TTY,
993     noTTY         => \&noTTY,
994     ReadLine      => \&ReadLine,
995     NonStop       => \&NonStop,
996     LineInfo      => \&LineInfo,
997     recallCommand => \&recallCommand,
998     ShellBang     => \&shellBang,
999     pager         => \&pager,
1000     signalLevel   => \&signalLevel,
1001     warnLevel     => \&warnLevel,
1002     dieLevel      => \&dieLevel,
1003     tkRunning     => \&tkRunning,
1004     ornaments     => \&ornaments,
1005     RemotePort    => \&RemotePort,
1006     DollarCaretP  => \&DollarCaretP,
1007 );
1008
1009 =pod
1010
1011 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1012 option is used.
1013
1014 =cut
1015
1016 # Note that this list is not complete: several options not listed here
1017 # actually require that dumpvar.pl be loaded for them to work, but are
1018 # not in the table. A subsequent patch will correct this problem; for
1019 # the moment, we're just recommenting, and we are NOT going to change
1020 # function.
1021 use vars qw(%optionRequire);
1022
1023 %optionRequire = (
1024     compactDump => 'dumpvar.pl',
1025     veryCompact => 'dumpvar.pl',
1026     quote       => 'dumpvar.pl',
1027 );
1028
1029 =pod
1030
1031 There are a number of initialization-related variables which can be set
1032 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1033 variable. These are:
1034
1035 =over 4
1036
1037 =item C<$rl> - readline control XXX needs more explanation
1038
1039 =item C<$warnLevel> - whether or not debugger takes over warning handling
1040
1041 =item C<$dieLevel> - whether or not debugger takes over die handling
1042
1043 =item C<$signalLevel> - whether or not debugger takes over signal handling
1044
1045 =item C<$pre> - preprompt actions (array reference)
1046
1047 =item C<$post> - postprompt actions (array reference)
1048
1049 =item C<$pretype>
1050
1051 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1052
1053 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1054
1055 =back
1056
1057 =cut
1058
1059 # These guys may be defined in $ENV{PERL5DB} :
1060 $rl          = 1     unless defined $rl;
1061 $warnLevel   = 1     unless defined $warnLevel;
1062 $dieLevel    = 1     unless defined $dieLevel;
1063 $signalLevel = 1     unless defined $signalLevel;
1064 $pre         = []    unless defined $pre;
1065 $post        = []    unless defined $post;
1066 $pretype     = []    unless defined $pretype;
1067 $CreateTTY   = 3     unless defined $CreateTTY;
1068 $CommandSet  = '580' unless defined $CommandSet;
1069
1070 share($rl);
1071 share($warnLevel);
1072 share($dieLevel);
1073 share($signalLevel);
1074 share($pre);
1075 share($post);
1076 share($pretype);
1077 share($rl);
1078 share($CreateTTY);
1079 share($CommandSet);
1080
1081 =pod
1082
1083 The default C<die>, C<warn>, and C<signal> handlers are set up.
1084
1085 =cut
1086
1087 warnLevel($warnLevel);
1088 dieLevel($dieLevel);
1089 signalLevel($signalLevel);
1090
1091 =pod
1092
1093 The pager to be used is needed next. We try to get it from the
1094 environment first.  If it's not defined there, we try to find it in
1095 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1096 then call the C<pager()> function to save the pager name.
1097
1098 =cut
1099
1100 # This routine makes sure $pager is set up so that '|' can use it.
1101 pager(
1102
1103     # If PAGER is defined in the environment, use it.
1104     defined $ENV{PAGER}
1105     ? $ENV{PAGER}
1106
1107       # If not, see if Config.pm defines it.
1108     : eval { require Config }
1109       && defined $Config::Config{pager}
1110     ? $Config::Config{pager}
1111
1112       # If not, fall back to 'more'.
1113     : 'more'
1114   )
1115   unless defined $pager;
1116
1117 =pod
1118
1119 We set up the command to be used to access the man pages, the command
1120 recall character (C<!> unless otherwise defined) and the shell escape
1121 character (C<!> unless otherwise defined). Yes, these do conflict, and
1122 neither works in the debugger at the moment.
1123
1124 =cut
1125
1126 setman();
1127
1128 # Set up defaults for command recall and shell escape (note:
1129 # these currently don't work in linemode debugging).
1130 recallCommand("!") unless defined $prc;
1131 shellBang("!")     unless defined $psh;
1132
1133 =pod
1134
1135 We then set up the gigantic string containing the debugger help.
1136 We also set the limit on the number of arguments we'll display during a
1137 trace.
1138
1139 =cut
1140
1141 sethelp();
1142
1143 # If we didn't get a default for the length of eval/stack trace args,
1144 # set it here.
1145 $maxtrace = 400 unless defined $maxtrace;
1146
1147 =head2 SETTING UP THE DEBUGGER GREETING
1148
1149 The debugger I<greeting> helps to inform the user how many debuggers are
1150 running, and whether the current debugger is the primary or a child.
1151
1152 If we are the primary, we just hang onto our pid so we'll have it when
1153 or if we start a child debugger. If we are a child, we'll set things up
1154 so we'll have a unique greeting and so the parent will give us our own
1155 TTY later.
1156
1157 We save the current contents of the C<PERLDB_PIDS> environment variable
1158 because we mess around with it. We'll also need to hang onto it because
1159 we'll need it if we restart.
1160
1161 Child debuggers make a label out of the current PID structure recorded in
1162 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1163 yet so the parent will give them one later via C<resetterm()>.
1164
1165 =cut
1166
1167 # Save the current contents of the environment; we're about to
1168 # much with it. We'll need this if we have to restart.
1169 use vars qw($ini_pids);
1170 $ini_pids = $ENV{PERLDB_PIDS};
1171
1172 use vars qw ($pids $term_pid);
1173
1174 if ( defined $ENV{PERLDB_PIDS} ) {
1175
1176     # We're a child. Make us a label out of the current PID structure
1177     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1178     # a term yet so the parent will give us one later via resetterm().
1179
1180     my $env_pids = $ENV{PERLDB_PIDS};
1181     $pids = "[$env_pids]";
1182
1183     # Unless we are on OpenVMS, all programs under the DCL shell run under
1184     # the same PID.
1185
1186     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1187         $term_pid         = $$;
1188     }
1189     else {
1190         $ENV{PERLDB_PIDS} .= "->$$";
1191         $term_pid = -1;
1192     }
1193
1194 } ## end if (defined $ENV{PERLDB_PIDS...
1195 else {
1196
1197     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1198     # child debugger, and mark us as the parent, so we'll know to set up
1199     # more TTY's is we have to.
1200     $ENV{PERLDB_PIDS} = "$$";
1201     $pids             = "[pid=$$]";
1202     $term_pid         = $$;
1203 }
1204
1205 use vars qw($pidprompt);
1206 $pidprompt = '';
1207
1208 # Sets up $emacs as a synonym for $slave_editor.
1209 use vars qw($slave_editor);
1210 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1211
1212 =head2 READING THE RC FILE
1213
1214 The debugger will read a file of initialization options if supplied. If
1215 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1216
1217 =cut
1218
1219 # As noted, this test really doesn't check accurately that the debugger
1220 # is running at a terminal or not.
1221
1222 use vars qw($rcfile);
1223 {
1224     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1225     # this is the wrong metric!
1226     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1227 }
1228
1229 =pod
1230
1231 The debugger does a safety test of the file to be read. It must be owned
1232 either by the current user or root, and must only be writable by the owner.
1233
1234 =cut
1235
1236 # This wraps a safety test around "do" to read and evaluate the init file.
1237 #
1238 # This isn't really safe, because there's a race
1239 # between checking and opening.  The solution is to
1240 # open and fstat the handle, but then you have to read and
1241 # eval the contents.  But then the silly thing gets
1242 # your lexical scope, which is unfortunate at best.
1243 sub safe_do {
1244     my $file = shift;
1245
1246     # Just exactly what part of the word "CORE::" don't you understand?
1247     local $SIG{__WARN__};
1248     local $SIG{__DIE__};
1249
1250     unless ( is_safe_file($file) ) {
1251         CORE::warn <<EO_GRIPE;
1252 perldb: Must not source insecure rcfile $file.
1253         You or the superuser must be the owner, and it must not
1254         be writable by anyone but its owner.
1255 EO_GRIPE
1256         return;
1257     } ## end unless (is_safe_file($file...
1258
1259     do $file;
1260     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1261 } ## end sub safe_do
1262
1263 # This is the safety test itself.
1264 #
1265 # Verifies that owner is either real user or superuser and that no
1266 # one but owner may write to it.  This function is of limited use
1267 # when called on a path instead of upon a handle, because there are
1268 # no guarantees that filename (by dirent) whose file (by ino) is
1269 # eventually accessed is the same as the one tested.
1270 # Assumes that the file's existence is not in doubt.
1271 sub is_safe_file {
1272     my $path = shift;
1273     stat($path) || return;    # mysteriously vaporized
1274     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1275
1276     return 0 if $uid != 0 && $uid != $<;
1277     return 0 if $mode & 022;
1278     return 1;
1279 } ## end sub is_safe_file
1280
1281 # If the rcfile (whichever one we decided was the right one to read)
1282 # exists, we safely do it.
1283 if ( -f $rcfile ) {
1284     safe_do("./$rcfile");
1285 }
1286
1287 # If there isn't one here, try the user's home directory.
1288 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1289     safe_do("$ENV{HOME}/$rcfile");
1290 }
1291
1292 # Else try the login directory.
1293 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1294     safe_do("$ENV{LOGDIR}/$rcfile");
1295 }
1296
1297 # If the PERLDB_OPTS variable has options in it, parse those out next.
1298 if ( defined $ENV{PERLDB_OPTS} ) {
1299     parse_options( $ENV{PERLDB_OPTS} );
1300 }
1301
1302 =pod
1303
1304 The last thing we do during initialization is determine which subroutine is
1305 to be used to obtain a new terminal when a new debugger is started. Right now,
1306 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1307 (darwin).
1308
1309 =cut
1310
1311 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1312 # Works if you're running an xterm or xterm-like window, or you're on
1313 # OS/2, or on Mac OS X. This may need some expansion.
1314
1315 if (not defined &get_fork_TTY)       # only if no routine exists
1316 {
1317     if ( defined $remoteport ) {
1318                                                  # Expect an inetd-like server
1319         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1320     }
1321     elsif (defined $ENV{TERM}                    # If we know what kind
1322                                                  # of terminal this is,
1323         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1324         and defined $ENV{DISPLAY}                # and what display it's on,
1325       )
1326     {
1327         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1328     }
1329     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1330         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1331     }
1332     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1333             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1334             and $ENV{TERM_PROGRAM}
1335                 eq 'Apple_Terminal'              # Terminal.app
1336             )
1337     {
1338         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1339     }
1340 } ## end if (not defined &get_fork_TTY...
1341
1342 # untaint $^O, which may have been tainted by the last statement.
1343 # see bug [perl #24674]
1344 $^O =~ m/^(.*)\z/;
1345 $^O = $1;
1346
1347 # Here begin the unreadable code.  It needs fixing.
1348
1349 =head2 RESTART PROCESSING
1350
1351 This section handles the restart command. When the C<R> command is invoked, it
1352 tries to capture all of the state it can into environment variables, and
1353 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1354 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1355 the R command stuffed into the environment variables.
1356
1357   PERLDB_RESTART   - flag only, contains no restart data itself.
1358   PERLDB_HIST      - command history, if it's available
1359   PERLDB_ON_LOAD   - breakpoints set by the rc file
1360   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1361   PERLDB_VISITED   - files that had breakpoints
1362   PERLDB_FILE_...  - breakpoints for a file
1363   PERLDB_OPT       - active options
1364   PERLDB_INC       - the original @INC
1365   PERLDB_PRETYPE   - preprompt debugger actions
1366   PERLDB_PRE       - preprompt Perl code
1367   PERLDB_POST      - post-prompt Perl code
1368   PERLDB_TYPEAHEAD - typeahead captured by readline()
1369
1370 We chug through all these variables and plug the values saved in them
1371 back into the appropriate spots in the debugger.
1372
1373 =cut
1374
1375 use vars qw(@hist @truehist %postponed_file @typeahead);
1376
1377 sub _restore_shared_globals_after_restart
1378 {
1379     @hist          = get_list('PERLDB_HIST');
1380     %break_on_load = get_list("PERLDB_ON_LOAD");
1381     %postponed     = get_list("PERLDB_POSTPONE");
1382
1383     share(@hist);
1384     share(@truehist);
1385     share(%break_on_load);
1386     share(%postponed);
1387 }
1388
1389 sub _restore_breakpoints_and_actions {
1390
1391     my @had_breakpoints = get_list("PERLDB_VISITED");
1392
1393     for my $file_idx ( 0 .. $#had_breakpoints ) {
1394         my $filename = $had_breakpoints[$file_idx];
1395         my %pf = get_list("PERLDB_FILE_$file_idx");
1396         $postponed_file{ $filename } = \%pf if %pf;
1397         my @lines = sort {$a <=> $b} keys(%pf);
1398         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1399         for my $line_idx (0 .. $#lines) {
1400             _set_breakpoint_enabled_status(
1401                 $filename,
1402                 $lines[$line_idx],
1403                 ($enabled_statuses[$line_idx] ? 1 : ''),
1404             );
1405         }
1406     }
1407
1408     return;
1409 }
1410
1411 sub _restore_options_after_restart
1412 {
1413     my %options_map = get_list("PERLDB_OPT");
1414
1415     while ( my ( $opt, $val ) = each %options_map ) {
1416         $val =~ s/[\\\']/\\$1/g;
1417         parse_options("$opt'$val'");
1418     }
1419
1420     return;
1421 }
1422
1423 sub _restore_globals_after_restart
1424 {
1425     # restore original @INC
1426     @INC     = get_list("PERLDB_INC");
1427     @ini_INC = @INC;
1428
1429     # return pre/postprompt actions and typeahead buffer
1430     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1431     $pre       = [ get_list("PERLDB_PRE") ];
1432     $post      = [ get_list("PERLDB_POST") ];
1433     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1434
1435     return;
1436 }
1437
1438
1439 if ( exists $ENV{PERLDB_RESTART} ) {
1440
1441     # We're restarting, so we don't need the flag that says to restart anymore.
1442     delete $ENV{PERLDB_RESTART};
1443
1444     # $restart = 1;
1445     _restore_shared_globals_after_restart();
1446
1447     _restore_breakpoints_and_actions();
1448
1449     # restore options
1450     _restore_options_after_restart();
1451
1452     _restore_globals_after_restart();
1453 } ## end if (exists $ENV{PERLDB_RESTART...
1454
1455 =head2 SETTING UP THE TERMINAL
1456
1457 Now, we'll decide how the debugger is going to interact with the user.
1458 If there's no TTY, we set the debugger to run non-stop; there's not going
1459 to be anyone there to enter commands.
1460
1461 =cut
1462
1463 use vars qw($notty $console $tty $LINEINFO);
1464 use vars qw($lineinfo $doccmd);
1465
1466 our ($runnonstop);
1467
1468 if ($notty) {
1469     $runnonstop = 1;
1470     share($runnonstop);
1471 }
1472
1473 =pod
1474
1475 If there is a TTY, we have to determine who it belongs to before we can
1476 proceed. If this is a slave editor or graphical debugger (denoted by
1477 the first command-line switch being '-emacs'), we shift this off and
1478 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1479
1480 =cut
1481
1482 else {
1483
1484     # Is Perl being run from a slave editor or graphical debugger?
1485     # If so, don't use readline, and set $slave_editor = 1.
1486     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1487         $rl = 0;
1488         shift(@main::ARGV);
1489     }
1490
1491     #require Term::ReadLine;
1492
1493 =pod
1494
1495 We then determine what the console should be on various systems:
1496
1497 =over 4
1498
1499 =item * Cygwin - We use C<stdin> instead of a separate device.
1500
1501 =cut
1502
1503     if ( $^O eq 'cygwin' ) {
1504
1505         # /dev/tty is binary. use stdin for textmode
1506         undef $console;
1507     }
1508
1509 =item * Unix - use C</dev/tty>.
1510
1511 =cut
1512
1513     elsif ( -e "/dev/tty" ) {
1514         $console = "/dev/tty";
1515     }
1516
1517 =item * Windows or MSDOS - use C<con>.
1518
1519 =cut
1520
1521     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1522         $console = "con";
1523     }
1524
1525 =item * VMS - use C<sys$command>.
1526
1527 =cut
1528
1529     else {
1530
1531         # everything else is ...
1532         $console = "sys\$command";
1533     }
1534
1535 =pod
1536
1537 =back
1538
1539 Several other systems don't use a specific console. We C<undef $console>
1540 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1541 with a slave editor, Epoc).
1542
1543 =cut
1544
1545     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1546
1547         # /dev/tty is binary. use stdin for textmode
1548         $console = undef;
1549     }
1550
1551     if ( $^O eq 'NetWare' ) {
1552
1553         # /dev/tty is binary. use stdin for textmode
1554         $console = undef;
1555     }
1556
1557     # In OS/2, we need to use STDIN to get textmode too, even though
1558     # it pretty much looks like Unix otherwise.
1559     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1560     {    # In OS/2
1561         $console = undef;
1562     }
1563
1564     # EPOC also falls into the 'got to use STDIN' camp.
1565     if ( $^O eq 'epoc' ) {
1566         $console = undef;
1567     }
1568
1569 =pod
1570
1571 If there is a TTY hanging around from a parent, we use that as the console.
1572
1573 =cut
1574
1575     $console = $tty if defined $tty;
1576
1577 =head2 SOCKET HANDLING
1578
1579 The debugger is capable of opening a socket and carrying out a debugging
1580 session over the socket.
1581
1582 If C<RemotePort> was defined in the options, the debugger assumes that it
1583 should try to start a debugging session on that port. It builds the socket
1584 and then tries to connect the input and output filehandles to it.
1585
1586 =cut
1587
1588     # Handle socket stuff.
1589
1590     if ( defined $remoteport ) {
1591
1592         # If RemotePort was defined in the options, connect input and output
1593         # to the socket.
1594         $IN = $OUT = connect_remoteport();
1595     } ## end if (defined $remoteport)
1596
1597 =pod
1598
1599 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1600 this is probably a situation where multiple debuggers are running (for example,
1601 a backticked command that starts up another debugger). We create a new IN and
1602 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1603 and if we can.
1604
1605 =cut
1606
1607     # Non-socket.
1608     else {
1609
1610         # Two debuggers running (probably a system or a backtick that invokes
1611         # the debugger itself under the running one). create a new IN and OUT
1612         # filehandle, and do the necessary mojo to create a new tty if we
1613         # know how, and we can.
1614         create_IN_OUT(4) if $CreateTTY & 4;
1615         if ($console) {
1616
1617             # If we have a console, check to see if there are separate ins and
1618             # outs to open. (They are assumed identical if not.)
1619
1620             my ( $i, $o ) = split /,/, $console;
1621             $o = $i unless defined $o;
1622
1623             # read/write on in, or just read, or read on STDIN.
1624             open( IN,      "+<$i" )
1625               || open( IN, "<$i" )
1626               || open( IN, "<&STDIN" );
1627
1628             # read/write/create/clobber out, or write/create/clobber out,
1629             # or merge with STDERR, or merge with STDOUT.
1630                  open( OUT, "+>$o" )
1631               || open( OUT, ">$o" )
1632               || open( OUT, ">&STDERR" )
1633               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1634
1635         } ## end if ($console)
1636         elsif ( not defined $console ) {
1637
1638             # No console. Open STDIN.
1639             open( IN, "<&STDIN" );
1640
1641             # merge with STDERR, or with STDOUT.
1642             open( OUT,      ">&STDERR" )
1643               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1644             $console = 'STDIN/OUT';
1645         } ## end elsif (not defined $console)
1646
1647         # Keep copies of the filehandles so that when the pager runs, it
1648         # can close standard input without clobbering ours.
1649         if ($console or (not defined($console))) {
1650             $IN = \*IN;
1651             $OUT = \*OUT;
1652         }
1653     } ## end elsif (from if(defined $remoteport))
1654
1655     # Unbuffer DB::OUT. We need to see responses right away.
1656     $OUT->autoflush(1);
1657
1658     # Line info goes to debugger output unless pointed elsewhere.
1659     # Pointing elsewhere makes it possible for slave editors to
1660     # keep track of file and position. We have both a filehandle
1661     # and a I/O description to keep track of.
1662     $LINEINFO = $OUT     unless defined $LINEINFO;
1663     $lineinfo = $console unless defined $lineinfo;
1664     # share($LINEINFO); # <- unable to share globs
1665     share($lineinfo);   #
1666
1667 =pod
1668
1669 To finish initialization, we show the debugger greeting,
1670 and then call the C<afterinit()> subroutine if there is one.
1671
1672 =cut
1673
1674     # Show the debugger greeting.
1675     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1676     unless ($runnonstop) {
1677         local $\ = '';
1678         local $, = '';
1679         if ( $term_pid eq '-1' ) {
1680             print $OUT "\nDaughter DB session started...\n";
1681         }
1682         else {
1683             print $OUT "\nLoading DB routines from $header\n";
1684             print $OUT (
1685                 "Editor support ",
1686                 $slave_editor ? "enabled" : "available", ".\n"
1687             );
1688             print $OUT
1689 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1690         } ## end else [ if ($term_pid eq '-1')
1691     } ## end unless ($runnonstop)
1692 } ## end else [ if ($notty)
1693
1694 # XXX This looks like a bug to me.
1695 # Why copy to @ARGS and then futz with @args?
1696 @ARGS = @ARGV;
1697 # for (@args) {
1698     # Make sure backslashes before single quotes are stripped out, and
1699     # keep args unless they are numeric (XXX why?)
1700     # s/\'/\\\'/g;                      # removed while not justified understandably
1701     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1702 # }
1703
1704 # If there was an afterinit() sub defined, call it. It will get
1705 # executed in our scope, so it can fiddle with debugger globals.
1706 if ( defined &afterinit ) {    # May be defined in $rcfile
1707     afterinit();
1708 }
1709
1710 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1711 use vars qw($I_m_init);
1712
1713 $I_m_init = 1;
1714
1715 ############################################################ Subroutines
1716
1717 =head1 SUBROUTINES
1718
1719 =head2 DB
1720
1721 This gigantic subroutine is the heart of the debugger. Called before every
1722 statement, its job is to determine if a breakpoint has been reached, and
1723 stop if so; read commands from the user, parse them, and execute
1724 them, and then send execution off to the next statement.
1725
1726 Note that the order in which the commands are processed is very important;
1727 some commands earlier in the loop will actually alter the C<$cmd> variable
1728 to create other commands to be executed later. This is all highly I<optimized>
1729 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1730 see what's happening in any given command.
1731
1732 =cut
1733
1734 use vars qw(
1735     $action
1736     %alias
1737     $cmd
1738     $doret
1739     $fall_off_end
1740     $file
1741     $filename_ini
1742     $finished
1743     %had_breakpoints
1744     $incr
1745     $laststep
1746     $level
1747     $max
1748     $package
1749     $rc
1750     $sh
1751     $try
1752     $end
1753 );
1754
1755 our ( $stack_depth, @stack, @to_watch, @old_watch, );
1756
1757 sub _DB__determine_if_we_should_break
1758 {
1759     # if we have something here, see if we should break.
1760     # $stop is lexical and local to this block - $action on the other hand
1761     # is global.
1762     my $stop;
1763
1764     if ( $dbline{$line}
1765         && _is_breakpoint_enabled($filename, $line)
1766         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1767     {
1768
1769         # Stop if the stop criterion says to just stop.
1770         if ( $stop eq '1' ) {
1771             $signal |= 1;
1772         }
1773
1774         # It's a conditional stop; eval it in the user's context and
1775         # see if we should stop. If so, remove the one-time sigil.
1776         elsif ($stop) {
1777             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1778             &eval;
1779             # If the breakpoint is temporary, then delete its enabled status.
1780             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1781                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1782             }
1783         }
1784     } ## end if ($dbline{$line} && ...
1785 }
1786
1787 sub _DB__is_finished {
1788     if ($finished and $level <= 1) {
1789         end_report();
1790         return 1;
1791     }
1792     else {
1793         return;
1794     }
1795 }
1796
1797 sub _DB__read_next_cmd
1798 {
1799     my ($tid) = @_;
1800
1801     # We have a terminal, or can get one ...
1802     if (!$term) {
1803         setterm();
1804     }
1805
1806     # ... and it belogs to this PID or we get one for this PID ...
1807     if ($term_pid != $$) {
1808         resetterm(1);
1809     }
1810
1811     # ... and we got a line of command input ...
1812     $cmd = DB::readline(
1813         "$pidprompt $tid DB"
1814         . ( '<' x $level )
1815         . ( $#hist + 1 )
1816         . ( '>' x $level ) . " "
1817     );
1818
1819     return defined($cmd);
1820 }
1821
1822 sub _DB__trim_command_and_return_first_component {
1823     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1824     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1825
1826     $cmd =~ m{\A(\S*)};
1827     return $1;
1828 }
1829
1830 sub DB {
1831
1832     # lock the debugger and get the thread id for the prompt
1833     lock($DBGR);
1834     my $tid;
1835     my $position;
1836     my ($prefix, $after, $infix);
1837     my $pat;
1838     my $explicit_stop;
1839
1840     if ($ENV{PERL5DB_THREADED}) {
1841         $tid = eval { "[".threads->tid."]" };
1842     }
1843
1844     my $obj = DB::Obj->new(
1845         {
1846             position => \$position,
1847             prefix => \$prefix,
1848             after => \$after,
1849             explicit_stop => \$explicit_stop,
1850             infix => \$infix,
1851         },
1852     );
1853
1854     $obj->_DB_on_init__initialize_globals(@_);
1855
1856     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1857     # The code being debugged may have altered them.
1858     &save;
1859
1860     # Since DB::DB gets called after every line, we can use caller() to
1861     # figure out where we last were executing. Sneaky, eh? This works because
1862     # caller is returning all the extra information when called from the
1863     # debugger.
1864     local ( $package, $filename, $line ) = caller;
1865     $filename_ini = $filename;
1866
1867     # set up the context for DB::eval, so it can properly execute
1868     # code on behalf of the user. We add the package in so that the
1869     # code is eval'ed in the proper package (not in the debugger!).
1870     local $usercontext = _calc_usercontext($package);
1871
1872     # Create an alias to the active file magical array to simplify
1873     # the code here.
1874     local (*dbline) = $main::{ '_<' . $filename };
1875
1876     # Last line in the program.
1877     $max = $#dbline;
1878
1879     _DB__determine_if_we_should_break(@_);
1880
1881     # Preserve the current stop-or-not, and see if any of the W
1882     # (watch expressions) has changed.
1883     my $was_signal = $signal;
1884
1885     # If we have any watch expressions ...
1886     $obj->_DB__handle_watch_expressions(@_);
1887
1888 =head2 C<watchfunction()>
1889
1890 C<watchfunction()> is a function that can be defined by the user; it is a
1891 function which will be run on each entry to C<DB::DB>; it gets the
1892 current package, filename, and line as its parameters.
1893
1894 The watchfunction can do anything it likes; it is executing in the
1895 debugger's context, so it has access to all of the debugger's internal
1896 data structures and functions.
1897
1898 C<watchfunction()> can control the debugger's actions. Any of the following
1899 will cause the debugger to return control to the user's program after
1900 C<watchfunction()> executes:
1901
1902 =over 4
1903
1904 =item *
1905
1906 Returning a false value from the C<watchfunction()> itself.
1907
1908 =item *
1909
1910 Altering C<$single> to a false value.
1911
1912 =item *
1913
1914 Altering C<$signal> to a false value.
1915
1916 =item *
1917
1918 Turning off the C<4> bit in C<$trace> (this also disables the
1919 check for C<watchfunction()>. This can be done with
1920
1921     $trace &= ~4;
1922
1923 =back
1924
1925 =cut
1926
1927     # If there's a user-defined DB::watchfunction, call it with the
1928     # current package, filename, and line. The function executes in
1929     # the DB:: package.
1930     if ( $trace & 4 ) {    # User-installed watch
1931         return
1932           if watchfunction( $package, $filename, $line )
1933           and not $single
1934           and not $was_signal
1935           and not( $trace & ~4 );
1936     } ## end if ($trace & 4)
1937
1938     # Pick up any alteration to $signal in the watchfunction, and
1939     # turn off the signal now.
1940     $was_signal = $signal;
1941     $signal     = 0;
1942
1943 =head2 GETTING READY TO EXECUTE COMMANDS
1944
1945 The debugger decides to take control if single-step mode is on, the
1946 C<t> command was entered, or the user generated a signal. If the program
1947 has fallen off the end, we set things up so that entering further commands
1948 won't cause trouble, and we say that the program is over.
1949
1950 =cut
1951
1952     # Make sure that we always print if asked for explicitly regardless
1953     # of $trace_to_depth .
1954     $explicit_stop = ($single || $was_signal);
1955
1956     # Check to see if we should grab control ($single true,
1957     # trace set appropriately, or we got a signal).
1958     if ( $explicit_stop || ( $trace & 1 ) ) {
1959         $obj->_DB__grab_control(@_);
1960     } ## end if ($single || ($trace...
1961
1962 =pod
1963
1964 If there's an action to be executed for the line we stopped at, execute it.
1965 If there are any preprompt actions, execute those as well.
1966
1967 =cut
1968
1969     # If there's an action, do it now.
1970     if ($action) {
1971         $evalarg = $action;
1972         DB::eval();
1973     }
1974
1975     # Are we nested another level (e.g., did we evaluate a function
1976     # that had a breakpoint in it at the debugger prompt)?
1977     if ( $single || $was_signal ) {
1978
1979         # Yes, go down a level.
1980         local $level = $level + 1;
1981
1982         # Do any pre-prompt actions.
1983         foreach $evalarg (@$pre) {
1984             DB::eval();
1985         }
1986
1987         # Complain about too much recursion if we passed the limit.
1988         if ($single & 4) {
1989             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
1990         }
1991
1992         # The line we're currently on. Set $incr to -1 to stay here
1993         # until we get a command that tells us to advance.
1994         $start = $line;
1995         $incr  = -1;      # for backward motion.
1996
1997         # Tack preprompt debugger actions ahead of any actual input.
1998         @typeahead = ( @$pretype, @typeahead );
1999
2000 =head2 WHERE ARE WE?
2001
2002 XXX Relocate this section?
2003
2004 The debugger normally shows the line corresponding to the current line of
2005 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2006 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2007
2008 C<$incr> controls by how many lines the I<current> line should move forward
2009 after a command is executed. If set to -1, this indicates that the I<current>
2010 line shouldn't change.
2011
2012 C<$start> is the I<current> line. It is used for things like knowing where to
2013 move forwards or backwards from when doing an C<L> or C<-> command.
2014
2015 C<$max> tells the debugger where the last line of the current file is. It's
2016 used to terminate loops most often.
2017
2018 =head2 THE COMMAND LOOP
2019
2020 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2021 in two parts:
2022
2023 =over 4
2024
2025 =item *
2026
2027 The outer part of the loop, starting at the C<CMD> label. This loop
2028 reads a command and then executes it.
2029
2030 =item *
2031
2032 The inner part of the loop, starting at the C<PIPE> label. This part
2033 is wholly contained inside the C<CMD> block and only executes a command.
2034 Used to handle commands running inside a pager.
2035
2036 =back
2037
2038 So why have two labels to restart the loop? Because sometimes, it's easier to
2039 have a command I<generate> another command and then re-execute the loop to do
2040 the new command. This is faster, but perhaps a bit more convoluted.
2041
2042 =cut
2043
2044         # The big command dispatch loop. It keeps running until the
2045         # user yields up control again.
2046         #
2047         # If we have a terminal for input, and we get something back
2048         # from readline(), keep on processing.
2049         my $piped;
2050         my $selected;
2051
2052       CMD:
2053         while (_DB__read_next_cmd($tid))
2054         {
2055
2056             share($cmd);
2057             # ... try to execute the input as debugger commands.
2058
2059             # Don't stop running.
2060             $single = 0;
2061
2062             # No signal is active.
2063             $signal = 0;
2064
2065             # Handle continued commands (ending with \):
2066             if ($cmd =~ s/\\\z/\n/) {
2067                 $cmd .= DB::readline("  cont: ");
2068                 redo CMD;
2069             }
2070
2071 =head4 The null command
2072
2073 A newline entered by itself means I<re-execute the last command>. We grab the
2074 command out of C<$laststep> (where it was recorded previously), and copy it
2075 back into C<$cmd> to be executed below. If there wasn't any previous command,
2076 we'll do nothing below (no command will match). If there was, we also save it
2077 in the command history and fall through to allow the command parsing to pick
2078 it up.
2079
2080 =cut
2081
2082             # Empty input means repeat the last command.
2083             if ($cmd eq '') {
2084                 $cmd = $laststep;
2085             }
2086             chomp($cmd);    # get rid of the annoying extra newline
2087             if (length($cmd) >= 2) {
2088                 push( @hist, $cmd );
2089             }
2090             push( @truehist, $cmd );
2091             share(@hist);
2092             share(@truehist);
2093
2094             # This is a restart point for commands that didn't arrive
2095             # via direct user input. It allows us to 'redo PIPE' to
2096             # re-execute command processing without reading a new command.
2097           PIPE: {
2098                 my $i = _DB__trim_command_and_return_first_component();
2099
2100 =head3 COMMAND ALIASES
2101
2102 The debugger can create aliases for commands (these are stored in the
2103 C<%alias> hash). Before a command is executed, the command loop looks it up
2104 in the alias hash and substitutes the contents of the alias for the command,
2105 completely replacing it.
2106
2107 =cut
2108
2109                 # See if there's an alias for the command, and set it up if so.
2110                 if ( $alias{$i} ) {
2111
2112                     # Squelch signal handling; we want to keep control here
2113                     # if something goes loco during the alias eval.
2114                     local $SIG{__DIE__};
2115                     local $SIG{__WARN__};
2116
2117                     # This is a command, so we eval it in the DEBUGGER's
2118                     # scope! Otherwise, we can't see the special debugger
2119                     # variables, or get to the debugger's subs. (Well, we
2120                     # _could_, but why make it even more complicated?)
2121                     eval "\$cmd =~ $alias{$i}";
2122                     if ($@) {
2123                         local $\ = '';
2124                         print $OUT "Couldn't evaluate '$i' alias: $@";
2125                         next CMD;
2126                     }
2127                 } ## end if ($alias{$i})
2128
2129 =head3 MAIN-LINE COMMANDS
2130
2131 All of these commands work up to and after the program being debugged has
2132 terminated.
2133
2134 =head4 C<q> - quit
2135
2136 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2137 try to execute further, cleaning any restart-related stuff out of the
2138 environment, and executing with the last value of C<$?>.
2139
2140 =cut
2141
2142                 if ($cmd eq 'q') {
2143                     $fall_off_end = 1;
2144                     clean_ENV();
2145                     exit $?;
2146                 }
2147
2148 =head4 C<t> - trace [n]
2149
2150 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2151 If level is specified, set C<$trace_to_depth>.
2152
2153 =cut
2154
2155                 $obj->_handle_t_command();
2156
2157 =head4 C<S> - list subroutines matching/not matching a pattern
2158
2159 Walks through C<%sub>, checking to see whether or not to print the name.
2160
2161 =cut
2162
2163                 if (my ($print_all_subs, $should_reverse, $Spatt)
2164                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2165                     # $Spatt is the pattern (if any) to use.
2166                     # Reverse scan?
2167                     my $Srev     = defined $should_reverse;
2168                     # No args - print all subs.
2169                     my $Snocheck = !defined $print_all_subs;
2170
2171                     # Need to make these sane here.
2172                     local $\ = '';
2173                     local $, = '';
2174
2175                     # Search through the debugger's magical hash of subs.
2176                     # If $nocheck is true, just print the sub name.
2177                     # Otherwise, check it against the pattern. We then use
2178                     # the XOR trick to reverse the condition as required.
2179                     foreach $subname ( sort( keys %sub ) ) {
2180                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2181                             print $OUT $subname, "\n";
2182                         }
2183                     }
2184                     next CMD;
2185                 }
2186
2187 =head4 C<X> - list variables in current package
2188
2189 Since the C<V> command actually processes this, just change this to the
2190 appropriate C<V> command and fall through.
2191
2192 =cut
2193
2194                 $cmd =~ s/^X\b/V $package/;
2195
2196 =head4 C<V> - list variables
2197
2198 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2199
2200 =cut
2201
2202                 # Bare V commands get the currently-being-debugged package
2203                 # added.
2204                 if ($cmd eq "V") {
2205                     $cmd = "V $package";
2206                 }
2207
2208                 # V - show variables in package.
2209                 if (my ($new_packname, $new_vars_str) =
2210                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2211
2212                     # Save the currently selected filehandle and
2213                     # force output to debugger's filehandle (dumpvar
2214                     # just does "print" for output).
2215                     my $savout = select($OUT);
2216
2217                     # Grab package name and variables to dump.
2218                     $packname = $new_packname;
2219                     my @vars     = split( ' ', $new_vars_str );
2220
2221                     # If main::dumpvar isn't here, get it.
2222                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2223                     if ( defined &main::dumpvar ) {
2224
2225                         # We got it. Turn off subroutine entry/exit messages
2226                         # for the moment, along with return values.
2227                         local $frame = 0;
2228                         local $doret = -2;
2229
2230                         # must detect sigpipe failures  - not catching
2231                         # then will cause the debugger to die.
2232                         eval {
2233                             &main::dumpvar(
2234                                 $packname,
2235                                 defined $option{dumpDepth}
2236                                 ? $option{dumpDepth}
2237                                 : -1,    # assume -1 unless specified
2238                                 @vars
2239                             );
2240                         };
2241
2242                         # The die doesn't need to include the $@, because
2243                         # it will automatically get propagated for us.
2244                         if ($@) {
2245                             die unless $@ =~ /dumpvar print failed/;
2246                         }
2247                     } ## end if (defined &main::dumpvar)
2248                     else {
2249
2250                         # Couldn't load dumpvar.
2251                         print $OUT "dumpvar.pl not available.\n";
2252                     }
2253
2254                     # Restore the output filehandle, and go round again.
2255                     select($savout);
2256                     next CMD;
2257                 }
2258
2259 =head4 C<x> - evaluate and print an expression
2260
2261 Hands the expression off to C<DB::eval>, setting it up to print the value
2262 via C<dumpvar.pl> instead of just printing it directly.
2263
2264 =cut
2265
2266                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2267                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2268
2269                     # handle special  "x 3 blah" syntax XXX propagate
2270                     # doc back to special variables.
2271                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2272                         $onetimedumpDepth = $1;
2273                     }
2274                 }
2275
2276 =head4 C<m> - print methods
2277
2278 Just uses C<DB::methods> to determine what methods are available.
2279
2280 =cut
2281
2282                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2283                     methods($1);
2284                     next CMD;
2285                 }
2286
2287                 # m expr - set up DB::eval to do the work
2288                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2289                     $onetimeDump = 'methods';   #  method output gets used there
2290                 }
2291
2292 =head4 C<f> - switch files
2293
2294 =cut
2295
2296                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2297                     $file =~ s/\s+$//;
2298
2299                     # help for no arguments (old-style was return from sub).
2300                     if ( !$file ) {
2301                         print $OUT
2302                           "The old f command is now the r command.\n";    # hint
2303                         print $OUT "The new f command switches filenames.\n";
2304                         next CMD;
2305                     } ## end if (!$file)
2306
2307                     # if not in magic file list, try a close match.
2308                     if ( !defined $main::{ '_<' . $file } ) {
2309                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2310                             {
2311                                 $try = substr( $try, 2 );
2312                                 print $OUT "Choosing $try matching '$file':\n";
2313                                 $file = $try;
2314                             }
2315                         } ## end if (($try) = grep(m#^_<.*$file#...
2316                     } ## end if (!defined $main::{ ...
2317
2318                     # If not successfully switched now, we failed.
2319                     if ( !defined $main::{ '_<' . $file } ) {
2320                         print $OUT "No file matching '$file' is loaded.\n";
2321                         next CMD;
2322                     }
2323
2324                     # We switched, so switch the debugger internals around.
2325                     elsif ( $file ne $filename ) {
2326                         *dbline   = $main::{ '_<' . $file };
2327                         $max      = $#dbline;
2328                         $filename = $file;
2329                         $start    = 1;
2330                         $cmd      = "l";
2331                     } ## end elsif ($file ne $filename)
2332
2333                     # We didn't switch; say we didn't.
2334                     else {
2335                         print $OUT "Already in $file.\n";
2336                         next CMD;
2337                     }
2338                 }
2339
2340 =head4 C<.> - return to last-executed line.
2341
2342 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2343 and then we look up the line in the magical C<%dbline> hash.
2344
2345 =cut
2346
2347                 # . command.
2348                 if ($cmd eq '.') {
2349                     $incr = -1;    # stay at current line
2350
2351                     # Reset everything to the old location.
2352                     $start    = $line;
2353                     $filename = $filename_ini;
2354                     *dbline   = $main::{ '_<' . $filename };
2355                     $max      = $#dbline;
2356
2357                     # Now where are we?
2358                     print_lineinfo($position);
2359                     next CMD;
2360                 }
2361
2362 =head4 C<-> - back one window
2363
2364 We change C<$start> to be one window back; if we go back past the first line,
2365 we set it to be the first line. We ser C<$incr> to put us back at the
2366 currently-executing line, and then put a C<l $start +> (list one window from
2367 C<$start>) in C<$cmd> to be executed later.
2368
2369 =cut
2370
2371                 # - - back a window.
2372                 if ($cmd eq '-') {
2373
2374                     # back up by a window; go to 1 if back too far.
2375                     $start -= $incr + $window + 1;
2376                     $start = 1 if $start <= 0;
2377                     $incr  = $window - 1;
2378
2379                     # Generate and execute a "l +" command (handled below).
2380                     $cmd = 'l ' . ($start) . '+';
2381                 }
2382
2383 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2384
2385 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2386 problems, most notably that the default case of several commands destroying
2387 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2388 retain the old commands for those who were used to using them or who preferred
2389 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2390 deal with them instead of processing them in-line.
2391
2392 =cut
2393
2394                 # All of these commands were remapped in perl 5.8.0;
2395                 # we send them off to the secondary dispatcher (see below).
2396                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2397                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2398                     next CMD;
2399                 }
2400
2401 =head4 C<y> - List lexicals in higher scope
2402
2403 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2404 above the current one and then displays then using C<dumpvar.pl>.
2405
2406 =cut
2407
2408                 if (my ($match_level, $match_vars)
2409                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2410
2411                     # See if we've got the necessary support.
2412                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2413                       or &warn(
2414                         $@ =~ /locate/
2415                         ? "PadWalker module not found - please install\n"
2416                         : $@
2417                       )
2418                       and next CMD;
2419
2420                     # Load up dumpvar if we don't have it. If we can, that is.
2421                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2422                     defined &main::dumpvar
2423                       or print $OUT "dumpvar.pl not available.\n"
2424                       and next CMD;
2425
2426                     # Got all the modules we need. Find them and print them.
2427                     my @vars = split( ' ', $match_vars || '' );
2428
2429                     # Find the pad.
2430                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2431
2432                     # Oops. Can't find it.
2433                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2434
2435                     # Show the desired vars with dumplex().
2436                     my $savout = select($OUT);
2437
2438                     # Have dumplex dump the lexicals.
2439                     dumpvar::dumplex( $_, $h->{$_},
2440                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2441                         @vars )
2442                       for sort keys %$h;
2443                     select($savout);
2444                     next CMD;
2445                 }
2446
2447 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2448
2449 All of the commands below this point don't work after the program being
2450 debugged has ended. All of them check to see if the program has ended; this
2451 allows the commands to be relocated without worrying about a 'line of
2452 demarcation' above which commands can be entered anytime, and below which
2453 they can't.
2454
2455 =head4 C<n> - single step, but don't trace down into subs
2456
2457 Done by setting C<$single> to 2, which forces subs to execute straight through
2458 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2459 so a null command knows what to re-execute.
2460
2461 =cut
2462
2463                 # n - next
2464                 if ($cmd eq 'n') {
2465                     next CMD if _DB__is_finished();
2466
2467                     # Single step, but don't enter subs.
2468                     $single = 2;
2469
2470                     # Save for empty command (repeat last).
2471                     $laststep = $cmd;
2472                     last CMD;
2473                 }
2474
2475 =head4 C<s> - single-step, entering subs
2476
2477 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2478 subs. Also saves C<s> as C<$lastcmd>.
2479
2480 =cut
2481
2482                 # s - single step.
2483                 if ($cmd eq 's') {
2484
2485                     # Get out and restart the command loop if program
2486                     # has finished.
2487                     next CMD if _DB__is_finished();
2488
2489                     # Single step should enter subs.
2490                     $single = 1;
2491
2492                     # Save for empty command (repeat last).
2493                     $laststep = $cmd;
2494                     last CMD;
2495                 }
2496
2497 =head4 C<c> - run continuously, setting an optional breakpoint
2498
2499 Most of the code for this command is taken up with locating the optional
2500 breakpoint, which is either a subroutine name or a line number. We set
2501 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2502 in this and all call levels above this one.
2503
2504 =cut
2505
2506                 # c - start continuous execution.
2507                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2508
2509                     # Hey, show's over. The debugged program finished
2510                     # executing already.
2511                     next CMD if _DB__is_finished();
2512
2513                     # Capture the place to put a one-time break.
2514                     $subname = $i;
2515
2516                     #  Probably not needed, since we finish an interactive
2517                     #  sub-session anyway...
2518                     # local $filename = $filename;
2519                     # local *dbline = *dbline; # XXX Would this work?!
2520                     #
2521                     # The above question wonders if localizing the alias
2522                     # to the magic array works or not. Since it's commented
2523                     # out, we'll just leave that to speculation for now.
2524
2525                     # If the "subname" isn't all digits, we'll assume it
2526                     # is a subroutine name, and try to find it.
2527                     if ( $subname =~ /\D/ ) {    # subroutine name
2528                             # Qualify it to the current package unless it's
2529                             # already qualified.
2530                         $subname = $package . "::" . $subname
2531                           unless $subname =~ /::/;
2532
2533                         # find_sub will return "file:line_number" corresponding
2534                         # to where the subroutine is defined; we call find_sub,
2535                         # break up the return value, and assign it in one
2536                         # operation.
2537                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2538
2539                         # Force the line number to be numeric.
2540                         $i += 0;
2541
2542                         # If we got a line number, we found the sub.
2543                         if ($i) {
2544
2545                             # Switch all the debugger's internals around so
2546                             # we're actually working with that file.
2547                             $filename = $file;
2548                             *dbline   = $main::{ '_<' . $filename };
2549
2550                             # Mark that there's a breakpoint in this file.
2551                             $had_breakpoints{$filename} |= 1;
2552
2553                             # Scan forward to the first executable line
2554                             # after the 'sub whatever' line.
2555                             $max = $#dbline;
2556                             ++$i while $dbline[$i] == 0 && $i < $max;
2557                         } ## end if ($i)
2558
2559                         # We didn't find a sub by that name.
2560                         else {
2561                             print $OUT "Subroutine $subname not found.\n";
2562                             next CMD;
2563                         }
2564                     } ## end if ($subname =~ /\D/)
2565
2566                     # At this point, either the subname was all digits (an
2567                     # absolute line-break request) or we've scanned through
2568                     # the code following the definition of the sub, looking
2569                     # for an executable, which we may or may not have found.
2570                     #
2571                     # If $i (which we set $subname from) is non-zero, we
2572                     # got a request to break at some line somewhere. On
2573                     # one hand, if there wasn't any real subroutine name
2574                     # involved, this will be a request to break in the current
2575                     # file at the specified line, so we have to check to make
2576                     # sure that the line specified really is breakable.
2577                     #
2578                     # On the other hand, if there was a subname supplied, the
2579                     # preceding block has moved us to the proper file and
2580                     # location within that file, and then scanned forward
2581                     # looking for the next executable line. We have to make
2582                     # sure that one was found.
2583                     #
2584                     # On the gripping hand, we can't do anything unless the
2585                     # current value of $i points to a valid breakable line.
2586                     # Check that.
2587                     if ($i) {
2588
2589                         # Breakable?
2590                         if ( $dbline[$i] == 0 ) {
2591                             print $OUT "Line $i not breakable.\n";
2592                             next CMD;
2593                         }
2594
2595                         # Yes. Set up the one-time-break sigil.
2596                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2597                         _enable_breakpoint_temp_enabled_status($filename, $i);
2598                     } ## end if ($i)
2599
2600                     # Turn off stack tracing from here up.
2601                     for my $i (0 .. $stack_depth) {
2602                         $stack[ $i ] &= ~1;
2603                     }
2604                     last CMD;
2605                 }
2606
2607 =head4 C<r> - return from a subroutine
2608
2609 For C<r> to work properly, the debugger has to stop execution again
2610 immediately after the return is executed. This is done by forcing
2611 single-stepping to be on in the call level above the current one. If
2612 we are printing return values when a C<r> is executed, set C<$doret>
2613 appropriately, and force us out of the command loop.
2614
2615 =cut
2616
2617                 # r - return from the current subroutine.
2618                 if ($cmd eq 'r') {
2619
2620                     # Can't do anything if the program's over.
2621                     next CMD if _DB__is_finished();
2622
2623                     # Turn on stack trace.
2624                     $stack[$stack_depth] |= 1;
2625
2626                     # Print return value unless the stack is empty.
2627                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2628                     last CMD;
2629                 }
2630
2631 =head4 C<T> - stack trace
2632
2633 Just calls C<DB::print_trace>.
2634
2635 =cut
2636
2637                 if ($cmd eq 'T') {
2638                     print_trace( $OUT, 1 );    # skip DB
2639                     next CMD;
2640                 }
2641
2642 =head4 C<w> - List window around current line.
2643
2644 Just calls C<DB::cmd_w>.
2645
2646 =cut
2647
2648                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2649                     &cmd_w( 'w', $arg );
2650                     next CMD;
2651                 }
2652
2653 =head4 C<W> - watch-expression processing.
2654
2655 Just calls C<DB::cmd_W>.
2656
2657 =cut
2658
2659                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2660                     &cmd_W( 'W', $arg );
2661                     next CMD;
2662                 }
2663
2664 =head4 C</> - search forward for a string in the source
2665
2666 We take the argument and treat it as a pattern. If it turns out to be a
2667 bad one, we return the error we got from trying to C<eval> it and exit.
2668 If not, we create some code to do the search and C<eval> it so it can't
2669 mess us up.
2670
2671 =cut
2672
2673                 # The pattern as a string.
2674                 use vars qw($inpat);
2675
2676                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2677
2678                     # Remove the final slash.
2679                     $inpat =~ s:([^\\])/$:$1:;
2680
2681                     # If the pattern isn't null ...
2682                     if ( $inpat ne "" ) {
2683
2684                         # Turn of warn and die procesing for a bit.
2685                         local $SIG{__DIE__};
2686                         local $SIG{__WARN__};
2687
2688                         # Create the pattern.
2689                         eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2690                         if ( $@ ne "" ) {
2691
2692                             # Oops. Bad pattern. No biscuit.
2693                             # Print the eval error and go back for more
2694                             # commands.
2695                             print $OUT "$@";
2696                             next CMD;
2697                         }
2698                         $pat = $inpat;
2699                     } ## end if ($inpat ne "")
2700
2701                     # Set up to stop on wrap-around.
2702                     $end = $start;
2703
2704                     # Don't move off the current line.
2705                     $incr = -1;
2706
2707                     # Done in eval so nothing breaks if the pattern
2708                     # does something weird.
2709                     eval '
2710                         no strict q/vars/;
2711                         for (;;) {
2712                             # Move ahead one line.
2713                             ++$start;
2714
2715                             # Wrap if we pass the last line.
2716                             $start = 1 if ($start > $max);
2717
2718                             # Stop if we have gotten back to this line again,
2719                             last if ($start == $end);
2720
2721                             # A hit! (Note, though, that we are doing
2722                             # case-insensitive matching. Maybe a qr//
2723                             # expression would be better, so the user could
2724                             # do case-sensitive matching if desired.
2725                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2726                                 if ($slave_editor) {
2727                                     # Handle proper escaping in the slave.
2728                                     print $OUT "\032\032$filename:$start:0\n";
2729                                 }
2730                                 else {
2731                                     # Just print the line normally.
2732                                     print $OUT "$start:\t",$dbline[$start],"\n";
2733                                 }
2734                                 # And quit since we found something.
2735                                 last;
2736                             }
2737                          } ';
2738
2739                     # If we wrapped, there never was a match.
2740                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2741                     next CMD;
2742                 }
2743
2744 =head4 C<?> - search backward for a string in the source
2745
2746 Same as for C</>, except the loop runs backwards.
2747
2748 =cut
2749
2750                 # ? - backward pattern search.
2751                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2752
2753                     # Get the pattern, remove trailing question mark.
2754                     $inpat =~ s:([^\\])\?$:$1:;
2755
2756                     # If we've got one ...
2757                     if ( $inpat ne "" ) {
2758
2759                         # Turn off die & warn handlers.
2760                         local $SIG{__DIE__};
2761                         local $SIG{__WARN__};
2762                         eval '$inpat =~ m' . "\a$inpat\a";
2763
2764                         if ( $@ ne "" ) {
2765
2766                             # Ouch. Not good. Print the error.
2767                             print $OUT $@;
2768                             next CMD;
2769                         }
2770                         $pat = $inpat;
2771                     } ## end if ($inpat ne "")
2772
2773                     # Where we are now is where to stop after wraparound.
2774                     $end = $start;
2775
2776                     # Don't move away from this line.
2777                     $incr = -1;
2778
2779                     # Search inside the eval to prevent pattern badness
2780                     # from killing us.
2781                     eval '
2782                         no strict q/vars/;
2783                         for (;;) {
2784                             # Back up a line.
2785                             --$start;
2786
2787                             # Wrap if we pass the first line.
2788
2789                             $start = $max if ($start <= 0);
2790
2791                             # Quit if we get back where we started,
2792                             last if ($start == $end);
2793
2794                             # Match?
2795                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2796                                 if ($slave_editor) {
2797                                     # Yep, follow slave editor requirements.
2798                                     print $OUT "\032\032$filename:$start:0\n";
2799                                 }
2800                                 else {
2801                                     # Yep, just print normally.
2802                                     print $OUT "$start:\t",$dbline[$start],"\n";
2803                                 }
2804
2805                                 # Found, so done.
2806                                 last;
2807                             }
2808                         } ';
2809
2810                     # Say we failed if the loop never found anything,
2811                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2812                     next CMD;
2813                 }
2814
2815 =head4 C<$rc> - Recall command
2816
2817 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2818 that the terminal supports history). It find the the command required, puts it
2819 into C<$cmd>, and redoes the loop to execute it.
2820
2821 =cut
2822
2823                 # $rc - recall command.
2824                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2825
2826                     # No arguments, take one thing off history.
2827                     pop(@hist) if length($cmd) > 1;
2828
2829                     # Relative (- found)?
2830                     #  Y - index back from most recent (by 1 if bare minus)
2831                     #  N - go to that particular command slot or the last
2832                     #      thing if nothing following.
2833                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2834
2835                     # Pick out the command desired.
2836                     $cmd = $hist[$i];
2837
2838                     # Print the command to be executed and restart the loop
2839                     # with that command in the buffer.
2840                     print $OUT $cmd, "\n";
2841                     redo CMD;
2842                 }
2843
2844 =head4 C<$sh$sh> - C<system()> command
2845
2846 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2847 C<STDOUT> from getting messed up.
2848
2849 =cut
2850
2851                 # $sh$sh - run a shell command (if it's all ASCII).
2852                 # Can't run shell commands with Unicode in the debugger, hmm.
2853                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2854
2855                     # System it.
2856                     &system($arg);
2857                     next CMD;
2858                 }
2859
2860 =head4 C<$rc I<pattern> $rc> - Search command history
2861
2862 Another command to manipulate C<@hist>: this one searches it with a pattern.
2863 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2864
2865 =cut
2866
2867                 # $rc pattern $rc - find a command in the history.
2868                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2869
2870                     # Create the pattern to use.
2871                     $pat = "^$arg";
2872
2873                     # Toss off last entry if length is >1 (and it always is).
2874                     pop(@hist) if length($cmd) > 1;
2875
2876                     # Look backward through the history.
2877                     for ( $i = $#hist ; $i ; --$i ) {
2878                         # Stop if we find it.
2879                         last if $hist[$i] =~ /$pat/;
2880                     }
2881
2882                     if ( !$i ) {
2883
2884                         # Never found it.
2885                         print $OUT "No such command!\n\n";
2886                         next CMD;
2887                     }
2888
2889                     # Found it. Put it in the buffer, print it, and process it.
2890                     $cmd = $hist[$i];
2891                     print $OUT $cmd, "\n";
2892                     redo CMD;
2893                 }
2894
2895 =head4 C<$sh> - Invoke a shell
2896
2897 Uses C<DB::system> to invoke a shell.
2898
2899 =cut
2900
2901                 # $sh - start a shell.
2902                 if ($cmd =~ /\A$sh\z/) {
2903
2904                     # Run the user's shell. If none defined, run Bourne.
2905                     # We resume execution when the shell terminates.
2906                     &system( $ENV{SHELL} || "/bin/sh" );
2907                     next CMD;
2908                 }
2909
2910 =head4 C<$sh I<command>> - Force execution of a command in a shell
2911
2912 Like the above, but the command is passed to the shell. Again, we use
2913 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2914
2915 =cut
2916
2917                 # $sh command - start a shell and run a command in it.
2918                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2919
2920                     # XXX: using csh or tcsh destroys sigint retvals!
2921                     #&system($1);  # use this instead
2922
2923                     # use the user's shell, or Bourne if none defined.
2924                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2925                     next CMD;
2926                 }
2927
2928 =head4 C<H> - display commands in history
2929
2930 Prints the contents of C<@hist> (if any).
2931
2932 =cut
2933
2934                 if ($cmd =~ /\AH\b\s*\*/) {
2935                     @hist = @truehist = ();
2936                     print $OUT "History cleansed\n";
2937                     next CMD;
2938                 }
2939
2940                 if (my ($num)
2941                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2942
2943                     # Anything other than negative numbers is ignored by
2944                     # the (incorrect) pattern, so this test does nothing.
2945                     $end = $num ? ( $#hist - $num ) : 0;
2946
2947                     # Set to the minimum if less than zero.
2948                     $hist = 0 if $hist < 0;
2949
2950                     # Start at the end of the array.
2951                     # Stay in while we're still above the ending value.
2952                     # Tick back by one each time around the loop.
2953                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2954
2955                         # Print the command  unless it has no arguments.
2956                         print $OUT "$i: ", $hist[$i], "\n"
2957                           unless $hist[$i] =~ /^.?$/;
2958                     }
2959                     next CMD;
2960                 }
2961
2962 =head4 C<man, doc, perldoc> - look up documentation
2963
2964 Just calls C<runman()> to print the appropriate document.
2965
2966 =cut
2967
2968                 # man, perldoc, doc - show manual pages.
2969                 if (my ($man_page)
2970                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2971                     runman($man_page);
2972                     next CMD;
2973                 }
2974
2975 =head4 C<p> - print
2976
2977 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2978 the bottom of the loop.
2979
2980 =cut
2981
2982                 my $print_cmd = 'print {$DB::OUT} ';
2983                 # p - print (no args): print $_.
2984                 if ($cmd eq 'p') {
2985                     $cmd = $print_cmd . '$_';
2986                 }
2987
2988                 # p - print the given expression.
2989                 $cmd =~ s/\Ap\b/$print_cmd /;
2990
2991 =head4 C<=> - define command alias
2992
2993 Manipulates C<%alias> to add or list command aliases.
2994
2995 =cut
2996
2997                 # = - set up a command alias.
2998                 if ($cmd =~ s/\A=\s*//) {
2999                     my @keys;
3000                     if ( length $cmd == 0 ) {
3001
3002                         # No args, get current aliases.
3003                         @keys = sort keys %alias;
3004                     }
3005                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3006
3007                         # Creating a new alias. $k is alias name, $v is
3008                         # alias value.
3009
3010                         # can't use $_ or kill //g state
3011                         for my $x ( $k, $v ) {
3012
3013                             # Escape "alarm" characters.
3014                             $x =~ s/\a/\\a/g;
3015                         }
3016
3017                         # Substitute key for value, using alarm chars
3018                         # as separators (which is why we escaped them in
3019                         # the command).
3020                         $alias{$k} = "s\a$k\a$v\a";
3021
3022                         # Turn off standard warn and die behavior.
3023                         local $SIG{__DIE__};
3024                         local $SIG{__WARN__};
3025
3026                         # Is it valid Perl?
3027                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3028
3029                             # Nope. Bad alias. Say so and get out.
3030                             print $OUT "Can't alias $k to $v: $@\n";
3031                             delete $alias{$k};
3032                             next CMD;
3033                         }
3034
3035                         # We'll only list the new one.
3036                         @keys = ($k);
3037                     } ## end elsif (my ($k, $v) = ($cmd...
3038
3039                     # The argument is the alias to list.
3040                     else {
3041                         @keys = ($cmd);
3042                     }
3043
3044                     # List aliases.
3045                     for my $k (@keys) {
3046
3047                         # Messy metaquoting: Trim the substitution code off.
3048                         # We use control-G as the delimiter because it's not
3049                         # likely to appear in the alias.
3050                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3051
3052                             # Print the alias.
3053                             print $OUT "$k\t= $1\n";
3054                         }
3055                         elsif ( defined $alias{$k} ) {
3056
3057                             # Couldn't trim it off; just print the alias code.
3058                             print $OUT "$k\t$alias{$k}\n";
3059                         }
3060                         else {
3061
3062                             # No such, dude.
3063                             print "No alias for $k\n";
3064                         }
3065                     } ## end for my $k (@keys)
3066                     next CMD;
3067                 }
3068
3069 =head4 C<source> - read commands from a file.
3070
3071 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3072 pick it up.
3073
3074 =cut
3075
3076                 # source - read commands from a file (or pipe!) and execute.
3077                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3078                     if ( open my $fh, $sourced_fn ) {
3079
3080                         # Opened OK; stick it in the list of file handles.
3081                         push @cmdfhs, $fh;
3082                     }
3083                     else {
3084
3085                         # Couldn't open it.
3086                         &warn("Can't execute '$sourced_fn': $!\n");
3087                     }
3088                     next CMD;
3089                 }
3090
3091                 if (my ($which_cmd, $position)
3092                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3093
3094                     my ($fn, $line_num);
3095                     if ($position =~ m{\A\d+\z})
3096                     {
3097                         $fn = $filename;
3098                         $line_num = $position;
3099                     }
3100                     elsif (my ($new_fn, $new_line_num)
3101                         = $position =~ m{\A(.*):(\d+)\z}) {
3102                         ($fn, $line_num) = ($new_fn, $new_line_num);
3103                     }
3104                     else
3105                     {
3106                         &warn("Wrong spec for enable/disable argument.\n");
3107                     }
3108
3109                     if (defined($fn)) {
3110                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3111                             _set_breakpoint_enabled_status($fn, $line_num,
3112                                 ($which_cmd eq 'enable' ? 1 : '')
3113                             );
3114                         }
3115                         else {
3116                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3117                         }
3118                     }
3119
3120                     next CMD;
3121                 }
3122
3123 =head4 C<save> - send current history to a file
3124
3125 Takes the complete history, (not the shrunken version you see with C<H>),
3126 and saves it to the given filename, so it can be replayed using C<source>.
3127
3128 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3129
3130 =cut
3131
3132                 # save source - write commands to a file for later use
3133                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3134                     my $filename = $new_fn || '.perl5dbrc';    # default?
3135                     if ( open my $fh, '>', $filename ) {
3136
3137                        # chomp to remove extraneous newlines from source'd files
3138                         chomp( my @truelist =
3139                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3140                               @truehist );
3141                         print $fh join( "\n", @truelist );
3142                         print "commands saved in $file\n";
3143                     }
3144                     else {
3145                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3146                     }
3147                     next CMD;
3148                 }
3149
3150 =head4 C<R> - restart
3151
3152 Restart the debugger session.
3153
3154 =head4 C<rerun> - rerun the current session
3155
3156 Return to any given position in the B<true>-history list
3157
3158 =cut
3159
3160                 # R - restart execution.
3161                 # rerun - controlled restart execution.
3162                 if (my ($cmd_cmd, $cmd_params) =
3163                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3164                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3165
3166                     # Close all non-system fds for a clean restart.  A more
3167                     # correct method would be to close all fds that were not
3168                     # open when the process started, but this seems to be
3169                     # hard.  See "debugger 'R'estart and open database
3170                     # connections" on p5p.
3171
3172                     my $max_fd = 1024; # default if POSIX can't be loaded
3173                     if (eval { require POSIX }) {
3174                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3175                     }
3176
3177                     if (defined $max_fd) {
3178                         foreach ($^F+1 .. $max_fd-1) {
3179                             next unless open FD_TO_CLOSE, "<&=$_";
3180                             close(FD_TO_CLOSE);
3181                         }
3182                     }
3183
3184                     # And run Perl again.  We use exec() to keep the
3185                     # PID stable (and that way $ini_pids is still valid).
3186                     exec(@args) || print $OUT "exec failed: $!\n";
3187
3188                     last CMD;
3189                 }
3190
3191 =head4 C<|, ||> - pipe output through the pager.
3192
3193 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3194 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3195 pipe to the pager (restoring the output filehandles if this fails). If this
3196 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3197 set C<$signal>, sending us back into the debugger.
3198
3199 We then trim off the pipe symbols and C<redo> the command loop at the
3200 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3201 reading another.
3202
3203 =cut
3204
3205                 # || - run command in the pager, with output to DB::OUT.
3206                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3207                     if ( $pager =~ /^\|/ ) {
3208
3209                         # Default pager is into a pipe. Redirect I/O.
3210                         open( SAVEOUT, ">&STDOUT" )
3211                           || &warn("Can't save STDOUT");
3212                         open( STDOUT, ">&OUT" )
3213                           || &warn("Can't redirect STDOUT");
3214                     } ## end if ($pager =~ /^\|/)
3215                     else {
3216
3217                         # Not into a pipe. STDOUT is safe.
3218                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3219                     }
3220
3221                     # Fix up environment to record we have less if so.
3222                     fix_less();
3223
3224                     unless ( $piped = open( OUT, $pager ) ) {
3225
3226                         # Couldn't open pipe to pager.
3227                         &warn("Can't pipe output to '$pager'");
3228                         if ( $pager =~ /^\|/ ) {
3229
3230                             # Redirect I/O back again.
3231                             open( OUT, ">&STDOUT" )    # XXX: lost message
3232                               || &warn("Can't restore DB::OUT");
3233                             open( STDOUT, ">&SAVEOUT" )
3234                               || &warn("Can't restore STDOUT");
3235                             close(SAVEOUT);
3236                         } ## end if ($pager =~ /^\|/)
3237                         else {
3238
3239                             # Redirect I/O. STDOUT already safe.
3240                             open( OUT, ">&STDOUT" )    # XXX: lost message
3241                               || &warn("Can't restore DB::OUT");
3242                         }
3243                         next CMD;
3244                     } ## end unless ($piped = open(OUT,...
3245
3246                     # Set up broken-pipe handler if necessary.
3247                     $SIG{PIPE} = \&DB::catch
3248                       if $pager =~ /^\|/
3249                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3250
3251                     OUT->autoflush(1);
3252                     # Save current filehandle, and put it back.
3253                     $selected = select(OUT);
3254                     # Don't put it back if pager was a pipe.
3255                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3256
3257                     # Trim off the pipe symbols and run the command now.
3258                     $cmd =~ s#\A\|+\s*##;
3259                     redo PIPE;
3260                 }
3261
3262 =head3 END OF COMMAND PARSING
3263
3264 Anything left in C<$cmd> at this point is a Perl expression that we want to
3265 evaluate. We'll always evaluate in the user's context, and fully qualify
3266 any variables we might want to address in the C<DB> package.
3267
3268 =cut
3269
3270                 # t - turn trace on.
3271                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3272                     my $trace_arg = $1;
3273                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3274                 }
3275
3276                 # s - single-step. Remember the last command was 's'.
3277                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3278                     $laststep = 's';
3279                 }
3280
3281                 # n - single-step, but not into subs. Remember last command
3282                 # was 'n'.
3283                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3284                     $laststep = 'n';
3285                 }
3286
3287             }    # PIPE:
3288
3289             # Make sure the flag that says "the debugger's running" is
3290             # still on, to make sure we get control again.
3291             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3292
3293             # Run *our* eval that executes in the caller's context.
3294             DB::eval();
3295
3296             # Turn off the one-time-dump stuff now.
3297             if ($onetimeDump) {
3298                 $onetimeDump      = undef;
3299                 $onetimedumpDepth = undef;
3300             }
3301             elsif ( $term_pid == $$ ) {
3302                 eval { # May run under miniperl, when not available...
3303                     STDOUT->flush();
3304                     STDERR->flush();
3305                 };
3306
3307                 # XXX If this is the master pid, print a newline.
3308                 print {$OUT} "\n";
3309             }
3310         } ## end while (($term || &setterm...
3311
3312 =head3 POST-COMMAND PROCESSING
3313
3314 After each command, we check to see if the command output was piped anywhere.
3315 If so, we go through the necessary code to unhook the pipe and go back to
3316 our standard filehandles for input and output.
3317
3318 =cut
3319
3320         continue {    # CMD:
3321
3322             # At the end of every command:
3323             if ($piped) {
3324
3325                 # Unhook the pipe mechanism now.
3326                 if ( $pager =~ /^\|/ ) {
3327
3328                     # No error from the child.
3329                     $? = 0;
3330
3331                     # we cannot warn here: the handle is missing --tchrist
3332                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3333
3334                     # most of the $? crud was coping with broken cshisms
3335                     # $? is explicitly set to 0, so this never runs.
3336                     if ($?) {
3337                         print SAVEOUT "Pager '$pager' failed: ";
3338                         if ( $? == -1 ) {
3339                             print SAVEOUT "shell returned -1\n";
3340                         }
3341                         elsif ( $? >> 8 ) {
3342                             print SAVEOUT ( $? & 127 )
3343                               ? " (SIG#" . ( $? & 127 ) . ")"
3344                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3345                         }
3346                         else {
3347                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3348                         }
3349                     } ## end if ($?)
3350
3351                     # Reopen filehandle for our output (if we can) and
3352                     # restore STDOUT (if we can).
3353                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3354                     open( STDOUT, ">&SAVEOUT" )
3355                       || &warn("Can't restore STDOUT");
3356
3357                     # Turn off pipe exception handler if necessary.
3358                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3359
3360                     # Will stop ignoring SIGPIPE if done like nohup(1)
3361                     # does SIGINT but Perl doesn't give us a choice.
3362                 } ## end if ($pager =~ /^\|/)
3363                 else {
3364
3365                     # Non-piped "pager". Just restore STDOUT.
3366                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3367                 }
3368
3369                 # Close filehandle pager was using, restore the normal one
3370                 # if necessary,
3371                 close(SAVEOUT);
3372                 select($selected), $selected = "" unless $selected eq "";
3373
3374                 # No pipes now.
3375                 $piped = "";
3376             } ## end if ($piped)
3377         }    # CMD:
3378
3379 =head3 COMMAND LOOP TERMINATION
3380
3381 When commands have finished executing, we come here. If the user closed the
3382 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3383 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3384 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3385 The interpreter will then execute the next line and then return control to us
3386 again.
3387
3388 =cut
3389
3390         # No more commands? Quit.
3391         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3392
3393         # Evaluate post-prompt commands.
3394         foreach $evalarg (@$post) {
3395             DB::eval();
3396         }
3397     }    # if ($single || $signal)
3398
3399     # Put the user's globals back where you found them.
3400     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3401     ();
3402 } ## end sub DB
3403
3404 package DB::Obj;
3405
3406 sub new {
3407     my $class = shift;
3408
3409     my $self = bless {}, $class;
3410
3411     $self->_init(@_);
3412
3413     return $self;
3414 }
3415
3416 sub _init {
3417     my ($self, $args) = @_;
3418
3419     %{$self} = (%$self, %$args);
3420
3421     return;
3422 }
3423
3424 {
3425     no strict 'refs';
3426     foreach my $slot_name (qw(after explicit_stop infix position prefix)) {
3427         my $slot = $slot_name;
3428         *{$slot} = sub {
3429             my $self = shift;
3430
3431             if (@_) {
3432                 ${ $self->{$slot} } = shift;
3433             }
3434
3435             return ${ $self->{$slot} };
3436         };
3437
3438         *{"append_to_$slot"} = sub {
3439             my $self = shift;
3440             my $s = shift;
3441
3442             return $self->$slot($self->$slot . $s);
3443         };
3444     }
3445 }
3446
3447 sub _DB_on_init__initialize_globals
3448 {
3449     my $self = shift;
3450
3451     # Check for whether we should be running continuously or not.
3452     # _After_ the perl program is compiled, $single is set to 1:
3453     if ( $single and not $second_time++ ) {
3454
3455         # Options say run non-stop. Run until we get an interrupt.
3456         if ($runnonstop) {    # Disable until signal
3457                 # If there's any call stack in place, turn off single
3458                 # stepping into subs throughout the stack.
3459             for my $i (0 .. $stack_depth) {
3460                 $stack[ $i ] &= ~1;
3461             }
3462
3463             # And we are now no longer in single-step mode.
3464             $single = 0;
3465
3466             # If we simply returned at this point, we wouldn't get
3467             # the trace info. Fall on through.
3468             # return;
3469         } ## end if ($runnonstop)
3470
3471         elsif ($ImmediateStop) {
3472
3473             # We are supposed to stop here; XXX probably a break.
3474             $ImmediateStop = 0;    # We've processed it; turn it off
3475             $signal        = 1;    # Simulate an interrupt to force
3476                                    # us into the command loop
3477         }
3478     } ## end if ($single and not $second_time...
3479
3480     # If we're in single-step mode, or an interrupt (real or fake)
3481     # has occurred, turn off non-stop mode.
3482     $runnonstop = 0 if $single or $signal;
3483
3484     return;
3485 }
3486
3487 sub _DB__handle_watch_expressions
3488 {
3489     my $self = shift;
3490
3491     if ( $trace & 2 ) {
3492         for my $n (0 .. $#to_watch) {
3493             $evalarg = $to_watch[$n];
3494             local $onetimeDump;    # Tell DB::eval() to not output results
3495
3496             # Fix context DB::eval() wants to return an array, but
3497             # we need a scalar here.
3498             my ($val) = join( "', '", DB::eval() );
3499             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3500
3501             # Did it change?
3502             if ( $val ne $old_watch[$n] ) {
3503
3504                 # Yep! Show the difference, and fake an interrupt.
3505                 $signal = 1;
3506                 print {$OUT} <<EOP;
3507 Watchpoint $n:\t$to_watch[$n] changed:
3508     old value:\t$old_watch[$n]
3509     new value:\t$val
3510 EOP
3511                 $old_watch[$n] = $val;
3512             } ## end if ($val ne $old_watch...
3513         } ## end for my $n (0 ..
3514     } ## end if ($trace & 2)
3515
3516     return;
3517 }
3518
3519 sub _my_print_lineinfo
3520 {
3521     my ($self, $i, $incr_pos) = @_;
3522
3523     if ($frame) {
3524         # Print it indented if tracing is on.
3525         DB::print_lineinfo( ' ' x $stack_depth,
3526             "$i:\t$DB::dbline[$i]" . $self->after );
3527     }
3528     else {
3529         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3530     }
3531 }
3532
3533 sub _curr_line {
3534     return $DB::dbline[$line];
3535 }
3536
3537 sub _DB__grab_control
3538 {
3539     my $self = shift;
3540
3541     # Yes, grab control.
3542     if ($DB::slave_editor) {
3543
3544         # Tell the editor to update its position.
3545         $self->position("\032\032${DB::filename}:$line:0\n");
3546         DB::print_lineinfo($self->position());
3547     }
3548
3549 =pod
3550
3551 Special check: if we're in package C<DB::fake>, we've gone through the
3552 C<END> block at least once. We set up everything so that we can continue
3553 to enter commands and have a valid context to be in.
3554
3555 =cut
3556
3557     elsif ( $DB::package eq 'DB::fake' ) {
3558
3559         # Fallen off the end already.
3560         if (!$DB::term) {
3561             DB::setterm();
3562         }
3563
3564         DB::print_help(<<EOP);
3565 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3566 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3567 B<h q>, B<h R> or B<h o> to get additional info.
3568 EOP
3569
3570         # Set the DB::eval context appropriately.
3571         $DB::package     = 'main';
3572         $DB::usercontext = DB::_calc_usercontext($DB::package);
3573     } ## end elsif ($package eq 'DB::fake')
3574
3575 =pod
3576
3577 If the program hasn't finished executing, we scan forward to the
3578 next executable line, print that out, build the prompt from the file and line
3579 number information, and print that.
3580
3581 =cut
3582
3583     else {
3584
3585
3586         # Still somewhere in the midst of execution. Set up the
3587         #  debugger prompt.
3588         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3589                              # Perl 5 ones (sorry, we don't print Klingon
3590                              #module names)
3591
3592         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3593         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3594         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3595
3596         # Break up the prompt if it's really long.
3597         if ( length($self->prefix()) > 30 ) {
3598             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3599             $self->prefix("");
3600             $self->infix(":\t");
3601         }
3602         else {
3603             $self->infix("):\t");
3604             $self->position(
3605                 $self->prefix . $line. $self->infix
3606                 . $self->_curr_line . $self->after
3607             );
3608         }
3609
3610         # Print current line info, indenting if necessary.
3611         $self->_my_print_lineinfo($line, $self->position);
3612
3613         my $i;
3614         my $line_i = sub { return $DB::dbline[$i]; };
3615
3616         # Scan forward, stopping at either the end or the next
3617         # unbreakable line.
3618         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3619         {    #{ vi
3620
3621             # Drop out on null statements, block closers, and comments.
3622             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3623
3624             # Drop out if the user interrupted us.
3625             last if $signal;
3626
3627             # Append a newline if the line doesn't have one. Can happen
3628             # in eval'ed text, for instance.
3629             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3630
3631             # Next executable line.
3632             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3633                 . $self->after;
3634             $self->append_to_position($incr_pos);
3635             $self->_my_print_lineinfo($i, $incr_pos);
3636         } ## end for ($i = $line + 1 ; $i...
3637     } ## end else [ if ($slave_editor)
3638
3639     return;
3640 }
3641
3642 sub _handle_t_command {
3643     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3644         $trace ^= 1;
3645         local $\ = '';
3646         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3647         print {$OUT} "Trace = "
3648         . ( ( $trace & 1 )
3649             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3650             : "off" ) . "\n";
3651         next CMD;
3652     }
3653
3654     return;
3655 }
3656
3657 package DB;
3658
3659 # The following code may be executed now:
3660 # BEGIN {warn 4}
3661
3662 =head2 sub
3663
3664 C<sub> is called whenever a subroutine call happens in the program being
3665 debugged. The variable C<$DB::sub> contains the name of the subroutine
3666 being called.
3667
3668 The core function of this subroutine is to actually call the sub in the proper
3669 context, capturing its output. This of course causes C<DB::DB> to get called
3670 again, repeating until the subroutine ends and returns control to C<DB::sub>
3671 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3672 return value, and returns its captured copy of the return value as its own
3673 return value. The value then feeds back into the program being debugged as if
3674 C<DB::sub> hadn't been there at all.
3675
3676 C<sub> does all the work of printing the subroutine entry and exit messages
3677 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3678 and also prints the return value if needed (for the C<r> command and if
3679 the 16 bit is set in C<$frame>).
3680
3681 It also tracks the subroutine call depth by saving the current setting of
3682 C<$single> in the C<@stack> package global; if this exceeds the value in
3683 C<$deep>, C<sub> automatically turns on printing of the current depth by
3684 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3685 of stop/don't stop on entry to subs set as it currently is set.
3686
3687 =head3 C<caller()> support
3688
3689 If C<caller()> is called from the package C<DB>, it provides some
3690 additional data, in the following order:
3691
3692 =over 4
3693
3694 =item * C<$package>
3695
3696 The package name the sub was in
3697
3698 =item * C<$filename>
3699
3700 The filename it was defined in
3701
3702 =item * C<$line>
3703
3704 The line number it was defined on
3705
3706 =item * C<$subroutine>
3707
3708 The subroutine name; C<(eval)> if an C<eval>().
3709
3710 =item * C<$hasargs>
3711
3712 1 if it has arguments, 0 if not
3713
3714 =item * C<$wantarray>
3715
3716 1 if array context, 0 if scalar context
3717
3718 =item * C<$evaltext>
3719
3720 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3721
3722 =item * C<$is_require>
3723
3724 frame was created by a C<use> or C<require> statement
3725
3726 =item * C<$hints>
3727
3728 pragma information; subject to change between versions
3729
3730 =item * C<$bitmask>
3731
3732 pragma information; subject to change between versions
3733
3734 =item * C<@DB::args>
3735
3736 arguments with which the subroutine was invoked
3737
3738 =back
3739
3740 =cut
3741
3742 use vars qw($deep);
3743
3744 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3745 # happy. -- Shlomi Fish
3746 sub DB::sub {
3747     # Do not use a regex in this subroutine -> results in corrupted memory
3748     # See: [perl #66110]
3749
3750     # lock ourselves under threads
3751     lock($DBGR);
3752
3753     # Whether or not the autoloader was running, a scalar to put the
3754     # sub's return value in (if needed), and an array to put the sub's
3755     # return value in (if needed).
3756     my ( $al, $ret, @ret ) = "";
3757     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3758         print "creating new thread\n";
3759     }
3760
3761     # If the last ten characters are '::AUTOLOAD', note we've traced
3762     # into AUTOLOAD for $sub.
3763     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3764         no strict 'refs';
3765         $al = " for $$sub" if defined $$sub;
3766     }
3767
3768     # We stack the stack pointer and then increment it to protect us
3769     # from a situation that might unwind a whole bunch of call frames
3770     # at once. Localizing the stack pointer means that it will automatically
3771     # unwind the same amount when multiple stack frames are unwound.
3772     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3773
3774     # Expand @stack.
3775     $#stack = $stack_depth;
3776
3777     # Save current single-step setting.
3778     $stack[-1] = $single;
3779
3780     # Turn off all flags except single-stepping.
3781     $single &= 1;
3782
3783     # If we've gotten really deeply recursed, turn on the flag that will
3784     # make us stop with the 'deep recursion' message.
3785     $single |= 4 if $stack_depth == $deep;
3786
3787     # If frame messages are on ...
3788     (
3789         $frame & 4    # Extended frame entry message
3790         ? (
3791             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3792
3793             # Why -1? But it works! :-(
3794             # Because print_trace will call add 1 to it and then call
3795             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3796             # in dump_trace.
3797             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3798           )
3799         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3800
3801           # standard frame entry message
3802       )
3803       if $frame;
3804
3805     # Determine the sub's return type, and capture appropriately.
3806     if (wantarray) {
3807
3808         # Called in array context. call sub and capture output.
3809         # DB::DB will recursively get control again if appropriate; we'll come
3810         # back here when the sub is finished.
3811         {
3812             no strict 'refs';
3813             @ret = &$sub;
3814         }
3815
3816         # Pop the single-step value back off the stack.
3817         $single |= $stack[ $stack_depth-- ];
3818
3819         # Check for exit trace messages...
3820         (
3821             $frame & 4    # Extended exit message
3822             ? (
3823                 print_lineinfo( ' ' x $stack_depth, "out " ),
3824                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3825               )
3826             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3827
3828               # Standard exit message
3829           )
3830           if $frame & 2;
3831
3832         # Print the return info if we need to.
3833         if ( $doret eq $stack_depth or $frame & 16 ) {
3834
3835             # Turn off output record separator.
3836             local $\ = '';
3837             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3838
3839             # Indent if we're printing because of $frame tracing.
3840             print $fh ' ' x $stack_depth if $frame & 16;
3841
3842             # Print the return value.
3843             print $fh "list context return from $sub:\n";
3844             dumpit( $fh, \@ret );
3845
3846             # And don't print it again.
3847             $doret = -2;
3848         } ## end if ($doret eq $stack_depth...
3849             # And we have to return the return value now.
3850         @ret;
3851     } ## end if (wantarray)
3852
3853     # Scalar context.
3854     else {
3855         if ( defined wantarray ) {
3856             no strict 'refs';
3857             # Save the value if it's wanted at all.
3858             $ret = &$sub;
3859         }
3860         else {
3861             no strict 'refs';
3862             # Void return, explicitly.
3863             &$sub;
3864             undef $ret;
3865         }
3866
3867         # Pop the single-step value off the stack.
3868         $single |= $stack[ $stack_depth-- ];
3869
3870         # If we're doing exit messages...
3871         (
3872             $frame & 4    # Extended messages
3873             ? (
3874                 print_lineinfo( ' ' x $stack_depth, "out " ),
3875                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3876               )
3877             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3878
3879               # Standard messages
3880           )
3881           if $frame & 2;
3882
3883         # If we are supposed to show the return value... same as before.
3884         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3885             local $\ = '';
3886             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3887             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3888             print $fh (
3889                 defined wantarray
3890                 ? "scalar context return from $sub: "
3891                 : "void context return from $sub\n"
3892             );
3893             dumpit( $fh, $ret ) if defined wantarray;
3894             $doret = -2;
3895         } ## end if ($doret eq $stack_depth...
3896
3897         # Return the appropriate scalar value.
3898         $ret;
3899     } ## end else [ if (wantarray)
3900 } ## end sub _sub
3901
3902 sub lsub : lvalue {
3903
3904     no strict 'refs';
3905
3906     # lock ourselves under threads
3907     lock($DBGR);
3908
3909     # Whether or not the autoloader was running, a scalar to put the
3910     # sub's return value in (if needed), and an array to put the sub's
3911     # return value in (if needed).
3912     my ( $al, $ret, @ret ) = "";
3913     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3914         print "creating new thread\n";
3915     }
3916
3917     # If the last ten characters are C'::AUTOLOAD', note we've traced
3918     # into AUTOLOAD for $sub.
3919     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3920         $al = " for $$sub";
3921     }
3922
3923     # We stack the stack pointer and then increment it to protect us
3924     # from a situation that might unwind a whole bunch of call frames
3925     # at once. Localizing the stack pointer means that it will automatically
3926     # unwind the same amount when multiple stack frames are unwound.
3927     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3928
3929     # Expand @stack.
3930     $#stack = $stack_depth;
3931
3932     # Save current single-step setting.
3933     $stack[-1] = $single;
3934
3935     # Turn off all flags except single-stepping.
3936     $single &= 1;
3937
3938     # If we've gotten really deeply recursed, turn on the flag that will
3939     # make us stop with the 'deep recursion' message.
3940     $single |= 4 if $stack_depth == $deep;
3941
3942     # If frame messages are on ...
3943     (
3944         $frame & 4    # Extended frame entry message
3945         ? (
3946             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3947
3948             # Why -1? But it works! :-(
3949             # Because print_trace will call add 1 to it and then call
3950             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3951             # in dump_trace.
3952             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3953           )
3954         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3955
3956           # standard frame entry message
3957       )
3958       if $frame;
3959
3960     # Pop the single-step value back off the stack.
3961     $single |= $stack[ $stack_depth-- ];
3962
3963     # call the original lvalue sub.
3964     &$sub;
3965 }
3966
3967 # Abstracting common code from multiple places elsewhere:
3968 sub depth_print_lineinfo {
3969     my $always_print = shift;
3970
3971     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3972 }
3973
3974 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3975
3976 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3977 Most of the changes were to systematize the command structure and to eliminate
3978 commands that threw away user input without checking.
3979
3980 The following sections describe the code added to make it easy to support
3981 multiple command sets with conflicting command names. This section is a start
3982 at unifying all command processing to make it simpler to develop commands.
3983
3984 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3985 number, and C<$dbline> (the current line) as arguments.
3986
3987 Support functions in this section which have multiple modes of failure C<die>
3988 on error; the rest simply return a false value.
3989
3990 The user-interface functions (all of the C<cmd_*> functions) just output
3991 error messages.
3992
3993 =head2 C<%set>
3994
3995 The C<%set> hash defines the mapping from command letter to subroutine
3996 name suffix.
3997
3998 C<%set> is a two-level hash, indexed by set name and then by command name.
3999 Note that trying to set the CommandSet to C<foobar> simply results in the
4000 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4001
4002 =cut
4003
4004 ### The API section
4005
4006 my %set = (    #
4007     'pre580' => {
4008         'a' => 'pre580_a',
4009         'A' => 'pre580_null',
4010         'b' => 'pre580_b',
4011         'B' => 'pre580_null',
4012         'd' => 'pre580_null',
4013         'D' => 'pre580_D',
4014         'h' => 'pre580_h',
4015         'M' => 'pre580_null',
4016         'O' => 'o',
4017         'o' => 'pre580_null',
4018         'v' => 'M',
4019         'w' => 'v',
4020         'W' => 'pre580_W',
4021     },
4022     'pre590' => {
4023         '<'  => 'pre590_prepost',
4024         '<<' => 'pre590_prepost',
4025         '>'  => 'pre590_prepost',
4026         '>>' => 'pre590_prepost',
4027         '{'  => 'pre590_prepost',
4028         '{{' => 'pre590_prepost',
4029     },
4030 );
4031
4032 my %breakpoints_data;
4033
4034 sub _has_breakpoint_data_ref {
4035     my ($filename, $line) = @_;
4036
4037     return (
4038         exists( $breakpoints_data{$filename} )
4039             and
4040         exists( $breakpoints_data{$filename}{$line} )
4041     );
4042 }
4043
4044 sub _get_breakpoint_data_ref {
4045     my ($filename, $line) = @_;
4046
4047     return ($breakpoints_data{$filename}{$line} ||= +{});
4048 }
4049
4050 sub _delete_breakpoint_data_ref {
4051     my ($filename, $line) = @_;
4052
4053     delete($breakpoints_data{$filename}{$line});
4054     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4055         delete($breakpoints_data{$filename});
4056     }
4057
4058     return;
4059 }
4060
4061 sub _set_breakpoint_enabled_status {
4062     my ($filename, $line, $status) = @_;
4063
4064     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4065         ($status ? 1 : '')
4066         ;
4067
4068     return;
4069 }
4070
4071 sub _enable_breakpoint_temp_enabled_status {
4072     my ($filename, $line) = @_;
4073
4074     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4075
4076     return;
4077 }
4078
4079 sub _cancel_breakpoint_temp_enabled_status {
4080     my ($filename, $line) = @_;
4081
4082     my $ref = _get_breakpoint_data_ref($filename, $line);
4083
4084     delete ($ref->{'temp_enabled'});
4085
4086     if (! %$ref) {
4087         _delete_breakpoint_data_ref($filename, $line);
4088     }
4089
4090     return;
4091 }
4092
4093 sub _is_breakpoint_enabled {
4094     my ($filename, $line) = @_;
4095
4096     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4097     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4098 }
4099
4100 =head2 C<cmd_wrapper()> (API)
4101
4102 C<cmd_wrapper()> allows the debugger to switch command sets
4103 depending on the value of the C<CommandSet> option.
4104
4105 It tries to look up the command in the C<%set> package-level I<lexical>
4106 (which means external entities can't fiddle with it) and create the name of
4107 the sub to call based on the value found in the hash (if it's there). I<All>
4108 of the commands to be handled in a set have to be added to C<%set>; if they
4109 aren't found, the 5.8.0 equivalent is called (if there is one).
4110
4111 This code uses symbolic references.
4112
4113 =cut
4114
4115 sub cmd_wrapper {
4116     my $cmd      = shift;
4117     my $line     = shift;
4118     my $dblineno = shift;
4119
4120     # Assemble the command subroutine's name by looking up the
4121     # command set and command name in %set. If we can't find it,
4122     # default to the older version of the command.
4123     my $call = 'cmd_'
4124       . ( $set{$CommandSet}{$cmd}
4125           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4126
4127     # Call the command subroutine, call it by name.
4128     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4129 } ## end sub cmd_wrapper
4130
4131 =head3 C<cmd_a> (command)
4132
4133 The C<a> command handles pre-execution actions. These are associated with a
4134 particular line, so they're stored in C<%dbline>. We default to the current
4135 line if none is specified.
4136
4137 =cut
4138
4139 sub cmd_a {
4140     my $cmd    = shift;
4141     my $line   = shift || '';    # [.|line] expr
4142     my $dbline = shift;
4143
4144     # If it's dot (here), or not all digits,  use the current line.
4145     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4146
4147     # Should be a line number followed by an expression.
4148     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4149         my ( $lineno, $expr ) = ( $1, $2 );
4150
4151         # If we have an expression ...
4152         if ( length $expr ) {
4153
4154             # ... but the line isn't breakable, complain.
4155             if ( $dbline[$lineno] == 0 ) {
4156                 print $OUT
4157                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4158             }
4159             else {
4160
4161                 # It's executable. Record that the line has an action.
4162                 $had_breakpoints{$filename} |= 2;
4163
4164                 # Remove any action, temp breakpoint, etc.
4165                 $dbline{$lineno} =~ s/\0[^\0]*//;
4166
4167                 # Add the action to the line.
4168                 $dbline{$lineno} .= "\0" . action($expr);
4169
4170                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4171             }
4172         } ## end if (length $expr)
4173     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4174     else {
4175
4176         # Syntax wrong.
4177         print $OUT
4178           "Adding an action requires an optional lineno and an expression\n"
4179           ;    # hint
4180     }
4181 } ## end sub cmd_a
4182
4183 =head3 C<cmd_A> (command)
4184
4185 Delete actions. Similar to above, except the delete code is in a separate
4186 subroutine, C<delete_action>.
4187
4188 =cut
4189
4190 sub cmd_A {
4191     my $cmd    = shift;
4192     my $line   = shift || '';
4193     my $dbline = shift;
4194
4195     # Dot is this line.
4196     $line =~ s/^\./$dbline/;
4197
4198     # Call delete_action with a null param to delete them all.
4199     # The '1' forces the eval to be true. It'll be false only
4200     # if delete_action blows up for some reason, in which case
4201     # we print $@ and get out.
4202     if ( $line eq '*' ) {
4203         if (! eval { _delete_all_actions(); 1 }) {
4204             print {$OUT} $@;
4205             return;
4206         }
4207     }
4208
4209     # There's a real line  number. Pass it to delete_action.
4210     # Error trapping is as above.
4211     elsif ( $line =~ /^(\S.*)/ ) {
4212         if (! eval { delete_action($1); 1 }) {
4213             print {$OUT} $@;
4214             return;
4215         }
4216     }
4217
4218     # Swing and a miss. Bad syntax.
4219     else {
4220         print $OUT
4221           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4222     }
4223 } ## end sub cmd_A
4224
4225 =head3 C<delete_action> (API)
4226
4227 C<delete_action> accepts either a line number or C<undef>. If a line number
4228 is specified, we check for the line being executable (if it's not, it
4229 couldn't have had an  action). If it is, we just take the action off (this
4230 will get any kind of an action, including breakpoints).
4231
4232 =cut
4233
4234 sub _remove_action_from_dbline {
4235     my $i = shift;
4236
4237     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4238     delete $dbline{$i} if $dbline{$i} eq '';
4239
4240     return;
4241 }
4242
4243 sub _delete_all_actions {
4244     print {$OUT} "Deleting all actions...\n";
4245
4246     for my $file ( keys %had_breakpoints ) {
4247         local *dbline = $main::{ '_<' . $file };
4248         $max = $#dbline;
4249         my $was;
4250         for my $i (1 .. $max) {
4251             if ( defined $dbline{$i} ) {
4252                 _remove_action_from_dbline($i);
4253             }
4254         }
4255
4256         unless ( $had_breakpoints{$file} &= ~2 ) {
4257             delete $had_breakpoints{$file};
4258         }
4259     }
4260
4261     return;
4262 }
4263
4264 sub delete_action {
4265     my $i = shift;
4266
4267     if ( defined($i) ) {
4268         # Can there be one?
4269         die "Line $i has no action .\n" if $dbline[$i] == 0;
4270
4271         # Nuke whatever's there.
4272         _remove_action_from_dbline($i);
4273     }
4274     else {
4275         _delete_all_actions();
4276     }
4277 }
4278
4279 =head3 C<cmd_b> (command)
4280
4281 Set breakpoints. Since breakpoints can be set in so many places, in so many
4282 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4283 we try to parse the command type, and then shuttle it off to an appropriate
4284 subroutine to actually do the work of setting the breakpoint in the right
4285 place.
4286
4287 =cut
4288
4289 sub cmd_b {
4290     my $cmd    = shift;
4291     my $line   = shift;    # [.|line] [cond]
4292     my $dbline = shift;
4293
4294     my $default_cond = sub {
4295         my $cond = shift;
4296         return length($cond) ? $cond : '1';
4297     };
4298
4299     # Make . the current line number if it's there..
4300     $line =~ s/^\.(\s|\z)/$dbline$1/;
4301
4302     # No line number, no condition. Simple break on current line.
4303     if ( $line =~ /^\s*$/ ) {
4304         cmd_b_line( $dbline, 1 );
4305     }
4306
4307     # Break on load for a file.
4308     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4309         $file =~ s/\s+\z//;
4310         cmd_b_load($file);
4311     }
4312
4313     # b compile|postpone <some sub> [<condition>]
4314     # The interpreter actually traps this one for us; we just put the
4315     # necessary condition in the %postponed hash.
4316     elsif ( my ($action, $subname, $cond)
4317         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4318
4319         # De-Perl4-ify the name - ' separators to ::.
4320         $subname =~ s/'/::/g;
4321
4322         # Qualify it into the current package unless it's already qualified.
4323         $subname = "${package}::" . $subname unless $subname =~ /::/;
4324
4325         # Add main if it starts with ::.
4326         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4327
4328         # Save the break type for this sub.
4329         $postponed{$subname} = (($action eq 'postpone')
4330             ? ( "break +0 if " . $default_cond->($cond) )
4331             : "compile");
4332     } ## end elsif ($line =~ ...
4333     # b <filename>:<line> [<condition>]
4334     elsif (my ($filename, $line_num, $cond)
4335         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4336         cmd_b_filename_line(
4337             $filename,
4338             $line_num,
4339             (length($cond) ? $cond : '1'),
4340         );
4341     }
4342     # b <sub name> [<condition>]
4343     elsif ( my ($new_subname, $new_cond) =
4344         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4345
4346         #
4347         $subname = $new_subname;
4348         cmd_b_sub( $subname, $default_cond->($new_cond) );
4349     }
4350
4351     # b <line> [<condition>].
4352     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4353
4354         # Capture the line. If none, it's the current line.
4355         $line = $line_n || $dbline;
4356
4357         # Break on line.
4358         cmd_b_line( $line, $default_cond->($cond) );
4359     }
4360
4361     # Line didn't make sense.
4362     else {
4363         print "confused by line($line)?\n";
4364     }
4365
4366     return;
4367 } ## end sub cmd_b
4368
4369 =head3 C<break_on_load> (API)
4370
4371 We want to break when this file is loaded. Mark this file in the
4372 C<%break_on_load> hash, and note that it has a breakpoint in
4373 C<%had_breakpoints>.
4374
4375 =cut
4376
4377 sub break_on_load {
4378     my $file = shift;
4379     $break_on_load{$file} = 1;
4380     $had_breakpoints{$file} |= 1;
4381 }
4382
4383 =head3 C<report_break_on_load> (API)
4384
4385 Gives us an array of filenames that are set to break on load. Note that
4386 only files with break-on-load are in here, so simply showing the keys
4387 suffices.
4388
4389 =cut
4390
4391 sub report_break_on_load {
4392     sort keys %break_on_load;
4393 }
4394
4395 =head3 C<cmd_b_load> (command)
4396
4397 We take the file passed in and try to find it in C<%INC> (which maps modules
4398 to files they came from). We mark those files for break-on-load via
4399 C<break_on_load> and then report that it was done.
4400
4401 =cut
4402
4403 sub cmd_b_load {
4404     my $file = shift;
4405     my @files;
4406
4407     # This is a block because that way we can use a redo inside it
4408     # even without there being any looping structure at all outside it.
4409     {
4410
4411         # Save short name and full path if found.
4412         push @files, $file;
4413         push @files, $::INC{$file} if $::INC{$file};
4414
4415         # Tack on .pm and do it again unless there was a '.' in the name
4416         # already.
4417         $file .= '.pm', redo unless $file =~ /\./;
4418     }
4419
4420     # Do the real work here.
4421     break_on_load($_) for @files;
4422
4423     # All the files that have break-on-load breakpoints.
4424     @files = report_break_on_load;
4425
4426     # Normalize for the purposes of our printing this.
4427     local $\ = '';
4428     local $" = ' ';
4429     print $OUT "Will stop on load of '@files'.\n";
4430 } ## end sub cmd_b_load
4431
4432 =head3 C<$filename_error> (API package global)
4433
4434 Several of the functions we need to implement in the API need to work both
4435 on the current file and on other files. We don't want to duplicate code, so
4436 C<$filename_error> is used to contain the name of the file that's being
4437 worked on (if it's not the current one).
4438
4439 We can now build functions in pairs: the basic function works on the current
4440 file, and uses C<$filename_error> as part of its error message. Since this is
4441 initialized to C<"">, no filename will appear when we are working on the
4442 current file.
4443
4444 The second function is a wrapper which does the following:
4445
4446 =over 4
4447
4448 =item *
4449
4450 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4451
4452 =item *
4453
4454 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4455
4456 =item *
4457
4458 Calls the first function.
4459
4460 The first function works on the I<current> file (i.e., the one we changed to),
4461 and prints C<$filename_error> in the error message (the name of the other file)
4462 if it needs to. When the functions return, C<*dbline> is restored to point
4463 to the actual current file (the one we're executing in) and
4464 C<$filename_error> is restored to C<"">. This restores everything to
4465 the way it was before the second function was called at all.
4466
4467 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4468 details.
4469
4470 =back
4471
4472 =cut
4473
4474 use vars qw($filename_error);
4475 $filename_error = '';
4476
4477 =head3 breakable_line(from, to) (API)
4478
4479 The subroutine decides whether or not a line in the current file is breakable.
4480 It walks through C<@dbline> within the range of lines specified, looking for
4481 the first line that is breakable.
4482
4483 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4484 first line I<after> C<$to> that's breakable, if there is one.
4485
4486 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4487 first line I<before> C<$to> that's breakable, if there is one.
4488
4489 =cut
4490
4491 sub breakable_line {
4492
4493     my ( $from, $to ) = @_;
4494
4495     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4496     my $i = $from;
4497
4498     # If there are at least 2 arguments, we're trying to search a range.
4499     if ( @_ >= 2 ) {
4500
4501         # $delta is positive for a forward search, negative for a backward one.
4502         my $delta = $from < $to ? +1 : -1;
4503
4504         # Keep us from running off the ends of the file.
4505         my $limit = $delta > 0 ? $#dbline : 1;
4506
4507         # Clever test. If you're a mathematician, it's obvious why this
4508         # test works. If not:
4509         # If $delta is positive (going forward), $limit will be $#dbline.
4510         #    If $to is less than $limit, ($limit - $to) will be positive, times
4511         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4512         #    as the stopping point.
4513         #
4514         #    If $to is greater than $limit, ($limit - $to) is negative,
4515         #    times $delta of 1 (positive), so the result is < 0 and we should
4516         #    use $limit ($#dbline) as the stopping point.
4517         #
4518         # If $delta is negative (going backward), $limit will be 1.
4519         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4520         #    (negative) so the result is > 0, and we use $to as the stopping
4521         #    point.
4522         #
4523         #    If $to is less than zero, ($limit - $to) will be positive,
4524         #    times $delta of -1 (negative), so the result is not > 0, and
4525         #    we use $limit (1) as the stopping point.
4526         #
4527         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4528         #    (negative), still giving zero; the result is not > 0, and
4529         #    we use $limit (1) as the stopping point.
4530         #
4531         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4532         #    (negative), giving a positive (>0) value, so we'll set $limit to
4533         #    $to.
4534
4535         $limit = $to if ( $limit - $to ) * $delta > 0;
4536
4537         # The real search loop.
4538         # $i starts at $from (the point we want to start searching from).
4539         # We move through @dbline in the appropriate direction (determined
4540         # by $delta: either -1 (back) or +1 (ahead).
4541         # We stay in as long as we haven't hit an executable line
4542         # ($dbline[$i] == 0 means not executable) and we haven't reached
4543         # the limit yet (test similar to the above).
4544         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4545
4546     } ## end if (@_ >= 2)
4547
4548     # If $i points to a line that is executable, return that.
4549     return $i unless $dbline[$i] == 0;
4550
4551     # Format the message and print it: no breakable lines in range.
4552     my ( $pl, $upto ) = ( '', '' );
4553     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4554
4555     # If there's a filename in filename_error, we'll see it.
4556     # If not, not.
4557     die "Line$pl $from$upto$filename_error not breakable\n";
4558 } ## end sub breakable_line
4559
4560 =head3 breakable_line_in_filename(file, from, to) (API)