lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_04';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     @cmdfhs
 631     $CommandSet
 632     $CreateTTY
 633     $DBGR
 634     @dbline
 635     $dbline
 636     %dbline
 637     $dieLevel
 638     $evalarg
 639     $filename
 640     $frame
 641     $hist
 642     $histfile
 643     $histsize
 644     $ImmediateStop
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $line
 650     $maxtrace
 651     $od
 652     $onetimeDump
 653     $onetimedumpDepth
 654     %option
 655     @options
 656     $osingle
 657     $otrace
 658     $OUT
 659     $packname
 660     $pager
 661     $post
 662     %postponed
 663     $prc
 664     $pre
 665     $pretype
 666     $psh
 667     @RememberOnROptions
 668     $remoteport
 669     @res
 670     $rl
 671     @saved
 672     $signal
 673     $signalLevel
 674     $single
 675     $start
 676     $sub
 677     %sub
 678     $subname
 679     $term
 680     $trace
 681     $usercontext
 682     $warnLevel
 683     $window
 684 );
 685
 686 # Used to save @ARGV and extract any debugger-related flags.
 687 use vars qw(@ARGS);
 688
 689 # Used to prevent multiple entries to diesignal()
 690 # (if for instance diesignal() itself dies)
 691 use vars qw($panic);
 692
 693 # Used to prevent the debugger from running nonstop
 694 # after a restart
 695 use vars qw($second_time);
 696
 697 sub _calc_usercontext {
 698     my ($package) = @_;
 699
 700     # Cancel strict completely for the evaluated code, so the code
 701     # the user evaluates won't be affected by it. (Shlomi Fish)
 702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
 703     . "package $package;";    # this won't let them modify, alas
 704 }
 705
 706 sub eval {
 707
 708     # 'my' would make it visible from user code
 709     #    but so does local! --tchrist
 710     # Remember: this localizes @DB::res, not @main::res.
 711     local @res;
 712     {
 713
 714         # Try to keep the user code from messing  with us. Save these so that
 715         # even if the eval'ed code changes them, we can put them back again.
 716         # Needed because the user could refer directly to the debugger's
 717         # package globals (and any 'my' variables in this containing scope)
 718         # inside the eval(), and we want to try to stay safe.
 719         local $otrace  = $trace;
 720         local $osingle = $single;
 721         local $od      = $^D;
 722
 723         # Untaint the incoming eval() argument.
 724         { ($evalarg) = $evalarg =~ /(.*)/s; }
 725
 726         # $usercontext built in DB::DB near the comment
 727         # "set up the context for DB::eval ..."
 728         # Evaluate and save any results.
 729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 730
 731         # Restore those old values.
 732         $trace  = $otrace;
 733         $single = $osingle;
 734         $^D     = $od;
 735     }
 736
 737     # Save the current value of $@, and preserve it in the debugger's copy
 738     # of the saved precious globals.
 739     my $at = $@;
 740
 741     # Since we're only saving $@, we only have to localize the array element
 742     # that it will be stored in.
 743     local $saved[0];    # Preserve the old value of $@
 744     eval { &DB::save };
 745
 746     # Now see whether we need to report an error back to the user.
 747     if ($at) {
 748         local $\ = '';
 749         print $OUT $at;
 750     }
 751
 752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 753     # are package globals.
 754     elsif ($onetimeDump) {
 755         if ( $onetimeDump eq 'dump' ) {
 756             local $option{dumpDepth} = $onetimedumpDepth
 757               if defined $onetimedumpDepth;
 758             dumpit( $OUT, \@res );
 759         }
 760         elsif ( $onetimeDump eq 'methods' ) {
 761             methods( $res[0] );
 762         }
 763     } ## end elsif ($onetimeDump)
 764     @res;
 765 } ## end sub eval
 766
 767 ############################################## End lexical danger zone
 768
 769 # After this point it is safe to introduce lexicals.
 770 # The code being debugged will be executing in its own context, and
 771 # can't see the inside of the debugger.
 772 #
 773 # However, one should not overdo it: leave as much control from outside as
 774 # possible. If you make something a lexical, it's not going to be addressable
 775 # from outside the debugger even if you know its name.
 776
 777 # This file is automatically included if you do perl -d.
 778 # It's probably not useful to include this yourself.
 779 #
 780 # Before venturing further into these twisty passages, it is
 781 # wise to read the perldebguts man page or risk the ire of dragons.
 782 #
 783 # (It should be noted that perldebguts will tell you a lot about
 784 # the underlying mechanics of how the debugger interfaces into the
 785 # Perl interpreter, but not a lot about the debugger itself. The new
 786 # comments in this code try to address this problem.)
 787
 788 # Note that no subroutine call is possible until &DB::sub is defined
 789 # (for subroutines defined outside of the package DB). In fact the same is
 790 # true if $deep is not defined.
 791
 792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 793
 794 # modified Perl debugger, to be run from Emacs in perldb-mode
 795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 796 # Johan Vromans -- upgrade to 4.0 pl 10
 797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 798 ########################################################################
 799
 800 =head1 DEBUGGER INITIALIZATION
 801
 802 The debugger starts up in phases.
 803
 804 =head2 BASIC SETUP
 805
 806 First, it initializes the environment it wants to run in: turning off
 807 warnings during its own compilation, defining variables which it will need
 808 to avoid warnings later, setting itself up to not exit when the program
 809 terminates, and defaulting to printing return values for the C<r> command.
 810
 811 =cut
 812
 813 # Needed for the statement after exec():
 814 #
 815 # This BEGIN block is simply used to switch off warnings during debugger
 816 # compilation. Probably it would be better practice to fix the warnings,
 817 # but this is how it's done at the moment.
 818
 819 BEGIN {
 820     $ini_warn = $^W;
 821     $^W       = 0;
 822 }    # Switch compilation warnings off until another BEGIN.
 823
 824 local ($^W) = 0;    # Switch run-time warnings off during init.
 825
 826 =head2 THREADS SUPPORT
 827
 828 If we are running under a threaded Perl, we require threads and threads::shared
 829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 830 threaded debugger control.  C<-dt> can also be used to set this.
 831
 832 Each new thread will be announced and the debugger prompt will always inform
 833 you of each new thread created.  It will also indicate the thread id in which
 834 we are currently running within the prompt like this:
 835
 836         [tid] DB<$i>
 837
 838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 839 command prompt.  The prompt will show: C<[0]> when running under threads, but
 840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 841
 842 While running under threads, when you set or delete a breakpoint (etc.), this
 843 will apply to all threads, not just the currently running one.  When you are
 844 in a currently executing thread, you will stay there until it completes.  With
 845 the current implementation it is not currently possible to hop from one thread
 846 to another.
 847
 848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 849
 850 Note that threading support was built into the debugger as of Perl version
 851 C<5.8.6> and debugger version C<1.2.8>.
 852
 853 =cut
 854
 855 BEGIN {
 856   # ensure we can share our non-threaded variables or no-op
 857   if ($ENV{PERL5DB_THREADED}) {
 858         require threads;
 859         require threads::shared;
 860         import threads::shared qw(share);
 861         $DBGR;
 862         share(\$DBGR);
 863         lock($DBGR);
 864         print "Threads support enabled\n";
 865   } else {
 866         *lock  = sub(*) {};
 867         *share = sub(*) {};
 868   }
 869 }
 870
 871 # These variables control the execution of 'dumpvar.pl'.
 872 {
 873     package dumpvar;
 874     use vars qw(
 875     $hashDepth
 876     $arrayDepth
 877     $dumpDBFiles
 878     $dumpPackages
 879     $quoteHighBit
 880     $printUndef
 881     $globPrint
 882     $usageOnly
 883     );
 884 }
 885
 886 # used to control die() reporting in diesignal()
 887 {
 888     package Carp;
 889     use vars qw($CarpLevel);
 890 }
 891
 892 # without threads, $filename is not defined until DB::DB is called
 893 foreach my $k (keys (%INC)) {
 894         share(\$main::{'_<'.$filename}) if defined $filename;
 895 };
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 sub _restore_breakpoints_and_actions {
1383
1384     my @had_breakpoints = get_list("PERLDB_VISITED");
1385
1386     for my $file_idx ( 0 .. $#had_breakpoints ) {
1387         my $filename = $had_breakpoints[$file_idx];
1388         my %pf = get_list("PERLDB_FILE_$file_idx");
1389         $postponed_file{ $filename } = \%pf if %pf;
1390         my @lines = sort {$a <=> $b} keys(%pf);
1391         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1392         for my $line_idx (0 .. $#lines) {
1393             _set_breakpoint_enabled_status(
1394                 $filename,
1395                 $lines[$line_idx],
1396                 ($enabled_statuses[$line_idx] ? 1 : ''),
1397             );
1398         }
1399     }
1400
1401     return;
1402 }
1403
1404 sub _restore_options_after_restart
1405 {
1406     my %options_map = get_list("PERLDB_OPT");
1407
1408     while ( my ( $opt, $val ) = each %options_map ) {
1409         $val =~ s/[\\\']/\\$1/g;
1410         parse_options("$opt'$val'");
1411     }
1412
1413     return;
1414 }
1415
1416 if ( exists $ENV{PERLDB_RESTART} ) {
1417
1418     # We're restarting, so we don't need the flag that says to restart anymore.
1419     delete $ENV{PERLDB_RESTART};
1420
1421     # $restart = 1;
1422     @hist          = get_list('PERLDB_HIST');
1423     %break_on_load = get_list("PERLDB_ON_LOAD");
1424     %postponed     = get_list("PERLDB_POSTPONE");
1425
1426     share(@hist);
1427     share(@truehist);
1428     share(%break_on_load);
1429     share(%postponed);
1430
1431     _restore_breakpoints_and_actions();
1432
1433     # restore options
1434     _restore_options_after_restart();
1435
1436     # restore original @INC
1437     @INC     = get_list("PERLDB_INC");
1438     @ini_INC = @INC;
1439
1440     # return pre/postprompt actions and typeahead buffer
1441     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1442     $pre       = [ get_list("PERLDB_PRE") ];
1443     $post      = [ get_list("PERLDB_POST") ];
1444     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1445 } ## end if (exists $ENV{PERLDB_RESTART...
1446
1447 =head2 SETTING UP THE TERMINAL
1448
1449 Now, we'll decide how the debugger is going to interact with the user.
1450 If there's no TTY, we set the debugger to run non-stop; there's not going
1451 to be anyone there to enter commands.
1452
1453 =cut
1454
1455 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1456 use vars qw($lineinfo $doccmd);
1457
1458 if ($notty) {
1459     $runnonstop = 1;
1460         share($runnonstop);
1461 }
1462
1463 =pod
1464
1465 If there is a TTY, we have to determine who it belongs to before we can
1466 proceed. If this is a slave editor or graphical debugger (denoted by
1467 the first command-line switch being '-emacs'), we shift this off and
1468 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1469
1470 =cut
1471
1472 else {
1473
1474     # Is Perl being run from a slave editor or graphical debugger?
1475     # If so, don't use readline, and set $slave_editor = 1.
1476     $slave_editor =
1477       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1478     $rl = 0, shift(@main::ARGV) if $slave_editor;
1479
1480     #require Term::ReadLine;
1481
1482 =pod
1483
1484 We then determine what the console should be on various systems:
1485
1486 =over 4
1487
1488 =item * Cygwin - We use C<stdin> instead of a separate device.
1489
1490 =cut
1491
1492     if ( $^O eq 'cygwin' ) {
1493
1494         # /dev/tty is binary. use stdin for textmode
1495         undef $console;
1496     }
1497
1498 =item * Unix - use C</dev/tty>.
1499
1500 =cut
1501
1502     elsif ( -e "/dev/tty" ) {
1503         $console = "/dev/tty";
1504     }
1505
1506 =item * Windows or MSDOS - use C<con>.
1507
1508 =cut
1509
1510     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1511         $console = "con";
1512     }
1513
1514 =item * VMS - use C<sys$command>.
1515
1516 =cut
1517
1518     else {
1519
1520         # everything else is ...
1521         $console = "sys\$command";
1522     }
1523
1524 =pod
1525
1526 =back
1527
1528 Several other systems don't use a specific console. We C<undef $console>
1529 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1530 with a slave editor, Epoc).
1531
1532 =cut
1533
1534     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1535
1536         # /dev/tty is binary. use stdin for textmode
1537         $console = undef;
1538     }
1539
1540     if ( $^O eq 'NetWare' ) {
1541
1542         # /dev/tty is binary. use stdin for textmode
1543         $console = undef;
1544     }
1545
1546     # In OS/2, we need to use STDIN to get textmode too, even though
1547     # it pretty much looks like Unix otherwise.
1548     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1549     {    # In OS/2
1550         $console = undef;
1551     }
1552
1553     # EPOC also falls into the 'got to use STDIN' camp.
1554     if ( $^O eq 'epoc' ) {
1555         $console = undef;
1556     }
1557
1558 =pod
1559
1560 If there is a TTY hanging around from a parent, we use that as the console.
1561
1562 =cut
1563
1564     $console = $tty if defined $tty;
1565
1566 =head2 SOCKET HANDLING
1567
1568 The debugger is capable of opening a socket and carrying out a debugging
1569 session over the socket.
1570
1571 If C<RemotePort> was defined in the options, the debugger assumes that it
1572 should try to start a debugging session on that port. It builds the socket
1573 and then tries to connect the input and output filehandles to it.
1574
1575 =cut
1576
1577     # Handle socket stuff.
1578
1579     if ( defined $remoteport ) {
1580
1581         # If RemotePort was defined in the options, connect input and output
1582         # to the socket.
1583         $IN = $OUT = connect_remoteport();
1584     } ## end if (defined $remoteport)
1585
1586 =pod
1587
1588 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1589 this is probably a situation where multiple debuggers are running (for example,
1590 a backticked command that starts up another debugger). We create a new IN and
1591 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1592 and if we can.
1593
1594 =cut
1595
1596     # Non-socket.
1597     else {
1598
1599         # Two debuggers running (probably a system or a backtick that invokes
1600         # the debugger itself under the running one). create a new IN and OUT
1601         # filehandle, and do the necessary mojo to create a new tty if we
1602         # know how, and we can.
1603         create_IN_OUT(4) if $CreateTTY & 4;
1604         if ($console) {
1605
1606             # If we have a console, check to see if there are separate ins and
1607             # outs to open. (They are assumed identical if not.)
1608
1609             my ( $i, $o ) = split /,/, $console;
1610             $o = $i unless defined $o;
1611
1612             # read/write on in, or just read, or read on STDIN.
1613             open( IN,      "+<$i" )
1614               || open( IN, "<$i" )
1615               || open( IN, "<&STDIN" );
1616
1617             # read/write/create/clobber out, or write/create/clobber out,
1618             # or merge with STDERR, or merge with STDOUT.
1619                  open( OUT, "+>$o" )
1620               || open( OUT, ">$o" )
1621               || open( OUT, ">&STDERR" )
1622               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1623
1624         } ## end if ($console)
1625         elsif ( not defined $console ) {
1626
1627             # No console. Open STDIN.
1628             open( IN, "<&STDIN" );
1629
1630             # merge with STDERR, or with STDOUT.
1631             open( OUT,      ">&STDERR" )
1632               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1633             $console = 'STDIN/OUT';
1634         } ## end elsif (not defined $console)
1635
1636         # Keep copies of the filehandles so that when the pager runs, it
1637         # can close standard input without clobbering ours.
1638         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1639     } ## end elsif (from if(defined $remoteport))
1640
1641     # Unbuffer DB::OUT. We need to see responses right away.
1642     $OUT->autoflush(1);
1643
1644     # Line info goes to debugger output unless pointed elsewhere.
1645     # Pointing elsewhere makes it possible for slave editors to
1646     # keep track of file and position. We have both a filehandle
1647     # and a I/O description to keep track of.
1648     $LINEINFO = $OUT     unless defined $LINEINFO;
1649     $lineinfo = $console unless defined $lineinfo;
1650         # share($LINEINFO); # <- unable to share globs
1651         share($lineinfo);   #
1652
1653 =pod
1654
1655 To finish initialization, we show the debugger greeting,
1656 and then call the C<afterinit()> subroutine if there is one.
1657
1658 =cut
1659
1660     # Show the debugger greeting.
1661     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1662     unless ($runnonstop) {
1663         local $\ = '';
1664         local $, = '';
1665         if ( $term_pid eq '-1' ) {
1666             print $OUT "\nDaughter DB session started...\n";
1667         }
1668         else {
1669             print $OUT "\nLoading DB routines from $header\n";
1670             print $OUT (
1671                 "Editor support ",
1672                 $slave_editor ? "enabled" : "available", ".\n"
1673             );
1674             print $OUT
1675 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1676         } ## end else [ if ($term_pid eq '-1')
1677     } ## end unless ($runnonstop)
1678 } ## end else [ if ($notty)
1679
1680 # XXX This looks like a bug to me.
1681 # Why copy to @ARGS and then futz with @args?
1682 @ARGS = @ARGV;
1683 # for (@args) {
1684     # Make sure backslashes before single quotes are stripped out, and
1685     # keep args unless they are numeric (XXX why?)
1686     # s/\'/\\\'/g;                      # removed while not justified understandably
1687     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1688 # }
1689
1690 # If there was an afterinit() sub defined, call it. It will get
1691 # executed in our scope, so it can fiddle with debugger globals.
1692 if ( defined &afterinit ) {    # May be defined in $rcfile
1693     &afterinit();
1694 }
1695
1696 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1697 use vars qw($I_m_init);
1698
1699 $I_m_init = 1;
1700
1701 ############################################################ Subroutines
1702
1703 =head1 SUBROUTINES
1704
1705 =head2 DB
1706
1707 This gigantic subroutine is the heart of the debugger. Called before every
1708 statement, its job is to determine if a breakpoint has been reached, and
1709 stop if so; read commands from the user, parse them, and execute
1710 them, and then send execution off to the next statement.
1711
1712 Note that the order in which the commands are processed is very important;
1713 some commands earlier in the loop will actually alter the C<$cmd> variable
1714 to create other commands to be executed later. This is all highly I<optimized>
1715 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1716 see what's happening in any given command.
1717
1718 =cut
1719
1720 use vars qw(
1721     $action
1722     %alias
1723     $cmd
1724     $doret
1725     $fall_off_end
1726     $file
1727     $filename_ini
1728     $finished
1729     %had_breakpoints
1730     $incr
1731     $laststep
1732     $level
1733     $max
1734     @old_watch
1735     $package
1736     $rc
1737     $sh
1738     @stack
1739     $stack_depth
1740     @to_watch
1741     $try
1742     $end
1743 );
1744
1745 sub DB {
1746
1747     # lock the debugger and get the thread id for the prompt
1748         lock($DBGR);
1749         my $tid;
1750         my $position;
1751         my ($prefix, $after, $infix);
1752         my $pat;
1753
1754         if ($ENV{PERL5DB_THREADED}) {
1755                 $tid = eval { "[".threads->tid."]" };
1756         }
1757
1758     # Check for whether we should be running continuously or not.
1759     # _After_ the perl program is compiled, $single is set to 1:
1760     if ( $single and not $second_time++ ) {
1761
1762         # Options say run non-stop. Run until we get an interrupt.
1763         if ($runnonstop) {    # Disable until signal
1764                 # If there's any call stack in place, turn off single
1765                 # stepping into subs throughout the stack.
1766             for my $i (0 .. $stack_depth) {
1767                 $stack[ $i ] &= ~1;
1768             }
1769
1770             # And we are now no longer in single-step mode.
1771             $single = 0;
1772
1773             # If we simply returned at this point, we wouldn't get
1774             # the trace info. Fall on through.
1775             # return;
1776         } ## end if ($runnonstop)
1777
1778         elsif ($ImmediateStop) {
1779
1780             # We are supposed to stop here; XXX probably a break.
1781             $ImmediateStop = 0;    # We've processed it; turn it off
1782             $signal        = 1;    # Simulate an interrupt to force
1783                                    # us into the command loop
1784         }
1785     } ## end if ($single and not $second_time...
1786
1787     # If we're in single-step mode, or an interrupt (real or fake)
1788     # has occurred, turn off non-stop mode.
1789     $runnonstop = 0 if $single or $signal;
1790
1791     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1792     # The code being debugged may have altered them.
1793     &save;
1794
1795     # Since DB::DB gets called after every line, we can use caller() to
1796     # figure out where we last were executing. Sneaky, eh? This works because
1797     # caller is returning all the extra information when called from the
1798     # debugger.
1799     local ( $package, $filename, $line ) = caller;
1800     $filename_ini = $filename;
1801
1802     # set up the context for DB::eval, so it can properly execute
1803     # code on behalf of the user. We add the package in so that the
1804     # code is eval'ed in the proper package (not in the debugger!).
1805     local $usercontext = _calc_usercontext($package);
1806
1807     # Create an alias to the active file magical array to simplify
1808     # the code here.
1809     local (*dbline) = $main::{ '_<' . $filename };
1810
1811     # Last line in the program.
1812     $max = $#dbline;
1813
1814     # if we have something here, see if we should break.
1815     {
1816         # $stop is lexical and local to this block - $action on the other hand
1817         # is global.
1818         my $stop;
1819
1820         if ( $dbline{$line}
1821             && _is_breakpoint_enabled($filename, $line)
1822             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1823         {
1824
1825             # Stop if the stop criterion says to just stop.
1826             if ( $stop eq '1' ) {
1827                 $signal |= 1;
1828             }
1829
1830             # It's a conditional stop; eval it in the user's context and
1831             # see if we should stop. If so, remove the one-time sigil.
1832             elsif ($stop) {
1833                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1834                 &eval;
1835                 # If the breakpoint is temporary, then delete its enabled status.
1836                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1837                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1838                 }
1839             }
1840         } ## end if ($dbline{$line} && ...
1841     }
1842
1843     # Preserve the current stop-or-not, and see if any of the W
1844     # (watch expressions) has changed.
1845     my $was_signal = $signal;
1846
1847     # If we have any watch expressions ...
1848     if ( $trace & 2 ) {
1849         for my $n (0 .. $#to_watch) {
1850             $evalarg = $to_watch[$n];
1851             local $onetimeDump;    # Tell DB::eval() to not output results
1852
1853             # Fix context DB::eval() wants to return an array, but
1854             # we need a scalar here.
1855             my ($val) = join( "', '", &eval );
1856             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1857
1858             # Did it change?
1859             if ( $val ne $old_watch[$n] ) {
1860
1861                 # Yep! Show the difference, and fake an interrupt.
1862                 $signal = 1;
1863                 print $OUT <<EOP;
1864 Watchpoint $n:\t$to_watch[$n] changed:
1865     old value:\t$old_watch[$n]
1866     new value:\t$val
1867 EOP
1868                 $old_watch[$n] = $val;
1869             } ## end if ($val ne $old_watch...
1870         } ## end for my $n (0 ..
1871     } ## end if ($trace & 2)
1872
1873 =head2 C<watchfunction()>
1874
1875 C<watchfunction()> is a function that can be defined by the user; it is a
1876 function which will be run on each entry to C<DB::DB>; it gets the
1877 current package, filename, and line as its parameters.
1878
1879 The watchfunction can do anything it likes; it is executing in the
1880 debugger's context, so it has access to all of the debugger's internal
1881 data structures and functions.
1882
1883 C<watchfunction()> can control the debugger's actions. Any of the following
1884 will cause the debugger to return control to the user's program after
1885 C<watchfunction()> executes:
1886
1887 =over 4
1888
1889 =item *
1890
1891 Returning a false value from the C<watchfunction()> itself.
1892
1893 =item *
1894
1895 Altering C<$single> to a false value.
1896
1897 =item *
1898
1899 Altering C<$signal> to a false value.
1900
1901 =item *
1902
1903 Turning off the C<4> bit in C<$trace> (this also disables the
1904 check for C<watchfunction()>. This can be done with
1905
1906     $trace &= ~4;
1907
1908 =back
1909
1910 =cut
1911
1912     # If there's a user-defined DB::watchfunction, call it with the
1913     # current package, filename, and line. The function executes in
1914     # the DB:: package.
1915     if ( $trace & 4 ) {    # User-installed watch
1916         return
1917           if watchfunction( $package, $filename, $line )
1918           and not $single
1919           and not $was_signal
1920           and not( $trace & ~4 );
1921     } ## end if ($trace & 4)
1922
1923     # Pick up any alteration to $signal in the watchfunction, and
1924     # turn off the signal now.
1925     $was_signal = $signal;
1926     $signal     = 0;
1927
1928 =head2 GETTING READY TO EXECUTE COMMANDS
1929
1930 The debugger decides to take control if single-step mode is on, the
1931 C<t> command was entered, or the user generated a signal. If the program
1932 has fallen off the end, we set things up so that entering further commands
1933 won't cause trouble, and we say that the program is over.
1934
1935 =cut
1936
1937     # Make sure that we always print if asked for explicitly regardless
1938     # of $trace_to_depth .
1939     my $explicit_stop = ($single || $was_signal);
1940
1941     # Check to see if we should grab control ($single true,
1942     # trace set appropriately, or we got a signal).
1943     if ( $explicit_stop || ( $trace & 1 ) ) {
1944
1945         # Yes, grab control.
1946         if ($slave_editor) {
1947
1948             # Tell the editor to update its position.
1949             $position = "\032\032$filename:$line:0\n";
1950             print_lineinfo($position);
1951         }
1952
1953 =pod
1954
1955 Special check: if we're in package C<DB::fake>, we've gone through the
1956 C<END> block at least once. We set up everything so that we can continue
1957 to enter commands and have a valid context to be in.
1958
1959 =cut
1960
1961         elsif ( $package eq 'DB::fake' ) {
1962
1963             # Fallen off the end already.
1964             $term || &setterm;
1965             print_help(<<EOP);
1966 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1967   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1968   B<h q>, B<h R> or B<h o> to get additional info.
1969 EOP
1970
1971             # Set the DB::eval context appropriately.
1972             $package     = 'main';
1973             $usercontext = _calc_usercontext($package);
1974         } ## end elsif ($package eq 'DB::fake')
1975
1976 =pod
1977
1978 If the program hasn't finished executing, we scan forward to the
1979 next executable line, print that out, build the prompt from the file and line
1980 number information, and print that.
1981
1982 =cut
1983
1984         else {
1985
1986
1987             # Still somewhere in the midst of execution. Set up the
1988             #  debugger prompt.
1989             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1990                                  # Perl 5 ones (sorry, we don't print Klingon
1991                                  #module names)
1992
1993             $prefix = $sub =~ /::/ ? "" : ($package . '::');
1994             $prefix .= "$sub($filename:";
1995             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1996
1997             # Break up the prompt if it's really long.
1998             if ( length($prefix) > 30 ) {
1999                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2000                 $prefix   = "";
2001                 $infix    = ":\t";
2002             }
2003             else {
2004                 $infix    = "):\t";
2005                 $position = "$prefix$line$infix$dbline[$line]$after";
2006             }
2007
2008             # Print current line info, indenting if necessary.
2009             if ($frame) {
2010                 print_lineinfo( ' ' x $stack_depth,
2011                     "$line:\t$dbline[$line]$after" );
2012             }
2013             else {
2014                 depth_print_lineinfo($explicit_stop, $position);
2015             }
2016
2017             # Scan forward, stopping at either the end or the next
2018             # unbreakable line.
2019             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2020             {    #{ vi
2021
2022                 # Drop out on null statements, block closers, and comments.
2023                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2024
2025                 # Drop out if the user interrupted us.
2026                 last if $signal;
2027
2028                 # Append a newline if the line doesn't have one. Can happen
2029                 # in eval'ed text, for instance.
2030                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2031
2032                 # Next executable line.
2033                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2034                 $position .= $incr_pos;
2035                 if ($frame) {
2036
2037                     # Print it indented if tracing is on.
2038                     print_lineinfo( ' ' x $stack_depth,
2039                         "$i:\t$dbline[$i]$after" );
2040                 }
2041                 else {
2042                     depth_print_lineinfo($explicit_stop, $incr_pos);
2043                 }
2044             } ## end for ($i = $line + 1 ; $i...
2045         } ## end else [ if ($slave_editor)
2046     } ## end if ($single || ($trace...
2047
2048 =pod
2049
2050 If there's an action to be executed for the line we stopped at, execute it.
2051 If there are any preprompt actions, execute those as well.
2052
2053 =cut
2054
2055     # If there's an action, do it now.
2056     $evalarg = $action, &eval if $action;
2057
2058     # Are we nested another level (e.g., did we evaluate a function
2059     # that had a breakpoint in it at the debugger prompt)?
2060     if ( $single || $was_signal ) {
2061
2062         # Yes, go down a level.
2063         local $level = $level + 1;
2064
2065         # Do any pre-prompt actions.
2066         foreach $evalarg (@$pre) {
2067             &eval;
2068         }
2069
2070         # Complain about too much recursion if we passed the limit.
2071         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2072           if $single & 4;
2073
2074         # The line we're currently on. Set $incr to -1 to stay here
2075         # until we get a command that tells us to advance.
2076         $start = $line;
2077         $incr  = -1;      # for backward motion.
2078
2079         # Tack preprompt debugger actions ahead of any actual input.
2080         @typeahead = ( @$pretype, @typeahead );
2081
2082 =head2 WHERE ARE WE?
2083
2084 XXX Relocate this section?
2085
2086 The debugger normally shows the line corresponding to the current line of
2087 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2088 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2089
2090 C<$incr> controls by how many lines the I<current> line should move forward
2091 after a command is executed. If set to -1, this indicates that the I<current>
2092 line shouldn't change.
2093
2094 C<$start> is the I<current> line. It is used for things like knowing where to
2095 move forwards or backwards from when doing an C<L> or C<-> command.
2096
2097 C<$max> tells the debugger where the last line of the current file is. It's
2098 used to terminate loops most often.
2099
2100 =head2 THE COMMAND LOOP
2101
2102 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2103 in two parts:
2104
2105 =over 4
2106
2107 =item *
2108
2109 The outer part of the loop, starting at the C<CMD> label. This loop
2110 reads a command and then executes it.
2111
2112 =item *
2113
2114 The inner part of the loop, starting at the C<PIPE> label. This part
2115 is wholly contained inside the C<CMD> block and only executes a command.
2116 Used to handle commands running inside a pager.
2117
2118 =back
2119
2120 So why have two labels to restart the loop? Because sometimes, it's easier to
2121 have a command I<generate> another command and then re-execute the loop to do
2122 the new command. This is faster, but perhaps a bit more convoluted.
2123
2124 =cut
2125
2126         # The big command dispatch loop. It keeps running until the
2127         # user yields up control again.
2128         #
2129         # If we have a terminal for input, and we get something back
2130         # from readline(), keep on processing.
2131         my $piped;
2132         my $selected;
2133
2134       CMD:
2135         while (
2136
2137             # We have a terminal, or can get one ...
2138             ( $term || &setterm ),
2139
2140             # ... and it belogs to this PID or we get one for this PID ...
2141             ( $term_pid == $$ or resetterm(1) ),
2142
2143             # ... and we got a line of command input ...
2144             defined(
2145                 $cmd = &readline(
2146                         "$pidprompt $tid DB"
2147                       . ( '<' x $level )
2148                       . ( $#hist + 1 )
2149                       . ( '>' x $level ) . " "
2150                 )
2151             )
2152           )
2153         {
2154
2155                         share($cmd);
2156             # ... try to execute the input as debugger commands.
2157
2158             # Don't stop running.
2159             $single = 0;
2160
2161             # No signal is active.
2162             $signal = 0;
2163
2164             # Handle continued commands (ending with \):
2165             if ($cmd =~ s/\\\z/\n/) {
2166                 $cmd .= &readline("  cont: ");
2167                 redo CMD;
2168             }
2169
2170 =head4 The null command
2171
2172 A newline entered by itself means I<re-execute the last command>. We grab the
2173 command out of C<$laststep> (where it was recorded previously), and copy it
2174 back into C<$cmd> to be executed below. If there wasn't any previous command,
2175 we'll do nothing below (no command will match). If there was, we also save it
2176 in the command history and fall through to allow the command parsing to pick
2177 it up.
2178
2179 =cut
2180
2181             # Empty input means repeat the last command.
2182             $cmd =~ /^$/ && ( $cmd = $laststep );
2183             chomp($cmd);    # get rid of the annoying extra newline
2184             push( @hist, $cmd ) if length($cmd) > 1;
2185             push( @truehist, $cmd );
2186                         share(@hist);
2187                         share(@truehist);
2188
2189             # This is a restart point for commands that didn't arrive
2190             # via direct user input. It allows us to 'redo PIPE' to
2191             # re-execute command processing without reading a new command.
2192           PIPE: {
2193                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2194                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2195                 my ($i) = split( /\s+/, $cmd );
2196
2197 =head3 COMMAND ALIASES
2198
2199 The debugger can create aliases for commands (these are stored in the
2200 C<%alias> hash). Before a command is executed, the command loop looks it up
2201 in the alias hash and substitutes the contents of the alias for the command,
2202 completely replacing it.
2203
2204 =cut
2205
2206                 # See if there's an alias for the command, and set it up if so.
2207                 if ( $alias{$i} ) {
2208
2209                     # Squelch signal handling; we want to keep control here
2210                     # if something goes loco during the alias eval.
2211                     local $SIG{__DIE__};
2212                     local $SIG{__WARN__};
2213
2214                     # This is a command, so we eval it in the DEBUGGER's
2215                     # scope! Otherwise, we can't see the special debugger
2216                     # variables, or get to the debugger's subs. (Well, we
2217                     # _could_, but why make it even more complicated?)
2218                     eval "\$cmd =~ $alias{$i}";
2219                     if ($@) {
2220                         local $\ = '';
2221                         print $OUT "Couldn't evaluate '$i' alias: $@";
2222                         next CMD;
2223                     }
2224                 } ## end if ($alias{$i})
2225
2226 =head3 MAIN-LINE COMMANDS
2227
2228 All of these commands work up to and after the program being debugged has
2229 terminated.
2230
2231 =head4 C<q> - quit
2232
2233 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2234 try to execute further, cleaning any restart-related stuff out of the
2235 environment, and executing with the last value of C<$?>.
2236
2237 =cut
2238
2239                 if ($cmd eq 'q') {
2240                     $fall_off_end = 1;
2241                     clean_ENV();
2242                     exit $?;
2243                 }
2244
2245 =head4 C<t> - trace [n]
2246
2247 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2248 If level is specified, set C<$trace_to_depth>.
2249
2250 =cut
2251
2252                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2253                     $trace ^= 1;
2254                     local $\ = '';
2255                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2256                     print $OUT "Trace = "
2257                       . ( ( $trace & 1 )
2258                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2259                       : "off" ) . "\n";
2260                     next CMD;
2261                 }
2262
2263 =head4 C<S> - list subroutines matching/not matching a pattern
2264
2265 Walks through C<%sub>, checking to see whether or not to print the name.
2266
2267 =cut
2268
2269                 if (my ($print_all_subs, $should_reverse, $Spatt)
2270                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2271                     # $Spatt is the pattern (if any) to use.
2272                     # Reverse scan?
2273                     my $Srev     = defined $should_reverse;
2274                     # No args - print all subs.
2275                     my $Snocheck = !defined $print_all_subs;
2276
2277                     # Need to make these sane here.
2278                     local $\ = '';
2279                     local $, = '';
2280
2281                     # Search through the debugger's magical hash of subs.
2282                     # If $nocheck is true, just print the sub name.
2283                     # Otherwise, check it against the pattern. We then use
2284                     # the XOR trick to reverse the condition as required.
2285                     foreach $subname ( sort( keys %sub ) ) {
2286                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2287                             print $OUT $subname, "\n";
2288                         }
2289                     }
2290                     next CMD;
2291                 }
2292
2293 =head4 C<X> - list variables in current package
2294
2295 Since the C<V> command actually processes this, just change this to the
2296 appropriate C<V> command and fall through.
2297
2298 =cut
2299
2300                 $cmd =~ s/^X\b/V $package/;
2301
2302 =head4 C<V> - list variables
2303
2304 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2305
2306 =cut
2307
2308                 # Bare V commands get the currently-being-debugged package
2309                 # added.
2310                 if ($cmd eq "V") {
2311                     $cmd = "V $package";
2312                 }
2313
2314                 # V - show variables in package.
2315                 if (my ($new_packname, $new_vars_str) =
2316                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2317
2318                     # Save the currently selected filehandle and
2319                     # force output to debugger's filehandle (dumpvar
2320                     # just does "print" for output).
2321                     my $savout = select($OUT);
2322
2323                     # Grab package name and variables to dump.
2324                     $packname = $new_packname;
2325                     my @vars     = split( ' ', $new_vars_str );
2326
2327                     # If main::dumpvar isn't here, get it.
2328                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2329                     if ( defined &main::dumpvar ) {
2330
2331                         # We got it. Turn off subroutine entry/exit messages
2332                         # for the moment, along with return values.
2333                         local $frame = 0;
2334                         local $doret = -2;
2335
2336                         # must detect sigpipe failures  - not catching
2337                         # then will cause the debugger to die.
2338                         eval {
2339                             &main::dumpvar(
2340                                 $packname,
2341                                 defined $option{dumpDepth}
2342                                 ? $option{dumpDepth}
2343                                 : -1,    # assume -1 unless specified
2344                                 @vars
2345                             );
2346                         };
2347
2348                         # The die doesn't need to include the $@, because
2349                         # it will automatically get propagated for us.
2350                         if ($@) {
2351                             die unless $@ =~ /dumpvar print failed/;
2352                         }
2353                     } ## end if (defined &main::dumpvar)
2354                     else {
2355
2356                         # Couldn't load dumpvar.
2357                         print $OUT "dumpvar.pl not available.\n";
2358                     }
2359
2360                     # Restore the output filehandle, and go round again.
2361                     select($savout);
2362                     next CMD;
2363                 }
2364
2365 =head4 C<x> - evaluate and print an expression
2366
2367 Hands the expression off to C<DB::eval>, setting it up to print the value
2368 via C<dumpvar.pl> instead of just printing it directly.
2369
2370 =cut
2371
2372                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2373                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2374
2375                     # handle special  "x 3 blah" syntax XXX propagate
2376                     # doc back to special variables.
2377                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2378                         $onetimedumpDepth = $1;
2379                     }
2380                 }
2381
2382 =head4 C<m> - print methods
2383
2384 Just uses C<DB::methods> to determine what methods are available.
2385
2386 =cut
2387
2388                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2389                     methods($1);
2390                     next CMD;
2391                 }
2392
2393                 # m expr - set up DB::eval to do the work
2394                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2395                     $onetimeDump = 'methods';   #  method output gets used there
2396                 }
2397
2398 =head4 C<f> - switch files
2399
2400 =cut
2401
2402                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2403                     $file =~ s/\s+$//;
2404
2405                     # help for no arguments (old-style was return from sub).
2406                     if ( !$file ) {
2407                         print $OUT
2408                           "The old f command is now the r command.\n";    # hint
2409                         print $OUT "The new f command switches filenames.\n";
2410                         next CMD;
2411                     } ## end if (!$file)
2412
2413                     # if not in magic file list, try a close match.
2414                     if ( !defined $main::{ '_<' . $file } ) {
2415                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2416                             {
2417                                 $try = substr( $try, 2 );
2418                                 print $OUT "Choosing $try matching '$file':\n";
2419                                 $file = $try;
2420                             }
2421                         } ## end if (($try) = grep(m#^_<.*$file#...
2422                     } ## end if (!defined $main::{ ...
2423
2424                     # If not successfully switched now, we failed.
2425                     if ( !defined $main::{ '_<' . $file } ) {
2426                         print $OUT "No file matching '$file' is loaded.\n";
2427                         next CMD;
2428                     }
2429
2430                     # We switched, so switch the debugger internals around.
2431                     elsif ( $file ne $filename ) {
2432                         *dbline   = $main::{ '_<' . $file };
2433                         $max      = $#dbline;
2434                         $filename = $file;
2435                         $start    = 1;
2436                         $cmd      = "l";
2437                     } ## end elsif ($file ne $filename)
2438
2439                     # We didn't switch; say we didn't.
2440                     else {
2441                         print $OUT "Already in $file.\n";
2442                         next CMD;
2443                     }
2444                 }
2445
2446 =head4 C<.> - return to last-executed line.
2447
2448 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2449 and then we look up the line in the magical C<%dbline> hash.
2450
2451 =cut
2452
2453                 # . command.
2454                 if ($cmd eq '.') {
2455                     $incr = -1;    # stay at current line
2456
2457                     # Reset everything to the old location.
2458                     $start    = $line;
2459                     $filename = $filename_ini;
2460                     *dbline   = $main::{ '_<' . $filename };
2461                     $max      = $#dbline;
2462
2463                     # Now where are we?
2464                     print_lineinfo($position);
2465                     next CMD;
2466                 }
2467
2468 =head4 C<-> - back one window
2469
2470 We change C<$start> to be one window back; if we go back past the first line,
2471 we set it to be the first line. We ser C<$incr> to put us back at the
2472 currently-executing line, and then put a C<l $start +> (list one window from
2473 C<$start>) in C<$cmd> to be executed later.
2474
2475 =cut
2476
2477                 # - - back a window.
2478                 if ($cmd eq '-') {
2479
2480                     # back up by a window; go to 1 if back too far.
2481                     $start -= $incr + $window + 1;
2482                     $start = 1 if $start <= 0;
2483                     $incr  = $window - 1;
2484
2485                     # Generate and execute a "l +" command (handled below).
2486                     $cmd = 'l ' . ($start) . '+';
2487                 }
2488
2489 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2490
2491 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2492 problems, most notably that the default case of several commands destroying
2493 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2494 retain the old commands for those who were used to using them or who preferred
2495 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2496 deal with them instead of processing them in-line.
2497
2498 =cut
2499
2500                 # All of these commands were remapped in perl 5.8.0;
2501                 # we send them off to the secondary dispatcher (see below).
2502                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2503                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2504                     next CMD;
2505                 }
2506
2507 =head4 C<y> - List lexicals in higher scope
2508
2509 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2510 above the current one and then displays then using C<dumpvar.pl>.
2511
2512 =cut
2513
2514                 if (my ($match_level, $match_vars)
2515                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2516
2517                     # See if we've got the necessary support.
2518                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2519                       or &warn(
2520                         $@ =~ /locate/
2521                         ? "PadWalker module not found - please install\n"
2522                         : $@
2523                       )
2524                       and next CMD;
2525
2526                     # Load up dumpvar if we don't have it. If we can, that is.
2527                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2528                     defined &main::dumpvar
2529                       or print $OUT "dumpvar.pl not available.\n"
2530                       and next CMD;
2531
2532                     # Got all the modules we need. Find them and print them.
2533                     my @vars = split( ' ', $match_vars || '' );
2534
2535                     # Find the pad.
2536                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2537
2538                     # Oops. Can't find it.
2539                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2540
2541                     # Show the desired vars with dumplex().
2542                     my $savout = select($OUT);
2543
2544                     # Have dumplex dump the lexicals.
2545                     dumpvar::dumplex( $_, $h->{$_},
2546                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2547                         @vars )
2548                       for sort keys %$h;
2549                     select($savout);
2550                     next CMD;
2551                 }
2552
2553 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2554
2555 All of the commands below this point don't work after the program being
2556 debugged has ended. All of them check to see if the program has ended; this
2557 allows the commands to be relocated without worrying about a 'line of
2558 demarcation' above which commands can be entered anytime, and below which
2559 they can't.
2560
2561 =head4 C<n> - single step, but don't trace down into subs
2562
2563 Done by setting C<$single> to 2, which forces subs to execute straight through
2564 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2565 so a null command knows what to re-execute.
2566
2567 =cut
2568
2569                 # n - next
2570                 if ($cmd eq 'n') {
2571                     end_report(), next CMD if $finished and $level <= 1;
2572
2573                     # Single step, but don't enter subs.
2574                     $single = 2;
2575
2576                     # Save for empty command (repeat last).
2577                     $laststep = $cmd;
2578                     last CMD;
2579                 }
2580
2581 =head4 C<s> - single-step, entering subs
2582
2583 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2584 subs. Also saves C<s> as C<$lastcmd>.
2585
2586 =cut
2587
2588                 # s - single step.
2589                 if ($cmd eq 's') {
2590
2591                     # Get out and restart the command loop if program
2592                     # has finished.
2593                     end_report(), next CMD if $finished and $level <= 1;
2594
2595                     # Single step should enter subs.
2596                     $single = 1;
2597
2598                     # Save for empty command (repeat last).
2599                     $laststep = $cmd;
2600                     last CMD;
2601                 }
2602
2603 =head4 C<c> - run continuously, setting an optional breakpoint
2604
2605 Most of the code for this command is taken up with locating the optional
2606 breakpoint, which is either a subroutine name or a line number. We set
2607 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2608 in this and all call levels above this one.
2609
2610 =cut
2611
2612                 # c - start continuous execution.
2613                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2614
2615                     # Hey, show's over. The debugged program finished
2616                     # executing already.
2617                     end_report(), next CMD if $finished and $level <= 1;
2618
2619                     # Capture the place to put a one-time break.
2620                     $subname = $i;
2621
2622                     #  Probably not needed, since we finish an interactive
2623                     #  sub-session anyway...
2624                     # local $filename = $filename;
2625                     # local *dbline = *dbline; # XXX Would this work?!
2626                     #
2627                     # The above question wonders if localizing the alias
2628                     # to the magic array works or not. Since it's commented
2629                     # out, we'll just leave that to speculation for now.
2630
2631                     # If the "subname" isn't all digits, we'll assume it
2632                     # is a subroutine name, and try to find it.
2633                     if ( $subname =~ /\D/ ) {    # subroutine name
2634                             # Qualify it to the current package unless it's
2635                             # already qualified.
2636                         $subname = $package . "::" . $subname
2637                           unless $subname =~ /::/;
2638
2639                         # find_sub will return "file:line_number" corresponding
2640                         # to where the subroutine is defined; we call find_sub,
2641                         # break up the return value, and assign it in one
2642                         # operation.
2643                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2644
2645                         # Force the line number to be numeric.
2646                         $i += 0;
2647
2648                         # If we got a line number, we found the sub.
2649                         if ($i) {
2650
2651                             # Switch all the debugger's internals around so
2652                             # we're actually working with that file.
2653                             $filename = $file;
2654                             *dbline   = $main::{ '_<' . $filename };
2655
2656                             # Mark that there's a breakpoint in this file.
2657                             $had_breakpoints{$filename} |= 1;
2658
2659                             # Scan forward to the first executable line
2660                             # after the 'sub whatever' line.
2661                             $max = $#dbline;
2662                             ++$i while $dbline[$i] == 0 && $i < $max;
2663                         } ## end if ($i)
2664
2665                         # We didn't find a sub by that name.
2666                         else {
2667                             print $OUT "Subroutine $subname not found.\n";
2668                             next CMD;
2669                         }
2670                     } ## end if ($subname =~ /\D/)
2671
2672                     # At this point, either the subname was all digits (an
2673                     # absolute line-break request) or we've scanned through
2674                     # the code following the definition of the sub, looking
2675                     # for an executable, which we may or may not have found.
2676                     #
2677                     # If $i (which we set $subname from) is non-zero, we
2678                     # got a request to break at some line somewhere. On
2679                     # one hand, if there wasn't any real subroutine name
2680                     # involved, this will be a request to break in the current
2681                     # file at the specified line, so we have to check to make
2682                     # sure that the line specified really is breakable.
2683                     #
2684                     # On the other hand, if there was a subname supplied, the
2685                     # preceding block has moved us to the proper file and
2686                     # location within that file, and then scanned forward
2687                     # looking for the next executable line. We have to make
2688                     # sure that one was found.
2689                     #
2690                     # On the gripping hand, we can't do anything unless the
2691                     # current value of $i points to a valid breakable line.
2692                     # Check that.
2693                     if ($i) {
2694
2695                         # Breakable?
2696                         if ( $dbline[$i] == 0 ) {
2697                             print $OUT "Line $i not breakable.\n";
2698                             next CMD;
2699                         }
2700
2701                         # Yes. Set up the one-time-break sigil.
2702                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2703                         _enable_breakpoint_temp_enabled_status($filename, $i);
2704                     } ## end if ($i)
2705
2706                     # Turn off stack tracing from here up.
2707                     for my $i (0 .. $stack_depth) {
2708                         $stack[ $i ] &= ~1;
2709                     }
2710                     last CMD;
2711                 }
2712
2713 =head4 C<r> - return from a subroutine
2714
2715 For C<r> to work properly, the debugger has to stop execution again
2716 immediately after the return is executed. This is done by forcing
2717 single-stepping to be on in the call level above the current one. If
2718 we are printing return values when a C<r> is executed, set C<$doret>
2719 appropriately, and force us out of the command loop.
2720
2721 =cut
2722
2723                 # r - return from the current subroutine.
2724                 if ($cmd eq 'r') {
2725
2726                     # Can't do anything if the program's over.
2727                     end_report(), next CMD if $finished and $level <= 1;
2728
2729                     # Turn on stack trace.
2730                     $stack[$stack_depth] |= 1;
2731
2732                     # Print return value unless the stack is empty.
2733                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2734                     last CMD;
2735                 }
2736
2737 =head4 C<T> - stack trace
2738
2739 Just calls C<DB::print_trace>.
2740
2741 =cut
2742
2743                 if ($cmd eq 'T') {
2744                     print_trace( $OUT, 1 );    # skip DB
2745                     next CMD;
2746                 }
2747
2748 =head4 C<w> - List window around current line.
2749
2750 Just calls C<DB::cmd_w>.
2751
2752 =cut
2753
2754                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2755                     &cmd_w( 'w', $arg );
2756                     next CMD;
2757                 }
2758
2759 =head4 C<W> - watch-expression processing.
2760
2761 Just calls C<DB::cmd_W>.
2762
2763 =cut
2764
2765                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2766                     &cmd_W( 'W', $arg );
2767                     next CMD;
2768                 }
2769
2770 =head4 C</> - search forward for a string in the source
2771
2772 We take the argument and treat it as a pattern. If it turns out to be a
2773 bad one, we return the error we got from trying to C<eval> it and exit.
2774 If not, we create some code to do the search and C<eval> it so it can't
2775 mess us up.
2776
2777 =cut
2778
2779                 # The pattern as a string.
2780                 use vars qw($inpat);
2781
2782                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2783
2784                     # Remove the final slash.
2785                     $inpat =~ s:([^\\])/$:$1:;
2786
2787                     # If the pattern isn't null ...
2788                     if ( $inpat ne "" ) {
2789
2790                         # Turn of warn and die procesing for a bit.
2791                         local $SIG{__DIE__};
2792                         local $SIG{__WARN__};
2793
2794                         # Create the pattern.
2795                         eval '$inpat =~ m' . "\a$inpat\a";
2796                         if ( $@ ne "" ) {
2797
2798                             # Oops. Bad pattern. No biscuit.
2799                             # Print the eval error and go back for more
2800                             # commands.
2801                             print $OUT "$@";
2802                             next CMD;
2803                         }
2804                         $pat = $inpat;
2805                     } ## end if ($inpat ne "")
2806
2807                     # Set up to stop on wrap-around.
2808                     $end = $start;
2809
2810                     # Don't move off the current line.
2811                     $incr = -1;
2812
2813                     # Done in eval so nothing breaks if the pattern
2814                     # does something weird.
2815                     eval '
2816                         for (;;) {
2817                             # Move ahead one line.
2818                             ++$start;
2819
2820                             # Wrap if we pass the last line.
2821                             $start = 1 if ($start > $max);
2822
2823                             # Stop if we have gotten back to this line again,
2824                             last if ($start == $end);
2825
2826                             # A hit! (Note, though, that we are doing
2827                             # case-insensitive matching. Maybe a qr//
2828                             # expression would be better, so the user could
2829                             # do case-sensitive matching if desired.
2830                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2831                                 if ($slave_editor) {
2832                                     # Handle proper escaping in the slave.
2833                                     print $OUT "\032\032$filename:$start:0\n";
2834                                 }
2835                                 else {
2836                                     # Just print the line normally.
2837                                     print $OUT "$start:\t",$dbline[$start],"\n";
2838                                 }
2839                                 # And quit since we found something.
2840                                 last;
2841                             }
2842                          } ';
2843
2844                     # If we wrapped, there never was a match.
2845                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2846                     next CMD;
2847                 }
2848
2849 =head4 C<?> - search backward for a string in the source
2850
2851 Same as for C</>, except the loop runs backwards.
2852
2853 =cut
2854
2855                 # ? - backward pattern search.
2856                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2857
2858                     # Get the pattern, remove trailing question mark.
2859                     $inpat =~ s:([^\\])\?$:$1:;
2860
2861                     # If we've got one ...
2862                     if ( $inpat ne "" ) {
2863
2864                         # Turn off die & warn handlers.
2865                         local $SIG{__DIE__};
2866                         local $SIG{__WARN__};
2867                         eval '$inpat =~ m' . "\a$inpat\a";
2868
2869                         if ( $@ ne "" ) {
2870
2871                             # Ouch. Not good. Print the error.
2872                             print $OUT $@;
2873                             next CMD;
2874                         }
2875                         $pat = $inpat;
2876                     } ## end if ($inpat ne "")
2877
2878                     # Where we are now is where to stop after wraparound.
2879                     $end = $start;
2880
2881                     # Don't move away from this line.
2882                     $incr = -1;
2883
2884                     # Search inside the eval to prevent pattern badness
2885                     # from killing us.
2886                     eval '
2887                         for (;;) {
2888                             # Back up a line.
2889                             --$start;
2890
2891                             # Wrap if we pass the first line.
2892
2893                             $start = $max if ($start <= 0);
2894
2895                             # Quit if we get back where we started,
2896                             last if ($start == $end);
2897
2898                             # Match?
2899                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2900                                 if ($slave_editor) {
2901                                     # Yep, follow slave editor requirements.
2902                                     print $OUT "\032\032$filename:$start:0\n";
2903                                 }
2904                                 else {
2905                                     # Yep, just print normally.
2906                                     print $OUT "$start:\t",$dbline[$start],"\n";
2907                                 }
2908
2909                                 # Found, so done.
2910                                 last;
2911                             }
2912                         } ';
2913
2914                     # Say we failed if the loop never found anything,
2915                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2916                     next CMD;
2917                 }
2918
2919 =head4 C<$rc> - Recall command
2920
2921 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2922 that the terminal supports history). It find the the command required, puts it
2923 into C<$cmd>, and redoes the loop to execute it.
2924
2925 =cut
2926
2927                 # $rc - recall command.
2928                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2929
2930                     # No arguments, take one thing off history.
2931                     pop(@hist) if length($cmd) > 1;
2932
2933                     # Relative (- found)?
2934                     #  Y - index back from most recent (by 1 if bare minus)
2935                     #  N - go to that particular command slot or the last
2936                     #      thing if nothing following.
2937                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2938
2939                     # Pick out the command desired.
2940                     $cmd = $hist[$i];
2941
2942                     # Print the command to be executed and restart the loop
2943                     # with that command in the buffer.
2944                     print $OUT $cmd, "\n";
2945                     redo CMD;
2946                 }
2947
2948 =head4 C<$sh$sh> - C<system()> command
2949
2950 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2951 C<STDOUT> from getting messed up.
2952
2953 =cut
2954
2955                 # $sh$sh - run a shell command (if it's all ASCII).
2956                 # Can't run shell commands with Unicode in the debugger, hmm.
2957                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2958
2959                     # System it.
2960                     &system($arg);
2961                     next CMD;
2962                 }
2963
2964 =head4 C<$rc I<pattern> $rc> - Search command history
2965
2966 Another command to manipulate C<@hist>: this one searches it with a pattern.
2967 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2968
2969 =cut
2970
2971                 # $rc pattern $rc - find a command in the history.
2972                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2973
2974                     # Create the pattern to use.
2975                     $pat = "^$arg";
2976
2977                     # Toss off last entry if length is >1 (and it always is).
2978                     pop(@hist) if length($cmd) > 1;
2979
2980                     # Look backward through the history.
2981                     for ( $i = $#hist ; $i ; --$i ) {
2982                         # Stop if we find it.
2983                         last if $hist[$i] =~ /$pat/;
2984                     }
2985
2986                     if ( !$i ) {
2987
2988                         # Never found it.
2989                         print $OUT "No such command!\n\n";
2990                         next CMD;
2991                     }
2992
2993                     # Found it. Put it in the buffer, print it, and process it.
2994                     $cmd = $hist[$i];
2995                     print $OUT $cmd, "\n";
2996                     redo CMD;
2997                 }
2998
2999 =head4 C<$sh> - Invoke a shell
3000
3001 Uses C<DB::system> to invoke a shell.
3002
3003 =cut
3004
3005                 # $sh - start a shell.
3006                 if ($cmd =~ /\A$sh\z/) {
3007
3008                     # Run the user's shell. If none defined, run Bourne.
3009                     # We resume execution when the shell terminates.
3010                     &system( $ENV{SHELL} || "/bin/sh" );
3011                     next CMD;
3012                 }
3013
3014 =head4 C<$sh I<command>> - Force execution of a command in a shell
3015
3016 Like the above, but the command is passed to the shell. Again, we use
3017 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3018
3019 =cut
3020
3021                 # $sh command - start a shell and run a command in it.
3022                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
3023
3024                     # XXX: using csh or tcsh destroys sigint retvals!
3025                     #&system($1);  # use this instead
3026
3027                     # use the user's shell, or Bourne if none defined.
3028                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
3029                     next CMD;
3030                 }
3031
3032 =head4 C<H> - display commands in history
3033
3034 Prints the contents of C<@hist> (if any).
3035
3036 =cut
3037
3038                 if ($cmd =~ /\AH\b\s*\*/) {
3039                     @hist = @truehist = ();
3040                     print $OUT "History cleansed\n";
3041                     next CMD;
3042                 }
3043
3044                 if (my ($num)
3045                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3046
3047                     # Anything other than negative numbers is ignored by
3048                     # the (incorrect) pattern, so this test does nothing.
3049                     $end = $num ? ( $#hist - $num ) : 0;
3050
3051                     # Set to the minimum if less than zero.
3052                     $hist = 0 if $hist < 0;
3053
3054                     # Start at the end of the array.
3055                     # Stay in while we're still above the ending value.
3056                     # Tick back by one each time around the loop.
3057                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3058
3059                         # Print the command  unless it has no arguments.
3060                         print $OUT "$i: ", $hist[$i], "\n"
3061                           unless $hist[$i] =~ /^.?$/;
3062                     }
3063                     next CMD;
3064                 }
3065
3066 =head4 C<man, doc, perldoc> - look up documentation
3067
3068 Just calls C<runman()> to print the appropriate document.
3069
3070 =cut
3071
3072                 # man, perldoc, doc - show manual pages.
3073                 if (my ($man_page)
3074                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3075                     runman($man_page);
3076                     next CMD;
3077                 }
3078
3079 =head4 C<p> - print
3080
3081 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3082 the bottom of the loop.
3083
3084 =cut
3085
3086                 my $print_cmd = 'print {$DB::OUT} ';
3087                 # p - print (no args): print $_.
3088                 if ($cmd eq 'p') {
3089                     $cmd = $print_cmd . '$_';
3090                 }
3091
3092                 # p - print the given expression.
3093                 $cmd =~ s/\Ap\b/$print_cmd /;
3094
3095 =head4 C<=> - define command alias
3096
3097 Manipulates C<%alias> to add or list command aliases.
3098
3099 =cut
3100
3101                 # = - set up a command alias.
3102                 if ($cmd =~ s/\A=\s*//) {
3103                     my @keys;
3104                     if ( length $cmd == 0 ) {
3105
3106                         # No args, get current aliases.
3107                         @keys = sort keys %alias;
3108                     }
3109                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3110
3111                         # Creating a new alias. $k is alias name, $v is
3112                         # alias value.
3113
3114                         # can't use $_ or kill //g state
3115                         for my $x ( $k, $v ) {
3116
3117                             # Escape "alarm" characters.
3118                             $x =~ s/\a/\\a/g;
3119                         }
3120
3121                         # Substitute key for value, using alarm chars
3122                         # as separators (which is why we escaped them in
3123                         # the command).
3124                         $alias{$k} = "s\a$k\a$v\a";
3125
3126                         # Turn off standard warn and die behavior.
3127                         local $SIG{__DIE__};
3128                         local $SIG{__WARN__};
3129
3130                         # Is it valid Perl?
3131                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3132
3133                             # Nope. Bad alias. Say so and get out.
3134                             print $OUT "Can't alias $k to $v: $@\n";
3135                             delete $alias{$k};
3136                             next CMD;
3137                         }
3138
3139                         # We'll only list the new one.
3140                         @keys = ($k);
3141                     } ## end elsif (my ($k, $v) = ($cmd...
3142
3143                     # The argument is the alias to list.
3144                     else {
3145                         @keys = ($cmd);
3146                     }
3147
3148                     # List aliases.
3149                     for my $k (@keys) {
3150
3151                         # Messy metaquoting: Trim the substitution code off.
3152                         # We use control-G as the delimiter because it's not
3153                         # likely to appear in the alias.
3154                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3155
3156                             # Print the alias.
3157                             print $OUT "$k\t= $1\n";
3158                         }
3159                         elsif ( defined $alias{$k} ) {
3160
3161                             # Couldn't trim it off; just print the alias code.
3162                             print $OUT "$k\t$alias{$k}\n";
3163                         }
3164                         else {
3165
3166                             # No such, dude.
3167                             print "No alias for $k\n";
3168                         }
3169                     } ## end for my $k (@keys)
3170                     next CMD;
3171                 }
3172
3173 =head4 C<source> - read commands from a file.
3174
3175 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3176 pick it up.
3177
3178 =cut
3179
3180                 # source - read commands from a file (or pipe!) and execute.
3181                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3182                     if ( open my $fh, $sourced_fn ) {
3183
3184                         # Opened OK; stick it in the list of file handles.
3185                         push @cmdfhs, $fh;
3186                     }
3187                     else {
3188
3189                         # Couldn't open it.
3190                         &warn("Can't execute '$sourced_fn': $!\n");
3191                     }
3192                     next CMD;
3193                 }
3194
3195                 if (my ($which_cmd, $position)
3196                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3197
3198                     my ($fn, $line_num);
3199                     if ($position =~ m{\A\d+\z})
3200                     {
3201                         $fn = $filename;
3202                         $line_num = $position;
3203                     }
3204                     elsif (my ($new_fn, $new_line_num)
3205                         = $position =~ m{\A(.*):(\d+)\z}) {
3206                         ($fn, $line_num) = ($new_fn, $new_line_num);
3207                     }
3208                     else
3209                     {
3210                         &warn("Wrong spec for enable/disable argument.\n");
3211                     }
3212
3213                     if (defined($fn)) {
3214                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3215                             _set_breakpoint_enabled_status($fn, $line_num,
3216                                 ($which_cmd eq 'enable' ? 1 : '')
3217                             );
3218                         }
3219                         else {
3220                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3221                         }
3222                     }
3223
3224                     next CMD;
3225                 }
3226
3227 =head4 C<save> - send current history to a file
3228
3229 Takes the complete history, (not the shrunken version you see with C<H>),
3230 and saves it to the given filename, so it can be replayed using C<source>.
3231
3232 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3233
3234 =cut
3235
3236                 # save source - write commands to a file for later use
3237                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3238                     my $filename = $new_fn || '.perl5dbrc';    # default?
3239                     if ( open my $fh, '>', $filename ) {
3240
3241                        # chomp to remove extraneous newlines from source'd files
3242                         chomp( my @truelist =
3243                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3244                               @truehist );
3245                         print $fh join( "\n", @truelist );
3246                         print "commands saved in $file\n";
3247                     }
3248                     else {
3249                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3250                     }
3251                     next CMD;
3252                 }
3253
3254 =head4 C<R> - restart
3255
3256 Restart the debugger session.
3257
3258 =head4 C<rerun> - rerun the current session
3259
3260 Return to any given position in the B<true>-history list
3261
3262 =cut
3263
3264                 # R - restart execution.
3265                 # rerun - controlled restart execution.
3266                 if (my ($cmd_cmd, $cmd_params) =
3267                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3268                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3269
3270                     # Close all non-system fds for a clean restart.  A more
3271                     # correct method would be to close all fds that were not
3272                     # open when the process started, but this seems to be
3273                     # hard.  See "debugger 'R'estart and open database
3274                     # connections" on p5p.
3275
3276                     my $max_fd = 1024; # default if POSIX can't be loaded
3277                     if (eval { require POSIX }) {
3278                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3279                     }
3280
3281                     if (defined $max_fd) {
3282                         foreach ($^F+1 .. $max_fd-1) {
3283                             next unless open FD_TO_CLOSE, "<&=$_";
3284                             close(FD_TO_CLOSE);
3285                         }
3286                     }
3287
3288                     # And run Perl again.  We use exec() to keep the
3289                     # PID stable (and that way $ini_pids is still valid).
3290                     exec(@args) || print $OUT "exec failed: $!\n";
3291
3292                     last CMD;
3293                 }
3294
3295 =head4 C<|, ||> - pipe output through the pager.
3296
3297 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3298 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3299 pipe to the pager (restoring the output filehandles if this fails). If this
3300 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3301 set C<$signal>, sending us back into the debugger.
3302
3303 We then trim off the pipe symbols and C<redo> the command loop at the
3304 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3305 reading another.
3306
3307 =cut
3308
3309                 # || - run command in the pager, with output to DB::OUT.
3310                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3311                     if ( $pager =~ /^\|/ ) {
3312
3313                         # Default pager is into a pipe. Redirect I/O.
3314                         open( SAVEOUT, ">&STDOUT" )
3315                           || &warn("Can't save STDOUT");
3316                         open( STDOUT, ">&OUT" )
3317                           || &warn("Can't redirect STDOUT");
3318                     } ## end if ($pager =~ /^\|/)
3319                     else {
3320
3321                         # Not into a pipe. STDOUT is safe.
3322                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3323                     }
3324
3325                     # Fix up environment to record we have less if so.
3326                     fix_less();
3327
3328                     unless ( $piped = open( OUT, $pager ) ) {
3329
3330                         # Couldn't open pipe to pager.
3331                         &warn("Can't pipe output to '$pager'");
3332                         if ( $pager =~ /^\|/ ) {
3333
3334                             # Redirect I/O back again.
3335                             open( OUT, ">&STDOUT" )    # XXX: lost message
3336                               || &warn("Can't restore DB::OUT");
3337                             open( STDOUT, ">&SAVEOUT" )
3338                               || &warn("Can't restore STDOUT");
3339                             close(SAVEOUT);
3340                         } ## end if ($pager =~ /^\|/)
3341                         else {
3342
3343                             # Redirect I/O. STDOUT already safe.
3344                             open( OUT, ">&STDOUT" )    # XXX: lost message
3345                               || &warn("Can't restore DB::OUT");
3346                         }
3347                         next CMD;
3348                     } ## end unless ($piped = open(OUT,...
3349
3350                     # Set up broken-pipe handler if necessary.
3351                     $SIG{PIPE} = \&DB::catch
3352                       if $pager =~ /^\|/
3353                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3354
3355                     OUT->autoflush(1);
3356                     # Save current filehandle, and put it back.
3357                     $selected = select(OUT);
3358                     # Don't put it back if pager was a pipe.
3359                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3360
3361                     # Trim off the pipe symbols and run the command now.
3362                     $cmd =~ s#\A\|+\s*##;
3363                     redo PIPE;
3364                 }
3365
3366 =head3 END OF COMMAND PARSING
3367
3368 Anything left in C<$cmd> at this point is a Perl expression that we want to
3369 evaluate. We'll always evaluate in the user's context, and fully qualify
3370 any variables we might want to address in the C<DB> package.
3371
3372 =cut
3373
3374                 # t - turn trace on.
3375                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3376                     my $trace_arg = $1;
3377                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3378                 }
3379
3380                 # s - single-step. Remember the last command was 's'.
3381                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3382                     $laststep = 's';
3383                 }
3384
3385                 # n - single-step, but not into subs. Remember last command
3386                 # was 'n'.
3387                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3388                     $laststep = 'n';
3389                 }
3390
3391             }    # PIPE:
3392
3393             # Make sure the flag that says "the debugger's running" is
3394             # still on, to make sure we get control again.
3395             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3396
3397             # Run *our* eval that executes in the caller's context.
3398             &eval;
3399
3400             # Turn off the one-time-dump stuff now.
3401             if ($onetimeDump) {
3402                 $onetimeDump      = undef;
3403                 $onetimedumpDepth = undef;
3404             }
3405             elsif ( $term_pid == $$ ) {
3406                 eval {          # May run under miniperl, when not available...
3407                     STDOUT->flush();
3408                     STDERR->flush();
3409                 };
3410
3411                 # XXX If this is the master pid, print a newline.
3412                 print $OUT "\n";
3413             }
3414         } ## end while (($term || &setterm...
3415
3416 =head3 POST-COMMAND PROCESSING
3417
3418 After each command, we check to see if the command output was piped anywhere.
3419 If so, we go through the necessary code to unhook the pipe and go back to
3420 our standard filehandles for input and output.
3421
3422 =cut
3423
3424         continue {    # CMD:
3425
3426             # At the end of every command:
3427             if ($piped) {
3428
3429                 # Unhook the pipe mechanism now.
3430                 if ( $pager =~ /^\|/ ) {
3431
3432                     # No error from the child.
3433                     $? = 0;
3434
3435                     # we cannot warn here: the handle is missing --tchrist
3436                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3437
3438                     # most of the $? crud was coping with broken cshisms
3439                     # $? is explicitly set to 0, so this never runs.
3440                     if ($?) {
3441                         print SAVEOUT "Pager '$pager' failed: ";
3442                         if ( $? == -1 ) {
3443                             print SAVEOUT "shell returned -1\n";
3444                         }
3445                         elsif ( $? >> 8 ) {
3446                             print SAVEOUT ( $? & 127 )
3447                               ? " (SIG#" . ( $? & 127 ) . ")"
3448                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3449                         }
3450                         else {
3451                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3452                         }
3453                     } ## end if ($?)
3454
3455                     # Reopen filehandle for our output (if we can) and
3456                     # restore STDOUT (if we can).
3457                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3458                     open( STDOUT, ">&SAVEOUT" )
3459                       || &warn("Can't restore STDOUT");
3460
3461                     # Turn off pipe exception handler if necessary.
3462                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3463
3464                     # Will stop ignoring SIGPIPE if done like nohup(1)
3465                     # does SIGINT but Perl doesn't give us a choice.
3466                 } ## end if ($pager =~ /^\|/)
3467                 else {
3468
3469                     # Non-piped "pager". Just restore STDOUT.
3470                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3471                 }
3472
3473                 # Close filehandle pager was using, restore the normal one
3474                 # if necessary,
3475                 close(SAVEOUT);
3476                 select($selected), $selected = "" unless $selected eq "";
3477
3478                 # No pipes now.
3479                 $piped = "";
3480             } ## end if ($piped)
3481         }    # CMD:
3482
3483 =head3 COMMAND LOOP TERMINATION
3484
3485 When commands have finished executing, we come here. If the user closed the
3486 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3487 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3488 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3489 The interpreter will then execute the next line and then return control to us
3490 again.
3491
3492 =cut
3493
3494         # No more commands? Quit.
3495         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3496
3497         # Evaluate post-prompt commands.
3498         foreach $evalarg (@$post) {
3499             &eval;
3500         }
3501     }    # if ($single || $signal)
3502
3503     # Put the user's globals back where you found them.
3504     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3505     ();
3506 } ## end sub DB
3507
3508 # The following code may be executed now:
3509 # BEGIN {warn 4}
3510
3511 =head2 sub
3512
3513 C<sub> is called whenever a subroutine call happens in the program being
3514 debugged. The variable C<$DB::sub> contains the name of the subroutine
3515 being called.
3516
3517 The core function of this subroutine is to actually call the sub in the proper
3518 context, capturing its output. This of course causes C<DB::DB> to get called
3519 again, repeating until the subroutine ends and returns control to C<DB::sub>
3520 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3521 return value, and returns its captured copy of the return value as its own
3522 return value. The value then feeds back into the program being debugged as if
3523 C<DB::sub> hadn't been there at all.
3524
3525 C<sub> does all the work of printing the subroutine entry and exit messages
3526 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3527 and also prints the return value if needed (for the C<r> command and if
3528 the 16 bit is set in C<$frame>).
3529
3530 It also tracks the subroutine call depth by saving the current setting of
3531 C<$single> in the C<@stack> package global; if this exceeds the value in
3532 C<$deep>, C<sub> automatically turns on printing of the current depth by
3533 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3534 of stop/don't stop on entry to subs set as it currently is set.
3535
3536 =head3 C<caller()> support
3537
3538 If C<caller()> is called from the package C<DB>, it provides some
3539 additional data, in the following order:
3540
3541 =over 4
3542
3543 =item * C<$package>
3544
3545 The package name the sub was in
3546
3547 =item * C<$filename>
3548
3549 The filename it was defined in
3550
3551 =item * C<$line>
3552
3553 The line number it was defined on
3554
3555 =item * C<$subroutine>
3556
3557 The subroutine name; C<(eval)> if an C<eval>().
3558
3559 =item * C<$hasargs>
3560
3561 1 if it has arguments, 0 if not
3562
3563 =item * C<$wantarray>
3564
3565 1 if array context, 0 if scalar context
3566
3567 =item * C<$evaltext>
3568
3569 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3570
3571 =item * C<$is_require>
3572
3573 frame was created by a C<use> or C<require> statement
3574
3575 =item * C<$hints>
3576
3577 pragma information; subject to change between versions
3578
3579 =item * C<$bitmask>
3580
3581 pragma information; subject to change between versions
3582
3583 =item * C<@DB::args>
3584
3585 arguments with which the subroutine was invoked
3586
3587 =back
3588
3589 =cut
3590
3591 use vars qw($deep);
3592
3593 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3594 # happy. -- Shlomi Fish
3595 sub DB::sub {
3596         # Do not use a regex in this subroutine -> results in corrupted memory
3597         # See: [perl #66110]
3598
3599         # lock ourselves under threads
3600         lock($DBGR);
3601
3602     # Whether or not the autoloader was running, a scalar to put the
3603     # sub's return value in (if needed), and an array to put the sub's
3604     # return value in (if needed).
3605     my ( $al, $ret, @ret ) = "";
3606         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3607                 print "creating new thread\n";
3608         }
3609
3610     # If the last ten characters are '::AUTOLOAD', note we've traced
3611     # into AUTOLOAD for $sub.
3612     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3613         no strict 'refs';
3614         $al = " for $$sub" if defined $$sub;
3615     }
3616
3617     # We stack the stack pointer and then increment it to protect us
3618     # from a situation that might unwind a whole bunch of call frames
3619     # at once. Localizing the stack pointer means that it will automatically
3620     # unwind the same amount when multiple stack frames are unwound.
3621     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3622
3623     # Expand @stack.
3624     $#stack = $stack_depth;
3625
3626     # Save current single-step setting.
3627     $stack[-1] = $single;
3628
3629     # Turn off all flags except single-stepping.
3630     $single &= 1;
3631
3632     # If we've gotten really deeply recursed, turn on the flag that will
3633     # make us stop with the 'deep recursion' message.
3634     $single |= 4 if $stack_depth == $deep;
3635
3636     # If frame messages are on ...
3637     (
3638         $frame & 4    # Extended frame entry message
3639         ? (
3640             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3641
3642             # Why -1? But it works! :-(
3643             # Because print_trace will call add 1 to it and then call
3644             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3645             # in dump_trace.
3646             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3647           )
3648         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3649
3650           # standard frame entry message
3651       )
3652       if $frame;
3653
3654     # Determine the sub's return type, and capture appropriately.
3655     if (wantarray) {
3656
3657         # Called in array context. call sub and capture output.
3658         # DB::DB will recursively get control again if appropriate; we'll come
3659         # back here when the sub is finished.
3660         {
3661             no strict 'refs';
3662             @ret = &$sub;
3663         }
3664
3665         # Pop the single-step value back off the stack.
3666         $single |= $stack[ $stack_depth-- ];
3667
3668         # Check for exit trace messages...
3669         (
3670             $frame & 4    # Extended exit message
3671             ? (
3672                 print_lineinfo( ' ' x $stack_depth, "out " ),
3673                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3674               )
3675             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3676
3677               # Standard exit message
3678           )
3679           if $frame & 2;
3680
3681         # Print the return info if we need to.
3682         if ( $doret eq $stack_depth or $frame & 16 ) {
3683
3684             # Turn off output record separator.
3685             local $\ = '';
3686             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3687
3688             # Indent if we're printing because of $frame tracing.
3689             print $fh ' ' x $stack_depth if $frame & 16;
3690
3691             # Print the return value.
3692             print $fh "list context return from $sub:\n";
3693             dumpit( $fh, \@ret );
3694
3695             # And don't print it again.
3696             $doret = -2;
3697         } ## end if ($doret eq $stack_depth...
3698             # And we have to return the return value now.
3699         @ret;
3700     } ## end if (wantarray)
3701
3702     # Scalar context.
3703     else {
3704         if ( defined wantarray ) {
3705         no strict 'refs';
3706             # Save the value if it's wanted at all.
3707             $ret = &$sub;
3708         }
3709         else {
3710         no strict 'refs';
3711             # Void return, explicitly.
3712             &$sub;
3713             undef $ret;
3714         }
3715
3716         # Pop the single-step value off the stack.
3717         $single |= $stack[ $stack_depth-- ];
3718
3719         # If we're doing exit messages...
3720         (
3721             $frame & 4    # Extended messages
3722             ? (
3723                 print_lineinfo( ' ' x $stack_depth, "out " ),
3724                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3725               )
3726             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3727
3728               # Standard messages
3729           )
3730           if $frame & 2;
3731
3732         # If we are supposed to show the return value... same as before.
3733         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3734             local $\ = '';
3735             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3736             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3737             print $fh (
3738                 defined wantarray
3739                 ? "scalar context return from $sub: "
3740                 : "void context return from $sub\n"
3741             );
3742             dumpit( $fh, $ret ) if defined wantarray;
3743             $doret = -2;
3744         } ## end if ($doret eq $stack_depth...
3745
3746         # Return the appropriate scalar value.
3747         $ret;
3748     } ## end else [ if (wantarray)
3749 } ## end sub _sub
3750
3751 sub lsub : lvalue {
3752
3753     no strict 'refs';
3754
3755         # lock ourselves under threads
3756         lock($DBGR);
3757
3758     # Whether or not the autoloader was running, a scalar to put the
3759     # sub's return value in (if needed), and an array to put the sub's
3760     # return value in (if needed).
3761     my ( $al, $ret, @ret ) = "";
3762         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3763                 print "creating new thread\n";
3764         }
3765
3766     # If the last ten characters are C'::AUTOLOAD', note we've traced
3767     # into AUTOLOAD for $sub.
3768     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3769         $al = " for $$sub";
3770     }
3771
3772     # We stack the stack pointer and then increment it to protect us
3773     # from a situation that might unwind a whole bunch of call frames
3774     # at once. Localizing the stack pointer means that it will automatically
3775     # unwind the same amount when multiple stack frames are unwound.
3776     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3777
3778     # Expand @stack.
3779     $#stack = $stack_depth;
3780
3781     # Save current single-step setting.
3782     $stack[-1] = $single;
3783
3784     # Turn off all flags except single-stepping.
3785     $single &= 1;
3786
3787     # If we've gotten really deeply recursed, turn on the flag that will
3788     # make us stop with the 'deep recursion' message.
3789     $single |= 4 if $stack_depth == $deep;
3790
3791     # If frame messages are on ...
3792     (
3793         $frame & 4    # Extended frame entry message
3794         ? (
3795             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3796
3797             # Why -1? But it works! :-(
3798             # Because print_trace will call add 1 to it and then call
3799             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3800             # in dump_trace.
3801             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3802           )
3803         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3804
3805           # standard frame entry message
3806       )
3807       if $frame;
3808
3809     # Pop the single-step value back off the stack.
3810     $single |= $stack[ $stack_depth-- ];
3811
3812     # call the original lvalue sub.
3813     &$sub;
3814 }
3815
3816 # Abstracting common code from multiple places elsewhere:
3817 sub depth_print_lineinfo {
3818     my $always_print = shift;
3819
3820     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3821 }
3822
3823 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3824
3825 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3826 Most of the changes were to systematize the command structure and to eliminate
3827 commands that threw away user input without checking.
3828
3829 The following sections describe the code added to make it easy to support
3830 multiple command sets with conflicting command names. This section is a start
3831 at unifying all command processing to make it simpler to develop commands.
3832
3833 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3834 number, and C<$dbline> (the current line) as arguments.
3835
3836 Support functions in this section which have multiple modes of failure C<die>
3837 on error; the rest simply return a false value.
3838
3839 The user-interface functions (all of the C<cmd_*> functions) just output
3840 error messages.
3841
3842 =head2 C<%set>
3843
3844 The C<%set> hash defines the mapping from command letter to subroutine
3845 name suffix.
3846
3847 C<%set> is a two-level hash, indexed by set name and then by command name.
3848 Note that trying to set the CommandSet to C<foobar> simply results in the
3849 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3850
3851 =cut
3852
3853 ### The API section
3854
3855 my %set = (    #
3856     'pre580' => {
3857         'a' => 'pre580_a',
3858         'A' => 'pre580_null',
3859         'b' => 'pre580_b',
3860         'B' => 'pre580_null',
3861         'd' => 'pre580_null',
3862         'D' => 'pre580_D',
3863         'h' => 'pre580_h',
3864         'M' => 'pre580_null',
3865         'O' => 'o',
3866         'o' => 'pre580_null',
3867         'v' => 'M',
3868         'w' => 'v',
3869         'W' => 'pre580_W',
3870     },
3871     'pre590' => {
3872         '<'  => 'pre590_prepost',
3873         '<<' => 'pre590_prepost',
3874         '>'  => 'pre590_prepost',
3875         '>>' => 'pre590_prepost',
3876         '{'  => 'pre590_prepost',
3877         '{{' => 'pre590_prepost',
3878     },
3879 );
3880
3881 my %breakpoints_data;
3882
3883 sub _has_breakpoint_data_ref {
3884     my ($filename, $line) = @_;
3885
3886     return (
3887         exists( $breakpoints_data{$filename} )
3888             and
3889         exists( $breakpoints_data{$filename}{$line} )
3890     );
3891 }
3892
3893 sub _get_breakpoint_data_ref {
3894     my ($filename, $line) = @_;
3895
3896     return ($breakpoints_data{$filename}{$line} ||= +{});
3897 }
3898
3899 sub _delete_breakpoint_data_ref {
3900     my ($filename, $line) = @_;
3901
3902     delete($breakpoints_data{$filename}{$line});
3903     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3904         delete($breakpoints_data{$filename});
3905     }
3906
3907     return;
3908 }
3909
3910 sub _set_breakpoint_enabled_status {
3911     my ($filename, $line, $status) = @_;
3912
3913     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3914         ($status ? 1 : '')
3915         ;
3916
3917     return;
3918 }
3919
3920 sub _enable_breakpoint_temp_enabled_status {
3921     my ($filename, $line) = @_;
3922
3923     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3924
3925     return;
3926 }
3927
3928 sub _cancel_breakpoint_temp_enabled_status {
3929     my ($filename, $line) = @_;
3930
3931     my $ref = _get_breakpoint_data_ref($filename, $line);
3932
3933     delete ($ref->{'temp_enabled'});
3934
3935     if (! %$ref) {
3936         _delete_breakpoint_data_ref($filename, $line);
3937     }
3938
3939     return;
3940 }
3941
3942 sub _is_breakpoint_enabled {
3943     my ($filename, $line) = @_;
3944
3945     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3946     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3947 }
3948
3949 =head2 C<cmd_wrapper()> (API)
3950
3951 C<cmd_wrapper()> allows the debugger to switch command sets
3952 depending on the value of the C<CommandSet> option.
3953
3954 It tries to look up the command in the C<%set> package-level I<lexical>
3955 (which means external entities can't fiddle with it) and create the name of
3956 the sub to call based on the value found in the hash (if it's there). I<All>
3957 of the commands to be handled in a set have to be added to C<%set>; if they
3958 aren't found, the 5.8.0 equivalent is called (if there is one).
3959
3960 This code uses symbolic references.
3961
3962 =cut
3963
3964 sub cmd_wrapper {
3965     my $cmd      = shift;
3966     my $line     = shift;
3967     my $dblineno = shift;
3968
3969     # Assemble the command subroutine's name by looking up the
3970     # command set and command name in %set. If we can't find it,
3971     # default to the older version of the command.
3972     my $call = 'cmd_'
3973       . ( $set{$CommandSet}{$cmd}
3974           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3975
3976     # Call the command subroutine, call it by name.
3977     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3978 } ## end sub cmd_wrapper
3979
3980 =head3 C<cmd_a> (command)
3981
3982 The C<a> command handles pre-execution actions. These are associated with a
3983 particular line, so they're stored in C<%dbline>. We default to the current
3984 line if none is specified.
3985
3986 =cut
3987
3988 sub cmd_a {
3989     my $cmd    = shift;
3990     my $line   = shift || '';    # [.|line] expr
3991     my $dbline = shift;
3992
3993     # If it's dot (here), or not all digits,  use the current line.
3994     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3995
3996     # Should be a line number followed by an expression.
3997     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3998         my ( $lineno, $expr ) = ( $1, $2 );
3999
4000         # If we have an expression ...
4001         if ( length $expr ) {
4002
4003             # ... but the line isn't breakable, complain.
4004             if ( $dbline[$lineno] == 0 ) {
4005                 print $OUT
4006                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4007             }
4008             else {
4009
4010                 # It's executable. Record that the line has an action.
4011                 $had_breakpoints{$filename} |= 2;
4012
4013                 # Remove any action, temp breakpoint, etc.
4014                 $dbline{$lineno} =~ s/\0[^\0]*//;
4015
4016                 # Add the action to the line.
4017                 $dbline{$lineno} .= "\0" . action($expr);
4018
4019                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4020             }
4021         } ## end if (length $expr)
4022     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4023     else {
4024
4025         # Syntax wrong.
4026         print $OUT
4027           "Adding an action requires an optional lineno and an expression\n"
4028           ;    # hint
4029     }
4030 } ## end sub cmd_a
4031
4032 =head3 C<cmd_A> (command)
4033
4034 Delete actions. Similar to above, except the delete code is in a separate
4035 subroutine, C<delete_action>.
4036
4037 =cut
4038
4039 sub cmd_A {
4040     my $cmd    = shift;
4041     my $line   = shift || '';
4042     my $dbline = shift;
4043
4044     # Dot is this line.
4045     $line =~ s/^\./$dbline/;
4046
4047     # Call delete_action with a null param to delete them all.
4048     # The '1' forces the eval to be true. It'll be false only
4049     # if delete_action blows up for some reason, in which case
4050     # we print $@ and get out.
4051     if ( $line eq '*' ) {
4052         eval { &delete_action(); 1 } or print $OUT $@ and return;
4053     }
4054
4055     # There's a real line  number. Pass it to delete_action.
4056     # Error trapping is as above.
4057     elsif ( $line =~ /^(\S.*)/ ) {
4058         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4059     }
4060
4061     # Swing and a miss. Bad syntax.
4062     else {
4063         print $OUT
4064           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4065     }
4066 } ## end sub cmd_A
4067
4068 =head3 C<delete_action> (API)
4069
4070 C<delete_action> accepts either a line number or C<undef>. If a line number
4071 is specified, we check for the line being executable (if it's not, it
4072 couldn't have had an  action). If it is, we just take the action off (this
4073 will get any kind of an action, including breakpoints).
4074
4075 =cut
4076
4077 sub delete_action {
4078     my $i = shift;
4079     if ( defined($i) ) {
4080
4081         # Can there be one?
4082         die "Line $i has no action .\n" if $dbline[$i] == 0;
4083
4084         # Nuke whatever's there.
4085         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4086         delete $dbline{$i} if $dbline{$i} eq '';
4087     }
4088     else {
4089         print $OUT "Deleting all actions...\n";
4090         for my $file ( keys %had_breakpoints ) {
4091             local *dbline = $main::{ '_<' . $file };
4092             $max = $#dbline;
4093             my $was;
4094             for $i (1 .. $max) {
4095                 if ( defined $dbline{$i} ) {
4096                     $dbline{$i} =~ s/\0[^\0]*//;
4097                     delete $dbline{$i} if $dbline{$i} eq '';
4098                 }
4099                 unless ( $had_breakpoints{$file} &= ~2 ) {
4100                     delete $had_breakpoints{$file};
4101                 }
4102             } ## end for ($i = 1 .. $max)
4103         } ## end for my $file (keys %had_breakpoints)
4104     } ## end else [ if (defined($i))
4105 } ## end sub delete_action
4106
4107 =head3 C<cmd_b> (command)
4108
4109 Set breakpoints. Since breakpoints can be set in so many places, in so many
4110 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4111 we try to parse the command type, and then shuttle it off to an appropriate
4112 subroutine to actually do the work of setting the breakpoint in the right
4113 place.
4114
4115 =cut
4116
4117 sub cmd_b {
4118     my $cmd    = shift;
4119     my $line   = shift;    # [.|line] [cond]
4120     my $dbline = shift;
4121
4122     # Make . the current line number if it's there..
4123     $line =~ s/^\.(\s|\z)/$dbline$1/;
4124
4125     # No line number, no condition. Simple break on current line.
4126     if ( $line =~ /^\s*$/ ) {
4127         &cmd_b_line( $dbline, 1 );
4128     }
4129
4130     # Break on load for a file.
4131     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4132         my $file = $1;
4133         $file =~ s/\s+$//;
4134         &cmd_b_load($file);
4135     }
4136
4137     # b compile|postpone <some sub> [<condition>]
4138     # The interpreter actually traps this one for us; we just put the
4139     # necessary condition in the %postponed hash.
4140     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4141
4142         # Capture the condition if there is one. Make it true if none.
4143         my $cond = length $3 ? $3 : '1';
4144
4145         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4146         # if it was 'compile'.
4147         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4148
4149         # De-Perl4-ify the name - ' separators to ::.
4150         $subname =~ s/\'/::/g;
4151
4152         # Qualify it into the current package unless it's already qualified.
4153         $subname = "${package}::" . $subname unless $subname =~ /::/;
4154
4155         # Add main if it starts with ::.
4156         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4157
4158         # Save the break type for this sub.
4159         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4160     } ## end elsif ($line =~ ...
4161     # b <filename>:<line> [<condition>]
4162     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4163         my ($filename, $line_num, $cond) = ($1, $2, $3);
4164         cmd_b_filename_line(
4165             $filename,
4166             $line_num,
4167             (length($cond) ? $cond : '1'),
4168         );
4169     }
4170     # b <sub name> [<condition>]
4171     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4172
4173         #
4174         $subname = $1;
4175         my $cond = length $2 ? $2 : '1';
4176         &cmd_b_sub( $subname, $cond );
4177     }
4178
4179     # b <line> [<condition>].
4180     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4181
4182         # Capture the line. If none, it's the current line.
4183         $line = $1 || $dbline;
4184
4185         # If there's no condition, make it '1'.
4186         my $cond = length $2 ? $2 : '1';
4187
4188         # Break on line.
4189         &cmd_b_line( $line, $cond );
4190     }
4191
4192     # Line didn't make sense.
4193     else {
4194         print "confused by line($line)?\n";
4195     }
4196 } ## end sub cmd_b
4197
4198 =head3 C<break_on_load> (API)
4199
4200 We want to break when this file is loaded. Mark this file in the
4201 C<%break_on_load> hash, and note that it has a breakpoint in
4202 C<%had_breakpoints>.
4203
4204 =cut
4205
4206 sub break_on_load {
4207     my $file = shift;
4208     $break_on_load{$file} = 1;
4209     $had_breakpoints{$file} |= 1;
4210 }
4211
4212 =head3 C<report_break_on_load> (API)
4213
4214 Gives us an array of filenames that are set to break on load. Note that
4215 only files with break-on-load are in here, so simply showing the keys
4216 suffices.
4217
4218 =cut
4219
4220 sub report_break_on_load {
4221     sort keys %break_on_load;
4222 }
4223
4224 =head3 C<cmd_b_load> (command)
4225
4226 We take the file passed in and try to find it in C<%INC> (which maps modules
4227 to files they came from). We mark those files for break-on-load via
4228 C<break_on_load> and then report that it was done.
4229
4230 =cut
4231
4232 sub cmd_b_load {
4233     my $file = shift;
4234     my @files;
4235
4236     # This is a block because that way we can use a redo inside it
4237     # even without there being any looping structure at all outside it.
4238     {
4239
4240         # Save short name and full path if found.
4241         push @files, $file;
4242         push @files, $::INC{$file} if $::INC{$file};
4243
4244         # Tack on .pm and do it again unless there was a '.' in the name
4245         # already.
4246         $file .= '.pm', redo unless $file =~ /\./;
4247     }
4248
4249     # Do the real work here.
4250     break_on_load($_) for @files;
4251
4252     # All the files that have break-on-load breakpoints.
4253     @files = report_break_on_load;
4254
4255     # Normalize for the purposes of our printing this.
4256     local $\ = '';
4257     local $" = ' ';
4258     print $OUT "Will stop on load of '@files'.\n";
4259 } ## end sub cmd_b_load
4260
4261 =head3 C<$filename_error> (API package global)
4262
4263 Several of the functions we need to implement in the API need to work both
4264 on the current file and on other files. We don't want to duplicate code, so
4265 C<$filename_error> is used to contain the name of the file that's being
4266 worked on (if it's not the current one).
4267
4268 We can now build functions in pairs: the basic function works on the current
4269 file, and uses C<$filename_error> as part of its error message. Since this is
4270 initialized to C<"">, no filename will appear when we are working on the
4271 current file.
4272
4273 The second function is a wrapper which does the following:
4274
4275 =over 4
4276
4277 =item *
4278
4279 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4280
4281 =item *
4282
4283 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4284
4285 =item *
4286
4287 Calls the first function.
4288
4289 The first function works on the I<current> file (i.e., the one we changed to),
4290 and prints C<$filename_error> in the error message (the name of the other file)
4291 if it needs to. When the functions return, C<*dbline> is restored to point
4292 to the actual current file (the one we're executing in) and
4293 C<$filename_error> is restored to C<"">. This restores everything to
4294 the way it was before the second function was called at all.
4295
4296 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4297 details.
4298
4299 =back
4300
4301 =cut
4302
4303 use vars qw($filename_error);
4304 $filename_error = '';
4305
4306 =head3 breakable_line(from, to) (API)
4307
4308 The subroutine decides whether or not a line in the current file is breakable.
4309 It walks through C<@dbline> within the range of lines specified, looking for
4310 the first line that is breakable.
4311
4312 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4313 first line I<after> C<$to> that's breakable, if there is one.
4314
4315 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4316 first line I<before> C<$to> that's breakable, if there is one.
4317
4318 =cut
4319
4320 sub breakable_line {
4321
4322     my ( $from, $to ) = @_;
4323
4324     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4325     my $i = $from;
4326
4327     # If there are at least 2 arguments, we're trying to search a range.
4328     if ( @_ >= 2 ) {
4329
4330         # $delta is positive for a forward search, negative for a backward one.
4331         my $delta = $from < $to ? +1 : -1;
4332
4333         # Keep us from running off the ends of the file.
4334         my $limit = $delta > 0 ? $#dbline : 1;
4335
4336         # Clever test. If you're a mathematician, it's obvious why this
4337         # test works. If not:
4338         # If $delta is positive (going forward), $limit will be $#dbline.
4339         #    If $to is less than $limit, ($limit - $to) will be positive, times
4340         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4341         #    as the stopping point.
4342         #
4343         #    If $to is greater than $limit, ($limit - $to) is negative,
4344         #    times $delta of 1 (positive), so the result is < 0 and we should
4345         #    use $limit ($#dbline) as the stopping point.
4346         #
4347         # If $delta is negative (going backward), $limit will be 1.
4348         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4349         #    (negative) so the result is > 0, and we use $to as the stopping
4350         #    point.
4351         #
4352         #    If $to is less than zero, ($limit - $to) will be positive,
4353         #    times $delta of -1 (negative), so the result is not > 0, and
4354         #    we use $limit (1) as the stopping point.
4355         #
4356         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4357         #    (negative), still giving zero; the result is not > 0, and
4358         #    we use $limit (1) as the stopping point.
4359         #
4360         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4361         #    (negative), giving a positive (>0) value, so we'll set $limit to
4362         #    $to.
4363
4364         $limit = $to if ( $limit - $to ) * $delta > 0;
4365
4366         # The real search loop.
4367         # $i starts at $from (the point we want to start searching from).
4368         # We move through @dbline in the appropriate direction (determined
4369         # by $delta: either -1 (back) or +1 (ahead).
4370         # We stay in as long as we haven't hit an executable line
4371         # ($dbline[$i] == 0 means not executable) and we haven't reached
4372         # the limit yet (test similar to the above).
4373         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4374
4375     } ## end if (@_ >= 2)
4376
4377     # If $i points to a line that is executable, return that.
4378     return $i unless $dbline[$i] == 0;
4379
4380     # Format the message and print it: no breakable lines in range.
4381     my ( $pl, $upto ) = ( '', '' );
4382     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4383
4384     # If there's a filename in filename_error, we'll see it.
4385     # If not, not.
4386     die "Line$pl $from$upto$filename_error not breakable\n";
4387 } ## end sub breakable_line
4388
4389 =head3 breakable_line_in_filename(file, from, to) (API)
4390
4391 Like C<breakable_line>, but look in another file.
4392
4393 =cut
4394
4395 sub breakable_line_in_filename {
4396
4397     # Capture the file name.
4398     my ($f) = shift;
4399
4400     # Swap the magic line array over there temporarily.
4401     local *dbline = $main::{ '_<' . $f };
4402
4403     # If there's an error, it's in this other file.
4404     local $filename_error = " of '$f'";
4405
4406     # Find the breakable line.
4407     breakable_line(@_);
4408
4409     # *dbline and $filename_error get restored when this block ends.
4410
4411 } ## end sub breakable_line_in_filename
4412
4413 =head3 break_on_line(lineno, [condition]) (API)
4414
4415 Adds a breakpoint with the specified condition (or 1 if no condition was
4416 specified) to the specified line. Dies if it can't.
4417
4418 =cut
4419
4420 sub break_on_line {
4421     my ( $i, $cond ) = @_;
4422
4423     # Always true if no condition supplied.
4424     $cond = 1 unless @_ >= 2;
4425
4426     my $inii  = $i;
4427     my $after = '';
4428     my $pl    = '';
4429
4430     # Woops, not a breakable line. $filename_error allows us to say
4431     # if it was in a different file.
4432     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4433
4434     # Mark this file as having breakpoints in it.
4435     $had_breakpoints{$filename} |= 1;
4436
4437     # If there is an action or condition here already ...
4438     if ( $dbline{$i} ) {
4439
4440         # ... swap this condition for the existing one.
4441         $dbline{$i} =~ s/^[^\0]*/$cond/;
4442     }
4443     else {
4444
4445         # Nothing here - just add the condition.
4446         $dbline{$i} = $cond;
4447
4448         _set_breakpoint_enabled_status($filename, $i, 1);
4449     }
4450 } ## end sub break_on_line
4451
4452 =head3 cmd_b_line(line, [condition]) (command)
4453
4454 Wrapper for C<break_on_line>. Prints the failure message if it
4455 doesn't work.
4456
4457 =cut
4458
4459 sub cmd_b_line {
4460     if (not eval { break_on_line(@_); 1 }) {
4461         local $\ = '';
4462         print $OUT $@ and return;
4463     }
4464
4465     return;
4466 } ## end sub cmd_b_line
4467
4468 =head3 cmd_b_filename_line(line, [condition]) (command)
4469
4470 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4471 doesn't work.
4472
4473 =cut
4474
4475 sub cmd_b_filename_line {
4476     if (not eval { break_on_filename_line(@_); 1 }) {
4477         local $\ = '';
4478         print $OUT $@ and return;
4479     }
4480
4481     return;
4482 }
4483
4484 =head3 break_on_filename_line(file, line, [condition]) (API)
4485
4486 Switches to the file specified and then calls C<break_on_line> to set
4487 the breakpoint.
4488
4489 =cut
4490
4491 sub break_on_filename_line {
4492     my ( $f, $i, $cond ) = @_;
4493
4494     # Always true if condition left off.
4495     $cond = 1 unless @_ >= 3;
4496
4497     # Switch the magical hash temporarily.
4498     local *dbline = $main::{ '_<' . $f };
4499
4500     # Localize the variables that break_on_line uses to make its message.
4501     local $filename_error = " of '$f'";
4502     local $filename       = $f;
4503
4504     # Add the breakpoint.
4505     break_on_line( $i, $cond );
4506 } ## end sub break_on_filename_line
4507
4508 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4509
4510 Switch to another file, search the range of lines specified for an
4511 executable one, and put a breakpoint on the first one you find.
4512
4513 =cut
4514
4515 sub break_on_filename_line_range {
4516     my ( $f, $from, $to, $cond ) = @_;
4517
4518     # Find a breakable line if there is one.
4519     my $i = breakable_line_in_filename( $f, $from, $to );
4520
4521     # Always true if missing.
4522     $cond = 1 unless @_ >= 3;
4523
4524     # Add the breakpoint.
4525     break_on_filename_line( $f, $i, $cond );
4526 } ## end sub break_on_filename_line_range
4527
4528 =head3 subroutine_filename_lines(subname, [condition]) (API)
4529
4530 Search for a subroutine within a given file. The condition is ignored.
4531 Uses C<find_sub> to locate the desired subroutine.
4532
4533 =cut
4534
4535 sub subroutine_filename_lines {
4536     my ( $subname, $cond ) = @_;
4537
4538     # Returned value from find_sub() is fullpathname:startline-endline.
4539     # The match creates the list (fullpathname, start, end). Falling off