This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Correct Unicode 6.1 omission
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Prior to 5.14, generally a property would have either its
166 # map table or its match tables written but not both.  Again, what gets
167 # written is controlled by lists which can easily be changed.  Starting in
168 # 5.14, advantage was taken of this, and all the map tables needed to
169 # reconstruct the Unicode db are now written out, while suppressing the
170 # Unicode .txt files that contain the data.  Our tables are much more compact
171 # than the .txt files, so a significant space savings was achieved.
172
173 # Properties have a 'Type', like binary, or string, or enum depending on how
174 # many match tables there are and the content of the maps.  This 'Type' is
175 # different than a range 'Type', so don't get confused by the two concepts
176 # having the same name.
177 #
178 # For information about the Unicode properties, see Unicode's UAX44 document:
179
180 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
181
182 # As stated earlier, this program will work on any release of Unicode so far.
183 # Most obvious problems in earlier data have NOT been corrected except when
184 # necessary to make Perl or this program work reasonably.  For example, no
185 # folding information was given in early releases, so this program substitutes
186 # lower case instead, just so that a regular expression with the /i option
187 # will do something that actually gives the right results in many cases.
188 # There are also a couple other corrections for version 1.1.5, commented at
189 # the point they are made.  As an example of corrections that weren't made
190 # (but could be) is this statement from DerivedAge.txt: "The supplementary
191 # private use code points and the non-character code points were assigned in
192 # version 2.0, but not specifically listed in the UCD until versions 3.0 and
193 # 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0) More information
194 # on Unicode version glitches is further down in these introductory comments.
195 #
196 # This program works on all non-provisional properties as of 6.0, though the
197 # files for some are suppressed from apparent lack of demand for them.  You
198 # can change which are output by changing lists in this program.
199 #
200 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
201 # loose matchings rules (from Unicode TR18):
202 #
203 #    The recommended names for UCD properties and property values are in
204 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
205 #    [PropValue]. There are both abbreviated names and longer, more
206 #    descriptive names. It is strongly recommended that both names be
207 #    recognized, and that loose matching of property names be used,
208 #    whereby the case distinctions, whitespace, hyphens, and underbar
209 #    are ignored.
210 # The program still allows Fuzzy to override its determination of if loose
211 # matching should be used, but it isn't currently used, as it is no longer
212 # needed; the calculations it makes are good enough.
213 #
214 # SUMMARY OF HOW IT WORKS:
215 #
216 #   Process arguments
217 #
218 #   A list is constructed containing each input file that is to be processed
219 #
220 #   Each file on the list is processed in a loop, using the associated handler
221 #   code for each:
222 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
223 #            first.  These files name the properties and property values.
224 #            Objects are created of all the property and property value names
225 #            that the rest of the input should expect, including all synonyms.
226 #        The other input files give mappings from properties to property
227 #           values.  That is, they list code points and say what the mapping
228 #           is under the given property.  Some files give the mappings for
229 #           just one property; and some for many.  This program goes through
230 #           each file and populates the properties from them.  Some properties
231 #           are listed in more than one file, and Unicode has set up a
232 #           precedence as to which has priority if there is a conflict.  Thus
233 #           the order of processing matters, and this program handles the
234 #           conflict possibility by processing the overriding input files
235 #           last, so that if necessary they replace earlier values.
236 #        After this is all done, the program creates the property mappings not
237 #            furnished by Unicode, but derivable from what it does give.
238 #        The tables of code points that match each property value in each
239 #            property that is accessible by regular expressions are created.
240 #        The Perl-defined properties are created and populated.  Many of these
241 #            require data determined from the earlier steps
242 #        Any Perl-defined synonyms are created, and name clashes between Perl
243 #            and Unicode are reconciled and warned about.
244 #        All the properties are written to files
245 #        Any other files are written, and final warnings issued.
246 #
247 # For clarity, a number of operators have been overloaded to work on tables:
248 #   ~ means invert (take all characters not in the set).  The more
249 #       conventional '!' is not used because of the possibility of confusing
250 #       it with the actual boolean operation.
251 #   + means union
252 #   - means subtraction
253 #   & means intersection
254 # The precedence of these is the order listed.  Parentheses should be
255 # copiously used.  These are not a general scheme.  The operations aren't
256 # defined for a number of things, deliberately, to avoid getting into trouble.
257 # Operations are done on references and affect the underlying structures, so
258 # that the copy constructors for them have been overloaded to not return a new
259 # clone, but the input object itself.
260 #
261 # The bool operator is deliberately not overloaded to avoid confusion with
262 # "should it mean if the object merely exists, or also is non-empty?".
263 #
264 # WHY CERTAIN DESIGN DECISIONS WERE MADE
265 #
266 # This program needs to be able to run under miniperl.  Therefore, it uses a
267 # minimum of other modules, and hence implements some things itself that could
268 # be gotten from CPAN
269 #
270 # This program uses inputs published by the Unicode Consortium.  These can
271 # change incompatibly between releases without the Perl maintainers realizing
272 # it.  Therefore this program is now designed to try to flag these.  It looks
273 # at the directories where the inputs are, and flags any unrecognized files.
274 # It keeps track of all the properties in the files it handles, and flags any
275 # that it doesn't know how to handle.  It also flags any input lines that
276 # don't match the expected syntax, among other checks.
277 #
278 # It is also designed so if a new input file matches one of the known
279 # templates, one hopefully just needs to add it to a list to have it
280 # processed.
281 #
282 # As mentioned earlier, some properties are given in more than one file.  In
283 # particular, the files in the extracted directory are supposedly just
284 # reformattings of the others.  But they contain information not easily
285 # derivable from the other files, including results for Unihan, which this
286 # program doesn't ordinarily look at, and for unassigned code points.  They
287 # also have historically had errors or been incomplete.  In an attempt to
288 # create the best possible data, this program thus processes them first to
289 # glean information missing from the other files; then processes those other
290 # files to override any errors in the extracted ones.  Much of the design was
291 # driven by this need to store things and then possibly override them.
292 #
293 # It tries to keep fatal errors to a minimum, to generate something usable for
294 # testing purposes.  It always looks for files that could be inputs, and will
295 # warn about any that it doesn't know how to handle (the -q option suppresses
296 # the warning).
297 #
298 # Why is there more than one type of range?
299 #   This simplified things.  There are some very specialized code points that
300 #   have to be handled specially for output, such as Hangul syllable names.
301 #   By creating a range type (done late in the development process), it
302 #   allowed this to be stored with the range, and overridden by other input.
303 #   Originally these were stored in another data structure, and it became a
304 #   mess trying to decide if a second file that was for the same property was
305 #   overriding the earlier one or not.
306 #
307 # Why are there two kinds of tables, match and map?
308 #   (And there is a base class shared by the two as well.)  As stated above,
309 #   they actually are for different things.  Development proceeded much more
310 #   smoothly when I (khw) realized the distinction.  Map tables are used to
311 #   give the property value for every code point (actually every code point
312 #   that doesn't map to a default value).  Match tables are used for regular
313 #   expression matches, and are essentially the inverse mapping.  Separating
314 #   the two allows more specialized methods, and error checks so that one
315 #   can't just take the intersection of two map tables, for example, as that
316 #   is nonsensical.
317 #
318 # DEBUGGING
319 #
320 # This program is written so it will run under miniperl.  Occasionally changes
321 # will cause an error where the backtrace doesn't work well under miniperl.
322 # To diagnose the problem, you can instead run it under regular perl, if you
323 # have one compiled.
324 #
325 # There is a good trace facility.  To enable it, first sub DEBUG must be set
326 # to return true.  Then a line like
327 #
328 # local $to_trace = 1 if main::DEBUG;
329 #
330 # can be added to enable tracing in its lexical scope or until you insert
331 # another line:
332 #
333 # local $to_trace = 0 if main::DEBUG;
334 #
335 # then use a line like "trace $a, @b, %c, ...;
336 #
337 # Some of the more complex subroutines already have trace statements in them.
338 # Permanent trace statements should be like:
339 #
340 # trace ... if main::DEBUG && $to_trace;
341 #
342 # If there is just one or a few files that you're debugging, you can easily
343 # cause most everything else to be skipped.  Change the line
344 #
345 # my $debug_skip = 0;
346 #
347 # to 1, and every file whose object is in @input_file_objects and doesn't have
348 # a, 'non_skip => 1,' in its constructor will be skipped.
349 #
350 # To compare the output tables, it may be useful to specify the -annotate
351 # flag.  This causes the tables to expand so there is one entry for each
352 # non-algorithmically named code point giving, currently its name, and its
353 # graphic representation if printable (and you have a font that knows about
354 # it).  This makes it easier to see what the particular code points are in
355 # each output table.  The tables are usable, but because they don't have
356 # ranges (for the most part), a Perl using them will run slower.  Non-named
357 # code points are annotated with a description of their status, and contiguous
358 # ones with the same description will be output as a range rather than
359 # individually.  Algorithmically named characters are also output as ranges,
360 # except when there are just a few contiguous ones.
361 #
362 # FUTURE ISSUES
363 #
364 # The program would break if Unicode were to change its names so that
365 # interior white space, underscores, or dashes differences were significant
366 # within property and property value names.
367 #
368 # It might be easier to use the xml versions of the UCD if this program ever
369 # would need heavy revision, and the ability to handle old versions was not
370 # required.
371 #
372 # There is the potential for name collisions, in that Perl has chosen names
373 # that Unicode could decide it also likes.  There have been such collisions in
374 # the past, with mostly Perl deciding to adopt the Unicode definition of the
375 # name.  However in the 5.2 Unicode beta testing, there were a number of such
376 # collisions, which were withdrawn before the final release, because of Perl's
377 # and other's protests.  These all involved new properties which began with
378 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
379 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
380 # Unicode document, so they are unlikely to be used by Unicode for another
381 # purpose.  However, they might try something beginning with 'In', or use any
382 # of the other Perl-defined properties.  This program will warn you of name
383 # collisions, and refuse to generate tables with them, but manual intervention
384 # will be required in this event.  One scheme that could be implemented, if
385 # necessary, would be to have this program generate another file, or add a
386 # field to mktables.lst that gives the date of first definition of a property.
387 # Each new release of Unicode would use that file as a basis for the next
388 # iteration.  And the Perl synonym addition code could sort based on the age
389 # of the property, so older properties get priority, and newer ones that clash
390 # would be refused; hence existing code would not be impacted, and some other
391 # synonym would have to be used for the new property.  This is ugly, and
392 # manual intervention would certainly be easier to do in the short run; lets
393 # hope it never comes to this.
394 #
395 # A NOTE ON UNIHAN
396 #
397 # This program can generate tables from the Unihan database.  But it doesn't
398 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
399 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
400 # database was split into 8 different files, all beginning with the letters
401 # 'Unihan'.  This program will read those file(s) if present, but it needs to
402 # know which of the many properties in the file(s) should have tables created
403 # for them.  It will create tables for any properties listed in
404 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
405 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
406 # property you want is not in those files of the release you are building
407 # against, you must add it to those two arrays.  Starting in 4.0, the
408 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
409 # is present in the directory, a table will be generated for that property.
410 # In 5.2, several more properties were added.  For your convenience, the two
411 # arrays are initialized with all the 6.0 listed properties that are also in
412 # earlier releases.  But these are commented out.  You can just uncomment the
413 # ones you want, or use them as a template for adding entries for other
414 # properties.
415 #
416 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
417 # and filter_unihan_line() are the functions where this is done.  This program
418 # already does some adjusting to make the lines look more like the rest of the
419 # Unicode DB;  You can see what that is in filter_unihan_line()
420 #
421 # There is a bug in the 3.2 data file in which some values for the
422 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
423 # could be added for these; or for a particular installation, the Unihan.txt
424 # file could be edited to fix them.
425 #
426 # HOW TO ADD A FILE TO BE PROCESSED
427 #
428 # A new file from Unicode needs to have an object constructed for it in
429 # @input_file_objects, probably at the end or at the end of the extracted
430 # ones.  The program should warn you if its name will clash with others on
431 # restrictive file systems, like DOS.  If so, figure out a better name, and
432 # add lines to the README.perl file giving that.  If the file is a character
433 # property, it should be in the format that Unicode has by default
434 # standardized for such files for the more recently introduced ones.
435 # If so, the Input_file constructor for @input_file_objects can just be the
436 # file name and release it first appeared in.  If not, then it should be
437 # possible to construct an each_line_handler() to massage the line into the
438 # standardized form.
439 #
440 # For non-character properties, more code will be needed.  You can look at
441 # the existing entries for clues.
442 #
443 # UNICODE VERSIONS NOTES
444 #
445 # The Unicode UCD has had a number of errors in it over the versions.  And
446 # these remain, by policy, in the standard for that version.  Therefore it is
447 # risky to correct them, because code may be expecting the error.  So this
448 # program doesn't generally make changes, unless the error breaks the Perl
449 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
450 # for U+1105, which causes real problems for the algorithms for Jamo
451 # calculations, so it is changed here.
452 #
453 # But it isn't so clear cut as to what to do about concepts that are
454 # introduced in a later release; should they extend back to earlier releases
455 # where the concept just didn't exist?  It was easier to do this than to not,
456 # so that's what was done.  For example, the default value for code points not
457 # in the files for various properties was probably undefined until changed by
458 # some version.  No_Block for blocks is such an example.  This program will
459 # assign No_Block even in Unicode versions that didn't have it.  This has the
460 # benefit that code being written doesn't have to special case earlier
461 # versions; and the detriment that it doesn't match the Standard precisely for
462 # the affected versions.
463 #
464 # Here are some observations about some of the issues in early versions:
465 #
466 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
467 # the reason is that the CJK block starting at 4E00 was removed from PropList,
468 # and was not put back in until 3.1.0
469 #
470 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
471 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
472 # reason is that 3.2 introduced U+205F=medium math space, which was not
473 # classed as white space, but Perl figured out that it should have been. 4.0
474 # reclassified it correctly.
475 #
476 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
477 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
478 # was left with no code points, as all the ones that mapped to 202 stayed
479 # mapped to 202.  Thus if your program used the numeric name for the class,
480 # it would not have been affected, but if it used the mnemonic, it would have
481 # been.
482 #
483 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
484 # points which eventually came to have this script property value, instead
485 # mapped to "Unknown".  But in the next release all these code points were
486 # moved to \p{sc=common} instead.
487 #
488 # The default for missing code points for BidiClass is complicated.  Starting
489 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
490 # tries to do the best it can for earlier releases.  It is done in
491 # process_PropertyAliases()
492 #
493 ##############################################################################
494
495 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
496                         # and errors
497 my $MAX_LINE_WIDTH = 78;
498
499 # Debugging aid to skip most files so as to not be distracted by them when
500 # concentrating on the ones being debugged.  Add
501 # non_skip => 1,
502 # to the constructor for those files you want processed when you set this.
503 # Files with a first version number of 0 are special: they are always
504 # processed regardless of the state of this flag.  Generally, Jamo.txt and
505 # UnicodeData.txt must not be skipped if you want this program to not die
506 # before normal completion.
507 my $debug_skip = 0;
508
509 # Set to 1 to enable tracing.
510 our $to_trace = 0;
511
512 { # Closure for trace: debugging aid
513     my $print_caller = 1;        # ? Include calling subroutine name
514     my $main_with_colon = 'main::';
515     my $main_colon_length = length($main_with_colon);
516
517     sub trace {
518         return unless $to_trace;        # Do nothing if global flag not set
519
520         my @input = @_;
521
522         local $DB::trace = 0;
523         $DB::trace = 0;          # Quiet 'used only once' message
524
525         my $line_number;
526
527         # Loop looking up the stack to get the first non-trace caller
528         my $caller_line;
529         my $caller_name;
530         my $i = 0;
531         do {
532             $line_number = $caller_line;
533             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
534             $caller = $main_with_colon unless defined $caller;
535
536             $caller_name = $caller;
537
538             # get rid of pkg
539             $caller_name =~ s/.*:://;
540             if (substr($caller_name, 0, $main_colon_length)
541                 eq $main_with_colon)
542             {
543                 $caller_name = substr($caller_name, $main_colon_length);
544             }
545
546         } until ($caller_name ne 'trace');
547
548         # If the stack was empty, we were called from the top level
549         $caller_name = 'main' if ($caller_name eq ""
550                                     || $caller_name eq 'trace');
551
552         my $output = "";
553         foreach my $string (@input) {
554             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
555             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
556                 $output .= simple_dumper($string);
557             }
558             else {
559                 $string = "$string" if ref $string;
560                 $string = $UNDEF unless defined $string;
561                 chomp $string;
562                 $string = '""' if $string eq "";
563                 $output .= " " if $output ne ""
564                                 && $string ne ""
565                                 && substr($output, -1, 1) ne " "
566                                 && substr($string, 0, 1) ne " ";
567                 $output .= $string;
568             }
569         }
570
571         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
572         print STDERR "$caller_name: " if $print_caller;
573         print STDERR $output, "\n";
574         return;
575     }
576 }
577
578 # This is for a rarely used development feature that allows you to compare two
579 # versions of the Unicode standard without having to deal with changes caused
580 # by the code points introduced in the later version.  Change the 0 to a
581 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
582 # code points introduced in that release and earlier will be used; later ones
583 # are thrown away.  You use the version number of the earliest one you want to
584 # compare; then run this program on directory structures containing each
585 # release, and compare the outputs.  These outputs will therefore include only
586 # the code points common to both releases, and you can see the changes caused
587 # just by the underlying release semantic changes.  For versions earlier than
588 # 3.2, you must copy a version of DAge.txt into the directory.
589 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
590 my $compare_versions = DEBUG
591                        && $string_compare_versions
592                        && pack "C*", split /\./, $string_compare_versions;
593
594 sub uniques {
595     # Returns non-duplicated input values.  From "Perl Best Practices:
596     # Encapsulated Cleverness".  p. 455 in first edition.
597
598     my %seen;
599     # Arguably this breaks encapsulation, if the goal is to permit multiple
600     # distinct objects to stringify to the same value, and be interchangeable.
601     # However, for this program, no two objects stringify identically, and all
602     # lists passed to this function are either objects or strings. So this
603     # doesn't affect correctness, but it does give a couple of percent speedup.
604     no overloading;
605     return grep { ! $seen{$_}++ } @_;
606 }
607
608 $0 = File::Spec->canonpath($0);
609
610 my $make_test_script = 0;      # ? Should we output a test script
611 my $write_unchanged_files = 0; # ? Should we update the output files even if
612                                #    we don't think they have changed
613 my $use_directory = "";        # ? Should we chdir somewhere.
614 my $pod_directory;             # input directory to store the pod file.
615 my $pod_file = 'perluniprops';
616 my $t_path;                     # Path to the .t test file
617 my $file_list = 'mktables.lst'; # File to store input and output file names.
618                                # This is used to speed up the build, by not
619                                # executing the main body of the program if
620                                # nothing on the list has changed since the
621                                # previous build
622 my $make_list = 1;             # ? Should we write $file_list.  Set to always
623                                # make a list so that when the pumpking is
624                                # preparing a release, s/he won't have to do
625                                # special things
626 my $glob_list = 0;             # ? Should we try to include unknown .txt files
627                                # in the input.
628 my $output_range_counts = $debugging_build;   # ? Should we include the number
629                                               # of code points in ranges in
630                                               # the output
631 my $annotate = 0;              # ? Should character names be in the output
632
633 # Verbosity levels; 0 is quiet
634 my $NORMAL_VERBOSITY = 1;
635 my $PROGRESS = 2;
636 my $VERBOSE = 3;
637
638 my $verbosity = $NORMAL_VERBOSITY;
639
640 # Process arguments
641 while (@ARGV) {
642     my $arg = shift @ARGV;
643     if ($arg eq '-v') {
644         $verbosity = $VERBOSE;
645     }
646     elsif ($arg eq '-p') {
647         $verbosity = $PROGRESS;
648         $| = 1;     # Flush buffers as we go.
649     }
650     elsif ($arg eq '-q') {
651         $verbosity = 0;
652     }
653     elsif ($arg eq '-w') {
654         $write_unchanged_files = 1; # update the files even if havent changed
655     }
656     elsif ($arg eq '-check') {
657         my $this = shift @ARGV;
658         my $ok = shift @ARGV;
659         if ($this ne $ok) {
660             print "Skipping as check params are not the same.\n";
661             exit(0);
662         }
663     }
664     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
665         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
666     }
667     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
668     {
669         $make_test_script = 1;
670     }
671     elsif ($arg eq '-makelist') {
672         $make_list = 1;
673     }
674     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
675         -d $use_directory or croak "Unknown directory '$use_directory'";
676     }
677     elsif ($arg eq '-L') {
678
679         # Existence not tested until have chdir'd
680         $file_list = shift;
681     }
682     elsif ($arg eq '-globlist') {
683         $glob_list = 1;
684     }
685     elsif ($arg eq '-c') {
686         $output_range_counts = ! $output_range_counts
687     }
688     elsif ($arg eq '-annotate') {
689         $annotate = 1;
690         $debugging_build = 1;
691         $output_range_counts = 1;
692     }
693     else {
694         my $with_c = 'with';
695         $with_c .= 'out' if $output_range_counts;   # Complements the state
696         croak <<END;
697 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
698           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
699           [-check A B ]
700   -c          : Output comments $with_c number of code points in ranges
701   -q          : Quiet Mode: Only output serious warnings.
702   -p          : Set verbosity level to normal plus show progress.
703   -v          : Set Verbosity level high:  Show progress and non-serious
704                 warnings
705   -w          : Write files regardless
706   -C dir      : Change to this directory before proceeding. All relative paths
707                 except those specified by the -P and -T options will be done
708                 with respect to this directory.
709   -P dir      : Output $pod_file file to directory 'dir'.
710   -T path     : Create a test script as 'path'; overrides -maketest
711   -L filelist : Use alternate 'filelist' instead of standard one
712   -globlist   : Take as input all non-Test *.txt files in current and sub
713                 directories
714   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
715                 overrides -T
716   -makelist   : Rewrite the file list $file_list based on current setup
717   -annotate   : Output an annotation for each character in the table files;
718                 useful for debugging mktables, looking at diffs; but is slow,
719                 memory intensive; resulting tables are usable but are slow and
720                 very large (and currently fail the Unicode::UCD.t tests).
721   -check A B  : Executes $0 only if A and B are the same
722 END
723     }
724 }
725
726 # Stores the most-recently changed file.  If none have changed, can skip the
727 # build
728 my $most_recent = (stat $0)[9];   # Do this before the chdir!
729
730 # Change directories now, because need to read 'version' early.
731 if ($use_directory) {
732     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
733         $pod_directory = File::Spec->rel2abs($pod_directory);
734     }
735     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
736         $t_path = File::Spec->rel2abs($t_path);
737     }
738     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
739     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
740         $pod_directory = File::Spec->abs2rel($pod_directory);
741     }
742     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
743         $t_path = File::Spec->abs2rel($t_path);
744     }
745 }
746
747 # Get Unicode version into regular and v-string.  This is done now because
748 # various tables below get populated based on it.  These tables are populated
749 # here to be near the top of the file, and so easily seeable by those needing
750 # to modify things.
751 open my $VERSION, "<", "version"
752                     or croak "$0: can't open required file 'version': $!\n";
753 my $string_version = <$VERSION>;
754 close $VERSION;
755 chomp $string_version;
756 my $v_version = pack "C*", split /\./, $string_version;        # v string
757
758 # The following are the complete names of properties with property values that
759 # are known to not match any code points in some versions of Unicode, but that
760 # may change in the future so they should be matchable, hence an empty file is
761 # generated for them.
762 my @tables_that_may_be_empty = (
763                                 'Joining_Type=Left_Joining',
764                                 );
765 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
766 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
767 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
768                                                     if $v_version ge v4.1.0;
769 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
770                                                     if $v_version ge v6.0.0;
771 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
772                                                     if $v_version ge v6.1.0;
773
774 # The lists below are hashes, so the key is the item in the list, and the
775 # value is the reason why it is in the list.  This makes generation of
776 # documentation easier.
777
778 my %why_suppressed;  # No file generated for these.
779
780 # Files aren't generated for empty extraneous properties.  This is arguable.
781 # Extraneous properties generally come about because a property is no longer
782 # used in a newer version of Unicode.  If we generated a file without code
783 # points, programs that used to work on that property will still execute
784 # without errors.  It just won't ever match (or will always match, with \P{}).
785 # This means that the logic is now likely wrong.  I (khw) think its better to
786 # find this out by getting an error message.  Just move them to the table
787 # above to change this behavior
788 my %why_suppress_if_empty_warn_if_not = (
789
790    # It is the only property that has ever officially been removed from the
791    # Standard.  The database never contained any code points for it.
792    'Special_Case_Condition' => 'Obsolete',
793
794    # Apparently never official, but there were code points in some versions of
795    # old-style PropList.txt
796    'Non_Break' => 'Obsolete',
797 );
798
799 # These would normally go in the warn table just above, but they were changed
800 # a long time before this program was written, so warnings about them are
801 # moot.
802 if ($v_version gt v3.2.0) {
803     push @tables_that_may_be_empty,
804                                 'Canonical_Combining_Class=Attached_Below_Left'
805 }
806
807 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
808 # unless explicitly added.
809 if ($v_version ge v5.2.0) {
810     my $unihan = 'Unihan; remove from list if using Unihan';
811     foreach my $table (qw (
812                            kAccountingNumeric
813                            kOtherNumeric
814                            kPrimaryNumeric
815                            kCompatibilityVariant
816                            kIICore
817                            kIRG_GSource
818                            kIRG_HSource
819                            kIRG_JSource
820                            kIRG_KPSource
821                            kIRG_MSource
822                            kIRG_KSource
823                            kIRG_TSource
824                            kIRG_USource
825                            kIRG_VSource
826                            kRSUnicode
827                         ))
828     {
829         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
830     }
831 }
832
833 # Enum values for to_output_map() method in the Map_Table package.
834 my $EXTERNAL_MAP = 1;
835 my $INTERNAL_MAP = 2;
836 my $OUTPUT_ADJUSTED = 3;
837
838 # To override computed values for writing the map tables for these properties.
839 # The default for enum map tables is to write them out, so that the Unicode
840 # .txt files can be removed, but all the data to compute any property value
841 # for any code point is available in a more compact form.
842 my %global_to_output_map = (
843     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
844     # get stuck supporting it if things change.  Since it is a STRING
845     # property, it normally would be listed in the pod, but INTERNAL_MAP
846     # suppresses that.
847     Unicode_1_Name => $INTERNAL_MAP,
848
849     Present_In => 0,                # Suppress, as easily computed from Age
850     Block => 0,                     # Suppress, as Blocks.txt is retained.
851
852     # Suppress, as mapping can be found instead from the
853     # Perl_Decomposition_Mapping file
854     Decomposition_Type => 0,
855 );
856
857 # Properties that this program ignores.
858 my @unimplemented_properties;
859
860 # With this release, it is automatically handled if the Unihan db is
861 # downloaded
862 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
863
864 # There are several types of obsolete properties defined by Unicode.  These
865 # must be hand-edited for every new Unicode release.
866 my %why_deprecated;  # Generates a deprecated warning message if used.
867 my %why_stabilized;  # Documentation only
868 my %why_obsolete;    # Documentation only
869
870 {   # Closure
871     my $simple = 'Perl uses the more complete version of this property';
872     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
873
874     my $other_properties = 'other properties';
875     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
876     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
877
878     %why_deprecated = (
879         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
880         'Jamo_Short_Name' => $contributory,
881         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
882         'Other_Alphabetic' => $contributory,
883         'Other_Default_Ignorable_Code_Point' => $contributory,
884         'Other_Grapheme_Extend' => $contributory,
885         'Other_ID_Continue' => $contributory,
886         'Other_ID_Start' => $contributory,
887         'Other_Lowercase' => $contributory,
888         'Other_Math' => $contributory,
889         'Other_Uppercase' => $contributory,
890         'Expands_On_NFC' => $why_no_expand,
891         'Expands_On_NFD' => $why_no_expand,
892         'Expands_On_NFKC' => $why_no_expand,
893         'Expands_On_NFKD' => $why_no_expand,
894     );
895
896     %why_suppressed = (
897         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
898         # contains the same information, but without the algorithmically
899         # determinable Hangul syllables'.  This file is not published, so it's
900         # existence is not noted in the comment.
901         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or Unicode::UCD::prop_invmap()',
902
903         'Indic_Matra_Category' => "Provisional",
904         'Indic_Syllabic_Category' => "Provisional",
905
906         # Don't suppress ISO_Comment, as otherwise special handling is needed
907         # to differentiate between it and gc=c, which can be written as 'isc',
908         # which is the same characters as ISO_Comment's short name.
909
910         'Name' => "Accessible via \\N{...} or 'use charnames;' or Unicode::UCD::prop_invmap()",
911
912         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold or Unicode::UCD::prop_invmap()",
913         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
914         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
915         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
916
917         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
918     );
919
920     foreach my $property (
921
922             # The following are suppressed because they were made contributory
923             # or deprecated by Unicode before Perl ever thought about
924             # supporting them.
925             'Jamo_Short_Name',
926             'Grapheme_Link',
927             'Expands_On_NFC',
928             'Expands_On_NFD',
929             'Expands_On_NFKC',
930             'Expands_On_NFKD',
931
932             # The following are suppressed because they have been marked
933             # as deprecated for a sufficient amount of time
934             'Other_Alphabetic',
935             'Other_Default_Ignorable_Code_Point',
936             'Other_Grapheme_Extend',
937             'Other_ID_Continue',
938             'Other_ID_Start',
939             'Other_Lowercase',
940             'Other_Math',
941             'Other_Uppercase',
942     ) {
943         $why_suppressed{$property} = $why_deprecated{$property};
944     }
945
946     # Customize the message for all the 'Other_' properties
947     foreach my $property (keys %why_deprecated) {
948         next if (my $main_property = $property) !~ s/^Other_//;
949         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
950     }
951 }
952
953 if ($v_version ge 4.0.0) {
954     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
955     if ($v_version ge 6.0.0) {
956         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
957     }
958 }
959 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
960     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
961     if ($v_version ge 6.0.0) {
962         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
963     }
964 }
965
966 # Probably obsolete forever
967 if ($v_version ge v4.1.0) {
968     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
969 }
970 if ($v_version ge v6.0.0) {
971     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana (or both)"';
972     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
973 }
974
975 # This program can create files for enumerated-like properties, such as
976 # 'Numeric_Type'.  This file would be the same format as for a string
977 # property, with a mapping from code point to its value, so you could look up,
978 # for example, the script a code point is in.  But no one so far wants this
979 # mapping, or they have found another way to get it since this is a new
980 # feature.  So no file is generated except if it is in this list.
981 my @output_mapped_properties = split "\n", <<END;
982 END
983
984 # If you are using the Unihan database in a Unicode version before 5.2, you
985 # need to add the properties that you want to extract from it to this table.
986 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
987 # listed, commented out
988 my @cjk_properties = split "\n", <<'END';
989 #cjkAccountingNumeric; kAccountingNumeric
990 #cjkOtherNumeric; kOtherNumeric
991 #cjkPrimaryNumeric; kPrimaryNumeric
992 #cjkCompatibilityVariant; kCompatibilityVariant
993 #cjkIICore ; kIICore
994 #cjkIRG_GSource; kIRG_GSource
995 #cjkIRG_HSource; kIRG_HSource
996 #cjkIRG_JSource; kIRG_JSource
997 #cjkIRG_KPSource; kIRG_KPSource
998 #cjkIRG_KSource; kIRG_KSource
999 #cjkIRG_TSource; kIRG_TSource
1000 #cjkIRG_USource; kIRG_USource
1001 #cjkIRG_VSource; kIRG_VSource
1002 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1003 END
1004
1005 # Similarly for the property values.  For your convenience, the lines in the
1006 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1007 # '#' marks (for Unicode versions before 5.2)
1008 my @cjk_property_values = split "\n", <<'END';
1009 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1010 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1011 ## @missing: 0000..10FFFF; cjkIICore; <none>
1012 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1013 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1014 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1015 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1016 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1017 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1018 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1019 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1020 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1021 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1022 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1023 END
1024
1025 # The input files don't list every code point.  Those not listed are to be
1026 # defaulted to some value.  Below are hard-coded what those values are for
1027 # non-binary properties as of 5.1.  Starting in 5.0, there are
1028 # machine-parsable comment lines in the files the give the defaults; so this
1029 # list shouldn't have to be extended.  The claim is that all missing entries
1030 # for binary properties will default to 'N'.  Unicode tried to change that in
1031 # 5.2, but the beta period produced enough protest that they backed off.
1032 #
1033 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1034 # be in the form that it expects.  The others may be synonyms.
1035 my $CODE_POINT = '<code point>';
1036 my %default_mapping = (
1037     Age => "Unassigned",
1038     # Bidi_Class => Complicated; set in code
1039     Bidi_Mirroring_Glyph => "",
1040     Block => 'No_Block',
1041     Canonical_Combining_Class => 0,
1042     Case_Folding => $CODE_POINT,
1043     Decomposition_Mapping => $CODE_POINT,
1044     Decomposition_Type => 'None',
1045     East_Asian_Width => "Neutral",
1046     FC_NFKC_Closure => $CODE_POINT,
1047     General_Category => 'Cn',
1048     Grapheme_Cluster_Break => 'Other',
1049     Hangul_Syllable_Type => 'NA',
1050     ISO_Comment => "",
1051     Jamo_Short_Name => "",
1052     Joining_Group => "No_Joining_Group",
1053     # Joining_Type => Complicated; set in code
1054     kIICore => 'N',   #                       Is converted to binary
1055     #Line_Break => Complicated; set in code
1056     Lowercase_Mapping => $CODE_POINT,
1057     Name => "",
1058     Name_Alias => "",
1059     NFC_QC => 'Yes',
1060     NFD_QC => 'Yes',
1061     NFKC_QC => 'Yes',
1062     NFKD_QC => 'Yes',
1063     Numeric_Type => 'None',
1064     Numeric_Value => 'NaN',
1065     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1066     Sentence_Break => 'Other',
1067     Simple_Case_Folding => $CODE_POINT,
1068     Simple_Lowercase_Mapping => $CODE_POINT,
1069     Simple_Titlecase_Mapping => $CODE_POINT,
1070     Simple_Uppercase_Mapping => $CODE_POINT,
1071     Titlecase_Mapping => $CODE_POINT,
1072     Unicode_1_Name => "",
1073     Unicode_Radical_Stroke => "",
1074     Uppercase_Mapping => $CODE_POINT,
1075     Word_Break => 'Other',
1076 );
1077
1078 # Below are files that Unicode furnishes, but this program ignores, and why
1079 my %ignored_files = (
1080     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1081     'Index.txt' => 'Alphabetical index of Unicode characters',
1082     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1083     'NamesList.txt' => 'Annotated list of characters',
1084     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1085     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1086     'ReadMe.txt' => 'Documentation',
1087     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1088     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1089     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1090     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1091     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1092     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1093 );
1094
1095 my %skipped_files;  # List of files that we skip
1096
1097 ### End of externally interesting definitions, except for @input_file_objects
1098
1099 my $HEADER=<<"EOF";
1100 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1101 # This file is machine-generated by $0 from the Unicode
1102 # database, Version $string_version.  Any changes made here will be lost!
1103 EOF
1104
1105 my $INTERNAL_ONLY_HEADER = <<"EOF";
1106
1107 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1108 # This file is for internal use by core Perl only.  The format and even the
1109 # name or existence of this file are subject to change without notice.  Don't
1110 # use it directly.
1111 EOF
1112
1113 my $DEVELOPMENT_ONLY=<<"EOF";
1114 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1115 # This file contains information artificially constrained to code points
1116 # present in Unicode release $string_compare_versions.
1117 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1118 # not be used for production.
1119
1120 EOF
1121
1122 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1123 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1124 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1125
1126 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1127 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1128 # to decrease backtracking.  The first regex allows the code point to be at
1129 # the end of a word, but to work properly, the word shouldn't end with a valid
1130 # hex character.  The second one won't match a code point at the end of a
1131 # word, and doesn't have the run-on issue
1132 my $run_on_code_point_re =
1133             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1134 my $code_point_re = qr/\b$run_on_code_point_re/;
1135
1136 # This matches the beginning of the line in the Unicode db files that give the
1137 # defaults for code points not listed (i.e., missing) in the file.  The code
1138 # depends on this ending with a semi-colon, so it can assume it is a valid
1139 # field when the line is split() by semi-colons
1140 my $missing_defaults_prefix =
1141             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1142
1143 # Property types.  Unicode has more types, but these are sufficient for our
1144 # purposes.
1145 my $UNKNOWN = -1;   # initialized to illegal value
1146 my $NON_STRING = 1; # Either binary or enum
1147 my $BINARY = 2;
1148 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1149                        # tables, additional true and false tables are
1150                        # generated so that false is anything matching the
1151                        # default value, and true is everything else.
1152 my $ENUM = 4;       # Include catalog
1153 my $STRING = 5;     # Anything else: string or misc
1154
1155 # Some input files have lines that give default values for code points not
1156 # contained in the file.  Sometimes these should be ignored.
1157 my $NO_DEFAULTS = 0;        # Must evaluate to false
1158 my $NOT_IGNORED = 1;
1159 my $IGNORED = 2;
1160
1161 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1162 # and will appear in the main body of the tables in the output files, but
1163 # there are other types of ranges as well, listed below, that are specially
1164 # handled.   There are pseudo-types as well that will never be stored as a
1165 # type, but will affect the calculation of the type.
1166
1167 # 0 is for normal, non-specials
1168 my $MULTI_CP = 1;           # Sequence of more than code point
1169 my $HANGUL_SYLLABLE = 2;
1170 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1171 my $NULL = 4;               # The map is to the null string; utf8.c can't
1172                             # handle these, nor is there an accepted syntax
1173                             # for them in \p{} constructs
1174 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1175                              # otherwise be $MULTI_CP type are instead type 0
1176
1177 # process_generic_property_file() can accept certain overrides in its input.
1178 # Each of these must begin AND end with $CMD_DELIM.
1179 my $CMD_DELIM = "\a";
1180 my $REPLACE_CMD = 'replace';    # Override the Replace
1181 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1182
1183 my $NO = 0;
1184 my $YES = 1;
1185
1186 # Values for the Replace argument to add_range.
1187 # $NO                      # Don't replace; add only the code points not
1188                            # already present.
1189 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1190                            # the comments at the subroutine definition.
1191 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1192 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1193                            # already there
1194 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1195                            # already there
1196 my $CROAK = 6;             # Die with an error if is already there
1197
1198 # Flags to give property statuses.  The phrases are to remind maintainers that
1199 # if the flag is changed, the indefinite article referring to it in the
1200 # documentation may need to be as well.
1201 my $NORMAL = "";
1202 my $DEPRECATED = 'D';
1203 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1204 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1205 my $DISCOURAGED = 'X';
1206 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1207 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1208 my $STRICTER = 'T';
1209 my $a_bold_stricter = "a 'B<$STRICTER>'";
1210 my $A_bold_stricter = "A 'B<$STRICTER>'";
1211 my $STABILIZED = 'S';
1212 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1213 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1214 my $OBSOLETE = 'O';
1215 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1216 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1217
1218 my %status_past_participles = (
1219     $DISCOURAGED => 'discouraged',
1220     $STABILIZED => 'stabilized',
1221     $OBSOLETE => 'obsolete',
1222     $DEPRECATED => 'deprecated',
1223 );
1224
1225 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1226 # externally documented.
1227 my $ORDINARY = 0;       # The normal fate.
1228 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1229                         # but there is a file written that can be used to
1230                         # reconstruct this table
1231 my $SUPPRESSED = 3;     # The file for this table is not written out.
1232 my $INTERNAL_ONLY = 4;  # The file for this table is written out, but it is
1233                         # for Perl's internal use only
1234 my $PLACEHOLDER = 5;    # A property that is defined as a placeholder in a
1235                         # Unicode version that doesn't have it, but we need it
1236                         # to be defined, if empty, to have things work.
1237                         # Implies no pod entry generated
1238
1239 # The format of the values of the tables:
1240 my $EMPTY_FORMAT = "";
1241 my $BINARY_FORMAT = 'b';
1242 my $DECIMAL_FORMAT = 'd';
1243 my $FLOAT_FORMAT = 'f';
1244 my $INTEGER_FORMAT = 'i';
1245 my $HEX_FORMAT = 'x';
1246 my $RATIONAL_FORMAT = 'r';
1247 my $STRING_FORMAT = 's';
1248 my $ADJUST_FORMAT = 'a';
1249 my $DECOMP_STRING_FORMAT = 'c';
1250 my $STRING_WHITE_SPACE_LIST = 'sw';
1251
1252 my %map_table_formats = (
1253     $BINARY_FORMAT => 'binary',
1254     $DECIMAL_FORMAT => 'single decimal digit',
1255     $FLOAT_FORMAT => 'floating point number',
1256     $INTEGER_FORMAT => 'integer',
1257     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1258     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1259     $STRING_FORMAT => 'string',
1260     $ADJUST_FORMAT => 'some entries need adjustment',
1261     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1262     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1263 );
1264
1265 # Unicode didn't put such derived files in a separate directory at first.
1266 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1267 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1268 my $AUXILIARY = 'auxiliary';
1269
1270 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1271 # and into UCD.pl for the use of UCD.pm
1272 my %loose_to_file_of;       # loosely maps table names to their respective
1273                             # files
1274 my %stricter_to_file_of;    # same; but for stricter mapping.
1275 my %loose_property_to_file_of; # Maps a loose property name to its map file
1276 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1277                             # in the hash %utf8::SwashInfo
1278 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1279                              # their rational equivalent
1280 my %loose_property_name_of; # Loosely maps (non_string) property names to
1281                             # standard form
1282 my %string_property_loose_to_name; # Same, for string properties.
1283 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1284                             # the property name in standard loose form, and
1285                             # 'value' is the default value for that property,
1286                             # also in standard loose form.
1287 my %loose_to_standard_value; # loosely maps table names to the canonical
1288                             # alias for them
1289 my %ambiguous_names;        # keys are alias names (in standard form) that
1290                             # have more than one possible meaning.
1291 my %prop_aliases;           # Keys are standard property name; values are each
1292                             # one's aliases
1293 my %prop_value_aliases;     # Keys of top level are standard property name;
1294                             # values are keys to another hash,  Each one is
1295                             # one of the property's values, in standard form.
1296                             # The values are that prop-val's aliases.
1297 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1298
1299 # Most properties are immune to caseless matching, otherwise you would get
1300 # nonsensical results, as properties are a function of a code point, not
1301 # everything that is caselessly equivalent to that code point.  For example,
1302 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1303 # be true because 's' and 'S' are equivalent caselessly.  However,
1304 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1305 # extend that concept to those very few properties that are like this.  Each
1306 # such property will match the full range caselessly.  They are hard-coded in
1307 # the program; it's not worth trying to make it general as it's extremely
1308 # unlikely that they will ever change.
1309 my %caseless_equivalent_to;
1310
1311 # These constants names and values were taken from the Unicode standard,
1312 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1313 # syllables.  The '_string' versions are so generated tables can retain the
1314 # hex format, which is the more familiar value
1315 my $SBase_string = "0xAC00";
1316 my $SBase = CORE::hex $SBase_string;
1317 my $LBase_string = "0x1100";
1318 my $LBase = CORE::hex $LBase_string;
1319 my $VBase_string = "0x1161";
1320 my $VBase = CORE::hex $VBase_string;
1321 my $TBase_string = "0x11A7";
1322 my $TBase = CORE::hex $TBase_string;
1323 my $SCount = 11172;
1324 my $LCount = 19;
1325 my $VCount = 21;
1326 my $TCount = 28;
1327 my $NCount = $VCount * $TCount;
1328
1329 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1330 # with the above published constants.
1331 my %Jamo;
1332 my %Jamo_L;     # Leading consonants
1333 my %Jamo_V;     # Vowels
1334 my %Jamo_T;     # Trailing consonants
1335
1336 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1337 # The key is the base name of the code point, and the value is an
1338 # array giving all the ranges that use this base name.  Each range
1339 # is actually a hash giving the 'low' and 'high' values of it.
1340 my %names_ending_in_code_point;
1341 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1342                                         # removed from the names
1343 # Inverse mapping.  The list of ranges that have these kinds of
1344 # names.  Each element contains the low, high, and base names in an
1345 # anonymous hash.
1346 my @code_points_ending_in_code_point;
1347
1348 # Boolean: does this Unicode version have the hangul syllables, and are we
1349 # writing out a table for them?
1350 my $has_hangul_syllables = 0;
1351
1352 # Does this Unicode version have code points whose names end in their
1353 # respective code points, and are we writing out a table for them?  0 for no;
1354 # otherwise points to first property that a table is needed for them, so that
1355 # if multiple tables are needed, we don't create duplicates
1356 my $needing_code_points_ending_in_code_point = 0;
1357
1358 my @backslash_X_tests;     # List of tests read in for testing \X
1359 my @unhandled_properties;  # Will contain a list of properties found in
1360                            # the input that we didn't process.
1361 my @match_properties;      # Properties that have match tables, to be
1362                            # listed in the pod
1363 my @map_properties;        # Properties that get map files written
1364 my @named_sequences;       # NamedSequences.txt contents.
1365 my %potential_files;       # Generated list of all .txt files in the directory
1366                            # structure so we can warn if something is being
1367                            # ignored.
1368 my @files_actually_output; # List of files we generated.
1369 my @more_Names;            # Some code point names are compound; this is used
1370                            # to store the extra components of them.
1371 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1372                            # the minimum before we consider it equivalent to a
1373                            # candidate rational
1374 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1375
1376 # These store references to certain commonly used property objects
1377 my $gc;
1378 my $perl;
1379 my $block;
1380 my $perl_charname;
1381 my $print;
1382 my $Any;
1383 my $script;
1384
1385 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1386 my $has_In_conflicts = 0;
1387 my $has_Is_conflicts = 0;
1388
1389 sub internal_file_to_platform ($) {
1390     # Convert our file paths which have '/' separators to those of the
1391     # platform.
1392
1393     my $file = shift;
1394     return undef unless defined $file;
1395
1396     return File::Spec->join(split '/', $file);
1397 }
1398
1399 sub file_exists ($) {   # platform independent '-e'.  This program internally
1400                         # uses slash as a path separator.
1401     my $file = shift;
1402     return 0 if ! defined $file;
1403     return -e internal_file_to_platform($file);
1404 }
1405
1406 sub objaddr($) {
1407     # Returns the address of the blessed input object.
1408     # It doesn't check for blessedness because that would do a string eval
1409     # every call, and the program is structured so that this is never called
1410     # for a non-blessed object.
1411
1412     no overloading; # If overloaded, numifying below won't work.
1413
1414     # Numifying a ref gives its address.
1415     return pack 'J', $_[0];
1416 }
1417
1418 # These are used only if $annotate is true.
1419 # The entire range of Unicode characters is examined to populate these
1420 # after all the input has been processed.  But most can be skipped, as they
1421 # have the same descriptive phrases, such as being unassigned
1422 my @viacode;            # Contains the 1 million character names
1423 my @printable;          # boolean: And are those characters printable?
1424 my @annotate_char_type; # Contains a type of those characters, specifically
1425                         # for the purposes of annotation.
1426 my $annotate_ranges;    # A map of ranges of code points that have the same
1427                         # name for the purposes of annotation.  They map to the
1428                         # upper edge of the range, so that the end point can
1429                         # be immediately found.  This is used to skip ahead to
1430                         # the end of a range, and avoid processing each
1431                         # individual code point in it.
1432 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1433                                    # characters, but excluding those which are
1434                                    # also noncharacter code points
1435
1436 # The annotation types are an extension of the regular range types, though
1437 # some of the latter are folded into one.  Make the new types negative to
1438 # avoid conflicting with the regular types
1439 my $SURROGATE_TYPE = -1;
1440 my $UNASSIGNED_TYPE = -2;
1441 my $PRIVATE_USE_TYPE = -3;
1442 my $NONCHARACTER_TYPE = -4;
1443 my $CONTROL_TYPE = -5;
1444 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1445
1446 sub populate_char_info ($) {
1447     # Used only with the $annotate option.  Populates the arrays with the
1448     # input code point's info that are needed for outputting more detailed
1449     # comments.  If calling context wants a return, it is the end point of
1450     # any contiguous range of characters that share essentially the same info
1451
1452     my $i = shift;
1453     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1454
1455     $viacode[$i] = $perl_charname->value_of($i) || "";
1456
1457     # A character is generally printable if Unicode says it is,
1458     # but below we make sure that most Unicode general category 'C' types
1459     # aren't.
1460     $printable[$i] = $print->contains($i);
1461
1462     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1463
1464     # Only these two regular types are treated specially for annotations
1465     # purposes
1466     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1467                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1468
1469     # Give a generic name to all code points that don't have a real name.
1470     # We output ranges, if applicable, for these.  Also calculate the end
1471     # point of the range.
1472     my $end;
1473     if (! $viacode[$i]) {
1474         if ($gc-> table('Surrogate')->contains($i)) {
1475             $viacode[$i] = 'Surrogate';
1476             $annotate_char_type[$i] = $SURROGATE_TYPE;
1477             $printable[$i] = 0;
1478             $end = $gc->table('Surrogate')->containing_range($i)->end;
1479         }
1480         elsif ($gc-> table('Private_use')->contains($i)) {
1481             $viacode[$i] = 'Private Use';
1482             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1483             $printable[$i] = 0;
1484             $end = $gc->table('Private_Use')->containing_range($i)->end;
1485         }
1486         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1487                                                                 contains($i))
1488         {
1489             $viacode[$i] = 'Noncharacter';
1490             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1491             $printable[$i] = 0;
1492             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1493                                                     containing_range($i)->end;
1494         }
1495         elsif ($gc-> table('Control')->contains($i)) {
1496             $viacode[$i] = 'Control';
1497             $annotate_char_type[$i] = $CONTROL_TYPE;
1498             $printable[$i] = 0;
1499             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1500         }
1501         elsif ($gc-> table('Unassigned')->contains($i)) {
1502             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1503             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1504             $printable[$i] = 0;
1505
1506             # Because we name the unassigned by the blocks they are in, it
1507             # can't go past the end of that block, and it also can't go past
1508             # the unassigned range it is in.  The special table makes sure
1509             # that the non-characters, which are unassigned, are separated
1510             # out.
1511             $end = min($block->containing_range($i)->end,
1512                        $unassigned_sans_noncharacters-> containing_range($i)->
1513                                                                          end);
1514         }
1515         else {
1516             Carp::my_carp_bug("Can't figure out how to annotate "
1517                               . sprintf("U+%04X", $i)
1518                               . ".  Proceeding anyway.");
1519             $viacode[$i] = 'UNKNOWN';
1520             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1521             $printable[$i] = 0;
1522         }
1523     }
1524
1525     # Here, has a name, but if it's one in which the code point number is
1526     # appended to the name, do that.
1527     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1528         $viacode[$i] .= sprintf("-%04X", $i);
1529         $end = $perl_charname->containing_range($i)->end;
1530     }
1531
1532     # And here, has a name, but if it's a hangul syllable one, replace it with
1533     # the correct name from the Unicode algorithm
1534     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1535         use integer;
1536         my $SIndex = $i - $SBase;
1537         my $L = $LBase + $SIndex / $NCount;
1538         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1539         my $T = $TBase + $SIndex % $TCount;
1540         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1541         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1542         $end = $perl_charname->containing_range($i)->end;
1543     }
1544
1545     return if ! defined wantarray;
1546     return $i if ! defined $end;    # If not a range, return the input
1547
1548     # Save this whole range so can find the end point quickly
1549     $annotate_ranges->add_map($i, $end, $end);
1550
1551     return $end;
1552 }
1553
1554 # Commented code below should work on Perl 5.8.
1555 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1556 ## the native perl version of it (which is what would operate under miniperl)
1557 ## is extremely slow, as it does a string eval every call.
1558 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1559 #                            && defined eval "require Scalar::Util";
1560 #
1561 #sub objaddr($) {
1562 #    # Returns the address of the blessed input object.  Uses the XS version if
1563 #    # available.  It doesn't check for blessedness because that would do a
1564 #    # string eval every call, and the program is structured so that this is
1565 #    # never called for a non-blessed object.
1566 #
1567 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1568 #
1569 #    # Check at least that is a ref.
1570 #    my $pkg = ref($_[0]) or return undef;
1571 #
1572 #    # Change to a fake package to defeat any overloaded stringify
1573 #    bless $_[0], 'main::Fake';
1574 #
1575 #    # Numifying a ref gives its address.
1576 #    my $addr = pack 'J', $_[0];
1577 #
1578 #    # Return to original class
1579 #    bless $_[0], $pkg;
1580 #    return $addr;
1581 #}
1582
1583 sub max ($$) {
1584     my $a = shift;
1585     my $b = shift;
1586     return $a if $a >= $b;
1587     return $b;
1588 }
1589
1590 sub min ($$) {
1591     my $a = shift;
1592     my $b = shift;
1593     return $a if $a <= $b;
1594     return $b;
1595 }
1596
1597 sub clarify_number ($) {
1598     # This returns the input number with underscores inserted every 3 digits
1599     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1600     # checked.
1601
1602     my $number = shift;
1603     my $pos = length($number) - 3;
1604     return $number if $pos <= 1;
1605     while ($pos > 0) {
1606         substr($number, $pos, 0) = '_';
1607         $pos -= 3;
1608     }
1609     return $number;
1610 }
1611
1612
1613 package Carp;
1614
1615 # These routines give a uniform treatment of messages in this program.  They
1616 # are placed in the Carp package to cause the stack trace to not include them,
1617 # although an alternative would be to use another package and set @CARP_NOT
1618 # for it.
1619
1620 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1621
1622 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1623 # and overload trying to load Scalar:Util under miniperl.  See
1624 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1625 undef $overload::VERSION;
1626
1627 sub my_carp {
1628     my $message = shift || "";
1629     my $nofold = shift || 0;
1630
1631     if ($message) {
1632         $message = main::join_lines($message);
1633         $message =~ s/^$0: *//;     # Remove initial program name
1634         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1635         $message = "\n$0: $message;";
1636
1637         # Fold the message with program name, semi-colon end punctuation
1638         # (which looks good with the message that carp appends to it), and a
1639         # hanging indent for continuation lines.
1640         $message = main::simple_fold($message, "", 4) unless $nofold;
1641         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1642                                     # appends is to the same line
1643     }
1644
1645     return $message if defined wantarray;   # If a caller just wants the msg
1646
1647     carp $message;
1648     return;
1649 }
1650
1651 sub my_carp_bug {
1652     # This is called when it is clear that the problem is caused by a bug in
1653     # this program.
1654
1655     my $message = shift;
1656     $message =~ s/^$0: *//;
1657     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1658     carp $message;
1659     return;
1660 }
1661
1662 sub carp_too_few_args {
1663     if (@_ != 2) {
1664         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1665         return;
1666     }
1667
1668     my $args_ref = shift;
1669     my $count = shift;
1670
1671     my_carp_bug("Need at least $count arguments to "
1672         . (caller 1)[3]
1673         . ".  Instead got: '"
1674         . join ', ', @$args_ref
1675         . "'.  No action taken.");
1676     return;
1677 }
1678
1679 sub carp_extra_args {
1680     my $args_ref = shift;
1681     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1682
1683     unless (ref $args_ref) {
1684         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1685         return;
1686     }
1687     my ($package, $file, $line) = caller;
1688     my $subroutine = (caller 1)[3];
1689
1690     my $list;
1691     if (ref $args_ref eq 'HASH') {
1692         foreach my $key (keys %$args_ref) {
1693             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1694         }
1695         $list = join ', ', each %{$args_ref};
1696     }
1697     elsif (ref $args_ref eq 'ARRAY') {
1698         foreach my $arg (@$args_ref) {
1699             $arg = $UNDEF unless defined $arg;
1700         }
1701         $list = join ', ', @$args_ref;
1702     }
1703     else {
1704         my_carp_bug("Can't cope with ref "
1705                 . ref($args_ref)
1706                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1707         return;
1708     }
1709
1710     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1711     return;
1712 }
1713
1714 package main;
1715
1716 { # Closure
1717
1718     # This program uses the inside-out method for objects, as recommended in
1719     # "Perl Best Practices".  This closure aids in generating those.  There
1720     # are two routines.  setup_package() is called once per package to set
1721     # things up, and then set_access() is called for each hash representing a
1722     # field in the object.  These routines arrange for the object to be
1723     # properly destroyed when no longer used, and for standard accessor
1724     # functions to be generated.  If you need more complex accessors, just
1725     # write your own and leave those accesses out of the call to set_access().
1726     # More details below.
1727
1728     my %constructor_fields; # fields that are to be used in constructors; see
1729                             # below
1730
1731     # The values of this hash will be the package names as keys to other
1732     # hashes containing the name of each field in the package as keys, and
1733     # references to their respective hashes as values.
1734     my %package_fields;
1735
1736     sub setup_package {
1737         # Sets up the package, creating standard DESTROY and dump methods
1738         # (unless already defined).  The dump method is used in debugging by
1739         # simple_dumper().
1740         # The optional parameters are:
1741         #   a)  a reference to a hash, that gets populated by later
1742         #       set_access() calls with one of the accesses being
1743         #       'constructor'.  The caller can then refer to this, but it is
1744         #       not otherwise used by these two routines.
1745         #   b)  a reference to a callback routine to call during destruction
1746         #       of the object, before any fields are actually destroyed
1747
1748         my %args = @_;
1749         my $constructor_ref = delete $args{'Constructor_Fields'};
1750         my $destroy_callback = delete $args{'Destroy_Callback'};
1751         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1752
1753         my %fields;
1754         my $package = (caller)[0];
1755
1756         $package_fields{$package} = \%fields;
1757         $constructor_fields{$package} = $constructor_ref;
1758
1759         unless ($package->can('DESTROY')) {
1760             my $destroy_name = "${package}::DESTROY";
1761             no strict "refs";
1762
1763             # Use typeglob to give the anonymous subroutine the name we want
1764             *$destroy_name = sub {
1765                 my $self = shift;
1766                 my $addr = do { no overloading; pack 'J', $self; };
1767
1768                 $self->$destroy_callback if $destroy_callback;
1769                 foreach my $field (keys %{$package_fields{$package}}) {
1770                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1771                     delete $package_fields{$package}{$field}{$addr};
1772                 }
1773                 return;
1774             }
1775         }
1776
1777         unless ($package->can('dump')) {
1778             my $dump_name = "${package}::dump";
1779             no strict "refs";
1780             *$dump_name = sub {
1781                 my $self = shift;
1782                 return dump_inside_out($self, $package_fields{$package}, @_);
1783             }
1784         }
1785         return;
1786     }
1787
1788     sub set_access {
1789         # Arrange for the input field to be garbage collected when no longer
1790         # needed.  Also, creates standard accessor functions for the field
1791         # based on the optional parameters-- none if none of these parameters:
1792         #   'addable'    creates an 'add_NAME()' accessor function.
1793         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1794         #                function.
1795         #   'settable'   creates a 'set_NAME()' accessor function.
1796         #   'constructor' doesn't create an accessor function, but adds the
1797         #                field to the hash that was previously passed to
1798         #                setup_package();
1799         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1800         # 'add' etc. all mean 'addable'.
1801         # The read accessor function will work on both array and scalar
1802         # values.  If another accessor in the parameter list is 'a', the read
1803         # access assumes an array.  You can also force it to be array access
1804         # by specifying 'readable_array' instead of 'readable'
1805         #
1806         # A sort-of 'protected' access can be set-up by preceding the addable,
1807         # readable or settable with some initial portion of 'protected_' (but,
1808         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1809         # "protection" is only by convention.  All that happens is that the
1810         # accessor functions' names begin with an underscore.  So instead of
1811         # calling set_foo, the call is _set_foo.  (Real protection could be
1812         # accomplished by having a new subroutine, end_package, called at the
1813         # end of each package, and then storing the __LINE__ ranges and
1814         # checking them on every accessor.  But that is way overkill.)
1815
1816         # We create anonymous subroutines as the accessors and then use
1817         # typeglobs to assign them to the proper package and name
1818
1819         my $name = shift;   # Name of the field
1820         my $field = shift;  # Reference to the inside-out hash containing the
1821                             # field
1822
1823         my $package = (caller)[0];
1824
1825         if (! exists $package_fields{$package}) {
1826             croak "$0: Must call 'setup_package' before 'set_access'";
1827         }
1828
1829         # Stash the field so DESTROY can get it.
1830         $package_fields{$package}{$name} = $field;
1831
1832         # Remaining arguments are the accessors.  For each...
1833         foreach my $access (@_) {
1834             my $access = lc $access;
1835
1836             my $protected = "";
1837
1838             # Match the input as far as it goes.
1839             if ($access =~ /^(p[^_]*)_/) {
1840                 $protected = $1;
1841                 if (substr('protected_', 0, length $protected)
1842                     eq $protected)
1843                 {
1844
1845                     # Add 1 for the underscore not included in $protected
1846                     $access = substr($access, length($protected) + 1);
1847                     $protected = '_';
1848                 }
1849                 else {
1850                     $protected = "";
1851                 }
1852             }
1853
1854             if (substr('addable', 0, length $access) eq $access) {
1855                 my $subname = "${package}::${protected}add_$name";
1856                 no strict "refs";
1857
1858                 # add_ accessor.  Don't add if already there, which we
1859                 # determine using 'eq' for scalars and '==' otherwise.
1860                 *$subname = sub {
1861                     use strict "refs";
1862                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1863                     my $self = shift;
1864                     my $value = shift;
1865                     my $addr = do { no overloading; pack 'J', $self; };
1866                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1867                     if (ref $value) {
1868                         return if grep { $value == $_ } @{$field->{$addr}};
1869                     }
1870                     else {
1871                         return if grep { $value eq $_ } @{$field->{$addr}};
1872                     }
1873                     push @{$field->{$addr}}, $value;
1874                     return;
1875                 }
1876             }
1877             elsif (substr('constructor', 0, length $access) eq $access) {
1878                 if ($protected) {
1879                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1880                 }
1881                 else {
1882                     $constructor_fields{$package}{$name} = $field;
1883                 }
1884             }
1885             elsif (substr('readable_array', 0, length $access) eq $access) {
1886
1887                 # Here has read access.  If one of the other parameters for
1888                 # access is array, or this one specifies array (by being more
1889                 # than just 'readable_'), then create a subroutine that
1890                 # assumes the data is an array.  Otherwise just a scalar
1891                 my $subname = "${package}::${protected}$name";
1892                 if (grep { /^a/i } @_
1893                     or length($access) > length('readable_'))
1894                 {
1895                     no strict "refs";
1896                     *$subname = sub {
1897                         use strict "refs";
1898                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1899                         my $addr = do { no overloading; pack 'J', $_[0]; };
1900                         if (ref $field->{$addr} ne 'ARRAY') {
1901                             my $type = ref $field->{$addr};
1902                             $type = 'scalar' unless $type;
1903                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1904                             return;
1905                         }
1906                         return scalar @{$field->{$addr}} unless wantarray;
1907
1908                         # Make a copy; had problems with caller modifying the
1909                         # original otherwise
1910                         my @return = @{$field->{$addr}};
1911                         return @return;
1912                     }
1913                 }
1914                 else {
1915
1916                     # Here not an array value, a simpler function.
1917                     no strict "refs";
1918                     *$subname = sub {
1919                         use strict "refs";
1920                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1921                         no overloading;
1922                         return $field->{pack 'J', $_[0]};
1923                     }
1924                 }
1925             }
1926             elsif (substr('settable', 0, length $access) eq $access) {
1927                 my $subname = "${package}::${protected}set_$name";
1928                 no strict "refs";
1929                 *$subname = sub {
1930                     use strict "refs";
1931                     if (main::DEBUG) {
1932                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1933                         Carp::carp_extra_args(\@_) if @_ > 2;
1934                     }
1935                     # $self is $_[0]; $value is $_[1]
1936                     no overloading;
1937                     $field->{pack 'J', $_[0]} = $_[1];
1938                     return;
1939                 }
1940             }
1941             else {
1942                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1943             }
1944         }
1945         return;
1946     }
1947 }
1948
1949 package Input_file;
1950
1951 # All input files use this object, which stores various attributes about them,
1952 # and provides for convenient, uniform handling.  The run method wraps the
1953 # processing.  It handles all the bookkeeping of opening, reading, and closing
1954 # the file, returning only significant input lines.
1955 #
1956 # Each object gets a handler which processes the body of the file, and is
1957 # called by run().  Most should use the generic, default handler, which has
1958 # code scrubbed to handle things you might not expect.  A handler should
1959 # basically be a while(next_line()) {...} loop.
1960 #
1961 # You can also set up handlers to
1962 #   1) call before the first line is read for pre processing
1963 #   2) call to adjust each line of the input before the main handler gets them
1964 #   3) call upon EOF before the main handler exits its loop
1965 #   4) call at the end for post processing
1966 #
1967 # $_ is used to store the input line, and is to be filtered by the
1968 # each_line_handler()s.  So, if the format of the line is not in the desired
1969 # format for the main handler, these are used to do that adjusting.  They can
1970 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1971 # so the $_ output of one is used as the input to the next.  None of the other
1972 # handlers are stackable, but could easily be changed to be so.
1973 #
1974 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1975 # which insert the parameters as lines to be processed before the next input
1976 # file line is read.  This allows the EOF handler to flush buffers, for
1977 # example.  The difference between the two routines is that the lines inserted
1978 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1979 # called it from such a handler, you would get infinite recursion.)  Lines
1980 # inserted by insert_adjusted_lines() go directly to the main handler without
1981 # any adjustments.  If the  post-processing handler calls any of these, there
1982 # will be no effect.  Some error checking for these conditions could be added,
1983 # but it hasn't been done.
1984 #
1985 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1986 # to prevent further processing of the line.  This routine will output the
1987 # message as a warning once, and then keep a count of the lines that have the
1988 # same message, and output that count at the end of the file's processing.
1989 # This keeps the number of messages down to a manageable amount.
1990 #
1991 # get_missings() should be called to retrieve any @missing input lines.
1992 # Messages will be raised if this isn't done if the options aren't to ignore
1993 # missings.
1994
1995 sub trace { return main::trace(@_); }
1996
1997 { # Closure
1998     # Keep track of fields that are to be put into the constructor.
1999     my %constructor_fields;
2000
2001     main::setup_package(Constructor_Fields => \%constructor_fields);
2002
2003     my %file; # Input file name, required
2004     main::set_access('file', \%file, qw{ c r });
2005
2006     my %first_released; # Unicode version file was first released in, required
2007     main::set_access('first_released', \%first_released, qw{ c r });
2008
2009     my %handler;    # Subroutine to process the input file, defaults to
2010                     # 'process_generic_property_file'
2011     main::set_access('handler', \%handler, qw{ c });
2012
2013     my %property;
2014     # name of property this file is for.  defaults to none, meaning not
2015     # applicable, or is otherwise determinable, for example, from each line.
2016     main::set_access('property', \%property, qw{ c });
2017
2018     my %optional;
2019     # If this is true, the file is optional.  If not present, no warning is
2020     # output.  If it is present, the string given by this parameter is
2021     # evaluated, and if false the file is not processed.
2022     main::set_access('optional', \%optional, 'c', 'r');
2023
2024     my %non_skip;
2025     # This is used for debugging, to skip processing of all but a few input
2026     # files.  Add 'non_skip => 1' to the constructor for those files you want
2027     # processed when you set the $debug_skip global.
2028     main::set_access('non_skip', \%non_skip, 'c');
2029
2030     my %skip;
2031     # This is used to skip processing of this input file semi-permanently,
2032     # when it evaluates to true.  The value should be the reason the file is
2033     # being skipped.  It is used for files that we aren't planning to process
2034     # anytime soon, but want to allow to be in the directory and not raise a
2035     # message that we are not handling.  Mostly for test files.  This is in
2036     # contrast to the non_skip element, which is supposed to be used very
2037     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2038     # pretty much will never look at can be placed in the global
2039     # %ignored_files instead.  Ones used here will be added to %skipped files
2040     main::set_access('skip', \%skip, 'c');
2041
2042     my %each_line_handler;
2043     # list of subroutines to look at and filter each non-comment line in the
2044     # file.  defaults to none.  The subroutines are called in order, each is
2045     # to adjust $_ for the next one, and the final one adjusts it for
2046     # 'handler'
2047     main::set_access('each_line_handler', \%each_line_handler, 'c');
2048
2049     my %has_missings_defaults;
2050     # ? Are there lines in the file giving default values for code points
2051     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2052     # the norm, but IGNORED means it has such lines, but the handler doesn't
2053     # use them.  Having these three states allows us to catch changes to the
2054     # UCD that this program should track
2055     main::set_access('has_missings_defaults',
2056                                         \%has_missings_defaults, qw{ c r });
2057
2058     my %pre_handler;
2059     # Subroutine to call before doing anything else in the file.  If undef, no
2060     # such handler is called.
2061     main::set_access('pre_handler', \%pre_handler, qw{ c });
2062
2063     my %eof_handler;
2064     # Subroutine to call upon getting an EOF on the input file, but before
2065     # that is returned to the main handler.  This is to allow buffers to be
2066     # flushed.  The handler is expected to call insert_lines() or
2067     # insert_adjusted() with the buffered material
2068     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2069
2070     my %post_handler;
2071     # Subroutine to call after all the lines of the file are read in and
2072     # processed.  If undef, no such handler is called.
2073     main::set_access('post_handler', \%post_handler, qw{ c });
2074
2075     my %progress_message;
2076     # Message to print to display progress in lieu of the standard one
2077     main::set_access('progress_message', \%progress_message, qw{ c });
2078
2079     my %handle;
2080     # cache open file handle, internal.  Is undef if file hasn't been
2081     # processed at all, empty if has;
2082     main::set_access('handle', \%handle);
2083
2084     my %added_lines;
2085     # cache of lines added virtually to the file, internal
2086     main::set_access('added_lines', \%added_lines);
2087
2088     my %errors;
2089     # cache of errors found, internal
2090     main::set_access('errors', \%errors);
2091
2092     my %missings;
2093     # storage of '@missing' defaults lines
2094     main::set_access('missings', \%missings);
2095
2096     sub new {
2097         my $class = shift;
2098
2099         my $self = bless \do{ my $anonymous_scalar }, $class;
2100         my $addr = do { no overloading; pack 'J', $self; };
2101
2102         # Set defaults
2103         $handler{$addr} = \&main::process_generic_property_file;
2104         $non_skip{$addr} = 0;
2105         $skip{$addr} = 0;
2106         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2107         $handle{$addr} = undef;
2108         $added_lines{$addr} = [ ];
2109         $each_line_handler{$addr} = [ ];
2110         $errors{$addr} = { };
2111         $missings{$addr} = [ ];
2112
2113         # Two positional parameters.
2114         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2115         $file{$addr} = main::internal_file_to_platform(shift);
2116         $first_released{$addr} = shift;
2117
2118         # The rest of the arguments are key => value pairs
2119         # %constructor_fields has been set up earlier to list all possible
2120         # ones.  Either set or push, depending on how the default has been set
2121         # up just above.
2122         my %args = @_;
2123         foreach my $key (keys %args) {
2124             my $argument = $args{$key};
2125
2126             # Note that the fields are the lower case of the constructor keys
2127             my $hash = $constructor_fields{lc $key};
2128             if (! defined $hash) {
2129                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2130                 next;
2131             }
2132             if (ref $hash->{$addr} eq 'ARRAY') {
2133                 if (ref $argument eq 'ARRAY') {
2134                     foreach my $argument (@{$argument}) {
2135                         next if ! defined $argument;
2136                         push @{$hash->{$addr}}, $argument;
2137                     }
2138                 }
2139                 else {
2140                     push @{$hash->{$addr}}, $argument if defined $argument;
2141                 }
2142             }
2143             else {
2144                 $hash->{$addr} = $argument;
2145             }
2146             delete $args{$key};
2147         };
2148
2149         # If the file has a property for it, it means that the property is not
2150         # listed in the file's entries.  So add a handler to the list of line
2151         # handlers to insert the property name into the lines, to provide a
2152         # uniform interface to the final processing subroutine.
2153         # the final code doesn't have to worry about that.
2154         if ($property{$addr}) {
2155             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2156         }
2157
2158         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2159             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2160         }
2161
2162         # If skipping, set to optional, and add to list of ignored files,
2163         # including its reason
2164         if ($skip{$addr}) {
2165             $optional{$addr} = 1;
2166             $skipped_files{$file{$addr}} = $skip{$addr}
2167         }
2168
2169         return $self;
2170     }
2171
2172
2173     use overload
2174         fallback => 0,
2175         qw("") => "_operator_stringify",
2176         "." => \&main::_operator_dot,
2177     ;
2178
2179     sub _operator_stringify {
2180         my $self = shift;
2181
2182         return __PACKAGE__ . " object for " . $self->file;
2183     }
2184
2185     # flag to make sure extracted files are processed early
2186     my $seen_non_extracted_non_age = 0;
2187
2188     sub run {
2189         # Process the input object $self.  This opens and closes the file and
2190         # calls all the handlers for it.  Currently,  this can only be called
2191         # once per file, as it destroy's the EOF handler
2192
2193         my $self = shift;
2194         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2195
2196         my $addr = do { no overloading; pack 'J', $self; };
2197
2198         my $file = $file{$addr};
2199
2200         # Don't process if not expecting this file (because released later
2201         # than this Unicode version), and isn't there.  This means if someone
2202         # copies it into an earlier version's directory, we will go ahead and
2203         # process it.
2204         return if $first_released{$addr} gt $v_version && ! -e $file;
2205
2206         # If in debugging mode and this file doesn't have the non-skip
2207         # flag set, and isn't one of the critical files, skip it.
2208         if ($debug_skip
2209             && $first_released{$addr} ne v0
2210             && ! $non_skip{$addr})
2211         {
2212             print "Skipping $file in debugging\n" if $verbosity;
2213             return;
2214         }
2215
2216         # File could be optional
2217         if ($optional{$addr}) {
2218             return unless -e $file;
2219             my $result = eval $optional{$addr};
2220             if (! defined $result) {
2221                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2222                 return;
2223             }
2224             if (! $result) {
2225                 if ($verbosity) {
2226                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2227                 }
2228                 return;
2229             }
2230         }
2231
2232         if (! defined $file || ! -e $file) {
2233
2234             # If the file doesn't exist, see if have internal data for it
2235             # (based on first_released being 0).
2236             if ($first_released{$addr} eq v0) {
2237                 $handle{$addr} = 'pretend_is_open';
2238             }
2239             else {
2240                 if (! $optional{$addr}  # File could be optional
2241                     && $v_version ge $first_released{$addr})
2242                 {
2243                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2244                 }
2245                 return;
2246             }
2247         }
2248         else {
2249
2250             # Here, the file exists.  Some platforms may change the case of
2251             # its name
2252             if ($seen_non_extracted_non_age) {
2253                 if ($file =~ /$EXTRACTED/i) {
2254                     Carp::my_carp_bug(main::join_lines(<<END
2255 $file should be processed just after the 'Prop...Alias' files, and before
2256 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2257 have subtle problems
2258 END
2259                     ));
2260                 }
2261             }
2262             elsif ($EXTRACTED_DIR
2263                     && $first_released{$addr} ne v0
2264                     && $file !~ /$EXTRACTED/i
2265                     && lc($file) ne 'dage.txt')
2266             {
2267                 # We don't set this (by the 'if' above) if we have no
2268                 # extracted directory, so if running on an early version,
2269                 # this test won't work.  Not worth worrying about.
2270                 $seen_non_extracted_non_age = 1;
2271             }
2272
2273             # And mark the file as having being processed, and warn if it
2274             # isn't a file we are expecting.  As we process the files,
2275             # they are deleted from the hash, so any that remain at the
2276             # end of the program are files that we didn't process.
2277             my $fkey = File::Spec->rel2abs($file);
2278             my $expecting = delete $potential_files{lc($fkey)};
2279
2280             Carp::my_carp("Was not expecting '$file'.") if
2281                     ! $expecting
2282                     && ! defined $handle{$addr};
2283
2284             # Having deleted from expected files, we can quit if not to do
2285             # anything.  Don't print progress unless really want verbosity
2286             if ($skip{$addr}) {
2287                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2288                 return;
2289             }
2290
2291             # Open the file, converting the slashes used in this program
2292             # into the proper form for the OS
2293             my $file_handle;
2294             if (not open $file_handle, "<", $file) {
2295                 Carp::my_carp("Can't open $file.  Skipping: $!");
2296                 return 0;
2297             }
2298             $handle{$addr} = $file_handle; # Cache the open file handle
2299         }
2300
2301         if ($verbosity >= $PROGRESS) {
2302             if ($progress_message{$addr}) {
2303                 print "$progress_message{$addr}\n";
2304             }
2305             else {
2306                 # If using a virtual file, say so.
2307                 print "Processing ", (-e $file)
2308                                        ? $file
2309                                        : "substitute $file",
2310                                      "\n";
2311             }
2312         }
2313
2314
2315         # Call any special handler for before the file.
2316         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2317
2318         # Then the main handler
2319         &{$handler{$addr}}($self);
2320
2321         # Then any special post-file handler.
2322         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2323
2324         # If any errors have been accumulated, output the counts (as the first
2325         # error message in each class was output when it was encountered).
2326         if ($errors{$addr}) {
2327             my $total = 0;
2328             my $types = 0;
2329             foreach my $error (keys %{$errors{$addr}}) {
2330                 $total += $errors{$addr}->{$error};
2331                 delete $errors{$addr}->{$error};
2332                 $types++;
2333             }
2334             if ($total > 1) {
2335                 my $message
2336                         = "A total of $total lines had errors in $file.  ";
2337
2338                 $message .= ($types == 1)
2339                             ? '(Only the first one was displayed.)'
2340                             : '(Only the first of each type was displayed.)';
2341                 Carp::my_carp($message);
2342             }
2343         }
2344
2345         if (@{$missings{$addr}}) {
2346             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2347         }
2348
2349         # If a real file handle, close it.
2350         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2351                                                         ref $handle{$addr};
2352         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2353                                # the file, as opposed to undef
2354         return;
2355     }
2356
2357     sub next_line {
2358         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2359         # if such a line exists.  'logical' means that any lines that have
2360         # been added via insert_lines() will be returned in $_ before the file
2361         # is read again.
2362
2363         my $self = shift;
2364         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2365
2366         my $addr = do { no overloading; pack 'J', $self; };
2367
2368         # Here the file is open (or if the handle is not a ref, is an open
2369         # 'virtual' file).  Get the next line; any inserted lines get priority
2370         # over the file itself.
2371         my $adjusted;
2372
2373         LINE:
2374         while (1) { # Loop until find non-comment, non-empty line
2375             #local $to_trace = 1 if main::DEBUG;
2376             my $inserted_ref = shift @{$added_lines{$addr}};
2377             if (defined $inserted_ref) {
2378                 ($adjusted, $_) = @{$inserted_ref};
2379                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2380                 return 1 if $adjusted;
2381             }
2382             else {
2383                 last if ! ref $handle{$addr}; # Don't read unless is real file
2384                 last if ! defined ($_ = readline $handle{$addr});
2385             }
2386             chomp;
2387             trace $_ if main::DEBUG && $to_trace;
2388
2389             # See if this line is the comment line that defines what property
2390             # value that code points that are not listed in the file should
2391             # have.  The format or existence of these lines is not guaranteed
2392             # by Unicode since they are comments, but the documentation says
2393             # that this was added for machine-readability, so probably won't
2394             # change.  This works starting in Unicode Version 5.0.  They look
2395             # like:
2396             #
2397             # @missing: 0000..10FFFF; Not_Reordered
2398             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2399             # @missing: 0000..10FFFF; ; NaN
2400             #
2401             # Save the line for a later get_missings() call.
2402             if (/$missing_defaults_prefix/) {
2403                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2404                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2405                 }
2406                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2407                     my @defaults = split /\s* ; \s*/x, $_;
2408
2409                     # The first field is the @missing, which ends in a
2410                     # semi-colon, so can safely shift.
2411                     shift @defaults;
2412
2413                     # Some of these lines may have empty field placeholders
2414                     # which get in the way.  An example is:
2415                     # @missing: 0000..10FFFF; ; NaN
2416                     # Remove them.  Process starting from the top so the
2417                     # splice doesn't affect things still to be looked at.
2418                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2419                         next if $defaults[$i] ne "";
2420                         splice @defaults, $i, 1;
2421                     }
2422
2423                     # What's left should be just the property (maybe) and the
2424                     # default.  Having only one element means it doesn't have
2425                     # the property.
2426                     my $default;
2427                     my $property;
2428                     if (@defaults >= 1) {
2429                         if (@defaults == 1) {
2430                             $default = $defaults[0];
2431                         }
2432                         else {
2433                             $property = $defaults[0];
2434                             $default = $defaults[1];
2435                         }
2436                     }
2437
2438                     if (@defaults < 1
2439                         || @defaults > 2
2440                         || ($default =~ /^</
2441                             && $default !~ /^<code *point>$/i
2442                             && $default !~ /^<none>$/i
2443                             && $default !~ /^<script>$/i))
2444                     {
2445                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2446                     }
2447                     else {
2448
2449                         # If the property is missing from the line, it should
2450                         # be the one for the whole file
2451                         $property = $property{$addr} if ! defined $property;
2452
2453                         # Change <none> to the null string, which is what it
2454                         # really means.  If the default is the code point
2455                         # itself, set it to <code point>, which is what
2456                         # Unicode uses (but sometimes they've forgotten the
2457                         # space)
2458                         if ($default =~ /^<none>$/i) {
2459                             $default = "";
2460                         }
2461                         elsif ($default =~ /^<code *point>$/i) {
2462                             $default = $CODE_POINT;
2463                         }
2464                         elsif ($default =~ /^<script>$/i) {
2465
2466                             # Special case this one.  Currently is from
2467                             # ScriptExtensions.txt, and means for all unlisted
2468                             # code points, use their Script property values.
2469                             # For the code points not listed in that file, the
2470                             # default value is 'Unknown'.
2471                             $default = "Unknown";
2472                         }
2473
2474                         # Store them as a sub-arrays with both components.
2475                         push @{$missings{$addr}}, [ $default, $property ];
2476                     }
2477                 }
2478
2479                 # There is nothing for the caller to process on this comment
2480                 # line.
2481                 next;
2482             }
2483
2484             # Remove comments and trailing space, and skip this line if the
2485             # result is empty
2486             s/#.*//;
2487             s/\s+$//;
2488             next if /^$/;
2489
2490             # Call any handlers for this line, and skip further processing of
2491             # the line if the handler sets the line to null.
2492             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2493                 &{$sub_ref}($self);
2494                 next LINE if /^$/;
2495             }
2496
2497             # Here the line is ok.  return success.
2498             return 1;
2499         } # End of looping through lines.
2500
2501         # If there is an EOF handler, call it (only once) and if it generates
2502         # more lines to process go back in the loop to handle them.
2503         if ($eof_handler{$addr}) {
2504             &{$eof_handler{$addr}}($self);
2505             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2506             goto LINE if $added_lines{$addr};
2507         }
2508
2509         # Return failure -- no more lines.
2510         return 0;
2511
2512     }
2513
2514 #   Not currently used, not fully tested.
2515 #    sub peek {
2516 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2517 #        # record.  Not callable from an each_line_handler(), nor does it call
2518 #        # an each_line_handler() on the line.
2519 #
2520 #        my $self = shift;
2521 #        my $addr = do { no overloading; pack 'J', $self; };
2522 #
2523 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2524 #            my ($adjusted, $line) = @{$inserted_ref};
2525 #            next if $adjusted;
2526 #
2527 #            # Remove comments and trailing space, and return a non-empty
2528 #            # resulting line
2529 #            $line =~ s/#.*//;
2530 #            $line =~ s/\s+$//;
2531 #            return $line if $line ne "";
2532 #        }
2533 #
2534 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2535 #        while (1) { # Loop until find non-comment, non-empty line
2536 #            local $to_trace = 1 if main::DEBUG;
2537 #            trace $_ if main::DEBUG && $to_trace;
2538 #            return if ! defined (my $line = readline $handle{$addr});
2539 #            chomp $line;
2540 #            push @{$added_lines{$addr}}, [ 0, $line ];
2541 #
2542 #            $line =~ s/#.*//;
2543 #            $line =~ s/\s+$//;
2544 #            return $line if $line ne "";
2545 #        }
2546 #
2547 #        return;
2548 #    }
2549
2550
2551     sub insert_lines {
2552         # Lines can be inserted so that it looks like they were in the input
2553         # file at the place it was when this routine is called.  See also
2554         # insert_adjusted_lines().  Lines inserted via this routine go through
2555         # any each_line_handler()
2556
2557         my $self = shift;
2558
2559         # Each inserted line is an array, with the first element being 0 to
2560         # indicate that this line hasn't been adjusted, and needs to be
2561         # processed.
2562         no overloading;
2563         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2564         return;
2565     }
2566
2567     sub insert_adjusted_lines {
2568         # Lines can be inserted so that it looks like they were in the input
2569         # file at the place it was when this routine is called.  See also
2570         # insert_lines().  Lines inserted via this routine are already fully
2571         # adjusted, ready to be processed; each_line_handler()s handlers will
2572         # not be called.  This means this is not a completely general
2573         # facility, as only the last each_line_handler on the stack should
2574         # call this.  It could be made more general, by passing to each of the
2575         # line_handlers their position on the stack, which they would pass on
2576         # to this routine, and that would replace the boolean first element in
2577         # the anonymous array pushed here, so that the next_line routine could
2578         # use that to call only those handlers whose index is after it on the
2579         # stack.  But this is overkill for what is needed now.
2580
2581         my $self = shift;
2582         trace $_[0] if main::DEBUG && $to_trace;
2583
2584         # Each inserted line is an array, with the first element being 1 to
2585         # indicate that this line has been adjusted
2586         no overloading;
2587         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2588         return;
2589     }
2590
2591     sub get_missings {
2592         # Returns the stored up @missings lines' values, and clears the list.
2593         # The values are in an array, consisting of the default in the first
2594         # element, and the property in the 2nd.  However, since these lines
2595         # can be stacked up, the return is an array of all these arrays.
2596
2597         my $self = shift;
2598         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2599
2600         my $addr = do { no overloading; pack 'J', $self; };
2601
2602         # If not accepting a list return, just return the first one.
2603         return shift @{$missings{$addr}} unless wantarray;
2604
2605         my @return = @{$missings{$addr}};
2606         undef @{$missings{$addr}};
2607         return @return;
2608     }
2609
2610     sub _insert_property_into_line {
2611         # Add a property field to $_, if this file requires it.
2612
2613         my $self = shift;
2614         my $addr = do { no overloading; pack 'J', $self; };
2615         my $property = $property{$addr};
2616         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2617
2618         $_ =~ s/(;|$)/; $property$1/;
2619         return;
2620     }
2621
2622     sub carp_bad_line {
2623         # Output consistent error messages, using either a generic one, or the
2624         # one given by the optional parameter.  To avoid gazillions of the
2625         # same message in case the syntax of a  file is way off, this routine
2626         # only outputs the first instance of each message, incrementing a
2627         # count so the totals can be output at the end of the file.
2628
2629         my $self = shift;
2630         my $message = shift;
2631         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2632
2633         my $addr = do { no overloading; pack 'J', $self; };
2634
2635         $message = 'Unexpected line' unless $message;
2636
2637         # No trailing punctuation so as to fit with our addenda.
2638         $message =~ s/[.:;,]$//;
2639
2640         # If haven't seen this exact message before, output it now.  Otherwise
2641         # increment the count of how many times it has occurred
2642         unless ($errors{$addr}->{$message}) {
2643             Carp::my_carp("$message in '$_' in "
2644                             . $file{$addr}
2645                             . " at line $..  Skipping this line;");
2646             $errors{$addr}->{$message} = 1;
2647         }
2648         else {
2649             $errors{$addr}->{$message}++;
2650         }
2651
2652         # Clear the line to prevent any further (meaningful) processing of it.
2653         $_ = "";
2654
2655         return;
2656     }
2657 } # End closure
2658
2659 package Multi_Default;
2660
2661 # Certain properties in early versions of Unicode had more than one possible
2662 # default for code points missing from the files.  In these cases, one
2663 # default applies to everything left over after all the others are applied,
2664 # and for each of the others, there is a description of which class of code
2665 # points applies to it.  This object helps implement this by storing the
2666 # defaults, and for all but that final default, an eval string that generates
2667 # the class that it applies to.
2668
2669
2670 {   # Closure
2671
2672     main::setup_package();
2673
2674     my %class_defaults;
2675     # The defaults structure for the classes
2676     main::set_access('class_defaults', \%class_defaults);
2677
2678     my %other_default;
2679     # The default that applies to everything left over.
2680     main::set_access('other_default', \%other_default, 'r');
2681
2682
2683     sub new {
2684         # The constructor is called with default => eval pairs, terminated by
2685         # the left-over default. e.g.
2686         # Multi_Default->new(
2687         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2688         #               -  0x200D',
2689         #        'R' => 'some other expression that evaluates to code points',
2690         #        .
2691         #        .
2692         #        .
2693         #        'U'));
2694
2695         my $class = shift;
2696
2697         my $self = bless \do{my $anonymous_scalar}, $class;
2698         my $addr = do { no overloading; pack 'J', $self; };
2699
2700         while (@_ > 1) {
2701             my $default = shift;
2702             my $eval = shift;
2703             $class_defaults{$addr}->{$default} = $eval;
2704         }
2705
2706         $other_default{$addr} = shift;
2707
2708         return $self;
2709     }
2710
2711     sub get_next_defaults {
2712         # Iterates and returns the next class of defaults.
2713         my $self = shift;
2714         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2715
2716         my $addr = do { no overloading; pack 'J', $self; };
2717
2718         return each %{$class_defaults{$addr}};
2719     }
2720 }
2721
2722 package Alias;
2723
2724 # An alias is one of the names that a table goes by.  This class defines them
2725 # including some attributes.  Everything is currently setup in the
2726 # constructor.
2727
2728
2729 {   # Closure
2730
2731     main::setup_package();
2732
2733     my %name;
2734     main::set_access('name', \%name, 'r');
2735
2736     my %loose_match;
2737     # Should this name match loosely or not.
2738     main::set_access('loose_match', \%loose_match, 'r');
2739
2740     my %make_re_pod_entry;
2741     # Some aliases should not get their own entries in the re section of the
2742     # pod, because they are covered by a wild-card, and some we want to
2743     # discourage use of.  Binary
2744     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
2745
2746     my %ucd;
2747     # Is this documented to be accessible via Unicode::UCD
2748     main::set_access('ucd', \%ucd, 'r', 's');
2749
2750     my %status;
2751     # Aliases have a status, like deprecated, or even suppressed (which means
2752     # they don't appear in documentation).  Enum
2753     main::set_access('status', \%status, 'r');
2754
2755     my %ok_as_filename;
2756     # Similarly, some aliases should not be considered as usable ones for
2757     # external use, such as file names, or we don't want documentation to
2758     # recommend them.  Boolean
2759     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
2760
2761     sub new {
2762         my $class = shift;
2763
2764         my $self = bless \do { my $anonymous_scalar }, $class;
2765         my $addr = do { no overloading; pack 'J', $self; };
2766
2767         $name{$addr} = shift;
2768         $loose_match{$addr} = shift;
2769         $make_re_pod_entry{$addr} = shift;
2770         $ok_as_filename{$addr} = shift;
2771         $status{$addr} = shift;
2772         $ucd{$addr} = shift;
2773
2774         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2775
2776         # Null names are never ok externally
2777         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
2778
2779         return $self;
2780     }
2781 }
2782
2783 package Range;
2784
2785 # A range is the basic unit for storing code points, and is described in the
2786 # comments at the beginning of the program.  Each range has a starting code
2787 # point; an ending code point (not less than the starting one); a value
2788 # that applies to every code point in between the two end-points, inclusive;
2789 # and an enum type that applies to the value.  The type is for the user's
2790 # convenience, and has no meaning here, except that a non-zero type is
2791 # considered to not obey the normal Unicode rules for having standard forms.
2792 #
2793 # The same structure is used for both map and match tables, even though in the
2794 # latter, the value (and hence type) is irrelevant and could be used as a
2795 # comment.  In map tables, the value is what all the code points in the range
2796 # map to.  Type 0 values have the standardized version of the value stored as
2797 # well, so as to not have to recalculate it a lot.
2798
2799 sub trace { return main::trace(@_); }
2800
2801 {   # Closure
2802
2803     main::setup_package();
2804
2805     my %start;
2806     main::set_access('start', \%start, 'r', 's');
2807
2808     my %end;
2809     main::set_access('end', \%end, 'r', 's');
2810
2811     my %value;
2812     main::set_access('value', \%value, 'r');
2813
2814     my %type;
2815     main::set_access('type', \%type, 'r');
2816
2817     my %standard_form;
2818     # The value in internal standard form.  Defined only if the type is 0.
2819     main::set_access('standard_form', \%standard_form);
2820
2821     # Note that if these fields change, the dump() method should as well
2822
2823     sub new {
2824         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2825         my $class = shift;
2826
2827         my $self = bless \do { my $anonymous_scalar }, $class;
2828         my $addr = do { no overloading; pack 'J', $self; };
2829
2830         $start{$addr} = shift;
2831         $end{$addr} = shift;
2832
2833         my %args = @_;
2834
2835         my $value = delete $args{'Value'};  # Can be 0
2836         $value = "" unless defined $value;
2837         $value{$addr} = $value;
2838
2839         $type{$addr} = delete $args{'Type'} || 0;
2840
2841         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2842
2843         if (! $type{$addr}) {
2844             $standard_form{$addr} = main::standardize($value);
2845         }
2846
2847         return $self;
2848     }
2849
2850     use overload
2851         fallback => 0,
2852         qw("") => "_operator_stringify",
2853         "." => \&main::_operator_dot,
2854     ;
2855
2856     sub _operator_stringify {
2857         my $self = shift;
2858         my $addr = do { no overloading; pack 'J', $self; };
2859
2860         # Output it like '0041..0065 (value)'
2861         my $return = sprintf("%04X", $start{$addr})
2862                         .  '..'
2863                         . sprintf("%04X", $end{$addr});
2864         my $value = $value{$addr};
2865         my $type = $type{$addr};
2866         $return .= ' (';
2867         $return .= "$value";
2868         $return .= ", Type=$type" if $type != 0;
2869         $return .= ')';
2870
2871         return $return;
2872     }
2873
2874     sub standard_form {
2875         # The standard form is the value itself if the standard form is
2876         # undefined (that is if the value is special)
2877
2878         my $self = shift;
2879         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2880
2881         my $addr = do { no overloading; pack 'J', $self; };
2882
2883         return $standard_form{$addr} if defined $standard_form{$addr};
2884         return $value{$addr};
2885     }
2886
2887     sub dump {
2888         # Human, not machine readable.  For machine readable, comment out this
2889         # entire routine and let the standard one take effect.
2890         my $self = shift;
2891         my $indent = shift;
2892         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2893
2894         my $addr = do { no overloading; pack 'J', $self; };
2895
2896         my $return = $indent
2897                     . sprintf("%04X", $start{$addr})
2898                     . '..'
2899                     . sprintf("%04X", $end{$addr})
2900                     . " '$value{$addr}';";
2901         if (! defined $standard_form{$addr}) {
2902             $return .= "(type=$type{$addr})";
2903         }
2904         elsif ($standard_form{$addr} ne $value{$addr}) {
2905             $return .= "(standard '$standard_form{$addr}')";
2906         }
2907         return $return;
2908     }
2909 } # End closure
2910
2911 package _Range_List_Base;
2912
2913 # Base class for range lists.  A range list is simply an ordered list of
2914 # ranges, so that the ranges with the lowest starting numbers are first in it.
2915 #
2916 # When a new range is added that is adjacent to an existing range that has the
2917 # same value and type, it merges with it to form a larger range.
2918 #
2919 # Ranges generally do not overlap, except that there can be multiple entries
2920 # of single code point ranges.  This is because of NameAliases.txt.
2921 #
2922 # In this program, there is a standard value such that if two different
2923 # values, have the same standard value, they are considered equivalent.  This
2924 # value was chosen so that it gives correct results on Unicode data
2925
2926 # There are a number of methods to manipulate range lists, and some operators
2927 # are overloaded to handle them.
2928
2929 sub trace { return main::trace(@_); }
2930
2931 { # Closure
2932
2933     our $addr;
2934
2935     main::setup_package();
2936
2937     my %ranges;
2938     # The list of ranges
2939     main::set_access('ranges', \%ranges, 'readable_array');
2940
2941     my %max;
2942     # The highest code point in the list.  This was originally a method, but
2943     # actual measurements said it was used a lot.
2944     main::set_access('max', \%max, 'r');
2945
2946     my %each_range_iterator;
2947     # Iterator position for each_range()
2948     main::set_access('each_range_iterator', \%each_range_iterator);
2949
2950     my %owner_name_of;
2951     # Name of parent this is attached to, if any.  Solely for better error
2952     # messages.
2953     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2954
2955     my %_search_ranges_cache;
2956     # A cache of the previous result from _search_ranges(), for better
2957     # performance
2958     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2959
2960     sub new {
2961         my $class = shift;
2962         my %args = @_;
2963
2964         # Optional initialization data for the range list.
2965         my $initialize = delete $args{'Initialize'};
2966
2967         my $self;
2968
2969         # Use _union() to initialize.  _union() returns an object of this
2970         # class, which means that it will call this constructor recursively.
2971         # But it won't have this $initialize parameter so that it won't
2972         # infinitely loop on this.
2973         return _union($class, $initialize, %args) if defined $initialize;
2974
2975         $self = bless \do { my $anonymous_scalar }, $class;
2976         my $addr = do { no overloading; pack 'J', $self; };
2977
2978         # Optional parent object, only for debug info.
2979         $owner_name_of{$addr} = delete $args{'Owner'};
2980         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2981
2982         # Stringify, in case it is an object.
2983         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2984
2985         # This is used only for error messages, and so a colon is added
2986         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2987
2988         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2989
2990         # Max is initialized to a negative value that isn't adjacent to 0,
2991         # for simpler tests
2992         $max{$addr} = -2;
2993
2994         $_search_ranges_cache{$addr} = 0;
2995         $ranges{$addr} = [];
2996
2997         return $self;
2998     }
2999
3000     use overload
3001         fallback => 0,
3002         qw("") => "_operator_stringify",
3003         "." => \&main::_operator_dot,
3004     ;
3005
3006     sub _operator_stringify {
3007         my $self = shift;
3008         my $addr = do { no overloading; pack 'J', $self; };
3009
3010         return "Range_List attached to '$owner_name_of{$addr}'"
3011                                                 if $owner_name_of{$addr};
3012         return "anonymous Range_List " . \$self;
3013     }
3014
3015     sub _union {
3016         # Returns the union of the input code points.  It can be called as
3017         # either a constructor or a method.  If called as a method, the result
3018         # will be a new() instance of the calling object, containing the union
3019         # of that object with the other parameter's code points;  if called as
3020         # a constructor, the first parameter gives the class that the new object
3021         # should be, and the second parameter gives the code points to go into
3022         # it.
3023         # In either case, there are two parameters looked at by this routine;
3024         # any additional parameters are passed to the new() constructor.
3025         #
3026         # The code points can come in the form of some object that contains
3027         # ranges, and has a conventionally named method to access them; or
3028         # they can be an array of individual code points (as integers); or
3029         # just a single code point.
3030         #
3031         # If they are ranges, this routine doesn't make any effort to preserve
3032         # the range values and types of one input over the other.  Therefore
3033         # this base class should not allow _union to be called from other than
3034         # initialization code, so as to prevent two tables from being added
3035         # together where the range values matter.  The general form of this
3036         # routine therefore belongs in a derived class, but it was moved here
3037         # to avoid duplication of code.  The failure to overload this in this
3038         # class keeps it safe.
3039         #
3040         # It does make the effort during initialization to accept tables with
3041         # multiple values for the same code point, and to preserve the order
3042         # of these.  If there is only one input range or range set, it doesn't
3043         # sort (as it should already be sorted to the desired order), and will
3044         # accept multiple values per code point.  Otherwise it will merge
3045         # multiple values into a single one.
3046
3047         my $self;
3048         my @args;   # Arguments to pass to the constructor
3049
3050         my $class = shift;
3051
3052         # If a method call, will start the union with the object itself, and
3053         # the class of the new object will be the same as self.
3054         if (ref $class) {
3055             $self = $class;
3056             $class = ref $self;
3057             push @args, $self;
3058         }
3059
3060         # Add the other required parameter.
3061         push @args, shift;
3062         # Rest of parameters are passed on to the constructor
3063
3064         # Accumulate all records from both lists.
3065         my @records;
3066         my $input_count = 0;
3067         for my $arg (@args) {
3068             #local $to_trace = 0 if main::DEBUG;
3069             trace "argument = $arg" if main::DEBUG && $to_trace;
3070             if (! defined $arg) {
3071                 my $message = "";
3072                 if (defined $self) {
3073                     no overloading;
3074                     $message .= $owner_name_of{pack 'J', $self};
3075                 }
3076                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
3077                 return;
3078             }
3079
3080             $arg = [ $arg ] if ! ref $arg;
3081             my $type = ref $arg;
3082             if ($type eq 'ARRAY') {
3083                 foreach my $element (@$arg) {
3084                     push @records, Range->new($element, $element);
3085                     $input_count++;
3086                 }
3087             }
3088             elsif ($arg->isa('Range')) {
3089                 push @records, $arg;
3090                 $input_count++;
3091             }
3092             elsif ($arg->can('ranges')) {
3093                 push @records, $arg->ranges;
3094                 $input_count++;
3095             }
3096             else {
3097                 my $message = "";
3098                 if (defined $self) {
3099                     no overloading;
3100                     $message .= $owner_name_of{pack 'J', $self};
3101                 }
3102                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3103                 return;
3104             }
3105         }
3106
3107         # Sort with the range containing the lowest ordinal first, but if
3108         # two ranges start at the same code point, sort with the bigger range
3109         # of the two first, because it takes fewer cycles.
3110         if ($input_count > 1) {
3111             @records = sort { ($a->start <=> $b->start)
3112                                       or
3113                                     # if b is shorter than a, b->end will be
3114                                     # less than a->end, and we want to select
3115                                     # a, so want to return -1
3116                                     ($b->end <=> $a->end)
3117                                    } @records;
3118         }
3119
3120         my $new = $class->new(@_);
3121
3122         # Fold in records so long as they add new information.
3123         for my $set (@records) {
3124             my $start = $set->start;
3125             my $end   = $set->end;
3126             my $value = $set->value;
3127             my $type  = $set->type;
3128             if ($start > $new->max) {
3129                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3130             }
3131             elsif ($end > $new->max) {
3132                 $new->_add_delete('+', $new->max +1, $end, $value,
3133                                                                 Type => $type);
3134             }
3135             elsif ($input_count == 1) {
3136                 # Here, overlaps existing range, but is from a single input,
3137                 # so preserve the multiple values from that input.
3138                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3139                                                 Replace => $MULTIPLE_AFTER);
3140             }
3141         }
3142
3143         return $new;
3144     }
3145
3146     sub range_count {        # Return the number of ranges in the range list
3147         my $self = shift;
3148         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3149
3150         no overloading;
3151         return scalar @{$ranges{pack 'J', $self}};
3152     }
3153
3154     sub min {
3155         # Returns the minimum code point currently in the range list, or if
3156         # the range list is empty, 2 beyond the max possible.  This is a
3157         # method because used so rarely, that not worth saving between calls,
3158         # and having to worry about changing it as ranges are added and
3159         # deleted.
3160
3161         my $self = shift;
3162         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3163
3164         my $addr = do { no overloading; pack 'J', $self; };
3165
3166         # If the range list is empty, return a large value that isn't adjacent
3167         # to any that could be in the range list, for simpler tests
3168         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3169         return $ranges{$addr}->[0]->start;
3170     }
3171
3172     sub contains {
3173         # Boolean: Is argument in the range list?  If so returns $i such that:
3174         #   range[$i]->end < $codepoint <= range[$i+1]->end
3175         # which is one beyond what you want; this is so that the 0th range
3176         # doesn't return false
3177         my $self = shift;
3178         my $codepoint = shift;
3179         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3180
3181         my $i = $self->_search_ranges($codepoint);
3182         return 0 unless defined $i;
3183
3184         # The search returns $i, such that
3185         #   range[$i-1]->end < $codepoint <= range[$i]->end
3186         # So is in the table if and only iff it is at least the start position
3187         # of range $i.
3188         no overloading;
3189         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3190         return $i + 1;
3191     }
3192
3193     sub containing_range {
3194         # Returns the range object that contains the code point, undef if none
3195
3196         my $self = shift;
3197         my $codepoint = shift;
3198         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3199
3200         my $i = $self->contains($codepoint);
3201         return unless $i;
3202
3203         # contains() returns 1 beyond where we should look
3204         no overloading;
3205         return $ranges{pack 'J', $self}->[$i-1];
3206     }
3207
3208     sub value_of {
3209         # Returns the value associated with the code point, undef if none
3210
3211         my $self = shift;
3212         my $codepoint = shift;
3213         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3214
3215         my $range = $self->containing_range($codepoint);
3216         return unless defined $range;
3217
3218         return $range->value;
3219     }
3220
3221     sub type_of {
3222         # Returns the type of the range containing the code point, undef if
3223         # the code point is not in the table
3224
3225         my $self = shift;
3226         my $codepoint = shift;
3227         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3228
3229         my $range = $self->containing_range($codepoint);
3230         return unless defined $range;
3231
3232         return $range->type;
3233     }
3234
3235     sub _search_ranges {
3236         # Find the range in the list which contains a code point, or where it
3237         # should go if were to add it.  That is, it returns $i, such that:
3238         #   range[$i-1]->end < $codepoint <= range[$i]->end
3239         # Returns undef if no such $i is possible (e.g. at end of table), or
3240         # if there is an error.
3241
3242         my $self = shift;
3243         my $code_point = shift;
3244         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3245
3246         my $addr = do { no overloading; pack 'J', $self; };
3247
3248         return if $code_point > $max{$addr};
3249         my $r = $ranges{$addr};                # The current list of ranges
3250         my $range_list_size = scalar @$r;
3251         my $i;
3252
3253         use integer;        # want integer division
3254
3255         # Use the cached result as the starting guess for this one, because,
3256         # an experiment on 5.1 showed that 90% of the time the cache was the
3257         # same as the result on the next call (and 7% it was one less).
3258         $i = $_search_ranges_cache{$addr};
3259         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3260                                             # from an intervening deletion
3261         #local $to_trace = 1 if main::DEBUG;
3262         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3263         return $i if $code_point <= $r->[$i]->end
3264                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3265
3266         # Here the cache doesn't yield the correct $i.  Try adding 1.
3267         if ($i < $range_list_size - 1
3268             && $r->[$i]->end < $code_point &&
3269             $code_point <= $r->[$i+1]->end)
3270         {
3271             $i++;
3272             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3273             $_search_ranges_cache{$addr} = $i;
3274             return $i;
3275         }
3276
3277         # Here, adding 1 also didn't work.  We do a binary search to
3278         # find the correct position, starting with current $i
3279         my $lower = 0;
3280         my $upper = $range_list_size - 1;
3281         while (1) {
3282             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3283
3284             if ($code_point <= $r->[$i]->end) {
3285
3286                 # Here we have met the upper constraint.  We can quit if we
3287                 # also meet the lower one.
3288                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3289
3290                 $upper = $i;        # Still too high.
3291
3292             }
3293             else {
3294
3295                 # Here, $r[$i]->end < $code_point, so look higher up.
3296                 $lower = $i;
3297             }
3298
3299             # Split search domain in half to try again.
3300             my $temp = ($upper + $lower) / 2;
3301
3302             # No point in continuing unless $i changes for next time
3303             # in the loop.
3304             if ($temp == $i) {
3305
3306                 # We can't reach the highest element because of the averaging.
3307                 # So if one below the upper edge, force it there and try one
3308                 # more time.
3309                 if ($i == $range_list_size - 2) {
3310
3311                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3312                     $i = $range_list_size - 1;
3313
3314                     # Change $lower as well so if fails next time through,
3315                     # taking the average will yield the same $i, and we will
3316                     # quit with the error message just below.
3317                     $lower = $i;
3318                     next;
3319                 }
3320                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3321                 return;
3322             }
3323             $i = $temp;
3324         } # End of while loop
3325
3326         if (main::DEBUG && $to_trace) {
3327             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3328             trace "i=  [ $i ]", $r->[$i];
3329             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3330         }
3331
3332         # Here we have found the offset.  Cache it as a starting point for the
3333         # next call.
3334         $_search_ranges_cache{$addr} = $i;
3335         return $i;
3336     }
3337
3338     sub _add_delete {
3339         # Add, replace or delete ranges to or from a list.  The $type
3340         # parameter gives which:
3341         #   '+' => insert or replace a range, returning a list of any changed
3342         #          ranges.
3343         #   '-' => delete a range, returning a list of any deleted ranges.
3344         #
3345         # The next three parameters give respectively the start, end, and
3346         # value associated with the range.  'value' should be null unless the
3347         # operation is '+';
3348         #
3349         # The range list is kept sorted so that the range with the lowest
3350         # starting position is first in the list, and generally, adjacent
3351         # ranges with the same values are merged into a single larger one (see
3352         # exceptions below).
3353         #
3354         # There are more parameters; all are key => value pairs:
3355         #   Type    gives the type of the value.  It is only valid for '+'.
3356         #           All ranges have types; if this parameter is omitted, 0 is
3357         #           assumed.  Ranges with type 0 are assumed to obey the
3358         #           Unicode rules for casing, etc; ranges with other types are
3359         #           not.  Otherwise, the type is arbitrary, for the caller's
3360         #           convenience, and looked at only by this routine to keep
3361         #           adjacent ranges of different types from being merged into
3362         #           a single larger range, and when Replace =>
3363         #           $IF_NOT_EQUIVALENT is specified (see just below).
3364         #   Replace  determines what to do if the range list already contains
3365         #            ranges which coincide with all or portions of the input
3366         #            range.  It is only valid for '+':
3367         #       => $NO            means that the new value is not to replace
3368         #                         any existing ones, but any empty gaps of the
3369         #                         range list coinciding with the input range
3370         #                         will be filled in with the new value.
3371         #       => $UNCONDITIONALLY  means to replace the existing values with
3372         #                         this one unconditionally.  However, if the
3373         #                         new and old values are identical, the
3374         #                         replacement is skipped to save cycles
3375         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3376         #          (the default)  with this one if they are not equivalent.
3377         #                         Ranges are equivalent if their types are the
3378         #                         same, and they are the same string; or if
3379         #                         both are type 0 ranges, if their Unicode
3380         #                         standard forms are identical.  In this last
3381         #                         case, the routine chooses the more "modern"
3382         #                         one to use.  This is because some of the
3383         #                         older files are formatted with values that
3384         #                         are, for example, ALL CAPs, whereas the
3385         #                         derived files have a more modern style,
3386         #                         which looks better.  By looking for this
3387         #                         style when the pre-existing and replacement
3388         #                         standard forms are the same, we can move to
3389         #                         the modern style
3390         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3391         #                         existing one, but has a different value,
3392         #                         don't replace the existing one, but insert
3393         #                         this, one so that the same range can occur
3394         #                         multiple times.  They are stored LIFO, so
3395         #                         that the final one inserted is the first one
3396         #                         returned in an ordered search of the table.
3397         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3398         #                         FIFO, so that this one is inserted after all
3399         #                         others that currently exist.
3400         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3401         #
3402         # "same value" means identical for non-type-0 ranges, and it means
3403         # having the same standard forms for type-0 ranges.
3404
3405         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3406
3407         my $self = shift;
3408         my $operation = shift;   # '+' for add/replace; '-' for delete;
3409         my $start = shift;
3410         my $end   = shift;
3411         my $value = shift;
3412
3413         my %args = @_;
3414
3415         $value = "" if not defined $value;        # warning: $value can be "0"
3416
3417         my $replace = delete $args{'Replace'};
3418         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3419
3420         my $type = delete $args{'Type'};
3421         $type = 0 unless defined $type;
3422
3423         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3424
3425         my $addr = do { no overloading; pack 'J', $self; };
3426
3427         if ($operation ne '+' && $operation ne '-') {
3428             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3429             return;
3430         }
3431         unless (defined $start && defined $end) {
3432             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3433             return;
3434         }
3435         unless ($end >= $start) {
3436             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3437             return;
3438         }
3439         #local $to_trace = 1 if main::DEBUG;
3440
3441         if ($operation eq '-') {
3442             if ($replace != $IF_NOT_EQUIVALENT) {
3443                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3444                 $replace = $IF_NOT_EQUIVALENT;
3445             }
3446             if ($type) {
3447                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3448                 $type = 0;
3449             }
3450             if ($value ne "") {
3451                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3452                 $value = "";
3453             }
3454         }
3455
3456         my $r = $ranges{$addr};               # The current list of ranges
3457         my $range_list_size = scalar @$r;     # And its size
3458         my $max = $max{$addr};                # The current high code point in
3459                                               # the list of ranges
3460
3461         # Do a special case requiring fewer machine cycles when the new range
3462         # starts after the current highest point.  The Unicode input data is
3463         # structured so this is common.
3464         if ($start > $max) {
3465
3466             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3467             return if $operation eq '-'; # Deleting a non-existing range is a
3468                                          # no-op
3469
3470             # If the new range doesn't logically extend the current final one
3471             # in the range list, create a new range at the end of the range
3472             # list.  (max cleverly is initialized to a negative number not
3473             # adjacent to 0 if the range list is empty, so even adding a range
3474             # to an empty range list starting at 0 will have this 'if'
3475             # succeed.)
3476             if ($start > $max + 1        # non-adjacent means can't extend.
3477                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3478                 || @{$r}[-1]->type != $type # types differ, can't extend.
3479             ) {
3480                 push @$r, Range->new($start, $end,
3481                                      Value => $value,
3482                                      Type => $type);
3483             }
3484             else {
3485
3486                 # Here, the new range starts just after the current highest in
3487                 # the range list, and they have the same type and value.
3488                 # Extend the current range to incorporate the new one.
3489                 @{$r}[-1]->set_end($end);
3490             }
3491
3492             # This becomes the new maximum.
3493             $max{$addr} = $end;
3494
3495             return;
3496         }
3497         #local $to_trace = 0 if main::DEBUG;
3498
3499         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3500
3501         # Here, the input range isn't after the whole rest of the range list.
3502         # Most likely 'splice' will be needed.  The rest of the routine finds
3503         # the needed splice parameters, and if necessary, does the splice.
3504         # First, find the offset parameter needed by the splice function for
3505         # the input range.  Note that the input range may span multiple
3506         # existing ones, but we'll worry about that later.  For now, just find
3507         # the beginning.  If the input range is to be inserted starting in a
3508         # position not currently in the range list, it must (obviously) come
3509         # just after the range below it, and just before the range above it.
3510         # Slightly less obviously, it will occupy the position currently
3511         # occupied by the range that is to come after it.  More formally, we
3512         # are looking for the position, $i, in the array of ranges, such that:
3513         #
3514         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3515         #
3516         # (The ordered relationships within existing ranges are also shown in
3517         # the equation above).  However, if the start of the input range is
3518         # within an existing range, the splice offset should point to that
3519         # existing range's position in the list; that is $i satisfies a
3520         # somewhat different equation, namely:
3521         #
3522         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3523         #
3524         # More briefly, $start can come before or after r[$i]->start, and at
3525         # this point, we don't know which it will be.  However, these
3526         # two equations share these constraints:
3527         #
3528         #   r[$i-1]->end < $start <= r[$i]->end
3529         #
3530         # And that is good enough to find $i.
3531
3532         my $i = $self->_search_ranges($start);
3533         if (! defined $i) {
3534             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3535             return;
3536         }
3537
3538         # The search function returns $i such that:
3539         #
3540         # r[$i-1]->end < $start <= r[$i]->end
3541         #
3542         # That means that $i points to the first range in the range list
3543         # that could possibly be affected by this operation.  We still don't
3544         # know if the start of the input range is within r[$i], or if it
3545         # points to empty space between r[$i-1] and r[$i].
3546         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3547
3548         # Special case the insertion of data that is not to replace any
3549         # existing data.
3550         if ($replace == $NO) {  # If $NO, has to be operation '+'
3551             #local $to_trace = 1 if main::DEBUG;
3552             trace "Doesn't replace" if main::DEBUG && $to_trace;
3553
3554             # Here, the new range is to take effect only on those code points
3555             # that aren't already in an existing range.  This can be done by
3556             # looking through the existing range list and finding the gaps in
3557             # the ranges that this new range affects, and then calling this
3558             # function recursively on each of those gaps, leaving untouched
3559             # anything already in the list.  Gather up a list of the changed
3560             # gaps first so that changes to the internal state as new ranges
3561             # are added won't be a problem.
3562             my @gap_list;
3563
3564             # First, if the starting point of the input range is outside an
3565             # existing one, there is a gap from there to the beginning of the
3566             # existing range -- add a span to fill the part that this new
3567             # range occupies
3568             if ($start < $r->[$i]->start) {
3569                 push @gap_list, Range->new($start,
3570                                            main::min($end,
3571                                                      $r->[$i]->start - 1),
3572                                            Type => $type);
3573                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3574             }
3575
3576             # Then look through the range list for other gaps until we reach
3577             # the highest range affected by the input one.
3578             my $j;
3579             for ($j = $i+1; $j < $range_list_size; $j++) {
3580                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3581                 last if $end < $r->[$j]->start;
3582
3583                 # If there is a gap between when this range starts and the
3584                 # previous one ends, add a span to fill it.  Note that just
3585                 # because there are two ranges doesn't mean there is a
3586                 # non-zero gap between them.  It could be that they have
3587                 # different values or types
3588                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3589                     push @gap_list,
3590                         Range->new($r->[$j-1]->end + 1,
3591                                    $r->[$j]->start - 1,
3592                                    Type => $type);
3593                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3594                 }
3595             }
3596
3597             # Here, we have either found an existing range in the range list,
3598             # beyond the area affected by the input one, or we fell off the
3599             # end of the loop because the input range affects the whole rest
3600             # of the range list.  In either case, $j is 1 higher than the
3601             # highest affected range.  If $j == $i, it means that there are no
3602             # affected ranges, that the entire insertion is in the gap between
3603             # r[$i-1], and r[$i], which we already have taken care of before
3604             # the loop.
3605             # On the other hand, if there are affected ranges, it might be
3606             # that there is a gap that needs filling after the final such
3607             # range to the end of the input range
3608             if ($r->[$j-1]->end < $end) {
3609                     push @gap_list, Range->new(main::max($start,
3610                                                          $r->[$j-1]->end + 1),
3611                                                $end,
3612                                                Type => $type);
3613                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3614             }
3615
3616             # Call recursively to fill in all the gaps.
3617             foreach my $gap (@gap_list) {
3618                 $self->_add_delete($operation,
3619                                    $gap->start,
3620                                    $gap->end,
3621                                    $value,
3622                                    Type => $type);
3623             }
3624
3625             return;
3626         }
3627
3628         # Here, we have taken care of the case where $replace is $NO.
3629         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3630         # If inserting a multiple record, this is where it goes, before the
3631         # first (if any) existing one if inserting LIFO.  (If this is to go
3632         # afterwards, FIFO, we below move the pointer to there.)  These imply
3633         # an insertion, and no change to any existing ranges.  Note that $i
3634         # can be -1 if this new range doesn't actually duplicate any existing,
3635         # and comes at the beginning of the list.
3636         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3637
3638             if ($start != $end) {
3639                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3640                 return;
3641             }
3642
3643             # If the new code point is within a current range ...
3644             if ($end >= $r->[$i]->start) {
3645
3646                 # Don't add an exact duplicate, as it isn't really a multiple
3647                 my $existing_value = $r->[$i]->value;
3648                 my $existing_type = $r->[$i]->type;
3649                 return if $value eq $existing_value && $type eq $existing_type;
3650
3651                 # If the multiple value is part of an existing range, we want
3652                 # to split up that range, so that only the single code point
3653                 # is affected.  To do this, we first call ourselves
3654                 # recursively to delete that code point from the table, having
3655                 # preserved its current data above.  Then we call ourselves
3656                 # recursively again to add the new multiple, which we know by
3657                 # the test just above is different than the current code
3658                 # point's value, so it will become a range containing a single
3659                 # code point: just itself.  Finally, we add back in the
3660                 # pre-existing code point, which will again be a single code
3661                 # point range.  Because 'i' likely will have changed as a
3662                 # result of these operations, we can't just continue on, but
3663                 # do this operation recursively as well.  If we are inserting
3664                 # LIFO, the pre-existing code point needs to go after the new
3665                 # one, so use MULTIPLE_AFTER; and vice versa.
3666                 if ($r->[$i]->start != $r->[$i]->end) {
3667                     $self->_add_delete('-', $start, $end, "");
3668                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3669                     return $self->_add_delete('+',
3670                             $start, $end,
3671                             $existing_value,
3672                             Type => $existing_type,
3673                             Replace => ($replace == $MULTIPLE_BEFORE)
3674                                        ? $MULTIPLE_AFTER
3675                                        : $MULTIPLE_BEFORE);
3676                 }
3677             }
3678
3679             # If to place this new record after, move to beyond all existing
3680             # ones; but don't add this one if identical to any of them, as it
3681             # isn't really a multiple
3682             if ($replace == $MULTIPLE_AFTER) {
3683                 while ($i < @$r && $r->[$i]->start == $start) {
3684                     return if $value eq $r->[$i]->value
3685                               && $type eq $r->[$i]->type;
3686                     $i++;
3687                 }
3688             }
3689
3690             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3691             my @return = splice @$r,
3692                                 $i,
3693                                 0,
3694                                 Range->new($start,
3695                                            $end,
3696                                            Value => $value,
3697                                            Type => $type);
3698             if (main::DEBUG && $to_trace) {
3699                 trace "After splice:";
3700                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3701                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3702                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3703                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3704                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3705                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3706             }
3707             return @return;
3708         }
3709
3710         # Here, we have taken care of $NO and $MULTIPLE_foo replaces.  This
3711         # leaves delete, insert, and replace either unconditionally or if not
3712         # equivalent.  $i still points to the first potential affected range.
3713         # Now find the highest range affected, which will determine the length
3714         # parameter to splice.  (The input range can span multiple existing
3715         # ones.)  If this isn't a deletion, while we are looking through the
3716         # range list, see also if this is a replacement rather than a clean
3717         # insertion; that is if it will change the values of at least one
3718         # existing range.  Start off assuming it is an insert, until find it
3719         # isn't.
3720         my $clean_insert = $operation eq '+';
3721         my $j;        # This will point to the highest affected range
3722
3723         # For non-zero types, the standard form is the value itself;
3724         my $standard_form = ($type) ? $value : main::standardize($value);
3725
3726         for ($j = $i; $j < $range_list_size; $j++) {
3727             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3728
3729             # If find a range that it doesn't overlap into, we can stop
3730             # searching
3731             last if $end < $r->[$j]->start;
3732
3733             # Here, overlaps the range at $j.  If the values don't match,
3734             # and so far we think this is a clean insertion, it becomes a
3735             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3736             if ($clean_insert) {
3737                 if ($r->[$j]->standard_form ne $standard_form) {
3738                     $clean_insert = 0;
3739                     if ($replace == $CROAK) {
3740                         main::croak("The range to add "
3741                         . sprintf("%04X", $start)
3742                         . '-'
3743                         . sprintf("%04X", $end)
3744                         . " with value '$value' overlaps an existing range $r->[$j]");
3745                     }
3746                 }
3747                 else {
3748
3749                     # Here, the two values are essentially the same.  If the
3750                     # two are actually identical, replacing wouldn't change
3751                     # anything so skip it.
3752                     my $pre_existing = $r->[$j]->value;
3753                     if ($pre_existing ne $value) {
3754
3755                         # Here the new and old standardized values are the
3756                         # same, but the non-standardized values aren't.  If
3757                         # replacing unconditionally, then replace
3758                         if( $replace == $UNCONDITIONALLY) {
3759                             $clean_insert = 0;
3760                         }
3761                         else {
3762
3763                             # Here, are replacing conditionally.  Decide to
3764                             # replace or not based on which appears to look
3765                             # the "nicest".  If one is mixed case and the
3766                             # other isn't, choose the mixed case one.
3767                             my $new_mixed = $value =~ /[A-Z]/
3768                                             && $value =~ /[a-z]/;
3769                             my $old_mixed = $pre_existing =~ /[A-Z]/
3770                                             && $pre_existing =~ /[a-z]/;
3771
3772                             if ($old_mixed != $new_mixed) {
3773                                 $clean_insert = 0 if $new_mixed;
3774                                 if (main::DEBUG && $to_trace) {
3775                                     if ($clean_insert) {
3776                                         trace "Retaining $pre_existing over $value";
3777                                     }
3778                                     else {
3779                                         trace "Replacing $pre_existing with $value";
3780                                     }
3781                                 }
3782                             }
3783                             else {
3784
3785                                 # Here casing wasn't different between the two.
3786                                 # If one has hyphens or underscores and the
3787                                 # other doesn't, choose the one with the
3788                                 # punctuation.
3789                                 my $new_punct = $value =~ /[-_]/;
3790                                 my $old_punct = $pre_existing =~ /[-_]/;
3791
3792                                 if ($old_punct != $new_punct) {
3793                                     $clean_insert = 0 if $new_punct;
3794                                     if (main::DEBUG && $to_trace) {
3795                                         if ($clean_insert) {
3796                                             trace "Retaining $pre_existing over $value";
3797                                         }
3798                                         else {
3799                                             trace "Replacing $pre_existing with $value";
3800                                         }
3801                                     }
3802                                 }   # else existing one is just as "good";
3803                                     # retain it to save cycles.
3804                             }
3805                         }
3806                     }
3807                 }
3808             }
3809         } # End of loop looking for highest affected range.
3810
3811         # Here, $j points to one beyond the highest range that this insertion
3812         # affects (hence to beyond the range list if that range is the final
3813         # one in the range list).
3814
3815         # The splice length is all the affected ranges.  Get it before
3816         # subtracting, for efficiency, so we don't have to later add 1.
3817         my $length = $j - $i;
3818
3819         $j--;        # $j now points to the highest affected range.
3820         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3821
3822         # Here, have taken care of $NO and $MULTIPLE_foo replaces.
3823         # $j points to the highest affected range.  But it can be < $i or even
3824         # -1.  These happen only if the insertion is entirely in the gap
3825         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3826         # above exited first time through with $end < $r->[$i]->start.  (And
3827         # then we subtracted one from j)  This implies also that $start <
3828         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3829         # $start, so the entire input range is in the gap.
3830         if ($j < $i) {
3831
3832             # Here the entire input range is in the gap before $i.
3833
3834             if (main::DEBUG && $to_trace) {
3835                 if ($i) {
3836                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3837                 }
3838                 else {
3839                     trace "Entire range is before $r->[$i]";
3840                 }
3841             }
3842             return if $operation ne '+'; # Deletion of a non-existent range is
3843                                          # a no-op
3844         }
3845         else {
3846
3847             # Here part of the input range is not in the gap before $i.  Thus,
3848             # there is at least one affected one, and $j points to the highest
3849             # such one.
3850
3851             # At this point, here is the situation:
3852             # This is not an insertion of a multiple, nor of tentative ($NO)
3853             # data.
3854             #   $i  points to the first element in the current range list that
3855             #            may be affected by this operation.  In fact, we know
3856             #            that the range at $i is affected because we are in
3857             #            the else branch of this 'if'
3858             #   $j  points to the highest affected range.
3859             # In other words,
3860             #   r[$i-1]->end < $start <= r[$i]->end
3861             # And:
3862             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3863             #
3864             # Also:
3865             #   $clean_insert is a boolean which is set true if and only if
3866             #        this is a "clean insertion", i.e., not a change nor a
3867             #        deletion (multiple was handled above).
3868
3869             # We now have enough information to decide if this call is a no-op
3870             # or not.  It is a no-op if this is an insertion of already
3871             # existing data.
3872
3873             if (main::DEBUG && $to_trace && $clean_insert
3874                                          && $i == $j
3875                                          && $start >= $r->[$i]->start)
3876             {
3877                     trace "no-op";
3878             }
3879             return if $clean_insert
3880                       && $i == $j # more than one affected range => not no-op
3881
3882                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3883                       # Further, $start and/or $end is >= r[$i]->start
3884                       # The test below hence guarantees that
3885                       #     r[$i]->start < $start <= $end <= r[$i]->end
3886                       # This means the input range is contained entirely in
3887                       # the one at $i, so is a no-op
3888                       && $start >= $r->[$i]->start;
3889         }
3890
3891         # Here, we know that some action will have to be taken.  We have
3892         # calculated the offset and length (though adjustments may be needed)
3893         # for the splice.  Now start constructing the replacement list.
3894         my @replacement;
3895         my $splice_start = $i;
3896
3897         my $extends_below;
3898         my $extends_above;
3899
3900         # See if should extend any adjacent ranges.
3901         if ($operation eq '-') { # Don't extend deletions
3902             $extends_below = $extends_above = 0;
3903         }
3904         else {  # Here, should extend any adjacent ranges.  See if there are
3905                 # any.
3906             $extends_below = ($i > 0
3907                             # can't extend unless adjacent
3908                             && $r->[$i-1]->end == $start -1
3909                             # can't extend unless are same standard value
3910                             && $r->[$i-1]->standard_form eq $standard_form
3911                             # can't extend unless share type
3912                             && $r->[$i-1]->type == $type);
3913             $extends_above = ($j+1 < $range_list_size
3914                             && $r->[$j+1]->start == $end +1
3915                             && $r->[$j+1]->standard_form eq $standard_form
3916                             && $r->[$j+1]->type == $type);
3917         }
3918         if ($extends_below && $extends_above) { # Adds to both
3919             $splice_start--;     # start replace at element below
3920             $length += 2;        # will replace on both sides
3921             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3922
3923             # The result will fill in any gap, replacing both sides, and
3924             # create one large range.
3925             @replacement = Range->new($r->[$i-1]->start,
3926                                       $r->[$j+1]->end,
3927                                       Value => $value,
3928                                       Type => $type);
3929         }
3930         else {
3931
3932             # Here we know that the result won't just be the conglomeration of
3933             # a new range with both its adjacent neighbors.  But it could
3934             # extend one of them.
3935
3936             if ($extends_below) {
3937
3938                 # Here the new element adds to the one below, but not to the
3939                 # one above.  If inserting, and only to that one range,  can
3940                 # just change its ending to include the new one.
3941                 if ($length == 0 && $clean_insert) {
3942                     $r->[$i-1]->set_end($end);
3943                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3944                     return;
3945                 }
3946                 else {
3947                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3948                     $splice_start--;        # start replace at element below
3949                     $length++;              # will replace the element below
3950                     $start = $r->[$i-1]->start;
3951                 }
3952             }
3953             elsif ($extends_above) {
3954
3955                 # Here the new element adds to the one above, but not below.
3956                 # Mirror the code above
3957                 if ($length == 0 && $clean_insert) {
3958                     $r->[$j+1]->set_start($start);
3959                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3960                     return;
3961                 }
3962                 else {
3963                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3964                     $length++; &