lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_10';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     $CommandSet
 631     $CreateTTY
 632     $DBGR
 633     @dbline
 634     $dbline
 635     %dbline
 636     $dieLevel
 637     $filename
 638     $histfile
 639     $histsize
 640     $IN
 641     $inhibit_exit
 642     @ini_INC
 643     $ini_warn
 644     $maxtrace
 645     $od
 646     @options
 647     $osingle
 648     $otrace
 649     $pager
 650     $post
 651     %postponed
 652     $prc
 653     $pre
 654     $pretype
 655     $psh
 656     @RememberOnROptions
 657     $remoteport
 658     @res
 659     $rl
 660     @saved
 661     $signalLevel
 662     $sub
 663     $term
 664     $usercontext
 665     $warnLevel
 666 );
 667
 668 our (
 669     @cmdfhs,
 670     $evalarg,
 671     $frame,
 672     $hist,
 673     $ImmediateStop,
 674     $line,
 675     $onetimeDump,
 676     $onetimedumpDepth,
 677     %option,
 678     $OUT,
 679     $packname,
 680     $signal,
 681     $single,
 682     $start,
 683     %sub,
 684     $subname,
 685     $trace,
 686     $window,
 687 );
 688
 689 # Used to save @ARGV and extract any debugger-related flags.
 690 use vars qw(@ARGS);
 691
 692 # Used to prevent multiple entries to diesignal()
 693 # (if for instance diesignal() itself dies)
 694 use vars qw($panic);
 695
 696 # Used to prevent the debugger from running nonstop
 697 # after a restart
 698 our ($second_time);
 699
 700 sub _calc_usercontext {
 701     my ($package) = @_;
 702
 703     # Cancel strict completely for the evaluated code, so the code
 704     # the user evaluates won't be affected by it. (Shlomi Fish)
 705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 706     . "package $package;";    # this won't let them modify, alas
 707 }
 708
 709 sub eval {
 710
 711     # 'my' would make it visible from user code
 712     #    but so does local! --tchrist
 713     # Remember: this localizes @DB::res, not @main::res.
 714     local @res;
 715     {
 716
 717         # Try to keep the user code from messing  with us. Save these so that
 718         # even if the eval'ed code changes them, we can put them back again.
 719         # Needed because the user could refer directly to the debugger's
 720         # package globals (and any 'my' variables in this containing scope)
 721         # inside the eval(), and we want to try to stay safe.
 722         local $otrace  = $trace;
 723         local $osingle = $single;
 724         local $od      = $^D;
 725
 726         # Untaint the incoming eval() argument.
 727         { ($evalarg) = $evalarg =~ /(.*)/s; }
 728
 729         # $usercontext built in DB::DB near the comment
 730         # "set up the context for DB::eval ..."
 731         # Evaluate and save any results.
 732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 733
 734         # Restore those old values.
 735         $trace  = $otrace;
 736         $single = $osingle;
 737         $^D     = $od;
 738     }
 739
 740     # Save the current value of $@, and preserve it in the debugger's copy
 741     # of the saved precious globals.
 742     my $at = $@;
 743
 744     # Since we're only saving $@, we only have to localize the array element
 745     # that it will be stored in.
 746     local $saved[0];    # Preserve the old value of $@
 747     eval { DB::save() };
 748
 749     # Now see whether we need to report an error back to the user.
 750     if ($at) {
 751         local $\ = '';
 752         print $OUT $at;
 753     }
 754
 755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 756     # are package globals.
 757     elsif ($onetimeDump) {
 758         if ( $onetimeDump eq 'dump' ) {
 759             local $option{dumpDepth} = $onetimedumpDepth
 760               if defined $onetimedumpDepth;
 761             dumpit( $OUT, \@res );
 762         }
 763         elsif ( $onetimeDump eq 'methods' ) {
 764             methods( $res[0] );
 765         }
 766     } ## end elsif ($onetimeDump)
 767     @res;
 768 } ## end sub eval
 769
 770 ############################################## End lexical danger zone
 771
 772 # After this point it is safe to introduce lexicals.
 773 # The code being debugged will be executing in its own context, and
 774 # can't see the inside of the debugger.
 775 #
 776 # However, one should not overdo it: leave as much control from outside as
 777 # possible. If you make something a lexical, it's not going to be addressable
 778 # from outside the debugger even if you know its name.
 779
 780 # This file is automatically included if you do perl -d.
 781 # It's probably not useful to include this yourself.
 782 #
 783 # Before venturing further into these twisty passages, it is
 784 # wise to read the perldebguts man page or risk the ire of dragons.
 785 #
 786 # (It should be noted that perldebguts will tell you a lot about
 787 # the underlying mechanics of how the debugger interfaces into the
 788 # Perl interpreter, but not a lot about the debugger itself. The new
 789 # comments in this code try to address this problem.)
 790
 791 # Note that no subroutine call is possible until &DB::sub is defined
 792 # (for subroutines defined outside of the package DB). In fact the same is
 793 # true if $deep is not defined.
 794
 795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 796
 797 # modified Perl debugger, to be run from Emacs in perldb-mode
 798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 799 # Johan Vromans -- upgrade to 4.0 pl 10
 800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 801 ########################################################################
 802
 803 =head1 DEBUGGER INITIALIZATION
 804
 805 The debugger starts up in phases.
 806
 807 =head2 BASIC SETUP
 808
 809 First, it initializes the environment it wants to run in: turning off
 810 warnings during its own compilation, defining variables which it will need
 811 to avoid warnings later, setting itself up to not exit when the program
 812 terminates, and defaulting to printing return values for the C<r> command.
 813
 814 =cut
 815
 816 # Needed for the statement after exec():
 817 #
 818 # This BEGIN block is simply used to switch off warnings during debugger
 819 # compilation. Probably it would be better practice to fix the warnings,
 820 # but this is how it's done at the moment.
 821
 822 BEGIN {
 823     $ini_warn = $^W;
 824     $^W       = 0;
 825 }    # Switch compilation warnings off until another BEGIN.
 826
 827 local ($^W) = 0;    # Switch run-time warnings off during init.
 828
 829 =head2 THREADS SUPPORT
 830
 831 If we are running under a threaded Perl, we require threads and threads::shared
 832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 833 threaded debugger control.  C<-dt> can also be used to set this.
 834
 835 Each new thread will be announced and the debugger prompt will always inform
 836 you of each new thread created.  It will also indicate the thread id in which
 837 we are currently running within the prompt like this:
 838
 839     [tid] DB<$i>
 840
 841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 842 command prompt.  The prompt will show: C<[0]> when running under threads, but
 843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 844
 845 While running under threads, when you set or delete a breakpoint (etc.), this
 846 will apply to all threads, not just the currently running one.  When you are
 847 in a currently executing thread, you will stay there until it completes.  With
 848 the current implementation it is not currently possible to hop from one thread
 849 to another.
 850
 851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 852
 853 Note that threading support was built into the debugger as of Perl version
 854 C<5.8.6> and debugger version C<1.2.8>.
 855
 856 =cut
 857
 858 BEGIN {
 859     # ensure we can share our non-threaded variables or no-op
 860     if ($ENV{PERL5DB_THREADED}) {
 861         require threads;
 862         require threads::shared;
 863         import threads::shared qw(share);
 864         $DBGR;
 865         share(\$DBGR);
 866         lock($DBGR);
 867         print "Threads support enabled\n";
 868     } else {
 869         *share = sub(\[$@%]) {};
 870     }
 871 }
 872
 873 # These variables control the execution of 'dumpvar.pl'.
 874 {
 875     package dumpvar;
 876     use vars qw(
 877     $hashDepth
 878     $arrayDepth
 879     $dumpDBFiles
 880     $dumpPackages
 881     $quoteHighBit
 882     $printUndef
 883     $globPrint
 884     $usageOnly
 885     );
 886 }
 887
 888 # used to control die() reporting in diesignal()
 889 {
 890     package Carp;
 891     use vars qw($CarpLevel);
 892 }
 893
 894 # without threads, $filename is not defined until DB::DB is called
 895 share($main::{'_<'.$filename}) if defined $filename;
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 our ($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(%postponed_file @typeahead);
1381
1382 our (@hist, @truehist);
1383
1384 sub _restore_shared_globals_after_restart
1385 {
1386     @hist          = get_list('PERLDB_HIST');
1387     %break_on_load = get_list("PERLDB_ON_LOAD");
1388     %postponed     = get_list("PERLDB_POSTPONE");
1389
1390     share(@hist);
1391     share(@truehist);
1392     share(%break_on_load);
1393     share(%postponed);
1394 }
1395
1396 sub _restore_breakpoints_and_actions {
1397
1398     my @had_breakpoints = get_list("PERLDB_VISITED");
1399
1400     for my $file_idx ( 0 .. $#had_breakpoints ) {
1401         my $filename = $had_breakpoints[$file_idx];
1402         my %pf = get_list("PERLDB_FILE_$file_idx");
1403         $postponed_file{ $filename } = \%pf if %pf;
1404         my @lines = sort {$a <=> $b} keys(%pf);
1405         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1406         for my $line_idx (0 .. $#lines) {
1407             _set_breakpoint_enabled_status(
1408                 $filename,
1409                 $lines[$line_idx],
1410                 ($enabled_statuses[$line_idx] ? 1 : ''),
1411             );
1412         }
1413     }
1414
1415     return;
1416 }
1417
1418 sub _restore_options_after_restart
1419 {
1420     my %options_map = get_list("PERLDB_OPT");
1421
1422     while ( my ( $opt, $val ) = each %options_map ) {
1423         $val =~ s/[\\\']/\\$1/g;
1424         parse_options("$opt'$val'");
1425     }
1426
1427     return;
1428 }
1429
1430 sub _restore_globals_after_restart
1431 {
1432     # restore original @INC
1433     @INC     = get_list("PERLDB_INC");
1434     @ini_INC = @INC;
1435
1436     # return pre/postprompt actions and typeahead buffer
1437     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1438     $pre       = [ get_list("PERLDB_PRE") ];
1439     $post      = [ get_list("PERLDB_POST") ];
1440     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1441
1442     return;
1443 }
1444
1445
1446 if ( exists $ENV{PERLDB_RESTART} ) {
1447
1448     # We're restarting, so we don't need the flag that says to restart anymore.
1449     delete $ENV{PERLDB_RESTART};
1450
1451     # $restart = 1;
1452     _restore_shared_globals_after_restart();
1453
1454     _restore_breakpoints_and_actions();
1455
1456     # restore options
1457     _restore_options_after_restart();
1458
1459     _restore_globals_after_restart();
1460 } ## end if (exists $ENV{PERLDB_RESTART...
1461
1462 =head2 SETTING UP THE TERMINAL
1463
1464 Now, we'll decide how the debugger is going to interact with the user.
1465 If there's no TTY, we set the debugger to run non-stop; there's not going
1466 to be anyone there to enter commands.
1467
1468 =cut
1469
1470 use vars qw($notty $console $tty $LINEINFO);
1471 use vars qw($lineinfo $doccmd);
1472
1473 our ($runnonstop);
1474
1475 # Local autoflush to avoid rt#116769,
1476 # as calling IO::File methods causes an unresolvable loop
1477 # that results in debugger failure.
1478 sub _autoflush {
1479     my $o = select($_[0]);
1480     $|++;
1481     select($o);
1482 }
1483
1484 if ($notty) {
1485     $runnonstop = 1;
1486     share($runnonstop);
1487 }
1488
1489 =pod
1490
1491 If there is a TTY, we have to determine who it belongs to before we can
1492 proceed. If this is a slave editor or graphical debugger (denoted by
1493 the first command-line switch being '-emacs'), we shift this off and
1494 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1495
1496 =cut
1497
1498 else {
1499
1500     # Is Perl being run from a slave editor or graphical debugger?
1501     # If so, don't use readline, and set $slave_editor = 1.
1502     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1503         $rl = 0;
1504         shift(@main::ARGV);
1505     }
1506
1507     #require Term::ReadLine;
1508
1509 =pod
1510
1511 We then determine what the console should be on various systems:
1512
1513 =over 4
1514
1515 =item * Cygwin - We use C<stdin> instead of a separate device.
1516
1517 =cut
1518
1519     if ( $^O eq 'cygwin' ) {
1520
1521         # /dev/tty is binary. use stdin for textmode
1522         undef $console;
1523     }
1524
1525 =item * Unix - use F</dev/tty>.
1526
1527 =cut
1528
1529     elsif ( -e "/dev/tty" ) {
1530         $console = "/dev/tty";
1531     }
1532
1533 =item * Windows or MSDOS - use C<con>.
1534
1535 =cut
1536
1537     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1538         $console = "con";
1539     }
1540
1541 =item * VMS - use C<sys$command>.
1542
1543 =cut
1544
1545     else {
1546
1547         # everything else is ...
1548         $console = "sys\$command";
1549     }
1550
1551 =pod
1552
1553 =back
1554
1555 Several other systems don't use a specific console. We C<undef $console>
1556 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1557 with a slave editor).
1558
1559 =cut
1560
1561     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1562
1563         # /dev/tty is binary. use stdin for textmode
1564         $console = undef;
1565     }
1566
1567     if ( $^O eq 'NetWare' ) {
1568
1569         # /dev/tty is binary. use stdin for textmode
1570         $console = undef;
1571     }
1572
1573     # In OS/2, we need to use STDIN to get textmode too, even though
1574     # it pretty much looks like Unix otherwise.
1575     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1576     {    # In OS/2
1577         $console = undef;
1578     }
1579
1580 =pod
1581
1582 If there is a TTY hanging around from a parent, we use that as the console.
1583
1584 =cut
1585
1586     $console = $tty if defined $tty;
1587
1588 =head2 SOCKET HANDLING
1589
1590 The debugger is capable of opening a socket and carrying out a debugging
1591 session over the socket.
1592
1593 If C<RemotePort> was defined in the options, the debugger assumes that it
1594 should try to start a debugging session on that port. It builds the socket
1595 and then tries to connect the input and output filehandles to it.
1596
1597 =cut
1598
1599     # Handle socket stuff.
1600
1601     if ( defined $remoteport ) {
1602
1603         # If RemotePort was defined in the options, connect input and output
1604         # to the socket.
1605         $IN = $OUT = connect_remoteport();
1606     } ## end if (defined $remoteport)
1607
1608 =pod
1609
1610 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1611 this is probably a situation where multiple debuggers are running (for example,
1612 a backticked command that starts up another debugger). We create a new IN and
1613 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1614 and if we can.
1615
1616 =cut
1617
1618     # Non-socket.
1619     else {
1620
1621         # Two debuggers running (probably a system or a backtick that invokes
1622         # the debugger itself under the running one). create a new IN and OUT
1623         # filehandle, and do the necessary mojo to create a new tty if we
1624         # know how, and we can.
1625         create_IN_OUT(4) if $CreateTTY & 4;
1626         if ($console) {
1627
1628             # If we have a console, check to see if there are separate ins and
1629             # outs to open. (They are assumed identical if not.)
1630
1631             my ( $i, $o ) = split /,/, $console;
1632             $o = $i unless defined $o;
1633
1634             # read/write on in, or just read, or read on STDIN.
1635             open( IN,      "+<$i" )
1636               || open( IN, "<$i" )
1637               || open( IN, "<&STDIN" );
1638
1639             # read/write/create/clobber out, or write/create/clobber out,
1640             # or merge with STDERR, or merge with STDOUT.
1641                  open( OUT, "+>$o" )
1642               || open( OUT, ">$o" )
1643               || open( OUT, ">&STDERR" )
1644               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1645
1646         } ## end if ($console)
1647         elsif ( not defined $console ) {
1648
1649             # No console. Open STDIN.
1650             open( IN, "<&STDIN" );
1651
1652             # merge with STDERR, or with STDOUT.
1653             open( OUT,      ">&STDERR" )
1654               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1655             $console = 'STDIN/OUT';
1656         } ## end elsif (not defined $console)
1657
1658         # Keep copies of the filehandles so that when the pager runs, it
1659         # can close standard input without clobbering ours.
1660         if ($console or (not defined($console))) {
1661             $IN = \*IN;
1662             $OUT = \*OUT;
1663         }
1664     } ## end elsif (from if(defined $remoteport))
1665
1666     # Unbuffer DB::OUT. We need to see responses right away.
1667     _autoflush($OUT);
1668
1669     # Line info goes to debugger output unless pointed elsewhere.
1670     # Pointing elsewhere makes it possible for slave editors to
1671     # keep track of file and position. We have both a filehandle
1672     # and a I/O description to keep track of.
1673     $LINEINFO = $OUT     unless defined $LINEINFO;
1674     $lineinfo = $console unless defined $lineinfo;
1675     # share($LINEINFO); # <- unable to share globs
1676     share($lineinfo);   #
1677
1678 =pod
1679
1680 To finish initialization, we show the debugger greeting,
1681 and then call the C<afterinit()> subroutine if there is one.
1682
1683 =cut
1684
1685     # Show the debugger greeting.
1686     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1687     unless ($runnonstop) {
1688         local $\ = '';
1689         local $, = '';
1690         if ( $term_pid eq '-1' ) {
1691             print $OUT "\nDaughter DB session started...\n";
1692         }
1693         else {
1694             print $OUT "\nLoading DB routines from $header\n";
1695             print $OUT (
1696                 "Editor support ",
1697                 $slave_editor ? "enabled" : "available", ".\n"
1698             );
1699             print $OUT
1700 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1701         } ## end else [ if ($term_pid eq '-1')
1702     } ## end unless ($runnonstop)
1703 } ## end else [ if ($notty)
1704
1705 # XXX This looks like a bug to me.
1706 # Why copy to @ARGS and then futz with @args?
1707 @ARGS = @ARGV;
1708 # for (@args) {
1709     # Make sure backslashes before single quotes are stripped out, and
1710     # keep args unless they are numeric (XXX why?)
1711     # s/\'/\\\'/g;                      # removed while not justified understandably
1712     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1713 # }
1714
1715 # If there was an afterinit() sub defined, call it. It will get
1716 # executed in our scope, so it can fiddle with debugger globals.
1717 if ( defined &afterinit ) {    # May be defined in $rcfile
1718     afterinit();
1719 }
1720
1721 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1722 use vars qw($I_m_init);
1723
1724 $I_m_init = 1;
1725
1726 ############################################################ Subroutines
1727
1728 =head1 SUBROUTINES
1729
1730 =head2 DB
1731
1732 This gigantic subroutine is the heart of the debugger. Called before every
1733 statement, its job is to determine if a breakpoint has been reached, and
1734 stop if so; read commands from the user, parse them, and execute
1735 them, and then send execution off to the next statement.
1736
1737 Note that the order in which the commands are processed is very important;
1738 some commands earlier in the loop will actually alter the C<$cmd> variable
1739 to create other commands to be executed later. This is all highly I<optimized>
1740 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1741 see what's happening in any given command.
1742
1743 =cut
1744
1745 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1746
1747 use vars qw(
1748     $action
1749     $cmd
1750     $file
1751     $filename_ini
1752     $finished
1753     %had_breakpoints
1754     $level
1755     $max
1756     $package
1757     $try
1758 );
1759
1760 our (
1761     %alias,
1762     $doret,
1763     $end,
1764     $fall_off_end,
1765     $incr,
1766     $laststep,
1767     $rc,
1768     $sh,
1769     $stack_depth,
1770     @stack,
1771     @to_watch,
1772     @old_watch,
1773 );
1774
1775 sub _DB__determine_if_we_should_break
1776 {
1777     # if we have something here, see if we should break.
1778     # $stop is lexical and local to this block - $action on the other hand
1779     # is global.
1780     my $stop;
1781
1782     if ( $dbline{$line}
1783         && _is_breakpoint_enabled($filename, $line)
1784         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1785     {
1786
1787         # Stop if the stop criterion says to just stop.
1788         if ( $stop eq '1' ) {
1789             $signal |= 1;
1790         }
1791
1792         # It's a conditional stop; eval it in the user's context and
1793         # see if we should stop. If so, remove the one-time sigil.
1794         elsif ($stop) {
1795             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1796             DB::eval();
1797             # If the breakpoint is temporary, then delete its enabled status.
1798             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1799                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1800             }
1801         }
1802     } ## end if ($dbline{$line} && ...
1803 }
1804
1805 sub _DB__is_finished {
1806     if ($finished and $level <= 1) {
1807         end_report();
1808         return 1;
1809     }
1810     else {
1811         return;
1812     }
1813 }
1814
1815 sub _DB__read_next_cmd
1816 {
1817     my ($tid) = @_;
1818
1819     # We have a terminal, or can get one ...
1820     if (!$term) {
1821         setterm();
1822     }
1823
1824     # ... and it belongs to this PID or we get one for this PID ...
1825     if ($term_pid != $$) {
1826         resetterm(1);
1827     }
1828
1829     # ... and we got a line of command input ...
1830     $cmd = DB::readline(
1831         "$pidprompt $tid DB"
1832         . ( '<' x $level )
1833         . ( $#hist + 1 )
1834         . ( '>' x $level ) . " "
1835     );
1836
1837     return defined($cmd);
1838 }
1839
1840 sub _DB__trim_command_and_return_first_component {
1841     my ($obj) = @_;
1842
1843     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1844     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1845
1846     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1847
1848     $obj->cmd_verb($verb);
1849     $obj->cmd_args($args);
1850
1851     return;
1852 }
1853
1854 sub _DB__handle_f_command {
1855     my ($obj) = @_;
1856
1857     if ($file = $obj->cmd_args) {
1858         # help for no arguments (old-style was return from sub).
1859         if ( !$file ) {
1860             print $OUT
1861             "The old f command is now the r command.\n";    # hint
1862             print $OUT "The new f command switches filenames.\n";
1863             next CMD;
1864         } ## end if (!$file)
1865
1866         # if not in magic file list, try a close match.
1867         if ( !defined $main::{ '_<' . $file } ) {
1868             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1869                 {
1870                     $try = substr( $try, 2 );
1871                     print $OUT "Choosing $try matching '$file':\n";
1872                     $file = $try;
1873                 }
1874             } ## end if (($try) = grep(m#^_<.*$file#...
1875         } ## end if (!defined $main::{ ...
1876
1877         # If not successfully switched now, we failed.
1878         if ( !defined $main::{ '_<' . $file } ) {
1879             print $OUT "No file matching '$file' is loaded.\n";
1880             next CMD;
1881         }
1882
1883         # We switched, so switch the debugger internals around.
1884         elsif ( $file ne $filename ) {
1885             *dbline   = $main::{ '_<' . $file };
1886             $max      = $#dbline;
1887             $filename = $file;
1888             $start    = 1;
1889             $cmd      = "l";
1890         } ## end elsif ($file ne $filename)
1891
1892         # We didn't switch; say we didn't.
1893         else {
1894             print $OUT "Already in $file.\n";
1895             next CMD;
1896         }
1897     }
1898
1899     return;
1900 }
1901
1902 sub _DB__handle_dot_command {
1903     my ($obj) = @_;
1904
1905     # . command.
1906     if ($obj->_is_full('.')) {
1907         $incr = -1;    # stay at current line
1908
1909         # Reset everything to the old location.
1910         $start    = $line;
1911         $filename = $filename_ini;
1912         *dbline   = $main::{ '_<' . $filename };
1913         $max      = $#dbline;
1914
1915         # Now where are we?
1916         print_lineinfo($obj->position());
1917         next CMD;
1918     }
1919
1920     return;
1921 }
1922
1923 sub _DB__handle_y_command {
1924     my ($obj) = @_;
1925
1926     if (my ($match_level, $match_vars)
1927         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1928
1929         # See if we've got the necessary support.
1930         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1931             my $Err = $@;
1932             _db_warn(
1933                 $Err =~ /locate/
1934                 ? "PadWalker module not found - please install\n"
1935                 : $Err
1936             );
1937             next CMD;
1938         }
1939
1940         # Load up dumpvar if we don't have it. If we can, that is.
1941         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1942         defined &main::dumpvar
1943             or print $OUT "dumpvar.pl not available.\n"
1944             and next CMD;
1945
1946         # Got all the modules we need. Find them and print them.
1947         my @vars = split( ' ', $match_vars || '' );
1948
1949         # Find the pad.
1950         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1951
1952         # Oops. Can't find it.
1953         if (my $Err = $@) {
1954             $Err =~ s/ at .*//;
1955             _db_warn($Err);
1956             next CMD;
1957         }
1958
1959         # Show the desired vars with dumplex().
1960         my $savout = select($OUT);
1961
1962         # Have dumplex dump the lexicals.
1963         foreach my $key (sort keys %$h) {
1964             dumpvar::dumplex( $key, $h->{$key},
1965                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1966                 @vars );
1967         }
1968         select($savout);
1969         next CMD;
1970     }
1971 }
1972
1973 sub _DB__handle_c_command {
1974     my ($obj) = @_;
1975
1976     my $i = $obj->cmd_args;
1977
1978     if ($i =~ m#\A[\w:]*\z#) {
1979
1980         # Hey, show's over. The debugged program finished
1981         # executing already.
1982         next CMD if _DB__is_finished();
1983
1984         # Capture the place to put a one-time break.
1985         $subname = $i;
1986
1987         #  Probably not needed, since we finish an interactive
1988         #  sub-session anyway...
1989         # local $filename = $filename;
1990         # local *dbline = *dbline; # XXX Would this work?!
1991         #
1992         # The above question wonders if localizing the alias
1993         # to the magic array works or not. Since it's commented
1994         # out, we'll just leave that to speculation for now.
1995
1996         # If the "subname" isn't all digits, we'll assume it
1997         # is a subroutine name, and try to find it.
1998         if ( $subname =~ /\D/ ) {    # subroutine name
1999             # Qualify it to the current package unless it's
2000             # already qualified.
2001             $subname = $package . "::" . $subname
2002             unless $subname =~ /::/;
2003
2004             # find_sub will return "file:line_number" corresponding
2005             # to where the subroutine is defined; we call find_sub,
2006             # break up the return value, and assign it in one
2007             # operation.
2008             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2009
2010             # Force the line number to be numeric.
2011             $i = $i + 0;
2012
2013             # If we got a line number, we found the sub.
2014             if ($i) {
2015
2016                 # Switch all the debugger's internals around so
2017                 # we're actually working with that file.
2018                 $filename = $file;
2019                 *dbline   = $main::{ '_<' . $filename };
2020
2021                 # Mark that there's a breakpoint in this file.
2022                 $had_breakpoints{$filename} |= 1;
2023
2024                 # Scan forward to the first executable line
2025                 # after the 'sub whatever' line.
2026                 $max = $#dbline;
2027                 my $_line_num = $i;
2028                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2029                 {
2030                     $_line_num++;
2031                 }
2032                 $i = $_line_num;
2033             } ## end if ($i)
2034
2035             # We didn't find a sub by that name.
2036             else {
2037                 print $OUT "Subroutine $subname not found.\n";
2038                 next CMD;
2039             }
2040         } ## end if ($subname =~ /\D/)
2041
2042         # At this point, either the subname was all digits (an
2043         # absolute line-break request) or we've scanned through
2044         # the code following the definition of the sub, looking
2045         # for an executable, which we may or may not have found.
2046         #
2047         # If $i (which we set $subname from) is non-zero, we
2048         # got a request to break at some line somewhere. On
2049         # one hand, if there wasn't any real subroutine name
2050         # involved, this will be a request to break in the current
2051         # file at the specified line, so we have to check to make
2052         # sure that the line specified really is breakable.
2053         #
2054         # On the other hand, if there was a subname supplied, the
2055         # preceding block has moved us to the proper file and
2056         # location within that file, and then scanned forward
2057         # looking for the next executable line. We have to make
2058         # sure that one was found.
2059         #
2060         # On the gripping hand, we can't do anything unless the
2061         # current value of $i points to a valid breakable line.
2062         # Check that.
2063         if ($i) {
2064
2065             # Breakable?
2066             if ( $dbline[$i] == 0 ) {
2067                 print $OUT "Line $i not breakable.\n";
2068                 next CMD;
2069             }
2070
2071             # Yes. Set up the one-time-break sigil.
2072             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2073             _enable_breakpoint_temp_enabled_status($filename, $i);
2074         } ## end if ($i)
2075
2076         # Turn off stack tracing from here up.
2077         for my $j (0 .. $stack_depth) {
2078             $stack[ $j ] &= ~1;
2079         }
2080         last CMD;
2081     }
2082
2083     return;
2084 }
2085
2086 sub _DB__handle_forward_slash_command {
2087     my ($obj) = @_;
2088
2089     # The pattern as a string.
2090     use vars qw($inpat);
2091
2092     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2093
2094         # Remove the final slash.
2095         $inpat =~ s:([^\\])/$:$1:;
2096
2097         # If the pattern isn't null ...
2098         if ( $inpat ne "" ) {
2099
2100             # Turn off warn and die processing for a bit.
2101             local $SIG{__DIE__};
2102             local $SIG{__WARN__};
2103
2104             # Create the pattern.
2105             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2106             if ( $@ ne "" ) {
2107
2108                 # Oops. Bad pattern. No biscuit.
2109                 # Print the eval error and go back for more
2110                 # commands.
2111                 print {$OUT} "$@";
2112                 next CMD;
2113             }
2114             $obj->pat($inpat);
2115         } ## end if ($inpat ne "")
2116
2117         # Set up to stop on wrap-around.
2118         $end = $start;
2119
2120         # Don't move off the current line.
2121         $incr = -1;
2122
2123         my $pat = $obj->pat;
2124
2125         # Done in eval so nothing breaks if the pattern
2126         # does something weird.
2127         eval
2128         {
2129             no strict q/vars/;
2130             for (;;) {
2131                 # Move ahead one line.
2132                 ++$start;
2133
2134                 # Wrap if we pass the last line.
2135                 if ($start > $max) {
2136                     $start = 1;
2137                 }
2138
2139                 # Stop if we have gotten back to this line again,
2140                 last if ($start == $end);
2141
2142                 # A hit! (Note, though, that we are doing
2143                 # case-insensitive matching. Maybe a qr//
2144                 # expression would be better, so the user could
2145                 # do case-sensitive matching if desired.
2146                 if ($dbline[$start] =~ m/$pat/i) {
2147                     if ($slave_editor) {
2148                         # Handle proper escaping in the slave.
2149                         print {$OUT} "\032\032$filename:$start:0\n";
2150                     }
2151                     else {
2152                         # Just print the line normally.
2153                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2154                     }
2155                     # And quit since we found something.
2156                     last;
2157                 }
2158             }
2159         };
2160
2161         if ($@) {
2162             warn $@;
2163         }
2164
2165         # If we wrapped, there never was a match.
2166         if ( $start == $end ) {
2167             print {$OUT} "/$pat/: not found\n";
2168         }
2169         next CMD;
2170     }
2171
2172     return;
2173 }
2174
2175 sub _DB__handle_question_mark_command {
2176     my ($obj) = @_;
2177
2178     # ? - backward pattern search.
2179     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2180
2181         # Get the pattern, remove trailing question mark.
2182         $inpat =~ s:([^\\])\?$:$1:;
2183
2184         # If we've got one ...
2185         if ( $inpat ne "" ) {
2186
2187             # Turn off die & warn handlers.
2188             local $SIG{__DIE__};
2189             local $SIG{__WARN__};
2190             eval '$inpat =~ m' . "\a$inpat\a";
2191
2192             if ( $@ ne "" ) {
2193
2194                 # Ouch. Not good. Print the error.
2195                 print $OUT $@;
2196                 next CMD;
2197             }
2198             $obj->pat($inpat);
2199         } ## end if ($inpat ne "")
2200
2201         # Where we are now is where to stop after wraparound.
2202         $end = $start;
2203
2204         # Don't move away from this line.
2205         $incr = -1;
2206
2207         my $pat = $obj->pat;
2208         # Search inside the eval to prevent pattern badness
2209         # from killing us.
2210         eval {
2211             no strict q/vars/;
2212             for (;;) {
2213                 # Back up a line.
2214                 --$start;
2215
2216                 # Wrap if we pass the first line.
2217
2218                 $start = $max if ($start <= 0);
2219
2220                 # Quit if we get back where we started,
2221                 last if ($start == $end);
2222
2223                 # Match?
2224                 if ($dbline[$start] =~ m/$pat/i) {
2225                     if ($slave_editor) {
2226                         # Yep, follow slave editor requirements.
2227                         print $OUT "\032\032$filename:$start:0\n";
2228                     }
2229                     else {
2230                         # Yep, just print normally.
2231                         print $OUT "$start:\t",$dbline[$start],"\n";
2232                     }
2233
2234                     # Found, so done.
2235                     last;
2236                 }
2237             }
2238         };
2239
2240         # Say we failed if the loop never found anything,
2241         if ( $start == $end ) {
2242             print {$OUT} "?$pat?: not found\n";
2243         }
2244         next CMD;
2245     }
2246
2247     return;
2248 }
2249
2250 sub _DB__handle_restart_and_rerun_commands {
2251     my ($obj) = @_;
2252
2253     my $cmd_cmd = $obj->cmd_verb;
2254     my $cmd_params = $obj->cmd_args;
2255     # R - restart execution.
2256     # rerun - controlled restart execution.
2257     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2258         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2259
2260         # Close all non-system fds for a clean restart.  A more
2261         # correct method would be to close all fds that were not
2262         # open when the process started, but this seems to be
2263         # hard.  See "debugger 'R'estart and open database
2264         # connections" on p5p.
2265
2266         my $max_fd = 1024; # default if POSIX can't be loaded
2267         if (eval { require POSIX }) {
2268             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2269         }
2270
2271         if (defined $max_fd) {
2272             foreach ($^F+1 .. $max_fd-1) {
2273                 next unless open FD_TO_CLOSE, "<&=$_";
2274                 close(FD_TO_CLOSE);
2275             }
2276         }
2277
2278         # And run Perl again.  We use exec() to keep the
2279         # PID stable (and that way $ini_pids is still valid).
2280         exec(@args) or print {$OUT} "exec failed: $!\n";
2281
2282         last CMD;
2283     }
2284
2285     return;
2286 }
2287
2288 sub _DB__handle_run_command_in_pager_command {
2289     my ($obj) = @_;
2290
2291     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2292         if ( $pager =~ /^\|/ ) {
2293
2294             # Default pager is into a pipe. Redirect I/O.
2295             open( SAVEOUT, ">&STDOUT" )
2296             || _db_warn("Can't save STDOUT");
2297             open( STDOUT, ">&OUT" )
2298             || _db_warn("Can't redirect STDOUT");
2299         } ## end if ($pager =~ /^\|/)
2300         else {
2301
2302             # Not into a pipe. STDOUT is safe.
2303             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2304         }
2305
2306         # Fix up environment to record we have less if so.
2307         fix_less();
2308
2309         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2310
2311             # Couldn't open pipe to pager.
2312             _db_warn("Can't pipe output to '$pager'");
2313             if ( $pager =~ /^\|/ ) {
2314
2315                 # Redirect I/O back again.
2316                 open( OUT, ">&STDOUT" )    # XXX: lost message
2317                 || _db_warn("Can't restore DB::OUT");
2318                 open( STDOUT, ">&SAVEOUT" )
2319                 || _db_warn("Can't restore STDOUT");
2320                 close(SAVEOUT);
2321             } ## end if ($pager =~ /^\|/)
2322             else {
2323
2324                 # Redirect I/O. STDOUT already safe.
2325                 open( OUT, ">&STDOUT" )    # XXX: lost message
2326                 || _db_warn("Can't restore DB::OUT");
2327             }
2328             next CMD;
2329         } ## end unless ($piped = open(OUT,...
2330
2331         # Set up broken-pipe handler if necessary.
2332         $SIG{PIPE} = \&DB::catch
2333         if $pager =~ /^\|/
2334         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2335
2336         _autoflush(\*OUT);
2337         # Save current filehandle, and put it back.
2338         $obj->selected(scalar( select(OUT) ));
2339         # Don't put it back if pager was a pipe.
2340         if ($cmd !~ /\A\|\|/)
2341         {
2342             select($obj->selected());
2343             $obj->selected("");
2344         }
2345
2346         # Trim off the pipe symbols and run the command now.
2347         $cmd =~ s#\A\|+\s*##;
2348         redo PIPE;
2349     }
2350
2351     return;
2352 }
2353
2354 sub _DB__handle_m_command {
2355     my ($obj) = @_;
2356
2357     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2358         methods($1);
2359         next CMD;
2360     }
2361
2362     # m expr - set up DB::eval to do the work
2363     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2364         $onetimeDump = 'methods';   #  method output gets used there
2365     }
2366
2367     return;
2368 }
2369
2370 sub _DB__at_end_of_every_command {
2371     my ($obj) = @_;
2372
2373     # At the end of every command:
2374     if ($obj->piped) {
2375
2376         # Unhook the pipe mechanism now.
2377         if ( $pager =~ /^\|/ ) {
2378
2379             # No error from the child.
2380             $? = 0;
2381
2382             # we cannot warn here: the handle is missing --tchrist
2383             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2384
2385             # most of the $? crud was coping with broken cshisms
2386             # $? is explicitly set to 0, so this never runs.
2387             if ($?) {
2388                 print SAVEOUT "Pager '$pager' failed: ";
2389                 if ( $? == -1 ) {
2390                     print SAVEOUT "shell returned -1\n";
2391                 }
2392                 elsif ( $? >> 8 ) {
2393                     print SAVEOUT ( $? & 127 )
2394                     ? " (SIG#" . ( $? & 127 ) . ")"
2395                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2396                 }
2397                 else {
2398                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2399                 }
2400             } ## end if ($?)
2401
2402             # Reopen filehandle for our output (if we can) and
2403             # restore STDOUT (if we can).
2404             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2405             open( STDOUT, ">&SAVEOUT" )
2406             || _db_warn("Can't restore STDOUT");
2407
2408             # Turn off pipe exception handler if necessary.
2409             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2410
2411             # Will stop ignoring SIGPIPE if done like nohup(1)
2412             # does SIGINT but Perl doesn't give us a choice.
2413         } ## end if ($pager =~ /^\|/)
2414         else {
2415
2416             # Non-piped "pager". Just restore STDOUT.
2417             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2418         }
2419
2420         # Close filehandle pager was using, restore the normal one
2421         # if necessary,
2422         close(SAVEOUT);
2423
2424         if ($obj->selected() ne "") {
2425             select($obj->selected);
2426             $obj->selected("");
2427         }
2428
2429         # No pipes now.
2430         $obj->piped("");
2431     } ## end if ($piped)
2432
2433     return;
2434 }
2435
2436 sub _DB__handle_watch_expressions
2437 {
2438     my $self = shift;
2439
2440     if ( $DB::trace & 2 ) {
2441         for my $n (0 .. $#DB::to_watch) {
2442             $DB::evalarg = $DB::to_watch[$n];
2443             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2444
2445             # Fix context DB::eval() wants to return an array, but
2446             # we need a scalar here.
2447             my ($val) = join( "', '", DB::eval(@_) );
2448             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2449
2450             # Did it change?
2451             if ( $val ne $DB::old_watch[$n] ) {
2452
2453                 # Yep! Show the difference, and fake an interrupt.
2454                 $DB::signal = 1;
2455                 print {$DB::OUT} <<EOP;
2456 Watchpoint $n:\t$DB::to_watch[$n] changed:
2457     old value:\t$DB::old_watch[$n]
2458     new value:\t$val
2459 EOP
2460                 $DB::old_watch[$n] = $val;
2461             } ## end if ($val ne $old_watch...
2462         } ## end for my $n (0 ..
2463     } ## end if ($trace & 2)
2464
2465     return;
2466 }
2467
2468 # 't' is type.
2469 # 'm' is method.
2470 # 'v' is the value (i.e: method name or subroutine ref).
2471 # 's' is subroutine.
2472 my %cmd_lookup =
2473 (
2474     '-' => { t => 'm', v => '_handle_dash_command', },
2475     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2476     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2477     'H' => { t => 'm', v => '_handle_H_command', },
2478     'S' => { t => 'm', v => '_handle_S_command', },
2479     'T' => { t => 'm', v => '_handle_T_command', },
2480     'W' => { t => 'm', v => '_handle_W_command', },
2481     'c' => { t => 's', v => \&_DB__handle_c_command, },
2482     'f' => { t => 's', v => \&_DB__handle_f_command, },
2483     'm' => { t => 's', v => \&_DB__handle_m_command, },
2484     'n' => { t => 'm', v => '_handle_n_command', },
2485     'p' => { t => 'm', v => '_handle_p_command', },
2486     'q' => { t => 'm', v => '_handle_q_command', },
2487     'r' => { t => 'm', v => '_handle_r_command', },
2488     's' => { t => 'm', v => '_handle_s_command', },
2489     'save' => { t => 'm', v => '_handle_save_command', },
2490     'source' => { t => 'm', v => '_handle_source_command', },
2491     't' => { t => 'm', v => '_handle_t_command', },
2492     'w' => { t => 'm', v => '_handle_w_command', },
2493     'x' => { t => 'm', v => '_handle_x_command', },
2494     'y' => { t => 's', v => \&_DB__handle_y_command, },
2495     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2496         ('X', 'V')),
2497     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2498         qw(enable disable)),
2499     (map { $_ =>
2500         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2501         } qw(R rerun)),
2502     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2503         qw(a A b B e E h i l L M o O v w W)),
2504 );
2505
2506 sub DB {
2507
2508     # lock the debugger and get the thread id for the prompt
2509     lock($DBGR);
2510     my $tid;
2511     my $position;
2512     my ($prefix, $after, $infix);
2513     my $pat;
2514     my $explicit_stop;
2515     my $piped;
2516     my $selected;
2517
2518     if ($ENV{PERL5DB_THREADED}) {
2519         $tid = eval { "[".threads->tid."]" };
2520     }
2521
2522     my $cmd_verb;
2523     my $cmd_args;
2524
2525     my $obj = DB::Obj->new(
2526         {
2527             position => \$position,
2528             prefix => \$prefix,
2529             after => \$after,
2530             explicit_stop => \$explicit_stop,
2531             infix => \$infix,
2532             cmd_args => \$cmd_args,
2533             cmd_verb => \$cmd_verb,
2534             pat => \$pat,
2535             piped => \$piped,
2536             selected => \$selected,
2537         },
2538     );
2539
2540     $obj->_DB_on_init__initialize_globals(@_);
2541
2542     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2543     # The code being debugged may have altered them.
2544     DB::save();
2545
2546     # Since DB::DB gets called after every line, we can use caller() to
2547     # figure out where we last were executing. Sneaky, eh? This works because
2548     # caller is returning all the extra information when called from the
2549     # debugger.
2550     local ( $package, $filename, $line ) = caller;
2551     $filename_ini = $filename;
2552
2553     # set up the context for DB::eval, so it can properly execute
2554     # code on behalf of the user. We add the package in so that the
2555     # code is eval'ed in the proper package (not in the debugger!).
2556     local $usercontext = _calc_usercontext($package);
2557
2558     # Create an alias to the active file magical array to simplify
2559     # the code here.
2560     local (*dbline) = $main::{ '_<' . $filename };
2561
2562     # Last line in the program.
2563     $max = $#dbline;
2564
2565     _DB__determine_if_we_should_break(@_);
2566
2567     # Preserve the current stop-or-not, and see if any of the W
2568     # (watch expressions) has changed.
2569     my $was_signal = $signal;
2570
2571     # If we have any watch expressions ...
2572     _DB__handle_watch_expressions($obj);
2573
2574 =head2 C<watchfunction()>
2575
2576 C<watchfunction()> is a function that can be defined by the user; it is a
2577 function which will be run on each entry to C<DB::DB>; it gets the
2578 current package, filename, and line as its parameters.
2579
2580 The watchfunction can do anything it likes; it is executing in the
2581 debugger's context, so it has access to all of the debugger's internal
2582 data structures and functions.
2583
2584 C<watchfunction()> can control the debugger's actions. Any of the following
2585 will cause the debugger to return control to the user's program after
2586 C<watchfunction()> executes:
2587
2588 =over 4
2589
2590 =item *
2591
2592 Returning a false value from the C<watchfunction()> itself.
2593
2594 =item *
2595
2596 Altering C<$single> to a false value.
2597
2598 =item *
2599
2600 Altering C<$signal> to a false value.
2601
2602 =item *
2603
2604 Turning off the C<4> bit in C<$trace> (this also disables the
2605 check for C<watchfunction()>. This can be done with
2606
2607     $trace &= ~4;
2608
2609 =back
2610
2611 =cut
2612
2613     # If there's a user-defined DB::watchfunction, call it with the
2614     # current package, filename, and line. The function executes in
2615     # the DB:: package.
2616     if ( $trace & 4 ) {    # User-installed watch
2617         return
2618           if watchfunction( $package, $filename, $line )
2619           and not $single
2620           and not $was_signal
2621           and not( $trace & ~4 );
2622     } ## end if ($trace & 4)
2623
2624     # Pick up any alteration to $signal in the watchfunction, and
2625     # turn off the signal now.
2626     $was_signal = $signal;
2627     $signal     = 0;
2628
2629 =head2 GETTING READY TO EXECUTE COMMANDS
2630
2631 The debugger decides to take control if single-step mode is on, the
2632 C<t> command was entered, or the user generated a signal. If the program
2633 has fallen off the end, we set things up so that entering further commands
2634 won't cause trouble, and we say that the program is over.
2635
2636 =cut
2637
2638     # Make sure that we always print if asked for explicitly regardless
2639     # of $trace_to_depth .
2640     $explicit_stop = ($single || $was_signal);
2641
2642     # Check to see if we should grab control ($single true,
2643     # trace set appropriately, or we got a signal).
2644     if ( $explicit_stop || ( $trace & 1 ) ) {
2645         $obj->_DB__grab_control(@_);
2646     } ## end if ($single || ($trace...
2647
2648 =pod
2649
2650 If there's an action to be executed for the line we stopped at, execute it.
2651 If there are any preprompt actions, execute those as well.
2652
2653 =cut
2654
2655     # If there's an action, do it now.
2656     if ($action) {
2657         $evalarg = $action;
2658         DB::eval();
2659     }
2660
2661     # Are we nested another level (e.g., did we evaluate a function
2662     # that had a breakpoint in it at the debugger prompt)?
2663     if ( $single || $was_signal ) {
2664
2665         # Yes, go down a level.
2666         local $level = $level + 1;
2667
2668         # Do any pre-prompt actions.
2669         foreach $evalarg (@$pre) {
2670             DB::eval();
2671         }
2672
2673         # Complain about too much recursion if we passed the limit.
2674         if ($single & 4) {
2675             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2676         }
2677
2678         # The line we're currently on. Set $incr to -1 to stay here
2679         # until we get a command that tells us to advance.
2680         $start = $line;
2681         $incr  = -1;      # for backward motion.
2682
2683         # Tack preprompt debugger actions ahead of any actual input.
2684         @typeahead = ( @$pretype, @typeahead );
2685
2686 =head2 WHERE ARE WE?
2687
2688 XXX Relocate this section?
2689
2690 The debugger normally shows the line corresponding to the current line of
2691 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2692 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2693
2694 C<$incr> controls by how many lines the I<current> line should move forward
2695 after a command is executed. If set to -1, this indicates that the I<current>
2696 line shouldn't change.
2697
2698 C<$start> is the I<current> line. It is used for things like knowing where to
2699 move forwards or backwards from when doing an C<L> or C<-> command.
2700
2701 C<$max> tells the debugger where the last line of the current file is. It's
2702 used to terminate loops most often.
2703
2704 =head2 THE COMMAND LOOP
2705
2706 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2707 in two parts:
2708
2709 =over 4
2710
2711 =item *
2712
2713 The outer part of the loop, starting at the C<CMD> label. This loop
2714 reads a command and then executes it.
2715
2716 =item *
2717
2718 The inner part of the loop, starting at the C<PIPE> label. This part
2719 is wholly contained inside the C<CMD> block and only executes a command.
2720 Used to handle commands running inside a pager.
2721
2722 =back
2723
2724 So why have two labels to restart the loop? Because sometimes, it's easier to
2725 have a command I<generate> another command and then re-execute the loop to do
2726 the new command. This is faster, but perhaps a bit more convoluted.
2727
2728 =cut
2729
2730         # The big command dispatch loop. It keeps running until the
2731         # user yields up control again.
2732         #
2733         # If we have a terminal for input, and we get something back
2734         # from readline(), keep on processing.
2735
2736       CMD:
2737         while (_DB__read_next_cmd($tid))
2738         {
2739
2740             share($cmd);
2741             # ... try to execute the input as debugger commands.
2742
2743             # Don't stop running.
2744             $single = 0;
2745
2746             # No signal is active.
2747             $signal = 0;
2748
2749             # Handle continued commands (ending with \):
2750             if ($cmd =~ s/\\\z/\n/) {
2751                 $cmd .= DB::readline("  cont: ");
2752                 redo CMD;
2753             }
2754
2755 =head4 The null command
2756
2757 A newline entered by itself means I<re-execute the last command>. We grab the
2758 command out of C<$laststep> (where it was recorded previously), and copy it
2759 back into C<$cmd> to be executed below. If there wasn't any previous command,
2760 we'll do nothing below (no command will match). If there was, we also save it
2761 in the command history and fall through to allow the command parsing to pick
2762 it up.
2763
2764 =cut
2765
2766             # Empty input means repeat the last command.
2767             if ($cmd eq '') {
2768                 $cmd = $laststep;
2769             }
2770             chomp($cmd);    # get rid of the annoying extra newline
2771             if (length($cmd) >= 2) {
2772                 push( @hist, $cmd );
2773             }
2774             push( @truehist, $cmd );
2775             share(@hist);
2776             share(@truehist);
2777
2778             # This is a restart point for commands that didn't arrive
2779             # via direct user input. It allows us to 'redo PIPE' to
2780             # re-execute command processing without reading a new command.
2781           PIPE: {
2782                 _DB__trim_command_and_return_first_component($obj);
2783
2784 =head3 COMMAND ALIASES
2785
2786 The debugger can create aliases for commands (these are stored in the
2787 C<%alias> hash). Before a command is executed, the command loop looks it up
2788 in the alias hash and substitutes the contents of the alias for the command,
2789 completely replacing it.
2790
2791 =cut
2792
2793                 # See if there's an alias for the command, and set it up if so.
2794                 if ( $alias{$cmd_verb} ) {
2795
2796                     # Squelch signal handling; we want to keep control here
2797                     # if something goes loco during the alias eval.
2798                     local $SIG{__DIE__};
2799                     local $SIG{__WARN__};
2800
2801                     # This is a command, so we eval it in the DEBUGGER's
2802                     # scope! Otherwise, we can't see the special debugger
2803                     # variables, or get to the debugger's subs. (Well, we
2804                     # _could_, but why make it even more complicated?)
2805                     eval "\$cmd =~ $alias{$cmd_verb}";
2806                     if ($@) {
2807                         local $\ = '';
2808                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2809                         next CMD;
2810                     }
2811                     _DB__trim_command_and_return_first_component($obj);
2812                 } ## end if ($alias{$cmd_verb})
2813
2814 =head3 MAIN-LINE COMMANDS
2815
2816 All of these commands work up to and after the program being debugged has
2817 terminated.
2818
2819 =head4 C<q> - quit
2820
2821 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2822 try to execute further, cleaning any restart-related stuff out of the
2823 environment, and executing with the last value of C<$?>.
2824
2825 =cut
2826
2827                 # All of these commands were remapped in perl 5.8.0;
2828                 # we send them off to the secondary dispatcher (see below).
2829                 $obj->_handle_special_char_cmd_wrapper_commands;
2830                 _DB__trim_command_and_return_first_component($obj);
2831
2832                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2833                     my $type = $cmd_rec->{t};
2834                     my $val = $cmd_rec->{v};
2835                     if ($type eq 'm') {
2836                         $obj->$val();
2837                     }
2838                     elsif ($type eq 's') {
2839                         $val->($obj);
2840                     }
2841                 }
2842
2843 =head4 C<t> - trace [n]
2844
2845 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2846 If level is specified, set C<$trace_to_depth>.
2847
2848 =head4 C<S> - list subroutines matching/not matching a pattern
2849
2850 Walks through C<%sub>, checking to see whether or not to print the name.
2851
2852 =head4 C<X> - list variables in current package
2853
2854 Since the C<V> command actually processes this, just change this to the
2855 appropriate C<V> command and fall through.
2856
2857 =head4 C<V> - list variables
2858
2859 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2860
2861 =head4 C<x> - evaluate and print an expression
2862
2863 Hands the expression off to C<DB::eval>, setting it up to print the value
2864 via C<dumpvar.pl> instead of just printing it directly.
2865
2866 =head4 C<m> - print methods
2867
2868 Just uses C<DB::methods> to determine what methods are available.
2869
2870 =head4 C<f> - switch files
2871
2872 Switch to a different filename.
2873
2874 =head4 C<.> - return to last-executed line.
2875
2876 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2877 and then we look up the line in the magical C<%dbline> hash.
2878
2879 =head4 C<-> - back one window
2880
2881 We change C<$start> to be one window back; if we go back past the first line,
2882 we set it to be the first line. We ser C<$incr> to put us back at the
2883 currently-executing line, and then put a C<l $start +> (list one window from
2884 C<$start>) in C<$cmd> to be executed later.
2885
2886 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2887
2888 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2889 problems, most notably that the default case of several commands destroying
2890 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2891 retain the old commands for those who were used to using them or who preferred
2892 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2893 deal with them instead of processing them in-line.
2894
2895 =head4 C<y> - List lexicals in higher scope
2896
2897 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2898 above the current one and then displays then using C<dumpvar.pl>.
2899
2900 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2901
2902 All of the commands below this point don't work after the program being
2903 debugged has ended. All of them check to see if the program has ended; this
2904 allows the commands to be relocated without worrying about a 'line of
2905 demarcation' above which commands can be entered anytime, and below which
2906 they can't.
2907
2908 =head4 C<n> - single step, but don't trace down into subs
2909
2910 Done by setting C<$single> to 2, which forces subs to execute straight through
2911 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2912 so a null command knows what to re-execute.
2913
2914 =head4 C<s> - single-step, entering subs
2915
2916 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2917 subs. Also saves C<s> as C<$lastcmd>.
2918
2919 =head4 C<c> - run continuously, setting an optional breakpoint
2920
2921 Most of the code for this command is taken up with locating the optional
2922 breakpoint, which is either a subroutine name or a line number. We set
2923 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2924 in this and all call levels above this one.
2925
2926 =head4 C<r> - return from a subroutine
2927
2928 For C<r> to work properly, the debugger has to stop execution again
2929 immediately after the return is executed. This is done by forcing
2930 single-stepping to be on in the call level above the current one. If
2931 we are printing return values when a C<r> is executed, set C<$doret>
2932 appropriately, and force us out of the command loop.
2933
2934 =head4 C<T> - stack trace
2935
2936 Just calls C<DB::print_trace>.
2937
2938 =head4 C<w> - List window around current line.
2939
2940 Just calls C<DB::cmd_w>.
2941
2942 =head4 C<W> - watch-expression processing.
2943
2944 Just calls C<DB::cmd_W>.
2945
2946 =head4 C</> - search forward for a string in the source
2947
2948 We take the argument and treat it as a pattern. If it turns out to be a
2949 bad one, we return the error we got from trying to C<eval> it and exit.
2950 If not, we create some code to do the search and C<eval> it so it can't
2951 mess us up.
2952
2953 =cut
2954
2955                 _DB__handle_forward_slash_command($obj);
2956
2957 =head4 C<?> - search backward for a string in the source
2958
2959 Same as for C</>, except the loop runs backwards.
2960
2961 =cut
2962
2963                 _DB__handle_question_mark_command($obj);
2964
2965 =head4 C<$rc> - Recall command
2966
2967 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2968 that the terminal supports history). It finds the command required, puts it
2969 into C<$cmd>, and redoes the loop to execute it.
2970
2971 =cut
2972
2973                 # $rc - recall command.
2974                 $obj->_handle_rc_recall_command;
2975
2976 =head4 C<$sh$sh> - C<system()> command
2977
2978 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
2979 C<STDOUT> from getting messed up.
2980
2981 =cut
2982
2983                 $obj->_handle_sh_command;
2984
2985 =head4 C<$rc I<pattern> $rc> - Search command history
2986
2987 Another command to manipulate C<@hist>: this one searches it with a pattern.
2988 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2989
2990 =cut
2991
2992                 $obj->_handle_rc_search_history_command;
2993
2994 =head4 C<$sh> - Invoke a shell
2995
2996 Uses C<_db_system()> to invoke a shell.
2997
2998 =cut
2999
3000 =head4 C<$sh I<command>> - Force execution of a command in a shell
3001
3002 Like the above, but the command is passed to the shell. Again, we use
3003 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3004
3005 =head4 C<H> - display commands in history
3006
3007 Prints the contents of C<@hist> (if any).
3008
3009 =head4 C<man, doc, perldoc> - look up documentation
3010
3011 Just calls C<runman()> to print the appropriate document.
3012
3013 =cut
3014
3015                 $obj->_handle_doc_command;
3016
3017 =head4 C<p> - print
3018
3019 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3020 the bottom of the loop.
3021
3022 =head4 C<=> - define command alias
3023
3024 Manipulates C<%alias> to add or list command aliases.
3025
3026 =head4 C<source> - read commands from a file.
3027
3028 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3029 pick it up.
3030
3031 =head4 C<enable> C<disable> - enable or disable breakpoints
3032
3033 This enables or disables breakpoints.
3034
3035 =head4 C<save> - send current history to a file
3036
3037 Takes the complete history, (not the shrunken version you see with C<H>),
3038 and saves it to the given filename, so it can be replayed using C<source>.
3039
3040 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3041
3042 =head4 C<R> - restart
3043
3044 Restart the debugger session.
3045
3046 =head4 C<rerun> - rerun the current session
3047
3048 Return to any given position in the B<true>-history list
3049
3050 =head4 C<|, ||> - pipe output through the pager.
3051
3052 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3053 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3054 pipe to the pager (restoring the output filehandles if this fails). If this
3055 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3056 set C<$signal>, sending us back into the debugger.
3057
3058 We then trim off the pipe symbols and C<redo> the command loop at the
3059 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3060 reading another.
3061
3062 =cut
3063
3064                 # || - run command in the pager, with output to DB::OUT.
3065                 _DB__handle_run_command_in_pager_command($obj);
3066
3067 =head3 END OF COMMAND PARSING
3068
3069 Anything left in C<$cmd> at this point is a Perl expression that we want to
3070 evaluate. We'll always evaluate in the user's context, and fully qualify
3071 any variables we might want to address in the C<DB> package.
3072
3073 =cut
3074
3075             }    # PIPE:
3076
3077             # trace an expression
3078             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3079
3080             # Make sure the flag that says "the debugger's running" is
3081             # still on, to make sure we get control again.
3082             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3083
3084             # Run *our* eval that executes in the caller's context.
3085             DB::eval();
3086
3087             # Turn off the one-time-dump stuff now.
3088             if ($onetimeDump) {
3089                 $onetimeDump      = undef;
3090                 $onetimedumpDepth = undef;
3091             }
3092             elsif ( $term_pid == $$ ) {
3093                 eval { # May run under miniperl, when not available...
3094                     STDOUT->flush();
3095                     STDERR->flush();
3096                 };
3097
3098                 # XXX If this is the master pid, print a newline.
3099                 print {$OUT} "\n";
3100             }
3101         } ## end while (($term || &setterm...
3102
3103 =head3 POST-COMMAND PROCESSING
3104
3105 After each command, we check to see if the command output was piped anywhere.
3106 If so, we go through the necessary code to unhook the pipe and go back to
3107 our standard filehandles for input and output.
3108
3109 =cut
3110
3111         continue {    # CMD:
3112             _DB__at_end_of_every_command($obj);
3113         }    # CMD:
3114
3115 =head3 COMMAND LOOP TERMINATION
3116
3117 When commands have finished executing, we come here. If the user closed the
3118 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3119 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3120 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3121 The interpreter will then execute the next line and then return control to us
3122 again.
3123
3124 =cut
3125
3126         # No more commands? Quit.
3127         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3128
3129         # Evaluate post-prompt commands.
3130         foreach $evalarg (@$post) {
3131             DB::eval();
3132         }
3133     }    # if ($single || $signal)
3134
3135     # Put the user's globals back where you found them.
3136     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3137     ();
3138 } ## end sub DB
3139
3140 # Because DB::Obj is used above,
3141 #
3142 #   my $obj = DB::Obj->new(
3143 #
3144 # The following package declaration must come before that,
3145 # or else runtime errors will occur with
3146 #
3147 #   PERLDB_OPTS="autotrace nonstop"
3148 #
3149 # ( rt#116771 )
3150 BEGIN {
3151
3152 package DB::Obj;
3153
3154 sub new {
3155     my $class = shift;
3156
3157     my $self = bless {}, $class;
3158
3159     $self->_init(@_);
3160
3161     return $self;
3162 }
3163
3164 sub _init {
3165     my ($self, $args) = @_;
3166
3167     %{$self} = (%$self, %$args);
3168
3169     return;
3170 }
3171
3172 {
3173     no strict 'refs';
3174     foreach my $slot_name (qw(
3175         after explicit_stop infix pat piped position prefix selected cmd_verb
3176         cmd_args
3177         )) {
3178         my $slot = $slot_name;
3179         *{$slot} = sub {
3180             my $self = shift;
3181
3182             if (@_) {
3183                 ${ $self->{$slot} } = shift;
3184             }
3185
3186             return ${ $self->{$slot} };
3187         };
3188
3189         *{"append_to_$slot"} = sub {
3190             my $self = shift;
3191             my $s = shift;
3192
3193             return $self->$slot($self->$slot . $s);
3194         };
3195     }
3196 }
3197
3198 sub _DB_on_init__initialize_globals
3199 {
3200     my $self = shift;
3201
3202     # Check for whether we should be running continuously or not.
3203     # _After_ the perl program is compiled, $single is set to 1:
3204     if ( $single and not $second_time++ ) {
3205
3206         # Options say run non-stop. Run until we get an interrupt.
3207         if ($runnonstop) {    # Disable until signal
3208                 # If there's any call stack in place, turn off single
3209                 # stepping into subs throughout the stack.
3210             for my $i (0 .. $stack_depth) {
3211                 $stack[ $i ] &= ~1;
3212             }
3213
3214             # And we are now no longer in single-step mode.
3215             $single = 0;
3216
3217             # If we simply returned at this point, we wouldn't get
3218             # the trace info. Fall on through.
3219             # return;
3220         } ## end if ($runnonstop)
3221
3222         elsif ($ImmediateStop) {
3223
3224             # We are supposed to stop here; XXX probably a break.
3225             $ImmediateStop = 0;    # We've processed it; turn it off
3226             $signal        = 1;    # Simulate an interrupt to force
3227                                    # us into the command loop
3228         }
3229     } ## end if ($single and not $second_time...
3230
3231     # If we're in single-step mode, or an interrupt (real or fake)
3232     # has occurred, turn off non-stop mode.
3233     $runnonstop = 0 if $single or $signal;
3234
3235     return;
3236 }
3237
3238 sub _my_print_lineinfo
3239 {
3240     my ($self, $i, $incr_pos) = @_;
3241
3242     if ($frame) {
3243         # Print it indented if tracing is on.
3244         DB::print_lineinfo( ' ' x $stack_depth,
3245             "$i:\t$DB::dbline[$i]" . $self->after );
3246     }
3247     else {
3248         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3249     }
3250 }
3251
3252 sub _curr_line {
3253     return $DB::dbline[$line];
3254 }
3255
3256 sub _is_full {
3257     my ($self, $letter) = @_;
3258
3259     return ($DB::cmd eq $letter);
3260 }
3261
3262 sub _DB__grab_control
3263 {
3264     my $self = shift;
3265
3266     # Yes, grab control.
3267     if ($slave_editor) {
3268
3269         # Tell the editor to update its position.
3270         $self->position("\032\032${DB::filename}:$line:0\n");
3271         DB::print_lineinfo($self->position());
3272     }
3273
3274 =pod
3275
3276 Special check: if we're in package C<DB::fake>, we've gone through the
3277 C<END> block at least once. We set up everything so that we can continue
3278 to enter commands and have a valid context to be in.
3279
3280 =cut
3281
3282     elsif ( $DB::package eq 'DB::fake' ) {
3283
3284         # Fallen off the end already.
3285         if (!$DB::term) {
3286             DB::setterm();
3287         }
3288
3289         DB::print_help(<<EOP);
3290 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3291 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3292 B<h q>, B<h R> or B<h o> to get additional info.
3293 EOP
3294
3295         # Set the DB::eval context appropriately.
3296         $DB::package     = 'main';
3297         $DB::usercontext = DB::_calc_usercontext($DB::package);
3298     } ## end elsif ($package eq 'DB::fake')
3299
3300 =pod
3301
3302 If the program hasn't finished executing, we scan forward to the
3303 next executable line, print that out, build the prompt from the file and line
3304 number information, and print that.
3305
3306 =cut
3307
3308     else {
3309
3310
3311         # Still somewhere in the midst of execution. Set up the
3312         #  debugger prompt.
3313         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3314                              # Perl 5 ones (sorry, we don't print Klingon
3315                              #module names)
3316
3317         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3318         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3319         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3320
3321         # Break up the prompt if it's really long.
3322         if ( length($self->prefix()) > 30 ) {
3323             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3324             $self->prefix("");
3325             $self->infix(":\t");
3326         }
3327         else {
3328             $self->infix("):\t");
3329             $self->position(
3330                 $self->prefix . $line. $self->infix
3331                 . $self->_curr_line . $self->after
3332             );
3333         }
3334
3335         # Print current line info, indenting if necessary.
3336         $self->_my_print_lineinfo($line, $self->position);
3337
3338         my $i;
3339         my $line_i = sub { return $DB::dbline[$i]; };
3340
3341         # Scan forward, stopping at either the end or the next
3342         # unbreakable line.
3343         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3344         {    #{ vi
3345
3346             # Drop out on null statements, block closers, and comments.
3347             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3348
3349             # Drop out if the user interrupted us.
3350             last if $signal;
3351
3352             # Append a newline if the line doesn't have one. Can happen
3353             # in eval'ed text, for instance.
3354             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3355
3356             # Next executable line.
3357             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3358                 . $self->after;
3359             $self->append_to_position($incr_pos);
3360             $self->_my_print_lineinfo($i, $incr_pos);
3361         } ## end for ($i = $line + 1 ; $i...
3362     } ## end else [ if ($slave_editor)
3363
3364     return;
3365 }
3366
3367 sub _handle_t_command {
3368     my $self = shift;
3369
3370     my $levels = $self->cmd_args();
3371
3372     if ((!length($levels)) or ($levels !~ /\D/)) {
3373         $trace ^= 1;
3374         local $\ = '';
3375         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3376         print {$OUT} "Trace = "
3377         . ( ( $trace & 1 )
3378             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3379             : "off" ) . "\n";
3380         next CMD;
3381     }
3382
3383     return;
3384 }
3385
3386
3387 sub _handle_S_command {
3388     my $self = shift;
3389
3390     if (my ($print_all_subs, $should_reverse, $Spatt)
3391         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3392         # $Spatt is the pattern (if any) to use.
3393         # Reverse scan?
3394         my $Srev     = defined $should_reverse;
3395         # No args - print all subs.
3396         my $Snocheck = !defined $print_all_subs;
3397
3398         # Need to make these sane here.
3399         local $\ = '';
3400         local $, = '';
3401
3402         # Search through the debugger's magical hash of subs.
3403         # If $nocheck is true, just print the sub name.
3404         # Otherwise, check it against the pattern. We then use
3405         # the XOR trick to reverse the condition as required.
3406         foreach $subname ( sort( keys %sub ) ) {
3407             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3408                 print $OUT $subname, "\n";
3409             }
3410         }
3411         next CMD;
3412     }
3413
3414     return;
3415 }
3416
3417 sub _handle_V_command_and_X_command {
3418     my $self = shift;
3419
3420     $DB::cmd =~ s/^X\b/V $DB::package/;
3421
3422     # Bare V commands get the currently-being-debugged package
3423     # added.
3424     if ($self->_is_full('V')) {
3425         $DB::cmd = "V $DB::package";
3426     }
3427
3428     # V - show variables in package.
3429     if (my ($new_packname, $new_vars_str) =
3430         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3431
3432         # Save the currently selected filehandle and
3433         # force output to debugger's filehandle (dumpvar
3434         # just does "print" for output).
3435         my $savout = select($OUT);
3436
3437         # Grab package name and variables to dump.
3438         $packname = $new_packname;
3439         my @vars     = split( ' ', $new_vars_str );
3440
3441         # If main::dumpvar isn't here, get it.
3442         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3443         if ( defined &main::dumpvar ) {
3444
3445             # We got it. Turn off subroutine entry/exit messages
3446             # for the moment, along with return values.
3447             local $frame = 0;
3448             local $doret = -2;
3449
3450             # must detect sigpipe failures  - not catching
3451             # then will cause the debugger to die.
3452             eval {
3453                 main::dumpvar(
3454                     $packname,
3455                     defined $option{dumpDepth}
3456                     ? $option{dumpDepth}
3457                     : -1,    # assume -1 unless specified
3458                     @vars
3459                 );
3460             };
3461
3462             # The die doesn't need to include the $@, because
3463             # it will automatically get propagated for us.
3464             if ($@) {
3465                 die unless $@ =~ /dumpvar print failed/;
3466             }
3467         } ## end if (defined &main::dumpvar)
3468         else {
3469
3470             # Couldn't load dumpvar.
3471             print $OUT "dumpvar.pl not available.\n";
3472         }
3473
3474         # Restore the output filehandle, and go round again.
3475         select($savout);
3476         next CMD;
3477     }
3478
3479     return;
3480 }
3481
3482 sub _handle_dash_command {
3483     my $self = shift;
3484
3485     if ($self->_is_full('-')) {
3486
3487         # back up by a window; go to 1 if back too far.
3488         $start -= $incr + $window + 1;
3489         $start = 1 if $start <= 0;
3490         $incr  = $window - 1;
3491
3492         # Generate and execute a "l +" command (handled below).
3493         $DB::cmd = 'l ' . ($start) . '+';
3494         redo CMD;
3495     }
3496     return;
3497 }
3498
3499 sub _n_or_s_commands_generic {
3500     my ($self, $new_val) = @_;
3501     # n - next
3502     next CMD if DB::_DB__is_finished();
3503
3504     # Single step, but don't enter subs.
3505     $single = $new_val;
3506
3507     # Save for empty command (repeat last).
3508     $laststep = $DB::cmd;
3509     last CMD;
3510 }
3511
3512 sub _n_or_s {
3513     my ($self, $letter, $new_val) = @_;
3514
3515     if ($self->_is_full($letter)) {
3516         $self->_n_or_s_commands_generic($new_val);
3517     }
3518     else {
3519         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3520     }
3521
3522     return;
3523 }
3524
3525 sub _handle_n_command {
3526     my $self = shift;
3527
3528     return $self->_n_or_s('n', 2);
3529 }
3530
3531 sub _handle_s_command {
3532     my $self = shift;
3533
3534     return $self->_n_or_s('s', 1);
3535 }
3536
3537 sub _handle_r_command {
3538     my $self = shift;
3539
3540     # r - return from the current subroutine.
3541     if ($self->_is_full('r')) {
3542
3543         # Can't do anything if the program's over.
3544         next CMD if DB::_DB__is_finished();
3545
3546         # Turn on stack trace.
3547         $stack[$stack_depth] |= 1;
3548
3549         # Print return value unless the stack is empty.
3550         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3551         last CMD;
3552     }
3553
3554     return;
3555 }
3556
3557 sub _handle_T_command {
3558     my $self = shift;
3559
3560     if ($self->_is_full('T')) {
3561         DB::print_trace( $OUT, 1 );    # skip DB
3562         next CMD;
3563     }
3564
3565     return;
3566 }
3567
3568 sub _handle_w_command {
3569     my $self = shift;
3570
3571     DB::cmd_w( 'w', $self->cmd_args() );
3572     next CMD;
3573
3574     return;
3575 }
3576
3577 sub _handle_W_command {
3578     my $self = shift;
3579
3580     if (my $arg = $self->cmd_args) {
3581         DB::cmd_W( 'W', $arg );
3582         next CMD;
3583     }
3584
3585     return;
3586 }
3587
3588 sub _handle_rc_recall_command {
3589     my $self = shift;
3590
3591     # $rc - recall command.
3592     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3593
3594         # No arguments, take one thing off history.
3595         pop(@hist) if length($DB::cmd) > 1;
3596
3597         # Relative (- found)?
3598         #  Y - index back from most recent (by 1 if bare minus)
3599         #  N - go to that particular command slot or the last
3600         #      thing if nothing following.
3601
3602         $self->cmd_verb(
3603             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3604         );
3605
3606         # Pick out the command desired.
3607         $DB::cmd = $hist[$self->cmd_verb];
3608
3609         # Print the command to be executed and restart the loop
3610         # with that command in the buffer.
3611         print {$OUT} $DB::cmd, "\n";
3612         redo CMD;
3613     }
3614
3615     return;
3616 }
3617
3618 sub _handle_rc_search_history_command {
3619     my $self = shift;
3620
3621     # $rc pattern $rc - find a command in the history.
3622     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3623
3624         # Create the pattern to use.
3625         my $pat = "^$arg";
3626         $self->pat($pat);
3627
3628         # Toss off last entry if length is >1 (and it always is).
3629         pop(@hist) if length($DB::cmd) > 1;
3630
3631         my $i;
3632
3633         # Look backward through the history.
3634         SEARCH_HIST:
3635         for ( $i = $#hist ; $i ; --$i ) {
3636             # Stop if we find it.
3637             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3638         }
3639
3640         if ( !$i ) {
3641
3642             # Never found it.
3643             print $OUT "No such command!\n\n";
3644             next CMD;
3645         }
3646
3647         # Found it. Put it in the buffer, print it, and process it.
3648         $DB::cmd = $hist[$i];
3649         print $OUT $DB::cmd, "\n";
3650         redo CMD;
3651     }
3652
3653     return;
3654 }
3655
3656 sub _handle_H_command {
3657     my $self = shift;
3658
3659     if ($self->cmd_args =~ m#\A\*#) {
3660         @hist = @truehist = ();
3661         print $OUT "History cleansed\n";
3662         next CMD;
3663     }
3664
3665     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3666
3667         # Anything other than negative numbers is ignored by
3668         # the (incorrect) pattern, so this test does nothing.
3669         $end = $num ? ( $#hist - $num ) : 0;
3670
3671         # Set to the minimum if less than zero.
3672         $hist = 0 if $hist < 0;
3673
3674         # Start at the end of the array.
3675         # Stay in while we're still above the ending value.
3676         # Tick back by one each time around the loop.
3677         my $i;
3678
3679         for ( $i = $#hist ; $i > $end ; $i-- ) {
3680
3681             # Print the command  unless it has no arguments.
3682             print $OUT "$i: ", $hist[$i], "\n"
3683             unless $hist[$i] =~ /^.?$/;
3684         }
3685
3686         next CMD;
3687     }
3688
3689     return;
3690 }
3691
3692 sub _handle_doc_command {
3693     my $self = shift;
3694
3695     # man, perldoc, doc - show manual pages.
3696     if (my ($man_page)
3697         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3698         DB::runman($man_page);
3699         next CMD;
3700     }
3701
3702     return;
3703 }
3704
3705 sub _handle_p_command {
3706     my $self = shift;
3707
3708     my $print_cmd = 'print {$DB::OUT} ';
3709     # p - print (no args): print $_.
3710     if ($self->_is_full('p')) {
3711         $DB::cmd = $print_cmd . '$_';
3712     }
3713     else {
3714         # p - print the given expression.
3715         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3716     }
3717
3718     return;
3719 }
3720
3721 sub _handle_equal_sign_command {
3722     my $self = shift;
3723
3724     if ($DB::cmd =~ s/\A=\s*//) {
3725         my @keys;
3726         if ( length $DB::cmd == 0 ) {
3727
3728             # No args, get current aliases.
3729             @keys = sort keys %alias;
3730         }
3731         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3732
3733             # Creating a new alias. $k is alias name, $v is
3734             # alias value.
3735
3736             # can't use $_ or kill //g state
3737             for my $x ( $k, $v ) {
3738
3739                 # Escape "alarm" characters.
3740                 $x =~ s/\a/\\a/g;
3741             }
3742
3743             # Substitute key for value, using alarm chars
3744             # as separators (which is why we escaped them in
3745             # the command).
3746             $alias{$k} = "s\a$k\a$v\a";
3747
3748             # Turn off standard warn and die behavior.
3749             local $SIG{__DIE__};
3750             local $SIG{__WARN__};
3751
3752             # Is it valid Perl?
3753             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3754
3755                 # Nope. Bad alias. Say so and get out.
3756                 print $OUT "Can't alias $k to $v: $@\n";
3757                 delete $alias{$k};
3758                 next CMD;
3759             }
3760
3761             # We'll only list the new one.
3762             @keys = ($k);
3763         } ## end elsif (my ($k, $v) = ($DB::cmd...
3764
3765         # The argument is the alias to list.
3766         else {
3767             @keys = ($DB::cmd);
3768         }
3769
3770         # List aliases.
3771         for my $k (@keys) {
3772
3773             # Messy metaquoting: Trim the substitution code off.
3774             # We use control-G as the delimiter because it's not
3775             # likely to appear in the alias.
3776             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3777
3778                 # Print the alias.
3779                 print $OUT "$k\t= $1\n";
3780             }
3781             elsif ( defined $alias{$k} ) {
3782
3783                 # Couldn't trim it off; just print the alias code.
3784                 print $OUT "$k\t$alias{$k}\n";
3785             }
3786             else {
3787
3788                 # No such, dude.
3789                 print "No alias for $k\n";
3790             }
3791         } ## end for my $k (@keys)
3792         next CMD;
3793     }
3794
3795     return;
3796 }
3797
3798 sub _handle_source_command {
3799     my $self = shift;
3800
3801     # source - read commands from a file (or pipe!) and execute.
3802     if (my $sourced_fn = $self->cmd_args) {
3803         if ( open my $fh, $sourced_fn ) {
3804
3805             # Opened OK; stick it in the list of file handles.
3806             push @cmdfhs, $fh;
3807         }
3808         else {
3809
3810             # Couldn't open it.
3811             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3812         }
3813         next CMD;
3814     }
3815
3816     return;
3817 }
3818
3819 sub _handle_enable_disable_commands {
3820     my $self = shift;
3821
3822     my $which_cmd = $self->cmd_verb;
3823     my $position = $self->cmd_args;
3824
3825     if ($position !~ /\s/) {
3826         my ($fn, $line_num);
3827         if ($position =~ m{\A\d+\z})
3828         {
3829             $fn = $DB::filename;
3830             $line_num = $position;
3831         }
3832         elsif (my ($new_fn, $new_line_num)
3833             = $position =~ m{\A(.*):(\d+)\z}) {
3834             ($fn, $line_num) = ($new_fn, $new_line_num);
3835         }
3836         else
3837         {
3838             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3839         }
3840
3841         if (defined($fn)) {
3842             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3843                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3844                     ($which_cmd eq 'enable' ? 1 : '')
3845                 );
3846             }
3847             else {
3848                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3849             }
3850         }
3851
3852         next CMD;
3853     }
3854
3855     return;
3856 }
3857
3858 sub _handle_save_command {
3859     my $self = shift;
3860
3861     if (my $new_fn = $self->cmd_args) {
3862         my $filename = $new_fn || '.perl5dbrc';    # default?
3863         if ( open my $fh, '>', $filename ) {
3864
3865             # chomp to remove extraneous newlines from source'd files
3866             chomp( my @truelist =
3867                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3868                 @truehist );
3869             print {$fh} join( "\n", @truelist );
3870             print "commands saved in $filename\n";
3871         }
3872         else {
3873             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3874         }
3875         next CMD;
3876     }
3877
3878     return;
3879 }
3880
3881 sub _n_or_s_and_arg_commands_generic {
3882     my ($self, $letter, $new_val) = @_;
3883
3884     # s - single-step. Remember the last command was 's'.
3885     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3886         $laststep = $letter;
3887     }
3888
3889     return;
3890 }
3891
3892 sub _handle_sh_command {
3893     my $self = shift;
3894
3895     # $sh$sh - run a shell command (if it's all ASCII).
3896     # Can't run shell commands with Unicode in the debugger, hmm.
3897     my $my_cmd = $DB::cmd;
3898     if ($my_cmd =~ m#\A$sh#gms) {
3899
3900         if ($my_cmd =~ m#\G\z#cgms) {
3901             # Run the user's shell. If none defined, run Bourne.
3902             # We resume execution when the shell terminates.
3903             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3904             next CMD;
3905         }
3906         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3907             # System it.
3908             DB::_db_system($1);
3909             next CMD;
3910         }
3911         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3912             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3913             next CMD;
3914         }
3915     }
3916 }
3917
3918 sub _handle_x_command {
3919     my $self = shift;
3920
3921     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3922         $onetimeDump = 'dump';    # main::dumpvar shows the output
3923
3924         # handle special  "x 3 blah" syntax XXX propagate
3925         # doc back to special variables.
3926         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3927             $onetimedumpDepth = $1;
3928         }
3929     }
3930
3931     return;
3932 }
3933
3934 sub _handle_q_command {
3935     my $self = shift;
3936
3937     if ($self->_is_full('q')) {
3938         $fall_off_end = 1;
3939         DB::clean_ENV();
3940         exit $?;
3941     }
3942
3943     return;
3944 }
3945
3946 sub _handle_cmd_wrapper_commands {
3947     my $self = shift;
3948
3949     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
3950     next CMD;
3951 }
3952
3953 sub _handle_special_char_cmd_wrapper_commands {
3954     my $self = shift;
3955
3956     # All of these commands were remapped in perl 5.8.0;
3957     # we send them off to the secondary dispatcher (see below).
3958     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
3959         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
3960         next CMD;
3961     }
3962
3963     return;
3964 }
3965
3966 } ## end DB::Obj
3967
3968 package DB;
3969
3970 # The following code may be executed now:
3971 # BEGIN {warn 4}
3972
3973 =head2 sub
3974
3975 C<sub> is called whenever a subroutine call happens in the program being
3976 debugged. The variable C<$DB::sub> contains the name of the subroutine
3977 being called.
3978
3979 The core function of this subroutine is to actually call the sub in the proper
3980 context, capturing its output. This of course causes C<DB::DB> to get called
3981 again, repeating until the subroutine ends and returns control to C<DB::sub>
3982 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3983 return value, and returns its captured copy of the return value as its own
3984 return value. The value then feeds back into the program being debugged as if
3985 C<DB::sub> hadn't been there at all.
3986
3987 C<sub> does all the work of printing the subroutine entry and exit messages
3988 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3989 and also prints the return value if needed (for the C<r> command and if
3990 the 16 bit is set in C<$frame>).
3991
3992 It also tracks the subroutine call depth by saving the current setting of
3993 C<$single> in the C<@stack> package global; if this exceeds the value in
3994 C<$deep>, C<sub> automatically turns on printing of the current depth by
3995 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3996 of stop/don't stop on entry to subs set as it currently is set.
3997
3998 =head3 C<caller()> support
3999
4000 If C<caller()> is called from the package C<DB>, it provides some
4001 additional data, in the following order:
4002
4003 =over 4
4004
4005 =item * C<$package>
4006
4007 The package name the sub was in
4008
4009 =item * C<$filename>
4010
4011 The filename it was defined in
4012
4013 =item * C<$line>
4014
4015 The line number it was defined on
4016
4017 =item * C<$subroutine>
4018
4019 The subroutine name; C<(eval)> if an C<eval>().
4020
4021 =item * C<$hasargs>
4022
4023 1 if it has arguments, 0 if not
4024
4025 =item * C<$wantarray>
4026
4027 1 if array context, 0 if scalar context
4028
4029 =item * C<$evaltext>
4030
4031 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4032
4033 =item * C<$is_require>
4034
4035 frame was created by a C<use> or C<require> statement
4036
4037 =item * C<$hints>
4038
4039 pragma information; subject to change between versions
4040
4041 =item * C<$bitmask>
4042
4043 pragma information; subject to change between versions
4044
4045 =item * C<@DB::args>
4046
4047 arguments with which the subroutine was invoked
4048
4049 =back
4050
4051 =cut
4052
4053 use vars qw($deep);
4054
4055 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4056 # happy. -- Shlomi Fish
4057
4058 sub _indent_print_line_info {
4059     my ($offset, $str) = @_;
4060
4061     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4062
4063     return;
4064 }
4065
4066 sub _print_frame_message {
4067     my ($al) = @_;
4068
4069     if ($frame) {
4070         if ($frame & 4) {   # Extended frame entry message
4071             _indent_print_line_info(-1, "in  ");
4072
4073             # Why -1? But it works! :-(
4074             # Because print_trace will call add 1 to it and then call
4075             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4076             # in dump_trace.
4077             #
4078             # Now it's 0 because we extracted a function.
4079             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4080         }
4081         else {
4082             _indent_print_line_info(-1, "entering $sub$al\n" );
4083         }
4084     }
4085
4086     return;
4087 }
4088
4089 sub DB::sub {
4090     # Do not use a regex in this subroutine -> results in corrupted memory
4091     # See: [perl #66110]
4092
4093     # lock ourselves under threads
4094     lock($DBGR);
4095
4096     # Whether or not the autoloader was running, a scalar to put the
4097     # sub's return value in (if needed), and an array to put the sub's
4098     # return value in (if needed).
4099     my ( $al, $ret, @ret ) = "";
4100     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4101         print "creating new thread\n";
4102     }
4103
4104     # If the last ten characters are '::AUTOLOAD', note we've traced
4105     # into AUTOLOAD for $sub.
4106     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4107         no strict 'refs';
4108         $al = " for $$sub" if defined $$sub;
4109     }
4110
4111     # We stack the stack pointer and then increment it to protect us
4112     # from a situation that might unwind a whole bunch of call frames
4113     # at once. Localizing the stack pointer means that it will automatically
4114     # unwind the same amount when multiple stack frames are unwound.
4115     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4116
4117     # Expand @stack.
4118     $#stack = $stack_depth;
4119
4120     # Save current single-step setting.
4121     $stack[-1] = $single;
4122
4123     # Turn off all flags except single-stepping.
4124     $single &= 1;
4125
4126     # If we've gotten really deeply recursed, turn on the flag that will
4127     # make us stop with the 'deep recursion' message.
4128     $single |= 4 if $stack_depth == $deep;
4129
4130     # If frame messages are on ...
4131
4132     _print_frame_message($al);
4133     # standard frame entry message
4134
4135     my $print_exit_msg = sub {
4136         # Check for exit trace messages...
4137         if ($frame & 2)
4138         {
4139             if ($frame & 4)    # Extended exit message
4140             {
4141                 _indent_print_line_info(0, "out ");
4142                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4143             }
4144             else
4145             {
4146                 _indent_print_line_info(0, "exited $sub$al\n" );
4147             }
4148         }
4149         return;
4150     };
4151
4152     # Determine the sub's return type, and capture appropriately.
4153     if (wantarray) {
4154
4155         # Called in array context. call sub and capture output.
4156         # DB::DB will recursively get control again if appropriate; we'll come
4157         # back here when the sub is finished.
4158         {
4159             no strict 'refs';
4160             @ret = &$sub;
4161         }
4162
4163         # Pop the single-step value back off the stack.
4164         $single |= $stack[ $stack_depth-- ];
4165
4166         $print_exit_msg->();
4167
4168         # Print the return info if we need to.
4169         if ( $doret eq $stack_depth or $frame & 16 ) {
4170
4171             # Turn off output record separator.
4172             local $\ = '';
4173             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4174
4175             # Indent if we're printing because of $frame tracing.
4176             if ($frame & 16)
4177             {
4178                 print {$fh} ' ' x $stack_depth;
4179             }
4180
4181             # Print the return value.
4182             print {$fh} "list context return from $sub:\n";
4183             dumpit( $fh, \@ret );
4184
4185             # And don't print it again.
4186             $doret = -2;
4187         } ## end if ($doret eq $stack_depth...
4188             # And we have to return the return value now.
4189         @ret;
4190     } ## end if (wantarray)
4191
4192     # Scalar context.
4193     else {
4194         if ( defined wantarray ) {
4195             no strict 'refs';
4196             # Save the value if it's wanted at all.
4197             $ret = &$sub;
4198         }
4199         else {
4200             no strict 'refs';
4201             # Void return, explicitly.
4202             &$sub;
4203             undef $ret;
4204         }
4205
4206         # Pop the single-step value off the stack.
4207         $single |= $stack[ $stack_depth-- ];
4208
4209         # If we're doing exit messages...
4210         $print_exit_msg->();
4211
4212         # If we are supposed to show the return value... same as before.
4213         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4214             local $\ = '';
4215             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4216             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4217             print $fh (
4218                 defined wantarray
4219                 ? "scalar context return from $sub: "
4220                 : "void context return from $sub\n"
4221             );
4222             dumpit( $fh, $ret ) if defined wantarray;
4223             $doret = -2;
4224         } ## end if ($doret eq $stack_depth...
4225
4226         # Return the appropriate scalar value.
4227         $ret;
4228     } ## end else [ if (wantarray)
4229 } ## end sub _sub
4230
4231 sub lsub : lvalue {
4232
4233     no strict 'refs';
4234
4235     # lock ourselves under threads
4236     lock($DBGR);
4237
4238     # Whether or not the autoloader was running, a scalar to put the
4239     # sub's return value in (if needed), and an array to put the sub's
4240     # return value in (if needed).
4241     my ( $al, $ret, @ret ) = "";
4242     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4243         print "creating new thread\n";
4244     }
4245
4246     # If the last ten characters are C'::AUTOLOAD', note we've traced
4247     # into AUTOLOAD for $sub.
4248     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4249         $al = " for $$sub";
4250     }
4251
4252     # We stack the stack pointer and then increment it to protect us
4253     # from a situation that might unwind a whole bunch of call frames
4254     # at once. Localizing the stack pointer means that it will automatically
4255     # unwind the same amount when multiple stack frames are unwound.
4256     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4257
4258     # Expand @stack.
4259     $#stack = $stack_depth;
4260
4261     # Save current single-step setting.
4262     $stack[-1] = $single;
4263
4264     # Turn off all flags except single-stepping.
4265     $single &= 1;
4266
4267     # If we've gotten really deeply recursed, turn on the flag that will
4268     # make us stop with the 'deep recursion' message.
4269     $single |= 4 if $stack_depth == $deep;
4270
4271     # If frame messages are on ...
4272     _print_frame_message($al);
4273
4274     # Pop the single-step value back off the stack.
4275     $single |= $stack[ $stack_depth-- ];
4276
4277     # call the original lvalue sub.
4278     &$sub;
4279 }
4280
4281 # Abstracting common code from multiple places elsewhere:
4282 sub depth_print_lineinfo {
4283     my $always_print = shift;
4284
4285     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4286 }
4287
4288 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4289
4290 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4291 Most of the changes were to systematize the command structure and to eliminate
4292 commands that threw away user input without checking.
4293
4294 The following sections describe the code added to make it easy to support
4295 multiple command sets with conflicting command names. This section is a start
4296 at unifying all command processing to make it simpler to develop commands.
4297
4298 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4299 number, and C<$dbline> (the current line) as arguments.
4300
4301 Support functions in this section which have multiple modes of failure C<die>
4302 on error; the rest simply return a false value.
4303
4304 The user-interface functions (all of the C<cmd_*> functions) just output
4305 error messages.
4306
4307 =head2 C<%set>
4308
4309 The C<%set> hash defines the mapping from command letter to subroutine
4310 name suffix.
4311
4312 C<%set> is a two-level hash, indexed by set name and then by command name.
4313 Note that trying to set the CommandSet to C<foobar> simply results in the
4314 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4315
4316 =cut
4317
4318 ### The API section
4319
4320 my %set = (    #
4321     'pre580' => {
4322         'a' => 'pre580_a',
4323         'A' => 'pre580_null',
4324         'b' => 'pre580_b',
4325         'B' => 'pre580_null',
4326         'd' => 'pre580_null',
4327         'D' => 'pre580_D',
4328         'h' => 'pre580_h',
4329         'M' => 'pre580_null',
4330         'O' => 'o',
4331         'o' => 'pre580_null',
4332         'v' => 'M',
4333         'w' => 'v',
4334         'W' => 'pre580_W',
4335     },
4336     'pre590' => {
4337         '<'  => 'pre590_prepost',
4338         '<<' => 'pre590_prepost',
4339         '>'  => 'pre590_prepost',
4340         '>>' => 'pre590_prepost',
4341         '{'  => 'pre590_prepost',
4342         '{{' => 'pre590_prepost',
4343     },
4344 );
4345
4346 my %breakpoints_data;
4347
4348 sub _has_breakpoint_data_ref {
4349     my ($filename, $line) = @_;
4350
4351     return (
4352         exists( $breakpoints_data{$filename} )
4353             and
4354         exists( $breakpoints_data{$filename}{$line} )
4355     );
4356 }
4357
4358 sub _get_breakpoint_data_ref {
4359     my ($filename, $line) = @_;
4360
4361     return ($breakpoints_data{$filename}{$line} ||= +{});
4362 }
4363
4364 sub _delete_breakpoint_data_ref {
4365     my ($filename, $line) = @_;
4366
4367     delete($breakpoints_data{$filename}{$line});
4368     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4369         delete($breakpoints_data{$filename});
4370     }
4371
4372     return;
4373 }
4374
4375 sub _set_breakpoint_enabled_status {
4376     my ($filename, $line, $status) = @_;
4377
4378     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4379         ($status ? 1 : '')
4380         ;
4381
4382     return;
4383 }
4384
4385 sub _enable_breakpoint_temp_enabled_status {
4386     my ($filename, $line) = @_;
4387
4388     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4389
4390     return;
4391 }
4392
4393 sub _cancel_breakpoint_temp_enabled_status {
4394     my ($filename, $line) = @_;
4395
4396     my $ref = _get_breakpoint_data_ref($filename, $line);
4397
4398     delete ($ref->{'temp_enabled'});
4399
4400     if (! %$ref) {
4401         _delete_breakpoint_data_ref($filename, $line);
4402     }
4403
4404     return;
4405 }
4406
4407 sub _is_breakpoint_enabled {
4408     my ($filename, $line) = @_;
4409
4410     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4411     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4412 }
4413
4414 =head2 C<cmd_wrapper()> (API)
4415
4416 C<cmd_wrapper()> allows the debugger to switch command sets
4417 depending on the value of the C<CommandSet> option.
4418
4419 It tries to look up the command in the C<%set> package-level I<lexical>
4420 (which means external entities can't fiddle with it) and create the name of
4421 the sub to call based on the value found in the hash (if it's there). I<All>
4422 of the commands to be handled in a set have to be added to C<%set>; if they
4423 aren't found, the 5.8.0 equivalent is called (if there is one).
4424
4425 This code uses symbolic references.
4426
4427 =cut
4428
4429 sub cmd_wrapper {
4430     my $cmd      = shift;
4431     my $line     = shift;
4432     my $dblineno = shift;
4433
4434     # Assemble the command subroutine's name by looking up the
4435     # command set and command name in %set. If we can't find it,
4436     # default to the older version of the command.
4437     my $call = 'cmd_'
4438       . ( $set{$CommandSet}{$cmd}
4439           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4440
4441     # Call the command subroutine, call it by name.
4442     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4443 } ## end sub cmd_wrapper
4444
4445 =head3 C<cmd_a> (command)
4446
4447 The C<a> command handles pre-execution actions. These are associated with a
4448 particular line, so they're stored in C<%dbline>. We default to the current
4449 line if none is specified.
4450
4451 =cut
4452
4453 sub cmd_a {
4454     my $cmd    = shift;
4455     my $line   = shift || '';    # [.|line] expr
4456     my $dbline = shift;
4457
4458     # If it's dot (here), or not all digits,  use the current line.
4459     $line =~ s/\A\./$dbline/;
4460
4461     # Should be a line number followed by an expression.
4462     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4463
4464         if (! length($lineno)) {
4465             $lineno = $dbline;
4466         }
4467
4468         # If we have an expression ...
4469         if ( length $expr ) {
4470
4471             # ... but the line isn't breakable, complain.
4472             if ( $dbline[$lineno] == 0 ) {
4473                 print $OUT
4474                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4475             }
4476             else {
4477
4478                 # It's executable. Record that the line has an action.
4479                 $had_breakpoints{$filename} |= 2;
4480
4481                 # Remove any action, temp breakpoint, etc.
4482                 $dbline{$lineno} =~ s/\0[^\0]*//;
4483
4484                 # Add the action to the line.
4485                 $dbline{$lineno} .= "\0" . action($expr);
4486
4487                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4488             }
4489         } ## end if (length $expr)
4490     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4491     else {
4492
4493         # Syntax wrong.
4494         print $OUT
4495           "Adding an action requires an optional lineno and an expression\n"
4496           ;    # hint
4497     }
4498 } ## end sub cmd_a
4499
4500 =head3 C<cmd_A> (command)
4501
4502 Delete actions. Similar to above, except the delete code is in a separate
4503 subroutine, C<delete_action>.
4504
4505 =cut
4506
4507 sub cmd_A {
4508     my $cmd    = shift;
4509     my $line   = shift || '';
4510     my $dbline = shift;
4511
4512     # Dot is this line.
4513     $line =~ s/^\./$dbline/;
4514
4515     # Call delete_action with a null param to delete them all.
4516     # The '1' forces the eval to be true. It'll be false only
4517     # if delete_action blows up for some reason, in which case
4518     # we print $@ and get out.
4519     if ( $line eq '*' ) {
4520         if (! eval { _delete_all_actions(); 1 }) {
4521             print {$OUT} $@;
4522             return;
4523         }
4524     }
4525
4526     # There's a real line  number. Pass it to delete_action.
4527     # Error trapping is as above.
4528     elsif ( $line =~ /^(\S.*)/ ) {
4529         if (! eval { delete_action($1); 1 }) {
4530             print {$OUT} $@;
4531             return;
4532         }
4533     }
4534
4535     # Swing and a miss. Bad syntax.
4536     else {
4537         print $OUT
4538           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4539     }
4540 } ## end sub cmd_A
4541
4542 =head3 C<delete_action> (API)
4543
4544 C<delete_action> accepts either a line number or C<undef>. If a line number
4545 is specified, we check for the line being executable (if it's not, it
4546 couldn't have had an  action). If it is, we just take the action off (this
4547 will get any kind of an action, including breakpoints).
4548
4549 =cut
4550
4551 sub _remove_action_from_dbline {
4552     my $i = shift;
4553
4554     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4555     delete $dbline{$i} if $dbline{$i} eq '';
4556
4557     return;
4558 }
4559
4560 sub _delete_all_actions {
4561     print {$OUT} "Deleting all actions...\n";
4562
4563     for my $file ( keys %had_breakpoints ) {
4564         local *dbline = $main::{ '_<' . $file };
4565         $max = $#dbline;
4566         my $was;
4567         for my $i (1 .. $max) {
4568             if ( defined $dbline{$i} ) {
4569                 _remove_action_from_dbline($i);
4570             }
4571         }
4572
4573         unless ( $had_breakpoints{$file} &= ~2 ) {
4574             delete $had_breakpoints{$file};
4575         }
4576     }
4577
4578     return;
4579 }
4580
4581 sub delete_action {
4582     my $i = shift;
4583
4584     if ( defined($i) ) {
4585         # Can there be one?
4586         die "Line $i has no action .\n" if $dbline[$i] == 0;
4587
4588         # Nuke whatever's there.
4589         _remove_action_from_dbline($i);
4590     }
4591     else {
4592         _delete_all_actions();
4593     }
4594 }
4595
4596 =head3 C<cmd_b> (command)
4597
4598 Set breakpoints. Since breakpoints can be set in so many places, in so many
4599 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4600 we try to parse the command type, and then shuttle it off to an appropriate
4601 subroutine to actually do the work of setting the breakpoint in the right
4602 place.
4603
4604 =cut
4605
4606 sub cmd_b {
4607     my $cmd    = shift;
4608     my $line   = shift;    # [.|line] [cond]
4609     my $dbline = shift;
4610
4611     my $default_cond = sub {
4612         my $cond = shift;
4613         return length($cond) ? $cond : '1';
4614     };
4615
4616     # Make . the current line number if it's there..
4617     $line =~ s/^\.(\s|\z)/$dbline$1/;
4618
4619     # No line number, no condition. Simple break on current line.
4620     if ( $line =~ /^\s*$/ ) {
4621         cmd_b_line( $dbline, 1 );
4622     }
4623
4624     # Break on load for a file.
4625     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4626         $file =~ s/\s+\z//;
4627         cmd_b_load($file);
4628     }
4629
4630     # b compile|postpone <some sub> [<condition>]
4631     # The interpreter actually traps this one for us; we just put the
4632     # necessary condition in the %postponed hash.
4633     elsif ( my ($action, $subname, $cond)
4634         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4635
4636         # De-Perl4-ify the name - ' separators to ::.
4637         $subname =~ s/'/::/g;
4638
4639         # Qualify it into the current package unless it's already qualified.
4640         $subname = "${package}::" . $subname unless $subname =~ /::/;
4641
4642         # Add main if it starts with ::.
4643         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4644
4645         # Save the break type for this sub.
4646         $postponed{$subname} = (($action eq 'postpone')
4647             ? ( "break +0 if " . $default_cond->($cond) )
4648             : "compile");
4649     } ## end elsif ($line =~ ...
4650     # b <filename>:<line> [<condition>]
4651     elsif (my ($filename, $line_num, $cond)
4652         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4653         cmd_b_filename_line(
4654             $filename,
4655             $line_num,
4656             (length($cond) ? $cond : '1'),
4657         );
4658     }
4659     # b <sub name> [<condition>]
4660     elsif ( my ($new_subname, $new_cond) =
4661         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4662
4663         #
4664         $subname = $new_subname;
4665         cmd_b_sub( $subname, $default_cond->($new_cond) );
4666     }
4667
4668     # b <line> [<condition>].
4669     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4670
4671         # Capture the line. If none, it's the current line.
4672         $line = $line_n || $dbline;
4673
4674         # Break on line.
4675         cmd_b_line( $line, $default_cond->($cond) );
4676     }
4677
4678     # Line didn't make sense.
4679     else {
4680         print "confused by line($line)?\n";
4681     }
4682
4683     return;
4684 } ## end sub cmd_b
4685
4686 =head3 C<break_on_load> (API)
4687
4688 We want to break when this file is loaded. Mark this file in the
4689 C<%break_on_load> hash, and note that it has a breakpoint in
4690 C<%had_breakpoints>.
4691
4692 =cut
4693
4694 sub break_on_load {
4695     my $file = shift;
4696     $break_on_load{$file} = 1;
4697     $had_breakpoints{$file} |= 1;
4698 }
4699
4700 =head3 C<report_break_on_load> (API)
4701
4702 Gives us an array of filenames that are set to break on load. Note that
4703 only files with break-on-load are in here, so simply showing the keys
4704 suffices.
4705
4706 =cut
4707
4708 sub report_break_on_load {
4709     sort keys %break_on_load;
4710 }
4711
4712 =head3 C<cmd_b_load> (command)
4713
4714 We take the file passed in and try to find it in C<%INC> (which maps modules
4715 to files they came from). We mark those files for break-on-load via
4716 C<break_on_load> and then report that it was done.
4717
4718 =cut
4719
4720 sub cmd_b_load {
4721     my $file = shift;
4722     my @files;
4723
4724     # This is a block because that way we can use a redo inside it
4725     # even without there being any looping structure at all outside it.
4726     {
4727
4728         # Save short name and full path if found.
4729         push @files, $file;
4730         push @files, $::INC{$file} if $::INC{$file};
4731
4732         # Tack on .pm and do it again unless there was a '.' in the name
4733         # already.
4734         $file .= '.pm', redo unless $file =~ /\./;
4735     }
4736
4737     # Do the real work here.
4738     break_on_load($_) for @files;
4739
4740     # All the files that have break-on-load breakpoints.
4741     @files = report_break_on_load;
4742
4743     # Normalize for the purposes of our printing this.
4744     local $\ = '';
4745     local $" = ' ';
4746     print $OUT "Will stop on load of '@files'.\n";
4747 } ## end sub cmd_b_load
4748
4749 =head3 C<$filename_error> (API package global)
4750
4751 Several of the functions we need to implement in the API need to work both
4752 on the current file and on other files. We don't want to duplicate code, so
4753 C<$filename_error> is used to contain the name of the file that's being
4754 worked on (if it's not the current one).
4755
4756 We can now build functions in pairs: the basic function works on the current
4757 file, and uses C<$filename_error> as part of its error message. Since this is
4758 initialized to C<"">, no filename will appear when we are working on the
4759 current file.
4760
4761 The second function is a wrapper which does the following:
4762
4763 =over 4
4764
4765 =item *
4766
4767 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4768
4769 =item *
4770
4771 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4772
4773 =item *
4774
4775 Calls the first function.
4776
4777 The first function works on the I<current> file (i.e., the one we changed to),
4778 and prints C<$filename_error> in the error message (the name of the other file)
4779 if it needs to. When the functions return, C<*dbline> is restored to point
4780 to the actual current file (the one we're executing in) and
4781 C<$filename_error> is restored to C<"">. This restores everything to
4782 the way it was before the second function was called at all.
4783
4784 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4785 details.
4786
4787 =back
4788
4789 =cut
4790
4791 use vars qw($filename_error);
4792 $filename_error = '';
4793
4794 =head3 breakable_line(from, to) (API)
4795
4796 The subroutine decides whether or not a line in the current file is breakable.
4797 It walks through C<@dbline> within the range of lines specified, looking for
4798 the first line that is breakable.
4799
4800 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4801 first line I<after> C<$to> that's breakable, if there is one.
4802
4803 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4804 first line I<before> C<$to> that's breakable, if there is one.
4805
4806 =cut
4807
4808 sub breakable_line {
4809
4810     my ( $from, $to ) = @_;
4811
4812     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4813     my $i = $from;
4814
4815     # If there are at least 2 arguments, we're trying to search a range.
4816     if ( @_ >= 2 ) {
4817
4818         # $delta is positive for a forward search, negative for a backward one.
4819         my $delta = $from < $to ? +1 : -1;
4820
4821         # Keep us from running off the ends of the file.
4822         my $limit = $delta > 0 ? $#dbline : 1;
4823
4824         # Clever test. If you're a mathematician, it's obvious why this
4825         # test works. If not:
4826         # If $delta is positive (going forward), $limit will be $#dbline.
4827         #    If $to is less than $limit, ($limit - $to) will be positive, times
4828         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4829         #    as the stopping point.
4830         #
4831         #    If $to is greater than $limit, ($limit - $to) is negative,
4832         #    times $delta of 1 (positive), so the result is < 0 and we should
4833         #    use $limit ($#dbline) as the stopping point.
4834         #
4835         # If $delta is negative (going backward), $limit will be 1.
4836         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4837         #    (negative) so the result is > 0, and we use $to as the stopping
4838         #    point.
4839         #
4840         #    If $to is less than zero, ($limit - $to) will be positive,
4841         #    times $delta of -1 (negative), so the result is not > 0, and
4842         #    we use $limit (1) as the stopping point.
4843         #
4844         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4845         #    (negative), still giving zero; the result is not > 0, and
4846         #    we use $limit (1) as the stopping point.
4847         #
4848         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4849         #    (negative), giving a positive (>0) value, so we'll set $limit to
4850         #    $to.
4851
4852         $limit = $to if ( $limit - $to ) * $delta > 0;
4853
4854         # The real search loop.
4855         # $i starts at $from (the point we want to start searching from).
4856         # We move through @dbline in the appropriate direction (determined
4857         # by $delta: either -1 (back) or +1 (ahead).
4858         # We stay in as long as we haven't hit an executable line
4859         # ($dbline[$i] == 0 means not executable) and we haven't reached
4860         # the limit yet (test similar to the above).
4861         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4862
4863     } ## end if (@_ >= 2)
4864
4865     # If $i points to a line that is executable, return that.
4866     return $i unless $dbline[$i] == 0;
4867
4868     # Format the message and print it: no breakable lines in range.
4869     my ( $pl, $upto ) = ( '', '' );
4870     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4871
4872     # If there's a filename in filename_error, we'll see it.
4873     # If not, not.
4874     die "Line$pl $from$upto$filename_error not breakable\n";
4875 } ## end sub breakable_line
4876
4877 =head3 breakable_line_in_filename(file, from, to) (API)
4878
4879 Like C<breakable_line>, but look in another file.
4880
4881 =cut
4882
4883 sub breakable_line_in_filename {
4884
4885     # Capture the file name.
4886     my ($f) = shift;
4887
4888     # Swap the magic line array over there temporarily.
4889     local *dbline = $main::{ '_<' . $f };
4890
4891     # If there's an error, it's in this other file.
4892     local $filename_error = " of '$f'";
4893
4894     # Find the breakable line.
4895     breakable_line(@_);
4896
4897     # *dbline and $filename_error get restored when this block ends.
4898
4899 } ## end sub breakable_line_in_filename
4900
4901 =head3 break_on_line(lineno, [condition]) (API)
4902
4903 Adds a breakpoint with the specified condition (or 1 if no condition was
4904 specified) to the specified line. Dies if it can't.
4905
4906 =cut
4907
4908 sub break_on_line {
4909     my $i = shift;
4910     my $cond = @_ ? shift(@_) : 1;
4911
4912     my $inii  = $i;
4913     my $after = '';
4914     my $pl    = '';
4915
4916     # Woops, not a breakable line. $filename_error allows us to say
4917     # if it was in a different file.
4918     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4919
4920     # Mark this file as having breakpoints in it.
4921     $had_breakpoints{$filename} |= 1;
4922
4923     # If there is an action or condition here already ...
4924     if ( $dbline{$i} ) {
4925
4926         # ... swap this condition for the existing one.
4927         $dbline{$i} =~ s/^[^\0]*/$cond/;
4928     }
4929     else {
4930
4931         # Nothing here - just add the condition.
4932         $dbline{$i} = $cond;
4933
4934         _set_breakpoint_enabled_status($filename, $i, 1);
4935     }
4936
4937     return;
4938 } ## end sub break_on_line
4939
4940 =head3 cmd_b_line(line, [condition]) (command)
4941
4942 Wrapper for C<break_on_line>. Prints the failure message if it
4943 doesn't work.
4944
4945 =cut
4946
4947 sub cmd_b_line {
4948     if (not eval { break_on_line(@_); 1 }) {
4949         local $\ = '';
4950         print $OUT $@ and return;
4951     }
4952
4953     return;
4954 } ## end sub cmd_b_line
4955
4956 =head3 cmd_b_filename_line(line, [condition]) (command)
4957
4958 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4959 doesn't work.
4960
4961 =cut
4962
4963 sub cmd_b_filename_line {
4964     if (not eval { break_on_filename_line(@_); 1 }) {
4965         local $\ = '';
4966         print $OUT $@ and return;
4967     }
4968
4969     return;
4970 }
4971
4972 =head3 break_on_filename_line(file, line, [condition]) (API)
4973
4974 Switches to the file specified and then calls C<break_on_line> to set
4975 the breakpoint.
4976
4977 =cut
4978
4979 sub break_on_filename_line {
4980     my $f = shift;
4981     my $i = shift;
4982     my $cond = @_ ? shift(@_) : 1;
4983
4984     # Switch the magical hash temporarily.
4985     local *dbline = $main::{ '_<' . $f };
4986
4987     # Localize the variables that break_on_line uses to make its message.
4988     local $filename_error = " of '$f'";
4989     local $filename       = $f;
4990
4991     # Add the breakpoint.
4992     break_on_line( $i, $cond );
4993
4994     return;
4995 } ## end sub break_on_filename_line
4996
4997 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4998
4999 Switch to another file, search the range of lines specified for an
5000 executable one, and put a breakpoint on the first one you find.
5001
5002 =cut
5003
5004 sub break_on_filename_line_range {
5005     my $f = shift;
5006     my $from = shift;
5007     my $to = shift;
5008     my $cond = @_ ? shift(@_) : 1;
5009
5010     # Find a breakable line if there is one.
5011     my $i = breakable_line_in_filename( $f, $from, $to );
5012
5013     # Add the breakpoint.
5014     break_on_filename_line( $f, $i, $cond );
5015
5016     return;
5017 } ## end sub break_on_filename_line_range
5018
5019 =head3 subroutine_filename_lines(subname, [condition]) (API)
5020
5021 Search for a subroutine within a given file. The condition is ignored.
5022 Uses C<find_sub> to locate the desired subroutine.
5023
5024 =cut
5025
5026 sub subroutine_filename_lines {
5027     my ( $subname ) = @_;
5028
5029     # Returned value from find_sub() is fullpathname:startline-endline.
5030     # The match creates the list (fullpathname, start, end).
5031     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5032 } ## end sub subroutine_filename_lines
5033
5034 =head3 break_subroutine(subname) (API)
5035
5036 Places a break on the first line possible in the specified subroutine. Uses
5037 C<subroutine_filename_lines> to find the subroutine, and
5038 C<break_on_filename_line_range> to place the break.
5039
5040 =cut
5041
5042 sub break_subroutine {
5043     my $subname = shift;
5044
5045     # Get filename, start, and end.
5046     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5047       or die "Subroutine $subname not found.\n";
5048
5049
5050     # Null condition changes to '1' (always true).
5051     my $cond = @_ ? shift(@_) : 1;
5052
5053     # Put a break the first place possible in the range of lines
5054     # that make up this subroutine.
5055     break_on_filename_line_range( $file, $s, $e, $cond );
5056
5057     return;
5058 } ## end sub break_subroutine
5059
5060 =head3 cmd_b_sub(subname, [condition]) (command)
5061
5062 We take the incoming subroutine name and fully-qualify it as best we can.
5063
5064 =over 4
5065
5066 =item 1. If it's already fully-qualified, leave it alone.
5067
5068 =item 2. Try putting it in the current package.
5069
5070 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5071
5072 =item 4. If it starts with '::', put it in 'main::'.
5073
5074 =back
5075
5076 After all this cleanup, we call C<break_subroutine> to try to set the
5077 breakpoint.
5078
5079 =cut
5080
5081 sub cmd_b_sub {
5082     my $subname = shift;
5083     my $cond = @_ ? shift : 1;
5084
5085     # If the subname isn't a code reference, qualify it so that
5086     # break_subroutine() will work right.
5087     if ( ref($subname) ne 'CODE' ) {
5088
5089         # Not Perl 4.
5090         $subname =~ s/'/::/g;
5091         my $s = $subname;
5092
5093         # Put it in this package unless it's already qualified.
5094         if ($subname !~ /::/)
5095         {
5096             $subname = $package . '::' . $subname;
5097         };
5098
5099         # Requalify it into CORE::GLOBAL if qualifying it into this
5100         # package resulted in its not being defined, but only do so
5101         # if it really is in CORE::GLOBAL.
5102         my $core_name = "CORE::GLOBAL::$s";
5103         if ((!defined(&$subname))
5104                 and ($s !~ /::/)
5105                 and (defined &{$core_name}))
5106         {
5107             $subname = $core_name;
5108         }
5109
5110         # Put it in package 'main' if it has a leading ::.
5111         if ($subname =~ /\A::/)
5112         {
5113             $subname = "main" . $subname;
5114         }
5115     } ## end if ( ref($subname) ne 'CODE' ) {
5116
5117     # Try to set the breakpoint.
5118     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5119         local $\ = '';
5120         print {$OUT} $@;
5121         return;
5122     }
5123
5124     return;
5125 } ## end sub cmd_b_sub
5126
5127 =head3 C<cmd_B> - delete breakpoint(s) (command)
5128
5129 The command mostly parses the command line and tries to turn the argument
5130 into a line spec. If it can't, it uses the current line. It then calls
5131 C<delete_breakpoint> to actually do the work.
5132
5133 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5134 thereby deleting all the breakpoints.
5135
5136 =cut
5137
5138 sub cmd_B {
5139     my $cmd = shift;
5140
5141     # No line spec? Use dbline.
5142     # If there is one, use it if it's non-zero, or wipe it out if it is.
5143     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5144     my $dbline = shift;
5145
5146     # If the line was dot, make the line the current one.
5147     $line =~ s/^\./$dbline/;
5148
5149     # If it's * we're deleting all the breakpoints.
5150     if ( $line eq '*' ) {
5151         if (not eval { delete_breakpoint(); 1 }) {
5152             print {$OUT} $@;
5153         }
5154     }
5155
5156     # If there is a line spec, delete the breakpoint on that line.
5157     elsif ( $line =~ /\A(\S.*)/ ) {
5158         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5159             local $\ = '';
5160             print {$OUT} $@;
5161         }
5162     } ## end elsif ($line =~ /^(\S.*)/)
5163
5164     # No line spec.
5165     else {
5166         print {$OUT}
5167           "Deleting a breakpoint requires a line number, or '*' for all\n"
5168           ;    # hint
5169     }
5170
5171     return;
5172 } ## end sub cmd_B
5173
5174 =head3 delete_breakpoint([line]) (API)
5175
5176 This actually does the work of deleting either a single breakpoint, or all
5177 of them.
5178
5179 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5180 just drop out with a message saying so. If it is, we remove the condition
5181 part of the 'condition\0action' that says there's a breakpoint here. If,
5182 after we've done that, there's nothing left, we delete the corresponding
5183 line in C<%dbline> to signal that no action needs to be taken for this line.
5184
5185 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5186 which lists all currently-loaded files which have breakpoints. We then look
5187 at each line in each of these files, temporarily switching the C<%dbline>
5188 and C<@dbline> structures to point to the files in question, and do what
5189 we did in the single line case: delete the condition in C<@dbline>, and
5190 delete the key in C<%dbline> if nothing's left.
5191
5192 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5193 C<%break_on_load>, because these structures contain breakpoints for files
5194 and code that haven't been loaded yet. We can just kill these off because there
5195 are no magical debugger structures associated with them.
5196
5197 =cut
5198
5199 sub _remove_breakpoint_entry {
5200     my ($fn, $i) = @_;
5201
5202     delete $dbline{$i};
5203     _delete_breakpoint_data_ref($fn, $i);
5204
5205     return;
5206 }
5207
5208 sub _delete_all_breakpoints {
5209     print {$OUT} "Deleting all breakpoints...\n";
5210
5211     # %had_breakpoints lists every file that had at least one
5212     # breakpoint in it.
5213     for my $fn ( keys %had_breakpoints ) {
5214
5215         # Switch to the desired file temporarily.
5216         local *dbline = $main::{ '_<' . $fn };
5217
5218         $max = $#dbline;
5219
5220         # For all lines in this file ...
5221         for my $i (1 .. $max) {
5222
5223             # If there's a breakpoint or action on this line ...
5224             if ( defined $dbline{$i} ) {
5225
5226                 # ... remove the breakpoint.
5227                 $dbline{$i} =~ s/\A[^\0]+//;
5228                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5229                     # Remove the entry altogether if no action is there.
5230                     _remove_breakpoint_entry($fn, $i);
5231                 }
5232             } ## end if (defined $dbline{$i...
5233         } ## end for $i (1 .. $max)
5234
5235         # If, after we turn off the "there were breakpoints in this file"
5236         # bit, the entry in %had_breakpoints for this file is zero,
5237         # we should remove this file from the hash.
5238         if ( not $had_breakpoints{$fn} &= (~1) ) {
5239             delete $had_breakpoints{$fn};
5240         }
5241     } ## end for my $fn (keys %had_breakpoints)
5242
5243     # Kill off all the other breakpoints that are waiting for files that
5244     # haven't been loaded yet.
5245     undef %postponed;
5246     undef %postponed_file;
5247     undef %break_on_load;
5248
5249     return;
5250 }
5251
5252 sub _delete_breakpoint_from_line {
5253     my ($i) = @_;
5254
5255     # Woops. This line wasn't breakable at all.
5256     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5257
5258     # Kill the condition, but leave any action.
5259     $dbline{$i} =~ s/\A[^\0]*//;
5260
5261     # Remove the entry entirely if there's no action left.
5262     if ($dbline{$i} eq '') {
5263         _remove_breakpoint_entry($filename, $i);
5264     }
5265
5266     return;
5267 }
5268
5269 sub delete_breakpoint {
5270     my $i = shift;
5271
5272     # If we got a line, delete just that one.
5273     if ( defined($i) ) {
5274         _delete_breakpoint_from_line($i);
5275     }
5276     # No line; delete them all.
5277     else {
5278         _delete_all_breakpoints();
5279     }
5280
5281     return;
5282 }
5283
5284 =head3 cmd_stop (command)
5285
5286 This is meant to be part of the new command API, but it isn't called or used
5287 anywhere else in the debugger. XXX It is probably meant for use in development
5288 of new commands.
5289
5290 =cut
5291
5292 sub cmd_stop {    # As on ^C, but not signal-safy.
5293     $signal = 1;
5294 }
5295
5296 =head3 C<cmd_e> - threads
5297
5298 Display the current thread id:
5299
5300     e
5301
5302 This could be how (when implemented) to send commands to this thread id (e cmd)
5303 or that thread id (e tid cmd).
5304
5305 =cut
5306
5307 sub cmd_e {
5308     my $cmd  = shift;
5309     my $line = shift;
5310     unless (exists($INC{'threads.pm'})) {
5311         print "threads not loaded($ENV{PERL5DB_THREADED})
5312         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5313     } else {
5314         my $tid = threads->tid;
5315         print "thread id: $tid\n";
5316     }
5317 } ## end sub cmd_e
5318
5319 =head3 C<cmd_E> - list of thread ids
5320
5321 Display the list of available thread ids:
5322
5323     E
5324
5325 This could be used (when implemented) to send commands to all threads (E cmd).
5326
5327 =cut
5328
5329 sub cmd_E {
5330     my $cmd  = shift;
5331     my $line = shift;
5332     unless (exists($INC{'threads.pm'})) {
5333         print "threads not loaded($ENV{PERL5DB_THREADED})
5334         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5335     } else {
5336         my $tid = threads->tid;
5337         print "thread ids: ".join(', ',
5338             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5339         )."\n";
5340     }
5341 } ## end sub cmd_E
5342
5343 =head3 C<cmd_h> - help command (command)
5344
5345 Does the work of either
5346
5347 =over 4
5348
5349 =item *
5350
5351 Showing all the debugger help
5352
5353 =item *
5354
5355 Showing help for a specific command
5356
5357 =back
5358
5359 =cut
5360
5361 use vars qw($help);
5362 use vars qw($summary);
5363
5364 sub cmd_h {
5365     my $cmd = shift;
5366
5367     # If we have no operand, assume null.
5368     my $line = shift || '';
5369
5370     # 'h h'. Print the long-format help.
5371     if ( $line =~ /\Ah\s*\z/ ) {
5372         print_help($help);
5373     }
5374
5375     # 'h <something>'. Search for the command and print only its help.
5376     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5377
5378         # support long commands; otherwise bogus errors
5379         # happen when you ask for h on <CR> for example
5380         my $qasked = quotemeta($asked);    # for searching; we don't
5381                                            # want to use it as a pattern.
5382                                            # XXX: finds CR but not <CR>
5383
5384         # Search the help string for the command.
5385         if (
5386             $help =~ /^                    # Start of a line
5387                       <?                   # Optional '<'
5388                       (?:[IB]<)            # Optional markup
5389                       $qasked              # The requested command
5390                      /mx
5391           )
5392         {
5393
5394             # It's there; pull it out and print it.
5395             while (
5396                 $help =~ /^
5397                               (<?            # Optional '<'
5398                                  (?:[IB]<)   # Optional markup
5399                                  $qasked     # The command
5400                                  ([\s\S]*?)  # Description line(s)
5401                               \n)            # End of last description line
5402                               (?!\s)         # Next line not starting with
5403                                              # whitespace
5404                              /mgx
5405               )
5406             {
5407                 print_help($1);
5408             }
5409         }
5410
5411         # Not found; not a debugger command.
5412         else {
5413             print_help("B<$asked> is not a debugger command.\n");
5414         }
5415     } ## end elsif ($line =~ /^(\S.*)$/)
5416
5417     # 'h' - print the summary help.
5418     else {
5419         print_help($summary);
5420     }
5421 } ## end sub cmd_h
5422
5423 =head3 C<cmd_i> - inheritance display
5424
5425 Display the (nested) parentage of the module or object given.
5426
5427 =cut
5428
5429 sub cmd_i {
5430     my $cmd  = shift;
5431     my $line = shift;
5432     foreach my $isa ( split( /\s+/, $line ) ) {
5433         $evalarg = $isa;
5434         ($isa) = DB::eval();
5435         no strict 'refs';
5436         print join(
5437             ', ',
5438             map {
5439                 "$_"
5440                   . (
5441                     defined( ${"$_\::VERSION"} )
5442                     ? ' ' . ${"$_\::VERSION"}
5443                     : undef )
5444               } @{mro::get_linear_isa(ref($isa) || $isa)}
5445         );
5446         print "\n";
5447     }
5448 } ## end sub cmd_i
5449
5450 =head3 C<cmd_l> - list lines (command)
5451
5452 Most of the command is taken up with transforming all the different line
5453 specification syntaxes into 'start-stop'. After that is done, the command
5454 runs a loop over C<@dbline> for the specified range of lines. It handles
5455 the printing of each line and any markers (C<==E<gt>> for current line,
5456 C<b> for break on this line, C<a> for action on this line, C<:> for this
5457 line breakable).
5458
5459 We save the last line listed in the C<$start> global for further listing
5460 later.
5461
5462 =cut
5463
5464 sub _min {
5465     my $min = shift;
5466     foreach my $v (@_) {
5467         if ($min > $v) {
5468             $min = $v;
5469         }
5470     }
5471     return $min;
5472 }
5473
5474 sub _max {
5475     my $max = shift;
5476     foreach my $v (@_) {
5477         if ($max < $v) {
5478             $max = $v;
5479         }
5480     }
5481     return $max;
5482 }
5483
5484 sub _minify_to_max {
5485     my $ref = shift;
5486
5487     $$ref = _min($$ref, $max);
5488
5489     return;
5490 }
5491
5492 sub _cmd_l_handle_var_name {
5493     my $var_name = shift;
5494
5495     $evalarg = $var_name;
5496
5497     my ($s) = DB::eval();
5498
5499     # Ooops. Bad scalar.
5500     if ($@) {
5501         print {$OUT} "Error: $@\n";
5502         next CMD;
5503     }
5504
5505     # Good scalar. If it's a reference, find what it points to.
5506     $s = CvGV_name($s);
5507     print {$OUT} "Interpreted as: $1 $s\n";
5508     $line = "$1 $s";
5509
5510     # Call self recursively to really do the command.
5511     return _cmd_l_main( $s );
5512 }
5513
5514 sub _cmd_l_handle_subname {
5515
5516     my $s = $subname;
5517
5518     # De-Perl4.
5519     $subname =~ s/\'/::/;
5520
5521     # Put it in this package unless it starts with ::.
5522     $subname = $package . "::" . $subname unless $subname =~ /::/;
5523
5524     # Put it in CORE::GLOBAL if t doesn't start with :: and
5525     # it doesn't live in this package and it lives in CORE::GLOBAL.
5526     $subname = "CORE::GLOBAL::$s"
5527     if not defined &$subname
5528         and $s !~ /::/
5529         and defined &{"CORE::GLOBAL::$s"};
5530
5531     # Put leading '::' names into 'main::'.
5532     $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5533
5534     # Get name:start-stop from find_sub, and break this up at
5535     # colons.
5536     my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5537
5538     # Pull off start-stop.
5539     my $subrange = pop @pieces;
5540
5541     # If the name contained colons, the split broke it up.
5542     # Put it back together.
5543     $file = join( ':', @pieces );
5544
5545     # If we're not in that file, switch over to it.
5546     if ( $file ne $filename ) {
5547         if (! $slave_editor) {
5548             print {$OUT} "Switching to file '$file'.\n";
5549         }
5550
5551         # Switch debugger's magic structures.
5552         *dbline   = $main::{ '_<' . $file };
5553         $max      = $#dbline;
5554         $filename = $file;
5555     } ## end if ($file ne $filename)
5556
5557     # Subrange is 'start-stop'. If this is less than a window full,
5558     # swap it to 'start+', which will list a window from the start point.
5559     if ($subrange) {
5560         if ( eval($subrange) < -$window ) {
5561             $subrange =~ s/-.*/+/;
5562         }
5563
5564         # Call self recursively to list the range.
5565         return _cmd_l_main( $subrange );
5566     } ## end if ($subrange)
5567
5568     # Couldn't find it.
5569     else {
5570         print {$OUT} "Subroutine $subname not found.\n";
5571         return;
5572     }
5573 }
5574
5575 sub _cmd_l_empty {
5576     # Compute new range to list.
5577     $incr = $window - 1;
5578
5579     # Recurse to do it.
5580     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5581 }
5582
5583 sub _cmd_l_plus {
5584     my ($new_start, $new_incr) = @_;
5585
5586     # Don't reset start for 'l +nnn'.
5587     $start = $new_start if $new_start;
5588
5589     # Increment for list. Use window size if not specified.
5590     # (Allows 'l +' to work.)
5591     $incr = $new_incr || ($window - 1);
5592
5593     # Create a line range we'll understand, and recurse to do it.
5594     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5595 }
5596
5597 sub _cmd_l_calc_initial_end_and_i {
5598     my ($spec, $start_match, $end_match) = @_;
5599
5600     # Determine end point; use end of file if not specified.
5601     my $end = ( !defined $start_match ) ? $max :
5602     ( $end_match ? $end_match : $start_match );
5603
5604     # Go on to the end, and then stop.
5605     _minify_to_max(\$end);
5606
5607     # Determine start line.
5608     my $i = $start_match;
5609
5610     if ($i eq '.') {
5611         $i = $spec;
5612     }
5613
5614     $i = _max($i, 1);
5615
5616     $incr = $end - $i;
5617
5618     return ($end, $i);
5619 }
5620
5621 sub _cmd_l_range {
5622     my ($spec, $current_line, $start_match, $end_match) = @_;
5623
5624     my ($end, $i) =
5625         _cmd_l_calc_initial_end_and_i($spec, $start_match, $end_match);
5626
5627     # If we're running under a slave editor, force it to show the lines.
5628     if ($slave_editor) {
5629         print {$OUT} "\032\032$filename:$i:0\n";
5630         $i = $end;
5631     }
5632     # We're doing it ourselves. We want to show the line and special
5633     # markers for:
5634     # - the current line in execution
5635     # - whether a line is breakable or not
5636     # - whether a line has a break or not
5637     # - whether a line has an action or not
5638     else {
5639         I_TO_END:
5640         for ( ; $i <= $end ; $i++ ) {
5641
5642             # Check for breakpoints and actions.
5643             my ( $stop, $action );
5644             if ($dbline{$i}) {
5645                 ( $stop, $action ) = split( /\0/, $dbline{$i} );
5646             }
5647
5648             # ==> if this is the current line in execution,
5649             # : if it's breakable.
5650             my $arrow =
5651             ( $i == $current_line and $filename eq $filename_ini )
5652             ? '==>'
5653             : ( $dbline[$i] + 0 ? ':' : ' ' );
5654
5655             # Add break and action indicators.
5656             $arrow .= 'b' if $stop;
5657             $arrow .= 'a' if $action;
5658
5659             # Print the line.
5660             print {$OUT} "$i$arrow\t", $dbline[$i];
5661
5662             # Move on to the next line. Drop out on an interrupt.
5663             if ($signal) {
5664                 $i++;
5665                 last I_TO_END;
5666             }
5667         } ## end for (; $i <= $end ; $i++)
5668
5669         # Line the prompt up; print a newline if the last line listed
5670         # didn't have a newline.
5671         if ($dbline[ $i - 1 ] !~ /\n\z/) {
5672             print {$OUT} "\n";
5673         }
5674     } ## end else [ if ($slave_editor)
5675
5676     # Save the point we last listed to in case another relative 'l'
5677     # command is desired. Don't let it run off the end.
5678     $start = $i;
5679     _minify_to_max(\$start);
5680
5681     return;
5682 }
5683
5684 sub _cmd_l_main {
5685     my $spec = shift;
5686
5687     # If this is '-something', delete any spaces after the dash.
5688     $spec =~ s/\A-\s*\z/-/;
5689
5690     # If the line is '$something', assume this is a scalar containing a
5691     # line number.
5692     # Set up for DB::eval() - evaluate in *user* context.
5693     if ( my ($var_name) = $spec =~ /\A(\$.*)/s ) {
5694         return _cmd_l_handle_var_name($var_name);
5695     }
5696     # l name. Try to find a sub by that name.
5697     elsif ( ($subname) = $spec =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5698         return _cmd_l_handle_subname();
5699     }
5700     # Bare 'l' command.
5701     elsif ( $spec !~ /\S/ ) {
5702         return _cmd_l_empty();
5703     }
5704     # l [start]+number_of_lines
5705     elsif ( my ($new_start, $new_incr) = $spec =~ /\A(\d*)\+(\d*)\z/ ) {
5706         return _cmd_l_plus($new_start, $new_incr);
5707     }
5708     # l start-stop or l start,stop
5709     elsif (my ($s, $e) = $spec =~ /^(?:(-?[\d\$\.]+)(?:[-,]([\d\$\.]+))?)?/ ) {
5710         return _cmd_l_range($spec, $line, $s, $e);
5711     }
5712
5713     return;
5714 } ## end sub cmd_l
5715
5716 sub cmd_l {
5717     my (undef, $line) = @_;
5718
5719     return _cmd_l_main($line);
5720 }
5721
5722 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5723
5724 To list breakpoints, the command has to look determine where all of them are
5725 first. It starts a C<%had_breakpoints>, which tells us what all files have
5726 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5727 magic source and breakpoint data structures) to the file, and then look
5728 through C<%dbline> for lines with breakpoints and/or actions, listing them
5729 out. We look through C<%postponed> not-yet-compiled subroutines that have
5730 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5731 that have breakpoints.
5732
5733 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5734
5735 =cut
5736
5737 sub _cmd_L_calc_arg {
5738     # If no argument, list everything. Pre-5.8.0 version always lists
5739     # everything
5740     my $arg = shift || 'abw';
5741     if ($CommandSet ne '580')
5742     {
5743         $arg = 'abw';
5744     }
5745
5746     return $arg;
5747 }
5748
5749 sub _cmd_L_calc_wanted_flags {
5750     my $arg = _cmd_L_calc_arg(shift);
5751
5752     return (map { index($arg, $_) >= 0 ? 1 : 0 } qw(a b w));
5753 }
5754
5755
5756 sub _cmd_L_handle_breakpoints {
5757     my ($handle_db_line) = @_;
5758
5759     BREAKPOINTS_SCAN:
5760     # Look in all the files with breakpoints...
5761     for my $file ( keys %had_breakpoints ) {
5762
5763         # Temporary switch to this file.
5764         local *dbline = $main::{ '_<' . $file };
5765
5766         # Set up to look through the whole file.
5767         $max = $#dbline;
5768         my $was;    # Flag: did we print something
5769         # in this file?
5770
5771         # For each line in the file ...
5772         for my $i (1 .. $max) {
5773
5774             # We've got something on this line.
5775             if ( defined $dbline{$i} ) {
5776
5777                 # Print the header if we haven't.
5778                 if (not $was++) {
5779                     print {$OUT} "$file:\n";
5780                 }
5781
5782                 # Print the line.
5783                 print {$OUT} " $i:\t", $dbline[$i];
5784
5785                 $handle_db_line->($dbline{$i});
5786
5787                 # Quit if the user hit interrupt.
5788                 if ($signal) {
5789                     last BREAKPOINTS_SCAN;
5790                 }
5791             } ## end if (defined $dbline{$i...
5792         } ## end for my $i (1 .. $max)
5793     } ## end for my $file (keys %had_breakpoints)
5794
5795     return;
5796 }
5797
5798 sub _cmd_L_handle_postponed_breakpoints {
5799     my ($handle_db_line) = @_;
5800
5801     print {$OUT} "Postponed breakpoints in files:\n";
5802
5803     POSTPONED_SCANS:
5804     for my $file ( keys %postponed_file ) {
5805         my $db = $postponed_file{$file};
5806         print {$OUT} " $file:\n";
5807         for my $line ( sort { $a <=> $b } keys %$db ) {
5808             print {$OUT} "  $line:\n";
5809
5810             $handle_db_line->($db->{$line});
5811
5812             if ($signal) {
5813                 last POSTPONED_SCANS;
5814             }
5815         }
5816         if ($signal) {
5817             last POSTPONED_SCANS;
5818         }
5819     }
5820
5821     return;
5822 }
5823
5824
5825 sub cmd_L {
5826     my $cmd = shift;
5827
5828     my ($action_wanted, $break_wanted, $watch_wanted) =
5829         _cmd_L_calc_wanted_flags(shift);
5830
5831     my $handle_db_line = sub {
5832         my ($l) = @_;
5833
5834         my ( $stop, $action ) = split( /\0/, $l );
5835
5836         if ($stop and $break_wanted) {
5837             print {$OUT} "    break if (", $stop, ")\n"
5838         }
5839
5840         if ($action && $action_wanted) {
5841             print {$OUT} "    action:  ", $action, "\n"
5842         }
5843
5844         return;
5845     };
5846
5847     # Breaks and actions are found together, so we look in the same place
5848     # for both.
5849     if ( $break_wanted or $action_wanted ) {
5850         _cmd_L_handle_breakpoints($handle_db_line);
5851     }
5852
5853     # Look for breaks in not-yet-compiled subs:
5854     if ( %postponed and $break_wanted ) {
5855         print {$OUT} "Postponed breakpoints in subroutines:\n";
5856         my $subname;
5857         SUBS_SCAN:
5858         for $subname ( keys %postponed ) {
5859             print {$OUT} " $subname\t$postponed{$subname}\n";
5860             if ($signal) {
5861                 last SUBS_SCAN;
5862             }
5863         }
5864     } ## end if (%postponed and $break_wanted)
5865
5866     # Find files that have not-yet-loaded breaks:
5867     my @have = map {    # Combined keys
5868         keys %{ $postponed_file{$_} }
5869     } keys %postponed_file;
5870
5871     # If there are any, list them.
5872     if ( @have and ( $break_wanted or $action_wanted ) ) {
5873         _cmd_L_handle_postponed_breakpoints($handle_db_line);
5874     } ## end if (@have and ($break_wanted...
5875
5876     if ( %break_on_load and $break_wanted ) {
5877         print {$OUT} "Breakpoints on load:\n";
5878         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5879             print {$OUT} " $filename\n";
5880             last BREAK_ON_LOAD if $signal;
5881         }
5882     } ## end if (%break_on_load and...
5883
5884     if ($watch_wanted and ( $trace & 2 )) {
5885         print {$OUT} "Watch-expressions:\n" if @to_watch;
5886         TO_WATCH: for my $expr (@to_watch) {
5887             print {$OUT} " $expr\n";
5888             last TO_WATCH if $signal;
5889         }
5890     }
5891
5892     return;
5893 } ## end sub cmd_L
5894
5895 =head3 C<cmd_M> - list modules (command)
5896
5897 Just call C<list_modules>.
5898
5899 =cut
5900
5901 sub cmd_M {
5902     list_modules();
5903
5904     return;
5905 }
5906
5907 =head3 C<cmd_o> - options (command)
5908
5909 If this is just C<o> by itself, we list the current settings via
5910 C<dump_option>. If there's a nonblank value following it, we pass that on to
5911 C<parse_options> for processing.
5912
5913 =cut
5914
5915 sub cmd_o {
5916     my $cmd = shift;
5917     my $opt = shift || '';    # opt[=val]
5918
5919     # Nonblank. Try to parse and process.
5920     if ( $opt =~ /^(\S.*)/ ) {
5921         parse_options($1);
5922     }
5923
5924     # Blank. List the current option settings.
5925     else {
5926         for (@options) {
5927             dump_option($_);
5928         }
5929     }
5930 } ## end sub cmd_o
5931
5932 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5933
5934 Advises the user that the O command has been renamed.
5935
5936 =cut
5937
5938 sub cmd_O {
5939     print $OUT "The old O command is now the o command.\n";             # hint
5940     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5941     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5942 }
5943
5944 =head3 C<cmd_v> - view window (command)
5945
5946 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5947 move back a few lines to list the selected line in context. Uses C<cmd_l>
5948 to do the actual listing after figuring out the range of line to request.
5949
5950 =cut
5951
5952 use vars qw($preview);
5953
5954 sub cmd_v {
5955     my $cmd  = shift;
5956     my $line = shift;
5957
5958     # Extract the line to list around. (Astute readers will have noted that
5959     # this pattern will match whether or not a numeric line is specified,
5960     # which means that we'll always enter this loop (though a non-numeric
5961     # argument results in no action at all)).
5962     if ( $line =~ /^(\d*)$/ ) {
5963
5964         # Total number of lines to list (a windowful).
5965         $incr = $window - 1;
5966
5967         # Set the start to the argument given (if there was one).
5968         $start = $1 if $1;
5969
5970         # Back up by the context amount.
5971         $start -= $preview;
5972
5973         # Put together a linespec that cmd_l will like.
5974         $line = $start . '-' . ( $start + $incr );
5975
5976         # List the lines.
5977         cmd_l( 'l', $line );
5978     } ## end if ($line =~ /^(\d*)$/)
5979 } ## end sub cmd_v
5980
5981 =head3 C<cmd_w> - add a watch expression (command)
5982
5983 The 5.8 version of this command adds a watch expression if one is specified;
5984 it does nothing if entered with no operands.
5985
5986 We extract the expression, save it, evaluate it in the user's context, and
5987 save the value. We'll re-evaluate it each time the debugger passes a line,
5988 and will stop (see the code at the top of the command loop) if the value
5989 of any of the expressions changes.
5990
5991 =cut
5992
5993 sub _add_watch_expr {
5994     my $expr = shift;
5995
5996     # ... save it.
5997     push @to_watch, $expr;
5998
5999     # Parameterize DB::eval and call it to get the expression's value
6000     # in the user's context. This version can handle expressions which
6001     # return a list value.
6002     $evalarg = $expr;
6003     my ($val) = join( ' ', DB::eval() );
6004     $val = ( defined $val ) ? "'$val'" : 'undef';
6005
6006     # Save the current value of the expression.
6007     push @old_watch, $val;
6008
6009     # We are now watching expressions.
6010     $trace |= 2;
6011
6012     return;
6013 }
6014
6015 sub cmd_w {
6016     my $cmd = shift;
6017
6018     # Null expression if no arguments.
6019     my $expr = shift || '';
6020
6021     # If expression is not null ...
6022     if ( $expr =~ /\A\S/ ) {
6023         _add_watch_expr($expr);
6024     } ## end if ($expr =~ /^(\S.*)/)
6025
6026     # You have to give one to get one.
6027     else {
6028         print $OUT "Adding a watch-expression requires an expression\n";  # hint
6029     }
6030
6031     return;
6032 }
6033
6034 =head3 C<cmd_W> - delete watch expressions (command)
6035
6036 This command accepts either a watch expression to be removed from the list
6037 of watch expressions, or C<*> to delete them all.
6038
6039 If C<*> is specified, we simply empty the watch expression list and the
6040 watch expression value list. We also turn off the bit that says we've got
6041 watch expressions.
6042
6043 If an expression (or partial expression) is specified, we pattern-match
6044 through the expressions and remove the ones that match. We also discard
6045 the corresponding values. If no watch expressions are left, we turn off
6046 the I<watching expressions> bit.
6047
6048 =cut
6049
6050 sub cmd_W {
6051     my $cmd  = shift;
6052     my $expr = shift || '';
6053
6054     # Delete them all.
6055     if ( $expr eq '*' ) {
6056
6057         # Not watching now.
6058         $trace &= ~2;
6059
6060         print $OUT "Deleting all watch expressions ...\n";
6061
6062         # And all gone.
6063         @to_watch = @old_watch = ();
6064     }
6065
6066     # Delete one of them.
6067     elsif ( $expr =~ /^(\S.*)/ ) {
6068
6069         # Where we are in the list.
6070         my $i_cnt = 0;
6071
6072         # For each expression ...
6073         foreach (@to_watch) {
6074             my $val = $to_watch[$i_cnt];
6075
6076             # Does this one match the command argument?
6077             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
6078                                       # Yes. Turn it off, and its value too.
6079                 splice( @to_watch,  $i_cnt, 1 );
6080                 splice( @old_watch, $i_cnt, 1 );
6081             }
6082             $i_cnt++;
6083         } ## end foreach (@to_watch)
6084
6085         # We don't bother to turn watching off because
6086         #  a) we don't want to stop calling watchfunction() if it exists
6087         #  b) foreach over a null list doesn't do anything anyway
6088
6089     } ## end elsif ($expr =~ /^(\S.*)/)
6090
6091     # No command arguments entered.
6092     else {
6093         print $OUT
6094           "Deleting a watch-expression requires an expression, or '*' for all\n"
6095           ;    # hint
6096     }
6097 } ## end sub cmd_W
6098
6099 ### END of the API section
6100
6101 =head1 SUPPORT ROUTINES
6102
6103 These are general support routines that are used in a number of places
6104 throughout the debugger.
6105
6106 =head2 save
6107
6108 save() saves the user's versions of globals that would mess us up in C<@saved>,
6109 and installs the versions we like better.
6110
6111 =cut
6112
6113 sub save {
6114
6115     # Save eval failure, command failure, extended OS error, output field
6116     # separator, input record separator, output record separator and
6117     # the warning setting.
6118     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
6119
6120     $,  = "";      # output field separator is null string
6121     $/  = "\n";    # input record separator is newline
6122     $\  = "";      # output record separator is null string
6123     $^W = 0;       # warnings are off
6124 } ## end sub save
6125
6126 =head2 C<print_lineinfo> - show where we are now
6127
6128 print_lineinfo prints whatever it is that it is handed; it prints it to the
6129 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
6130 us to feed line information to a slave editor without messing up the
6131 debugger output.
6132
6133 =cut
6134
6135 sub print_lineinfo {
6136
6137     # Make the terminal sensible if we're not the primary debugger.
6138     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
6139     local $\ = '';
6140     local $, = '';
6141     print $LINEINFO @_;
6142 } ## end sub print_lineinfo
6143
6144 =head2 C<postponed_sub>
6145
6146 Handles setting postponed breakpoints in subroutines once they're compiled.
6147 For breakpoints, we use C<DB::find_sub> to locate the source file and line
6148 range for the subroutine, then mark the file as having a breakpoint,
6149 temporarily switch the C<*dbline> glob over to the source file, and then
6150 search the given range of lines to find a breakable line. If we find one,
6151 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6152
6153 =cut
6154
6155 # The following takes its argument via $evalarg to preserve current @_
6156
6157 sub postponed_sub {
6158
6159     # Get the subroutine name.
6160     my $subname = shift;
6161
6162     # If this is a 'break +<n> if <condition>' ...
6163     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6164
6165         # If there's no offset, use '+0'.
6166         my $offset = $1 || 0;
6167
6168         # find_sub's value is 'fullpath-filename:start-stop'. It's
6169         # possible that the filename might have colons in it too.
6170         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6171         if ($i) {
6172
6173             # We got the start line. Add the offset '+<n>' from
6174             # $postponed{subname}.
6175             $i += $offset;
6176
6177             # Switch to the file this sub is in, temporarily.
6178             local *dbline = $main::{ '_<' . $file };
6179
6180             # No warnings, please.
6181             local $^W = 0;    # != 0 is magical below
6182
6183             # This file's got a breakpoint in it.
6184             $had_breakpoints{$file} |= 1;
6185
6186             # Last line in file.
6187             $max = $#dbline;
6188
6189             # Search forward until we hit a breakable line or get to
6190             # the end of the file.
6191             ++$i until $dbline[$i] != 0 or $i >= $max;
6192
6193             # Copy the breakpoint in and delete it from %postponed.
6194             $dbline{$i} = delete $postponed{$subname};
6195         } ## end if ($i)
6196
6197         # find_sub didn't find the sub.
6198         else {
6199             local $\ = '';
6200             print $OUT "Subroutine $subname not found.\n";
6201         }
6202         return;
6203     } ## end if ($postponed{$subname...
6204     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6205
6206     #print $OUT "In postponed_sub for '$subname'.\n";
6207 } ## end sub postponed_sub
6208
6209 =head2 C<postponed>
6210
6211 Called after each required file is compiled, but before it is executed;
6212 also called if the name of a just-compiled subroutine is a key of
6213 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6214 etc.) into the just-compiled code.
6215
6216 If this is a C<require>'d file, the incoming parameter is the glob
6217 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6218
6219 If it's a subroutine, the incoming parameter is the subroutine name.
6220
6221 =cut
6222
6223 sub postponed {
6224
6225     # If there's a break, process it.
6226     if ($ImmediateStop) {
6227
6228         # Right, we've stopped. Turn it off.
6229         $ImmediateStop = 0;
6230
6231         # Enter the command loop when DB::DB gets called.
6232         $signal = 1;
6233     }
6234
6235     # If this is a subroutine, let postponed_sub() deal with it.
6236     if (ref(\$_[0]) ne 'GLOB') {
6237         return postponed_sub(@_);
6238     }
6239
6240     # Not a subroutine. Deal with the file.
6241     local *dbline = shift;
6242     my $filename = $dbline;
6243     $filename =~ s/^_<//;
6244     local $\ = '';
6245     $signal = 1, print $OUT "'$filename' loaded...\n"
6246       if $break_on_load{$filename};
6247     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6248
6249     # Do we have any breakpoints to put in this file?
6250     return unless $postponed_file{$filename};
6251
6252     # Yes. Mark this file as having breakpoints.
6253     $had_breakpoints{$filename} |= 1;
6254
6255     # "Cannot be done: insufficient magic" - we can't just put the
6256     # breakpoints saved in %postponed_file into %dbline by assigning
6257     # the whole hash; we have to do it one item at a time for the
6258     # breakpoints to be set properly.
6259     #%dbline = %{$postponed_file{$filename}};
6260
6261     # Set the breakpoints, one at a time.
6262     my $key;
6263
6264     for $key ( keys %{ $postponed_file{$filename} } ) {
6265
6266         # Stash the saved breakpoint into the current file's magic line array.
6267         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6268     }
6269
6270     # This file's been compiled; discard the stored breakpoints.
6271     delete $postponed_file{$filename};
6272
6273 } ## end sub postponed
6274
6275 =head2 C<dumpit>
6276
6277 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6278
6279 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6280 a reference to a variable (the thing to be dumped) as its input.
6281
6282 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6283 the currently-selected filehandle, thank you very much). The current
6284 values of the package globals C<$single> and C<$trace> are backed up in
6285 lexicals, and they are turned off (this keeps the debugger from trying
6286 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6287 preserve its current value and it is set to zero to prevent entry/exit
6288 messages from printing, and C<$doret> is localized as well and set to -2 to
6289 prevent return values from being shown.
6290
6291 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6292 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6293 installed version in C<@INC>, yours will be used instead. Possible security
6294 problem?).
6295
6296 It then checks to see if the subroutine C<main::dumpValue> is now defined
6297 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6298 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6299 is called, and picks up the variable to be dumped from the parameter list.
6300
6301 It checks the package global C<%options> to see if there's a C<dumpDepth>
6302 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6303 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6304 structure: -1 means dump everything.
6305
6306 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6307 warning.
6308
6309 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6310 and we then return to the caller.
6311
6312 =cut
6313
6314 sub dumpit {
6315
6316     # Save the current output filehandle and switch to the one
6317     # passed in as the first parameter.
6318     my $savout = select(shift);
6319
6320     # Save current settings of $single and $trace, and then turn them off.
6321     my $osingle = $single;
6322     my $otrace  = $trace;
6323     $single = $trace = 0;
6324
6325     # XXX Okay, what do $frame and $doret do, again?
6326     local $frame = 0;
6327     local $doret = -2;
6328
6329     # Load dumpvar.pl unless we've already got the sub we need from it.
6330     unless ( defined &main::dumpValue ) {
6331         do 'dumpvar.pl' or die $@;
6332     }
6333
6334     # If the load succeeded (or we already had dumpvalue()), go ahead
6335     # and dump things.
6336     if ( defined &main::dumpValue ) {
6337         local $\ = '';
6338         local $, = '';
6339         local $" = ' ';
6340         my $v = shift;
6341         my $maxdepth = shift || $option{dumpDepth};
6342         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6343         main::dumpValue( $v, $maxdepth );
6344     } ## end if (defined &main::dumpValue)
6345
6346     # Oops, couldn't load dumpvar.pl.
6347     else {
6348         local $\ = '';
6349         print $OUT "dumpvar.pl not available.\n";
6350     }
6351
6352     # Reset $single and $trace to their old values.
6353     $single = $osingle;
6354     $trace  = $otrace;
6355
6356     # Restore the old filehandle.
6357     select($savout);
6358 } ## end sub dumpit
6359
6360 =head2 C<print_trace>
6361
6362 C<print_trace>'s job is to print a stack trace. It does this via the
6363 C<dump_trace> routine, which actually does all the ferreting-out of the
6364 stack trace data. C<print_trace> takes care of formatting it nicely and
6365 printing it to the proper filehandle.
6366
6367 Parameters:
6368
6369 =over 4
6370
6371 =item *
6372
6373 The filehandle to print to.
6374
6375 =item *
6376
6377 How many frames to skip before starting trace.
6378
6379 =item *
6380
6381 How many frames to print.
6382
6383 =item *
6384
6385 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6386
6387 =back
6388
6389 The original comment below seems to be noting that the traceback may not be
6390 correct if this routine is called in a tied method.
6391
6392 =cut
6393
6394 # Tied method do not create a context, so may get wrong message:
6395
6396 sub print_trace {
6397     local $\ = '';
6398     my $fh = shift;
6399
6400     # If this is going to a slave editor, but we're not the primary
6401     # debugger, reset it first.
6402     resetterm(1)
6403       if $fh        eq $LINEINFO    # slave editor
6404       and $LINEINFO eq $OUT         # normal output
6405       and $term_pid != $$;          # not the primary
6406
6407     # Collect the actual trace information to be formatted.
6408     # This is an array of hashes of subroutine call info.
6409     my @sub = dump_trace( $_[0] + 1, $_[1] );
6410
6411     # Grab the "short report" flag from @_.
6412     my $short = $_[2];              # Print short report, next one for sub name
6413
6414     # Run through the traceback info, format it, and print it.
6415     my $s;
6416     for my $i (0 .. $#sub) {
6417
6418         # Drop out if the user has lost interest and hit control-C.
6419         last if $signal;
6420
6421         # Set the separator so arrays print nice.
6422         local $" = ', ';
6423
6424         # Grab and stringify the arguments if they are there.
6425         my $args =
6426           defined $sub[$i]{args}
6427           ? "(@{ $sub[$i]{args} })"
6428           : '';
6429
6430         # Shorten them up if $maxtrace says they're too long.
6431         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6432           if length $args > $maxtrace;
6433
6434         # Get the file name.
6435         my $file = $sub[$i]{file};
6436
6437         # Put in a filename header if short is off.
6438         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6439
6440         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6441         $s = $sub[$i]{'sub'};
6442         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6443
6444         # Short report uses trimmed file and sub names.
6445         if ($short) {
6446             my $sub = @_ >= 4 ? $_[3] : $s;
6447             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6448         } ## end if ($short)
6449
6450         # Non-short report includes full names.
6451         else {
6452             print $fh "$sub[$i]{context} = $s$args"
6453               . " called from $file"
6454               . " line $sub[$i]{line}\n";
6455         }
6456     } ## end for my $i (0 .. $#sub)
6457 } ## end sub print_trace
6458
6459 =head2 dump_trace(skip[,count])
6460
6461 Actually collect the traceback information available via C<caller()>. It does
6462 some filtering and cleanup of the data, but mostly it just collects it to
6463 make C<print_trace()>'s job easier.
6464
6465 C<skip> defines the number of stack frames to be skipped, working backwards
6466 from the most current. C<count> determines the total number of frames to
6467 be returned; all of them (well, the first 10^9) are returned if C<count>
6468 is omitted.
6469
6470 This routine returns a list of hashes, from most-recent to least-recent
6471 stack frame. Each has the following keys and values:
6472
6473 =over 4
6474
6475 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6476
6477 =item * C<sub> - subroutine name, or C<eval> information
6478
6479 =item * C<args> - undef, or a reference to an array of arguments
6480
6481 =item * C<file> - the file in which this item was defined (if any)
6482
6483 =item * C<line> - the line on which it was defined
6484
6485 =back
6486
6487 =cut
6488
6489 sub _dump_trace_calc_saved_single_arg
6490 {
6491     my ($nothard, $arg) = @_;
6492
6493     my $type;
6494     if ( not defined $arg ) {    # undefined parameter
6495         return "undef";
6496     }
6497
6498     elsif ( $nothard and tied $arg ) {    # tied parameter
6499         return "tied";
6500     }
6501     elsif ( $nothard and $type = ref $arg ) {    # reference
6502         return "ref($type)";
6503     }
6504     else {                                       # can be stringified
6505         local $_ =
6506         "$arg";    # Safe to stringify now - should not call f().
6507
6508         # Backslash any single-quotes or backslashes.
6509         s/([\'\\])/\\$1/g;
6510
6511         # Single-quote it unless it's a number or a colon-separated
6512         # name.
6513         s/(.*)/'$1'/s
6514         unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6515
6516         # Turn high-bit characters into meta-whatever.
6517         s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
6518
6519         # Turn control characters into ^-whatever.
6520         s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
6521
6522         return $_;
6523     }
6524 }
6525
6526 sub _dump_trace_calc_save_args {
6527     my ($nothard) = @_;
6528
6529     return [
6530         map { _dump_trace_calc_saved_single_arg($nothard, $_) } @args
6531     ];
6532 }
6533
6534 sub dump_trace {
6535
6536     # How many levels to skip.
6537     my $skip = shift;
6538
6539     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6540     # it's unlikely that we'll have more than a billion stack frames. If you
6541     # do, you've got an awfully big machine...)
6542     my $count = shift || 1e9;
6543
6544     # We increment skip because caller(1) is the first level *back* from
6545     # the current one.  Add $skip to the count of frames so we have a
6546     # simple stop criterion, counting from $skip to $count+$skip.
6547     $skip++;
6548     $count += $skip;
6549
6550     # These variables are used to capture output from caller();
6551     my ( $p, $file, $line, $sub, $h, $context );
6552
6553     my ( $e, $r, @sub, $args );
6554
6555     # XXX Okay... why'd we do that?
6556     my $nothard = not $frame & 8;
6557     local $frame = 0;
6558
6559     # Do not want to trace this.
6560     my $otrace = $trace;
6561     $trace = 0;
6562
6563     # Start out at the skip count.
6564     # If we haven't reached the number of frames requested, and caller() is
6565     # still returning something, stay in the loop. (If we pass the requested
6566     # number of stack frames, or we run out - caller() returns nothing - we
6567     # quit.
6568     # Up the stack frame index to go back one more level each time.
6569     for (
6570         my $i = $skip ;
6571         $i < $count
6572         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6573         $i++
6574     )
6575     {
6576
6577         # Go through the arguments and save them for later.
6578         my $save_args = _dump_trace_calc_save_args($nothard);
6579
6580         # If context is true, this is array (@)context.
6581         # If context is false, this is scalar ($) context.
6582         # If neither, context isn't defined. (This is apparently a 'can't
6583         # happen' trap.)
6584         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6585
6586         # if the sub has args ($h true), make an anonymous array of the
6587         # dumped args.
6588         $args = $h ? $save_args : undef;
6589
6590         # remove trailing newline-whitespace-semicolon-end of line sequence
6591         # from the eval text, if any.
6592         $e =~ s/\n\s*\;\s*\Z// if $e;
6593
6594         # Escape backslashed single-quotes again if necessary.
6595         $e =~ s/([\\\'])/\\$1/g if $e;
6596
6597         # if the require flag is true, the eval text is from a require.
6598         if ($r) {
6599             $sub = "require '$e'";
6600         }
6601
6602         # if it's false, the eval text is really from an eval.
6603         elsif ( defined $r ) {
6604             $sub = "eval '$e'";
6605         }
6606
6607         # If the sub is '(eval)', this is a block eval, meaning we don't
6608         # know what the eval'ed text actually was.
6609         elsif ( $sub eq '(eval)' ) {
6610             $sub = "eval {...}";
6611         }
6612
6613         # Stick the collected information into @sub as an anonymous hash.
6614         push(
6615             @sub,
6616             {
6617                 context => $context,
6618                 sub     => $sub,
6619                 args    => $args,
6620                 file    => $file,
6621                 line    => $line
6622             }
6623         );
6624
6625         # Stop processing frames if the user hit control-C.
6626         last if $signal;
6627     } ## end for ($i = $skip ; $i < ...
6628
6629     # Restore the trace value again.
6630     $trace = $otrace;
6631     @sub;
6632 } ## end sub dump_trace
6633
6634 =head2 C<action()>
6635
6636 C<action()> takes input provided as the argument to an add-action command,
6637 either pre- or post-, and makes sure it's a complete command. It doesn't do
6638 any fancy parsing; it just keeps reading input until it gets a string
6639 without a trailing backslash.
6640
6641 =cut
6642
6643 sub action {
6644     my $action = shift;
6645
6646     while ( $action =~ s/\\$// ) {
6647
6648         # We have a backslash on the end. Read more.
6649         $action .= gets();
6650     } ## end while ($action =~ s/\\$//)
6651
6652     # Return the assembled action.
6653     $action;
6654 } ## end sub action
6655
6656 =head2 unbalanced
6657
6658 This routine mostly just packages up a regular expression to be used
6659 to check that the thing it's being matched against has properly-matched
6660 curly braces.
6661
6662 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6663 speeds things up by only creating the qr//'ed expression once; if it's
6664 already defined, we don't try to define it again. A speed hack.
6665
6666 =cut
6667
6668 use vars qw($balanced_brace_re);
6669
6670 sub unbalanced {
6671
6672     # I hate using globals!
6673     $balanced_brace_re ||= qr{
6674         ^ \{
6675              (?:
6676                  (?> [^{}] + )              # Non-parens without backtracking
6677                 |
6678                  (??{ $balanced_brace_re }) # Group with matching parens
6679               ) *
6680           \} $
6681    }x;
6682     return $_[0] !~ m/$balanced_brace_re/;
6683 } ## end sub unbalanced
6684
6685 =head2 C<gets()>
6686
6687 C<gets()> is a primitive (very primitive) routine to read continuations.
6688 It was devised for reading continuations for actions.
6689 it just reads more input with C<readline()> and returns it.
6690
6691 =cut
6692
6693 sub gets {
6694     return DB::readline("cont: ");
6695 }
6696
6697 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6698
6699 The C<system()> function assumes that it can just go ahead and use STDIN and
6700 STDOUT, but under the debugger, we want it to use the debugger's input and
6701 outout filehandles.
6702
6703 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6704 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6705 and then puts everything back again.
6706
6707 =cut
6708
6709 sub _db_system {
6710
6711     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6712     # some non-Unix systems can do system() but have problems with fork().
6713     open( SAVEIN,  "<&STDIN" )  || db_warn("Can't save STDIN");
6714     open( SAVEOUT, ">&STDOUT" ) || db_warn("Can't save STDOUT");
6715     open( STDIN,   "<&IN" )     || db_warn("Can't redirect STDIN");
6716     open( STDOUT,  ">&OUT" )    || db_warn("Can't redirect STDOUT");
6717
6718     # XXX: using csh or tcsh destroys sigint retvals!
6719     system(@_);
6720     open( STDIN,  "<&SAVEIN" )  || db_warn("Can't restore STDIN");
6721     open( STDOUT, ">&SAVEOUT" ) || db_warn("Can't restore STDOUT");
6722     close(SAVEIN);
6723     close(SAVEOUT);
6724
6725     # most of the $? crud was coping with broken cshisms
6726     if ( $? >> 8 ) {
6727         db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6728     }
6729     elsif ($?) {
6730         db_warn(
6731             "(Command died of SIG#",
6732             ( $? & 127 ),
6733             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6734             ")", "\n"
6735         );
6736     } ## end elsif ($?)
6737
6738     return $?;
6739
6740 } ## end sub system
6741
6742 *system = \&_db_system;
6743
6744 =head1 TTY MANAGEMENT
6745
6746 The subs here do some of the terminal management for multiple debuggers.
6747
6748 =head2 setterm
6749
6750 Top-level function called when we want to set up a new terminal for use
6751 by the debugger.
6752
6753 If the C<noTTY> debugger option was set, we'll either use the terminal
6754 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6755 to find one. If we're a forked debugger, we call C<resetterm> to try to
6756 get a whole new terminal if we can.
6757
6758 In either case, we set up the terminal next. If the C<ReadLine> option was
6759 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6760 the appropriate attributes. We then
6761
6762 =cut
6763
6764 use vars qw($ornaments);
6765 use vars qw($rl_attribs);
6766
6767 sub setterm {
6768
6769     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6770     local $frame = 0;
6771     local $doret = -2;
6772     require Term::ReadLine;
6773
6774     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6775     if ($notty) {
6776         if ($tty) {
6777             my ( $i, $o ) = split $tty, /,/;
6778             $o = $i unless defined $o;
6779             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6780             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6781             $IN  = \*IN;
6782             $OUT = \*OUT;
6783             _autoflush($OUT);
6784         } ## end if ($tty)
6785
6786         # We don't have a TTY - try to find one via Term::Rendezvous.
6787         else {
6788             require Term::Rendezvous;
6789
6790             # See if we have anything to pass to Term::Rendezvous.
6791             # Use $HOME/.perldbtty$$ if not.
6792             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6793
6794             # Rendezvous and get the filehandles.
6795             my $term_rv = Term::Rendezvous->new( $rv );
6796             $IN  = $term_rv->IN;
6797             $OUT = $term_rv->OUT;
6798         } ## end else [ if ($tty)
6799     } ## end if ($notty)
6800
6801     # We're a daughter debugger. Try to fork off another TTY.
6802     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6803         resetterm(2);
6804     }
6805
6806     # If we shouldn't use Term::ReadLine, don't.
6807     if ( !$rl ) {
6808         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6809     }
6810
6811     # We're using Term::ReadLine. Get all the attributes for this terminal.
6812     else {
6813         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6814
6815         $rl_attribs = $term->Attribs;
6816         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6817           if defined $rl_attribs->{basic_word_break_characters}
6818           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6819         $rl_attribs->{special_prefixes} = '$@&%';
6820         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6821         $rl_attribs->{completion_function} = \&db_complete;
6822     } ## end else [ if (!$rl)
6823
6824     # Set up the LINEINFO filehandle.
6825     $LINEINFO = $OUT     unless defined $LINEINFO;
6826     $lineinfo = $console unless defined $lineinfo;
6827
6828     $term->MinLine(2);
6829
6830     load_hist();
6831
6832     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6833         $term->SetHistory(@hist);
6834     }
6835
6836     # XXX Ornaments are turned on unconditionally, which is not
6837     # always a good thing.
6838     ornaments($ornaments) if defined $ornaments;
6839     $term_pid = $$;
6840 } ## end sub setterm
6841
6842 sub load_hist {
6843     $histfile //= option_val("HistFile", undef);
6844     return unless defined $histfile;
6845     open my $fh, "<", $histfile or return;
6846     local $/ = "\n";
6847     @hist = ();
6848     while (<$fh>) {
6849         chomp;
6850         push @hist, $_;
6851     }
6852     close $fh;
6853 }
6854
6855 sub save_hist {
6856     return unless defined $histfile;
6857     eval { require File::Path } or return;
6858     eval { require File::Basename } or return;
6859     File::Path::mkpath(File::Basename::dirname($histfile));
6860     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6861     $histsize //= option_val("HistSize",100);
6862     my @copy = grep { $_ ne '?' } @hist;
6863     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6864     for ($start .. $#copy) {
6865         print $fh "$copy[$_]\n";
6866     }
6867     close $fh or die "Could not write '$histfile': $!";
6868 }
6869
6870 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6871
6872 When the process being debugged forks, or the process invokes a command
6873 via C<system()> which starts a new debugger, we need to be able to get a new
6874 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6875 fight over the terminal, and you can never quite be sure who's going to get the
6876 input you're typing.
6877
6878 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6879 is tasked with doing all the necessary operating system mojo to get a new
6880 TTY (and probably another window) and to direct the new debugger to read and
6881 write there.
6882
6883 The debugger provides C<get_fork_TTY> functions which work for TCP
6884 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6885 supported. You are encouraged to write C<get_fork_TTY> functions which
6886 work for I<your> platform and contribute them.
6887
6888 =head3 C<socket_get_fork_TTY>
6889
6890 =cut
6891
6892 sub connect_remoteport {
6893     require IO::Socket;
6894
6895     my $socket = IO::Socket::INET->new(
6896         Timeout  => '10',
6897         PeerAddr => $remoteport,
6898         Proto    => 'tcp',
6899     );
6900     if ( ! $socket ) {
6901         die "Unable to connect to remote host: $remoteport\n";
6902     }
6903     return $socket;
6904 }
6905
6906 sub socket_get_fork_TTY {
6907     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6908
6909     # Do I need to worry about setting $term?
6910
6911     reset_IN_OUT( $IN, $OUT );
6912     return '';
6913 }
6914
6915 =head3 C<xterm_get_fork_TTY>
6916
6917 This function provides the C<get_fork_TTY> function for X11. If a
6918 program running under the debugger forks, a new <xterm> window is opened and
6919 the subsidiary debugger is directed there.
6920
6921 The C<open()> call is of particular note here. We have the new C<xterm>
6922 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6923 command (which prints the device name of the TTY we'll want to use for input
6924 and output to STDOUT, then C<sleep> for a very long time, routing this output
6925 to file number 3. This way we can simply read from the <XT> filehandle (which
6926 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6927
6928 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6929 properly set up.
6930
6931 =cut
6932
6933 sub xterm_get_fork_TTY {
6934     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6935     open XT,
6936 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6937  sleep 10000000' |];
6938
6939     # Get the output from 'tty' and clean it up a little.
6940     my $tty = <XT>;
6941     chomp $tty;
6942
6943     $pidprompt = '';    # Shown anyway in titlebar
6944
6945     # We need $term defined or we can not switch to the newly created xterm
6946     if ($tty ne '' && !defined $term) {
6947         require Term::ReadLine;
6948         if ( !$rl ) {
6949             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6950         }
6951         else {
6952             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6953         }
6954     }
6955     # There's our new TTY.
6956     return $tty;
6957 } ## end sub xterm_get_fork_TTY
6958
6959 =head3 C<os2_get_fork_TTY>
6960
6961 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6962
6963 =cut
6964
6965 # This example function resets $IN, $OUT itself
6966 my $c_pipe = 0;
6967 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6968     local $\  = '';
6969     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6970     my %opt = ( title => "Daughter Perl debugger $pids $name",
6971         ($rl ? (read_by_key => 1) : ()) );
6972     require OS2::Process;
6973     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6974       or return;
6975     $pidprompt = '';    # Shown anyway in titlebar
6976     reset_IN_OUT($in, $out);
6977     $tty = '*reset*';
6978     return '';          # Indicate that reset_IN_OUT is called
6979 } ## end sub os2_get_fork_TTY
6980
6981 =head3 C<macosx_get_fork_TTY>
6982
6983 The Mac OS X version uses AppleScript to tell Terminal.app to create
6984 a new window.
6985
6986 =cut
6987
6988 # Notes about Terminal.app's AppleScript support,
6989 # (aka things that might break in future OS versions).
6990 #
6991 # The "do script" command doesn't return a reference to the new window
6992 # it creates, but since it appears frontmost and windows are enumerated
6993 # front to back, we can use "first window" === "window 1".
6994 #
6995 # Since "do script" is implemented by supplying the argument (plus a
6996 # return character) as terminal input, there's a potential race condition
6997 # where the debugger could beat the shell to reading the command.
6998 # To prevent this, we wait for the screen to clear before proceeding.
6999 #
7000 # 10.3 and 10.4:
7001 # There's no direct accessor for the tty device name, so we fiddle
7002 # with the window title options until it says what we want.
7003 #
7004 # 10.5:
7005 # There _is_ a direct accessor for the tty device name, _and_ there's
7006 # a new possible component of the window title (the name of the settings
7007 # set).  A separate version is needed.
7008
7009 my @script_versions=
7010
7011     ([237, <<'__LEOPARD__'],
7012 tell application "Terminal"
7013     do script "clear;exec sleep 100000"
7014     tell first tab of first window
7015         copy tty to thetty
7016         set custom title to "forked perl debugger"
7017         set title displays custom title to true
7018         repeat while (length of first paragraph of (get contents)) > 0
7019             delay 0.1
7020         end repeat
7021     end tell
7022 end tell
7023 thetty
7024 __LEOPARD__
7025
7026      [100, <<'__JAGUAR_TIGER__'],
7027 tell application "Terminal"
7028     do script "clear;exec sleep 100000"
7029     tell first window
7030         set title displays shell path to false
7031         set title displays window size to false
7032         set title displays file name to false
7033         set title displays device name to true
7034         set title displays custom title to true
7035         set custom title to ""
7036         copy "/dev/" & name to thetty
7037         set custom title to "forked perl debugger"
7038         repeat while (length of first paragraph of (get contents)) > 0
7039             delay 0.1
7040         end repeat
7041     end tell
7042 end tell
7043 thetty
7044 __JAGUAR_TIGER__
7045
7046 );
7047
7048 sub macosx_get_fork_TTY
7049 {
7050     my($version,$script,$pipe,$tty);
7051
7052     return unless $version=$ENV{TERM_PROGRAM_VERSION};
7053     foreach my $entry (@script_versions) {
7054         if ($version>=$entry->[0]) {
7055             $script=$entry->[1];
7056             last;
7057         }
7058     }
7059     return unless defined($script);
7060     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
7061     $tty=readline($pipe);
7062     close($pipe);
7063     return unless defined($tty) && $tty =~ m(^/dev/);
7064     chomp $tty;
7065     return $tty;
7066 }
7067
7068 =head2 C<create_IN_OUT($flags)>
7069
7070 Create a new pair of filehandles, pointing to a new TTY. If impossible,
7071 try to diagnose why.
7072
7073 Flags are:
7074
7075 =over 4
7076
7077 =item * 1 - Don't know how to create a new TTY.
7078
7079 =item * 2 - Debugger has forked, but we can't get a new TTY.
7080
7081 =item * 4 - standard debugger startup is happening.
7082
7083 =back
7084
7085 =cut
7086
7087 use vars qw($fork_TTY);
7088
7089 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
7090
7091     # If we know how to get a new TTY, do it! $in will have
7092     # the TTY name if get_fork_TTY works.
7093     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
7094
7095     # It used to be that
7096     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
7097
7098     if ( not defined $in ) {
7099         my $why = shift;
7100
7101         # We don't know how.
7102         print_help(<<EOP) if $why == 1;
7103 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
7104 EOP
7105
7106         # Forked debugger.
7107         print_help(<<EOP) if $why == 2;
7108 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
7109   This may be an asynchronous session, so the parent debugger may be active.
7110 EOP
7111
7112         # Note that both debuggers are fighting over the same input.
7113         print_help(<<EOP) if $why != 4;
7114   Since two debuggers fight for the same TTY, input is severely entangled.
7115
7116 EOP
7117         print_help(<<EOP);
7118   I know how to switch the output to a different window in xterms, OS/2
7119   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
7120   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
7121   B<DB::get_fork_TTY()> returning this.
7122
7123   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
7124   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
7125
7126 EOP
7127     } ## end if (not defined $in)
7128     elsif ( $in ne '' ) {
7129         TTY($in);
7130     }
7131     else {
7132         $console = '';    # Indicate no need to open-from-the-console
7133     }
7134     undef $fork_TTY;
7135 } ## end sub create_IN_OUT
7136
7137 =head2 C<resetterm>
7138
7139 Handles rejiggering the prompt when we've forked off a new debugger.
7140
7141 If the new debugger happened because of a C<system()> that invoked a
7142 program under the debugger, the arrow between the old pid and the new
7143 in the prompt has I<two> dashes instead of one.
7144
7145 We take the current list of pids and add this one to the end. If there
7146 isn't any list yet, we make one up out of the initial pid associated with
7147 the terminal and our new pid, sticking an arrow (either one-dashed or
7148 two dashed) in between them.
7149
7150 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
7151 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
7152 and try to do that.
7153
7154 =cut
7155
7156 sub resetterm {    # We forked, so we need a different TTY
7157
7158     # Needs to be passed to create_IN_OUT() as well.
7159     my $in = shift;
7160
7161     # resetterm(2): got in here because of a system() starting a debugger.
7162     # resetterm(1): just forked.
7163     my $systemed = $in > 1 ? '-' : '';
7164
7165     # If there's already a list of pids, add this to the end.
7166     if ($pids) {
7167         $pids =~ s/\]/$systemed->$$]/;
7168     }
7169
7170     # No pid list. Time to make one.
7171     else {
7172         $pids = "[$term_pid->$$]";
7173     }
7174
7175     # The prompt we're going to be using for this debugger.
7176     $pidprompt = $pids;
7177
7178     # We now 0wnz this terminal.
7179     $term_pid = $$;
7180
7181     # Just return if we're not supposed to try to create a new TTY.
7182     return unless $CreateTTY & $in;
7183
7184     # Try to create a new IN/OUT pair.
7185     create_IN_OUT($in);
7186 } ## end sub resetterm
7187
7188 =head2 C<readline>
7189
7190 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7191 the next line, print a message saying we got it, add it to the terminal
7192 history (if possible), and return it.
7193
7194 If there's nothing in the typeahead buffer, check the command filehandle stack.
7195 If there are any filehandles there, read from the last one, and return the line
7196 if we got one. If not, we pop the filehandle off and close it, and try the
7197 next one up the stack.
7198
7199 If we've emptied the filehandle stack, we check to see if we've got a socket
7200 open, and we read that and return it if we do. If we don't, we just call the
7201 core C<readline()> and return its value.
7202
7203 =cut
7204
7205 sub readline {
7206
7207     # Localize to prevent it from being smashed in the program being debugged.
7208     local $.;
7209
7210     # If there are stacked filehandles to read from ...
7211     # (Handle it before the typeahead, because we may call source/etc. from
7212     # the typeahead.)
7213     while (@cmdfhs) {
7214
7215         # Read from the last one in the stack.
7216         my $line = CORE::readline( $cmdfhs[-1] );
7217
7218         # If we got a line ...
7219         defined $line
7220           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7221           : close pop @cmdfhs;                            # Pop and close
7222     } ## end while (@cmdfhs)
7223
7224     # Pull a line out of the typeahead if there's stuff there.
7225     if (@typeahead) {
7226
7227         # How many lines left.
7228         my $left = @typeahead;
7229
7230         # Get the next line.
7231         my $got = shift @typeahead;
7232
7233         # Print a message saying we got input from the typeahead.
7234         local $\ = '';
7235         print $OUT "auto(-$left)", shift, $got, "\n";
7236
7237         # Add it to the terminal history (if possible).
7238         $term->AddHistory($got)
7239           if length($got) > 1
7240           and defined $term->Features->{addHistory};
7241         return $got;
7242     } ## end if (@typeahead)
7243
7244     # We really need to read some input. Turn off entry/exit trace and
7245     # return value printing.
7246     local $frame = 0;
7247     local $doret = -2;
7248
7249     # Nothing on the filehandle stack. Socket?
7250     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7251
7252         # Send anything we have to send.
7253         $OUT->write( join( '', @_ ) );
7254
7255         # Receive anything there is to receive.
7256         my $stuff = '';
7257         my $buf;
7258         my $first_time = 1;
7259
7260         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7261         {
7262             $first_time = 0;
7263             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7264                                             # XXX Don't know. You tell me.
7265         }
7266
7267         # What we got.
7268         return $stuff;
7269     } ## end if (ref $OUT and UNIVERSAL::isa...
7270
7271     # No socket. Just read from the terminal.
7272     else {
7273         return $term->readline(@_);
7274     }
7275 } ## end sub readline
7276
7277 =head1 OPTIONS SUPPORT ROUTINES
7278
7279 These routines handle listing and setting option values.
7280
7281 =head2 C<dump_option> - list the current value of an option setting
7282
7283 This routine uses C<option_val> to look up the value for an option.
7284 It cleans up escaped single-quotes and then displays the option and
7285 its value.
7286
7287 =cut
7288
7289 sub dump_option {
7290     my ( $opt, $val ) = @_;
7291     $val = option_val( $opt, 'N/A' );
7292     $val =~ s/([\\\'])/\\$1/g;
7293     printf $OUT "%20s = '%s'\n", $opt, $val;
7294 } ## end sub dump_option
7295
7296 sub options2remember {
7297     foreach my $k (@RememberOnROptions) {
7298         $option{$k} = option_val( $k, 'N/A' );
7299     }
7300     return %option;
7301 }
7302
7303 =head2 C<option_val> - find the current value of an option
7304
7305 This can't just be a simple hash lookup because of the indirect way that
7306 the option values are stored. Some are retrieved by calling a subroutine,
7307 some are just variables.
7308
7309 You must supply a default value to be used in case the option isn't set.
7310
7311 =cut
7312
7313 sub option_val {
7314     my ( $opt, $default ) = @_;
7315     my $val;
7316
7317     # Does this option exist, and is it a variable?
7318     # If so, retrieve the value via the value in %optionVars.
7319     if (    defined $optionVars{$opt}
7320         and defined ${ $optionVars{$opt} } )
7321     {
7322         $val = ${ $optionVars{$opt} };
7323     }
7324
7325     # Does this option exist, and it's a subroutine?
7326     # If so, call the subroutine via the ref in %optionAction
7327     # and capture the value.
7328     elsif ( defined $optionAction{$opt}
7329         and defined &{ $optionAction{$opt} } )
7330     {
7331         $val = &{ $optionAction{$opt} }();
7332     }
7333
7334     # If there's an action or variable for the supplied option,
7335     # but no value was set, use the default.
7336     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7337         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7338     {
7339         $val = $default;
7340     }
7341
7342     # Otherwise, do the simple hash lookup.
7343     else {
7344         $val = $option{$opt};
7345     }
7346
7347     # If the value isn't defined, use the default.
7348     # Then return whatever the value is.
7349     $val = $default unless defined $val;
7350     $val;
7351 } ## end sub option_val
7352
7353 =head2 C<parse_options>
7354
7355 Handles the parsing and execution of option setting/displaying commands.
7356
7357 An option entered by itself is assumed to be I<set me to 1> (the default value)
7358 if the option is a boolean one. If not, the user is prompted to enter a valid
7359 value or to query the current value (via C<option? >).
7360
7361 If C<option=value> is entered, we try to extract a quoted string from the
7362 value (if it is quoted). If it's not, we just use the whole value as-is.
7363
7364 We load any modules required to service this option, and then we set it: if
7365 it just gets stuck in a variable, we do that; if there's a subroutine to
7366 handle setting the option, we call that.
7367
7368 Finally, if we're running in interactive mode, we display the effect of the
7369 user's command back to the terminal, skipping this if we're setting things
7370 during initialization.
7371
7372 =cut
7373
7374 sub parse_options {
7375     my ($s) = @_;
7376     local $\ = '';
7377
7378     my $option;
7379
7380     # These options need a value. Don't allow them to be clobbered by accident.
7381     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7382       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7383       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7384     };
7385
7386     while (length($s)) {
7387         my $val_defaulted;
7388
7389         # Clean off excess leading whitespace.
7390         $s =~ s/^\s+// && next;
7391
7392         # Options are always all word characters, followed by a non-word
7393         # separator.
7394         if ($s !~ s/^(\w+)(\W?)//) {
7395             print {$OUT} "Invalid option '$s'\n";
7396             last;
7397         }
7398         my ( $opt, $sep ) = ( $1, $2 );
7399
7400         # Make sure that such an option exists.
7401         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7402           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7403
7404         unless ($matches) {
7405             print {$OUT} "Unknown option '$opt'\n";
7406             next;
7407         }
7408         if ($matches > 1) {
7409             print {$OUT} "Ambiguous option '$opt'\n";
7410             next;
7411         }
7412         my $val;
7413
7414         # '?' as separator means query, but must have whitespace after it.
7415         if ( "?" eq $sep ) {
7416             if ($s =~ /\A\S/) {
7417                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7418
7419                 last;
7420             }
7421
7422             #&dump_option($opt);
7423         } ## end if ("?" eq $sep)
7424
7425         # Separator is whitespace (or just a carriage return).
7426         # They're going for a default, which we assume is 1.
7427         elsif ( $sep !~ /\S/ ) {
7428             $val_defaulted = 1;
7429             $val           = "1";   #  this is an evil default; make 'em set it!
7430         }
7431
7432         # Separator is =. Trying to set a value.
7433         elsif ( $sep eq "=" ) {
7434
7435             # If quoted, extract a quoted string.
7436             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7437                 my $quote = $1;
7438                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7439             }
7440
7441             # Not quoted. Use the whole thing. Warn about 'option='.
7442             else {
7443                 $s =~ s/^(\S*)//;
7444                 $val = $1;
7445                 print OUT qq(Option better cleared using $opt=""\n)
7446                   unless length $val;
7447             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7448
7449         } ## end elsif ($sep eq "=")
7450
7451         # "Quoted" with [], <>, or {}.
7452         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7453             my ($end) =
7454               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7455             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7456               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7457             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7458         } ## end else [ if ("?" eq $sep)
7459
7460         # Exclude non-booleans from getting set to 1 by default.
7461         if ( $opt_needs_val{$option} && $val_defaulted ) {
7462             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7463             print {$OUT}
7464 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7465             next;
7466         } ## end if ($opt_needs_val{$option...
7467
7468         # Save the option value.
7469         $option{$option} = $val if defined $val;
7470
7471         # Load any module that this option requires.
7472         if ( defined($optionRequire{$option}) && defined($val) ) {
7473             eval qq{
7474             local \$frame = 0;
7475             local \$doret = -2;
7476             require '$optionRequire{$option}';
7477             1;
7478             } || die $@   # XXX: shouldn't happen
7479         }
7480
7481         # Set it.
7482         # Stick it in the proper variable if it goes in a variable.
7483         if (defined($optionVars{$option}) && defined($val)) {
7484             ${ $optionVars{$option} } = $val;
7485         }
7486
7487         # Call the appropriate sub if it gets set via sub.
7488         if (defined($optionAction{$option})
7489           && defined (&{ $optionAction{$option} })
7490           && defined ($val))
7491         {
7492           &{ $optionAction{$option} }($val);
7493         }
7494
7495         # Not initialization - echo the value we set it to.
7496         dump_option($option) if ($OUT ne \*STDERR);
7497     } ## end while (length)
7498 } ## end sub parse_options
7499
7500 =head1 RESTART SUPPORT
7501
7502 These routines are used to store (and restore) lists of items in environment
7503 variables during a restart.
7504
7505 =head2 set_list
7506
7507 Set_list packages up items to be stored in a set of environment variables
7508 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7509 the values). Values outside the standard ASCII charset are stored by encoding
7510 then as hexadecimal values.
7511
7512 =cut
7513
7514 sub set_list {
7515     my ( $stem, @list ) = @_;
7516     my $val;
7517
7518     # VAR_n: how many we have. Scalar assignment gets the number of items.
7519     $ENV{"${stem}_n"} = @list;
7520
7521     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7522     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7523     for my $i ( 0 .. $#list ) {
7524         $val = $list[$i];
7525         $val =~ s/\\/\\\\/g;
7526         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
7527         $ENV{"${stem}_$i"} = $val;
7528     } ## end for $i (0 .. $#list)
7529 } ## end sub set_list
7530
7531 =head2 get_list
7532
7533 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7534 back, and then pull VAR_0, VAR_1. etc. back out.
7535
7536 =cut
7537
7538 sub get_list {
7539     my $stem = shift;
7540     my @list;
7541     my $n = delete $ENV{"${stem}_n"};
7542     my $val;
7543     for my $i ( 0 .. $n - 1 ) {
7544         $val = delete $ENV{"${stem}_$i"};
7545         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7546         push @list, $val;
7547     }
7548     @list;
7549 } ## end sub get_list
7550
7551 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7552
7553 =head2 catch()
7554
7555 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7556 set an already-existing global scalar variable to a constant value. This
7557 avoids allocating any memory possibly in the middle of something that will
7558 get all confused if we do, particularly under I<unsafe signals>.
7559
7560 =cut
7561
7562 sub catch {
7563     $signal = 1;
7564     return;    # Put nothing on the stack - malloc/free land!
7565 }
7566
7567 =head2 C<warn()>
7568
7569 C<warn> emits a warning, by joining together its arguments and printing
7570 them, with couple of fillips.
7571
7572 If the composited message I<doesn't> end with a newline, we automatically
7573 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7574 to be set to the filehandle to be used to output warnings; it makes no
7575 assumptions about what filehandles are available.
7576
7577 =cut
7578
7579 sub _db_warn {
7580     my ($msg) = join( "", @_ );
7581     $msg .= ": $!\n" unless $msg =~ /\n$/;
7582     local $\ = '';
7583     print $OUT $msg;
7584 } ## end sub warn
7585
7586 *warn = \&_db_warn;
7587
7588 =head1 INITIALIZATION TTY SUPPORT
7589
7590 =head2 C<reset_IN_OUT>
7591
7592 This routine handles restoring the debugger's input and output filehandles
7593 after we've tried and failed to move them elsewhere.  In addition, it assigns
7594 the debugger's output filehandle to $LINEINFO if it was already open there.
7595
7596 =cut
7597
7598 sub reset_IN_OUT {
7599     my $switch_li = $LINEINFO eq $OUT;
7600
7601     # If there's a term and it's able to get a new tty, try to get one.
7602     if ( $term and $term->Features->{newTTY} ) {
7603         ( $IN, $OUT ) = ( shift, shift );
7604         $term->newTTY( $IN, $OUT );
7605     }
7606
7607     # This term can't get a new tty now. Better luck later.
7608     elsif ($term) {
7609         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7610     }
7611
7612     # Set the filehndles up as they were.
7613     else {
7614         ( $IN, $OUT ) = ( shift, shift );
7615     }
7616
7617     # Unbuffer the output filehandle.
7618     _autoflush($OUT);
7619
7620     # Point LINEINFO to the same output filehandle if it was there before.
7621     $LINEINFO = $OUT if $switch_li;
7622 } ## end sub reset_IN_OUT
7623
7624 =head1 OPTION SUPPORT ROUTINES
7625
7626 The following routines are used to process some of the more complicated
7627 debugger options.
7628
7629 =head2 C<TTY>
7630
7631 Sets the input and output filehandles to the specified files or pipes.
7632 If the terminal supports switching, we go ahead and do it. If not, and
7633 there's already a terminal in place, we save the information to take effect
7634 on restart.
7635
7636 If there's no terminal yet (for instance, during debugger initialization),
7637 we go ahead and set C<$console> and C<$tty> to the file indicated.
7638
7639 =cut
7640
7641 sub TTY {
7642
7643     if ( @_ and $term and $term->Features->{newTTY} ) {
7644
7645         # This terminal supports switching to a new TTY.
7646         # Can be a list of two files, or on string containing both names,
7647         # comma-separated.
7648         # XXX Should this perhaps be an assignment from @_?
7649         my ( $in, $out ) = shift;
7650         if ( $in =~ /,/ ) {
7651
7652             # Split list apart if supplied.
7653             ( $in, $out ) = split /,/, $in, 2;
7654         }
7655         else {
7656
7657             # Use the same file for both input and output.
7658             $out = $in;
7659         }
7660
7661         # Open file onto the debugger's filehandles, if you can.
7662         open IN,  $in     or die "cannot open '$in' for read: $!";
7663         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7664
7665         # Swap to the new filehandles.
7666         reset_IN_OUT( \*IN, \*OUT );
7667
7668         # Save the setting for later.
7669         return $tty = $in;
7670     } ## end if (@_ and $term and $term...
7671
7672     # Terminal doesn't support new TTY, or doesn't support readline.
7673     # Can't do it now, try restarting.
7674     if ($term and @_) {
7675         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7676     }
7677
7678     # Useful if done through PERLDB_OPTS:
7679     $console = $tty = shift if @_;
7680
7681     # Return whatever the TTY is.
7682     $tty or $console;
7683 } ## end sub TTY
7684
7685 =head2 C<noTTY>
7686
7687 Sets the C<$notty> global, controlling whether or not the debugger tries to
7688 get a terminal to read from. If called after a terminal is already in place,
7689 we save the value to use it if we're restarted.
7690
7691 =cut
7692
7693 sub noTTY {
7694     if ($term) {
7695         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7696     }
7697     $notty = shift if @_;
7698     $notty;
7699 } ## end sub noTTY
7700
7701 =head2 C<ReadLine>
7702
7703 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7704 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7705 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7706 the value in case a restart is done so we can change it then.
7707
7708 =cut
7709
7710 sub ReadLine {
7711     if ($term) {
7712         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7713     }
7714     $rl = shift if @_;
7715     $rl;
7716 } ## end sub ReadLine
7717
7718 =head2 C<RemotePort>
7719
7720 Sets the port that the debugger will try to connect to when starting up.
7721 If the terminal's already been set up, we can't do it, but we remember the
7722 setting in case the user does a restart.
7723
7724 =cut
7725
7726 sub RemotePort {
7727     if ($term) {
7728         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7729     }
7730     $remoteport = shift if @_;
7731     $remoteport;
7732 } ## end sub RemotePort
7733
7734 =head2 C<tkRunning>
7735
7736 Checks with the terminal to see if C<Tk> is running, and returns true or
7737 false. Returns false if the current terminal doesn't support C<readline>.
7738
7739 =cut
7740
7741 sub tkRunning {
7742     if ( ${ $term->Features }{tkRunning} ) {
7743         return $term->tkRunning(@_);
7744     }
7745     else {
7746         local $\ = '';
7747         print $OUT "tkRunning not supported by current ReadLine package.\n";
7748         0;
7749     }
7750 } ## end sub tkRunning
7751
7752 =head2 C<NonStop>
7753
7754 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7755 debugger remembers the setting in case you restart, though.
7756
7757 =cut
7758
7759 sub NonStop {
7760     if ($term) {
7761         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7762           if @_;
7763     }
7764     $runnonstop = shift if @_;
7765     $runnonstop;
7766 } ## end sub NonStop
7767
7768 sub DollarCaretP {
7769     if ($term) {
7770         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7771           if @_;
7772     }
7773     $^P = parse_DollarCaretP_flags(shift) if @_;
7774     expand_DollarCaretP_flags($^P);
7775 }
7776
7777 =head2 C<pager>
7778
7779 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7780 there already.
7781
7782 =cut
7783
7784 sub pager {
7785     if (@_) {
7786         $pager = shift;
7787         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7788     }
7789     $pager;
7790 } ## end sub pager
7791
7792 =head2 C<shellBang>
7793
7794 Sets the shell escape command, and generates a printable copy to be used
7795 in the help.
7796
7797 =cut
7798
7799 sub shellBang {
7800
7801     # If we got an argument, meta-quote it, and add '\b' if it
7802     # ends in a word character.
7803     if (@_) {
7804         $sh = quotemeta shift;
7805         $sh .= "\\b" if $sh =~ /\w$/;
7806     }
7807
7808     # Generate the printable version for the help:
7809     $psh = $sh;    # copy it
7810     $psh =~ s/\\b$//;        # Take off trailing \b if any
7811     $psh =~ s/\\(.)/$1/g;    # De-escape
7812     $psh;                    # return the printable version
7813 } ## end sub shellBang
7814
7815 =head2 C<ornaments>
7816
7817 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7818 was passed as the argument. (This means you can't override the terminal's
7819 ornaments.)
7820
7821 =cut
7822
7823 sub ornaments {
7824     if ( defined $term ) {
7825
7826         # We don't want to show warning backtraces, but we do want die() ones.
7827         local $warnLevel = 0;
7828         local $dieLevel = 1;
7829
7830         # No ornaments if the terminal doesn't support them.
7831         if (not $term->Features->{ornaments}) {
7832             return '';
7833         }
7834
7835         return (eval { $term->ornaments(@_) } || '');
7836     }
7837
7838     # Use what was passed in if we can't determine it ourselves.
7839     else {
7840         $ornaments = shift;
7841
7842         return $ornaments;
7843     }
7844
7845 } ## end sub ornaments
7846
7847 =head2 C<recallCommand>
7848
7849 Sets the recall command, and builds a printable version which will appear in
7850 the help text.
7851
7852 =cut
7853
7854 sub recallCommand {
7855
7856     # If there is input, metaquote it. Add '\b' if it ends with a word
7857     # character.
7858     if (@_) {
7859         $rc = quotemeta shift;
7860         $rc .= "\\b" if $rc =~ /\w$/;
7861     }
7862
7863     # Build it into a printable version.
7864     $prc = $rc;              # Copy it
7865     $prc =~ s/\\b$//;        # Remove trailing \b
7866     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7867     return $prc;             # Return the printable version
7868 } ## end sub recallCommand
7869
7870 =head2 C<LineInfo> - where the line number information goes
7871
7872 Called with no arguments, returns the file or pipe that line info should go to.
7873
7874 Called with an argument (a file or a pipe), it opens that onto the
7875 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7876 file or pipe again to the caller.
7877
7878 =cut
7879
7880 sub LineInfo {
7881     if (@_) {
7882         $lineinfo = shift;
7883
7884         #  If this is a valid "thing to be opened for output", tack a
7885         # '>' onto the front.
7886         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7887
7888         # If this is a pipe, the stream points to a slave editor.
7889         $slave_editor = ( $stream =~ /^\|/ );
7890
7891         my $new_lineinfo_fh;
7892         # Open it up and unbuffer it.
7893         open ($new_lineinfo_fh , $stream )
7894             or _db_warn("Cannot open '$stream' for write");
7895         $LINEINFO = $new_lineinfo_fh;
7896         _autoflush($LINEINFO);
7897     }
7898
7899     return $lineinfo;
7900 } ## end sub LineInfo
7901
7902 =head1 COMMAND SUPPORT ROUTINES
7903
7904 These subroutines provide functionality for various commands.
7905
7906 =head2 C<list_modules>
7907
7908 For the C<M> command: list modules loaded and their versions.
7909 Essentially just runs through the keys in %INC, picks each package's
7910 C<$VERSION> variable, gets the file name, and formats the information
7911 for output.
7912
7913 =cut
7914
7915 sub list_modules {    # versions
7916     my %version;
7917     my $file;
7918
7919     # keys are the "as-loaded" name, values are the fully-qualified path
7920     # to the file itself.
7921     for ( keys %INC ) {
7922         $file = $_;                                # get the module name
7923         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7924         s,/,::,g;                                  # change '/' to '::'
7925         s/^perl5db$/DB/;                           # Special case: debugger
7926                                                    # moves to package DB
7927         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7928
7929         # If the package has a $VERSION package global (as all good packages
7930         # should!) decode it and save as partial message.
7931         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7932         if ( defined $pkg_version ) {
7933             $version{$file} = "$pkg_version from ";
7934         }
7935
7936         # Finish up the message with the file the package came from.
7937         $version{$file} .= $INC{$file};
7938     } ## end for (keys %INC)
7939
7940     # Hey, dumpit() formats a hash nicely, so why not use it?
7941     dumpit( $OUT, \%version );
7942 } ## end sub list_modules
7943
7944 =head2 C<sethelp()>
7945
7946 Sets up the monster string used to format and print the help.
7947
7948 =head3 HELP MESSAGE FORMAT
7949
7950 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7951 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7952 easy to parse and portable, but which still allows the help to be a little
7953 nicer than just plain text.
7954
7955 Essentially, you define the command name (usually marked up with C<< B<> >>
7956 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7957 newline. The descriptive text can also be marked up in the same way. If you
7958 need to continue the descriptive text to another line, start that line with
7959 just tabs and then enter the marked-up text.
7960
7961 If you are modifying the help text, I<be careful>. The help-string parser is
7962 not very sophisticated, and if you don't follow these rules it will mangle the
7963 help beyond hope until you fix the string.
7964
7965 =cut
7966
7967 use vars qw($pre580_help);
7968 use vars qw($pre580_summary);
7969
7970 sub sethelp {
7971
7972     # XXX: make sure there are tabs between the command and explanation,
7973     #      or print_help will screw up your formatting if you have
7974     #      eeevil ornaments enabled.  This is an insane mess.
7975
7976     $help = "
7977 Help is currently only available for the new 5.8 command set.
7978 No help is available for the old command set.
7979 We assume you know what you're doing if you switch to it.
7980
7981 B<T>        Stack trace.
7982 B<s> [I<expr>]    Single step [in I<expr>].
7983 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7984 <B<CR>>        Repeat last B<n> or B<s> command.
7985 B<r>        Return from current subroutine.
7986 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7987         at the specified position.
7988 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7989 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7990 B<l> I<line>        List single I<line>.
7991 B<l> I<subname>    List first window of lines from subroutine.
7992 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7993 B<l>        List next window of lines.
7994 B<->        List previous window of lines.
7995 B<v> [I<line>]    View window around I<line>.
7996 B<.>        Return to the executed line.
7997 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7998         I<filename> may be either the full name of the file, or a regular
7999         expression matching the full file name:
8000         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8001         Evals (with saved bodies) are considered to be filenames:
8002         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8003         (in the order of execution).
8004 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8005 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8006 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
8007 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8008 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
8009 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8010 B<b>        Sets breakpoint on current line)
8011 B<b> [I<line>] [I<condition>]
8012         Set breakpoint; I<line> defaults to the current execution line;
8013         I<condition> breaks if it evaluates to true, defaults to '1'.
8014 B<b> I<subname> [I<condition>]
8015         Set breakpoint at first line of subroutine.
8016 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8017 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8018 B<b> B<postpone> I<subname> [I<condition>]
8019         Set breakpoint at first line of subroutine after
8020         it is compiled.
8021 B<b> B<compile> I<subname>
8022         Stop after the subroutine is compiled.
8023 B<B> [I<line>]    Delete the breakpoint for I<line>.
8024 B<B> I<*>             Delete all breakpoints.
8025 B<a> [I<line>] I<command>
8026         Set an action to be done before the I<line> is executed;
8027         I<line> defaults to the current execution line.
8028         Sequence is: check for breakpoint/watchpoint, print line
8029         if necessary, do action, prompt user if necessary,
8030         execute line.
8031 B<a>        Does nothing
8032 B<A> [I<line>]    Delete the action for I<line>.
8033 B<A> I<*>             Delete all actions.
8034 B<w> I<expr>        Add a global watch-expression.
8035 B<w>             Does nothing
8036 B<W> I<expr>        Delete a global watch-expression.
8037 B<W> I<*>             Delete all watch-expressions.
8038 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8039         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8040 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8041 B<x> I<expr>        Evals expression in list context, dumps the result.
8042 B<m> I<expr>        Evals expression in list context, prints methods callable
8043         on the first element of the result.
8044 B<m> I<class>        Prints methods callable via the given class.
8045 B<M>        Show versions of loaded modules.
8046 B<i> I<class>       Prints nested parents of given class.
8047 B<e>         Display current thread id.
8048 B<E>         Display all thread ids the current one will be identified: <n>.
8049 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8050
8051 B<<> ?            List Perl commands to run before each prompt.
8052 B<<> I<expr>        Define Perl command to run before each prompt.
8053 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8054 B<< *>                Delete the list of perl commands to run before each prompt.
8055 B<>> ?            List Perl commands to run after each prompt.
8056 B<>> I<expr>        Define Perl command to run after each prompt.
8057 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8058 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
8059 B<{> I<db_command>    Define debugger command to run before each prompt.
8060 B<{> ?            List debugger commands to run before each prompt.
8061 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8062 B<{ *>             Delete the list of debugger commands to run before each prompt.
8063 B<$prc> I<number>    Redo a previous command (default previous command).
8064 B<$prc> I<-number>    Redo number'th-to-last command.
8065 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8066         See 'B<O> I<recallCommand>' too.
8067 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8068       . (
8069         $rc eq $sh
8070         ? ""
8071         : "
8072 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8073       ) . "
8074         See 'B<O> I<shellBang>' too.
8075 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
8076 B<save> I<file>       Save current debugger session (actual history) to I<file>.
8077 B<rerun>           Rerun session to current position.
8078 B<rerun> I<n>         Rerun session to numbered command.
8079 B<rerun> I<-n>        Rerun session to number'th-to-last command.
8080 B<H> I<-number>    Display last number commands (default all).
8081 B<H> I<*>          Delete complete history.
8082 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8083 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8084 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
8085 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8086 I<command>        Execute as a perl statement in current package.
8087 B<R>        Pure-man-restart of debugger, some of debugger state
8088         and command-line options may be lost.
8089         Currently the following settings are preserved:
8090         history, breakpoints and actions, debugger B<O>ptions
8091         and the following command-line options: I<-w>, I<-I>, I<-e>.
8092
8093 B<o> [I<opt>] ...    Set boolean option to true
8094 B<o> [I<opt>B<?>]    Query options
8095 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8096         Set options.  Use quotes if spaces in value.
8097     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8098     I<pager>            program for output of \"|cmd\";
8099     I<tkRunning>            run Tk while prompting (with ReadLine);
8100     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8101     I<inhibit_exit>        Allows stepping off the end of the script.
8102     I<ImmediateStop>        Debugger should stop as early as possible.
8103     I<RemotePort>            Remote hostname:port for remote debugging
8104   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8105     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8106     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8107     I<globPrint>             whether to print contents of globs;
8108     I<DumpDBFiles>         dump arrays holding debugged files;
8109     I<DumpPackages>         dump symbol tables of packages;
8110     I<DumpReused>             dump contents of \"reused\" addresses;
8111     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8112     I<bareStringify>         Do not print the overload-stringified value;
8113   Other options include:
8114     I<PrintRet>        affects printing of return value after B<r> command,
8115     I<frame>        affects printing messages on subroutine entry/exit.
8116     I<AutoTrace>    affects printing messages on possible breaking points.
8117     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8118     I<ornaments>     affects screen appearance of the command line.
8119     I<CreateTTY>     bits control attempts to create a new TTY on events:
8120             1: on fork()    2: debugger is started inside debugger
8121             4: on startup
8122     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8123     You can put additional initialization options I<TTY>, I<noTTY>,
8124     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8125     B<R> after you set them).
8126
8127 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8128 B<h>        Summary of debugger commands.
8129 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8130 B<h h>        Long help for debugger commands
8131 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8132         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8133         Set B<\$DB::doccmd> to change viewer.
8134
8135 Type '|h h' for a paged display if this was too hard to read.
8136
8137 ";    # Fix balance of vi % matching: }}}}
8138
8139     #  note: tabs in the following section are not-so-helpful
8140     $summary = <<"END_SUM";
8141 I<List/search source lines:>               I<Control script execution:>
8142   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8143   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8144   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
8145   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8146   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8147   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
8148 I<Debugger controls:>                        B<L>           List break/watch/actions
8149   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
8150   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8151   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
8152   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8153   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
8154   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
8155   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
8156   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8157   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8158 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8159   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8160   B<p> I<expr>         Print expression (uses script's current package).
8161   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8162   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8163   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
8164   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8165   B<e>     Display thread id     B<E> Display all thread ids.
8166 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8167 END_SUM
8168
8169     # ')}}; # Fix balance of vi % matching
8170
8171     # and this is really numb...
8172     $pre580_help = "
8173 B<T>        Stack trace.
8174 B<s> [I<expr>]    Single step [in I<expr>].
8175 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8176 B<CR>>        Repeat last B<n> or B<s> command.
8177 B<r>        Return from current subroutine.
8178 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8179         at the specified position.
8180 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8181 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8182 B<l> I<line>        List single I<line>.
8183 B<l> I<subname>    List first window of lines from subroutine.
8184 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8185 B<l>        List next window of lines.
8186 B<->        List previous window of lines.
8187 B<w> [I<line>]    List window around I<line>.
8188 B<.>        Return to the executed line.
8189 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8190         I<filename> may be either the full name of the file, or a regular
8191         expression matching the full file name:
8192         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8193         Evals (with saved bodies) are considered to be filenames:
8194         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8195         (in the order of execution).
8196 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8197 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8198 B<L>        List all breakpoints and actions.
8199 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8200 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8201 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8202 B<b> [I<line>] [I<condition>]
8203         Set breakpoint; I<line> defaults to the current execution line;
8204         I<condition> breaks if it evaluates to true, defaults to '1'.
8205 B<b> I<subname> [I<condition>]
8206         Set breakpoint at first line of subroutine.
8207 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8208 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8209 B<b> B<postpone> I<subname> [I<condition>]
8210         Set breakpoint at first line of subroutine after
8211         it is compiled.
8212 B<b> B<compile> I<subname>
8213         Stop after the subroutine is compiled.
8214 B<d> [I<line>]    Delete the breakpoint for I<line>.
8215 B<D>        Delete all breakpoints.
8216 B<a> [I<line>] I<command>
8217         Set an action to be done before the I<line> is executed;
8218         I<line> defaults to the current execution line.
8219         Sequence is: check for breakpoint/watchpoint, print line
8220         if necessary, do action, prompt user if necessary,
8221         execute line.
8222 B<a> [I<line>]    Delete the action for I<line>.
8223 B<A>        Delete all actions.
8224 B<W> I<expr>        Add a global watch-expression.
8225 B<W>        Delete all watch-expressions.
8226 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8227         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8228 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8229 B<x> I<expr>        Evals expression in list context, dumps the result.
8230 B<m> I<expr>        Evals expression in list context, prints methods callable
8231         on the first element of the result.
8232 B<m> I<class>        Prints methods callable via the given class.
8233
8234 B<<> ?            List Perl commands to run before each prompt.
8235 B<<> I<expr>        Define Perl command to run before each prompt.
8236 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8237 B<>> ?            List Perl commands to run after each prompt.
8238 B<>> I<expr>        Define Perl command to run after each prompt.
8239 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8240 B<{> I<db_command>    Define debugger command to run before each prompt.
8241 B<{> ?            List debugger commands to run before each prompt.
8242 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8243 B<$prc> I<number>    Redo a previous command (default previous command).
8244 B<$prc> I<-number>    Redo number'th-to-last command.
8245 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8246         See 'B<O> I<recallCommand>' too.
8247 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8248       . (
8249         $rc eq $sh
8250         ? ""
8251         : "
8252 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8253       ) . "
8254         See 'B<O> I<shellBang>' too.
8255 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8256 B<H> I<-number>    Display last number commands (default all).
8257 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8258 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8259 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8260 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8261 I<command>        Execute as a perl statement in current package.
8262 B<v>        Show versions of loaded modules.
8263 B<R>        Pure-man-restart of debugger, some of debugger state
8264         and command-line options may be lost.
8265         Currently the following settings are preserved:
8266         history, breakpoints and actions, debugger B<O>ptions
8267         and the following command-line options: I<-w>, I<-I>, I<-e>.
8268
8269 B<O> [I<opt>] ...    Set boolean option to true
8270 B<O> [I<opt>B<?>]    Query options
8271 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8272         Set options.  Use quotes if spaces in value.
8273     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8274     I<pager>            program for output of \"|cmd\";
8275     I<tkRunning>            run Tk while prompting (with ReadLine);
8276     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8277     I<inhibit_exit>        Allows stepping off the end of the script.
8278     I<ImmediateStop>        Debugger should stop as early as possible.
8279     I<RemotePort>            Remote hostname:port for remote debugging
8280   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8281     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8282     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8283     I<globPrint>             whether to print contents of globs;
8284     I<DumpDBFiles>         dump arrays holding debugged files;
8285     I<DumpPackages>         dump symbol tables of packages;
8286     I<DumpReused>             dump contents of \"reused\" addresses;
8287     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8288     I<bareStringify>         Do not print the overload-stringified value;
8289   Other options include:
8290     I<PrintRet>        affects printing of return value after B<r> command,
8291     I<frame>        affects printing messages on subroutine entry/exit.
8292     I<AutoTrace>    affects printing messages on possible breaking points.
8293     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8294     I<ornaments>     affects screen appearance of the command line.
8295     I<CreateTTY>     bits control attempts to create a new TTY on events:
8296             1: on fork()    2: debugger is started inside debugger
8297             4: on startup
8298     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8299     You can put additional initialization options I<TTY>, I<noTTY>,
8300     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8301     B<R> after you set them).
8302
8303 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8304 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8305 B<h h>        Summary of debugger commands.
8306 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8307         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8308         Set B<\$DB::doccmd> to change viewer.
8309
8310 Type '|h' for a paged display if this was too hard to read.
8311
8312 ";    # Fix balance of vi % matching: }}}}
8313
8314     #  note: tabs in the following section are not-so-helpful
8315     $pre580_summary = <<"END_SUM";
8316 I<List/search source lines:>               I<Control script execution:>
8317   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8318   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8319   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8320   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8321   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8322   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8323 I<Debugger controls:>                        B<L>           List break/watch/actions
8324   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8325   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8326   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8327   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8328   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8329   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8330   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8331   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8332 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8333   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8334   B<p> I<expr>         Print expression (uses script's current package).
8335   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8336   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8337   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8338   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8339 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8340 END_SUM
8341
8342     # ')}}; # Fix balance of vi % matching
8343
8344 } ## end sub sethelp
8345
8346 =head2 C<print_help()>
8347
8348 Most of what C<print_help> does is just text formatting. It finds the
8349 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8350 terminal control characters to simulate them (courtesy of
8351 C<Term::ReadLine::TermCap>).
8352
8353 =cut
8354
8355 sub print_help {
8356     my $help_str = shift;
8357
8358     # Restore proper alignment destroyed by eeevil I<> and B<>
8359     # ornaments: A pox on both their houses!
8360     #
8361     # A help command will have everything up to and including
8362     # the first tab sequence padded into a field 16 (or if indented 20)
8363     # wide.  If it's wider than that, an extra space will be added.
8364     $help_str =~ s{
8365         ^                       # only matters at start of line
8366           ( \040{4} | \t )*     # some subcommands are indented
8367           ( < ?                 # so <CR> works
8368             [BI] < [^\t\n] + )  # find an eeevil ornament
8369           ( \t+ )               # original separation, discarded
8370           ( .* )                # this will now start (no earlier) than
8371                                 # column 16
8372     } {
8373         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8374         my $clean = $command;
8375         $clean =~ s/[BI]<([^>]*)>/$1/g;
8376
8377         # replace with this whole string:
8378         ($leadwhite ? " " x 4 : "")
8379       . $command
8380       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8381       . $text;
8382
8383     }mgex;
8384
8385     $help_str =~ s{                          # handle bold ornaments
8386        B < ( [^>] + | > ) >
8387     } {
8388           $Term::ReadLine::TermCap::rl_term_set[2]
8389         . $1
8390         . $Term::ReadLine::TermCap::rl_term_set[3]
8391     }gex;
8392
8393     $help_str =~ s{                         # handle italic ornaments
8394        I < ( [^>] + | > ) >
8395     } {
8396           $Term::ReadLine::TermCap::rl_term_set[0]
8397         . $1
8398         . $Term::ReadLine::TermCap::rl_term_set[1]
8399     }gex;
8400
8401     local $\ = '';
8402     print {$OUT} $help_str;
8403
8404     return;
8405 } ## end sub print_help
8406
8407 =head2 C<fix_less>
8408
8409 This routine does a lot of gyrations to be sure that the pager is C<less>.
8410 It checks for C<less> masquerading as C<more> and records the result in
8411 C<$fixed_less> so we don't have to go through doing the stats again.
8412
8413 =cut
8414
8415 use vars qw($fixed_less);
8416
8417 sub _calc_is_less {
8418     if ($pager =~ /\bless\b/)
8419     {
8420         return 1;
8421     }
8422     elsif ($pager =~ /\bmore\b/)
8423     {
8424         # Nope, set to more. See what's out there.
8425         my @st_more = stat('/usr/bin/more');
8426         my @st_less = stat('/usr/bin/less');
8427
8428         # is it really less, pretending to be more?
8429         return (
8430             @st_more
8431             && @st_less
8432             && $st_more[0] == $st_less[0]
8433             && $st_more[1] == $st_less[1]
8434         );
8435     }
8436     else {
8437         return;
8438     }
8439 }
8440
8441 sub fix_less {
8442
8443     # We already know if this is set.
8444     return if $fixed_less;
8445
8446     # changes environment!
8447     # 'r' added so we don't do (slow) stats again.
8448     $fixed_less = 1 if _calc_is_less();
8449
8450     return;
8451 } ## end sub fix_less
8452
8453 =head1 DIE AND WARN MANAGEMENT
8454
8455 =head2 C<diesignal>
8456
8457 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8458 to debug a debugger problem.
8459
8460 It does its best to report the error that occurred, and then forces the
8461 program, debugger, and everything to die.
8462
8463 =cut
8464
8465 sub diesignal {
8466
8467     # No entry/exit messages.
8468     local $frame = 0;
8469
8470     # No return value prints.
8471     local $doret = -2;
8472
8473     # set the abort signal handling to the default (just terminate).
8474     $SIG{'ABRT'} = 'DEFAULT';
8475
8476     # If we enter the signal handler recursively, kill myself with an
8477     # abort signal (so we just terminate).
8478     kill 'ABRT', $$ if $panic++;
8479
8480     # If we can show detailed info, do so.
8481     if ( defined &Carp::longmess ) {
8482
8483         # Don't recursively enter the warn handler, since we're carping.
8484         local $SIG{__WARN__} = '';
8485
8486         # Skip two levels before reporting traceback: we're skipping
8487         # mydie and confess.
8488         local $Carp::CarpLevel = 2;    # mydie + confess
8489
8490         # Tell us all about it.
8491         _db_warn( Carp::longmess("Signal @_") );
8492     }
8493
8494     # No Carp. Tell us about the signal as best we can.
8495     else {
8496         local $\ = '';
8497         print $DB::OUT "Got signal @_\n";
8498     }
8499
8500     # Drop dead.
8501     kill 'ABRT', $$;
8502 } ## end sub diesignal
8503
8504 =head2 C<dbwarn>
8505
8506 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8507 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8508
8509 =cut
8510
8511 sub dbwarn {
8512
8513     # No entry/exit trace.
8514     local $frame = 0;
8515
8516     # No return value printing.
8517     local $doret = -2;
8518
8519     # Turn off warn and die handling to prevent recursive entries to this
8520     # routine.
8521     local $SIG{__WARN__} = '';
8522     local $SIG{__DIE__}  = '';
8523
8524     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8525     # done yet), we may not be able to do a require.
8526     eval { require Carp }
8527       if defined $^S;    # If error/warning during compilation,
8528                          # require may be broken.
8529
8530     # Use the core warn() unless Carp loaded OK.
8531     CORE::warn( @_,
8532         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8533       return
8534       unless defined &Carp::longmess;
8535
8536     # Save the current values of $single and $trace, and then turn them off.
8537     my ( $mysingle, $mytrace ) = ( $single, $trace );
8538     $single = 0;
8539     $trace  = 0;
8540
8541     # We can call Carp::longmess without its being "debugged" (which we
8542     # don't want - we just want to use it!). Capture this for later.
8543     my $mess = Carp::longmess(@_);
8544
8545     # Restore $single and $trace to their original values.
8546     ( $single, $trace ) = ( $mysingle, $mytrace );
8547
8548     # Use the debugger's own special way of printing warnings to print
8549     # the stack trace message.
8550     _db_warn($mess);
8551 } ## end sub dbwarn
8552
8553 =head2 C<dbdie>
8554
8555 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8556 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8557 single stepping and tracing during the call to C<Carp::longmess> to avoid
8558 debugging it - we just want to use it.
8559
8560 If C<dieLevel> is zero, we let the program being debugged handle the
8561 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8562 the debugger takes over all exception handling, printing a backtrace and
8563 displaying the exception via its C<dbwarn()> routine.
8564
8565 =cut
8566
8567 sub dbdie {
8568     local $frame         = 0;
8569     local $doret         = -2;
8570     local $SIG{__DIE__}  = '';
8571     local $SIG{__WARN__} = '';
8572     if ( $dieLevel > 2 ) {
8573         local $SIG{__WARN__} = \&dbwarn;
8574         _db_warn(@_);    # Yell no matter what
8575         return;
8576     }
8577     if ( $dieLevel < 2 ) {
8578         die @_ if $^S;    # in eval propagate
8579     }
8580
8581     # The code used to check $^S to see if compilation of the current thing
8582     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8583     eval { require Carp };
8584
8585     die( @_,
8586         "\nCannot print stack trace, load with -MCarp option to see stack" )
8587       unless defined &Carp::longmess;
8588
8589     # We do not want to debug this chunk (automatic disabling works
8590     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8591     # get the stack trace from Carp::longmess (if possible), restore $signal
8592     # and $trace, and then die with the stack trace.
8593     my ( $mysingle, $mytrace ) = ( $single, $trace );
8594     $single = 0;
8595     $trace  = 0;
8596     my $mess = "@_";
8597     {
8598
8599         package Carp;    # Do not include us in the list
8600         eval { $mess = Carp::longmess(@_); };
8601     }
8602     ( $single, $trace ) = ( $mysingle, $mytrace );
8603     die $mess;
8604 } ## end sub dbdie
8605
8606 =head2 C<warnlevel()>
8607
8608 Set the C<$DB::warnLevel> variable that stores the value of the
8609 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8610 results in the debugger taking over all warning handlers. Setting
8611 C<warnLevel> to zero leaves any warning handlers set up by the program
8612 being debugged in place.
8613
8614 =cut
8615
8616 sub warnLevel {
8617     if (@_) {
8618         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8619         $warnLevel = shift;
8620         if ($warnLevel) {
8621             $SIG{__WARN__} = \&DB::dbwarn;
8622         }
8623         elsif ($prevwarn) {
8624             $SIG{__WARN__} = $prevwarn;
8625         } else {
8626             undef $SIG{__WARN__};
8627         }
8628     } ## end if (@_)
8629     $warnLevel;
8630 } ## end sub warnLevel
8631
8632 =head2 C<dielevel>
8633
8634 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8635 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8636 zero lets you use your own C<die()> handler.
8637
8638 =cut
8639
8640 sub dieLevel {
8641     local $\ = '';
8642     if (@_) {
8643         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8644         $dieLevel = shift;
8645         if ($dieLevel) {
8646
8647             # Always set it to dbdie() for non-zero values.
8648             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8649
8650             # No longer exists, so don't try  to use it.
8651             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8652
8653             # If we've finished initialization, mention that stack dumps
8654             # are enabled, If dieLevel is 1, we won't stack dump if we die
8655             # in an eval().
8656             print $OUT "Stack dump during die enabled",
8657               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8658               if $I_m_init;
8659
8660             # XXX This is probably obsolete, given that diehard() is gone.
8661             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8662         } ## end if ($dieLevel)
8663
8664         # Put the old one back if there was one.
8665         elsif ($prevdie) {
8666             $SIG{__DIE__} = $prevdie;
8667             print $OUT "Default die handler restored.\n";
8668         } else {
8669             undef $SIG{__DIE__};
8670             print $OUT "Die handler removed.\n";
8671         }
8672     } ## end if (@_)
8673     $dieLevel;
8674 } ## end sub dieLevel
8675
8676 =head2 C<signalLevel>
8677
8678 Number three in a series: set C<signalLevel> to zero to keep your own
8679 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8680 takes over and handles them with C<DB::diesignal()>.
8681
8682 =cut
8683
8684 sub signalLevel {
8685     if (@_) {
8686         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8687         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8688         $signalLevel = shift;
8689         if ($signalLevel) {
8690             $SIG{SEGV} = \&DB::diesignal;
8691             $SIG{BUS}  = \&DB::diesignal;
8692         }
8693         else {
8694             $SIG{SEGV} = $prevsegv;
8695             $SIG{BUS}  = $prevbus;
8696         }
8697     } ## end if (@_)
8698     $signalLevel;
8699 } ## end sub signalLevel
8700
8701 =head1 SUBROUTINE DECODING SUPPORT
8702
8703 These subroutines are used during the C<x> and C<X> commands to try to
8704 produce as much information as possible about a code reference. They use
8705 L<Devel::Peek> to try to find the glob in which this code reference lives
8706 (if it does) - this allows us to actually code references which correspond
8707 to named subroutines (including those aliased via glob assignment).
8708
8709 =head2 C<CvGV_name()>
8710
8711 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8712 via that routine. If this fails, return the reference again (when the
8713 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8714
8715 =cut
8716
8717 sub CvGV_name {
8718     my $in   = shift;
8719     my $name = CvGV_name_or_bust($in);
8720     defined $name ? $name : $in;
8721 }
8722
8723 =head2 C<CvGV_name_or_bust> I<coderef>
8724
8725 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8726 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8727 find a glob for this ref.
8728
8729 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8730
8731 =cut
8732
8733 use vars qw($skipCvGV);
8734
8735 sub CvGV_name_or_bust {
8736     my $in = shift;
8737     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8738     return unless ref $in;
8739     $in = \&$in;            # Hard reference...
8740     eval { require Devel::Peek; 1 } or return;
8741     my $gv = Devel::Peek::CvGV($in) or return;
8742     *$gv{PACKAGE} . '::' . *$gv{NAME};
8743 } ## end sub CvGV_name_or_bust
8744
8745 =head2 C<find_sub>
8746
8747 A utility routine used in various places; finds the file where a subroutine
8748 was defined, and returns that filename and a line-number range.
8749
8750 Tries to use C<@sub> first; if it can't find it there, it tries building a
8751 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8752 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8753 this way, it brute-force searches C<%sub>, checking for identical references.
8754
8755 =cut
8756
8757 sub _find_sub_helper {
8758     my $subr = shift;
8759
8760     return unless defined &$subr;
8761     my $name = CvGV_name_or_bust($subr);
8762     my $data;
8763     $data = $sub{$name} if defined $name;
8764     return $data if defined $data;
8765
8766     # Old stupid way...
8767     $subr = \&$subr;    # Hard reference
8768     my $s;
8769     for ( keys %sub ) {
8770         $s = $_, last if $subr eq \&$_;
8771     }
8772     if ($s)
8773     {
8774         return $sub{$s};
8775     }
8776     else
8777     {
8778         return;
8779     }
8780
8781 }
8782
8783 sub find_sub {
8784     my $subr = shift;
8785     return ( $sub{$subr} || _find_sub_helper($subr) );
8786 } ## end sub find_sub
8787
8788 =head2 C<methods>
8789
8790 A subroutine that uses the utility function C<methods_via> to find all the
8791 methods in the class corresponding to the current reference and in
8792 C<UNIVERSAL>.
8793
8794 =cut
8795
8796 use vars qw(%seen);
8797
8798 sub methods {
8799
8800     # Figure out the class - either this is the class or it's a reference
8801     # to something blessed into that class.
8802     my $class = shift;
8803     $class = ref $class if ref $class;
8804
8805     local %seen;
8806
8807     # Show the methods that this class has.
8808     methods_via( $class, '', 1 );
8809
8810     # Show the methods that UNIVERSAL has.
8811     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8812 } ## end sub methods
8813
8814 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8815
8816 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8817 all the parent class methods. C<$class> is the name of the next class to
8818 try; C<$prefix> is the message prefix, which gets built up as we go up the
8819 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8820 higher in the C<@ISA> tree, 0 if we should stop.
8821
8822 =cut
8823
8824 sub methods_via {
8825
8826     # If we've processed this class already, just quit.
8827     my $class = shift;
8828     return if $seen{$class}++;
8829
8830     # This is a package that is contributing the methods we're about to print.
8831     my $prefix  = shift;
8832     my $prepend = $prefix ? "via $prefix: " : '';
8833     my @to_print;
8834
8835     # Extract from all the symbols in this class.
8836     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8837     while (my ($name, $glob) = each %$class_ref) {
8838         # references directly in the symbol table are Proxy Constant
8839         # Subroutines, and are by their very nature defined
8840         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8841         # to a subroutine reference, which can be tested by defined.
8842         # $glob might also be the value -1  (from sub foo;)
8843         # or (say) '$$' (from sub foo ($$);)
8844         # \$glob will be SCALAR in both cases.
8845         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8846             && !$seen{$name}++) {
8847             push @to_print, "$prepend$name\n";
8848         }
8849     }
8850
8851     {
8852         local $\ = '';
8853         local $, = '';
8854         print $DB::OUT $_ foreach sort @to_print;
8855     }
8856
8857     # If the $crawl_upward argument is false, just quit here.
8858     return unless shift;
8859
8860     # $crawl_upward true: keep going up the tree.
8861     # Find all the classes this one is a subclass of.
8862     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8863     for my $name ( @$class_ISA_ref ) {
8864
8865         # Set up the new prefix.
8866         $prepend = $prefix ? $prefix . " -> $name" : $name;
8867
8868         # Crawl up the tree and keep trying to crawl up.
8869         methods_via( $name, $prepend, 1 );
8870     }
8871 } ## end sub methods_via
8872
8873 =head2 C<setman> - figure out which command to use to show documentation
8874
8875 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8876
8877 =cut
8878
8879 sub setman {
8880     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8881       ? "man"         # O Happy Day!
8882       : "perldoc";    # Alas, poor unfortunates
8883 } ## end sub setman
8884
8885 =head2 C<runman> - run the appropriate command to show documentation
8886
8887 Accepts a man page name; runs the appropriate command to display it (set up
8888 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8889 program's STDIN and STDOUT.
8890
8891 =cut
8892
8893 sub runman {
8894     my $page = shift;
8895     unless ($page) {
8896         _db_system("$doccmd $doccmd");
8897         return;
8898     }
8899
8900     # this way user can override, like with $doccmd="man -Mwhatever"
8901     # or even just "man " to disable the path check.
8902     if ( $doccmd ne 'man' ) {
8903         _db_system("$doccmd $page");
8904         return;
8905     }
8906
8907     $page = 'perl' if lc($page) eq 'help';
8908
8909     require Config;
8910     my $man1dir = $Config::Config{man1direxp};
8911     my $man3dir = $Config::Config{man3direxp};
8912     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8913     my $manpath = '';
8914     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8915     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8916     chop $manpath if $manpath;
8917
8918     # harmless if missing, I figure
8919     local $ENV{MANPATH} = $manpath if $manpath;
8920     my $nopathopt = $^O =~ /dunno what goes here/;
8921     if (
8922         CORE::system(
8923             $doccmd,
8924
8925             # I just *know* there are men without -M
8926             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8927             split ' ', $page
8928         )
8929       )
8930     {
8931         unless ( $page =~ /^perl\w/ ) {
8932             # Previously the debugger contained a list which it slurped in,
8933             # listing the known "perl" manpages. However, it was out of date,
8934             # with errors both of omission and inclusion. This approach is
8935             # considerably less complex. The failure mode on a butchered
8936             # install is simply that the user has to run man or perldoc
8937             # "manually" with the full manpage name.
8938
8939             # There is a list of $^O values in installperl to determine whether
8940             # the directory is 'pods' or 'pod'. However, we can avoid tight
8941             # coupling to that by simply checking the "non-standard" 'pods'
8942             # first.
8943             my $pods = "$Config::Config{privlibexp}/pods";
8944             $pods = "$Config::Config{privlibexp}/pod"
8945                 unless -d $pods;
8946             if (-f "$pods/perl$page.pod") {
8947                 CORE::system( $doccmd,
8948                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8949                     "perl$page" );
8950             }
8951         }
8952     } ## end if (CORE::system($doccmd...
8953 } ## end sub runman
8954
8955 #use Carp;                          # This did break, left for debugging
8956
8957 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8958
8959 Because of the way the debugger interface to the Perl core is designed, any
8960 debugger package globals that C<DB::sub()> requires have to be defined before
8961 any subroutines can be called. These are defined in the second C<BEGIN> block.
8962
8963 This block sets things up so that (basically) the world is sane
8964 before the debugger starts executing. We set up various variables that the
8965 debugger has to have set up before the Perl core starts running:
8966
8967 =over 4
8968
8969 =item *
8970
8971 The debugger's own filehandles (copies of STD and STDOUT for now).
8972
8973 =item *
8974
8975 Characters for shell escapes, the recall command, and the history command.
8976
8977 =item *
8978
8979 The maximum recursion depth.
8980
8981 =item *
8982
8983 The size of a C<w> command's window.
8984
8985 =item *
8986
8987 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8988
8989 =item *
8990
8991 The fact that we're not in a sub at all right now.
8992
8993 =item *
8994
8995 The default SIGINT handler for the debugger.
8996
8997 =item *
8998
8999 The appropriate value of the flag in C<$^D> that says the debugger is running
9000
9001 =item *
9002
9003 The current debugger recursion level
9004
9005 =item *
9006
9007 The list of postponed items and the C<$single> stack (XXX define this)
9008
9009 =item *
9010
9011 That we want no return values and no subroutine entry/exit trace.
9012
9013 =back
9014
9015 =cut
9016
9017 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
9018
9019 use vars qw($db_stop);
9020
9021 BEGIN {    # This does not compile, alas. (XXX eh?)
9022     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
9023     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
9024
9025     # Define characters used by command parsing.
9026     $sh       = '!';      # Shell escape (does not work)
9027     $rc       = ',';      # Recall command (does not work)
9028     @hist     = ('?');    # Show history (does not work)
9029     @truehist = ();       # Can be saved for replay (per session)
9030
9031     # This defines the point at which you get the 'deep recursion'
9032     # warning. It MUST be defined or the debugger will not load.
9033     $deep = 100;
9034
9035     # Number of lines around the current one that are shown in the
9036     # 'w' command.
9037     $window = 10;
9038
9039     # How much before-the-current-line context the 'v' command should
9040     # use in calculating the start of the window it will display.
9041     $preview = 3;
9042
9043     # We're not in any sub yet, but we need this to be a defined value.
9044     $sub = '';
9045
9046     # Set up the debugger's interrupt handler. It simply sets a flag
9047     # ($signal) that DB::DB() will check before each command is executed.
9048     $SIG{INT} = \&DB::catch;
9049
9050     # The following lines supposedly, if uncommented, allow the debugger to
9051     # debug itself. Perhaps we can try that someday.
9052     # This may be enabled to debug debugger:
9053     #$warnLevel = 1 unless defined $warnLevel;
9054     #$dieLevel = 1 unless defined $dieLevel;
9055     #$signalLevel = 1 unless defined $signalLevel;
9056
9057     # This is the flag that says "a debugger is running, please call
9058     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9059     # execute anything in the user's context, because we always want to
9060     # get control back.
9061     $db_stop = 0;          # Compiler warning ...
9062     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9063
9064     # This variable records how many levels we're nested in debugging. Used
9065     # Used in the debugger prompt, and in determining whether it's all over or
9066     # not.
9067     $level = 0;            # Level of recursive debugging
9068
9069     # "Triggers bug (?) in perl if we postpone this until runtime."
9070     # XXX No details on this yet, or whether we should fix the bug instead
9071     # of work around it. Stay tuned.
9072     @stack = (0);
9073
9074     # Used to track the current stack depth using the auto-stacked-variable
9075     # trick.
9076     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9077
9078     # Don't print return values on exiting a subroutine.
9079     $doret = -2;
9080
9081     # No extry/exit tracing.
9082     $frame = 0;
9083
9084 } ## end BEGIN
9085
9086 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9087
9088 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9089
9090 =head2 db_complete
9091
9092 C<readline> support - adds command completion to basic C<readline>.
9093
9094 Returns a list of possible completions to C<readline> when invoked. C<readline>
9095 will print the longest common substring following the text already entered.
9096
9097 If there is only a single possible completion, C<readline> will use it in full.
9098
9099 This code uses C<map> and C<grep> heavily to create lists of possible
9100 completion. Think LISP in this section.
9101
9102 =cut
9103
9104 sub db_complete {
9105
9106     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9107     # $text is the text to be completed.
9108     # $line is the incoming line typed by the user.
9109     # $start is the start of the text to be completed in the incoming line.
9110     my ( $text, $line, $start ) = @_;
9111
9112     # Save the initial text.
9113     # The search pattern is current package, ::, extract the next qualifier
9114     # Prefix and pack are set to undef.
9115     my ( $itext, $search, $prefix, $pack ) =
9116       ( $text, "^\Q${package}::\E([^:]+)\$" );
9117
9118 =head3 C<b postpone|compile>
9119
9120 =over 4
9121
9122 =item *
9123
9124 Find all the subroutines that might match in this package
9125
9126 =item *
9127
9128 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9129
9130 =item *
9131
9132 Include all the rest of the subs that are known
9133
9134 =item *
9135
9136 C<grep> out the ones that match the text we have so far
9137
9138 =item *
9139
9140 Return this as the list of possible completions
9141
9142 =back
9143
9144 =cut
9145
9146     return sort grep /^\Q$text/, ( keys %sub ),
9147       qw(postpone load compile),    # subroutines
9148       ( map { /$search/ ? ($1) : () } keys %sub )
9149       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9150
9151 =head3 C<b load>
9152
9153 Get all the possible files from C<@INC> as it currently stands and
9154 select the ones that match the text so far.
9155
9156 =cut
9157
9158     return sort grep /^\Q$text/, values %INC    # files
9159       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9160
9161 =head3  C<V> (list variable) and C<m> (list modules)
9162
9163 There are two entry points for these commands:
9164
9165 =head4 Unqualified package names
9166
9167 Get the top-level packages and grab everything that matches the text
9168 so far. For each match, recursively complete the partial packages to
9169 get all possible matching packages. Return this sorted list.
9170
9171 =cut
9172
9173     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9174       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9175       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9176
9177 =head4 Qualified package names
9178
9179 Take a partially-qualified package and find all subpackages for it
9180 by getting all the subpackages for the package so far, matching all
9181 the subpackages against the text, and discarding all of them which
9182 start with 'main::'. Return this list.
9183
9184 =cut
9185
9186     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9187       grep !/^main::/, grep /^\Q$text/,
9188       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9189       do { no strict 'refs'; keys %{ $prefix . '::' } }
9190       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9191       and $text =~ /^(.*[^:])::?(\w*)$/
9192       and $prefix = $1;
9193
9194 =head3 C<f> - switch files
9195
9196 Here, we want to get a fully-qualified filename for the C<f> command.
9197 Possibilities are:
9198
9199 =over 4
9200
9201 =item 1. The original source file itself
9202
9203 =item 2. A file from C<@INC>
9204
9205 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9206
9207 =back
9208
9209 =cut
9210
9211     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9212            # We might possibly want to switch to an eval (which has a "filename"
9213            # like '(eval 9)'), so we may need to clean up the completion text
9214            # before proceeding.
9215         $prefix = length($1) - length($text);
9216         $text   = $1;
9217
9218 =pod
9219
9220 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9221 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9222 out of C<%main::>, add the initial source file, and extract the ones that
9223 match the completion text so far.
9224
9225 =cut
9226
9227         return sort
9228           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9229           $0;
9230     } ## end if ($line =~ /^\|*f\s+(.*)/)
9231
9232 =head3 Subroutine name completion
9233
9234 We look through all of the defined subs (the keys of C<%sub>) and
9235 return both all the possible matches to the subroutine name plus
9236 all the matches qualified to the current package.
9237
9238 =cut
9239
9240     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9241         $text = substr $text, 1;
9242         $prefix = "&";
9243         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9244           (
9245             map { /$search/ ? ($1) : () }
9246               keys %sub
9247           );
9248     } ## end if ((substr $text, 0, ...
9249
9250 =head3  Scalar, array, and hash completion: partially qualified package
9251
9252 Much like the above, except we have to do a little more cleanup:
9253
9254 =cut
9255
9256     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9257
9258 =pod
9259
9260 =over 4
9261
9262 =item *
9263
9264 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9265
9266 =cut
9267
9268         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9269
9270 =pod
9271
9272 =item *
9273
9274 Figure out the prefix vs. what needs completing.
9275
9276 =cut
9277
9278         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9279         $text   = $2;
9280
9281 =pod
9282
9283 =item *
9284
9285 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9286
9287 =cut
9288
9289         my @out = do {
9290             no strict 'refs';
9291             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9292             keys %$pack;
9293         };
9294
9295 =pod
9296
9297 =item *
9298
9299 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9300
9301 =cut
9302
9303         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9304             return db_complete( $out[0], $line, $start );
9305         }
9306
9307         # Return the list of possibles.
9308         return sort @out;
9309
9310     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9311
9312 =pod
9313
9314 =back
9315
9316 =head3 Symbol completion: current package or package C<main>.
9317
9318 =cut
9319
9320     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9321 =pod
9322
9323 =over 4
9324
9325 =item *
9326
9327 If it's C<main>, delete main to just get C<::> leading.
9328
9329 =cut
9330
9331         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9332
9333 =pod
9334
9335 =item *
9336
9337 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9338
9339 =cut
9340
9341         $prefix = substr $text, 0, 1;
9342         $text   = substr $text, 1;
9343
9344         my @out;
9345
9346 =pod
9347
9348 =item *
9349
9350 We look for the lexical scope above DB::DB and auto-complete lexical variables
9351 if PadWalker could be loaded.
9352
9353 =cut
9354
9355         if (not $text =~ /::/ and eval { require PadWalker } ) {
9356             my $level = 1;
9357             while (1) {
9358                 my @info = caller($level);
9359                 $level++;
9360                 $level = -1, last
9361                   if not @info;
9362                 last if $info[3] eq 'DB::DB';
9363             }
9364             if ($level > 0) {
9365                 my $lexicals = PadWalker::peek_my($level);
9366                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9367             }
9368         }
9369
9370 =pod
9371
9372 =item *
9373
9374 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9375
9376 =cut
9377
9378         push @out, map "$prefix$_", grep /^\Q$text/,
9379           ( grep /^_?[a-zA-Z]/, keys %$pack ),
9380           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9381
9382 =item *
9383
9384 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9385
9386 =back
9387
9388 =cut
9389
9390         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9391             return db_complete( $out[0], $line, $start );
9392         }
9393
9394         # Return the list of possibles.
9395         return sort @out;
9396     } ## end if ($text =~ /^[\$@%]/)
9397
9398 =head3 Options
9399
9400 We use C<option_val()> to look up the current value of the option. If there's
9401 only a single value, we complete the command in such a way that it is a
9402 complete command for setting the option in question. If there are multiple
9403 possible values, we generate a command consisting of the option plus a trailing
9404 question mark, which, if executed, will list the current value of the option.
9405
9406 =cut
9407
9408     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9409     {    # Options after space
9410            # We look for the text to be matched in the list of possible options,
9411            # and fetch the current value.
9412         my @out = grep /^\Q$text/, @options;
9413         my $val = option_val( $out[0], undef );
9414
9415         # Set up a 'query option's value' command.
9416         my $out = '? ';
9417         if ( not defined $val or $val =~ /[\n\r]/ ) {
9418
9419             # There's really nothing else we can do.
9420         }
9421
9422         # We have a value. Create a proper option-setting command.
9423         elsif ( $val =~ /\s/ ) {
9424
9425             # XXX This may be an extraneous variable.
9426             my $found;
9427
9428             # We'll want to quote the string (because of the embedded
9429             # whtespace), but we want to make sure we don't end up with
9430             # mismatched quote characters. We try several possibilities.
9431             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9432
9433                 # If we didn't find this quote character in the value,
9434                 # quote it using this quote character.
9435                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9436             }
9437         } ## end elsif ($val =~ /\s/)
9438
9439         # Don't need any quotes.
9440         else {
9441             $out = "=$val ";
9442         }
9443
9444         # If there were multiple possible values, return '? ', which
9445         # makes the command into a query command. If there was just one,
9446         # have readline append that.
9447         $rl_attribs->{completer_terminator_character} =
9448           ( @out == 1 ? $out : '? ' );
9449
9450         # Return list of possibilities.
9451         return sort @out;
9452     } ## end if ((substr $line, 0, ...
9453
9454 =head3 Filename completion
9455
9456 For entering filenames. We simply call C<readline>'s C<filename_list()>
9457 method with the completion text to get the possible completions.
9458
9459 =cut
9460
9461     return $term->filename_list($text);    # filenames
9462
9463 } ## end sub db_complete
9464
9465 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9466
9467 Functions that possibly ought to be somewhere else.
9468
9469 =head2 end_report
9470
9471 Say we're done.
9472
9473 =cut
9474
9475 sub end_report {
9476     local $\ = '';
9477     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9478 }
9479
9480 =head2 clean_ENV
9481
9482 If we have $ini_pids, save it in the environment; else remove it from the
9483 environment. Used by the C<R> (restart) command.
9484
9485 =cut
9486
9487 sub clean_ENV {
9488     if ( defined($ini_pids) ) {
9489         $ENV{PERLDB_PIDS} = $ini_pids;
9490     }
9491     else {
9492         delete( $ENV{PERLDB_PIDS} );
9493     }
9494 } ## end sub clean_ENV
9495
9496 # PERLDBf_... flag names from perl.h
9497 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9498
9499 BEGIN {
9500     %DollarCaretP_flags = (
9501         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9502         PERLDBf_LINE      => 0x02,     # Keep line #
9503         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9504         PERLDBf_INTER     => 0x08,     # Preserve more data
9505         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9506         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9507         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9508         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9509         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9510         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9511         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9512         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9513     );
9514     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9515     # doesn't need to set it. It's provided for the benefit of profilers and
9516     # other code analysers.
9517
9518     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9519 }
9520
9521 sub parse_DollarCaretP_flags {
9522     my $flags = shift;
9523     $flags =~ s/^\s+//;
9524     $flags =~ s/\s+$//;
9525     my $acu = 0;
9526     foreach my $f ( split /\s*\|\s*/, $flags ) {
9527         my $value;
9528         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9529             $value = hex $1;
9530         }
9531         elsif ( $f =~ /^(\d+)$/ ) {
9532             $value = int $1;
9533         }
9534         elsif ( $f =~ /^DEFAULT$/i ) {
9535             $value = $DollarCaretP_flags{PERLDB_ALL};
9536         }
9537         else {
9538             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9539             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9540             unless ( defined $value ) {
9541                 print $OUT (
9542                     "Unrecognized \$^P flag '$f'!\n",
9543                     "Acceptable flags are: "
9544                       . join( ', ', sort keys %DollarCaretP_flags ),
9545                     ", and hexadecimal and decimal numbers.\n"
9546                 );
9547                 return undef;
9548             }
9549         }
9550         $acu |= $value;
9551     }
9552     $acu;
9553 }
9554
9555 sub expand_DollarCaretP_flags {
9556     my $DollarCaretP = shift;
9557     my @bits         = (
9558         map {
9559             my $n = ( 1 << $_ );
9560             ( $DollarCaretP & $n )
9561               ? ( $DollarCaretP_flags_r{$n}
9562                   || sprintf( '0x%x', $n ) )
9563               : ()
9564           } 0 .. 31
9565     );
9566     return @bits ? join( '|', @bits ) : 0;
9567 }
9568
9569 =over 4
9570
9571 =item rerun
9572
9573 Rerun the current session to:
9574
9575     rerun        current position
9576
9577     rerun 4      command number 4
9578
9579     rerun -4     current command minus 4 (go back 4 steps)
9580
9581 Whether this always makes sense, in the current context is unknowable, and is
9582 in part left as a useful exercise for the reader.  This sub returns the
9583 appropriate arguments to rerun the current session.
9584
9585 =cut
9586
9587 sub rerun {
9588     my $i = shift;
9589     my @args;
9590     pop(@truehist);                      # strim
9591     unless (defined $truehist[$i]) {
9592         print "Unable to return to non-existent command: $i\n";
9593     } else {
9594         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9595         my @temp = @truehist;            # store
9596         push(@DB::typeahead, @truehist); # saved
9597         @truehist = @hist = ();          # flush
9598         @args = restart();              # setup
9599         get_list("PERLDB_HIST");        # clean
9600         set_list("PERLDB_HIST", @temp); # reset
9601     }
9602     return @args;
9603 }
9604
9605 =item restart
9606
9607 Restarting the debugger is a complex operation that occurs in several phases.
9608 First, we try to reconstruct the command line that was used to invoke Perl
9609 and the debugger.
9610
9611 =cut
9612
9613 sub restart {
9614     # I may not be able to resurrect you, but here goes ...
9615     print $OUT
9616 "Warning: some settings and command-line options may be lost!\n";
9617     my ( @script, @flags, $cl );
9618
9619     # If warn was on before, turn it on again.
9620     push @flags, '-w' if $ini_warn;
9621
9622     # Rebuild the -I flags that were on the initial
9623     # command line.
9624     for (@ini_INC) {
9625         push @flags, '-I', $_;
9626     }
9627
9628     # Turn on taint if it was on before.
9629     push @flags, '-T' if ${^TAINT};
9630
9631     # Arrange for setting the old INC:
9632     # Save the current @init_INC in the environment.
9633     set_list( "PERLDB_INC", @ini_INC );
9634
9635     # If this was a perl one-liner, go to the "file"
9636     # corresponding to the one-liner read all the lines
9637     # out of it (except for the first one, which is going
9638     # to be added back on again when 'perl -d' runs: that's
9639     # the 'require perl5db.pl;' line), and add them back on
9640     # to the command line to be executed.
9641     if ( $0 eq '-e' ) {
9642         my $lines = *{$main::{'_<-e'}}{ARRAY};
9643         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9644             chomp( $cl = $lines->[$_] );
9645             push @script, '-e', $cl;
9646         }
9647     } ## end if ($0 eq '-e')
9648
9649     # Otherwise we just reuse the original name we had
9650     # before.
9651     else {
9652         @script = $0;
9653     }
9654
9655 =pod
9656
9657 After the command line  has been reconstructed, the next step is to save
9658 the debugger's status in environment variables. The C<DB::set_list> routine
9659 is used to save aggregate variables (both hashes and arrays); scalars are
9660 just popped into environment variables directly.
9661
9662 =cut
9663
9664     # If the terminal supported history, grab it and
9665     # save that in the environment.
9666     set_list( "PERLDB_HIST",
9667           $term->Features->{getHistory}
9668         ? $term->GetHistory
9669         : @hist );
9670
9671     # Find all the files that were visited during this
9672     # session (i.e., the debugger had magic hashes
9673     # corresponding to them) and stick them in the environment.
9674     my @had_breakpoints = keys %had_breakpoints;
9675     set_list( "PERLDB_VISITED", @had_breakpoints );
9676
9677     # Save the debugger options we chose.
9678     set_list( "PERLDB_OPT", %option );
9679     # set_list( "PERLDB_OPT", options2remember() );
9680
9681     # Save the break-on-loads.
9682     set_list( "PERLDB_ON_LOAD", %break_on_load );
9683
9684 =pod
9685
9686 The most complex part of this is the saving of all of the breakpoints. They
9687 can live in an awful lot of places, and we have to go through all of them,
9688 find the breakpoints, and then save them in the appropriate environment
9689 variable via C<DB::set_list>.
9690
9691 =cut
9692
9693     # Go through all the breakpoints and make sure they're
9694     # still valid.
9695     my @hard;
9696     for ( 0 .. $#had_breakpoints ) {
9697
9698         # We were in this file.
9699         my $file = $had_breakpoints[$_];
9700
9701         # Grab that file's magic line hash.
9702         *dbline = $main::{ '_<' . $file };
9703
9704         # Skip out if it doesn't exist, or if the breakpoint
9705         # is in a postponed file (we'll do postponed ones
9706         # later).
9707         next unless %dbline or $postponed_file{$file};
9708
9709         # In an eval. This is a little harder, so we'll
9710         # do more processing on that below.
9711         ( push @hard, $file ), next
9712           if $file =~ /^\(\w*eval/;
9713
9714         # XXX I have no idea what this is doing. Yet.
9715         my @add;
9716         @add = %{ $postponed_file{$file} }
9717           if $postponed_file{$file};
9718
9719         # Save the list of all the breakpoints for this file.
9720         set_list( "PERLDB_FILE_$_", %dbline, @add );
9721
9722         # Serialize the extra data %breakpoints_data hash.
9723         # That's a bug fix.
9724         set_list( "PERLDB_FILE_ENABLED_$_",
9725             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9726             sort { $a <=> $b } keys(%dbline)
9727         )
9728     } ## end for (0 .. $#had_breakpoints)
9729
9730     # The breakpoint was inside an eval. This is a little
9731     # more difficult. XXX and I don't understand it.
9732     foreach my $hard_file (@hard) {
9733         # Get over to the eval in question.
9734         *dbline = $main::{ '_<' . $hard_file };
9735         my $quoted = quotemeta $hard_file;
9736         my %subs;
9737         for my $sub ( keys %sub ) {
9738             if (my ($n1, $n2) = $sub{$sub} =~ /\A$quoted:(\d+)-(\d+)\z/) {
9739                 $subs{$sub} = [ $n1, $n2 ];
9740             }
9741         }
9742         unless (%subs) {
9743             print {$OUT}
9744             "No subroutines in $hard_file, ignoring breakpoints.\n";
9745             next;
9746         }
9747         LINES: foreach my $line ( keys %dbline ) {
9748
9749             # One breakpoint per sub only:
9750             my ( $offset, $found );
9751             SUBS: foreach my $sub ( keys %subs ) {
9752                 if (
9753                     $subs{$sub}->[1] >= $line    # Not after the subroutine
9754                     and (
9755                         not defined $offset    # Not caught
9756                             or $offset < 0
9757                     )
9758                 )
9759                 {                              # or badly caught
9760                     $found  = $sub;
9761                     $offset = $line - $subs{$sub}->[0];
9762                     if ($offset >= 0) {
9763                         $offset = "+$offset";
9764                         last SUBS;
9765                     }
9766                 } ## end if ($subs{$sub}->[1] >=...
9767             } ## end for $sub (keys %subs)
9768             if ( defined $offset ) {
9769                 $postponed{$found} =
9770                 "break $offset if $dbline{$line}";
9771             }
9772             else {
9773                 print {$OUT}
9774                 ("Breakpoint in ${hard_file}:$line ignored:"
9775                 . " after all the subroutines.\n");
9776             }
9777         } ## end for $line (keys %dbline)
9778     } ## end for (@hard)
9779
9780     # Save the other things that don't need to be
9781     # processed.
9782     set_list( "PERLDB_POSTPONE",  %postponed );
9783     set_list( "PERLDB_PRETYPE",   @$pretype );
9784     set_list( "PERLDB_PRE",       @$pre );
9785     set_list( "PERLDB_POST",      @$post );
9786     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9787
9788     # We are officially restarting.
9789     $ENV{PERLDB_RESTART} = 1;
9790
9791     # We are junking all child debuggers.
9792     delete $ENV{PERLDB_PIDS};    # Restore ini state
9793
9794     # Set this back to the initial pid.
9795     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9796
9797 =pod
9798
9799 After all the debugger status has been saved, we take the command we built up
9800 and then return it, so we can C<exec()> it. The debugger will spot the
9801 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9802 from the environment.
9803
9804 =cut
9805
9806     # And run Perl again. Add the "-d" flag, all the
9807     # flags we built up, the script (whether a one-liner
9808     # or a file), add on the -emacs flag for a slave editor,
9809     # and then the old arguments.
9810
9811     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9812
9813 };  # end restart
9814
9815 =back
9816
9817 =head1 END PROCESSING - THE C<END> BLOCK
9818
9819 Come here at the very end of processing. We want to go into a
9820 loop where we allow the user to enter commands and interact with the
9821 debugger, but we don't want anything else to execute.
9822
9823 First we set the C<$finished> variable, so that some commands that
9824 shouldn't be run after the end of program quit working.
9825
9826 We then figure out whether we're truly done (as in the user entered a C<q>
9827 command, or we finished execution while running nonstop). If we aren't,
9828 we set C<$single> to 1 (causing the debugger to get control again).
9829
9830 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9831 message and returns control to the debugger. Repeat.
9832
9833 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9834 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9835 break, run to completion.).
9836
9837 =cut
9838
9839 END {
9840     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9841     $fall_off_end = 1 unless $inhibit_exit;
9842
9843     # Do not stop in at_exit() and destructors on exit:
9844     if ($fall_off_end or $runnonstop) {
9845         save_hist();
9846     } else {
9847         $DB::single = 1;
9848         DB::fake::at_exit();
9849     }
9850 } ## end END
9851
9852 =head1 PRE-5.8 COMMANDS
9853
9854 Some of the commands changed function quite a bit in the 5.8 command
9855 realignment, so much so that the old code had to be replaced completely.
9856 Because we wanted to retain the option of being able to go back to the
9857 former command set, we moved the old code off to this section.
9858
9859 There's an awful lot of duplicated code here. We've duplicated the
9860 comments to keep things clear.
9861
9862 =head2 Null command
9863
9864 Does nothing. Used to I<turn off> commands.
9865
9866 =cut
9867
9868 sub cmd_pre580_null {
9869
9870     # do nothing...
9871 }
9872
9873 =head2 Old C<a> command.
9874
9875 This version added actions if you supplied them, and deleted them
9876 if you didn't.
9877
9878 =cut
9879
9880 sub cmd_pre580_a {
9881     my $xcmd = shift;
9882     my $cmd  = shift;
9883
9884     # Argument supplied. Add the action.
9885     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9886
9887         # If the line isn't there, use the current line.
9888         my $i = $1 || $line;
9889         my $j = $2;
9890
9891         # If there is an action ...
9892         if ( length $j ) {
9893
9894             # ... but the line isn't breakable, skip it.
9895             if ( $dbline[$i] == 0 ) {
9896                 print $OUT "Line $i may not have an action.\n";
9897             }
9898             else {
9899
9900                 # ... and the line is breakable:
9901                 # Mark that there's an action in this file.
9902                 $had_breakpoints{$filename} |= 2;
9903
9904                 # Delete any current action.
9905                 $dbline{$i} =~ s/\0[^\0]*//;
9906
9907                 # Add the new action, continuing the line as needed.
9908                 $dbline{$i} .= "\0" . action($j);
9909             }
9910         } ## end if (length $j)
9911
9912         # No action supplied.
9913         else {
9914
9915             # Delete the action.
9916             $dbline{$i} =~ s/\0[^\0]*//;
9917
9918             # Mark as having no break or action if nothing's left.
9919             delete $dbline{$i} if $dbline{$i} eq '';
9920         }
9921     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9922 } ## end sub cmd_pre580_a
9923
9924 =head2 Old C<b> command
9925
9926 Add breakpoints.
9927
9928 =cut
9929
9930 sub cmd_pre580_b {
9931     my $xcmd   = shift;
9932     my $cmd    = shift;
9933     my $dbline = shift;
9934
9935     # Break on load.
9936     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9937         my $file = $1;
9938         $file =~ s/\s+$//;
9939         cmd_b_load($file);
9940     }
9941
9942     # b compile|postpone <some sub> [<condition>]
9943     # The interpreter actually traps this one for us; we just put the
9944     # necessary condition in the %postponed hash.
9945     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9946
9947         # Capture the condition if there is one. Make it true if none.
9948         my $cond = length $3 ? $3 : '1';
9949
9950         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9951         # if it was 'compile'.
9952         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9953
9954         # De-Perl4-ify the name - ' separators to ::.
9955         $subname =~ s/\'/::/g;
9956
9957         # Qualify it into the current package unless it's already qualified.
9958         $subname = "${package}::" . $subname
9959           unless $subname =~ /::/;
9960
9961         # Add main if it starts with ::.
9962         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9963
9964         # Save the break type for this sub.
9965         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9966     } ## end elsif ($cmd =~ ...
9967
9968     # b <sub name> [<condition>]
9969     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9970         my $subname = $1;
9971         my $cond = length $2 ? $2 : '1';
9972         cmd_b_sub( $subname, $cond );
9973     }
9974     # b <line> [<condition>].
9975     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9976         my $i = $1 || $dbline;
9977         my $cond = length $2 ? $2 : '1';
9978         cmd_b_line( $i, $cond );
9979     }
9980 } ## end sub cmd_pre580_b
9981
9982 =head2 Old C<D> command.
9983
9984 Delete all breakpoints unconditionally.
9985
9986 =cut
9987
9988 sub cmd_pre580_D {
9989     my $xcmd = shift;
9990     my $cmd  = shift;
9991     if ( $cmd =~ /^\s*$/ ) {
9992         print $OUT "Deleting all breakpoints...\n";
9993
9994         # %had_breakpoints lists every file that had at least one
9995         # breakpoint in it.
9996         my $file;
9997         for $file ( keys %had_breakpoints ) {
9998
9999             # Switch to the desired file temporarily.
10000             local *dbline = $main::{ '_<' . $file };
10001
10002             $max = $#dbline;
10003             my $was;
10004
10005             # For all lines in this file ...
10006             for my $i (1 .. $max) {
10007
10008                 # If there's a breakpoint or action on this line ...
10009                 if ( defined $dbline{$i} ) {
10010
10011                     # ... remove the breakpoint.
10012                     $dbline{$i} =~ s/^[^\0]+//;
10013                     if ( $dbline{$i} =~ s/^\0?$// ) {
10014
10015                         # Remove the entry altogether if no action is there.
10016                         delete $dbline{$i};
10017                     }
10018                 } ## end if (defined $dbline{$i...
10019             } ## end for my $i (1 .. $max)
10020
10021             # If, after we turn off the "there were breakpoints in this file"
10022             # bit, the entry in %had_breakpoints for this file is zero,
10023             # we should remove this file from the hash.
10024             if ( not $had_breakpoints{$file} &= ~1 ) {
10025                 delete $had_breakpoints{$file};
10026             }
10027         } ## end for $file (keys %had_breakpoints)
10028
10029         # Kill off all the other breakpoints that are waiting for files that
10030         # haven't been loaded yet.
10031         undef %postponed;
10032         undef %postponed_file;
10033         undef %break_on_load;
10034     } ## end if ($cmd =~ /^\s*$/)
10035 } ## end sub cmd_pre580_D
10036
10037 =head2 Old C<h> command
10038
10039 Print help. Defaults to printing the long-form help; the 5.8 version
10040 prints the summary by default.
10041
10042 =cut
10043
10044 sub cmd_pre580_h {
10045     my $xcmd = shift;
10046     my $cmd  = shift;
10047
10048     # Print the *right* help, long format.
10049     if ( $cmd =~ /^\s*$/ ) {
10050         print_help($pre580_help);
10051     }
10052
10053     # 'h h' - explicitly-requested summary.
10054     elsif ( $cmd =~ /^h\s*/ ) {
10055         print_help($pre580_summary);
10056     }
10057
10058     # Find and print a command's help.
10059     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10060         my $asked  = $1;                   # for proper errmsg
10061         my $qasked = quotemeta($asked);    # for searching
10062                                            # XXX: finds CR but not <CR>
10063         if (
10064             $pre580_help =~ /^
10065                               <?           # Optional '<'
10066                               (?:[IB]<)    # Optional markup
10067                               $qasked      # The command name
10068                             /mx
10069           )
10070         {
10071
10072             while (
10073                 $pre580_help =~ /^
10074                                   (             # The command help:
10075                                    <?           # Optional '<'
10076                                    (?:[IB]<)    # Optional markup
10077                                    $qasked      # The command name
10078                                    ([\s\S]*?)   # Lines starting with tabs
10079                                    \n           # Final newline
10080                                   )
10081                                   (?!\s)/mgx
10082               )    # Line not starting with space
10083                    # (Next command's help)
10084             {
10085                 print_help($1);
10086             }
10087         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10088
10089         # Help not found.
10090         else {
10091             print_help("B<$asked> is not a debugger command.\n");
10092         }
10093     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10094 } ## end sub cmd_pre580_h
10095
10096 =head2 Old C<W> command
10097
10098 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10099
10100 =cut
10101
10102 sub cmd_pre580_W {
10103     my $xcmd = shift;
10104     my $cmd  = shift;
10105
10106     # Delete all watch expressions.
10107     if ( $cmd =~ /^$/ ) {
10108
10109         # No watching is going on.
10110         $trace &= ~2;
10111
10112         # Kill all the watch expressions and values.
10113         @to_watch = @old_watch = ();
10114     }
10115
10116     # Add a watch expression.
10117     elsif ( $cmd =~ /^(.*)/s ) {
10118
10119         # add it to the list to be watched.
10120         push @to_watch, $1;
10121
10122         # Get the current value of the expression.
10123         # Doesn't handle expressions returning list values!
10124         $evalarg = $1;
10125         my ($val) = DB::eval();
10126         $val = ( defined $val ) ? "'$val'" : 'undef';
10127
10128         # Save it.
10129         push @old_watch, $val;
10130
10131         # We're watching stuff.
10132         $trace |= 2;
10133
10134     } ## end elsif ($cmd =~ /^(.*)/s)
10135 } ## end sub cmd_pre580_W
10136
10137 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10138
10139 The debugger used to have a bunch of nearly-identical code to handle
10140 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10141 C<cmd_prepost> unify all this into one set of code to handle the
10142 appropriate actions.
10143
10144 =head2 C<cmd_pre590_prepost>
10145
10146 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10147 do something destructive. In pre 5.8 debuggers, the default action was to
10148 delete all the actions.
10149
10150 =cut
10151
10152 sub cmd_pre590_prepost {
10153     my $cmd    = shift;
10154     my $line   = shift || '*';
10155     my $dbline = shift;
10156
10157     return cmd_prepost( $cmd, $line, $dbline );
10158 } ## end sub cmd_pre590_prepost
10159
10160 =head2 C<cmd_prepost>
10161
10162 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10163 Since the lists of actions are all held in arrays that are pointed to by
10164 references anyway, all we have to do is pick the right array reference and
10165 then use generic code to all, delete, or list actions.
10166
10167 =cut
10168
10169 sub cmd_prepost {
10170     my $cmd = shift;
10171
10172     # No action supplied defaults to 'list'.
10173     my $line = shift || '?';
10174
10175     # Figure out what to put in the prompt.
10176     my $which = '';
10177
10178     # Make sure we have some array or another to address later.
10179     # This means that if for some reason the tests fail, we won't be
10180     # trying to stash actions or delete them from the wrong place.
10181     my $aref = [];
10182
10183     # < - Perl code to run before prompt.
10184     if ( $cmd =~ /^\</o ) {
10185         $which = 'pre-perl';
10186         $aref  = $pre;
10187     }
10188
10189     # > - Perl code to run after prompt.
10190     elsif ( $cmd =~ /^\>/o ) {
10191         $which = 'post-perl';
10192         $aref  = $post;
10193     }
10194
10195     # { - first check for properly-balanced braces.
10196     elsif ( $cmd =~ /^\{/o ) {
10197         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10198             print $OUT
10199 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10200         }
10201
10202         # Properly balanced. Pre-prompt debugger actions.
10203         else {
10204             $which = 'pre-debugger';
10205             $aref  = $pretype;
10206         }
10207     } ## end elsif ( $cmd =~ /^\{/o )
10208
10209     # Did we find something that makes sense?
10210     unless ($which) {
10211         print $OUT "Confused by command: $cmd\n";
10212     }
10213
10214     # Yes.
10215     else {
10216
10217         # List actions.
10218         if ( $line =~ /^\s*\?\s*$/o ) {
10219             unless (@$aref) {
10220
10221                 # Nothing there. Complain.
10222                 print $OUT "No $which actions.\n";
10223             }
10224             else {
10225
10226                 # List the actions in the selected list.
10227                 print $OUT "$which commands:\n";
10228                 foreach my $action (@$aref) {
10229                     print $OUT "\t$cmd -- $action\n";
10230                 }
10231             } ## end else
10232         } ## end if ( $line =~ /^\s*\?\s*$/o)
10233
10234         # Might be a delete.
10235         else {
10236             if ( length($cmd) == 1 ) {
10237                 if ( $line =~ /^\s*\*\s*$/o ) {
10238
10239                     # It's a delete. Get rid of the old actions in the
10240                     # selected list..
10241                     @$aref = ();
10242                     print $OUT "All $cmd actions cleared.\n";
10243                 }
10244                 else {
10245
10246                     # Replace all the actions. (This is a <, >, or {).
10247                     @$aref = action($line);
10248                 }
10249             } ## end if ( length($cmd) == 1)
10250             elsif ( length($cmd) == 2 ) {
10251
10252                 # Add the action to the line. (This is a <<, >>, or {{).
10253                 push @$aref, action($line);
10254             }
10255             else {
10256
10257                 # <<<, >>>>, {{{{{{ ... something not a command.
10258                 print $OUT
10259                   "Confused by strange length of $which command($cmd)...\n";
10260             }
10261         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10262     } ## end else
10263 } ## end sub cmd_prepost
10264
10265 =head1 C<DB::fake>
10266
10267 Contains the C<at_exit> routine that the debugger uses to issue the
10268 C<Debugged program terminated ...> message after the program completes. See
10269 the C<END> block documentation for more details.
10270
10271 =cut
10272
10273 package DB::fake;
10274
10275 sub at_exit {
10276     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10277 }
10278
10279 package DB;    # Do not trace this 1; below!
10280
10281 1;
10282
10283