This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Resync with mainline
[perl5.git] / lib / Dumpvalue.pm
1 use 5.005_64;                   # for (defined ref) and $#$v and our
2 package Dumpvalue;
3 use strict;
4 our(%address, $stab, @stab, %stab, %subs);
5
6 # translate control chars to ^X - Randal Schwartz
7 # Modifications to print types by Peter Gordon v1.0
8
9 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
10
11 # Won't dump symbol tables and contents of debugged files by default
12
13 # (IZ) changes for objectification:
14 #   c) quote() renamed to method set_quote();
15 #   d) unctrlSet() renamed to method set_unctrl();
16 #   f) Compiles with `use strict', but in two places no strict refs is needed:
17 #      maybe more problems are waiting...
18
19 my %defaults = (
20                 globPrint             => 0,
21                 printUndef            => 1,
22                 tick                  => "auto",
23                 unctrl                => 'quote',
24                 subdump               => 1,
25                 dumpReused            => 0,
26                 bareStringify         => 1,
27                 hashDepth             => '',
28                 arrayDepth            => '',
29                 dumpDBFiles           => '',
30                 dumpPackages          => '',
31                 quoteHighBit          => '',
32                 usageOnly             => '',
33                 compactDump           => '',
34                 veryCompact           => '',
35                 stopDbSignal          => '',
36                );
37
38 sub new {
39   my $class = shift;
40   my %opt = (%defaults, @_);
41   bless \%opt, $class;
42 }
43
44 sub set {
45   my $self = shift;
46   my %opt = @_;
47   @$self{keys %opt} = values %opt;
48 }
49
50 sub get {
51   my $self = shift;
52   wantarray ? @$self{@_} : $$self{pop @_};
53 }
54
55 sub dumpValue {
56   my $self = shift;
57   die "usage: \$dumper->dumpValue(value)" unless @_ == 1;
58   local %address;
59   local $^W=0;
60   (print "undef\n"), return unless defined $_[0];
61   (print $self->stringify($_[0]), "\n"), return unless ref $_[0];
62   $self->unwrap($_[0],0);
63 }
64
65 sub dumpValues {
66   my $self = shift;
67   local %address;
68   local $^W=0;
69   (print "undef\n"), return unless defined $_[0];
70   $self->unwrap(\@_,0);
71 }
72
73 # This one is good for variable names:
74
75 sub unctrl {
76   local($_) = @_;
77
78   return \$_ if ref \$_ eq "GLOB";
79   s/([\001-\037\177])/'^'.pack('c',ord($1)^64)/eg;
80   $_;
81 }
82
83 sub stringify {
84   my $self = shift;
85   local $_ = shift;
86   my $noticks = shift;
87   my $tick = $self->{tick};
88
89   return 'undef' unless defined $_ or not $self->{printUndef};
90   return $_ . "" if ref \$_ eq 'GLOB';
91   { no strict 'refs';
92     $_ = &{'overload::StrVal'}($_)
93       if $self->{bareStringify} and ref $_
94         and %overload:: and defined &{'overload::StrVal'};
95   }
96
97   if ($tick eq 'auto') {
98     if (/[\000-\011\013-\037\177]/) {
99       $tick = '"';
100     } else {
101       $tick = "'";
102     }
103   }
104   if ($tick eq "'") {
105     s/([\'\\])/\\$1/g;
106   } elsif ($self->{unctrl} eq 'unctrl') {
107     s/([\"\\])/\\$1/g ;
108     s/([\000-\037\177])/'^'.pack('c',ord($1)^64)/eg;
109     s/([\200-\377])/'\\0x'.sprintf('%2X',ord($1))/eg
110       if $self->{quoteHighBit};
111   } elsif ($self->{unctrl} eq 'quote') {
112     s/([\"\\\$\@])/\\$1/g if $tick eq '"';
113     s/\033/\\e/g;
114     s/([\000-\037\177])/'\\c'.chr(ord($1)^64)/eg;
115   }
116   s/([\200-\377])/'\\'.sprintf('%3o',ord($1))/eg if $self->{quoteHighBit};
117   ($noticks || /^\d+(\.\d*)?\Z/)
118     ? $_
119       : $tick . $_ . $tick;
120 }
121
122 sub DumpElem {
123   my ($self, $v) = (shift, shift);
124   my $short = $self->stringify($v, ref $v);
125   my $shortmore = '';
126   if ($self->{veryCompact} && ref $v
127       && (ref $v eq 'ARRAY' and !grep(ref $_, @$v) )) {
128     my $depth = $#$v;
129     ($shortmore, $depth) = (' ...', $self->{arrayDepth} - 1)
130       if $self->{arrayDepth} and $depth >= $self->{arrayDepth};
131     my @a = map $self->stringify($_), @$v[0..$depth];
132     print "0..$#{$v}  @a$shortmore\n";
133   } elsif ($self->{veryCompact} && ref $v
134            && (ref $v eq 'HASH') and !grep(ref $_, values %$v)) {
135     my @a = sort keys %$v;
136     my $depth = $#a;
137     ($shortmore, $depth) = (' ...', $self->{hashDepth} - 1)
138       if $self->{hashDepth} and $depth >= $self->{hashDepth};
139     my @b = map {$self->stringify($_) . " => " . $self->stringify($$v{$_})}
140       @a[0..$depth];
141     local $" = ', ';
142     print "@b$shortmore\n";
143   } else {
144     print "$short\n";
145     $self->unwrap($v,shift);
146   }
147 }
148
149 sub unwrap {
150   my $self = shift;
151   return if $DB::signal and $self->{stopDbSignal};
152   my ($v) = shift ;
153   my ($s) = shift ;             # extra no of spaces
154   my $sp;
155   my (%v,@v,$address,$short,$fileno);
156
157   $sp = " " x $s ;
158   $s += 3 ;
159
160   # Check for reused addresses
161   if (ref $v) {
162     my $val = $v;
163     { no strict 'refs';
164       $val = &{'overload::StrVal'}($v)
165         if %overload:: and defined &{'overload::StrVal'};
166     }
167     ($address) = $val =~ /(0x[0-9a-f]+)\)$/ ;
168     if (!$self->{dumpReused} && defined $address) {
169       $address{$address}++ ;
170       if ( $address{$address} > 1 ) {
171         print "${sp}-> REUSED_ADDRESS\n" ;
172         return ;
173       }
174     }
175   } elsif (ref \$v eq 'GLOB') {
176     $address = "$v" . "";       # To avoid a bug with globs
177     $address{$address}++ ;
178     if ( $address{$address} > 1 ) {
179       print "${sp}*DUMPED_GLOB*\n" ;
180       return ;
181     }
182   }
183
184   if (ref $v eq 'Regexp') {
185     my $re = "$v";
186     $re =~ s,/,\\/,g;
187     print "$sp-> qr/$re/\n";
188     return;
189   }
190
191   if ( UNIVERSAL::isa($v, 'HASH') ) {
192     my @sortKeys = sort keys(%$v) ;
193     my $more;
194     my $tHashDepth = $#sortKeys ;
195     $tHashDepth = $#sortKeys < $self->{hashDepth}-1 ? $#sortKeys : $self->{hashDepth}-1
196       unless $self->{hashDepth} eq '' ;
197     $more = "....\n" if $tHashDepth < $#sortKeys ;
198     my $shortmore = "";
199     $shortmore = ", ..." if $tHashDepth < $#sortKeys ;
200     $#sortKeys = $tHashDepth ;
201     if ($self->{compactDump} && !grep(ref $_, values %{$v})) {
202       $short = $sp;
203       my @keys;
204       for (@sortKeys) {
205         push @keys, $self->stringify($_) . " => " . $self->stringify($v->{$_});
206       }
207       $short .= join ', ', @keys;
208       $short .= $shortmore;
209       (print "$short\n"), return if length $short <= $self->{compactDump};
210     }
211     for my $key (@sortKeys) {
212       return if $DB::signal and $self->{stopDbSignal};
213       my $value = $ {$v}{$key} ;
214       print $sp, $self->stringify($key), " => ";
215       $self->DumpElem($value, $s);
216     }
217     print "$sp  empty hash\n" unless @sortKeys;
218     print "$sp$more" if defined $more ;
219   } elsif ( UNIVERSAL::isa($v, 'ARRAY') ) {
220     my $tArrayDepth = $#{$v} ;
221     my $more ;
222     $tArrayDepth = $#$v < $self->{arrayDepth}-1 ? $#$v : $self->{arrayDepth}-1
223       unless  $self->{arrayDepth} eq '' ;
224     $more = "....\n" if $tArrayDepth < $#{$v} ;
225     my $shortmore = "";
226     $shortmore = " ..." if $tArrayDepth < $#{$v} ;
227     if ($self->{compactDump} && !grep(ref $_, @{$v})) {
228       if ($#$v >= 0) {
229         $short = $sp . "0..$#{$v}  " .
230           join(" ",
231                map {$self->stringify($_)} @{$v}[0..$tArrayDepth])
232             . "$shortmore";
233       } else {
234         $short = $sp . "empty array";
235       }
236       (print "$short\n"), return if length $short <= $self->{compactDump};
237     }
238     for my $num ($[ .. $tArrayDepth) {
239       return if $DB::signal and $self->{stopDbSignal};
240       print "$sp$num  ";
241       $self->DumpElem($v->[$num], $s);
242     }
243     print "$sp  empty array\n" unless @$v;
244     print "$sp$more" if defined $more ;
245   } elsif (  UNIVERSAL::isa($v, 'SCALAR') or ref $v eq 'REF' ) {
246     print "$sp-> ";
247     $self->DumpElem($$v, $s);
248   } elsif ( UNIVERSAL::isa($v, 'CODE') ) {
249     print "$sp-> ";
250     $self->dumpsub(0, $v);
251   } elsif ( UNIVERSAL::isa($v, 'GLOB') ) {
252     print "$sp-> ",$self->stringify($$v,1),"\n";
253     if ($self->{globPrint}) {
254       $s += 3;
255       $self->dumpglob('', $s, "{$$v}", $$v, 1);
256     } elsif (defined ($fileno = fileno($v))) {
257       print( (' ' x ($s+3)) .  "FileHandle({$$v}) => fileno($fileno)\n" );
258     }
259   } elsif (ref \$v eq 'GLOB') {
260     if ($self->{globPrint}) {
261       $self->dumpglob('', $s, "{$v}", $v, 1);
262     } elsif (defined ($fileno = fileno(\$v))) {
263       print( (' ' x $s) .  "FileHandle({$v}) => fileno($fileno)\n" );
264     }
265   }
266 }
267
268 sub matchvar {
269   $_[0] eq $_[1] or
270     ($_[1] =~ /^([!~])(.)([\x00-\xff]*)/) and
271       ($1 eq '!') ^ (eval {($_[2] . "::" . $_[0]) =~ /$2$3/});
272 }
273
274 sub compactDump {
275   my $self = shift;
276   $self->{compactDump} = shift if @_;
277   $self->{compactDump} = 6*80-1 
278     if $self->{compactDump} and $self->{compactDump} < 2;
279   $self->{compactDump};
280 }
281
282 sub veryCompact {
283   my $self = shift;
284   $self->{veryCompact} = shift if @_;
285   $self->compactDump(1) if !$self->{compactDump} and $self->{veryCompact};
286   $self->{veryCompact};
287 }
288
289 sub set_unctrl {
290   my $self = shift;
291   if (@_) {
292     my $in = shift;
293     if ($in eq 'unctrl' or $in eq 'quote') {
294       $self->{unctrl} = $in;
295     } else {
296       print "Unknown value for `unctrl'.\n";
297     }
298   }
299   $self->{unctrl};
300 }
301
302 sub set_quote {
303   my $self = shift;
304   if (@_ and $_[0] eq '"') {
305     $self->{tick} = '"';
306     $self->{unctrl} = 'quote';
307   } elsif (@_ and $_[0] eq 'auto') {
308     $self->{tick} = 'auto';
309     $self->{unctrl} = 'quote';
310   } elsif (@_) {                # Need to set
311     $self->{tick} = "'";
312     $self->{unctrl} = 'unctrl';
313   }
314   $self->{tick};
315 }
316
317 sub dumpglob {
318   my $self = shift;
319   return if $DB::signal and $self->{stopDbSignal};
320   my ($package, $off, $key, $val, $all) = @_;
321   local(*stab) = $val;
322   my $fileno;
323   if (($key !~ /^_</ or $self->{dumpDBFiles}) and defined $stab) {
324     print( (' ' x $off) . "\$", &unctrl($key), " = " );
325     $self->DumpElem($stab, 3+$off);
326   }
327   if (($key !~ /^_</ or $self->{dumpDBFiles}) and @stab) {
328     print( (' ' x $off) . "\@$key = (\n" );
329     $self->unwrap(\@stab,3+$off) ;
330     print( (' ' x $off) .  ")\n" );
331   }
332   if ($key ne "main::" && $key ne "DB::" && %stab
333       && ($self->{dumpPackages} or $key !~ /::$/)
334       && ($key !~ /^_</ or $self->{dumpDBFiles})
335       && !($package eq "Dumpvalue" and $key eq "stab")) {
336     print( (' ' x $off) . "\%$key = (\n" );
337     $self->unwrap(\%stab,3+$off) ;
338     print( (' ' x $off) .  ")\n" );
339   }
340   if (defined ($fileno = fileno(*stab))) {
341     print( (' ' x $off) .  "FileHandle($key) => fileno($fileno)\n" );
342   }
343   if ($all) {
344     if (defined &stab) {
345       $self->dumpsub($off, $key);
346     }
347   }
348 }
349
350 sub CvGV_name {
351   my $self = shift;
352   my $in = shift;
353   return if $self->{skipCvGV};  # Backdoor to avoid problems if XS broken...
354   $in = \&$in;                  # Hard reference...
355   eval {require Devel::Peek; 1} or return;
356   my $gv = Devel::Peek::CvGV($in) or return;
357   *$gv{PACKAGE} . '::' . *$gv{NAME};
358 }
359
360 sub dumpsub {
361   my $self = shift;
362   my ($off,$sub) = @_;
363   my $ini = $sub;
364   my $s;
365   $sub = $1 if $sub =~ /^\{\*(.*)\}$/;
366   my $subref = defined $1 ? \&$sub : \&$ini;
367   my $place = $DB::sub{$sub} || (($s = $subs{"$subref"}) && $DB::sub{$s})
368     || (($s = $self->CvGV_name($subref)) && $DB::sub{$s})
369     || ($self->{subdump} && ($s = $self->findsubs("$subref"))
370         && $DB::sub{$s});
371   $s = $sub unless defined $s;
372   $place = '???' unless defined $place;
373   print( (' ' x $off) .  "&$s in $place\n" );
374 }
375
376 sub findsubs {
377   my $self = shift;
378   return undef unless %DB::sub;
379   my ($addr, $name, $loc);
380   while (($name, $loc) = each %DB::sub) {
381     $addr = \&$name;
382     $subs{"$addr"} = $name;
383   }
384   $self->{subdump} = 0;
385   $subs{ shift() };
386 }
387
388 sub dumpvars {
389   my $self = shift;
390   my ($package,@vars) = @_;
391   local(%address,$^W);
392   my ($key,$val);
393   $package .= "::" unless $package =~ /::$/;
394   *stab = *main::;
395
396   while ($package =~ /(\w+?::)/g) {
397     *stab = $ {stab}{$1};
398   }
399   $self->{TotalStrings} = 0;
400   $self->{Strings} = 0;
401   $self->{CompleteTotal} = 0;
402   while (($key,$val) = each(%stab)) {
403     return if $DB::signal and $self->{stopDbSignal};
404     next if @vars && !grep( matchvar($key, $_), @vars );
405     if ($self->{usageOnly}) {
406       $self->globUsage(\$val, $key)
407         unless $package eq 'Dumpvalue' and $key eq 'stab';
408     } else {
409       $self->dumpglob($package, 0,$key, $val);
410     }
411   }
412   if ($self->{usageOnly}) {
413     print <<EOP;
414 String space: $self->{TotalStrings} bytes in $self->{Strings} strings.
415 EOP
416     $self->{CompleteTotal} += $self->{TotalStrings};
417     print <<EOP;
418 Grand total = $self->{CompleteTotal} bytes (1 level deep) + overhead.
419 EOP
420   }
421 }
422
423 sub scalarUsage {
424   my $self = shift;
425   my $size = length($_[0]);
426   $self->{TotalStrings} += $size;
427   $self->{Strings}++;
428   $size;
429 }
430
431 sub arrayUsage {                # array ref, name
432   my $self = shift;
433   my $size = 0;
434   map {$size += $self->scalarUsage($_)} @{$_[0]};
435   my $len = @{$_[0]};
436   print "\@$_[1] = $len item", ($len > 1 ? "s" : ""), " (data: $size bytes)\n"
437       if defined $_[1];
438   $self->{CompleteTotal} +=  $size;
439   $size;
440 }
441
442 sub hashUsage {                 # hash ref, name
443   my $self = shift;
444   my @keys = keys %{$_[0]};
445   my @values = values %{$_[0]};
446   my $keys = $self->arrayUsage(\@keys);
447   my $values = $self->arrayUsage(\@values);
448   my $len = @keys;
449   my $total = $keys + $values;
450   print "\%$_[1] = $len item", ($len > 1 ? "s" : ""),
451     " (keys: $keys; values: $values; total: $total bytes)\n"
452       if defined $_[1];
453   $total;
454 }
455
456 sub globUsage {                 # glob ref, name
457   my $self = shift;
458   local *stab = *{$_[0]};
459   my $total = 0;
460   $total += $self->scalarUsage($stab) if defined $stab;
461   $total += $self->arrayUsage(\@stab, $_[1]) if @stab;
462   $total += $self->hashUsage(\%stab, $_[1]) 
463     if %stab and $_[1] ne "main::" and $_[1] ne "DB::"; 
464   #and !($package eq "Dumpvalue" and $key eq "stab"));
465   $total;
466 }
467
468 1;
469
470 =head1 NAME
471
472 Dumpvalue - provides screen dump of Perl data.
473
474 =head1 SYNOPSIS
475
476   use Dumpvalue;
477   my $dumper = new Dumpvalue;
478   $dumper->set(globPrint => 1);
479   $dumper->dumpValue(\*::);
480   $dumper->dumpvars('main');
481
482 =head1 DESCRIPTION
483
484 =head2 Creation
485
486 A new dumper is created by a call
487
488   $d = new Dumpvalue(option1 => value1, option2 => value2)
489
490 Recognized options:
491
492 =over
493
494 =item C<arrayDepth>, C<hashDepth>
495
496 Print only first N elements of arrays and hashes.  If false, prints all the
497 elements.
498
499 =item C<compactDump>, C<veryCompact>
500
501 Change style of array and hash dump.  If true, short array
502 may be printed on one line.
503
504 =item C<globPrint>
505
506 Whether to print contents of globs.
507
508 =item C<DumpDBFiles>
509
510 Dump arrays holding contents of debugged files.
511
512 =item C<DumpPackages>
513
514 Dump symbol tables of packages.
515
516 =item C<DumpReused>
517
518 Dump contents of "reused" addresses.
519
520 =item C<tick>, C<HighBit>, C<printUndef>
521
522 Change style of string dump.  Default value of C<tick> is C<auto>, one
523 can enable either double-quotish dump, or single-quotish by setting it
524 to C<"> or C<'>.  By default, characters with high bit set are printed
525 I<as is>.
526
527 =item C<UsageOnly>
528
529 I<very> rudimentally per-package memory usage dump.  If set,
530 C<dumpvars> calculates total size of strings in variables in the package.
531
532 =item unctrl
533
534 Changes the style of printout of strings.  Possible values are
535 C<unctrl> and C<quote>.
536
537 =item subdump
538
539 Whether to try to find the subroutine name given the reference.
540
541 =item bareStringify
542
543 Whether to write the non-overloaded form of the stringify-overloaded objects.
544
545 =item quoteHighBit
546
547 Whether to print chars with high bit set in binary or "as is".
548
549 =item stopDbSignal
550
551 Whether to abort printing if debugger signal flag is raised.
552
553 =back
554
555 Later in the life of the object the methods may be queries with get()
556 method and set() method (which accept multiple arguments).
557
558 =head2 Methods
559
560 =over
561
562 =item dumpValue
563
564   $dumper->dumpValue($value);
565   $dumper->dumpValue([$value1, $value2]);
566
567 =item dumpValues
568
569   $dumper->dumpValues($value1, $value2);
570
571 =item dumpvars
572
573   $dumper->dumpvars('my_package');
574   $dumper->dumpvars('my_package', 'foo', '~bar$', '!......');
575
576 The optional arguments are considered as literal strings unless they
577 start with C<~> or C<!>, in which case they are interpreted as regular
578 expressions (possibly negated).
579
580 The second example prints entries with names C<foo>, and also entries
581 with names which ends on C<bar>, or are shorter than 5 chars.
582
583 =item set_quote
584
585   $d->set_quote('"');
586
587 Sets C<tick> and C<unctrl> options to suitable values for printout with the
588 given quote char.  Possible values are C<auto>, C<'> and C<">.
589
590 =item set_unctrl
591
592   $d->set_unctrl('"');
593
594 Sets C<unctrl> option with checking for an invalid argument.
595 Possible values are C<unctrl> and C<quote>.
596
597 =item compactDump
598
599   $d->compactDump(1);
600
601 Sets C<compactDump> option.  If the value is 1, sets to a reasonable
602 big number.
603
604 =item veryCompact
605
606   $d->veryCompact(1);
607
608 Sets C<compactDump> and C<veryCompact> options simultaneously.
609
610 =item set
611
612   $d->set(option1 => value1, option2 => value2);
613
614 =item get
615
616   @values = $d->get('option1', 'option2');
617
618 =back
619
620 =cut
621