This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
ce861932d1fbb1852c8e178db41d0a1390a63d9b
[perl5.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPf_PARENS
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          SVpad_TYPED
21          CVf_METHOD CVf_LVALUE
22          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
23          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED PMf_EXTENDED_MORE);
24 $VERSION = '1.29';
25 use strict;
26 use vars qw/$AUTOLOAD/;
27 use warnings ();
28 require feature;
29
30 BEGIN {
31     # List version-specific constants here.
32     # Easiest way to keep this code portable between version looks to
33     # be to fake up a dummy constant that will never actually be true.
34     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
35                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
36                 RXf_PMf_CHARSET RXf_PMf_KEEPCOPY
37                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
38                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES
39                 OPpLVREF_TYPE OPpLVREF_SV OPpLVREF_AV OPpLVREF_HV
40                 OPpLVREF_CV OPpLVREF_ELEM SVpad_STATE)) {
41         eval { import B $_ };
42         no strict 'refs';
43         *{$_} = sub () {0} unless *{$_}{CODE};
44     }
45 }
46
47 # Changes between 0.50 and 0.51:
48 # - fixed nulled leave with live enter in sort { }
49 # - fixed reference constants (\"str")
50 # - handle empty programs gracefully
51 # - handle infinite loops (for (;;) {}, while (1) {})
52 # - differentiate between 'for my $x ...' and 'my $x; for $x ...'
53 # - various minor cleanups
54 # - moved globals into an object
55 # - added '-u', like B::C
56 # - package declarations using cop_stash
57 # - subs, formats and code sorted by cop_seq
58 # Changes between 0.51 and 0.52:
59 # - added pp_threadsv (special variables under USE_5005THREADS)
60 # - added documentation
61 # Changes between 0.52 and 0.53:
62 # - many changes adding precedence contexts and associativity
63 # - added '-p' and '-s' output style options
64 # - various other minor fixes
65 # Changes between 0.53 and 0.54:
66 # - added support for new 'for (1..100)' optimization,
67 #   thanks to Gisle Aas
68 # Changes between 0.54 and 0.55:
69 # - added support for new qr// construct
70 # - added support for new pp_regcreset OP
71 # Changes between 0.55 and 0.56:
72 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
73 # - fixed $# on non-lexicals broken in last big rewrite
74 # - added temporary fix for change in opcode of OP_STRINGIFY
75 # - fixed problem in 0.54's for() patch in 'for (@ary)'
76 # - fixed precedence in conditional of ?:
77 # - tweaked list paren elimination in 'my($x) = @_'
78 # - made continue-block detection trickier wrt. null ops
79 # - fixed various prototype problems in pp_entersub
80 # - added support for sub prototypes that never get GVs
81 # - added unquoting for special filehandle first arg in truncate
82 # - print doubled rv2gv (a bug) as '*{*GV}' instead of illegal '**GV'
83 # - added semicolons at the ends of blocks
84 # - added -l '#line' declaration option -- fixes cmd/subval.t 27,28
85 # Changes between 0.56 and 0.561:
86 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
87 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
88 # Changes between 0.561 and 0.57:
89 # - stylistic changes to symbolic constant stuff
90 # - handled scope in s///e replacement code
91 # - added unquote option for expanding "" into concats, etc.
92 # - split method and proto parts of pp_entersub into separate functions
93 # - various minor cleanups
94 # Changes after 0.57:
95 # - added parens in \&foo (patch by Albert Dvornik)
96 # Changes between 0.57 and 0.58:
97 # - fixed '0' statements that weren't being printed
98 # - added methods for use from other programs
99 #   (based on patches from James Duncan and Hugo van der Sanden)
100 # - added -si and -sT to control indenting (also based on a patch from Hugo)
101 # - added -sv to print something else instead of '???'
102 # - preliminary version of utf8 tr/// handling
103 # Changes after 0.58:
104 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
105 # - added support for Hugo's new OP_SETSTATE (like nextstate)
106 # Changes between 0.58 and 0.59
107 # - added support for Chip's OP_METHOD_NAMED
108 # - added support for Ilya's OPpTARGET_MY optimization
109 # - elided arrows before '()' subscripts when possible
110 # Changes between 0.59 and 0.60
111 # - support for method attributes was added
112 # - some warnings fixed
113 # - separate recognition of constant subs
114 # - rewrote continue block handling, now recognizing for loops
115 # - added more control of expanding control structures
116 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
117 # - many bug-fixes
118 # - support for pragmas and 'use'
119 # - support for the little-used $[ variable
120 # - support for __DATA__ sections
121 # - UTF8 support
122 # - BEGIN, CHECK, INIT and END blocks
123 # - scoping of subroutine declarations fixed
124 # - compile-time output from the input program can be suppressed, so that the
125 #   output is just the deparsed code. (a change to O.pm in fact)
126 # - our() declarations
127 # - *all* the known bugs are now listed in the BUGS section
128 # - comprehensive test mechanism (TEST -deparse)
129 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
130 # - bug-fixes
131 # - new switch -P
132 # - support for command-line switches (-l, -0, etc.)
133 # Changes between 0.63 and 0.64
134 # - support for //, CHECK blocks, and assertions
135 # - improved handling of foreach loops and lexicals
136 # - option to use Data::Dumper for constants
137 # - more bug fixes
138 # - discovered lots more bugs not yet fixed
139 #
140 # ...
141 #
142 # Changes between 0.72 and 0.73
143 # - support new switch constructs
144
145 # Todo:
146 #  (See also BUGS section at the end of this file)
147 #
148 # - finish tr/// changes
149 # - add option for even more parens (generalize \&foo change)
150 # - left/right context
151 # - copy comments (look at real text with $^P?)
152 # - avoid semis in one-statement blocks
153 # - associativity of &&=, ||=, ?:
154 # - ',' => '=>' (auto-unquote?)
155 # - break long lines ("\r" as discretionary break?)
156 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
157 # - more style options: brace style, hex vs. octal, quotes, ...
158 # - print big ints as hex/octal instead of decimal (heuristic?)
159 # - handle 'my $x if 0'?
160 # - version using op_next instead of op_first/sibling?
161 # - avoid string copies (pass arrays, one big join?)
162 # - here-docs?
163
164 # Current test.deparse failures
165 # comp/hints 6 - location of BEGIN blocks wrt. block openings
166 # run/switchI 1 - missing -I switches entirely
167 #    perl -Ifoo -e 'print @INC'
168 # op/caller 2 - warning mask propagates backwards before warnings::register
169 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
170 # op/getpid 2 - can't assign to shared my() declaration (threads only)
171 #    'my $x : shared = 5'
172 # op/override 7 - parens on overridden require change v-string interpretation
173 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
174 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
175 # op/pat 774 - losing Unicode-ness of Latin1-only strings
176 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
177 # op/recurse 12 - missing parens on recursive call makes it look like method
178 #    'sub f { f($x) }'
179 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
180 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
181 # op/tiehandle compile - "use strict" deparsed in the wrong place
182 # uni/tr_ several
183 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
184 # ext/Data/Dumper/t/dumper compile
185 # ext/DB_file/several
186 # ext/Encode/several
187 # ext/Ernno/Errno warnings
188 # ext/IO/lib/IO/t/io_sel 23
189 # ext/PerlIO/t/encoding compile
190 # ext/POSIX/t/posix 6
191 # ext/Socket/Socket 8
192 # ext/Storable/t/croak compile
193 # lib/Attribute/Handlers/t/multi compile
194 # lib/bignum/ several
195 # lib/charnames 35
196 # lib/constant 32
197 # lib/English 40
198 # lib/ExtUtils/t/bytes 4
199 # lib/File/DosGlob compile
200 # lib/Filter/Simple/t/data 1
201 # lib/Math/BigInt/t/constant 1
202 # lib/Net/t/config Deparse-warning
203 # lib/overload compile
204 # lib/Switch/ several
205 # lib/Symbol 4
206 # lib/Test/Simple several
207 # lib/Term/Complete
208 # lib/Tie/File/t/29_downcopy 5
209 # lib/vars 22
210
211 # Object fields (were globals):
212 #
213 # avoid_local:
214 # (local($a), local($b)) and local($a, $b) have the same internal
215 # representation but the short form looks better. We notice we can
216 # use a large-scale local when checking the list, but need to prevent
217 # individual locals too. This hash holds the addresses of OPs that
218 # have already had their local-ness accounted for. The same thing
219 # is done with my().
220 #
221 # curcv:
222 # CV for current sub (or main program) being deparsed
223 #
224 # curcvlex:
225 # Cached hash of lexical variables for curcv: keys are
226 # names prefixed with "m" or "o" (representing my/our), and
227 # each value is an array with two elements indicating the cop_seq
228 # of scopes in which a var of that name is valid and a third ele-
229 # ment referencing the pad name.
230 #
231 # curcop:
232 # COP for statement being deparsed
233 #
234 # curstash:
235 # name of the current package for deparsed code
236 #
237 # subs_todo:
238 # array of [cop_seq, CV, is_format?] for subs and formats we still
239 # want to deparse
240 #
241 # protos_todo:
242 # as above, but [name, prototype] for subs that never got a GV
243 #
244 # subs_done, forms_done:
245 # keys are addresses of GVs for subs and formats we've already
246 # deparsed (or at least put into subs_todo)
247 #
248 # subs_declared
249 # keys are names of subs for which we've printed declarations.
250 # That means we can omit parentheses from the arguments. It also means we
251 # need to put CORE:: on core functions of the same name.
252 #
253 # subs_deparsed
254 # Keeps track of fully qualified names of all deparsed subs.
255 #
256 # in_subst_repl
257 # True when deparsing the replacement part of a substitution.
258 #
259 # in_refgen
260 # True when deparsing the argument to \.
261 #
262 # parens: -p
263 # linenums: -l
264 # unquote: -q
265 # cuddle: ' ' or '\n', depending on -sC
266 # indent_size: -si
267 # use_tabs: -sT
268 # ex_const: -sv
269
270 # A little explanation of how precedence contexts and associativity
271 # work:
272 #
273 # deparse() calls each per-op subroutine with an argument $cx (short
274 # for context, but not the same as the cx* in the perl core), which is
275 # a number describing the op's parents in terms of precedence, whether
276 # they're inside an expression or at statement level, etc.  (see
277 # chart below). When ops with children call deparse on them, they pass
278 # along their precedence. Fractional values are used to implement
279 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
280 # parentheses hacks. The major disadvantage of this scheme is that
281 # it doesn't know about right sides and left sides, so say if you
282 # assign a listop to a variable, it can't tell it's allowed to leave
283 # the parens off the listop.
284
285 # Precedences:
286 # 26             [TODO] inside interpolation context ("")
287 # 25 left        terms and list operators (leftward)
288 # 24 left        ->
289 # 23 nonassoc    ++ --
290 # 22 right       **
291 # 21 right       ! ~ \ and unary + and -
292 # 20 left        =~ !~
293 # 19 left        * / % x
294 # 18 left        + - .
295 # 17 left        << >>
296 # 16 nonassoc    named unary operators
297 # 15 nonassoc    < > <= >= lt gt le ge
298 # 14 nonassoc    == != <=> eq ne cmp
299 # 13 left        &
300 # 12 left        | ^
301 # 11 left        &&
302 # 10 left        ||
303 #  9 nonassoc    ..  ...
304 #  8 right       ?:
305 #  7 right       = += -= *= etc.
306 #  6 left        , =>
307 #  5 nonassoc    list operators (rightward)
308 #  4 right       not
309 #  3 left        and
310 #  2 left        or xor
311 #  1             statement modifiers
312 #  0.5           statements, but still print scopes as do { ... }
313 #  0             statement level
314 # -1             format body
315
316 # Nonprinting characters with special meaning:
317 # \cS - steal parens (see maybe_parens_unop)
318 # \n - newline and indent
319 # \t - increase indent
320 # \b - decrease indent ('outdent')
321 # \f - flush left (no indent)
322 # \cK - kill following semicolon, if any
323
324
325
326 BEGIN { for (qw[ const stringify rv2sv list glob pushmark null aelem]) {
327     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
328 }}
329
330 # _pessimise_walk(): recursively walk the optree of a sub,
331 # possibly undoing optimisations along the way.
332
333 sub _pessimise_walk {
334     my ($self, $startop) = @_;
335
336     return unless $$startop;
337     my ($op, $prevop);
338     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
339         my $ppname = $op->name;
340
341         # pessimisations start here
342
343         if ($ppname eq "padrange") {
344             # remove PADRANGE:
345             # the original optimisation either (1) changed this:
346             #    pushmark -> (various pad and list and null ops) -> the_rest
347             # or (2), for the = @_ case, changed this:
348             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
349             # into this:
350             #    padrange ----------------------------------------> the_rest
351             # so we just need to convert the padrange back into a
352             # pushmark, and in case (1), set its op_next to op_sibling,
353             # which is the head of the original chain of optimised-away
354             # pad ops, or for (2), set it to sibling->first, which is
355             # the original gv[_].
356
357             $B::overlay->{$$op} = {
358                     type => OP_PUSHMARK,
359                     name => 'pushmark',
360                     private => ($op->private & OPpLVAL_INTRO),
361                     next    => ($op->flags & OPf_SPECIAL)
362                                     ? $op->sibling->first
363                                     : $op->sibling,
364             };
365         }
366
367         # pessimisations end here
368
369         if (class($op) eq 'PMOP'
370             && ref($op->pmreplroot)
371             && ${$op->pmreplroot}
372             && $op->pmreplroot->isa( 'B::OP' ))
373         {
374             $self-> _pessimise_walk($op->pmreplroot);
375         }
376
377         if ($op->flags & OPf_KIDS) {
378             $self-> _pessimise_walk($op->first);
379         }
380
381     }
382 }
383
384
385 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
386 # possibly undoing optimisations along the way.
387
388 sub _pessimise_walk_exe {
389     my ($self, $startop, $visited) = @_;
390
391     return unless $$startop;
392     return if $visited->{$$startop};
393     my ($op, $prevop);
394     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
395         last if $visited->{$$op};
396         $visited->{$$op} = 1;
397         my $ppname = $op->name;
398         if ($ppname =~
399             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
400             # entertry is also a logop, but its op_other invariably points
401             # into the same chain as the main execution path, so we skip it
402         ) {
403             $self->_pessimise_walk_exe($op->other, $visited);
404         }
405         elsif ($ppname eq "subst") {
406             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
407         }
408         elsif ($ppname =~ /^(enter(loop|iter))$/) {
409             # redoop and nextop will already be covered by the main block
410             # of the loop
411             $self->_pessimise_walk_exe($op->lastop, $visited);
412         }
413
414         # pessimisations start here
415     }
416 }
417
418 # Go through an optree and "remove" some optimisations by using an
419 # overlay to selectively modify or un-null some ops. Deparsing in the
420 # absence of those optimisations is then easier.
421 #
422 # Note that older optimisations are not removed, as Deparse was already
423 # written to recognise them before the pessimise/overlay system was added.
424
425 sub pessimise {
426     my ($self, $root, $start) = @_;
427
428     # walk tree in root-to-branch order
429     $self->_pessimise_walk($root);
430
431     my %visited;
432     # walk tree in execution order
433     $self->_pessimise_walk_exe($start, \%visited);
434 }
435
436
437 sub null {
438     my $op = shift;
439     return class($op) eq "NULL";
440 }
441
442 sub todo {
443     my $self = shift;
444     my($cv, $is_form) = @_;
445     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
446     my $seq;
447     if ($cv->OUTSIDE_SEQ) {
448         $seq = $cv->OUTSIDE_SEQ;
449     } elsif (!null($cv->START) and is_state($cv->START)) {
450         $seq = $cv->START->cop_seq;
451     } else {
452         $seq = 0;
453     }
454     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
455     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
456         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
457     }
458 }
459
460 sub next_todo {
461     my $self = shift;
462     my $ent = shift @{$self->{'subs_todo'}};
463     my $cv = $ent->[1];
464     my $gv = $cv->GV;
465     my $name = $self->gv_name($gv);
466     if ($ent->[2]) {
467         return $self->keyword("format") . " $name =\n"
468             . $self->deparse_format($ent->[1]). "\n";
469     } else {
470         $self->{'subs_declared'}{$name} = 1;
471         if ($name eq "BEGIN") {
472             my $use_dec = $self->begin_is_use($cv);
473             if (defined ($use_dec) and $self->{'expand'} < 5) {
474                 return () if 0 == length($use_dec);
475                 $use_dec =~ s/^(use|no)\b/$self->keyword($1)/e;
476                 return $use_dec;
477             }
478         }
479         my $l = '';
480         if ($self->{'linenums'}) {
481             my $line = $gv->LINE;
482             my $file = $gv->FILE;
483             $l = "\n\f#line $line \"$file\"\n";
484         }
485         my $p = '';
486         if (class($cv->STASH) ne "SPECIAL") {
487             my $stash = $cv->STASH->NAME;
488             if ($stash ne $self->{'curstash'}) {
489                 $p = $self->keyword("package") . " $stash;\n";
490                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
491                 $self->{'curstash'} = $stash;
492             }
493             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
494         }
495         return "${p}${l}" . $self->keyword("sub") . " $name "
496               . $self->deparse_sub($cv);
497     }
498 }
499
500 # Return a "use" declaration for this BEGIN block, if appropriate
501 sub begin_is_use {
502     my ($self, $cv) = @_;
503     my $root = $cv->ROOT;
504     local @$self{qw'curcv curcvlex'} = ($cv);
505     local $B::overlay = {};
506     $self->pessimise($root, $cv->START);
507 #require B::Debug;
508 #B::walkoptree($cv->ROOT, "debug");
509     my $lineseq = $root->first;
510     return if $lineseq->name ne "lineseq";
511
512     my $req_op = $lineseq->first->sibling;
513     return if $req_op->name ne "require";
514
515     my $module;
516     if ($req_op->first->private & OPpCONST_BARE) {
517         # Actually it should always be a bareword
518         $module = $self->const_sv($req_op->first)->PV;
519         $module =~ s[/][::]g;
520         $module =~ s/.pm$//;
521     }
522     else {
523         $module = $self->const($self->const_sv($req_op->first), 6);
524     }
525
526     my $version;
527     my $version_op = $req_op->sibling;
528     return if class($version_op) eq "NULL";
529     if ($version_op->name eq "lineseq") {
530         # We have a version parameter; skip nextstate & pushmark
531         my $constop = $version_op->first->next->next;
532
533         return unless $self->const_sv($constop)->PV eq $module;
534         $constop = $constop->sibling;
535         $version = $self->const_sv($constop);
536         if (class($version) eq "IV") {
537             $version = $version->int_value;
538         } elsif (class($version) eq "NV") {
539             $version = $version->NV;
540         } elsif (class($version) ne "PVMG") {
541             # Includes PVIV and PVNV
542             $version = $version->PV;
543         } else {
544             # version specified as a v-string
545             $version = 'v'.join '.', map ord, split //, $version->PV;
546         }
547         $constop = $constop->sibling;
548         return if $constop->name ne "method_named";
549         return if $self->meth_sv($constop)->PV ne "VERSION";
550     }
551
552     $lineseq = $version_op->sibling;
553     return if $lineseq->name ne "lineseq";
554     my $entersub = $lineseq->first->sibling;
555     if ($entersub->name eq "stub") {
556         return "use $module $version ();\n" if defined $version;
557         return "use $module ();\n";
558     }
559     return if $entersub->name ne "entersub";
560
561     # See if there are import arguments
562     my $args = '';
563
564     my $svop = $entersub->first->sibling; # Skip over pushmark
565     return unless $self->const_sv($svop)->PV eq $module;
566
567     # Pull out the arguments
568     for ($svop=$svop->sibling; $svop->name ne "method_named";
569                 $svop = $svop->sibling) {
570         $args .= ", " if length($args);
571         $args .= $self->deparse($svop, 6);
572     }
573
574     my $use = 'use';
575     my $method_named = $svop;
576     return if $method_named->name ne "method_named";
577     my $method_name = $self->meth_sv($method_named)->PV;
578
579     if ($method_name eq "unimport") {
580         $use = 'no';
581     }
582
583     # Certain pragmas are dealt with using hint bits,
584     # so we ignore them here
585     if ($module eq 'strict' || $module eq 'integer'
586         || $module eq 'bytes' || $module eq 'warnings'
587         || $module eq 'feature') {
588         return "";
589     }
590
591     if (defined $version && length $args) {
592         return "$use $module $version ($args);\n";
593     } elsif (defined $version) {
594         return "$use $module $version;\n";
595     } elsif (length $args) {
596         return "$use $module ($args);\n";
597     } else {
598         return "$use $module;\n";
599     }
600 }
601
602 sub stash_subs {
603     my ($self, $pack, $seen) = @_;
604     my (@ret, $stash);
605     if (!defined $pack) {
606         $pack = '';
607         $stash = \%::;
608     }
609     else {
610         $pack =~ s/(::)?$/::/;
611         no strict 'refs';
612         $stash = \%{"main::$pack"};
613     }
614     return
615         if ($seen ||= {})->{
616             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
617            }++;
618     my %stash = svref_2object($stash)->ARRAY;
619     while (my ($key, $val) = each %stash) {
620         my $class = class($val);
621         if ($class eq "PV") {
622             # Just a prototype. As an ugly but fairly effective way
623             # to find out if it belongs here is to see if the AUTOLOAD
624             # (if any) for the stash was defined in one of our files.
625             my $A = $stash{"AUTOLOAD"};
626             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
627                 && class($A->CV) eq "CV") {
628                 my $AF = $A->FILE;
629                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
630             }
631             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
632         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
633             # Just a name. As above.
634             # But skip proxy constant subroutines, as some form of perl-space
635             # visible code must have created them, be it a use statement, or
636             # some direct symbol-table manipulation code that we will Deparse
637             my $A = $stash{"AUTOLOAD"};
638             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
639                 && class($A->CV) eq "CV") {
640                 my $AF = $A->FILE;
641                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
642             }
643             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
644         } elsif ($class eq "GV") {
645             if (class(my $cv = $val->CV) ne "SPECIAL") {
646                 next if $self->{'subs_done'}{$$val}++;
647                 next if $$val != ${$cv->GV};   # Ignore imposters
648                 $self->todo($cv, 0);
649             }
650             if (class(my $cv = $val->FORM) ne "SPECIAL") {
651                 next if $self->{'forms_done'}{$$val}++;
652                 next if $$val != ${$cv->GV};   # Ignore imposters
653                 $self->todo($cv, 1);
654             }
655             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
656                 $self->stash_subs($pack . $key, $seen);
657             }
658         }
659     }
660 }
661
662 sub print_protos {
663     my $self = shift;
664     my $ar;
665     my @ret;
666     foreach $ar (@{$self->{'protos_todo'}}) {
667         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
668         push @ret, "sub " . $ar->[0] .  "$proto;\n";
669     }
670     delete $self->{'protos_todo'};
671     return @ret;
672 }
673
674 sub style_opts {
675     my $self = shift;
676     my $opts = shift;
677     my $opt;
678     while (length($opt = substr($opts, 0, 1))) {
679         if ($opt eq "C") {
680             $self->{'cuddle'} = " ";
681             $opts = substr($opts, 1);
682         } elsif ($opt eq "i") {
683             $opts =~ s/^i(\d+)//;
684             $self->{'indent_size'} = $1;
685         } elsif ($opt eq "T") {
686             $self->{'use_tabs'} = 1;
687             $opts = substr($opts, 1);
688         } elsif ($opt eq "v") {
689             $opts =~ s/^v([^.]*)(.|$)//;
690             $self->{'ex_const'} = $1;
691         }
692     }
693 }
694
695 sub new {
696     my $class = shift;
697     my $self = bless {}, $class;
698     $self->{'cuddle'} = "\n";
699     $self->{'curcop'} = undef;
700     $self->{'curstash'} = "main";
701     $self->{'ex_const'} = "'???'";
702     $self->{'expand'} = 0;
703     $self->{'files'} = {};
704     $self->{'indent_size'} = 4;
705     $self->{'linenums'} = 0;
706     $self->{'parens'} = 0;
707     $self->{'subs_todo'} = [];
708     $self->{'unquote'} = 0;
709     $self->{'use_dumper'} = 0;
710     $self->{'use_tabs'} = 0;
711
712     $self->{'ambient_arybase'} = 0;
713     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
714     $self->{'ambient_hints'} = 0;
715     $self->{'ambient_hinthash'} = undef;
716     $self->init();
717
718     while (my $arg = shift @_) {
719         if ($arg eq "-d") {
720             $self->{'use_dumper'} = 1;
721             require Data::Dumper;
722         } elsif ($arg =~ /^-f(.*)/) {
723             $self->{'files'}{$1} = 1;
724         } elsif ($arg eq "-l") {
725             $self->{'linenums'} = 1;
726         } elsif ($arg eq "-p") {
727             $self->{'parens'} = 1;
728         } elsif ($arg eq "-P") {
729             $self->{'noproto'} = 1;
730         } elsif ($arg eq "-q") {
731             $self->{'unquote'} = 1;
732         } elsif (substr($arg, 0, 2) eq "-s") {
733             $self->style_opts(substr $arg, 2);
734         } elsif ($arg =~ /^-x(\d)$/) {
735             $self->{'expand'} = $1;
736         }
737     }
738     return $self;
739 }
740
741 {
742     # Mask out the bits that L<warnings::register> uses
743     my $WARN_MASK;
744     BEGIN {
745         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
746     }
747     sub WARN_MASK () {
748         return $WARN_MASK;
749     }
750 }
751
752 # Initialise the contextual information, either from
753 # defaults provided with the ambient_pragmas method,
754 # or from perl's own defaults otherwise.
755 sub init {
756     my $self = shift;
757
758     $self->{'arybase'}  = $self->{'ambient_arybase'};
759     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
760                                 ? $self->{'ambient_warnings'} & WARN_MASK
761                                 : undef;
762     $self->{'hints'}    = $self->{'ambient_hints'};
763     $self->{'hints'} &= 0xFF if $] < 5.009;
764     $self->{'hinthash'} = $self->{'ambient_hinthash'};
765
766     # also a convenient place to clear out subs_declared
767     delete $self->{'subs_declared'};
768 }
769
770 sub compile {
771     my(@args) = @_;
772     return sub {
773         my $self = B::Deparse->new(@args);
774         # First deparse command-line args
775         if (defined $^I) { # deparse -i
776             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
777         }
778         if ($^W) { # deparse -w
779             print qq(BEGIN { \$^W = $^W; }\n);
780         }
781         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
782             my $fs = perlstring($/) || 'undef';
783             my $bs = perlstring($O::savebackslash) || 'undef';
784             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
785         }
786         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
787         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
788             ? B::unitcheck_av->ARRAY
789             : ();
790         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
791         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
792         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
793         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
794             $self->todo($block, 0);
795         }
796         $self->stash_subs();
797         local($SIG{"__DIE__"}) =
798           sub {
799               if ($self->{'curcop'}) {
800                   my $cop = $self->{'curcop'};
801                   my($line, $file) = ($cop->line, $cop->file);
802                   print STDERR "While deparsing $file near line $line,\n";
803               }
804             };
805         $self->{'curcv'} = main_cv;
806         $self->{'curcvlex'} = undef;
807         print $self->print_protos;
808         @{$self->{'subs_todo'}} =
809           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
810         my $root = main_root;
811         local $B::overlay = {};
812         unless (null $root) {
813             $self->pessimise($root, main_start);
814             print $self->indent($self->deparse_root($root)), "\n";
815         }
816         my @text;
817         while (scalar(@{$self->{'subs_todo'}})) {
818             push @text, $self->next_todo;
819         }
820         print $self->indent(join("", @text)), "\n" if @text;
821
822         # Print __DATA__ section, if necessary
823         no strict 'refs';
824         my $laststash = defined $self->{'curcop'}
825             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
826         if (defined *{$laststash."::DATA"}{IO}) {
827             print $self->keyword("package") . " $laststash;\n"
828                 unless $laststash eq $self->{'curstash'};
829             print $self->keyword("__DATA__") . "\n";
830             print readline(*{$laststash."::DATA"});
831         }
832     }
833 }
834
835 sub coderef2text {
836     my $self = shift;
837     my $sub = shift;
838     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
839
840     $self->init();
841     return $self->indent($self->deparse_sub(svref_2object($sub)));
842 }
843
844 my %strict_bits = do {
845     local $^H;
846     map +($_ => strict::bits($_)), qw/refs subs vars/
847 };
848
849 sub ambient_pragmas {
850     my $self = shift;
851     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
852
853     while (@_ > 1) {
854         my $name = shift();
855         my $val  = shift();
856
857         if ($name eq 'strict') {
858             require strict;
859
860             if ($val eq 'none') {
861                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
862                 next();
863             }
864
865             my @names;
866             if ($val eq "all") {
867                 @names = qw/refs subs vars/;
868             }
869             elsif (ref $val) {
870                 @names = @$val;
871             }
872             else {
873                 @names = split' ', $val;
874             }
875             $hint_bits |= $strict_bits{$_} for @names;
876         }
877
878         elsif ($name eq '$[') {
879             if (OPpCONST_ARYBASE) {
880                 $arybase = $val;
881             } else {
882                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
883             }
884         }
885
886         elsif ($name eq 'integer'
887             || $name eq 'bytes'
888             || $name eq 'utf8') {
889             require "$name.pm";
890             if ($val) {
891                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
892             }
893             else {
894                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
895             }
896         }
897
898         elsif ($name eq 're') {
899             require re;
900             if ($val eq 'none') {
901                 $hint_bits &= ~re::bits(qw/taint eval/);
902                 next();
903             }
904
905             my @names;
906             if ($val eq 'all') {
907                 @names = qw/taint eval/;
908             }
909             elsif (ref $val) {
910                 @names = @$val;
911             }
912             else {
913                 @names = split' ',$val;
914             }
915             $hint_bits |= re::bits(@names);
916         }
917
918         elsif ($name eq 'warnings') {
919             if ($val eq 'none') {
920                 $warning_bits = $warnings::NONE;
921                 next();
922             }
923
924             my @names;
925             if (ref $val) {
926                 @names = @$val;
927             }
928             else {
929                 @names = split/\s+/, $val;
930             }
931
932             $warning_bits = $warnings::NONE if !defined ($warning_bits);
933             $warning_bits |= warnings::bits(@names);
934         }
935
936         elsif ($name eq 'warning_bits') {
937             $warning_bits = $val;
938         }
939
940         elsif ($name eq 'hint_bits') {
941             $hint_bits = $val;
942         }
943
944         elsif ($name eq '%^H') {
945             $hinthash = $val;
946         }
947
948         else {
949             croak "Unknown pragma type: $name";
950         }
951     }
952     if (@_) {
953         croak "The ambient_pragmas method expects an even number of args";
954     }
955
956     $self->{'ambient_arybase'} = $arybase;
957     $self->{'ambient_warnings'} = $warning_bits;
958     $self->{'ambient_hints'} = $hint_bits;
959     $self->{'ambient_hinthash'} = $hinthash;
960 }
961
962 # This method is the inner loop, so try to keep it simple
963 sub deparse {
964     my $self = shift;
965     my($op, $cx) = @_;
966
967     Carp::confess("Null op in deparse") if !defined($op)
968                                         || class($op) eq "NULL";
969     my $meth = "pp_" . $op->name;
970     return $self->$meth($op, $cx);
971 }
972
973 sub indent {
974     my $self = shift;
975     my $txt = shift;
976     my @lines = split(/\n/, $txt);
977     my $leader = "";
978     my $level = 0;
979     my $line;
980     for $line (@lines) {
981         my $cmd = substr($line, 0, 1);
982         if ($cmd eq "\t" or $cmd eq "\b") {
983             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
984             if ($self->{'use_tabs'}) {
985                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
986             } else {
987                 $leader = " " x $level;
988             }
989             $line = substr($line, 1);
990         }
991         if (index($line, "\f") > 0) {
992                 $line =~ s/\f/\n/;
993         }
994         if (substr($line, 0, 1) eq "\f") {
995             $line = substr($line, 1); # no indent
996         } else {
997             $line = $leader . $line;
998         }
999         $line =~ s/\cK;?//g;
1000     }
1001     return join("\n", @lines);
1002 }
1003
1004 sub deparse_sub {
1005     my $self = shift;
1006     my $cv = shift;
1007     my $proto = "";
1008 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
1009 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
1010     local $self->{'curcop'} = $self->{'curcop'};
1011     if ($cv->FLAGS & SVf_POK) {
1012         $proto = "(". $cv->PV . ") ";
1013     }
1014     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
1015         $proto .= ": ";
1016         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
1017         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
1018         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
1019     }
1020
1021     local($self->{'curcv'}) = $cv;
1022     local($self->{'curcvlex'});
1023     local(@$self{qw'curstash warnings hints hinthash'})
1024                 = @$self{qw'curstash warnings hints hinthash'};
1025     my $body;
1026     my $root = $cv->ROOT;
1027     local $B::overlay = {};
1028     if (not null $root) {
1029         $self->pessimise($root, $cv->START);
1030         my $lineseq = $root->first;
1031         if ($lineseq->name eq "lineseq") {
1032             my @ops;
1033             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
1034                 push @ops, $o;
1035             }
1036             $body = $self->lineseq(undef, 0, @ops).";";
1037             my $scope_en = $self->find_scope_en($lineseq);
1038             if (defined $scope_en) {
1039                 my $subs = join"", $self->seq_subs($scope_en);
1040                 $body .= ";\n$subs" if length($subs);
1041             }
1042         }
1043         else {
1044             $body = $self->deparse($root->first, 0);
1045         }
1046     }
1047     else {
1048         my $sv = $cv->const_sv;
1049         if ($$sv) {
1050             # uh-oh. inlinable sub... format it differently
1051             return $proto . "{ " . $self->const($sv, 0) . " }\n";
1052         } else { # XSUB? (or just a declaration)
1053             return "$proto;\n";
1054         }
1055     }
1056     return $proto ."{\n\t$body\n\b}" ."\n";
1057 }
1058
1059 sub deparse_format {
1060     my $self = shift;
1061     my $form = shift;
1062     my @text;
1063     local($self->{'curcv'}) = $form;
1064     local($self->{'curcvlex'});
1065     local($self->{'in_format'}) = 1;
1066     local(@$self{qw'curstash warnings hints hinthash'})
1067                 = @$self{qw'curstash warnings hints hinthash'};
1068     my $op = $form->ROOT;
1069     local $B::overlay = {};
1070     $self->pessimise($op, $form->START);
1071     my $kid;
1072     return "\f." if $op->first->name eq 'stub'
1073                 || $op->first->name eq 'nextstate';
1074     $op = $op->first->first; # skip leavewrite, lineseq
1075     while (not null $op) {
1076         $op = $op->sibling; # skip nextstate
1077         my @exprs;
1078         $kid = $op->first->sibling; # skip pushmark
1079         push @text, "\f".$self->const_sv($kid)->PV;
1080         $kid = $kid->sibling;
1081         for (; not null $kid; $kid = $kid->sibling) {
1082             push @exprs, $self->deparse($kid, -1);
1083             $exprs[-1] =~ s/;\z//;
1084         }
1085         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1086         $op = $op->sibling;
1087     }
1088     return join("", @text) . "\f.";
1089 }
1090
1091 sub is_scope {
1092     my $op = shift;
1093     return $op->name eq "leave" || $op->name eq "scope"
1094       || $op->name eq "lineseq"
1095         || ($op->name eq "null" && class($op) eq "UNOP"
1096             && (is_scope($op->first) || $op->first->name eq "enter"));
1097 }
1098
1099 sub is_state {
1100     my $name = $_[0]->name;
1101     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1102 }
1103
1104 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1105     my $op = shift;
1106     return (!null($op) and null($op->sibling)
1107             and $op->name eq "null" and class($op) eq "UNOP"
1108             and (($op->first->name =~ /^(and|or)$/
1109                   and $op->first->first->sibling->name eq "lineseq")
1110                  or ($op->first->name eq "lineseq"
1111                      and not null $op->first->first->sibling
1112                      and $op->first->first->sibling->name eq "unstack")
1113                  ));
1114 }
1115
1116 # Check if the op and its sibling are the initialization and the rest of a
1117 # for (..;..;..) { ... } loop
1118 sub is_for_loop {
1119     my $op = shift;
1120     # This OP might be almost anything, though it won't be a
1121     # nextstate. (It's the initialization, so in the canonical case it
1122     # will be an sassign.) The sibling is (old style) a lineseq whose
1123     # first child is a nextstate and whose second is a leaveloop, or
1124     # (new style) an unstack whose sibling is a leaveloop.
1125     my $lseq = $op->sibling;
1126     return 0 unless !is_state($op) and !null($lseq);
1127     if ($lseq->name eq "lineseq") {
1128         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1129             && (my $sib = $lseq->first->sibling)) {
1130             return (!null($sib) && $sib->name eq "leaveloop");
1131         }
1132     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1133         my $sib = $lseq->sibling;
1134         return $sib && !null($sib) && $sib->name eq "leaveloop";
1135     }
1136     return 0;
1137 }
1138
1139 sub is_scalar {
1140     my $op = shift;
1141     return ($op->name eq "rv2sv" or
1142             $op->name eq "padsv" or
1143             $op->name eq "gv" or # only in array/hash constructs
1144             $op->flags & OPf_KIDS && !null($op->first)
1145               && $op->first->name eq "gvsv");
1146 }
1147
1148 sub maybe_parens {
1149     my $self = shift;
1150     my($text, $cx, $prec) = @_;
1151     if ($prec < $cx              # unary ops nest just fine
1152         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1153         or $self->{'parens'})
1154     {
1155         $text = "($text)";
1156         # In a unop, let parent reuse our parens; see maybe_parens_unop
1157         $text = "\cS" . $text if $cx == 16;
1158         return $text;
1159     } else {
1160         return $text;
1161     }
1162 }
1163
1164 # same as above, but get around the 'if it looks like a function' rule
1165 sub maybe_parens_unop {
1166     my $self = shift;
1167     my($name, $kid, $cx) = @_;
1168     if ($cx > 16 or $self->{'parens'}) {
1169         $kid =  $self->deparse($kid, 1);
1170         if ($name eq "umask" && $kid =~ /^\d+$/) {
1171             $kid = sprintf("%#o", $kid);
1172         }
1173         return $self->keyword($name) . "($kid)";
1174     } else {
1175         $kid = $self->deparse($kid, 16);
1176         if ($name eq "umask" && $kid =~ /^\d+$/) {
1177             $kid = sprintf("%#o", $kid);
1178         }
1179         $name = $self->keyword($name);
1180         if (substr($kid, 0, 1) eq "\cS") {
1181             # use kid's parens
1182             return $name . substr($kid, 1);
1183         } elsif (substr($kid, 0, 1) eq "(") {
1184             # avoid looks-like-a-function trap with extra parens
1185             # ('+' can lead to ambiguities)
1186             return "$name(" . $kid  . ")";
1187         } else {
1188             return "$name $kid";
1189         }
1190     }
1191 }
1192
1193 sub maybe_parens_func {
1194     my $self = shift;
1195     my($func, $text, $cx, $prec) = @_;
1196     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1197         return "$func($text)";
1198     } else {
1199         return "$func $text";
1200     }
1201 }
1202
1203 sub find_our_type {
1204     my ($self, $name) = @_;
1205     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1206     my $seq = $self->{'curcop'}->cop_seq;
1207     for my $a (@{$self->{'curcvlex'}{"o$name"}}) {
1208         my ($st, undef, $padname) = @$a;
1209         if ($st == $seq && $padname->FLAGS & SVpad_TYPED) {
1210             return $padname->SvSTASH->NAME;
1211         }
1212     }
1213     return '';
1214 }
1215
1216 sub maybe_local {
1217     my $self = shift;
1218     my($op, $cx, $text) = @_;
1219     my $name = $op->name;
1220     my $our_intro = ($name =~ /^(?:(?:gv|rv2)[ash]v|split|refassign
1221                                   |lv(?:av)?ref)$/x)
1222                         ? OPpOUR_INTRO
1223                         : 0;
1224     my $lval_intro = $name eq 'split' ? 0 : OPpLVAL_INTRO;
1225     # The @a in \(@a) isn't in ref context, but only when the
1226     # parens are there.
1227     my $need_parens = $self->{'in_refgen'} && $name =~ /[ah]v\z/
1228                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1229     if ((my $priv = $op->private) & ($lval_intro|$our_intro)) {
1230         my @our_local;
1231         push @our_local, "local" if $priv & $lval_intro;
1232         push @our_local, "our"   if $priv & $our_intro;
1233         my $our_local = join " ", map $self->keyword($_), @our_local;
1234         if( $our_local[-1] eq 'our' ) {
1235             if ( $text !~ /^\W(\w+::)*\w+\z/
1236              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1237             ) {
1238                 die "Unexpected our($text)\n";
1239             }
1240             $text =~ s/(\w+::)+//;
1241
1242             if (my $type = $self->find_our_type($text)) {
1243                 $our_local .= ' ' . $type;
1244             }
1245         }
1246         return $need_parens ? "($text)" : $text
1247             if $self->{'avoid_local'}{$$op};
1248         if ($need_parens) {
1249             return "$our_local($text)";
1250         } elsif (want_scalar($op)) {
1251             return "$our_local $text";
1252         } else {
1253             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1254         }
1255     } else {
1256         return $need_parens ? "($text)" : $text;
1257     }
1258 }
1259
1260 sub maybe_targmy {
1261     my $self = shift;
1262     my($op, $cx, $func, @args) = @_;
1263     if ($op->private & OPpTARGET_MY) {
1264         my $var = $self->padname($op->targ);
1265         my $val = $func->($self, $op, 7, @args);
1266         return $self->maybe_parens("$var = $val", $cx, 7);
1267     } else {
1268         return $func->($self, $op, $cx, @args);
1269     }
1270 }
1271
1272 sub padname_sv {
1273     my $self = shift;
1274     my $targ = shift;
1275     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1276 }
1277
1278 sub maybe_my {
1279     my $self = shift;
1280     my($op, $cx, $text, $padname, $forbid_parens) = @_;
1281     # The @a in \(@a) isn't in ref context, but only when the
1282     # parens are there.
1283     my $need_parens = !$forbid_parens && $self->{'in_refgen'}
1284                    && $op->name =~ /[ah]v\z/
1285                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1286     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1287         # Check $padname->FLAGS for statehood, rather than $op->private,
1288         # because enteriter ops do not carry the flag.
1289         my $my =
1290             $self->keyword($padname->FLAGS & SVpad_STATE ? "state" : "my");
1291         if ($padname->FLAGS & SVpad_TYPED) {
1292             $my .= ' ' . $padname->SvSTASH->NAME;
1293         }
1294         if ($need_parens) {
1295             return "$my($text)";
1296         } elsif ($forbid_parens || want_scalar($op)) {
1297             return "$my $text";
1298         } else {
1299             return $self->maybe_parens_func($my, $text, $cx, 16);
1300         }
1301     } else {
1302         return $need_parens ? "($text)" : $text;
1303     }
1304 }
1305
1306 # The following OPs don't have functions:
1307
1308 # pp_padany -- does not exist after parsing
1309
1310 sub AUTOLOAD {
1311     if ($AUTOLOAD =~ s/^.*::pp_//) {
1312         warn "unexpected OP_".uc $AUTOLOAD;
1313         return "XXX";
1314     } else {
1315         die "Undefined subroutine $AUTOLOAD called";
1316     }
1317 }
1318
1319 sub DESTROY {}  #       Do not AUTOLOAD
1320
1321 # $root should be the op which represents the root of whatever
1322 # we're sequencing here. If it's undefined, then we don't append
1323 # any subroutine declarations to the deparsed ops, otherwise we
1324 # append appropriate declarations.
1325 sub lineseq {
1326     my($self, $root, $cx, @ops) = @_;
1327     my($expr, @exprs);
1328
1329     my $out_cop = $self->{'curcop'};
1330     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1331     my $limit_seq;
1332     if (defined $root) {
1333         $limit_seq = $out_seq;
1334         my $nseq;
1335         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1336         $limit_seq = $nseq if !defined($limit_seq)
1337                            or defined($nseq) && $nseq < $limit_seq;
1338     }
1339     $limit_seq = $self->{'limit_seq'}
1340         if defined($self->{'limit_seq'})
1341         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1342     local $self->{'limit_seq'} = $limit_seq;
1343
1344     $self->walk_lineseq($root, \@ops,
1345                        sub { push @exprs, $_[0]} );
1346
1347     my $sep = $cx ? '; ' : ";\n";
1348     my $body = join($sep, grep {length} @exprs);
1349     my $subs = "";
1350     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1351         $subs = join "\n", $self->seq_subs($limit_seq);
1352     }
1353     return join($sep, grep {length} $body, $subs);
1354 }
1355
1356 sub scopeop {
1357     my($real_block, $self, $op, $cx) = @_;
1358     my $kid;
1359     my @kids;
1360
1361     local(@$self{qw'curstash warnings hints hinthash'})
1362                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1363     if ($real_block) {
1364         $kid = $op->first->sibling; # skip enter
1365         if (is_miniwhile($kid)) {
1366             my $top = $kid->first;
1367             my $name = $top->name;
1368             if ($name eq "and") {
1369                 $name = $self->keyword("while");
1370             } elsif ($name eq "or") {
1371                 $name = $self->keyword("until");
1372             } else { # no conditional -> while 1 or until 0
1373                 return $self->deparse($top->first, 1) . " "
1374                      . $self->keyword("while") . " 1";
1375             }
1376             my $cond = $top->first;
1377             my $body = $cond->sibling->first; # skip lineseq
1378             $cond = $self->deparse($cond, 1);
1379             $body = $self->deparse($body, 1);
1380             return "$body $name $cond";
1381         }
1382     } else {
1383         $kid = $op->first;
1384     }
1385     for (; !null($kid); $kid = $kid->sibling) {
1386         push @kids, $kid;
1387     }
1388     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1389         my $body = $self->lineseq($op, 0, @kids);
1390         return is_lexical_subs(@kids)
1391                 ? $body
1392                 : ($self->lex_in_scope("&do") ? "CORE::do" : "do")
1393                  . " {\n\t$body\n\b}";
1394     } else {
1395         my $lineseq = $self->lineseq($op, $cx, @kids);
1396         return (length ($lineseq) ? "$lineseq;" : "");
1397     }
1398 }
1399
1400 sub pp_scope { scopeop(0, @_); }
1401 sub pp_lineseq { scopeop(0, @_); }
1402 sub pp_leave { scopeop(1, @_); }
1403
1404 # This is a special case of scopeop and lineseq, for the case of the
1405 # main_root. The difference is that we print the output statements as
1406 # soon as we get them, for the sake of impatient users.
1407 sub deparse_root {
1408     my $self = shift;
1409     my($op) = @_;
1410     local(@$self{qw'curstash warnings hints hinthash'})
1411       = @$self{qw'curstash warnings hints hinthash'};
1412     my @kids;
1413     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1414     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1415         push @kids, $kid;
1416     }
1417     $self->walk_lineseq($op, \@kids,
1418                         sub { print $self->indent($_[0].';');
1419                               print "\n" unless $_[1] == $#kids;
1420                           });
1421 }
1422
1423 sub walk_lineseq {
1424     my ($self, $op, $kids, $callback) = @_;
1425     my @kids = @$kids;
1426     for (my $i = 0; $i < @kids; $i++) {
1427         my $expr = "";
1428         if (is_state $kids[$i]) {
1429             $expr = $self->deparse($kids[$i++], 0);
1430             if ($i > $#kids) {
1431                 $callback->($expr, $i);
1432                 last;
1433             }
1434         }
1435         if (is_for_loop($kids[$i])) {
1436             $callback->($expr . $self->for_loop($kids[$i], 0),
1437                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1438             next;
1439         }
1440         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1441         $expr =~ s/;\n?\z//;
1442         $callback->($expr, $i);
1443     }
1444 }
1445
1446 # The BEGIN {} is used here because otherwise this code isn't executed
1447 # when you run B::Deparse on itself.
1448 my %globalnames;
1449 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1450             "ENV", "ARGV", "ARGVOUT", "_"); }
1451
1452 sub gv_name {
1453     my $self = shift;
1454     my $gv = shift;
1455     my $raw = shift;
1456 #Carp::confess() unless ref($gv) eq "B::GV";
1457     my $cv = $gv->FLAGS & SVf_ROK ? $gv->RV : 0;
1458     my $stash = ($cv || $gv)->STASH->NAME;
1459     my $name = $raw
1460         ? $cv ? $cv->NAME_HEK || $cv->GV->NAME : $gv->NAME
1461         : $cv
1462             ? B::safename($cv->NAME_HEK || $cv->GV->NAME)
1463             : $gv->SAFENAME;
1464     if ($stash eq 'main' && $name =~ /^::/) {
1465         $stash = '::';
1466     }
1467     elsif (($stash eq 'main'
1468             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1469         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1470             && ($stash eq 'main' || $name !~ /::/))
1471           )
1472     {
1473         $stash = "";
1474     } else {
1475         $stash = $stash . "::";
1476     }
1477     if (!$raw and $name =~ /^(\^..|{)/) {
1478         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1479     }
1480     return $stash . $name;
1481 }
1482
1483 # Return the name to use for a stash variable.
1484 # If a lexical with the same name is in scope, or
1485 # if strictures are enabled, it may need to be
1486 # fully-qualified.
1487 sub stash_variable {
1488     my ($self, $prefix, $name, $cx) = @_;
1489
1490     return "$prefix$name" if $name =~ /::/;
1491
1492     unless ($prefix eq '$' || $prefix eq '@' || #'
1493             $prefix eq '%' || $prefix eq '$#') {
1494         return "$prefix$name";
1495     }
1496
1497     if ($name =~ /^[^\w+-]$/) {
1498       if (defined $cx && $cx == 26) {
1499         if ($prefix eq '@') {
1500             return "$prefix\{$name}";
1501         }
1502         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1503       }
1504       if ($prefix eq '$#') {
1505         return "\$#{$name}";
1506       }
1507     }
1508
1509     return $prefix . $self->maybe_qualify($prefix, $name);
1510 }
1511
1512 # Return just the name, without the prefix.  It may be returned as a quoted
1513 # string.  The second return value is a boolean indicating that.
1514 sub stash_variable_name {
1515     my($self, $prefix, $gv) = @_;
1516     my $name = $self->gv_name($gv, 1);
1517     $name = $self->maybe_qualify($prefix,$name);
1518     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1519         $name =~ s/^([\ca-\cz])/'^'.($1|'@')/e;
1520         $name =~ /^(\^..|{)/ and $name = "{$name}";
1521         return $name, 0; # not quoted
1522     }
1523     else {
1524         single_delim("q", "'", $name, $self), 1;
1525     }
1526 }
1527
1528 sub maybe_qualify {
1529     my ($self,$prefix,$name) = @_;
1530     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1531     return $name if !$prefix || $name =~ /::/;
1532     return $self->{'curstash'}.'::'. $name
1533         if
1534             $name =~ /^(?!\d)\w/         # alphabetic
1535          && $v    !~ /^\$[ab]\z/         # not $a or $b
1536          && !$globalnames{$name}         # not a global name
1537          && $self->{hints} & $strict_bits{vars}  # strict vars
1538          && !$self->lex_in_scope($v,1)   # no "our"
1539       or $self->lex_in_scope($v);        # conflicts with "my" variable
1540     return $name;
1541 }
1542
1543 sub lex_in_scope {
1544     my ($self, $name, $our) = @_;
1545     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1546     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1547
1548     return 0 if !defined($self->{'curcop'});
1549     my $seq = $self->{'curcop'}->cop_seq;
1550     return 0 if !exists $self->{'curcvlex'}{$name};
1551     for my $a (@{$self->{'curcvlex'}{$name}}) {
1552         my ($st, $en) = @$a;
1553         return 1 if $seq > $st && $seq <= $en;
1554     }
1555     return 0;
1556 }
1557
1558 sub populate_curcvlex {
1559     my $self = shift;
1560     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1561         my $padlist = $cv->PADLIST;
1562         # an undef CV still in lexical chain
1563         next if class($padlist) eq "SPECIAL";
1564         my @padlist = $padlist->ARRAY;
1565         my @ns = $padlist[0]->ARRAY;
1566
1567         for (my $i=0; $i<@ns; ++$i) {
1568             next if class($ns[$i]) eq "SPECIAL";
1569             if (class($ns[$i]) eq "PV") {
1570                 # Probably that pesky lexical @_
1571                 next;
1572             }
1573             my $name = $ns[$i]->PVX;
1574             my ($seq_st, $seq_en) =
1575                 ($ns[$i]->FLAGS & SVf_FAKE)
1576                     ? (0, 999999)
1577                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1578
1579             push @{$self->{'curcvlex'}{
1580                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1581                   }}, [$seq_st, $seq_en, $ns[$i]];
1582         }
1583     }
1584 }
1585
1586 sub find_scope_st { ((find_scope(@_))[0]); }
1587 sub find_scope_en { ((find_scope(@_))[1]); }
1588
1589 # Recurses down the tree, looking for pad variable introductions and COPs
1590 sub find_scope {
1591     my ($self, $op, $scope_st, $scope_en) = @_;
1592     carp("Undefined op in find_scope") if !defined $op;
1593     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1594
1595     my @queue = ($op);
1596     while(my $op = shift @queue ) {
1597         for (my $o=$op->first; $$o; $o=$o->sibling) {
1598             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1599                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1600                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1601                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1602                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1603                 return ($scope_st, $scope_en);
1604             }
1605             elsif (is_state($o)) {
1606                 my $c = $o->cop_seq;
1607                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1608                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1609                 return ($scope_st, $scope_en);
1610             }
1611             elsif ($o->flags & OPf_KIDS) {
1612                 unshift (@queue, $o);
1613             }
1614         }
1615     }
1616
1617     return ($scope_st, $scope_en);
1618 }
1619
1620 # Returns a list of subs which should be inserted before the COP
1621 sub cop_subs {
1622     my ($self, $op, $out_seq) = @_;
1623     my $seq = $op->cop_seq;
1624     # If we have nephews, then our sequence number indicates
1625     # the cop_seq of the end of some sort of scope.
1626     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1627         and my $nseq = $self->find_scope_st($op->sibling) ) {
1628         $seq = $nseq;
1629     }
1630     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1631     return $self->seq_subs($seq);
1632 }
1633
1634 sub seq_subs {
1635     my ($self, $seq) = @_;
1636     my @text;
1637 #push @text, "# ($seq)\n";
1638
1639     return "" if !defined $seq;
1640     while (scalar(@{$self->{'subs_todo'}})
1641            and $seq > $self->{'subs_todo'}[0][0]) {
1642         push @text, $self->next_todo;
1643     }
1644     return @text;
1645 }
1646
1647 sub _features_from_bundle {
1648     my ($hints, $hh) = @_;
1649     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
1650         $hh->{$feature::feature{$_}} = 1;
1651     }
1652     return $hh;
1653 }
1654
1655 # Notice how subs and formats are inserted between statements here;
1656 # also $[ assignments and pragmas.
1657 sub pp_nextstate {
1658     my $self = shift;
1659     my($op, $cx) = @_;
1660     $self->{'curcop'} = $op;
1661     my @text;
1662     push @text, $self->cop_subs($op);
1663     my $stash = $op->stashpv;
1664     if ($stash ne $self->{'curstash'}) {
1665         push @text, $self->keyword("package") . " $stash;\n";
1666         $self->{'curstash'} = $stash;
1667     }
1668
1669     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1670         push @text, '$[ = '. $op->arybase .";\n";
1671         $self->{'arybase'} = $op->arybase;
1672     }
1673
1674     my $warnings = $op->warnings;
1675     my $warning_bits;
1676     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1677         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1678     }
1679     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1680         $warning_bits = $warnings::NONE;
1681     }
1682     elsif ($warnings->isa("B::SPECIAL")) {
1683         $warning_bits = undef;
1684     }
1685     else {
1686         $warning_bits = $warnings->PV & WARN_MASK;
1687     }
1688
1689     if (defined ($warning_bits) and
1690        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1691         push @text,
1692             $self->declare_warnings($self->{'warnings'}, $warning_bits);
1693         $self->{'warnings'} = $warning_bits;
1694     }
1695
1696     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1697     my $old_hints = $self->{'hints'};
1698     if ($self->{'hints'} != $hints) {
1699         push @text, $self->declare_hints($self->{'hints'}, $hints);
1700         $self->{'hints'} = $hints;
1701     }
1702
1703     my $newhh;
1704     if ($] > 5.009) {
1705         $newhh = $op->hints_hash->HASH;
1706     }
1707
1708     if ($] >= 5.015006) {
1709         # feature bundle hints
1710         my $from = $old_hints & $feature::hint_mask;
1711         my $to   = $    hints & $feature::hint_mask;
1712         if ($from != $to) {
1713             if ($to == $feature::hint_mask) {
1714                 if ($self->{'hinthash'}) {
1715                     delete $self->{'hinthash'}{$_}
1716                         for grep /^feature_/, keys %{$self->{'hinthash'}};
1717                 }
1718                 else { $self->{'hinthash'} = {} }
1719                 $self->{'hinthash'}
1720                     = _features_from_bundle($from, $self->{'hinthash'});
1721             }
1722             else {
1723                 my $bundle =
1724                     $feature::hint_bundles[$to >> $feature::hint_shift];
1725                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
1726                 push @text,
1727                     $self->keyword("no") . " feature;\n",
1728                     $self->keyword("use") . " feature ':$bundle';\n";
1729             }
1730         }
1731     }
1732
1733     if ($] > 5.009) {
1734         push @text, $self->declare_hinthash(
1735             $self->{'hinthash'}, $newhh,
1736             $self->{indent_size}, $self->{hints},
1737         );
1738         $self->{'hinthash'} = $newhh;
1739     }
1740
1741     # This should go after of any branches that add statements, to
1742     # increase the chances that it refers to the same line it did in
1743     # the original program.
1744     if ($self->{'linenums'}) {
1745         push @text, "\f#line " . $op->line .
1746           ' "' . $op->file, qq'"\n';
1747     }
1748
1749     push @text, $op->label . ": " if $op->label;
1750
1751     return join("", @text);
1752 }
1753
1754 sub declare_warnings {
1755     my ($self, $from, $to) = @_;
1756     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1757         return $self->keyword("use") . " warnings;\n";
1758     }
1759     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1760         return $self->keyword("no") . " warnings;\n";
1761     }
1762     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1763 }
1764
1765 sub declare_hints {
1766     my ($self, $from, $to) = @_;
1767     my $use = $to   & ~$from;
1768     my $no  = $from & ~$to;
1769     my $decls = "";
1770     for my $pragma (hint_pragmas($use)) {
1771         $decls .= $self->keyword("use") . " $pragma;\n";
1772     }
1773     for my $pragma (hint_pragmas($no)) {
1774         $decls .= $self->keyword("no") . " $pragma;\n";
1775     }
1776     return $decls;
1777 }
1778
1779 # Internal implementation hints that the core sets automatically, so don't need
1780 # (or want) to be passed back to the user
1781 my %ignored_hints = (
1782     'open<' => 1,
1783     'open>' => 1,
1784     ':'     => 1,
1785     'strict/refs' => 1,
1786     'strict/subs' => 1,
1787     'strict/vars' => 1,
1788 );
1789
1790 my %rev_feature;
1791
1792 sub declare_hinthash {
1793     my ($self, $from, $to, $indent, $hints) = @_;
1794     my $doing_features =
1795         ($hints & $feature::hint_mask) == $feature::hint_mask;
1796     my @decls;
1797     my @features;
1798     my @unfeatures; # bugs?
1799     for my $key (sort keys %$to) {
1800         next if $ignored_hints{$key};
1801         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1802         next if $is_feature and not $doing_features;
1803         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
1804             push(@features, $key), next if $is_feature;
1805             push @decls,
1806                 qq(\$^H{) . single_delim("q", "'", $key, $self) . qq(} = )
1807               . (
1808                    defined $to->{$key}
1809                         ? single_delim("q", "'", $to->{$key}, $self)
1810                         : 'undef'
1811                 )
1812               . qq(;);
1813         }
1814     }
1815     for my $key (sort keys %$from) {
1816         next if $ignored_hints{$key};
1817         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1818         next if $is_feature and not $doing_features;
1819         if (!exists $to->{$key}) {
1820             push(@unfeatures, $key), next if $is_feature;
1821             push @decls, qq(delete \$^H{'$key'};);
1822         }
1823     }
1824     my @ret;
1825     if (@features || @unfeatures) {
1826         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
1827     }
1828     if (@features) {
1829         push @ret, $self->keyword("use") . " feature "
1830                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
1831     }
1832     if (@unfeatures) {
1833         push @ret, $self->keyword("no") . " feature "
1834                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
1835                  . ";\n";
1836     }
1837     @decls and
1838         push @ret,
1839              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1840     return @ret;
1841 }
1842
1843 sub hint_pragmas {
1844     my ($bits) = @_;
1845     my (@pragmas, @strict);
1846     push @pragmas, "integer" if $bits & 0x1;
1847     for (sort keys %strict_bits) {
1848         push @strict, "'$_'" if $bits & $strict_bits{$_};
1849     }
1850     if (@strict == keys %strict_bits) {
1851         push @pragmas, "strict";
1852     }
1853     elsif (@strict) {
1854         push @pragmas, "strict " . join ', ', @strict;
1855     }
1856     push @pragmas, "bytes" if $bits & 0x8;
1857     return @pragmas;
1858 }
1859
1860 sub pp_dbstate { pp_nextstate(@_) }
1861 sub pp_setstate { pp_nextstate(@_) }
1862
1863 sub pp_unstack { return "" } # see also leaveloop
1864
1865 my %feature_keywords = (
1866   # keyword => 'feature',
1867     state   => 'state',
1868     say     => 'say',
1869     given   => 'switch',
1870     when    => 'switch',
1871     default => 'switch',
1872     break   => 'switch',
1873     evalbytes=>'evalbytes',
1874     __SUB__ => '__SUB__',
1875    fc       => 'fc',
1876 );
1877
1878 # keywords that are strong and also have a prototype
1879 #
1880 my %strong_proto_keywords = map { $_ => 1 } qw(
1881     pos
1882     prototype
1883     scalar
1884     study
1885     undef
1886 );
1887
1888 sub feature_enabled {
1889         my($self,$name) = @_;
1890         my $hh;
1891         my $hints = $self->{hints} & $feature::hint_mask;
1892         if ($hints && $hints != $feature::hint_mask) {
1893             $hh = _features_from_bundle($hints);
1894         }
1895         elsif ($hints) { $hh = $self->{'hinthash'} }
1896         return $hh && $hh->{"feature_$feature_keywords{$name}"}
1897 }
1898
1899 sub keyword {
1900     my $self = shift;
1901     my $name = shift;
1902     return $name if $name =~ /^CORE::/; # just in case
1903     if (exists $feature_keywords{$name}) {
1904         return "CORE::$name" if not $self->feature_enabled($name);
1905     }
1906     # This sub may be called for a program that has no nextstate ops.  In
1907     # that case we may have a lexical sub named no/use/sub in scope but
1908     # but $self->lex_in_scope will return false because it depends on the
1909     # current nextstate op.  So we need this alternate method if there is
1910     # no current cop.
1911     if (!$self->{'curcop'}) {
1912         $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1913         return "CORE::$name" if exists $self->{'curcvlex'}{"m&$name"}
1914                              || exists $self->{'curcvlex'}{"o&$name"};
1915     } elsif ($self->lex_in_scope("&$name")
1916           || $self->lex_in_scope("&$name", 1)) {
1917         return "CORE::$name";
1918     }
1919     if ($strong_proto_keywords{$name}
1920         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1921             && !defined eval{prototype "CORE::$name"})
1922     ) { return $name }
1923     if (
1924         exists $self->{subs_declared}{$name}
1925          or
1926         exists &{"$self->{curstash}::$name"}
1927     ) {
1928         return "CORE::$name"
1929     }
1930     return $name;
1931 }
1932
1933 sub baseop {
1934     my $self = shift;
1935     my($op, $cx, $name) = @_;
1936     return $self->keyword($name);
1937 }
1938
1939 sub pp_stub {
1940     my $self = shift;
1941     my($op, $cx, $name) = @_;
1942     if ($cx >= 1) {
1943         return "()";
1944     }
1945     else {
1946         return "();";
1947     }
1948 }
1949 sub pp_wantarray { baseop(@_, "wantarray") }
1950 sub pp_fork { baseop(@_, "fork") }
1951 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1952 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1953 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1954 sub pp_tms { baseop(@_, "times") }
1955 sub pp_ghostent { baseop(@_, "gethostent") }
1956 sub pp_gnetent { baseop(@_, "getnetent") }
1957 sub pp_gprotoent { baseop(@_, "getprotoent") }
1958 sub pp_gservent { baseop(@_, "getservent") }
1959 sub pp_ehostent { baseop(@_, "endhostent") }
1960 sub pp_enetent { baseop(@_, "endnetent") }
1961 sub pp_eprotoent { baseop(@_, "endprotoent") }
1962 sub pp_eservent { baseop(@_, "endservent") }
1963 sub pp_gpwent { baseop(@_, "getpwent") }
1964 sub pp_spwent { baseop(@_, "setpwent") }
1965 sub pp_epwent { baseop(@_, "endpwent") }
1966 sub pp_ggrent { baseop(@_, "getgrent") }
1967 sub pp_sgrent { baseop(@_, "setgrent") }
1968 sub pp_egrent { baseop(@_, "endgrent") }
1969 sub pp_getlogin { baseop(@_, "getlogin") }
1970
1971 sub POSTFIX () { 1 }
1972
1973 # I couldn't think of a good short name, but this is the category of
1974 # symbolic unary operators with interesting precedence
1975
1976 sub pfixop {
1977     my $self = shift;
1978     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1979     my $kid = $op->first;
1980     $kid = $self->deparse($kid, $prec);
1981     return $self->maybe_parens(($flags & POSTFIX)
1982                                  ? "$kid$name"
1983                                    # avoid confusion with filetests
1984                                  : $name eq '-'
1985                                    && $kid =~ /^[a-zA-Z](?!\w)/
1986                                         ? "$name($kid)"
1987                                         : "$name$kid",
1988                                $cx, $prec);
1989 }
1990
1991 sub pp_preinc { pfixop(@_, "++", 23) }
1992 sub pp_predec { pfixop(@_, "--", 23) }
1993 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1994 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1995 sub pp_i_preinc { pfixop(@_, "++", 23) }
1996 sub pp_i_predec { pfixop(@_, "--", 23) }
1997 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1998 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1999 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
2000
2001 sub pp_negate { maybe_targmy(@_, \&real_negate) }
2002 sub real_negate {
2003     my $self = shift;
2004     my($op, $cx) = @_;
2005     if ($op->first->name =~ /^(i_)?negate$/) {
2006         # avoid --$x
2007         $self->pfixop($op, $cx, "-", 21.5);
2008     } else {
2009         $self->pfixop($op, $cx, "-", 21);       
2010     }
2011 }
2012 sub pp_i_negate { pp_negate(@_) }
2013
2014 sub pp_not {
2015     my $self = shift;
2016     my($op, $cx) = @_;
2017     if ($cx <= 4) {
2018         $self->listop($op, $cx, "not", $op->first);
2019     } else {
2020         $self->pfixop($op, $cx, "!", 21);       
2021     }
2022 }
2023
2024 sub unop {
2025     my $self = shift;
2026     my($op, $cx, $name, $nollafr) = @_;
2027     my $kid;
2028     if ($op->flags & OPf_KIDS) {
2029         $kid = $op->first;
2030         if (not $name) {
2031             # this deals with 'boolkeys' right now
2032             return $self->deparse($kid,$cx);
2033         }
2034         my $builtinname = $name;
2035         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
2036         if (defined prototype($builtinname)
2037            && prototype($builtinname) =~ /^;?\*/
2038            && $kid->name eq "rv2gv") {
2039             $kid = $kid->first;
2040         }
2041
2042         if ($nollafr) {
2043             ($kid = $self->deparse($kid, 16)) =~ s/^\cS//;
2044             return $self->maybe_parens(
2045                         $self->keyword($name) . " $kid", $cx, 16
2046                    );
2047         }   
2048         return $self->maybe_parens_unop($name, $kid, $cx);
2049     } else {
2050         return $self->maybe_parens(
2051             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
2052             $cx, 16,
2053         );
2054     }
2055 }
2056
2057 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
2058 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
2059 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
2060 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
2061 sub pp_defined { unop(@_, "defined") }
2062 sub pp_undef { unop(@_, "undef") }
2063 sub pp_study { unop(@_, "study") }
2064 sub pp_ref { unop(@_, "ref") }
2065 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
2066
2067 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
2068 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
2069 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
2070 sub pp_srand { unop(@_, "srand") }
2071 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
2072 sub pp_log { maybe_targmy(@_, \&unop, "log") }
2073 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
2074 sub pp_int { maybe_targmy(@_, \&unop, "int") }
2075 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
2076 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
2077 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
2078
2079 sub pp_length { maybe_targmy(@_, \&unop, "length") }
2080 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
2081 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
2082
2083 sub pp_each { unop(@_, "each") }
2084 sub pp_values { unop(@_, "values") }
2085 sub pp_keys { unop(@_, "keys") }
2086 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2087 sub pp_boolkeys { 
2088     # no name because its an optimisation op that has no keyword
2089     unop(@_,"");
2090 }
2091 sub pp_aeach { unop(@_, "each") }
2092 sub pp_avalues { unop(@_, "values") }
2093 sub pp_akeys { unop(@_, "keys") }
2094 sub pp_pop { unop(@_, "pop") }
2095 sub pp_shift { unop(@_, "shift") }
2096
2097 sub pp_caller { unop(@_, "caller") }
2098 sub pp_reset { unop(@_, "reset") }
2099 sub pp_exit { unop(@_, "exit") }
2100 sub pp_prototype { unop(@_, "prototype") }
2101
2102 sub pp_close { unop(@_, "close") }
2103 sub pp_fileno { unop(@_, "fileno") }
2104 sub pp_umask { unop(@_, "umask") }
2105 sub pp_untie { unop(@_, "untie") }
2106 sub pp_tied { unop(@_, "tied") }
2107 sub pp_dbmclose { unop(@_, "dbmclose") }
2108 sub pp_getc { unop(@_, "getc") }
2109 sub pp_eof { unop(@_, "eof") }
2110 sub pp_tell { unop(@_, "tell") }
2111 sub pp_getsockname { unop(@_, "getsockname") }
2112 sub pp_getpeername { unop(@_, "getpeername") }
2113
2114 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
2115 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2116 sub pp_readlink { unop(@_, "readlink") }
2117 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2118 sub pp_readdir { unop(@_, "readdir") }
2119 sub pp_telldir { unop(@_, "telldir") }
2120 sub pp_rewinddir { unop(@_, "rewinddir") }
2121 sub pp_closedir { unop(@_, "closedir") }
2122 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2123 sub pp_localtime { unop(@_, "localtime") }
2124 sub pp_gmtime { unop(@_, "gmtime") }
2125 sub pp_alarm { unop(@_, "alarm") }
2126 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2127
2128 sub pp_dofile {
2129     my $code = unop(@_, "do", 1); # llafr does not apply
2130     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2131     $code;
2132 }
2133 sub pp_entereval {
2134     unop(
2135       @_,
2136       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
2137     )
2138 }
2139
2140 sub pp_ghbyname { unop(@_, "gethostbyname") }
2141 sub pp_gnbyname { unop(@_, "getnetbyname") }
2142 sub pp_gpbyname { unop(@_, "getprotobyname") }
2143 sub pp_shostent { unop(@_, "sethostent") }
2144 sub pp_snetent { unop(@_, "setnetent") }
2145 sub pp_sprotoent { unop(@_, "setprotoent") }
2146 sub pp_sservent { unop(@_, "setservent") }
2147 sub pp_gpwnam { unop(@_, "getpwnam") }
2148 sub pp_gpwuid { unop(@_, "getpwuid") }
2149 sub pp_ggrnam { unop(@_, "getgrnam") }
2150 sub pp_ggrgid { unop(@_, "getgrgid") }
2151
2152 sub pp_lock { unop(@_, "lock") }
2153
2154 sub pp_continue { unop(@_, "continue"); }
2155 sub pp_break { unop(@_, "break"); }
2156
2157 sub givwhen {
2158     my $self = shift;
2159     my($op, $cx, $givwhen) = @_;
2160
2161     my $enterop = $op->first;
2162     my ($head, $block);
2163     if ($enterop->flags & OPf_SPECIAL) {
2164         $head = $self->keyword("default");
2165         $block = $self->deparse($enterop->first, 0);
2166     }
2167     else {
2168         my $cond = $enterop->first;
2169         my $cond_str = $self->deparse($cond, 1);
2170         $head = "$givwhen ($cond_str)";
2171         $block = $self->deparse($cond->sibling, 0);
2172     }
2173
2174     return "$head {\n".
2175         "\t$block\n".
2176         "\b}\cK";
2177 }
2178
2179 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2180 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2181
2182 sub pp_exists {
2183     my $self = shift;
2184     my($op, $cx) = @_;
2185     my $arg;
2186     my $name = $self->keyword("exists");
2187     if ($op->private & OPpEXISTS_SUB) {
2188         # Checking for the existence of a subroutine
2189         return $self->maybe_parens_func($name,
2190                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2191     }
2192     if ($op->flags & OPf_SPECIAL) {
2193         # Array element, not hash element
2194         return $self->maybe_parens_func($name,
2195                                 $self->pp_aelem($op->first, 16), $cx, 16);
2196     }
2197     return $self->maybe_parens_func($name, $self->pp_helem($op->first, 16),
2198                                     $cx, 16);
2199 }
2200
2201 sub pp_delete {
2202     my $self = shift;
2203     my($op, $cx) = @_;
2204     my $arg;
2205     my $name = $self->keyword("delete");
2206     if ($op->private & OPpSLICE) {
2207         if ($op->flags & OPf_SPECIAL) {
2208             # Deleting from an array, not a hash
2209             return $self->maybe_parens_func($name,
2210                                         $self->pp_aslice($op->first, 16),
2211                                         $cx, 16);
2212         }
2213         return $self->maybe_parens_func($name,
2214                                         $self->pp_hslice($op->first, 16),
2215                                         $cx, 16);
2216     } else {
2217         if ($op->flags & OPf_SPECIAL) {
2218             # Deleting from an array, not a hash
2219             return $self->maybe_parens_func($name,
2220                                         $self->pp_aelem($op->first, 16),
2221                                         $cx, 16);
2222         }
2223         return $self->maybe_parens_func($name,
2224                                         $self->pp_helem($op->first, 16),
2225                                         $cx, 16);
2226     }
2227 }
2228
2229 sub pp_require {
2230     my $self = shift;
2231     my($op, $cx) = @_;
2232     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2233     if (class($op) eq "UNOP" and $op->first->name eq "const"
2234         and $op->first->private & OPpCONST_BARE)
2235     {
2236         my $name = $self->const_sv($op->first)->PV;
2237         $name =~ s[/][::]g;
2238         $name =~ s/\.pm//g;
2239         return $self->maybe_parens("$opname $name", $cx, 16);
2240     } else {    
2241         $self->unop(
2242             $op, $cx,
2243             $op->first->name eq 'const'
2244              && $op->first->private & OPpCONST_NOVER
2245                  ? "no"
2246                  : $opname,
2247             1, # llafr does not apply
2248         );
2249     }
2250 }
2251
2252 sub pp_scalar {
2253     my $self = shift;
2254     my($op, $cx) = @_;
2255     my $kid = $op->first;
2256     if (not null $kid->sibling) {
2257         # XXX Was a here-doc
2258         return $self->dquote($op);
2259     }
2260     $self->unop(@_, "scalar");
2261 }
2262
2263
2264 sub padval {
2265     my $self = shift;
2266     my $targ = shift;
2267     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2268 }
2269
2270 sub anon_hash_or_list {
2271     my $self = shift;
2272     my($op, $cx) = @_;
2273
2274     my($pre, $post) = @{{"anonlist" => ["[","]"],
2275                          "anonhash" => ["{","}"]}->{$op->name}};
2276     my($expr, @exprs);
2277     $op = $op->first->sibling; # skip pushmark
2278     for (; !null($op); $op = $op->sibling) {
2279         $expr = $self->deparse($op, 6);
2280         push @exprs, $expr;
2281     }
2282     if ($pre eq "{" and $cx < 1) {
2283         # Disambiguate that it's not a block
2284         $pre = "+{";
2285     }
2286     return $pre . join(", ", @exprs) . $post;
2287 }
2288
2289 sub pp_anonlist {
2290     my $self = shift;
2291     my ($op, $cx) = @_;
2292     if ($op->flags & OPf_SPECIAL) {
2293         return $self->anon_hash_or_list($op, $cx);
2294     }
2295     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2296     return 'XXX';
2297 }
2298
2299 *pp_anonhash = \&pp_anonlist;
2300
2301 sub pp_refgen {
2302     my $self = shift;   
2303     my($op, $cx) = @_;
2304     my $kid = $op->first;
2305     if ($kid->name eq "null") {
2306         $kid = $kid->first;
2307         if (!null($kid->sibling) and
2308                  $kid->sibling->name eq "anoncode") {
2309             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
2310         } elsif ($kid->name eq "pushmark") {
2311             my $sib_name = $kid->sibling->name;
2312             if ($sib_name eq 'entersub') {
2313                 my $text = $self->deparse($kid->sibling, 1);
2314                 # Always show parens for \(&func()), but only with -p otherwise
2315                 $text = "($text)" if $self->{'parens'}
2316                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2317                 return "\\$text";
2318             }
2319         }
2320     }
2321     local $self->{'in_refgen'} = 1;
2322     $self->pfixop($op, $cx, "\\", 20);
2323 }
2324
2325 sub e_anoncode {
2326     my ($self, $info) = @_;
2327     my $text = $self->deparse_sub($info->{code});
2328     return $self->keyword("sub") . " $text";
2329 }
2330
2331 sub pp_srefgen { pp_refgen(@_) }
2332
2333 sub pp_readline {
2334     my $self = shift;
2335     my($op, $cx) = @_;
2336     my $kid = $op->first;
2337     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
2338     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
2339     return $self->unop($op, $cx, "readline");
2340 }
2341
2342 sub pp_rcatline {
2343     my $self = shift;
2344     my($op) = @_;
2345     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2346 }
2347
2348 # Unary operators that can occur as pseudo-listops inside double quotes
2349 sub dq_unop {
2350     my $self = shift;
2351     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2352     my $kid;
2353     if ($op->flags & OPf_KIDS) {
2354        $kid = $op->first;
2355        # If there's more than one kid, the first is an ex-pushmark.
2356        $kid = $kid->sibling if not null $kid->sibling;
2357        return $self->maybe_parens_unop($name, $kid, $cx);
2358     } else {
2359        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2360     }
2361 }
2362
2363 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2364 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2365 sub pp_uc { dq_unop(@_, "uc") }
2366 sub pp_lc { dq_unop(@_, "lc") }
2367 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2368 sub pp_fc { dq_unop(@_, "fc") }
2369
2370 sub loopex {
2371     my $self = shift;
2372     my ($op, $cx, $name) = @_;
2373     if (class($op) eq "PVOP") {
2374         $name .= " " . $op->pv;
2375     } elsif (class($op) eq "OP") {
2376         # no-op
2377     } elsif (class($op) eq "UNOP") {
2378         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2379         $name .= " $kid";
2380     }
2381     return $self->maybe_parens($name, $cx, 7);
2382 }
2383
2384 sub pp_last { loopex(@_, "last") }
2385 sub pp_next { loopex(@_, "next") }
2386 sub pp_redo { loopex(@_, "redo") }
2387 sub pp_goto { loopex(@_, "goto") }
2388 sub pp_dump { loopex(@_, "CORE::dump") }
2389
2390 sub ftst {
2391     my $self = shift;
2392     my($op, $cx, $name) = @_;
2393     if (class($op) eq "UNOP") {
2394         # Genuine '-X' filetests are exempt from the LLAFR, but not
2395         # l?stat()
2396         if ($name =~ /^-/) {
2397             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2398             return $self->maybe_parens("$name $kid", $cx, 16);
2399         }
2400         return $self->maybe_parens_unop($name, $op->first, $cx);
2401     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2402         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2403     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2404         return $name;
2405     }
2406 }
2407
2408 sub pp_lstat    { ftst(@_, "lstat") }
2409 sub pp_stat     { ftst(@_, "stat") }
2410 sub pp_ftrread  { ftst(@_, "-R") }
2411 sub pp_ftrwrite { ftst(@_, "-W") }
2412 sub pp_ftrexec  { ftst(@_, "-X") }
2413 sub pp_fteread  { ftst(@_, "-r") }
2414 sub pp_ftewrite { ftst(@_, "-w") }
2415 sub pp_fteexec  { ftst(@_, "-x") }
2416 sub pp_ftis     { ftst(@_, "-e") }
2417 sub pp_fteowned { ftst(@_, "-O") }
2418 sub pp_ftrowned { ftst(@_, "-o") }
2419 sub pp_ftzero   { ftst(@_, "-z") }
2420 sub pp_ftsize   { ftst(@_, "-s") }
2421 sub pp_ftmtime  { ftst(@_, "-M") }
2422 sub pp_ftatime  { ftst(@_, "-A") }
2423 sub pp_ftctime  { ftst(@_, "-C") }
2424 sub pp_ftsock   { ftst(@_, "-S") }
2425 sub pp_ftchr    { ftst(@_, "-c") }
2426 sub pp_ftblk    { ftst(@_, "-b") }
2427 sub pp_ftfile   { ftst(@_, "-f") }
2428 sub pp_ftdir    { ftst(@_, "-d") }
2429 sub pp_ftpipe   { ftst(@_, "-p") }
2430 sub pp_ftlink   { ftst(@_, "-l") }
2431 sub pp_ftsuid   { ftst(@_, "-u") }
2432 sub pp_ftsgid   { ftst(@_, "-g") }
2433 sub pp_ftsvtx   { ftst(@_, "-k") }
2434 sub pp_fttty    { ftst(@_, "-t") }
2435 sub pp_fttext   { ftst(@_, "-T") }
2436 sub pp_ftbinary { ftst(@_, "-B") }
2437
2438 sub SWAP_CHILDREN () { 1 }
2439 sub ASSIGN () { 2 } # has OP= variant
2440 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2441
2442 my(%left, %right);
2443
2444 sub assoc_class {
2445     my $op = shift;
2446     my $name = $op->name;
2447     if ($name eq "concat" and $op->first->name eq "concat") {
2448         # avoid spurious '=' -- see comment in pp_concat
2449         return "concat";
2450     }
2451     if ($name eq "null" and class($op) eq "UNOP"
2452         and $op->first->name =~ /^(and|x?or)$/
2453         and null $op->first->sibling)
2454     {
2455         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2456         # with a null that's used as the common end point of the two
2457         # flows of control. For precedence purposes, ignore it.
2458         # (COND_EXPRs have these too, but we don't bother with
2459         # their associativity).
2460         return assoc_class($op->first);
2461     }
2462     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2463 }
2464
2465 # Left associative operators, like '+', for which
2466 # $a + $b + $c is equivalent to ($a + $b) + $c
2467
2468 BEGIN {
2469     %left = ('multiply' => 19, 'i_multiply' => 19,
2470              'divide' => 19, 'i_divide' => 19,
2471              'modulo' => 19, 'i_modulo' => 19,
2472              'repeat' => 19,
2473              'add' => 18, 'i_add' => 18,
2474              'subtract' => 18, 'i_subtract' => 18,
2475              'concat' => 18,
2476              'left_shift' => 17, 'right_shift' => 17,
2477              'bit_and' => 13,
2478              'bit_or' => 12, 'bit_xor' => 12,
2479              'and' => 3,
2480              'or' => 2, 'xor' => 2,
2481             );
2482 }
2483
2484 sub deparse_binop_left {
2485     my $self = shift;
2486     my($op, $left, $prec) = @_;
2487     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2488         and $left{assoc_class($op)} == $left{assoc_class($left)})
2489     {
2490         return $self->deparse($left, $prec - .00001);
2491     } else {
2492         return $self->deparse($left, $prec);    
2493     }
2494 }
2495
2496 # Right associative operators, like '=', for which
2497 # $a = $b = $c is equivalent to $a = ($b = $c)
2498
2499 BEGIN {
2500     %right = ('pow' => 22,
2501               'sassign=' => 7, 'aassign=' => 7,
2502               'multiply=' => 7, 'i_multiply=' => 7,
2503               'divide=' => 7, 'i_divide=' => 7,
2504               'modulo=' => 7, 'i_modulo=' => 7,
2505               'repeat=' => 7, 'refassign' => 7, 'refassign=' => 7,
2506               'add=' => 7, 'i_add=' => 7,
2507               'subtract=' => 7, 'i_subtract=' => 7,
2508               'concat=' => 7,
2509               'left_shift=' => 7, 'right_shift=' => 7,
2510               'bit_and=' => 7,
2511               'bit_or=' => 7, 'bit_xor=' => 7,
2512               'andassign' => 7,
2513               'orassign' => 7,
2514              );
2515 }
2516
2517 sub deparse_binop_right {
2518     my $self = shift;
2519     my($op, $right, $prec) = @_;
2520     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2521         and $right{assoc_class($op)} == $right{assoc_class($right)})
2522     {
2523         return $self->deparse($right, $prec - .00001);
2524     } else {
2525         return $self->deparse($right, $prec);   
2526     }
2527 }
2528
2529 sub binop {
2530     my $self = shift;
2531     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2532     my $left = $op->first;
2533     my $right = $op->last;
2534     my $eq = "";
2535     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2536         $eq = "=";
2537         $prec = 7;
2538     }
2539     if ($flags & SWAP_CHILDREN) {
2540         ($left, $right) = ($right, $left);
2541     }
2542     $left = $self->deparse_binop_left($op, $left, $prec);
2543     $left = "($left)" if $flags & LIST_CONTEXT
2544                 && $left !~ /^(my|our|local|)[\@\(]/;
2545     $right = $self->deparse_binop_right($op, $right, $prec);
2546     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2547 }
2548
2549 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2550 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2551 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2552 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2553 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2554 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2555 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2556 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2557 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2558 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2559 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2560
2561 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2562 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2563 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2564 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2565 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2566
2567 sub pp_eq { binop(@_, "==", 14) }
2568 sub pp_ne { binop(@_, "!=", 14) }
2569 sub pp_lt { binop(@_, "<", 15) }
2570 sub pp_gt { binop(@_, ">", 15) }
2571 sub pp_ge { binop(@_, ">=", 15) }
2572 sub pp_le { binop(@_, "<=", 15) }
2573 sub pp_ncmp { binop(@_, "<=>", 14) }
2574 sub pp_i_eq { binop(@_, "==", 14) }
2575 sub pp_i_ne { binop(@_, "!=", 14) }
2576 sub pp_i_lt { binop(@_, "<", 15) }
2577 sub pp_i_gt { binop(@_, ">", 15) }
2578 sub pp_i_ge { binop(@_, ">=", 15) }
2579 sub pp_i_le { binop(@_, "<=", 15) }
2580 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2581
2582 sub pp_seq { binop(@_, "eq", 14) }
2583 sub pp_sne { binop(@_, "ne", 14) }
2584 sub pp_slt { binop(@_, "lt", 15) }
2585 sub pp_sgt { binop(@_, "gt", 15) }
2586 sub pp_sge { binop(@_, "ge", 15) }
2587 sub pp_sle { binop(@_, "le", 15) }
2588 sub pp_scmp { binop(@_, "cmp", 14) }
2589
2590 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2591 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2592
2593 sub pp_smartmatch {
2594     my ($self, $op, $cx) = @_;
2595     if ($op->flags & OPf_SPECIAL) {
2596         return $self->deparse($op->last, $cx);
2597     }
2598     else {
2599         binop(@_, "~~", 14);
2600     }
2601 }
2602
2603 # '.' is special because concats-of-concats are optimized to save copying
2604 # by making all but the first concat stacked. The effect is as if the
2605 # programmer had written '($a . $b) .= $c', except legal.
2606 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2607 sub real_concat {
2608     my $self = shift;
2609     my($op, $cx) = @_;
2610     my $left = $op->first;
2611     my $right = $op->last;
2612     my $eq = "";
2613     my $prec = 18;
2614     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2615         $eq = "=";
2616         $prec = 7;
2617     }
2618     $left = $self->deparse_binop_left($op, $left, $prec);
2619     $right = $self->deparse_binop_right($op, $right, $prec);
2620     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2621 }
2622
2623 # 'x' is weird when the left arg is a list
2624 sub pp_repeat {
2625     my $self = shift;
2626     my($op, $cx) = @_;
2627     my $left = $op->first;
2628     my $right = $op->last;
2629     my $eq = "";
2630     my $prec = 19;
2631     if ($op->flags & OPf_STACKED) {
2632         $eq = "=";
2633         $prec = 7;
2634     }
2635     if (null($right)) { # list repeat; count is inside left-side ex-list
2636         my $kid = $left->first->sibling; # skip pushmark
2637         my @exprs;
2638         for (; !null($kid->sibling); $kid = $kid->sibling) {
2639             push @exprs, $self->deparse($kid, 6);
2640         }
2641         $right = $kid;
2642         $left = "(" . join(", ", @exprs). ")";
2643     } else {
2644         $left = $self->deparse_binop_left($op, $left, $prec);
2645     }
2646     $right = $self->deparse_binop_right($op, $right, $prec);
2647     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2648 }
2649
2650 sub range {
2651     my $self = shift;
2652     my ($op, $cx, $type) = @_;
2653     my $left = $op->first;
2654     my $right = $left->sibling;
2655     $left = $self->deparse($left, 9);
2656     $right = $self->deparse($right, 9);
2657     return $self->maybe_parens("$left $type $right", $cx, 9);
2658 }
2659
2660 sub pp_flop {
2661     my $self = shift;
2662     my($op, $cx) = @_;
2663     my $flip = $op->first;
2664     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2665     return $self->range($flip->first, $cx, $type);
2666 }
2667
2668 # one-line while/until is handled in pp_leave
2669
2670 sub logop {
2671     my $self = shift;
2672     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2673     my $left = $op->first;
2674     my $right = $op->first->sibling;
2675     $blockname &&= $self->keyword($blockname);
2676     if ($cx < 1 and is_scope($right) and $blockname
2677         and $self->{'expand'} < 7)
2678     { # if ($a) {$b}
2679         $left = $self->deparse($left, 1);
2680         $right = $self->deparse($right, 0);
2681         return "$blockname ($left) {\n\t$right\n\b}\cK";
2682     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2683              and $self->{'expand'} < 7) { # $b if $a
2684         $right = $self->deparse($right, 1);
2685         $left = $self->deparse($left, 1);
2686         return "$right $blockname $left";
2687     } elsif ($cx > $lowprec and $highop) { # $a && $b
2688         $left = $self->deparse_binop_left($op, $left, $highprec);
2689         $right = $self->deparse_binop_right($op, $right, $highprec);
2690         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2691     } else { # $a and $b
2692         $left = $self->deparse_binop_left($op, $left, $lowprec);
2693         $right = $self->deparse_binop_right($op, $right, $lowprec);
2694         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2695     }
2696 }
2697
2698 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2699 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2700 sub pp_dor { logop(@_, "//", 10) }
2701
2702 # xor is syntactically a logop, but it's really a binop (contrary to
2703 # old versions of opcode.pl). Syntax is what matters here.
2704 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2705
2706 sub logassignop {
2707     my $self = shift;
2708     my ($op, $cx, $opname) = @_;
2709     my $left = $op->first;
2710     my $right = $op->first->sibling->first; # skip sassign
2711     $left = $self->deparse($left, 7);
2712     $right = $self->deparse($right, 7);
2713     return $self->maybe_parens("$left $opname $right", $cx, 7);
2714 }
2715
2716 sub pp_andassign { logassignop(@_, "&&=") }
2717 sub pp_orassign  { logassignop(@_, "||=") }
2718 sub pp_dorassign { logassignop(@_, "//=") }
2719
2720 sub rv2gv_or_string {
2721     my($self,$op) = @_;
2722     if ($op->name eq "gv") { # could be open("open") or open("###")
2723         my($name,$quoted) =
2724             $self->stash_variable_name("", $self->gv_or_padgv($op));
2725         $quoted ? $name : "*$name";
2726     }
2727     else {
2728         $self->deparse($op, 6);
2729     }
2730 }
2731
2732 sub listop {
2733     my $self = shift;
2734     my($op, $cx, $name, $kid, $nollafr) = @_;
2735     my(@exprs);
2736     my $parens = ($cx >= 5) || $self->{'parens'};
2737     $kid ||= $op->first->sibling;
2738     # If there are no arguments, add final parentheses (or parenthesize the
2739     # whole thing if the llafr does not apply) to account for cases like
2740     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
2741     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
2742     if (null $kid) {
2743         return $nollafr
2744                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
2745                 : $self->keyword($name) . '()' x (7 < $cx);
2746     }
2747     my $first;
2748     my $fullname = $self->keyword($name);
2749     my $proto = prototype("CORE::$name");
2750     if (
2751          (     (defined $proto && $proto =~ /^;?\*/)
2752             || $name eq 'select' # select(F) doesn't have a proto
2753          )
2754          && $kid->name eq "rv2gv"
2755          && !($kid->private & OPpLVAL_INTRO)
2756     ) {
2757         $first = $self->rv2gv_or_string($kid->first);
2758     }
2759     else {
2760         $first = $self->deparse($kid, 6);
2761     }
2762     if ($name eq "chmod" && $first =~ /^\d+$/) {
2763         $first = sprintf("%#o", $first);
2764     }
2765     $first = "+$first"
2766         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
2767     push @exprs, $first;
2768     $kid = $kid->sibling;
2769     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
2770          && !($kid->private & OPpLVAL_INTRO)) {
2771         push @exprs, $first = $self->rv2gv_or_string($kid->first);
2772         $kid = $kid->sibling;
2773     }
2774     for (; !null($kid); $kid = $kid->sibling) {
2775         push @exprs, $self->deparse($kid, 6);
2776     }
2777     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2778         return "$exprs[0] = $fullname"
2779                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2780     }
2781     if ($name =~ /^(system|exec)$/
2782         && ($op->flags & OPf_STACKED)
2783         && @exprs > 1)
2784     {
2785         # handle the "system prog a1,a2,.." form
2786         my $prog = shift @exprs;
2787         $exprs[0] = "$prog $exprs[0]";
2788     }
2789
2790     if ($parens && $nollafr) {
2791         return "($fullname " . join(", ", @exprs) . ")";
2792     } elsif ($parens) {
2793         return "$fullname(" . join(", ", @exprs) . ")";
2794     } else {
2795         return "$fullname " . join(", ", @exprs);
2796     }
2797 }
2798
2799 sub pp_bless { listop(@_, "bless") }
2800 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2801 sub pp_substr {
2802     my ($self,$op,$cx) = @_;
2803     if ($op->private & OPpSUBSTR_REPL_FIRST) {
2804         return
2805            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
2806          . " = "
2807          . $self->deparse($op->first->sibling, 7);
2808     }
2809     maybe_local(@_, listop(@_, "substr"))
2810 }
2811 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2812 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2813 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2814 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2815 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2816 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2817 sub pp_unpack { listop(@_, "unpack") }
2818 sub pp_pack { listop(@_, "pack") }
2819 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2820 sub pp_splice { listop(@_, "splice") }
2821 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2822 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2823 sub pp_reverse { listop(@_, "reverse") }
2824 sub pp_warn { listop(@_, "warn") }
2825 sub pp_die { listop(@_, "die") }
2826 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
2827 sub pp_open { listop(@_, "open") }
2828 sub pp_pipe_op { listop(@_, "pipe") }
2829 sub pp_tie { listop(@_, "tie") }
2830 sub pp_binmode { listop(@_, "binmode") }
2831 sub pp_dbmopen { listop(@_, "dbmopen") }
2832 sub pp_sselect { listop(@_, "select") }
2833 sub pp_select { listop(@_, "select") }
2834 sub pp_read { listop(@_, "read") }
2835 sub pp_sysopen { listop(@_, "sysopen") }
2836 sub pp_sysseek { listop(@_, "sysseek") }
2837 sub pp_sysread { listop(@_, "sysread") }
2838 sub pp_syswrite { listop(@_, "syswrite") }
2839 sub pp_send { listop(@_, "send") }
2840 sub pp_recv { listop(@_, "recv") }
2841 sub pp_seek { listop(@_, "seek") }
2842 sub pp_fcntl { listop(@_, "fcntl") }
2843 sub pp_ioctl { listop(@_, "ioctl") }
2844 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2845 sub pp_socket { listop(@_, "socket") }
2846 sub pp_sockpair { listop(@_, "socketpair") }
2847 sub pp_bind { listop(@_, "bind") }
2848 sub pp_connect { listop(@_, "connect") }
2849 sub pp_listen { listop(@_, "listen") }
2850 sub pp_accept { listop(@_, "accept") }
2851 sub pp_shutdown { listop(@_, "shutdown") }
2852 sub pp_gsockopt { listop(@_, "getsockopt") }
2853 sub pp_ssockopt { listop(@_, "setsockopt") }
2854 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2855 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2856 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2857 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2858 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2859 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2860 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2861 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2862 sub pp_open_dir { listop(@_, "opendir") }
2863 sub pp_seekdir { listop(@_, "seekdir") }
2864 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2865 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2866 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2867 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2868 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2869 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2870 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2871 sub pp_shmget { listop(@_, "shmget") }
2872 sub pp_shmctl { listop(@_, "shmctl") }
2873 sub pp_shmread { listop(@_, "shmread") }
2874 sub pp_shmwrite { listop(@_, "shmwrite") }
2875 sub pp_msgget { listop(@_, "msgget") }
2876 sub pp_msgctl { listop(@_, "msgctl") }
2877 sub pp_msgsnd { listop(@_, "msgsnd") }
2878 sub pp_msgrcv { listop(@_, "msgrcv") }
2879 sub pp_semget { listop(@_, "semget") }
2880 sub pp_semctl { listop(@_, "semctl") }
2881 sub pp_semop { listop(@_, "semop") }
2882 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2883 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2884 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2885 sub pp_gsbyname { listop(@_, "getservbyname") }
2886 sub pp_gsbyport { listop(@_, "getservbyport") }
2887 sub pp_syscall { listop(@_, "syscall") }
2888
2889 sub pp_glob {
2890     my $self = shift;
2891     my($op, $cx) = @_;
2892     my $kid = $op->first->sibling;  # skip pushmark
2893     my $keyword =
2894         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2895     my $text;
2896     if ($keyword =~ /^CORE::/
2897         or $kid->name ne 'const'
2898         or ($text = $self->dq($kid))
2899              =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2900         or $text =~ /[<>]/) {
2901         $text = $self->deparse($kid);
2902         return $cx >= 5 || $self->{'parens'}
2903             ? "$keyword($text)"
2904             : "$keyword $text";
2905     } else {
2906         return '<' . $text . '>';
2907     }
2908 }
2909
2910 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2911 # be a filehandle. This could probably be better fixed in the core
2912 # by moving the GV lookup into ck_truc.
2913
2914 sub pp_truncate {
2915     my $self = shift;
2916     my($op, $cx) = @_;
2917     my(@exprs);
2918     my $parens = ($cx >= 5) || $self->{'parens'};
2919     my $kid = $op->first->sibling;
2920     my $fh;
2921     if ($op->flags & OPf_SPECIAL) {
2922         # $kid is an OP_CONST
2923         $fh = $self->const_sv($kid)->PV;
2924     } else {
2925         $fh = $self->deparse($kid, 6);
2926         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2927     }
2928     my $len = $self->deparse($kid->sibling, 6);
2929     my $name = $self->keyword('truncate');
2930     if ($parens) {
2931         return "$name($fh, $len)";
2932     } else {
2933         return "$name $fh, $len";
2934     }
2935 }
2936
2937 sub indirop {
2938     my $self = shift;
2939     my($op, $cx, $name) = @_;
2940     my($expr, @exprs);
2941     my $firstkid = my $kid = $op->first->sibling;
2942     my $indir = "";
2943     if ($op->flags & OPf_STACKED) {
2944         $indir = $kid;
2945         $indir = $indir->first; # skip rv2gv
2946         if (is_scope($indir)) {
2947             $indir = "{" . $self->deparse($indir, 0) . "}";
2948             $indir = "{;}" if $indir eq "{}";
2949         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2950             $indir = $self->const_sv($indir)->PV;
2951         } else {
2952             $indir = $self->deparse($indir, 24);
2953         }
2954         $indir = $indir . " ";
2955         $kid = $kid->sibling;
2956     }
2957     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2958         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2959                                                   : '{$a <=> $b} ';
2960     }
2961     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2962         $indir = '{$b cmp $a} ';
2963     }
2964     for (; !null($kid); $kid = $kid->sibling) {
2965         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2966         push @exprs, $expr;
2967     }
2968     my $name2;
2969     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2970         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2971     }
2972     else { $name2 = $self->keyword($name) }
2973     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2974         return "$exprs[0] = $name2 $indir $exprs[0]";
2975     }
2976
2977     my $args = $indir . join(", ", @exprs);
2978     if ($indir ne "" && $name eq "sort") {
2979         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2980         # give bareword warnings in that case. Therefore if context
2981         # requires, we'll put parens around the outside "(sort f 1, 2,
2982         # 3)". Unfortunately, we'll currently think the parens are
2983         # necessary more often that they really are, because we don't
2984         # distinguish which side of an assignment we're on.
2985         if ($cx >= 5) {
2986             return "($name2 $args)";
2987         } else {
2988             return "$name2 $args";
2989         }
2990     } elsif (
2991         !$indir && $name eq "sort"
2992       && !null($op->first->sibling)
2993       && $op->first->sibling->name eq 'entersub'
2994     ) {
2995         # We cannot say sort foo(bar), as foo will be interpreted as a
2996         # comparison routine.  We have to say sort(...) in that case.
2997         return "$name2($args)";
2998     } else {
2999         return $self->maybe_parens_func($name2, $args, $cx, 5);
3000     }
3001
3002 }
3003
3004 sub pp_prtf { indirop(@_, "printf") }
3005 sub pp_print { indirop(@_, "print") }
3006 sub pp_say  { indirop(@_, "say") }
3007 sub pp_sort { indirop(@_, "sort") }
3008
3009 sub mapop {
3010     my $self = shift;
3011     my($op, $cx, $name) = @_;
3012     my($expr, @exprs);
3013     my $kid = $op->first; # this is the (map|grep)start
3014     $kid = $kid->first->sibling; # skip a pushmark
3015     my $code = $kid->first; # skip a null
3016     if (is_scope $code) {
3017         $code = "{" . $self->deparse($code, 0) . "} ";
3018     } else {
3019         $code = $self->deparse($code, 24);
3020         $code .= ", " if !null($kid->sibling);
3021     }
3022     $kid = $kid->sibling;
3023     for (; !null($kid); $kid = $kid->sibling) {
3024         $expr = $self->deparse($kid, 6);
3025         push @exprs, $expr if defined $expr;
3026     }
3027     return $self->maybe_parens_func($self->keyword($name),
3028                                     $code . join(", ", @exprs), $cx, 5);
3029 }
3030
3031 sub pp_mapwhile { mapop(@_, "map") }
3032 sub pp_grepwhile { mapop(@_, "grep") }
3033 sub pp_mapstart { baseop(@_, "map") }
3034 sub pp_grepstart { baseop(@_, "grep") }
3035
3036 sub pp_list {
3037     my $self = shift;
3038     my($op, $cx) = @_;
3039     my($expr, @exprs);
3040     my $kid = $op->first->sibling; # skip pushmark
3041     return '' if class($kid) eq 'NULL';
3042     my $lop;
3043     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
3044     my $type;
3045     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3046         # This assumes that no other private flags equal 128, and that
3047         # OPs that store things other than flags in their op_private,
3048         # like OP_AELEMFAST, won't be immediate children of a list.
3049         #
3050         # OP_ENTERSUB and OP_SPLIT can break this logic, so check for them.
3051         # I suspect that open and exit can too.
3052         # XXX This really needs to be rewritten to accept only those ops
3053         #     known to take the OPpLVAL_INTRO flag.
3054
3055         my $lopname = $lop->name;
3056         my $loppriv = $lop->private;
3057         if (!($loppriv & (OPpLVAL_INTRO|OPpOUR_INTRO)
3058                 or $lopname eq "undef")
3059             or $lopname =~ /^(?:entersub|exit|open|split
3060                                |lv(?:av)?ref(?:slice)?)\z/x)
3061         {
3062             $local = ""; # or not
3063             last;
3064         }
3065         my $newtype;
3066         if ($lopname =~ /^pad[ash]v$/) {
3067             if ($loppriv & OPpPAD_STATE) { # state()
3068                 ($local = "", last) if $local !~ /^(?:either|state)$/;
3069                 $local = "state";
3070             } else { # my()
3071                 ($local = "", last) if $local !~ /^(?:either|my)$/;
3072                 $local = "my";
3073             }
3074             my $padname = $self->padname_sv($lop->targ);
3075             if ($padname->FLAGS & SVpad_TYPED) {
3076                 $newtype = $padname->SvSTASH->NAME;
3077             }
3078         } elsif ($lopname =~ /^(?:gv|rv2)([ash])v$/
3079                         && $loppriv & OPpOUR_INTRO
3080                 or $lopname eq "null" && $lop->first->name eq "gvsv"
3081                         && $lop->first->private & OPpOUR_INTRO) { # our()
3082             my $newlocal = "local " x !!($loppriv & OPpLVAL_INTRO) . "our";
3083             ($local = "", last)
3084                 if $local ne 'either' && $local ne $newlocal;
3085             $local = $newlocal;
3086             my $funny = !$1 || $1 eq 's' ? '$' : $1 eq 'a' ? '@' : '%';
3087             if (my $t = $self->find_our_type(
3088                     $funny . $self->gv_or_padgv($lop->first)->NAME
3089                )) {
3090                 $newtype = $t;
3091             }
3092         } elsif ($lopname ne "undef"
3093                 # specifically avoid the "reverse sort" optimisation,
3094                 # where "reverse" is nullified
3095                 && !($lopname eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
3096         {
3097             # local()
3098             ($local = "", last) if $local !~ /^(?:either|local)$/;
3099             $local = "local";
3100         }
3101         if (defined $type && defined $newtype && $newtype ne $type) {
3102             $local = '';
3103             last;
3104         }
3105         $type = $newtype;
3106     }
3107     $local = "" if $local eq "either"; # no point if it's all undefs
3108     $local &&= join ' ', map $self->keyword($_), split / /, $local;
3109     $local .= " $type " if $local && length $type;
3110     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
3111     for (; !null($kid); $kid = $kid->sibling) {
3112         if ($local) {
3113             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3114                 $lop = $kid->first;
3115             } else {
3116                 $lop = $kid;
3117             }
3118             $self->{'avoid_local'}{$$lop}++;
3119             $expr = $self->deparse($kid, 6);
3120             delete $self->{'avoid_local'}{$$lop};
3121         } else {
3122             $expr = $self->deparse($kid, 6);
3123         }
3124         push @exprs, $expr;
3125     }
3126     if ($local) {
3127         return "$local(" . join(", ", @exprs) . ")";
3128     } else {
3129         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3130     }
3131 }
3132
3133 sub is_ifelse_cont {
3134     my $op = shift;
3135     return ($op->name eq "null" and class($op) eq "UNOP"
3136             and $op->first->name =~ /^(and|cond_expr)$/
3137             and is_scope($op->first->first->sibling));
3138 }
3139
3140 sub pp_cond_expr {
3141     my $self = shift;
3142     my($op, $cx) = @_;
3143     my $cond = $op->first;
3144     my $true = $cond->sibling;
3145     my $false = $true->sibling;
3146     my $cuddle = $self->{'cuddle'};
3147     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3148             (is_scope($false) || is_ifelse_cont($false))
3149             and $self->{'expand'} < 7) {
3150         $cond = $self->deparse($cond, 8);
3151         $true = $self->deparse($true, 6);
3152         $false = $self->deparse($false, 8);
3153         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3154     }
3155
3156     $cond = $self->deparse($cond, 1);
3157     $true = $self->deparse($true, 0);
3158     my $head = $self->keyword("if") . " ($cond) {\n\t$true\n\b}";
3159     my @elsifs;
3160     my $elsif;
3161     while (!null($false) and is_ifelse_cont($false)) {
3162         my $newop = $false->first;
3163         my $newcond = $newop->first;
3164         my $newtrue = $newcond->sibling;
3165         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3166         if ($newcond->name eq "lineseq")
3167         {
3168             # lineseq to ensure correct line numbers in elsif()
3169             # Bug #37302 fixed by change #33710.
3170             $newcond = $newcond->first->sibling;
3171         }
3172         $newcond = $self->deparse($newcond, 1);
3173         $newtrue = $self->deparse($newtrue, 0);
3174         $elsif ||= $self->keyword("elsif");
3175         push @elsifs, "$elsif ($newcond) {\n\t$newtrue\n\b}";
3176     }
3177     if (!null($false)) {
3178         $false = $cuddle . $self->keyword("else") . " {\n\t" .
3179           $self->deparse($false, 0) . "\n\b}\cK";
3180     } else {
3181         $false = "\cK";
3182     }
3183     return $head . join($cuddle, "", @elsifs) . $false;
3184 }
3185
3186 sub pp_once {
3187     my ($self, $op, $cx) = @_;
3188     my $cond = $op->first;
3189     my $true = $cond->sibling;
3190
3191     return $self->deparse($true, $cx);
3192 }
3193
3194 sub loop_common {
3195     my $self = shift;
3196     my($op, $cx, $init) = @_;
3197     my $enter = $op->first;
3198     my $kid = $enter->sibling;
3199     local(@$self{qw'curstash warnings hints hinthash'})
3200                 = @$self{qw'curstash warnings hints hinthash'};
3201     my $head = "";
3202     my $bare = 0;
3203     my $body;
3204     my $cond = undef;
3205     my $name;
3206     if ($kid->name eq "lineseq") { # bare or infinite loop
3207         if ($kid->last->name eq "unstack") { # infinite
3208             $head = "while (1) "; # Can't use for(;;) if there's a continue
3209             $cond = "";
3210         } else {
3211             $bare = 1;
3212         }
3213         $body = $kid;
3214     } elsif ($enter->name eq "enteriter") { # foreach
3215         my $ary = $enter->first->sibling; # first was pushmark
3216         my $var = $ary->sibling;
3217         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3218             # "reverse" was optimised away
3219             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3220         } elsif ($enter->flags & OPf_STACKED
3221             and not null $ary->first->sibling->sibling)
3222         {
3223             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3224               $self->deparse($ary->first->sibling->sibling, 9);
3225         } else {
3226             $ary = $self->deparse($ary, 1);
3227         }
3228         if (null $var) {
3229             $var = $self->pp_padsv($enter, 1, 1);
3230         } elsif ($var->name eq "rv2gv") {
3231             $var = $self->pp_rv2sv($var, 1);
3232             if ($enter->private & OPpOUR_INTRO) {
3233                 # our declarations don't have package names
3234                 $var =~ s/^(.).*::/$1/;
3235                 $var = "our $var";
3236             }
3237         } elsif ($var->name eq "gv") {
3238             $var = "\$" . $self->deparse($var, 1);
3239         } else {
3240             $var = $self->deparse($var, 1);
3241         }
3242         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3243         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3244             confess unless $var eq '$_';
3245             $body = $body->first;
3246             return $self->deparse($body, 2) . " "
3247                  . $self->keyword("foreach") . " ($ary)";
3248         }
3249         $head = "foreach $var ($ary) ";
3250     } elsif ($kid->name eq "null") { # while/until
3251         $kid = $kid->first;
3252         $name = {"and" => "while", "or" => "until"}->{$kid->name};
3253         $cond = $kid->first;
3254         $body = $kid->first->sibling;
3255     } elsif ($kid->name eq "stub") { # bare and empty
3256         return "{;}"; # {} could be a hashref
3257     }
3258     # If there isn't a continue block, then the next pointer for the loop
3259     # will point to the unstack, which is kid's last child, except
3260     # in a bare loop, when it will point to the leaveloop. When neither of
3261     # these conditions hold, then the second-to-last child is the continue
3262     # block (or the last in a bare loop).
3263     my $cont_start = $enter->nextop;
3264     my $cont;
3265     my $precond;
3266     my $postcond;
3267     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3268         if ($bare) {
3269             $cont = $body->last;
3270         } else {
3271             $cont = $body->first;
3272             while (!null($cont->sibling->sibling)) {
3273                 $cont = $cont->sibling;
3274             }
3275         }
3276         my $state = $body->first;
3277         my $cuddle = $self->{'cuddle'};
3278         my @states;
3279         for (; $$state != $$cont; $state = $state->sibling) {
3280             push @states, $state;
3281         }
3282         $body = $self->lineseq(undef, 0, @states);
3283         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3284             $precond = "for ($init; ";
3285             $postcond = "; " . $self->deparse($cont, 1) .") ";
3286             $cont = "\cK";
3287         } else {
3288             $cont = $cuddle . "continue {\n\t" .
3289               $self->deparse($cont, 0) . "\n\b}\cK";
3290         }
3291     } else {
3292         return "" if !defined $body;
3293         if (length $init) {
3294             $precond = "for ($init; ";
3295             $postcond = ";) ";
3296         }
3297         $cont = "\cK";
3298         $body = $self->deparse($body, 0);
3299     }
3300     if ($precond) { # for(;;)
3301         $cond &&= $name eq 'until'
3302                     ? listop($self, undef, 1, "not", $cond->first)
3303                     : $self->deparse($cond, 1);
3304         $head = "$precond$cond$postcond";
3305     }
3306     if ($name && !$head) {
3307         ref $cond and $cond = $self->deparse($cond, 1);
3308         $head = "$name ($cond) ";
3309     }
3310     $head =~ s/^(for(?:each)?|while|until)/$self->keyword($1)/e;
3311     $body =~ s/;?$/;\n/;
3312
3313     return $head . "{\n\t" . $body . "\b}" . $cont;
3314 }
3315
3316 sub pp_leaveloop { shift->loop_common(@_, "") }
3317
3318 sub for_loop {
3319     my $self = shift;
3320     my($op, $cx) = @_;
3321     my $init = $self->deparse($op, 1);
3322     my $s = $op->sibling;
3323     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3324     return $self->loop_common($ll, $cx, $init);
3325 }
3326
3327 sub pp_leavetry {
3328     my $self = shift;
3329     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3330 }
3331
3332 sub _op_is_or_was {
3333   my ($op, $expect_type) = @_;
3334   my $type = $op->type;
3335   return($type == $expect_type
3336          || ($type == OP_NULL && $op->targ == $expect_type));
3337 }
3338
3339 sub pp_null {
3340     my $self = shift;
3341     my($op, $cx) = @_;
3342     if (class($op) eq "OP") {
3343         # old value is lost
3344         return $self->{'ex_const'} if $op->targ == OP_CONST;
3345     } elsif ($op->first->name eq 'pushmark'
3346              or $op->first->name eq 'null'
3347                 && $op->first->targ == OP_PUSHMARK
3348                 && _op_is_or_was($op, OP_LIST)) {
3349         return $self->pp_list($op, $cx);
3350     } elsif ($op->first->name eq "enter") {
3351         return $self->pp_leave($op, $cx);
3352     } elsif ($op->first->name eq "leave") {
3353         return $self->pp_leave($op->first, $cx);
3354     } elsif ($op->first->name eq "scope") {
3355         return $self->pp_scope($op->first, $cx);
3356     } elsif ($op->targ == OP_STRINGIFY) {
3357         return $self->dquote($op, $cx);
3358     } elsif ($op->targ == OP_GLOB) {
3359         return $self->pp_glob(
3360                  $op->first    # entersub
3361                     ->first    # ex-list
3362                     ->first    # pushmark
3363                     ->sibling, # glob
3364                  $cx
3365                );
3366     } elsif (!null($op->first->sibling) and
3367              $op->first->sibling->name eq "readline" and
3368              $op->first->sibling->flags & OPf_STACKED) {
3369         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
3370                                    . $self->deparse($op->first->sibling, 7),
3371                                    $cx, 7);
3372     } elsif (!null($op->first->sibling) and
3373              $op->first->sibling->name eq "trans" and
3374              $op->first->sibling->flags & OPf_STACKED) {
3375         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
3376                                    . $self->deparse($op->first->sibling, 20),
3377                                    $cx, 20);
3378     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
3379         return ($self->lex_in_scope("&do") ? "CORE::do" : "do")
3380              . " {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
3381     } elsif (!null($op->first->sibling) and
3382              $op->first->sibling->name eq "null" and
3383              class($op->first->sibling) eq "UNOP" and
3384              $op->first->sibling->first->flags & OPf_STACKED and
3385              $op->first->sibling->first->name eq "rcatline") {
3386         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
3387                                    . $self->deparse($op->first->sibling, 18),
3388                                    $cx, 18);
3389     } else {
3390         return $self->deparse($op->first, $cx);
3391     }
3392 }
3393
3394 sub padname {
3395     my $self = shift;
3396     my $targ = shift;
3397     return $self->padname_sv($targ)->PVX;
3398 }
3399
3400 sub padany {
3401     my $self = shift;
3402     my $op = shift;
3403     return substr($self->padname($op->targ), 1); # skip $/@/%
3404 }
3405
3406 sub pp_padsv {
3407     my $self = shift;
3408     my($op, $cx, $forbid_parens) = @_;
3409     my $targ = $op->targ;
3410     return $self->maybe_my($op, $cx, $self->padname($targ),
3411                            $self->padname_sv($targ),
3412                            $forbid_parens);
3413 }
3414
3415 sub pp_padav { pp_padsv(@_) }
3416 sub pp_padhv { pp_padsv(@_) }
3417
3418 sub gv_or_padgv {
3419     my $self = shift;
3420     my $op = shift;
3421     if (class($op) eq "PADOP") {
3422         return $self->padval($op->padix);
3423     } else { # class($op) eq "SVOP"
3424         return $op->gv;
3425     }
3426 }
3427
3428 sub pp_gvsv {
3429     my $self = shift;
3430     my($op, $cx) = @_;
3431     my $gv = $self->gv_or_padgv($op);
3432     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
3433                                  $self->gv_name($gv), $cx));
3434 }
3435
3436 sub pp_gv {
3437     my $self = shift;
3438     my($op, $cx) = @_;
3439     my $gv = $self->gv_or_padgv($op);
3440     return $self->gv_name($gv);
3441 }
3442
3443 sub pp_aelemfast_lex {
3444     my $self = shift;
3445     my($op, $cx) = @_;
3446     my $name = $self->padname($op->targ);
3447     $name =~ s/^@/\$/;
3448     my $i = $op->private;
3449     $i -= 256 if $i > 127;
3450     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
3451 }
3452
3453 sub pp_aelemfast {
3454     my $self = shift;
3455     my($op, $cx) = @_;
3456     # optimised PADAV, pre 5.15
3457     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
3458
3459     my $gv = $self->gv_or_padgv($op);
3460     my($name,$quoted) = $self->stash_variable_name('@',$gv);
3461     $name = $quoted ? "$name->" : '$' . $name;
3462     my $i = $op->private;
3463     $i -= 256 if $i > 127;
3464     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
3465 }
3466
3467 sub rv2x {
3468     my $self = shift;
3469     my($op, $cx, $type) = @_;
3470
3471     if (class($op) eq 'NULL' || !$op->can("first")) {
3472         carp("Unexpected op in pp_rv2x");
3473         return 'XXX';
3474     }
3475     my $kid = $op->first;
3476     if ($kid->name eq "gv") {
3477         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
3478     } elsif (is_scalar $kid) {
3479         my $str = $self->deparse($kid, 0);
3480         if ($str =~ /^\$([^\w\d])\z/) {
3481             # "$$+" isn't a legal way to write the scalar dereference
3482             # of $+, since the lexer can't tell you aren't trying to
3483             # do something like "$$ + 1" to get one more than your
3484             # PID. Either "${$+}" or "$${+}" are workable
3485             # disambiguations, but if the programmer did the former,
3486             # they'd be in the "else" clause below rather than here.
3487             # It's not clear if this should somehow be unified with
3488             # the code in dq and re_dq that also adds lexer
3489             # disambiguation braces.
3490             $str = '$' . "{$1}"; #'
3491         }
3492         return $type . $str;
3493     } else {
3494         return $type . "{" . $self->deparse($kid, 0) . "}";
3495     }
3496 }
3497
3498 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3499 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3500 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3501
3502 # skip rv2av
3503 sub pp_av2arylen {
3504     my $self = shift;
3505     my($op, $cx) = @_;
3506     if ($op->first->name eq "padav") {
3507         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3508     } else {
3509         return $self->maybe_local($op, $cx,
3510                                   $self->rv2x($op->first, $cx, '$#'));
3511     }
3512 }
3513
3514 # skip down to the old, ex-rv2cv
3515 sub pp_rv2cv {
3516     my ($self, $op, $cx) = @_;
3517     if (!null($op->first) && $op->first->name eq 'null' &&
3518         $op->first->targ == OP_LIST)
3519     {
3520         return $self->rv2x($op->first->first->sibling, $cx, "&")
3521     }
3522     else {
3523         return $self->rv2x($op, $cx, "")
3524     }
3525 }
3526
3527 sub list_const {
3528     my $self = shift;
3529     my($cx, @list) = @_;
3530     my @a = map $self->const($_, 6), @list;
3531     if (@a == 0) {
3532         return "()";
3533     } elsif (@a == 1) {
3534         return $a[0];
3535     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3536         # collapse (-1,0,1,2) into (-1..2)
3537         my ($s, $e) = @a[0,-1];
3538         my $i = $s;
3539         return $self->maybe_parens("$s..$e", $cx, 9)
3540           unless grep $i++ != $_, @a;
3541     }
3542     return $self->maybe_parens(join(", ", @a), $cx, 6);
3543 }
3544
3545 sub pp_rv2av {
3546     my $self = shift;
3547     my($op, $cx) = @_;
3548     my $kid = $op->first;
3549     if ($kid->name eq "const") { # constant list
3550         my $av = $self->const_sv($kid);
3551         return $self->list_const($cx, $av->ARRAY);
3552     } else {
3553         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3554     }
3555  }
3556
3557 sub is_subscriptable {
3558     my $op = shift;
3559     if ($op->name =~ /^[ahg]elem/) {
3560         return 1;
3561     } elsif ($op->name eq "entersub") {
3562         my $kid = $op->first;
3563         return 0 unless null $kid->sibling;
3564         $kid = $kid->first;
3565         $kid = $kid->sibling until null $kid->sibling;
3566         return 0 if is_scope($kid);
3567         $kid = $kid->first;
3568         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
3569         return 0 if is_scalar($kid);
3570         return is_subscriptable($kid);  
3571     } else {
3572         return 0;
3573     }
3574 }
3575
3576 sub elem_or_slice_array_name
3577 {
3578     my $self = shift;
3579     my ($array, $left, $padname, $allow_arrow) = @_;
3580
3581     if ($array->name eq $padname) {
3582         return $self->padany($array);
3583     } elsif (is_scope($array)) { # ${expr}[0]
3584         return "{" . $self->deparse($array, 0) . "}";
3585     } elsif ($array->name eq "gv") {
3586         ($array, my $quoted) =
3587             $self->stash_variable_name(
3588                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
3589             );
3590         if (!$allow_arrow && $quoted) {
3591             # This cannot happen.
3592             die "Invalid variable name $array for slice";
3593         }
3594         return $quoted ? "$array->" : $array;
3595     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3596         return $self->deparse($array, 24);
3597     } else {
3598         return undef;
3599     }
3600 }
3601
3602 sub elem_or_slice_single_index
3603 {
3604     my $self = shift;
3605     my ($idx) = @_;
3606
3607     $idx = $self->deparse($idx, 1);
3608
3609     # Outer parens in an array index will confuse perl
3610     # if we're interpolating in a regular expression, i.e.
3611     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3612     #
3613     # If $self->{parens}, then an initial '(' will
3614     # definitely be paired with a final ')'. If
3615     # !$self->{parens}, the misleading parens won't
3616     # have been added in the first place.
3617     #
3618     # [You might think that we could get "(...)...(...)"
3619     # where the initial and final parens do not match
3620     # each other. But we can't, because the above would
3621     # only happen if there's an infix binop between the
3622     # two pairs of parens, and *that* means that the whole
3623     # expression would be parenthesized as well.]
3624     #
3625     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3626
3627     # Hash-element braces will autoquote a bareword inside themselves.
3628     # We need to make sure that C<$hash{warn()}> doesn't come out as
3629     # C<$hash{warn}>, which has a quite different meaning. Currently
3630     # B::Deparse will always quote strings, even if the string was a
3631     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3632     # for constant strings.) So we can cheat slightly here - if we see
3633     # a bareword, we know that it is supposed to be a function call.
3634     #
3635     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3636
3637     return $idx;
3638 }
3639
3640 sub elem {
3641     my $self = shift;
3642     my ($op, $cx, $left, $right, $padname) = @_;
3643     my($array, $idx) = ($op->first, $op->first->sibling);
3644
3645     $idx = $self->elem_or_slice_single_index($idx);
3646
3647     unless ($array->name eq $padname) { # Maybe this has been fixed     
3648         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3649     }
3650     if (my $array_name=$self->elem_or_slice_array_name
3651             ($array, $left, $padname, 1)) {
3652         return ($array_name =~ /->\z/
3653                     ? $array_name
3654                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
3655               . $left . $idx . $right;
3656     } else {
3657         # $x[20][3]{hi} or expr->[20]
3658         my $arrow = is_subscriptable($array) ? "" : "->";
3659         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3660     }
3661
3662 }
3663
3664 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3665 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3666
3667 sub pp_gelem {
3668     my $self = shift;
3669     my($op, $cx) = @_;
3670     my($glob, $part) = ($op->first, $op->last);
3671     $glob = $glob->first; # skip rv2gv
3672     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3673     my $scope = is_scope($glob);
3674     $glob = $self->deparse($glob, 0);
3675     $part = $self->deparse($part, 1);
3676     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3677 }
3678
3679 sub slice {
3680     my $self = shift;
3681     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3682     my $last;
3683     my(@elems, $kid, $array, $list);
3684     if (class($op) eq "LISTOP") {
3685         $last = $op->last;
3686     } else { # ex-hslice inside delete()
3687         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3688         $last = $kid;
3689     }
3690     $array = $last;
3691     $array = $array->first
3692         if $array->name eq $regname or $array->name eq "null";
3693     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3694     $kid = $op->first->sibling; # skip pushmark
3695     if ($kid->name eq "list") {
3696         $kid = $kid->first->sibling; # skip list, pushmark
3697         for (; !null $kid; $kid = $kid->sibling) {
3698             push @elems, $self->deparse($kid, 6);
3699         }
3700         $list = join(", ", @elems);
3701     } else {
3702         $list = $self->elem_or_slice_single_index($kid);
3703     }
3704     my $lead = '@';
3705     $lead = '%' if $op->name =~ /^kv/i;
3706     return $lead . $array . $left . $list . $right;
3707 }
3708
3709 sub pp_aslice   { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3710 sub pp_kvaslice {                 slice(@_, "[", "]", "rv2av", "padav")  }
3711 sub pp_hslice   { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3712 sub pp_kvhslice {                 slice(@_, "{", "}", "rv2hv", "padhv")  }
3713
3714 sub pp_lslice {
3715     my $self = shift;
3716     my($op, $cx) = @_;
3717     my $idx = $op->first;
3718     my $list = $op->last;
3719     my(@elems, $kid);
3720     $list = $self->deparse($list, 1);
3721     $idx = $self->deparse($idx, 1);
3722     return "($list)" . "[$idx]";
3723 }
3724
3725 sub want_scalar {
3726     my $op = shift;
3727     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3728 }
3729
3730 sub want_list {
3731     my $op = shift;
3732     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3733 }
3734
3735 sub _method {
3736     my $self = shift;
3737     my($op, $cx) = @_;
3738     my $kid = $op->first->sibling; # skip pushmark
3739     my($meth, $obj, @exprs);
3740     if ($kid->name eq "list" and want_list $kid) {
3741         # When an indirect object isn't a bareword but the args are in
3742         # parens, the parens aren't part of the method syntax (the LLAFR
3743         # doesn't apply), but they make a list with OPf_PARENS set that
3744         # doesn't get flattened by the append_elem that adds the method,
3745         # making a (object, arg1, arg2, ...) list where the object
3746         # usually is. This can be distinguished from
3747         # '($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3748         # object) because in the later the list is in scalar context
3749         # as the left side of -> always is, while in the former
3750         # the list is in list context as method arguments always are.
3751         # (Good thing there aren't method prototypes!)
3752         $meth = $kid->sibling;
3753         $kid = $kid->first->sibling; # skip pushmark
3754         $obj = $kid;
3755         $kid = $kid->sibling;
3756         for (; not null $kid; $kid = $kid->sibling) {
3757             push @exprs, $kid;
3758         }
3759     } else {
3760         $obj = $kid;
3761         $kid = $kid->sibling;
3762         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3763               $kid = $kid->sibling) {
3764             push @exprs, $kid
3765         }
3766         $meth = $kid;
3767     }
3768
3769     if ($meth->name eq "method_named") {
3770         $meth = $self->meth_sv($meth)->PV;
3771     } else {
3772         $meth = $meth->first;
3773         if ($meth->name eq "const") {
3774             # As of 5.005_58, this case is probably obsoleted by the
3775             # method_named case above
3776             $meth = $self->const_sv($meth)->PV; # needs to be bare
3777         }
3778     }
3779
3780     return { method => $meth, variable_method => ref($meth),
3781              object => $obj, args => \@exprs  },
3782            $cx;
3783 }
3784
3785 # compat function only
3786 sub method {
3787     my $self = shift;
3788     my $info = $self->_method(@_);
3789     return $self->e_method( $self->_method(@_) );
3790 }
3791
3792 sub e_method {
3793     my ($self, $info, $cx) = @_;
3794     my $obj = $self->deparse($info->{object}, 24);
3795
3796     my $meth = $info->{method};
3797     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3798     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3799     if ($info->{object}->name eq 'scope' && want_list $info->{object}) {
3800         # method { $object }
3801         # This must be deparsed this way to preserve list context
3802         # of $object.
3803         my $need_paren = $cx >= 6;
3804         return '(' x $need_paren
3805              . $meth . substr($obj,2) # chop off the "do"
3806              . " $args"
3807              . ')' x $need_paren;
3808     }
3809     my $kid = $obj . "->" . $meth;
3810     if (length $args) {
3811         return $kid . "(" . $args . ")"; # parens mandatory
3812     } else {
3813         return $kid;
3814     }
3815 }
3816
3817 # returns "&" if the prototype doesn't match the args,
3818 # or ("", $args_after_prototype_demunging) if it does.
3819 sub check_proto {
3820     my $self = shift;
3821     return "&" if $self->{'noproto'};
3822     my($proto, @args) = @_;
3823     my($arg, $real);
3824     my $doneok = 0;
3825     my @reals;
3826     # An unbackslashed @ or % gobbles up the rest of the args
3827     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3828     $proto =~ s/^\s*//;
3829     while ($proto) {
3830         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)\s*//;
3831         my $chr = $1;
3832         if ($chr eq "") {
3833             return "&" if @args;
3834         } elsif ($chr eq ";") {
3835             $doneok = 1;
3836         } elsif ($chr eq "@" or $chr eq "%") {
3837             push @reals, map($self->deparse($_, 6), @args);
3838             @args = ();
3839         } else {
3840             $arg = shift @args;
3841             last unless $arg;
3842             if ($chr eq "\$" || $chr eq "_") {
3843                 if (want_scalar $arg) {
3844                     push @reals, $self->deparse($arg, 6);
3845                 } else {
3846                     return "&";
3847                 }
3848             } elsif ($chr eq "&") {
3849                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3850                     push @reals, $self->deparse($arg, 6);
3851                 } else {
3852                     return "&";
3853                 }
3854             } elsif ($chr eq "*") {
3855                 if ($arg->name =~ /^s?refgen$/
3856                     and $arg->first->first->name eq "rv2gv")
3857                   {
3858                       $real = $arg->first->first; # skip refgen, null
3859                       if ($real->first->name eq "gv") {
3860                           push @reals, $self->deparse($real, 6);
3861                       } else {
3862                           push @reals, $self->deparse($real->first, 6);
3863                       }
3864                   } else {
3865                       return "&";
3866                   }
3867             } elsif (substr($chr, 0, 1) eq "\\") {
3868                 $chr =~ tr/\\[]//d;
3869                 if ($arg->name =~ /^s?refgen$/ and
3870                     !null($real = $arg->first) and
3871                     ($chr =~ /\$/ && is_scalar($real->first)
3872                      or ($chr =~ /@/
3873                          && class($real->first->sibling) ne 'NULL'
3874                          && $real->first->sibling->name
3875                          =~ /^(rv2|pad)av$/)
3876                      or ($chr =~ /%/
3877                          && class($real->first->sibling) ne 'NULL'
3878                          && $real->first->sibling->name
3879                          =~ /^(rv2|pad)hv$/)
3880                      #or ($chr =~ /&/ # This doesn't work
3881                      #   && $real->first->name eq "rv2cv")
3882                      or ($chr =~ /\*/
3883                          && $real->first->name eq "rv2gv")))
3884                   {
3885                       push @reals, $self->deparse($real, 6);
3886                   } else {
3887                       return "&";
3888                   }
3889             }
3890        }
3891     }
3892     return "&" if $proto and !$doneok; # too few args and no ';'
3893     return "&" if @args;               # too many args
3894     return ("", join ", ", @reals);
3895 }
3896
3897 sub pp_entersub {
3898     my $self = shift;
3899     my($op, $cx) = @_;
3900     return $self->e_method($self->_method($op, $cx))
3901         unless null $op->first->sibling;
3902     my $prefix = "";
3903     my $amper = "";
3904     my($kid, @exprs);
3905     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3906         $prefix = "do ";
3907     } elsif ($op->private & OPpENTERSUB_AMPER) {
3908         $amper = "&";
3909     }
3910     $kid = $op->first;
3911     $kid = $kid->first->sibling; # skip ex-list, pushmark
3912     for (; not null $kid->sibling; $kid = $kid->sibling) {
3913         push @exprs, $kid;
3914     }
3915     my $simple = 0;
3916     my $proto = undef;
3917     if (is_scope($kid)) {
3918         $amper = "&";
3919         $kid = "{" . $self->deparse($kid, 0) . "}";
3920     } elsif ($kid->first->name eq "gv") {
3921         my $gv = $self->gv_or_padgv($kid->first);
3922         my $cv;
3923         if (class($gv) eq 'GV' && class($cv = $gv->CV) ne "SPECIAL"
3924          || $gv->FLAGS & SVf_ROK && class($cv = $gv->RV) eq 'CV') {
3925             $proto = $cv->PV if $cv->FLAGS & SVf_POK;
3926         }
3927         $simple = 1; # only calls of named functions can be prototyped
3928         $kid = $self->deparse($kid, 24);
3929         if (!$amper) {
3930             if ($kid eq 'main::') {
3931                 $kid = '::';
3932             }
3933             else {
3934               if ($kid !~ /::/ && $kid ne 'x') {
3935                 # Fully qualify any sub name that is also a keyword.  While
3936                 # we could check the import flag, we cannot guarantee that
3937                 # the code deparsed so far would set that flag, so we qual-
3938                 # ify the names regardless of importation.
3939                 my $fq;
3940                 if (exists $feature_keywords{$kid}) {
3941                     $fq++ if $self->feature_enabled($kid);
3942                 } elsif (do { local $@; local $SIG{__DIE__};
3943                               eval { () = prototype "CORE::$kid"; 1 } }) {
3944                     $fq++
3945                 }
3946                 $fq and substr $kid, 0, 0, = $self->{'curstash'}.'::';
3947               }
3948               if ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3949                 $kid = single_delim("q", "'", $kid, $self) . '->';
3950               }
3951             }
3952         }
3953     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3954         $amper = "&";
3955         $kid = $self->deparse($kid, 24);
3956     } else {
3957         $prefix = "";
3958         my $arrow = is_subscriptable($kid->first) || $kid->first->name eq "padcv" ? "" : "->";
3959         $kid = $self->deparse($kid, 24) . $arrow;
3960     }
3961
3962     # Doesn't matter how many prototypes there are, if
3963     # they haven't happened yet!
3964     my $declared;
3965     {
3966         no strict 'refs';
3967         no warnings 'uninitialized';
3968         $declared = exists $self->{'subs_declared'}{$kid}
3969             || (
3970                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3971                  && !exists
3972                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3973                  && defined prototype $self->{'curstash'}."::".$kid
3974                );
3975         if (!$declared && defined($proto)) {
3976             # Avoid "too early to check prototype" warning
3977             ($amper, $proto) = ('&');
3978         }
3979     }
3980
3981     my $args;
3982     if ($declared and defined $proto and not $amper) {
3983         ($amper, $args) = $self->check_proto($proto, @exprs);
3984         if ($amper eq "&") {
3985             $args = join(", ", map($self->deparse($_, 6), @exprs));
3986         }
3987     } else {
3988         $args = join(", ", map($self->deparse($_, 6), @exprs));
3989     }
3990     if ($prefix or $amper) {
3991         if ($kid eq '&') { $kid = "{$kid}" } # &{&} cannot be written as &&
3992         if ($op->flags & OPf_STACKED) {
3993             return $prefix . $amper . $kid . "(" . $args . ")";
3994         } else {
3995             return $prefix . $amper. $kid;
3996         }
3997     } else {
3998         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3999         # so it must have been translated from a keyword call. Translate
4000         # it back.
4001         $kid =~ s/^CORE::GLOBAL:://;
4002
4003         my $dproto = defined($proto) ? $proto : "undefined";
4004         if (!$declared) {
4005             return "$kid(" . $args . ")";
4006         } elsif ($dproto =~ /^\s*\z/) {
4007             return $kid;
4008         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
4009             # is_scalar is an excessively conservative test here:
4010             # really, we should be comparing to the precedence of the
4011             # top operator of $exprs[0] (ala unop()), but that would
4012             # take some major code restructuring to do right.
4013             return $self->maybe_parens_func($kid, $args, $cx, 16);
4014         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
4015             return $self->maybe_parens_func($kid, $args, $cx, 5);
4016         } else {
4017             return "$kid(" . $args . ")";
4018         }
4019     }
4020 }
4021
4022 sub pp_enterwrite { unop(@_, "write") }
4023
4024 # escape things that cause interpolation in double quotes,
4025 # but not character escapes
4026 sub uninterp {
4027     my($str) = @_;
4028     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
4029     return $str;
4030 }
4031
4032 {
4033 my $bal;
4034 BEGIN {
4035     use re "eval";
4036     # Matches any string which is balanced with respect to {braces}
4037     $bal = qr(
4038       (?:
4039         [^\\{}]
4040       | \\\\
4041       | \\[{}]
4042       | \{(??{$bal})\}
4043       )*
4044     )x;
4045 }
4046
4047 # the same, but treat $|, $), $( and $ at the end of the string differently
4048 sub re_uninterp {
4049     my($str) = @_;
4050
4051     $str =~ s/
4052           ( ^|\G                  # $1
4053           | [^\\]
4054           )
4055
4056           (                       # $2
4057             (?:\\\\)*
4058           )
4059
4060           (                       # $3
4061             (\(\?\??\{$bal\}\))   # $4
4062           | [\$\@]
4063             (?!\||\)|\(|$)
4064           | \\[uUlLQE]
4065           )
4066
4067         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
4068
4069     return $str;
4070 }
4071
4072 # This is for regular expressions with the /x modifier
4073 # We have to leave comments unmangled.
4074 sub re_uninterp_extended {
4075     my($str) = @_;
4076
4077     $str =~ s/
4078           ( ^|\G                  # $1
4079           | [^\\]
4080           )
4081
4082           (                       # $2
4083             (?:\\\\)*
4084           )
4085
4086           (                       # $3
4087             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
4088             | \#[^\n]*            #     (skip over comments)
4089             )
4090           | [\$\@]
4091             (?!\||\)|\(|$|\s)
4092           | \\[uUlLQE]
4093           )
4094
4095         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
4096
4097     return $str;
4098 }
4099 }
4100
4101 my %unctrl = # portable to EBCDIC
4102     (
4103      "\c@" => '\c@',    # unused
4104      "\cA" => '\cA',
4105      "\cB" => '\cB',
4106      "\cC" => '\cC',
4107      "\cD" => '\cD',
4108      "\cE" => '\cE',
4109      "\cF" => '\cF',
4110      "\cG" => '\cG',
4111      "\cH" => '\cH',
4112      "\cI" => '\cI',
4113      "\cJ" => '\cJ',
4114      "\cK" => '\cK',
4115      "\cL" => '\cL',
4116      "\cM" => '\cM',
4117      "\cN" => '\cN',
4118      "\cO" => '\cO',
4119      "\cP" => '\cP',
4120      "\cQ" => '\cQ',
4121      "\cR" => '\cR',
4122      "\cS" => '\cS',
4123      "\cT" => '\cT',
4124      "\cU" => '\cU',
4125      "\cV" => '\cV',
4126      "\cW" => '\cW',
4127      "\cX" => '\cX',
4128      "\cY" => '\cY',
4129      "\cZ" => '\cZ',
4130      "\c[" => '\c[',    # unused
4131      "\c\\" => '\c\\',  # unused
4132      "\c]" => '\c]',    # unused
4133      "\c_" => '\c_',    # unused
4134     );
4135
4136 # character escapes, but not delimiters that might need to be escaped
4137 sub escape_str { # ASCII, UTF8
4138     my($str) = @_;
4139     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4140     $str =~ s/\a/\\a/g;
4141 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
4142     $str =~ s/\t/\\t/g;
4143     $str =~ s/\n/\\n/g;
4144     $str =~ s/\e/\\e/g;
4145     $str =~ s/\f/\\f/g;
4146     $str =~ s/\r/\\r/g;
4147     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
4148     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
4149     return $str;
4150 }
4151
4152 # For regexes with the /x modifier.
4153 # Leave whitespace unmangled.
4154 sub escape_extended_re {
4155     my($str) = @_;
4156     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4157     $str =~ s/([[:^print:]])/
4158         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
4159     $str =~ s/\n/\n\f/g;
4160     return $str;
4161 }
4162
4163 # Don't do this for regexen
4164 sub unback {
4165     my($str) = @_;
4166     $str =~ s/\\/\\\\/g;
4167     return $str;
4168 }
4169
4170 # Remove backslashes which precede literal control characters,
4171 # to avoid creating ambiguity when we escape the latter.
4172 sub re_unback {
4173     my($str) = @_;
4174
4175     # the insane complexity here is due to the behaviour of "\c\"
4176     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
4177     return $str;
4178 }
4179
4180 sub balanced_delim {
4181     my($str) = @_;
4182     my @str = split //, $str;
4183     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
4184     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
4185         ($open, $close) = @$ar;
4186         $fail = 0; $cnt = 0; $last_bs = 0;
4187         for $c (@str) {
4188             if ($c eq $open) {
4189                 $fail = 1 if $last_bs;
4190                 $cnt++;
4191             } elsif ($c eq $close) {
4192                 $fail = 1 if $last_bs;
4193                 $cnt--;
4194                 if ($cnt < 0) {
4195                     # qq()() isn't ")("
4196                     $fail = 1;
4197                     last;
4198                 }
4199             }
4200             $last_bs = $c eq '\\';
4201         }
4202         $fail = 1 if $cnt != 0;
4203         return ($open, "$open$str$close") if not $fail;
4204     }
4205     return ("", $str);
4206 }
4207
4208 sub single_delim {
4209     my($q, $default, $str, $self) = @_;
4210     return "$default$str$default" if $default and index($str, $default) == -1;
4211     my $coreq = $self->keyword($q); # maybe CORE::q
4212     if ($q ne 'qr') {
4213         (my $succeed, $str) = balanced_delim($str);
4214         return "$coreq$str" if $succeed;
4215     }
4216     for my $delim ('/', '"', '#') {
4217         return "$coreq$delim" . $str . $delim if index($str, $delim) == -1;
4218     }
4219     if ($default) {
4220         $str =~ s/$default/\\$default/g;
4221         return "$default$str$default";
4222     } else {
4223         $str =~ s[/][\\/]g;
4224         return "$coreq/$str/";
4225     }
4226 }
4227
4228 my $max_prec;
4229 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
4230
4231 # Split a floating point number into an integer mantissa and a binary
4232 # exponent. Assumes you've already made sure the number isn't zero or
4233 # some weird infinity or NaN.
4234 sub split_float {
4235     my($f) = @_;
4236     my $exponent = 0;
4237     if ($f == int($f)) {
4238         while ($f % 2 == 0) {
4239             $f /= 2;
4240             $exponent++;
4241         }
4242     } else {
4243         while ($f != int($f)) {
4244             $f *= 2;
4245             $exponent--;
4246         }
4247     }
4248     my $mantissa = sprintf("%.0f", $f);
4249     return ($mantissa, $exponent);
4250 }
4251
4252 sub const {
4253     my $self = shift;
4254     my($sv, $cx) = @_;
4255     if ($self->{'use_dumper'}) {
4256         return $self->const_dumper($sv, $cx);
4257     }
4258     if (class($sv) eq "SPECIAL") {
4259         # sv_undef, sv_yes, sv_no
4260         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
4261     }
4262     if (class($sv) eq "NULL") {
4263        return 'undef';
4264     }
4265     # convert a version object into the "v1.2.3" string in its V magic
4266     if ($sv->FLAGS & SVs_RMG) {
4267         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4268             return $mg->PTR if $mg->TYPE eq 'V';
4269         }
4270     }
4271
4272     if ($sv->FLAGS & SVf_IOK) {
4273         my $str = $sv->int_value;
4274         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
4275         return $str;
4276     } elsif ($sv->FLAGS & SVf_NOK) {
4277         my $nv = $sv->NV;
4278         if ($nv == 0) {
4279             if (pack("F", $nv) eq pack("F", 0)) {
4280                 # positive zero
4281                 return "0";
4282             } else {
4283                 # negative zero
4284                 return $self->maybe_parens("-.0", $cx, 21);
4285             }
4286         } elsif (1/$nv == 0) {
4287             if ($nv > 0) {
4288                 # positive infinity
4289                 return $self->maybe_parens("9**9**9", $cx, 22);
4290             } else {
4291                 # negative infinity
4292                 return $self->maybe_parens("-9**9**9", $cx, 21);
4293             }
4294         } elsif ($nv != $nv) {
4295             # NaN
4296             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
4297                 # the normal kind
4298                 return "sin(9**9**9)";
4299             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
4300                 # the inverted kind
4301                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
4302             } else {
4303                 # some other kind
4304                 my $hex = unpack("h*", pack("F", $nv));
4305                 return qq'unpack("F", pack("h*", "$hex"))';
4306             }
4307         }
4308         # first, try the default stringification
4309         my $str = "$nv";
4310         if ($str != $nv) {
4311             # failing that, try using more precision
4312             $str = sprintf("%.${max_prec}g", $nv);
4313 #           if (pack("F", $str) ne pack("F", $nv)) {
4314             if ($str != $nv) {
4315                 # not representable in decimal with whatever sprintf()
4316                 # and atof() Perl is using here.
4317                 my($mant, $exp) = split_float($nv);
4318                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
4319             }
4320         }
4321         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
4322         return $str;
4323     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
4324         my $ref = $sv->RV;
4325         if (class($ref) eq "AV") {
4326             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
4327         } elsif (class($ref) eq "HV") {
4328             my %hash = $ref->ARRAY;
4329             my @elts;
4330             for my $k (sort keys %hash) {
4331                 push @elts, "$k => " . $self->const($hash{$k}, 6);
4332             }
4333             return "{" . join(", ", @elts) . "}";
4334         } elsif (class($ref) eq "CV") {
4335             BEGIN {
4336                 if ($] > 5.0150051) {
4337                     require overloading;
4338                     unimport overloading;
4339                 }
4340             }
4341             if ($] > 5.0150051 && $self->{curcv} &&
4342                  $self->{curcv}->object_2svref == $ref->object_2svref) {
4343                 return $self->keyword("__SUB__");
4344             }
4345             return "sub " . $self->deparse_sub($ref);
4346         }
4347         if ($ref->FLAGS & SVs_SMG) {
4348             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4349                 if ($mg->TYPE eq 'r') {
4350                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
4351                     return single_delim("qr", "", $re, $self);
4352                 }
4353             }
4354         }
4355         
4356         my $const = $self->const($ref, 20);
4357         if ($self->{in_subst_repl} && $const =~ /^[0-9]/) {
4358             $const = "($const)";
4359         }
4360         return $self->maybe_parens("\\$const", $cx, 20);
4361     } elsif ($sv->FLAGS & SVf_POK) {
4362         my $str = $sv->PV;
4363         if ($str =~ /[[:^print:]]/) {
4364             return single_delim("qq", '"',
4365                                  uninterp(escape_str unback $str), $self);
4366         } else {
4367             return single_delim("q", "'", unback($str), $self);
4368         }
4369     } else {
4370         return "undef";
4371     }
4372 }
4373
4374 sub const_dumper {
4375     my $self = shift;
4376     my($sv, $cx) = @_;
4377     my $ref = $sv->object_2svref();
4378     my $dumper = Data::Dumper->new([$$ref], ['$v']);
4379     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
4380     my $str = $dumper->Dump();
4381     if ($str =~ /^\$v/) {
4382         return '${my ' . $str . ' \$v}';
4383     } else {
4384         return $str;
4385     }
4386 }
4387
4388 sub const_sv {
4389     my $self = shift;
4390     my $op = shift;
4391     my $sv = $op->sv;
4392     # the constant could be in the pad (under useithreads)
4393     $sv = $self->padval($op->targ) unless $$sv;
4394     return $sv;
4395 }
4396
4397 sub meth_sv {
4398     my $self = shift;
4399     my $op = shift;
4400     my $sv = $op->meth_sv;
4401     # the constant could be in the pad (under useithreads)
4402     $sv = $self->padval($op->targ) unless $$sv;
4403     return $sv;
4404 }
4405
4406 sub pp_const {
4407     my $self = shift;
4408     my($op, $cx) = @_;
4409     if ($op->private & OPpCONST_ARYBASE) {
4410         return '$[';
4411     }
4412 #    if ($op->private & OPpCONST_BARE) { # trouble with '=>' autoquoting
4413 #       return $self->const_sv($op)->PV;
4414 #    }
4415     my $sv = $self->const_sv($op);
4416     return $self->const($sv, $cx);
4417 }
4418
4419 sub dq {
4420     my $self = shift;
4421     my $op = shift;
4422     my $type = $op->name;
4423     if ($type eq "const") {
4424         return '$[' if $op->private & OPpCONST_ARYBASE;
4425         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
4426     } elsif ($type eq "concat") {
4427         my $first = $self->dq($op->first);
4428         my $last  = $self->dq($op->last);
4429
4430         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
4431         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4432             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4433             || ($last =~ /^[:'{\[\w_]/ && #'
4434                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4435
4436         return $first . $last;
4437     } elsif ($type eq "uc") {
4438         return '\U' . $self->dq($op->first->sibling) . '\E';
4439     } elsif ($type eq "lc") {
4440         return '\L' . $self->dq($op->first->sibling) . '\E';
4441     } elsif ($type eq "ucfirst") {
4442         return '\u' . $self->dq($op->first->sibling);
4443     } elsif ($type eq "lcfirst") {
4444         return '\l' . $self->dq($op->first->sibling);
4445     } elsif ($type eq "quotemeta") {
4446         return '\Q' . $self->dq($op->first->sibling) . '\E';
4447     } elsif ($type eq "fc") {
4448         return '\F' . $self->dq($op->first->sibling) . '\E';
4449     } elsif ($type eq "join") {
4450         return $self->deparse($op->last, 26); # was join($", @ary)
4451     } else {
4452         return $self->deparse($op, 26);
4453     }
4454 }
4455
4456 sub pp_backtick {
4457     my $self = shift;
4458     my($op, $cx) = @_;
4459     # skip pushmark if it exists (readpipe() vs ``)
4460     my $child = $op->first->sibling->isa('B::NULL')
4461         ? $op->first : $op->first->sibling;
4462     if ($self->pure_string($child)) {
4463         return single_delim("qx", '`', $self->dq($child, 1), $self);
4464     }
4465     unop($self, @_, "readpipe");
4466 }
4467
4468 sub dquote {
4469     my $self = shift;
4470     my($op, $cx) = @_;
4471     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
4472     return $self->deparse($kid, $cx) if $self->{'unquote'};
4473     $self->maybe_targmy($kid, $cx,
4474                         sub {single_delim("qq", '"', $self->dq($_[1]),
4475                                            $self)});
4476 }
4477
4478 # OP_STRINGIFY is a listop, but it only ever has one arg
4479 sub pp_stringify { maybe_targmy(@_, \&dquote) }
4480
4481 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
4482 # note that tr(from)/to/ is OK, but not tr/from/(to)
4483 sub double_delim {
4484     my($from, $to) = @_;
4485     my($succeed, $delim);
4486 &nb