This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Time::Local patch take 2
[perl5.git] / lib / Time / Local.t
1 #!./perl
2
3 BEGIN {
4   if ($ENV{PERL_CORE}){
5     chdir('t') if -d 't';
6     @INC = ('.', '../lib');
7   }
8 }
9
10 use strict;
11
12 use Test::More;
13 use Time::Local;
14
15 # Set up time values to test
16 my @time =
17   (
18    #year,mon,day,hour,min,sec
19    [1970,  1,  2, 00, 00, 00],
20    [1980,  2, 28, 12, 00, 00],
21    [1980,  2, 29, 12, 00, 00],
22    [1999, 12, 31, 23, 59, 59],
23    [2000,  1,  1, 00, 00, 00],
24    [2010, 10, 12, 14, 13, 12],
25    # leap day
26    [2020,  2, 29, 12, 59, 59],
27    [2030,  7,  4, 17, 07, 06],
28 # The following test fails on a surprising number of systems
29 # so it is commented out. The end of the Epoch for a 32-bit signed
30 # implementation of time_t should be Jan 19, 2038  03:14:07 UTC.
31 #  [2038,  1, 17, 23, 59, 59],     # last full day in any tz
32   );
33
34 my @bad_time =
35     (
36      # month too large
37      [1995, 13, 01, 01, 01, 01],
38      # day too large
39      [1995, 02, 30, 01, 01, 01],
40      # hour too large
41      [1995, 02, 10, 25, 01, 01],
42      # minute too large
43      [1995, 02, 10, 01, 60, 01],
44      # second too large
45      [1995, 02, 10, 01, 01, 60],
46     );
47
48 my @neg_time =
49     (
50      # test negative epochs for systems that handle it
51      [ 1969, 12, 31, 16, 59, 59 ],
52      [ 1950, 04, 12, 9, 30, 31 ],
53     );
54
55 # Leap year tests
56 my @years =
57     (
58      [ 1900 => 0 ],
59      [ 1947 => 0 ],
60      [ 1996 => 1 ],
61      [ 2000 => 1 ],
62      [ 2100 => 0 ],
63     );
64
65 # Use 3 days before the start of the epoch because with Borland on
66 # Win32 it will work for -3600 _if_ your time zone is +01:00 (or
67 # greater).
68 my $neg_epoch_ok = defined ((localtime(-259200))[0]) ? 1 : 0;
69
70 # use vmsish 'time' makes for oddness around the Unix epoch
71 if ($^O eq 'VMS') {
72     $time[0][2]++;
73     $neg_epoch_ok = 0; # time_t is unsigned
74 }
75
76 my $tests = (@time * 12);
77 $tests += @neg_time * 12;
78 $tests += @bad_time;
79 $tests += @years;
80 $tests += 5;
81 $tests += 2 if $ENV{PERL_CORE};
82 $tests += 8 if $ENV{MAINTAINER};
83
84 plan tests => $tests;
85
86 for (@time, @neg_time) {
87     my($year, $mon, $mday, $hour, $min, $sec) = @$_;
88     $year -= 1900;
89     $mon--;
90
91  SKIP: {
92         skip '1970 test on VOS fails.', 12
93             if $^O eq 'vos' && $year == 70;
94         skip 'this platform does not support negative epochs.', 12
95             if $year < 70 && ! $neg_epoch_ok;
96
97         {
98             my $year_in = $year < 70 ? $year + 1900 : $year;
99             my $time = timelocal($sec,$min,$hour,$mday,$mon,$year_in);
100
101             my($s,$m,$h,$D,$M,$Y) = localtime($time);
102
103             is($s, $sec, "timelocal second for @$_");
104             is($m, $min, "timelocal minute for @$_");
105             is($h, $hour, "timelocal hour for @$_");
106             is($D, $mday, "timelocal day for @$_");
107             is($M, $mon, "timelocal month for @$_");
108             is($Y, $year, "timelocal year for @$_");
109         }
110
111         {
112             my $year_in = $year < 70 ? $year + 1900 : $year;
113             my $time = timegm($sec,$min,$hour,$mday,$mon,$year_in);
114
115             my($s,$m,$h,$D,$M,$Y) = gmtime($time);
116
117             is($s, $sec, "timegm second for @$_");
118             is($m, $min, "timegm minute for @$_");
119             is($h, $hour, "timegm hour for @$_");
120             is($D, $mday, "timegm day for @$_");
121             is($M, $mon, "timegm month for @$_");
122             is($Y, $year, "timegm year for @$_");
123         }
124     }
125 }
126
127 for (@bad_time) {
128     my($year, $mon, $mday, $hour, $min, $sec) = @$_;
129     $year -= 1900;
130     $mon--;
131
132     eval { timegm($sec,$min,$hour,$mday,$mon,$year) };
133
134     like($@, qr/.*out of range.*/, 'invalid time caused an error');
135 }
136
137 {
138     is(timelocal(0,0,1,1,0,90) - timelocal(0,0,0,1,0,90), 3600,
139        'one hour difference between two calls to timelocal');
140
141     is(timelocal(1,2,3,1,0,100) - timelocal(1,2,3,31,11,99), 24 * 3600,
142        'one day difference between two calls to timelocal');
143
144     # Diff beween Jan 1, 1980 and Mar 1, 1980 = (31 + 29 = 60 days)
145     is(timegm(0,0,0, 1, 2, 80) - timegm(0,0,0, 1, 0, 80), 60 * 24 * 3600,
146        '60 day difference between two calls to timegm');
147 }
148
149 # bugid #19393
150 # At a DST transition, the clock skips forward, eg from 01:59:59 to
151 # 03:00:00. In this case, 02:00:00 is an invalid time, and should be
152 # treated like 03:00:00 rather than 01:00:00 - negative zone offsets used
153 # to do the latter
154 {
155     my $hour = (localtime(timelocal(0, 0, 2, 7, 3, 102)))[2];
156     # testers in US/Pacific should get 3,
157     # other testers should get 2
158     ok($hour == 2 || $hour == 3, 'hour should be 2 or 3');
159 }
160
161 for my $p (@years) {
162     my ( $year, $is_leap_year ) = @$p;
163
164     my $string = $is_leap_year ? 'is' : 'is not';
165     is( Time::Local::_is_leap_year($year), $is_leap_year,
166         "$year $string a leap year" );
167 }
168
169 SKIP:
170 {
171     skip 'this platform does not support negative epochs.', 1
172         unless $neg_epoch_ok;
173
174     eval { timegm(0,0,0,29,1,1904) };
175     is($@, '', 'no error with leap day of 1904');
176 }
177
178 if ($ENV{MAINTAINER}) {
179     require POSIX;
180
181     local $ENV{TZ} = 'Europe/Vienna';
182     POSIX::tzset();
183
184     # 2001-10-28 02:30:00 - could be either summer or standard time,
185     # prefer earlier of the two, in this case summer
186     my $time = timelocal(0, 30, 2, 28, 9, 101);
187     is($time, 1004229000,
188        'timelocal prefers earlier epoch in the presence of a DST change');
189
190     local $ENV{TZ} = 'America/Chicago';
191     POSIX::tzset();
192
193     # Same local time in America/Chicago.  There is a transition here
194     # as well.
195     $time = timelocal(0, 30, 1, 28, 9, 101);
196     is($time, 1004250600,
197        'timelocal prefers earlier epoch in the presence of a DST change');
198
199     $time = timelocal(0, 30, 2, 1, 3, 101);
200     is($time, 986113800,
201        'timelocal for non-existent time gives you the time one hour later');
202
203     local $ENV{TZ} = 'Australia/Sydney';
204     POSIX::tzset();
205     # 2001-03-25 02:30:00 in Australia/Sydney.  This is the transition
206     # _to_ summer time.  The southern hemisphere transitions are
207     # opposite those of the northern.
208     $time = timelocal(0, 30, 2, 25, 2, 101);
209     is($time, 985447800,
210        'timelocal prefers earlier epoch in the presence of a DST change');
211
212     $time = timelocal(0, 30, 2, 28, 9, 101);
213     is($time, 1004200200,
214        'timelocal for non-existent time gives you the time one hour later');
215
216     local $ENV{TZ} = 'Europe/London';
217     POSIX::tzset();
218     $time = timelocal( localtime(1111917720) );
219     is($time, 1111917720,
220        'timelocal for round trip bug on date of DST change for Europe/London');
221
222     # There is no 1:00 AM on this date, as it leaps forward to
223     # 2:00 on the DST change - this should return 2:00 per the
224     # docs.
225     is( ( localtime( timelocal( 0, 0, 1, 27, 2, 2005 ) ) )[2], 2,
226         'hour is 2 when given 1:00 AM on Europe/London date change' );
227
228     is( ( localtime( timelocal( 0, 0, 2, 27, 2, 2005 ) ) )[2], 2,
229         'hour is 2 when given 2:00 AM on Europe/London date change' );
230 }
231
232 if ($ENV{PERL_CORE}) {
233   package test;
234   require 'timelocal.pl';
235
236   # need to get ok() from main package
237   ::is(timegm(0,0,0,1,0,80), main::timegm(0,0,0,1,0,80),
238      'timegm in timelocal.pl');
239
240   ::is(timelocal(1,2,3,4,5,88), main::timelocal(1,2,3,4,5,88),
241      'timelocal in timelocal.pl');
242 }