This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Move ExtUtils::ParseXS from cpan/ to dist/
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still currrent
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # "not absolute" is the the default, as it saves some fakery within TestInit
27 # which can peturb tests, and takes CPU. Working with the upstream author of
28 # any of these, to figure out how to remove them from this list, considered
29 # "a good thing".
30 my %abs = (
31            '../cpan/Archive-Extract' => 1,
32            '../cpan/Archive-Tar' => 1,
33            '../cpan/AutoLoader' => 1,
34            '../cpan/CPAN' => 1,
35            '../cpan/Class-ISA' => 1,
36            '../cpan/Devel-PPPort' => 1,
37            '../cpan/Encode' => 1,
38            '../cpan/ExtUtils-Command' => 1,
39            '../cpan/ExtUtils-Constant' => 1,
40            '../cpan/ExtUtils-MakeMaker' => 1,
41            '../cpan/ExtUtils-Manifest' => 1,
42            '../cpan/File-Fetch' => 1,
43            '../cpan/IPC-Cmd' => 1,
44            '../cpan/IPC-SysV' => 1,
45            '../cpan/Locale-Codes' => 1,
46            '../cpan/Log-Message' => 1,
47            '../cpan/Math-BigInt' => 1,
48            '../cpan/Math-BigRat' => 1,
49            '../cpan/Math-Complex' => 1,
50            '../cpan/Module-Build' => 1,
51            '../cpan/Module-Load' => 1,
52            '../cpan/Module-Load-Conditional' => 1,
53            '../cpan/Object-Accessor' => 1,
54            '../cpan/Package-Constants' => 1,
55            '../cpan/Parse-CPAN-Meta' => 1,
56            '../cpan/Pod-Simple' => 1,
57            '../cpan/Term-UI' => 1,
58            '../cpan/Test-Simple' => 1,
59            '../cpan/Tie-File' => 1,
60            '../cpan/bignum' => 1,
61            '../cpan/podlators' => 1,
62            '../dist/Cwd' => 1,
63            '../dist/ExtUtils-Install' => 1,
64            '../dist/ExtUtils-ParseXS' => 1,
65           );
66
67 my %temp_no_core =
68     ('../cpan/B-Debug' => 1,
69      '../cpan/Compress-Raw-Bzip2' => 1,
70      '../cpan/Compress-Raw-Zlib' => 1,
71      '../cpan/Devel-PPPort' => 1,
72      '../cpan/Getopt-Long' => 1,
73      '../cpan/IO-Compress' => 1,
74      '../cpan/Math-BigInt' => 1,
75      '../cpan/Math-BigRat' => 1,
76      '../cpan/MIME-Base64' => 1,
77      '../cpan/NEXT' => 1,
78      '../cpan/parent' => 1,
79      '../cpan/Parse-CPAN-Meta' => 1,
80      '../cpan/Pod-Simple' => 1,
81      '../cpan/podlators' => 1,
82      '../cpan/Test-Simple' => 1,
83      '../cpan/Tie-RefHash' => 1,
84      '../cpan/Time-HiRes' => 1,
85      '../cpan/Unicode-Collate' => 1,
86      '../cpan/Unicode-Normalize' => 1,
87     );
88
89 # delete env vars that may influence the results
90 # but allow override via *_TEST env var if wanted
91 # (e.g. PERL5OPT_TEST=-d:NYTProf)
92 for my $envname (qw(PERL5LIB PERLLIB PERL5OPT)) {
93     my $override = $ENV{"${envname}_TEST"};
94     if (defined $override) {
95         warn "$0: $envname=$override\n";
96         $ENV{$envname} = $override;
97     }
98     else {
99         delete $ENV{$envname};
100     }
101 }
102
103 if ($::do_nothing) {
104     return 1;
105 }
106
107 # Location to put the Valgrind log.
108 our $Valgrind_Log;
109
110 $| = 1;
111
112 # for testing TEST only
113 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
114 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
115
116 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
117 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
118 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
119
120 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
121 # can't rely on require working.
122 {
123     my @argv = ();
124     foreach my $idx (0..$#ARGV) {
125         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
126         $::benchmark = 1 if $1 eq 'benchmark';
127         $::core    = 1 if $1 eq 'core';
128         $::verbose = 1 if $1 eq 'v';
129         $::torture = 1 if $1 eq 'torture';
130         $::with_utf8 = 1 if $1 eq 'utf8';
131         $::with_utf16 = 1 if $1 eq 'utf16';
132         $::taintwarn = 1 if $1 eq 'taintwarn';
133         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
134         if ($1 =~ /^deparse(,.+)?$/) {
135             $::deparse = 1;
136             $::deparse_opts = $1;
137         }
138     }
139     @ARGV = @argv;
140 }
141
142 chdir 't' if -f 't/TEST';
143 if (-f 'TEST' && -f 'harness' && -d '../lib') {
144     @INC = '../lib';
145 }
146
147 die "You need to run \"make test\" first to set things up.\n"
148   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
149
150 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
151     unless (-x 'perl.third') {
152         unless (-x '../perl.third') {
153             die "You need to run \"make perl.third first.\n";
154         }
155         else {
156             print "Symlinking ../perl.third as perl.third...\n";
157             die "Failed to symlink: $!\n"
158                 unless symlink("../perl.third", "perl.third");
159             die "Symlinked but no executable perl.third: $!\n"
160                 unless -x 'perl.third';
161         }
162     }
163 }
164
165 # check leakage for embedders
166 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
167
168 $ENV{EMXSHELL} = 'sh';        # For OS/2
169
170 if ($show_elapsed_time) { require Time::HiRes }
171
172 my %skip = (
173             '.' => 1,
174             '..' => 1,
175             'CVS' => 1,
176             'RCS' => 1,
177             'SCCS' => 1,
178             '.svn' => 1,
179            );
180
181 # Roll your own File::Find!
182 sub _find_tests {
183     my($dir) = @_;
184     opendir DIR, $dir or die "Trouble opening $dir: $!";
185     foreach my $f (sort { $a cmp $b } readdir DIR) {
186         next if $skip{$f};
187
188         my $fullpath = "$dir/$f";
189
190         if (-d $fullpath) {
191             _find_tests($fullpath);
192         } elsif ($f =~ /\.t$/) {
193             push @ARGV, $fullpath;
194         }
195     }
196 }
197
198
199 # Scan the text of the test program to find switches and special options
200 # we might need to apply.
201 sub _scan_test {
202     my($test, $type) = @_;
203
204     open(my $script, "<", $test) or die "Can't read $test.\n";
205     my $first_line = <$script>;
206
207     $first_line =~ tr/\0//d if $::with_utf16;
208
209     my $switch = "";
210     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
211         $switch = "-$1";
212     } else {
213         if ($::taintwarn) {
214             # not all tests are expected to pass with this option
215             $switch = '-t';
216         } else {
217             $switch = '';
218         }
219     }
220
221     my $file_opts = "";
222     if ($type eq 'deparse') {
223         # Look for #line directives which change the filename
224         while (<$script>) {
225             $file_opts = $file_opts . ",-f$3$4"
226               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
227         }
228     }
229
230     close $script;
231
232     my $perl = './perl';
233     my $lib  = '../lib';
234     my $run_dir;
235     my $return_dir;
236
237     $test =~ /^(.+)\/[^\/]+/;
238     my $dir = $1;
239     my $testswitch = $dir_to_switch{$dir};
240     if (!defined $testswitch) {
241         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
242             $run_dir = $1;
243             $return_dir = '../../t';
244             $lib = '../../lib';
245             $perl = '../../t/perl';
246             $testswitch = "-I../.. -MTestInit=U2T";
247             if ($2 eq 'cpan' || $2 eq 'dist') {
248                 if($abs{$run_dir}) {
249                     $testswitch = $testswitch . ',A';
250                 }
251                 if ($temp_no_core{$run_dir}) {
252                     $testswitch = $testswitch . ',NC';
253                 }
254             }
255         } else {
256             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
257         }
258     }
259
260     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
261
262     my %options = (
263         perl => $perl,
264         lib => $lib,
265         test => $test,
266         run_dir => $run_dir,
267         return_dir => $return_dir,
268         testswitch => $testswitch,
269         utf8 => $utf8,
270         file => $file_opts,
271         switch => $switch,
272     );
273
274     return \%options;
275 }
276
277 sub _cmd {
278     my($options, $type) = @_;
279
280     my $test = $options->{test};
281
282     my $cmd;
283     if ($type eq 'deparse') {
284         my $perl = "$options->{perl} $options->{testswitch}";
285         my $lib = $options->{lib};
286
287         $cmd = (
288           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
289           "-l$::deparse_opts$options->{file} ".
290           "$test > $test.dp ".
291           "&& $perl $options->{switch} -I$lib $test.dp"
292         );
293     }
294     elsif ($type eq 'perl') {
295         my $perl = $options->{perl};
296         my $redir = $^O eq 'VMS' ? '2>&1' : '';
297
298         if ($ENV{PERL_VALGRIND}) {
299             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
300             my $valgrind = $ENV{VALGRIND} // 'valgrind';
301             my $vg_opts = $ENV{VG_OPTS}
302               //  "--suppressions=$perl_supp --leak-check=yes "
303                 . "--leak-resolution=high --show-reachable=yes "
304                   . "--num-callers=50 --track-origins=yes";
305             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
306             $redir = "3>$Valgrind_Log";
307             if ($options->{run_dir}) {
308                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
309             }
310         }
311
312         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
313         $cmd = $perl . _quote_args($args) . " $test $redir";
314     }
315
316     return $cmd;
317 }
318
319 sub _before_fork {
320     my ($options) = @_;
321
322     if ($options->{run_dir}) {
323         my $run_dir = $options->{run_dir};
324         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
325     }
326
327     return;
328 }
329
330 sub _after_fork {
331     my ($options) = @_;
332
333     if ($options->{return_dir}) {
334         my $return_dir = $options->{return_dir};
335         chdir $return_dir
336            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
337     }
338
339     return;
340 }
341
342 sub _run_test {
343     my ($test, $type) = @_;
344
345     my $options = _scan_test($test, $type);
346     # $test might have changed if we're in ext/Foo, so don't use it anymore
347     # from now on. Use $options->{test} instead.
348
349     _before_fork($options);
350
351     my $cmd = _cmd($options, $type);
352
353     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
354
355     _after_fork($options);
356
357     # Our environment may force us to use UTF-8, but we can't be sure that
358     # anything we're reading from will be generating (well formed) UTF-8
359     # This may not be the best way - possibly we should unset ${^OPEN} up
360     # top?
361     binmode $results;
362
363     return $results;
364 }
365
366 sub _quote_args {
367     my ($args) = @_;
368     my $argstring = '';
369
370     foreach (split(/\s+/,$args)) {
371        # In VMS protect with doublequotes because otherwise
372        # DCL will lowercase -- unless already doublequoted.
373        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
374        $argstring = $argstring . ' ' . $_;
375     }
376     return $argstring;
377 }
378
379 sub _populate_hash {
380     return unless defined $_[0];
381     return map {$_, 1} split /\s+/, $_[0];
382 }
383
384 sub _tests_from_manifest {
385     my ($extensions, $known_extensions) = @_;
386     my %skip;
387     my %extensions = _populate_hash($extensions);
388     my %known_extensions = _populate_hash($known_extensions);
389
390     foreach (keys %known_extensions) {
391         $skip{$_} = 1 unless $extensions{$_};
392     }
393
394     my @results;
395     my $mani = '../MANIFEST';
396     if (open(MANI, $mani)) {
397         while (<MANI>) {
398             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
399                 my $t = $1;
400                 my $extension = $2;
401                 if (!$::core || $t =~ m!^lib/[a-z]!) {
402                     if (defined $extension) {
403                         $extension =~ s!/t$!!;
404                         # XXX Do I want to warn that I'm skipping these?
405                         next if $skip{$extension};
406                         my $flat_extension = $extension;
407                         $flat_extension =~ s!-!/!g;
408                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
409                     }
410                     my $path = "../$t";
411                     push @results, $path;
412                     $::path_to_name{$path} = $t;
413                 }
414             }
415         }
416         close MANI;
417     } else {
418         warn "$0: cannot open $mani: $!\n";
419     }
420     return @results;
421 }
422
423 unless (@ARGV) {
424     # base first, as TEST bails out if that can't run
425     # then comp, to validate that require works
426     # then run, to validate that -M works
427     # then we know we can -MTestInit for everything else, making life simpler
428     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
429         _find_tests($dir);
430     }
431     _find_tests("lib") unless $::core;
432     # Config.pm may be broken for make minitest. And this is only a refinement
433     # for skipping tests on non-default builds, so it is allowed to fail.
434     # What we want to to is make a list of extensions which we did not build.
435     my $configsh = '../config.sh';
436     my ($extensions, $known_extensions);
437     if (-f $configsh) {
438         open FH, $configsh or die "Can't open $configsh: $!";
439         while (<FH>) {
440             if (/^extensions=['"](.*)['"]$/) {
441                 $extensions = $1;
442             }
443             elsif (/^known_extensions=['"](.*)['"]$/) {
444                 $known_extensions = $1;
445             }
446         }
447         if (!defined $known_extensions) {
448             warn "No known_extensions line found in $configsh";
449         }
450         if (!defined $extensions) {
451             warn "No extensions line found in $configsh";
452         }
453     }
454     # The "complex" constructions of list return from a subroutine, and push of
455     # a list, might fail if perl is really hosed, but they aren't needed for
456     # make minitest, and the building of extensions will likely also fail if
457     # something is that badly wrong.
458     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
459     unless ($::core) {
460         _find_tests('x2p');
461         _find_tests('porting');
462         _find_tests('japh') if $::torture;
463         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
464     }
465 }
466
467 if ($::deparse) {
468     _testprogs('deparse', '',   @ARGV);
469 }
470 elsif ($::with_utf16) {
471     for my $e (0, 1) {
472         for my $b (0, 1) {
473             print STDERR "# ENDIAN $e BOM $b\n";
474             my @UARGV;
475             for my $a (@ARGV) {
476                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
477                 my $f = $e ? "v" : "n";
478                 push @UARGV, $u;
479                 unlink($u);
480                 if (open(A, $a)) {
481                     if (open(U, ">$u")) {
482                         print U pack("$f", 0xFEFF) if $b;
483                         while (<A>) {
484                             print U pack("$f*", unpack("C*", $_));
485                         }
486                         close(U);
487                     }
488                     close(A);
489                 }
490             }
491             _testprogs('perl', '', @UARGV);
492             unlink(@UARGV);
493         }
494     }
495 }
496 else {
497     _testprogs('perl',    '',   @ARGV);
498 }
499
500 sub _testprogs {
501     my ($type, $args, @tests) = @_;
502
503     print <<'EOT' if ($type eq 'deparse');
504 ------------------------------------------------------------------------------
505 TESTING DEPARSER
506 ------------------------------------------------------------------------------
507 EOT
508
509     $::bad_files = 0;
510
511     foreach my $t (@tests) {
512       unless (exists $::path_to_name{$t}) {
513         my $tname = "t/$t";
514         $::path_to_name{$t} = $tname;
515       }
516     }
517     my $maxlen = 0;
518     foreach (@::path_to_name{@tests}) {
519         s/\.\w+\z/./;
520         my $len = length ;
521         $maxlen = $len if $len > $maxlen;
522     }
523     # + 3 : we want three dots between the test name and the "ok"
524     my $dotdotdot = $maxlen + 3 ;
525     my $valgrind = 0;
526     my $total_files = @tests;
527     my $good_files = 0;
528     my $tested_files  = 0;
529     my $totmax = 0;
530     my %failed_tests;
531
532     while (my $test = shift @tests) {
533         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
534
535         if ($test =~ /^$/) {
536             next;
537         }
538         if ($type eq 'deparse') {
539             if ($test eq "comp/redef.t") {
540                 # Redefinition happens at compile time
541                 next;
542             }
543             elsif ($test =~ m{lib/Switch/t/}) {
544                 # B::Deparse doesn't support source filtering
545                 next;
546             }
547         }
548         my $te = $::path_to_name{$test} . '.'
549                     x ($dotdotdot - length($::path_to_name{$test}));
550
551         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
552             print $te;
553             $te = '';
554         }
555
556         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
557         my $results = _run_test($test, $type);
558
559         my $failure;
560         my $next = 0;
561         my $seen_leader = 0;
562         my $seen_ok = 0;
563         my $trailing_leader = 0;
564         my $max;
565         my %todo;
566         while (<$results>) {
567             next if /^\s*$/; # skip blank lines
568             if (/^1..$/ && ($^O eq 'VMS')) {
569                 # VMS pipe bug inserts blank lines.
570                 my $l2 = <RESULTS>;
571                 if ($l2 =~ /^\s*$/) {
572                     $l2 = <RESULTS>;
573                 }
574                 $_ = '1..' . $l2;
575             }
576             if ($::verbose) {
577                 print $_;
578             }
579             unless (/^\#/) {
580                 if ($trailing_leader) {
581                     # shouldn't be anything following a postfix 1..n
582                     $failure = 'FAILED--extra output after trailing 1..n';
583                     last;
584                 }
585                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
586                     if ($seen_leader) {
587                         $failure = 'FAILED--seen duplicate leader';
588                         last;
589                     }
590                     $max = $1;
591                     %todo = map { $_ => 1 } split / /, $3 if $3;
592                     $totmax = $totmax + $max;
593                     $tested_files = $tested_files + 1;
594                     if ($seen_ok) {
595                         # 1..n appears at end of file
596                         $trailing_leader = 1;
597                         if ($next != $max) {
598                             $failure = "FAILED--expected $max tests, saw $next";
599                             last;
600                         }
601                     }
602                     else {
603                         $next = 0;
604                     }
605                     $seen_leader = 1;
606                 }
607                 else {
608                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
609                         unless ($seen_leader) {
610                             unless ($seen_ok) {
611                                 $next = 0;
612                             }
613                         }
614                         $seen_ok = 1;
615                         $next = $next + 1;
616                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
617                         $num = $next unless $num;
618
619                         if ($num == $next) {
620
621                             # SKIP is essentially the same as TODO for t/TEST
622                             # this still conforms to TAP:
623                             # http://search.cpan.org/dist/TAP/TAP.pm
624                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
625                             $istodo = 1 if $todo{$num};
626
627                             if( $not && !$istodo ) {
628                                 $failure = "FAILED at test $num";
629                                 last;
630                             }
631                         }
632                         else {
633                             $failure ="FAILED--expected test $next, saw test $num";
634                             last;
635                         }
636                     }
637                     elsif (/^Bail out!\s*(.*)/i) { # magic words
638                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
639                     }
640                     else {
641                         # module tests are allowed extra output,
642                         # because Test::Harness allows it
643                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
644                         $failure = "FAILED--unexpected output at test $next";
645                         last;
646                     }
647                 }
648             }
649         }
650         close $results;
651
652         if (not defined $failure) {
653             $failure = 'FAILED--no leader found' unless $seen_leader;
654         }
655
656         if ($ENV{PERL_VALGRIND}) {
657             my @valgrind;
658             if (-e $Valgrind_Log) {
659                 if (open(V, $Valgrind_Log)) {
660                     @valgrind = <V>;
661                     close V;
662                 } else {
663                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
664                 }
665             }
666             if ($ENV{VG_OPTS} =~ /cachegrind/) {
667                 if (rename $Valgrind_Log, "$test.valgrind") {
668                     $valgrind = $valgrind + 1;
669                 } else {
670                     warn "$0: Failed to create '$test.valgrind': $!\n";
671                 }
672             }
673             elsif (@valgrind) {
674                 my $leaks = 0;
675                 my $errors = 0;
676                 for my $i (0..$#valgrind) {
677                     local $_ = $valgrind[$i];
678                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
679                         $errors = $errors + $1;   # there may be multiple error summaries
680                     } elsif (/^==\d+== LEAK SUMMARY:/) {
681                         for my $off (1 .. 4) {
682                             if ($valgrind[$i+$off] =~
683                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
684                                 $leaks = $leaks + $1;
685                             }
686                         }
687                     }
688                 }
689                 if ($errors or $leaks) {
690                     if (rename $Valgrind_Log, "$test.valgrind") {
691                         $valgrind = $valgrind + 1;
692                     } else {
693                         warn "$0: Failed to create '$test.valgrind': $!\n";
694                     }
695                 }
696             } else {
697                 warn "No valgrind output?\n";
698             }
699             if (-e $Valgrind_Log) {
700                 unlink $Valgrind_Log
701                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
702             }
703         }
704         if ($type eq 'deparse') {
705             unlink "./$test.dp";
706         }
707         if ($ENV{PERL_3LOG}) {
708             my $tpp = $test;
709             $tpp =~ s:^\.\./::;
710             $tpp =~ s:/:_:g;
711             $tpp =~ s:\.t$:.3log:;
712             rename("perl.3log", $tpp) ||
713                 die "rename: perl3.log to $tpp: $!\n";
714         }
715         if (not defined $failure and $next != $max) {
716             $failure="FAILED--expected $max tests, saw $next";
717         }
718
719         if( !defined $failure  # don't mask a test failure
720             and $? )
721         {
722             $failure = "FAILED--non-zero wait status: $?";
723         }
724
725         if (defined $failure) {
726             print "${te}$failure\n";
727             $::bad_files = $::bad_files + 1;
728             if ($test =~ /^base/) {
729                 die "Failed a basic test ($test) -- cannot continue.\n";
730             }
731             $failed_tests{$test} = 1;
732         }
733         else {
734             if ($max) {
735                 my $elapsed;
736                 if ( $show_elapsed_time ) {
737                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
738                 }
739                 else {
740                     $elapsed = "";
741                 }
742                 print "${te}ok$elapsed\n";
743                 $good_files = $good_files + 1;
744             }
745             else {
746                 print "${te}skipped\n";
747                 $tested_files = $tested_files - 1;
748             }
749         }
750     } # while tests
751
752     if ($::bad_files == 0) {
753         if ($good_files) {
754             print "All tests successful.\n";
755             # XXX add mention of 'perlbug -ok' ?
756         }
757         else {
758             die "FAILED--no tests were run for some reason.\n";
759         }
760     }
761     else {
762         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
763         my $s = $::bad_files == 1 ? "" : "s";
764         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
765         for my $test ( sort keys %failed_tests ) {
766             print "\t$test\n";
767         }
768         warn <<'SHRDLU_1';
769 ### Since not all tests were successful, you may want to run some of
770 ### them individually and examine any diagnostic messages they produce.
771 ### See the INSTALL document's section on "make test".
772 SHRDLU_1
773         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
774 ### You have a good chance to get more information by running
775 ###   ./perl harness
776 ### in the 't' directory since most (>=80%) of the tests succeeded.
777 SHRDLU_2
778         if (eval {require Config; import Config; 1}) {
779             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
780                 warn <<SHRDLU_3;
781 ### You may have to set your dynamic library search path,
782 ### $p, to point to the build directory:
783 SHRDLU_3
784                 if (exists $ENV{$p} && $ENV{$p} ne '') {
785                     warn <<SHRDLU_4a;
786 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
787 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
788 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
789 SHRDLU_4a
790                 } else {
791                     warn <<SHRDLU_4b;
792 ###   setenv $p `pwd`; cd t; ./perl harness
793 ###   $p=`pwd`; export $p; cd t; ./perl harness
794 ###   export $p=`pwd`; cd t; ./perl harness
795 SHRDLU_4b
796                 }
797                 warn <<SHRDLU_5;
798 ### for csh-style shells, like tcsh; or for traditional/modern
799 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
800 SHRDLU_5
801             }
802         }
803     }
804     my ($user,$sys,$cuser,$csys) = times;
805     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
806         $user,$sys,$cuser,$csys,$tested_files,$totmax);
807     if ($ENV{PERL_VALGRIND}) {
808         my $s = $valgrind == 1 ? '' : 's';
809         print "$valgrind valgrind report$s created.\n", ;
810     }
811 }
812 exit ($::bad_files != 0);
813
814 # ex: set ts=8 sts=4 sw=4 noet: