This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
ext/re/re.pm: Fix up setting debug option defaults
[perl5.git] / ext / re / re.pm
1 package re;
2
3 # pragma for controlling the regexp engine
4 use strict;
5 use warnings;
6
7 our $VERSION     = "0.39";
8 our @ISA         = qw(Exporter);
9 our @EXPORT_OK   = ('regmust',
10                     qw(is_regexp regexp_pattern
11                        regname regnames regnames_count));
12 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
13
14 my %bitmask = (
15     taint   => 0x00100000, # HINT_RE_TAINT
16     eval    => 0x00200000, # HINT_RE_EVAL
17 );
18
19 my $flags_hint = 0x02000000; # HINT_RE_FLAGS
20 my $PMMOD_SHIFT = 0;
21 my %reflags = (
22     m => 1 << ($PMMOD_SHIFT + 0),
23     s => 1 << ($PMMOD_SHIFT + 1),
24     i => 1 << ($PMMOD_SHIFT + 2),
25     x => 1 << ($PMMOD_SHIFT + 3),
26    xx => 1 << ($PMMOD_SHIFT + 4),
27     n => 1 << ($PMMOD_SHIFT + 5),
28     p => 1 << ($PMMOD_SHIFT + 6),
29     strict => 1 << ($PMMOD_SHIFT + 10),
30 # special cases:
31     d => 0,
32     l => 1,
33     u => 2,
34     a => 3,
35     aa => 4,
36 );
37
38 sub setcolor {
39  eval {                         # Ignore errors
40   require Term::Cap;
41
42   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
43   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
44   my @props = split /,/, $props;
45   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
46
47   $colors =~ s/\0//g;
48   $ENV{PERL_RE_COLORS} = $colors;
49  };
50  if ($@) {
51     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
52  }
53
54 }
55
56 my %flags = (
57     COMPILE           => 0x0000FF,
58     PARSE             => 0x000001,
59     OPTIMISE          => 0x000002,
60     TRIEC             => 0x000004,
61     DUMP              => 0x000008,
62     FLAGS             => 0x000010,
63     TEST              => 0x000020,
64
65     EXECUTE           => 0x00FF00,
66     INTUIT            => 0x000100,
67     MATCH             => 0x000200,
68     TRIEE             => 0x000400,
69
70     EXTRA             => 0x3FF0000,
71     TRIEM             => 0x0010000,
72     OFFSETS           => 0x0020000,
73     OFFSETSDBG        => 0x0040000,
74     STATE             => 0x0080000,
75     OPTIMISEM         => 0x0100000,
76     STACK             => 0x0280000,
77     BUFFERS           => 0x0400000,
78     GPOS              => 0x0800000,
79     DUMP_PRE_OPTIMIZE => 0x1000000,
80     WILDCARD          => 0x2000000,
81 );
82 $flags{ALL} = -1 & ~($flags{OFFSETS}
83                     |$flags{OFFSETSDBG}
84                     |$flags{BUFFERS}
85                     |$flags{DUMP_PRE_OPTIMIZE}
86                     |$flags{WILDCARD}
87                     );
88 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
89 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE} | $flags{GPOS};
90 $flags{More} = $flags{MORE} =
91                     $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
92 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
93 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
94
95 if (defined &DynaLoader::boot_DynaLoader) {
96     require XSLoader;
97     XSLoader::load();
98 }
99 # else we're miniperl
100 # We need to work for miniperl, because the XS toolchain uses Text::Wrap, which
101 # uses re 'taint'.
102
103 sub _load_unload {
104     my ($on)= @_;
105     if ($on) {
106         # We call install() every time, as if we didn't, we wouldn't
107         # "see" any changes to the color environment var since
108         # the last time it was called.
109
110         # install() returns an integer, which if casted properly
111         # in C resolves to a structure containing the regexp
112         # hooks. Setting it to a random integer will guarantee
113         # segfaults.
114         $^H{regcomp} = install();
115     } else {
116         delete $^H{regcomp};
117     }
118 }
119
120 sub bits {
121     my $on = shift;
122     my $bits = 0;
123     my $turning_all_off = ! @_ && ! $on;
124     my $seen_Debug = 0;
125     if ($turning_all_off) {
126
127         # Pretend were called with certain parameters, which are best dealt
128         # with that way.
129         push @_, keys %bitmask; # taint and eval
130         push @_, 'strict';
131     }
132
133     # Process each subpragma parameter
134    ARG:
135     foreach my $idx (0..$#_){
136         my $s=$_[$idx];
137         if ($s eq 'Debug' or $s eq 'Debugcolor') {
138             if (! $seen_Debug) {
139                 $seen_Debug = 1;
140
141                 # Reset to nothing, and then add what follows.  $seen_Debug
142                 # allows, though unlikely someone would do it, more than one
143                 # Debug and flags in the arguments
144                 ${^RE_DEBUG_FLAGS} = 0;
145             }
146             setcolor() if $s =~/color/i;
147             for my $idx ($idx+1..$#_) {
148                 if ($flags{$_[$idx]}) {
149                     if ($on) {
150                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
151                     } else {
152                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
153                     }
154                 } else {
155                     require Carp;
156                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
157                                join(", ",sort keys %flags ) );
158                 }
159             }
160             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
161             last;
162         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
163
164             # These default flags should be kept in sync with the same values
165             # in regcomp.h
166             ${^RE_DEBUG_FLAGS} = $flags{'EXECUTE'} | $flags{'DUMP'};
167             setcolor() if $s =~/color/i;
168             _load_unload($on);
169             last;
170         } elsif (exists $bitmask{$s}) {
171             $bits |= $bitmask{$s};
172         } elsif ($EXPORT_OK{$s}) {
173             require Exporter;
174             re->export_to_level(2, 're', $s);
175         } elsif ($s eq 'strict') {
176             if ($on) {
177                 $^H{reflags} |= $reflags{$s};
178                 warnings::warnif('experimental::re_strict',
179                                  "\"use re 'strict'\" is experimental");
180
181                 # Turn on warnings if not already done.
182                 if (! warnings::enabled('regexp')) {
183                     require warnings;
184                     warnings->import('regexp');
185                     $^H{re_strict} = 1;
186                 }
187             }
188             else {
189                 $^H{reflags} &= ~$reflags{$s} if $^H{reflags};
190
191                 # Turn off warnings if we turned them on.
192                 warnings->unimport('regexp') if $^H{re_strict};
193             }
194             if ($^H{reflags}) {
195                 $^H |= $flags_hint;
196             }
197             else {
198                 $^H &= ~$flags_hint;
199             }
200         } elsif ($s =~ s/^\///) {
201             my $reflags = $^H{reflags} || 0;
202             my $seen_charset;
203             my $x_count = 0;
204             while ($s =~ m/( . )/gx) {
205                 local $_ = $1;
206                 if (/[adul]/) {
207                     # The 'a' may be repeated; hide this from the rest of the
208                     # code by counting and getting rid of all of them, then
209                     # changing to 'aa' if there is a repeat.
210                     if ($_ eq 'a') {
211                         my $sav_pos = pos $s;
212                         my $a_count = $s =~ s/a//g;
213                         pos $s = $sav_pos - 1;  # -1 because got rid of the 'a'
214                         if ($a_count > 2) {
215                             require Carp;
216                             Carp::carp(
217                             qq 'The "a" flag may only appear a maximum of twice'
218                             );
219                         }
220                         elsif ($a_count == 2) {
221                             $_ = 'aa';
222                         }
223                     }
224                     if ($on) {
225                         if ($seen_charset) {
226                             require Carp;
227                             if ($seen_charset ne $_) {
228                                 Carp::carp(
229                                 qq 'The "$seen_charset" and "$_" flags '
230                                 .qq 'are exclusive'
231                                 );
232                             }
233                             else {
234                                 Carp::carp(
235                                 qq 'The "$seen_charset" flag may not appear '
236                                 .qq 'twice'
237                                 );
238                             }
239                         }
240                         $^H{reflags_charset} = $reflags{$_};
241                         $seen_charset = $_;
242                     }
243                     else {
244                         delete $^H{reflags_charset}
245                                      if defined $^H{reflags_charset}
246                                         && $^H{reflags_charset} == $reflags{$_};
247                     }
248                 } elsif (exists $reflags{$_}) {
249                     if ($_ eq 'x') {
250                         $x_count++;
251                         if ($x_count > 2) {
252                             require Carp;
253                             Carp::carp(
254                             qq 'The "x" flag may only appear a maximum of twice'
255                             );
256                         }
257                         elsif ($x_count == 2) {
258                             $_ = 'xx';  # First time through got the /x
259                         }
260                     }
261
262                     $on
263                       ? $reflags |= $reflags{$_}
264                       : ($reflags &= ~$reflags{$_});
265                 } else {
266                     require Carp;
267                     Carp::carp(
268                      qq'Unknown regular expression flag "$_"'
269                     );
270                     next ARG;
271                 }
272             }
273             ($^H{reflags} = $reflags or defined $^H{reflags_charset})
274                             ? $^H |= $flags_hint
275                             : ($^H &= ~$flags_hint);
276         } else {
277             require Carp;
278             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
279                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
280                        ")");
281         }
282     }
283
284     if ($turning_all_off) {
285         _load_unload(0);
286         $^H{reflags} = 0;
287         $^H{reflags_charset} = 0;
288         $^H &= ~$flags_hint;
289     }
290
291     $bits;
292 }
293
294 sub import {
295     shift;
296     $^H |= bits(1, @_);
297 }
298
299 sub unimport {
300     shift;
301     $^H &= ~ bits(0, @_);
302 }
303
304 1;
305
306 __END__
307
308 =head1 NAME
309
310 re - Perl pragma to alter regular expression behaviour
311
312 =head1 SYNOPSIS
313
314     use re 'taint';
315     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
316
317     $pat = '(?{ $foo = 1 })';
318     use re 'eval';
319     /foo${pat}bar/;                # won't fail (when not under -T
320                                    # switch)
321
322     {
323         no re 'taint';             # the default
324         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
325
326         no re 'eval';              # the default
327         /foo${pat}bar/;            # disallowed (with or without -T
328                                    # switch)
329     }
330
331     use re 'strict';               # Raise warnings for more conditions
332
333     use re '/ix';
334     "FOO" =~ / foo /; # /ix implied
335     no re '/x';
336     "FOO" =~ /foo/; # just /i implied
337
338     use re 'debug';                # output debugging info during
339     /^(.*)$/s;                     # compile and run time
340
341
342     use re 'debugcolor';           # same as 'debug', but with colored
343                                    # output
344     ...
345
346     use re qw(Debug All);          # Same as "use re 'debug'", but you
347                                    # can use "Debug" with things other
348                                    # than 'All'
349     use re qw(Debug More);         # 'All' plus output more details
350     no re qw(Debug ALL);           # Turn on (almost) all re debugging
351                                    # in this scope
352
353     use re qw(is_regexp regexp_pattern); # import utility functions
354     my ($pat,$mods)=regexp_pattern(qr/foo/i);
355     if (is_regexp($obj)) {
356         print "Got regexp: ",
357             scalar regexp_pattern($obj); # just as perl would stringify
358     }                                    # it but no hassle with blessed
359                                          # re's.
360
361 (We use $^X in these examples because it's tainted by default.)
362
363 =head1 DESCRIPTION
364
365 =head2 'taint' mode
366
367 When C<use re 'taint'> is in effect, and a tainted string is the target
368 of a regexp, the regexp memories (or values returned by the m// operator
369 in list context) are tainted.  This feature is useful when regexp operations
370 on tainted data aren't meant to extract safe substrings, but to perform
371 other transformations.
372
373 =head2 'eval' mode
374
375 When C<use re 'eval'> is in effect, a regexp is allowed to contain
376 C<(?{ ... })> zero-width assertions and C<(??{ ... })> postponed
377 subexpressions that are derived from variable interpolation, rather than
378 appearing literally within the regexp.  That is normally disallowed, since
379 it is a
380 potential security risk.  Note that this pragma is ignored when the regular
381 expression is obtained from tainted data, i.e.  evaluation is always
382 disallowed with tainted regular expressions.  See L<perlre/(?{ code })> 
383 and L<perlre/(??{ code })>.
384
385 For the purpose of this pragma, interpolation of precompiled regular
386 expressions (i.e., the result of C<qr//>) is I<not> considered variable
387 interpolation.  Thus:
388
389     /foo${pat}bar/
390
391 I<is> allowed if $pat is a precompiled regular expression, even
392 if $pat contains C<(?{ ... })> assertions or C<(??{ ... })> subexpressions.
393
394 =head2 'strict' mode
395
396 Note that this is an experimental feature which may be changed or removed in a
397 future Perl release.
398
399 When C<use re 'strict'> is in effect, stricter checks are applied than
400 otherwise when compiling regular expressions patterns.  These may cause more
401 warnings to be raised than otherwise, and more things to be fatal instead of
402 just warnings.  The purpose of this is to find and report at compile time some
403 things, which may be legal, but have a reasonable possibility of not being the
404 programmer's actual intent.  This automatically turns on the C<"regexp">
405 warnings category (if not already on) within its scope.
406
407 As an example of something that is caught under C<"strict'>, but not
408 otherwise, is the pattern
409
410  qr/\xABC/
411
412 The C<"\x"> construct without curly braces should be followed by exactly two
413 hex digits; this one is followed by three.  This currently evaluates as
414 equivalent to
415
416  qr/\x{AB}C/
417
418 that is, the character whose code point value is C<0xAB>, followed by the
419 letter C<C>.  But since C<C> is a a hex digit, there is a reasonable chance
420 that the intent was
421
422  qr/\x{ABC}/
423
424 that is the single character at C<0xABC>.  Under C<'strict'> it is an error to
425 not follow C<\x> with exactly two hex digits.  When not under C<'strict'> a
426 warning is generated if there is only one hex digit, and no warning is raised
427 if there are more than two.
428
429 It is expected that what exactly C<'strict'> does will evolve over time as we
430 gain experience with it.  This means that programs that compile under it in
431 today's Perl may not compile, or may have more or fewer warnings, in future
432 Perls.  There is no backwards compatibility promises with regards to it.  Also
433 there are already proposals for an alternate syntax for enabling it.  For
434 these reasons, using it will raise a C<experimental::re_strict> class warning,
435 unless that category is turned off.
436
437 Note that if a pattern compiled within C<'strict'> is recompiled, say by
438 interpolating into another pattern, outside of C<'strict'>, it is not checked
439 again for strictness.  This is because if it works under strict it must work
440 under non-strict.
441
442 =head2 '/flags' mode
443
444 When C<use re '/I<flags>'> is specified, the given I<flags> are automatically
445 added to every regular expression till the end of the lexical scope.
446 I<flags> can be any combination of
447 C<'a'>,
448 C<'aa'>,
449 C<'d'>,
450 C<'i'>,
451 C<'l'>,
452 C<'m'>,
453 C<'n'>,
454 C<'p'>,
455 C<'s'>,
456 C<'u'>,
457 C<'x'>,
458 and/or
459 C<'xx'>.
460
461 C<no re '/I<flags>'> will turn off the effect of C<use re '/I<flags>'> for the
462 given flags.
463
464 For example, if you want all your regular expressions to have /msxx on by
465 default, simply put
466
467     use re '/msxx';
468
469 at the top of your code.
470
471 The character set C</adul> flags cancel each other out. So, in this example,
472
473     use re "/u";
474     "ss" =~ /\xdf/;
475     use re "/d";
476     "ss" =~ /\xdf/;
477
478 the second C<use re> does an implicit C<no re '/u'>.
479
480 Similarly,
481
482     use re "/xx";   # Doubled-x
483     ...
484     use re "/x";    # Single x from here on
485     ...
486
487 Turning on one of the character set flags with C<use re> takes precedence over the
488 C<locale> pragma and the 'unicode_strings' C<feature>, for regular
489 expressions. Turning off one of these flags when it is active reverts to
490 the behaviour specified by whatever other pragmata are in scope. For
491 example:
492
493     use feature "unicode_strings";
494     no re "/u"; # does nothing
495     use re "/l";
496     no re "/l"; # reverts to unicode_strings behaviour
497
498 =head2 'debug' mode
499
500 When C<use re 'debug'> is in effect, perl emits debugging messages when
501 compiling and using regular expressions.  The output is the same as that
502 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
503 B<-Dr> switch. It may be quite voluminous depending on the complexity
504 of the match.  Using C<debugcolor> instead of C<debug> enables a
505 form of output that can be used to get a colorful display on terminals
506 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
507 comma-separated list of C<termcap> properties to use for highlighting
508 strings on/off, pre-point part on/off.
509 See L<perldebug/"Debugging Regular Expressions"> for additional info.
510
511 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
512 lexically scoped, as the other directives are.  However they have both
513 compile-time and run-time effects.
514
515 See L<perlmodlib/Pragmatic Modules>.
516
517 =head2 'Debug' mode
518
519 Similarly C<use re 'Debug'> produces debugging output, the difference
520 being that it allows the fine tuning of what debugging output will be
521 emitted. Options are divided into three groups, those related to
522 compilation, those related to execution and those related to special
523 purposes. The options are as follows:
524
525 =over 4
526
527 =item Compile related options
528
529 =over 4
530
531 =item COMPILE
532
533 Turns on all non-extra compile related debug options.
534
535 =item PARSE
536
537 Turns on debug output related to the process of parsing the pattern.
538
539 =item OPTIMISE
540
541 Enables output related to the optimisation phase of compilation.
542
543 =item TRIEC
544
545 Detailed info about trie compilation.
546
547 =item DUMP
548
549 Dump the final program out after it is compiled and optimised.
550
551 =item FLAGS
552
553 Dump the flags associated with the program
554
555 =item TEST
556
557 Print output intended for testing the internals of the compile process
558
559 =back
560
561 =item Execute related options
562
563 =over 4
564
565 =item EXECUTE
566
567 Turns on all non-extra execute related debug options.
568
569 =item MATCH
570
571 Turns on debugging of the main matching loop.
572
573 =item TRIEE
574
575 Extra debugging of how tries execute.
576
577 =item INTUIT
578
579 Enable debugging of start-point optimisations.
580
581 =back
582
583 =item Extra debugging options
584
585 =over 4
586
587 =item EXTRA
588
589 Turns on all "extra" debugging options.
590
591 =item BUFFERS
592
593 Enable debugging the capture group storage during match. Warning,
594 this can potentially produce extremely large output.
595
596 =item TRIEM
597
598 Enable enhanced TRIE debugging. Enhances both TRIEE
599 and TRIEC.
600
601 =item STATE
602
603 Enable debugging of states in the engine.
604
605 =item STACK
606
607 Enable debugging of the recursion stack in the engine. Enabling
608 or disabling this option automatically does the same for debugging
609 states as well. This output from this can be quite large.
610
611 =item GPOS
612
613 Enable debugging of the \G modifier.
614
615 =item OPTIMISEM
616
617 Enable enhanced optimisation debugging and start-point optimisations.
618 Probably not useful except when debugging the regexp engine itself.
619
620 =item OFFSETS
621
622 Dump offset information. This can be used to see how regops correlate
623 to the pattern. Output format is
624
625    NODENUM:POSITION[LENGTH]
626
627 Where 1 is the position of the first char in the string. Note that position
628 can be 0, or larger than the actual length of the pattern, likewise length
629 can be zero.
630
631 =item OFFSETSDBG
632
633 Enable debugging of offsets information. This emits copious
634 amounts of trace information and doesn't mesh well with other
635 debug options.
636
637 Almost definitely only useful to people hacking
638 on the offsets part of the debug engine.
639
640 =item DUMP_PRE_OPTIMIZE
641
642 Enable the dumping of the compiled pattern before the optimization phase.
643
644 =item WILDCARD
645
646 When Perl encounters a wildcard subpattern, (see L<perlunicode/Wildcards in
647 Property Values>), it suspends compilation of the main pattern, compiles the
648 subpattern, and then matches that against all legal possibilities to determine
649 the actual code points the subpattern matches.  After that it adds these to
650 the main pattern, and continues its compilation.
651
652 You may very well want to see how your subpattern gets compiled, but it is
653 likely of less use to you to see how Perl matches that against all the legal
654 possibilities, as that is under control of Perl, not you.   Therefore, the
655 debugging information of the compilation portion is as specified by the other
656 options, but the debugging output of the matching portion is normally
657 suppressed.
658
659 You can use the WILDCARD option to enable the debugging output of this
660 subpattern matching.  Careful!  This can lead to voluminous outputs, and it
661 may not make much sense to you what and why Perl is doing what it is.
662 But it may be helpful to you to see why things aren't going the way you
663 expect.
664
665 Note that this option alone doesn't cause any debugging information to be
666 output.  What it does is stop the normal suppression of execution-related
667 debugging information during the matching portion of the compilation of
668 wildcards.  You also have to specify which execution debugging information you
669 want, such as by also including the EXECUTE option.
670
671 =back
672
673 =item Other useful flags
674
675 These are useful shortcuts to save on the typing.
676
677 =over 4
678
679 =item ALL
680
681 Enable all options at once except OFFSETS, OFFSETSDBG, BUFFERS, WILDCARD, and
682 DUMP_PRE_OPTIMIZE.
683 (To get every single option without exception, use both ALL and EXTRA, or
684 starting in 5.30 on a C<-DDEBUGGING>-enabled perl interpreter, use
685 the B<-Drv> command-line switches.)
686
687 =item All
688
689 Enable DUMP and all non-extra execute options. Equivalent to:
690
691   use re 'debug';
692
693 =item MORE
694
695 =item More
696
697 Enable the options enabled by "All", plus STATE, TRIEC, and TRIEM.
698
699 =back
700
701 =back
702
703 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
704 lexically scoped, as are the other directives.  However they have both
705 compile-time and run-time effects.
706
707 =head2 Exportable Functions
708
709 As of perl 5.9.5 're' debug contains a number of utility functions that
710 may be optionally exported into the caller's namespace. They are listed
711 below.
712
713 =over 4
714
715 =item is_regexp($ref)
716
717 Returns true if the argument is a compiled regular expression as returned
718 by C<qr//>, false if it is not.
719
720 This function will not be confused by overloading or blessing. In
721 internals terms, this extracts the regexp pointer out of the
722 PERL_MAGIC_qr structure so it cannot be fooled.
723
724 =item regexp_pattern($ref)
725
726 If the argument is a compiled regular expression as returned by C<qr//>,
727 then this function returns the pattern.
728
729 In list context it returns a two element list, the first element
730 containing the pattern and the second containing the modifiers used when
731 the pattern was compiled.
732
733   my ($pat, $mods) = regexp_pattern($ref);
734
735 In scalar context it returns the same as perl would when stringifying a raw
736 C<qr//> with the same pattern inside.  If the argument is not a compiled
737 reference then this routine returns false but defined in scalar context,
738 and the empty list in list context. Thus the following
739
740     if (regexp_pattern($ref) eq '(?^i:foo)')
741
742 will be warning free regardless of what $ref actually is.
743
744 Like C<is_regexp> this function will not be confused by overloading
745 or blessing of the object.
746
747 =item regmust($ref)
748
749 If the argument is a compiled regular expression as returned by C<qr//>,
750 then this function returns what the optimiser considers to be the longest
751 anchored fixed string and longest floating fixed string in the pattern.
752
753 A I<fixed string> is defined as being a substring that must appear for the
754 pattern to match. An I<anchored fixed string> is a fixed string that must
755 appear at a particular offset from the beginning of the match. A I<floating
756 fixed string> is defined as a fixed string that can appear at any point in
757 a range of positions relative to the start of the match. For example,
758
759     my $qr = qr/here .* there/x;
760     my ($anchored, $floating) = regmust($qr);
761     print "anchored:'$anchored'\nfloating:'$floating'\n";
762
763 results in
764
765     anchored:'here'
766     floating:'there'
767
768 Because the C<here> is before the C<.*> in the pattern, its position
769 can be determined exactly. That's not true, however, for the C<there>;
770 it could appear at any point after where the anchored string appeared.
771 Perl uses both for its optimisations, preferring the longer, or, if they are
772 equal, the floating.
773
774 B<NOTE:> This may not necessarily be the definitive longest anchored and
775 floating string. This will be what the optimiser of the Perl that you
776 are using thinks is the longest. If you believe that the result is wrong
777 please report it via the L<perlbug> utility.
778
779 =item regname($name,$all)
780
781 Returns the contents of a named buffer of the last successful match. If
782 $all is true, then returns an array ref containing one entry per buffer,
783 otherwise returns the first defined buffer.
784
785 =item regnames($all)
786
787 Returns a list of all of the named buffers defined in the last successful
788 match. If $all is true, then it returns all names defined, if not it returns
789 only names which were involved in the match.
790
791 =item regnames_count()
792
793 Returns the number of distinct names defined in the pattern used
794 for the last successful match.
795
796 B<Note:> this result is always the actual number of distinct
797 named buffers defined, it may not actually match that which is
798 returned by C<regnames()> and related routines when those routines
799 have not been called with the $all parameter set.
800
801 =back
802
803 =head1 SEE ALSO
804
805 L<perlmodlib/Pragmatic Modules>.
806
807 =cut