regen/opcode.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Regenerate (overwriting only if changed):
   4 #
   5 #    opcode.h
   6 #    opnames.h
   7 #    pp.sym
   8 #
   9 # from information stored in the DATA section of this file, plus the
  10 # values hardcoded into this script in @raw_alias.
  11 #
  12 # Accepts the standard regen_lib -q and -v args.
  13 #
  14 # This script is normally invoked from regen.pl.
  15
  16 use strict;
  17
  18 BEGIN {
  19     # Get function prototypes
  20     require 'regen/regen_lib.pl';
  21 }
  22
  23 my $opcode_new = 'opcode.h-new';
  24 my $opname_new = 'opnames.h-new';
  25 my $oc = safer_open($opcode_new);
  26 my $on = safer_open($opname_new);
  27 select $oc;
  28
  29 # Read data.
  30
  31 my %seen;
  32 my (@ops, %desc, %check, %ckname, %flags, %args, %opnum);
  33
  34 while (<DATA>) {
  35     chop;
  36     next unless $_;
  37     next if /^#/;
  38     my ($key, $desc, $check, $flags, $args) = split(/\t+/, $_, 5);
  39     $args = '' unless defined $args;
  40
  41     warn qq[Description "$desc" duplicates $seen{$desc}\n] if $seen{$desc};
  42     die qq[Opcode "$key" duplicates $seen{$key}\n] if $seen{$key};
  43     $seen{$desc} = qq[description of opcode "$key"];
  44     $seen{$key} = qq[opcode "$key"];
  45
  46     push(@ops, $key);
  47     $opnum{$key} = $#ops;
  48     $desc{$key} = $desc;
  49     $check{$key} = $check;
  50     $ckname{$check}++;
  51     $flags{$key} = $flags;
  52     $args{$key} = $args;
  53 }
  54
  55 # Set up aliases
  56
  57 my %alias;
  58
  59 # Format is "this function" => "does these op names"
  60 my @raw_alias = (
  61                  Perl_do_kv => [qw( keys values )],
  62                  Perl_unimplemented_op => [qw(padany mapstart custom)],
  63                  # All the ops with a body of { return NORMAL; }
  64                  Perl_pp_null => [qw(scalar regcmaybe lineseq scope)],
  65
  66                  Perl_pp_goto => ['dump'],
  67                  Perl_pp_require => ['dofile'],
  68                  Perl_pp_untie => ['dbmclose'],
  69                  Perl_pp_sysread => [qw(read recv)],
  70                  Perl_pp_sysseek => ['seek'],
  71                  Perl_pp_ioctl => ['fcntl'],
  72                  Perl_pp_ssockopt => ['gsockopt'],
  73                  Perl_pp_getpeername => ['getsockname'],
  74                  Perl_pp_stat => ['lstat'],
  75                  Perl_pp_ftrowned => [qw(fteowned ftzero ftsock ftchr ftblk
  76                                          ftfile ftdir ftpipe ftsuid ftsgid
  77                                          ftsvtx)],
  78                  Perl_pp_fttext => ['ftbinary'],
  79                  Perl_pp_gmtime => ['localtime'],
  80                  Perl_pp_semget => [qw(shmget msgget)],
  81                  Perl_pp_semctl => [qw(shmctl msgctl)],
  82                  Perl_pp_ghostent => [qw(ghbyname ghbyaddr)],
  83                  Perl_pp_gnetent => [qw(gnbyname gnbyaddr)],
  84                  Perl_pp_gprotoent => [qw(gpbyname gpbynumber)],
  85                  Perl_pp_gservent => [qw(gsbyname gsbyport)],
  86                  Perl_pp_gpwent => [qw(gpwnam gpwuid)],
  87                  Perl_pp_ggrent => [qw(ggrnam ggrgid)],
  88                  Perl_pp_ftis => [qw(ftsize ftmtime ftatime ftctime)],
  89                  Perl_pp_chown => [qw(unlink chmod utime kill)],
  90                  Perl_pp_link => ['symlink'],
  91                  Perl_pp_ftrread => [qw(ftrwrite ftrexec fteread ftewrite
  92                                         fteexec)],
  93                  Perl_pp_shmwrite => [qw(shmread msgsnd msgrcv semop)],
  94                  Perl_pp_send => ['syswrite'],
  95                  Perl_pp_defined => [qw(dor dorassign)],
  96                  Perl_pp_and => ['andassign'],
  97                  Perl_pp_or => ['orassign'],
  98                  Perl_pp_ucfirst => ['lcfirst'],
  99                  Perl_pp_sle => [qw(slt sgt sge)],
 100                  Perl_pp_print => ['say'],
 101                  Perl_pp_index => ['rindex'],
 102                  Perl_pp_oct => ['hex'],
 103                  Perl_pp_shift => ['pop'],
 104                  Perl_pp_sin => [qw(cos exp log sqrt)],
 105                  Perl_pp_bit_or => ['bit_xor'],
 106                  Perl_pp_rv2av => ['rv2hv'],
 107                  Perl_pp_akeys => ['avalues'],
 108                  Perl_pp_rkeys => [qw(rvalues reach)],
 109                 );
 110
 111 while (my ($func, $names) = splice @raw_alias, 0, 2) {
 112     foreach (@$names) {
 113         $alias{$_} = $func;
 114     }
 115 }
 116
 117 # Emit defines.
 118
 119 print <<"END";
 120 /* -*- buffer-read-only: t -*-
 121  *
 122  *    opcode.h
 123  *
 124  *    Copyright (C) 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
 125  *    2001, 2002, 2003, 2004, 2005, 2006, 2007 by Larry Wall and others
 126  *
 127  *    You may distribute under the terms of either the GNU General Public
 128  *    License or the Artistic License, as specified in the README file.
 129  *
 130  * !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
 131  *  This file is built by regen/opcode.pl from its data.  Any changes made
 132  *  here will be lost!
 133  */
 134
 135 #ifndef PERL_GLOBAL_STRUCT_INIT
 136
 137 #define Perl_pp_i_preinc Perl_pp_preinc
 138 #define Perl_pp_i_predec Perl_pp_predec
 139 #define Perl_pp_i_postinc Perl_pp_postinc
 140 #define Perl_pp_i_postdec Perl_pp_postdec
 141
 142 PERL_PPDEF(Perl_unimplemented_op)
 143
 144 END
 145
 146 print $on <<"END";
 147 /* -*- buffer-read-only: t -*-
 148  *
 149  *    opnames.h
 150  *
 151  *    Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
 152  *    2007, 2008 by Larry Wall and others
 153  *
 154  *    You may distribute under the terms of either the GNU General Public
 155  *    License or the Artistic License, as specified in the README file.
 156  *
 157  *
 158  * !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
 159  *  This file is built by regen/opcode.pl from its data.  Any changes made
 160  *  here will be lost!
 161  */
 162
 163 typedef enum opcode {
 164 END
 165
 166 my $i = 0;
 167 for (@ops) {
 168     # print $on "\t", &tab(3,"OP_\U$_,"), "/* ", $i++, " */\n";
 169       print $on "\t", &tab(3,"OP_\U$_"), " = ", $i++, ",\n";
 170 }
 171 print $on "\t", &tab(3,"OP_max"), "\n";
 172 print $on "} opcode;\n";
 173 print $on "\n#define MAXO ", scalar @ops, "\n";
 174 print $on "#define OP_phoney_INPUT_ONLY -1\n";
 175 print $on "#define OP_phoney_OUTPUT_ONLY -2\n\n";
 176
 177 # Emit op names and descriptions.
 178
 179 print <<END;
 180 START_EXTERN_C
 181
 182 #define OP_NAME(o) ((o)->op_type == OP_CUSTOM ? custom_op_name(o) : \\
 183                     PL_op_name[(o)->op_type])
 184 #define OP_DESC(o) ((o)->op_type == OP_CUSTOM ? custom_op_desc(o) : \\
 185                     PL_op_desc[(o)->op_type])
 186
 187 #ifndef DOINIT
 188 EXTCONST char* const PL_op_name[];
 189 #else
 190 EXTCONST char* const PL_op_name[] = {
 191 END
 192
 193 for (@ops) {
 194     print qq(\t"$_",\n);
 195 }
 196
 197 print <<END;
 198 };
 199 #endif
 200
 201 END
 202
 203 print <<END;
 204 #ifndef DOINIT
 205 EXTCONST char* const PL_op_desc[];
 206 #else
 207 EXTCONST char* const PL_op_desc[] = {
 208 END
 209
 210 for (@ops) {
 211     my($safe_desc) = $desc{$_};
 212
 213     # Have to escape double quotes and escape characters.
 214     $safe_desc =~ s/([\\"])/\\$1/g;
 215
 216     print qq(\t"$safe_desc",\n);
 217 }
 218
 219 print <<END;
 220 };
 221 #endif
 222
 223 END_EXTERN_C
 224
 225 #endif /* !PERL_GLOBAL_STRUCT_INIT */
 226 END
 227
 228 # Emit function declarations.
 229
 230 #for (sort keys %ckname) {
 231 #    print "OP *\t", &tab(3,$_),"(pTHX_ OP* o);\n";
 232 #}
 233 #
 234 #print "\n";
 235 #
 236 #for (@ops) {
 237 #    print "OP *\t", &tab(3, "pp_$_"), "(pTHX);\n";
 238 #}
 239
 240 # Emit ppcode switch array.
 241
 242 print <<END;
 243
 244 START_EXTERN_C
 245
 246 #ifdef PERL_GLOBAL_STRUCT_INIT
 247 #  define PERL_PPADDR_INITED
 248 static const Perl_ppaddr_t Gppaddr[]
 249 #else
 250 #  ifndef PERL_GLOBAL_STRUCT
 251 #    define PERL_PPADDR_INITED
 252 EXT Perl_ppaddr_t PL_ppaddr[] /* or perlvars.h */
 253 #  endif
 254 #endif /* PERL_GLOBAL_STRUCT */
 255 #if (defined(DOINIT) && !defined(PERL_GLOBAL_STRUCT)) || defined(PERL_GLOBAL_STRUCT_INIT)
 256 #  define PERL_PPADDR_INITED
 257 = {
 258 END
 259
 260 for (@ops) {
 261     if (my $name = $alias{$_}) {
 262         print "\t$name,\t/* Perl_pp_$_ */\n";
 263     }
 264     else {
 265         print "\tPerl_pp_$_,\n";
 266     }
 267 }
 268
 269 print <<END;
 270 }
 271 #endif
 272 #ifdef PERL_PPADDR_INITED
 273 ;
 274 #endif
 275
 276 END
 277
 278 # Emit check routines.
 279
 280 print <<END;
 281 #ifdef PERL_GLOBAL_STRUCT_INIT
 282 #  define PERL_CHECK_INITED
 283 static const Perl_check_t Gcheck[]
 284 #else
 285 #  ifndef PERL_GLOBAL_STRUCT
 286 #    define PERL_CHECK_INITED
 287 EXT Perl_check_t PL_check[] /* or perlvars.h */
 288 #  endif
 289 #endif
 290 #if (defined(DOINIT) && !defined(PERL_GLOBAL_STRUCT)) || defined(PERL_GLOBAL_STRUCT_INIT)
 291 #  define PERL_CHECK_INITED
 292 = {
 293 END
 294
 295 for (@ops) {
 296     print "\t", &tab(3, "Perl_$check{$_},"), "\t/* $_ */\n";
 297 }
 298
 299 print <<END;
 300 }
 301 #endif
 302 #ifdef PERL_CHECK_INITED
 303 ;
 304 #endif /* #ifdef PERL_CHECK_INITED */
 305
 306 END
 307
 308 # Emit allowed argument types.
 309
 310 my $ARGBITS = 32;
 311
 312 print <<END;
 313 #ifndef PERL_GLOBAL_STRUCT_INIT
 314
 315 #ifndef DOINIT
 316 EXTCONST U32 PL_opargs[];
 317 #else
 318 EXTCONST U32 PL_opargs[] = {
 319 END
 320
 321 my %argnum = (
 322     'S',  1,            # scalar
 323     'L',  2,            # list
 324     'A',  3,            # array value
 325     'H',  4,            # hash value
 326     'C',  5,            # code value
 327     'F',  6,            # file value
 328     'R',  7,            # scalar reference
 329 );
 330
 331 my %opclass = (
 332     '0',  0,            # baseop
 333     '1',  1,            # unop
 334     '2',  2,            # binop
 335     '|',  3,            # logop
 336     '@',  4,            # listop
 337     '/',  5,            # pmop
 338     '$',  6,            # svop_or_padop
 339     '#',  7,            # padop
 340     '"',  8,            # pvop_or_svop
 341     '{',  9,            # loop
 342     ';',  10,           # cop
 343     '%',  11,           # baseop_or_unop
 344     '-',  12,           # filestatop
 345     '}',  13,           # loopexop
 346 );
 347
 348 my %opflags = (
 349     'm' =>   1,         # needs stack mark
 350     'f' =>   2,         # fold constants
 351     's' =>   4,         # always produces scalar
 352     't' =>   8,         # needs target scalar
 353     'T' =>   8 | 16,    # ... which may be lexical
 354     'i' =>   0,         # always produces integer (unused since e7311069)
 355     'I' =>  32,         # has corresponding int op
 356     'd' =>  64,         # danger, unknown side effects
 357     'u' => 128,         # defaults to $_
 358 );
 359
 360 my %OP_IS_SOCKET;
 361 my %OP_IS_FILETEST;
 362 my %OP_IS_FT_ACCESS;
 363 my $OCSHIFT = 8;
 364 my $OASHIFT = 12;
 365
 366 for my $op (@ops) {
 367     my $argsum = 0;
 368     my $flags = $flags{$op};
 369     for my $flag (keys %opflags) {
 370         if ($flags =~ s/$flag//) {
 371             die "Flag collision for '$op' ($flags{$op}, $flag)\n"
 372                 if $argsum & $opflags{$flag};
 373             $argsum |= $opflags{$flag};
 374         }
 375     }
 376     die qq[Opcode '$op' has no class indicator ($flags{$op} => $flags)\n]
 377         unless exists $opclass{$flags};
 378     $argsum |= $opclass{$flags} << $OCSHIFT;
 379     my $argshift = $OASHIFT;
 380     for my $arg (split(' ',$args{$op})) {
 381         if ($arg =~ /^F/) {
 382             # record opnums of these opnames
 383             $OP_IS_SOCKET{$op}   = $opnum{$op} if $arg =~ s/s//;
 384             $OP_IS_FILETEST{$op} = $opnum{$op} if $arg =~ s/-//;
 385             $OP_IS_FT_ACCESS{$op} = $opnum{$op} if $arg =~ s/\+//;
 386         }
 387         my $argnum = ($arg =~ s/\?//) ? 8 : 0;
 388         die "op = $op, arg = $arg\n"
 389             unless exists $argnum{$arg};
 390         $argnum += $argnum{$arg};
 391         die "Argument overflow for '$op'\n"
 392             if $argshift >= $ARGBITS ||
 393                $argnum > ((1 << ($ARGBITS - $argshift)) - 1);
 394         $argsum += $argnum << $argshift;
 395         $argshift += 4;
 396     }
 397     $argsum = sprintf("0x%08x", $argsum);
 398     print "\t", &tab(3, "$argsum,"), "/* $op */\n";
 399 }
 400
 401 print <<END;
 402 };
 403 #endif
 404
 405 #endif /* !PERL_GLOBAL_STRUCT_INIT */
 406
 407 END_EXTERN_C
 408
 409 END
 410
 411 # Emit OP_IS_* macros
 412
 413 print $on <<EO_OP_IS_COMMENT;
 414
 415 /* the OP_IS_(SOCKET|FILETEST) macros are optimized to a simple range
 416     check because all the member OPs are contiguous in opcode.pl
 417     <DATA> table.  opcode.pl verifies the range contiguity.  */
 418
 419 EO_OP_IS_COMMENT
 420
 421 gen_op_is_macro( \%OP_IS_SOCKET, 'OP_IS_SOCKET');
 422 gen_op_is_macro( \%OP_IS_FILETEST, 'OP_IS_FILETEST');
 423 gen_op_is_macro( \%OP_IS_FT_ACCESS, 'OP_IS_FILETEST_ACCESS');
 424
 425 sub gen_op_is_macro {
 426     my ($op_is, $macname) = @_;
 427     if (keys %$op_is) {
 428
 429         # get opnames whose numbers are lowest and highest
 430         my ($first, @rest) = sort {
 431             $op_is->{$a} <=> $op_is->{$b}
 432         } keys %$op_is;
 433
 434         my $last = pop @rest;   # @rest slurped, get its last
 435         die "Invalid range of ops: $first .. $last\n" unless $last;
 436
 437         print $on "#define $macname(op) \\\n\t(";
 438
 439         # verify that op-ct matches 1st..last range (and fencepost)
 440         # (we know there are no dups)
 441         if ( $op_is->{$last} - $op_is->{$first} == scalar @rest + 1) {
 442
 443             # contiguous ops -> optimized version
 444             print $on "(op) >= OP_" . uc($first) . " && (op) <= OP_" . uc($last);
 445             print $on ")\n\n";
 446         }
 447         else {
 448             print $on join(" || \\\n\t ",
 449                           map { "(op) == OP_" . uc() } sort keys %$op_is);
 450             print $on ")\n\n";
 451         }
 452     }
 453 }
 454
 455 print $oc "/* ex: set ro: */\n";
 456 print $on "/* ex: set ro: */\n";
 457
 458 safer_close($oc);
 459 safer_close($on);
 460
 461 rename_if_different $opcode_new, 'opcode.h';
 462 rename_if_different $opname_new, 'opnames.h';
 463
 464 my $pp_sym_new  = 'pp.sym-new';
 465 my $ppsym = safer_open($pp_sym_new);
 466
 467 print $ppsym <<"END";
 468 # -*- buffer-read-only: t -*-
 469 #
 470 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
 471 #   This file is built by regen/opcode.pl from its data.  Any changes made
 472 #   here will be lost!
 473 #
 474
 475 END
 476
 477
 478 for (sort keys %ckname) {
 479     print $ppsym "Perl_$_\n";
 480 #OP *\t", &tab(3,$_),"(OP* o);\n";
 481 }
 482
 483 for (@ops) {
 484     next if /^i_(pre|post)(inc|dec)$/;
 485     next if /^custom$/;
 486     print $ppsym "Perl_pp_$_\n";
 487 }
 488 print $ppsym "\n# ex: set ro:\n";
 489
 490 safer_close($ppsym);
 491
 492 rename_if_different $pp_sym_new, 'pp.sym';
 493
 494 END {
 495   foreach ('opcode.h', 'opnames.h', 'pp.sym') {
 496     1 while unlink "$_-old";
 497   }
 498 }
 499
 500 ###########################################################################
 501 sub tab {
 502     my ($l, $t) = @_;
 503     $t .= "\t" x ($l - (length($t) + 1) / 8);
 504     $t;
 505 }
 506 ###########################################################################
 507
 508 # Some comments about 'T' opcode classifier:
 509
 510 # Safe to set if the ppcode uses:
 511 #       tryAMAGICbin, tryAMAGICun, SETn, SETi, SETu, PUSHn, PUSHTARG, SETTARG,
 512 #       SETs(TARG), XPUSHn, XPUSHu,
 513
 514 # Unsafe to set if the ppcode uses dTARG or [X]RETPUSH[YES|NO|UNDEF]
 515
 516 # lt and friends do SETs (including ncmp, but not scmp)
 517
 518 # Additional mode of failure: the opcode can modify TARG before it "used"
 519 # all the arguments (or may call an external function which does the same).
 520 # If the target coincides with one of the arguments ==> kaboom.
 521
 522 # pp.c  pos substr each not OK (RETPUSHUNDEF)
 523 #       substr vec also not OK due to LV to target (are they???)
 524 #       ref not OK (RETPUSHNO)
 525 #       trans not OK (dTARG; TARG = sv_newmortal();)
 526 #       ucfirst etc not OK: TMP arg processed inplace
 527 #       quotemeta not OK (unsafe when TARG == arg)
 528 #       each repeat not OK too due to list context
 529 #       pack split - unknown whether they are safe
 530 #       sprintf: is calling do_sprintf(TARG,...) which can act on TARG
 531 #         before other args are processed.
 532
 533 #       Suspicious wrt "additional mode of failure" (and only it):
 534 #       schop, chop, postinc/dec, bit_and etc, negate, complement.
 535
 536 #       Also suspicious: 4-arg substr, sprintf, uc/lc (POK_only), reverse, pack.
 537
 538 #       substr/vec: doing TAINT_off()???
 539
 540 # pp_hot.c
 541 #       readline - unknown whether it is safe
 542 #       match subst not OK (dTARG)
 543 #       grepwhile not OK (not always setting)
 544 #       join not OK (unsafe when TARG == arg)
 545
 546 #       Suspicious wrt "additional mode of failure": concat (dealt with
 547 #       in ck_sassign()), join (same).
 548
 549 # pp_ctl.c
 550 #       mapwhile flip caller not OK (not always setting)
 551
 552 # pp_sys.c
 553 #       backtick glob warn die not OK (not always setting)
 554 #       warn not OK (RETPUSHYES)
 555 #       open fileno getc sysread syswrite ioctl accept shutdown
 556 #        ftsize(etc) readlink telldir fork alarm getlogin not OK (RETPUSHUNDEF)
 557 #       umask select not OK (XPUSHs(&PL_sv_undef);)
 558 #       fileno getc sysread syswrite tell not OK (meth("FILENO" "GETC"))
 559 #       sselect shm* sem* msg* syscall - unknown whether they are safe
 560 #       gmtime not OK (list context)
 561
 562 #       Suspicious wrt "additional mode of failure": warn, die, select.
 563
 564 __END__
 565
 566 # New ops always go at the end
 567 # The restriction on having custom as the last op has been removed
 568
 569 # A recapitulation of the format of this file:
 570 # The file consists of five columns: the name of the op, an English
 571 # description, the name of the "check" routine used to optimize this
 572 # operation, some flags, and a description of the operands.
 573
 574 # The flags consist of options followed by a mandatory op class signifier
 575
 576 # The classes are:
 577 # baseop      - 0            unop     - 1            binop      - 2
 578 # logop       - |            listop   - @            pmop       - /
 579 # padop/svop  - $            padop    - # (unused)   loop       - {
 580 # baseop/unop - %            loopexop - }            filestatop - -
 581 # pvop/svop   - "            cop      - ;
 582
 583 # Other options are:
 584 #   needs stack mark                    - m
 585 #   needs constant folding              - f
 586 #   produces a scalar                   - s
 587 #   produces an integer                 - i
 588 #   needs a target                      - t
 589 #   target can be in a pad              - T
 590 #   has a corresponding integer version - I
 591 #   has side effects                    - d
 592 #   uses $_ if no argument given        - u
 593
 594 # Values for the operands are:
 595 # scalar      - S            list     - L            array     - A
 596 # hash        - H            sub (CV) - C            file      - F
 597 # socket      - Fs           filetest - F-           filetest_access - F-+
 598
 599 # reference - R
 600 # "?" denotes an optional operand.
 601
 602 # Nothing.
 603
 604 null            null operation          ck_null         0
 605 stub            stub                    ck_null         0
 606 scalar          scalar                  ck_fun          s%      S
 607
 608 # Pushy stuff.
 609
 610 pushmark        pushmark                ck_null         s0
 611 wantarray       wantarray               ck_null         is0
 612
 613 const           constant item           ck_svconst      s$
 614
 615 gvsv            scalar variable         ck_null         ds$
 616 gv              glob value              ck_null         ds$
 617 gelem           glob elem               ck_null         d2      S S
 618 padsv           private variable        ck_null         ds0
 619 padav           private array           ck_null         d0
 620 padhv           private hash            ck_null         d0
 621 padany          private value           ck_null         d0
 622
 623 pushre          push regexp             ck_null         d/
 624
 625 # References and stuff.
 626
 627 rv2gv           ref-to-glob cast        ck_rvconst      ds1
 628 rv2sv           scalar dereference      ck_rvconst      ds1
 629 av2arylen       array length            ck_null         is1
 630 rv2cv           subroutine dereference  ck_rvconst      d1
 631 anoncode        anonymous subroutine    ck_anoncode     $
 632 prototype       subroutine prototype    ck_null         s%      S
 633 refgen          reference constructor   ck_spair        m1      L
 634 srefgen         single ref constructor  ck_null         fs1     S
 635 ref             reference-type operator ck_fun          stu%    S?
 636 bless           bless                   ck_fun          s@      S S?
 637
 638 # Pushy I/O.
 639
 640 backtick        quoted execution (``, qx)       ck_open         tu%     S?
 641 # glob defaults its first arg to $_
 642 glob            glob                    ck_glob         t@      S?
 643 readline        <HANDLE>                ck_readline     t%      F?
 644 rcatline        append I/O operator     ck_null         t$
 645
 646 # Bindable operators.
 647
 648 regcmaybe       regexp internal guard   ck_fun          s1      S
 649 regcreset       regexp internal reset   ck_fun          s1      S
 650 regcomp         regexp compilation      ck_null         s|      S
 651 match           pattern match (m//)     ck_match        d/
 652 qr              pattern quote (qr//)    ck_match        s/
 653 subst           substitution (s///)     ck_match        dis/    S
 654 substcont       substitution iterator   ck_null         dis|
 655 trans           transliteration (tr///) ck_match        is"     S
 656
 657 # Lvalue operators.
 658 # sassign is special-cased for op class
 659
 660 sassign         scalar assignment       ck_sassign      s0
 661 aassign         list assignment         ck_null         t2      L L
 662
 663 chop            chop                    ck_spair        mts%    L
 664 schop           scalar chop             ck_null         stu%    S?
 665 chomp           chomp                   ck_spair        mTs%    L
 666 schomp          scalar chomp            ck_null         sTu%    S?
 667 defined         defined operator        ck_defined      isu%    S?
 668 undef           undef operator          ck_lfun         s%      S?
 669 study           study                   ck_fun          su%     S?
 670 pos             match position          ck_lfun         stu%    S?
 671
 672 preinc          preincrement (++)               ck_lfun         dIs1    S
 673 i_preinc        integer preincrement (++)       ck_lfun         dis1    S
 674 predec          predecrement (--)               ck_lfun         dIs1    S
 675 i_predec        integer predecrement (--)       ck_lfun         dis1    S
 676 postinc         postincrement (++)              ck_lfun         dIst1   S
 677 i_postinc       integer postincrement (++)      ck_lfun         disT1   S
 678 postdec         postdecrement (--)              ck_lfun         dIst1   S
 679 i_postdec       integer postdecrement (--)      ck_lfun         disT1   S
 680
 681 # Ordinary operators.
 682
 683 pow             exponentiation (**)     ck_null         fsT2    S S
 684
 685 multiply        multiplication (*)      ck_null         IfsT2   S S
 686 i_multiply      integer multiplication (*)      ck_null         ifsT2   S S
 687 divide          division (/)            ck_null         IfsT2   S S
 688 i_divide        integer division (/)    ck_null         ifsT2   S S
 689 modulo          modulus (%)             ck_null         IifsT2  S S
 690 i_modulo        integer modulus (%)     ck_null         ifsT2   S S
 691 repeat          repeat (x)              ck_repeat       mt2     L S
 692
 693 add             addition (+)            ck_null         IfsT2   S S
 694 i_add           integer addition (+)    ck_null         ifsT2   S S
 695 subtract        subtraction (-)         ck_null         IfsT2   S S
 696 i_subtract      integer subtraction (-) ck_null         ifsT2   S S
 697 concat          concatenation (.) or string     ck_concat       fsT2    S S
 698 stringify       string                  ck_fun          fsT@    S
 699
 700 left_shift      left bitshift (<<)      ck_bitop        fsT2    S S
 701 right_shift     right bitshift (>>)     ck_bitop        fsT2    S S
 702
 703 lt              numeric lt (<)          ck_null         Iifs2   S S
 704 i_lt            integer lt (<)          ck_null         ifs2    S S
 705 gt              numeric gt (>)          ck_null         Iifs2   S S
 706 i_gt            integer gt (>)          ck_null         ifs2    S S
 707 le              numeric le (<=)         ck_null         Iifs2   S S
 708 i_le            integer le (<=)         ck_null         ifs2    S S
 709 ge              numeric ge (>=)         ck_null         Iifs2   S S
 710 i_ge            integer ge (>=)         ck_null         ifs2    S S
 711 eq              numeric eq (==)         ck_null         Iifs2   S S
 712 i_eq            integer eq (==)         ck_null         ifs2    S S
 713 ne              numeric ne (!=)         ck_null         Iifs2   S S
 714 i_ne            integer ne (!=)         ck_null         ifs2    S S
 715 ncmp            numeric comparison (<=>)        ck_null         Iifst2  S S
 716 i_ncmp          integer comparison (<=>)        ck_null         ifst2   S S
 717
 718 slt             string lt               ck_null         ifs2    S S
 719 sgt             string gt               ck_null         ifs2    S S
 720 sle             string le               ck_null         ifs2    S S
 721 sge             string ge               ck_null         ifs2    S S
 722 seq             string eq               ck_null         ifs2    S S
 723 sne             string ne               ck_null         ifs2    S S
 724 scmp            string comparison (cmp) ck_null         ifst2   S S
 725
 726 bit_and         bitwise and (&)         ck_bitop        fst2    S S
 727 bit_xor         bitwise xor (^)         ck_bitop        fst2    S S
 728 bit_or          bitwise or (|)          ck_bitop        fst2    S S
 729
 730 negate          negation (-)            ck_null         Ifst1   S
 731 i_negate        integer negation (-)    ck_null         ifsT1   S
 732 not             not                     ck_null         ifs1    S
 733 complement      1's complement (~)      ck_bitop        fst1    S
 734
 735 smartmatch      smart match             ck_smartmatch   s2
 736
 737 # High falutin' math.
 738
 739 atan2           atan2                   ck_fun          fsT@    S S
 740 sin             sin                     ck_fun          fsTu%   S?
 741 cos             cos                     ck_fun          fsTu%   S?
 742 rand            rand                    ck_fun          sT%     S?
 743 srand           srand                   ck_fun          sT%     S?
 744 exp             exp                     ck_fun          fsTu%   S?
 745 log             log                     ck_fun          fsTu%   S?
 746 sqrt            sqrt                    ck_fun          fsTu%   S?
 747
 748 # Lowbrow math.
 749
 750 int             int                     ck_fun          fsTu%   S?
 751 hex             hex                     ck_fun          fsTu%   S?
 752 oct             oct                     ck_fun          fsTu%   S?
 753 abs             abs                     ck_fun          fsTu%   S?
 754
 755 # String stuff.
 756
 757 length          length                  ck_fun          ifsTu%  S?
 758 substr          substr                  ck_substr       st@     S S S? S?
 759 vec             vec                     ck_fun          ist@    S S S
 760
 761 index           index                   ck_index        isT@    S S S?
 762 rindex          rindex                  ck_index        isT@    S S S?
 763
 764 sprintf         sprintf                 ck_fun          fmst@   S L
 765 formline        formline                ck_fun          ms@     S L
 766 ord             ord                     ck_fun          ifsTu%  S?
 767 chr             chr                     ck_fun          fsTu%   S?
 768 crypt           crypt                   ck_fun          fsT@    S S
 769 ucfirst         ucfirst                 ck_fun          fstu%   S?
 770 lcfirst         lcfirst                 ck_fun          fstu%   S?
 771 uc              uc                      ck_fun          fstu%   S?
 772 lc              lc                      ck_fun          fstu%   S?
 773 quotemeta       quotemeta               ck_fun          fstu%   S?
 774
 775 # Arrays.
 776
 777 rv2av           array dereference       ck_rvconst      dt1
 778 aelemfast       constant array element  ck_null         s$      A S
 779 aelem           array element           ck_null         s2      A S
 780 aslice          array slice             ck_null         m@      A L
 781
 782 aeach           each on array           ck_each         %       A
 783 akeys           keys on array           ck_each         t%      A
 784 avalues         values on array         ck_each         t%      A
 785
 786 # Hashes.
 787
 788 each            each                    ck_each         %       H
 789 values          values                  ck_each         t%      H
 790 keys            keys                    ck_each         t%      H
 791 delete          delete                  ck_delete       %       S
 792 exists          exists                  ck_exists       is%     S
 793 rv2hv           hash dereference        ck_rvconst      dt1
 794 helem           hash element            ck_null         s2      H S
 795 hslice          hash slice              ck_null         m@      H L
 796 boolkeys        boolkeys                ck_fun          %       H
 797
 798 # Explosives and implosives.
 799
 800 unpack          unpack                  ck_unpack       @       S S?
 801 pack            pack                    ck_fun          mst@    S L
 802 split           split                   ck_split        t@      S S S
 803 join            join or string          ck_join         mst@    S L
 804
 805 # List operators.
 806
 807 list            list                    ck_null         m@      L
 808 lslice          list slice              ck_null         2       H L L
 809 anonlist        anonymous list ([])     ck_fun          ms@     L
 810 anonhash        anonymous hash ({})     ck_fun          ms@     L
 811
 812 splice          splice                  ck_push         m@      A S? S? L
 813 push            push                    ck_push         imsT@   A L
 814 pop             pop                     ck_shift        s%      A?
 815 shift           shift                   ck_shift        s%      A?
 816 unshift         unshift                 ck_push         imsT@   A L
 817 sort            sort                    ck_sort         dm@     C? L
 818 reverse         reverse                 ck_fun          mt@     L
 819
 820 grepstart       grep                    ck_grep         dm@     C L
 821 grepwhile       grep iterator           ck_null         dt|
 822
 823 mapstart        map                     ck_grep         dm@     C L
 824 mapwhile        map iterator            ck_null         dt|
 825
 826 # Range stuff.
 827
 828 range           flipflop                ck_null         |       S S
 829 flip            range (or flip)         ck_null         1       S S
 830 flop            range (or flop)         ck_null         1
 831
 832 # Control.
 833
 834 and             logical and (&&)                ck_null         |
 835 or              logical or (||)                 ck_null         |
 836 xor             logical xor                     ck_null         fs2     S S
 837 dor             defined or (//)                 ck_null         |
 838 cond_expr       conditional expression          ck_null         d|
 839 andassign       logical and assignment (&&=)    ck_null         s|
 840 orassign        logical or assignment (||=)     ck_null         s|
 841 dorassign       defined or assignment (//=)     ck_null         s|
 842
 843 method          method lookup           ck_method       d1
 844 entersub        subroutine entry        ck_subr         dmt1    L
 845 leavesub        subroutine exit         ck_null         1
 846 leavesublv      lvalue subroutine return        ck_null         1
 847 caller          caller                  ck_fun          t%      S?
 848 warn            warn                    ck_fun          imst@   L
 849 die             die                     ck_die          dimst@  L
 850 reset           symbol reset            ck_fun          is%     S?
 851
 852 lineseq         line sequence           ck_null         @
 853 nextstate       next statement          ck_null         s;
 854 dbstate         debug next statement    ck_null         s;
 855 unstack         iteration finalizer     ck_null         s0
 856 enter           block entry             ck_null         0
 857 leave           block exit              ck_null         @
 858 scope           block                   ck_null         @
 859 enteriter       foreach loop entry      ck_null         d{
 860 iter            foreach loop iterator   ck_null         0
 861 enterloop       loop entry              ck_null         d{
 862 leaveloop       loop exit               ck_null         2
 863 return          return                  ck_return       dm@     L
 864 last            last                    ck_null         ds}
 865 next            next                    ck_null         ds}
 866 redo            redo                    ck_null         ds}
 867 dump            dump                    ck_null         ds}
 868 goto            goto                    ck_null         ds}
 869 exit            exit                    ck_exit         ds%     S?
 870 method_named    method with known name  ck_null         d$
 871
 872 entergiven      given()                 ck_null         d|
 873 leavegiven      leave given block       ck_null         1
 874 enterwhen       when()                  ck_null         d|
 875 leavewhen       leave when block        ck_null         1
 876 break           break                   ck_null         0
 877 continue        continue                ck_null         0
 878
 879 # I/O.
 880
 881 open            open                    ck_open         ismt@   F S? L
 882 close           close                   ck_fun          is%     F?
 883 pipe_op         pipe                    ck_fun          is@     F F
 884
 885 fileno          fileno                  ck_fun          ist%    F
 886 umask           umask                   ck_fun          ist%    S?
 887 binmode         binmode                 ck_fun          s@      F S?
 888
 889 tie             tie                     ck_fun          idms@   R S L
 890 untie           untie                   ck_fun          is%     R
 891 tied            tied                    ck_fun          s%      R
 892 dbmopen         dbmopen                 ck_fun          is@     H S S
 893 dbmclose        dbmclose                ck_fun          is%     H
 894
 895 sselect         select system call      ck_select       t@      S S S S
 896 select          select                  ck_select       st@     F?
 897
 898 getc            getc                    ck_eof          st%     F?
 899 read            read                    ck_fun          imst@   F R S S?
 900 enterwrite      write                   ck_fun          dis%    F?
 901 leavewrite      write exit              ck_null         1
 902
 903 prtf            printf                  ck_listiob      ims@    F? L
 904 print           print                   ck_listiob      ims@    F? L
 905 say             say                     ck_listiob      ims@    F? L
 906
 907 sysopen         sysopen                 ck_fun          s@      F S S S?
 908 sysseek         sysseek                 ck_fun          s@      F S S
 909 sysread         sysread                 ck_fun          imst@   F R S S?
 910 syswrite        syswrite                ck_fun          imst@   F S S? S?
 911
 912 eof             eof                     ck_eof          is%     F?
 913 tell            tell                    ck_fun          st%     F?
 914 seek            seek                    ck_fun          s@      F S S
 915 # truncate really behaves as if it had both "S S" and "F S"
 916 truncate        truncate                ck_trunc        is@     S S
 917
 918 fcntl           fcntl                   ck_fun          st@     F S S
 919 ioctl           ioctl                   ck_fun          st@     F S S
 920 flock           flock                   ck_fun          isT@    F S
 921
 922 # Sockets.  OP_IS_SOCKET wants them consecutive (so moved 1st 2)
 923
 924 send            send                    ck_fun          imst@   Fs S S S?
 925 recv            recv                    ck_fun          imst@   Fs R S S
 926
 927 socket          socket                  ck_fun          is@     Fs S S S
 928 sockpair        socketpair              ck_fun          is@     Fs Fs S S S
 929
 930 bind            bind                    ck_fun          is@     Fs S
 931 connect         connect                 ck_fun          is@     Fs S
 932 listen          listen                  ck_fun          is@     Fs S
 933 accept          accept                  ck_fun          ist@    Fs Fs
 934 shutdown        shutdown                ck_fun          ist@    Fs S
 935
 936 gsockopt        getsockopt              ck_fun          is@     Fs S S
 937 ssockopt        setsockopt              ck_fun          is@     Fs S S S
 938
 939 getsockname     getsockname             ck_fun          is%     Fs
 940 getpeername     getpeername             ck_fun          is%     Fs
 941
 942 # Stat calls.  OP_IS_FILETEST wants them consecutive.
 943
 944 lstat           lstat                   ck_ftst         u-      F
 945 stat            stat                    ck_ftst         u-      F
 946 ftrread         -R                      ck_ftst         isu-    F-+
 947 ftrwrite        -W                      ck_ftst         isu-    F-+
 948 ftrexec         -X                      ck_ftst         isu-    F-+
 949 fteread         -r                      ck_ftst         isu-    F-+
 950 ftewrite        -w                      ck_ftst         isu-    F-+
 951 fteexec         -x                      ck_ftst         isu-    F-+
 952 ftis            -e                      ck_ftst         isu-    F-
 953 ftsize          -s                      ck_ftst         istu-   F-
 954 ftmtime         -M                      ck_ftst         stu-    F-
 955 ftatime         -A                      ck_ftst         stu-    F-
 956 ftctime         -C                      ck_ftst         stu-    F-
 957 ftrowned        -O                      ck_ftst         isu-    F-
 958 fteowned        -o                      ck_ftst         isu-    F-
 959 ftzero          -z                      ck_ftst         isu-    F-
 960 ftsock          -S                      ck_ftst         isu-    F-
 961 ftchr           -c                      ck_ftst         isu-    F-
 962 ftblk           -b                      ck_ftst         isu-    F-
 963 ftfile          -f                      ck_ftst         isu-    F-
 964 ftdir           -d                      ck_ftst         isu-    F-
 965 ftpipe          -p                      ck_ftst         isu-    F-
 966 ftsuid          -u                      ck_ftst         isu-    F-
 967 ftsgid          -g                      ck_ftst         isu-    F-
 968 ftsvtx          -k                      ck_ftst         isu-    F-
 969 ftlink          -l                      ck_ftst         isu-    F-
 970 fttty           -t                      ck_ftst         is-     F-
 971 fttext          -T                      ck_ftst         isu-    F-
 972 ftbinary        -B                      ck_ftst         isu-    F-
 973
 974 # File calls.
 975
 976 # chdir really behaves as if it had both "S?" and "F?"
 977 chdir           chdir                   ck_chdir        isT%    S?
 978 chown           chown                   ck_fun          imsT@   L
 979 chroot          chroot                  ck_fun          isTu%   S?
 980 unlink          unlink                  ck_fun          imsTu@  L
 981 chmod           chmod                   ck_fun          imsT@   L
 982 utime           utime                   ck_fun          imsT@   L
 983 rename          rename                  ck_fun          isT@    S S
 984 link            link                    ck_fun          isT@    S S
 985 symlink         symlink                 ck_fun          isT@    S S
 986 readlink        readlink                ck_fun          stu%    S?
 987 mkdir           mkdir                   ck_fun          isTu@   S? S?
 988 rmdir           rmdir                   ck_fun          isTu%   S?
 989
 990 # Directory calls.
 991
 992 open_dir        opendir                 ck_fun          is@     F S
 993 readdir         readdir                 ck_fun          %       F
 994 telldir         telldir                 ck_fun          st%     F
 995 seekdir         seekdir                 ck_fun          s@      F S
 996 rewinddir       rewinddir               ck_fun          s%      F
 997 closedir        closedir                ck_fun          is%     F
 998
 999 # Process control.
1000
1001 fork            fork                    ck_null         ist0
1002 wait            wait                    ck_null         isT0
1003 waitpid         waitpid                 ck_fun          isT@    S S
1004 system          system                  ck_exec         imsT@   S? L
1005 exec            exec                    ck_exec         dimsT@  S? L
1006 kill            kill                    ck_fun          dimsT@  L
1007 getppid         getppid                 ck_null         isT0
1008 getpgrp         getpgrp                 ck_fun          isT%    S?
1009 setpgrp         setpgrp                 ck_fun          isT@    S? S?
1010 getpriority     getpriority             ck_fun          isT@    S S
1011 setpriority     setpriority             ck_fun          isT@    S S S
1012
1013 # Time calls.
1014
1015 # NOTE: MacOS patches the 'i' of time() away later when the interpreter
1016 # is created because in MacOS time() is already returning times > 2**31-1,
1017 # that is, non-integers.
1018
1019 time            time                    ck_null         isT0
1020 tms             times                   ck_null         0
1021 localtime       localtime               ck_fun          t%      S?
1022 gmtime          gmtime                  ck_fun          t%      S?
1023 alarm           alarm                   ck_fun          istu%   S?
1024 sleep           sleep                   ck_fun          isT%    S?
1025
1026 # Shared memory.
1027
1028 shmget          shmget                  ck_fun          imst@   S S S
1029 shmctl          shmctl                  ck_fun          imst@   S S S
1030 shmread         shmread                 ck_fun          imst@   S S S S
1031 shmwrite        shmwrite                ck_fun          imst@   S S S S
1032
1033 # Message passing.
1034
1035 msgget          msgget                  ck_fun          imst@   S S
1036 msgctl          msgctl                  ck_fun          imst@   S S S
1037 msgsnd          msgsnd                  ck_fun          imst@   S S S
1038 msgrcv          msgrcv                  ck_fun          imst@   S S S S S
1039
1040 # Semaphores.
1041
1042 semop           semop                   ck_fun          imst@   S S
1043 semget          semget                  ck_fun          imst@   S S S
1044 semctl          semctl                  ck_fun          imst@   S S S S
1045
1046 # Eval.
1047
1048 require         require                 ck_require      du%     S?
1049 dofile          do "file"               ck_fun          d1      S
1050 hintseval       eval hints              ck_svconst      s$
1051 entereval       eval "string"           ck_eval         d%      S
1052 leaveeval       eval "string" exit      ck_null         1       S
1053 #evalonce       eval constant string    ck_null         d1      S
1054 entertry        eval {block}            ck_eval         d%
1055 leavetry        eval {block} exit       ck_null         @
1056
1057 # Get system info.
1058
1059 ghbyname        gethostbyname           ck_fun          %       S
1060 ghbyaddr        gethostbyaddr           ck_fun          @       S S
1061 ghostent        gethostent              ck_null         0
1062 gnbyname        getnetbyname            ck_fun          %       S
1063 gnbyaddr        getnetbyaddr            ck_fun          @       S S
1064 gnetent         getnetent               ck_null         0
1065 gpbyname        getprotobyname          ck_fun          %       S
1066 gpbynumber      getprotobynumber        ck_fun          @       S
1067 gprotoent       getprotoent             ck_null         0
1068 gsbyname        getservbyname           ck_fun          @       S S
1069 gsbyport        getservbyport           ck_fun          @       S S
1070 gservent        getservent              ck_null         0
1071 shostent        sethostent              ck_fun          is%     S
1072 snetent         setnetent               ck_fun          is%     S
1073 sprotoent       setprotoent             ck_fun          is%     S
1074 sservent        setservent              ck_fun          is%     S
1075 ehostent        endhostent              ck_null         is0
1076 enetent         endnetent               ck_null         is0
1077 eprotoent       endprotoent             ck_null         is0
1078 eservent        endservent              ck_null         is0
1079 gpwnam          getpwnam                ck_fun          %       S
1080 gpwuid          getpwuid                ck_fun          %       S
1081 gpwent          getpwent                ck_null         0
1082 spwent          setpwent                ck_null         is0
1083 epwent          endpwent                ck_null         is0
1084 ggrnam          getgrnam                ck_fun          %       S
1085 ggrgid          getgrgid                ck_fun          %       S
1086 ggrent          getgrent                ck_null         0
1087 sgrent          setgrent                ck_null         is0
1088 egrent          endgrent                ck_null         is0
1089 getlogin        getlogin                ck_null         st0
1090
1091 # Miscellaneous.
1092
1093 syscall         syscall                 ck_fun          imst@   S L
1094
1095 # For multi-threading
1096 lock            lock                    ck_rfun         s%      R
1097
1098 # For state support
1099
1100 once            once                    ck_null         |
1101
1102 custom          unknown custom operator         ck_null         0
1103
1104 # For smart dereference for each/keys/values
1105 reach           each on reference                       ck_each         %       S
1106 rkeys           keys on reference                       ck_each         t%      S
1107 rvalues         values on reference                     ck_each         t%      S