This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Remove support for Splint static source code analyzer
[perl5.git] / regen / embed.pl
1 #!/usr/bin/perl -w
2
3 # Regenerate (overwriting only if changed):
4 #
5 #    embed.h
6 #    embedvar.h
7 #    perlapi.c
8 #    perlapi.h
9 #    proto.h
10 #
11 # from information stored in
12 #
13 #    embed.fnc
14 #    intrpvar.h
15 #    perlvars.h
16 #    regen/opcodes
17 #
18 # Accepts the standard regen_lib -q and -v args.
19 #
20 # This script is normally invoked from regen.pl.
21
22 require 5.004;  # keep this compatible, an old perl is all we may have before
23                 # we build the new one
24
25 use strict;
26
27 BEGIN {
28     # Get function prototypes
29     require './regen/regen_lib.pl';
30     require './regen/embed_lib.pl';
31 }
32
33 my $unflagged_pointers;
34
35 #
36 # See database of global and static function prototypes in embed.fnc
37 # This is used to generate prototype headers under various configurations,
38 # export symbols lists for different platforms, and macros to provide an
39 # implicit interpreter context argument.
40 #
41
42 sub full_name ($$) { # Returns the function name with potentially the
43                      # prefixes 'S_' or 'Perl_'
44     my ($func, $flags) = @_;
45
46     return "Perl_$func" if $flags =~ /p/;
47     return "S_$func" if $flags =~ /[si]/;
48     return $func;
49 }
50
51 sub open_print_header {
52     my ($file, $quote) = @_;
53
54     return open_new($file, '>',
55                     { file => $file, style => '*', by => 'regen/embed.pl',
56                       from => ['data in embed.fnc', 'regen/embed.pl',
57                                'regen/opcodes', 'intrpvar.h', 'perlvars.h'],
58                       final => "\nEdit those files and run 'make regen_headers' to effect changes.\n",
59                       copyright => [1993 .. 2009], quote => $quote });
60 }
61
62 my ($embed, $core, $ext, $api) = setup_embed();
63
64 # generate proto.h
65 {
66     my $pr = open_print_header("proto.h");
67     print $pr "START_EXTERN_C\n";
68     my $ret;
69
70     foreach (@$embed) {
71         if (@$_ == 1) {
72             print $pr "$_->[0]\n";
73             next;
74         }
75
76         my ($flags,$retval,$plain_func,@args) = @$_;
77         if ($flags =~ / ( [^AabDdEfiMmnOoPpRrsUWXx] ) /x) {
78             warn "flag $1 is not legal (for function $plain_func)";
79         }
80         my @nonnull;
81         my $has_depth = ( $flags =~ /W/ );
82         my $has_context = ( $flags !~ /n/ );
83         my $never_returns = ( $flags =~ /r/ );
84         my $binarycompat = ( $flags =~ /b/ );
85         my $commented_out = ( ! $binarycompat && $flags =~ /m/ );
86         my $is_malloc = ( $flags =~ /a/ );
87         my $can_ignore = ( $flags !~ /R/ ) && ( $flags !~ /P/ ) && !$is_malloc;
88         my @names_of_nn;
89         my $func;
90
91         if (! $can_ignore && $retval eq 'void') {
92             warn "It is nonsensical to require the return value of a void function ($plain_func) to be checked";
93         }
94
95         warn "$plain_func: s flag is mutually exclusive from the i and p plags"
96                                             if $flags =~ /s/ && $flags =~ /[ip]/;
97
98         if ($flags =~ /([si])/) {
99             my $type;
100             if ($never_returns) {
101                 $type = $1 eq 's' ? "PERL_STATIC_NO_RET" : "PERL_STATIC_INLINE_NO_RET";
102             }
103             else {
104                 $type = $1 eq 's' ? "STATIC" : "PERL_STATIC_INLINE";
105             }
106             $retval = "$type $retval";
107         }
108         else {
109             if ($never_returns) {
110                 $retval = "PERL_CALLCONV_NO_RET $retval";
111             }
112             else {
113                 $retval = "PERL_CALLCONV $retval";
114             }
115         }
116         $func = full_name($plain_func, $flags);
117         $ret = "";
118         $ret .= "#ifndef NO_MATHOMS\n" if $binarycompat;
119         $ret .= "$retval\t$func(";
120         if ( $has_context ) {
121             $ret .= @args ? "pTHX_ " : "pTHX";
122         }
123         if (@args) {
124             my $n;
125             for my $arg ( @args ) {
126                 ++$n;
127                 if ( $arg =~ /\*/ && $arg !~ /\b(NN|NULLOK)\b/ ) {
128                     warn "$func: $arg needs NN or NULLOK\n";
129                     ++$unflagged_pointers;
130                 }
131                 my $nn = ( $arg =~ s/\s*\bNN\b\s+// );
132                 push( @nonnull, $n ) if $nn;
133
134                 my $nullok = ( $arg =~ s/\s*\bNULLOK\b\s+// ); # strip NULLOK with no effect
135
136                 # Make sure each arg has at least a type and a var name.
137                 # An arg of "int" is valid C, but want it to be "int foo".
138                 my $temp_arg = $arg;
139                 $temp_arg =~ s/\*//g;
140                 $temp_arg =~ s/\s*\bstruct\b\s*/ /g;
141                 if ( ($temp_arg ne "...")
142                      && ($temp_arg !~ /\w+\s+(\w+)(?:\[\d+\])?\s*$/) ) {
143                     warn "$func: $arg ($n) doesn't have a name\n";
144                 }
145                 if (defined $1 && $nn && !($commented_out && !$binarycompat)) {
146                     push @names_of_nn, $1;
147                 }
148             }
149             $ret .= join ", ", @args;
150         }
151         else {
152             $ret .= "void" if !$has_context;
153         }
154         $ret .= " _pDEPTH" if $has_depth;
155         $ret .= ")";
156         my @attrs;
157         if ( $flags =~ /r/ ) {
158             push @attrs, "__attribute__noreturn__";
159         }
160         if ( $flags =~ /D/ ) {
161             push @attrs, "__attribute__deprecated__";
162         }
163         if ( $is_malloc ) {
164             push @attrs, "__attribute__malloc__";
165         }
166         if ( !$can_ignore ) {
167             push @attrs, "__attribute__warn_unused_result__";
168         }
169         if ( $flags =~ /P/ ) {
170             push @attrs, "__attribute__pure__";
171         }
172         if( $flags =~ /f/ ) {
173             my $prefix  = $has_context ? 'pTHX_' : '';
174             my ($args, $pat);
175             if ($args[-1] eq '...') {
176                 $args   = scalar @args;
177                 $pat    = $args - 1;
178                 $args   = $prefix . $args;
179             }
180             else {
181                 # don't check args, and guess which arg is the pattern
182                 # (one of 'fmt', 'pat', 'f'),
183                 $args = 0;
184                 my @fmts = grep $args[$_] =~ /\b(f|pat|fmt)$/, 0..$#args;
185                 if (@fmts != 1) {
186                     die "embed.pl: '$plain_func': can't determine pattern arg\n";
187                 }
188                 $pat = $fmts[0] + 1;
189             }
190             my $macro   = grep($_ == $pat, @nonnull)
191                                 ? '__attribute__format__'
192                                 : '__attribute__format__null_ok__';
193             if ($plain_func =~ /strftime/) {
194                 push @attrs, sprintf "%s(__strftime__,%s1,0)", $macro, $prefix;
195             }
196             else {
197                 push @attrs, sprintf "%s(__printf__,%s%d,%s)", $macro,
198                                     $prefix, $pat, $args;
199             }
200         }
201         if ( @attrs ) {
202             $ret .= "\n";
203             $ret .= join( "\n", map { "\t\t\t$_" } @attrs );
204         }
205         $ret .= ";";
206         $ret = "/* $ret */" if $commented_out;
207         if (@names_of_nn) {
208             $ret .= "\n#define PERL_ARGS_ASSERT_\U$plain_func\E\t\\\n\t"
209                 . join '; ', map "assert($_)", @names_of_nn;
210         }
211         $ret .= "\n#endif" if $binarycompat;
212         $ret .= @attrs ? "\n\n" : "\n";
213
214         print $pr $ret;
215     }
216
217     print $pr <<'EOF';
218 #ifdef PERL_CORE
219 #  include "pp_proto.h"
220 #endif
221 END_EXTERN_C
222 EOF
223
224     read_only_bottom_close_and_rename($pr);
225 }
226
227 warn "$unflagged_pointers pointer arguments to clean up\n" if $unflagged_pointers;
228
229 sub readvars {
230     my ($file, $pre) = @_;
231     local (*FILE, $_);
232     my %seen;
233     open(FILE, "< $file")
234         or die "embed.pl: Can't open $file: $!\n";
235     while (<FILE>) {
236         s/[ \t]*#.*//;          # Delete comments.
237         if (/PERLVARA?I?C?\($pre,\s*(\w+)/) {
238             warn "duplicate symbol $1 while processing $file line $.\n"
239                 if $seen{$1}++;
240         }
241     }
242     close(FILE);
243     return sort keys %seen;
244 }
245
246 my @intrp = readvars 'intrpvar.h','I';
247 my @globvar = readvars 'perlvars.h','G';
248
249 sub hide {
250     my ($from, $to, $indent) = @_;
251     $indent = '' unless defined $indent;
252     my $t = int(length("$indent$from") / 8);
253     "#${indent}define $from" . "\t" x ($t < 3 ? 3 - $t : 1) . "$to\n";
254 }
255
256 sub multon ($$$) {
257     my ($sym,$pre,$ptr) = @_;
258     hide("PL_$sym", "($ptr$pre$sym)");
259 }
260
261 my $em = open_print_header('embed.h');
262
263 print $em <<'END';
264 /* (Doing namespace management portably in C is really gross.) */
265
266 /* By defining PERL_NO_SHORT_NAMES (not done by default) the short forms
267  * (like warn instead of Perl_warn) for the API are not defined.
268  * Not defining the short forms is a good thing for cleaner embedding. */
269
270 #ifndef PERL_NO_SHORT_NAMES
271
272 /* Hide global symbols */
273
274 END
275
276 my @az = ('a'..'z');
277
278 sub embed_h {
279     my ($guard, $funcs) = @_;
280     print $em "$guard\n" if $guard;
281
282     my $lines;
283     foreach (@$funcs) {
284         if (@$_ == 1) {
285             my $cond = $_->[0];
286             # Indent the conditionals if we are wrapped in an #if/#endif pair.
287             $cond =~ s/#(.*)/#  $1/ if $guard;
288             $lines .= "$cond\n";
289             next;
290         }
291         my $ret = "";
292         my ($flags,$retval,$func,@args) = @$_;
293         unless ($flags =~ /[om]/) {
294             my $args = scalar @args;
295             if ($flags =~ /n/) {
296                 my $full_name = full_name($func, $flags);
297                 next if $full_name eq $func;    # Don't output a no-op.
298                 $ret = hide($func, $full_name);
299             }
300             elsif ($args and $args[$args-1] =~ /\.\.\./) {
301                 if ($flags =~ /p/) {
302                     # we're out of luck for varargs functions under CPP
303                     # So we can only do these macros for no implicit context:
304                     $ret = "#ifndef PERL_IMPLICIT_CONTEXT\n"
305                         . hide($func, full_name($func, $flags)) . "#endif\n";
306                 }
307             }
308             else {
309                 my $alist = join(",", @az[0..$args-1]);
310                 $ret = "#define $func($alist)";
311                 my $t = int(length($ret) / 8);
312                 $ret .=  "\t" x ($t < 4 ? 4 - $t : 1);
313                 $ret .= full_name($func, $flags) . "(aTHX";
314                 $ret .= "_ " if $alist;
315                 $ret .= $alist;
316                 if ($flags =~ /W/) {
317                     if ($alist) {
318                         $ret .= " _aDEPTH";
319                     } else {
320                         die "Can't use W without other args (currently)";
321                     }
322                 }
323                 $ret .= ")\n";
324             }
325             $ret = "#ifndef NO_MATHOMS\n$ret#endif\n" if $flags =~ /b/;
326         }
327         $lines .= $ret;
328     }
329     # Prune empty #if/#endif pairs.
330     while ($lines =~ s/#\s*if[^\n]+\n#\s*endif\n//) {
331     }
332     # Merge adjacent blocks.
333     while ($lines =~ s/(#ifndef PERL_IMPLICIT_CONTEXT
334 [^\n]+
335 )#endif
336 #ifndef PERL_IMPLICIT_CONTEXT
337 /$1/) {
338     }
339
340     print $em $lines;
341     print $em "#endif\n" if $guard;
342 }
343
344 embed_h('', $api);
345 embed_h('#if defined(PERL_CORE) || defined(PERL_EXT)', $ext);
346 embed_h('#ifdef PERL_CORE', $core);
347
348 print $em <<'END';
349
350 #endif  /* #ifndef PERL_NO_SHORT_NAMES */
351
352 /* Compatibility stubs.  Compile extensions with -DPERL_NOCOMPAT to
353    disable them.
354  */
355
356 #if !defined(PERL_CORE)
357 #  define sv_setptrobj(rv,ptr,name)     sv_setref_iv(rv,name,PTR2IV(ptr))
358 #  define sv_setptrref(rv,ptr)          sv_setref_iv(rv,NULL,PTR2IV(ptr))
359 #endif
360
361 #if !defined(PERL_CORE) && !defined(PERL_NOCOMPAT)
362
363 /* Compatibility for various misnamed functions.  All functions
364    in the API that begin with "perl_" (not "Perl_") take an explicit
365    interpreter context pointer.
366    The following are not like that, but since they had a "perl_"
367    prefix in previous versions, we provide compatibility macros.
368  */
369 #  define perl_atexit(a,b)              call_atexit(a,b)
370 END
371
372 foreach (@$embed) {
373     my ($flags, $retval, $func, @args) = @$_;
374     next unless $func;
375     next unless $flags =~ /O/;
376
377     my $alist = join ",", @az[0..$#args];
378     my $ret = "#  define perl_$func($alist)";
379     my $t = (length $ret) >> 3;
380     $ret .=  "\t" x ($t < 5 ? 5 - $t : 1);
381     print $em "$ret$func($alist)\n";
382 }
383
384 my @nocontext;
385 {
386     my (%has_va, %has_nocontext);
387     foreach (@$embed) {
388         next unless @$_ > 1;
389         ++$has_va{$_->[2]} if $_->[-1] =~ /\.\.\./;
390         ++$has_nocontext{$1} if $_->[2] =~ /(.*)_nocontext/;
391     }
392
393     @nocontext = sort grep {
394         $has_nocontext{$_}
395             && !/printf/ # Not clear to me why these are skipped but they are.
396     } keys %has_va;
397 }
398
399 print $em <<'END';
400
401 /* varargs functions can't be handled with CPP macros. :-(
402    This provides a set of compatibility functions that don't take
403    an extra argument but grab the context pointer using the macro
404    dTHX.
405  */
406 #if defined(PERL_IMPLICIT_CONTEXT) && !defined(PERL_NO_SHORT_NAMES)
407 END
408
409 foreach (@nocontext) {
410     print $em hide($_, "Perl_${_}_nocontext", "  ");
411 }
412
413 print $em <<'END';
414 #endif
415
416 #endif /* !defined(PERL_CORE) && !defined(PERL_NOCOMPAT) */
417
418 #if !defined(PERL_IMPLICIT_CONTEXT)
419 /* undefined symbols, point them back at the usual ones */
420 END
421
422 foreach (@nocontext) {
423     print $em hide("Perl_${_}_nocontext", "Perl_$_", "  ");
424 }
425
426 print $em <<'END';
427 #endif
428 END
429
430 read_only_bottom_close_and_rename($em);
431
432 $em = open_print_header('embedvar.h');
433
434 print $em <<'END';
435 /* (Doing namespace management portably in C is really gross.) */
436
437 /*
438    The following combinations of MULTIPLICITY and PERL_IMPLICIT_CONTEXT
439    are supported:
440      1) none
441      2) MULTIPLICITY    # supported for compatibility
442      3) MULTIPLICITY && PERL_IMPLICIT_CONTEXT
443
444    All other combinations of these flags are errors.
445
446    only #3 is supported directly, while #2 is a special
447    case of #3 (supported by redefining vTHX appropriately).
448 */
449
450 #if defined(MULTIPLICITY)
451 /* cases 2 and 3 above */
452
453 #  if defined(PERL_IMPLICIT_CONTEXT)
454 #    define vTHX        aTHX
455 #  else
456 #    define vTHX        PERL_GET_INTERP
457 #  endif
458
459 END
460
461 my $sym;
462
463 for $sym (@intrp) {
464     if ($sym eq 'sawampersand') {
465         print $em "#ifndef PL_sawampersand\n";
466     }
467     print $em multon($sym,'I','vTHX->');
468     if ($sym eq 'sawampersand') {
469         print $em "#endif\n";
470     }
471 }
472
473 print $em <<'END';
474
475 #endif  /* MULTIPLICITY */
476
477 #if defined(PERL_GLOBAL_STRUCT)
478
479 END
480
481 for $sym (@globvar) {
482     print $em "#ifdef OS2\n" if $sym eq 'sh_path';
483     print $em "#ifdef __VMS\n" if $sym eq 'perllib_sep';
484     print $em multon($sym,   'G','my_vars->');
485     print $em multon("G$sym",'', 'my_vars->');
486     print $em "#endif\n" if $sym eq 'sh_path';
487     print $em "#endif\n" if $sym eq 'perllib_sep';
488 }
489
490 print $em <<'END';
491
492 #endif /* PERL_GLOBAL_STRUCT */
493 END
494
495 read_only_bottom_close_and_rename($em);
496
497 my $capih = open_print_header('perlapi.h');
498
499 print $capih <<'EOT';
500 /* declare accessor functions for Perl variables */
501 #ifndef __perlapi_h__
502 #define __perlapi_h__
503
504 #if defined (MULTIPLICITY) && defined (PERL_GLOBAL_STRUCT)
505
506 START_EXTERN_C
507
508 #undef PERLVAR
509 #undef PERLVARA
510 #undef PERLVARI
511 #undef PERLVARIC
512 #define PERLVAR(p,v,t)  EXTERN_C t* Perl_##p##v##_ptr(pTHX);
513 #define PERLVARA(p,v,n,t)       typedef t PL_##v##_t[n];                \
514                         EXTERN_C PL_##v##_t* Perl_##p##v##_ptr(pTHX);
515 #define PERLVARI(p,v,t,i)       PERLVAR(p,v,t)
516 #define PERLVARIC(p,v,t,i) PERLVAR(p,v, const t)
517
518 #include "perlvars.h"
519
520 #undef PERLVAR
521 #undef PERLVARA
522 #undef PERLVARI
523 #undef PERLVARIC
524
525 END_EXTERN_C
526
527 #if defined(PERL_CORE)
528
529 /* accessor functions for Perl "global" variables */
530
531 /* these need to be mentioned here, or most linkers won't put them in
532    the perl executable */
533
534 #ifndef PERL_NO_FORCE_LINK
535
536 START_EXTERN_C
537
538 #ifndef DOINIT
539 EXTCONST void * const PL_force_link_funcs[];
540 #else
541 EXTCONST void * const PL_force_link_funcs[] = {
542 #undef PERLVAR
543 #undef PERLVARA
544 #undef PERLVARI
545 #undef PERLVARIC
546 #define PERLVAR(p,v,t)          (void*)Perl_##p##v##_ptr,
547 #define PERLVARA(p,v,n,t)       PERLVAR(p,v,t)
548 #define PERLVARI(p,v,t,i)       PERLVAR(p,v,t)
549 #define PERLVARIC(p,v,t,i)      PERLVAR(p,v,t)
550
551 /* In Tru64 (__DEC && __osf__) the cc option -std1 causes that one
552  * cannot cast between void pointers and function pointers without
553  * info level warnings.  The PL_force_link_funcs[] would cause a few
554  * hundred of those warnings.  In code one can circumnavigate this by using
555  * unions that overlay the different pointers, but in declarations one
556  * cannot use this trick.  Therefore we just disable the warning here
557  * for the duration of the PL_force_link_funcs[] declaration. */
558
559 #if defined(__DECC) && defined(__osf__)
560 #pragma message save
561 #pragma message disable (nonstandcast)
562 #endif
563
564 #include "perlvars.h"
565
566 #if defined(__DECC) && defined(__osf__)
567 #pragma message restore
568 #endif
569
570 #undef PERLVAR
571 #undef PERLVARA
572 #undef PERLVARI
573 #undef PERLVARIC
574 };
575 #endif  /* DOINIT */
576
577 END_EXTERN_C
578
579 #endif  /* PERL_NO_FORCE_LINK */
580
581 #else   /* !PERL_CORE */
582
583 EOT
584
585 foreach $sym (@globvar) {
586     print $capih
587         "#undef  PL_$sym\n" . hide("PL_$sym", "(*Perl_G${sym}_ptr(NULL))");
588 }
589
590 print $capih <<'EOT';
591
592 #endif /* !PERL_CORE */
593 #endif /* MULTIPLICITY && PERL_GLOBAL_STRUCT */
594
595 #endif /* __perlapi_h__ */
596 EOT
597
598 read_only_bottom_close_and_rename($capih);
599
600 my $capi = open_print_header('perlapi.c', <<'EOQ');
601  *
602  *
603  * Up to the threshold of the door there mounted a flight of twenty-seven
604  * broad stairs, hewn by some unknown art of the same black stone.  This
605  * was the only entrance to the tower; ...
606  *
607  *     [p.577 of _The Lord of the Rings_, III/x: "The Voice of Saruman"]
608  *
609  */
610 EOQ
611
612 print $capi <<'EOT';
613 #include "EXTERN.h"
614 #include "perl.h"
615 #include "perlapi.h"
616
617 #if defined (MULTIPLICITY) && defined (PERL_GLOBAL_STRUCT)
618
619 /* accessor functions for Perl "global" variables */
620 START_EXTERN_C
621
622 #undef PERLVARI
623 #define PERLVARI(p,v,t,i) PERLVAR(p,v,t)
624
625 #undef PERLVAR
626 #undef PERLVARA
627 #define PERLVAR(p,v,t)          t* Perl_##p##v##_ptr(pTHX)              \
628                         { dVAR; PERL_UNUSED_CONTEXT; return &(PL_##v); }
629 #define PERLVARA(p,v,n,t)       PL_##v##_t* Perl_##p##v##_ptr(pTHX)     \
630                         { dVAR; PERL_UNUSED_CONTEXT; return &(PL_##v); }
631 #undef PERLVARIC
632 #define PERLVARIC(p,v,t,i)      \
633                         const t* Perl_##p##v##_ptr(pTHX)                \
634                         { PERL_UNUSED_CONTEXT; return (const t *)&(PL_##v); }
635 #include "perlvars.h"
636
637 #undef PERLVAR
638 #undef PERLVARA
639 #undef PERLVARI
640 #undef PERLVARIC
641
642 END_EXTERN_C
643
644 #endif /* MULTIPLICITY && PERL_GLOBAL_STRUCT */
645 EOT
646
647 read_only_bottom_close_and_rename($capi);
648
649 # ex: set ts=8 sts=4 sw=4 noet: