This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Update ExtUtils-MakeMaker to CPAN version 6.72
[perl5.git] / cpan / ExtUtils-MakeMaker / lib / ExtUtils / Liblist / Kid.pm
1 package ExtUtils::Liblist::Kid;
2
3 # XXX Splitting this out into its own .pm is a temporary solution.
4
5 # This kid package is to be used by MakeMaker.  It will not work if
6 # $self is not a Makemaker.
7
8 use 5.006;
9
10 # Broken out of MakeMaker from version 4.11
11
12 use strict;
13 use warnings;
14 our $VERSION = '6.72';
15
16 use ExtUtils::MakeMaker::Config;
17 use Cwd 'cwd';
18 use File::Basename;
19 use File::Spec;
20
21 sub ext {
22     if    ( $^O eq 'VMS' )     { return &_vms_ext; }
23     elsif ( $^O eq 'MSWin32' ) { return &_win32_ext; }
24     else                       { return &_unix_os2_ext; }
25 }
26
27 sub _unix_os2_ext {
28     my ( $self, $potential_libs, $verbose, $give_libs ) = @_;
29     $verbose ||= 0;
30
31     if ( $^O =~ 'os2' and $Config{perllibs} ) {
32
33         # Dynamic libraries are not transitive, so we may need including
34         # the libraries linked against perl.dll again.
35
36         $potential_libs .= " " if $potential_libs;
37         $potential_libs .= $Config{perllibs};
38     }
39     return ( "", "", "", "", ( $give_libs ? [] : () ) ) unless $potential_libs;
40     warn "Potential libraries are '$potential_libs':\n" if $verbose;
41
42     my ( $so ) = $Config{so};
43     my ( $libs ) = defined $Config{perllibs} ? $Config{perllibs} : $Config{libs};
44     my $Config_libext = $Config{lib_ext} || ".a";
45     my $Config_dlext = $Config{dlext};
46
47     # compute $extralibs, $bsloadlibs and $ldloadlibs from
48     # $potential_libs
49     # this is a rewrite of Andy Dougherty's extliblist in perl
50
51     my ( @searchpath );    # from "-L/path" entries in $potential_libs
52     my ( @libpath ) = split " ", $Config{'libpth'};
53     my ( @ldloadlibs, @bsloadlibs, @extralibs, @ld_run_path, %ld_run_path_seen );
54     my ( @libs,       %libs_seen );
55     my ( $fullname,   @fullname );
56     my ( $pwd )   = cwd();    # from Cwd.pm
57     my ( $found ) = 0;
58
59     foreach my $thislib ( split ' ', $potential_libs ) {
60
61         # Handle possible linker path arguments.
62         if ( $thislib =~ s/^(-[LR]|-Wl,-R)// ) {    # save path flag type
63             my ( $ptype ) = $1;
64             unless ( -d $thislib ) {
65                 warn "$ptype$thislib ignored, directory does not exist\n"
66                   if $verbose;
67                 next;
68             }
69             my ( $rtype ) = $ptype;
70             if ( ( $ptype eq '-R' ) or ( $ptype eq '-Wl,-R' ) ) {
71                 if ( $Config{'lddlflags'} =~ /-Wl,-R/ ) {
72                     $rtype = '-Wl,-R';
73                 }
74                 elsif ( $Config{'lddlflags'} =~ /-R/ ) {
75                     $rtype = '-R';
76                 }
77             }
78             unless ( File::Spec->file_name_is_absolute( $thislib ) ) {
79                 warn "Warning: $ptype$thislib changed to $ptype$pwd/$thislib\n";
80                 $thislib = $self->catdir( $pwd, $thislib );
81             }
82             push( @searchpath, $thislib );
83             push( @extralibs,  "$ptype$thislib" );
84             push( @ldloadlibs, "$rtype$thislib" );
85             next;
86         }
87
88         # Handle possible library arguments.
89         unless ( $thislib =~ s/^-l// ) {
90             warn "Unrecognized argument in LIBS ignored: '$thislib'\n";
91             next;
92         }
93
94         my ( $found_lib ) = 0;
95         foreach my $thispth ( @searchpath, @libpath ) {
96
97             # Try to find the full name of the library.  We need this to
98             # determine whether it's a dynamically-loadable library or not.
99             # This tends to be subject to various os-specific quirks.
100             # For gcc-2.6.2 on linux (March 1995), DLD can not load
101             # .sa libraries, with the exception of libm.sa, so we
102             # deliberately skip them.
103             if ( @fullname = $self->lsdir( $thispth, "^\Qlib$thislib.$so.\E[0-9]+" ) ) {
104
105                 # Take care that libfoo.so.10 wins against libfoo.so.9.
106                 # Compare two libraries to find the most recent version
107                 # number.  E.g.  if you have libfoo.so.9.0.7 and
108                 # libfoo.so.10.1, first convert all digits into two
109                 # decimal places.  Then we'll add ".00" to the shorter
110                 # strings so that we're comparing strings of equal length
111                 # Thus we'll compare libfoo.so.09.07.00 with
112                 # libfoo.so.10.01.00.  Some libraries might have letters
113                 # in the version.  We don't know what they mean, but will
114                 # try to skip them gracefully -- we'll set any letter to
115                 # '0'.  Finally, sort in reverse so we can take the
116                 # first element.
117
118                 #TODO: iterate through the directory instead of sorting
119
120                 $fullname = "$thispth/" . (
121                     sort {
122                         my ( $ma ) = $a;
123                         my ( $mb ) = $b;
124                         $ma =~ tr/A-Za-z/0/s;
125                         $ma =~ s/\b(\d)\b/0$1/g;
126                         $mb =~ tr/A-Za-z/0/s;
127                         $mb =~ s/\b(\d)\b/0$1/g;
128                         while ( length( $ma ) < length( $mb ) ) { $ma .= ".00"; }
129                         while ( length( $mb ) < length( $ma ) ) { $mb .= ".00"; }
130
131                         # Comparison deliberately backwards
132                         $mb cmp $ma;
133                       } @fullname
134                 )[0];
135             }
136             elsif ( -f ( $fullname = "$thispth/lib$thislib.$so" )
137                 && ( ( $Config{'dlsrc'} ne "dl_dld.xs" ) || ( $thislib eq "m" ) ) )
138             {
139             }
140             elsif (-f ( $fullname = "$thispth/lib${thislib}_s$Config_libext" )
141                 && ( $Config{'archname'} !~ /RM\d\d\d-svr4/ )
142                 && ( $thislib .= "_s" ) )
143             {    # we must explicitly use _s version
144             }
145             elsif ( -f ( $fullname = "$thispth/lib$thislib$Config_libext" ) ) {
146             }
147             elsif ( defined( $Config_dlext )
148                 && -f ( $fullname = "$thispth/lib$thislib.$Config_dlext" ) )
149             {
150             }
151             elsif ( -f ( $fullname = "$thispth/$thislib$Config_libext" ) ) {
152             }
153             elsif ( -f ( $fullname = "$thispth/lib$thislib.dll$Config_libext" ) ) {
154             }
155             elsif ( $^O eq 'cygwin' && -f ( $fullname = "$thispth/$thislib.dll" ) ) {
156             }
157             elsif ( -f ( $fullname = "$thispth/Slib$thislib$Config_libext" ) ) {
158             }
159             elsif ($^O eq 'dgux'
160                 && -l ( $fullname = "$thispth/lib$thislib$Config_libext" )
161                 && readlink( $fullname ) =~ /^elink:/s )
162             {
163
164                 # Some of DG's libraries look like misconnected symbolic
165                 # links, but development tools can follow them.  (They
166                 # look like this:
167                 #
168                 #    libm.a -> elink:${SDE_PATH:-/usr}/sde/\
169                 #    ${TARGET_BINARY_INTERFACE:-m88kdgux}/usr/lib/libm.a
170                 #
171                 # , the compilation tools expand the environment variables.)
172             }
173             else {
174                 warn "$thislib not found in $thispth\n" if $verbose;
175                 next;
176             }
177             warn "'-l$thislib' found at $fullname\n" if $verbose;
178             push @libs, $fullname unless $libs_seen{$fullname}++;
179             $found++;
180             $found_lib++;
181
182             # Now update library lists
183
184             # what do we know about this library...
185             my $is_dyna = ( $fullname !~ /\Q$Config_libext\E\z/ );
186             my $in_perl = ( $libs =~ /\B-l\Q${thislib}\E\b/s );
187
188             # include the path to the lib once in the dynamic linker path
189             # but only if it is a dynamic lib and not in Perl itself
190             my ( $fullnamedir ) = dirname( $fullname );
191             push @ld_run_path, $fullnamedir
192               if $is_dyna
193                   && !$in_perl
194                   && !$ld_run_path_seen{$fullnamedir}++;
195
196             # Do not add it into the list if it is already linked in
197             # with the main perl executable.
198             # We have to special-case the NeXT, because math and ndbm
199             # are both in libsys_s
200             unless (
201                 $in_perl
202                 || ( $Config{'osname'} eq 'next'
203                     && ( $thislib eq 'm' || $thislib eq 'ndbm' ) )
204               )
205             {
206                 push( @extralibs, "-l$thislib" );
207             }
208
209             # We might be able to load this archive file dynamically
210             if (   ( $Config{'dlsrc'} =~ /dl_next/ && $Config{'osvers'} lt '4_0' )
211                 || ( $Config{'dlsrc'} =~ /dl_dld/ ) )
212             {
213
214                 # We push -l$thislib instead of $fullname because
215                 # it avoids hardwiring a fixed path into the .bs file.
216                 # Mkbootstrap will automatically add dl_findfile() to
217                 # the .bs file if it sees a name in the -l format.
218                 # USE THIS, when dl_findfile() is fixed:
219                 # push(@bsloadlibs, "-l$thislib");
220                 # OLD USE WAS while checking results against old_extliblist
221                 push( @bsloadlibs, "$fullname" );
222             }
223             else {
224                 if ( $is_dyna ) {
225
226                     # For SunOS4, do not add in this shared library if
227                     # it is already linked in the main perl executable
228                     push( @ldloadlibs, "-l$thislib" )
229                       unless ( $in_perl and $^O eq 'sunos' );
230                 }
231                 else {
232                     push( @ldloadlibs, "-l$thislib" );
233                 }
234             }
235             last;    # found one here so don't bother looking further
236         }
237         warn "Warning (mostly harmless): " . "No library found for -l$thislib\n"
238           unless $found_lib > 0;
239     }
240
241     unless ( $found ) {
242         return ( '', '', '', '', ( $give_libs ? \@libs : () ) );
243     }
244     else {
245         return ( "@extralibs", "@bsloadlibs", "@ldloadlibs", join( ":", @ld_run_path ), ( $give_libs ? \@libs : () ) );
246     }
247 }
248
249 sub _win32_ext {
250
251     require Text::ParseWords;
252
253     my ( $self, $potential_libs, $verbose, $give_libs ) = @_;
254     $verbose ||= 0;
255
256     # If user did not supply a list, we punt.
257     # (caller should probably use the list in $Config{libs})
258     return ( "", "", "", "", ( $give_libs ? [] : () ) ) unless $potential_libs;
259
260     # TODO: make this use MM_Win32.pm's compiler detection
261     my %libs_seen;
262     my @extralibs;
263     my $cc = $Config{cc} || '';
264     my $VC = $cc =~ /\bcl\b/i;
265     my $GC = $cc =~ /\bgcc\b/i;
266
267     my $libext     = _win32_lib_extensions();
268     my @searchpath = ( '' );                                    # from "-L/path" entries in $potential_libs
269     my @libpath    = _win32_default_search_paths( $VC, $GC );
270     my $pwd        = cwd();                                     # from Cwd.pm
271     my $search     = 1;
272
273     # compute @extralibs from $potential_libs
274     my @lib_search_list = _win32_make_lib_search_list( $potential_libs, $verbose );
275     for ( @lib_search_list ) {
276
277         my $thislib = $_;
278
279         # see if entry is a flag
280         if ( /^:\w+$/ ) {
281             $search = 0 if lc eq ':nosearch';
282             $search = 1 if lc eq ':search';
283             _debug( "Ignoring unknown flag '$thislib'\n", $verbose ) if !/^:(no)?(search|default)$/i;
284             next;
285         }
286
287         # if searching is disabled, do compiler-specific translations
288         unless ( $search ) {
289             s/^-l(.+)$/$1.lib/ unless $GC;
290             s/^-L/-libpath:/ if $VC;
291             push( @extralibs, $_ );
292             next;
293         }
294
295         # handle possible linker path arguments
296         if ( s/^-L// and not -d ) {
297             _debug( "$thislib ignored, directory does not exist\n", $verbose );
298             next;
299         }
300         elsif ( -d ) {
301             unless ( File::Spec->file_name_is_absolute( $_ ) ) {
302                 warn "Warning: '$thislib' changed to '-L$pwd/$_'\n";
303                 $_ = $self->catdir( $pwd, $_ );
304             }
305             push( @searchpath, $_ );
306             next;
307         }
308
309         my @paths = ( @searchpath, @libpath );
310         my ( $fullname, $path ) = _win32_search_file( $thislib, $libext, \@paths, $verbose, $GC );
311
312         if ( !$fullname ) {
313             warn "Warning (mostly harmless): No library found for $thislib\n";
314             next;
315         }
316
317         _debug( "'$thislib' found as '$fullname'\n", $verbose );
318         push( @extralibs, $fullname );
319         $libs_seen{$fullname} = 1 if $path;    # why is this a special case?
320     }
321
322     my @libs = keys %libs_seen;
323
324     return ( '', '', '', '', ( $give_libs ? \@libs : () ) ) unless @extralibs;
325
326     # make sure paths with spaces are properly quoted
327     @extralibs = map { /\s/ ? qq["$_"] : $_ } @extralibs;
328     @libs      = map { /\s/ ? qq["$_"] : $_ } @libs;
329
330     my $lib = join( ' ', @extralibs );
331
332     # normalize back to backward slashes (to help braindead tools)
333     # XXX this may break equally braindead GNU tools that don't understand
334     # backslashes, either.  Seems like one can't win here.  Cursed be CP/M.
335     $lib =~ s,/,\\,g;
336
337     _debug( "Result: $lib\n", $verbose );
338     wantarray ? ( $lib, '', $lib, '', ( $give_libs ? \@libs : () ) ) : $lib;
339 }
340
341 sub _win32_make_lib_search_list {
342     my ( $potential_libs, $verbose ) = @_;
343
344     # If Config.pm defines a set of default libs, we always
345     # tack them on to the user-supplied list, unless the user
346     # specified :nodefault
347     my $libs = $Config{'perllibs'};
348     $potential_libs = join( ' ', $potential_libs, $libs ) if $libs and $potential_libs !~ /:nodefault/i;
349     _debug( "Potential libraries are '$potential_libs':\n", $verbose );
350
351     $potential_libs =~ s,\\,/,g;    # normalize to forward slashes
352
353     my @list = Text::ParseWords::quotewords( '\s+', 0, $potential_libs );
354
355     return @list;
356 }
357
358 sub _win32_default_search_paths {
359     my ( $VC, $GC ) = @_;
360
361     my $libpth = $Config{'libpth'} || '';
362     $libpth =~ s,\\,/,g;            # normalize to forward slashes
363
364     my @libpath = Text::ParseWords::quotewords( '\s+', 0, $libpth );
365     push @libpath, "$Config{installarchlib}/CORE";    # add "$Config{installarchlib}/CORE" to default search path
366
367     push @libpath, split /;/, $ENV{LIB}          if $VC and $ENV{LIB};
368     push @libpath, split /;/, $ENV{LIBRARY_PATH} if $GC and $ENV{LIBRARY_PATH};
369
370     return @libpath;
371 }
372
373 sub _win32_search_file {
374     my ( $thislib, $libext, $paths, $verbose, $GC ) = @_;
375
376     my @file_list = _win32_build_file_list( $thislib, $GC, $libext );
377
378     for my $lib_file ( @file_list ) {
379         for my $path ( @{$paths} ) {
380             my $fullname = $lib_file;
381             $fullname = "$path\\$fullname" if $path;
382
383             return ( $fullname, $path ) if -f $fullname;
384
385             _debug( "'$thislib' not found as '$fullname'\n", $verbose );
386         }
387     }
388
389     return;
390 }
391
392 sub _win32_build_file_list {
393     my ( $lib, $GC, $extensions ) = @_;
394
395     my @pre_fixed = _win32_build_prefixed_list( $lib, $GC );
396     return map _win32_attach_extensions( $_, $extensions ), @pre_fixed;
397 }
398
399 sub _win32_build_prefixed_list {
400     my ( $lib, $GC ) = @_;
401
402     return $lib if $lib !~ s/^-l//;
403     return $lib if $lib =~ /^lib/ and !$GC;
404
405     ( my $no_prefix = $lib ) =~ s/^lib//i;
406     $lib = "lib$lib" if $no_prefix eq $lib;
407
408     return ( $lib, $no_prefix ) if $GC;
409     return ( $no_prefix, $lib );
410 }
411
412 sub _win32_attach_extensions {
413     my ( $lib, $extensions ) = @_;
414     return map _win32_try_attach_extension( $lib, $_ ), @{$extensions};
415 }
416
417 sub _win32_try_attach_extension {
418     my ( $lib, $extension ) = @_;
419
420     return $lib if $lib =~ /\Q$extension\E$/i;
421     return "$lib$extension";
422 }
423
424 sub _win32_lib_extensions {
425     my %extensions;
426     $extensions{ $Config{'lib_ext'} } = 1 if $Config{'lib_ext'};
427     $extensions{".dll.a"} = 1 if $extensions{".a"};
428     $extensions{".lib"}   = 1;
429     return [ keys %extensions ];
430 }
431
432 sub _debug {
433     my ( $message, $verbose ) = @_;
434     return if !$verbose;
435     warn $message;
436     return;
437 }
438
439 sub _vms_ext {
440     my ( $self, $potential_libs, $verbose, $give_libs ) = @_;
441     $verbose ||= 0;
442
443     my ( @crtls, $crtlstr );
444     @crtls = ( ( $Config{'ldflags'} =~ m-/Debug-i ? $Config{'dbgprefix'} : '' ) . 'PerlShr/Share' );
445     push( @crtls, grep { not /\(/ } split /\s+/, $Config{'perllibs'} );
446     push( @crtls, grep { not /\(/ } split /\s+/, $Config{'libc'} );
447
448     # In general, we pass through the basic libraries from %Config unchanged.
449     # The one exception is that if we're building in the Perl source tree, and
450     # a library spec could be resolved via a logical name, we go to some trouble
451     # to insure that the copy in the local tree is used, rather than one to
452     # which a system-wide logical may point.
453     if ( $self->{PERL_SRC} ) {
454         my ( $locspec, $type );
455         foreach my $lib ( @crtls ) {
456             if ( ( $locspec, $type ) = $lib =~ m{^([\w\$-]+)(/\w+)?} and $locspec =~ /perl/i ) {
457                 if    ( lc $type eq '/share' )   { $locspec .= $Config{'exe_ext'}; }
458                 elsif ( lc $type eq '/library' ) { $locspec .= $Config{'lib_ext'}; }
459                 else                             { $locspec .= $Config{'obj_ext'}; }
460                 $locspec = $self->catfile( $self->{PERL_SRC}, $locspec );
461                 $lib = "$locspec$type" if -e $locspec;
462             }
463         }
464     }
465     $crtlstr = @crtls ? join( ' ', @crtls ) : '';
466
467     unless ( $potential_libs ) {
468         warn "Result:\n\tEXTRALIBS: \n\tLDLOADLIBS: $crtlstr\n" if $verbose;
469         return ( '', '', $crtlstr, '', ( $give_libs ? [] : () ) );
470     }
471
472     my ( %found, @fndlibs, $ldlib );
473     my $cwd = cwd();
474     my ( $so, $lib_ext, $obj_ext ) = @Config{ 'so', 'lib_ext', 'obj_ext' };
475
476     # List of common Unix library names and their VMS equivalents
477     # (VMS equivalent of '' indicates that the library is automatically
478     # searched by the linker, and should be skipped here.)
479     my ( @flibs, %libs_seen );
480     my %libmap = (
481         'm'      => '',
482         'f77'    => '',
483         'F77'    => '',
484         'V77'    => '',
485         'c'      => '',
486         'malloc' => '',
487         'crypt'  => '',
488         'resolv' => '',
489         'c_s'    => '',
490         'socket' => '',
491         'X11'    => 'DECW$XLIBSHR',
492         'Xt'     => 'DECW$XTSHR',
493         'Xm'     => 'DECW$XMLIBSHR',
494         'Xmu'    => 'DECW$XMULIBSHR'
495     );
496     if ( $Config{'vms_cc_type'} ne 'decc' ) { $libmap{'curses'} = 'VAXCCURSE'; }
497
498     warn "Potential libraries are '$potential_libs'\n" if $verbose;
499
500     # First, sort out directories and library names in the input
501     my ( @dirs, @libs );
502     foreach my $lib ( split ' ', $potential_libs ) {
503         push( @dirs, $1 ),   next if $lib =~ /^-L(.*)/;
504         push( @dirs, $lib ), next if $lib =~ /[:>\]]$/;
505         push( @dirs, $lib ), next if -d $lib;
506         push( @libs, $1 ),   next if $lib =~ /^-l(.*)/;
507         push( @libs, $lib );
508     }
509     push( @dirs, split( ' ', $Config{'libpth'} ) );
510
511     # Now make sure we've got VMS-syntax absolute directory specs
512     # (We don't, however, check whether someone's hidden a relative
513     # path in a logical name.)
514     foreach my $dir ( @dirs ) {
515         unless ( -d $dir ) {
516             warn "Skipping nonexistent Directory $dir\n" if $verbose > 1;
517             $dir = '';
518             next;
519         }
520         warn "Resolving directory $dir\n" if $verbose;
521         if ( File::Spec->file_name_is_absolute( $dir ) ) {
522             $dir = $self->fixpath( $dir, 1 );
523         }
524         else {
525             $dir = $self->catdir( $cwd, $dir );
526         }
527     }
528     @dirs = grep { length( $_ ) } @dirs;
529     unshift( @dirs, '' );    # Check each $lib without additions first
530
531   LIB: foreach my $lib ( @libs ) {
532         if ( exists $libmap{$lib} ) {
533             next unless length $libmap{$lib};
534             $lib = $libmap{$lib};
535         }
536
537         my ( @variants, $cand );
538         my ( $ctype ) = '';
539
540         # If we don't have a file type, consider it a possibly abbreviated name and
541         # check for common variants.  We try these first to grab libraries before
542         # a like-named executable image (e.g. -lperl resolves to perlshr.exe
543         # before perl.exe).
544         if ( $lib !~ /\.[^:>\]]*$/ ) {
545             push( @variants, "${lib}shr", "${lib}rtl", "${lib}lib" );
546             push( @variants, "lib$lib" ) if $lib !~ /[:>\]]/;
547         }
548         push( @variants, $lib );
549         warn "Looking for $lib\n" if $verbose;
550         foreach my $variant ( @variants ) {
551             my ( $fullname, $name );
552
553             foreach my $dir ( @dirs ) {
554                 my ( $type );
555
556                 $name = "$dir$variant";
557                 warn "\tChecking $name\n" if $verbose > 2;
558                 $fullname = VMS::Filespec::rmsexpand( $name );
559                 if ( defined $fullname and -f $fullname ) {
560
561                     # It's got its own suffix, so we'll have to figure out the type
562                     if    ( $fullname =~ /(?:$so|exe)$/i )      { $type = 'SHR'; }
563                     elsif ( $fullname =~ /(?:$lib_ext|olb)$/i ) { $type = 'OLB'; }
564                     elsif ( $fullname =~ /(?:$obj_ext|obj)$/i ) {
565                         warn "Warning (mostly harmless): " . "Plain object file $fullname found in library list\n";
566                         $type = 'OBJ';
567                     }
568                     else {
569                         warn "Warning (mostly harmless): " . "Unknown library type for $fullname; assuming shared\n";
570                         $type = 'SHR';
571                     }
572                 }
573                 elsif (-f ( $fullname = VMS::Filespec::rmsexpand( $name, $so ) )
574                     or -f ( $fullname = VMS::Filespec::rmsexpand( $name, '.exe' ) ) )
575                 {
576                     $type = 'SHR';
577                     $name = $fullname unless $fullname =~ /exe;?\d*$/i;
578                 }
579                 elsif (
580                     not length( $ctype ) and    # If we've got a lib already,
581                                                 # don't bother
582                     ( -f ( $fullname = VMS::Filespec::rmsexpand( $name, $lib_ext ) ) or -f ( $fullname = VMS::Filespec::rmsexpand( $name, '.olb' ) ) )
583                   )
584                 {
585                     $type = 'OLB';
586                     $name = $fullname unless $fullname =~ /olb;?\d*$/i;
587                 }
588                 elsif (
589                     not length( $ctype ) and    # If we've got a lib already,
590                                                 # don't bother
591                     ( -f ( $fullname = VMS::Filespec::rmsexpand( $name, $obj_ext ) ) or -f ( $fullname = VMS::Filespec::rmsexpand( $name, '.obj' ) ) )
592                   )
593                 {
594                     warn "Warning (mostly harmless): " . "Plain object file $fullname found in library list\n";
595                     $type = 'OBJ';
596                     $name = $fullname unless $fullname =~ /obj;?\d*$/i;
597                 }
598                 if ( defined $type ) {
599                     $ctype = $type;
600                     $cand  = $name;
601                     last if $ctype eq 'SHR';
602                 }
603             }
604             if ( $ctype ) {
605
606                 # This has to precede any other CRTLs, so just make it first
607                 if ( $cand eq 'VAXCCURSE' ) { unshift @{ $found{$ctype} }, $cand; }
608                 else                        { push @{ $found{$ctype} }, $cand; }
609                 warn "\tFound as $cand (really $fullname), type $ctype\n"
610                   if $verbose > 1;
611                 push @flibs, $name unless $libs_seen{$fullname}++;
612                 next LIB;
613             }
614         }
615         warn "Warning (mostly harmless): " . "No library found for $lib\n";
616     }
617
618     push @fndlibs, @{ $found{OBJ} } if exists $found{OBJ};
619     push @fndlibs, map { "$_/Library" } @{ $found{OLB} } if exists $found{OLB};
620     push @fndlibs, map { "$_/Share" } @{ $found{SHR} }   if exists $found{SHR};
621     my $lib = join( ' ', @fndlibs );
622
623     $ldlib = $crtlstr ? "$lib $crtlstr" : $lib;
624     warn "Result:\n\tEXTRALIBS: $lib\n\tLDLOADLIBS: $ldlib\n" if $verbose;
625     wantarray ? ( $lib, '', $ldlib, '', ( $give_libs ? \@flibs : () ) ) : $lib;
626 }
627
628 1;