This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
PATCH: [perl #90646] perlop.pod: Clarify & | and ^ binary operations
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands. For example C<$a + $b>
10 is always a numeric addition, and if C<$a> or C<$b> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument. It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison. For example C<$a == $b> compares
17 two numbers for equality, and C<$a eq $b> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|> and C<^> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
32 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
33 22> and not C<6 * 5 == 30>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first or the right.  For example, in C<8
38 - 4 - 2>, subtraction is left associative so Perl evaluates the
39 expression left to right.  C<8 - 4> is evaluated first making the
40 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in precedence order.
75
76 Many operators can be overloaded for objects.  See L<overload>.
77
78 =head2 Terms and List Operators (Leftward)
79 X<list operator> X<operator, list> X<term>
80
81 A TERM has the highest precedence in Perl.  They include variables,
82 quote and quote-like operators, any expression in parentheses,
83 and any function whose arguments are parenthesized.  Actually, there
84 aren't really functions in this sense, just list operators and unary
85 operators behaving as functions because you put parentheses around
86 the arguments.  These are all documented in L<perlfunc>.
87
88 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
89 is followed by a left parenthesis as the next token, the operator and
90 arguments within parentheses are taken to be of highest precedence,
91 just like a normal function call.
92
93 In the absence of parentheses, the precedence of list operators such as
94 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
95 whether you are looking at the left side or the right side of the operator.
96 For example, in
97
98     @ary = (1, 3, sort 4, 2);
99     print @ary;         # prints 1324
100
101 the commas on the right of the sort are evaluated before the sort,
102 but the commas on the left are evaluated after.  In other words,
103 list operators tend to gobble up all arguments that follow, and
104 then act like a simple TERM with regard to the preceding expression.
105 Be careful with parentheses:
106
107     # These evaluate exit before doing the print:
108     print($foo, exit);  # Obviously not what you want.
109     print $foo, exit;   # Nor is this.
110
111     # These do the print before evaluating exit:
112     (print $foo), exit; # This is what you want.
113     print($foo), exit;  # Or this.
114     print ($foo), exit; # Or even this.
115
116 Also note that
117
118     print ($foo & 255) + 1, "\n";
119
120 probably doesn't do what you expect at first glance.  The parentheses
121 enclose the argument list for C<print> which is evaluated (printing
122 the result of C<$foo & 255>).  Then one is added to the return value
123 of C<print> (usually 1).  The result is something like this:
124
125     1 + 1, "\n";    # Obviously not what you meant.
126
127 To do what you meant properly, you must write:
128
129     print(($foo & 255) + 1, "\n");
130
131 See L<Named Unary Operators> for more discussion of this.
132
133 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
134 well as subroutine and method calls, and the anonymous
135 constructors C<[]> and C<{}>.
136
137 See also L<Quote and Quote-like Operators> toward the end of this section,
138 as well as L</"I/O Operators">.
139
140 =head2 The Arrow Operator
141 X<arrow> X<dereference> X<< -> >>
142
143 "C<< -> >>" is an infix dereference operator, just as it is in C
144 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
145 C<(...)> subscript, then the left side must be either a hard or
146 symbolic reference to an array, a hash, or a subroutine respectively.
147 (Or technically speaking, a location capable of holding a hard
148 reference, if it's an array or hash reference being used for
149 assignment.)  See L<perlreftut> and L<perlref>.
150
151 Otherwise, the right side is a method name or a simple scalar
152 variable containing either the method name or a subroutine reference,
153 and the left side must be either an object (a blessed reference)
154 or a class name (that is, a package name).  See L<perlobj>.
155
156 The dereferencing cases (as opposed to method-calling cases) are
157 somewhat extended by the experimental C<postderef> feature.  For the
158 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
159
160 =head2 Auto-increment and Auto-decrement
161 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
162
163 "++" and "--" work as in C.  That is, if placed before a variable,
164 they increment or decrement the variable by one before returning the
165 value, and if placed after, increment or decrement after returning the
166 value.
167
168     $i = 0;  $j = 0;
169     print $i++;  # prints 0
170     print ++$j;  # prints 1
171
172 Note that just as in C, Perl doesn't define B<when> the variable is
173 incremented or decremented. You just know it will be done sometime
174 before or after the value is returned. This also means that modifying
175 a variable twice in the same statement will lead to undefined behavior.
176 Avoid statements like:
177
178     $i = $i ++;
179     print ++ $i + $i ++;
180
181 Perl will not guarantee what the result of the above statements is.
182
183 The auto-increment operator has a little extra builtin magic to it.  If
184 you increment a variable that is numeric, or that has ever been used in
185 a numeric context, you get a normal increment.  If, however, the
186 variable has been used in only string contexts since it was set, and
187 has a value that is not the empty string and matches the pattern
188 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
189 character within its range, with carry:
190
191     print ++($foo = "99");      # prints "100"
192     print ++($foo = "a0");      # prints "a1"
193     print ++($foo = "Az");      # prints "Ba"
194     print ++($foo = "zz");      # prints "aaa"
195
196 C<undef> is always treated as numeric, and in particular is changed
197 to C<0> before incrementing (so that a post-increment of an undef value
198 will return C<0> rather than C<undef>).
199
200 The auto-decrement operator is not magical.
201
202 =head2 Exponentiation
203 X<**> X<exponentiation> X<power>
204
205 Binary "**" is the exponentiation operator.  It binds even more
206 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
207 implemented using C's pow(3) function, which actually works on doubles
208 internally.)
209
210 =head2 Symbolic Unary Operators
211 X<unary operator> X<operator, unary>
212
213 Unary "!" performs logical negation, that is, "not".  See also C<not> for a lower
214 precedence version of this.
215 X<!>
216
217 Unary "-" performs arithmetic negation if the operand is numeric,
218 including any string that looks like a number.  If the operand is
219 an identifier, a string consisting of a minus sign concatenated
220 with the identifier is returned.  Otherwise, if the string starts
221 with a plus or minus, a string starting with the opposite sign is
222 returned.  One effect of these rules is that -bareword is equivalent
223 to the string "-bareword".  If, however, the string begins with a
224 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
225 the string to a numeric and the arithmetic negation is performed. If the
226 string cannot be cleanly converted to a numeric, Perl will give the warning
227 B<Argument "the string" isn't numeric in negation (-) at ...>.
228 X<-> X<negation, arithmetic>
229
230 Unary "~" performs bitwise negation, that is, 1's complement.  For
231 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
232 L<Bitwise String Operators>.)  Note that the width of the result is
233 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
234 bits wide on a 64-bit platform, so if you are expecting a certain bit
235 width, remember to use the "&" operator to mask off the excess bits.
236 X<~> X<negation, binary>
237
238 When complementing strings, if all characters have ordinal values under
239 256, then their complements will, also.  But if they do not, all
240 characters will be in either 32- or 64-bit complements, depending on your
241 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
242 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
243
244 Unary "+" has no effect whatsoever, even on strings.  It is useful
245 syntactically for separating a function name from a parenthesized expression
246 that would otherwise be interpreted as the complete list of function
247 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
248 X<+>
249
250 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
251 and L<perlref>.  Do not confuse this behavior with the behavior of
252 backslash within a string, although both forms do convey the notion
253 of protecting the next thing from interpolation.
254 X<\> X<reference> X<backslash>
255
256 =head2 Binding Operators
257 X<binding> X<operator, binding> X<=~> X<!~>
258
259 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
260 search or modify the string $_ by default.  This operator makes that kind
261 of operation work on some other string.  The right argument is a search
262 pattern, substitution, or transliteration.  The left argument is what is
263 supposed to be searched, substituted, or transliterated instead of the default
264 $_.  When used in scalar context, the return value generally indicates the
265 success of the operation.  The exceptions are substitution (s///)
266 and transliteration (y///) with the C</r> (non-destructive) option,
267 which cause the B<r>eturn value to be the result of the substitution.
268 Behavior in list context depends on the particular operator.
269 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
270 examples using these operators.
271
272 If the right argument is an expression rather than a search pattern,
273 substitution, or transliteration, it is interpreted as a search pattern at run
274 time. Note that this means that its contents will be interpolated twice, so
275
276     '\\' =~ q'\\';
277
278 is not ok, as the regex engine will end up trying to compile the
279 pattern C<\>, which it will consider a syntax error.
280
281 Binary "!~" is just like "=~" except the return value is negated in
282 the logical sense.
283
284 Binary "!~" with a non-destructive substitution (s///r) or transliteration
285 (y///r) is a syntax error.
286
287 =head2 Multiplicative Operators
288 X<operator, multiplicative>
289
290 Binary "*" multiplies two numbers.
291 X<*>
292
293 Binary "/" divides two numbers.
294 X</> X<slash>
295
296 Binary "%" is the modulo operator, which computes the division
297 remainder of its first argument with respect to its second argument.
298 Given integer
299 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
300 C<$a> minus the largest multiple of C<$b> less than or equal to
301 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
302 smallest multiple of C<$b> that is not less than C<$a> (that is, the
303 result will be less than or equal to zero).  If the operands
304 C<$a> and C<$b> are floating point values and the absolute value of
305 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
306 the integer portion of C<$a> and C<$b> will be used in the operation
307 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
308 If the absolute value of the right operand (C<abs($b)>) is greater than
309 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
310 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
311 integer that makes C<$r> have the same sign as the right operand
312 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
313 and the absolute value less than that of C<$b>.
314 Note that when C<use integer> is in scope, "%" gives you direct access
315 to the modulo operator as implemented by your C compiler.  This
316 operator is not as well defined for negative operands, but it will
317 execute faster.
318 X<%> X<remainder> X<modulo> X<mod>
319
320 Binary "x" is the repetition operator.  In scalar context or if the left
321 operand is not enclosed in parentheses, it returns a string consisting
322 of the left operand repeated the number of times specified by the right
323 operand.  In list context, if the left operand is enclosed in
324 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
325 If the right operand is zero or negative, it returns an empty string
326 or an empty list, depending on the context.
327 X<x>
328
329     print '-' x 80;             # print row of dashes
330
331     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
332
333     @ones = (1) x 80;           # a list of 80 1's
334     @ones = (5) x @ones;        # set all elements to 5
335
336
337 =head2 Additive Operators
338 X<operator, additive>
339
340 Binary C<+> returns the sum of two numbers.
341 X<+>
342
343 Binary C<-> returns the difference of two numbers.
344 X<->
345
346 Binary C<.> concatenates two strings.
347 X<string, concatenation> X<concatenation>
348 X<cat> X<concat> X<concatenate> X<.>
349
350 =head2 Shift Operators
351 X<shift operator> X<operator, shift> X<<< << >>>
352 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
353 X<shl> X<shr> X<shift, right> X<shift, left>
354
355 Binary C<<< << >>> returns the value of its left argument shifted left by the
356 number of bits specified by the right argument.  Arguments should be
357 integers.  (See also L<Integer Arithmetic>.)
358
359 Binary C<<< >> >>> returns the value of its left argument shifted right by
360 the number of bits specified by the right argument.  Arguments should
361 be integers.  (See also L<Integer Arithmetic>.)
362
363 Note that both C<<< << >>> and C<<< >> >>> in Perl are implemented directly using
364 C<<< << >>> and C<<< >> >>>  in C.  If C<use integer> (see L<Integer Arithmetic>) is
365 in force then signed C integers are used, else unsigned C integers are
366 used.  Either way, the implementation isn't going to generate results
367 larger than the size of the integer type Perl was built with (32 bits
368 or 64 bits).
369
370 The result of overflowing the range of the integers is undefined
371 because it is undefined also in C.  In other words, using 32-bit
372 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
373 of bits is also undefined.
374
375 If you get tired of being subject to your platform's native integers,
376 the C<use bigint> pragma neatly sidesteps the issue altogether:
377
378     print 20 << 20;  # 20971520
379     print 20 << 40;  # 5120 on 32-bit machines, 
380                      # 21990232555520 on 64-bit machines
381     use bigint;
382     print 20 << 100; # 25353012004564588029934064107520
383
384 =head2 Named Unary Operators
385 X<operator, named unary>
386
387 The various named unary operators are treated as functions with one
388 argument, with optional parentheses.
389
390 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
391 is followed by a left parenthesis as the next token, the operator and
392 arguments within parentheses are taken to be of highest precedence,
393 just like a normal function call.  For example,
394 because named unary operators are higher precedence than C<||>:
395
396     chdir $foo    || die;       # (chdir $foo) || die
397     chdir($foo)   || die;       # (chdir $foo) || die
398     chdir ($foo)  || die;       # (chdir $foo) || die
399     chdir +($foo) || die;       # (chdir $foo) || die
400
401 but, because * is higher precedence than named operators:
402
403     chdir $foo * 20;    # chdir ($foo * 20)
404     chdir($foo) * 20;   # (chdir $foo) * 20
405     chdir ($foo) * 20;  # (chdir $foo) * 20
406     chdir +($foo) * 20; # chdir ($foo * 20)
407
408     rand 10 * 20;       # rand (10 * 20)
409     rand(10) * 20;      # (rand 10) * 20
410     rand (10) * 20;     # (rand 10) * 20
411     rand +(10) * 20;    # rand (10 * 20)
412
413 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
414 treated like named unary operators, but they don't follow this functional
415 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
416 equivalent to C<-f "$file.bak">.
417 X<-X> X<filetest> X<operator, filetest>
418
419 See also L<"Terms and List Operators (Leftward)">.
420
421 =head2 Relational Operators
422 X<relational operator> X<operator, relational>
423
424 Perl operators that return true or false generally return values 
425 that can be safely used as numbers.  For example, the relational
426 operators in this section and the equality operators in the next
427 one return C<1> for true and a special version of the defined empty
428 string, C<"">, which counts as a zero but is exempt from warnings
429 about improper numeric conversions, just as C<"0 but true"> is.
430
431 Binary "<" returns true if the left argument is numerically less than
432 the right argument.
433 X<< < >>
434
435 Binary ">" returns true if the left argument is numerically greater
436 than the right argument.
437 X<< > >>
438
439 Binary "<=" returns true if the left argument is numerically less than
440 or equal to the right argument.
441 X<< <= >>
442
443 Binary ">=" returns true if the left argument is numerically greater
444 than or equal to the right argument.
445 X<< >= >>
446
447 Binary "lt" returns true if the left argument is stringwise less than
448 the right argument.
449 X<< lt >>
450
451 Binary "gt" returns true if the left argument is stringwise greater
452 than the right argument.
453 X<< gt >>
454
455 Binary "le" returns true if the left argument is stringwise less than
456 or equal to the right argument.
457 X<< le >>
458
459 Binary "ge" returns true if the left argument is stringwise greater
460 than or equal to the right argument.
461 X<< ge >>
462
463 =head2 Equality Operators
464 X<equality> X<equal> X<equals> X<operator, equality>
465
466 Binary "==" returns true if the left argument is numerically equal to
467 the right argument.
468 X<==>
469
470 Binary "!=" returns true if the left argument is numerically not equal
471 to the right argument.
472 X<!=>
473
474 Binary "<=>" returns -1, 0, or 1 depending on whether the left
475 argument is numerically less than, equal to, or greater than the right
476 argument.  If your platform supports NaNs (not-a-numbers) as numeric
477 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
478 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
479 returns true, as does NaN != anything else. If your platform doesn't
480 support NaNs then NaN is just a string with numeric value 0.
481 X<< <=> >> X<spaceship>
482
483     $ perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
484     $ perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
485
486 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all 
487 support "NaN".)
488
489 Binary "eq" returns true if the left argument is stringwise equal to
490 the right argument.
491 X<eq>
492
493 Binary "ne" returns true if the left argument is stringwise not equal
494 to the right argument.
495 X<ne>
496
497 Binary "cmp" returns -1, 0, or 1 depending on whether the left
498 argument is stringwise less than, equal to, or greater than the right
499 argument.
500 X<cmp>
501
502 Binary "~~" does a smartmatch between its arguments.  Smart matching
503 is described in the next section.
504 X<~~>
505
506 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
507 by the current locale if a legacy C<use locale> (but not
508 C<use locale ':not_characters'>) is in effect.  See
509 L<perllocale>.  Do not mix these with Unicode, only with legacy binary
510 encodings.  The standard L<Unicode::Collate> and
511 L<Unicode::Collate::Locale> modules offer much more powerful solutions to
512 collation issues.
513
514 =head2 Smartmatch Operator
515
516 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
517 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
518 used implicitly in the C<when> construct described in L<perlsyn>, although
519 not all C<when> clauses call the smartmatch operator.  Unique among all of
520 Perl's operators, the smartmatch operator can recurse.  The smartmatch
521 operator is L<experimental|perlpolicy/experimental> and its behavior is
522 subject to change.
523
524 It is also unique in that all other Perl operators impose a context
525 (usually string or numeric context) on their operands, autoconverting
526 those operands to those imposed contexts.  In contrast, smartmatch
527 I<infers> contexts from the actual types of its operands and uses that
528 type information to select a suitable comparison mechanism.
529
530 The C<~~> operator compares its operands "polymorphically", determining how
531 to compare them according to their actual types (numeric, string, array,
532 hash, etc.)  Like the equality operators with which it shares the same
533 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
534 read aloud as "in", "inside of", or "is contained in", because the left
535 operand is often looked for I<inside> the right operand.  That makes the
536 order of the operands to the smartmatch operand often opposite that of
537 the regular match operator.  In other words, the "smaller" thing is usually
538 placed in the left operand and the larger one in the right.
539
540 The behavior of a smartmatch depends on what type of things its arguments
541 are, as determined by the following table.  The first row of the table
542 whose types apply determines the smartmatch behavior.  Because what
543 actually happens is mostly determined by the type of the second operand,
544 the table is sorted on the right operand instead of on the left.
545
546  Left      Right      Description and pseudocode                               
547  ===============================================================
548  Any       undef      check whether Any is undefined                    
549                 like: !defined Any
550
551  Any       Object     invoke ~~ overloading on Object, or die
552
553  Right operand is an ARRAY:
554
555  Left      Right      Description and pseudocode                               
556  ===============================================================
557  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
558                 like: (ARRAY1[0] ~~ ARRAY2[0])
559                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
560  HASH      ARRAY      any ARRAY elements exist as HASH keys             
561                 like: grep { exists HASH->{$_} } ARRAY
562  Regexp    ARRAY      any ARRAY elements pattern match Regexp
563                 like: grep { /Regexp/ } ARRAY
564  undef     ARRAY      undef in ARRAY                                    
565                 like: grep { !defined } ARRAY
566  Any       ARRAY      smartmatch each ARRAY element[3]                   
567                 like: grep { Any ~~ $_ } ARRAY
568
569  Right operand is a HASH:
570
571  Left      Right      Description and pseudocode                               
572  ===============================================================
573  HASH1     HASH2      all same keys in both HASHes                      
574                 like: keys HASH1 ==
575                          grep { exists HASH2->{$_} } keys HASH1
576  ARRAY     HASH       any ARRAY elements exist as HASH keys             
577                 like: grep { exists HASH->{$_} } ARRAY
578  Regexp    HASH       any HASH keys pattern match Regexp                
579                 like: grep { /Regexp/ } keys HASH
580  undef     HASH       always false (undef can't be a key)               
581                 like: 0 == 1
582  Any       HASH       HASH key existence                                
583                 like: exists HASH->{Any}
584
585  Right operand is CODE:
586
587  Left      Right      Description and pseudocode                               
588  ===============================================================
589  ARRAY     CODE       sub returns true on all ARRAY elements[1]
590                 like: !grep { !CODE->($_) } ARRAY
591  HASH      CODE       sub returns true on all HASH keys[1]
592                 like: !grep { !CODE->($_) } keys HASH
593  Any       CODE       sub passed Any returns true              
594                 like: CODE->(Any)
595
596 Right operand is a Regexp:
597
598  Left      Right      Description and pseudocode                               
599  ===============================================================
600  ARRAY     Regexp     any ARRAY elements match Regexp                   
601                 like: grep { /Regexp/ } ARRAY
602  HASH      Regexp     any HASH keys match Regexp                        
603                 like: grep { /Regexp/ } keys HASH
604  Any       Regexp     pattern match                                     
605                 like: Any =~ /Regexp/
606
607  Other:
608
609  Left      Right      Description and pseudocode                               
610  ===============================================================
611  Object    Any        invoke ~~ overloading on Object,
612                       or fall back to...
613
614  Any       Num        numeric equality                                  
615                  like: Any == Num
616  Num       nummy[4]    numeric equality
617                  like: Num == nummy
618  undef     Any        check whether undefined
619                  like: !defined(Any)
620  Any       Any        string equality                                   
621                  like: Any eq Any
622
623
624 Notes:
625
626 =over
627
628 =item 1.
629 Empty hashes or arrays match. 
630
631 =item 2.
632 That is, each element smartmatches the element of the same index in the other array.[3]
633
634 =item 3.
635 If a circular reference is found, fall back to referential equality. 
636
637 =item 4.
638 Either an actual number, or a string that looks like one.
639
640 =back
641
642 The smartmatch implicitly dereferences any non-blessed hash or array
643 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
644 For blessed references, the C<I<Object>> entries apply.  Smartmatches
645 involving hashes only consider hash keys, never hash values.
646
647 The "like" code entry is not always an exact rendition.  For example, the
648 smartmatch operator short-circuits whenever possible, but C<grep> does
649 not.  Also, C<grep> in scalar context returns the number of matches, but
650 C<~~> returns only true or false.
651
652 Unlike most operators, the smartmatch operator knows to treat C<undef>
653 specially:
654
655     use v5.10.1;
656     @array = (1, 2, 3, undef, 4, 5);
657     say "some elements undefined" if undef ~~ @array;
658
659 Each operand is considered in a modified scalar context, the modification
660 being that array and hash variables are passed by reference to the
661 operator, which implicitly dereferences them.  Both elements
662 of each pair are the same:
663
664     use v5.10.1;
665
666     my %hash = (red    => 1, blue   => 2, green  => 3,
667                 orange => 4, yellow => 5, purple => 6,
668                 black  => 7, grey   => 8, white  => 9);
669
670     my @array = qw(red blue green);
671
672     say "some array elements in hash keys" if  @array ~~  %hash;
673     say "some array elements in hash keys" if \@array ~~ \%hash;
674
675     say "red in array" if "red" ~~  @array;
676     say "red in array" if "red" ~~ \@array;
677
678     say "some keys end in e" if /e$/ ~~  %hash;
679     say "some keys end in e" if /e$/ ~~ \%hash;
680
681 Two arrays smartmatch if each element in the first array smartmatches
682 (that is, is "in") the corresponding element in the second array,
683 recursively.
684
685     use v5.10.1;
686     my @little = qw(red blue green);
687     my @bigger = ("red", "blue", [ "orange", "green" ] );
688     if (@little ~~ @bigger) {  # true!
689         say "little is contained in bigger";
690     } 
691
692 Because the smartmatch operator recurses on nested arrays, this
693 will still report that "red" is in the array.
694
695     use v5.10.1;
696     my @array = qw(red blue green);
697     my $nested_array = [[[[[[[ @array ]]]]]]];
698     say "red in array" if "red" ~~ $nested_array;
699
700 If two arrays smartmatch each other, then they are deep
701 copies of each others' values, as this example reports:
702
703     use v5.12.0;
704     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
705     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
706
707     if (@a ~~ @b && @b ~~ @a) {
708         say "a and b are deep copies of each other";
709     } 
710     elsif (@a ~~ @b) {
711         say "a smartmatches in b";
712     } 
713     elsif (@b ~~ @a) {
714         say "b smartmatches in a";
715     } 
716     else {
717         say "a and b don't smartmatch each other at all";
718     } 
719
720
721 If you were to set C<$b[3] = 4>, then instead of reporting that "a and b
722 are deep copies of each other", it now reports that "b smartmatches in a".
723 That because the corresponding position in C<@a> contains an array that
724 (eventually) has a 4 in it.
725
726 Smartmatching one hash against another reports whether both contain the
727 same keys, no more and no less. This could be used to see whether two
728 records have the same field names, without caring what values those fields
729 might have.  For example:
730
731     use v5.10.1;
732     sub make_dogtag {
733         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
734
735         my ($class, $init_fields) = @_;
736
737         die "Must supply (only) name, rank, and serial number"
738             unless $init_fields ~~ $REQUIRED_FIELDS;
739
740         ...
741     }
742
743 or, if other non-required fields are allowed, use ARRAY ~~ HASH:
744
745     use v5.10.1;
746     sub make_dogtag {
747         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
748
749         my ($class, $init_fields) = @_;
750
751         die "Must supply (at least) name, rank, and serial number"
752             unless [keys %{$init_fields}] ~~ $REQUIRED_FIELDS;
753
754         ...
755     }
756
757 The smartmatch operator is most often used as the implicit operator of a
758 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
759
760 =head3 Smartmatching of Objects
761
762 To avoid relying on an object's underlying representation, if the
763 smartmatch's right operand is an object that doesn't overload C<~~>,
764 it raises the exception "C<Smartmatching a non-overloaded object
765 breaks encapsulation>". That's because one has no business digging
766 around to see whether something is "in" an object. These are all
767 illegal on objects without a C<~~> overload:
768
769     %hash ~~ $object
770        42 ~~ $object
771    "fred" ~~ $object
772
773 However, you can change the way an object is smartmatched by overloading
774 the C<~~> operator. This is allowed to extend the usual smartmatch semantics.
775 For objects that do have an C<~~> overload, see L<overload>.
776
777 Using an object as the left operand is allowed, although not very useful.
778 Smartmatching rules take precedence over overloading, so even if the
779 object in the left operand has smartmatch overloading, this will be
780 ignored.  A left operand that is a non-overloaded object falls back on a
781 string or numeric comparison of whatever the C<ref> operator returns.  That
782 means that
783
784     $object ~~ X
785
786 does I<not> invoke the overload method with C<I<X>> as an argument.
787 Instead the above table is consulted as normal, and based on the type of
788 C<I<X>>, overloading may or may not be invoked.  For simple strings or
789 numbers, in becomes equivalent to this:
790
791     $object ~~ $number          ref($object) == $number
792     $object ~~ $string          ref($object) eq $string 
793
794 For example, this reports that the handle smells IOish
795 (but please don't really do this!):
796
797     use IO::Handle;
798     my $fh = IO::Handle->new();
799     if ($fh ~~ /\bIO\b/) {
800         say "handle smells IOish";
801     } 
802
803 That's because it treats C<$fh> as a string like
804 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
805
806 =head2 Bitwise And
807 X<operator, bitwise, and> X<bitwise and> X<&>
808
809 Binary "&" returns its operands ANDed together bit by bit.  Although no
810 warning is currently raised, the result is not well defined when this operation
811 is performed on operands that aren't either numbers (see
812 L<Integer Arithmetic>) or bitstrings (see L<Bitwise String Operators>).
813
814 Note that "&" has lower priority than relational operators, so for example
815 the parentheses are essential in a test like
816
817     print "Even\n" if ($x & 1) == 0;
818
819 =head2 Bitwise Or and Exclusive Or
820 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
821 X<bitwise xor> X<^>
822
823 Binary "|" returns its operands ORed together bit by bit.
824
825 Binary "^" returns its operands XORed together bit by bit.
826
827 Although no warning is currently raised, the results are not well
828 defined when these operations are performed on operands that aren't either
829 numbers (see L<Integer Arithmetic>) or bitstrings (see L<Bitwise String
830 Operators>).
831
832 Note that "|" and "^" have lower priority than relational operators, so
833 for example the brackets are essential in a test like
834
835     print "false\n" if (8 | 2) != 10;
836
837 =head2 C-style Logical And
838 X<&&> X<logical and> X<operator, logical, and>
839
840 Binary "&&" performs a short-circuit logical AND operation.  That is,
841 if the left operand is false, the right operand is not even evaluated.
842 Scalar or list context propagates down to the right operand if it
843 is evaluated.
844
845 =head2 C-style Logical Or
846 X<||> X<operator, logical, or>
847
848 Binary "||" performs a short-circuit logical OR operation.  That is,
849 if the left operand is true, the right operand is not even evaluated.
850 Scalar or list context propagates down to the right operand if it
851 is evaluated.
852
853 =head2 Logical Defined-Or
854 X<//> X<operator, logical, defined-or>
855
856 Although it has no direct equivalent in C, Perl's C<//> operator is related
857 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
858 tests the left hand side's definedness instead of its truth.  Thus,
859 C<< EXPR1 // EXPR2 >> returns the value of C<< EXPR1 >> if it's defined,
860 otherwise, the value of C<< EXPR2 >> is returned. (C<< EXPR1 >> is evaluated
861 in scalar context, C<< EXPR2 >> in the context of C<< // >> itself). Usually,
862 this is the same result as C<< defined(EXPR1) ? EXPR1 : EXPR2 >> (except that
863 the ternary-operator form can be used as a lvalue, while C<< EXPR1 // EXPR2 >>
864 cannot). This is very useful for
865 providing default values for variables.  If you actually want to test if
866 at least one of C<$a> and C<$b> is defined, use C<defined($a // $b)>.
867
868 The C<||>, C<//> and C<&&> operators return the last value evaluated
869 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
870 portable way to find out the home directory might be:
871
872     $home =  $ENV{HOME}
873           // $ENV{LOGDIR}
874           // (getpwuid($<))[7]
875           // die "You're homeless!\n";
876
877 In particular, this means that you shouldn't use this
878 for selecting between two aggregates for assignment:
879
880     @a = @b || @c;              # this is wrong
881     @a = scalar(@b) || @c;      # really meant this
882     @a = @b ? @b : @c;          # this works fine, though
883
884 As alternatives to C<&&> and C<||> when used for
885 control flow, Perl provides the C<and> and C<or> operators (see below).
886 The short-circuit behavior is identical.  The precedence of "and"
887 and "or" is much lower, however, so that you can safely use them after a
888 list operator without the need for parentheses:
889
890     unlink "alpha", "beta", "gamma"
891             or gripe(), next LINE;
892
893 With the C-style operators that would have been written like this:
894
895     unlink("alpha", "beta", "gamma")
896             || (gripe(), next LINE);
897
898 It would be even more readable to write that this way:
899
900     unless(unlink("alpha", "beta", "gamma")) {
901         gripe();
902         next LINE;
903     } 
904
905 Using "or" for assignment is unlikely to do what you want; see below.
906
907 =head2 Range Operators
908 X<operator, range> X<range> X<..> X<...>
909
910 Binary ".." is the range operator, which is really two different
911 operators depending on the context.  In list context, it returns a
912 list of values counting (up by ones) from the left value to the right
913 value.  If the left value is greater than the right value then it
914 returns the empty list.  The range operator is useful for writing
915 C<foreach (1..10)> loops and for doing slice operations on arrays. In
916 the current implementation, no temporary array is created when the
917 range operator is used as the expression in C<foreach> loops, but older
918 versions of Perl might burn a lot of memory when you write something
919 like this:
920
921     for (1 .. 1_000_000) {
922         # code
923     }
924
925 The range operator also works on strings, using the magical
926 auto-increment, see below.
927
928 In scalar context, ".." returns a boolean value.  The operator is
929 bistable, like a flip-flop, and emulates the line-range (comma)
930 operator of B<sed>, B<awk>, and various editors. Each ".." operator
931 maintains its own boolean state, even across calls to a subroutine
932 that contains it. It is false as long as its left operand is false.
933 Once the left operand is true, the range operator stays true until the
934 right operand is true, I<AFTER> which the range operator becomes false
935 again.  It doesn't become false till the next time the range operator
936 is evaluated.  It can test the right operand and become false on the
937 same evaluation it became true (as in B<awk>), but it still returns
938 true once. If you don't want it to test the right operand until the
939 next evaluation, as in B<sed>, just use three dots ("...") instead of
940 two.  In all other regards, "..." behaves just like ".." does.
941
942 The right operand is not evaluated while the operator is in the
943 "false" state, and the left operand is not evaluated while the
944 operator is in the "true" state.  The precedence is a little lower
945 than || and &&.  The value returned is either the empty string for
946 false, or a sequence number (beginning with 1) for true.  The sequence
947 number is reset for each range encountered.  The final sequence number
948 in a range has the string "E0" appended to it, which doesn't affect
949 its numeric value, but gives you something to search for if you want
950 to exclude the endpoint.  You can exclude the beginning point by
951 waiting for the sequence number to be greater than 1.
952
953 If either operand of scalar ".." is a constant expression,
954 that operand is considered true if it is equal (C<==>) to the current
955 input line number (the C<$.> variable).
956
957 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
958 but that is only an issue if you use a floating point expression; when
959 implicitly using C<$.> as described in the previous paragraph, the
960 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
961 is set to a floating point value and you are not reading from a file.
962 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
963 you want in scalar context because each of the operands are evaluated
964 using their integer representation.
965
966 Examples:
967
968 As a scalar operator:
969
970     if (101 .. 200) { print; } # print 2nd hundred lines, short for
971                                #  if ($. == 101 .. $. == 200) { print; }
972
973     next LINE if (1 .. /^$/);  # skip header lines, short for
974                                #   next LINE if ($. == 1 .. /^$/);
975                                # (typically in a loop labeled LINE)
976
977     s/^/> / if (/^$/ .. eof());  # quote body
978
979     # parse mail messages
980     while (<>) {
981         $in_header =   1  .. /^$/;
982         $in_body   = /^$/ .. eof;
983         if ($in_header) {
984             # do something
985         } else { # in body
986             # do something else
987         }
988     } continue {
989         close ARGV if eof;             # reset $. each file
990     }
991
992 Here's a simple example to illustrate the difference between
993 the two range operators:
994
995     @lines = ("   - Foo",
996               "01 - Bar",
997               "1  - Baz",
998               "   - Quux");
999
1000     foreach (@lines) {
1001         if (/0/ .. /1/) {
1002             print "$_\n";
1003         }
1004     }
1005
1006 This program will print only the line containing "Bar". If
1007 the range operator is changed to C<...>, it will also print the
1008 "Baz" line.
1009
1010 And now some examples as a list operator:
1011
1012     for (101 .. 200) { print }      # print $_ 100 times
1013     @foo = @foo[0 .. $#foo];        # an expensive no-op
1014     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1015
1016 The range operator (in list context) makes use of the magical
1017 auto-increment algorithm if the operands are strings.  You
1018 can say
1019
1020     @alphabet = ("A" .. "Z");
1021
1022 to get all normal letters of the English alphabet, or
1023
1024     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1025
1026 to get a hexadecimal digit, or
1027
1028     @z2 = ("01" .. "31");
1029     print $z2[$mday];
1030
1031 to get dates with leading zeros.
1032
1033 If the final value specified is not in the sequence that the magical
1034 increment would produce, the sequence goes until the next value would
1035 be longer than the final value specified.
1036
1037 If the initial value specified isn't part of a magical increment
1038 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1039 only the initial value will be returned.  So the following will only
1040 return an alpha:
1041
1042     use charnames "greek";
1043     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1044
1045 To get the 25 traditional lowercase Greek letters, including both sigmas,
1046 you could use this instead:
1047
1048     use charnames "greek";
1049     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1050                                         ..
1051                                      ord("\N{omega}") 
1052                                    );
1053
1054 However, because there are I<many> other lowercase Greek characters than
1055 just those, to match lowercase Greek characters in a regular expression,
1056 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1057 L<experimental feature|perlrecharclass/Extended Bracketed Character
1058 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1059
1060 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
1061 return two elements in list context.
1062
1063     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1064
1065 =head2 Conditional Operator
1066 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1067
1068 Ternary "?:" is the conditional operator, just as in C.  It works much
1069 like an if-then-else.  If the argument before the ? is true, the
1070 argument before the : is returned, otherwise the argument after the :
1071 is returned.  For example:
1072
1073     printf "I have %d dog%s.\n", $n,
1074             ($n == 1) ? "" : "s";
1075
1076 Scalar or list context propagates downward into the 2nd
1077 or 3rd argument, whichever is selected.
1078
1079     $a = $ok ? $b : $c;  # get a scalar
1080     @a = $ok ? @b : @c;  # get an array
1081     $a = $ok ? @b : @c;  # oops, that's just a count!
1082
1083 The operator may be assigned to if both the 2nd and 3rd arguments are
1084 legal lvalues (meaning that you can assign to them):
1085
1086     ($a_or_b ? $a : $b) = $c;
1087
1088 Because this operator produces an assignable result, using assignments
1089 without parentheses will get you in trouble.  For example, this:
1090
1091     $a % 2 ? $a += 10 : $a += 2
1092
1093 Really means this:
1094
1095     (($a % 2) ? ($a += 10) : $a) += 2
1096
1097 Rather than this:
1098
1099     ($a % 2) ? ($a += 10) : ($a += 2)
1100
1101 That should probably be written more simply as:
1102
1103     $a += ($a % 2) ? 10 : 2;
1104
1105 =head2 Assignment Operators
1106 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1107 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1108 X<%=> X<^=> X<x=>
1109
1110 "=" is the ordinary assignment operator.
1111
1112 Assignment operators work as in C.  That is,
1113
1114     $a += 2;
1115
1116 is equivalent to
1117
1118     $a = $a + 2;
1119
1120 although without duplicating any side effects that dereferencing the lvalue
1121 might trigger, such as from tie().  Other assignment operators work similarly.
1122 The following are recognized:
1123
1124     **=    +=    *=    &=    <<=    &&=
1125            -=    /=    |=    >>=    ||=
1126            .=    %=    ^=           //=
1127                  x=
1128
1129 Although these are grouped by family, they all have the precedence
1130 of assignment.
1131
1132 Unlike in C, the scalar assignment operator produces a valid lvalue.
1133 Modifying an assignment is equivalent to doing the assignment and
1134 then modifying the variable that was assigned to.  This is useful
1135 for modifying a copy of something, like this:
1136
1137     ($tmp = $global) =~ tr/13579/24680/;
1138
1139 Although as of 5.14, that can be also be accomplished this way:
1140
1141     use v5.14;
1142     $tmp = ($global =~  tr/13579/24680/r);
1143
1144 Likewise,
1145
1146     ($a += 2) *= 3;
1147
1148 is equivalent to
1149
1150     $a += 2;
1151     $a *= 3;
1152
1153 Similarly, a list assignment in list context produces the list of
1154 lvalues assigned to, and a list assignment in scalar context returns
1155 the number of elements produced by the expression on the right hand
1156 side of the assignment.
1157
1158 =head2 Comma Operator
1159 X<comma> X<operator, comma> X<,>
1160
1161 Binary "," is the comma operator.  In scalar context it evaluates
1162 its left argument, throws that value away, then evaluates its right
1163 argument and returns that value.  This is just like C's comma operator.
1164
1165 In list context, it's just the list argument separator, and inserts
1166 both its arguments into the list.  These arguments are also evaluated
1167 from left to right.
1168
1169 The C<< => >> operator is a synonym for the comma except that it causes a
1170 word on its left to be interpreted as a string if it begins with a letter
1171 or underscore and is composed only of letters, digits and underscores.
1172 This includes operands that might otherwise be interpreted as operators,
1173 constants, single number v-strings or function calls. If in doubt about
1174 this behavior, the left operand can be quoted explicitly.
1175
1176 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1177 or list argument separator, according to context.
1178
1179 For example:
1180
1181     use constant FOO => "something";
1182
1183     my %h = ( FOO => 23 );
1184
1185 is equivalent to:
1186
1187     my %h = ("FOO", 23);
1188
1189 It is I<NOT>:
1190
1191     my %h = ("something", 23);
1192
1193 The C<< => >> operator is helpful in documenting the correspondence
1194 between keys and values in hashes, and other paired elements in lists.
1195
1196     %hash = ( $key => $value );
1197     login( $username => $password );
1198
1199 The special quoting behavior ignores precedence, and hence may apply to
1200 I<part> of the left operand:
1201
1202     print time.shift => "bbb";
1203
1204 That example prints something like "1314363215shiftbbb", because the
1205 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1206 the fact that C<time.shift> is the entire left operand.
1207
1208 =head2 List Operators (Rightward)
1209 X<operator, list, rightward> X<list operator>
1210
1211 On the right side of a list operator, the comma has very low precedence,
1212 such that it controls all comma-separated expressions found there.
1213 The only operators with lower precedence are the logical operators
1214 "and", "or", and "not", which may be used to evaluate calls to list
1215 operators without the need for parentheses:
1216
1217     open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n";
1218
1219 However, some people find that code harder to read than writing
1220 it with parentheses:
1221
1222     open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n";
1223
1224 in which case you might as well just use the more customary "||" operator:
1225
1226     open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n";
1227
1228 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
1229
1230 =head2 Logical Not
1231 X<operator, logical, not> X<not>
1232
1233 Unary "not" returns the logical negation of the expression to its right.
1234 It's the equivalent of "!" except for the very low precedence.
1235
1236 =head2 Logical And
1237 X<operator, logical, and> X<and>
1238
1239 Binary "and" returns the logical conjunction of the two surrounding
1240 expressions.  It's equivalent to C<&&> except for the very low
1241 precedence.  This means that it short-circuits: the right
1242 expression is evaluated only if the left expression is true.
1243
1244 =head2 Logical or and Exclusive Or
1245 X<operator, logical, or> X<operator, logical, xor>
1246 X<operator, logical, exclusive or>
1247 X<or> X<xor>
1248
1249 Binary "or" returns the logical disjunction of the two surrounding
1250 expressions.  It's equivalent to C<||> except for the very low precedence.
1251 This makes it useful for control flow:
1252
1253     print FH $data              or die "Can't write to FH: $!";
1254
1255 This means that it short-circuits: the right expression is evaluated
1256 only if the left expression is false.  Due to its precedence, you must
1257 be careful to avoid using it as replacement for the C<||> operator.
1258 It usually works out better for flow control than in assignments:
1259
1260     $a = $b or $c;              # bug: this is wrong
1261     ($a = $b) or $c;            # really means this
1262     $a = $b || $c;              # better written this way
1263
1264 However, when it's a list-context assignment and you're trying to use
1265 C<||> for control flow, you probably need "or" so that the assignment
1266 takes higher precedence.
1267
1268     @info = stat($file) || die;     # oops, scalar sense of stat!
1269     @info = stat($file) or die;     # better, now @info gets its due
1270
1271 Then again, you could always use parentheses.
1272
1273 Binary C<xor> returns the exclusive-OR of the two surrounding expressions.
1274 It cannot short-circuit (of course).
1275
1276 There is no low precedence operator for defined-OR.
1277
1278 =head2 C Operators Missing From Perl
1279 X<operator, missing from perl> X<&> X<*>
1280 X<typecasting> X<(TYPE)>
1281
1282 Here is what C has that Perl doesn't:
1283
1284 =over 8
1285
1286 =item unary &
1287
1288 Address-of operator.  (But see the "\" operator for taking a reference.)
1289
1290 =item unary *
1291
1292 Dereference-address operator. (Perl's prefix dereferencing
1293 operators are typed: $, @, %, and &.)
1294
1295 =item (TYPE)
1296
1297 Type-casting operator.
1298
1299 =back
1300
1301 =head2 Quote and Quote-like Operators
1302 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1303 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1304 X<escape sequence> X<escape>
1305
1306 While we usually think of quotes as literal values, in Perl they
1307 function as operators, providing various kinds of interpolating and
1308 pattern matching capabilities.  Perl provides customary quote characters
1309 for these behaviors, but also provides a way for you to choose your
1310 quote character for any of them.  In the following table, a C<{}> represents
1311 any pair of delimiters you choose.
1312
1313     Customary  Generic        Meaning        Interpolates
1314         ''       q{}          Literal             no
1315         ""      qq{}          Literal             yes
1316         ``      qx{}          Command             yes*
1317                 qw{}         Word list            no
1318         //       m{}       Pattern match          yes*
1319                 qr{}          Pattern             yes*
1320                  s{}{}      Substitution          yes*
1321                 tr{}{}    Transliteration         no (but see below)
1322                  y{}{}    Transliteration         no (but see below)
1323         <<EOF                 here-doc            yes*
1324
1325         * unless the delimiter is ''.
1326
1327 Non-bracketing delimiters use the same character fore and aft, but the four
1328 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1329 that
1330
1331     q{foo{bar}baz}
1332
1333 is the same as
1334
1335     'foo{bar}baz'
1336
1337 Note, however, that this does not always work for quoting Perl code:
1338
1339     $s = q{ if($a eq "}") ... }; # WRONG
1340
1341 is a syntax error. The C<Text::Balanced> module (standard as of v5.8,
1342 and from CPAN before then) is able to do this properly.
1343
1344 There can be whitespace between the operator and the quoting
1345 characters, except when C<#> is being used as the quoting character.
1346 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
1347 operator C<q> followed by a comment.  Its argument will be taken
1348 from the next line.  This allows you to write:
1349
1350     s {foo}  # Replace foo
1351       {bar}  # with bar.
1352
1353 The following escape sequences are available in constructs that interpolate,
1354 and in transliterations:
1355 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1356 X<\o{}>
1357
1358     Sequence     Note  Description
1359     \t                  tab               (HT, TAB)
1360     \n                  newline           (NL)
1361     \r                  return            (CR)
1362     \f                  form feed         (FF)
1363     \b                  backspace         (BS)
1364     \a                  alarm (bell)      (BEL)
1365     \e                  escape            (ESC)
1366     \x{263A}     [1,8]  hex char          (example: SMILEY)
1367     \x1b         [2,8]  restricted range hex char (example: ESC)
1368     \N{name}     [3]    named Unicode character or character sequence
1369     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1370     \c[          [5]    control char      (example: chr(27))
1371     \o{23072}    [6,8]  octal char        (example: SMILEY)
1372     \033         [7,8]  restricted range octal char  (example: ESC)
1373
1374 =over 4
1375
1376 =item [1]
1377
1378 The result is the character specified by the hexadecimal number between
1379 the braces.  See L</[8]> below for details on which character.
1380
1381 Only hexadecimal digits are valid between the braces. If an invalid
1382 character is encountered, a warning will be issued and the invalid
1383 character and all subsequent characters (valid or invalid) within the
1384 braces will be discarded.
1385
1386 If there are no valid digits between the braces, the generated character is
1387 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1388 will not cause a warning (currently).
1389
1390 =item [2]
1391
1392 The result is the character specified by the hexadecimal number in the range
1393 0x00 to 0xFF.  See L</[8]> below for details on which character.
1394
1395 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1396 by fewer than two valid digits, any valid digits will be zero-padded.  This
1397 means that C<\x7> will be interpreted as C<\x07>, and a lone <\x> will be
1398 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1399 two valid digits will result in a warning.  Note that although the warning
1400 says the illegal character is ignored, it is only ignored as part of the
1401 escape and will still be used as the subsequent character in the string.
1402 For example:
1403
1404   Original    Result    Warns?
1405   "\x7"       "\x07"    no
1406   "\x"        "\x00"    no
1407   "\x7q"      "\x07q"   yes
1408   "\xq"       "\x00q"   yes
1409
1410 =item [3]
1411
1412 The result is the Unicode character or character sequence given by I<name>.
1413 See L<charnames>.
1414
1415 =item [4]
1416
1417 C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code
1418 point is I<hexadecimal number>.
1419
1420 =item [5]
1421
1422 The character following C<\c> is mapped to some other character as shown in the
1423 table:
1424
1425  Sequence   Value
1426    \c@      chr(0)
1427    \cA      chr(1)
1428    \ca      chr(1)
1429    \cB      chr(2)
1430    \cb      chr(2)
1431    ...
1432    \cZ      chr(26)
1433    \cz      chr(26)
1434    \c[      chr(27)
1435    \c]      chr(29)
1436    \c^      chr(30)
1437    \c?      chr(127)
1438
1439 In other words, it's the character whose code point has had 64 xor'd with
1440 its uppercase.  C<\c?> is DELETE because C<ord("?") ^ 64> is 127, and
1441 C<\c@> is NULL because the ord of "@" is 64, so xor'ing 64 itself produces 0.
1442
1443 Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the
1444 end of a string, because the backslash would be parsed as escaping the end
1445 quote.
1446
1447 On ASCII platforms, the resulting characters from the list above are the
1448 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1449 L<perlebcdic/OPERATOR DIFFERENCES> for the complete list of what these
1450 sequences mean on both ASCII and EBCDIC platforms.
1451
1452 Use of any other character following the "c" besides those listed above is
1453 discouraged, and some are deprecated with the intention of removing
1454 those in a later Perl version.  What happens for any of these
1455 other characters currently though, is that the value is derived by xor'ing
1456 with the seventh bit, which is 64.
1457
1458 To get platform independent controls, you can use C<\N{...}>.
1459
1460 =item [6]
1461
1462 The result is the character specified by the octal number between the braces.
1463 See L</[8]> below for details on which character.
1464
1465 If a character that isn't an octal digit is encountered, a warning is raised,
1466 and the value is based on the octal digits before it, discarding it and all
1467 following characters up to the closing brace.  It is a fatal error if there are
1468 no octal digits at all.
1469
1470 =item [7]
1471
1472 The result is the character specified by the three-digit octal number in the
1473 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1474 L</[8]> below for details on which character.
1475
1476 Some contexts allow 2 or even 1 digit, but any usage without exactly
1477 three digits, the first being a zero, may give unintended results.  (For
1478 example, in a regular expression it may be confused with a backreference;
1479 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1480 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1481 use this construct only for ordinals C<\077> and below, remembering to pad to
1482 the left with zeros to make three digits.  For larger ordinals, either use
1483 C<\o{}>, or convert to something else, such as to hex and use C<\x{}>
1484 instead.
1485
1486 Having fewer than 3 digits may lead to a misleading warning message that says
1487 that what follows is ignored.  For example, C<"\128"> in the ASCII character set
1488 is equivalent to the two characters C<"\n8">, but the warning C<Illegal octal
1489 digit '8' ignored> will be thrown.  If C<"\n8"> is what you want, you can
1490 avoid this warning by padding your octal number with C<0>'s: C<"\0128">.
1491
1492 =item [8]
1493
1494 Several constructs above specify a character by a number.  That number
1495 gives the character's position in the character set encoding (indexed from 0).
1496 This is called synonymously its ordinal, code position, or code point.  Perl
1497 works on platforms that have a native encoding currently of either ASCII/Latin1
1498 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1499 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1500 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1501 it as a Unicode code point and the result is the corresponding Unicode
1502 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1503 decimal, which is less than 256, so the number is interpreted in the native
1504 character set encoding.  In ASCII the character in the 80th position (indexed
1505 from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&".
1506 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1507 as a Unicode code point no matter what the native encoding is.  The name of the
1508 character in the 256th position (indexed by 0) in Unicode is
1509 C<LATIN CAPITAL LETTER A WITH MACRON>.
1510
1511 There are a couple of exceptions to the above rule.  S<C<\N{U+I<hex number>}>> is
1512 always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even
1513 on EBCDIC platforms.  And if L<C<S<use encoding>>|encoding> is in effect, the
1514 number is considered to be in that encoding, and is translated from that into
1515 the platform's native encoding if there is a corresponding native character;
1516 otherwise to Unicode.
1517
1518 =back
1519
1520 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1521 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1522 use C<\ck> or
1523 C<\x0b>.  (C<\v>
1524 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1525
1526 The following escape sequences are available in constructs that interpolate,
1527 but not in transliterations.
1528 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1529
1530     \l          lowercase next character only
1531     \u          titlecase (not uppercase!) next character only
1532     \L          lowercase all characters till \E or end of string
1533     \U          uppercase all characters till \E or end of string
1534     \F          foldcase all characters till \E or end of string
1535     \Q          quote (disable) pattern metacharacters till \E or
1536                 end of string
1537     \E          end either case modification or quoted section
1538                 (whichever was last seen)
1539
1540 See L<perlfunc/quotemeta> for the exact definition of characters that
1541 are quoted by C<\Q>.
1542
1543 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1544 C<\E> for each.  For example:
1545
1546  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1547  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1548
1549 If C<use locale> is in effect (but not C<use locale ':not_characters'>),
1550 the case map used by C<\l>, C<\L>,
1551 C<\u>, and C<\U> is taken from the current locale.  See L<perllocale>.
1552 If Unicode (for example, C<\N{}> or code points of 0x100 or
1553 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u>, and
1554 C<\U> is as defined by Unicode.  That means that case-mapping
1555 a single character can sometimes produce several characters.
1556 Under C<use locale>, C<\F> produces the same results as C<\L>
1557 for all locales but a UTF-8 one, where it instead uses the Unicode
1558 definition.
1559
1560 All systems use the virtual C<"\n"> to represent a line terminator,
1561 called a "newline".  There is no such thing as an unvarying, physical
1562 newline character.  It is only an illusion that the operating system,
1563 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1564 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1565 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1566 and on systems without line terminator,
1567 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1568 you mean a "newline" for your system, but use the literal ASCII when you
1569 need an exact character.  For example, most networking protocols expect
1570 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1571 and although they often accept just C<"\012">, they seldom tolerate just
1572 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1573 you may be burned some day.
1574 X<newline> X<line terminator> X<eol> X<end of line>
1575 X<\n> X<\r> X<\r\n>
1576
1577 For constructs that do interpolate, variables beginning with "C<$>"
1578 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1579 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1580 But method calls such as C<< $obj->meth >> are not.
1581
1582 Interpolating an array or slice interpolates the elements in order,
1583 separated by the value of C<$">, so is equivalent to interpolating
1584 C<join $", @array>.  "Punctuation" arrays such as C<@*> are usually
1585 interpolated only if the name is enclosed in braces C<@{*}>, but the
1586 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1587
1588 For double-quoted strings, the quoting from C<\Q> is applied after
1589 interpolation and escapes are processed.
1590
1591     "abc\Qfoo\tbar$s\Exyz"
1592
1593 is equivalent to
1594
1595     "abc" . quotemeta("foo\tbar$s") . "xyz"
1596
1597 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1598 the quoting from C<\Q> is applied after interpolation is processed,
1599 but before escapes are processed. This allows the pattern to match
1600 literally (except for C<$> and C<@>). For example, the following matches:
1601
1602     '\s\t' =~ /\Q\s\t/
1603
1604 Because C<$> or C<@> trigger interpolation, you'll need to use something
1605 like C</\Quser\E\@\Qhost/> to match them literally.
1606
1607 Patterns are subject to an additional level of interpretation as a
1608 regular expression.  This is done as a second pass, after variables are
1609 interpolated, so that regular expressions may be incorporated into the
1610 pattern from the variables.  If this is not what you want, use C<\Q> to
1611 interpolate a variable literally.
1612
1613 Apart from the behavior described above, Perl does not expand
1614 multiple levels of interpolation.  In particular, contrary to the
1615 expectations of shell programmers, back-quotes do I<NOT> interpolate
1616 within double quotes, nor do single quotes impede evaluation of
1617 variables when used within double quotes.
1618
1619 =head2 Regexp Quote-Like Operators
1620 X<operator, regexp>
1621
1622 Here are the quote-like operators that apply to pattern
1623 matching and related activities.
1624
1625 =over 8
1626
1627 =item qr/STRING/msixpodual
1628 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1629
1630 This operator quotes (and possibly compiles) its I<STRING> as a regular
1631 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1632 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1633 is done.  Returns a Perl value which may be used instead of the
1634 corresponding C</STRING/msixpodual> expression. The returned value is a
1635 normalized version of the original pattern. It magically differs from
1636 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1637 however, dereferencing it is not well defined (you currently get the 
1638 normalized version of the original pattern, but this may change).
1639
1640
1641 For example,
1642
1643     $rex = qr/my.STRING/is;
1644     print $rex;                 # prints (?si-xm:my.STRING)
1645     s/$rex/foo/;
1646
1647 is equivalent to
1648
1649     s/my.STRING/foo/is;
1650
1651 The result may be used as a subpattern in a match:
1652
1653     $re = qr/$pattern/;
1654     $string =~ /foo${re}bar/;   # can be interpolated in other
1655                                 # patterns
1656     $string =~ $re;             # or used standalone
1657     $string =~ /$re/;           # or this way
1658
1659 Since Perl may compile the pattern at the moment of execution of the qr()
1660 operator, using qr() may have speed advantages in some situations,
1661 notably if the result of qr() is used standalone:
1662
1663     sub match {
1664         my $patterns = shift;
1665         my @compiled = map qr/$_/i, @$patterns;
1666         grep {
1667             my $success = 0;
1668             foreach my $pat (@compiled) {
1669                 $success = 1, last if /$pat/;
1670             }
1671             $success;
1672         } @_;
1673     }
1674
1675 Precompilation of the pattern into an internal representation at
1676 the moment of qr() avoids a need to recompile the pattern every
1677 time a match C</$pat/> is attempted.  (Perl has many other internal
1678 optimizations, but none would be triggered in the above example if
1679 we did not use qr() operator.)
1680
1681 Options (specified by the following modifiers) are:
1682
1683     m   Treat string as multiple lines.
1684     s   Treat string as single line. (Make . match a newline)
1685     i   Do case-insensitive pattern matching.
1686     x   Use extended regular expressions.
1687     p   When matching preserve a copy of the matched string so
1688         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1689         defined.
1690     o   Compile pattern only once.
1691     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two
1692         a's further restricts /i matching so that no ASCII
1693         character will match a non-ASCII one.
1694     l   Use the locale.
1695     u   Use Unicode rules.
1696     d   Use Unicode or native charset, as in 5.12 and earlier.
1697
1698 If a precompiled pattern is embedded in a larger pattern then the effect
1699 of "msixpluad" will be propagated appropriately.  The effect the "o"
1700 modifier has is not propagated, being restricted to those patterns
1701 explicitly using it.
1702
1703 The last four modifiers listed above, added in Perl 5.14,
1704 control the character set rules, but C</a> is the only one you are likely
1705 to want to specify explicitly; the other three are selected
1706 automatically by various pragmas.
1707
1708 See L<perlre> for additional information on valid syntax for STRING, and
1709 for a detailed look at the semantics of regular expressions.  In
1710 particular, all modifiers except the largely obsolete C</o> are further
1711 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1712
1713 =item m/PATTERN/msixpodualgc
1714 X<m> X<operator, match>
1715 X<regexp, options> X<regexp> X<regex, options> X<regex>
1716 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1717
1718 =item /PATTERN/msixpodualgc
1719
1720 Searches a string for a pattern match, and in scalar context returns
1721 true if it succeeds, false if it fails.  If no string is specified
1722 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1723 string specified with C<=~> need not be an lvalue--it may be the
1724 result of an expression evaluation, but remember the C<=~> binds
1725 rather tightly.)  See also L<perlre>.
1726
1727 Options are as described in C<qr//> above; in addition, the following match
1728 process modifiers are available:
1729
1730  g  Match globally, i.e., find all occurrences.
1731  c  Do not reset search position on a failed match when /g is
1732     in effect.
1733
1734 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1735 you can use any pair of non-whitespace (ASCII) characters
1736 as delimiters.  This is particularly useful for matching path names
1737 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1738 the delimiter, then a match-only-once rule applies,
1739 described in C<m?PATTERN?> below. If "'" (single quote) is the delimiter,
1740 no interpolation is performed on the PATTERN.
1741 When using a character valid in an identifier, whitespace is required
1742 after the C<m>.
1743
1744 PATTERN may contain variables, which will be interpolated
1745 every time the pattern search is evaluated, except
1746 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1747 C<$|> are not interpolated because they look like end-of-string tests.)
1748 Perl will not recompile the pattern unless an interpolated
1749 variable that it contains changes.  You can force Perl to skip the
1750 test and never recompile by adding a C</o> (which stands for "once")
1751 after the trailing delimiter.
1752 Once upon a time, Perl would recompile regular expressions
1753 unnecessarily, and this modifier was useful to tell it not to do so, in the
1754 interests of speed.  But now, the only reasons to use C</o> are either:
1755
1756 =over
1757
1758 =item 1
1759
1760 The variables are thousands of characters long and you know that they
1761 don't change, and you need to wring out the last little bit of speed by
1762 having Perl skip testing for that.  (There is a maintenance penalty for
1763 doing this, as mentioning C</o> constitutes a promise that you won't
1764 change the variables in the pattern.  If you do change them, Perl won't
1765 even notice.)
1766
1767 =item 2
1768
1769 you want the pattern to use the initial values of the variables
1770 regardless of whether they change or not.  (But there are saner ways
1771 of accomplishing this than using C</o>.)
1772
1773 =item 3
1774
1775 If the pattern contains embedded code, such as
1776
1777     use re 'eval';
1778     $code = 'foo(?{ $x })';
1779     /$code/
1780
1781 then perl will recompile each time, even though the pattern string hasn't
1782 changed, to ensure that the current value of C<$x> is seen each time.
1783 Use C</o> if you want to avoid this.
1784
1785 =back
1786
1787 The bottom line is that using C</o> is almost never a good idea.
1788
1789 =item The empty pattern //
1790
1791 If the PATTERN evaluates to the empty string, the last
1792 I<successfully> matched regular expression is used instead. In this
1793 case, only the C<g> and C<c> flags on the empty pattern are honored;
1794 the other flags are taken from the original pattern. If no match has
1795 previously succeeded, this will (silently) act instead as a genuine
1796 empty pattern (which will always match).
1797
1798 Note that it's possible to confuse Perl into thinking C<//> (the empty
1799 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1800 good about this, but some pathological cases might trigger this, such as
1801 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1802 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1803 will assume you meant defined-or.  If you meant the empty regex, just
1804 use parentheses or spaces to disambiguate, or even prefix the empty
1805 regex with an C<m> (so C<//> becomes C<m//>).
1806
1807 =item Matching in list context
1808
1809 If the C</g> option is not used, C<m//> in list context returns a
1810 list consisting of the subexpressions matched by the parentheses in the
1811 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1812 also set).  When there are no parentheses in the pattern, the return
1813 value is the list C<(1)> for success.  
1814 With or without parentheses, an empty list is returned upon failure.
1815
1816 Examples:
1817
1818  open(TTY, "+</dev/tty")
1819     || die "can't access /dev/tty: $!";
1820
1821  <TTY> =~ /^y/i && foo();       # do foo if desired
1822
1823  if (/Version: *([0-9.]*)/) { $version = $1; }
1824
1825  next if m#^/usr/spool/uucp#;
1826
1827  # poor man's grep
1828  $arg = shift;
1829  while (<>) {
1830     print if /$arg/o; # compile only once (no longer needed!)
1831  }
1832
1833  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1834
1835 This last example splits $foo into the first two words and the
1836 remainder of the line, and assigns those three fields to $F1, $F2, and
1837 $Etc.  The conditional is true if any variables were assigned; that is,
1838 if the pattern matched.
1839
1840 The C</g> modifier specifies global pattern matching--that is,
1841 matching as many times as possible within the string. How it behaves
1842 depends on the context. In list context, it returns a list of the
1843 substrings matched by any capturing parentheses in the regular
1844 expression. If there are no parentheses, it returns a list of all
1845 the matched strings, as if there were parentheses around the whole
1846 pattern.
1847
1848 In scalar context, each execution of C<m//g> finds the next match,
1849 returning true if it matches, and false if there is no further match.
1850 The position after the last match can be read or set using the C<pos()>
1851 function; see L<perlfunc/pos>. A failed match normally resets the
1852 search position to the beginning of the string, but you can avoid that
1853 by adding the C</c> modifier (for example, C<m//gc>). Modifying the target
1854 string also resets the search position.
1855
1856 =item \G assertion
1857
1858 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1859 zero-width assertion that matches the exact position where the
1860 previous C<m//g>, if any, left off. Without the C</g> modifier, the
1861 C<\G> assertion still anchors at C<pos()> as it was at the start of
1862 the operation (see L<perlfunc/pos>), but the match is of course only
1863 attempted once. Using C<\G> without C</g> on a target string that has
1864 not previously had a C</g> match applied to it is the same as using
1865 the C<\A> assertion to match the beginning of the string.  Note also
1866 that, currently, C<\G> is only properly supported when anchored at the
1867 very beginning of the pattern.
1868
1869 Examples:
1870
1871     # list context
1872     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1873
1874     # scalar context
1875     local $/ = "";
1876     while ($paragraph = <>) {
1877         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1878             $sentences++;
1879         }
1880     }
1881     say $sentences;
1882
1883 Here's another way to check for sentences in a paragraph:
1884
1885  my $sentence_rx = qr{
1886     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1887                                 # whitespace
1888     \p{Lu}                      # capital letter
1889     .*?                         # a bunch of anything
1890     (?<= \S )                   # that ends in non-
1891                                 # whitespace
1892     (?<! \b [DMS]r  )           # but isn't a common abbr.
1893     (?<! \b Mrs )
1894     (?<! \b Sra )
1895     (?<! \b St  )
1896     [.?!]                       # followed by a sentence
1897                                 # ender
1898     (?= $ | \s )                # in front of end-of-string
1899                                 # or whitespace
1900  }sx;
1901  local $/ = "";
1902  while (my $paragraph = <>) {
1903     say "NEW PARAGRAPH";
1904     my $count = 0;
1905     while ($paragraph =~ /($sentence_rx)/g) {
1906         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1907     }
1908  }
1909
1910 Here's how to use C<m//gc> with C<\G>:
1911
1912     $_ = "ppooqppqq";
1913     while ($i++ < 2) {
1914         print "1: '";
1915         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1916         print "2: '";
1917         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1918         print "3: '";
1919         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1920     }
1921     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1922
1923 The last example should print:
1924
1925     1: 'oo', pos=4
1926     2: 'q', pos=5
1927     3: 'pp', pos=7
1928     1: '', pos=7
1929     2: 'q', pos=8
1930     3: '', pos=8
1931     Final: 'q', pos=8
1932
1933 Notice that the final match matched C<q> instead of C<p>, which a match
1934 without the C<\G> anchor would have done. Also note that the final match
1935 did not update C<pos>. C<pos> is only updated on a C</g> match. If the
1936 final match did indeed match C<p>, it's a good bet that you're running a
1937 very old (pre-5.6.0) version of Perl.
1938
1939 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1940 combine several regexps like this to process a string part-by-part,
1941 doing different actions depending on which regexp matched.  Each
1942 regexp tries to match where the previous one leaves off.
1943
1944  $_ = <<'EOL';
1945     $url = URI::URL->new( "http://example.com/" );
1946     die if $url eq "xXx";
1947  EOL
1948
1949  LOOP: {
1950      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1951      print(" lowercase"),    redo LOOP
1952                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
1953      print(" UPPERCASE"),    redo LOOP
1954                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
1955      print(" Capitalized"),  redo LOOP
1956                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
1957      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
1958      print(" alphanumeric"), redo LOOP
1959                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
1960      print(" line-noise"),   redo LOOP if /\G\W+/gc;
1961      print ". That's all!\n";
1962  }
1963
1964 Here is the output (split into several lines):
1965
1966  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
1967  line-noise lowercase line-noise lowercase line-noise lowercase
1968  lowercase line-noise lowercase lowercase line-noise lowercase
1969  lowercase line-noise MiXeD line-noise. That's all!
1970
1971 =item m?PATTERN?msixpodualgc
1972 X<?> X<operator, match-once>
1973
1974 =item ?PATTERN?msixpodualgc
1975
1976 This is just like the C<m/PATTERN/> search, except that it matches
1977 only once between calls to the reset() operator.  This is a useful
1978 optimization when you want to see only the first occurrence of
1979 something in each file of a set of files, for instance.  Only C<m??>
1980 patterns local to the current package are reset.
1981
1982     while (<>) {
1983         if (m?^$?) {
1984                             # blank line between header and body
1985         }
1986     } continue {
1987         reset if eof;       # clear m?? status for next file
1988     }
1989
1990 Another example switched the first "latin1" encoding it finds
1991 to "utf8" in a pod file:
1992
1993     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
1994
1995 The match-once behavior is controlled by the match delimiter being
1996 C<?>; with any other delimiter this is the normal C<m//> operator.  
1997
1998 For historical reasons, the leading C<m> in C<m?PATTERN?> is optional,
1999 but the resulting C<?PATTERN?> syntax is deprecated, will warn on
2000 usage and might be removed from a future stable release of Perl (without
2001 further notice!).
2002
2003 =item s/PATTERN/REPLACEMENT/msixpodualgcer
2004 X<substitute> X<substitution> X<replace> X<regexp, replace>
2005 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2006
2007 Searches a string for a pattern, and if found, replaces that pattern
2008 with the replacement text and returns the number of substitutions
2009 made.  Otherwise it returns false (specifically, the empty string).
2010
2011 If the C</r> (non-destructive) option is used then it runs the
2012 substitution on a copy of the string and instead of returning the
2013 number of substitutions, it returns the copy whether or not a
2014 substitution occurred.  The original string is never changed when
2015 C</r> is used.  The copy will always be a plain string, even if the
2016 input is an object or a tied variable.
2017
2018 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2019 variable is searched and modified.  Unless the C</r> option is used,
2020 the string specified must be a scalar variable, an array element, a
2021 hash element, or an assignment to one of those; that is, some sort of
2022 scalar lvalue.
2023
2024 If the delimiter chosen is a single quote, no interpolation is
2025 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
2026 PATTERN contains a $ that looks like a variable rather than an
2027 end-of-string test, the variable will be interpolated into the pattern
2028 at run-time.  If you want the pattern compiled only once the first time
2029 the variable is interpolated, use the C</o> option.  If the pattern
2030 evaluates to the empty string, the last successfully executed regular
2031 expression is used instead.  See L<perlre> for further explanation on these.
2032
2033 Options are as with m// with the addition of the following replacement
2034 specific options:
2035
2036     e   Evaluate the right side as an expression.
2037     ee  Evaluate the right side as a string then eval the
2038         result.
2039     r   Return substitution and leave the original string
2040         untouched.
2041
2042 Any non-whitespace delimiter may replace the slashes.  Add space after
2043 the C<s> when using a character allowed in identifiers.  If single quotes
2044 are used, no interpretation is done on the replacement string (the C</e>
2045 modifier overrides this, however).  Note that Perl treats backticks
2046 as normal delimiters; the replacement text is not evaluated as a command.
2047 If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has
2048 its own pair of quotes, which may or may not be bracketing quotes, for example,
2049 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2050 replacement portion to be treated as a full-fledged Perl expression
2051 and evaluated right then and there.  It is, however, syntax checked at
2052 compile-time. A second C<e> modifier will cause the replacement portion
2053 to be C<eval>ed before being run as a Perl expression.
2054
2055 Examples:
2056
2057     s/\bgreen\b/mauve/g;              # don't change wintergreen
2058
2059     $path =~ s|/usr/bin|/usr/local/bin|;
2060
2061     s/Login: $foo/Login: $bar/; # run-time pattern
2062
2063     ($foo = $bar) =~ s/this/that/;      # copy first, then
2064                                         # change
2065     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2066                                         # copy, then change
2067     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2068     $foo = $bar =~ s/this/that/r
2069                 =~ s/that/the other/r;  # Chained substitutes
2070                                         # using /r
2071     @foo = map { s/this/that/r } @bar   # /r is very useful in
2072                                         # maps
2073
2074     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2075
2076     $_ = 'abc123xyz';
2077     s/\d+/$&*2/e;               # yields 'abc246xyz'
2078     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2079     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2080
2081     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2082     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2083     s/^=(\w+)/pod($1)/ge;       # use function call
2084
2085     $_ = 'abc123xyz';
2086     $a = s/abc/def/r;           # $a is 'def123xyz' and
2087                                 # $_ remains 'abc123xyz'.
2088
2089     # expand variables in $_, but dynamics only, using
2090     # symbolic dereferencing
2091     s/\$(\w+)/${$1}/g;
2092
2093     # Add one to the value of any numbers in the string
2094     s/(\d+)/1 + $1/eg;
2095
2096     # Titlecase words in the last 30 characters only
2097     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2098
2099     # This will expand any embedded scalar variable
2100     # (including lexicals) in $_ : First $1 is interpolated
2101     # to the variable name, and then evaluated
2102     s/(\$\w+)/$1/eeg;
2103
2104     # Delete (most) C comments.
2105     $program =~ s {
2106         /\*     # Match the opening delimiter.
2107         .*?     # Match a minimal number of characters.
2108         \*/     # Match the closing delimiter.
2109     } []gsx;
2110
2111     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2112                                 # expensively
2113
2114     for ($variable) {           # trim whitespace in $variable,
2115                                 # cheap
2116         s/^\s+//;
2117         s/\s+$//;
2118     }
2119
2120     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2121
2122 Note the use of $ instead of \ in the last example.  Unlike
2123 B<sed>, we use the \<I<digit>> form in only the left hand side.
2124 Anywhere else it's $<I<digit>>.
2125
2126 Occasionally, you can't use just a C</g> to get all the changes
2127 to occur that you might want.  Here are two common cases:
2128
2129     # put commas in the right places in an integer
2130     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2131
2132     # expand tabs to 8-column spacing
2133     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2134
2135 =back
2136
2137 =head2 Quote-Like Operators
2138 X<operator, quote-like>
2139
2140 =over 4
2141
2142 =item q/STRING/
2143 X<q> X<quote, single> X<'> X<''>
2144
2145 =item 'STRING'
2146
2147 A single-quoted, literal string.  A backslash represents a backslash
2148 unless followed by the delimiter or another backslash, in which case
2149 the delimiter or backslash is interpolated.
2150
2151     $foo = q!I said, "You said, 'She said it.'"!;
2152     $bar = q('This is it.');
2153     $baz = '\n';                # a two-character string
2154
2155 =item qq/STRING/
2156 X<qq> X<quote, double> X<"> X<"">
2157
2158 =item "STRING"
2159
2160 A double-quoted, interpolated string.
2161
2162     $_ .= qq
2163      (*** The previous line contains the naughty word "$1".\n)
2164                 if /\b(tcl|java|python)\b/i;      # :-)
2165     $baz = "\n";                # a one-character string
2166
2167 =item qx/STRING/
2168 X<qx> X<`> X<``> X<backtick>
2169
2170 =item `STRING`
2171
2172 A string which is (possibly) interpolated and then executed as a
2173 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2174 pipes, and redirections will be honored.  The collected standard
2175 output of the command is returned; standard error is unaffected.  In
2176 scalar context, it comes back as a single (potentially multi-line)
2177 string, or undef if the command failed.  In list context, returns a
2178 list of lines (however you've defined lines with $/ or
2179 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
2180
2181 Because backticks do not affect standard error, use shell file descriptor
2182 syntax (assuming the shell supports this) if you care to address this.
2183 To capture a command's STDERR and STDOUT together:
2184
2185     $output = `cmd 2>&1`;
2186
2187 To capture a command's STDOUT but discard its STDERR:
2188
2189     $output = `cmd 2>/dev/null`;
2190
2191 To capture a command's STDERR but discard its STDOUT (ordering is
2192 important here):
2193
2194     $output = `cmd 2>&1 1>/dev/null`;
2195
2196 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2197 but leave its STDOUT to come out the old STDERR:
2198
2199     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2200
2201 To read both a command's STDOUT and its STDERR separately, it's easiest
2202 to redirect them separately to files, and then read from those files
2203 when the program is done:
2204
2205     system("program args 1>program.stdout 2>program.stderr");
2206
2207 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2208 For example:
2209
2210     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2211     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2212     print STDOUT `sort`;
2213
2214 will print the sorted contents of the file named F<"stuff">.
2215
2216 Using single-quote as a delimiter protects the command from Perl's
2217 double-quote interpolation, passing it on to the shell instead:
2218
2219     $perl_info  = qx(ps $$);            # that's Perl's $$
2220     $shell_info = qx'ps $$';            # that's the new shell's $$
2221
2222 How that string gets evaluated is entirely subject to the command
2223 interpreter on your system.  On most platforms, you will have to protect
2224 shell metacharacters if you want them treated literally.  This is in
2225 practice difficult to do, as it's unclear how to escape which characters.
2226 See L<perlsec> for a clean and safe example of a manual fork() and exec()
2227 to emulate backticks safely.
2228
2229 On some platforms (notably DOS-like ones), the shell may not be
2230 capable of dealing with multiline commands, so putting newlines in
2231 the string may not get you what you want.  You may be able to evaluate
2232 multiple commands in a single line by separating them with the command
2233 separator character, if your shell supports that (for example, C<;> on 
2234 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2235
2236 Perl will attempt to flush all files opened for
2237 output before starting the child process, but this may not be supported
2238 on some platforms (see L<perlport>).  To be safe, you may need to set
2239 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2240 C<IO::Handle> on any open handles.
2241
2242 Beware that some command shells may place restrictions on the length
2243 of the command line.  You must ensure your strings don't exceed this
2244 limit after any necessary interpolations.  See the platform-specific
2245 release notes for more details about your particular environment.
2246
2247 Using this operator can lead to programs that are difficult to port,
2248 because the shell commands called vary between systems, and may in
2249 fact not be present at all.  As one example, the C<type> command under
2250 the POSIX shell is very different from the C<type> command under DOS.
2251 That doesn't mean you should go out of your way to avoid backticks
2252 when they're the right way to get something done.  Perl was made to be
2253 a glue language, and one of the things it glues together is commands.
2254 Just understand what you're getting yourself into.
2255
2256 See L</"I/O Operators"> for more discussion.
2257
2258 =item qw/STRING/
2259 X<qw> X<quote, list> X<quote, words>
2260
2261 Evaluates to a list of the words extracted out of STRING, using embedded
2262 whitespace as the word delimiters.  It can be understood as being roughly
2263 equivalent to:
2264
2265     split(" ", q/STRING/);
2266
2267 the differences being that it generates a real list at compile time, and
2268 in scalar context it returns the last element in the list.  So
2269 this expression:
2270
2271     qw(foo bar baz)
2272
2273 is semantically equivalent to the list:
2274
2275     "foo", "bar", "baz"
2276
2277 Some frequently seen examples:
2278
2279     use POSIX qw( setlocale localeconv )
2280     @EXPORT = qw( foo bar baz );
2281
2282 A common mistake is to try to separate the words with comma or to
2283 put comments into a multi-line C<qw>-string.  For this reason, the
2284 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
2285 produces warnings if the STRING contains the "," or the "#" character.
2286
2287 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsr
2288 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2289
2290 =item y/SEARCHLIST/REPLACEMENTLIST/cdsr
2291
2292 Transliterates all occurrences of the characters found in the search list
2293 with the corresponding character in the replacement list.  It returns
2294 the number of characters replaced or deleted.  If no string is
2295 specified via the C<=~> or C<!~> operator, the $_ string is transliterated.
2296
2297 If the C</r> (non-destructive) option is present, a new copy of the string
2298 is made and its characters transliterated, and this copy is returned no
2299 matter whether it was modified or not: the original string is always
2300 left unchanged.  The new copy is always a plain string, even if the input
2301 string is an object or a tied variable.
2302
2303 Unless the C</r> option is used, the string specified with C<=~> must be a
2304 scalar variable, an array element, a hash element, or an assignment to one
2305 of those; in other words, an lvalue.
2306
2307 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2308 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2309 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2310 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
2311 its own pair of quotes, which may or may not be bracketing quotes;
2312 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2313
2314 Note that C<tr> does B<not> do regular expression character classes such as
2315 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the tr(1)
2316 utility.  If you want to map strings between lower/upper cases, see
2317 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
2318 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
2319 C<\l> string-interpolation escapes on the right side of a substitution
2320 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
2321 (except sometimes on legacy 7-bit data).
2322
2323 Note also that the whole range idea is rather unportable between
2324 character sets--and even within character sets they may cause results
2325 you probably didn't expect.  A sound principle is to use only ranges
2326 that begin from and end at either alphabets of equal case (a-e, A-E),
2327 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
2328 character sets in full.
2329
2330 Options:
2331
2332     c   Complement the SEARCHLIST.
2333     d   Delete found but unreplaced characters.
2334     s   Squash duplicate replaced characters.
2335     r   Return the modified string and leave the original string
2336         untouched.
2337
2338 If the C</c> modifier is specified, the SEARCHLIST character set
2339 is complemented.  If the C</d> modifier is specified, any characters
2340 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
2341 (Note that this is slightly more flexible than the behavior of some
2342 B<tr> programs, which delete anything they find in the SEARCHLIST,
2343 period.) If the C</s> modifier is specified, sequences of characters
2344 that were transliterated to the same character are squashed down
2345 to a single instance of the character.
2346
2347 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
2348 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
2349 than the SEARCHLIST, the final character is replicated till it is long
2350 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
2351 This latter is useful for counting characters in a class or for
2352 squashing character sequences in a class.
2353
2354 Examples:
2355
2356     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2357
2358     $cnt = tr/*/*/;             # count the stars in $_
2359
2360     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2361
2362     $cnt = tr/0-9//;            # count the digits in $_
2363
2364     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2365
2366     ($HOST = $host) =~ tr/a-z/A-Z/;
2367      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2368
2369     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2370                   =~ s/:/ -p/r;
2371
2372     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2373
2374     @stripped = map tr/a-zA-Z/ /csr, @original;
2375                                 # /r with map
2376
2377     tr [\200-\377]
2378        [\000-\177];             # wickedly delete 8th bit
2379
2380 If multiple transliterations are given for a character, only the
2381 first one is used:
2382
2383     tr/AAA/XYZ/
2384
2385 will transliterate any A to X.
2386
2387 Because the transliteration table is built at compile time, neither
2388 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
2389 interpolation.  That means that if you want to use variables, you
2390 must use an eval():
2391
2392     eval "tr/$oldlist/$newlist/";
2393     die $@ if $@;
2394
2395     eval "tr/$oldlist/$newlist/, 1" or die $@;
2396
2397 =item <<EOF
2398 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2399
2400 A line-oriented form of quoting is based on the shell "here-document"
2401 syntax.  Following a C<< << >> you specify a string to terminate
2402 the quoted material, and all lines following the current line down to
2403 the terminating string are the value of the item.
2404
2405 The terminating string may be either an identifier (a word), or some
2406 quoted text.  An unquoted identifier works like double quotes.
2407 There may not be a space between the C<< << >> and the identifier,
2408 unless the identifier is explicitly quoted.  (If you put a space it
2409 will be treated as a null identifier, which is valid, and matches the
2410 first empty line.)  The terminating string must appear by itself
2411 (unquoted and with no surrounding whitespace) on the terminating line.
2412
2413 If the terminating string is quoted, the type of quotes used determine
2414 the treatment of the text.
2415
2416 =over 4
2417
2418 =item Double Quotes
2419
2420 Double quotes indicate that the text will be interpolated using exactly
2421 the same rules as normal double quoted strings.
2422
2423        print <<EOF;
2424     The price is $Price.
2425     EOF
2426
2427        print << "EOF"; # same as above
2428     The price is $Price.
2429     EOF
2430
2431
2432 =item Single Quotes
2433
2434 Single quotes indicate the text is to be treated literally with no
2435 interpolation of its content. This is similar to single quoted
2436 strings except that backslashes have no special meaning, with C<\\>
2437 being treated as two backslashes and not one as they would in every
2438 other quoting construct.
2439
2440 Just as in the shell, a backslashed bareword following the C<<< << >>>
2441 means the same thing as a single-quoted string does:
2442
2443         $cost = <<'VISTA';  # hasta la ...
2444     That'll be $10 please, ma'am.
2445     VISTA
2446
2447         $cost = <<\VISTA;   # Same thing!
2448     That'll be $10 please, ma'am.
2449     VISTA
2450
2451 This is the only form of quoting in perl where there is no need
2452 to worry about escaping content, something that code generators
2453 can and do make good use of.
2454
2455 =item Backticks
2456
2457 The content of the here doc is treated just as it would be if the
2458 string were embedded in backticks. Thus the content is interpolated
2459 as though it were double quoted and then executed via the shell, with
2460 the results of the execution returned.
2461
2462        print << `EOC`; # execute command and get results
2463     echo hi there
2464     EOC
2465
2466 =back
2467
2468 It is possible to stack multiple here-docs in a row:
2469
2470        print <<"foo", <<"bar"; # you can stack them
2471     I said foo.
2472     foo
2473     I said bar.
2474     bar
2475
2476        myfunc(<< "THIS", 23, <<'THAT');
2477     Here's a line
2478     or two.
2479     THIS
2480     and here's another.
2481     THAT
2482
2483 Just don't forget that you have to put a semicolon on the end
2484 to finish the statement, as Perl doesn't know you're not going to
2485 try to do this:
2486
2487        print <<ABC
2488     179231
2489     ABC
2490        + 20;
2491
2492 If you want to remove the line terminator from your here-docs,
2493 use C<chomp()>.
2494
2495     chomp($string = <<'END');
2496     This is a string.
2497     END
2498
2499 If you want your here-docs to be indented with the rest of the code,
2500 you'll need to remove leading whitespace from each line manually:
2501
2502     ($quote = <<'FINIS') =~ s/^\s+//gm;
2503        The Road goes ever on and on,
2504        down from the door where it began.
2505     FINIS
2506
2507 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2508 the quoted material must still come on the line following the
2509 C<<< <<FOO >>> marker, which means it may be inside the delimited
2510 construct:
2511
2512     s/this/<<E . 'that'
2513     the other
2514     E
2515      . 'more '/eg;
2516
2517 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2518 you would have to write
2519
2520     s/this/<<E . 'that'
2521      . 'more '/eg;
2522     the other
2523     E
2524
2525 outside of string evals.
2526
2527 Additionally, quoting rules for the end-of-string identifier are
2528 unrelated to Perl's quoting rules. C<q()>, C<qq()>, and the like are not
2529 supported in place of C<''> and C<"">, and the only interpolation is for
2530 backslashing the quoting character:
2531
2532     print << "abc\"def";
2533     testing...
2534     abc"def
2535
2536 Finally, quoted strings cannot span multiple lines.  The general rule is
2537 that the identifier must be a string literal.  Stick with that, and you
2538 should be safe.
2539
2540 =back
2541
2542 =head2 Gory details of parsing quoted constructs
2543 X<quote, gory details>
2544
2545 When presented with something that might have several different
2546 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2547 principle to pick the most probable interpretation.  This strategy
2548 is so successful that Perl programmers often do not suspect the
2549 ambivalence of what they write.  But from time to time, Perl's
2550 notions differ substantially from what the author honestly meant.
2551
2552 This section hopes to clarify how Perl handles quoted constructs.
2553 Although the most common reason to learn this is to unravel labyrinthine
2554 regular expressions, because the initial steps of parsing are the
2555 same for all quoting operators, they are all discussed together.
2556
2557 The most important Perl parsing rule is the first one discussed
2558 below: when processing a quoted construct, Perl first finds the end
2559 of that construct, then interprets its contents.  If you understand
2560 this rule, you may skip the rest of this section on the first
2561 reading.  The other rules are likely to contradict the user's
2562 expectations much less frequently than this first one.
2563
2564 Some passes discussed below are performed concurrently, but because
2565 their results are the same, we consider them individually.  For different
2566 quoting constructs, Perl performs different numbers of passes, from
2567 one to four, but these passes are always performed in the same order.
2568
2569 =over 4
2570
2571 =item Finding the end
2572
2573 The first pass is finding the end of the quoted construct, where
2574 the information about the delimiters is used in parsing.
2575 During this search, text between the starting and ending delimiters
2576 is copied to a safe location. The text copied gets delimiter-independent.
2577
2578 If the construct is a here-doc, the ending delimiter is a line
2579 that has a terminating string as the content. Therefore C<<<EOF> is
2580 terminated by C<EOF> immediately followed by C<"\n"> and starting
2581 from the first column of the terminating line.
2582 When searching for the terminating line of a here-doc, nothing
2583 is skipped. In other words, lines after the here-doc syntax
2584 are compared with the terminating string line by line.
2585
2586 For the constructs except here-docs, single characters are used as starting
2587 and ending delimiters. If the starting delimiter is an opening punctuation
2588 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2589 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2590 If the starting delimiter is an unpaired character like C</> or a closing
2591 punctuation, the ending delimiter is same as the starting delimiter.
2592 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2593 C<qq[]> and C<qq]]> constructs.
2594
2595 When searching for single-character delimiters, escaped delimiters
2596 and C<\\> are skipped.  For example, while searching for terminating C</>,
2597 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2598 bracketing, nested pairs are also skipped.  For example, while searching
2599 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2600 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2601 However, when backslashes are used as the delimiters (like C<qq\\> and
2602 C<tr\\\>), nothing is skipped.
2603 During the search for the end, backslashes that escape delimiters or
2604 other backslashes are removed (exactly speaking, they are not copied to the
2605 safe location).
2606
2607 For constructs with three-part delimiters (C<s///>, C<y///>, and
2608 C<tr///>), the search is repeated once more.
2609 If the first delimiter is not an opening punctuation, three delimiters must
2610 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
2611 terminates the left part and starts the right part at once.
2612 If the left part is delimited by bracketing punctuation (that is C<()>,
2613 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2614 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2615 and comments are allowed between both parts, though the comment must follow
2616 at least one whitespace character; otherwise a character expected as the 
2617 start of the comment may be regarded as the starting delimiter of the right part.
2618
2619 During this search no attention is paid to the semantics of the construct.
2620 Thus:
2621
2622     "$hash{"$foo/$bar"}"
2623
2624 or:
2625
2626     m/
2627       bar       # NOT a comment, this slash / terminated m//!
2628      /x
2629
2630 do not form legal quoted expressions.   The quoted part ends on the
2631 first C<"> and C</>, and the rest happens to be a syntax error.
2632 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2633 the example above is not C<m//x>, but rather C<m//> with no C</x>
2634 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2635
2636 Also no attention is paid to C<\c\> (multichar control char syntax) during
2637 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2638 of C<\/>, and the following C</> is not recognized as a delimiter.
2639 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2640
2641 =item Interpolation
2642 X<interpolation>
2643
2644 The next step is interpolation in the text obtained, which is now
2645 delimiter-independent.  There are multiple cases.
2646
2647 =over 4
2648
2649 =item C<<<'EOF'>
2650
2651 No interpolation is performed.
2652 Note that the combination C<\\> is left intact, since escaped delimiters
2653 are not available for here-docs.
2654
2655 =item  C<m''>, the pattern of C<s'''>
2656
2657 No interpolation is performed at this stage.
2658 Any backslashed sequences including C<\\> are treated at the stage
2659 to L</"parsing regular expressions">.
2660
2661 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2662
2663 The only interpolation is removal of C<\> from pairs of C<\\>.
2664 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
2665 as a hyphen and no character range is available.
2666 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2667
2668 =item C<tr///>, C<y///>
2669
2670 No variable interpolation occurs.  String modifying combinations for
2671 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2672 The other escape sequences such as C<\200> and C<\t> and backslashed
2673 characters such as C<\\> and C<\-> are converted to appropriate literals.
2674 The character C<-> is treated specially and therefore C<\-> is treated
2675 as a literal C<->.
2676
2677 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2678
2679 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2680 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2681 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
2682 The other escape sequences such as C<\200> and C<\t> and backslashed
2683 characters such as C<\\> and C<\-> are replaced with appropriate
2684 expansions.
2685
2686 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2687 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2688 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2689 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2690 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2691 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2692 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2693
2694   $str = '\t';
2695   return "\Q$str";
2696
2697 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2698
2699 Interpolated scalars and arrays are converted internally to the C<join> and
2700 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
2701
2702   $foo . " XXX '" . (join $", @arr) . "'";
2703
2704 All operations above are performed simultaneously, left to right.
2705
2706 Because the result of C<"\Q STRING \E"> has all metacharacters
2707 quoted, there is no way to insert a literal C<$> or C<@> inside a
2708 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2709 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2710 scalar.
2711
2712 Note also that the interpolation code needs to make a decision on
2713 where the interpolated scalar ends.  For instance, whether
2714 C<< "a $b -> {c}" >> really means:
2715
2716   "a " . $b . " -> {c}";
2717
2718 or:
2719
2720   "a " . $b -> {c};
2721
2722 Most of the time, the longest possible text that does not include
2723 spaces between components and which contains matching braces or
2724 brackets.  because the outcome may be determined by voting based
2725 on heuristic estimators, the result is not strictly predictable.
2726 Fortunately, it's usually correct for ambiguous cases.
2727
2728 =item the replacement of C<s///>
2729
2730 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2731 happens as with C<qq//> constructs.
2732
2733 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2734 the replacement text of C<s///>, in order to correct the incorrigible
2735 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2736 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2737 (that is, the C<$^W> variable) was set.
2738
2739 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2740
2741 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2742 and interpolation happens (almost) as with C<qq//> constructs.
2743
2744 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2745 form for the regex compiler.  (This is because, as mentioned below, the regex
2746 compilation may be done at execution time, and C<\N{...}> is a compile-time
2747 construct.)
2748
2749 However any other combinations of C<\> followed by a character
2750 are not substituted but only skipped, in order to parse them
2751 as regular expressions at the following step.
2752 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2753 treated as an array symbol (for example C<@foo>),
2754 even though the same text in C<qq//> gives interpolation of C<\c@>.
2755
2756 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2757 back to the perl parser, in a similar way that an interpolated array
2758 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2759
2760 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2761 a C<#>-comment in a C<//x>-regular expression, no processing is
2762 performed whatsoever.  This is the first step at which the presence
2763 of the C<//x> modifier is relevant.
2764
2765 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2766 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2767 voted (by several different estimators) to be either an array element
2768 or C<$var> followed by an RE alternative.  This is where the notation
2769 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2770 array element C<-9>, not as a regular expression from the variable
2771 C<$arr> followed by a digit, which would be the interpretation of
2772 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2773 the result is not predictable.
2774
2775 The lack of processing of C<\\> creates specific restrictions on
2776 the post-processed text.  If the delimiter is C</>, one cannot get
2777 the combination C<\/> into the result of this step.  C</> will
2778 finish the regular expression, C<\/> will be stripped to C</> on
2779 the previous step, and C<\\/> will be left as is.  Because C</> is
2780 equivalent to C<\/> inside a regular expression, this does not
2781 matter unless the delimiter happens to be character special to the
2782 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2783 alphanumeric char, as in:
2784
2785   m m ^ a \s* b mmx;
2786
2787 In the RE above, which is intentionally obfuscated for illustration, the
2788 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2789 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2790 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2791 non-whitespace choices.
2792
2793 =back
2794
2795 This step is the last one for all constructs except regular expressions,
2796 which are processed further.
2797
2798 =item parsing regular expressions
2799 X<regexp, parse>
2800
2801 Previous steps were performed during the compilation of Perl code,
2802 but this one happens at run time, although it may be optimized to
2803 be calculated at compile time if appropriate.  After preprocessing
2804 described above, and possibly after evaluation if concatenation,
2805 joining, casing translation, or metaquoting are involved, the
2806 resulting I<string> is passed to the RE engine for compilation.
2807
2808 Whatever happens in the RE engine might be better discussed in L<perlre>,
2809 but for the sake of continuity, we shall do so here.
2810
2811 This is another step where the presence of the C<//x> modifier is
2812 relevant.  The RE engine scans the string from left to right and
2813 converts it to a finite automaton.
2814
2815 Backslashed characters are either replaced with corresponding
2816 literal strings (as with C<\{>), or else they generate special nodes
2817 in the finite automaton (as with C<\b>).  Characters special to the
2818 RE engine (such as C<|>) generate corresponding nodes or groups of
2819 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2820 converted to literal strings to match, or else is ignored (as is
2821 whitespace and C<#>-style comments if C<//x> is present).
2822
2823 Parsing of the bracketed character class construct, C<[...]>, is
2824 rather different than the rule used for the rest of the pattern.
2825 The terminator of this construct is found using the same rules as
2826 for finding the terminator of a C<{}>-delimited construct, the only
2827 exception being that C<]> immediately following C<[> is treated as
2828 though preceded by a backslash.
2829
2830 The terminator of runtime C<(?{...})> is found by temporarily switching
2831 control to the perl parser, which should stop at the point where the
2832 logically balancing terminating C<}> is found.
2833
2834 It is possible to inspect both the string given to RE engine and the
2835 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2836 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2837 switch documented in L<perlrun/"Command Switches">.
2838
2839 =item Optimization of regular expressions
2840 X<regexp, optimization>
2841
2842 This step is listed for completeness only.  Since it does not change
2843 semantics, details of this step are not documented and are subject
2844 to change without notice.  This step is performed over the finite
2845 automaton that was generated during the previous pass.
2846
2847 It is at this stage that C<split()> silently optimizes C</^/> to
2848 mean C</^/m>.
2849
2850 =back
2851
2852 =head2 I/O Operators
2853 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2854 X<< <> >> X<@ARGV>
2855
2856 There are several I/O operators you should know about.
2857
2858 A string enclosed by backticks (grave accents) first undergoes
2859 double-quote interpolation.  It is then interpreted as an external
2860 command, and the output of that command is the value of the
2861 backtick string, like in a shell.  In scalar context, a single string
2862 consisting of all output is returned.  In list context, a list of
2863 values is returned, one per line of output.  (You can set C<$/> to use
2864 a different line terminator.)  The command is executed each time the
2865 pseudo-literal is evaluated.  The status value of the command is
2866 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2867 Unlike in B<csh>, no translation is done on the return data--newlines
2868 remain newlines.  Unlike in any of the shells, single quotes do not
2869 hide variable names in the command from interpretation.  To pass a
2870 literal dollar-sign through to the shell you need to hide it with a
2871 backslash.  The generalized form of backticks is C<qx//>.  (Because
2872 backticks always undergo shell expansion as well, see L<perlsec> for
2873 security concerns.)
2874 X<qx> X<`> X<``> X<backtick> X<glob>
2875
2876 In scalar context, evaluating a filehandle in angle brackets yields
2877 the next line from that file (the newline, if any, included), or
2878 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2879 (sometimes known as file-slurp mode) and the file is empty, it
2880 returns C<''> the first time, followed by C<undef> subsequently.
2881
2882 Ordinarily you must assign the returned value to a variable, but
2883 there is one situation where an automatic assignment happens.  If
2884 and only if the input symbol is the only thing inside the conditional
2885 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2886 the value is automatically assigned to the global variable $_,
2887 destroying whatever was there previously.  (This may seem like an
2888 odd thing to you, but you'll use the construct in almost every Perl
2889 script you write.)  The $_ variable is not implicitly localized.
2890 You'll have to put a C<local $_;> before the loop if you want that
2891 to happen.
2892
2893 The following lines are equivalent:
2894
2895     while (defined($_ = <STDIN>)) { print; }
2896     while ($_ = <STDIN>) { print; }
2897     while (<STDIN>) { print; }
2898     for (;<STDIN>;) { print; }
2899     print while defined($_ = <STDIN>);
2900     print while ($_ = <STDIN>);
2901     print while <STDIN>;
2902
2903 This also behaves similarly, but assigns to a lexical variable 
2904 instead of to C<$_>:
2905
2906     while (my $line = <STDIN>) { print $line }
2907
2908 In these loop constructs, the assigned value (whether assignment
2909 is automatic or explicit) is then tested to see whether it is
2910 defined.  The defined test avoids problems where the line has a string
2911 value that would be treated as false by Perl; for example a "" or
2912 a "0" with no trailing newline.  If you really mean for such values
2913 to terminate the loop, they should be tested for explicitly:
2914
2915     while (($_ = <STDIN>) ne '0') { ... }
2916     while (<STDIN>) { last unless $_; ... }
2917
2918 In other boolean contexts, C<< <FILEHANDLE> >> without an
2919 explicit C<defined> test or comparison elicits a warning if the
2920 C<use warnings> pragma or the B<-w>
2921 command-line switch (the C<$^W> variable) is in effect.
2922
2923 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2924 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2925 in packages, where they would be interpreted as local identifiers
2926 rather than global.)  Additional filehandles may be created with
2927 the open() function, amongst others.  See L<perlopentut> and
2928 L<perlfunc/open> for details on this.
2929 X<stdin> X<stdout> X<sterr>
2930
2931 If a <FILEHANDLE> is used in a context that is looking for
2932 a list, a list comprising all input lines is returned, one line per
2933 list element.  It's easy to grow to a rather large data space this
2934 way, so use with care.
2935
2936 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2937 See L<perlfunc/readline>.
2938
2939 The null filehandle <> is special: it can be used to emulate the
2940 behavior of B<sed> and B<awk>, and any other Unix filter program
2941 that takes a list of filenames, doing the same to each line
2942 of input from all of them.  Input from <> comes either from
2943 standard input, or from each file listed on the command line.  Here's
2944 how it works: the first time <> is evaluated, the @ARGV array is
2945 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2946 gives you standard input.  The @ARGV array is then processed as a list
2947 of filenames.  The loop
2948
2949     while (<>) {
2950         ...                     # code for each line
2951     }
2952
2953 is equivalent to the following Perl-like pseudo code:
2954
2955     unshift(@ARGV, '-') unless @ARGV;
2956     while ($ARGV = shift) {
2957         open(ARGV, $ARGV);
2958         while (<ARGV>) {
2959             ...         # code for each line
2960         }
2961     }
2962
2963 except that it isn't so cumbersome to say, and will actually work.
2964 It really does shift the @ARGV array and put the current filename
2965 into the $ARGV variable.  It also uses filehandle I<ARGV>
2966 internally. <> is just a synonym for <ARGV>, which
2967 is magical.  (The pseudo code above doesn't work because it treats
2968 <ARGV> as non-magical.)
2969
2970 Since the null filehandle uses the two argument form of L<perlfunc/open>
2971 it interprets special characters, so if you have a script like this:
2972
2973     while (<>) {
2974         print;
2975     }
2976
2977 and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a
2978 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
2979 If you want all items in C<@ARGV> to be interpreted as file names, you
2980 can use the module C<ARGV::readonly> from CPAN.
2981
2982 You can modify @ARGV before the first <> as long as the array ends up
2983 containing the list of filenames you really want.  Line numbers (C<$.>)
2984 continue as though the input were one big happy file.  See the example
2985 in L<perlfunc/eof> for how to reset line numbers on each file.
2986
2987 If you want to set @ARGV to your own list of files, go right ahead.
2988 This sets @ARGV to all plain text files if no @ARGV was given:
2989
2990     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2991
2992 You can even set them to pipe commands.  For example, this automatically
2993 filters compressed arguments through B<gzip>:
2994
2995     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2996
2997 If you want to pass switches into your script, you can use one of the
2998 Getopts modules or put a loop on the front like this:
2999
3000     while ($_ = $ARGV[0], /^-/) {
3001         shift;
3002         last if /^--$/;
3003         if (/^-D(.*)/) { $debug = $1 }
3004         if (/^-v/)     { $verbose++  }
3005         # ...           # other switches
3006     }
3007
3008     while (<>) {
3009         # ...           # code for each line
3010     }
3011
3012 The <> symbol will return C<undef> for end-of-file only once.
3013 If you call it again after this, it will assume you are processing another
3014 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
3015
3016 If what the angle brackets contain is a simple scalar variable (for example,
3017 <$foo>), then that variable contains the name of the
3018 filehandle to input from, or its typeglob, or a reference to the
3019 same.  For example:
3020
3021     $fh = \*STDIN;
3022     $line = <$fh>;
3023
3024 If what's within the angle brackets is neither a filehandle nor a simple
3025 scalar variable containing a filehandle name, typeglob, or typeglob
3026 reference, it is interpreted as a filename pattern to be globbed, and
3027 either a list of filenames or the next filename in the list is returned,
3028 depending on context.  This distinction is determined on syntactic
3029 grounds alone.  That means C<< <$x> >> is always a readline() from
3030 an indirect handle, but C<< <$hash{key}> >> is always a glob().
3031 That's because $x is a simple scalar variable, but C<$hash{key}> is
3032 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3033 is treated as C<glob("$x ")>, not C<readline($x)>.
3034
3035 One level of double-quote interpretation is done first, but you can't
3036 say C<< <$foo> >> because that's an indirect filehandle as explained
3037 in the previous paragraph.  (In older versions of Perl, programmers
3038 would insert curly brackets to force interpretation as a filename glob:
3039 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3040 internal function directly as C<glob($foo)>, which is probably the right
3041 way to have done it in the first place.)  For example:
3042
3043     while (<*.c>) {
3044         chmod 0644, $_;
3045     }
3046
3047 is roughly equivalent to:
3048
3049     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3050     while (<FOO>) {
3051         chomp;
3052         chmod 0644, $_;
3053     }
3054
3055 except that the globbing is actually done internally using the standard
3056 C<File::Glob> extension.  Of course, the shortest way to do the above is:
3057
3058     chmod 0644, <*.c>;
3059
3060 A (file)glob evaluates its (embedded) argument only when it is
3061 starting a new list.  All values must be read before it will start
3062 over.  In list context, this isn't important because you automatically
3063 get them all anyway.  However, in scalar context the operator returns
3064 the next value each time it's called, or C<undef> when the list has
3065 run out.  As with filehandle reads, an automatic C<defined> is
3066 generated when the glob occurs in the test part of a C<while>,
3067 because legal glob returns (for example,
3068 a file called F<0>) would otherwise
3069 terminate the loop.  Again, C<undef> is returned only once.  So if
3070 you're expecting a single value from a glob, it is much better to
3071 say
3072
3073     ($file) = <blurch*>;
3074
3075 than
3076
3077     $file = <blurch*>;
3078
3079 because the latter will alternate between returning a filename and
3080 returning false.
3081
3082 If you're trying to do variable interpolation, it's definitely better
3083 to use the glob() function, because the older notation can cause people
3084 to become confused with the indirect filehandle notation.
3085
3086     @files = glob("$dir/*.[ch]");
3087     @files = glob($files[$i]);
3088
3089 =head2 Constant Folding
3090 X<constant folding> X<folding>
3091
3092 Like C, Perl does a certain amount of expression evaluation at
3093 compile time whenever it determines that all arguments to an
3094 operator are static and have no side effects.  In particular, string
3095 concatenation happens at compile time between literals that don't do
3096 variable substitution.  Backslash interpolation also happens at
3097 compile time.  You can say
3098
3099       'Now is the time for all'
3100     . "\n" 
3101     .  'good men to come to.'
3102
3103 and this all reduces to one string internally.  Likewise, if
3104 you say
3105
3106     foreach $file (@filenames) {
3107         if (-s $file > 5 + 100 * 2**16) {  }
3108     }
3109
3110 the compiler precomputes the number which that expression
3111 represents so that the interpreter won't have to.
3112
3113 =head2 No-ops
3114 X<no-op> X<nop>
3115
3116 Perl doesn't officially have a no-op operator, but the bare constants
3117 C<0> and C<1> are special-cased not to produce a warning in void
3118 context, so you can for example safely do
3119
3120     1 while foo();
3121
3122 =head2 Bitwise String Operators
3123 X<operator, bitwise, string>
3124
3125 Bitstrings of any size may be manipulated by the bitwise operators
3126 (C<~ | & ^>).
3127
3128 If the operands to a binary bitwise op are strings of different
3129 sizes, B<|> and B<^> ops act as though the shorter operand had
3130 additional zero bits on the right, while the B<&> op acts as though
3131 the longer operand were truncated to the length of the shorter.
3132 The granularity for such extension or truncation is one or more
3133 bytes.
3134
3135     # ASCII-based examples
3136     print "j p \n" ^ " a h";            # prints "JAPH\n"
3137     print "JA" | "  ph\n";              # prints "japh\n"
3138     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3139     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3140
3141 If you are intending to manipulate bitstrings, be certain that
3142 you're supplying bitstrings: If an operand is a number, that will imply
3143 a B<numeric> bitwise operation.  You may explicitly show which type of
3144 operation you intend by using C<""> or C<0+>, as in the examples below.
3145
3146     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3147     $foo = '150' |  105;        # yields 255
3148     $foo =  150  | '105';       # yields 255
3149     $foo = '150' | '105';       # yields string '155' (under ASCII)
3150
3151     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3152     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3153
3154 See L<perlfunc/vec> for information on how to manipulate individual bits
3155 in a bit vector.
3156
3157 =head2 Integer Arithmetic
3158 X<integer>
3159
3160 By default, Perl assumes that it must do most of its arithmetic in
3161 floating point.  But by saying
3162
3163     use integer;
3164
3165 you may tell the compiler to use integer operations
3166 (see L<integer> for a detailed explanation) from here to the end of
3167 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3168
3169     no integer;
3170
3171 which lasts until the end of that BLOCK.  Note that this doesn't
3172 mean everything is an integer, merely that Perl will use integer
3173 operations for arithmetic, comparison, and bitwise operators.  For
3174 example, even under C<use integer>, if you take the C<sqrt(2)>, you'll
3175 still get C<1.4142135623731> or so.
3176
3177 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
3178 and ">>") always produce integral results.  (But see also
3179 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
3180 them.  By default, their results are interpreted as unsigned integers, but
3181 if C<use integer> is in effect, their results are interpreted
3182 as signed integers.  For example, C<~0> usually evaluates to a large
3183 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
3184 machines.
3185
3186 =head2 Floating-point Arithmetic
3187
3188 X<floating-point> X<floating point> X<float> X<real>
3189
3190 While C<use integer> provides integer-only arithmetic, there is no
3191 analogous mechanism to provide automatic rounding or truncation to a
3192 certain number of decimal places.  For rounding to a certain number
3193 of digits, sprintf() or printf() is usually the easiest route.
3194 See L<perlfaq4>.
3195
3196 Floating-point numbers are only approximations to what a mathematician
3197 would call real numbers.  There are infinitely more reals than floats,
3198 so some corners must be cut.  For example:
3199
3200     printf "%.20g\n", 123456789123456789;
3201     #        produces 123456789123456784
3202
3203 Testing for exact floating-point equality or inequality is not a
3204 good idea.  Here's a (relatively expensive) work-around to compare
3205 whether two floating-point numbers are equal to a particular number of
3206 decimal places.  See Knuth, volume II, for a more robust treatment of
3207 this topic.
3208
3209     sub fp_equal {
3210         my ($X, $Y, $POINTS) = @_;
3211         my ($tX, $tY);
3212         $tX = sprintf("%.${POINTS}g", $X);
3213         $tY = sprintf("%.${POINTS}g", $Y);
3214         return $tX eq $tY;
3215     }
3216
3217 The POSIX module (part of the standard perl distribution) implements
3218 ceil(), floor(), and other mathematical and trigonometric functions.
3219 The Math::Complex module (part of the standard perl distribution)
3220 defines mathematical functions that work on both the reals and the
3221 imaginary numbers.  Math::Complex not as efficient as POSIX, but
3222 POSIX can't work with complex numbers.
3223
3224 Rounding in financial applications can have serious implications, and
3225 the rounding method used should be specified precisely.  In these
3226 cases, it probably pays not to trust whichever system rounding is
3227 being used by Perl, but to instead implement the rounding function you
3228 need yourself.
3229
3230 =head2 Bigger Numbers
3231 X<number, arbitrary precision>
3232
3233 The standard C<Math::BigInt>, C<Math::BigRat>, and C<Math::BigFloat> modules,
3234 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3235 variable-precision arithmetic and overloaded operators, although
3236 they're currently pretty slow. At the cost of some space and
3237 considerable speed, they avoid the normal pitfalls associated with
3238 limited-precision representations.
3239
3240         use 5.010;
3241         use bigint;  # easy interface to Math::BigInt
3242         $x = 123456789123456789;
3243         say $x * $x;
3244     +15241578780673678515622620750190521
3245
3246 Or with rationals:
3247
3248         use 5.010;
3249         use bigrat;
3250         $a = 3/22;
3251         $b = 4/6;
3252         say "a/b is ", $a/$b;
3253         say "a*b is ", $a*$b;
3254     a/b is 9/44
3255     a*b is 1/11
3256
3257 Several modules let you calculate with (bound only by memory and CPU time)
3258 unlimited or fixed precision. There are also some non-standard modules that
3259 provide faster implementations via external C libraries.
3260
3261 Here is a short, but incomplete summary:
3262
3263   Math::String           treat string sequences like numbers
3264   Math::FixedPrecision   calculate with a fixed precision
3265   Math::Currency         for currency calculations
3266   Bit::Vector            manipulate bit vectors fast (uses C)
3267   Math::BigIntFast       Bit::Vector wrapper for big numbers
3268   Math::Pari             provides access to the Pari C library
3269   Math::Cephes           uses the external Cephes C library (no
3270                          big numbers)
3271   Math::Cephes::Fraction fractions via the Cephes library
3272   Math::GMP              another one using an external C library
3273   Math::GMPz             an alternative interface to libgmp's big ints
3274   Math::GMPq             an interface to libgmp's fraction numbers
3275   Math::GMPf             an interface to libgmp's floating point numbers
3276
3277 Choose wisely.
3278
3279 =cut