t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 # "not absolute" is the the default, as it saves some fakery within TestInit
  27 # which can peturb tests, and takes CPU. Working with the upstream author of
  28 # any of these, to figure out how to remove them from this list, considered
  29 # "a good thing".
  30 my %abs = (
  31            '../cpan/Archive-Extract' => 1,
  32            '../cpan/Archive-Tar' => 1,
  33            '../cpan/AutoLoader' => 1,
  34            '../cpan/CPAN' => 1,
  35            '../cpan/Class-ISA' => 1,
  36            '../cpan/Devel-PPPort' => 1,
  37            '../cpan/Encode' => 1,
  38            '../cpan/ExtUtils-Constant' => 1,
  39            '../cpan/ExtUtils-MakeMaker' => 1,
  40            '../cpan/File-Fetch' => 1,
  41            '../cpan/IPC-Cmd' => 1,
  42            '../cpan/IPC-SysV' => 1,
  43            '../cpan/Locale-Codes' => 1,
  44            '../cpan/Log-Message' => 1,
  45            '../cpan/Module-Build' => 1,
  46            '../cpan/Module-Load' => 1,
  47            '../cpan/Module-Load-Conditional' => 1,
  48            '../cpan/Object-Accessor' => 1,
  49            '../cpan/Package-Constants' => 1,
  50            '../cpan/Parse-CPAN-Meta' => 1,
  51            '../cpan/Pod-Simple' => 1,
  52            '../cpan/Term-UI' => 1,
  53            '../cpan/Test-Simple' => 1,
  54            '../cpan/podlators' => 1,
  55            '../dist/Cwd' => 1,
  56            '../dist/ExtUtils-Command' => 1,
  57            '../dist/ExtUtils-Install' => 1,
  58            '../dist/ExtUtils-Manifest' => 1,
  59            '../dist/ExtUtils-ParseXS' => 1,
  60            '../dist/Tie-File' => 1,
  61           );
  62
  63 my %temp_no_core =
  64     ('../cpan/B-Debug' => 1,
  65      '../cpan/Compress-Raw-Bzip2' => 1,
  66      '../cpan/Compress-Raw-Zlib' => 1,
  67      '../cpan/Devel-PPPort' => 1,
  68      '../cpan/Getopt-Long' => 1,
  69      '../cpan/IO-Compress' => 1,
  70      '../cpan/MIME-Base64' => 1,
  71      '../cpan/parent' => 1,
  72      '../cpan/Parse-CPAN-Meta' => 1,
  73      '../cpan/Pod-Simple' => 1,
  74      '../cpan/podlators' => 1,
  75      '../cpan/Test-Simple' => 1,
  76      '../cpan/Tie-RefHash' => 1,
  77      '../cpan/Unicode-Collate' => 1,
  78      '../cpan/Unicode-Normalize' => 1,
  79     );
  80
  81 # delete env vars that may influence the results
  82 # but allow override via *_TEST env var if wanted
  83 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  84 for my $envname (qw(PERL5LIB PERLLIB PERL5OPT)) {
  85     my $override = $ENV{"${envname}_TEST"};
  86     if (defined $override) {
  87         warn "$0: $envname=$override\n";
  88         $ENV{$envname} = $override;
  89     }
  90     else {
  91         delete $ENV{$envname};
  92     }
  93 }
  94
  95 if ($::do_nothing) {
  96     return 1;
  97 }
  98
  99 # Location to put the Valgrind log.
 100 our $Valgrind_Log;
 101
 102 $| = 1;
 103
 104 # for testing TEST only
 105 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 106 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 107
 108 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 109 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 110 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 111
 112 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 113 # can't rely on require working.
 114 {
 115     my @argv = ();
 116     foreach my $idx (0..$#ARGV) {
 117         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 118         $::benchmark = 1 if $1 eq 'benchmark';
 119         $::core    = 1 if $1 eq 'core';
 120         $::verbose = 1 if $1 eq 'v';
 121         $::torture = 1 if $1 eq 'torture';
 122         $::with_utf8 = 1 if $1 eq 'utf8';
 123         $::with_utf16 = 1 if $1 eq 'utf16';
 124         $::taintwarn = 1 if $1 eq 'taintwarn';
 125         if ($1 =~ /^deparse(,.+)?$/) {
 126             $::deparse = 1;
 127             $::deparse_opts = $1;
 128         }
 129     }
 130     @ARGV = @argv;
 131 }
 132
 133 chdir 't' if -f 't/TEST';
 134 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 135     @INC = '../lib';
 136 }
 137
 138 die "You need to run \"make test\" first to set things up.\n"
 139   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 140
 141 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
 142     unless (-x 'perl.third') {
 143         unless (-x '../perl.third') {
 144             die "You need to run \"make perl.third first.\n";
 145         }
 146         else {
 147             print "Symlinking ../perl.third as perl.third...\n";
 148             die "Failed to symlink: $!\n"
 149                 unless symlink("../perl.third", "perl.third");
 150             die "Symlinked but no executable perl.third: $!\n"
 151                 unless -x 'perl.third';
 152         }
 153     }
 154 }
 155
 156 # check leakage for embedders
 157 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 158 # check existence of all symbols
 159 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
 160
 161 $ENV{EMXSHELL} = 'sh';        # For OS/2
 162
 163 if ($show_elapsed_time) { require Time::HiRes }
 164 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
 165
 166 my %skip = (
 167             '.' => 1,
 168             '..' => 1,
 169             'CVS' => 1,
 170             'RCS' => 1,
 171             'SCCS' => 1,
 172             '.svn' => 1,
 173            );
 174
 175 # Roll your own File::Find!
 176 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
 177 sub _find_files {
 178     my($patt, @dirs) = @_;
 179     for my $dir (@dirs) {
 180         opendir DIR, $dir or die "Trouble opening $dir: $!";
 181         foreach my $f (sort { $a cmp $b } readdir DIR) {
 182             next if $skip{$f};
 183
 184             my $fullpath = "$dir/$f";
 185
 186             if (-d $fullpath) {
 187                 _find_files($patt, $fullpath);
 188             } elsif ($f =~ /$patt/) {
 189                 push @found, $fullpath;
 190             }
 191         }
 192     }
 193     @found;
 194 }
 195
 196
 197 # Scan the text of the test program to find switches and special options
 198 # we might need to apply.
 199 sub _scan_test {
 200     my($test, $type) = @_;
 201
 202     open(my $script, "<", $test) or die "Can't read $test.\n";
 203     my $first_line = <$script>;
 204
 205     $first_line =~ tr/\0//d if $::with_utf16;
 206
 207     my $switch = "";
 208     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 209         $switch = "-$1";
 210     } else {
 211         if ($::taintwarn) {
 212             # not all tests are expected to pass with this option
 213             $switch = '-t';
 214         } else {
 215             $switch = '';
 216         }
 217     }
 218
 219     my $file_opts = "";
 220     if ($type eq 'deparse') {
 221         # Look for #line directives which change the filename
 222         while (<$script>) {
 223             $file_opts = $file_opts . ",-f$3$4"
 224               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 225         }
 226     }
 227
 228     close $script;
 229
 230     my $perl = './perl';
 231     my $lib  = '../lib';
 232     my $run_dir;
 233     my $return_dir;
 234
 235     $test =~ /^(.+)\/[^\/]+/;
 236     my $dir = $1;
 237     my $testswitch = $dir_to_switch{$dir};
 238     if (!defined $testswitch) {
 239         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 240             $run_dir = $1;
 241             $return_dir = '../../t';
 242             $lib = '../../lib';
 243             $perl = '../../t/perl';
 244             $testswitch = "-I../.. -MTestInit=U2T";
 245             if ($2 eq 'cpan' || $2 eq 'dist') {
 246                 if($abs{$run_dir}) {
 247                     $testswitch = $testswitch . ',A';
 248                 }
 249                 if ($temp_no_core{$run_dir}) {
 250                     $testswitch = $testswitch . ',NC';
 251                 }
 252             }
 253         } elsif ($test =~ m!^\.\./lib!) {
 254             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 255         } else {
 256             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 257         }
 258     }
 259
 260     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 261
 262     my %options = (
 263         perl => $perl,
 264         lib => $lib,
 265         test => $test,
 266         run_dir => $run_dir,
 267         return_dir => $return_dir,
 268         testswitch => $testswitch,
 269         utf8 => $utf8,
 270         file => $file_opts,
 271         switch => $switch,
 272     );
 273
 274     return \%options;
 275 }
 276
 277 sub _cmd {
 278     my($options, $type) = @_;
 279
 280     my $test = $options->{test};
 281
 282     my $cmd;
 283     if ($type eq 'deparse') {
 284         my $perl = "$options->{perl} $options->{testswitch}";
 285         my $lib = $options->{lib};
 286
 287         $cmd = (
 288           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 289           "-l$::deparse_opts$options->{file} ".
 290           "$test > $test.dp ".
 291           "&& $perl $options->{switch} -I$lib $test.dp"
 292         );
 293     }
 294     elsif ($type eq 'perl') {
 295         my $perl = $options->{perl};
 296         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 297
 298         if ($ENV{PERL_VALGRIND}) {
 299             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 300             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
 301             my $vg_opts = $ENV{VG_OPTS}
 302               // '--log-fd=3 '
 303                   . "--suppressions=$perl_supp --leak-check=yes "
 304                   . "--leak-resolution=high --show-reachable=yes "
 305                   . "--num-callers=50 --track-origins=yes";
 306             $perl = "$valgrind_exe $vg_opts $perl";
 307             $redir = "3>$Valgrind_Log";
 308             if ($options->{run_dir}) {
 309                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 310             }
 311         }
 312
 313         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 314         $cmd = $perl . _quote_args($args) . " $test $redir";
 315     }
 316     return $cmd;
 317 }
 318
 319 sub _before_fork {
 320     my ($options) = @_;
 321
 322     if ($options->{run_dir}) {
 323         my $run_dir = $options->{run_dir};
 324         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 325     }
 326
 327     return;
 328 }
 329
 330 sub _after_fork {
 331     my ($options) = @_;
 332
 333     if ($options->{return_dir}) {
 334         my $return_dir = $options->{return_dir};
 335         chdir $return_dir
 336            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 337     }
 338
 339     return;
 340 }
 341
 342 sub _run_test {
 343     my ($test, $type) = @_;
 344
 345     my $options = _scan_test($test, $type);
 346     # $test might have changed if we're in ext/Foo, so don't use it anymore
 347     # from now on. Use $options->{test} instead.
 348
 349     _before_fork($options);
 350
 351     my $cmd = _cmd($options, $type);
 352
 353     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 354
 355     _after_fork($options);
 356
 357     # Our environment may force us to use UTF-8, but we can't be sure that
 358     # anything we're reading from will be generating (well formed) UTF-8
 359     # This may not be the best way - possibly we should unset ${^OPEN} up
 360     # top?
 361     binmode $results;
 362
 363     return $results;
 364 }
 365
 366 sub _quote_args {
 367     my ($args) = @_;
 368     my $argstring = '';
 369
 370     foreach (split(/\s+/,$args)) {
 371        # In VMS protect with doublequotes because otherwise
 372        # DCL will lowercase -- unless already doublequoted.
 373        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 374        $argstring = $argstring . ' ' . $_;
 375     }
 376     return $argstring;
 377 }
 378
 379 sub _populate_hash {
 380     return unless defined $_[0];
 381     return map {$_, 1} split /\s+/, $_[0];
 382 }
 383
 384 sub _tests_from_manifest {
 385     my ($extensions, $known_extensions) = @_;
 386     my %skip;
 387     my %extensions = _populate_hash($extensions);
 388     my %known_extensions = _populate_hash($known_extensions);
 389
 390     foreach (keys %known_extensions) {
 391         $skip{$_} = 1 unless $extensions{$_};
 392     }
 393
 394     my @results;
 395     my $mani = '../MANIFEST';
 396     if (open(MANI, $mani)) {
 397         while (<MANI>) {
 398             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 399                 my $t = $1;
 400                 my $extension = $2;
 401                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 402                     if (defined $extension) {
 403                         $extension =~ s!/t(:?/\S+)*$!!;
 404                         # XXX Do I want to warn that I'm skipping these?
 405                         next if $skip{$extension};
 406                         my $flat_extension = $extension;
 407                         $flat_extension =~ s!-!/!g;
 408                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 409                     }
 410                     my $path = "../$t";
 411                     push @results, $path;
 412                     $::path_to_name{$path} = $t;
 413                 }
 414             }
 415         }
 416         close MANI;
 417     } else {
 418         warn "$0: cannot open $mani: $!\n";
 419     }
 420     return @results;
 421 }
 422
 423 unless (@ARGV) {
 424     # base first, as TEST bails out if that can't run
 425     # then comp, to validate that require works
 426     # then run, to validate that -M works
 427     # then we know we can -MTestInit for everything else, making life simpler
 428     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
 429         _find_tests($dir);
 430     }
 431     unless ($::core) {
 432         _find_tests('porting');
 433         _find_tests("lib");
 434     }
 435     # Config.pm may be broken for make minitest. And this is only a refinement
 436     # for skipping tests on non-default builds, so it is allowed to fail.
 437     # What we want to to is make a list of extensions which we did not build.
 438     my $configsh = '../config.sh';
 439     my ($extensions, $known_extensions);
 440     if (-f $configsh) {
 441         open FH, $configsh or die "Can't open $configsh: $!";
 442         while (<FH>) {
 443             if (/^extensions=['"](.*)['"]$/) {
 444                 $extensions = $1;
 445             }
 446             elsif (/^known_extensions=['"](.*)['"]$/) {
 447                 $known_extensions = $1;
 448             }
 449         }
 450         if (!defined $known_extensions) {
 451             warn "No known_extensions line found in $configsh";
 452         }
 453         if (!defined $extensions) {
 454             warn "No extensions line found in $configsh";
 455         }
 456     }
 457     # The "complex" constructions of list return from a subroutine, and push of
 458     # a list, might fail if perl is really hosed, but they aren't needed for
 459     # make minitest, and the building of extensions will likely also fail if
 460     # something is that badly wrong.
 461     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 462     unless ($::core) {
 463         _find_tests('x2p');
 464         _find_tests('japh') if $::torture;
 465         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 466     }
 467 }
 468
 469 if ($::deparse) {
 470     _testprogs('deparse', '',   @ARGV);
 471 }
 472 elsif ($::with_utf16) {
 473     for my $e (0, 1) {
 474         for my $b (0, 1) {
 475             print STDERR "# ENDIAN $e BOM $b\n";
 476             my @UARGV;
 477             for my $a (@ARGV) {
 478                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 479                 my $f = $e ? "v" : "n";
 480                 push @UARGV, $u;
 481                 unlink($u);
 482                 if (open(A, $a)) {
 483                     if (open(U, ">$u")) {
 484                         print U pack("$f", 0xFEFF) if $b;
 485                         while (<A>) {
 486                             print U pack("$f*", unpack("C*", $_));
 487                         }
 488                         close(U);
 489                     }
 490                     close(A);
 491                 }
 492             }
 493             _testprogs('perl', '', @UARGV);
 494             unlink(@UARGV);
 495         }
 496     }
 497 }
 498 else {
 499     _testprogs('perl',    '',   @ARGV);
 500 }
 501
 502 sub _testprogs {
 503     my ($type, $args, @tests) = @_;
 504
 505     print <<'EOT' if ($type eq 'deparse');
 506 ------------------------------------------------------------------------------
 507 TESTING DEPARSER
 508 ------------------------------------------------------------------------------
 509 EOT
 510
 511     $::bad_files = 0;
 512
 513     foreach my $t (@tests) {
 514       unless (exists $::path_to_name{$t}) {
 515         my $tname = "t/$t";
 516         $::path_to_name{$t} = $tname;
 517       }
 518     }
 519     my $maxlen = 0;
 520     foreach (@::path_to_name{@tests}) {
 521         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
 522         my $len = length ;
 523         $maxlen = $len if $len > $maxlen;
 524     }
 525     # + 3 : we want three dots between the test name and the "ok"
 526     my $dotdotdot = $maxlen + 3 ;
 527     my $grind_ct = 0;           # count of non-empty valgrind reports
 528     my $total_files = @tests;
 529     my $good_files = 0;
 530     my $tested_files  = 0;
 531     my $totmax = 0;
 532     my %failed_tests;
 533     my $toolnm;         # valgrind, cachegrind, perf
 534
 535     while (my $test = shift @tests) {
 536         my ($test_start_time, @starttimes) = 0;
 537         if ($show_elapsed_time) {
 538             $test_start_time = Time::HiRes::time();
 539             # times() reports usage by TEST, but we want usage of each
 540             # testprog it calls, so record accumulated times now,
 541             # subtract them out afterwards.  Ideally, we'd take times
 542             # in BEGIN/END blocks (giving better visibility of self vs
 543             # children of each testprog), but that would require some
 544             # IPC to send results back here, or a completely different
 545             # collection scheme (Storable isnt tuned for incremental use)
 546             @starttimes = times;
 547         }
 548         if ($test =~ /^$/) {
 549             next;
 550         }
 551         if ($type eq 'deparse') {
 552             if ($test eq "comp/redef.t") {
 553                 # Redefinition happens at compile time
 554                 next;
 555             }
 556             elsif ($test =~ m{lib/Switch/t/}) {
 557                 # B::Deparse doesn't support source filtering
 558                 next;
 559             }
 560         }
 561         my $te = $::path_to_name{$test} . '.'
 562                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
 563
 564         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 565             print $te;
 566             $te = '';
 567         }
 568
 569         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 570         my $results = _run_test($test, $type);
 571
 572         my $failure;
 573         my $next = 0;
 574         my $seen_leader = 0;
 575         my $seen_ok = 0;
 576         my $trailing_leader = 0;
 577         my $max;
 578         my %todo;
 579         while (<$results>) {
 580             next if /^\s*$/; # skip blank lines
 581             if (/^1..$/ && ($^O eq 'VMS')) {
 582                 # VMS pipe bug inserts blank lines.
 583                 my $l2 = <RESULTS>;
 584                 if ($l2 =~ /^\s*$/) {
 585                     $l2 = <RESULTS>;
 586                 }
 587                 $_ = '1..' . $l2;
 588             }
 589             if ($::verbose) {
 590                 print $_;
 591             }
 592             unless (/^\#/) {
 593                 if ($trailing_leader) {
 594                     # shouldn't be anything following a postfix 1..n
 595                     $failure = 'FAILED--extra output after trailing 1..n';
 596                     last;
 597                 }
 598                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 599                     if ($seen_leader) {
 600                         $failure = 'FAILED--seen duplicate leader';
 601                         last;
 602                     }
 603                     $max = $1;
 604                     %todo = map { $_ => 1 } split / /, $3 if $3;
 605                     $totmax = $totmax + $max;
 606                     $tested_files = $tested_files + 1;
 607                     if ($seen_ok) {
 608                         # 1..n appears at end of file
 609                         $trailing_leader = 1;
 610                         if ($next != $max) {
 611                             $failure = "FAILED--expected $max tests, saw $next";
 612                             last;
 613                         }
 614                     }
 615                     else {
 616                         $next = 0;
 617                     }
 618                     $seen_leader = 1;
 619                 }
 620                 else {
 621                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 622                         unless ($seen_leader) {
 623                             unless ($seen_ok) {
 624                                 $next = 0;
 625                             }
 626                         }
 627                         $seen_ok = 1;
 628                         $next = $next + 1;
 629                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 630                         $num = $next unless $num;
 631
 632                         if ($num == $next) {
 633
 634                             # SKIP is essentially the same as TODO for t/TEST
 635                             # this still conforms to TAP:
 636                             # http://testanything.org/wiki/index.php/TAP_specification
 637                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 638                             $istodo = 1 if $todo{$num};
 639
 640                             if( $not && !$istodo ) {
 641                                 $failure = "FAILED at test $num";
 642                                 last;
 643                             }
 644                         }
 645                         else {
 646                             $failure ="FAILED--expected test $next, saw test $num";
 647                             last;
 648                         }
 649                     }
 650                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 651                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 652                     }
 653                     else {
 654                         # module tests are allowed extra output,
 655                         # because Test::Harness allows it
 656                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 657                         $failure = "FAILED--unexpected output at test $next";
 658                         last;
 659                     }
 660                 }
 661             }
 662         }
 663         close $results;
 664
 665         if (not defined $failure) {
 666             $failure = 'FAILED--no leader found' unless $seen_leader;
 667         }
 668
 669         if ($ENV{PERL_VALGRIND}) {
 670             $toolnm = $ENV{VALGRIND};
 671             $toolnm =~ s|.*/||;  # keep basename
 672             my @valgrind;       # gets content of file
 673             if (-e $Valgrind_Log) {
 674                 if (open(V, $Valgrind_Log)) {
 675                     @valgrind = <V>;
 676                     close V;
 677                 } else {
 678                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
 679                 }
 680             }
 681             if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $toolnm =~ /(perf)/) {
 682                 $toolnm = $1;
 683                 if ($toolnm eq 'perf') {
 684                     # append perfs subcommand, not just stat
 685                     my ($sub) = split /\s/, $ENV{VG_OPTS};
 686                     $toolnm .= "-$sub";
 687                 }
 688                 if (rename $Valgrind_Log, "$test.$toolnm") {
 689                     $grind_ct++;
 690                 } else {
 691                     warn "$0: Failed to create '$test.$toolnm': $!\n";
 692                 }
 693             }
 694             elsif (@valgrind) {
 695                 my $leaks = 0;
 696                 my $errors = 0;
 697                 for my $i (0..$#valgrind) {
 698                     local $_ = $valgrind[$i];
 699                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 700                         $errors = $errors + $1;   # there may be multiple error summaries
 701                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 702                         for my $off (1 .. 4) {
 703                             if ($valgrind[$i+$off] =~
 704                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 705                                 $leaks = $leaks + $1;
 706                             }
 707                         }
 708                     }
 709                 }
 710                 if ($errors or $leaks) {
 711                     if (rename $Valgrind_Log, "$test.valgrind") {
 712                         $grind_ct = $grind_ct + 1;
 713                     } else {
 714                         warn "$0: Failed to create '$test.valgrind': $!\n";
 715                     }
 716                 }
 717             } else {
 718                 warn "No valgrind output?\n";
 719             }
 720             if (-e $Valgrind_Log) {
 721                 unlink $Valgrind_Log
 722                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 723             }
 724         }
 725         if ($type eq 'deparse') {
 726             unlink "./$test.dp";
 727         }
 728         if ($ENV{PERL_3LOG}) {
 729             my $tpp = $test;
 730             $tpp =~ s:^\.\./::;
 731             $tpp =~ s:/:_:g;
 732             $tpp =~ s:\.t$:.3log:;
 733             rename("perl.3log", $tpp) ||
 734                 die "rename: perl3.log to $tpp: $!\n";
 735         }
 736         if (not defined $failure and $next != $max) {
 737             $failure="FAILED--expected $max tests, saw $next";
 738         }
 739
 740         if( !defined $failure  # don't mask a test failure
 741             and $? )
 742         {
 743             $failure = "FAILED--non-zero wait status: $?";
 744         }
 745
 746         if (defined $failure) {
 747             print "${te}$failure\n";
 748             $::bad_files = $::bad_files + 1;
 749             if ($test =~ /^base/) {
 750                 die "Failed a basic test ($test) -- cannot continue.\n";
 751             }
 752             $failed_tests{$test} = 1;
 753         }
 754         else {
 755             if ($max) {
 756                 my ($elapsed, $etms) = ("", 0);
 757                 if ( $show_elapsed_time ) {
 758                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
 759                     $elapsed = sprintf(" %8.0f ms", $etms);
 760
 761                     my (@endtimes) = times;
 762                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
 763                     splice @endtimes, 0, 2;    # drop self/harness times
 764                     $_ *= 1000 for @endtimes;  # and scale to ms
 765                     $timings{$test} = [$etms,@endtimes];
 766                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
 767                 }
 768                 print "${te}ok$elapsed\n";
 769                 $good_files = $good_files + 1;
 770             }
 771             else {
 772                 print "${te}skipped\n";
 773                 $tested_files = $tested_files - 1;
 774             }
 775         }
 776     } # while tests
 777
 778     if ($::bad_files == 0) {
 779         if ($good_files) {
 780             print "All tests successful.\n";
 781             # XXX add mention of 'perlbug -ok' ?
 782         }
 783         else {
 784             die "FAILED--no tests were run for some reason.\n";
 785         }
 786     }
 787     else {
 788         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 789         my $s = $::bad_files == 1 ? "" : "s";
 790         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 791         for my $test ( sort keys %failed_tests ) {
 792             print "\t$test\n";
 793         }
 794         warn <<'SHRDLU_1';
 795 ### Since not all tests were successful, you may want to run some of
 796 ### them individually and examine any diagnostic messages they produce.
 797 ### See the INSTALL document's section on "make test".
 798 SHRDLU_1
 799         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 800 ### You have a good chance to get more information by running
 801 ###   ./perl harness
 802 ### in the 't' directory since most (>=80%) of the tests succeeded.
 803 SHRDLU_2
 804         if (eval {require Config; import Config; 1}) {
 805             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 806                 warn <<SHRDLU_3;
 807 ### You may have to set your dynamic library search path,
 808 ### $p, to point to the build directory:
 809 SHRDLU_3
 810                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 811                     warn <<SHRDLU_4a;
 812 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 813 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 814 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 815 SHRDLU_4a
 816                 } else {
 817                     warn <<SHRDLU_4b;
 818 ###   setenv $p `pwd`; cd t; ./perl harness
 819 ###   $p=`pwd`; export $p; cd t; ./perl harness
 820 ###   export $p=`pwd`; cd t; ./perl harness
 821 SHRDLU_4b
 822                 }
 823                 warn <<SHRDLU_5;
 824 ### for csh-style shells, like tcsh; or for traditional/modern
 825 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 826 SHRDLU_5
 827             }
 828         }
 829     }
 830     my ($user,$sys,$cuser,$csys) = times;
 831     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
 832                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
 833     print "$tot\n";
 834     if ($good_files) {
 835         if (-d $show_elapsed_time) {
 836             # HARNESS_TIMER = <a-directory>.  Save timings etc to
 837             # storable file there.  NB: the test cds to ./t/, so
 838             # relative path must account for that, ie ../../perf
 839             # points to dir next to source tree.
 840             require Storable;
 841             my @dt = localtime;
 842             $dt[5] += 1900; $dt[4] += 1; # fix year, month
 843             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
 844             Storable::store({ perf => \%timings,
 845                               gather_conf_platform_info(),
 846                               total => $tot,
 847                             }, $fn);
 848             print "wrote storable file: $fn\n";
 849         }
 850     }
 851     if ($ENV{PERL_VALGRIND}) {
 852         my $s = $grind_ct == 1 ? '' : 's';
 853         print "$grind_ct valgrind report$s created.\n", ;
 854         if ($toolnm eq 'cachegrind') {
 855             # cachegrind leaves a lot of cachegrind.out.$pid litter
 856             # around the tree, find and delete them
 857             unlink _find_files('cachegrind.out.\d+$',
 858                              qw ( ../t ../cpan ../ext ../dist/ ));
 859         }
 860     }
 861 }
 862 exit ($::bad_files != 0);
 863
 864 # Collect platform, config data that should allow comparing
 865 # performance data between different machines.  With enough data,
 866 # and/or clever statistical analysis, it should be possible to
 867 # determine the effect of config choices, more memory, etc
 868
 869 sub gather_conf_platform_info {
 870     # currently rather quick & dirty, and subject to change
 871     # for both content and format.
 872     require Config;
 873     my (%conf, @platform) = ();
 874     $conf{$_} = $Config::Config{$_} for
 875         grep /cc|git|config_arg\d+/, keys %Config::Config;
 876     if (-f '/proc/cpuinfo') {
 877         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
 878         @platform = grep /name|cpu/, <$fh>;
 879         chomp $_ for @platform;
 880     }
 881     unshift @platform, $^O;
 882
 883     return (
 884         conf => \%conf,
 885         platform => {cpu => \@platform,
 886                      mem => [ grep s/\s+/ /,
 887                               grep chomp, `free` ],
 888                      load => [ grep chomp, `uptime` ],
 889         },
 890         host => (grep chomp, `hostname -f`),
 891         version => '0.03', # bump for conf, platform, or data collection changes
 892         );
 893 }
 894
 895 # ex: set ts=8 sts=4 sw=4 noet: