This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Revert the ‘return’ part of 6edcbed6
[perl5.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPf_PARENS
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER OPpREPEAT_DOLIST
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          SVpad_TYPED
21          CVf_METHOD CVf_LVALUE
22          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
23          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED PMf_EXTENDED_MORE);
24 $VERSION = '1.30';
25 use strict;
26 use vars qw/$AUTOLOAD/;
27 use warnings ();
28 require feature;
29
30 BEGIN {
31     # List version-specific constants here.
32     # Easiest way to keep this code portable between version looks to
33     # be to fake up a dummy constant that will never actually be true.
34     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
35                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
36                 RXf_PMf_CHARSET RXf_PMf_KEEPCOPY
37                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
38                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES
39                 OPpLVREF_TYPE OPpLVREF_SV OPpLVREF_AV OPpLVREF_HV
40                 OPpLVREF_CV OPpLVREF_ELEM SVpad_STATE)) {
41         eval { import B $_ };
42         no strict 'refs';
43         *{$_} = sub () {0} unless *{$_}{CODE};
44     }
45 }
46
47 # Changes between 0.50 and 0.51:
48 # - fixed nulled leave with live enter in sort { }
49 # - fixed reference constants (\"str")
50 # - handle empty programs gracefully
51 # - handle infinite loops (for (;;) {}, while (1) {})
52 # - differentiate between 'for my $x ...' and 'my $x; for $x ...'
53 # - various minor cleanups
54 # - moved globals into an object
55 # - added '-u', like B::C
56 # - package declarations using cop_stash
57 # - subs, formats and code sorted by cop_seq
58 # Changes between 0.51 and 0.52:
59 # - added pp_threadsv (special variables under USE_5005THREADS)
60 # - added documentation
61 # Changes between 0.52 and 0.53:
62 # - many changes adding precedence contexts and associativity
63 # - added '-p' and '-s' output style options
64 # - various other minor fixes
65 # Changes between 0.53 and 0.54:
66 # - added support for new 'for (1..100)' optimization,
67 #   thanks to Gisle Aas
68 # Changes between 0.54 and 0.55:
69 # - added support for new qr// construct
70 # - added support for new pp_regcreset OP
71 # Changes between 0.55 and 0.56:
72 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
73 # - fixed $# on non-lexicals broken in last big rewrite
74 # - added temporary fix for change in opcode of OP_STRINGIFY
75 # - fixed problem in 0.54's for() patch in 'for (@ary)'
76 # - fixed precedence in conditional of ?:
77 # - tweaked list paren elimination in 'my($x) = @_'
78 # - made continue-block detection trickier wrt. null ops
79 # - fixed various prototype problems in pp_entersub
80 # - added support for sub prototypes that never get GVs
81 # - added unquoting for special filehandle first arg in truncate
82 # - print doubled rv2gv (a bug) as '*{*GV}' instead of illegal '**GV'
83 # - added semicolons at the ends of blocks
84 # - added -l '#line' declaration option -- fixes cmd/subval.t 27,28
85 # Changes between 0.56 and 0.561:
86 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
87 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
88 # Changes between 0.561 and 0.57:
89 # - stylistic changes to symbolic constant stuff
90 # - handled scope in s///e replacement code
91 # - added unquote option for expanding "" into concats, etc.
92 # - split method and proto parts of pp_entersub into separate functions
93 # - various minor cleanups
94 # Changes after 0.57:
95 # - added parens in \&foo (patch by Albert Dvornik)
96 # Changes between 0.57 and 0.58:
97 # - fixed '0' statements that weren't being printed
98 # - added methods for use from other programs
99 #   (based on patches from James Duncan and Hugo van der Sanden)
100 # - added -si and -sT to control indenting (also based on a patch from Hugo)
101 # - added -sv to print something else instead of '???'
102 # - preliminary version of utf8 tr/// handling
103 # Changes after 0.58:
104 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
105 # - added support for Hugo's new OP_SETSTATE (like nextstate)
106 # Changes between 0.58 and 0.59
107 # - added support for Chip's OP_METHOD_NAMED
108 # - added support for Ilya's OPpTARGET_MY optimization
109 # - elided arrows before '()' subscripts when possible
110 # Changes between 0.59 and 0.60
111 # - support for method attributes was added
112 # - some warnings fixed
113 # - separate recognition of constant subs
114 # - rewrote continue block handling, now recognizing for loops
115 # - added more control of expanding control structures
116 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
117 # - many bug-fixes
118 # - support for pragmas and 'use'
119 # - support for the little-used $[ variable
120 # - support for __DATA__ sections
121 # - UTF8 support
122 # - BEGIN, CHECK, INIT and END blocks
123 # - scoping of subroutine declarations fixed
124 # - compile-time output from the input program can be suppressed, so that the
125 #   output is just the deparsed code. (a change to O.pm in fact)
126 # - our() declarations
127 # - *all* the known bugs are now listed in the BUGS section
128 # - comprehensive test mechanism (TEST -deparse)
129 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
130 # - bug-fixes
131 # - new switch -P
132 # - support for command-line switches (-l, -0, etc.)
133 # Changes between 0.63 and 0.64
134 # - support for //, CHECK blocks, and assertions
135 # - improved handling of foreach loops and lexicals
136 # - option to use Data::Dumper for constants
137 # - more bug fixes
138 # - discovered lots more bugs not yet fixed
139 #
140 # ...
141 #
142 # Changes between 0.72 and 0.73
143 # - support new switch constructs
144
145 # Todo:
146 #  (See also BUGS section at the end of this file)
147 #
148 # - finish tr/// changes
149 # - add option for even more parens (generalize \&foo change)
150 # - left/right context
151 # - copy comments (look at real text with $^P?)
152 # - avoid semis in one-statement blocks
153 # - associativity of &&=, ||=, ?:
154 # - ',' => '=>' (auto-unquote?)
155 # - break long lines ("\r" as discretionary break?)
156 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
157 # - more style options: brace style, hex vs. octal, quotes, ...
158 # - print big ints as hex/octal instead of decimal (heuristic?)
159 # - handle 'my $x if 0'?
160 # - version using op_next instead of op_first/sibling?
161 # - avoid string copies (pass arrays, one big join?)
162 # - here-docs?
163
164 # Current test.deparse failures
165 # comp/hints 6 - location of BEGIN blocks wrt. block openings
166 # run/switchI 1 - missing -I switches entirely
167 #    perl -Ifoo -e 'print @INC'
168 # op/caller 2 - warning mask propagates backwards before warnings::register
169 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
170 # op/getpid 2 - can't assign to shared my() declaration (threads only)
171 #    'my $x : shared = 5'
172 # op/override 7 - parens on overridden require change v-string interpretation
173 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
174 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
175 # op/pat 774 - losing Unicode-ness of Latin1-only strings
176 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
177 # op/recurse 12 - missing parens on recursive call makes it look like method
178 #    'sub f { f($x) }'
179 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
180 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
181 # op/tiehandle compile - "use strict" deparsed in the wrong place
182 # uni/tr_ several
183 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
184 # ext/Data/Dumper/t/dumper compile
185 # ext/DB_file/several
186 # ext/Encode/several
187 # ext/Ernno/Errno warnings
188 # ext/IO/lib/IO/t/io_sel 23
189 # ext/PerlIO/t/encoding compile
190 # ext/POSIX/t/posix 6
191 # ext/Socket/Socket 8
192 # ext/Storable/t/croak compile
193 # lib/Attribute/Handlers/t/multi compile
194 # lib/bignum/ several
195 # lib/charnames 35
196 # lib/constant 32
197 # lib/English 40
198 # lib/ExtUtils/t/bytes 4
199 # lib/File/DosGlob compile
200 # lib/Filter/Simple/t/data 1
201 # lib/Math/BigInt/t/constant 1
202 # lib/Net/t/config Deparse-warning
203 # lib/overload compile
204 # lib/Switch/ several
205 # lib/Symbol 4
206 # lib/Test/Simple several
207 # lib/Term/Complete
208 # lib/Tie/File/t/29_downcopy 5
209 # lib/vars 22
210
211 # Object fields (were globals):
212 #
213 # avoid_local:
214 # (local($a), local($b)) and local($a, $b) have the same internal
215 # representation but the short form looks better. We notice we can
216 # use a large-scale local when checking the list, but need to prevent
217 # individual locals too. This hash holds the addresses of OPs that
218 # have already had their local-ness accounted for. The same thing
219 # is done with my().
220 #
221 # curcv:
222 # CV for current sub (or main program) being deparsed
223 #
224 # curcvlex:
225 # Cached hash of lexical variables for curcv: keys are
226 # names prefixed with "m" or "o" (representing my/our), and
227 # each value is an array with two elements indicating the cop_seq
228 # of scopes in which a var of that name is valid and a third ele-
229 # ment referencing the pad name.
230 #
231 # curcop:
232 # COP for statement being deparsed
233 #
234 # curstash:
235 # name of the current package for deparsed code
236 #
237 # subs_todo:
238 # array of [cop_seq, CV, is_format?] for subs and formats we still
239 # want to deparse
240 #
241 # protos_todo:
242 # as above, but [name, prototype] for subs that never got a GV
243 #
244 # subs_done, forms_done:
245 # keys are addresses of GVs for subs and formats we've already
246 # deparsed (or at least put into subs_todo)
247 #
248 # subs_declared
249 # keys are names of subs for which we've printed declarations.
250 # That means we can omit parentheses from the arguments. It also means we
251 # need to put CORE:: on core functions of the same name.
252 #
253 # subs_deparsed
254 # Keeps track of fully qualified names of all deparsed subs.
255 #
256 # in_subst_repl
257 # True when deparsing the replacement part of a substitution.
258 #
259 # in_refgen
260 # True when deparsing the argument to \.
261 #
262 # parens: -p
263 # linenums: -l
264 # unquote: -q
265 # cuddle: ' ' or '\n', depending on -sC
266 # indent_size: -si
267 # use_tabs: -sT
268 # ex_const: -sv
269
270 # A little explanation of how precedence contexts and associativity
271 # work:
272 #
273 # deparse() calls each per-op subroutine with an argument $cx (short
274 # for context, but not the same as the cx* in the perl core), which is
275 # a number describing the op's parents in terms of precedence, whether
276 # they're inside an expression or at statement level, etc.  (see
277 # chart below). When ops with children call deparse on them, they pass
278 # along their precedence. Fractional values are used to implement
279 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
280 # parentheses hacks. The major disadvantage of this scheme is that
281 # it doesn't know about right sides and left sides, so say if you
282 # assign a listop to a variable, it can't tell it's allowed to leave
283 # the parens off the listop.
284
285 # Precedences:
286 # 26             [TODO] inside interpolation context ("")
287 # 25 left        terms and list operators (leftward)
288 # 24 left        ->
289 # 23 nonassoc    ++ --
290 # 22 right       **
291 # 21 right       ! ~ \ and unary + and -
292 # 20 left        =~ !~
293 # 19 left        * / % x
294 # 18 left        + - .
295 # 17 left        << >>
296 # 16 nonassoc    named unary operators
297 # 15 nonassoc    < > <= >= lt gt le ge
298 # 14 nonassoc    == != <=> eq ne cmp
299 # 13 left        &
300 # 12 left        | ^
301 # 11 left        &&
302 # 10 left        ||
303 #  9 nonassoc    ..  ...
304 #  8 right       ?:
305 #  7 right       = += -= *= etc.
306 #  6 left        , =>
307 #  5 nonassoc    list operators (rightward)
308 #  4 right       not
309 #  3 left        and
310 #  2 left        or xor
311 #  1             statement modifiers
312 #  0.5           statements, but still print scopes as do { ... }
313 #  0             statement level
314 # -1             format body
315
316 # Nonprinting characters with special meaning:
317 # \cS - steal parens (see maybe_parens_unop)
318 # \n - newline and indent
319 # \t - increase indent
320 # \b - decrease indent ('outdent')
321 # \f - flush left (no indent)
322 # \cK - kill following semicolon, if any
323
324
325
326 BEGIN { for (qw[ const stringify rv2sv list glob pushmark null aelem
327                  custom ]) {
328     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
329 }}
330
331 # _pessimise_walk(): recursively walk the optree of a sub,
332 # possibly undoing optimisations along the way.
333
334 sub _pessimise_walk {
335     my ($self, $startop) = @_;
336
337     return unless $$startop;
338     my ($op, $prevop);
339     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
340         my $ppname = $op->name;
341
342         # pessimisations start here
343
344         if ($ppname eq "padrange") {
345             # remove PADRANGE:
346             # the original optimisation either (1) changed this:
347             #    pushmark -> (various pad and list and null ops) -> the_rest
348             # or (2), for the = @_ case, changed this:
349             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
350             # into this:
351             #    padrange ----------------------------------------> the_rest
352             # so we just need to convert the padrange back into a
353             # pushmark, and in case (1), set its op_next to op_sibling,
354             # which is the head of the original chain of optimised-away
355             # pad ops, or for (2), set it to sibling->first, which is
356             # the original gv[_].
357
358             $B::overlay->{$$op} = {
359                     type => OP_PUSHMARK,
360                     name => 'pushmark',
361                     private => ($op->private & OPpLVAL_INTRO),
362             };
363         }
364
365         # pessimisations end here
366
367         if (class($op) eq 'PMOP'
368             && ref($op->pmreplroot)
369             && ${$op->pmreplroot}
370             && $op->pmreplroot->isa( 'B::OP' ))
371         {
372             $self-> _pessimise_walk($op->pmreplroot);
373         }
374
375         if ($op->flags & OPf_KIDS) {
376             $self-> _pessimise_walk($op->first);
377         }
378
379     }
380 }
381
382
383 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
384 # possibly undoing optimisations along the way.
385
386 sub _pessimise_walk_exe {
387     my ($self, $startop, $visited) = @_;
388
389     return unless $$startop;
390     return if $visited->{$$startop};
391     my ($op, $prevop);
392     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
393         last if $visited->{$$op};
394         $visited->{$$op} = 1;
395         my $ppname = $op->name;
396         if ($ppname =~
397             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
398             # entertry is also a logop, but its op_other invariably points
399             # into the same chain as the main execution path, so we skip it
400         ) {
401             $self->_pessimise_walk_exe($op->other, $visited);
402         }
403         elsif ($ppname eq "subst") {
404             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
405         }
406         elsif ($ppname =~ /^(enter(loop|iter))$/) {
407             # redoop and nextop will already be covered by the main block
408             # of the loop
409             $self->_pessimise_walk_exe($op->lastop, $visited);
410         }
411
412         # pessimisations start here
413     }
414 }
415
416 # Go through an optree and "remove" some optimisations by using an
417 # overlay to selectively modify or un-null some ops. Deparsing in the
418 # absence of those optimisations is then easier.
419 #
420 # Note that older optimisations are not removed, as Deparse was already
421 # written to recognise them before the pessimise/overlay system was added.
422
423 sub pessimise {
424     my ($self, $root, $start) = @_;
425
426     # walk tree in root-to-branch order
427     $self->_pessimise_walk($root);
428
429     my %visited;
430     # walk tree in execution order
431     $self->_pessimise_walk_exe($start, \%visited);
432 }
433
434
435 sub null {
436     my $op = shift;
437     return class($op) eq "NULL";
438 }
439
440 sub todo {
441     my $self = shift;
442     my($cv, $is_form) = @_;
443     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
444     my $seq;
445     if ($cv->OUTSIDE_SEQ) {
446         $seq = $cv->OUTSIDE_SEQ;
447     } elsif (!null($cv->START) and is_state($cv->START)) {
448         $seq = $cv->START->cop_seq;
449     } else {
450         $seq = 0;
451     }
452     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
453     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
454         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
455     }
456 }
457
458 sub next_todo {
459     my $self = shift;
460     my $ent = shift @{$self->{'subs_todo'}};
461     my $cv = $ent->[1];
462     my $gv = $cv->GV;
463     my $name = $self->gv_name($gv);
464     if ($ent->[2]) {
465         return $self->keyword("format") . " $name =\n"
466             . $self->deparse_format($ent->[1]). "\n";
467     } else {
468         $self->{'subs_declared'}{$name} = 1;
469         if ($name eq "BEGIN") {
470             my $use_dec = $self->begin_is_use($cv);
471             if (defined ($use_dec) and $self->{'expand'} < 5) {
472                 return () if 0 == length($use_dec);
473                 $use_dec =~ s/^(use|no)\b/$self->keyword($1)/e;
474                 return $use_dec;
475             }
476         }
477         my $l = '';
478         if ($self->{'linenums'}) {
479             my $line = $gv->LINE;
480             my $file = $gv->FILE;
481             $l = "\n\f#line $line \"$file\"\n";
482         }
483         my $p = '';
484         if (class($cv->STASH) ne "SPECIAL") {
485             my $stash = $cv->STASH->NAME;
486             if ($stash ne $self->{'curstash'}) {
487                 $p = $self->keyword("package") . " $stash;\n";
488                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
489                 $self->{'curstash'} = $stash;
490             }
491             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
492         }
493         return "${p}${l}" . $self->keyword("sub") . " $name "
494               . $self->deparse_sub($cv);
495     }
496 }
497
498 # Return a "use" declaration for this BEGIN block, if appropriate
499 sub begin_is_use {
500     my ($self, $cv) = @_;
501     my $root = $cv->ROOT;
502     local @$self{qw'curcv curcvlex'} = ($cv);
503     local $B::overlay = {};
504     $self->pessimise($root, $cv->START);
505 #require B::Debug;
506 #B::walkoptree($cv->ROOT, "debug");
507     my $lineseq = $root->first;
508     return if $lineseq->name ne "lineseq";
509
510     my $req_op = $lineseq->first->sibling;
511     return if $req_op->name ne "require";
512
513     my $module;
514     if ($req_op->first->private & OPpCONST_BARE) {
515         # Actually it should always be a bareword
516         $module = $self->const_sv($req_op->first)->PV;
517         $module =~ s[/][::]g;
518         $module =~ s/.pm$//;
519     }
520     else {
521         $module = $self->const($self->const_sv($req_op->first), 6);
522     }
523
524     my $version;
525     my $version_op = $req_op->sibling;
526     return if class($version_op) eq "NULL";
527     if ($version_op->name eq "lineseq") {
528         # We have a version parameter; skip nextstate & pushmark
529         my $constop = $version_op->first->next->next;
530
531         return unless $self->const_sv($constop)->PV eq $module;
532         $constop = $constop->sibling;
533         $version = $self->const_sv($constop);
534         if (class($version) eq "IV") {
535             $version = $version->int_value;
536         } elsif (class($version) eq "NV") {
537             $version = $version->NV;
538         } elsif (class($version) ne "PVMG") {
539             # Includes PVIV and PVNV
540             $version = $version->PV;
541         } else {
542             # version specified as a v-string
543             $version = 'v'.join '.', map ord, split //, $version->PV;
544         }
545         $constop = $constop->sibling;
546         return if $constop->name ne "method_named";
547         return if $self->meth_sv($constop)->PV ne "VERSION";
548     }
549
550     $lineseq = $version_op->sibling;
551     return if $lineseq->name ne "lineseq";
552     my $entersub = $lineseq->first->sibling;
553     if ($entersub->name eq "stub") {
554         return "use $module $version ();\n" if defined $version;
555         return "use $module ();\n";
556     }
557     return if $entersub->name ne "entersub";
558
559     # See if there are import arguments
560     my $args = '';
561
562     my $svop = $entersub->first->sibling; # Skip over pushmark
563     return unless $self->const_sv($svop)->PV eq $module;
564
565     # Pull out the arguments
566     for ($svop=$svop->sibling; $svop->name ne "method_named";
567                 $svop = $svop->sibling) {
568         $args .= ", " if length($args);
569         $args .= $self->deparse($svop, 6);
570     }
571
572     my $use = 'use';
573     my $method_named = $svop;
574     return if $method_named->name ne "method_named";
575     my $method_name = $self->meth_sv($method_named)->PV;
576
577     if ($method_name eq "unimport") {
578         $use = 'no';
579     }
580
581     # Certain pragmas are dealt with using hint bits,
582     # so we ignore them here
583     if ($module eq 'strict' || $module eq 'integer'
584         || $module eq 'bytes' || $module eq 'warnings'
585         || $module eq 'feature') {
586         return "";
587     }
588
589     if (defined $version && length $args) {
590         return "$use $module $version ($args);\n";
591     } elsif (defined $version) {
592         return "$use $module $version;\n";
593     } elsif (length $args) {
594         return "$use $module ($args);\n";
595     } else {
596         return "$use $module;\n";
597     }
598 }
599
600 sub stash_subs {
601     my ($self, $pack, $seen) = @_;
602     my (@ret, $stash);
603     if (!defined $pack) {
604         $pack = '';
605         $stash = \%::;
606     }
607     else {
608         $pack =~ s/(::)?$/::/;
609         no strict 'refs';
610         $stash = \%{"main::$pack"};
611     }
612     return
613         if ($seen ||= {})->{
614             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
615            }++;
616     my %stash = svref_2object($stash)->ARRAY;
617     while (my ($key, $val) = each %stash) {
618         my $class = class($val);
619         if ($class eq "PV") {
620             # Just a prototype. As an ugly but fairly effective way
621             # to find out if it belongs here is to see if the AUTOLOAD
622             # (if any) for the stash was defined in one of our files.
623             my $A = $stash{"AUTOLOAD"};
624             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
625                 && class($A->CV) eq "CV") {
626                 my $AF = $A->FILE;
627                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
628             }
629             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
630         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
631             # Just a name. As above.
632             # But skip proxy constant subroutines, as some form of perl-space
633             # visible code must have created them, be it a use statement, or
634             # some direct symbol-table manipulation code that we will Deparse
635             my $A = $stash{"AUTOLOAD"};
636             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
637                 && class($A->CV) eq "CV") {
638                 my $AF = $A->FILE;
639                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
640             }
641             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
642         } elsif ($class eq "IV") {
643             # A reference.  Dump this if it is a reference to a CV.
644             if (class(my $cv = $val->RV) eq "CV") {
645                 $self->todo($cv, 0);
646             }
647         } elsif ($class eq "GV") {
648             if (class(my $cv = $val->CV) ne "SPECIAL") {
649                 next if $self->{'subs_done'}{$$val}++;
650                 next if $$val != ${$cv->GV};   # Ignore imposters
651                 $self->todo($cv, 0);
652             }
653             if (class(my $cv = $val->FORM) ne "SPECIAL") {
654                 next if $self->{'forms_done'}{$$val}++;
655                 next if $$val != ${$cv->GV};   # Ignore imposters
656                 $self->todo($cv, 1);
657             }
658             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
659                 $self->stash_subs($pack . $key, $seen);
660             }
661         }
662     }
663 }
664
665 sub print_protos {
666     my $self = shift;
667     my $ar;
668     my @ret;
669     foreach $ar (@{$self->{'protos_todo'}}) {
670         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
671         push @ret, "sub " . $ar->[0] .  "$proto;\n";
672     }
673     delete $self->{'protos_todo'};
674     return @ret;
675 }
676
677 sub style_opts {
678     my $self = shift;
679     my $opts = shift;
680     my $opt;
681     while (length($opt = substr($opts, 0, 1))) {
682         if ($opt eq "C") {
683             $self->{'cuddle'} = " ";
684             $opts = substr($opts, 1);
685         } elsif ($opt eq "i") {
686             $opts =~ s/^i(\d+)//;
687             $self->{'indent_size'} = $1;
688         } elsif ($opt eq "T") {
689             $self->{'use_tabs'} = 1;
690             $opts = substr($opts, 1);
691         } elsif ($opt eq "v") {
692             $opts =~ s/^v([^.]*)(.|$)//;
693             $self->{'ex_const'} = $1;
694         }
695     }
696 }
697
698 sub new {
699     my $class = shift;
700     my $self = bless {}, $class;
701     $self->{'cuddle'} = "\n";
702     $self->{'curcop'} = undef;
703     $self->{'curstash'} = "main";
704     $self->{'ex_const'} = "'???'";
705     $self->{'expand'} = 0;
706     $self->{'files'} = {};
707     $self->{'indent_size'} = 4;
708     $self->{'linenums'} = 0;
709     $self->{'parens'} = 0;
710     $self->{'subs_todo'} = [];
711     $self->{'unquote'} = 0;
712     $self->{'use_dumper'} = 0;
713     $self->{'use_tabs'} = 0;
714
715     $self->{'ambient_arybase'} = 0;
716     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
717     $self->{'ambient_hints'} = 0;
718     $self->{'ambient_hinthash'} = undef;
719     $self->init();
720
721     while (my $arg = shift @_) {
722         if ($arg eq "-d") {
723             $self->{'use_dumper'} = 1;
724             require Data::Dumper;
725         } elsif ($arg =~ /^-f(.*)/) {
726             $self->{'files'}{$1} = 1;
727         } elsif ($arg eq "-l") {
728             $self->{'linenums'} = 1;
729         } elsif ($arg eq "-p") {
730             $self->{'parens'} = 1;
731         } elsif ($arg eq "-P") {
732             $self->{'noproto'} = 1;
733         } elsif ($arg eq "-q") {
734             $self->{'unquote'} = 1;
735         } elsif (substr($arg, 0, 2) eq "-s") {
736             $self->style_opts(substr $arg, 2);
737         } elsif ($arg =~ /^-x(\d)$/) {
738             $self->{'expand'} = $1;
739         }
740     }
741     return $self;
742 }
743
744 {
745     # Mask out the bits that L<warnings::register> uses
746     my $WARN_MASK;
747     BEGIN {
748         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
749     }
750     sub WARN_MASK () {
751         return $WARN_MASK;
752     }
753 }
754
755 # Initialise the contextual information, either from
756 # defaults provided with the ambient_pragmas method,
757 # or from perl's own defaults otherwise.
758 sub init {
759     my $self = shift;
760
761     $self->{'arybase'}  = $self->{'ambient_arybase'};
762     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
763                                 ? $self->{'ambient_warnings'} & WARN_MASK
764                                 : undef;
765     $self->{'hints'}    = $self->{'ambient_hints'};
766     $self->{'hints'} &= 0xFF if $] < 5.009;
767     $self->{'hinthash'} = $self->{'ambient_hinthash'};
768
769     # also a convenient place to clear out subs_declared
770     delete $self->{'subs_declared'};
771 }
772
773 sub compile {
774     my(@args) = @_;
775     return sub {
776         my $self = B::Deparse->new(@args);
777         # First deparse command-line args
778         if (defined $^I) { # deparse -i
779             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
780         }
781         if ($^W) { # deparse -w
782             print qq(BEGIN { \$^W = $^W; }\n);
783         }
784         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
785             my $fs = perlstring($/) || 'undef';
786             my $bs = perlstring($O::savebackslash) || 'undef';
787             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
788         }
789         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
790         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
791             ? B::unitcheck_av->ARRAY
792             : ();
793         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
794         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
795         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
796         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
797             $self->todo($block, 0);
798         }
799         $self->stash_subs();
800         local($SIG{"__DIE__"}) =
801           sub {
802               if ($self->{'curcop'}) {
803                   my $cop = $self->{'curcop'};
804                   my($line, $file) = ($cop->line, $cop->file);
805                   print STDERR "While deparsing $file near line $line,\n";
806               }
807             };
808         $self->{'curcv'} = main_cv;
809         $self->{'curcvlex'} = undef;
810         print $self->print_protos;
811         @{$self->{'subs_todo'}} =
812           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
813         my $root = main_root;
814         local $B::overlay = {};
815         unless (null $root) {
816             $self->pessimise($root, main_start);
817             print $self->indent($self->deparse_root($root)), "\n";
818         }
819         my @text;
820         while (scalar(@{$self->{'subs_todo'}})) {
821             push @text, $self->next_todo;
822         }
823         print $self->indent(join("", @text)), "\n" if @text;
824
825         # Print __DATA__ section, if necessary
826         no strict 'refs';
827         my $laststash = defined $self->{'curcop'}
828             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
829         if (defined *{$laststash."::DATA"}{IO}) {
830             print $self->keyword("package") . " $laststash;\n"
831                 unless $laststash eq $self->{'curstash'};
832             print $self->keyword("__DATA__") . "\n";
833             print readline(*{$laststash."::DATA"});
834         }
835     }
836 }
837
838 sub coderef2text {
839     my $self = shift;
840     my $sub = shift;
841     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
842
843     $self->init();
844     return $self->indent($self->deparse_sub(svref_2object($sub)));
845 }
846
847 my %strict_bits = do {
848     local $^H;
849     map +($_ => strict::bits($_)), qw/refs subs vars/
850 };
851
852 sub ambient_pragmas {
853     my $self = shift;
854     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
855
856     while (@_ > 1) {
857         my $name = shift();
858         my $val  = shift();
859
860         if ($name eq 'strict') {
861             require strict;
862
863             if ($val eq 'none') {
864                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
865                 next();
866             }
867
868             my @names;
869             if ($val eq "all") {
870                 @names = qw/refs subs vars/;
871             }
872             elsif (ref $val) {
873                 @names = @$val;
874             }
875             else {
876                 @names = split' ', $val;
877             }
878             $hint_bits |= $strict_bits{$_} for @names;
879         }
880
881         elsif ($name eq '$[') {
882             if (OPpCONST_ARYBASE) {
883                 $arybase = $val;
884             } else {
885                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
886             }
887         }
888
889         elsif ($name eq 'integer'
890             || $name eq 'bytes'
891             || $name eq 'utf8') {
892             require "$name.pm";
893             if ($val) {
894                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
895             }
896             else {
897                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
898             }
899         }
900
901         elsif ($name eq 're') {
902             require re;
903             if ($val eq 'none') {
904                 $hint_bits &= ~re::bits(qw/taint eval/);
905                 next();
906             }
907
908             my @names;
909             if ($val eq 'all') {
910                 @names = qw/taint eval/;
911             }
912             elsif (ref $val) {
913                 @names = @$val;
914             }
915             else {
916                 @names = split' ',$val;
917             }
918             $hint_bits |= re::bits(@names);
919         }
920
921         elsif ($name eq 'warnings') {
922             if ($val eq 'none') {
923                 $warning_bits = $warnings::NONE;
924                 next();
925             }
926
927             my @names;
928             if (ref $val) {
929                 @names = @$val;
930             }
931             else {
932                 @names = split/\s+/, $val;
933             }
934
935             $warning_bits = $warnings::NONE if !defined ($warning_bits);
936             $warning_bits |= warnings::bits(@names);
937         }
938
939         elsif ($name eq 'warning_bits') {
940             $warning_bits = $val;
941         }
942
943         elsif ($name eq 'hint_bits') {
944             $hint_bits = $val;
945         }
946
947         elsif ($name eq '%^H') {
948             $hinthash = $val;
949         }
950
951         else {
952             croak "Unknown pragma type: $name";
953         }
954     }
955     if (@_) {
956         croak "The ambient_pragmas method expects an even number of args";
957     }
958
959     $self->{'ambient_arybase'} = $arybase;
960     $self->{'ambient_warnings'} = $warning_bits;
961     $self->{'ambient_hints'} = $hint_bits;
962     $self->{'ambient_hinthash'} = $hinthash;
963 }
964
965 # This method is the inner loop, so try to keep it simple
966 sub deparse {
967     my $self = shift;
968     my($op, $cx) = @_;
969
970     Carp::confess("Null op in deparse") if !defined($op)
971                                         || class($op) eq "NULL";
972     my $meth = "pp_" . $op->name;
973     return $self->$meth($op, $cx);
974 }
975
976 sub indent {
977     my $self = shift;
978     my $txt = shift;
979     my @lines = split(/\n/, $txt);
980     my $leader = "";
981     my $level = 0;
982     my $line;
983     for $line (@lines) {
984         my $cmd = substr($line, 0, 1);
985         if ($cmd eq "\t" or $cmd eq "\b") {
986             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
987             if ($self->{'use_tabs'}) {
988                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
989             } else {
990                 $leader = " " x $level;
991             }
992             $line = substr($line, 1);
993         }
994         if (index($line, "\f") > 0) {
995                 $line =~ s/\f/\n/;
996         }
997         if (substr($line, 0, 1) eq "\f") {
998             $line = substr($line, 1); # no indent
999         } else {
1000             $line = $leader . $line;
1001         }
1002         $line =~ s/\cK;?//g;
1003     }
1004     return join("\n", @lines);
1005 }
1006
1007 sub deparse_sub {
1008     my $self = shift;
1009     my $cv = shift;
1010     my $proto = "";
1011 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
1012 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
1013     local $self->{'curcop'} = $self->{'curcop'};
1014     if ($cv->FLAGS & SVf_POK) {
1015         $proto = "(". $cv->PV . ") ";
1016     }
1017     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
1018         $proto .= ": ";
1019         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
1020         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
1021         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
1022     }
1023
1024     local($self->{'curcv'}) = $cv;
1025     local($self->{'curcvlex'});
1026     local(@$self{qw'curstash warnings hints hinthash'})
1027                 = @$self{qw'curstash warnings hints hinthash'};
1028     my $body;
1029     my $root = $cv->ROOT;
1030     local $B::overlay = {};
1031     if (not null $root) {
1032         $self->pessimise($root, $cv->START);
1033         my $lineseq = $root->first;
1034         if ($lineseq->name eq "lineseq") {
1035             my @ops;
1036             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
1037                 push @ops, $o;
1038             }
1039             $body = $self->lineseq(undef, 0, @ops).";";
1040             my $scope_en = $self->find_scope_en($lineseq);
1041             if (defined $scope_en) {
1042                 my $subs = join"", $self->seq_subs($scope_en);
1043                 $body .= ";\n$subs" if length($subs);
1044             }
1045         }
1046         else {
1047             $body = $self->deparse($root->first, 0);
1048         }
1049     }
1050     else {
1051         my $sv = $cv->const_sv;
1052         if ($$sv) {
1053             # uh-oh. inlinable sub... format it differently
1054             return $proto . "{ " . $self->const($sv, 0) . " }\n";
1055         } else { # XSUB? (or just a declaration)
1056             return "$proto;\n";
1057         }
1058     }
1059     return $proto ."{\n\t$body\n\b}" ."\n";
1060 }
1061
1062 sub deparse_format {
1063     my $self = shift;
1064     my $form = shift;
1065     my @text;
1066     local($self->{'curcv'}) = $form;
1067     local($self->{'curcvlex'});
1068     local($self->{'in_format'}) = 1;
1069     local(@$self{qw'curstash warnings hints hinthash'})
1070                 = @$self{qw'curstash warnings hints hinthash'};
1071     my $op = $form->ROOT;
1072     local $B::overlay = {};
1073     $self->pessimise($op, $form->START);
1074     my $kid;
1075     return "\f." if $op->first->name eq 'stub'
1076                 || $op->first->name eq 'nextstate';
1077     $op = $op->first->first; # skip leavewrite, lineseq
1078     while (not null $op) {
1079         $op = $op->sibling; # skip nextstate
1080         my @exprs;
1081         $kid = $op->first->sibling; # skip pushmark
1082         push @text, "\f".$self->const_sv($kid)->PV;
1083         $kid = $kid->sibling;
1084         for (; not null $kid; $kid = $kid->sibling) {
1085             push @exprs, $self->deparse($kid, -1);
1086             $exprs[-1] =~ s/;\z//;
1087         }
1088         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1089         $op = $op->sibling;
1090     }
1091     return join("", @text) . "\f.";
1092 }
1093
1094 sub is_scope {
1095     my $op = shift;
1096     return $op->name eq "leave" || $op->name eq "scope"
1097       || $op->name eq "lineseq"
1098         || ($op->name eq "null" && class($op) eq "UNOP"
1099             && (is_scope($op->first) || $op->first->name eq "enter"));
1100 }
1101
1102 sub is_state {
1103     my $name = $_[0]->name;
1104     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1105 }
1106
1107 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1108     my $op = shift;
1109     return (!null($op) and null($op->sibling)
1110             and $op->name eq "null" and class($op) eq "UNOP"
1111             and (($op->first->name =~ /^(and|or)$/
1112                   and $op->first->first->sibling->name eq "lineseq")
1113                  or ($op->first->name eq "lineseq"
1114                      and not null $op->first->first->sibling
1115                      and $op->first->first->sibling->name eq "unstack")
1116                  ));
1117 }
1118
1119 # Check if the op and its sibling are the initialization and the rest of a
1120 # for (..;..;..) { ... } loop
1121 sub is_for_loop {
1122     my $op = shift;
1123     # This OP might be almost anything, though it won't be a
1124     # nextstate. (It's the initialization, so in the canonical case it
1125     # will be an sassign.) The sibling is (old style) a lineseq whose
1126     # first child is a nextstate and whose second is a leaveloop, or
1127     # (new style) an unstack whose sibling is a leaveloop.
1128     my $lseq = $op->sibling;
1129     return 0 unless !is_state($op) and !null($lseq);
1130     if ($lseq->name eq "lineseq") {
1131         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1132             && (my $sib = $lseq->first->sibling)) {
1133             return (!null($sib) && $sib->name eq "leaveloop");
1134         }
1135     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1136         my $sib = $lseq->sibling;
1137         return $sib && !null($sib) && $sib->name eq "leaveloop";
1138     }
1139     return 0;
1140 }
1141
1142 sub is_scalar {
1143     my $op = shift;
1144     return ($op->name eq "rv2sv" or
1145             $op->name eq "padsv" or
1146             $op->name eq "gv" or # only in array/hash constructs
1147             $op->flags & OPf_KIDS && !null($op->first)
1148               && $op->first->name eq "gvsv");
1149 }
1150
1151 sub maybe_parens {
1152     my $self = shift;
1153     my($text, $cx, $prec) = @_;
1154     if ($prec < $cx              # unary ops nest just fine
1155         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1156         or $self->{'parens'})
1157     {
1158         $text = "($text)";
1159         # In a unop, let parent reuse our parens; see maybe_parens_unop
1160         $text = "\cS" . $text if $cx == 16;
1161         return $text;
1162     } else {
1163         return $text;
1164     }
1165 }
1166
1167 # same as above, but get around the 'if it looks like a function' rule
1168 sub maybe_parens_unop {
1169     my $self = shift;
1170     my($name, $kid, $cx) = @_;
1171     if ($cx > 16 or $self->{'parens'}) {
1172         $kid =  $self->deparse($kid, 1);
1173         if ($name eq "umask" && $kid =~ /^\d+$/) {
1174             $kid = sprintf("%#o", $kid);
1175         }
1176         return $self->keyword($name) . "($kid)";
1177     } else {
1178         $kid = $self->deparse($kid, 16);
1179         if ($name eq "umask" && $kid =~ /^\d+$/) {
1180             $kid = sprintf("%#o", $kid);
1181         }
1182         $name = $self->keyword($name);
1183         if (substr($kid, 0, 1) eq "\cS") {
1184             # use kid's parens
1185             return $name . substr($kid, 1);
1186         } elsif (substr($kid, 0, 1) eq "(") {
1187             # avoid looks-like-a-function trap with extra parens
1188             # ('+' can lead to ambiguities)
1189             return "$name(" . $kid  . ")";
1190         } else {
1191             return "$name $kid";
1192         }
1193     }
1194 }
1195
1196 sub maybe_parens_func {
1197     my $self = shift;
1198     my($func, $text, $cx, $prec) = @_;
1199     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1200         return "$func($text)";
1201     } else {
1202         return "$func $text";
1203     }
1204 }
1205
1206 sub find_our_type {
1207     my ($self, $name) = @_;
1208     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1209     my $seq = $self->{'curcop'} ? $self->{'curcop'}->cop_seq : 0;
1210     for my $a (@{$self->{'curcvlex'}{"o$name"}}) {
1211         my ($st, undef, $padname) = @$a;
1212         if ($st >= $seq && $padname->FLAGS & SVpad_TYPED) {
1213             return $padname->SvSTASH->NAME;
1214         }
1215     }
1216     return '';
1217 }
1218
1219 sub maybe_local {
1220     my $self = shift;
1221     my($op, $cx, $text) = @_;
1222     my $name = $op->name;
1223     my $our_intro = ($name =~ /^(?:(?:gv|rv2)[ash]v|split|refassign
1224                                   |lv(?:av)?ref)$/x)
1225                         ? OPpOUR_INTRO
1226                         : 0;
1227     my $lval_intro = $name eq 'split' ? 0 : OPpLVAL_INTRO;
1228     # The @a in \(@a) isn't in ref context, but only when the
1229     # parens are there.
1230     my $need_parens = $self->{'in_refgen'} && $name =~ /[ah]v\z/
1231                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1232     if ((my $priv = $op->private) & ($lval_intro|$our_intro)) {
1233         my @our_local;
1234         push @our_local, "local" if $priv & $lval_intro;
1235         push @our_local, "our"   if $priv & $our_intro;
1236         my $our_local = join " ", map $self->keyword($_), @our_local;
1237         if( $our_local[-1] eq 'our' ) {
1238             if ( $text !~ /^\W(\w+::)*\w+\z/
1239              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1240             ) {
1241                 die "Unexpected our($text)\n";
1242             }
1243             $text =~ s/(\w+::)+//;
1244
1245             if (my $type = $self->find_our_type($text)) {
1246                 $our_local .= ' ' . $type;
1247             }
1248         }
1249         return $need_parens ? "($text)" : $text
1250             if $self->{'avoid_local'}{$$op};
1251         if ($need_parens) {
1252             return "$our_local($text)";
1253         } elsif (want_scalar($op)) {
1254             return "$our_local $text";
1255         } else {
1256             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1257         }
1258     } else {
1259         return $need_parens ? "($text)" : $text;
1260     }
1261 }
1262
1263 sub maybe_targmy {
1264     my $self = shift;
1265     my($op, $cx, $func, @args) = @_;
1266     if ($op->private & OPpTARGET_MY) {
1267         my $var = $self->padname($op->targ);
1268         my $val = $func->($self, $op, 7, @args);
1269         return $self->maybe_parens("$var = $val", $cx, 7);
1270     } else {
1271         return $func->($self, $op, $cx, @args);
1272     }
1273 }
1274
1275 sub padname_sv {
1276     my $self = shift;
1277     my $targ = shift;
1278     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1279 }
1280
1281 sub maybe_my {
1282     my $self = shift;
1283     my($op, $cx, $text, $padname, $forbid_parens) = @_;
1284     # The @a in \(@a) isn't in ref context, but only when the
1285     # parens are there.
1286     my $need_parens = !$forbid_parens && $self->{'in_refgen'}
1287                    && $op->name =~ /[ah]v\z/
1288                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1289     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1290         # Check $padname->FLAGS for statehood, rather than $op->private,
1291         # because enteriter ops do not carry the flag.
1292         my $my =
1293             $self->keyword($padname->FLAGS & SVpad_STATE ? "state" : "my");
1294         if ($padname->FLAGS & SVpad_TYPED) {
1295             $my .= ' ' . $padname->SvSTASH->NAME;
1296         }
1297         if ($need_parens) {
1298             return "$my($text)";
1299         } elsif ($forbid_parens || want_scalar($op)) {
1300             return "$my $text";
1301         } else {
1302             return $self->maybe_parens_func($my, $text, $cx, 16);
1303         }
1304     } else {
1305         return $need_parens ? "($text)" : $text;
1306     }
1307 }
1308
1309 # The following OPs don't have functions:
1310
1311 # pp_padany -- does not exist after parsing
1312
1313 sub AUTOLOAD {
1314     if ($AUTOLOAD =~ s/^.*::pp_//) {
1315         warn "unexpected OP_".
1316           ($_[1]->type == OP_CUSTOM ? "CUSTOM ($AUTOLOAD)" : uc $AUTOLOAD);
1317         return "XXX";
1318     } else {
1319         die "Undefined subroutine $AUTOLOAD called";
1320     }
1321 }
1322
1323 sub DESTROY {}  #       Do not AUTOLOAD
1324
1325 # $root should be the op which represents the root of whatever
1326 # we're sequencing here. If it's undefined, then we don't append
1327 # any subroutine declarations to the deparsed ops, otherwise we
1328 # append appropriate declarations.
1329 sub lineseq {
1330     my($self, $root, $cx, @ops) = @_;
1331     my($expr, @exprs);
1332
1333     my $out_cop = $self->{'curcop'};
1334     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1335     my $limit_seq;
1336     if (defined $root) {
1337         $limit_seq = $out_seq;
1338         my $nseq;
1339         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1340         $limit_seq = $nseq if !defined($limit_seq)
1341                            or defined($nseq) && $nseq < $limit_seq;
1342     }
1343     $limit_seq = $self->{'limit_seq'}
1344         if defined($self->{'limit_seq'})
1345         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1346     local $self->{'limit_seq'} = $limit_seq;
1347
1348     $self->walk_lineseq($root, \@ops,
1349                        sub { push @exprs, $_[0]} );
1350
1351     my $sep = $cx ? '; ' : ";\n";
1352     my $body = join($sep, grep {length} @exprs);
1353     my $subs = "";
1354     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1355         $subs = join "\n", $self->seq_subs($limit_seq);
1356     }
1357     return join($sep, grep {length} $body, $subs);
1358 }
1359
1360 sub scopeop {
1361     my($real_block, $self, $op, $cx) = @_;
1362     my $kid;
1363     my @kids;
1364
1365     local(@$self{qw'curstash warnings hints hinthash'})
1366                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1367     if ($real_block) {
1368         $kid = $op->first->sibling; # skip enter
1369         if (is_miniwhile($kid)) {
1370             my $top = $kid->first;
1371             my $name = $top->name;
1372             if ($name eq "and") {
1373                 $name = $self->keyword("while");
1374             } elsif ($name eq "or") {
1375                 $name = $self->keyword("until");
1376             } else { # no conditional -> while 1 or until 0
1377                 return $self->deparse($top->first, 1) . " "
1378                      . $self->keyword("while") . " 1";
1379             }
1380             my $cond = $top->first;
1381             my $body = $cond->sibling->first; # skip lineseq
1382             $cond = $self->deparse($cond, 1);
1383             $body = $self->deparse($body, 1);
1384             return "$body $name $cond";
1385         }
1386     } else {
1387         $kid = $op->first;
1388     }
1389     for (; !null($kid); $kid = $kid->sibling) {
1390         push @kids, $kid;
1391     }
1392     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1393         my $body = $self->lineseq($op, 0, @kids);
1394         return is_lexical_subs(@kids)
1395                 ? $body
1396                 : ($self->lex_in_scope("&do") ? "CORE::do" : "do")
1397                  . " {\n\t$body\n\b}";
1398     } else {
1399         my $lineseq = $self->lineseq($op, $cx, @kids);
1400         return (length ($lineseq) ? "$lineseq;" : "");
1401     }
1402 }
1403
1404 sub pp_scope { scopeop(0, @_); }
1405 sub pp_lineseq { scopeop(0, @_); }
1406 sub pp_leave { scopeop(1, @_); }
1407
1408 # This is a special case of scopeop and lineseq, for the case of the
1409 # main_root. The difference is that we print the output statements as
1410 # soon as we get them, for the sake of impatient users.
1411 sub deparse_root {
1412     my $self = shift;
1413     my($op) = @_;
1414     local(@$self{qw'curstash warnings hints hinthash'})
1415       = @$self{qw'curstash warnings hints hinthash'};
1416     my @kids;
1417     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1418     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1419         push @kids, $kid;
1420     }
1421     $self->walk_lineseq($op, \@kids,
1422                         sub { print $self->indent($_[0].';');
1423                               print "\n" unless $_[1] == $#kids;
1424                           });
1425 }
1426
1427 sub walk_lineseq {
1428     my ($self, $op, $kids, $callback) = @_;
1429     my @kids = @$kids;
1430     for (my $i = 0; $i < @kids; $i++) {
1431         my $expr = "";
1432         if (is_state $kids[$i]) {
1433             $expr = $self->deparse($kids[$i++], 0);
1434             if ($i > $#kids) {
1435                 $callback->($expr, $i);
1436                 last;
1437             }
1438         }
1439         if (is_for_loop($kids[$i])) {
1440             $callback->($expr . $self->for_loop($kids[$i], 0),
1441                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1442             next;
1443         }
1444         my $expr2 = $self->deparse($kids[$i], (@kids != 1)/2);
1445         $expr2 =~ s/^sub :/+sub :/; # statement label otherwise
1446         $expr .= $expr2;
1447         $expr =~ s/;\n?\z//;
1448         $callback->($expr, $i);
1449     }
1450 }
1451
1452 # The BEGIN {} is used here because otherwise this code isn't executed
1453 # when you run B::Deparse on itself.
1454 my %globalnames;
1455 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1456             "ENV", "ARGV", "ARGVOUT", "_"); }
1457
1458 sub gv_name {
1459     my $self = shift;
1460     my $gv = shift;
1461     my $raw = shift;
1462 #Carp::confess() unless ref($gv) eq "B::GV";
1463     my $cv = $gv->FLAGS & SVf_ROK ? $gv->RV : 0;
1464     my $stash = ($cv || $gv)->STASH->NAME;
1465     my $name = $raw
1466         ? $cv ? $cv->NAME_HEK || $cv->GV->NAME : $gv->NAME
1467         : $cv
1468             ? B::safename($cv->NAME_HEK || $cv->GV->NAME)
1469             : $gv->SAFENAME;
1470     if ($stash eq 'main' && $name =~ /^::/) {
1471         $stash = '::';
1472     }
1473     elsif (($stash eq 'main'
1474             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1475         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1476             && ($stash eq 'main' || $name !~ /::/))
1477           )
1478     {
1479         $stash = "";
1480     } else {
1481         $stash = $stash . "::";
1482     }
1483     if (!$raw and $name =~ /^(\^..|{)/) {
1484         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1485     }
1486     return $stash . $name;
1487 }
1488
1489 # Return the name to use for a stash variable.
1490 # If a lexical with the same name is in scope, or
1491 # if strictures are enabled, it may need to be
1492 # fully-qualified.
1493 sub stash_variable {
1494     my ($self, $prefix, $name, $cx) = @_;
1495
1496     return "$prefix$name" if $name =~ /::/;
1497
1498     unless ($prefix eq '$' || $prefix eq '@' || #'
1499             $prefix eq '%' || $prefix eq '$#') {
1500         return "$prefix$name";
1501     }
1502
1503     if ($name =~ /^[^\w+-]$/) {
1504       if (defined $cx && $cx == 26) {
1505         if ($prefix eq '@') {
1506             return "$prefix\{$name}";
1507         }
1508         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1509       }
1510       if ($prefix eq '$#') {
1511         return "\$#{$name}";
1512       }
1513     }
1514
1515     return $prefix . $self->maybe_qualify($prefix, $name);
1516 }
1517
1518 # Return just the name, without the prefix.  It may be returned as a quoted
1519 # string.  The second return value is a boolean indicating that.
1520 sub stash_variable_name {
1521     my($self, $prefix, $gv) = @_;
1522     my $name = $self->gv_name($gv, 1);
1523     $name = $self->maybe_qualify($prefix,$name);
1524     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1525         $name =~ s/^([\ca-\cz])/'^'.($1|'@')/e;
1526         $name =~ /^(\^..|{)/ and $name = "{$name}";
1527         return $name, 0; # not quoted
1528     }
1529     else {
1530         single_delim("q", "'", $name, $self), 1;
1531     }
1532 }
1533
1534 sub maybe_qualify {
1535     my ($self,$prefix,$name) = @_;
1536     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1537     return $name if !$prefix || $name =~ /::/;
1538     return $self->{'curstash'}.'::'. $name
1539         if
1540             $name =~ /^(?!\d)\w/         # alphabetic
1541          && $v    !~ /^\$[ab]\z/         # not $a or $b
1542          && !$globalnames{$name}         # not a global name
1543          && $self->{hints} & $strict_bits{vars}  # strict vars
1544          && !$self->lex_in_scope($v,1)   # no "our"
1545       or $self->lex_in_scope($v);        # conflicts with "my" variable
1546     return $name;
1547 }
1548
1549 sub lex_in_scope {
1550     my ($self, $name, $our) = @_;
1551     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1552     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1553
1554     return 0 if !defined($self->{'curcop'});
1555     my $seq = $self->{'curcop'}->cop_seq;
1556     return 0 if !exists $self->{'curcvlex'}{$name};
1557     for my $a (@{$self->{'curcvlex'}{$name}}) {
1558         my ($st, $en) = @$a;
1559         return 1 if $seq > $st && $seq <= $en;
1560     }
1561     return 0;
1562 }
1563
1564 sub populate_curcvlex {
1565     my $self = shift;
1566     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1567         my $padlist = $cv->PADLIST;
1568         # an undef CV still in lexical chain
1569         next if class($padlist) eq "SPECIAL";
1570         my @padlist = $padlist->ARRAY;
1571         my @ns = $padlist[0]->ARRAY;
1572
1573         for (my $i=0; $i<@ns; ++$i) {
1574             next if class($ns[$i]) eq "SPECIAL";
1575             if (class($ns[$i]) eq "PV") {
1576                 # Probably that pesky lexical @_
1577                 next;
1578             }
1579             my $name = $ns[$i]->PVX;
1580             my ($seq_st, $seq_en) =
1581                 ($ns[$i]->FLAGS & SVf_FAKE)
1582                     ? (0, 999999)
1583                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1584
1585             push @{$self->{'curcvlex'}{
1586                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1587                   }}, [$seq_st, $seq_en, $ns[$i]];
1588         }
1589     }
1590 }
1591
1592 sub find_scope_st { ((find_scope(@_))[0]); }
1593 sub find_scope_en { ((find_scope(@_))[1]); }
1594
1595 # Recurses down the tree, looking for pad variable introductions and COPs
1596 sub find_scope {
1597     my ($self, $op, $scope_st, $scope_en) = @_;
1598     carp("Undefined op in find_scope") if !defined $op;
1599     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1600
1601     my @queue = ($op);
1602     while(my $op = shift @queue ) {
1603         for (my $o=$op->first; $$o; $o=$o->sibling) {
1604             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1605                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1606                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1607                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1608                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1609                 return ($scope_st, $scope_en);
1610             }
1611             elsif (is_state($o)) {
1612                 my $c = $o->cop_seq;
1613                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1614                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1615                 return ($scope_st, $scope_en);
1616             }
1617             elsif ($o->flags & OPf_KIDS) {
1618                 unshift (@queue, $o);
1619             }
1620         }
1621     }
1622
1623     return ($scope_st, $scope_en);
1624 }
1625
1626 # Returns a list of subs which should be inserted before the COP
1627 sub cop_subs {
1628     my ($self, $op, $out_seq) = @_;
1629     my $seq = $op->cop_seq;
1630     if ($] < 5.021006) {
1631       # If we have nephews, then our sequence number indicates
1632       # the cop_seq of the end of some sort of scope.
1633       if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1634         and my $nseq = $self->find_scope_st($op->sibling) ) {
1635         $seq = $nseq;
1636       }
1637     }
1638     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1639     return $self->seq_subs($seq);
1640 }
1641
1642 sub seq_subs {
1643     my ($self, $seq) = @_;
1644     my @text;
1645 #push @text, "# ($seq)\n";
1646
1647     return "" if !defined $seq;
1648     while (scalar(@{$self->{'subs_todo'}})
1649            and $seq > $self->{'subs_todo'}[0][0]) {
1650         push @text, $self->next_todo;
1651     }
1652     return @text;
1653 }
1654
1655 sub _features_from_bundle {
1656     my ($hints, $hh) = @_;
1657     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
1658         $hh->{$feature::feature{$_}} = 1;
1659     }
1660     return $hh;
1661 }
1662
1663 # Notice how subs and formats are inserted between statements here;
1664 # also $[ assignments and pragmas.
1665 sub pp_nextstate {
1666     my $self = shift;
1667     my($op, $cx) = @_;
1668     $self->{'curcop'} = $op;
1669     my @text;
1670     push @text, $self->cop_subs($op);
1671     my $stash = $op->stashpv;
1672     if ($stash ne $self->{'curstash'}) {
1673         push @text, $self->keyword("package") . " $stash;\n";
1674         $self->{'curstash'} = $stash;
1675     }
1676
1677     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1678         push @text, '$[ = '. $op->arybase .";\n";
1679         $self->{'arybase'} = $op->arybase;
1680     }
1681
1682     my $warnings = $op->warnings;
1683     my $warning_bits;
1684     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1685         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1686     }
1687     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1688         $warning_bits = $warnings::NONE;
1689     }
1690     elsif ($warnings->isa("B::SPECIAL")) {
1691         $warning_bits = undef;
1692     }
1693     else {
1694         $warning_bits = $warnings->PV & WARN_MASK;
1695     }
1696
1697     if (defined ($warning_bits) and
1698        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1699         push @text,
1700             $self->declare_warnings($self->{'warnings'}, $warning_bits);
1701         $self->{'warnings'} = $warning_bits;
1702     }
1703
1704     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1705     my $old_hints = $self->{'hints'};
1706     if ($self->{'hints'} != $hints) {
1707         push @text, $self->declare_hints($self->{'hints'}, $hints);
1708         $self->{'hints'} = $hints;
1709     }
1710
1711     my $newhh;
1712     if ($] > 5.009) {
1713         $newhh = $op->hints_hash->HASH;
1714     }
1715
1716     if ($] >= 5.015006) {
1717         # feature bundle hints
1718         my $from = $old_hints & $feature::hint_mask;
1719         my $to   = $    hints & $feature::hint_mask;
1720         if ($from != $to) {
1721             if ($to == $feature::hint_mask) {
1722                 if ($self->{'hinthash'}) {
1723                     delete $self->{'hinthash'}{$_}
1724                         for grep /^feature_/, keys %{$self->{'hinthash'}};
1725                 }
1726                 else { $self->{'hinthash'} = {} }
1727                 $self->{'hinthash'}
1728                     = _features_from_bundle($from, $self->{'hinthash'});
1729             }
1730             else {
1731                 my $bundle =
1732                     $feature::hint_bundles[$to >> $feature::hint_shift];
1733                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
1734                 push @text,
1735                     $self->keyword("no") . " feature;\n",
1736                     $self->keyword("use") . " feature ':$bundle';\n";
1737             }
1738         }
1739     }
1740
1741     if ($] > 5.009) {
1742         push @text, $self->declare_hinthash(
1743             $self->{'hinthash'}, $newhh,
1744             $self->{indent_size}, $self->{hints},
1745         );
1746         $self->{'hinthash'} = $newhh;
1747     }
1748
1749     # This should go after of any branches that add statements, to
1750     # increase the chances that it refers to the same line it did in
1751     # the original program.
1752     if ($self->{'linenums'}) {
1753         push @text, "\f#line " . $op->line .
1754           ' "' . $op->file, qq'"\n';
1755     }
1756
1757     push @text, $op->label . ": " if $op->label;
1758
1759     return join("", @text);
1760 }
1761
1762 sub declare_warnings {
1763     my ($self, $from, $to) = @_;
1764     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1765         return $self->keyword("use") . " warnings;\n";
1766     }
1767     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1768         return $self->keyword("no") . " warnings;\n";
1769     }
1770     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1771 }
1772
1773 sub declare_hints {
1774     my ($self, $from, $to) = @_;
1775     my $use = $to   & ~$from;
1776     my $no  = $from & ~$to;
1777     my $decls = "";
1778     for my $pragma (hint_pragmas($use)) {
1779         $decls .= $self->keyword("use") . " $pragma;\n";
1780     }
1781     for my $pragma (hint_pragmas($no)) {
1782         $decls .= $self->keyword("no") . " $pragma;\n";
1783     }
1784     return $decls;
1785 }
1786
1787 # Internal implementation hints that the core sets automatically, so don't need
1788 # (or want) to be passed back to the user
1789 my %ignored_hints = (
1790     'open<' => 1,
1791     'open>' => 1,
1792     ':'     => 1,
1793     'strict/refs' => 1,
1794     'strict/subs' => 1,
1795     'strict/vars' => 1,
1796 );
1797
1798 my %rev_feature;
1799
1800 sub declare_hinthash {
1801     my ($self, $from, $to, $indent, $hints) = @_;
1802     my $doing_features =
1803         ($hints & $feature::hint_mask) == $feature::hint_mask;
1804     my @decls;
1805     my @features;
1806     my @unfeatures; # bugs?
1807     for my $key (sort keys %$to) {
1808         next if $ignored_hints{$key};
1809         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1810         next if $is_feature and not $doing_features;
1811         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
1812             push(@features, $key), next if $is_feature;
1813             push @decls,
1814                 qq(\$^H{) . single_delim("q", "'", $key, $self) . qq(} = )
1815               . (
1816                    defined $to->{$key}
1817                         ? single_delim("q", "'", $to->{$key}, $self)
1818                         : 'undef'
1819                 )
1820               . qq(;);
1821         }
1822     }
1823     for my $key (sort keys %$from) {
1824         next if $ignored_hints{$key};
1825         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1826         next if $is_feature and not $doing_features;
1827         if (!exists $to->{$key}) {
1828             push(@unfeatures, $key), next if $is_feature;
1829             push @decls, qq(delete \$^H{'$key'};);
1830         }
1831     }
1832     my @ret;
1833     if (@features || @unfeatures) {
1834         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
1835     }
1836     if (@features) {
1837         push @ret, $self->keyword("use") . " feature "
1838                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
1839     }
1840     if (@unfeatures) {
1841         push @ret, $self->keyword("no") . " feature "
1842                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
1843                  . ";\n";
1844     }
1845     @decls and
1846         push @ret,
1847              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1848     return @ret;
1849 }
1850
1851 sub hint_pragmas {
1852     my ($bits) = @_;
1853     my (@pragmas, @strict);
1854     push @pragmas, "integer" if $bits & 0x1;
1855     for (sort keys %strict_bits) {
1856         push @strict, "'$_'" if $bits & $strict_bits{$_};
1857     }
1858     if (@strict == keys %strict_bits) {
1859         push @pragmas, "strict";
1860     }
1861     elsif (@strict) {
1862         push @pragmas, "strict " . join ', ', @strict;
1863     }
1864     push @pragmas, "bytes" if $bits & 0x8;
1865     return @pragmas;
1866 }
1867
1868 sub pp_dbstate { pp_nextstate(@_) }
1869 sub pp_setstate { pp_nextstate(@_) }
1870
1871 sub pp_unstack { return "" } # see also leaveloop
1872
1873 my %feature_keywords = (
1874   # keyword => 'feature',
1875     state   => 'state',
1876     say     => 'say',
1877     given   => 'switch',
1878     when    => 'switch',
1879     default => 'switch',
1880     break   => 'switch',
1881     evalbytes=>'evalbytes',
1882     __SUB__ => '__SUB__',
1883    fc       => 'fc',
1884 );
1885
1886 # keywords that are strong and also have a prototype
1887 #
1888 my %strong_proto_keywords = map { $_ => 1 } qw(
1889     pos
1890     prototype
1891     scalar
1892     study
1893     undef
1894 );
1895
1896 sub feature_enabled {
1897         my($self,$name) = @_;
1898         my $hh;
1899         my $hints = $self->{hints} & $feature::hint_mask;
1900         if ($hints && $hints != $feature::hint_mask) {
1901             $hh = _features_from_bundle($hints);
1902         }
1903         elsif ($hints) { $hh = $self->{'hinthash'} }
1904         return $hh && $hh->{"feature_$feature_keywords{$name}"}
1905 }
1906
1907 sub keyword {
1908     my $self = shift;
1909     my $name = shift;
1910     return $name if $name =~ /^CORE::/; # just in case
1911     if (exists $feature_keywords{$name}) {
1912         return "CORE::$name" if not $self->feature_enabled($name);
1913     }
1914     # This sub may be called for a program that has no nextstate ops.  In
1915     # that case we may have a lexical sub named no/use/sub in scope but
1916     # but $self->lex_in_scope will return false because it depends on the
1917     # current nextstate op.  So we need this alternate method if there is
1918     # no current cop.
1919     if (!$self->{'curcop'}) {
1920         $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1921         return "CORE::$name" if exists $self->{'curcvlex'}{"m&$name"}
1922                              || exists $self->{'curcvlex'}{"o&$name"};
1923     } elsif ($self->lex_in_scope("&$name")
1924           || $self->lex_in_scope("&$name", 1)) {
1925         return "CORE::$name";
1926     }
1927     if ($strong_proto_keywords{$name}
1928         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1929             && !defined eval{prototype "CORE::$name"})
1930     ) { return $name }
1931     if (
1932         exists $self->{subs_declared}{$name}
1933          or
1934         exists &{"$self->{curstash}::$name"}
1935     ) {
1936         return "CORE::$name"
1937     }
1938     return $name;
1939 }
1940
1941 sub baseop {
1942     my $self = shift;
1943     my($op, $cx, $name) = @_;
1944     return $self->keyword($name);
1945 }
1946
1947 sub pp_stub {
1948     my $self = shift;
1949     my($op, $cx, $name) = @_;
1950     if ($cx >= 1) {
1951         return "()";
1952     }
1953     else {
1954         return "();";
1955     }
1956 }
1957 sub pp_wantarray { baseop(@_, "wantarray") }
1958 sub pp_fork { baseop(@_, "fork") }
1959 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1960 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1961 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1962 sub pp_tms { baseop(@_, "times") }
1963 sub pp_ghostent { baseop(@_, "gethostent") }
1964 sub pp_gnetent { baseop(@_, "getnetent") }
1965 sub pp_gprotoent { baseop(@_, "getprotoent") }
1966 sub pp_gservent { baseop(@_, "getservent") }
1967 sub pp_ehostent { baseop(@_, "endhostent") }
1968 sub pp_enetent { baseop(@_, "endnetent") }
1969 sub pp_eprotoent { baseop(@_, "endprotoent") }
1970 sub pp_eservent { baseop(@_, "endservent") }
1971 sub pp_gpwent { baseop(@_, "getpwent") }
1972 sub pp_spwent { baseop(@_, "setpwent") }
1973 sub pp_epwent { baseop(@_, "endpwent") }
1974 sub pp_ggrent { baseop(@_, "getgrent") }
1975 sub pp_sgrent { baseop(@_, "setgrent") }
1976 sub pp_egrent { baseop(@_, "endgrent") }
1977 sub pp_getlogin { baseop(@_, "getlogin") }
1978
1979 sub POSTFIX () { 1 }
1980
1981 # I couldn't think of a good short name, but this is the category of
1982 # symbolic unary operators with interesting precedence
1983
1984 sub pfixop {
1985     my $self = shift;
1986     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1987     my $kid = $op->first;
1988     $kid = $self->deparse($kid, $prec);
1989     return $self->maybe_parens(($flags & POSTFIX)
1990                                  ? "$kid$name"
1991                                    # avoid confusion with filetests
1992                                  : $name eq '-'
1993                                    && $kid =~ /^[a-zA-Z](?!\w)/
1994                                         ? "$name($kid)"
1995                                         : "$name$kid",
1996                                $cx, $prec);
1997 }
1998
1999 sub pp_preinc { pfixop(@_, "++", 23) }
2000 sub pp_predec { pfixop(@_, "--", 23) }
2001 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2002 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2003 sub pp_i_preinc { pfixop(@_, "++", 23) }
2004 sub pp_i_predec { pfixop(@_, "--", 23) }
2005 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2006 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2007 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
2008
2009 sub pp_negate { maybe_targmy(@_, \&real_negate) }
2010 sub real_negate {
2011     my $self = shift;
2012     my($op, $cx) = @_;
2013     if ($op->first->name =~ /^(i_)?negate$/) {
2014         # avoid --$x
2015         $self->pfixop($op, $cx, "-", 21.5);
2016     } else {
2017         $self->pfixop($op, $cx, "-", 21);       
2018     }
2019 }
2020 sub pp_i_negate { pp_negate(@_) }
2021
2022 sub pp_not {
2023     my $self = shift;
2024     my($op, $cx) = @_;
2025     if ($cx <= 4) {
2026         $self->listop($op, $cx, "not", $op->first);
2027     } else {
2028         $self->pfixop($op, $cx, "!", 21);       
2029     }
2030 }
2031
2032 sub unop {
2033     my $self = shift;
2034     my($op, $cx, $name, $nollafr) = @_;
2035     my $kid;
2036     if ($op->flags & OPf_KIDS) {
2037         $kid = $op->first;
2038         if (not $name) {
2039             # this deals with 'boolkeys' right now
2040             return $self->deparse($kid,$cx);
2041         }
2042         my $builtinname = $name;
2043         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
2044         if (defined prototype($builtinname)
2045            && prototype($builtinname) =~ /^;?\*/
2046            && $kid->name eq "rv2gv") {
2047             $kid = $kid->first;
2048         }
2049
2050         if ($nollafr) {
2051             ($kid = $self->deparse($kid, 16)) =~ s/^\cS//;
2052             return $self->maybe_parens(
2053                         $self->keyword($name) . " $kid", $cx, 16
2054                    );
2055         }   
2056         return $self->maybe_parens_unop($name, $kid, $cx);
2057     } else {
2058         return $self->maybe_parens(
2059             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
2060             $cx, 16,
2061         );
2062     }
2063 }
2064
2065 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
2066 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
2067 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
2068 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
2069 sub pp_defined { unop(@_, "defined") }
2070 sub pp_undef { unop(@_, "undef") }
2071 sub pp_study { unop(@_, "study") }
2072 sub pp_ref { unop(@_, "ref") }
2073 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
2074
2075 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
2076 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
2077 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
2078 sub pp_srand { unop(@_, "srand") }
2079 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
2080 sub pp_log { maybe_targmy(@_, \&unop, "log") }
2081 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
2082 sub pp_int { maybe_targmy(@_, \&unop, "int") }
2083 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
2084 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
2085 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
2086
2087 sub pp_length { maybe_targmy(@_, \&unop, "length") }
2088 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
2089 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
2090
2091 sub pp_each { unop(@_, "each") }
2092 sub pp_values { unop(@_, "values") }
2093 sub pp_keys { unop(@_, "keys") }
2094 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2095 sub pp_boolkeys { 
2096     # no name because its an optimisation op that has no keyword
2097     unop(@_,"");
2098 }
2099 sub pp_aeach { unop(@_, "each") }
2100 sub pp_avalues { unop(@_, "values") }
2101 sub pp_akeys { unop(@_, "keys") }
2102 sub pp_pop { unop(@_, "pop") }
2103 sub pp_shift { unop(@_, "shift") }
2104
2105 sub pp_caller { unop(@_, "caller") }
2106 sub pp_reset { unop(@_, "reset") }
2107 sub pp_exit { unop(@_, "exit") }
2108 sub pp_prototype { unop(@_, "prototype") }
2109
2110 sub pp_close { unop(@_, "close") }
2111 sub pp_fileno { unop(@_, "fileno") }
2112 sub pp_umask { unop(@_, "umask") }
2113 sub pp_untie { unop(@_, "untie") }
2114 sub pp_tied { unop(@_, "tied") }
2115 sub pp_dbmclose { unop(@_, "dbmclose") }
2116 sub pp_getc { unop(@_, "getc") }
2117 sub pp_eof { unop(@_, "eof") }
2118 sub pp_tell { unop(@_, "tell") }
2119 sub pp_getsockname { unop(@_, "getsockname") }
2120 sub pp_getpeername { unop(@_, "getpeername") }
2121
2122 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
2123 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2124 sub pp_readlink { unop(@_, "readlink") }
2125 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2126 sub pp_readdir { unop(@_, "readdir") }
2127 sub pp_telldir { unop(@_, "telldir") }
2128 sub pp_rewinddir { unop(@_, "rewinddir") }
2129 sub pp_closedir { unop(@_, "closedir") }
2130 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2131 sub pp_localtime { unop(@_, "localtime") }
2132 sub pp_gmtime { unop(@_, "gmtime") }
2133 sub pp_alarm { unop(@_, "alarm") }
2134 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2135
2136 sub pp_dofile {
2137     my $code = unop(@_, "do", 1); # llafr does not apply
2138     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2139     $code;
2140 }
2141 sub pp_entereval {
2142     unop(
2143       @_,
2144       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
2145     )
2146 }
2147
2148 sub pp_ghbyname { unop(@_, "gethostbyname") }
2149 sub pp_gnbyname { unop(@_, "getnetbyname") }
2150 sub pp_gpbyname { unop(@_, "getprotobyname") }
2151 sub pp_shostent { unop(@_, "sethostent") }
2152 sub pp_snetent { unop(@_, "setnetent") }
2153 sub pp_sprotoent { unop(@_, "setprotoent") }
2154 sub pp_sservent { unop(@_, "setservent") }
2155 sub pp_gpwnam { unop(@_, "getpwnam") }
2156 sub pp_gpwuid { unop(@_, "getpwuid") }
2157 sub pp_ggrnam { unop(@_, "getgrnam") }
2158 sub pp_ggrgid { unop(@_, "getgrgid") }
2159
2160 sub pp_lock { unop(@_, "lock") }
2161
2162 sub pp_continue { unop(@_, "continue"); }
2163 sub pp_break { unop(@_, "break"); }
2164
2165 sub givwhen {
2166     my $self = shift;
2167     my($op, $cx, $givwhen) = @_;
2168
2169     my $enterop = $op->first;
2170     my ($head, $block);
2171     if ($enterop->flags & OPf_SPECIAL) {
2172         $head = $self->keyword("default");
2173         $block = $self->deparse($enterop->first, 0);
2174     }
2175     else {
2176         my $cond = $enterop->first;
2177         my $cond_str = $self->deparse($cond, 1);
2178         $head = "$givwhen ($cond_str)";
2179         $block = $self->deparse($cond->sibling, 0);
2180     }
2181
2182     return "$head {\n".
2183         "\t$block\n".
2184         "\b}\cK";
2185 }
2186
2187 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2188 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2189
2190 sub pp_exists {
2191     my $self = shift;
2192     my($op, $cx) = @_;
2193     my $arg;
2194     my $name = $self->keyword("exists");
2195     if ($op->private & OPpEXISTS_SUB) {
2196         # Checking for the existence of a subroutine
2197         return $self->maybe_parens_func($name,
2198                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2199     }
2200     if ($op->flags & OPf_SPECIAL) {
2201         # Array element, not hash element
2202         return $self->maybe_parens_func($name,
2203                                 $self->pp_aelem($op->first, 16), $cx, 16);
2204     }
2205     return $self->maybe_parens_func($name, $self->pp_helem($op->first, 16),
2206                                     $cx, 16);
2207 }
2208
2209 sub pp_delete {
2210     my $self = shift;
2211     my($op, $cx) = @_;
2212     my $arg;
2213     my $name = $self->keyword("delete");
2214     if ($op->private & OPpSLICE) {
2215         if ($op->flags & OPf_SPECIAL) {
2216             # Deleting from an array, not a hash
2217             return $self->maybe_parens_func($name,
2218                                         $self->pp_aslice($op->first, 16),
2219                                         $cx, 16);
2220         }
2221         return $self->maybe_parens_func($name,
2222                                         $self->pp_hslice($op->first, 16),
2223                                         $cx, 16);
2224     } else {
2225         if ($op->flags & OPf_SPECIAL) {
2226             # Deleting from an array, not a hash
2227             return $self->maybe_parens_func($name,
2228                                         $self->pp_aelem($op->first, 16),
2229                                         $cx, 16);
2230         }
2231         return $self->maybe_parens_func($name,
2232                                         $self->pp_helem($op->first, 16),
2233                                         $cx, 16);
2234     }
2235 }
2236
2237 sub pp_require {
2238     my $self = shift;
2239     my($op, $cx) = @_;
2240     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2241     if (class($op) eq "UNOP" and $op->first->name eq "const"
2242         and $op->first->private & OPpCONST_BARE)
2243     {
2244         my $name = $self->const_sv($op->first)->PV;
2245         $name =~ s[/][::]g;
2246         $name =~ s/\.pm//g;
2247         return $self->maybe_parens("$opname $name", $cx, 16);
2248     } else {    
2249         $self->unop(
2250             $op, $cx,
2251             $op->first->name eq 'const'
2252              && $op->first->private & OPpCONST_NOVER
2253                  ? "no"
2254                  : $opname,
2255             1, # llafr does not apply
2256         );
2257     }
2258 }
2259
2260 sub pp_scalar {
2261     my $self = shift;
2262     my($op, $cx) = @_;
2263     my $kid = $op->first;
2264     if (not null $kid->sibling) {
2265         # XXX Was a here-doc
2266         return $self->dquote($op);
2267     }
2268     $self->unop(@_, "scalar");
2269 }
2270
2271
2272 sub padval {
2273     my $self = shift;
2274     my $targ = shift;
2275     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2276 }
2277
2278 sub anon_hash_or_list {
2279     my $self = shift;
2280     my($op, $cx) = @_;
2281
2282     my($pre, $post) = @{{"anonlist" => ["[","]"],
2283                          "anonhash" => ["{","}"]}->{$op->name}};
2284     my($expr, @exprs);
2285     $op = $op->first->sibling; # skip pushmark
2286     for (; !null($op); $op = $op->sibling) {
2287         $expr = $self->deparse($op, 6);
2288         push @exprs, $expr;
2289     }
2290     if ($pre eq "{" and $cx < 1) {
2291         # Disambiguate that it's not a block
2292         $pre = "+{";
2293     }
2294     return $pre . join(", ", @exprs) . $post;
2295 }
2296
2297 sub pp_anonlist {
2298     my $self = shift;
2299     my ($op, $cx) = @_;
2300     if ($op->flags & OPf_SPECIAL) {
2301         return $self->anon_hash_or_list($op, $cx);
2302     }
2303     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2304     return 'XXX';
2305 }
2306
2307 *pp_anonhash = \&pp_anonlist;
2308
2309 sub pp_refgen {
2310     my $self = shift;   
2311     my($op, $cx) = @_;
2312     my $kid = $op->first;
2313     if ($kid->name eq "null") {
2314         my $anoncode = $kid = $kid->first;
2315         if ($anoncode->name eq "anoncode"
2316          or !null($anoncode = $kid->sibling) and
2317                  $anoncode->name eq "anoncode") {
2318             return $self->e_anoncode({ code => $self->padval($anoncode->targ) });
2319         } elsif ($kid->name eq "pushmark") {
2320             my $sib_name = $kid->sibling->name;
2321             if ($sib_name eq 'entersub') {
2322                 my $text = $self->deparse($kid->sibling, 1);
2323                 # Always show parens for \(&func()), but only with -p otherwise
2324                 $text = "($text)" if $self->{'parens'}
2325                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2326                 return "\\$text";
2327             }
2328         }
2329     }
2330     local $self->{'in_refgen'} = 1;
2331     $self->pfixop($op, $cx, "\\", 20);
2332 }
2333
2334 sub e_anoncode {
2335     my ($self, $info) = @_;
2336     my $text = $self->deparse_sub($info->{code});
2337     return $self->keyword("sub") . " $text";
2338 }
2339
2340 sub pp_srefgen { pp_refgen(@_) }
2341
2342 sub pp_readline {
2343     my $self = shift;
2344     my($op, $cx) = @_;
2345     my $kid = $op->first;
2346     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
2347     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
2348     return $self->unop($op, $cx, "readline");
2349 }
2350
2351 sub pp_rcatline {
2352     my $self = shift;
2353     my($op) = @_;
2354     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2355 }
2356
2357 # Unary operators that can occur as pseudo-listops inside double quotes
2358 sub dq_unop {
2359     my $self = shift;
2360     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2361     my $kid;
2362     if ($op->flags & OPf_KIDS) {
2363        $kid = $op->first;
2364        # If there's more than one kid, the first is an ex-pushmark.
2365        $kid = $kid->sibling if not null $kid->sibling;
2366        return $self->maybe_parens_unop($name, $kid, $cx);
2367     } else {
2368        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2369     }
2370 }
2371
2372 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2373 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2374 sub pp_uc { dq_unop(@_, "uc") }
2375 sub pp_lc { dq_unop(@_, "lc") }
2376 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2377 sub pp_fc { dq_unop(@_, "fc") }
2378
2379 sub loopex {
2380     my $self = shift;
2381     my ($op, $cx, $name) = @_;
2382     if (class($op) eq "PVOP") {
2383         $name .= " " . $op->pv;
2384     } elsif (class($op) eq "OP") {
2385         # no-op
2386     } elsif (class($op) eq "UNOP") {
2387         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2388         $name .= " $kid";
2389     }
2390     return $self->maybe_parens($name, $cx, 7);
2391 }
2392
2393 sub pp_last { loopex(@_, "last") }
2394 sub pp_next { loopex(@_, "next") }
2395 sub pp_redo { loopex(@_, "redo") }
2396 sub pp_goto { loopex(@_, "goto") }
2397 sub pp_dump { loopex(@_, "CORE::dump") }
2398
2399 sub ftst {
2400     my $self = shift;
2401     my($op, $cx, $name) = @_;
2402     if (class($op) eq "UNOP") {
2403         # Genuine '-X' filetests are exempt from the LLAFR, but not
2404         # l?stat()
2405         if ($name =~ /^-/) {
2406             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2407             return $self->maybe_parens("$name $kid", $cx, 16);
2408         }
2409         return $self->maybe_parens_unop($name, $op->first, $cx);
2410     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2411         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2412     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2413         return $name;
2414     }
2415 }
2416
2417 sub pp_lstat    { ftst(@_, "lstat") }
2418 sub pp_stat     { ftst(@_, "stat") }
2419 sub pp_ftrread  { ftst(@_, "-R") }
2420 sub pp_ftrwrite { ftst(@_, "-W") }
2421 sub pp_ftrexec  { ftst(@_, "-X") }
2422 sub pp_fteread  { ftst(@_, "-r") }
2423 sub pp_ftewrite { ftst(@_, "-w") }
2424 sub pp_fteexec  { ftst(@_, "-x") }
2425 sub pp_ftis     { ftst(@_, "-e") }
2426 sub pp_fteowned { ftst(@_, "-O") }
2427 sub pp_ftrowned { ftst(@_, "-o") }
2428 sub pp_ftzero   { ftst(@_, "-z") }
2429 sub pp_ftsize   { ftst(@_, "-s") }
2430 sub pp_ftmtime  { ftst(@_, "-M") }
2431 sub pp_ftatime  { ftst(@_, "-A") }
2432 sub pp_ftctime  { ftst(@_, "-C") }
2433 sub pp_ftsock   { ftst(@_, "-S") }
2434 sub pp_ftchr    { ftst(@_, "-c") }
2435 sub pp_ftblk    { ftst(@_, "-b") }
2436 sub pp_ftfile   { ftst(@_, "-f") }
2437 sub pp_ftdir    { ftst(@_, "-d") }
2438 sub pp_ftpipe   { ftst(@_, "-p") }
2439 sub pp_ftlink   { ftst(@_, "-l") }
2440 sub pp_ftsuid   { ftst(@_, "-u") }
2441 sub pp_ftsgid   { ftst(@_, "-g") }
2442 sub pp_ftsvtx   { ftst(@_, "-k") }
2443 sub pp_fttty    { ftst(@_, "-t") }
2444 sub pp_fttext   { ftst(@_, "-T") }
2445 sub pp_ftbinary { ftst(@_, "-B") }
2446
2447 sub SWAP_CHILDREN () { 1 }
2448 sub ASSIGN () { 2 } # has OP= variant
2449 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2450
2451 my(%left, %right);
2452
2453 sub assoc_class {
2454     my $op = shift;
2455     my $name = $op->name;
2456     if ($name eq "concat" and $op->first->name eq "concat") {
2457         # avoid spurious '=' -- see comment in pp_concat
2458         return "concat";
2459     }
2460     if ($name eq "null" and class($op) eq "UNOP"
2461         and $op->first->name =~ /^(and|x?or)$/
2462         and null $op->first->sibling)
2463     {
2464         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2465         # with a null that's used as the common end point of the two
2466         # flows of control. For precedence purposes, ignore it.
2467         # (COND_EXPRs have these too, but we don't bother with
2468         # their associativity).
2469         return assoc_class($op->first);
2470     }
2471     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2472 }
2473
2474 # Left associative operators, like '+', for which
2475 # $a + $b + $c is equivalent to ($a + $b) + $c
2476
2477 BEGIN {
2478     %left = ('multiply' => 19, 'i_multiply' => 19,
2479              'divide' => 19, 'i_divide' => 19,
2480              'modulo' => 19, 'i_modulo' => 19,
2481              'repeat' => 19,
2482              'add' => 18, 'i_add' => 18,
2483              'subtract' => 18, 'i_subtract' => 18,
2484              'concat' => 18,
2485              'left_shift' => 17, 'right_shift' => 17,
2486              'bit_and' => 13,
2487              'bit_or' => 12, 'bit_xor' => 12,
2488              'and' => 3,
2489              'or' => 2, 'xor' => 2,
2490             );
2491 }
2492
2493 sub deparse_binop_left {
2494     my $self = shift;
2495     my($op, $left, $prec) = @_;
2496     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2497         and $left{assoc_class($op)} == $left{assoc_class($left)})
2498     {
2499         return $self->deparse($left, $prec - .00001);
2500     } else {
2501         return $self->deparse($left, $prec);    
2502     }
2503 }
2504
2505 # Right associative operators, like '=', for which
2506 # $a = $b = $c is equivalent to $a = ($b = $c)
2507
2508 BEGIN {
2509     %right = ('pow' => 22,
2510               'sassign=' => 7, 'aassign=' => 7,
2511               'multiply=' => 7, 'i_multiply=' => 7,
2512               'divide=' => 7, 'i_divide=' => 7,
2513               'modulo=' => 7, 'i_modulo=' => 7,
2514               'repeat=' => 7, 'refassign' => 7, 'refassign=' => 7,
2515               'add=' => 7, 'i_add=' => 7,
2516               'subtract=' => 7, 'i_subtract=' => 7,
2517               'concat=' => 7,
2518               'left_shift=' => 7, 'right_shift=' => 7,
2519               'bit_and=' => 7,
2520               'bit_or=' => 7, 'bit_xor=' => 7,
2521               'andassign' => 7,
2522               'orassign' => 7,
2523              );
2524 }
2525
2526 sub deparse_binop_right {
2527     my $self = shift;
2528     my($op, $right, $prec) = @_;
2529     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2530         and $right{assoc_class($op)} == $right{assoc_class($right)})
2531     {
2532         return $self->deparse($right, $prec - .00001);
2533     } else {
2534         return $self->deparse($right, $prec);   
2535     }
2536 }
2537
2538 sub binop {
2539     my $self = shift;
2540     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2541     my $left = $op->first;
2542     my $right = $op->last;
2543     my $eq = "";
2544     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2545         $eq = "=";
2546         $prec = 7;
2547     }
2548     if ($flags & SWAP_CHILDREN) {
2549         ($left, $right) = ($right, $left);
2550     }
2551     my $leftop = $left;
2552     $left = $self->deparse_binop_left($op, $left, $prec);
2553     $left = "($left)" if $flags & LIST_CONTEXT
2554                      and    $left !~ /^(my|our|local|)[\@\(]/
2555                          || do {
2556                                 # Parenthesize if the left argument is a
2557                                 # lone repeat op.
2558                                 my $left = $leftop->first->sibling;
2559                                 $left->name eq 'repeat'
2560                                     && null($left->sibling);
2561                             };
2562     $right = $self->deparse_binop_right($op, $right, $prec);
2563     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2564 }
2565
2566 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2567 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2568 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2569 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2570 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2571 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2572 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2573 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2574 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2575 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2576 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2577
2578 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2579 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2580 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2581 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2582 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2583
2584 sub pp_eq { binop(@_, "==", 14) }
2585 sub pp_ne { binop(@_, "!=", 14) }
2586 sub pp_lt { binop(@_, "<", 15) }
2587 sub pp_gt { binop(@_, ">", 15) }
2588 sub pp_ge { binop(@_, ">=", 15) }
2589 sub pp_le { binop(@_, "<=", 15) }
2590 sub pp_ncmp { binop(@_, "<=>", 14) }
2591 sub pp_i_eq { binop(@_, "==", 14) }
2592 sub pp_i_ne { binop(@_, "!=", 14) }
2593 sub pp_i_lt { binop(@_, "<", 15) }
2594 sub pp_i_gt { binop(@_, ">", 15) }
2595 sub pp_i_ge { binop(@_, ">=", 15) }
2596 sub pp_i_le { binop(@_, "<=", 15) }
2597 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2598
2599 sub pp_seq { binop(@_, "eq", 14) }
2600 sub pp_sne { binop(@_, "ne", 14) }
2601 sub pp_slt { binop(@_, "lt", 15) }
2602 sub pp_sgt { binop(@_, "gt", 15) }
2603 sub pp_sge { binop(@_, "ge", 15) }
2604 sub pp_sle { binop(@_, "le", 15) }
2605 sub pp_scmp { binop(@_, "cmp", 14) }
2606
2607 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2608 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2609
2610 sub pp_smartmatch {
2611     my ($self, $op, $cx) = @_;
2612     if ($op->flags & OPf_SPECIAL) {
2613         return $self->deparse($op->last, $cx);
2614     }
2615     else {
2616         binop(@_, "~~", 14);
2617     }
2618 }
2619
2620 # '.' is special because concats-of-concats are optimized to save copying
2621 # by making all but the first concat stacked. The effect is as if the
2622 # programmer had written '($a . $b) .= $c', except legal.
2623 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2624 sub real_concat {
2625     my $self = shift;
2626     my($op, $cx) = @_;
2627     my $left = $op->first;
2628     my $right = $op->last;
2629     my $eq = "";
2630     my $prec = 18;
2631     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2632         $eq = "=";
2633         $prec = 7;
2634     }
2635     $left = $self->deparse_binop_left($op, $left, $prec);
2636     $right = $self->deparse_binop_right($op, $right, $prec);
2637     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2638 }
2639
2640 sub pp_repeat { maybe_targmy(@_, \&repeat) }
2641
2642 # 'x' is weird when the left arg is a list
2643 sub repeat {
2644     my $self = shift;
2645     my($op, $cx) = @_;
2646     my $left = $op->first;
2647     my $right = $op->last;
2648     my $eq = "";
2649     my $prec = 19;
2650     if ($op->flags & OPf_STACKED) {
2651         $eq = "=";
2652         $prec = 7;
2653     }
2654     if (null($right)) { # list repeat; count is inside left-side ex-list
2655                         # in 5.21.5 and earlier
2656         my $kid = $left->first->sibling; # skip pushmark
2657         my @exprs;
2658         for (; !null($kid->sibling); $kid = $kid->sibling) {
2659             push @exprs, $self->deparse($kid, 6);
2660         }
2661         $right = $kid;
2662         $left = "(" . join(", ", @exprs). ")";
2663     } else {
2664         my $dolist = $op->private & OPpREPEAT_DOLIST;
2665         $left = $self->deparse_binop_left($op, $left, $dolist ? 1 : $prec);
2666         if ($dolist) {
2667             $left = "($left)";
2668         }
2669     }
2670     $right = $self->deparse_binop_right($op, $right, $prec);
2671     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2672 }
2673
2674 sub range {
2675     my $self = shift;
2676     my ($op, $cx, $type) = @_;
2677     my $left = $op->first;
2678     my $right = $left->sibling;
2679     $left = $self->deparse($left, 9);
2680     $right = $self->deparse($right, 9);
2681     return $self->maybe_parens("$left $type $right", $cx, 9);
2682 }
2683
2684 sub pp_flop {
2685     my $self = shift;
2686     my($op, $cx) = @_;
2687     my $flip = $op->first;
2688     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2689     return $self->range($flip->first, $cx, $type);
2690 }
2691
2692 # one-line while/until is handled in pp_leave
2693
2694 sub logop {
2695     my $self = shift;
2696     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2697     my $left = $op->first;
2698     my $right = $op->first->sibling;
2699     $blockname &&= $self->keyword($blockname);
2700     if ($cx < 1 and is_scope($right) and $blockname
2701         and $self->{'expand'} < 7)
2702     { # if ($a) {$b}
2703         $left = $self->deparse($left, 1);
2704         $right = $self->deparse($right, 0);
2705         return "$blockname ($left) {\n\t$right\n\b}\cK";
2706     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2707              and $self->{'expand'} < 7) { # $b if $a
2708         $right = $self->deparse($right, 1);
2709         $left = $self->deparse($left, 1);
2710         return "$right $blockname $left";
2711     } elsif ($cx > $lowprec and $highop) { # $a && $b
2712         $left = $self->deparse_binop_left($op, $left, $highprec);
2713         $right = $self->deparse_binop_right($op, $right, $highprec);
2714         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2715     } else { # $a and $b
2716         $left = $self->deparse_binop_left($op, $left, $lowprec);
2717         $right = $self->deparse_binop_right($op, $right, $lowprec);
2718         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2719     }
2720 }
2721
2722 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2723 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2724 sub pp_dor { logop(@_, "//", 10) }
2725
2726 # xor is syntactically a logop, but it's really a binop (contrary to
2727 # old versions of opcode.pl). Syntax is what matters here.
2728 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2729
2730 sub logassignop {
2731     my $self = shift;
2732     my ($op, $cx, $opname) = @_;
2733     my $left = $op->first;
2734     my $right = $op->first->sibling->first; # skip sassign
2735     $left = $self->deparse($left, 7);
2736     $right = $self->deparse($right, 7);
2737     return $self->maybe_parens("$left $opname $right", $cx, 7);
2738 }
2739
2740 sub pp_andassign { logassignop(@_, "&&=") }
2741 sub pp_orassign  { logassignop(@_, "||=") }
2742 sub pp_dorassign { logassignop(@_, "//=") }
2743
2744 sub rv2gv_or_string {
2745     my($self,$op) = @_;
2746     if ($op->name eq "gv") { # could be open("open") or open("###")
2747         my($name,$quoted) =
2748             $self->stash_variable_name("", $self->gv_or_padgv($op));
2749         $quoted ? $name : "*$name";
2750     }
2751     else {
2752         $self->deparse($op, 6);
2753     }
2754 }
2755
2756 sub listop {
2757     my $self = shift;
2758     my($op, $cx, $name, $kid, $nollafr) = @_;
2759     my(@exprs);
2760     my $parens = ($cx >= 5) || $self->{'parens'};
2761     $kid ||= $op->first->sibling;
2762     # If there are no arguments, add final parentheses (or parenthesize the
2763     # whole thing if the llafr does not apply) to account for cases like
2764     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
2765     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
2766     if (null $kid) {
2767         return $nollafr
2768                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
2769                 : $self->keyword($name) . '()' x (7 < $cx);
2770     }
2771     my $first;
2772     my $fullname = $self->keyword($name);
2773     my $proto = prototype("CORE::$name");
2774     if (
2775          (     (defined $proto && $proto =~ /^;?\*/)
2776             || $name eq 'select' # select(F) doesn't have a proto
2777          )
2778          && $kid->name eq "rv2gv"
2779          && !($kid->private & OPpLVAL_INTRO)
2780     ) {
2781         $first = $self->rv2gv_or_string($kid->first);
2782     }
2783     else {
2784         $first = $self->deparse($kid, 6);
2785     }
2786     if ($name eq "chmod" && $first =~ /^\d+$/) {
2787         $first = sprintf("%#o", $first);
2788     }
2789     $first = "+$first"
2790         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
2791     push @exprs, $first;
2792     $kid = $kid->sibling;
2793     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
2794          && !($kid->private & OPpLVAL_INTRO)) {
2795         push @exprs, $first = $self->rv2gv_or_string($kid->first);
2796         $kid = $kid->sibling;
2797     }
2798     for (; !null($kid); $kid = $kid->sibling) {
2799         push @exprs, $self->deparse($kid, 6);
2800     }
2801     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2802         return "$exprs[0] = $fullname"
2803                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2804     }
2805     if ($name =~ /^(system|exec)$/
2806         && ($op->flags & OPf_STACKED)
2807         && @exprs > 1)
2808     {
2809         # handle the "system prog a1,a2,.." form
2810         my $prog = shift @exprs;
2811         $exprs[0] = "$prog $exprs[0]";
2812     }
2813
2814     if ($parens && $nollafr) {
2815         return "($fullname " . join(", ", @exprs) . ")";
2816     } elsif ($parens) {
2817         return "$fullname(" . join(", ", @exprs) . ")";
2818     } else {
2819         return "$fullname " . join(", ", @exprs);
2820     }
2821 }
2822
2823 sub pp_bless { listop(@_, "bless") }
2824 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2825 sub pp_substr {
2826     my ($self,$op,$cx) = @_;
2827     if ($op->private & OPpSUBSTR_REPL_FIRST) {
2828         return
2829            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
2830          . " = "
2831          . $self->deparse($op->first->sibling, 7);
2832     }
2833     maybe_local(@_, listop(@_, "substr"))
2834 }
2835 sub pp_vec { maybe_targmy(@_, \&maybe_local, listop(@_, "vec")) }
2836 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2837 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2838 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2839 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2840 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2841 sub pp_unpack { listop(@_, "unpack") }
2842 sub pp_pack { listop(@_, "pack") }
2843 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2844 sub pp_splice { listop(@_, "splice") }
2845 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2846 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2847 sub pp_reverse { listop(@_, "reverse") }
2848 sub pp_warn { listop(@_, "warn") }
2849 sub pp_die { listop(@_, "die") }
2850 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
2851 sub pp_open { listop(@_, "open") }
2852 sub pp_pipe_op { listop(@_, "pipe") }
2853 sub pp_tie { listop(@_, "tie") }
2854 sub pp_binmode { listop(@_, "binmode") }
2855 sub pp_dbmopen { listop(@_, "dbmopen") }
2856 sub pp_sselect { listop(@_, "select") }
2857 sub pp_select { listop(@_, "select") }
2858 sub pp_read { listop(@_, "read") }
2859 sub pp_sysopen { listop(@_, "sysopen") }
2860 sub pp_sysseek { listop(@_, "sysseek") }
2861 sub pp_sysread { listop(@_, "sysread") }
2862 sub pp_syswrite { listop(@_, "syswrite") }
2863 sub pp_send { listop(@_, "send") }
2864 sub pp_recv { listop(@_, "recv") }
2865 sub pp_seek { listop(@_, "seek") }
2866 sub pp_fcntl { listop(@_, "fcntl") }
2867 sub pp_ioctl { listop(@_, "ioctl") }
2868 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2869 sub pp_socket { listop(@_, "socket") }
2870 sub pp_sockpair { listop(@_, "socketpair") }
2871 sub pp_bind { listop(@_, "bind") }
2872 sub pp_connect { listop(@_, "connect") }
2873 sub pp_listen { listop(@_, "listen") }
2874 sub pp_accept { listop(@_, "accept") }
2875 sub pp_shutdown { listop(@_, "shutdown") }
2876 sub pp_gsockopt { listop(@_, "getsockopt") }
2877 sub pp_ssockopt { listop(@_, "setsockopt") }
2878 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2879 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2880 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2881 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2882 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2883 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2884 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2885 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2886 sub pp_open_dir { listop(@_, "opendir") }
2887 sub pp_seekdir { listop(@_, "seekdir") }
2888 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2889 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2890 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2891 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2892 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2893 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2894 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2895 sub pp_shmget { listop(@_, "shmget") }
2896 sub pp_shmctl { listop(@_, "shmctl") }
2897 sub pp_shmread { listop(@_, "shmread") }
2898 sub pp_shmwrite { listop(@_, "shmwrite") }
2899 sub pp_msgget { listop(@_, "msgget") }
2900 sub pp_msgctl { listop(@_, "msgctl") }
2901 sub pp_msgsnd { listop(@_, "msgsnd") }
2902 sub pp_msgrcv { listop(@_, "msgrcv") }
2903 sub pp_semget { listop(@_, "semget") }
2904 sub pp_semctl { listop(@_, "semctl") }
2905 sub pp_semop { listop(@_, "semop") }
2906 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2907 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2908 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2909 sub pp_gsbyname { listop(@_, "getservbyname") }
2910 sub pp_gsbyport { listop(@_, "getservbyport") }
2911 sub pp_syscall { listop(@_, "syscall") }
2912
2913 sub pp_glob {
2914     my $self = shift;
2915     my($op, $cx) = @_;
2916     my $kid = $op->first->sibling;  # skip pushmark
2917     my $keyword =
2918         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2919     my $text;
2920     if ($keyword =~ /^CORE::/
2921         or $kid->name ne 'const'
2922         or ($text = $self->dq($kid))
2923              =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2924         or $text =~ /[<>]/) {
2925         $text = $self->deparse($kid);
2926         return $cx >= 5 || $self->{'parens'}
2927             ? "$keyword($text)"
2928             : "$keyword $text";
2929     } else {
2930         return '<' . $text . '>';
2931     }
2932 }
2933
2934 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2935 # be a filehandle. This could probably be better fixed in the core
2936 # by moving the GV lookup into ck_truc.
2937
2938 sub pp_truncate {
2939     my $self = shift;
2940     my($op, $cx) = @_;
2941     my(@exprs);
2942     my $parens = ($cx >= 5) || $self->{'parens'};
2943     my $kid = $op->first->sibling;
2944     my $fh;
2945     if ($op->flags & OPf_SPECIAL) {
2946         # $kid is an OP_CONST
2947         $fh = $self->const_sv($kid)->PV;
2948     } else {
2949         $fh = $self->deparse($kid, 6);
2950         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2951     }
2952     my $len = $self->deparse($kid->sibling, 6);
2953     my $name = $self->keyword('truncate');
2954     if ($parens) {
2955         return "$name($fh, $len)";
2956     } else {
2957         return "$name $fh, $len";
2958     }
2959 }
2960
2961 sub indirop {
2962     my $self = shift;
2963     my($op, $cx, $name) = @_;
2964     my($expr, @exprs);
2965     my $firstkid = my $kid = $op->first->sibling;
2966     my $indir = "";
2967     if ($op->flags & OPf_STACKED) {
2968         $indir = $kid;
2969         $indir = $indir->first; # skip rv2gv
2970         if (is_scope($indir)) {
2971             $indir = "{" . $self->deparse($indir, 0) . "}";
2972             $indir = "{;}" if $indir eq "{}";
2973         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2974             $indir = $self->const_sv($indir)->PV;
2975         } else {
2976             $indir = $self->deparse($indir, 24);
2977         }
2978         $indir = $indir . " ";
2979         $kid = $kid->sibling;
2980     }
2981     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2982         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2983                                                   : '{$a <=> $b} ';
2984     }
2985     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2986         $indir = '{$b cmp $a} ';
2987     }
2988     for (; !null($kid); $kid = $kid->sibling) {
2989         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2990         push @exprs, $expr;
2991     }
2992     my $name2;
2993     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2994         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2995     }
2996     else { $name2 = $self->keyword($name) }
2997     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2998         return "$exprs[0] = $name2 $indir $exprs[0]";
2999     }
3000
3001     my $args = $indir . join(", ", @exprs);
3002     if ($indir ne "" && $name eq "sort") {
3003         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
3004         # give bareword warnings in that case. Therefore if context
3005         # requires, we'll put parens around the outside "(sort f 1, 2,
3006         # 3)". Unfortunately, we'll currently think the parens are
3007         # necessary more often that they really are, because we don't
3008         # distinguish which side of an assignment we're on.
3009         if ($cx >= 5) {
3010             return "($name2 $args)";
3011         } else {
3012             return "$name2 $args";
3013         }
3014     } elsif (
3015         !$indir && $name eq "sort"
3016       && !null($op->first->sibling)
3017       && $op->first->sibling->name eq 'entersub'
3018     ) {
3019         # We cannot say sort foo(bar), as foo will be interpreted as a
3020         # comparison routine.  We have to say sort(...) in that case.
3021         return "$name2($args)";
3022     } else {
3023         return $self->maybe_parens_func($name2, $args, $cx, 5);
3024     }
3025
3026 }
3027
3028 sub pp_prtf { indirop(@_, "printf") }
3029 sub pp_print { indirop(@_, "print") }
3030 sub pp_say  { indirop(@_, "say") }
3031 sub pp_sort { indirop(@_, "sort") }
3032
3033 sub mapop {
3034     my $self = shift;
3035     my($op, $cx, $name) = @_;
3036     my($expr, @exprs);
3037     my $kid = $op->first; # this is the (map|grep)start
3038     $kid = $kid->first->sibling; # skip a pushmark
3039     my $code = $kid->first; # skip a null
3040     if (is_scope $code) {
3041         $code = "{" . $self->deparse($code, 0) . "} ";
3042     } else {
3043         $code = $self->deparse($code, 24);
3044         $code .= ", " if !null($kid->sibling);
3045     }
3046     $kid = $kid->sibling;
3047     for (; !null($kid); $kid = $kid->sibling) {
3048         $expr = $self->deparse($kid, 6);
3049         push @exprs, $expr if defined $expr;
3050     }
3051     return $self->maybe_parens_func($self->keyword($name),
3052                                     $code . join(", ", @exprs), $cx, 5);
3053 }
3054
3055 sub pp_mapwhile { mapop(@_, "map") }
3056 sub pp_grepwhile { mapop(@_, "grep") }
3057 sub pp_mapstart { baseop(@_, "map") }
3058 sub pp_grepstart { baseop(@_, "grep") }
3059
3060 my %uses_intro;
3061 BEGIN {
3062     @uses_intro{
3063         eval { require B::Op_private }
3064           ? @{$B::Op_private::ops_using{OPpLVAL_INTRO}}
3065           : qw(gvsv rv2sv rv2hv rv2gv rv2av aelem helem aslice
3066                hslice delete padsv padav padhv enteriter entersub padrange
3067                pushmark cond_expr refassign list)
3068     } = ();
3069     delete @uses_intro{qw( lvref lvrefslice lvavref )};
3070 }
3071
3072 sub pp_list {
3073     my $self = shift;
3074     my($op, $cx) = @_;
3075     my($expr, @exprs);
3076     my $kid = $op->first->sibling; # skip pushmark
3077     return '' if class($kid) eq 'NULL';
3078     my $lop;
3079     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
3080     my $type;
3081     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3082         my $lopname = $lop->name;
3083         my $loppriv = $lop->private;
3084         my $newtype;
3085         if ($lopname =~ /^pad[ash]v$/ && $loppriv & OPpLVAL_INTRO) {
3086             if ($loppriv & OPpPAD_STATE) { # state()
3087                 ($local = "", last) if $local !~ /^(?:either|state)$/;
3088                 $local = "state";
3089             } else { # my()
3090                 ($local = "", last) if $local !~ /^(?:either|my)$/;
3091                 $local = "my";
3092             }
3093             my $padname = $self->padname_sv($lop->targ);
3094             if ($padname->FLAGS & SVpad_TYPED) {
3095                 $newtype = $padname->SvSTASH->NAME;
3096             }
3097         } elsif ($lopname =~ /^(?:gv|rv2)([ash])v$/
3098                         && $loppriv & OPpOUR_INTRO
3099                 or $lopname eq "null" && $lop->first->name eq "gvsv"
3100                         && $lop->first->private & OPpOUR_INTRO) { # our()
3101             my $newlocal = "local " x !!($loppriv & OPpLVAL_INTRO) . "our";
3102             ($local = "", last)
3103                 if $local ne 'either' && $local ne $newlocal;
3104             $local = $newlocal;
3105             my $funny = !$1 || $1 eq 's' ? '$' : $1 eq 'a' ? '@' : '%';
3106             if (my $t = $self->find_our_type(
3107                     $funny . $self->gv_or_padgv($lop->first)->NAME
3108                )) {
3109                 $newtype = $t;
3110             }
3111         } elsif ($lopname ne 'undef'
3112            and    !($loppriv & OPpLVAL_INTRO)
3113                || !exists $uses_intro{$lopname eq 'null'
3114                                         ? substr B::ppname($lop->targ), 3
3115                                         : $lopname})
3116         {
3117             $local = ""; # or not
3118             last;
3119         } elsif ($lopname ne "undef")
3120         {
3121             # local()
3122             ($local = "", last) if $local !~ /^(?:either|local)$/;
3123             $local = "local";
3124         }
3125         if (defined $type && defined $newtype && $newtype ne $type) {
3126             $local = '';
3127             last;
3128         }
3129         $type = $newtype;
3130     }
3131     $local = "" if $local eq "either"; # no point if it's all undefs
3132     $local &&= join ' ', map $self->keyword($_), split / /, $local;
3133     $local .= " $type " if $local && length $type;
3134     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
3135     for (; !null($kid); $kid = $kid->sibling) {
3136         if ($local) {
3137             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3138                 $lop = $kid->first;
3139             } else {
3140                 $lop = $kid;
3141             }
3142             $self->{'avoid_local'}{$$lop}++;
3143             $expr = $self->deparse($kid, 6);
3144             delete $self->{'avoid_local'}{$$lop};
3145         } else {
3146             $expr = $self->deparse($kid, 6);
3147         }
3148         push @exprs, $expr;
3149     }
3150     if ($local) {
3151         return "$local(" . join(", ", @exprs) . ")";
3152     } else {
3153         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3154     }
3155 }
3156
3157 sub is_ifelse_cont {
3158     my $op = shift;
3159     return ($op->name eq "null" and class($op) eq "UNOP"
3160             and $op->first->name =~ /^(and|cond_expr)$/
3161             and is_scope($op->first->first->sibling));
3162 }
3163
3164 sub pp_cond_expr {
3165     my $self = shift;
3166     my($op, $cx) = @_;
3167     my $cond = $op->first;
3168     my $true = $cond->sibling;
3169     my $false = $true->sibling;
3170     my $cuddle = $self->{'cuddle'};
3171     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3172             (is_scope($false) || is_ifelse_cont($false))
3173             and $self->{'expand'} < 7) {
3174         $cond = $self->deparse($cond, 8);
3175         $true = $self->deparse($true, 6);
3176         $false = $self->deparse($false, 8);
3177         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3178     }
3179
3180     $cond = $self->deparse($cond, 1);
3181     $true = $self->deparse($true, 0);
3182     my $head = $self->keyword("if") . " ($cond) {\n\t$true\n\b}";
3183     my @elsifs;
3184     my $elsif;
3185     while (!null($false) and is_ifelse_cont($false)) {
3186         my $newop = $false->first;
3187         my $newcond = $newop->first;
3188         my $newtrue = $newcond->sibling;
3189         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3190         if ($newcond->name eq "lineseq")
3191         {
3192             # lineseq to ensure correct line numbers in elsif()
3193             # Bug #37302 fixed by change #33710.
3194             $newcond = $newcond->first->sibling;
3195         }
3196         $newcond = $self->deparse($newcond, 1);
3197         $newtrue = $self->deparse($newtrue, 0);
3198         $elsif ||= $self->keyword("elsif");
3199         push @elsifs, "$elsif ($newcond) {\n\t$newtrue\n\b}";
3200     }
3201     if (!null($false)) {
3202         $false = $cuddle . $self->keyword("else") . " {\n\t" .
3203           $self->deparse($false, 0) . "\n\b}\cK";
3204     } else {
3205         $false = "\cK";
3206     }
3207     return $head . join($cuddle, "", @elsifs) . $false;
3208 }
3209
3210 sub pp_once {
3211     my ($self, $op, $cx) = @_;
3212     my $cond = $op->first;
3213     my $true = $cond->sibling;
3214
3215     my $ret = $self->deparse($true, $cx);
3216     $ret =~ s/^(\(?)\$/$1 . $self->keyword("state") . ' $'/e;
3217     $ret;
3218 }
3219
3220 sub loop_common {
3221     my $self = shift;
3222     my($op, $cx, $init) = @_;
3223     my $enter = $op->first;
3224     my $kid = $enter->sibling;
3225     local(@$self{qw'curstash warnings hints hinthash'})
3226                 = @$self{qw'curstash warnings hints hinthash'};
3227     my $head = "";
3228     my $bare = 0;
3229     my $body;
3230     my $cond = undef;
3231     my $name;
3232     if ($kid->name eq "lineseq") { # bare or infinite loop
3233         if ($kid->last->name eq "unstack") { # infinite
3234             $head = "while (1) "; # Can't use for(;;) if there's a continue
3235             $cond = "";
3236         } else {
3237             $bare = 1;
3238         }
3239         $body = $kid;
3240     } elsif ($enter->name eq "enteriter") { # foreach
3241         my $ary = $enter->first->sibling; # first was pushmark
3242         my $var = $ary->sibling;
3243         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3244             # "reverse" was optimised away
3245             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3246         } elsif ($enter->flags & OPf_STACKED
3247             and not null $ary->first->sibling->sibling)
3248         {
3249             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3250               $self->deparse($ary->first->sibling->sibling, 9);
3251         } else {
3252             $ary = $self->deparse($ary, 1);
3253         }
3254         if (null $var) {
3255             $var = $self->pp_padsv($enter, 1, 1);
3256         } elsif ($var->name eq "rv2gv") {
3257             $var = $self->pp_rv2sv($var, 1);
3258             if ($enter->private & OPpOUR_INTRO) {
3259                 # our declarations don't have package names
3260                 $var =~ s/^(.).*::/$1/;
3261                 $var = "our $var";
3262             }
3263         } elsif ($var->name eq "gv") {
3264             $var = "\$" . $self->deparse($var, 1);
3265         } else {
3266             $var = $self->deparse($var, 1);
3267         }
3268         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3269         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3270             confess unless $var eq '$_';
3271             $body = $body->first;
3272             return $self->deparse($body, 2) . " "
3273                  . $self->keyword("foreach") . " ($ary)";
3274         }
3275         $head = "foreach $var ($ary) ";
3276     } elsif ($kid->name eq "null") { # while/until
3277         $kid = $kid->first;
3278         $name = {"and" => "while", "or" => "until"}->{$kid->name};
3279         $cond = $kid->first;
3280         $body = $kid->first->sibling;
3281     } elsif ($kid->name eq "stub") { # bare and empty
3282         return "{;}"; # {} could be a hashref
3283     }
3284     # If there isn't a continue block, then the next pointer for the loop
3285     # will point to the unstack, which is kid's last child, except
3286     # in a bare loop, when it will point to the leaveloop. When neither of
3287     # these conditions hold, then the second-to-last child is the continue
3288     # block (or the last in a bare loop).
3289     my $cont_start = $enter->nextop;
3290     my $cont;
3291     my $precond;
3292     my $postcond;
3293     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3294         if ($bare) {
3295             $cont = $body->last;
3296         } else {
3297             $cont = $body->first;
3298             while (!null($cont->sibling->sibling)) {
3299                 $cont = $cont->sibling;
3300             }
3301         }
3302         my $state = $body->first;
3303         my $cuddle = $self->{'cuddle'};
3304         my @states;
3305         for (; $$state != $$cont; $state = $state->sibling) {
3306             push @states, $state;
3307         }
3308         $body = $self->lineseq(undef, 0, @states);
3309         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3310             $precond = "for ($init; ";
3311             $postcond = "; " . $self->deparse($cont, 1) .") ";
3312             $cont = "\cK";
3313         } else {
3314             $cont = $cuddle . "continue {\n\t" .
3315               $self->deparse($cont, 0) . "\n\b}\cK";
3316         }
3317     } else {
3318         return "" if !defined $body;
3319         if (length $init) {
3320             $precond = "for ($init; ";
3321             $postcond = ";) ";
3322         }
3323         $cont = "\cK";
3324         $body = $self->deparse($body, 0);
3325     }
3326     if ($precond) { # for(;;)
3327         $cond &&= $name eq 'until'
3328                     ? listop($self, undef, 1, "not", $cond->first)
3329                     : $self->deparse($cond, 1);
3330         $head = "$precond$cond$postcond";
3331     }
3332     if ($name && !$head) {
3333         ref $cond and $cond = $self->deparse($cond, 1);
3334         $head = "$name ($cond) ";
3335     }
3336     $head =~ s/^(for(?:each)?|while|until)/$self->keyword($1)/e;
3337     $body =~ s/;?$/;\n/;
3338
3339     return $head . "{\n\t" . $body . "\b}" . $cont;
3340 }
3341
3342 sub pp_leaveloop { shift->loop_common(@_, "") }
3343
3344 sub for_loop {
3345     my $self = shift;
3346     my($op, $cx) = @_;
3347     my $init = $self->deparse($op, 1);
3348     my $s = $op->sibling;
3349     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3350     return $self->loop_common($ll, $cx, $init);
3351 }
3352
3353 sub pp_leavetry {
3354     my $self = shift;
3355     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3356 }
3357
3358 sub _op_is_or_was {
3359   my ($op, $expect_type) = @_;
3360   my $type = $op->type;
3361   return($type == $expect_type
3362          || ($type == OP_NULL && $op->targ == $expect_type));
3363 }
3364
3365 sub pp_null {
3366     my $self = shift;
3367     my($op, $cx) = @_;
3368     if (class($op) eq "OP") {
3369         # old value is lost
3370         return $self->{'ex_const'} if $op->targ == OP_CONST;
3371     } elsif ($op->first->name eq 'pushmark'
3372              or $op->first->name eq 'null'
3373                 && $op->first->targ == OP_PUSHMARK
3374                 && _op_is_or_was($op, OP_LIST)) {
3375         return $self->pp_list($op, $cx);
3376     } elsif ($op->first->name eq "enter") {
3377         return $self->pp_leave($op, $cx);
3378     } elsif ($op->first->name eq "leave") {
3379         return $self->pp_leave($op->first, $cx);
3380     } elsif ($op->first->name eq "scope") {
3381         return $self->pp_scope($op->first, $cx);
3382     } elsif ($op->targ == OP_STRINGIFY) {
3383         return $self->dquote($op, $cx);
3384     } elsif ($op->targ == OP_GLOB) {
3385         return $self->pp_glob(
3386                  $op->first    # entersub
3387                     ->first    # ex-list
3388                     ->first    # pushmark
3389                     ->sibling, # glob
3390                  $cx
3391                );
3392     } elsif (!null($op->first->sibling) and
3393              $op->first->sibling->name eq "readline" and
3394              $op->first->sibling->flags & OPf_STACKED) {
3395         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
3396                                    . $self->deparse($op->first->sibling, 7),
3397                                    $cx, 7);
3398     } elsif (!null($op->first->sibling) and
3399              $op->first->sibling->name eq "trans" and
3400              $op->first->sibling->flags & OPf_STACKED) {
3401         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
3402                                    . $self->deparse($op->first->sibling, 20),
3403                                    $cx, 20);
3404     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
3405         return ($self->lex_in_scope("&do") ? "CORE::do" : "do")
3406              . " {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
3407     } elsif (!null($op->first->sibling) and
3408              $op->first->sibling->name eq "null" and
3409              class($op->first->sibling) eq "UNOP" and
3410              $op->first->sibling->first->flags & OPf_STACKED and
3411              $op->first->sibling->first->name eq "rcatline") {
3412         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
3413                                    . $self->deparse($op->first->sibling, 18),
3414                                    $cx, 18);
3415     } else {
3416         return $self->deparse($op->first, $cx);
3417     }
3418 }
3419
3420 sub padname {
3421     my $self = shift;
3422     my $targ = shift;
3423     return $self->padname_sv($targ)->PVX;
3424 }
3425
3426 sub padany {
3427     my $self = shift;
3428     my $op = shift;
3429     return substr($self->padname($op->targ), 1); # skip $/@/%
3430 }
3431
3432 sub pp_padsv {
3433     my $self = shift;
3434     my($op, $cx, $forbid_parens) = @_;
3435     my $targ = $op->targ;
3436     return $self->maybe_my($op, $cx, $self->padname($targ),
3437                            $self->padname_sv($targ),
3438                            $forbid_parens);
3439 }
3440
3441 sub pp_padav { pp_padsv(@_) }
3442 sub pp_padhv { pp_padsv(@_) }
3443
3444 sub gv_or_padgv {
3445     my $self = shift;
3446     my $op = shift;
3447     if (class($op) eq "PADOP") {
3448         return $self->padval($op->padix);
3449     } else { # class($op) eq "SVOP"
3450         return $op->gv;
3451     }
3452 }
3453
3454 sub pp_gvsv {
3455     my $self = shift;
3456     my($op, $cx) = @_;
3457     my $gv = $self->gv_or_padgv($op);
3458     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
3459                                  $self->gv_name($gv), $cx));
3460 }
3461
3462 sub pp_gv {
3463     my $self = shift;
3464     my($op, $cx) = @_;
3465     my $gv = $self->gv_or_padgv($op);
3466     return $self->gv_name($gv);
3467 }
3468
3469 sub pp_aelemfast_lex {
3470     my $self = shift;
3471     my($op, $cx) = @_;
3472     my $name = $self->padname($op->targ);
3473     $name =~ s/^@/\$/;
3474     my $i = $op->private;
3475     $i -= 256 if $i > 127;
3476     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
3477 }
3478
3479 sub pp_aelemfast {
3480     my $self = shift;
3481     my($op, $cx) = @_;
3482     # optimised PADAV, pre 5.15
3483     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
3484
3485     my $gv = $self->gv_or_padgv($op);
3486     my($name,$quoted) = $self->stash_variable_name('@',$gv);
3487     $name = $quoted ? "$name->" : '$' . $name;
3488     my $i = $op->private;
3489     $i -= 256 if $i > 127;
3490     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
3491 }
3492
3493 sub rv2x {
3494     my $self = shift;
3495     my($op, $cx, $type) = @_;
3496
3497     if (class($op) eq 'NULL' || !$op->can("first")) {
3498         carp("Unexpected op in pp_rv2x");
3499         return 'XXX';
3500     }
3501     my $kid = $op->first;
3502     if ($kid->name eq "gv") {
3503         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
3504     } elsif (is_scalar $kid) {
3505         my $str = $self->deparse($kid, 0);
3506         if ($str =~ /^\$([^\w\d])\z/) {
3507             # "$$+" isn't a legal way to write the scalar dereference
3508             # of $+, since the lexer can't tell you aren't trying to
3509             # do something like "$$ + 1" to get one more than your
3510             # PID. Either "${$+}" or "$${+}" are workable
3511             # disambiguations, but if the programmer did the former,
3512             # they'd be in the "else" clause below rather than here.
3513             # It's not clear if this should somehow be unified with
3514             # the code in dq and re_dq that also adds lexer
3515             # disambiguation braces.
3516             $str = '$' . "{$1}"; #'
3517         }
3518         return $type . $str;
3519     } else {
3520         return $type . "{" . $self->deparse($kid, 0) . "}";
3521     }
3522 }
3523
3524 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3525 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3526 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3527
3528 # skip rv2av
3529 sub pp_av2arylen {
3530     my $self = shift;
3531     my($op, $cx) = @_;
3532     if ($op->first->name eq "padav") {
3533         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3534     } else {
3535         return $self->maybe_local($op, $cx,
3536                                   $self->rv2x($op->first, $cx, '$#'));
3537     }
3538 }
3539
3540 # skip down to the old, ex-rv2cv
3541 sub pp_rv2cv {
3542     my ($self, $op, $cx) = @_;
3543     if (!null($op->first) && $op->first->name eq 'null' &&
3544         $op->first->targ == OP_LIST)
3545     {
3546         return $self->rv2x($op->first->first->sibling, $cx, "&")
3547     }
3548     else {
3549         return $self->rv2x($op, $cx, "")
3550     }
3551 }
3552
3553 sub list_const {
3554     my $self = shift;
3555     my($cx, @list) = @_;
3556     my @a = map $self->const($_, 6), @list;
3557     if (@a == 0) {
3558         return "()";
3559     } elsif (@a == 1) {
3560         return $a[0];
3561     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3562         # collapse (-1,0,1,2) into (-1..2)
3563         my ($s, $e) = @a[0,-1];
3564         my $i = $s;
3565         return $self->maybe_parens("$s..$e", $cx, 9)
3566           unless grep $i++ != $_, @a;
3567     }
3568     return $self->maybe_parens(join(", ", @a), $cx, 6);
3569 }
3570
3571 sub pp_rv2av {
3572     my $self = shift;
3573     my($op, $cx) = @_;
3574     my $kid = $op->first;
3575     if ($kid->name eq "const") { # constant list
3576         my $av = $self->const_sv($kid);
3577         return $self->list_const($cx, $av->ARRAY);
3578     } else {
3579         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3580     }
3581  }
3582
3583 sub is_subscriptable {
3584     my $op = shift;
3585     if ($op->name =~ /^[ahg]elem/) {
3586         return 1;
3587     } elsif ($op->name eq "entersub") {
3588         my $kid = $op->first;
3589         return 0 unless null $kid->sibling;
3590         $kid = $kid->first;
3591         $kid = $kid->sibling until null $kid->sibling;
3592         return 0 if is_scope($kid);
3593         $kid = $kid->first;
3594         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
3595         return 0 if is_scalar($kid);
3596         return is_subscriptable($kid);  
3597     } else {
3598         return 0;
3599     }
3600 }
3601
3602 sub elem_or_slice_array_name
3603 {
3604     my $self = shift;
3605     my ($array, $left, $padname, $allow_arrow) = @_;
3606
3607     if ($array->name eq $padname) {
3608         return $self->padany($array);
3609     } elsif (is_scope($array)) { # ${expr}[0]
3610         return "{" . $self->deparse($array, 0) . "}";
3611     } elsif ($array->name eq "gv") {
3612         ($array, my $quoted) =
3613             $self->stash_variable_name(
3614                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
3615             );
3616         if (!$allow_arrow && $quoted) {
3617             # This cannot happen.
3618             die "Invalid variable name $array for slice";
3619         }
3620         return $quoted ? "$array->" : $array;
3621     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3622         return $self->deparse($array, 24);
3623     } else {
3624         return undef;
3625     }
3626 }
3627
3628 sub elem_or_slice_single_index
3629 {
3630     my $self = shift;
3631     my ($idx) = @_;
3632
3633     $idx = $self->deparse($idx, 1);
3634
3635     # Outer parens in an array index will confuse perl
3636     # if we're interpolating in a regular expression, i.e.
3637     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3638     #
3639     # If $self->{parens}, then an initial '(' will
3640     # definitely be paired with a final ')'. If
3641     # !$self->{parens}, the misleading parens won't
3642     # have been added in the first place.
3643     #
3644     # [You might think that we could get "(...)...(...)"
3645     # where the initial and final parens do not match
3646     # each other. But we can't, because the above would
3647     # only happen if there's an infix binop between the
3648     # two pairs of parens, and *that* means that the whole
3649     # expression would be parenthesized as well.]
3650     #
3651     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3652
3653     # Hash-element braces will autoquote a bareword inside themselves.
3654     # We need to make sure that C<$hash{warn()}> doesn't come out as
3655     # C<$hash{warn}>, which has a quite different meaning. Currently
3656     # B::Deparse will always quote strings, even if the string was a
3657     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3658     # for constant strings.) So we can cheat slightly here - if we see
3659     # a bareword, we know that it is supposed to be a function call.
3660     #
3661     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3662
3663     return $idx;
3664 }
3665
3666 sub elem {
3667     my $self = shift;
3668     my ($op, $cx, $left, $right, $padname) = @_;
3669     my($array, $idx) = ($op->first, $op->first->sibling);
3670
3671     $idx = $self->elem_or_slice_single_index($idx);
3672
3673     unless ($array->name eq $padname) { # Maybe this has been fixed     
3674         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3675     }
3676     if (my $array_name=$self->elem_or_slice_array_name
3677             ($array, $left, $padname, 1)) {
3678         return ($array_name =~ /->\z/
3679                     ? $array_name
3680                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
3681               . $left . $idx . $right;
3682     } else {
3683         # $x[20][3]{hi} or expr->[20]
3684         my $arrow = is_subscriptable($array) ? "" : "->";
3685         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3686     }
3687
3688 }
3689
3690 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3691 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3692
3693 sub pp_gelem {
3694     my $self = shift;
3695     my($op, $cx) = @_;
3696     my($glob, $part) = ($op->first, $op->last);
3697     $glob = $glob->first; # skip rv2gv
3698     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3699     my $scope = is_scope($glob);
3700     $glob = $self->deparse($glob, 0);
3701     $part = $self->deparse($part, 1);
3702     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3703 }
3704
3705 sub slice {
3706     my $self = shift;
3707     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3708     my $last;
3709     my(@elems, $kid, $array, $list);
3710     if (class($op) eq "LISTOP") {
3711         $last = $op->last;
3712     } else { # ex-hslice inside delete()
3713         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3714         $last = $kid;
3715     }
3716     $array = $last;
3717     $array = $array->first
3718         if $array->name eq $regname or $array->name eq "null";
3719     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3720     $kid = $op->first->sibling; # skip pushmark
3721     if ($kid->name eq "list") {
3722         $kid = $kid->first->sibling; # skip list, pushmark
3723         for (; !null $kid; $kid = $kid->sibling) {
3724             push @elems, $self->deparse($kid, 6);
3725         }
3726         $list = join(", ", @elems);
3727     } else {
3728         $list = $self->elem_or_slice_single_index($kid);
3729     }
3730     my $lead = '@';
3731     $lead = '%' if $op->name =~ /^kv/i;
3732     return $lead . $array . $left . $list . $right;
3733 }
3734
3735 sub pp_aslice   { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3736 sub pp_kvaslice {                 slice(@_, "[", "]", "rv2av", "padav")  }
3737 sub pp_hslice   { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3738 sub pp_kvhslice {                 slice(@_, "{", "}", "rv2hv", "padhv")  }
3739
3740 sub pp_lslice {
3741     my $self = shift;
3742     my($op, $cx) = @_;
3743     my $idx = $op->first;
3744     my $list = $op->last;
3745     my(@elems, $kid);
3746     $list = $self->deparse($list, 1);
3747     $idx = $self->deparse($idx, 1);
3748     return "($list)" . "[$idx]";
3749 }
3750
3751 sub want_scalar {
3752     my $op = shift;
3753     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3754 }
3755
3756 sub want_list {
3757     my $op = shift;
3758     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3759 }
3760
3761 sub _method {
3762     my $self = shift;
3763     my($op, $cx) = @_;
3764     my $kid = $op->first->sibling; # skip pushmark
3765     my($meth, $obj, @exprs);
3766     if ($kid->name eq "list" and want_list $kid) {
3767         # When an indirect object isn't a bareword but the args are in
3768         # parens, the parens aren't part of the method syntax (the LLAFR
3769         # doesn't apply), but they make a list with OPf_PARENS set that
3770         # doesn't get flattened by the append_elem that adds the method,
3771         # making a (object, arg1, arg2, ...) list where the object
3772         # usually is. This can be distinguished from
3773         # '($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3774         # object) because in the later the list is in scalar context
3775         # as the left side of -> always is, while in the former
3776         # the list is in list context as method arguments always are.
3777         # (Good thing there aren't method prototypes!)
3778         $meth = $kid->sibling;
3779         $kid = $kid->first->sibling; # skip pushmark
3780         $obj = $kid;
3781         $kid = $kid->sibling;
3782         for (; not null $kid; $kid = $kid->sibling) {
3783             push @exprs, $kid;
3784         }
3785     } else {
3786         $obj = $kid;
3787         $kid = $kid->sibling;
3788         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3789               $kid = $kid->sibling) {
3790             push @exprs, $kid
3791         }
3792         $meth = $kid;
3793     }
3794
3795     if ($meth->name eq "method_named") {
3796         $meth = $self->meth_sv($meth)->PV;
3797     } else {
3798         $meth = $meth->first;
3799         if ($meth->name eq "const") {
3800             # As of 5.005_58, this case is probably obsoleted by the
3801             # method_named case above
3802             $meth = $self->const_sv($meth)->PV; # needs to be bare
3803         }
3804     }
3805
3806     return { method => $meth, variable_method => ref($meth),
3807              object => $obj, args => \@exprs  },
3808            $cx;
3809 }
3810
3811 # compat function only
3812 sub method {
3813     my $self = shift;
3814     my $info = $self->_method(@_);
3815     return $self->e_method( $self->_method(@_) );
3816 }
3817
3818 sub e_method {
3819     my ($self, $info, $cx) = @_;
3820     my $obj = $self->deparse($info->{object}, 24);
3821
3822     my $meth = $info->{method};
3823     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3824     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3825     if ($info->{object}->name eq 'scope' && want_list $info->{object}) {
3826         # method { $object }
3827         # This must be deparsed this way to preserve list context
3828         # of $object.
3829         my $need_paren = $cx >= 6;
3830         return '(' x $need_paren
3831              . $meth . substr($obj,2) # chop off the "do"
3832              . " $args"
3833              . ')' x $need_paren;
3834     }
3835     my $kid = $obj . "->" . $meth;
3836     if (length $args) {
3837         return $kid . "(" . $args . ")"; # parens mandatory
3838     } else {
3839         return $kid;
3840     }
3841 }
3842
3843 # returns "&" if the prototype doesn't match the args,
3844 # or ("", $args_after_prototype_demunging) if it does.
3845 sub check_proto {
3846     my $self = shift;
3847     return "&" if $self->{'noproto'};
3848     my($proto, @args) = @_;
3849     my($arg, $real);
3850     my $doneok = 0;
3851     my @reals;
3852     # An unbackslashed @ or % gobbles up the rest of the args
3853     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3854     $proto =~ s/^\s*//;
3855     while ($proto) {
3856         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)\s*//;
3857         my $chr = $1;
3858         if ($chr eq "") {
3859             return "&" if @args;
3860         } elsif ($chr eq ";") {
3861             $doneok = 1;
3862         } elsif ($chr eq "@" or $chr eq "%") {
3863             push @reals, map($self->deparse($_, 6), @args);
3864             @args = ();
3865         } else {
3866             $arg = shift @args;
3867             last unless $arg;
3868             if ($chr eq "\$" || $chr eq "_") {
3869                 if (want_scalar $arg) {
3870                     push @reals, $self->deparse($arg, 6);
3871                 } else {
3872                     return "&";
3873                 }
3874             } elsif ($chr eq "&") {
3875                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3876                     push @reals, $self->deparse($arg, 6);
3877                 } else {
3878                     return "&";
3879                 }
3880             } elsif ($chr eq "*") {
3881                 if ($arg->name =~ /^s?refgen$/
3882                     and $arg->first->first->name eq "rv2gv")
3883                   {
3884                       $real = $arg->first->first; # skip refgen, null
3885                       if ($real->first->name eq "gv") {
3886                           push @reals, $self->deparse($real, 6);
3887                       } else {
3888                           push @reals, $self->deparse($real->first, 6);
3889                       }
3890                   } else {
3891                       return "&";
3892                   }
3893             } elsif (substr($chr, 0, 1) eq "\\") {
3894                 $chr =~ tr/\\[]//d;
3895                 if ($arg->name =~ /^s?refgen$/ and
3896                     !null($real = $arg->first) and
3897                     ($chr =~ /\$/ && is_scalar($real->first)
3898                      or ($chr =~ /@/
3899                          && class($real->first->sibling) ne 'NULL'
3900                          && $real->first->sibling->name
3901                          =~ /^(rv2|pad)av$/)
3902                      or ($chr =~ /%/
3903                          && class($real->first->sibling) ne 'NULL'
3904                          && $real->first->sibling->name
3905                          =~ /^(rv2|pad)hv$/)
3906                      #or ($chr =~ /&/ # This doesn't work
3907                      #   && $real->first->name eq "rv2cv")
3908                      or ($chr =~ /\*/
3909                          && $real->first->name eq "rv2gv")))
3910                   {
3911                       push @reals, $self->deparse($real, 6);
3912                   } else {
3913                       return "&";
3914                   }
3915             }
3916        }
3917     }
3918     return "&" if $proto and !$doneok; # too few args and no ';'
3919     return "&" if @args;               # too many args
3920     return ("", join ", ", @reals);
3921 }
3922
3923 sub pp_entersub {
3924     my $self = shift;
3925     my($op, $cx) = @_;
3926     return $self->e_method($self->_method($op, $cx))
3927         unless null $op->first->sibling;
3928     my $prefix = "";
3929     my $amper = "";
3930     my($kid, @exprs);
3931     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3932         $prefix = "do ";
3933     } elsif ($op->private & OPpENTERSUB_AMPER) {
3934         $amper = "&";
3935     }
3936     $kid = $op->first;
3937     $kid = $kid->first->sibling; # skip ex-list, pushmark
3938     for (; not null $kid->sibling; $kid = $kid->sibling) {
3939         push @exprs, $kid;
3940     }
3941     my $simple = 0;
3942     my $proto = undef;
3943     if (is_scope($kid)) {
3944         $amper = "&";
3945         $kid = "{" . $self->deparse($kid, 0) . "}";
3946     } elsif ($kid->first->name eq "gv") {
3947         my $gv = $self->gv_or_padgv($kid->first);
3948         my $cv;
3949         if (class($gv) eq 'GV' && class($cv = $gv->CV) ne "SPECIAL"
3950          || $gv->FLAGS & SVf_ROK && class($cv = $gv->RV) eq 'CV') {
3951             $proto = $cv->PV if $cv->FLAGS & SVf_POK;
3952         }
3953         $simple = 1; # only calls of named functions can be prototyped
3954         $kid = $self->deparse($kid, 24);
3955         if (!$amper) {
3956             if ($kid eq 'main::') {
3957                 $kid = '::';
3958             }
3959             else {
3960               if ($kid !~ /::/ && $kid ne 'x') {
3961                 # Fully qualify any sub name that is also a keyword.  While
3962                 # we could check the import flag, we cannot guarantee that
3963                 # the code deparsed so far would set that flag, so we qual-
3964                 # ify the names regardless of importation.
3965                 my $fq;
3966                 if (exists $feature_keywords{$kid}) {
3967                     $fq++ if $self->feature_enabled($kid);
3968                 } elsif (do { local $@; local $SIG{__DIE__};
3969                               eval { () = prototype "CORE::$kid"; 1 } }) {
3970                     $fq++
3971                 }
3972                 $fq and substr $kid, 0, 0, = $self->{'curstash'}.'::';
3973               }
3974               if ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3975                 $kid = single_delim("q", "'", $kid, $self) . '->';
3976               }
3977             }
3978         }
3979     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3980         $amper = "&";
3981         $kid = $self->deparse($kid, 24);
3982     } else {
3983         $prefix = "";
3984         my $arrow = is_subscriptable($kid->first) || $kid->first->name eq "padcv" ? "" : "->";
3985         $kid = $self->deparse($kid, 24) . $arrow;
3986     }
3987
3988     # Doesn't matter how many prototypes there are, if
3989     # they haven't happened yet!
3990     my $declared;
3991     {
3992         no strict 'refs';
3993         no warnings 'uninitialized';
3994         $declared = exists $self->{'subs_declared'}{$kid}
3995             || (
3996                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3997                  && !exists
3998                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3999                  && defined prototype $self->{'curstash'}."::".$kid
4000                );
4001         if (!$declared && defined($proto)) {
4002             # Avoid "too early to check prototype" warning
4003             ($amper, $proto) = ('&');
4004         }
4005     }
4006
4007     my $args;
4008     if ($declared and defined $proto and not $amper) {
4009         ($amper, $args) = $self->check_proto($proto, @exprs);
4010         if ($amper eq "&") {
4011             $args = join(", ", map($self->deparse($_, 6), @exprs));
4012         }
4013     } else {
4014         $args = join(", ", map($self->deparse($_, 6), @exprs));
4015     }
4016     if ($prefix or $amper) {
4017         if ($kid eq '&') { $kid = "{$kid}" } # &{&} cannot be written as &&
4018         if ($op->flags & OPf_STACKED) {
4019             return $prefix . $amper . $kid . "(" . $args . ")";
4020         } else {
4021             return $prefix . $amper. $kid;
4022         }
4023     } else {
4024         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
4025         # so it must have been translated from a keyword call. Translate
4026         # it back.
4027         $kid =~ s/^CORE::GLOBAL:://;
4028
4029         my $dproto = defined($proto) ? $proto : "undefined";
4030         if (!$declared) {
4031             return "$kid(" . $args . ")";
4032         } elsif ($dproto =~ /^\s*\z/) {
4033             return $kid;
4034         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
4035             # is_scalar is an excessively conservative test here:
4036             # really, we should be comparing to the precedence of the
4037             # top operator of $exprs[0] (ala unop()), but that would
4038             # take some major code restructuring to do right.
4039             return $self->maybe_parens_func($kid, $args, $cx, 16);
4040         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
4041             return $self->maybe_parens_func($kid, $args, $cx, 5);
4042         } else {
4043             return "$kid(" . $args . ")";
4044         }
4045     }
4046 }
4047
4048 sub pp_enterwrite { unop(@_, "write") }
4049
4050 # escape things that cause interpolation in double quotes,
4051 # but not character escapes
4052 sub uninterp {
4053     my($str) = @_;
4054     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
4055     return $str;
4056 }
4057
4058 {
4059 my $bal;
4060 BEGIN {
4061     use re "eval";
4062     # Matches any string which is balanced with respect to {braces}
4063     $bal = qr(
4064       (?:
4065         [^\\{}]
4066       | \\\\
4067       | \\[{}]
4068       | \{(??{$bal})\}
4069       )*
4070     )x;
4071 }
4072
4073 # the same, but treat $|, $), $( and $ at the end of the string differently
4074 sub re_uninterp {
4075     my($str) = @_;
4076
4077     $str =~ s/
4078           ( ^|\G                  # $1
4079           | [^\\]
4080           )
4081
4082           (                       # $2
4083             (?:\\\\)*
4084           )
4085
4086           (                       # $3
4087             (\(\?\??\{$bal\}\))   # $4
4088           | [\$\@]
4089             (?!\||\)|\(|$)
4090           | \\[uUlLQE]
4091           )
4092
4093         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
4094
4095     return $str;
4096 }
4097
4098 # This is for regular expressions with the /x modifier
4099 # We have to leave comments unmangled.
4100 sub re_uninterp_extended {
4101     my($str) = @_;
4102
4103     $str =~ s/
4104           ( ^|\G                  # $1
4105           | [^\\]
4106           )
4107
4108           (                       # $2
4109             (?:\\\\)*
4110           )
4111
4112           (                       # $3
4113             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
4114             | \#[^\n]*            #     (skip over comments)
4115             )
4116           | [\$\@]
4117             (?!\||\)|\(|$|\s)
4118           | \\[uUlLQE]
4119           )
4120
4121         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
4122
4123     return $str;
4124 }
4125 }
4126
4127 my %unctrl = # portable to EBCDIC
4128     (
4129      "\c@" => '\c@',    # unused
4130      "\cA" => '\cA',
4131      "\cB" => '\cB',
4132      "\cC" => '\cC',
4133      "\cD" => '\cD',
4134      "\cE" => '\cE',
4135      "\cF" => '\cF',
4136      "\cG" => '\cG',
4137      "\cH" => '\cH',
4138      "\cI" => '\cI',
4139      "\cJ" => '\cJ',
4140      "\cK" => '\cK',
4141      "\cL" => '\cL',
4142      "\cM" => '\cM',
4143      "\cN" => '\cN',
4144      "\cO" => '\cO',
4145      "\cP" => '\cP',
4146      "\cQ" => '\cQ',
4147      "\cR" => '\cR',
4148      "\cS" => '\cS',
4149      "\cT" => '\cT',
4150      "\cU" => '\cU',
4151      "\cV" => '\cV',
4152      "\cW" => '\cW',
4153      "\cX" => '\cX',
4154      "\cY" => '\cY',
4155      "\cZ" => '\cZ',
4156      "\c[" => '\c[',    # unused
4157      "\c\\" => '\c\\',  # unused
4158      "\c]" => '\c]',    # unused
4159      "\c_" => '\c_',    # unused
4160     );
4161
4162 # character escapes, but not delimiters that might need to be escaped
4163 sub escape_str { # ASCII, UTF8
4164     my($str) = @_;
4165     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4166     $str =~ s/\a/\\a/g;
4167 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
4168     $str =~ s/\t/\\t/g;
4169     $str =~ s/\n/\\n/g;
4170     $str =~ s/\e/\\e/g;
4171     $str =~ s/\f/\\f/g;
4172     $str =~ s/\r/\\r/g;
4173     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
4174     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
4175     return $str;
4176 }
4177
4178 # For regexes with the /x modifier.
4179 # Leave whitespace unmangled.
4180 sub escape_extended_re {
4181     my($str) = @_;
4182     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4183     $str =~ s/([[:^print:]])/
4184         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
4185     $str =~ s/\n/\n\f/g;
4186     return $str;
4187 }
4188
4189 # Don't do this for regexen
4190 sub unback {
4191     my($str) = @_;
4192     $str =~ s/\\/\\\\/g;
4193     return $str;
4194 }
4195
4196 # Remove backslashes which precede literal control characters,
4197 # to avoid creating ambiguity when we escape the latter.
4198 sub re_unback {
4199     my($str) = @_;
4200
4201     # the insane complexity here is due to the behaviour of "\c\"
4202     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
4203     return $str;
4204 }
4205
4206 sub balanced_delim {
4207     my($str) = @_;
4208     my @str = split //, $str;
4209     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
4210     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
4211         ($open, $close) = @$ar;
4212         $fail = 0; $cnt = 0; $last_bs = 0;
4213         for $c (@str) {
4214             if ($c eq $open) {
4215                 $fail = 1 if $last_bs;
4216                 $cnt++;
4217             } elsif ($c eq $close) {
4218                 $fail = 1 if $last_bs;
4219                 $cnt--;
4220                 if ($cnt < 0) {
4221                     # qq()() isn't ")("
4222                     $fail = 1;
4223                     last;
4224                 }
4225             }
4226             $last_bs = $c eq '\\';
4227         }
4228         $fail = 1 if $cnt != 0;
4229         return ($open, "$open$str$close") if not $fail;
4230     }
4231     return ("", $str);
4232 }
4233
4234 sub single_delim {
4235     my($q, $default, $str, $self) = @_;
4236     return "$default$str$default" if $default and index($str, $default) == -1;
4237     my $coreq = $self->keyword($q); # maybe CORE::q
4238     if ($q ne 'qr') {
4239         (my $succeed, $str) = balanced_delim($str);
4240         return "$coreq$str" if $succeed;
4241     }
4242     for my $delim ('/', '"', '#') {
4243         return "$coreq$delim" . $str . $delim if index($str, $delim) == -1;
4244     }
4245     if ($default) {
4246         $str =~ s/$default/\\$default/g;
4247         return "$default$str$default";
4248     } else {
4249         $str =~ s[/][\\/]g;
4250         return "$coreq/$str/";
4251     }
4252 }
4253
4254 my $max_prec;
4255 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
4256
4257 # Split a floating point number into an integer mantissa and a binary
4258 # exponent. Assumes you've already made sure the number isn't zero or
4259 # some weird infinity or NaN.
4260 sub split_float {
4261     my($f) = @_;
4262     my $exponent = 0;
4263     if ($f == int($f)) {
4264         while ($f % 2 == 0) {
4265             $f /= 2;
4266             $exponent++;
4267         }
4268     } else {
4269         while ($f != int($f)) {
4270             $f *= 2;
4271             $exponent--;
4272         }
4273     }
4274     my $mantissa = sprintf("%.0f", $f);
4275     return ($mantissa, $exponent);
4276 }
4277
4278 sub const {
4279     my $self = shift;
4280     my($sv, $cx) = @_;
4281     if ($self->{'use_dumper'}) {
4282         return $self->const_dumper($sv, $cx);
4283     }
4284     if (class($sv) eq "SPECIAL") {
4285         # sv_undef, sv_yes, sv_no
4286         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
4287     }
4288     if (class($sv) eq "NULL") {
4289        return 'undef';
4290     }
4291     # convert a version object into the "v1.2.3" string in its V magic
4292     if ($sv->FLAGS & SVs_RMG) {
4293         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4294             return $mg->PTR if $mg->TYPE eq 'V';
4295         }
4296     }
4297
4298     if ($sv->FLAGS & SVf_IOK) {
4299         my $str = $sv->int_value;
4300         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
4301         return $str;
4302     } elsif ($sv->FLAGS & SVf_NOK) {
4303         my $nv = $sv->NV;
4304         if ($nv == 0) {
4305             if (pack("F", $nv) eq pack("F", 0)) {
4306                 # positive zero
4307                 return "0";
4308             } else {
4309                 # negative zero
4310                 return $self->maybe_parens("-.0", $cx, 21);
4311             }
4312         } elsif (1/$nv == 0) {
4313             if ($nv > 0) {
4314                 # positive infinity
4315                 return $self->maybe_parens("9**9**9", $cx, 22);
4316             } else {
4317                 # negative infinity
4318                 return $self->maybe_parens("-9**9**9", $cx, 21);
4319             }
4320         } elsif ($nv != $nv) {
4321             # NaN
4322             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
4323                 # the normal kind
4324                 return "sin(9**9**9)";
4325             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
4326                 # the inverted kind
4327                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
4328             } else {
4329                 # some other kind
4330                 my $hex = unpack("h*", pack("F", $nv));
4331                 return qq'unpack("F", pack("h*", "$hex"))';
4332             }
4333         }
4334         # first, try the default stringification
4335         my $str = "$nv";
4336         if ($str != $nv) {
4337             # failing that, try using more precision
4338             $str = sprintf("%.${max_prec}g", $nv);
4339 #           if (pack("F", $str) ne pack("F", $nv)) {
4340             if ($str != $nv) {
4341                 # not representable in decimal with whatever sprintf()
4342                 # and atof() Perl is using here.
4343                 my($mant, $exp) = split_float($nv);
4344                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
4345             }
4346         }
4347         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
4348         return $str;
4349     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
4350         my $ref = $sv->RV;
4351         if (class($ref) eq "AV") {
4352             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
4353         } elsif (class($ref) eq "HV") {
4354             my %hash = $ref->ARRAY;
4355             my @elts;
4356             for my $k (sort keys %hash) {
4357                 push @elts, "$k => " . $self->const($hash{$k}, 6);
4358             }
4359             return "{" . join(", ", @elts) . "}";
4360         } elsif (class($ref) eq "CV") {
4361             BEGIN {
4362                 if ($] > 5.0150051) {
4363                     require overloading;
4364                     unimport overloading;
4365                 }
4366             }
4367             if ($] > 5.0150051 && $self->{curcv} &&
4368                  $self->{curcv}->object_2svref == $ref->object_2svref) {
4369                 return $self->keyword("__SUB__");
4370             }
4371             return "sub " . $self->deparse_sub($ref);
4372         }
4373         if ($ref->FLAGS & SVs_SMG) {
4374             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4375                 if ($mg->TYPE eq 'r') {
4376                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
4377                     return single_delim("qr", "", $re, $self);
4378                 }
4379             }
4380         }
4381         
4382         my $const = $self->const($ref, 20);
4383         if ($self->{in_subst_repl} && $const =~ /^[0-9]/) {
4384             $const = "($const)";
4385         }
4386         return $self->maybe_parens("\\$const", $cx, 20);
4387     } elsif ($sv->FLAGS & SVf_POK) {
4388         my $str = $sv->PV;
4389         if ($str =~ /[[:^print:]]/) {
4390             return single_delim("qq", '"',
4391                                  uninterp(escape_str unback $str), $self);
4392         } else {
4393             return single_delim("q", "'", unback($str), $self);
4394         }
4395     } else {
4396         return "undef";
4397     }
4398 }
4399
4400 sub const_dumper {
4401     my $self = shift;
4402     my($sv, $cx) = @_;
4403     my $ref = $sv->object_2svref();
4404     my $dumper = Data::Dumper->new([$$ref], ['$v']);
4405     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
4406     my $str = $dumper->Dump();
4407     if ($str =~ /^\$v/) {
4408         return '${my ' . $str . ' \$v}';
4409     } else {
4410         return $str;
4411     }
4412 }
4413
4414 sub const_sv {
4415     my $self = shift;
4416     my $op = shift;
4417     my $sv = $op->sv;
4418     # the constant could be in the pad (under useithreads)
4419     $sv = $self->padval($op->targ) unless $$sv;
4420     return $sv;
4421 }
4422
4423 sub meth_sv {
4424     my $self = shift;
4425     my $op = shift;
4426     my $sv = $op->meth_sv;
4427     # the constant could be in the pad (under useithreads)
4428     $sv = $self->padval($op->targ) unless $$sv;
4429     return $sv;
4430 }
4431
4432 sub pp_const {
4433     my $self = shift;
4434     my($op, $cx) = @_;
4435     if ($op->private & OPpCONST_ARYBASE) {
4436         return '$[';
4437     }
4438 #    if ($op->private & OPpCONST_BARE) { # trouble with '=>' autoquoting
4439 #       return $self->const_sv($op)->PV;
4440 #    }
4441     my $sv = $self->const_sv($op);
4442     return $self->const($sv, $cx);
4443 }
4444
4445 sub dq {
4446     my $self = shift;
4447     my $op = shift;
4448     my $type = $op->name;
4449     if ($type eq "const") {
4450         return '$[' if $op->private & OPpCONST_ARYBASE;
4451         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
4452     } elsif ($type eq "concat") {
4453         my $first = $self->dq($op->first);
4454         my $last  = $self->dq($op->last);
4455
4456         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
4457         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4458             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4459             || ($last =~ /^[:'{\[\w_]/ && #'
4460                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4461
4462         return $first . $last;
4463     } elsif ($type eq "uc") {
4464         return '\U' . $self->dq($op->first->sibling) . '\E';
4465     } elsif ($type eq "lc") {
4466         return '\L' . $self->dq($op->first->sibling) . '\E';
4467     } elsif ($type eq "ucfirst") {
4468         return '\u' . $self->dq($op->first->sibling);
4469     } elsif ($type eq "lcfirst") {
4470         return '\l' . $self->dq($op->first->sibling);
4471     } elsif ($type eq "quotemeta") {
4472         return '\Q' . $self->dq($op->first->sibling) . '\E';
4473     } elsif ($type eq "fc") {
4474         return '\F' . $self->dq($op->first->sibling) . '\E';
4475     } elsif ($type eq "join") {
4476         return $self->deparse($op->last, 26); # was join($", @ary)
4477     } else {
4478         return $self->deparse($op, 26);
4479     }
4480 }
4481
4482 sub pp_backtick {
4483     my $self = shift;
4484     my($op, $cx) = @_;
4485     # skip pushmark if it exists (readpipe() vs ``)
4486     my $child = $op->first->sibling->isa('B::NULL')
4487         ? $op->first : $op->first->sibling;
4488     if ($self->pure_string($child)) {
4489         return single_delim("qx", '`', $self->dq($child, 1), $self);
4490     }
4491     unop($self, @_, "readpipe");
4492 }
4493
4494 sub dquote {
4495     my $self = shift;
4496     my($op, $cx) = @_;
4497     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
4498  &nb