This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
c7e683a48f48e4e4fcf2a038d86a8dffedddf2ee
[perl5.git] / pod / perllocale.pod
1 =encoding utf8
2
3 =head1 NAME
4
5 perllocale - Perl locale handling (internationalization and localization)
6
7 =head1 DESCRIPTION
8
9 In the beginning there was ASCII, the "American Standard Code for
10 Information Interchange", which works quite well for Americans with
11 their English alphabet and dollar-denominated currency.  But it doesn't
12 work so well even for other English speakers, who may use different
13 currencies, such as the pound sterling (as the symbol for that currency
14 is not in ASCII); and it's hopelessly inadequate for many of the
15 thousands of the world's other languages.
16
17 To address these deficiencies, the concept of locales was invented
18 (formally the ISO C, XPG4, POSIX 1.c "locale system").  And applications
19 were and are being written that use the locale mechanism.  The process of
20 making such an application take account of its users' preferences in
21 these kinds of matters is called B<internationalization> (often
22 abbreviated as B<i18n>); telling such an application about a particular
23 set of preferences is known as B<localization> (B<l10n>).
24
25 Perl has been extended to support certain types of locales available in
26 the locale system.  This is controlled per application by using one
27 pragma, one function call, and several environment variables.
28
29 Perl supports single-byte locales that are supersets of ASCII, such as
30 the ISO 8859 ones, and one multi-byte-type locale, UTF-8 ones, described
31 in the next paragraph.  Perl doesn't support any other multi-byte
32 locales, such as the ones for East Asian languages.
33
34 Unfortunately, there are quite a few deficiencies with the design (and
35 often, the implementations) of locales.  Unicode was invented (see
36 L<perlunitut> for an introduction to that) in part to address these
37 design deficiencies, and nowadays, there is a series of "UTF-8
38 locales", based on Unicode.  These are locales whose character set is
39 Unicode, encoded in UTF-8.  Starting in v5.20, Perl fully supports
40 UTF-8 locales, except for sorting and string comparisons like C<lt> and
41 C<ge>.  Starting in v5.26, Perl can handle these reasonably as well,
42 depending on the platform's implementation.  However, for earlier
43 releases or for better control, use L<Unicode::Collate>.  Perl continues to
44 support the old non UTF-8 locales as well.  There are currently no UTF-8
45 locales for EBCDIC platforms.
46
47 (Unicode is also creating C<CLDR>, the "Common Locale Data Repository",
48 L<http://cldr.unicode.org/> which includes more types of information than
49 are available in the POSIX locale system.  At the time of this writing,
50 there was no CPAN module that provides access to this XML-encoded data.
51 However, it is possible to compute the POSIX locale data from them, and
52 earlier CLDR versions had these already extracted for you as UTF-8 locales
53 L<http://unicode.org/Public/cldr/2.0.1/>.)
54
55 =head1 WHAT IS A LOCALE
56
57 A locale is a set of data that describes various aspects of how various
58 communities in the world categorize their world.  These categories are
59 broken down into the following types (some of which include a brief
60 note here):
61
62 =over
63
64 =item Category C<LC_NUMERIC>: Numeric formatting
65
66 This indicates how numbers should be formatted for human readability,
67 for example the character used as the decimal point.
68
69 =item Category C<LC_MONETARY>: Formatting of monetary amounts
70
71 =for comment
72 The nbsp below makes this look better (though not great)
73
74 E<160>
75
76 =item Category C<LC_TIME>: Date/Time formatting
77
78 =for comment
79 The nbsp below makes this look better (though not great)
80
81 E<160>
82
83 =item Category C<LC_MESSAGES>: Error and other messages
84
85 This is used by Perl itself only for accessing operating system error
86 messages via L<$!|perlvar/$ERRNO> and L<$^E|perlvar/$EXTENDED_OS_ERROR>.
87
88 =item Category C<LC_COLLATE>: Collation
89
90 This indicates the ordering of letters for comparison and sorting.
91 In Latin alphabets, for example, "b", generally follows "a".
92
93 =item Category C<LC_CTYPE>: Character Types
94
95 This indicates, for example if a character is an uppercase letter.
96
97 =item Other categories
98
99 Some platforms have other categories, dealing with such things as
100 measurement units and paper sizes.  None of these are used directly by
101 Perl, but outside operations that Perl interacts with may use
102 these.  See L</Not within the scope of "use locale"> below.
103
104 =back
105
106 More details on the categories used by Perl are given below in L</LOCALE
107 CATEGORIES>.
108
109 Together, these categories go a long way towards being able to customize
110 a single program to run in many different locations.  But there are
111 deficiencies, so keep reading.
112
113 =head1 PREPARING TO USE LOCALES
114
115 Perl itself (outside the L<POSIX> module) will not use locales unless
116 specifically requested to (but
117 again note that Perl may interact with code that does use them).  Even
118 if there is such a request, B<all> of the following must be true
119 for it to work properly:
120
121 =over 4
122
123 =item *
124
125 B<Your operating system must support the locale system>.  If it does,
126 you should find that the C<setlocale()> function is a documented part of
127 its C library.
128
129 =item *
130
131 B<Definitions for locales that you use must be installed>.  You, or
132 your system administrator, must make sure that this is the case. The
133 available locales, the location in which they are kept, and the manner
134 in which they are installed all vary from system to system.  Some systems
135 provide only a few, hard-wired locales and do not allow more to be
136 added.  Others allow you to add "canned" locales provided by the system
137 supplier.  Still others allow you or the system administrator to define
138 and add arbitrary locales.  (You may have to ask your supplier to
139 provide canned locales that are not delivered with your operating
140 system.)  Read your system documentation for further illumination.
141
142 =item *
143
144 B<Perl must believe that the locale system is supported>.  If it does,
145 C<perl -V:d_setlocale> will say that the value for C<d_setlocale> is
146 C<define>.
147
148 =back
149
150 If you want a Perl application to process and present your data
151 according to a particular locale, the application code should include
152 the S<C<use locale>> pragma (see L</The "use locale" pragma>) where
153 appropriate, and B<at least one> of the following must be true:
154
155 =over 4
156
157 =item 1
158
159 B<The locale-determining environment variables (see L</"ENVIRONMENT">)
160 must be correctly set up> at the time the application is started, either
161 by yourself or by whomever set up your system account; or
162
163 =item 2
164
165 B<The application must set its own locale> using the method described in
166 L</The setlocale function>.
167
168 =back
169
170 =head1 USING LOCALES
171
172 =head2 The C<"use locale"> pragma
173
174 WARNING!  Do NOT use this pragma in scripts that have multiple
175 L<threads|threads> active.  The locale is not local to a single thread.
176 Another thread may change the locale at any time, which could cause at a
177 minimum that a given thread is operating in a locale it isn't expecting
178 to be in.  On some platforms, segfaults can also occur.  The locale
179 change need not be explicit; some operations cause perl to change the
180 locale itself.  You are vulnerable simply by having done a C<"use
181 locale">.
182
183 By default, Perl itself (outside the L<POSIX> module)
184 ignores the current locale.  The S<C<use locale>>
185 pragma tells Perl to use the current locale for some operations.
186 Starting in v5.16, there are optional parameters to this pragma,
187 described below, which restrict which operations are affected by it.
188
189 The current locale is set at execution time by
190 L<setlocale()|/The setlocale function> described below.  If that function
191 hasn't yet been called in the course of the program's execution, the
192 current locale is that which was determined by the L</"ENVIRONMENT"> in
193 effect at the start of the program.
194 If there is no valid environment, the current locale is whatever the
195 system default has been set to.   On POSIX systems, it is likely, but
196 not necessarily, the "C" locale.  On Windows, the default is set via the
197 computer's S<C<Control Panel-E<gt>Regional and Language Options>> (or its
198 current equivalent).
199
200 The operations that are affected by locale are:
201
202 =over 4
203
204 =item B<Not within the scope of C<"use locale">>
205
206 Only certain operations originating outside Perl should be affected, as
207 follows:
208
209 =over 4
210
211 =item *
212
213 The current locale is used when going outside of Perl with
214 operations like L<system()|perlfunc/system LIST> or
215 L<qxE<sol>E<sol>|perlop/qxE<sol>STRINGE<sol>>, if those operations are
216 locale-sensitive.
217
218 =item *
219
220 Also Perl gives access to various C library functions through the
221 L<POSIX> module.  Some of those functions are always affected by the
222 current locale.  For example, C<POSIX::strftime()> uses C<LC_TIME>;
223 C<POSIX::strtod()> uses C<LC_NUMERIC>; C<POSIX::strcoll()> and
224 C<POSIX::strxfrm()> use C<LC_COLLATE>.  All such functions
225 will behave according to the current underlying locale, even if that
226 locale isn't exposed to Perl space.
227
228 This applies as well to L<I18N::Langinfo>.
229
230 =item *
231
232 XS modules for all categories but C<LC_NUMERIC> get the underlying
233 locale, and hence any C library functions they call will use that
234 underlying locale.  For more discussion, see L<perlxs/CAVEATS>.
235
236 =back
237
238 Note that all C programs (including the perl interpreter, which is
239 written in C) always have an underlying locale.  That locale is the "C"
240 locale unless changed by a call to L<setlocale()|/The setlocale
241 function>.  When Perl starts up, it changes the underlying locale to the
242 one which is indicated by the L</ENVIRONMENT>.  When using the L<POSIX>
243 module or writing XS code, it is important to keep in mind that the
244 underlying locale may be something other than "C", even if the program
245 hasn't explicitly changed it.
246
247 =for comment
248 The nbsp below makes this look better (though not great)
249
250 E<160>
251
252 =item B<Lingering effects of C<S<use locale>>>
253
254 Certain Perl operations that are set-up within the scope of a
255 C<use locale> retain that effect even outside the scope.
256 These include:
257
258 =over 4
259
260 =item *
261
262 The output format of a L<write()|perlfunc/write> is determined by an
263 earlier format declaration (L<perlfunc/format>), so whether or not the
264 output is affected by locale is determined by if the C<format()> is
265 within the scope of a C<use locale>, not whether the C<write()>
266 is.
267
268 =item *
269
270 Regular expression patterns can be compiled using
271 L<qrE<sol>E<sol>|perlop/qrE<sol>STRINGE<sol>msixpodualn> with actual
272 matching deferred to later.  Again, it is whether or not the compilation
273 was done within the scope of C<use locale> that determines the match
274 behavior, not if the matches are done within such a scope or not.
275
276 =back
277
278 =for comment
279 The nbsp below makes this look better (though not great)
280
281
282 E<160>
283
284 =item B<Under C<"use locale";>>
285
286 =over 4
287
288 =item *
289
290 All the above operations
291
292 =item *
293
294 B<Format declarations> (L<perlfunc/format>) and hence any subsequent
295 C<write()>s use C<LC_NUMERIC>.
296
297 =item *
298
299 B<stringification and output> use C<LC_NUMERIC>.
300 These include the results of
301 C<print()>,
302 C<printf()>,
303 C<say()>,
304 and
305 C<sprintf()>.
306
307 =item *
308
309 B<The comparison operators> (C<lt>, C<le>, C<cmp>, C<ge>, and C<gt>) use
310 C<LC_COLLATE>.  C<sort()> is also affected if used without an
311 explicit comparison function, because it uses C<cmp> by default.
312
313 B<Note:> C<eq> and C<ne> are unaffected by locale: they always
314 perform a char-by-char comparison of their scalar operands.  What's
315 more, if C<cmp> finds that its operands are equal according to the
316 collation sequence specified by the current locale, it goes on to
317 perform a char-by-char comparison, and only returns I<0> (equal) if the
318 operands are char-for-char identical.  If you really want to know whether
319 two strings--which C<eq> and C<cmp> may consider different--are equal
320 as far as collation in the locale is concerned, see the discussion in
321 L<Category C<LC_COLLATE>: Collation>.
322
323 =item *
324
325 B<Regular expressions and case-modification functions> (C<uc()>, C<lc()>,
326 C<ucfirst()>, and C<lcfirst()>) use C<LC_CTYPE>
327
328 =item *
329
330 B<The variables L<$!|perlvar/$ERRNO>> (and its synonyms C<$ERRNO> and
331 C<$OS_ERROR>) B<and L<$^E|perlvar/$EXTENDED_OS_ERROR>> (and its synonym
332 C<$EXTENDED_OS_ERROR>) when used as strings use C<LC_MESSAGES>.
333
334 =back
335
336 =back
337
338 The default behavior is restored with the S<C<no locale>> pragma, or
339 upon reaching the end of the block enclosing C<use locale>.
340 Note that C<use locale> calls may be
341 nested, and that what is in effect within an inner scope will revert to
342 the outer scope's rules at the end of the inner scope.
343
344 The string result of any operation that uses locale
345 information is tainted, as it is possible for a locale to be
346 untrustworthy.  See L</"SECURITY">.
347
348 Starting in Perl v5.16 in a very limited way, and more generally in
349 v5.22, you can restrict which category or categories are enabled by this
350 particular instance of the pragma by adding parameters to it.  For
351 example,
352
353  use locale qw(:ctype :numeric);
354
355 enables locale awareness within its scope of only those operations
356 (listed above) that are affected by C<LC_CTYPE> and C<LC_NUMERIC>.
357
358 The possible categories are: C<:collate>, C<:ctype>, C<:messages>,
359 C<:monetary>, C<:numeric>, C<:time>, and the pseudo category
360 C<:characters> (described below).
361
362 Thus you can say
363
364  use locale ':messages';
365
366 and only L<$!|perlvar/$ERRNO> and L<$^E|perlvar/$EXTENDED_OS_ERROR>
367 will be locale aware.  Everything else is unaffected.
368
369 Since Perl doesn't currently do anything with the C<LC_MONETARY>
370 category, specifying C<:monetary> does effectively nothing.  Some
371 systems have other categories, such as C<LC_PAPER_SIZE>, but Perl
372 also doesn't know anything about them, and there is no way to specify
373 them in this pragma's arguments.
374
375 You can also easily say to use all categories but one, by either, for
376 example,
377
378  use locale ':!ctype';
379  use locale ':not_ctype';
380
381 both of which mean to enable locale awarness of all categories but
382 C<LC_CTYPE>.  Only one category argument may be specified in a
383 S<C<use locale>> if it is of the negated form.
384
385 Prior to v5.22 only one form of the pragma with arguments is available:
386
387  use locale ':not_characters';
388
389 (and you have to say C<not_>; you can't use the bang C<!> form).  This
390 pseudo category is a shorthand for specifying both C<:collate> and
391 C<:ctype>.  Hence, in the negated form, it is nearly the same thing as
392 saying
393
394  use locale qw(:messages :monetary :numeric :time);
395
396 We use the term "nearly", because C<:not_characters> also turns on
397 S<C<use feature 'unicode_strings'>> within its scope.  This form is
398 less useful in v5.20 and later, and is described fully in
399 L</Unicode and UTF-8>, but briefly, it tells Perl to not use the
400 character portions of the locale definition, that is the C<LC_CTYPE> and
401 C<LC_COLLATE> categories.  Instead it will use the native character set
402 (extended by Unicode).  When using this parameter, you are responsible
403 for getting the external character set translated into the
404 native/Unicode one (which it already will be if it is one of the
405 increasingly popular UTF-8 locales).  There are convenient ways of doing
406 this, as described in L</Unicode and UTF-8>.
407
408 =head2 The setlocale function
409
410 WARNING!  Do NOT use this function in a L<thread|threads>.  The locale
411 will change in all other threads at the same time, and should your
412 thread get paused by the operating system, and another started, that
413 thread will not have the locale it is expecting.  On some platforms,
414 there can be a race leading to segfaults if two threads call this
415 function nearly simultaneously.
416
417 You can switch locales as often as you wish at run time with the
418 C<POSIX::setlocale()> function:
419
420         # Import locale-handling tool set from POSIX module.
421         # This example uses: setlocale -- the function call
422         #                    LC_CTYPE -- explained below
423         # (Showing the testing for success/failure of operations is
424         # omitted in these examples to avoid distracting from the main
425         # point)
426
427         use POSIX qw(locale_h);
428         use locale;
429         my $old_locale;
430
431         # query and save the old locale
432         $old_locale = setlocale(LC_CTYPE);
433
434         setlocale(LC_CTYPE, "fr_CA.ISO8859-1");
435         # LC_CTYPE now in locale "French, Canada, codeset ISO 8859-1"
436
437         setlocale(LC_CTYPE, "");
438         # LC_CTYPE now reset to the default defined by the
439         # LC_ALL/LC_CTYPE/LANG environment variables, or to the system
440         # default.  See below for documentation.
441
442         # restore the old locale
443         setlocale(LC_CTYPE, $old_locale);
444
445 The first argument of C<setlocale()> gives the B<category>, the second the
446 B<locale>.  The category tells in what aspect of data processing you
447 want to apply locale-specific rules.  Category names are discussed in
448 L</LOCALE CATEGORIES> and L</"ENVIRONMENT">.  The locale is the name of a
449 collection of customization information corresponding to a particular
450 combination of language, country or territory, and codeset.  Read on for
451 hints on the naming of locales: not all systems name locales as in the
452 example.
453
454 If no second argument is provided and the category is something other
455 than C<LC_ALL>, the function returns a string naming the current locale
456 for the category.  You can use this value as the second argument in a
457 subsequent call to C<setlocale()>, B<but> on some platforms the string
458 is opaque, not something that most people would be able to decipher as
459 to what locale it means.
460
461 If no second argument is provided and the category is C<LC_ALL>, the
462 result is implementation-dependent.  It may be a string of
463 concatenated locale names (separator also implementation-dependent)
464 or a single locale name.  Please consult your L<setlocale(3)> man page for
465 details.
466
467 If a second argument is given and it corresponds to a valid locale,
468 the locale for the category is set to that value, and the function
469 returns the now-current locale value.  You can then use this in yet
470 another call to C<setlocale()>.  (In some implementations, the return
471 value may sometimes differ from the value you gave as the second
472 argument--think of it as an alias for the value you gave.)
473
474 As the example shows, if the second argument is an empty string, the
475 category's locale is returned to the default specified by the
476 corresponding environment variables.  Generally, this results in a
477 return to the default that was in force when Perl started up: changes
478 to the environment made by the application after startup may or may not
479 be noticed, depending on your system's C library.
480
481 Note that when a form of C<use locale> that doesn't include all
482 categories is specified, Perl ignores the excluded categories.
483
484 If C<set_locale()> fails for some reason (for example, an attempt to set
485 to a locale unknown to the system), the locale for the category is not
486 changed, and the function returns C<undef>.
487
488
489 For further information about the categories, consult L<setlocale(3)>.
490
491 =head2 Finding locales
492
493 For locales available in your system, consult also L<setlocale(3)> to
494 see whether it leads to the list of available locales (search for the
495 I<SEE ALSO> section).  If that fails, try the following command lines:
496
497         locale -a
498
499         nlsinfo
500
501         ls /usr/lib/nls/loc
502
503         ls /usr/lib/locale
504
505         ls /usr/lib/nls
506
507         ls /usr/share/locale
508
509 and see whether they list something resembling these
510
511         en_US.ISO8859-1     de_DE.ISO8859-1     ru_RU.ISO8859-5
512         en_US.iso88591      de_DE.iso88591      ru_RU.iso88595
513         en_US               de_DE               ru_RU
514         en                  de                  ru
515         english             german              russian
516         english.iso88591    german.iso88591     russian.iso88595
517         english.roman8                          russian.koi8r
518
519 Sadly, even though the calling interface for C<setlocale()> has been
520 standardized, names of locales and the directories where the
521 configuration resides have not been.  The basic form of the name is
522 I<language_territory>B<.>I<codeset>, but the latter parts after
523 I<language> are not always present.  The I<language> and I<country>
524 are usually from the standards B<ISO 3166> and B<ISO 639>, the
525 two-letter abbreviations for the countries and the languages of the
526 world, respectively.  The I<codeset> part often mentions some B<ISO
527 8859> character set, the Latin codesets.  For example, C<ISO 8859-1>
528 is the so-called "Western European codeset" that can be used to encode
529 most Western European languages adequately.  Again, there are several
530 ways to write even the name of that one standard.  Lamentably.
531
532 Two special locales are worth particular mention: "C" and "POSIX".
533 Currently these are effectively the same locale: the difference is
534 mainly that the first one is defined by the C standard, the second by
535 the POSIX standard.  They define the B<default locale> in which
536 every program starts in the absence of locale information in its
537 environment.  (The I<default> default locale, if you will.)  Its language
538 is (American) English and its character codeset ASCII or, rarely, a
539 superset thereof (such as the "DEC Multinational Character Set
540 (DEC-MCS)").  B<Warning>. The C locale delivered by some vendors
541 may not actually exactly match what the C standard calls for.  So
542 beware.
543
544 B<NOTE>: Not all systems have the "POSIX" locale (not all systems are
545 POSIX-conformant), so use "C" when you need explicitly to specify this
546 default locale.
547
548 =head2 LOCALE PROBLEMS
549
550 You may encounter the following warning message at Perl startup:
551
552         perl: warning: Setting locale failed.
553         perl: warning: Please check that your locale settings:
554                 LC_ALL = "En_US",
555                 LANG = (unset)
556             are supported and installed on your system.
557         perl: warning: Falling back to the standard locale ("C").
558
559 This means that your locale settings had C<LC_ALL> set to "En_US" and
560 LANG exists but has no value.  Perl tried to believe you but could not.
561 Instead, Perl gave up and fell back to the "C" locale, the default locale
562 that is supposed to work no matter what.  (On Windows, it first tries
563 falling back to the system default locale.)  This usually means your
564 locale settings were wrong, they mention locales your system has never
565 heard of, or the locale installation in your system has problems (for
566 example, some system files are broken or missing).  There are quick and
567 temporary fixes to these problems, as well as more thorough and lasting
568 fixes.
569
570 =head2 Testing for broken locales
571
572 If you are building Perl from source, the Perl test suite file
573 F<lib/locale.t> can be used to test the locales on your system.
574 Setting the environment variable C<PERL_DEBUG_FULL_TEST> to 1
575 will cause it to output detailed results.  For example, on Linux, you
576 could say
577
578  PERL_DEBUG_FULL_TEST=1 ./perl -T -Ilib lib/locale.t > locale.log 2>&1
579
580 Besides many other tests, it will test every locale it finds on your
581 system to see if they conform to the POSIX standard.  If any have
582 errors, it will include a summary near the end of the output of which
583 locales passed all its tests, and which failed, and why.
584
585 =head2 Temporarily fixing locale problems
586
587 The two quickest fixes are either to render Perl silent about any
588 locale inconsistencies or to run Perl under the default locale "C".
589
590 Perl's moaning about locale problems can be silenced by setting the
591 environment variable C<PERL_BADLANG> to "0" or "".
592 This method really just sweeps the problem under the carpet: you tell
593 Perl to shut up even when Perl sees that something is wrong.  Do not
594 be surprised if later something locale-dependent misbehaves.
595
596 Perl can be run under the "C" locale by setting the environment
597 variable C<LC_ALL> to "C".  This method is perhaps a bit more civilized
598 than the C<PERL_BADLANG> approach, but setting C<LC_ALL> (or
599 other locale variables) may affect other programs as well, not just
600 Perl.  In particular, external programs run from within Perl will see
601 these changes.  If you make the new settings permanent (read on), all
602 programs you run see the changes.  See L</"ENVIRONMENT"> for
603 the full list of relevant environment variables and L</"USING LOCALES">
604 for their effects in Perl.  Effects in other programs are
605 easily deducible.  For example, the variable C<LC_COLLATE> may well affect
606 your B<sort> program (or whatever the program that arranges "records"
607 alphabetically in your system is called).
608
609 You can test out changing these variables temporarily, and if the
610 new settings seem to help, put those settings into your shell startup
611 files.  Consult your local documentation for the exact details.  For
612 Bourne-like shells (B<sh>, B<ksh>, B<bash>, B<zsh>):
613
614         LC_ALL=en_US.ISO8859-1
615         export LC_ALL
616
617 This assumes that we saw the locale "en_US.ISO8859-1" using the commands
618 discussed above.  We decided to try that instead of the above faulty
619 locale "En_US"--and in Cshish shells (B<csh>, B<tcsh>)
620
621         setenv LC_ALL en_US.ISO8859-1
622
623 or if you have the "env" application you can do (in any shell)
624
625         env LC_ALL=en_US.ISO8859-1 perl ...
626
627 If you do not know what shell you have, consult your local
628 helpdesk or the equivalent.
629
630 =head2 Permanently fixing locale problems
631
632 The slower but superior fixes are when you may be able to yourself
633 fix the misconfiguration of your own environment variables.  The
634 mis(sing)configuration of the whole system's locales usually requires
635 the help of your friendly system administrator.
636
637 First, see earlier in this document about L</Finding locales>.  That tells
638 how to find which locales are really supported--and more importantly,
639 installed--on your system.  In our example error message, environment
640 variables affecting the locale are listed in the order of decreasing
641 importance (and unset variables do not matter).  Therefore, having
642 LC_ALL set to "En_US" must have been the bad choice, as shown by the
643 error message.  First try fixing locale settings listed first.
644
645 Second, if using the listed commands you see something B<exactly>
646 (prefix matches do not count and case usually counts) like "En_US"
647 without the quotes, then you should be okay because you are using a
648 locale name that should be installed and available in your system.
649 In this case, see L</Permanently fixing your system's locale configuration>.
650
651 =head2 Permanently fixing your system's locale configuration
652
653 This is when you see something like:
654
655         perl: warning: Please check that your locale settings:
656                 LC_ALL = "En_US",
657                 LANG = (unset)
658             are supported and installed on your system.
659
660 but then cannot see that "En_US" listed by the above-mentioned
661 commands.  You may see things like "en_US.ISO8859-1", but that isn't
662 the same.  In this case, try running under a locale
663 that you can list and which somehow matches what you tried.  The
664 rules for matching locale names are a bit vague because
665 standardization is weak in this area.  See again the
666 L</Finding locales> about general rules.
667
668 =head2 Fixing system locale configuration
669
670 Contact a system administrator (preferably your own) and report the exact
671 error message you get, and ask them to read this same documentation you
672 are now reading.  They should be able to check whether there is something
673 wrong with the locale configuration of the system.  The L</Finding locales>
674 section is unfortunately a bit vague about the exact commands and places
675 because these things are not that standardized.
676
677 =head2 The localeconv function
678
679 The C<POSIX::localeconv()> function allows you to get particulars of the
680 locale-dependent numeric formatting information specified by the current
681 underlying C<LC_NUMERIC> and C<LC_MONETARY> locales (regardless of
682 whether called from within the scope of C<S<use locale>> or not).  (If
683 you just want the name of
684 the current locale for a particular category, use C<POSIX::setlocale()>
685 with a single parameter--see L</The setlocale function>.)
686
687         use POSIX qw(locale_h);
688
689         # Get a reference to a hash of locale-dependent info
690         $locale_values = localeconv();
691
692         # Output sorted list of the values
693         for (sort keys %$locale_values) {
694             printf "%-20s = %s\n", $_, $locale_values->{$_}
695         }
696
697 C<localeconv()> takes no arguments, and returns B<a reference to> a hash.
698 The keys of this hash are variable names for formatting, such as
699 C<decimal_point> and C<thousands_sep>.  The values are the
700 corresponding, er, values.  See L<POSIX/localeconv> for a longer
701 example listing the categories an implementation might be expected to
702 provide; some provide more and others fewer.  You don't need an
703 explicit C<use locale>, because C<localeconv()> always observes the
704 current locale.
705
706 Here's a simple-minded example program that rewrites its command-line
707 parameters as integers correctly formatted in the current locale:
708
709     use POSIX qw(locale_h);
710
711     # Get some of locale's numeric formatting parameters
712     my ($thousands_sep, $grouping) =
713             @{localeconv()}{'thousands_sep', 'grouping'};
714
715     # Apply defaults if values are missing
716     $thousands_sep = ',' unless $thousands_sep;
717
718     # grouping and mon_grouping are packed lists
719     # of small integers (characters) telling the
720     # grouping (thousand_seps and mon_thousand_seps
721     # being the group dividers) of numbers and
722     # monetary quantities.  The integers' meanings:
723     # 255 means no more grouping, 0 means repeat
724     # the previous grouping, 1-254 means use that
725     # as the current grouping.  Grouping goes from
726     # right to left (low to high digits).  In the
727     # below we cheat slightly by never using anything
728     # else than the first grouping (whatever that is).
729     if ($grouping) {
730         @grouping = unpack("C*", $grouping);
731     } else {
732         @grouping = (3);
733     }
734
735     # Format command line params for current locale
736     for (@ARGV) {
737         $_ = int;    # Chop non-integer part
738         1 while
739         s/(\d)(\d{$grouping[0]}($|$thousands_sep))/$1$thousands_sep$2/;
740         print "$_";
741     }
742     print "\n";
743
744 Note that if the platform doesn't have C<LC_NUMERIC> and/or
745 C<LC_MONETARY> available or enabled, the corresponding elements of the
746 hash will be missing.
747
748 =head2 I18N::Langinfo
749
750 Another interface for querying locale-dependent information is the
751 C<I18N::Langinfo::langinfo()> function, available at least in Unix-like
752 systems and VMS.
753
754 The following example will import the C<langinfo()> function itself and
755 three constants to be used as arguments to C<langinfo()>: a constant for
756 the abbreviated first day of the week (the numbering starts from
757 Sunday = 1) and two more constants for the affirmative and negative
758 answers for a yes/no question in the current locale.
759
760     use I18N::Langinfo qw(langinfo ABDAY_1 YESSTR NOSTR);
761
762     my ($abday_1, $yesstr, $nostr)
763                 = map { langinfo } qw(ABDAY_1 YESSTR NOSTR);
764
765     print "$abday_1? [$yesstr/$nostr] ";
766
767 In other words, in the "C" (or English) locale the above will probably
768 print something like:
769
770     Sun? [yes/no]
771
772 See L<I18N::Langinfo> for more information.
773
774 =head1 LOCALE CATEGORIES
775
776 The following subsections describe basic locale categories.  Beyond these,
777 some combination categories allow manipulation of more than one
778 basic category at a time.  See L</"ENVIRONMENT"> for a discussion of these.
779
780 =head2 Category C<LC_COLLATE>: Collation: Text Comparisons and Sorting
781
782 In the scope of a S<C<use locale>> form that includes collation, Perl
783 looks to the C<LC_COLLATE>
784 environment variable to determine the application's notions on collation
785 (ordering) of characters.  For example, "b" follows "a" in Latin
786 alphabets, but where do "E<aacute>" and "E<aring>" belong?  And while
787 "color" follows "chocolate" in English, what about in traditional Spanish?
788
789 The following collations all make sense and you may meet any of them
790 if you C<"use locale">.
791
792         A B C D E a b c d e
793         A a B b C c D d E e
794         a A b B c C d D e E
795         a b c d e A B C D E
796
797 Here is a code snippet to tell what "word"
798 characters are in the current locale, in that locale's order:
799
800         use locale;
801         print +(sort grep /\w/, map { chr } 0..255), "\n";
802
803 Compare this with the characters that you see and their order if you
804 state explicitly that the locale should be ignored:
805
806         no locale;
807         print +(sort grep /\w/, map { chr } 0..255), "\n";
808
809 This machine-native collation (which is what you get unless S<C<use
810 locale>> has appeared earlier in the same block) must be used for
811 sorting raw binary data, whereas the locale-dependent collation of the
812 first example is useful for natural text.
813
814 As noted in L</USING LOCALES>, C<cmp> compares according to the current
815 collation locale when C<use locale> is in effect, but falls back to a
816 char-by-char comparison for strings that the locale says are equal. You
817 can use C<POSIX::strcoll()> if you don't want this fall-back:
818
819         use POSIX qw(strcoll);
820         $equal_in_locale =
821             !strcoll("space and case ignored", "SpaceAndCaseIgnored");
822
823 C<$equal_in_locale> will be true if the collation locale specifies a
824 dictionary-like ordering that ignores space characters completely and
825 which folds case.
826
827 Perl uses the platform's C library collation functions C<strcoll()> and
828 C<strxfrm()>.  That means you get whatever they give.  On some
829 platforms, these functions work well on UTF-8 locales, giving
830 a reasonable default collation for the code points that are important in
831 that locale.  (And if they aren't working well, the problem may only be
832 that the locale definition is deficient, so can be fixed by using a
833 better definition file.  Unicode's definitions (see L</Freely available
834 locale definitions>) provide reasonable UTF-8 locale collation
835 definitions.)  Starting in Perl v5.26, Perl's use of these functions has
836 been made more seamless.  This may be sufficient for your needs.  For
837 more control, and to make sure strings containing any code point (not
838 just the ones important in the locale) collate properly, the
839 L<Unicode::Collate> module is suggested.
840
841 In non-UTF-8 locales (hence single byte), code points above 0xFF are
842 technically invalid.  But if present, again starting in v5.26, they will
843 collate to the same position as the highest valid code point does.  This
844 generally gives good results, but the collation order may be skewed if
845 the valid code point gets special treatment when it forms particular
846 sequences with other characters as defined by the locale.
847 When two strings collate identically, the code point order is used as a
848 tie breaker.
849
850 If Perl detects that there are problems with the locale collation order,
851 it reverts to using non-locale collation rules for that locale.
852
853 If you have a single string that you want to check for "equality in
854 locale" against several others, you might think you could gain a little
855 efficiency by using C<POSIX::strxfrm()> in conjunction with C<eq>:
856
857         use POSIX qw(strxfrm);
858         $xfrm_string = strxfrm("Mixed-case string");
859         print "locale collation ignores spaces\n"
860             if $xfrm_string eq strxfrm("Mixed-casestring");
861         print "locale collation ignores hyphens\n"
862             if $xfrm_string eq strxfrm("Mixedcase string");
863         print "locale collation ignores case\n"
864             if $xfrm_string eq strxfrm("mixed-case string");
865
866 C<strxfrm()> takes a string and maps it into a transformed string for use
867 in char-by-char comparisons against other transformed strings during
868 collation.  "Under the hood", locale-affected Perl comparison operators
869 call C<strxfrm()> for both operands, then do a char-by-char
870 comparison of the transformed strings.  By calling C<strxfrm()> explicitly
871 and using a non locale-affected comparison, the example attempts to save
872 a couple of transformations.  But in fact, it doesn't save anything: Perl
873 magic (see L<perlguts/Magic Variables>) creates the transformed version of a
874 string the first time it's needed in a comparison, then keeps this version around
875 in case it's needed again.  An example rewritten the easy way with
876 C<cmp> runs just about as fast.  It also copes with null characters
877 embedded in strings; if you call C<strxfrm()> directly, it treats the first
878 null it finds as a terminator.  Don't expect the transformed strings
879 it produces to be portable across systems--or even from one revision
880 of your operating system to the next.  In short, don't call C<strxfrm()>
881 directly: let Perl do it for you.
882
883 Note: C<use locale> isn't shown in some of these examples because it isn't
884 needed: C<strcoll()> and C<strxfrm()> are POSIX functions
885 which use the standard system-supplied C<libc> functions that
886 always obey the current C<LC_COLLATE> locale.
887
888 =head2 Category C<LC_CTYPE>: Character Types
889
890 In the scope of a S<C<use locale>> form that includes C<LC_CTYPE>, Perl
891 obeys the C<LC_CTYPE> locale
892 setting.  This controls the application's notion of which characters are
893 alphabetic, numeric, punctuation, I<etc>.  This affects Perl's C<\w>
894 regular expression metanotation,
895 which stands for alphanumeric characters--that is, alphabetic,
896 numeric, and the platform's native underscore.
897 (Consult L<perlre> for more information about
898 regular expressions.)  Thanks to C<LC_CTYPE>, depending on your locale
899 setting, characters like "E<aelig>", "E<eth>", "E<szlig>", and
900 "E<oslash>" may be understood as C<\w> characters.
901 It also affects things like C<\s>, C<\D>, and the POSIX character
902 classes, like C<[[:graph:]]>.  (See L<perlrecharclass> for more
903 information on all these.)
904
905 The C<LC_CTYPE> locale also provides the map used in transliterating
906 characters between lower and uppercase.  This affects the case-mapping
907 functions--C<fc()>, C<lc()>, C<lcfirst()>, C<uc()>, and C<ucfirst()>;
908 case-mapping
909 interpolation with C<\F>, C<\l>, C<\L>, C<\u>, or C<\U> in double-quoted
910 strings and C<s///> substitutions; and case-independent regular expression
911 pattern matching using the C<i> modifier.
912
913 Starting in v5.20, Perl supports UTF-8 locales for C<LC_CTYPE>, but
914 otherwise Perl only supports single-byte locales, such as the ISO 8859
915 series.  This means that wide character locales, for example for Asian
916 languages, are not well-supported.  Use of these locales may cause core
917 dumps.  If the platform has the capability for Perl to detect such a
918 locale, starting in Perl v5.22, L<Perl will warn, default
919 enabled|warnings/Category Hierarchy>, using the C<locale> warning
920 category, whenever such a locale is switched into.  The UTF-8 locale
921 support is actually a
922 superset of POSIX locales, because it is really full Unicode behavior
923 as if no C<LC_CTYPE> locale were in effect at all (except for tainting;
924 see L</SECURITY>).  POSIX locales, even UTF-8 ones,
925 are lacking certain concepts in Unicode, such as the idea that changing
926 the case of a character could expand to be more than one character.
927 Perl in a UTF-8 locale, will give you that expansion.  Prior to v5.20,
928 Perl treated a UTF-8 locale on some platforms like an ISO 8859-1 one,
929 with some restrictions, and on other platforms more like the "C" locale.
930 For releases v5.16 and v5.18, C<S<use locale 'not_characters>> could be
931 used as a workaround for this (see L</Unicode and UTF-8>).
932
933 Note that there are quite a few things that are unaffected by the
934 current locale.  Any literal character is the native character for the
935 given platform.  Hence 'A' means the character at code point 65 on ASCII
936 platforms, and 193 on EBCDIC.  That may or may not be an 'A' in the
937 current locale, if that locale even has an 'A'.
938 Similarly, all the escape sequences for particular characters,
939 C<\n> for example, always mean the platform's native one.  This means,
940 for example, that C<\N> in regular expressions (every character
941 but new-line) works on the platform character set.
942
943 Starting in v5.22, Perl will by default warn when switching into a
944 locale that redefines any ASCII printable character (plus C<\t> and
945 C<\n>) into a different class than expected.  This is likely to
946 happen on modern locales only on EBCDIC platforms, where, for example,
947 a CCSID 0037 locale on a CCSID 1047 machine moves C<"[">, but it can
948 happen on ASCII platforms with the ISO 646 and other
949 7-bit locales that are essentially obsolete.  Things may still work,
950 depending on what features of Perl are used by the program.  For
951 example, in the example from above where C<"|"> becomes a C<\w>, and
952 there are no regular expressions where this matters, the program may
953 still work properly.  The warning lists all the characters that
954 it can determine could be adversely affected.
955
956 B<Note:> A broken or malicious C<LC_CTYPE> locale definition may result
957 in clearly ineligible characters being considered to be alphanumeric by
958 your application.  For strict matching of (mundane) ASCII letters and
959 digits--for example, in command strings--locale-aware applications
960 should use C<\w> with the C</a> regular expression modifier.  See L</"SECURITY">.
961
962 =head2 Category C<LC_NUMERIC>: Numeric Formatting
963
964 After a proper C<POSIX::setlocale()> call, and within the scope of
965 of a C<use locale> form that includes numerics, Perl obeys the
966 C<LC_NUMERIC> locale information, which controls an application's idea
967 of how numbers should be formatted for human readability.
968 In most implementations the only effect is to
969 change the character used for the decimal point--perhaps from "."  to ",".
970 The functions aren't aware of such niceties as thousands separation and
971 so on. (See L</The localeconv function> if you care about these things.)
972
973  use POSIX qw(strtod setlocale LC_NUMERIC);
974  use locale;
975
976  setlocale LC_NUMERIC, "";
977
978  $n = 5/2;   # Assign numeric 2.5 to $n
979
980  $a = " $n"; # Locale-dependent conversion to string
981
982  print "half five is $n\n";       # Locale-dependent output
983
984  printf "half five is %g\n", $n;  # Locale-dependent output
985
986  print "DECIMAL POINT IS COMMA\n"
987           if $n == (strtod("2,5"))[0]; # Locale-dependent conversion
988
989 See also L<I18N::Langinfo> and C<RADIXCHAR>.
990
991 =head2 Category C<LC_MONETARY>: Formatting of monetary amounts
992
993 The C standard defines the C<LC_MONETARY> category, but not a function
994 that is affected by its contents.  (Those with experience of standards
995 committees will recognize that the working group decided to punt on the
996 issue.)  Consequently, Perl essentially takes no notice of it.  If you
997 really want to use C<LC_MONETARY>, you can query its contents--see
998 L</The localeconv function>--and use the information that it returns in your
999 application's own formatting of currency amounts.  However, you may well
1000 find that the information, voluminous and complex though it may be, still
1001 does not quite meet your requirements: currency formatting is a hard nut
1002 to crack.
1003
1004 See also L<I18N::Langinfo> and C<CRNCYSTR>.
1005
1006 =head2 Category C<LC_TIME>: Respresentation of time
1007
1008 Output produced by C<POSIX::strftime()>, which builds a formatted
1009 human-readable date/time string, is affected by the current C<LC_TIME>
1010 locale.  Thus, in a French locale, the output produced by the C<%B>
1011 format element (full month name) for the first month of the year would
1012 be "janvier".  Here's how to get a list of long month names in the
1013 current locale:
1014
1015         use POSIX qw(strftime);
1016         for (0..11) {
1017             $long_month_name[$_] =
1018                 strftime("%B", 0, 0, 0, 1, $_, 96);
1019         }
1020
1021 Note: C<use locale> isn't needed in this example: C<strftime()> is a POSIX
1022 function which uses the standard system-supplied C<libc> function that
1023 always obeys the current C<LC_TIME> locale.
1024
1025 See also L<I18N::Langinfo> and C<ABDAY_1>..C<ABDAY_7>, C<DAY_1>..C<DAY_7>,
1026 C<ABMON_1>..C<ABMON_12>, and C<ABMON_1>..C<ABMON_12>.
1027
1028 =head2 Other categories
1029
1030 The remaining locale categories are not currently used by Perl itself.
1031 But again note that things Perl interacts with may use these, including
1032 extensions outside the standard Perl distribution, and by the
1033 operating system and its utilities.  Note especially that the string
1034 value of C<$!> and the error messages given by external utilities may
1035 be changed by C<LC_MESSAGES>.  If you want to have portable error
1036 codes, use C<%!>.  See L<Errno>.
1037
1038 =head1 SECURITY
1039
1040 Although the main discussion of Perl security issues can be found in
1041 L<perlsec>, a discussion of Perl's locale handling would be incomplete
1042 if it did not draw your attention to locale-dependent security issues.
1043 Locales--particularly on systems that allow unprivileged users to
1044 build their own locales--are untrustworthy.  A malicious (or just plain
1045 broken) locale can make a locale-aware application give unexpected
1046 results.  Here are a few possibilities:
1047
1048 =over 4
1049
1050 =item *
1051
1052 Regular expression checks for safe file names or mail addresses using
1053 C<\w> may be spoofed by an C<LC_CTYPE> locale that claims that
1054 characters such as C<"E<gt>"> and C<"|"> are alphanumeric.
1055
1056 =item *
1057
1058 String interpolation with case-mapping, as in, say, C<$dest =
1059 "C:\U$name.$ext">, may produce dangerous results if a bogus C<LC_CTYPE>
1060 case-mapping table is in effect.
1061
1062 =item *
1063
1064 A sneaky C<LC_COLLATE> locale could result in the names of students with
1065 "D" grades appearing ahead of those with "A"s.
1066
1067 =item *
1068
1069 An application that takes the trouble to use information in
1070 C<LC_MONETARY> may format debits as if they were credits and vice versa
1071 if that locale has been subverted.  Or it might make payments in US
1072 dollars instead of Hong Kong dollars.
1073
1074 =item *
1075
1076 The date and day names in dates formatted by C<strftime()> could be
1077 manipulated to advantage by a malicious user able to subvert the
1078 C<LC_DATE> locale.  ("Look--it says I wasn't in the building on
1079 Sunday.")
1080
1081 =back
1082
1083 Such dangers are not peculiar to the locale system: any aspect of an
1084 application's environment which may be modified maliciously presents
1085 similar challenges.  Similarly, they are not specific to Perl: any
1086 programming language that allows you to write programs that take
1087 account of their environment exposes you to these issues.
1088
1089 Perl cannot protect you from all possibilities shown in the
1090 examples--there is no substitute for your own vigilance--but, when
1091 C<use locale> is in effect, Perl uses the tainting mechanism (see
1092 L<perlsec>) to mark string results that become locale-dependent, and
1093 which may be untrustworthy in consequence.  Here is a summary of the
1094 tainting behavior of operators and functions that may be affected by
1095 the locale:
1096
1097 =over 4
1098
1099 =item  *
1100
1101 B<Comparison operators> (C<lt>, C<le>, C<ge>, C<gt> and C<cmp>):
1102
1103 Scalar true/false (or less/equal/greater) result is never tainted.
1104
1105 =item  *
1106
1107 B<Case-mapping interpolation> (with C<\l>, C<\L>, C<\u>, C<\U>, or C<\F>)
1108
1109 The result string containing interpolated material is tainted if
1110 a C<use locale> form that includes C<LC_CTYPE> is in effect.
1111
1112 =item  *
1113
1114 B<Matching operator> (C<m//>):
1115
1116 Scalar true/false result never tainted.
1117
1118 All subpatterns, either delivered as a list-context result or as C<$1>
1119 I<etc>., are tainted if a C<use locale> form that includes
1120 C<LC_CTYPE> is in effect, and the subpattern
1121 regular expression contains a locale-dependent construct.  These
1122 constructs include C<\w> (to match an alphanumeric character), C<\W>
1123 (non-alphanumeric character), C<\b> and C<\B> (word-boundary and
1124 non-boundardy, which depend on what C<\w> and C<\W> match), C<\s>
1125 (whitespace character), C<\S> (non whitespace character), C<\d> and
1126 C<\D> (digits and non-digits), and the POSIX character classes, such as
1127 C<[:alpha:]> (see L<perlrecharclass/POSIX Character Classes>).
1128
1129 Tainting is also likely if the pattern is to be matched
1130 case-insensitively (via C</i>).  The exception is if all the code points
1131 to be matched this way are above 255 and do not have folds under Unicode
1132 rules to below 256.  Tainting is not done for these because Perl
1133 only uses Unicode rules for such code points, and those rules are the
1134 same no matter what the current locale.
1135
1136 The matched-pattern variables, C<$&>, C<$`> (pre-match), C<$'>
1137 (post-match), and C<$+> (last match) also are tainted.
1138
1139 =item  *
1140
1141 B<Substitution operator> (C<s///>):
1142
1143 Has the same behavior as the match operator.  Also, the left
1144 operand of C<=~> becomes tainted when a C<use locale>
1145 form that includes C<LC_CTYPE> is in effect, if modified as
1146 a result of a substitution based on a regular
1147 expression match involving any of the things mentioned in the previous
1148 item, or of case-mapping, such as C<\l>, C<\L>,C<\u>, C<\U>, or C<\F>.
1149
1150 =item *
1151
1152 B<Output formatting functions> (C<printf()> and C<write()>):
1153
1154 Results are never tainted because otherwise even output from print,
1155 for example C<print(1/7)>, should be tainted if C<use locale> is in
1156 effect.
1157
1158 =item *
1159
1160 B<Case-mapping functions> (C<lc()>, C<lcfirst()>, C<uc()>, C<ucfirst()>):
1161
1162 Results are tainted if a C<use locale> form that includes C<LC_CTYPE> is
1163 in effect.
1164
1165 =item *
1166
1167 B<POSIX locale-dependent functions> (C<localeconv()>, C<strcoll()>,
1168 C<strftime()>, C<strxfrm()>):
1169
1170 Results are never tainted.
1171
1172 =back
1173
1174 Three examples illustrate locale-dependent tainting.
1175 The first program, which ignores its locale, won't run: a value taken
1176 directly from the command line may not be used to name an output file
1177 when taint checks are enabled.
1178
1179         #/usr/local/bin/perl -T
1180         # Run with taint checking
1181
1182         # Command line sanity check omitted...
1183         $tainted_output_file = shift;
1184
1185         open(F, ">$tainted_output_file")
1186             or warn "Open of $tainted_output_file failed: $!\n";
1187
1188 The program can be made to run by "laundering" the tainted value through
1189 a regular expression: the second example--which still ignores locale
1190 information--runs, creating the file named on its command line
1191 if it can.
1192
1193         #/usr/local/bin/perl -T
1194
1195         $tainted_output_file = shift;
1196         $tainted_output_file =~ m%[\w/]+%;
1197         $untainted_output_file = $&;
1198
1199         open(F, ">$untainted_output_file")
1200             or warn "Open of $untainted_output_file failed: $!\n";
1201
1202 Compare this with a similar but locale-aware program:
1203
1204         #/usr/local/bin/perl -T
1205
1206         $tainted_output_file = shift;
1207         use locale;
1208         $tainted_output_file =~ m%[\w/]+%;
1209         $localized_output_file = $&;
1210
1211         open(F, ">$localized_output_file")
1212             or warn "Open of $localized_output_file failed: $!\n";
1213
1214 This third program fails to run because C<$&> is tainted: it is the result
1215 of a match involving C<\w> while C<use locale> is in effect.
1216
1217 =head1 ENVIRONMENT
1218
1219 =over 12
1220
1221 =item PERL_SKIP_LOCALE_INIT
1222
1223 This environment variable, available starting in Perl v5.20, if set
1224 (to any value), tells Perl to not use the rest of the
1225 environment variables to initialize with.  Instead, Perl uses whatever
1226 the current locale settings are.  This is particularly useful in
1227 embedded environments, see
1228 L<perlembed/Using embedded Perl with POSIX locales>.
1229
1230 =item PERL_BADLANG
1231
1232 A string that can suppress Perl's warning about failed locale settings
1233 at startup.  Failure can occur if the locale support in the operating
1234 system is lacking (broken) in some way--or if you mistyped the name of
1235 a locale when you set up your environment.  If this environment
1236 variable is absent, or has a value other than "0" or "", Perl will
1237 complain about locale setting failures.
1238
1239 B<NOTE>: C<PERL_BADLANG> only gives you a way to hide the warning message.
1240 The message tells about some problem in your system's locale support,
1241 and you should investigate what the problem is.
1242
1243 =back
1244
1245 The following environment variables are not specific to Perl: They are
1246 part of the standardized (ISO C, XPG4, POSIX 1.c) C<setlocale()> method
1247 for controlling an application's opinion on data.  Windows is non-POSIX,
1248 but Perl arranges for the following to work as described anyway.
1249 If the locale given by an environment variable is not valid, Perl tries
1250 the next lower one in priority.  If none are valid, on Windows, the
1251 system default locale is then tried.  If all else fails, the C<"C">
1252 locale is used.  If even that doesn't work, something is badly broken,
1253 but Perl tries to forge ahead with whatever the locale settings might
1254 be.
1255
1256 =over 12
1257
1258 =item C<LC_ALL>
1259
1260 C<LC_ALL> is the "override-all" locale environment variable. If
1261 set, it overrides all the rest of the locale environment variables.
1262
1263 =item C<LANGUAGE>
1264
1265 B<NOTE>: C<LANGUAGE> is a GNU extension, it affects you only if you
1266 are using the GNU libc.  This is the case if you are using e.g. Linux.
1267 If you are using "commercial" Unixes you are most probably I<not>
1268 using GNU libc and you can ignore C<LANGUAGE>.
1269
1270 However, in the case you are using C<LANGUAGE>: it affects the
1271 language of informational, warning, and error messages output by
1272 commands (in other words, it's like C<LC_MESSAGES>) but it has higher
1273 priority than C<LC_ALL>.  Moreover, it's not a single value but
1274 instead a "path" (":"-separated list) of I<languages> (not locales).
1275 See the GNU C<gettext> library documentation for more information.
1276
1277 =item C<LC_CTYPE>
1278
1279 In the absence of C<LC_ALL>, C<LC_CTYPE> chooses the character type
1280 locale.  In the absence of both C<LC_ALL> and C<LC_CTYPE>, C<LANG>
1281 chooses the character type locale.
1282
1283 =item C<LC_COLLATE>
1284
1285 In the absence of C<LC_ALL>, C<LC_COLLATE> chooses the collation
1286 (sorting) locale.  In the absence of both C<LC_ALL> and C<LC_COLLATE>,
1287 C<LANG> chooses the collation locale.
1288
1289 =item C<LC_MONETARY>
1290
1291 In the absence of C<LC_ALL>, C<LC_MONETARY> chooses the monetary
1292 formatting locale.  In the absence of both C<LC_ALL> and C<LC_MONETARY>,
1293 C<LANG> chooses the monetary formatting locale.
1294
1295 =item C<LC_NUMERIC>
1296
1297 In the absence of C<LC_ALL>, C<LC_NUMERIC> chooses the numeric format
1298 locale.  In the absence of both C<LC_ALL> and C<LC_NUMERIC>, C<LANG>
1299 chooses the numeric format.
1300
1301 =item C<LC_TIME>
1302
1303 In the absence of C<LC_ALL>, C<LC_TIME> chooses the date and time
1304 formatting locale.  In the absence of both C<LC_ALL> and C<LC_TIME>,
1305 C<LANG> chooses the date and time formatting locale.
1306
1307 =item C<LANG>
1308
1309 C<LANG> is the "catch-all" locale environment variable. If it is set, it
1310 is used as the last resort after the overall C<LC_ALL> and the
1311 category-specific C<LC_I<foo>>.
1312
1313 =back
1314
1315 =head2 Examples
1316
1317 The C<LC_NUMERIC> controls the numeric output:
1318
1319    use locale;
1320    use POSIX qw(locale_h); # Imports setlocale() and the LC_ constants.
1321    setlocale(LC_NUMERIC, "fr_FR") or die "Pardon";
1322    printf "%g\n", 1.23; # If the "fr_FR" succeeded, probably shows 1,23.
1323
1324 and also how strings are parsed by C<POSIX::strtod()> as numbers:
1325
1326    use locale;
1327    use POSIX qw(locale_h strtod);
1328    setlocale(LC_NUMERIC, "de_DE") or die "Entschuldigung";
1329    my $x = strtod("2,34") + 5;
1330    print $x, "\n"; # Probably shows 7,34.
1331
1332 =head1 NOTES
1333
1334 =head2 String C<eval> and C<LC_NUMERIC>
1335
1336 A string L<eval|perlfunc/eval EXPR> parses its expression as standard
1337 Perl.  It is therefore expecting the decimal point to be a dot.  If
1338 C<LC_NUMERIC> is set to have this be a comma instead, the parsing will
1339 be confused, perhaps silently.
1340
1341  use locale;
1342  use POSIX qw(locale_h);
1343  setlocale(LC_NUMERIC, "fr_FR") or die "Pardon";
1344  my $a = 1.2;
1345  print eval "$a + 1.5";
1346  print "\n";
1347
1348 prints C<13,5>.  This is because in that locale, the comma is the
1349 decimal point character.  The C<eval> thus expands to:
1350
1351  eval "1,2 + 1.5"
1352
1353 and the result is not what you likely expected.  No warnings are
1354 generated.  If you do string C<eval>'s within the scope of
1355 S<C<use locale>>, you should instead change the C<eval> line to do
1356 something like:
1357
1358  print eval "no locale; $a + 1.5";
1359
1360 This prints C<2.7>.
1361
1362 You could also exclude C<LC_NUMERIC>, if you don't need it, by
1363
1364  use locale ':!numeric';
1365
1366 =head2 Backward compatibility
1367
1368 Versions of Perl prior to 5.004 B<mostly> ignored locale information,
1369 generally behaving as if something similar to the C<"C"> locale were
1370 always in force, even if the program environment suggested otherwise
1371 (see L</The setlocale function>).  By default, Perl still behaves this
1372 way for backward compatibility.  If you want a Perl application to pay
1373 attention to locale information, you B<must> use the S<C<use locale>>
1374 pragma (see L</The "use locale" pragma>) or, in the unlikely event
1375 that you want to do so for just pattern matching, the
1376 C</l> regular expression modifier (see L<perlre/Character set
1377 modifiers>) to instruct it to do so.
1378
1379 Versions of Perl from 5.002 to 5.003 did use the C<LC_CTYPE>
1380 information if available; that is, C<\w> did understand what
1381 were the letters according to the locale environment variables.
1382 The problem was that the user had no control over the feature:
1383 if the C library supported locales, Perl used them.
1384
1385 =head2 I18N:Collate obsolete
1386
1387 In versions of Perl prior to 5.004, per-locale collation was possible
1388 using the C<I18N::Collate> library module.  This module is now mildly
1389 obsolete and should be avoided in new applications.  The C<LC_COLLATE>
1390 functionality is now integrated into the Perl core language: One can
1391 use locale-specific scalar data completely normally with C<use locale>,
1392 so there is no longer any need to juggle with the scalar references of
1393 C<I18N::Collate>.
1394
1395 =head2 Sort speed and memory use impacts
1396
1397 Comparing and sorting by locale is usually slower than the default
1398 sorting; slow-downs of two to four times have been observed.  It will
1399 also consume more memory: once a Perl scalar variable has participated
1400 in any string comparison or sorting operation obeying the locale
1401 collation rules, it will take 3-15 times more memory than before.  (The
1402 exact multiplier depends on the string's contents, the operating system
1403 and the locale.) These downsides are dictated more by the operating
1404 system's implementation of the locale system than by Perl.
1405
1406 =head2 Freely available locale definitions
1407
1408 The Unicode CLDR project extracts the POSIX portion of many of its
1409 locales, available at
1410
1411   http://unicode.org/Public/cldr/2.0.1/
1412
1413 (Newer versions of CLDR require you to compute the POSIX data yourself.
1414 See L<http://unicode.org/Public/cldr/latest/>.)
1415
1416 There is a large collection of locale definitions at:
1417
1418   http://std.dkuug.dk/i18n/WG15-collection/locales/
1419
1420 You should be aware that it is
1421 unsupported, and is not claimed to be fit for any purpose.  If your
1422 system allows installation of arbitrary locales, you may find the
1423 definitions useful as they are, or as a basis for the development of
1424 your own locales.
1425
1426 =head2 I18n and l10n
1427
1428 "Internationalization" is often abbreviated as B<i18n> because its first
1429 and last letters are separated by eighteen others.  (You may guess why
1430 the internalin ... internaliti ... i18n tends to get abbreviated.)  In
1431 the same way, "localization" is often abbreviated to B<l10n>.
1432
1433 =head2 An imperfect standard
1434
1435 Internationalization, as defined in the C and POSIX standards, can be
1436 criticized as incomplete, ungainly, and having too large a granularity.
1437 (Locales apply to a whole process, when it would arguably be more useful
1438 to have them apply to a single thread, window group, or whatever.)  They
1439 also have a tendency, like standards groups, to divide the world into
1440 nations, when we all know that the world can equally well be divided
1441 into bankers, bikers, gamers, and so on.
1442
1443 =head1 Unicode and UTF-8
1444
1445 The support of Unicode is new starting from Perl version v5.6, and more fully
1446 implemented in versions v5.8 and later.  See L<perluniintro>.
1447
1448 Starting in Perl v5.20, UTF-8 locales are supported in Perl, except
1449 C<LC_COLLATE> is only partially supported; collation support is improved
1450 in Perl v5.26 to a level that may be sufficient for your needs
1451 (see L</Category C<LC_COLLATE>: Collation: Text Comparisons and Sorting>).
1452
1453 If you have Perl v5.16 or v5.18 and can't upgrade, you can use
1454
1455     use locale ':not_characters';
1456
1457 When this form of the pragma is used, only the non-character portions of
1458 locales are used by Perl, for example C<LC_NUMERIC>.  Perl assumes that
1459 you have translated all the characters it is to operate on into Unicode
1460 (actually the platform's native character set (ASCII or EBCDIC) plus
1461 Unicode).  For data in files, this can conveniently be done by also
1462 specifying
1463
1464     use open ':locale';
1465
1466 This pragma arranges for all inputs from files to be translated into
1467 Unicode from the current locale as specified in the environment (see
1468 L</ENVIRONMENT>), and all outputs to files to be translated back
1469 into the locale.  (See L<open>).  On a per-filehandle basis, you can
1470 instead use the L<PerlIO::locale> module, or the L<Encode::Locale>
1471 module, both available from CPAN.  The latter module also has methods to
1472 ease the handling of C<ARGV> and environment variables, and can be used
1473 on individual strings.  If you know that all your locales will be
1474 UTF-8, as many are these days, you can use the L<B<-C>|perlrun/-C>
1475 command line switch.
1476
1477 This form of the pragma allows essentially seamless handling of locales
1478 with Unicode.  The collation order will be by Unicode code point order.
1479 L<Unicode::Collate> can be used to get Unicode rules collation.
1480
1481 All the modules and switches just described can be used in v5.20 with
1482 just plain C<use locale>, and, should the input locales not be UTF-8,
1483 you'll get the less than ideal behavior, described below, that you get
1484 with pre-v5.16 Perls, or when you use the locale pragma without the
1485 C<:not_characters> parameter in v5.16 and v5.18.  If you are using
1486 exclusively UTF-8 locales in v5.20 and higher, the rest of this section
1487 does not apply to you.
1488
1489 There are two cases, multi-byte and single-byte locales.  First
1490 multi-byte:
1491
1492 The only multi-byte (or wide character) locale that Perl is ever likely
1493 to support is UTF-8.  This is due to the difficulty of implementation,
1494 the fact that high quality UTF-8 locales are now published for every
1495 area of the world (L<http://unicode.org/Public/cldr/2.0.1/> for
1496 ones that are already set-up, but from an earlier version;
1497 L<http://unicode.org/Public/cldr/latest/> for the most up-to-date, but
1498 you have to extract the POSIX information yourself), and that
1499 failing all that you can use the L<Encode> module to translate to/from
1500 your locale.  So, you'll have to do one of those things if you're using
1501 one of these locales, such as Big5 or Shift JIS.  For UTF-8 locales, in
1502 Perls (pre v5.20) that don't have full UTF-8 locale support, they may
1503 work reasonably well (depending on your C library implementation)
1504 simply because both
1505 they and Perl store characters that take up multiple bytes the same way.
1506 However, some, if not most, C library implementations may not process
1507 the characters in the upper half of the Latin-1 range (128 - 255)
1508 properly under C<LC_CTYPE>.  To see if a character is a particular type
1509 under a locale, Perl uses the functions like C<isalnum()>.  Your C
1510 library may not work for UTF-8 locales with those functions, instead
1511 only working under the newer wide library functions like C<iswalnum()>,
1512 which Perl does not use.
1513 These multi-byte locales are treated like single-byte locales, and will
1514 have the restrictions described below.  Starting in Perl v5.22 a warning
1515 message is raised when Perl detects a multi-byte locale that it doesn't
1516 fully support.
1517
1518 For single-byte locales,
1519 Perl generally takes the tack to use locale rules on code points that can fit
1520 in a single byte, and Unicode rules for those that can't (though this
1521 isn't uniformly applied, see the note at the end of this section).  This
1522 prevents many problems in locales that aren't UTF-8.  Suppose the locale
1523 is ISO8859-7, Greek.  The character at 0xD7 there is a capital Chi. But
1524 in the ISO8859-1 locale, Latin1, it is a multiplication sign.  The POSIX
1525 regular expression character class C<[[:alpha:]]> will magically match
1526 0xD7 in the Greek locale but not in the Latin one.
1527
1528 However, there are places where this breaks down.  Certain Perl constructs are
1529 for Unicode only, such as C<\p{Alpha}>.  They assume that 0xD7 always has its
1530 Unicode meaning (or the equivalent on EBCDIC platforms).  Since Latin1 is a
1531 subset of Unicode and 0xD7 is the multiplication sign in both Latin1 and
1532 Unicode, C<\p{Alpha}> will never match it, regardless of locale.  A similar
1533 issue occurs with C<\N{...}>.  Prior to v5.20, it is therefore a bad
1534 idea to use C<\p{}> or
1535 C<\N{}> under plain C<use locale>--I<unless> you can guarantee that the
1536 locale will be ISO8859-1.  Use POSIX character classes instead.
1537
1538 Another problem with this approach is that operations that cross the
1539 single byte/multiple byte boundary are not well-defined, and so are
1540 disallowed.  (This boundary is between the codepoints at 255/256.)
1541 For example, lower casing LATIN CAPITAL LETTER Y WITH DIAERESIS (U+0178)
1542 should return LATIN SMALL LETTER Y WITH DIAERESIS (U+00FF).  But in the
1543 Greek locale, for example, there is no character at 0xFF, and Perl
1544 has no way of knowing what the character at 0xFF is really supposed to
1545 represent.  Thus it disallows the operation.  In this mode, the
1546 lowercase of U+0178 is itself.
1547
1548 The same problems ensue if you enable automatic UTF-8-ification of your
1549 standard file handles, default C<open()> layer, and C<@ARGV> on non-ISO8859-1,
1550 non-UTF-8 locales (by using either the B<-C> command line switch or the
1551 C<PERL_UNICODE> environment variable; see L<perlrun>).
1552 Things are read in as UTF-8, which would normally imply a Unicode
1553 interpretation, but the presence of a locale causes them to be interpreted
1554 in that locale instead.  For example, a 0xD7 code point in the Unicode
1555 input, which should mean the multiplication sign, won't be interpreted by
1556 Perl that way under the Greek locale.  This is not a problem
1557 I<provided> you make certain that all locales will always and only be either
1558 an ISO8859-1, or, if you don't have a deficient C library, a UTF-8 locale.
1559
1560 Still another problem is that this approach can lead to two code
1561 points meaning the same character.  Thus in a Greek locale, both U+03A7
1562 and U+00D7 are GREEK CAPITAL LETTER CHI.
1563
1564 Because of all these problems, starting in v5.22, Perl will raise a
1565 warning if a multi-byte (hence Unicode) code point is used when a
1566 single-byte locale is in effect.  (Although it doesn't check for this if
1567 doing so would unreasonably slow execution down.)
1568
1569 Vendor locales are notoriously buggy, and it is difficult for Perl to test
1570 its locale-handling code because this interacts with code that Perl has no
1571 control over; therefore the locale-handling code in Perl may be buggy as
1572 well.  (However, the Unicode-supplied locales should be better, and
1573 there is a feed back mechanism to correct any problems.  See
1574 L</Freely available locale definitions>.)
1575
1576 If you have Perl v5.16, the problems mentioned above go away if you use
1577 the C<:not_characters> parameter to the locale pragma (except for vendor
1578 bugs in the non-character portions).  If you don't have v5.16, and you
1579 I<do> have locales that work, using them may be worthwhile for certain
1580 specific purposes, as long as you keep in mind the gotchas already
1581 mentioned.  For example, if the collation for your locales works, it
1582 runs faster under locales than under L<Unicode::Collate>; and you gain
1583 access to such things as the local currency symbol and the names of the
1584 months and days of the week.  (But to hammer home the point, in v5.16,
1585 you get this access without the downsides of locales by using the
1586 C<:not_characters> form of the pragma.)
1587
1588 Note: The policy of using locale rules for code points that can fit in a
1589 byte, and Unicode rules for those that can't is not uniformly applied.
1590 Pre-v5.12, it was somewhat haphazard; in v5.12 it was applied fairly
1591 consistently to regular expression matching except for bracketed
1592 character classes; in v5.14 it was extended to all regex matches; and in
1593 v5.16 to the casing operations such as C<\L> and C<uc()>.  For
1594 collation, in all releases so far, the system's C<strxfrm()> function is
1595 called, and whatever it does is what you get.  Starting in v5.26, various
1596 bugs are fixed with the way perl uses this function.
1597
1598 =head1 BUGS
1599
1600 =head2 Collation of strings containing embedded C<NUL> characters
1601
1602 C<NUL> characters will sort the same as the lowest collating control
1603 character does, or to C<"\001"> in the unlikely event that there are no
1604 control characters at all in the locale.  In cases where the strings
1605 don't contain this non-C<NUL> control, the results will be correct, and
1606 in many locales, this control, whatever it might be, will rarely be
1607 encountered.  But there are cases where a C<NUL> should sort before this
1608 control, but doesn't.  If two strings do collate identically, the one
1609 containing the C<NUL> will sort to earlier.  Prior to 5.26, there were
1610 more bugs.
1611
1612 =head2 Broken systems
1613
1614 In certain systems, the operating system's locale support
1615 is broken and cannot be fixed or used by Perl.  Such deficiencies can
1616 and will result in mysterious hangs and/or Perl core dumps when
1617 C<use locale> is in effect.  When confronted with such a system,
1618 please report in excruciating detail to <F<perlbug@perl.org>>, and
1619 also contact your vendor: bug fixes may exist for these problems
1620 in your operating system.  Sometimes such bug fixes are called an
1621 operating system upgrade.  If you have the source for Perl, include in
1622 the perlbug email the output of the test described above in L</Testing
1623 for broken locales>.
1624
1625 =head1 SEE ALSO
1626
1627 L<I18N::Langinfo>, L<perluniintro>, L<perlunicode>, L<open>,
1628 L<POSIX/localeconv>,
1629 L<POSIX/setlocale>, L<POSIX/strcoll>, L<POSIX/strftime>,
1630 L<POSIX/strtod>, L<POSIX/strxfrm>.
1631
1632 For special considerations when Perl is embedded in a C program,
1633 see L<perlembed/Using embedded Perl with POSIX locales>.
1634
1635 =head1 HISTORY
1636
1637 Jarkko Hietaniemi's original F<perli18n.pod> heavily hacked by Dominic
1638 Dunlop, assisted by the perl5-porters.  Prose worked over a bit by
1639 Tom Christiansen, and now maintained by Perl 5 porters.