This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
cca118607708103b329444de865194a757937223
[perl5.git] / cpan / CPAN / lib / CPAN / HandleConfig.pm
1 package CPAN::HandleConfig;
2 use strict;
3 use vars qw(%can %keys $loading $VERSION);
4
5 $VERSION = "5.5001"; # see also CPAN::Config::VERSION at end of file
6
7 %can = (
8         commit   => "Commit changes to disk",
9         defaults => "Reload defaults from disk",
10         help     => "Short help about 'o conf' usage",
11         init     => "Interactive setting of all options",
12 );
13
14 # Q: where is the "How do I add a new config option" HOWTO?
15 # A1: svn diff -r 757:758 # where dagolden added test_report [git e997b71de88f1019a1472fc13cb97b1b7f96610f]
16 # A2: svn diff -r 985:986 # where andk added yaml_module [git 312b6d9b12b1bdec0b6e282d853482145475021f]
17 # A3: 1. add new config option to %keys below
18 #     2. add a Pod description in CPAN::FirstTime; it should include a
19 #        prompt line; see others for examples
20 #     3. add a "matcher" section in CPAN::FirstTime::init that includes
21 #        a prompt function; see others for examples
22 #     4. add config option to documentation section in CPAN.pm
23
24 %keys = map { $_ => undef }
25     (
26      "applypatch",
27      "auto_commit",
28      "build_cache",
29      "build_dir",
30      "build_dir_reuse",
31      "build_requires_install_policy",
32      "bzip2",
33      "cache_metadata",
34      "check_sigs",
35      "colorize_debug",
36      "colorize_output",
37      "colorize_print",
38      "colorize_warn",
39      "commandnumber_in_prompt",
40      "commands_quote",
41      "connect_to_internet_ok",
42      "cpan_home",
43      "curl",
44      "dontload_hash", # deprecated after 1.83_68 (rev. 581)
45      "dontload_list",
46      "ftp",
47      "ftp_passive",
48      "ftp_proxy",
49      "ftpstats_size",
50      "ftpstats_period",
51      "getcwd",
52      "gpg",
53      "gzip",
54      "halt_on_failure",
55      "histfile",
56      "histsize",
57      "http_proxy",
58      "inactivity_timeout",
59      "index_expire",
60      "inhibit_startup_message",
61      "keep_source_where",
62      "load_module_verbosity",
63      "lynx",
64      "make",
65      "make_arg",
66      "make_install_arg",
67      "make_install_make_command",
68      "makepl_arg",
69      "mbuild_arg",
70      "mbuild_install_arg",
71      "mbuild_install_build_command",
72      "mbuildpl_arg",
73      "ncftp",
74      "ncftpget",
75      "no_proxy",
76      "pager",
77      "password",
78      "patch",
79      "patches_dir",
80      "perl5lib_verbosity",
81      "prefer_external_tar",
82      "prefer_installer",
83      "prefs_dir",
84      "prerequisites_policy",
85      "proxy_pass",
86      "proxy_user",
87      "randomize_urllist",
88      "scan_cache",
89      "shell",
90      "show_unparsable_versions",
91      "show_upload_date",
92      "show_zero_versions",
93      "tar",
94      "tar_verbosity",
95      "term_is_latin",
96      "term_ornaments",
97      "test_report",
98      "trust_test_report_history",
99      "unzip",
100      "urllist",
101      "use_file_homedir",
102      "use_sqlite",
103      "username",
104      "version_timeout",
105      "wait_list",
106      "wget",
107      "yaml_load_code",
108      "yaml_module",
109     );
110
111 my %prefssupport = map { $_ => 1 }
112     (
113      "build_requires_install_policy",
114      "check_sigs",
115      "make",
116      "make_install_make_command",
117      "prefer_installer",
118      "test_report",
119     );
120
121 # returns true on successful action
122 sub edit {
123     my($self,@args) = @_;
124     return unless @args;
125     CPAN->debug("self[$self]args[".join(" | ",@args)."]");
126     my($o,$str,$func,$args,$key_exists);
127     $o = shift @args;
128     if($can{$o}) {
129         my $success = $self->$o(args => \@args); # o conf init => sub init => sub load
130         unless ($success) {
131             die "Panic: could not configure CPAN.pm for args [@args]. Giving up.";
132         }
133     } else {
134         CPAN->debug("o[$o]") if $CPAN::DEBUG;
135         unless (exists $keys{$o}) {
136             $CPAN::Frontend->mywarn("Warning: unknown configuration variable '$o'\n");
137         }
138         my $changed;
139
140
141         # one day I used randomize_urllist for a boolean, so we must
142         # list them explicitly --ak
143         if (0) {
144         } elsif ($o =~ /^(wait_list|urllist|dontload_list)$/) {
145
146             #
147             # ARRAYS
148             #
149
150             $func = shift @args;
151             $func ||= "";
152             CPAN->debug("func[$func]args[@args]") if $CPAN::DEBUG;
153             # Let's avoid eval, it's easier to comprehend without.
154             if ($func eq "push") {
155                 push @{$CPAN::Config->{$o}}, @args;
156                 $changed = 1;
157             } elsif ($func eq "pop") {
158                 pop @{$CPAN::Config->{$o}};
159                 $changed = 1;
160             } elsif ($func eq "shift") {
161                 shift @{$CPAN::Config->{$o}};
162                 $changed = 1;
163             } elsif ($func eq "unshift") {
164                 unshift @{$CPAN::Config->{$o}}, @args;
165                 $changed = 1;
166             } elsif ($func eq "splice") {
167                 my $offset = shift @args || 0;
168                 my $length = shift @args || 0;
169                 splice @{$CPAN::Config->{$o}}, $offset, $length, @args; # may warn
170                 $changed = 1;
171             } elsif ($func) {
172                 $CPAN::Config->{$o} = [$func, @args];
173                 $changed = 1;
174             } else {
175                 $self->prettyprint($o);
176             }
177             if ($changed) {
178                 if ($o eq "urllist") {
179                     # reset the cached values
180                     undef $CPAN::FTP::Thesite;
181                     undef $CPAN::FTP::Themethod;
182                     $CPAN::Index::LAST_TIME = 0;
183                 } elsif ($o eq "dontload_list") {
184                     # empty it, it will be built up again
185                     $CPAN::META->{dontload_hash} = {};
186                 }
187             }
188         } elsif ($o =~ /_hash$/) {
189
190             #
191             # HASHES
192             #
193
194             if (@args==1 && $args[0] eq "") {
195                 @args = ();
196             } elsif (@args % 2) {
197                 push @args, "";
198             }
199             $CPAN::Config->{$o} = { @args };
200             $changed = 1;
201         } else {
202
203             #
204             # SCALARS
205             #
206
207             if (defined $args[0]) {
208                 $CPAN::CONFIG_DIRTY = 1;
209                 $CPAN::Config->{$o} = $args[0];
210                 $changed = 1;
211             }
212             $self->prettyprint($o)
213                 if exists $keys{$o} or defined $CPAN::Config->{$o};
214         }
215         if ($changed) {
216             if ($CPAN::Config->{auto_commit}) {
217                 $self->commit;
218             } else {
219                 $CPAN::CONFIG_DIRTY = 1;
220                 $CPAN::Frontend->myprint("Please use 'o conf commit' to ".
221                                          "make the config permanent!\n\n");
222             }
223         }
224     }
225 }
226
227 sub prettyprint {
228     my($self,$k) = @_;
229     my $v = $CPAN::Config->{$k};
230     if (ref $v) {
231         my(@report);
232         if (ref $v eq "ARRAY") {
233             @report = map {"\t$_ \[$v->[$_]]\n"} 0..$#$v;
234         } else {
235             @report = map
236                 {
237                     sprintf "\t%-18s => %s\n",
238                                "[$_]",
239                                         defined $v->{$_} ? "[$v->{$_}]" : "undef"
240                 } keys %$v;
241         }
242         $CPAN::Frontend->myprint(
243                                  join(
244                                       "",
245                                       sprintf(
246                                               "    %-18s\n",
247                                               $k
248                                              ),
249                                       @report
250                                      )
251                                 );
252     } elsif (defined $v) {
253         $CPAN::Frontend->myprint(sprintf "    %-18s [%s]\n", $k, $v);
254     } else {
255         $CPAN::Frontend->myprint(sprintf "    %-18s undef\n", $k);
256     }
257 }
258
259 sub commit {
260     my($self,@args) = @_;
261     CPAN->debug("args[@args]") if $CPAN::DEBUG;
262     if ($CPAN::RUN_DEGRADED) {
263                              $CPAN::Frontend->mydie(
264                                                     "'o conf commit' disabled in ".
265                                                     "degraded mode. Maybe try\n".
266                                                     " !undef \$CPAN::RUN_DEGRADED\n"
267                                                    );
268     }
269     my $configpm;
270     if (@args) {
271       if ($args[0] eq "args") {
272         # we have not signed that contract
273       } else {
274         $configpm = $args[0];
275       }
276     }
277     unless (defined $configpm) {
278         $configpm ||= $INC{"CPAN/MyConfig.pm"};
279         $configpm ||= $INC{"CPAN/Config.pm"};
280         $configpm || Carp::confess(q{
281 CPAN::Config::commit called without an argument.
282 Please specify a filename where to save the configuration or try
283 "o conf init" to have an interactive course through configing.
284 });
285     }
286     my($mode);
287     if (-f $configpm) {
288         $mode = (stat $configpm)[2];
289         if ($mode && ! -w _) {
290             Carp::confess("$configpm is not writable");
291         }
292     }
293
294     my $msg;
295     my $home = home();
296     $msg = <<EOF unless $configpm =~ /MyConfig/;
297
298 # This is CPAN.pm's systemwide configuration file. This file provides
299 # defaults for users, and the values can be changed in a per-user
300 # configuration file. The user-config file is being looked for as
301 # $home/.cpan/CPAN/MyConfig.pm.
302
303 EOF
304     $msg ||= "\n";
305     my($fh) = FileHandle->new;
306     rename $configpm, "$configpm~" if -f $configpm;
307     open $fh, ">$configpm" or
308         $CPAN::Frontend->mydie("Couldn't open >$configpm: $!");
309     $fh->print(qq[$msg\$CPAN::Config = \{\n]);
310     foreach (sort keys %$CPAN::Config) {
311         unless (exists $keys{$_}) {
312             # do not drop them: forward compatibility!
313             $CPAN::Frontend->mywarn("Unknown config variable '$_'\n");
314             next;
315         }
316         $fh->print(
317             "  '$_' => ",
318             $self->neatvalue($CPAN::Config->{$_}),
319             ",\n"
320         );
321     }
322
323     $fh->print("};\n1;\n__END__\n");
324     close $fh;
325
326     #$mode = 0444 | ( $mode & 0111 ? 0111 : 0 );
327     #chmod $mode, $configpm;
328 ###why was that so?    $self->defaults;
329     $CPAN::Frontend->myprint("commit: wrote '$configpm'\n");
330     $CPAN::CONFIG_DIRTY = 0;
331     1;
332 }
333
334 # stolen from MakeMaker; not taking the original because it is buggy;
335 # bugreport will have to say: keys of hashes remain unquoted and can
336 # produce syntax errors
337 sub neatvalue {
338     my($self, $v) = @_;
339     return "undef" unless defined $v;
340     my($t) = ref $v;
341     unless ($t) {
342         $v =~ s/\\/\\\\/g;
343         return "q[$v]";
344     }
345     if ($t eq 'ARRAY') {
346         my(@m, @neat);
347         push @m, "[";
348         foreach my $elem (@$v) {
349             push @neat, "q[$elem]";
350         }
351         push @m, join ", ", @neat;
352         push @m, "]";
353         return join "", @m;
354     }
355     return "$v" unless $t eq 'HASH';
356     my(@m, $key, $val);
357     while (($key,$val) = each %$v) {
358         last unless defined $key; # cautious programming in case (undef,undef) is true
359         push(@m,"q[$key]=>".$self->neatvalue($val)) ;
360     }
361     return "{ ".join(', ',@m)." }";
362 }
363
364 sub defaults {
365     my($self) = @_;
366     if ($CPAN::RUN_DEGRADED) {
367                              $CPAN::Frontend->mydie(
368                                                     "'o conf defaults' disabled in ".
369                                                     "degraded mode. Maybe try\n".
370                                                     " !undef \$CPAN::RUN_DEGRADED\n"
371                                                    );
372     }
373     my $done;
374     for my $config (qw(CPAN/MyConfig.pm CPAN/Config.pm)) {
375         if ($INC{$config}) {
376             CPAN->debug("INC{'$config'}[$INC{$config}]") if $CPAN::DEBUG;
377             CPAN::Shell->_reload_this($config,{reloforce => 1});
378             $CPAN::Frontend->myprint("'$INC{$config}' reread\n");
379             last;
380         }
381     }
382     $CPAN::CONFIG_DIRTY = 0;
383     1;
384 }
385
386 =head2 C<< CLASS->safe_quote ITEM >>
387
388 Quotes an item to become safe against spaces
389 in shell interpolation. An item is enclosed
390 in double quotes if:
391
392   - the item contains spaces in the middle
393   - the item does not start with a quote
394
395 This happens to avoid shell interpolation
396 problems when whitespace is present in
397 directory names.
398
399 This method uses C<commands_quote> to determine
400 the correct quote. If C<commands_quote> is
401 a space, no quoting will take place.
402
403
404 if it starts and ends with the same quote character: leave it as it is
405
406 if it contains no whitespace: leave it as it is
407
408 if it contains whitespace, then
409
410 if it contains quotes: better leave it as it is
411
412 else: quote it with the correct quote type for the box we're on
413
414 =cut
415
416 {
417     # Instead of patching the guess, set commands_quote
418     # to the right value
419     my ($quotes,$use_quote)
420         = $^O eq 'MSWin32'
421             ? ('"', '"')
422                 : (q{"'}, "'")
423                     ;
424
425     sub safe_quote {
426         my ($self, $command) = @_;
427         # Set up quote/default quote
428         my $quote = $CPAN::Config->{commands_quote} || $quotes;
429
430         if ($quote ne ' '
431             and defined($command )
432             and $command =~ /\s/
433             and $command !~ /[$quote]/) {
434             return qq<$use_quote$command$use_quote>
435         }
436         return $command;
437     }
438 }
439
440 sub init {
441     my($self,@args) = @_;
442     CPAN->debug("self[$self]args[".join(",",@args)."]");
443     $self->load(doit => 1, @args);
444     1;
445 }
446
447 # This is a piece of repeated code that is abstracted here for
448 # maintainability.  RMB
449 #
450 sub _configpmtest {
451     my($configpmdir, $configpmtest) = @_;
452     if (-w $configpmtest) {
453         return $configpmtest;
454     } elsif (-w $configpmdir) {
455         #_#_# following code dumped core on me with 5.003_11, a.k.
456         my $configpm_bak = "$configpmtest.bak";
457         unlink $configpm_bak if -f $configpm_bak;
458         if( -f $configpmtest ) {
459             if( rename $configpmtest, $configpm_bak ) {
460                 $CPAN::Frontend->mywarn(<<END);
461 Old configuration file $configpmtest
462     moved to $configpm_bak
463 END
464             }
465         }
466         my $fh = FileHandle->new;
467         if ($fh->open(">$configpmtest")) {
468             $fh->print("1;\n");
469             return $configpmtest;
470         } else {
471             # Should never happen
472             Carp::confess("Cannot open >$configpmtest");
473         }
474     } else { return }
475 }
476
477 sub require_myconfig_or_config () {
478     return if $INC{"CPAN/MyConfig.pm"};
479     local @INC = @INC;
480     my $home = home();
481     unshift @INC, File::Spec->catdir($home,'.cpan');
482     eval { require CPAN::MyConfig };
483     my $err_myconfig = $@;
484     if ($err_myconfig and $err_myconfig !~ m#locate CPAN/MyConfig\.pm#) {
485         die "Error while requiring CPAN::MyConfig:\n$err_myconfig";
486     }
487     unless ($INC{"CPAN/MyConfig.pm"}) { # this guy has settled his needs already
488       eval {require CPAN::Config;}; # not everybody has one
489       my $err_config = $@;
490       if ($err_config and $err_config !~ m#locate CPAN/Config\.pm#) {
491           die "Error while requiring CPAN::Config:\n$err_config";
492       }
493     }
494 }
495
496 sub home () {
497     my $home;
498     # Suppress load messages until we load the config and know whether
499     # load messages are desired.  Otherwise, it's unexpected and odd 
500     # why one load message pops up even when verbosity is turned off.
501     # This means File::HomeDir load messages are never seen, but I
502     # think that's probably OK -- DAGOLDEN
503     
504     # 5.6.2 seemed to segfault localizing a value in a hashref 
505     # so do it manually instead
506     my $old_v = $CPAN::Config->{load_module_verbosity};
507     $CPAN::Config->{load_module_verbosity} = q[none];
508     if (CPAN::_use_file_homedir()) {
509         if ($^O eq 'darwin') {
510             $home = File::HomeDir->my_home; # my_data is ~/Library/Application Support on darwin,
511                                             # which causes issues in the toolchain.
512         }
513         else {
514             $home = File::HomeDir->my_data || File::HomeDir->my_home;
515        }
516     }
517     unless (defined $home) {
518         $home = $ENV{HOME};
519     }
520     $CPAN::Config->{load_module_verbosity} = $old_v;
521     $home;
522 }
523
524 sub load {
525     my($self, %args) = @_;
526     $CPAN::Be_Silent+=0; # protect against 'used only once'
527     $CPAN::Be_Silent++ if $args{be_silent}; # do not use; planned to be removed in 2011
528     my $doit;
529     $doit = delete $args{doit} || 0;
530     $loading = 0 unless defined $loading;
531
532     use Carp;
533     require_myconfig_or_config;
534     my @miss = $self->missing_config_data;
535     CPAN->debug("doit[$doit]loading[$loading]miss[@miss]") if $CPAN::DEBUG;
536     return unless $doit || @miss;
537     return if $loading;
538     local $loading = ($loading||0) + 1;
539
540     require CPAN::FirstTime;
541     my($redo,$configpm,$fh);
542     if (defined $INC{"CPAN/Config.pm"} && -w $INC{"CPAN/Config.pm"}) {
543         $configpm = $INC{"CPAN/Config.pm"};
544         $redo++;
545     } elsif (defined $INC{"CPAN/MyConfig.pm"} && -w $INC{"CPAN/MyConfig.pm"}) {
546         $configpm = $INC{"CPAN/MyConfig.pm"};
547         $redo++;
548     } else {
549         my($path_to_cpan) = File::Basename::dirname($INC{"CPAN.pm"});
550         my($configpmdir) = File::Spec->catdir($path_to_cpan,"CPAN");
551         my($configpmtest) = File::Spec->catfile($configpmdir,"Config.pm");
552         my $inc_key;
553         if (-d $configpmdir or File::Path::mkpath($configpmdir)) {
554             $configpm = _configpmtest($configpmdir,$configpmtest);
555             $inc_key = "CPAN/Config.pm";
556         }
557         unless ($configpm) {
558             $configpmdir = File::Spec->catdir(home,".cpan","CPAN");
559             File::Path::mkpath($configpmdir);
560             $configpmtest = File::Spec->catfile($configpmdir,"MyConfig.pm");
561             $configpm = _configpmtest($configpmdir,$configpmtest);
562             $inc_key = "CPAN/MyConfig.pm";
563         }
564         if ($configpm) {
565           $INC{$inc_key} = $configpm;
566         } else {
567           my $myconfigpm = File::Spec->catfile(home,".cpan","CPAN","MyConfig.pm");
568           $CPAN::Frontend->mydie(<<"END");
569 WARNING: CPAN.pm is unable to write a configuration file.  You need write
570 access to your default perl library directories or you must be able to
571 create and write to '$myconfigpm'.
572
573 Aborting configuration.
574 END
575         }
576
577     }
578     local($") = ", ";
579     if ($redo && !$doit) {
580         $CPAN::Frontend->myprint(<<END);
581 Sorry, we have to rerun the configuration dialog for CPAN.pm due to
582 some missing parameters...  Will write to
583  <<$configpm>>
584
585 END
586         $args{args} = \@miss;
587     }
588     my $initialized = CPAN::FirstTime::init($configpm, %args);
589     return $initialized;
590 }
591
592
593 # returns mandatory but missing entries in the Config
594 sub missing_config_data {
595     my(@miss);
596     for (
597          "auto_commit",
598          "build_cache",
599          "build_dir",
600          "cache_metadata",
601          "cpan_home",
602          "ftp_proxy",
603          #"gzip",
604          "http_proxy",
605          "index_expire",
606          #"inhibit_startup_message",
607          "keep_source_where",
608          #"make",
609          "make_arg",
610          "make_install_arg",
611          "makepl_arg",
612          "mbuild_arg",
613          "mbuild_install_arg",
614          ($^O eq "MSWin32" ? "" : "mbuild_install_build_command"),
615          "mbuildpl_arg",
616          "no_proxy",
617          #"pager",
618          "prerequisites_policy",
619          "scan_cache",
620          #"tar",
621          #"unzip",
622          "urllist",
623         ) {
624         next unless exists $keys{$_};
625         push @miss, $_ unless defined $CPAN::Config->{$_};
626     }
627     return @miss;
628 }
629
630 sub help {
631     $CPAN::Frontend->myprint(q[
632 Known options:
633   commit    commit session changes to disk
634   defaults  reload default config values from disk
635   help      this help
636   init      enter a dialog to set all or a set of parameters
637
638 Edit key values as in the following (the "o" is a literal letter o):
639   o conf build_cache 15
640   o conf build_dir "/foo/bar"
641   o conf urllist shift
642   o conf urllist unshift ftp://ftp.foo.bar/
643   o conf inhibit_startup_message 1
644
645 ]);
646     1; #don't reprint CPAN::Config
647 }
648
649 sub cpl {
650     my($word,$line,$pos) = @_;
651     $word ||= "";
652     CPAN->debug("word[$word] line[$line] pos[$pos]") if $CPAN::DEBUG;
653     my(@words) = split " ", substr($line,0,$pos+1);
654     if (
655         defined($words[2])
656         and
657         $words[2] =~ /list$/
658         and
659         (
660         @words == 3
661         ||
662         @words == 4 && length($word)
663         )
664        ) {
665         return grep /^\Q$word\E/, qw(splice shift unshift pop push);
666     } elsif (defined($words[2])
667              and
668              $words[2] eq "init"
669              and
670             (
671              @words == 3
672              ||
673              @words >= 4 && length($word)
674             )) {
675         return sort grep /^\Q$word\E/, keys %keys;
676     } elsif (@words >= 4) {
677         return ();
678     }
679     my %seen;
680     my(@o_conf) =  sort grep { !$seen{$_}++ }
681         keys %can,
682             keys %$CPAN::Config,
683                 keys %keys;
684     return grep /^\Q$word\E/, @o_conf;
685 }
686
687 sub prefs_lookup {
688     my($self,$distro,$what) = @_;
689
690     if ($prefssupport{$what}) {
691         return $CPAN::Config->{$what} unless
692             $distro
693                 and $distro->prefs
694                     and $distro->prefs->{cpanconfig}
695                         and defined $distro->prefs->{cpanconfig}{$what};
696         return $distro->prefs->{cpanconfig}{$what};
697     } else {
698         $CPAN::Frontend->mywarn("Warning: $what not yet officially ".
699                                 "supported for distroprefs, doing a normal lookup");
700         return $CPAN::Config->{$what};
701     }
702 }
703
704
705 {
706     package
707         CPAN::Config; ####::###### #hide from indexer
708     # note: J. Nick Koston wrote me that they are using
709     # CPAN::Config->commit although undocumented. I suggested
710     # CPAN::Shell->o("conf","commit") even when ugly it is at least
711     # documented
712
713     # that's why I added the CPAN::Config class with autoload and
714     # deprecated warning
715
716     use strict;
717     use vars qw($AUTOLOAD $VERSION);
718     $VERSION = "5.5001";
719
720     # formerly CPAN::HandleConfig was known as CPAN::Config
721     sub AUTOLOAD { ## no critic
722         my $class = shift; # e.g. in dh-make-perl: CPAN::Config
723         my($l) = $AUTOLOAD;
724         $CPAN::Frontend->mywarn("Dispatching deprecated method '$l' to CPAN::HandleConfig\n");
725         $l =~ s/.*:://;
726         CPAN::HandleConfig->$l(@_);
727     }
728 }
729
730 1;
731
732 __END__
733
734 =head1 LICENSE
735
736 This program is free software; you can redistribute it and/or
737 modify it under the same terms as Perl itself.
738
739 =cut
740
741 # Local Variables:
742 # mode: cperl
743 # cperl-indent-level: 4
744 # End: