This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Refactor Storable::{net_,}pstore to return undef/true, instead of 1 or 0.
[perl5.git] / dist / Storable / Storable.pm
1 #
2 #  Copyright (c) 1995-2000, Raphael Manfredi
3 #  
4 #  You may redistribute only under the same terms as Perl 5, as specified
5 #  in the README file that comes with the distribution.
6 #
7
8 require DynaLoader;
9 require Exporter;
10 package Storable; @ISA = qw(Exporter DynaLoader);
11
12 @EXPORT = qw(store retrieve);
13 @EXPORT_OK = qw(
14         nstore store_fd nstore_fd fd_retrieve
15         freeze nfreeze thaw
16         dclone
17         retrieve_fd
18         lock_store lock_nstore lock_retrieve
19         file_magic read_magic
20 );
21
22 use AutoLoader;
23 use FileHandle;
24 use vars qw($canonical $forgive_me $VERSION);
25
26 $VERSION = '2.23';
27 *AUTOLOAD = \&AutoLoader::AUTOLOAD;             # Grrr...
28
29 #
30 # Use of Log::Agent is optional
31 #
32
33 {
34     local $SIG{__DIE__};
35     eval "use Log::Agent";
36 }
37
38 require Carp;
39
40 #
41 # They might miss :flock in Fcntl
42 #
43
44 BEGIN {
45         if (eval { require Fcntl; 1 } && exists $Fcntl::EXPORT_TAGS{'flock'}) {
46                 Fcntl->import(':flock');
47         } else {
48                 eval q{
49                         sub LOCK_SH ()  {1}
50                         sub LOCK_EX ()  {2}
51                 };
52         }
53 }
54
55 sub CLONE {
56     # clone context under threads
57     Storable::init_perinterp();
58 }
59
60 # Can't Autoload cleanly as this clashes 8.3 with &retrieve
61 sub retrieve_fd { &fd_retrieve }                # Backward compatibility
62
63 # By default restricted hashes are downgraded on earlier perls.
64
65 $Storable::downgrade_restricted = 1;
66 $Storable::accept_future_minor = 1;
67 bootstrap Storable;
68 1;
69 __END__
70 #
71 # Use of Log::Agent is optional. If it hasn't imported these subs then
72 # Autoloader will kindly supply our fallback implementation.
73 #
74
75 sub logcroak {
76     Carp::croak(@_);
77 }
78
79 sub logcarp {
80   Carp::carp(@_);
81 }
82
83 #
84 # Determine whether locking is possible, but only when needed.
85 #
86
87 sub CAN_FLOCK; my $CAN_FLOCK; sub CAN_FLOCK {
88         return $CAN_FLOCK if defined $CAN_FLOCK;
89         require Config; import Config;
90         return $CAN_FLOCK =
91                 $Config{'d_flock'} ||
92                 $Config{'d_fcntl_can_lock'} ||
93                 $Config{'d_lockf'};
94 }
95
96 sub show_file_magic {
97     print <<EOM;
98 #
99 # To recognize the data files of the Perl module Storable,
100 # the following lines need to be added to the local magic(5) file,
101 # usually either /usr/share/misc/magic or /etc/magic.
102 #
103 0       string  perl-store      perl Storable(v0.6) data
104 >4      byte    >0      (net-order %d)
105 >>4     byte    &01     (network-ordered)
106 >>4     byte    =3      (major 1)
107 >>4     byte    =2      (major 1)
108
109 0       string  pst0    perl Storable(v0.7) data
110 >4      byte    >0
111 >>4     byte    &01     (network-ordered)
112 >>4     byte    =5      (major 2)
113 >>4     byte    =4      (major 2)
114 >>5     byte    >0      (minor %d)
115 EOM
116 }
117
118 sub file_magic {
119     my $file = shift;
120     my $fh = new FileHandle;
121     open($fh, "<". $file) || die "Can't open '$file': $!";
122     binmode($fh);
123     defined(sysread($fh, my $buf, 32)) || die "Can't read from '$file': $!";
124     close($fh);
125
126     $file = "./$file" unless $file;  # ensure TRUE value
127
128     return read_magic($buf, $file);
129 }
130
131 sub read_magic {
132     my($buf, $file) = @_;
133     my %info;
134
135     my $buflen = length($buf);
136     my $magic;
137     if ($buf =~ s/^(pst0|perl-store)//) {
138         $magic = $1;
139         $info{file} = $file || 1;
140     }
141     else {
142         return undef if $file;
143         $magic = "";
144     }
145
146     return undef unless length($buf);
147
148     my $net_order;
149     if ($magic eq "perl-store" && ord(substr($buf, 0, 1)) > 1) {
150         $info{version} = -1;
151         $net_order = 0;
152     }
153     else {
154         $net_order = ord(substr($buf, 0, 1, ""));
155         my $major = $net_order >> 1;
156         return undef if $major > 4; # sanity (assuming we never go that high)
157         $info{major} = $major;
158         $net_order &= 0x01;
159         if ($major > 1) {
160             return undef unless length($buf);
161             my $minor = ord(substr($buf, 0, 1, ""));
162             $info{minor} = $minor;
163             $info{version} = "$major.$minor";
164             $info{version_nv} = sprintf "%d.%03d", $major, $minor;
165         }
166         else {
167             $info{version} = $major;
168         }
169     }
170     $info{version_nv} ||= $info{version};
171     $info{netorder} = $net_order;
172
173     unless ($net_order) {
174         return undef unless length($buf);
175         my $len = ord(substr($buf, 0, 1, ""));
176         return undef unless length($buf) >= $len;
177         return undef unless $len == 4 || $len == 8;  # sanity
178         $info{byteorder} = substr($buf, 0, $len, "");
179         $info{intsize} = ord(substr($buf, 0, 1, ""));
180         $info{longsize} = ord(substr($buf, 0, 1, ""));
181         $info{ptrsize} = ord(substr($buf, 0, 1, ""));
182         if ($info{version_nv} >= 2.002) {
183             return undef unless length($buf);
184             $info{nvsize} = ord(substr($buf, 0, 1, ""));
185         }
186     }
187     $info{hdrsize} = $buflen - length($buf);
188
189     return \%info;
190 }
191
192 sub BIN_VERSION_NV {
193     sprintf "%d.%03d", BIN_MAJOR(), BIN_MINOR();
194 }
195
196 sub BIN_WRITE_VERSION_NV {
197     sprintf "%d.%03d", BIN_MAJOR(), BIN_WRITE_MINOR();
198 }
199
200 #
201 # store
202 #
203 # Store target object hierarchy, identified by a reference to its root.
204 # The stored object tree may later be retrieved to memory via retrieve.
205 # Returns undef if an I/O error occurred, in which case the file is
206 # removed.
207 #
208 sub store {
209         return _store(\&pstore, @_, 0);
210 }
211
212 #
213 # nstore
214 #
215 # Same as store, but in network order.
216 #
217 sub nstore {
218         return _store(\&net_pstore, @_, 0);
219 }
220
221 #
222 # lock_store
223 #
224 # Same as store, but flock the file first (advisory locking).
225 #
226 sub lock_store {
227         return _store(\&pstore, @_, 1);
228 }
229
230 #
231 # lock_nstore
232 #
233 # Same as nstore, but flock the file first (advisory locking).
234 #
235 sub lock_nstore {
236         return _store(\&net_pstore, @_, 1);
237 }
238
239 # Internal store to file routine
240 sub _store {
241         my $xsptr = shift;
242         my $self = shift;
243         my ($file, $use_locking) = @_;
244         logcroak "not a reference" unless ref($self);
245         logcroak "wrong argument number" unless @_ == 2;        # No @foo in arglist
246         local *FILE;
247         if ($use_locking) {
248                 open(FILE, ">>$file") || logcroak "can't write into $file: $!";
249                 unless (&CAN_FLOCK) {
250                         logcarp "Storable::lock_store: fcntl/flock emulation broken on $^O";
251                         return undef;
252                 }
253                 flock(FILE, LOCK_EX) ||
254                         logcroak "can't get exclusive lock on $file: $!";
255                 truncate FILE, 0;
256                 # Unlocking will happen when FILE is closed
257         } else {
258                 open(FILE, ">$file") || logcroak "can't create $file: $!";
259         }
260         binmode FILE;                           # Archaic systems...
261         my $da = $@;                            # Don't mess if called from exception handler
262         my $ret;
263         # Call C routine nstore or pstore, depending on network order
264         eval { $ret = &$xsptr(*FILE, $self) };
265         # close will return true on success, so the or short-circuits, the ()
266         # expression is true, and for that case the block will only be entered
267         # if $@ is true (ie eval failed)
268         # if close fails, it returns false, $ret is altered, *that* is (also)
269         # false, so the () expression is false, !() is true, and the block is
270         # entered.
271         if (!(close(FILE) or undef $ret) || $@) {
272                 unlink($file) or warn "Can't unlink $file: $!\n";
273         }
274         logcroak $@ if $@ =~ s/\.?\n$/,/;
275         $@ = $da;
276         return $ret;
277 }
278
279 #
280 # store_fd
281 #
282 # Same as store, but perform on an already opened file descriptor instead.
283 # Returns undef if an I/O error occurred.
284 #
285 sub store_fd {
286         return _store_fd(\&pstore, @_);
287 }
288
289 #
290 # nstore_fd
291 #
292 # Same as store_fd, but in network order.
293 #
294 sub nstore_fd {
295         my ($self, $file) = @_;
296         return _store_fd(\&net_pstore, @_);
297 }
298
299 # Internal store routine on opened file descriptor
300 sub _store_fd {
301         my $xsptr = shift;
302         my $self = shift;
303         my ($file) = @_;
304         logcroak "not a reference" unless ref($self);
305         logcroak "too many arguments" unless @_ == 1;   # No @foo in arglist
306         my $fd = fileno($file);
307         logcroak "not a valid file descriptor" unless defined $fd;
308         my $da = $@;                            # Don't mess if called from exception handler
309         my $ret;
310         # Call C routine nstore or pstore, depending on network order
311         eval { $ret = &$xsptr($file, $self) };
312         logcroak $@ if $@ =~ s/\.?\n$/,/;
313         local $\; print $file '';       # Autoflush the file if wanted
314         $@ = $da;
315         return $ret;
316 }
317
318 #
319 # freeze
320 #
321 # Store oject and its hierarchy in memory and return a scalar
322 # containing the result.
323 #
324 sub freeze {
325         _freeze(\&mstore, @_);
326 }
327
328 #
329 # nfreeze
330 #
331 # Same as freeze but in network order.
332 #
333 sub nfreeze {
334         _freeze(\&net_mstore, @_);
335 }
336
337 # Internal freeze routine
338 sub _freeze {
339         my $xsptr = shift;
340         my $self = shift;
341         logcroak "not a reference" unless ref($self);
342         logcroak "too many arguments" unless @_ == 0;   # No @foo in arglist
343         my $da = $@;                            # Don't mess if called from exception handler
344         my $ret;
345         # Call C routine mstore or net_mstore, depending on network order
346         eval { $ret = &$xsptr($self) };
347         logcroak $@ if $@ =~ s/\.?\n$/,/;
348         $@ = $da;
349         return $ret ? $ret : undef;
350 }
351
352 #
353 # retrieve
354 #
355 # Retrieve object hierarchy from disk, returning a reference to the root
356 # object of that tree.
357 #
358 sub retrieve {
359         _retrieve($_[0], 0);
360 }
361
362 #
363 # lock_retrieve
364 #
365 # Same as retrieve, but with advisory locking.
366 #
367 sub lock_retrieve {
368         _retrieve($_[0], 1);
369 }
370
371 # Internal retrieve routine
372 sub _retrieve {
373         my ($file, $use_locking) = @_;
374         local *FILE;
375         open(FILE, $file) || logcroak "can't open $file: $!";
376         binmode FILE;                                                   # Archaic systems...
377         my $self;
378         my $da = $@;                                                    # Could be from exception handler
379         if ($use_locking) {
380                 unless (&CAN_FLOCK) {
381                         logcarp "Storable::lock_store: fcntl/flock emulation broken on $^O";
382                         return undef;
383                 }
384                 flock(FILE, LOCK_SH) || logcroak "can't get shared lock on $file: $!";
385                 # Unlocking will happen when FILE is closed
386         }
387         eval { $self = pretrieve(*FILE) };              # Call C routine
388         close(FILE);
389         logcroak $@ if $@ =~ s/\.?\n$/,/;
390         $@ = $da;
391         return $self;
392 }
393
394 #
395 # fd_retrieve
396 #
397 # Same as retrieve, but perform from an already opened file descriptor instead.
398 #
399 sub fd_retrieve {
400         my ($file) = @_;
401         my $fd = fileno($file);
402         logcroak "not a valid file descriptor" unless defined $fd;
403         my $self;
404         my $da = $@;                                                    # Could be from exception handler
405         eval { $self = pretrieve($file) };              # Call C routine
406         logcroak $@ if $@ =~ s/\.?\n$/,/;
407         $@ = $da;
408         return $self;
409 }
410
411 #
412 # thaw
413 #
414 # Recreate objects in memory from an existing frozen image created
415 # by freeze.  If the frozen image passed is undef, return undef.
416 #
417 sub thaw {
418         my ($frozen) = @_;
419         return undef unless defined $frozen;
420         my $self;
421         my $da = $@;                                                    # Could be from exception handler
422         eval { $self = mretrieve($frozen) };    # Call C routine
423         logcroak $@ if $@ =~ s/\.?\n$/,/;
424         $@ = $da;
425         return $self;
426 }
427
428 1;
429 __END__
430
431 =head1 NAME
432
433 Storable - persistence for Perl data structures
434
435 =head1 SYNOPSIS
436
437  use Storable;
438  store \%table, 'file';
439  $hashref = retrieve('file');
440
441  use Storable qw(nstore store_fd nstore_fd freeze thaw dclone);
442
443  # Network order
444  nstore \%table, 'file';
445  $hashref = retrieve('file');   # There is NO nretrieve()
446
447  # Storing to and retrieving from an already opened file
448  store_fd \@array, \*STDOUT;
449  nstore_fd \%table, \*STDOUT;
450  $aryref = fd_retrieve(\*SOCKET);
451  $hashref = fd_retrieve(\*SOCKET);
452
453  # Serializing to memory
454  $serialized = freeze \%table;
455  %table_clone = %{ thaw($serialized) };
456
457  # Deep (recursive) cloning
458  $cloneref = dclone($ref);
459
460  # Advisory locking
461  use Storable qw(lock_store lock_nstore lock_retrieve)
462  lock_store \%table, 'file';
463  lock_nstore \%table, 'file';
464  $hashref = lock_retrieve('file');
465
466 =head1 DESCRIPTION
467
468 The Storable package brings persistence to your Perl data structures
469 containing SCALAR, ARRAY, HASH or REF objects, i.e. anything that can be
470 conveniently stored to disk and retrieved at a later time.
471
472 It can be used in the regular procedural way by calling C<store> with
473 a reference to the object to be stored, along with the file name where
474 the image should be written.
475
476 The routine returns C<undef> for I/O problems or other internal error,
477 a true value otherwise. Serious errors are propagated as a C<die> exception.
478
479 To retrieve data stored to disk, use C<retrieve> with a file name.
480 The objects stored into that file are recreated into memory for you,
481 and a I<reference> to the root object is returned. In case an I/O error
482 occurs while reading, C<undef> is returned instead. Other serious
483 errors are propagated via C<die>.
484
485 Since storage is performed recursively, you might want to stuff references
486 to objects that share a lot of common data into a single array or hash
487 table, and then store that object. That way, when you retrieve back the
488 whole thing, the objects will continue to share what they originally shared.
489
490 At the cost of a slight header overhead, you may store to an already
491 opened file descriptor using the C<store_fd> routine, and retrieve
492 from a file via C<fd_retrieve>. Those names aren't imported by default,
493 so you will have to do that explicitly if you need those routines.
494 The file descriptor you supply must be already opened, for read
495 if you're going to retrieve and for write if you wish to store.
496
497         store_fd(\%table, *STDOUT) || die "can't store to stdout\n";
498         $hashref = fd_retrieve(*STDIN);
499
500 You can also store data in network order to allow easy sharing across
501 multiple platforms, or when storing on a socket known to be remotely
502 connected. The routines to call have an initial C<n> prefix for I<network>,
503 as in C<nstore> and C<nstore_fd>. At retrieval time, your data will be
504 correctly restored so you don't have to know whether you're restoring
505 from native or network ordered data.  Double values are stored stringified
506 to ensure portability as well, at the slight risk of loosing some precision
507 in the last decimals.
508
509 When using C<fd_retrieve>, objects are retrieved in sequence, one
510 object (i.e. one recursive tree) per associated C<store_fd>.
511
512 If you're more from the object-oriented camp, you can inherit from
513 Storable and directly store your objects by invoking C<store> as
514 a method. The fact that the root of the to-be-stored tree is a
515 blessed reference (i.e. an object) is special-cased so that the
516 retrieve does not provide a reference to that object but rather the
517 blessed object reference itself. (Otherwise, you'd get a reference
518 to that blessed object).
519
520 =head1 MEMORY STORE
521
522 The Storable engine can also store data into a Perl scalar instead, to
523 later retrieve them. This is mainly used to freeze a complex structure in
524 some safe compact memory place (where it can possibly be sent to another
525 process via some IPC, since freezing the structure also serializes it in
526 effect). Later on, and maybe somewhere else, you can thaw the Perl scalar
527 out and recreate the original complex structure in memory.
528
529 Surprisingly, the routines to be called are named C<freeze> and C<thaw>.
530 If you wish to send out the frozen scalar to another machine, use
531 C<nfreeze> instead to get a portable image.
532
533 Note that freezing an object structure and immediately thawing it
534 actually achieves a deep cloning of that structure:
535
536     dclone(.) = thaw(freeze(.))
537
538 Storable provides you with a C<dclone> interface which does not create
539 that intermediary scalar but instead freezes the structure in some
540 internal memory space and then immediately thaws it out.
541
542 =head1 ADVISORY LOCKING
543
544 The C<lock_store> and C<lock_nstore> routine are equivalent to
545 C<store> and C<nstore>, except that they get an exclusive lock on
546 the file before writing.  Likewise, C<lock_retrieve> does the same
547 as C<retrieve>, but also gets a shared lock on the file before reading.
548
549 As with any advisory locking scheme, the protection only works if you
550 systematically use C<lock_store> and C<lock_retrieve>.  If one side of
551 your application uses C<store> whilst the other uses C<lock_retrieve>,
552 you will get no protection at all.
553
554 The internal advisory locking is implemented using Perl's flock()
555 routine.  If your system does not support any form of flock(), or if
556 you share your files across NFS, you might wish to use other forms
557 of locking by using modules such as LockFile::Simple which lock a
558 file using a filesystem entry, instead of locking the file descriptor.
559
560 =head1 SPEED
561
562 The heart of Storable is written in C for decent speed. Extra low-level
563 optimizations have been made when manipulating perl internals, to
564 sacrifice encapsulation for the benefit of greater speed.
565
566 =head1 CANONICAL REPRESENTATION
567
568 Normally, Storable stores elements of hashes in the order they are
569 stored internally by Perl, i.e. pseudo-randomly.  If you set
570 C<$Storable::canonical> to some C<TRUE> value, Storable will store
571 hashes with the elements sorted by their key.  This allows you to
572 compare data structures by comparing their frozen representations (or
573 even the compressed frozen representations), which can be useful for
574 creating lookup tables for complicated queries.
575
576 Canonical order does not imply network order; those are two orthogonal
577 settings.
578
579 =head1 CODE REFERENCES
580
581 Since Storable version 2.05, CODE references may be serialized with
582 the help of L<B::Deparse>. To enable this feature, set
583 C<$Storable::Deparse> to a true value. To enable deserialization,
584 C<$Storable::Eval> should be set to a true value. Be aware that
585 deserialization is done through C<eval>, which is dangerous if the
586 Storable file contains malicious data. You can set C<$Storable::Eval>
587 to a subroutine reference which would be used instead of C<eval>. See
588 below for an example using a L<Safe> compartment for deserialization
589 of CODE references.
590
591 If C<$Storable::Deparse> and/or C<$Storable::Eval> are set to false
592 values, then the value of C<$Storable::forgive_me> (see below) is
593 respected while serializing and deserializing.
594
595 =head1 FORWARD COMPATIBILITY
596
597 This release of Storable can be used on a newer version of Perl to
598 serialize data which is not supported by earlier Perls.  By default,
599 Storable will attempt to do the right thing, by C<croak()>ing if it
600 encounters data that it cannot deserialize.  However, the defaults
601 can be changed as follows:
602
603 =over 4
604
605 =item utf8 data
606
607 Perl 5.6 added support for Unicode characters with code points > 255,
608 and Perl 5.8 has full support for Unicode characters in hash keys.
609 Perl internally encodes strings with these characters using utf8, and
610 Storable serializes them as utf8.  By default, if an older version of
611 Perl encounters a utf8 value it cannot represent, it will C<croak()>.
612 To change this behaviour so that Storable deserializes utf8 encoded
613 values as the string of bytes (effectively dropping the I<is_utf8> flag)
614 set C<$Storable::drop_utf8> to some C<TRUE> value.  This is a form of
615 data loss, because with C<$drop_utf8> true, it becomes impossible to tell
616 whether the original data was the Unicode string, or a series of bytes
617 that happen to be valid utf8.
618
619 =item restricted hashes
620
621 Perl 5.8 adds support for restricted hashes, which have keys
622 restricted to a given set, and can have values locked to be read only.
623 By default, when Storable encounters a restricted hash on a perl
624 that doesn't support them, it will deserialize it as a normal hash,
625 silently discarding any placeholder keys and leaving the keys and
626 all values unlocked.  To make Storable C<croak()> instead, set
627 C<$Storable::downgrade_restricted> to a C<FALSE> value.  To restore
628 the default set it back to some C<TRUE> value.
629
630 =item files from future versions of Storable
631
632 Earlier versions of Storable would immediately croak if they encountered
633 a file with a higher internal version number than the reading Storable
634 knew about.  Internal version numbers are increased each time new data
635 types (such as restricted hashes) are added to the vocabulary of the file
636 format.  This meant that a newer Storable module had no way of writing a
637 file readable by an older Storable, even if the writer didn't store newer
638 data types.
639
640 This version of Storable will defer croaking until it encounters a data
641 type in the file that it does not recognize.  This means that it will
642 continue to read files generated by newer Storable modules which are careful
643 in what they write out, making it easier to upgrade Storable modules in a
644 mixed environment.
645
646 The old behaviour of immediate croaking can be re-instated by setting
647 C<$Storable::accept_future_minor> to some C<FALSE> value.
648
649 =back
650
651 All these variables have no effect on a newer Perl which supports the
652 relevant feature.
653
654 =head1 ERROR REPORTING
655
656 Storable uses the "exception" paradigm, in that it does not try to workaround
657 failures: if something bad happens, an exception is generated from the
658 caller's perspective (see L<Carp> and C<croak()>).  Use eval {} to trap
659 those exceptions.
660
661 When Storable croaks, it tries to report the error via the C<logcroak()>
662 routine from the C<Log::Agent> package, if it is available.
663
664 Normal errors are reported by having store() or retrieve() return C<undef>.
665 Such errors are usually I/O errors (or truncated stream errors at retrieval).
666
667 =head1 WIZARDS ONLY
668
669 =head2 Hooks
670
671 Any class may define hooks that will be called during the serialization
672 and deserialization process on objects that are instances of that class.
673 Those hooks can redefine the way serialization is performed (and therefore,
674 how the symmetrical deserialization should be conducted).
675
676 Since we said earlier:
677
678     dclone(.) = thaw(freeze(.))
679
680 everything we say about hooks should also hold for deep cloning. However,
681 hooks get to know whether the operation is a mere serialization, or a cloning.
682
683 Therefore, when serializing hooks are involved,
684
685     dclone(.) <> thaw(freeze(.))
686
687 Well, you could keep them in sync, but there's no guarantee it will always
688 hold on classes somebody else wrote.  Besides, there is little to gain in
689 doing so: a serializing hook could keep only one attribute of an object,
690 which is probably not what should happen during a deep cloning of that
691 same object.
692
693 Here is the hooking interface:
694
695 =over 4
696
697 =item C<STORABLE_freeze> I<obj>, I<cloning>
698
699 The serializing hook, called on the object during serialization.  It can be
700 inherited, or defined in the class itself, like any other method.
701
702 Arguments: I<obj> is the object to serialize, I<cloning> is a flag indicating
703 whether we're in a dclone() or a regular serialization via store() or freeze().
704
705 Returned value: A LIST C<($serialized, $ref1, $ref2, ...)> where $serialized
706 is the serialized form to be used, and the optional $ref1, $ref2, etc... are
707 extra references that you wish to let the Storable engine serialize.
708
709 At deserialization time, you will be given back the same LIST, but all the
710 extra references will be pointing into the deserialized structure.
711
712 The B<first time> the hook is hit in a serialization flow, you may have it
713 return an empty list.  That will signal the Storable engine to further
714 discard that hook for this class and to therefore revert to the default
715 serialization of the underlying Perl data.  The hook will again be normally
716 processed in the next serialization.
717
718 Unless you know better, serializing hook should always say:
719
720     sub STORABLE_freeze {
721         my ($self, $cloning) = @_;
722         return if $cloning;         # Regular default serialization
723         ....
724     }
725
726 in order to keep reasonable dclone() semantics.
727
728 =item C<STORABLE_thaw> I<obj>, I<cloning>, I<serialized>, ...
729
730 The deserializing hook called on the object during deserialization.
731 But wait: if we're deserializing, there's no object yet... right?
732
733 Wrong: the Storable engine creates an empty one for you.  If you know Eiffel,
734 you can view C<STORABLE_thaw> as an alternate creation routine.
735
736 This means the hook can be inherited like any other method, and that
737 I<obj> is your blessed reference for this particular instance.
738
739 The other arguments should look familiar if you know C<STORABLE_freeze>:
740 I<cloning> is true when we're part of a deep clone operation, I<serialized>
741 is the serialized string you returned to the engine in C<STORABLE_freeze>,
742 and there may be an optional list of references, in the same order you gave
743 them at serialization time, pointing to the deserialized objects (which
744 have been processed courtesy of the Storable engine).
745
746 When the Storable engine does not find any C<STORABLE_thaw> hook routine,
747 it tries to load the class by requiring the package dynamically (using
748 the blessed package name), and then re-attempts the lookup.  If at that
749 time the hook cannot be located, the engine croaks.  Note that this mechanism
750 will fail if you define several classes in the same file, but L<perlmod>
751 warned you.
752
753 It is up to you to use this information to populate I<obj> the way you want.
754
755 Returned value: none.
756
757 =item C<STORABLE_attach> I<class>, I<cloning>, I<serialized>
758
759 While C<STORABLE_freeze> and C<STORABLE_thaw> are useful for classes where
760 each instance is independent, this mechanism has difficulty (or is
761 incompatible) with objects that exist as common process-level or
762 system-level resources, such as singleton objects, database pools, caches
763 or memoized objects.
764
765 The alternative C<STORABLE_attach> method provides a solution for these
766 shared objects. Instead of C<STORABLE_freeze> --E<gt> C<STORABLE_thaw>,
767 you implement C<STORABLE_freeze> --E<gt> C<STORABLE_attach> instead.
768
769 Arguments: I<class> is the class we are attaching to, I<cloning> is a flag
770 indicating whether we're in a dclone() or a regular de-serialization via
771 thaw(), and I<serialized> is the stored string for the resource object.
772
773 Because these resource objects are considered to be owned by the entire
774 process/system, and not the "property" of whatever is being serialized,
775 no references underneath the object should be included in the serialized
776 string. Thus, in any class that implements C<STORABLE_attach>, the
777 C<STORABLE_freeze> method cannot return any references, and C<Storable>
778 will throw an error if C<STORABLE_freeze> tries to return references.
779
780 All information required to "attach" back to the shared resource object
781 B<must> be contained B<only> in the C<STORABLE_freeze> return string.
782 Otherwise, C<STORABLE_freeze> behaves as normal for C<STORABLE_attach>
783 classes.
784
785 Because C<STORABLE_attach> is passed the class (rather than an object),
786 it also returns the object directly, rather than modifying the passed
787 object.
788
789 Returned value: object of type C<class>
790
791 =back
792
793 =head2 Predicates
794
795 Predicates are not exportable.  They must be called by explicitly prefixing
796 them with the Storable package name.
797
798 =over 4
799
800 =item C<Storable::last_op_in_netorder>
801
802 The C<Storable::last_op_in_netorder()> predicate will tell you whether
803 network order was used in the last store or retrieve operation.  If you
804 don't know how to use this, just forget about it.
805
806 =item C<Storable::is_storing>
807
808 Returns true if within a store operation (via STORABLE_freeze hook).
809
810 =item C<Storable::is_retrieving>
811
812 Returns true if within a retrieve operation (via STORABLE_thaw hook).
813
814 =back
815
816 =head2 Recursion
817
818 With hooks comes the ability to recurse back to the Storable engine.
819 Indeed, hooks are regular Perl code, and Storable is convenient when
820 it comes to serializing and deserializing things, so why not use it
821 to handle the serialization string?
822
823 There are a few things you need to know, however:
824
825 =over 4
826
827 =item *
828
829 You can create endless loops if the things you serialize via freeze()
830 (for instance) point back to the object we're trying to serialize in
831 the hook.
832
833 =item *
834
835 Shared references among objects will not stay shared: if we're serializing
836 the list of object [A, C] where both object A and C refer to the SAME object
837 B, and if there is a serializing hook in A that says freeze(B), then when
838 deserializing, we'll get [A', C'] where A' refers to B', but C' refers to D,
839 a deep clone of B'.  The topology was not preserved.
840
841 =back
842
843 That's why C<STORABLE_freeze> lets you provide a list of references
844 to serialize.  The engine guarantees that those will be serialized in the
845 same context as the other objects, and therefore that shared objects will
846 stay shared.
847
848 In the above [A, C] example, the C<STORABLE_freeze> hook could return:
849
850         ("something", $self->{B})
851
852 and the B part would be serialized by the engine.  In C<STORABLE_thaw>, you
853 would get back the reference to the B' object, deserialized for you.
854
855 Therefore, recursion should normally be avoided, but is nonetheless supported.
856
857 =head2 Deep Cloning
858
859 There is a Clone module available on CPAN which implements deep cloning
860 natively, i.e. without freezing to memory and thawing the result.  It is
861 aimed to replace Storable's dclone() some day.  However, it does not currently
862 support Storable hooks to redefine the way deep cloning is performed.
863
864 =head1 Storable magic
865
866 Yes, there's a lot of that :-) But more precisely, in UNIX systems
867 there's a utility called C<file>, which recognizes data files based on
868 their contents (usually their first few bytes).  For this to work,
869 a certain file called F<magic> needs to taught about the I<signature>
870 of the data.  Where that configuration file lives depends on the UNIX
871 flavour; often it's something like F</usr/share/misc/magic> or
872 F</etc/magic>.  Your system administrator needs to do the updating of
873 the F<magic> file.  The necessary signature information is output to
874 STDOUT by invoking Storable::show_file_magic().  Note that the GNU
875 implementation of the C<file> utility, version 3.38 or later,
876 is expected to contain support for recognising Storable files
877 out-of-the-box, in addition to other kinds of Perl files.
878
879 You can also use the following functions to extract the file header
880 information from Storable images:
881
882 =over
883
884 =item $info = Storable::file_magic( $filename )
885
886 If the given file is a Storable image return a hash describing it.  If
887 the file is readable, but not a Storable image return C<undef>.  If
888 the file does not exist or is unreadable then croak.
889
890 The hash returned has the following elements:
891
892 =over
893
894 =item C<version>
895
896 This returns the file format version.  It is a string like "2.7".
897
898 Note that this version number is not the same as the version number of
899 the Storable module itself.  For instance Storable v0.7 create files
900 in format v2.0 and Storable v2.15 create files in format v2.7.  The
901 file format version number only increment when additional features
902 that would confuse older versions of the module are added.
903
904 Files older than v2.0 will have the one of the version numbers "-1",
905 "0" or "1".  No minor number was used at that time.
906
907 =item C<version_nv>
908
909 This returns the file format version as number.  It is a string like
910 "2.007".  This value is suitable for numeric comparisons.
911
912 The constant function C<Storable::BIN_VERSION_NV> returns a comparable
913 number that represent the highest file version number that this
914 version of Storable fully support (but see discussion of
915 C<$Storable::accept_future_minor> above).  The constant
916 C<Storable::BIN_WRITE_VERSION_NV> function returns what file version
917 is written and might be less than C<Storable::BIN_VERSION_NV> in some
918 configuations.
919
920 =item C<major>, C<minor>
921
922 This also returns the file format version.  If the version is "2.7"
923 then major would be 2 and minor would be 7.  The minor element is
924 missing for when major is less than 2.
925
926 =item C<hdrsize>
927
928 The is the number of bytes that the Storable header occupies.
929
930 =item C<netorder>
931
932 This is TRUE if the image store data in network order.  This means
933 that it was created with nstore() or similar.
934
935 =item C<byteorder>
936
937 This is only present when C<netorder> is FALSE.  It is the
938 $Config{byteorder} string of the perl that created this image.  It is
939 a string like "1234" (32 bit little endian) or "87654321" (64 bit big
940 endian).  This must match the current perl for the image to be
941 readable by Storable.
942
943 =item C<intsize>, C<longsize>, C<ptrsize>, C<nvsize>
944
945 These are only present when C<netorder> is FALSE. These are the sizes of
946 various C datatypes of the perl that created this image.  These must
947 match the current perl for the image to be readable by Storable.
948
949 The C<nvsize> element is only present for file format v2.2 and
950 higher.
951
952 =item C<file>
953
954 The name of the file.
955
956 =back
957
958 =item $info = Storable::read_magic( $buffer )
959
960 =item $info = Storable::read_magic( $buffer, $must_be_file )
961
962 The $buffer should be a Storable image or the first few bytes of it.
963 If $buffer starts with a Storable header, then a hash describing the
964 image is returned, otherwise C<undef> is returned.
965
966 The hash has the same structure as the one returned by
967 Storable::file_magic().  The C<file> element is true if the image is a
968 file image.
969
970 If the $must_be_file argument is provided and is TRUE, then return
971 C<undef> unless the image looks like it belongs to a file dump.
972
973 The maximum size of a Storable header is currently 21 bytes.  If the
974 provided $buffer is only the first part of a Storable image it should
975 at least be this long to ensure that read_magic() will recognize it as
976 such.
977
978 =back
979
980 =head1 EXAMPLES
981
982 Here are some code samples showing a possible usage of Storable:
983
984         use Storable qw(store retrieve freeze thaw dclone);
985
986         %color = ('Blue' => 0.1, 'Red' => 0.8, 'Black' => 0, 'White' => 1);
987
988         store(\%color, 'mycolors') or die "Can't store %a in mycolors!\n";
989
990         $colref = retrieve('mycolors');
991         die "Unable to retrieve from mycolors!\n" unless defined $colref;
992         printf "Blue is still %lf\n", $colref->{'Blue'};
993
994         $colref2 = dclone(\%color);
995
996         $str = freeze(\%color);
997         printf "Serialization of %%color is %d bytes long.\n", length($str);
998         $colref3 = thaw($str);
999
1000 which prints (on my machine):
1001
1002         Blue is still 0.100000
1003         Serialization of %color is 102 bytes long.
1004
1005 Serialization of CODE references and deserialization in a safe
1006 compartment:
1007
1008 =for example begin
1009
1010         use Storable qw(freeze thaw);
1011         use Safe;
1012         use strict;
1013         my $safe = new Safe;
1014         # because of opcodes used in "use strict":
1015         $safe->permit(qw(:default require));
1016         local $Storable::Deparse = 1;
1017         local $Storable::Eval = sub { $safe->reval($_[0]) };
1018         my $serialized = freeze(sub { 42 });
1019         my $code = thaw($serialized);
1020         $code->() == 42;
1021
1022 =for example end
1023
1024 =for example_testing
1025         is( $code->(), 42 );
1026
1027 =head1 WARNING
1028
1029 If you're using references as keys within your hash tables, you're bound
1030 to be disappointed when retrieving your data. Indeed, Perl stringifies
1031 references used as hash table keys. If you later wish to access the
1032 items via another reference stringification (i.e. using the same
1033 reference that was used for the key originally to record the value into
1034 the hash table), it will work because both references stringify to the
1035 same string.
1036
1037 It won't work across a sequence of C<store> and C<retrieve> operations,
1038 however, because the addresses in the retrieved objects, which are
1039 part of the stringified references, will probably differ from the
1040 original addresses. The topology of your structure is preserved,
1041 but not hidden semantics like those.
1042
1043 On platforms where it matters, be sure to call C<binmode()> on the
1044 descriptors that you pass to Storable functions.
1045
1046 Storing data canonically that contains large hashes can be
1047 significantly slower than storing the same data normally, as
1048 temporary arrays to hold the keys for each hash have to be allocated,
1049 populated, sorted and freed.  Some tests have shown a halving of the
1050 speed of storing -- the exact penalty will depend on the complexity of
1051 your data.  There is no slowdown on retrieval.
1052
1053 =head1 BUGS
1054
1055 You can't store GLOB, FORMLINE, REGEXP, etc.... If you can define semantics
1056 for those operations, feel free to enhance Storable so that it can
1057 deal with them.
1058
1059 The store functions will C<croak> if they run into such references
1060 unless you set C<$Storable::forgive_me> to some C<TRUE> value. In that
1061 case, the fatal message is turned in a warning and some
1062 meaningless string is stored instead.
1063
1064 Setting C<$Storable::canonical> may not yield frozen strings that
1065 compare equal due to possible stringification of numbers. When the
1066 string version of a scalar exists, it is the form stored; therefore,
1067 if you happen to use your numbers as strings between two freezing
1068 operations on the same data structures, you will get different
1069 results.
1070
1071 When storing doubles in network order, their value is stored as text.
1072 However, you should also not expect non-numeric floating-point values
1073 such as infinity and "not a number" to pass successfully through a
1074 nstore()/retrieve() pair.
1075
1076 As Storable neither knows nor cares about character sets (although it
1077 does know that characters may be more than eight bits wide), any difference
1078 in the interpretation of character codes between a host and a target
1079 system is your problem.  In particular, if host and target use different
1080 code points to represent the characters used in the text representation
1081 of floating-point numbers, you will not be able be able to exchange
1082 floating-point data, even with nstore().
1083
1084 C<Storable::drop_utf8> is a blunt tool.  There is no facility either to
1085 return B<all> strings as utf8 sequences, or to attempt to convert utf8
1086 data back to 8 bit and C<croak()> if the conversion fails.
1087
1088 Prior to Storable 2.01, no distinction was made between signed and
1089 unsigned integers on storing.  By default Storable prefers to store a
1090 scalars string representation (if it has one) so this would only cause
1091 problems when storing large unsigned integers that had never been converted
1092 to string or floating point.  In other words values that had been generated
1093 by integer operations such as logic ops and then not used in any string or
1094 arithmetic context before storing.
1095
1096 =head2 64 bit data in perl 5.6.0 and 5.6.1
1097
1098 This section only applies to you if you have existing data written out
1099 by Storable 2.02 or earlier on perl 5.6.0 or 5.6.1 on Unix or Linux which
1100 has been configured with 64 bit integer support (not the default)
1101 If you got a precompiled perl, rather than running Configure to build
1102 your own perl from source, then it almost certainly does not affect you,
1103 and you can stop reading now (unless you're curious). If you're using perl
1104 on Windows it does not affect you.
1105
1106 Storable writes a file header which contains the sizes of various C
1107 language types for the C compiler that built Storable (when not writing in
1108 network order), and will refuse to load files written by a Storable not
1109 on the same (or compatible) architecture.  This check and a check on
1110 machine byteorder is needed because the size of various fields in the file
1111 are given by the sizes of the C language types, and so files written on
1112 different architectures are incompatible.  This is done for increased speed.
1113 (When writing in network order, all fields are written out as standard
1114 lengths, which allows full interworking, but takes longer to read and write)
1115
1116 Perl 5.6.x introduced the ability to optional configure the perl interpreter
1117 to use C's C<long long> type to allow scalars to store 64 bit integers on 32
1118 bit systems.  However, due to the way the Perl configuration system
1119 generated the C configuration files on non-Windows platforms, and the way
1120 Storable generates its header, nothing in the Storable file header reflected
1121 whether the perl writing was using 32 or 64 bit integers, despite the fact
1122 that Storable was storing some data differently in the file.  Hence Storable
1123 running on perl with 64 bit integers will read the header from a file
1124 written by a 32 bit perl, not realise that the data is actually in a subtly
1125 incompatible format, and then go horribly wrong (possibly crashing) if it
1126 encountered a stored integer.  This is a design failure.
1127
1128 Storable has now been changed to write out and read in a file header with
1129 information about the size of integers.  It's impossible to detect whether
1130 an old file being read in was written with 32 or 64 bit integers (they have
1131 the same header) so it's impossible to automatically switch to a correct
1132 backwards compatibility mode.  Hence this Storable defaults to the new,
1133 correct behaviour.
1134
1135 What this means is that if you have data written by Storable 1.x running
1136 on perl 5.6.0 or 5.6.1 configured with 64 bit integers on Unix or Linux
1137 then by default this Storable will refuse to read it, giving the error
1138 I<Byte order is not compatible>.  If you have such data then you you
1139 should set C<$Storable::interwork_56_64bit> to a true value to make this
1140 Storable read and write files with the old header.  You should also
1141 migrate your data, or any older perl you are communicating with, to this
1142 current version of Storable.
1143
1144 If you don't have data written with specific configuration of perl described
1145 above, then you do not and should not do anything.  Don't set the flag -
1146 not only will Storable on an identically configured perl refuse to load them,
1147 but Storable a differently configured perl will load them believing them
1148 to be correct for it, and then may well fail or crash part way through
1149 reading them.
1150
1151 =head1 CREDITS
1152
1153 Thank you to (in chronological order):
1154
1155         Jarkko Hietaniemi <jhi@iki.fi>
1156         Ulrich Pfeifer <pfeifer@charly.informatik.uni-dortmund.de>
1157         Benjamin A. Holzman <bah@ecnvantage.com>
1158         Andrew Ford <A.Ford@ford-mason.co.uk>
1159         Gisle Aas <gisle@aas.no>
1160         Jeff Gresham <gresham_jeffrey@jpmorgan.com>
1161         Murray Nesbitt <murray@activestate.com>
1162         Marc Lehmann <pcg@opengroup.org>
1163         Justin Banks <justinb@wamnet.com>
1164         Jarkko Hietaniemi <jhi@iki.fi> (AGAIN, as perl 5.7.0 Pumpkin!)
1165         Salvador Ortiz Garcia <sog@msg.com.mx>
1166         Dominic Dunlop <domo@computer.org>
1167         Erik Haugan <erik@solbors.no>
1168
1169 for their bug reports, suggestions and contributions.
1170
1171 Benjamin Holzman contributed the tied variable support, Andrew Ford
1172 contributed the canonical order for hashes, and Gisle Aas fixed
1173 a few misunderstandings of mine regarding the perl internals,
1174 and optimized the emission of "tags" in the output streams by
1175 simply counting the objects instead of tagging them (leading to
1176 a binary incompatibility for the Storable image starting at version
1177 0.6--older images are, of course, still properly understood).
1178 Murray Nesbitt made Storable thread-safe.  Marc Lehmann added overloading
1179 and references to tied items support.
1180
1181 =head1 AUTHOR
1182
1183 Storable was written by Raphael Manfredi F<E<lt>Raphael_Manfredi@pobox.comE<gt>>
1184 Maintenance is now done by the perl5-porters F<E<lt>perl5-porters@perl.orgE<gt>>
1185
1186 Please e-mail us with problems, bug fixes, comments and complaints,
1187 although if you have compliments you should send them to Raphael.
1188 Please don't e-mail Raphael with problems, as he no longer works on
1189 Storable, and your message will be delayed while he forwards it to us.
1190
1191 =head1 SEE ALSO
1192
1193 L<Clone>.
1194
1195 =cut