This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
VMS fixage and cleanup
[perl5.git] / ext / Cwd / t / cwd.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6 }
7
8 use Config;
9 use Cwd;
10 use strict;
11 use warnings;
12 use File::Path;
13
14 use Test::More tests => 16;
15
16 my $IsVMS = $^O eq 'VMS';
17
18 # check imports
19 can_ok('main', qw(cwd getcwd fastcwd fastgetcwd));
20 ok( !defined(&chdir),           'chdir() not exported by default' );
21 ok( !defined(&abs_path),        '  nor abs_path()' );
22 ok( !defined(&fast_abs_path),   '  nor fast_abs_path()');
23
24
25 # XXX force Cwd to bootsrap its XSUBs since we have set @INC = "../lib"
26 # XXX and subsequent chdir()s can make them impossible to find
27 eval { fastcwd };
28
29 # Must find an external pwd (or equivalent) command.
30
31 my $pwd_cmd =
32     ($^O eq "MSWin32" || $^O eq "NetWare") ? "cd" : (grep { -x && -f } map { "$_/pwd" }
33                                split m/$Config{path_sep}/, $ENV{PATH})[0];
34
35 $pwd_cmd = 'SHOW DEFAULT' if $IsVMS;
36
37 SKIP: {
38     skip "No native pwd command found to test against", 4 unless $pwd_cmd;
39
40     chomp(my $start = `$pwd_cmd`);
41     # Win32's cd returns native C:\ style
42     $start =~ s,\\,/,g if ($^O eq 'MSWin32' || $^O eq "NetWare");
43     # DCL SHOW DEFAULT has leading spaces
44     $start =~ s/^\s+// if $IsVMS;
45     SKIP: {
46         skip "'$pwd_cmd' failed, nothing to test against", 4 if $?;
47
48         my $cwd        = cwd;
49         my $getcwd     = getcwd;
50         my $fastcwd    = fastcwd;
51         my $fastgetcwd = fastgetcwd;
52         is(cwd(),       $start, 'cwd()');
53         is(getcwd(),    $start, 'getcwd()');
54         is(fastcwd(),   $start, 'fastcwd()');
55         is(fastgetcwd(),$start, 'fastgetcwd()');
56     }
57 }
58
59 my $Top_Test_Dir = '_ptrslt_';
60 my $Test_Dir     = "$Top_Test_Dir/_path_/_to_/_a_/_dir_";
61 my $want = "t/$Test_Dir";
62 if( $IsVMS ) {
63     # translate the unixy path to VMSish
64     $want = uc $want;
65     $want =~ s|/|\.|g;
66     $want .= '\]';
67 }
68
69 mkpath(["$Test_Dir"], 0, 0777);
70 Cwd::chdir "$Test_Dir";
71
72 like(cwd(),        qr|$want$|, 'chdir() + cwd()');
73 like(getcwd(),     qr|$want$|, '        + getcwd()');    
74 like(fastcwd(),    qr|$want$|, '        + fastcwd()');
75 like(fastgetcwd(), qr|$want$|, '        + fastgetcwd()');
76
77 # Cwd::chdir should also update $ENV{PWD}
78 like($ENV{PWD}, qr|$want$|,      'Cwd::chdir() updates $ENV{PWD}');
79 Cwd::chdir "..";
80 print "#$ENV{PWD}\n";
81 Cwd::chdir "..";
82 print "#$ENV{PWD}\n";
83 Cwd::chdir "..";
84 print "#$ENV{PWD}\n";
85 Cwd::chdir "..";
86 print "#$ENV{PWD}\n";
87 Cwd::chdir "..";
88 print "#$ENV{PWD}\n";
89
90 rmtree([$Top_Test_Dir], 0, 0);
91
92 if ($IsVMS) {
93     like($ENV{PWD}, qr|\bT\]$|);
94 }
95 else {
96     like($ENV{PWD}, qr|\bt$|);
97 }
98
99 SKIP: {
100     skip "no symlinks on this platform", 2 unless $Config{d_symlink};
101
102     mkpath([$Test_Dir], 0, 0777);
103     symlink $Test_Dir => "linktest";
104
105     my $abs_path      =  Cwd::abs_path("linktest");
106     my $fast_abs_path =  Cwd::fast_abs_path("linktest");
107     my $want          = "t/$Test_Dir";
108
109     like($abs_path,      qr|$want$|);
110     like($fast_abs_path, qr|$want$|);
111
112     rmtree([$Top_Test_Dir], 0, 0);
113     unlink "linktest";
114 }