This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
cf36bf22480767b5e028120d369f61b276538934
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor err
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L</"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behaviour.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = '99');      # prints '100'
172     print ++($foo = 'a0');      # prints 'a1'
173     print ++($foo = 'Az');      # prints 'Ba'
174     print ++($foo = 'zz');      # prints 'aaa'
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric.  If
198 the operand is an identifier, a string consisting of a minus sign
199 concatenated with the identifier is returned.  Otherwise, if the string
200 starts with a plus or minus, a string starting with the opposite sign
201 is returned.  One effect of these rules is that -bareword is equivalent
202 to the string "-bareword".  If, however, the string begins with a
203 non-alphabetic character (exluding "+" or "-"), Perl will attempt to convert
204 the string to a numeric and the arithmetic negation is performed. If the
205 string cannot be cleanly converted to a numeric, Perl will give the warning
206 B<Argument "the string" isn't numeric in negation (-) at ...>.
207 X<-> X<negation, arithmetic>
208
209 Unary "~" performs bitwise negation, i.e., 1's complement.  For
210 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
211 L<Bitwise String Operators>.)  Note that the width of the result is
212 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
213 bits wide on a 64-bit platform, so if you are expecting a certain bit
214 width, remember to use the & operator to mask off the excess bits.
215 X<~> X<negation, binary>
216
217 Unary "+" has no effect whatsoever, even on strings.  It is useful
218 syntactically for separating a function name from a parenthesized expression
219 that would otherwise be interpreted as the complete list of function
220 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
221 X<+>
222
223 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
224 and L<perlref>.  Do not confuse this behavior with the behavior of
225 backslash within a string, although both forms do convey the notion
226 of protecting the next thing from interpolation.
227 X<\> X<reference> X<backslash>
228
229 =head2 Binding Operators
230 X<binding> X<operator, binding> X<=~> X<!~>
231
232 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
233 search or modify the string $_ by default.  This operator makes that kind
234 of operation work on some other string.  The right argument is a search
235 pattern, substitution, or transliteration.  The left argument is what is
236 supposed to be searched, substituted, or transliterated instead of the default
237 $_.  When used in scalar context, the return value generally indicates the
238 success of the operation.  Behavior in list context depends on the particular
239 operator.  See L</"Regexp Quote-Like Operators"> for details and
240 L<perlretut> for examples using these operators.
241
242 If the right argument is an expression rather than a search pattern,
243 substitution, or transliteration, it is interpreted as a search pattern at run
244 time. Note that this means that its contents will be interpolated twice, so
245
246   '\\' =~ q'\\';
247
248 is not ok, as the regex engine will end up trying to compile the
249 pattern C<\>, which it will consider a syntax error.
250
251 Binary "!~" is just like "=~" except the return value is negated in
252 the logical sense.
253
254 =head2 Multiplicative Operators
255 X<operator, multiplicative>
256
257 Binary "*" multiplies two numbers.
258 X<*>
259
260 Binary "/" divides two numbers.
261 X</> X<slash>
262
263 Binary "%" computes the modulus of two numbers.  Given integer
264 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
265 C<$a> minus the largest multiple of C<$b> that is not greater than
266 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
267 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
268 result will be less than or equal to zero).  If the operands
269 C<$a> and C<$b> are floting point values, only the integer portion
270 of C<$a> and C<$b> will be used in the operation.
271 Note that when C<use integer> is in scope, "%" gives you direct access
272 to the modulus operator as implemented by your C compiler.  This
273 operator is not as well defined for negative operands, but it will
274 execute faster.
275 X<%> X<remainder> X<modulus> X<mod>
276
277 Binary "x" is the repetition operator.  In scalar context or if the left
278 operand is not enclosed in parentheses, it returns a string consisting
279 of the left operand repeated the number of times specified by the right
280 operand.  In list context, if the left operand is enclosed in
281 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
282 If the right operand is zero or negative, it returns an empty string
283 or an empty list, depending on the context.
284 X<x>
285
286     print '-' x 80;             # print row of dashes
287
288     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
289
290     @ones = (1) x 80;           # a list of 80 1's
291     @ones = (5) x @ones;        # set all elements to 5
292
293
294 =head2 Additive Operators
295 X<operator, additive>
296
297 Binary "+" returns the sum of two numbers.
298 X<+>
299
300 Binary "-" returns the difference of two numbers.
301 X<->
302
303 Binary "." concatenates two strings.
304 X<string, concatenation> X<concatenation>
305 X<cat> X<concat> X<concatenate> X<.>
306
307 =head2 Shift Operators
308 X<shift operator> X<operator, shift> X<<< << >>>
309 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
310 X<shl> X<shr> X<shift, right> X<shift, left>
311
312 Binary "<<" returns the value of its left argument shifted left by the
313 number of bits specified by the right argument.  Arguments should be
314 integers.  (See also L<Integer Arithmetic>.)
315
316 Binary ">>" returns the value of its left argument shifted right by
317 the number of bits specified by the right argument.  Arguments should
318 be integers.  (See also L<Integer Arithmetic>.)
319
320 Note that both "<<" and ">>" in Perl are implemented directly using
321 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
322 in force then signed C integers are used, else unsigned C integers are
323 used.  Either way, the implementation isn't going to generate results
324 larger than the size of the integer type Perl was built with (32 bits
325 or 64 bits).
326
327 The result of overflowing the range of the integers is undefined
328 because it is undefined also in C.  In other words, using 32-bit
329 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
330 of bits is also undefined.
331
332 =head2 Named Unary Operators
333 X<operator, named unary>
334
335 The various named unary operators are treated as functions with one
336 argument, with optional parentheses.
337
338 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
339 is followed by a left parenthesis as the next token, the operator and
340 arguments within parentheses are taken to be of highest precedence,
341 just like a normal function call.  For example,
342 because named unary operators are higher precedence than ||:
343
344     chdir $foo    || die;       # (chdir $foo) || die
345     chdir($foo)   || die;       # (chdir $foo) || die
346     chdir ($foo)  || die;       # (chdir $foo) || die
347     chdir +($foo) || die;       # (chdir $foo) || die
348
349 but, because * is higher precedence than named operators:
350
351     chdir $foo * 20;    # chdir ($foo * 20)
352     chdir($foo) * 20;   # (chdir $foo) * 20
353     chdir ($foo) * 20;  # (chdir $foo) * 20
354     chdir +($foo) * 20; # chdir ($foo * 20)
355
356     rand 10 * 20;       # rand (10 * 20)
357     rand(10) * 20;      # (rand 10) * 20
358     rand (10) * 20;     # (rand 10) * 20
359     rand +(10) * 20;    # rand (10 * 20)
360
361 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
362 treated like named unary operators, but they don't follow this functional
363 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
364 equivalent to C<-f "$file.bak">.
365 X<-X> X<filetest> X<operator, filetest>
366
367 See also L<"Terms and List Operators (Leftward)">.
368
369 =head2 Relational Operators
370 X<relational operator> X<operator, relational>
371
372 Binary "<" returns true if the left argument is numerically less than
373 the right argument.
374 X<< < >>
375
376 Binary ">" returns true if the left argument is numerically greater
377 than the right argument.
378 X<< > >>
379
380 Binary "<=" returns true if the left argument is numerically less than
381 or equal to the right argument.
382 X<< <= >>
383
384 Binary ">=" returns true if the left argument is numerically greater
385 than or equal to the right argument.
386 X<< >= >>
387
388 Binary "lt" returns true if the left argument is stringwise less than
389 the right argument.
390 X<< lt >>
391
392 Binary "gt" returns true if the left argument is stringwise greater
393 than the right argument.
394 X<< gt >>
395
396 Binary "le" returns true if the left argument is stringwise less than
397 or equal to the right argument.
398 X<< le >>
399
400 Binary "ge" returns true if the left argument is stringwise greater
401 than or equal to the right argument.
402 X<< ge >>
403
404 =head2 Equality Operators
405 X<equality> X<equal> X<equals> X<operator, equality>
406
407 Binary "==" returns true if the left argument is numerically equal to
408 the right argument.
409 X<==>
410
411 Binary "!=" returns true if the left argument is numerically not equal
412 to the right argument.
413 X<!=>
414
415 Binary "<=>" returns -1, 0, or 1 depending on whether the left
416 argument is numerically less than, equal to, or greater than the right
417 argument.  If your platform supports NaNs (not-a-numbers) as numeric
418 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
419 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
420 returns true, as does NaN != anything else. If your platform doesn't
421 support NaNs then NaN is just a string with numeric value 0.
422 X<< <=> >> X<spaceship>
423
424     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
425     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
426
427 Binary "eq" returns true if the left argument is stringwise equal to
428 the right argument.
429 X<eq>
430
431 Binary "ne" returns true if the left argument is stringwise not equal
432 to the right argument.
433 X<ne>
434
435 Binary "cmp" returns -1, 0, or 1 depending on whether the left
436 argument is stringwise less than, equal to, or greater than the right
437 argument.
438 X<cmp>
439
440 Binary "~~" does a smart match between its arguments. Smart matching
441 is described in L<perlsyn/"Smart matching in detail">.
442 This operator is only available if you enable the "~~" feature:
443 see L<feature> for more information.
444 X<~~>
445
446 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
447 by the current locale if C<use locale> is in effect.  See L<perllocale>.
448
449 =head2 Bitwise And
450 X<operator, bitwise, and> X<bitwise and> X<&>
451
452 Binary "&" returns its operands ANDed together bit by bit.
453 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
454
455 Note that "&" has lower priority than relational operators, so for example
456 the brackets are essential in a test like
457
458         print "Even\n" if ($x & 1) == 0;
459
460 =head2 Bitwise Or and Exclusive Or
461 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
462 X<bitwise xor> X<^>
463
464 Binary "|" returns its operands ORed together bit by bit.
465 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
466
467 Binary "^" returns its operands XORed together bit by bit.
468 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
469
470 Note that "|" and "^" have lower priority than relational operators, so
471 for example the brackets are essential in a test like
472
473         print "false\n" if (8 | 2) != 10;
474
475 =head2 C-style Logical And
476 X<&&> X<logical and> X<operator, logical, and>
477
478 Binary "&&" performs a short-circuit logical AND operation.  That is,
479 if the left operand is false, the right operand is not even evaluated.
480 Scalar or list context propagates down to the right operand if it
481 is evaluated.
482
483 =head2 C-style Logical Or
484 X<||> X<operator, logical, or>
485
486 Binary "||" performs a short-circuit logical OR operation.  That is,
487 if the left operand is true, the right operand is not even evaluated.
488 Scalar or list context propagates down to the right operand if it
489 is evaluated.
490
491 =head2 C-style Logical Defined-Or
492 X<//> X<operator, logical, defined-or>
493
494 Although it has no direct equivalent in C, Perl's C<//> operator is related
495 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
496 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
497 is similar to C<defined($a) || $b> (except that it returns the value of C<$a>
498 rather than the value of C<defined($a)>) and is exactly equivalent to
499 C<defined($a) ? $a : $b>.  This is very useful for providing default values
500 for variables.  If you actually want to test if at least one of C<$a> and
501 C<$b> is defined, use C<defined($a // $b)>.
502
503 The C<||>, C<//> and C<&&> operators return the last value evaluated
504 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
505 portable way to find out the home directory might be:
506
507     $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
508         (getpwuid($<))[7] // die "You're homeless!\n";
509
510 In particular, this means that you shouldn't use this
511 for selecting between two aggregates for assignment:
512
513     @a = @b || @c;              # this is wrong
514     @a = scalar(@b) || @c;      # really meant this
515     @a = @b ? @b : @c;          # this works fine, though
516
517 As more readable alternatives to C<&&>, C<//> and C<||> when used for
518 control flow, Perl provides C<and>, C<err> and C<or> operators (see below).
519 The short-circuit behavior is identical.  The precedence of "and", "err"
520 and "or" is much lower, however, so that you can safely use them after a
521 list operator without the need for parentheses:
522
523     unlink "alpha", "beta", "gamma"
524             or gripe(), next LINE;
525
526 With the C-style operators that would have been written like this:
527
528     unlink("alpha", "beta", "gamma")
529             || (gripe(), next LINE);
530
531 Using "or" for assignment is unlikely to do what you want; see below.
532
533 =head2 Range Operators
534 X<operator, range> X<range> X<..> X<...>
535
536 Binary ".." is the range operator, which is really two different
537 operators depending on the context.  In list context, it returns a
538 list of values counting (up by ones) from the left value to the right
539 value.  If the left value is greater than the right value then it
540 returns the empty list.  The range operator is useful for writing
541 C<foreach (1..10)> loops and for doing slice operations on arrays. In
542 the current implementation, no temporary array is created when the
543 range operator is used as the expression in C<foreach> loops, but older
544 versions of Perl might burn a lot of memory when you write something
545 like this:
546
547     for (1 .. 1_000_000) {
548         # code
549     }
550
551 The range operator also works on strings, using the magical auto-increment,
552 see below.
553
554 In scalar context, ".." returns a boolean value.  The operator is
555 bistable, like a flip-flop, and emulates the line-range (comma) operator
556 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
557 own boolean state.  It is false as long as its left operand is false.
558 Once the left operand is true, the range operator stays true until the
559 right operand is true, I<AFTER> which the range operator becomes false
560 again.  It doesn't become false till the next time the range operator is
561 evaluated.  It can test the right operand and become false on the same
562 evaluation it became true (as in B<awk>), but it still returns true once.
563 If you don't want it to test the right operand till the next
564 evaluation, as in B<sed>, just use three dots ("...") instead of
565 two.  In all other regards, "..." behaves just like ".." does.
566
567 The right operand is not evaluated while the operator is in the
568 "false" state, and the left operand is not evaluated while the
569 operator is in the "true" state.  The precedence is a little lower
570 than || and &&.  The value returned is either the empty string for
571 false, or a sequence number (beginning with 1) for true.  The
572 sequence number is reset for each range encountered.  The final
573 sequence number in a range has the string "E0" appended to it, which
574 doesn't affect its numeric value, but gives you something to search
575 for if you want to exclude the endpoint.  You can exclude the
576 beginning point by waiting for the sequence number to be greater
577 than 1.
578
579 If either operand of scalar ".." is a constant expression,
580 that operand is considered true if it is equal (C<==>) to the current
581 input line number (the C<$.> variable).
582
583 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
584 but that is only an issue if you use a floating point expression; when
585 implicitly using C<$.> as described in the previous paragraph, the
586 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
587 is set to a floating point value and you are not reading from a file.
588 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
589 you want in scalar context because each of the operands are evaluated
590 using their integer representation.
591
592 Examples:
593
594 As a scalar operator:
595
596     if (101 .. 200) { print; } # print 2nd hundred lines, short for
597                                #   if ($. == 101 .. $. == 200) ...
598
599     next LINE if (1 .. /^$/);  # skip header lines, short for
600                                #   ... if ($. == 1 .. /^$/);
601                                # (typically in a loop labeled LINE)
602
603     s/^/> / if (/^$/ .. eof());  # quote body
604
605     # parse mail messages
606     while (<>) {
607         $in_header =   1  .. /^$/;
608         $in_body   = /^$/ .. eof;
609         if ($in_header) {
610             # ...
611         } else { # in body
612             # ...
613         }
614     } continue {
615         close ARGV if eof;             # reset $. each file
616     }
617
618 Here's a simple example to illustrate the difference between
619 the two range operators:
620
621     @lines = ("   - Foo",
622               "01 - Bar",
623               "1  - Baz",
624               "   - Quux");
625
626     foreach (@lines) {
627         if (/0/ .. /1/) {
628             print "$_\n";
629         }
630     }
631
632 This program will print only the line containing "Bar". If
633 the range operator is changed to C<...>, it will also print the
634 "Baz" line.
635
636 And now some examples as a list operator:
637
638     for (101 .. 200) { print; } # print $_ 100 times
639     @foo = @foo[0 .. $#foo];    # an expensive no-op
640     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
641
642 The range operator (in list context) makes use of the magical
643 auto-increment algorithm if the operands are strings.  You
644 can say
645
646     @alphabet = ('A' .. 'Z');
647
648 to get all normal letters of the English alphabet, or
649
650     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
651
652 to get a hexadecimal digit, or
653
654     @z2 = ('01' .. '31');  print $z2[$mday];
655
656 to get dates with leading zeros.
657
658 If the final value specified is not in the sequence that the magical
659 increment would produce, the sequence goes until the next value would
660 be longer than the final value specified.
661
662 If the initial value specified isn't part of a magical increment
663 sequence (that is, a non-empty string matching "/^[a-zA-Z]*[0-9]*\z/"),
664 only the initial value will be returned.  So the following will only
665 return an alpha:
666
667     use charnames 'greek';
668     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
669
670 To get lower-case greek letters, use this instead:
671
672     my @greek_small =  map { chr } ( ord("\N{alpha}") .. ord("\N{omega}") );
673
674 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
675 return two elements in list context.
676
677     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
678
679 =head2 Conditional Operator
680 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
681
682 Ternary "?:" is the conditional operator, just as in C.  It works much
683 like an if-then-else.  If the argument before the ? is true, the
684 argument before the : is returned, otherwise the argument after the :
685 is returned.  For example:
686
687     printf "I have %d dog%s.\n", $n,
688             ($n == 1) ? '' : "s";
689
690 Scalar or list context propagates downward into the 2nd
691 or 3rd argument, whichever is selected.
692
693     $a = $ok ? $b : $c;  # get a scalar
694     @a = $ok ? @b : @c;  # get an array
695     $a = $ok ? @b : @c;  # oops, that's just a count!
696
697 The operator may be assigned to if both the 2nd and 3rd arguments are
698 legal lvalues (meaning that you can assign to them):
699
700     ($a_or_b ? $a : $b) = $c;
701
702 Because this operator produces an assignable result, using assignments
703 without parentheses will get you in trouble.  For example, this:
704
705     $a % 2 ? $a += 10 : $a += 2
706
707 Really means this:
708
709     (($a % 2) ? ($a += 10) : $a) += 2
710
711 Rather than this:
712
713     ($a % 2) ? ($a += 10) : ($a += 2)
714
715 That should probably be written more simply as:
716
717     $a += ($a % 2) ? 10 : 2;
718
719 =head2 Assignment Operators
720 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
721 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
722 X<%=> X<^=> X<x=>
723
724 "=" is the ordinary assignment operator.
725
726 Assignment operators work as in C.  That is,
727
728     $a += 2;
729
730 is equivalent to
731
732     $a = $a + 2;
733
734 although without duplicating any side effects that dereferencing the lvalue
735 might trigger, such as from tie().  Other assignment operators work similarly.
736 The following are recognized:
737
738     **=    +=    *=    &=    <<=    &&=
739            -=    /=    |=    >>=    ||=
740            .=    %=    ^=           //=
741                  x=
742
743 Although these are grouped by family, they all have the precedence
744 of assignment.
745
746 Unlike in C, the scalar assignment operator produces a valid lvalue.
747 Modifying an assignment is equivalent to doing the assignment and
748 then modifying the variable that was assigned to.  This is useful
749 for modifying a copy of something, like this:
750
751     ($tmp = $global) =~ tr [A-Z] [a-z];
752
753 Likewise,
754
755     ($a += 2) *= 3;
756
757 is equivalent to
758
759     $a += 2;
760     $a *= 3;
761
762 Similarly, a list assignment in list context produces the list of
763 lvalues assigned to, and a list assignment in scalar context returns
764 the number of elements produced by the expression on the right hand
765 side of the assignment.
766
767 =head2 Comma Operator
768 X<comma> X<operator, comma> X<,>
769
770 Binary "," is the comma operator.  In scalar context it evaluates
771 its left argument, throws that value away, then evaluates its right
772 argument and returns that value.  This is just like C's comma operator.
773
774 In list context, it's just the list argument separator, and inserts
775 both its arguments into the list.  These arguments are also evaluated
776 from left to right.
777
778 The C<< => >> operator is a synonym for the comma, but forces any word
779 (consisting entirely of word characters) to its left to be interpreted
780 as a string (as of 5.001).  This includes words that might otherwise be
781 considered a constant or function call.
782
783     use constant FOO => "something";
784
785     my %h = ( FOO => 23 );
786
787 is equivalent to:
788
789     my %h = ("FOO", 23);
790
791 It is I<NOT>:
792
793     my %h = ("something", 23);
794
795 If the argument on the left is not a word, it is first interpreted as
796 an expression, and then the string value of that is used.
797
798 The C<< => >> operator is helpful in documenting the correspondence
799 between keys and values in hashes, and other paired elements in lists.
800
801         %hash = ( $key => $value );
802         login( $username => $password );
803
804 =head2 List Operators (Rightward)
805 X<operator, list, rightward> X<list operator>
806
807 On the right side of a list operator, it has very low precedence,
808 such that it controls all comma-separated expressions found there.
809 The only operators with lower precedence are the logical operators
810 "and", "or", and "not", which may be used to evaluate calls to list
811 operators without the need for extra parentheses:
812
813     open HANDLE, "filename"
814         or die "Can't open: $!\n";
815
816 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
817
818 =head2 Logical Not
819 X<operator, logical, not> X<not>
820
821 Unary "not" returns the logical negation of the expression to its right.
822 It's the equivalent of "!" except for the very low precedence.
823
824 =head2 Logical And
825 X<operator, logical, and> X<and>
826
827 Binary "and" returns the logical conjunction of the two surrounding
828 expressions.  It's equivalent to && except for the very low
829 precedence.  This means that it short-circuits: i.e., the right
830 expression is evaluated only if the left expression is true.
831
832 =head2 Logical or, Defined or, and Exclusive Or
833 X<operator, logical, or> X<operator, logical, xor> X<operator, logical, err>
834 X<operator, logical, defined or> X<operator, logical, exclusive or>
835 X<or> X<xor> X<err>
836
837 Binary "or" returns the logical disjunction of the two surrounding
838 expressions.  It's equivalent to || except for the very low precedence.
839 This makes it useful for control flow
840
841     print FH $data              or die "Can't write to FH: $!";
842
843 This means that it short-circuits: i.e., the right expression is evaluated
844 only if the left expression is false.  Due to its precedence, you should
845 probably avoid using this for assignment, only for control flow.
846
847     $a = $b or $c;              # bug: this is wrong
848     ($a = $b) or $c;            # really means this
849     $a = $b || $c;              # better written this way
850
851 However, when it's a list-context assignment and you're trying to use
852 "||" for control flow, you probably need "or" so that the assignment
853 takes higher precedence.
854
855     @info = stat($file) || die;     # oops, scalar sense of stat!
856     @info = stat($file) or die;     # better, now @info gets its due
857
858 Then again, you could always use parentheses.
859
860 Binary "err" is equivalent to C<//>--it's just like binary "or", except it
861 tests its left argument's definedness instead of its truth.  There are two
862 ways to remember "err":  either because many functions return C<undef> on
863 an B<err>or, or as a sort of correction:  C<$a = ($b err 'default')>. This
864 keyword is only available when the 'err' feature is enabled: see
865 L<feature> for more information.
866
867 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
868 It cannot short circuit, of course.
869
870 =head2 C Operators Missing From Perl
871 X<operator, missing from perl> X<&> X<*>
872 X<typecasting> X<(TYPE)>
873
874 Here is what C has that Perl doesn't:
875
876 =over 8
877
878 =item unary &
879
880 Address-of operator.  (But see the "\" operator for taking a reference.)
881
882 =item unary *
883
884 Dereference-address operator. (Perl's prefix dereferencing
885 operators are typed: $, @, %, and &.)
886
887 =item (TYPE)
888
889 Type-casting operator.
890
891 =back
892
893 =head2 Quote and Quote-like Operators
894 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
895 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
896 X<escape sequence> X<escape>
897
898
899 While we usually think of quotes as literal values, in Perl they
900 function as operators, providing various kinds of interpolating and
901 pattern matching capabilities.  Perl provides customary quote characters
902 for these behaviors, but also provides a way for you to choose your
903 quote character for any of them.  In the following table, a C<{}> represents
904 any pair of delimiters you choose.
905
906     Customary  Generic        Meaning        Interpolates
907         ''       q{}          Literal             no
908         ""      qq{}          Literal             yes
909         ``      qx{}          Command             yes*
910                 qw{}         Word list            no
911         //       m{}       Pattern match          yes*
912                 qr{}          Pattern             yes*
913                  s{}{}      Substitution          yes*
914                 tr{}{}    Transliteration         no (but see below)
915         <<EOF                 here-doc            yes*
916
917         * unless the delimiter is ''.
918
919 Non-bracketing delimiters use the same character fore and aft, but the four
920 sorts of brackets (round, angle, square, curly) will all nest, which means
921 that
922
923         q{foo{bar}baz}
924
925 is the same as
926
927         'foo{bar}baz'
928
929 Note, however, that this does not always work for quoting Perl code:
930
931         $s = q{ if($a eq "}") ... }; # WRONG
932
933 is a syntax error. The C<Text::Balanced> module (from CPAN, and
934 starting from Perl 5.8 part of the standard distribution) is able
935 to do this properly.
936
937 There can be whitespace between the operator and the quoting
938 characters, except when C<#> is being used as the quoting character.
939 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
940 operator C<q> followed by a comment.  Its argument will be taken
941 from the next line.  This allows you to write:
942
943     s {foo}  # Replace foo
944       {bar}  # with bar.
945
946 The following escape sequences are available in constructs that interpolate
947 and in transliterations.
948 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N>
949
950     \t          tab             (HT, TAB)
951     \n          newline         (NL)
952     \r          return          (CR)
953     \f          form feed       (FF)
954     \b          backspace       (BS)
955     \a          alarm (bell)    (BEL)
956     \e          escape          (ESC)
957     \033        octal char      (ESC)
958     \x1b        hex char        (ESC)
959     \x{263a}    wide hex char   (SMILEY)
960     \c[         control char    (ESC)
961     \N{name}    named Unicode character
962
963 B<NOTE>: Unlike C and other languages, Perl has no \v escape sequence for
964 the vertical tab (VT - ASCII 11).
965
966 The following escape sequences are available in constructs that interpolate
967 but not in transliterations.
968 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
969
970     \l          lowercase next char
971     \u          uppercase next char
972     \L          lowercase till \E
973     \U          uppercase till \E
974     \E          end case modification
975     \Q          quote non-word characters till \E
976
977 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
978 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
979 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
980 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
981 C<\U> is as defined by Unicode.  For documentation of C<\N{name}>,
982 see L<charnames>.
983
984 All systems use the virtual C<"\n"> to represent a line terminator,
985 called a "newline".  There is no such thing as an unvarying, physical
986 newline character.  It is only an illusion that the operating system,
987 device drivers, C libraries, and Perl all conspire to preserve.  Not all
988 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
989 on a Mac, these are reversed, and on systems without line terminator,
990 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
991 you mean a "newline" for your system, but use the literal ASCII when you
992 need an exact character.  For example, most networking protocols expect
993 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
994 and although they often accept just C<"\012">, they seldom tolerate just
995 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
996 you may be burned some day.
997 X<newline> X<line terminator> X<eol> X<end of line>
998 X<\n> X<\r> X<\r\n>
999
1000 For constructs that do interpolate, variables beginning with "C<$>"
1001 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1002 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1003 But method calls such as C<< $obj->meth >> are not.
1004
1005 Interpolating an array or slice interpolates the elements in order,
1006 separated by the value of C<$">, so is equivalent to interpolating
1007 C<join $", @array>.    "Punctuation" arrays such as C<@*> are only
1008 interpolated if the name is enclosed in braces C<@{*}>, but special
1009 arrays C<@_>, C<@+>, and C<@-> are interpolated, even without braces.
1010
1011 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
1012 An unescaped C<$> or C<@> interpolates the corresponding variable,
1013 while escaping will cause the literal string C<\$> to be inserted.
1014 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
1015
1016 Patterns are subject to an additional level of interpretation as a
1017 regular expression.  This is done as a second pass, after variables are
1018 interpolated, so that regular expressions may be incorporated into the
1019 pattern from the variables.  If this is not what you want, use C<\Q> to
1020 interpolate a variable literally.
1021
1022 Apart from the behavior described above, Perl does not expand
1023 multiple levels of interpolation.  In particular, contrary to the
1024 expectations of shell programmers, back-quotes do I<NOT> interpolate
1025 within double quotes, nor do single quotes impede evaluation of
1026 variables when used within double quotes.
1027
1028 =head2 Regexp Quote-Like Operators
1029 X<operator, regexp>
1030
1031 Here are the quote-like operators that apply to pattern
1032 matching and related activities.
1033
1034 =over 8
1035
1036 =item ?PATTERN?
1037 X<?>
1038
1039 This is just like the C</pattern/> search, except that it matches only
1040 once between calls to the reset() operator.  This is a useful
1041 optimization when you want to see only the first occurrence of
1042 something in each file of a set of files, for instance.  Only C<??>
1043 patterns local to the current package are reset.
1044
1045     while (<>) {
1046         if (?^$?) {
1047                             # blank line between header and body
1048         }
1049     } continue {
1050         reset if eof;       # clear ?? status for next file
1051     }
1052
1053 This usage is vaguely deprecated, which means it just might possibly
1054 be removed in some distant future version of Perl, perhaps somewhere
1055 around the year 2168.
1056
1057 =item m/PATTERN/cgimosx
1058 X<m> X<operator, match>
1059 X<regexp, options> X<regexp> X<regex, options> X<regex>
1060 X</c> X</i> X</m> X</o> X</s> X</x>
1061
1062 =item /PATTERN/cgimosx
1063
1064 Searches a string for a pattern match, and in scalar context returns
1065 true if it succeeds, false if it fails.  If no string is specified
1066 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1067 string specified with C<=~> need not be an lvalue--it may be the
1068 result of an expression evaluation, but remember the C<=~> binds
1069 rather tightly.)  See also L<perlre>.  See L<perllocale> for
1070 discussion of additional considerations that apply when C<use locale>
1071 is in effect.
1072
1073 Options are:
1074
1075     c   Do not reset search position on a failed match when /g is in effect.
1076     g   Match globally, i.e., find all occurrences.
1077     i   Do case-insensitive pattern matching.
1078     m   Treat string as multiple lines.
1079     o   Compile pattern only once.
1080     s   Treat string as single line.
1081     x   Use extended regular expressions.
1082
1083 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1084 you can use any pair of non-alphanumeric, non-whitespace characters
1085 as delimiters.  This is particularly useful for matching path names
1086 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1087 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
1088 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1089
1090 PATTERN may contain variables, which will be interpolated (and the
1091 pattern recompiled) every time the pattern search is evaluated, except
1092 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1093 C<$|> are not interpolated because they look like end-of-string tests.)
1094 If you want such a pattern to be compiled only once, add a C</o> after
1095 the trailing delimiter.  This avoids expensive run-time recompilations,
1096 and is useful when the value you are interpolating won't change over
1097 the life of the script.  However, mentioning C</o> constitutes a promise
1098 that you won't change the variables in the pattern.  If you change them,
1099 Perl won't even notice.  See also L<"qr/STRING/imosx">.
1100
1101 If the PATTERN evaluates to the empty string, the last
1102 I<successfully> matched regular expression is used instead. In this
1103 case, only the C<g> and C<c> flags on the empty pattern is honoured -
1104 the other flags are taken from the original pattern. If no match has
1105 previously succeeded, this will (silently) act instead as a genuine
1106 empty pattern (which will always match).
1107
1108 Note that it's possible to confuse Perl into thinking C<//> (the empty
1109 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1110 good about this, but some pathological cases might trigger this, such as
1111 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1112 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1113 will assume you meant defined-or.  If you meant the empty regex, just
1114 use parentheses or spaces to disambiguate, or even prefix the empty
1115 regex with an C<m> (so C<//> becomes C<m//>).
1116
1117 If the C</g> option is not used, C<m//> in list context returns a
1118 list consisting of the subexpressions matched by the parentheses in the
1119 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1120 also set, and that this differs from Perl 4's behavior.)  When there are
1121 no parentheses in the pattern, the return value is the list C<(1)> for
1122 success.  With or without parentheses, an empty list is returned upon
1123 failure.
1124
1125 Examples:
1126
1127     open(TTY, '/dev/tty');
1128     <TTY> =~ /^y/i && foo();    # do foo if desired
1129
1130     if (/Version: *([0-9.]*)/) { $version = $1; }
1131
1132     next if m#^/usr/spool/uucp#;
1133
1134     # poor man's grep
1135     $arg = shift;
1136     while (<>) {
1137         print if /$arg/o;       # compile only once
1138     }
1139
1140     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1141
1142 This last example splits $foo into the first two words and the
1143 remainder of the line, and assigns those three fields to $F1, $F2, and
1144 $Etc.  The conditional is true if any variables were assigned, i.e., if
1145 the pattern matched.
1146
1147 The C</g> modifier specifies global pattern matching--that is,
1148 matching as many times as possible within the string.  How it behaves
1149 depends on the context.  In list context, it returns a list of the
1150 substrings matched by any capturing parentheses in the regular
1151 expression.  If there are no parentheses, it returns a list of all
1152 the matched strings, as if there were parentheses around the whole
1153 pattern.
1154
1155 In scalar context, each execution of C<m//g> finds the next match,
1156 returning true if it matches, and false if there is no further match.
1157 The position after the last match can be read or set using the pos()
1158 function; see L<perlfunc/pos>.   A failed match normally resets the
1159 search position to the beginning of the string, but you can avoid that
1160 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
1161 string also resets the search position.
1162
1163 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1164 zero-width assertion that matches the exact position where the previous
1165 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
1166 still anchors at pos(), but the match is of course only attempted once.
1167 Using C<\G> without C</g> on a target string that has not previously had a
1168 C</g> match applied to it is the same as using the C<\A> assertion to match
1169 the beginning of the string.  Note also that, currently, C<\G> is only
1170 properly supported when anchored at the very beginning of the pattern.
1171
1172 Examples:
1173
1174     # list context
1175     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1176
1177     # scalar context
1178     $/ = "";
1179     while (defined($paragraph = <>)) {
1180         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1181             $sentences++;
1182         }
1183     }
1184     print "$sentences\n";
1185
1186     # using m//gc with \G
1187     $_ = "ppooqppqq";
1188     while ($i++ < 2) {
1189         print "1: '";
1190         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1191         print "2: '";
1192         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1193         print "3: '";
1194         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1195     }
1196     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1197
1198 The last example should print:
1199
1200     1: 'oo', pos=4
1201     2: 'q', pos=5
1202     3: 'pp', pos=7
1203     1: '', pos=7
1204     2: 'q', pos=8
1205     3: '', pos=8
1206     Final: 'q', pos=8
1207
1208 Notice that the final match matched C<q> instead of C<p>, which a match
1209 without the C<\G> anchor would have done. Also note that the final match
1210 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
1211 final match did indeed match C<p>, it's a good bet that you're running an
1212 older (pre-5.6.0) Perl.
1213
1214 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1215 combine several regexps like this to process a string part-by-part,
1216 doing different actions depending on which regexp matched.  Each
1217 regexp tries to match where the previous one leaves off.
1218
1219  $_ = <<'EOL';
1220       $url = URI::URL->new( "http://www/" );   die if $url eq "xXx";
1221  EOL
1222  LOOP:
1223     {
1224       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1225       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1226       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1227       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1228       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1229       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1230       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
1231       print ". That's all!\n";
1232     }
1233
1234 Here is the output (split into several lines):
1235
1236  line-noise lowercase line-noise lowercase UPPERCASE line-noise
1237  UPPERCASE line-noise lowercase line-noise lowercase line-noise
1238  lowercase lowercase line-noise lowercase lowercase line-noise
1239  MiXeD line-noise. That's all!
1240
1241 =item q/STRING/
1242 X<q> X<quote, single> X<'> X<''>
1243
1244 =item 'STRING'
1245
1246 A single-quoted, literal string.  A backslash represents a backslash
1247 unless followed by the delimiter or another backslash, in which case
1248 the delimiter or backslash is interpolated.
1249
1250     $foo = q!I said, "You said, 'She said it.'"!;
1251     $bar = q('This is it.');
1252     $baz = '\n';                # a two-character string
1253
1254 =item qq/STRING/
1255 X<qq> X<quote, double> X<"> X<"">
1256
1257 =item "STRING"
1258
1259 A double-quoted, interpolated string.
1260
1261     $_ .= qq
1262      (*** The previous line contains the naughty word "$1".\n)
1263                 if /\b(tcl|java|python)\b/i;      # :-)
1264     $baz = "\n";                # a one-character string
1265
1266 =item qr/STRING/imosx
1267 X<qr> X</i> X</m> X</o> X</s> X</x>
1268
1269 This operator quotes (and possibly compiles) its I<STRING> as a regular
1270 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1271 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1272 is done.  Returns a Perl value which may be used instead of the
1273 corresponding C</STRING/imosx> expression.
1274
1275 For example,
1276
1277     $rex = qr/my.STRING/is;
1278     s/$rex/foo/;
1279
1280 is equivalent to
1281
1282     s/my.STRING/foo/is;
1283
1284 The result may be used as a subpattern in a match:
1285
1286     $re = qr/$pattern/;
1287     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1288     $string =~ $re;             # or used standalone
1289     $string =~ /$re/;           # or this way
1290
1291 Since Perl may compile the pattern at the moment of execution of qr()
1292 operator, using qr() may have speed advantages in some situations,
1293 notably if the result of qr() is used standalone:
1294
1295     sub match {
1296         my $patterns = shift;
1297         my @compiled = map qr/$_/i, @$patterns;
1298         grep {
1299             my $success = 0;
1300             foreach my $pat (@compiled) {
1301                 $success = 1, last if /$pat/;
1302             }
1303             $success;
1304         } @_;
1305     }
1306
1307 Precompilation of the pattern into an internal representation at
1308 the moment of qr() avoids a need to recompile the pattern every
1309 time a match C</$pat/> is attempted.  (Perl has many other internal
1310 optimizations, but none would be triggered in the above example if
1311 we did not use qr() operator.)
1312
1313 Options are:
1314
1315     i   Do case-insensitive pattern matching.
1316     m   Treat string as multiple lines.
1317     o   Compile pattern only once.
1318     s   Treat string as single line.
1319     x   Use extended regular expressions.
1320
1321 See L<perlre> for additional information on valid syntax for STRING, and
1322 for a detailed look at the semantics of regular expressions.
1323
1324 =item qx/STRING/
1325 X<qx> X<`> X<``> X<backtick>
1326
1327 =item `STRING`
1328
1329 A string which is (possibly) interpolated and then executed as a
1330 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1331 pipes, and redirections will be honored.  The collected standard
1332 output of the command is returned; standard error is unaffected.  In
1333 scalar context, it comes back as a single (potentially multi-line)
1334 string, or undef if the command failed.  In list context, returns a
1335 list of lines (however you've defined lines with $/ or
1336 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1337
1338 Because backticks do not affect standard error, use shell file descriptor
1339 syntax (assuming the shell supports this) if you care to address this.
1340 To capture a command's STDERR and STDOUT together:
1341
1342     $output = `cmd 2>&1`;
1343
1344 To capture a command's STDOUT but discard its STDERR:
1345
1346     $output = `cmd 2>/dev/null`;
1347
1348 To capture a command's STDERR but discard its STDOUT (ordering is
1349 important here):
1350
1351     $output = `cmd 2>&1 1>/dev/null`;
1352
1353 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1354 but leave its STDOUT to come out the old STDERR:
1355
1356     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1357
1358 To read both a command's STDOUT and its STDERR separately, it's easiest
1359 to redirect them separately to files, and then read from those files
1360 when the program is done:
1361
1362     system("program args 1>program.stdout 2>program.stderr");
1363
1364 The STDIN filehandle used by the command is inherited from Perl's STDIN.
1365 For example:
1366
1367     open BLAM, "blam" || die "Can't open: $!";
1368     open STDIN, "<&BLAM";
1369     print `sort`;
1370
1371 will print the sorted contents of the file "blam".
1372
1373 Using single-quote as a delimiter protects the command from Perl's
1374 double-quote interpolation, passing it on to the shell instead:
1375
1376     $perl_info  = qx(ps $$);            # that's Perl's $$
1377     $shell_info = qx'ps $$';            # that's the new shell's $$
1378
1379 How that string gets evaluated is entirely subject to the command
1380 interpreter on your system.  On most platforms, you will have to protect
1381 shell metacharacters if you want them treated literally.  This is in
1382 practice difficult to do, as it's unclear how to escape which characters.
1383 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1384 to emulate backticks safely.
1385
1386 On some platforms (notably DOS-like ones), the shell may not be
1387 capable of dealing with multiline commands, so putting newlines in
1388 the string may not get you what you want.  You may be able to evaluate
1389 multiple commands in a single line by separating them with the command
1390 separator character, if your shell supports that (e.g. C<;> on many Unix
1391 shells; C<&> on the Windows NT C<cmd> shell).
1392
1393 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1394 output before starting the child process, but this may not be supported
1395 on some platforms (see L<perlport>).  To be safe, you may need to set
1396 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1397 C<IO::Handle> on any open handles.
1398
1399 Beware that some command shells may place restrictions on the length
1400 of the command line.  You must ensure your strings don't exceed this
1401 limit after any necessary interpolations.  See the platform-specific
1402 release notes for more details about your particular environment.
1403
1404 Using this operator can lead to programs that are difficult to port,
1405 because the shell commands called vary between systems, and may in
1406 fact not be present at all.  As one example, the C<type> command under
1407 the POSIX shell is very different from the C<type> command under DOS.
1408 That doesn't mean you should go out of your way to avoid backticks
1409 when they're the right way to get something done.  Perl was made to be
1410 a glue language, and one of the things it glues together is commands.
1411 Just understand what you're getting yourself into.
1412
1413 See L</"I/O Operators"> for more discussion.
1414
1415 =item qw/STRING/
1416 X<qw> X<quote, list> X<quote, words>
1417
1418 Evaluates to a list of the words extracted out of STRING, using embedded
1419 whitespace as the word delimiters.  It can be understood as being roughly
1420 equivalent to:
1421
1422     split(' ', q/STRING/);
1423
1424 the differences being that it generates a real list at compile time, and
1425 in scalar context it returns the last element in the list.  So
1426 this expression:
1427
1428     qw(foo bar baz)
1429
1430 is semantically equivalent to the list:
1431
1432     'foo', 'bar', 'baz'
1433
1434 Some frequently seen examples:
1435
1436     use POSIX qw( setlocale localeconv )
1437     @EXPORT = qw( foo bar baz );
1438
1439 A common mistake is to try to separate the words with comma or to
1440 put comments into a multi-line C<qw>-string.  For this reason, the
1441 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
1442 produces warnings if the STRING contains the "," or the "#" character.
1443
1444 =item s/PATTERN/REPLACEMENT/egimosx
1445 X<substitute> X<substitution> X<replace> X<regexp, replace>
1446 X<regexp, substitute> X</e> X</g> X</i> X</m> X</o> X</s> X</x>
1447
1448 Searches a string for a pattern, and if found, replaces that pattern
1449 with the replacement text and returns the number of substitutions
1450 made.  Otherwise it returns false (specifically, the empty string).
1451
1452 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1453 variable is searched and modified.  (The string specified with C<=~> must
1454 be scalar variable, an array element, a hash element, or an assignment
1455 to one of those, i.e., an lvalue.)
1456
1457 If the delimiter chosen is a single quote, no interpolation is
1458 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1459 PATTERN contains a $ that looks like a variable rather than an
1460 end-of-string test, the variable will be interpolated into the pattern
1461 at run-time.  If you want the pattern compiled only once the first time
1462 the variable is interpolated, use the C</o> option.  If the pattern
1463 evaluates to the empty string, the last successfully executed regular
1464 expression is used instead.  See L<perlre> for further explanation on these.
1465 See L<perllocale> for discussion of additional considerations that apply
1466 when C<use locale> is in effect.
1467
1468 Options are:
1469
1470     e   Evaluate the right side as an expression.
1471     g   Replace globally, i.e., all occurrences.
1472     i   Do case-insensitive pattern matching.
1473     m   Treat string as multiple lines.
1474     o   Compile pattern only once.
1475     s   Treat string as single line.
1476     x   Use extended regular expressions.
1477
1478 Any non-alphanumeric, non-whitespace delimiter may replace the
1479 slashes.  If single quotes are used, no interpretation is done on the
1480 replacement string (the C</e> modifier overrides this, however).  Unlike
1481 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1482 text is not evaluated as a command.  If the
1483 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1484 pair of quotes, which may or may not be bracketing quotes, e.g.,
1485 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1486 replacement portion to be treated as a full-fledged Perl expression
1487 and evaluated right then and there.  It is, however, syntax checked at
1488 compile-time. A second C<e> modifier will cause the replacement portion
1489 to be C<eval>ed before being run as a Perl expression.
1490
1491 Examples:
1492
1493     s/\bgreen\b/mauve/g;                # don't change wintergreen
1494
1495     $path =~ s|/usr/bin|/usr/local/bin|;
1496
1497     s/Login: $foo/Login: $bar/; # run-time pattern
1498
1499     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1500
1501     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1502
1503     $_ = 'abc123xyz';
1504     s/\d+/$&*2/e;               # yields 'abc246xyz'
1505     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1506     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1507
1508     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1509     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1510     s/^=(\w+)/pod($1)/ge;       # use function call
1511
1512     # expand variables in $_, but dynamics only, using
1513     # symbolic dereferencing
1514     s/\$(\w+)/${$1}/g;
1515
1516     # Add one to the value of any numbers in the string
1517     s/(\d+)/1 + $1/eg;
1518
1519     # This will expand any embedded scalar variable
1520     # (including lexicals) in $_ : First $1 is interpolated
1521     # to the variable name, and then evaluated
1522     s/(\$\w+)/$1/eeg;
1523
1524     # Delete (most) C comments.
1525     $program =~ s {
1526         /\*     # Match the opening delimiter.
1527         .*?     # Match a minimal number of characters.
1528         \*/     # Match the closing delimiter.
1529     } []gsx;
1530
1531     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1532
1533     for ($variable) {           # trim whitespace in $variable, cheap
1534         s/^\s+//;
1535         s/\s+$//;
1536     }
1537
1538     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1539
1540 Note the use of $ instead of \ in the last example.  Unlike
1541 B<sed>, we use the \<I<digit>> form in only the left hand side.
1542 Anywhere else it's $<I<digit>>.
1543
1544 Occasionally, you can't use just a C</g> to get all the changes
1545 to occur that you might want.  Here are two common cases:
1546
1547     # put commas in the right places in an integer
1548     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
1549
1550     # expand tabs to 8-column spacing
1551     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1552
1553 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1554 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1555
1556 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1557
1558 Transliterates all occurrences of the characters found in the search list
1559 with the corresponding character in the replacement list.  It returns
1560 the number of characters replaced or deleted.  If no string is
1561 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1562 string specified with =~ must be a scalar variable, an array element, a
1563 hash element, or an assignment to one of those, i.e., an lvalue.)
1564
1565 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
1566 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1567 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1568 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1569 its own pair of quotes, which may or may not be bracketing quotes,
1570 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1571
1572 Note that C<tr> does B<not> do regular expression character classes
1573 such as C<\d> or C<[:lower:]>.  The C<tr> operator is not equivalent to
1574 the tr(1) utility.  If you want to map strings between lower/upper
1575 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1576 using the C<s> operator if you need regular expressions.
1577
1578 Note also that the whole range idea is rather unportable between
1579 character sets--and even within character sets they may cause results
1580 you probably didn't expect.  A sound principle is to use only ranges
1581 that begin from and end at either alphabets of equal case (a-e, A-E),
1582 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1583 character sets in full.
1584
1585 Options:
1586
1587     c   Complement the SEARCHLIST.
1588     d   Delete found but unreplaced characters.
1589     s   Squash duplicate replaced characters.
1590
1591 If the C</c> modifier is specified, the SEARCHLIST character set
1592 is complemented.  If the C</d> modifier is specified, any characters
1593 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1594 (Note that this is slightly more flexible than the behavior of some
1595 B<tr> programs, which delete anything they find in the SEARCHLIST,
1596 period.) If the C</s> modifier is specified, sequences of characters
1597 that were transliterated to the same character are squashed down
1598 to a single instance of the character.
1599
1600 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1601 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1602 than the SEARCHLIST, the final character is replicated till it is long
1603 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1604 This latter is useful for counting characters in a class or for
1605 squashing character sequences in a class.
1606
1607 Examples:
1608
1609     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1610
1611     $cnt = tr/*/*/;             # count the stars in $_
1612
1613     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1614
1615     $cnt = tr/0-9//;            # count the digits in $_
1616
1617     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1618
1619     ($HOST = $host) =~ tr/a-z/A-Z/;
1620
1621     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1622
1623     tr [\200-\377]
1624        [\000-\177];             # delete 8th bit
1625
1626 If multiple transliterations are given for a character, only the
1627 first one is used:
1628
1629     tr/AAA/XYZ/
1630
1631 will transliterate any A to X.
1632
1633 Because the transliteration table is built at compile time, neither
1634 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1635 interpolation.  That means that if you want to use variables, you
1636 must use an eval():
1637
1638     eval "tr/$oldlist/$newlist/";
1639     die $@ if $@;
1640
1641     eval "tr/$oldlist/$newlist/, 1" or die $@;
1642
1643 =item <<EOF
1644 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
1645
1646 A line-oriented form of quoting is based on the shell "here-document"
1647 syntax.  Following a C<< << >> you specify a string to terminate
1648 the quoted material, and all lines following the current line down to
1649 the terminating string are the value of the item.
1650
1651 The terminating string may be either an identifier (a word), or some
1652 quoted text.  An unquoted identifier works like double quotes.
1653 There may not be a space between the C<< << >> and the identifier,
1654 unless the identifier is explicitly quoted.  (If you put a space it
1655 will be treated as a null identifier, which is valid, and matches the
1656 first empty line.)  The terminating string must appear by itself
1657 (unquoted and with no surrounding whitespace) on the terminating line.
1658
1659 If the terminating string is quoted, the type of quotes used determine
1660 the treatment of the text.
1661
1662 =over 4
1663
1664 =item Double Quotes
1665
1666 Double quotes indicate that the text will be interpolated using exactly
1667 the same rules as normal double quoted strings.
1668
1669        print <<EOF;
1670     The price is $Price.
1671     EOF
1672
1673        print << "EOF"; # same as above
1674     The price is $Price.
1675     EOF
1676
1677
1678 =item Single Quotes
1679
1680 Single quotes indicate the text is to be treated literally with no
1681 interpolation of its content. This is similar to single quoted
1682 strings except that backslashes have no special meaning, with C<\\>
1683 being treated as two backslashes and not one as they would in every
1684 other quoting construct.
1685
1686 This is the only form of quoting in perl where there is no need
1687 to worry about escaping content, something that code generators
1688 can and do make good use of.
1689
1690 =item Backticks
1691
1692 The content of the here doc is treated just as it would be if the
1693 string were embedded in backticks. Thus the content is interpolated
1694 as though it were double quoted and then executed via the shell, with
1695 the results of the execution returned.
1696
1697        print << `EOC`; # execute command and get results
1698     echo hi there
1699     EOC
1700
1701 =back
1702
1703 It is possible to stack multiple here-docs in a row:
1704
1705        print <<"foo", <<"bar"; # you can stack them
1706     I said foo.
1707     foo
1708     I said bar.
1709     bar
1710
1711        myfunc(<< "THIS", 23, <<'THAT');
1712     Here's a line
1713     or two.
1714     THIS
1715     and here's another.
1716     THAT
1717
1718 Just don't forget that you have to put a semicolon on the end
1719 to finish the statement, as Perl doesn't know you're not going to
1720 try to do this:
1721
1722        print <<ABC
1723     179231
1724     ABC
1725        + 20;
1726
1727 If you want to remove the line terminator from your here-docs,
1728 use C<chomp()>.
1729
1730     chomp($string = <<'END');
1731     This is a string.
1732     END
1733
1734 If you want your here-docs to be indented with the rest of the code,
1735 you'll need to remove leading whitespace from each line manually:
1736
1737     ($quote = <<'FINIS') =~ s/^\s+//gm;
1738        The Road goes ever on and on,
1739        down from the door where it began.
1740     FINIS
1741
1742 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1743 the quoted material must come on the lines following the final delimiter.
1744 So instead of
1745
1746     s/this/<<E . 'that'
1747     the other
1748     E
1749      . 'more '/eg;
1750
1751 you have to write
1752
1753     s/this/<<E . 'that'
1754      . 'more '/eg;
1755     the other
1756     E
1757
1758 If the terminating identifier is on the last line of the program, you
1759 must be sure there is a newline after it; otherwise, Perl will give the
1760 warning B<Can't find string terminator "END" anywhere before EOF...>.
1761
1762 Additionally, the quoting rules for the end of string identifier are not
1763 related to Perl's quoting rules -- C<q()>, C<qq()>, and the like are not
1764 supported in place of C<''> and C<"">, and the only interpolation is for
1765 backslashing the quoting character:
1766
1767     print << "abc\"def";
1768     testing...
1769     abc"def
1770
1771 Finally, quoted strings cannot span multiple lines.  The general rule is
1772 that the identifier must be a string literal.  Stick with that, and you
1773 should be safe.
1774
1775 =back
1776
1777 =head2 Gory details of parsing quoted constructs
1778 X<quote, gory details>
1779
1780 When presented with something that might have several different
1781 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1782 principle to pick the most probable interpretation.  This strategy
1783 is so successful that Perl programmers often do not suspect the
1784 ambivalence of what they write.  But from time to time, Perl's
1785 notions differ substantially from what the author honestly meant.
1786
1787 This section hopes to clarify how Perl handles quoted constructs.
1788 Although the most common reason to learn this is to unravel labyrinthine
1789 regular expressions, because the initial steps of parsing are the
1790 same for all quoting operators, they are all discussed together.
1791
1792 The most important Perl parsing rule is the first one discussed
1793 below: when processing a quoted construct, Perl first finds the end
1794 of that construct, then interprets its contents.  If you understand
1795 this rule, you may skip the rest of this section on the first
1796 reading.  The other rules are likely to contradict the user's
1797 expectations much less frequently than this first one.
1798
1799 Some passes discussed below are performed concurrently, but because
1800 their results are the same, we consider them individually.  For different
1801 quoting constructs, Perl performs different numbers of passes, from
1802 one to four, but these passes are always performed in the same order.
1803
1804 =over 4
1805
1806 =item Finding the end
1807
1808 The first pass is finding the end of the quoted construct, where
1809 the information about the delimiters is used in parsing.
1810 During this search, text between the starting and ending delimiters
1811 is copied to a safe location. The text copied gets delimiter-independent.
1812
1813 If the construct is a here-doc, the ending delimiter is a line
1814 that has a terminating string as the content. Therefore C<<<EOF> is
1815 terminated by C<EOF> immediately followed by C<"\n"> and starting
1816 from the first column of the terminating line.
1817 When searching for the terminating line of a here-doc, nothing
1818 is skipped. In other words, lines after the here-doc syntax
1819 are compared with the terminating string line by line.
1820
1821 For the constructs except here-docs, single characters are used as starting
1822 and ending delimiters. If the starting delimiter is an opening punctuation
1823 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
1824 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
1825 If the starting delimiter is an unpaired character like C</> or a closing
1826 punctuation, the ending delimiter is same as the starting delimiter.
1827 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
1828 C<qq[]> and C<qq]]> constructs.
1829
1830 When searching for single-character delimiters, escaped delimiters
1831 and C<\\> are skipped. For example, while searching for terminating C</>,
1832 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
1833 bracketing, nested pairs are also skipped.  For example, while searching
1834 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
1835 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
1836 However, when backslashes are used as the delimiters (like C<qq\\> and
1837 C<tr\\\>), nothing is skipped.
1838 During the search for the end, backslashes that escape delimiters
1839 are removed (exactly speaking, they are not copied to the safe location).
1840
1841 For constructs with three-part delimiters (C<s///>, C<y///>, and
1842 C<tr///>), the search is repeated once more.
1843 If the first delimiter is not an opening punctuation, three delimiters must
1844 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
1845 terminates the left part and starts the right part at once.
1846 If the left part is delimited by bracketing punctuations (that is C<()>,
1847 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
1848 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespaces
1849 and comments are allowed between both parts, though the comment must follow
1850 at least one whitespace; otherwise a character expected as the start of
1851 the comment may be regarded as the starting delimiter of the right part.
1852
1853 During this search no attention is paid to the semantics of the construct.
1854 Thus:
1855
1856     "$hash{"$foo/$bar"}"
1857
1858 or:
1859
1860     m/
1861       bar       # NOT a comment, this slash / terminated m//!
1862      /x
1863
1864 do not form legal quoted expressions.   The quoted part ends on the
1865 first C<"> and C</>, and the rest happens to be a syntax error.
1866 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1867 the example above is not C<m//x>, but rather C<m//> with no C</x>
1868 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1869
1870 Also no attention is paid to C<\c\> (multichar control char syntax) during
1871 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
1872 of C<\/>, and the following C</> is not recognized as a delimiter.
1873 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
1874
1875 =item Interpolation
1876 X<interpolation>
1877
1878 The next step is interpolation in the text obtained, which is now
1879 delimiter-independent.  There are multiple cases.
1880
1881 =over 4
1882
1883 =item C<<<'EOF'>
1884
1885 No interpolation is performed.
1886 Note that the combination C<\\> is left intact, since escaped delimiters
1887 are not available for here-docs.
1888
1889 =item  C<m''>, the pattern of C<s'''>
1890
1891 No interpolation is performed at this stage.
1892 Any backslashed sequences including C<\\> are treated at the stage
1893 to L</"parsing regular expressions">.
1894
1895 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
1896
1897 The only interpolation is removal of C<\> from pairs of C<\\>.
1898 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
1899 as a hyphen and no character range is available.
1900 C<\1> in the replacement of C<s'''> does not work as C<$1>.
1901
1902 =item C<tr///>, C<y///>
1903
1904 No variable interpolation occurs.  String modifying combinations for
1905 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
1906 The other escape sequences such as C<\200> and C<\t> and backslashed
1907 characters such as C<\\> and C<\-> are converted to appropriate literals.
1908 The character C<-> is treated specially and therefore C<\-> is treated
1909 as a literal C<->.
1910
1911 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
1912
1913 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1914 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1915 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1916 The other escape sequences such as C<\200> and C<\t> and backslashed
1917 characters such as C<\\> and C<\-> are replaced with appropriate
1918 expansions.
1919
1920 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1921 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1922 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1923 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1924 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1925 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1926 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1927
1928   $str = '\t';
1929   return "\Q$str";
1930
1931 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1932
1933 Interpolated scalars and arrays are converted internally to the C<join> and
1934 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1935
1936   $foo . " XXX '" . (join $", @arr) . "'";
1937
1938 All operations above are performed simultaneously, left to right.
1939
1940 Because the result of C<"\Q STRING \E"> has all metacharacters
1941 quoted, there is no way to insert a literal C<$> or C<@> inside a
1942 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1943 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1944 scalar.
1945
1946 Note also that the interpolation code needs to make a decision on
1947 where the interpolated scalar ends.  For instance, whether
1948 C<< "a $b -> {c}" >> really means:
1949
1950   "a " . $b . " -> {c}";
1951
1952 or:
1953
1954   "a " . $b -> {c};
1955
1956 Most of the time, the longest possible text that does not include
1957 spaces between components and which contains matching braces or
1958 brackets.  because the outcome may be determined by voting based
1959 on heuristic estimators, the result is not strictly predictable.
1960 Fortunately, it's usually correct for ambiguous cases.
1961
1962 =item the replacement of C<s///>
1963
1964 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1965 happens as with C<qq//> constructs.
1966
1967 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1968 the replacement text of C<s///>, in order to correct the incorrigible
1969 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1970 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
1971 (that is, the C<$^W> variable) was set.
1972
1973 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
1974
1975 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\E>,
1976 and interpolation happens (almost) as with C<qq//> constructs.
1977
1978 However any other combinations of C<\> followed by a character
1979 are not substituted but only skipped, in order to parse them
1980 as regular expressions at the following step.
1981 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
1982 treated as an array symbol (for example C<@foo>),
1983 even though the same text in C<qq//> gives interpolation of C<\c@>.
1984
1985 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1986 a C<#>-comment in a C<//x>-regular expression, no processing is
1987 performed whatsoever.  This is the first step at which the presence
1988 of the C<//x> modifier is relevant.
1989
1990 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
1991 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
1992 voted (by several different estimators) to be either an array element
1993 or C<$var> followed by an RE alternative.  This is where the notation
1994 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1995 array element C<-9>, not as a regular expression from the variable
1996 C<$arr> followed by a digit, which would be the interpretation of
1997 C</$arr[0-9]/>.  Since voting among different estimators may occur,
1998 the result is not predictable.
1999
2000 The lack of processing of C<\\> creates specific restrictions on
2001 the post-processed text.  If the delimiter is C</>, one cannot get
2002 the combination C<\/> into the result of this step.  C</> will
2003 finish the regular expression, C<\/> will be stripped to C</> on
2004 the previous step, and C<\\/> will be left as is.  Because C</> is
2005 equivalent to C<\/> inside a regular expression, this does not
2006 matter unless the delimiter happens to be character special to the
2007 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2008 alphanumeric char, as in:
2009
2010   m m ^ a \s* b mmx;
2011
2012 In the RE above, which is intentionally obfuscated for illustration, the
2013 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2014 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2015 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2016 non-whitespace choices.
2017
2018 =back
2019
2020 This step is the last one for all constructs except regular expressions,
2021 which are processed further.
2022
2023 =item parsing regular expressions
2024 X<regexp, parse>
2025
2026 Previous steps were performed during the compilation of Perl code,
2027 but this one happens at run time--although it may be optimized to
2028 be calculated at compile time if appropriate.  After preprocessing
2029 described above, and possibly after evaluation if concatenation,
2030 joining, casing translation, or metaquoting are involved, the
2031 resulting I<string> is passed to the RE engine for compilation.
2032
2033 Whatever happens in the RE engine might be better discussed in L<perlre>,
2034 but for the sake of continuity, we shall do so here.
2035
2036 This is another step where the presence of the C<//x> modifier is
2037 relevant.  The RE engine scans the string from left to right and
2038 converts it to a finite automaton.
2039
2040 Backslashed characters are either replaced with corresponding
2041 literal strings (as with C<\{>), or else they generate special nodes
2042 in the finite automaton (as with C<\b>).  Characters special to the
2043 RE engine (such as C<|>) generate corresponding nodes or groups of
2044 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2045 converted to literal strings to match, or else is ignored (as is
2046 whitespace and C<#>-style comments if C<//x> is present).
2047
2048 Parsing of the bracketed character class construct, C<[...]>, is
2049 rather different than the rule used for the rest of the pattern.
2050 The terminator of this construct is found using the same rules as
2051 for finding the terminator of a C<{}>-delimited construct, the only
2052 exception being that C<]> immediately following C<[> is treated as
2053 though preceded by a backslash.  Similarly, the terminator of
2054 C<(?{...})> is found using the same rules as for finding the
2055 terminator of a C<{}>-delimited construct.
2056
2057 It is possible to inspect both the string given to RE engine and the
2058 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2059 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2060 switch documented in L<perlrun/"Command Switches">.
2061
2062 =item Optimization of regular expressions
2063 X<regexp, optimization>
2064
2065 This step is listed for completeness only.  Since it does not change
2066 semantics, details of this step are not documented and are subject
2067 to change without notice.  This step is performed over the finite
2068 automaton that was generated during the previous pass.
2069
2070 It is at this stage that C<split()> silently optimizes C</^/> to
2071 mean C</^/m>.
2072
2073 =back
2074
2075 =head2 I/O Operators
2076 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2077 X<< <> >> X<@ARGV>
2078
2079 There are several I/O operators you should know about.
2080
2081 A string enclosed by backticks (grave accents) first undergoes
2082 double-quote interpolation.  It is then interpreted as an external
2083 command, and the output of that command is the value of the
2084 backtick string, like in a shell.  In scalar context, a single string
2085 consisting of all output is returned.  In list context, a list of
2086 values is returned, one per line of output.  (You can set C<$/> to use
2087 a different line terminator.)  The command is executed each time the
2088 pseudo-literal is evaluated.  The status value of the command is
2089 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2090 Unlike in B<csh>, no translation is done on the return data--newlines
2091 remain newlines.  Unlike in any of the shells, single quotes do not
2092 hide variable names in the command from interpretation.  To pass a
2093 literal dollar-sign through to the shell you need to hide it with a
2094 backslash.  The generalized form of backticks is C<qx//>.  (Because
2095 backticks always undergo shell expansion as well, see L<perlsec> for
2096 security concerns.)
2097 X<qx> X<`> X<``> X<backtick> X<glob>
2098
2099 In scalar context, evaluating a filehandle in angle brackets yields
2100 the next line from that file (the newline, if any, included), or
2101 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2102 (sometimes known as file-slurp mode) and the file is empty, it
2103 returns C<''> the first time, followed by C<undef> subsequently.
2104
2105 Ordinarily you must assign the returned value to a variable, but
2106 there is one situation where an automatic assignment happens.  If
2107 and only if the input symbol is the only thing inside the conditional
2108 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2109 the value is automatically assigned to the global variable $_,
2110 destroying whatever was there previously.  (This may seem like an
2111 odd thing to you, but you'll use the construct in almost every Perl
2112 script you write.)  The $_ variable is not implicitly localized.
2113 You'll have to put a C<local $_;> before the loop if you want that
2114 to happen.
2115
2116 The following lines are equivalent:
2117
2118     while (defined($_ = <STDIN>)) { print; }
2119     while ($_ = <STDIN>) { print; }
2120     while (<STDIN>) { print; }
2121     for (;<STDIN>;) { print; }
2122     print while defined($_ = <STDIN>);
2123     print while ($_ = <STDIN>);
2124     print while <STDIN>;
2125
2126 This also behaves similarly, but avoids $_ :
2127
2128     while (my $line = <STDIN>) { print $line }
2129
2130 In these loop constructs, the assigned value (whether assignment
2131 is automatic or explicit) is then tested to see whether it is
2132 defined.  The defined test avoids problems where line has a string
2133 value that would be treated as false by Perl, for example a "" or
2134 a "0" with no trailing newline.  If you really mean for such values
2135 to terminate the loop, they should be tested for explicitly:
2136
2137     while (($_ = <STDIN>) ne '0') { ... }
2138     while (<STDIN>) { last unless $_; ... }
2139
2140 In other boolean contexts, C<< <I<filehandle>> >> without an
2141 explicit C<defined> test or comparison elicit a warning if the
2142 C<use warnings> pragma or the B<-w>
2143 command-line switch (the C<$^W> variable) is in effect.
2144
2145 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2146 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2147 in packages, where they would be interpreted as local identifiers
2148 rather than global.)  Additional filehandles may be created with
2149 the open() function, amongst others.  See L<perlopentut> and
2150 L<perlfunc/open> for details on this.
2151 X<stdin> X<stdout> X<sterr>
2152
2153 If a <FILEHANDLE> is used in a context that is looking for
2154 a list, a list comprising all input lines is returned, one line per
2155 list element.  It's easy to grow to a rather large data space this
2156 way, so use with care.
2157
2158 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2159 See L<perlfunc/readline>.
2160
2161 The null filehandle <> is special: it can be used to emulate the
2162 behavior of B<sed> and B<awk>.  Input from <> comes either from
2163 standard input, or from each file listed on the command line.  Here's
2164 how it works: the first time <> is evaluated, the @ARGV array is
2165 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2166 gives you standard input.  The @ARGV array is then processed as a list
2167 of filenames.  The loop
2168
2169     while (<>) {
2170         ...                     # code for each line
2171     }
2172
2173 is equivalent to the following Perl-like pseudo code:
2174
2175     unshift(@ARGV, '-') unless @ARGV;
2176     while ($ARGV = shift) {
2177         open(ARGV, $ARGV);
2178         while (<ARGV>) {
2179             ...         # code for each line
2180         }
2181     }
2182
2183 except that it isn't so cumbersome to say, and will actually work.
2184 It really does shift the @ARGV array and put the current filename
2185 into the $ARGV variable.  It also uses filehandle I<ARGV>
2186 internally--<> is just a synonym for <ARGV>, which
2187 is magical.  (The pseudo code above doesn't work because it treats
2188 <ARGV> as non-magical.)
2189
2190 You can modify @ARGV before the first <> as long as the array ends up
2191 containing the list of filenames you really want.  Line numbers (C<$.>)
2192 continue as though the input were one big happy file.  See the example
2193 in L<perlfunc/eof> for how to reset line numbers on each file.
2194
2195 If you want to set @ARGV to your own list of files, go right ahead.
2196 This sets @ARGV to all plain text files if no @ARGV was given:
2197
2198     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2199
2200 You can even set them to pipe commands.  For example, this automatically
2201 filters compressed arguments through B<gzip>:
2202
2203     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2204
2205 If you want to pass switches into your script, you can use one of the
2206 Getopts modules or put a loop on the front like this:
2207
2208     while ($_ = $ARGV[0], /^-/) {
2209         shift;
2210         last if /^--$/;
2211         if (/^-D(.*)/) { $debug = $1 }
2212         if (/^-v/)     { $verbose++  }
2213         # ...           # other switches
2214     }
2215
2216     while (<>) {
2217         # ...           # code for each line
2218     }
2219
2220 The <> symbol will return C<undef> for end-of-file only once.
2221 If you call it again after this, it will assume you are processing another
2222 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2223
2224 If what the angle brackets contain is a simple scalar variable (e.g.,
2225 <$foo>), then that variable contains the name of the
2226 filehandle to input from, or its typeglob, or a reference to the
2227 same.  For example:
2228
2229     $fh = \*STDIN;
2230     $line = <$fh>;
2231
2232 If what's within the angle brackets is neither a filehandle nor a simple
2233 scalar variable containing a filehandle name, typeglob, or typeglob
2234 reference, it is interpreted as a filename pattern to be globbed, and
2235 either a list of filenames or the next filename in the list is returned,
2236 depending on context.  This distinction is determined on syntactic
2237 grounds alone.  That means C<< <$x> >> is always a readline() from
2238 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2239 That's because $x is a simple scalar variable, but C<$hash{key}> is
2240 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2241 is treated as C<glob("$x ")>, not C<readline($x)>.
2242
2243 One level of double-quote interpretation is done first, but you can't
2244 say C<< <$foo> >> because that's an indirect filehandle as explained
2245 in the previous paragraph.  (In older versions of Perl, programmers
2246 would insert curly brackets to force interpretation as a filename glob:
2247 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2248 internal function directly as C<glob($foo)>, which is probably the right
2249 way to have done it in the first place.)  For example:
2250
2251     while (<*.c>) {
2252         chmod 0644, $_;
2253     }
2254
2255 is roughly equivalent to:
2256
2257     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2258     while (<FOO>) {
2259         chomp;
2260         chmod 0644, $_;
2261     }
2262
2263 except that the globbing is actually done internally using the standard
2264 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2265
2266     chmod 0644, <*.c>;
2267
2268 A (file)glob evaluates its (embedded) argument only when it is
2269 starting a new list.  All values must be read before it will start
2270 over.  In list context, this isn't important because you automatically
2271 get them all anyway.  However, in scalar context the operator returns
2272 the next value each time it's called, or C<undef> when the list has
2273 run out.  As with filehandle reads, an automatic C<defined> is
2274 generated when the glob occurs in the test part of a C<while>,
2275 because legal glob returns (e.g. a file called F<0>) would otherwise
2276 terminate the loop.  Again, C<undef> is returned only once.  So if
2277 you're expecting a single value from a glob, it is much better to
2278 say
2279
2280     ($file) = <blurch*>;
2281
2282 than
2283
2284     $file = <blurch*>;
2285
2286 because the latter will alternate between returning a filename and
2287 returning false.
2288
2289 If you're trying to do variable interpolation, it's definitely better
2290 to use the glob() function, because the older notation can cause people
2291 to become confused with the indirect filehandle notation.
2292
2293     @files = glob("$dir/*.[ch]");
2294     @files = glob($files[$i]);
2295
2296 =head2 Constant Folding
2297 X<constant folding> X<folding>
2298
2299 Like C, Perl does a certain amount of expression evaluation at
2300 compile time whenever it determines that all arguments to an
2301 operator are static and have no side effects.  In particular, string
2302 concatenation happens at compile time between literals that don't do
2303 variable substitution.  Backslash interpolation also happens at
2304 compile time.  You can say
2305
2306     'Now is the time for all' . "\n" .
2307         'good men to come to.'
2308
2309 and this all reduces to one string internally.  Likewise, if
2310 you say
2311
2312     foreach $file (@filenames) {
2313         if (-s $file > 5 + 100 * 2**16) {  }
2314     }
2315
2316 the compiler will precompute the number which that expression
2317 represents so that the interpreter won't have to.
2318
2319 =head2 No-ops
2320 X<no-op> X<nop>
2321
2322 Perl doesn't officially have a no-op operator, but the bare constants
2323 C<0> and C<1> are special-cased to not produce a warning in a void
2324 context, so you can for example safely do
2325
2326     1 while foo();
2327
2328 =head2 Bitwise String Operators
2329 X<operator, bitwise, string>
2330
2331 Bitstrings of any size may be manipulated by the bitwise operators
2332 (C<~ | & ^>).
2333
2334 If the operands to a binary bitwise op are strings of different
2335 sizes, B<|> and B<^> ops act as though the shorter operand had
2336 additional zero bits on the right, while the B<&> op acts as though
2337 the longer operand were truncated to the length of the shorter.
2338 The granularity for such extension or truncation is one or more
2339 bytes.
2340
2341     # ASCII-based examples
2342     print "j p \n" ^ " a h";            # prints "JAPH\n"
2343     print "JA" | "  ph\n";              # prints "japh\n"
2344     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2345     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2346
2347 If you are intending to manipulate bitstrings, be certain that
2348 you're supplying bitstrings: If an operand is a number, that will imply
2349 a B<numeric> bitwise operation.  You may explicitly show which type of
2350 operation you intend by using C<""> or C<0+>, as in the examples below.
2351
2352     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2353     $foo = '150' |  105;        # yields 255
2354     $foo =  150  | '105';       # yields 255
2355     $foo = '150' | '105';       # yields string '155' (under ASCII)
2356
2357     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2358     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2359
2360 See L<perlfunc/vec> for information on how to manipulate individual bits
2361 in a bit vector.
2362
2363 =head2 Integer Arithmetic
2364 X<integer>
2365
2366 By default, Perl assumes that it must do most of its arithmetic in
2367 floating point.  But by saying
2368
2369     use integer;
2370
2371 you may tell the compiler that it's okay to use integer operations
2372 (if it feels like it) from here to the end of the enclosing BLOCK.
2373 An inner BLOCK may countermand this by saying
2374
2375     no integer;
2376
2377 which lasts until the end of that BLOCK.  Note that this doesn't
2378 mean everything is only an integer, merely that Perl may use integer
2379 operations if it is so inclined.  For example, even under C<use
2380 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
2381 or so.
2382
2383 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2384 and ">>") always produce integral results.  (But see also
2385 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2386 them.  By default, their results are interpreted as unsigned integers, but
2387 if C<use integer> is in effect, their results are interpreted
2388 as signed integers.  For example, C<~0> usually evaluates to a large
2389 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2390 machines.
2391
2392 =head2 Floating-point Arithmetic
2393 X<floating-point> X<floating point> X<float> X<real>
2394
2395 While C<use integer> provides integer-only arithmetic, there is no
2396 analogous mechanism to provide automatic rounding or truncation to a
2397 certain number of decimal places.  For rounding to a certain number
2398 of digits, sprintf() or printf() is usually the easiest route.
2399 See L<perlfaq4>.
2400
2401 Floating-point numbers are only approximations to what a mathematician
2402 would call real numbers.  There are infinitely more reals than floats,
2403 so some corners must be cut.  For example:
2404
2405     printf "%.20g\n", 123456789123456789;
2406     #        produces 123456789123456784
2407
2408 Testing for exact equality of floating-point equality or inequality is
2409 not a good idea.  Here's a (relatively expensive) work-around to compare
2410 whether two floating-point numbers are equal to a particular number of
2411 decimal places.  See Knuth, volume II, for a more robust treatment of
2412 this topic.
2413
2414     sub fp_equal {
2415         my ($X, $Y, $POINTS) = @_;
2416         my ($tX, $tY);
2417         $tX = sprintf("%.${POINTS}g", $X);
2418         $tY = sprintf("%.${POINTS}g", $Y);
2419         return $tX eq $tY;
2420     }
2421
2422 The POSIX module (part of the standard perl distribution) implements
2423 ceil(), floor(), and other mathematical and trigonometric functions.
2424 The Math::Complex module (part of the standard perl distribution)
2425 defines mathematical functions that work on both the reals and the
2426 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2427 POSIX can't work with complex numbers.
2428
2429 Rounding in financial applications can have serious implications, and
2430 the rounding method used should be specified precisely.  In these
2431 cases, it probably pays not to trust whichever system rounding is
2432 being used by Perl, but to instead implement the rounding function you
2433 need yourself.
2434
2435 =head2 Bigger Numbers
2436 X<number, arbitrary precision>
2437
2438 The standard Math::BigInt and Math::BigFloat modules provide
2439 variable-precision arithmetic and overloaded operators, although
2440 they're currently pretty slow. At the cost of some space and
2441 considerable speed, they avoid the normal pitfalls associated with
2442 limited-precision representations.
2443
2444     use Math::BigInt;
2445     $x = Math::BigInt->new('123456789123456789');
2446     print $x * $x;
2447
2448     # prints +15241578780673678515622620750190521
2449
2450 There are several modules that let you calculate with (bound only by
2451 memory and cpu-time) unlimited or fixed precision. There are also
2452 some non-standard modules that provide faster implementations via
2453 external C libraries.
2454
2455 Here is a short, but incomplete summary:
2456
2457         Math::Fraction          big, unlimited fractions like 9973 / 12967
2458         Math::String            treat string sequences like numbers
2459         Math::FixedPrecision    calculate with a fixed precision
2460         Math::Currency          for currency calculations
2461         Bit::Vector             manipulate bit vectors fast (uses C)
2462         Math::BigIntFast        Bit::Vector wrapper for big numbers
2463         Math::Pari              provides access to the Pari C library
2464         Math::BigInteger        uses an external C library
2465         Math::Cephes            uses external Cephes C library (no big numbers)
2466         Math::Cephes::Fraction  fractions via the Cephes library
2467         Math::GMP               another one using an external C library
2468
2469 Choose wisely.
2470
2471 =cut