This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
In installperl, don't chdir 'lib' before finding files in lib/
[perl5.git] / installperl
1 #!./perl -w
2
3 BEGIN {
4     require 5.004;
5     chdir '..' if !-d 'lib' and -d '../lib';
6     @INC = 'lib';
7     $ENV{PERL5LIB} = 'lib';
8
9     # This needs to be at BEGIN time, before any use of Config
10     require './install_lib.pl';
11 }
12
13 use strict;
14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
15             %opts $packlist);
16 my ($dostrip, $versiononly, $force,
17     $otherperls, $archname, $nwinstall, $nopods);
18 # Not sure how easy it would be to refactor to remove the need for local $depth
19 # below
20 use vars qw /$depth/;
21
22 BEGIN {
23     if ($Is_VMS) { eval 'use VMS::Filespec;' }
24 }
25
26 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
27
28 use File::Find;
29 use File::Compare;
30 use File::Copy ();
31 use File::Path ();
32 use ExtUtils::Packlist;
33 use Cwd;
34
35 if ($Is_NetWare) {
36     $Is_W32 = 0;
37     $scr_ext = '.pl';
38 }
39
40 # override the ones in the rest of the script
41 sub mkpath {
42     File::Path::mkpath(@_) unless $opts{notify};
43 }
44
45 my $mainperldir = "/usr/bin";
46 my $exe_ext = $Config{exe_ext};
47
48 # Allow "make install PERLNAME=something_besides_perl":
49 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
50
51 # This is the base used for versioned names, like "perl5.6.0".
52 # It's separate because a common use of $PERLNAME is to install
53 # perl as "perl5", if that's used as base for versioned files you
54 # get "perl55.6.0".
55 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
56                     ? $ENV{PERLNAME_VERBASE}
57                     : $perl;
58 my $dbg = '';
59 my $ndbg = '';
60 if ( $Is_VMS ) {
61     if ( defined $Config{usevmsdebug} ) {
62         if ( $Config{usevmsdebug} eq 'define' ) {
63             $dbg = 'dbg';
64             $ndbg = 'ndbg';
65         }
66     }
67 }
68
69 $otherperls = 1;
70 # This little hack simplifies making the code after the comment "Fetch some
71 # frequently-used items from %Config" warning free. With $opts{destdir} always
72 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
73
74 $opts{destdir} = '';
75 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
76 # feature is implemented, to distinguish + and - options.
77 while (@ARGV) {
78     $opts{notify} = 1 if $ARGV[0] eq '-n';
79     $dostrip = 1 if $ARGV[0] eq '-s';
80     $versiononly = 1 if $ARGV[0] eq '-v';
81     $versiononly = 0 if $ARGV[0] eq '+v';
82     $opts{silent} = 1 if $ARGV[0] eq '-S';
83     $otherperls = 0 if $ARGV[0] eq '-o';
84     $force = 1 if $ARGV[0] eq '-f';
85     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
86     $archname = 1 if $ARGV[0] eq '-A';
87     $nwinstall = 1 if $ARGV[0] eq '-netware';
88     $nopods = 1 if $ARGV[0] eq '-p';
89     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
90     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
91         print <<"EOT";
92 Usage $0: [switches]
93   -n        Don't actually run any commands; just print them.
94   -s        Run strip on installed binaries.
95   -v        Only install perl as a binary with the version number in the name.
96             (Override whatever config.sh says)
97   +v        Install perl as "perl" and as a binary with the version number in
98             the name.  (Override whatever config.sh says)
99   -S        Silent mode.
100   -f        Force installation (don't check if same version is there)
101   -o        Skip checking for other copies of perl in your PATH.
102   -V        Verbose mode.
103   -A        Also install perl with the architecture's name in the perl binary's
104             name.
105   -p        Don't install the pod files. [This will break use diagnostics;]
106   -netware  Install correctly on a Netware server.
107   -destdir  Prefix installation directories by this string.
108 EOT
109         exit;
110     }
111     shift;
112 }
113
114 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
115 my (@scripts, @tolink);
116 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
117 while (<SCRIPTS>) {
118     next if /^#/;
119     next if /a2p/; # a2p is binary, to be installed separately
120     chomp;
121     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
122         push @scripts, $1;
123         push @tolink, [$1, $2];
124     } else {
125         push @scripts, $_;
126     }
127 }
128 close SCRIPTS;
129
130 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
131
132 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
133
134 # Specify here any .pm files that are actually architecture-dependent.
135 # (Those included with XS extensions under ext/ are automatically
136 # added later.)
137 # Now that the default privlib has the full perl version number included,
138 # we no longer have to play the trick of sticking version-specific .pm
139 # files under the archlib directory.
140 my %archpms = (
141     Config => 1,
142     lib => 1,
143     Cwd => 1,
144 );
145
146 if ($^O eq 'dos') {
147     push(@scripts,'djgpp/fixpmain');
148     $archpms{config} = $archpms{filehand} = 1;
149 }
150
151 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
152     push(@scripts, map("$_.exe", @scripts));
153 }
154
155 # Exclude nonxs extensions that are not architecture dependent
156 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
157
158 my @ext_dirs = qw(cpan dist ext);
159 foreach my $ext_dir (@ext_dirs) {
160     find(sub {
161         if (($File::Find::name =~ m{^$ext_dir\b(.*)/([^/]+)\.pm$}) &&
162             ! grep { (my $dir = $_) =~ s/\//-/g;
163                      $File::Find::name =~ /^$ext_dir\/$dir\// } @nonxs)
164         {
165             my($path, $modname) = ($1,$2);
166
167             # Change hyphenated name like Filter-Util-Call to nested
168             # directory name Filter/Util/Call
169             $path =~ s{-}{/}g;
170
171             # strip to optional "/lib", or remove trailing component
172             $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
173
174             # strip any leading /
175             $path =~ s{^/}{};
176
177             # reconstitute canonical module name
178             $modname = "$path/$modname" if length $path;
179
180             # remember it
181             $archpms{$modname} = 1;
182         }
183     }, $ext_dir);
184 }
185
186 # print "[$_]\n" for sort keys %archpms;
187
188 my $ver = $Config{version};
189 my $release = substr($],0,3);   # Not used currently.
190 my $patchlevel = substr($],3,2);
191 die "Patchlevel of perl ($patchlevel)",
192     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
193         if $patchlevel != $Config{'PERL_VERSION'};
194
195 # Fetch some frequently-used items from %Config
196 my $installbin = "$opts{destdir}$Config{installbin}";
197 my $installscript = "$opts{destdir}$Config{installscript}";
198 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
199 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
200 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
201 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
202 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
203 my $man1ext = $Config{man1ext};
204 my $libperl = $Config{libperl};
205 # Shared library and dynamic loading suffixes.
206 my $so = $Config{so};
207 my $dlext = $Config{dlext};
208 my $dlsrc = $Config{dlsrc};
209 if ($^O eq 'os390') {
210     my $pwd;
211     chomp($pwd=`pwd`);
212     my $archlibexp = $Config{archlibexp};
213     my $usedl = $Config{usedl};
214     if ($usedl eq 'define') {
215         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
216     }
217 }
218
219 if ($nwinstall) {
220     # This is required only if we are installing on a NetWare server
221     $installscript = $Config{installnwscripts};
222     $installprivlib = $Config{installnwlib};
223     $installarchlib = $Config{installnwlib};
224     $installsitelib = $Config{installnwlib};
225 }
226
227 my $binexp = $Config{binexp};
228
229 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
230     foreach ( \$installbin,     \$installscript,  \$installprivlib,
231               \$installarchlib, \$installsitelib, \$installsitearch,
232               \$installman1dir ) {
233         $$_ = unixify($$_);  $$_ =~ s:/$::;
234     }
235 }
236
237 # Do some quick sanity checks.
238
239    $installbin          || die "No installbin directory in config.sh\n";
240 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
241 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
242 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
243         unless $installbin =~ m#^/afs/# || $opts{notify};
244
245 if (!$Is_NetWare) {
246 if (!$Is_VMS) {
247 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
248 }
249 else {
250 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
251     if ($dbg) {
252         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
253     }
254 }
255
256 -f 't/rantests'         || $Is_W32
257                         || warn "WARNING: You've never run 'make test' or",
258                                 " some tests failed! (Installing anyway.)\n";
259 } #if (!$Is_NetWare)
260
261 # This will be used to store the packlist
262 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
263
264 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
265     my $perldll;
266
267     if ($Is_Cygwin) {
268         $perldll = $libperl;
269     } else {
270         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
271     }
272
273     if ($dlsrc ne "dl_none.xs") {
274         -f $perldll || die "No perl DLL built\n";
275     }
276
277     # Install the DLL
278     safe_unlink("$installbin/$perldll");
279     copy("$perldll", "$installbin/$perldll");
280     chmod(0755, "$installbin/$perldll");
281     $packlist->{"$installbin/$perldll"} = { type => 'file' };
282 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
283
284 # First we install the version-numbered executables.
285
286 if ($Is_VMS) {
287     safe_unlink("$installbin/perl_setup.com");
288     copy("perl_setup.com", "$installbin/perl_setup.com");
289     chmod(0755, "$installbin/perl_setup.com");
290     safe_unlink("$installbin/$dbg$perl$exe_ext");
291     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
292     chmod(0755, "$installbin/$dbg$perl$exe_ext");
293     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
294     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
295     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
296     if ($ndbg) {
297         safe_unlink("$installbin/$ndbg$perl$exe_ext");
298         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
299         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
300         safe_unlink("$installbin/${dbg}a2p$exe_ext");
301         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
302         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
303     }
304 }
305 elsif ($^O eq 'mpeix') {
306     # MPE lacks hard links and requires that executables with special
307     # capabilities reside in the MPE namespace.
308     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
309     # Install the primary executable into the MPE namespace as perlpath.
310     copy("perl$exe_ext", $Config{perlpath});
311     chmod(0755, $Config{perlpath});
312     # Create a backup copy with the version number.
313     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
314 }
315 elsif ($^O ne 'dos') {
316     if (!$Is_NetWare) {
317         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
318         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
319         strip("$installbin/$perl_verbase$ver$exe_ext");
320         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
321     }
322     else {
323         # If installing onto a NetWare server
324         if ($nwinstall) {
325             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
326             mkpath($Config{installnwsystem}, $opts{verbose}, 0777);
327             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
328             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
329             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
330             copy("x2p\\a2p.nlm", $Config{installnwsystem});
331             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
332             mkpath($Config{installnwlcgi}, $opts{verbose}, 0777);
333             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
334         }
335     } #if (!$Is_NetWare)
336 }
337 else {
338     safe_unlink("$installbin/$perl.exe");
339     copy("perl.exe", "$installbin/$perl.exe");
340 }
341
342 # Install library files.
343
344 my $do_installarchlib = !samepath($installarchlib, 'lib');
345 my $do_installprivlib = !samepath($installprivlib, 'lib');
346 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
347 $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
348
349 mkpath($installprivlib, $opts{verbose}, 0777);
350 mkpath($installarchlib, $opts{verbose}, 0777);
351 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
352 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
353
354 if (-d 'lib') {
355     find(\&installlib, 'lib')
356         if $do_installarchlib || $do_installprivlib;
357 }
358 else {
359     warn "Can't install lib files - 'lib/' does not exist";
360 }
361
362 # Install header files and libraries.
363 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
364 my @corefiles;
365 if ($Is_VMS) {  # We did core file selection during build
366     my $coredir = "lib/$Config{archname}/$ver/CORE";
367     $coredir =~ tr/./_/;
368     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
369 }
370 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
371     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
372     my $coredll = "$installarchlib/CORE/$libperl";
373     safe_unlink($coredll);
374     ( $Config{'d_link'} eq 'define' &&
375       eval {
376           CORE::link("$installbin/$libperl", $coredll);
377           $packlist->{$coredll} = { from => "$installbin/$libperl",
378                                     type => 'link' };
379       }
380     ) ||
381     eval {
382         symlink("$installbin/$libperl", $coredll);
383         $packlist->{$coredll} = { from => "$installbin/$libperl",
384                                   type => 'link' };
385     } ||
386     ( copy("$installbin/$libperl", $coredll) &&
387       push(@corefiles, $coredll)
388     )
389 } else {
390     # [als] hard-coded 'libperl' name... not good!
391     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
392
393     # AIX needs perl.exp installed as well.
394     push(@corefiles,'perl.exp') if $^O eq 'aix';
395     if ($^O eq 'mpeix') {
396         # MPE needs mpeixish.h installed as well.
397         mkpath("$installarchlib/CORE/mpeix", $opts{verbose}, 0777);
398         push(@corefiles,'mpeix/mpeixish.h');
399     }
400 }
401 foreach my $file (@corefiles) {
402     # HP-UX (at least) needs to maintain execute permissions
403     # on dynamically-loadable libraries. So we do it for all.
404     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
405         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
406             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
407             chmod(0555, "$installarchlib/CORE/$file");
408         } else {
409             chmod(0444, "$installarchlib/CORE/$file");
410         }
411     }
412 }
413
414 # Install main perl executables
415 # Make links to ordinary names if installbin directory isn't current directory.
416
417 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
418     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
419     if ($^O eq 'mpeix') {
420         # MPE doesn't support hard links, so use a symlink.
421         # We don't want another cloned copy.
422         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
423     } elsif ($^O eq 'vos') {
424         # VOS doesn't support hard links, so use a symlink.
425         symlink("$installbin/$perl_verbase$ver$exe_ext",
426                 "$installbin/$perl$exe_ext");
427     } else {
428         link("$installbin/$perl_verbase$ver$exe_ext",
429                 "$installbin/$perl$exe_ext");
430     }
431 }
432
433 # For development purposes it can be very useful to have multiple perls
434 # build for different "architectures" (eg threading or not) simultaneously.
435 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
436     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
437     safe_unlink("$installbin/$archperl");
438     if ($^O eq 'mpeix') {
439         # MPE doesn't support hard links, so use a symlink.
440         # We don't want another cloned copy.
441         symlink($Config{perlpath}, "$installbin/$archperl");
442     } elsif ($^O eq 'vos') {
443         # VOS doesn't support hard links, so use a symlink.
444         symlink("$installbin/$perl_verbase$ver$exe_ext",
445                 "$installbin/$archperl");
446     } else {
447         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
448     }
449 }
450
451 # Offer to install perl in a "standard" location
452
453 my $mainperl_is_instperl = 0;
454
455 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
456     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
457         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
458     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
459     my($instperl)       = "$installbin/$perl$exe_ext";
460     my($expinstperl)    = "$binexp/$perl$exe_ext";
461
462     # First make sure $usrbinperl is not already the same as the perl we
463     # just installed.
464     if (-x $usrbinperl) {
465         # Try to be clever about mainperl being a symbolic link
466         # to binexp/perl if binexp and installbin are different.
467         $mainperl_is_instperl =
468             samepath($usrbinperl, $instperl) ||
469             samepath($usrbinperl, $expinstperl) ||
470              (($binexp ne $installbin) &&
471               (-l $usrbinperl) &&
472               ((readlink $usrbinperl) eq $expinstperl));
473     }
474     if (! $mainperl_is_instperl) {
475         unlink($usrbinperl);
476         ( $Config{'d_link'} eq 'define' &&
477           eval { CORE::link $instperl, $usrbinperl } )  ||
478         eval { symlink $expinstperl, $usrbinperl }      ||
479         copy($instperl, $usrbinperl);
480
481         $mainperl_is_instperl = 1;
482     }
483 }
484
485 # Make links to ordinary names if installbin directory isn't current directory.
486 if (!$Is_NetWare && $dbg eq '') {
487     if (! samepath($installbin, 'x2p')) {
488         my $base = 'a2p';
489         $base .= $ver if $versiononly;
490         safe_unlink("$installbin/$base$exe_ext");
491         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
492         strip("$installbin/$base$exe_ext");
493         chmod(0755, "$installbin/$base$exe_ext");
494     }
495 }
496
497 # cppstdin is just a script, but it is architecture-dependent, so
498 # it can't safely be shared.  Place it in $installbin.
499 # Note that Configure doesn't build cppstin if it isn't needed, so
500 # we skip this if cppstdin doesn't exist.
501 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
502     safe_unlink("$installbin/cppstdin");
503     copy("cppstdin", "$installbin/cppstdin");
504     chmod(0755, "$installbin/cppstdin");
505 }
506
507 sub script_alias {
508     my ($installscript, $orig, $alias, $scr_ext) = @_;
509
510     safe_unlink("$installscript/$alias$scr_ext");
511     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
512         copy("$installscript/$orig$scr_ext",
513              "$installscript/$alias$scr_ext");
514     } elsif ($^O eq 'vos') {
515         symlink("$installscript/$orig$scr_ext",
516                 "$installscript/$alias$scr_ext");
517     } else {
518         link("$installscript/$orig$scr_ext",
519              "$installscript/$alias$scr_ext");
520     }
521 }
522
523 # Install scripts.
524 mkpath($installscript, $opts{verbose}, 0777);
525 if ($versiononly) {
526     for (@scripts) {
527         (my $base = $_) =~ s#.*/##;
528         $base .= $ver;
529         copy($_,    "$installscript/$base");
530         chmod(0755, "$installscript/$base");
531     }
532
533     for (@tolink) {
534         my ($from, $to) = map { "$_$ver" } @$_;
535         (my $frbase = $from) =~ s#.*/##;
536         (my $tobase = $to) =~ s#.*/##;
537         script_alias($installscript, $frbase, $tobase, $scr_ext);
538     }
539 } else {
540     for (@scripts) {
541         (my $base = $_) =~ s#.*/##;
542         copy($_, "$installscript/$base");
543         chmod(0755, "$installscript/$base");
544     }
545
546     for (@tolink) {
547         my ($from, $to) = @$_;
548         (my $frbase = $from) =~ s#.*/##;
549         (my $tobase = $to) =~ s#.*/##;
550         script_alias($installscript, $frbase, $tobase, $scr_ext);
551     }
552 }
553
554 # Install pod pages.  Where? I guess in $installprivlib/pod
555 # ($installprivlib/pods for cygwin).
556
557 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
558 if ( !$versiononly || ($installprivlib =~ m/\Q$vershort/)) {
559     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
560
561     for (@pods) {
562         # $_ is a name like  pod/perl.pod
563         (my $base = $_) =~ s#.*/##;
564         copy_if_diff($_, "${installprivlib}/$pod/${base}");
565     }
566
567 }
568
569 # Check to make sure there aren't other perls around in installer's
570 # path.  This is probably UNIX-specific.  Check all absolute directories
571 # in the path except for where public executables are supposed to live.
572 # Also skip $mainperl if the user opted to have it be a link to the
573 # installed perl.
574
575 if (!$versiononly && $otherperls) {
576     my ($path, @path);
577     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
578     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
579     @path = split(/$dirsep/, $path);
580     if ($Is_VMS) {
581         my $i = 0;
582         while (exists $ENV{'DCL$PATH' . $i}) {
583             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
584             push(@path,$dir);
585         }
586     }
587     my @otherperls;
588     my %otherperls;
589     for (@path) {
590         next unless m,^/,;
591         # Use &samepath here because some systems have other dirs linked
592         # to $mainperldir (like SunOS)
593         next unless -d;
594         next if samepath($_, $binexp);
595         next if samepath($_, cwd());
596         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
597         my $otherperl = "$_/$perl$exe_ext";
598         next if $otherperls{$otherperl}++;
599         push(@otherperls, $otherperl)
600             if (-x $otherperl && ! -d $otherperl);
601     }
602     if (@otherperls) {
603         warn "\nWarning: $perl appears in your path in the following " .
604             "locations beyond where\nwe just installed it:\n";
605         for (@otherperls) {
606             warn "    ", $_, "\n";
607         }
608         warn "\n";
609     }
610
611 }
612
613 $packlist->write() unless $opts{notify};
614 print "  Installation complete\n" if $opts{verbose};
615
616 exit 0;
617
618 ###############################################################################
619
620 # If these are needed elsewhere, move them into install_lib.pl rather than
621 # copying them.
622
623 sub yn {
624     my($prompt) = @_;
625     my($answer);
626     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
627     print STDERR $prompt;
628     chop($answer = <STDIN>);
629     $answer = $default if $answer =~ m/^\s*$/;
630     ($answer =~ m/^[yY]/);
631 }
632
633 sub safe_unlink {
634     return if $opts{notify} or $Is_VMS;
635     my @names = @_;
636     foreach my $name (@names) {
637         next unless -e $name;
638         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
639         print "  unlink $name\n" if $opts{verbose};
640         next if CORE::unlink($name);
641         warn "Couldn't unlink $name: $!\n";
642         if ($! =~ /busy/i) {
643             print "  mv $name $name.old\n" if $opts{verbose};
644             safe_rename($name, "$name.old")
645                 or warn "Couldn't rename $name: $!\n";
646         }
647     }
648 }
649
650 sub safe_rename {
651     my($from,$to) = @_;
652     if (-f $to and not unlink($to)) {
653         my($i);
654         for ($i = 1; $i < 50; $i++) {
655             last if rename($to, "$to.$i");
656         }
657         warn("Cannot rename to '$to.$i': $!"), return 0
658            if $i >= 50; # Give up!
659     }
660     link($from,$to) || return 0;
661     unlink($from);
662 }
663
664 sub copy {
665     my($from,$to) = @_;
666
667     my $xto = $to;
668     $xto =~ s/^\Q$opts{destdir}\E//;
669     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
670         unless $opts{silent};
671     print "  creating new version of $xto\n"
672         if $Is_VMS and -e $to and !$opts{silent};
673     unless ($opts{notify} or File::Copy::copy($from, $to)) {
674         # Might have been that F::C::c can't overwrite the target
675         warn "Couldn't copy $from to $to: $!\n"
676             unless -f $to and (chmod(0666, $to), unlink $to)
677                    and File::Copy::copy($from, $to);
678     }
679     $packlist->{$xto} = { type => 'file' };
680 }
681
682 sub installlib {
683     my $dir = $File::Find::dir;
684     $dir =~ s!\Alib/?!!;
685     local($depth) = $File::Find::dir . '/';
686
687     my $name = $_;
688
689     # Ignore version control directories.
690     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
691         $File::Find::prune = 1;
692         return;
693     }
694
695     # ignore patch backups, RCS files, emacs backup & temp files and the
696     # .exists files, .PL files, and test files.
697     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util\.pl$|^filter-util\.pl$|^uupacktool\.pl$|^\.gitignore$} ||
698               $dir  =~ m{/t(?:/|$)};
699     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
700     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
701     # the corelist script from lib/Module/CoreList/bin and ptar* in
702     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
703     # and zipdetails in cpan/IO-Compress/bin
704     # (they're installed later with other utils)
705     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|ptargrep|config_data|zipdetails)\z/;
706     # ignore the Makefiles
707     return if $name =~ /^makefile$/i;
708     # ignore the test extensions
709     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
710     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
711     # ignore the build support code
712     return if $name =~ /\bbuildcustomize\.pl$/;
713     # ignore the demo files
714     return if $dir =~ /\b(?:demos?|eg)\b/;
715     # ignore unneeded unicore files
716     if ( $dir =~ /^unicore/ ) {
717       if ( $name =~ /\.txt\z/ ) {
718         # We can ignore most, but not all .txt files
719         return unless $name =~ /\A(?:Blocks|CaseFolding|SpecialCasing|NamedSequences)\.txt\z/;
720       }
721       else {
722         # TestProp only needed during testing
723         return if $name =~ /\ATestProp.pl\z/;
724         # we need version and *.pl files and can skip the rest
725         return unless $name =~ /\A(?:version|\w+\.p[lm])\z/;
726       }
727     }
728
729     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
730     # Changes.e2x and README.e2x are needed by enc2xs.
731     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
732     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
733     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
734     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
735     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
736     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
737
738     # if using a shared perl library then ignore:
739     # - static library files [of statically linked extensions];
740     # - import library files and export library files (only present on Win32
741     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
742     return if $Config{useshrplib} eq 'true' and
743              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
744
745     $name = "$dir/$name" if $dir ne '';
746
747     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
748
749     my $installlib = $installprivlib;
750     if ($dir =~ /^auto\// ||
751           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
752           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
753           $name=~/^Config_(heavy|git)\.pl\z/
754        ) {
755         $installlib = $installarchlib;
756         return unless $do_installarchlib;
757     } else {
758         return unless $do_installprivlib;
759     }
760
761     if ($Is_NetWare && !$nwinstall && /\.(?:nlp|nlm|bs)$/) {
762         # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
763         # if copied will give problems when building new extensions.
764         # Has to be copied if we are installing on a NetWare server and
765         # hence the check !$nwinstall
766         return;
767     }
768
769     if (-f $_) {
770         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
771             $installlib = $installprivlib;
772             #We're installing *.al and *.ix files into $installprivlib,
773             #but we have to delete old *.al and *.ix files from the 5.000
774             #distribution:
775             #This might not work because $archname might have changed.
776             unlink("$installarchlib/$name");
777         }
778         my $xname = "$installlib/$name";
779         $xname =~ s/^\Q$opts{destdir}\E//;
780         $packlist->{$xname} = { type => 'file' };
781         if ($force || compare($_, "$installlib/$name") || $opts{notify}) {
782             unlink("$installlib/$name");
783             mkpath("$installlib/$dir", $opts{verbose}, 0777);
784             # HP-UX (at least) needs to maintain execute permissions
785             # on dynamically-loaded libraries.
786             if (copy_if_diff($_, "$installlib/$name")) {
787                 strip("-S", "$installlib/$name")
788                     if $^O =~ /^(rhapsody|darwin)$/ and /\.(?:so|$dlext|a)$/;
789                 chmod(/\.(so|$dlext)$/ ? 0555 : 0444, "$installlib/$name");
790             }
791         }
792     }
793 }
794
795 # Copy $from to $to, only if $from is different than $to.
796 # Also preserve modification times for .a libraries.
797 # On some systems, if you do
798 #   ranlib libperl.a
799 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
800 # and then try to link against the installed libperl.a, you might
801 # get an error message to the effect that the symbol table is older
802 # than the library.
803 # Return true if copying occurred.
804
805 sub copy_if_diff {
806     my($from,$to)=@_;
807     return 1 if (($^O eq 'VMS') && (-d $from));
808     my $xto = $to;
809     $xto =~ s/^\Q$opts{destdir}\E//;
810     my $perlpodbadsymlink;
811     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
812         -l $from &&
813         ! -e $from) {
814         # Some Linux implementations have problems traversing over
815         # multiple symlinks (when going over NFS?) and fail to read
816         # the symlink target.  Combine this with the fact that some
817         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
818         # and you end up with those pods not getting installed.
819         $perlpodbadsymlink = 1;
820     }
821     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
822     $packlist->{$xto} = { type => 'file' };
823     if ($force || compare($from, $to) || $opts{notify}) {
824         safe_unlink($to);   # In case we don't have write permissions.
825         if ($opts{notify}) {
826             $from = $depth . $from if $depth;
827         }
828         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
829             $from = "README.$1";
830         }
831         copy($from, $to);
832         # Restore timestamps if it's a .a library or for OS/2.
833         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
834             my ($atime, $mtime) = (stat $from)[8,9];
835             utime $atime, $mtime, $to;
836         }
837         1;
838     }
839 }
840
841 sub strip
842 {
843     my(@args) = @_;
844
845     return unless $dostrip;
846
847     my @opts;
848     while (@args && $args[0] =~ /^(-\w+)$/) {
849         push @opts, shift @args;
850     }
851
852     foreach my $file (@args) {
853         if (-f $file) {
854             if ($opts{verbose}) {
855                 print "  strip " . join(' ', @opts);
856                 print " " if (@opts);
857                 print "$file\n";
858             }
859             system("strip", @opts, $file);
860         } else {
861             print "# file '$file' skipped\n" if $opts{verbose};
862         }
863     }
864 }
865
866 # Local variables:
867 # cperl-indent-level: 4
868 # indent-tabs-mode: nil
869 # End:
870 #
871 # ex: set ts=8 sts=4 sw=4 et: