This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Fix up runtime regex codeblocks.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME 
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator 
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.       
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a 
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the 
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the 
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>, 
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep 
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on 
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern 
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/      
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0 
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1 
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1 
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0 
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant 
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar. 
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be 
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a 
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do 
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the 
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually 
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in 
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial. 
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core 
156 smack in the middle of the interpreter's execution loop. It's much faster for 
157 a C program (like the interpreter) to check a bit in a scalar than to access 
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of 
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE         
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob 
183 assignment) contains breakpoints and actions.  The keys are line numbers; 
184 you can set individual values, but not the whole hash. The Perl interpreter 
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has 
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its 
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY 
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY 
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine 
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop 
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo 
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort 
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input. 
283
284 =over   
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited. 
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many 
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger 
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4 
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information. 
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> , 
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4 
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course 
491 execute immediately) spread through the code. Why is that? 
492
493 The debugger needs to be able to change some things and set some things up 
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value. 
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
514
515 BEGIN {
516     require feature;
517     $^V =~ /^v(\d+\.\d+)/;
518     feature->import(":$1");
519 }
520
521 # Debugger for Perl 5.00x; perl5db.pl patch level:
522 $VERSION = '1.38';
523
524 $header = "perl5db.pl version $VERSION";
525
526 =head1 DEBUGGER ROUTINES
527
528 =head2 C<DB::eval()>
529
530 This function replaces straight C<eval()> inside the debugger; it simplifies
531 the process of evaluating code in the user's context.
532
533 The code to be evaluated is passed via the package global variable 
534 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
535
536 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
537 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
538 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
539 user's current package, grabbed when C<DB::DB> got control.  This causes the
540 proper context to be used when the eval is actually done.  Afterward, we
541 restore C<$trace>, C<$single>, and C<$^D>.
542
543 Next we need to handle C<$@> without getting confused. We save C<$@> in a
544 local lexical, localize C<$saved[0]> (which is where C<save()> will put 
545 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>, 
546 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
547 considered sane by the debugger. If there was an C<eval()> error, we print 
548 it on the debugger's output. If C<$onetimedump> is defined, we call 
549 C<dumpit> if it's set to 'dump', or C<methods> if it's set to 
550 'methods'. Setting it to something else causes the debugger to do the eval 
551 but not print the result - handy if you want to do something else with it 
552 (the "watch expressions" code does this to get the value of the watch
553 expression but not show it unless it matters).
554
555 In any case, we then return the list of output from C<eval> to the caller, 
556 and unwinding restores the former version of C<$@> in C<@saved> as well 
557 (the localization of C<$saved[0]> goes away at the end of this scope).
558
559 =head3 Parameters and variables influencing execution of DB::eval()
560
561 C<DB::eval> isn't parameterized in the standard way; this is to keep the
562 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
563 The variables listed below influence C<DB::eval()>'s execution directly. 
564
565 =over 4
566
567 =item C<$evalarg> - the thing to actually be eval'ed
568
569 =item C<$trace> - Current state of execution tracing
570
571 =item C<$single> - Current state of single-stepping
572
573 =item C<$onetimeDump> - what is to be displayed after the evaluation 
574
575 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
576
577 =back
578
579 The following variables are altered by C<DB::eval()> during its execution. They
580 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>. 
581
582 =over 4
583
584 =item C<@res> - used to capture output from actual C<eval>.
585
586 =item C<$otrace> - saved value of C<$trace>.
587
588 =item C<$osingle> - saved value of C<$single>.      
589
590 =item C<$od> - saved value of C<$^D>.
591
592 =item C<$saved[0]> - saved value of C<$@>.
593
594 =item $\ - for output of C<$@> if there is an evaluation error.      
595
596 =back
597
598 =head3 The problem of lexicals
599
600 The context of C<DB::eval()> presents us with some problems. Obviously,
601 we want to be 'sandboxed' away from the debugger's internals when we do
602 the eval, but we need some way to control how punctuation variables and
603 debugger globals are used. 
604
605 We can't use local, because the code inside C<DB::eval> can see localized
606 variables; and we can't use C<my> either for the same reason. The code
607 in this routine compromises and uses C<my>.
608
609 After this routine is over, we don't have user code executing in the debugger's
610 context, so we can use C<my> freely.
611
612 =cut
613
614 ############################################## Begin lexical danger zone
615
616 # 'my' variables used here could leak into (that is, be visible in)
617 # the context that the code being evaluated is executing in. This means that
618 # the code could modify the debugger's variables.
619 #
620 # Fiddling with the debugger's context could be Bad. We insulate things as
621 # much as we can.
622
623 sub eval {
624
625     # 'my' would make it visible from user code
626     #    but so does local! --tchrist
627     # Remember: this localizes @DB::res, not @main::res.
628     local @res;
629     {
630
631         # Try to keep the user code from messing  with us. Save these so that
632         # even if the eval'ed code changes them, we can put them back again.
633         # Needed because the user could refer directly to the debugger's
634         # package globals (and any 'my' variables in this containing scope)
635         # inside the eval(), and we want to try to stay safe.
636         local $otrace  = $trace;
637         local $osingle = $single;
638         local $od      = $^D;
639
640         # Untaint the incoming eval() argument.
641         { ($evalarg) = $evalarg =~ /(.*)/s; }
642
643         # $usercontext built in DB::DB near the comment
644         # "set up the context for DB::eval ..."
645         # Evaluate and save any results.
646         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
647
648         # Restore those old values.
649         $trace  = $otrace;
650         $single = $osingle;
651         $^D     = $od;
652     }
653
654     # Save the current value of $@, and preserve it in the debugger's copy
655     # of the saved precious globals.
656     my $at = $@;
657
658     # Since we're only saving $@, we only have to localize the array element
659     # that it will be stored in.
660     local $saved[0];    # Preserve the old value of $@
661     eval { &DB::save };
662
663     # Now see whether we need to report an error back to the user.
664     if ($at) {
665         local $\ = '';
666         print $OUT $at;
667     }
668
669     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
670     # are package globals.
671     elsif ($onetimeDump) {
672         if ( $onetimeDump eq 'dump' ) {
673             local $option{dumpDepth} = $onetimedumpDepth
674               if defined $onetimedumpDepth;
675             dumpit( $OUT, \@res );
676         }
677         elsif ( $onetimeDump eq 'methods' ) {
678             methods( $res[0] );
679         }
680     } ## end elsif ($onetimeDump)
681     @res;
682 } ## end sub eval
683
684 ############################################## End lexical danger zone
685
686 # After this point it is safe to introduce lexicals.
687 # The code being debugged will be executing in its own context, and
688 # can't see the inside of the debugger.
689 #
690 # However, one should not overdo it: leave as much control from outside as
691 # possible. If you make something a lexical, it's not going to be addressable
692 # from outside the debugger even if you know its name.
693
694 # This file is automatically included if you do perl -d.
695 # It's probably not useful to include this yourself.
696 #
697 # Before venturing further into these twisty passages, it is
698 # wise to read the perldebguts man page or risk the ire of dragons.
699 #
700 # (It should be noted that perldebguts will tell you a lot about
701 # the underlying mechanics of how the debugger interfaces into the
702 # Perl interpreter, but not a lot about the debugger itself. The new
703 # comments in this code try to address this problem.)
704
705 # Note that no subroutine call is possible until &DB::sub is defined
706 # (for subroutines defined outside of the package DB). In fact the same is
707 # true if $deep is not defined.
708
709 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
710
711 # modified Perl debugger, to be run from Emacs in perldb-mode
712 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
713 # Johan Vromans -- upgrade to 4.0 pl 10
714 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
715 ########################################################################
716
717 =head1 DEBUGGER INITIALIZATION
718
719 The debugger starts up in phases.
720
721 =head2 BASIC SETUP
722
723 First, it initializes the environment it wants to run in: turning off
724 warnings during its own compilation, defining variables which it will need
725 to avoid warnings later, setting itself up to not exit when the program
726 terminates, and defaulting to printing return values for the C<r> command.
727
728 =cut
729
730 # Needed for the statement after exec():
731 #
732 # This BEGIN block is simply used to switch off warnings during debugger
733 # compilation. Probably it would be better practice to fix the warnings,
734 # but this is how it's done at the moment.
735
736 BEGIN {
737     $ini_warn = $^W;
738     $^W       = 0;
739 }    # Switch compilation warnings off until another BEGIN.
740
741 local ($^W) = 0;    # Switch run-time warnings off during init.
742
743 =head2 THREADS SUPPORT
744
745 If we are running under a threaded Perl, we require threads and threads::shared
746 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
747 threaded debugger control.  C<-dt> can also be used to set this.
748
749 Each new thread will be announced and the debugger prompt will always inform
750 you of each new thread created.  It will also indicate the thread id in which
751 we are currently running within the prompt like this:
752
753         [tid] DB<$i>
754
755 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
756 command prompt.  The prompt will show: C<[0]> when running under threads, but
757 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
758
759 While running under threads, when you set or delete a breakpoint (etc.), this
760 will apply to all threads, not just the currently running one.  When you are 
761 in a currently executing thread, you will stay there until it completes.  With
762 the current implementation it is not currently possible to hop from one thread
763 to another.
764
765 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
766
767 Note that threading support was built into the debugger as of Perl version
768 C<5.8.6> and debugger version C<1.2.8>.
769
770 =cut
771
772 BEGIN {
773   # ensure we can share our non-threaded variables or no-op
774   if ($ENV{PERL5DB_THREADED}) {
775         require threads;
776         require threads::shared;
777         import threads::shared qw(share);
778         $DBGR;
779         share(\$DBGR);
780         lock($DBGR);
781         print "Threads support enabled\n";
782   } else {
783         *lock  = sub(*) {};
784         *share = sub(*) {};
785   }
786 }
787
788 # This would probably be better done with "use vars", but that wasn't around
789 # when this code was originally written. (Neither was "use strict".) And on
790 # the principle of not fiddling with something that was working, this was
791 # left alone.
792 warn(               # Do not ;-)
793     # These variables control the execution of 'dumpvar.pl'.
794     $dumpvar::hashDepth,
795     $dumpvar::arrayDepth,
796     $dumpvar::dumpDBFiles,
797     $dumpvar::dumpPackages,
798     $dumpvar::quoteHighBit,
799     $dumpvar::printUndef,
800     $dumpvar::globPrint,
801     $dumpvar::usageOnly,
802
803     # used to save @ARGV and extract any debugger-related flags.
804     @ARGS,
805
806     # used to control die() reporting in diesignal()
807     $Carp::CarpLevel,
808
809     # used to prevent multiple entries to diesignal()
810     # (if for instance diesignal() itself dies)
811     $panic,
812
813     # used to prevent the debugger from running nonstop
814     # after a restart
815     $second_time,
816   )
817   if 0;
818
819 # without threads, $filename is not defined until DB::DB is called
820 foreach my $k (keys (%INC)) {
821         &share(\$main::{'_<'.$filename}) if defined $filename;
822 };
823
824 # Command-line + PERLLIB:
825 # Save the contents of @INC before they are modified elsewhere.
826 @ini_INC = @INC;
827
828 # This was an attempt to clear out the previous values of various
829 # trapped errors. Apparently it didn't help. XXX More info needed!
830 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
831
832 # We set these variables to safe values. We don't want to blindly turn
833 # off warnings, because other packages may still want them.
834 $trace = $signal = $single = 0;    # Uninitialized warning suppression
835                                    # (local $^W cannot help - other packages!).
836
837 # Default to not exiting when program finishes; print the return
838 # value when the 'r' command is used to return from a subroutine.
839 $inhibit_exit = $option{PrintRet} = 1;
840
841 # Default to 1 so the prompt will display the first line.
842 $trace_to_depth = 1;
843
844 =head1 OPTION PROCESSING
845
846 The debugger's options are actually spread out over the debugger itself and 
847 C<dumpvar.pl>; some of these are variables to be set, while others are 
848 subs to be called with a value. To try to make this a little easier to
849 manage, the debugger uses a few data structures to define what options
850 are legal and how they are to be processed.
851
852 First, the C<@options> array defines the I<names> of all the options that
853 are to be accepted.
854
855 =cut
856
857 @options = qw(
858   CommandSet   HistFile      HistSize
859   hashDepth    arrayDepth    dumpDepth
860   DumpDBFiles  DumpPackages  DumpReused
861   compactDump  veryCompact   quote
862   HighBit      undefPrint    globPrint
863   PrintRet     UsageOnly     frame
864   AutoTrace    TTY           noTTY
865   ReadLine     NonStop       LineInfo
866   maxTraceLen  recallCommand ShellBang
867   pager        tkRunning     ornaments
868   signalLevel  warnLevel     dieLevel
869   inhibit_exit ImmediateStop bareStringify
870   CreateTTY    RemotePort    windowSize
871   DollarCaretP
872 );
873
874 @RememberOnROptions = qw(DollarCaretP);
875
876 =pod
877
878 Second, C<optionVars> lists the variables that each option uses to save its
879 state.
880
881 =cut
882
883 %optionVars = (
884     hashDepth     => \$dumpvar::hashDepth,
885     arrayDepth    => \$dumpvar::arrayDepth,
886     CommandSet    => \$CommandSet,
887     DumpDBFiles   => \$dumpvar::dumpDBFiles,
888     DumpPackages  => \$dumpvar::dumpPackages,
889     DumpReused    => \$dumpvar::dumpReused,
890     HighBit       => \$dumpvar::quoteHighBit,
891     undefPrint    => \$dumpvar::printUndef,
892     globPrint     => \$dumpvar::globPrint,
893     UsageOnly     => \$dumpvar::usageOnly,
894     CreateTTY     => \$CreateTTY,
895     bareStringify => \$dumpvar::bareStringify,
896     frame         => \$frame,
897     AutoTrace     => \$trace,
898     inhibit_exit  => \$inhibit_exit,
899     maxTraceLen   => \$maxtrace,
900     ImmediateStop => \$ImmediateStop,
901     RemotePort    => \$remoteport,
902     windowSize    => \$window,
903     HistFile      => \$histfile,
904     HistSize      => \$histsize,
905 );
906
907 =pod
908
909 Third, C<%optionAction> defines the subroutine to be called to process each
910 option.
911
912 =cut 
913
914 %optionAction = (
915     compactDump   => \&dumpvar::compactDump,
916     veryCompact   => \&dumpvar::veryCompact,
917     quote         => \&dumpvar::quote,
918     TTY           => \&TTY,
919     noTTY         => \&noTTY,
920     ReadLine      => \&ReadLine,
921     NonStop       => \&NonStop,
922     LineInfo      => \&LineInfo,
923     recallCommand => \&recallCommand,
924     ShellBang     => \&shellBang,
925     pager         => \&pager,
926     signalLevel   => \&signalLevel,
927     warnLevel     => \&warnLevel,
928     dieLevel      => \&dieLevel,
929     tkRunning     => \&tkRunning,
930     ornaments     => \&ornaments,
931     RemotePort    => \&RemotePort,
932     DollarCaretP  => \&DollarCaretP,
933 );
934
935 =pod
936
937 Last, the C<%optionRequire> notes modules that must be C<require>d if an
938 option is used.
939
940 =cut
941
942 # Note that this list is not complete: several options not listed here
943 # actually require that dumpvar.pl be loaded for them to work, but are
944 # not in the table. A subsequent patch will correct this problem; for
945 # the moment, we're just recommenting, and we are NOT going to change
946 # function.
947 %optionRequire = (
948     compactDump => 'dumpvar.pl',
949     veryCompact => 'dumpvar.pl',
950     quote       => 'dumpvar.pl',
951 );
952
953 =pod
954
955 There are a number of initialization-related variables which can be set
956 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
957 variable. These are:
958
959 =over 4
960
961 =item C<$rl> - readline control XXX needs more explanation
962
963 =item C<$warnLevel> - whether or not debugger takes over warning handling
964
965 =item C<$dieLevel> - whether or not debugger takes over die handling
966
967 =item C<$signalLevel> - whether or not debugger takes over signal handling
968
969 =item C<$pre> - preprompt actions (array reference)
970
971 =item C<$post> - postprompt actions (array reference)
972
973 =item C<$pretype>
974
975 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
976
977 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
978
979 =back
980
981 =cut
982
983 # These guys may be defined in $ENV{PERL5DB} :
984 $rl          = 1     unless defined $rl;
985 $warnLevel   = 1     unless defined $warnLevel;
986 $dieLevel    = 1     unless defined $dieLevel;
987 $signalLevel = 1     unless defined $signalLevel;
988 $pre         = []    unless defined $pre;
989 $post        = []    unless defined $post;
990 $pretype     = []    unless defined $pretype;
991 $CreateTTY   = 3     unless defined $CreateTTY;
992 $CommandSet  = '580' unless defined $CommandSet;
993
994 share($rl);
995 share($warnLevel);
996 share($dieLevel);
997 share($signalLevel);
998 share($pre);
999 share($post);
1000 share($pretype);
1001 share($rl);
1002 share($CreateTTY);
1003 share($CommandSet);
1004
1005 =pod
1006
1007 The default C<die>, C<warn>, and C<signal> handlers are set up.
1008
1009 =cut
1010
1011 warnLevel($warnLevel);
1012 dieLevel($dieLevel);
1013 signalLevel($signalLevel);
1014
1015 =pod
1016
1017 The pager to be used is needed next. We try to get it from the
1018 environment first.  If it's not defined there, we try to find it in
1019 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1020 then call the C<pager()> function to save the pager name.
1021
1022 =cut
1023
1024 # This routine makes sure $pager is set up so that '|' can use it.
1025 pager(
1026
1027     # If PAGER is defined in the environment, use it.
1028     defined $ENV{PAGER}
1029     ? $ENV{PAGER}
1030
1031       # If not, see if Config.pm defines it.
1032     : eval { require Config }
1033       && defined $Config::Config{pager}
1034     ? $Config::Config{pager}
1035
1036       # If not, fall back to 'more'.
1037     : 'more'
1038   )
1039   unless defined $pager;
1040
1041 =pod
1042
1043 We set up the command to be used to access the man pages, the command
1044 recall character (C<!> unless otherwise defined) and the shell escape
1045 character (C<!> unless otherwise defined). Yes, these do conflict, and
1046 neither works in the debugger at the moment.
1047
1048 =cut
1049
1050 setman();
1051
1052 # Set up defaults for command recall and shell escape (note:
1053 # these currently don't work in linemode debugging).
1054 &recallCommand("!") unless defined $prc;
1055 &shellBang("!")     unless defined $psh;
1056
1057 =pod
1058
1059 We then set up the gigantic string containing the debugger help.
1060 We also set the limit on the number of arguments we'll display during a
1061 trace.
1062
1063 =cut
1064
1065 sethelp();
1066
1067 # If we didn't get a default for the length of eval/stack trace args,
1068 # set it here.
1069 $maxtrace = 400 unless defined $maxtrace;
1070
1071 =head2 SETTING UP THE DEBUGGER GREETING
1072
1073 The debugger I<greeting> helps to inform the user how many debuggers are
1074 running, and whether the current debugger is the primary or a child.
1075
1076 If we are the primary, we just hang onto our pid so we'll have it when
1077 or if we start a child debugger. If we are a child, we'll set things up
1078 so we'll have a unique greeting and so the parent will give us our own
1079 TTY later.
1080
1081 We save the current contents of the C<PERLDB_PIDS> environment variable
1082 because we mess around with it. We'll also need to hang onto it because
1083 we'll need it if we restart.
1084
1085 Child debuggers make a label out of the current PID structure recorded in
1086 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1087 yet so the parent will give them one later via C<resetterm()>.
1088
1089 =cut
1090
1091 # Save the current contents of the environment; we're about to
1092 # much with it. We'll need this if we have to restart.
1093 $ini_pids = $ENV{PERLDB_PIDS};
1094
1095 if ( defined $ENV{PERLDB_PIDS} ) {
1096
1097     # We're a child. Make us a label out of the current PID structure
1098     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1099     # a term yet so the parent will give us one later via resetterm().
1100
1101     my $env_pids = $ENV{PERLDB_PIDS};
1102     $pids = "[$env_pids]";
1103
1104     # Unless we are on OpenVMS, all programs under the DCL shell run under
1105     # the same PID.
1106
1107     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1108         $term_pid         = $$;
1109     }
1110     else {
1111         $ENV{PERLDB_PIDS} .= "->$$";
1112         $term_pid = -1;
1113     }
1114
1115 } ## end if (defined $ENV{PERLDB_PIDS...
1116 else {
1117
1118     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1119     # child debugger, and mark us as the parent, so we'll know to set up
1120     # more TTY's is we have to.
1121     $ENV{PERLDB_PIDS} = "$$";
1122     $pids             = "[pid=$$]";
1123     $term_pid         = $$;
1124 }
1125
1126 $pidprompt = '';
1127
1128 # Sets up $emacs as a synonym for $slave_editor.
1129 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1130
1131 =head2 READING THE RC FILE
1132
1133 The debugger will read a file of initialization options if supplied. If    
1134 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1135
1136 =cut      
1137
1138 # As noted, this test really doesn't check accurately that the debugger
1139 # is running at a terminal or not.
1140
1141 my $dev_tty = '/dev/tty';
1142    $dev_tty = 'TT:' if ($^O eq 'VMS');
1143 if ( -e $dev_tty ) {                      # this is the wrong metric!
1144     $rcfile = ".perldb";
1145 }
1146 else {
1147     $rcfile = "perldb.ini";
1148 }
1149
1150 =pod
1151
1152 The debugger does a safety test of the file to be read. It must be owned
1153 either by the current user or root, and must only be writable by the owner.
1154
1155 =cut
1156
1157 # This wraps a safety test around "do" to read and evaluate the init file.
1158 #
1159 # This isn't really safe, because there's a race
1160 # between checking and opening.  The solution is to
1161 # open and fstat the handle, but then you have to read and
1162 # eval the contents.  But then the silly thing gets
1163 # your lexical scope, which is unfortunate at best.
1164 sub safe_do {
1165     my $file = shift;
1166
1167     # Just exactly what part of the word "CORE::" don't you understand?
1168     local $SIG{__WARN__};
1169     local $SIG{__DIE__};
1170
1171     unless ( is_safe_file($file) ) {
1172         CORE::warn <<EO_GRIPE;
1173 perldb: Must not source insecure rcfile $file.
1174         You or the superuser must be the owner, and it must not 
1175         be writable by anyone but its owner.
1176 EO_GRIPE
1177         return;
1178     } ## end unless (is_safe_file($file...
1179
1180     do $file;
1181     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1182 } ## end sub safe_do
1183
1184 # This is the safety test itself.
1185 #
1186 # Verifies that owner is either real user or superuser and that no
1187 # one but owner may write to it.  This function is of limited use
1188 # when called on a path instead of upon a handle, because there are
1189 # no guarantees that filename (by dirent) whose file (by ino) is
1190 # eventually accessed is the same as the one tested.
1191 # Assumes that the file's existence is not in doubt.
1192 sub is_safe_file {
1193     my $path = shift;
1194     stat($path) || return;    # mysteriously vaporized
1195     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1196
1197     return 0 if $uid != 0 && $uid != $<;
1198     return 0 if $mode & 022;
1199     return 1;
1200 } ## end sub is_safe_file
1201
1202 # If the rcfile (whichever one we decided was the right one to read)
1203 # exists, we safely do it.
1204 if ( -f $rcfile ) {
1205     safe_do("./$rcfile");
1206 }
1207
1208 # If there isn't one here, try the user's home directory.
1209 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1210     safe_do("$ENV{HOME}/$rcfile");
1211 }
1212
1213 # Else try the login directory.
1214 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1215     safe_do("$ENV{LOGDIR}/$rcfile");
1216 }
1217
1218 # If the PERLDB_OPTS variable has options in it, parse those out next.
1219 if ( defined $ENV{PERLDB_OPTS} ) {
1220     parse_options( $ENV{PERLDB_OPTS} );
1221 }
1222
1223 =pod
1224
1225 The last thing we do during initialization is determine which subroutine is
1226 to be used to obtain a new terminal when a new debugger is started. Right now,
1227 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1228 (darwin).
1229
1230 =cut
1231
1232 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1233 # Works if you're running an xterm or xterm-like window, or you're on
1234 # OS/2, or on Mac OS X. This may need some expansion.
1235
1236 if (not defined &get_fork_TTY)       # only if no routine exists
1237 {
1238     if ( defined $remoteport ) {                 
1239                                                  # Expect an inetd-like server
1240         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1241     }
1242     elsif (defined $ENV{TERM}                    # If we know what kind
1243                                                  # of terminal this is,
1244         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1245         and defined $ENV{DISPLAY}                # and what display it's on,
1246       )
1247     {
1248         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1249     }
1250     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1251         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1252     }
1253     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1254             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1255             and $ENV{TERM_PROGRAM}
1256                 eq 'Apple_Terminal'              # Terminal.app
1257             )
1258     {
1259         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1260     }
1261 } ## end if (not defined &get_fork_TTY...
1262
1263 # untaint $^O, which may have been tainted by the last statement.
1264 # see bug [perl #24674]
1265 $^O =~ m/^(.*)\z/;
1266 $^O = $1;
1267
1268 # Here begin the unreadable code.  It needs fixing.
1269
1270 =head2 RESTART PROCESSING
1271
1272 This section handles the restart command. When the C<R> command is invoked, it
1273 tries to capture all of the state it can into environment variables, and
1274 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1275 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1276 the R command stuffed into the environment variables.
1277
1278   PERLDB_RESTART   - flag only, contains no restart data itself.       
1279   PERLDB_HIST      - command history, if it's available
1280   PERLDB_ON_LOAD   - breakpoints set by the rc file
1281   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1282   PERLDB_VISITED   - files that had breakpoints
1283   PERLDB_FILE_...  - breakpoints for a file
1284   PERLDB_OPT       - active options
1285   PERLDB_INC       - the original @INC
1286   PERLDB_PRETYPE   - preprompt debugger actions
1287   PERLDB_PRE       - preprompt Perl code
1288   PERLDB_POST      - post-prompt Perl code
1289   PERLDB_TYPEAHEAD - typeahead captured by readline()
1290
1291 We chug through all these variables and plug the values saved in them
1292 back into the appropriate spots in the debugger.
1293
1294 =cut
1295
1296 if ( exists $ENV{PERLDB_RESTART} ) {
1297
1298     # We're restarting, so we don't need the flag that says to restart anymore.
1299     delete $ENV{PERLDB_RESTART};
1300
1301     # $restart = 1;
1302     @hist          = get_list('PERLDB_HIST');
1303     %break_on_load = get_list("PERLDB_ON_LOAD");
1304     %postponed     = get_list("PERLDB_POSTPONE");
1305
1306         share(@hist);
1307         share(@truehist);
1308         share(%break_on_load);
1309         share(%postponed);
1310
1311     # restore breakpoints/actions
1312     my @had_breakpoints = get_list("PERLDB_VISITED");
1313     for my $file_idx ( 0 .. $#had_breakpoints ) {
1314         my $filename = $had_breakpoints[$file_idx];
1315         my %pf = get_list("PERLDB_FILE_$file_idx");
1316         $postponed_file{ $filename } = \%pf if %pf;
1317         my @lines = sort {$a <=> $b} keys(%pf);
1318         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1319         for my $line_idx (0 .. $#lines) {
1320             _set_breakpoint_enabled_status(
1321                 $filename,
1322                 $lines[$line_idx],
1323                 ($enabled_statuses[$line_idx] ? 1 : ''),
1324             );
1325         }
1326     }
1327
1328     # restore options
1329     my %opt = get_list("PERLDB_OPT");
1330     my ( $opt, $val );
1331     while ( ( $opt, $val ) = each %opt ) {
1332         $val =~ s/[\\\']/\\$1/g;
1333         parse_options("$opt'$val'");
1334     }
1335
1336     # restore original @INC
1337     @INC     = get_list("PERLDB_INC");
1338     @ini_INC = @INC;
1339
1340     # return pre/postprompt actions and typeahead buffer
1341     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1342     $pre       = [ get_list("PERLDB_PRE") ];
1343     $post      = [ get_list("PERLDB_POST") ];
1344     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1345 } ## end if (exists $ENV{PERLDB_RESTART...
1346
1347 =head2 SETTING UP THE TERMINAL
1348
1349 Now, we'll decide how the debugger is going to interact with the user.
1350 If there's no TTY, we set the debugger to run non-stop; there's not going
1351 to be anyone there to enter commands.
1352
1353 =cut
1354
1355 if ($notty) {
1356     $runnonstop = 1;
1357         share($runnonstop);
1358 }
1359
1360 =pod
1361
1362 If there is a TTY, we have to determine who it belongs to before we can
1363 proceed. If this is a slave editor or graphical debugger (denoted by
1364 the first command-line switch being '-emacs'), we shift this off and
1365 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1366
1367 =cut
1368
1369 else {
1370
1371     # Is Perl being run from a slave editor or graphical debugger?
1372     # If so, don't use readline, and set $slave_editor = 1.
1373     $slave_editor =
1374       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1375     $rl = 0, shift(@main::ARGV) if $slave_editor;
1376
1377     #require Term::ReadLine;
1378
1379 =pod
1380
1381 We then determine what the console should be on various systems:
1382
1383 =over 4
1384
1385 =item * Cygwin - We use C<stdin> instead of a separate device.
1386
1387 =cut
1388
1389     if ( $^O eq 'cygwin' ) {
1390
1391         # /dev/tty is binary. use stdin for textmode
1392         undef $console;
1393     }
1394
1395 =item * Unix - use C</dev/tty>.
1396
1397 =cut
1398
1399     elsif ( -e "/dev/tty" ) {
1400         $console = "/dev/tty";
1401     }
1402
1403 =item * Windows or MSDOS - use C<con>.
1404
1405 =cut
1406
1407     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1408         $console = "con";
1409     }
1410
1411 =item * VMS - use C<sys$command>.
1412
1413 =cut
1414
1415     else {
1416
1417         # everything else is ...
1418         $console = "sys\$command";
1419     }
1420
1421 =pod
1422
1423 =back
1424
1425 Several other systems don't use a specific console. We C<undef $console>
1426 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1427 with a slave editor, Epoc).
1428
1429 =cut
1430
1431     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1432
1433         # /dev/tty is binary. use stdin for textmode
1434         $console = undef;
1435     }
1436
1437     if ( $^O eq 'NetWare' ) {
1438
1439         # /dev/tty is binary. use stdin for textmode
1440         $console = undef;
1441     }
1442
1443     # In OS/2, we need to use STDIN to get textmode too, even though
1444     # it pretty much looks like Unix otherwise.
1445     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1446     {    # In OS/2
1447         $console = undef;
1448     }
1449
1450     # EPOC also falls into the 'got to use STDIN' camp.
1451     if ( $^O eq 'epoc' ) {
1452         $console = undef;
1453     }
1454
1455 =pod
1456
1457 If there is a TTY hanging around from a parent, we use that as the console.
1458
1459 =cut
1460
1461     $console = $tty if defined $tty;
1462
1463 =head2 SOCKET HANDLING   
1464
1465 The debugger is capable of opening a socket and carrying out a debugging
1466 session over the socket.
1467
1468 If C<RemotePort> was defined in the options, the debugger assumes that it
1469 should try to start a debugging session on that port. It builds the socket
1470 and then tries to connect the input and output filehandles to it.
1471
1472 =cut
1473
1474     # Handle socket stuff.
1475
1476     if ( defined $remoteport ) {
1477
1478         # If RemotePort was defined in the options, connect input and output
1479         # to the socket.
1480         $IN = $OUT = connect_remoteport();
1481     } ## end if (defined $remoteport)
1482
1483 =pod
1484
1485 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1486 this is probably a situation where multiple debuggers are running (for example,
1487 a backticked command that starts up another debugger). We create a new IN and
1488 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1489 and if we can.
1490
1491 =cut
1492
1493     # Non-socket.
1494     else {
1495
1496         # Two debuggers running (probably a system or a backtick that invokes
1497         # the debugger itself under the running one). create a new IN and OUT
1498         # filehandle, and do the necessary mojo to create a new tty if we
1499         # know how, and we can.
1500         create_IN_OUT(4) if $CreateTTY & 4;
1501         if ($console) {
1502
1503             # If we have a console, check to see if there are separate ins and
1504             # outs to open. (They are assumed identical if not.)
1505
1506             my ( $i, $o ) = split /,/, $console;
1507             $o = $i unless defined $o;
1508
1509             # read/write on in, or just read, or read on STDIN.
1510             open( IN,      "+<$i" )
1511               || open( IN, "<$i" )
1512               || open( IN, "<&STDIN" );
1513
1514             # read/write/create/clobber out, or write/create/clobber out,
1515             # or merge with STDERR, or merge with STDOUT.
1516                  open( OUT, "+>$o" )
1517               || open( OUT, ">$o" )
1518               || open( OUT, ">&STDERR" )
1519               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1520
1521         } ## end if ($console)
1522         elsif ( not defined $console ) {
1523
1524             # No console. Open STDIN.
1525             open( IN, "<&STDIN" );
1526
1527             # merge with STDERR, or with STDOUT.
1528             open( OUT,      ">&STDERR" )
1529               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1530             $console = 'STDIN/OUT';
1531         } ## end elsif (not defined $console)
1532
1533         # Keep copies of the filehandles so that when the pager runs, it
1534         # can close standard input without clobbering ours.
1535         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1536     } ## end elsif (from if(defined $remoteport))
1537
1538     # Unbuffer DB::OUT. We need to see responses right away.
1539     my $previous = select($OUT);
1540     $| = 1;                                  # for DB::OUT
1541     select($previous);
1542
1543     # Line info goes to debugger output unless pointed elsewhere.
1544     # Pointing elsewhere makes it possible for slave editors to
1545     # keep track of file and position. We have both a filehandle
1546     # and a I/O description to keep track of.
1547     $LINEINFO = $OUT     unless defined $LINEINFO;
1548     $lineinfo = $console unless defined $lineinfo;
1549         # share($LINEINFO); # <- unable to share globs
1550         share($lineinfo);   # 
1551
1552 =pod
1553
1554 To finish initialization, we show the debugger greeting,
1555 and then call the C<afterinit()> subroutine if there is one.
1556
1557 =cut
1558
1559     # Show the debugger greeting.
1560     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1561     unless ($runnonstop) {
1562         local $\ = '';
1563         local $, = '';
1564         if ( $term_pid eq '-1' ) {
1565             print $OUT "\nDaughter DB session started...\n";
1566         }
1567         else {
1568             print $OUT "\nLoading DB routines from $header\n";
1569             print $OUT (
1570                 "Editor support ",
1571                 $slave_editor ? "enabled" : "available", ".\n"
1572             );
1573             print $OUT
1574 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1575         } ## end else [ if ($term_pid eq '-1')
1576     } ## end unless ($runnonstop)
1577 } ## end else [ if ($notty)
1578
1579 # XXX This looks like a bug to me.
1580 # Why copy to @ARGS and then futz with @args?
1581 @ARGS = @ARGV;
1582 for (@args) {
1583     # Make sure backslashes before single quotes are stripped out, and
1584     # keep args unless they are numeric (XXX why?)
1585     # s/\'/\\\'/g;                      # removed while not justified understandably
1586     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1587 }
1588
1589 # If there was an afterinit() sub defined, call it. It will get
1590 # executed in our scope, so it can fiddle with debugger globals.
1591 if ( defined &afterinit ) {    # May be defined in $rcfile
1592     &afterinit();
1593 }
1594
1595 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1596 $I_m_init = 1;
1597
1598 ############################################################ Subroutines
1599
1600 =head1 SUBROUTINES
1601
1602 =head2 DB
1603
1604 This gigantic subroutine is the heart of the debugger. Called before every
1605 statement, its job is to determine if a breakpoint has been reached, and
1606 stop if so; read commands from the user, parse them, and execute
1607 them, and then send execution off to the next statement.
1608
1609 Note that the order in which the commands are processed is very important;
1610 some commands earlier in the loop will actually alter the C<$cmd> variable
1611 to create other commands to be executed later. This is all highly I<optimized>
1612 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1613 see what's happening in any given command.
1614
1615 =cut
1616
1617 sub DB {
1618
1619     # lock the debugger and get the thread id for the prompt
1620         lock($DBGR);
1621         my $tid;
1622         if ($ENV{PERL5DB_THREADED}) {
1623                 $tid = eval { "[".threads->tid."]" };
1624         }
1625
1626     # Check for whether we should be running continuously or not.
1627     # _After_ the perl program is compiled, $single is set to 1:
1628     if ( $single and not $second_time++ ) {
1629
1630         # Options say run non-stop. Run until we get an interrupt.
1631         if ($runnonstop) {    # Disable until signal
1632                 # If there's any call stack in place, turn off single
1633                 # stepping into subs throughout the stack.
1634             for ( $i = 0 ; $i <= $stack_depth ; ) {
1635                 $stack[ $i++ ] &= ~1;
1636             }
1637
1638             # And we are now no longer in single-step mode.
1639             $single = 0;
1640
1641             # If we simply returned at this point, we wouldn't get
1642             # the trace info. Fall on through.
1643             # return;
1644         } ## end if ($runnonstop)
1645
1646         elsif ($ImmediateStop) {
1647
1648             # We are supposed to stop here; XXX probably a break.
1649             $ImmediateStop = 0;    # We've processed it; turn it off
1650             $signal        = 1;    # Simulate an interrupt to force
1651                                    # us into the command loop
1652         }
1653     } ## end if ($single and not $second_time...
1654
1655     # If we're in single-step mode, or an interrupt (real or fake)
1656     # has occurred, turn off non-stop mode.
1657     $runnonstop = 0 if $single or $signal;
1658
1659     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1660     # The code being debugged may have altered them.
1661     &save;
1662
1663     # Since DB::DB gets called after every line, we can use caller() to
1664     # figure out where we last were executing. Sneaky, eh? This works because
1665     # caller is returning all the extra information when called from the
1666     # debugger.
1667     local ( $package, $filename, $line ) = caller;
1668     local $filename_ini = $filename;
1669
1670     # set up the context for DB::eval, so it can properly execute
1671     # code on behalf of the user. We add the package in so that the
1672     # code is eval'ed in the proper package (not in the debugger!).
1673     local $usercontext =
1674       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1675
1676     # Create an alias to the active file magical array to simplify
1677     # the code here.
1678     local (*dbline) = $main::{ '_<' . $filename };
1679
1680     # Last line in the program.
1681     local $max = $#dbline;
1682
1683     # if we have something here, see if we should break.
1684     if ( $dbline{$line}
1685         && _is_breakpoint_enabled($filename, $line)
1686         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1687     {
1688
1689         # Stop if the stop criterion says to just stop.
1690         if ( $stop eq '1' ) {
1691             $signal |= 1;
1692         }
1693
1694         # It's a conditional stop; eval it in the user's context and
1695         # see if we should stop. If so, remove the one-time sigil.
1696         elsif ($stop) {
1697             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1698             &eval;
1699             # If the breakpoint is temporary, then delete its enabled status.
1700             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1701                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1702             }
1703         }
1704     } ## end if ($dbline{$line} && ...
1705
1706     # Preserve the current stop-or-not, and see if any of the W
1707     # (watch expressions) has changed.
1708     my $was_signal = $signal;
1709
1710     # If we have any watch expressions ...
1711     if ( $trace & 2 ) {
1712         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1713             $evalarg = $to_watch[$n];
1714             local $onetimeDump;    # Tell DB::eval() to not output results
1715
1716             # Fix context DB::eval() wants to return an array, but
1717             # we need a scalar here.
1718             my ($val) = join( "', '", &eval );
1719             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1720
1721             # Did it change?
1722             if ( $val ne $old_watch[$n] ) {
1723
1724                 # Yep! Show the difference, and fake an interrupt.
1725                 $signal = 1;
1726                 print $OUT <<EOP;
1727 Watchpoint $n:\t$to_watch[$n] changed:
1728     old value:\t$old_watch[$n]
1729     new value:\t$val
1730 EOP
1731                 $old_watch[$n] = $val;
1732             } ## end if ($val ne $old_watch...
1733         } ## end for (my $n = 0 ; $n <= ...
1734     } ## end if ($trace & 2)
1735
1736 =head2 C<watchfunction()>
1737
1738 C<watchfunction()> is a function that can be defined by the user; it is a
1739 function which will be run on each entry to C<DB::DB>; it gets the 
1740 current package, filename, and line as its parameters.
1741
1742 The watchfunction can do anything it likes; it is executing in the 
1743 debugger's context, so it has access to all of the debugger's internal
1744 data structures and functions.
1745
1746 C<watchfunction()> can control the debugger's actions. Any of the following
1747 will cause the debugger to return control to the user's program after
1748 C<watchfunction()> executes:
1749
1750 =over 4 
1751
1752 =item *
1753
1754 Returning a false value from the C<watchfunction()> itself.
1755
1756 =item *
1757
1758 Altering C<$single> to a false value.
1759
1760 =item *
1761
1762 Altering C<$signal> to a false value.
1763
1764 =item *
1765
1766 Turning off the C<4> bit in C<$trace> (this also disables the
1767 check for C<watchfunction()>. This can be done with
1768
1769     $trace &= ~4;
1770
1771 =back
1772
1773 =cut
1774
1775     # If there's a user-defined DB::watchfunction, call it with the
1776     # current package, filename, and line. The function executes in
1777     # the DB:: package.
1778     if ( $trace & 4 ) {    # User-installed watch
1779         return
1780           if watchfunction( $package, $filename, $line )
1781           and not $single
1782           and not $was_signal
1783           and not( $trace & ~4 );
1784     } ## end if ($trace & 4)
1785
1786     # Pick up any alteration to $signal in the watchfunction, and
1787     # turn off the signal now.
1788     $was_signal = $signal;
1789     $signal     = 0;
1790
1791 =head2 GETTING READY TO EXECUTE COMMANDS
1792
1793 The debugger decides to take control if single-step mode is on, the
1794 C<t> command was entered, or the user generated a signal. If the program
1795 has fallen off the end, we set things up so that entering further commands
1796 won't cause trouble, and we say that the program is over.
1797
1798 =cut
1799
1800     # Make sure that we always print if asked for explicitly regardless
1801     # of $trace_to_depth .
1802     my $explicit_stop = ($single || $was_signal);
1803
1804     # Check to see if we should grab control ($single true,
1805     # trace set appropriately, or we got a signal).
1806     if ( $explicit_stop || ( $trace & 1 ) ) {
1807
1808         # Yes, grab control.
1809         if ($slave_editor) {
1810
1811             # Tell the editor to update its position.
1812             $position = "\032\032$filename:$line:0\n";
1813             print_lineinfo($position);
1814         }
1815
1816 =pod
1817
1818 Special check: if we're in package C<DB::fake>, we've gone through the 
1819 C<END> block at least once. We set up everything so that we can continue
1820 to enter commands and have a valid context to be in.
1821
1822 =cut
1823
1824         elsif ( $package eq 'DB::fake' ) {
1825
1826             # Fallen off the end already.
1827             $term || &setterm;
1828             print_help(<<EOP);
1829 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1830   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1831   B<h q>, B<h R> or B<h o> to get additional info.  
1832 EOP
1833
1834             # Set the DB::eval context appropriately.
1835             $package     = 'main';
1836             $usercontext =
1837                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
1838               . "package $package;";    # this won't let them modify, alas
1839         } ## end elsif ($package eq 'DB::fake')
1840
1841 =pod
1842
1843 If the program hasn't finished executing, we scan forward to the
1844 next executable line, print that out, build the prompt from the file and line
1845 number information, and print that.   
1846
1847 =cut
1848
1849         else {
1850
1851
1852             # Still somewhere in the midst of execution. Set up the
1853             #  debugger prompt.
1854             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1855                                  # Perl 5 ones (sorry, we don't print Klingon
1856                                  #module names)
1857
1858             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
1859             $prefix .= "$sub($filename:";
1860             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1861
1862             # Break up the prompt if it's really long.
1863             if ( length($prefix) > 30 ) {
1864                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1865                 $prefix   = "";
1866                 $infix    = ":\t";
1867             }
1868             else {
1869                 $infix    = "):\t";
1870                 $position = "$prefix$line$infix$dbline[$line]$after";
1871             }
1872
1873             # Print current line info, indenting if necessary.
1874             if ($frame) {
1875                 print_lineinfo( ' ' x $stack_depth,
1876                     "$line:\t$dbline[$line]$after" );
1877             }
1878             else {
1879                 depth_print_lineinfo($explicit_stop, $position);
1880             }
1881
1882             # Scan forward, stopping at either the end or the next
1883             # unbreakable line.
1884             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
1885             {    #{ vi
1886
1887                 # Drop out on null statements, block closers, and comments.
1888                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
1889
1890                 # Drop out if the user interrupted us.
1891                 last if $signal;
1892
1893                 # Append a newline if the line doesn't have one. Can happen
1894                 # in eval'ed text, for instance.
1895                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
1896
1897                 # Next executable line.
1898                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
1899                 $position .= $incr_pos;
1900                 if ($frame) {
1901
1902                     # Print it indented if tracing is on.
1903                     print_lineinfo( ' ' x $stack_depth,
1904                         "$i:\t$dbline[$i]$after" );
1905                 }
1906                 else {
1907                     depth_print_lineinfo($explicit_stop, $incr_pos);
1908                 }
1909             } ## end for ($i = $line + 1 ; $i...
1910         } ## end else [ if ($slave_editor)
1911     } ## end if ($single || ($trace...
1912
1913 =pod
1914
1915 If there's an action to be executed for the line we stopped at, execute it.
1916 If there are any preprompt actions, execute those as well.      
1917
1918 =cut
1919
1920     # If there's an action, do it now.
1921     $evalarg = $action, &eval if $action;
1922
1923     # Are we nested another level (e.g., did we evaluate a function
1924     # that had a breakpoint in it at the debugger prompt)?
1925     if ( $single || $was_signal ) {
1926
1927         # Yes, go down a level.
1928         local $level = $level + 1;
1929
1930         # Do any pre-prompt actions.
1931         foreach $evalarg (@$pre) {
1932             &eval;
1933         }
1934
1935         # Complain about too much recursion if we passed the limit.
1936         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
1937           if $single & 4;
1938
1939         # The line we're currently on. Set $incr to -1 to stay here
1940         # until we get a command that tells us to advance.
1941         $start = $line;
1942         $incr  = -1;      # for backward motion.
1943
1944         # Tack preprompt debugger actions ahead of any actual input.
1945         @typeahead = ( @$pretype, @typeahead );
1946
1947 =head2 WHERE ARE WE?
1948
1949 XXX Relocate this section?
1950
1951 The debugger normally shows the line corresponding to the current line of
1952 execution. Sometimes, though, we want to see the next line, or to move elsewhere
1953 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
1954
1955 C<$incr> controls by how many lines the I<current> line should move forward
1956 after a command is executed. If set to -1, this indicates that the I<current>
1957 line shouldn't change.
1958
1959 C<$start> is the I<current> line. It is used for things like knowing where to
1960 move forwards or backwards from when doing an C<L> or C<-> command.
1961
1962 C<$max> tells the debugger where the last line of the current file is. It's
1963 used to terminate loops most often.
1964
1965 =head2 THE COMMAND LOOP
1966
1967 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
1968 in two parts:
1969
1970 =over 4
1971
1972 =item *
1973
1974 The outer part of the loop, starting at the C<CMD> label. This loop
1975 reads a command and then executes it.
1976
1977 =item *
1978
1979 The inner part of the loop, starting at the C<PIPE> label. This part
1980 is wholly contained inside the C<CMD> block and only executes a command.
1981 Used to handle commands running inside a pager.
1982
1983 =back
1984
1985 So why have two labels to restart the loop? Because sometimes, it's easier to
1986 have a command I<generate> another command and then re-execute the loop to do
1987 the new command. This is faster, but perhaps a bit more convoluted.
1988
1989 =cut
1990
1991         # The big command dispatch loop. It keeps running until the
1992         # user yields up control again.
1993         #
1994         # If we have a terminal for input, and we get something back
1995         # from readline(), keep on processing.
1996       CMD:
1997         while (
1998
1999             # We have a terminal, or can get one ...
2000             ( $term || &setterm ),
2001
2002             # ... and it belogs to this PID or we get one for this PID ...
2003             ( $term_pid == $$ or resetterm(1) ),
2004
2005             # ... and we got a line of command input ...
2006             defined(
2007                 $cmd = &readline(
2008                         "$pidprompt $tid DB"
2009                       . ( '<' x $level )
2010                       . ( $#hist + 1 )
2011                       . ( '>' x $level ) . " "
2012                 )
2013             )
2014           )
2015         {
2016
2017                         share($cmd);
2018             # ... try to execute the input as debugger commands.
2019
2020             # Don't stop running.
2021             $single = 0;
2022
2023             # No signal is active.
2024             $signal = 0;
2025
2026             # Handle continued commands (ending with \):
2027             $cmd =~ s/\\$/\n/ && do {
2028                 $cmd .= &readline("  cont: ");
2029                 redo CMD;
2030             };
2031
2032 =head4 The null command
2033
2034 A newline entered by itself means I<re-execute the last command>. We grab the
2035 command out of C<$laststep> (where it was recorded previously), and copy it
2036 back into C<$cmd> to be executed below. If there wasn't any previous command,
2037 we'll do nothing below (no command will match). If there was, we also save it
2038 in the command history and fall through to allow the command parsing to pick
2039 it up.
2040
2041 =cut
2042
2043             # Empty input means repeat the last command.
2044             $cmd =~ /^$/ && ( $cmd = $laststep );
2045             chomp($cmd);    # get rid of the annoying extra newline
2046             push( @hist, $cmd ) if length($cmd) > 1;
2047             push( @truehist, $cmd );
2048                         share(@hist);
2049                         share(@truehist);
2050
2051             # This is a restart point for commands that didn't arrive
2052             # via direct user input. It allows us to 'redo PIPE' to
2053             # re-execute command processing without reading a new command.
2054           PIPE: {
2055                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2056                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2057                 ($i) = split( /\s+/, $cmd );
2058
2059 =head3 COMMAND ALIASES
2060
2061 The debugger can create aliases for commands (these are stored in the
2062 C<%alias> hash). Before a command is executed, the command loop looks it up
2063 in the alias hash and substitutes the contents of the alias for the command,
2064 completely replacing it.
2065
2066 =cut
2067
2068                 # See if there's an alias for the command, and set it up if so.
2069                 if ( $alias{$i} ) {
2070
2071                     # Squelch signal handling; we want to keep control here
2072                     # if something goes loco during the alias eval.
2073                     local $SIG{__DIE__};
2074                     local $SIG{__WARN__};
2075
2076                     # This is a command, so we eval it in the DEBUGGER's
2077                     # scope! Otherwise, we can't see the special debugger
2078                     # variables, or get to the debugger's subs. (Well, we
2079                     # _could_, but why make it even more complicated?)
2080                     eval "\$cmd =~ $alias{$i}";
2081                     if ($@) {
2082                         local $\ = '';
2083                         print $OUT "Couldn't evaluate '$i' alias: $@";
2084                         next CMD;
2085                     }
2086                 } ## end if ($alias{$i})
2087
2088 =head3 MAIN-LINE COMMANDS
2089
2090 All of these commands work up to and after the program being debugged has
2091 terminated. 
2092
2093 =head4 C<q> - quit
2094
2095 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't 
2096 try to execute further, cleaning any restart-related stuff out of the
2097 environment, and executing with the last value of C<$?>.
2098
2099 =cut
2100
2101                 $cmd =~ /^q$/ && do {
2102                     $fall_off_end = 1;
2103                     clean_ENV();
2104                     exit $?;
2105                 };
2106
2107 =head4 C<t> - trace [n]
2108
2109 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2110 If level is specified, set C<$trace_to_depth>.
2111
2112 =cut
2113
2114                 $cmd =~ /^t(?:\s+(\d+))?$/ && do {
2115                     my $levels = $1;
2116                     $trace ^= 1;
2117                     local $\ = '';
2118                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2119                     print $OUT "Trace = "
2120                       . ( ( $trace & 1 )
2121                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2122                       : "off" ) . "\n";
2123                     next CMD;
2124                 };
2125
2126 =head4 C<S> - list subroutines matching/not matching a pattern
2127
2128 Walks through C<%sub>, checking to see whether or not to print the name.
2129
2130 =cut
2131
2132                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2133
2134                     $Srev     = defined $2;     # Reverse scan?
2135                     $Spatt    = $3;             # The pattern (if any) to use.
2136                     $Snocheck = !defined $1;    # No args - print all subs.
2137
2138                     # Need to make these sane here.
2139                     local $\ = '';
2140                     local $, = '';
2141
2142                     # Search through the debugger's magical hash of subs.
2143                     # If $nocheck is true, just print the sub name.
2144                     # Otherwise, check it against the pattern. We then use
2145                     # the XOR trick to reverse the condition as required.
2146                     foreach $subname ( sort( keys %sub ) ) {
2147                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2148                             print $OUT $subname, "\n";
2149                         }
2150                     }
2151                     next CMD;
2152                 };
2153
2154 =head4 C<X> - list variables in current package
2155
2156 Since the C<V> command actually processes this, just change this to the 
2157 appropriate C<V> command and fall through.
2158
2159 =cut
2160
2161                 $cmd =~ s/^X\b/V $package/;
2162
2163 =head4 C<V> - list variables
2164
2165 Uses C<dumpvar.pl> to dump out the current values for selected variables. 
2166
2167 =cut
2168
2169                 # Bare V commands get the currently-being-debugged package
2170                 # added.
2171                 $cmd =~ /^V$/ && do {
2172                     $cmd = "V $package";
2173                 };
2174
2175                 # V - show variables in package.
2176                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2177
2178                     # Save the currently selected filehandle and
2179                     # force output to debugger's filehandle (dumpvar
2180                     # just does "print" for output).
2181                     local ($savout) = select($OUT);
2182
2183                     # Grab package name and variables to dump.
2184                     $packname = $1;
2185                     @vars     = split( ' ', $2 );
2186
2187                     # If main::dumpvar isn't here, get it.
2188                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2189                     if ( defined &main::dumpvar ) {
2190
2191                         # We got it. Turn off subroutine entry/exit messages
2192                         # for the moment, along with return values.
2193                         local $frame = 0;
2194                         local $doret = -2;
2195
2196                         # must detect sigpipe failures  - not catching
2197                         # then will cause the debugger to die.
2198                         eval {
2199                             &main::dumpvar(
2200                                 $packname,
2201                                 defined $option{dumpDepth}
2202                                 ? $option{dumpDepth}
2203                                 : -1,    # assume -1 unless specified
2204                                 @vars
2205                             );
2206                         };
2207
2208                         # The die doesn't need to include the $@, because
2209                         # it will automatically get propagated for us.
2210                         if ($@) {
2211                             die unless $@ =~ /dumpvar print failed/;
2212                         }
2213                     } ## end if (defined &main::dumpvar)
2214                     else {
2215
2216                         # Couldn't load dumpvar.
2217                         print $OUT "dumpvar.pl not available.\n";
2218                     }
2219
2220                     # Restore the output filehandle, and go round again.
2221                     select($savout);
2222                     next CMD;
2223                 };
2224
2225 =head4 C<x> - evaluate and print an expression
2226
2227 Hands the expression off to C<DB::eval>, setting it up to print the value
2228 via C<dumpvar.pl> instead of just printing it directly.
2229
2230 =cut
2231
2232                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2233                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2234
2235                     # handle special  "x 3 blah" syntax XXX propagate
2236                     # doc back to special variables.
2237                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2238                         $onetimedumpDepth = $1;
2239                     }
2240                 };
2241
2242 =head4 C<m> - print methods
2243
2244 Just uses C<DB::methods> to determine what methods are available.
2245
2246 =cut
2247
2248                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2249                     methods($1);
2250                     next CMD;
2251                 };
2252
2253                 # m expr - set up DB::eval to do the work
2254                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2255                     $onetimeDump = 'methods';   #  method output gets used there
2256                 };
2257
2258 =head4 C<f> - switch files
2259
2260 =cut
2261
2262                 $cmd =~ /^f\b\s*(.*)/ && do {
2263                     $file = $1;
2264                     $file =~ s/\s+$//;
2265
2266                     # help for no arguments (old-style was return from sub).
2267                     if ( !$file ) {
2268                         print $OUT
2269                           "The old f command is now the r command.\n";    # hint
2270                         print $OUT "The new f command switches filenames.\n";
2271                         next CMD;
2272                     } ## end if (!$file)
2273
2274                     # if not in magic file list, try a close match.
2275                     if ( !defined $main::{ '_<' . $file } ) {
2276                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2277                             {
2278                                 $try = substr( $try, 2 );
2279                                 print $OUT "Choosing $try matching '$file':\n";
2280                                 $file = $try;
2281                             }
2282                         } ## end if (($try) = grep(m#^_<.*$file#...
2283                     } ## end if (!defined $main::{ ...
2284
2285                     # If not successfully switched now, we failed.
2286                     if ( !defined $main::{ '_<' . $file } ) {
2287                         print $OUT "No file matching '$file' is loaded.\n";
2288                         next CMD;
2289                     }
2290
2291                     # We switched, so switch the debugger internals around.
2292                     elsif ( $file ne $filename ) {
2293                         *dbline   = $main::{ '_<' . $file };
2294                         $max      = $#dbline;
2295                         $filename = $file;
2296                         $start    = 1;
2297                         $cmd      = "l";
2298                     } ## end elsif ($file ne $filename)
2299
2300                     # We didn't switch; say we didn't.
2301                     else {
2302                         print $OUT "Already in $file.\n";
2303                         next CMD;
2304                     }
2305                 };
2306
2307 =head4 C<.> - return to last-executed line.
2308
2309 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2310 and then we look up the line in the magical C<%dbline> hash.
2311
2312 =cut
2313
2314                 # . command.
2315                 $cmd =~ /^\.$/ && do {
2316                     $incr = -1;    # stay at current line
2317
2318                     # Reset everything to the old location.
2319                     $start    = $line;
2320                     $filename = $filename_ini;
2321                     *dbline   = $main::{ '_<' . $filename };
2322                     $max      = $#dbline;
2323
2324                     # Now where are we?
2325                     print_lineinfo($position);
2326                     next CMD;
2327                 };
2328
2329 =head4 C<-> - back one window
2330
2331 We change C<$start> to be one window back; if we go back past the first line,
2332 we set it to be the first line. We ser C<$incr> to put us back at the
2333 currently-executing line, and then put a C<l $start +> (list one window from
2334 C<$start>) in C<$cmd> to be executed later.
2335
2336 =cut
2337
2338                 # - - back a window.
2339                 $cmd =~ /^-$/ && do {
2340
2341                     # back up by a window; go to 1 if back too far.
2342                     $start -= $incr + $window + 1;
2343                     $start = 1 if $start <= 0;
2344                     $incr  = $window - 1;
2345
2346                     # Generate and execute a "l +" command (handled below).
2347                     $cmd = 'l ' . ($start) . '+';
2348                 };
2349
2350 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2351
2352 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2353 problems, most notably that the default case of several commands destroying
2354 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2355 retain the old commands for those who were used to using them or who preferred
2356 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2357 deal with them instead of processing them in-line.
2358
2359 =cut
2360
2361                 # All of these commands were remapped in perl 5.8.0;
2362                 # we send them off to the secondary dispatcher (see below).
2363                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2364                     &cmd_wrapper( $1, $2, $line );
2365                     next CMD;
2366                 };
2367
2368 =head4 C<y> - List lexicals in higher scope
2369
2370 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope    
2371 above the current one and then displays then using C<dumpvar.pl>.
2372
2373 =cut
2374
2375                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2376
2377                     # See if we've got the necessary support.
2378                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2379                       or &warn(
2380                         $@ =~ /locate/
2381                         ? "PadWalker module not found - please install\n"
2382                         : $@
2383                       )
2384                       and next CMD;
2385
2386                     # Load up dumpvar if we don't have it. If we can, that is.
2387                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2388                     defined &main::dumpvar
2389                       or print $OUT "dumpvar.pl not available.\n"
2390                       and next CMD;
2391
2392                     # Got all the modules we need. Find them and print them.
2393                     my @vars = split( ' ', $2 || '' );
2394
2395                     # Find the pad.
2396                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2397
2398                     # Oops. Can't find it.
2399                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2400
2401                     # Show the desired vars with dumplex().
2402                     my $savout = select($OUT);
2403
2404                     # Have dumplex dump the lexicals.
2405                     dumpvar::dumplex( $_, $h->{$_},
2406                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2407                         @vars )
2408                       for sort keys %$h;
2409                     select($savout);
2410                     next CMD;
2411                 };
2412
2413 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2414
2415 All of the commands below this point don't work after the program being
2416 debugged has ended. All of them check to see if the program has ended; this
2417 allows the commands to be relocated without worrying about a 'line of
2418 demarcation' above which commands can be entered anytime, and below which
2419 they can't.
2420
2421 =head4 C<n> - single step, but don't trace down into subs
2422
2423 Done by setting C<$single> to 2, which forces subs to execute straight through
2424 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2425 so a null command knows what to re-execute. 
2426
2427 =cut
2428
2429                 # n - next
2430                 $cmd =~ /^n$/ && do {
2431                     end_report(), next CMD if $finished and $level <= 1;
2432
2433                     # Single step, but don't enter subs.
2434                     $single = 2;
2435
2436                     # Save for empty command (repeat last).
2437                     $laststep = $cmd;
2438                     last CMD;
2439                 };
2440
2441 =head4 C<s> - single-step, entering subs
2442
2443 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside     
2444 subs. Also saves C<s> as C<$lastcmd>.
2445
2446 =cut
2447
2448                 # s - single step.
2449                 $cmd =~ /^s$/ && do {
2450
2451                     # Get out and restart the command loop if program
2452                     # has finished.
2453                     end_report(), next CMD if $finished and $level <= 1;
2454
2455                     # Single step should enter subs.
2456                     $single = 1;
2457
2458                     # Save for empty command (repeat last).
2459                     $laststep = $cmd;
2460                     last CMD;
2461                 };
2462
2463 =head4 C<c> - run continuously, setting an optional breakpoint
2464
2465 Most of the code for this command is taken up with locating the optional
2466 breakpoint, which is either a subroutine name or a line number. We set
2467 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2468 in this and all call levels above this one.
2469
2470 =cut
2471
2472                 # c - start continuous execution.
2473                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2474
2475                     # Hey, show's over. The debugged program finished
2476                     # executing already.
2477                     end_report(), next CMD if $finished and $level <= 1;
2478
2479                     # Capture the place to put a one-time break.
2480                     $subname = $i = $1;
2481
2482                     #  Probably not needed, since we finish an interactive
2483                     #  sub-session anyway...
2484                     # local $filename = $filename;
2485                     # local *dbline = *dbline; # XXX Would this work?!
2486                     #
2487                     # The above question wonders if localizing the alias
2488                     # to the magic array works or not. Since it's commented
2489                     # out, we'll just leave that to speculation for now.
2490
2491                     # If the "subname" isn't all digits, we'll assume it
2492                     # is a subroutine name, and try to find it.
2493                     if ( $subname =~ /\D/ ) {    # subroutine name
2494                             # Qualify it to the current package unless it's
2495                             # already qualified.
2496                         $subname = $package . "::" . $subname
2497                           unless $subname =~ /::/;
2498
2499                         # find_sub will return "file:line_number" corresponding
2500                         # to where the subroutine is defined; we call find_sub,
2501                         # break up the return value, and assign it in one
2502                         # operation.
2503                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2504
2505                         # Force the line number to be numeric.
2506                         $i += 0;
2507
2508                         # If we got a line number, we found the sub.
2509                         if ($i) {
2510
2511                             # Switch all the debugger's internals around so
2512                             # we're actually working with that file.
2513                             $filename = $file;
2514                             *dbline   = $main::{ '_<' . $filename };
2515
2516                             # Mark that there's a breakpoint in this file.
2517                             $had_breakpoints{$filename} |= 1;
2518
2519                             # Scan forward to the first executable line
2520                             # after the 'sub whatever' line.
2521                             $max = $#dbline;
2522                             ++$i while $dbline[$i] == 0 && $i < $max;
2523                         } ## end if ($i)
2524
2525                         # We didn't find a sub by that name.
2526                         else {
2527                             print $OUT "Subroutine $subname not found.\n";
2528                             next CMD;
2529                         }
2530                     } ## end if ($subname =~ /\D/)
2531
2532                     # At this point, either the subname was all digits (an
2533                     # absolute line-break request) or we've scanned through
2534                     # the code following the definition of the sub, looking
2535                     # for an executable, which we may or may not have found.
2536                     #
2537                     # If $i (which we set $subname from) is non-zero, we
2538                     # got a request to break at some line somewhere. On
2539                     # one hand, if there wasn't any real subroutine name
2540                     # involved, this will be a request to break in the current
2541                     # file at the specified line, so we have to check to make
2542                     # sure that the line specified really is breakable.
2543                     #
2544                     # On the other hand, if there was a subname supplied, the
2545                     # preceding block has moved us to the proper file and
2546                     # location within that file, and then scanned forward
2547                     # looking for the next executable line. We have to make
2548                     # sure that one was found.
2549                     #
2550                     # On the gripping hand, we can't do anything unless the
2551                     # current value of $i points to a valid breakable line.
2552                     # Check that.
2553                     if ($i) {
2554
2555                         # Breakable?
2556                         if ( $dbline[$i] == 0 ) {
2557                             print $OUT "Line $i not breakable.\n";
2558                             next CMD;
2559                         }
2560
2561                         # Yes. Set up the one-time-break sigil.
2562                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2563                         _enable_breakpoint_temp_enabled_status($filename, $i);
2564                     } ## end if ($i)
2565
2566                     # Turn off stack tracing from here up.
2567                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2568                         $stack[ $i++ ] &= ~1;
2569                     }
2570                     last CMD;
2571                 };
2572
2573 =head4 C<r> - return from a subroutine
2574
2575 For C<r> to work properly, the debugger has to stop execution again
2576 immediately after the return is executed. This is done by forcing
2577 single-stepping to be on in the call level above the current one. If
2578 we are printing return values when a C<r> is executed, set C<$doret>
2579 appropriately, and force us out of the command loop.
2580
2581 =cut
2582
2583                 # r - return from the current subroutine.
2584                 $cmd =~ /^r$/ && do {
2585
2586                     # Can't do anything if the program's over.
2587                     end_report(), next CMD if $finished and $level <= 1;
2588
2589                     # Turn on stack trace.
2590                     $stack[$stack_depth] |= 1;
2591
2592                     # Print return value unless the stack is empty.
2593                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2594                     last CMD;
2595                 };
2596
2597 =head4 C<T> - stack trace
2598
2599 Just calls C<DB::print_trace>.
2600
2601 =cut
2602
2603                 $cmd =~ /^T$/ && do {
2604                     print_trace( $OUT, 1 );    # skip DB
2605                     next CMD;
2606                 };
2607
2608 =head4 C<w> - List window around current line.
2609
2610 Just calls C<DB::cmd_w>.
2611
2612 =cut
2613
2614                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2615
2616 =head4 C<W> - watch-expression processing.
2617
2618 Just calls C<DB::cmd_W>. 
2619
2620 =cut
2621
2622                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2623
2624 =head4 C</> - search forward for a string in the source
2625
2626 We take the argument and treat it as a pattern. If it turns out to be a 
2627 bad one, we return the error we got from trying to C<eval> it and exit.
2628 If not, we create some code to do the search and C<eval> it so it can't 
2629 mess us up.
2630
2631 =cut
2632
2633                 $cmd =~ /^\/(.*)$/ && do {
2634
2635                     # The pattern as a string.
2636                     $inpat = $1;
2637
2638                     # Remove the final slash.
2639                     $inpat =~ s:([^\\])/$:$1:;
2640
2641                     # If the pattern isn't null ...
2642                     if ( $inpat ne "" ) {
2643
2644                         # Turn of warn and die procesing for a bit.
2645                         local $SIG{__DIE__};
2646                         local $SIG{__WARN__};
2647
2648                         # Create the pattern.
2649                         eval '$inpat =~ m' . "\a$inpat\a";
2650                         if ( $@ ne "" ) {
2651
2652                             # Oops. Bad pattern. No biscuit.
2653                             # Print the eval error and go back for more
2654                             # commands.
2655                             print $OUT "$@";
2656                             next CMD;
2657                         }
2658                         $pat = $inpat;
2659                     } ## end if ($inpat ne "")
2660
2661                     # Set up to stop on wrap-around.
2662                     $end = $start;
2663
2664                     # Don't move off the current line.
2665                     $incr = -1;
2666
2667                     # Done in eval so nothing breaks if the pattern
2668                     # does something weird.
2669                     eval '
2670                         for (;;) {
2671                             # Move ahead one line.
2672                             ++$start;
2673
2674                             # Wrap if we pass the last line.
2675                             $start = 1 if ($start > $max);
2676
2677                             # Stop if we have gotten back to this line again,
2678                             last if ($start == $end);
2679
2680                             # A hit! (Note, though, that we are doing
2681                             # case-insensitive matching. Maybe a qr//
2682                             # expression would be better, so the user could
2683                             # do case-sensitive matching if desired.
2684                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2685                                 if ($slave_editor) {
2686                                     # Handle proper escaping in the slave.
2687                                     print $OUT "\032\032$filename:$start:0\n";
2688                                 } 
2689                                 else {
2690                                     # Just print the line normally.
2691                                     print $OUT "$start:\t",$dbline[$start],"\n";
2692                                 }
2693                                 # And quit since we found something.
2694                                 last;
2695                             }
2696                          } ';
2697
2698                     # If we wrapped, there never was a match.
2699                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2700                     next CMD;
2701                 };
2702
2703 =head4 C<?> - search backward for a string in the source
2704
2705 Same as for C</>, except the loop runs backwards.
2706
2707 =cut
2708
2709                 # ? - backward pattern search.
2710                 $cmd =~ /^\?(.*)$/ && do {
2711
2712                     # Get the pattern, remove trailing question mark.
2713                     $inpat = $1;
2714                     $inpat =~ s:([^\\])\?$:$1:;
2715
2716                     # If we've got one ...
2717                     if ( $inpat ne "" ) {
2718
2719                         # Turn off die & warn handlers.
2720                         local $SIG{__DIE__};
2721                         local $SIG{__WARN__};
2722                         eval '$inpat =~ m' . "\a$inpat\a";
2723
2724                         if ( $@ ne "" ) {
2725
2726                             # Ouch. Not good. Print the error.
2727                             print $OUT $@;
2728                             next CMD;
2729                         }
2730                         $pat = $inpat;
2731                     } ## end if ($inpat ne "")
2732
2733                     # Where we are now is where to stop after wraparound.
2734                     $end = $start;
2735
2736                     # Don't move away from this line.
2737                     $incr = -1;
2738
2739                     # Search inside the eval to prevent pattern badness
2740                     # from killing us.
2741                     eval '
2742                         for (;;) {
2743                             # Back up a line.
2744                             --$start;
2745
2746                             # Wrap if we pass the first line.
2747
2748                             $start = $max if ($start <= 0);
2749
2750                             # Quit if we get back where we started,
2751                             last if ($start == $end);
2752
2753                             # Match?
2754                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2755                                 if ($slave_editor) {
2756                                     # Yep, follow slave editor requirements.
2757                                     print $OUT "\032\032$filename:$start:0\n";
2758                                 } 
2759                                 else {
2760                                     # Yep, just print normally.
2761                                     print $OUT "$start:\t",$dbline[$start],"\n";
2762                                 }
2763
2764                                 # Found, so done.
2765                                 last;
2766                             }
2767                         } ';
2768
2769                     # Say we failed if the loop never found anything,
2770                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2771                     next CMD;
2772                 };
2773
2774 =head4 C<$rc> - Recall command
2775
2776 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2777 that the terminal supports history). It find the the command required, puts it
2778 into C<$cmd>, and redoes the loop to execute it.
2779
2780 =cut
2781
2782                 # $rc - recall command.
2783                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
2784
2785                     # No arguments, take one thing off history.
2786                     pop(@hist) if length($cmd) > 1;
2787
2788                     # Relative (- found)?
2789                     #  Y - index back from most recent (by 1 if bare minus)
2790                     #  N - go to that particular command slot or the last
2791                     #      thing if nothing following.
2792                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
2793
2794                     # Pick out the command desired.
2795                     $cmd = $hist[$i];
2796
2797                     # Print the command to be executed and restart the loop
2798                     # with that command in the buffer.
2799                     print $OUT $cmd, "\n";
2800                     redo CMD;
2801                 };
2802
2803 =head4 C<$sh$sh> - C<system()> command
2804
2805 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2806 C<STDOUT> from getting messed up.
2807
2808 =cut
2809
2810                 # $sh$sh - run a shell command (if it's all ASCII).
2811                 # Can't run shell commands with Unicode in the debugger, hmm.
2812                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
2813
2814                     # System it.
2815                     &system($1);
2816                     next CMD;
2817                 };
2818
2819 =head4 C<$rc I<pattern> $rc> - Search command history
2820
2821 Another command to manipulate C<@hist>: this one searches it with a pattern.
2822 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2823
2824 =cut
2825
2826                 # $rc pattern $rc - find a command in the history.
2827                 $cmd =~ /^$rc([^$rc].*)$/ && do {
2828
2829                     # Create the pattern to use.
2830                     $pat = "^$1";
2831
2832                     # Toss off last entry if length is >1 (and it always is).
2833                     pop(@hist) if length($cmd) > 1;
2834
2835                     # Look backward through the history.
2836                     for ( $i = $#hist ; $i ; --$i ) {
2837
2838                         # Stop if we find it.
2839                         last if $hist[$i] =~ /$pat/;
2840                     }
2841
2842                     if ( !$i ) {
2843
2844                         # Never found it.
2845                         print $OUT "No such command!\n\n";
2846                         next CMD;
2847                     }
2848
2849                     # Found it. Put it in the buffer, print it, and process it.
2850                     $cmd = $hist[$i];
2851                     print $OUT $cmd, "\n";
2852                     redo CMD;
2853                 };
2854
2855 =head4 C<$sh> - Invoke a shell     
2856
2857 Uses C<DB::system> to invoke a shell.
2858
2859 =cut
2860
2861                 # $sh - start a shell.
2862                 $cmd =~ /^$sh$/ && do {
2863
2864                     # Run the user's shell. If none defined, run Bourne.
2865                     # We resume execution when the shell terminates.
2866                     &system( $ENV{SHELL} || "/bin/sh" );
2867                     next CMD;
2868                 };
2869
2870 =head4 C<$sh I<command>> - Force execution of a command in a shell
2871
2872 Like the above, but the command is passed to the shell. Again, we use
2873 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2874
2875 =cut
2876
2877                 # $sh command - start a shell and run a command in it.
2878                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
2879
2880                     # XXX: using csh or tcsh destroys sigint retvals!
2881                     #&system($1);  # use this instead
2882
2883                     # use the user's shell, or Bourne if none defined.
2884                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
2885                     next CMD;
2886                 };
2887
2888 =head4 C<H> - display commands in history
2889
2890 Prints the contents of C<@hist> (if any).
2891
2892 =cut
2893
2894                 $cmd =~ /^H\b\s*\*/ && do {
2895                     @hist = @truehist = ();
2896                     print $OUT "History cleansed\n";
2897                     next CMD;
2898                 };
2899
2900                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
2901
2902                     # Anything other than negative numbers is ignored by
2903                     # the (incorrect) pattern, so this test does nothing.
2904                     $end = $2 ? ( $#hist - $2 ) : 0;
2905
2906                     # Set to the minimum if less than zero.
2907                     $hist = 0 if $hist < 0;
2908
2909                     # Start at the end of the array.
2910                     # Stay in while we're still above the ending value.
2911                     # Tick back by one each time around the loop.
2912                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2913
2914                         # Print the command  unless it has no arguments.
2915                         print $OUT "$i: ", $hist[$i], "\n"
2916                           unless $hist[$i] =~ /^.?$/;
2917                     }
2918                     next CMD;
2919                 };
2920
2921 =head4 C<man, doc, perldoc> - look up documentation
2922
2923 Just calls C<runman()> to print the appropriate document.
2924
2925 =cut
2926
2927                 # man, perldoc, doc - show manual pages.
2928                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
2929                     runman($1);
2930                     next CMD;
2931                 };
2932
2933 =head4 C<p> - print
2934
2935 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2936 the bottom of the loop.
2937
2938 =cut
2939
2940                 # p - print (no args): print $_.
2941                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
2942
2943                 # p - print the given expression.
2944                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
2945
2946 =head4 C<=> - define command alias
2947
2948 Manipulates C<%alias> to add or list command aliases.
2949
2950 =cut
2951
2952                 # = - set up a command alias.
2953                 $cmd =~ s/^=\s*// && do {
2954                     my @keys;
2955                     if ( length $cmd == 0 ) {
2956
2957                         # No args, get current aliases.
2958                         @keys = sort keys %alias;
2959                     }
2960                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
2961
2962                         # Creating a new alias. $k is alias name, $v is
2963                         # alias value.
2964
2965                         # can't use $_ or kill //g state
2966                         for my $x ( $k, $v ) {
2967
2968                             # Escape "alarm" characters.
2969                             $x =~ s/\a/\\a/g;
2970                         }
2971
2972                         # Substitute key for value, using alarm chars
2973                         # as separators (which is why we escaped them in
2974                         # the command).
2975                         $alias{$k} = "s\a$k\a$v\a";
2976
2977                         # Turn off standard warn and die behavior.
2978                         local $SIG{__DIE__};
2979                         local $SIG{__WARN__};
2980
2981                         # Is it valid Perl?
2982                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
2983
2984                             # Nope. Bad alias. Say so and get out.
2985                             print $OUT "Can't alias $k to $v: $@\n";
2986                             delete $alias{$k};
2987                             next CMD;
2988                         }
2989
2990                         # We'll only list the new one.
2991                         @keys = ($k);
2992                     } ## end elsif (my ($k, $v) = ($cmd...
2993
2994                     # The argument is the alias to list.
2995                     else {
2996                         @keys = ($cmd);
2997                     }
2998
2999                     # List aliases.
3000                     for my $k (@keys) {
3001
3002                         # Messy metaquoting: Trim the substitution code off.
3003                         # We use control-G as the delimiter because it's not
3004                         # likely to appear in the alias.
3005                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3006
3007                             # Print the alias.
3008                             print $OUT "$k\t= $1\n";
3009                         }
3010                         elsif ( defined $alias{$k} ) {
3011
3012                             # Couldn't trim it off; just print the alias code.
3013                             print $OUT "$k\t$alias{$k}\n";
3014                         }
3015                         else {
3016
3017                             # No such, dude.
3018                             print "No alias for $k\n";
3019                         }
3020                     } ## end for my $k (@keys)
3021                     next CMD;
3022                 };
3023
3024 =head4 C<source> - read commands from a file.
3025
3026 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3027 pick it up.
3028
3029 =cut
3030
3031                 # source - read commands from a file (or pipe!) and execute.
3032                 $cmd =~ /^source\s+(.*\S)/ && do {
3033                     if ( open my $fh, $1 ) {
3034
3035                         # Opened OK; stick it in the list of file handles.
3036                         push @cmdfhs, $fh;
3037                     }
3038                     else {
3039
3040                         # Couldn't open it.
3041                         &warn("Can't execute '$1': $!\n");
3042                     }
3043                     next CMD;
3044                 };
3045
3046                 $cmd =~ /^(enable|disable)\s+(\S+)\s*$/ && do {
3047                     my ($cmd, $position) = ($1, $2);
3048
3049                     my ($fn, $line_num);
3050                     if ($position =~ m{\A\d+\z})
3051                     {
3052                         $fn = $filename;
3053                         $line_num = $position;
3054                     }
3055                     elsif ($position =~ m{\A(.*):(\d+)\z})
3056                     {
3057                         ($fn, $line_num) = ($1, $2);
3058                     }
3059                     else
3060                     {
3061                         &warn("Wrong spec for enable/disable argument.\n");
3062                     }
3063
3064                     if (defined($fn)) {
3065                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3066                             _set_breakpoint_enabled_status($fn, $line_num,
3067                                 ($cmd eq 'enable' ? 1 : '')
3068                             );
3069                         }
3070                         else {
3071                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3072                         }
3073                     }
3074
3075                     next CMD;
3076                 };
3077
3078 =head4 C<save> - send current history to a file
3079
3080 Takes the complete history, (not the shrunken version you see with C<H>),
3081 and saves it to the given filename, so it can be replayed using C<source>.
3082
3083 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3084
3085 =cut
3086
3087                 # save source - write commands to a file for later use
3088                 $cmd =~ /^save\s*(.*)$/ && do {
3089                     my $file = $1 || '.perl5dbrc';    # default?
3090                     if ( open my $fh, "> $file" ) {
3091
3092                        # chomp to remove extraneous newlines from source'd files
3093                         chomp( my @truelist =
3094                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3095                               @truehist );
3096                         print $fh join( "\n", @truelist );
3097                         print "commands saved in $file\n";
3098                     }
3099                     else {
3100                         &warn("Can't save debugger commands in '$1': $!\n");
3101                     }
3102                     next CMD;
3103                 };
3104
3105 =head4 C<R> - restart
3106
3107 Restart the debugger session. 
3108
3109 =head4 C<rerun> - rerun the current session
3110
3111 Return to any given position in the B<true>-history list
3112
3113 =cut
3114
3115                 # R - restart execution.
3116                 # rerun - controlled restart execution.
3117                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3118                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3119
3120                     # Close all non-system fds for a clean restart.  A more
3121                     # correct method would be to close all fds that were not
3122                     # open when the process started, but this seems to be
3123                     # hard.  See "debugger 'R'estart and open database
3124                     # connections" on p5p.
3125
3126                     my $max_fd = 1024; # default if POSIX can't be loaded
3127                     if (eval { require POSIX }) {
3128                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3129                     }
3130
3131                     if (defined $max_fd) {
3132                         foreach ($^F+1 .. $max_fd-1) {
3133                             next unless open FD_TO_CLOSE, "<&=$_";
3134                             close(FD_TO_CLOSE);
3135                         }
3136                     }
3137
3138                     # And run Perl again.  We use exec() to keep the
3139                     # PID stable (and that way $ini_pids is still valid).
3140                     exec(@args) || print $OUT "exec failed: $!\n";
3141
3142                     last CMD;
3143                 };
3144
3145 =head4 C<|, ||> - pipe output through the pager.
3146
3147 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3148 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3149 pipe to the pager (restoring the output filehandles if this fails). If this
3150 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply 
3151 set C<$signal>, sending us back into the debugger.
3152
3153 We then trim off the pipe symbols and C<redo> the command loop at the
3154 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3155 reading another.
3156
3157 =cut
3158
3159                 # || - run command in the pager, with output to DB::OUT.
3160                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3161                     if ( $pager =~ /^\|/ ) {
3162
3163                         # Default pager is into a pipe. Redirect I/O.
3164                         open( SAVEOUT, ">&STDOUT" )
3165                           || &warn("Can't save STDOUT");
3166                         open( STDOUT, ">&OUT" )
3167                           || &warn("Can't redirect STDOUT");
3168                     } ## end if ($pager =~ /^\|/)
3169                     else {
3170
3171                         # Not into a pipe. STDOUT is safe.
3172                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3173                     }
3174
3175                     # Fix up environment to record we have less if so.
3176                     fix_less();
3177
3178                     unless ( $piped = open( OUT, $pager ) ) {
3179
3180                         # Couldn't open pipe to pager.
3181                         &warn("Can't pipe output to '$pager'");
3182                         if ( $pager =~ /^\|/ ) {
3183
3184                             # Redirect I/O back again.
3185                             open( OUT, ">&STDOUT" )    # XXX: lost message
3186                               || &warn("Can't restore DB::OUT");
3187                             open( STDOUT, ">&SAVEOUT" )
3188                               || &warn("Can't restore STDOUT");
3189                             close(SAVEOUT);
3190                         } ## end if ($pager =~ /^\|/)
3191                         else {
3192
3193                             # Redirect I/O. STDOUT already safe.
3194                             open( OUT, ">&STDOUT" )    # XXX: lost message
3195                               || &warn("Can't restore DB::OUT");
3196                         }
3197                         next CMD;
3198                     } ## end unless ($piped = open(OUT,...
3199
3200                     # Set up broken-pipe handler if necessary.
3201                     $SIG{PIPE} = \&DB::catch
3202                       if $pager =~ /^\|/
3203                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3204
3205                     # Save current filehandle, unbuffer out, and put it back.
3206                     $selected = select(OUT);
3207                     $|        = 1;
3208
3209                     # Don't put it back if pager was a pipe.
3210                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3211
3212                     # Trim off the pipe symbols and run the command now.
3213                     $cmd =~ s/^\|+\s*//;
3214                     redo PIPE;
3215                 };
3216
3217 =head3 END OF COMMAND PARSING
3218
3219 Anything left in C<$cmd> at this point is a Perl expression that we want to 
3220 evaluate. We'll always evaluate in the user's context, and fully qualify 
3221 any variables we might want to address in the C<DB> package.
3222
3223 =cut
3224
3225                 # t - turn trace on.
3226                 $cmd =~ s/^t\s+(\d+)?/\$DB::trace |= 1;\n/ && do {
3227                     $trace_to_depth = $1 ? $stack_depth||0 + $1 : 1E9;
3228                 };
3229
3230                 # s - single-step. Remember the last command was 's'.
3231                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3232
3233                 # n - single-step, but not into subs. Remember last command
3234                 # was 'n'.
3235                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3236
3237             }    # PIPE:
3238
3239             # Make sure the flag that says "the debugger's running" is
3240             # still on, to make sure we get control again.
3241             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3242
3243             # Run *our* eval that executes in the caller's context.
3244             &eval;
3245
3246             # Turn off the one-time-dump stuff now.
3247             if ($onetimeDump) {
3248                 $onetimeDump      = undef;
3249                 $onetimedumpDepth = undef;
3250             }
3251             elsif ( $term_pid == $$ ) {
3252                 eval {          # May run under miniperl, when not available...
3253                     STDOUT->flush();
3254                     STDERR->flush();
3255                 };
3256
3257                 # XXX If this is the master pid, print a newline.
3258                 print $OUT "\n";
3259             }
3260         } ## end while (($term || &setterm...
3261
3262 =head3 POST-COMMAND PROCESSING
3263
3264 After each command, we check to see if the command output was piped anywhere.
3265 If so, we go through the necessary code to unhook the pipe and go back to
3266 our standard filehandles for input and output.
3267
3268 =cut
3269
3270         continue {    # CMD:
3271
3272             # At the end of every command:
3273             if ($piped) {
3274
3275                 # Unhook the pipe mechanism now.
3276                 if ( $pager =~ /^\|/ ) {
3277
3278                     # No error from the child.
3279                     $? = 0;
3280
3281                     # we cannot warn here: the handle is missing --tchrist
3282                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3283
3284                     # most of the $? crud was coping with broken cshisms
3285                     # $? is explicitly set to 0, so this never runs.
3286                     if ($?) {
3287                         print SAVEOUT "Pager '$pager' failed: ";
3288                         if ( $? == -1 ) {
3289                             print SAVEOUT "shell returned -1\n";
3290                         }
3291                         elsif ( $? >> 8 ) {
3292                             print SAVEOUT ( $? & 127 )
3293                               ? " (SIG#" . ( $? & 127 ) . ")"
3294                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3295                         }
3296                         else {
3297                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3298                         }
3299                     } ## end if ($?)
3300
3301                     # Reopen filehandle for our output (if we can) and
3302                     # restore STDOUT (if we can).
3303                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3304                     open( STDOUT, ">&SAVEOUT" )
3305                       || &warn("Can't restore STDOUT");
3306
3307                     # Turn off pipe exception handler if necessary.
3308                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3309
3310                     # Will stop ignoring SIGPIPE if done like nohup(1)
3311                     # does SIGINT but Perl doesn't give us a choice.
3312                 } ## end if ($pager =~ /^\|/)
3313                 else {
3314
3315                     # Non-piped "pager". Just restore STDOUT.
3316                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3317                 }
3318
3319                 # Close filehandle pager was using, restore the normal one
3320                 # if necessary,
3321                 close(SAVEOUT);
3322                 select($selected), $selected = "" unless $selected eq "";
3323
3324                 # No pipes now.
3325                 $piped = "";
3326             } ## end if ($piped)
3327         }    # CMD:
3328
3329 =head3 COMMAND LOOP TERMINATION
3330
3331 When commands have finished executing, we come here. If the user closed the
3332 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3333 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3334 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3335 The interpreter will then execute the next line and then return control to us
3336 again.
3337
3338 =cut
3339
3340         # No more commands? Quit.
3341         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3342
3343         # Evaluate post-prompt commands.
3344         foreach $evalarg (@$post) {
3345             &eval;
3346         }
3347     }    # if ($single || $signal)
3348
3349     # Put the user's globals back where you found them.
3350     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3351     ();
3352 } ## end sub DB
3353
3354 # The following code may be executed now:
3355 # BEGIN {warn 4}
3356
3357 =head2 sub
3358
3359 C<sub> is called whenever a subroutine call happens in the program being 
3360 debugged. The variable C<$DB::sub> contains the name of the subroutine
3361 being called.
3362
3363 The core function of this subroutine is to actually call the sub in the proper
3364 context, capturing its output. This of course causes C<DB::DB> to get called
3365 again, repeating until the subroutine ends and returns control to C<DB::sub>
3366 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3367 return value, and returns its captured copy of the return value as its own
3368 return value. The value then feeds back into the program being debugged as if
3369 C<DB::sub> hadn't been there at all.
3370
3371 C<sub> does all the work of printing the subroutine entry and exit messages
3372 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3373 and also prints the return value if needed (for the C<r> command and if 
3374 the 16 bit is set in C<$frame>).
3375
3376 It also tracks the subroutine call depth by saving the current setting of
3377 C<$single> in the C<@stack> package global; if this exceeds the value in
3378 C<$deep>, C<sub> automatically turns on printing of the current depth by
3379 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3380 of stop/don't stop on entry to subs set as it currently is set.
3381
3382 =head3 C<caller()> support
3383
3384 If C<caller()> is called from the package C<DB>, it provides some
3385 additional data, in the following order:
3386
3387 =over 4
3388
3389 =item * C<$package>
3390
3391 The package name the sub was in
3392
3393 =item * C<$filename>
3394
3395 The filename it was defined in
3396
3397 =item * C<$line>
3398
3399 The line number it was defined on
3400
3401 =item * C<$subroutine>
3402
3403 The subroutine name; C<(eval)> if an C<eval>().
3404
3405 =item * C<$hasargs>
3406
3407 1 if it has arguments, 0 if not
3408
3409 =item * C<$wantarray>
3410
3411 1 if array context, 0 if scalar context
3412
3413 =item * C<$evaltext>
3414
3415 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3416
3417 =item * C<$is_require>
3418
3419 frame was created by a C<use> or C<require> statement
3420
3421 =item * C<$hints>
3422
3423 pragma information; subject to change between versions
3424
3425 =item * C<$bitmask>
3426
3427 pragma information; subject to change between versions
3428
3429 =item * C<@DB::args>
3430
3431 arguments with which the subroutine was invoked
3432
3433 =back
3434
3435 =cut
3436
3437 sub sub {
3438         # Do not use a regex in this subroutine -> results in corrupted memory
3439         # See: [perl #66110]
3440
3441         # lock ourselves under threads
3442         lock($DBGR);
3443
3444     # Whether or not the autoloader was running, a scalar to put the
3445     # sub's return value in (if needed), and an array to put the sub's
3446     # return value in (if needed).
3447     my ( $al, $ret, @ret ) = "";
3448         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3449                 print "creating new thread\n"; 
3450         }
3451
3452     # If the last ten characters are '::AUTOLOAD', note we've traced
3453     # into AUTOLOAD for $sub.
3454     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3455         $al = " for $$sub" if defined $$sub;
3456     }
3457
3458     # We stack the stack pointer and then increment it to protect us
3459     # from a situation that might unwind a whole bunch of call frames
3460     # at once. Localizing the stack pointer means that it will automatically
3461     # unwind the same amount when multiple stack frames are unwound.
3462     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3463
3464     # Expand @stack.
3465     $#stack = $stack_depth;
3466
3467     # Save current single-step setting.
3468     $stack[-1] = $single;
3469
3470     # Turn off all flags except single-stepping.
3471     $single &= 1;
3472
3473     # If we've gotten really deeply recursed, turn on the flag that will
3474     # make us stop with the 'deep recursion' message.
3475     $single |= 4 if $stack_depth == $deep;
3476
3477     # If frame messages are on ...
3478     (
3479         $frame & 4    # Extended frame entry message
3480         ? (
3481             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3482
3483             # Why -1? But it works! :-(
3484             # Because print_trace will call add 1 to it and then call
3485             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3486             # in dump_trace.
3487             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3488           )
3489         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3490
3491           # standard frame entry message
3492       )
3493       if $frame;
3494
3495     # Determine the sub's return type, and capture appropriately.
3496     if (wantarray) {
3497
3498         # Called in array context. call sub and capture output.
3499         # DB::DB will recursively get control again if appropriate; we'll come
3500         # back here when the sub is finished.
3501         @ret = &$sub;
3502
3503         # Pop the single-step value back off the stack.
3504         $single |= $stack[ $stack_depth-- ];
3505
3506         # Check for exit trace messages...
3507         (
3508             $frame & 4    # Extended exit message
3509             ? (
3510                 print_lineinfo( ' ' x $stack_depth, "out " ),
3511                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3512               )
3513             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3514
3515               # Standard exit message
3516           )
3517           if $frame & 2;
3518
3519         # Print the return info if we need to.
3520         if ( $doret eq $stack_depth or $frame & 16 ) {
3521
3522             # Turn off output record separator.
3523             local $\ = '';
3524             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3525
3526             # Indent if we're printing because of $frame tracing.
3527             print $fh ' ' x $stack_depth if $frame & 16;
3528
3529             # Print the return value.
3530             print $fh "list context return from $sub:\n";
3531             dumpit( $fh, \@ret );
3532
3533             # And don't print it again.
3534             $doret = -2;
3535         } ## end if ($doret eq $stack_depth...
3536             # And we have to return the return value now.
3537         @ret;
3538     } ## end if (wantarray)
3539
3540     # Scalar context.
3541     else {
3542         if ( defined wantarray ) {
3543
3544             # Save the value if it's wanted at all.
3545             $ret = &$sub;
3546         }
3547         else {
3548
3549             # Void return, explicitly.
3550             &$sub;
3551             undef $ret;
3552         }
3553
3554         # Pop the single-step value off the stack.
3555         $single |= $stack[ $stack_depth-- ];
3556
3557         # If we're doing exit messages...
3558         (
3559             $frame & 4    # Extended messages
3560             ? (
3561                 print_lineinfo( ' ' x $stack_depth, "out " ),
3562                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3563               )
3564             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3565
3566               # Standard messages
3567           )
3568           if $frame & 2;
3569
3570         # If we are supposed to show the return value... same as before.
3571         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3572             local $\ = '';
3573             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3574             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3575             print $fh (
3576                 defined wantarray
3577                 ? "scalar context return from $sub: "
3578                 : "void context return from $sub\n"
3579             );
3580             dumpit( $fh, $ret ) if defined wantarray;
3581             $doret = -2;
3582         } ## end if ($doret eq $stack_depth...
3583
3584         # Return the appropriate scalar value.
3585         $ret;
3586     } ## end else [ if (wantarray)
3587 } ## end sub sub
3588
3589 sub lsub : lvalue {
3590
3591         # lock ourselves under threads
3592         lock($DBGR);
3593
3594     # Whether or not the autoloader was running, a scalar to put the
3595     # sub's return value in (if needed), and an array to put the sub's
3596     # return value in (if needed).
3597     my ( $al, $ret, @ret ) = "";
3598         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3599                 print "creating new thread\n";
3600         }
3601
3602     # If the last ten characters are C'::AUTOLOAD', note we've traced
3603     # into AUTOLOAD for $sub.
3604     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3605         $al = " for $$sub";
3606     }
3607
3608     # We stack the stack pointer and then increment it to protect us
3609     # from a situation that might unwind a whole bunch of call frames
3610     # at once. Localizing the stack pointer means that it will automatically
3611     # unwind the same amount when multiple stack frames are unwound.
3612     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3613
3614     # Expand @stack.
3615     $#stack = $stack_depth;
3616
3617     # Save current single-step setting.
3618     $stack[-1] = $single;
3619
3620     # Turn off all flags except single-stepping.
3621     $single &= 1;
3622
3623     # If we've gotten really deeply recursed, turn on the flag that will
3624     # make us stop with the 'deep recursion' message.
3625     $single |= 4 if $stack_depth == $deep;
3626
3627     # If frame messages are on ...
3628     (
3629         $frame & 4    # Extended frame entry message
3630         ? (
3631             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3632
3633             # Why -1? But it works! :-(
3634             # Because print_trace will call add 1 to it and then call
3635             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3636             # in dump_trace.
3637             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3638           )
3639         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3640
3641           # standard frame entry message
3642       )
3643       if $frame;
3644
3645     # Pop the single-step value back off the stack.
3646     $single |= $stack[ $stack_depth-- ];
3647
3648     # call the original lvalue sub.
3649     &$sub;
3650 }
3651
3652 # Abstracting common code from multiple places elsewhere:
3653 sub depth_print_lineinfo {
3654     my $always_print = shift;
3655
3656     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3657 }
3658
3659 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3660
3661 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3662 Most of the changes were to systematize the command structure and to eliminate
3663 commands that threw away user input without checking.
3664
3665 The following sections describe the code added to make it easy to support 
3666 multiple command sets with conflicting command names. This section is a start 
3667 at unifying all command processing to make it simpler to develop commands.
3668
3669 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line 
3670 number, and C<$dbline> (the current line) as arguments.
3671
3672 Support functions in this section which have multiple modes of failure C<die> 
3673 on error; the rest simply return a false value.
3674
3675 The user-interface functions (all of the C<cmd_*> functions) just output
3676 error messages.
3677
3678 =head2 C<%set>
3679
3680 The C<%set> hash defines the mapping from command letter to subroutine
3681 name suffix. 
3682
3683 C<%set> is a two-level hash, indexed by set name and then by command name.
3684 Note that trying to set the CommandSet to C<foobar> simply results in the
3685 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3686
3687 =cut 
3688
3689 ### The API section
3690
3691 my %set = (    #
3692     'pre580' => {
3693         'a' => 'pre580_a',
3694         'A' => 'pre580_null',
3695         'b' => 'pre580_b',
3696         'B' => 'pre580_null',
3697         'd' => 'pre580_null',
3698         'D' => 'pre580_D',
3699         'h' => 'pre580_h',
3700         'M' => 'pre580_null',
3701         'O' => 'o',
3702         'o' => 'pre580_null',
3703         'v' => 'M',
3704         'w' => 'v',
3705         'W' => 'pre580_W',
3706     },
3707     'pre590' => {
3708         '<'  => 'pre590_prepost',
3709         '<<' => 'pre590_prepost',
3710         '>'  => 'pre590_prepost',
3711         '>>' => 'pre590_prepost',
3712         '{'  => 'pre590_prepost',
3713         '{{' => 'pre590_prepost',
3714     },
3715 );
3716
3717 my %breakpoints_data;
3718
3719 sub _has_breakpoint_data_ref {
3720     my ($filename, $line) = @_;
3721
3722     return (
3723         exists( $breakpoints_data{$filename} )
3724             and
3725         exists( $breakpoints_data{$filename}{$line} )
3726     );
3727 }
3728
3729 sub _get_breakpoint_data_ref {
3730     my ($filename, $line) = @_;
3731
3732     return ($breakpoints_data{$filename}{$line} ||= +{});
3733 }
3734
3735 sub _delete_breakpoint_data_ref {
3736     my ($filename, $line) = @_;
3737
3738     delete($breakpoints_data{$filename}{$line});
3739     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3740         delete($breakpoints_data{$filename});
3741     }
3742
3743     return;
3744 }
3745
3746 sub _set_breakpoint_enabled_status {
3747     my ($filename, $line, $status) = @_;
3748
3749     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3750         ($status ? 1 : '')
3751         ;
3752
3753     return;
3754 }
3755
3756 sub _enable_breakpoint_temp_enabled_status {
3757     my ($filename, $line) = @_;
3758
3759     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3760
3761     return;
3762 }
3763
3764 sub _cancel_breakpoint_temp_enabled_status {
3765     my ($filename, $line) = @_;
3766
3767     my $ref = _get_breakpoint_data_ref($filename, $line);
3768     
3769     delete ($ref->{'temp_enabled'});
3770
3771     if (! %$ref) {
3772         _delete_breakpoint_data_ref($filename, $line);
3773     }
3774
3775     return;
3776 }
3777
3778 sub _is_breakpoint_enabled {
3779     my ($filename, $line) = @_;
3780
3781     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3782     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3783 }
3784
3785 =head2 C<cmd_wrapper()> (API)
3786
3787 C<cmd_wrapper()> allows the debugger to switch command sets 
3788 depending on the value of the C<CommandSet> option. 
3789
3790 It tries to look up the command in the C<%set> package-level I<lexical>
3791 (which means external entities can't fiddle with it) and create the name of 
3792 the sub to call based on the value found in the hash (if it's there). I<All> 
3793 of the commands to be handled in a set have to be added to C<%set>; if they 
3794 aren't found, the 5.8.0 equivalent is called (if there is one).
3795
3796 This code uses symbolic references. 
3797
3798 =cut
3799
3800 sub cmd_wrapper {
3801     my $cmd      = shift;
3802     my $line     = shift;
3803     my $dblineno = shift;
3804
3805     # Assemble the command subroutine's name by looking up the
3806     # command set and command name in %set. If we can't find it,
3807     # default to the older version of the command.
3808     my $call = 'cmd_'
3809       . ( $set{$CommandSet}{$cmd}
3810           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3811
3812     # Call the command subroutine, call it by name.
3813     return &$call( $cmd, $line, $dblineno );
3814 } ## end sub cmd_wrapper
3815
3816 =head3 C<cmd_a> (command)
3817
3818 The C<a> command handles pre-execution actions. These are associated with a
3819 particular line, so they're stored in C<%dbline>. We default to the current 
3820 line if none is specified. 
3821
3822 =cut
3823
3824 sub cmd_a {
3825     my $cmd    = shift;
3826     my $line   = shift || '';    # [.|line] expr
3827     my $dbline = shift;
3828
3829     # If it's dot (here), or not all digits,  use the current line.
3830     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3831
3832     # Should be a line number followed by an expression.
3833     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3834         my ( $lineno, $expr ) = ( $1, $2 );
3835
3836         # If we have an expression ...
3837         if ( length $expr ) {
3838
3839             # ... but the line isn't breakable, complain.
3840             if ( $dbline[$lineno] == 0 ) {
3841                 print $OUT
3842                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3843             }
3844             else {
3845
3846                 # It's executable. Record that the line has an action.
3847                 $had_breakpoints{$filename} |= 2;
3848
3849                 # Remove any action, temp breakpoint, etc.
3850                 $dbline{$lineno} =~ s/\0[^\0]*//;
3851
3852                 # Add the action to the line.
3853                 $dbline{$lineno} .= "\0" . action($expr);
3854             }
3855         } ## end if (length $expr)
3856     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3857     else {
3858
3859         # Syntax wrong.
3860         print $OUT
3861           "Adding an action requires an optional lineno and an expression\n"
3862           ;    # hint
3863     }
3864 } ## end sub cmd_a
3865
3866 =head3 C<cmd_A> (command)
3867
3868 Delete actions. Similar to above, except the delete code is in a separate
3869 subroutine, C<delete_action>.
3870
3871 =cut
3872
3873 sub cmd_A {
3874     my $cmd    = shift;
3875     my $line   = shift || '';
3876     my $dbline = shift;
3877
3878     # Dot is this line.
3879     $line =~ s/^\./$dbline/;
3880
3881     # Call delete_action with a null param to delete them all.
3882     # The '1' forces the eval to be true. It'll be false only
3883     # if delete_action blows up for some reason, in which case
3884     # we print $@ and get out.
3885     if ( $line eq '*' ) {
3886         eval { &delete_action(); 1 } or print $OUT $@ and return;
3887     }
3888
3889     # There's a real line  number. Pass it to delete_action.
3890     # Error trapping is as above.
3891     elsif ( $line =~ /^(\S.*)/ ) {
3892         eval { &delete_action($1); 1 } or print $OUT $@ and return;
3893     }
3894
3895     # Swing and a miss. Bad syntax.
3896     else {
3897         print $OUT
3898           "Deleting an action requires a line number, or '*' for all\n" ; # hint
3899     }
3900 } ## end sub cmd_A
3901
3902 =head3 C<delete_action> (API)
3903
3904 C<delete_action> accepts either a line number or C<undef>. If a line number
3905 is specified, we check for the line being executable (if it's not, it 
3906 couldn't have had an  action). If it is, we just take the action off (this
3907 will get any kind of an action, including breakpoints).
3908
3909 =cut
3910
3911 sub delete_action {
3912     my $i = shift;
3913     if ( defined($i) ) {
3914
3915         # Can there be one?
3916         die "Line $i has no action .\n" if $dbline[$i] == 0;
3917
3918         # Nuke whatever's there.
3919         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
3920         delete $dbline{$i} if $dbline{$i} eq '';
3921     }
3922     else {
3923         print $OUT "Deleting all actions...\n";
3924         for my $file ( keys %had_breakpoints ) {
3925             local *dbline = $main::{ '_<' . $file };
3926             my $max = $#dbline;
3927             my $was;
3928             for ( $i = 1 ; $i <= $max ; $i++ ) {
3929                 if ( defined $dbline{$i} ) {
3930                     $dbline{$i} =~ s/\0[^\0]*//;
3931                     delete $dbline{$i} if $dbline{$i} eq '';
3932                 }
3933                 unless ( $had_breakpoints{$file} &= ~2 ) {
3934                     delete $had_breakpoints{$file};
3935                 }
3936             } ## end for ($i = 1 ; $i <= $max...
3937         } ## end for my $file (keys %had_breakpoints)
3938     } ## end else [ if (defined($i))
3939 } ## end sub delete_action
3940
3941 =head3 C<cmd_b> (command)
3942
3943 Set breakpoints. Since breakpoints can be set in so many places, in so many
3944 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
3945 we try to parse the command type, and then shuttle it off to an appropriate
3946 subroutine to actually do the work of setting the breakpoint in the right
3947 place.
3948
3949 =cut
3950
3951 sub cmd_b {
3952     my $cmd    = shift;
3953     my $line   = shift;    # [.|line] [cond]
3954     my $dbline = shift;
3955
3956     # Make . the current line number if it's there..
3957     $line =~ s/^\.(\s|\z)/$dbline$1/;
3958
3959     # No line number, no condition. Simple break on current line.
3960     if ( $line =~ /^\s*$/ ) {
3961         &cmd_b_line( $dbline, 1 );
3962     }
3963
3964     # Break on load for a file.
3965     elsif ( $line =~ /^load\b\s*(.*)/ ) {
3966         my $file = $1;
3967         $file =~ s/\s+$//;
3968         &cmd_b_load($file);
3969     }
3970
3971     # b compile|postpone <some sub> [<condition>]
3972     # The interpreter actually traps this one for us; we just put the
3973     # necessary condition in the %postponed hash.
3974     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
3975
3976         # Capture the condition if there is one. Make it true if none.
3977         my $cond = length $3 ? $3 : '1';
3978
3979         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
3980         # if it was 'compile'.
3981         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
3982
3983         # De-Perl4-ify the name - ' separators to ::.
3984         $subname =~ s/\'/::/g;
3985
3986         # Qualify it into the current package unless it's already qualified.
3987         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
3988
3989         # Add main if it starts with ::.
3990         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
3991
3992         # Save the break type for this sub.
3993         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
3994     } ## end elsif ($line =~ ...
3995     # b <filename>:<line> [<condition>]
3996     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
3997         my ($filename, $line_num, $cond) = ($1, $2, $3);
3998         cmd_b_filename_line(
3999             $filename,
4000             $line_num, 
4001             (length($cond) ? $cond : '1'),
4002         );
4003     }
4004     # b <sub name> [<condition>]
4005     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4006
4007         #
4008         $subname = $1;
4009         $cond = length $2 ? $2 : '1';
4010         &cmd_b_sub( $subname, $cond );
4011     }
4012
4013     # b <line> [<condition>].
4014     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4015
4016         # Capture the line. If none, it's the current line.
4017         $line = $1 || $dbline;
4018
4019         # If there's no condition, make it '1'.
4020         $cond = length $2 ? $2 : '1';
4021
4022         # Break on line.
4023         &cmd_b_line( $line, $cond );
4024     }
4025
4026     # Line didn't make sense.
4027     else {
4028         print "confused by line($line)?\n";
4029     }
4030 } ## end sub cmd_b
4031
4032 =head3 C<break_on_load> (API)
4033
4034 We want to break when this file is loaded. Mark this file in the
4035 C<%break_on_load> hash, and note that it has a breakpoint in 
4036 C<%had_breakpoints>.
4037
4038 =cut
4039
4040 sub break_on_load {
4041     my $file = shift;
4042     $break_on_load{$file} = 1;
4043     $had_breakpoints{$file} |= 1;
4044 }
4045
4046 =head3 C<report_break_on_load> (API)
4047
4048 Gives us an array of filenames that are set to break on load. Note that 
4049 only files with break-on-load are in here, so simply showing the keys
4050 suffices.
4051
4052 =cut
4053
4054 sub report_break_on_load {
4055     sort keys %break_on_load;
4056 }
4057
4058 =head3 C<cmd_b_load> (command)
4059
4060 We take the file passed in and try to find it in C<%INC> (which maps modules
4061 to files they came from). We mark those files for break-on-load via 
4062 C<break_on_load> and then report that it was done.
4063
4064 =cut
4065
4066 sub cmd_b_load {
4067     my $file = shift;
4068     my @files;
4069
4070     # This is a block because that way we can use a redo inside it
4071     # even without there being any looping structure at all outside it.
4072     {
4073
4074         # Save short name and full path if found.
4075         push @files, $file;
4076         push @files, $::INC{$file} if $::INC{$file};
4077
4078         # Tack on .pm and do it again unless there was a '.' in the name
4079         # already.
4080         $file .= '.pm', redo unless $file =~ /\./;
4081     }
4082
4083     # Do the real work here.
4084     break_on_load($_) for @files;
4085
4086     # All the files that have break-on-load breakpoints.
4087     @files = report_break_on_load;
4088
4089     # Normalize for the purposes of our printing this.
4090     local $\ = '';
4091     local $" = ' ';
4092     print $OUT "Will stop on load of '@files'.\n";
4093 } ## end sub cmd_b_load
4094
4095 =head3 C<$filename_error> (API package global)
4096
4097 Several of the functions we need to implement in the API need to work both
4098 on the current file and on other files. We don't want to duplicate code, so
4099 C<$filename_error> is used to contain the name of the file that's being 
4100 worked on (if it's not the current one).
4101
4102 We can now build functions in pairs: the basic function works on the current
4103 file, and uses C<$filename_error> as part of its error message. Since this is
4104 initialized to C<"">, no filename will appear when we are working on the
4105 current file.
4106
4107 The second function is a wrapper which does the following:
4108
4109 =over 4 
4110
4111 =item *
4112
4113 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4114
4115 =item *
4116
4117 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process. 
4118
4119 =item *
4120
4121 Calls the first function. 
4122
4123 The first function works on the I<current> file (i.e., the one we changed to),
4124 and prints C<$filename_error> in the error message (the name of the other file)
4125 if it needs to. When the functions return, C<*dbline> is restored to point
4126 to the actual current file (the one we're executing in) and
4127 C<$filename_error> is restored to C<"">. This restores everything to
4128 the way it was before the second function was called at all.
4129
4130 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4131 details.
4132
4133 =back
4134
4135 =cut
4136
4137 $filename_error = '';
4138
4139 =head3 breakable_line(from, to) (API)
4140
4141 The subroutine decides whether or not a line in the current file is breakable.
4142 It walks through C<@dbline> within the range of lines specified, looking for
4143 the first line that is breakable.
4144
4145 If C<$to> is greater than C<$from>, the search moves forwards, finding the 
4146 first line I<after> C<$to> that's breakable, if there is one.
4147
4148 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4149 first line I<before> C<$to> that's breakable, if there is one.
4150
4151 =cut
4152
4153 sub breakable_line {
4154
4155     my ( $from, $to ) = @_;
4156
4157     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4158     my $i = $from;
4159
4160     # If there are at least 2 arguments, we're trying to search a range.
4161     if ( @_ >= 2 ) {
4162
4163         # $delta is positive for a forward search, negative for a backward one.
4164         my $delta = $from < $to ? +1 : -1;
4165
4166         # Keep us from running off the ends of the file.
4167         my $limit = $delta > 0 ? $#dbline : 1;
4168
4169         # Clever test. If you're a mathematician, it's obvious why this
4170         # test works. If not:
4171         # If $delta is positive (going forward), $limit will be $#dbline.
4172         #    If $to is less than $limit, ($limit - $to) will be positive, times
4173         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4174         #    as the stopping point.
4175         #
4176         #    If $to is greater than $limit, ($limit - $to) is negative,
4177         #    times $delta of 1 (positive), so the result is < 0 and we should
4178         #    use $limit ($#dbline) as the stopping point.
4179         #
4180         # If $delta is negative (going backward), $limit will be 1.
4181         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4182         #    (negative) so the result is > 0, and we use $to as the stopping
4183         #    point.
4184         #
4185         #    If $to is less than zero, ($limit - $to) will be positive,
4186         #    times $delta of -1 (negative), so the result is not > 0, and
4187         #    we use $limit (1) as the stopping point.
4188         #
4189         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4190         #    (negative), still giving zero; the result is not > 0, and
4191         #    we use $limit (1) as the stopping point.
4192         #
4193         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4194         #    (negative), giving a positive (>0) value, so we'll set $limit to
4195         #    $to.
4196
4197         $limit = $to if ( $limit - $to ) * $delta > 0;
4198
4199         # The real search loop.
4200         # $i starts at $from (the point we want to start searching from).
4201         # We move through @dbline in the appropriate direction (determined
4202         # by $delta: either -1 (back) or +1 (ahead).
4203         # We stay in as long as we haven't hit an executable line
4204         # ($dbline[$i] == 0 means not executable) and we haven't reached
4205         # the limit yet (test similar to the above).
4206         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4207
4208     } ## end if (@_ >= 2)
4209
4210     # If $i points to a line that is executable, return that.
4211     return $i unless $dbline[$i] == 0;
4212
4213     # Format the message and print it: no breakable lines in range.
4214     my ( $pl, $upto ) = ( '', '' );
4215     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4216
4217     # If there's a filename in filename_error, we'll see it.
4218     # If not, not.
4219     die "Line$pl $from$upto$filename_error not breakable\n";
4220 } ## end sub breakable_line
4221
4222 =head3 breakable_line_in_filename(file, from, to) (API)
4223
4224 Like C<breakable_line>, but look in another file.
4225
4226 =cut
4227
4228 sub breakable_line_in_filename {
4229
4230     # Capture the file name.
4231     my ($f) = shift;
4232
4233     # Swap the magic line array over there temporarily.
4234     local *dbline = $main::{ '_<' . $f };
4235
4236     # If there's an error, it's in this other file.
4237     local $filename_error = " of '$f'";
4238
4239     # Find the breakable line.
4240     breakable_line(@_);
4241
4242     # *dbline and $filename_error get restored when this block ends.
4243
4244 } ## end sub breakable_line_in_filename
4245
4246 =head3 break_on_line(lineno, [condition]) (API)
4247
4248 Adds a breakpoint with the specified condition (or 1 if no condition was 
4249 specified) to the specified line. Dies if it can't.
4250
4251 =cut
4252
4253 sub break_on_line {
4254     my ( $i, $cond ) = @_;
4255
4256     # Always true if no condition supplied.
4257     $cond = 1 unless @_ >= 2;
4258
4259     my $inii  = $i;
4260     my $after = '';
4261     my $pl    = '';
4262
4263     # Woops, not a breakable line. $filename_error allows us to say
4264     # if it was in a different file.
4265     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4266
4267     # Mark this file as having breakpoints in it.
4268     $had_breakpoints{$filename} |= 1;
4269
4270     # If there is an action or condition here already ...
4271     if ( $dbline{$i} ) {
4272
4273         # ... swap this condition for the existing one.
4274         $dbline{$i} =~ s/^[^\0]*/$cond/;
4275     }
4276     else {
4277
4278         # Nothing here - just add the condition.
4279         $dbline{$i} = $cond;
4280
4281         _set_breakpoint_enabled_status($filename, $i, 1);
4282     }
4283 } ## end sub break_on_line
4284
4285 =head3 cmd_b_line(line, [condition]) (command)
4286
4287 Wrapper for C<break_on_line>. Prints the failure message if it 
4288 doesn't work.
4289
4290 =cut 
4291
4292 sub cmd_b_line {
4293     eval { break_on_line(@_); 1 } or do {
4294         local $\ = '';
4295         print $OUT $@ and return;
4296     };
4297 } ## end sub cmd_b_line
4298
4299 =head3 cmd_b_filename_line(line, [condition]) (command)
4300
4301 Wrapper for C<break_on_filename_line>. Prints the failure message if it 
4302 doesn't work.
4303
4304 =cut 
4305
4306 sub cmd_b_filename_line {
4307     eval { break_on_filename_line(@_); 1 } or do {
4308         local $\ = '';
4309         print $OUT $@ and return;
4310     };
4311 }
4312
4313 =head3 break_on_filename_line(file, line, [condition]) (API)
4314
4315 Switches to the file specified and then calls C<break_on_line> to set 
4316 the breakpoint.
4317
4318 =cut
4319
4320 sub break_on_filename_line {
4321     my ( $f, $i, $cond ) = @_;
4322
4323     # Always true if condition left off.
4324     $cond = 1 unless @_ >= 3;
4325
4326     # Switch the magical hash temporarily.
4327     local *dbline = $main::{ '_<' . $f };
4328
4329     # Localize the variables that break_on_line uses to make its message.
4330     local $filename_error = " of '$f'";
4331     local $filename       = $f;
4332
4333     # Add the breakpoint.
4334     break_on_line( $i, $cond );
4335 } ## end sub break_on_filename_line
4336
4337 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4338
4339 Switch to another file, search the range of lines specified for an 
4340 executable one, and put a breakpoint on the first one you find.
4341
4342 =cut
4343
4344 sub break_on_filename_line_range {
4345     my ( $f, $from, $to, $cond ) = @_;
4346
4347     # Find a breakable line if there is one.
4348     my $i = breakable_line_in_filename( $f, $from, $to );
4349
4350     # Always true if missing.
4351     $cond = 1 unless @_ >= 3;
4352
4353     # Add the breakpoint.
4354     break_on_filename_line( $f, $i, $cond );
4355 } ## end sub break_on_filename_line_range
4356
4357 =head3 subroutine_filename_lines(subname, [condition]) (API)
4358
4359 Search for a subroutine within a given file. The condition is ignored.
4360 Uses C<find_sub> to locate the desired subroutine.
4361
4362 =cut
4363
4364 sub subroutine_filename_lines {
4365     my ( $subname, $cond ) = @_;
4366
4367     # Returned value from find_sub() is fullpathname:startline-endline.
4368     # The match creates the list (fullpathname, start, end). Falling off
4369     # the end of the subroutine returns this implicitly.
4370     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4371 } ## end sub subroutine_filename_lines
4372
4373 =head3 break_subroutine(subname) (API)
4374
4375 Places a break on the first line possible in the specified subroutine. Uses
4376 C<subroutine_filename_lines> to find the subroutine, and 
4377 C<break_on_filename_line_range> to place the break.
4378
4379 =cut
4380
4381 sub break_subroutine {
4382     my $subname = shift;
4383
4384     # Get filename, start, and end.
4385     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4386       or die "Subroutine $subname not found.\n";
4387
4388     # Null condition changes to '1' (always true).
4389     $cond = 1 unless @_ >= 2;
4390
4391     # Put a break the first place possible in the range of lines
4392     # that make up this subroutine.
4393     break_on_filename_line_range( $file, $s, $e, @_ );
4394 } ## end sub break_subroutine
4395
4396 =head3 cmd_b_sub(subname, [condition]) (command)
4397
4398 We take the incoming subroutine name and fully-qualify it as best we can.
4399
4400 =over 4
4401
4402 =item 1. If it's already fully-qualified, leave it alone. 
4403
4404 =item 2. Try putting it in the current package.
4405
4406 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4407
4408 =item 4. If it starts with '::', put it in 'main::'.
4409
4410 =back
4411
4412 After all this cleanup, we call C<break_subroutine> to try to set the 
4413 breakpoint.
4414
4415 =cut
4416
4417 sub cmd_b_sub {
4418     my ( $subname, $cond ) = @_;
4419
4420     # Add always-true condition if we have none.
4421     $cond = 1 unless @_ >= 2;
4422
4423     # If the subname isn't a code reference, qualify it so that
4424     # break_subroutine() will work right.
4425     unless ( ref $subname eq 'CODE' ) {
4426
4427         # Not Perl4.
4428         $subname =~ s/\'/::/g;
4429         my $s = $subname;
4430
4431         # Put it in this package unless it's already qualified.
4432         $subname = "${'package'}::" . $subname
4433           unless $subname =~ /::/;
4434
4435         # Requalify it into CORE::GLOBAL if qualifying it into this
4436         # package resulted in its not being defined, but only do so
4437         # if it really is in CORE::GLOBAL.
4438         $subname = "CORE::GLOBAL::$s"
4439           if not defined &$subname
4440           and $s !~ /::/
4441           and defined &{"CORE::GLOBAL::$s"};
4442
4443         # Put it in package 'main' if it has a leading ::.
4444         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4445
4446     } ## end unless (ref $subname eq 'CODE')
4447
4448     # Try to set the breakpoint.
4449     eval { break_subroutine( $subname, $cond ); 1 } or do {
4450         local $\ = '';
4451         print $OUT $@ and return;
4452       }
4453 } ## end sub cmd_b_sub
4454
4455 =head3 C<cmd_B> - delete breakpoint(s) (command)
4456
4457 The command mostly parses the command line and tries to turn the argument
4458 into a line spec. If it can't, it uses the current line. It then calls
4459 C<delete_breakpoint> to actually do the work.
4460
4461 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4462 thereby deleting all the breakpoints.
4463
4464 =cut
4465
4466 sub cmd_B {
4467     my $cmd = shift;
4468
4469     # No line spec? Use dbline.
4470     # If there is one, use it if it's non-zero, or wipe it out if it is.
4471     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4472     my $dbline = shift;
4473
4474     # If the line was dot, make the line the current one.
4475     $line =~ s/^\./$dbline/;
4476
4477     # If it's * we're deleting all the breakpoints.
4478     if ( $line eq '*' ) {
4479         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4480     }
4481
4482     # If there is a line spec, delete the breakpoint on that line.
4483     elsif ( $line =~ /^(\S.*)/ ) {
4484         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4485             local $\ = '';
4486             print $OUT $@ and return;
4487         };
4488     } ## end elsif ($line =~ /^(\S.*)/)
4489
4490     # No line spec.
4491     else {
4492         print $OUT
4493           "Deleting a breakpoint requires a line number, or '*' for all\n"
4494           ;    # hint
4495     }
4496 } ## end sub cmd_B
4497
4498 =head3 delete_breakpoint([line]) (API)
4499
4500 This actually does the work of deleting either a single breakpoint, or all
4501 of them.
4502
4503 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4504 just drop out with a message saying so. If it is, we remove the condition
4505 part of the 'condition\0action' that says there's a breakpoint here. If,
4506 after we've done that, there's nothing left, we delete the corresponding
4507 line in C<%dbline> to signal that no action needs to be taken for this line.
4508
4509 For all breakpoints, we iterate through the keys of C<%had_breakpoints>, 
4510 which lists all currently-loaded files which have breakpoints. We then look